dist/lib/lib_pm.PL

   1 use Config;
   2 use File::Basename qw(&basename &dirname);
   3 use File::Spec;
   4 use Cwd;
   5
   6 my $origdir = cwd;
   7 chdir dirname($0);
   8 my $file = basename($0, '.PL');
   9 $file =~ s/_(pm)$/.$1/i;
  10
  11 my $useConfig;
  12 my $Config_archname;
  13 my $Config_version;
  14 my $Config_inc_version_list;
  15
  16 # Expand the variables only if explicitly requested
  17 # or if a previously installed lib.pm does this, too
  18 # because otherwise relocating Perl becomes much harder.
  19
  20 my $expand_config_vars = 0;
  21 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS}) {
  22   $expand_config_vars = 1;
  23 }
  24 elsif (exists $ENV{PERL_BUILD_EXPAND_CONFIG_VARS}) {
  25   $expand_config_vars = 0;
  26 }
  27 else {
  28   eval <<'HERE';
  29   require lib;
  30   my $lib_file = $INC{"lib.pm"};
  31   open my $fh, '<', $lib_file
  32     or die "Could not open file '$lib_file' for reading: $!";
  33   my $ConfigRegex = qr/(?:use|require)\s+Config(?:\s+|;)/;
  34   my $found_config = 0;
  35   while (defined($_ = <$fh>)) {
  36     # crude heuristics to check that we were using Config
  37     if (/^\s*$ConfigRegex/ || /^\s*eval.*$ConfigRegex/) {
  38       $found_config = 1;
  39       last;
  40     }
  41   }
  42   $expand_config_vars = $found_config ? 0 : 1;
  43 HERE
  44   $expand_config_vars = 0 if $@;
  45 }
  46
  47 if ($expand_config_vars) {
  48     $useConfig = '';
  49     $Config_archname = qq('$Config{archname}');
  50     $Config_version  = qq('$Config{version}');
  51     my @Config_inc_version_list =
  52         reverse split / /, $Config{inc_version_list};
  53     $Config_inc_version_list =
  54         @Config_inc_version_list ?
  55             qq(qw(@Config_inc_version_list)) : q(());
  56 } else {
  57     $useConfig = 'use Config;';
  58     $Config_archname = q($Config{archname});
  59     $Config_version  = q($Config{version});
  60     $Config_inc_version_list =
  61               q(reverse split / /, $Config{inc_version_list});
  62 }
  63
  64 open OUT,'>', $file or die "Can't create $file: $!";
  65
  66 print "Extracting $file (with variable substitutions)\n";
  67
  68 # In this section, perl variables will be expanded during extraction.
  69 # You can use $Config{...} to use Configure variables.
  70
  71 print OUT <<"!GROK!THIS!";
  72 package lib;
  73
  74 # THIS FILE IS AUTOMATICALLY GENERATED FROM lib_pm.PL.
  75 # ANY CHANGES TO THIS FILE WILL BE OVERWRITTEN BY THE NEXT PERL BUILD.
  76
  77 $useConfig
  78
  79 use strict;
  80
  81 my \$archname         = $Config_archname;
  82 my \$version          = $Config_version;
  83 my \@inc_version_list = $Config_inc_version_list;
  84
  85 !GROK!THIS!
  86 print OUT <<'!NO!SUBS!';
  87
  88 our @ORIG_INC = @INC;   # take a handy copy of 'original' value
  89 our $VERSION = '0.64';
  90
  91 sub import {
  92     shift;
  93
  94     my %names;
  95     foreach (reverse @_) {
  96         my $path = $_;          # we'll be modifying it, so break the alias
  97         if ($path eq '') {
  98             require Carp;
  99             Carp::carp("Empty compile time value given to use lib");
 100         }
 101
 102         if ($path !~ /\.par$/i && -e $path && ! -d _) {
 103             require Carp;
 104             Carp::carp("Parameter to use lib must be directory, not file");
 105         }
 106         unshift(@INC, $path);
 107         # Add any previous version directories we found at configure time
 108         foreach my $incver (@inc_version_list)
 109         {
 110             my $dir = "$path/$incver";
 111             unshift(@INC, $dir) if -d $dir;
 112         }
 113         # Put a corresponding archlib directory in front of $path if it
 114         # looks like $path has an archlib directory below it.
 115         my($arch_auto_dir, $arch_dir, $version_dir, $version_arch_dir)
 116             = _get_dirs($path);
 117         unshift(@INC, $arch_dir)         if -d $arch_auto_dir;
 118         unshift(@INC, $version_dir)      if -d $version_dir;
 119         unshift(@INC, $version_arch_dir) if -d $version_arch_dir;
 120     }
 121
 122     # remove trailing duplicates
 123     @INC = grep { ++$names{$_} == 1 } @INC;
 124     return;
 125 }
 126
 127
 128 sub unimport {
 129     shift;
 130
 131     my %names;
 132     foreach my $path (@_) {
 133         my($arch_auto_dir, $arch_dir, $version_dir, $version_arch_dir)
 134             = _get_dirs($path);
 135         ++$names{$path};
 136         ++$names{$arch_dir}         if -d $arch_auto_dir;
 137         ++$names{$version_dir}      if -d $version_dir;
 138         ++$names{$version_arch_dir} if -d $version_arch_dir;
 139     }
 140
 141     # Remove ALL instances of each named directory.
 142     @INC = grep { !exists $names{$_} } @INC;
 143     return;
 144 }
 145
 146 sub _get_dirs {
 147     my($dir) = @_;
 148     my($arch_auto_dir, $arch_dir, $version_dir, $version_arch_dir);
 149
 150     $arch_auto_dir    = "$dir/$archname/auto";
 151     $arch_dir         = "$dir/$archname";
 152     $version_dir      = "$dir/$version";
 153     $version_arch_dir = "$dir/$version/$archname";
 154
 155     return($arch_auto_dir, $arch_dir, $version_dir, $version_arch_dir);
 156 }
 157
 158 1;
 159 __END__
 160
 161 =head1 NAME
 162
 163 lib - manipulate @INC at compile time
 164
 165 =head1 SYNOPSIS
 166
 167     use lib LIST;
 168
 169     no lib LIST;
 170
 171 =head1 DESCRIPTION
 172
 173 This is a small simple module which simplifies the manipulation of @INC
 174 at compile time.
 175
 176 It is typically used to add extra directories to perl's search path so
 177 that later C<use> or C<require> statements will find modules which are
 178 not located on perl's default search path.
 179
 180 =head2 Adding directories to @INC
 181
 182 The parameters to C<use lib> are added to the start of the perl search
 183 path. Saying
 184
 185     use lib LIST;
 186
 187 is I<almost> the same as saying
 188
 189     BEGIN { unshift(@INC, LIST) }
 190
 191 For each directory in LIST (called $dir here) the lib module also
 192 checks to see if a directory called $dir/$archname/auto exists.
 193 If so the $dir/$archname directory is assumed to be a corresponding
 194 architecture specific directory and is added to @INC in front of $dir.
 195 lib.pm also checks if directories called $dir/$version and $dir/$version/$archname
 196 exist and adds these directories to @INC.
 197
 198 The current value of C<$archname> can be found with this command:
 199
 200     perl -V:archname
 201
 202 The corresponding command to get the current value of C<$version> is:
 203
 204     perl -V:version
 205
 206 To avoid memory leaks, all trailing duplicate entries in @INC are
 207 removed.
 208
 209 =head2 Deleting directories from @INC
 210
 211 You should normally only add directories to @INC.  If you need to
 212 delete directories from @INC take care to only delete those which you
 213 added yourself or which you are certain are not needed by other modules
 214 in your script.  Other modules may have added directories which they
 215 need for correct operation.
 216
 217 The C<no lib> statement deletes all instances of each named directory
 218 from @INC.
 219
 220 For each directory in LIST (called $dir here) the lib module also
 221 checks to see if a directory called $dir/$archname/auto exists.
 222 If so the $dir/$archname directory is assumed to be a corresponding
 223 architecture specific directory and is also deleted from @INC.
 224
 225 =head2 Restoring original @INC
 226
 227 When the lib module is first loaded it records the current value of @INC
 228 in an array C<@lib::ORIG_INC>. To restore @INC to that value you
 229 can say
 230
 231     @INC = @lib::ORIG_INC;
 232
 233 =head1 CAVEATS
 234
 235 In order to keep lib.pm small and simple, it only works with Unix
 236 filepaths.  This doesn't mean it only works on Unix, but non-Unix
 237 users must first translate their file paths to Unix conventions.
 238
 239     # VMS users wanting to put [.stuff.moo] into
 240     # their @INC would write
 241     use lib 'stuff/moo';
 242
 243 =head1 NOTES
 244
 245 In the future, this module will likely use File::Spec for determining
 246 paths, as it does now for Mac OS (where Unix-style or Mac-style paths
 247 work, and Unix-style paths are converted properly to Mac-style paths
 248 before being added to @INC).
 249
 250 If you try to add a file to @INC as follows:
 251
 252   use lib 'this_is_a_file.txt';
 253
 254 C<lib> will warn about this. The sole exceptions are files with the
 255 C<.par> extension which are intended to be used as libraries.
 256
 257 =head1 SEE ALSO
 258
 259 FindBin - optional module which deals with paths relative to the source file.
 260
 261 PAR - optional module which can treat C<.par> files as Perl libraries.
 262
 263 =head1 AUTHOR
 264
 265 Tim Bunce, 2nd June 1995.
 266
 267 C<lib> is maintained by the perl5-porters. Please direct
 268 any questions to the canonical mailing list. Anything that
 269 is applicable to the CPAN release can be sent to its maintainer,
 270 though.
 271
 272 Maintainer: The Perl5-Porters <perl5-porters@perl.org>
 273
 274 Maintainer of the CPAN release: Steffen Mueller <smueller@cpan.org>
 275
 276 =head1 COPYRIGHT AND LICENSE
 277
 278 This package has been part of the perl core since perl 5.001.
 279 It has been released separately to CPAN so older installations
 280 can benefit from bug fixes.
 281
 282 This package has the same copyright and license as the perl core.
 283
 284 =cut
 285 !NO!SUBS!
 286
 287 close OUT or die "Can't close $file: $!";
 288 chdir $origdir;