ext/DynaLoader/DynaLoader_pm.PL

   1 use Config;
   2
   3 sub to_string {
   4     my ($value) = @_;
   5     $value =~ s/\\/\\\\/g;
   6     $value =~ s/'/\\'/g;
   7     return "'$value'";
   8 }
   9
  10 #
  11 # subroutine expand_os_specific expands $^O-specific preprocessing information
  12 # so that it will not be re-calculated at runtime in Dynaloader.pm
  13 #
  14 # Syntax of preprocessor should be kept extremely simple:
  15 #  - directives are in double angle brackets <<...>>
  16 #  - <<=string>> will be just evaluated
  17 #  - for $^O-specific there are two forms:
  18 #   <<$^O-eq-osname>>
  19 #   <<$^O-ne-osname>>
  20 #  this directive should be closed with respectively
  21 #   <</$^O-eq-osname>>
  22 #   <</$^O-ne-osname>>
  23 #  construct <<|$^O-ne-osname>> means #else
  24 #  nested <<$^O...>>-constructs are allowed but nested values must be for
  25 #   different OS-names!
  26 #
  27 #  -- added by VKON, 03-10-2004 to separate $^O-specific between OSes
  28 #     (so that Win32 never checks for $^O eq 'VMS' for example)
  29 #
  30 # The $^O tests test both for $^O and for $Config{osname}.
  31 # The latter is better for some for cross-compilation setups.
  32 #
  33 sub expand_os_specific {
  34     my $s = shift;
  35     for ($s) {
  36         s/<<=(.*?)>>/$1/gee;
  37         s/<<\$\^O-(eq|ne)-(\w+)>>(.*?)<<\/\$\^O-\1-\2>>/
  38           my ($op, $os, $expr) = ($1,$2,$3);
  39           if ($op ne 'eq' and $op ne 'ne') {die "wrong eq-ne arg in $&"};
  40           if ($expr =~ m[^(.*?)<<\|\$\^O-$op-$os>>(.*?)$]s) {
  41               # #if;#else;#endif
  42               my ($if,$el) = ($1,$2);
  43               if (($op eq 'eq' and ($^O eq $os || $Config{osname} eq $os)) || ($op eq 'ne' and ($^O ne $os || $Config{osname} ne $os))) {
  44                   $if
  45               }
  46               else {
  47                   $el
  48               }
  49           }
  50           else {
  51               # #if;#endif
  52               if (($op eq 'eq' and ($^O eq $os || $Config{osname} eq $os)) || ($op eq 'ne' and ($^O ne $os || $Config{osname} ne $os))) {
  53                   $expr
  54               }
  55               else {
  56                   ""
  57               }
  58           }
  59         /ges;
  60         if (/<<(=|\$\^O-)/) {die "bad <<\$^O-eq/ne-osname>> expression.".
  61             " Unclosed brackets?";
  62         }
  63     }
  64     $s;
  65 }
  66
  67 unlink "DynaLoader.pm" if -f "DynaLoader.pm";
  68 open OUT, '>', "DynaLoader.pm" or die $!;
  69 print OUT <<'EOT';
  70
  71 # Generated from DynaLoader_pm.PL, this file is unique for every OS
  72
  73 package DynaLoader;
  74
  75 #   And Gandalf said: 'Many folk like to know beforehand what is to
  76 #   be set on the table; but those who have laboured to prepare the
  77 #   feast like to keep their secret; for wonder makes the words of
  78 #   praise louder.'
  79
  80 #   (Quote from Tolkien suggested by Anno Siegel.)
  81 #
  82 # See pod text at end of file for documentation.
  83 # See also ext/DynaLoader/README in source tree for other information.
  84 #
  85 # Tim.Bunce@ig.co.uk, August 1994
  86
  87 BEGIN {
  88     $VERSION = '1.41';
  89 }
  90
  91 EOT
  92
  93 if (!$ENV{PERL_BUILD_EXPAND_CONFIG_VARS}) {
  94     print OUT "use Config;\n";
  95 }
  96
  97 print OUT <<'EOT';
  98
  99 # enable debug/trace messages from DynaLoader perl code
 100 $dl_debug = $ENV{PERL_DL_DEBUG} || 0 unless defined $dl_debug;
 101
 102 #
 103 # Flags to alter dl_load_file behaviour.  Assigned bits:
 104 #   0x01  make symbols available for linking later dl_load_file's.
 105 #         (only known to work on Solaris 2 using dlopen(RTLD_GLOBAL))
 106 #         (ignored under VMS; effect is built-in to image linking)
 107 #         (ignored under Android; the linker always uses RTLD_LOCAL)
 108 #
 109 # This is called as a class method $module->dl_load_flags.  The
 110 # definition here will be inherited and result on "default" loading
 111 # behaviour unless a sub-class of DynaLoader defines its own version.
 112 #
 113
 114 sub dl_load_flags { 0x00 }
 115
 116 EOT
 117
 118 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS}) {
 119     print OUT "(\$dl_dlext, \$dl_so, \$dlsrc) = (",
 120               to_string($Config{'dlext'}), ",",
 121               to_string($Config{'so'}), ",",
 122               to_string($Config{'dlsrc'}), ")\n;" ;
 123 }
 124 else {
 125     print OUT <<'EOT';
 126 ($dl_dlext, $dl_so, $dlsrc) = @Config::Config{qw(dlext so dlsrc)};
 127 EOT
 128 }
 129
 130 print OUT expand_os_specific(<<'EOT');
 131
 132 <<$^O-eq-VMS>>
 133 # Some systems need special handling to expand file specifications
 134 # (VMS support by Charles Bailey <bailey@HMIVAX.HUMGEN.UPENN.EDU>)
 135 # See dl_expandspec() for more details. Should be harmless but
 136 # inefficient to define on systems that don't need it.
 137 $Is_VMS    = $^O eq 'VMS';
 138 <</$^O-eq-VMS>>
 139 $do_expand = <<$^O-eq-VMS>>1<<|$^O-eq-VMS>>0<</$^O-eq-VMS>>;
 140
 141 @dl_require_symbols = ();       # names of symbols we need<<$^O-eq-freemint>>
 142 @dl_resolve_using   = ();       # names of files to link with<</$^O-eq-freemint>><<$^O-eq-hpux>>
 143 @dl_resolve_using   = ();       # names of files to link with<</$^O-eq-hpux>>
 144 @dl_library_path    = ();       # path to look for files
 145
 146 #XSLoader.pm may have added elements before we were required
 147 #@dl_shared_objects  = ();       # shared objects for symbols we have
 148 #@dl_librefs         = ();       # things we have loaded
 149 #@dl_modules         = ();       # Modules we have loaded
 150
 151 EOT
 152
 153 my $cfg_dl_library_path = <<'EOT';
 154 push(@dl_library_path, split(' ', $Config::Config{libpth}));
 155 EOT
 156
 157 sub dquoted_comma_list {
 158     join(", ", map {'"'.quotemeta($_).'"'} @_);
 159 }
 160
 161 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS}) {
 162     eval $cfg_dl_library_path;
 163     if (!$ENV{PERL_BUILD_EXPAND_ENV_VARS}) {
 164         my $dl_library_path = dquoted_comma_list(@dl_library_path);
 165         print OUT <<EOT;
 166 # The below \@dl_library_path has been expanded (%Config) in Perl build time.
 167
 168 \@dl_library_path = ($dl_library_path);
 169
 170 EOT
 171     }
 172 }
 173 else {
 174     print OUT <<EOT;
 175 # Initialise \@dl_library_path with the 'standard' library path
 176 # for this platform as determined by Configure.
 177
 178 $cfg_dl_library_path
 179
 180 EOT
 181 }
 182
 183 my $ldlibpthname;
 184 my $ldlibpthname_defined;
 185 my $pthsep;
 186
 187 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS}) {
 188     $ldlibpthname         = to_string($Config::Config{ldlibpthname});
 189     $ldlibpthname_defined = to_string(defined $Config::Config{ldlibpthname} ? 1 : 0);
 190     $pthsep               = to_string($Config::Config{path_sep});
 191 }
 192 else {
 193     $ldlibpthname         = q($Config::Config{ldlibpthname});
 194     $ldlibpthname_defined = q(defined $Config::Config{ldlibpthname});
 195     $pthsep               = q($Config::Config{path_sep});
 196 }
 197 print OUT <<EOT;
 198 my \$ldlibpthname         = $ldlibpthname;
 199 my \$ldlibpthname_defined = $ldlibpthname_defined;
 200 my \$pthsep               = $pthsep;
 201
 202 EOT
 203
 204 my $env_dl_library_path = <<'EOT';
 205 if ($ldlibpthname_defined &&
 206     exists $ENV{$ldlibpthname}) {
 207     push(@dl_library_path, split(/$pthsep/, $ENV{$ldlibpthname}));
 208 }
 209
 210 # E.g. HP-UX supports both its native SHLIB_PATH *and* LD_LIBRARY_PATH.
 211
 212 if ($ldlibpthname_defined &&
 213     $ldlibpthname ne 'LD_LIBRARY_PATH' &&
 214     exists $ENV{LD_LIBRARY_PATH}) {
 215     push(@dl_library_path, split(/$pthsep/, $ENV{LD_LIBRARY_PATH}));
 216 }
 217 EOT
 218
 219 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS} && $ENV{PERL_BUILD_EXPAND_ENV_VARS}) {
 220     eval $env_dl_library_path;
 221 }
 222 else {
 223     print OUT <<EOT;
 224 # Add to \@dl_library_path any extra directories we can gather from environment
 225 # during runtime.
 226
 227 $env_dl_library_path
 228
 229 EOT
 230 }
 231
 232 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS} && $ENV{PERL_BUILD_EXPAND_ENV_VARS}) {
 233     my $dl_library_path = dquoted_comma_list(@dl_library_path);
 234     print OUT <<EOT;
 235 # The below \@dl_library_path has been expanded (%Config, %ENV)
 236 # in Perl build time.
 237
 238 \@dl_library_path = ($dl_library_path);
 239
 240 EOT
 241 }
 242
 243 if ( $Config::Config{d_libname_unique} ) {
 244     printf OUT <<'EOT', length($Config::Config{dlext}) + 1;
 245 sub mod2fname {
 246     my $parts = shift;
 247     my $so_len = %d;
 248     my $name_max = 255; # No easy way to get this here
 249
 250     my $libname = "PL_" .  join("__", @$parts);
 251
 252     return $libname if (length($libname)+$so_len) <= $name_max;
 253
 254     # It's too darned big, so we need to go strip. We use the same
 255     # algorithm as xsubpp does. First, strip out doubled __
 256     $libname =~ s/__/_/g;
 257     return $libname if (length($libname)+$so_len) <= $name_max;
 258
 259     # Strip duplicate letters
 260     1 while $libname =~ s/(.)\1/\U$1/i;
 261     return $libname if (length($libname)+$so_len) <= $name_max;
 262
 263     # Still too long. Truncate.
 264     $libname = substr($libname, 0, $name_max - $so_len);
 265     return $libname;
 266 }
 267 EOT
 268 }
 269
 270 # following long string contains $^O-specific stuff, which is factored out
 271 print OUT expand_os_specific(<<'EOT');
 272 # No prizes for guessing why we don't say 'bootstrap DynaLoader;' here.
 273 # NOTE: All dl_*.xs (including dl_none.xs) define a dl_error() XSUB
 274 boot_DynaLoader('DynaLoader') if defined(&boot_DynaLoader) &&
 275                                 !defined(&dl_error);
 276
 277 if ($dl_debug) {
 278     print STDERR "DynaLoader.pm loaded (@INC, @dl_library_path)\n";
 279     print STDERR "DynaLoader not linked into this perl\n"
 280             unless defined(&boot_DynaLoader);
 281 }
 282
 283 1; # End of main code
 284
 285
 286 sub croak   { require Carp; Carp::croak(@_)   }
 287
 288 sub bootstrap_inherit {
 289     my $module = $_[0];
 290     local *isa = *{"$module\::ISA"};
 291     local @isa = (@isa, 'DynaLoader');
 292     # Cannot goto due to delocalization.  Will report errors on a wrong line?
 293     bootstrap(@_);
 294 }
 295
 296 sub bootstrap {
 297     # use local vars to enable $module.bs script to edit values
 298     local(@args) = @_;
 299     local($module) = $args[0];
 300     local(@dirs, $file);
 301
 302     unless ($module) {
 303         require Carp;
 304         Carp::confess("Usage: DynaLoader::bootstrap(module)");
 305     }
 306
 307     # A common error on platforms which don't support dynamic loading.
 308     # Since it's fatal and potentially confusing we give a detailed message.
 309     croak("Can't load module $module, dynamic loading not available in this perl.\n".
 310         "  (You may need to build a new perl executable which either supports\n".
 311         "  dynamic loading or has the $module module statically linked into it.)\n")
 312         unless defined(&dl_load_file);
 313
 314
 315     <<$^O-eq-os2>>
 316     # Can dynaload, but cannot dynaload Perl modules...
 317     die 'Dynaloaded Perl modules are not available in this build of Perl' if $OS2::is_static;
 318
 319     <</$^O-eq-os2>>
 320     my @modparts = split(/::/,$module);
 321     my $modfname = $modparts[-1];
 322     my $modfname_orig = $modfname; # For .bs file search
 323
 324     # Some systems have restrictions on files names for DLL's etc.
 325     # mod2fname returns appropriate file base name (typically truncated)
 326     # It may also edit @modparts if required.
 327     $modfname = &mod2fname(\@modparts) if defined &mod2fname;
 328
 329     <<$^O-eq-NetWare>>
 330     # Truncate the module name to 8.3 format for NetWare
 331         if ((length($modfname) > 8)) {
 332                 $modfname = substr($modfname, 0, 8);
 333         }
 334     <</$^O-eq-NetWare>>
 335
 336     my $modpname = join('/',@modparts);
 337
 338     print STDERR "DynaLoader::bootstrap for $module ",
 339                        "(auto/$modpname/$modfname.$dl_dlext)\n"
 340         if $dl_debug;
 341
 342     my $dir;
 343     foreach (@INC) {
 344         <<$^O-eq-VMS>>chop($_ = VMS::Filespec::unixpath($_));<</$^O-eq-VMS>>
 345             $dir = "$_/auto/$modpname";
 346
 347         next unless -d $dir; # skip over uninteresting directories
 348
 349         # check for common cases to avoid autoload of dl_findfile
 350         my $try = "$dir/$modfname.$dl_dlext";
 351         last if $file = ($do_expand) ? dl_expandspec($try) : ((-f $try) && $try);
 352
 353         # no luck here, save dir for possible later dl_findfile search
 354         push @dirs, $dir;
 355     }
 356     # last resort, let dl_findfile have a go in all known locations
 357     $file = dl_findfile(map("-L$_",@dirs,@INC), $modfname) unless $file;
 358
 359     croak("Can't locate loadable object for module $module in \@INC (\@INC contains: @INC)")
 360         unless $file;   # wording similar to error from 'require'
 361
 362     <<$^O-eq-VMS>>$file = uc($file) if $Config::Config{d_vms_case_sensitive_symbols};<</$^O-eq-VMS>>
 363     my $bootname = "boot_$module";
 364     $bootname =~ s/\W/_/g;
 365     @dl_require_symbols = ($bootname);
 366
 367     # Execute optional '.bootstrap' perl script for this module.
 368     # The .bs file can be used to configure @dl_resolve_using etc to
 369     # match the needs of the individual module on this architecture.
 370     # N.B. The .bs file does not following the naming convention used
 371     # by mod2fname.
 372     my $bs = "$dir/$modfname_orig";
 373     $bs =~ s/(\.\w+)?(;\d*)?$/\.bs/; # look for .bs 'beside' the library
 374     if (-s $bs) { # only read file if it's not empty
 375         print STDERR "BS: $bs ($^O, $dlsrc)\n" if $dl_debug;
 376         eval { do $bs; };
 377         warn "$bs: $@\n" if $@;
 378     }
 379
 380     my $boot_symbol_ref;
 381
 382     <<$^O-eq-darwin>>
 383     if ($boot_symbol_ref = dl_find_symbol(0, $bootname, 1)) {
 384         goto boot; #extension library has already been loaded, e.g. darwin
 385     }
 386     <</$^O-eq-darwin>>
 387
 388     # Many dynamic extension loading problems will appear to come from
 389     # this section of code: XYZ failed at line 123 of DynaLoader.pm.
 390     # Often these errors are actually occurring in the initialisation
 391     # C code of the extension XS file. Perl reports the error as being
 392     # in this perl code simply because this was the last perl code
 393     # it executed.
 394
 395     my $flags = $module->dl_load_flags;
 396     <<$^O-eq-android>>
 397     # See the note above regarding the linker.
 398     $flags = 0x00;
 399     <</$^O-eq-android>>
 400     my $libref = dl_load_file($file, $flags) or
 401         croak("Can't load '$file' for module $module: ".dl_error());
 402
 403     push(@dl_librefs,$libref);  # record loaded object
 404 <<$^O-eq-freemint>>
 405     my @unresolved = dl_undef_symbols();
 406     if (@unresolved) {
 407         require Carp;
 408         Carp::carp("Undefined symbols present after loading $file: @unresolved\n");
 409     }
 410 <</$^O-eq-freemint>>
 411     $boot_symbol_ref = dl_find_symbol($libref, $bootname) or
 412          croak("Can't find '$bootname' symbol in $file\n");
 413
 414     push(@dl_modules, $module); # record loaded module
 415
 416   boot:
 417     my $xs = dl_install_xsub("${module}::bootstrap", $boot_symbol_ref, $file);
 418
 419     # See comment block above
 420
 421         push(@dl_shared_objects, $file); # record files loaded
 422
 423     &$xs(@args);
 424 }
 425
 426 sub dl_findfile {
 427     # This function does not automatically consider the architecture
 428     # or the perl library auto directories.
 429     my (@args) = @_;
 430     my (@dirs,  $dir);   # which directories to search
 431     my (@found);         # full paths to real files we have found
 432     #my $dl_ext= <<=to_string($Config::Config{'dlext'})>>; # $Config::Config{'dlext'} suffix for perl extensions
 433     #my $dl_so = <<=to_string($Config::Config{'so'})>>; # $Config::Config{'so'} suffix for shared libraries
 434
 435     print STDERR "dl_findfile(@args)\n" if $dl_debug;
 436
 437     # accumulate directories but process files as they appear
 438     arg: foreach(@args) {
 439         #  Special fast case: full filepath requires no search
 440         <<$^O-eq-VMS>>
 441         if (m%[:>/\]]% && -f $_) {
 442             push(@found,dl_expandspec(VMS::Filespec::vmsify($_)));
 443             last arg unless wantarray;
 444             next;
 445         }
 446         <</$^O-eq-VMS>>
 447         <<$^O-ne-VMS>>
 448         if (m:/: && -f $_) {
 449             push(@found,$_);
 450             last arg unless wantarray;
 451             next;
 452         }
 453         <</$^O-ne-VMS>>
 454
 455         # Deal with directories first:
 456         #  Using a -L prefix is the preferred option (faster and more robust)
 457         if (m:^-L:) { s/^-L//; push(@dirs, $_); next; }
 458
 459         #  Otherwise we try to try to spot directories by a heuristic
 460         #  (this is a more complicated issue than it first appears)
 461         if (m:/: && -d $_) {   push(@dirs, $_); next; }
 462
 463         <<$^O-eq-VMS>>
 464         # VMS: we may be using native VMS directory syntax instead of
 465         # Unix emulation, so check this as well
 466         if (/[:>\]]/ && -d $_) {   push(@dirs, $_); next; }
 467         <</$^O-eq-VMS>>
 468
 469         #  Only files should get this far...
 470         my(@names, $name);    # what filenames to look for
 471         if (m:-l: ) {          # convert -lname to appropriate library name
 472             s/-l//;
 473             push(@names,"lib$_.$dl_so");
 474             push(@names,"lib$_.a");
 475         } else {                # Umm, a bare name. Try various alternatives:
 476             # these should be ordered with the most likely first
 477             push(@names,"$_.$dl_dlext")    unless m/\.$dl_dlext$/o;
 478             push(@names,"$_.$dl_so")     unless m/\.$dl_so$/o;
 479             <<$^O-eq-cygwin>>
 480             push(@names,"cyg$_.$dl_so")  unless m:/:;
 481             <</$^O-eq-cygwin>>
 482             push(@names,"lib$_.$dl_so")  unless m:/:;
 483             push(@names, $_);
 484         }
 485         my $dirsep = '/';
 486         <<$^O-eq-symbian>>
 487         $dirsep = '\\';
 488         if ($0 =~ /^([a-z]):/i) {
 489             my $drive = $1;
 490             @dirs = map { "$drive:$_" } @dirs;
 491             @dl_library_path = map { "$drive:$_" } @dl_library_path;
 492         }
 493         <</$^O-eq-symbian>>
 494         foreach $dir (@dirs, @dl_library_path) {
 495             next unless -d $dir;
 496             <<$^O-eq-VMS>>
 497             chop($dir = VMS::Filespec::unixpath($dir));
 498             <</$^O-eq-VMS>>
 499             foreach $name (@names) {
 500                 my($file) = "$dir$dirsep$name";
 501                 print STDERR " checking in $dir for $name\n" if $dl_debug;
 502                 $file = ($do_expand) ? dl_expandspec($file) : (-f $file && $file);
 503                 #$file = _check_file($file);
 504                 if ($file) {
 505                     push(@found, $file);
 506                     next arg; # no need to look any further
 507                 }
 508             }
 509         }
 510     }
 511     if ($dl_debug) {
 512         foreach(@dirs) {
 513             print STDERR " dl_findfile ignored non-existent directory: $_\n" unless -d $_;
 514         }
 515         print STDERR "dl_findfile found: @found\n";
 516     }
 517     return $found[0] unless wantarray;
 518     @found;
 519 }
 520
 521
 522 <<$^O-eq-VMS>>
 523 # dl_expandspec should be defined in dl_vms.xs
 524 <<|$^O-eq-VMS>>
 525 sub dl_expandspec {
 526     my($spec) = @_;
 527     # Optional function invoked if DynaLoader.pm sets $do_expand.
 528     # Most systems do not require or use this function.
 529     # Some systems may implement it in the dl_*.xs file in which case
 530     # this Perl version should be excluded at build time.
 531
 532     # This function is designed to deal with systems which treat some
 533     # 'filenames' in a special way. For example VMS 'Logical Names'
 534     # (something like unix environment variables - but different).
 535     # This function should recognise such names and expand them into
 536     # full file paths.
 537     # Must return undef if $spec is invalid or file does not exist.
 538
 539     my $file = $spec; # default output to input
 540
 541         return undef unless -f $file;
 542     print STDERR "dl_expandspec($spec) => $file\n" if $dl_debug;
 543     $file;
 544 }
 545 <</$^O-eq-VMS>>
 546
 547 sub dl_find_symbol_anywhere
 548 {
 549     my $sym = shift;
 550     my $libref;
 551     foreach $libref (@dl_librefs) {
 552         my $symref = dl_find_symbol($libref,$sym,1);
 553         return $symref if $symref;
 554     }
 555     return undef;
 556 }
 557
 558 __END__
 559
 560 =head1 NAME
 561
 562 DynaLoader - Dynamically load C libraries into Perl code
 563
 564 =head1 SYNOPSIS
 565
 566     package YourPackage;
 567     require DynaLoader;
 568     @ISA = qw(... DynaLoader ...);
 569     bootstrap YourPackage;
 570
 571     # optional method for 'global' loading
 572     sub dl_load_flags { 0x01 }
 573
 574
 575 =head1 DESCRIPTION
 576
 577 This document defines a standard generic interface to the dynamic
 578 linking mechanisms available on many platforms.  Its primary purpose is
 579 to implement automatic dynamic loading of Perl modules.
 580
 581 This document serves as both a specification for anyone wishing to
 582 implement the DynaLoader for a new platform and as a guide for
 583 anyone wishing to use the DynaLoader directly in an application.
 584
 585 The DynaLoader is designed to be a very simple high-level
 586 interface that is sufficiently general to cover the requirements
 587 of SunOS, HP-UX, Linux, VMS and other platforms.
 588
 589 It is also hoped that the interface will cover the needs of OS/2, NT
 590 etc and also allow pseudo-dynamic linking (using C<ld -A> at runtime).
 591
 592 It must be stressed that the DynaLoader, by itself, is practically
 593 useless for accessing non-Perl libraries because it provides almost no
 594 Perl-to-C 'glue'.  There is, for example, no mechanism for calling a C
 595 library function or supplying arguments.  A C::DynaLib module
 596 is available from CPAN sites which performs that function for some
 597 common system types.  And since the year 2000, there's also Inline::C,
 598 a module that allows you to write Perl subroutines in C.  Also available
 599 from your local CPAN site.
 600
 601 DynaLoader Interface Summary
 602
 603   @dl_library_path
 604   @dl_resolve_using
 605   @dl_require_symbols
 606   $dl_debug
 607   $dl_dlext
 608   @dl_librefs
 609   @dl_modules
 610   @dl_shared_objects
 611                                                   Implemented in:
 612   bootstrap($modulename)                               Perl
 613   @filepaths = dl_findfile(@names)                     Perl
 614   $flags = $modulename->dl_load_flags                  Perl
 615   $symref  = dl_find_symbol_anywhere($symbol)          Perl
 616
 617   $libref  = dl_load_file($filename, $flags)           C
 618   $status  = dl_unload_file($libref)                   C
 619   $symref  = dl_find_symbol($libref, $symbol)          C
 620   @symbols = dl_undef_symbols()                        C
 621   dl_install_xsub($name, $symref [, $filename])        C
 622   $message = dl_error                                  C
 623
 624 =over 4
 625
 626 =item @dl_library_path
 627
 628 The standard/default list of directories in which dl_findfile() will
 629 search for libraries etc.  Directories are searched in order:
 630 $dl_library_path[0], [1], ... etc
 631
 632 @dl_library_path is initialised to hold the list of 'normal' directories
 633 (F</usr/lib>, etc) determined by B<Configure> (C<$Config{'libpth'}>).  This should
 634 ensure portability across a wide range of platforms.
 635
 636 @dl_library_path should also be initialised with any other directories
 637 that can be determined from the environment at runtime (such as
 638 LD_LIBRARY_PATH for SunOS).
 639
 640 After initialisation @dl_library_path can be manipulated by an
 641 application using push and unshift before calling dl_findfile().
 642 Unshift can be used to add directories to the front of the search order
 643 either to save search time or to override libraries with the same name
 644 in the 'normal' directories.
 645
 646 The load function that dl_load_file() calls may require an absolute
 647 pathname.  The dl_findfile() function and @dl_library_path can be
 648 used to search for and return the absolute pathname for the
 649 library/object that you wish to load.
 650
 651 =item @dl_resolve_using
 652
 653 A list of additional libraries or other shared objects which can be
 654 used to resolve any undefined symbols that might be generated by a
 655 later call to load_file().
 656
 657 This is only required on some platforms which do not handle dependent
 658 libraries automatically.  For example the Socket Perl extension
 659 library (F<auto/Socket/Socket.so>) contains references to many socket
 660 functions which need to be resolved when it's loaded.  Most platforms
 661 will automatically know where to find the 'dependent' library (e.g.,
 662 F</usr/lib/libsocket.so>).  A few platforms need to be told the
 663 location of the dependent library explicitly.  Use @dl_resolve_using
 664 for this.
 665
 666 Example usage:
 667
 668     @dl_resolve_using = dl_findfile('-lsocket');
 669
 670 =item @dl_require_symbols
 671
 672 A list of one or more symbol names that are in the library/object file
 673 to be dynamically loaded.  This is only required on some platforms.
 674
 675 =item @dl_librefs
 676
 677 An array of the handles returned by successful calls to dl_load_file(),
 678 made by bootstrap, in the order in which they were loaded.
 679 Can be used with dl_find_symbol() to look for a symbol in any of
 680 the loaded files.
 681
 682 =item @dl_modules
 683
 684 An array of module (package) names that have been bootstrap'ed.
 685
 686 =item @dl_shared_objects
 687
 688 An array of file names for the shared objects that were loaded.
 689
 690 =item dl_error()
 691
 692 Syntax:
 693
 694     $message = dl_error();
 695
 696 Error message text from the last failed DynaLoader function.  Note
 697 that, similar to errno in unix, a successful function call does not
 698 reset this message.
 699
 700 Implementations should detect the error as soon as it occurs in any of
 701 the other functions and save the corresponding message for later
 702 retrieval.  This will avoid problems on some platforms (such as SunOS)
 703 where the error message is very temporary (e.g., dlerror()).
 704
 705 =item $dl_debug
 706
 707 Internal debugging messages are enabled when $dl_debug is set true.
 708 Currently setting $dl_debug only affects the Perl side of the
 709 DynaLoader.  These messages should help an application developer to
 710 resolve any DynaLoader usage problems.
 711
 712 $dl_debug is set to C<$ENV{'PERL_DL_DEBUG'}> if defined.
 713
 714 For the DynaLoader developer/porter there is a similar debugging
 715 variable added to the C code (see dlutils.c) and enabled if Perl was
 716 built with the B<-DDEBUGGING> flag.  This can also be set via the
 717 PERL_DL_DEBUG environment variable.  Set to 1 for minimal information or
 718 higher for more.
 719
 720 =item $dl_dlext
 721
 722 When specified (localised) in a module's F<.pm> file, indicates the extension
 723 which the module's loadable object will have. For example:
 724
 725     local $DynaLoader::dl_dlext = 'unusual_ext';
 726
 727 would indicate that the module's loadable object has an extension of
 728 C<unusual_ext> instead of the more usual C<$Config{dlext}>.  NOTE: This also
 729 requires that the module's F<Makefile.PL> specify (in C<WriteMakefile()>):
 730
 731     DLEXT => 'unusual_ext',
 732
 733 =item dl_findfile()
 734
 735 Syntax:
 736
 737     @filepaths = dl_findfile(@names)
 738
 739 Determine the full paths (including file suffix) of one or more
 740 loadable files given their generic names and optionally one or more
 741 directories.  Searches directories in @dl_library_path by default and
 742 returns an empty list if no files were found.
 743
 744 Names can be specified in a variety of platform independent forms.  Any
 745 names in the form B<-lname> are converted into F<libname.*>, where F<.*> is
 746 an appropriate suffix for the platform.
 747
 748 If a name does not already have a suitable prefix and/or suffix then
 749 the corresponding file will be searched for by trying combinations of
 750 prefix and suffix appropriate to the platform: "$name.o", "lib$name.*"
 751 and "$name".
 752
 753 If any directories are included in @names they are searched before
 754 @dl_library_path.  Directories may be specified as B<-Ldir>.  Any other
 755 names are treated as filenames to be searched for.
 756
 757 Using arguments of the form C<-Ldir> and C<-lname> is recommended.
 758
 759 Example:
 760
 761     @dl_resolve_using = dl_findfile(qw(-L/usr/5lib -lposix));
 762
 763
 764 =item dl_expandspec()
 765
 766 Syntax:
 767
 768     $filepath = dl_expandspec($spec)
 769
 770 Some unusual systems, such as VMS, require special filename handling in
 771 order to deal with symbolic names for files (i.e., VMS's Logical Names).
 772
 773 To support these systems a dl_expandspec() function can be implemented
 774 either in the F<dl_*.xs> file or code can be added to the dl_expandspec()
 775 function in F<DynaLoader.pm>.  See F<DynaLoader_pm.PL> for more information.
 776
 777 =item dl_load_file()
 778
 779 Syntax:
 780
 781     $libref = dl_load_file($filename, $flags)
 782
 783 Dynamically load $filename, which must be the path to a shared object
 784 or library.  An opaque 'library reference' is returned as a handle for
 785 the loaded object.  Returns undef on error.
 786
 787 The $flags argument to alters dl_load_file behaviour.
 788 Assigned bits:
 789
 790  0x01  make symbols available for linking later dl_load_file's.
 791        (only known to work on Solaris 2 using dlopen(RTLD_GLOBAL))
 792        (ignored under VMS; this is a normal part of image linking)
 793
 794 (On systems that provide a handle for the loaded object such as SunOS
 795 and HPUX, $libref will be that handle.  On other systems $libref will
 796 typically be $filename or a pointer to a buffer containing $filename.
 797 The application should not examine or alter $libref in any way.)
 798
 799 This is the function that does the real work.  It should use the
 800 current values of @dl_require_symbols and @dl_resolve_using if required.
 801
 802     SunOS: dlopen($filename)
 803     HP-UX: shl_load($filename)
 804     Linux: dld_create_reference(@dl_require_symbols); dld_link($filename)
 805     VMS:   lib$find_image_symbol($filename,$dl_require_symbols[0])
 806
 807 (The dlopen() function is also used by Solaris and some versions of
 808 Linux, and is a common choice when providing a "wrapper" on other
 809 mechanisms as is done in the OS/2 port.)
 810
 811 =item dl_unload_file()
 812
 813 Syntax:
 814
 815     $status = dl_unload_file($libref)
 816
 817 Dynamically unload $libref, which must be an opaque 'library reference' as
 818 returned from dl_load_file.  Returns one on success and zero on failure.
 819 This function is optional and may not necessarily be provided on all platforms.
 820
 821 If it is defined and perl is compiled with the C macro C<DL_UNLOAD_ALL_AT_EXIT>
 822 defined, then it is called automatically when the interpreter exits for
 823 every shared object or library loaded by DynaLoader::bootstrap.  All such
 824 library references are stored in @dl_librefs by DynaLoader::Bootstrap as it
 825 loads the libraries.  The files are unloaded in last-in, first-out order.
 826
 827 This unloading is usually necessary when embedding a shared-object perl (e.g.
 828 one configured with -Duseshrplib) within a larger application, and the perl
 829 interpreter is created and destroyed several times within the lifetime of the
 830 application.  In this case it is possible that the system dynamic linker will
 831 unload and then subsequently reload the shared libperl without relocating any
 832 references to it from any files DynaLoaded by the previous incarnation of the
 833 interpreter.  As a result, any shared objects opened by DynaLoader may point to
 834 a now invalid 'ghost' of the libperl shared object, causing apparently random
 835 memory corruption and crashes.  This behaviour is most commonly seen when using
 836 Apache and mod_perl built with the APXS mechanism.
 837
 838     SunOS: dlclose($libref)
 839     HP-UX: ???
 840     Linux: ???
 841     VMS:   ???
 842
 843 (The dlclose() function is also used by Solaris and some versions of
 844 Linux, and is a common choice when providing a "wrapper" on other
 845 mechanisms as is done in the OS/2 port.)
 846
 847 =item dl_load_flags()
 848
 849 Syntax:
 850
 851     $flags = dl_load_flags $modulename;
 852
 853 Designed to be a method call, and to be overridden by a derived class
 854 (i.e. a class which has DynaLoader in its @ISA).  The definition in
 855 DynaLoader itself returns 0, which produces standard behavior from
 856 dl_load_file().
 857
 858 =item dl_find_symbol()
 859
 860 Syntax:
 861
 862     $symref = dl_find_symbol($libref, $symbol)
 863
 864 Return the address of the symbol $symbol or C<undef> if not found.  If the
 865 target system has separate functions to search for symbols of different
 866 types then dl_find_symbol() should search for function symbols first and
 867 then other types.
 868
 869 The exact manner in which the address is returned in $symref is not
 870 currently defined.  The only initial requirement is that $symref can
 871 be passed to, and understood by, dl_install_xsub().
 872
 873     SunOS: dlsym($libref, $symbol)
 874     HP-UX: shl_findsym($libref, $symbol)
 875     Linux: dld_get_func($symbol) and/or dld_get_symbol($symbol)
 876     VMS:   lib$find_image_symbol($libref,$symbol)
 877
 878
 879 =item dl_find_symbol_anywhere()
 880
 881 Syntax:
 882
 883     $symref = dl_find_symbol_anywhere($symbol)
 884
 885 Applies dl_find_symbol() to the members of @dl_librefs and returns
 886 the first match found.
 887
 888 =item dl_undef_symbols()
 889
 890 Example
 891
 892     @symbols = dl_undef_symbols()
 893
 894 Return a list of symbol names which remain undefined after load_file().
 895 Returns C<()> if not known.  Don't worry if your platform does not provide
 896 a mechanism for this.  Most do not need it and hence do not provide it,
 897 they just return an empty list.
 898
 899
 900 =item dl_install_xsub()
 901
 902 Syntax:
 903
 904     dl_install_xsub($perl_name, $symref [, $filename])
 905
 906 Create a new Perl external subroutine named $perl_name using $symref as
 907 a pointer to the function which implements the routine.  This is simply
 908 a direct call to newXS()/newXS_flags().  Returns a reference to the installed
 909 function.
 910
 911 The $filename parameter is used by Perl to identify the source file for
 912 the function if required by die(), caller() or the debugger.  If
 913 $filename is not defined then "DynaLoader" will be used.
 914
 915
 916 =item bootstrap()
 917
 918 Syntax:
 919
 920 bootstrap($module [...])
 921
 922 This is the normal entry point for automatic dynamic loading in Perl.
 923
 924 It performs the following actions:
 925
 926 =over 8
 927
 928 =item *
 929
 930 locates an auto/$module directory by searching @INC
 931
 932 =item *
 933
 934 uses dl_findfile() to determine the filename to load
 935
 936 =item *
 937
 938 sets @dl_require_symbols to C<("boot_$module")>
 939
 940 =item *
 941
 942 executes an F<auto/$module/$module.bs> file if it exists
 943 (typically used to add to @dl_resolve_using any files which
 944 are required to load the module on the current platform)
 945
 946 =item *
 947
 948 calls dl_load_flags() to determine how to load the file.
 949
 950 =item *
 951
 952 calls dl_load_file() to load the file
 953
 954 =item *
 955
 956 calls dl_undef_symbols() and warns if any symbols are undefined
 957
 958 =item *
 959
 960 calls dl_find_symbol() for "boot_$module"
 961
 962 =item *
 963
 964 calls dl_install_xsub() to install it as "${module}::bootstrap"
 965
 966 =item *
 967
 968 calls &{"${module}::bootstrap"} to bootstrap the module (actually
 969 it uses the function reference returned by dl_install_xsub for speed)
 970
 971 =back
 972
 973 All arguments to bootstrap() are passed to the module's bootstrap function.
 974 The default code generated by F<xsubpp> expects $module [, $version]
 975 If the optional $version argument is not given, it defaults to
 976 C<$XS_VERSION // $VERSION> in the module's symbol table. The default code
 977 compares the Perl-space version with the version of the compiled XS code,
 978 and croaks with an error if they do not match.
 979
 980 =back
 981
 982
 983 =head1 AUTHOR
 984
 985 Tim Bunce, 11 August 1994.
 986
 987 This interface is based on the work and comments of (in no particular
 988 order): Larry Wall, Robert Sanders, Dean Roehrich, Jeff Okamoto, Anno
 989 Siegel, Thomas Neumann, Paul Marquess, Charles Bailey, myself and others.
 990
 991 Larry Wall designed the elegant inherited bootstrap mechanism and
 992 implemented the first Perl 5 dynamic loader using it.
 993
 994 Solaris global loading added by Nick Ing-Simmons with design/coding
 995 assistance from Tim Bunce, January 1996.
 996
 997 =cut
 998 EOT
 999
1000 close OUT or die $!;
1001