This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
1c6bcf1276cf41262c5b8e7e22a09a34d940a3a4
[perl5.git] / t / harness
1 #!./perl
2
3 # We suppose that perl _mostly_ works at this moment, so may use
4 # sophisticated testing.
5
6 BEGIN {
7     chdir 't' if -d 't';
8     @INC = '../lib';              # pick up only this build's lib
9     $ENV{PERL5LIB} = '../lib';    # so children will see it too
10 }
11
12 my $torture; # torture testing?
13
14 use Test::Harness;
15 use strict;
16
17 $Test::Harness::switches = "";    # Too much noise otherwise
18 $Test::Harness::Verbose++ while @ARGV && $ARGV[0] eq '-v' && shift;
19
20 if ($ARGV[0] && $ARGV[0] eq '-torture') {
21     shift;
22     $torture = 1;
23 }
24
25 # Let tests know they're running in the perl core.  Useful for modules
26 # which live dual lives on CPAN.
27 $ENV{PERL_CORE} = 1;
28
29 #fudge DATA for now.
30 my %datahandle = qw(
31                 lib/bigint.t            1
32                 lib/bigintpm.t          1
33                 lib/bigfloat.t          1
34                 lib/bigfloatpm.t        1
35                 op/gv.t                 1
36                 lib/complex.t           1
37                 lib/ph.t                1
38                 lib/soundex.t           1
39                 op/misc.t               1
40                 op/runlevel.t           1
41                 op/tie.t                1
42                 op/lex_assign.t         1
43                 );
44
45 foreach (keys %datahandle) {
46      unlink "$_.t";
47 }
48
49 my (@tests, $re);
50
51 # [.VMS]TEST.COM calls harness with empty arguments, so clean-up @ARGV
52 @ARGV = grep $_ && length( $_ ) => @ARGV;
53
54 sub _populate_hash {
55     return map {$_, 1} split /\s+/, $_[0];
56 }
57
58 if ($ARGV[0] && $ARGV[0]=~/^-re/) {
59     if ($ARGV[0]!~/=/) {
60         shift;
61         $re=join "|",@ARGV;
62         @ARGV=();
63     } else {
64         (undef,$re)=split/=/,shift;
65     }
66 }
67
68 if (@ARGV) {
69     if ($^O eq 'MSWin32') {
70         @tests = map(glob($_),@ARGV);
71     }
72     else {
73         @tests = @ARGV;
74     }
75 } else {
76     unless (@tests) {
77         push @tests, <base/*.t>;
78         push @tests, <comp/*.t>;
79         push @tests, <cmd/*.t>;
80         push @tests, <run/*.t>;
81         push @tests, <io/*.t>;
82         push @tests, <op/*.t>;
83         push @tests, <uni/*.t>;
84         push @tests, <mro/*.t>;
85         push @tests, <lib/*.t>;
86         push @tests, <japh/*.t> if $torture;
87         push @tests, <win32/*.t> if $^O eq 'MSWin32';
88         use Config;
89         my %skip;
90         {
91             my %extensions = _populate_hash $Config{'extensions'};
92             my %known_extensions = _populate_hash $Config{'known_extensions'};
93             foreach (keys %known_extensions) {
94                 $skip{$_}++ unless $extensions{$_};
95             }
96         }
97         use File::Spec;
98         my $updir = File::Spec->updir;
99         my $mani  = File::Spec->catfile(File::Spec->updir, "MANIFEST");
100         if (open(MANI, $mani)) {
101             my @manitests = ();
102             my $ext_pat = $^O eq 'MSWin32' ? '(?:win32/)?ext' : 'ext';
103             while (<MANI>) { # similar code in t/TEST
104                 if (m!^($ext_pat/(\S+)/+(?:[^/\s]+\.t|test\.pl)|lib/\S+?(?:\.t|test\.pl))\s!) {
105                     my ($test, $extension) = ($1, $2);
106                     if (defined $extension) {
107                         $extension =~ s!/t$!!;
108                         # XXX Do I want to warn that I'm skipping these?
109                         next if $skip{$extension};
110                     }
111                     push @manitests, File::Spec->catfile($updir, $test);
112                 }
113             }
114             close MANI;
115             # Sort the list of test files read from MANIFEST into a sensible
116             # order instead of using the order in which they are listed there
117             push @tests, sort { lc $a cmp lc $b } @manitests;
118         } else {
119             warn "$0: cannot open $mani: $!\n";
120         }
121         push @tests, <Module_Pluggable/*.t>;
122         push @tests, <pod/*.t>;
123         push @tests, <x2p/*.t>;
124     }
125 }
126 if ($^O eq 'MSWin32') {
127     s,\\,/,g for @tests;
128 }
129 @tests=grep /$re/, @tests 
130     if $re;
131 Test::Harness::runtests @tests;
132 exit(0);