This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
2047dd60478318c977e72842bcacd46817812db8
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2 X<function>
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides a scalar context to its
16 argument, while a list operator may provide either scalar or list
17 contexts for its arguments.  If it does both, scalar arguments 
18 come first and list argument follow, and there can only ever
19 be one such list argument.  For instance, splice() has three scalar
20 arguments followed by a list, whereas gethostbyname() has four scalar
21 arguments.
22
23 In the syntax descriptions that follow, list operators that expect a
24 list (and provide list context for elements of the list) are shown
25 with LIST as an argument.  Such a list may consist of any combination
26 of scalar arguments or list values; the list values will be included
27 in the list as if each individual element were interpolated at that
28 point in the list, forming a longer single-dimensional list value.
29 Commas should separate literal elements of the LIST.
30
31 Any function in the list below may be used either with or without
32 parentheses around its arguments.  (The syntax descriptions omit the
33 parentheses.)  If you use parentheses, the simple but occasionally 
34 surprising rule is this: It I<looks> like a function, therefore it I<is> a
35 function, and precedence doesn't matter.  Otherwise it's a list
36 operator or unary operator, and precedence does matter.  Whitespace
37 between the function and left parenthesis doesn't count, so sometimes
38 you need to be careful:
39
40     print 1+2+4;      # Prints 7.
41     print(1+2) + 4;   # Prints 3.
42     print (1+2)+4;    # Also prints 3!
43     print +(1+2)+4;   # Prints 7.
44     print ((1+2)+4);  # Prints 7.
45
46 If you run Perl with the B<-w> switch it can warn you about this.  For
47 example, the third line above produces:
48
49     print (...) interpreted as function at - line 1.
50     Useless use of integer addition in void context at - line 1.
51
52 A few functions take no arguments at all, and therefore work as neither
53 unary nor list operators.  These include such functions as C<time>
54 and C<endpwent>.  For example, C<time+86_400> always means
55 C<time() + 86_400>.
56
57 For functions that can be used in either a scalar or list context,
58 nonabortive failure is generally indicated in a scalar context by
59 returning the undefined value, and in a list context by returning the
60 empty list.
61
62 Remember the following important rule: There is B<no rule> that relates
63 the behavior of an expression in list context to its behavior in scalar
64 context, or vice versa.  It might do two totally different things.
65 Each operator and function decides which sort of value would be most
66 appropriate to return in scalar context.  Some operators return the
67 length of the list that would have been returned in list context.  Some
68 operators return the first value in the list.  Some operators return the
69 last value in the list.  Some operators return a count of successful
70 operations.  In general, they do what you want, unless you want
71 consistency.
72 X<context>
73
74 A named array in scalar context is quite different from what would at
75 first glance appear to be a list in scalar context.  You can't get a list
76 like C<(1,2,3)> into being in scalar context, because the compiler knows
77 the context at compile time.  It would generate the scalar comma operator
78 there, not the list construction version of the comma.  That means it
79 was never a list to start with.
80
81 In general, functions in Perl that serve as wrappers for system calls ("syscalls")
82 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
83 true when they succeed and C<undef> otherwise, as is usually mentioned
84 in the descriptions below.  This is different from the C interfaces,
85 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
86 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
87 variable on failure.  Other functions do not, except accidentally.
88
89 Extension modules can also hook into the Perl parser to define new
90 kinds of keyword-headed expression.  These may look like functions, but
91 may also look completely different.  The syntax following the keyword
92 is defined entirely by the extension.  If you are an implementor, see
93 L<perlapi/PL_keyword_plugin> for the mechanism.  If you are using such
94 a module, see the module's documentation for details of the syntax that
95 it defines.
96
97 =head2 Perl Functions by Category
98 X<function>
99
100 Here are Perl's functions (including things that look like
101 functions, like some keywords and named operators)
102 arranged by category.  Some functions appear in more
103 than one place.
104
105 =over 4
106
107 =item Functions for SCALARs or strings
108 X<scalar> X<string> X<character>
109
110 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
111 C<length>, C<oct>, C<ord>, C<pack>, C<q//>, C<qq//>, C<reverse>,
112 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
113
114 =item Regular expressions and pattern matching
115 X<regular expression> X<regex> X<regexp>
116
117 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
118
119 =item Numeric functions
120 X<numeric> X<number> X<trigonometric> X<trigonometry>
121
122 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
123 C<sin>, C<sqrt>, C<srand>
124
125 =item Functions for real @ARRAYs
126 X<array>
127
128 C<each>, C<keys>, C<pop>, C<push>, C<shift>, C<splice>, C<unshift>, C<values>
129
130 =item Functions for list data
131 X<list>
132
133 C<grep>, C<join>, C<map>, C<qw//>, C<reverse>, C<sort>, C<unpack>
134
135 =item Functions for real %HASHes
136 X<hash>
137
138 C<delete>, C<each>, C<exists>, C<keys>, C<values>
139
140 =item Input and output functions
141 X<I/O> X<input> X<output> X<dbm>
142
143 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
144 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
145 C<readdir>, C<rewinddir>, C<say>, C<seek>, C<seekdir>, C<select>, C<syscall>,
146 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
147 C<warn>, C<write>
148
149 =item Functions for fixed length data or records
150
151 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
152
153 =item Functions for filehandles, files, or directories
154 X<file> X<filehandle> X<directory> X<pipe> X<link> X<symlink>
155
156 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
157 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
158 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
159 C<umask>, C<unlink>, C<utime>
160
161 =item Keywords related to the control flow of your Perl program
162 X<control flow>
163
164 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
165 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
166
167 =item Keywords related to switch
168
169 C<break>, C<continue>, C<given>, C<when>, C<default>
170
171 (These are available only if you enable the C<"switch"> feature.
172 See L<feature> and L<perlsyn/"Switch statements">.)
173
174 =item Keywords related to scoping
175
176 C<caller>, C<import>, C<local>, C<my>, C<our>, C<state>, C<package>,
177 C<use>
178
179 (C<state> is available only if the C<"state"> feature is enabled. See
180 L<feature>.)
181
182 =item Miscellaneous functions
183
184 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>,
185 C<reset>, C<scalar>, C<state>, C<undef>, C<wantarray>
186
187 =item Functions for processes and process groups
188 X<process> X<pid> X<process id>
189
190 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
191 C<pipe>, C<qx//>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
192 C<times>, C<wait>, C<waitpid>
193
194 =item Keywords related to Perl modules
195 X<module>
196
197 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
198
199 =item Keywords related to classes and object-orientation
200 X<object> X<class> X<package>
201
202 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
203 C<untie>, C<use>
204
205 =item Low-level socket functions
206 X<socket> X<sock>
207
208 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
209 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
210 C<socket>, C<socketpair>
211
212 =item System V interprocess communication functions
213 X<IPC> X<System V> X<semaphore> X<shared memory> X<memory> X<message>
214
215 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
216 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
217
218 =item Fetching user and group info
219 X<user> X<group> X<password> X<uid> X<gid>  X<passwd> X</etc/passwd>
220
221 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
222 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
223 C<getpwuid>, C<setgrent>, C<setpwent>
224
225 =item Fetching network info
226 X<network> X<protocol> X<host> X<hostname> X<IP> X<address> X<service>
227
228 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
229 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
230 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
231 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
232 C<setnetent>, C<setprotoent>, C<setservent>
233
234 =item Time-related functions
235 X<time> X<date>
236
237 C<gmtime>, C<localtime>, C<time>, C<times>
238
239 =item Functions new in perl5
240 X<perl5>
241
242 C<abs>, C<bless>, C<break>, C<chomp>, C<chr>, C<continue>, C<default>, 
243 C<exists>, C<formline>, C<given>, C<glob>, C<import>, C<lc>, C<lcfirst>,
244 C<lock>, C<map>, C<my>, C<no>, C<our>, C<prototype>, C<qr//>, C<qw//>, C<qx//>,
245 C<readline>, C<readpipe>, C<ref>, C<sub>*, C<sysopen>, C<tie>, C<tied>, C<uc>,
246 C<ucfirst>, C<untie>, C<use>, C<when>
247
248 * C<sub> was a keyword in Perl 4, but in Perl 5 it is an
249 operator, which can be used in expressions.
250
251 =item Functions obsoleted in perl5
252
253 C<dbmclose>, C<dbmopen>
254
255 =back
256
257 =head2 Portability
258 X<portability> X<Unix> X<portable>
259
260 Perl was born in Unix and can therefore access all common Unix
261 system calls.  In non-Unix environments, the functionality of some
262 Unix system calls may not be available, or details of the available
263 functionality may differ slightly.  The Perl functions affected
264 by this are:
265
266 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
267 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
268 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
269 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
270 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
271 C<getppid>, C<getpgrp>, C<getpriority>, C<getprotobynumber>,
272 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
273 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
274 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
275 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
276 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
277 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
278 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
279 C<shmwrite>, C<socket>, C<socketpair>,
280 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
281 C<times>, C<truncate>, C<umask>, C<unlink>,
282 C<utime>, C<wait>, C<waitpid>
283
284 For more information about the portability of these functions, see
285 L<perlport> and other available platform-specific documentation.
286
287 =head2 Alphabetical Listing of Perl Functions
288
289 =over 
290
291 =item -X FILEHANDLE
292 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
293 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
294
295 =item -X EXPR
296
297 =item -X DIRHANDLE
298
299 =item -X
300
301 A file test, where X is one of the letters listed below.  This unary
302 operator takes one argument, either a filename, a filehandle, or a dirhandle, 
303 and tests the associated file to see if something is true about it.  If the
304 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
305 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
306 the undefined value if the file doesn't exist.  Despite the funny
307 names, precedence is the same as any other named unary operator.  The
308 operator may be any of:
309
310     -r  File is readable by effective uid/gid.
311     -w  File is writable by effective uid/gid.
312     -x  File is executable by effective uid/gid.
313     -o  File is owned by effective uid.
314
315     -R  File is readable by real uid/gid.
316     -W  File is writable by real uid/gid.
317     -X  File is executable by real uid/gid.
318     -O  File is owned by real uid.
319
320     -e  File exists.
321     -z  File has zero size (is empty).
322     -s  File has nonzero size (returns size in bytes).
323
324     -f  File is a plain file.
325     -d  File is a directory.
326     -l  File is a symbolic link.
327     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
328     -S  File is a socket.
329     -b  File is a block special file.
330     -c  File is a character special file.
331     -t  Filehandle is opened to a tty.
332
333     -u  File has setuid bit set.
334     -g  File has setgid bit set.
335     -k  File has sticky bit set.
336
337     -T  File is an ASCII text file (heuristic guess).
338     -B  File is a "binary" file (opposite of -T).
339
340     -M  Script start time minus file modification time, in days.
341     -A  Same for access time.
342     -C  Same for inode change time (Unix, may differ for other platforms)
343
344 Example:
345
346     while (<>) {
347         chomp;
348         next unless -f $_;  # ignore specials
349         #...
350     }
351
352 The interpretation of the file permission operators C<-r>, C<-R>,
353 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
354 of the file and the uids and gids of the user.  There may be other
355 reasons you can't actually read, write, or execute the file: for
356 example network filesystem access controls, ACLs (access control lists),
357 read-only filesystems, and unrecognized executable formats.  Note
358 that the use of these six specific operators to verify if some operation
359 is possible is usually a mistake, because it may be open to race
360 conditions.
361
362 Also note that, for the superuser on the local filesystems, the C<-r>,
363 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
364 if any execute bit is set in the mode.  Scripts run by the superuser
365 may thus need to do a stat() to determine the actual mode of the file,
366 or temporarily set their effective uid to something else.
367
368 If you are using ACLs, there is a pragma called C<filetest> that may
369 produce more accurate results than the bare stat() mode bits.
370 When under the C<use filetest 'access'> the above-mentioned filetests
371 test whether the permission can (not) be granted using the
372 access(2) family of system calls.  Also note that the C<-x> and C<-X> may
373 under this pragma return true even if there are no execute permission
374 bits set (nor any extra execute permission ACLs).  This strangeness is
375 due to the underlying system calls' definitions. Note also that, due to
376 the implementation of C<use filetest 'access'>, the C<_> special
377 filehandle won't cache the results of the file tests when this pragma is
378 in effect.  Read the documentation for the C<filetest> pragma for more
379 information.
380
381 Note that C<-s/a/b/> does not do a negated substitution.  Saying
382 C<-exp($foo)> still works as expected, however: only single letters
383 following a minus are interpreted as file tests.
384
385 The C<-T> and C<-B> switches work as follows.  The first block or so of the
386 file is examined for odd characters such as strange control codes or
387 characters with the high bit set.  If too many strange characters (>30%)
388 are found, it's a C<-B> file; otherwise it's a C<-T> file.  Also, any file
389 containing a zero byte in the first block is considered a binary file.  If C<-T>
390 or C<-B> is used on a filehandle, the current IO buffer is examined
391 rather than the first block.  Both C<-T> and C<-B> return true on an empty
392 file, or a file at EOF when testing a filehandle.  Because you have to
393 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
394 against the file first, as in C<next unless -f $file && -T $file>.
395
396 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
397 the special filehandle consisting of a solitary underline, then the stat
398 structure of the previous file test (or stat operator) is used, saving
399 a system call.  (This doesn't work with C<-t>, and you need to remember
400 that lstat() and C<-l> leave values in the stat structure for the
401 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
402 an C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
403 Example:
404
405     print "Can do.\n" if -r $a || -w _ || -x _;
406
407     stat($filename);
408     print "Readable\n" if -r _;
409     print "Writable\n" if -w _;
410     print "Executable\n" if -x _;
411     print "Setuid\n" if -u _;
412     print "Setgid\n" if -g _;
413     print "Sticky\n" if -k _;
414     print "Text\n" if -T _;
415     print "Binary\n" if -B _;
416
417 As of Perl 5.9.1, as a form of purely syntactic sugar, you can stack file
418 test operators, in a way that C<-f -w -x $file> is equivalent to
419 C<-x $file && -w _ && -f _>. (This is only fancy fancy: if you use
420 the return value of C<-f $file> as an argument to another filetest
421 operator, no special magic will happen.)
422
423 =item abs VALUE
424 X<abs> X<absolute>
425
426 =item abs
427
428 Returns the absolute value of its argument.
429 If VALUE is omitted, uses C<$_>.
430
431 =item accept NEWSOCKET,GENERICSOCKET
432 X<accept>
433
434 Accepts an incoming socket connect, just as accept(2) 
435 does.  Returns the packed address if it succeeded, false otherwise.
436 See the example in L<perlipc/"Sockets: Client/Server Communication">.
437
438 On systems that support a close-on-exec flag on files, the flag will
439 be set for the newly opened file descriptor, as determined by the
440 value of $^F.  See L<perlvar/$^F>.
441
442 =item alarm SECONDS
443 X<alarm>
444 X<SIGALRM>
445 X<timer>
446
447 =item alarm
448
449 Arranges to have a SIGALRM delivered to this process after the
450 specified number of wallclock seconds has elapsed.  If SECONDS is not
451 specified, the value stored in C<$_> is used. (On some machines,
452 unfortunately, the elapsed time may be up to one second less or more
453 than you specified because of how seconds are counted, and process
454 scheduling may delay the delivery of the signal even further.)
455
456 Only one timer may be counting at once.  Each call disables the
457 previous timer, and an argument of C<0> may be supplied to cancel the
458 previous timer without starting a new one.  The returned value is the
459 amount of time remaining on the previous timer.
460
461 For delays of finer granularity than one second, the Time::HiRes module
462 (from CPAN, and starting from Perl 5.8 part of the standard
463 distribution) provides ualarm().  You may also use Perl's four-argument
464 version of select() leaving the first three arguments undefined, or you
465 might be able to use the C<syscall> interface to access setitimer(2) if
466 your system supports it. See L<perlfaq8> for details.
467
468 It is usually a mistake to intermix C<alarm> and C<sleep> calls, because
469 C<sleep> may be internally implemented on your system with C<alarm>.
470
471 If you want to use C<alarm> to time out a system call you need to use an
472 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
473 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
474 restart system calls on some systems.  Using C<eval>/C<die> always works,
475 modulo the caveats given in L<perlipc/"Signals">.
476
477     eval {
478         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
479         alarm $timeout;
480         $nread = sysread SOCKET, $buffer, $size;
481         alarm 0;
482     };
483     if ($@) {
484         die unless $@ eq "alarm\n";   # propagate unexpected errors
485         # timed out
486     }
487     else {
488         # didn't
489     }
490
491 For more information see L<perlipc>.
492
493 =item atan2 Y,X
494 X<atan2> X<arctangent> X<tan> X<tangent>
495
496 Returns the arctangent of Y/X in the range -PI to PI.
497
498 For the tangent operation, you may use the C<Math::Trig::tan>
499 function, or use the familiar relation:
500
501     sub tan { sin($_[0]) / cos($_[0])  }
502
503 The return value for C<atan2(0,0)> is implementation-defined; consult
504 your atan2(3) manpage for more information.
505
506 =item bind SOCKET,NAME
507 X<bind>
508
509 Binds a network address to a socket, just as bind(2)
510 does.  Returns true if it succeeded, false otherwise.  NAME should be a
511 packed address of the appropriate type for the socket.  See the examples in
512 L<perlipc/"Sockets: Client/Server Communication">.
513
514 =item binmode FILEHANDLE, LAYER
515 X<binmode> X<binary> X<text> X<DOS> X<Windows>
516
517 =item binmode FILEHANDLE
518
519 Arranges for FILEHANDLE to be read or written in "binary" or "text"
520 mode on systems where the run-time libraries distinguish between
521 binary and text files.  If FILEHANDLE is an expression, the value is
522 taken as the name of the filehandle.  Returns true on success,
523 otherwise it returns C<undef> and sets C<$!> (errno).
524
525 On some systems (in general, DOS and Windows-based systems) binmode()
526 is necessary when you're not working with a text file.  For the sake
527 of portability it is a good idea to always use it when appropriate,
528 and to never use it when it isn't appropriate.  Also, people can
529 set their I/O to be by default UTF-8 encoded Unicode, not bytes.
530
531 In other words: regardless of platform, use binmode() on binary data,
532 like for example images.
533
534 If LAYER is present it is a single string, but may contain multiple
535 directives. The directives alter the behaviour of the filehandle.
536 When LAYER is present using binmode on a text file makes sense.
537
538 If LAYER is omitted or specified as C<:raw> the filehandle is made
539 suitable for passing binary data. This includes turning off possible CRLF
540 translation and marking it as bytes (as opposed to Unicode characters).
541 Note that, despite what may be implied in I<"Programming Perl"> (the
542 Camel, 3rd edition) or elsewhere, C<:raw> is I<not> simply the inverse of C<:crlf>.
543 Other layers that would affect the binary nature of the stream are
544 I<also> disabled. See L<PerlIO>, L<perlrun>, and the discussion about the
545 PERLIO environment variable.
546
547 The C<:bytes>, C<:crlf>, C<:utf8>, and any other directives of the
548 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
549 establish default I/O layers.  See L<open>.
550
551 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
552 in "Programming Perl, 3rd Edition".  However, since the publishing of this
553 book, by many known as "Camel III", the consensus of the naming of this
554 functionality has moved from "discipline" to "layer".  All documentation
555 of this version of Perl therefore refers to "layers" rather than to
556 "disciplines".  Now back to the regularly scheduled documentation...>
557
558 To mark FILEHANDLE as UTF-8, use C<:utf8> or C<:encoding(utf8)>.
559 C<:utf8> just marks the data as UTF-8 without further checking,
560 while C<:encoding(utf8)> checks the data for actually being valid
561 UTF-8. More details can be found in L<PerlIO::encoding>.
562
563 In general, binmode() should be called after open() but before any I/O
564 is done on the filehandle.  Calling binmode() normally flushes any
565 pending buffered output data (and perhaps pending input data) on the
566 handle.  An exception to this is the C<:encoding> layer that
567 changes the default character encoding of the handle, see L<open>.
568 The C<:encoding> layer sometimes needs to be called in
569 mid-stream, and it doesn't flush the stream.  The C<:encoding>
570 also implicitly pushes on top of itself the C<:utf8> layer because
571 internally Perl operates on UTF8-encoded Unicode characters.
572
573 The operating system, device drivers, C libraries, and Perl run-time
574 system all work together to let the programmer treat a single
575 character (C<\n>) as the line terminator, irrespective of the external
576 representation.  On many operating systems, the native text file
577 representation matches the internal representation, but on some
578 platforms the external representation of C<\n> is made up of more than
579 one character.
580
581 Mac OS, all variants of Unix, and Stream_LF files on VMS use a single
582 character to end each line in the external representation of text (even
583 though that single character is CARRIAGE RETURN on Mac OS and LINE FEED
584 on Unix and most VMS files). In other systems like OS/2, DOS and the
585 various flavors of MS-Windows your program sees a C<\n> as a simple C<\cJ>,
586 but what's stored in text files are the two characters C<\cM\cJ>.  That
587 means that, if you don't use binmode() on these systems, C<\cM\cJ>
588 sequences on disk will be converted to C<\n> on input, and any C<\n> in
589 your program will be converted back to C<\cM\cJ> on output.  This is what
590 you want for text files, but it can be disastrous for binary files.
591
592 Another consequence of using binmode() (on some systems) is that
593 special end-of-file markers will be seen as part of the data stream.
594 For systems from the Microsoft family this means that if your binary
595 data contains C<\cZ>, the I/O subsystem will regard it as the end of
596 the file, unless you use binmode().
597
598 binmode() is important not only for readline() and print() operations,
599 but also when using read(), seek(), sysread(), syswrite() and tell()
600 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
601 in L<perlvar> for how to manually set your input and output
602 line-termination sequences.
603
604 =item bless REF,CLASSNAME
605 X<bless>
606
607 =item bless REF
608
609 This function tells the thingy referenced by REF that it is now an object
610 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
611 is used.  Because a C<bless> is often the last thing in a constructor,
612 it returns the reference for convenience.  Always use the two-argument
613 version if a derived class might inherit the function doing the blessing.
614 See L<perltoot> and L<perlobj> for more about the blessing (and blessings)
615 of objects.
616
617 Consider always blessing objects in CLASSNAMEs that are mixed case.
618 Namespaces with all lowercase names are considered reserved for
619 Perl pragmata.  Builtin types have all uppercase names. To prevent
620 confusion, you may wish to avoid such package names as well.  Make sure
621 that CLASSNAME is a true value.
622
623 See L<perlmod/"Perl Modules">.
624
625 =item break
626
627 Break out of a C<given()> block.
628
629 This keyword is enabled by the C<"switch"> feature: see L<feature>
630 for more information.
631
632 =item caller EXPR
633 X<caller> X<call stack> X<stack> X<stack trace>
634
635 =item caller
636
637 Returns the context of the current subroutine call.  In scalar context,
638 returns the caller's package name if there I<is> a caller (that is, if
639 we're in a subroutine or C<eval> or C<require>) and the undefined value
640 otherwise.  In list context, returns
641
642     # 0         1          2
643     ($package, $filename, $line) = caller;
644
645 With EXPR, it returns some extra information that the debugger uses to
646 print a stack trace.  The value of EXPR indicates how many call frames
647 to go back before the current one.
648
649     #  0         1          2      3            4
650     ($package, $filename, $line, $subroutine, $hasargs,
651
652     #  5          6          7            8       9         10
653     $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash)
654      = caller($i);
655
656 Here $subroutine may be C<(eval)> if the frame is not a subroutine
657 call, but an C<eval>.  In such a case additional elements $evaltext and
658 C<$is_require> are set: C<$is_require> is true if the frame is created by a
659 C<require> or C<use> statement, $evaltext contains the text of the
660 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
661 $subroutine is C<(eval)>, but $evaltext is undefined.  (Note also that
662 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
663 frame.)  $subroutine may also be C<(unknown)> if this particular
664 subroutine happens to have been deleted from the symbol table.
665 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
666 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
667 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
668 between versions of Perl, and are not meant for external use.
669
670 C<$hinthash> is a reference to a hash containing the value of C<%^H> when the
671 caller was compiled, or C<undef> if C<%^H> was empty. Do not modify the values
672 of this hash, as they are the actual values stored in the optree.
673
674 Furthermore, when called from within the DB package, caller returns more
675 detailed information: it sets the list variable C<@DB::args> to be the
676 arguments with which the subroutine was invoked.
677
678 Be aware that the optimizer might have optimized call frames away before
679 C<caller> had a chance to get the information.  That means that C<caller(N)>
680 might not return information about the call frame you expect it to, for
681 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
682 previous time C<caller> was called.
683
684 Also be aware that setting C<@DB::args> is I<best effort>, intended for
685 debugging or generating backtraces, and should not be relied upon. In
686 particular, as C<@_> contains aliases to the caller's arguments, Perl does
687 not take a copy of C<@_>, so C<@DB::args> will contain modifications the
688 subroutine makes to C<@_> or its contents, not the original values at call
689 time. C<@DB::args>, like C<@_>, does not hold explicit references to its
690 elements, so under certain cases its elements may have become freed and
691 reallocated for other variables or temporary values. Finally, a side effect
692 of the current implementation means that the effects of C<shift @_> can
693 I<normally> be undone (but not C<pop @_> or other splicing, and not if a
694 reference to C<@_> has been taken, and subject to the caveat about reallocated
695 elements), so C<@DB::args> is actually a hybrid of the current state and
696 initial state of C<@_>. Buyer beware.
697
698 =item chdir EXPR
699 X<chdir>
700 X<cd>
701 X<directory, change>
702
703 =item chdir FILEHANDLE
704
705 =item chdir DIRHANDLE
706
707 =item chdir
708
709 Changes the working directory to EXPR, if possible. If EXPR is omitted,
710 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
711 changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the
712 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If
713 neither is set, C<chdir> does nothing. It returns true on success,
714 false otherwise. See the example under C<die>.
715
716 On systems that support fchdir(2), you may pass a filehandle or
717 directory handle as argument.  On systems that don't support fchdir(2),
718 passing handles raises an exception.
719
720 =item chmod LIST
721 X<chmod> X<permission> X<mode>
722
723 Changes the permissions of a list of files.  The first element of the
724 list must be the numerical mode, which should probably be an octal
725 number, and which definitely should I<not> be a string of octal digits:
726 C<0644> is okay, but C<"0644"> is not.  Returns the number of files
727 successfully changed.  See also L</oct>, if all you have is a string.
728
729     $cnt = chmod 0755, "foo", "bar";
730     chmod 0755, @executables;
731     $mode = "0644"; chmod $mode, "foo";      # !!! sets mode to
732                                              # --w----r-T
733     $mode = "0644"; chmod oct($mode), "foo"; # this is better
734     $mode = 0644;   chmod $mode, "foo";      # this is best
735
736 On systems that support fchmod(2), you may pass filehandles among the
737 files.  On systems that don't support fchmod(2), passing filehandles raises
738 an exception.  Filehandles must be passed as globs or glob references to be
739 recognized; barewords are considered filenames.
740
741     open(my $fh, "<", "foo");
742     my $perm = (stat $fh)[2] & 07777;
743     chmod($perm | 0600, $fh);
744
745 You can also import the symbolic C<S_I*> constants from the C<Fcntl>
746 module:
747
748     use Fcntl qw( :mode );
749     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
750     # Identical to the chmod 0755 of the example above.
751
752 =item chomp VARIABLE
753 X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol>
754
755 =item chomp( LIST )
756
757 =item chomp
758
759 This safer version of L</chop> removes any trailing string
760 that corresponds to the current value of C<$/> (also known as
761 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
762 number of characters removed from all its arguments.  It's often used to
763 remove the newline from the end of an input record when you're worried
764 that the final record may be missing its newline.  When in paragraph
765 mode (C<$/ = "">), it removes all trailing newlines from the string.
766 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
767 a reference to an integer or the like, see L<perlvar>) chomp() won't
768 remove anything.
769 If VARIABLE is omitted, it chomps C<$_>.  Example:
770
771     while (<>) {
772         chomp;  # avoid \n on last field
773         @array = split(/:/);
774         # ...
775     }
776
777 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
778
779 You can actually chomp anything that's an lvalue, including an assignment:
780
781     chomp($cwd = `pwd`);
782     chomp($answer = <STDIN>);
783
784 If you chomp a list, each element is chomped, and the total number of
785 characters removed is returned.
786
787 Note that parentheses are necessary when you're chomping anything
788 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
789 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
790 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
791 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
792 as C<chomp($a, $b)>.
793
794 =item chop VARIABLE
795 X<chop>
796
797 =item chop( LIST )
798
799 =item chop
800
801 Chops off the last character of a string and returns the character
802 chopped.  It is much more efficient than C<s/.$//s> because it neither
803 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
804 If VARIABLE is a hash, it chops the hash's values, but not its keys.
805
806 You can actually chop anything that's an lvalue, including an assignment.
807
808 If you chop a list, each element is chopped.  Only the value of the
809 last C<chop> is returned.
810
811 Note that C<chop> returns the last character.  To return all but the last
812 character, use C<substr($string, 0, -1)>.
813
814 See also L</chomp>.
815
816 =item chown LIST
817 X<chown> X<owner> X<user> X<group>
818
819 Changes the owner (and group) of a list of files.  The first two
820 elements of the list must be the I<numeric> uid and gid, in that
821 order.  A value of -1 in either position is interpreted by most
822 systems to leave that value unchanged.  Returns the number of files
823 successfully changed.
824
825     $cnt = chown $uid, $gid, 'foo', 'bar';
826     chown $uid, $gid, @filenames;
827
828 On systems that support fchown(2), you may pass filehandles among the
829 files.  On systems that don't support fchown(2), passing filehandles raises
830 an exception.  Filehandles must be passed as globs or glob references to be
831 recognized; barewords are considered filenames.
832
833 Here's an example that looks up nonnumeric uids in the passwd file:
834
835     print "User: ";
836     chomp($user = <STDIN>);
837     print "Files: ";
838     chomp($pattern = <STDIN>);
839
840     ($login,$pass,$uid,$gid) = getpwnam($user)
841         or die "$user not in passwd file";
842
843     @ary = glob($pattern);  # expand filenames
844     chown $uid, $gid, @ary;
845
846 On most systems, you are not allowed to change the ownership of the
847 file unless you're the superuser, although you should be able to change
848 the group to any of your secondary groups.  On insecure systems, these
849 restrictions may be relaxed, but this is not a portable assumption.
850 On POSIX systems, you can detect this condition this way:
851
852     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
853     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
854
855 =item chr NUMBER
856 X<chr> X<character> X<ASCII> X<Unicode>
857
858 =item chr
859
860 Returns the character represented by that NUMBER in the character set.
861 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
862 chr(0x263a) is a Unicode smiley face.  
863
864 Negative values give the Unicode replacement character (chr(0xfffd)),
865 except under the L<bytes> pragma, where the low eight bits of the value
866 (truncated to an integer) are used.
867
868 If NUMBER is omitted, uses C<$_>.
869
870 For the reverse, use L</ord>.
871
872 Note that characters from 128 to 255 (inclusive) are by default
873 internally not encoded as UTF-8 for backward compatibility reasons.
874
875 See L<perlunicode> for more about Unicode.
876
877 =item chroot FILENAME
878 X<chroot> X<root>
879
880 =item chroot
881
882 This function works like the system call by the same name: it makes the
883 named directory the new root directory for all further pathnames that
884 begin with a C</> by your process and all its children.  (It doesn't
885 change your current working directory, which is unaffected.)  For security
886 reasons, this call is restricted to the superuser.  If FILENAME is
887 omitted, does a C<chroot> to C<$_>.
888
889 =item close FILEHANDLE
890 X<close>
891
892 =item close
893
894 Closes the file or pipe associated with the filehandle, flushes the IO
895 buffers, and closes the system file descriptor.  Returns true if those
896 operations have succeeded and if no error was reported by any PerlIO
897 layer.  Closes the currently selected filehandle if the argument is
898 omitted.
899
900 You don't have to close FILEHANDLE if you are immediately going to do
901 another C<open> on it, because C<open> closes it for you.  (See
902 C<open>.)  However, an explicit C<close> on an input file resets the line
903 counter (C<$.>), while the implicit close done by C<open> does not.
904
905 If the filehandle came from a piped open, C<close> returns false if one of
906 the other syscalls involved fails or if its program exits with non-zero
907 status.  If the only problem was that the program exited non-zero, C<$!>
908 will be set to C<0>.  Closing a pipe also waits for the process executing
909 on the pipe to exit--in case you wish to look at the output of the pipe
910 afterwards--and implicitly puts the exit status value of that command into
911 C<$?> and C<${^CHILD_ERROR_NATIVE}>.
912
913 If there are multiple threads running, C<close> on a filehandle from a
914 piped open returns true without waiting for the child process to terminate,
915 if the filehandle is still open in another thread.
916
917 Closing the read end of a pipe before the process writing to it at the
918 other end is done writing results in the writer receiving a SIGPIPE.  If
919 the other end can't handle that, be sure to read all the data before
920 closing the pipe.
921
922 Example:
923
924     open(OUTPUT, '|sort >foo')  # pipe to sort
925         or die "Can't start sort: $!";
926     #...                        # print stuff to output
927     close OUTPUT                # wait for sort to finish
928         or warn $! ? "Error closing sort pipe: $!"
929                    : "Exit status $? from sort";
930     open(INPUT, 'foo')          # get sort's results
931         or die "Can't open 'foo' for input: $!";
932
933 FILEHANDLE may be an expression whose value can be used as an indirect
934 filehandle, usually the real filehandle name.
935
936 =item closedir DIRHANDLE
937 X<closedir>
938
939 Closes a directory opened by C<opendir> and returns the success of that
940 system call.
941
942 =item connect SOCKET,NAME
943 X<connect>
944
945 Attempts to connect to a remote socket, just like connect(2).
946 Returns true if it succeeded, false otherwise.  NAME should be a
947 packed address of the appropriate type for the socket.  See the examples in
948 L<perlipc/"Sockets: Client/Server Communication">.
949
950 =item continue BLOCK
951 X<continue>
952
953 =item continue
954
955 C<continue> is actually a flow control statement rather than a function.  If
956 there is a C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
957 C<foreach>), it is always executed just before the conditional is about to
958 be evaluated again, just like the third part of a C<for> loop in C.  Thus
959 it can be used to increment a loop variable, even when the loop has been
960 continued via the C<next> statement (which is similar to the C C<continue>
961 statement).
962
963 C<last>, C<next>, or C<redo> may appear within a C<continue>
964 block; C<last> and C<redo> behave as if they had been executed within
965 the main block.  So will C<next>, but since it will execute a C<continue>
966 block, it may be more entertaining.
967
968     while (EXPR) {
969         ### redo always comes here
970         do_something;
971     } continue {
972         ### next always comes here
973         do_something_else;
974         # then back the top to re-check EXPR
975     }
976     ### last always comes here
977
978 Omitting the C<continue> section is equivalent to using an
979 empty one, logically enough, so C<next> goes directly back
980 to check the condition at the top of the loop.
981
982 If the C<"switch"> feature is enabled, C<continue> is also a
983 function that exits the current C<when> (or C<default>) block and
984 falls through to the next one.  See L<feature> and
985 L<perlsyn/"Switch statements"> for more information.
986
987
988 =item cos EXPR
989 X<cos> X<cosine> X<acos> X<arccosine>
990
991 =item cos
992
993 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
994 takes cosine of C<$_>.
995
996 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
997 function, or use this relation:
998
999     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
1000
1001 =item crypt PLAINTEXT,SALT
1002 X<crypt> X<digest> X<hash> X<salt> X<plaintext> X<password>
1003 X<decrypt> X<cryptography> X<passwd> X<encrypt>
1004
1005 Creates a digest string exactly like the crypt(3) function in the C
1006 library (assuming that you actually have a version there that has not
1007 been extirpated as a potential munition).
1008
1009 crypt() is a one-way hash function.  The PLAINTEXT and SALT is turned
1010 into a short string, called a digest, which is returned.  The same
1011 PLAINTEXT and SALT will always return the same string, but there is no
1012 (known) way to get the original PLAINTEXT from the hash.  Small
1013 changes in the PLAINTEXT or SALT will result in large changes in the
1014 digest.
1015
1016 There is no decrypt function.  This function isn't all that useful for
1017 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
1018 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
1019 primarily used to check if two pieces of text are the same without
1020 having to transmit or store the text itself.  An example is checking
1021 if a correct password is given.  The digest of the password is stored,
1022 not the password itself.  The user types in a password that is
1023 crypt()'d with the same salt as the stored digest.  If the two digests
1024 match the password is correct.
1025
1026 When verifying an existing digest string you should use the digest as
1027 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
1028 to create the digest is visible as part of the digest.  This ensures
1029 crypt() will hash the new string with the same salt as the digest.
1030 This allows your code to work with the standard L<crypt|/crypt> and
1031 with more exotic implementations.  In other words, do not assume
1032 anything about the returned string itself, or how many bytes in the
1033 digest matter.
1034
1035 Traditionally the result is a string of 13 bytes: two first bytes of
1036 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
1037 the first eight bytes of PLAINTEXT mattered. But alternative
1038 hashing schemes (like MD5), higher level security schemes (like C2),
1039 and implementations on non-Unix platforms may produce different
1040 strings.
1041
1042 When choosing a new salt create a random two character string whose
1043 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
1044 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
1045 characters is just a recommendation; the characters allowed in
1046 the salt depend solely on your system's crypt library, and Perl can't
1047 restrict what salts C<crypt()> accepts.
1048
1049 Here's an example that makes sure that whoever runs this program knows
1050 their password:
1051
1052     $pwd = (getpwuid($<))[1];
1053
1054     system "stty -echo";
1055     print "Password: ";
1056     chomp($word = <STDIN>);
1057     print "\n";
1058     system "stty echo";
1059
1060     if (crypt($word, $pwd) ne $pwd) {
1061         die "Sorry...\n";
1062     } else {
1063         print "ok\n";
1064     }
1065
1066 Of course, typing in your own password to whoever asks you
1067 for it is unwise.
1068
1069 The L<crypt|/crypt> function is unsuitable for hashing large quantities
1070 of data, not least of all because you can't get the information
1071 back.  Look at the L<Digest> module for more robust algorithms.
1072
1073 If using crypt() on a Unicode string (which I<potentially> has
1074 characters with codepoints above 255), Perl tries to make sense
1075 of the situation by trying to downgrade (a copy of the string)
1076 the string back to an eight-bit byte string before calling crypt()
1077 (on that copy).  If that works, good.  If not, crypt() dies with
1078 C<Wide character in crypt>.
1079
1080 =item dbmclose HASH
1081 X<dbmclose>
1082
1083 [This function has been largely superseded by the C<untie> function.]
1084
1085 Breaks the binding between a DBM file and a hash.
1086
1087 =item dbmopen HASH,DBNAME,MASK
1088 X<dbmopen> X<dbm> X<ndbm> X<sdbm> X<gdbm>
1089
1090 [This function has been largely superseded by the C<tie> function.]
1091
1092 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
1093 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
1094 argument is I<not> a filehandle, even though it looks like one).  DBNAME
1095 is the name of the database (without the F<.dir> or F<.pag> extension if
1096 any).  If the database does not exist, it is created with protection
1097 specified by MASK (as modified by the C<umask>).  If your system supports
1098 only the older DBM functions, you may make only one C<dbmopen> call in your
1099 program.  In older versions of Perl, if your system had neither DBM nor
1100 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
1101 sdbm(3).
1102
1103 If you don't have write access to the DBM file, you can only read hash
1104 variables, not set them.  If you want to test whether you can write,
1105 either use file tests or try setting a dummy hash entry inside an C<eval> 
1106 to trap the error.
1107
1108 Note that functions such as C<keys> and C<values> may return huge lists
1109 when used on large DBM files.  You may prefer to use the C<each>
1110 function to iterate over large DBM files.  Example:
1111
1112     # print out history file offsets
1113     dbmopen(%HIST,'/usr/lib/news/history',0666);
1114     while (($key,$val) = each %HIST) {
1115         print $key, ' = ', unpack('L',$val), "\n";
1116     }
1117     dbmclose(%HIST);
1118
1119 See also L<AnyDBM_File> for a more general description of the pros and
1120 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1121 rich implementation.
1122
1123 You can control which DBM library you use by loading that library
1124 before you call dbmopen():
1125
1126     use DB_File;
1127     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1128         or die "Can't open netscape history file: $!";
1129
1130 =item defined EXPR
1131 X<defined> X<undef> X<undefined>
1132
1133 =item defined
1134
1135 Returns a Boolean value telling whether EXPR has a value other than
1136 the undefined value C<undef>.  If EXPR is not present, C<$_> is
1137 checked.
1138
1139 Many operations return C<undef> to indicate failure, end of file,
1140 system error, uninitialized variable, and other exceptional
1141 conditions.  This function allows you to distinguish C<undef> from
1142 other values.  (A simple Boolean test will not distinguish among
1143 C<undef>, zero, the empty string, and C<"0">, which are all equally
1144 false.)  Note that since C<undef> is a valid scalar, its presence
1145 doesn't I<necessarily> indicate an exceptional condition: C<pop>
1146 returns C<undef> when its argument is an empty array, I<or> when the
1147 element to return happens to be C<undef>.
1148
1149 You may also use C<defined(&func)> to check whether subroutine C<&func>
1150 has ever been defined.  The return value is unaffected by any forward
1151 declarations of C<&func>.  A subroutine that is not defined
1152 may still be callable: its package may have an C<AUTOLOAD> method that
1153 makes it spring into existence the first time that it is called; see
1154 L<perlsub>.
1155
1156 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1157 used to report whether memory for that aggregate has ever been
1158 allocated.  This behavior may disappear in future versions of Perl.
1159 You should instead use a simple test for size:
1160
1161     if (@an_array) { print "has array elements\n" }
1162     if (%a_hash)   { print "has hash members\n"   }
1163
1164 When used on a hash element, it tells you whether the value is defined,
1165 not whether the key exists in the hash.  Use L</exists> for the latter
1166 purpose.
1167
1168 Examples:
1169
1170     print if defined $switch{'D'};
1171     print "$val\n" while defined($val = pop(@ary));
1172     die "Can't readlink $sym: $!"
1173         unless defined($value = readlink $sym);
1174     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1175     $debugging = 0 unless defined $debugging;
1176
1177 Note:  Many folks tend to overuse C<defined>, and then are surprised to
1178 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1179 defined values.  For example, if you say
1180
1181     "ab" =~ /a(.*)b/;
1182
1183 The pattern match succeeds and C<$1> is defined, although it
1184 matched "nothing".  It didn't really fail to match anything.  Rather, it
1185 matched something that happened to be zero characters long.  This is all
1186 very above-board and honest.  When a function returns an undefined value,
1187 it's an admission that it couldn't give you an honest answer.  So you
1188 should use C<defined> only when questioning the integrity of what
1189 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1190 what you want.
1191
1192 See also L</undef>, L</exists>, L</ref>.
1193
1194 =item delete EXPR
1195 X<delete>
1196
1197 Given an expression that specifies an element or slice of a hash, C<delete>
1198 deletes the specified elements from that hash so that exists() on that element
1199 no longer returns true.  Setting a hash element to the undefined value does
1200 not remove its key, but deleting it does; see L</exists>.
1201
1202 It returns the value or values deleted in list context, or the last such
1203 element in scalar context.  The return list's length always matches that of
1204 the argument list: deleting non-existent elements returns the undefined value
1205 in their corresponding positions.
1206
1207 delete() may also be used on arrays and array slices, but its behavior is less
1208 straightforward.  Although exists() will return false for deleted entries,
1209 deleting array elements never changes indices of existing values; use shift()
1210 or splice() for that.  However, if all deleted elements fall at the end of an
1211 array, the array's size shrinks to the position of the highest element that
1212 still tests true for exists(), or to 0 if none do.
1213
1214 B<Be aware> that calling delete on array values is deprecated and likely to
1215 be removed in a future version of Perl.
1216
1217 Deleting from C<%ENV> modifies the environment.  Deleting from a hash tied to
1218 a DBM file deletes the entry from the DBM file.  Deleting from a C<tied> hash
1219 or array may not necessarily return anything; it depends on the implementation
1220 of the C<tied> package's DELETE method, which may do whatever it pleases.
1221
1222 The C<delete local EXPR> construct localizes the deletion to the current
1223 block at run time.  Until the block exits, elements locally deleted
1224 temporarily no longer exist.  See L<perlsub/"Localized deletion of elements
1225 of composite types">.
1226
1227     %hash = (foo => 11, bar => 22, baz => 33);
1228     $scalar = delete $hash{foo};             # $scalar is 11
1229     $scalar = delete @hash{qw(foo bar)};     # $scalar is 22
1230     @array  = delete @hash{qw(foo bar baz)}; # @array  is (undef,undef,33)
1231
1232 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1233
1234     foreach $key (keys %HASH) {
1235         delete $HASH{$key};
1236     }
1237
1238     foreach $index (0 .. $#ARRAY) {
1239         delete $ARRAY[$index];
1240     }
1241
1242 And so do these:
1243
1244     delete @HASH{keys %HASH};
1245
1246     delete @ARRAY[0 .. $#ARRAY];
1247
1248 But both are slower than assigning the empty list
1249 or undefining %HASH or @ARRAY, which is the customary 
1250 way to empty out an aggregate:
1251
1252     %HASH = ();     # completely empty %HASH
1253     undef %HASH;    # forget %HASH ever existed
1254
1255     @ARRAY = ();    # completely empty @ARRAY
1256     undef @ARRAY;   # forget @ARRAY ever existed
1257
1258 The EXPR can be arbitrarily complicated provided its
1259 final operation is an element or slice of an aggregate:
1260
1261     delete $ref->[$x][$y]{$key};
1262     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1263
1264     delete $ref->[$x][$y][$index];
1265     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1266
1267 =item die LIST
1268 X<die> X<throw> X<exception> X<raise> X<$@> X<abort>
1269
1270 C<die> raises an exception. Inside an C<eval> the error message is stuffed
1271 into C<$@> and the C<eval> is terminated with the undefined value.
1272 If the exception is outside of all enclosing C<eval>s, then the uncaught
1273 exception prints LIST to C<STDERR> and exits with a non-zero value. If you
1274 need to exit the process with a specific exit code, see L<exit>.
1275
1276 Equivalent examples:
1277
1278     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1279     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1280
1281 If the last element of LIST does not end in a newline, the current
1282 script line number and input line number (if any) are also printed,
1283 and a newline is supplied.  Note that the "input line number" (also
1284 known as "chunk") is subject to whatever notion of "line" happens to
1285 be currently in effect, and is also available as the special variable
1286 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1287
1288 Hint: sometimes appending C<", stopped"> to your message will cause it
1289 to make better sense when the string C<"at foo line 123"> is appended.
1290 Suppose you are running script "canasta".
1291
1292     die "/etc/games is no good";
1293     die "/etc/games is no good, stopped";
1294
1295 produce, respectively
1296
1297     /etc/games is no good at canasta line 123.
1298     /etc/games is no good, stopped at canasta line 123.
1299
1300 If the output is empty and C<$@> already contains a value (typically from a
1301 previous eval) that value is reused after appending C<"\t...propagated">.
1302 This is useful for propagating exceptions:
1303
1304     eval { ... };
1305     die unless $@ =~ /Expected exception/;
1306
1307 If the output is empty and C<$@> contains an object reference that has a
1308 C<PROPAGATE> method, that method will be called with additional file
1309 and line number parameters.  The return value replaces the value in
1310 C<$@>.  i.e., as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1311 were called.
1312
1313 If C<$@> is empty then the string C<"Died"> is used.
1314
1315 If an uncaught exception results in interpreter exit, the exit code is
1316 determined from the values of C<$!> and C<$?> with this pseudocode:
1317
1318     exit $! if $!;              # errno
1319     exit $? >> 8 if $? >> 8;    # child exit status
1320     exit 255;                   # last resort
1321
1322 The intent is to squeeze as much possible information about the likely cause
1323 into the limited space of the system exit code. However, as C<$!> is the value
1324 of C's C<errno>, which can be set by any system call, this means that the value
1325 of the exit code used by C<die> can be non-predictable, so should not be relied
1326 upon, other than to be non-zero.
1327
1328 You can also call C<die> with a reference argument, and if this is trapped
1329 within an C<eval>, C<$@> contains that reference.  This permits more
1330 elaborate exception handling using objects that maintain arbitrary state
1331 about the exception.  Such a scheme is sometimes preferable to matching
1332 particular string values of C<$@> with regular expressions.  Because C<$@> 
1333 is a global variable and C<eval> may be used within object implementations,
1334 be careful that analyzing the error object doesn't replace the reference in
1335 the global variable.  It's easiest to make a local copy of the reference
1336 before any manipulations.  Here's an example:
1337
1338     use Scalar::Util "blessed";
1339
1340     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1341     if (my $ev_err = $@) {
1342         if (blessed($ev_err) && $ev_err->isa("Some::Module::Exception")) {
1343             # handle Some::Module::Exception
1344         }
1345         else {
1346             # handle all other possible exceptions
1347         }
1348     }
1349
1350 Because Perl stringifies uncaught exception messages before display,
1351 you'll probably want to overload stringification operations on
1352 exception objects.  See L<overload> for details about that.
1353
1354 You can arrange for a callback to be run just before the C<die>
1355 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1356 handler is called with the error text and can change the error
1357 message, if it sees fit, by calling C<die> again.  See
1358 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1359 L<"eval BLOCK"> for some examples.  Although this feature was 
1360 to be run only right before your program was to exit, this is not
1361 currently so: the C<$SIG{__DIE__}> hook is currently called
1362 even inside eval()ed blocks/strings!  If one wants the hook to do
1363 nothing in such situations, put
1364
1365     die @_ if $^S;
1366
1367 as the first line of the handler (see L<perlvar/$^S>).  Because
1368 this promotes strange action at a distance, this counterintuitive
1369 behavior may be fixed in a future release.
1370
1371 See also exit(), warn(), and the Carp module.
1372
1373 =item do BLOCK
1374 X<do> X<block>
1375
1376 Not really a function.  Returns the value of the last command in the
1377 sequence of commands indicated by BLOCK.  When modified by the C<while> or
1378 C<until> loop modifier, executes the BLOCK once before testing the loop
1379 condition. (On other statements the loop modifiers test the conditional
1380 first.)
1381
1382 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1383 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1384 See L<perlsyn> for alternative strategies.
1385
1386 =item do SUBROUTINE(LIST)
1387 X<do>
1388
1389 This form of subroutine call is deprecated.  See L<perlsub>.
1390
1391 =item do EXPR
1392 X<do>
1393
1394 Uses the value of EXPR as a filename and executes the contents of the
1395 file as a Perl script.
1396
1397     do 'stat.pl';
1398
1399 is just like
1400
1401     eval `cat stat.pl`;
1402
1403 except that it's more efficient and concise, keeps track of the current
1404 filename for error messages, searches the @INC directories, and updates
1405 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1406 variables.  It also differs in that code evaluated with C<do FILENAME>
1407 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1408 same, however, in that it does reparse the file every time you call it,
1409 so you probably don't want to do this inside a loop.
1410
1411 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1412 error.  If C<do> can read the file but cannot compile it, it
1413 returns undef and sets an error message in C<$@>.   If the file is
1414 successfully compiled, C<do> returns the value of the last expression
1415 evaluated.
1416
1417 Inclusion of library modules is better done with the
1418 C<use> and C<require> operators, which also do automatic error checking
1419 and raise an exception if there's a problem.
1420
1421 You might like to use C<do> to read in a program configuration
1422 file.  Manual error checking can be done this way:
1423
1424     # read in config files: system first, then user
1425     for $file ("/share/prog/defaults.rc",
1426                "$ENV{HOME}/.someprogrc")
1427     {
1428         unless ($return = do $file) {
1429             warn "couldn't parse $file: $@" if $@;
1430             warn "couldn't do $file: $!"    unless defined $return;
1431             warn "couldn't run $file"       unless $return;
1432         }
1433     }
1434
1435 =item dump LABEL
1436 X<dump> X<core> X<undump>
1437
1438 =item dump
1439
1440 This function causes an immediate core dump.  See also the B<-u>
1441 command-line switch in L<perlrun>, which does the same thing.
1442 Primarily this is so that you can use the B<undump> program (not
1443 supplied) to turn your core dump into an executable binary after
1444 having initialized all your variables at the beginning of the
1445 program.  When the new binary is executed it will begin by executing
1446 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1447 Think of it as a goto with an intervening core dump and reincarnation.
1448 If C<LABEL> is omitted, restarts the program from the top.
1449
1450 B<WARNING>: Any files opened at the time of the dump will I<not>
1451 be open any more when the program is reincarnated, with possible
1452 resulting confusion by Perl.
1453
1454 This function is now largely obsolete, mostly because it's very hard to
1455 convert a core file into an executable. That's why you should now invoke
1456 it as C<CORE::dump()>, if you don't want to be warned against a possible
1457 typo.
1458
1459 =item each HASH (or HASHREF)
1460 X<each> X<hash, iterator>
1461
1462 =item each ARRAY (or ARRAYREF)
1463 X<array, iterator>
1464
1465 When called in list context, returns a 2-element list consisting of the key
1466 and value for the next element of a hash, or the index and value for the
1467 next element of an array, so that you can iterate over it.  When called in
1468 scalar context, returns only the key (not the value) in a hash, or the index
1469 in an array.
1470
1471 Hash entries are returned in an apparently random order.  The actual random
1472 order is subject to change in future versions of Perl, but it is
1473 guaranteed to be in the same order as either the C<keys> or C<values>
1474 function would produce on the same (unmodified) hash.  Since Perl
1475 5.8.2 the ordering can be different even between different runs of Perl
1476 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1477
1478 After C<each> has returned all entries from the hash or array, the next
1479 call to C<each> returns the empty list in list context and C<undef> in
1480 scalar context.  The next call following that one restarts iteration.  Each
1481 hash or array has its own internal iterator, accessed by C<each>, C<keys>,
1482 and C<values>.  The iterator is implicitly reset when C<each> has reached
1483 the end as just described; it can be explicitly reset by calling C<keys> or
1484 C<values> on the hash or array.  If you add or delete a hash's elements
1485 while iterating over it, entries may be skipped or duplicated--so don't do
1486 that.  Exception: It is always safe to delete the item most recently
1487 returned by C<each()>, so the following code works properly:
1488
1489         while (($key, $value) = each %hash) {
1490           print $key, "\n";
1491           delete $hash{$key};   # This is safe
1492         }
1493
1494 This prints out your environment like the printenv(1) program,
1495 but in a different order:
1496
1497     while (($key,$value) = each %ENV) {
1498         print "$key=$value\n";
1499     }
1500
1501 When given a reference to a hash or array, the argument will be
1502 dereferenced automatically.
1503
1504     while (($key,$value) = each $hashref) { ... }
1505
1506 If the reference is a blessed object that overrides either C<%{}> or
1507 C<@{}>, the override will be used instead of dereferencing the underlying
1508 variable type.  If both overrides are provided, C<%{}> will be the default.
1509 If this is not desired, you must dereference the argument yourself.
1510
1511 See also C<keys>, C<values> and C<sort>.
1512
1513 =item eof FILEHANDLE
1514 X<eof>
1515 X<end of file>
1516 X<end-of-file>
1517
1518 =item eof ()
1519
1520 =item eof
1521
1522 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1523 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1524 gives the real filehandle.  (Note that this function actually
1525 reads a character and then C<ungetc>s it, so isn't useful in an
1526 interactive context.)  Do not read from a terminal file (or call
1527 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1528 as terminals may lose the end-of-file condition if you do.
1529
1530 An C<eof> without an argument uses the last file read.  Using C<eof()>
1531 with empty parentheses is different.  It refers to the pseudo file
1532 formed from the files listed on the command line and accessed via the
1533 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1534 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1535 used will cause C<@ARGV> to be examined to determine if input is
1536 available.   Similarly, an C<eof()> after C<< <> >> has returned
1537 end-of-file will assume you are processing another C<@ARGV> list,
1538 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1539 see L<perlop/"I/O Operators">.
1540
1541 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1542 detect the end of each file, C<eof()> will detect the end of only the
1543 last file.  Examples:
1544
1545     # reset line numbering on each input file
1546     while (<>) {
1547         next if /^\s*#/;  # skip comments
1548         print "$.\t$_";
1549     } continue {
1550         close ARGV if eof;  # Not eof()!
1551     }
1552
1553     # insert dashes just before last line of last file
1554     while (<>) {
1555         if (eof()) {  # check for end of last file
1556             print "--------------\n";
1557         }
1558         print;
1559         last if eof();          # needed if we're reading from a terminal
1560     }
1561
1562 Practical hint: you almost never need to use C<eof> in Perl, because the
1563 input operators typically return C<undef> when they run out of data, or if
1564 there was an error.
1565
1566 =item eval EXPR
1567 X<eval> X<try> X<catch> X<evaluate> X<parse> X<execute>
1568 X<error, handling> X<exception, handling>
1569
1570 =item eval BLOCK
1571
1572 =item eval
1573
1574 In the first form, the return value of EXPR is parsed and executed as if it
1575 were a little Perl program.  The value of the expression (which is itself
1576 determined within scalar context) is first parsed, and if there weren't any
1577 errors, executed in the lexical context of the current Perl program, so
1578 that any variable settings or subroutine and format definitions remain
1579 afterwards.  Note that the value is parsed every time the C<eval> executes.
1580 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1581 delay parsing and subsequent execution of the text of EXPR until run time.
1582
1583 In the second form, the code within the BLOCK is parsed only once--at the
1584 same time the code surrounding the C<eval> itself was parsed--and executed
1585 within the context of the current Perl program.  This form is typically
1586 used to trap exceptions more efficiently than the first (see below), while
1587 also providing the benefit of checking the code within BLOCK at compile
1588 time.
1589
1590 The final semicolon, if any, may be omitted from the value of EXPR or within
1591 the BLOCK.
1592
1593 In both forms, the value returned is the value of the last expression
1594 evaluated inside the mini-program; a return statement may be also used, just
1595 as with subroutines.  The expression providing the return value is evaluated
1596 in void, scalar, or list context, depending on the context of the C<eval> 
1597 itself.  See L</wantarray> for more on how the evaluation context can be 
1598 determined.
1599
1600 If there is a syntax error or runtime error, or a C<die> statement is
1601 executed, C<eval> returns an undefined value in scalar context
1602 or an empty list in list context, and C<$@> is set to the
1603 error message.  If there was no error, C<$@> is guaranteed to be the empty
1604 string.  Beware that using C<eval> neither silences Perl from printing
1605 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1606 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1607 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1608 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1609
1610 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1611 determining whether a particular feature (such as C<socket> or C<symlink>)
1612 is implemented.  It is also Perl's exception-trapping mechanism, where
1613 the die operator is used to raise exceptions.
1614
1615 If you want to trap errors when loading an XS module, some problems with
1616 the binary interface (such as Perl version skew) may be fatal even with
1617 C<eval> unless C<$ENV{PERL_DL_NONLAZY}> is set. See L<perlrun>.
1618
1619 If the code to be executed doesn't vary, you may use the eval-BLOCK
1620 form to trap run-time errors without incurring the penalty of
1621 recompiling each time.  The error, if any, is still returned in C<$@>.
1622 Examples:
1623
1624     # make divide-by-zero nonfatal
1625     eval { $answer = $a / $b; }; warn $@ if $@;
1626
1627     # same thing, but less efficient
1628     eval '$answer = $a / $b'; warn $@ if $@;
1629
1630     # a compile-time error
1631     eval { $answer = }; # WRONG
1632
1633     # a run-time error
1634     eval '$answer =';   # sets $@
1635
1636 Using the C<eval{}> form as an exception trap in libraries does have some
1637 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
1638 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
1639 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1640 as this example shows:
1641
1642     # a private exception trap for divide-by-zero
1643     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1644     warn $@ if $@;
1645
1646 This is especially significant, given that C<__DIE__> hooks can call
1647 C<die> again, which has the effect of changing their error messages:
1648
1649     # __DIE__ hooks may modify error messages
1650     {
1651        local $SIG{'__DIE__'} =
1652               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1653        eval { die "foo lives here" };
1654        print $@ if $@;                # prints "bar lives here"
1655     }
1656
1657 Because this promotes action at a distance, this counterintuitive behavior
1658 may be fixed in a future release.
1659
1660 With an C<eval>, you should be especially careful to remember what's
1661 being looked at when:
1662
1663     eval $x;        # CASE 1
1664     eval "$x";      # CASE 2
1665
1666     eval '$x';      # CASE 3
1667     eval { $x };    # CASE 4
1668
1669     eval "\$$x++";  # CASE 5
1670     $$x++;          # CASE 6
1671
1672 Cases 1 and 2 above behave identically: they run the code contained in
1673 the variable $x.  (Although case 2 has misleading double quotes making
1674 the reader wonder what else might be happening (nothing is).)  Cases 3
1675 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1676 does nothing but return the value of $x.  (Case 4 is preferred for
1677 purely visual reasons, but it also has the advantage of compiling at
1678 compile-time instead of at run-time.)  Case 5 is a place where
1679 normally you I<would> like to use double quotes, except that in this
1680 particular situation, you can just use symbolic references instead, as
1681 in case 6.
1682
1683 Before Perl 5.14, the assignment to C<$@> occured before restoration of localised variables, which means that, if your code is to run on older
1684 versions, a temporary is required if you want to mask some but not all
1685 errors:
1686
1687     # alter $@ on nefarious repugnancy only
1688     {
1689        my $e;
1690        {
1691           local $@; # protect existing $@
1692           eval { test_repugnancy() };
1693           # $@ =~ /nefarious/ and die $@; # Perl 5.14 and higher only
1694           $@ =~ /nefarious/ and $e = $@;
1695        }
1696        die $e if defined $e
1697     }
1698
1699 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1700 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1701
1702 An C<eval ''> executed within the C<DB> package doesn't see the usual
1703 surrounding lexical scope, but rather the scope of the first non-DB piece
1704 of code that called it. You don't normally need to worry about this unless
1705 you are writing a Perl debugger.
1706
1707 =item exec LIST
1708 X<exec> X<execute>
1709
1710 =item exec PROGRAM LIST
1711
1712 The C<exec> function executes a system command I<and never returns>;
1713 use C<system> instead of C<exec> if you want it to return.  It fails and
1714 returns false only if the command does not exist I<and> it is executed
1715 directly instead of via your system's command shell (see below).
1716
1717 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1718 warns you if there is a following statement that isn't C<die>, C<warn>,
1719 or C<exit> (if C<-w> is set--but you always do that, right?).   If you
1720 I<really> want to follow an C<exec> with some other statement, you
1721 can use one of these styles to avoid the warning:
1722
1723     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1724     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1725
1726 If there is more than one argument in LIST, or if LIST is an array
1727 with more than one value, calls execvp(3) with the arguments in LIST.
1728 If there is only one scalar argument or an array with one element in it,
1729 the argument is checked for shell metacharacters, and if there are any,
1730 the entire argument is passed to the system's command shell for parsing
1731 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1732 If there are no shell metacharacters in the argument, it is split into
1733 words and passed directly to C<execvp>, which is more efficient.
1734 Examples:
1735
1736     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1737     exec "sort $outfile | uniq";
1738
1739 If you don't really want to execute the first argument, but want to lie
1740 to the program you are executing about its own name, you can specify
1741 the program you actually want to run as an "indirect object" (without a
1742 comma) in front of the LIST.  (This always forces interpretation of the
1743 LIST as a multivalued list, even if there is only a single scalar in
1744 the list.)  Example:
1745
1746     $shell = '/bin/csh';
1747     exec $shell '-sh';    # pretend it's a login shell
1748
1749 or, more directly,
1750
1751     exec {'/bin/csh'} '-sh';  # pretend it's a login shell
1752
1753 When the arguments get executed via the system shell, results are
1754 subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1755 for details.
1756
1757 Using an indirect object with C<exec> or C<system> is also more
1758 secure.  This usage (which also works fine with system()) forces
1759 interpretation of the arguments as a multivalued list, even if the
1760 list had just one argument.  That way you're safe from the shell
1761 expanding wildcards or splitting up words with whitespace in them.
1762
1763     @args = ( "echo surprise" );
1764
1765     exec @args;               # subject to shell escapes
1766                                 # if @args == 1
1767     exec { $args[0] } @args;  # safe even with one-arg list
1768
1769 The first version, the one without the indirect object, ran the I<echo>
1770 program, passing it C<"surprise"> an argument.  The second version didn't;
1771 it tried to run a program named I<"echo surprise">, didn't find it, and set
1772 C<$?> to a non-zero value indicating failure.
1773
1774 Beginning with v5.6.0, Perl attempts to flush all files opened for
1775 output before the exec, but this may not be supported on some platforms
1776 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1777 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1778 open handles to avoid lost output.
1779
1780 Note that C<exec> will not call your C<END> blocks, nor will it invoke
1781 C<DESTROY> methods on your objects.
1782
1783 =item exists EXPR
1784 X<exists> X<autovivification>
1785
1786 Given an expression that specifies an element of a hash, returns true if the
1787 specified element in the hash has ever been initialized, even if the
1788 corresponding value is undefined.
1789
1790     print "Exists\n"    if exists $hash{$key};
1791     print "Defined\n"   if defined $hash{$key};
1792     print "True\n"      if $hash{$key};
1793
1794 exists may also be called on array elements, but its behavior is much less
1795 obvious, and is strongly tied to the use of L</delete> on arrays.  B<Be aware>
1796 that calling exists on array values is deprecated and likely to be removed in
1797 a future version of Perl.
1798
1799     print "Exists\n"    if exists $array[$index];
1800     print "Defined\n"   if defined $array[$index];
1801     print "True\n"      if $array[$index];
1802
1803 A hash or array element can be true only if it's defined, and defined if
1804 it exists, but the reverse doesn't necessarily hold true.
1805
1806 Given an expression that specifies the name of a subroutine,
1807 returns true if the specified subroutine has ever been declared, even
1808 if it is undefined.  Mentioning a subroutine name for exists or defined
1809 does not count as declaring it.  Note that a subroutine that does not
1810 exist may still be callable: its package may have an C<AUTOLOAD>
1811 method that makes it spring into existence the first time that it is
1812 called; see L<perlsub>.
1813
1814     print "Exists\n"  if exists &subroutine;
1815     print "Defined\n" if defined &subroutine;
1816
1817 Note that the EXPR can be arbitrarily complicated as long as the final
1818 operation is a hash or array key lookup or subroutine name:
1819
1820     if (exists $ref->{A}->{B}->{$key})  { }
1821     if (exists $hash{A}{B}{$key})       { }
1822
1823     if (exists $ref->{A}->{B}->[$ix])   { }
1824     if (exists $hash{A}{B}[$ix])        { }
1825
1826     if (exists &{$ref->{A}{B}{$key}})   { }
1827
1828 Although the mostly deeply nested array or hash will not spring into
1829 existence just because its existence was tested, any intervening ones will.
1830 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1831 into existence due to the existence test for the $key element above.
1832 This happens anywhere the arrow operator is used, including even here:
1833
1834     undef $ref;
1835     if (exists $ref->{"Some key"})    { }
1836     print $ref;  # prints HASH(0x80d3d5c)
1837
1838 This surprising autovivification in what does not at first--or even
1839 second--glance appear to be an lvalue context may be fixed in a future
1840 release.
1841
1842 Use of a subroutine call, rather than a subroutine name, as an argument
1843 to exists() is an error.
1844
1845     exists &sub;    # OK
1846     exists &sub();  # Error
1847
1848 =item exit EXPR
1849 X<exit> X<terminate> X<abort>
1850
1851 =item exit
1852
1853 Evaluates EXPR and exits immediately with that value.    Example:
1854
1855     $ans = <STDIN>;
1856     exit 0 if $ans =~ /^[Xx]/;
1857
1858 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1859 universally recognized values for EXPR are C<0> for success and C<1>
1860 for error; other values are subject to interpretation depending on the
1861 environment in which the Perl program is running.  For example, exiting
1862 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1863 the mailer to return the item undelivered, but that's not true everywhere.
1864
1865 Don't use C<exit> to abort a subroutine if there's any chance that
1866 someone might want to trap whatever error happened.  Use C<die> instead,
1867 which can be trapped by an C<eval>.
1868
1869 The exit() function does not always exit immediately.  It calls any
1870 defined C<END> routines first, but these C<END> routines may not
1871 themselves abort the exit.  Likewise any object destructors that need to
1872 be called are called before the real exit.  C<END> routines and destructors
1873 can change the exit status by modifying C<$?>. If this is a problem, you
1874 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1875 See L<perlmod> for details.
1876
1877 =item exp EXPR
1878 X<exp> X<exponential> X<antilog> X<antilogarithm> X<e>
1879
1880 =item exp
1881
1882 Returns I<e> (the natural logarithm base) to the power of EXPR.
1883 If EXPR is omitted, gives C<exp($_)>.
1884
1885 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1886 X<fcntl>
1887
1888 Implements the fcntl(2) function.  You'll probably have to say
1889
1890     use Fcntl;
1891
1892 first to get the correct constant definitions.  Argument processing and
1893 value returned work just like C<ioctl> below.
1894 For example:
1895
1896     use Fcntl;
1897     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1898         or die "can't fcntl F_GETFL: $!";
1899
1900 You don't have to check for C<defined> on the return from C<fcntl>.
1901 Like C<ioctl>, it maps a C<0> return from the system call into
1902 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1903 in numeric context.  It is also exempt from the normal B<-w> warnings
1904 on improper numeric conversions.
1905
1906 Note that C<fcntl> raises an exception if used on a machine that
1907 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1908 manpage to learn what functions are available on your system.
1909
1910 Here's an example of setting a filehandle named C<REMOTE> to be
1911 non-blocking at the system level.  You'll have to negotiate C<$|>
1912 on your own, though.
1913
1914     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
1915
1916     $flags = fcntl(REMOTE, F_GETFL, 0)
1917                 or die "Can't get flags for the socket: $!\n";
1918
1919     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
1920                 or die "Can't set flags for the socket: $!\n";
1921
1922 =item fileno FILEHANDLE
1923 X<fileno>
1924
1925 Returns the file descriptor for a filehandle, or undefined if the
1926 filehandle is not open.  This is mainly useful for constructing
1927 bitmaps for C<select> and low-level POSIX tty-handling operations.
1928 If FILEHANDLE is an expression, the value is taken as an indirect
1929 filehandle, generally its name.
1930
1931 You can use this to find out whether two handles refer to the
1932 same underlying descriptor:
1933
1934     if (fileno(THIS) == fileno(THAT)) {
1935         print "THIS and THAT are dups\n";
1936     }
1937
1938 (Filehandles connected to memory objects via new features of C<open> may
1939 return undefined even though they are open.)
1940
1941
1942 =item flock FILEHANDLE,OPERATION
1943 X<flock> X<lock> X<locking>
1944
1945 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1946 for success, false on failure.  Produces a fatal error if used on a
1947 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1948 C<flock> is Perl's portable file locking interface, although it locks
1949 entire files only, not records.
1950
1951 Two potentially non-obvious but traditional C<flock> semantics are
1952 that it waits indefinitely until the lock is granted, and that its locks
1953 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1954 fewer guarantees.  This means that programs that do not also use C<flock>
1955 may modify files locked with C<flock>.  See L<perlport>, 
1956 your port's specific documentation, or your system-specific local manpages
1957 for details.  It's best to assume traditional behavior if you're writing
1958 portable programs.  (But if you're not, you should as always feel perfectly
1959 free to write for your own system's idiosyncrasies (sometimes called
1960 "features").  Slavish adherence to portability concerns shouldn't get
1961 in the way of your getting your job done.)
1962
1963 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1964 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1965 you can use the symbolic names if you import them from the Fcntl module,
1966 either individually, or as a group using the ':flock' tag.  LOCK_SH
1967 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1968 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1969 LOCK_SH or LOCK_EX then C<flock> returns immediately rather than blocking
1970 waiting for the lock; check the return status to see if you got it.
1971
1972 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1973 before locking or unlocking it.
1974
1975 Note that the emulation built with lockf(3) doesn't provide shared
1976 locks, and it requires that FILEHANDLE be open with write intent.  These
1977 are the semantics that lockf(3) implements.  Most if not all systems
1978 implement lockf(3) in terms of fcntl(2) locking, though, so the
1979 differing semantics shouldn't bite too many people.
1980
1981 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
1982 be open with read intent to use LOCK_SH and requires that it be open
1983 with write intent to use LOCK_EX.
1984
1985 Note also that some versions of C<flock> cannot lock things over the
1986 network; you would need to use the more system-specific C<fcntl> for
1987 that.  If you like you can force Perl to ignore your system's flock(2)
1988 function, and so provide its own fcntl(2)-based emulation, by passing
1989 the switch C<-Ud_flock> to the F<Configure> program when you configure
1990 Perl.
1991
1992 Here's a mailbox appender for BSD systems.
1993
1994     use Fcntl qw(:flock SEEK_END); # import LOCK_* and SEEK_END constants
1995
1996     sub lock {
1997         my ($fh) = @_;
1998         flock($fh, LOCK_EX) or die "Cannot lock mailbox - $!\n";
1999
2000         # and, in case someone appended while we were waiting...
2001         seek($fh, 0, SEEK_END) or die "Cannot seek - $!\n";
2002     }
2003
2004     sub unlock {
2005         my ($fh) = @_;
2006         flock($fh, LOCK_UN) or die "Cannot unlock mailbox - $!\n";
2007     }
2008
2009     open(my $mbox, ">>", "/usr/spool/mail/$ENV{'USER'}")
2010         or die "Can't open mailbox: $!";
2011
2012     lock($mbox);
2013     print $mbox $msg,"\n\n";
2014     unlock($mbox);
2015
2016 On systems that support a real flock(2), locks are inherited across fork()
2017 calls, whereas those that must resort to the more capricious fcntl(2)
2018 function lose their locks, making it seriously harder to write servers.
2019
2020 See also L<DB_File> for other flock() examples.
2021
2022 =item fork
2023 X<fork> X<child> X<parent>
2024
2025 Does a fork(2) system call to create a new process running the
2026 same program at the same point.  It returns the child pid to the
2027 parent process, C<0> to the child process, or C<undef> if the fork is
2028 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
2029 are shared, while everything else is copied.  On most systems supporting
2030 fork(), great care has gone into making it extremely efficient (for
2031 example, using copy-on-write technology on data pages), making it the
2032 dominant paradigm for multitasking over the last few decades.
2033
2034 Beginning with v5.6.0, Perl attempts to flush all files opened for
2035 output before forking the child process, but this may not be supported
2036 on some platforms (see L<perlport>).  To be safe, you may need to set
2037 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
2038 C<IO::Handle> on any open handles to avoid duplicate output.
2039
2040 If you C<fork> without ever waiting on your children, you will
2041 accumulate zombies.  On some systems, you can avoid this by setting
2042 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
2043 forking and reaping moribund children.
2044
2045 Note that if your forked child inherits system file descriptors like
2046 STDIN and STDOUT that are actually connected by a pipe or socket, even
2047 if you exit, then the remote server (such as, say, a CGI script or a
2048 backgrounded job launched from a remote shell) won't think you're done.
2049 You should reopen those to F</dev/null> if it's any issue.
2050
2051 =item format
2052 X<format>
2053
2054 Declare a picture format for use by the C<write> function.  For
2055 example:
2056
2057     format Something =
2058         Test: @<<<<<<<< @||||| @>>>>>
2059               $str,     $%,    '$' . int($num)
2060     .
2061
2062     $str = "widget";
2063     $num = $cost/$quantity;
2064     $~ = 'Something';
2065     write;
2066
2067 See L<perlform> for many details and examples.
2068
2069 =item formline PICTURE,LIST
2070 X<formline>
2071
2072 This is an internal function used by C<format>s, though you may call it,
2073 too.  It formats (see L<perlform>) a list of values according to the
2074 contents of PICTURE, placing the output into the format output
2075 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
2076 Eventually, when a C<write> is done, the contents of
2077 C<$^A> are written to some filehandle.  You could also read C<$^A>
2078 and then set C<$^A> back to C<"">.  Note that a format typically
2079 does one C<formline> per line of form, but the C<formline> function itself
2080 doesn't care how many newlines are embedded in the PICTURE.  This means
2081 that the C<~> and C<~~> tokens treat the entire PICTURE as a single line.
2082 You may therefore need to use multiple formlines to implement a single
2083 record format, just like the C<format> compiler.
2084
2085 Be careful if you put double quotes around the picture, because an C<@>
2086 character may be taken to mean the beginning of an array name.
2087 C<formline> always returns true.  See L<perlform> for other examples.
2088
2089 =item getc FILEHANDLE
2090 X<getc> X<getchar> X<character> X<file, read>
2091
2092 =item getc
2093
2094 Returns the next character from the input file attached to FILEHANDLE,
2095 or the undefined value at end of file or if there was an error (in
2096 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
2097 STDIN.  This is not particularly efficient.  However, it cannot be
2098 used by itself to fetch single characters without waiting for the user
2099 to hit enter.  For that, try something more like:
2100
2101     if ($BSD_STYLE) {
2102         system "stty cbreak </dev/tty >/dev/tty 2>&1";
2103     }
2104     else {
2105         system "stty", '-icanon', 'eol', "\001";
2106     }
2107
2108     $key = getc(STDIN);
2109
2110     if ($BSD_STYLE) {
2111         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
2112     }
2113     else {
2114         system 'stty', 'icanon', 'eol', '^@'; # ASCII NUL
2115     }
2116     print "\n";
2117
2118 Determination of whether $BSD_STYLE should be set
2119 is left as an exercise to the reader.
2120
2121 The C<POSIX::getattr> function can do this more portably on
2122 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
2123 module from your nearest CPAN site; details on CPAN can be found on
2124 L<perlmodlib/CPAN>.
2125
2126 =item getlogin
2127 X<getlogin> X<login>
2128
2129 This implements the C library function of the same name, which on most
2130 systems returns the current login from F</etc/utmp>, if any.  If it
2131 returns the empty string, use C<getpwuid>.
2132
2133     $login = getlogin || getpwuid($<) || "Kilroy";
2134
2135 Do not consider C<getlogin> for authentication: it is not as
2136 secure as C<getpwuid>.
2137
2138 =item getpeername SOCKET
2139 X<getpeername> X<peer>
2140
2141 Returns the packed sockaddr address of other end of the SOCKET connection.
2142
2143     use Socket;
2144     $hersockaddr    = getpeername(SOCK);
2145     ($port, $iaddr) = sockaddr_in($hersockaddr);
2146     $herhostname    = gethostbyaddr($iaddr, AF_INET);
2147     $herstraddr     = inet_ntoa($iaddr);
2148
2149 =item getpgrp PID
2150 X<getpgrp> X<group>
2151
2152 Returns the current process group for the specified PID.  Use
2153 a PID of C<0> to get the current process group for the
2154 current process.  Will raise an exception if used on a machine that
2155 doesn't implement getpgrp(2).  If PID is omitted, returns process
2156 group of current process.  Note that the POSIX version of C<getpgrp>
2157 does not accept a PID argument, so only C<PID==0> is truly portable.
2158
2159 =item getppid
2160 X<getppid> X<parent> X<pid>
2161
2162 Returns the process id of the parent process.
2163
2164 Note for Linux users: on Linux, the C functions C<getpid()> and
2165 C<getppid()> return different values from different threads. In order to
2166 be portable, this behavior is not reflected by the Perl-level function
2167 C<getppid()>, that returns a consistent value across threads. If you want
2168 to call the underlying C<getppid()>, you may use the CPAN module
2169 C<Linux::Pid>.
2170
2171 =item getpriority WHICH,WHO
2172 X<getpriority> X<priority> X<nice>
2173
2174 Returns the current priority for a process, a process group, or a user.
2175 (See C<getpriority(2)>.)  Will raise a fatal exception if used on a
2176 machine that doesn't implement getpriority(2).
2177
2178 =item getpwnam NAME
2179 X<getpwnam> X<getgrnam> X<gethostbyname> X<getnetbyname> X<getprotobyname>
2180 X<getpwuid> X<getgrgid> X<getservbyname> X<gethostbyaddr> X<getnetbyaddr>
2181 X<getprotobynumber> X<getservbyport> X<getpwent> X<getgrent> X<gethostent>
2182 X<getnetent> X<getprotoent> X<getservent> X<setpwent> X<setgrent> X<sethostent>
2183 X<setnetent> X<setprotoent> X<setservent> X<endpwent> X<endgrent> X<endhostent>
2184 X<endnetent> X<endprotoent> X<endservent> 
2185
2186 =item getgrnam NAME
2187
2188 =item gethostbyname NAME
2189
2190 =item getnetbyname NAME
2191
2192 =item getprotobyname NAME
2193
2194 =item getpwuid UID
2195
2196 =item getgrgid GID
2197
2198 =item getservbyname NAME,PROTO
2199
2200 =item gethostbyaddr ADDR,ADDRTYPE
2201
2202 =item getnetbyaddr ADDR,ADDRTYPE
2203
2204 =item getprotobynumber NUMBER
2205
2206 =item getservbyport PORT,PROTO
2207
2208 =item getpwent
2209
2210 =item getgrent
2211
2212 =item gethostent
2213
2214 =item getnetent
2215
2216 =item getprotoent
2217
2218 =item getservent
2219
2220 =item setpwent
2221
2222 =item setgrent
2223
2224 =item sethostent STAYOPEN
2225
2226 =item setnetent STAYOPEN
2227
2228 =item setprotoent STAYOPEN
2229
2230 =item setservent STAYOPEN
2231
2232 =item endpwent
2233
2234 =item endgrent
2235
2236 =item endhostent
2237
2238 =item endnetent
2239
2240 =item endprotoent
2241
2242 =item endservent
2243
2244 These routines are the same as their counterparts in the
2245 system C library.  In list context, the return values from the
2246 various get routines are as follows:
2247
2248     ($name,$passwd,$uid,$gid,
2249        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
2250     ($name,$passwd,$gid,$members) = getgr*
2251     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2252     ($name,$aliases,$addrtype,$net) = getnet*
2253     ($name,$aliases,$proto) = getproto*
2254     ($name,$aliases,$port,$proto) = getserv*
2255
2256 (If the entry doesn't exist you get an empty list.)
2257
2258 The exact meaning of the $gcos field varies but it usually contains
2259 the real name of the user (as opposed to the login name) and other
2260 information pertaining to the user.  Beware, however, that in many
2261 system users are able to change this information and therefore it
2262 cannot be trusted and therefore the $gcos is tainted (see
2263 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2264 login shell, are also tainted, because of the same reason.
2265
2266 In scalar context, you get the name, unless the function was a
2267 lookup by name, in which case you get the other thing, whatever it is.
2268 (If the entry doesn't exist you get the undefined value.)  For example:
2269
2270     $uid   = getpwnam($name);
2271     $name  = getpwuid($num);
2272     $name  = getpwent();
2273     $gid   = getgrnam($name);
2274     $name  = getgrgid($num);
2275     $name  = getgrent();
2276     #etc.
2277
2278 In I<getpw*()> the fields $quota, $comment, and $expire are special
2279 in that they are unsupported on many systems.  If the
2280 $quota is unsupported, it is an empty scalar.  If it is supported, it
2281 usually encodes the disk quota.  If the $comment field is unsupported,
2282 it is an empty scalar.  If it is supported it usually encodes some
2283 administrative comment about the user.  In some systems the $quota
2284 field may be $change or $age, fields that have to do with password
2285 aging.  In some systems the $comment field may be $class.  The $expire
2286 field, if present, encodes the expiration period of the account or the
2287 password.  For the availability and the exact meaning of these fields
2288 in your system, please consult your getpwnam(3) documentation and your
2289 F<pwd.h> file.  You can also find out from within Perl what your
2290 $quota and $comment fields mean and whether you have the $expire field
2291 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2292 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2293 files are supported only if your vendor has implemented them in the
2294 intuitive fashion that calling the regular C library routines gets the
2295 shadow versions if you're running under privilege or if there exists
2296 the shadow(3) functions as found in System V (this includes Solaris
2297 and Linux.)  Those systems that implement a proprietary shadow password
2298 facility are unlikely to be supported.
2299
2300 The $members value returned by I<getgr*()> is a space separated list of
2301 the login names of the members of the group.
2302
2303 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2304 C, it will be returned to you via C<$?> if the function call fails.  The
2305 C<@addrs> value returned by a successful call is a list of raw
2306 addresses returned by the corresponding library call.  In the
2307 Internet domain, each address is four bytes long; you can unpack it
2308 by saying something like:
2309
2310     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2311
2312 The Socket library makes this slightly easier:
2313
2314     use Socket;
2315     $iaddr = inet_aton("127.1"); # or whatever address
2316     $name  = gethostbyaddr($iaddr, AF_INET);
2317
2318     # or going the other way
2319     $straddr = inet_ntoa($iaddr);
2320
2321 In the opposite way, to resolve a hostname to the IP address
2322 you can write this:
2323
2324     use Socket;
2325     $packed_ip = gethostbyname("www.perl.org");
2326     if (defined $packed_ip) {
2327         $ip_address = inet_ntoa($packed_ip);
2328     }
2329
2330 Make sure <gethostbyname()> is called in SCALAR context and that
2331 its return value is checked for definedness.
2332
2333 If you get tired of remembering which element of the return list
2334 contains which return value, by-name interfaces are provided
2335 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2336 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2337 and C<User::grent>.  These override the normal built-ins, supplying
2338 versions that return objects with the appropriate names
2339 for each field.  For example:
2340
2341    use File::stat;
2342    use User::pwent;
2343    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2344
2345 Even though it looks like they're the same method calls (uid),
2346 they aren't, because a C<File::stat> object is different from
2347 a C<User::pwent> object.
2348
2349 =item getsockname SOCKET
2350 X<getsockname>
2351
2352 Returns the packed sockaddr address of this end of the SOCKET connection,
2353 in case you don't know the address because you have several different
2354 IPs that the connection might have come in on.
2355
2356     use Socket;
2357     $mysockaddr = getsockname(SOCK);
2358     ($port, $myaddr) = sockaddr_in($mysockaddr);
2359     printf "Connect to %s [%s]\n",
2360        scalar gethostbyaddr($myaddr, AF_INET),
2361        inet_ntoa($myaddr);
2362
2363 =item getsockopt SOCKET,LEVEL,OPTNAME
2364 X<getsockopt>
2365
2366 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2367 Options may exist at multiple protocol levels depending on the socket
2368 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2369 C<Socket> module) will exist. To query options at another level the
2370 protocol number of the appropriate protocol controlling the option
2371 should be supplied. For example, to indicate that an option is to be
2372 interpreted by the TCP protocol, LEVEL should be set to the protocol
2373 number of TCP, which you can get using C<getprotobyname>.
2374
2375 The function returns a packed string representing the requested socket
2376 option, or C<undef> on error, with the reason for the error placed in
2377 C<$!>). Just what is in the packed string depends on LEVEL and OPTNAME;
2378 consult getsockopt(2) for details.  A common case is that the option is an
2379 integer, in which case the result is a packed integer, which you can decode
2380 using C<unpack> with the C<i> (or C<I>) format.
2381
2382 An example to test whether Nagle's algorithm is turned on on a socket:
2383
2384     use Socket qw(:all);
2385
2386     defined(my $tcp = getprotobyname("tcp"))
2387         or die "Could not determine the protocol number for tcp";
2388     # my $tcp = IPPROTO_TCP; # Alternative
2389     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2390         or die "getsockopt TCP_NODELAY: $!";
2391     my $nodelay = unpack("I", $packed);
2392     print "Nagle's algorithm is turned ", $nodelay ? "off\n" : "on\n";
2393
2394
2395 =item glob EXPR
2396 X<glob> X<wildcard> X<filename, expansion> X<expand>
2397
2398 =item glob
2399
2400 In list context, returns a (possibly empty) list of filename expansions on
2401 the value of EXPR such as the standard Unix shell F</bin/csh> would do. In
2402 scalar context, glob iterates through such filename expansions, returning
2403 undef when the list is exhausted. This is the internal function
2404 implementing the C<< <*.c> >> operator, but you can use it directly. If
2405 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2406 more detail in L<perlop/"I/O Operators">.
2407
2408 Note that C<glob> splits its arguments on whitespace and treats
2409 each segment as separate pattern.  As such, C<glob("*.c *.h")> 
2410 matches all files with a F<.c> or F<.h> extension.  The expression
2411 C<glob(".* *")> matches all files in the current working directory.
2412
2413 If non-empty braces are the only wildcard characters used in the
2414 C<glob>, no filenames are matched, but potentially many strings
2415 are returned.  For example, this produces nine strings, one for
2416 each pairing of fruits and colors:
2417
2418     @many =  glob "{apple,tomato,cherry}={green,yellow,red}";
2419
2420 Beginning with v5.6.0, this operator is implemented using the standard
2421 C<File::Glob> extension.  See L<File::Glob> for details, including
2422 C<bsd_glob> which does not treat whitespace as a pattern separator.
2423
2424 =item gmtime EXPR
2425 X<gmtime> X<UTC> X<Greenwich>
2426
2427 =item gmtime
2428
2429 Works just like L<localtime> but the returned values are
2430 localized for the standard Greenwich time zone.
2431
2432 Note: when called in list context, $isdst, the last value
2433 returned by gmtime is always C<0>.  There is no
2434 Daylight Saving Time in GMT.
2435
2436 See L<perlport/gmtime> for portability concerns.
2437
2438 =item goto LABEL
2439 X<goto> X<jump> X<jmp>
2440
2441 =item goto EXPR
2442
2443 =item goto &NAME
2444
2445 The C<goto-LABEL> form finds the statement labeled with LABEL and
2446 resumes execution there. It can't be used to get out of a block or
2447 subroutine given to C<sort>.  It can be used to go almost anywhere
2448 else within the dynamic scope, including out of subroutines, but it's
2449 usually better to use some other construct such as C<last> or C<die>.
2450 The author of Perl has never felt the need to use this form of C<goto>
2451 (in Perl, that is; C is another matter).  (The difference is that C
2452 does not offer named loops combined with loop control.  Perl does, and
2453 this replaces most structured uses of C<goto> in other languages.)
2454
2455 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2456 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2457 necessarily recommended if you're optimizing for maintainability:
2458
2459     goto ("FOO", "BAR", "GLARCH")[$i];
2460
2461 Use of C<goto-LABEL> or C<goto-EXPR> to jump into a construct is
2462 deprecated and will issue a warning.  Even then, it may not be used to
2463 go into any construct that requires initialization, such as a
2464 subroutine or a C<foreach> loop.  It also can't be used to go into a
2465 construct that is optimized away.
2466
2467 The C<goto-&NAME> form is quite different from the other forms of
2468 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2469 doesn't have the stigma associated with other gotos.  Instead, it
2470 exits the current subroutine (losing any changes set by local()) and
2471 immediately calls in its place the named subroutine using the current
2472 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2473 load another subroutine and then pretend that the other subroutine had
2474 been called in the first place (except that any modifications to C<@_>
2475 in the current subroutine are propagated to the other subroutine.)
2476 After the C<goto>, not even C<caller> will be able to tell that this
2477 routine was called first.
2478
2479 NAME needn't be the name of a subroutine; it can be a scalar variable
2480 containing a code reference, or a block that evaluates to a code
2481 reference.
2482
2483 =item grep BLOCK LIST
2484 X<grep>
2485
2486 =item grep EXPR,LIST
2487
2488 This is similar in spirit to, but not the same as, grep(1) and its
2489 relatives.  In particular, it is not limited to using regular expressions.
2490
2491 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2492 C<$_> to each element) and returns the list value consisting of those
2493 elements for which the expression evaluated to true.  In scalar
2494 context, returns the number of times the expression was true.
2495
2496     @foo = grep(!/^#/, @bar);    # weed out comments
2497
2498 or equivalently,
2499
2500     @foo = grep {!/^#/} @bar;    # weed out comments
2501
2502 Note that C<$_> is an alias to the list value, so it can be used to
2503 modify the elements of the LIST.  While this is useful and supported,
2504 it can cause bizarre results if the elements of LIST are not variables.
2505 Similarly, grep returns aliases into the original list, much as a for
2506 loop's index variable aliases the list elements.  That is, modifying an
2507 element of a list returned by grep (for example, in a C<foreach>, C<map>
2508 or another C<grep>) actually modifies the element in the original list.
2509 This is usually something to be avoided when writing clear code.
2510
2511 If C<$_> is lexical in the scope where the C<grep> appears (because it has
2512 been declared with C<my $_>) then, in addition to being locally aliased to
2513 the list elements, C<$_> keeps being lexical inside the block; i.e., it
2514 can't be seen from the outside, avoiding any potential side-effects.
2515
2516 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2517
2518 =item hex EXPR
2519 X<hex> X<hexadecimal>
2520
2521 =item hex
2522
2523 Interprets EXPR as a hex string and returns the corresponding value.
2524 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
2525 L</oct>.)  If EXPR is omitted, uses C<$_>.
2526
2527     print hex '0xAf'; # prints '175'
2528     print hex 'aF';   # same
2529
2530 Hex strings may only represent integers.  Strings that would cause
2531 integer overflow trigger a warning.  Leading whitespace is not stripped,
2532 unlike oct(). To present something as hex, look into L</printf>,
2533 L</sprintf>, or L</unpack>.
2534
2535 =item import LIST
2536 X<import>
2537
2538 There is no builtin C<import> function.  It is just an ordinary
2539 method (subroutine) defined (or inherited) by modules that wish to export
2540 names to another module.  The C<use> function calls the C<import> method
2541 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2542
2543 =item index STR,SUBSTR,POSITION
2544 X<index> X<indexOf> X<InStr>
2545
2546 =item index STR,SUBSTR
2547
2548 The index function searches for one string within another, but without
2549 the wildcard-like behavior of a full regular-expression pattern match.
2550 It returns the position of the first occurrence of SUBSTR in STR at
2551 or after POSITION.  If POSITION is omitted, starts searching from the
2552 beginning of the string.  POSITION before the beginning of the string
2553 or after its end is treated as if it were the beginning or the end,
2554 respectively.  POSITION and the return value are based at C<0> (or whatever
2555 you've set the C<$[> variable to--but don't do that).  If the substring
2556 is not found, C<index> returns one less than the base, ordinarily C<-1>.
2557
2558 =item int EXPR
2559 X<int> X<integer> X<truncate> X<trunc> X<floor>
2560
2561 =item int
2562
2563 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2564 You should not use this function for rounding: one because it truncates
2565 towards C<0>, and two because machine representations of floating-point
2566 numbers can sometimes produce counterintuitive results.  For example,
2567 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2568 because it's really more like -268.99999999999994315658 instead.  Usually,
2569 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2570 functions will serve you better than will int().
2571
2572 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2573 X<ioctl>
2574
2575 Implements the ioctl(2) function.  You'll probably first have to say
2576
2577     require "sys/ioctl.ph";  # probably in $Config{archlib}/sys/ioctl.ph
2578
2579 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
2580 exist or doesn't have the correct definitions you'll have to roll your
2581 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2582 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2583 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2584 written depending on the FUNCTION; a C pointer to the string value of SCALAR
2585 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2586 has no string value but does have a numeric value, that value will be
2587 passed rather than a pointer to the string value.  To guarantee this to be
2588 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2589 functions may be needed to manipulate the values of structures used by
2590 C<ioctl>.
2591
2592 The return value of C<ioctl> (and C<fcntl>) is as follows:
2593
2594     if OS returns:      then Perl returns:
2595         -1               undefined value
2596          0              string "0 but true"
2597     anything else           that number
2598
2599 Thus Perl returns true on success and false on failure, yet you can
2600 still easily determine the actual value returned by the operating
2601 system:
2602
2603     $retval = ioctl(...) || -1;
2604     printf "System returned %d\n", $retval;
2605
2606 The special string C<"0 but true"> is exempt from B<-w> complaints
2607 about improper numeric conversions.
2608
2609 =item join EXPR,LIST
2610 X<join>
2611
2612 Joins the separate strings of LIST into a single string with fields
2613 separated by the value of EXPR, and returns that new string.  Example:
2614
2615     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2616
2617 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2618 first argument.  Compare L</split>.
2619
2620 =item keys HASH (or HASHREF)
2621 X<keys> X<key>
2622
2623 =item keys ARRAY (or ARRAYREF)
2624
2625 Returns a list consisting of all the keys of the named hash, or the indices
2626 of an array. (In scalar context, returns the number of keys or indices.)
2627
2628 The keys of a hash are returned in an apparently random order.  The actual
2629 random order is subject to change in future versions of Perl, but it
2630 is guaranteed to be the same order as either the C<values> or C<each>
2631 function produces (given that the hash has not been modified).  Since
2632 Perl 5.8.1 the ordering can be different even between different runs of
2633 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
2634 Attacks">).
2635
2636 As a side effect, calling keys() resets the HASH or ARRAY's internal iterator
2637 (see L</each>).  In particular, calling keys() in void context resets
2638 the iterator with no other overhead.
2639
2640 Here is yet another way to print your environment:
2641
2642     @keys = keys %ENV;
2643     @values = values %ENV;
2644     while (@keys) {
2645         print pop(@keys), '=', pop(@values), "\n";
2646     }
2647
2648 or how about sorted by key:
2649
2650     foreach $key (sort(keys %ENV)) {
2651         print $key, '=', $ENV{$key}, "\n";
2652     }
2653
2654 The returned values are copies of the original keys in the hash, so
2655 modifying them will not affect the original hash.  Compare L</values>.
2656
2657 To sort a hash by value, you'll need to use a C<sort> function.
2658 Here's a descending numeric sort of a hash by its values:
2659
2660     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2661         printf "%4d %s\n", $hash{$key}, $key;
2662     }
2663
2664 Used as an lvalue, C<keys> allows you to increase the number of hash buckets
2665 allocated for the given hash.  This can gain you a measure of efficiency if
2666 you know the hash is going to get big.  (This is similar to pre-extending
2667 an array by assigning a larger number to $#array.)  If you say
2668
2669     keys %hash = 200;
2670
2671 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2672 in fact, since it rounds up to the next power of two.  These
2673 buckets will be retained even if you do C<%hash = ()>, use C<undef
2674 %hash> if you want to free the storage while C<%hash> is still in scope.
2675 You can't shrink the number of buckets allocated for the hash using
2676 C<keys> in this way (but you needn't worry about doing this by accident,
2677 as trying has no effect). C<keys @array> in an lvalue context is a syntax
2678 error.
2679
2680 When given a reference to a hash or array, the argument will be
2681 dereferenced automatically.
2682
2683     for (keys $hashref) { ... }
2684     for (keys $obj->get_arrayref) { ... }
2685
2686 If the reference is a blessed object that overrides either C<%{}> or
2687 C<@{}>, the override will be used instead of dereferencing the underlying
2688 variable type.  If both overrides are provided, C<%{}> will be the default.
2689 If this is not desired, you must dereference the argument yourself.
2690
2691 See also C<each>, C<values> and C<sort>.
2692
2693 =item kill SIGNAL, LIST
2694 X<kill> X<signal>
2695
2696 Sends a signal to a list of processes.  Returns the number of
2697 processes successfully signaled (which is not necessarily the
2698 same as the number actually killed).
2699
2700     $cnt = kill 1, $child1, $child2;
2701     kill 9, @goners;
2702
2703 If SIGNAL is zero, no signal is sent to the process, but C<kill>
2704 checks whether it's I<possible> to send a signal to it (that
2705 means, to be brief, that the process is owned by the same user, or we are
2706 the super-user).  This is useful to check that a child process is still
2707 alive (even if only as a zombie) and hasn't changed its UID.  See
2708 L<perlport> for notes on the portability of this construct.
2709
2710 Unlike in the shell, if SIGNAL is negative, it kills process groups instead
2711 of processes. That means you usually want to use positive not negative signals.
2712 You may also use a signal name in quotes.
2713
2714 The behavior of kill when a I<PROCESS> number is zero or negative depends on
2715 the operating system.  For example, on POSIX-conforming systems, zero will
2716 signal the current process group and -1 will signal all processes.
2717
2718 See L<perlipc/"Signals"> for more details.
2719
2720 =item last LABEL
2721 X<last> X<break>
2722
2723 =item last
2724
2725 The C<last> command is like the C<break> statement in C (as used in
2726 loops); it immediately exits the loop in question.  If the LABEL is
2727 omitted, the command refers to the innermost enclosing loop.  The
2728 C<continue> block, if any, is not executed:
2729
2730     LINE: while (<STDIN>) {
2731         last LINE if /^$/;  # exit when done with header
2732         #...
2733     }
2734
2735 C<last> cannot be used to exit a block that returns a value such as
2736 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2737 a grep() or map() operation.
2738
2739 Note that a block by itself is semantically identical to a loop
2740 that executes once.  Thus C<last> can be used to effect an early
2741 exit out of such a block.
2742
2743 See also L</continue> for an illustration of how C<last>, C<next>, and
2744 C<redo> work.
2745
2746 =item lc EXPR
2747 X<lc> X<lowercase>
2748
2749 =item lc
2750
2751 Returns a lowercased version of EXPR.  This is the internal function
2752 implementing the C<\L> escape in double-quoted strings.
2753
2754 If EXPR is omitted, uses C<$_>.
2755
2756 What gets returned depends on several factors:
2757
2758 =over
2759
2760 =item If C<use bytes> is in effect:
2761
2762 =over
2763
2764 =item On EBCDIC platforms
2765
2766 The results are what the C language system call C<tolower()> returns.
2767
2768 =item On ASCII platforms
2769
2770 The results follow ASCII semantics.  Only characters C<A-Z> change, to C<a-z>
2771 respectively.
2772
2773 =back
2774
2775 =item Otherwise, If EXPR has the UTF8 flag set
2776
2777 If the current package has a subroutine named C<ToLower>, it will be used to
2778 change the case (See L<perlunicode/User-Defined Case Mappings>.)
2779 Otherwise Unicode semantics are used for the case change.
2780
2781 =item Otherwise, if C<use locale> is in effect
2782
2783 Respects current LC_CTYPE locale.  See L<perllocale>.
2784
2785 =item Otherwise, if C<use feature 'unicode_strings'> is in effect:
2786
2787 Unicode semantics are used for the case change.  Any subroutine named
2788 C<ToLower> will not be used.
2789
2790 =item Otherwise:
2791
2792 =over
2793
2794 =item On EBCDIC platforms
2795
2796 The results are what the C language system call C<tolower()> returns.
2797
2798 =item On ASCII platforms
2799
2800 ASCII semantics are used for the case change.  The lowercase of any character
2801 outside the ASCII range is the character itself.
2802
2803 =back
2804
2805 =back
2806
2807 =item lcfirst EXPR
2808 X<lcfirst> X<lowercase>
2809
2810 =item lcfirst
2811
2812 Returns the value of EXPR with the first character lowercased.  This
2813 is the internal function implementing the C<\l> escape in
2814 double-quoted strings.
2815
2816 If EXPR is omitted, uses C<$_>.
2817
2818 This function behaves the same way under various pragma, such as in a locale,
2819 as L</lc> does.
2820
2821 =item length EXPR
2822 X<length> X<size>
2823
2824 =item length
2825
2826 Returns the length in I<characters> of the value of EXPR.  If EXPR is
2827 omitted, returns length of C<$_>.  If EXPR is undefined, returns C<undef>.
2828
2829 This function cannot be used on an entire array or hash to find out how
2830 many elements these have.  For that, use C<scalar @array> and C<scalar keys
2831 %hash>, respectively.
2832
2833 Like all Perl character operations, length() normally deals in logical
2834 characters, not physical bytes.  For how many bytes a string encoded as
2835 UTF-8 would take up, use C<length(Encode::encode_utf8(EXPR))> (you'll have
2836 to C<use Encode> first).  See L<Encode> and L<perlunicode>.
2837
2838 =item link OLDFILE,NEWFILE
2839 X<link>
2840
2841 Creates a new filename linked to the old filename.  Returns true for
2842 success, false otherwise.
2843
2844 =item listen SOCKET,QUEUESIZE
2845 X<listen>
2846
2847 Does the same thing that the listen(2) system call does.  Returns true if
2848 it succeeded, false otherwise.  See the example in
2849 L<perlipc/"Sockets: Client/Server Communication">.
2850
2851 =item local EXPR
2852 X<local>
2853
2854 You really probably want to be using C<my> instead, because C<local> isn't
2855 what most people think of as "local".  See
2856 L<perlsub/"Private Variables via my()"> for details.
2857
2858 A local modifies the listed variables to be local to the enclosing
2859 block, file, or eval.  If more than one value is listed, the list must
2860 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2861 for details, including issues with tied arrays and hashes.
2862
2863 The C<delete local EXPR> construct can also be used to localize the deletion
2864 of array/hash elements to the current block.
2865 See L<perlsub/"Localized deletion of elements of composite types">.
2866
2867 =item localtime EXPR
2868 X<localtime> X<ctime>
2869
2870 =item localtime
2871
2872 Converts a time as returned by the time function to a 9-element list
2873 with the time analyzed for the local time zone.  Typically used as
2874 follows:
2875
2876     #  0    1    2     3     4    5     6     7     8
2877     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2878                                                 localtime(time);
2879
2880 All list elements are numeric, and come straight out of the C `struct
2881 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
2882 of the specified time.
2883
2884 C<$mday> is the day of the month, and C<$mon> is the month itself, in
2885 the range C<0..11> with 0 indicating January and 11 indicating December.
2886 This makes it easy to get a month name from a list:
2887
2888     my @abbr = qw( Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec );
2889     print "$abbr[$mon] $mday";
2890     # $mon=9, $mday=18 gives "Oct 18"
2891
2892 C<$year> is the number of years since 1900, not just the last two digits
2893 of the year.  That is, C<$year> is C<123> in year 2023.  The proper way
2894 to get a 4-digit year is simply:
2895
2896     $year += 1900;
2897
2898 Otherwise you create non-Y2K-compliant programs--and you wouldn't want
2899 to do that, would you?
2900
2901 To get the last two digits of the year (e.g., '01' in 2001) do:
2902
2903     $year = sprintf("%02d", $year % 100);
2904
2905 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
2906 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
2907 (or C<0..365> in leap years.)
2908
2909 C<$isdst> is true if the specified time occurs during Daylight Saving
2910 Time, false otherwise.
2911
2912 If EXPR is omitted, C<localtime()> uses the current time (as returned
2913 by time(3)).
2914
2915 In scalar context, C<localtime()> returns the ctime(3) value:
2916
2917     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2918
2919 This scalar value is B<not> locale dependent but is a Perl builtin. For GMT
2920 instead of local time use the L</gmtime> builtin. See also the
2921 C<Time::Local> module (to convert the second, minutes, hours, ... back to
2922 the integer value returned by time()), and the L<POSIX> module's strftime(3)
2923 and mktime(3) functions.
2924
2925 To get somewhat similar but locale dependent date strings, set up your
2926 locale environment variables appropriately (please see L<perllocale>) and
2927 try for example:
2928
2929     use POSIX qw(strftime);
2930     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2931     # or for GMT formatted appropriately for your locale:
2932     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
2933
2934 Note that the C<%a> and C<%b>, the short forms of the day of the week
2935 and the month of the year, may not necessarily be three characters wide.
2936
2937 See L<perlport/localtime> for portability concerns.
2938
2939 The L<Time::gmtime> and L<Time::localtime> modules provides a convenient,
2940 by-name access mechanism to the gmtime() and localtime() functions,
2941 respectively.
2942
2943 For a comprehensive date and time representation look at the
2944 L<DateTime> module on CPAN.
2945
2946 =item lock THING
2947 X<lock>
2948
2949 This function places an advisory lock on a shared variable, or referenced
2950 object contained in I<THING> until the lock goes out of scope.
2951
2952 lock() is a "weak keyword" : this means that if you've defined a function
2953 by this name (before any calls to it), that function will be called
2954 instead.  If you are not under C<use threads::shared> this does nothing.
2955 See L<threads::shared>.
2956
2957 =item log EXPR
2958 X<log> X<logarithm> X<e> X<ln> X<base>
2959
2960 =item log
2961
2962 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2963 returns log of C<$_>.  To get the log of another base, use basic algebra:
2964 The base-N log of a number is equal to the natural log of that number
2965 divided by the natural log of N.  For example:
2966
2967     sub log10 {
2968         my $n = shift;
2969         return log($n)/log(10);
2970     }
2971
2972 See also L</exp> for the inverse operation.
2973
2974 =item lstat EXPR
2975 X<lstat>
2976
2977 =item lstat
2978
2979 Does the same thing as the C<stat> function (including setting the
2980 special C<_> filehandle) but stats a symbolic link instead of the file
2981 the symbolic link points to.  If symbolic links are unimplemented on
2982 your system, a normal C<stat> is done.  For much more detailed
2983 information, please see the documentation for C<stat>.
2984
2985 If EXPR is omitted, stats C<$_>.
2986
2987 =item m//
2988
2989 The match operator.  See L<perlop/"Regexp Quote-Like Operators">.
2990
2991 =item map BLOCK LIST
2992 X<map>
2993
2994 =item map EXPR,LIST
2995
2996 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2997 C<$_> to each element) and returns the list value composed of the
2998 results of each such evaluation.  In scalar context, returns the
2999 total number of elements so generated.  Evaluates BLOCK or EXPR in
3000 list context, so each element of LIST may produce zero, one, or
3001 more elements in the returned value.
3002
3003     @chars = map(chr, @numbers);
3004
3005 translates a list of numbers to the corresponding characters.
3006
3007     my @squares = map { $_ * $_ } @numbers;
3008
3009 translates a list of numbers to their squared values.
3010
3011     my @squares = map { $_ > 5 ? ($_ * $_) : () } @numbers;
3012
3013 shows that number of returned elements can differ from the number of
3014 input elements. To omit an element, return an empty list ().
3015 This could also be achieved by writing
3016
3017     my @squares = map { $_ * $_ } grep { $_ > 5 } @numbers;
3018
3019 which makes the intention more clear.
3020
3021 Map always returns a list which can be assigned to a hash where the elements
3022 become key/value pairs. See L<perldata> for more details.
3023
3024     %hash = map { get_a_key_for($_) => $_ } @array;
3025
3026 is just a funny way to write
3027
3028     %hash = ();
3029     foreach (@array) {
3030         $hash{get_a_key_for($_)} = $_;
3031     }
3032
3033 Note that C<$_> is an alias to the list value, so it can be used to
3034 modify the elements of the LIST.  While this is useful and supported,
3035 it can cause bizarre results if the elements of LIST are not variables.
3036 Using a regular C<foreach> loop for this purpose would be clearer in
3037 most cases.  See also L</grep> for an array composed of those items of
3038 the original list for which the BLOCK or EXPR evaluates to true.
3039
3040 If C<$_> is lexical in the scope where the C<map> appears (because it has
3041 been declared with C<my $_>), then, in addition to being locally aliased to
3042 the list elements, C<$_> keeps being lexical inside the block; that is, it
3043 can't be seen from the outside, avoiding any potential side-effects.
3044
3045 C<{> starts both hash references and blocks, so C<map { ...> could be either
3046 the start of map BLOCK LIST or map EXPR, LIST. Because Perl doesn't look
3047 ahead for the closing C<}> it has to take a guess at which it's dealing with
3048 based on what it finds just after the C<{>. Usually it gets it right, but if it
3049 doesn't it won't realize something is wrong until it gets to the C<}> and
3050 encounters the missing (or unexpected) comma. The syntax error will be
3051 reported close to the C<}>, but you'll need to change something near the C<{>
3052 such as using a unary C<+> to give Perl some help:
3053
3054     %hash = map {  "\L$_" => 1  } @array  # perl guesses EXPR.  wrong
3055     %hash = map { +"\L$_" => 1  } @array  # perl guesses BLOCK. right
3056     %hash = map { ("\L$_" => 1) } @array  # this also works
3057     %hash = map {  lc($_) => 1  } @array  # as does this.
3058     %hash = map +( lc($_) => 1 ), @array  # this is EXPR and works!
3059
3060     %hash = map  ( lc($_), 1 ),   @array  # evaluates to (1, @array)
3061
3062 or to force an anon hash constructor use C<+{>:
3063
3064    @hashes = map +{ lc($_) => 1 }, @array # EXPR, so needs comma at end
3065
3066 to get a list of anonymous hashes each with only one entry apiece.
3067
3068 =item mkdir FILENAME,MASK
3069 X<mkdir> X<md> X<directory, create>
3070
3071 =item mkdir FILENAME
3072
3073 =item mkdir
3074
3075 Creates the directory specified by FILENAME, with permissions
3076 specified by MASK (as modified by C<umask>).  If it succeeds it
3077 returns true, otherwise it returns false and sets C<$!> (errno).
3078 If omitted, MASK defaults to 0777. If omitted, FILENAME defaults
3079 to C<$_>.
3080
3081 In general, it is better to create directories with permissive MASK,
3082 and let the user modify that with their C<umask>, than it is to supply
3083 a restrictive MASK and give the user no way to be more permissive.
3084 The exceptions to this rule are when the file or directory should be
3085 kept private (mail files, for instance).  The perlfunc(1) entry on
3086 C<umask> discusses the choice of MASK in more detail.
3087
3088 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
3089 number of trailing slashes.  Some operating and filesystems do not get
3090 this right, so Perl automatically removes all trailing slashes to keep
3091 everyone happy.
3092
3093 To recursively create a directory structure, look at
3094 the C<mkpath> function of the L<File::Path> module.
3095
3096 =item msgctl ID,CMD,ARG
3097 X<msgctl>
3098
3099 Calls the System V IPC function msgctl(2).  You'll probably have to say
3100
3101     use IPC::SysV;
3102
3103 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
3104 then ARG must be a variable that will hold the returned C<msqid_ds>
3105 structure.  Returns like C<ioctl>: the undefined value for error,
3106 C<"0 but true"> for zero, or the actual return value otherwise.  See also
3107 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::Semaphore> documentation.
3108
3109 =item msgget KEY,FLAGS
3110 X<msgget>
3111
3112 Calls the System V IPC function msgget(2).  Returns the message queue
3113 id, or the undefined value if there is an error.  See also
3114 L<perlipc/"SysV IPC"> and C<IPC::SysV> and C<IPC::Msg> documentation.
3115
3116 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
3117 X<msgrcv>
3118
3119 Calls the System V IPC function msgrcv to receive a message from
3120 message queue ID into variable VAR with a maximum message size of
3121 SIZE.  Note that when a message is received, the message type as a
3122 native long integer will be the first thing in VAR, followed by the
3123 actual message.  This packing may be opened with C<unpack("l! a*")>.
3124 Taints the variable.  Returns true if successful, or false if there is
3125 an error.  See also L<perlipc/"SysV IPC">, C<IPC::SysV>, and
3126 C<IPC::SysV::Msg> documentation.
3127
3128 =item msgsnd ID,MSG,FLAGS
3129 X<msgsnd>
3130
3131 Calls the System V IPC function msgsnd to send the message MSG to the
3132 message queue ID.  MSG must begin with the native long integer message
3133 type, and be followed by the length of the actual message, and finally
3134 the message itself.  This kind of packing can be achieved with
3135 C<pack("l! a*", $type, $message)>.  Returns true if successful,
3136 or false if there is an error.  See also C<IPC::SysV>
3137 and C<IPC::SysV::Msg> documentation.
3138
3139 =item my EXPR
3140 X<my>
3141
3142 =item my TYPE EXPR
3143
3144 =item my EXPR : ATTRS
3145
3146 =item my TYPE EXPR : ATTRS
3147
3148 A C<my> declares the listed variables to be local (lexically) to the
3149 enclosing block, file, or C<eval>.  If more than one value is listed,
3150 the list must be placed in parentheses.
3151
3152 The exact semantics and interface of TYPE and ATTRS are still
3153 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3154 and attributes are handled using the C<attributes> pragma, or starting
3155 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3156 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3157 L<attributes>, and L<Attribute::Handlers>.
3158
3159 =item next LABEL
3160 X<next> X<continue>
3161
3162 =item next
3163
3164 The C<next> command is like the C<continue> statement in C; it starts
3165 the next iteration of the loop:
3166
3167     LINE: while (<STDIN>) {
3168         next LINE if /^#/;  # discard comments
3169         #...
3170     }
3171
3172 Note that if there were a C<continue> block on the above, it would get
3173 executed even on discarded lines.  If LABEL is omitted, the command
3174 refers to the innermost enclosing loop.
3175
3176 C<next> cannot be used to exit a block which returns a value such as
3177 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
3178 a grep() or map() operation.
3179
3180 Note that a block by itself is semantically identical to a loop
3181 that executes once.  Thus C<next> will exit such a block early.
3182
3183 See also L</continue> for an illustration of how C<last>, C<next>, and
3184 C<redo> work.
3185
3186 =item no MODULE VERSION LIST
3187 X<no declarations>
3188 X<unimporting>
3189
3190 =item no MODULE VERSION
3191
3192 =item no MODULE LIST
3193
3194 =item no MODULE
3195
3196 =item no VERSION
3197
3198 See the C<use> function, of which C<no> is the opposite.
3199
3200 =item oct EXPR
3201 X<oct> X<octal> X<hex> X<hexadecimal> X<binary> X<bin>
3202
3203 =item oct
3204
3205 Interprets EXPR as an octal string and returns the corresponding
3206 value.  (If EXPR happens to start off with C<0x>, interprets it as a
3207 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
3208 binary string.  Leading whitespace is ignored in all three cases.)
3209 The following will handle decimal, binary, octal, and hex in standard
3210 Perl notation:
3211
3212     $val = oct($val) if $val =~ /^0/;
3213
3214 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
3215 in octal), use sprintf() or printf():
3216
3217     $dec_perms = (stat("filename"))[2] & 07777;
3218     $oct_perm_str = sprintf "%o", $perms;
3219
3220 The oct() function is commonly used when a string such as C<644> needs
3221 to be converted into a file mode, for example.  Although Perl 
3222 automatically converts strings into numbers as needed, this automatic
3223 conversion assumes base 10.
3224
3225 Leading white space is ignored without warning, as too are any trailing 
3226 non-digits, such as a decimal point (C<oct> only handles non-negative
3227 integers, not negative integers or floating point).
3228
3229 =item open FILEHANDLE,EXPR
3230 X<open> X<pipe> X<file, open> X<fopen>
3231
3232 =item open FILEHANDLE,MODE,EXPR
3233
3234 =item open FILEHANDLE,MODE,EXPR,LIST
3235
3236 =item open FILEHANDLE,MODE,REFERENCE
3237
3238 =item open FILEHANDLE
3239
3240 Opens the file whose filename is given by EXPR, and associates it with
3241 FILEHANDLE.
3242
3243 Simple examples to open a file for reading:
3244
3245     open(my $fh, '<', "input.txt") or die $!;
3246
3247 and for writing:
3248
3249     open(my $fh, '>', "output.txt") or die $!;
3250
3251 (The following is a comprehensive reference to open(): for a gentler
3252 introduction you may consider L<perlopentut>.)
3253
3254 If FILEHANDLE is an undefined scalar variable (or array or hash element)
3255 the variable is assigned a reference to a new anonymous filehandle,
3256 otherwise if FILEHANDLE is an expression, its value is used as the name of
3257 the real filehandle wanted.  (This is considered a symbolic reference, so
3258 C<use strict 'refs'> should I<not> be in effect.)
3259
3260 If EXPR is omitted, the scalar variable of the same name as the
3261 FILEHANDLE contains the filename.  (Note that lexical variables--those
3262 declared with C<my>--will not work for this purpose; so if you're
3263 using C<my>, specify EXPR in your call to open.)
3264
3265 If three or more arguments are specified then the mode of opening and
3266 the filename are separate. If MODE is C<< '<' >> or nothing, the file
3267 is opened for input.  If MODE is C<< '>' >>, the file is truncated and
3268 opened for output, being created if necessary.  If MODE is C<<< '>>' >>>,
3269 the file is opened for appending, again being created if necessary.
3270
3271 You can put a C<'+'> in front of the C<< '>' >> or C<< '<' >> to
3272 indicate that you want both read and write access to the file; thus
3273 C<< '+<' >> is almost always preferred for read/write updates--the 
3274 C<< '+>' >> mode would clobber the file first.  You can't usually use
3275 either read-write mode for updating textfiles, since they have
3276 variable length records.  See the B<-i> switch in L<perlrun> for a
3277 better approach.  The file is created with permissions of C<0666>
3278 modified by the process's C<umask> value.
3279
3280 These various prefixes correspond to the fopen(3) modes of C<'r'>,
3281 C<'r+'>, C<'w'>, C<'w+'>, C<'a'>, and C<'a+'>.
3282
3283 In the two-argument (and one-argument) form of the call, the mode and
3284 filename should be concatenated (in that order), possibly separated by
3285 spaces.  You may omit the mode in these forms when that mode is
3286 C<< '<' >>.
3287
3288 If the filename begins with C<'|'>, the filename is interpreted as a
3289 command to which output is to be piped, and if the filename ends with a
3290 C<'|'>, the filename is interpreted as a command that pipes output to
3291 us.  See L<perlipc/"Using open() for IPC">
3292 for more examples of this.  (You are not allowed to C<open> to a command
3293 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
3294 and L<perlipc/"Bidirectional Communication with Another Process">
3295 for alternatives.)
3296
3297 For three or more arguments if MODE is C<'|-'>, the filename is
3298 interpreted as a command to which output is to be piped, and if MODE
3299 is C<'-|'>, the filename is interpreted as a command that pipes
3300 output to us.  In the two-argument (and one-argument) form, one should
3301 replace dash (C<'-'>) with the command.
3302 See L<perlipc/"Using open() for IPC"> for more examples of this.
3303 (You are not allowed to C<open> to a command that pipes both in I<and>
3304 out, but see L<IPC::Open2>, L<IPC::Open3>, and
3305 L<perlipc/"Bidirectional Communication"> for alternatives.)
3306
3307 In the form of pipe opens taking three or more arguments, if LIST is specified
3308 (extra arguments after the command name) then LIST becomes arguments
3309 to the command invoked if the platform supports it.  The meaning of
3310 C<open> with more than three arguments for non-pipe modes is not yet
3311 defined, but experimental "layers" may give extra LIST arguments
3312 meaning.
3313
3314 In the two-argument (and one-argument) form, opening C<< '<-' >> 
3315 or C<'-'> opens STDIN and opening C<< '>-' >> opens STDOUT.
3316
3317 You may use the three-argument form of open to specify I/O layers
3318 (sometimes referred to as "disciplines") to apply to the handle
3319 that affect how the input and output are processed (see L<open> and
3320 L<PerlIO> for more details). For example:
3321
3322   open(my $fh, "<:encoding(UTF-8)", "filename")
3323     || die "can't open UTF-8 encoded filename: $!";
3324
3325 opens the UTF-8 encoded file containing Unicode characters;
3326 see L<perluniintro>. Note that if layers are specified in the
3327 three-argument form, then default layers stored in ${^OPEN} (see L<perlvar>;
3328 usually set by the B<open> pragma or the switch B<-CioD>) are ignored.
3329
3330 Open returns nonzero on success, the undefined value otherwise.  If
3331 the C<open> involved a pipe, the return value happens to be the pid of
3332 the subprocess.
3333
3334 If you're running Perl on a system that distinguishes between text
3335 files and binary files, then you should check out L</binmode> for tips
3336 for dealing with this.  The key distinction between systems that need
3337 C<binmode> and those that don't is their text file formats.  Systems
3338 like Unix, Mac OS, and Plan 9, that end lines with a single
3339 character and encode that character in C as C<"\n"> do not
3340 need C<binmode>.  The rest need it.
3341
3342 When opening a file, it's seldom a good idea to continue 
3343 if the request failed, so C<open> is frequently used with
3344 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
3345 where you want to format a suitable error message (but there are
3346 modules that can help with that problem)) always check
3347 the return value from opening a file.  
3348
3349 As a special case the 3-arg form with a read/write mode and the third
3350 argument being C<undef>:
3351
3352     open(my $tmp, "+>", undef) or die ...
3353
3354 opens a filehandle to an anonymous temporary file.  Also using "+<"
3355 works for symmetry, but you really should consider writing something
3356 to the temporary file first.  You will need to seek() to do the
3357 reading.
3358
3359 Since v5.8.0, Perl has built using PerlIO by default.  Unless you've
3360 changed this (i.e., Configure -Uuseperlio), you can open filehandles 
3361 directly to Perl scalars via:
3362
3363     open($fh, '>', \$variable) || ..
3364
3365 To (re)open C<STDOUT> or C<STDERR> as an in-memory file, close it first:
3366
3367     close STDOUT;
3368     open STDOUT, '>', \$variable or die "Can't open STDOUT: $!";
3369
3370 General examples:
3371
3372     $ARTICLE = 100;
3373     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
3374     while (<ARTICLE>) {...
3375
3376     open(LOG, '>>/usr/spool/news/twitlog');  # (log is reserved)
3377     # if the open fails, output is discarded
3378
3379     open(my $dbase, '+<', 'dbase.mine')      # open for update
3380         or die "Can't open 'dbase.mine' for update: $!";
3381
3382     open(my $dbase, '+<dbase.mine')          # ditto
3383         or die "Can't open 'dbase.mine' for update: $!";
3384
3385     open(ARTICLE, '-|', "caesar <$article")  # decrypt article
3386         or die "Can't start caesar: $!";
3387
3388     open(ARTICLE, "caesar <$article |")      # ditto
3389         or die "Can't start caesar: $!";
3390
3391     open(EXTRACT, "|sort >Tmp$$")            # $$ is our process id
3392         or die "Can't start sort: $!";
3393
3394     # in-memory files
3395     open(MEMORY,'>', \$var)
3396         or die "Can't open memory file: $!";
3397     print MEMORY "foo!\n";                   # output will appear in $var
3398
3399     # process argument list of files along with any includes
3400
3401     foreach $file (@ARGV) {
3402         process($file, 'fh00');
3403     }
3404
3405     sub process {
3406         my($filename, $input) = @_;
3407         $input++;    # this is a string increment
3408         unless (open($input, $filename)) {
3409             print STDERR "Can't open $filename: $!\n";
3410             return;
3411         }
3412
3413         local $_;
3414         while (<$input>) {    # note use of indirection
3415             if (/^#include "(.*)"/) {
3416                 process($1, $input);
3417                 next;
3418             }
3419             #...          # whatever
3420         }
3421     }
3422
3423 See L<perliol> for detailed info on PerlIO.
3424
3425 You may also, in the Bourne shell tradition, specify an EXPR beginning
3426 with C<< '>&' >>, in which case the rest of the string is interpreted
3427 as the name of a filehandle (or file descriptor, if numeric) to be
3428 duped (as C<dup(2)>) and opened.  You may use C<&> after C<< > >>,
3429 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
3430 The mode you specify should match the mode of the original filehandle.
3431 (Duping a filehandle does not take into account any existing contents
3432 of IO buffers.) If you use the 3-arg form then you can pass either a
3433 number, the name of a filehandle or the normal "reference to a glob".
3434
3435 Here is a script that saves, redirects, and restores C<STDOUT> and
3436 C<STDERR> using various methods:
3437
3438     #!/usr/bin/perl
3439     open my $oldout, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3440     open OLDERR,     ">&", \*STDERR or die "Can't dup STDERR: $!";
3441
3442     open STDOUT, '>', "foo.out" or die "Can't redirect STDOUT: $!";
3443     open STDERR, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3444
3445     select STDERR; $| = 1;  # make unbuffered
3446     select STDOUT; $| = 1;  # make unbuffered
3447
3448     print STDOUT "stdout 1\n";  # this works for
3449     print STDERR "stderr 1\n";  # subprocesses too
3450
3451     open STDOUT, ">&", $oldout or die "Can't dup \$oldout: $!";
3452     open STDERR, ">&OLDERR"    or die "Can't dup OLDERR: $!";
3453
3454     print STDOUT "stdout 2\n";
3455     print STDERR "stderr 2\n";
3456
3457 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
3458 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
3459 that file descriptor (and not call C<dup(2)>); this is more
3460 parsimonious of file descriptors.  For example:
3461
3462     # open for input, reusing the fileno of $fd
3463     open(FILEHANDLE, "<&=$fd")
3464
3465 or
3466
3467     open(FILEHANDLE, "<&=", $fd)
3468
3469 or
3470
3471     # open for append, using the fileno of OLDFH
3472     open(FH, ">>&=", OLDFH)
3473
3474 or
3475
3476     open(FH, ">>&=OLDFH")
3477
3478 Being parsimonious on filehandles is also useful (besides being
3479 parsimonious) for example when something is dependent on file
3480 descriptors, like for example locking using flock().  If you do just
3481 C<< open(A, '>>&B') >>, the filehandle A will not have the same file
3482 descriptor as B, and therefore flock(A) will not flock(B), and vice
3483 versa.  But with C<< open(A, '>>&=B') >> the filehandles will share
3484 the same file descriptor.
3485
3486 Note that if you are using Perls older than 5.8.0, Perl will be using
3487 the standard C libraries' fdopen() to implement the "=" functionality.
3488 On many Unix systems fdopen() fails when file descriptors exceed a
3489 certain value, typically 255.  For Perls 5.8.0 and later, PerlIO is
3490 most often the default.
3491
3492 You can see whether Perl has been compiled with PerlIO or not by
3493 running C<perl -V> and looking for C<useperlio=> line.  If C<useperlio>
3494 is C<define>, you have PerlIO, otherwise you don't.
3495
3496 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
3497 with 2-arguments (or 1-argument) form of open(), then
3498 there is an implicit fork done, and the return value of open is the pid
3499 of the child within the parent process, and C<0> within the child
3500 process.  (Use C<defined($pid)> to determine whether the open was successful.)
3501 The filehandle behaves normally for the parent, but I/O to that
3502 filehandle is piped from/to the STDOUT/STDIN of the child process.
3503 In the child process, the filehandle isn't opened--I/O happens from/to
3504 the new STDOUT/STDIN.  Typically this is used like the normal
3505 piped open when you want to exercise more control over just how the
3506 pipe command gets executed, such as when running setuid and
3507 you don't want to have to scan shell commands for metacharacters.
3508
3509 The following blocks are more or less equivalent:
3510
3511     open(FOO, "|tr '[a-z]' '[A-Z]'");
3512     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
3513     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
3514     open(FOO, '|-', "tr", '[a-z]', '[A-Z]');
3515
3516     open(FOO, "cat -n '$file'|");
3517     open(FOO, '-|', "cat -n '$file'");
3518     open(FOO, '-|') || exec 'cat', '-n', $file;
3519     open(FOO, '-|', "cat", '-n', $file);
3520
3521 The last two examples in each block shows the pipe as "list form", which is
3522 not yet supported on all platforms.  A good rule of thumb is that if
3523 your platform has true C<fork()> (in other words, if your platform is
3524 Unix) you can use the list form.
3525
3526 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
3527
3528 Beginning with v5.6.0, Perl will attempt to flush all files opened for
3529 output before any operation that may do a fork, but this may not be
3530 supported on some platforms (see L<perlport>).  To be safe, you may need
3531 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
3532 of C<IO::Handle> on any open handles.
3533
3534 On systems that support a close-on-exec flag on files, the flag will
3535 be set for the newly opened file descriptor as determined by the value
3536 of $^F.  See L<perlvar/$^F>.
3537
3538 Closing any piped filehandle causes the parent process to wait for the
3539 child to finish, and returns the status value in C<$?> and
3540 C<${^CHILD_ERROR_NATIVE}>.
3541
3542 The filename passed to 2-argument (or 1-argument) form of open() will
3543 have leading and trailing whitespace deleted, and the normal
3544 redirection characters honored.  This property, known as "magic open",
3545 can often be used to good effect.  A user could specify a filename of
3546 F<"rsh cat file |">, or you could change certain filenames as needed:
3547
3548     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
3549     open(FH, $filename) or die "Can't open $filename: $!";
3550
3551 Use 3-argument form to open a file with arbitrary weird characters in it,
3552
3553     open(FOO, '<', $file);
3554
3555 otherwise it's necessary to protect any leading and trailing whitespace:
3556
3557     $file =~ s#^(\s)#./$1#;
3558     open(FOO, "< $file\0");
3559
3560 (this may not work on some bizarre filesystems).  One should
3561 conscientiously choose between the I<magic> and 3-arguments form
3562 of open():
3563
3564     open IN, $ARGV[0];
3565
3566 will allow the user to specify an argument of the form C<"rsh cat file |">,
3567 but will not work on a filename that happens to have a trailing space, while
3568
3569     open IN, '<', $ARGV[0];
3570
3571 will have exactly the opposite restrictions.
3572
3573 If you want a "real" C C<open> (see C<open(2)> on your system), then you
3574 should use the C<sysopen> function, which involves no such magic (but
3575 may use subtly different filemodes than Perl open(), which is mapped
3576 to C fopen()).  This is
3577 another way to protect your filenames from interpretation.  For example:
3578
3579     use IO::Handle;
3580     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
3581         or die "sysopen $path: $!";
3582     $oldfh = select(HANDLE); $| = 1; select($oldfh);
3583     print HANDLE "stuff $$\n";
3584     seek(HANDLE, 0, 0);
3585     print "File contains: ", <HANDLE>;
3586
3587 Using the constructor from the C<IO::Handle> package (or one of its
3588 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3589 filehandles that have the scope of whatever variables hold references to
3590 them, and automatically close whenever and however you leave that scope:
3591
3592     use IO::File;
3593     #...
3594     sub read_myfile_munged {
3595         my $ALL = shift;
3596         my $handle = IO::File->new;
3597         open($handle, "myfile") or die "myfile: $!";
3598         $first = <$handle>
3599             or return ();     # Automatically closed here.
3600         mung $first or die "mung failed";  # Or here.
3601         return $first, <$handle> if $ALL;  # Or here.
3602         $first;          # Or here.
3603     }
3604
3605 See L</seek> for some details about mixing reading and writing.
3606
3607 =item opendir DIRHANDLE,EXPR
3608 X<opendir>
3609
3610 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3611 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3612 DIRHANDLE may be an expression whose value can be used as an indirect
3613 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
3614 scalar variable (or array or hash element), the variable is assigned a
3615 reference to a new anonymous dirhandle.
3616 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3617
3618 See example at C<readdir>.
3619
3620 =item ord EXPR
3621 X<ord> X<encoding>
3622
3623 =item ord
3624
3625 Returns the numeric (the native 8-bit encoding, like ASCII or EBCDIC,
3626 or Unicode) value of the first character of EXPR.  If EXPR is an empty
3627 string, returns 0.  If EXPR is omitted, uses C<$_>.
3628
3629 For the reverse, see L</chr>.
3630 See L<perlunicode> for more about Unicode.
3631
3632 =item our EXPR
3633 X<our> X<global>
3634
3635 =item our TYPE EXPR
3636
3637 =item our EXPR : ATTRS
3638
3639 =item our TYPE EXPR : ATTRS
3640
3641 C<our> associates a simple name with a package variable in the current
3642 package for use within the current scope.  When C<use strict 'vars'> is in
3643 effect, C<our> lets you use declared global variables without qualifying
3644 them with package names, within the lexical scope of the C<our> declaration.
3645 In this way C<our> differs from C<use vars>, which is package scoped.
3646
3647 Unlike C<my>, which both allocates storage for a variable and associates
3648 a simple name with that storage for use within the current scope, C<our>
3649 associates a simple name with a package variable in the current package,
3650 for use within the current scope.  In other words, C<our> has the same
3651 scoping rules as C<my>, but does not necessarily create a
3652 variable.
3653
3654 If more than one value is listed, the list must be placed
3655 in parentheses.
3656
3657     our $foo;
3658     our($bar, $baz);
3659
3660 An C<our> declaration declares a global variable that will be visible
3661 across its entire lexical scope, even across package boundaries.  The
3662 package in which the variable is entered is determined at the point
3663 of the declaration, not at the point of use.  This means the following
3664 behavior holds:
3665
3666     package Foo;
3667     our $bar;      # declares $Foo::bar for rest of lexical scope
3668     $bar = 20;
3669
3670     package Bar;
3671     print $bar;    # prints 20, as it refers to $Foo::bar
3672
3673 Multiple C<our> declarations with the same name in the same lexical
3674 scope are allowed if they are in different packages.  If they happen
3675 to be in the same package, Perl will emit warnings if you have asked
3676 for them, just like multiple C<my> declarations.  Unlike a second
3677 C<my> declaration, which will bind the name to a fresh variable, a
3678 second C<our> declaration in the same package, in the same scope, is
3679 merely redundant.
3680
3681     use warnings;
3682     package Foo;
3683     our $bar;      # declares $Foo::bar for rest of lexical scope
3684     $bar = 20;
3685
3686     package Bar;
3687     our $bar = 30; # declares $Bar::bar for rest of lexical scope
3688     print $bar;    # prints 30
3689
3690     our $bar;      # emits warning but has no other effect
3691     print $bar;    # still prints 30
3692
3693 An C<our> declaration may also have a list of attributes associated
3694 with it.
3695
3696 The exact semantics and interface of TYPE and ATTRS are still
3697 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3698 and attributes are handled using the C<attributes> pragma, or starting
3699 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3700 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3701 L<attributes>, and L<Attribute::Handlers>.
3702
3703 =item pack TEMPLATE,LIST
3704 X<pack>
3705
3706 Takes a LIST of values and converts it into a string using the rules
3707 given by the TEMPLATE.  The resulting string is the concatenation of
3708 the converted values.  Typically, each converted value looks
3709 like its machine-level representation.  For example, on 32-bit machines
3710 an integer may be represented by a sequence of 4 bytes, which  will in
3711 Perl be presented as a string that's 4 characters long. 
3712
3713 See L<perlpacktut> for an introduction to this function.
3714
3715 The TEMPLATE is a sequence of characters that give the order and type
3716 of values, as follows:
3717
3718     a  A string with arbitrary binary data, will be null padded.
3719     A  A text (ASCII) string, will be space padded.
3720     Z  A null-terminated (ASCIZ) string, will be null padded.
3721
3722     b  A bit string (ascending bit order inside each byte, like vec()).
3723     B  A bit string (descending bit order inside each byte).
3724     h  A hex string (low nybble first).
3725     H  A hex string (high nybble first).
3726
3727     c  A signed char (8-bit) value.
3728     C  An unsigned char (octet) value.
3729     W  An unsigned char value (can be greater than 255).
3730
3731     s  A signed short (16-bit) value.
3732     S  An unsigned short value.
3733
3734     l  A signed long (32-bit) value.
3735     L  An unsigned long value.
3736
3737     q  A signed quad (64-bit) value.
3738     Q  An unsigned quad value.
3739       (Quads are available only if your system supports 64-bit
3740        integer values _and_ if Perl has been compiled to support those.
3741            Raises an exception otherwise.)
3742
3743     i  A signed integer value.
3744     I  A unsigned integer value.
3745       (This 'integer' is _at_least_ 32 bits wide.  Its exact
3746            size depends on what a local C compiler calls 'int'.)
3747
3748     n  An unsigned short (16-bit) in "network" (big-endian) order.
3749     N  An unsigned long (32-bit) in "network" (big-endian) order.
3750     v  An unsigned short (16-bit) in "VAX" (little-endian) order.
3751     V  An unsigned long (32-bit) in "VAX" (little-endian) order.
3752
3753     j   A Perl internal signed integer value (IV).
3754     J   A Perl internal unsigned integer value (UV).
3755
3756     f  A single-precision float in native format.
3757     d  A double-precision float in native format.
3758
3759     F  A Perl internal floating-point value (NV) in native format
3760     D  A float of long-double precision in native format.
3761       (Long doubles are available only if your system supports long
3762        double values _and_ if Perl has been compiled to support those.
3763            Raises an exception otherwise.)
3764
3765     p  A pointer to a null-terminated string.
3766     P  A pointer to a structure (fixed-length string).
3767
3768     u  A uuencoded string.
3769     U  A Unicode character number.  Encodes to a character in character mode
3770         and UTF-8 (or UTF-EBCDIC in EBCDIC platforms) in byte mode.
3771
3772     w  A BER compressed integer (not an ASN.1 BER, see perlpacktut for
3773        details).  Its bytes represent an unsigned integer in base 128,
3774        most significant digit first, with as few digits as possible.  Bit
3775        eight (the high bit) is set on each byte except the last.
3776
3777     x  A null byte (a.k.a ASCII NUL, "\000", chr(0))
3778     X  Back up a byte.
3779     @  Null-fill or truncate to absolute position, counted from the
3780        start of the innermost ()-group.
3781     .  Null-fill or truncate to absolute position specified by the value.
3782     (  Start of a ()-group.
3783
3784 One or more modifiers below may optionally follow certain letters in the
3785 TEMPLATE (the second column lists letters for which the modifier is valid):
3786
3787     !   sSlLiI     Forces native (short, long, int) sizes instead
3788                    of fixed (16-/32-bit) sizes.
3789
3790         xX         Make x and X act as alignment commands.
3791
3792         nNvV       Treat integers as signed instead of unsigned.
3793
3794         @.         Specify position as byte offset in the internal
3795                    representation of the packed string. Efficient but
3796                    dangerous.
3797
3798     >   sSiIlLqQ   Force big-endian byte-order on the type.
3799         jJfFdDpP   (The "big end" touches the construct.)
3800
3801     <   sSiIlLqQ   Force little-endian byte-order on the type.
3802         jJfFdDpP   (The "little end" touches the construct.)
3803
3804 The C<< > >> and C<< < >> modifiers can also be used on C<()> groups 
3805 to force a particular byte-order on all components in that group, 
3806 including all its subgroups.
3807
3808 The following rules apply:
3809
3810 =over 
3811
3812 =item *
3813
3814 Each letter may optionally be followed by a number indicating the repeat
3815 count.  A numeric repeat count may optionally be enclosed in brackets, as
3816 in C<pack("C[80]", @arr)>.  The repeat count gobbles that many values from
3817 the LIST when used with all format types other than C<a>, C<A>, C<Z>, C<b>,
3818 C<B>, C<h>, C<H>, C<@>, C<.>, C<x>, C<X>, and C<P>, where it means
3819 something else, dscribed below.  Supplying a C<*> for the repeat count
3820 instead of a number means to use however many items are left, except for:
3821
3822 =over 
3823
3824 =item * 
3825
3826 C<@>, C<x>, and C<X>, where it is equivalent to C<0>.
3827
3828 =item * 
3829
3830 <.>, where it means relative to the start of the string.
3831
3832 =item * 
3833
3834 C<u>, where it is equivalent to 1 (or 45, which here is equivalent).
3835
3836 =back 
3837
3838 One can replace a numeric repeat count with a template letter enclosed in
3839 brackets to use the packed byte length of the bracketed template for the
3840 repeat count.
3841
3842 For example, the template C<x[L]> skips as many bytes as in a packed long,
3843 and the template C<"$t X[$t] $t"> unpacks twice whatever $t (when
3844 variable-expanded) unpacks.  If the template in brackets contains alignment
3845 commands (such as C<x![d]>), its packed length is calculated as if the
3846 start of the template had the maximal possible alignment.
3847
3848 When used with C<Z>, a C<*> as the repeat count is guaranteed to add a
3849 trailing null byte, so the resulting string is always one byte longer than
3850 the byte length of the item itself.
3851
3852 When used with C<@>, the repeat count represents an offset from the start
3853 of the innermost C<()> group.
3854
3855 When used with C<.>, the repeat count determines the starting position to
3856 calculate the value offset as follows:
3857
3858 =over 
3859
3860 =item *
3861
3862 If the repeat count is C<0>, it's relative to the current position.
3863
3864 =item *
3865
3866 If the repeat count is C<*>, the offset is relative to the start of the
3867 packed string.
3868
3869 =item *
3870
3871 And if it's an integer I<n>, the offset is relative to the start of the
3872 I<n>th innermost C<()> group, or to the start of the string if I<n> is
3873 bigger then the group level.
3874
3875 =back
3876
3877 The repeat count for C<u> is interpreted as the maximal number of bytes
3878 to encode per line of output, with 0, 1 and 2 replaced by 45. The repeat 
3879 count should not be more than 65.
3880
3881 =item *
3882
3883 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
3884 string of length count, padding with nulls or spaces as needed.  When
3885 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
3886 after the first null, and C<a> returns data without any sort of trimming.
3887
3888 If the value to pack is too long, the result is truncated.  If it's too
3889 long and an explicit count is provided, C<Z> packs only C<$count-1> bytes,
3890 followed by a null byte.  Thus C<Z> always packs a trailing null, except
3891 for when the count is 0.
3892
3893 =item *
3894
3895 Likewise, the C<b> and C<B> formats pack a string that's that many bits long.
3896 Each such format generates 1 bit of the result.
3897
3898 Each result bit is based on the least-significant bit of the corresponding
3899 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
3900 and C<"1"> generate bits 0 and 1, as do characters C<"\000"> and C<"\001">.
3901
3902 Starting from the beginning of the input string, each 8-tuple
3903 of characters is converted to 1 character of output.  With format C<b>,
3904 the first character of the 8-tuple determines the least-significant bit of a
3905 character; with format C<B>, it determines the most-significant bit of
3906 a character.
3907
3908 If the length of the input string is not evenly divisible by 8, the
3909 remainder is packed as if the input string were padded by null characters
3910 at the end.  Similarly during unpacking, "extra" bits are ignored.
3911
3912 If the input string is longer than needed, remaining characters are ignored.
3913
3914 A C<*> for the repeat count uses all characters of the input field.  
3915 On unpacking, bits are converted to a string of C<"0">s and C<"1">s.
3916
3917 =item *
3918
3919 The C<h> and C<H> formats pack a string that many nybbles (4-bit groups,
3920 representable as hexadecimal digits, C<"0".."9"> C<"a".."f">) long.
3921
3922 For each such format, pack() generates 4 bits of the result.
3923 With non-alphabetical characters, the result is based on the 4 least-significant
3924 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
3925 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
3926 C<"\000"> and C<"\001">.  For characters C<"a".."f"> and C<"A".."F">, the result
3927 is compatible with the usual hexadecimal digits, so that C<"a"> and
3928 C<"A"> both generate the nybble C<0xa==10>.  Do not use any characters
3929 but these with this format.
3930
3931 Starting from the beginning of the template to pack(), each pair
3932 of characters is converted to 1 character of output.  With format C<h>, the
3933 first character of the pair determines the least-significant nybble of the
3934 output character; with format C<H>, it determines the most-significant
3935 nybble.
3936
3937 If the length of the input string is not even, it behaves as if padded by
3938 a null character at the end.  Similarly, "extra" nybbles are ignored during
3939 unpacking.
3940
3941 If the input string is longer than needed, extra characters are ignored.
3942
3943 A C<*> for the repeat count uses all characters of the input field.  For
3944 unpack(), nybbles are converted to a string of hexadecimal digits.
3945
3946 =item *
3947
3948 The C<p> format packs a pointer to a null-terminated string.  You are
3949 responsible for ensuring that the string is not a temporary value, as that
3950 could potentially get deallocated before you got around to using the packed
3951 result.  The C<P> format packs a pointer to a structure of the size indicated
3952 by the length.  A null pointer is created if the corresponding value for
3953 C<p> or C<P> is C<undef>; similarly with unpack(), where a null pointer
3954 unpacks into C<undef>.
3955
3956 If your system has a strange pointer size--meaning a pointer is neither as
3957 big as an int nor as big as a long--it may not be possible to pack or
3958 unpack pointers in big- or little-endian byte order.  Attempting to do
3959 so raises an exception.
3960
3961 =item *
3962
3963 The C</> template character allows packing and unpacking of a sequence of
3964 items where the packed structure contains a packed item count followed by
3965 the packed items themselves.  This is useful when the structure you're
3966 unpacking has encoded the sizes or repeat counts for some of its fields
3967 within the structure itself as separate fields.
3968
3969 For C<pack>, you write I<length-item>C</>I<sequence-item>, and the
3970 I<length-item> describes how the length value is packed. Formats likely
3971 to be of most use are integer-packing ones like C<n> for Java strings,
3972 C<w> for ASN.1 or SNMP, and C<N> for Sun XDR.
3973
3974 For C<pack>, I<sequence-item> may have a repeat count, in which case
3975 the minimum of that and the number of available items is used as the argument
3976 for I<length-item>. If it has no repeat count or uses a '*', the number
3977 of available items is used.
3978
3979 For C<unpack>, an internal stack of integer arguments unpacked so far is
3980 used. You write C</>I<sequence-item> and the repeat count is obtained by
3981 popping off the last element from the stack. The I<sequence-item> must not
3982 have a repeat count.
3983
3984 If I<sequence-item> refers to a string type (C<"A">, C<"a">, or C<"Z">),
3985 the I<length-item> is the string length, not the number of strings.  With
3986 an explicit repeat count for pack, the packed string is adjusted to that
3987 length.  For example:
3988
3989     unpack("W/a", "\004Gurusamy")           gives ("Guru")
3990     unpack("a3/A A*", "007 Bond  J ")       gives (" Bond", "J")
3991     unpack("a3 x2 /A A*", "007: Bond, J.")  gives ("Bond, J", ".")
3992
3993     pack("n/a* w/a","hello,","world")       gives "\000\006hello,\005world"
3994     pack("a/W2", ord("a") .. ord("z"))      gives "2ab"
3995
3996 The I<length-item> is not returned explicitly from C<unpack>.
3997
3998 Supplying a count to the I<length-item> format letter is only useful with
3999 C<A>, C<a>, or C<Z>.  Packing with a I<length-item> of C<a> or C<Z> may
4000 introduce C<"\000"> characters, which Perl does not regard as legal in
4001 numeric strings.
4002
4003 =item *
4004
4005 The integer types C<s>, C<S>, C<l>, and C<L> may be
4006 followed by a C<!> modifier to specify native shorts or
4007 longs.  As shown in the example above, a bare C<l> means
4008 exactly 32 bits, although the native C<long> as seen by the local C compiler
4009 may be larger.  This is mainly an issue on 64-bit platforms.  You can
4010 see whether using C<!> makes any difference this way:
4011
4012     printf "format s is %d, s! is %d\n", 
4013         length pack("s"), length pack("s!");
4014
4015     printf "format l is %d, l! is %d\n", 
4016         length pack("l"), length pack("l!");
4017
4018
4019 C<i!> and C<I!> are also allowed, but only for completeness' sake:
4020 they are identical to C<i> and C<I>.
4021
4022 The actual sizes (in bytes) of native shorts, ints, longs, and long
4023 longs on the platform where Perl was built are also available from
4024 the command line:
4025
4026     $ perl -V:{short,int,long{,long}}size
4027     shortsize='2';
4028     intsize='4';
4029     longsize='4';
4030     longlongsize='8';
4031
4032 or programmatically via the C<Config> module:
4033
4034        use Config;
4035        print $Config{shortsize},    "\n";
4036        print $Config{intsize},      "\n";
4037        print $Config{longsize},     "\n";
4038        print $Config{longlongsize}, "\n";
4039
4040 C<$Config{longlongsize}> is undefined on systems without 
4041 long long support.
4042
4043 =item *
4044
4045 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J> are
4046 inherently non-portable between processors and operating systems because
4047 they obey native byteorder and endianness.  For example, a 4-byte integer
4048 0x12345678 (305419896 decimal) would be ordered natively (arranged in and
4049 handled by the CPU registers) into bytes as
4050
4051     0x12 0x34 0x56 0x78  # big-endian
4052     0x78 0x56 0x34 0x12  # little-endian
4053
4054 Basically, Intel and VAX CPUs are little-endian, while everybody else,
4055 including Motorola m68k/88k, PPC, Sparc, HP PA, Power, and Cray, are
4056 big-endian.  Alpha and MIPS can be either: Digital/Compaq used/uses them in
4057 little-endian mode, but SGI/Cray uses them in big-endian mode.
4058
4059 The names I<big-endian> and I<little-endian> are comic references to the
4060 egg-eating habits of the little-endian Lilliputians and the big-endian
4061 Blefuscudians from the classic Jonathan Swift satire, I<Gulliver's Travels>.
4062 This entered computer lingo via the paper "On Holy Wars and a Plea for
4063 Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980.
4064
4065 Some systems may have even weirder byte orders such as
4066
4067    0x56 0x78 0x12 0x34
4068    0x34 0x12 0x78 0x56
4069
4070 You can determine your system endianness with this incantation:
4071
4072    printf("%#02x ", $_) for unpack("W*", pack L=>0x12345678); 
4073
4074 The byteorder on the platform where Perl was built is also available
4075 via L<Config>:
4076
4077     use Config;
4078     print "$Config{byteorder}\n";
4079
4080 or from the command line:
4081
4082     $ perl -V:byteorder
4083
4084 Byteorders C<"1234"> and C<"12345678"> are little-endian; C<"4321">
4085 and C<"87654321"> are big-endian.
4086
4087 For portably packed integers, either use the formats C<n>, C<N>, C<v>, 
4088 and C<V> or else use the C<< > >> and C<< < >> modifiers described
4089 immediately below.  See also L<perlport>.
4090
4091 =item *
4092
4093 Starting with Perl 5.9.2, integer and floating-point formats, along with
4094 the C<p> and C<P> formats and C<()> groups, may all be followed by the 
4095 C<< > >> or C<< < >> endianness modifiers to respectively enforce big-
4096 or little-endian byte-order.  These modifiers are especially useful 
4097 given how C<n>, C<N>, C<v> and C<V> don't cover signed integers, 
4098 64-bit integers, or floating-point values.
4099
4100 Here are some concerns to keep in mind when using endianness modifier:
4101
4102 =over
4103
4104 =item * 
4105
4106 Exchanging signed integers between different platforms works only 
4107 when all platforms store them in the same format.  Most platforms store
4108 signed integers in two's-complement notation, so usually this is not an issue.
4109
4110 =item * 
4111
4112 The C<< > >> or C<< < >> modifiers can only be used on floating-point
4113 formats on big- or little-endian machines.  Otherwise, attempting to
4114 use them raises an exception.
4115
4116 =item * 
4117
4118 Forcing big- or little-endian byte-order on floating-point values for
4119 data exchange can work only if all platforms use the same
4120 binary representation such as IEEE floating-point.  Even if all
4121 platforms are using IEEE, there may still be subtle differences.  Being able
4122 to use C<< > >> or C<< < >> on floating-point values can be useful,
4123 but also dangerous if you don't know exactly what you're doing.
4124 It is not a general way to portably store floating-point values.
4125
4126 =item * 
4127
4128 When using C<< > >> or C<< < >> on a C<()> group, this affects
4129 all types inside the group that accept byte-order modifiers,
4130 including all subgroups.  It is silently ignored for all other
4131 types.  You are not allowed to override the byte-order within a group
4132 that already has a byte-order modifier suffix.
4133
4134 =back
4135
4136 =item *
4137
4138 Real numbers (floats and doubles) are in native machine format only.
4139 Due to the multiplicity of floating-point formats and the lack of a
4140 standard "network" representation for them, no facility for interchange has been
4141 made.  This means that packed floating-point data written on one machine
4142 may not be readable on another, even if both use IEEE floating-point
4143 arithmetic (because the endianness of the memory representation is not part
4144 of the IEEE spec).  See also L<perlport>.
4145
4146 If you know I<exactly> what you're doing, you can use the C<< > >> or C<< < >>
4147 modifiers to force big- or little-endian byte-order on floating-point values.
4148
4149 Because Perl uses doubles (or long doubles, if configured) internally for
4150 all numeric calculation, converting from double into float and thence 
4151 to double again loses precision, so C<unpack("f", pack("f", $foo)>)
4152 will not in general equal $foo.
4153
4154 =item *
4155
4156 Pack and unpack can operate in two modes: character mode (C<C0> mode) where
4157 the packed string is processed per character, and UTF-8 mode (C<U0> mode)
4158 where the packed string is processed in its UTF-8-encoded Unicode form on
4159 a byte-by-byte basis. Character mode is the default unless the format string 
4160 starts with C<U>. You can always switch mode mid-format with an explicit 
4161 C<C0> or C<U0> in the format.  This mode remains in effect until the next 
4162 mode change, or until the end of the C<()> group it (directly) applies to.
4163
4164 =item *
4165
4166 You must yourself do any alignment or padding by inserting, for example,
4167 enough C<"x">es while packing.  There is no way for pack() and unpack()
4168 to know where characters are going to or coming from, so they 
4169 handle their output and input as flat sequences of characters.
4170
4171 =item *
4172
4173 A C<()> group is a sub-TEMPLATE enclosed in parentheses.  A group may
4174 take a repeat count either as postfix, or for unpack(), also via the C</>
4175 template character.  Within each repetition of a group, positioning with
4176 C<@> starts over at 0. Therefore, the result of
4177
4178     pack("@1A((@2A)@3A)", qw[X Y Z])
4179
4180 is the string C<"\0X\0\0YZ">.
4181
4182 =item *
4183
4184 C<x> and C<X> accept the C<!> modifier to act as alignment commands: they
4185 jump forward or back to the closest position aligned at a multiple of C<count>
4186 characters. For example, to pack() or unpack() a C structure like
4187
4188     struct {
4189         char   c;    /* one signed, 8-bit character */
4190         double d; 
4191         char   cc[2];
4192     }
4193
4194 one may need to use the template C<c x![d] d c[2]>.  This assumes that
4195 doubles must be aligned to the size of double.
4196
4197 For alignment commands, a C<count> of 0 is equivalent to a C<count> of 1;
4198 both are no-ops.
4199
4200 =item *
4201
4202 C<n>, C<N>, C<v> and C<V> accept the C<!> modifier to
4203 represent signed 16-/32-bit integers in big-/little-endian order.
4204 This is portable only when all platforms sharing packed data use the
4205 same binary representation for signed integers; for example, when all
4206 platforms use two's-complement representation.
4207
4208 =item *
4209
4210 Comments can be embedded in a TEMPLATE using C<#> through the end of line.
4211 White space can separate pack codes from each other, but modifiers and
4212 repeat counts must follow immediately.  Breaking complex templates into
4213 individual line-by-line components, suitably annotated, can do as much to
4214 improve legibility and maintainability of pack/unpack formats as C</x> can
4215 for complicated pattern matches.
4216
4217 =item *
4218
4219 If TEMPLATE requires more arguments that pack() is given, pack()
4220 assumes additional C<""> arguments.  If TEMPLATE requires fewer arguments
4221 than given, extra arguments are ignored.
4222
4223 =back
4224
4225 Examples:
4226
4227     $foo = pack("WWWW",65,66,67,68);
4228     # foo eq "ABCD"
4229     $foo = pack("W4",65,66,67,68);
4230     # same thing
4231     $foo = pack("W4",0x24b6,0x24b7,0x24b8,0x24b9);
4232     # same thing with Unicode circled letters.
4233     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
4234     # same thing with Unicode circled letters. You don't get the UTF-8
4235     # bytes because the U at the start of the format caused a switch to
4236     # U0-mode, so the UTF-8 bytes get joined into characters
4237     $foo = pack("C0U4",0x24b6,0x24b7,0x24b8,0x24b9);
4238     # foo eq "\xe2\x92\xb6\xe2\x92\xb7\xe2\x92\xb8\xe2\x92\xb9"
4239     # This is the UTF-8 encoding of the string in the previous example
4240
4241     $foo = pack("ccxxcc",65,66,67,68);
4242     # foo eq "AB\0\0CD"
4243
4244     # NOTE: The examples above featuring "W" and "c" are true
4245     # only on ASCII and ASCII-derived systems such as ISO Latin 1
4246     # and UTF-8.  On EBCDIC systems, the first example would be
4247     #      $foo = pack("WWWW",193,194,195,196);
4248
4249     $foo = pack("s2",1,2);
4250     # "\001\000\002\000" on little-endian
4251     # "\000\001\000\002" on big-endian
4252
4253     $foo = pack("a4","abcd","x","y","z");
4254     # "abcd"
4255
4256     $foo = pack("aaaa","abcd","x","y","z");
4257     # "axyz"
4258
4259     $foo = pack("a14","abcdefg");
4260     # "abcdefg\0\0\0\0\0\0\0"
4261
4262     $foo = pack("i9pl", gmtime);
4263     # a real struct tm (on my system anyway)
4264
4265     $utmp_template = "Z8 Z8 Z16 L";
4266     $utmp = pack($utmp_template, @utmp1);
4267     # a struct utmp (BSDish)
4268
4269     @utmp2 = unpack($utmp_template, $utmp);
4270     # "@utmp1" eq "@utmp2"
4271
4272     sub bintodec {
4273         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
4274     }
4275
4276     $foo = pack('sx2l', 12, 34);
4277     # short 12, two zero bytes padding, long 34
4278     $bar = pack('s@4l', 12, 34);
4279     # short 12, zero fill to position 4, long 34
4280     # $foo eq $bar
4281     $baz = pack('s.l', 12, 4, 34);
4282     # short 12, zero fill to position 4, long 34
4283
4284     $foo = pack('nN', 42, 4711);
4285     # pack big-endian 16- and 32-bit unsigned integers
4286     $foo = pack('S>L>', 42, 4711);
4287     # exactly the same
4288     $foo = pack('s<l<', -42, 4711);
4289     # pack little-endian 16- and 32-bit signed integers
4290     $foo = pack('(sl)<', -42, 4711);
4291     # exactly the same
4292
4293 The same template may generally also be used in unpack().
4294
4295 =item package NAMESPACE VERSION
4296 X<package> X<module> X<namespace> X<version>
4297
4298 =item package NAMESPACE
4299
4300 =item package NAMESPACE VERSION BLOCK
4301 X<package> X<module> X<namespace> X<version>
4302
4303 =item package NAMESPACE BLOCK
4304
4305 Declares the BLOCK, or the rest of the compilation unit, as being in
4306 the given namespace.  The scope of the package declaration is either the
4307 supplied code BLOCK or, in the absence of a BLOCK, from the declaration
4308 itself through the end of the enclosing block, file, or eval (the same
4309 as the C<my> operator).  All unqualified dynamic identifiers in this
4310 scope will be in the given namespace, except where overridden by another
4311 C<package> declaration.
4312
4313 A package statement affects dynamic variables only, including those
4314 you've used C<local> on, but I<not> lexical variables, which are created
4315 with C<my> (or C<our> (or C<state>)).  Typically it would be the first 
4316 declaration in a file included by C<require> or C<use>.  You can switch into a
4317 package in more than one place, since this only determines which default 
4318 symbol table the compiler uses for the rest of that block.  You can refer to
4319 identifiers in other packages than the current one by prefixing the identifier
4320 with the package name and a double colon, as in C<$SomePack::var>
4321 or C<ThatPack::INPUT_HANDLE>.  If package name is omitted, the C<main>
4322 package as assumed.  That is, C<$::sail> is equivalent to
4323 C<$main::sail> (as well as to C<$main'sail>, still seen in ancient
4324 code, mostly from Perl 4).
4325
4326 If VERSION is provided, C<package> sets the C<$VERSION> variable in the given
4327 namespace to a L<version> object with the VERSION provided.  VERSION must be a
4328 "strict" style version number as defined by the L<version> module: a positive
4329 decimal number (integer or decimal-fraction) without exponentiation or else a
4330 dotted-decimal v-string with a leading 'v' character and at least three
4331 components.  You should set C<$VERSION> only once per package.
4332
4333 See L<perlmod/"Packages"> for more information about packages, modules,
4334 and classes.  See L<perlsub> for other scoping issues.
4335
4336 =item pipe READHANDLE,WRITEHANDLE
4337 X<pipe>
4338
4339 Opens a pair of connected pipes like the corresponding system call.
4340 Note that if you set up a loop of piped processes, deadlock can occur
4341 unless you are very careful.  In addition, note that Perl's pipes use
4342 IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE
4343 after each command, depending on the application.
4344
4345 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
4346 for examples of such things.
4347
4348 On systems that support a close-on-exec flag on files, that flag is set
4349 on all newly opened file descriptors whose C<fileno>s are I<higher> than 
4350 the current value of $^F (by default 2 for C<STDERR>).  See L<perlvar/$^F>.
4351
4352 =item pop ARRAY (or ARRAYREF)
4353 X<pop> X<stack>
4354
4355 =item pop
4356
4357 Pops and returns the last value of the array, shortening the array by
4358 one element.
4359
4360 Returns the undefined value if the array is empty, although this may also
4361 happen at other times.  If ARRAY is omitted, pops the C<@ARGV> array in the
4362 main program, but the C<@_> array in subroutines, just like C<shift>.
4363
4364 If given a reference to an array, the argument will be dereferenced
4365 automatically.
4366
4367 =item pos SCALAR
4368 X<pos> X<match, position>
4369
4370 =item pos
4371
4372 Returns the offset of where the last C<m//g> search left off for the
4373 variable in question (C<$_> is used when the variable is not
4374 specified). Note that 0 is a valid match offset. C<undef> indicates
4375 that the search position is reset (usually due to match failure, but
4376 can also be because no match has yet been run on the scalar).
4377
4378 C<pos> directly accesses the location used by the regexp engine to
4379 store the offset, so assigning to C<pos> will change that offset, and
4380 so will also influence the C<\G> zero-width assertion in regular
4381 expressions. Both of these effects take place for the next match, so
4382 you can't affect the position with C<pos> during the current match,
4383 such as in C<(?{pos() = 5})> or C<s//pos() = 5/e>.
4384
4385 Because a failed C<m//gc> match doesn't reset the offset, the return
4386 from C<pos> won't change either in this case.  See L<perlre> and
4387 L<perlop>.
4388
4389 =item print FILEHANDLE LIST
4390 X<print>
4391
4392 =item print LIST
4393
4394 =item print
4395
4396 Prints a string or a list of strings.  Returns true if successful.
4397 FILEHANDLE may be a scalar variable containing
4398 the name of or a reference to the filehandle, thus introducing
4399 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
4400 the next token is a term, it may be misinterpreted as an operator
4401 unless you interpose a C<+> or put parentheses around the arguments.)
4402 If FILEHANDLE is omitted, prints to standard output by default, or
4403 to the last selected output channel; see L</select>.  If LIST is
4404 also omitted, prints C<$_> to the currently selected output handle.
4405 To set the default output handle to something other than STDOUT
4406 use the select operation.  The current value of C<$,> (if any) is
4407 printed between each LIST item.  The current value of C<$\> (if
4408 any) is printed after the entire LIST has been printed.  Because
4409 print takes a LIST, anything in the LIST is evaluated in list
4410 context, and any subroutine that you call will have one or more of
4411 its expressions evaluated in list context.  Also be careful not to
4412 follow the print keyword with a left parenthesis unless you want
4413 the corresponding right parenthesis to terminate the arguments to
4414 the print; put parentheses around all the arguments 
4415 (or interpose a C<+>, but that doesn't look as good).
4416
4417 Note that if you're storing FILEHANDLEs in an array, or if you're using
4418 any other expression more complex than a scalar variable to retrieve it,
4419 you will have to use a block returning the filehandle value instead:
4420
4421     print { $files[$i] } "stuff\n";
4422     print { $OK ? STDOUT : STDERR } "stuff\n";
4423
4424 Printing to a closed pipe or socket will generate a SIGPIPE signal.  See
4425 L<perlipc> for more on signal handling.
4426
4427 =item printf FILEHANDLE FORMAT, LIST
4428 X<printf>
4429
4430 =item printf FORMAT, LIST
4431
4432 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
4433 (the output record separator) is not appended.  The first argument
4434 of the list will be interpreted as the C<printf> format. See C<sprintf>
4435 for an explanation of the format argument.  If C<use locale> is in effect,
4436 and POSIX::setlocale() has been called, the character used for the decimal
4437 separator in formatted floating-point numbers is affected by the LC_NUMERIC
4438 locale.  See L<perllocale> and L<POSIX>.
4439
4440 Don't fall into the trap of using a C<printf> when a simple
4441 C<print> would do.  The C<print> is more efficient and less
4442 error prone.
4443
4444 =item prototype FUNCTION
4445 X<prototype>
4446
4447 Returns the prototype of a function as a string (or C<undef> if the
4448 function has no prototype).  FUNCTION is a reference to, or the name of,
4449 the function whose prototype you want to retrieve.
4450
4451 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
4452 name for a Perl builtin.  If the builtin is not I<overridable> (such as
4453 C<qw//>) or if its arguments cannot be adequately expressed by a prototype
4454 (such as C<system>), prototype() returns C<undef>, because the builtin
4455 does not really behave like a Perl function.  Otherwise, the string
4456 describing the equivalent prototype is returned.
4457
4458 =item push ARRAY (or ARRAYREF),LIST
4459 X<push> X<stack>
4460
4461 Treats ARRAY as a stack, and pushes the values of LIST
4462 onto the end of ARRAY.  The length of ARRAY increases by the length of
4463 LIST.  Has the same effect as
4464
4465     for $value (LIST) {
4466         $ARRAY[++$#ARRAY] = $value;
4467     }
4468
4469 but is more efficient.  Returns the number of elements in the array following
4470 the completed C<push>.
4471
4472 If given a reference to an array, the argument will be dereferenced
4473 automatically.
4474
4475 =item q/STRING/
4476
4477 =item qq/STRING/
4478
4479 =item qx/STRING/
4480
4481 =item qw/STRING/
4482
4483 Generalized quotes.  See L<perlop/"Quote-Like Operators">.
4484
4485 =item qr/STRING/
4486
4487 Regexp-like quote.  See L<perlop/"Regexp Quote-Like Operators">.
4488
4489 =item quotemeta EXPR
4490 X<quotemeta> X<metacharacter>
4491
4492 =item quotemeta
4493
4494 Returns the value of EXPR with all non-"word"
4495 characters backslashed.  (That is, all characters not matching
4496 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
4497 returned string, regardless of any locale settings.)
4498 This is the internal function implementing
4499 the C<\Q> escape in double-quoted strings.
4500
4501 If EXPR is omitted, uses C<$_>.
4502
4503 quotemeta (and C<\Q> ... C<\E>) are useful when interpolating strings into
4504 regular expressions, because by default an interpolated variable will be
4505 considered a mini-regular expression. For example:
4506
4507     my $sentence = 'The quick brown fox jumped over the lazy dog';
4508     my $substring = 'quick.*?fox';
4509     $sentence =~ s{$substring}{big bad wolf};
4510
4511 Will cause C<$sentence> to become C<'The big bad wolf jumped over...'>.
4512
4513 On the other hand:
4514
4515     my $sentence = 'The quick brown fox jumped over the lazy dog';
4516     my $substring = 'quick.*?fox';
4517     $sentence =~ s{\Q$substring\E}{big bad wolf};
4518
4519 Or:
4520
4521     my $sentence = 'The quick brown fox jumped over the lazy dog';
4522     my $substring = 'quick.*?fox';
4523     my $quoted_substring = quotemeta($substring);
4524     $sentence =~ s{$quoted_substring}{big bad wolf};
4525
4526 Will both leave the sentence as is. Normally, when accepting string input from
4527 the user, quotemeta() or C<\Q> must be used.
4528
4529 =item rand EXPR
4530 X<rand> X<random>
4531
4532 =item rand
4533
4534 Returns a random fractional number greater than or equal to C<0> and less
4535 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
4536 omitted, the value C<1> is used.  Currently EXPR with the value C<0> is
4537 also special-cased as C<1> (this was undocumented before Perl 5.8.0
4538 and is subject to change in future versions of Perl).  Automatically calls
4539 C<srand> unless C<srand> has already been called.  See also C<srand>.
4540
4541 Apply C<int()> to the value returned by C<rand()> if you want random
4542 integers instead of random fractional numbers.  For example,
4543
4544     int(rand(10))
4545
4546 returns a random integer between C<0> and C<9>, inclusive.
4547
4548 (Note: If your rand function consistently returns numbers that are too
4549 large or too small, then your version of Perl was probably compiled
4550 with the wrong number of RANDBITS.)
4551
4552 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
4553 X<read> X<file, read>
4554
4555 =item read FILEHANDLE,SCALAR,LENGTH
4556
4557 Attempts to read LENGTH I<characters> of data into variable SCALAR
4558 from the specified FILEHANDLE.  Returns the number of characters
4559 actually read, C<0> at end of file, or undef if there was an error (in
4560 the latter case C<$!> is also set).  SCALAR will be grown or shrunk 
4561 so that the last character actually read is the last character of the
4562 scalar after the read.
4563
4564 An OFFSET may be specified to place the read data at some place in the
4565 string other than the beginning.  A negative OFFSET specifies
4566 placement at that many characters counting backwards from the end of
4567 the string.  A positive OFFSET greater than the length of SCALAR
4568 results in the string being padded to the required size with C<"\0">
4569 bytes before the result of the read is appended.
4570
4571 The call is implemented in terms of either Perl's or your system's native
4572 fread(3) library function.  To get a true read(2) system call, see C<sysread>.
4573
4574 Note the I<characters>: depending on the status of the filehandle,
4575 either (8-bit) bytes or characters are read.  By default all
4576 filehandles operate on bytes, but for example if the filehandle has
4577 been opened with the C<:utf8> I/O layer (see L</open>, and the C<open>
4578 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4579 characters, not bytes.  Similarly for the C<:encoding> pragma:
4580 in that case pretty much any characters can be read.
4581
4582 =item readdir DIRHANDLE
4583 X<readdir>
4584
4585 Returns the next directory entry for a directory opened by C<opendir>.
4586 If used in list context, returns all the rest of the entries in the
4587 directory.  If there are no more entries, returns the undefined value in
4588 scalar context and the empty list in list context.
4589
4590 If you're planning to filetest the return values out of a C<readdir>, you'd
4591 better prepend the directory in question.  Otherwise, because we didn't
4592 C<chdir> there, it would have been testing the wrong file.
4593
4594     opendir(my $dh, $some_dir) || die "can't opendir $some_dir: $!";
4595     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir($dh);
4596     closedir $dh;
4597
4598 As of Perl 5.11.2 you can use a bare C<readdir> in a C<while> loop,
4599 which will set C<$_> on every iteration.
4600
4601     opendir(my $dh, $some_dir) || die;
4602     while(readdir $dh) {
4603         print "$some_dir/$_\n";
4604     }
4605     closedir $dh;
4606
4607 =item readline EXPR
4608
4609 =item readline
4610 X<readline> X<gets> X<fgets>
4611
4612 Reads from the filehandle whose typeglob is contained in EXPR (or from
4613 *ARGV if EXPR is not provided).  In scalar context, each call reads and
4614 returns the next line until end-of-file is reached, whereupon the
4615 subsequent call returns C<undef>.  In list context, reads until end-of-file
4616 is reached and returns a list of lines.  Note that the notion of "line"
4617 used here is whatever you may have defined with C<$/> or
4618 C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
4619
4620 When C<$/> is set to C<undef>, when C<readline> is in scalar
4621 context (i.e., file slurp mode), and when an empty file is read, it
4622 returns C<''> the first time, followed by C<undef> subsequently.
4623
4624 This is the internal function implementing the C<< <EXPR> >>
4625 operator, but you can use it directly.  The C<< <EXPR> >>
4626 operator is discussed in more detail in L<perlop/"I/O Operators">.
4627
4628     $line = <STDIN>;
4629     $line = readline(*STDIN);    # same thing
4630
4631 If C<readline> encounters an operating system error, C<$!> will be set
4632 with the corresponding error message.  It can be helpful to check
4633 C<$!> when you are reading from filehandles you don't trust, such as a
4634 tty or a socket.  The following example uses the operator form of
4635 C<readline> and dies if the result is not defined.
4636
4637     while ( ! eof($fh) ) {
4638         defined( $_ = <$fh> ) or die "readline failed: $!";
4639         ...
4640     }
4641
4642 Note that you have can't handle C<readline> errors that way with the
4643 C<ARGV> filehandle. In that case, you have to open each element of
4644 C<@ARGV> yourself since C<eof> handles C<ARGV> differently.
4645
4646     foreach my $arg (@ARGV) {
4647         open(my $fh, $arg) or warn "Can't open $arg: $!";
4648
4649         while ( ! eof($fh) ) {