This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
perlfunc: bad wording
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2 X<function>
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides scalar context to its
16 argument, while a list operator may provide either scalar or list
17 contexts for its arguments.  If it does both, scalar arguments 
18 come first and list argument follow, and there can only ever
19 be one such list argument.  For instance, splice() has three scalar
20 arguments followed by a list, whereas gethostbyname() has four scalar
21 arguments.
22
23 In the syntax descriptions that follow, list operators that expect a
24 list (and provide list context for elements of the list) are shown
25 with LIST as an argument.  Such a list may consist of any combination
26 of scalar arguments or list values; the list values will be included
27 in the list as if each individual element were interpolated at that
28 point in the list, forming a longer single-dimensional list value.
29 Commas should separate literal elements of the LIST.
30
31 Any function in the list below may be used either with or without
32 parentheses around its arguments.  (The syntax descriptions omit the
33 parentheses.)  If you use parentheses, the simple but occasionally 
34 surprising rule is this: It I<looks> like a function, therefore it I<is> a
35 function, and precedence doesn't matter.  Otherwise it's a list
36 operator or unary operator, and precedence does matter.  Whitespace
37 between the function and left parenthesis doesn't count, so sometimes
38 you need to be careful:
39
40     print 1+2+4;      # Prints 7.
41     print(1+2) + 4;   # Prints 3.
42     print (1+2)+4;    # Also prints 3!
43     print +(1+2)+4;   # Prints 7.
44     print ((1+2)+4);  # Prints 7.
45
46 If you run Perl with the B<-w> switch it can warn you about this.  For
47 example, the third line above produces:
48
49     print (...) interpreted as function at - line 1.
50     Useless use of integer addition in void context at - line 1.
51
52 A few functions take no arguments at all, and therefore work as neither
53 unary nor list operators.  These include such functions as C<time>
54 and C<endpwent>.  For example, C<time+86_400> always means
55 C<time() + 86_400>.
56
57 For functions that can be used in either a scalar or list context,
58 nonabortive failure is generally indicated in scalar context by
59 returning the undefined value, and in list context by returning the
60 empty list.
61
62 Remember the following important rule: There is B<no rule> that relates
63 the behavior of an expression in list context to its behavior in scalar
64 context, or vice versa.  It might do two totally different things.
65 Each operator and function decides which sort of value would be most
66 appropriate to return in scalar context.  Some operators return the
67 length of the list that would have been returned in list context.  Some
68 operators return the first value in the list.  Some operators return the
69 last value in the list.  Some operators return a count of successful
70 operations.  In general, they do what you want, unless you want
71 consistency.
72 X<context>
73
74 A named array in scalar context is quite different from what would at
75 first glance appear to be a list in scalar context.  You can't get a list
76 like C<(1,2,3)> into being in scalar context, because the compiler knows
77 the context at compile time.  It would generate the scalar comma operator
78 there, not the list construction version of the comma.  That means it
79 was never a list to start with.
80
81 In general, functions in Perl that serve as wrappers for system calls ("syscalls")
82 of the same name (like chown(2), fork(2), closedir(2), etc.) return
83 true when they succeed and C<undef> otherwise, as is usually mentioned
84 in the descriptions below.  This is different from the C interfaces,
85 which return C<-1> on failure.  Exceptions to this rule include C<wait>,
86 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
87 variable on failure.  Other functions do not, except accidentally.
88
89 Extension modules can also hook into the Perl parser to define new
90 kinds of keyword-headed expression.  These may look like functions, but
91 may also look completely different.  The syntax following the keyword
92 is defined entirely by the extension.  If you are an implementor, see
93 L<perlapi/PL_keyword_plugin> for the mechanism.  If you are using such
94 a module, see the module's documentation for details of the syntax that
95 it defines.
96
97 =head2 Perl Functions by Category
98 X<function>
99
100 Here are Perl's functions (including things that look like
101 functions, like some keywords and named operators)
102 arranged by category.  Some functions appear in more
103 than one place.
104
105 =over 4
106
107 =item Functions for SCALARs or strings
108 X<scalar> X<string> X<character>
109
110 =for Pod::Functions =String
111
112 C<chomp>, C<chop>, C<chr>, C<crypt>, C<fc>, C<hex>, C<index>, C<lc>,
113 C<lcfirst>, C<length>, C<oct>, C<ord>, C<pack>, C<q//>, C<qq//>, C<reverse>,
114 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
115
116 C<fc> is available only if the C<"fc"> feature is enabled or if it is
117 prefixed with C<CORE::>.  The C<"fc"> feature is enabled automatically
118 with a C<use v5.16> (or higher) declaration in the current scope.
119
120
121 =item Regular expressions and pattern matching
122 X<regular expression> X<regex> X<regexp>
123
124 =for Pod::Functions =Regexp
125
126 C<m//>, C<pos>, C<qr//>, C<quotemeta>, C<s///>, C<split>, C<study>
127
128 =item Numeric functions
129 X<numeric> X<number> X<trigonometric> X<trigonometry>
130
131 =for Pod::Functions =Math
132
133 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
134 C<sin>, C<sqrt>, C<srand>
135
136 =item Functions for real @ARRAYs
137 X<array>
138
139 =for Pod::Functions =ARRAY
140
141 C<each>, C<keys>, C<pop>, C<push>, C<shift>, C<splice>, C<unshift>, C<values>
142
143 =item Functions for list data
144 X<list>
145
146 =for Pod::Functions =LIST
147
148 C<grep>, C<join>, C<map>, C<qw//>, C<reverse>, C<sort>, C<unpack>
149
150 =item Functions for real %HASHes
151 X<hash>
152
153 =for Pod::Functions =HASH
154
155 C<delete>, C<each>, C<exists>, C<keys>, C<values>
156
157 =item Input and output functions
158 X<I/O> X<input> X<output> X<dbm>
159
160 =for Pod::Functions =I/O
161
162 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
163 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
164 C<readdir>, C<readline> C<rewinddir>, C<say>, C<seek>, C<seekdir>, C<select>,
165 C<syscall>, C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>,
166 C<truncate>, C<warn>, C<write>
167
168 C<say> is available only if the C<"say"> feature is enabled or if it is
169 prefixed with C<CORE::>.  The C<"say"> feature is enabled automatically
170 with a C<use v5.10> (or higher) declaration in the current scope.
171
172 =item Functions for fixed-length data or records
173
174 =for Pod::Functions =Binary
175
176 C<pack>, C<read>, C<syscall>, C<sysread>, C<sysseek>, C<syswrite>, C<unpack>,
177 C<vec>
178
179 =item Functions for filehandles, files, or directories
180 X<file> X<filehandle> X<directory> X<pipe> X<link> X<symlink>
181
182 =for Pod::Functions =File
183
184 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
185 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
186 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
187 C<umask>, C<unlink>, C<utime>
188
189 =item Keywords related to the control flow of your Perl program
190 X<control flow>
191
192 =for Pod::Functions =Flow
193
194 C<caller>, C<continue>, C<die>, C<do>,
195 C<dump>, C<eval>, C<evalbytes> C<exit>,
196 C<__FILE__>, C<goto>, C<last>, C<__LINE__>, C<next>, C<__PACKAGE__>,
197 C<prototype>, C<redo>, C<return>, C<sub>, C<__SUB__>, C<wantarray>
198
199 C<evalbytes> is only available with with the C<"evalbytes"> feature (see
200 L<feature>) or if prefixed with C<CORE::>.  C<__SUB__> is only available
201 with with the C<"current_sub"> feature or if prefixed with C<CORE::>. Both
202 the C<"evalbytes"> and C<"current_sub"> features are enabled automatically
203 with a C<use v5.16> (or higher) declaration in the current scope.
204
205 =item Keywords related to the switch feature
206
207 =for Pod::Functions =Switch
208
209 C<break>, C<continue>, C<default>, C<given>, C<when>
210
211 Except for C<continue>, these are available only if you enable the
212 C<"switch"> feature or use the C<CORE::> prefix.  See L<feature> and
213 L<perlsyn/"Switch Statements">.  The C<"switch"> feature is enabled
214 automatically with a C<use v5.10> (or higher) declaration in the current
215 scope.  In Perl 5.14 and earlier, C<continue> required the C<"switch">
216 feature, like the other keywords.
217
218 =item Keywords related to scoping
219
220 =for Pod::Functions =Namespace
221
222 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<state>, C<use>
223
224 C<state> is available only if the C<"state"> feature is enabled or if it is
225 prefixed with C<CORE::>.  The C<"state"> feature is enabled automatically
226 with a C<use v5.10> (or higher) declaration in the current scope.
227
228 =item Miscellaneous functions
229
230 =for Pod::Functions =Misc
231
232 C<defined>, C<dump>, C<eval>, C<evalbytes>,
233 C<formline>, C<local>, C<lock>, C<my>, C<our>, C<prototype>,
234 C<reset>, C<scalar>, C<state>, C<undef>, C<wantarray>
235
236 =item Functions for processes and process groups
237 X<process> X<pid> X<process id>
238
239 =for Pod::Functions =Process
240
241 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
242 C<pipe>, C<qx//>, C<readpipe>, C<setpgrp>,
243 C<setpriority>, C<sleep>, C<system>,
244 C<times>, C<wait>, C<waitpid>
245
246 =item Keywords related to Perl modules
247 X<module>
248
249 =for Pod::Functions =Modules
250
251 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
252
253 =item Keywords related to classes and object-orientation
254 X<object> X<class> X<package>
255
256 =for Pod::Functions =Objects
257
258 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
259 C<untie>, C<use>
260
261 =item Low-level socket functions
262 X<socket> X<sock>
263
264 =for Pod::Functions =Socket
265
266 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
267 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
268 C<socket>, C<socketpair>
269
270 =item System V interprocess communication functions
271 X<IPC> X<System V> X<semaphore> X<shared memory> X<memory> X<message>
272
273 =for Pod::Functions =SysV
274
275 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
276 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
277
278 =item Fetching user and group info
279 X<user> X<group> X<password> X<uid> X<gid>  X<passwd> X</etc/passwd>
280
281 =for Pod::Functions =User
282
283 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
284 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
285 C<getpwuid>, C<setgrent>, C<setpwent>
286
287 =item Fetching network info
288 X<network> X<protocol> X<host> X<hostname> X<IP> X<address> X<service>
289
290 =for Pod::Functions =Network
291
292 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
293 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
294 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
295 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
296 C<setnetent>, C<setprotoent>, C<setservent>
297
298 =item Time-related functions
299 X<time> X<date>
300
301 =for Pod::Functions =Time
302
303 C<gmtime>, C<localtime>, C<time>, C<times>
304
305 =item Non-function keywords
306
307 =for Pod::Functions =!Non-functions
308
309 C<and>, C<AUTOLOAD>, C<BEGIN>, C<CHECK>, C<cmp>, C<CORE>, C<__DATA__>,
310 C<DESTROY>, C<else>, C<elseif>, C<elsif>, C<END>, C<__END__>, C<eq>, C<for>,
311 C<foreach>, C<ge>, C<gt>, C<if>, C<INIT>, C<le>, C<lt>, C<ne>, C<not>, C<or>,
312 C<UNITCHECK>, C<unless>, C<until>, C<while>, C<x>, C<xor>
313
314 =back
315
316 =head2 Portability
317 X<portability> X<Unix> X<portable>
318
319 Perl was born in Unix and can therefore access all common Unix
320 system calls.  In non-Unix environments, the functionality of some
321 Unix system calls may not be available or details of the available
322 functionality may differ slightly.  The Perl functions affected
323 by this are:
324
325 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
326 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
327 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
328 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
329 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
330 C<getppid>, C<getpgrp>, C<getpriority>, C<getprotobynumber>,
331 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
332 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
333 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
334 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
335 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
336 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
337 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
338 C<shmwrite>, C<socket>, C<socketpair>,
339 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
340 C<times>, C<truncate>, C<umask>, C<unlink>,
341 C<utime>, C<wait>, C<waitpid>
342
343 For more information about the portability of these functions, see
344 L<perlport> and other available platform-specific documentation.
345
346 =head2 Alphabetical Listing of Perl Functions
347
348 =over 
349
350 =item -X FILEHANDLE
351 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
352 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
353
354 =item -X EXPR
355
356 =item -X DIRHANDLE
357
358 =item -X
359
360 =for Pod::Functions a file test (-r, -x, etc)
361
362 A file test, where X is one of the letters listed below.  This unary
363 operator takes one argument, either a filename, a filehandle, or a dirhandle, 
364 and tests the associated file to see if something is true about it.  If the
365 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
366 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
367 the undefined value if the file doesn't exist.  Despite the funny
368 names, precedence is the same as any other named unary operator.  The
369 operator may be any of:
370
371     -r  File is readable by effective uid/gid.
372     -w  File is writable by effective uid/gid.
373     -x  File is executable by effective uid/gid.
374     -o  File is owned by effective uid.
375
376     -R  File is readable by real uid/gid.
377     -W  File is writable by real uid/gid.
378     -X  File is executable by real uid/gid.
379     -O  File is owned by real uid.
380
381     -e  File exists.
382     -z  File has zero size (is empty).
383     -s  File has nonzero size (returns size in bytes).
384
385     -f  File is a plain file.
386     -d  File is a directory.
387     -l  File is a symbolic link.
388     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
389     -S  File is a socket.
390     -b  File is a block special file.
391     -c  File is a character special file.
392     -t  Filehandle is opened to a tty.
393
394     -u  File has setuid bit set.
395     -g  File has setgid bit set.
396     -k  File has sticky bit set.
397
398     -T  File is an ASCII text file (heuristic guess).
399     -B  File is a "binary" file (opposite of -T).
400
401     -M  Script start time minus file modification time, in days.
402     -A  Same for access time.
403     -C  Same for inode change time (Unix, may differ for other platforms)
404
405 Example:
406
407     while (<>) {
408         chomp;
409         next unless -f $_;  # ignore specials
410         #...
411     }
412
413 Note that C<-s/a/b/> does not do a negated substitution.  Saying
414 C<-exp($foo)> still works as expected, however: only single letters
415 following a minus are interpreted as file tests.
416
417 These operators are exempt from the "looks like a function rule" described
418 above.  That is, an opening parenthesis after the operator does not affect
419 how much of the following code constitutes the argument.  Put the opening
420 parentheses before the operator to separate it from code that follows (this
421 applies only to operators with higher precedence than unary operators, of
422 course):
423
424     -s($file) + 1024   # probably wrong; same as -s($file + 1024)
425     (-s $file) + 1024  # correct
426
427 The interpretation of the file permission operators C<-r>, C<-R>,
428 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
429 of the file and the uids and gids of the user.  There may be other
430 reasons you can't actually read, write, or execute the file: for
431 example network filesystem access controls, ACLs (access control lists),
432 read-only filesystems, and unrecognized executable formats.  Note
433 that the use of these six specific operators to verify if some operation
434 is possible is usually a mistake, because it may be open to race
435 conditions.
436
437 Also note that, for the superuser on the local filesystems, the C<-r>,
438 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
439 if any execute bit is set in the mode.  Scripts run by the superuser
440 may thus need to do a stat() to determine the actual mode of the file,
441 or temporarily set their effective uid to something else.
442
443 If you are using ACLs, there is a pragma called C<filetest> that may
444 produce more accurate results than the bare stat() mode bits.
445 When under C<use filetest 'access'> the above-mentioned filetests
446 test whether the permission can(not) be granted using the
447 access(2) family of system calls.  Also note that the C<-x> and C<-X> may
448 under this pragma return true even if there are no execute permission
449 bits set (nor any extra execute permission ACLs).  This strangeness is
450 due to the underlying system calls' definitions.  Note also that, due to
451 the implementation of C<use filetest 'access'>, the C<_> special
452 filehandle won't cache the results of the file tests when this pragma is
453 in effect.  Read the documentation for the C<filetest> pragma for more
454 information.
455
456 The C<-T> and C<-B> switches work as follows.  The first block or so of the
457 file is examined for odd characters such as strange control codes or
458 characters with the high bit set.  If too many strange characters (>30%)
459 are found, it's a C<-B> file; otherwise it's a C<-T> file.  Also, any file
460 containing a zero byte in the first block is considered a binary file.  If C<-T>
461 or C<-B> is used on a filehandle, the current IO buffer is examined
462 rather than the first block.  Both C<-T> and C<-B> return true on an empty
463 file, or a file at EOF when testing a filehandle.  Because you have to
464 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
465 against the file first, as in C<next unless -f $file && -T $file>.
466
467 If any of the file tests (or either the C<stat> or C<lstat> operator) is given
468 the special filehandle consisting of a solitary underline, then the stat
469 structure of the previous file test (or stat operator) is used, saving
470 a system call.  (This doesn't work with C<-t>, and you need to remember
471 that lstat() and C<-l> leave values in the stat structure for the
472 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
473 an C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
474 Example:
475
476     print "Can do.\n" if -r $a || -w _ || -x _;
477
478     stat($filename);
479     print "Readable\n" if -r _;
480     print "Writable\n" if -w _;
481     print "Executable\n" if -x _;
482     print "Setuid\n" if -u _;
483     print "Setgid\n" if -g _;
484     print "Sticky\n" if -k _;
485     print "Text\n" if -T _;
486     print "Binary\n" if -B _;
487
488 As of Perl 5.9.1, as a form of purely syntactic sugar, you can stack file
489 test operators, in a way that C<-f -w -x $file> is equivalent to
490 C<-x $file && -w _ && -f _>.  (This is only fancy fancy: if you use
491 the return value of C<-f $file> as an argument to another filetest
492 operator, no special magic will happen.)
493
494 Portability issues: L<perlport/-X>.
495
496 To avoid confusing would-be users of your code with mysterious
497 syntax errors, put something like this at the top of your script:
498
499     use 5.010;  # so filetest ops can stack
500
501 =item abs VALUE
502 X<abs> X<absolute>
503
504 =item abs
505
506 =for Pod::Functions absolute value function
507
508 Returns the absolute value of its argument.
509 If VALUE is omitted, uses C<$_>.
510
511 =item accept NEWSOCKET,GENERICSOCKET
512 X<accept>
513
514 =for Pod::Functions accept an incoming socket connect
515
516 Accepts an incoming socket connect, just as accept(2) 
517 does.  Returns the packed address if it succeeded, false otherwise.
518 See the example in L<perlipc/"Sockets: Client/Server Communication">.
519
520 On systems that support a close-on-exec flag on files, the flag will
521 be set for the newly opened file descriptor, as determined by the
522 value of $^F.  See L<perlvar/$^F>.
523
524 =item alarm SECONDS
525 X<alarm>
526 X<SIGALRM>
527 X<timer>
528
529 =item alarm
530
531 =for Pod::Functions schedule a SIGALRM
532
533 Arranges to have a SIGALRM delivered to this process after the
534 specified number of wallclock seconds has elapsed.  If SECONDS is not
535 specified, the value stored in C<$_> is used.  (On some machines,
536 unfortunately, the elapsed time may be up to one second less or more
537 than you specified because of how seconds are counted, and process
538 scheduling may delay the delivery of the signal even further.)
539
540 Only one timer may be counting at once.  Each call disables the
541 previous timer, and an argument of C<0> may be supplied to cancel the
542 previous timer without starting a new one.  The returned value is the
543 amount of time remaining on the previous timer.
544
545 For delays of finer granularity than one second, the Time::HiRes module
546 (from CPAN, and starting from Perl 5.8 part of the standard
547 distribution) provides ualarm().  You may also use Perl's four-argument
548 version of select() leaving the first three arguments undefined, or you
549 might be able to use the C<syscall> interface to access setitimer(2) if
550 your system supports it.  See L<perlfaq8> for details.
551
552 It is usually a mistake to intermix C<alarm> and C<sleep> calls, because
553 C<sleep> may be internally implemented on your system with C<alarm>.
554
555 If you want to use C<alarm> to time out a system call you need to use an
556 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
557 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
558 restart system calls on some systems.  Using C<eval>/C<die> always works,
559 modulo the caveats given in L<perlipc/"Signals">.
560
561     eval {
562         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
563         alarm $timeout;
564         $nread = sysread SOCKET, $buffer, $size;
565         alarm 0;
566     };
567     if ($@) {
568         die unless $@ eq "alarm\n";   # propagate unexpected errors
569         # timed out
570     }
571     else {
572         # didn't
573     }
574
575 For more information see L<perlipc>.
576
577 Portability issues: L<perlport/alarm>.
578
579 =item atan2 Y,X
580 X<atan2> X<arctangent> X<tan> X<tangent>
581
582 =for Pod::Functions arctangent of Y/X in the range -PI to PI
583
584 Returns the arctangent of Y/X in the range -PI to PI.
585
586 For the tangent operation, you may use the C<Math::Trig::tan>
587 function, or use the familiar relation:
588
589     sub tan { sin($_[0]) / cos($_[0])  }
590
591 The return value for C<atan2(0,0)> is implementation-defined; consult
592 your atan2(3) manpage for more information.
593
594 Portability issues: L<perlport/atan2>.
595
596 =item bind SOCKET,NAME
597 X<bind>
598
599 =for Pod::Functions binds an address to a socket
600
601 Binds a network address to a socket, just as bind(2)
602 does.  Returns true if it succeeded, false otherwise.  NAME should be a
603 packed address of the appropriate type for the socket.  See the examples in
604 L<perlipc/"Sockets: Client/Server Communication">.
605
606 =item binmode FILEHANDLE, LAYER
607 X<binmode> X<binary> X<text> X<DOS> X<Windows>
608
609 =item binmode FILEHANDLE
610
611 =for Pod::Functions prepare binary files for I/O
612
613 Arranges for FILEHANDLE to be read or written in "binary" or "text"
614 mode on systems where the run-time libraries distinguish between
615 binary and text files.  If FILEHANDLE is an expression, the value is
616 taken as the name of the filehandle.  Returns true on success,
617 otherwise it returns C<undef> and sets C<$!> (errno).
618
619 On some systems (in general, DOS- and Windows-based systems) binmode()
620 is necessary when you're not working with a text file.  For the sake
621 of portability it is a good idea always to use it when appropriate,
622 and never to use it when it isn't appropriate.  Also, people can
623 set their I/O to be by default UTF8-encoded Unicode, not bytes.
624
625 In other words: regardless of platform, use binmode() on binary data,
626 like images, for example.
627
628 If LAYER is present it is a single string, but may contain multiple
629 directives.  The directives alter the behaviour of the filehandle.
630 When LAYER is present, using binmode on a text file makes sense.
631
632 If LAYER is omitted or specified as C<:raw> the filehandle is made
633 suitable for passing binary data.  This includes turning off possible CRLF
634 translation and marking it as bytes (as opposed to Unicode characters).
635 Note that, despite what may be implied in I<"Programming Perl"> (the
636 Camel, 3rd edition) or elsewhere, C<:raw> is I<not> simply the inverse of C<:crlf>.
637 Other layers that would affect the binary nature of the stream are
638 I<also> disabled.  See L<PerlIO>, L<perlrun>, and the discussion about the
639 PERLIO environment variable.
640
641 The C<:bytes>, C<:crlf>, C<:utf8>, and any other directives of the
642 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
643 establish default I/O layers.  See L<open>.
644
645 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
646 in "Programming Perl, 3rd Edition".  However, since the publishing of this
647 book, by many known as "Camel III", the consensus of the naming of this
648 functionality has moved from "discipline" to "layer".  All documentation
649 of this version of Perl therefore refers to "layers" rather than to
650 "disciplines".  Now back to the regularly scheduled documentation...>
651
652 To mark FILEHANDLE as UTF-8, use C<:utf8> or C<:encoding(UTF-8)>.
653 C<:utf8> just marks the data as UTF-8 without further checking,
654 while C<:encoding(UTF-8)> checks the data for actually being valid
655 UTF-8.  More details can be found in L<PerlIO::encoding>.
656
657 In general, binmode() should be called after open() but before any I/O
658 is done on the filehandle.  Calling binmode() normally flushes any
659 pending buffered output data (and perhaps pending input data) on the
660 handle.  An exception to this is the C<:encoding> layer that
661 changes the default character encoding of the handle; see L</open>.
662 The C<:encoding> layer sometimes needs to be called in
663 mid-stream, and it doesn't flush the stream.  The C<:encoding>
664 also implicitly pushes on top of itself the C<:utf8> layer because
665 internally Perl operates on UTF8-encoded Unicode characters.
666
667 The operating system, device drivers, C libraries, and Perl run-time
668 system all conspire to let the programmer treat a single
669 character (C<\n>) as the line terminator, irrespective of external
670 representation.  On many operating systems, the native text file
671 representation matches the internal representation, but on some
672 platforms the external representation of C<\n> is made up of more than
673 one character.
674
675 All variants of Unix, Mac OS (old and new), and Stream_LF files on VMS use
676 a single character to end each line in the external representation of text
677 (even though that single character is CARRIAGE RETURN on old, pre-Darwin
678 flavors of Mac OS, and is LINE FEED on Unix and most VMS files).  In other
679 systems like OS/2, DOS, and the various flavors of MS-Windows, your program
680 sees a C<\n> as a simple C<\cJ>, but what's stored in text files are the
681 two characters C<\cM\cJ>.  That means that if you don't use binmode() on
682 these systems, C<\cM\cJ> sequences on disk will be converted to C<\n> on
683 input, and any C<\n> in your program will be converted back to C<\cM\cJ> on
684 output.  This is what you want for text files, but it can be disastrous for
685 binary files.
686
687 Another consequence of using binmode() (on some systems) is that
688 special end-of-file markers will be seen as part of the data stream.
689 For systems from the Microsoft family this means that, if your binary
690 data contain C<\cZ>, the I/O subsystem will regard it as the end of
691 the file, unless you use binmode().
692
693 binmode() is important not only for readline() and print() operations,
694 but also when using read(), seek(), sysread(), syswrite() and tell()
695 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
696 in L<perlvar> for how to manually set your input and output
697 line-termination sequences.
698
699 Portability issues: L<perlport/binmode>.
700
701 =item bless REF,CLASSNAME
702 X<bless>
703
704 =item bless REF
705
706 =for Pod::Functions create an object
707
708 This function tells the thingy referenced by REF that it is now an object
709 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
710 is used.  Because a C<bless> is often the last thing in a constructor,
711 it returns the reference for convenience.  Always use the two-argument
712 version if a derived class might inherit the function doing the blessing.
713 SeeL<perlobj> for more about the blessing (and blessings) of objects.
714
715 Consider always blessing objects in CLASSNAMEs that are mixed case.
716 Namespaces with all lowercase names are considered reserved for
717 Perl pragmata.  Builtin types have all uppercase names.  To prevent
718 confusion, you may wish to avoid such package names as well.  Make sure
719 that CLASSNAME is a true value.
720
721 See L<perlmod/"Perl Modules">.
722
723 =item break
724
725 =for Pod::Functions +switch break out of a C<given> block
726
727 Break out of a C<given()> block.
728
729 This keyword is enabled by the C<"switch"> feature: see
730 L<feature> for more information.  You can also access it by
731 prefixing it with C<CORE::>.  Alternately, include a C<use
732 v5.10> or later to the current scope.
733
734 =item caller EXPR
735 X<caller> X<call stack> X<stack> X<stack trace>
736
737 =item caller
738
739 =for Pod::Functions get context of the current subroutine call
740
741 Returns the context of the current subroutine call.  In scalar context,
742 returns the caller's package name if there I<is> a caller (that is, if
743 we're in a subroutine or C<eval> or C<require>) and the undefined value
744 otherwise.  In list context, returns
745
746     # 0         1          2
747     ($package, $filename, $line) = caller;
748
749 With EXPR, it returns some extra information that the debugger uses to
750 print a stack trace.  The value of EXPR indicates how many call frames
751 to go back before the current one.
752
753     #  0         1          2      3            4
754     ($package, $filename, $line, $subroutine, $hasargs,
755
756     #  5          6          7            8       9         10
757     $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash)
758      = caller($i);
759
760 Here $subroutine may be C<(eval)> if the frame is not a subroutine
761 call, but an C<eval>.  In such a case additional elements $evaltext and
762 C<$is_require> are set: C<$is_require> is true if the frame is created by a
763 C<require> or C<use> statement, $evaltext contains the text of the
764 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
765 $subroutine is C<(eval)>, but $evaltext is undefined.  (Note also that
766 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
767 frame.)  $subroutine may also be C<(unknown)> if this particular
768 subroutine happens to have been deleted from the symbol table.
769 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
770 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
771 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
772 between versions of Perl, and are not meant for external use.
773
774 C<$hinthash> is a reference to a hash containing the value of C<%^H> when the
775 caller was compiled, or C<undef> if C<%^H> was empty.  Do not modify the values
776 of this hash, as they are the actual values stored in the optree.
777
778 Furthermore, when called from within the DB package in
779 list context, and with an argument, caller returns more
780 detailed information: it sets the list variable C<@DB::args> to be the
781 arguments with which the subroutine was invoked.
782
783 Be aware that the optimizer might have optimized call frames away before
784 C<caller> had a chance to get the information.  That means that C<caller(N)>
785 might not return information about the call frame you expect it to, for
786 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
787 previous time C<caller> was called.
788
789 Be aware that setting C<@DB::args> is I<best effort>, intended for
790 debugging or generating backtraces, and should not be relied upon.  In
791 particular, as C<@_> contains aliases to the caller's arguments, Perl does
792 not take a copy of C<@_>, so C<@DB::args> will contain modifications the
793 subroutine makes to C<@_> or its contents, not the original values at call
794 time.  C<@DB::args>, like C<@_>, does not hold explicit references to its
795 elements, so under certain cases its elements may have become freed and
796 reallocated for other variables or temporary values.  Finally, a side effect
797 of the current implementation is that the effects of C<shift @_> can
798 I<normally> be undone (but not C<pop @_> or other splicing, I<and> not if a
799 reference to C<@_> has been taken, I<and> subject to the caveat about reallocated
800 elements), so C<@DB::args> is actually a hybrid of the current state and
801 initial state of C<@_>.  Buyer beware.
802
803 =item chdir EXPR
804 X<chdir>
805 X<cd>
806 X<directory, change>
807
808 =item chdir FILEHANDLE
809
810 =item chdir DIRHANDLE
811
812 =item chdir
813
814 =for Pod::Functions change your current working directory
815
816 Changes the working directory to EXPR, if possible.  If EXPR is omitted,
817 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
818 changes to the directory specified by C<$ENV{LOGDIR}>.  (Under VMS, the
819 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.)  If
820 neither is set, C<chdir> does nothing.  It returns true on success,
821 false otherwise.  See the example under C<die>.
822
823 On systems that support fchdir(2), you may pass a filehandle or
824 directory handle as the argument.  On systems that don't support fchdir(2),
825 passing handles raises an exception.
826
827 =item chmod LIST
828 X<chmod> X<permission> X<mode>
829
830 =for Pod::Functions changes the permissions on a list of files
831
832 Changes the permissions of a list of files.  The first element of the
833 list must be the numeric mode, which should probably be an octal
834 number, and which definitely should I<not> be a string of octal digits:
835 C<0644> is okay, but C<"0644"> is not.  Returns the number of files
836 successfully changed.  See also L</oct> if all you have is a string.
837
838     $cnt = chmod 0755, "foo", "bar";
839     chmod 0755, @executables;
840     $mode = "0644"; chmod $mode, "foo";      # !!! sets mode to
841                                              # --w----r-T
842     $mode = "0644"; chmod oct($mode), "foo"; # this is better
843     $mode = 0644;   chmod $mode, "foo";      # this is best
844
845 On systems that support fchmod(2), you may pass filehandles among the
846 files.  On systems that don't support fchmod(2), passing filehandles raises
847 an exception.  Filehandles must be passed as globs or glob references to be
848 recognized; barewords are considered filenames.
849
850     open(my $fh, "<", "foo");
851     my $perm = (stat $fh)[2] & 07777;
852     chmod($perm | 0600, $fh);
853
854 You can also import the symbolic C<S_I*> constants from the C<Fcntl>
855 module:
856
857     use Fcntl qw( :mode );
858     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
859     # Identical to the chmod 0755 of the example above.
860
861 Portability issues: L<perlport/chmod>.
862
863 =item chomp VARIABLE
864 X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol>
865
866 =item chomp( LIST )
867
868 =item chomp
869
870 =for Pod::Functions remove a trailing record separator from a string
871
872 This safer version of L</chop> removes any trailing string
873 that corresponds to the current value of C<$/> (also known as
874 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
875 number of characters removed from all its arguments.  It's often used to
876 remove the newline from the end of an input record when you're worried
877 that the final record may be missing its newline.  When in paragraph
878 mode (C<$/ = "">), it removes all trailing newlines from the string.
879 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
880 a reference to an integer or the like; see L<perlvar>) chomp() won't
881 remove anything.
882 If VARIABLE is omitted, it chomps C<$_>.  Example:
883
884     while (<>) {
885         chomp;  # avoid \n on last field
886         @array = split(/:/);
887         # ...
888     }
889
890 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
891
892 You can actually chomp anything that's an lvalue, including an assignment:
893
894     chomp($cwd = `pwd`);
895     chomp($answer = <STDIN>);
896
897 If you chomp a list, each element is chomped, and the total number of
898 characters removed is returned.
899
900 Note that parentheses are necessary when you're chomping anything
901 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
902 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
903 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
904 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
905 as C<chomp($a, $b)>.
906
907 =item chop VARIABLE
908 X<chop>
909
910 =item chop( LIST )
911
912 =item chop
913
914 =for Pod::Functions remove the last character from a string
915
916 Chops off the last character of a string and returns the character
917 chopped.  It is much more efficient than C<s/.$//s> because it neither
918 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
919 If VARIABLE is a hash, it chops the hash's values, but not its keys.
920
921 You can actually chop anything that's an lvalue, including an assignment.
922
923 If you chop a list, each element is chopped.  Only the value of the
924 last C<chop> is returned.
925
926 Note that C<chop> returns the last character.  To return all but the last
927 character, use C<substr($string, 0, -1)>.
928
929 See also L</chomp>.
930
931 =item chown LIST
932 X<chown> X<owner> X<user> X<group>
933
934 =for Pod::Functions change the ownership on a list of files
935
936 Changes the owner (and group) of a list of files.  The first two
937 elements of the list must be the I<numeric> uid and gid, in that
938 order.  A value of -1 in either position is interpreted by most
939 systems to leave that value unchanged.  Returns the number of files
940 successfully changed.
941
942     $cnt = chown $uid, $gid, 'foo', 'bar';
943     chown $uid, $gid, @filenames;
944
945 On systems that support fchown(2), you may pass filehandles among the
946 files.  On systems that don't support fchown(2), passing filehandles raises
947 an exception.  Filehandles must be passed as globs or glob references to be
948 recognized; barewords are considered filenames.
949
950 Here's an example that looks up nonnumeric uids in the passwd file:
951
952     print "User: ";
953     chomp($user = <STDIN>);
954     print "Files: ";
955     chomp($pattern = <STDIN>);
956
957     ($login,$pass,$uid,$gid) = getpwnam($user)
958         or die "$user not in passwd file";
959
960     @ary = glob($pattern);  # expand filenames
961     chown $uid, $gid, @ary;
962
963 On most systems, you are not allowed to change the ownership of the
964 file unless you're the superuser, although you should be able to change
965 the group to any of your secondary groups.  On insecure systems, these
966 restrictions may be relaxed, but this is not a portable assumption.
967 On POSIX systems, you can detect this condition this way:
968
969     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
970     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
971
972 Portability issues: L<perlport/chmod>.
973
974 =item chr NUMBER
975 X<chr> X<character> X<ASCII> X<Unicode>
976
977 =item chr
978
979 =for Pod::Functions get character this number represents
980
981 Returns the character represented by that NUMBER in the character set.
982 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
983 chr(0x263a) is a Unicode smiley face.  
984
985 Negative values give the Unicode replacement character (chr(0xfffd)),
986 except under the L<bytes> pragma, where the low eight bits of the value
987 (truncated to an integer) are used.
988
989 If NUMBER is omitted, uses C<$_>.
990
991 For the reverse, use L</ord>.
992
993 Note that characters from 128 to 255 (inclusive) are by default
994 internally not encoded as UTF-8 for backward compatibility reasons.
995
996 See L<perlunicode> for more about Unicode.
997
998 =item chroot FILENAME
999 X<chroot> X<root>
1000
1001 =item chroot
1002
1003 =for Pod::Functions make directory new root for path lookups
1004
1005 This function works like the system call by the same name: it makes the
1006 named directory the new root directory for all further pathnames that
1007 begin with a C</> by your process and all its children.  (It doesn't
1008 change your current working directory, which is unaffected.)  For security
1009 reasons, this call is restricted to the superuser.  If FILENAME is
1010 omitted, does a C<chroot> to C<$_>.
1011
1012 Portability issues: L<perlport/chroot>.
1013
1014 =item close FILEHANDLE
1015 X<close>
1016
1017 =item close
1018
1019 =for Pod::Functions close file (or pipe or socket) handle
1020
1021 Closes the file or pipe associated with the filehandle, flushes the IO
1022 buffers, and closes the system file descriptor.  Returns true if those
1023 operations succeed and if no error was reported by any PerlIO
1024 layer.  Closes the currently selected filehandle if the argument is
1025 omitted.
1026
1027 You don't have to close FILEHANDLE if you are immediately going to do
1028 another C<open> on it, because C<open> closes it for you.  (See
1029 L<open|/open FILEHANDLE>.)  However, an explicit C<close> on an input file resets the line
1030 counter (C<$.>), while the implicit close done by C<open> does not.
1031
1032 If the filehandle came from a piped open, C<close> returns false if one of
1033 the other syscalls involved fails or if its program exits with non-zero
1034 status.  If the only problem was that the program exited non-zero, C<$!>
1035 will be set to C<0>.  Closing a pipe also waits for the process executing
1036 on the pipe to exit--in case you wish to look at the output of the pipe
1037 afterwards--and implicitly puts the exit status value of that command into
1038 C<$?> and C<${^CHILD_ERROR_NATIVE}>.
1039
1040 If there are multiple threads running, C<close> on a filehandle from a
1041 piped open returns true without waiting for the child process to terminate,
1042 if the filehandle is still open in another thread.
1043
1044 Closing the read end of a pipe before the process writing to it at the
1045 other end is done writing results in the writer receiving a SIGPIPE.  If
1046 the other end can't handle that, be sure to read all the data before
1047 closing the pipe.
1048
1049 Example:
1050
1051     open(OUTPUT, '|sort >foo')  # pipe to sort
1052         or die "Can't start sort: $!";
1053     #...                        # print stuff to output
1054     close OUTPUT                # wait for sort to finish
1055         or warn $! ? "Error closing sort pipe: $!"
1056                    : "Exit status $? from sort";
1057     open(INPUT, 'foo')          # get sort's results
1058         or die "Can't open 'foo' for input: $!";
1059
1060 FILEHANDLE may be an expression whose value can be used as an indirect
1061 filehandle, usually the real filehandle name or an autovivified handle.
1062
1063 =item closedir DIRHANDLE
1064 X<closedir>
1065
1066 =for Pod::Functions close directory handle
1067
1068 Closes a directory opened by C<opendir> and returns the success of that
1069 system call.
1070
1071 =item connect SOCKET,NAME
1072 X<connect>
1073
1074 =for Pod::Functions connect to a remote socket
1075
1076 Attempts to connect to a remote socket, just like connect(2).
1077 Returns true if it succeeded, false otherwise.  NAME should be a
1078 packed address of the appropriate type for the socket.  See the examples in
1079 L<perlipc/"Sockets: Client/Server Communication">.
1080
1081 =item continue BLOCK
1082 X<continue>
1083
1084 =item continue
1085
1086 =for Pod::Functions optional trailing block in a while or foreach
1087
1088 When followed by a BLOCK, C<continue> is actually a
1089 flow control statement rather than a function.  If
1090 there is a C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
1091 C<foreach>), it is always executed just before the conditional is about to
1092 be evaluated again, just like the third part of a C<for> loop in C.  Thus
1093 it can be used to increment a loop variable, even when the loop has been
1094 continued via the C<next> statement (which is similar to the C C<continue>
1095 statement).
1096
1097 C<last>, C<next>, or C<redo> may appear within a C<continue>
1098 block; C<last> and C<redo> behave as if they had been executed within
1099 the main block.  So will C<next>, but since it will execute a C<continue>
1100 block, it may be more entertaining.
1101
1102     while (EXPR) {
1103         ### redo always comes here
1104         do_something;
1105     } continue {
1106         ### next always comes here
1107         do_something_else;
1108         # then back the top to re-check EXPR
1109     }
1110     ### last always comes here
1111
1112 Omitting the C<continue> section is equivalent to using an
1113 empty one, logically enough, so C<next> goes directly back
1114 to check the condition at the top of the loop.
1115
1116 When there is no BLOCK, C<continue> is a function that
1117 falls through the current C<when> or C<default> block instead of iterating
1118 a dynamically enclosing C<foreach> or exiting a lexically enclosing C<given>.
1119 In Perl 5.14 and earlier, this form of C<continue> was
1120 only available when the C<"switch"> feature was enabled.
1121 See L<feature> and L<perlsyn/"Switch Statements"> for more
1122 information.
1123
1124 =item cos EXPR
1125 X<cos> X<cosine> X<acos> X<arccosine>
1126
1127 =item cos
1128
1129 =for Pod::Functions cosine function
1130
1131 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
1132 takes the cosine of C<$_>.
1133
1134 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
1135 function, or use this relation:
1136
1137     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
1138
1139 =item crypt PLAINTEXT,SALT
1140 X<crypt> X<digest> X<hash> X<salt> X<plaintext> X<password>
1141 X<decrypt> X<cryptography> X<passwd> X<encrypt>
1142
1143 =for Pod::Functions one-way passwd-style encryption
1144
1145 Creates a digest string exactly like the crypt(3) function in the C
1146 library (assuming that you actually have a version there that has not
1147 been extirpated as a potential munition).
1148
1149 crypt() is a one-way hash function.  The PLAINTEXT and SALT are turned
1150 into a short string, called a digest, which is returned.  The same
1151 PLAINTEXT and SALT will always return the same string, but there is no
1152 (known) way to get the original PLAINTEXT from the hash.  Small
1153 changes in the PLAINTEXT or SALT will result in large changes in the
1154 digest.
1155
1156 There is no decrypt function.  This function isn't all that useful for
1157 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
1158 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
1159 primarily used to check if two pieces of text are the same without
1160 having to transmit or store the text itself.  An example is checking
1161 if a correct password is given.  The digest of the password is stored,
1162 not the password itself.  The user types in a password that is
1163 crypt()'d with the same salt as the stored digest.  If the two digests
1164 match, the password is correct.
1165
1166 When verifying an existing digest string you should use the digest as
1167 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
1168 to create the digest is visible as part of the digest.  This ensures
1169 crypt() will hash the new string with the same salt as the digest.
1170 This allows your code to work with the standard L<crypt|/crypt> and
1171 with more exotic implementations.  In other words, assume
1172 nothing about the returned string itself nor about how many bytes 
1173 of SALT may matter.
1174
1175 Traditionally the result is a string of 13 bytes: two first bytes of
1176 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
1177 the first eight bytes of PLAINTEXT mattered.  But alternative
1178 hashing schemes (like MD5), higher level security schemes (like C2),
1179 and implementations on non-Unix platforms may produce different
1180 strings.
1181
1182 When choosing a new salt create a random two character string whose
1183 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
1184 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
1185 characters is just a recommendation; the characters allowed in
1186 the salt depend solely on your system's crypt library, and Perl can't
1187 restrict what salts C<crypt()> accepts.
1188
1189 Here's an example that makes sure that whoever runs this program knows
1190 their password:
1191
1192     $pwd = (getpwuid($<))[1];
1193
1194     system "stty -echo";
1195     print "Password: ";
1196     chomp($word = <STDIN>);
1197     print "\n";
1198     system "stty echo";
1199
1200     if (crypt($word, $pwd) ne $pwd) {
1201         die "Sorry...\n";
1202     } else {
1203         print "ok\n";
1204     }
1205
1206 Of course, typing in your own password to whoever asks you
1207 for it is unwise.
1208
1209 The L<crypt|/crypt> function is unsuitable for hashing large quantities
1210 of data, not least of all because you can't get the information
1211 back.  Look at the L<Digest> module for more robust algorithms.
1212
1213 If using crypt() on a Unicode string (which I<potentially> has
1214 characters with codepoints above 255), Perl tries to make sense
1215 of the situation by trying to downgrade (a copy of)
1216 the string back to an eight-bit byte string before calling crypt()
1217 (on that copy).  If that works, good.  If not, crypt() dies with
1218 C<Wide character in crypt>.
1219
1220 Portability issues: L<perlport/crypt>.
1221
1222 =item dbmclose HASH
1223 X<dbmclose>
1224
1225 =for Pod::Functions breaks binding on a tied dbm file
1226
1227 [This function has been largely superseded by the C<untie> function.]
1228
1229 Breaks the binding between a DBM file and a hash.
1230
1231 Portability issues: L<perlport/dbmclose>.
1232
1233 =item dbmopen HASH,DBNAME,MASK
1234 X<dbmopen> X<dbm> X<ndbm> X<sdbm> X<gdbm>
1235
1236 =for Pod::Functions create binding on a tied dbm file
1237
1238 [This function has been largely superseded by the
1239 L<tie|/tie VARIABLE,CLASSNAME,LIST> function.]
1240
1241 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
1242 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
1243 argument is I<not> a filehandle, even though it looks like one).  DBNAME
1244 is the name of the database (without the F<.dir> or F<.pag> extension if
1245 any).  If the database does not exist, it is created with protection
1246 specified by MASK (as modified by the C<umask>).  To prevent creation of
1247 the database if it doesn't exist, you may specify a MODE
1248 of 0, and the function will return a false value if it
1249 can't find an existing database.  If your system supports
1250 only the older DBM functions, you may make only one C<dbmopen> call in your
1251 program.  In older versions of Perl, if your system had neither DBM nor
1252 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
1253 sdbm(3).
1254
1255 If you don't have write access to the DBM file, you can only read hash
1256 variables, not set them.  If you want to test whether you can write,
1257 either use file tests or try setting a dummy hash entry inside an C<eval> 
1258 to trap the error.
1259
1260 Note that functions such as C<keys> and C<values> may return huge lists
1261 when used on large DBM files.  You may prefer to use the C<each>
1262 function to iterate over large DBM files.  Example:
1263
1264     # print out history file offsets
1265     dbmopen(%HIST,'/usr/lib/news/history',0666);
1266     while (($key,$val) = each %HIST) {
1267         print $key, ' = ', unpack('L',$val), "\n";
1268     }
1269     dbmclose(%HIST);
1270
1271 See also L<AnyDBM_File> for a more general description of the pros and
1272 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1273 rich implementation.
1274
1275 You can control which DBM library you use by loading that library
1276 before you call dbmopen():
1277
1278     use DB_File;
1279     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1280         or die "Can't open netscape history file: $!";
1281
1282 Portability issues: L<perlport/dbmopen>.
1283
1284 =item default BLOCK
1285
1286 =for Pod::Functions !RT #108848
1287
1288 Within a C<foreach> or a C<given>, a C<default> BLOCK acts like a C<when>
1289 that's always true.  Only available after Perl 5.10, and only if the
1290 C<switch> feature has been requested or if the keyword is prefixed with
1291 C<CORE::>.  See L</when>.
1292
1293 =item defined EXPR
1294 X<defined> X<undef> X<undefined>
1295
1296 =item defined
1297
1298 =for Pod::Functions test whether a value, variable, or function is defined
1299
1300 Returns a Boolean value telling whether EXPR has a value other than
1301 the undefined value C<undef>.  If EXPR is not present, C<$_> is
1302 checked.
1303
1304 Many operations return C<undef> to indicate failure, end of file,
1305 system error, uninitialized variable, and other exceptional
1306 conditions.  This function allows you to distinguish C<undef> from
1307 other values.  (A simple Boolean test will not distinguish among
1308 C<undef>, zero, the empty string, and C<"0">, which are all equally
1309 false.)  Note that since C<undef> is a valid scalar, its presence
1310 doesn't I<necessarily> indicate an exceptional condition: C<pop>
1311 returns C<undef> when its argument is an empty array, I<or> when the
1312 element to return happens to be C<undef>.
1313
1314 You may also use C<defined(&func)> to check whether subroutine C<&func>
1315 has ever been defined.  The return value is unaffected by any forward
1316 declarations of C<&func>.  A subroutine that is not defined
1317 may still be callable: its package may have an C<AUTOLOAD> method that
1318 makes it spring into existence the first time that it is called; see
1319 L<perlsub>.
1320
1321 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1322 used to report whether memory for that aggregate had ever been
1323 allocated.  This behavior may disappear in future versions of Perl.
1324 You should instead use a simple test for size:
1325
1326     if (@an_array) { print "has array elements\n" }
1327     if (%a_hash)   { print "has hash members\n"   }
1328
1329 When used on a hash element, it tells you whether the value is defined,
1330 not whether the key exists in the hash.  Use L</exists> for the latter
1331 purpose.
1332
1333 Examples:
1334
1335     print if defined $switch{D};
1336     print "$val\n" while defined($val = pop(@ary));
1337     die "Can't readlink $sym: $!"
1338         unless defined($value = readlink $sym);
1339     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1340     $debugging = 0 unless defined $debugging;
1341
1342 Note:  Many folks tend to overuse C<defined> and are then surprised to
1343 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1344 defined values.  For example, if you say
1345
1346     "ab" =~ /a(.*)b/;
1347
1348 The pattern match succeeds and C<$1> is defined, although it
1349 matched "nothing".  It didn't really fail to match anything.  Rather, it
1350 matched something that happened to be zero characters long.  This is all
1351 very above-board and honest.  When a function returns an undefined value,
1352 it's an admission that it couldn't give you an honest answer.  So you
1353 should use C<defined> only when questioning the integrity of what
1354 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1355 what you want.
1356
1357 See also L</undef>, L</exists>, L</ref>.
1358
1359 =item delete EXPR
1360 X<delete>
1361
1362 =for Pod::Functions deletes a value from a hash
1363
1364 Given an expression that specifies an element or slice of a hash, C<delete>
1365 deletes the specified elements from that hash so that exists() on that element
1366 no longer returns true.  Setting a hash element to the undefined value does
1367 not remove its key, but deleting it does; see L</exists>.
1368
1369 In list context, returns the value or values deleted, or the last such
1370 element in scalar context.  The return list's length always matches that of
1371 the argument list: deleting non-existent elements returns the undefined value
1372 in their corresponding positions.
1373
1374 delete() may also be used on arrays and array slices, but its behavior is less
1375 straightforward.  Although exists() will return false for deleted entries,
1376 deleting array elements never changes indices of existing values; use shift()
1377 or splice() for that.  However, if all deleted elements fall at the end of an
1378 array, the array's size shrinks to the position of the highest element that
1379 still tests true for exists(), or to 0 if none do.
1380
1381 B<WARNING:> Calling delete on array values is deprecated and likely to
1382 be removed in a future version of Perl.
1383
1384 Deleting from C<%ENV> modifies the environment.  Deleting from a hash tied to
1385 a DBM file deletes the entry from the DBM file.  Deleting from a C<tied> hash
1386 or array may not necessarily return anything; it depends on the implementation
1387 of the C<tied> package's DELETE method, which may do whatever it pleases.
1388
1389 The C<delete local EXPR> construct localizes the deletion to the current
1390 block at run time.  Until the block exits, elements locally deleted
1391 temporarily no longer exist.  See L<perlsub/"Localized deletion of elements
1392 of composite types">.
1393
1394     %hash = (foo => 11, bar => 22, baz => 33);
1395     $scalar = delete $hash{foo};             # $scalar is 11
1396     $scalar = delete @hash{qw(foo bar)};     # $scalar is 22
1397     @array  = delete @hash{qw(foo bar baz)}; # @array  is (undef,undef,33)
1398
1399 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1400
1401     foreach $key (keys %HASH) {
1402         delete $HASH{$key};
1403     }
1404
1405     foreach $index (0 .. $#ARRAY) {
1406         delete $ARRAY[$index];
1407     }
1408
1409 And so do these:
1410
1411     delete @HASH{keys %HASH};
1412
1413     delete @ARRAY[0 .. $#ARRAY];
1414
1415 But both are slower than assigning the empty list
1416 or undefining %HASH or @ARRAY, which is the customary 
1417 way to empty out an aggregate:
1418
1419     %HASH = ();     # completely empty %HASH
1420     undef %HASH;    # forget %HASH ever existed
1421
1422     @ARRAY = ();    # completely empty @ARRAY
1423     undef @ARRAY;   # forget @ARRAY ever existed
1424
1425 The EXPR can be arbitrarily complicated provided its
1426 final operation is an element or slice of an aggregate:
1427
1428     delete $ref->[$x][$y]{$key};
1429     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1430
1431     delete $ref->[$x][$y][$index];
1432     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1433
1434 =item die LIST
1435 X<die> X<throw> X<exception> X<raise> X<$@> X<abort>
1436
1437 =for Pod::Functions raise an exception or bail out
1438
1439 C<die> raises an exception.  Inside an C<eval> the error message is stuffed
1440 into C<$@> and the C<eval> is terminated with the undefined value.
1441 If the exception is outside of all enclosing C<eval>s, then the uncaught
1442 exception prints LIST to C<STDERR> and exits with a non-zero value.  If you
1443 need to exit the process with a specific exit code, see L</exit>.
1444
1445 Equivalent examples:
1446
1447     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1448     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1449
1450 If the last element of LIST does not end in a newline, the current
1451 script line number and input line number (if any) are also printed,
1452 and a newline is supplied.  Note that the "input line number" (also
1453 known as "chunk") is subject to whatever notion of "line" happens to
1454 be currently in effect, and is also available as the special variable
1455 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1456
1457 Hint: sometimes appending C<", stopped"> to your message will cause it
1458 to make better sense when the string C<"at foo line 123"> is appended.
1459 Suppose you are running script "canasta".
1460
1461     die "/etc/games is no good";
1462     die "/etc/games is no good, stopped";
1463
1464 produce, respectively
1465
1466     /etc/games is no good at canasta line 123.
1467     /etc/games is no good, stopped at canasta line 123.
1468
1469 If the output is empty and C<$@> already contains a value (typically from a
1470 previous eval) that value is reused after appending C<"\t...propagated">.
1471 This is useful for propagating exceptions:
1472
1473     eval { ... };
1474     die unless $@ =~ /Expected exception/;
1475
1476 If the output is empty and C<$@> contains an object reference that has a
1477 C<PROPAGATE> method, that method will be called with additional file
1478 and line number parameters.  The return value replaces the value in
1479 C<$@>;  i.e., as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1480 were called.
1481
1482 If C<$@> is empty then the string C<"Died"> is used.
1483
1484 If an uncaught exception results in interpreter exit, the exit code is
1485 determined from the values of C<$!> and C<$?> with this pseudocode:
1486
1487     exit $! if $!;              # errno
1488     exit $? >> 8 if $? >> 8;    # child exit status
1489     exit 255;                   # last resort
1490
1491 The intent is to squeeze as much possible information about the likely cause
1492 into the limited space of the system exit
1493 code.  However, as C<$!> is the value
1494 of C's C<errno>, which can be set by any system call, this means that the value
1495 of the exit code used by C<die> can be non-predictable, so should not be relied
1496 upon, other than to be non-zero.
1497
1498 You can also call C<die> with a reference argument, and if this is trapped
1499 within an C<eval>, C<$@> contains that reference.  This permits more
1500 elaborate exception handling using objects that maintain arbitrary state
1501 about the exception.  Such a scheme is sometimes preferable to matching
1502 particular string values of C<$@> with regular expressions.  Because C<$@> 
1503 is a global variable and C<eval> may be used within object implementations,
1504 be careful that analyzing the error object doesn't replace the reference in
1505 the global variable.  It's easiest to make a local copy of the reference
1506 before any manipulations.  Here's an example:
1507
1508     use Scalar::Util "blessed";
1509
1510     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1511     if (my $ev_err = $@) {
1512         if (blessed($ev_err) && $ev_err->isa("Some::Module::Exception")) {
1513             # handle Some::Module::Exception
1514         }
1515         else {
1516             # handle all other possible exceptions
1517         }
1518     }
1519
1520 Because Perl stringifies uncaught exception messages before display,
1521 you'll probably want to overload stringification operations on
1522 exception objects.  See L<overload> for details about that.
1523
1524 You can arrange for a callback to be run just before the C<die>
1525 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1526 handler is called with the error text and can change the error
1527 message, if it sees fit, by calling C<die> again.  See
1528 L<perlvar/%SIG> for details on setting C<%SIG> entries, and
1529 L<"eval BLOCK"> for some examples.  Although this feature was 
1530 to be run only right before your program was to exit, this is not
1531 currently so: the C<$SIG{__DIE__}> hook is currently called
1532 even inside eval()ed blocks/strings!  If one wants the hook to do
1533 nothing in such situations, put
1534
1535     die @_ if $^S;
1536
1537 as the first line of the handler (see L<perlvar/$^S>).  Because
1538 this promotes strange action at a distance, this counterintuitive
1539 behavior may be fixed in a future release.
1540
1541 See also exit(), warn(), and the Carp module.
1542
1543 =item do BLOCK
1544 X<do> X<block>
1545
1546 =for Pod::Functions turn a BLOCK into a TERM
1547
1548 Not really a function.  Returns the value of the last command in the
1549 sequence of commands indicated by BLOCK.  When modified by the C<while> or
1550 C<until> loop modifier, executes the BLOCK once before testing the loop
1551 condition.  (On other statements the loop modifiers test the conditional
1552 first.)
1553
1554 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1555 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1556 See L<perlsyn> for alternative strategies.
1557
1558 =item do SUBROUTINE(LIST)
1559 X<do>
1560
1561 This form of subroutine call is deprecated.  SUBROUTINE can be a bareword,
1562 a scalar variable or a subroutine beginning with C<&>.
1563
1564 =item do EXPR
1565 X<do>
1566
1567 Uses the value of EXPR as a filename and executes the contents of the
1568 file as a Perl script.
1569
1570     do 'stat.pl';
1571
1572 is just like
1573
1574     eval `cat stat.pl`;
1575
1576 except that it's more efficient and concise, keeps track of the current
1577 filename for error messages, searches the C<@INC> directories, and updates
1578 C<%INC> if the file is found.  See L<perlvar/@INC> and L<perlvar/%INC> for
1579 these variables.  It also differs in that code evaluated with C<do FILENAME>
1580 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1581 same, however, in that it does reparse the file every time you call it,
1582 so you probably don't want to do this inside a loop.
1583
1584 If C<do> can read the file but cannot compile it, it returns C<undef> and sets
1585 an error message in C<$@>.  If C<do> cannot read the file, it returns undef
1586 and sets C<$!> to the error.  Always check C<$@> first, as compilation
1587 could fail in a way that also sets C<$!>.  If the file is successfully
1588 compiled, C<do> returns the value of the last expression evaluated.
1589
1590 Inclusion of library modules is better done with the
1591 C<use> and C<require> operators, which also do automatic error checking
1592 and raise an exception if there's a problem.
1593
1594 You might like to use C<do> to read in a program configuration
1595 file.  Manual error checking can be done this way:
1596
1597     # read in config files: system first, then user
1598     for $file ("/share/prog/defaults.rc",
1599                "$ENV{HOME}/.someprogrc")
1600     {
1601         unless ($return = do $file) {
1602             warn "couldn't parse $file: $@" if $@;
1603             warn "couldn't do $file: $!"    unless defined $return;
1604             warn "couldn't run $file"       unless $return;
1605         }
1606     }
1607
1608 =item dump LABEL
1609 X<dump> X<core> X<undump>
1610
1611 =item dump
1612
1613 =for Pod::Functions create an immediate core dump
1614
1615 This function causes an immediate core dump.  See also the B<-u>
1616 command-line switch in L<perlrun>, which does the same thing.
1617 Primarily this is so that you can use the B<undump> program (not
1618 supplied) to turn your core dump into an executable binary after
1619 having initialized all your variables at the beginning of the
1620 program.  When the new binary is executed it will begin by executing
1621 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1622 Think of it as a goto with an intervening core dump and reincarnation.
1623 If C<LABEL> is omitted, restarts the program from the top.
1624
1625 B<WARNING>: Any files opened at the time of the dump will I<not>
1626 be open any more when the program is reincarnated, with possible
1627 resulting confusion by Perl.
1628
1629 This function is now largely obsolete, mostly because it's very hard to
1630 convert a core file into an executable.  That's why you should now invoke
1631 it as C<CORE::dump()>, if you don't want to be warned against a possible
1632 typo.
1633
1634 Portability issues: L<perlport/dump>.
1635
1636 =item each HASH
1637 X<each> X<hash, iterator>
1638
1639 =item each ARRAY
1640 X<array, iterator>
1641
1642 =item each EXPR
1643
1644 =for Pod::Functions retrieve the next key/value pair from a hash
1645
1646 When called on a hash in list context, returns a 2-element list
1647 consisting of the key and value for the next element of a hash.  In Perl
1648 5.12 and later only, it will also return the index and value for the next
1649 element of an array so that you can iterate over it; older Perls consider
1650 this a syntax error.  When called in scalar context, returns only the key
1651 (not the value) in a hash, or the index in an array.
1652
1653 Hash entries are returned in an apparently random order.  The actual random
1654 order is subject to change in future versions of Perl, but it is
1655 guaranteed to be in the same order as either the C<keys> or C<values>
1656 function would produce on the same (unmodified) hash.  Since Perl
1657 5.8.2 the ordering can be different even between different runs of Perl
1658 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1659
1660 After C<each> has returned all entries from the hash or array, the next
1661 call to C<each> returns the empty list in list context and C<undef> in
1662 scalar context; the next call following I<that> one restarts iteration.
1663 Each hash or array has its own internal iterator, accessed by C<each>,
1664 C<keys>, and C<values>.  The iterator is implicitly reset when C<each> has
1665 reached the end as just described; it can be explicitly reset by calling
1666 C<keys> or C<values> on the hash or array.  If you add or delete a hash's
1667 elements while iterating over it, entries may be skipped or duplicated--so
1668 don't do that.  Exception: In the current implementation, it is always safe
1669 to delete the item most recently returned by C<each()>, so the following
1670 code works properly:
1671
1672         while (($key, $value) = each %hash) {
1673           print $key, "\n";
1674           delete $hash{$key};   # This is safe
1675         }
1676
1677 This prints out your environment like the printenv(1) program,
1678 but in a different order:
1679
1680     while (($key,$value) = each %ENV) {
1681         print "$key=$value\n";
1682     }
1683
1684 Starting with Perl 5.14, C<each> can take a scalar EXPR, which must hold
1685 reference to an unblessed hash or array.  The argument will be dereferenced
1686 automatically.  This aspect of C<each> is considered highly experimental.
1687 The exact behaviour may change in a future version of Perl.
1688
1689     while (($key,$value) = each $hashref) { ... }
1690
1691 To avoid confusing would-be users of your code who are running earlier
1692 versions of Perl with mysterious syntax errors, put this sort of thing at
1693 the top of your file to signal that your code will work I<only> on Perls of
1694 a recent vintage:
1695
1696     use 5.012;  # so keys/values/each work on arrays
1697     use 5.014;  # so keys/values/each work on scalars (experimental)
1698
1699 See also C<keys>, C<values>, and C<sort>.
1700
1701 =item eof FILEHANDLE
1702 X<eof>
1703 X<end of file>
1704 X<end-of-file>
1705
1706 =item eof ()
1707
1708 =item eof
1709
1710 =for Pod::Functions test a filehandle for its end
1711
1712 Returns 1 if the next read on FILEHANDLE will return end of file I<or> if
1713 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1714 gives the real filehandle.  (Note that this function actually
1715 reads a character and then C<ungetc>s it, so isn't useful in an
1716 interactive context.)  Do not read from a terminal file (or call
1717 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1718 as terminals may lose the end-of-file condition if you do.
1719
1720 An C<eof> without an argument uses the last file read.  Using C<eof()>
1721 with empty parentheses is different.  It refers to the pseudo file
1722 formed from the files listed on the command line and accessed via the
1723 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1724 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1725 used will cause C<@ARGV> to be examined to determine if input is
1726 available.   Similarly, an C<eof()> after C<< <> >> has returned
1727 end-of-file will assume you are processing another C<@ARGV> list,
1728 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1729 see L<perlop/"I/O Operators">.
1730
1731 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1732 detect the end of each file, whereas C<eof()> will detect the end 
1733 of the very last file only.  Examples:
1734
1735     # reset line numbering on each input file
1736     while (<>) {
1737         next if /^\s*#/;  # skip comments
1738         print "$.\t$_";
1739     } continue {
1740         close ARGV if eof;  # Not eof()!
1741     }
1742
1743     # insert dashes just before last line of last file
1744     while (<>) {
1745         if (eof()) {  # check for end of last file
1746             print "--------------\n";
1747         }
1748         print;
1749         last if eof();      # needed if we're reading from a terminal
1750     }
1751
1752 Practical hint: you almost never need to use C<eof> in Perl, because the
1753 input operators typically return C<undef> when they run out of data or 
1754 encounter an error.
1755
1756 =item eval EXPR
1757 X<eval> X<try> X<catch> X<evaluate> X<parse> X<execute>
1758 X<error, handling> X<exception, handling>
1759
1760 =item eval BLOCK
1761
1762 =item eval
1763
1764 =for Pod::Functions catch exceptions or compile and run code
1765
1766 In the first form, the return value of EXPR is parsed and executed as if it
1767 were a little Perl program.  The value of the expression (which is itself
1768 determined within scalar context) is first parsed, and if there were no
1769 errors, executed as a block within the lexical context of the current Perl
1770 program.  This means, that in particular, any outer lexical variables are
1771 visible to it, and any package variable settings or subroutine and format
1772 definitions remain afterwards.
1773
1774 Note that the value is parsed every time the C<eval> executes.
1775 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1776 delay parsing and subsequent execution of the text of EXPR until run time.
1777
1778 If the C<unicode_eval> feature is enabled (which is the default under a
1779 C<use 5.16> or higher declaration), EXPR or C<$_> is treated as a string of
1780 characters, so C<use utf8> declarations have no effect, and source filters
1781 are forbidden.  In the absence of the C<unicode_eval> feature, the string
1782 will sometimes be treated as characters and sometimes as bytes, depending
1783 on the internal encoding, and source filters activated within the C<eval>
1784 exhibit the erratic, but historical, behaviour of affecting some outer file
1785 scope that is still compiling.  See also the L</evalbytes> keyword, which
1786 always treats its input as a byte stream and works properly with source
1787 filters, and the L<feature> pragma.
1788
1789 In the second form, the code within the BLOCK is parsed only once--at the
1790 same time the code surrounding the C<eval> itself was parsed--and executed
1791 within the context of the current Perl program.  This form is typically
1792 used to trap exceptions more efficiently than the first (see below), while
1793 also providing the benefit of checking the code within BLOCK at compile
1794 time.
1795
1796 The final semicolon, if any, may be omitted from the value of EXPR or within
1797 the BLOCK.
1798
1799 In both forms, the value returned is the value of the last expression
1800 evaluated inside the mini-program; a return statement may be also used, just
1801 as with subroutines.  The expression providing the return value is evaluated
1802 in void, scalar, or list context, depending on the context of the C<eval> 
1803 itself.  See L</wantarray> for more on how the evaluation context can be 
1804 determined.
1805
1806 If there is a syntax error or runtime error, or a C<die> statement is
1807 executed, C<eval> returns C<undef> in scalar context
1808 or an empty list in list context, and C<$@> is set to the error
1809 message.  (Prior to 5.16, a bug caused C<undef> to be returned
1810 in list context for syntax errors, but not for runtime errors.)
1811 If there was no error, C<$@> is set to the empty string.  A
1812 control flow operator like C<last> or C<goto> can bypass the setting of
1813 C<$@>.  Beware that using C<eval> neither silences Perl from printing
1814 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1815 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1816 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1817 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1818
1819 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1820 determining whether a particular feature (such as C<socket> or C<symlink>)
1821 is implemented.  It is also Perl's exception-trapping mechanism, where
1822 the die operator is used to raise exceptions.
1823
1824 If you want to trap errors when loading an XS module, some problems with
1825 the binary interface (such as Perl version skew) may be fatal even with
1826 C<eval> unless C<$ENV{PERL_DL_NONLAZY}> is set.  See L<perlrun>.
1827
1828 If the code to be executed doesn't vary, you may use the eval-BLOCK
1829 form to trap run-time errors without incurring the penalty of
1830 recompiling each time.  The error, if any, is still returned in C<$@>.
1831 Examples:
1832
1833     # make divide-by-zero nonfatal
1834     eval { $answer = $a / $b; }; warn $@ if $@;
1835
1836     # same thing, but less efficient
1837     eval '$answer = $a / $b'; warn $@ if $@;
1838
1839     # a compile-time error
1840     eval { $answer = }; # WRONG
1841
1842     # a run-time error
1843     eval '$answer =';   # sets $@
1844
1845 Using the C<eval{}> form as an exception trap in libraries does have some
1846 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
1847 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
1848 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1849 as this example shows:
1850
1851     # a private exception trap for divide-by-zero
1852     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1853     warn $@ if $@;
1854
1855 This is especially significant, given that C<__DIE__> hooks can call
1856 C<die> again, which has the effect of changing their error messages:
1857
1858     # __DIE__ hooks may modify error messages
1859     {
1860        local $SIG{'__DIE__'} =
1861               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1862        eval { die "foo lives here" };
1863        print $@ if $@;                # prints "bar lives here"
1864     }
1865
1866 Because this promotes action at a distance, this counterintuitive behavior
1867 may be fixed in a future release.
1868
1869 With an C<eval>, you should be especially careful to remember what's
1870 being looked at when:
1871
1872     eval $x;        # CASE 1
1873     eval "$x";      # CASE 2
1874
1875     eval '$x';      # CASE 3
1876     eval { $x };    # CASE 4
1877
1878     eval "\$$x++";  # CASE 5
1879     $$x++;          # CASE 6
1880
1881 Cases 1 and 2 above behave identically: they run the code contained in
1882 the variable $x.  (Although case 2 has misleading double quotes making
1883 the reader wonder what else might be happening (nothing is).)  Cases 3
1884 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1885 does nothing but return the value of $x.  (Case 4 is preferred for
1886 purely visual reasons, but it also has the advantage of compiling at
1887 compile-time instead of at run-time.)  Case 5 is a place where
1888 normally you I<would> like to use double quotes, except that in this
1889 particular situation, you can just use symbolic references instead, as
1890 in case 6.
1891
1892 Before Perl 5.14, the assignment to C<$@> occurred before restoration 
1893 of localized variables, which means that for your code to run on older
1894 versions, a temporary is required if you want to mask some but not all
1895 errors:
1896
1897     # alter $@ on nefarious repugnancy only
1898     {
1899        my $e;
1900        {
1901           local $@; # protect existing $@
1902           eval { test_repugnancy() };
1903           # $@ =~ /nefarious/ and die $@; # Perl 5.14 and higher only
1904           $@ =~ /nefarious/ and $e = $@;
1905        }
1906        die $e if defined $e
1907     }
1908
1909 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1910 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1911
1912 An C<eval ''> executed within the C<DB> package doesn't see the usual
1913 surrounding lexical scope, but rather the scope of the first non-DB piece
1914 of code that called it.  You don't normally need to worry about this unless
1915 you are writing a Perl debugger.
1916
1917 =item evalbytes EXPR
1918 X<evalbytes>
1919
1920 =item evalbytes
1921
1922 =for Pod::Functions +evalbytes similar to string eval, but intend to parse a bytestream
1923
1924 This function is like L</eval> with a string argument, except it always
1925 parses its argument, or C<$_> if EXPR is omitted, as a string of bytes.  A
1926 string containing characters whose ordinal value exceeds 255 results in an
1927 error.  Source filters activated within the evaluated code apply to the
1928 code itself.
1929
1930 This function is only available under the C<evalbytes> feature, a
1931 C<use v5.16> (or higher) declaration, or with a C<CORE::> prefix.  See
1932 L<feature> for more information.
1933
1934 =item exec LIST
1935 X<exec> X<execute>
1936
1937 =item exec PROGRAM LIST
1938
1939 =for Pod::Functions abandon this program to run another
1940
1941 The C<exec> function executes a system command I<and never returns>;
1942 use C<system> instead of C<exec> if you want it to return.  It fails and
1943 returns false only if the command does not exist I<and> it is executed
1944 directly instead of via your system's command shell (see below).
1945
1946 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1947 warns you if there is a following statement that isn't C<die>, C<warn>,
1948 or C<exit> (if C<-w> is set--but you always do that, right?).   If you
1949 I<really> want to follow an C<exec> with some other statement, you
1950 can use one of these styles to avoid the warning:
1951
1952     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1953     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1954
1955 If there is more than one argument in LIST, or if LIST is an array
1956 with more than one value, calls execvp(3) with the arguments in LIST.
1957 If there is only one scalar argument or an array with one element in it,
1958 the argument is checked for shell metacharacters, and if there are any,
1959 the entire argument is passed to the system's command shell for parsing
1960 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1961 If there are no shell metacharacters in the argument, it is split into
1962 words and passed directly to C<execvp>, which is more efficient.
1963 Examples:
1964
1965     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1966     exec "sort $outfile | uniq";
1967
1968 If you don't really want to execute the first argument, but want to lie
1969 to the program you are executing about its own name, you can specify
1970 the program you actually want to run as an "indirect object" (without a
1971 comma) in front of the LIST.  (This always forces interpretation of the
1972 LIST as a multivalued list, even if there is only a single scalar in
1973 the list.)  Example:
1974
1975     $shell = '/bin/csh';
1976     exec $shell '-sh';    # pretend it's a login shell
1977
1978 or, more directly,
1979
1980     exec {'/bin/csh'} '-sh';  # pretend it's a login shell
1981
1982 When the arguments get executed via the system shell, results are
1983 subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1984 for details.
1985
1986 Using an indirect object with C<exec> or C<system> is also more
1987 secure.  This usage (which also works fine with system()) forces
1988 interpretation of the arguments as a multivalued list, even if the
1989 list had just one argument.  That way you're safe from the shell
1990 expanding wildcards or splitting up words with whitespace in them.
1991
1992     @args = ( "echo surprise" );
1993
1994     exec @args;               # subject to shell escapes
1995                                 # if @args == 1
1996     exec { $args[0] } @args;  # safe even with one-arg list
1997
1998 The first version, the one without the indirect object, ran the I<echo>
1999 program, passing it C<"surprise"> an argument.  The second version didn't;
2000 it tried to run a program named I<"echo surprise">, didn't find it, and set
2001 C<$?> to a non-zero value indicating failure.
2002
2003 Beginning with v5.6.0, Perl attempts to flush all files opened for
2004 output before the exec, but this may not be supported on some platforms
2005 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
2006 in English) or call the C<autoflush()> method of C<IO::Handle> on any
2007 open handles to avoid lost output.
2008
2009 Note that C<exec> will not call your C<END> blocks, nor will it invoke
2010 C<DESTROY> methods on your objects.
2011
2012 Portability issues: L<perlport/exec>.
2013
2014 =item exists EXPR
2015 X<exists> X<autovivification>
2016
2017 =for Pod::Functions test whether a hash key is present
2018
2019 Given an expression that specifies an element of a hash, returns true if the
2020 specified element in the hash has ever been initialized, even if the
2021 corresponding value is undefined.
2022
2023     print "Exists\n"    if exists $hash{$key};
2024     print "Defined\n"   if defined $hash{$key};
2025     print "True\n"      if $hash{$key};
2026
2027 exists may also be called on array elements, but its behavior is much less
2028 obvious and is strongly tied to the use of L</delete> on arrays.  B<Be aware>
2029 that calling exists on array values is deprecated and likely to be removed in
2030 a future version of Perl.
2031
2032     print "Exists\n"    if exists $array[$index];
2033     print "Defined\n"   if defined $array[$index];
2034     print "True\n"      if $array[$index];
2035
2036 A hash or array element can be true only if it's defined and defined only if
2037 it exists, but the reverse doesn't necessarily hold true.
2038
2039 Given an expression that specifies the name of a subroutine,
2040 returns true if the specified subroutine has ever been declared, even
2041 if it is undefined.  Mentioning a subroutine name for exists or defined
2042 does not count as declaring it.  Note that a subroutine that does not
2043 exist may still be callable: its package may have an C<AUTOLOAD>
2044 method that makes it spring into existence the first time that it is
2045 called; see L<perlsub>.
2046
2047     print "Exists\n"  if exists &subroutine;
2048     print "Defined\n" if defined &subroutine;
2049
2050 Note that the EXPR can be arbitrarily complicated as long as the final
2051 operation is a hash or array key lookup or subroutine name:
2052
2053     if (exists $ref->{A}->{B}->{$key})  { }
2054     if (exists $hash{A}{B}{$key})       { }
2055
2056     if (exists $ref->{A}->{B}->[$ix])   { }
2057     if (exists $hash{A}{B}[$ix])        { }
2058
2059     if (exists &{$ref->{A}{B}{$key}})   { }
2060
2061 Although the mostly deeply nested array or hash will not spring into
2062 existence just because its existence was tested, any intervening ones will.
2063 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
2064 into existence due to the existence test for the $key element above.
2065 This happens anywhere the arrow operator is used, including even here:
2066
2067     undef $ref;
2068     if (exists $ref->{"Some key"})    { }
2069     print $ref;  # prints HASH(0x80d3d5c)
2070
2071 This surprising autovivification in what does not at first--or even
2072 second--glance appear to be an lvalue context may be fixed in a future
2073 release.
2074
2075 Use of a subroutine call, rather than a subroutine name, as an argument
2076 to exists() is an error.
2077
2078     exists &sub;    # OK
2079     exists &sub();  # Error
2080
2081 =item exit EXPR
2082 X<exit> X<terminate> X<abort>
2083
2084 =item exit
2085
2086 =for Pod::Functions terminate this program
2087
2088 Evaluates EXPR and exits immediately with that value.    Example:
2089
2090     $ans = <STDIN>;
2091     exit 0 if $ans =~ /^[Xx]/;
2092
2093 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
2094 universally recognized values for EXPR are C<0> for success and C<1>
2095 for error; other values are subject to interpretation depending on the
2096 environment in which the Perl program is running.  For example, exiting
2097 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
2098 the mailer to return the item undelivered, but that's not true everywhere.
2099
2100 Don't use C<exit> to abort a subroutine if there's any chance that
2101 someone might want to trap whatever error happened.  Use C<die> instead,
2102 which can be trapped by an C<eval>.
2103
2104 The exit() function does not always exit immediately.  It calls any
2105 defined C<END> routines first, but these C<END> routines may not
2106 themselves abort the exit.  Likewise any object destructors that need to
2107 be called are called before the real exit.  C<END> routines and destructors
2108 can change the exit status by modifying C<$?>.  If this is a problem, you
2109 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
2110 See L<perlmod> for details.
2111
2112 Portability issues: L<perlport/exit>.
2113
2114 =item exp EXPR
2115 X<exp> X<exponential> X<antilog> X<antilogarithm> X<e>
2116
2117 =item exp
2118
2119 =for Pod::Functions raise I<e> to a power
2120
2121 Returns I<e> (the natural logarithm base) to the power of EXPR.
2122 If EXPR is omitted, gives C<exp($_)>.
2123
2124 =item fc EXPR
2125 X<fc> X<foldcase> X<casefold> X<fold-case> X<case-fold>
2126
2127 =item fc
2128
2129 =for Pod::Functions +fc return casefolded version of a string
2130
2131 Returns the casefolded version of EXPR.  This is the internal function
2132 implementing the C<\F> escape in double-quoted strings.
2133
2134 Casefolding is the process of mapping strings to a form where case
2135 differences are erased; comparing two strings in their casefolded
2136 form is effectively a way of asking if two strings are equal,
2137 regardless of case.
2138
2139 Roughly, if you ever found yourself writing this
2140
2141     lc($this) eq lc($that)  # Wrong!
2142         # or
2143     uc($this) eq uc($that)  # Also wrong!
2144         # or
2145     $this =~ /\Q$that/i     # Right!
2146
2147 Now you can write
2148
2149     fc($this) eq fc($that)
2150
2151 And get the correct results.
2152
2153 Perl only implements the full form of casefolding.
2154 For further information on casefolding, refer to
2155 the Unicode Standard, specifically sections 3.13 C<Default Case Operations>,
2156 4.2 C<Case-Normative>, and 5.18 C<Case Mappings>,
2157 available at L<http://www.unicode.org/versions/latest/>, as well as the
2158 Case Charts available at L<http://www.unicode.org/charts/case/>.
2159
2160 If EXPR is omitted, uses C<$_>.
2161
2162 This function behaves the same way under various pragma, such as in a locale,
2163 as L</lc> does.
2164
2165 While the Unicode Standard defines two additional forms of casefolding,
2166 one for Turkic languages and one that never maps one character into multiple
2167 characters, these are not provided by the Perl core; However, the CPAN module
2168 C<Unicode::Casing> may be used to provide an implementation.
2169
2170 This keyword is available only when the C<"fc"> feature is enabled,
2171 or when prefixed with C<CORE::>; See L<feature>. Alternately,
2172 include a C<use v5.16> or later to the current scope.
2173
2174 =item fcntl FILEHANDLE,FUNCTION,SCALAR
2175 X<fcntl>
2176
2177 =for Pod::Functions file control system call
2178
2179 Implements the fcntl(2) function.  You'll probably have to say
2180
2181     use Fcntl;
2182
2183 first to get the correct constant definitions.  Argument processing and
2184 value returned work just like C<ioctl> below.
2185 For example:
2186
2187     use Fcntl;
2188     fcntl($filehandle, F_GETFL, $packed_return_buffer)
2189         or die "can't fcntl F_GETFL: $!";
2190
2191 You don't have to check for C<defined> on the return from C<fcntl>.
2192 Like C<ioctl>, it maps a C<0> return from the system call into
2193 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
2194 in numeric context.  It is also exempt from the normal B<-w> warnings
2195 on improper numeric conversions.
2196
2197 Note that C<fcntl> raises an exception if used on a machine that
2198 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
2199 manpage to learn what functions are available on your system.
2200
2201 Here's an example of setting a filehandle named C<REMOTE> to be
2202 non-blocking at the system level.  You'll have to negotiate C<$|>
2203 on your own, though.
2204
2205     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
2206
2207     $flags = fcntl(REMOTE, F_GETFL, 0)
2208                 or die "Can't get flags for the socket: $!\n";
2209
2210     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
2211                 or die "Can't set flags for the socket: $!\n";
2212
2213 Portability issues: L<perlport/fcntl>.
2214
2215 =item __FILE__
2216 X<__FILE__>
2217
2218 =for Pod::Functions the name of the current source file
2219
2220 A special token that returns the name of the file in which it occurs.
2221
2222 =item fileno FILEHANDLE
2223 X<fileno>
2224
2225 =for Pod::Functions return file descriptor from filehandle
2226
2227 Returns the file descriptor for a filehandle, or undefined if the
2228 filehandle is not open.  If there is no real file descriptor at the OS
2229 level, as can happen with filehandles connected to memory objects via
2230 C<open> with a reference for the third argument, -1 is returned.
2231
2232 This is mainly useful for constructing
2233 bitmaps for C<select> and low-level POSIX tty-handling operations.
2234 If FILEHANDLE is an expression, the value is taken as an indirect
2235 filehandle, generally its name.
2236
2237 You can use this to find out whether two handles refer to the
2238 same underlying descriptor:
2239
2240     if (fileno(THIS) == fileno(THAT)) {
2241         print "THIS and THAT are dups\n";
2242     }
2243
2244 =item flock FILEHANDLE,OPERATION
2245 X<flock> X<lock> X<locking>
2246
2247 =for Pod::Functions lock an entire file with an advisory lock
2248
2249 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
2250 for success, false on failure.  Produces a fatal error if used on a
2251 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
2252 C<flock> is Perl's portable file-locking interface, although it locks
2253 entire files only, not records.
2254
2255 Two potentially non-obvious but traditional C<flock> semantics are
2256 that it waits indefinitely until the lock is granted, and that its locks
2257 are B<merely advisory>.  Such discretionary locks are more flexible, but
2258 offer fewer guarantees.  This means that programs that do not also use
2259 C<flock> may modify files locked with C<flock>.  See L<perlport>, 
2260 your port's specific documentation, and your system-specific local manpages
2261 for details.  It's best to assume traditional behavior if you're writing
2262 portable programs.  (But if you're not, you should as always feel perfectly
2263 free to write for your own system's idiosyncrasies (sometimes called
2264 "features").  Slavish adherence to portability concerns shouldn't get
2265 in the way of your getting your job done.)
2266
2267 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
2268 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
2269 you can use the symbolic names if you import them from the L<Fcntl> module,
2270 either individually, or as a group using the C<:flock> tag.  LOCK_SH
2271 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
2272 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
2273 LOCK_SH or LOCK_EX, then C<flock> returns immediately rather than blocking
2274 waiting for the lock; check the return status to see if you got it.
2275
2276 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
2277 before locking or unlocking it.
2278
2279 Note that the emulation built with lockf(3) doesn't provide shared
2280 locks, and it requires that FILEHANDLE be open with write intent.  These
2281 are the semantics that lockf(3) implements.  Most if not all systems
2282 implement lockf(3) in terms of fcntl(2) locking, though, so the
2283 differing semantics shouldn't bite too many people.
2284
2285 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
2286 be open with read intent to use LOCK_SH and requires that it be open
2287 with write intent to use LOCK_EX.
2288
2289 Note also that some versions of C<flock> cannot lock things over the
2290 network; you would need to use the more system-specific C<fcntl> for
2291 that.  If you like you can force Perl to ignore your system's flock(2)
2292 function, and so provide its own fcntl(2)-based emulation, by passing
2293 the switch C<-Ud_flock> to the F<Configure> program when you configure
2294 and build a new Perl.
2295
2296 Here's a mailbox appender for BSD systems.
2297
2298     use Fcntl qw(:flock SEEK_END); # import LOCK_* and SEEK_END constants
2299
2300     sub lock {
2301         my ($fh) = @_;
2302         flock($fh, LOCK_EX) or die "Cannot lock mailbox - $!\n";
2303
2304         # and, in case someone appended while we were waiting...
2305         seek($fh, 0, SEEK_END) or die "Cannot seek - $!\n";
2306     }
2307
2308     sub unlock {
2309         my ($fh) = @_;
2310         flock($fh, LOCK_UN) or die "Cannot unlock mailbox - $!\n";
2311     }
2312
2313     open(my $mbox, ">>", "/usr/spool/mail/$ENV{'USER'}")
2314         or die "Can't open mailbox: $!";
2315
2316     lock($mbox);
2317     print $mbox $msg,"\n\n";
2318     unlock($mbox);
2319
2320 On systems that support a real flock(2), locks are inherited across fork()
2321 calls, whereas those that must resort to the more capricious fcntl(2)
2322 function lose their locks, making it seriously harder to write servers.
2323
2324 See also L<DB_File> for other flock() examples.
2325
2326 Portability issues: L<perlport/flock>.
2327
2328 =item fork
2329 X<fork> X<child> X<parent>
2330
2331 =for Pod::Functions create a new process just like this one
2332
2333 Does a fork(2) system call to create a new process running the
2334 same program at the same point.  It returns the child pid to the
2335 parent process, C<0> to the child process, or C<undef> if the fork is
2336 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
2337 are shared, while everything else is copied.  On most systems supporting
2338 fork(), great care has gone into making it extremely efficient (for
2339 example, using copy-on-write technology on data pages), making it the
2340 dominant paradigm for multitasking over the last few decades.
2341
2342 Beginning with v5.6.0, Perl attempts to flush all files opened for
2343 output before forking the child process, but this may not be supported
2344 on some platforms (see L<perlport>).  To be safe, you may need to set
2345 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
2346 C<IO::Handle> on any open handles to avoid duplicate output.
2347
2348 If you C<fork> without ever waiting on your children, you will
2349 accumulate zombies.  On some systems, you can avoid this by setting
2350 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
2351 forking and reaping moribund children.
2352
2353 Note that if your forked child inherits system file descriptors like
2354 STDIN and STDOUT that are actually connected by a pipe or socket, even
2355 if you exit, then the remote server (such as, say, a CGI script or a
2356 backgrounded job launched from a remote shell) won't think you're done.
2357 You should reopen those to F</dev/null> if it's any issue.
2358
2359 On some platforms such as Windows, where the fork() system call is not available,
2360 Perl can be built to emulate fork() in the Perl interpreter.
2361 The emulation is designed, at the level of the Perl program,
2362 to be as compatible as possible with the "Unix" fork().
2363 However it has limitations that have to be considered in code intended to be portable.
2364 See L<perlfork> for more details.
2365
2366 Portability issues: L<perlport/fork>.
2367
2368 =item format
2369 X<format>
2370
2371 =for Pod::Functions declare a picture format with use by the write() function
2372
2373 Declare a picture format for use by the C<write> function.  For
2374 example:
2375
2376     format Something =
2377         Test: @<<<<<<<< @||||| @>>>>>
2378               $str,     $%,    '$' . int($num)
2379     .
2380
2381     $str = "widget";
2382     $num = $cost/$quantity;
2383     $~ = 'Something';
2384     write;
2385
2386 See L<perlform> for many details and examples.
2387
2388 =item formline PICTURE,LIST
2389 X<formline>
2390
2391 =for Pod::Functions internal function used for formats
2392
2393 This is an internal function used by C<format>s, though you may call it,
2394 too.  It formats (see L<perlform>) a list of values according to the
2395 contents of PICTURE, placing the output into the format output
2396 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
2397 Eventually, when a C<write> is done, the contents of
2398 C<$^A> are written to some filehandle.  You could also read C<$^A>
2399 and then set C<$^A> back to C<"">.  Note that a format typically
2400 does one C<formline> per line of form, but the C<formline> function itself
2401 doesn't care how many newlines are embedded in the PICTURE.  This means
2402 that the C<~> and C<~~> tokens treat the entire PICTURE as a single line.
2403 You may therefore need to use multiple formlines to implement a single
2404 record format, just like the C<format> compiler.
2405
2406 Be careful if you put double quotes around the picture, because an C<@>
2407 character may be taken to mean the beginning of an array name.
2408 C<formline> always returns true.  See L<perlform> for other examples.
2409
2410 If you are trying to use this instead of C<write> to capture the output,
2411 you may find it easier to open a filehandle to a scalar
2412 (C<< open $fh, ">", \$output >>) and write to that instead.
2413
2414 =item getc FILEHANDLE
2415 X<getc> X<getchar> X<character> X<file, read>
2416
2417 =item getc
2418
2419 =for Pod::Functions get the next character from the filehandle
2420
2421 Returns the next character from the input file attached to FILEHANDLE,
2422 or the undefined value at end of file or if there was an error (in
2423 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
2424 STDIN.  This is not particularly efficient.  However, it cannot be
2425 used by itself to fetch single characters without waiting for the user
2426 to hit enter.  For that, try something more like:
2427
2428     if ($BSD_STYLE) {
2429         system "stty cbreak </dev/tty >/dev/tty 2>&1";
2430     }
2431     else {
2432         system "stty", '-icanon', 'eol', "\001";
2433     }
2434
2435     $key = getc(STDIN);
2436
2437     if ($BSD_STYLE) {
2438         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
2439     }
2440     else {
2441         system 'stty', 'icanon', 'eol', '^@'; # ASCII NUL
2442     }
2443     print "\n";
2444
2445 Determination of whether $BSD_STYLE should be set
2446 is left as an exercise to the reader.
2447
2448 The C<POSIX::getattr> function can do this more portably on
2449 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
2450 module from your nearest CPAN site; details on CPAN can be found under
2451 L<perlmodlib/CPAN>.
2452
2453 =item getlogin
2454 X<getlogin> X<login>
2455
2456 =for Pod::Functions return who logged in at this tty
2457
2458 This implements the C library function of the same name, which on most
2459 systems returns the current login from F</etc/utmp>, if any.  If it
2460 returns the empty string, use C<getpwuid>.
2461
2462     $login = getlogin || getpwuid($<) || "Kilroy";
2463
2464 Do not consider C<getlogin> for authentication: it is not as
2465 secure as C<getpwuid>.
2466
2467 Portability issues: L<perlport/getlogin>.
2468
2469 =item getpeername SOCKET
2470 X<getpeername> X<peer>
2471
2472 =for Pod::Functions find the other end of a socket connection
2473
2474 Returns the packed sockaddr address of the other end of the SOCKET
2475 connection.
2476
2477     use Socket;
2478     $hersockaddr    = getpeername(SOCK);
2479     ($port, $iaddr) = sockaddr_in($hersockaddr);
2480     $herhostname    = gethostbyaddr($iaddr, AF_INET);
2481     $herstraddr     = inet_ntoa($iaddr);
2482
2483 =item getpgrp PID
2484 X<getpgrp> X<group>
2485
2486 =for Pod::Functions get process group
2487
2488 Returns the current process group for the specified PID.  Use
2489 a PID of C<0> to get the current process group for the
2490 current process.  Will raise an exception if used on a machine that
2491 doesn't implement getpgrp(2).  If PID is omitted, returns the process
2492 group of the current process.  Note that the POSIX version of C<getpgrp>
2493 does not accept a PID argument, so only C<PID==0> is truly portable.
2494
2495 Portability issues: L<perlport/getpgrp>.
2496
2497 =item getppid
2498 X<getppid> X<parent> X<pid>
2499
2500 =for Pod::Functions get parent process ID
2501
2502 Returns the process id of the parent process.
2503
2504 Note for Linux users: Between v5.8.1 and v5.16.0 Perl would work
2505 around non-POSIX thread semantics the minority of Linux systems (and
2506 Debian GNU/kFreeBSD systems) that used LinuxThreads, this emulation
2507 has since been removed. See the documentation for L<$$|perlvar/$$> for
2508 details.
2509
2510 Portability issues: L<perlport/getppid>.
2511
2512 =item getpriority WHICH,WHO
2513 X<getpriority> X<priority> X<nice>
2514
2515 =for Pod::Functions get current nice value
2516
2517 Returns the current priority for a process, a process group, or a user.
2518 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
2519 machine that doesn't implement getpriority(2).
2520
2521 Portability issues: L<perlport/getpriority>.
2522
2523 =item getpwnam NAME
2524 X<getpwnam> X<getgrnam> X<gethostbyname> X<getnetbyname> X<getprotobyname>
2525 X<getpwuid> X<getgrgid> X<getservbyname> X<gethostbyaddr> X<getnetbyaddr>
2526 X<getprotobynumber> X<getservbyport> X<getpwent> X<getgrent> X<gethostent>
2527 X<getnetent> X<getprotoent> X<getservent> X<setpwent> X<setgrent> X<sethostent>
2528 X<setnetent> X<setprotoent> X<setservent> X<endpwent> X<endgrent> X<endhostent>
2529 X<endnetent> X<endprotoent> X<endservent> 
2530
2531 =for Pod::Functions get passwd record given user login name
2532
2533 =item getgrnam NAME
2534
2535 =for Pod::Functions get group record given group name
2536
2537 =item gethostbyname NAME
2538
2539 =for Pod::Functions get host record given name
2540
2541 =item getnetbyname NAME
2542
2543 =for Pod::Functions get networks record given name
2544
2545 =item getprotobyname NAME
2546
2547 =for Pod::Functions get protocol record given name
2548
2549 =item getpwuid UID
2550
2551 =for Pod::Functions get passwd record given user ID
2552
2553 =item getgrgid GID
2554
2555 =for Pod::Functions get group record given group user ID
2556
2557 =item getservbyname NAME,PROTO
2558
2559 =for Pod::Functions get services record given its name
2560
2561 =item gethostbyaddr ADDR,ADDRTYPE
2562
2563 =for Pod::Functions get host record given its address
2564
2565 =item getnetbyaddr ADDR,ADDRTYPE
2566
2567 =for Pod::Functions get network record given its address
2568
2569 =item getprotobynumber NUMBER
2570
2571 =for Pod::Functions get protocol record numeric protocol
2572
2573 =item getservbyport PORT,PROTO
2574
2575 =for Pod::Functions get services record given numeric port
2576
2577 =item getpwent
2578
2579 =for Pod::Functions get next passwd record
2580
2581 =item getgrent
2582
2583 =for Pod::Functions get next group record
2584
2585 =item gethostent
2586
2587 =for Pod::Functions get next hosts record
2588
2589 =item getnetent
2590
2591 =for Pod::Functions get next networks record
2592
2593 =item getprotoent
2594
2595 =for Pod::Functions get next protocols record
2596
2597 =item getservent
2598
2599 =for Pod::Functions get next services record
2600
2601 =item setpwent
2602
2603 =for Pod::Functions prepare passwd file for use
2604
2605 =item setgrent
2606
2607 =for Pod::Functions prepare group file for use
2608
2609 =item sethostent STAYOPEN
2610
2611 =for Pod::Functions prepare hosts file for use
2612
2613 =item setnetent STAYOPEN
2614
2615 =for Pod::Functions prepare networks file for use
2616
2617 =item setprotoent STAYOPEN
2618
2619 =for Pod::Functions prepare protocols file for use
2620
2621 =item setservent STAYOPEN
2622
2623 =for Pod::Functions prepare services file for use
2624
2625 =item endpwent
2626
2627 =for Pod::Functions be done using passwd file
2628
2629 =item endgrent
2630
2631 =for Pod::Functions be done using group file
2632
2633 =item endhostent
2634
2635 =for Pod::Functions be done using hosts file
2636
2637 =item endnetent
2638
2639 =for Pod::Functions be done using networks file
2640
2641 =item endprotoent
2642
2643 =for Pod::Functions be done using protocols file
2644
2645 =item endservent
2646
2647 =for Pod::Functions be done using services file
2648
2649 These routines are the same as their counterparts in the
2650 system C library.  In list context, the return values from the
2651 various get routines are as follows:
2652
2653     ($name,$passwd,$uid,$gid,
2654        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
2655     ($name,$passwd,$gid,$members) = getgr*
2656     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2657     ($name,$aliases,$addrtype,$net) = getnet*
2658     ($name,$aliases,$proto) = getproto*
2659     ($name,$aliases,$port,$proto) = getserv*
2660
2661 (If the entry doesn't exist you get an empty list.)
2662
2663 The exact meaning of the $gcos field varies but it usually contains
2664 the real name of the user (as opposed to the login name) and other
2665 information pertaining to the user.  Beware, however, that in many
2666 system users are able to change this information and therefore it
2667 cannot be trusted and therefore the $gcos is tainted (see
2668 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2669 login shell, are also tainted, for the same reason.
2670
2671 In scalar context, you get the name, unless the function was a
2672 lookup by name, in which case you get the other thing, whatever it is.
2673 (If the entry doesn't exist you get the undefined value.)  For example:
2674
2675     $uid   = getpwnam($name);
2676     $name  = getpwuid($num);
2677     $name  = getpwent();
2678     $gid   = getgrnam($name);
2679     $name  = getgrgid($num);
2680     $name  = getgrent();
2681     #etc.
2682
2683 In I<getpw*()> the fields $quota, $comment, and $expire are special
2684 in that they are unsupported on many systems.  If the
2685 $quota is unsupported, it is an empty scalar.  If it is supported, it
2686 usually encodes the disk quota.  If the $comment field is unsupported,
2687 it is an empty scalar.  If it is supported it usually encodes some
2688 administrative comment about the user.  In some systems the $quota
2689 field may be $change or $age, fields that have to do with password
2690 aging.  In some systems the $comment field may be $class.  The $expire
2691 field, if present, encodes the expiration period of the account or the
2692 password.  For the availability and the exact meaning of these fields
2693 in your system, please consult getpwnam(3) and your system's 
2694 F<pwd.h> file.  You can also find out from within Perl what your
2695 $quota and $comment fields mean and whether you have the $expire field
2696 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2697 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2698 files are supported only if your vendor has implemented them in the
2699 intuitive fashion that calling the regular C library routines gets the
2700 shadow versions if you're running under privilege or if there exists
2701 the shadow(3) functions as found in System V (this includes Solaris
2702 and Linux).  Those systems that implement a proprietary shadow password
2703 facility are unlikely to be supported.
2704
2705 The $members value returned by I<getgr*()> is a space-separated list of
2706 the login names of the members of the group.
2707
2708 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2709 C, it will be returned to you via C<$?> if the function call fails.  The
2710 C<@addrs> value returned by a successful call is a list of raw
2711 addresses returned by the corresponding library call.  In the
2712 Internet domain, each address is four bytes long; you can unpack it
2713 by saying something like:
2714
2715     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2716
2717 The Socket library makes this slightly easier:
2718
2719     use Socket;
2720     $iaddr = inet_aton("127.1"); # or whatever address
2721     $name  = gethostbyaddr($iaddr, AF_INET);
2722
2723     # or going the other way
2724     $straddr = inet_ntoa($iaddr);
2725
2726 In the opposite way, to resolve a hostname to the IP address
2727 you can write this:
2728
2729     use Socket;
2730     $packed_ip = gethostbyname("www.perl.org");
2731     if (defined $packed_ip) {
2732         $ip_address = inet_ntoa($packed_ip);
2733     }
2734
2735 Make sure C<gethostbyname()> is called in SCALAR context and that
2736 its return value is checked for definedness.
2737
2738 The C<getprotobynumber> function, even though it only takes one argument,
2739 has the precedence of a list operator, so beware:
2740
2741     getprotobynumber $number eq 'icmp'   # WRONG
2742     getprotobynumber($number eq 'icmp')  # actually means this
2743     getprotobynumber($number) eq 'icmp'  # better this way
2744
2745 If you get tired of remembering which element of the return list
2746 contains which return value, by-name interfaces are provided
2747 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2748 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2749 and C<User::grent>.  These override the normal built-ins, supplying
2750 versions that return objects with the appropriate names
2751 for each field.  For example:
2752
2753    use File::stat;
2754    use User::pwent;
2755    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2756
2757 Even though it looks as though they're the same method calls (uid),
2758 they aren't, because a C<File::stat> object is different from
2759 a C<User::pwent> object.
2760
2761 Portability issues: L<perlport/getpwnam> to L<perlport/endservent>.
2762
2763 =item getsockname SOCKET
2764 X<getsockname>
2765
2766 =for Pod::Functions retrieve the sockaddr for a given socket
2767
2768 Returns the packed sockaddr address of this end of the SOCKET connection,
2769 in case you don't know the address because you have several different
2770 IPs that the connection might have come in on.
2771
2772     use Socket;
2773     $mysockaddr = getsockname(SOCK);
2774     ($port, $myaddr) = sockaddr_in($mysockaddr);
2775     printf "Connect to %s [%s]\n",
2776        scalar gethostbyaddr($myaddr, AF_INET),
2777        inet_ntoa($myaddr);
2778
2779 =item getsockopt SOCKET,LEVEL,OPTNAME
2780 X<getsockopt>
2781
2782 =for Pod::Functions get socket options on a given socket
2783
2784 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2785 Options may exist at multiple protocol levels depending on the socket
2786 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2787 C<Socket> module) will exist.  To query options at another level the
2788 protocol number of the appropriate protocol controlling the option
2789 should be supplied.  For example, to indicate that an option is to be
2790 interpreted by the TCP protocol, LEVEL should be set to the protocol
2791 number of TCP, which you can get using C<getprotobyname>.
2792
2793 The function returns a packed string representing the requested socket
2794 option, or C<undef> on error, with the reason for the error placed in
2795 C<$!>.  Just what is in the packed string depends on LEVEL and OPTNAME;
2796 consult getsockopt(2) for details.  A common case is that the option is an
2797 integer, in which case the result is a packed integer, which you can decode
2798 using C<unpack> with the C<i> (or C<I>) format.
2799
2800 Here's an example to test whether Nagle's algorithm is enabled on a socket:
2801
2802     use Socket qw(:all);
2803
2804     defined(my $tcp = getprotobyname("tcp"))
2805         or die "Could not determine the protocol number for tcp";
2806     # my $tcp = IPPROTO_TCP; # Alternative
2807     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2808         or die "getsockopt TCP_NODELAY: $!";
2809     my $nodelay = unpack("I", $packed);
2810     print "Nagle's algorithm is turned ", $nodelay ? "off\n" : "on\n";
2811
2812 Portability issues: L<perlport/getsockopt>.
2813
2814 =item given EXPR BLOCK
2815 X<given>
2816
2817 =item given BLOCK
2818
2819 =for Pod::Functions !RT #108848
2820
2821 C<given> is analogous to the C<switch>
2822 keyword in other languages.  C<given>
2823 and C<when> are used in Perl to implement C<switch>/C<case> like statements.
2824 Only available after Perl 5.10.  For example:
2825
2826     use v5.10;
2827     given ($fruit) {
2828         when (/apples?/) {
2829             print "I like apples."
2830         }
2831         when (/oranges?/) {
2832             print "I don't like oranges."
2833         }
2834         default {
2835             print "I don't like anything"
2836         }
2837     }
2838
2839 See L<perlsyn/"Switch Statements"> for detailed information.
2840
2841 =item glob EXPR
2842 X<glob> X<wildcard> X<filename, expansion> X<expand>
2843
2844 =item glob
2845
2846 =for Pod::Functions expand filenames using wildcards
2847
2848 In list context, returns a (possibly empty) list of filename expansions on
2849 the value of EXPR such as the standard Unix shell F</bin/csh> would do.  In
2850 scalar context, glob iterates through such filename expansions, returning
2851 undef when the list is exhausted.  This is the internal function
2852 implementing the C<< <*.c> >> operator, but you can use it directly.  If
2853 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2854 more detail in L<perlop/"I/O Operators">.
2855
2856 Note that C<glob> splits its arguments on whitespace and treats
2857 each segment as separate pattern.  As such, C<glob("*.c *.h")> 
2858 matches all files with a F<.c> or F<.h> extension.  The expression
2859 C<glob(".* *")> matches all files in the current working directory.
2860 If you want to glob filenames that might contain whitespace, you'll
2861 have to use extra quotes around the spacey filename to protect it.
2862 For example, to glob filenames that have an C<e> followed by a space
2863 followed by an C<f>, use either of:
2864
2865     @spacies = <"*e f*">;
2866     @spacies = glob '"*e f*"';
2867     @spacies = glob q("*e f*");
2868
2869 If you had to get a variable through, you could do this:
2870
2871     @spacies = glob "'*${var}e f*'";
2872     @spacies = glob qq("*${var}e f*");
2873
2874 If non-empty braces are the only wildcard characters used in the
2875 C<glob>, no filenames are matched, but potentially many strings
2876 are returned.  For example, this produces nine strings, one for
2877 each pairing of fruits and colors:
2878
2879     @many =  glob "{apple,tomato,cherry}={green,yellow,red}";
2880
2881 Beginning with v5.6.0, this operator is implemented using the standard
2882 C<File::Glob> extension.  See L<File::Glob> for details, including
2883 C<bsd_glob> which does not treat whitespace as a pattern separator.
2884
2885 Portability issues: L<perlport/glob>.
2886
2887 =item gmtime EXPR
2888 X<gmtime> X<UTC> X<Greenwich>
2889
2890 =item gmtime
2891
2892 =for Pod::Functions convert UNIX time into record or string using Greenwich time
2893
2894 Works just like L</localtime> but the returned values are
2895 localized for the standard Greenwich time zone.
2896
2897 Note: When called in list context, $isdst, the last value
2898 returned by gmtime, is always C<0>.  There is no
2899 Daylight Saving Time in GMT.
2900
2901 Portability issues: L<perlport/gmtime>.
2902
2903 =item goto LABEL
2904 X<goto> X<jump> X<jmp>
2905
2906 =item goto EXPR
2907
2908 =item goto &NAME
2909
2910 =for Pod::Functions create spaghetti code
2911
2912 The C<goto-LABEL> form finds the statement labeled with LABEL and
2913 resumes execution there.  It can't be used to get out of a block or
2914 subroutine given to C<sort>.  It can be used to go almost anywhere
2915 else within the dynamic scope, including out of subroutines, but it's
2916 usually better to use some other construct such as C<last> or C<die>.
2917 The author of Perl has never felt the need to use this form of C<goto>
2918 (in Perl, that is; C is another matter).  (The difference is that C
2919 does not offer named loops combined with loop control.  Perl does, and
2920 this replaces most structured uses of C<goto> in other languages.)
2921
2922 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2923 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2924 necessarily recommended if you're optimizing for maintainability:
2925
2926     goto ("FOO", "BAR", "GLARCH")[$i];
2927
2928 As shown in this example, C<goto-EXPR> is exempt from the "looks like a
2929 function" rule.  A pair of parentheses following it does not (necessarily)
2930 delimit its argument.  C<goto("NE")."XT"> is equivalent to C<goto NEXT>.
2931
2932 Use of C<goto-LABEL> or C<goto-EXPR> to jump into a construct is
2933 deprecated and will issue a warning.  Even then, it may not be used to
2934 go into any construct that requires initialization, such as a
2935 subroutine or a C<foreach> loop.  It also can't be used to go into a
2936 construct that is optimized away.
2937
2938 The C<goto-&NAME> form is quite different from the other forms of
2939 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2940 doesn't have the stigma associated with other gotos.  Instead, it
2941 exits the current subroutine (losing any changes set by local()) and
2942 immediately calls in its place the named subroutine using the current
2943 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2944 load another subroutine and then pretend that the other subroutine had
2945 been called in the first place (except that any modifications to C<@_>
2946 in the current subroutine are propagated to the other subroutine.)
2947 After the C<goto>, not even C<caller> will be able to tell that this
2948 routine was called first.
2949
2950 NAME needn't be the name of a subroutine; it can be a scalar variable
2951 containing a code reference or a block that evaluates to a code
2952 reference.
2953
2954 =item grep BLOCK LIST
2955 X<grep>
2956
2957 =item grep EXPR,LIST
2958
2959 =for Pod::Functions locate elements in a list test true against a given criterion
2960
2961 This is similar in spirit to, but not the same as, grep(1) and its
2962 relatives.  In particular, it is not limited to using regular expressions.
2963
2964 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2965 C<$_> to each element) and returns the list value consisting of those
2966 elements for which the expression evaluated to true.  In scalar
2967 context, returns the number of times the expression was true.
2968
2969     @foo = grep(!/^#/, @bar);    # weed out comments
2970
2971 or equivalently,
2972
2973     @foo = grep {!/^#/} @bar;    # weed out comments
2974
2975 Note that C<$_> is an alias to the list value, so it can be used to
2976 modify the elements of the LIST.  While this is useful and supported,
2977 it can cause bizarre results if the elements of LIST are not variables.
2978 Similarly, grep returns aliases into the original list, much as a for
2979 loop's index variable aliases the list elements.  That is, modifying an
2980 element of a list returned by grep (for example, in a C<foreach>, C<map>
2981 or another C<grep>) actually modifies the element in the original list.
2982 This is usually something to be avoided when writing clear code.
2983
2984 If C<$_> is lexical in the scope where the C<grep> appears (because it has
2985 been declared with C<my $_>) then, in addition to being locally aliased to
2986 the list elements, C<$_> keeps being lexical inside the block; i.e., it
2987 can't be seen from the outside, avoiding any potential side-effects.
2988
2989 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2990
2991 =item hex EXPR
2992 X<hex> X<hexadecimal>
2993
2994 =item hex
2995
2996 =for Pod::Functions convert a string to a hexadecimal number
2997
2998 Interprets EXPR as a hex string and returns the corresponding value.
2999 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
3000 L</oct>.)  If EXPR is omitted, uses C<$_>.
3001
3002     print hex '0xAf'; # prints '175'
3003     print hex 'aF';   # same
3004
3005 Hex strings may only represent integers.  Strings that would cause
3006 integer overflow trigger a warning.  Leading whitespace is not stripped,
3007 unlike oct().  To present something as hex, look into L</printf>,
3008 L</sprintf>, and L</unpack>.
3009
3010 =item import LIST
3011 X<import>
3012
3013 =for Pod::Functions patch a module's namespace into your own
3014
3015 There is no builtin C<import> function.  It is just an ordinary
3016 method (subroutine) defined (or inherited) by modules that wish to export
3017 names to another module.  The C<use> function calls the C<import> method
3018 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
3019
3020 =item index STR,SUBSTR,POSITION
3021 X<index> X<indexOf> X<InStr>
3022
3023 =item index STR,SUBSTR
3024
3025 =for Pod::Functions find a substring within a string
3026
3027 The index function searches for one string within another, but without
3028 the wildcard-like behavior of a full regular-expression pattern match.
3029 It returns the position of the first occurrence of SUBSTR in STR at
3030 or after POSITION.  If POSITION is omitted, starts searching from the
3031 beginning of the string.  POSITION before the beginning of the string
3032 or after its end is treated as if it were the beginning or the end,
3033 respectively.  POSITION and the return value are based at zero.
3034 If the substring is not found, C<index> returns -1.
3035
3036 =item int EXPR
3037 X<int> X<integer> X<truncate> X<trunc> X<floor>
3038
3039 =item int
3040
3041 =for Pod::Functions get the integer portion of a number
3042
3043 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
3044 You should not use this function for rounding: one because it truncates
3045 towards C<0>, and two because machine representations of floating-point
3046 numbers can sometimes produce counterintuitive results.  For example,
3047 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
3048 because it's really more like -268.99999999999994315658 instead.  Usually,
3049 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
3050 functions will serve you better than will int().
3051
3052 =item ioctl FILEHANDLE,FUNCTION,SCALAR
3053 X<ioctl>
3054
3055 =for Pod::Functions system-dependent device control system call
3056
3057 Implements the ioctl(2) function.  You'll probably first have to say
3058
3059     require "sys/ioctl.ph";  # probably in $Config{archlib}/sys/ioctl.ph
3060
3061 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
3062 exist or doesn't have the correct definitions you'll have to roll your
3063 own, based on your C header files such as F<< <sys/ioctl.h> >>.
3064 (There is a Perl script called B<h2ph> that comes with the Perl kit that
3065 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
3066 written depending on the FUNCTION; a C pointer to the string value of SCALAR
3067 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
3068 has no string value but does have a numeric value, that value will be
3069 passed rather than a pointer to the string value.  To guarantee this to be
3070 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
3071 functions may be needed to manipulate the values of structures used by
3072 C<ioctl>.
3073
3074 The return value of C<ioctl> (and C<fcntl>) is as follows:
3075
3076     if OS returns:      then Perl returns:
3077         -1               undefined value
3078          0              string "0 but true"
3079     anything else           that number
3080
3081 Thus Perl returns true on success and false on failure, yet you can
3082 still easily determine the actual value returned by the operating
3083 system:
3084
3085     $retval = ioctl(...) || -1;
3086     printf "System returned %d\n", $retval;
3087
3088 The special string C<"0 but true"> is exempt from B<-w> complaints
3089 about improper numeric conversions.
3090
3091 Portability issues: L<perlport/ioctl>.
3092
3093 =item join EXPR,LIST
3094 X<join>
3095
3096 =for Pod::Functions join a list into a string using a separator
3097
3098 Joins the separate strings of LIST into a single string with fields
3099 separated by the value of EXPR, and returns that new string.  Example:
3100
3101     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
3102
3103 Beware that unlike C<split>, C<join> doesn't take a pattern as its
3104 first argument.  Compare L</split>.
3105
3106 =item keys HASH
3107 X<keys> X<key>
3108
3109 =item keys ARRAY
3110
3111 =item keys EXPR
3112
3113 =for Pod::Functions retrieve list of indices from a hash
3114
3115 Called in list context, returns a list consisting of all the keys of the
3116 named hash, or in Perl 5.12 or later only, the indices of an array.  Perl
3117 releases prior to 5.12 will produce a syntax error if you try to use an
3118 array argument.  In scalar context, returns the number of keys or indices.
3119
3120 The keys of a hash are returned in an apparently random order.  The actual
3121 random order is subject to change in future versions of Perl, but it
3122 is guaranteed to be the same order as either the C<values> or C<each>
3123 function produces (given that the hash has not been modified).  Since
3124 Perl 5.8.1 the ordering can be different even between different runs of
3125 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
3126 Attacks">).
3127
3128 As a side effect, calling keys() resets the internal interator of the HASH or ARRAY
3129 (see L</each>).  In particular, calling keys() in void context resets
3130 the iterator with no other overhead.
3131
3132 Here is yet another way to print your environment:
3133
3134     @keys = keys %ENV;
3135     @values = values %ENV;
3136     while (@keys) {
3137         print pop(@keys), '=', pop(@values), "\n";
3138     }
3139
3140 or how about sorted by key:
3141
3142     foreach $key (sort(keys %ENV)) {
3143         print $key, '=', $ENV{$key}, "\n";
3144     }
3145
3146 The returned values are copies of the original keys in the hash, so
3147 modifying them will not affect the original hash.  Compare L</values>.
3148
3149 To sort a hash by value, you'll need to use a C<sort> function.
3150 Here's a descending numeric sort of a hash by its values:
3151
3152     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
3153         printf "%4d %s\n", $hash{$key}, $key;
3154     }
3155
3156 Used as an lvalue, C<keys> allows you to increase the number of hash buckets
3157 allocated for the given hash.  This can gain you a measure of efficiency if
3158 you know the hash is going to get big.  (This is similar to pre-extending
3159 an array by assigning a larger number to $#array.)  If you say
3160
3161     keys %hash = 200;
3162
3163 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
3164 in fact, since it rounds up to the next power of two.  These
3165 buckets will be retained even if you do C<%hash = ()>, use C<undef
3166 %hash> if you want to free the storage while C<%hash> is still in scope.
3167 You can't shrink the number of buckets allocated for the hash using
3168 C<keys> in this way (but you needn't worry about doing this by accident,
3169 as trying has no effect).  C<keys @array> in an lvalue context is a syntax
3170 error.
3171
3172 Starting with Perl 5.14, C<keys> can take a scalar EXPR, which must contain
3173 a reference to an unblessed hash or array.  The argument will be
3174 dereferenced automatically.  This aspect of C<keys> is considered highly
3175 experimental.  The exact behaviour may change in a future version of Perl.
3176
3177     for (keys $hashref) { ... }
3178     for (keys $obj->get_arrayref) { ... }
3179
3180 To avoid confusing would-be users of your code who are running earlier
3181 versions of Perl with mysterious syntax errors, put this sort of thing at
3182 the top of your file to signal that your code will work I<only> on Perls of
3183 a recent vintage:
3184
3185     use 5.012;  # so keys/values/each work on arrays
3186     use 5.014;  # so keys/values/each work on scalars (experimental)
3187
3188 See also C<each>, C<values>, and C<sort>.
3189
3190 =item kill SIGNAL, LIST
3191
3192 =item kill SIGNAL
3193 X<kill> X<signal>
3194
3195 =for Pod::Functions send a signal to a process or process group
3196
3197 Sends a signal to a list of processes.  Returns the number of
3198 processes successfully signaled (which is not necessarily the
3199 same as the number actually killed).
3200
3201     $cnt = kill 1, $child1, $child2;
3202     kill 9, @goners;
3203
3204 If SIGNAL is zero, no signal is sent to the process, but C<kill>
3205 checks whether it's I<possible> to send a signal to it (that
3206 means, to be brief, that the process is owned by the same user, or we are
3207 the super-user).  This is useful to check that a child process is still
3208 alive (even if only as a zombie) and hasn't changed its UID.  See
3209 L<perlport> for notes on the portability of this construct.
3210
3211 Unlike in the shell, if SIGNAL is negative, it kills process groups instead
3212 of processes.  That means you usually
3213 want to use positive not negative signals.
3214 You may also use a signal name in quotes.
3215
3216 The behavior of kill when a I<PROCESS> number is zero or negative depends on
3217 the operating system.  For example, on POSIX-conforming systems, zero will
3218 signal the current process group and -1 will signal all processes.
3219
3220 See L<perlipc/"Signals"> for more details.
3221
3222 On some platforms such as Windows where the fork() system call is not available.
3223 Perl can be built to emulate fork() at the interpreter level.
3224 This emulation has limitations related to kill that have to be considered,
3225 for code running on Windows and in code intended to be portable.
3226
3227 See L<perlfork> for more details.
3228
3229 If there is no I<LIST> of processes, no signal is sent, and the return
3230 value is 0.  This form is sometimes used, however, because it causes
3231 tainting checks to be run.  But see
3232 L<perlsec/Laundering and Detecting Tainted Data>.
3233
3234 Portability issues: L<perlport/kill>.
3235
3236 =item last LABEL
3237 X<last> X<break>
3238
3239 =item last
3240
3241 =for Pod::Functions exit a block prematurely
3242
3243 The C<last> command is like the C<break> statement in C (as used in
3244 loops); it immediately exits the loop in question.  If the LABEL is
3245 omitted, the command refers to the innermost enclosing loop.  The
3246 C<continue> block, if any, is not executed:
3247
3248     LINE: while (<STDIN>) {
3249         last LINE if /^$/;  # exit when done with header
3250         #...
3251     }
3252
3253 C<last> cannot be used to exit a block that returns a value such as
3254 C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit
3255 a grep() or map() operation.
3256
3257 Note that a block by itself is semantically identical to a loop
3258 that executes once.  Thus C<last> can be used to effect an early
3259 exit out of such a block.
3260
3261 See also L</continue> for an illustration of how C<last>, C<next>, and
3262 C<redo> work.
3263
3264 =item lc EXPR
3265 X<lc> X<lowercase>
3266
3267 =item lc
3268
3269 =for Pod::Functions return lower-case version of a string
3270
3271 Returns a lowercased version of EXPR.  This is the internal function
3272 implementing the C<\L> escape in double-quoted strings.
3273
3274 If EXPR is omitted, uses C<$_>.
3275
3276 What gets returned depends on several factors:
3277
3278 =over
3279
3280 =item If C<use bytes> is in effect:
3281
3282 =over
3283
3284 =item On EBCDIC platforms
3285
3286 The results are what the C language system call C<tolower()> returns.
3287
3288 =item On ASCII platforms
3289
3290 The results follow ASCII semantics.  Only characters C<A-Z> change, to C<a-z>
3291 respectively.
3292
3293 =back
3294
3295 =item Otherwise, if C<use locale> (but not C<use locale ':not_characters'>) is in effect:
3296
3297 Respects current LC_CTYPE locale for code points < 256; and uses Unicode
3298 semantics for the remaining code points (this last can only happen if
3299 the UTF8 flag is also set).  See L<perllocale>.
3300
3301 A deficiency in this is that case changes that cross the 255/256
3302 boundary are not well-defined.  For example, the lower case of LATIN CAPITAL
3303 LETTER SHARP S (U+1E9E) in Unicode semantics is U+00DF (on ASCII
3304 platforms).   But under C<use locale>, the lower case of U+1E9E is
3305 itself, because 0xDF may not be LATIN SMALL LETTER SHARP S in the
3306 current locale, and Perl has no way of knowing if that character even
3307 exists in the locale, much less what code point it is.  Perl returns
3308 the input character unchanged, for all instances (and there aren't
3309 many) where the 255/256 boundary would otherwise be crossed.
3310
3311 =item Otherwise, If EXPR has the UTF8 flag set:
3312
3313 Unicode semantics are used for the case change.
3314
3315 =item Otherwise, if C<use feature 'unicode_strings'> or C<use locale ':not_characters'>) is in effect:
3316
3317 Unicode semantics are used for the case change.
3318
3319 =item Otherwise:
3320
3321 =over
3322
3323 =item On EBCDIC platforms
3324
3325 The results are what the C language system call C<tolower()> returns.
3326
3327 =item On ASCII platforms
3328
3329 ASCII semantics are used for the case change.  The lowercase of any character
3330 outside the ASCII range is the character itself.
3331
3332 =back
3333
3334 =back
3335
3336 =item lcfirst EXPR
3337 X<lcfirst> X<lowercase>
3338
3339 =item lcfirst
3340
3341 =for Pod::Functions return a string with just the next letter in lower case
3342
3343 Returns the value of EXPR with the first character lowercased.  This
3344 is the internal function implementing the C<\l> escape in
3345 double-quoted strings.
3346
3347 If EXPR is omitted, uses C<$_>.
3348
3349 This function behaves the same way under various pragmata, such as in a locale,
3350 as L</lc> does.
3351
3352 =item length EXPR
3353 X<length> X<size>
3354
3355 =item length
3356
3357 =for Pod::Functions return the number of bytes in a string
3358
3359 Returns the length in I<characters> of the value of EXPR.  If EXPR is
3360 omitted, returns the length of C<$_>.  If EXPR is undefined, returns
3361 C<undef>.
3362
3363 This function cannot be used on an entire array or hash to find out how
3364 many elements these have.  For that, use C<scalar @array> and C<scalar keys
3365 %hash>, respectively.
3366
3367 Like all Perl character operations, length() normally deals in logical
3368 characters, not physical bytes.  For how many bytes a string encoded as
3369 UTF-8 would take up, use C<length(Encode::encode_utf8(EXPR))> (you'll have
3370 to C<use Encode> first).  See L<Encode> and L<perlunicode>.
3371
3372 =item __LINE__
3373 X<__LINE__>
3374
3375 =for Pod::Functions the current source line number
3376
3377 A special token that compiles to the current line number.
3378
3379 =item link OLDFILE,NEWFILE
3380 X<link>
3381
3382 =for Pod::Functions create a hard link in the filesystem
3383
3384 Creates a new filename linked to the old filename.  Returns true for
3385 success, false otherwise.
3386
3387 Portability issues: L<perlport/link>.
3388
3389 =item listen SOCKET,QUEUESIZE
3390 X<listen>
3391
3392 =for Pod::Functions register your socket as a server
3393
3394 Does the same thing that the listen(2) system call does.  Returns true if
3395 it succeeded, false otherwise.  See the example in
3396 L<perlipc/"Sockets: Client/Server Communication">.
3397
3398 =item local EXPR
3399 X<local>
3400
3401 =for Pod::Functions create a temporary value for a global variable (dynamic scoping)
3402
3403 You really probably want to be using C<my> instead, because C<local> isn't
3404 what most people think of as "local".  See
3405 L<perlsub/"Private Variables via my()"> for details.
3406
3407 A local modifies the listed variables to be local to the enclosing
3408 block, file, or eval.  If more than one value is listed, the list must
3409 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
3410 for details, including issues with tied arrays and hashes.
3411
3412 The C<delete local EXPR> construct can also be used to localize the deletion
3413 of array/hash elements to the current block.
3414 See L<perlsub/"Localized deletion of elements of composite types">.
3415
3416 =item localtime EXPR
3417 X<localtime> X<ctime>
3418
3419 =item localtime
3420
3421 =for Pod::Functions convert UNIX time into record or string using local time
3422
3423 Converts a time as returned by the time function to a 9-element list
3424 with the time analyzed for the local time zone.  Typically used as
3425 follows:
3426
3427     #  0    1    2     3     4    5     6     7     8
3428     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
3429                                                 localtime(time);
3430
3431 All list elements are numeric and come straight out of the C `struct
3432 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
3433 of the specified time.
3434
3435 C<$mday> is the day of the month and C<$mon> the month in
3436 the range C<0..11>, with 0 indicating January and 11 indicating December.
3437 This makes it easy to get a month name from a list:
3438
3439     my @abbr = qw( Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec );
3440     print "$abbr[$mon] $mday";
3441     # $mon=9, $mday=18 gives "Oct 18"
3442
3443 C<$year> contains the number of years since 1900.  To get a 4-digit
3444 year write:
3445
3446     $year += 1900;
3447
3448 To get the last two digits of the year (e.g., "01" in 2001) do:
3449
3450     $year = sprintf("%02d", $year % 100);
3451
3452 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
3453 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
3454 (or C<0..365> in leap years.)
3455
3456 C<$isdst> is true if the specified time occurs during Daylight Saving
3457 Time, false otherwise.
3458
3459 If EXPR is omitted, C<localtime()> uses the current time (as returned
3460 by time(3)).
3461
3462 In scalar context, C<localtime()> returns the ctime(3) value:
3463
3464     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
3465
3466 The format of this scalar value is B<not> locale-dependent
3467 but built into Perl.  For GMT instead of local
3468 time use the L</gmtime> builtin.  See also the
3469 C<Time::Local> module (for converting seconds, minutes, hours, and such back to
3470 the integer value returned by time()), and the L<POSIX> module's strftime(3)
3471 and mktime(3) functions.
3472
3473 To get somewhat similar but locale-dependent date strings, set up your
3474 locale environment variables appropriately (please see L<perllocale>) and
3475 try for example:
3476
3477     use POSIX qw(strftime);
3478     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
3479     # or for GMT formatted appropriately for your locale:
3480     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
3481
3482 Note that the C<%a> and C<%b>, the short forms of the day of the week
3483 and the month of the year, may not necessarily be three characters wide.
3484
3485 The L<Time::gmtime> and L<Time::localtime> modules provide a convenient,
3486 by-name access mechanism to the gmtime() and localtime() functions,
3487 respectively.
3488
3489 For a comprehensive date and time representation look at the
3490 L<DateTime> module on CPAN.
3491
3492 Portability issues: L<perlport/localtime>.
3493
3494 =item lock THING
3495 X<lock>
3496
3497 =for Pod::Functions +5.005 get a thread lock on a variable, subroutine, or method
3498
3499 This function places an advisory lock on a shared variable or referenced
3500 object contained in I<THING> until the lock goes out of scope.
3501
3502 The value returned is the scalar itself, if the argument is a scalar, or a
3503 reference, if the argument is a hash, array or subroutine.
3504
3505 lock() is a "weak keyword" : this means that if you've defined a function
3506 by this name (before any calls to it), that function will be called
3507 instead.  If you are not under C<use threads::shared> this does nothing.
3508 See L<threads::shared>.
3509
3510 =item log EXPR
3511 X<log> X<logarithm> X<e> X<ln> X<base>
3512
3513 =item log
3514
3515 =for Pod::Functions retrieve the natural logarithm for a number
3516
3517 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
3518 returns the log of C<$_>.  To get the
3519 log of another base, use basic algebra:
3520 The base-N log of a number is equal to the natural log of that number
3521 divided by the natural log of N.  For example:
3522
3523     sub log10 {
3524         my $n = shift;
3525         return log($n)/log(10);
3526     }
3527
3528 See also L</exp> for the inverse operation.
3529
3530 =item lstat FILEHANDLE
3531 X<lstat>
3532
3533 =item lstat EXPR
3534
3535 =item lstat DIRHANDLE
3536
3537 =item lstat
3538
3539 =for Pod::Functions stat a symbolic link
3540
3541 Does the same thing as the C<stat> function (including setting the
3542 special C<_> filehandle) but stats a symbolic link instead of the file
3543 the symbolic link points to.  If symbolic links are unimplemented on
3544 your system, a normal C<stat> is done.  For much more detailed
3545 information, please see the documentation for C<stat>.
3546
3547 If EXPR is omitted, stats C<$_>.
3548
3549 Portability issues: L<perlport/lstat>.
3550
3551 =item m//
3552
3553 =for Pod::Functions match a string with a regular expression pattern
3554
3555 The match operator.  See L<perlop/"Regexp Quote-Like Operators">.
3556
3557 =item map BLOCK LIST
3558 X<map>
3559
3560 =item map EXPR,LIST
3561
3562 =for Pod::Functions apply a change to a list to get back a new list with the changes
3563
3564 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
3565 C<$_> to each element) and returns the list value composed of the
3566 results of each such evaluation.  In scalar context, returns the
3567 total number of elements so generated.  Evaluates BLOCK or EXPR in
3568 list context, so each element of LIST may produce zero, one, or
3569 more elements in the returned value.
3570
3571     @chars = map(chr, @numbers);
3572
3573 translates a list of numbers to the corresponding characters.
3574
3575     my @squares = map { $_ * $_ } @numbers;
3576
3577 translates a list of numbers to their squared values.
3578
3579     my @squares = map { $_ > 5 ? ($_ * $_) : () } @numbers;
3580
3581 shows that number of returned elements can differ from the number of
3582 input elements.  To omit an element, return an empty list ().
3583 This could also be achieved by writing
3584
3585     my @squares = map { $_ * $_ } grep { $_ > 5 } @numbers;
3586
3587 which makes the intention more clear.
3588
3589 Map always returns a list, which can be
3590 assigned to a hash such that the elements
3591 become key/value pairs.  See L<perldata> for more details.
3592
3593     %hash = map { get_a_key_for($_) => $_ } @array;
3594
3595 is just a funny way to write
3596
3597     %hash = ();
3598     foreach (@array) {
3599         $hash{get_a_key_for($_)} = $_;
3600     }
3601
3602 Note that C<$_> is an alias to the list value, so it can be used to
3603 modify the elements of the LIST.  While this is useful and supported,
3604 it can cause bizarre results if the elements of LIST are not variables.
3605 Using a regular C<foreach> loop for this purpose would be clearer in
3606 most cases.  See also L</grep> for an array composed of those items of
3607 the original list for which the BLOCK or EXPR evaluates to true.
3608
3609 If C<$_> is lexical in the scope where the C<map> appears (because it has
3610 been declared with C<my $_>), then, in addition to being locally aliased to
3611 the list elements, C<$_> keeps being lexical inside the block; that is, it
3612 can't be seen from the outside, avoiding any potential side-effects.
3613
3614 C<{> starts both hash references and blocks, so C<map { ...> could be either
3615 the start of map BLOCK LIST or map EXPR, LIST.  Because Perl doesn't look
3616 ahead for the closing C<}> it has to take a guess at which it's dealing with
3617 based on what it finds just after the
3618 C<{>.  Usually it gets it right, but if it
3619 doesn't it won't realize something is wrong until it gets to the C<}> and
3620 encounters the missing (or unexpected) comma.  The syntax error will be
3621 reported close to the C<}>, but you'll need to change something near the C<{>
3622 such as using a unary C<+> to give Perl some help:
3623
3624     %hash = map {  "\L$_" => 1  } @array  # perl guesses EXPR.  wrong
3625     %hash = map { +"\L$_" => 1  } @array  # perl guesses BLOCK. right
3626     %hash = map { ("\L$_" => 1) } @array  # this also works
3627     %hash = map {  lc($_) => 1  } @array  # as does this.
3628     %hash = map +( lc($_) => 1 ), @array  # this is EXPR and works!
3629
3630     %hash = map  ( lc($_), 1 ),   @array  # evaluates to (1, @array)
3631
3632 or to force an anon hash constructor use C<+{>:
3633
3634    @hashes = map +{ lc($_) => 1 }, @array # EXPR, so needs comma at end
3635
3636 to get a list of anonymous hashes each with only one entry apiece.
3637
3638 =item mkdir FILENAME,MASK
3639 X<mkdir> X<md> X<directory, create>
3640
3641 =item mkdir FILENAME
3642
3643 =item mkdir
3644
3645 =for Pod::Functions create a directory
3646
3647 Creates the directory specified by FILENAME, with permissions
3648 specified by MASK (as modified by C<umask>).  If it succeeds it
3649 returns true; otherwise it returns false and sets C<$!> (errno).
3650 MASK defaults to 0777 if omitted, and FILENAME defaults
3651 to C<$_> if omitted.
3652
3653 In general, it is better to create directories with a permissive MASK
3654 and let the user modify that with their C<umask> than it is to supply
3655 a restrictive MASK and give the user no way to be more permissive.
3656 The exceptions to this rule are when the file or directory should be
3657 kept private (mail files, for instance).  The perlfunc(1) entry on
3658 C<umask> discusses the choice of MASK in more detail.
3659
3660 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
3661 number of trailing slashes.  Some operating and filesystems do not get
3662 this right, so Perl automatically removes all trailing slashes to keep
3663 everyone happy.
3664
3665 To recursively create a directory structure, look at
3666 the C<mkpath> function of the L<File::Path> module.
3667
3668 =item msgctl ID,CMD,ARG
3669 X<msgctl>
3670
3671 =for Pod::Functions SysV IPC message control operations
3672
3673 Calls the System V IPC function msgctl(2).  You'll probably have to say
3674
3675     use IPC::SysV;
3676
3677 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
3678 then ARG must be a variable that will hold the returned C<msqid_ds>
3679 structure.  Returns like C<ioctl>: the undefined value for error,
3680 C<"0 but true"> for zero, or the actual return value otherwise.  See also
3681 L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and
3682 C<IPC::Semaphore>.
3683
3684 Portability issues: L<perlport/msgctl>.
3685
3686 =item msgget KEY,FLAGS
3687 X<msgget>
3688
3689 =for Pod::Functions get SysV IPC message queue
3690
3691 Calls the System V IPC function msgget(2).  Returns the message queue
3692 id, or C<undef> on error.  See also
3693 L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and
3694 C<IPC::Msg>.
3695
3696 Portability issues: L<perlport/msgget>.
3697
3698 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
3699 X<msgrcv>
3700
3701 =for Pod::Functions receive a SysV IPC message from a message queue
3702
3703 Calls the System V IPC function msgrcv to receive a message from
3704 message queue ID into variable VAR with a maximum message size of
3705 SIZE.  Note that when a message is received, the message type as a
3706 native long integer will be the first thing in VAR, followed by the
3707 actual message.  This packing may be opened with C<unpack("l! a*")>.
3708 Taints the variable.  Returns true if successful, false 
3709 on error.  See also L<perlipc/"SysV IPC"> and the documentation for
3710 C<IPC::SysV> and C<IPC::SysV::Msg>.
3711
3712 Portability issues: L<perlport/msgrcv>.
3713
3714 =item msgsnd ID,MSG,FLAGS
3715 X<msgsnd>
3716
3717 =for Pod::Functions send a SysV IPC message to a message queue
3718
3719 Calls the System V IPC function msgsnd to send the message MSG to the
3720 message queue ID.  MSG must begin with the native long integer message
3721 type, be followed by the length of the actual message, and then finally
3722 the message itself.  This kind of packing can be achieved with
3723 C<pack("l! a*", $type, $message)>.  Returns true if successful,
3724 false on error.  See also the C<IPC::SysV>
3725 and C<IPC::SysV::Msg> documentation.
3726
3727 Portability issues: L<perlport/msgsnd>.
3728
3729 =item my EXPR
3730 X<my>
3731
3732 =item my TYPE EXPR
3733
3734 =item my EXPR : ATTRS
3735
3736 =item my TYPE EXPR : ATTRS
3737
3738 =for Pod::Functions declare and assign a local variable (lexical scoping)
3739
3740 A C<my> declares the listed variables to be local (lexically) to the
3741 enclosing block, file, or C<eval>.  If more than one value is listed,
3742 the list must be placed in parentheses.
3743
3744 The exact semantics and interface of TYPE and ATTRS are still
3745 evolving.  TYPE is currently bound to the use of the C<fields> pragma,
3746 and attributes are handled using the C<attributes> pragma, or starting
3747 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3748 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3749 L<attributes>, and L<Attribute::Handlers>.
3750
3751 =item next LABEL
3752 X<next> X<continue>
3753
3754 =item next
3755
3756 =for Pod::Functions iterate a block prematurely
3757
3758 The C<next> command is like the C<continue> statement in C; it starts
3759 the next iteration of the loop:
3760
3761     LINE: while (<STDIN>) {
3762         next LINE if /^#/;  # discard comments
3763         #...
3764     }
3765
3766 Note that if there were a C<continue> block on the above, it would get
3767 executed even on discarded lines.  If LABEL is omitted, the command
3768 refers to the innermost enclosing loop.
3769
3770 C<next> cannot be used to exit a block which returns a value such as
3771 C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit
3772 a grep() or map() operation.
3773
3774 Note that a block by itself is semantically identical to a loop
3775 that executes once.  Thus C<next> will exit such a block early.
3776
3777 See also L</continue> for an illustration of how C<last>, C<next>, and
3778 C<redo> work.
3779
3780 =item no MODULE VERSION LIST
3781 X<no declarations>
3782 X<unimporting>
3783
3784 =item no MODULE VERSION
3785
3786 =item no MODULE LIST
3787
3788 =item no MODULE
3789
3790 =item no VERSION
3791
3792 =for Pod::Functions unimport some module symbols or semantics at compile time
3793
3794 See the C<use> function, of which C<no> is the opposite.
3795
3796 =item oct EXPR
3797 X<oct> X<octal> X<hex> X<hexadecimal> X<binary> X<bin>
3798
3799 =item oct
3800
3801 =for Pod::Functions convert a string to an octal number
3802
3803 Interprets EXPR as an octal string and returns the corresponding
3804 value.  (If EXPR happens to start off with C<0x>, interprets it as a
3805 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
3806 binary string.  Leading whitespace is ignored in all three cases.)
3807 The following will handle decimal, binary, octal, and hex in standard
3808 Perl notation:
3809
3810     $val = oct($val) if $val =~ /^0/;
3811
3812 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
3813 in octal), use sprintf() or printf():
3814
3815     $dec_perms = (stat("filename"))[2] & 07777;
3816     $oct_perm_str = sprintf "%o", $perms;
3817
3818 The oct() function is commonly used when a string such as C<644> needs
3819 to be converted into a file mode, for example.  Although Perl 
3820 automatically converts strings into numbers as needed, this automatic
3821 conversion assumes base 10.
3822
3823 Leading white space is ignored without warning, as too are any trailing 
3824 non-digits, such as a decimal point (C<oct> only handles non-negative
3825 integers, not negative integers or floating point).
3826
3827 =item open FILEHANDLE,EXPR
3828 X<open> X<pipe> X<file, open> X<fopen>
3829
3830 =item open FILEHANDLE,MODE,EXPR
3831
3832 =item open FILEHANDLE,MODE,EXPR,LIST
3833
3834 =item open FILEHANDLE,MODE,REFERENCE
3835
3836 =item open FILEHANDLE
3837
3838 =for Pod::Functions open a file, pipe, or descriptor
3839
3840 Opens the file whose filename is given by EXPR, and associates it with
3841 FILEHANDLE.
3842
3843 Simple examples to open a file for reading:
3844
3845     open(my $fh, "<", "input.txt") 
3846         or die "cannot open < input.txt: $!";
3847
3848 and for writing:
3849
3850     open(my $fh, ">", "output.txt") 
3851         or die "cannot open > output.txt: $!";
3852
3853 (The following is a comprehensive reference to open(): for a gentler
3854 introduction you may consider L<perlopentut>.)
3855
3856 If FILEHANDLE is an undefined scalar variable (or array or hash element), a
3857 new filehandle is autovivified, meaning that the variable is assigned a
3858 reference to a newly allocated anonymous filehandle.  Otherwise if
3859 FILEHANDLE is an expression, its value is the real filehandle.  (This is
3860 considered a symbolic reference, so C<use strict "refs"> should I<not> be
3861 in effect.)
3862
3863 If EXPR is omitted, the global (package) scalar variable of the same
3864 name as the FILEHANDLE contains the filename.  (Note that lexical 
3865 variables--those declared with C<my> or C<state>--will not work for this
3866 purpose; so if you're using C<my> or C<state>, specify EXPR in your
3867 call to open.)
3868
3869 If three (or more) arguments are specified, the open mode (including
3870 optional encoding) in the second argument are distinct from the filename in
3871 the third.  If MODE is C<< < >> or nothing, the file is opened for input.
3872 If MODE is C<< > >>, the file is opened for output, with existing files
3873 first being truncated ("clobbered") and nonexisting files newly created.
3874 If MODE is C<<< >> >>>, the file is opened for appending, again being
3875 created if necessary.
3876
3877 You can put a C<+> in front of the C<< > >> or C<< < >> to
3878 indicate that you want both read and write access to the file; thus
3879 C<< +< >> is almost always preferred for read/write updates--the 
3880 C<< +> >> mode would clobber the file first.  You can't usually use
3881 either read-write mode for updating textfiles, since they have
3882 variable-length records.  See the B<-i> switch in L<perlrun> for a
3883 better approach.  The file is created with permissions of C<0666>
3884 modified by the process's C<umask> value.
3885
3886 These various prefixes correspond to the fopen(3) modes of C<r>,
3887 C<r+>, C<w>, C<w+>, C<a>, and C<a+>.
3888
3889 In the one- and two-argument forms of the call, the mode and filename
3890 should be concatenated (in that order), preferably separated by white
3891 space.  You can--but shouldn't--omit the mode in these forms when that mode
3892 is C<< < >>.  It is always safe to use the two-argument form of C<open> if
3893 the filename argument is a known literal.
3894
3895 For three or more arguments if MODE is C<|->, the filename is
3896 interpreted as a command to which output is to be piped, and if MODE
3897 is C<-|>, the filename is interpreted as a command that pipes
3898 output to us.  In the two-argument (and one-argument) form, one should
3899 replace dash (C<->) with the command.
3900 See L<perlipc/"Using open() for IPC"> for more examples of this.
3901 (You are not allowed to C<open> to a command that pipes both in I<and>
3902 out, but see L<IPC::Open2>, L<IPC::Open3>, and
3903 L<perlipc/"Bidirectional Communication with Another Process"> for
3904 alternatives.)
3905
3906 In the form of pipe opens taking three or more arguments, if LIST is specified
3907 (extra arguments after the command name) then LIST becomes arguments
3908 to the command invoked if the platform supports it.  The meaning of
3909 C<open> with more than three arguments for non-pipe modes is not yet
3910 defined, but experimental "layers" may give extra LIST arguments
3911 meaning.
3912
3913 In the two-argument (and one-argument) form, opening C<< <- >> 
3914 or C<-> opens STDIN and opening C<< >- >> opens STDOUT.
3915
3916 You may (and usually should) use the three-argument form of open to specify
3917 I/O layers (sometimes referred to as "disciplines") to apply to the handle
3918 that affect how the input and output are processed (see L<open> and
3919 L<PerlIO> for more details).  For example:
3920
3921   open(my $fh, "<:encoding(UTF-8)", "filename")
3922     || die "can't open UTF-8 encoded filename: $!";
3923
3924 opens the UTF8-encoded file containing Unicode characters;
3925 see L<perluniintro>.  Note that if layers are specified in the
3926 three-argument form, then default layers stored in ${^OPEN} (see L<perlvar>;
3927 usually set by the B<open> pragma or the switch B<-CioD>) are ignored.
3928 Those layers will also be ignored if you specifying a colon with no name
3929 following it.  In that case the default layer for the operating system
3930 (:raw on Unix, :crlf on Windows) is used.
3931
3932 Open returns nonzero on success, the undefined value otherwise.  If
3933 the C<open> involved a pipe, the return value happens to be the pid of
3934 the subprocess.
3935
3936 If you're running Perl on a system that distinguishes between text
3937 files and binary files, then you should check out L</binmode> for tips
3938 for dealing with this.  The key distinction between systems that need
3939 C<binmode> and those that don't is their text file formats.  Systems
3940 like Unix, Mac OS, and Plan 9, that end lines with a single
3941 character and encode that character in C as C<"\n"> do not
3942 need C<binmode>.  The rest need it.
3943
3944 When opening a file, it's seldom a good idea to continue 
3945 if the request failed, so C<open> is frequently used with
3946 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
3947 where you want to format a suitable error message (but there are
3948 modules that can help with that problem)) always check
3949 the return value from opening a file.  
3950
3951 As a special case the three-argument form with a read/write mode and the third
3952 argument being C<undef>:
3953
3954     open(my $tmp, "+>", undef) or die ...
3955
3956 opens a filehandle to an anonymous temporary file.  Also using C<< +< >>
3957 works for symmetry, but you really should consider writing something
3958 to the temporary file first.  You will need to seek() to do the
3959 reading.
3960
3961 Since v5.8.0, Perl has built using PerlIO by default.  Unless you've
3962 changed this (such as building Perl with C<Configure -Uuseperlio>), you can
3963 open filehandles directly to Perl scalars via:
3964
3965     open($fh, ">", \$variable) || ..
3966
3967 To (re)open C<STDOUT> or C<STDERR> as an in-memory file, close it first:
3968
3969     close STDOUT;
3970     open(STDOUT, ">", \$variable)
3971         or die "Can't open STDOUT: $!";
3972
3973 General examples:
3974
3975     $ARTICLE = 100;
3976     open(ARTICLE) or die "Can't find article $ARTICLE: $!\n";
3977     while (<ARTICLE>) {...
3978
3979     open(LOG, ">>/usr/spool/news/twitlog");  # (log is reserved)
3980     # if the open fails, output is discarded
3981
3982     open(my $dbase, "+<", "dbase.mine")      # open for update
3983         or die "Can't open 'dbase.mine' for update: $!";
3984
3985     open(my $dbase, "+<dbase.mine")          # ditto
3986         or die "Can't open 'dbase.mine' for update: $!";
3987
3988     open(ARTICLE, "-|", "caesar <$article")  # decrypt article
3989         or die "Can't start caesar: $!";
3990
3991     open(ARTICLE, "caesar <$article |")      # ditto
3992         or die "Can't start caesar: $!";
3993
3994     open(EXTRACT, "|sort >Tmp$$")            # $$ is our process id
3995         or die "Can't start sort: $!";
3996
3997     # in-memory files
3998     open(MEMORY, ">", \$var)
3999         or die "Can't open memory file: $!";
4000     print MEMORY "foo!\n";                   # output will appear in $var
4001
4002     # process argument list of files along with any includes
4003
4004     foreach $file (@ARGV) {
4005         process($file, "fh00");
4006     }
4007
4008     sub process {
4009         my($filename, $input) = @_;
4010         $input++;    # this is a string increment
4011         unless (open($input, "<", $filename)) {
4012             print STDERR "Can't open $filename: $!\n";
4013             return;
4014         }
4015
4016         local $_;
4017         while (<$input>) {    # note use of indirection
4018             if (/^#include "(.*)"/) {
4019                 process($1, $input);
4020                 next;
4021             }
4022             #...          # whatever
4023         }
4024     }
4025
4026 See L<perliol> for detailed info on PerlIO.
4027
4028 You may also, in the Bourne shell tradition, specify an EXPR beginning
4029 with C<< >& >>, in which case the rest of the string is interpreted
4030 as the name of a filehandle (or file descriptor, if numeric) to be
4031 duped (as C<dup(2)>) and opened.  You may use C<&> after C<< > >>,
4032 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
4033 The mode you specify should match the mode of the original filehandle.
4034 (Duping a filehandle does not take into account any existing contents
4035 of IO buffers.)  If you use the three-argument
4036 form, then you can pass either a
4037 number, the name of a filehandle, or the normal "reference to a glob".
4038
4039 Here is a script that saves, redirects, and restores C<STDOUT> and
4040 C<STDERR> using various methods:
4041
4042     #!/usr/bin/perl
4043     open(my $oldout, ">&STDOUT")     or die "Can't dup STDOUT: $!";
4044     open(OLDERR,     ">&", \*STDERR) or die "Can't dup STDERR: $!";
4045
4046     open(STDOUT, '>', "foo.out") or die "Can't redirect STDOUT: $!";
4047     open(STDERR, ">&STDOUT")     or die "Can't dup STDOUT: $!";
4048
4049     select STDERR; $| = 1;  # make unbuffered
4050     select STDOUT; $| = 1;  # make unbuffered
4051
4052     print STDOUT "stdout 1\n";  # this works for
4053     print STDERR "stderr 1\n";  # subprocesses too
4054
4055     open(STDOUT, ">&", $oldout) or die "Can't dup \$oldout: $!";
4056     open(STDERR, ">&OLDERR")    or die "Can't dup OLDERR: $!";
4057
4058     print STDOUT "stdout 2\n";
4059     print STDERR "stderr 2\n";
4060
4061 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
4062 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
4063 that file descriptor (and not call C<dup(2)>); this is more
4064 parsimonious of file descriptors.  For example:
4065
4066     # open for input, reusing the fileno of $fd
4067     open(FILEHANDLE, "<&=$fd")
4068
4069 or
4070
4071     open(FILEHANDLE, "<&=", $fd)
4072
4073 or
4074
4075     # open for append, using the fileno of OLDFH
4076     open(FH, ">>&=", OLDFH)
4077
4078 or
4079
4080     open(FH, ">>&=OLDFH")
4081
4082 Being parsimonious on filehandles is also useful (besides being
4083 parsimonious) for example when something is dependent on file
4084 descriptors, like for example locking using flock().  If you do just
4085 C<< open(A, ">>&B") >>, the filehandle A will not have the same file
4086 descriptor as B, and therefore flock(A) will not flock(B) nor vice
4087 versa.  But with C<< open(A, ">>&=B") >>, the filehandles will share
4088 the same underlying system file descriptor.
4089
4090 Note that under Perls older than 5.8.0, Perl uses the standard C library's'
4091 fdopen() to implement the C<=> functionality.  On many Unix systems,
4092 fdopen() fails when file descriptors exceed a certain value, typically 255.
4093 For Perls 5.8.0 and later, PerlIO is (most often) the default.
4094
4095 You can see whether your Perl was built with PerlIO by running C<perl -V>
4096 and looking for the C<useperlio=> line.  If C<useperlio> is C<define>, you
4097 have PerlIO; otherwise you don't.
4098
4099 If you open a pipe on the command C<-> (that is, specify either C<|-> or C<-|>
4100 with the one- or two-argument forms of C<open>), 
4101 an implicit C<fork> is done, so C<open> returns twice: in the parent
4102 process it returns the pid
4103 of the child process, and in the child process it returns (a defined) C<0>.
4104 Use C<defined($pid)> or C<//> to determine whether the open was successful.
4105
4106 For example, use either
4107
4108     $child_pid = open(FROM_KID, "-|")   // die "can't fork: $!";
4109
4110 or
4111     $child_pid = open(TO_KID,   "|-")   // die "can't fork: $!";
4112
4113 followed by 
4114
4115     if ($child_pid) {
4116         # am the parent:
4117         # either write TO_KID or else read FROM_KID
4118         ...
4119         wait $child_pid;
4120     } else {
4121         # am the child; use STDIN/STDOUT normally
4122         ...
4123         exit;
4124     } 
4125
4126 The filehandle behaves normally for the parent, but I/O to that
4127 filehandle is piped from/to the STDOUT/STDIN of the child process.
4128 In the child process, the filehandle isn't opened--I/O happens from/to
4129 the new STDOUT/STDIN.  Typically this is used like the normal
4130 piped open when you want to exercise more control over just how the
4131 pipe command gets executed, such as when running setuid and
4132 you don't want to have to scan shell commands for metacharacters.
4133
4134 The following blocks are more or less equivalent:
4135
4136     open(FOO, "|tr '[a-z]' '[A-Z]'");
4137     open(FOO, "|-", "tr '[a-z]' '[A-Z]'");
4138     open(FOO, "|-") || exec 'tr', '[a-z]', '[A-Z]';
4139     open(FOO, "|-", "tr", '[a-z]', '[A-Z]');
4140
4141     open(FOO, "cat -n '$file'|");
4142     open(FOO, "-|", "cat -n '$file'");
4143     open(FOO, "-|") || exec "cat", "-n", $file;
4144     open(FOO, "-|", "cat", "-n", $file);
4145
4146 The last two examples in each block show the pipe as "list form", which is
4147 not yet supported on all platforms.  A good rule of thumb is that if
4148 your platform has a real C<fork()> (in other words, if your platform is
4149 Unix, including Linux and MacOS X), you can use the list form.  You would 
4150 want to use the list form of the pipe so you can pass literal arguments
4151 to the command without risk of the shell interpreting any shell metacharacters
4152 in them.  However, this also bars you from opening pipes to commands
4153 that intentionally contain shell metacharacters, such as:
4154
4155     open(FOO, "|cat -n | expand -4 | lpr")
4156         // die "Can't open pipeline to lpr: $!";
4157
4158 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
4159
4160 Beginning with v5.6.0, Perl will attempt to flush all files opened for
4161 output before any operation that may do a fork, but this may not be
4162 supported on some platforms (see L<perlport>).  To be safe, you may need
4163 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
4164 of C<IO::Handle> on any open handles.
4165
4166 On systems that support a close-on-exec flag on files, the flag will
4167 be set for the newly opened file descriptor as determined by the value
4168 of C<$^F>.  See L<perlvar/$^F>.
4169
4170 Closing any piped filehandle causes the parent process to wait for the
4171 child to finish, then returns the status value in C<$?> and
4172 C<${^CHILD_ERROR_NATIVE}>.
4173
4174 The filename passed to the one- and two-argument forms of open() will
4175 have leading and trailing whitespace deleted and normal
4176 redirection characters honored.  This property, known as "magic open",
4177 can often be used to good effect.  A user could specify a filename of
4178 F<"rsh cat file |">, or you could change certain filenames as needed:
4179
4180     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
4181     open(FH, $filename) or die "Can't open $filename: $!";
4182
4183 Use the three-argument form to open a file with arbitrary weird characters in it,
4184
4185     open(FOO, "<", $file)
4186         || die "can't open < $file: $!";
4187
4188 otherwise it's necessary to protect any leading and trailing whitespace:
4189
4190     $file =~ s#^(\s)#./$1#;
4191     open(FOO, "< $file\0")
4192         || die "open failed: $!";
4193
4194 (this may not work on some bizarre filesystems).  One should
4195 conscientiously choose between the I<magic> and I<three-argument> form
4196 of open():
4197
4198     open(IN, $ARGV[0]) || die "can't open $ARGV[0]: $!";
4199
4200 will allow the user to specify an argument of the form C<"rsh cat file |">,
4201 but will not work on a filename that happens to have a trailing space, while
4202
4203     open(IN, "<", $ARGV[0])
4204         || die "can't open < $ARGV[0]: $!";
4205
4206 will have exactly the opposite restrictions.
4207
4208 If you want a "real" C C<open> (see L<open(2)> on your system), then you
4209 should use the C<sysopen> function, which involves no such magic (but may
4210 use subtly different filemodes than Perl open(), which is mapped to C
4211 fopen()).  This is another way to protect your filenames from
4212 interpretation.  For example:
4213
4214     use IO::Handle;
4215     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
4216         or die "sysopen $path: $!";
4217     $oldfh = select(HANDLE); $| = 1; select($oldfh);
4218     print HANDLE "stuff $$\n";
4219     seek(HANDLE, 0, 0);
4220     print "File contains: ", <HANDLE>;
4221
4222 Using the constructor from the C<IO::Handle> package (or one of its
4223 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
4224 filehandles that have the scope of the variables used to hold them, then
4225 automatically (but silently) close once their reference counts become
4226 zero, typically at scope exit:
4227
4228     use IO::File;
4229     #...
4230     sub read_myfile_munged {
4231         my $ALL = shift;
4232         # or just leave it undef to autoviv
4233         my $handle = IO::File->new;
4234         open($handle, "<", "myfile") or die "myfile: $!";
4235         $first = <$handle>
4236             or return ();     # Automatically closed here.
4237         mung($first) or die "mung failed";  # Or here.
4238         return (first, <$handle>) if $ALL;  # Or here.
4239         return $first;                      # Or here.
4240     }
4241
4242 B<WARNING:> The previous example has a bug because the automatic
4243 close that happens when the refcount on C<handle> does not
4244 properly detect and report failures.  I<Always> close the handle
4245 yourself and inspect the return value.
4246
4247     close($handle) 
4248         || warn "close failed: $!";
4249
4250 See L</seek> for some details about mixing reading and writing.
4251
4252 Portability issues: L<perlport/open>.
4253
4254 =item opendir DIRHANDLE,EXPR
4255 X<opendir>
4256
4257 =for Pod::Functions open a directory
4258
4259 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
4260 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
4261 DIRHANDLE may be an expression whose value can be used as an indirect
4262 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
4263 scalar variable (or array or hash element), the variable is assigned a
4264 reference to a new anonymous dirhandle; that is, it's autovivified.
4265 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
4266
4267 See the example at C<readdir>.
4268
4269 =item ord EXPR
4270 X<ord> X<encoding>
4271
4272 =item ord
4273
4274 =for Pod::Functions find a character's numeric representation
4275
4276 Returns the numeric value of the first character of EXPR.
4277 If EXPR is an empty string, returns 0.  If EXPR is omitted, uses C<$_>.
4278 (Note I<character>, not byte.)
4279
4280 For the reverse, see L</chr>.
4281 See L<perlunicode> for more about Unicode.
4282
4283 =item our EXPR
4284 X<our> X<global>
4285
4286 =item our TYPE EXPR
4287
4288 =item our EXPR : ATTRS
4289
4290 =item our TYPE EXPR : ATTRS
4291
4292 =for Pod::Functions +5.6.0 declare and assign a package variable (lexical scoping)
4293
4294 C<our> associates a simple name with a package variable in the current
4295 package for use within the current scope.  When C<use strict 'vars'> is in
4296 effect, C<our> lets you use declared global variables without qualifying
4297 them with package names, within the lexical scope of the C<our> declaration.
4298 In this way C<our> differs from C<use vars>, which is package-scoped.
4299
4300 Unlike C<my> or C<state>, which allocates storage for a variable and
4301 associates a simple name with that storage for use within the current
4302 scope, C<our> associates a simple name with a package (read: global)
4303 variable in the current package, for use within the current lexical scope.
4304 In other words, C<our> has the same scoping rules as C<my> or C<state>, but
4305 does not necessarily create a variable.
4306
4307 If more than one value is listed, the list must be placed
4308 in parentheses.
4309
4310     our $foo;
4311     our($bar, $baz);
4312
4313 An C<our> declaration declares a global variable that will be visible
4314 across its entire lexical scope, even across package boundaries.  The
4315 package in which the variable is entered is determined at the point
4316 of the declaration, not at the point of use.  This means the following
4317 behavior holds:
4318
4319     package Foo;
4320     our $bar;      # declares $Foo::bar for rest of lexical scope
4321     $bar = 20;
4322
4323     package Bar;
4324     print $bar;    # prints 20, as it refers to $Foo::bar
4325
4326 Multiple C<our> declarations with the same name in the same lexical
4327 scope are allowed if they are in different packages.  If they happen
4328 to be in the same package, Perl will emit warnings if you have asked
4329 for them, just like multiple C<my> declarations.  Unlike a second
4330 C<my> declaration, which will bind the name to a fresh variable, a
4331 second C<our> declaration in the same package, in the same scope, is
4332 merely redundant.
4333
4334     use warnings;
4335     package Foo;
4336     our $bar;      # declares $Foo::bar for rest of lexical scope
4337     $bar = 20;
4338
4339     package Bar;
4340     our $bar = 30; # declares $Bar::bar for rest of lexical scope
4341     print $bar;    # prints 30
4342
4343     our $bar;      # emits warning but has no other effect
4344     print $bar;    # still prints 30
4345
4346 An C<our> declaration may also have a list of attributes associated
4347 with it.
4348
4349 The exact semantics and interface of TYPE and ATTRS are still
4350 evolving.  TYPE is currently bound to the use of the C<fields> pragma,
4351 and attributes are handled using the C<attributes> pragma, or, starting
4352 from Perl 5.8.0, also via the C<Attribute::Handlers> module.  See
4353 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
4354 L<attributes>, and L<Attribute::Handlers>.
4355
4356 =item pack TEMPLATE,LIST
4357 X<pack>
4358
4359 =for Pod::Functions convert a list into a binary representation
4360
4361 Takes a LIST of values and converts it into a string using the rules
4362 given by the TEMPLATE.  The resulting string is the concatenation of
4363 the converted values.  Typically, each converted value looks
4364 like its machine-level representation.  For example, on 32-bit machines
4365 an integer may be represented by a sequence of 4 bytes, which  will in
4366 Perl be presented as a string that's 4 characters long. 
4367
4368 See L<perlpacktut> for an introduction to this function.
4369
4370 The TEMPLATE is a sequence of characters that give the order and type
4371 of values, as follows:
4372
4373     a  A string with arbitrary binary data, will be null padded.
4374     A  A text (ASCII) string, will be space padded.
4375     Z  A null-terminated (ASCIZ) string, will be null padded.
4376
4377     b  A bit string (ascending bit order inside each byte,
4378        like vec()).
4379     B  A bit string (descending bit order inside each byte).
4380     h  A hex string (low nybble first).
4381     H  A hex string (high nybble first).
4382
4383     c  A signed char (8-bit) value.
4384     C  An unsigned char (octet) value.
4385     W  An unsigned char value (can be greater than 255).
4386
4387     s  A signed short (16-bit) value.
4388     S  An unsigned short value.
4389
4390     l  A signed long (32-bit) value.
4391     L  An unsigned long value.
4392
4393     q  A signed quad (64-bit) value.
4394     Q  An unsigned quad value.
4395          (Quads are available only if your system supports 64-bit
4396           integer values _and_ if Perl has been compiled to support
4397           those.  Raises an exception otherwise.)
4398
4399     i  A signed integer value.
4400     I  A unsigned integer value.
4401          (This 'integer' is _at_least_ 32 bits wide.  Its exact
4402           size depends on what a local C compiler calls 'int'.)
4403
4404     n  An unsigned short (16-bit) in "network" (big-endian) order.
4405     N  An unsigned long (32-bit) in "network" (big-endian) order.
4406     v  An unsigned short (16-bit) in "VAX" (little-endian) order.
4407     V  An unsigned long (32-bit) in "VAX" (little-endian) order.
4408
4409     j  A Perl internal signed integer value (IV).
4410     J  A Perl internal unsigned integer value (UV).
4411
4412     f  A single-precision float in native format.
4413     d  A double-precision float in native format.
4414
4415     F  A Perl internal floating-point value (NV) in native format
4416     D  A float of long-double precision in native format.
4417          (Long doubles are available only if your system supports
4418           long double values _and_ if Perl has been compiled to
4419           support those.  Raises an exception otherwise.)
4420
4421     p  A pointer to a null-terminated string.
4422     P  A pointer to a structure (fixed-length string).
4423
4424     u  A uuencoded string.
4425     U  A Unicode character number.  Encodes to a character in char-
4426        acter mode and UTF-8 (or UTF-EBCDIC in EBCDIC platforms) in
4427        byte mode.
4428
4429     w  A BER compressed integer (not an ASN.1 BER, see perlpacktut
4430        for details).  Its bytes represent an unsigned integer in
4431        base 128, most significant digit first, with as few digits
4432        as possible.  Bit eight (the high bit) is set on each byte
4433        except the last.
4434
4435     x  A null byte (a.k.a ASCII NUL, "\000", chr(0))
4436     X  Back up a byte.
4437     @  Null-fill or truncate to absolute position, counted from the
4438        start of the innermost ()-group.
4439     .  Null-fill or truncate to absolute position specified by
4440        the value.
4441     (  Start of a ()-group.
4442
4443 One or more modifiers below may optionally follow certain letters in the
4444 TEMPLATE (the second column lists letters for which the modifier is valid):
4445
4446     !   sSlLiI     Forces native (short, long, int) sizes instead
4447                    of fixed (16-/32-bit) sizes.
4448
4449         xX         Make x and X act as alignment commands.
4450
4451         nNvV       Treat integers as signed instead of unsigned.
4452
4453         @.         Specify position as byte offset in the internal
4454                    representation of the packed string.  Efficient
4455                    but dangerous.
4456
4457     >   sSiIlLqQ   Force big-endian byte-order on the type.
4458         jJfFdDpP   (The "big end" touches the construct.)
4459
4460     <   sSiIlLqQ   Force little-endian byte-order on the type.
4461         jJfFdDpP   (The "little end" touches the construct.)
4462
4463 The C<< > >> and C<< < >> modifiers can also be used on C<()> groups 
4464 to force a particular byte-order on all components in that group, 
4465 including all its subgroups.
4466
4467 The following rules apply:
4468
4469 =over 
4470
4471 =item *
4472
4473 Each letter may optionally be followed by a number indicating the repeat
4474 count.  A numeric repeat count may optionally be enclosed in brackets, as
4475 in C<pack("C[80]", @arr)>.  The repeat count gobbles that many values from
4476 the LIST when used with all format types other than C<a>, C<A>, C<Z>, C<b>,
4477 C<B>, C<h>, C<H>, C<@>, C<.>, C<x>, C<X>, and C<P>, where it means
4478 something else, described below.  Supplying a C<*> for the repeat count
4479 instead of a number means to use however many items are left, except for:
4480
4481 =over 
4482
4483 =item * 
4484
4485 C<@>, C<x>, and C<X>, where it is equivalent to C<0>.
4486
4487 =item * 
4488
4489 <.>, where it means relative to the start of the string.
4490
4491 =item * 
4492
4493 C<u>, where it is equivalent to 1 (or 45, which here is equivalent).
4494
4495 =back 
4496
4497 One can replace a numeric repeat count with a template letter enclosed in
4498 brackets to use the packed byte length of the bracketed template for the
4499 repeat count.
4500
4501 For example, the template C<x[L]> skips as many bytes as in a packed long,
4502 and the template C<"$t X[$t] $t"> unpacks twice whatever $t (when
4503 variable-expanded) unpacks.  If the template in brackets contains alignment
4504 commands (such as C<x![d]>), its packed length is calculated as if the
4505 start of the template had the maximal possible alignment.
4506
4507 When used with C<Z>, a C<*> as the repeat count is guaranteed to add a
4508 trailing null byte, so the resulting string is always one byte longer than
4509 the byte length of the item itself.
4510
4511 When used with C<@>, the repeat count represents an offset from the start
4512 of the innermost C<()> group.
4513
4514 When used with C<.>, the repeat count determines the starting position to
4515 calculate the value offset as follows:
4516
4517 =over 
4518
4519 =item *
4520
4521 If the repeat count is C<0>, it's relative to the current position.
4522
4523 =item *
4524
4525 If the repeat count is C<*>, the offset is relative to the start of the
4526 packed string.
4527
4528 =item *
4529
4530 And if it's an integer I<n>, the offset is relative to the start of the
4531 I<n>th innermost C<( )> group, or to the start of the string if I<n> is
4532 bigger then the group level.
4533
4534 =back
4535
4536 The repeat count for C<u> is interpreted as the maximal number of bytes
4537 to encode per line of output, with 0, 1 and 2 replaced by 45.  The repeat 
4538 count should not be more than 65.
4539
4540 =item *
4541
4542 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
4543 string of length count, padding with nulls or spaces as needed.  When
4544 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
4545 after the first null, and C<a> returns data with no stripping at all.
4546
4547 If the value to pack is too long, the result is truncated.  If it's too
4548 long and an explicit count is provided, C<Z> packs only C<$count-1> bytes,
4549 followed by a null byte.  Thus C<Z> always packs a trailing null, except
4550 when the count is 0.
4551
4552 =item *
4553
4554 Likewise, the C<b> and C<B> formats pack a string that's that many bits long.
4555 Each such format generates 1 bit of the result.  These are typically followed
4556 by a repeat count like C<B8> or C<B64>.
4557
4558 Each result bit is based on the least-significant bit of the corresponding
4559 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
4560 and C<"1"> generate bits 0 and 1, as do characters C<"\000"> and C<"\001">.
4561
4562 Starting from the beginning of the input string, each 8-tuple
4563 of characters is converted to 1 character of output.  With format C<b>,
4564 the first character of the 8-tuple determines the least-significant bit of a
4565 character; with format C<B>, it determines the most-significant bit of
4566 a character.
4567
4568 If the length of the input string is not evenly divisible by 8, the
4569 remainder is packed as if the input string were padded by null characters
4570 at the end.  Similarly during unpacking, "extra" bits are ignored.
4571
4572 If the input string is longer than needed, remaining characters are ignored.
4573
4574 A C<*> for the repeat count uses all characters of the input field.  
4575 On unpacking, bits are converted to a string of C<0>s and C<1>s.
4576
4577 =item *
4578
4579 The C<h> and C<H> formats pack a string that many nybbles (4-bit groups,
4580 representable as hexadecimal digits, C<"0".."9"> C<"a".."f">) long.
4581
4582 For each such format, pack() generates 4 bits of result.
4583 With non-alphabetical characters, the result is based on the 4 least-significant
4584 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
4585 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
4586 C<"\000"> and C<"\001">.  For characters C<"a".."f"> and C<"A".."F">, the result
4587 is compatible with the usual hexadecimal digits, so that C<"a"> and
4588 C<"A"> both generate the nybble C<0xA==10>.  Use only these specific hex 
4589 characters with this format.
4590
4591 Starting from the beginning of the template to pack(), each pair
4592 of characters is converted to 1 character of output.  With format C<h>, the
4593 first character of the pair determines the least-significant nybble of the
4594 output character; with format C<H>, it determines the most-significant
4595 nybble.
4596
4597 If the length of the input string is not even, it behaves as if padded by
4598 a null character at the end.  Similarly, "extra" nybbles are ignored during
4599 unpacking.
4600
4601 If the input string is longer than needed, extra characters are ignored.
4602
4603 A C<*> for the repeat count uses all characters of the input field.  For
4604 unpack(), nybbles are converted to a string of hexadecimal digits.
4605
4606 =item *
4607
4608 The C<p> format packs a pointer to a null-terminated string.  You are
4609 responsible for ensuring that the string is not a temporary value, as that
4610 could potentially get deallocated before you got around to using the packed
4611 result.  The C<P> format packs a pointer to a structure of the size indicated
4612 by the length.  A null pointer is created if the corresponding value for
4613 C<p> or C<P> is C<undef>; similarly with unpack(), where a null pointer
4614 unpacks into C<undef>.
4615
4616 If your system has a strange pointer size--meaning a pointer is neither as
4617 big as an int nor as big as a long--it may not be possible to pack or
4618 unpack pointers in big- or little-endian byte order.  Attempting to do
4619 so raises an exception.
4620
4621 =item *
4622
4623 The C</> template character allows packing and unpacking of a sequence of
4624 items where the packed structure contains a packed item count followed by
4625 the packed items themselves.  This is useful when the structure you're
4626 unpacking has encoded the sizes or repeat counts for some of its fields
4627 within the structure itself as separate fields.
4628
4629 For C<pack>, you write I<length-item>C</>I<sequence-item>, and the
4630 I<length-item> describes how the length value is packed.  Formats likely
4631 to be of most use are integer-packing ones like C<n> for Java strings,
4632 C<w> for ASN.1 or SNMP, and C<N> for Sun XDR.
4633
4634 For C<pack>, I<sequence-item> may have a repeat count, in which case
4635 the minimum of that and the number of available items is used as the argument
4636 for I<length-item>.  If it has no repeat count or uses a '*', the number
4637 of available items is used.
4638
4639 For C<unpack>, an internal stack of integer arguments unpacked so far is
4640 used.  You write C</>I<sequence-item> and the repeat count is obtained by
4641 popping off the last element from the stack.  The I<sequence-item> must not
4642 have a repeat count.
4643
4644 If I<sequence-item> refers to a string type (C<"A">, C<"a">, or C<"Z">),
4645 the I<length-item> is the string length, not the number of strings.  With
4646 an explicit repeat count for pack, the packed string is adjusted to that
4647 length.  For example:
4648
4649  This code:                              gives this result:
4650  
4651   unpack("W/a", "\004Gurusamy")          ("Guru")
4652   unpack("a3/A A*", "007 Bond  J ")      (" Bond", "J")
4653   unpack("a3 x2 /A A*", "007: Bond, J.") ("Bond, J", ".")
4654
4655   pack("n/a* w/a","hello,","world")     "\000\006hello,\005world"
4656   pack("a/W2", ord("a") .. ord("z"))    "2ab"
4657
4658 The I<length-item> is not returned explicitly from C<unpack>.
4659
4660 Supplying a count to the I<length-item> format letter is only useful with
4661 C<A>, C<a>, or C<Z>.  Packing with a I<length-item> of C<a> or C<Z> may
4662 introduce C<"\000"> characters, which Perl does not regard as legal in
4663 numeric strings.
4664
4665 =item *
4666
4667 The integer types C<s>, C<S>, C<l>, and C<L> may be
4668 followed by a C<!> modifier to specify native shorts or
4669 longs.  As shown in the example above, a bare C<l> means
4670 exactly 32 bits, although the native C<long> as seen by the local C compiler
4671 may be larger.  This is mainly an issue on 64-bit platforms.  You can
4672 see whether using C<!> makes any difference this way:
4673
4674     printf "format s is %d, s! is %d\n", 
4675         length pack("s"), length pack("s!");
4676
4677     printf "format l is %d, l! is %d\n", 
4678         length pack("l"), length pack("l!");
4679
4680
4681 C<i!> and C<I!> are also allowed, but only for completeness' sake:
4682 they are identical to C<i> and C<I>.
4683
4684 The actual sizes (in bytes) of native shorts, ints, longs, and long
4685 longs on the platform where Perl was built are also available from
4686 the command line:
4687
4688     $ perl -V:{short,int,long{,long}}size
4689     shortsize='2';
4690     intsize='4';
4691     longsize='4';
4692     longlongsize='8';
4693
4694 or programmatically via the C<Config> module:
4695
4696        use Config;
4697        print $Config{shortsize},    "\n";
4698        print $Config{intsize},      "\n";
4699        print $Config{longsize},     "\n";
4700        print $Config{longlongsize}, "\n";
4701
4702 C<$Config{longlongsize}> is undefined on systems without 
4703 long long support.
4704
4705 =item *
4706
4707 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J> are
4708 inherently non-portable between processors and operating systems because
4709 they obey native byteorder and endianness.  For example, a 4-byte integer
4710 0x12345678 (305419896 decimal) would be ordered natively (arranged in and
4711 handled by the CPU registers) into bytes as