This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
[perl #112522] Mildly incorrect wording in "perldoc perlre"
[perl5.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.
9
10 If you haven't used regular expressions before, a quick-start
11 introduction is available in L<perlrequick>, and a longer tutorial
12 introduction is available in L<perlretut>.
13
14 For reference on how regular expressions are used in matching
15 operations, plus various examples of the same, see discussions of
16 C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
17 Operators">.
18
19
20 =head2 Modifiers
21
22 Matching operations can have various modifiers.  Modifiers
23 that relate to the interpretation of the regular expression inside
24 are listed below.  Modifiers that alter the way a regular expression
25 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
26 L<perlop/"Gory details of parsing quoted constructs">.
27
28 =over 4
29
30 =item m
31 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
32
33 Treat string as multiple lines.  That is, change "^" and "$" from matching
34 the start or end of line only at the left and right ends of the string to
35 matching them anywhere within the string.
36
37 =item s
38 X</s> X<regex, single-line> X<regexp, single-line>
39 X<regular expression, single-line>
40
41 Treat string as single line.  That is, change "." to match any character
42 whatsoever, even a newline, which normally it would not match.
43
44 Used together, as C</ms>, they let the "." match any character whatsoever,
45 while still allowing "^" and "$" to match, respectively, just after
46 and just before newlines within the string.
47
48 =item i
49 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
50 X<regular expression, case-insensitive>
51
52 Do case-insensitive pattern matching.
53
54 If locale matching rules are in effect, the case map is taken from the
55 current
56 locale for code points less than 255, and from Unicode rules for larger
57 code points.  However, matches that would cross the Unicode
58 rules/non-Unicode rules boundary (ords 255/256) will not succeed.  See
59 L<perllocale>.
60
61 There are a number of Unicode characters that match multiple characters
62 under C</i>.  For example, C<LATIN SMALL LIGATURE FI>
63 should match the sequence C<fi>.  Perl is not
64 currently able to do this when the multiple characters are in the pattern and
65 are split between groupings, or when one or more are quantified.  Thus
66
67  "\N{LATIN SMALL LIGATURE FI}" =~ /fi/i;          # Matches
68  "\N{LATIN SMALL LIGATURE FI}" =~ /[fi][fi]/i;    # Doesn't match!
69  "\N{LATIN SMALL LIGATURE FI}" =~ /fi*/i;         # Doesn't match!
70
71  # The below doesn't match, and it isn't clear what $1 and $2 would
72  # be even if it did!!
73  "\N{LATIN SMALL LIGATURE FI}" =~ /(f)(i)/i;      # Doesn't match!
74
75 Perl doesn't match multiple characters in an inverted bracketed
76 character class, which otherwise could be highly confusing.  See
77 L<perlrecharclass/Negation>.
78
79 Another bug involves character classes that match both a sequence of
80 multiple characters, and an initial sub-string of that sequence.  For
81 example,
82
83  /[s\xDF]/i
84
85 should match both a single and a double "s", since C<\xDF> (on ASCII
86 platforms) matches "ss".  However, this bug
87 (L<[perl #89774]|https://rt.perl.org/rt3/Ticket/Display.html?id=89774>)
88 causes it to only match a single "s", even if the final larger match
89 fails, and matching the double "ss" would have succeeded.
90
91 Also, Perl matching doesn't fully conform to the current Unicode C</i>
92 recommendations, which ask that the matching be made upon the NFD
93 (Normalization Form Decomposed) of the text.  However, Unicode is
94 in the process of reconsidering and revising their recommendations.
95
96 =item x
97 X</x>
98
99 Extend your pattern's legibility by permitting whitespace and comments.
100 Details in L</"/x">
101
102 =item p
103 X</p> X<regex, preserve> X<regexp, preserve>
104
105 Preserve the string matched such that ${^PREMATCH}, ${^MATCH}, and
106 ${^POSTMATCH} are available for use after matching.
107
108 =item g and c
109 X</g> X</c>
110
111 Global matching, and keep the Current position after failed matching.
112 Unlike i, m, s and x, these two flags affect the way the regex is used
113 rather than the regex itself. See
114 L<perlretut/"Using regular expressions in Perl"> for further explanation
115 of the g and c modifiers.
116
117 =item a, d, l and u
118 X</a> X</d> X</l> X</u>
119
120 These modifiers, all new in 5.14, affect which character-set semantics
121 (Unicode, etc.) are used, as described below in
122 L</Character set modifiers>.
123
124 =back
125
126 Regular expression modifiers are usually written in documentation
127 as e.g., "the C</x> modifier", even though the delimiter
128 in question might not really be a slash.  The modifiers C</imsxadlup>
129 may also be embedded within the regular expression itself using
130 the C<(?...)> construct, see L</Extended Patterns> below.
131
132 =head3 /x
133
134 C</x> tells
135 the regular expression parser to ignore most whitespace that is neither
136 backslashed nor within a character class.  You can use this to break up
137 your regular expression into (slightly) more readable parts.  The C<#>
138 character is also treated as a metacharacter introducing a comment,
139 just as in ordinary Perl code.  This also means that if you want real
140 whitespace or C<#> characters in the pattern (outside a character
141 class, where they are unaffected by C</x>), then you'll either have to
142 escape them (using backslashes or C<\Q...\E>) or encode them using octal,
143 hex, or C<\N{}> escapes.  Taken together, these features go a long way towards
144 making Perl's regular expressions more readable.  Note that you have to
145 be careful not to include the pattern delimiter in the comment--perl has
146 no way of knowing you did not intend to close the pattern early.  See
147 the C-comment deletion code in L<perlop>.  Also note that anything inside
148 a C<\Q...\E> stays unaffected by C</x>.  And note that C</x> doesn't affect
149 space interpretation within a single multi-character construct.  For
150 example in C<\x{...}>, regardless of the C</x> modifier, there can be no
151 spaces.  Same for a L<quantifier|/Quantifiers> such as C<{3}> or
152 C<{5,}>.  Similarly, C<(?:...)> can't have a space between the C<?> and C<:>,
153 but can between the C<(> and C<?>.  Within any delimiters for such a
154 construct, allowed spaces are not affected by C</x>, and depend on the
155 construct.  For example, C<\x{...}> can't have spaces because hexadecimal
156 numbers don't have spaces in them.  But, Unicode properties can have spaces, so
157 in C<\p{...}> there can be spaces that follow the Unicode rules, for which see
158 L<perluniprops/Properties accessible through \p{} and \P{}>.
159 X</x>
160
161 =head3 Character set modifiers
162
163 C</d>, C</u>, C</a>, and C</l>, available starting in 5.14, are called
164 the character set modifiers; they affect the character set semantics
165 used for the regular expression.
166
167 The C</d>, C</u>, and C</l> modifiers are not likely to be of much use
168 to you, and so you need not worry about them very much.  They exist for
169 Perl's internal use, so that complex regular expression data structures
170 can be automatically serialized and later exactly reconstituted,
171 including all their nuances.  But, since Perl can't keep a secret, and
172 there may be rare instances where they are useful, they are documented
173 here.
174
175 The C</a> modifier, on the other hand, may be useful.  Its purpose is to
176 allow code that is to work mostly on ASCII data to not have to concern
177 itself with Unicode.
178
179 Briefly, C</l> sets the character set to that of whatever B<L>ocale is in
180 effect at the time of the execution of the pattern match.
181
182 C</u> sets the character set to B<U>nicode.
183
184 C</a> also sets the character set to Unicode, BUT adds several
185 restrictions for B<A>SCII-safe matching.
186
187 C</d> is the old, problematic, pre-5.14 B<D>efault character set
188 behavior.  Its only use is to force that old behavior.
189
190 At any given time, exactly one of these modifiers is in effect.  Their
191 existence allows Perl to keep the originally compiled behavior of a
192 regular expression, regardless of what rules are in effect when it is
193 actually executed.  And if it is interpolated into a larger regex, the
194 original's rules continue to apply to it, and only it.
195
196 The C</l> and C</u> modifiers are automatically selected for
197 regular expressions compiled within the scope of various pragmas,
198 and we recommend that in general, you use those pragmas instead of
199 specifying these modifiers explicitly.  For one thing, the modifiers
200 affect only pattern matching, and do not extend to even any replacement
201 done, whereas using the pragmas give consistent results for all
202 appropriate operations within their scopes.  For example,
203
204  s/foo/\Ubar/il
205
206 will match "foo" using the locale's rules for case-insensitive matching,
207 but the C</l> does not affect how the C<\U> operates.  Most likely you
208 want both of them to use locale rules.  To do this, instead compile the
209 regular expression within the scope of C<use locale>.  This both
210 implicitly adds the C</l> and applies locale rules to the C<\U>.   The
211 lesson is to C<use locale> and not C</l> explicitly.
212
213 Similarly, it would be better to use C<use feature 'unicode_strings'>
214 instead of,
215
216  s/foo/\Lbar/iu
217
218 to get Unicode rules, as the C<\L> in the former (but not necessarily
219 the latter) would also use Unicode rules.
220
221 More detail on each of the modifiers follows.  Most likely you don't
222 need to know this detail for C</l>, C</u>, and C</d>, and can skip ahead
223 to L<E<sol>a|/E<sol>a (and E<sol>aa)>.
224
225 =head4 /l
226
227 means to use the current locale's rules (see L<perllocale>) when pattern
228 matching.  For example, C<\w> will match the "word" characters of that
229 locale, and C<"/i"> case-insensitive matching will match according to
230 the locale's case folding rules.  The locale used will be the one in
231 effect at the time of execution of the pattern match.  This may not be
232 the same as the compilation-time locale, and can differ from one match
233 to another if there is an intervening call of the
234 L<setlocale() function|perllocale/The setlocale function>.
235
236 Perl only supports single-byte locales.  This means that code points
237 above 255 are treated as Unicode no matter what locale is in effect.
238 Under Unicode rules, there are a few case-insensitive matches that cross
239 the 255/256 boundary.  These are disallowed under C</l>.  For example,
240 0xFF (on ASCII platforms) does not caselessly match the character at
241 0x178, C<LATIN CAPITAL LETTER Y WITH DIAERESIS>, because 0xFF may not be
242 C<LATIN SMALL LETTER Y WITH DIAERESIS> in the current locale, and Perl
243 has no way of knowing if that character even exists in the locale, much
244 less what code point it is.
245
246 This modifier may be specified to be the default by C<use locale>, but
247 see L</Which character set modifier is in effect?>.
248 X</l>
249
250 =head4 /u
251
252 means to use Unicode rules when pattern matching.  On ASCII platforms,
253 this means that the code points between 128 and 255 take on their
254 Latin-1 (ISO-8859-1) meanings (which are the same as Unicode's).
255 (Otherwise Perl considers their meanings to be undefined.)  Thus,
256 under this modifier, the ASCII platform effectively becomes a Unicode
257 platform; and hence, for example, C<\w> will match any of the more than
258 100_000 word characters in Unicode.
259
260 Unlike most locales, which are specific to a language and country pair,
261 Unicode classifies all the characters that are letters I<somewhere> in
262 the world as
263 C<\w>.  For example, your locale might not think that C<LATIN SMALL
264 LETTER ETH> is a letter (unless you happen to speak Icelandic), but
265 Unicode does.  Similarly, all the characters that are decimal digits
266 somewhere in the world will match C<\d>; this is hundreds, not 10,
267 possible matches.  And some of those digits look like some of the 10
268 ASCII digits, but mean a different number, so a human could easily think
269 a number is a different quantity than it really is.  For example,
270 C<BENGALI DIGIT FOUR> (U+09EA) looks very much like an
271 C<ASCII DIGIT EIGHT> (U+0038).  And, C<\d+>, may match strings of digits
272 that are a mixture from different writing systems, creating a security
273 issue.  L<Unicode::UCD/num()> can be used to sort
274 this out.  Or the C</a> modifier can be used to force C<\d> to match
275 just the ASCII 0 through 9.
276
277 Also, under this modifier, case-insensitive matching works on the full
278 set of Unicode
279 characters.  The C<KELVIN SIGN>, for example matches the letters "k" and
280 "K"; and C<LATIN SMALL LIGATURE FF> matches the sequence "ff", which,
281 if you're not prepared, might make it look like a hexadecimal constant,
282 presenting another potential security issue.  See
283 L<http://unicode.org/reports/tr36> for a detailed discussion of Unicode
284 security issues.
285
286 On the EBCDIC platforms that Perl handles, the native character set is
287 equivalent to Latin-1.  Thus this modifier changes behavior only when
288 the C<"/i"> modifier is also specified, and it turns out it affects only
289 two characters, giving them full Unicode semantics: the C<MICRO SIGN>
290 will match the Greek capital and small letters C<MU>, otherwise not; and
291 the C<LATIN CAPITAL LETTER SHARP S> will match any of C<SS>, C<Ss>,
292 C<sS>, and C<ss>, otherwise not.
293
294 This modifier may be specified to be the default by C<use feature
295 'unicode_strings>, C<use locale ':not_characters'>, or
296 C<L<use 5.012|perlfunc/use VERSION>> (or higher),
297 but see L</Which character set modifier is in effect?>.
298 X</u>
299
300 =head4 /d
301
302 This modifier means to use the "Default" native rules of the platform
303 except when there is cause to use Unicode rules instead, as follows:
304
305 =over 4
306
307 =item 1
308
309 the target string is encoded in UTF-8; or
310
311 =item 2
312
313 the pattern is encoded in UTF-8; or
314
315 =item 3
316
317 the pattern explicitly mentions a code point that is above 255 (say by
318 C<\x{100}>); or
319
320 =item 4
321
322 the pattern uses a Unicode name (C<\N{...}>);  or
323
324 =item 5
325
326 the pattern uses a Unicode property (C<\p{...}>)
327
328 =back
329
330 Another mnemonic for this modifier is "Depends", as the rules actually
331 used depend on various things, and as a result you can get unexpected
332 results.  See L<perlunicode/The "Unicode Bug">.  The Unicode Bug has
333 become rather infamous, leading to yet another (printable) name for this
334 modifier, "Dodgy".
335
336 On ASCII platforms, the native rules are ASCII, and on EBCDIC platforms
337 (at least the ones that Perl handles), they are Latin-1.
338
339 Here are some examples of how that works on an ASCII platform:
340
341  $str =  "\xDF";      # $str is not in UTF-8 format.
342  $str =~ /^\w/;       # No match, as $str isn't in UTF-8 format.
343  $str .= "\x{0e0b}";  # Now $str is in UTF-8 format.
344  $str =~ /^\w/;       # Match! $str is now in UTF-8 format.
345  chop $str;
346  $str =~ /^\w/;       # Still a match! $str remains in UTF-8 format.
347
348 This modifier is automatically selected by default when none of the
349 others are, so yet another name for it is "Default".
350
351 Because of the unexpected behaviors associated with this modifier, you
352 probably should only use it to maintain weird backward compatibilities.
353
354 =head4 /a (and /aa)
355
356 This modifier stands for ASCII-restrict (or ASCII-safe).  This modifier,
357 unlike the others, may be doubled-up to increase its effect.
358
359 When it appears singly, it causes the sequences C<\d>, C<\s>, C<\w>, and
360 the Posix character classes to match only in the ASCII range.  They thus
361 revert to their pre-5.6, pre-Unicode meanings.  Under C</a>,  C<\d>
362 always means precisely the digits C<"0"> to C<"9">; C<\s> means the five
363 characters C<[ \f\n\r\t]>; C<\w> means the 63 characters
364 C<[A-Za-z0-9_]>; and likewise, all the Posix classes such as
365 C<[[:print:]]> match only the appropriate ASCII-range characters.
366
367 This modifier is useful for people who only incidentally use Unicode,
368 and who do not wish to be burdened with its complexities and security
369 concerns.
370
371 With C</a>, one can write C<\d> with confidence that it will only match
372 ASCII characters, and should the need arise to match beyond ASCII, you
373 can instead use C<\p{Digit}> (or C<\p{Word}> for C<\w>).  There are
374 similar C<\p{...}> constructs that can match beyond ASCII both white
375 space (see L<perlrecharclass/Whitespace>), and Posix classes (see
376 L<perlrecharclass/POSIX Character Classes>).  Thus, this modifier
377 doesn't mean you can't use Unicode, it means that to get Unicode
378 matching you must explicitly use a construct (C<\p{}>, C<\P{}>) that
379 signals Unicode.
380
381 As you would expect, this modifier causes, for example, C<\D> to mean
382 the same thing as C<[^0-9]>; in fact, all non-ASCII characters match
383 C<\D>, C<\S>, and C<\W>.  C<\b> still means to match at the boundary
384 between C<\w> and C<\W>, using the C</a> definitions of them (similarly
385 for C<\B>).
386
387 Otherwise, C</a> behaves like the C</u> modifier, in that
388 case-insensitive matching uses Unicode semantics; for example, "k" will
389 match the Unicode C<\N{KELVIN SIGN}> under C</i> matching, and code
390 points in the Latin1 range, above ASCII will have Unicode rules when it
391 comes to case-insensitive matching.
392
393 To forbid ASCII/non-ASCII matches (like "k" with C<\N{KELVIN SIGN}>),
394 specify the "a" twice, for example C</aai> or C</aia>.  (The first
395 occurrence of "a" restricts the C<\d>, etc., and the second occurrence
396 adds the C</i> restrictions.)  But, note that code points outside the
397 ASCII range will use Unicode rules for C</i> matching, so the modifier
398 doesn't really restrict things to just ASCII; it just forbids the
399 intermixing of ASCII and non-ASCII.
400
401 To summarize, this modifier provides protection for applications that
402 don't wish to be exposed to all of Unicode.  Specifying it twice
403 gives added protection.
404
405 This modifier may be specified to be the default by C<use re '/a'>
406 or C<use re '/aa'>.  If you do so, you may actually have occasion to use
407 the C</u> modifier explictly if there are a few regular expressions
408 where you do want full Unicode rules (but even here, it's best if
409 everything were under feature C<"unicode_strings">, along with the
410 C<use re '/aa'>).  Also see L</Which character set modifier is in
411 effect?>.
412 X</a>
413 X</aa>
414
415 =head4 Which character set modifier is in effect?
416
417 Which of these modifiers is in effect at any given point in a regular
418 expression depends on a fairly complex set of interactions.  These have
419 been designed so that in general you don't have to worry about it, but
420 this section gives the gory details.  As
421 explained below in L</Extended Patterns> it is possible to explicitly
422 specify modifiers that apply only to portions of a regular expression.
423 The innermost always has priority over any outer ones, and one applying
424 to the whole expression has priority over any of the default settings that are
425 described in the remainder of this section.
426
427 The C<L<use re 'E<sol>foo'|re/"'/flags' mode">> pragma can be used to set
428 default modifiers (including these) for regular expressions compiled
429 within its scope.  This pragma has precedence over the other pragmas
430 listed below that also change the defaults.
431
432 Otherwise, C<L<use locale|perllocale>> sets the default modifier to C</l>;
433 and C<L<use feature 'unicode_strings|feature>>, or
434 C<L<use 5.012|perlfunc/use VERSION>> (or higher) set the default to
435 C</u> when not in the same scope as either C<L<use locale|perllocale>>
436 or C<L<use bytes|bytes>>.
437 (C<L<use locale ':not_characters'|perllocale/Unicode and UTF-8>> also
438 sets the default to C</u>, overriding any plain C<use locale>.)
439 Unlike the mechanisms mentioned above, these
440 affect operations besides regular expressions pattern matching, and so
441 give more consistent results with other operators, including using
442 C<\U>, C<\l>, etc. in substitution replacements.
443
444 If none of the above apply, for backwards compatibility reasons, the
445 C</d> modifier is the one in effect by default.  As this can lead to
446 unexpected results, it is best to specify which other rule set should be
447 used.
448
449 =head4 Character set modifier behavior prior to Perl 5.14
450
451 Prior to 5.14, there were no explicit modifiers, but C</l> was implied
452 for regexes compiled within the scope of C<use locale>, and C</d> was
453 implied otherwise.  However, interpolating a regex into a larger regex
454 would ignore the original compilation in favor of whatever was in effect
455 at the time of the second compilation.  There were a number of
456 inconsistencies (bugs) with the C</d> modifier, where Unicode rules
457 would be used when inappropriate, and vice versa.  C<\p{}> did not imply
458 Unicode rules, and neither did all occurrences of C<\N{}>, until 5.12.
459
460 =head2 Regular Expressions
461
462 =head3 Metacharacters
463
464 The patterns used in Perl pattern matching evolved from those supplied in
465 the Version 8 regex routines.  (The routines are derived
466 (distantly) from Henry Spencer's freely redistributable reimplementation
467 of the V8 routines.)  See L<Version 8 Regular Expressions> for
468 details.
469
470 In particular the following metacharacters have their standard I<egrep>-ish
471 meanings:
472 X<metacharacter>
473 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
474
475
476     \        Quote the next metacharacter
477     ^        Match the beginning of the line
478     .        Match any character (except newline)
479     $        Match the end of the line (or before newline at the end)
480     |        Alternation
481     ()       Grouping
482     []       Bracketed Character class
483
484 By default, the "^" character is guaranteed to match only the
485 beginning of the string, the "$" character only the end (or before the
486 newline at the end), and Perl does certain optimizations with the
487 assumption that the string contains only one line.  Embedded newlines
488 will not be matched by "^" or "$".  You may, however, wish to treat a
489 string as a multi-line buffer, such that the "^" will match after any
490 newline within the string (except if the newline is the last character in
491 the string), and "$" will match before any newline.  At the
492 cost of a little more overhead, you can do this by using the /m modifier
493 on the pattern match operator.  (Older programs did this by setting C<$*>,
494 but this option was removed in perl 5.9.)
495 X<^> X<$> X</m>
496
497 To simplify multi-line substitutions, the "." character never matches a
498 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
499 the string is a single line--even if it isn't.
500 X<.> X</s>
501
502 =head3 Quantifiers
503
504 The following standard quantifiers are recognized:
505 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
506
507     *           Match 0 or more times
508     +           Match 1 or more times
509     ?           Match 1 or 0 times
510     {n}         Match exactly n times
511     {n,}        Match at least n times
512     {n,m}       Match at least n but not more than m times
513
514 (If a curly bracket occurs in any other context and does not form part of
515 a backslashed sequence like C<\x{...}>, it is treated
516 as a regular character.  In particular, the lower quantifier bound
517 is not optional.  However, in Perl v5.18, it is planned to issue a
518 deprecation warning for all such occurrences, and in Perl v5.20 to
519 require literal uses of a curly bracket to be escaped, say by preceding
520 them with a backslash or enclosing them within square brackets, (C<"\{">
521 or C<"[{]">).  This change will allow for future syntax extensions (like
522 making the lower bound of a quantifier optional), and better error
523 checking of quantifiers.  Now, a typo in a quantifier silently causes
524 it to be treated as the literal characters.  For example,
525
526     /o{4,3}/
527
528 looks like a quantifier that matches 0 times, since 4 is greater than 3,
529 but it really means to match the sequence of six characters
530 S<C<"o { 4 , 3 }">>.)
531
532 The "*" quantifier is equivalent to C<{0,}>, the "+"
533 quantifier to C<{1,}>, and the "?" quantifier to C<{0,1}>.  n and m are limited
534 to non-negative integral values less than a preset limit defined when perl is built.
535 This is usually 32766 on the most common platforms.  The actual limit can
536 be seen in the error message generated by code such as this:
537
538     $_ **= $_ , / {$_} / for 2 .. 42;
539
540 By default, a quantified subpattern is "greedy", that is, it will match as
541 many times as possible (given a particular starting location) while still
542 allowing the rest of the pattern to match.  If you want it to match the
543 minimum number of times possible, follow the quantifier with a "?".  Note
544 that the meanings don't change, just the "greediness":
545 X<metacharacter> X<greedy> X<greediness>
546 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
547
548     *?        Match 0 or more times, not greedily
549     +?        Match 1 or more times, not greedily
550     ??        Match 0 or 1 time, not greedily
551     {n}?      Match exactly n times, not greedily (redundant)
552     {n,}?     Match at least n times, not greedily
553     {n,m}?    Match at least n but not more than m times, not greedily
554
555 By default, when a quantified subpattern does not allow the rest of the
556 overall pattern to match, Perl will backtrack. However, this behaviour is
557 sometimes undesirable. Thus Perl provides the "possessive" quantifier form
558 as well.
559
560  *+     Match 0 or more times and give nothing back
561  ++     Match 1 or more times and give nothing back
562  ?+     Match 0 or 1 time and give nothing back
563  {n}+   Match exactly n times and give nothing back (redundant)
564  {n,}+  Match at least n times and give nothing back
565  {n,m}+ Match at least n but not more than m times and give nothing back
566
567 For instance,
568
569    'aaaa' =~ /a++a/
570
571 will never match, as the C<a++> will gobble up all the C<a>'s in the
572 string and won't leave any for the remaining part of the pattern. This
573 feature can be extremely useful to give perl hints about where it
574 shouldn't backtrack. For instance, the typical "match a double-quoted
575 string" problem can be most efficiently performed when written as:
576
577    /"(?:[^"\\]++|\\.)*+"/
578
579 as we know that if the final quote does not match, backtracking will not
580 help. See the independent subexpression
581 L</C<< (?>pattern) >>> for more details;
582 possessive quantifiers are just syntactic sugar for that construct. For
583 instance the above example could also be written as follows:
584
585    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
586
587 =head3 Escape sequences
588
589 Because patterns are processed as double-quoted strings, the following
590 also work:
591
592  \t          tab                   (HT, TAB)
593  \n          newline               (LF, NL)
594  \r          return                (CR)
595  \f          form feed             (FF)
596  \a          alarm (bell)          (BEL)
597  \e          escape (think troff)  (ESC)
598  \cK         control char          (example: VT)
599  \x{}, \x00  character whose ordinal is the given hexadecimal number
600  \N{name}    named Unicode character or character sequence
601  \N{U+263D}  Unicode character     (example: FIRST QUARTER MOON)
602  \o{}, \000  character whose ordinal is the given octal number
603  \l          lowercase next char (think vi)
604  \u          uppercase next char (think vi)
605  \L          lowercase till \E (think vi)
606  \U          uppercase till \E (think vi)
607  \Q          quote (disable) pattern metacharacters till \E
608  \E          end either case modification or quoted section, think vi
609
610 Details are in L<perlop/Quote and Quote-like Operators>.
611
612 =head3 Character Classes and other Special Escapes
613
614 In addition, Perl defines the following:
615 X<\g> X<\k> X<\K> X<backreference>
616
617  Sequence   Note    Description
618   [...]     [1]  Match a character according to the rules of the
619                    bracketed character class defined by the "...".
620                    Example: [a-z] matches "a" or "b" or "c" ... or "z"
621   [[:...:]] [2]  Match a character according to the rules of the POSIX
622                    character class "..." within the outer bracketed
623                    character class.  Example: [[:upper:]] matches any
624                    uppercase character.
625   \w        [3]  Match a "word" character (alphanumeric plus "_", plus
626                    other connector punctuation chars plus Unicode
627                    marks)
628   \W        [3]  Match a non-"word" character
629   \s        [3]  Match a whitespace character
630   \S        [3]  Match a non-whitespace character
631   \d        [3]  Match a decimal digit character
632   \D        [3]  Match a non-digit character
633   \pP       [3]  Match P, named property.  Use \p{Prop} for longer names
634   \PP       [3]  Match non-P
635   \X        [4]  Match Unicode "eXtended grapheme cluster"
636   \C             Match a single C-language char (octet) even if that is
637                    part of a larger UTF-8 character.  Thus it breaks up
638                    characters into their UTF-8 bytes, so you may end up
639                    with malformed pieces of UTF-8.  Unsupported in
640                    lookbehind.
641   \1        [5]  Backreference to a specific capture group or buffer.
642                    '1' may actually be any positive integer.
643   \g1       [5]  Backreference to a specific or previous group,
644   \g{-1}    [5]  The number may be negative indicating a relative
645                    previous group and may optionally be wrapped in
646                    curly brackets for safer parsing.
647   \g{name}  [5]  Named backreference
648   \k<name>  [5]  Named backreference
649   \K        [6]  Keep the stuff left of the \K, don't include it in $&
650   \N        [7]  Any character but \n (experimental).  Not affected by
651                    /s modifier
652   \v        [3]  Vertical whitespace
653   \V        [3]  Not vertical whitespace
654   \h        [3]  Horizontal whitespace
655   \H        [3]  Not horizontal whitespace
656   \R        [4]  Linebreak
657
658 =over 4
659
660 =item [1]
661
662 See L<perlrecharclass/Bracketed Character Classes> for details.
663
664 =item [2]
665
666 See L<perlrecharclass/POSIX Character Classes> for details.
667
668 =item [3]
669
670 See L<perlrecharclass/Backslash sequences> for details.
671
672 =item [4]
673
674 See L<perlrebackslash/Misc> for details.
675
676 =item [5]
677
678 See L</Capture groups> below for details.
679
680 =item [6]
681
682 See L</Extended Patterns> below for details.
683
684 =item [7]
685
686 Note that C<\N> has two meanings.  When of the form C<\N{NAME}>, it matches the
687 character or character sequence whose name is C<NAME>; and similarly
688 when of the form C<\N{U+I<hex>}>, it matches the character whose Unicode
689 code point is I<hex>.  Otherwise it matches any character but C<\n>.
690
691 =back
692
693 =head3 Assertions
694
695 Perl defines the following zero-width assertions:
696 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
697 X<regexp, zero-width assertion>
698 X<regular expression, zero-width assertion>
699 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
700
701     \b  Match a word boundary
702     \B  Match except at a word boundary
703     \A  Match only at beginning of string
704     \Z  Match only at end of string, or before newline at the end
705     \z  Match only at end of string
706     \G  Match only at pos() (e.g. at the end-of-match position
707         of prior m//g)
708
709 A word boundary (C<\b>) is a spot between two characters
710 that has a C<\w> on one side of it and a C<\W> on the other side
711 of it (in either order), counting the imaginary characters off the
712 beginning and end of the string as matching a C<\W>.  (Within
713 character classes C<\b> represents backspace rather than a word
714 boundary, just as it normally does in any double-quoted string.)
715 The C<\A> and C<\Z> are just like "^" and "$", except that they
716 won't match multiple times when the C</m> modifier is used, while
717 "^" and "$" will match at every internal line boundary.  To match
718 the actual end of the string and not ignore an optional trailing
719 newline, use C<\z>.
720 X<\b> X<\A> X<\Z> X<\z> X</m>
721
722 The C<\G> assertion can be used to chain global matches (using
723 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
724 It is also useful when writing C<lex>-like scanners, when you have
725 several patterns that you want to match against consequent substrings
726 of your string; see the previous reference.  The actual location
727 where C<\G> will match can also be influenced by using C<pos()> as
728 an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
729 matches (see L</"Repeated Patterns Matching a Zero-length Substring">)
730 is modified somewhat, in that contents to the left of C<\G> are
731 not counted when determining the length of the match. Thus the following
732 will not match forever:
733 X<\G>
734
735      my $string = 'ABC';
736      pos($string) = 1;
737      while ($string =~ /(.\G)/g) {
738          print $1;
739      }
740
741 It will print 'A' and then terminate, as it considers the match to
742 be zero-width, and thus will not match at the same position twice in a
743 row.
744
745 It is worth noting that C<\G> improperly used can result in an infinite
746 loop. Take care when using patterns that include C<\G> in an alternation.
747
748 =head3 Capture groups
749
750 The bracketing construct C<( ... )> creates capture groups (also referred to as
751 capture buffers). To refer to the current contents of a group later on, within
752 the same pattern, use C<\g1> (or C<\g{1}>) for the first, C<\g2> (or C<\g{2}>)
753 for the second, and so on.
754 This is called a I<backreference>.
755 X<regex, capture buffer> X<regexp, capture buffer>
756 X<regex, capture group> X<regexp, capture group>
757 X<regular expression, capture buffer> X<backreference>
758 X<regular expression, capture group> X<backreference>
759 X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
760 X<named capture buffer> X<regular expression, named capture buffer>
761 X<named capture group> X<regular expression, named capture group>
762 X<%+> X<$+{name}> X<< \k<name> >>
763 There is no limit to the number of captured substrings that you may use.
764 Groups are numbered with the leftmost open parenthesis being number 1, etc.  If
765 a group did not match, the associated backreference won't match either. (This
766 can happen if the group is optional, or in a different branch of an
767 alternation.)
768 You can omit the C<"g">, and write C<"\1">, etc, but there are some issues with
769 this form, described below.
770
771 You can also refer to capture groups relatively, by using a negative number, so
772 that C<\g-1> and C<\g{-1}> both refer to the immediately preceding capture
773 group, and C<\g-2> and C<\g{-2}> both refer to the group before it.  For
774 example:
775
776         /
777          (Y)            # group 1
778          (              # group 2
779             (X)         # group 3
780             \g{-1}      # backref to group 3
781             \g{-3}      # backref to group 1
782          )
783         /x
784
785 would match the same as C</(Y) ( (X) \g3 \g1 )/x>.  This allows you to
786 interpolate regexes into larger regexes and not have to worry about the
787 capture groups being renumbered.
788
789 You can dispense with numbers altogether and create named capture groups.
790 The notation is C<(?E<lt>I<name>E<gt>...)> to declare and C<\g{I<name>}> to
791 reference.  (To be compatible with .Net regular expressions, C<\g{I<name>}> may
792 also be written as C<\k{I<name>}>, C<\kE<lt>I<name>E<gt>> or C<\k'I<name>'>.)
793 I<name> must not begin with a number, nor contain hyphens.
794 When different groups within the same pattern have the same name, any reference
795 to that name assumes the leftmost defined group.  Named groups count in
796 absolute and relative numbering, and so can also be referred to by those
797 numbers.
798 (It's possible to do things with named capture groups that would otherwise
799 require C<(??{})>.)
800
801 Capture group contents are dynamically scoped and available to you outside the
802 pattern until the end of the enclosing block or until the next successful
803 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
804 You can refer to them by absolute number (using C<"$1"> instead of C<"\g1">,
805 etc); or by name via the C<%+> hash, using C<"$+{I<name>}">.
806
807 Braces are required in referring to named capture groups, but are optional for
808 absolute or relative numbered ones.  Braces are safer when creating a regex by
809 concatenating smaller strings.  For example if you have C<qr/$a$b/>, and C<$a>
810 contained C<"\g1">, and C<$b> contained C<"37">, you would get C</\g137/> which
811 is probably not what you intended.
812
813 The C<\g> and C<\k> notations were introduced in Perl 5.10.0.  Prior to that
814 there were no named nor relative numbered capture groups.  Absolute numbered
815 groups were referred to using C<\1>,
816 C<\2>, etc., and this notation is still
817 accepted (and likely always will be).  But it leads to some ambiguities if
818 there are more than 9 capture groups, as C<\10> could mean either the tenth
819 capture group, or the character whose ordinal in octal is 010 (a backspace in
820 ASCII).  Perl resolves this ambiguity by interpreting C<\10> as a backreference
821 only if at least 10 left parentheses have opened before it.  Likewise C<\11> is
822 a backreference only if at least 11 left parentheses have opened before it.
823 And so on.  C<\1> through C<\9> are always interpreted as backreferences.
824 There are several examples below that illustrate these perils.  You can avoid
825 the ambiguity by always using C<\g{}> or C<\g> if you mean capturing groups;
826 and for octal constants always using C<\o{}>, or for C<\077> and below, using 3
827 digits padded with leading zeros, since a leading zero implies an octal
828 constant.
829
830 The C<\I<digit>> notation also works in certain circumstances outside
831 the pattern.  See L</Warning on \1 Instead of $1> below for details.
832
833 Examples:
834
835     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
836
837     /(.)\g1/                        # find first doubled char
838          and print "'$1' is the first doubled character\n";
839
840     /(?<char>.)\k<char>/            # ... a different way
841          and print "'$+{char}' is the first doubled character\n";
842
843     /(?'char'.)\g1/                 # ... mix and match
844          and print "'$1' is the first doubled character\n";
845
846     if (/Time: (..):(..):(..)/) {   # parse out values
847         $hours = $1;
848         $minutes = $2;
849         $seconds = $3;
850     }
851
852     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\g10/   # \g10 is a backreference
853     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\10/    # \10 is octal
854     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\10/  # \10 is a backreference
855     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\010/ # \010 is octal
856
857     $a = '(.)\1';        # Creates problems when concatenated.
858     $b = '(.)\g{1}';     # Avoids the problems.
859     "aa" =~ /${a}/;      # True
860     "aa" =~ /${b}/;      # True
861     "aa0" =~ /${a}0/;    # False!
862     "aa0" =~ /${b}0/;    # True
863     "aa\x08" =~ /${a}0/;  # True!
864     "aa\x08" =~ /${b}0/;  # False
865
866 Several special variables also refer back to portions of the previous
867 match.  C<$+> returns whatever the last bracket match matched.
868 C<$&> returns the entire matched string.  (At one point C<$0> did
869 also, but now it returns the name of the program.)  C<$`> returns
870 everything before the matched string.  C<$'> returns everything
871 after the matched string. And C<$^N> contains whatever was matched by
872 the most-recently closed group (submatch). C<$^N> can be used in
873 extended patterns (see below), for example to assign a submatch to a
874 variable.
875 X<$+> X<$^N> X<$&> X<$`> X<$'>
876
877 These special variables, like the C<%+> hash and the numbered match variables
878 (C<$1>, C<$2>, C<$3>, etc.) are dynamically scoped
879 until the end of the enclosing block or until the next successful
880 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
881 X<$+> X<$^N> X<$&> X<$`> X<$'>
882 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
883
884 B<NOTE>: Failed matches in Perl do not reset the match variables,
885 which makes it easier to write code that tests for a series of more
886 specific cases and remembers the best match.
887
888 B<WARNING>: Once Perl sees that you need one of C<$&>, C<$`>, or
889 C<$'> anywhere in the program, it has to provide them for every
890 pattern match.  This may substantially slow your program.  Perl
891 uses the same mechanism to produce C<$1>, C<$2>, etc, so you also pay a
892 price for each pattern that contains capturing parentheses.  (To
893 avoid this cost while retaining the grouping behaviour, use the
894 extended regular expression C<(?: ... )> instead.)  But if you never
895 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
896 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
897 if you can, but if you can't (and some algorithms really appreciate
898 them), once you've used them once, use them at will, because you've
899 already paid the price.  As of 5.005, C<$&> is not so costly as the
900 other two.
901 X<$&> X<$`> X<$'>
902
903 As a workaround for this problem, Perl 5.10.0 introduces C<${^PREMATCH}>,
904 C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
905 and C<$'>, B<except> that they are only guaranteed to be defined after a
906 successful match that was executed with the C</p> (preserve) modifier.
907 The use of these variables incurs no global performance penalty, unlike
908 their punctuation char equivalents, however at the trade-off that you
909 have to tell perl when you want to use them.
910 X</p> X<p modifier>
911
912 =head2 Quoting metacharacters
913
914 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
915 C<\w>, C<\n>.  Unlike some other regular expression languages, there
916 are no backslashed symbols that aren't alphanumeric.  So anything
917 that looks like \\, \(, \), \<, \>, \{, or \} is always
918 interpreted as a literal character, not a metacharacter.  This was
919 once used in a common idiom to disable or quote the special meanings
920 of regular expression metacharacters in a string that you want to
921 use for a pattern. Simply quote all non-"word" characters:
922
923     $pattern =~ s/(\W)/\\$1/g;
924
925 (If C<use locale> is set, then this depends on the current locale.)
926 Today it is more common to use the quotemeta() function or the C<\Q>
927 metaquoting escape sequence to disable all metacharacters' special
928 meanings like this:
929
930     /$unquoted\Q$quoted\E$unquoted/
931
932 Beware that if you put literal backslashes (those not inside
933 interpolated variables) between C<\Q> and C<\E>, double-quotish
934 backslash interpolation may lead to confusing results.  If you
935 I<need> to use literal backslashes within C<\Q...\E>,
936 consult L<perlop/"Gory details of parsing quoted constructs">.
937
938 C<quotemeta()> and C<\Q> are fully described in L<perlfunc/quotemeta>.
939
940 =head2 Extended Patterns
941
942 Perl also defines a consistent extension syntax for features not
943 found in standard tools like B<awk> and
944 B<lex>.  The syntax for most of these is a
945 pair of parentheses with a question mark as the first thing within
946 the parentheses.  The character after the question mark indicates
947 the extension.
948
949 The stability of these extensions varies widely.  Some have been
950 part of the core language for many years.  Others are experimental
951 and may change without warning or be completely removed.  Check
952 the documentation on an individual feature to verify its current
953 status.
954
955 A question mark was chosen for this and for the minimal-matching
956 construct because 1) question marks are rare in older regular
957 expressions, and 2) whenever you see one, you should stop and
958 "question" exactly what is going on.  That's psychology....
959
960 =over 4
961
962 =item C<(?#text)>
963 X<(?#)>
964
965 A comment.  The text is ignored.  If the C</x> modifier enables
966 whitespace formatting, a simple C<#> will suffice.  Note that Perl closes
967 the comment as soon as it sees a C<)>, so there is no way to put a literal
968 C<)> in the comment.
969
970 =item C<(?adlupimsx-imsx)>
971
972 =item C<(?^alupimsx)>
973 X<(?)> X<(?^)>
974
975 One or more embedded pattern-match modifiers, to be turned on (or
976 turned off, if preceded by C<->) for the remainder of the pattern or
977 the remainder of the enclosing pattern group (if any).
978
979 This is particularly useful for dynamic patterns, such as those read in from a
980 configuration file, taken from an argument, or specified in a table
981 somewhere.  Consider the case where some patterns want to be
982 case-sensitive and some do not:  The case-insensitive ones merely need to
983 include C<(?i)> at the front of the pattern.  For example:
984
985     $pattern = "foobar";
986     if ( /$pattern/i ) { }
987
988     # more flexible:
989
990     $pattern = "(?i)foobar";
991     if ( /$pattern/ ) { }
992
993 These modifiers are restored at the end of the enclosing group. For example,
994
995     ( (?i) blah ) \s+ \g1
996
997 will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
998 repetition of the previous word, assuming the C</x> modifier, and no C</i>
999 modifier outside this group.
1000
1001 These modifiers do not carry over into named subpatterns called in the
1002 enclosing group. In other words, a pattern such as C<((?i)(?&NAME))> does not
1003 change the case-sensitivity of the "NAME" pattern.
1004
1005 Any of these modifiers can be set to apply globally to all regular
1006 expressions compiled within the scope of a C<use re>.  See
1007 L<re/"'/flags' mode">.
1008
1009 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
1010 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Flags (except
1011 C<"d">) may follow the caret to override it.
1012 But a minus sign is not legal with it.
1013
1014 Note that the C<a>, C<d>, C<l>, C<p>, and C<u> modifiers are special in
1015 that they can only be enabled, not disabled, and the C<a>, C<d>, C<l>, and
1016 C<u> modifiers are mutually exclusive: specifying one de-specifies the
1017 others, and a maximum of one (or two C<a>'s) may appear in the
1018 construct.  Thus, for
1019 example, C<(?-p)> will warn when compiled under C<use warnings>;
1020 C<(?-d:...)> and C<(?dl:...)> are fatal errors.
1021
1022 Note also that the C<p> modifier is special in that its presence
1023 anywhere in a pattern has a global effect.
1024
1025 =item C<(?:pattern)>
1026 X<(?:)>
1027
1028 =item C<(?adluimsx-imsx:pattern)>
1029
1030 =item C<(?^aluimsx:pattern)>
1031 X<(?^:)>
1032
1033 This is for clustering, not capturing; it groups subexpressions like
1034 "()", but doesn't make backreferences as "()" does.  So
1035
1036     @fields = split(/\b(?:a|b|c)\b/)
1037
1038 is like
1039
1040     @fields = split(/\b(a|b|c)\b/)
1041
1042 but doesn't spit out extra fields.  It's also cheaper not to capture
1043 characters if you don't need to.
1044
1045 Any letters between C<?> and C<:> act as flags modifiers as with
1046 C<(?adluimsx-imsx)>.  For example,
1047
1048     /(?s-i:more.*than).*million/i
1049
1050 is equivalent to the more verbose
1051
1052     /(?:(?s-i)more.*than).*million/i
1053
1054 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
1055 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Any positive
1056 flags (except C<"d">) may follow the caret, so
1057
1058     (?^x:foo)
1059
1060 is equivalent to
1061
1062     (?x-ims:foo)
1063
1064 The caret tells Perl that this cluster doesn't inherit the flags of any
1065 surrounding pattern, but uses the system defaults (C<d-imsx>),
1066 modified by any flags specified.
1067
1068 The caret allows for simpler stringification of compiled regular
1069 expressions.  These look like
1070
1071     (?^:pattern)
1072
1073 with any non-default flags appearing between the caret and the colon.
1074 A test that looks at such stringification thus doesn't need to have the
1075 system default flags hard-coded in it, just the caret.  If new flags are
1076 added to Perl, the meaning of the caret's expansion will change to include
1077 the default for those flags, so the test will still work, unchanged.
1078
1079 Specifying a negative flag after the caret is an error, as the flag is
1080 redundant.
1081
1082 Mnemonic for C<(?^...)>:  A fresh beginning since the usual use of a caret is
1083 to match at the beginning.
1084
1085 =item C<(?|pattern)>
1086 X<(?|)> X<Branch reset>
1087
1088 This is the "branch reset" pattern, which has the special property
1089 that the capture groups are numbered from the same starting point
1090 in each alternation branch. It is available starting from perl 5.10.0.
1091
1092 Capture groups are numbered from left to right, but inside this
1093 construct the numbering is restarted for each branch.
1094
1095 The numbering within each branch will be as normal, and any groups
1096 following this construct will be numbered as though the construct
1097 contained only one branch, that being the one with the most capture
1098 groups in it.
1099
1100 This construct is useful when you want to capture one of a
1101 number of alternative matches.
1102
1103 Consider the following pattern.  The numbers underneath show in
1104 which group the captured content will be stored.
1105
1106
1107     # before  ---------------branch-reset----------- after        
1108     / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
1109     # 1            2         2  3        2     3     4  
1110
1111 Be careful when using the branch reset pattern in combination with 
1112 named captures. Named captures are implemented as being aliases to 
1113 numbered groups holding the captures, and that interferes with the
1114 implementation of the branch reset pattern. If you are using named
1115 captures in a branch reset pattern, it's best to use the same names,
1116 in the same order, in each of the alternations:
1117
1118    /(?|  (?<a> x ) (?<b> y )
1119       |  (?<a> z ) (?<b> w )) /x
1120
1121 Not doing so may lead to surprises:
1122
1123   "12" =~ /(?| (?<a> \d+ ) | (?<b> \D+))/x;
1124   say $+ {a};   # Prints '12'
1125   say $+ {b};   # *Also* prints '12'.
1126
1127 The problem here is that both the group named C<< a >> and the group
1128 named C<< b >> are aliases for the group belonging to C<< $1 >>.
1129
1130 =item Look-Around Assertions
1131 X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
1132
1133 Look-around assertions are zero-width patterns which match a specific
1134 pattern without including it in C<$&>. Positive assertions match when
1135 their subpattern matches, negative assertions match when their subpattern
1136 fails. Look-behind matches text up to the current match position,
1137 look-ahead matches text following the current match position.
1138
1139 =over 4
1140
1141 =item C<(?=pattern)>
1142 X<(?=)> X<look-ahead, positive> X<lookahead, positive>
1143
1144 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
1145 matches a word followed by a tab, without including the tab in C<$&>.
1146
1147 =item C<(?!pattern)>
1148 X<(?!)> X<look-ahead, negative> X<lookahead, negative>
1149
1150 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
1151 matches any occurrence of "foo" that isn't followed by "bar".  Note
1152 however that look-ahead and look-behind are NOT the same thing.  You cannot
1153 use this for look-behind.
1154
1155 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
1156 will not do what you want.  That's because the C<(?!foo)> is just saying that
1157 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
1158 match.  Use look-behind instead (see below).
1159
1160 =item C<(?<=pattern)> C<\K>
1161 X<(?<=)> X<look-behind, positive> X<lookbehind, positive> X<\K>
1162
1163 A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
1164 matches a word that follows a tab, without including the tab in C<$&>.
1165 Works only for fixed-width look-behind.
1166
1167 There is a special form of this construct, called C<\K>, which causes the
1168 regex engine to "keep" everything it had matched prior to the C<\K> and
1169 not include it in C<$&>. This effectively provides variable-length
1170 look-behind. The use of C<\K> inside of another look-around assertion
1171 is allowed, but the behaviour is currently not well defined.
1172
1173 For various reasons C<\K> may be significantly more efficient than the
1174 equivalent C<< (?<=...) >> construct, and it is especially useful in
1175 situations where you want to efficiently remove something following
1176 something else in a string. For instance
1177
1178   s/(foo)bar/$1/g;
1179
1180 can be rewritten as the much more efficient
1181
1182   s/foo\Kbar//g;
1183
1184 =item C<(?<!pattern)>
1185 X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
1186
1187 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
1188 matches any occurrence of "foo" that does not follow "bar".  Works
1189 only for fixed-width look-behind.
1190
1191 =back
1192
1193 =item C<(?'NAME'pattern)>
1194
1195 =item C<< (?<NAME>pattern) >>
1196 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
1197
1198 A named capture group. Identical in every respect to normal capturing
1199 parentheses C<()> but for the additional fact that the group
1200 can be referred to by name in various regular expression
1201 constructs (like C<\g{NAME}>) and can be accessed by name
1202 after a successful match via C<%+> or C<%->. See L<perlvar>
1203 for more details on the C<%+> and C<%-> hashes.
1204
1205 If multiple distinct capture groups have the same name then the
1206 $+{NAME} will refer to the leftmost defined group in the match.
1207
1208 The forms C<(?'NAME'pattern)> and C<< (?<NAME>pattern) >> are equivalent.
1209
1210 B<NOTE:> While the notation of this construct is the same as the similar
1211 function in .NET regexes, the behavior is not. In Perl the groups are
1212 numbered sequentially regardless of being named or not. Thus in the
1213 pattern
1214
1215   /(x)(?<foo>y)(z)/
1216
1217 $+{foo} will be the same as $2, and $3 will contain 'z' instead of
1218 the opposite which is what a .NET regex hacker might expect.
1219
1220 Currently NAME is restricted to simple identifiers only.
1221 In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
1222 its Unicode extension (see L<utf8>),
1223 though it isn't extended by the locale (see L<perllocale>).
1224
1225 B<NOTE:> In order to make things easier for programmers with experience
1226 with the Python or PCRE regex engines, the pattern C<< (?PE<lt>NAMEE<gt>pattern) >>
1227 may be used instead of C<< (?<NAME>pattern) >>; however this form does not
1228 support the use of single quotes as a delimiter for the name.
1229
1230 =item C<< \k<NAME> >>
1231
1232 =item C<< \k'NAME' >>
1233
1234 Named backreference. Similar to numeric backreferences, except that
1235 the group is designated by name and not number. If multiple groups
1236 have the same name then it refers to the leftmost defined group in
1237 the current match.
1238
1239 It is an error to refer to a name not defined by a C<< (?<NAME>) >>
1240 earlier in the pattern.
1241
1242 Both forms are equivalent.
1243
1244 B<NOTE:> In order to make things easier for programmers with experience
1245 with the Python or PCRE regex engines, the pattern C<< (?P=NAME) >>
1246 may be used instead of C<< \k<NAME> >>.
1247
1248 =item C<(?{ code })>
1249 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
1250
1251 B<WARNING>: This extended regular expression feature is considered
1252 experimental, and may be changed without notice. Code executed that
1253 has side effects may not perform identically from version to version
1254 due to the effect of future optimisations in the regex engine.
1255
1256 This zero-width assertion evaluates any embedded Perl code.  It
1257 always succeeds, and its C<code> is not interpolated.  Currently,
1258 the rules to determine where the C<code> ends are somewhat convoluted.
1259
1260 This feature can be used together with the special variable C<$^N> to
1261 capture the results of submatches in variables without having to keep
1262 track of the number of nested parentheses. For example:
1263
1264   $_ = "The brown fox jumps over the lazy dog";
1265   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
1266   print "color = $color, animal = $animal\n";
1267
1268 Inside the C<(?{...})> block, C<$_> refers to the string the regular
1269 expression is matching against. You can also use C<pos()> to know what is
1270 the current position of matching within this string.
1271
1272 The C<code> is properly scoped in the following sense: If the assertion
1273 is backtracked (compare L<"Backtracking">), all changes introduced after
1274 C<local>ization are undone, so that
1275
1276   $_ = 'a' x 8;
1277   m<
1278      (?{ $cnt = 0 })               # Initialize $cnt.
1279      (
1280        a
1281        (?{
1282            local $cnt = $cnt + 1;  # Update $cnt,
1283                                    # backtracking-safe.
1284        })
1285      )*
1286      aaaa
1287      (?{ $res = $cnt })            # On success copy to
1288                                    # non-localized location.
1289    >x;
1290
1291 will set C<$res = 4>.  Note that after the match, C<$cnt> returns to the globally
1292 introduced value, because the scopes that restrict C<local> operators
1293 are unwound.
1294
1295 This assertion may be used as a C<(?(condition)yes-pattern|no-pattern)>
1296 switch.  If I<not> used in this way, the result of evaluation of
1297 C<code> is put into the special variable C<$^R>.  This happens
1298 immediately, so C<$^R> can be used from other C<(?{ code })> assertions
1299 inside the same regular expression.
1300
1301 The assignment to C<$^R> above is properly localized, so the old
1302 value of C<$^R> is restored if the assertion is backtracked; compare
1303 L<"Backtracking">.
1304
1305 For reasons of security, this construct is forbidden if the regular
1306 expression involves run-time interpolation of variables, unless the
1307 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
1308 variables contain results of the C<qr//> operator (see
1309 L<perlop/"qr/STRINGE<sol>msixpodual">).
1310
1311 This restriction is due to the wide-spread and remarkably convenient
1312 custom of using run-time determined strings as patterns.  For example:
1313
1314     $re = <>;
1315     chomp $re;
1316     $string =~ /$re/;
1317
1318 Before Perl knew how to execute interpolated code within a pattern,
1319 this operation was completely safe from a security point of view,
1320 although it could raise an exception from an illegal pattern.  If
1321 you turn on the C<use re 'eval'>, though, it is no longer secure,
1322 so you should only do so if you are also using taint checking.
1323 Better yet, use the carefully constrained evaluation within a Safe
1324 compartment.  See L<perlsec> for details about both these mechanisms.
1325
1326 B<WARNING>: Use of lexical (C<my>) variables in these blocks is
1327 broken. The result is unpredictable and will make perl unstable. The
1328 workaround is to use global (C<our>) variables.
1329
1330 B<WARNING>: In perl 5.12.x and earlier, the regex engine
1331 was not re-entrant, so interpolated code could not
1332 safely invoke the regex engine either directly with
1333 C<m//> or C<s///>), or indirectly with functions such as
1334 C<split>. Invoking the regex engine in these blocks would make perl
1335 unstable.
1336
1337 =item C<(??{ code })>
1338 X<(??{})>
1339 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
1340
1341 B<WARNING>: This extended regular expression feature is considered
1342 experimental, and may be changed without notice. Code executed that
1343 has side effects may not perform identically from version to version
1344 due to the effect of future optimisations in the regex engine.
1345
1346 This is a "postponed" regular subexpression.  The C<code> is evaluated
1347 at run time, at the moment this subexpression may match.  The result
1348 of evaluation is considered a regular expression and matched as
1349 if it were inserted instead of this construct.  Note that this means
1350 that the contents of capture groups defined inside an eval'ed pattern
1351 are not available outside of the pattern, and vice versa, there is no
1352 way for the inner pattern returned from the code block to refer to a
1353 capture group defined outside.  (The code block itself can use C<$1>, etc.,
1354 to refer to the enclosing pattern's capture groups.)  Thus,
1355
1356     ('a' x 100)=~/(??{'(.)' x 100})/
1357
1358 B<will> match, it will B<not> set $1.
1359
1360 The C<code> is not interpolated.  As before, the rules to determine
1361 where the C<code> ends are currently somewhat convoluted.
1362
1363 The following pattern matches a parenthesized group:
1364
1365  $re = qr{
1366             \(
1367             (?:
1368                (?> [^()]+ )  # Non-parens without backtracking
1369              |
1370                (??{ $re })   # Group with matching parens
1371             )*
1372             \)
1373          }x;
1374
1375 See also C<(?PARNO)> for a different, more efficient way to accomplish
1376 the same task.
1377
1378 For reasons of security, this construct is forbidden if the regular
1379 expression involves run-time interpolation of variables, unless the
1380 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
1381 variables contain results of the C<qr//> operator (see
1382 L<perlop/"qrE<sol>STRINGE<sol>msixpodual">).
1383
1384 In perl 5.12.x and earlier, because the regex engine was not re-entrant,
1385 delayed code could not safely invoke the regex engine either directly with
1386 C<m//> or C<s///>), or indirectly with functions such as C<split>.
1387
1388 Recursing deeper than 50 times without consuming any input string will
1389 result in a fatal error.  The maximum depth is compiled into perl, so
1390 changing it requires a custom build.
1391
1392 =item C<(?PARNO)> C<(?-PARNO)> C<(?+PARNO)> C<(?R)> C<(?0)>
1393 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
1394 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
1395 X<regex, relative recursion>
1396
1397 Similar to C<(??{ code })> except it does not involve compiling any code,
1398 instead it treats the contents of a capture group as an independent
1399 pattern that must match at the current position.  Capture groups
1400 contained by the pattern will have the value as determined by the
1401 outermost recursion.
1402
1403 PARNO is a sequence of digits (not starting with 0) whose value reflects
1404 the paren-number of the capture group to recurse to. C<(?R)> recurses to
1405 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
1406 C<(?R)>. If PARNO is preceded by a plus or minus sign then it is assumed
1407 to be relative, with negative numbers indicating preceding capture groups
1408 and positive ones following. Thus C<(?-1)> refers to the most recently
1409 declared group, and C<(?+1)> indicates the next group to be declared.
1410 Note that the counting for relative recursion differs from that of
1411 relative backreferences, in that with recursion unclosed groups B<are>
1412 included.
1413
1414 The following pattern matches a function foo() which may contain
1415 balanced parentheses as the argument.
1416
1417   $re = qr{ (                   # paren group 1 (full function)
1418               foo
1419               (                 # paren group 2 (parens)
1420                 \(
1421                   (             # paren group 3 (contents of parens)
1422                   (?:
1423                    (?> [^()]+ ) # Non-parens without backtracking
1424                   |
1425                    (?2)         # Recurse to start of paren group 2
1426                   )*
1427                   )
1428                 \)
1429               )
1430             )
1431           }x;
1432
1433 If the pattern was used as follows
1434
1435     'foo(bar(baz)+baz(bop))'=~/$re/
1436         and print "\$1 = $1\n",
1437                   "\$2 = $2\n",
1438                   "\$3 = $3\n";
1439
1440 the output produced should be the following:
1441
1442     $1 = foo(bar(baz)+baz(bop))
1443     $2 = (bar(baz)+baz(bop))
1444     $3 = bar(baz)+baz(bop)
1445
1446 If there is no corresponding capture group defined, then it is a
1447 fatal error.  Recursing deeper than 50 times without consuming any input
1448 string will also result in a fatal error.  The maximum depth is compiled
1449 into perl, so changing it requires a custom build.
1450
1451 The following shows how using negative indexing can make it
1452 easier to embed recursive patterns inside of a C<qr//> construct
1453 for later use:
1454
1455     my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1456     if (/foo $parens \s+ + \s+ bar $parens/x) {
1457        # do something here...
1458     }
1459
1460 B<Note> that this pattern does not behave the same way as the equivalent
1461 PCRE or Python construct of the same form. In Perl you can backtrack into
1462 a recursed group, in PCRE and Python the recursed into group is treated
1463 as atomic. Also, modifiers are resolved at compile time, so constructs
1464 like (?i:(?1)) or (?:(?i)(?1)) do not affect how the sub-pattern will
1465 be processed.
1466
1467 =item C<(?&NAME)>
1468 X<(?&NAME)>
1469
1470 Recurse to a named subpattern. Identical to C<(?PARNO)> except that the
1471 parenthesis to recurse to is determined by name. If multiple parentheses have
1472 the same name, then it recurses to the leftmost.
1473
1474 It is an error to refer to a name that is not declared somewhere in the
1475 pattern.
1476
1477 B<NOTE:> In order to make things easier for programmers with experience
1478 with the Python or PCRE regex engines the pattern C<< (?P>NAME) >>
1479 may be used instead of C<< (?&NAME) >>.
1480
1481 =item C<(?(condition)yes-pattern|no-pattern)>
1482 X<(?()>
1483
1484 =item C<(?(condition)yes-pattern)>
1485
1486 Conditional expression. Matches C<yes-pattern> if C<condition> yields
1487 a true value, matches C<no-pattern> otherwise. A missing pattern always
1488 matches.
1489
1490 C<(condition)> should be either an integer in
1491 parentheses (which is valid if the corresponding pair of parentheses
1492 matched), a look-ahead/look-behind/evaluate zero-width assertion, a
1493 name in angle brackets or single quotes (which is valid if a group
1494 with the given name matched), or the special symbol (R) (true when
1495 evaluated inside of recursion or eval). Additionally the R may be
1496 followed by a number, (which will be true when evaluated when recursing
1497 inside of the appropriate group), or by C<&NAME>, in which case it will
1498 be true only when evaluated during recursion in the named group.
1499
1500 Here's a summary of the possible predicates:
1501
1502 =over 4
1503
1504 =item (1) (2) ...
1505
1506 Checks if the numbered capturing group has matched something.
1507
1508 =item (<NAME>) ('NAME')
1509
1510 Checks if a group with the given name has matched something.
1511
1512 =item (?=...) (?!...) (?<=...) (?<!...)
1513
1514 Checks whether the pattern matches (or does not match, for the '!'
1515 variants).
1516
1517 =item (?{ CODE })
1518
1519 Treats the return value of the code block as the condition.
1520
1521 =item (R)
1522
1523 Checks if the expression has been evaluated inside of recursion.
1524
1525 =item (R1) (R2) ...
1526
1527 Checks if the expression has been evaluated while executing directly
1528 inside of the n-th capture group. This check is the regex equivalent of
1529
1530   if ((caller(0))[3] eq 'subname') { ... }
1531
1532 In other words, it does not check the full recursion stack.
1533
1534 =item (R&NAME)
1535
1536 Similar to C<(R1)>, this predicate checks to see if we're executing
1537 directly inside of the leftmost group with a given name (this is the same
1538 logic used by C<(?&NAME)> to disambiguate). It does not check the full
1539 stack, but only the name of the innermost active recursion.
1540
1541 =item (DEFINE)
1542
1543 In this case, the yes-pattern is never directly executed, and no
1544 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
1545 See below for details.
1546
1547 =back
1548
1549 For example:
1550
1551     m{ ( \( )?
1552        [^()]+
1553        (?(1) \) )
1554      }x
1555
1556 matches a chunk of non-parentheses, possibly included in parentheses
1557 themselves.
1558
1559 A special form is the C<(DEFINE)> predicate, which never executes its
1560 yes-pattern directly, and does not allow a no-pattern. This allows one to
1561 define subpatterns which will be executed only by the recursion mechanism.
1562 This way, you can define a set of regular expression rules that can be
1563 bundled into any pattern you choose.
1564
1565 It is recommended that for this usage you put the DEFINE block at the
1566 end of the pattern, and that you name any subpatterns defined within it.
1567
1568 Also, it's worth noting that patterns defined this way probably will
1569 not be as efficient, as the optimiser is not very clever about
1570 handling them.
1571
1572 An example of how this might be used is as follows:
1573
1574   /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
1575    (?(DEFINE)
1576      (?<NAME_PAT>....)
1577      (?<ADRESS_PAT>....)
1578    )/x
1579
1580 Note that capture groups matched inside of recursion are not accessible
1581 after the recursion returns, so the extra layer of capturing groups is
1582 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
1583 C<$+{NAME}> would be.
1584
1585 Finally, keep in mind that subpatterns created inside a DEFINE block
1586 count towards the absolute and relative number of captures, so this:
1587
1588     my @captures = "a" =~ /(.)                  # First capture
1589                            (?(DEFINE)
1590                                (?<EXAMPLE> 1 )  # Second capture
1591                            )/x;
1592     say scalar @captures;
1593
1594 Will output 2, not 1. This is particularly important if you intend to
1595 compile the definitions with the C<qr//> operator, and later
1596 interpolate them in another pattern.
1597
1598 =item C<< (?>pattern) >>
1599 X<backtrack> X<backtracking> X<atomic> X<possessive>
1600
1601 An "independent" subexpression, one which matches the substring
1602 that a I<standalone> C<pattern> would match if anchored at the given
1603 position, and it matches I<nothing other than this substring>.  This
1604 construct is useful for optimizations of what would otherwise be
1605 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
1606 It may also be useful in places where the "grab all you can, and do not
1607 give anything back" semantic is desirable.
1608
1609 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
1610 (anchored at the beginning of string, as above) will match I<all>
1611 characters C<a> at the beginning of string, leaving no C<a> for
1612 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
1613 since the match of the subgroup C<a*> is influenced by the following
1614 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
1615 C<a*ab> will match fewer characters than a standalone C<a*>, since
1616 this makes the tail match.
1617
1618 C<< (?>pattern) >> does not disable backtracking altogether once it has
1619 matched. It is still possible to backtrack past the construct, but not
1620 into it. So C<< ((?>a*)|(?>b*))ar >> will still match "bar".
1621
1622 An effect similar to C<< (?>pattern) >> may be achieved by writing
1623 C<(?=(pattern))\g{-1}>.  This matches the same substring as a standalone
1624 C<a+>, and the following C<\g{-1}> eats the matched string; it therefore
1625 makes a zero-length assertion into an analogue of C<< (?>...) >>.
1626 (The difference between these two constructs is that the second one
1627 uses a capturing group, thus shifting ordinals of backreferences
1628 in the rest of a regular expression.)
1629
1630 Consider this pattern:
1631
1632     m{ \(
1633           (
1634             [^()]+           # x+
1635           |
1636             \( [^()]* \)
1637           )+
1638        \)
1639      }x
1640
1641 That will efficiently match a nonempty group with matching parentheses
1642 two levels deep or less.  However, if there is no such group, it
1643 will take virtually forever on a long string.  That's because there
1644 are so many different ways to split a long string into several
1645 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
1646 to a subpattern of the above pattern.  Consider how the pattern
1647 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
1648 seconds, but that each extra letter doubles this time.  This
1649 exponential performance will make it appear that your program has
1650 hung.  However, a tiny change to this pattern
1651
1652     m{ \(
1653           (
1654             (?> [^()]+ )        # change x+ above to (?> x+ )
1655           |
1656             \( [^()]* \)
1657           )+
1658        \)
1659      }x
1660
1661 which uses C<< (?>...) >> matches exactly when the one above does (verifying
1662 this yourself would be a productive exercise), but finishes in a fourth
1663 the time when used on a similar string with 1000000 C<a>s.  Be aware,
1664 however, that, when this construct is followed by a
1665 quantifier, it currently triggers a warning message under
1666 the C<use warnings> pragma or B<-w> switch saying it
1667 C<"matches null string many times in regex">.
1668
1669 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
1670 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
1671 This was only 4 times slower on a string with 1000000 C<a>s.
1672
1673 The "grab all you can, and do not give anything back" semantic is desirable
1674 in many situations where on the first sight a simple C<()*> looks like
1675 the correct solution.  Suppose we parse text with comments being delimited
1676 by C<#> followed by some optional (horizontal) whitespace.  Contrary to
1677 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
1678 the comment delimiter, because it may "give up" some whitespace if
1679 the remainder of the pattern can be made to match that way.  The correct
1680 answer is either one of these:
1681
1682     (?>#[ \t]*)
1683     #[ \t]*(?![ \t])
1684
1685 For example, to grab non-empty comments into $1, one should use either
1686 one of these:
1687
1688     / (?> \# [ \t]* ) (        .+ ) /x;
1689     /     \# [ \t]*   ( [^ \t] .* ) /x;
1690
1691 Which one you pick depends on which of these expressions better reflects
1692 the above specification of comments.
1693
1694 In some literature this construct is called "atomic matching" or
1695 "possessive matching".
1696
1697 Possessive quantifiers are equivalent to putting the item they are applied
1698 to inside of one of these constructs. The following equivalences apply:
1699
1700     Quantifier Form     Bracketing Form
1701     ---------------     ---------------
1702     PAT*+               (?>PAT*)
1703     PAT++               (?>PAT+)
1704     PAT?+               (?>PAT?)
1705     PAT{min,max}+       (?>PAT{min,max})
1706
1707 =back
1708
1709 =head2 Special Backtracking Control Verbs
1710
1711 B<WARNING:> These patterns are experimental and subject to change or
1712 removal in a future version of Perl. Their usage in production code should
1713 be noted to avoid problems during upgrades.
1714
1715 These special patterns are generally of the form C<(*VERB:ARG)>. Unless
1716 otherwise stated the ARG argument is optional; in some cases, it is
1717 forbidden.
1718
1719 Any pattern containing a special backtracking verb that allows an argument
1720 has the special behaviour that when executed it sets the current package's
1721 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
1722 rules apply:
1723
1724 On failure, the C<$REGERROR> variable will be set to the ARG value of the
1725 verb pattern, if the verb was involved in the failure of the match. If the
1726 ARG part of the pattern was omitted, then C<$REGERROR> will be set to the
1727 name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
1728 none. Also, the C<$REGMARK> variable will be set to FALSE.
1729
1730 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
1731 the C<$REGMARK> variable will be set to the name of the last
1732 C<(*MARK:NAME)> pattern executed.  See the explanation for the
1733 C<(*MARK:NAME)> verb below for more details.
1734
1735 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
1736 and most other regex-related variables. They are not local to a scope, nor
1737 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
1738 Use C<local> to localize changes to them to a specific scope if necessary.
1739
1740 If a pattern does not contain a special backtracking verb that allows an
1741 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
1742
1743 =over 3
1744
1745 =item Verbs that take an argument
1746
1747 =over 4
1748
1749 =item C<(*PRUNE)> C<(*PRUNE:NAME)>
1750 X<(*PRUNE)> X<(*PRUNE:NAME)>
1751
1752 This zero-width pattern prunes the backtracking tree at the current point
1753 when backtracked into on failure. Consider the pattern C<A (*PRUNE) B>,
1754 where A and B are complex patterns. Until the C<(*PRUNE)> verb is reached,
1755 A may backtrack as necessary to match. Once it is reached, matching
1756 continues in B, which may also backtrack as necessary; however, should B
1757 not match, then no further backtracking will take place, and the pattern
1758 will fail outright at the current starting position.
1759
1760 The following example counts all the possible matching strings in a
1761 pattern (without actually matching any of them).
1762
1763     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
1764     print "Count=$count\n";
1765
1766 which produces:
1767
1768     aaab
1769     aaa
1770     aa
1771     a
1772     aab
1773     aa
1774     a
1775     ab
1776     a
1777     Count=9
1778
1779 If we add a C<(*PRUNE)> before the count like the following
1780
1781     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
1782     print "Count=$count\n";
1783
1784 we prevent backtracking and find the count of the longest matching string
1785 at each matching starting point like so:
1786
1787     aaab
1788     aab
1789     ab
1790     Count=3
1791
1792 Any number of C<(*PRUNE)> assertions may be used in a pattern.
1793
1794 See also C<< (?>pattern) >> and possessive quantifiers for other ways to
1795 control backtracking. In some cases, the use of C<(*PRUNE)> can be
1796 replaced with a C<< (?>pattern) >> with no functional difference; however,
1797 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
1798 C<< (?>pattern) >> alone.
1799
1800 =item C<(*SKIP)> C<(*SKIP:NAME)>
1801 X<(*SKIP)>
1802
1803 This zero-width pattern is similar to C<(*PRUNE)>, except that on
1804 failure it also signifies that whatever text that was matched leading up
1805 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
1806 of this pattern. This effectively means that the regex engine "skips" forward
1807 to this position on failure and tries to match again, (assuming that
1808 there is sufficient room to match).
1809
1810 The name of the C<(*SKIP:NAME)> pattern has special significance. If a
1811 C<(*MARK:NAME)> was encountered while matching, then it is that position
1812 which is used as the "skip point". If no C<(*MARK)> of that name was
1813 encountered, then the C<(*SKIP)> operator has no effect. When used
1814 without a name the "skip point" is where the match point was when
1815 executing the (*SKIP) pattern.
1816
1817 Compare the following to the examples in C<(*PRUNE)>; note the string
1818 is twice as long:
1819
1820  'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
1821  print "Count=$count\n";
1822
1823 outputs
1824
1825     aaab
1826     aaab
1827     Count=2
1828
1829 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
1830 executed, the next starting point will be where the cursor was when the
1831 C<(*SKIP)> was executed.
1832
1833 =item C<(*MARK:NAME)> C<(*:NAME)>
1834 X<(*MARK)> X<(*MARK:NAME)> X<(*:NAME)>
1835
1836 This zero-width pattern can be used to mark the point reached in a string
1837 when a certain part of the pattern has been successfully matched. This
1838 mark may be given a name. A later C<(*SKIP)> pattern will then skip
1839 forward to that point if backtracked into on failure. Any number of
1840 C<(*MARK)> patterns are allowed, and the NAME portion may be duplicated.
1841
1842 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
1843 can be used to "label" a pattern branch, so that after matching, the
1844 program can determine which branches of the pattern were involved in the
1845 match.
1846
1847 When a match is successful, the C<$REGMARK> variable will be set to the
1848 name of the most recently executed C<(*MARK:NAME)> that was involved
1849 in the match.
1850
1851 This can be used to determine which branch of a pattern was matched
1852 without using a separate capture group for each branch, which in turn
1853 can result in a performance improvement, as perl cannot optimize
1854 C</(?:(x)|(y)|(z))/> as efficiently as something like
1855 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
1856
1857 When a match has failed, and unless another verb has been involved in
1858 failing the match and has provided its own name to use, the C<$REGERROR>
1859 variable will be set to the name of the most recently executed
1860 C<(*MARK:NAME)>.
1861
1862 See L</(*SKIP)> for more details.
1863
1864 As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
1865
1866 =item C<(*THEN)> C<(*THEN:NAME)>
1867
1868 This is similar to the "cut group" operator C<::> from Perl 6.  Like
1869 C<(*PRUNE)>, this verb always matches, and when backtracked into on
1870 failure, it causes the regex engine to try the next alternation in the
1871 innermost enclosing group (capturing or otherwise) that has alternations.
1872 The two branches of a C<(?(condition)yes-pattern|no-pattern)> do not
1873 count as an alternation, as far as C<(*THEN)> is concerned.
1874
1875 Its name comes from the observation that this operation combined with the
1876 alternation operator (C<|>) can be used to create what is essentially a
1877 pattern-based if/then/else block:
1878
1879   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
1880
1881 Note that if this operator is used and NOT inside of an alternation then
1882 it acts exactly like the C<(*PRUNE)> operator.
1883
1884   / A (*PRUNE) B /
1885
1886 is the same as
1887
1888   / A (*THEN) B /
1889
1890 but
1891
1892   / ( A (*THEN) B | C (*THEN) D ) /
1893
1894 is not the same as
1895
1896   / ( A (*PRUNE) B | C (*PRUNE) D ) /
1897
1898 as after matching the A but failing on the B the C<(*THEN)> verb will
1899 backtrack and try C; but the C<(*PRUNE)> verb will simply fail.
1900
1901 =back
1902
1903 =item Verbs without an argument
1904
1905 =over 4
1906
1907 =item C<(*COMMIT)>
1908 X<(*COMMIT)>
1909
1910 This is the Perl 6 "commit pattern" C<< <commit> >> or C<:::>. It's a
1911 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
1912 into on failure it causes the match to fail outright. No further attempts
1913 to find a valid match by advancing the start pointer will occur again.
1914 For example,
1915
1916  'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
1917  print "Count=$count\n";
1918
1919 outputs
1920
1921     aaab
1922     Count=1
1923
1924 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
1925 does not match, the regex engine will not try any further matching on the
1926 rest of the string.
1927
1928 =item C<(*FAIL)> C<(*F)>
1929 X<(*FAIL)> X<(*F)>
1930
1931 This pattern matches nothing and always fails. It can be used to force the
1932 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
1933 fact, C<(?!)> gets optimised into C<(*FAIL)> internally.
1934
1935 It is probably useful only when combined with C<(?{})> or C<(??{})>.
1936
1937 =item C<(*ACCEPT)>
1938 X<(*ACCEPT)>
1939
1940 B<WARNING:> This feature is highly experimental. It is not recommended
1941 for production code.
1942
1943 This pattern matches nothing and causes the end of successful matching at
1944 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
1945 whether there is actually more to match in the string. When inside of a
1946 nested pattern, such as recursion, or in a subpattern dynamically generated
1947 via C<(??{})>, only the innermost pattern is ended immediately.
1948
1949 If the C<(*ACCEPT)> is inside of capturing groups then the groups are
1950 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
1951 For instance:
1952
1953   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
1954
1955 will match, and C<$1> will be C<AB> and C<$2> will be C<B>, C<$3> will not
1956 be set. If another branch in the inner parentheses was matched, such as in the
1957 string 'ACDE', then the C<D> and C<E> would have to be matched as well.
1958
1959 =back
1960
1961 =back
1962
1963 =head2 Backtracking
1964 X<backtrack> X<backtracking>
1965
1966 NOTE: This section presents an abstract approximation of regular
1967 expression behavior.  For a more rigorous (and complicated) view of
1968 the rules involved in selecting a match among possible alternatives,
1969 see L<Combining RE Pieces>.
1970
1971 A fundamental feature of regular expression matching involves the
1972 notion called I<backtracking>, which is currently used (when needed)
1973 by all regular non-possessive expression quantifiers, namely C<*>, C<*?>, C<+>,
1974 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
1975 internally, but the general principle outlined here is valid.
1976
1977 For a regular expression to match, the I<entire> regular expression must
1978 match, not just part of it.  So if the beginning of a pattern containing a
1979 quantifier succeeds in a way that causes later parts in the pattern to
1980 fail, the matching engine backs up and recalculates the beginning
1981 part--that's why it's called backtracking.
1982
1983 Here is an example of backtracking:  Let's say you want to find the
1984 word following "foo" in the string "Food is on the foo table.":
1985
1986     $_ = "Food is on the foo table.";
1987     if ( /\b(foo)\s+(\w+)/i ) {
1988         print "$2 follows $1.\n";
1989     }
1990
1991 When the match runs, the first part of the regular expression (C<\b(foo)>)
1992 finds a possible match right at the beginning of the string, and loads up
1993 $1 with "Foo".  However, as soon as the matching engine sees that there's
1994 no whitespace following the "Foo" that it had saved in $1, it realizes its
1995 mistake and starts over again one character after where it had the
1996 tentative match.  This time it goes all the way until the next occurrence
1997 of "foo". The complete regular expression matches this time, and you get
1998 the expected output of "table follows foo."
1999
2000 Sometimes minimal matching can help a lot.  Imagine you'd like to match
2001 everything between "foo" and "bar".  Initially, you write something
2002 like this:
2003
2004     $_ =  "The food is under the bar in the barn.";
2005     if ( /foo(.*)bar/ ) {
2006         print "got <$1>\n";
2007     }
2008
2009 Which perhaps unexpectedly yields:
2010
2011   got <d is under the bar in the >
2012
2013 That's because C<.*> was greedy, so you get everything between the
2014 I<first> "foo" and the I<last> "bar".  Here it's more effective
2015 to use minimal matching to make sure you get the text between a "foo"
2016 and the first "bar" thereafter.
2017
2018     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
2019   got <d is under the >
2020
2021 Here's another example. Let's say you'd like to match a number at the end
2022 of a string, and you also want to keep the preceding part of the match.
2023 So you write this:
2024
2025     $_ = "I have 2 numbers: 53147";
2026     if ( /(.*)(\d*)/ ) {                                # Wrong!
2027         print "Beginning is <$1>, number is <$2>.\n";
2028     }
2029
2030 That won't work at all, because C<.*> was greedy and gobbled up the
2031 whole string. As C<\d*> can match on an empty string the complete
2032 regular expression matched successfully.
2033
2034     Beginning is <I have 2 numbers: 53147>, number is <>.
2035
2036 Here are some variants, most of which don't work:
2037
2038     $_ = "I have 2 numbers: 53147";
2039     @pats = qw{
2040         (.*)(\d*)
2041         (.*)(\d+)
2042         (.*?)(\d*)
2043         (.*?)(\d+)
2044         (.*)(\d+)$
2045         (.*?)(\d+)$
2046         (.*)\b(\d+)$
2047         (.*\D)(\d+)$
2048     };
2049
2050     for $pat (@pats) {
2051         printf "%-12s ", $pat;
2052         if ( /$pat/ ) {
2053             print "<$1> <$2>\n";
2054         } else {
2055             print "FAIL\n";
2056         }
2057     }
2058
2059 That will print out:
2060
2061     (.*)(\d*)    <I have 2 numbers: 53147> <>
2062     (.*)(\d+)    <I have 2 numbers: 5314> <7>
2063     (.*?)(\d*)   <> <>
2064     (.*?)(\d+)   <I have > <2>
2065     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
2066     (.*?)(\d+)$  <I have 2 numbers: > <53147>
2067     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
2068     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
2069
2070 As you see, this can be a bit tricky.  It's important to realize that a
2071 regular expression is merely a set of assertions that gives a definition
2072 of success.  There may be 0, 1, or several different ways that the
2073 definition might succeed against a particular string.  And if there are
2074 multiple ways it might succeed, you need to understand backtracking to
2075 know which variety of success you will achieve.
2076
2077 When using look-ahead assertions and negations, this can all get even
2078 trickier.  Imagine you'd like to find a sequence of non-digits not
2079 followed by "123".  You might try to write that as
2080
2081     $_ = "ABC123";
2082     if ( /^\D*(?!123)/ ) {                # Wrong!
2083         print "Yup, no 123 in $_\n";
2084     }
2085
2086 But that isn't going to match; at least, not the way you're hoping.  It
2087 claims that there is no 123 in the string.  Here's a clearer picture of
2088 why that pattern matches, contrary to popular expectations:
2089
2090     $x = 'ABC123';
2091     $y = 'ABC445';
2092
2093     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
2094     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
2095
2096     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
2097     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
2098
2099 This prints
2100
2101     2: got ABC
2102     3: got AB
2103     4: got ABC
2104
2105 You might have expected test 3 to fail because it seems to a more
2106 general purpose version of test 1.  The important difference between
2107 them is that test 3 contains a quantifier (C<\D*>) and so can use
2108 backtracking, whereas test 1 will not.  What's happening is
2109 that you've asked "Is it true that at the start of $x, following 0 or more
2110 non-digits, you have something that's not 123?"  If the pattern matcher had
2111 let C<\D*> expand to "ABC", this would have caused the whole pattern to
2112 fail.
2113
2114 The search engine will initially match C<\D*> with "ABC".  Then it will
2115 try to match C<(?!123)> with "123", which fails.  But because
2116 a quantifier (C<\D*>) has been used in the regular expression, the
2117 search engine can backtrack and retry the match differently
2118 in the hope of matching the complete regular expression.
2119
2120 The pattern really, I<really> wants to succeed, so it uses the
2121 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
2122 time.  Now there's indeed something following "AB" that is not
2123 "123".  It's "C123", which suffices.
2124
2125 We can deal with this by using both an assertion and a negation.
2126 We'll say that the first part in $1 must be followed both by a digit
2127 and by something that's not "123".  Remember that the look-aheads
2128 are zero-width expressions--they only look, but don't consume any
2129 of the string in their match.  So rewriting this way produces what
2130 you'd expect; that is, case 5 will fail, but case 6 succeeds:
2131
2132     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
2133     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
2134
2135     6: got ABC
2136
2137 In other words, the two zero-width assertions next to each other work as though
2138 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
2139 matches only if you're at the beginning of the line AND the end of the
2140 line simultaneously.  The deeper underlying truth is that juxtaposition in
2141 regular expressions always means AND, except when you write an explicit OR
2142 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
2143 although the attempted matches are made at different positions because "a"
2144 is not a zero-width assertion, but a one-width assertion.
2145
2146 B<WARNING>: Particularly complicated regular expressions can take
2147 exponential time to solve because of the immense number of possible
2148 ways they can use backtracking to try for a match.  For example, without
2149 internal optimizations done by the regular expression engine, this will
2150 take a painfully long time to run:
2151
2152     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
2153
2154 And if you used C<*>'s in the internal groups instead of limiting them
2155 to 0 through 5 matches, then it would take forever--or until you ran
2156 out of stack space.  Moreover, these internal optimizations are not
2157 always applicable.  For example, if you put C<{0,5}> instead of C<*>
2158 on the external group, no current optimization is applicable, and the
2159 match takes a long time to finish.
2160
2161 A powerful tool for optimizing such beasts is what is known as an
2162 "independent group",
2163 which does not backtrack (see L</C<< (?>pattern) >>>).  Note also that
2164 zero-length look-ahead/look-behind assertions will not backtrack to make
2165 the tail match, since they are in "logical" context: only
2166 whether they match is considered relevant.  For an example
2167 where side-effects of look-ahead I<might> have influenced the
2168 following match, see L</C<< (?>pattern) >>>.
2169
2170 =head2 Version 8 Regular Expressions
2171 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
2172
2173 In case you're not familiar with the "regular" Version 8 regex
2174 routines, here are the pattern-matching rules not described above.
2175
2176 Any single character matches itself, unless it is a I<metacharacter>
2177 with a special meaning described here or above.  You can cause
2178 characters that normally function as metacharacters to be interpreted
2179 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
2180 character; "\\" matches a "\"). This escape mechanism is also required
2181 for the character used as the pattern delimiter.
2182
2183 A series of characters matches that series of characters in the target
2184 string, so the pattern C<blurfl> would match "blurfl" in the target
2185 string.
2186
2187 You can specify a character class, by enclosing a list of characters
2188 in C<[]>, which will match any character from the list.  If the
2189 first character after the "[" is "^", the class matches any character not
2190 in the list.  Within a list, the "-" character specifies a
2191 range, so that C<a-z> represents all characters between "a" and "z",
2192 inclusive.  If you want either "-" or "]" itself to be a member of a
2193 class, put it at the start of the list (possibly after a "^"), or
2194 escape it with a backslash.  "-" is also taken literally when it is
2195 at the end of the list, just before the closing "]".  (The
2196 following all specify the same class of three characters: C<[-az]>,
2197 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
2198 specifies a class containing twenty-six characters, even on EBCDIC-based
2199 character sets.)  Also, if you try to use the character
2200 classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of
2201 a range, the "-" is understood literally.
2202
2203 Note also that the whole range idea is rather unportable between
2204 character sets--and even within character sets they may cause results
2205 you probably didn't expect.  A sound principle is to use only ranges
2206 that begin from and end at either alphabetics of equal case ([a-e],
2207 [A-E]), or digits ([0-9]).  Anything else is unsafe.  If in doubt,
2208 spell out the character sets in full.
2209
2210 Characters may be specified using a metacharacter syntax much like that
2211 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
2212 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
2213 of three octal digits, matches the character whose coded character set value
2214 is I<nnn>.  Similarly, \xI<nn>, where I<nn> are hexadecimal digits,
2215 matches the character whose ordinal is I<nn>. The expression \cI<x>
2216 matches the character control-I<x>.  Finally, the "." metacharacter
2217 matches any character except "\n" (unless you use C</s>).
2218
2219 You can specify a series of alternatives for a pattern using "|" to
2220 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
2221 or "foe" in the target string (as would C<f(e|i|o)e>).  The
2222 first alternative includes everything from the last pattern delimiter
2223 ("(", "(?:", etc. or the beginning of the pattern) up to the first "|", and
2224 the last alternative contains everything from the last "|" to the next
2225 closing pattern delimiter.  That's why it's common practice to include
2226 alternatives in parentheses: to minimize confusion about where they
2227 start and end.
2228
2229 Alternatives are tried from left to right, so the first
2230 alternative found for which the entire expression matches, is the one that
2231 is chosen. This means that alternatives are not necessarily greedy. For
2232 example: when matching C<foo|foot> against "barefoot", only the "foo"
2233 part will match, as that is the first alternative tried, and it successfully
2234 matches the target string. (This might not seem important, but it is
2235 important when you are capturing matched text using parentheses.)
2236
2237 Also remember that "|" is interpreted as a literal within square brackets,
2238 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
2239
2240 Within a pattern, you may designate subpatterns for later reference
2241 by enclosing them in parentheses, and you may refer back to the
2242 I<n>th subpattern later in the pattern using the metacharacter
2243 \I<n> or \gI<n>.  Subpatterns are numbered based on the left to right order
2244 of their opening parenthesis.  A backreference matches whatever
2245 actually matched the subpattern in the string being examined, not
2246 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\g1\d*> will
2247 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
2248 1 matched "0x", even though the rule C<0|0x> could potentially match
2249 the leading 0 in the second number.
2250
2251 =head2 Warning on \1 Instead of $1
2252
2253 Some people get too used to writing things like:
2254
2255     $pattern =~ s/(\W)/\\\1/g;
2256
2257 This is grandfathered (for \1 to \9) for the RHS of a substitute to avoid
2258 shocking the
2259 B<sed> addicts, but it's a dirty habit to get into.  That's because in
2260 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
2261 the usual double-quoted string means a control-A.  The customary Unix
2262 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
2263 of doing that, you get yourself into trouble if you then add an C</e>
2264 modifier.
2265
2266     s/(\d+)/ \1 + 1 /eg;            # causes warning under -w
2267
2268 Or if you try to do
2269
2270     s/(\d+)/\1000/;
2271
2272 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
2273 C<${1}000>.  The operation of interpolation should not be confused
2274 with the operation of matching a backreference.  Certainly they mean two
2275 different things on the I<left> side of the C<s///>.
2276
2277 =head2 Repeated Patterns Matching a Zero-length Substring
2278
2279 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
2280
2281 Regular expressions provide a terse and powerful programming language.  As
2282 with most other power tools, power comes together with the ability
2283 to wreak havoc.
2284
2285 A common abuse of this power stems from the ability to make infinite
2286 loops using regular expressions, with something as innocuous as:
2287
2288     'foo' =~ m{ ( o? )* }x;
2289
2290 The C<o?> matches at the beginning of C<'foo'>, and since the position
2291 in the string is not moved by the match, C<o?> would match again and again
2292 because of the C<*> quantifier.  Another common way to create a similar cycle
2293 is with the looping modifier C<//g>:
2294
2295     @matches = ( 'foo' =~ m{ o? }xg );
2296
2297 or
2298
2299     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
2300
2301 or the loop implied by split().
2302
2303 However, long experience has shown that many programming tasks may
2304 be significantly simplified by using repeated subexpressions that
2305 may match zero-length substrings.  Here's a simple example being:
2306
2307     @chars = split //, $string;           # // is not magic in split
2308     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
2309
2310 Thus Perl allows such constructs, by I<forcefully breaking
2311 the infinite loop>.  The rules for this are different for lower-level
2312 loops given by the greedy quantifiers C<*+{}>, and for higher-level
2313 ones like the C</g> modifier or split() operator.
2314
2315 The lower-level loops are I<interrupted> (that is, the loop is
2316 broken) when Perl detects that a repeated expression matched a
2317 zero-length substring.   Thus
2318
2319    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
2320
2321 is made equivalent to
2322
2323    m{ (?: NON_ZERO_LENGTH )* (?: ZERO_LENGTH )? }x;
2324
2325 For example, this program
2326
2327    #!perl -l
2328    "aaaaab" =~ /
2329      (?:
2330         a                 # non-zero
2331         |                 # or
2332        (?{print "hello"}) # print hello whenever this
2333                           #    branch is tried
2334        (?=(b))            # zero-width assertion
2335      )*  # any number of times
2336     /x;
2337    print $&;
2338    print $1;
2339
2340 prints
2341
2342    hello
2343    aaaaa
2344    b
2345
2346 Notice that "hello" is only printed once, as when Perl sees that the sixth
2347 iteration of the outermost C<(?:)*> matches a zero-length string, it stops
2348 the C<*>.
2349
2350 The higher-level loops preserve an additional state between iterations:
2351 whether the last match was zero-length.  To break the loop, the following
2352 match after a zero-length match is prohibited to have a length of zero.
2353 This prohibition interacts with backtracking (see L<"Backtracking">),
2354 and so the I<second best> match is chosen if the I<best> match is of
2355 zero length.
2356
2357 For example:
2358
2359     $_ = 'bar';
2360     s/\w??/<$&>/g;
2361
2362 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
2363 match given by non-greedy C<??> is the zero-length match, and the I<second
2364 best> match is what is matched by C<\w>.  Thus zero-length matches
2365 alternate with one-character-long matches.
2366
2367 Similarly, for repeated C<m/()/g> the second-best match is the match at the
2368 position one notch further in the string.
2369
2370 The additional state of being I<matched with zero-length> is associated with
2371 the matched string, and is reset by each assignment to pos().
2372 Zero-length matches at the end of the previous match are ignored
2373 during C<split>.
2374
2375 =head2 Combining RE Pieces
2376
2377 Each of the elementary pieces of regular expressions which were described
2378 before (such as C<ab> or C<\Z>) could match at most one substring
2379 at the given position of the input string.  However, in a typical regular
2380 expression these elementary pieces are combined into more complicated
2381 patterns using combining operators C<ST>, C<S|T>, C<S*> etc.
2382 (in these examples C<S> and C<T> are regular subexpressions).
2383
2384 Such combinations can include alternatives, leading to a problem of choice:
2385 if we match a regular expression C<a|ab> against C<"abc">, will it match
2386 substring C<"a"> or C<"ab">?  One way to describe which substring is
2387 actually matched is the concept of backtracking (see L<"Backtracking">).
2388 However, this description is too low-level and makes you think
2389 in terms of a particular implementation.
2390
2391 Another description starts with notions of "better"/"worse".  All the
2392 substrings which may be matched by the given regular expression can be
2393 sorted from the "best" match to the "worst" match, and it is the "best"
2394 match which is chosen.  This substitutes the question of "what is chosen?"
2395 by the question of "which matches are better, and which are worse?".
2396
2397 Again, for elementary pieces there is no such question, since at most
2398 one match at a given position is possible.  This section describes the
2399 notion of better/worse for combining operators.  In the description
2400 below C<S> and C<T> are regular subexpressions.
2401
2402 =over 4
2403
2404 =item C<ST>
2405
2406 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
2407 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
2408 which can be matched by C<T>.
2409
2410 If C<A> is a better match for C<S> than C<A'>, C<AB> is a better
2411 match than C<A'B'>.
2412
2413 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
2414 C<B> is a better match for C<T> than C<B'>.
2415
2416 =item C<S|T>
2417
2418 When C<S> can match, it is a better match than when only C<T> can match.
2419
2420 Ordering of two matches for C<S> is the same as for C<S>.  Similar for
2421 two matches for C<T>.
2422
2423 =item C<S{REPEAT_COUNT}>
2424
2425 Matches as C<SSS...S> (repeated as many times as necessary).
2426
2427 =item C<S{min,max}>
2428
2429 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
2430
2431 =item C<S{min,max}?>
2432
2433 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
2434
2435 =item C<S?>, C<S*>, C<S+>
2436
2437 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
2438
2439 =item C<S??>, C<S*?>, C<S+?>
2440
2441 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
2442
2443 =item C<< (?>S) >>
2444
2445 Matches the best match for C<S> and only that.
2446
2447 =item C<(?=S)>, C<(?<=S)>
2448
2449 Only the best match for C<S> is considered.  (This is important only if
2450 C<S> has capturing parentheses, and backreferences are used somewhere
2451 else in the whole regular expression.)
2452
2453 =item C<(?!S)>, C<(?<!S)>
2454
2455 For this grouping operator there is no need to describe the ordering, since
2456 only whether or not C<S> can match is important.
2457
2458 =item C<(??{ EXPR })>, C<(?PARNO)>
2459
2460 The ordering is the same as for the regular expression which is
2461 the result of EXPR, or the pattern contained by capture group PARNO.
2462
2463 =item C<(?(condition)yes-pattern|no-pattern)>
2464
2465 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
2466 already determined.  The ordering of the matches is the same as for the
2467 chosen subexpression.
2468
2469 =back
2470
2471 The above recipes describe the ordering of matches I<at a given position>.
2472 One more rule is needed to understand how a match is determined for the
2473 whole regular expression: a match at an earlier position is always better
2474 than a match at a later position.
2475
2476 =head2 Creating Custom RE Engines
2477
2478 As of Perl 5.10.0, one can create custom regular expression engines.  This
2479 is not for the faint of heart, as they have to plug in at the C level.  See
2480 L<perlreapi> for more details.
2481
2482 As an alternative, overloaded constants (see L<overload>) provide a simple
2483 way to extend the functionality of the RE engine, by substituting one
2484 pattern for another.
2485
2486 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
2487 matches at a boundary between whitespace characters and non-whitespace
2488 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
2489 at these positions, so we want to have each C<\Y|> in the place of the
2490 more complicated version.  We can create a module C<customre> to do
2491 this:
2492
2493     package customre;
2494     use overload;
2495
2496     sub import {
2497       shift;
2498       die "No argument to customre::import allowed" if @_;
2499       overload::constant 'qr' => \&convert;
2500     }
2501
2502     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
2503
2504     # We must also take care of not escaping the legitimate \\Y|
2505     # sequence, hence the presence of '\\' in the conversion rules.
2506     my %rules = ( '\\' => '\\\\',
2507                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
2508     sub convert {
2509       my $re = shift;
2510       $re =~ s{
2511                 \\ ( \\ | Y . )
2512               }
2513               { $rules{$1} or invalid($re,$1) }sgex;
2514       return $re;
2515     }
2516
2517 Now C<use customre> enables the new escape in constant regular
2518 expressions, i.e., those without any runtime variable interpolations.
2519 As documented in L<overload>, this conversion will work only over
2520 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
2521 part of this regular expression needs to be converted explicitly
2522 (but only if the special meaning of C<\Y|> should be enabled inside $re):
2523
2524     use customre;
2525     $re = <>;
2526     chomp $re;
2527     $re = customre::convert $re;
2528     /\Y|$re\Y|/;
2529
2530 =head2 PCRE/Python Support
2531
2532 As of Perl 5.10.0, Perl supports several Python/PCRE-specific extensions
2533 to the regex syntax. While Perl programmers are encouraged to use the
2534 Perl-specific syntax, the following are also accepted:
2535
2536 =over 4
2537
2538 =item C<< (?PE<lt>NAMEE<gt>pattern) >>
2539
2540 Define a named capture group. Equivalent to C<< (?<NAME>pattern) >>.
2541
2542 =item C<< (?P=NAME) >>
2543
2544 Backreference to a named capture group. Equivalent to C<< \g{NAME} >>.
2545
2546 =item C<< (?P>NAME) >>
2547
2548 Subroutine call to a named capture group. Equivalent to C<< (?&NAME) >>.
2549
2550 =back
2551
2552 =head1 BUGS
2553
2554 Many regular expression constructs don't work on EBCDIC platforms.
2555
2556 There are a number of issues with regard to case-insensitive matching
2557 in Unicode rules.  See C<i> under L</Modifiers> above.
2558
2559 This document varies from difficult to understand to completely
2560 and utterly opaque.  The wandering prose riddled with jargon is
2561 hard to fathom in several places.
2562
2563 This document needs a rewrite that separates the tutorial content
2564 from the reference content.
2565
2566 =head1 SEE ALSO
2567
2568 L<perlrequick>.
2569
2570 L<perlretut>.
2571
2572 L<perlop/"Regexp Quote-Like Operators">.
2573
2574 L<perlop/"Gory details of parsing quoted constructs">.
2575
2576 L<perlfaq6>.
2577
2578 L<perlfunc/pos>.
2579
2580 L<perllocale>.
2581
2582 L<perlebcdic>.
2583
2584 I<Mastering Regular Expressions> by Jeffrey Friedl, published
2585 by O'Reilly and Associates.