This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Support for pp_boolkeys in B::Deparse.
[perl5.git] / dist / B-Deparse / Deparse.pm
1 # B::Deparse.pm
2 # Copyright (c) 1998-2000, 2002, 2003, 2004, 2005, 2006 Stephen McCamant.
3 # All rights reserved.
4 # This module is free software; you can redistribute and/or modify
5 # it under the same terms as Perl itself.
6
7 # This is based on the module of the same name by Malcolm Beattie,
8 # but essentially none of his code remains.
9
10 package B::Deparse;
11 use Carp;
12 use B qw(class main_root main_start main_cv svref_2object opnumber perlstring
13          OPf_WANT OPf_WANT_VOID OPf_WANT_SCALAR OPf_WANT_LIST
14          OPf_KIDS OPf_REF OPf_STACKED OPf_SPECIAL OPf_MOD OPpPAD_STATE
15          OPpLVAL_INTRO OPpOUR_INTRO OPpENTERSUB_AMPER OPpSLICE OPpCONST_BARE
16          OPpTRANS_SQUASH OPpTRANS_DELETE OPpTRANS_COMPLEMENT OPpTARGET_MY
17          OPpCONST_ARYBASE OPpEXISTS_SUB OPpSORT_NUMERIC OPpSORT_INTEGER
18          OPpSORT_REVERSE OPpSORT_INPLACE OPpSORT_DESCEND OPpITER_REVERSED
19          SVf_IOK SVf_NOK SVf_ROK SVf_POK SVpad_OUR SVf_FAKE SVs_RMG SVs_SMG
20          CVf_METHOD CVf_LVALUE
21          PMf_KEEP PMf_GLOBAL PMf_CONTINUE PMf_EVAL PMf_ONCE
22          PMf_MULTILINE PMf_SINGLELINE PMf_FOLD PMf_EXTENDED),
23          ($] < 5.009 ? 'PMf_SKIPWHITE' : 'RXf_SKIPWHITE'),
24          ($] < 5.011 ? 'CVf_LOCKED' : ());
25 $VERSION = 0.92;
26 use strict;
27 use vars qw/$AUTOLOAD/;
28 use warnings ();
29
30 BEGIN {
31     # Easiest way to keep this code portable between 5.12.x and 5.10.x looks to
32     # be to fake up a dummy CVf_LOCKED that will never actually be true.
33     *CVf_LOCKED = sub () {0} unless defined &CVf_LOCKED;
34 }
35
36 # Changes between 0.50 and 0.51:
37 # - fixed nulled leave with live enter in sort { }
38 # - fixed reference constants (\"str")
39 # - handle empty programs gracefully
40 # - handle infinte loops (for (;;) {}, while (1) {})
41 # - differentiate between `for my $x ...' and `my $x; for $x ...'
42 # - various minor cleanups
43 # - moved globals into an object
44 # - added `-u', like B::C
45 # - package declarations using cop_stash
46 # - subs, formats and code sorted by cop_seq
47 # Changes between 0.51 and 0.52:
48 # - added pp_threadsv (special variables under USE_5005THREADS)
49 # - added documentation
50 # Changes between 0.52 and 0.53:
51 # - many changes adding precedence contexts and associativity
52 # - added `-p' and `-s' output style options
53 # - various other minor fixes
54 # Changes between 0.53 and 0.54:
55 # - added support for new `for (1..100)' optimization,
56 #   thanks to Gisle Aas
57 # Changes between 0.54 and 0.55:
58 # - added support for new qr// construct
59 # - added support for new pp_regcreset OP
60 # Changes between 0.55 and 0.56:
61 # - tested on base/*.t, cmd/*.t, comp/*.t, io/*.t
62 # - fixed $# on non-lexicals broken in last big rewrite
63 # - added temporary fix for change in opcode of OP_STRINGIFY
64 # - fixed problem in 0.54's for() patch in `for (@ary)'
65 # - fixed precedence in conditional of ?:
66 # - tweaked list paren elimination in `my($x) = @_'
67 # - made continue-block detection trickier wrt. null ops
68 # - fixed various prototype problems in pp_entersub
69 # - added support for sub prototypes that never get GVs
70 # - added unquoting for special filehandle first arg in truncate
71 # - print doubled rv2gv (a bug) as `*{*GV}' instead of illegal `**GV'
72 # - added semicolons at the ends of blocks
73 # - added -l `#line' declaration option -- fixes cmd/subval.t 27,28
74 # Changes between 0.56 and 0.561:
75 # - fixed multiply-declared my var in pp_truncate (thanks to Sarathy)
76 # - used new B.pm symbolic constants (done by Nick Ing-Simmons)
77 # Changes between 0.561 and 0.57:
78 # - stylistic changes to symbolic constant stuff
79 # - handled scope in s///e replacement code
80 # - added unquote option for expanding "" into concats, etc.
81 # - split method and proto parts of pp_entersub into separate functions
82 # - various minor cleanups
83 # Changes after 0.57:
84 # - added parens in \&foo (patch by Albert Dvornik)
85 # Changes between 0.57 and 0.58:
86 # - fixed `0' statements that weren't being printed
87 # - added methods for use from other programs
88 #   (based on patches from James Duncan and Hugo van der Sanden)
89 # - added -si and -sT to control indenting (also based on a patch from Hugo)
90 # - added -sv to print something else instead of '???'
91 # - preliminary version of utf8 tr/// handling
92 # Changes after 0.58:
93 # - uses of $op->ppaddr changed to new $op->name (done by Sarathy)
94 # - added support for Hugo's new OP_SETSTATE (like nextstate)
95 # Changes between 0.58 and 0.59
96 # - added support for Chip's OP_METHOD_NAMED
97 # - added support for Ilya's OPpTARGET_MY optimization
98 # - elided arrows before `()' subscripts when possible
99 # Changes between 0.59 and 0.60
100 # - support for method attribues was added
101 # - some warnings fixed
102 # - separate recognition of constant subs
103 # - rewrote continue block handling, now recoginizing for loops
104 # - added more control of expanding control structures
105 # Changes between 0.60 and 0.61 (mostly by Robin Houston)
106 # - many bug-fixes
107 # - support for pragmas and 'use'
108 # - support for the little-used $[ variable
109 # - support for __DATA__ sections
110 # - UTF8 support
111 # - BEGIN, CHECK, INIT and END blocks
112 # - scoping of subroutine declarations fixed
113 # - compile-time output from the input program can be suppressed, so that the
114 #   output is just the deparsed code. (a change to O.pm in fact)
115 # - our() declarations
116 # - *all* the known bugs are now listed in the BUGS section
117 # - comprehensive test mechanism (TEST -deparse)
118 # Changes between 0.62 and 0.63 (mostly by Rafael Garcia-Suarez)
119 # - bug-fixes
120 # - new switch -P
121 # - support for command-line switches (-l, -0, etc.)
122 # Changes between 0.63 and 0.64
123 # - support for //, CHECK blocks, and assertions
124 # - improved handling of foreach loops and lexicals
125 # - option to use Data::Dumper for constants
126 # - more bug fixes
127 # - discovered lots more bugs not yet fixed
128 #
129 # ...
130 #
131 # Changes between 0.72 and 0.73
132 # - support new switch constructs
133
134 # Todo:
135 #  (See also BUGS section at the end of this file)
136 #
137 # - finish tr/// changes
138 # - add option for even more parens (generalize \&foo change)
139 # - left/right context
140 # - copy comments (look at real text with $^P?)
141 # - avoid semis in one-statement blocks
142 # - associativity of &&=, ||=, ?:
143 # - ',' => '=>' (auto-unquote?)
144 # - break long lines ("\r" as discretionary break?)
145 # - configurable syntax highlighting: ANSI color, HTML, TeX, etc.
146 # - more style options: brace style, hex vs. octal, quotes, ...
147 # - print big ints as hex/octal instead of decimal (heuristic?)
148 # - handle `my $x if 0'?
149 # - version using op_next instead of op_first/sibling?
150 # - avoid string copies (pass arrays, one big join?)
151 # - here-docs?
152
153 # Current test.deparse failures
154 # comp/hints 6 - location of BEGIN blocks wrt. block openings
155 # run/switchI 1 - missing -I switches entirely
156 #    perl -Ifoo -e 'print @INC'
157 # op/caller 2 - warning mask propagates backwards before warnings::register
158 #    'use warnings; BEGIN {${^WARNING_BITS} eq "U"x12;} use warnings::register'
159 # op/getpid 2 - can't assign to shared my() declaration (threads only)
160 #    'my $x : shared = 5'
161 # op/override 7 - parens on overriden require change v-string interpretation
162 #    'BEGIN{*CORE::GLOBAL::require=sub {}} require v5.6'
163 #    c.f. 'BEGIN { *f = sub {0} }; f 2'
164 # op/pat 774 - losing Unicode-ness of Latin1-only strings
165 #    'use charnames ":short"; $x="\N{latin:a with acute}"'
166 # op/recurse 12 - missing parens on recursive call makes it look like method
167 #    'sub f { f($x) }'
168 # op/subst 90 - inconsistent handling of utf8 under "use utf8"
169 # op/taint 29 - "use re 'taint'" deparsed in the wrong place wrt. block open
170 # op/tiehandle compile - "use strict" deparsed in the wrong place
171 # uni/tr_ several
172 # ext/B/t/xref 11 - line numbers when we add newlines to one-line subs
173 # ext/Data/Dumper/t/dumper compile
174 # ext/DB_file/several
175 # ext/Encode/several
176 # ext/Ernno/Errno warnings
177 # ext/IO/lib/IO/t/io_sel 23
178 # ext/PerlIO/t/encoding compile
179 # ext/POSIX/t/posix 6
180 # ext/Socket/Socket 8
181 # ext/Storable/t/croak compile
182 # lib/Attribute/Handlers/t/multi compile
183 # lib/bignum/ several
184 # lib/charnames 35
185 # lib/constant 32
186 # lib/English 40
187 # lib/ExtUtils/t/bytes 4
188 # lib/File/DosGlob compile
189 # lib/Filter/Simple/t/data 1
190 # lib/Math/BigInt/t/constant 1
191 # lib/Net/t/config Deparse-warning
192 # lib/overload compile
193 # lib/Switch/ several
194 # lib/Symbol 4
195 # lib/Test/Simple several
196 # lib/Term/Complete
197 # lib/Tie/File/t/29_downcopy 5
198 # lib/vars 22
199
200 # Object fields (were globals):
201 #
202 # avoid_local:
203 # (local($a), local($b)) and local($a, $b) have the same internal
204 # representation but the short form looks better. We notice we can
205 # use a large-scale local when checking the list, but need to prevent
206 # individual locals too. This hash holds the addresses of OPs that
207 # have already had their local-ness accounted for. The same thing
208 # is done with my().
209 #
210 # curcv:
211 # CV for current sub (or main program) being deparsed
212 #
213 # curcvlex:
214 # Cached hash of lexical variables for curcv: keys are names,
215 # each value is an array of pairs, indicating the cop_seq of scopes
216 # in which a var of that name is valid.
217 #
218 # curcop:
219 # COP for statement being deparsed
220 #
221 # curstash:
222 # name of the current package for deparsed code
223 #
224 # subs_todo:
225 # array of [cop_seq, CV, is_format?] for subs and formats we still
226 # want to deparse
227 #
228 # protos_todo:
229 # as above, but [name, prototype] for subs that never got a GV
230 #
231 # subs_done, forms_done:
232 # keys are addresses of GVs for subs and formats we've already
233 # deparsed (or at least put into subs_todo)
234 #
235 # subs_declared
236 # keys are names of subs for which we've printed declarations.
237 # That means we can omit parentheses from the arguments.
238 #
239 # subs_deparsed
240 # Keeps track of fully qualified names of all deparsed subs.
241 #
242 # parens: -p
243 # linenums: -l
244 # unquote: -q
245 # cuddle: ` ' or `\n', depending on -sC
246 # indent_size: -si
247 # use_tabs: -sT
248 # ex_const: -sv
249
250 # A little explanation of how precedence contexts and associativity
251 # work:
252 #
253 # deparse() calls each per-op subroutine with an argument $cx (short
254 # for context, but not the same as the cx* in the perl core), which is
255 # a number describing the op's parents in terms of precedence, whether
256 # they're inside an expression or at statement level, etc.  (see
257 # chart below). When ops with children call deparse on them, they pass
258 # along their precedence. Fractional values are used to implement
259 # associativity (`($x + $y) + $z' => `$x + $y + $y') and related
260 # parentheses hacks. The major disadvantage of this scheme is that
261 # it doesn't know about right sides and left sides, so say if you
262 # assign a listop to a variable, it can't tell it's allowed to leave
263 # the parens off the listop.
264
265 # Precedences:
266 # 26             [TODO] inside interpolation context ("")
267 # 25 left        terms and list operators (leftward)
268 # 24 left        ->
269 # 23 nonassoc    ++ --
270 # 22 right       **
271 # 21 right       ! ~ \ and unary + and -
272 # 20 left        =~ !~
273 # 19 left        * / % x
274 # 18 left        + - .
275 # 17 left        << >>
276 # 16 nonassoc    named unary operators
277 # 15 nonassoc    < > <= >= lt gt le ge
278 # 14 nonassoc    == != <=> eq ne cmp
279 # 13 left        &
280 # 12 left        | ^
281 # 11 left        &&
282 # 10 left        ||
283 #  9 nonassoc    ..  ...
284 #  8 right       ?:
285 #  7 right       = += -= *= etc.
286 #  6 left        , =>
287 #  5 nonassoc    list operators (rightward)
288 #  4 right       not
289 #  3 left        and
290 #  2 left        or xor
291 #  1             statement modifiers
292 #  0.5           statements, but still print scopes as do { ... }
293 #  0             statement level
294
295 # Nonprinting characters with special meaning:
296 # \cS - steal parens (see maybe_parens_unop)
297 # \n - newline and indent
298 # \t - increase indent
299 # \b - decrease indent (`outdent')
300 # \f - flush left (no indent)
301 # \cK - kill following semicolon, if any
302
303 sub null {
304     my $op = shift;
305     return class($op) eq "NULL";
306 }
307
308 sub todo {
309     my $self = shift;
310     my($cv, $is_form) = @_;
311     return unless ($cv->FILE eq $0 || exists $self->{files}{$cv->FILE});
312     my $seq;
313     if ($cv->OUTSIDE_SEQ) {
314         $seq = $cv->OUTSIDE_SEQ;
315     } elsif (!null($cv->START) and is_state($cv->START)) {
316         $seq = $cv->START->cop_seq;
317     } else {
318         $seq = 0;
319     }
320     push @{$self->{'subs_todo'}}, [$seq, $cv, $is_form];
321     unless ($is_form || class($cv->STASH) eq 'SPECIAL') {
322         $self->{'subs_deparsed'}{$cv->STASH->NAME."::".$cv->GV->NAME} = 1;
323     }
324 }
325
326 sub next_todo {
327     my $self = shift;
328     my $ent = shift @{$self->{'subs_todo'}};
329     my $cv = $ent->[1];
330     my $gv = $cv->GV;
331     my $name = $self->gv_name($gv);
332     if ($ent->[2]) {
333         return "format $name =\n"
334             . $self->deparse_format($ent->[1]). "\n";
335     } else {
336         $self->{'subs_declared'}{$name} = 1;
337         if ($name eq "BEGIN") {
338             my $use_dec = $self->begin_is_use($cv);
339             if (defined ($use_dec) and $self->{'expand'} < 5) {
340                 return () if 0 == length($use_dec);
341                 return $use_dec;
342             }
343         }
344         my $l = '';
345         if ($self->{'linenums'}) {
346             my $line = $gv->LINE;
347             my $file = $gv->FILE;
348             $l = "\n\f#line $line \"$file\"\n";
349         }
350         my $p = '';
351         if (class($cv->STASH) ne "SPECIAL") {
352             my $stash = $cv->STASH->NAME;
353             if ($stash ne $self->{'curstash'}) {
354                 $p = "package $stash;\n";
355                 $name = "$self->{'curstash'}::$name" unless $name =~ /::/;
356                 $self->{'curstash'} = $stash;
357             }
358             $name =~ s/^\Q$stash\E::(?!\z|.*::)//;
359         }
360         return "${p}${l}sub $name " . $self->deparse_sub($cv);
361     }
362 }
363
364 # Return a "use" declaration for this BEGIN block, if appropriate
365 sub begin_is_use {
366     my ($self, $cv) = @_;
367     my $root = $cv->ROOT;
368     local @$self{qw'curcv curcvlex'} = ($cv);
369 #require B::Debug;
370 #B::walkoptree($cv->ROOT, "debug");
371     my $lineseq = $root->first;
372     return if $lineseq->name ne "lineseq";
373
374     my $req_op = $lineseq->first->sibling;
375     return if $req_op->name ne "require";
376
377     my $module;
378     if ($req_op->first->private & OPpCONST_BARE) {
379         # Actually it should always be a bareword
380         $module = $self->const_sv($req_op->first)->PV;
381         $module =~ s[/][::]g;
382         $module =~ s/.pm$//;
383     }
384     else {
385         $module = $self->const($self->const_sv($req_op->first), 6);
386     }
387
388     my $version;
389     my $version_op = $req_op->sibling;
390     return if class($version_op) eq "NULL";
391     if ($version_op->name eq "lineseq") {
392         # We have a version parameter; skip nextstate & pushmark
393         my $constop = $version_op->first->next->next;
394
395         return unless $self->const_sv($constop)->PV eq $module;
396         $constop = $constop->sibling;
397         $version = $self->const_sv($constop);
398         if (class($version) eq "IV") {
399             $version = $version->int_value;
400         } elsif (class($version) eq "NV") {
401             $version = $version->NV;
402         } elsif (class($version) ne "PVMG") {
403             # Includes PVIV and PVNV
404             $version = $version->PV;
405         } else {
406             # version specified as a v-string
407             $version = 'v'.join '.', map ord, split //, $version->PV;
408         }
409         $constop = $constop->sibling;
410         return if $constop->name ne "method_named";
411         return if $self->const_sv($constop)->PV ne "VERSION";
412     }
413
414     $lineseq = $version_op->sibling;
415     return if $lineseq->name ne "lineseq";
416     my $entersub = $lineseq->first->sibling;
417     if ($entersub->name eq "stub") {
418         return "use $module $version ();\n" if defined $version;
419         return "use $module ();\n";
420     }
421     return if $entersub->name ne "entersub";
422
423     # See if there are import arguments
424     my $args = '';
425
426     my $svop = $entersub->first->sibling; # Skip over pushmark
427     return unless $self->const_sv($svop)->PV eq $module;
428
429     # Pull out the arguments
430     for ($svop=$svop->sibling; $svop->name ne "method_named";
431                 $svop = $svop->sibling) {
432         $args .= ", " if length($args);
433         $args .= $self->deparse($svop, 6);
434     }
435
436     my $use = 'use';
437     my $method_named = $svop;
438     return if $method_named->name ne "method_named";
439     my $method_name = $self->const_sv($method_named)->PV;
440
441     if ($method_name eq "unimport") {
442         $use = 'no';
443     }
444
445     # Certain pragmas are dealt with using hint bits,
446     # so we ignore them here
447     if ($module eq 'strict' || $module eq 'integer'
448         || $module eq 'bytes' || $module eq 'warnings'
449         || $module eq 'feature') {
450         return "";
451     }
452
453     if (defined $version && length $args) {
454         return "$use $module $version ($args);\n";
455     } elsif (defined $version) {
456         return "$use $module $version;\n";
457     } elsif (length $args) {
458         return "$use $module ($args);\n";
459     } else {
460         return "$use $module;\n";
461     }
462 }
463
464 sub stash_subs {
465     my ($self, $pack) = @_;
466     my (@ret, $stash);
467     if (!defined $pack) {
468         $pack = '';
469         $stash = \%::;
470     }
471     else {
472         $pack =~ s/(::)?$/::/;
473         no strict 'refs';
474         $stash = \%$pack;
475     }
476     my %stash = svref_2object($stash)->ARRAY;
477     while (my ($key, $val) = each %stash) {
478         my $class = class($val);
479         if ($class eq "PV") {
480             # Just a prototype. As an ugly but fairly effective way
481             # to find out if it belongs here is to see if the AUTOLOAD
482             # (if any) for the stash was defined in one of our files.
483             my $A = $stash{"AUTOLOAD"};
484             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
485                 && class($A->CV) eq "CV") {
486                 my $AF = $A->FILE;
487                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
488             }
489             push @{$self->{'protos_todo'}}, [$pack . $key, $val->PV];
490         } elsif ($class eq "IV" && !($val->FLAGS & SVf_ROK)) {
491             # Just a name. As above.
492             # But skip proxy constant subroutines, as some form of perl-space
493             # visible code must have created them, be it a use statement, or
494             # some direct symbol-table manipulation code that we will Deparse
495             my $A = $stash{"AUTOLOAD"};
496             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
497                 && class($A->CV) eq "CV") {
498                 my $AF = $A->FILE;
499                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
500             }
501             push @{$self->{'protos_todo'}}, [$pack . $key, undef];
502         } elsif ($class eq "GV") {
503             if (class(my $cv = $val->CV) ne "SPECIAL") {
504                 next if $self->{'subs_done'}{$$val}++;
505                 next if $$val != ${$cv->GV};   # Ignore imposters
506                 $self->todo($cv, 0);
507             }
508             if (class(my $cv = $val->FORM) ne "SPECIAL") {
509                 next if $self->{'forms_done'}{$$val}++;
510                 next if $$val != ${$cv->GV};   # Ignore imposters
511                 $self->todo($cv, 1);
512             }
513             if (class($val->HV) ne "SPECIAL" && $key =~ /::$/) {
514                 $self->stash_subs($pack . $key)
515                     unless $pack eq '' && $key eq 'main::';
516                     # avoid infinite recursion
517             }
518         }
519     }
520 }
521
522 sub print_protos {
523     my $self = shift;
524     my $ar;
525     my @ret;
526     foreach $ar (@{$self->{'protos_todo'}}) {
527         my $proto = (defined $ar->[1] ? " (". $ar->[1] . ")" : "");
528         push @ret, "sub " . $ar->[0] .  "$proto;\n";
529     }
530     delete $self->{'protos_todo'};
531     return @ret;
532 }
533
534 sub style_opts {
535     my $self = shift;
536     my $opts = shift;
537     my $opt;
538     while (length($opt = substr($opts, 0, 1))) {
539         if ($opt eq "C") {
540             $self->{'cuddle'} = " ";
541             $opts = substr($opts, 1);
542         } elsif ($opt eq "i") {
543             $opts =~ s/^i(\d+)//;
544             $self->{'indent_size'} = $1;
545         } elsif ($opt eq "T") {
546             $self->{'use_tabs'} = 1;
547             $opts = substr($opts, 1);
548         } elsif ($opt eq "v") {
549             $opts =~ s/^v([^.]*)(.|$)//;
550             $self->{'ex_const'} = $1;
551         }
552     }
553 }
554
555 sub new {
556     my $class = shift;
557     my $self = bless {}, $class;
558     $self->{'cuddle'} = "\n";
559     $self->{'curcop'} = undef;
560     $self->{'curstash'} = "main";
561     $self->{'ex_const'} = "'???'";
562     $self->{'expand'} = 0;
563     $self->{'files'} = {};
564     $self->{'indent_size'} = 4;
565     $self->{'linenums'} = 0;
566     $self->{'parens'} = 0;
567     $self->{'subs_todo'} = [];
568     $self->{'unquote'} = 0;
569     $self->{'use_dumper'} = 0;
570     $self->{'use_tabs'} = 0;
571
572     $self->{'ambient_arybase'} = 0;
573     $self->{'ambient_warnings'} = undef; # Assume no lexical warnings
574     $self->{'ambient_hints'} = 0;
575     $self->{'ambient_hinthash'} = undef;
576     $self->init();
577
578     while (my $arg = shift @_) {
579         if ($arg eq "-d") {
580             $self->{'use_dumper'} = 1;
581             require Data::Dumper;
582         } elsif ($arg =~ /^-f(.*)/) {
583             $self->{'files'}{$1} = 1;
584         } elsif ($arg eq "-l") {
585             $self->{'linenums'} = 1;
586         } elsif ($arg eq "-p") {
587             $self->{'parens'} = 1;
588         } elsif ($arg eq "-P") {
589             $self->{'noproto'} = 1;
590         } elsif ($arg eq "-q") {
591             $self->{'unquote'} = 1;
592         } elsif (substr($arg, 0, 2) eq "-s") {
593             $self->style_opts(substr $arg, 2);
594         } elsif ($arg =~ /^-x(\d)$/) {
595             $self->{'expand'} = $1;
596         }
597     }
598     return $self;
599 }
600
601 {
602     # Mask out the bits that L<warnings::register> uses
603     my $WARN_MASK;
604     BEGIN {
605         $WARN_MASK = $warnings::Bits{all} | $warnings::DeadBits{all};
606     }
607     sub WARN_MASK () {
608         return $WARN_MASK;
609     }
610 }
611
612 sub scan_for_constants {
613     my ($self) = @_;
614     my %ret;
615
616     B::walksymtable(\%::, sub {
617         my ($gv) = @_;
618
619         my $cv = $gv->CV;
620         return if !$cv || class($cv) ne 'CV';
621
622         my $const = $cv->const_sv;
623         return if !$const || class($const) eq 'SPECIAL';
624
625         $ret{ 0 + $const->object_2svref } = $gv->NAME;
626     }, sub { 1 });
627
628     return \%ret;
629 }
630
631 # Initialise the contextual information, either from
632 # defaults provided with the ambient_pragmas method,
633 # or from perl's own defaults otherwise.
634 sub init {
635     my $self = shift;
636
637     $self->{'arybase'}  = $self->{'ambient_arybase'};
638     $self->{'warnings'} = defined ($self->{'ambient_warnings'})
639                                 ? $self->{'ambient_warnings'} & WARN_MASK
640                                 : undef;
641     $self->{'hints'}    = $self->{'ambient_hints'};
642     $self->{'hints'} &= 0xFF if $] < 5.009;
643     $self->{'hinthash'} = $self->{'ambient_hinthash'};
644
645     # also a convenient place to clear out subs_declared
646     delete $self->{'subs_declared'};
647 }
648
649 sub compile {
650     my(@args) = @_;
651     return sub {
652         my $self = B::Deparse->new(@args);
653         # First deparse command-line args
654         if (defined $^I) { # deparse -i
655             print q(BEGIN { $^I = ).perlstring($^I).qq(; }\n);
656         }
657         if ($^W) { # deparse -w
658             print qq(BEGIN { \$^W = $^W; }\n);
659         }
660         if ($/ ne "\n" or defined $O::savebackslash) { # deparse -l and -0
661             my $fs = perlstring($/) || 'undef';
662             my $bs = perlstring($O::savebackslash) || 'undef';
663             print qq(BEGIN { \$/ = $fs; \$\\ = $bs; }\n);
664         }
665         my @BEGINs  = B::begin_av->isa("B::AV") ? B::begin_av->ARRAY : ();
666         my @UNITCHECKs = B::unitcheck_av->isa("B::AV")
667             ? B::unitcheck_av->ARRAY
668             : ();
669         my @CHECKs  = B::check_av->isa("B::AV") ? B::check_av->ARRAY : ();
670         my @INITs   = B::init_av->isa("B::AV") ? B::init_av->ARRAY : ();
671         my @ENDs    = B::end_av->isa("B::AV") ? B::end_av->ARRAY : ();
672         for my $block (@BEGINs, @UNITCHECKs, @CHECKs, @INITs, @ENDs) {
673             $self->todo($block, 0);
674         }
675         $self->stash_subs();
676         local($SIG{"__DIE__"}) =
677           sub {
678               if ($self->{'curcop'}) {
679                   my $cop = $self->{'curcop'};
680                   my($line, $file) = ($cop->line, $cop->file);
681                   print STDERR "While deparsing $file near line $line,\n";
682               }
683             };
684         $self->{'curcv'} = main_cv;
685         $self->{'curcvlex'} = undef;
686         print $self->print_protos;
687         @{$self->{'subs_todo'}} =
688           sort {$a->[0] <=> $b->[0]} @{$self->{'subs_todo'}};
689         print $self->indent($self->deparse_root(main_root)), "\n"
690           unless null main_root;
691         my @text;
692         while (scalar(@{$self->{'subs_todo'}})) {
693             push @text, $self->next_todo;
694         }
695         print $self->indent(join("", @text)), "\n" if @text;
696
697         # Print __DATA__ section, if necessary
698         no strict 'refs';
699         my $laststash = defined $self->{'curcop'}
700             ? $self->{'curcop'}->stash->NAME : $self->{'curstash'};
701         if (defined *{$laststash."::DATA"}{IO}) {
702             print "package $laststash;\n"
703                 unless $laststash eq $self->{'curstash'};
704             print "__DATA__\n";
705             print readline(*{$laststash."::DATA"});
706         }
707     }
708 }
709
710 sub coderef2text {
711     my $self = shift;
712     my $sub = shift;
713     croak "Usage: ->coderef2text(CODEREF)" unless UNIVERSAL::isa($sub, "CODE");
714
715     $self->init();
716     return $self->indent($self->deparse_sub(svref_2object($sub)));
717 }
718
719 sub ambient_pragmas {
720     my $self = shift;
721     my ($arybase, $hint_bits, $warning_bits, $hinthash) = (0, 0);
722
723     while (@_ > 1) {
724         my $name = shift();
725         my $val  = shift();
726
727         if ($name eq 'strict') {
728             require strict;
729
730             if ($val eq 'none') {
731                 $hint_bits &= ~strict::bits(qw/refs subs vars/);
732                 next();
733             }
734
735             my @names;
736             if ($val eq "all") {
737                 @names = qw/refs subs vars/;
738             }
739             elsif (ref $val) {
740                 @names = @$val;
741             }
742             else {
743                 @names = split' ', $val;
744             }
745             $hint_bits |= strict::bits(@names);
746         }
747
748         elsif ($name eq '$[') {
749             $arybase = $val;
750         }
751
752         elsif ($name eq 'integer'
753             || $name eq 'bytes'
754             || $name eq 'utf8') {
755             require "$name.pm";
756             if ($val) {
757                 $hint_bits |= ${$::{"${name}::"}{"hint_bits"}};
758             }
759             else {
760                 $hint_bits &= ~${$::{"${name}::"}{"hint_bits"}};
761             }
762         }
763
764         elsif ($name eq 're') {
765             require re;
766             if ($val eq 'none') {
767                 $hint_bits &= ~re::bits(qw/taint eval/);
768                 next();
769             }
770
771             my @names;
772             if ($val eq 'all') {
773                 @names = qw/taint eval/;
774             }
775             elsif (ref $val) {
776                 @names = @$val;
777             }
778             else {
779                 @names = split' ',$val;
780             }
781             $hint_bits |= re::bits(@names);
782         }
783
784         elsif ($name eq 'warnings') {
785             if ($val eq 'none') {
786                 $warning_bits = $warnings::NONE;
787                 next();
788             }
789
790             my @names;
791             if (ref $val) {
792                 @names = @$val;
793             }
794             else {
795                 @names = split/\s+/, $val;
796             }
797
798             $warning_bits = $warnings::NONE if !defined ($warning_bits);
799             $warning_bits |= warnings::bits(@names);
800         }
801
802         elsif ($name eq 'warning_bits') {
803             $warning_bits = $val;
804         }
805
806         elsif ($name eq 'hint_bits') {
807             $hint_bits = $val;
808         }
809
810         elsif ($name eq '%^H') {
811             $hinthash = $val;
812         }
813
814         else {
815             croak "Unknown pragma type: $name";
816         }
817     }
818     if (@_) {
819         croak "The ambient_pragmas method expects an even number of args";
820     }
821
822     $self->{'ambient_arybase'} = $arybase;
823     $self->{'ambient_warnings'} = $warning_bits;
824     $self->{'ambient_hints'} = $hint_bits;
825     $self->{'ambient_hinthash'} = $hinthash;
826 }
827
828 # This method is the inner loop, so try to keep it simple
829 sub deparse {
830     my $self = shift;
831     my($op, $cx) = @_;
832
833     Carp::confess("Null op in deparse") if !defined($op)
834                                         || class($op) eq "NULL";
835     my $meth = "pp_" . $op->name;
836     return $self->$meth($op, $cx);
837 }
838
839 sub indent {
840     my $self = shift;
841     my $txt = shift;
842     my @lines = split(/\n/, $txt);
843     my $leader = "";
844     my $level = 0;
845     my $line;
846     for $line (@lines) {
847         my $cmd = substr($line, 0, 1);
848         if ($cmd eq "\t" or $cmd eq "\b") {
849             $level += ($cmd eq "\t" ? 1 : -1) * $self->{'indent_size'};
850             if ($self->{'use_tabs'}) {
851                 $leader = "\t" x ($level / 8) . " " x ($level % 8);
852             } else {
853                 $leader = " " x $level;
854             }
855             $line = substr($line, 1);
856         }
857         if (substr($line, 0, 1) eq "\f") {
858             $line = substr($line, 1); # no indent
859         } else {
860             $line = $leader . $line;
861         }
862         $line =~ s/\cK;?//g;
863     }
864     return join("\n", @lines);
865 }
866
867 sub deparse_sub {
868     my $self = shift;
869     my $cv = shift;
870     my $proto = "";
871 Carp::confess("NULL in deparse_sub") if !defined($cv) || $cv->isa("B::NULL");
872 Carp::confess("SPECIAL in deparse_sub") if $cv->isa("B::SPECIAL");
873     local $self->{'curcop'} = $self->{'curcop'};
874     if ($cv->FLAGS & SVf_POK) {
875         $proto = "(". $cv->PV . ") ";
876     }
877     if ($cv->CvFLAGS & (CVf_METHOD|CVf_LOCKED|CVf_LVALUE)) {
878         $proto .= ": ";
879         $proto .= "lvalue " if $cv->CvFLAGS & CVf_LVALUE;
880         $proto .= "locked " if $cv->CvFLAGS & CVf_LOCKED;
881         $proto .= "method " if $cv->CvFLAGS & CVf_METHOD;
882     }
883
884     local($self->{'curcv'}) = $cv;
885     local($self->{'curcvlex'});
886     local(@$self{qw'curstash warnings hints hinthash'})
887                 = @$self{qw'curstash warnings hints hinthash'};
888     my $body;
889     if (not null $cv->ROOT) {
890         my $lineseq = $cv->ROOT->first;
891         if ($lineseq->name eq "lineseq") {
892             my @ops;
893             for(my$o=$lineseq->first; $$o; $o=$o->sibling) {
894                 push @ops, $o;
895             }
896             $body = $self->lineseq(undef, @ops).";";
897             my $scope_en = $self->find_scope_en($lineseq);
898             if (defined $scope_en) {
899                 my $subs = join"", $self->seq_subs($scope_en);
900                 $body .= ";\n$subs" if length($subs);
901             }
902         }
903         else {
904             $body = $self->deparse($cv->ROOT->first, 0);
905         }
906     }
907     else {
908         my $sv = $cv->const_sv;
909         if ($$sv) {
910             # uh-oh. inlinable sub... format it differently
911             return $proto . "{ " . $self->const($sv, 0) . " }\n";
912         } else { # XSUB? (or just a declaration)
913             return "$proto;\n";
914         }
915     }
916     return $proto ."{\n\t$body\n\b}" ."\n";
917 }
918
919 sub deparse_format {
920     my $self = shift;
921     my $form = shift;
922     my @text;
923     local($self->{'curcv'}) = $form;
924     local($self->{'curcvlex'});
925     local($self->{'in_format'}) = 1;
926     local(@$self{qw'curstash warnings hints hinthash'})
927                 = @$self{qw'curstash warnings hints hinthash'};
928     my $op = $form->ROOT;
929     my $kid;
930     return "\f." if $op->first->name eq 'stub'
931                 || $op->first->name eq 'nextstate';
932     $op = $op->first->first; # skip leavewrite, lineseq
933     while (not null $op) {
934         $op = $op->sibling; # skip nextstate
935         my @exprs;
936         $kid = $op->first->sibling; # skip pushmark
937         push @text, "\f".$self->const_sv($kid)->PV;
938         $kid = $kid->sibling;
939         for (; not null $kid; $kid = $kid->sibling) {
940             push @exprs, $self->deparse($kid, 0);
941         }
942         push @text, "\f".join(", ", @exprs)."\n" if @exprs;
943         $op = $op->sibling;
944     }
945     return join("", @text) . "\f.";
946 }
947
948 sub is_scope {
949     my $op = shift;
950     return $op->name eq "leave" || $op->name eq "scope"
951       || $op->name eq "lineseq"
952         || ($op->name eq "null" && class($op) eq "UNOP"
953             && (is_scope($op->first) || $op->first->name eq "enter"));
954 }
955
956 sub is_state {
957     my $name = $_[0]->name;
958     return $name eq "nextstate" || $name eq "dbstate" || $name eq "setstate";
959 }
960
961 sub is_miniwhile { # check for one-line loop (`foo() while $y--')
962     my $op = shift;
963     return (!null($op) and null($op->sibling)
964             and $op->name eq "null" and class($op) eq "UNOP"
965             and (($op->first->name =~ /^(and|or)$/
966                   and $op->first->first->sibling->name eq "lineseq")
967                  or ($op->first->name eq "lineseq"
968                      and not null $op->first->first->sibling
969                      and $op->first->first->sibling->name eq "unstack")
970                  ));
971 }
972
973 # Check if the op and its sibling are the initialization and the rest of a
974 # for (..;..;..) { ... } loop
975 sub is_for_loop {
976     my $op = shift;
977     # This OP might be almost anything, though it won't be a
978     # nextstate. (It's the initialization, so in the canonical case it
979     # will be an sassign.) The sibling is a lineseq whose first child
980     # is a nextstate and whose second is a leaveloop.
981     my $lseq = $op->sibling;
982     if (!is_state $op and !null($lseq) and $lseq->name eq "lineseq") {
983         if ($lseq->first && !null($lseq->first) && is_state($lseq->first)
984             && (my $sib = $lseq->first->sibling)) {
985             return (!null($sib) && $sib->name eq "leaveloop");
986         }
987     }
988     return 0;
989 }
990
991 sub is_scalar {
992     my $op = shift;
993     return ($op->name eq "rv2sv" or
994             $op->name eq "padsv" or
995             $op->name eq "gv" or # only in array/hash constructs
996             $op->flags & OPf_KIDS && !null($op->first)
997               && $op->first->name eq "gvsv");
998 }
999
1000 sub maybe_parens {
1001     my $self = shift;
1002     my($text, $cx, $prec) = @_;
1003     if ($prec < $cx              # unary ops nest just fine
1004         or $prec == $cx and $cx != 4 and $cx != 16 and $cx != 21
1005         or $self->{'parens'})
1006     {
1007         $text = "($text)";
1008         # In a unop, let parent reuse our parens; see maybe_parens_unop
1009         $text = "\cS" . $text if $cx == 16;
1010         return $text;
1011     } else {
1012         return $text;
1013     }
1014 }
1015
1016 # same as above, but get around the `if it looks like a function' rule
1017 sub maybe_parens_unop {
1018     my $self = shift;
1019     my($name, $kid, $cx) = @_;
1020     if ($cx > 16 or $self->{'parens'}) {
1021         $kid =  $self->deparse($kid, 1);
1022         if ($name eq "umask" && $kid =~ /^\d+$/) {
1023             $kid = sprintf("%#o", $kid);
1024         }
1025         return "$name($kid)";
1026     } else {
1027         $kid = $self->deparse($kid, 16);
1028         if ($name eq "umask" && $kid =~ /^\d+$/) {
1029             $kid = sprintf("%#o", $kid);
1030         }
1031         if (substr($kid, 0, 1) eq "\cS") {
1032             # use kid's parens
1033             return $name . substr($kid, 1);
1034         } elsif (substr($kid, 0, 1) eq "(") {
1035             # avoid looks-like-a-function trap with extra parens
1036             # (`+' can lead to ambiguities)
1037             return "$name(" . $kid  . ")";
1038         } else {
1039             return "$name $kid";
1040         }
1041     }
1042 }
1043
1044 sub maybe_parens_func {
1045     my $self = shift;
1046     my($func, $text, $cx, $prec) = @_;
1047     if ($prec <= $cx or substr($text, 0, 1) eq "(" or $self->{'parens'}) {
1048         return "$func($text)";
1049     } else {
1050         return "$func $text";
1051     }
1052 }
1053
1054 sub maybe_local {
1055     my $self = shift;
1056     my($op, $cx, $text) = @_;
1057     my $our_intro = ($op->name =~ /^(gv|rv2)[ash]v$/) ? OPpOUR_INTRO : 0;
1058     if ($op->private & (OPpLVAL_INTRO|$our_intro)
1059         and not $self->{'avoid_local'}{$$op}) {
1060         my $our_local = ($op->private & OPpLVAL_INTRO) ? "local" : "our";
1061         if( $our_local eq 'our' ) {
1062             # XXX This assertion fails code with non-ASCII identifiers,
1063             # like ./ext/Encode/t/jperl.t
1064             die "Unexpected our($text)\n" unless $text =~ /^\W(\w+::)*\w+\z/;
1065             $text =~ s/(\w+::)+//;
1066         }
1067         if (want_scalar($op)) {
1068             return "$our_local $text";
1069         } else {
1070             return $self->maybe_parens_func("$our_local", $text, $cx, 16);
1071         }
1072     } else {
1073         return $text;
1074     }
1075 }
1076
1077 sub maybe_targmy {
1078     my $self = shift;
1079     my($op, $cx, $func, @args) = @_;
1080     if ($op->private & OPpTARGET_MY) {
1081         my $var = $self->padname($op->targ);
1082         my $val = $func->($self, $op, 7, @args);
1083         return $self->maybe_parens("$var = $val", $cx, 7);
1084     } else {
1085         return $func->($self, $op, $cx, @args);
1086     }
1087 }
1088
1089 sub padname_sv {
1090     my $self = shift;
1091     my $targ = shift;
1092     return $self->{'curcv'}->PADLIST->ARRAYelt(0)->ARRAYelt($targ);
1093 }
1094
1095 sub maybe_my {
1096     my $self = shift;
1097     my($op, $cx, $text) = @_;
1098     if ($op->private & OPpLVAL_INTRO and not $self->{'avoid_local'}{$$op}) {
1099         my $my = $op->private & OPpPAD_STATE ? "state" : "my";
1100         if (want_scalar($op)) {
1101             return "$my $text";
1102         } else {
1103             return $self->maybe_parens_func($my, $text, $cx, 16);
1104         }
1105     } else {
1106         return $text;
1107     }
1108 }
1109
1110 # The following OPs don't have functions:
1111
1112 # pp_padany -- does not exist after parsing
1113
1114 sub AUTOLOAD {
1115     if ($AUTOLOAD =~ s/^.*::pp_//) {
1116         warn "unexpected OP_".uc $AUTOLOAD;
1117         return "XXX";
1118     } else {
1119         die "Undefined subroutine $AUTOLOAD called";
1120     }
1121 }
1122
1123 sub DESTROY {}  #       Do not AUTOLOAD
1124
1125 # $root should be the op which represents the root of whatever
1126 # we're sequencing here. If it's undefined, then we don't append
1127 # any subroutine declarations to the deparsed ops, otherwise we
1128 # append appropriate declarations.
1129 sub lineseq {
1130     my($self, $root, @ops) = @_;
1131     my($expr, @exprs);
1132
1133     my $out_cop = $self->{'curcop'};
1134     my $out_seq = defined($out_cop) ? $out_cop->cop_seq : undef;
1135     my $limit_seq;
1136     if (defined $root) {
1137         $limit_seq = $out_seq;
1138         my $nseq;
1139         $nseq = $self->find_scope_st($root->sibling) if ${$root->sibling};
1140         $limit_seq = $nseq if !defined($limit_seq)
1141                            or defined($nseq) && $nseq < $limit_seq;
1142     }
1143     $limit_seq = $self->{'limit_seq'}
1144         if defined($self->{'limit_seq'})
1145         && (!defined($limit_seq) || $self->{'limit_seq'} < $limit_seq);
1146     local $self->{'limit_seq'} = $limit_seq;
1147
1148     $self->walk_lineseq($root, \@ops,
1149                        sub { push @exprs, $_[0]} );
1150
1151     my $body = join(";\n", grep {length} @exprs);
1152     my $subs = "";
1153     if (defined $root && defined $limit_seq && !$self->{'in_format'}) {
1154         $subs = join "\n", $self->seq_subs($limit_seq);
1155     }
1156     return join(";\n", grep {length} $body, $subs);
1157 }
1158
1159 sub scopeop {
1160     my($real_block, $self, $op, $cx) = @_;
1161     my $kid;
1162     my @kids;
1163
1164     local(@$self{qw'curstash warnings hints hinthash'})
1165                 = @$self{qw'curstash warnings hints hinthash'} if $real_block;
1166     if ($real_block) {
1167         $kid = $op->first->sibling; # skip enter
1168         if (is_miniwhile($kid)) {
1169             my $top = $kid->first;
1170             my $name = $top->name;
1171             if ($name eq "and") {
1172                 $name = "while";
1173             } elsif ($name eq "or") {
1174                 $name = "until";
1175             } else { # no conditional -> while 1 or until 0
1176                 return $self->deparse($top->first, 1) . " while 1";
1177             }
1178             my $cond = $top->first;
1179             my $body = $cond->sibling->first; # skip lineseq
1180             $cond = $self->deparse($cond, 1);
1181             $body = $self->deparse($body, 1);
1182             return "$body $name $cond";
1183         }
1184     } else {
1185         $kid = $op->first;
1186     }
1187     for (; !null($kid); $kid = $kid->sibling) {
1188         push @kids, $kid;
1189     }
1190     if ($cx > 0) { # inside an expression, (a do {} while for lineseq)
1191         return "do {\n\t" . $self->lineseq($op, @kids) . "\n\b}";
1192     } else {
1193         my $lineseq = $self->lineseq($op, @kids);
1194         return (length ($lineseq) ? "$lineseq;" : "");
1195     }
1196 }
1197
1198 sub pp_scope { scopeop(0, @_); }
1199 sub pp_lineseq { scopeop(0, @_); }
1200 sub pp_leave { scopeop(1, @_); }
1201
1202 # This is a special case of scopeop and lineseq, for the case of the
1203 # main_root. The difference is that we print the output statements as
1204 # soon as we get them, for the sake of impatient users.
1205 sub deparse_root {
1206     my $self = shift;
1207     my($op) = @_;
1208     local(@$self{qw'curstash warnings hints hinthash'})
1209       = @$self{qw'curstash warnings hints hinthash'};
1210     my @kids;
1211     return if null $op->first; # Can happen, e.g., for Bytecode without -k
1212     for (my $kid = $op->first->sibling; !null($kid); $kid = $kid->sibling) {
1213         push @kids, $kid;
1214     }
1215     $self->walk_lineseq($op, \@kids,
1216                         sub { print $self->indent($_[0].';');
1217                               print "\n" unless $_[1] == $#kids;
1218                           });
1219 }
1220
1221 sub walk_lineseq {
1222     my ($self, $op, $kids, $callback) = @_;
1223     my @kids = @$kids;
1224     for (my $i = 0; $i < @kids; $i++) {
1225         my $expr = "";
1226         if (is_state $kids[$i]) {
1227             $expr = $self->deparse($kids[$i++], 0);
1228             if ($i > $#kids) {
1229                 $callback->($expr, $i);
1230                 last;
1231             }
1232         }
1233         if (is_for_loop($kids[$i])) {
1234             $callback->($expr . $self->for_loop($kids[$i], 0), $i++);
1235             next;
1236         }
1237         $expr .= $self->deparse($kids[$i], (@kids != 1)/2);
1238         $expr =~ s/;\n?\z//;
1239         $callback->($expr, $i);
1240     }
1241 }
1242
1243 # The BEGIN {} is used here because otherwise this code isn't executed
1244 # when you run B::Deparse on itself.
1245 my %globalnames;
1246 BEGIN { map($globalnames{$_}++, "SIG", "STDIN", "STDOUT", "STDERR", "INC",
1247             "ENV", "ARGV", "ARGVOUT", "_"); }
1248
1249 sub gv_name {
1250     my $self = shift;
1251     my $gv = shift;
1252 Carp::confess() unless ref($gv) eq "B::GV";
1253     my $stash = $gv->STASH->NAME;
1254     my $name = $gv->SAFENAME;
1255     if ($stash eq 'main' && $name =~ /^::/) {
1256         $stash = '::';
1257     }
1258     elsif (($stash eq 'main' && $globalnames{$name})
1259         or ($stash eq $self->{'curstash'} && !$globalnames{$name}
1260             && ($stash eq 'main' || $name !~ /::/))
1261         or $name =~ /^[^A-Za-z_:]/)
1262     {
1263         $stash = "";
1264     } else {
1265         $stash = $stash . "::";
1266     }
1267     if ($name =~ /^(\^..|{)/) {
1268         $name = "{$name}";       # ${^WARNING_BITS}, etc and ${
1269     }
1270     return $stash . $name;
1271 }
1272
1273 # Return the name to use for a stash variable.
1274 # If a lexical with the same name is in scope, it may need to be
1275 # fully-qualified.
1276 sub stash_variable {
1277     my ($self, $prefix, $name) = @_;
1278
1279     return "$prefix$name" if $name =~ /::/;
1280
1281     unless ($prefix eq '$' || $prefix eq '@' || #'
1282             $prefix eq '%' || $prefix eq '$#') {
1283         return "$prefix$name";
1284     }
1285
1286     my $v = ($prefix eq '$#' ? '@' : $prefix) . $name;
1287     return $prefix .$self->{'curstash'}.'::'. $name if $self->lex_in_scope($v);
1288     return "$prefix$name";
1289 }
1290
1291 sub lex_in_scope {
1292     my ($self, $name) = @_;
1293     $self->populate_curcvlex() if !defined $self->{'curcvlex'};
1294
1295     return 0 if !defined($self->{'curcop'});
1296     my $seq = $self->{'curcop'}->cop_seq;
1297     return 0 if !exists $self->{'curcvlex'}{$name};
1298     for my $a (@{$self->{'curcvlex'}{$name}}) {
1299         my ($st, $en) = @$a;
1300         return 1 if $seq > $st && $seq <= $en;
1301     }
1302     return 0;
1303 }
1304
1305 sub populate_curcvlex {
1306     my $self = shift;
1307     for (my $cv = $self->{'curcv'}; class($cv) eq "CV"; $cv = $cv->OUTSIDE) {
1308         my $padlist = $cv->PADLIST;
1309         # an undef CV still in lexical chain
1310         next if class($padlist) eq "SPECIAL";
1311         my @padlist = $padlist->ARRAY;
1312         my @ns = $padlist[0]->ARRAY;
1313
1314         for (my $i=0; $i<@ns; ++$i) {
1315             next if class($ns[$i]) eq "SPECIAL";
1316             next if $ns[$i]->FLAGS & SVpad_OUR;  # Skip "our" vars
1317             if (class($ns[$i]) eq "PV") {
1318                 # Probably that pesky lexical @_
1319                 next;
1320             }
1321             my $name = $ns[$i]->PVX;
1322             my ($seq_st, $seq_en) =
1323                 ($ns[$i]->FLAGS & SVf_FAKE)
1324                     ? (0, 999999)
1325                     : ($ns[$i]->COP_SEQ_RANGE_LOW, $ns[$i]->COP_SEQ_RANGE_HIGH);
1326
1327             push @{$self->{'curcvlex'}{$name}}, [$seq_st, $seq_en];
1328         }
1329     }
1330 }
1331
1332 sub find_scope_st { ((find_scope(@_))[0]); }
1333 sub find_scope_en { ((find_scope(@_))[1]); }
1334
1335 # Recurses down the tree, looking for pad variable introductions and COPs
1336 sub find_scope {
1337     my ($self, $op, $scope_st, $scope_en) = @_;
1338     carp("Undefined op in find_scope") if !defined $op;
1339     return ($scope_st, $scope_en) unless $op->flags & OPf_KIDS;
1340
1341     my @queue = ($op);
1342     while(my $op = shift @queue ) {
1343         for (my $o=$op->first; $$o; $o=$o->sibling) {
1344             if ($o->name =~ /^pad.v$/ && $o->private & OPpLVAL_INTRO) {
1345                 my $s = int($self->padname_sv($o->targ)->COP_SEQ_RANGE_LOW);
1346                 my $e = $self->padname_sv($o->targ)->COP_SEQ_RANGE_HIGH;
1347                 $scope_st = $s if !defined($scope_st) || $s < $scope_st;
1348                 $scope_en = $e if !defined($scope_en) || $e > $scope_en;
1349                 return ($scope_st, $scope_en);
1350             }
1351             elsif (is_state($o)) {
1352                 my $c = $o->cop_seq;
1353                 $scope_st = $c if !defined($scope_st) || $c < $scope_st;
1354                 $scope_en = $c if !defined($scope_en) || $c > $scope_en;
1355                 return ($scope_st, $scope_en);
1356             }
1357             elsif ($o->flags & OPf_KIDS) {
1358                 unshift (@queue, $o);
1359             }
1360         }
1361     }
1362
1363     return ($scope_st, $scope_en);
1364 }
1365
1366 # Returns a list of subs which should be inserted before the COP
1367 sub cop_subs {
1368     my ($self, $op, $out_seq) = @_;
1369     my $seq = $op->cop_seq;
1370     # If we have nephews, then our sequence number indicates
1371     # the cop_seq of the end of some sort of scope.
1372     if (class($op->sibling) ne "NULL" && $op->sibling->flags & OPf_KIDS
1373         and my $nseq = $self->find_scope_st($op->sibling) ) {
1374         $seq = $nseq;
1375     }
1376     $seq = $out_seq if defined($out_seq) && $out_seq < $seq;
1377     return $self->seq_subs($seq);
1378 }
1379
1380 sub seq_subs {
1381     my ($self, $seq) = @_;
1382     my @text;
1383 #push @text, "# ($seq)\n";
1384
1385     return "" if !defined $seq;
1386     while (scalar(@{$self->{'subs_todo'}})
1387            and $seq > $self->{'subs_todo'}[0][0]) {
1388         push @text, $self->next_todo;
1389     }
1390     return @text;
1391 }
1392
1393 # Notice how subs and formats are inserted between statements here;
1394 # also $[ assignments and pragmas.
1395 sub pp_nextstate {
1396     my $self = shift;
1397     my($op, $cx) = @_;
1398     $self->{'curcop'} = $op;
1399     my @text;
1400     push @text, $self->cop_subs($op);
1401     push @text, $op->label . ": " if $op->label;
1402     my $stash = $op->stashpv;
1403     if ($stash ne $self->{'curstash'}) {
1404         push @text, "package $stash;\n";
1405         $self->{'curstash'} = $stash;
1406     }
1407
1408     if ($self->{'arybase'} != $op->arybase) {
1409         push @text, '$[ = '. $op->arybase .";\n";
1410         $self->{'arybase'} = $op->arybase;
1411     }
1412
1413     my $warnings = $op->warnings;
1414     my $warning_bits;
1415     if ($warnings->isa("B::SPECIAL") && $$warnings == 4) {
1416         $warning_bits = $warnings::Bits{"all"} & WARN_MASK;
1417     }
1418     elsif ($warnings->isa("B::SPECIAL") && $$warnings == 5) {
1419         $warning_bits = $warnings::NONE;
1420     }
1421     elsif ($warnings->isa("B::SPECIAL")) {
1422         $warning_bits = undef;
1423     }
1424     else {
1425         $warning_bits = $warnings->PV & WARN_MASK;
1426     }
1427
1428     if (defined ($warning_bits) and
1429        !defined($self->{warnings}) || $self->{'warnings'} ne $warning_bits) {
1430         push @text, declare_warnings($self->{'warnings'}, $warning_bits);
1431         $self->{'warnings'} = $warning_bits;
1432     }
1433
1434     if ($self->{'hints'} != $op->hints) {
1435         push @text, declare_hints($self->{'hints'}, $op->hints);
1436         $self->{'hints'} = $op->hints;
1437     }
1438
1439     # hack to check that the hint hash hasn't changed
1440     if ($] > 5.009 &&
1441         "@{[sort %{$self->{'hinthash'} || {}}]}"
1442         ne "@{[sort %{$op->hints_hash->HASH || {}}]}") {
1443         push @text, declare_hinthash($self->{'hinthash'}, $op->hints_hash->HASH, $self->{indent_size});
1444         $self->{'hinthash'} = $op->hints_hash->HASH;
1445     }
1446
1447     # This should go after of any branches that add statements, to
1448     # increase the chances that it refers to the same line it did in
1449     # the original program.
1450     if ($self->{'linenums'}) {
1451         push @text, "\f#line " . $op->line .
1452           ' "' . $op->file, qq'"\n';
1453     }
1454
1455     return join("", @text);
1456 }
1457
1458 sub declare_warnings {
1459     my ($from, $to) = @_;
1460     if (($to & WARN_MASK) eq (warnings::bits("all") & WARN_MASK)) {
1461         return "use warnings;\n";
1462     }
1463     elsif (($to & WARN_MASK) eq ("\0"x length($to) & WARN_MASK)) {
1464         return "no warnings;\n";
1465     }
1466     return "BEGIN {\${^WARNING_BITS} = ".perlstring($to)."}\n";
1467 }
1468
1469 sub declare_hints {
1470     my ($from, $to) = @_;
1471     my $use = $to   & ~$from;
1472     my $no  = $from & ~$to;
1473     my $decls = "";
1474     for my $pragma (hint_pragmas($use)) {
1475         $decls .= "use $pragma;\n";
1476     }
1477     for my $pragma (hint_pragmas($no)) {
1478         $decls .= "no $pragma;\n";
1479     }
1480     return $decls;
1481 }
1482
1483 # Internal implementation hints that the core sets automatically, so don't need
1484 # (or want) to be passed back to the user
1485 my %ignored_hints = (
1486     'open<' => 1,
1487     'open>' => 1,
1488     ':'     => 1,
1489 );
1490
1491 sub declare_hinthash {
1492     my ($from, $to, $indent) = @_;
1493     my @decls;
1494     for my $key (keys %$to) {
1495         next if $ignored_hints{$key};
1496         if (!defined $from->{$key} or $from->{$key} ne $to->{$key}) {
1497             push @decls, qq(\$^H{'$key'} = q($to->{$key}););
1498         }
1499     }
1500     for my $key (keys %$from) {
1501         next if $ignored_hints{$key};
1502         if (!exists $to->{$key}) {
1503             push @decls, qq(delete \$^H{'$key'};);
1504         }
1505     }
1506     @decls or return '';
1507     return join("\n" . (" " x $indent), "BEGIN {", @decls) . "\n}\n";
1508 }
1509
1510 sub hint_pragmas {
1511     my ($bits) = @_;
1512     my @pragmas;
1513     push @pragmas, "integer" if $bits & 0x1;
1514     push @pragmas, "strict 'refs'" if $bits & 0x2;
1515     push @pragmas, "bytes" if $bits & 0x8;
1516     return @pragmas;
1517 }
1518
1519 sub pp_dbstate { pp_nextstate(@_) }
1520 sub pp_setstate { pp_nextstate(@_) }
1521
1522 sub pp_unstack { return "" } # see also leaveloop
1523
1524 sub baseop {
1525     my $self = shift;
1526     my($op, $cx, $name) = @_;
1527     return $name;
1528 }
1529
1530 sub pp_stub {
1531     my $self = shift;
1532     my($op, $cx, $name) = @_;
1533     if ($cx >= 1) {
1534         return "()";
1535     }
1536     else {
1537         return "();";
1538     }
1539 }
1540 sub pp_wantarray { baseop(@_, "wantarray") }
1541 sub pp_fork { baseop(@_, "fork") }
1542 sub pp_wait { maybe_targmy(@_, \&baseop, "wait") }
1543 sub pp_getppid { maybe_targmy(@_, \&baseop, "getppid") }
1544 sub pp_time { maybe_targmy(@_, \&baseop, "time") }
1545 sub pp_tms { baseop(@_, "times") }
1546 sub pp_ghostent { baseop(@_, "gethostent") }
1547 sub pp_gnetent { baseop(@_, "getnetent") }
1548 sub pp_gprotoent { baseop(@_, "getprotoent") }
1549 sub pp_gservent { baseop(@_, "getservent") }
1550 sub pp_ehostent { baseop(@_, "endhostent") }
1551 sub pp_enetent { baseop(@_, "endnetent") }
1552 sub pp_eprotoent { baseop(@_, "endprotoent") }
1553 sub pp_eservent { baseop(@_, "endservent") }
1554 sub pp_gpwent { baseop(@_, "getpwent") }
1555 sub pp_spwent { baseop(@_, "setpwent") }
1556 sub pp_epwent { baseop(@_, "endpwent") }
1557 sub pp_ggrent { baseop(@_, "getgrent") }
1558 sub pp_sgrent { baseop(@_, "setgrent") }
1559 sub pp_egrent { baseop(@_, "endgrent") }
1560 sub pp_getlogin { baseop(@_, "getlogin") }
1561
1562 sub POSTFIX () { 1 }
1563
1564 # I couldn't think of a good short name, but this is the category of
1565 # symbolic unary operators with interesting precedence
1566
1567 sub pfixop {
1568     my $self = shift;
1569     my($op, $cx, $name, $prec, $flags) = (@_, 0);
1570     my $kid = $op->first;
1571     $kid = $self->deparse($kid, $prec);
1572     return $self->maybe_parens(($flags & POSTFIX) ? "$kid$name" : "$name$kid",
1573                                $cx, $prec);
1574 }
1575
1576 sub pp_preinc { pfixop(@_, "++", 23) }
1577 sub pp_predec { pfixop(@_, "--", 23) }
1578 sub pp_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1579 sub pp_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1580 sub pp_i_preinc { pfixop(@_, "++", 23) }
1581 sub pp_i_predec { pfixop(@_, "--", 23) }
1582 sub pp_i_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1583 sub pp_i_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1584 sub pp_complement { maybe_targmy(@_, \&pfixop, "~", 21) }
1585
1586 sub pp_negate { maybe_targmy(@_, \&real_negate) }
1587 sub real_negate {
1588     my $self = shift;
1589     my($op, $cx) = @_;
1590     if ($op->first->name =~ /^(i_)?negate$/) {
1591         # avoid --$x
1592         $self->pfixop($op, $cx, "-", 21.5);
1593     } else {
1594         $self->pfixop($op, $cx, "-", 21);       
1595     }
1596 }
1597 sub pp_i_negate { pp_negate(@_) }
1598
1599 sub pp_not {
1600     my $self = shift;
1601     my($op, $cx) = @_;
1602     if ($cx <= 4) {
1603         $self->pfixop($op, $cx, "not ", 4);
1604     } else {
1605         $self->pfixop($op, $cx, "!", 21);       
1606     }
1607 }
1608
1609 sub unop {
1610     my $self = shift;
1611     my($op, $cx, $name) = @_;
1612     my $kid;
1613     if ($op->flags & OPf_KIDS) {
1614         if (not $name) {
1615             # this deals with 'boolkeys' right now
1616             return $self->deparse($kid,$cx);
1617         }
1618         $kid = $op->first;
1619         my $builtinname = $name;
1620         $builtinname =~ /^CORE::/ or $builtinname = "CORE::$name";
1621         if (defined prototype($builtinname)
1622            && prototype($builtinname) =~ /^;?\*/
1623            && $kid->name eq "rv2gv") {
1624             $kid = $kid->first;
1625         }
1626
1627         return $self->maybe_parens_unop($name, $kid, $cx);
1628     } else {
1629         return $name .  ($op->flags & OPf_SPECIAL ? "()" : "");
1630     }
1631 }
1632
1633 sub pp_chop { maybe_targmy(@_, \&unop, "chop") }
1634 sub pp_chomp { maybe_targmy(@_, \&unop, "chomp") }
1635 sub pp_schop { maybe_targmy(@_, \&unop, "chop") }
1636 sub pp_schomp { maybe_targmy(@_, \&unop, "chomp") }
1637 sub pp_defined { unop(@_, "defined") }
1638 sub pp_undef { unop(@_, "undef") }
1639 sub pp_study { unop(@_, "study") }
1640 sub pp_ref { unop(@_, "ref") }
1641 sub pp_pos { maybe_local(@_, unop(@_, "pos")) }
1642
1643 sub pp_sin { maybe_targmy(@_, \&unop, "sin") }
1644 sub pp_cos { maybe_targmy(@_, \&unop, "cos") }
1645 sub pp_rand { maybe_targmy(@_, \&unop, "rand") }
1646 sub pp_srand { unop(@_, "srand") }
1647 sub pp_exp { maybe_targmy(@_, \&unop, "exp") }
1648 sub pp_log { maybe_targmy(@_, \&unop, "log") }
1649 sub pp_sqrt { maybe_targmy(@_, \&unop, "sqrt") }
1650 sub pp_int { maybe_targmy(@_, \&unop, "int") }
1651 sub pp_hex { maybe_targmy(@_, \&unop, "hex") }
1652 sub pp_oct { maybe_targmy(@_, \&unop, "oct") }
1653 sub pp_abs { maybe_targmy(@_, \&unop, "abs") }
1654
1655 sub pp_length { maybe_targmy(@_, \&unop, "length") }
1656 sub pp_ord { maybe_targmy(@_, \&unop, "ord") }
1657 sub pp_chr { maybe_targmy(@_, \&unop, "chr") }
1658
1659 sub pp_each { unop(@_, "each") }
1660 sub pp_values { unop(@_, "values") }
1661 sub pp_keys { unop(@_, "keys") }
1662 sub pp_boolkeys { 
1663     # no name because its an optimisation op that has no keyword
1664     unop(@_,"");
1665 }
1666 sub pp_aeach { unop(@_, "each") }
1667 sub pp_avalues { unop(@_, "values") }
1668 sub pp_akeys { unop(@_, "keys") }
1669 sub pp_pop { unop(@_, "pop") }
1670 sub pp_shift { unop(@_, "shift") }
1671
1672 sub pp_caller { unop(@_, "caller") }
1673 sub pp_reset { unop(@_, "reset") }
1674 sub pp_exit { unop(@_, "exit") }
1675 sub pp_prototype { unop(@_, "prototype") }
1676
1677 sub pp_close { unop(@_, "close") }
1678 sub pp_fileno { unop(@_, "fileno") }
1679 sub pp_umask { unop(@_, "umask") }
1680 sub pp_untie { unop(@_, "untie") }
1681 sub pp_tied { unop(@_, "tied") }
1682 sub pp_dbmclose { unop(@_, "dbmclose") }
1683 sub pp_getc { unop(@_, "getc") }
1684 sub pp_eof { unop(@_, "eof") }
1685 sub pp_tell { unop(@_, "tell") }
1686 sub pp_getsockname { unop(@_, "getsockname") }
1687 sub pp_getpeername { unop(@_, "getpeername") }
1688
1689 sub pp_chdir { maybe_targmy(@_, \&unop, "chdir") }
1690 sub pp_chroot { maybe_targmy(@_, \&unop, "chroot") }
1691 sub pp_readlink { unop(@_, "readlink") }
1692 sub pp_rmdir { maybe_targmy(@_, \&unop, "rmdir") }
1693 sub pp_readdir { unop(@_, "readdir") }
1694 sub pp_telldir { unop(@_, "telldir") }
1695 sub pp_rewinddir { unop(@_, "rewinddir") }
1696 sub pp_closedir { unop(@_, "closedir") }
1697 sub pp_getpgrp { maybe_targmy(@_, \&unop, "getpgrp") }
1698 sub pp_localtime { unop(@_, "localtime") }
1699 sub pp_gmtime { unop(@_, "gmtime") }
1700 sub pp_alarm { unop(@_, "alarm") }
1701 sub pp_sleep { maybe_targmy(@_, \&unop, "sleep") }
1702
1703 sub pp_dofile { unop(@_, "do") }
1704 sub pp_entereval { unop(@_, "eval") }
1705
1706 sub pp_ghbyname { unop(@_, "gethostbyname") }
1707 sub pp_gnbyname { unop(@_, "getnetbyname") }
1708 sub pp_gpbyname { unop(@_, "getprotobyname") }
1709 sub pp_shostent { unop(@_, "sethostent") }
1710 sub pp_snetent { unop(@_, "setnetent") }
1711 sub pp_sprotoent { unop(@_, "setprotoent") }
1712 sub pp_sservent { unop(@_, "setservent") }
1713 sub pp_gpwnam { unop(@_, "getpwnam") }
1714 sub pp_gpwuid { unop(@_, "getpwuid") }
1715 sub pp_ggrnam { unop(@_, "getgrnam") }
1716 sub pp_ggrgid { unop(@_, "getgrgid") }
1717
1718 sub pp_lock { unop(@_, "lock") }
1719
1720 sub pp_continue { unop(@_, "continue"); }
1721 sub pp_break {
1722     my ($self, $op) = @_;
1723     return "" if $op->flags & OPf_SPECIAL;
1724     unop(@_, "break");
1725 }
1726
1727 sub givwhen {
1728     my $self = shift;
1729     my($op, $cx, $givwhen) = @_;
1730
1731     my $enterop = $op->first;
1732     my ($head, $block);
1733     if ($enterop->flags & OPf_SPECIAL) {
1734         $head = "default";
1735         $block = $self->deparse($enterop->first, 0);
1736     }
1737     else {
1738         my $cond = $enterop->first;
1739         my $cond_str = $self->deparse($cond, 1);
1740         $head = "$givwhen ($cond_str)";
1741         $block = $self->deparse($cond->sibling, 0);
1742     }
1743
1744     return "$head {\n".
1745         "\t$block\n".
1746         "\b}\cK";
1747 }
1748
1749 sub pp_leavegiven { givwhen(@_, "given"); }
1750 sub pp_leavewhen  { givwhen(@_, "when"); }
1751
1752 sub pp_exists {
1753     my $self = shift;
1754     my($op, $cx) = @_;
1755     my $arg;
1756     if ($op->private & OPpEXISTS_SUB) {
1757         # Checking for the existence of a subroutine
1758         return $self->maybe_parens_func("exists",
1759                                 $self->pp_rv2cv($op->first, 16), $cx, 16);
1760     }
1761     if ($op->flags & OPf_SPECIAL) {
1762         # Array element, not hash element
1763         return $self->maybe_parens_func("exists",
1764                                 $self->pp_aelem($op->first, 16), $cx, 16);
1765     }
1766     return $self->maybe_parens_func("exists", $self->pp_helem($op->first, 16),
1767                                     $cx, 16);
1768 }
1769
1770 sub pp_delete {
1771     my $self = shift;
1772     my($op, $cx) = @_;
1773     my $arg;
1774     if ($op->private & OPpSLICE) {
1775         if ($op->flags & OPf_SPECIAL) {
1776             # Deleting from an array, not a hash
1777             return $self->maybe_parens_func("delete",
1778                                         $self->pp_aslice($op->first, 16),
1779                                         $cx, 16);
1780         }
1781         return $self->maybe_parens_func("delete",
1782                                         $self->pp_hslice($op->first, 16),
1783                                         $cx, 16);
1784     } else {
1785         if ($op->flags & OPf_SPECIAL) {
1786             # Deleting from an array, not a hash
1787             return $self->maybe_parens_func("delete",
1788                                         $self->pp_aelem($op->first, 16),
1789                                         $cx, 16);
1790         }
1791         return $self->maybe_parens_func("delete",
1792                                         $self->pp_helem($op->first, 16),
1793                                         $cx, 16);
1794     }
1795 }
1796
1797 sub pp_require {
1798     my $self = shift;
1799     my($op, $cx) = @_;
1800     my $opname = $op->flags & OPf_SPECIAL ? 'CORE::require' : 'require';
1801     if (class($op) eq "UNOP" and $op->first->name eq "const"
1802         and $op->first->private & OPpCONST_BARE)
1803     {
1804         my $name = $self->const_sv($op->first)->PV;
1805         $name =~ s[/][::]g;
1806         $name =~ s/\.pm//g;
1807         return "$opname $name";
1808     } else {    
1809         $self->unop($op, $cx, $opname);
1810     }
1811 }
1812
1813 sub pp_scalar {
1814     my $self = shift;
1815     my($op, $cx) = @_;
1816     my $kid = $op->first;
1817     if (not null $kid->sibling) {
1818         # XXX Was a here-doc
1819         return $self->dquote($op);
1820     }
1821     $self->unop(@_, "scalar");
1822 }
1823
1824
1825 sub padval {
1826     my $self = shift;
1827     my $targ = shift;
1828     return $self->{'curcv'}->PADLIST->ARRAYelt(1)->ARRAYelt($targ);
1829 }
1830
1831 sub anon_hash_or_list {
1832     my $self = shift;
1833     my($op, $cx) = @_;
1834
1835     my($pre, $post) = @{{"anonlist" => ["[","]"],
1836                          "anonhash" => ["{","}"]}->{$op->name}};
1837     my($expr, @exprs);
1838     $op = $op->first->sibling; # skip pushmark
1839     for (; !null($op); $op = $op->sibling) {
1840         $expr = $self->deparse($op, 6);
1841         push @exprs, $expr;
1842     }
1843     if ($pre eq "{" and $cx < 1) {
1844         # Disambiguate that it's not a block
1845         $pre = "+{";
1846     }
1847     return $pre . join(", ", @exprs) . $post;
1848 }
1849
1850 sub pp_anonlist {
1851     my $self = shift;
1852     my ($op, $cx) = @_;
1853     if ($op->flags & OPf_SPECIAL) {
1854         return $self->anon_hash_or_list($op, $cx);
1855     }
1856     warn "Unexpected op pp_" . $op->name() . " without OPf_SPECIAL";
1857     return 'XXX';
1858 }
1859
1860 *pp_anonhash = \&pp_anonlist;
1861
1862 sub pp_refgen {
1863     my $self = shift;   
1864     my($op, $cx) = @_;
1865     my $kid = $op->first;
1866     if ($kid->name eq "null") {
1867         $kid = $kid->first;
1868         if (!null($kid->sibling) and
1869                  $kid->sibling->name eq "anoncode") {
1870             return $self->e_anoncode({ code => $self->padval($kid->sibling->targ) });
1871         } elsif ($kid->name eq "pushmark") {
1872             my $sib_name = $kid->sibling->name;
1873             if ($sib_name =~ /^(pad|rv2)[ah]v$/
1874                 and not $kid->sibling->flags & OPf_REF)
1875             {
1876                 # The @a in \(@a) isn't in ref context, but only when the
1877                 # parens are there.
1878                 return "\\(" . $self->pp_list($op->first) . ")";
1879             } elsif ($sib_name eq 'entersub') {
1880                 my $text = $self->deparse($kid->sibling, 1);
1881                 # Always show parens for \(&func()), but only with -p otherwise
1882                 $text = "($text)" if $self->{'parens'}
1883                                  or $kid->sibling->private & OPpENTERSUB_AMPER;
1884                 return "\\$text";
1885             }
1886         }
1887     }
1888     $self->pfixop($op, $cx, "\\", 20);
1889 }
1890
1891 sub e_anoncode {
1892     my ($self, $info) = @_;
1893     my $text = $self->deparse_sub($info->{code});
1894     return "sub " . $text;
1895 }
1896
1897 sub pp_srefgen { pp_refgen(@_) }
1898
1899 sub pp_readline {
1900     my $self = shift;
1901     my($op, $cx) = @_;
1902     my $kid = $op->first;
1903     $kid = $kid->first if $kid->name eq "rv2gv"; # <$fh>
1904     return "<" . $self->deparse($kid, 1) . ">" if is_scalar($kid);
1905     return $self->unop($op, $cx, "readline");
1906 }
1907
1908 sub pp_rcatline {
1909     my $self = shift;
1910     my($op) = @_;
1911     return "<" . $self->gv_name($self->gv_or_padgv($op)) . ">";
1912 }
1913
1914 # Unary operators that can occur as pseudo-listops inside double quotes
1915 sub dq_unop {
1916     my $self = shift;
1917     my($op, $cx, $name, $prec, $flags) = (@_, 0, 0);
1918     my $kid;
1919     if ($op->flags & OPf_KIDS) {
1920        $kid = $op->first;
1921        # If there's more than one kid, the first is an ex-pushmark.
1922        $kid = $kid->sibling if not null $kid->sibling;
1923        return $self->maybe_parens_unop($name, $kid, $cx);
1924     } else {
1925        return $name .  ($op->flags & OPf_SPECIAL ? "()" : "");
1926     }
1927 }
1928
1929 sub pp_ucfirst { dq_unop(@_, "ucfirst") }
1930 sub pp_lcfirst { dq_unop(@_, "lcfirst") }
1931 sub pp_uc { dq_unop(@_, "uc") }
1932 sub pp_lc { dq_unop(@_, "lc") }
1933 sub pp_quotemeta { maybe_targmy(@_, \&dq_unop, "quotemeta") }
1934
1935 sub loopex {
1936     my $self = shift;
1937     my ($op, $cx, $name) = @_;
1938     if (class($op) eq "PVOP") {
1939         return "$name " . $op->pv;
1940     } elsif (class($op) eq "OP") {
1941         return $name;
1942     } elsif (class($op) eq "UNOP") {
1943         # Note -- loop exits are actually exempt from the
1944         # looks-like-a-func rule, but a few extra parens won't hurt
1945         return $self->maybe_parens_unop($name, $op->first, $cx);
1946     }
1947 }
1948
1949 sub pp_last { loopex(@_, "last") }
1950 sub pp_next { loopex(@_, "next") }
1951 sub pp_redo { loopex(@_, "redo") }
1952 sub pp_goto { loopex(@_, "goto") }
1953 sub pp_dump { loopex(@_, "dump") }
1954
1955 sub ftst {
1956     my $self = shift;
1957     my($op, $cx, $name) = @_;
1958     if (class($op) eq "UNOP") {
1959         # Genuine `-X' filetests are exempt from the LLAFR, but not
1960         # l?stat(); for the sake of clarity, give'em all parens
1961         return $self->maybe_parens_unop($name, $op->first, $cx);
1962     } elsif (class($op) =~ /^(SV|PAD)OP$/) {
1963         return $self->maybe_parens_func($name, $self->pp_gv($op, 1), $cx, 16);
1964     } else { # I don't think baseop filetests ever survive ck_ftst, but...
1965         return $name;
1966     }
1967 }
1968
1969 sub pp_lstat    { ftst(@_, "lstat") }
1970 sub pp_stat     { ftst(@_, "stat") }
1971 sub pp_ftrread  { ftst(@_, "-R") }
1972 sub pp_ftrwrite { ftst(@_, "-W") }
1973 sub pp_ftrexec  { ftst(@_, "-X") }
1974 sub pp_fteread  { ftst(@_, "-r") }
1975 sub pp_ftewrite { ftst(@_, "-w") }
1976 sub pp_fteexec  { ftst(@_, "-x") }
1977 sub pp_ftis     { ftst(@_, "-e") }
1978 sub pp_fteowned { ftst(@_, "-O") }
1979 sub pp_ftrowned { ftst(@_, "-o") }
1980 sub pp_ftzero   { ftst(@_, "-z") }
1981 sub pp_ftsize   { ftst(@_, "-s") }
1982 sub pp_ftmtime  { ftst(@_, "-M") }
1983 sub pp_ftatime  { ftst(@_, "-A") }
1984 sub pp_ftctime  { ftst(@_, "-C") }
1985 sub pp_ftsock   { ftst(@_, "-S") }
1986 sub pp_ftchr    { ftst(@_, "-c") }
1987 sub pp_ftblk    { ftst(@_, "-b") }
1988 sub pp_ftfile   { ftst(@_, "-f") }
1989 sub pp_ftdir    { ftst(@_, "-d") }
1990 sub pp_ftpipe   { ftst(@_, "-p") }
1991 sub pp_ftlink   { ftst(@_, "-l") }
1992 sub pp_ftsuid   { ftst(@_, "-u") }
1993 sub pp_ftsgid   { ftst(@_, "-g") }
1994 sub pp_ftsvtx   { ftst(@_, "-k") }
1995 sub pp_fttty    { ftst(@_, "-t") }
1996 sub pp_fttext   { ftst(@_, "-T") }
1997 sub pp_ftbinary { ftst(@_, "-B") }
1998
1999 sub SWAP_CHILDREN () { 1 }
2000 sub ASSIGN () { 2 } # has OP= variant
2001 sub LIST_CONTEXT () { 4 } # Assignment is in list context
2002
2003 my(%left, %right);
2004
2005 sub assoc_class {
2006     my $op = shift;
2007     my $name = $op->name;
2008     if ($name eq "concat" and $op->first->name eq "concat") {
2009         # avoid spurious `=' -- see comment in pp_concat
2010         return "concat";
2011     }
2012     if ($name eq "null" and class($op) eq "UNOP"
2013         and $op->first->name =~ /^(and|x?or)$/
2014         and null $op->first->sibling)
2015     {
2016         # Like all conditional constructs, OP_ANDs and OP_ORs are topped
2017         # with a null that's used as the common end point of the two
2018         # flows of control. For precedence purposes, ignore it.
2019         # (COND_EXPRs have these too, but we don't bother with
2020         # their associativity).
2021         return assoc_class($op->first);
2022     }
2023     return $name . ($op->flags & OPf_STACKED ? "=" : "");
2024 }
2025
2026 # Left associative operators, like `+', for which
2027 # $a + $b + $c is equivalent to ($a + $b) + $c
2028
2029 BEGIN {
2030     %left = ('multiply' => 19, 'i_multiply' => 19,
2031              'divide' => 19, 'i_divide' => 19,
2032              'modulo' => 19, 'i_modulo' => 19,
2033              'repeat' => 19,
2034              'add' => 18, 'i_add' => 18,
2035              'subtract' => 18, 'i_subtract' => 18,
2036              'concat' => 18,
2037              'left_shift' => 17, 'right_shift' => 17,
2038              'bit_and' => 13,
2039              'bit_or' => 12, 'bit_xor' => 12,
2040              'and' => 3,
2041              'or' => 2, 'xor' => 2,
2042             );
2043 }
2044
2045 sub deparse_binop_left {
2046     my $self = shift;
2047     my($op, $left, $prec) = @_;
2048     if ($left{assoc_class($op)} && $left{assoc_class($left)}
2049         and $left{assoc_class($op)} == $left{assoc_class($left)})
2050     {
2051         return $self->deparse($left, $prec - .00001);
2052     } else {
2053         return $self->deparse($left, $prec);    
2054     }
2055 }
2056
2057 # Right associative operators, like `=', for which
2058 # $a = $b = $c is equivalent to $a = ($b = $c)
2059
2060 BEGIN {
2061     %right = ('pow' => 22,
2062               'sassign=' => 7, 'aassign=' => 7,
2063               'multiply=' => 7, 'i_multiply=' => 7,
2064               'divide=' => 7, 'i_divide=' => 7,
2065               'modulo=' => 7, 'i_modulo=' => 7,
2066               'repeat=' => 7,
2067               'add=' => 7, 'i_add=' => 7,
2068               'subtract=' => 7, 'i_subtract=' => 7,
2069               'concat=' => 7,
2070               'left_shift=' => 7, 'right_shift=' => 7,
2071               'bit_and=' => 7,
2072               'bit_or=' => 7, 'bit_xor=' => 7,
2073               'andassign' => 7,
2074               'orassign' => 7,
2075              );
2076 }
2077
2078 sub deparse_binop_right {
2079     my $self = shift;
2080     my($op, $right, $prec) = @_;
2081     if ($right{assoc_class($op)} && $right{assoc_class($right)}
2082         and $right{assoc_class($op)} == $right{assoc_class($right)})
2083     {
2084         return $self->deparse($right, $prec - .00001);
2085     } else {
2086         return $self->deparse($right, $prec);   
2087     }
2088 }
2089
2090 sub binop {
2091     my $self = shift;
2092     my ($op, $cx, $opname, $prec, $flags) = (@_, 0);
2093     my $left = $op->first;
2094     my $right = $op->last;
2095     my $eq = "";
2096     if ($op->flags & OPf_STACKED && $flags & ASSIGN) {
2097         $eq = "=";
2098         $prec = 7;
2099     }
2100     if ($flags & SWAP_CHILDREN) {
2101         ($left, $right) = ($right, $left);
2102     }
2103     $left = $self->deparse_binop_left($op, $left, $prec);
2104     $left = "($left)" if $flags & LIST_CONTEXT
2105                 && $left !~ /^(my|our|local|)[\@\(]/;
2106     $right = $self->deparse_binop_right($op, $right, $prec);
2107     return $self->maybe_parens("$left $opname$eq $right", $cx, $prec);
2108 }
2109
2110 sub pp_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
2111 sub pp_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
2112 sub pp_subtract { maybe_targmy(@_, \&binop, "-",18,  ASSIGN) }
2113 sub pp_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
2114 sub pp_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
2115 sub pp_i_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
2116 sub pp_i_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
2117 sub pp_i_subtract { maybe_targmy(@_, \&binop, "-", 18, ASSIGN) }
2118 sub pp_i_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
2119 sub pp_i_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
2120 sub pp_pow { maybe_targmy(@_, \&binop, "**", 22, ASSIGN) }
2121
2122 sub pp_left_shift { maybe_targmy(@_, \&binop, "<<", 17, ASSIGN) }
2123 sub pp_right_shift { maybe_targmy(@_, \&binop, ">>", 17, ASSIGN) }
2124 sub pp_bit_and { maybe_targmy(@_, \&binop, "&", 13, ASSIGN) }
2125 sub pp_bit_or { maybe_targmy(@_, \&binop, "|", 12, ASSIGN) }
2126 sub pp_bit_xor { maybe_targmy(@_, \&binop, "^", 12, ASSIGN) }
2127
2128 sub pp_eq { binop(@_, "==", 14) }
2129 sub pp_ne { binop(@_, "!=", 14) }
2130 sub pp_lt { binop(@_, "<", 15) }
2131 sub pp_gt { binop(@_, ">", 15) }
2132 sub pp_ge { binop(@_, ">=", 15) }
2133 sub pp_le { binop(@_, "<=", 15) }
2134 sub pp_ncmp { binop(@_, "<=>", 14) }
2135 sub pp_i_eq { binop(@_, "==", 14) }
2136 sub pp_i_ne { binop(@_, "!=", 14) }
2137 sub pp_i_lt { binop(@_, "<", 15) }
2138 sub pp_i_gt { binop(@_, ">", 15) }
2139 sub pp_i_ge { binop(@_, ">=", 15) }
2140 sub pp_i_le { binop(@_, "<=", 15) }
2141 sub pp_i_ncmp { binop(@_, "<=>", 14) }
2142
2143 sub pp_seq { binop(@_, "eq", 14) }
2144 sub pp_sne { binop(@_, "ne", 14) }
2145 sub pp_slt { binop(@_, "lt", 15) }
2146 sub pp_sgt { binop(@_, "gt", 15) }
2147 sub pp_sge { binop(@_, "ge", 15) }
2148 sub pp_sle { binop(@_, "le", 15) }
2149 sub pp_scmp { binop(@_, "cmp", 14) }
2150
2151 sub pp_sassign { binop(@_, "=", 7, SWAP_CHILDREN) }
2152 sub pp_aassign { binop(@_, "=", 7, SWAP_CHILDREN | LIST_CONTEXT) }
2153
2154 sub pp_smartmatch {
2155     my ($self, $op, $cx) = @_;
2156     if ($op->flags & OPf_SPECIAL) {
2157         return $self->deparse($op->last, $cx);
2158     }
2159     else {
2160         binop(@_, "~~", 14);
2161     }
2162 }
2163
2164 # `.' is special because concats-of-concats are optimized to save copying
2165 # by making all but the first concat stacked. The effect is as if the
2166 # programmer had written `($a . $b) .= $c', except legal.
2167 sub pp_concat { maybe_targmy(@_, \&real_concat) }
2168 sub real_concat {
2169     my $self = shift;
2170     my($op, $cx) = @_;
2171     my $left = $op->first;
2172     my $right = $op->last;
2173     my $eq = "";
2174     my $prec = 18;
2175     if ($op->flags & OPf_STACKED and $op->first->name ne "concat") {
2176         $eq = "=";
2177         $prec = 7;
2178     }
2179     $left = $self->deparse_binop_left($op, $left, $prec);
2180     $right = $self->deparse_binop_right($op, $right, $prec);
2181     return $self->maybe_parens("$left .$eq $right", $cx, $prec);
2182 }
2183
2184 # `x' is weird when the left arg is a list
2185 sub pp_repeat {
2186     my $self = shift;
2187     my($op, $cx) = @_;
2188     my $left = $op->first;
2189     my $right = $op->last;
2190     my $eq = "";
2191     my $prec = 19;
2192     if ($op->flags & OPf_STACKED) {
2193         $eq = "=";
2194         $prec = 7;
2195     }
2196     if (null($right)) { # list repeat; count is inside left-side ex-list
2197         my $kid = $left->first->sibling; # skip pushmark
2198         my @exprs;
2199         for (; !null($kid->sibling); $kid = $kid->sibling) {
2200             push @exprs, $self->deparse($kid, 6);
2201         }
2202         $right = $kid;
2203         $left = "(" . join(", ", @exprs). ")";
2204     } else {
2205         $left = $self->deparse_binop_left($op, $left, $prec);
2206     }
2207     $right = $self->deparse_binop_right($op, $right, $prec);
2208     return $self->maybe_parens("$left x$eq $right", $cx, $prec);
2209 }
2210
2211 sub range {
2212     my $self = shift;
2213     my ($op, $cx, $type) = @_;
2214     my $left = $op->first;
2215     my $right = $left->sibling;
2216     $left = $self->deparse($left, 9);
2217     $right = $self->deparse($right, 9);
2218     return $self->maybe_parens("$left $type $right", $cx, 9);
2219 }
2220
2221 sub pp_flop {
2222     my $self = shift;
2223     my($op, $cx) = @_;
2224     my $flip = $op->first;
2225     my $type = ($flip->flags & OPf_SPECIAL) ? "..." : "..";
2226     return $self->range($flip->first, $cx, $type);
2227 }
2228
2229 # one-line while/until is handled in pp_leave
2230
2231 sub logop {
2232     my $self = shift;
2233     my ($op, $cx, $lowop, $lowprec, $highop, $highprec, $blockname) = @_;
2234     my $left = $op->first;
2235     my $right = $op->first->sibling;
2236     if ($cx < 1 and is_scope($right) and $blockname
2237         and $self->{'expand'} < 7)
2238     { # if ($a) {$b}
2239         $left = $self->deparse($left, 1);
2240         $right = $self->deparse($right, 0);
2241         return "$blockname ($left) {\n\t$right\n\b}\cK";
2242     } elsif ($cx < 1 and $blockname and not $self->{'parens'}
2243              and $self->{'expand'} < 7) { # $b if $a
2244         $right = $self->deparse($right, 1);
2245         $left = $self->deparse($left, 1);
2246         return "$right $blockname $left";
2247     } elsif ($cx > $lowprec and $highop) { # $a && $b
2248         $left = $self->deparse_binop_left($op, $left, $highprec);
2249         $right = $self->deparse_binop_right($op, $right, $highprec);
2250         return $self->maybe_parens("$left $highop $right", $cx, $highprec);
2251     } else { # $a and $b
2252         $left = $self->deparse_binop_left($op, $left, $lowprec);
2253         $right = $self->deparse_binop_right($op, $right, $lowprec);
2254         return $self->maybe_parens("$left $lowop $right", $cx, $lowprec);
2255     }
2256 }
2257
2258 sub pp_and { logop(@_, "and", 3, "&&", 11, "if") }
2259 sub pp_or  { logop(@_, "or",  2, "||", 10, "unless") }
2260 sub pp_dor { logop(@_, "//", 10) }
2261
2262 # xor is syntactically a logop, but it's really a binop (contrary to
2263 # old versions of opcode.pl). Syntax is what matters here.
2264 sub pp_xor { logop(@_, "xor", 2, "",   0,  "") }
2265
2266 sub logassignop {
2267     my $self = shift;
2268     my ($op, $cx, $opname) = @_;
2269     my $left = $op->first;
2270     my $right = $op->first->sibling->first; # skip sassign
2271     $left = $self->deparse($left, 7);
2272     $right = $self->deparse($right, 7);
2273     return $self->maybe_parens("$left $opname $right", $cx, 7);
2274 }
2275
2276 sub pp_andassign { logassignop(@_, "&&=") }
2277 sub pp_orassign  { logassignop(@_, "||=") }
2278 sub pp_dorassign { logassignop(@_, "//=") }
2279
2280 sub listop {
2281     my $self = shift;
2282     my($op, $cx, $name) = @_;
2283     my(@exprs);
2284     my $parens = ($cx >= 5) || $self->{'parens'};
2285     my $kid = $op->first->sibling;
2286     return $name if null $kid;
2287     my $first;
2288     $name = "socketpair" if $name eq "sockpair";
2289     my $proto = prototype("CORE::$name");
2290     if (defined $proto
2291         && $proto =~ /^;?\*/
2292         && $kid->name eq "rv2gv") {
2293         $first = $self->deparse($kid->first, 6);
2294     }
2295     else {
2296         $first = $self->deparse($kid, 6);
2297     }
2298     if ($name eq "chmod" && $first =~ /^\d+$/) {
2299         $first = sprintf("%#o", $first);
2300     }
2301     $first = "+$first" if not $parens and substr($first, 0, 1) eq "(";
2302     push @exprs, $first;
2303     $kid = $kid->sibling;
2304     if (defined $proto && $proto =~ /^\*\*/ && $kid->name eq "rv2gv") {
2305         push @exprs, $self->deparse($kid->first, 6);
2306         $kid = $kid->sibling;
2307     }
2308     for (; !null($kid); $kid = $kid->sibling) {
2309         push @exprs, $self->deparse($kid, 6);
2310     }
2311     if ($parens) {
2312         return "$name(" . join(", ", @exprs) . ")";
2313     } else {
2314         return "$name " . join(", ", @exprs);
2315     }
2316 }
2317
2318 sub pp_bless { listop(@_, "bless") }
2319 sub pp_atan2 { maybe_targmy(@_, \&listop, "atan2") }
2320 sub pp_substr { maybe_local(@_, listop(@_, "substr")) }
2321 sub pp_vec { maybe_local(@_, listop(@_, "vec")) }
2322 sub pp_index { maybe_targmy(@_, \&listop, "index") }
2323 sub pp_rindex { maybe_targmy(@_, \&listop, "rindex") }
2324 sub pp_sprintf { maybe_targmy(@_, \&listop, "sprintf") }
2325 sub pp_formline { listop(@_, "formline") } # see also deparse_format
2326 sub pp_crypt { maybe_targmy(@_, \&listop, "crypt") }
2327 sub pp_unpack { listop(@_, "unpack") }
2328 sub pp_pack { listop(@_, "pack") }
2329 sub pp_join { maybe_targmy(@_, \&listop, "join") }
2330 sub pp_splice { listop(@_, "splice") }
2331 sub pp_push { maybe_targmy(@_, \&listop, "push") }
2332 sub pp_unshift { maybe_targmy(@_, \&listop, "unshift") }
2333 sub pp_reverse { listop(@_, "reverse") }
2334 sub pp_warn { listop(@_, "warn") }
2335 sub pp_die { listop(@_, "die") }
2336 # Actually, return is exempt from the LLAFR (see examples in this very
2337 # module!), but for consistency's sake, ignore that fact
2338 sub pp_return { listop(@_, "return") }
2339 sub pp_open { listop(@_, "open") }
2340 sub pp_pipe_op { listop(@_, "pipe") }
2341 sub pp_tie { listop(@_, "tie") }
2342 sub pp_binmode { listop(@_, "binmode") }
2343 sub pp_dbmopen { listop(@_, "dbmopen") }
2344 sub pp_sselect { listop(@_, "select") }
2345 sub pp_select { listop(@_, "select") }
2346 sub pp_read { listop(@_, "read") }
2347 sub pp_sysopen { listop(@_, "sysopen") }
2348 sub pp_sysseek { listop(@_, "sysseek") }
2349 sub pp_sysread { listop(@_, "sysread") }
2350 sub pp_syswrite { listop(@_, "syswrite") }
2351 sub pp_send { listop(@_, "send") }
2352 sub pp_recv { listop(@_, "recv") }
2353 sub pp_seek { listop(@_, "seek") }
2354 sub pp_fcntl { listop(@_, "fcntl") }
2355 sub pp_ioctl { listop(@_, "ioctl") }
2356 sub pp_flock { maybe_targmy(@_, \&listop, "flock") }
2357 sub pp_socket { listop(@_, "socket") }
2358 sub pp_sockpair { listop(@_, "sockpair") }
2359 sub pp_bind { listop(@_, "bind") }
2360 sub pp_connect { listop(@_, "connect") }
2361 sub pp_listen { listop(@_, "listen") }
2362 sub pp_accept { listop(@_, "accept") }
2363 sub pp_shutdown { listop(@_, "shutdown") }
2364 sub pp_gsockopt { listop(@_, "getsockopt") }
2365 sub pp_ssockopt { listop(@_, "setsockopt") }
2366 sub pp_chown { maybe_targmy(@_, \&listop, "chown") }
2367 sub pp_unlink { maybe_targmy(@_, \&listop, "unlink") }
2368 sub pp_chmod { maybe_targmy(@_, \&listop, "chmod") }
2369 sub pp_utime { maybe_targmy(@_, \&listop, "utime") }
2370 sub pp_rename { maybe_targmy(@_, \&listop, "rename") }
2371 sub pp_link { maybe_targmy(@_, \&listop, "link") }
2372 sub pp_symlink { maybe_targmy(@_, \&listop, "symlink") }
2373 sub pp_mkdir { maybe_targmy(@_, \&listop, "mkdir") }
2374 sub pp_open_dir { listop(@_, "opendir") }
2375 sub pp_seekdir { listop(@_, "seekdir") }
2376 sub pp_waitpid { maybe_targmy(@_, \&listop, "waitpid") }
2377 sub pp_system { maybe_targmy(@_, \&listop, "system") }
2378 sub pp_exec { maybe_targmy(@_, \&listop, "exec") }
2379 sub pp_kill { maybe_targmy(@_, \&listop, "kill") }
2380 sub pp_setpgrp { maybe_targmy(@_, \&listop, "setpgrp") }
2381 sub pp_getpriority { maybe_targmy(@_, \&listop, "getpriority") }
2382 sub pp_setpriority { maybe_targmy(@_, \&listop, "setpriority") }
2383 sub pp_shmget { listop(@_, "shmget") }
2384 sub pp_shmctl { listop(@_, "shmctl") }
2385 sub pp_shmread { listop(@_, "shmread") }
2386 sub pp_shmwrite { listop(@_, "shmwrite") }
2387 sub pp_msgget { listop(@_, "msgget") }
2388 sub pp_msgctl { listop(@_, "msgctl") }
2389 sub pp_msgsnd { listop(@_, "msgsnd") }
2390 sub pp_msgrcv { listop(@_, "msgrcv") }
2391 sub pp_semget { listop(@_, "semget") }
2392 sub pp_semctl { listop(@_, "semctl") }
2393 sub pp_semop { listop(@_, "semop") }
2394 sub pp_ghbyaddr { listop(@_, "gethostbyaddr") }
2395 sub pp_gnbyaddr { listop(@_, "getnetbyaddr") }
2396 sub pp_gpbynumber { listop(@_, "getprotobynumber") }
2397 sub pp_gsbyname { listop(@_, "getservbyname") }
2398 sub pp_gsbyport { listop(@_, "getservbyport") }
2399 sub pp_syscall { listop(@_, "syscall") }
2400
2401 sub pp_glob {
2402     my $self = shift;
2403     my($op, $cx) = @_;
2404     my $text = $self->dq($op->first->sibling);  # skip pushmark
2405     if ($text =~ /^\$?(\w|::|\`)+$/ # could look like a readline
2406         or $text =~ /[<>]/) {
2407         return 'glob(' . single_delim('qq', '"', $text) . ')';
2408     } else {
2409         return '<' . $text . '>';
2410     }
2411 }
2412
2413 # Truncate is special because OPf_SPECIAL makes a bareword first arg
2414 # be a filehandle. This could probably be better fixed in the core
2415 # by moving the GV lookup into ck_truc.
2416
2417 sub pp_truncate {
2418     my $self = shift;
2419     my($op, $cx) = @_;
2420     my(@exprs);
2421     my $parens = ($cx >= 5) || $self->{'parens'};
2422     my $kid = $op->first->sibling;
2423     my $fh;
2424     if ($op->flags & OPf_SPECIAL) {
2425         # $kid is an OP_CONST
2426         $fh = $self->const_sv($kid)->PV;
2427     } else {
2428         $fh = $self->deparse($kid, 6);
2429         $fh = "+$fh" if not $parens and substr($fh, 0, 1) eq "(";
2430     }
2431     my $len = $self->deparse($kid->sibling, 6);
2432     if ($parens) {
2433         return "truncate($fh, $len)";
2434     } else {
2435         return "truncate $fh, $len";
2436     }
2437 }
2438
2439 sub indirop {
2440     my $self = shift;
2441     my($op, $cx, $name) = @_;
2442     my($expr, @exprs);
2443     my $kid = $op->first->sibling;
2444     my $indir = "";
2445     if ($op->flags & OPf_STACKED) {
2446         $indir = $kid;
2447         $indir = $indir->first; # skip rv2gv
2448         if (is_scope($indir)) {
2449             $indir = "{" . $self->deparse($indir, 0) . "}";
2450             $indir = "{;}" if $indir eq "{}";
2451         } elsif ($indir->name eq "const" && $indir->private & OPpCONST_BARE) {
2452             $indir = $self->const_sv($indir)->PV;
2453         } else {
2454             $indir = $self->deparse($indir, 24);
2455         }
2456         $indir = $indir . " ";
2457         $kid = $kid->sibling;
2458     }
2459     if ($name eq "sort" && $op->private & (OPpSORT_NUMERIC | OPpSORT_INTEGER)) {
2460         $indir = ($op->private & OPpSORT_DESCEND) ? '{$b <=> $a} '
2461                                                   : '{$a <=> $b} ';
2462     }
2463     elsif ($name eq "sort" && $op->private & OPpSORT_DESCEND) {
2464         $indir = '{$b cmp $a} ';
2465     }
2466     for (; !null($kid); $kid = $kid->sibling) {
2467         $expr = $self->deparse($kid, 6);
2468         push @exprs, $expr;
2469     }
2470     my $name2 = $name;
2471     if ($name eq "sort" && $op->private & OPpSORT_REVERSE) {
2472         $name2 = 'reverse sort';
2473     }
2474     if ($name eq "sort" && ($op->private & OPpSORT_INPLACE)) {
2475         return "$exprs[0] = $name2 $indir $exprs[0]";
2476     }
2477
2478     my $args = $indir . join(", ", @exprs);
2479     if ($indir ne "" and $name eq "sort") {
2480         # We don't want to say "sort(f 1, 2, 3)", since perl -w will
2481         # give bareword warnings in that case. Therefore if context
2482         # requires, we'll put parens around the outside "(sort f 1, 2,
2483         # 3)". Unfortunately, we'll currently think the parens are
2484         # necessary more often that they really are, because we don't
2485         # distinguish which side of an assignment we're on.
2486         if ($cx >= 5) {
2487             return "($name2 $args)";
2488         } else {
2489             return "$name2 $args";
2490         }
2491     } else {
2492         return $self->maybe_parens_func($name2, $args, $cx, 5);
2493     }
2494
2495 }
2496
2497 sub pp_prtf { indirop(@_, "printf") }
2498 sub pp_print { indirop(@_, "print") }
2499 sub pp_say  { indirop(@_, "say") }
2500 sub pp_sort { indirop(@_, "sort") }
2501
2502 sub mapop {
2503     my $self = shift;
2504     my($op, $cx, $name) = @_;
2505     my($expr, @exprs);
2506     my $kid = $op->first; # this is the (map|grep)start
2507     $kid = $kid->first->sibling; # skip a pushmark
2508     my $code = $kid->first; # skip a null
2509     if (is_scope $code) {
2510         $code = "{" . $self->deparse($code, 0) . "} ";
2511     } else {
2512         $code = $self->deparse($code, 24) . ", ";
2513     }
2514     $kid = $kid->sibling;
2515     for (; !null($kid); $kid = $kid->sibling) {
2516         $expr = $self->deparse($kid, 6);
2517         push @exprs, $expr if defined $expr;
2518     }
2519     return $self->maybe_parens_func($name, $code . join(", ", @exprs), $cx, 5);
2520 }
2521
2522 sub pp_mapwhile { mapop(@_, "map") }
2523 sub pp_grepwhile { mapop(@_, "grep") }
2524 sub pp_mapstart { baseop(@_, "map") }
2525 sub pp_grepstart { baseop(@_, "grep") }
2526
2527 sub pp_list {
2528     my $self = shift;
2529     my($op, $cx) = @_;
2530     my($expr, @exprs);
2531     my $kid = $op->first->sibling; # skip pushmark
2532     my $lop;
2533     my $local = "either"; # could be local(...), my(...), state(...) or our(...)
2534     for ($lop = $kid; !null($lop); $lop = $lop->sibling) {
2535         # This assumes that no other private flags equal 128, and that
2536         # OPs that store things other than flags in their op_private,
2537         # like OP_AELEMFAST, won't be immediate children of a list.
2538         #
2539         # OP_ENTERSUB can break this logic, so check for it.
2540         # I suspect that open and exit can too.
2541
2542         if (!($lop->private & (OPpLVAL_INTRO|OPpOUR_INTRO)
2543                 or $lop->name eq "undef")
2544             or $lop->name eq "entersub"
2545             or $lop->name eq "exit"
2546             or $lop->name eq "open")
2547         {
2548             $local = ""; # or not
2549             last;
2550         }
2551         if ($lop->name =~ /^pad[ash]v$/) {
2552             if ($lop->private & OPpPAD_STATE) { # state()
2553                 ($local = "", last) if $local =~ /^(?:local|our|my)$/;
2554                 $local = "state";
2555             } else { # my()
2556                 ($local = "", last) if $local =~ /^(?:local|our|state)$/;
2557                 $local = "my";
2558             }
2559         } elsif ($lop->name =~ /^(gv|rv2)[ash]v$/
2560                         && $lop->private & OPpOUR_INTRO
2561                 or $lop->name eq "null" && $lop->first->name eq "gvsv"
2562                         && $lop->first->private & OPpOUR_INTRO) { # our()
2563             ($local = "", last) if $local =~ /^(?:my|local|state)$/;
2564             $local = "our";
2565         } elsif ($lop->name ne "undef"
2566                 # specifically avoid the "reverse sort" optimisation,
2567                 # where "reverse" is nullified
2568                 && !($lop->name eq 'sort' && ($lop->flags & OPpSORT_REVERSE)))
2569         {
2570             # local()
2571             ($local = "", last) if $local =~ /^(?:my|our|state)$/;
2572             $local = "local";
2573         }
2574     }
2575     $local = "" if $local eq "either"; # no point if it's all undefs
2576     return $self->deparse($kid, $cx) if null $kid->sibling and not $local;
2577     for (; !null($kid); $kid = $kid->sibling) {
2578         if ($local) {
2579             if (class($kid) eq "UNOP" and $kid->first->name eq "gvsv") {
2580                 $lop = $kid->first;
2581             } else {
2582                 $lop = $kid;
2583             }
2584             $self->{'avoid_local'}{$$lop}++;
2585             $expr = $self->deparse($kid, 6);
2586             delete $self->{'avoid_local'}{$$lop};
2587         } else {
2588             $expr = $self->deparse($kid, 6);
2589         }
2590         push @exprs, $expr;
2591     }
2592     if ($local) {
2593         return "$local(" . join(", ", @exprs) . ")";
2594     } else {
2595         return $self->maybe_parens( join(", ", @exprs), $cx, 6);        
2596     }
2597 }
2598
2599 sub is_ifelse_cont {
2600     my $op = shift;
2601     return ($op->name eq "null" and class($op) eq "UNOP"
2602             and $op->first->name =~ /^(and|cond_expr)$/
2603             and is_scope($op->first->first->sibling));
2604 }
2605
2606 sub pp_cond_expr {
2607     my $self = shift;
2608     my($op, $cx) = @_;
2609     my $cond = $op->first;
2610     my $true = $cond->sibling;
2611     my $false = $true->sibling;
2612     my $cuddle = $self->{'cuddle'};
2613     unless ($cx < 1 and (is_scope($true) and $true->name ne "null") and
2614             (is_scope($false) || is_ifelse_cont($false))
2615             and $self->{'expand'} < 7) {
2616         $cond = $self->deparse($cond, 8);
2617         $true = $self->deparse($true, 6);
2618         $false = $self->deparse($false, 8);
2619         return $self->maybe_parens("$cond ? $true : $false", $cx, 8);
2620     }
2621
2622     $cond = $self->deparse($cond, 1);
2623     $true = $self->deparse($true, 0);
2624     my $head = "if ($cond) {\n\t$true\n\b}";
2625     my @elsifs;
2626     while (!null($false) and is_ifelse_cont($false)) {
2627         my $newop = $false->first;
2628         my $newcond = $newop->first;
2629         my $newtrue = $newcond->sibling;
2630         $false = $newtrue->sibling; # last in chain is OP_AND => no else
2631         if ($newcond->name eq "lineseq")
2632         {
2633             # lineseq to ensure correct line numbers in elsif()
2634             # Bug #37302 fixed by change #33710.
2635             $newcond = $newcond->first->sibling;
2636         }
2637         $newcond = $self->deparse($newcond, 1);
2638         $newtrue = $self->deparse($newtrue, 0);
2639         push @elsifs, "elsif ($newcond) {\n\t$newtrue\n\b}";
2640     }
2641     if (!null($false)) {
2642         $false = $cuddle . "else {\n\t" .
2643           $self->deparse($false, 0) . "\n\b}\cK";
2644     } else {
2645         $false = "\cK";
2646     }
2647     return $head . join($cuddle, "", @elsifs) . $false;
2648 }
2649
2650 sub pp_once {
2651     my ($self, $op, $cx) = @_;
2652     my $cond = $op->first;
2653     my $true = $cond->sibling;
2654
2655     return $self->deparse($true, $cx);
2656 }
2657
2658 sub loop_common {
2659     my $self = shift;
2660     my($op, $cx, $init) = @_;
2661     my $enter = $op->first;
2662     my $kid = $enter->sibling;
2663     local(@$self{qw'curstash warnings hints hinthash'})
2664                 = @$self{qw'curstash warnings hints hinthash'};
2665     my $head = "";
2666     my $bare = 0;
2667     my $body;
2668     my $cond = undef;
2669     if ($kid->name eq "lineseq") { # bare or infinite loop
2670         if ($kid->last->name eq "unstack") { # infinite
2671             $head = "while (1) "; # Can't use for(;;) if there's a continue
2672             $cond = "";
2673         } else {
2674             $bare = 1;
2675         }
2676         $body = $kid;
2677     } elsif ($enter->name eq "enteriter") { # foreach
2678         my $ary = $enter->first->sibling; # first was pushmark
2679         my $var = $ary->sibling;
2680         if ($ary->name eq 'null' and $enter->private & OPpITER_REVERSED) {
2681             # "reverse" was optimised away
2682             $ary = listop($self, $ary->first->sibling, 1, 'reverse');
2683         } elsif ($enter->flags & OPf_STACKED
2684             and not null $ary->first->sibling->sibling)
2685         {
2686             $ary = $self->deparse($ary->first->sibling, 9) . " .. " .
2687               $self->deparse($ary->first->sibling->sibling, 9);
2688         } else {
2689             $ary = $self->deparse($ary, 1);
2690         }
2691         if (null $var) {
2692             if ($enter->flags & OPf_SPECIAL) { # thread special var
2693                 $var = $self->pp_threadsv($enter, 1);
2694             } else { # regular my() variable
2695                 $var = $self->pp_padsv($enter, 1);
2696             }
2697         } elsif ($var->name eq "rv2gv") {
2698             $var = $self->pp_rv2sv($var, 1);
2699             if ($enter->private & OPpOUR_INTRO) {
2700                 # our declarations don't have package names
2701                 $var =~ s/^(.).*::/$1/;
2702                 $var = "our $var";
2703             }
2704         } elsif ($var->name eq "gv") {
2705             $var = "\$" . $self->deparse($var, 1);
2706         }
2707         $body = $kid->first->first->sibling; # skip OP_AND and OP_ITER
2708         if (!is_state $body->first and $body->first->name ne "stub") {
2709             confess unless $var eq '$_';
2710             $body = $body->first;
2711             return $self->deparse($body, 2) . " foreach ($ary)";
2712         }
2713         $head = "foreach $var ($ary) ";
2714     } elsif ($kid->name eq "null") { # while/until
2715         $kid = $kid->first;
2716         my $name = {"and" => "while", "or" => "until"}->{$kid->name};
2717         $cond = $self->deparse($kid->first, 1);
2718         $head = "$name ($cond) ";
2719         $body = $kid->first->sibling;
2720     } elsif ($kid->name eq "stub") { # bare and empty
2721         return "{;}"; # {} could be a hashref
2722     }
2723     # If there isn't a continue block, then the next pointer for the loop
2724     # will point to the unstack, which is kid's last child, except
2725     # in a bare loop, when it will point to the leaveloop. When neither of
2726     # these conditions hold, then the second-to-last child is the continue
2727     # block (or the last in a bare loop).
2728     my $cont_start = $enter->nextop;
2729     my $cont;
2730     if ($$cont_start != $$op && ${$cont_start} != ${$body->last}) {
2731         if ($bare) {
2732             $cont = $body->last;
2733         } else {
2734             $cont = $body->first;
2735             while (!null($cont->sibling->sibling)) {
2736                 $cont = $cont->sibling;
2737             }
2738         }
2739         my $state = $body->first;
2740         my $cuddle = $self->{'cuddle'};
2741         my @states;
2742         for (; $$state != $$cont; $state = $state->sibling) {
2743             push @states, $state;
2744         }
2745         $body = $self->lineseq(undef, @states);
2746         if (defined $cond and not is_scope $cont and $self->{'expand'} < 3) {
2747             $head = "for ($init; $cond; " . $self->deparse($cont, 1) .") ";
2748             $cont = "\cK";
2749         } else {
2750             $cont = $cuddle . "continue {\n\t" .
2751               $self->deparse($cont, 0) . "\n\b}\cK";
2752         }
2753     } else {
2754         return "" if !defined $body;
2755         if (length $init) {
2756             $head = "for ($init; $cond;) ";
2757         }
2758         $cont = "\cK";
2759         $body = $self->deparse($body, 0);
2760     }
2761     $body =~ s/;?$/;\n/;
2762
2763     return $head . "{\n\t" . $body . "\b}" . $cont;
2764 }
2765
2766 sub pp_leaveloop { shift->loop_common(@_, "") }
2767
2768 sub for_loop {
2769     my $self = shift;
2770     my($op, $cx) = @_;
2771     my $init = $self->deparse($op, 1);
2772     return $self->loop_common($op->sibling->first->sibling, $cx, $init);
2773 }
2774
2775 sub pp_leavetry {
2776     my $self = shift;
2777     return "eval {\n\t" . $self->pp_leave(@_) . "\n\b}";
2778 }
2779
2780 BEGIN { eval "sub OP_CONST () {" . opnumber("const") . "}" }
2781 BEGIN { eval "sub OP_STRINGIFY () {" . opnumber("stringify") . "}" }
2782 BEGIN { eval "sub OP_RV2SV () {" . opnumber("rv2sv") . "}" }
2783 BEGIN { eval "sub OP_LIST () {" . opnumber("list") . "}" }
2784
2785 sub pp_null {
2786     my $self = shift;
2787     my($op, $cx) = @_;
2788     if (class($op) eq "OP") {
2789         # old value is lost
2790         return $self->{'ex_const'} if $op->targ == OP_CONST;
2791     } elsif ($op->first->name eq "pushmark") {
2792         return $self->pp_list($op, $cx);
2793     } elsif ($op->first->name eq "enter") {
2794         return $self->pp_leave($op, $cx);
2795     } elsif ($op->first->name eq "leave") {
2796         return $self->pp_leave($op->first, $cx);
2797     } elsif ($op->first->name eq "scope") {
2798         return $self->pp_scope($op->first, $cx);
2799     } elsif ($op->targ == OP_STRINGIFY) {
2800         return $self->dquote($op, $cx);
2801     } elsif (!null($op->first->sibling) and
2802              $op->first->sibling->name eq "readline" and
2803              $op->first->sibling->flags & OPf_STACKED) {
2804         return $self->maybe_parens($self->deparse($op->first, 7) . " = "
2805                                    . $self->deparse($op->first->sibling, 7),
2806                                    $cx, 7);
2807     } elsif (!null($op->first->sibling) and
2808              $op->first->sibling->name eq "trans" and
2809              $op->first->sibling->flags & OPf_STACKED) {
2810         return $self->maybe_parens($self->deparse($op->first, 20) . " =~ "
2811                                    . $self->deparse($op->first->sibling, 20),
2812                                    $cx, 20);
2813     } elsif ($op->flags & OPf_SPECIAL && $cx < 1 && !$op->targ) {
2814         return "do {\n\t". $self->deparse($op->first, $cx) ."\n\b};";
2815     } elsif (!null($op->first->sibling) and
2816              $op->first->sibling->name eq "null" and
2817              class($op->first->sibling) eq "UNOP" and
2818              $op->first->sibling->first->flags & OPf_STACKED and
2819              $op->first->sibling->first->name eq "rcatline") {
2820         return $self->maybe_parens($self->deparse($op->first, 18) . " .= "
2821                                    . $self->deparse($op->first->sibling, 18),
2822                                    $cx, 18);
2823     } else {
2824         return $self->deparse($op->first, $cx);
2825     }
2826 }
2827
2828 sub padname {
2829     my $self = shift;
2830     my $targ = shift;
2831     return $self->padname_sv($targ)->PVX;
2832 }
2833
2834 sub padany {
2835     my $self = shift;
2836     my $op = shift;
2837     return substr($self->padname($op->targ), 1); # skip $/@/%
2838 }
2839
2840 sub pp_padsv {
2841     my $self = shift;
2842     my($op, $cx) = @_;
2843     return $self->maybe_my($op, $cx, $self->padname($op->targ));
2844 }
2845
2846 sub pp_padav { pp_padsv(@_) }
2847 sub pp_padhv { pp_padsv(@_) }
2848
2849 my @threadsv_names;
2850
2851 BEGIN {
2852     @threadsv_names = ("_", "1", "2", "3", "4", "5", "6", "7", "8", "9",
2853                        "&", "`", "'", "+", "/", ".", ",", "\\", '"', ";",
2854                        "^", "-", "%", "=", "|", "~", ":", "^A", "^E",
2855                        "!", "@");
2856 }
2857
2858 sub pp_threadsv {
2859     my $self = shift;
2860     my($op, $cx) = @_;
2861     return $self->maybe_local($op, $cx, "\$" .  $threadsv_names[$op->targ]);
2862 }
2863
2864 sub gv_or_padgv {
2865     my $self = shift;
2866     my $op = shift;
2867     if (class($op) eq "PADOP") {
2868         return $self->padval($op->padix);
2869     } else { # class($op) eq "SVOP"
2870         return $op->gv;
2871     }
2872 }
2873
2874 sub pp_gvsv {
2875     my $self = shift;
2876     my($op, $cx) = @_;
2877     my $gv = $self->gv_or_padgv($op);
2878     return $self->maybe_local($op, $cx, $self->stash_variable("\$",
2879                                  $self->gv_name($gv)));
2880 }
2881
2882 sub pp_gv {
2883     my $self = shift;
2884     my($op, $cx) = @_;
2885     my $gv = $self->gv_or_padgv($op);
2886     return $self->gv_name($gv);
2887 }
2888
2889 sub pp_aelemfast {
2890     my $self = shift;
2891     my($op, $cx) = @_;
2892     my $name;
2893     if ($op->flags & OPf_SPECIAL) { # optimised PADAV
2894         $name = $self->padname($op->targ);
2895         $name =~ s/^@/\$/;
2896     }
2897     else {
2898         my $gv = $self->gv_or_padgv($op);
2899         $name = $self->gv_name($gv);
2900         $name = $self->{'curstash'}."::$name"
2901             if $name !~ /::/ && $self->lex_in_scope('@'.$name);
2902         $name = '$' . $name;
2903     }
2904
2905     return $name . "[" .  ($op->private + $self->{'arybase'}) . "]";
2906 }
2907
2908 sub rv2x {
2909     my $self = shift;
2910     my($op, $cx, $type) = @_;
2911
2912     if (class($op) eq 'NULL' || !$op->can("first")) {
2913         carp("Unexpected op in pp_rv2x");
2914         return 'XXX';
2915     }
2916     my $kid = $op->first;
2917     if ($kid->name eq "gv") {
2918         return $self->stash_variable($type, $self->deparse($kid, 0));
2919     } elsif (is_scalar $kid) {
2920         my $str = $self->deparse($kid, 0);
2921         if ($str =~ /^\$([^\w\d])\z/) {
2922             # "$$+" isn't a legal way to write the scalar dereference
2923             # of $+, since the lexer can't tell you aren't trying to
2924             # do something like "$$ + 1" to get one more than your
2925             # PID. Either "${$+}" or "$${+}" are workable
2926             # disambiguations, but if the programmer did the former,
2927             # they'd be in the "else" clause below rather than here.
2928             # It's not clear if this should somehow be unified with
2929             # the code in dq and re_dq that also adds lexer
2930             # disambiguation braces.
2931             $str = '$' . "{$1}"; #'
2932         }
2933         return $type . $str;
2934     } else {
2935         return $type . "{" . $self->deparse($kid, 0) . "}";
2936     }
2937 }
2938
2939 sub pp_rv2sv { maybe_local(@_, rv2x(@_, "\$")) }
2940 sub pp_rv2hv { maybe_local(@_, rv2x(@_, "%")) }
2941 sub pp_rv2gv { maybe_local(@_, rv2x(@_, "*")) }
2942
2943 # skip rv2av
2944 sub pp_av2arylen {
2945     my $self = shift;
2946     my($op, $cx) = @_;
2947     if ($op->first->name eq "padav") {
2948         return $self->maybe_local($op, $cx, '$#' . $self->padany($op->first));
2949     } else {
2950         return $self->maybe_local($op, $cx,
2951                                   $self->rv2x($op->first, $cx, '$#'));
2952     }
2953 }
2954
2955 # skip down to the old, ex-rv2cv
2956 sub pp_rv2cv {
2957     my ($self, $op, $cx) = @_;
2958     if (!null($op->first) && $op->first->name eq 'null' &&
2959         $op->first->targ eq OP_LIST)
2960     {
2961         return $self->rv2x($op->first->first->sibling, $cx, "&")
2962     }
2963     else {
2964         return $self->rv2x($op, $cx, "")
2965     }
2966 }
2967
2968 sub list_const {
2969     my $self = shift;
2970     my($cx, @list) = @_;
2971     my @a = map $self->const($_, 6), @list;
2972     if (@a == 0) {
2973         return "()";
2974     } elsif (@a == 1) {
2975         return $a[0];
2976     } elsif ( @a > 2 and !grep(!/^-?\d+$/, @a)) {
2977         # collapse (-1,0,1,2) into (-1..2)
2978         my ($s, $e) = @a[0,-1];
2979         my $i = $s;
2980         return $self->maybe_parens("$s..$e", $cx, 9)
2981           unless grep $i++ != $_, @a;
2982     }
2983     return $self->maybe_parens(join(", ", @a), $cx, 6);
2984 }
2985
2986 sub pp_rv2av {
2987     my $self = shift;
2988     my($op, $cx) = @_;
2989     my $kid = $op->first;
2990     if ($kid->name eq "const") { # constant list
2991         my $av = $self->const_sv($kid);
2992         return $self->list_const($cx, $av->ARRAY);
2993     } else {
2994         return $self->maybe_local($op, $cx, $self->rv2x($op, $cx, "\@"));
2995     }
2996  }
2997
2998 sub is_subscriptable {
2999     my $op = shift;
3000     if ($op->name =~ /^[ahg]elem/) {
3001         return 1;
3002     } elsif ($op->name eq "entersub") {
3003         my $kid = $op->first;
3004         return 0 unless null $kid->sibling;
3005         $kid = $kid->first;
3006         $kid = $kid->sibling until null $kid->sibling;
3007         return 0 if is_scope($kid);
3008         $kid = $kid->first;
3009         return 0 if $kid->name eq "gv";
3010         return 0 if is_scalar($kid);
3011         return is_subscriptable($kid);  
3012     } else {
3013         return 0;
3014     }
3015 }
3016
3017 sub elem_or_slice_array_name
3018 {
3019     my $self = shift;
3020     my ($array, $left, $padname, $allow_arrow) = @_;
3021
3022     if ($array->name eq $padname) {
3023         return $self->padany($array);
3024     } elsif (is_scope($array)) { # ${expr}[0]
3025         return "{" . $self->deparse($array, 0) . "}";
3026     } elsif ($array->name eq "gv") {
3027         $array = $self->gv_name($self->gv_or_padgv($array));
3028         if ($array !~ /::/) {
3029             my $prefix = ($left eq '[' ? '@' : '%');
3030             $array = $self->{curstash}.'::'.$array
3031                 if $self->lex_in_scope($prefix . $array);
3032         }
3033         return $array;
3034     } elsif (!$allow_arrow || is_scalar $array) { # $x[0], $$x[0], ...
3035         return $self->deparse($array, 24);
3036     } else {
3037         return undef;
3038     }
3039 }
3040
3041 sub elem_or_slice_single_index
3042 {
3043     my $self = shift;
3044     my ($idx) = @_;
3045
3046     $idx = $self->deparse($idx, 1);
3047
3048     # Outer parens in an array index will confuse perl
3049     # if we're interpolating in a regular expression, i.e.
3050     # /$x$foo[(-1)]/ is *not* the same as /$x$foo[-1]/
3051     #
3052     # If $self->{parens}, then an initial '(' will
3053     # definitely be paired with a final ')'. If
3054     # !$self->{parens}, the misleading parens won't
3055     # have been added in the first place.
3056     #
3057     # [You might think that we could get "(...)...(...)"
3058     # where the initial and final parens do not match
3059     # each other. But we can't, because the above would
3060     # only happen if there's an infix binop between the
3061     # two pairs of parens, and *that* means that the whole
3062     # expression would be parenthesized as well.]
3063     #
3064     $idx =~ s/^\((.*)\)$/$1/ if $self->{'parens'};
3065
3066     # Hash-element braces will autoquote a bareword inside themselves.
3067     # We need to make sure that C<$hash{warn()}> doesn't come out as
3068     # C<$hash{warn}>, which has a quite different meaning. Currently
3069     # B::Deparse will always quote strings, even if the string was a
3070     # bareword in the original (i.e. the OPpCONST_BARE flag is ignored
3071     # for constant strings.) So we can cheat slightly here - if we see
3072     # a bareword, we know that it is supposed to be a function call.
3073     #
3074     $idx =~ s/^([A-Za-z_]\w*)$/$1()/;
3075
3076     return $idx;
3077 }
3078
3079 sub elem {
3080     my $self = shift;
3081     my ($op, $cx, $left, $right, $padname) = @_;
3082     my($array, $idx) = ($op->first, $op->first->sibling);
3083
3084     $idx = $self->elem_or_slice_single_index($idx);
3085
3086     unless ($array->name eq $padname) { # Maybe this has been fixed     
3087         $array = $array->first; # skip rv2av (or ex-rv2av in _53+)
3088     }
3089     if (my $array_name=$self->elem_or_slice_array_name
3090             ($array, $left, $padname, 1)) {
3091         return "\$" . $array_name . $left . $idx . $right;
3092     } else {
3093         # $x[20][3]{hi} or expr->[20]
3094         my $arrow = is_subscriptable($array) ? "" : "->";
3095         return $self->deparse($array, 24) . $arrow . $left . $idx . $right;
3096     }
3097
3098 }
3099
3100 sub pp_aelem { maybe_local(@_, elem(@_, "[", "]", "padav")) }
3101 sub pp_helem { maybe_local(@_, elem(@_, "{", "}", "padhv")) }
3102
3103 sub pp_gelem {
3104     my $self = shift;
3105     my($op, $cx) = @_;
3106     my($glob, $part) = ($op->first, $op->last);
3107     $glob = $glob->first; # skip rv2gv
3108     $glob = $glob->first if $glob->name eq "rv2gv"; # this one's a bug
3109     my $scope = is_scope($glob);
3110     $glob = $self->deparse($glob, 0);
3111     $part = $self->deparse($part, 1);
3112     return "*" . ($scope ? "{$glob}" : $glob) . "{$part}";
3113 }
3114
3115 sub slice {
3116     my $self = shift;
3117     my ($op, $cx, $left, $right, $regname, $padname) = @_;
3118     my $last;
3119     my(@elems, $kid, $array, $list);
3120     if (class($op) eq "LISTOP") {
3121         $last = $op->last;
3122     } else { # ex-hslice inside delete()
3123         for ($kid = $op->first; !null $kid->sibling; $kid = $kid->sibling) {}
3124         $last = $kid;
3125     }
3126     $array = $last;
3127     $array = $array->first
3128         if $array->name eq $regname or $array->name eq "null";
3129     $array = $self->elem_or_slice_array_name($array,$left,$padname,0);
3130     $kid = $op->first->sibling; # skip pushmark
3131     if ($kid->name eq "list") {
3132         $kid = $kid->first->sibling; # skip list, pushmark
3133         for (; !null $kid; $kid = $kid->sibling) {
3134             push @elems, $self->deparse($kid, 6);
3135         }
3136         $list = join(", ", @elems);
3137     } else {
3138         $list = $self->elem_or_slice_single_index($kid);
3139     }
3140     return "\@" . $array . $left . $list . $right;
3141 }
3142
3143 sub pp_aslice { maybe_local(@_, slice(@_, "[", "]", "rv2av", "padav")) }
3144 sub pp_hslice { maybe_local(@_, slice(@_, "{", "}", "rv2hv", "padhv")) }
3145
3146 sub pp_lslice {
3147     my $self = shift;
3148     my($op, $cx) = @_;
3149     my $idx = $op->first;
3150     my $list = $op->last;
3151     my(@elems, $kid);
3152     $list = $self->deparse($list, 1);
3153     $idx = $self->deparse($idx, 1);
3154     return "($list)" . "[$idx]";
3155 }
3156
3157 sub want_scalar {
3158     my $op = shift;
3159     return ($op->flags & OPf_WANT) == OPf_WANT_SCALAR;
3160 }
3161
3162 sub want_list {
3163     my $op = shift;
3164     return ($op->flags & OPf_WANT) == OPf_WANT_LIST;
3165 }
3166
3167 sub _method {
3168     my $self = shift;
3169     my($op, $cx) = @_;
3170     my $kid = $op->first->sibling; # skip pushmark
3171     my($meth, $obj, @exprs);
3172     if ($kid->name eq "list" and want_list $kid) {
3173         # When an indirect object isn't a bareword but the args are in
3174         # parens, the parens aren't part of the method syntax (the LLAFR
3175         # doesn't apply), but they make a list with OPf_PARENS set that
3176         # doesn't get flattened by the append_elem that adds the method,
3177         # making a (object, arg1, arg2, ...) list where the object
3178         # usually is. This can be distinguished from
3179         # `($obj, $arg1, $arg2)->meth()' (which is legal if $arg2 is an
3180         # object) because in the later the list is in scalar context
3181         # as the left side of -> always is, while in the former
3182         # the list is in list context as method arguments always are.
3183         # (Good thing there aren't method prototypes!)
3184         $meth = $kid->sibling;
3185         $kid = $kid->first->sibling; # skip pushmark
3186         $obj = $kid;
3187         $kid = $kid->sibling;
3188         for (; not null $kid; $kid = $kid->sibling) {
3189             push @exprs, $kid;
3190         }
3191     } else {
3192         $obj = $kid;
3193         $kid = $kid->sibling;
3194         for (; !null ($kid->sibling) && $kid->name ne "method_named";
3195               $kid = $kid->sibling) {
3196             push @exprs, $kid
3197         }
3198         $meth = $kid;
3199     }
3200
3201     if ($meth->name eq "method_named") {
3202         $meth = $self->const_sv($meth)->PV;
3203     } else {
3204         $meth = $meth->first;
3205         if ($meth->name eq "const") {
3206             # As of 5.005_58, this case is probably obsoleted by the
3207             # method_named case above
3208             $meth = $self->const_sv($meth)->PV; # needs to be bare
3209         }
3210     }
3211
3212     return { method => $meth, variable_method => ref($meth),
3213              object => $obj, args => \@exprs  };
3214 }
3215
3216 # compat function only
3217 sub method {
3218     my $self = shift;
3219     my $info = $self->_method(@_);
3220     return $self->e_method( $self->_method(@_) );
3221 }
3222
3223 sub e_method {
3224     my ($self, $info) = @_;
3225     my $obj = $self->deparse($info->{object}, 24);
3226
3227     my $meth = $info->{method};
3228     $meth = $self->deparse($meth, 1) if $info->{variable_method};
3229     my $args = join(", ", map { $self->deparse($_, 6) } @{$info->{args}} );
3230     my $kid = $obj . "->" . $meth;
3231     if (length $args) {
3232         return $kid . "(" . $args . ")"; # parens mandatory
3233     } else {
3234         return $kid;
3235     }
3236 }
3237
3238 # returns "&" if the prototype doesn't match the args,
3239 # or ("", $args_after_prototype_demunging) if it does.
3240 sub check_proto {
3241     my $self = shift;
3242     return "&" if $self->{'noproto'};
3243     my($proto, @args) = @_;
3244     my($arg, $real);
3245     my $doneok = 0;
3246     my @reals;
3247     # An unbackslashed @ or % gobbles up the rest of the args
3248     1 while $proto =~ s/(?<!\\)([@%])[^\]]+$/$1/;
3249     while ($proto) {
3250         $proto =~ s/^(\\?[\$\@&%*_]|\\\[[\$\@&%*]+\]|;)//;
3251         my $chr = $1;
3252         if ($chr eq "") {
3253             return "&" if @args;
3254         } elsif ($chr eq ";") {
3255             $doneok = 1;
3256         } elsif ($chr eq "@" or $chr eq "%") {
3257             push @reals, map($self->deparse($_, 6), @args);
3258             @args = ();
3259         } else {
3260             $arg = shift @args;
3261             last unless $arg;
3262             if ($chr eq "\$" || $chr eq "_") {
3263                 if (want_scalar $arg) {
3264                     push @reals, $self->deparse($arg, 6);
3265                 } else {
3266                     return "&";
3267                 }
3268             } elsif ($chr eq "&") {
3269                 if ($arg->name =~ /^(s?refgen|undef)$/) {
3270                     push @reals, $self->deparse($arg, 6);
3271                 } else {
3272                     return "&";
3273                 }
3274             } elsif ($chr eq "*") {
3275                 if ($arg->name =~ /^s?refgen$/
3276                     and $arg->first->first->name eq "rv2gv")
3277                   {
3278                       $real = $arg->first->first; # skip refgen, null
3279                       if ($real->first->name eq "gv") {
3280                           push @reals, $self->deparse($real, 6);
3281                       } else {
3282                           push @reals, $self->deparse($real->first, 6);
3283                       }
3284                   } else {
3285                       return "&";
3286                   }
3287             } elsif (substr($chr, 0, 1) eq "\\") {
3288                 $chr =~ tr/\\[]//d;
3289                 if ($arg->name =~ /^s?refgen$/ and
3290                     !null($real = $arg->first) and
3291                     ($chr =~ /\$/ && is_scalar($real->first)
3292                      or ($chr =~ /@/
3293                          && class($real->first->sibling) ne 'NULL'
3294                          && $real->first->sibling->name
3295                          =~ /^(rv2|pad)av$/)
3296                      or ($chr =~ /%/
3297                          && class($real->first->sibling) ne 'NULL'
3298                          && $real->first->sibling->name
3299                          =~ /^(rv2|pad)hv$/)
3300                      #or ($chr =~ /&/ # This doesn't work
3301                      #   && $real->first->name eq "rv2cv")
3302                      or ($chr =~ /\*/
3303                          && $real->first->name eq "rv2gv")))
3304                   {
3305                       push @reals, $self->deparse($real, 6);
3306                   } else {
3307                       return "&";
3308                   }
3309             }
3310        }
3311     }
3312     return "&" if $proto and !$doneok; # too few args and no `;'
3313     return "&" if @args;               # too many args
3314     return ("", join ", ", @reals);
3315 }
3316
3317 sub pp_entersub {
3318     my $self = shift;
3319     my($op, $cx) = @_;
3320     return $self->e_method($self->_method($op, $cx))
3321         unless null $op->first->sibling;
3322     my $prefix = "";
3323     my $amper = "";
3324     my($kid, @exprs);
3325     if ($op->flags & OPf_SPECIAL && !($op->flags & OPf_MOD)) {
3326         $prefix = "do ";
3327     } elsif ($op->private & OPpENTERSUB_AMPER) {
3328         $amper = "&";
3329     }
3330     $kid = $op->first;
3331     $kid = $kid->first->sibling; # skip ex-list, pushmark
3332     for (; not null $kid->sibling; $kid = $kid->sibling) {
3333         push @exprs, $kid;
3334     }
3335     my $simple = 0;
3336     my $proto = undef;
3337     if (is_scope($kid)) {
3338         $amper = "&";
3339         $kid = "{" . $self->deparse($kid, 0) . "}";
3340     } elsif ($kid->first->name eq "gv") {
3341         my $gv = $self->gv_or_padgv($kid->first);
3342         if (class($gv->CV) ne "SPECIAL") {
3343             $proto = $gv->CV->PV if $gv->CV->FLAGS & SVf_POK;
3344         }
3345         $simple = 1; # only calls of named functions can be prototyped
3346         $kid = $self->deparse($kid, 24);
3347         if (!$amper) {
3348             if ($kid eq 'main::') {
3349                 $kid = '::';
3350             } elsif ($kid !~ /^(?:\w|::)(?:[\w\d]|::(?!\z))*\z/) {
3351                 $kid = single_delim("q", "'", $kid) . '->';
3352             }
3353         }
3354     } elsif (is_scalar ($kid->first) && $kid->first->name ne 'rv2cv') {
3355         $amper = "&";
3356         $kid = $self->deparse($kid, 24);
3357     } else {
3358         $prefix = "";
3359         my $arrow = is_subscriptable($kid->first) ? "" : "->";
3360         $kid = $self->deparse($kid, 24) . $arrow;
3361     }
3362
3363     # Doesn't matter how many prototypes there are, if
3364     # they haven't happened yet!
3365     my $declared;
3366     {
3367         no strict 'refs';
3368         no warnings 'uninitialized';
3369         $declared = exists $self->{'subs_declared'}{$kid}
3370             || (
3371                  defined &{ ${$self->{'curstash'}."::"}{$kid} }
3372                  && !exists
3373                      $self->{'subs_deparsed'}{$self->{'curstash'}."::".$kid}
3374                  && defined prototype $self->{'curstash'}."::".$kid
3375                );
3376         if (!$declared && defined($proto)) {
3377             # Avoid "too early to check prototype" warning
3378             ($amper, $proto) = ('&');
3379         }
3380     }
3381
3382     my $args;
3383     if ($declared and defined $proto and not $amper) {
3384         ($amper, $args) = $self->check_proto($proto, @exprs);
3385         if ($amper eq "&") {
3386             $args = join(", ", map($self->deparse($_, 6), @exprs));
3387         }
3388     } else {
3389         $args = join(", ", map($self->deparse($_, 6), @exprs));
3390     }
3391     if ($prefix or $amper) {
3392         if ($op->flags & OPf_STACKED) {
3393             return $prefix . $amper . $kid . "(" . $args . ")";
3394         } else {
3395             return $prefix . $amper. $kid;
3396         }
3397     } else {
3398         # glob() invocations can be translated into calls of
3399         # CORE::GLOBAL::glob with a second parameter, a number.
3400         # Reverse this.
3401         if ($kid eq "CORE::GLOBAL::glob") {
3402             $kid = "glob";
3403             $args =~ s/\s*,[^,]+$//;
3404         }
3405
3406         # It's a syntax error to call CORE::GLOBAL::foo without a prefix,
3407         # so it must have been translated from a keyword call. Translate
3408         # it back.
3409         $kid =~ s/^CORE::GLOBAL:://;
3410
3411         my $dproto = defined($proto) ? $proto : "undefined";
3412         if (!$declared) {
3413             return "$kid(" . $args . ")";
3414         } elsif ($dproto eq "") {
3415             return $kid;
3416         } elsif ($dproto eq "\$" and is_scalar($exprs[0])) {
3417             # is_scalar is an excessively conservative test here:
3418             # really, we should be comparing to the precedence of the
3419             # top operator of $exprs[0] (ala unop()), but that would
3420             # take some major code restructuring to do right.
3421             return $self->maybe_parens_func($kid, $args, $cx, 16);
3422         } elsif ($dproto ne '$' and defined($proto) || $simple) { #'
3423             return $self->maybe_parens_func($kid, $args, $cx, 5);
3424         } else {
3425             return "$kid(" . $args . ")";
3426         }
3427     }
3428 }
3429
3430 sub pp_enterwrite { unop(@_, "write") }
3431
3432 # escape things that cause interpolation in double quotes,
3433 # but not character escapes
3434 sub uninterp {
3435     my($str) = @_;
3436     $str =~ s/(^|\G|[^\\])((?:\\\\)*)([\$\@]|\\[uUlLQE])/$1$2\\$3/g;
3437     return $str;
3438 }
3439
3440 {
3441 my $bal;
3442 BEGIN {
3443     use re "eval";
3444     # Matches any string which is balanced with respect to {braces}
3445     $bal = qr(
3446       (?:
3447         [^\\{}]
3448       | \\\\
3449       | \\[{}]
3450       | \{(??{$bal})\}
3451       )*
3452     )x;
3453 }
3454
3455 # the same, but treat $|, $), $( and $ at the end of the string differently
3456 sub re_uninterp {
3457     my($str) = @_;
3458
3459     $str =~ s/
3460           ( ^|\G                  # $1
3461           | [^\\]
3462           )
3463
3464           (                       # $2
3465             (?:\\\\)*
3466           )
3467
3468           (                       # $3
3469             (\(\?\??\{$bal\}\))   # $4
3470           | [\$\@]
3471             (?!\||\)|\(|$)
3472           | \\[uUlLQE]
3473           )
3474
3475         /defined($4) && length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
3476
3477     return $str;
3478 }
3479
3480 # This is for regular expressions with the /x modifier
3481 # We have to leave comments unmangled.
3482 sub re_uninterp_extended {
3483     my($str) = @_;
3484
3485     $str =~ s/
3486           ( ^|\G                  # $1
3487           | [^\\]
3488           )
3489
3490           (                       # $2
3491             (?:\\\\)*
3492           )
3493
3494           (                       # $3
3495             ( \(\?\??\{$bal\}\)   # $4  (skip over (?{}) and (??{}) blocks)
3496             | \#[^\n]*            #     (skip over comments)
3497             )
3498           | [\$\@]
3499             (?!\||\)|\(|$|\s)
3500           | \\[uUlLQE]
3501           )
3502
3503         /defined($4) && length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
3504
3505     return $str;
3506 }
3507 }
3508
3509 my %unctrl = # portable to to EBCDIC
3510     (
3511      "\c@" => '\c@',    # unused
3512      "\cA" => '\cA',
3513      "\cB" => '\cB',
3514      "\cC" => '\cC',
3515      "\cD" => '\cD',
3516      "\cE" => '\cE',
3517      "\cF" => '\cF',
3518      "\cG" => '\cG',
3519      "\cH" => '\cH',
3520      "\cI" => '\cI',
3521      "\cJ" => '\cJ',
3522      "\cK" => '\cK',
3523      "\cL" => '\cL',
3524      "\cM" => '\cM',
3525      "\cN" => '\cN',
3526      "\cO" => '\cO',
3527      "\cP" => '\cP',
3528      "\cQ" => '\cQ',
3529      "\cR" => '\cR',
3530      "\cS" => '\cS',
3531      "\cT" => '\cT',
3532      "\cU" => '\cU',
3533      "\cV" => '\cV',
3534      "\cW" => '\cW',
3535      "\cX" => '\cX',
3536      "\cY" => '\cY',
3537      "\cZ" => '\cZ',
3538      "\c[" => '\c[',    # unused
3539      "\c\\" => '\c\\',  # unused
3540      "\c]" => '\c]',    # unused
3541      "\c_" => '\c_',    # unused
3542     );
3543
3544 # character escapes, but not delimiters that might need to be escaped
3545 sub escape_str { # ASCII, UTF8
3546     my($str) = @_;
3547     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
3548     $str =~ s/\a/\\a/g;
3549 #    $str =~ s/\cH/\\b/g; # \b means something different in a regex
3550     $str =~ s/\t/\\t/g;
3551     $str =~ s/\n/\\n/g;
3552     $str =~ s/\e/\\e/g;
3553     $str =~ s/\f/\\f/g;
3554     $str =~ s/\r/\\r/g;
3555     $str =~ s/([\cA-\cZ])/$unctrl{$1}/ge;
3556     $str =~ s/([[:^print:]])/sprintf("\\%03o", ord($1))/ge;
3557     return $str;
3558 }
3559
3560 # For regexes with the /x modifier.
3561 # Leave whitespace unmangled.
3562 sub escape_extended_re {
3563     my($str) = @_;
3564     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
3565     $str =~ s/([[:^print:]])/
3566         ($1 =~ y! \t\n!!) ? $1 : sprintf("\\%03o", ord($1))/ge;
3567     $str =~ s/\n/\n\f/g;
3568     return $str;
3569 }
3570
3571 # Don't do this for regexen
3572 sub unback {
3573     my($str) = @_;
3574     $str =~ s/\\/\\\\/g;
3575     return $str;
3576 }
3577
3578 # Remove backslashes which precede literal control characters,
3579 # to avoid creating ambiguity when we escape the latter.
3580 sub re_unback {
3581     my($str) = @_;
3582
3583     # the insane complexity here is due to the behaviour of "\c\"
3584     $str =~ s/(^|[^\\]|\\c\\)(?<!\\c)\\(\\\\)*(?=[[:^print:]])/$1$2/g;
3585     return $str;
3586 }
3587
3588 sub balanced_delim {
3589     my($str) = @_;
3590     my @str = split //, $str;
3591     my($ar, $open, $close, $fail, $c, $cnt, $last_bs);
3592     for $ar (['[',']'], ['(',')'], ['<','>'], ['{','}']) {
3593         ($open, $close) = @$ar;
3594         $fail = 0; $cnt = 0; $last_bs = 0;
3595         for $c (@str) {
3596             if ($c eq $open) {
3597                 $fail = 1 if $last_bs;
3598                 $cnt++;
3599             } elsif ($c eq $close) {
3600                 $fail = 1 if $last_bs;
3601                 $cnt--;
3602                 if ($cnt < 0) {
3603                     # qq()() isn't ")("
3604                     $fail = 1;
3605                     last;
3606                 }
3607             }
3608             $last_bs = $c eq '\\';
3609         }
3610         $fail = 1 if $cnt != 0;
3611         return ($open, "$open$str$close") if not $fail;
3612     }
3613     return ("", $str);
3614 }
3615
3616 sub single_delim {
3617     my($q, $default, $str) = @_;
3618     return "$default$str$default" if $default and index($str, $default) == -1;
3619     if ($q ne 'qr') {
3620         (my $succeed, $str) = balanced_delim($str);
3621         return "$q$str" if $succeed;
3622     }
3623     for my $delim ('/', '"', '#') {
3624         return "$q$delim" . $str . $delim if index($str, $delim) == -1;
3625     }
3626     if ($default) {
3627         $str =~ s/$default/\\$default/g;
3628         return "$default$str$default";
3629     } else {
3630         $str =~ s[/][\\/]g;
3631         return "$q/$str/";
3632     }
3633 }
3634
3635 my $max_prec;
3636 BEGIN { $max_prec = int(0.999 + 8*length(pack("F", 42))*log(2)/log(10)); }
3637
3638 # Split a floating point number into an integer mantissa and a binary
3639 # exponent. Assumes you've already made sure the number isn't zero or
3640 # some weird infinity or NaN.
3641 sub split_float {
3642     my($f) = @_;
3643     my $exponent = 0;
3644     if ($f == int($f)) {
3645         while ($f % 2 == 0) {
3646             $f /= 2;
3647             $exponent++;
3648         }
3649     } else {
3650         while ($f != int($f)) {
3651             $f *= 2;
3652             $exponent--;
3653         }
3654     }
3655     my $mantissa = sprintf("%.0f", $f);
3656     return ($mantissa, $exponent);
3657 }
3658
3659 sub const {
3660     my $self = shift;
3661     my($sv, $cx) = @_;
3662     if ($self->{'use_dumper'}) {
3663         return $self->const_dumper($sv, $cx);
3664     }
3665     if (class($sv) eq "SPECIAL") {
3666         # sv_undef, sv_yes, sv_no
3667         return ('undef', '1', $self->maybe_parens("!1", $cx, 21))[$$sv-1];
3668     }
3669     if (class($sv) eq "NULL") {
3670        return 'undef';
3671     }
3672     if ($cx) {
3673         unless ($self->{'inlined_constants'}) {
3674             $self->{'inlined_constants'} = $self->scan_for_constants;
3675         }
3676         my $const = $self->{'inlined_constants'}->{ 0 + $sv->object_2svref };
3677         return $const if $const;
3678     }
3679     # convert a version object into the "v1.2.3" string in its V magic
3680     if ($sv->FLAGS & SVs_RMG) {
3681         for (my $mg = $sv->MAGIC; $mg; $mg = $mg->MOREMAGIC) {
3682             return $mg->PTR if $mg->TYPE eq 'V';
3683         }
3684     }
3685
3686     if ($sv->FLAGS & SVf_IOK) {
3687         my $str = $sv->int_value;
3688         $str = $self->maybe_parens($str, $cx, 21) if $str < 0;
3689         return $str;
3690     } elsif ($sv->FLAGS & SVf_NOK) {
3691         my $nv = $sv->NV;
3692         if ($nv == 0) {
3693             if (pack("F", $nv) eq pack("F", 0)) {
3694                 # positive zero
3695                 return "0";
3696             } else {
3697                 # negative zero
3698                 return $self->maybe_parens("-.0", $cx, 21);
3699             }
3700         } elsif (1/$nv == 0) {
3701             if ($nv > 0) {
3702                 # positive infinity
3703                 return $self->maybe_parens("9**9**9", $cx, 22);
3704             } else {
3705                 # negative infinity
3706                 return $self->maybe_parens("-9**9**9", $cx, 21);
3707             }
3708         } elsif ($nv != $nv) {
3709             # NaN
3710             if (pack("F", $nv) eq pack("F", sin(9**9**9))) {
3711                 # the normal kind
3712                 return "sin(9**9**9)";
3713             } elsif (pack("F", $nv) eq pack("F", -sin(9**9**9))) {
3714                 # the inverted kind
3715                 return $self->maybe_parens("-sin(9**9**9)", $cx, 21);
3716             } else {
3717                 # some other kind
3718                 my $hex = unpack("h*", pack("F", $nv));
3719                 return qq'unpack("F", pack("h*", "$hex"))';
3720             }
3721         }
3722         # first, try the default stringification
3723         my $str = "$nv";
3724         if ($str != $nv) {
3725             # failing that, try using more precision
3726             $str = sprintf("%.${max_prec}g", $nv);
3727 #           if (pack("F", $str) ne pack("F", $nv)) {
3728             if ($str != $nv) {
3729                 # not representable in decimal with whatever sprintf()
3730                 # and atof() Perl is using here.
3731                 my($mant, $exp) = split_float($nv);
3732                 return $self->maybe_parens("$mant * 2**$exp", $cx, 19);
3733             }
3734         }
3735         $str = $self->maybe_parens($str, $cx, 21) if $nv < 0;
3736         return $str;
3737     } elsif ($sv->FLAGS & SVf_ROK && $sv->can("RV")) {
3738         my $ref = $sv->RV;
3739         if (class($ref) eq "AV") {
3740             return "[" . $self->list_const(2, $ref->ARRAY) . "]";
3741         } elsif (class($ref) eq "HV") {
3742             my %hash = $ref->ARRAY;
3743             my @elts;
3744             for my $k (sort keys %hash) {
3745                 push @elts, "$k => " . $self->const($hash{$k}, 6);
3746             }
3747             return "{" . join(", ", @elts) . "}";
3748         } elsif (class($ref) eq "CV") {
3749             return "sub " . $self->deparse_sub($ref);
3750         }
3751         if ($ref->FLAGS & SVs_SMG) {
3752             for (my $mg = $ref->MAGIC; $mg; $mg = $mg->MOREMAGIC) {
3753                 if ($mg->TYPE eq 'r') {
3754                     my $re = re_uninterp(escape_str(re_unback($mg->precomp)));
3755                     return single_delim("qr", "", $re);
3756                 }
3757             }
3758         }
3759         
3760         return $self->maybe_parens("\\" . $self->const($ref, 20), $cx, 20);
3761     } elsif ($sv->FLAGS & SVf_POK) {
3762         my $str = $sv->PV;
3763         if ($str =~ /[[:^print:]]/) {
3764             return single_delim("qq", '"', uninterp escape_str unback $str);
3765         } else {
3766             return single_delim("q", "'", unback $str);
3767         }
3768     } else {
3769         return "undef";
3770     }
3771 }
3772
3773 sub const_dumper {
3774     my $self = shift;
3775     my($sv, $cx) = @_;
3776     my $ref = $sv->object_2svref();
3777     my $dumper = Data::Dumper->new([$$ref], ['$v']);
3778     $dumper->Purity(1)->Terse(1)->Deparse(1)->Indent(0)->Useqq(1)->Sortkeys(1);
3779     my $str = $dumper->Dump();
3780     if ($str =~ /^\$v/) {
3781         return '${my ' . $str . ' \$v}';
3782     } else {
3783         return $str;
3784     }
3785 }
3786
3787 sub const_sv {
3788     my $self = shift;
3789     my $op = shift;
3790     my $sv = $op->sv;
3791     # the constant could be in the pad (under useithreads)
3792     $sv = $self->padval($op->targ) unless $$sv;
3793     return $sv;
3794 }
3795
3796 sub pp_const {
3797     my $self = shift;
3798     my($op, $cx) = @_;
3799     if ($op->private & OPpCONST_ARYBASE) {
3800         return '$[';
3801     }
3802 #    if ($op->private & OPpCONST_BARE) { # trouble with `=>' autoquoting
3803 #       return $self->const_sv($op)->PV;
3804 #    }
3805     my $sv = $self->const_sv($op);
3806     return $self->const($sv, $cx);
3807 }
3808
3809 sub dq {
3810     my $self = shift;
3811     my $op = shift;
3812     my $type = $op->name;
3813     if ($type eq "const") {
3814         return '$[' if $op->private & OPpCONST_ARYBASE;
3815         return uninterp(escape_str(unback($self->const_sv($op)->as_string)));
3816     } elsif ($type eq "concat") {
3817         my $first = $self->dq($op->first);
3818         my $last  = $self->dq($op->last);
3819
3820         # Disambiguate "${foo}bar", "${foo}{bar}", "${foo}[1]", "$foo\::bar"
3821         ($last =~ /^[A-Z\\\^\[\]_?]/ &&
3822             $first =~ s/([\$@])\^$/${1}{^}/)  # "${^}W" etc
3823             || ($last =~ /^[:'{\[\w_]/ && #'
3824                 $first =~ s/([\$@])([A-Za-z_]\w*)$/${1}{$2}/);
3825
3826         return $first . $last;
3827     } elsif ($type eq "uc") {
3828         return '\U' . $self->dq($op->first->sibling) . '\E';
3829     } elsif ($type eq "lc") {
3830         return '\L' . $self->dq($op->first->sibling) . '\E';
3831     } elsif ($type eq "ucfirst") {
3832         return '\u' . $self->dq($op->first->sibling);
3833     } elsif ($type eq "lcfirst") {
3834         return '\l' . $self->dq($op->first->sibling);
3835     } elsif ($type eq "quotemeta") {
3836         return '\Q' . $self->dq($op->first->sibling) . '\E';
3837     } elsif ($type eq "join") {
3838         return $self->deparse($op->last, 26); # was join($", @ary)
3839     } else {
3840         return $self->deparse($op, 26);
3841     }
3842 }
3843
3844 sub pp_backtick {
3845     my $self = shift;
3846     my($op, $cx) = @_;
3847     # skip pushmark if it exists (readpipe() vs ``)
3848     my $child = $op->first->sibling->isa('B::NULL')
3849         ? $op->first : $op->first->sibling;
3850     return single_delim("qx", '`', $self->dq($child));
3851 }
3852
3853 sub dquote {
3854     my $self = shift;
3855     my($op, $cx) = @_;
3856     my $kid = $op->first->sibling; # skip ex-stringify, pushmark
3857     return $self->deparse($kid, $cx) if $self->{'unquote'};
3858     $self->maybe_targmy($kid, $cx,
3859                         sub {single_delim("qq", '"', $self->dq($_[1]))});
3860 }
3861
3862 # OP_STRINGIFY is a listop, but it only ever has one arg
3863 sub pp_stringify { maybe_targmy(@_, \&dquote) }
3864
3865 # tr/// and s/// (and tr[][], tr[]//, tr###, etc)
3866 # note that tr(from)/to/ is OK, but not tr/from/(to)
3867 sub double_delim {
3868     my($from, $to) = @_;
3869     my($succeed, $delim);
3870     if ($from !~ m[/] and $to !~ m[/]) {
3871         return "/$from/$to/";
3872     } elsif (($succeed, $from) = balanced_delim($from) and $succeed) {
3873         if (($succeed, $to) = balanced_delim($to) and $succeed) {
3874             return "$from$to";
3875         } else {
3876             for $delim ('/', '"', '#') { # note no `'' -- s''' is special
3877                 return "$from$delim$to$delim" if index($to, $delim) == -1;
3878             }
3879             $to =~ s[/][\\/]g;
3880             return "$from/$to/";
3881         }
3882     } else {
3883         for $delim ('/', '"', '#') { # note no '
3884             return "$delim$from$delim$to$delim"
3885                 if index($to . $from, $delim) == -1;
3886         }
3887         $from =~ s[/][\\/]g;
3888         $to =~ s[/][\\/]g;
3889         return "/$from/$to/";   
3890     }
3891 }
3892
3893 # Only used by tr///, so backslashes hyphens
3894 sub pchr { # ASCII
3895     my($n) = @_;
3896     if ($n == ord '\\') {
3897         return '\\\\';
3898     } elsif ($n == ord "-") {
3899         return "\\-";
3900     } elsif ($n >= ord(' ') and $n <= ord('~')) {
3901         return chr($n);
3902     } elsif ($n == ord "\a") {
3903         return '\\a';
3904     } elsif ($n == ord "\b") {
3905         return '\\b';
3906     } elsif ($n == ord "\t") {
3907         return '\\t';
3908     } elsif ($n == ord "\n") {
3909         return '\\n';
3910     } elsif ($n == ord "\e") {
3911         return '\\e';
3912     } elsif ($n == ord "\f") {
3913         return '\\f';
3914     } elsif ($n == ord "\r") {
3915         return '\\r';
3916     } elsif ($n >= ord("\cA") and $n <= ord("\cZ")) {
3917         return '\\c' . chr(ord("@") + $n);
3918     } else {
3919 #       return '\x' . sprintf("%02x", $n);
3920         return '\\' . sprintf("%03o", $n);
3921     }
3922 }
3923
3924 sub collapse {
3925     my(@chars) = @_;
3926     my($str, $c, $tr) = ("");
3927     for ($c = 0; $c < @chars; $c++) {
3928         $tr = $chars[$c];
3929         $str .= pchr($tr);
3930         if ($c <= $#chars - 2 and $chars[$c + 1] == $tr + 1 and
3931             $chars[$c + 2] == $tr + 2)
3932         {
3933             for (; $c <= $#chars-1 and $chars[$c + 1] == $chars[$c] + 1; $c++)
3934               {}
3935             $str .= "-";
3936             $str .= pchr($chars[$c]);
3937         }
3938     }
3939     return $str;
3940 }
3941
3942 sub tr_decode_byte {
3943     my($table, $flags) = @_;
3944     my(@table) = unpack("s*", $table);
3945     splice @table, 0x100, 1;   # Number of subsequent elements
3946     my($c, $tr, @from, @to, @delfrom, $delhyphen);
3947     if ($table[ord "-"] != -1 and
3948         $table[ord("-") - 1] == -1 || $table[ord("-") + 1] == -1)
3949     {
3950         $tr = $table[ord "-"];
3951         $table[ord "-"] = -1;
3952         if ($tr >= 0) {
3953             @from = ord("-");
3954             @to = $tr;
3955         } else { # -2 ==> delete
3956             $delhyphen = 1;
3957         }
3958     }
3959     for ($c = 0; $c < @table; $c++) {
3960         $tr = $table[$c];
3961         if ($tr >= 0) {
3962             push @from, $c; push @to, $tr;
3963         } elsif ($tr == -2) {
3964             push @delfrom, $c;
3965         }
3966     }
3967     @from = (@from, @delfrom);
3968     if ($flags & OPpTRANS_COMPLEMENT) {
3969         my @newfrom = ();
3970         my %from;
3971         @from{@from} = (1) x @from;
3972         for ($c = 0; $c < 256; $c++) {
3973             push @newfrom, $c unless $from{$c};
3974         }
3975         @from = @newfrom;
3976     }
3977     unless ($flags & OPpTRANS_DELETE || !@to) {
3978         pop @to while $#to and $to[$#to] == $to[$#to -1];
3979     }
3980     my($from, $to);
3981     $from = collapse(@from);
3982     $to = collapse(@to);
3983     $from .= "-" if $delhyphen;
3984     return ($from, $to);
3985 }
3986
3987 sub tr_chr {
3988     my $x = shift;
3989     if ($x == ord "-") {
3990         return "\\-";
3991     } elsif ($x == ord "\\") {
3992         return "\\\\";
3993     } else {
3994         return chr $x;
3995     }
3996 }
3997
3998 # XXX This doesn't yet handle all cases correctly either
3999
4000 sub tr_decode_utf8 {
4001     my($swash_hv, $flags) = @_;
4002     my %swash = $swash_hv->ARRAY;
4003     my $final = undef;
4004     $final = $swash{'FINAL'}->IV if exists $swash{'FINAL'};
4005     my $none = $swash{"NONE"}->IV;
4006     my $extra = $none + 1;
4007     my(@from, @delfrom, @to);
4008     my $line;
4009     foreach $line (split /\n/, $swash{'LIST'}->PV) {
4010         my($min, $max, $result) = split(/\t/, $line);
4011         $min = hex $min;
4012         if (length $max) {
4013             $max = hex $max;
4014         } else {
4015             $max = $min;
4016         }
4017         $result = hex $result;
4018         if ($result == $extra) {
4019             push @delfrom, [$min, $max];
4020         } else {
4021             push @from, [$min, $max];
4022             push @to, [$result, $result + $max - $min];
4023         }
4024     }
4025     for my $i (0 .. $#from) {
4026         if ($from[$i][0] == ord '-') {
4027             unshift @from, splice(@from, $i, 1);
4028             unshift @to, splice(@to, $i, 1);
4029             last;
4030         } elsif ($from[$i][1] == ord '-') {
4031             $from[$i][1]--;
4032             $to[$i][1]--;
4033             unshift @from, ord '-';
4034             unshift @to, ord '-';
4035             last;
4036         }
4037     }
4038     for my $i (0 .. $#delfrom) {
4039         if ($delfrom[$i][0] == ord '-') {
4040             push @delfrom, splice(@delfrom, $i, 1);
4041             last;
4042         } elsif ($delfrom[$i][1] == ord '-') {
4043             $delfrom[$i][1]--;
4044             push @delfrom, ord '-';
4045             last;
4046         }
4047     }
4048     if (defined $final and $to[$#to][1] != $final) {
4049         push @to, [$final, $final];
4050     }
4051     push @from, @delfrom;
4052     if ($flags & OPpTRANS_COMPLEMENT) {
4053         my @newfrom;
4054         my $next = 0;
4055         for my $i (0 .. $#from) {
4056             push @newfrom, [$next, $from[$i][0] - 1];
4057             $next = $from[$i][1] + 1;
4058         }
4059         @from = ();
4060         for my $range (@newfrom) {
4061             if ($range->[0] <= $range->[1]) {
4062                 push @from, $range;
4063             }
4064         }
4065     }
4066     my($from, $to, $diff);
4067     for my $chunk (@from) {
4068         $diff = $chunk->[1] - $chunk->[0];
4069         if ($diff > 1) {
4070             $from .= tr_chr($chunk->[0]) . "-" . tr_chr($chunk->[1]);
4071         } elsif ($diff == 1) {
4072             $from .= tr_chr($chunk->[0]) . tr_chr($chunk->[1]);
4073         } else {
4074             $from .= tr_chr($chunk->[0]);
4075         }
4076     }
4077     for my $chunk (@to) {
4078         $diff = $chunk->[1] - $chunk->[0];
4079         if ($diff > 1) {
4080             $to .= tr_chr($chunk->[0]) . "-" . tr_chr($chunk->[1]);
4081         } elsif ($diff == 1) {
4082             $to .= tr_chr($chunk->[0]) . tr_chr($chunk->[1]);
4083         } else {
4084             $to .= tr_chr($chunk->[0]);
4085         }
4086     }
4087     #$final = sprintf("%04x", $final) if defined $final;
4088     #$none = sprintf("%04x", $none) if defined $none;
4089     #$extra = sprintf("%04x", $extra) if defined $extra;
4090     #print STDERR "final: $final\n none: $none\nextra: $extra\n";
4091     #print STDERR $swash{'LIST'}->PV;
4092     return (escape_str($from), escape_str($to));
4093 }
4094
4095 sub pp_trans {
4096     my $self = shift;
4097     my($op, $cx) = @_;
4098     my($from, $to);
4099     if (class($op) eq "PVOP") {
4100         ($from, $to) = tr_decode_byte($op->pv, $op->private);
4101     } else { # class($op) eq "SVOP"
4102         ($from, $to) = tr_decode_utf8($op->sv->RV, $op->private);
4103     }
4104     my $flags = "";
4105     $flags .= "c" if $op->private & OPpTRANS_COMPLEMENT;
4106     $flags .= "d" if $op->private & OPpTRANS_DELETE;
4107     $to = "" if $from eq $to and $flags eq "";
4108     $flags .= "s" if $op->private & OPpTRANS_SQUASH;
4109     return "tr" . double_delim($from, $to) . $flags;
4110 }
4111
4112 sub re_dq_disambiguate {
4113     my ($first, $last) = @_;
4114     # Disambiguate "${foo}bar", "${foo}{bar}", "${foo}[1]"
4115     ($last =~ /^[A-Z\\\^\[\]_?]/ &&
4116         $first =~ s/([\$@])\^$/${1}{^}/)  # "${^}W" etc
4117         || ($last =~ /^[{\[\w_]/ &&
4118             $first =~ s/([\$@])([A-Za-z_]\w*)$/${1}{$2}/);
4119     return $first . $last;
4120 }
4121
4122 # Like dq(), but different
4123 sub re_dq {
4124     my $self = shift;
4125     my ($op, $extended) = @_;
4126
4127     my $type = $op->name;
4128     if ($type eq "const") {
4129         return '$[' if $op->private & OPpCONST_ARYBASE;
4130         my $unbacked = re_unback($self->const_sv($op)->as_string);
4131         return re_uninterp_extended(escape_extended_re($unbacked))
4132             if $extended;
4133         return re_uninterp(escape_str($unbacked));
4134     } elsif ($type eq "concat") {
4135         my $first = $self->re_dq($op->first, $extended);
4136         my $last  = $self->re_dq($op->last,  $extended);
4137         return re_dq_disambiguate($first, $last);
4138     } elsif ($type eq "uc") {
4139         return '\U' . $self->re_dq($op->first->sibling, $extended) . '\E';
4140     } elsif ($type eq "lc") {
4141         return '\L' . $self->re_dq($op->first->sibling, $extended) . '\E';
4142     } elsif ($type eq "ucfirst") {
4143         return '\u' . $self->re_dq($op->first->sibling, $extended);
4144     } elsif ($type eq "lcfirst") {
4145         return '\l' . $self->re_dq($op->first->sibling, $extended);
4146     } elsif ($type eq "quotemeta") {
4147         return '\Q' . $self->re_dq($op->first->sibling, $extended) . '\E';
4148     } elsif ($type eq "join") {
4149         return $self->deparse($op->last, 26); # was join($", @ary)
4150     } else {
4151         return $self->deparse($op, 26);
4152     }
4153 }
4154
4155 sub pure_string {
4156     my ($self, $op) = @_;
4157     return 0 if null $op;
4158     my $type = $op->name;
4159
4160     if ($type eq 'const') {
4161         return 1;
4162     }
4163     elsif ($type =~ /^[ul]c(first)?$/ || $type eq 'quotemeta') {
4164         return $self->pure_string($op->first->sibling);
4165     }
4166     elsif ($type eq 'join') {
4167         my $join_op = $op->first->sibling;  # Skip pushmark
4168         return 0 unless $join_op->name eq 'null' && $join_op->targ eq OP_RV2SV;
4169
4170         my $gvop = $join_op->first;
4171         return 0 unless $gvop->name eq 'gvsv';
4172         return 0 unless '"' eq $self->gv_name($self->gv_or_padgv($gvop));
4173
4174         return 0 unless ${$join_op->sibling} eq ${$op->last};
4175         return 0 unless $op->last->name =~ /^(?:[ah]slice|(?:rv2|pad)av)$/;
4176     }
4177     elsif ($type eq 'concat') {
4178         return $self->pure_string($op->first)
4179             && $self->pure_string($op->last);
4180     }
4181     elsif (is_scalar($op) || $type =~ /^[ah]elem$/) {
4182         return 1;
4183     }
4184     elsif ($type eq "null" and $op->can('first') and not null $op->first and
4185            $op->first->name eq "null" and $op->first->can('first')
4186            and not null $op->first->first and
4187            $op->first->first->name eq "aelemfast") {
4188         return 1;
4189     }
4190     else {
4191         return 0;
4192     }
4193
4194     return 1;
4195 }
4196
4197 sub regcomp {
4198     my $self = shift;
4199     my($op, $cx, $extended) = @_;
4200     my $kid = $op->first;
4201     $kid = $kid->first if $kid->name eq "regcmaybe";
4202     $kid = $kid->first if $kid->name eq "regcreset";
4203     if ($kid->name eq "null" and !null($kid->first)
4204         and $kid->first->name eq 'pushmark')
4205     {
4206         my $str = '';
4207         $kid = $kid->first->sibling;
4208         while (!null($kid)) {
4209             my $first = $str;
4210             my $last = $self->re_dq($kid, $extended);
4211             $str = re_dq_disambiguate($first, $last);
4212             $kid = $kid->sibling;
4213         }
4214         return $str, 1;
4215     }
4216
4217     return ($self->re_dq($kid, $extended), 1) if $self->pure_string($kid);
4218     return ($self->deparse($kid, $cx), 0);
4219 }
4220
4221 sub pp_regcomp {
4222     my ($self, $op, $cx) = @_;
4223     return (($self->regcomp($op, $cx, 0))[0]);
4224 }
4225
4226 # osmic acid -- see osmium tetroxide
4227
4228 my %matchwords;
4229 map($matchwords{join "", sort split //, $_} = $_, 'cig', 'cog', 'cos', 'cogs',
4230     'cox', 'go', 'is', 'ism', 'iso', 'mig', 'mix', 'osmic', 'ox', 'sic',
4231     'sig', 'six', 'smog', 'so', 'soc', 'sog', 'xi');
4232
4233 sub matchop {
4234     my $self = shift;
4235     my($op, $cx, $name, $delim) = @_;
4236     my $kid = $op->first;
4237     my ($binop, $var, $re) = ("", "", "");
4238     if ($op->flags & OPf_STACKED) {
4239         $binop = 1;
4240         $var = $self->deparse($kid, 20);
4241         $kid = $kid->sibling;
4242     }
4243     my $quote = 1;
4244     my $extended = ($op->pmflags & PMf_EXTENDED);
4245     if (null $kid) {
4246         my $unbacked = re_unback($op->precomp);
4247         if ($extended) {
4248             $re = re_uninterp_extended(escape_extended_re($unbacked));
4249         } else {
4250             $re = re_uninterp(escape_str(re_unback($op->precomp)));
4251         }
4252     } elsif ($kid->name ne 'regcomp') {
4253         carp("found ".$kid->name." where regcomp expected");
4254     } else {
4255         ($re, $quote) = $self->regcomp($kid, 21, $extended);
4256     }
4257     my $flags = "";
4258     $flags .= "c" if $op->pmflags & PMf_CONTINUE;
4259     $flags .= "g" if $op->pmflags & PMf_GLOBAL;
4260     $flags .= "i" if $op->pmflags & PMf_FOLD;
4261     $flags .= "m" if $op->pmflags & PMf_MULTILINE;
4262     $flags .= "o" if $op->pmflags & PMf_KEEP;
4263     $flags .= "s" if $op->pmflags & PMf_SINGLELINE;
4264     $flags .= "x" if $op->pmflags & PMf_EXTENDED;
4265     $flags = $matchwords{$flags} if $matchwords{$flags};
4266     if ($op->pmflags & PMf_ONCE) { # only one kind of delimiter works here
4267         $re =~ s/\?/\\?/g;
4268         $re = "?$re?";
4269     } elsif ($quote) {
4270         $re = single_delim($name, $delim, $re);
4271     }
4272     $re = $re . $flags if $quote;
4273     if ($binop) {
4274         return $self->maybe_parens("$var =~ $re", $cx, 20);
4275     } else {
4276         return $re;
4277     }
4278 }
4279
4280 sub pp_match { matchop(@_, "m", "/") }
4281 sub pp_pushre { matchop(@_, "m", "/") }
4282 sub pp_qr { matchop(@_, "qr", "") }
4283
4284 sub pp_split {
4285     my $self = shift;
4286     my($op, $cx) = @_;
4287     my($kid, @exprs, $ary, $expr);
4288     $kid = $op->first;
4289
4290     # For our kid (an OP_PUSHRE), pmreplroot is never actually the
4291     # root of a replacement; it's either empty, or abused to point to
4292     # the GV for an array we split into (an optimization to save
4293     # assignment overhead). Depending on whether we're using ithreads,
4294     # this OP* holds either a GV* or a PADOFFSET. Luckily, B.xs
4295     # figures out for us which it is.
4296     my $replroot = $kid->pmreplroot;
4297     my $gv = 0;
4298     if (ref($replroot) eq "B::GV") {
4299         $gv = $replroot;
4300     } elsif (!ref($replroot) and $replroot > 0) {
4301         $gv = $self->padval($replroot);
4302     }
4303     $ary = $self->stash_variable('@', $self->gv_name($gv)) if $gv;
4304
4305     for (; !null($kid); $kid = $kid->sibling) {
4306         push @exprs, $self->deparse($kid, 6);
4307     }
4308
4309     # handle special case of split(), and split(' ') that compiles to /\s+/
4310     $kid = $op->first;
4311     if ( $kid->flags & OPf_SPECIAL
4312          and ( $] < 5.009 ? $kid->pmflags & PMf_SKIPWHITE()
4313               : $kid->reflags & RXf_SKIPWHITE() ) ) {
4314         $exprs[0] = "' '";
4315     }
4316
4317     $expr = "split(" . join(", ", @exprs) . ")";
4318     if ($ary) {
4319         return $self->maybe_parens("$ary = $expr", $cx, 7);
4320     } else {
4321         return $expr;
4322     }
4323 }
4324
4325 # oxime -- any of various compounds obtained chiefly by the action of
4326 # hydroxylamine on aldehydes and ketones and characterized by the
4327 # bivalent grouping C=NOH [Webster's Tenth]
4328
4329 my %substwords;
4330 map($substwords{join "", sort split //, $_} = $_, 'ego', 'egoism', 'em',
4331     'es', 'ex', 'exes', 'gee', 'go', 'goes', 'ie', 'ism', 'iso', 'me',
4332     'meese', 'meso', 'mig', 'mix', 'os', 'ox', 'oxime', 'see', 'seem',
4333     'seg', 'sex', 'sig', 'six', 'smog', 'sog', 'some', 'xi');
4334
4335 sub pp_subst {
4336     my $self = shift;
4337     my($op, $cx) = @_;
4338     my $kid = $op->first;
4339     my($binop, $var, $re, $repl) = ("", "", "", "");
4340     if ($op->flags & OPf_STACKED) {
4341         $binop = 1;
4342         $var = $self->deparse($kid, 20);
4343         $kid = $kid->sibling;
4344     }
4345     my $flags = "";
4346     if (null($op->pmreplroot)) {
4347         $repl = $self->dq($kid);
4348         $kid = $kid->sibling;
4349     } else {
4350         $repl = $op->pmreplroot->first; # skip substcont
4351         while ($repl->name eq "entereval") {
4352             $repl = $repl->first;
4353             $flags .= "e";
4354         }
4355         if ($op->pmflags & PMf_EVAL) {
4356             $repl = $self->deparse($repl->first, 0);
4357         } else {
4358             $repl = $self->dq($repl);   
4359         }
4360     }
4361     my $extended = ($op->pmflags & PMf_EXTENDED);
4362     if (null $kid) {
4363         my $unbacked = re_unback($op->precomp);
4364         if ($extended) {
4365             $re = re_uninterp_extended(escape_extended_re($unbacked));
4366         }
4367         else {
4368             $re = re_uninterp(escape_str($unbacked));
4369         }
4370     } else {
4371         ($re) = $self->regcomp($kid, 1, $extended);
4372     }
4373     $flags .= "e" if $op->pmflags & PMf_EVAL;
4374     $flags .= "g" if $op->pmflags & PMf_GLOBAL;
4375     $flags .= "i" if $op->pmflags & PMf_FOLD;
4376     $flags .= "m" if $op->pmflags & PMf_MULTILINE;
4377     $flags .= "o" if $op->pmflags & PMf_KEEP;
4378     $flags .= "s" if $op->pmf