This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
OS X clock_gettime() and clock_getres() emulation
[perl5.git] / dist / Time-HiRes / Makefile.PL
1 #!/usr/bin/perl
2 #
3 # In general we trust %Config, but for nanosleep() this trust
4 # may be misplaced (it may be linkable but not really functional).
5 # Use $ENV{FORCE_NANOSLEEP_SCAN} to force rescanning whether there
6 # really is hope.
7
8 { use 5.006; }
9
10 use Config;
11 use ExtUtils::MakeMaker;
12 use strict;
13
14 my $VERBOSE = $ENV{VERBOSE};
15 my $DEFINE;
16 my $LIBS = [];
17 my $XSOPT = '';
18 my $SYSCALL_H;
19
20 our $self; # Used in 'sourcing' the hints.
21
22 # TBD: Can we just use $Config(exe_ext) here instead of this complex
23 #      expression?
24 my $ld_exeext = ($^O eq 'cygwin' ||
25                  $^O eq 'os2' && $Config{ldflags} =~ /-Zexe\b/) ? '.exe' :
26                 (($^O eq 'vos') ? $Config{exe_ext} : '');
27
28 unless($ENV{PERL_CORE}) {
29     $ENV{PERL_CORE} = 1 if grep { $_ eq 'PERL_CORE=1' } @ARGV;
30 }
31
32 # Perls 5.002 and 5.003 did not have File::Spec, fake what we need.
33
34 sub my_dirsep {
35     $^O eq 'VMS' ? '.' :
36         $^O =~ /mswin32|netware|djgpp/i ? '\\' :
37             $^O eq 'MacOS' ? ':'
38                 : '/';
39 }
40
41 sub my_catdir {
42     shift;
43     my $catdir = join(my_dirsep, @_);
44     $^O eq 'VMS' ? "[$catdir]" : $catdir;
45 }
46
47 sub my_catfile {
48     shift;
49     return join(my_dirsep, @_) unless $^O eq 'VMS';
50     my $file = pop;
51     return my_catdir (undef, @_) . $file;
52 }
53
54 sub my_updir {
55     shift;
56     $^O eq 'VMS' ? "-" : "..";
57 }
58
59 BEGIN {
60     eval { require File::Spec };
61     if ($@) {
62         *File::Spec::catdir  = \&my_catdir;
63         *File::Spec::updir   = \&my_updir;
64         *File::Spec::catfile = \&my_catfile;
65     }
66 }
67
68 # Avoid 'used only once' warnings.
69 my $nop1 = *File::Spec::catdir;
70 my $nop2 = *File::Spec::updir;
71 my $nop3 = *File::Spec::catfile;
72
73 # if you have 5.004_03 (and some slightly older versions?), xsubpp
74 # tries to generate line numbers in the C code generated from the .xs.
75 # unfortunately, it is a little buggy around #ifdef'd code.
76 # my choice is leave it in and have people with old perls complain
77 # about the "Usage" bug, or leave it out and be unable to compile myself
78 # without changing it, and then I'd always forget to change it before a
79 # release. Sorry, Edward :)
80
81 sub try_compile_and_link {
82     my ($c, %args) = @_;
83
84     my ($ok) = 0;
85     my ($tmp) = "tmp$$";
86     local(*TMPC);
87
88     my $obj_ext = $Config{obj_ext} || ".o";
89     unlink("$tmp.c", "$tmp$obj_ext");
90
91     if (open(TMPC, ">$tmp.c")) {
92         print TMPC $c;
93         close(TMPC);
94
95         my $cccmd = $args{cccmd};
96
97         my $errornull;
98
99         my $COREincdir;
100
101         if ($ENV{PERL_CORE}) {
102             my $updir = File::Spec->updir;
103             $COREincdir = File::Spec->catdir(($updir) x 2);
104         } else {
105             $COREincdir = File::Spec->catdir($Config{'archlibexp'}, 'CORE');
106         }
107
108         if ($ENV{PERL_CORE}) {
109             unless (-f File::Spec->catfile($COREincdir, "EXTERN.h")) {
110                 die <<__EOD__;
111 Your environment variable PERL_CORE is '$ENV{PERL_CORE}' but there
112 is no EXTERN.h in $COREincdir.
113 Cannot continue, aborting.
114 __EOD__
115             }
116         }
117
118         my $ccflags = $Config{'ccflags'} . ' ' . "-I$COREincdir"
119          . ' -DPERL_NO_INLINE_FUNCTIONS';
120
121         if ($^O eq 'VMS') {
122             $cccmd = "$Config{'cc'} /include=($COREincdir) $tmp.c";
123         }
124
125         if ($args{silent} || !$VERBOSE) {
126             $errornull = "2>/dev/null" unless defined $errornull;
127         } else {
128             $errornull = '';
129         }
130
131         $cccmd = "$Config{'cc'} -o $tmp $ccflags $tmp.c @$LIBS $errornull"
132             unless defined $cccmd;
133
134        if ($^O eq 'VMS') {
135             open( CMDFILE, ">$tmp.com" );
136             print CMDFILE "\$ SET MESSAGE/NOFACILITY/NOSEVERITY/NOIDENT/NOTEXT\n";
137             print CMDFILE "\$ $cccmd\n";
138             print CMDFILE "\$ IF \$SEVERITY .NE. 1 THEN EXIT 44\n"; # escalate
139             close CMDFILE;
140             system("\@ $tmp.com");
141             $ok = $?==0;
142             for ("$tmp.c", "$tmp$obj_ext", "$tmp.com", "$tmp$Config{exe_ext}") {
143                 1 while unlink $_;
144             }
145         }
146         else
147         {
148             my $tmp_exe = "$tmp$ld_exeext";
149             printf "cccmd = $cccmd\n" if $VERBOSE;
150             my $res = system($cccmd);
151             $ok = defined($res) && $res == 0 && -s $tmp_exe && -x _;
152
153             if ( $ok && exists $args{run} && $args{run}) {
154                 my $tmp_exe =
155                     File::Spec->catfile(File::Spec->curdir, $tmp_exe);
156                 my @run = $tmp_exe;
157                 unshift @run, $Config{run} if $Config{run} && -e $Config{run};
158                 printf "Running $tmp_exe..." if $VERBOSE;
159                 if (system(@run) == 0) {
160                     $ok = 1;
161                 } else {
162                     $ok = 0;
163                     my $errno = $? >> 8;
164                     local $! = $errno;
165                     printf <<EOF;
166
167 *** The test run of '$tmp_exe' failed: status $?
168 *** (the status means: errno = $errno or '$!')
169 *** DO NOT PANIC: this just means that *some* functionality will be missing.
170 EOF
171                 }
172             }
173             unlink("$tmp.c", $tmp_exe);
174         }
175     }
176
177     return $ok;
178 }
179
180 my $TIME_HEADERS = <<EOH;
181 #include "EXTERN.h"
182 #include "perl.h"
183 #include "XSUB.h"
184 #ifdef I_SYS_TYPES
185 #   include <sys/types.h>
186 #endif
187 #ifdef I_SYS_TIME
188 #   include <sys/time.h>
189 #endif
190 #ifdef I_SYS_SELECT
191 #   include <sys/select.h>      /* struct timeval might be hidden in here */
192 #endif
193 EOH
194
195 sub has_gettimeofday {
196     # confusing but true (if condition true ==> -DHAS_GETTIMEOFDAY already)
197     return 0 if $Config{d_gettimeod};
198     return 1 if try_compile_and_link(<<EOM);
199 $TIME_HEADERS
200 static int foo()
201 {
202     struct timeval tv;
203     gettimeofday(&tv, 0);
204 }
205 int main(int argc, char** argv)
206 {
207     foo();
208 }
209 EOM
210     return 0;
211 }
212
213 sub has_x {
214     my ($x, %args) = @_;
215
216     return 1 if
217     try_compile_and_link(<<EOM, %args);
218 #include "EXTERN.h"
219 #include "perl.h"
220 #include "XSUB.h"
221
222 #ifdef I_UNISTD
223 #   include <unistd.h>
224 #endif
225
226 #ifdef I_SYS_TYPES
227 #   include <sys/types.h>
228 #endif
229
230 #ifdef I_SYS_TIME
231 #   include <sys/time.h>
232 #endif
233
234 int main(int argc, char** argv)
235 {
236         $x;
237 }
238 EOM
239     return 0;
240 }
241
242 sub has_nanosleep {
243     print "testing... ";
244     return 1 if
245     try_compile_and_link(<<EOM, run => 1);
246 #include <time.h>
247 #include <sys/time.h>
248 #include <stdio.h>
249 #include <stdlib.h>
250 #include <errno.h>
251
252 /* int nanosleep(const struct timespec *rqtp, struct timespec *rmtp); */
253
254 int main(int argc, char** argv) {
255     struct timespec ts1, ts2;
256     int ret;
257     ts1.tv_sec  = 0;
258     ts1.tv_nsec = 750000000;
259     ts2.tv_sec  = 0;
260     ts2.tv_nsec = 0;
261     errno = 0;
262     ret = nanosleep(&ts1, &ts2); /* E.g. in AIX nanosleep() fails and sets errno to ENOSYS. */
263     ret == 0 ? exit(0) : exit(errno ? errno : -1);
264 }
265 EOM
266 }
267
268 sub has_include {
269     my ($inc) = @_;
270     return 1 if
271     try_compile_and_link(<<EOM);
272 #include "EXTERN.h"
273 #include "perl.h"
274 #include "XSUB.h"
275
276 #include <$inc>
277 int main(int argc, char** argv)
278 {
279         return 0;
280 }
281 EOM
282     return 0;
283 }
284
285 sub has_clock_xxx_syscall {
286     my $x = shift;
287     return 0 unless defined $SYSCALL_H;
288     return 1 if
289     try_compile_and_link(<<EOM, run => 1);
290 #include "EXTERN.h"
291 #include "perl.h"
292 #include "XSUB.h"
293 #include <$SYSCALL_H>
294 int main(int argc, char** argv)
295 {
296     struct timespec ts;
297     /* Many Linuxes get ENOSYS even though the syscall exists. */
298     /* All implementations are supposed to support CLOCK_REALTIME. */
299     int ret = syscall(SYS_clock_$x, CLOCK_REALTIME, &ts);
300     ret == 0 ? exit(0) : exit(errno ? errno : -1);
301 }
302 EOM
303 }
304
305 sub has_clock_xxx {
306     my $xxx = shift;
307     return 1 if
308     try_compile_and_link(<<EOM, run => 1);
309 #include "EXTERN.h"
310 #include "perl.h"
311 #include "XSUB.h"
312 int main(int argc, char** argv)
313 {
314     struct timespec ts;
315     int ret = clock_$xxx(CLOCK_REALTIME, &ts); /* Many Linuxes get ENOSYS. */
316     /* All implementations are supposed to support CLOCK_REALTIME. */
317     ret == 0 ? exit(0) : exit(errno ? errno : -1);
318 }
319 EOM
320 }
321
322 sub has_clock {
323     return 1 if
324     try_compile_and_link(<<EOM, run => 1);
325 #include "EXTERN.h"
326 #include "perl.h"
327 #include "XSUB.h"
328 int main(int argc, char** argv)
329 {
330     clock_t tictoc;
331     clock_t ret = clock();
332     ret == (clock_t)-1 ? exit(errno ? errno : -1) : exit(0);
333 }
334 EOM
335 }
336
337 sub has_clock_nanosleep {
338     return 1 if
339     try_compile_and_link(<<EOM, run => 1);
340 #include "EXTERN.h"
341 #include "perl.h"
342 #include "XSUB.h"
343 #include <time.h>
344 int main(int argc, char** argv)
345 {
346     int ret;
347     struct timespec ts1;
348     struct timespec ts2;
349     ts1.tv_sec  = 0;
350     ts1.tv_nsec = 750000000;;
351     ret = clock_nanosleep(CLOCK_MONOTONIC, 0, &ts1, &ts2);
352     ret == 0 ? exit(0) : exit(errno ? errno : -1);
353 }
354 EOM
355 }
356
357 sub DEFINE {
358     my ($def, $val) = @_;
359     my $define = defined $val ? "$def=$val" : $def ;
360     unless ($DEFINE =~ /(?:^| )-D\Q$define\E(?: |$)/) {
361         $DEFINE .= " -D$define";
362     }
363 }
364
365 sub init {
366     my $hints = File::Spec->catfile("hints", "$^O.pl");
367     if (-f $hints) {
368         print "Using hints $hints...\n";
369         local $self;
370         do $hints;
371         if (exists $self->{LIBS}) {
372             $LIBS = $self->{LIBS};
373             print "Extra libraries: @$LIBS...\n";
374         }
375     }
376
377     $DEFINE = '';
378
379     if ($Config{d_syscall}) {
380         print "Have syscall()... looking for syscall.h... ";
381         if (has_include('syscall.h')) {
382             $SYSCALL_H = 'syscall.h';
383         } elsif (has_include('sys/syscall.h')) {
384             $SYSCALL_H = 'sys/syscall.h';
385         }
386     } else {
387         print "No syscall()...\n";
388     }
389
390     if ($Config{d_syscall}) {
391         if (defined $SYSCALL_H) {
392             print "found <$SYSCALL_H>.\n";
393         } else {
394             print "NOT found.\n";
395         }
396     }
397
398     print "Looking for gettimeofday()... ";
399     my $has_gettimeofday;
400     if (exists $Config{d_gettimeod}) {
401         $has_gettimeofday++ if $Config{d_gettimeod};
402     } elsif (has_gettimeofday()) {
403         $DEFINE .= ' -DHAS_GETTIMEOFDAY';
404         $has_gettimeofday++;
405     }
406
407     if ($has_gettimeofday) {
408         print "found.\n";
409     } else {
410         die <<EOD
411 Your operating system does not seem to have the gettimeofday() function.
412 (or, at least, I cannot find it)
413
414 There is no way Time::HiRes is going to work.
415
416 I am awfully sorry but I cannot go further.
417
418 Aborting configuration.
419
420 EOD
421     }
422
423     print "Looking for setitimer()... ";
424     my $has_setitimer;
425     if (exists $Config{d_setitimer}) {
426         $has_setitimer++ if $Config{d_setitimer};
427     } elsif (has_x("setitimer(ITIMER_REAL, 0, 0)")) {
428         $has_setitimer++;
429         $DEFINE .= ' -DHAS_SETITIMER';
430     }
431
432     if ($has_setitimer) {
433         print "found.\n";
434     } else {
435         print "NOT found.\n";
436     }
437
438     print "Looking for getitimer()... ";
439     my $has_getitimer;
440     if (exists $Config{'d_getitimer'}) {
441         $has_getitimer++ if $Config{'d_getitimer'};
442     } elsif (has_x("getitimer(ITIMER_REAL, 0)")) {
443         $has_getitimer++;
444         $DEFINE .= ' -DHAS_GETITIMER';
445     }
446
447     if ($has_getitimer) {
448         print "found.\n";
449     } else {
450         print "NOT found.\n";
451     }
452
453     if ($has_setitimer && $has_getitimer) {
454         print "You have interval timers (both setitimer and getitimer).\n";
455     } else {
456         print "You do not have interval timers.\n";
457     }
458
459     print "Looking for ualarm()... ";
460     my $has_ualarm;
461     if (exists $Config{d_ualarm}) {
462         $has_ualarm++ if $Config{d_ualarm};
463     } elsif (has_x ("ualarm (0, 0)")) {
464         $has_ualarm++;
465         $DEFINE .= ' -DHAS_UALARM';
466     }
467
468     if ($has_ualarm) {
469         print "found.\n";
470     } else {
471         print "NOT found.\n";
472         if ($has_setitimer) {
473             print "But you have setitimer().\n";
474             print "We can make a Time::HiRes::ualarm().\n";
475         }
476     }
477
478     print "Looking for usleep()... ";
479     my $has_usleep;
480     if (exists $Config{d_usleep}) {
481         $has_usleep++ if $Config{d_usleep};
482     } elsif (has_x ("usleep (0)")) {
483         $has_usleep++;
484         $DEFINE .= ' -DHAS_USLEEP';
485     }
486
487     if ($has_usleep) {
488         print "found.\n";
489     } else {
490         print "NOT found.\n";
491         print "Let's see if you have select()... ";
492         if ($Config{'d_select'}) {
493             print "found.\n";
494             print "We can make a Time::HiRes::usleep().\n";
495         } else {
496             print "NOT found.\n";
497             print "You won't have a Time::HiRes::usleep().\n";
498         }
499     }
500
501     print "Looking for nanosleep()... ";
502     my $has_nanosleep;
503     if ($ENV{FORCE_NANOSLEEP_SCAN}) {
504         print "forced scan... ";
505         if (has_nanosleep()) {
506             $has_nanosleep++;
507             $DEFINE .= ' -DTIME_HIRES_NANOSLEEP';
508         }
509     }
510     elsif (exists $Config{d_nanosleep}) {
511         print "believing \$Config{d_nanosleep}... ";
512         if ($Config{d_nanosleep}) {
513             $has_nanosleep++;
514             $DEFINE .= ' -DTIME_HIRES_NANOSLEEP';
515         }
516     } elsif ($^O =~ /^(mpeix)$/) {
517         # MPE/iX falsely finds nanosleep from its libc equivalent.
518         print "skipping because in $^O... ";
519     } else {
520         if (has_nanosleep()) {
521             $has_nanosleep++;
522             $DEFINE .= ' -DTIME_HIRES_NANOSLEEP';
523         }
524     }
525
526     if ($has_nanosleep) {
527         print "found.\n";
528         print "You can mix subsecond sleeps with signals, if you want to.\n";
529         print "(It's still not portable, though.)\n";
530     } else {
531         print "NOT found.\n";
532         my $nt = ($^O eq 'os2' ? '' : 'not');
533         print "You can$nt mix subsecond sleeps with signals.\n";
534         print "(It would not be portable anyway.)\n";
535     }
536
537     print "Looking for clock_gettime()... ";
538     my $has_clock_gettime;
539     my $has_clock_gettime_emulation;
540     if (exists $Config{d_clock_gettime}) {
541         $has_clock_gettime++ if $Config{d_clock_gettime}; # Unlikely...
542     } elsif (has_clock_xxx('gettime')) {
543         $has_clock_gettime++;
544         $DEFINE .= ' -DTIME_HIRES_CLOCK_GETTIME';
545     } elsif (defined $SYSCALL_H && has_clock_xxx_syscall('gettime')) {
546         $has_clock_gettime++;
547         $DEFINE .= ' -DTIME_HIRES_CLOCK_GETTIME -DTIME_HIRES_CLOCK_GETTIME_SYSCALL';
548     } elsif ($^O eq 'darwin') {
549        $has_clock_gettime_emulation++;
550        $has_clock_gettime++;
551        $DEFINE .= ' -DTIME_HIRES_CLOCK_GETTIME';
552     }
553
554     if ($has_clock_gettime) {
555         if ($DEFINE =~ /-DTIME_HIRES_CLOCK_GETTIME_SYSCALL/) {
556             print "found (via syscall).\n";
557         } elsif ($has_clock_gettime_emulation) {
558             print "found (via emulation).\n";
559         } else {
560             print "found.\n";
561         }
562     } else {
563         print "NOT found.\n";
564     }
565
566     print "Looking for clock_getres()... ";
567     my $has_clock_getres;
568     my $has_clock_getres_emulation;
569     if (exists $Config{d_clock_getres}) {
570         $has_clock_getres++ if $Config{d_clock_getres}; # Unlikely...
571     } elsif (has_clock_xxx('getres')) {
572         $has_clock_getres++;
573         $DEFINE .= ' -DTIME_HIRES_CLOCK_GETRES';
574     } elsif (defined $SYSCALL_H && has_clock_xxx_syscall('getres')) {
575         $has_clock_getres++;
576         $DEFINE .= ' -DTIME_HIRES_CLOCK_GETRES -DTIME_HIRES_CLOCK_GETRES_SYSCALL';
577     } elsif ($^O eq 'darwin') {
578        $has_clock_getres_emulation++;
579        $has_clock_getres++;
580        $DEFINE .= ' -DTIME_HIRES_CLOCK_GETRES';
581     }
582
583     if ($has_clock_getres) {
584         if ($DEFINE =~ /-DTIME_HIRES_CLOCK_GETRES_SYSCALL/) {
585             print "found (via syscall).\n";
586         } elsif ($has_clock_getres_emulation) {
587             print "found (via emulation).\n";
588         } else {
589             print "found.\n";
590         }
591     } else {
592         print "NOT found.\n";
593     }
594
595     print "Looking for clock_nanosleep()... ";
596     my $has_clock_nanosleep;
597     if (exists $Config{d_clock_nanosleep}) {
598         $has_clock_nanosleep++ if $Config{d_clock_nanosleep}; # Unlikely...
599     } elsif (has_clock_nanosleep()) {
600         $has_clock_nanosleep++;
601         $DEFINE .= ' -DTIME_HIRES_CLOCK_NANOSLEEP';
602     }
603
604     if ($has_clock_nanosleep) {
605         print "found.\n";
606     } else {
607         print "NOT found.\n";
608     }
609
610     print "Looking for clock()... ";
611     my $has_clock;
612     if (exists $Config{d_clock}) {
613         $has_clock++ if $Config{d_clock}; # Unlikely...
614     } elsif (has_clock()) {
615         $has_clock++;
616         $DEFINE .= ' -DTIME_HIRES_CLOCK';
617     }
618
619     if ($has_clock) {
620         print "found.\n";
621     } else {
622         print "NOT found.\n";
623     }
624
625     print "Looking for stat() subsecond timestamps...\n";
626
627     print "Trying struct stat st_atimespec.tv_nsec...";
628     my $has_stat_st_xtimespec;
629     if (try_compile_and_link(<<EOM)) {
630 $TIME_HEADERS
631 #include <sys/stat.h>
632 int main(int argc, char** argv) {
633     struct stat st;
634     st.st_atimespec.tv_nsec = 0;
635 }
636 EOM
637       $has_stat_st_xtimespec++;
638       DEFINE('TIME_HIRES_STAT', 1);
639     }
640
641     if ($has_stat_st_xtimespec) {
642         print "found.\n";
643     } else {
644         print "NOT found.\n";
645     }
646
647     print "Trying struct stat st_atimensec...";
648     my $has_stat_st_xtimensec;
649     if (try_compile_and_link(<<EOM)) {
650 $TIME_HEADERS
651 #include <sys/stat.h>
652 int main(int argc, char** argv) {
653     struct stat st;
654     st.st_atimensec = 0;
655 }
656 EOM
657       $has_stat_st_xtimensec++;
658       DEFINE('TIME_HIRES_STAT', 2);
659     }
660
661     if ($has_stat_st_xtimensec) {
662         print "found.\n";
663     } else {
664         print "NOT found.\n";
665     }
666
667     print "Trying struct stat st_atime_n...";
668     my $has_stat_st_xtime_n;
669     if (try_compile_and_link(<<EOM)) {
670 $TIME_HEADERS
671 #include <sys/stat.h>
672 int main(int argc, char** argv) {
673     struct stat st;
674     st.st_atime_n = 0;
675 }
676 EOM
677       $has_stat_st_xtime_n++;
678       DEFINE('TIME_HIRES_STAT', 3);
679     }
680
681     if ($has_stat_st_xtime_n) {
682         print "found.\n";
683     } else {
684         print "NOT found.\n";
685     }
686
687     print "Trying struct stat st_atim.tv_nsec...";
688     my $has_stat_st_xtim;
689     if (try_compile_and_link(<<EOM)) {
690 $TIME_HEADERS
691 #include <sys/stat.h>
692 int main(int argc, char** argv) {
693     struct stat st;
694     st.st_atim.tv_nsec = 0;
695 }
696 EOM
697       $has_stat_st_xtim++;
698       DEFINE('TIME_HIRES_STAT', 4);
699     }
700
701     if ($has_stat_st_xtim) {
702         print "found.\n";
703     } else {
704         print "NOT found.\n";
705     }
706
707     print "Trying struct stat st_uatime...";
708     my $has_stat_st_uxtime;
709     if (try_compile_and_link(<<EOM)) {
710 $TIME_HEADERS
711 #include <sys/stat.h>
712 int main(int argc, char** argv) {
713     struct stat st;
714     st.st_uatime = 0;
715 }
716 EOM
717       $has_stat_st_uxtime++;
718       DEFINE('TIME_HIRES_STAT', 5);
719     }
720
721     if ($has_stat_st_uxtime) {
722         print "found.\n";
723     } else {
724         print "NOT found.\n";
725     }
726
727    if ($DEFINE =~ /-DTIME_HIRES_STAT=\d+/) {
728     print "You seem to have stat() subsecond timestamps.\n";
729     print "(Your struct stat has them, but the filesystems must help.)\n";
730    } else {
731     print "You do not seem to have stat subsecond timestamps.\n";
732    }
733
734     my $has_w32api_windows_h;
735
736     if ($^O eq 'cygwin') {
737         print "Looking for <w32api/windows.h>... ";
738         if (has_include('w32api/windows.h')) {
739             $has_w32api_windows_h++;
740             DEFINE('HAS_W32API_WINDOWS_H');
741         }
742         if ($has_w32api_windows_h) {
743             print "found.\n";
744         } else {
745             print "NOT found.\n";
746         }
747     }
748
749     if ($DEFINE) {
750         $DEFINE =~ s/^\s+//;
751         if (open(XDEFINE, ">xdefine")) {
752             print XDEFINE $DEFINE, "\n";
753             close(XDEFINE);
754         }
755     }
756 }
757
758 sub doMakefile {
759     my @makefileopts = ();
760
761     if ($] >= 5.005) {
762         push (@makefileopts,
763             'AUTHOR'    => 'Jarkko Hietaniemi <jhi@iki.fi>',
764             'ABSTRACT_FROM' => 'HiRes.pm',
765         );
766         DEFINE('ATLEASTFIVEOHOHFIVE');
767     }
768
769     push (@makefileopts,
770         'NAME'  => 'Time::HiRes',
771         'VERSION_FROM' => 'HiRes.pm', # finds $VERSION
772         'LIBS'  => $LIBS,   # e.g., '-lm'
773         'DEFINE'        => $DEFINE,     # e.g., '-DHAS_SOMETHING'
774         'XSOPT' => $XSOPT,
775           # Do not even think about 'INC' => '-I/usr/ucbinclude',
776           # Solaris will avenge.
777         'INC'   => '',     # e.g., '-I/usr/include/other'
778         'INSTALLDIRS' => ($] >= 5.008 && $] < 5.011 ? 'perl' : 'site'),
779         'PREREQ_PM' => {
780             'Carp' => 0,
781             'Config' => 0,
782             'DynaLoader' => 0,
783             'Exporter' => 0,
784             'ExtUtils::MakeMaker' => 0,
785             'Test::More' => "0.82",
786             'strict' => 0,
787         },
788         'dist'      => {
789             'CI'       => 'ci -l',
790             'COMPRESS' => 'gzip -9f',
791             'SUFFIX'   => 'gz',
792         },
793         clean => { FILES => "xdefine" },
794         realclean => { FILES=> 'const-c.inc const-xs.inc' },
795     );
796
797     if ($^O eq "MSWin32" && !(grep { /\ALD[A-Z]*=/ } @ARGV)) {
798         my $libperl = $Config{libperl} || "";
799         my $gccversion = $Config{gccversion} || "";
800         if ($gccversion =~ /\A3\.4\.[0-9]+/ and $libperl =~ /\.lib\z/) {
801             # Avoid broken linkage with ActivePerl, by linking directly
802             # against the Perl DLL rather than the import library.
803             (my $llibperl = "-l$libperl") =~ s/\.lib\z//;
804             my $lddlflags = $Config{lddlflags} || "";
805             my $ldflags = $Config{ldflags} || "";
806             s/-L(?:".*?"|\S+)//g foreach $lddlflags, $ldflags;
807             my $libdirs = join ' ',
808                 map { s/(?<!\\)((?:\\\\)*")/\\$1/g; qq[-L"$_"] }
809                 @Config{qw/bin sitebin/};
810             push @makefileopts, macro => {
811                 LDDLFLAGS => "$lddlflags $libdirs $llibperl",
812                 LDFLAGS => "$ldflags $libdirs $llibperl",
813                 PERL_ARCHIVE => "",
814             };
815         }
816     }
817
818     if ($ENV{PERL_CORE}) {
819         push @makefileopts, MAN3PODS => {};
820     }
821
822     if ($ExtUtils::MakeMaker::VERSION >= 6.48) {
823         push @makefileopts, (MIN_PERL_VERSION => '5.008',);
824     }
825
826     if ($ExtUtils::MakeMaker::VERSION >= 6.31) {
827         push @makefileopts, (LICENSE => 'perl_5');
828     }
829
830     WriteMakefile(@makefileopts);
831 }
832
833 sub doConstants {
834     if (eval {require ExtUtils::Constant; 1}) {
835         my @names = qw(
836                        CLOCKS_PER_SEC
837                        CLOCK_BOOTTIME
838                        CLOCK_HIGHRES
839                        CLOCK_MONOTONIC
840                        CLOCK_MONOTONIC_COARSE
841                        CLOCK_MONOTONIC_PRECISE
842                        CLOCK_MONOTONIC_RAW
843                        CLOCK_PROCESS_CPUTIME_ID
844                        CLOCK_REALTIME
845                        CLOCK_REALTIME_COARSE
846                        CLOCK_REALTIME_FAST
847                        CLOCK_REALTIME_PRECISE
848                        CLOCK_SECOND
849                        CLOCK_SOFTTIME
850                        CLOCK_THREAD_CPUTIME_ID
851                        CLOCK_TIMEOFDAY
852                        CLOCK_UPTIME
853                        CLOCK_UPTIME_FAST
854                        CLOCK_UPTIME_PRECISE
855                        ITIMER_PROF
856                        ITIMER_REAL
857                        ITIMER_REALPROF
858                        ITIMER_VIRTUAL
859                        TIMER_ABSTIME
860                       );
861         foreach (qw (d_usleep d_ualarm d_gettimeofday d_getitimer d_setitimer
862                      d_nanosleep d_clock_gettime d_clock_getres
863                      d_clock d_clock_nanosleep d_hires_stat)) {
864             my $macro = $_;
865             if ($macro =~ /^(d_nanosleep|d_clock|d_clock_nanosleep)$/) {
866                 $macro =~ s/^d_(.+)/TIME_HIRES_\U$1/;
867             } elsif ($macro =~ /^(d_hires_stat)$/) {
868                 my $d_hires_stat = 0;
869                 $d_hires_stat = $1 if ($DEFINE =~ /-DTIME_HIRES_STAT=(\d+)/);
870                 push @names, {name => $_, macro => "TIME_HIRES_STAT", value => $d_hires_stat,
871                               default => ["IV", "0"]};
872                 next;
873             } elsif ($macro =~ /^(d_clock_gettime|d_clock_getres)$/) {
874                 $macro =~ s/^d_(.+)/TIME_HIRES_\U$1/;
875                 my $val = ($DEFINE =~ /-D$macro\b/) ? 1 : 0;
876                 push @names, {name => $_, macro => $macro, value => $val,
877                               default => ["IV", "0"]};
878                 next;
879             } else {
880                 $macro =~ s/^d_(.+)/HAS_\U$1/;
881             }
882             push @names, {name => $_, macro => $macro, value => 1,
883                           default => ["IV", "0"]};
884         }
885         ExtUtils::Constant::WriteConstants(
886                                            NAME => 'Time::HiRes',
887                                            NAMES => \@names,
888                                           );
889     } else {
890         my $file;
891         foreach $file ('const-c.inc', 'const-xs.inc') {
892             my $fallback = File::Spec->catfile('fallback', $file);
893             local $/;
894             open IN, "<$fallback" or die "Can't open $fallback: $!";
895             open OUT, ">$file" or die "Can't open $file: $!";
896             print OUT <IN> or die $!;
897             close OUT or die "Can't close $file: $!";
898             close IN or die "Can't close $fallback: $!";
899         }
900     }
901 }
902
903 sub main {
904     if (-f "xdefine" && !(@ARGV  && $ARGV[0] eq '--configure')) {
905         print qq[$0: The "xdefine" exists, skipping the configure step.\n];
906         print qq[("$^X $0 --configure" to force the configure step)\n];
907     } else {
908         print "Configuring Time::HiRes...\n";
909         1 while unlink("define");
910         if ($^O =~ /Win32/i) {
911             DEFINE('SELECT_IS_BROKEN');
912             $LIBS = [];
913             print "System is $^O, skipping full configure...\n";
914             open(XDEFINE, ">xdefine") or die "$0: Cannot create xdefine: $!\n";
915             close(XDEFINE);
916         } else {
917             init();
918         }
919         doMakefile;
920         doConstants;
921     }
922     my $make = $Config{'make'} || "make";
923     unless (exists $ENV{PERL_CORE} && $ENV{PERL_CORE}) {
924         print  <<EOM;
925 Now you may issue '$make'.  Do not forget also '$make test'.
926 EOM
927        if ($] == 5.008 &&
928            ((exists $ENV{LC_ALL}   && $ENV{LC_ALL}   =~ /utf-?8/i) ||
929             (exists $ENV{LC_CTYPE} && $ENV{LC_CTYPE} =~ /utf-?8/i) ||
930             (exists $ENV{LANG}     && $ENV{LANG}     =~ /utf-?8/i))) {
931             print <<EOM;
932
933 NOTE: if you get an error like this (the Makefile line number may vary):
934 Makefile:91: *** missing separator
935 then set the environment variable LC_ALL to "C" and retry
936 from scratch (re-run perl "Makefile.PL").
937 (And consider upgrading your Perl to, say, at least Perl 5.8.8.)
938 (You got this message because you seem to have
939  an UTF-8 locale active in your shell environment, this used
940  to cause broken Makefiles to be created from Makefile.PLs)
941 EOM
942         }
943     }
944 }
945
946 &main;
947
948 # EOF