dist/ExtUtils-Install/t/Install.t

   1 #!/usr/bin/perl -w
   2
   3 # Test ExtUtils::Install.
   4
   5 BEGIN {
   6     unshift @INC, 't/lib';
   7 }
   8
   9 use strict;
  10 use TieOut;
  11 use File::Path;
  12 use File::Spec;
  13 use File::Temp qw[tempdir];
  14
  15 use Test::More tests => 60;
  16
  17 use MakeMaker::Test::Setup::BFD;
  18
  19 BEGIN { use_ok('ExtUtils::Install') }
  20 # ensure the env doesn't pollute our tests
  21 local $ENV{EU_INSTALL_ALWAYS_COPY};
  22 local $ENV{EU_ALWAYS_COPY};
  23
  24 # Check exports.
  25 foreach my $func (qw(install uninstall pm_to_blib install_default)) {
  26     can_ok(__PACKAGE__, $func);
  27 }
  28
  29 my $tmpdir = tempdir( DIR => 't', CLEANUP => 1 );
  30 chdir $tmpdir;
  31
  32 ok( setup_recurs(), 'setup' );
  33 END {
  34     ok( chdir File::Spec->updir, 'chdir ..');
  35     ok( teardown_recurs(), 'teardown' );
  36 }
  37
  38 chdir 'Big-Dummy';
  39
  40 local $ENV{PERL_INSTALL_QUIET};
  41
  42 my $stdout = tie *STDOUT, 'TieOut';
  43 pm_to_blib( { 'lib/Big/Dummy.pm' => 'blib/lib/Big/Dummy.pm' },
  44             'blib/lib/auto'
  45           );
  46 END { rmtree 'blib' }
  47
  48 ok( -d 'blib/lib',              'pm_to_blib created blib dir' );
  49 ok( -r 'blib/lib/Big/Dummy.pm', '  copied .pm file' );
  50 ok( -r 'blib/lib/auto',         '  created autosplit dir' );
  51 is( $stdout->read, "cp lib/Big/Dummy.pm blib/lib/Big/Dummy.pm\n" );
  52
  53
  54 pm_to_blib( { 'lib/Big/Dummy.pm' => 'blib/lib/Big/Dummy.pm' },
  55             'blib/lib/auto'
  56           );
  57 ok( -d 'blib/lib',              'second run, blib dir still there' );
  58 ok( -r 'blib/lib/Big/Dummy.pm', '  .pm file still there' );
  59 ok( -r 'blib/lib/auto',         '  autosplit still there' );
  60 is( $stdout->read, "Skip blib/lib/Big/Dummy.pm (unchanged)\n" );
  61
  62
  63 install( { 'blib/lib' => 'install-test/lib/perl',
  64            read   => 'install-test/packlist',
  65            write  => 'install-test/packlist'
  66          },
  67        0, 1);
  68 ok( ! -d 'install-test/lib/perl',        'install made dir (dry run)');
  69 ok( ! -r 'install-test/lib/perl/Big/Dummy.pm',
  70                                          '  .pm file installed (dry run)');
  71 ok( ! -r 'install-test/packlist',        '  packlist exists (dry run)');
  72
  73 install( { 'blib/lib' => 'install-test/lib/perl',
  74            read   => 'install-test/packlist',
  75            write  => 'install-test/packlist'
  76          } );
  77 ok( -d 'install-test/lib/perl',                 'install made dir' );
  78 ok( -r 'install-test/lib/perl/Big/Dummy.pm',    '  .pm file installed' );
  79 ok(!-r 'install-test/lib/perl/Big/Dummy.SKIP',  '  ignored .SKIP file' );
  80 ok( -r 'install-test/packlist',                 '  packlist exists' );
  81
  82 open(PACKLIST, 'install-test/packlist' );
  83 my %packlist = map { chomp;  ($_ => 1) } <PACKLIST>;
  84 close PACKLIST;
  85
  86 # On case-insensitive filesystems (ie. VMS), the keys of the packlist might
  87 # be lowercase. :(
  88 my $native_dummy = File::Spec->catfile(qw(install-test lib perl Big Dummy.pm));
  89 is( keys %packlist, 1 );
  90 is( lc((keys %packlist)[0]), lc $native_dummy, 'packlist written' );
  91
  92
  93 # Test UNINST=1 preserving same versions in other dirs.
  94 install( { 'blib/lib' => 'install-test/other_lib/perl',
  95            read   => 'install-test/packlist',
  96            write  => 'install-test/packlist'
  97          },
  98        0, 0, 1);
  99 ok( -d 'install-test/other_lib/perl',        'install made other dir' );
 100 ok( -r 'install-test/other_lib/perl/Big/Dummy.pm', '  .pm file installed' );
 101 ok( -r 'install-test/packlist',              '  packlist exists' );
 102 ok( -r 'install-test/lib/perl/Big/Dummy.pm', '  UNINST=1 preserved same' );
 103
 104
 105 chmod 0644, 'blib/lib/Big/Dummy.pm' or die $!;
 106 open(DUMMY, ">>blib/lib/Big/Dummy.pm") or die $!;
 107 print DUMMY "Extra stuff\n";
 108 close DUMMY;
 109
 110
 111 # Test UNINST=0 does not remove other versions in other dirs.
 112 {
 113   ok( -r 'install-test/lib/perl/Big/Dummy.pm', 'different install exists' );
 114
 115   local @INC = ('install-test/lib/perl');
 116   local $ENV{PERL5LIB} = '';
 117   install( { 'blib/lib' => 'install-test/other_lib/perl',
 118            read   => 'install-test/packlist',
 119            write  => 'install-test/packlist'
 120          },
 121        0, 0, 0);
 122   ok( -d 'install-test/other_lib/perl',        'install made other dir' );
 123   ok( -r 'install-test/other_lib/perl/Big/Dummy.pm', '  .pm file installed' );
 124   ok( -r 'install-test/packlist',              '  packlist exists' );
 125   ok( -r 'install-test/lib/perl/Big/Dummy.pm',
 126                                              '  UNINST=0 left different' );
 127 }
 128
 129 # Test UNINST=1 only warning when failing to remove an irrelevant shadow file
 130 {
 131   my $tfile='install-test/lib/perl/Big/Dummy.pm';
 132   local $ExtUtils::Install::Testing = $tfile;
 133   local @INC = ('install-test/other_lib/perl','install-test/lib/perl');
 134   local $ENV{PERL5LIB} = '';
 135   ok( -r $tfile, 'different install exists' );
 136   my @warn;
 137   local $SIG{__WARN__}=sub { push @warn, @_; return };
 138   my $ok=eval {
 139     install( { 'blib/lib' => 'install-test/other_lib/perl',
 140            read   => 'install-test/packlist',
 141            write  => 'install-test/packlist'
 142          },
 143        0, 0, 1);
 144     1
 145   };
 146   ok($ok,'  we didnt die');
 147   ok(0+@warn,"  we did warn");
 148   ok( -d 'install-test/other_lib/perl',        'install made other dir' );
 149   ok( -r 'install-test/other_lib/perl/Big/Dummy.pm', '  .pm file installed' );
 150   ok( -r 'install-test/packlist',              '  packlist exists' );
 151   ok( -r $tfile, '  UNINST=1 failed to remove different' );
 152
 153 }
 154
 155 # Test UNINST=1 dieing when failing to remove an relevant shadow file
 156 {
 157   my $tfile='install-test/lib/perl/Big/Dummy.pm';
 158   local $ExtUtils::Install::Testing = $tfile;
 159   local @INC = ('install-test/lib/perl','install-test/other_lib/perl');
 160   local $ENV{PERL5LIB} = '';
 161   ok( -r $tfile, 'different install exists' );
 162   my @warn;
 163   local $SIG{__WARN__}=sub { push @warn,@_; return };
 164   my $ok=eval {
 165     install( { 'blib/lib' => 'install-test/other_lib/perl',
 166            read   => 'install-test/packlist',
 167            write  => 'install-test/packlist'
 168          },
 169        0, 0, 1);
 170     1
 171   };
 172   ok(!$ok,'  we did die');
 173   ok(!@warn,"  we didnt warn");
 174   ok( -d 'install-test/other_lib/perl',        'install made other dir' );
 175   ok( -r 'install-test/other_lib/perl/Big/Dummy.pm', '  .pm file installed' );
 176   ok( -r 'install-test/packlist',              '  packlist exists' );
 177   ok( -r $tfile,'  UNINST=1 failed to remove different' );
 178 }
 179
 180 # Test UNINST=1 removing other versions in other dirs.
 181 {
 182   local @INC = ('install-test/lib/perl');
 183   local $ENV{PERL5LIB} = '';
 184   install( { 'blib/lib' => 'install-test/other_lib/perl',
 185            read   => 'install-test/packlist',
 186            write  => 'install-test/packlist'
 187          },
 188        0, 0, 1);
 189   ok( -d 'install-test/other_lib/perl',        'install made other dir' );
 190   ok( -r 'install-test/other_lib/perl/Big/Dummy.pm', '  .pm file installed' );
 191   ok( -r 'install-test/packlist',              '  packlist exists' );
 192   ok( !-r 'install-test/lib/perl/Big/Dummy.pm',
 193                                              '  UNINST=1 removed different' );
 194 }
 195
 196
 197 # do a -w style test, but based on just on file perms rather than UID
 198 # (on UNIX, root sees everything as writeable)
 199
 200 sub writeable {
 201     my ($file) = @_;
 202     my @stat = stat $file;
 203     return 0 unless defined $stat[2]; # mode
 204     return $stat[2] & 0200;
 205 }
 206
 207
 208 # really this test should be run on any platform that supports
 209 # symbolic and hard links, but this representative sample should do for
 210 # now
 211
 212
 213 # check hard and symbolic links
 214
 215 SKIP: {
 216     my $has_links =
 217         $^O =~ /^(aix|bsdos|darwin|freebsd|hpux|irix|linux|openbsd|solaris)$/;
 218     skip "(sym)links not supported", 8 unless $has_links;
 219
 220     install([ from_to => { 'blib/lib/' => 'install-links',
 221                            read   => 'install-links/packlist',
 222                            write  => 'install-links/packlist'
 223                          },
 224     ]);
 225
 226     # make orig file a hard link and check that it doesn't get messed up
 227
 228     my $bigdir = 'install-links/Big';
 229     ok link("$bigdir/Dummy.pm", "$bigdir/DummyHard.pm"),
 230         'link DummyHard.pm';
 231
 232     open(my $fh, ">>", "blib/lib/Big/Dummy.pm") or die $!;
 233     print $fh "Extra stuff 2\n";
 234     close $fh;
 235
 236     install([ from_to => { 'blib/lib/' => 'install-links',
 237                            read   => 'install-links/packlist',
 238                            write  => 'install-links/packlist'
 239                          },
 240     ]);
 241
 242     ok( !writeable("$bigdir/DummyHard.pm"), 'DummyHard.pm not writeable' );
 243
 244     use File::Compare;
 245     ok(compare("$bigdir/Dummy.pm", "$bigdir/DummyHard.pm"),
 246         "hard-linked file should be different");
 247
 248     # make orig file a symlink and check that it doesn't get messed up
 249
 250     ok rename("$bigdir/Dummy.pm", "$bigdir/DummyOrig.pm"),
 251         'rename DummyOrig.pm';
 252     ok symlink('DummyOrig.pm', "$bigdir/Dummy.pm"),
 253         'symlink Dummy.pm';
 254
 255
 256     open($fh, ">>", "blib/lib/Big/Dummy.pm") or die $!;
 257     print $fh "Extra stuff 3\n";
 258     close $fh;
 259
 260     install([ from_to => { 'blib/lib/' => 'install-links',
 261                            read   => 'install-links/packlist',
 262                            write  => 'install-links/packlist'
 263                          },
 264     ]);
 265
 266     ok( !writeable("$bigdir/DummyOrig.pm"), 'DummyOrig.pm not writeable' );
 267     ok( !-l "$bigdir/Dummy.pm", 'Dummy.pm not a link' );
 268     ok(compare("$bigdir/Dummy.pm", "$bigdir/DummyOrig.pm"),
 269         "orig file should be different");
 270 }