This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
POD tweak to 'require' in perlfunc relating to putting Perl code in @INC
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2 X<function>
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides a scalar context to its
16 argument, while a list operator may provide either scalar or list
17 contexts for its arguments.  If it does both, scalar arguments 
18 come first and list argument follow, and there can only ever
19 be one such list argument.  For instance, splice() has three scalar
20 arguments followed by a list, whereas gethostbyname() has four scalar
21 arguments.
22
23 In the syntax descriptions that follow, list operators that expect a
24 list (and provide list context for elements of the list) are shown
25 with LIST as an argument.  Such a list may consist of any combination
26 of scalar arguments or list values; the list values will be included
27 in the list as if each individual element were interpolated at that
28 point in the list, forming a longer single-dimensional list value.
29 Commas should separate literal elements of the LIST.
30
31 Any function in the list below may be used either with or without
32 parentheses around its arguments.  (The syntax descriptions omit the
33 parentheses.)  If you use parentheses, the simple but occasionally 
34 surprising rule is this: It I<looks> like a function, therefore it I<is> a
35 function, and precedence doesn't matter.  Otherwise it's a list
36 operator or unary operator, and precedence does matter.  Whitespace
37 between the function and left parenthesis doesn't count, so sometimes
38 you need to be careful:
39
40     print 1+2+4;      # Prints 7.
41     print(1+2) + 4;   # Prints 3.
42     print (1+2)+4;    # Also prints 3!
43     print +(1+2)+4;   # Prints 7.
44     print ((1+2)+4);  # Prints 7.
45
46 If you run Perl with the B<-w> switch it can warn you about this.  For
47 example, the third line above produces:
48
49     print (...) interpreted as function at - line 1.
50     Useless use of integer addition in void context at - line 1.
51
52 A few functions take no arguments at all, and therefore work as neither
53 unary nor list operators.  These include such functions as C<time>
54 and C<endpwent>.  For example, C<time+86_400> always means
55 C<time() + 86_400>.
56
57 For functions that can be used in either a scalar or list context,
58 nonabortive failure is generally indicated in a scalar context by
59 returning the undefined value, and in a list context by returning the
60 empty list.
61
62 Remember the following important rule: There is B<no rule> that relates
63 the behavior of an expression in list context to its behavior in scalar
64 context, or vice versa.  It might do two totally different things.
65 Each operator and function decides which sort of value would be most
66 appropriate to return in scalar context.  Some operators return the
67 length of the list that would have been returned in list context.  Some
68 operators return the first value in the list.  Some operators return the
69 last value in the list.  Some operators return a count of successful
70 operations.  In general, they do what you want, unless you want
71 consistency.
72 X<context>
73
74 A named array in scalar context is quite different from what would at
75 first glance appear to be a list in scalar context.  You can't get a list
76 like C<(1,2,3)> into being in scalar context, because the compiler knows
77 the context at compile time.  It would generate the scalar comma operator
78 there, not the list construction version of the comma.  That means it
79 was never a list to start with.
80
81 In general, functions in Perl that serve as wrappers for system calls ("syscalls")
82 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
83 true when they succeed and C<undef> otherwise, as is usually mentioned
84 in the descriptions below.  This is different from the C interfaces,
85 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
86 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
87 variable on failure.  Other functions do not, except accidentally.
88
89 Extension modules can also hook into the Perl parser to define new
90 kinds of keyword-headed expression.  These may look like functions, but
91 may also look completely different.  The syntax following the keyword
92 is defined entirely by the extension.  If you are an implementor, see
93 L<perlapi/PL_keyword_plugin> for the mechanism.  If you are using such
94 a module, see the module's documentation for details of the syntax that
95 it defines.
96
97 =head2 Perl Functions by Category
98 X<function>
99
100 Here are Perl's functions (including things that look like
101 functions, like some keywords and named operators)
102 arranged by category.  Some functions appear in more
103 than one place.
104
105 =over 4
106
107 =item Functions for SCALARs or strings
108 X<scalar> X<string> X<character>
109
110 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
111 C<length>, C<oct>, C<ord>, C<pack>, C<q//>, C<qq//>, C<reverse>,
112 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
113
114 =item Regular expressions and pattern matching
115 X<regular expression> X<regex> X<regexp>
116
117 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
118
119 =item Numeric functions
120 X<numeric> X<number> X<trigonometric> X<trigonometry>
121
122 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
123 C<sin>, C<sqrt>, C<srand>
124
125 =item Functions for real @ARRAYs
126 X<array>
127
128 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
129
130 =item Functions for list data
131 X<list>
132
133 C<grep>, C<join>, C<map>, C<qw//>, C<reverse>, C<sort>, C<unpack>
134
135 =item Functions for real %HASHes
136 X<hash>
137
138 C<delete>, C<each>, C<exists>, C<keys>, C<values>
139
140 =item Input and output functions
141 X<I/O> X<input> X<output> X<dbm>
142
143 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
144 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
145 C<readdir>, C<rewinddir>, C<say>, C<seek>, C<seekdir>, C<select>, C<syscall>,
146 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
147 C<warn>, C<write>
148
149 =item Functions for fixed length data or records
150
151 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
152
153 =item Functions for filehandles, files, or directories
154 X<file> X<filehandle> X<directory> X<pipe> X<link> X<symlink>
155
156 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
157 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
158 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
159 C<umask>, C<unlink>, C<utime>
160
161 =item Keywords related to the control flow of your Perl program
162 X<control flow>
163
164 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
165 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
166
167 =item Keywords related to switch
168
169 C<break>, C<continue>, C<given>, C<when>, C<default>
170
171 (These are available only if you enable the C<"switch"> feature.
172 See L<feature> and L<perlsyn/"Switch statements">.)
173
174 =item Keywords related to scoping
175
176 C<caller>, C<import>, C<local>, C<my>, C<our>, C<state>, C<package>,
177 C<use>
178
179 (C<state> is available only if the C<"state"> feature is enabled. See
180 L<feature>.)
181
182 =item Miscellaneous functions
183
184 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>,
185 C<reset>, C<scalar>, C<state>, C<undef>, C<wantarray>
186
187 =item Functions for processes and process groups
188 X<process> X<pid> X<process id>
189
190 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
191 C<pipe>, C<qx//>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
192 C<times>, C<wait>, C<waitpid>
193
194 =item Keywords related to Perl modules
195 X<module>
196
197 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
198
199 =item Keywords related to classes and object-orientation
200 X<object> X<class> X<package>
201
202 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
203 C<untie>, C<use>
204
205 =item Low-level socket functions
206 X<socket> X<sock>
207
208 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
209 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
210 C<socket>, C<socketpair>
211
212 =item System V interprocess communication functions
213 X<IPC> X<System V> X<semaphore> X<shared memory> X<memory> X<message>
214
215 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
216 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
217
218 =item Fetching user and group info
219 X<user> X<group> X<password> X<uid> X<gid>  X<passwd> X</etc/passwd>
220
221 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
222 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
223 C<getpwuid>, C<setgrent>, C<setpwent>
224
225 =item Fetching network info
226 X<network> X<protocol> X<host> X<hostname> X<IP> X<address> X<service>
227
228 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
229 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
230 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
231 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
232 C<setnetent>, C<setprotoent>, C<setservent>
233
234 =item Time-related functions
235 X<time> X<date>
236
237 C<gmtime>, C<localtime>, C<time>, C<times>
238
239 =item Functions new in perl5
240 X<perl5>
241
242 C<abs>, C<bless>, C<break>, C<chomp>, C<chr>, C<continue>, C<default>, 
243 C<exists>, C<formline>, C<given>, C<glob>, C<import>, C<lc>, C<lcfirst>,
244 C<lock>, C<map>, C<my>, C<no>, C<our>, C<prototype>, C<qr//>, C<qw//>, C<qx//>,
245 C<readline>, C<readpipe>, C<ref>, C<sub>*, C<sysopen>, C<tie>, C<tied>, C<uc>,
246 C<ucfirst>, C<untie>, C<use>, C<when>
247
248 * C<sub> was a keyword in Perl 4, but in Perl 5 it is an
249 operator, which can be used in expressions.
250
251 =item Functions obsoleted in perl5
252
253 C<dbmclose>, C<dbmopen>
254
255 =back
256
257 =head2 Portability
258 X<portability> X<Unix> X<portable>
259
260 Perl was born in Unix and can therefore access all common Unix
261 system calls.  In non-Unix environments, the functionality of some
262 Unix system calls may not be available, or details of the available
263 functionality may differ slightly.  The Perl functions affected
264 by this are:
265
266 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
267 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
268 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
269 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
270 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
271 C<getppid>, C<getpgrp>, C<getpriority>, C<getprotobynumber>,
272 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
273 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
274 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
275 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
276 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
277 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
278 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
279 C<shmwrite>, C<socket>, C<socketpair>,
280 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
281 C<times>, C<truncate>, C<umask>, C<unlink>,
282 C<utime>, C<wait>, C<waitpid>
283
284 For more information about the portability of these functions, see
285 L<perlport> and other available platform-specific documentation.
286
287 =head2 Alphabetical Listing of Perl Functions
288
289 =over 
290
291 =item -X FILEHANDLE
292 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
293 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
294
295 =item -X EXPR
296
297 =item -X DIRHANDLE
298
299 =item -X
300
301 A file test, where X is one of the letters listed below.  This unary
302 operator takes one argument, either a filename, a filehandle, or a dirhandle, 
303 and tests the associated file to see if something is true about it.  If the
304 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
305 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
306 the undefined value if the file doesn't exist.  Despite the funny
307 names, precedence is the same as any other named unary operator.  The
308 operator may be any of:
309
310     -r  File is readable by effective uid/gid.
311     -w  File is writable by effective uid/gid.
312     -x  File is executable by effective uid/gid.
313     -o  File is owned by effective uid.
314
315     -R  File is readable by real uid/gid.
316     -W  File is writable by real uid/gid.
317     -X  File is executable by real uid/gid.
318     -O  File is owned by real uid.
319
320     -e  File exists.
321     -z  File has zero size (is empty).
322     -s  File has nonzero size (returns size in bytes).
323
324     -f  File is a plain file.
325     -d  File is a directory.
326     -l  File is a symbolic link.
327     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
328     -S  File is a socket.
329     -b  File is a block special file.
330     -c  File is a character special file.
331     -t  Filehandle is opened to a tty.
332
333     -u  File has setuid bit set.
334     -g  File has setgid bit set.
335     -k  File has sticky bit set.
336
337     -T  File is an ASCII text file (heuristic guess).
338     -B  File is a "binary" file (opposite of -T).
339
340     -M  Script start time minus file modification time, in days.
341     -A  Same for access time.
342     -C  Same for inode change time (Unix, may differ for other platforms)
343
344 Example:
345
346     while (<>) {
347         chomp;
348         next unless -f $_;  # ignore specials
349         #...
350     }
351
352 The interpretation of the file permission operators C<-r>, C<-R>,
353 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
354 of the file and the uids and gids of the user.  There may be other
355 reasons you can't actually read, write, or execute the file: for
356 example network filesystem access controls, ACLs (access control lists),
357 read-only filesystems, and unrecognized executable formats.  Note
358 that the use of these six specific operators to verify if some operation
359 is possible is usually a mistake, because it may be open to race
360 conditions.
361
362 Also note that, for the superuser on the local filesystems, the C<-r>,
363 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
364 if any execute bit is set in the mode.  Scripts run by the superuser
365 may thus need to do a stat() to determine the actual mode of the file,
366 or temporarily set their effective uid to something else.
367
368 If you are using ACLs, there is a pragma called C<filetest> that may
369 produce more accurate results than the bare stat() mode bits.
370 When under the C<use filetest 'access'> the above-mentioned filetests
371 test whether the permission can (not) be granted using the
372 access(2) family of system calls.  Also note that the C<-x> and C<-X> may
373 under this pragma return true even if there are no execute permission
374 bits set (nor any extra execute permission ACLs).  This strangeness is
375 due to the underlying system calls' definitions. Note also that, due to
376 the implementation of C<use filetest 'access'>, the C<_> special
377 filehandle won't cache the results of the file tests when this pragma is
378 in effect.  Read the documentation for the C<filetest> pragma for more
379 information.
380
381 Note that C<-s/a/b/> does not do a negated substitution.  Saying
382 C<-exp($foo)> still works as expected, however: only single letters
383 following a minus are interpreted as file tests.
384
385 The C<-T> and C<-B> switches work as follows.  The first block or so of the
386 file is examined for odd characters such as strange control codes or
387 characters with the high bit set.  If too many strange characters (>30%)
388 are found, it's a C<-B> file; otherwise it's a C<-T> file.  Also, any file
389 containing a zero byte in the first block is considered a binary file.  If C<-T>
390 or C<-B> is used on a filehandle, the current IO buffer is examined
391 rather than the first block.  Both C<-T> and C<-B> return true on an empty
392 file, or a file at EOF when testing a filehandle.  Because you have to
393 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
394 against the file first, as in C<next unless -f $file && -T $file>.
395
396 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
397 the special filehandle consisting of a solitary underline, then the stat
398 structure of the previous file test (or stat operator) is used, saving
399 a system call.  (This doesn't work with C<-t>, and you need to remember
400 that lstat() and C<-l> leave values in the stat structure for the
401 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
402 an C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
403 Example:
404
405     print "Can do.\n" if -r $a || -w _ || -x _;
406
407     stat($filename);
408     print "Readable\n" if -r _;
409     print "Writable\n" if -w _;
410     print "Executable\n" if -x _;
411     print "Setuid\n" if -u _;
412     print "Setgid\n" if -g _;
413     print "Sticky\n" if -k _;
414     print "Text\n" if -T _;
415     print "Binary\n" if -B _;
416
417 As of Perl 5.9.1, as a form of purely syntactic sugar, you can stack file
418 test operators, in a way that C<-f -w -x $file> is equivalent to
419 C<-x $file && -w _ && -f _>. (This is only fancy fancy: if you use
420 the return value of C<-f $file> as an argument to another filetest
421 operator, no special magic will happen.)
422
423 =item abs VALUE
424 X<abs> X<absolute>
425
426 =item abs
427
428 Returns the absolute value of its argument.
429 If VALUE is omitted, uses C<$_>.
430
431 =item accept NEWSOCKET,GENERICSOCKET
432 X<accept>
433
434 Accepts an incoming socket connect, just as accept(2) 
435 does.  Returns the packed address if it succeeded, false otherwise.
436 See the example in L<perlipc/"Sockets: Client/Server Communication">.
437
438 On systems that support a close-on-exec flag on files, the flag will
439 be set for the newly opened file descriptor, as determined by the
440 value of $^F.  See L<perlvar/$^F>.
441
442 =item alarm SECONDS
443 X<alarm>
444 X<SIGALRM>
445 X<timer>
446
447 =item alarm
448
449 Arranges to have a SIGALRM delivered to this process after the
450 specified number of wallclock seconds has elapsed.  If SECONDS is not
451 specified, the value stored in C<$_> is used. (On some machines,
452 unfortunately, the elapsed time may be up to one second less or more
453 than you specified because of how seconds are counted, and process
454 scheduling may delay the delivery of the signal even further.)
455
456 Only one timer may be counting at once.  Each call disables the
457 previous timer, and an argument of C<0> may be supplied to cancel the
458 previous timer without starting a new one.  The returned value is the
459 amount of time remaining on the previous timer.
460
461 For delays of finer granularity than one second, the Time::HiRes module
462 (from CPAN, and starting from Perl 5.8 part of the standard
463 distribution) provides ualarm().  You may also use Perl's four-argument
464 version of select() leaving the first three arguments undefined, or you
465 might be able to use the C<syscall> interface to access setitimer(2) if
466 your system supports it. See L<perlfaq8> for details.
467
468 It is usually a mistake to intermix C<alarm> and C<sleep> calls, because
469 C<sleep> may be internally implemented on your system with C<alarm>.
470
471 If you want to use C<alarm> to time out a system call you need to use an
472 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
473 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
474 restart system calls on some systems.  Using C<eval>/C<die> always works,
475 modulo the caveats given in L<perlipc/"Signals">.
476
477     eval {
478         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
479         alarm $timeout;
480         $nread = sysread SOCKET, $buffer, $size;
481         alarm 0;
482     };
483     if ($@) {
484         die unless $@ eq "alarm\n";   # propagate unexpected errors
485         # timed out
486     }
487     else {
488         # didn't
489     }
490
491 For more information see L<perlipc>.
492
493 =item atan2 Y,X
494 X<atan2> X<arctangent> X<tan> X<tangent>
495
496 Returns the arctangent of Y/X in the range -PI to PI.
497
498 For the tangent operation, you may use the C<Math::Trig::tan>
499 function, or use the familiar relation:
500
501     sub tan { sin($_[0]) / cos($_[0])  }
502
503 The return value for C<atan2(0,0)> is implementation-defined; consult
504 your atan2(3) manpage for more information.
505
506 =item bind SOCKET,NAME
507 X<bind>
508
509 Binds a network address to a socket, just as bind(2)
510 does.  Returns true if it succeeded, false otherwise.  NAME should be a
511 packed address of the appropriate type for the socket.  See the examples in
512 L<perlipc/"Sockets: Client/Server Communication">.
513
514 =item binmode FILEHANDLE, LAYER
515 X<binmode> X<binary> X<text> X<DOS> X<Windows>
516
517 =item binmode FILEHANDLE
518
519 Arranges for FILEHANDLE to be read or written in "binary" or "text"
520 mode on systems where the run-time libraries distinguish between
521 binary and text files.  If FILEHANDLE is an expression, the value is
522 taken as the name of the filehandle.  Returns true on success,
523 otherwise it returns C<undef> and sets C<$!> (errno).
524
525 On some systems (in general, DOS and Windows-based systems) binmode()
526 is necessary when you're not working with a text file.  For the sake
527 of portability it is a good idea to always use it when appropriate,
528 and to never use it when it isn't appropriate.  Also, people can
529 set their I/O to be by default UTF-8 encoded Unicode, not bytes.
530
531 In other words: regardless of platform, use binmode() on binary data,
532 like for example images.
533
534 If LAYER is present it is a single string, but may contain multiple
535 directives. The directives alter the behaviour of the filehandle.
536 When LAYER is present using binmode on a text file makes sense.
537
538 If LAYER is omitted or specified as C<:raw> the filehandle is made
539 suitable for passing binary data. This includes turning off possible CRLF
540 translation and marking it as bytes (as opposed to Unicode characters).
541 Note that, despite what may be implied in I<"Programming Perl"> (the
542 Camel, 3rd edition) or elsewhere, C<:raw> is I<not> simply the inverse of C<:crlf>.
543 Other layers that would affect the binary nature of the stream are
544 I<also> disabled. See L<PerlIO>, L<perlrun>, and the discussion about the
545 PERLIO environment variable.
546
547 The C<:bytes>, C<:crlf>, C<:utf8>, and any other directives of the
548 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
549 establish default I/O layers.  See L<open>.
550
551 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
552 in "Programming Perl, 3rd Edition".  However, since the publishing of this
553 book, by many known as "Camel III", the consensus of the naming of this
554 functionality has moved from "discipline" to "layer".  All documentation
555 of this version of Perl therefore refers to "layers" rather than to
556 "disciplines".  Now back to the regularly scheduled documentation...>
557
558 To mark FILEHANDLE as UTF-8, use C<:utf8> or C<:encoding(utf8)>.
559 C<:utf8> just marks the data as UTF-8 without further checking,
560 while C<:encoding(utf8)> checks the data for actually being valid
561 UTF-8. More details can be found in L<PerlIO::encoding>.
562
563 In general, binmode() should be called after open() but before any I/O
564 is done on the filehandle.  Calling binmode() normally flushes any
565 pending buffered output data (and perhaps pending input data) on the
566 handle.  An exception to this is the C<:encoding> layer that
567 changes the default character encoding of the handle, see L<open>.
568 The C<:encoding> layer sometimes needs to be called in
569 mid-stream, and it doesn't flush the stream.  The C<:encoding>
570 also implicitly pushes on top of itself the C<:utf8> layer because
571 internally Perl operates on UTF8-encoded Unicode characters.
572
573 The operating system, device drivers, C libraries, and Perl run-time
574 system all work together to let the programmer treat a single
575 character (C<\n>) as the line terminator, irrespective of the external
576 representation.  On many operating systems, the native text file
577 representation matches the internal representation, but on some
578 platforms the external representation of C<\n> is made up of more than
579 one character.
580
581 Mac OS, all variants of Unix, and Stream_LF files on VMS use a single
582 character to end each line in the external representation of text (even
583 though that single character is CARRIAGE RETURN on Mac OS and LINE FEED
584 on Unix and most VMS files). In other systems like OS/2, DOS and the
585 various flavors of MS-Windows your program sees a C<\n> as a simple C<\cJ>,
586 but what's stored in text files are the two characters C<\cM\cJ>.  That
587 means that, if you don't use binmode() on these systems, C<\cM\cJ>
588 sequences on disk will be converted to C<\n> on input, and any C<\n> in
589 your program will be converted back to C<\cM\cJ> on output.  This is what
590 you want for text files, but it can be disastrous for binary files.
591
592 Another consequence of using binmode() (on some systems) is that
593 special end-of-file markers will be seen as part of the data stream.
594 For systems from the Microsoft family this means that if your binary
595 data contains C<\cZ>, the I/O subsystem will regard it as the end of
596 the file, unless you use binmode().
597
598 binmode() is important not only for readline() and print() operations,
599 but also when using read(), seek(), sysread(), syswrite() and tell()
600 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
601 in L<perlvar> for how to manually set your input and output
602 line-termination sequences.
603
604 =item bless REF,CLASSNAME
605 X<bless>
606
607 =item bless REF
608
609 This function tells the thingy referenced by REF that it is now an object
610 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
611 is used.  Because a C<bless> is often the last thing in a constructor,
612 it returns the reference for convenience.  Always use the two-argument
613 version if a derived class might inherit the function doing the blessing.
614 See L<perltoot> and L<perlobj> for more about the blessing (and blessings)
615 of objects.
616
617 Consider always blessing objects in CLASSNAMEs that are mixed case.
618 Namespaces with all lowercase names are considered reserved for
619 Perl pragmata.  Builtin types have all uppercase names. To prevent
620 confusion, you may wish to avoid such package names as well.  Make sure
621 that CLASSNAME is a true value.
622
623 See L<perlmod/"Perl Modules">.
624
625 =item break
626
627 Break out of a C<given()> block.
628
629 This keyword is enabled by the C<"switch"> feature: see L<feature>
630 for more information.
631
632 =item caller EXPR
633 X<caller> X<call stack> X<stack> X<stack trace>
634
635 =item caller
636
637 Returns the context of the current subroutine call.  In scalar context,
638 returns the caller's package name if there I<is> a caller (that is, if
639 we're in a subroutine or C<eval> or C<require>) and the undefined value
640 otherwise.  In list context, returns
641
642     # 0         1          2
643     ($package, $filename, $line) = caller;
644
645 With EXPR, it returns some extra information that the debugger uses to
646 print a stack trace.  The value of EXPR indicates how many call frames
647 to go back before the current one.
648
649     #  0         1          2      3            4
650     ($package, $filename, $line, $subroutine, $hasargs,
651
652     #  5          6          7            8       9         10
653     $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash)
654      = caller($i);
655
656 Here $subroutine may be C<(eval)> if the frame is not a subroutine
657 call, but an C<eval>.  In such a case additional elements $evaltext and
658 C<$is_require> are set: C<$is_require> is true if the frame is created by a
659 C<require> or C<use> statement, $evaltext contains the text of the
660 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
661 $subroutine is C<(eval)>, but $evaltext is undefined.  (Note also that
662 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
663 frame.)  $subroutine may also be C<(unknown)> if this particular
664 subroutine happens to have been deleted from the symbol table.
665 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
666 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
667 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
668 between versions of Perl, and are not meant for external use.
669
670 C<$hinthash> is a reference to a hash containing the value of C<%^H> when the
671 caller was compiled, or C<undef> if C<%^H> was empty. Do not modify the values
672 of this hash, as they are the actual values stored in the optree.
673
674 Furthermore, when called from within the DB package, caller returns more
675 detailed information: it sets the list variable C<@DB::args> to be the
676 arguments with which the subroutine was invoked.
677
678 Be aware that the optimizer might have optimized call frames away before
679 C<caller> had a chance to get the information.  That means that C<caller(N)>
680 might not return information about the call frame you expect it to, for
681 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
682 previous time C<caller> was called.
683
684 Also be aware that setting C<@DB::args> is I<best effort>, intended for
685 debugging or generating backtraces, and should not be relied upon. In
686 particular, as C<@_> contains aliases to the caller's arguments, Perl does
687 not take a copy of C<@_>, so C<@DB::args> will contain modifications the
688 subroutine makes to C<@_> or its contents, not the original values at call
689 time. C<@DB::args>, like C<@_>, does not hold explicit references to its
690 elements, so under certain cases its elements may have become freed and
691 reallocated for other variables or temporary values. Finally, a side effect
692 of the current implementation means that the effects of C<shift @_> can
693 I<normally> be undone (but not C<pop @_> or other splicing, and not if a
694 reference to C<@_> has been taken, and subject to the caveat about reallocated
695 elements), so C<@DB::args> is actually a hybrid of the current state and
696 initial state of C<@_>. Buyer beware.
697
698 =item chdir EXPR
699 X<chdir>
700 X<cd>
701 X<directory, change>
702
703 =item chdir FILEHANDLE
704
705 =item chdir DIRHANDLE
706
707 =item chdir
708
709 Changes the working directory to EXPR, if possible. If EXPR is omitted,
710 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
711 changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the
712 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If
713 neither is set, C<chdir> does nothing. It returns true on success,
714 false otherwise. See the example under C<die>.
715
716 On systems that support fchdir(2), you may pass a filehandle or
717 directory handle as argument.  On systems that don't support fchdir(2),
718 passing handles raises an exception.
719
720 =item chmod LIST
721 X<chmod> X<permission> X<mode>
722
723 Changes the permissions of a list of files.  The first element of the
724 list must be the numerical mode, which should probably be an octal
725 number, and which definitely should I<not> be a string of octal digits:
726 C<0644> is okay, but C<"0644"> is not.  Returns the number of files
727 successfully changed.  See also L</oct>, if all you have is a string.
728
729     $cnt = chmod 0755, "foo", "bar";
730     chmod 0755, @executables;
731     $mode = "0644"; chmod $mode, "foo";      # !!! sets mode to
732                                              # --w----r-T
733     $mode = "0644"; chmod oct($mode), "foo"; # this is better
734     $mode = 0644;   chmod $mode, "foo";      # this is best
735
736 On systems that support fchmod(2), you may pass filehandles among the
737 files.  On systems that don't support fchmod(2), passing filehandles raises
738 an exception.  Filehandles must be passed as globs or glob references to be
739 recognized; barewords are considered filenames.
740
741     open(my $fh, "<", "foo");
742     my $perm = (stat $fh)[2] & 07777;
743     chmod($perm | 0600, $fh);
744
745 You can also import the symbolic C<S_I*> constants from the C<Fcntl>
746 module:
747
748     use Fcntl qw( :mode );
749     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
750     # Identical to the chmod 0755 of the example above.
751
752 =item chomp VARIABLE
753 X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol>
754
755 =item chomp( LIST )
756
757 =item chomp
758
759 This safer version of L</chop> removes any trailing string
760 that corresponds to the current value of C<$/> (also known as
761 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
762 number of characters removed from all its arguments.  It's often used to
763 remove the newline from the end of an input record when you're worried
764 that the final record may be missing its newline.  When in paragraph
765 mode (C<$/ = "">), it removes all trailing newlines from the string.
766 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
767 a reference to an integer or the like, see L<perlvar>) chomp() won't
768 remove anything.
769 If VARIABLE is omitted, it chomps C<$_>.  Example:
770
771     while (<>) {
772         chomp;  # avoid \n on last field
773         @array = split(/:/);
774         # ...
775     }
776
777 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
778
779 You can actually chomp anything that's an lvalue, including an assignment:
780
781     chomp($cwd = `pwd`);
782     chomp($answer = <STDIN>);
783
784 If you chomp a list, each element is chomped, and the total number of
785 characters removed is returned.
786
787 Note that parentheses are necessary when you're chomping anything
788 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
789 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
790 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
791 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
792 as C<chomp($a, $b)>.
793
794 =item chop VARIABLE
795 X<chop>
796
797 =item chop( LIST )
798
799 =item chop
800
801 Chops off the last character of a string and returns the character
802 chopped.  It is much more efficient than C<s/.$//s> because it neither
803 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
804 If VARIABLE is a hash, it chops the hash's values, but not its keys.
805
806 You can actually chop anything that's an lvalue, including an assignment.
807
808 If you chop a list, each element is chopped.  Only the value of the
809 last C<chop> is returned.
810
811 Note that C<chop> returns the last character.  To return all but the last
812 character, use C<substr($string, 0, -1)>.
813
814 See also L</chomp>.
815
816 =item chown LIST
817 X<chown> X<owner> X<user> X<group>
818
819 Changes the owner (and group) of a list of files.  The first two
820 elements of the list must be the I<numeric> uid and gid, in that
821 order.  A value of -1 in either position is interpreted by most
822 systems to leave that value unchanged.  Returns the number of files
823 successfully changed.
824
825     $cnt = chown $uid, $gid, 'foo', 'bar';
826     chown $uid, $gid, @filenames;
827
828 On systems that support fchown(2), you may pass filehandles among the
829 files.  On systems that don't support fchown(2), passing filehandles raises
830 an exception.  Filehandles must be passed as globs or glob references to be
831 recognized; barewords are considered filenames.
832
833 Here's an example that looks up nonnumeric uids in the passwd file:
834
835     print "User: ";
836     chomp($user = <STDIN>);
837     print "Files: ";
838     chomp($pattern = <STDIN>);
839
840     ($login,$pass,$uid,$gid) = getpwnam($user)
841         or die "$user not in passwd file";
842
843     @ary = glob($pattern);  # expand filenames
844     chown $uid, $gid, @ary;
845
846 On most systems, you are not allowed to change the ownership of the
847 file unless you're the superuser, although you should be able to change
848 the group to any of your secondary groups.  On insecure systems, these
849 restrictions may be relaxed, but this is not a portable assumption.
850 On POSIX systems, you can detect this condition this way:
851
852     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
853     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
854
855 =item chr NUMBER
856 X<chr> X<character> X<ASCII> X<Unicode>
857
858 =item chr
859
860 Returns the character represented by that NUMBER in the character set.
861 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
862 chr(0x263a) is a Unicode smiley face.  
863
864 Negative values give the Unicode replacement character (chr(0xfffd)),
865 except under the L<bytes> pragma, where the low eight bits of the value
866 (truncated to an integer) are used.
867
868 If NUMBER is omitted, uses C<$_>.
869
870 For the reverse, use L</ord>.
871
872 Note that characters from 128 to 255 (inclusive) are by default
873 internally not encoded as UTF-8 for backward compatibility reasons.
874
875 See L<perlunicode> for more about Unicode.
876
877 =item chroot FILENAME
878 X<chroot> X<root>
879
880 =item chroot
881
882 This function works like the system call by the same name: it makes the
883 named directory the new root directory for all further pathnames that
884 begin with a C</> by your process and all its children.  (It doesn't
885 change your current working directory, which is unaffected.)  For security
886 reasons, this call is restricted to the superuser.  If FILENAME is
887 omitted, does a C<chroot> to C<$_>.
888
889 =item close FILEHANDLE
890 X<close>
891
892 =item close
893
894 Closes the file or pipe associated with the filehandle, flushes the IO
895 buffers, and closes the system file descriptor.  Returns true if those
896 operations have succeeded and if no error was reported by any PerlIO
897 layer.  Closes the currently selected filehandle if the argument is
898 omitted.
899
900 You don't have to close FILEHANDLE if you are immediately going to do
901 another C<open> on it, because C<open> closes it for you.  (See
902 C<open>.)  However, an explicit C<close> on an input file resets the line
903 counter (C<$.>), while the implicit close done by C<open> does not.
904
905 If the filehandle came from a piped open, C<close> returns false if one of
906 the other syscalls involved fails or if its program exits with non-zero
907 status.  If the only problem was that the program exited non-zero, C<$!>
908 will be set to C<0>.  Closing a pipe also waits for the process executing
909 on the pipe to exit--in case you wish to look at the output of the pipe
910 afterwards--and implicitly puts the exit status value of that command into
911 C<$?> and C<${^CHILD_ERROR_NATIVE}>.
912
913 Closing the read end of a pipe before the process writing to it at the
914 other end is done writing results in the writer receiving a SIGPIPE.  If
915 the other end can't handle that, be sure to read all the data before
916 closing the pipe.
917
918 Example:
919
920     open(OUTPUT, '|sort >foo')  # pipe to sort
921         or die "Can't start sort: $!";
922     #...                        # print stuff to output
923     close OUTPUT                # wait for sort to finish
924         or warn $! ? "Error closing sort pipe: $!"
925                    : "Exit status $? from sort";
926     open(INPUT, 'foo')          # get sort's results
927         or die "Can't open 'foo' for input: $!";
928
929 FILEHANDLE may be an expression whose value can be used as an indirect
930 filehandle, usually the real filehandle name.
931
932 =item closedir DIRHANDLE
933 X<closedir>
934
935 Closes a directory opened by C<opendir> and returns the success of that
936 system call.
937
938 =item connect SOCKET,NAME
939 X<connect>
940
941 Attempts to connect to a remote socket, just like connect(2).
942 Returns true if it succeeded, false otherwise.  NAME should be a
943 packed address of the appropriate type for the socket.  See the examples in
944 L<perlipc/"Sockets: Client/Server Communication">.
945
946 =item continue BLOCK
947 X<continue>
948
949 =item continue
950
951 C<continue> is actually a flow control statement rather than a function.  If
952 there is a C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
953 C<foreach>), it is always executed just before the conditional is about to
954 be evaluated again, just like the third part of a C<for> loop in C.  Thus
955 it can be used to increment a loop variable, even when the loop has been
956 continued via the C<next> statement (which is similar to the C C<continue>
957 statement).
958
959 C<last>, C<next>, or C<redo> may appear within a C<continue>
960 block; C<last> and C<redo> behave as if they had been executed within
961 the main block.  So will C<next>, but since it will execute a C<continue>
962 block, it may be more entertaining.
963
964     while (EXPR) {
965         ### redo always comes here
966         do_something;
967     } continue {
968         ### next always comes here
969         do_something_else;
970         # then back the top to re-check EXPR
971     }
972     ### last always comes here
973
974 Omitting the C<continue> section is equivalent to using an
975 empty one, logically enough, so C<next> goes directly back
976 to check the condition at the top of the loop.
977
978 If the C<"switch"> feature is enabled, C<continue> is also a
979 function that exits the current C<when> (or C<default>) block and
980 falls through to the next one.  See L<feature> and
981 L<perlsyn/"Switch statements"> for more information.
982
983
984 =item cos EXPR
985 X<cos> X<cosine> X<acos> X<arccosine>
986
987 =item cos
988
989 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
990 takes cosine of C<$_>.
991
992 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
993 function, or use this relation:
994
995     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
996
997 =item crypt PLAINTEXT,SALT
998 X<crypt> X<digest> X<hash> X<salt> X<plaintext> X<password>
999 X<decrypt> X<cryptography> X<passwd> X<encrypt>
1000
1001 Creates a digest string exactly like the crypt(3) function in the C
1002 library (assuming that you actually have a version there that has not
1003 been extirpated as a potential munition).
1004
1005 crypt() is a one-way hash function.  The PLAINTEXT and SALT is turned
1006 into a short string, called a digest, which is returned.  The same
1007 PLAINTEXT and SALT will always return the same string, but there is no
1008 (known) way to get the original PLAINTEXT from the hash.  Small
1009 changes in the PLAINTEXT or SALT will result in large changes in the
1010 digest.
1011
1012 There is no decrypt function.  This function isn't all that useful for
1013 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
1014 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
1015 primarily used to check if two pieces of text are the same without
1016 having to transmit or store the text itself.  An example is checking
1017 if a correct password is given.  The digest of the password is stored,
1018 not the password itself.  The user types in a password that is
1019 crypt()'d with the same salt as the stored digest.  If the two digests
1020 match the password is correct.
1021
1022 When verifying an existing digest string you should use the digest as
1023 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
1024 to create the digest is visible as part of the digest.  This ensures
1025 crypt() will hash the new string with the same salt as the digest.
1026 This allows your code to work with the standard L<crypt|/crypt> and
1027 with more exotic implementations.  In other words, do not assume
1028 anything about the returned string itself, or how many bytes in the
1029 digest matter.
1030
1031 Traditionally the result is a string of 13 bytes: two first bytes of
1032 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
1033 the first eight bytes of PLAINTEXT mattered. But alternative
1034 hashing schemes (like MD5), higher level security schemes (like C2),
1035 and implementations on non-Unix platforms may produce different
1036 strings.
1037
1038 When choosing a new salt create a random two character string whose
1039 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
1040 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
1041 characters is just a recommendation; the characters allowed in
1042 the salt depend solely on your system's crypt library, and Perl can't
1043 restrict what salts C<crypt()> accepts.
1044
1045 Here's an example that makes sure that whoever runs this program knows
1046 their password:
1047
1048     $pwd = (getpwuid($<))[1];
1049
1050     system "stty -echo";
1051     print "Password: ";
1052     chomp($word = <STDIN>);
1053     print "\n";
1054     system "stty echo";
1055
1056     if (crypt($word, $pwd) ne $pwd) {
1057         die "Sorry...\n";
1058     } else {
1059         print "ok\n";
1060     }
1061
1062 Of course, typing in your own password to whoever asks you
1063 for it is unwise.
1064
1065 The L<crypt|/crypt> function is unsuitable for hashing large quantities
1066 of data, not least of all because you can't get the information
1067 back.  Look at the L<Digest> module for more robust algorithms.
1068
1069 If using crypt() on a Unicode string (which I<potentially> has
1070 characters with codepoints above 255), Perl tries to make sense
1071 of the situation by trying to downgrade (a copy of the string)
1072 the string back to an eight-bit byte string before calling crypt()
1073 (on that copy).  If that works, good.  If not, crypt() dies with
1074 C<Wide character in crypt>.
1075
1076 =item dbmclose HASH
1077 X<dbmclose>
1078
1079 [This function has been largely superseded by the C<untie> function.]
1080
1081 Breaks the binding between a DBM file and a hash.
1082
1083 =item dbmopen HASH,DBNAME,MASK
1084 X<dbmopen> X<dbm> X<ndbm> X<sdbm> X<gdbm>
1085
1086 [This function has been largely superseded by the C<tie> function.]
1087
1088 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
1089 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
1090 argument is I<not> a filehandle, even though it looks like one).  DBNAME
1091 is the name of the database (without the F<.dir> or F<.pag> extension if
1092 any).  If the database does not exist, it is created with protection
1093 specified by MASK (as modified by the C<umask>).  If your system supports
1094 only the older DBM functions, you may make only one C<dbmopen> call in your
1095 program.  In older versions of Perl, if your system had neither DBM nor
1096 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
1097 sdbm(3).
1098
1099 If you don't have write access to the DBM file, you can only read hash
1100 variables, not set them.  If you want to test whether you can write,
1101 either use file tests or try setting a dummy hash entry inside an C<eval> 
1102 to trap the error.
1103
1104 Note that functions such as C<keys> and C<values> may return huge lists
1105 when used on large DBM files.  You may prefer to use the C<each>
1106 function to iterate over large DBM files.  Example:
1107
1108     # print out history file offsets
1109     dbmopen(%HIST,'/usr/lib/news/history',0666);
1110     while (($key,$val) = each %HIST) {
1111         print $key, ' = ', unpack('L',$val), "\n";
1112     }
1113     dbmclose(%HIST);
1114
1115 See also L<AnyDBM_File> for a more general description of the pros and
1116 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1117 rich implementation.
1118
1119 You can control which DBM library you use by loading that library
1120 before you call dbmopen():
1121
1122     use DB_File;
1123     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1124         or die "Can't open netscape history file: $!";
1125
1126 =item defined EXPR
1127 X<defined> X<undef> X<undefined>
1128
1129 =item defined
1130
1131 Returns a Boolean value telling whether EXPR has a value other than
1132 the undefined value C<undef>.  If EXPR is not present, C<$_> is
1133 checked.
1134
1135 Many operations return C<undef> to indicate failure, end of file,
1136 system error, uninitialized variable, and other exceptional
1137 conditions.  This function allows you to distinguish C<undef> from
1138 other values.  (A simple Boolean test will not distinguish among
1139 C<undef>, zero, the empty string, and C<"0">, which are all equally
1140 false.)  Note that since C<undef> is a valid scalar, its presence
1141 doesn't I<necessarily> indicate an exceptional condition: C<pop>
1142 returns C<undef> when its argument is an empty array, I<or> when the
1143 element to return happens to be C<undef>.
1144
1145 You may also use C<defined(&func)> to check whether subroutine C<&func>
1146 has ever been defined.  The return value is unaffected by any forward
1147 declarations of C<&func>.  A subroutine that is not defined
1148 may still be callable: its package may have an C<AUTOLOAD> method that
1149 makes it spring into existence the first time that it is called; see
1150 L<perlsub>.
1151
1152 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1153 used to report whether memory for that aggregate has ever been
1154 allocated.  This behavior may disappear in future versions of Perl.
1155 You should instead use a simple test for size:
1156
1157     if (@an_array) { print "has array elements\n" }
1158     if (%a_hash)   { print "has hash members\n"   }
1159
1160 When used on a hash element, it tells you whether the value is defined,
1161 not whether the key exists in the hash.  Use L</exists> for the latter
1162 purpose.
1163
1164 Examples:
1165
1166     print if defined $switch{'D'};
1167     print "$val\n" while defined($val = pop(@ary));
1168     die "Can't readlink $sym: $!"
1169         unless defined($value = readlink $sym);
1170     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1171     $debugging = 0 unless defined $debugging;
1172
1173 Note:  Many folks tend to overuse C<defined>, and then are surprised to
1174 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1175 defined values.  For example, if you say
1176
1177     "ab" =~ /a(.*)b/;
1178
1179 The pattern match succeeds and C<$1> is defined, although it
1180 matched "nothing".  It didn't really fail to match anything.  Rather, it
1181 matched something that happened to be zero characters long.  This is all
1182 very above-board and honest.  When a function returns an undefined value,
1183 it's an admission that it couldn't give you an honest answer.  So you
1184 should use C<defined> only when questioning the integrity of what
1185 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1186 what you want.
1187
1188 See also L</undef>, L</exists>, L</ref>.
1189
1190 =item delete EXPR
1191 X<delete>
1192
1193 Given an expression that specifies an element or slice of a hash, C<delete>
1194 deletes the specified elements from that hash so that exists() on that element
1195 no longer returns true.  Setting a hash element to the undefined value does
1196 not remove its key, but deleting it does; see L</exists>.
1197
1198 It returns the value or values deleted in list context, or the last such
1199 element in scalar context.  The return list's length always matches that of
1200 the argument list: deleting non-existent elements returns the undefined value
1201 in their corresponding positions.
1202
1203 delete() may also be used on arrays and array slices, but its behavior is less
1204 straightforward.  Although exists() will return false for deleted entries,
1205 deleting array elements never changes indices of existing values; use shift()
1206 or splice() for that.  However, if all deleted elements fall at the end of an
1207 array, the array's size shrinks to the position of the highest element that
1208 still tests true for exists(), or to 0 if none do.
1209
1210 B<Be aware> that calling delete on array values is deprecated and likely to
1211 be removed in a future version of Perl.
1212
1213 Deleting from C<%ENV> modifies the environment.  Deleting from a hash tied to
1214 a DBM file deletes the entry from the DBM file.  Deleting from a C<tied> hash
1215 or array may not necessarily return anything; it depends on the implementation
1216 of the C<tied> package's DELETE method, which may do whatever it pleases.
1217
1218 The C<delete local EXPR> construct localizes the deletion to the current
1219 block at run time.  Until the block exits, elements locally deleted
1220 temporarily no longer exist.  See L<perlsub/"Localized deletion of elements
1221 of composite types">.
1222
1223     %hash = (foo => 11, bar => 22, baz => 33);
1224     $scalar = delete $hash{foo};             # $scalar is 11
1225     $scalar = delete @hash{qw(foo bar)};     # $scalar is 22
1226     @array  = delete @hash{qw(foo bar baz)}; # @array  is (undef,undef,33)
1227
1228 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1229
1230     foreach $key (keys %HASH) {
1231         delete $HASH{$key};
1232     }
1233
1234     foreach $index (0 .. $#ARRAY) {
1235         delete $ARRAY[$index];
1236     }
1237
1238 And so do these:
1239
1240     delete @HASH{keys %HASH};
1241
1242     delete @ARRAY[0 .. $#ARRAY];
1243
1244 But both are slower than assigning the empty list
1245 or undefining %HASH or @ARRAY, which is the customary 
1246 way to empty out an aggregate:
1247
1248     %HASH = ();     # completely empty %HASH
1249     undef %HASH;    # forget %HASH ever existed
1250
1251     @ARRAY = ();    # completely empty @ARRAY
1252     undef @ARRAY;   # forget @ARRAY ever existed
1253
1254 The EXPR can be arbitrarily complicated provided its
1255 final operation is an element or slice of an aggregate:
1256
1257     delete $ref->[$x][$y]{$key};
1258     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1259
1260     delete $ref->[$x][$y][$index];
1261     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1262
1263 =item die LIST
1264 X<die> X<throw> X<exception> X<raise> X<$@> X<abort>
1265
1266 Outside an C<eval>, prints the value of LIST to C<STDERR> and
1267 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
1268 exits with the value of C<<< ($? >> 8) >>> (backtick `command`
1269 status).  If C<<< ($? >> 8) >>> is C<0>, exits with C<255>.  Inside
1270 an C<eval(),> the error message is stuffed into C<$@> and the
1271 C<eval> is terminated with the undefined value.  This makes
1272 C<die> the way to raise an exception.
1273
1274 Equivalent examples:
1275
1276     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1277     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1278
1279 If the last element of LIST does not end in a newline, the current
1280 script line number and input line number (if any) are also printed,
1281 and a newline is supplied.  Note that the "input line number" (also
1282 known as "chunk") is subject to whatever notion of "line" happens to
1283 be currently in effect, and is also available as the special variable
1284 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1285
1286 Hint: sometimes appending C<", stopped"> to your message will cause it
1287 to make better sense when the string C<"at foo line 123"> is appended.
1288 Suppose you are running script "canasta".
1289
1290     die "/etc/games is no good";
1291     die "/etc/games is no good, stopped";
1292
1293 produce, respectively
1294
1295     /etc/games is no good at canasta line 123.
1296     /etc/games is no good, stopped at canasta line 123.
1297
1298 See also exit(), warn(), and the Carp module.
1299
1300 If the output is empty and C<$@> already contains a value (typically from a
1301 previous eval) that value is reused after appending C<"\t...propagated">.
1302 This is useful for propagating exceptions:
1303
1304     eval { ... };
1305     die unless $@ =~ /Expected exception/;
1306
1307 If the output is empty and C<$@> contains an object reference that has a
1308 C<PROPAGATE> method, that method will be called with additional file
1309 and line number parameters.  The return value replaces the value in
1310 C<$@>.  i.e., as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1311 were called.
1312
1313 If C<$@> is empty then the string C<"Died"> is used.
1314
1315 You can also call C<die> with a reference argument, and if this is trapped
1316 within an C<eval>, C<$@> contains that reference.  This permits more
1317 elaborate exception handling using objects that maintain arbitrary state
1318 about the exception.  Such a scheme is sometimes preferable to matching
1319 particular string values of C<$@> with regular expressions.  Because C<$@> 
1320 is a global variable and C<eval> may be used within object implementations,
1321 be careful that analyzing the error object doesn't replace the reference in
1322 the global variable.  It's easiest to make a local copy of the reference
1323 before any manipulations.  Here's an example:
1324
1325     use Scalar::Util "blessed";
1326
1327     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1328     if (my $ev_err = $@) {
1329         if (blessed($ev_err) && $ev_err->isa("Some::Module::Exception")) {
1330             # handle Some::Module::Exception
1331         }
1332         else {
1333             # handle all other possible exceptions
1334         }
1335     }
1336
1337 Because Perl stringifies uncaught exception messages before display,
1338 you'll probably want to overload stringification operations on
1339 exception objects.  See L<overload> for details about that.
1340
1341 You can arrange for a callback to be run just before the C<die>
1342 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1343 handler is called with the error text and can change the error
1344 message, if it sees fit, by calling C<die> again.  See
1345 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1346 L<"eval BLOCK"> for some examples.  Although this feature was 
1347 to be run only right before your program was to exit, this is not
1348 currently so: the C<$SIG{__DIE__}> hook is currently called
1349 even inside eval()ed blocks/strings!  If one wants the hook to do
1350 nothing in such situations, put
1351
1352     die @_ if $^S;
1353
1354 as the first line of the handler (see L<perlvar/$^S>).  Because
1355 this promotes strange action at a distance, this counterintuitive
1356 behavior may be fixed in a future release.
1357
1358 =item do BLOCK
1359 X<do> X<block>
1360
1361 Not really a function.  Returns the value of the last command in the
1362 sequence of commands indicated by BLOCK.  When modified by the C<while> or
1363 C<until> loop modifier, executes the BLOCK once before testing the loop
1364 condition. (On other statements the loop modifiers test the conditional
1365 first.)
1366
1367 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1368 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1369 See L<perlsyn> for alternative strategies.
1370
1371 =item do SUBROUTINE(LIST)
1372 X<do>
1373
1374 This form of subroutine call is deprecated.  See L<perlsub>.
1375
1376 =item do EXPR
1377 X<do>
1378
1379 Uses the value of EXPR as a filename and executes the contents of the
1380 file as a Perl script.
1381
1382     do 'stat.pl';
1383
1384 is just like
1385
1386     eval `cat stat.pl`;
1387
1388 except that it's more efficient and concise, keeps track of the current
1389 filename for error messages, searches the @INC directories, and updates
1390 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1391 variables.  It also differs in that code evaluated with C<do FILENAME>
1392 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1393 same, however, in that it does reparse the file every time you call it,
1394 so you probably don't want to do this inside a loop.
1395
1396 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1397 error.  If C<do> can read the file but cannot compile it, it
1398 returns undef and sets an error message in C<$@>.   If the file is
1399 successfully compiled, C<do> returns the value of the last expression
1400 evaluated.
1401
1402 Inclusion of library modules is better done with the
1403 C<use> and C<require> operators, which also do automatic error checking
1404 and raise an exception if there's a problem.
1405
1406 You might like to use C<do> to read in a program configuration
1407 file.  Manual error checking can be done this way:
1408
1409     # read in config files: system first, then user
1410     for $file ("/share/prog/defaults.rc",
1411                "$ENV{HOME}/.someprogrc")
1412     {
1413         unless ($return = do $file) {
1414             warn "couldn't parse $file: $@" if $@;
1415             warn "couldn't do $file: $!"    unless defined $return;
1416             warn "couldn't run $file"       unless $return;
1417         }
1418     }
1419
1420 =item dump LABEL
1421 X<dump> X<core> X<undump>
1422
1423 =item dump
1424
1425 This function causes an immediate core dump.  See also the B<-u>
1426 command-line switch in L<perlrun>, which does the same thing.
1427 Primarily this is so that you can use the B<undump> program (not
1428 supplied) to turn your core dump into an executable binary after
1429 having initialized all your variables at the beginning of the
1430 program.  When the new binary is executed it will begin by executing
1431 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1432 Think of it as a goto with an intervening core dump and reincarnation.
1433 If C<LABEL> is omitted, restarts the program from the top.
1434
1435 B<WARNING>: Any files opened at the time of the dump will I<not>
1436 be open any more when the program is reincarnated, with possible
1437 resulting confusion by Perl.
1438
1439 This function is now largely obsolete, mostly because it's very hard to
1440 convert a core file into an executable. That's why you should now invoke
1441 it as C<CORE::dump()>, if you don't want to be warned against a possible
1442 typo.
1443
1444 =item each HASH
1445 X<each> X<hash, iterator>
1446
1447 =item each ARRAY
1448 X<array, iterator>
1449
1450 When called in list context, returns a 2-element list consisting of the key
1451 and value for the next element of a hash, or the index and value for the
1452 next element of an array, so that you can iterate over it.  When called in
1453 scalar context, returns only the key (not the value) in a hash, or the index
1454 in an array.
1455
1456 Hash entries are returned in an apparently random order.  The actual random
1457 order is subject to change in future versions of Perl, but it is
1458 guaranteed to be in the same order as either the C<keys> or C<values>
1459 function would produce on the same (unmodified) hash.  Since Perl
1460 5.8.2 the ordering can be different even between different runs of Perl
1461 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1462
1463 After C<each> has returned all entries from the hash or array, the next
1464 call to C<each> returns the empty list in list context and C<undef> in
1465 scalar context.  The next call following that one restarts iteration.  Each
1466 hash or array has its own internal iterator, accessed by C<each>, C<keys>,
1467 and C<values>.  The iterator is implicitly reset when C<each> has reached
1468 the end as just described; it can be explicitly reset by calling C<keys> or
1469 C<values> on the hash or array.  If you add or delete a hash's elements
1470 while iterating over it, entries may be skipped or duplicated--so don't do
1471 that.  Exception: It is always safe to delete the item most recently
1472 returned by C<each()>, so the following code works properly:
1473
1474         while (($key, $value) = each %hash) {
1475           print $key, "\n";
1476           delete $hash{$key};   # This is safe
1477         }
1478
1479 This prints out your environment like the printenv(1) program,
1480 but in a different order:
1481
1482     while (($key,$value) = each %ENV) {
1483         print "$key=$value\n";
1484     }
1485
1486 See also C<keys>, C<values> and C<sort>.
1487
1488 =item eof FILEHANDLE
1489 X<eof>
1490 X<end of file>
1491 X<end-of-file>
1492
1493 =item eof ()
1494
1495 =item eof
1496
1497 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1498 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1499 gives the real filehandle.  (Note that this function actually
1500 reads a character and then C<ungetc>s it, so isn't useful in an
1501 interactive context.)  Do not read from a terminal file (or call
1502 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1503 as terminals may lose the end-of-file condition if you do.
1504
1505 An C<eof> without an argument uses the last file read.  Using C<eof()>
1506 with empty parentheses is different.  It refers to the pseudo file
1507 formed from the files listed on the command line and accessed via the
1508 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1509 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1510 used will cause C<@ARGV> to be examined to determine if input is
1511 available.   Similarly, an C<eof()> after C<< <> >> has returned
1512 end-of-file will assume you are processing another C<@ARGV> list,
1513 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1514 see L<perlop/"I/O Operators">.
1515
1516 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1517 detect the end of each file, C<eof()> will detect the end of only the
1518 last file.  Examples:
1519
1520     # reset line numbering on each input file
1521     while (<>) {
1522         next if /^\s*#/;  # skip comments
1523         print "$.\t$_";
1524     } continue {
1525         close ARGV if eof;  # Not eof()!
1526     }
1527
1528     # insert dashes just before last line of last file
1529     while (<>) {
1530         if (eof()) {  # check for end of last file
1531             print "--------------\n";
1532         }
1533         print;
1534         last if eof();          # needed if we're reading from a terminal
1535     }
1536
1537 Practical hint: you almost never need to use C<eof> in Perl, because the
1538 input operators typically return C<undef> when they run out of data, or if
1539 there was an error.
1540
1541 =item eval EXPR
1542 X<eval> X<try> X<catch> X<evaluate> X<parse> X<execute>
1543 X<error, handling> X<exception, handling>
1544
1545 =item eval BLOCK
1546
1547 =item eval
1548
1549 In the first form, the return value of EXPR is parsed and executed as if it
1550 were a little Perl program.  The value of the expression (which is itself
1551 determined within scalar context) is first parsed, and if there weren't any
1552 errors, executed in the lexical context of the current Perl program, so
1553 that any variable settings or subroutine and format definitions remain
1554 afterwards.  Note that the value is parsed every time the C<eval> executes.
1555 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1556 delay parsing and subsequent execution of the text of EXPR until run time.
1557
1558 In the second form, the code within the BLOCK is parsed only once--at the
1559 same time the code surrounding the C<eval> itself was parsed--and executed
1560 within the context of the current Perl program.  This form is typically
1561 used to trap exceptions more efficiently than the first (see below), while
1562 also providing the benefit of checking the code within BLOCK at compile
1563 time.
1564
1565 The final semicolon, if any, may be omitted from the value of EXPR or within
1566 the BLOCK.
1567
1568 In both forms, the value returned is the value of the last expression
1569 evaluated inside the mini-program; a return statement may be also used, just
1570 as with subroutines.  The expression providing the return value is evaluated
1571 in void, scalar, or list context, depending on the context of the C<eval> 
1572 itself.  See L</wantarray> for more on how the evaluation context can be 
1573 determined.
1574
1575 If there is a syntax error or runtime error, or a C<die> statement is
1576 executed, C<eval> returns an undefined value in scalar context
1577 or an empty list in list context, and C<$@> is set to the
1578 error message.  If there was no error, C<$@> is guaranteed to be the empty
1579 string.  Beware that using C<eval> neither silences Perl from printing
1580 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1581 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1582 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1583 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1584
1585 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1586 determining whether a particular feature (such as C<socket> or C<symlink>)
1587 is implemented.  It is also Perl's exception trapping mechanism, where
1588 the die operator is used to raise exceptions.
1589
1590 If you want to trap errors when loading an XS module, some problems with
1591 the binary interface (such as Perl version skew) may be fatal even with
1592 C<eval> unless C<$ENV{PERL_DL_NONLAZY}> is set. See L<perlrun>.
1593
1594 If the code to be executed doesn't vary, you may use the eval-BLOCK
1595 form to trap run-time errors without incurring the penalty of
1596 recompiling each time.  The error, if any, is still returned in C<$@>.
1597 Examples:
1598
1599     # make divide-by-zero nonfatal
1600     eval { $answer = $a / $b; }; warn $@ if $@;
1601
1602     # same thing, but less efficient
1603     eval '$answer = $a / $b'; warn $@ if $@;
1604
1605     # a compile-time error
1606     eval { $answer = }; # WRONG
1607
1608     # a run-time error
1609     eval '$answer =';   # sets $@
1610
1611 Using the C<eval{}> form as an exception trap in libraries does have some
1612 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
1613 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
1614 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1615 as this example shows:
1616
1617     # a private exception trap for divide-by-zero
1618     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1619     warn $@ if $@;
1620
1621 This is especially significant, given that C<__DIE__> hooks can call
1622 C<die> again, which has the effect of changing their error messages:
1623
1624     # __DIE__ hooks may modify error messages
1625     {
1626        local $SIG{'__DIE__'} =
1627               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1628        eval { die "foo lives here" };
1629        print $@ if $@;                # prints "bar lives here"
1630     }
1631
1632 Because this promotes action at a distance, this counterintuitive behavior
1633 may be fixed in a future release.
1634
1635 With an C<eval>, you should be especially careful to remember what's
1636 being looked at when:
1637
1638     eval $x;        # CASE 1
1639     eval "$x";      # CASE 2
1640
1641     eval '$x';      # CASE 3
1642     eval { $x };    # CASE 4
1643
1644     eval "\$$x++";  # CASE 5
1645     $$x++;          # CASE 6
1646
1647 Cases 1 and 2 above behave identically: they run the code contained in
1648 the variable $x.  (Although case 2 has misleading double quotes making
1649 the reader wonder what else might be happening (nothing is).)  Cases 3
1650 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1651 does nothing but return the value of $x.  (Case 4 is preferred for
1652 purely visual reasons, but it also has the advantage of compiling at
1653 compile-time instead of at run-time.)  Case 5 is a place where
1654 normally you I<would> like to use double quotes, except that in this
1655 particular situation, you can just use symbolic references instead, as
1656 in case 6.
1657
1658 The assignment to C<$@> occurs before restoration of localised variables,
1659 which means a temporary is required if you want to mask some but not all
1660 errors:
1661
1662     # alter $@ on nefarious repugnancy only
1663     {
1664        my $e;
1665        {
1666           local $@; # protect existing $@
1667           eval { test_repugnancy() };
1668           # $@ =~ /nefarious/ and die $@; # DOES NOT WORK
1669           $@ =~ /nefarious/ and $e = $@;
1670        }
1671        die $e if defined $e
1672     }
1673
1674 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1675 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1676
1677 An C<eval ''> executed within the C<DB> package doesn't see the usual
1678 surrounding lexical scope, but rather the scope of the first non-DB piece
1679 of code that called it. You don't normally need to worry about this unless
1680 you are writing a Perl debugger.
1681
1682 =item exec LIST
1683 X<exec> X<execute>
1684
1685 =item exec PROGRAM LIST
1686
1687 The C<exec> function executes a system command I<and never returns>;
1688 use C<system> instead of C<exec> if you want it to return.  It fails and
1689 returns false only if the command does not exist I<and> it is executed
1690 directly instead of via your system's command shell (see below).
1691
1692 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1693 warns you if there is a following statement that isn't C<die>, C<warn>,
1694 or C<exit> (if C<-w> is set--but you always do that, right?).   If you
1695 I<really> want to follow an C<exec> with some other statement, you
1696 can use one of these styles to avoid the warning:
1697
1698     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1699     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1700
1701 If there is more than one argument in LIST, or if LIST is an array
1702 with more than one value, calls execvp(3) with the arguments in LIST.
1703 If there is only one scalar argument or an array with one element in it,
1704 the argument is checked for shell metacharacters, and if there are any,
1705 the entire argument is passed to the system's command shell for parsing
1706 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1707 If there are no shell metacharacters in the argument, it is split into
1708 words and passed directly to C<execvp>, which is more efficient.
1709 Examples:
1710
1711     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1712     exec "sort $outfile | uniq";
1713
1714 If you don't really want to execute the first argument, but want to lie
1715 to the program you are executing about its own name, you can specify
1716 the program you actually want to run as an "indirect object" (without a
1717 comma) in front of the LIST.  (This always forces interpretation of the
1718 LIST as a multivalued list, even if there is only a single scalar in
1719 the list.)  Example:
1720
1721     $shell = '/bin/csh';
1722     exec $shell '-sh';    # pretend it's a login shell
1723
1724 or, more directly,
1725
1726     exec {'/bin/csh'} '-sh';  # pretend it's a login shell
1727
1728 When the arguments get executed via the system shell, results are
1729 subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1730 for details.
1731
1732 Using an indirect object with C<exec> or C<system> is also more
1733 secure.  This usage (which also works fine with system()) forces
1734 interpretation of the arguments as a multivalued list, even if the
1735 list had just one argument.  That way you're safe from the shell
1736 expanding wildcards or splitting up words with whitespace in them.
1737
1738     @args = ( "echo surprise" );
1739
1740     exec @args;               # subject to shell escapes
1741                                 # if @args == 1
1742     exec { $args[0] } @args;  # safe even with one-arg list
1743
1744 The first version, the one without the indirect object, ran the I<echo>
1745 program, passing it C<"surprise"> an argument.  The second version didn't;
1746 it tried to run a program named I<"echo surprise">, didn't find it, and set
1747 C<$?> to a non-zero value indicating failure.
1748
1749 Beginning with v5.6.0, Perl attempts to flush all files opened for
1750 output before the exec, but this may not be supported on some platforms
1751 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1752 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1753 open handles to avoid lost output.
1754
1755 Note that C<exec> will not call your C<END> blocks, nor will it invoke
1756 C<DESTROY> methods on your objects.
1757
1758 =item exists EXPR
1759 X<exists> X<autovivification>
1760
1761 Given an expression that specifies an element of a hash, returns true if the
1762 specified element in the hash has ever been initialized, even if the
1763 corresponding value is undefined.
1764
1765     print "Exists\n"    if exists $hash{$key};
1766     print "Defined\n"   if defined $hash{$key};
1767     print "True\n"      if $hash{$key};
1768
1769 exists may also be called on array elements, but its behavior is much less
1770 obvious, and is strongly tied to the use of L</delete> on arrays.  B<Be aware>
1771 that calling exists on array values is deprecated and likely to be removed in
1772 a future version of Perl.
1773
1774     print "Exists\n"    if exists $array[$index];
1775     print "Defined\n"   if defined $array[$index];
1776     print "True\n"      if $array[$index];
1777
1778 A hash or array element can be true only if it's defined, and defined if
1779 it exists, but the reverse doesn't necessarily hold true.
1780
1781 Given an expression that specifies the name of a subroutine,
1782 returns true if the specified subroutine has ever been declared, even
1783 if it is undefined.  Mentioning a subroutine name for exists or defined
1784 does not count as declaring it.  Note that a subroutine that does not
1785 exist may still be callable: its package may have an C<AUTOLOAD>
1786 method that makes it spring into existence the first time that it is
1787 called; see L<perlsub>.
1788
1789     print "Exists\n"  if exists &subroutine;
1790     print "Defined\n" if defined &subroutine;
1791
1792 Note that the EXPR can be arbitrarily complicated as long as the final
1793 operation is a hash or array key lookup or subroutine name:
1794
1795     if (exists $ref->{A}->{B}->{$key})  { }
1796     if (exists $hash{A}{B}{$key})       { }
1797
1798     if (exists $ref->{A}->{B}->[$ix])   { }
1799     if (exists $hash{A}{B}[$ix])        { }
1800
1801     if (exists &{$ref->{A}{B}{$key}})   { }
1802
1803 Although the mostly deeply nested array or hash will not spring into
1804 existence just because its existence was tested, any intervening ones will.
1805 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1806 into existence due to the existence test for the $key element above.
1807 This happens anywhere the arrow operator is used, including even here:
1808
1809     undef $ref;
1810     if (exists $ref->{"Some key"})    { }
1811     print $ref;  # prints HASH(0x80d3d5c)
1812
1813 This surprising autovivification in what does not at first--or even
1814 second--glance appear to be an lvalue context may be fixed in a future
1815 release.
1816
1817 Use of a subroutine call, rather than a subroutine name, as an argument
1818 to exists() is an error.
1819
1820     exists &sub;    # OK
1821     exists &sub();  # Error
1822
1823 =item exit EXPR
1824 X<exit> X<terminate> X<abort>
1825
1826 =item exit
1827
1828 Evaluates EXPR and exits immediately with that value.    Example:
1829
1830     $ans = <STDIN>;
1831     exit 0 if $ans =~ /^[Xx]/;
1832
1833 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1834 universally recognized values for EXPR are C<0> for success and C<1>
1835 for error; other values are subject to interpretation depending on the
1836 environment in which the Perl program is running.  For example, exiting
1837 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1838 the mailer to return the item undelivered, but that's not true everywhere.
1839
1840 Don't use C<exit> to abort a subroutine if there's any chance that
1841 someone might want to trap whatever error happened.  Use C<die> instead,
1842 which can be trapped by an C<eval>.
1843
1844 The exit() function does not always exit immediately.  It calls any
1845 defined C<END> routines first, but these C<END> routines may not
1846 themselves abort the exit.  Likewise any object destructors that need to
1847 be called are called before the real exit.  If this is a problem, you
1848 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1849 See L<perlmod> for details.
1850
1851 =item exp EXPR
1852 X<exp> X<exponential> X<antilog> X<antilogarithm> X<e>
1853
1854 =item exp
1855
1856 Returns I<e> (the natural logarithm base) to the power of EXPR.
1857 If EXPR is omitted, gives C<exp($_)>.
1858
1859 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1860 X<fcntl>
1861
1862 Implements the fcntl(2) function.  You'll probably have to say
1863
1864     use Fcntl;
1865
1866 first to get the correct constant definitions.  Argument processing and
1867 value returned work just like C<ioctl> below.
1868 For example:
1869
1870     use Fcntl;
1871     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1872         or die "can't fcntl F_GETFL: $!";
1873
1874 You don't have to check for C<defined> on the return from C<fcntl>.
1875 Like C<ioctl>, it maps a C<0> return from the system call into
1876 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1877 in numeric context.  It is also exempt from the normal B<-w> warnings
1878 on improper numeric conversions.
1879
1880 Note that C<fcntl> raises an exception if used on a machine that
1881 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1882 manpage to learn what functions are available on your system.
1883
1884 Here's an example of setting a filehandle named C<REMOTE> to be
1885 non-blocking at the system level.  You'll have to negotiate C<$|>
1886 on your own, though.
1887
1888     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
1889
1890     $flags = fcntl(REMOTE, F_GETFL, 0)
1891                 or die "Can't get flags for the socket: $!\n";
1892
1893     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
1894                 or die "Can't set flags for the socket: $!\n";
1895
1896 =item fileno FILEHANDLE
1897 X<fileno>
1898
1899 Returns the file descriptor for a filehandle, or undefined if the
1900 filehandle is not open.  This is mainly useful for constructing
1901 bitmaps for C<select> and low-level POSIX tty-handling operations.
1902 If FILEHANDLE is an expression, the value is taken as an indirect
1903 filehandle, generally its name.
1904
1905 You can use this to find out whether two handles refer to the
1906 same underlying descriptor:
1907
1908     if (fileno(THIS) == fileno(THAT)) {
1909         print "THIS and THAT are dups\n";
1910     }
1911
1912 (Filehandles connected to memory objects via new features of C<open> may
1913 return undefined even though they are open.)
1914
1915
1916 =item flock FILEHANDLE,OPERATION
1917 X<flock> X<lock> X<locking>
1918
1919 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1920 for success, false on failure.  Produces a fatal error if used on a
1921 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1922 C<flock> is Perl's portable file locking interface, although it locks
1923 entire files only, not records.
1924
1925 Two potentially non-obvious but traditional C<flock> semantics are
1926 that it waits indefinitely until the lock is granted, and that its locks
1927 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1928 fewer guarantees.  This means that programs that do not also use C<flock>
1929 may modify files locked with C<flock>.  See L<perlport>, 
1930 your port's specific documentation, or your system-specific local manpages
1931 for details.  It's best to assume traditional behavior if you're writing
1932 portable programs.  (But if you're not, you should as always feel perfectly
1933 free to write for your own system's idiosyncrasies (sometimes called
1934 "features").  Slavish adherence to portability concerns shouldn't get
1935 in the way of your getting your job done.)
1936
1937 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1938 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1939 you can use the symbolic names if you import them from the Fcntl module,
1940 either individually, or as a group using the ':flock' tag.  LOCK_SH
1941 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1942 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1943 LOCK_SH or LOCK_EX then C<flock> returns immediately rather than blocking
1944 waiting for the lock; check the return status to see if you got it.
1945
1946 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1947 before locking or unlocking it.
1948
1949 Note that the emulation built with lockf(3) doesn't provide shared
1950 locks, and it requires that FILEHANDLE be open with write intent.  These
1951 are the semantics that lockf(3) implements.  Most if not all systems
1952 implement lockf(3) in terms of fcntl(2) locking, though, so the
1953 differing semantics shouldn't bite too many people.
1954
1955 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
1956 be open with read intent to use LOCK_SH and requires that it be open
1957 with write intent to use LOCK_EX.
1958
1959 Note also that some versions of C<flock> cannot lock things over the
1960 network; you would need to use the more system-specific C<fcntl> for
1961 that.  If you like you can force Perl to ignore your system's flock(2)
1962 function, and so provide its own fcntl(2)-based emulation, by passing
1963 the switch C<-Ud_flock> to the F<Configure> program when you configure
1964 Perl.
1965
1966 Here's a mailbox appender for BSD systems.
1967
1968     use Fcntl qw(:flock SEEK_END); # import LOCK_* and SEEK_END constants
1969
1970     sub lock {
1971         my ($fh) = @_;
1972         flock($fh, LOCK_EX) or die "Cannot lock mailbox - $!\n";
1973
1974         # and, in case someone appended while we were waiting...
1975         seek($fh, 0, SEEK_END) or die "Cannot seek - $!\n";
1976     }
1977
1978     sub unlock {
1979         my ($fh) = @_;
1980         flock($fh, LOCK_UN) or die "Cannot unlock mailbox - $!\n";
1981     }
1982
1983     open(my $mbox, ">>", "/usr/spool/mail/$ENV{'USER'}")
1984         or die "Can't open mailbox: $!";
1985
1986     lock($mbox);
1987     print $mbox $msg,"\n\n";
1988     unlock($mbox);
1989
1990 On systems that support a real flock(2), locks are inherited across fork()
1991 calls, whereas those that must resort to the more capricious fcntl(2)
1992 function lose their locks, making it seriously harder to write servers.
1993
1994 See also L<DB_File> for other flock() examples.
1995
1996 =item fork
1997 X<fork> X<child> X<parent>
1998
1999 Does a fork(2) system call to create a new process running the
2000 same program at the same point.  It returns the child pid to the
2001 parent process, C<0> to the child process, or C<undef> if the fork is
2002 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
2003 are shared, while everything else is copied.  On most systems supporting
2004 fork(), great care has gone into making it extremely efficient (for
2005 example, using copy-on-write technology on data pages), making it the
2006 dominant paradigm for multitasking over the last few decades.
2007
2008 Beginning with v5.6.0, Perl attempts to flush all files opened for
2009 output before forking the child process, but this may not be supported
2010 on some platforms (see L<perlport>).  To be safe, you may need to set
2011 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
2012 C<IO::Handle> on any open handles to avoid duplicate output.
2013
2014 If you C<fork> without ever waiting on your children, you will
2015 accumulate zombies.  On some systems, you can avoid this by setting
2016 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
2017 forking and reaping moribund children.
2018
2019 Note that if your forked child inherits system file descriptors like
2020 STDIN and STDOUT that are actually connected by a pipe or socket, even
2021 if you exit, then the remote server (such as, say, a CGI script or a
2022 backgrounded job launched from a remote shell) won't think you're done.
2023 You should reopen those to F</dev/null> if it's any issue.
2024
2025 =item format
2026 X<format>
2027
2028 Declare a picture format for use by the C<write> function.  For
2029 example:
2030
2031     format Something =
2032         Test: @<<<<<<<< @||||| @>>>>>
2033               $str,     $%,    '$' . int($num)
2034     .
2035
2036     $str = "widget";
2037     $num = $cost/$quantity;
2038     $~ = 'Something';
2039     write;
2040
2041 See L<perlform> for many details and examples.
2042
2043 =item formline PICTURE,LIST
2044 X<formline>
2045
2046 This is an internal function used by C<format>s, though you may call it,
2047 too.  It formats (see L<perlform>) a list of values according to the
2048 contents of PICTURE, placing the output into the format output
2049 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
2050 Eventually, when a C<write> is done, the contents of
2051 C<$^A> are written to some filehandle.  You could also read C<$^A>
2052 and then set C<$^A> back to C<"">.  Note that a format typically
2053 does one C<formline> per line of form, but the C<formline> function itself
2054 doesn't care how many newlines are embedded in the PICTURE.  This means
2055 that the C<~> and C<~~> tokens treat the entire PICTURE as a single line.
2056 You may therefore need to use multiple formlines to implement a single
2057 record format, just like the C<format> compiler.
2058
2059 Be careful if you put double quotes around the picture, because an C<@>
2060 character may be taken to mean the beginning of an array name.
2061 C<formline> always returns true.  See L<perlform> for other examples.
2062
2063 =item getc FILEHANDLE
2064 X<getc> X<getchar> X<character> X<file, read>
2065
2066 =item getc
2067
2068 Returns the next character from the input file attached to FILEHANDLE,
2069 or the undefined value at end of file or if there was an error (in
2070 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
2071 STDIN.  This is not particularly efficient.  However, it cannot be
2072 used by itself to fetch single characters without waiting for the user
2073 to hit enter.  For that, try something more like:
2074
2075     if ($BSD_STYLE) {
2076         system "stty cbreak </dev/tty >/dev/tty 2>&1";
2077     }
2078     else {
2079         system "stty", '-icanon', 'eol', "\001";
2080     }
2081
2082     $key = getc(STDIN);
2083
2084     if ($BSD_STYLE) {
2085         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
2086     }
2087     else {
2088         system 'stty', 'icanon', 'eol', '^@'; # ASCII NUL
2089     }
2090     print "\n";
2091
2092 Determination of whether $BSD_STYLE should be set
2093 is left as an exercise to the reader.
2094
2095 The C<POSIX::getattr> function can do this more portably on
2096 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
2097 module from your nearest CPAN site; details on CPAN can be found on
2098 L<perlmodlib/CPAN>.
2099
2100 =item getlogin
2101 X<getlogin> X<login>
2102
2103 This implements the C library function of the same name, which on most
2104 systems returns the current login from F</etc/utmp>, if any.  If it
2105 returns the empty string, use C<getpwuid>.
2106
2107     $login = getlogin || getpwuid($<) || "Kilroy";
2108
2109 Do not consider C<getlogin> for authentication: it is not as
2110 secure as C<getpwuid>.
2111
2112 =item getpeername SOCKET
2113 X<getpeername> X<peer>
2114
2115 Returns the packed sockaddr address of other end of the SOCKET connection.
2116
2117     use Socket;
2118     $hersockaddr    = getpeername(SOCK);
2119     ($port, $iaddr) = sockaddr_in($hersockaddr);
2120     $herhostname    = gethostbyaddr($iaddr, AF_INET);
2121     $herstraddr     = inet_ntoa($iaddr);
2122
2123 =item getpgrp PID
2124 X<getpgrp> X<group>
2125
2126 Returns the current process group for the specified PID.  Use
2127 a PID of C<0> to get the current process group for the
2128 current process.  Will raise an exception if used on a machine that
2129 doesn't implement getpgrp(2).  If PID is omitted, returns process
2130 group of current process.  Note that the POSIX version of C<getpgrp>
2131 does not accept a PID argument, so only C<PID==0> is truly portable.
2132
2133 =item getppid
2134 X<getppid> X<parent> X<pid>
2135
2136 Returns the process id of the parent process.
2137
2138 Note for Linux users: on Linux, the C functions C<getpid()> and
2139 C<getppid()> return different values from different threads. In order to
2140 be portable, this behavior is not reflected by the Perl-level function
2141 C<getppid()>, that returns a consistent value across threads. If you want
2142 to call the underlying C<getppid()>, you may use the CPAN module
2143 C<Linux::Pid>.
2144
2145 =item getpriority WHICH,WHO
2146 X<getpriority> X<priority> X<nice>
2147
2148 Returns the current priority for a process, a process group, or a user.
2149 (See C<getpriority(2)>.)  Will raise a fatal exception if used on a
2150 machine that doesn't implement getpriority(2).
2151
2152 =item getpwnam NAME
2153 X<getpwnam> X<getgrnam> X<gethostbyname> X<getnetbyname> X<getprotobyname>
2154 X<getpwuid> X<getgrgid> X<getservbyname> X<gethostbyaddr> X<getnetbyaddr>
2155 X<getprotobynumber> X<getservbyport> X<getpwent> X<getgrent> X<gethostent>
2156 X<getnetent> X<getprotoent> X<getservent> X<setpwent> X<setgrent> X<sethostent>
2157 X<setnetent> X<setprotoent> X<setservent> X<endpwent> X<endgrent> X<endhostent>
2158 X<endnetent> X<endprotoent> X<endservent> 
2159
2160 =item getgrnam NAME
2161
2162 =item gethostbyname NAME
2163
2164 =item getnetbyname NAME
2165
2166 =item getprotobyname NAME
2167
2168 =item getpwuid UID
2169
2170 =item getgrgid GID
2171
2172 =item getservbyname NAME,PROTO
2173
2174 =item gethostbyaddr ADDR,ADDRTYPE
2175
2176 =item getnetbyaddr ADDR,ADDRTYPE
2177
2178 =item getprotobynumber NUMBER
2179
2180 =item getservbyport PORT,PROTO
2181
2182 =item getpwent
2183
2184 =item getgrent
2185
2186 =item gethostent
2187
2188 =item getnetent
2189
2190 =item getprotoent
2191
2192 =item getservent
2193
2194 =item setpwent
2195
2196 =item setgrent
2197
2198 =item sethostent STAYOPEN
2199
2200 =item setnetent STAYOPEN
2201
2202 =item setprotoent STAYOPEN
2203
2204 =item setservent STAYOPEN
2205
2206 =item endpwent
2207
2208 =item endgrent
2209
2210 =item endhostent
2211
2212 =item endnetent
2213
2214 =item endprotoent
2215
2216 =item endservent
2217
2218 These routines are the same as their counterparts in the
2219 system C library.  In list context, the return values from the
2220 various get routines are as follows:
2221
2222     ($name,$passwd,$uid,$gid,
2223        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
2224     ($name,$passwd,$gid,$members) = getgr*
2225     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2226     ($name,$aliases,$addrtype,$net) = getnet*
2227     ($name,$aliases,$proto) = getproto*
2228     ($name,$aliases,$port,$proto) = getserv*
2229
2230 (If the entry doesn't exist you get an empty list.)
2231
2232 The exact meaning of the $gcos field varies but it usually contains
2233 the real name of the user (as opposed to the login name) and other
2234 information pertaining to the user.  Beware, however, that in many
2235 system users are able to change this information and therefore it
2236 cannot be trusted and therefore the $gcos is tainted (see
2237 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2238 login shell, are also tainted, because of the same reason.
2239
2240 In scalar context, you get the name, unless the function was a
2241 lookup by name, in which case you get the other thing, whatever it is.
2242 (If the entry doesn't exist you get the undefined value.)  For example:
2243
2244     $uid   = getpwnam($name);
2245     $name  = getpwuid($num);
2246     $name  = getpwent();
2247     $gid   = getgrnam($name);
2248     $name  = getgrgid($num);
2249     $name  = getgrent();
2250     #etc.
2251
2252 In I<getpw*()> the fields $quota, $comment, and $expire are special
2253 in that they are unsupported on many systems.  If the
2254 $quota is unsupported, it is an empty scalar.  If it is supported, it
2255 usually encodes the disk quota.  If the $comment field is unsupported,
2256 it is an empty scalar.  If it is supported it usually encodes some
2257 administrative comment about the user.  In some systems the $quota
2258 field may be $change or $age, fields that have to do with password
2259 aging.  In some systems the $comment field may be $class.  The $expire
2260 field, if present, encodes the expiration period of the account or the
2261 password.  For the availability and the exact meaning of these fields
2262 in your system, please consult your getpwnam(3) documentation and your
2263 F<pwd.h> file.  You can also find out from within Perl what your
2264 $quota and $comment fields mean and whether you have the $expire field
2265 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2266 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2267 files are supported only if your vendor has implemented them in the
2268 intuitive fashion that calling the regular C library routines gets the
2269 shadow versions if you're running under privilege or if there exists
2270 the shadow(3) functions as found in System V (this includes Solaris
2271 and Linux.)  Those systems that implement a proprietary shadow password
2272 facility are unlikely to be supported.
2273
2274 The $members value returned by I<getgr*()> is a space separated list of
2275 the login names of the members of the group.
2276
2277 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2278 C, it will be returned to you via C<$?> if the function call fails.  The
2279 C<@addrs> value returned by a successful call is a list of raw
2280 addresses returned by the corresponding library call.  In the
2281 Internet domain, each address is four bytes long; you can unpack it
2282 by saying something like:
2283
2284     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2285
2286 The Socket library makes this slightly easier:
2287
2288     use Socket;
2289     $iaddr = inet_aton("127.1"); # or whatever address
2290     $name  = gethostbyaddr($iaddr, AF_INET);
2291
2292     # or going the other way
2293     $straddr = inet_ntoa($iaddr);
2294
2295 In the opposite way, to resolve a hostname to the IP address
2296 you can write this:
2297
2298     use Socket;
2299     $packed_ip = gethostbyname("www.perl.org");
2300     if (defined $packed_ip) {
2301         $ip_address = inet_ntoa($packed_ip);
2302     }
2303
2304 Make sure <gethostbyname()> is called in SCALAR context and that
2305 its return value is checked for definedness.
2306
2307 If you get tired of remembering which element of the return list
2308 contains which return value, by-name interfaces are provided
2309 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2310 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2311 and C<User::grent>.  These override the normal built-ins, supplying
2312 versions that return objects with the appropriate names
2313 for each field.  For example:
2314
2315    use File::stat;
2316    use User::pwent;
2317    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2318
2319 Even though it looks like they're the same method calls (uid),
2320 they aren't, because a C<File::stat> object is different from
2321 a C<User::pwent> object.
2322
2323 =item getsockname SOCKET
2324 X<getsockname>
2325
2326 Returns the packed sockaddr address of this end of the SOCKET connection,
2327 in case you don't know the address because you have several different
2328 IPs that the connection might have come in on.
2329
2330     use Socket;
2331     $mysockaddr = getsockname(SOCK);
2332     ($port, $myaddr) = sockaddr_in($mysockaddr);
2333     printf "Connect to %s [%s]\n",
2334        scalar gethostbyaddr($myaddr, AF_INET),
2335        inet_ntoa($myaddr);
2336
2337 =item getsockopt SOCKET,LEVEL,OPTNAME
2338 X<getsockopt>
2339
2340 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2341 Options may exist at multiple protocol levels depending on the socket
2342 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2343 C<Socket> module) will exist. To query options at another level the
2344 protocol number of the appropriate protocol controlling the option
2345 should be supplied. For example, to indicate that an option is to be
2346 interpreted by the TCP protocol, LEVEL should be set to the protocol
2347 number of TCP, which you can get using C<getprotobyname>.
2348
2349 The function returns a packed string representing the requested socket
2350 option, or C<undef> on error, with the reason for the error placed in
2351 C<$!>). Just what is in the packed string depends on LEVEL and OPTNAME;
2352 consult getsockopt(2) for details.  A common case is that the option is an
2353 integer, in which case the result is a packed integer, which you can decode
2354 using C<unpack> with the C<i> (or C<I>) format.
2355
2356 An example to test whether Nagle's algorithm is turned on on a socket:
2357
2358     use Socket qw(:all);
2359
2360     defined(my $tcp = getprotobyname("tcp"))
2361         or die "Could not determine the protocol number for tcp";
2362     # my $tcp = IPPROTO_TCP; # Alternative
2363     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2364         or die "getsockopt TCP_NODELAY: $!";
2365     my $nodelay = unpack("I", $packed);
2366     print "Nagle's algorithm is turned ", $nodelay ? "off\n" : "on\n";
2367
2368
2369 =item glob EXPR
2370 X<glob> X<wildcard> X<filename, expansion> X<expand>
2371
2372 =item glob
2373
2374 In list context, returns a (possibly empty) list of filename expansions on
2375 the value of EXPR such as the standard Unix shell F</bin/csh> would do. In
2376 scalar context, glob iterates through such filename expansions, returning
2377 undef when the list is exhausted. This is the internal function
2378 implementing the C<< <*.c> >> operator, but you can use it directly. If
2379 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2380 more detail in L<perlop/"I/O Operators">.
2381
2382 Note that C<glob> splits its arguments on whitespace and treats
2383 each segment as separate pattern.  As such, C<glob("*.c *.h")> 
2384 matches all files with a F<.c> or F<.h> extension.  The expression
2385 C<glob(".* *")> matchs all files in the current working directory.
2386
2387 If non-empty braces are the only wildcard characters used in the
2388 C<glob>, no filenames are matched, but potentially many strings
2389 are returned.  For example, this produces nine strings, one for
2390 each pairing of fruits and colors:
2391
2392     @many =  glob "{apple,tomato,cherry}={green,yellow,red}";
2393
2394 Beginning with v5.6.0, this operator is implemented using the standard
2395 C<File::Glob> extension.  See L<File::Glob> for details, including
2396 C<bsd_glob> which does not treat whitespace as a pattern separator.
2397
2398 =item gmtime EXPR
2399 X<gmtime> X<UTC> X<Greenwich>
2400
2401 =item gmtime
2402
2403 Works just like L<localtime> but the returned values are
2404 localized for the standard Greenwich time zone.
2405
2406 Note: when called in list context, $isdst, the last value
2407 returned by gmtime is always C<0>.  There is no
2408 Daylight Saving Time in GMT.
2409
2410 See L<perlport/gmtime> for portability concerns.
2411
2412 =item goto LABEL
2413 X<goto> X<jump> X<jmp>
2414
2415 =item goto EXPR
2416
2417 =item goto &NAME
2418
2419 The C<goto-LABEL> form finds the statement labeled with LABEL and
2420 resumes execution there. It can't be used to get out of a block or
2421 subroutine given to C<sort>.  It can be used to go almost anywhere
2422 else within the dynamic scope, including out of subroutines, but it's
2423 usually better to use some other construct such as C<last> or C<die>.
2424 The author of Perl has never felt the need to use this form of C<goto>
2425 (in Perl, that is; C is another matter).  (The difference is that C
2426 does not offer named loops combined with loop control.  Perl does, and
2427 this replaces most structured uses of C<goto> in other languages.)
2428
2429 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2430 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2431 necessarily recommended if you're optimizing for maintainability:
2432
2433     goto ("FOO", "BAR", "GLARCH")[$i];
2434
2435 Use of C<goto-LABEL> or C<goto-EXPR> to jump into a construct is
2436 deprecated and will issue a warning.  Even then, it may not be used to
2437 go into any construct that requires initialization, such as a
2438 subroutine or a C<foreach> loop.  It also can't be used to go into a
2439 construct that is optimized away.
2440
2441 The C<goto-&NAME> form is quite different from the other forms of
2442 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2443 doesn't have the stigma associated with other gotos.  Instead, it
2444 exits the current subroutine (losing any changes set by local()) and
2445 immediately calls in its place the named subroutine using the current
2446 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2447 load another subroutine and then pretend that the other subroutine had
2448 been called in the first place (except that any modifications to C<@_>
2449 in the current subroutine are propagated to the other subroutine.)
2450 After the C<goto>, not even C<caller> will be able to tell that this
2451 routine was called first.
2452
2453 NAME needn't be the name of a subroutine; it can be a scalar variable
2454 containing a code reference, or a block that evaluates to a code
2455 reference.
2456
2457 =item grep BLOCK LIST
2458 X<grep>
2459
2460 =item grep EXPR,LIST
2461
2462 This is similar in spirit to, but not the same as, grep(1) and its
2463 relatives.  In particular, it is not limited to using regular expressions.
2464
2465 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2466 C<$_> to each element) and returns the list value consisting of those
2467 elements for which the expression evaluated to true.  In scalar
2468 context, returns the number of times the expression was true.
2469
2470     @foo = grep(!/^#/, @bar);    # weed out comments
2471
2472 or equivalently,
2473
2474     @foo = grep {!/^#/} @bar;    # weed out comments
2475
2476 Note that C<$_> is an alias to the list value, so it can be used to
2477 modify the elements of the LIST.  While this is useful and supported,
2478 it can cause bizarre results if the elements of LIST are not variables.
2479 Similarly, grep returns aliases into the original list, much as a for
2480 loop's index variable aliases the list elements.  That is, modifying an
2481 element of a list returned by grep (for example, in a C<foreach>, C<map>
2482 or another C<grep>) actually modifies the element in the original list.
2483 This is usually something to be avoided when writing clear code.
2484
2485 If C<$_> is lexical in the scope where the C<grep> appears (because it has
2486 been declared with C<my $_>) then, in addition to being locally aliased to
2487 the list elements, C<$_> keeps being lexical inside the block; i.e., it
2488 can't be seen from the outside, avoiding any potential side-effects.
2489
2490 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2491
2492 =item hex EXPR
2493 X<hex> X<hexadecimal>
2494
2495 =item hex
2496
2497 Interprets EXPR as a hex string and returns the corresponding value.
2498 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
2499 L</oct>.)  If EXPR is omitted, uses C<$_>.
2500
2501     print hex '0xAf'; # prints '175'
2502     print hex 'aF';   # same
2503
2504 Hex strings may only represent integers.  Strings that would cause
2505 integer overflow trigger a warning.  Leading whitespace is not stripped,
2506 unlike oct(). To present something as hex, look into L</printf>,
2507 L</sprintf>, or L</unpack>.
2508
2509 =item import LIST
2510 X<import>
2511
2512 There is no builtin C<import> function.  It is just an ordinary
2513 method (subroutine) defined (or inherited) by modules that wish to export
2514 names to another module.  The C<use> function calls the C<import> method
2515 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2516
2517 =item index STR,SUBSTR,POSITION
2518 X<index> X<indexOf> X<InStr>
2519
2520 =item index STR,SUBSTR
2521
2522 The index function searches for one string within another, but without
2523 the wildcard-like behavior of a full regular-expression pattern match.
2524 It returns the position of the first occurrence of SUBSTR in STR at
2525 or after POSITION.  If POSITION is omitted, starts searching from the
2526 beginning of the string.  POSITION before the beginning of the string
2527 or after its end is treated as if it were the beginning or the end,
2528 respectively.  POSITION and the return value are based at C<0> (or whatever
2529 you've set the C<$[> variable to--but don't do that).  If the substring
2530 is not found, C<index> returns one less than the base, ordinarily C<-1>.
2531
2532 =item int EXPR
2533 X<int> X<integer> X<truncate> X<trunc> X<floor>
2534
2535 =item int
2536
2537 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2538 You should not use this function for rounding: one because it truncates
2539 towards C<0>, and two because machine representations of floating-point
2540 numbers can sometimes produce counterintuitive results.  For example,
2541 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2542 because it's really more like -268.99999999999994315658 instead.  Usually,
2543 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2544 functions will serve you better than will int().
2545
2546 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2547 X<ioctl>
2548
2549 Implements the ioctl(2) function.  You'll probably first have to say
2550
2551     require "sys/ioctl.ph";  # probably in $Config{archlib}/sys/ioctl.ph
2552
2553 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
2554 exist or doesn't have the correct definitions you'll have to roll your
2555 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2556 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2557 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2558 written depending on the FUNCTION; a C pointer to the string value of SCALAR
2559 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2560 has no string value but does have a numeric value, that value will be
2561 passed rather than a pointer to the string value.  To guarantee this to be
2562 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2563 functions may be needed to manipulate the values of structures used by
2564 C<ioctl>.
2565
2566 The return value of C<ioctl> (and C<fcntl>) is as follows:
2567
2568     if OS returns:      then Perl returns:
2569         -1               undefined value
2570          0              string "0 but true"
2571     anything else           that number
2572
2573 Thus Perl returns true on success and false on failure, yet you can
2574 still easily determine the actual value returned by the operating
2575 system:
2576
2577     $retval = ioctl(...) || -1;
2578     printf "System returned %d\n", $retval;
2579
2580 The special string C<"0 but true"> is exempt from B<-w> complaints
2581 about improper numeric conversions.
2582
2583 =item join EXPR,LIST
2584 X<join>
2585
2586 Joins the separate strings of LIST into a single string with fields
2587 separated by the value of EXPR, and returns that new string.  Example:
2588
2589     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2590
2591 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2592 first argument.  Compare L</split>.
2593
2594 =item keys HASH
2595 X<keys> X<key>
2596
2597 =item keys ARRAY
2598
2599 Returns a list consisting of all the keys of the named hash, or the indices
2600 of an array. (In scalar context, returns the number of keys or indices.)
2601
2602 The keys of a hash are returned in an apparently random order.  The actual
2603 random order is subject to change in future versions of Perl, but it
2604 is guaranteed to be the same order as either the C<values> or C<each>
2605 function produces (given that the hash has not been modified).  Since
2606 Perl 5.8.1 the ordering is different even between different runs of
2607 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
2608 Attacks">).
2609
2610 As a side effect, calling keys() resets the HASH or ARRAY's internal iterator
2611 (see L</each>).  In particular, calling keys() in void context resets
2612 the iterator with no other overhead.
2613
2614 Here is yet another way to print your environment:
2615
2616     @keys = keys %ENV;
2617     @values = values %ENV;
2618     while (@keys) {
2619         print pop(@keys), '=', pop(@values), "\n";
2620     }
2621
2622 or how about sorted by key:
2623
2624     foreach $key (sort(keys %ENV)) {
2625         print $key, '=', $ENV{$key}, "\n";
2626     }
2627
2628 The returned values are copies of the original keys in the hash, so
2629 modifying them will not affect the original hash.  Compare L</values>.
2630
2631 To sort a hash by value, you'll need to use a C<sort> function.
2632 Here's a descending numeric sort of a hash by its values:
2633
2634     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2635         printf "%4d %s\n", $hash{$key}, $key;
2636     }
2637
2638 Used as an lvalue, C<keys> allows you to increase the number of hash buckets
2639 allocated for the given hash.  This can gain you a measure of efficiency if
2640 you know the hash is going to get big.  (This is similar to pre-extending
2641 an array by assigning a larger number to $#array.)  If you say
2642
2643     keys %hash = 200;
2644
2645 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2646 in fact, since it rounds up to the next power of two.  These
2647 buckets will be retained even if you do C<%hash = ()>, use C<undef
2648 %hash> if you want to free the storage while C<%hash> is still in scope.
2649 You can't shrink the number of buckets allocated for the hash using
2650 C<keys> in this way (but you needn't worry about doing this by accident,
2651 as trying has no effect). C<keys @array> in an lvalue context is a syntax
2652 error.
2653
2654 See also C<each>, C<values> and C<sort>.
2655
2656 =item kill SIGNAL, LIST
2657 X<kill> X<signal>
2658
2659 Sends a signal to a list of processes.  Returns the number of
2660 processes successfully signaled (which is not necessarily the
2661 same as the number actually killed).
2662
2663     $cnt = kill 1, $child1, $child2;
2664     kill 9, @goners;
2665
2666 If SIGNAL is zero, no signal is sent to the process, but C<kill>
2667 checks whether it's I<possible> to send a signal to it (that
2668 means, to be brief, that the process is owned by the same user, or we are
2669 the super-user).  This is useful to check that a child process is still
2670 alive (even if only as a zombie) and hasn't changed its UID.  See
2671 L<perlport> for notes on the portability of this construct.
2672
2673 Unlike in the shell, if SIGNAL is negative, it kills process groups instead
2674 of processes. That means you usually want to use positive not negative signals.
2675 You may also use a signal name in quotes.
2676
2677 The behavior of kill when a I<PROCESS> number is zero or negative depends on
2678 the operating system.  For example, on POSIX-conforming systems, zero will
2679 signal the current process group and -1 will signal all processes.
2680
2681 See L<perlipc/"Signals"> for more details.
2682
2683 =item last LABEL
2684 X<last> X<break>
2685
2686 =item last
2687
2688 The C<last> command is like the C<break> statement in C (as used in
2689 loops); it immediately exits the loop in question.  If the LABEL is
2690 omitted, the command refers to the innermost enclosing loop.  The
2691 C<continue> block, if any, is not executed:
2692
2693     LINE: while (<STDIN>) {
2694         last LINE if /^$/;  # exit when done with header
2695         #...
2696     }
2697
2698 C<last> cannot be used to exit a block that returns a value such as
2699 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2700 a grep() or map() operation.
2701
2702 Note that a block by itself is semantically identical to a loop
2703 that executes once.  Thus C<last> can be used to effect an early
2704 exit out of such a block.
2705
2706 See also L</continue> for an illustration of how C<last>, C<next>, and
2707 C<redo> work.
2708
2709 =item lc EXPR
2710 X<lc> X<lowercase>
2711
2712 =item lc
2713
2714 Returns a lowercased version of EXPR.  This is the internal function
2715 implementing the C<\L> escape in double-quoted strings.
2716
2717 If EXPR is omitted, uses C<$_>.
2718
2719 What gets returned depends on several factors:
2720
2721 =over
2722
2723 =item If C<use bytes> is in effect:
2724
2725 =over
2726
2727 =item On EBCDIC platforms
2728
2729 The results are what the C language system call C<tolower()> returns.
2730
2731 =item On ASCII platforms
2732
2733 The results follow ASCII semantics.  Only characters C<A-Z> change, to C<a-z>
2734 respectively.
2735
2736 =back
2737
2738 =item Otherwise, If EXPR has the UTF8 flag set
2739
2740 If the current package has a subroutine named C<ToLower>, it will be used to
2741 change the case (See L<perlunicode/User-Defined Case Mappings>.)
2742 Otherwise Unicode semantics are used for the case change.
2743
2744 =item Otherwise, if C<use locale> is in effect
2745
2746 Respects current LC_CTYPE locale.  See L<perllocale>.
2747
2748 =item Otherwise, if C<use feature 'unicode_strings'> is in effect:
2749
2750 Unicode semantics are used for the case change.  Any subroutine named
2751 C<ToLower> will not be used.
2752
2753 =item Otherwise:
2754
2755 =over
2756
2757 =item On EBCDIC platforms
2758
2759 The results are what the C language system call C<tolower()> returns.
2760
2761 =item On ASCII platforms
2762
2763 ASCII semantics are used for the case change.  The lowercase of any character
2764 outside the ASCII range is the character itself.
2765
2766 =back
2767
2768 =back
2769
2770 =item lcfirst EXPR
2771 X<lcfirst> X<lowercase>
2772
2773 =item lcfirst
2774
2775 Returns the value of EXPR with the first character lowercased.  This
2776 is the internal function implementing the C<\l> escape in
2777 double-quoted strings.
2778
2779 If EXPR is omitted, uses C<$_>.
2780
2781 This function behaves the same way under various pragma, such as in a locale,
2782 as L</lc> does.
2783
2784 =item length EXPR
2785 X<length> X<size>
2786
2787 =item length
2788
2789 Returns the length in I<characters> of the value of EXPR.  If EXPR is
2790 omitted, returns length of C<$_>.  If EXPR is undefined, returns C<undef>.
2791
2792 This function cannot be used on an entire array or hash to find out how
2793 many elements these have.  For that, use C<scalar @array> and C<scalar keys
2794 %hash>, respectively.
2795
2796 Like all Perl character operations, length() normally deals in logical
2797 characters, not physical bytes.  For how many bytes a string encoded as
2798 UTF-8 would take up, use C<length(Encode::encode_utf8(EXPR))> (you'll have
2799 to C<use Encode> first).  See L<Encode> and L<perlunicode>.
2800
2801 =item link OLDFILE,NEWFILE
2802 X<link>
2803
2804 Creates a new filename linked to the old filename.  Returns true for
2805 success, false otherwise.
2806
2807 =item listen SOCKET,QUEUESIZE
2808 X<listen>
2809
2810 Does the same thing that the listen(2) system call does.  Returns true if
2811 it succeeded, false otherwise.  See the example in
2812 L<perlipc/"Sockets: Client/Server Communication">.
2813
2814 =item local EXPR
2815 X<local>
2816
2817 You really probably want to be using C<my> instead, because C<local> isn't
2818 what most people think of as "local".  See
2819 L<perlsub/"Private Variables via my()"> for details.
2820
2821 A local modifies the listed variables to be local to the enclosing
2822 block, file, or eval.  If more than one value is listed, the list must
2823 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2824 for details, including issues with tied arrays and hashes.
2825
2826 The C<delete local EXPR> construct can also be used to localize the deletion
2827 of array/hash elements to the current block.
2828 See L<perlsub/"Localized deletion of elements of composite types">.
2829
2830 =item localtime EXPR
2831 X<localtime> X<ctime>
2832
2833 =item localtime
2834
2835 Converts a time as returned by the time function to a 9-element list
2836 with the time analyzed for the local time zone.  Typically used as
2837 follows:
2838
2839     #  0    1    2     3     4    5     6     7     8
2840     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2841                                                 localtime(time);
2842
2843 All list elements are numeric, and come straight out of the C `struct
2844 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
2845 of the specified time.
2846
2847 C<$mday> is the day of the month, and C<$mon> is the month itself, in
2848 the range C<0..11> with 0 indicating January and 11 indicating December.
2849 This makes it easy to get a month name from a list:
2850
2851     my @abbr = qw( Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec );
2852     print "$abbr[$mon] $mday";
2853     # $mon=9, $mday=18 gives "Oct 18"
2854
2855 C<$year> is the number of years since 1900, not just the last two digits
2856 of the year.  That is, C<$year> is C<123> in year 2023.  The proper way
2857 to get a 4-digit year is simply:
2858
2859     $year += 1900;
2860
2861 Otherwise you create non-Y2K-compliant programs--and you wouldn't want
2862 to do that, would you?
2863
2864 To get the last two digits of the year (e.g., '01' in 2001) do:
2865
2866     $year = sprintf("%02d", $year % 100);
2867
2868 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
2869 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
2870 (or C<0..365> in leap years.)
2871
2872 C<$isdst> is true if the specified time occurs during Daylight Saving
2873 Time, false otherwise.
2874
2875 If EXPR is omitted, C<localtime()> uses the current time (as returned
2876 by time(3)).
2877
2878 In scalar context, C<localtime()> returns the ctime(3) value:
2879
2880     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2881
2882 This scalar value is B<not> locale dependent but is a Perl builtin. For GMT
2883 instead of local time use the L</gmtime> builtin. See also the
2884 C<Time::Local> module (to convert the second, minutes, hours, ... back to
2885 the integer value returned by time()), and the L<POSIX> module's strftime(3)
2886 and mktime(3) functions.
2887
2888 To get somewhat similar but locale dependent date strings, set up your
2889 locale environment variables appropriately (please see L<perllocale>) and
2890 try for example:
2891
2892     use POSIX qw(strftime);
2893     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2894     # or for GMT formatted appropriately for your locale:
2895     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
2896
2897 Note that the C<%a> and C<%b>, the short forms of the day of the week
2898 and the month of the year, may not necessarily be three characters wide.
2899
2900 See L<perlport/localtime> for portability concerns.
2901
2902 The L<Time::gmtime> and L<Time::localtime> modules provides a convenient,
2903 by-name access mechanism to the gmtime() and localtime() functions,
2904 respectively.
2905
2906 For a comprehensive date and time representation look at the
2907 L<DateTime> module on CPAN.
2908
2909 =item lock THING
2910 X<lock>
2911
2912 This function places an advisory lock on a shared variable, or referenced
2913 object contained in I<THING> until the lock goes out of scope.
2914
2915 lock() is a "weak keyword" : this means that if you've defined a function
2916 by this name (before any calls to it), that function will be called
2917 instead.  If you are not under C<use threads::shared> this does nothing.
2918 See L<threads::shared>.
2919
2920 =item log EXPR
2921 X<log> X<logarithm> X<e> X<ln> X<base>
2922
2923 =item log
2924
2925 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2926 returns log of C<$_>.  To get the log of another base, use basic algebra:
2927 The base-N log of a number is equal to the natural log of that number
2928 divided by the natural log of N.  For example:
2929
2930     sub log10 {
2931         my $n = shift;
2932         return log($n)/log(10);
2933     }
2934
2935 See also L</exp> for the inverse operation.
2936
2937 =item lstat EXPR
2938 X<lstat>
2939
2940 =item lstat
2941
2942 Does the same thing as the C<stat> function (including setting the
2943 special C<_> filehandle) but stats a symbolic link instead of the file
2944 the symbolic link points to.  If symbolic links are unimplemented on
2945 your system, a normal C<stat> is done.  For much more detailed
2946 information, please see the documentation for C<stat>.
2947
2948 If EXPR is omitted, stats C<$_>.
2949
2950 =item m//
2951
2952 The match operator.  See L<perlop/"Regexp Quote-Like Operators">.
2953
2954 =item map BLOCK LIST
2955 X<map>
2956
2957 =item map EXPR,LIST
2958
2959 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2960 C<$_> to each element) and returns the list value composed of the
2961 results of each such evaluation.  In scalar context, returns the
2962 total number of elements so generated.  Evaluates BLOCK or EXPR in
2963 list context, so each element of LIST may produce zero, one, or
2964 more elements in the returned value.
2965
2966     @chars = map(chr, @nums);
2967
2968 translates a list of numbers to the corresponding characters.  And
2969
2970     %hash = map { get_a_key_for($_) => $_ } @array;
2971
2972 is just a funny way to write
2973
2974     %hash = ();
2975     foreach (@array) {
2976         $hash{get_a_key_for($_)} = $_;
2977     }
2978
2979 Note that C<$_> is an alias to the list value, so it can be used to
2980 modify the elements of the LIST.  While this is useful and supported,
2981 it can cause bizarre results if the elements of LIST are not variables.
2982 Using a regular C<foreach> loop for this purpose would be clearer in
2983 most cases.  See also L</grep> for an array composed of those items of
2984 the original list for which the BLOCK or EXPR evaluates to true.
2985
2986 If C<$_> is lexical in the scope where the C<map> appears (because it has
2987 been declared with C<my $_>), then, in addition to being locally aliased to
2988 the list elements, C<$_> keeps being lexical inside the block; that is, it
2989 can't be seen from the outside, avoiding any potential side-effects.
2990
2991 C<{> starts both hash references and blocks, so C<map { ...> could be either
2992 the start of map BLOCK LIST or map EXPR, LIST. Because Perl doesn't look
2993 ahead for the closing C<}> it has to take a guess at which it's dealing with
2994 based on what it finds just after the C<{>. Usually it gets it right, but if it
2995 doesn't it won't realize something is wrong until it gets to the C<}> and
2996 encounters the missing (or unexpected) comma. The syntax error will be
2997 reported close to the C<}>, but you'll need to change something near the C<{>
2998 such as using a unary C<+> to give Perl some help:
2999
3000     %hash = map {  "\L$_" => 1  } @array  # perl guesses EXPR.  wrong
3001     %hash = map { +"\L$_" => 1  } @array  # perl guesses BLOCK. right
3002     %hash = map { ("\L$_" => 1) } @array  # this also works
3003     %hash = map {  lc($_) => 1  } @array  # as does this.
3004     %hash = map +( lc($_) => 1 ), @array  # this is EXPR and works!
3005
3006     %hash = map  ( lc($_), 1 ),   @array  # evaluates to (1, @array)
3007
3008 or to force an anon hash constructor use C<+{>:
3009
3010    @hashes = map +{ lc($_) => 1 }, @array # EXPR, so needs comma at end
3011
3012 to get a list of anonymous hashes each with only one entry apiece.
3013
3014 =item mkdir FILENAME,MASK
3015 X<mkdir> X<md> X<directory, create>
3016
3017 =item mkdir FILENAME
3018
3019 =item mkdir
3020
3021 Creates the directory specified by FILENAME, with permissions
3022 specified by MASK (as modified by C<umask>).  If it succeeds it
3023 returns true, otherwise it returns false and sets C<$!> (errno).
3024 If omitted, MASK defaults to 0777. If omitted, FILENAME defaults
3025 to C<$_>.
3026
3027 In general, it is better to create directories with permissive MASK,
3028 and let the user modify that with their C<umask>, than it is to supply
3029 a restrictive MASK and give the user no way to be more permissive.
3030 The exceptions to this rule are when the file or directory should be
3031 kept private (mail files, for instance).  The perlfunc(1) entry on
3032 C<umask> discusses the choice of MASK in more detail.
3033
3034 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
3035 number of trailing slashes.  Some operating and filesystems do not get
3036 this right, so Perl automatically removes all trailing slashes to keep
3037 everyone happy.
3038
3039 To recursively create a directory structure, look at
3040 the C<mkpath> function of the L<File::Path> module.
3041
3042 =item msgctl ID,CMD,ARG
3043 X<msgctl>
3044
3045 Calls the System V IPC function msgctl(2).  You'll probably have to say
3046
3047     use IPC::SysV;
3048
3049 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
3050 then ARG must be a variable that will hold the returned C<msqid_ds>
3051 structure.  Returns like C<ioctl>: the undefined value for error,
3052 C<"0 but true"> for zero, or the actual return value otherwise.  See also
3053 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::Semaphore> documentation.
3054
3055 =item msgget KEY,FLAGS
3056 X<msgget>
3057
3058 Calls the System V IPC function msgget(2).  Returns the message queue
3059 id, or the undefined value if there is an error.  See also
3060 L<perlipc/"SysV IPC"> and C<IPC::SysV> and C<IPC::Msg> documentation.
3061
3062 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
3063 X<msgrcv>
3064
3065 Calls the System V IPC function msgrcv to receive a message from
3066 message queue ID into variable VAR with a maximum message size of
3067 SIZE.  Note that when a message is received, the message type as a
3068 native long integer will be the first thing in VAR, followed by the
3069 actual message.  This packing may be opened with C<unpack("l! a*")>.
3070 Taints the variable.  Returns true if successful, or false if there is
3071 an error.  See also L<perlipc/"SysV IPC">, C<IPC::SysV>, and
3072 C<IPC::SysV::Msg> documentation.
3073
3074 =item msgsnd ID,MSG,FLAGS
3075 X<msgsnd>
3076
3077 Calls the System V IPC function msgsnd to send the message MSG to the
3078 message queue ID.  MSG must begin with the native long integer message
3079 type, and be followed by the length of the actual message, and finally
3080 the message itself.  This kind of packing can be achieved with
3081 C<pack("l! a*", $type, $message)>.  Returns true if successful,
3082 or false if there is an error.  See also C<IPC::SysV>
3083 and C<IPC::SysV::Msg> documentation.
3084
3085 =item my EXPR
3086 X<my>
3087
3088 =item my TYPE EXPR
3089
3090 =item my EXPR : ATTRS
3091
3092 =item my TYPE EXPR : ATTRS
3093
3094 A C<my> declares the listed variables to be local (lexically) to the
3095 enclosing block, file, or C<eval>.  If more than one value is listed,
3096 the list must be placed in parentheses.
3097
3098 The exact semantics and interface of TYPE and ATTRS are still
3099 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3100 and attributes are handled using the C<attributes> pragma, or starting
3101 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3102 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3103 L<attributes>, and L<Attribute::Handlers>.
3104
3105 =item next LABEL
3106 X<next> X<continue>
3107
3108 =item next
3109
3110 The C<next> command is like the C<continue> statement in C; it starts
3111 the next iteration of the loop:
3112
3113     LINE: while (<STDIN>) {
3114         next LINE if /^#/;  # discard comments
3115         #...
3116     }
3117
3118 Note that if there were a C<continue> block on the above, it would get
3119 executed even on discarded lines.  If LABEL is omitted, the command
3120 refers to the innermost enclosing loop.
3121
3122 C<next> cannot be used to exit a block which returns a value such as
3123 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
3124 a grep() or map() operation.
3125
3126 Note that a block by itself is semantically identical to a loop
3127 that executes once.  Thus C<next> will exit such a block early.
3128
3129 See also L</continue> for an illustration of how C<last>, C<next>, and
3130 C<redo> work.
3131
3132 =item no MODULE VERSION LIST
3133 X<no declarations>
3134 X<unimporting>
3135
3136 =item no MODULE VERSION
3137
3138 =item no MODULE LIST
3139
3140 =item no MODULE
3141
3142 =item no VERSION
3143
3144 See the C<use> function, of which C<no> is the opposite.
3145
3146 =item oct EXPR
3147 X<oct> X<octal> X<hex> X<hexadecimal> X<binary> X<bin>
3148
3149 =item oct
3150
3151 Interprets EXPR as an octal string and returns the corresponding
3152 value.  (If EXPR happens to start off with C<0x>, interprets it as a
3153 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
3154 binary string.  Leading whitespace is ignored in all three cases.)
3155 The following will handle decimal, binary, octal, and hex in standard
3156 Perl notation:
3157
3158     $val = oct($val) if $val =~ /^0/;
3159
3160 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
3161 in octal), use sprintf() or printf():
3162
3163     $dec_perms = (stat("filename"))[2] & 07777;
3164     $oct_perm_str = sprintf "%o", $perms;
3165
3166 The oct() function is commonly used when a string such as C<644> needs
3167 to be converted into a file mode, for example.  Although Perl 
3168 automatically converts strings into numbers as needed, this automatic
3169 conversion assumes base 10.
3170
3171 Leading white space is ignored without warning, as too are any trailing 
3172 non-digits, such as a decimal point (C<oct> only handles non-negative
3173 integers, not negative integers or floating point).
3174
3175 =item open FILEHANDLE,EXPR
3176 X<open> X<pipe> X<file, open> X<fopen>
3177
3178 =item open FILEHANDLE,MODE,EXPR
3179
3180 =item open FILEHANDLE,MODE,EXPR,LIST
3181
3182 =item open FILEHANDLE,MODE,REFERENCE
3183
3184 =item open FILEHANDLE
3185
3186 Opens the file whose filename is given by EXPR, and associates it with
3187 FILEHANDLE.
3188
3189 Simple examples to open a file for reading:
3190
3191     open(my $fh, '<', "input.txt") or die $!;
3192
3193 and for writing:
3194
3195     open(my $fh, '>', "output.txt") or die $!;
3196
3197 (The following is a comprehensive reference to open(): for a gentler
3198 introduction you may consider L<perlopentut>.)
3199
3200 If FILEHANDLE is an undefined scalar variable (or array or hash element)
3201 the variable is assigned a reference to a new anonymous filehandle,
3202 otherwise if FILEHANDLE is an expression, its value is used as the name of
3203 the real filehandle wanted.  (This is considered a symbolic reference, so
3204 C<use strict 'refs'> should I<not> be in effect.)
3205
3206 If EXPR is omitted, the scalar variable of the same name as the
3207 FILEHANDLE contains the filename.  (Note that lexical variables--those
3208 declared with C<my>--will not work for this purpose; so if you're
3209 using C<my>, specify EXPR in your call to open.)
3210
3211 If three or more arguments are specified then the mode of opening and
3212 the filename are separate. If MODE is C<< '<' >> or nothing, the file
3213 is opened for input.  If MODE is C<< '>' >>, the file is truncated and
3214 opened for output, being created if necessary.  If MODE is C<<< '>>' >>>,
3215 the file is opened for appending, again being created if necessary.
3216
3217 You can put a C<'+'> in front of the C<< '>' >> or C<< '<' >> to
3218 indicate that you want both read and write access to the file; thus
3219 C<< '+<' >> is almost always preferred for read/write updates--the 
3220 C<< '+>' >> mode would clobber the file first.  You can't usually use
3221 either read-write mode for updating textfiles, since they have
3222 variable length records.  See the B<-i> switch in L<perlrun> for a
3223 better approach.  The file is created with permissions of C<0666>
3224 modified by the process's C<umask> value.
3225
3226 These various prefixes correspond to the fopen(3) modes of C<'r'>,
3227 C<'r+'>, C<'w'>, C<'w+'>, C<'a'>, and C<'a+'>.
3228
3229 In the two-argument (and one-argument) form of the call, the mode and
3230 filename should be concatenated (in that order), possibly separated by
3231 spaces.  You may omit the mode in these forms when that mode is
3232 C<< '<' >>.
3233
3234 If the filename begins with C<'|'>, the filename is interpreted as a
3235 command to which output is to be piped, and if the filename ends with a
3236 C<'|'>, the filename is interpreted as a command that pipes output to
3237 us.  See L<perlipc/"Using open() for IPC">
3238 for more examples of this.  (You are not allowed to C<open> to a command
3239 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
3240 and L<perlipc/"Bidirectional Communication with Another Process">
3241 for alternatives.)
3242
3243 For three or more arguments if MODE is C<'|-'>, the filename is
3244 interpreted as a command to which output is to be piped, and if MODE
3245 is C<'-|'>, the filename is interpreted as a command that pipes
3246 output to us.  In the two-argument (and one-argument) form, one should
3247 replace dash (C<'-'>) with the command.
3248 See L<perlipc/"Using open() for IPC"> for more examples of this.
3249 (You are not allowed to C<open> to a command that pipes both in I<and>
3250 out, but see L<IPC::Open2>, L<IPC::Open3>, and
3251 L<perlipc/"Bidirectional Communication"> for alternatives.)
3252
3253 In the form of pipe opens taking three or more arguments, if LIST is specified
3254 (extra arguments after the command name) then LIST becomes arguments
3255 to the command invoked if the platform supports it.  The meaning of
3256 C<open> with more than three arguments for non-pipe modes is not yet
3257 defined, but experimental "layers" may give extra LIST arguments
3258 meaning.
3259
3260 In the two-argument (and one-argument) form, opening C<< '<-' >> 
3261 or C<'-'> opens STDIN and opening C<< '>-' >> opens STDOUT.
3262
3263 You may use the three-argument form of open to specify I/O layers
3264 (sometimes referred to as "disciplines") to apply to the handle
3265 that affect how the input and output are processed (see L<open> and
3266 L<PerlIO> for more details). For example:
3267
3268   open(my $fh, "<:encoding(UTF-8)", "filename")
3269     || die "can't open UTF-8 encoded filename: $!";
3270
3271 opens the UTF-8 encoded file containing Unicode characters;
3272 see L<perluniintro>. Note that if layers are specified in the
3273 three-argument form, then default layers stored in ${^OPEN} (see L<perlvar>;
3274 usually set by the B<open> pragma or the switch B<-CioD>) are ignored.
3275
3276 Open returns nonzero on success, the undefined value otherwise.  If
3277 the C<open> involved a pipe, the return value happens to be the pid of
3278 the subprocess.
3279
3280 If you're running Perl on a system that distinguishes between text
3281 files and binary files, then you should check out L</binmode> for tips
3282 for dealing with this.  The key distinction between systems that need
3283 C<binmode> and those that don't is their text file formats.  Systems
3284 like Unix, Mac OS, and Plan 9, that end lines with a single
3285 character and encode that character in C as C<"\n"> do not
3286 need C<binmode>.  The rest need it.
3287
3288 When opening a file, it's seldom a good idea to continue 
3289 if the request failed, so C<open> is frequently used with
3290 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
3291 where you want to format a suitable error message (but there are
3292 modules that can help with that problem)) always check
3293 the return value from opening a file.  
3294
3295 As a special case the 3-arg form with a read/write mode and the third
3296 argument being C<undef>:
3297
3298     open(my $tmp, "+>", undef) or die ...
3299
3300 opens a filehandle to an anonymous temporary file.  Also using "+<"
3301 works for symmetry, but you really should consider writing something
3302 to the temporary file first.  You will need to seek() to do the
3303 reading.
3304
3305 Since v5.8.0, Perl has built using PerlIO by default.  Unless you've
3306 changed this (i.e., Configure -Uuseperlio), you can open filehandles 
3307 directly to Perl scalars via:
3308
3309     open($fh, '>', \$variable) || ..
3310
3311 To (re)open C<STDOUT> or C<STDERR> as an in-memory file, close it first:
3312
3313     close STDOUT;
3314     open STDOUT, '>', \$variable or die "Can't open STDOUT: $!";
3315
3316 General examples:
3317
3318     $ARTICLE = 100;
3319     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
3320     while (<ARTICLE>) {...
3321
3322     open(LOG, '>>/usr/spool/news/twitlog');  # (log is reserved)
3323     # if the open fails, output is discarded
3324
3325     open(my $dbase, '+<', 'dbase.mine')      # open for update
3326         or die "Can't open 'dbase.mine' for update: $!";
3327
3328     open(my $dbase, '+<dbase.mine')          # ditto
3329         or die "Can't open 'dbase.mine' for update: $!";
3330
3331     open(ARTICLE, '-|', "caesar <$article")  # decrypt article
3332         or die "Can't start caesar: $!";
3333
3334     open(ARTICLE, "caesar <$article |")      # ditto
3335         or die "Can't start caesar: $!";
3336
3337     open(EXTRACT, "|sort >Tmp$$")            # $$ is our process id
3338         or die "Can't start sort: $!";
3339
3340     # in-memory files
3341     open(MEMORY,'>', \$var)
3342         or die "Can't open memory file: $!";
3343     print MEMORY "foo!\n";                   # output will appear in $var
3344
3345     # process argument list of files along with any includes
3346
3347     foreach $file (@ARGV) {
3348         process($file, 'fh00');
3349     }
3350
3351     sub process {
3352         my($filename, $input) = @_;
3353         $input++;    # this is a string increment
3354         unless (open($input, $filename)) {
3355             print STDERR "Can't open $filename: $!\n";
3356             return;
3357         }
3358
3359         local $_;
3360         while (<$input>) {    # note use of indirection
3361             if (/^#include "(.*)"/) {
3362                 process($1, $input);
3363                 next;
3364             }
3365             #...          # whatever
3366         }
3367     }
3368
3369 See L<perliol> for detailed info on PerlIO.
3370
3371 You may also, in the Bourne shell tradition, specify an EXPR beginning
3372 with C<< '>&' >>, in which case the rest of the string is interpreted
3373 as the name of a filehandle (or file descriptor, if numeric) to be
3374 duped (as C<dup(2)>) and opened.  You may use C<&> after C<< > >>,
3375 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
3376 The mode you specify should match the mode of the original filehandle.
3377 (Duping a filehandle does not take into account any existing contents
3378 of IO buffers.) If you use the 3-arg form then you can pass either a
3379 number, the name of a filehandle or the normal "reference to a glob".
3380
3381 Here is a script that saves, redirects, and restores C<STDOUT> and
3382 C<STDERR> using various methods:
3383
3384     #!/usr/bin/perl
3385     open my $oldout, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3386     open OLDERR,     ">&", \*STDERR or die "Can't dup STDERR: $!";
3387
3388     open STDOUT, '>', "foo.out" or die "Can't redirect STDOUT: $!";
3389     open STDERR, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3390
3391     select STDERR; $| = 1;  # make unbuffered
3392     select STDOUT; $| = 1;  # make unbuffered
3393
3394     print STDOUT "stdout 1\n";  # this works for
3395     print STDERR "stderr 1\n";  # subprocesses too
3396
3397     open STDOUT, ">&", $oldout or die "Can't dup \$oldout: $!";
3398     open STDERR, ">&OLDERR"    or die "Can't dup OLDERR: $!";
3399
3400     print STDOUT "stdout 2\n";
3401     print STDERR "stderr 2\n";
3402
3403 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
3404 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
3405 that file descriptor (and not call C<dup(2)>); this is more
3406 parsimonious of file descriptors.  For example:
3407
3408     # open for input, reusing the fileno of $fd
3409     open(FILEHANDLE, "<&=$fd")
3410
3411 or
3412
3413     open(FILEHANDLE, "<&=", $fd)
3414
3415 or
3416
3417     # open for append, using the fileno of OLDFH
3418     open(FH, ">>&=", OLDFH)
3419
3420 or
3421
3422     open(FH, ">>&=OLDFH")
3423
3424 Being parsimonious on filehandles is also useful (besides being
3425 parsimonious) for example when something is dependent on file
3426 descriptors, like for example locking using flock().  If you do just
3427 C<< open(A, '>>&B') >>, the filehandle A will not have the same file
3428 descriptor as B, and therefore flock(A) will not flock(B), and vice
3429 versa.  But with C<< open(A, '>>&=B') >> the filehandles will share
3430 the same file descriptor.
3431
3432 Note that if you are using Perls older than 5.8.0, Perl will be using
3433 the standard C libraries' fdopen() to implement the "=" functionality.
3434 On many Unix systems fdopen() fails when file descriptors exceed a
3435 certain value, typically 255.  For Perls 5.8.0 and later, PerlIO is
3436 most often the default.
3437
3438 You can see whether Perl has been compiled with PerlIO or not by
3439 running C<perl -V> and looking for C<useperlio=> line.  If C<useperlio>
3440 is C<define>, you have PerlIO, otherwise you don't.
3441
3442 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
3443 with 2-arguments (or 1-argument) form of open(), then
3444 there is an implicit fork done, and the return value of open is the pid
3445 of the child within the parent process, and C<0> within the child
3446 process.  (Use C<defined($pid)> to determine whether the open was successful.)
3447 The filehandle behaves normally for the parent, but I/O to that
3448 filehandle is piped from/to the STDOUT/STDIN of the child process.
3449 In the child process, the filehandle isn't opened--I/O happens from/to
3450 the new STDOUT/STDIN.  Typically this is used like the normal
3451 piped open when you want to exercise more control over just how the
3452 pipe command gets executed, such as when running setuid and
3453 you don't want to have to scan shell commands for metacharacters.
3454
3455 The following triples are more or less equivalent:
3456
3457     open(FOO, "|tr '[a-z]' '[A-Z]'");
3458     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
3459     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
3460     open(FOO, '|-', "tr", '[a-z]', '[A-Z]');
3461
3462     open(FOO, "cat -n '$file'|");
3463     open(FOO, '-|', "cat -n '$file'");
3464     open(FOO, '-|') || exec 'cat', '-n', $file;
3465     open(FOO, '-|', "cat", '-n', $file);
3466
3467 The last example in each block shows the pipe as "list form", which is
3468 not yet supported on all platforms.  A good rule of thumb is that if
3469 your platform has true C<fork()> (in other words, if your platform is
3470 Unix) you can use the list form.
3471
3472 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
3473
3474 Beginning with v5.6.0, Perl will attempt to flush all files opened for
3475 output before any operation that may do a fork, but this may not be
3476 supported on some platforms (see L<perlport>).  To be safe, you may need
3477 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
3478 of C<IO::Handle> on any open handles.
3479
3480 On systems that support a close-on-exec flag on files, the flag will
3481 be set for the newly opened file descriptor as determined by the value
3482 of $^F.  See L<perlvar/$^F>.
3483
3484 Closing any piped filehandle causes the parent process to wait for the
3485 child to finish, and returns the status value in C<$?> and
3486 C<${^CHILD_ERROR_NATIVE}>.
3487
3488 The filename passed to 2-argument (or 1-argument) form of open() will
3489 have leading and trailing whitespace deleted, and the normal
3490 redirection characters honored.  This property, known as "magic open",
3491 can often be used to good effect.  A user could specify a filename of
3492 F<"rsh cat file |">, or you could change certain filenames as needed:
3493
3494     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
3495     open(FH, $filename) or die "Can't open $filename: $!";
3496
3497 Use 3-argument form to open a file with arbitrary weird characters in it,
3498
3499     open(FOO, '<', $file);
3500
3501 otherwise it's necessary to protect any leading and trailing whitespace:
3502
3503     $file =~ s#^(\s)#./$1#;
3504     open(FOO, "< $file\0");
3505
3506 (this may not work on some bizarre filesystems).  One should
3507 conscientiously choose between the I<magic> and 3-arguments form
3508 of open():
3509
3510     open IN, $ARGV[0];
3511
3512 will allow the user to specify an argument of the form C<"rsh cat file |">,
3513 but will not work on a filename that happens to have a trailing space, while
3514
3515     open IN, '<', $ARGV[0];
3516
3517 will have exactly the opposite restrictions.
3518
3519 If you want a "real" C C<open> (see C<open(2)> on your system), then you
3520 should use the C<sysopen> function, which involves no such magic (but
3521 may use subtly different filemodes than Perl open(), which is mapped
3522 to C fopen()).  This is
3523 another way to protect your filenames from interpretation.  For example:
3524
3525     use IO::Handle;
3526     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
3527         or die "sysopen $path: $!";
3528     $oldfh = select(HANDLE); $| = 1; select($oldfh);
3529     print HANDLE "stuff $$\n";
3530     seek(HANDLE, 0, 0);
3531     print "File contains: ", <HANDLE>;
3532
3533 Using the constructor from the C<IO::Handle> package (or one of its
3534 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3535 filehandles that have the scope of whatever variables hold references to
3536 them, and automatically close whenever and however you leave that scope:
3537
3538     use IO::File;
3539     #...
3540     sub read_myfile_munged {
3541         my $ALL = shift;
3542         my $handle = IO::File->new;
3543         open($handle, "myfile") or die "myfile: $!";
3544         $first = <$handle>
3545             or return ();     # Automatically closed here.
3546         mung $first or die "mung failed";  # Or here.
3547         return $first, <$handle> if $ALL;  # Or here.
3548         $first;          # Or here.
3549     }
3550
3551 See L</seek> for some details about mixing reading and writing.
3552
3553 =item opendir DIRHANDLE,EXPR
3554 X<opendir>
3555
3556 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3557 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3558 DIRHANDLE may be an expression whose value can be used as an indirect
3559 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
3560 scalar variable (or array or hash element), the variable is assigned a
3561 reference to a new anonymous dirhandle.
3562 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3563
3564 See example at C<readdir>.
3565
3566 =item ord EXPR
3567 X<ord> X<encoding>
3568
3569 =item ord
3570
3571 Returns the numeric (the native 8-bit encoding, like ASCII or EBCDIC,
3572 or Unicode) value of the first character of EXPR.  If EXPR is omitted,
3573 uses C<$_>.
3574
3575 For the reverse, see L</chr>.
3576 See L<perlunicode> for more about Unicode.
3577
3578 =item our EXPR
3579 X<our> X<global>
3580
3581 =item our TYPE EXPR
3582
3583 =item our EXPR : ATTRS
3584
3585 =item our TYPE EXPR : ATTRS
3586
3587 C<our> associates a simple name with a package variable in the current
3588 package for use within the current scope.  When C<use strict 'vars'> is in
3589 effect, C<our> lets you use declared global variables without qualifying
3590 them with package names, within the lexical scope of the C<our> declaration.
3591 In this way C<our> differs from C<use vars>, which is package scoped.
3592
3593 Unlike C<my>, which both allocates storage for a variable and associates
3594 a simple name with that storage for use within the current scope, C<our>
3595 associates a simple name with a package variable in the current package,
3596 for use within the current scope.  In other words, C<our> has the same
3597 scoping rules as C<my>, but does not necessarily create a
3598 variable.
3599
3600 If more than one value is listed, the list must be placed
3601 in parentheses.
3602
3603     our $foo;
3604     our($bar, $baz);
3605
3606 An C<our> declaration declares a global variable that will be visible
3607 across its entire lexical scope, even across package boundaries.  The
3608 package in which the variable is entered is determined at the point
3609 of the declaration, not at the point of use.  This means the following
3610 behavior holds:
3611
3612     package Foo;
3613     our $bar;      # declares $Foo::bar for rest of lexical scope
3614     $bar = 20;
3615
3616     package Bar;
3617     print $bar;    # prints 20, as it refers to $Foo::bar
3618
3619 Multiple C<our> declarations with the same name in the same lexical
3620 scope are allowed if they are in different packages.  If they happen
3621 to be in the same package, Perl will emit warnings if you have asked
3622 for them, just like multiple C<my> declarations.  Unlike a second
3623 C<my> declaration, which will bind the name to a fresh variable, a
3624 second C<our> declaration in the same package, in the same scope, is
3625 merely redundant.
3626
3627     use warnings;
3628     package Foo;
3629     our $bar;      # declares $Foo::bar for rest of lexical scope
3630     $bar = 20;
3631
3632     package Bar;
3633     our $bar = 30; # declares $Bar::bar for rest of lexical scope
3634     print $bar;    # prints 30
3635
3636     our $bar;      # emits warning but has no other effect
3637     print $bar;    # still prints 30
3638
3639 An C<our> declaration may also have a list of attributes associated
3640 with it.
3641
3642 The exact semantics and interface of TYPE and ATTRS are still
3643 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3644 and attributes are handled using the C<attributes> pragma, or starting
3645 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3646 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3647 L<attributes>, and L<Attribute::Handlers>.
3648
3649 =item pack TEMPLATE,LIST
3650 X<pack>
3651
3652 Takes a LIST of values and converts it into a string using the rules
3653 given by the TEMPLATE.  The resulting string is the concatenation of
3654 the converted values.  Typically, each converted value looks
3655 like its machine-level representation.  For example, on 32-bit machines
3656 an integer may be represented by a sequence of 4 bytes, which  will in
3657 Perl be presented as a string that's 4 characters long. 
3658
3659 See L<perlpacktut> for an introduction to this function.
3660
3661 The TEMPLATE is a sequence of characters that give the order and type
3662 of values, as follows:
3663
3664     a  A string with arbitrary binary data, will be null padded.
3665     A  A text (ASCII) string, will be space padded.
3666     Z  A null-terminated (ASCIZ) string, will be null padded.
3667
3668     b  A bit string (ascending bit order inside each byte, like vec()).
3669     B  A bit string (descending bit order inside each byte).
3670     h  A hex string (low nybble first).
3671     H  A hex string (high nybble first).
3672
3673     c  A signed char (8-bit) value.
3674     C  An unsigned char (octet) value.
3675     W  An unsigned char value (can be greater than 255).
3676
3677     s  A signed short (16-bit) value.
3678     S  An unsigned short value.
3679
3680     l  A signed long (32-bit) value.
3681     L  An unsigned long value.
3682
3683     q  A signed quad (64-bit) value.
3684     Q  An unsigned quad value.
3685       (Quads are available only if your system supports 64-bit
3686        integer values _and_ if Perl has been compiled to support those.
3687            Raises an exception otherwise.)
3688
3689     i  A signed integer value.
3690     I  A unsigned integer value.
3691       (This 'integer' is _at_least_ 32 bits wide.  Its exact
3692            size depends on what a local C compiler calls 'int'.)
3693
3694     n  An unsigned short (16-bit) in "network" (big-endian) order.
3695     N  An unsigned long (32-bit) in "network" (big-endian) order.
3696     v  An unsigned short (16-bit) in "VAX" (little-endian) order.
3697     V  An unsigned long (32-bit) in "VAX" (little-endian) order.
3698
3699     j   A Perl internal signed integer value (IV).
3700     J   A Perl internal unsigned integer value (UV).
3701
3702     f  A single-precision float in native format.
3703     d  A double-precision float in native format.
3704
3705     F  A Perl internal floating-point value (NV) in native format
3706     D  A float of long-double precision in native format.
3707       (Long doubles are available only if your system supports long
3708        double values _and_ if Perl has been compiled to support those.
3709            Raises an exception otherwise.)
3710
3711     p  A pointer to a null-terminated string.
3712     P  A pointer to a structure (fixed-length string).
3713
3714     u  A uuencoded string.
3715     U  A Unicode character number.  Encodes to a character in character mode
3716         and UTF-8 (or UTF-EBCDIC in EBCDIC platforms) in byte mode.
3717
3718     w  A BER compressed integer (not an ASN.1 BER, see perlpacktut for
3719        details).  Its bytes represent an unsigned integer in base 128,
3720        most significant digit first, with as few digits as possible.  Bit
3721        eight (the high bit) is set on each byte except the last.
3722
3723     x  A null byte (a.k.a ASCII NUL, "\000", chr(0))
3724     X  Back up a byte.
3725     @  Null-fill or truncate to absolute position, counted from the
3726        start of the innermost ()-group.
3727     .  Null-fill or truncate to absolute position specified by the value.
3728     (  Start of a ()-group.
3729
3730 One or more modifiers below may optionally follow certain letters in the
3731 TEMPLATE (the second column lists letters for which the modifier is valid):
3732
3733     !   sSlLiI     Forces native (short, long, int) sizes instead
3734                    of fixed (16-/32-bit) sizes.
3735
3736         xX         Make x and X act as alignment commands.
3737
3738         nNvV       Treat integers as signed instead of unsigned.
3739
3740         @.         Specify position as byte offset in the internal
3741                    representation of the packed string. Efficient but
3742                    dangerous.
3743
3744     >   sSiIlLqQ   Force big-endian byte-order on the type.
3745         jJfFdDpP   (The "big end" touches the construct.)
3746
3747     <   sSiIlLqQ   Force little-endian byte-order on the type.
3748         jJfFdDpP   (The "little end" touches the construct.)
3749
3750 The C<< > >> and C<< < >> modifiers can also be used on C<()> groups 
3751 to force a particular byte-order on all components in that group, 
3752 including all its subgroups.
3753
3754 The following rules apply:
3755
3756 =over 
3757
3758 =item *
3759
3760 Each letter may optionally be followed by a number indicating the repeat
3761 count.  A numeric repeat count may optionally be enclosed in brackets, as
3762 in C<pack("C[80]", @arr)>.  The repeat count gobbles that many values from
3763 the LIST when used with all format types other than C<a>, C<A>, C<Z>, C<b>,
3764 C<B>, C<h>, C<H>, C<@>, C<.>, C<x>, C<X>, and C<P>, where it means
3765 something else, dscribed below.  Supplying a C<*> for the repeat count
3766 instead of a number means to use however many items are left, except for:
3767
3768 =over 
3769
3770 =item * 
3771
3772 C<@>, C<x>, and C<X>, where it is equivalent to C<0>.
3773
3774 =item * 
3775
3776 <.>, where it means relative to the start of the string.
3777
3778 =item * 
3779
3780 C<u>, where it is equivalent to 1 (or 45, which here is equivalent).
3781
3782 =back 
3783
3784 One can replace a numeric repeat count with a template letter enclosed in
3785 brackets to use the packed byte length of the bracketed template for the
3786 repeat count.
3787
3788 For example, the template C<x[L]> skips as many bytes as in a packed long,
3789 and the template C<"$t X[$t] $t"> unpacks twice whatever $t (when
3790 variable-expanded) unpacks.  If the template in brackets contains alignment
3791 commands (such as C<x![d]>), its packed length is calculated as if the
3792 start of the template had the maximal possible alignment.
3793
3794 When used with C<Z>, a C<*> as the repeat count is guaranteed to add a
3795 trailing null byte, so the resulting string is always one byte longer than
3796 the byte length of the item itself.
3797
3798 When used with C<@>, the repeat count represents an offset from the start
3799 of the innermost C<()> group.
3800
3801 When used with C<.>, the repeat count determines the starting position to
3802 calculate the value offset as follows:
3803
3804 =over 
3805
3806 =item *
3807
3808 If the repeat count is C<0>, it's relative to the current position.
3809
3810 =item *
3811
3812 If the repeat count is C<*>, the offset is relative to the start of the
3813 packed string.
3814
3815 =item *
3816
3817 And if it's an integer I<n>, the offset is relative to the start of the
3818 I<n>th innermost C<()> group, or to the start of the string if I<n> is
3819 bigger then the group level.
3820
3821 =back
3822
3823 The repeat count for C<u> is interpreted as the maximal number of bytes
3824 to encode per line of output, with 0, 1 and 2 replaced by 45. The repeat 
3825 count should not be more than 65.
3826
3827 =item *
3828
3829 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
3830 string of length count, padding with nulls or spaces as needed.  When
3831 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
3832 after the first null, and C<a> returns data without any sort of trimming.
3833
3834 If the value to pack is too long, the result is truncated.  If it's too
3835 long and an explicit count is provided, C<Z> packs only C<$count-1> bytes,
3836 followed by a null byte.  Thus C<Z> always packs a trailing null, except
3837 for when the count is 0.
3838
3839 =item *
3840
3841 Likewise, the C<b> and C<B> formats pack a string that's that many bits long.
3842 Each such format generates 1 bit of the result.
3843
3844 Each result bit is based on the least-significant bit of the corresponding
3845 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
3846 and C<"1"> generate bits 0 and 1, as do characters C<"\000"> and C<"\001">.
3847
3848 Starting from the beginning of the input string, each 8-tuple
3849 of characters is converted to 1 character of output.  With format C<b>,
3850 the first character of the 8-tuple determines the least-significant bit of a
3851 character; with format C<B>, it determines the most-significant bit of
3852 a character.
3853
3854 If the length of the input string is not evenly divisible by 8, the
3855 remainder is packed as if the input string were padded by null characters
3856 at the end.  Similarly during unpacking, "extra" bits are ignored.
3857
3858 If the input string is longer than needed, remaining characters are ignored.
3859
3860 A C<*> for the repeat count uses all characters of the input field.  
3861 On unpacking, bits are converted to a string of C<"0">s and C<"1">s.
3862
3863 =item *
3864
3865 The C<h> and C<H> formats pack a string that many nybbles (4-bit groups,
3866 representable as hexadecimal digits, C<"0".."9"> C<"a".."f">) long.
3867
3868 For each such format, pack() generates 4 bits of the result.
3869 With non-alphabetical characters, the result is based on the 4 least-significant
3870 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
3871 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
3872 C<"\0"> and C<"\1">.  For characters C<"a".."f"> and C<"A".."F">, the result
3873 is compatible with the usual hexadecimal digits, so that C<"a"> and
3874 C<"A"> both generate the nybble C<0xa==10>.  Do not use any characters
3875 but these with this format.
3876
3877 Starting from the beginning of the template to pack(), each pair
3878 of characters is converted to 1 character of output.  With format C<h>, the
3879 first character of the pair determines the least-significant nybble of the
3880 output character; with format C<H>, it determines the most-significant
3881 nybble.
3882
3883 If the length of the input string is not even, it behaves as if padded by
3884 a null character at the end.  Similarly, "extra" nybbles are ignored during
3885 unpacking.
3886
3887 If the input string is longer than needed, extra characters are ignored.
3888
3889 A C<*> for the repeat count uses all characters of the input field.  For
3890 unpack(), nybbles are converted to a string of hexadecimal digits.
3891
3892 =item *
3893
3894 The C<p> format packs a pointer to a null-terminated string.  You are
3895 responsible for ensuring that the string is not a temporary value, as that
3896 could potentially get deallocated before you got around to using the packed
3897 result.  The C<P> format packs a pointer to a structure of the size indicated
3898 by the length.  A null pointer is created if the corresponding value for
3899 C<p> or C<P> is C<undef>; similarly with unpack(), where a null pointer
3900 unpacks into C<undef>.
3901
3902 If your system has a strange pointer size--meaning a pointer is neither as
3903 big as an int nor as big as a long--it may not be possible to pack or
3904 unpack pointers in big- or little-endian byte order.  Attempting to do
3905 so raises an exception.
3906
3907 =item *
3908
3909 The C</> template character allows packing and unpacking of a sequence of
3910 items where the packed structure contains a packed item count followed by
3911 the packed items themselves.  This is useful when the structure you're
3912 unpacking has encoded the sizes or repeat counts for some of its fields
3913 within the structure itself as separate fields.
3914
3915 For C<pack>, you write I<length-item>C</>I<sequence-item>, and the
3916 I<length-item> describes how the length value is packed. Formats likely
3917 to be of most use are integer-packing ones like C<n> for Java strings,
3918 C<w> for ASN.1 or SNMP, and C<N> for Sun XDR.
3919
3920 For C<pack>, I<sequence-item> may have a repeat count, in which case
3921 the minimum of that and the number of available items is used as the argument
3922 for I<length-item>. If it has no repeat count or uses a '*', the number
3923 of available items is used.
3924
3925 For C<unpack>, an internal stack of integer arguments unpacked so far is
3926 used. You write C</>I<sequence-item> and the repeat count is obtained by
3927 popping off the last element from the stack. The I<sequence-item> must not
3928 have a repeat count.
3929
3930 If I<sequence-item> refers to a string type (C<"A">, C<"a">, or C<"Z">),
3931 the I<length-item> is the string length, not the number of strings.  With
3932 an explicit repeat count for pack, the packed string is adjusted to that
3933 length.  For example:
3934
3935     unpack("W/a", "\04Gurusamy")            gives ("Guru")
3936     unpack("a3/A A*", "007 Bond  J ")       gives (" Bond", "J")
3937     unpack("a3 x2 /A A*", "007: Bond, J.")  gives ("Bond, J", ".")
3938
3939     pack("n/a* w/a","hello,","world")       gives "\000\006hello,\005world"
3940     pack("a/W2", ord("a") .. ord("z"))      gives "2ab"
3941
3942 The I<length-item> is not returned explicitly from C<unpack>.
3943
3944 Supplying a count to the I<length-item> format letter is only useful with
3945 C<A>, C<a>, or C<Z>.  Packing with a I<length-item> of C<a> or C<Z> may
3946 introduce C<"\000"> characters, which Perl does not regard as legal in
3947 numeric strings.
3948
3949 =item *
3950
3951 The integer types C<s>, C<S>, C<l>, and C<L> may be
3952 followed by a C<!> modifier to specify native shorts or
3953 longs.  As shown in the example above, a bare C<l> means
3954 exactly 32 bits, although the native C<long> as seen by the local C compiler
3955 may be larger.  This is mainly an issue on 64-bit platforms.  You can
3956 see whether using C<!> makes any difference this way:
3957
3958     printf "format s is %d, s! is %d\n", 
3959         length pack("s"), length pack("s!");
3960
3961     printf "format l is %d, l! is %d\n", 
3962         length pack("l"), length pack("l!");
3963
3964
3965 C<i!> and C<I!> are also allowed, but only for completeness' sake:
3966 they are identical to C<i> and C<I>.
3967
3968 The actual sizes (in bytes) of native shorts, ints, longs, and long
3969 longs on the platform where Perl was built are also available from
3970 the command line:
3971
3972     $ perl -V:{short,int,long{,long}}size
3973     shortsize='2';
3974     intsize='4';
3975     longsize='4';
3976     longlongsize='8';
3977
3978 or programmatically via the C<Config> module:
3979
3980        use Config;
3981        print $Config{shortsize},    "\n";
3982        print $Config{intsize},      "\n";
3983        print $Config{longsize},     "\n";
3984        print $Config{longlongsize}, "\n";
3985
3986 C<$Config{longlongsize}> is undefined on systems without 
3987 long long support.
3988
3989 =item *
3990
3991 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J> are
3992 inherently non-portable between processors and operating systems because
3993 they obey native byteorder and endianness.  For example, a 4-byte integer
3994 0x12345678 (305419896 decimal) would be ordered natively (arranged in and
3995 handled by the CPU registers) into bytes as
3996
3997     0x12 0x34 0x56 0x78  # big-endian
3998     0x78 0x56 0x34 0x12  # little-endian
3999
4000 Basically, Intel and VAX CPUs are little-endian, while everybody else,
4001 including Motorola m68k/88k, PPC, Sparc, HP PA, Power, and Cray, are
4002 big-endian.  Alpha and MIPS can be either: Digital/Compaq used/uses them in
4003 little-endian mode, but SGI/Cray uses them in big-endian mode.
4004
4005 The names I<big-endian> and I<little-endian> are comic references to the
4006 egg-eating habits of the little-endian Lilliputians and the big-endian
4007 Blefuscudians from the classic Jonathan Swift satire, I<Gulliver's Travels>.
4008 This entered computer lingo via the paper "On Holy Wars and a Plea for
4009 Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980.
4010
4011 Some systems may have even weirder byte orders such as
4012
4013    0x56 0x78 0x12 0x34
4014    0x34 0x12 0x78 0x56
4015
4016 You can determine your system endianness with this incantation:
4017
4018    printf("%#02x ", $_) for unpack("W*", pack L=>0x12345678); 
4019
4020 The byteorder on the platform where Perl was built is also available
4021 via L<Config>:
4022
4023     use Config;
4024     print "$Config{byteorder}\n";
4025
4026 or from the command line:
4027
4028     $ perl -V:byteorder
4029
4030 Byteorders C<"1234"> and C<"12345678"> are little-endian; C<"4321">
4031 and C<"87654321"> are big-endian.
4032
4033 For portably packed integers, either use the formats C<n>, C<N>, C<v>, 
4034 and C<V> or else use the C<< > >> and C<< < >> modifiers described
4035 immediately below.  See also L<perlport>.
4036
4037 =item *
4038
4039 Starting with Perl 5.9.2, integer and floating-point formats, along with
4040 the C<p> and C<P> formats and C<()> groups, may all be followed by the 
4041 C<< > >> or C<< < >> endianness modifiers to respectively enforce big-
4042 or little-endian byte-order.  These modifiers are especially useful 
4043 given how C<n>, C<N>, C<v> and C<V> don't cover signed integers, 
4044 64-bit integers, or floating-point values.
4045
4046 Here are some concerns to keep in mind when using endianness modifier:
4047
4048 =over
4049
4050 =item * 
4051
4052 Exchanging signed integers between different platforms works only 
4053 when all platforms store them in the same format.  Most platforms store
4054 signed integers in two's-complement notation, so usually this is not an issue.
4055
4056 =item * 
4057
4058 The C<< > >> or C<< < >> modifiers can only be used on floating-point
4059 formats on big- or little-endian machines.  Otherwise, attempting to
4060 use them raises an exception.
4061
4062 =item * 
4063
4064 Forcing big- or little-endian byte-order on floating-point values for
4065 data exchange can work only if all platforms use the same
4066 binary representation such as IEEE floating-point.  Even if all
4067 platforms are using IEEE, there may still be subtle differences.  Being able
4068 to use C<< > >> or C<< < >> on floating-point values can be useful,
4069 but also dangerous if you don't know exactly what you're doing.
4070 It is not a general way to portably store floating-point values.
4071
4072 =item * 
4073
4074 When using C<< > >> or C<< < >> on a C<()> group, this affects
4075 all types inside the group that accept byte-order modifiers,
4076 including all subgroups.  It is silently ignored for all other
4077 types.  You are not allowed to override the byte-order within a group
4078 that already has a byte-order modifier suffix.
4079
4080 =back
4081
4082 =item *
4083
4084 Real numbers (floats and doubles) are in native machine format only.
4085 Due to the multiplicity of floating-point formats and the lack of a
4086 standard "network" representation for them, no facility for interchange has been
4087 made.  This means that packed floating-point data written on one machine
4088 may not be readable on another, even if both use IEEE floating-point
4089 arithmetic (because the endianness of the memory representation is not part
4090 of the IEEE spec).  See also L<perlport>.
4091
4092 If you know I<exactly> what you're doing, you can use the C<< > >> or C<< < >>
4093 modifiers to force big- or little-endian byte-order on floating-point values.
4094
4095 Because Perl uses doubles (or long doubles, if configured) internally for
4096 all numeric calculation, converting from double into float and thence 
4097 to double again loses precision, so C<unpack("f", pack("f", $foo)>)
4098 will not in general equal $foo.
4099
4100 =item *
4101
4102 Pack and unpack can operate in two modes: character mode (C<C0> mode) where
4103 the packed string is processed per character, and UTF-8 mode (C<U0> mode)
4104 where the packed string is processed in its UTF-8-encoded Unicode form on
4105 a byte-by-byte basis. Character mode is the default unless the format string 
4106 starts with C<U>. You can always switch mode mid-format with an explicit 
4107 C<C0> or C<U0> in the format.  This mode remains in effect until the next 
4108 mode change, or until the end of the C<()> group it (directly) applies to.
4109
4110 =item *
4111
4112 You must yourself do any alignment or padding by inserting, for example,
4113 enough C<"x">es while packing.  There is no way for pack() and unpack()
4114 to know where characters are going to or coming from, so they 
4115 handle their output and input as flat sequences of characters.
4116
4117 =item *
4118
4119 A C<()> group is a sub-TEMPLATE enclosed in parentheses.  A group may
4120 take a repeat count either as postfix, or for unpack(), also via the C</>
4121 template character.  Within each repetition of a group, positioning with
4122 C<@> starts over at 0. Therefore, the result of
4123
4124     pack("@1A((@2A)@3A)", qw[X Y Z])
4125
4126 is the string C<"\0X\0\0YZ">.
4127
4128 =item *
4129
4130 C<x> and C<X> accept the C<!> modifier to act as alignment commands: they
4131 jump forward or back to the closest position aligned at a multiple of C<count>
4132 characters. For example, to pack() or unpack() a C structure like
4133
4134     struct {
4135         char   c;    /* one signed, 8-bit character */
4136         double d; 
4137         char   cc[2];
4138     }
4139
4140 one may need to use the template C<c x![d] d c[2]>.  This assumes that
4141 doubles must be aligned to the size of double.
4142
4143 For alignment commands, a C<count> of 0 is equivalent to a C<count> of 1;
4144 both are no-ops.
4145
4146 =item *
4147
4148 C<n>, C<N>, C<v> and C<V> accept the C<!> modifier to
4149 represent signed 16-/32-bit integers in big-/little-endian order.
4150 This is portable only when all platforms sharing packed data use the
4151 same binary representation for signed integers; for example, when all
4152 platforms use two's-complement representation.
4153
4154 =item *
4155
4156 Comments can be embedded in a TEMPLATE using C<#> through the end of line.
4157 White space can separate pack codes from each other, but modifiers and
4158 repeat counts must follow immediately.  Breaking complex templates into
4159 individual line-by-line components, suitably annotated, can do as much to
4160 improve legibility and maintainability of pack/unpack formats as C</x> can
4161 for complicated pattern matches.
4162
4163 =item *
4164
4165 If TEMPLATE requires more arguments that pack() is given, pack()
4166 assumes additional C<""> arguments.  If TEMPLATE requires fewer arguments
4167 than given, extra arguments are ignored.
4168
4169 =back
4170
4171 Examples:
4172
4173     $foo = pack("WWWW",65,66,67,68);
4174     # foo eq "ABCD"
4175     $foo = pack("W4",65,66,67,68);
4176     # same thing
4177     $foo = pack("W4",0x24b6,0x24b7,0x24b8,0x24b9);
4178     # same thing with Unicode circled letters.
4179     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
4180     # same thing with Unicode circled letters. You don't get the UTF-8
4181     # bytes because the U at the start of the format caused a switch to
4182     # U0-mode, so the UTF-8 bytes get joined into characters
4183     $foo = pack("C0U4",0x24b6,0x24b7,0x24b8,0x24b9);
4184     # foo eq "\xe2\x92\xb6\xe2\x92\xb7\xe2\x92\xb8\xe2\x92\xb9"
4185     # This is the UTF-8 encoding of the string in the previous example
4186
4187     $foo = pack("ccxxcc",65,66,67,68);
4188     # foo eq "AB\0\0CD"
4189
4190     # NOTE: The examples above featuring "W" and "c" are true
4191     # only on ASCII and ASCII-derived systems such as ISO Latin 1
4192     # and UTF-8.  On EBCDIC systems, the first example would be
4193     #      $foo = pack("WWWW",193,194,195,196);
4194
4195     $foo = pack("s2",1,2);
4196     # "\1\0\2\0" on little-endian
4197     # "\0\1\0\2" on big-endian
4198
4199     $foo = pack("a4","abcd","x","y","z");
4200     # "abcd"
4201
4202     $foo = pack("aaaa","abcd","x","y","z");
4203     # "axyz"
4204
4205     $foo = pack("a14","abcdefg");
4206     # "abcdefg\0\0\0\0\0\0\0"
4207
4208     $foo = pack("i9pl", gmtime);
4209     # a real struct tm (on my system anyway)
4210
4211     $utmp_template = "Z8 Z8 Z16 L";
4212     $utmp = pack($utmp_template, @utmp1);
4213     # a struct utmp (BSDish)
4214
4215     @utmp2 = unpack($utmp_template, $utmp);
4216     # "@utmp1" eq "@utmp2"
4217
4218     sub bintodec {
4219         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
4220     }
4221
4222     $foo = pack('sx2l', 12, 34);
4223     # short 12, two zero bytes padding, long 34
4224     $bar = pack('s@4l', 12, 34);
4225     # short 12, zero fill to position 4, long 34
4226     # $foo eq $bar
4227     $baz = pack('s.l', 12, 4, 34);
4228     # short 12, zero fill to position 4, long 34
4229
4230     $foo = pack('nN', 42, 4711);
4231     # pack big-endian 16- and 32-bit unsigned integers
4232     $foo = pack('S>L>', 42, 4711);
4233     # exactly the same
4234     $foo = pack('s<l<', -42, 4711);
4235     # pack little-endian 16- and 32-bit signed integers
4236     $foo = pack('(sl)<', -42, 4711);
4237     # exactly the same
4238
4239 The same template may generally also be used in unpack().
4240
4241 =item package NAMESPACE VERSION
4242 X<package> X<module> X<namespace> X<version>
4243
4244 =item package NAMESPACE
4245
4246 Declares the compilation unit as being in the given namespace.  The scope
4247 of the package declaration is from the declaration itself through the end
4248 of the enclosing block, file, or eval (the same as the C<my> operator).
4249 All further unqualified dynamic identifiers will be in this namespace.
4250 A package statement affects dynamic variables only, including those
4251 you've used C<local> on, but I<not> lexical variables, which are created
4252 with C<my> (or C<our> (or C<state>)).  Typically it would be the first 
4253 declaration in a file included by C<require> or C<use>.  You can switch into a
4254 package in more than one place, since this only determines which default 
4255 symbol table the compiler uses for the rest of that block.  You can refer to
4256 identifiers in other packages than the current one by prefixing the identifier
4257 with the package name and a double colon, as in C<$SomePack::var>
4258 or C<ThatPack::INPUT_HANDLE>.  If package name is omitted, the C<main>
4259 package as assumed.  That is, C<$::sail> is equivalent to
4260 C<$main::sail> (as well as to C<$main'sail>, still seen in ancient
4261 code, mostly from Perl 4).
4262
4263 If VERSION is provided, C<package> sets the C<$VERSION> variable in the given
4264 namespace to a L<version> object with the VERSION provided.  VERSION must be a
4265 "strict" style version number as defined by the L<version> module: a positive
4266 decimal number (integer or decimal-fraction) without exponentiation or else a
4267 dotted-decimal v-string with a leading 'v' character and at least three
4268 components.  You should set C<$VERSION> only once per package.
4269
4270 See L<perlmod/"Packages"> for more information about packages, modules,
4271 and classes.  See L<perlsub> for other scoping issues.
4272
4273 =item pipe READHANDLE,WRITEHANDLE
4274 X<pipe>
4275
4276 Opens a pair of connected pipes like the corresponding system call.
4277 Note that if you set up a loop of piped processes, deadlock can occur
4278 unless you are very careful.  In addition, note that Perl's pipes use
4279 IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE
4280 after each command, depending on the application.
4281
4282 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
4283 for examples of such things.
4284
4285 On systems that support a close-on-exec flag on files, that flag is set
4286 on all newly opened file descriptors whose C<fileno>s are I<higher> than 
4287 the current value of $^F (by default 2 for C<STDERR>).  See L<perlvar/$^F>.
4288
4289 =item pop ARRAY
4290 X<pop> X<stack>
4291
4292 =item pop
4293
4294 Pops and returns the last value of the array, shortening the array by
4295 one element.
4296
4297 Returns the undefined value if the array is empty, although this may also
4298 happen at other times.  If ARRAY is omitted, pops the C<@ARGV> array in the
4299 main program, but the C<@_> array in subroutines, just like C<shift>.
4300
4301 =item pos SCALAR
4302 X<pos> X<match, position>
4303
4304 =item pos
4305
4306 Returns the offset of where the last C<m//g> search left off for the variable
4307 in question (C<$_> is used when the variable is not specified).  Note that
4308 0 is a valid match offset.  C<undef> indicates that the search position
4309 is reset (usually due to match failure, but can also be because no match has
4310 yet been run on the scalar). C<pos> directly accesses the location used
4311 by the regexp engine to store the offset, so assigning to C<pos> will change
4312 that offset, and so will also influence the C<\G> zero-width assertion in
4313 regular expressions. Because a failed C<m//gc> match doesn't reset the offset,
4314 the return from C<pos> won't change either in this case.  See L<perlre> and
4315 L<perlop>.
4316
4317 =item print FILEHANDLE LIST
4318 X<print>
4319
4320 =item print LIST
4321
4322 =item print
4323
4324 Prints a string or a list of strings.  Returns true if successful.
4325 FILEHANDLE may be a scalar variable containing
4326 the name of or a reference to the filehandle, thus introducing
4327 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
4328 the next token is a term, it may be misinterpreted as an operator
4329 unless you interpose a C<+> or put parentheses around the arguments.)
4330 If FILEHANDLE is omitted, prints to standard output by default, or
4331 to the last selected output channel; see L</select>.  If LIST is
4332 also omitted, prints C<$_> to the currently selected output handle.
4333 To set the default output handle to something other than STDOUT
4334 use the select operation.  The current value of C<$,> (if any) is
4335 printed between each LIST item.  The current value of C<$\> (if
4336 any) is printed after the entire LIST has been printed.  Because
4337 print takes a LIST, anything in the LIST is evaluated in list
4338 context, and any subroutine that you call will have one or more of
4339 its expressions evaluated in list context.  Also be careful not to
4340 follow the print keyword with a left parenthesis unless you want
4341 the corresponding right parenthesis to terminate the arguments to
4342 the print; put parentheses around all the arguments 
4343 (or interpose a C<+>, but that doesn't look as good).
4344
4345 Note that if you're storing FILEHANDLEs in an array, or if you're using
4346 any other expression more complex than a scalar variable to retrieve it,
4347 you will have to use a block returning the filehandle value instead:
4348
4349     print { $files[$i] } "stuff\n";
4350     print { $OK ? STDOUT : STDERR } "stuff\n";
4351
4352 Printing to a closed pipe or socket will generate a SIGPIPE signal.  See
4353 L<perlipc> for more on signal handling.
4354
4355 =item printf FILEHANDLE FORMAT, LIST
4356 X<printf>
4357
4358 =item printf FORMAT, LIST
4359
4360 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
4361 (the output record separator) is not appended.  The first argument
4362 of the list will be interpreted as the C<printf> format. See C<sprintf>
4363 for an explanation of the format argument.  If C<use locale> is in effect,
4364 and POSIX::setlocale() has been called, the character used for the decimal
4365 separator in formatted floating-point numbers is affected by the LC_NUMERIC
4366 locale.  See L<perllocale> and L<POSIX>.
4367
4368 Don't fall into the trap of using a C<printf> when a simple
4369 C<print> would do.  The C<print> is more efficient and less
4370 error prone.
4371
4372 =item prototype FUNCTION
4373 X<prototype>
4374
4375 Returns the prototype of a function as a string (or C<undef> if the
4376 function has no prototype).  FUNCTION is a reference to, or the name of,
4377 the function whose prototype you want to retrieve.
4378
4379 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
4380 name for a Perl builtin.  If the builtin is not I<overridable> (such as
4381 C<qw//>) or if its arguments cannot be adequately expressed by a prototype
4382 (such as C<system>), prototype() returns C<undef>, because the builtin
4383 does not really behave like a Perl function.  Otherwise, the string
4384 describing the equivalent prototype is returned.
4385
4386 =item push ARRAY,LIST
4387 X<push> X<stack>
4388
4389 Treats ARRAY as a stack, and pushes the values of LIST
4390 onto the end of ARRAY.  The length of ARRAY increases by the length of
4391 LIST.  Has the same effect as
4392
4393     for $value (LIST) {
4394         $ARRAY[++$#ARRAY] = $value;
4395     }
4396
4397 but is more efficient.  Returns the number of elements in the array following
4398 the completed C<push>.
4399
4400 =item q/STRING/
4401
4402 =item qq/STRING/
4403
4404 =item qx/STRING/
4405
4406 =item qw/STRING/
4407
4408 Generalized quotes.  See L<perlop/"Quote-Like Operators">.
4409
4410 =item qr/STRING/
4411
4412 Regexp-like quote.  See L<perlop/"Regexp Quote-Like Operators">.
4413
4414 =item quotemeta EXPR
4415 X<quotemeta> X<metacharacter>
4416
4417 =item quotemeta
4418
4419 Returns the value of EXPR with all non-"word"
4420 characters backslashed.  (That is, all characters not matching
4421 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
4422 returned string, regardless of any locale settings.)
4423 This is the internal function implementing
4424 the C<\Q> escape in double-quoted strings.
4425
4426 If EXPR is omitted, uses C<$_>.
4427
4428 quotemeta (and C<\Q> ... C<\E>) are useful when interpolating strings into
4429 regular expressions, because by default an interpolated variable will be
4430 considered a mini-regular expression. For example:
4431
4432     my $sentence = 'The quick brown fox jumped over the lazy dog';
4433     my $substring = 'quick.*?fox';
4434     $sentence =~ s{$substring}{big bad wolf};
4435
4436 Will cause C<$sentence> to become C<'The big bad wolf jumped over...'>.
4437
4438 On the other hand:
4439
4440     my $sentence = 'The quick brown fox jumped over the lazy dog';
4441     my $substring = 'quick.*?fox';
4442     $sentence =~ s{\Q$substring\E}{big bad wolf};
4443
4444 Or:
4445
4446     my $sentence = 'The quick brown fox jumped over the lazy dog';
4447     my $substring = 'quick.*?fox';
4448     my $quoted_substring = quotemeta($substring);
4449     $sentence =~ s{$quoted_substring}{big bad wolf};
4450
4451 Will both leave the sentence as is. Normally, when accepting string input from
4452 the user, quotemeta() or C<\Q> must be used.
4453
4454 =item rand EXPR
4455 X<rand> X<random>
4456
4457 =item rand
4458
4459 Returns a random fractional number greater than or equal to C<0> and less
4460 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
4461 omitted, the value C<1> is used.  Currently EXPR with the value C<0> is
4462 also special-cased as C<1> (this was undocumented before Perl 5.8.0
4463 and is subject to change in future versions of Perl).  Automatically calls
4464 C<srand> unless C<srand> has already been called.  See also C<srand>.
4465
4466 Apply C<int()> to the value returned by C<rand()> if you want random
4467 integers instead of random fractional numbers.  For example,
4468
4469     int(rand(10))
4470
4471 returns a random integer between C<0> and C<9>, inclusive.
4472
4473 (Note: If your rand function consistently returns numbers that are too
4474 large or too small, then your version of Perl was probably compiled
4475 with the wrong number of RANDBITS.)
4476
4477 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
4478 X<read> X<file, read>
4479
4480 =item read FILEHANDLE,SCALAR,LENGTH
4481
4482 Attempts to read LENGTH I<characters> of data into variable SCALAR
4483 from the specified FILEHANDLE.  Returns the number of characters
4484 actually read, C<0> at end of file, or undef if there was an error (in
4485 the latter case C<$!> is also set).  SCALAR will be grown or shrunk 
4486 so that the last character actually read is the last character of the
4487 scalar after the read.
4488
4489 An OFFSET may be specified to place the read data at some place in the
4490 string other than the beginning.  A negative OFFSET specifies
4491 placement at that many characters counting backwards from the end of
4492 the string.  A positive OFFSET greater than the length of SCALAR
4493 results in the string being padded to the required size with C<"\0">
4494 bytes before the result of the read is appended.
4495
4496 The call is implemented in terms of either Perl's or your system's native
4497 fread(3) library function.  To get a true read(2) system call, see C<sysread>.
4498
4499 Note the I<characters>: depending on the status of the filehandle,
4500 either (8-bit) bytes or characters are read.  By default all
4501 filehandles operate on bytes, but for example if the filehandle has
4502 been opened with the C<:utf8> I/O layer (see L</open>, and the C<open>
4503 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4504 characters, not bytes.  Similarly for the C<:encoding> pragma:
4505 in that case pretty much any characters can be read.
4506
4507 =item readdir DIRHANDLE
4508 X<readdir>
4509
4510 Returns the next directory entry for a directory opened by C<opendir>.
4511 If used in list context, returns all the rest of the entries in the
4512 directory.  If there are no more entries, returns the undefined value in
4513 scalar context and the empty list in list context.
4514
4515 If you're planning to filetest the return values out of a C<readdir>, you'd
4516 better prepend the directory in question.  Otherwise, because we didn't
4517 C<chdir> there, it would have been testing the wrong file.
4518
4519     opendir(my $dh, $some_dir) || die "can't opendir $some_dir: $!";
4520     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir($dh);
4521     closedir $dh;
4522
4523 As of Perl 5.11.2 you can use a bare C<readdir> in a C<while> loop,
4524 which will set C<$_> on every iteration.
4525
4526     opendir(my $dh, $some_dir) || die;
4527     while(readdir $dh) {
4528         print "$some_dir/$_\n";
4529     }
4530     closedir $dh;
4531
4532 =item readline EXPR
4533
4534 =item readline
4535 X<readline> X<gets> X<fgets>
4536
4537 Reads from the filehandle whose typeglob is contained in EXPR (or from
4538 *ARGV if EXPR is not provided).  In scalar context, each call reads and
4539 returns the next line until end-of-file is reached, whereupon the
4540 subsequent call returns C<undef>.  In list context, reads until end-of-file
4541 is reached and returns a list of lines.  Note that the notion of "line"
4542 used here is whatever you may have defined with C<$/> or
4543 C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
4544
4545 When C<$/> is set to C<undef>, when C<readline> is in scalar
4546 context (i.e., file slurp mode), and when an empty file is read, it
4547 returns C<''> the first time, followed by C<undef> subsequently.
4548
4549 This is the internal function implementing the C<< <EXPR> >>
4550 operator, but you can use it directly.  The C<< <EXPR> >>
4551 operator is discussed in more detail in L<perlop/"I/O Operators">.
4552
4553     $line = <STDIN>;
4554     $line = readline(*STDIN);    # same thing
4555
4556 If C<readline> encounters an operating system error, C<$!> will be set
4557 with the corresponding error message.  It can be helpful to check
4558 C<$!> when you are reading from filehandles you don't trust, such as a
4559 tty or a socket.  The following example uses the operator form of
4560 C<readline> and dies if the result is not defined.
4561
4562     while ( ! eof($fh) ) {
4563         defined( $_ = <$fh> ) or die "readline failed: $!";
4564         ...
4565     }
4566
4567 Note that you have can't handle C<readline> errors that way with the
4568 C<ARGV> filehandle. In that case, you have to open each element of
4569 C<@ARGV> yourself since C<eof> handles C<ARGV> differently.
4570
4571     foreach my $arg (@ARGV) {
4572         open(my $fh, $arg) or warn "Can't open $arg: $!";
4573
4574         while ( ! eof($fh) ) {
4575             defined( $_ = <$fh> )
4576                 or die "readline failed for $arg: $!";
4577             ...
4578         }
4579     }
4580
4581 =item readlink EXPR
4582 X<readlink>
4583
4584 =item readlink
4585
4586 Returns the value of a symbolic link, if symbolic links are
4587 implemented.  If not, raises an exception.  If there is a system
4588 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
4589 omitted, uses C<$_>.
4590
4591 =item readpipe EXPR
4592
4593 =item readpipe
4594 X<readpipe>
4595
4596 EXPR is executed as a system command.
4597 The collected standard output of the command is returned.
4598 In scalar context, it comes back as a single (potentially
4599 multi-line) string.  In list context, returns a list of lines
4600 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
4601 This is the internal function implementing the C<qx/EXPR/>
4602 operator, but you can use it directly.  The C<qx/EXPR/>
4603 operator is discussed in more detail in L<perlop/"I/O Operators">.
4604 If EXPR is omitted, uses C<$_>.
4605
4606 =item recv SOCKET,SCALAR,LENGTH,FLAGS
4607 X<recv>
4608
4609 Receives a message on a socket.  Attempts to receive LENGTH characters
4610 of data into variable SCALAR from the specified SOCKET filehandle.
4611 SCALAR will be grown or shrunk to the length actually read.  Takes the
4612 same flags as the system call of the same name.  Returns the address
4613 of the sender if SOCKET's protocol supports this; returns an empty
4614 string otherwise.  If there's an error, returns the undefined value.
4615 This call is actually implemented in terms of recvfrom(2) system call.
4616 See L<perlipc/"UDP: Message Passing"> for examples.
4617
4618 Note the I<characters>: depending on the status of the socket, either
4619 (8-bit) bytes or characters are received.  By default all sockets
4620 operate on bytes, but for example if the socket has been changed using
4621 binmode() to operate with the C<:encoding(utf8)> I/O layer (see the
4622 C<open> pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4623 characters, not bytes.  Similarly for the C<:encoding> pragma: in that
4624 case pretty much any characters can be read.
4625
4626 =item redo LABEL
4627 X<redo>
4628
4629 =item redo
4630
4631 The C<redo> command restarts the loop block without evaluating the
4632 conditional again.  The C<continue> block, if any, is not executed.  If
4633 the LABEL is omitted, the command refers to the innermost enclosing
4634 loop.  Programs that want to lie to themselves about what was just input 
4635 normally use this command:
4636
4637     # a simpleminded Pascal comment stripper
4638     # (warning: assumes no { or } in strings)
4639     LINE: while (<STDIN>) {
4640         while (s|({.*}.*){.*}|$1 |) {}
4641         s|{.*}| |;
4642         if (s|{.*| |) {
4643             $front = $_;
4644             while (<STDIN>) {
4645                 if (/}/) {  # end of comment?
4646                     s|^|$front\{|;
4647                     redo LINE;
4648                 }
4649             }
4650         }
4651         print;
4652     }
4653
4654 C<redo> cannot be used to retry a block that returns a value such as
4655 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
4656 a grep() or map() operation.
4657
4658 Note that a block by itself is semantically identical to a loop
4659 that executes once.  Thus C<redo> inside such a block will effectively
4660 turn it into a looping construct.
4661
4662 See also L</continue> for an illustration of how C<last>, C<next>, and
4663 C<redo> work.
4664
4665 =item ref EXPR
4666 X<ref> X<reference>
4667
4668 =item ref
4669