This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
[perl #96228] perlop misdocuments ${ qr/x/ } as undef
[perl5.git] / pod / perlop.pod
1 =head1 NAME
2 X<operator>
3
4 perlop - Perl operators and precedence
5
6 =head1 DESCRIPTION
7
8 =head2 Operator Precedence and Associativity
9 X<operator, precedence> X<precedence> X<associativity>
10
11 Operator precedence and associativity work in Perl more or less like
12 they do in mathematics.
13
14 I<Operator precedence> means some operators are evaluated before
15 others.  For example, in C<2 + 4 * 5>, the multiplication has higher
16 precedence so C<4 * 5> is evaluated first yielding C<2 + 20 ==
17 22> and not C<6 * 5 == 30>.
18
19 I<Operator associativity> defines what happens if a sequence of the
20 same operators is used one after another: whether the evaluator will
21 evaluate the left operations first or the right.  For example, in C<8
22 - 4 - 2>, subtraction is left associative so Perl evaluates the
23 expression left to right.  C<8 - 4> is evaluated first making the
24 expression C<4 - 2 == 2> and not C<8 - 2 == 6>.
25
26 Perl operators have the following associativity and precedence,
27 listed from highest precedence to lowest.  Operators borrowed from
28 C keep the same precedence relationship with each other, even where
29 C's precedence is slightly screwy.  (This makes learning Perl easier
30 for C folks.)  With very few exceptions, these all operate on scalar
31 values only, not array values.
32
33     left        terms and list operators (leftward)
34     left        ->
35     nonassoc    ++ --
36     right       **
37     right       ! ~ \ and unary + and -
38     left        =~ !~
39     left        * / % x
40     left        + - .
41     left        << >>
42     nonassoc    named unary operators
43     nonassoc    < > <= >= lt gt le ge
44     nonassoc    == != <=> eq ne cmp ~~
45     left        &
46     left        | ^
47     left        &&
48     left        || //
49     nonassoc    ..  ...
50     right       ?:
51     right       = += -= *= etc.
52     left        , =>
53     nonassoc    list operators (rightward)
54     right       not
55     left        and
56     left        or xor
57
58 In the following sections, these operators are covered in precedence order.
59
60 Many operators can be overloaded for objects.  See L<overload>.
61
62 =head2 Terms and List Operators (Leftward)
63 X<list operator> X<operator, list> X<term>
64
65 A TERM has the highest precedence in Perl.  They include variables,
66 quote and quote-like operators, any expression in parentheses,
67 and any function whose arguments are parenthesized.  Actually, there
68 aren't really functions in this sense, just list operators and unary
69 operators behaving as functions because you put parentheses around
70 the arguments.  These are all documented in L<perlfunc>.
71
72 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
73 is followed by a left parenthesis as the next token, the operator and
74 arguments within parentheses are taken to be of highest precedence,
75 just like a normal function call.
76
77 In the absence of parentheses, the precedence of list operators such as
78 C<print>, C<sort>, or C<chmod> is either very high or very low depending on
79 whether you are looking at the left side or the right side of the operator.
80 For example, in
81
82     @ary = (1, 3, sort 4, 2);
83     print @ary;         # prints 1324
84
85 the commas on the right of the sort are evaluated before the sort,
86 but the commas on the left are evaluated after.  In other words,
87 list operators tend to gobble up all arguments that follow, and
88 then act like a simple TERM with regard to the preceding expression.
89 Be careful with parentheses:
90
91     # These evaluate exit before doing the print:
92     print($foo, exit);  # Obviously not what you want.
93     print $foo, exit;   # Nor is this.
94
95     # These do the print before evaluating exit:
96     (print $foo), exit; # This is what you want.
97     print($foo), exit;  # Or this.
98     print ($foo), exit; # Or even this.
99
100 Also note that
101
102     print ($foo & 255) + 1, "\n";
103
104 probably doesn't do what you expect at first glance.  The parentheses
105 enclose the argument list for C<print> which is evaluated (printing
106 the result of C<$foo & 255>).  Then one is added to the return value
107 of C<print> (usually 1).  The result is something like this:
108
109     1 + 1, "\n";    # Obviously not what you meant.
110
111 To do what you meant properly, you must write:
112
113     print(($foo & 255) + 1, "\n");
114
115 See L<Named Unary Operators> for more discussion of this.
116
117 Also parsed as terms are the C<do {}> and C<eval {}> constructs, as
118 well as subroutine and method calls, and the anonymous
119 constructors C<[]> and C<{}>.
120
121 See also L<Quote and Quote-like Operators> toward the end of this section,
122 as well as L</"I/O Operators">.
123
124 =head2 The Arrow Operator
125 X<arrow> X<dereference> X<< -> >>
126
127 "C<< -> >>" is an infix dereference operator, just as it is in C
128 and C++.  If the right side is either a C<[...]>, C<{...}>, or a
129 C<(...)> subscript, then the left side must be either a hard or
130 symbolic reference to an array, a hash, or a subroutine respectively.
131 (Or technically speaking, a location capable of holding a hard
132 reference, if it's an array or hash reference being used for
133 assignment.)  See L<perlreftut> and L<perlref>.
134
135 Otherwise, the right side is a method name or a simple scalar
136 variable containing either the method name or a subroutine reference,
137 and the left side must be either an object (a blessed reference)
138 or a class name (that is, a package name).  See L<perlobj>.
139
140 =head2 Auto-increment and Auto-decrement
141 X<increment> X<auto-increment> X<++> X<decrement> X<auto-decrement> X<-->
142
143 "++" and "--" work as in C.  That is, if placed before a variable,
144 they increment or decrement the variable by one before returning the
145 value, and if placed after, increment or decrement after returning the
146 value.
147
148     $i = 0;  $j = 0;
149     print $i++;  # prints 0
150     print ++$j;  # prints 1
151
152 Note that just as in C, Perl doesn't define B<when> the variable is
153 incremented or decremented. You just know it will be done sometime
154 before or after the value is returned. This also means that modifying
155 a variable twice in the same statement will lead to undefined behavior.
156 Avoid statements like:
157
158     $i = $i ++;
159     print ++ $i + $i ++;
160
161 Perl will not guarantee what the result of the above statements is.
162
163 The auto-increment operator has a little extra builtin magic to it.  If
164 you increment a variable that is numeric, or that has ever been used in
165 a numeric context, you get a normal increment.  If, however, the
166 variable has been used in only string contexts since it was set, and
167 has a value that is not the empty string and matches the pattern
168 C</^[a-zA-Z]*[0-9]*\z/>, the increment is done as a string, preserving each
169 character within its range, with carry:
170
171     print ++($foo = "99");      # prints "100"
172     print ++($foo = "a0");      # prints "a1"
173     print ++($foo = "Az");      # prints "Ba"
174     print ++($foo = "zz");      # prints "aaa"
175
176 C<undef> is always treated as numeric, and in particular is changed
177 to C<0> before incrementing (so that a post-increment of an undef value
178 will return C<0> rather than C<undef>).
179
180 The auto-decrement operator is not magical.
181
182 =head2 Exponentiation
183 X<**> X<exponentiation> X<power>
184
185 Binary "**" is the exponentiation operator.  It binds even more
186 tightly than unary minus, so -2**4 is -(2**4), not (-2)**4. (This is
187 implemented using C's pow(3) function, which actually works on doubles
188 internally.)
189
190 =head2 Symbolic Unary Operators
191 X<unary operator> X<operator, unary>
192
193 Unary "!" performs logical negation, i.e., "not".  See also C<not> for a lower
194 precedence version of this.
195 X<!>
196
197 Unary "-" performs arithmetic negation if the operand is numeric,
198 including any string that looks like a number.  If the operand is
199 an identifier, a string consisting of a minus sign concatenated
200 with the identifier is returned.  Otherwise, if the string starts
201 with a plus or minus, a string starting with the opposite sign is
202 returned.  One effect of these rules is that -bareword is equivalent
203 to the string "-bareword".  If, however, the string begins with a
204 non-alphabetic character (excluding "+" or "-"), Perl will attempt to convert
205 the string to a numeric and the arithmetic negation is performed. If the
206 string cannot be cleanly converted to a numeric, Perl will give the warning
207 B<Argument "the string" isn't numeric in negation (-) at ...>.
208 X<-> X<negation, arithmetic>
209
210 Unary "~" performs bitwise negation, i.e., 1's complement.  For
211 example, C<0666 & ~027> is 0640.  (See also L<Integer Arithmetic> and
212 L<Bitwise String Operators>.)  Note that the width of the result is
213 platform-dependent: ~0 is 32 bits wide on a 32-bit platform, but 64
214 bits wide on a 64-bit platform, so if you are expecting a certain bit
215 width, remember to use the "&" operator to mask off the excess bits.
216 X<~> X<negation, binary>
217
218 When complementing strings, if all characters have ordinal values under
219 256, then their complements will, also.  But if they do not, all
220 characters will be in either 32- or 64-bit complements, depending on your
221 architecture.  So for example, C<~"\x{3B1}"> is C<"\x{FFFF_FC4E}"> on
222 32-bit machines and C<"\x{FFFF_FFFF_FFFF_FC4E}"> on 64-bit machines.
223
224 Unary "+" has no effect whatsoever, even on strings.  It is useful
225 syntactically for separating a function name from a parenthesized expression
226 that would otherwise be interpreted as the complete list of function
227 arguments.  (See examples above under L<Terms and List Operators (Leftward)>.)
228 X<+>
229
230 Unary "\" creates a reference to whatever follows it.  See L<perlreftut>
231 and L<perlref>.  Do not confuse this behavior with the behavior of
232 backslash within a string, although both forms do convey the notion
233 of protecting the next thing from interpolation.
234 X<\> X<reference> X<backslash>
235
236 =head2 Binding Operators
237 X<binding> X<operator, binding> X<=~> X<!~>
238
239 Binary "=~" binds a scalar expression to a pattern match.  Certain operations
240 search or modify the string $_ by default.  This operator makes that kind
241 of operation work on some other string.  The right argument is a search
242 pattern, substitution, or transliteration.  The left argument is what is
243 supposed to be searched, substituted, or transliterated instead of the default
244 $_.  When used in scalar context, the return value generally indicates the
245 success of the operation.  The exceptions are substitution (s///)
246 and transliteration (y///) with the C</r> (non-destructive) option,
247 which cause the B<r>eturn value to be the result of the substitution.
248 Behavior in list context depends on the particular operator.
249 See L</"Regexp Quote-Like Operators"> for details and L<perlretut> for
250 examples using these operators.
251
252 If the right argument is an expression rather than a search pattern,
253 substitution, or transliteration, it is interpreted as a search pattern at run
254 time. Note that this means that its contents will be interpolated twice, so
255
256   '\\' =~ q'\\';
257
258 is not ok, as the regex engine will end up trying to compile the
259 pattern C<\>, which it will consider a syntax error.
260
261 Binary "!~" is just like "=~" except the return value is negated in
262 the logical sense.
263
264 Binary "!~" with a non-destructive substitution (s///r) or transliteration
265 (y///r) is a syntax error.
266
267 =head2 Multiplicative Operators
268 X<operator, multiplicative>
269
270 Binary "*" multiplies two numbers.
271 X<*>
272
273 Binary "/" divides two numbers.
274 X</> X<slash>
275
276 Binary "%" is the modulo operator, which computes the division
277 remainder of its first argument with respect to its second argument.
278 Given integer
279 operands C<$a> and C<$b>: If C<$b> is positive, then C<$a % $b> is
280 C<$a> minus the largest multiple of C<$b> less than or equal to
281 C<$a>.  If C<$b> is negative, then C<$a % $b> is C<$a> minus the
282 smallest multiple of C<$b> that is not less than C<$a> (i.e. the
283 result will be less than or equal to zero).  If the operands
284 C<$a> and C<$b> are floating point values and the absolute value of
285 C<$b> (that is C<abs($b)>) is less than C<(UV_MAX + 1)>, only
286 the integer portion of C<$a> and C<$b> will be used in the operation
287 (Note: here C<UV_MAX> means the maximum of the unsigned integer type).
288 If the absolute value of the right operand (C<abs($b)>) is greater than
289 or equal to C<(UV_MAX + 1)>, "%" computes the floating-point remainder
290 C<$r> in the equation C<($r = $a - $i*$b)> where C<$i> is a certain
291 integer that makes C<$r> have the same sign as the right operand
292 C<$b> (B<not> as the left operand C<$a> like C function C<fmod()>)
293 and the absolute value less than that of C<$b>.
294 Note that when C<use integer> is in scope, "%" gives you direct access
295 to the modulo operator as implemented by your C compiler.  This
296 operator is not as well defined for negative operands, but it will
297 execute faster.
298 X<%> X<remainder> X<modulo> X<mod>
299
300 Binary "x" is the repetition operator.  In scalar context or if the left
301 operand is not enclosed in parentheses, it returns a string consisting
302 of the left operand repeated the number of times specified by the right
303 operand.  In list context, if the left operand is enclosed in
304 parentheses or is a list formed by C<qw/STRING/>, it repeats the list.
305 If the right operand is zero or negative, it returns an empty string
306 or an empty list, depending on the context.
307 X<x>
308
309     print '-' x 80;             # print row of dashes
310
311     print "\t" x ($tab/8), ' ' x ($tab%8);      # tab over
312
313     @ones = (1) x 80;           # a list of 80 1's
314     @ones = (5) x @ones;        # set all elements to 5
315
316
317 =head2 Additive Operators
318 X<operator, additive>
319
320 Binary "+" returns the sum of two numbers.
321 X<+>
322
323 Binary "-" returns the difference of two numbers.
324 X<->
325
326 Binary "." concatenates two strings.
327 X<string, concatenation> X<concatenation>
328 X<cat> X<concat> X<concatenate> X<.>
329
330 =head2 Shift Operators
331 X<shift operator> X<operator, shift> X<<< << >>>
332 X<<< >> >>> X<right shift> X<left shift> X<bitwise shift>
333 X<shl> X<shr> X<shift, right> X<shift, left>
334
335 Binary "<<" returns the value of its left argument shifted left by the
336 number of bits specified by the right argument.  Arguments should be
337 integers.  (See also L<Integer Arithmetic>.)
338
339 Binary ">>" returns the value of its left argument shifted right by
340 the number of bits specified by the right argument.  Arguments should
341 be integers.  (See also L<Integer Arithmetic>.)
342
343 Note that both "<<" and ">>" in Perl are implemented directly using
344 "<<" and ">>" in C.  If C<use integer> (see L<Integer Arithmetic>) is
345 in force then signed C integers are used, else unsigned C integers are
346 used.  Either way, the implementation isn't going to generate results
347 larger than the size of the integer type Perl was built with (32 bits
348 or 64 bits).
349
350 The result of overflowing the range of the integers is undefined
351 because it is undefined also in C.  In other words, using 32-bit
352 integers, C<< 1 << 32 >> is undefined.  Shifting by a negative number
353 of bits is also undefined.
354
355 =head2 Named Unary Operators
356 X<operator, named unary>
357
358 The various named unary operators are treated as functions with one
359 argument, with optional parentheses.
360
361 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
362 is followed by a left parenthesis as the next token, the operator and
363 arguments within parentheses are taken to be of highest precedence,
364 just like a normal function call.  For example,
365 because named unary operators are higher precedence than ||:
366
367     chdir $foo    || die;       # (chdir $foo) || die
368     chdir($foo)   || die;       # (chdir $foo) || die
369     chdir ($foo)  || die;       # (chdir $foo) || die
370     chdir +($foo) || die;       # (chdir $foo) || die
371
372 but, because * is higher precedence than named operators:
373
374     chdir $foo * 20;    # chdir ($foo * 20)
375     chdir($foo) * 20;   # (chdir $foo) * 20
376     chdir ($foo) * 20;  # (chdir $foo) * 20
377     chdir +($foo) * 20; # chdir ($foo * 20)
378
379     rand 10 * 20;       # rand (10 * 20)
380     rand(10) * 20;      # (rand 10) * 20
381     rand (10) * 20;     # (rand 10) * 20
382     rand +(10) * 20;    # rand (10 * 20)
383
384 Regarding precedence, the filetest operators, like C<-f>, C<-M>, etc. are
385 treated like named unary operators, but they don't follow this functional
386 parenthesis rule.  That means, for example, that C<-f($file).".bak"> is
387 equivalent to C<-f "$file.bak">.
388 X<-X> X<filetest> X<operator, filetest>
389
390 See also L<"Terms and List Operators (Leftward)">.
391
392 =head2 Relational Operators
393 X<relational operator> X<operator, relational>
394
395 Binary "<" returns true if the left argument is numerically less than
396 the right argument.
397 X<< < >>
398
399 Binary ">" returns true if the left argument is numerically greater
400 than the right argument.
401 X<< > >>
402
403 Binary "<=" returns true if the left argument is numerically less than
404 or equal to the right argument.
405 X<< <= >>
406
407 Binary ">=" returns true if the left argument is numerically greater
408 than or equal to the right argument.
409 X<< >= >>
410
411 Binary "lt" returns true if the left argument is stringwise less than
412 the right argument.
413 X<< lt >>
414
415 Binary "gt" returns true if the left argument is stringwise greater
416 than the right argument.
417 X<< gt >>
418
419 Binary "le" returns true if the left argument is stringwise less than
420 or equal to the right argument.
421 X<< le >>
422
423 Binary "ge" returns true if the left argument is stringwise greater
424 than or equal to the right argument.
425 X<< ge >>
426
427 =head2 Equality Operators
428 X<equality> X<equal> X<equals> X<operator, equality>
429
430 Binary "==" returns true if the left argument is numerically equal to
431 the right argument.
432 X<==>
433
434 Binary "!=" returns true if the left argument is numerically not equal
435 to the right argument.
436 X<!=>
437
438 Binary "<=>" returns -1, 0, or 1 depending on whether the left
439 argument is numerically less than, equal to, or greater than the right
440 argument.  If your platform supports NaNs (not-a-numbers) as numeric
441 values, using them with "<=>" returns undef.  NaN is not "<", "==", ">",
442 "<=" or ">=" anything (even NaN), so those 5 return false. NaN != NaN
443 returns true, as does NaN != anything else. If your platform doesn't
444 support NaNs then NaN is just a string with numeric value 0.
445 X<< <=> >> X<spaceship>
446
447     perl -le '$a = "NaN"; print "No NaN support here" if $a == $a'
448     perl -le '$a = "NaN"; print "NaN support here" if $a != $a'
449
450 Binary "eq" returns true if the left argument is stringwise equal to
451 the right argument.
452 X<eq>
453
454 Binary "ne" returns true if the left argument is stringwise not equal
455 to the right argument.
456 X<ne>
457
458 Binary "cmp" returns -1, 0, or 1 depending on whether the left
459 argument is stringwise less than, equal to, or greater than the right
460 argument.
461 X<cmp>
462
463 Binary "~~" does a smart match between its arguments. Smart matching
464 is described in L<perlsyn/"Smart matching in detail">.
465 X<~~>
466
467 "lt", "le", "ge", "gt" and "cmp" use the collation (sort) order specified
468 by the current locale if C<use locale> is in effect.  See L<perllocale>.
469
470 =head2 Bitwise And
471 X<operator, bitwise, and> X<bitwise and> X<&>
472
473 Binary "&" returns its operands ANDed together bit by bit.
474 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
475
476 Note that "&" has lower priority than relational operators, so for example
477 the brackets are essential in a test like
478
479         print "Even\n" if ($x & 1) == 0;
480
481 =head2 Bitwise Or and Exclusive Or
482 X<operator, bitwise, or> X<bitwise or> X<|> X<operator, bitwise, xor>
483 X<bitwise xor> X<^>
484
485 Binary "|" returns its operands ORed together bit by bit.
486 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
487
488 Binary "^" returns its operands XORed together bit by bit.
489 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
490
491 Note that "|" and "^" have lower priority than relational operators, so
492 for example the brackets are essential in a test like
493
494         print "false\n" if (8 | 2) != 10;
495
496 =head2 C-style Logical And
497 X<&&> X<logical and> X<operator, logical, and>
498
499 Binary "&&" performs a short-circuit logical AND operation.  That is,
500 if the left operand is false, the right operand is not even evaluated.
501 Scalar or list context propagates down to the right operand if it
502 is evaluated.
503
504 =head2 C-style Logical Or
505 X<||> X<operator, logical, or>
506
507 Binary "||" performs a short-circuit logical OR operation.  That is,
508 if the left operand is true, the right operand is not even evaluated.
509 Scalar or list context propagates down to the right operand if it
510 is evaluated.
511
512 =head2 C-style Logical Defined-Or
513 X<//> X<operator, logical, defined-or>
514
515 Although it has no direct equivalent in C, Perl's C<//> operator is related
516 to its C-style or.  In fact, it's exactly the same as C<||>, except that it
517 tests the left hand side's definedness instead of its truth.  Thus, C<$a // $b>
518 is similar to C<defined($a) || $b> (except that it returns the value of C<$a>
519 rather than the value of C<defined($a)>) and yields the same result as
520 C<defined($a) ? $a : $b> (except that the ternary-operator form can be
521 used as a lvalue, while C<$a // $b> cannot).  This is very useful for
522 providing default values for variables.  If you actually want to test if
523 at least one of C<$a> and C<$b> is defined, use C<defined($a // $b)>.
524
525 The C<||>, C<//> and C<&&> operators return the last value evaluated
526 (unlike C's C<||> and C<&&>, which return 0 or 1). Thus, a reasonably
527 portable way to find out the home directory might be:
528
529     $home =  $ENV{HOME}
530           // $ENV{LOGDIR}
531           // (getpwuid($<))[7]
532           // die "You're homeless!\n";
533
534 In particular, this means that you shouldn't use this
535 for selecting between two aggregates for assignment:
536
537     @a = @b || @c;              # this is wrong
538     @a = scalar(@b) || @c;      # really meant this
539     @a = @b ? @b : @c;          # this works fine, though
540
541 As more readable alternatives to C<&&> and C<||> when used for
542 control flow, Perl provides the C<and> and C<or> operators (see below).
543 The short-circuit behavior is identical.  The precedence of "and"
544 and "or" is much lower, however, so that you can safely use them after a
545 list operator without the need for parentheses:
546
547     unlink "alpha", "beta", "gamma"
548             or gripe(), next LINE;
549
550 With the C-style operators that would have been written like this:
551
552     unlink("alpha", "beta", "gamma")
553             || (gripe(), next LINE);
554
555 Using "or" for assignment is unlikely to do what you want; see below.
556
557 =head2 Range Operators
558 X<operator, range> X<range> X<..> X<...>
559
560 Binary ".." is the range operator, which is really two different
561 operators depending on the context.  In list context, it returns a
562 list of values counting (up by ones) from the left value to the right
563 value.  If the left value is greater than the right value then it
564 returns the empty list.  The range operator is useful for writing
565 C<foreach (1..10)> loops and for doing slice operations on arrays. In
566 the current implementation, no temporary array is created when the
567 range operator is used as the expression in C<foreach> loops, but older
568 versions of Perl might burn a lot of memory when you write something
569 like this:
570
571     for (1 .. 1_000_000) {
572         # code
573     }
574
575 The range operator also works on strings, using the magical
576 auto-increment, see below.
577
578 In scalar context, ".." returns a boolean value.  The operator is
579 bistable, like a flip-flop, and emulates the line-range (comma)
580 operator of B<sed>, B<awk>, and various editors. Each ".." operator
581 maintains its own boolean state, even across calls to a subroutine
582 that contains it. It is false as long as its left operand is false.
583 Once the left operand is true, the range operator stays true until the
584 right operand is true, I<AFTER> which the range operator becomes false
585 again.  It doesn't become false till the next time the range operator
586 is evaluated.  It can test the right operand and become false on the
587 same evaluation it became true (as in B<awk>), but it still returns
588 true once. If you don't want it to test the right operand until the
589 next evaluation, as in B<sed>, just use three dots ("...") instead of
590 two.  In all other regards, "..." behaves just like ".." does.
591
592 The right operand is not evaluated while the operator is in the
593 "false" state, and the left operand is not evaluated while the
594 operator is in the "true" state.  The precedence is a little lower
595 than || and &&.  The value returned is either the empty string for
596 false, or a sequence number (beginning with 1) for true.  The sequence
597 number is reset for each range encountered.  The final sequence number
598 in a range has the string "E0" appended to it, which doesn't affect
599 its numeric value, but gives you something to search for if you want
600 to exclude the endpoint.  You can exclude the beginning point by
601 waiting for the sequence number to be greater than 1.
602
603 If either operand of scalar ".." is a constant expression,
604 that operand is considered true if it is equal (C<==>) to the current
605 input line number (the C<$.> variable).
606
607 To be pedantic, the comparison is actually C<int(EXPR) == int(EXPR)>,
608 but that is only an issue if you use a floating point expression; when
609 implicitly using C<$.> as described in the previous paragraph, the
610 comparison is C<int(EXPR) == int($.)> which is only an issue when C<$.>
611 is set to a floating point value and you are not reading from a file.
612 Furthermore, C<"span" .. "spat"> or C<2.18 .. 3.14> will not do what
613 you want in scalar context because each of the operands are evaluated
614 using their integer representation.
615
616 Examples:
617
618 As a scalar operator:
619
620     if (101 .. 200) { print; } # print 2nd hundred lines, short for
621                                #  if ($. == 101 .. $. == 200) { print; }
622
623     next LINE if (1 .. /^$/);  # skip header lines, short for
624                                #   next LINE if ($. == 1 .. /^$/);
625                                # (typically in a loop labeled LINE)
626
627     s/^/> / if (/^$/ .. eof());  # quote body
628
629     # parse mail messages
630     while (<>) {
631         $in_header =   1  .. /^$/;
632         $in_body   = /^$/ .. eof;
633         if ($in_header) {
634             # do something
635         } else { # in body
636             # do something else
637         }
638     } continue {
639         close ARGV if eof;             # reset $. each file
640     }
641
642 Here's a simple example to illustrate the difference between
643 the two range operators:
644
645     @lines = ("   - Foo",
646               "01 - Bar",
647               "1  - Baz",
648               "   - Quux");
649
650     foreach (@lines) {
651         if (/0/ .. /1/) {
652             print "$_\n";
653         }
654     }
655
656 This program will print only the line containing "Bar". If
657 the range operator is changed to C<...>, it will also print the
658 "Baz" line.
659
660 And now some examples as a list operator:
661
662     for (101 .. 200) { print; } # print $_ 100 times
663     @foo = @foo[0 .. $#foo];    # an expensive no-op
664     @foo = @foo[$#foo-4 .. $#foo];      # slice last 5 items
665
666 The range operator (in list context) makes use of the magical
667 auto-increment algorithm if the operands are strings.  You
668 can say
669
670     @alphabet = ("A" .. "Z");
671
672 to get all normal letters of the English alphabet, or
673
674     $hexdigit = (0 .. 9, "a" .. "f")[$num & 15];
675
676 to get a hexadecimal digit, or
677
678     @z2 = ("01" .. "31");  print $z2[$mday];
679
680 to get dates with leading zeros.
681
682 If the final value specified is not in the sequence that the magical
683 increment would produce, the sequence goes until the next value would
684 be longer than the final value specified.
685
686 If the initial value specified isn't part of a magical increment
687 sequence (that is, a non-empty string matching C</^[a-zA-Z]*[0-9]*\z/>),
688 only the initial value will be returned.  So the following will only
689 return an alpha:
690
691     use charnames "greek";
692     my @greek_small =  ("\N{alpha}" .. "\N{omega}");
693
694 To get the 25 traditional lowercase Greek letters, including both sigmas,
695 you could use this instead:
696
697     use charnames "greek";
698     my @greek_small =  map { chr }
699                        ord "\N{alpha}" .. ord "\N{omega}";
700
701 However, because there are I<many> other lowercase Greek characters than
702 just those, to match lowercase Greek characters in a regular expression,
703 you would use the pattern C</(?:(?=\p{Greek})\p{Lower})+/>.
704
705 Because each operand is evaluated in integer form, C<2.18 .. 3.14> will
706 return two elements in list context.
707
708     @list = (2.18 .. 3.14); # same as @list = (2 .. 3);
709
710 =head2 Conditional Operator
711 X<operator, conditional> X<operator, ternary> X<ternary> X<?:>
712
713 Ternary "?:" is the conditional operator, just as in C.  It works much
714 like an if-then-else.  If the argument before the ? is true, the
715 argument before the : is returned, otherwise the argument after the :
716 is returned.  For example:
717
718     printf "I have %d dog%s.\n", $n,
719             ($n == 1) ? "" : "s";
720
721 Scalar or list context propagates downward into the 2nd
722 or 3rd argument, whichever is selected.
723
724     $a = $ok ? $b : $c;  # get a scalar
725     @a = $ok ? @b : @c;  # get an array
726     $a = $ok ? @b : @c;  # oops, that's just a count!
727
728 The operator may be assigned to if both the 2nd and 3rd arguments are
729 legal lvalues (meaning that you can assign to them):
730
731     ($a_or_b ? $a : $b) = $c;
732
733 Because this operator produces an assignable result, using assignments
734 without parentheses will get you in trouble.  For example, this:
735
736     $a % 2 ? $a += 10 : $a += 2
737
738 Really means this:
739
740     (($a % 2) ? ($a += 10) : $a) += 2
741
742 Rather than this:
743
744     ($a % 2) ? ($a += 10) : ($a += 2)
745
746 That should probably be written more simply as:
747
748     $a += ($a % 2) ? 10 : 2;
749
750 =head2 Assignment Operators
751 X<assignment> X<operator, assignment> X<=> X<**=> X<+=> X<*=> X<&=>
752 X<<< <<= >>> X<&&=> X<-=> X</=> X<|=> X<<< >>= >>> X<||=> X<//=> X<.=>
753 X<%=> X<^=> X<x=>
754
755 "=" is the ordinary assignment operator.
756
757 Assignment operators work as in C.  That is,
758
759     $a += 2;
760
761 is equivalent to
762
763     $a = $a + 2;
764
765 although without duplicating any side effects that dereferencing the lvalue
766 might trigger, such as from tie().  Other assignment operators work similarly.
767 The following are recognized:
768
769     **=    +=    *=    &=    <<=    &&=
770            -=    /=    |=    >>=    ||=
771            .=    %=    ^=           //=
772                  x=
773
774 Although these are grouped by family, they all have the precedence
775 of assignment.
776
777 Unlike in C, the scalar assignment operator produces a valid lvalue.
778 Modifying an assignment is equivalent to doing the assignment and
779 then modifying the variable that was assigned to.  This is useful
780 for modifying a copy of something, like this:
781
782     ($tmp = $global) =~ tr [0-9] [a-j];
783
784 Likewise,
785
786     ($a += 2) *= 3;
787
788 is equivalent to
789
790     $a += 2;
791     $a *= 3;
792
793 Similarly, a list assignment in list context produces the list of
794 lvalues assigned to, and a list assignment in scalar context returns
795 the number of elements produced by the expression on the right hand
796 side of the assignment.
797
798 =head2 The Triple-Dot Operator
799 X<...> X<... operator> X<yada-yada operator> X<whatever operator>
800 X<triple-dot operator>
801
802 The triple-dot operator, C<...>, sometimes called the "whatever operator", the
803 "yada-yada operator", or the "I<et cetera>" operator, is a placeholder for
804 code.  Perl parses it without error, but when you try to execute a whatever,
805 it throws an exception with the text C<Unimplemented>:
806
807     sub unimplemented { ... }
808
809     eval { unimplemented() };
810     if ($@ eq "Unimplemented" ) {
811         say "Oh look, an exception--whatever.";
812     }
813
814 You can only use the triple-dot operator to stand in for a complete statement.
815 These examples of the triple-dot work:
816
817     { ... }
818
819     sub foo { ... }
820
821     ...;
822
823     eval { ... };
824
825     sub foo {
826         my ($self) = shift;
827         ...;
828     }
829
830     do {
831         my $variable;
832         ...;
833         say "Hurrah!";
834     } while $cheering;
835
836 The yada-yada--or whatever--cannot stand in for an expression that is
837 part of a larger statement since the C<...> is also the three-dot version
838 of the binary range operator (see L<Range Operators>).  These examples of
839 the whatever operator are still syntax errors:
840
841     print ...;
842
843     open(PASSWD, ">", "/dev/passwd") or ...;
844
845     if ($condition && ...) { say "Hello" }
846
847 There are some cases where Perl can't immediately tell the difference
848 between an expression and a statement. For instance, the syntax for a
849 block and an anonymous hash reference constructor look the same unless
850 there's something in the braces that give Perl a hint. The whatever
851 is a syntax error if Perl doesn't guess that the C<{ ... }> is a
852 block. In that case, it doesn't think the C<...> is the whatever
853 because it's expecting an expression instead of a statement:
854
855     my @transformed = map { ... } @input;  # syntax error
856
857 You can use a C<;> inside your block to denote that the C<{ ... }> is
858 a block and not a hash reference constructor. Now the whatever works:
859
860     my @transformed = map {; ... } @input; # ; disambiguates
861
862     my @transformed = map { ...; } @input; # ; disambiguates
863
864 =head2 Comma Operator
865 X<comma> X<operator, comma> X<,>
866
867 Binary "," is the comma operator.  In scalar context it evaluates
868 its left argument, throws that value away, then evaluates its right
869 argument and returns that value.  This is just like C's comma operator.
870
871 In list context, it's just the list argument separator, and inserts
872 both its arguments into the list.  These arguments are also evaluated
873 from left to right.
874
875 The C<< => >> operator is a synonym for the comma except that it causes
876 its left operand to be interpreted as a string if it begins with a letter
877 or underscore and is composed only of letters, digits and underscores.
878 This includes operands that might otherwise be interpreted as operators,
879 constants, single number v-strings or function calls. If in doubt about
880 this behavior, the left operand can be quoted explicitly.
881
882 Otherwise, the C<< => >> operator behaves exactly as the comma operator
883 or list argument separator, according to context.
884
885 For example:
886
887     use constant FOO => "something";
888
889     my %h = ( FOO => 23 );
890
891 is equivalent to:
892
893     my %h = ("FOO", 23);
894
895 It is I<NOT>:
896
897     my %h = ("something", 23);
898
899 The C<< => >> operator is helpful in documenting the correspondence
900 between keys and values in hashes, and other paired elements in lists.
901
902         %hash = ( $key => $value );
903         login( $username => $password );
904
905 =head2 List Operators (Rightward)
906 X<operator, list, rightward> X<list operator>
907
908 On the right side of a list operator, the comma has very low precedence,
909 such that it controls all comma-separated expressions found there.
910 The only operators with lower precedence are the logical operators
911 "and", "or", and "not", which may be used to evaluate calls to list
912 operators without the need for extra parentheses:
913
914     open HANDLE, "< $file"
915         or die "Can't open $file: $!\n";
916
917 See also discussion of list operators in L<Terms and List Operators (Leftward)>.
918
919 =head2 Logical Not
920 X<operator, logical, not> X<not>
921
922 Unary "not" returns the logical negation of the expression to its right.
923 It's the equivalent of "!" except for the very low precedence.
924
925 =head2 Logical And
926 X<operator, logical, and> X<and>
927
928 Binary "and" returns the logical conjunction of the two surrounding
929 expressions.  It's equivalent to C<&&> except for the very low
930 precedence.  This means that it short-circuits: the right
931 expression is evaluated only if the left expression is true.
932
933 =head2 Logical or, Defined or, and Exclusive Or
934 X<operator, logical, or> X<operator, logical, xor>
935 X<operator, logical, defined or> X<operator, logical, exclusive or>
936 X<or> X<xor>
937
938 Binary "or" returns the logical disjunction of the two surrounding
939 expressions.  It's equivalent to C<||> except for the very low precedence.
940 This makes it useful for control flow:
941
942     print FH $data              or die "Can't write to FH: $!";
943
944 This means that it short-circuits: the right expression is evaluated
945 only if the left expression is false.  Due to its precedence, you must
946 be careful to avoid using it as replacement for the C<||> operator.
947 It usually works out better for flow control than in assignments:
948
949     $a = $b or $c;              # bug: this is wrong
950     ($a = $b) or $c;            # really means this
951     $a = $b || $c;              # better written this way
952
953 However, when it's a list-context assignment and you're trying to use
954 C<||> for control flow, you probably need "or" so that the assignment
955 takes higher precedence.
956
957     @info = stat($file) || die;     # oops, scalar sense of stat!
958     @info = stat($file) or die;     # better, now @info gets its due
959
960 Then again, you could always use parentheses.
961
962 Binary "xor" returns the exclusive-OR of the two surrounding expressions.
963 It cannot short-circuit (of course).
964
965 =head2 C Operators Missing From Perl
966 X<operator, missing from perl> X<&> X<*>
967 X<typecasting> X<(TYPE)>
968
969 Here is what C has that Perl doesn't:
970
971 =over 8
972
973 =item unary &
974
975 Address-of operator.  (But see the "\" operator for taking a reference.)
976
977 =item unary *
978
979 Dereference-address operator. (Perl's prefix dereferencing
980 operators are typed: $, @, %, and &.)
981
982 =item (TYPE)
983
984 Type-casting operator.
985
986 =back
987
988 =head2 Quote and Quote-like Operators
989 X<operator, quote> X<operator, quote-like> X<q> X<qq> X<qx> X<qw> X<m>
990 X<qr> X<s> X<tr> X<'> X<''> X<"> X<""> X<//> X<`> X<``> X<<< << >>>
991 X<escape sequence> X<escape>
992
993 While we usually think of quotes as literal values, in Perl they
994 function as operators, providing various kinds of interpolating and
995 pattern matching capabilities.  Perl provides customary quote characters
996 for these behaviors, but also provides a way for you to choose your
997 quote character for any of them.  In the following table, a C<{}> represents
998 any pair of delimiters you choose.
999
1000     Customary  Generic        Meaning        Interpolates
1001         ''       q{}          Literal             no
1002         ""      qq{}          Literal             yes
1003         ``      qx{}          Command             yes*
1004                 qw{}         Word list            no
1005         //       m{}       Pattern match          yes*
1006                 qr{}          Pattern             yes*
1007                  s{}{}      Substitution          yes*
1008                 tr{}{}    Transliteration         no (but see below)
1009                  y{}{}    Transliteration         no (but see below)
1010         <<EOF                 here-doc            yes*
1011
1012         * unless the delimiter is ''.
1013
1014 Non-bracketing delimiters use the same character fore and aft, but the four
1015 sorts of ASCII brackets (round, angle, square, curly) all nest, which means
1016 that
1017
1018     q{foo{bar}baz}
1019
1020 is the same as
1021
1022     'foo{bar}baz'
1023
1024 Note, however, that this does not always work for quoting Perl code:
1025
1026     $s = q{ if($a eq "}") ... }; # WRONG
1027
1028 is a syntax error. The C<Text::Balanced> module (standard as of v5.8,
1029 and from CPAN before then) is able to do this properly.
1030
1031 There can be whitespace between the operator and the quoting
1032 characters, except when C<#> is being used as the quoting character.
1033 C<q#foo#> is parsed as the string C<foo>, while C<q #foo#> is the
1034 operator C<q> followed by a comment.  Its argument will be taken
1035 from the next line.  This allows you to write:
1036
1037     s {foo}  # Replace foo
1038       {bar}  # with bar.
1039
1040 The following escape sequences are available in constructs that interpolate,
1041 and in transliterations:
1042 X<\t> X<\n> X<\r> X<\f> X<\b> X<\a> X<\e> X<\x> X<\0> X<\c> X<\N> X<\N{}>
1043 X<\o{}>
1044
1045     Sequence     Note  Description
1046     \t                  tab               (HT, TAB)
1047     \n                  newline           (NL)
1048     \r                  return            (CR)
1049     \f                  form feed         (FF)
1050     \b                  backspace         (BS)
1051     \a                  alarm (bell)      (BEL)
1052     \e                  escape            (ESC)
1053     \x{263A}     [1,8]  hex char          (example: SMILEY)
1054     \x1b         [2,8]  restricted range hex char (example: ESC)
1055     \N{name}     [3]    named Unicode character or character sequence
1056     \N{U+263D}   [4,8]  Unicode character (example: FIRST QUARTER MOON)
1057     \c[          [5]    control char      (example: chr(27))
1058     \o{23072}    [6,8]  octal char        (example: SMILEY)
1059     \033         [7,8]  restricted range octal char  (example: ESC)
1060
1061 =over 4
1062
1063 =item [1]
1064
1065 The result is the character specified by the hexadecimal number between
1066 the braces.  See L</[8]> below for details on which character.
1067
1068 Only hexadecimal digits are valid between the braces. If an invalid
1069 character is encountered, a warning will be issued and the invalid
1070 character and all subsequent characters (valid or invalid) within the
1071 braces will be discarded.
1072
1073 If there are no valid digits between the braces, the generated character is
1074 the NULL character (C<\x{00}>).  However, an explicit empty brace (C<\x{}>)
1075 will not cause a warning (currently).
1076
1077 =item [2]
1078
1079 The result is the character specified by the hexadecimal number in the range
1080 0x00 to 0xFF.  See L</[8]> below for details on which character.
1081
1082 Only hexadecimal digits are valid following C<\x>.  When C<\x> is followed
1083 by fewer than two valid digits, any valid digits will be zero-padded.  This
1084 means that C<\x7> will be interpreted as C<\x07>, and a lone <\x> will be
1085 interpreted as C<\x00>.  Except at the end of a string, having fewer than
1086 two valid digits will result in a warning.  Note that although the warning
1087 says the illegal character is ignored, it is only ignored as part of the
1088 escape and will still be used as the subsequent character in the string.
1089 For example:
1090
1091   Original    Result    Warns?
1092   "\x7"       "\x07"    no
1093   "\x"        "\x00"    no
1094   "\x7q"      "\x07q"   yes
1095   "\xq"       "\x00q"   yes
1096
1097 =item [3]
1098
1099 The result is the Unicode character or character sequence given by I<name>.
1100 See L<charnames>.
1101
1102 =item [4]
1103
1104 C<\N{U+I<hexadecimal number>}> means the Unicode character whose Unicode code
1105 point is I<hexadecimal number>.
1106
1107 =item [5]
1108
1109 The character following C<\c> is mapped to some other character as shown in the
1110 table:
1111
1112  Sequence   Value
1113    \c@      chr(0)
1114    \cA      chr(1)
1115    \ca      chr(1)
1116    \cB      chr(2)
1117    \cb      chr(2)
1118    ...
1119    \cZ      chr(26)
1120    \cz      chr(26)
1121    \c[      chr(27)
1122    \c]      chr(29)
1123    \c^      chr(30)
1124    \c?      chr(127)
1125
1126 In other words, it's the character whose code point has had 64 xor'd with
1127 its uppercase.  C<\c?> is DELETE because C<ord("@") ^ 64> is 127, and
1128 C<\c@> is NULL because the ord of "@" is 64, so xor'ing 64 itself produces 0.
1129
1130 Also, C<\c\I<X>> yields C< chr(28) . "I<X>"> for any I<X>, but cannot come at the
1131 end of a string, because the backslash would be parsed as escaping the end
1132 quote.
1133
1134 On ASCII platforms, the resulting characters from the list above are the
1135 complete set of ASCII controls.  This isn't the case on EBCDIC platforms; see
1136 L<perlebcdic/OPERATOR DIFFERENCES> for the complete list of what these
1137 sequences mean on both ASCII and EBCDIC platforms.
1138
1139 Use of any other character following the "c" besides those listed above is
1140 discouraged, and some are deprecated with the intention of removing
1141 those in Perl 5.16.  What happens for any of these
1142 other characters currently though, is that the value is derived by xor'ing
1143 with the seventh bit, which is 64.
1144
1145 To get platform independent controls, you can use C<\N{...}>.
1146
1147 =item [6]
1148
1149 The result is the character specified by the octal number between the braces.
1150 See L</[8]> below for details on which character.
1151
1152 If a character that isn't an octal digit is encountered, a warning is raised,
1153 and the value is based on the octal digits before it, discarding it and all
1154 following characters up to the closing brace.  It is a fatal error if there are
1155 no octal digits at all.
1156
1157 =item [7]
1158
1159 The result is the character specified by the three-digit octal number in the
1160 range 000 to 777 (but best to not use above 077, see next paragraph).  See
1161 L</[8]> below for details on which character.
1162
1163 Some contexts allow 2 or even 1 digit, but any usage without exactly
1164 three digits, the first being a zero, may give unintended results.  (For
1165 example, see L<perlrebackslash/Octal escapes>.)  Starting in Perl 5.14, you may
1166 use C<\o{}> instead, which avoids all these problems.  Otherwise, it is best to
1167 use this construct only for ordinals C<\077> and below, remembering to pad to
1168 the left with zeros to make three digits.  For larger ordinals, either use
1169 C<\o{}> , or convert to something else, such as to hex and use C<\x{}>
1170 instead.
1171
1172 Having fewer than 3 digits may lead to a misleading warning message that says
1173 that what follows is ignored.  For example, C<"\128"> in the ASCII character set
1174 is equivalent to the two characters C<"\n8">, but the warning C<Illegal octal
1175 digit '8' ignored> will be thrown.  To avoid this warning, make sure to pad
1176 your octal number with C<0>'s: C<"\0128">.
1177
1178 =item [8]
1179
1180 Several constructs above specify a character by a number.  That number
1181 gives the character's position in the character set encoding (indexed from 0).
1182 This is called synonymously its ordinal, code position, or code point.  Perl
1183 works on platforms that have a native encoding currently of either ASCII/Latin1
1184 or EBCDIC, each of which allow specification of 256 characters.  In general, if
1185 the number is 255 (0xFF, 0377) or below, Perl interprets this in the platform's
1186 native encoding.  If the number is 256 (0x100, 0400) or above, Perl interprets
1187 it as a Unicode code point and the result is the corresponding Unicode
1188 character.  For example C<\x{50}> and C<\o{120}> both are the number 80 in
1189 decimal, which is less than 256, so the number is interpreted in the native
1190 character set encoding.  In ASCII the character in the 80th position (indexed
1191 from 0) is the letter "P", and in EBCDIC it is the ampersand symbol "&".
1192 C<\x{100}> and C<\o{400}> are both 256 in decimal, so the number is interpreted
1193 as a Unicode code point no matter what the native encoding is.  The name of the
1194 character in the 100th position (indexed by 0) in Unicode is
1195 C<LATIN CAPITAL LETTER A WITH MACRON>.
1196
1197 There are a couple of exceptions to the above rule.  C<\N{U+I<hex number>}> is
1198 always interpreted as a Unicode code point, so that C<\N{U+0050}> is "P" even
1199 on EBCDIC platforms.  And if L<C<S<use encoding>>|encoding> is in effect, the
1200 number is considered to be in that encoding, and is translated from that into
1201 the platform's native encoding if there is a corresponding native character;
1202 otherwise to Unicode.
1203
1204 =back
1205
1206 B<NOTE>: Unlike C and other languages, Perl has no C<\v> escape sequence for
1207 the vertical tab (VT - ASCII 11), but you may use C<\ck> or C<\x0b>.  (C<\v>
1208 does have meaning in regular expression patterns in Perl, see L<perlre>.)
1209
1210 The following escape sequences are available in constructs that interpolate,
1211 but not in transliterations.
1212 X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q>
1213
1214     \l          lowercase next character only
1215     \u          titlecase (not uppercase!) next character only
1216     \L          lowercase all characters till \E seen
1217     \U          uppercase all characters till \E seen
1218     \Q          quote non-word characters till \E
1219     \E          end either case modification or quoted section
1220                 (whichever was last seen)
1221
1222 C<\L>, C<\U>, and C<\Q> can stack, in which case you need one
1223 C<\E> for each.  For example:
1224
1225         say "This \Qquoting \ubusiness \Uhere isn't quite\E done yet,\E is it?";
1226     This quoting\ Business\ HERE\ ISN\'T\ QUITE\ done\ yet\, is it?
1227
1228 If C<use locale> is in effect, the case map used by C<\l>, C<\L>,
1229 C<\u>, and C<\U> is taken from the current locale.  See L<perllocale>.
1230 If Unicode (for example, C<\N{}> or code points of 0x100 or
1231 beyond) is being used, the case map used by C<\l>, C<\L>, C<\u>, and
1232 C<\U> is as defined by Unicode.  That means that case-mapping
1233 a single character can sometimes produce several characters.
1234
1235 All systems use the virtual C<"\n"> to represent a line terminator,
1236 called a "newline".  There is no such thing as an unvarying, physical
1237 newline character.  It is only an illusion that the operating system,
1238 device drivers, C libraries, and Perl all conspire to preserve.  Not all
1239 systems read C<"\r"> as ASCII CR and C<"\n"> as ASCII LF.  For example,
1240 on the ancient Macs (pre-MacOS X) of yesteryear, these used to be reversed,
1241 and on systems without line terminator,
1242 printing C<"\n"> might emit no actual data.  In general, use C<"\n"> when
1243 you mean a "newline" for your system, but use the literal ASCII when you
1244 need an exact character.  For example, most networking protocols expect
1245 and prefer a CR+LF (C<"\015\012"> or C<"\cM\cJ">) for line terminators,
1246 and although they often accept just C<"\012">, they seldom tolerate just
1247 C<"\015">.  If you get in the habit of using C<"\n"> for networking,
1248 you may be burned some day.
1249 X<newline> X<line terminator> X<eol> X<end of line>
1250 X<\n> X<\r> X<\r\n>
1251
1252 For constructs that do interpolate, variables beginning with "C<$>"
1253 or "C<@>" are interpolated.  Subscripted variables such as C<$a[3]> or
1254 C<< $href->{key}[0] >> are also interpolated, as are array and hash slices.
1255 But method calls such as C<< $obj->meth >> are not.
1256
1257 Interpolating an array or slice interpolates the elements in order,
1258 separated by the value of C<$">, so is equivalent to interpolating
1259 C<join $", @array>.  "Punctuation" arrays such as C<@*> are usually
1260 interpolated only if the name is enclosed in braces C<@{*}>, but the
1261 arrays C<@_>, C<@+>, and C<@-> are interpolated even without braces.
1262
1263 For double-quoted strings, the quoting from C<\Q> is applied after
1264 interpolation and escapes are processed.
1265
1266     "abc\Qfoo\tbar$s\Exyz"
1267
1268 is equivalent to
1269
1270     "abc" . quotemeta("foo\tbar$s") . "xyz"
1271
1272 For the pattern of regex operators (C<qr//>, C<m//> and C<s///>),
1273 the quoting from C<\Q> is applied after interpolation is processed,
1274 but before escapes are processed. This allows the pattern to match
1275 literally (except for C<$> and C<@>). For example, the following matches:
1276
1277     '\s\t' =~ /\Q\s\t/
1278
1279 Because C<$> or C<@> trigger interpolation, you'll need to use something
1280 like C</\Quser\E\@\Qhost/> to match them literally.
1281
1282 Patterns are subject to an additional level of interpretation as a
1283 regular expression.  This is done as a second pass, after variables are
1284 interpolated, so that regular expressions may be incorporated into the
1285 pattern from the variables.  If this is not what you want, use C<\Q> to
1286 interpolate a variable literally.
1287
1288 Apart from the behavior described above, Perl does not expand
1289 multiple levels of interpolation.  In particular, contrary to the
1290 expectations of shell programmers, back-quotes do I<NOT> interpolate
1291 within double quotes, nor do single quotes impede evaluation of
1292 variables when used within double quotes.
1293
1294 =head2 Regexp Quote-Like Operators
1295 X<operator, regexp>
1296
1297 Here are the quote-like operators that apply to pattern
1298 matching and related activities.
1299
1300 =over 8
1301
1302 =item qr/STRING/msixpodual
1303 X<qr> X</i> X</m> X</o> X</s> X</x> X</p>
1304
1305 This operator quotes (and possibly compiles) its I<STRING> as a regular
1306 expression.  I<STRING> is interpolated the same way as I<PATTERN>
1307 in C<m/PATTERN/>.  If "'" is used as the delimiter, no interpolation
1308 is done.  Returns a Perl value which may be used instead of the
1309 corresponding C</STRING/msixpodual> expression. The returned value is a
1310 normalized version of the original pattern. It magically differs from
1311 a string containing the same characters: C<ref(qr/x/)> returns "Regexp";
1312 however, dereferencing it is not well defined (you currently get the 
1313 normalized version of the original pattern, but this may change).
1314
1315
1316 For example,
1317
1318     $rex = qr/my.STRING/is;
1319     print $rex;                 # prints (?si-xm:my.STRING)
1320     s/$rex/foo/;
1321
1322 is equivalent to
1323
1324     s/my.STRING/foo/is;
1325
1326 The result may be used as a subpattern in a match:
1327
1328     $re = qr/$pattern/;
1329     $string =~ /foo${re}bar/;   # can be interpolated in other patterns
1330     $string =~ $re;             # or used standalone
1331     $string =~ /$re/;           # or this way
1332
1333 Since Perl may compile the pattern at the moment of execution of the qr()
1334 operator, using qr() may have speed advantages in some situations,
1335 notably if the result of qr() is used standalone:
1336
1337     sub match {
1338         my $patterns = shift;
1339         my @compiled = map qr/$_/i, @$patterns;
1340         grep {
1341             my $success = 0;
1342             foreach my $pat (@compiled) {
1343                 $success = 1, last if /$pat/;
1344             }
1345             $success;
1346         } @_;
1347     }
1348
1349 Precompilation of the pattern into an internal representation at
1350 the moment of qr() avoids a need to recompile the pattern every
1351 time a match C</$pat/> is attempted.  (Perl has many other internal
1352 optimizations, but none would be triggered in the above example if
1353 we did not use qr() operator.)
1354
1355 Options (specified by the following modifiers) are:
1356
1357     m   Treat string as multiple lines.
1358     s   Treat string as single line. (Make . match a newline)
1359     i   Do case-insensitive pattern matching.
1360     x   Use extended regular expressions.
1361     p   When matching preserve a copy of the matched string so
1362         that ${^PREMATCH}, ${^MATCH}, ${^POSTMATCH} will be defined.
1363     o   Compile pattern only once.
1364     a   ASCII-restrict: Use ASCII for \d, \s, \w; specifying two a's
1365         further restricts /i matching so that no ASCII character will
1366         match a non-ASCII one
1367     l   Use the locale
1368     u   Use Unicode rules
1369     d   Use Unicode or native charset, as in 5.12 and earlier
1370
1371 If a precompiled pattern is embedded in a larger pattern then the effect
1372 of "msixpluad" will be propagated appropriately.  The effect the "o"
1373 modifier has is not propagated, being restricted to those patterns
1374 explicitly using it.
1375
1376 The last four modifiers listed above, added in Perl 5.14,
1377 control the character set semantics, but C</a> is the only one you are likely
1378 to want to specify explicitly; the other three are selected
1379 automatically by various pragmas.
1380
1381 See L<perlre> for additional information on valid syntax for STRING, and
1382 for a detailed look at the semantics of regular expressions.  In
1383 particular, all the modifiers execpt C</o> are further explained in
1384 L<perlre/Modifiers>.  C</o> is described in the next section.
1385
1386 =item m/PATTERN/msixpodualgc
1387 X<m> X<operator, match>
1388 X<regexp, options> X<regexp> X<regex, options> X<regex>
1389 X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c>
1390
1391 =item /PATTERN/msixpodualgc
1392
1393 Searches a string for a pattern match, and in scalar context returns
1394 true if it succeeds, false if it fails.  If no string is specified
1395 via the C<=~> or C<!~> operator, the $_ string is searched.  (The
1396 string specified with C<=~> need not be an lvalue--it may be the
1397 result of an expression evaluation, but remember the C<=~> binds
1398 rather tightly.)  See also L<perlre>.
1399
1400 Options are as described in C<qr//> above; in addition, the following match
1401 process modifiers are available:
1402
1403  g  Match globally, i.e., find all occurrences.
1404  c  Do not reset search position on a failed match when /g is in effect.
1405
1406 If "/" is the delimiter then the initial C<m> is optional.  With the C<m>
1407 you can use any pair of non-whitespace (ASCII) characters
1408 as delimiters.  This is particularly useful for matching path names
1409 that contain "/", to avoid LTS (leaning toothpick syndrome).  If "?" is
1410 the delimiter, then a match-only-once rule applies,
1411 described in C<m?PATTERN?> below.
1412 If "'" is the delimiter, no interpolation is performed on the PATTERN.
1413 When using a character valid in an identifier, whitespace is required
1414 after the C<m>.
1415
1416 PATTERN may contain variables, which will be interpolated
1417 every time the pattern search is evaluated, except
1418 for when the delimiter is a single quote.  (Note that C<$(>, C<$)>, and
1419 C<$|> are not interpolated because they look like end-of-string tests.)
1420 Perl will not recompile the pattern unless an interpolated
1421 variable that it contains changes.  You can force Perl to skip the
1422 test and never recompile by adding a C</o> (which stands for "once")
1423 after the trailing delimiter.
1424 Once upon a time, Perl would recompile regular expressions
1425 unnecessarily, and this modifier was useful to tell it not to do so, in the
1426 interests of speed.  But now, the only reasons to use C</o> are either:
1427
1428 =over
1429
1430 =item 1
1431
1432 The variables are thousands of characters long and you know that they
1433 don't change, and you need to wring out the last little bit of speed by
1434 having Perl skip testing for that.  (There is a maintenance penalty for
1435 doing this, as mentioning C</o> constitutes a promise that you won't
1436 change the variables in the pattern.  If you do change them, Perl won't
1437 even notice.)
1438
1439 =item 2
1440
1441 you want the pattern to use the initial values of the variables
1442 regardless of whether they change or not.  (But there are saner ways
1443 of accomplishing this than using C</o>.)
1444
1445 =back
1446
1447 The bottom line is that using C</o> is almost never a good idea.
1448
1449 =item The empty pattern //
1450
1451 If the PATTERN evaluates to the empty string, the last
1452 I<successfully> matched regular expression is used instead. In this
1453 case, only the C<g> and C<c> flags on the empty pattern are honored;
1454 the other flags are taken from the original pattern. If no match has
1455 previously succeeded, this will (silently) act instead as a genuine
1456 empty pattern (which will always match).
1457
1458 Note that it's possible to confuse Perl into thinking C<//> (the empty
1459 regex) is really C<//> (the defined-or operator).  Perl is usually pretty
1460 good about this, but some pathological cases might trigger this, such as
1461 C<$a///> (is that C<($a) / (//)> or C<$a // />?) and C<print $fh //>
1462 (C<print $fh(//> or C<print($fh //>?).  In all of these examples, Perl
1463 will assume you meant defined-or.  If you meant the empty regex, just
1464 use parentheses or spaces to disambiguate, or even prefix the empty
1465 regex with an C<m> (so C<//> becomes C<m//>).
1466
1467 =item Matching in list context
1468
1469 If the C</g> option is not used, C<m//> in list context returns a
1470 list consisting of the subexpressions matched by the parentheses in the
1471 pattern, i.e., (C<$1>, C<$2>, C<$3>...).  (Note that here C<$1> etc. are
1472 also set, and that this differs from Perl 4's behavior.)  When there are
1473 no parentheses in the pattern, the return value is the list C<(1)> for
1474 success.  With or without parentheses, an empty list is returned upon
1475 failure.
1476
1477 Examples:
1478
1479     open(TTY, "+>/dev/tty")
1480         || die "can't access /dev/tty: $!";
1481
1482     <TTY> =~ /^y/i && foo();    # do foo if desired
1483
1484     if (/Version: *([0-9.]*)/) { $version = $1; }
1485
1486     next if m#^/usr/spool/uucp#;
1487
1488     # poor man's grep
1489     $arg = shift;
1490     while (<>) {
1491         print if /$arg/o;       # compile only once (no longer needed!)
1492     }
1493
1494     if (($F1, $F2, $Etc) = ($foo =~ /^(\S+)\s+(\S+)\s*(.*)/))
1495
1496 This last example splits $foo into the first two words and the
1497 remainder of the line, and assigns those three fields to $F1, $F2, and
1498 $Etc.  The conditional is true if any variables were assigned; that is,
1499 if the pattern matched.
1500
1501 The C</g> modifier specifies global pattern matching--that is,
1502 matching as many times as possible within the string. How it behaves
1503 depends on the context. In list context, it returns a list of the
1504 substrings matched by any capturing parentheses in the regular
1505 expression. If there are no parentheses, it returns a list of all
1506 the matched strings, as if there were parentheses around the whole
1507 pattern.
1508
1509 In scalar context, each execution of C<m//g> finds the next match,
1510 returning true if it matches, and false if there is no further match.
1511 The position after the last match can be read or set using the C<pos()>
1512 function; see L<perlfunc/pos>. A failed match normally resets the
1513 search position to the beginning of the string, but you can avoid that
1514 by adding the C</c> modifier (e.g. C<m//gc>). Modifying the target
1515 string also resets the search position.
1516
1517 =item \G assertion
1518
1519 You can intermix C<m//g> matches with C<m/\G.../g>, where C<\G> is a
1520 zero-width assertion that matches the exact position where the
1521 previous C<m//g>, if any, left off. Without the C</g> modifier, the
1522 C<\G> assertion still anchors at C<pos()> as it was at the start of
1523 the operation (see L<perlfunc/pos>), but the match is of course only
1524 attempted once. Using C<\G> without C</g> on a target string that has
1525 not previously had a C</g> match applied to it is the same as using
1526 the C<\A> assertion to match the beginning of the string.  Note also
1527 that, currently, C<\G> is only properly supported when anchored at the
1528 very beginning of the pattern.
1529
1530 Examples:
1531
1532     # list context
1533     ($one,$five,$fifteen) = (`uptime` =~ /(\d+\.\d+)/g);
1534
1535     # scalar context
1536     local $/ = "";
1537     while ($paragraph = <>) {
1538         while ($paragraph =~ /\p{Ll}['")]*[.!?]+['")]*\s/g) {
1539             $sentences++;
1540         }
1541     }
1542     say $sentences;
1543
1544 Here's another way to check for sentences in a paragraph:
1545
1546     my $sentence_rx = qr{
1547         (?: (?<= ^ ) | (?<= \s ) )  # after start-of-string or whitespace
1548         \p{Lu}                      # capital letter
1549         .*?                         # a bunch of anything
1550         (?<= \S )                   # that ends in non-whitespace
1551         (?<! \b [DMS]r  )           # but isn't a common abbreviation
1552         (?<! \b Mrs )
1553         (?<! \b Sra )
1554         (?<! \b St  )
1555         [.?!]                       # followed by a sentence ender
1556         (?= $ | \s )                # in front of end-of-string or whitespace
1557     }sx;
1558     local $/ = "";
1559     while (my $paragraph = <>) {
1560         say "NEW PARAGRAPH";
1561         my $count = 0;
1562         while ($paragraph =~ /($sentence_rx)/g) {
1563             printf "\tgot sentence %d: <%s>\n", ++$count, $1;
1564         }
1565     }
1566
1567 Here's how to use C<m//gc> with C<\G>:
1568
1569     $_ = "ppooqppqq";
1570     while ($i++ < 2) {
1571         print "1: '";
1572         print $1 while /(o)/gc; print "', pos=", pos, "\n";
1573         print "2: '";
1574         print $1 if /\G(q)/gc;  print "', pos=", pos, "\n";
1575         print "3: '";
1576         print $1 while /(p)/gc; print "', pos=", pos, "\n";
1577     }
1578     print "Final: '$1', pos=",pos,"\n" if /\G(.)/;
1579
1580 The last example should print:
1581
1582     1: 'oo', pos=4
1583     2: 'q', pos=5
1584     3: 'pp', pos=7
1585     1: '', pos=7
1586     2: 'q', pos=8
1587     3: '', pos=8
1588     Final: 'q', pos=8
1589
1590 Notice that the final match matched C<q> instead of C<p>, which a match
1591 without the C<\G> anchor would have done. Also note that the final match
1592 did not update C<pos>. C<pos> is only updated on a C</g> match. If the
1593 final match did indeed match C<p>, it's a good bet that you're running a
1594 very old (pre-5.6.0) version of Perl.
1595
1596 A useful idiom for C<lex>-like scanners is C</\G.../gc>.  You can
1597 combine several regexps like this to process a string part-by-part,
1598 doing different actions depending on which regexp matched.  Each
1599 regexp tries to match where the previous one leaves off.
1600
1601  $_ = <<'EOL';
1602     $url = URI::URL->new( "http://example.com/" ); die if $url eq "xXx";
1603  EOL
1604
1605  LOOP: {
1606      print(" digits"),       redo LOOP if /\G\d+\b[,.;]?\s*/gc;
1607      print(" lowercase"),    redo LOOP if /\G\p{Ll}+\b[,.;]?\s*/gc;
1608      print(" UPPERCASE"),    redo LOOP if /\G\p{Lu}+\b[,.;]?\s*/gc;
1609      print(" Capitalized"),  redo LOOP if /\G\p{Lu}\p{Ll}+\b[,.;]?\s*/gc;
1610      print(" MiXeD"),        redo LOOP if /\G\pL+\b[,.;]?\s*/gc;
1611      print(" alphanumeric"), redo LOOP if /\G[\p{Alpha}\pN]+\b[,.;]?\s*/gc;
1612      print(" line-noise"),   redo LOOP if /\G\W+/gc;
1613      print ". That's all!\n";
1614  }
1615
1616 Here is the output (split into several lines):
1617
1618     line-noise lowercase line-noise UPPERCASE line-noise UPPERCASE
1619     line-noise lowercase line-noise lowercase line-noise lowercase
1620     lowercase line-noise lowercase lowercase line-noise lowercase
1621     lowercase line-noise MiXeD line-noise. That's all!
1622
1623 =item m?PATTERN?msixpodualgc
1624 X<?> X<operator, match-once>
1625
1626 =item ?PATTERN?msixpodualgc
1627
1628 This is just like the C<m/PATTERN/> search, except that it matches
1629 only once between calls to the reset() operator.  This is a useful
1630 optimization when you want to see only the first occurrence of
1631 something in each file of a set of files, for instance.  Only C<m??>
1632 patterns local to the current package are reset.
1633
1634     while (<>) {
1635         if (m?^$?) {
1636                             # blank line between header and body
1637         }
1638     } continue {
1639         reset if eof;       # clear m?? status for next file
1640     }
1641
1642 Another example switched the first "latin1" encoding it finds
1643 to "utf8" in a pod file:
1644
1645     s//utf8/ if m? ^ =encoding \h+ \K latin1 ?x;
1646
1647 The match-once behavior is controlled by the match delimiter being
1648 C<?>; with any other delimiter this is the normal C<m//> operator.  
1649
1650 For historical reasons, the leading C<m> in C<m?PATTERN?> is optional,
1651 but the resulting C<?PATTERN?> syntax is deprecated, will warn on
1652 usage and might be removed from a future stable release of Perl (without
1653 further notice!).
1654
1655 =item s/PATTERN/REPLACEMENT/msixpodualgcer
1656 X<substitute> X<substitution> X<replace> X<regexp, replace>
1657 X<regexp, substitute> X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c> X</e> X</r>
1658
1659 Searches a string for a pattern, and if found, replaces that pattern
1660 with the replacement text and returns the number of substitutions
1661 made.  Otherwise it returns false (specifically, the empty string).
1662
1663 If the C</r> (non-destructive) option is used then it runs the
1664 substitution on a copy of the string and instead of returning the
1665 number of substitutions, it returns the copy whether or not a
1666 substitution occurred.  The original string is never changed when
1667 C</r> is used.  The copy will always be a plain string, even if the
1668 input is an object or a tied variable.
1669
1670 If no string is specified via the C<=~> or C<!~> operator, the C<$_>
1671 variable is searched and modified.  Unless the C</r> option is used,
1672 the string specified must be a scalar variable, an array element, a
1673 hash element, or an assignment to one of those; that is, some sort of
1674 scalar lvalue.
1675
1676 If the delimiter chosen is a single quote, no interpolation is
1677 done on either the PATTERN or the REPLACEMENT.  Otherwise, if the
1678 PATTERN contains a $ that looks like a variable rather than an
1679 end-of-string test, the variable will be interpolated into the pattern
1680 at run-time.  If you want the pattern compiled only once the first time
1681 the variable is interpolated, use the C</o> option.  If the pattern
1682 evaluates to the empty string, the last successfully executed regular
1683 expression is used instead.  See L<perlre> for further explanation on these.
1684
1685 Options are as with m// with the addition of the following replacement
1686 specific options:
1687
1688     e   Evaluate the right side as an expression.
1689     ee  Evaluate the right side as a string then eval the result.
1690     r   Return substitution and leave the original string untouched.
1691
1692 Any non-whitespace delimiter may replace the slashes.  Add space after
1693 the C<s> when using a character allowed in identifiers.  If single quotes
1694 are used, no interpretation is done on the replacement string (the C</e>
1695 modifier overrides this, however).  Unlike Perl 4, Perl 5 treats backticks
1696 as normal delimiters; the replacement text is not evaluated as a command.
1697 If the PATTERN is delimited by bracketing quotes, the REPLACEMENT has
1698 its own pair of quotes, which may or may not be bracketing quotes, e.g.,
1699 C<s(foo)(bar)> or C<< s<foo>/bar/ >>.  A C</e> will cause the
1700 replacement portion to be treated as a full-fledged Perl expression
1701 and evaluated right then and there.  It is, however, syntax checked at
1702 compile-time. A second C<e> modifier will cause the replacement portion
1703 to be C<eval>ed before being run as a Perl expression.
1704
1705 Examples:
1706
1707     s/\bgreen\b/mauve/g;                # don't change wintergreen
1708
1709     $path =~ s|/usr/bin|/usr/local/bin|;
1710
1711     s/Login: $foo/Login: $bar/; # run-time pattern
1712
1713     ($foo = $bar) =~ s/this/that/;      # copy first, then change
1714     ($foo = "$bar") =~ s/this/that/;    # convert to string, copy, then change
1715     $foo = $bar =~ s/this/that/r;       # Same as above using /r
1716     $foo = $bar =~ s/this/that/r
1717                 =~ s/that/the other/r;  # Chained substitutes using /r
1718     @foo = map { s/this/that/r } @bar   # /r is very useful in maps
1719
1720     $count = ($paragraph =~ s/Mister\b/Mr./g);  # get change-count
1721
1722     $_ = 'abc123xyz';
1723     s/\d+/$&*2/e;               # yields 'abc246xyz'
1724     s/\d+/sprintf("%5d",$&)/e;  # yields 'abc  246xyz'
1725     s/\w/$& x 2/eg;             # yields 'aabbcc  224466xxyyzz'
1726
1727     s/%(.)/$percent{$1}/g;      # change percent escapes; no /e
1728     s/%(.)/$percent{$1} || $&/ge;       # expr now, so /e
1729     s/^=(\w+)/pod($1)/ge;       # use function call
1730
1731     $_ = 'abc123xyz';
1732     $a = s/abc/def/r;           # $a is 'def123xyz' and
1733                                 # $_ remains 'abc123xyz'.
1734
1735     # expand variables in $_, but dynamics only, using
1736     # symbolic dereferencing
1737     s/\$(\w+)/${$1}/g;
1738
1739     # Add one to the value of any numbers in the string
1740     s/(\d+)/1 + $1/eg;
1741
1742     # Titlecase words in the last 30 characters only
1743     substr($str, -30) =~ s/\b(\p{Alpha}+)\b/\u\L$1/g;
1744
1745     # This will expand any embedded scalar variable
1746     # (including lexicals) in $_ : First $1 is interpolated
1747     # to the variable name, and then evaluated
1748     s/(\$\w+)/$1/eeg;
1749
1750     # Delete (most) C comments.
1751     $program =~ s {
1752         /\*     # Match the opening delimiter.
1753         .*?     # Match a minimal number of characters.
1754         \*/     # Match the closing delimiter.
1755     } []gsx;
1756
1757     s/^\s*(.*?)\s*$/$1/;        # trim whitespace in $_, expensively
1758
1759     for ($variable) {           # trim whitespace in $variable, cheap
1760         s/^\s+//;
1761         s/\s+$//;
1762     }
1763
1764     s/([^ ]*) *([^ ]*)/$2 $1/;  # reverse 1st two fields
1765
1766 Note the use of $ instead of \ in the last example.  Unlike
1767 B<sed>, we use the \<I<digit>> form in only the left hand side.
1768 Anywhere else it's $<I<digit>>.
1769
1770 Occasionally, you can't use just a C</g> to get all the changes
1771 to occur that you might want.  Here are two common cases:
1772
1773     # put commas in the right places in an integer
1774     1 while s/(\d)(\d\d\d)(?!\d)/$1,$2/g;
1775
1776     # expand tabs to 8-column spacing
1777     1 while s/\t+/' ' x (length($&)*8 - length($`)%8)/e;
1778
1779 C<s///le> is treated as a substitution followed by the C<le> operator, not
1780 the C</le> flags.  This may change in a future version of Perl.  It
1781 produces a warning if warnings are enabled.  To disambiguate, use a space
1782 or change the order of the flags:
1783
1784     s/foo/bar/ le 5;  # "le" infix operator
1785     s/foo/bar/el;     # "e" and "l" flags
1786
1787 =back
1788
1789 =head2 Quote-Like Operators
1790 X<operator, quote-like>
1791
1792 =over 4
1793
1794 =item q/STRING/
1795 X<q> X<quote, single> X<'> X<''>
1796
1797 =item 'STRING'
1798
1799 A single-quoted, literal string.  A backslash represents a backslash
1800 unless followed by the delimiter or another backslash, in which case
1801 the delimiter or backslash is interpolated.
1802
1803     $foo = q!I said, "You said, 'She said it.'"!;
1804     $bar = q('This is it.');
1805     $baz = '\n';                # a two-character string
1806
1807 =item qq/STRING/
1808 X<qq> X<quote, double> X<"> X<"">
1809
1810 =item "STRING"
1811
1812 A double-quoted, interpolated string.
1813
1814     $_ .= qq
1815      (*** The previous line contains the naughty word "$1".\n)
1816                 if /\b(tcl|java|python)\b/i;      # :-)
1817     $baz = "\n";                # a one-character string
1818
1819 =item qx/STRING/
1820 X<qx> X<`> X<``> X<backtick>
1821
1822 =item `STRING`
1823
1824 A string which is (possibly) interpolated and then executed as a
1825 system command with C</bin/sh> or its equivalent.  Shell wildcards,
1826 pipes, and redirections will be honored.  The collected standard
1827 output of the command is returned; standard error is unaffected.  In
1828 scalar context, it comes back as a single (potentially multi-line)
1829 string, or undef if the command failed.  In list context, returns a
1830 list of lines (however you've defined lines with $/ or
1831 $INPUT_RECORD_SEPARATOR), or an empty list if the command failed.
1832
1833 Because backticks do not affect standard error, use shell file descriptor
1834 syntax (assuming the shell supports this) if you care to address this.
1835 To capture a command's STDERR and STDOUT together:
1836
1837     $output = `cmd 2>&1`;
1838
1839 To capture a command's STDOUT but discard its STDERR:
1840
1841     $output = `cmd 2>/dev/null`;
1842
1843 To capture a command's STDERR but discard its STDOUT (ordering is
1844 important here):
1845
1846     $output = `cmd 2>&1 1>/dev/null`;
1847
1848 To exchange a command's STDOUT and STDERR in order to capture the STDERR
1849 but leave its STDOUT to come out the old STDERR:
1850
1851     $output = `cmd 3>&1 1>&2 2>&3 3>&-`;
1852
1853 To read both a command's STDOUT and its STDERR separately, it's easiest
1854 to redirect them separately to files, and then read from those files
1855 when the program is done:
1856
1857     system("program args 1>program.stdout 2>program.stderr");
1858
1859 The STDIN filehandle used by the command is inherited from Perl's STDIN.
1860 For example:
1861
1862     open(SPLAT, "stuff")   || die "can't open stuff: $!";
1863     open(STDIN, "<&SPLAT") || die "can't dupe SPLAT: $!";
1864     print STDOUT `sort`;
1865
1866 will print the sorted contents of the file named F<"stuff">.
1867
1868 Using single-quote as a delimiter protects the command from Perl's
1869 double-quote interpolation, passing it on to the shell instead:
1870
1871     $perl_info  = qx(ps $$);            # that's Perl's $$
1872     $shell_info = qx'ps $$';            # that's the new shell's $$
1873
1874 How that string gets evaluated is entirely subject to the command
1875 interpreter on your system.  On most platforms, you will have to protect
1876 shell metacharacters if you want them treated literally.  This is in
1877 practice difficult to do, as it's unclear how to escape which characters.
1878 See L<perlsec> for a clean and safe example of a manual fork() and exec()
1879 to emulate backticks safely.
1880
1881 On some platforms (notably DOS-like ones), the shell may not be
1882 capable of dealing with multiline commands, so putting newlines in
1883 the string may not get you what you want.  You may be able to evaluate
1884 multiple commands in a single line by separating them with the command
1885 separator character, if your shell supports that (e.g. C<;> on many Unix
1886 shells; C<&> on the Windows NT C<cmd> shell).
1887
1888 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1889 output before starting the child process, but this may not be supported
1890 on some platforms (see L<perlport>).  To be safe, you may need to set
1891 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1892 C<IO::Handle> on any open handles.
1893
1894 Beware that some command shells may place restrictions on the length
1895 of the command line.  You must ensure your strings don't exceed this
1896 limit after any necessary interpolations.  See the platform-specific
1897 release notes for more details about your particular environment.
1898
1899 Using this operator can lead to programs that are difficult to port,
1900 because the shell commands called vary between systems, and may in
1901 fact not be present at all.  As one example, the C<type> command under
1902 the POSIX shell is very different from the C<type> command under DOS.
1903 That doesn't mean you should go out of your way to avoid backticks
1904 when they're the right way to get something done.  Perl was made to be
1905 a glue language, and one of the things it glues together is commands.
1906 Just understand what you're getting yourself into.
1907
1908 See L</"I/O Operators"> for more discussion.
1909
1910 =item qw/STRING/
1911 X<qw> X<quote, list> X<quote, words>
1912
1913 Evaluates to a list of the words extracted out of STRING, using embedded
1914 whitespace as the word delimiters.  It can be understood as being roughly
1915 equivalent to:
1916
1917     split(" ", q/STRING/);
1918
1919 the differences being that it generates a real list at compile time, and
1920 in scalar context it returns the last element in the list.  So
1921 this expression:
1922
1923     qw(foo bar baz)
1924
1925 is semantically equivalent to the list:
1926
1927     "foo", "bar", "baz"
1928
1929 Some frequently seen examples:
1930
1931     use POSIX qw( setlocale localeconv )
1932     @EXPORT = qw( foo bar baz );
1933
1934 A common mistake is to try to separate the words with comma or to
1935 put comments into a multi-line C<qw>-string.  For this reason, the
1936 C<use warnings> pragma and the B<-w> switch (that is, the C<$^W> variable)
1937 produces warnings if the STRING contains the "," or the "#" character.
1938
1939 =item tr/SEARCHLIST/REPLACEMENTLIST/cdsr
1940 X<tr> X<y> X<transliterate> X</c> X</d> X</s>
1941
1942 =item y/SEARCHLIST/REPLACEMENTLIST/cdsr
1943
1944 Transliterates all occurrences of the characters found in the search list
1945 with the corresponding character in the replacement list.  It returns
1946 the number of characters replaced or deleted.  If no string is
1947 specified via the C<=~> or C<!~> operator, the $_ string is transliterated.
1948
1949 If the C</r> (non-destructive) option is present, a new copy of the string
1950 is made and its characters transliterated, and this copy is returned no
1951 matter whether it was modified or not: the original string is always
1952 left unchanged.  The new copy is always a plain string, even if the input
1953 string is an object or a tied variable.
1954
1955 Unless the C</r> option is used, the string specified with C<=~> must be a
1956 scalar variable, an array element, a hash element, or an assignment to one
1957 of those; in other words, an lvalue.
1958
1959 A character range may be specified with a hyphen, so C<tr/A-J/0-9/>
1960 does the same replacement as C<tr/ACEGIBDFHJ/0246813579/>.
1961 For B<sed> devotees, C<y> is provided as a synonym for C<tr>.  If the
1962 SEARCHLIST is delimited by bracketing quotes, the REPLACEMENTLIST has
1963 its own pair of quotes, which may or may not be bracketing quotes;
1964 for example, C<tr[aeiouy][yuoiea]> or C<tr(+\-*/)/ABCD/>.
1965
1966 Note that C<tr> does B<not> do regular expression character classes such as
1967 C<\d> or C<\pL>.  The C<tr> operator is not equivalent to the tr(1)
1968 utility.  If you want to map strings between lower/upper cases, see
1969 L<perlfunc/lc> and L<perlfunc/uc>, and in general consider using the C<s>
1970 operator if you need regular expressions.  The C<\U>, C<\u>, C<\L>, and
1971 C<\l> string-interpolation escapes on the right side of a substitution
1972 operator will perform correct case-mappings, but C<tr[a-z][A-Z]> will not
1973 (except sometimes on legacy 7-bit data).
1974
1975 Note also that the whole range idea is rather unportable between
1976 character sets--and even within character sets they may cause results
1977 you probably didn't expect.  A sound principle is to use only ranges
1978 that begin from and end at either alphabets of equal case (a-e, A-E),
1979 or digits (0-4).  Anything else is unsafe.  If in doubt, spell out the
1980 character sets in full.
1981
1982 Options:
1983
1984     c   Complement the SEARCHLIST.
1985     d   Delete found but unreplaced characters.
1986     s   Squash duplicate replaced characters.
1987     r   Return the modified string and leave the original string
1988         untouched.
1989
1990 If the C</c> modifier is specified, the SEARCHLIST character set
1991 is complemented.  If the C</d> modifier is specified, any characters
1992 specified by SEARCHLIST not found in REPLACEMENTLIST are deleted.
1993 (Note that this is slightly more flexible than the behavior of some
1994 B<tr> programs, which delete anything they find in the SEARCHLIST,
1995 period.) If the C</s> modifier is specified, sequences of characters
1996 that were transliterated to the same character are squashed down
1997 to a single instance of the character.
1998
1999 If the C</d> modifier is used, the REPLACEMENTLIST is always interpreted
2000 exactly as specified.  Otherwise, if the REPLACEMENTLIST is shorter
2001 than the SEARCHLIST, the final character is replicated till it is long
2002 enough.  If the REPLACEMENTLIST is empty, the SEARCHLIST is replicated.
2003 This latter is useful for counting characters in a class or for
2004 squashing character sequences in a class.
2005
2006 Examples:
2007
2008     $ARGV[1] =~ tr/A-Z/a-z/;    # canonicalize to lower case ASCII
2009
2010     $cnt = tr/*/*/;             # count the stars in $_
2011
2012     $cnt = $sky =~ tr/*/*/;     # count the stars in $sky
2013
2014     $cnt = tr/0-9//;            # count the digits in $_
2015
2016     tr/a-zA-Z//s;               # bookkeeper -> bokeper
2017
2018     ($HOST = $host) =~ tr/a-z/A-Z/;
2019      $HOST = $host  =~ tr/a-z/A-Z/r;   # same thing
2020
2021     $HOST = $host =~ tr/a-z/A-Z/r    # chained with s///r
2022                   =~ s/:/ -p/r;
2023
2024     tr/a-zA-Z/ /cs;             # change non-alphas to single space
2025
2026     @stripped = map tr/a-zA-Z/ /csr, @original;
2027                                 # /r with map
2028
2029     tr [\200-\377]
2030        [\000-\177];             # wickedly delete 8th bit
2031
2032 If multiple transliterations are given for a character, only the
2033 first one is used:
2034
2035     tr/AAA/XYZ/
2036
2037 will transliterate any A to X.
2038
2039 Because the transliteration table is built at compile time, neither
2040 the SEARCHLIST nor the REPLACEMENTLIST are subjected to double quote
2041 interpolation.  That means that if you want to use variables, you
2042 must use an eval():
2043
2044     eval "tr/$oldlist/$newlist/";
2045     die $@ if $@;
2046
2047     eval "tr/$oldlist/$newlist/, 1" or die $@;
2048
2049 =item <<EOF
2050 X<here-doc> X<heredoc> X<here-document> X<<< << >>>
2051
2052 A line-oriented form of quoting is based on the shell "here-document"
2053 syntax.  Following a C<< << >> you specify a string to terminate
2054 the quoted material, and all lines following the current line down to
2055 the terminating string are the value of the item.
2056
2057 The terminating string may be either an identifier (a word), or some
2058 quoted text.  An unquoted identifier works like double quotes.
2059 There may not be a space between the C<< << >> and the identifier,
2060 unless the identifier is explicitly quoted.  (If you put a space it
2061 will be treated as a null identifier, which is valid, and matches the
2062 first empty line.)  The terminating string must appear by itself
2063 (unquoted and with no surrounding whitespace) on the terminating line.
2064
2065 If the terminating string is quoted, the type of quotes used determine
2066 the treatment of the text.
2067
2068 =over 4
2069
2070 =item Double Quotes
2071
2072 Double quotes indicate that the text will be interpolated using exactly
2073 the same rules as normal double quoted strings.
2074
2075        print <<EOF;
2076     The price is $Price.
2077     EOF
2078
2079        print << "EOF"; # same as above
2080     The price is $Price.
2081     EOF
2082
2083
2084 =item Single Quotes
2085
2086 Single quotes indicate the text is to be treated literally with no
2087 interpolation of its content. This is similar to single quoted
2088 strings except that backslashes have no special meaning, with C<\\>
2089 being treated as two backslashes and not one as they would in every
2090 other quoting construct.
2091
2092 Just as in the shell, a backslashed bareword following the C<<< << >>>
2093 means the same thing as a single-quoted string does:
2094
2095         $cost = <<'VISTA';  # hasta la ...
2096     That'll be $10 please, ma'am.
2097     VISTA
2098
2099         $cost = <<\VISTA;   # Same thing!
2100     That'll be $10 please, ma'am.
2101     VISTA
2102
2103 This is the only form of quoting in perl where there is no need
2104 to worry about escaping content, something that code generators
2105 can and do make good use of.
2106
2107 =item Backticks
2108
2109 The content of the here doc is treated just as it would be if the
2110 string were embedded in backticks. Thus the content is interpolated
2111 as though it were double quoted and then executed via the shell, with
2112 the results of the execution returned.
2113
2114        print << `EOC`; # execute command and get results
2115     echo hi there
2116     EOC
2117
2118 =back
2119
2120 It is possible to stack multiple here-docs in a row:
2121
2122        print <<"foo", <<"bar"; # you can stack them
2123     I said foo.
2124     foo
2125     I said bar.
2126     bar
2127
2128        myfunc(<< "THIS", 23, <<'THAT');
2129     Here's a line
2130     or two.
2131     THIS
2132     and here's another.
2133     THAT
2134
2135 Just don't forget that you have to put a semicolon on the end
2136 to finish the statement, as Perl doesn't know you're not going to
2137 try to do this:
2138
2139        print <<ABC
2140     179231
2141     ABC
2142        + 20;
2143
2144 If you want to remove the line terminator from your here-docs,
2145 use C<chomp()>.
2146
2147     chomp($string = <<'END');
2148     This is a string.
2149     END
2150
2151 If you want your here-docs to be indented with the rest of the code,
2152 you'll need to remove leading whitespace from each line manually:
2153
2154     ($quote = <<'FINIS') =~ s/^\s+//gm;
2155        The Road goes ever on and on,
2156        down from the door where it began.
2157     FINIS
2158
2159 If you use a here-doc within a delimited construct, such as in C<s///eg>,
2160 the quoted material must come on the lines following the final delimiter.
2161 So instead of
2162
2163     s/this/<<E . 'that'
2164     the other
2165     E
2166      . 'more '/eg;
2167
2168 you have to write
2169
2170     s/this/<<E . 'that'
2171      . 'more '/eg;
2172     the other
2173     E
2174
2175 If the terminating identifier is on the last line of the program, you
2176 must be sure there is a newline after it; otherwise, Perl will give the
2177 warning B<Can't find string terminator "END" anywhere before EOF...>.
2178
2179 Additionally, quoting rules for the end-of-string identifier are
2180 unrelated to Perl's quoting rules. C<q()>, C<qq()>, and the like are not
2181 supported in place of C<''> and C<"">, and the only interpolation is for
2182 backslashing the quoting character:
2183
2184     print << "abc\"def";
2185     testing...
2186     abc"def
2187
2188 Finally, quoted strings cannot span multiple lines.  The general rule is
2189 that the identifier must be a string literal.  Stick with that, and you
2190 should be safe.
2191
2192 =back
2193
2194 =head2 Gory details of parsing quoted constructs
2195 X<quote, gory details>
2196
2197 When presented with something that might have several different
2198 interpretations, Perl uses the B<DWIM> (that's "Do What I Mean")
2199 principle to pick the most probable interpretation.  This strategy
2200 is so successful that Perl programmers often do not suspect the
2201 ambivalence of what they write.  But from time to time, Perl's
2202 notions differ substantially from what the author honestly meant.
2203
2204 This section hopes to clarify how Perl handles quoted constructs.
2205 Although the most common reason to learn this is to unravel labyrinthine
2206 regular expressions, because the initial steps of parsing are the
2207 same for all quoting operators, they are all discussed together.
2208
2209 The most important Perl parsing rule is the first one discussed
2210 below: when processing a quoted construct, Perl first finds the end
2211 of that construct, then interprets its contents.  If you understand
2212 this rule, you may skip the rest of this section on the first
2213 reading.  The other rules are likely to contradict the user's
2214 expectations much less frequently than this first one.
2215
2216 Some passes discussed below are performed concurrently, but because
2217 their results are the same, we consider them individually.  For different
2218 quoting constructs, Perl performs different numbers of passes, from
2219 one to four, but these passes are always performed in the same order.
2220
2221 =over 4
2222
2223 =item Finding the end
2224
2225 The first pass is finding the end of the quoted construct, where
2226 the information about the delimiters is used in parsing.
2227 During this search, text between the starting and ending delimiters
2228 is copied to a safe location. The text copied gets delimiter-independent.
2229
2230 If the construct is a here-doc, the ending delimiter is a line
2231 that has a terminating string as the content. Therefore C<<<EOF> is
2232 terminated by C<EOF> immediately followed by C<"\n"> and starting
2233 from the first column of the terminating line.
2234 When searching for the terminating line of a here-doc, nothing
2235 is skipped. In other words, lines after the here-doc syntax
2236 are compared with the terminating string line by line.
2237
2238 For the constructs except here-docs, single characters are used as starting
2239 and ending delimiters. If the starting delimiter is an opening punctuation
2240 (that is C<(>, C<[>, C<{>, or C<< < >>), the ending delimiter is the
2241 corresponding closing punctuation (that is C<)>, C<]>, C<}>, or C<< > >>).
2242 If the starting delimiter is an unpaired character like C</> or a closing
2243 punctuation, the ending delimiter is same as the starting delimiter.
2244 Therefore a C</> terminates a C<qq//> construct, while a C<]> terminates
2245 C<qq[]> and C<qq]]> constructs.
2246
2247 When searching for single-character delimiters, escaped delimiters
2248 and C<\\> are skipped. For example, while searching for terminating C</>,
2249 combinations of C<\\> and C<\/> are skipped.  If the delimiters are
2250 bracketing, nested pairs are also skipped.  For example, while searching
2251 for closing C<]> paired with the opening C<[>, combinations of C<\\>, C<\]>,
2252 and C<\[> are all skipped, and nested C<[> and C<]> are skipped as well.
2253 However, when backslashes are used as the delimiters (like C<qq\\> and
2254 C<tr\\\>), nothing is skipped.
2255 During the search for the end, backslashes that escape delimiters
2256 are removed (exactly speaking, they are not copied to the safe location).
2257
2258 For constructs with three-part delimiters (C<s///>, C<y///>, and
2259 C<tr///>), the search is repeated once more.
2260 If the first delimiter is not an opening punctuation, three delimiters must
2261 be same such as C<s!!!> and C<tr)))>, in which case the second delimiter
2262 terminates the left part and starts the right part at once.
2263 If the left part is delimited by bracketing punctuation (that is C<()>,
2264 C<[]>, C<{}>, or C<< <> >>), the right part needs another pair of
2265 delimiters such as C<s(){}> and C<tr[]//>.  In these cases, whitespace
2266 and comments are allowed between both parts, though the comment must follow
2267 at least one whitespace character; otherwise a character expected as the 
2268 start of the comment may be regarded as the starting delimiter of the right part.
2269
2270 During this search no attention is paid to the semantics of the construct.
2271 Thus:
2272
2273     "$hash{"$foo/$bar"}"
2274
2275 or:
2276
2277     m/
2278       bar       # NOT a comment, this slash / terminated m//!
2279      /x
2280
2281 do not form legal quoted expressions.   The quoted part ends on the
2282 first C<"> and C</>, and the rest happens to be a syntax error.
2283 Because the slash that terminated C<m//> was followed by a C<SPACE>,
2284 the example above is not C<m//x>, but rather C<m//> with no C</x>
2285 modifier.  So the embedded C<#> is interpreted as a literal C<#>.
2286
2287 Also no attention is paid to C<\c\> (multichar control char syntax) during
2288 this search. Thus the second C<\> in C<qq/\c\/> is interpreted as a part
2289 of C<\/>, and the following C</> is not recognized as a delimiter.
2290 Instead, use C<\034> or C<\x1c> at the end of quoted constructs.
2291
2292 =item Interpolation
2293 X<interpolation>
2294
2295 The next step is interpolation in the text obtained, which is now
2296 delimiter-independent.  There are multiple cases.
2297
2298 =over 4
2299
2300 =item C<<<'EOF'>
2301
2302 No interpolation is performed.
2303 Note that the combination C<\\> is left intact, since escaped delimiters
2304 are not available for here-docs.
2305
2306 =item  C<m''>, the pattern of C<s'''>
2307
2308 No interpolation is performed at this stage.
2309 Any backslashed sequences including C<\\> are treated at the stage
2310 to L</"parsing regular expressions">.
2311
2312 =item C<''>, C<q//>, C<tr'''>, C<y'''>, the replacement of C<s'''>
2313
2314 The only interpolation is removal of C<\> from pairs of C<\\>.
2315 Therefore C<-> in C<tr'''> and C<y'''> is treated literally
2316 as a hyphen and no character range is available.
2317 C<\1> in the replacement of C<s'''> does not work as C<$1>.
2318
2319 =item C<tr///>, C<y///>
2320
2321 No variable interpolation occurs.  String modifying combinations for
2322 case and quoting such as C<\Q>, C<\U>, and C<\E> are not recognized.
2323 The other escape sequences such as C<\200> and C<\t> and backslashed
2324 characters such as C<\\> and C<\-> are converted to appropriate literals.
2325 The character C<-> is treated specially and therefore C<\-> is treated
2326 as a literal C<->.
2327
2328 =item C<"">, C<``>, C<qq//>, C<qx//>, C<< <file*glob> >>, C<<<"EOF">
2329
2330 C<\Q>, C<\U>, C<\u>, C<\L>, C<\l> (possibly paired with C<\E>) are
2331 converted to corresponding Perl constructs.  Thus, C<"$foo\Qbaz$bar">
2332 is converted to C<$foo . (quotemeta("baz" . $bar))> internally.
2333 The other escape sequences such as C<\200> and C<\t> and backslashed
2334 characters such as C<\\> and C<\-> are replaced with appropriate
2335 expansions.
2336
2337 Let it be stressed that I<whatever falls between C<\Q> and C<\E>>
2338 is interpolated in the usual way.  Something like C<"\Q\\E"> has
2339 no C<\E> inside.  instead, it has C<\Q>, C<\\>, and C<E>, so the
2340 result is the same as for C<"\\\\E">.  As a general rule, backslashes
2341 between C<\Q> and C<\E> may lead to counterintuitive results.  So,
2342 C<"\Q\t\E"> is converted to C<quotemeta("\t")>, which is the same
2343 as C<"\\\t"> (since TAB is not alphanumeric).  Note also that:
2344
2345   $str = '\t';
2346   return "\Q$str";
2347
2348 may be closer to the conjectural I<intention> of the writer of C<"\Q\t\E">.
2349
2350 Interpolated scalars and arrays are converted internally to the C<join> and
2351 C<.> catenation operations.  Thus, C<"$foo XXX '@arr'"> becomes:
2352
2353   $foo . " XXX '" . (join $", @arr) . "'";
2354
2355 All operations above are performed simultaneously, left to right.
2356
2357 Because the result of C<"\Q STRING \E"> has all metacharacters
2358 quoted, there is no way to insert a literal C<$> or C<@> inside a
2359 C<\Q\E> pair.  If protected by C<\>, C<$> will be quoted to became
2360 C<"\\\$">; if not, it is interpreted as the start of an interpolated
2361 scalar.
2362
2363 Note also that the interpolation code needs to make a decision on
2364 where the interpolated scalar ends.  For instance, whether
2365 C<< "a $b -> {c}" >> really means:
2366
2367   "a " . $b . " -> {c}";
2368
2369 or:
2370
2371   "a " . $b -> {c};
2372
2373 Most of the time, the longest possible text that does not include
2374 spaces between components and which contains matching braces or
2375 brackets.  because the outcome may be determined by voting based
2376 on heuristic estimators, the result is not strictly predictable.
2377 Fortunately, it's usually correct for ambiguous cases.
2378
2379 =item the replacement of C<s///>
2380
2381 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, and interpolation
2382 happens as with C<qq//> constructs.
2383
2384 It is at this step that C<\1> is begrudgingly converted to C<$1> in
2385 the replacement text of C<s///>, in order to correct the incorrigible
2386 I<sed> hackers who haven't picked up the saner idiom yet.  A warning
2387 is emitted if the C<use warnings> pragma or the B<-w> command-line flag
2388 (that is, the C<$^W> variable) was set.
2389
2390 =item C<RE> in C<?RE?>, C</RE/>, C<m/RE/>, C<s/RE/foo/>,
2391
2392 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\E>,
2393 and interpolation happens (almost) as with C<qq//> constructs.
2394
2395 Processing of C<\N{...}> is also done here, and compiled into an intermediate
2396 form for the regex compiler.  (This is because, as mentioned below, the regex
2397 compilation may be done at execution time, and C<\N{...}> is a compile-time
2398 construct.)
2399
2400 However any other combinations of C<\> followed by a character
2401 are not substituted but only skipped, in order to parse them
2402 as regular expressions at the following step.
2403 As C<\c> is skipped at this step, C<@> of C<\c@> in RE is possibly
2404 treated as an array symbol (for example C<@foo>),
2405 even though the same text in C<qq//> gives interpolation of C<\c@>.
2406
2407 Moreover, inside C<(?{BLOCK})>, C<(?# comment )>, and
2408 a C<#>-comment in a C<//x>-regular expression, no processing is
2409 performed whatsoever.  This is the first step at which the presence
2410 of the C<//x> modifier is relevant.
2411
2412 Interpolation in patterns has several quirks: C<$|>, C<$(>, C<$)>, C<@+>
2413 and C<@-> are not interpolated, and constructs C<$var[SOMETHING]> are
2414 voted (by several different estimators) to be either an array element
2415 or C<$var> followed by an RE alternative.  This is where the notation
2416 C<${arr[$bar]}> comes handy: C</${arr[0-9]}/> is interpreted as
2417 array element C<-9>, not as a regular expression from the variable
2418 C<$arr> followed by a digit, which would be the interpretation of
2419 C</$arr[0-9]/>.  Since voting among different estimators may occur,
2420 the result is not predictable.
2421
2422 The lack of processing of C<\\> creates specific restrictions on
2423 the post-processed text.  If the delimiter is C</>, one cannot get
2424 the combination C<\/> into the result of this step.  C</> will
2425 finish the regular expression, C<\/> will be stripped to C</> on
2426 the previous step, and C<\\/> will be left as is.  Because C</> is
2427 equivalent to C<\/> inside a regular expression, this does not
2428 matter unless the delimiter happens to be character special to the
2429 RE engine, such as in C<s*foo*bar*>, C<m[foo]>, or C<?foo?>; or an
2430 alphanumeric char, as in:
2431
2432   m m ^ a \s* b mmx;
2433
2434 In the RE above, which is intentionally obfuscated for illustration, the
2435 delimiter is C<m>, the modifier is C<mx>, and after delimiter-removal the
2436 RE is the same as for C<m/ ^ a \s* b /mx>.  There's more than one
2437 reason you're encouraged to restrict your delimiters to non-alphanumeric,
2438 non-whitespace choices.
2439
2440 =back
2441
2442 This step is the last one for all constructs except regular expressions,
2443 which are processed further.
2444
2445 =item parsing regular expressions
2446 X<regexp, parse>
2447
2448 Previous steps were performed during the compilation of Perl code,
2449 but this one happens at run time, although it may be optimized to
2450 be calculated at compile time if appropriate.  After preprocessing
2451 described above, and possibly after evaluation if concatenation,
2452 joining, casing translation, or metaquoting are involved, the
2453 resulting I<string> is passed to the RE engine for compilation.
2454
2455 Whatever happens in the RE engine might be better discussed in L<perlre>,
2456 but for the sake of continuity, we shall do so here.
2457
2458 This is another step where the presence of the C<//x> modifier is
2459 relevant.  The RE engine scans the string from left to right and
2460 converts it to a finite automaton.
2461
2462 Backslashed characters are either replaced with corresponding
2463 literal strings (as with C<\{>), or else they generate special nodes
2464 in the finite automaton (as with C<\b>).  Characters special to the
2465 RE engine (such as C<|>) generate corresponding nodes or groups of
2466 nodes.  C<(?#...)> comments are ignored.  All the rest is either
2467 converted to literal strings to match, or else is ignored (as is
2468 whitespace and C<#>-style comments if C<//x> is present).
2469
2470 Parsing of the bracketed character class construct, C<[...]>, is
2471 rather different than the rule used for the rest of the pattern.
2472 The terminator of this construct is found using the same rules as
2473 for finding the terminator of a C<{}>-delimited construct, the only
2474 exception being that C<]> immediately following C<[> is treated as
2475 though preceded by a backslash.  Similarly, the terminator of
2476 C<(?{...})> is found using the same rules as for finding the
2477 terminator of a C<{}>-delimited construct.
2478
2479 It is possible to inspect both the string given to RE engine and the
2480 resulting finite automaton.  See the arguments C<debug>/C<debugcolor>
2481 in the C<use L<re>> pragma, as well as Perl's B<-Dr> command-line
2482 switch documented in L<perlrun/"Command Switches">.
2483
2484 =item Optimization of regular expressions
2485 X<regexp, optimization>
2486
2487 This step is listed for completeness only.  Since it does not change
2488 semantics, details of this step are not documented and are subject
2489 to change without notice.  This step is performed over the finite
2490 automaton that was generated during the previous pass.
2491
2492 It is at this stage that C<split()> silently optimizes C</^/> to
2493 mean C</^/m>.
2494
2495 =back
2496
2497 =head2 I/O Operators
2498 X<operator, i/o> X<operator, io> X<io> X<while> X<filehandle>
2499 X<< <> >> X<@ARGV>
2500
2501 There are several I/O operators you should know about.
2502
2503 A string enclosed by backticks (grave accents) first undergoes
2504 double-quote interpolation.  It is then interpreted as an external
2505 command, and the output of that command is the value of the
2506 backtick string, like in a shell.  In scalar context, a single string
2507 consisting of all output is returned.  In list context, a list of
2508 values is returned, one per line of output.  (You can set C<$/> to use
2509 a different line terminator.)  The command is executed each time the
2510 pseudo-literal is evaluated.  The status value of the command is
2511 returned in C<$?> (see L<perlvar> for the interpretation of C<$?>).
2512 Unlike in B<csh>, no translation is done on the return data--newlines
2513 remain newlines.  Unlike in any of the shells, single quotes do not
2514 hide variable names in the command from interpretation.  To pass a
2515 literal dollar-sign through to the shell you need to hide it with a
2516 backslash.  The generalized form of backticks is C<qx//>.  (Because
2517 backticks always undergo shell expansion as well, see L<perlsec> for
2518 security concerns.)
2519 X<qx> X<`> X<``> X<backtick> X<glob>
2520
2521 In scalar context, evaluating a filehandle in angle brackets yields
2522 the next line from that file (the newline, if any, included), or
2523 C<undef> at end-of-file or on error.  When C<$/> is set to C<undef>
2524 (sometimes known as file-slurp mode) and the file is empty, it
2525 returns C<''> the first time, followed by C<undef> subsequently.
2526
2527 Ordinarily you must assign the returned value to a variable, but
2528 there is one situation where an automatic assignment happens.  If
2529 and only if the input symbol is the only thing inside the conditional
2530 of a C<while> statement (even if disguised as a C<for(;;)> loop),
2531 the value is automatically assigned to the global variable $_,
2532 destroying whatever was there previously.  (This may seem like an
2533 odd thing to you, but you'll use the construct in almost every Perl
2534 script you write.)  The $_ variable is not implicitly localized.
2535 You'll have to put a C<local $_;> before the loop if you want that
2536 to happen.
2537
2538 The following lines are equivalent:
2539
2540     while (defined($_ = <STDIN>)) { print; }
2541     while ($_ = <STDIN>) { print; }
2542     while (<STDIN>) { print; }
2543     for (;<STDIN>;) { print; }
2544     print while defined($_ = <STDIN>);
2545     print while ($_ = <STDIN>);
2546     print while <STDIN>;
2547
2548 This also behaves similarly, but avoids $_ :
2549
2550     while (my $line = <STDIN>) { print $line }
2551
2552 In these loop constructs, the assigned value (whether assignment
2553 is automatic or explicit) is then tested to see whether it is
2554 defined.  The defined test avoids problems where line has a string
2555 value that would be treated as false by Perl, for example a "" or
2556 a "0" with no trailing newline.  If you really mean for such values
2557 to terminate the loop, they should be tested for explicitly:
2558
2559     while (($_ = <STDIN>) ne '0') { ... }
2560     while (<STDIN>) { last unless $_; ... }
2561
2562 In other boolean contexts, C<< <filehandle> >> without an
2563 explicit C<defined> test or comparison elicits a warning if the
2564 C<use warnings> pragma or the B<-w>
2565 command-line switch (the C<$^W> variable) is in effect.
2566
2567 The filehandles STDIN, STDOUT, and STDERR are predefined.  (The
2568 filehandles C<stdin>, C<stdout>, and C<stderr> will also work except
2569 in packages, where they would be interpreted as local identifiers
2570 rather than global.)  Additional filehandles may be created with
2571 the open() function, amongst others.  See L<perlopentut> and
2572 L<perlfunc/open> for details on this.
2573 X<stdin> X<stdout> X<sterr>
2574
2575 If a <FILEHANDLE> is used in a context that is looking for
2576 a list, a list comprising all input lines is returned, one line per
2577 list element.  It's easy to grow to a rather large data space this
2578 way, so use with care.
2579
2580 <FILEHANDLE> may also be spelled C<readline(*FILEHANDLE)>.
2581 See L<perlfunc/readline>.
2582
2583 The null filehandle <> is special: it can be used to emulate the
2584 behavior of B<sed> and B<awk>.  Input from <> comes either from
2585 standard input, or from each file listed on the command line.  Here's
2586 how it works: the first time <> is evaluated, the @ARGV array is
2587 checked, and if it is empty, C<$ARGV[0]> is set to "-", which when opened
2588 gives you standard input.  The @ARGV array is then processed as a list
2589 of filenames.  The loop
2590
2591     while (<>) {
2592         ...                     # code for each line
2593     }
2594
2595 is equivalent to the following Perl-like pseudo code:
2596
2597     unshift(@ARGV, '-') unless @ARGV;
2598     while ($ARGV = shift) {
2599         open(ARGV, $ARGV);
2600         while (<ARGV>) {
2601             ...         # code for each line
2602         }
2603     }
2604
2605 except that it isn't so cumbersome to say, and will actually work.
2606 It really does shift the @ARGV array and put the current filename
2607 into the $ARGV variable.  It also uses filehandle I<ARGV>
2608 internally. <> is just a synonym for <ARGV>, which
2609 is magical.  (The pseudo code above doesn't work because it treats
2610 <ARGV> as non-magical.)
2611
2612 Since the null filehandle uses the two argument form of L<perlfunc/open>
2613 it interprets special characters, so if you have a script like this:
2614
2615     while (<>) {
2616         print;
2617     }
2618
2619 and call it with C<perl dangerous.pl 'rm -rfv *|'>, it actually opens a
2620 pipe, executes the C<rm> command and reads C<rm>'s output from that pipe.
2621 If you want all items in C<@ARGV> to be interpreted as file names, you
2622 can use the module C<ARGV::readonly> from CPAN.
2623
2624 You can modify @ARGV before the first <> as long as the array ends up
2625 containing the list of filenames you really want.  Line numbers (C<$.>)
2626 continue as though the input were one big happy file.  See the example
2627 in L<perlfunc/eof> for how to reset line numbers on each file.
2628
2629 If you want to set @ARGV to your own list of files, go right ahead.
2630 This sets @ARGV to all plain text files if no @ARGV was given:
2631
2632     @ARGV = grep { -f && -T } glob('*') unless @ARGV;
2633
2634 You can even set them to pipe commands.  For example, this automatically
2635 filters compressed arguments through B<gzip>:
2636
2637     @ARGV = map { /\.(gz|Z)$/ ? "gzip -dc < $_ |" : $_ } @ARGV;
2638
2639 If you want to pass switches into your script, you can use one of the
2640 Getopts modules or put a loop on the front like this:
2641
2642     while ($_ = $ARGV[0], /^-/) {
2643         shift;
2644         last if /^--$/;
2645         if (/^-D(.*)/) { $debug = $1 }
2646         if (/^-v/)     { $verbose++  }
2647         # ...           # other switches
2648     }
2649
2650     while (<>) {
2651         # ...           # code for each line
2652     }
2653
2654 The <> symbol will return C<undef> for end-of-file only once.
2655 If you call it again after this, it will assume you are processing another
2656 @ARGV list, and if you haven't set @ARGV, will read input from STDIN.
2657
2658 If what the angle brackets contain is a simple scalar variable (e.g.,
2659 <$foo>), then that variable contains the name of the
2660 filehandle to input from, or its typeglob, or a reference to the
2661 same.  For example:
2662
2663     $fh = \*STDIN;
2664     $line = <$fh>;
2665
2666 If what's within the angle brackets is neither a filehandle nor a simple
2667 scalar variable containing a filehandle name, typeglob, or typeglob
2668 reference, it is interpreted as a filename pattern to be globbed, and
2669 either a list of filenames or the next filename in the list is returned,
2670 depending on context.  This distinction is determined on syntactic
2671 grounds alone.  That means C<< <$x> >> is always a readline() from
2672 an indirect handle, but C<< <$hash{key}> >> is always a glob().
2673 That's because $x is a simple scalar variable, but C<$hash{key}> is
2674 not--it's a hash element.  Even C<< <$x > >> (note the extra space)
2675 is treated as C<glob("$x ")>, not C<readline($x)>.
2676
2677 One level of double-quote interpretation is done first, but you can't
2678 say C<< <$foo> >> because that's an indirect filehandle as explained
2679 in the previous paragraph.  (In older versions of Perl, programmers
2680 would insert curly brackets to force interpretation as a filename glob:
2681 C<< <${foo}> >>.  These days, it's considered cleaner to call the
2682 internal function directly as C<glob($foo)>, which is probably the right
2683 way to have done it in the first place.)  For example:
2684
2685     while (<*.c>) {
2686         chmod 0644, $_;
2687     }
2688
2689 is roughly equivalent to:
2690
2691     open(FOO, "echo *.c | tr -s ' \t\r\f' '\\012\\012\\012\\012'|");
2692     while (<FOO>) {
2693         chomp;
2694         chmod 0644, $_;
2695     }
2696
2697 except that the globbing is actually done internally using the standard
2698 C<File::Glob> extension.  Of course, the shortest way to do the above is:
2699
2700     chmod 0644, <*.c>;
2701
2702 A (file)glob evaluates its (embedded) argument only when it is
2703 starting a new list.  All values must be read before it will start
2704 over.  In list context, this isn't important because you automatically
2705 get them all anyway.  However, in scalar context the operator returns
2706 the next value each time it's called, or C<undef> when the list has
2707 run out.  As with filehandle reads, an automatic C<defined> is
2708 generated when the glob occurs in the test part of a C<while>,
2709 because legal glob returns (e.g. a file called F<0>) would otherwise
2710 terminate the loop.  Again, C<undef> is returned only once.  So if
2711 you're expecting a single value from a glob, it is much better to
2712 say
2713
2714     ($file) = <blurch*>;
2715
2716 than
2717
2718     $file = <blurch*>;
2719
2720 because the latter will alternate between returning a filename and
2721 returning false.
2722
2723 If you're trying to do variable interpolation, it's definitely better
2724 to use the glob() function, because the older notation can cause people
2725 to become confused with the indirect filehandle notation.
2726
2727     @files = glob("$dir/*.[ch]");
2728     @files = glob($files[$i]);
2729
2730 =head2 Constant Folding
2731 X<constant folding> X<folding>
2732
2733 Like C, Perl does a certain amount of expression evaluation at
2734 compile time whenever it determines that all arguments to an
2735 operator are static and have no side effects.  In particular, string
2736 concatenation happens at compile time between literals that don't do
2737 variable substitution.  Backslash interpolation also happens at
2738 compile time.  You can say
2739
2740     'Now is the time for all' . "\n" .
2741         'good men to come to.'
2742
2743 and this all reduces to one string internally.  Likewise, if
2744 you say
2745
2746     foreach $file (@filenames) {
2747         if (-s $file > 5 + 100 * 2**16) {  }
2748     }
2749
2750 the compiler will precompute the number which that expression
2751 represents so that the interpreter won't have to.
2752
2753 =head2 No-ops
2754 X<no-op> X<nop>
2755
2756 Perl doesn't officially have a no-op operator, but the bare constants
2757 C<0> and C<1> are special-cased to not produce a warning in a void
2758 context, so you can for example safely do
2759
2760     1 while foo();
2761
2762 =head2 Bitwise String Operators
2763 X<operator, bitwise, string>
2764
2765 Bitstrings of any size may be manipulated by the bitwise operators
2766 (C<~ | & ^>).
2767
2768 If the operands to a binary bitwise op are strings of different
2769 sizes, B<|> and B<^> ops act as though the shorter operand had
2770 additional zero bits on the right, while the B<&> op acts as though
2771 the longer operand were truncated to the length of the shorter.
2772 The granularity for such extension or truncation is one or more
2773 bytes.
2774
2775     # ASCII-based examples
2776     print "j p \n" ^ " a h";            # prints "JAPH\n"
2777     print "JA" | "  ph\n";              # prints "japh\n"
2778     print "japh\nJunk" & '_____';       # prints "JAPH\n";
2779     print 'p N$' ^ " E<H\n";            # prints "Perl\n";
2780
2781 If you are intending to manipulate bitstrings, be certain that
2782 you're supplying bitstrings: If an operand is a number, that will imply
2783 a B<numeric> bitwise operation.  You may explicitly show which type of
2784 operation you intend by using C<""> or C<0+>, as in the examples below.
2785
2786     $foo =  150  |  105;        # yields 255  (0x96 | 0x69 is 0xFF)
2787     $foo = '150' |  105;        # yields 255
2788     $foo =  150  | '105';       # yields 255
2789     $foo = '150' | '105';       # yields string '155' (under ASCII)
2790
2791     $baz = 0+$foo & 0+$bar;     # both ops explicitly numeric
2792     $biz = "$foo" ^ "$bar";     # both ops explicitly stringy
2793
2794 See L<perlfunc/vec> for information on how to manipulate individual bits
2795 in a bit vector.
2796
2797 =head2 Integer Arithmetic
2798 X<integer>
2799
2800 By default, Perl assumes that it must do most of its arithmetic in
2801 floating point.  But by saying
2802
2803     use integer;
2804
2805 you may tell the compiler to use integer operations
2806 (see L<integer> for a detailed explanation) from here to the end of
2807 the enclosing BLOCK.  An inner BLOCK may countermand this by saying
2808
2809     no integer;
2810
2811 which lasts until the end of that BLOCK.  Note that this doesn't
2812 mean everything is an integer, merely that Perl will use integer
2813 operations for arithmetic, comparison, and bitwise operators.  For
2814 example, even under C<use integer>, if you take the C<sqrt(2)>, you'll
2815 still get C<1.4142135623731> or so.
2816
2817 Used on numbers, the bitwise operators ("&", "|", "^", "~", "<<",
2818 and ">>") always produce integral results.  (But see also
2819 L<Bitwise String Operators>.)  However, C<use integer> still has meaning for
2820 them.  By default, their results are interpreted as unsigned integers, but
2821 if C<use integer> is in effect, their results are interpreted
2822 as signed integers.  For example, C<~0> usually evaluates to a large
2823 integral value.  However, C<use integer; ~0> is C<-1> on two's-complement
2824 machines.
2825
2826 =head2 Floating-point Arithmetic
2827
2828 X<floating-point> X<floating point> X<float> X<real>
2829
2830 While C<use integer> provides integer-only arithmetic, there is no
2831 analogous mechanism to provide automatic rounding or truncation to a
2832 certain number of decimal places.  For rounding to a certain number
2833 of digits, sprintf() or printf() is usually the easiest route.
2834 See L<perlfaq4>.
2835
2836 Floating-point numbers are only approximations to what a mathematician
2837 would call real numbers.  There are infinitely more reals than floats,
2838 so some corners must be cut.  For example:
2839
2840     printf "%.20g\n", 123456789123456789;
2841     #        produces 123456789123456784
2842
2843 Testing for exact floating-point equality or inequality is not a
2844 good idea.  Here's a (relatively expensive) work-around to compare
2845 whether two floating-point numbers are equal to a particular number of
2846 decimal places.  See Knuth, volume II, for a more robust treatment of
2847 this topic.
2848
2849     sub fp_equal {
2850         my ($X, $Y, $POINTS) = @_;
2851         my ($tX, $tY);
2852         $tX = sprintf("%.${POINTS}g", $X);
2853         $tY = sprintf("%.${POINTS}g", $Y);
2854         return $tX eq $tY;
2855     }
2856
2857 The POSIX module (part of the standard perl distribution) implements
2858 ceil(), floor(), and other mathematical and trigonometric functions.
2859 The Math::Complex module (part of the standard perl distribution)
2860 defines mathematical functions that work on both the reals and the
2861 imaginary numbers.  Math::Complex not as efficient as POSIX, but
2862 POSIX can't work with complex numbers.
2863
2864 Rounding in financial applications can have serious implications, and
2865 the rounding method used should be specified precisely.  In these
2866 cases, it probably pays not to trust whichever system rounding is
2867 being used by Perl, but to instead implement the rounding function you
2868 need yourself.
2869
2870 =head2 Bigger Numbers
2871 X<number, arbitrary precision>
2872
2873 The standard C<Math::BigInt>, C<Math::BigRat>, and C<Math::BigFloat> modules,
2874 along with the C<bigint>, C<bigrat>, and C<bitfloat> pragmas, provide
2875 variable-precision arithmetic and overloaded operators, although
2876 they're currently pretty slow. At the cost of some space and
2877 considerable speed, they avoid the normal pitfalls associated with
2878 limited-precision representations.
2879
2880         use 5.010;
2881         use bigint;  # easy interface to Math::BigInt
2882         $x = 123456789123456789;
2883         say $x * $x;
2884     +15241578780673678515622620750190521
2885
2886 Or with rationals:
2887
2888         use 5.010;
2889         use bigrat;
2890         $a = 3/22;
2891         $b = 4/6;
2892         say "a/b is ", $a/$b;
2893         say "a*b is ", $a*$b;
2894     a/b is 9/44
2895     a*b is 1/11
2896
2897 Several modules let you calculate with (bound only by memory and CPU time)
2898 unlimited or fixed precision. There are also some non-standard modules that
2899 provide faster implementations via external C libraries.
2900
2901 Here is a short, but incomplete summary:
2902
2903   Math::Fraction         big, unlimited fractions like 9973 / 12967
2904   Math::String           treat string sequences like numbers
2905   Math::FixedPrecision   calculate with a fixed precision
2906   Math::Currency         for currency calculations
2907   Bit::Vector            manipulate bit vectors fast (uses C)
2908   Math::BigIntFast       Bit::Vector wrapper for big numbers
2909   Math::Pari             provides access to the Pari C library
2910   Math::BigInteger       uses an external C library
2911   Math::Cephes           uses external Cephes C library (no big numbers)
2912   Math::Cephes::Fraction fractions via the Cephes library
2913   Math::GMP              another one using an external C library
2914
2915 Choose wisely.
2916
2917 =cut