This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Delete superfluous lines; clarify identifier parsing.
[perl5.git] / pod / perldata.pod
1 =head1 NAME
2
3 perldata - Perl data types
4
5 =head1 DESCRIPTION
6
7 =head2 Variable names
8 X<variable, name> X<variable name> X<data type> X<type>
9
10 Perl has three built-in data types: scalars, arrays of scalars, and
11 associative arrays of scalars, known as "hashes".  A scalar is a 
12 single string (of any size, limited only by the available memory),
13 number, or a reference to something (which will be discussed
14 in L<perlref>).  Normal arrays are ordered lists of scalars indexed
15 by number, starting with 0.  Hashes are unordered collections of scalar 
16 values indexed by their associated string key.
17
18 Values are usually referred to by name, or through a named reference.
19 The first character of the name tells you to what sort of data
20 structure it refers.  The rest of the name tells you the particular
21 value to which it refers.  Usually this name is a single I<identifier>,
22 that is, a string beginning with a letter or underscore, and
23 containing letters, underscores, and digits.  In some cases, it may
24 be a chain of identifiers, separated by C<::> (or by the slightly
25 archaic C<'>); all but the last are interpreted as names of packages,
26 to locate the namespace in which to look up the final identifier
27 (see L<perlmod/Packages> for details).  For a more in-depth discussion
28 on identifiers, see L<Identifier parsing>.  It's possible to
29 substitute for a simple identifier, an expression that produces a reference
30 to the value at runtime.   This is described in more detail below
31 and in L<perlref>.
32 X<identifier>
33
34 Perl also has its own built-in variables whose names don't follow
35 these rules.  They have strange names so they don't accidentally
36 collide with one of your normal variables.  Strings that match
37 parenthesized parts of a regular expression are saved under names
38 containing only digits after the C<$> (see L<perlop> and L<perlre>).
39 In addition, several special variables that provide windows into
40 the inner working of Perl have names containing punctuation characters
41 and control characters.  These are documented in L<perlvar>.
42 X<variable, built-in>
43
44 Scalar values are always named with '$', even when referring to a
45 scalar that is part of an array or a hash.  The '$' symbol works
46 semantically like the English word "the" in that it indicates a
47 single value is expected.
48 X<scalar>
49
50     $days               # the simple scalar value "days"
51     $days[28]           # the 29th element of array @days
52     $days{'Feb'}        # the 'Feb' value from hash %days
53     $#days              # the last index of array @days
54
55 Entire arrays (and slices of arrays and hashes) are denoted by '@',
56 which works much as the word "these" or "those" does in English,
57 in that it indicates multiple values are expected.
58 X<array>
59
60     @days               # ($days[0], $days[1],... $days[n])
61     @days[3,4,5]        # same as ($days[3],$days[4],$days[5])
62     @days{'a','c'}      # same as ($days{'a'},$days{'c'})
63
64 Entire hashes are denoted by '%':
65 X<hash>
66
67     %days               # (key1, val1, key2, val2 ...)
68
69 In addition, subroutines are named with an initial '&', though this
70 is optional when unambiguous, just as the word "do" is often redundant
71 in English.  Symbol table entries can be named with an initial '*',
72 but you don't really care about that yet (if ever :-).
73
74 Every variable type has its own namespace, as do several
75 non-variable identifiers.  This means that you can, without fear
76 of conflict, use the same name for a scalar variable, an array, or
77 a hash--or, for that matter, for a filehandle, a directory handle, a
78 subroutine name, a format name, or a label.  This means that $foo
79 and @foo are two different variables.  It also means that C<$foo[1]>
80 is a part of @foo, not a part of $foo.  This may seem a bit weird,
81 but that's okay, because it is weird.
82 X<namespace>
83
84 Because variable references always start with '$', '@', or '%', the
85 "reserved" words aren't in fact reserved with respect to variable
86 names.  They I<are> reserved with respect to labels and filehandles,
87 however, which don't have an initial special character.  You can't
88 have a filehandle named "log", for instance.  Hint: you could say
89 C<open(LOG,'logfile')> rather than C<open(log,'logfile')>.  Using
90 uppercase filehandles also improves readability and protects you
91 from conflict with future reserved words.  Case I<is> significant--"FOO",
92 "Foo", and "foo" are all different names.  Names that start with a
93 letter or underscore may also contain digits and underscores.
94 X<identifier, case sensitivity>
95 X<case>
96
97 It is possible to replace such an alphanumeric name with an expression
98 that returns a reference to the appropriate type.  For a description
99 of this, see L<perlref>.
100
101 Names that start with a digit may contain only more digits.  Names
102 that do not start with a letter, underscore, digit or a caret (i.e.
103 a control character) are limited to one character, e.g.,  C<$%> or
104 C<$$>.  (Most of these one character names have a predefined
105 significance to Perl.  For instance, C<$$> is the current process
106 id.)
107
108 =head2 Identifier parsing
109 X<identifiers>
110
111 Up until Perl 5.18, the actual rules of what a valid identifier
112 was were a bit fuzzy.  However, in general, anything defined here should
113 work on previous versions of Perl, while the opposite -- edge cases
114 that work in previous versions, but aren't defined here -- probably
115 won't work on newer versions.
116 As an important side note, please note that the following only applies
117 to bareword identifiers as found in Perl source code, not identifiers
118 introduced through symbolic references, which have much fewer
119 restrictions.
120 If working under the effect of the C<use utf8;> pragma, the following
121 rules apply:
122
123     / (?[ ( \p{Word} & \p{XID_Start} ) + [_] ])
124       (?[ ( \p{Word} & \p{XID_Continue} ) ]) *    /x
125
126 That is, a "start" character followed by any number of "continue"
127 characters.  Perl requires every character in an identifier to also
128 match C<\w> (this prevents some problematic cases); and Perl
129 additionally accepts identfier names beginning with an underscore.
130
131 If not under C<use utf8>, the source is treated as ASCII + 128 extra
132 controls, and identifiers should match
133
134     / (?aa) (?!\d) \w+ /x
135
136 That is, any word character in the ASCII range, as long as the first
137 character is not a digit.
138
139 There are two package separators in Perl: A double colon (C<::>) and a single
140 quote (C<'>).  Normal identifiers can start or end with a double colon, and
141 can contain several parts delimited by double colons.
142 Single quotes have similar rules, but with the exception that they are not
143 legal at the end of an identifier: That is, C<$'foo> and C<$foo'bar> are
144 legal, but C<$foo'bar'> is not.
145
146 Additionally, if the identifier is preceded by a sigil --
147 that is, if the identifier is part of a variable name -- it
148 may optionally be enclosed in braces.
149
150 While you can mix double colons with singles quotes, the quotes must come
151 after the colons: C<$::::'foo> and C<$foo::'bar> are legal, but C<$::'::foo>
152 and C<$foo'::bar> are not.
153
154 Put together, a grammar to match a basic identifier becomes
155
156  /
157   (?(DEFINE)
158       (?<variable>
159           (?&sigil)
160           (?:
161                   (?&normal_identifier)
162               |   \{ \s* (?&normal_identifier) \s* \}
163           )
164       )
165       (?<normal_identifier>
166           (?: :: )* '?
167            (?&basic_identifier)
168            (?: (?= (?: :: )+ '? | (?: :: )* ' ) (?&normal_identifier) )?
169           (?: :: )*
170       )
171       (?<basic_identifier>
172         # is use utf8 on?
173           (?(?{ (caller(0))[8] & $utf8::hint_bits })
174               (?&Perl_XIDS) (?&Perl_XIDC)*
175             | (?aa) (?!\d) \w+
176           )
177       )
178       (?<sigil> [&*\$\@\%])
179       (?<Perl_XIDS> (?[ ( \p{Word} & \p{XID_Start} ) + [_] ]) )
180       (?<Perl_XIDC> (?[ \p{Word} & \p{XID_Continue} ]) )
181   )
182  /x
183
184 Meanwhile, special identifiers don't follow the above rules; For the most
185 part, all of the identifiers in this category have a special meaning given
186 by Perl.  Because they have special parsing rules, these generally can't be
187 fully-qualified.  They come in four forms:
188
189 =over
190
191 =item A sigil, followed solely by digits matching \p{POSIX_Digit}, like C<$0>,
192 C<$1>, or C<$10000>.
193
194 =item A sigil, followed by either a caret and a single POSIX uppercase letter,
195 like C<$^V> or C<$^W>, or a sigil followed by a literal control character
196 matching the C<\p{POSIX_Cntrl}> property. Due to a historical oddity, if not
197 running under C<use utf8>, the 128 extra controls in the C<[0x80-0xff]> range
198 may also be used in length one variables.
199
200 =item Similar to the above, a sigil, followed by bareword text in brackets,
201 where the first character is either a caret followed by an uppercase letter,
202 or a literal control, like C<${^GLOBAL_PHASE}> or C<${\7LOBAL_PHASE}>.
203
204 =item A sigil followed by a single character matching the C<\p{POSIX_Punct}>
205 property, like C<$!> or C<%+>.
206
207 =back
208
209 =head2 Context
210 X<context> X<scalar context> X<list context>
211
212 The interpretation of operations and values in Perl sometimes depends
213 on the requirements of the context around the operation or value.
214 There are two major contexts: list and scalar.  Certain operations
215 return list values in contexts wanting a list, and scalar values
216 otherwise.  If this is true of an operation it will be mentioned in
217 the documentation for that operation.  In other words, Perl overloads
218 certain operations based on whether the expected return value is
219 singular or plural.  Some words in English work this way, like "fish"
220 and "sheep".
221
222 In a reciprocal fashion, an operation provides either a scalar or a
223 list context to each of its arguments.  For example, if you say
224
225     int( <STDIN> )
226
227 the integer operation provides scalar context for the <>
228 operator, which responds by reading one line from STDIN and passing it
229 back to the integer operation, which will then find the integer value
230 of that line and return that.  If, on the other hand, you say
231
232     sort( <STDIN> )
233
234 then the sort operation provides list context for <>, which
235 will proceed to read every line available up to the end of file, and
236 pass that list of lines back to the sort routine, which will then
237 sort those lines and return them as a list to whatever the context
238 of the sort was.
239
240 Assignment is a little bit special in that it uses its left argument
241 to determine the context for the right argument.  Assignment to a
242 scalar evaluates the right-hand side in scalar context, while
243 assignment to an array or hash evaluates the righthand side in list
244 context.  Assignment to a list (or slice, which is just a list
245 anyway) also evaluates the right-hand side in list context.
246
247 When you use the C<use warnings> pragma or Perl's B<-w> command-line 
248 option, you may see warnings
249 about useless uses of constants or functions in "void context".
250 Void context just means the value has been discarded, such as a
251 statement containing only C<"fred";> or C<getpwuid(0);>.  It still
252 counts as scalar context for functions that care whether or not
253 they're being called in list context.
254
255 User-defined subroutines may choose to care whether they are being
256 called in a void, scalar, or list context.  Most subroutines do not
257 need to bother, though.  That's because both scalars and lists are
258 automatically interpolated into lists.  See L<perlfunc/wantarray>
259 for how you would dynamically discern your function's calling
260 context.
261
262 =head2 Scalar values
263 X<scalar> X<number> X<string> X<reference>
264
265 All data in Perl is a scalar, an array of scalars, or a hash of
266 scalars.  A scalar may contain one single value in any of three
267 different flavors: a number, a string, or a reference.  In general,
268 conversion from one form to another is transparent.  Although a
269 scalar may not directly hold multiple values, it may contain a
270 reference to an array or hash which in turn contains multiple values.
271
272 Scalars aren't necessarily one thing or another.  There's no place
273 to declare a scalar variable to be of type "string", type "number",
274 type "reference", or anything else.  Because of the automatic
275 conversion of scalars, operations that return scalars don't need
276 to care (and in fact, cannot care) whether their caller is looking
277 for a string, a number, or a reference.  Perl is a contextually
278 polymorphic language whose scalars can be strings, numbers, or
279 references (which includes objects).  Although strings and numbers
280 are considered pretty much the same thing for nearly all purposes,
281 references are strongly-typed, uncastable pointers with builtin
282 reference-counting and destructor invocation.
283
284 A scalar value is interpreted as FALSE in the Boolean sense
285 if it is undefined, the null string or the number 0 (or its
286 string equivalent, "0"), and TRUE if it is anything else.  The
287 Boolean context is just a special kind of scalar context where no 
288 conversion to a string or a number is ever performed.
289 X<boolean> X<bool> X<true> X<false> X<truth>
290
291 There are actually two varieties of null strings (sometimes referred
292 to as "empty" strings), a defined one and an undefined one.  The
293 defined version is just a string of length zero, such as C<"">.
294 The undefined version is the value that indicates that there is
295 no real value for something, such as when there was an error, or
296 at end of file, or when you refer to an uninitialized variable or
297 element of an array or hash.  Although in early versions of Perl,
298 an undefined scalar could become defined when first used in a
299 place expecting a defined value, this no longer happens except for
300 rare cases of autovivification as explained in L<perlref>.  You can
301 use the defined() operator to determine whether a scalar value is
302 defined (this has no meaning on arrays or hashes), and the undef()
303 operator to produce an undefined value.
304 X<defined> X<undefined> X<undef> X<null> X<string, null>
305
306 To find out whether a given string is a valid non-zero number, it's
307 sometimes enough to test it against both numeric 0 and also lexical
308 "0" (although this will cause noises if warnings are on).  That's 
309 because strings that aren't numbers count as 0, just as they do in B<awk>:
310
311     if ($str == 0 && $str ne "0")  {
312         warn "That doesn't look like a number";
313     }
314
315 That method may be best because otherwise you won't treat IEEE
316 notations like C<NaN> or C<Infinity> properly.  At other times, you
317 might prefer to determine whether string data can be used numerically
318 by calling the POSIX::strtod() function or by inspecting your string
319 with a regular expression (as documented in L<perlre>).
320
321     warn "has nondigits"        if     /\D/;
322     warn "not a natural number" unless /^\d+$/;             # rejects -3
323     warn "not an integer"       unless /^-?\d+$/;           # rejects +3
324     warn "not an integer"       unless /^[+-]?\d+$/;
325     warn "not a decimal number" unless /^-?\d+\.?\d*$/;     # rejects .2
326     warn "not a decimal number" unless /^-?(?:\d+(?:\.\d*)?|\.\d+)$/;
327     warn "not a C float"
328         unless /^([+-]?)(?=\d|\.\d)\d*(\.\d*)?([Ee]([+-]?\d+))?$/;
329
330 The length of an array is a scalar value.  You may find the length
331 of array @days by evaluating C<$#days>, as in B<csh>.  However, this
332 isn't the length of the array; it's the subscript of the last element,
333 which is a different value since there is ordinarily a 0th element.
334 Assigning to C<$#days> actually changes the length of the array.
335 Shortening an array this way destroys intervening values.  Lengthening
336 an array that was previously shortened does not recover values
337 that were in those elements.
338 X<$#> X<array, length>
339
340 You can also gain some minuscule measure of efficiency by pre-extending
341 an array that is going to get big.  You can also extend an array
342 by assigning to an element that is off the end of the array.  You
343 can truncate an array down to nothing by assigning the null list
344 () to it.  The following are equivalent:
345
346     @whatever = ();
347     $#whatever = -1;
348
349 If you evaluate an array in scalar context, it returns the length
350 of the array.  (Note that this is not true of lists, which return
351 the last value, like the C comma operator, nor of built-in functions,
352 which return whatever they feel like returning.)  The following is
353 always true:
354 X<array, length>
355
356     scalar(@whatever) == $#whatever + 1;
357
358 Some programmers choose to use an explicit conversion so as to 
359 leave nothing to doubt:
360
361     $element_count = scalar(@whatever);
362
363 If you evaluate a hash in scalar context, it returns false if the
364 hash is empty.  If there are any key/value pairs, it returns true;
365 more precisely, the value returned is a string consisting of the
366 number of used buckets and the number of allocated buckets, separated
367 by a slash.  This is pretty much useful only to find out whether
368 Perl's internal hashing algorithm is performing poorly on your data
369 set.  For example, you stick 10,000 things in a hash, but evaluating
370 %HASH in scalar context reveals C<"1/16">, which means only one out
371 of sixteen buckets has been touched, and presumably contains all
372 10,000 of your items.  This isn't supposed to happen.  If a tied hash
373 is evaluated in scalar context, the C<SCALAR> method is called (with a
374 fallback to C<FIRSTKEY>).
375 X<hash, scalar context> X<hash, bucket> X<bucket>
376
377 You can preallocate space for a hash by assigning to the keys() function.
378 This rounds up the allocated buckets to the next power of two:
379
380     keys(%users) = 1000;                # allocate 1024 buckets
381
382 =head2 Scalar value constructors
383 X<scalar, literal> X<scalar, constant>
384
385 Numeric literals are specified in any of the following floating point or
386 integer formats:
387
388     12345
389     12345.67
390     .23E-10             # a very small number
391     3.14_15_92          # a very important number
392     4_294_967_296       # underscore for legibility
393     0xff                # hex
394     0xdead_beef         # more hex   
395     0377                # octal (only numbers, begins with 0)
396     0b011011            # binary
397
398 You are allowed to use underscores (underbars) in numeric literals
399 between digits for legibility (but not multiple underscores in a row:
400 C<23__500> is not legal; C<23_500> is).
401 You could, for example, group binary
402 digits by threes (as for a Unix-style mode argument such as 0b110_100_100)
403 or by fours (to represent nibbles, as in 0b1010_0110) or in other groups.
404 X<number, literal>
405
406 String literals are usually delimited by either single or double
407 quotes.  They work much like quotes in the standard Unix shells:
408 double-quoted string literals are subject to backslash and variable
409 substitution; single-quoted strings are not (except for C<\'> and
410 C<\\>).  The usual C-style backslash rules apply for making
411 characters such as newline, tab, etc., as well as some more exotic
412 forms.  See L<perlop/"Quote and Quote-like Operators"> for a list.
413 X<string, literal>
414
415 Hexadecimal, octal, or binary, representations in string literals
416 (e.g. '0xff') are not automatically converted to their integer
417 representation.  The hex() and oct() functions make these conversions
418 for you.  See L<perlfunc/hex> and L<perlfunc/oct> for more details.
419
420 You can also embed newlines directly in your strings, i.e., they can end
421 on a different line than they begin.  This is nice, but if you forget
422 your trailing quote, the error will not be reported until Perl finds
423 another line containing the quote character, which may be much further
424 on in the script.  Variable substitution inside strings is limited to
425 scalar variables, arrays, and array or hash slices.  (In other words,
426 names beginning with $ or @, followed by an optional bracketed
427 expression as a subscript.)  The following code segment prints out "The
428 price is $Z<>100."
429 X<interpolation>
430
431     $Price = '$100';    # not interpolated
432     print "The price is $Price.\n";     # interpolated
433
434 There is no double interpolation in Perl, so the C<$100> is left as is.
435
436 By default floating point numbers substituted inside strings use the
437 dot (".")  as the decimal separator.  If C<use locale> is in effect,
438 and POSIX::setlocale() has been called, the character used for the
439 decimal separator is affected by the LC_NUMERIC locale.
440 See L<perllocale> and L<POSIX>.
441
442 As in some shells, you can enclose the variable name in braces to
443 disambiguate it from following alphanumerics (and underscores).
444 You must also do
445 this when interpolating a variable into a string to separate the
446 variable name from a following double-colon or an apostrophe, since
447 these would be otherwise treated as a package separator:
448 X<interpolation>
449
450     $who = "Larry";
451     print PASSWD "${who}::0:0:Superuser:/:/bin/perl\n";
452     print "We use ${who}speak when ${who}'s here.\n";
453
454 Without the braces, Perl would have looked for a $whospeak, a
455 C<$who::0>, and a C<$who's> variable.  The last two would be the
456 $0 and the $s variables in the (presumably) non-existent package
457 C<who>.
458
459 In fact, a simple identifier within such curlies is forced to be
460 a string, and likewise within a hash subscript. Neither need
461 quoting.  Our earlier example, C<$days{'Feb'}> can be written as
462 C<$days{Feb}> and the quotes will be assumed automatically.  But
463 anything more complicated in the subscript will be interpreted as an
464 expression.  This means for example that C<$version{2.0}++> is
465 equivalent to C<$version{2}++>, not to C<$version{'2.0'}++>.
466
467 =head3 Version Strings
468 X<version string> X<vstring> X<v-string>
469
470 A literal of the form C<v1.20.300.4000> is parsed as a string composed
471 of characters with the specified ordinals.  This form, known as
472 v-strings, provides an alternative, more readable way to construct
473 strings, rather than use the somewhat less readable interpolation form
474 C<"\x{1}\x{14}\x{12c}\x{fa0}">.  This is useful for representing
475 Unicode strings, and for comparing version "numbers" using the string
476 comparison operators, C<cmp>, C<gt>, C<lt> etc.  If there are two or
477 more dots in the literal, the leading C<v> may be omitted.
478
479     print v9786;              # prints SMILEY, "\x{263a}"
480     print v102.111.111;       # prints "foo"
481     print 102.111.111;        # same
482
483 Such literals are accepted by both C<require> and C<use> for
484 doing a version check.  Note that using the v-strings for IPv4
485 addresses is not portable unless you also use the
486 inet_aton()/inet_ntoa() routines of the Socket package.
487
488 Note that since Perl 5.8.1 the single-number v-strings (like C<v65>)
489 are not v-strings before the C<< => >> operator (which is usually used
490 to separate a hash key from a hash value); instead they are interpreted
491 as literal strings ('v65').  They were v-strings from Perl 5.6.0 to
492 Perl 5.8.0, but that caused more confusion and breakage than good.
493 Multi-number v-strings like C<v65.66> and C<65.66.67> continue to
494 be v-strings always.
495
496 =head3 Special Literals
497 X<special literal> X<__END__> X<__DATA__> X<END> X<DATA>
498 X<end> X<data> X<^D> X<^Z>
499
500 The special literals __FILE__, __LINE__, and __PACKAGE__
501 represent the current filename, line number, and package name at that
502 point in your program.  __SUB__ gives a reference to the current
503 subroutine.  They may be used only as separate tokens; they
504 will not be interpolated into strings.  If there is no current package
505 (due to an empty C<package;> directive), __PACKAGE__ is the undefined
506 value.  (But the empty C<package;> is no longer supported, as of version
507 5.10.)  Outside of a subroutine, __SUB__ is the undefined value.  __SUB__
508 is only available in 5.16 or higher, and only with a C<use v5.16> or
509 C<use feature "current_sub"> declaration.
510 X<__FILE__> X<__LINE__> X<__PACKAGE__> X<__SUB__>
511 X<line> X<file> X<package>
512
513 The two control characters ^D and ^Z, and the tokens __END__ and __DATA__
514 may be used to indicate the logical end of the script before the actual
515 end of file.  Any following text is ignored.
516
517 Text after __DATA__ may be read via the filehandle C<PACKNAME::DATA>,
518 where C<PACKNAME> is the package that was current when the __DATA__
519 token was encountered.  The filehandle is left open pointing to the
520 line after __DATA__.  The program should C<close DATA> when it is done
521 reading from it.  (Leaving it open leaks filehandles if the module is
522 reloaded for any reason, so it's a safer practice to close it.)  For
523 compatibility with older scripts written before __DATA__ was
524 introduced, __END__ behaves like __DATA__ in the top level script (but
525 not in files loaded with C<require> or C<do>) and leaves the remaining
526 contents of the file accessible via C<main::DATA>.
527
528 See L<SelfLoader> for more description of __DATA__, and
529 an example of its use.  Note that you cannot read from the DATA
530 filehandle in a BEGIN block: the BEGIN block is executed as soon
531 as it is seen (during compilation), at which point the corresponding
532 __DATA__ (or __END__) token has not yet been seen.
533
534 =head3 Barewords
535 X<bareword>
536
537 A word that has no other interpretation in the grammar will
538 be treated as if it were a quoted string.  These are known as
539 "barewords".  As with filehandles and labels, a bareword that consists
540 entirely of lowercase letters risks conflict with future reserved
541 words, and if you use the C<use warnings> pragma or the B<-w> switch, 
542 Perl will warn you about any such words.  Perl limits barewords (like
543 identifiers) to about 250 characters.  Future versions of Perl are likely
544 to eliminate these arbitrary limitations.
545
546 Some people may wish to outlaw barewords entirely.  If you
547 say
548
549     use strict 'subs';
550
551 then any bareword that would NOT be interpreted as a subroutine call
552 produces a compile-time error instead.  The restriction lasts to the
553 end of the enclosing block.  An inner block may countermand this
554 by saying C<no strict 'subs'>.
555
556 =head3 Array Interpolation
557 X<array, interpolation> X<interpolation, array> X<$">
558
559 Arrays and slices are interpolated into double-quoted strings
560 by joining the elements with the delimiter specified in the C<$">
561 variable (C<$LIST_SEPARATOR> if "use English;" is specified), 
562 space by default.  The following are equivalent:
563
564     $temp = join($", @ARGV);
565     system "echo $temp";
566
567     system "echo @ARGV";
568
569 Within search patterns (which also undergo double-quotish substitution)
570 there is an unfortunate ambiguity:  Is C</$foo[bar]/> to be interpreted as
571 C</${foo}[bar]/> (where C<[bar]> is a character class for the regular
572 expression) or as C</${foo[bar]}/> (where C<[bar]> is the subscript to array
573 @foo)?  If @foo doesn't otherwise exist, then it's obviously a
574 character class.  If @foo exists, Perl takes a good guess about C<[bar]>,
575 and is almost always right.  If it does guess wrong, or if you're just
576 plain paranoid, you can force the correct interpretation with curly
577 braces as above.
578
579 If you're looking for the information on how to use here-documents,
580 which used to be here, that's been moved to
581 L<perlop/Quote and Quote-like Operators>.
582
583 =head2 List value constructors
584 X<list>
585
586 List values are denoted by separating individual values by commas
587 (and enclosing the list in parentheses where precedence requires it):
588
589     (LIST)
590
591 In a context not requiring a list value, the value of what appears
592 to be a list literal is simply the value of the final element, as
593 with the C comma operator.  For example,
594
595     @foo = ('cc', '-E', $bar);
596
597 assigns the entire list value to array @foo, but
598
599     $foo = ('cc', '-E', $bar);
600
601 assigns the value of variable $bar to the scalar variable $foo.
602 Note that the value of an actual array in scalar context is the
603 length of the array; the following assigns the value 3 to $foo:
604
605     @foo = ('cc', '-E', $bar);
606     $foo = @foo;                # $foo gets 3
607
608 You may have an optional comma before the closing parenthesis of a
609 list literal, so that you can say:
610
611     @foo = (
612         1,
613         2,
614         3,
615     );
616
617 To use a here-document to assign an array, one line per element,
618 you might use an approach like this:
619
620     @sauces = <<End_Lines =~ m/(\S.*\S)/g;
621         normal tomato
622         spicy tomato
623         green chile
624         pesto
625         white wine
626     End_Lines
627
628 LISTs do automatic interpolation of sublists.  That is, when a LIST is
629 evaluated, each element of the list is evaluated in list context, and
630 the resulting list value is interpolated into LIST just as if each
631 individual element were a member of LIST.  Thus arrays and hashes lose their
632 identity in a LIST--the list
633
634     (@foo,@bar,&SomeSub,%glarch)
635
636 contains all the elements of @foo followed by all the elements of @bar,
637 followed by all the elements returned by the subroutine named SomeSub 
638 called in list context, followed by the key/value pairs of %glarch.
639 To make a list reference that does I<NOT> interpolate, see L<perlref>.
640
641 The null list is represented by ().  Interpolating it in a list
642 has no effect.  Thus ((),(),()) is equivalent to ().  Similarly,
643 interpolating an array with no elements is the same as if no
644 array had been interpolated at that point.
645
646 This interpolation combines with the facts that the opening
647 and closing parentheses are optional (except when necessary for
648 precedence) and lists may end with an optional comma to mean that
649 multiple commas within lists are legal syntax.  The list C<1,,3> is a
650 concatenation of two lists, C<1,> and C<3>, the first of which ends
651 with that optional comma.  C<1,,3> is C<(1,),(3)> is C<1,3> (And
652 similarly for C<1,,,3> is C<(1,),(,),3> is C<1,3> and so on.)  Not that
653 we'd advise you to use this obfuscation.
654
655 A list value may also be subscripted like a normal array.  You must
656 put the list in parentheses to avoid ambiguity.  For example:
657
658     # Stat returns list value.
659     $time = (stat($file))[8];
660
661     # SYNTAX ERROR HERE.
662     $time = stat($file)[8];  # OOPS, FORGOT PARENTHESES
663
664     # Find a hex digit.
665     $hexdigit = ('a','b','c','d','e','f')[$digit-10];
666
667     # A "reverse comma operator".
668     return (pop(@foo),pop(@foo))[0];
669
670 Lists may be assigned to only when each element of the list
671 is itself legal to assign to:
672
673     ($a, $b, $c) = (1, 2, 3);
674
675     ($map{'red'}, $map{'blue'}, $map{'green'}) = (0x00f, 0x0f0, 0xf00);
676
677 An exception to this is that you may assign to C<undef> in a list.
678 This is useful for throwing away some of the return values of a
679 function:
680
681     ($dev, $ino, undef, undef, $uid, $gid) = stat($file);
682
683 List assignment in scalar context returns the number of elements
684 produced by the expression on the right side of the assignment:
685
686     $x = (($foo,$bar) = (3,2,1));       # set $x to 3, not 2
687     $x = (($foo,$bar) = f());           # set $x to f()'s return count
688
689 This is handy when you want to do a list assignment in a Boolean
690 context, because most list functions return a null list when finished,
691 which when assigned produces a 0, which is interpreted as FALSE.
692
693 It's also the source of a useful idiom for executing a function or
694 performing an operation in list context and then counting the number of
695 return values, by assigning to an empty list and then using that
696 assignment in scalar context.  For example, this code:
697
698     $count = () = $string =~ /\d+/g;
699
700 will place into $count the number of digit groups found in $string.
701 This happens because the pattern match is in list context (since it
702 is being assigned to the empty list), and will therefore return a list
703 of all matching parts of the string.  The list assignment in scalar
704 context will translate that into the number of elements (here, the
705 number of times the pattern matched) and assign that to $count.  Note
706 that simply using
707
708     $count = $string =~ /\d+/g;
709
710 would not have worked, since a pattern match in scalar context will
711 only return true or false, rather than a count of matches.
712
713 The final element of a list assignment may be an array or a hash:
714
715     ($a, $b, @rest) = split;
716     my($a, $b, %rest) = @_;
717
718 You can actually put an array or hash anywhere in the list, but the first one
719 in the list will soak up all the values, and anything after it will become
720 undefined.  This may be useful in a my() or local().
721
722 A hash can be initialized using a literal list holding pairs of
723 items to be interpreted as a key and a value:
724
725     # same as map assignment above
726     %map = ('red',0x00f,'blue',0x0f0,'green',0xf00);
727
728 While literal lists and named arrays are often interchangeable, that's
729 not the case for hashes.  Just because you can subscript a list value like
730 a normal array does not mean that you can subscript a list value as a
731 hash.  Likewise, hashes included as parts of other lists (including
732 parameters lists and return lists from functions) always flatten out into
733 key/value pairs.  That's why it's good to use references sometimes.
734
735 It is often more readable to use the C<< => >> operator between key/value
736 pairs.  The C<< => >> operator is mostly just a more visually distinctive
737 synonym for a comma, but it also arranges for its left-hand operand to be
738 interpreted as a string if it's a bareword that would be a legal simple
739 identifier.  C<< => >> doesn't quote compound identifiers, that contain
740 double colons.  This makes it nice for initializing hashes:
741
742     %map = (
743                  red   => 0x00f,
744                  blue  => 0x0f0,
745                  green => 0xf00,
746    );
747
748 or for initializing hash references to be used as records:
749
750     $rec = {
751                 witch => 'Mable the Merciless',
752                 cat   => 'Fluffy the Ferocious',
753                 date  => '10/31/1776',
754     };
755
756 or for using call-by-named-parameter to complicated functions:
757
758    $field = $query->radio_group(
759                name      => 'group_name',
760                values    => ['eenie','meenie','minie'],
761                default   => 'meenie',
762                linebreak => 'true',
763                labels    => \%labels
764    );
765
766 Note that just because a hash is initialized in that order doesn't
767 mean that it comes out in that order.  See L<perlfunc/sort> for examples
768 of how to arrange for an output ordering.
769
770 If a key appears more than once in the initializer list of a hash, the last
771 occurrence wins:
772
773     %circle = (
774                   center => [5, 10],
775                   center => [27, 9],
776                   radius => 100,
777                   color => [0xDF, 0xFF, 0x00],
778                   radius => 54,
779     );
780
781     # same as
782     %circle = (
783                   center => [27, 9],
784                   color => [0xDF, 0xFF, 0x00],
785                   radius => 54,
786     );
787
788 This can be used to provide overridable configuration defaults:
789
790     # values in %args take priority over %config_defaults
791     %config = (%config_defaults, %args);
792
793 =head2 Subscripts
794
795 An array can be accessed one scalar at a
796 time by specifying a dollar sign (C<$>), then the
797 name of the array (without the leading C<@>), then the subscript inside
798 square brackets.  For example:
799
800     @myarray = (5, 50, 500, 5000);
801     print "The Third Element is", $myarray[2], "\n";
802
803 The array indices start with 0.  A negative subscript retrieves its 
804 value from the end.  In our example, C<$myarray[-1]> would have been 
805 5000, and C<$myarray[-2]> would have been 500.
806
807 Hash subscripts are similar, only instead of square brackets curly brackets
808 are used.  For example:
809
810     %scientists = 
811     (
812         "Newton" => "Isaac",
813         "Einstein" => "Albert",
814         "Darwin" => "Charles",
815         "Feynman" => "Richard",
816     );
817
818     print "Darwin's First Name is ", $scientists{"Darwin"}, "\n";
819
820 You can also subscript a list to get a single element from it:
821
822     $dir = (getpwnam("daemon"))[7];
823
824 =head2 Multi-dimensional array emulation
825
826 Multidimensional arrays may be emulated by subscripting a hash with a
827 list.  The elements of the list are joined with the subscript separator
828 (see L<perlvar/$;>).
829
830     $foo{$a,$b,$c}
831
832 is equivalent to
833
834     $foo{join($;, $a, $b, $c)}
835
836 The default subscript separator is "\034", the same as SUBSEP in B<awk>.
837
838 =head2 Slices
839 X<slice> X<array, slice> X<hash, slice>
840
841 A slice accesses several elements of a list, an array, or a hash
842 simultaneously using a list of subscripts.  It's more convenient
843 than writing out the individual elements as a list of separate
844 scalar values.
845
846     ($him, $her)   = @folks[0,-1];              # array slice
847     @them          = @folks[0 .. 3];            # array slice
848     ($who, $home)  = @ENV{"USER", "HOME"};      # hash slice
849     ($uid, $dir)   = (getpwnam("daemon"))[2,7]; # list slice
850
851 Since you can assign to a list of variables, you can also assign to
852 an array or hash slice.
853
854     @days[3..5]    = qw/Wed Thu Fri/;
855     @colors{'red','blue','green'} 
856                    = (0xff0000, 0x0000ff, 0x00ff00);
857     @folks[0, -1]  = @folks[-1, 0];
858
859 The previous assignments are exactly equivalent to
860
861     ($days[3], $days[4], $days[5]) = qw/Wed Thu Fri/;
862     ($colors{'red'}, $colors{'blue'}, $colors{'green'})
863                    = (0xff0000, 0x0000ff, 0x00ff00);
864     ($folks[0], $folks[-1]) = ($folks[-1], $folks[0]);
865
866 Since changing a slice changes the original array or hash that it's
867 slicing, a C<foreach> construct will alter some--or even all--of the
868 values of the array or hash.
869
870     foreach (@array[ 4 .. 10 ]) { s/peter/paul/ } 
871
872     foreach (@hash{qw[key1 key2]}) {
873         s/^\s+//;           # trim leading whitespace
874         s/\s+$//;           # trim trailing whitespace
875         s/(\w+)/\u\L$1/g;   # "titlecase" words
876     }
877
878 A slice of an empty list is still an empty list.  Thus:
879
880     @a = ()[1,0];           # @a has no elements
881     @b = (@a)[0,1];         # @b has no elements
882
883 But:
884
885     @a = (1)[1,0];          # @a has two elements
886     @b = (1,undef)[1,0,2];  # @b has three elements
887
888 More generally, a slice yields the empty list if it indexes only
889 beyond the end of a list:
890
891     @a = (1)[  1,2];        # @a has no elements
892     @b = (1)[0,1,2];        # @b has three elements
893
894 This makes it easy to write loops that terminate when a null list
895 is returned:
896
897     while ( ($home, $user) = (getpwent)[7,0]) {
898         printf "%-8s %s\n", $user, $home;
899     }
900
901 As noted earlier in this document, the scalar sense of list assignment
902 is the number of elements on the right-hand side of the assignment.
903 The null list contains no elements, so when the password file is
904 exhausted, the result is 0, not 2.
905
906 Slices in scalar context return the last item of the slice.
907
908     @a = qw/first second third/;
909     %h = (first => 'A', second => 'B');
910     $t = @a[0, 1];                  # $t is now 'second'
911     $u = @h{'first', 'second'};     # $u is now 'B'
912
913 If you're confused about why you use an '@' there on a hash slice
914 instead of a '%', think of it like this.  The type of bracket (square
915 or curly) governs whether it's an array or a hash being looked at.
916 On the other hand, the leading symbol ('$' or '@') on the array or
917 hash indicates whether you are getting back a singular value (a
918 scalar) or a plural one (a list).
919
920 =head2 Typeglobs and Filehandles
921 X<typeglob> X<filehandle> X<*>
922
923 Perl uses an internal type called a I<typeglob> to hold an entire
924 symbol table entry.  The type prefix of a typeglob is a C<*>, because
925 it represents all types.  This used to be the preferred way to
926 pass arrays and hashes by reference into a function, but now that
927 we have real references, this is seldom needed.  
928
929 The main use of typeglobs in modern Perl is create symbol table aliases.
930 This assignment:
931
932     *this = *that;
933
934 makes $this an alias for $that, @this an alias for @that, %this an alias
935 for %that, &this an alias for &that, etc.  Much safer is to use a reference.
936 This:
937
938     local *Here::blue = \$There::green;
939
940 temporarily makes $Here::blue an alias for $There::green, but doesn't
941 make @Here::blue an alias for @There::green, or %Here::blue an alias for
942 %There::green, etc.  See L<perlmod/"Symbol Tables"> for more examples
943 of this.  Strange though this may seem, this is the basis for the whole
944 module import/export system.
945
946 Another use for typeglobs is to pass filehandles into a function or
947 to create new filehandles.  If you need to use a typeglob to save away
948 a filehandle, do it this way:
949
950     $fh = *STDOUT;
951
952 or perhaps as a real reference, like this:
953
954     $fh = \*STDOUT;
955
956 See L<perlsub> for examples of using these as indirect filehandles
957 in functions.
958
959 Typeglobs are also a way to create a local filehandle using the local()
960 operator.  These last until their block is exited, but may be passed back.
961 For example:
962
963     sub newopen {
964         my $path = shift;
965         local  *FH;  # not my!
966         open   (FH, $path)          or  return undef;
967         return *FH;
968     }
969     $fh = newopen('/etc/passwd');
970
971 Now that we have the C<*foo{THING}> notation, typeglobs aren't used as much
972 for filehandle manipulations, although they're still needed to pass brand
973 new file and directory handles into or out of functions.  That's because
974 C<*HANDLE{IO}> only works if HANDLE has already been used as a handle.
975 In other words, C<*FH> must be used to create new symbol table entries;
976 C<*foo{THING}> cannot.  When in doubt, use C<*FH>.
977
978 All functions that are capable of creating filehandles (open(),
979 opendir(), pipe(), socketpair(), sysopen(), socket(), and accept())
980 automatically create an anonymous filehandle if the handle passed to
981 them is an uninitialized scalar variable.  This allows the constructs
982 such as C<open(my $fh, ...)> and C<open(local $fh,...)> to be used to
983 create filehandles that will conveniently be closed automatically when
984 the scope ends, provided there are no other references to them.  This
985 largely eliminates the need for typeglobs when opening filehandles
986 that must be passed around, as in the following example:
987
988     sub myopen {
989         open my $fh, "@_"
990              or die "Can't open '@_': $!";
991         return $fh;
992     }
993
994     {
995         my $f = myopen("</etc/motd");
996         print <$f>;
997         # $f implicitly closed here
998     }
999
1000 Note that if an initialized scalar variable is used instead the
1001 result is different: C<my $fh='zzz'; open($fh, ...)> is equivalent
1002 to C<open( *{'zzz'}, ...)>.
1003 C<use strict 'refs'> forbids such practice.
1004
1005 Another way to create anonymous filehandles is with the Symbol
1006 module or with the IO::Handle module and its ilk.  These modules
1007 have the advantage of not hiding different types of the same name
1008 during the local().  See the bottom of L<perlfunc/open> for an
1009 example.
1010
1011 =head1 SEE ALSO
1012
1013 See L<perlvar> for a description of Perl's built-in variables and
1014 a discussion of legal variable names.  See L<perlref>, L<perlsub>,
1015 and L<perlmod/"Symbol Tables"> for more discussion on typeglobs and
1016 the C<*foo{THING}> syntax.