This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
1a17981ac04e103decd0e06c5907ee1fba82c236
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2
3 perlfunc - Perl builtin functions
4
5 =head1 DESCRIPTION
6
7 The functions in this section can serve as terms in an expression.
8 They fall into two major categories: list operators and named unary
9 operators.  These differ in their precedence relationship with a
10 following comma.  (See the precedence table in L<perlop>.)  List
11 operators take more than one argument, while unary operators can never
12 take more than one argument.  Thus, a comma terminates the argument of
13 a unary operator, but merely separates the arguments of a list
14 operator.  A unary operator generally provides a scalar context to its
15 argument, while a list operator may provide either scalar or list
16 contexts for its arguments.  If it does both, the scalar arguments will
17 be first, and the list argument will follow.  (Note that there can ever
18 be only one such list argument.)  For instance, splice() has three scalar
19 arguments followed by a list, whereas gethostbyname() has four scalar
20 arguments.
21
22 In the syntax descriptions that follow, list operators that expect a
23 list (and provide list context for the elements of the list) are shown
24 with LIST as an argument.  Such a list may consist of any combination
25 of scalar arguments or list values; the list values will be included
26 in the list as if each individual element were interpolated at that
27 point in the list, forming a longer single-dimensional list value.
28 Elements of the LIST should be separated by commas.
29
30 Any function in the list below may be used either with or without
31 parentheses around its arguments.  (The syntax descriptions omit the
32 parentheses.)  If you use the parentheses, the simple (but occasionally
33 surprising) rule is this: It I<looks> like a function, therefore it I<is> a
34 function, and precedence doesn't matter.  Otherwise it's a list
35 operator or unary operator, and precedence does matter.  And whitespace
36 between the function and left parenthesis doesn't count--so you need to
37 be careful sometimes:
38
39     print 1+2+4;        # Prints 7.
40     print(1+2) + 4;     # Prints 3.
41     print (1+2)+4;      # Also prints 3!
42     print +(1+2)+4;     # Prints 7.
43     print ((1+2)+4);    # Prints 7.
44
45 If you run Perl with the B<-w> switch it can warn you about this.  For
46 example, the third line above produces:
47
48     print (...) interpreted as function at - line 1.
49     Useless use of integer addition in void context at - line 1.
50
51 A few functions take no arguments at all, and therefore work as neither
52 unary nor list operators.  These include such functions as C<time>
53 and C<endpwent>.  For example, C<time+86_400> always means
54 C<time() + 86_400>.
55
56 For functions that can be used in either a scalar or list context,
57 nonabortive failure is generally indicated in a scalar context by
58 returning the undefined value, and in a list context by returning the
59 null list.
60
61 Remember the following important rule: There is B<no rule> that relates
62 the behavior of an expression in list context to its behavior in scalar
63 context, or vice versa.  It might do two totally different things.
64 Each operator and function decides which sort of value it would be most
65 appropriate to return in scalar context.  Some operators return the
66 length of the list that would have been returned in list context.  Some
67 operators return the first value in the list.  Some operators return the
68 last value in the list.  Some operators return a count of successful
69 operations.  In general, they do what you want, unless you want
70 consistency.
71
72 A named array in scalar context is quite different from what would at
73 first glance appear to be a list in scalar context.  You can't get a list
74 like C<(1,2,3)> into being in scalar context, because the compiler knows
75 the context at compile time.  It would generate the scalar comma operator
76 there, not the list construction version of the comma.  That means it
77 was never a list to start with.
78
79 In general, functions in Perl that serve as wrappers for system calls
80 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
81 true when they succeed and C<undef> otherwise, as is usually mentioned
82 in the descriptions below.  This is different from the C interfaces,
83 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
84 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
85 variable on failure.  Other functions do not, except accidentally.
86
87 =head2 Perl Functions by Category
88
89 Here are Perl's functions (including things that look like
90 functions, like some keywords and named operators)
91 arranged by category.  Some functions appear in more
92 than one place.
93
94 =over 4
95
96 =item Functions for SCALARs or strings
97
98 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
99 C<length>, C<oct>, C<ord>, C<pack>, C<q/STRING/>, C<qq/STRING/>, C<reverse>,
100 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
101
102 =item Regular expressions and pattern matching
103
104 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
105
106 =item Numeric functions
107
108 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
109 C<sin>, C<sqrt>, C<srand>
110
111 =item Functions for real @ARRAYs
112
113 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
114
115 =item Functions for list data
116
117 C<grep>, C<join>, C<map>, C<qw/STRING/>, C<reverse>, C<sort>, C<unpack>
118
119 =item Functions for real %HASHes
120
121 C<delete>, C<each>, C<exists>, C<keys>, C<values>
122
123 =item Input and output functions
124
125 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
126 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
127 C<readdir>, C<rewinddir>, C<seek>, C<seekdir>, C<select>, C<syscall>,
128 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
129 C<warn>, C<write>
130
131 =item Functions for fixed length data or records
132
133 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
134
135 =item Functions for filehandles, files, or directories
136
137 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
138 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
139 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<umask>,
140 C<unlink>, C<utime>
141
142 =item Keywords related to the control flow of your perl program
143
144 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
145 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
146
147 =item Keywords related to scoping
148
149 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<use>
150
151 =item Miscellaneous functions
152
153 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>, C<reset>,
154 C<scalar>, C<undef>, C<wantarray>
155
156 =item Functions for processes and process groups
157
158 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
159 C<pipe>, C<qx/STRING/>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
160 C<times>, C<wait>, C<waitpid>
161
162 =item Keywords related to perl modules
163
164 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
165
166 =item Keywords related to classes and object-orientedness
167
168 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
169 C<untie>, C<use>
170
171 =item Low-level socket functions
172
173 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
174 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
175 C<sockatmark>, C<socket>, C<socketpair>
176
177 =item System V interprocess communication functions
178
179 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
180 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
181
182 =item Fetching user and group info
183
184 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
185 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
186 C<getpwuid>, C<setgrent>, C<setpwent>
187
188 =item Fetching network info
189
190 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
191 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
192 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
193 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
194 C<setnetent>, C<setprotoent>, C<setservent>
195
196 =item Time-related functions
197
198 C<gmtime>, C<localtime>, C<time>, C<times>
199
200 =item Functions new in perl5
201
202 C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>,
203 C<import>, C<lc>, C<lcfirst>, C<map>, C<my>, C<no>, C<our>, C<prototype>,
204 C<qx>, C<qw>, C<readline>, C<readpipe>, C<ref>, C<sub*>, C<sysopen>, C<tie>,
205 C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use>
206
207 * - C<sub> was a keyword in perl4, but in perl5 it is an
208 operator, which can be used in expressions.
209
210 =item Functions obsoleted in perl5
211
212 C<dbmclose>, C<dbmopen>
213
214 =back
215
216 =head2 Portability
217
218 Perl was born in Unix and can therefore access all common Unix
219 system calls.  In non-Unix environments, the functionality of some
220 Unix system calls may not be available, or details of the available
221 functionality may differ slightly.  The Perl functions affected
222 by this are:
223
224 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
225 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
226 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
227 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostent>,
228 C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
229 C<getppid>, C<getprgp>, C<getpriority>, C<getprotobynumber>,
230 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
231 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
232 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
233 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
234 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
235 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
236 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
237 C<shmwrite>, C<sockatmark>, C<socket>, C<socketpair>,
238 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
239 C<times>, C<truncate>, C<umask>, C<unlink>,
240 C<utime>, C<wait>, C<waitpid>
241
242 For more information about the portability of these functions, see
243 L<perlport> and other available platform-specific documentation.
244
245 =head2 Alphabetical Listing of Perl Functions
246
247 =over 8
248
249 =item I<-X> FILEHANDLE
250
251 =item I<-X> EXPR
252
253 =item I<-X>
254
255 A file test, where X is one of the letters listed below.  This unary
256 operator takes one argument, either a filename or a filehandle, and
257 tests the associated file to see if something is true about it.  If the
258 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
259 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
260 the undefined value if the file doesn't exist.  Despite the funny
261 names, precedence is the same as any other named unary operator, and
262 the argument may be parenthesized like any other unary operator.  The
263 operator may be any of:
264 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
265 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
266
267     -r  File is readable by effective uid/gid.
268     -w  File is writable by effective uid/gid.
269     -x  File is executable by effective uid/gid.
270     -o  File is owned by effective uid.
271
272     -R  File is readable by real uid/gid.
273     -W  File is writable by real uid/gid.
274     -X  File is executable by real uid/gid.
275     -O  File is owned by real uid.
276
277     -e  File exists.
278     -z  File has zero size (is empty).
279     -s  File has nonzero size (returns size in bytes).
280
281     -f  File is a plain file.
282     -d  File is a directory.
283     -l  File is a symbolic link.
284     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
285     -S  File is a socket.
286     -b  File is a block special file.
287     -c  File is a character special file.
288     -t  Filehandle is opened to a tty.
289
290     -u  File has setuid bit set.
291     -g  File has setgid bit set.
292     -k  File has sticky bit set.
293
294     -T  File is an ASCII text file (heuristic guess).
295     -B  File is a "binary" file (opposite of -T).
296
297     -M  Script start time minus file modification time, in days.
298     -A  Same for access time.
299     -C  Same for inode change time (Unix, may differ for other platforms)
300
301 Example:
302
303     while (<>) {
304         chomp;
305         next unless -f $_;      # ignore specials
306         #...
307     }
308
309 The interpretation of the file permission operators C<-r>, C<-R>,
310 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
311 of the file and the uids and gids of the user.  There may be other
312 reasons you can't actually read, write, or execute the file.  Such
313 reasons may be for example network filesystem access controls, ACLs
314 (access control lists), read-only filesystems, and unrecognized
315 executable formats.
316
317 Also note that, for the superuser on the local filesystems, the C<-r>,
318 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
319 if any execute bit is set in the mode.  Scripts run by the superuser
320 may thus need to do a stat() to determine the actual mode of the file,
321 or temporarily set their effective uid to something else.
322
323 If you are using ACLs, there is a pragma called C<filetest> that may
324 produce more accurate results than the bare stat() mode bits.
325 When under the C<use filetest 'access'> the above-mentioned filetests
326 will test whether the permission can (not) be granted using the
327 access() family of system calls.  Also note that the C<-x> and C<-X> may
328 under this pragma return true even if there are no execute permission
329 bits set (nor any extra execute permission ACLs).  This strangeness is
330 due to the underlying system calls' definitions.  Read the
331 documentation for the C<filetest> pragma for more information.
332
333 Note that C<-s/a/b/> does not do a negated substitution.  Saying
334 C<-exp($foo)> still works as expected, however--only single letters
335 following a minus are interpreted as file tests.
336
337 The C<-T> and C<-B> switches work as follows.  The first block or so of the
338 file is examined for odd characters such as strange control codes or
339 characters with the high bit set.  If too many strange characters (>30%)
340 are found, it's a C<-B> file, otherwise it's a C<-T> file.  Also, any file
341 containing null in the first block is considered a binary file.  If C<-T>
342 or C<-B> is used on a filehandle, the current IO buffer is examined
343 rather than the first block.  Both C<-T> and C<-B> return true on a null
344 file, or a file at EOF when testing a filehandle.  Because you have to
345 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
346 against the file first, as in C<next unless -f $file && -T $file>.
347
348 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
349 the special filehandle consisting of a solitary underline, then the stat
350 structure of the previous file test (or stat operator) is used, saving
351 a system call.  (This doesn't work with C<-t>, and you need to remember
352 that lstat() and C<-l> will leave values in the stat structure for the
353 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
354 a C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
355 Example:
356
357     print "Can do.\n" if -r $a || -w _ || -x _;
358
359     stat($filename);
360     print "Readable\n" if -r _;
361     print "Writable\n" if -w _;
362     print "Executable\n" if -x _;
363     print "Setuid\n" if -u _;
364     print "Setgid\n" if -g _;
365     print "Sticky\n" if -k _;
366     print "Text\n" if -T _;
367     print "Binary\n" if -B _;
368
369 =item abs VALUE
370
371 =item abs
372
373 Returns the absolute value of its argument.
374 If VALUE is omitted, uses C<$_>.
375
376 =item accept NEWSOCKET,GENERICSOCKET
377
378 Accepts an incoming socket connect, just as the accept(2) system call
379 does.  Returns the packed address if it succeeded, false otherwise.
380 See the example in L<perlipc/"Sockets: Client/Server Communication">.
381
382 On systems that support a close-on-exec flag on files, the flag will
383 be set for the newly opened file descriptor, as determined by the
384 value of $^F.  See L<perlvar/$^F>.
385
386 =item alarm SECONDS
387
388 =item alarm
389
390 Arranges to have a SIGALRM delivered to this process after the
391 specified number of wallclock seconds have elapsed.  If SECONDS is not
392 specified, the value stored in C<$_> is used. (On some machines,
393 unfortunately, the elapsed time may be up to one second less or more
394 than you specified because of how seconds are counted, and process
395 scheduling may delay the delivery of the signal even further.)
396
397 Only one timer may be counting at once.  Each call disables the
398 previous timer, and an argument of C<0> may be supplied to cancel the
399 previous timer without starting a new one.  The returned value is the
400 amount of time remaining on the previous timer.
401
402 For delays of finer granularity than one second, you may use Perl's
403 four-argument version of select() leaving the first three arguments
404 undefined, or you might be able to use the C<syscall> interface to
405 access setitimer(2) if your system supports it.  The Time::HiRes
406 module (from CPAN, and starting from Perl 5.8 part of the standard
407 distribution) may also prove useful.
408
409 It is usually a mistake to intermix C<alarm> and C<sleep> calls.
410 (C<sleep> may be internally implemented in your system with C<alarm>)
411
412 If you want to use C<alarm> to time out a system call you need to use an
413 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
414 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
415 restart system calls on some systems.  Using C<eval>/C<die> always works,
416 modulo the caveats given in L<perlipc/"Signals">.
417
418     eval {
419         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
420         alarm $timeout;
421         $nread = sysread SOCKET, $buffer, $size;
422         alarm 0;
423     };
424     if ($@) {
425         die unless $@ eq "alarm\n";   # propagate unexpected errors
426         # timed out
427     }
428     else {
429         # didn't
430     }
431
432 =item atan2 Y,X
433
434 Returns the arctangent of Y/X in the range -PI to PI.
435
436 For the tangent operation, you may use the C<Math::Trig::tan>
437 function, or use the familiar relation:
438
439     sub tan { sin($_[0]) / cos($_[0])  }
440
441 =item bind SOCKET,NAME
442
443 Binds a network address to a socket, just as the bind system call
444 does.  Returns true if it succeeded, false otherwise.  NAME should be a
445 packed address of the appropriate type for the socket.  See the examples in
446 L<perlipc/"Sockets: Client/Server Communication">.
447
448 =item binmode FILEHANDLE, DISCIPLINE
449
450 =item binmode FILEHANDLE
451
452 Arranges for FILEHANDLE to be read or written in "binary" or "text" mode
453 on systems where the run-time libraries distinguish between binary and
454 text files.  If FILEHANDLE is an expression, the value is taken as the
455 name of the filehandle.  DISCIPLINE can be either of C<:raw> for
456 binary mode or C<:crlf> for "text" mode.  If the DISCIPLINE is
457 omitted, it defaults to C<:raw>.  Returns true on success, C<undef> on
458 failure.  The C<:raw> are C<:clrf>, and any other directives of the
459 form C<:...>, are called I/O I<disciplines>.
460
461 The C<open> pragma can be used to establish default I/O disciplines.
462 See L<open>.
463
464 In general, binmode() should be called after open() but before any I/O
465 is done on the filehandle.  Calling binmode() will flush any possibly
466 pending buffered input or output data on the handle.  The only
467 exception to this is the C<:encoding> discipline that changes
468 the default character encoding of the handle, see L<open>.
469 The C<:encoding> discipline sometimes needs to be called in
470 mid-stream, and it doesn't flush the stream.
471
472 On some systems binmode() is necessary when you're not working with a
473 text file.  For the sake of portability it is a good idea to always use
474 it when appropriate, and to never use it when it isn't appropriate.
475
476 In other words:  Regardless of platform, use binmode() on binary
477 files, and do not use binmode() on text files.
478
479 The operating system, device drivers, C libraries, and Perl run-time
480 system all work together to let the programmer treat a single
481 character (C<\n>) as the line terminator, irrespective of the external
482 representation.  On many operating systems, the native text file
483 representation matches the internal representation, but on some
484 platforms the external representation of C<\n> is made up of more than
485 one character.
486
487 Mac OS, all variants of Unix, and Stream_LF files on VMS use a single
488 character to end each line in the external representation of text (even
489 though that single character is CARRIAGE RETURN on Mac OS and LINE FEED
490 on Unix and most VMS files).  Consequently binmode() has no effect on
491 these operating systems.  In other systems like OS/2, DOS and the various
492 flavors of MS-Windows your program sees a C<\n> as a simple C<\cJ>, but
493 what's stored in text files are the two characters C<\cM\cJ>.  That means
494 that, if you don't use binmode() on these systems, C<\cM\cJ> sequences on
495 disk will be converted to C<\n> on input, and any C<\n> in your program
496 will be converted back to C<\cM\cJ> on output.  This is what you want for
497 text files, but it can be disastrous for binary files.
498
499 Another consequence of using binmode() (on some systems) is that
500 special end-of-file markers will be seen as part of the data stream.
501 For systems from the Microsoft family this means that if your binary
502 data contains C<\cZ>, the I/O subsystem will regard it as the end of
503 the file, unless you use binmode().
504
505 binmode() is not only important for readline() and print() operations,
506 but also when using read(), seek(), sysread(), syswrite() and tell()
507 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
508 in L<perlvar> for how to manually set your input and output
509 line-termination sequences.
510
511 =item bless REF,CLASSNAME
512
513 =item bless REF
514
515 This function tells the thingy referenced by REF that it is now an object
516 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
517 is used.  Because a C<bless> is often the last thing in a constructor,
518 it returns the reference for convenience.  Always use the two-argument
519 version if the function doing the blessing might be inherited by a
520 derived class.  See L<perltoot> and L<perlobj> for more about the blessing
521 (and blessings) of objects.
522
523 Consider always blessing objects in CLASSNAMEs that are mixed case.
524 Namespaces with all lowercase names are considered reserved for
525 Perl pragmata.  Builtin types have all uppercase names, so to prevent
526 confusion, you may wish to avoid such package names as well.  Make sure
527 that CLASSNAME is a true value.
528
529 See L<perlmod/"Perl Modules">.
530
531 =item caller EXPR
532
533 =item caller
534
535 Returns the context of the current subroutine call.  In scalar context,
536 returns the caller's package name if there is a caller, that is, if
537 we're in a subroutine or C<eval> or C<require>, and the undefined value
538 otherwise.  In list context, returns
539
540     ($package, $filename, $line) = caller;
541
542 With EXPR, it returns some extra information that the debugger uses to
543 print a stack trace.  The value of EXPR indicates how many call frames
544 to go back before the current one.
545
546     ($package, $filename, $line, $subroutine, $hasargs,
547     $wantarray, $evaltext, $is_require, $hints, $bitmask) = caller($i);
548
549 Here $subroutine may be C<(eval)> if the frame is not a subroutine
550 call, but an C<eval>.  In such a case additional elements $evaltext and
551 C<$is_require> are set: C<$is_require> is true if the frame is created by a
552 C<require> or C<use> statement, $evaltext contains the text of the
553 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
554 $filename is C<(eval)>, but $evaltext is undefined.  (Note also that
555 each C<use> statement creates a C<require> frame inside an C<eval EXPR>)
556 frame.  C<$hasargs> is true if a new instance of C<@_> was set up for the
557 frame.  C<$hints> and C<$bitmask> contain pragmatic hints that the caller
558 was compiled with.  The C<$hints> and C<$bitmask> values are subject to
559 change between versions of Perl, and are not meant for external use.
560
561 Furthermore, when called from within the DB package, caller returns more
562 detailed information: it sets the list variable C<@DB::args> to be the
563 arguments with which the subroutine was invoked.
564
565 Be aware that the optimizer might have optimized call frames away before
566 C<caller> had a chance to get the information.  That means that C<caller(N)>
567 might not return information about the call frame you expect it do, for
568 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
569 previous time C<caller> was called.
570
571 =item chdir EXPR
572
573 Changes the working directory to EXPR, if possible. If EXPR is omitted,
574 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
575 changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the
576 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If
577 neither is set, C<chdir> does nothing. It returns true upon success,
578 false otherwise. See the example under C<die>.
579
580 =item chmod LIST
581
582 Changes the permissions of a list of files.  The first element of the
583 list must be the numerical mode, which should probably be an octal
584 number, and which definitely should I<not> a string of octal digits:
585 C<0644> is okay, C<'0644'> is not.  Returns the number of files
586 successfully changed.  See also L</oct>, if all you have is a string.
587
588     $cnt = chmod 0755, 'foo', 'bar';
589     chmod 0755, @executables;
590     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
591                                              # --w----r-T
592     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
593     $mode = 0644;   chmod $mode, 'foo';      # this is best
594
595 You can also import the symbolic C<S_I*> constants from the Fcntl
596 module:
597
598     use Fcntl ':mode';
599
600     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
601     # This is identical to the chmod 0755 of the above example.
602
603 =item chomp VARIABLE
604
605 =item chomp( LIST )
606
607 =item chomp
608
609 This safer version of L</chop> removes any trailing string
610 that corresponds to the current value of C<$/> (also known as
611 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
612 number of characters removed from all its arguments.  It's often used to
613 remove the newline from the end of an input record when you're worried
614 that the final record may be missing its newline.  When in paragraph
615 mode (C<$/ = "">), it removes all trailing newlines from the string.
616 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
617 a reference to an integer or the like, see L<perlvar>) chomp() won't
618 remove anything.
619 If VARIABLE is omitted, it chomps C<$_>.  Example:
620
621     while (<>) {
622         chomp;  # avoid \n on last field
623         @array = split(/:/);
624         # ...
625     }
626
627 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
628
629 You can actually chomp anything that's an lvalue, including an assignment:
630
631     chomp($cwd = `pwd`);
632     chomp($answer = <STDIN>);
633
634 If you chomp a list, each element is chomped, and the total number of
635 characters removed is returned.
636
637 =item chop VARIABLE
638
639 =item chop( LIST )
640
641 =item chop
642
643 Chops off the last character of a string and returns the character
644 chopped.  It is much more efficient than C<s/.$//s> because it neither
645 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
646 If VARIABLE is a hash, it chops the hash's values, but not its keys.
647
648 You can actually chop anything that's an lvalue, including an assignment.
649
650 If you chop a list, each element is chopped.  Only the value of the
651 last C<chop> is returned.
652
653 Note that C<chop> returns the last character.  To return all but the last
654 character, use C<substr($string, 0, -1)>.
655
656 =item chown LIST
657
658 Changes the owner (and group) of a list of files.  The first two
659 elements of the list must be the I<numeric> uid and gid, in that
660 order.  A value of -1 in either position is interpreted by most
661 systems to leave that value unchanged.  Returns the number of files
662 successfully changed.
663
664     $cnt = chown $uid, $gid, 'foo', 'bar';
665     chown $uid, $gid, @filenames;
666
667 Here's an example that looks up nonnumeric uids in the passwd file:
668
669     print "User: ";
670     chomp($user = <STDIN>);
671     print "Files: ";
672     chomp($pattern = <STDIN>);
673
674     ($login,$pass,$uid,$gid) = getpwnam($user)
675         or die "$user not in passwd file";
676
677     @ary = glob($pattern);      # expand filenames
678     chown $uid, $gid, @ary;
679
680 On most systems, you are not allowed to change the ownership of the
681 file unless you're the superuser, although you should be able to change
682 the group to any of your secondary groups.  On insecure systems, these
683 restrictions may be relaxed, but this is not a portable assumption.
684 On POSIX systems, you can detect this condition this way:
685
686     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
687     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
688
689 =item chr NUMBER
690
691 =item chr
692
693 Returns the character represented by that NUMBER in the character set.
694 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
695 chr(0x263a) is a Unicode smiley face.  Note that characters from 127
696 to 255 (inclusive) are by default not encoded in Unicode for backward
697 compatibility reasons (but see L<encoding>).
698
699 For the reverse, use L</ord>.
700 See L<perlunicode> and L<encoding> for more about Unicode.
701
702 If NUMBER is omitted, uses C<$_>.
703
704 =item chroot FILENAME
705
706 =item chroot
707
708 This function works like the system call by the same name: it makes the
709 named directory the new root directory for all further pathnames that
710 begin with a C</> by your process and all its children.  (It doesn't
711 change your current working directory, which is unaffected.)  For security
712 reasons, this call is restricted to the superuser.  If FILENAME is
713 omitted, does a C<chroot> to C<$_>.
714
715 =item close FILEHANDLE
716
717 =item close
718
719 Closes the file or pipe associated with the file handle, returning
720 true only if IO buffers are successfully flushed and closes the system
721 file descriptor.  Closes the currently selected filehandle if the
722 argument is omitted.
723
724 You don't have to close FILEHANDLE if you are immediately going to do
725 another C<open> on it, because C<open> will close it for you.  (See
726 C<open>.)  However, an explicit C<close> on an input file resets the line
727 counter (C<$.>), while the implicit close done by C<open> does not.
728
729 If the file handle came from a piped open C<close> will additionally
730 return false if one of the other system calls involved fails or if the
731 program exits with non-zero status.  (If the only problem was that the
732 program exited non-zero C<$!> will be set to C<0>.)  Closing a pipe
733 also waits for the process executing on the pipe to complete, in case you
734 want to look at the output of the pipe afterwards, and
735 implicitly puts the exit status value of that command into C<$?>.
736
737 Prematurely closing the read end of a pipe (i.e. before the process
738 writing to it at the other end has closed it) will result in a
739 SIGPIPE being delivered to the writer.  If the other end can't
740 handle that, be sure to read all the data before closing the pipe.
741
742 Example:
743
744     open(OUTPUT, '|sort >foo')  # pipe to sort
745         or die "Can't start sort: $!";
746     #...                        # print stuff to output
747     close OUTPUT                # wait for sort to finish
748         or warn $! ? "Error closing sort pipe: $!"
749                    : "Exit status $? from sort";
750     open(INPUT, 'foo')          # get sort's results
751         or die "Can't open 'foo' for input: $!";
752
753 FILEHANDLE may be an expression whose value can be used as an indirect
754 filehandle, usually the real filehandle name.
755
756 =item closedir DIRHANDLE
757
758 Closes a directory opened by C<opendir> and returns the success of that
759 system call.
760
761 DIRHANDLE may be an expression whose value can be used as an indirect
762 dirhandle, usually the real dirhandle name.
763
764 =item connect SOCKET,NAME
765
766 Attempts to connect to a remote socket, just as the connect system call
767 does.  Returns true if it succeeded, false otherwise.  NAME should be a
768 packed address of the appropriate type for the socket.  See the examples in
769 L<perlipc/"Sockets: Client/Server Communication">.
770
771 =item continue BLOCK
772
773 Actually a flow control statement rather than a function.  If there is a
774 C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
775 C<foreach>), it is always executed just before the conditional is about to
776 be evaluated again, just like the third part of a C<for> loop in C.  Thus
777 it can be used to increment a loop variable, even when the loop has been
778 continued via the C<next> statement (which is similar to the C C<continue>
779 statement).
780
781 C<last>, C<next>, or C<redo> may appear within a C<continue>
782 block.  C<last> and C<redo> will behave as if they had been executed within
783 the main block.  So will C<next>, but since it will execute a C<continue>
784 block, it may be more entertaining.
785
786     while (EXPR) {
787         ### redo always comes here
788         do_something;
789     } continue {
790         ### next always comes here
791         do_something_else;
792         # then back the top to re-check EXPR
793     }
794     ### last always comes here
795
796 Omitting the C<continue> section is semantically equivalent to using an
797 empty one, logically enough.  In that case, C<next> goes directly back
798 to check the condition at the top of the loop.
799
800 =item cos EXPR
801
802 =item cos
803
804 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
805 takes cosine of C<$_>.
806
807 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
808 function, or use this relation:
809
810     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
811
812 =item crypt PLAINTEXT,SALT
813
814 Encrypts a string exactly like the crypt(3) function in the C library
815 (assuming that you actually have a version there that has not been
816 extirpated as a potential munition).  This can prove useful for checking
817 the password file for lousy passwords, amongst other things.  Only the
818 guys wearing white hats should do this.
819
820 Note that C<crypt> is intended to be a one-way function, much like
821 breaking eggs to make an omelette.  There is no (known) corresponding
822 decrypt function (in other words, the crypt() is a one-way hash
823 function).  As a result, this function isn't all that useful for
824 cryptography.  (For that, see your nearby CPAN mirror.)
825
826 When verifying an existing encrypted string you should use the
827 encrypted text as the salt (like C<crypt($plain, $crypted) eq
828 $crypted>).  This allows your code to work with the standard C<crypt>
829 and with more exotic implementations.  In other words, do not assume
830 anything about the returned string itself, or how many bytes in
831 the encrypted string matter.
832
833 Traditionally the result is a string of 13 bytes: two first bytes of
834 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
835 the first eight bytes of the encrypted string mattered, but
836 alternative hashing schemes (like MD5), higher level security schemes
837 (like C2), and implementations on non-UNIX platforms may produce
838 different strings.
839
840 When choosing a new salt create a random two character string whose
841 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
842 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).
843
844 Here's an example that makes sure that whoever runs this program knows
845 their own password:
846
847     $pwd = (getpwuid($<))[1];
848
849     system "stty -echo";
850     print "Password: ";
851     chomp($word = <STDIN>);
852     print "\n";
853     system "stty echo";
854
855     if (crypt($word, $pwd) ne $pwd) {
856         die "Sorry...\n";
857     } else {
858         print "ok\n";
859     }
860
861 Of course, typing in your own password to whoever asks you
862 for it is unwise.
863
864 The L<crypt> function is unsuitable for encrypting large quantities
865 of data, not least of all because you can't get the information
866 back.  Look at the F<by-module/Crypt> and F<by-module/PGP> directories
867 on your favorite CPAN mirror for a slew of potentially useful
868 modules.
869
870 If using crypt() on a Unicode string (which I<potentially> has
871 characters with codepoints above 255), Perl tries to make sense
872 of the situation by trying to downgrade (a copy of the string)
873 the string back to an eight-bit byte string before calling crypt()
874 (on that copy).  If that works, good.  If not, crypt() dies with
875 C<Wide character in crypt>.
876
877 =item dbmclose HASH
878
879 [This function has been largely superseded by the C<untie> function.]
880
881 Breaks the binding between a DBM file and a hash.
882
883 =item dbmopen HASH,DBNAME,MASK
884
885 [This function has been largely superseded by the C<tie> function.]
886
887 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
888 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
889 argument is I<not> a filehandle, even though it looks like one).  DBNAME
890 is the name of the database (without the F<.dir> or F<.pag> extension if
891 any).  If the database does not exist, it is created with protection
892 specified by MASK (as modified by the C<umask>).  If your system supports
893 only the older DBM functions, you may perform only one C<dbmopen> in your
894 program.  In older versions of Perl, if your system had neither DBM nor
895 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
896 sdbm(3).
897
898 If you don't have write access to the DBM file, you can only read hash
899 variables, not set them.  If you want to test whether you can write,
900 either use file tests or try setting a dummy hash entry inside an C<eval>,
901 which will trap the error.
902
903 Note that functions such as C<keys> and C<values> may return huge lists
904 when used on large DBM files.  You may prefer to use the C<each>
905 function to iterate over large DBM files.  Example:
906
907     # print out history file offsets
908     dbmopen(%HIST,'/usr/lib/news/history',0666);
909     while (($key,$val) = each %HIST) {
910         print $key, ' = ', unpack('L',$val), "\n";
911     }
912     dbmclose(%HIST);
913
914 See also L<AnyDBM_File> for a more general description of the pros and
915 cons of the various dbm approaches, as well as L<DB_File> for a particularly
916 rich implementation.
917
918 You can control which DBM library you use by loading that library
919 before you call dbmopen():
920
921     use DB_File;
922     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
923         or die "Can't open netscape history file: $!";
924
925 =item defined EXPR
926
927 =item defined
928
929 Returns a Boolean value telling whether EXPR has a value other than
930 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
931 checked.
932
933 Many operations return C<undef> to indicate failure, end of file,
934 system error, uninitialized variable, and other exceptional
935 conditions.  This function allows you to distinguish C<undef> from
936 other values.  (A simple Boolean test will not distinguish among
937 C<undef>, zero, the empty string, and C<"0">, which are all equally
938 false.)  Note that since C<undef> is a valid scalar, its presence
939 doesn't I<necessarily> indicate an exceptional condition: C<pop>
940 returns C<undef> when its argument is an empty array, I<or> when the
941 element to return happens to be C<undef>.
942
943 You may also use C<defined(&func)> to check whether subroutine C<&func>
944 has ever been defined.  The return value is unaffected by any forward
945 declarations of C<&foo>.  Note that a subroutine which is not defined
946 may still be callable: its package may have an C<AUTOLOAD> method that
947 makes it spring into existence the first time that it is called -- see
948 L<perlsub>.
949
950 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
951 used to report whether memory for that aggregate has ever been
952 allocated.  This behavior may disappear in future versions of Perl.
953 You should instead use a simple test for size:
954
955     if (@an_array) { print "has array elements\n" }
956     if (%a_hash)   { print "has hash members\n"   }
957
958 When used on a hash element, it tells you whether the value is defined,
959 not whether the key exists in the hash.  Use L</exists> for the latter
960 purpose.
961
962 Examples:
963
964     print if defined $switch{'D'};
965     print "$val\n" while defined($val = pop(@ary));
966     die "Can't readlink $sym: $!"
967         unless defined($value = readlink $sym);
968     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
969     $debugging = 0 unless defined $debugging;
970
971 Note:  Many folks tend to overuse C<defined>, and then are surprised to
972 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
973 defined values.  For example, if you say
974
975     "ab" =~ /a(.*)b/;
976
977 The pattern match succeeds, and C<$1> is defined, despite the fact that it
978 matched "nothing".  But it didn't really match nothing--rather, it
979 matched something that happened to be zero characters long.  This is all
980 very above-board and honest.  When a function returns an undefined value,
981 it's an admission that it couldn't give you an honest answer.  So you
982 should use C<defined> only when you're questioning the integrity of what
983 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
984 what you want.
985
986 See also L</undef>, L</exists>, L</ref>.
987
988 =item delete EXPR
989
990 Given an expression that specifies a hash element, array element, hash slice,
991 or array slice, deletes the specified element(s) from the hash or array.
992 In the case of an array, if the array elements happen to be at the end,
993 the size of the array will shrink to the highest element that tests
994 true for exists() (or 0 if no such element exists).
995
996 Returns each element so deleted or the undefined value if there was no such
997 element.  Deleting from C<$ENV{}> modifies the environment.  Deleting from
998 a hash tied to a DBM file deletes the entry from the DBM file.  Deleting
999 from a C<tie>d hash or array may not necessarily return anything.
1000
1001 Deleting an array element effectively returns that position of the array
1002 to its initial, uninitialized state.  Subsequently testing for the same
1003 element with exists() will return false.  Note that deleting array
1004 elements in the middle of an array will not shift the index of the ones
1005 after them down--use splice() for that.  See L</exists>.
1006
1007 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1008
1009     foreach $key (keys %HASH) {
1010         delete $HASH{$key};
1011     }
1012
1013     foreach $index (0 .. $#ARRAY) {
1014         delete $ARRAY[$index];
1015     }
1016
1017 And so do these:
1018
1019     delete @HASH{keys %HASH};
1020
1021     delete @ARRAY[0 .. $#ARRAY];
1022
1023 But both of these are slower than just assigning the empty list
1024 or undefining %HASH or @ARRAY:
1025
1026     %HASH = ();         # completely empty %HASH
1027     undef %HASH;        # forget %HASH ever existed
1028
1029     @ARRAY = ();        # completely empty @ARRAY
1030     undef @ARRAY;       # forget @ARRAY ever existed
1031
1032 Note that the EXPR can be arbitrarily complicated as long as the final
1033 operation is a hash element, array element,  hash slice, or array slice
1034 lookup:
1035
1036     delete $ref->[$x][$y]{$key};
1037     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1038
1039     delete $ref->[$x][$y][$index];
1040     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1041
1042 =item die LIST
1043
1044 Outside an C<eval>, prints the value of LIST to C<STDERR> and
1045 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
1046 exits with the value of C<<< ($? >> 8) >>> (backtick `command`
1047 status).  If C<<< ($? >> 8) >>> is C<0>, exits with C<255>.  Inside
1048 an C<eval(),> the error message is stuffed into C<$@> and the
1049 C<eval> is terminated with the undefined value.  This makes
1050 C<die> the way to raise an exception.
1051
1052 Equivalent examples:
1053
1054     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1055     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1056
1057 If the last element of LIST does not end in a newline, the current
1058 script line number and input line number (if any) are also printed,
1059 and a newline is supplied.  Note that the "input line number" (also
1060 known as "chunk") is subject to whatever notion of "line" happens to
1061 be currently in effect, and is also available as the special variable
1062 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1063
1064 Hint: sometimes appending C<", stopped"> to your message will cause it
1065 to make better sense when the string C<"at foo line 123"> is appended.
1066 Suppose you are running script "canasta".
1067
1068     die "/etc/games is no good";
1069     die "/etc/games is no good, stopped";
1070
1071 produce, respectively
1072
1073     /etc/games is no good at canasta line 123.
1074     /etc/games is no good, stopped at canasta line 123.
1075
1076 See also exit(), warn(), and the Carp module.
1077
1078 If LIST is empty and C<$@> already contains a value (typically from a
1079 previous eval) that value is reused after appending C<"\t...propagated">.
1080 This is useful for propagating exceptions:
1081
1082     eval { ... };
1083     die unless $@ =~ /Expected exception/;
1084
1085 If LIST is empty and C<$@> contains an object reference that has a
1086 C<PROPAGATE> method, that method will be called with additional file
1087 and line number parameters.  The return value replaces the value in
1088 C<$@>.  ie. as if C<<$@ = eval { $@->PROPAGATE(__FILE__, __LINE__) };>> 
1089 were called.
1090
1091 If C<$@> is empty then the string C<"Died"> is used.
1092
1093 die() can also be called with a reference argument.  If this happens to be
1094 trapped within an eval(), $@ contains the reference.  This behavior permits
1095 a more elaborate exception handling implementation using objects that
1096 maintain arbitrary state about the nature of the exception.  Such a scheme
1097 is sometimes preferable to matching particular string values of $@ using
1098 regular expressions.  Here's an example:
1099
1100     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1101     if ($@) {
1102         if (ref($@) && UNIVERSAL::isa($@,"Some::Module::Exception")) {
1103             # handle Some::Module::Exception
1104         }
1105         else {
1106             # handle all other possible exceptions
1107         }
1108     }
1109
1110 Because perl will stringify uncaught exception messages before displaying
1111 them, you may want to overload stringification operations on such custom
1112 exception objects.  See L<overload> for details about that.
1113
1114 You can arrange for a callback to be run just before the C<die>
1115 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1116 handler will be called with the error text and can change the error
1117 message, if it sees fit, by calling C<die> again.  See
1118 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1119 L<"eval BLOCK"> for some examples.  Although this feature was meant
1120 to be run only right before your program was to exit, this is not
1121 currently the case--the C<$SIG{__DIE__}> hook is currently called
1122 even inside eval()ed blocks/strings!  If one wants the hook to do
1123 nothing in such situations, put
1124
1125         die @_ if $^S;
1126
1127 as the first line of the handler (see L<perlvar/$^S>).  Because
1128 this promotes strange action at a distance, this counterintuitive
1129 behavior may be fixed in a future release.
1130
1131 =item do BLOCK
1132
1133 Not really a function.  Returns the value of the last command in the
1134 sequence of commands indicated by BLOCK.  When modified by a loop
1135 modifier, executes the BLOCK once before testing the loop condition.
1136 (On other statements the loop modifiers test the conditional first.)
1137
1138 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1139 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1140 See L<perlsyn> for alternative strategies.
1141
1142 =item do SUBROUTINE(LIST)
1143
1144 A deprecated form of subroutine call.  See L<perlsub>.
1145
1146 =item do EXPR
1147
1148 Uses the value of EXPR as a filename and executes the contents of the
1149 file as a Perl script.  Its primary use is to include subroutines
1150 from a Perl subroutine library.
1151
1152     do 'stat.pl';
1153
1154 is just like
1155
1156     eval `cat stat.pl`;
1157
1158 except that it's more efficient and concise, keeps track of the current
1159 filename for error messages, searches the @INC libraries, and updates
1160 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1161 variables.  It also differs in that code evaluated with C<do FILENAME>
1162 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1163 same, however, in that it does reparse the file every time you call it,
1164 so you probably don't want to do this inside a loop.
1165
1166 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1167 error.  If C<do> can read the file but cannot compile it, it
1168 returns undef and sets an error message in C<$@>.   If the file is
1169 successfully compiled, C<do> returns the value of the last expression
1170 evaluated.
1171
1172 Note that inclusion of library modules is better done with the
1173 C<use> and C<require> operators, which also do automatic error checking
1174 and raise an exception if there's a problem.
1175
1176 You might like to use C<do> to read in a program configuration
1177 file.  Manual error checking can be done this way:
1178
1179     # read in config files: system first, then user
1180     for $file ("/share/prog/defaults.rc",
1181                "$ENV{HOME}/.someprogrc")
1182    {
1183         unless ($return = do $file) {
1184             warn "couldn't parse $file: $@" if $@;
1185             warn "couldn't do $file: $!"    unless defined $return;
1186             warn "couldn't run $file"       unless $return;
1187         }
1188     }
1189
1190 =item dump LABEL
1191
1192 =item dump
1193
1194 This function causes an immediate core dump.  See also the B<-u>
1195 command-line switch in L<perlrun>, which does the same thing.
1196 Primarily this is so that you can use the B<undump> program (not
1197 supplied) to turn your core dump into an executable binary after
1198 having initialized all your variables at the beginning of the
1199 program.  When the new binary is executed it will begin by executing
1200 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1201 Think of it as a goto with an intervening core dump and reincarnation.
1202 If C<LABEL> is omitted, restarts the program from the top.
1203
1204 B<WARNING>: Any files opened at the time of the dump will I<not>
1205 be open any more when the program is reincarnated, with possible
1206 resulting confusion on the part of Perl.
1207
1208 This function is now largely obsolete, partly because it's very
1209 hard to convert a core file into an executable, and because the
1210 real compiler backends for generating portable bytecode and compilable
1211 C code have superseded it.  That's why you should now invoke it as
1212 C<CORE::dump()>, if you don't want to be warned against a possible
1213 typo.
1214
1215 If you're looking to use L<dump> to speed up your program, consider
1216 generating bytecode or native C code as described in L<perlcc>.  If
1217 you're just trying to accelerate a CGI script, consider using the
1218 C<mod_perl> extension to B<Apache>, or the CPAN module, CGI::Fast.
1219 You might also consider autoloading or selfloading, which at least
1220 make your program I<appear> to run faster.
1221
1222 =item each HASH
1223
1224 When called in list context, returns a 2-element list consisting of the
1225 key and value for the next element of a hash, so that you can iterate over
1226 it.  When called in scalar context, returns only the key for the next
1227 element in the hash.
1228
1229 Entries are returned in an apparently random order.  The actual random
1230 order is subject to change in future versions of perl, but it is guaranteed
1231 to be in the same order as either the C<keys> or C<values> function
1232 would produce on the same (unmodified) hash.
1233
1234 When the hash is entirely read, a null array is returned in list context
1235 (which when assigned produces a false (C<0>) value), and C<undef> in
1236 scalar context.  The next call to C<each> after that will start iterating
1237 again.  There is a single iterator for each hash, shared by all C<each>,
1238 C<keys>, and C<values> function calls in the program; it can be reset by
1239 reading all the elements from the hash, or by evaluating C<keys HASH> or
1240 C<values HASH>.  If you add or delete elements of a hash while you're
1241 iterating over it, you may get entries skipped or duplicated, so
1242 don't.  Exception: It is always safe to delete the item most recently
1243 returned by C<each()>, which means that the following code will work:
1244
1245         while (($key, $value) = each %hash) {
1246           print $key, "\n";
1247           delete $hash{$key};   # This is safe
1248         }
1249
1250 The following prints out your environment like the printenv(1) program,
1251 only in a different order:
1252
1253     while (($key,$value) = each %ENV) {
1254         print "$key=$value\n";
1255     }
1256
1257 See also C<keys>, C<values> and C<sort>.
1258
1259 =item eof FILEHANDLE
1260
1261 =item eof ()
1262
1263 =item eof
1264
1265 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1266 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1267 gives the real filehandle.  (Note that this function actually
1268 reads a character and then C<ungetc>s it, so isn't very useful in an
1269 interactive context.)  Do not read from a terminal file (or call
1270 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1271 as terminals may lose the end-of-file condition if you do.
1272
1273 An C<eof> without an argument uses the last file read.  Using C<eof()>
1274 with empty parentheses is very different.  It refers to the pseudo file
1275 formed from the files listed on the command line and accessed via the
1276 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1277 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1278 used will cause C<@ARGV> to be examined to determine if input is
1279 available.   Similarly, an C<eof()> after C<< <> >> has returned 
1280 end-of-file will assume you are processing another C<@ARGV> list,
1281 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1282 see L<perlop/"I/O Operators">.
1283
1284 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1285 detect the end of each file, C<eof()> will only detect the end of the
1286 last file.  Examples:
1287
1288     # reset line numbering on each input file
1289     while (<>) {
1290         next if /^\s*#/;        # skip comments
1291         print "$.\t$_";
1292     } continue {
1293         close ARGV  if eof;     # Not eof()!
1294     }
1295
1296     # insert dashes just before last line of last file
1297     while (<>) {
1298         if (eof()) {            # check for end of current file
1299             print "--------------\n";
1300             close(ARGV);        # close or last; is needed if we
1301                                 # are reading from the terminal
1302         }
1303         print;
1304     }
1305
1306 Practical hint: you almost never need to use C<eof> in Perl, because the
1307 input operators typically return C<undef> when they run out of data, or if
1308 there was an error.
1309
1310 =item eval EXPR
1311
1312 =item eval BLOCK
1313
1314 In the first form, the return value of EXPR is parsed and executed as if it
1315 were a little Perl program.  The value of the expression (which is itself
1316 determined within scalar context) is first parsed, and if there weren't any
1317 errors, executed in the lexical context of the current Perl program, so
1318 that any variable settings or subroutine and format definitions remain
1319 afterwards.  Note that the value is parsed every time the eval executes.
1320 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1321 delay parsing and subsequent execution of the text of EXPR until run time.
1322
1323 In the second form, the code within the BLOCK is parsed only once--at the
1324 same time the code surrounding the eval itself was parsed--and executed
1325 within the context of the current Perl program.  This form is typically
1326 used to trap exceptions more efficiently than the first (see below), while
1327 also providing the benefit of checking the code within BLOCK at compile
1328 time.
1329
1330 The final semicolon, if any, may be omitted from the value of EXPR or within
1331 the BLOCK.
1332
1333 In both forms, the value returned is the value of the last expression
1334 evaluated inside the mini-program; a return statement may be also used, just
1335 as with subroutines.  The expression providing the return value is evaluated
1336 in void, scalar, or list context, depending on the context of the eval itself.
1337 See L</wantarray> for more on how the evaluation context can be determined.
1338
1339 If there is a syntax error or runtime error, or a C<die> statement is
1340 executed, an undefined value is returned by C<eval>, and C<$@> is set to the
1341 error message.  If there was no error, C<$@> is guaranteed to be a null
1342 string.  Beware that using C<eval> neither silences perl from printing
1343 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1344 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1345 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1346 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1347
1348 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1349 determining whether a particular feature (such as C<socket> or C<symlink>)
1350 is implemented.  It is also Perl's exception trapping mechanism, where
1351 the die operator is used to raise exceptions.
1352
1353 If the code to be executed doesn't vary, you may use the eval-BLOCK
1354 form to trap run-time errors without incurring the penalty of
1355 recompiling each time.  The error, if any, is still returned in C<$@>.
1356 Examples:
1357
1358     # make divide-by-zero nonfatal
1359     eval { $answer = $a / $b; }; warn $@ if $@;
1360
1361     # same thing, but less efficient
1362     eval '$answer = $a / $b'; warn $@ if $@;
1363
1364     # a compile-time error
1365     eval { $answer = };                 # WRONG
1366
1367     # a run-time error
1368     eval '$answer =';   # sets $@
1369
1370 Due to the current arguably broken state of C<__DIE__> hooks, when using
1371 the C<eval{}> form as an exception trap in libraries, you may wish not
1372 to trigger any C<__DIE__> hooks that user code may have installed.
1373 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1374 as shown in this example:
1375
1376     # a very private exception trap for divide-by-zero
1377     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1378     warn $@ if $@;
1379
1380 This is especially significant, given that C<__DIE__> hooks can call
1381 C<die> again, which has the effect of changing their error messages:
1382
1383     # __DIE__ hooks may modify error messages
1384     {
1385        local $SIG{'__DIE__'} =
1386               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1387        eval { die "foo lives here" };
1388        print $@ if $@;                # prints "bar lives here"
1389     }
1390
1391 Because this promotes action at a distance, this counterintuitive behavior
1392 may be fixed in a future release.
1393
1394 With an C<eval>, you should be especially careful to remember what's
1395 being looked at when:
1396
1397     eval $x;            # CASE 1
1398     eval "$x";          # CASE 2
1399
1400     eval '$x';          # CASE 3
1401     eval { $x };        # CASE 4
1402
1403     eval "\$$x++";      # CASE 5
1404     $$x++;              # CASE 6
1405
1406 Cases 1 and 2 above behave identically: they run the code contained in
1407 the variable $x.  (Although case 2 has misleading double quotes making
1408 the reader wonder what else might be happening (nothing is).)  Cases 3
1409 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1410 does nothing but return the value of $x.  (Case 4 is preferred for
1411 purely visual reasons, but it also has the advantage of compiling at
1412 compile-time instead of at run-time.)  Case 5 is a place where
1413 normally you I<would> like to use double quotes, except that in this
1414 particular situation, you can just use symbolic references instead, as
1415 in case 6.
1416
1417 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1418 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1419
1420 =item exec LIST
1421
1422 =item exec PROGRAM LIST
1423
1424 The C<exec> function executes a system command I<and never returns>--
1425 use C<system> instead of C<exec> if you want it to return.  It fails and
1426 returns false only if the command does not exist I<and> it is executed
1427 directly instead of via your system's command shell (see below).
1428
1429 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1430 warns you if there is a following statement which isn't C<die>, C<warn>,
1431 or C<exit> (if C<-w> is set  -  but you always do that).   If you
1432 I<really> want to follow an C<exec> with some other statement, you
1433 can use one of these styles to avoid the warning:
1434
1435     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1436     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1437
1438 If there is more than one argument in LIST, or if LIST is an array
1439 with more than one value, calls execvp(3) with the arguments in LIST.
1440 If there is only one scalar argument or an array with one element in it,
1441 the argument is checked for shell metacharacters, and if there are any,
1442 the entire argument is passed to the system's command shell for parsing
1443 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1444 If there are no shell metacharacters in the argument, it is split into
1445 words and passed directly to C<execvp>, which is more efficient.
1446 Examples:
1447
1448     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1449     exec "sort $outfile | uniq";
1450
1451 If you don't really want to execute the first argument, but want to lie
1452 to the program you are executing about its own name, you can specify
1453 the program you actually want to run as an "indirect object" (without a
1454 comma) in front of the LIST.  (This always forces interpretation of the
1455 LIST as a multivalued list, even if there is only a single scalar in
1456 the list.)  Example:
1457
1458     $shell = '/bin/csh';
1459     exec $shell '-sh';          # pretend it's a login shell
1460
1461 or, more directly,
1462
1463     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1464
1465 When the arguments get executed via the system shell, results will
1466 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1467 for details.
1468
1469 Using an indirect object with C<exec> or C<system> is also more
1470 secure.  This usage (which also works fine with system()) forces
1471 interpretation of the arguments as a multivalued list, even if the
1472 list had just one argument.  That way you're safe from the shell
1473 expanding wildcards or splitting up words with whitespace in them.
1474
1475     @args = ( "echo surprise" );
1476
1477     exec @args;               # subject to shell escapes
1478                                 # if @args == 1
1479     exec { $args[0] } @args;  # safe even with one-arg list
1480
1481 The first version, the one without the indirect object, ran the I<echo>
1482 program, passing it C<"surprise"> an argument.  The second version
1483 didn't--it tried to run a program literally called I<"echo surprise">,
1484 didn't find it, and set C<$?> to a non-zero value indicating failure.
1485
1486 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1487 output before the exec, but this may not be supported on some platforms
1488 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1489 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1490 open handles in order to avoid lost output.
1491
1492 Note that C<exec> will not call your C<END> blocks, nor will it call
1493 any C<DESTROY> methods in your objects.
1494
1495 =item exists EXPR
1496
1497 Given an expression that specifies a hash element or array element,
1498 returns true if the specified element in the hash or array has ever
1499 been initialized, even if the corresponding value is undefined.  The
1500 element is not autovivified if it doesn't exist.
1501
1502     print "Exists\n"    if exists $hash{$key};
1503     print "Defined\n"   if defined $hash{$key};
1504     print "True\n"      if $hash{$key};
1505
1506     print "Exists\n"    if exists $array[$index];
1507     print "Defined\n"   if defined $array[$index];
1508     print "True\n"      if $array[$index];
1509
1510 A hash or array element can be true only if it's defined, and defined if
1511 it exists, but the reverse doesn't necessarily hold true.
1512
1513 Given an expression that specifies the name of a subroutine,
1514 returns true if the specified subroutine has ever been declared, even
1515 if it is undefined.  Mentioning a subroutine name for exists or defined
1516 does not count as declaring it.  Note that a subroutine which does not
1517 exist may still be callable: its package may have an C<AUTOLOAD>
1518 method that makes it spring into existence the first time that it is
1519 called -- see L<perlsub>.
1520
1521     print "Exists\n"    if exists &subroutine;
1522     print "Defined\n"   if defined &subroutine;
1523
1524 Note that the EXPR can be arbitrarily complicated as long as the final
1525 operation is a hash or array key lookup or subroutine name:
1526
1527     if (exists $ref->{A}->{B}->{$key})  { }
1528     if (exists $hash{A}{B}{$key})       { }
1529
1530     if (exists $ref->{A}->{B}->[$ix])   { }
1531     if (exists $hash{A}{B}[$ix])        { }
1532
1533     if (exists &{$ref->{A}{B}{$key}})   { }
1534
1535 Although the deepest nested array or hash will not spring into existence
1536 just because its existence was tested, any intervening ones will.
1537 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1538 into existence due to the existence test for the $key element above.
1539 This happens anywhere the arrow operator is used, including even:
1540
1541     undef $ref;
1542     if (exists $ref->{"Some key"})      { }
1543     print $ref;             # prints HASH(0x80d3d5c)
1544
1545 This surprising autovivification in what does not at first--or even
1546 second--glance appear to be an lvalue context may be fixed in a future
1547 release.
1548
1549 See L<perlref/"Pseudo-hashes: Using an array as a hash"> for specifics
1550 on how exists() acts when used on a pseudo-hash.
1551
1552 Use of a subroutine call, rather than a subroutine name, as an argument
1553 to exists() is an error.
1554
1555     exists &sub;        # OK
1556     exists &sub();      # Error
1557
1558 =item exit EXPR
1559
1560 Evaluates EXPR and exits immediately with that value.    Example:
1561
1562     $ans = <STDIN>;
1563     exit 0 if $ans =~ /^[Xx]/;
1564
1565 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1566 universally recognized values for EXPR are C<0> for success and C<1>
1567 for error; other values are subject to interpretation depending on the
1568 environment in which the Perl program is running.  For example, exiting
1569 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1570 the mailer to return the item undelivered, but that's not true everywhere.
1571
1572 Don't use C<exit> to abort a subroutine if there's any chance that
1573 someone might want to trap whatever error happened.  Use C<die> instead,
1574 which can be trapped by an C<eval>.
1575
1576 The exit() function does not always exit immediately.  It calls any
1577 defined C<END> routines first, but these C<END> routines may not
1578 themselves abort the exit.  Likewise any object destructors that need to
1579 be called are called before the real exit.  If this is a problem, you
1580 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1581 See L<perlmod> for details.
1582
1583 =item exp EXPR
1584
1585 =item exp
1586
1587 Returns I<e> (the natural logarithm base) to the power of EXPR.
1588 If EXPR is omitted, gives C<exp($_)>.
1589
1590 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1591
1592 Implements the fcntl(2) function.  You'll probably have to say
1593
1594     use Fcntl;
1595
1596 first to get the correct constant definitions.  Argument processing and
1597 value return works just like C<ioctl> below.
1598 For example:
1599
1600     use Fcntl;
1601     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1602         or die "can't fcntl F_GETFL: $!";
1603
1604 You don't have to check for C<defined> on the return from C<fnctl>.
1605 Like C<ioctl>, it maps a C<0> return from the system call into
1606 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1607 in numeric context.  It is also exempt from the normal B<-w> warnings
1608 on improper numeric conversions.
1609
1610 Note that C<fcntl> will produce a fatal error if used on a machine that
1611 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1612 manpage to learn what functions are available on your system.
1613
1614 =item fileno FILEHANDLE
1615
1616 Returns the file descriptor for a filehandle, or undefined if the
1617 filehandle is not open.  This is mainly useful for constructing
1618 bitmaps for C<select> and low-level POSIX tty-handling operations.
1619 If FILEHANDLE is an expression, the value is taken as an indirect
1620 filehandle, generally its name.
1621
1622 You can use this to find out whether two handles refer to the
1623 same underlying descriptor:
1624
1625     if (fileno(THIS) == fileno(THAT)) {
1626         print "THIS and THAT are dups\n";
1627     }
1628
1629 (Filehandles connected to memory objects via new features of C<open> may
1630 return undefined even though they are open.)
1631
1632
1633 =item flock FILEHANDLE,OPERATION
1634
1635 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1636 for success, false on failure.  Produces a fatal error if used on a
1637 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1638 C<flock> is Perl's portable file locking interface, although it locks
1639 only entire files, not records.
1640
1641 Two potentially non-obvious but traditional C<flock> semantics are
1642 that it waits indefinitely until the lock is granted, and that its locks
1643 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1644 fewer guarantees.  This means that files locked with C<flock> may be
1645 modified by programs that do not also use C<flock>.  See L<perlport>,
1646 your port's specific documentation, or your system-specific local manpages
1647 for details.  It's best to assume traditional behavior if you're writing
1648 portable programs.  (But if you're not, you should as always feel perfectly
1649 free to write for your own system's idiosyncrasies (sometimes called
1650 "features").  Slavish adherence to portability concerns shouldn't get
1651 in the way of your getting your job done.)
1652
1653 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1654 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1655 you can use the symbolic names if you import them from the Fcntl module,
1656 either individually, or as a group using the ':flock' tag.  LOCK_SH
1657 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1658 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1659 LOCK_SH or LOCK_EX then C<flock> will return immediately rather than blocking
1660 waiting for the lock (check the return status to see if you got it).
1661
1662 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1663 before locking or unlocking it.
1664
1665 Note that the emulation built with lockf(3) doesn't provide shared
1666 locks, and it requires that FILEHANDLE be open with write intent.  These
1667 are the semantics that lockf(3) implements.  Most if not all systems
1668 implement lockf(3) in terms of fcntl(2) locking, though, so the
1669 differing semantics shouldn't bite too many people.
1670
1671 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
1672 be open with read intent to use LOCK_SH and requires that it be open
1673 with write intent to use LOCK_EX.
1674
1675 Note also that some versions of C<flock> cannot lock things over the
1676 network; you would need to use the more system-specific C<fcntl> for
1677 that.  If you like you can force Perl to ignore your system's flock(2)
1678 function, and so provide its own fcntl(2)-based emulation, by passing
1679 the switch C<-Ud_flock> to the F<Configure> program when you configure
1680 perl.
1681
1682 Here's a mailbox appender for BSD systems.
1683
1684     use Fcntl ':flock'; # import LOCK_* constants
1685
1686     sub lock {
1687         flock(MBOX,LOCK_EX);
1688         # and, in case someone appended
1689         # while we were waiting...
1690         seek(MBOX, 0, 2);
1691     }
1692
1693     sub unlock {
1694         flock(MBOX,LOCK_UN);
1695     }
1696
1697     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1698             or die "Can't open mailbox: $!";
1699
1700     lock();
1701     print MBOX $msg,"\n\n";
1702     unlock();
1703
1704 On systems that support a real flock(), locks are inherited across fork()
1705 calls, whereas those that must resort to the more capricious fcntl()
1706 function lose the locks, making it harder to write servers.
1707
1708 See also L<DB_File> for other flock() examples.
1709
1710 =item fork
1711
1712 Does a fork(2) system call to create a new process running the
1713 same program at the same point.  It returns the child pid to the
1714 parent process, C<0> to the child process, or C<undef> if the fork is
1715 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
1716 are shared, while everything else is copied.  On most systems supporting
1717 fork(), great care has gone into making it extremely efficient (for
1718 example, using copy-on-write technology on data pages), making it the
1719 dominant paradigm for multitasking over the last few decades.
1720
1721 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1722 output before forking the child process, but this may not be supported
1723 on some platforms (see L<perlport>).  To be safe, you may need to set
1724 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1725 C<IO::Handle> on any open handles in order to avoid duplicate output.
1726
1727 If you C<fork> without ever waiting on your children, you will
1728 accumulate zombies.  On some systems, you can avoid this by setting
1729 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
1730 forking and reaping moribund children.
1731
1732 Note that if your forked child inherits system file descriptors like
1733 STDIN and STDOUT that are actually connected by a pipe or socket, even
1734 if you exit, then the remote server (such as, say, a CGI script or a
1735 backgrounded job launched from a remote shell) won't think you're done.
1736 You should reopen those to F</dev/null> if it's any issue.
1737
1738 =item format
1739
1740 Declare a picture format for use by the C<write> function.  For
1741 example:
1742
1743     format Something =
1744         Test: @<<<<<<<< @||||| @>>>>>
1745               $str,     $%,    '$' . int($num)
1746     .
1747
1748     $str = "widget";
1749     $num = $cost/$quantity;
1750     $~ = 'Something';
1751     write;
1752
1753 See L<perlform> for many details and examples.
1754
1755 =item formline PICTURE,LIST
1756
1757 This is an internal function used by C<format>s, though you may call it,
1758 too.  It formats (see L<perlform>) a list of values according to the
1759 contents of PICTURE, placing the output into the format output
1760 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1761 Eventually, when a C<write> is done, the contents of
1762 C<$^A> are written to some filehandle, but you could also read C<$^A>
1763 yourself and then set C<$^A> back to C<"">.  Note that a format typically
1764 does one C<formline> per line of form, but the C<formline> function itself
1765 doesn't care how many newlines are embedded in the PICTURE.  This means
1766 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1767 You may therefore need to use multiple formlines to implement a single
1768 record format, just like the format compiler.
1769
1770 Be careful if you put double quotes around the picture, because an C<@>
1771 character may be taken to mean the beginning of an array name.
1772 C<formline> always returns true.  See L<perlform> for other examples.
1773
1774 =item getc FILEHANDLE
1775
1776 =item getc
1777
1778 Returns the next character from the input file attached to FILEHANDLE,
1779 or the undefined value at end of file, or if there was an error.
1780 If FILEHANDLE is omitted, reads from STDIN.  This is not particularly
1781 efficient.  However, it cannot be used by itself to fetch single
1782 characters without waiting for the user to hit enter.  For that, try
1783 something more like:
1784
1785     if ($BSD_STYLE) {
1786         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1787     }
1788     else {
1789         system "stty", '-icanon', 'eol', "\001";
1790     }
1791
1792     $key = getc(STDIN);
1793
1794     if ($BSD_STYLE) {
1795         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1796     }
1797     else {
1798         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1799     }
1800     print "\n";
1801
1802 Determination of whether $BSD_STYLE should be set
1803 is left as an exercise to the reader.
1804
1805 The C<POSIX::getattr> function can do this more portably on
1806 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
1807 module from your nearest CPAN site; details on CPAN can be found on
1808 L<perlmodlib/CPAN>.
1809
1810 =item getlogin
1811
1812 Implements the C library function of the same name, which on most
1813 systems returns the current login from F</etc/utmp>, if any.  If null,
1814 use C<getpwuid>.
1815
1816     $login = getlogin || getpwuid($<) || "Kilroy";
1817
1818 Do not consider C<getlogin> for authentication: it is not as
1819 secure as C<getpwuid>.
1820
1821 =item getpeername SOCKET
1822
1823 Returns the packed sockaddr address of other end of the SOCKET connection.
1824
1825     use Socket;
1826     $hersockaddr    = getpeername(SOCK);
1827     ($port, $iaddr) = sockaddr_in($hersockaddr);
1828     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1829     $herstraddr     = inet_ntoa($iaddr);
1830
1831 =item getpgrp PID
1832
1833 Returns the current process group for the specified PID.  Use
1834 a PID of C<0> to get the current process group for the
1835 current process.  Will raise an exception if used on a machine that
1836 doesn't implement getpgrp(2).  If PID is omitted, returns process
1837 group of current process.  Note that the POSIX version of C<getpgrp>
1838 does not accept a PID argument, so only C<PID==0> is truly portable.
1839
1840 =item getppid
1841
1842 Returns the process id of the parent process.
1843
1844 =item getpriority WHICH,WHO
1845
1846 Returns the current priority for a process, a process group, or a user.
1847 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1848 machine that doesn't implement getpriority(2).
1849
1850 =item getpwnam NAME
1851
1852 =item getgrnam NAME
1853
1854 =item gethostbyname NAME
1855
1856 =item getnetbyname NAME
1857
1858 =item getprotobyname NAME
1859
1860 =item getpwuid UID
1861
1862 =item getgrgid GID
1863
1864 =item getservbyname NAME,PROTO
1865
1866 =item gethostbyaddr ADDR,ADDRTYPE
1867
1868 =item getnetbyaddr ADDR,ADDRTYPE
1869
1870 =item getprotobynumber NUMBER
1871
1872 =item getservbyport PORT,PROTO
1873
1874 =item getpwent
1875
1876 =item getgrent
1877
1878 =item gethostent
1879
1880 =item getnetent
1881
1882 =item getprotoent
1883
1884 =item getservent
1885
1886 =item setpwent
1887
1888 =item setgrent
1889
1890 =item sethostent STAYOPEN
1891
1892 =item setnetent STAYOPEN
1893
1894 =item setprotoent STAYOPEN
1895
1896 =item setservent STAYOPEN
1897
1898 =item endpwent
1899
1900 =item endgrent
1901
1902 =item endhostent
1903
1904 =item endnetent
1905
1906 =item endprotoent
1907
1908 =item endservent
1909
1910 These routines perform the same functions as their counterparts in the
1911 system library.  In list context, the return values from the
1912 various get routines are as follows:
1913
1914     ($name,$passwd,$uid,$gid,
1915        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
1916     ($name,$passwd,$gid,$members) = getgr*
1917     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
1918     ($name,$aliases,$addrtype,$net) = getnet*
1919     ($name,$aliases,$proto) = getproto*
1920     ($name,$aliases,$port,$proto) = getserv*
1921
1922 (If the entry doesn't exist you get a null list.)
1923
1924 The exact meaning of the $gcos field varies but it usually contains
1925 the real name of the user (as opposed to the login name) and other
1926 information pertaining to the user.  Beware, however, that in many
1927 system users are able to change this information and therefore it
1928 cannot be trusted and therefore the $gcos is tainted (see
1929 L<perlsec>).  The $passwd and $shell, user's encrypted password and
1930 login shell, are also tainted, because of the same reason.
1931
1932 In scalar context, you get the name, unless the function was a
1933 lookup by name, in which case you get the other thing, whatever it is.
1934 (If the entry doesn't exist you get the undefined value.)  For example:
1935
1936     $uid   = getpwnam($name);
1937     $name  = getpwuid($num);
1938     $name  = getpwent();
1939     $gid   = getgrnam($name);
1940     $name  = getgrgid($num;
1941     $name  = getgrent();
1942     #etc.
1943
1944 In I<getpw*()> the fields $quota, $comment, and $expire are special
1945 cases in the sense that in many systems they are unsupported.  If the
1946 $quota is unsupported, it is an empty scalar.  If it is supported, it
1947 usually encodes the disk quota.  If the $comment field is unsupported,
1948 it is an empty scalar.  If it is supported it usually encodes some
1949 administrative comment about the user.  In some systems the $quota
1950 field may be $change or $age, fields that have to do with password
1951 aging.  In some systems the $comment field may be $class.  The $expire
1952 field, if present, encodes the expiration period of the account or the
1953 password.  For the availability and the exact meaning of these fields
1954 in your system, please consult your getpwnam(3) documentation and your
1955 F<pwd.h> file.  You can also find out from within Perl what your
1956 $quota and $comment fields mean and whether you have the $expire field
1957 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
1958 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
1959 files are only supported if your vendor has implemented them in the
1960 intuitive fashion that calling the regular C library routines gets the
1961 shadow versions if you're running under privilege or if there exists
1962 the shadow(3) functions as found in System V ( this includes Solaris
1963 and Linux.)  Those systems which implement a proprietary shadow password
1964 facility are unlikely to be supported.
1965
1966 The $members value returned by I<getgr*()> is a space separated list of
1967 the login names of the members of the group.
1968
1969 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
1970 C, it will be returned to you via C<$?> if the function call fails.  The
1971 C<@addrs> value returned by a successful call is a list of the raw
1972 addresses returned by the corresponding system library call.  In the
1973 Internet domain, each address is four bytes long and you can unpack it
1974 by saying something like:
1975
1976     ($a,$b,$c,$d) = unpack('C4',$addr[0]);
1977
1978 The Socket library makes this slightly easier:
1979
1980     use Socket;
1981     $iaddr = inet_aton("127.1"); # or whatever address
1982     $name  = gethostbyaddr($iaddr, AF_INET);
1983
1984     # or going the other way
1985     $straddr = inet_ntoa($iaddr);
1986
1987 If you get tired of remembering which element of the return list
1988 contains which return value, by-name interfaces are provided
1989 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
1990 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
1991 and C<User::grent>.  These override the normal built-ins, supplying
1992 versions that return objects with the appropriate names
1993 for each field.  For example:
1994
1995    use File::stat;
1996    use User::pwent;
1997    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
1998
1999 Even though it looks like they're the same method calls (uid),
2000 they aren't, because a C<File::stat> object is different from
2001 a C<User::pwent> object.
2002
2003 =item getsockname SOCKET
2004
2005 Returns the packed sockaddr address of this end of the SOCKET connection,
2006 in case you don't know the address because you have several different
2007 IPs that the connection might have come in on.
2008
2009     use Socket;
2010     $mysockaddr = getsockname(SOCK);
2011     ($port, $myaddr) = sockaddr_in($mysockaddr);
2012     printf "Connect to %s [%s]\n",
2013        scalar gethostbyaddr($myaddr, AF_INET),
2014        inet_ntoa($myaddr);
2015
2016 =item getsockopt SOCKET,LEVEL,OPTNAME
2017
2018 Returns the socket option requested, or undef if there is an error.
2019
2020 =item glob EXPR
2021
2022 =item glob
2023
2024 Returns the value of EXPR with filename expansions such as the
2025 standard Unix shell F</bin/csh> would do.  This is the internal function
2026 implementing the C<< <*.c> >> operator, but you can use it directly.
2027 If EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is
2028 discussed in more detail in L<perlop/"I/O Operators">.
2029
2030 Beginning with v5.6.0, this operator is implemented using the standard
2031 C<File::Glob> extension.  See L<File::Glob> for details.
2032
2033 =item gmtime EXPR
2034
2035 Converts a time as returned by the time function to an 8-element list
2036 with the time localized for the standard Greenwich time zone.
2037 Typically used as follows:
2038
2039     #  0    1    2     3     4    5     6     7
2040     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday) =
2041                                             gmtime(time);
2042
2043 All list elements are numeric, and come straight out of the C `struct
2044 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2045 specified time.  $mday is the day of the month, and $mon is the month
2046 itself, in the range C<0..11> with 0 indicating January and 11
2047 indicating December.  $year is the number of years since 1900.  That
2048 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2049 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2050 the year, in the range C<0..364> (or C<0..365> in leap years.)
2051
2052 Note that the $year element is I<not> simply the last two digits of
2053 the year.  If you assume it is, then you create non-Y2K-compliant
2054 programs--and you wouldn't want to do that, would you?
2055
2056 The proper way to get a complete 4-digit year is simply:
2057
2058         $year += 1900;
2059
2060 And to get the last two digits of the year (e.g., '01' in 2001) do:
2061
2062         $year = sprintf("%02d", $year % 100);
2063
2064 If EXPR is omitted, C<gmtime()> uses the current time (C<gmtime(time)>).
2065
2066 In scalar context, C<gmtime()> returns the ctime(3) value:
2067
2068     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2069
2070 Also see the C<timegm> function provided by the C<Time::Local> module,
2071 and the strftime(3) function available via the POSIX module.
2072
2073 This scalar value is B<not> locale dependent (see L<perllocale>), but
2074 is instead a Perl builtin.  Also see the C<Time::Local> module, and the
2075 strftime(3) and mktime(3) functions available via the POSIX module.  To
2076 get somewhat similar but locale dependent date strings, set up your
2077 locale environment variables appropriately (please see L<perllocale>)
2078 and try for example:
2079
2080     use POSIX qw(strftime);
2081     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
2082
2083 Note that the C<%a> and C<%b> escapes, which represent the short forms
2084 of the day of the week and the month of the year, may not necessarily
2085 be three characters wide in all locales.
2086
2087 =item goto LABEL
2088
2089 =item goto EXPR
2090
2091 =item goto &NAME
2092
2093 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
2094 execution there.  It may not be used to go into any construct that
2095 requires initialization, such as a subroutine or a C<foreach> loop.  It
2096 also can't be used to go into a construct that is optimized away,
2097 or to get out of a block or subroutine given to C<sort>.
2098 It can be used to go almost anywhere else within the dynamic scope,
2099 including out of subroutines, but it's usually better to use some other
2100 construct such as C<last> or C<die>.  The author of Perl has never felt the
2101 need to use this form of C<goto> (in Perl, that is--C is another matter).
2102 (The difference being that C does not offer named loops combined with
2103 loop control.  Perl does, and this replaces most structured uses of C<goto>
2104 in other languages.)
2105
2106 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2107 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2108 necessarily recommended if you're optimizing for maintainability:
2109
2110     goto ("FOO", "BAR", "GLARCH")[$i];
2111
2112 The C<goto-&NAME> form is quite different from the other forms of
2113 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2114 doesn't have the stigma associated with other gotos.  Instead, it
2115 exits the current subroutine (losing any changes set by local()) and
2116 immediately calls in its place the named subroutine using the current
2117 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2118 load another subroutine and then pretend that the other subroutine had
2119 been called in the first place (except that any modifications to C<@_>
2120 in the current subroutine are propagated to the other subroutine.)
2121 After the C<goto>, not even C<caller> will be able to tell that this
2122 routine was called first.
2123
2124 NAME needn't be the name of a subroutine; it can be a scalar variable
2125 containing a code reference, or a block which evaluates to a code
2126 reference.
2127
2128 =item grep BLOCK LIST
2129
2130 =item grep EXPR,LIST
2131
2132 This is similar in spirit to, but not the same as, grep(1) and its
2133 relatives.  In particular, it is not limited to using regular expressions.
2134
2135 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2136 C<$_> to each element) and returns the list value consisting of those
2137 elements for which the expression evaluated to true.  In scalar
2138 context, returns the number of times the expression was true.
2139
2140     @foo = grep(!/^#/, @bar);    # weed out comments
2141
2142 or equivalently,
2143
2144     @foo = grep {!/^#/} @bar;    # weed out comments
2145
2146 Note that C<$_> is an alias to the list value, so it can be used to
2147 modify the elements of the LIST.  While this is useful and supported,
2148 it can cause bizarre results if the elements of LIST are not variables.
2149 Similarly, grep returns aliases into the original list, much as a for
2150 loop's index variable aliases the list elements.  That is, modifying an
2151 element of a list returned by grep (for example, in a C<foreach>, C<map>
2152 or another C<grep>) actually modifies the element in the original list.
2153 This is usually something to be avoided when writing clear code.
2154
2155 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2156
2157 =item hex EXPR
2158
2159 =item hex
2160
2161 Interprets EXPR as a hex string and returns the corresponding value.
2162 (To convert strings that might start with either 0, 0x, or 0b, see
2163 L</oct>.)  If EXPR is omitted, uses C<$_>.
2164
2165     print hex '0xAf'; # prints '175'
2166     print hex 'aF';   # same
2167
2168 Hex strings may only represent integers.  Strings that would cause
2169 integer overflow trigger a warning.  Leading whitespace is not stripped,
2170 unlike oct().
2171
2172 =item import
2173
2174 There is no builtin C<import> function.  It is just an ordinary
2175 method (subroutine) defined (or inherited) by modules that wish to export
2176 names to another module.  The C<use> function calls the C<import> method
2177 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2178
2179 =item index STR,SUBSTR,POSITION
2180
2181 =item index STR,SUBSTR
2182
2183 The index function searches for one string within another, but without
2184 the wildcard-like behavior of a full regular-expression pattern match.
2185 It returns the position of the first occurrence of SUBSTR in STR at
2186 or after POSITION.  If POSITION is omitted, starts searching from the
2187 beginning of the string.  The return value is based at C<0> (or whatever
2188 you've set the C<$[> variable to--but don't do that).  If the substring
2189 is not found, returns one less than the base, ordinarily C<-1>.
2190
2191 =item int EXPR
2192
2193 =item int
2194
2195 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2196 You should not use this function for rounding: one because it truncates
2197 towards C<0>, and two because machine representations of floating point
2198 numbers can sometimes produce counterintuitive results.  For example,
2199 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2200 because it's really more like -268.99999999999994315658 instead.  Usually,
2201 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2202 functions will serve you better than will int().
2203
2204 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2205
2206 Implements the ioctl(2) function.  You'll probably first have to say
2207
2208     require "ioctl.ph"; # probably in /usr/local/lib/perl/ioctl.ph
2209
2210 to get the correct function definitions.  If F<ioctl.ph> doesn't
2211 exist or doesn't have the correct definitions you'll have to roll your
2212 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2213 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2214 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2215 written depending on the FUNCTION--a pointer to the string value of SCALAR
2216 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2217 has no string value but does have a numeric value, that value will be
2218 passed rather than a pointer to the string value.  To guarantee this to be
2219 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2220 functions may be needed to manipulate the values of structures used by
2221 C<ioctl>.
2222
2223 The return value of C<ioctl> (and C<fcntl>) is as follows:
2224
2225         if OS returns:          then Perl returns:
2226             -1                    undefined value
2227              0                  string "0 but true"
2228         anything else               that number
2229
2230 Thus Perl returns true on success and false on failure, yet you can
2231 still easily determine the actual value returned by the operating
2232 system:
2233
2234     $retval = ioctl(...) || -1;
2235     printf "System returned %d\n", $retval;
2236
2237 The special string "C<0> but true" is exempt from B<-w> complaints
2238 about improper numeric conversions.
2239
2240 Here's an example of setting a filehandle named C<REMOTE> to be
2241 non-blocking at the system level.  You'll have to negotiate C<$|>
2242 on your own, though.
2243
2244     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
2245
2246     $flags = fcntl(REMOTE, F_GETFL, 0)
2247                 or die "Can't get flags for the socket: $!\n";
2248
2249     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
2250                 or die "Can't set flags for the socket: $!\n";
2251
2252 =item join EXPR,LIST
2253
2254 Joins the separate strings of LIST into a single string with fields
2255 separated by the value of EXPR, and returns that new string.  Example:
2256
2257     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2258
2259 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2260 first argument.  Compare L</split>.
2261
2262 =item keys HASH
2263
2264 Returns a list consisting of all the keys of the named hash.  (In
2265 scalar context, returns the number of keys.)  The keys are returned in
2266 an apparently random order.  The actual random order is subject to
2267 change in future versions of perl, but it is guaranteed to be the same
2268 order as either the C<values> or C<each> function produces (given
2269 that the hash has not been modified).  As a side effect, it resets
2270 HASH's iterator.
2271
2272 Here is yet another way to print your environment:
2273
2274     @keys = keys %ENV;
2275     @values = values %ENV;
2276     while (@keys) {
2277         print pop(@keys), '=', pop(@values), "\n";
2278     }
2279
2280 or how about sorted by key:
2281
2282     foreach $key (sort(keys %ENV)) {
2283         print $key, '=', $ENV{$key}, "\n";
2284     }
2285
2286 The returned values are copies of the original keys in the hash, so
2287 modifying them will not affect the original hash.  Compare L</values>.
2288
2289 To sort a hash by value, you'll need to use a C<sort> function.
2290 Here's a descending numeric sort of a hash by its values:
2291
2292     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2293         printf "%4d %s\n", $hash{$key}, $key;
2294     }
2295
2296 As an lvalue C<keys> allows you to increase the number of hash buckets
2297 allocated for the given hash.  This can gain you a measure of efficiency if
2298 you know the hash is going to get big.  (This is similar to pre-extending
2299 an array by assigning a larger number to $#array.)  If you say
2300
2301     keys %hash = 200;
2302
2303 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2304 in fact, since it rounds up to the next power of two.  These
2305 buckets will be retained even if you do C<%hash = ()>, use C<undef
2306 %hash> if you want to free the storage while C<%hash> is still in scope.
2307 You can't shrink the number of buckets allocated for the hash using
2308 C<keys> in this way (but you needn't worry about doing this by accident,
2309 as trying has no effect).
2310
2311 See also C<each>, C<values> and C<sort>.
2312
2313 =item kill SIGNAL, LIST
2314
2315 Sends a signal to a list of processes.  Returns the number of
2316 processes successfully signaled (which is not necessarily the
2317 same as the number actually killed).
2318
2319     $cnt = kill 1, $child1, $child2;
2320     kill 9, @goners;
2321
2322 If SIGNAL is zero, no signal is sent to the process.  This is a
2323 useful way to check that the process is alive and hasn't changed
2324 its UID.  See L<perlport> for notes on the portability of this
2325 construct.
2326
2327 Unlike in the shell, if SIGNAL is negative, it kills
2328 process groups instead of processes.  (On System V, a negative I<PROCESS>
2329 number will also kill process groups, but that's not portable.)  That
2330 means you usually want to use positive not negative signals.  You may also
2331 use a signal name in quotes.  See L<perlipc/"Signals"> for details.
2332
2333 =item last LABEL
2334
2335 =item last
2336
2337 The C<last> command is like the C<break> statement in C (as used in
2338 loops); it immediately exits the loop in question.  If the LABEL is
2339 omitted, the command refers to the innermost enclosing loop.  The
2340 C<continue> block, if any, is not executed:
2341
2342     LINE: while (<STDIN>) {
2343         last LINE if /^$/;      # exit when done with header
2344         #...
2345     }
2346
2347 C<last> cannot be used to exit a block which returns a value such as
2348 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2349 a grep() or map() operation.
2350
2351 Note that a block by itself is semantically identical to a loop
2352 that executes once.  Thus C<last> can be used to effect an early
2353 exit out of such a block.
2354
2355 See also L</continue> for an illustration of how C<last>, C<next>, and
2356 C<redo> work.
2357
2358 =item lc EXPR
2359
2360 =item lc
2361
2362 Returns a lowercased version of EXPR.  This is the internal function
2363 implementing the C<\L> escape in double-quoted strings.  Respects
2364 current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>
2365 and L<perlunicode> for more details about locale and Unicode support.
2366
2367 If EXPR is omitted, uses C<$_>.
2368
2369 =item lcfirst EXPR
2370
2371 =item lcfirst
2372
2373 Returns the value of EXPR with the first character lowercased.  This
2374 is the internal function implementing the C<\l> escape in
2375 double-quoted strings.  Respects current LC_CTYPE locale if C<use
2376 locale> in force.  See L<perllocale> and L<perlunicode> for more
2377 details about locale and Unicode support.
2378
2379 If EXPR is omitted, uses C<$_>.
2380
2381 =item length EXPR
2382
2383 =item length
2384
2385 Returns the length in characters of the value of EXPR.  If EXPR is
2386 omitted, returns length of C<$_>.  Note that this cannot be used on
2387 an entire array or hash to find out how many elements these have.
2388 For that, use C<scalar @array> and C<scalar keys %hash> respectively.
2389
2390 =item link OLDFILE,NEWFILE
2391
2392 Creates a new filename linked to the old filename.  Returns true for
2393 success, false otherwise.
2394
2395 =item listen SOCKET,QUEUESIZE
2396
2397 Does the same thing that the listen system call does.  Returns true if
2398 it succeeded, false otherwise.  See the example in
2399 L<perlipc/"Sockets: Client/Server Communication">.
2400
2401 =item local EXPR
2402
2403 You really probably want to be using C<my> instead, because C<local> isn't
2404 what most people think of as "local".  See
2405 L<perlsub/"Private Variables via my()"> for details.
2406
2407 A local modifies the listed variables to be local to the enclosing
2408 block, file, or eval.  If more than one value is listed, the list must
2409 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2410 for details, including issues with tied arrays and hashes.
2411
2412 =item localtime EXPR
2413
2414 Converts a time as returned by the time function to a 9-element list
2415 with the time analyzed for the local time zone.  Typically used as
2416 follows:
2417
2418     #  0    1    2     3     4    5     6     7     8
2419     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2420                                                 localtime(time);
2421
2422 All list elements are numeric, and come straight out of the C `struct
2423 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2424 specified time.  $mday is the day of the month, and $mon is the month
2425 itself, in the range C<0..11> with 0 indicating January and 11
2426 indicating December.  $year is the number of years since 1900.  That
2427 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2428 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2429 the year, in the range C<0..364> (or C<0..365> in leap years.)  $isdst
2430 is true if the specified time occurs during daylight savings time,
2431 false otherwise.
2432
2433 Note that the $year element is I<not> simply the last two digits of
2434 the year.  If you assume it is, then you create non-Y2K-compliant
2435 programs--and you wouldn't want to do that, would you?
2436
2437 The proper way to get a complete 4-digit year is simply:
2438
2439         $year += 1900;
2440
2441 And to get the last two digits of the year (e.g., '01' in 2001) do:
2442
2443         $year = sprintf("%02d", $year % 100);
2444
2445 If EXPR is omitted, C<localtime()> uses the current time (C<localtime(time)>).
2446
2447 In scalar context, C<localtime()> returns the ctime(3) value:
2448
2449     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2450
2451 This scalar value is B<not> locale dependent, see L<perllocale>, but
2452 instead a Perl builtin.  Also see the C<Time::Local> module
2453 (to convert the second, minutes, hours, ... back to seconds since the
2454 stroke of midnight the 1st of January 1970, the value returned by
2455 time()), and the strftime(3) and mktime(3) functions available via the
2456 POSIX module.  To get somewhat similar but locale dependent date
2457 strings, set up your locale environment variables appropriately
2458 (please see L<perllocale>) and try for example:
2459
2460     use POSIX qw(strftime);
2461     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2462
2463 Note that the C<%a> and C<%b>, the short forms of the day of the week
2464 and the month of the year, may not necessarily be three characters wide.
2465
2466 =item lock THING
2467
2468 This function places an advisory lock on a variable, subroutine,
2469 or referenced object contained in I<THING> until the lock goes out
2470 of scope.  This is a built-in function only if your version of Perl
2471 was built with threading enabled, and if you've said C<use Thread>.
2472 Otherwise a user-defined function by this name will be called.
2473 See L<Thread>.
2474
2475 =item log EXPR
2476
2477 =item log
2478
2479 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2480 returns log of C<$_>.  To get the log of another base, use basic algebra:
2481 The base-N log of a number is equal to the natural log of that number
2482 divided by the natural log of N.  For example:
2483
2484     sub log10 {
2485         my $n = shift;
2486         return log($n)/log(10);
2487     }
2488
2489 See also L</exp> for the inverse operation.
2490
2491 =item lstat EXPR
2492
2493 =item lstat
2494
2495 Does the same thing as the C<stat> function (including setting the
2496 special C<_> filehandle) but stats a symbolic link instead of the file
2497 the symbolic link points to.  If symbolic links are unimplemented on
2498 your system, a normal C<stat> is done.
2499
2500 If EXPR is omitted, stats C<$_>.
2501
2502 =item m//
2503
2504 The match operator.  See L<perlop>.
2505
2506 =item map BLOCK LIST
2507
2508 =item map EXPR,LIST
2509
2510 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2511 C<$_> to each element) and returns the list value composed of the
2512 results of each such evaluation.  In scalar context, returns the
2513 total number of elements so generated.  Evaluates BLOCK or EXPR in
2514 list context, so each element of LIST may produce zero, one, or
2515 more elements in the returned value.
2516
2517     @chars = map(chr, @nums);
2518
2519 translates a list of numbers to the corresponding characters.  And
2520
2521     %hash = map { getkey($_) => $_ } @array;
2522
2523 is just a funny way to write
2524
2525     %hash = ();
2526     foreach $_ (@array) {
2527         $hash{getkey($_)} = $_;
2528     }
2529
2530 Note that C<$_> is an alias to the list value, so it can be used to
2531 modify the elements of the LIST.  While this is useful and supported,
2532 it can cause bizarre results if the elements of LIST are not variables.
2533 Using a regular C<foreach> loop for this purpose would be clearer in
2534 most cases.  See also L</grep> for an array composed of those items of
2535 the original list for which the BLOCK or EXPR evaluates to true.
2536
2537 C<{> starts both hash references and blocks, so C<map { ...> could be either
2538 the start of map BLOCK LIST or map EXPR, LIST. Because perl doesn't look
2539 ahead for the closing C<}> it has to take a guess at which its dealing with
2540 based what it finds just after the C<{>. Usually it gets it right, but if it
2541 doesn't it won't realize something is wrong until it gets to the C<}> and
2542 encounters the missing (or unexpected) comma. The syntax error will be
2543 reported close to the C<}> but you'll need to change something near the C<{>
2544 such as using a unary C<+> to give perl some help:
2545
2546     %hash = map {  "\L$_", 1  } @array  # perl guesses EXPR.  wrong
2547     %hash = map { +"\L$_", 1  } @array  # perl guesses BLOCK. right
2548     %hash = map { ("\L$_", 1) } @array  # this also works
2549     %hash = map {  lc($_), 1  } @array  # as does this.
2550     %hash = map +( lc($_), 1 ), @array  # this is EXPR and works!
2551
2552     %hash = map  ( lc($_), 1 ), @array  # evaluates to (1, @array)
2553
2554 or to force an anon hash constructor use C<+{>
2555
2556    @hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end
2557
2558 and you get list of anonymous hashes each with only 1 entry.
2559
2560 =item mkdir FILENAME,MASK
2561
2562 =item mkdir FILENAME
2563
2564 Creates the directory specified by FILENAME, with permissions
2565 specified by MASK (as modified by C<umask>).  If it succeeds it
2566 returns true, otherwise it returns false and sets C<$!> (errno).
2567 If omitted, MASK defaults to 0777.
2568
2569 In general, it is better to create directories with permissive MASK,
2570 and let the user modify that with their C<umask>, than it is to supply
2571 a restrictive MASK and give the user no way to be more permissive.
2572 The exceptions to this rule are when the file or directory should be
2573 kept private (mail files, for instance).  The perlfunc(1) entry on
2574 C<umask> discusses the choice of MASK in more detail.
2575
2576 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
2577 number of trailing slashes.  Some operating and filesystems do not get
2578 this right, so Perl automatically removes all trailing slashes to keep
2579 everyone happy.
2580
2581 =item msgctl ID,CMD,ARG
2582
2583 Calls the System V IPC function msgctl(2).  You'll probably have to say
2584
2585     use IPC::SysV;
2586
2587 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2588 then ARG must be a variable which will hold the returned C<msqid_ds>
2589 structure.  Returns like C<ioctl>: the undefined value for error,
2590 C<"0 but true"> for zero, or the actual return value otherwise.  See also
2591 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::Semaphore> documentation.
2592
2593 =item msgget KEY,FLAGS
2594
2595 Calls the System V IPC function msgget(2).  Returns the message queue
2596 id, or the undefined value if there is an error.  See also
2597 L<perlipc/"SysV IPC"> and C<IPC::SysV> and C<IPC::Msg> documentation.
2598
2599 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2600
2601 Calls the System V IPC function msgrcv to receive a message from
2602 message queue ID into variable VAR with a maximum message size of
2603 SIZE.  Note that when a message is received, the message type as a
2604 native long integer will be the first thing in VAR, followed by the
2605 actual message.  This packing may be opened with C<unpack("l! a*")>.
2606 Taints the variable.  Returns true if successful, or false if there is
2607 an error.  See also L<perlipc/"SysV IPC">, C<IPC::SysV>, and
2608 C<IPC::SysV::Msg> documentation.
2609
2610 =item msgsnd ID,MSG,FLAGS
2611
2612 Calls the System V IPC function msgsnd to send the message MSG to the
2613 message queue ID.  MSG must begin with the native long integer message
2614 type, and be followed by the length of the actual message, and finally
2615 the message itself.  This kind of packing can be achieved with
2616 C<pack("l! a*", $type, $message)>.  Returns true if successful,
2617 or false if there is an error.  See also C<IPC::SysV>
2618 and C<IPC::SysV::Msg> documentation.
2619
2620 =item my EXPR
2621
2622 =item my EXPR : ATTRIBUTES
2623
2624 A C<my> declares the listed variables to be local (lexically) to the
2625 enclosing block, file, or C<eval>.  If
2626 more than one value is listed, the list must be placed in parentheses.  See
2627 L<perlsub/"Private Variables via my()"> for details.
2628
2629 =item next LABEL
2630
2631 =item next
2632
2633 The C<next> command is like the C<continue> statement in C; it starts
2634 the next iteration of the loop:
2635
2636     LINE: while (<STDIN>) {
2637         next LINE if /^#/;      # discard comments
2638         #...
2639     }
2640
2641 Note that if there were a C<continue> block on the above, it would get
2642 executed even on discarded lines.  If the LABEL is omitted, the command
2643 refers to the innermost enclosing loop.
2644
2645 C<next> cannot be used to exit a block which returns a value such as
2646 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2647 a grep() or map() operation.
2648
2649 Note that a block by itself is semantically identical to a loop
2650 that executes once.  Thus C<next> will exit such a block early.
2651
2652 See also L</continue> for an illustration of how C<last>, C<next>, and
2653 C<redo> work.
2654
2655 =item no Module LIST
2656
2657 See the L</use> function, which C<no> is the opposite of.
2658
2659 =item oct EXPR
2660
2661 =item oct
2662
2663 Interprets EXPR as an octal string and returns the corresponding
2664 value.  (If EXPR happens to start off with C<0x>, interprets it as a
2665 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
2666 binary string.  Leading whitespace is ignored in all three cases.)
2667 The following will handle decimal, binary, octal, and hex in the standard
2668 Perl or C notation:
2669
2670     $val = oct($val) if $val =~ /^0/;
2671
2672 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
2673 in octal), use sprintf() or printf():
2674
2675     $perms = (stat("filename"))[2] & 07777;
2676     $oct_perms = sprintf "%lo", $perms;
2677
2678 The oct() function is commonly used when a string such as C<644> needs
2679 to be converted into a file mode, for example. (Although perl will
2680 automatically convert strings into numbers as needed, this automatic
2681 conversion assumes base 10.)
2682
2683 =item open FILEHANDLE,EXPR
2684
2685 =item open FILEHANDLE,MODE,EXPR
2686
2687 =item open FILEHANDLE,MODE,EXPR,LIST
2688
2689 =item open FILEHANDLE,MODE,REFERENCE
2690
2691 =item open FILEHANDLE
2692
2693 Opens the file whose filename is given by EXPR, and associates it with
2694 FILEHANDLE.
2695
2696 (The following is a comprehensive reference to open(): for a gentler
2697 introduction you may consider L<perlopentut>.)
2698
2699 If FILEHANDLE is an undefined lexical (C<my>) variable the variable is
2700 assigned a reference to a new anonymous filehandle, otherwise if
2701 FILEHANDLE is an expression, its value is used as the name of the real
2702 filehandle wanted.  (This is considered a symbolic reference, so C<use
2703 strict 'refs'> should I<not> be in effect.)
2704
2705 If EXPR is omitted, the scalar variable of the same name as the
2706 FILEHANDLE contains the filename.  (Note that lexical variables--those
2707 declared with C<my>--will not work for this purpose; so if you're
2708 using C<my>, specify EXPR in your call to open.) 
2709
2710 If three or more arguments are specified then the mode of opening and
2711 the file name are separate. If MODE is C<< '<' >> or nothing, the file
2712 is opened for input.  If MODE is C<< '>' >>, the file is truncated and
2713 opened for output, being created if necessary.  If MODE is C<<< '>>' >>>,
2714 the file is opened for appending, again being created if necessary.
2715
2716 You can put a C<'+'> in front of the C<< '>' >> or C<< '<' >> to
2717 indicate that you want both read and write access to the file; thus
2718 C<< '+<' >> is almost always preferred for read/write updates--the C<<
2719 '+>' >> mode would clobber the file first.  You can't usually use
2720 either read-write mode for updating textfiles, since they have
2721 variable length records.  See the B<-i> switch in L<perlrun> for a
2722 better approach.  The file is created with permissions of C<0666>
2723 modified by the process' C<umask> value.
2724
2725 These various prefixes correspond to the fopen(3) modes of C<'r'>,
2726 C<'r+'>, C<'w'>, C<'w+'>, C<'a'>, and C<'a+'>.
2727
2728 In the 2-arguments (and 1-argument) form of the call the mode and
2729 filename should be concatenated (in this order), possibly separated by
2730 spaces.  It is possible to omit the mode in these forms if the mode is
2731 C<< '<' >>.
2732
2733 If the filename begins with C<'|'>, the filename is interpreted as a
2734 command to which output is to be piped, and if the filename ends with a
2735 C<'|'>, the filename is interpreted as a command which pipes output to
2736 us.  See L<perlipc/"Using open() for IPC">
2737 for more examples of this.  (You are not allowed to C<open> to a command
2738 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2739 and L<perlipc/"Bidirectional Communication with Another Process">
2740 for alternatives.)
2741
2742 For three or more arguments if MODE is C<'|-'>, the filename is
2743 interpreted as a command to which output is to be piped, and if MODE
2744 is C<'-|'>, the filename is interpreted as a command which pipes
2745 output to us.  In the 2-arguments (and 1-argument) form one should
2746 replace dash (C<'-'>) with the command.
2747 See L<perlipc/"Using open() for IPC"> for more examples of this.
2748 (You are not allowed to C<open> to a command that pipes both in I<and>
2749 out, but see L<IPC::Open2>, L<IPC::Open3>, and
2750 L<perlipc/"Bidirectional Communication"> for alternatives.)
2751
2752 In the three-or-more argument form of pipe opens, if LIST is specified
2753 (extra arguments after the command name) then LIST becomes arguments
2754 to the command invoked if the platform supports it.  The meaning of
2755 C<open> with more than three arguments for non-pipe modes is not yet
2756 specified. Experimental "layers" may give extra LIST arguments
2757 meaning.
2758
2759 In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN
2760 and opening C<< '>-' >> opens STDOUT.
2761
2762 You may use the three-argument form of open to specify
2763 I<I/O disciplines> that affect how the input and output
2764 are processed: see L</binmode> and L<open>.  For example
2765
2766   open(FH, "<:utf8", "file")
2767
2768 will open the UTF-8 encoded file containing Unicode characters,
2769 see L<perluniintro>.
2770
2771 Open returns nonzero upon success, the undefined value otherwise.  If
2772 the C<open> involved a pipe, the return value happens to be the pid of
2773 the subprocess.
2774
2775 If you're running Perl on a system that distinguishes between text
2776 files and binary files, then you should check out L</binmode> for tips
2777 for dealing with this.  The key distinction between systems that need
2778 C<binmode> and those that don't is their text file formats.  Systems
2779 like Unix, MacOS, and Plan9, which delimit lines with a single
2780 character, and which encode that character in C as C<"\n">, do not
2781 need C<binmode>.  The rest need it.
2782
2783 In the three argument form MODE may also contain a list of IO "layers"
2784 (see L<open> and L<PerlIO> for more details) to be applied to the
2785 handle. This can be used to achieve the effect of C<binmode> as well
2786 as more complex behaviours.
2787
2788 When opening a file, it's usually a bad idea to continue normal execution
2789 if the request failed, so C<open> is frequently used in connection with
2790 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
2791 where you want to make a nicely formatted error message (but there are
2792 modules that can help with that problem)) you should always check
2793 the return value from opening a file.  The infrequent exception is when
2794 working with an unopened filehandle is actually what you want to do.
2795
2796 As a special case the 3 arg form with a read/write mode and the third
2797 argument being C<undef>:
2798
2799     open(TMP, "+>", undef) or die ...
2800
2801 opens a filehandle to an anonymous temporary file.
2802
2803 File handles can be opened to "in memory" files held in Perl scalars via:
2804
2805     open($fh,'>', \$variable) || ..
2806
2807 Examples:
2808
2809     $ARTICLE = 100;
2810     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
2811     while (<ARTICLE>) {...
2812
2813     open(LOG, '>>/usr/spool/news/twitlog');     # (log is reserved)
2814     # if the open fails, output is discarded
2815
2816     open(DBASE, '+<', 'dbase.mine')             # open for update
2817         or die "Can't open 'dbase.mine' for update: $!";
2818
2819     open(DBASE, '+<dbase.mine')                 # ditto
2820         or die "Can't open 'dbase.mine' for update: $!";
2821
2822     open(ARTICLE, '-|', "caesar <$article")     # decrypt article
2823         or die "Can't start caesar: $!";
2824
2825     open(ARTICLE, "caesar <$article |")         # ditto
2826         or die "Can't start caesar: $!";
2827
2828     open(EXTRACT, "|sort >/tmp/Tmp$$")          # $$ is our process id
2829         or die "Can't start sort: $!";
2830
2831     # in memory files
2832     open(MEMORY,'>', \$var)
2833         or die "Can't open memory file: $!";
2834     print MEMORY "foo!\n";                      # output will end up in $var
2835
2836     # process argument list of files along with any includes
2837
2838     foreach $file (@ARGV) {
2839         process($file, 'fh00');
2840     }
2841
2842     sub process {
2843         my($filename, $input) = @_;
2844         $input++;               # this is a string increment
2845         unless (open($input, $filename)) {
2846             print STDERR "Can't open $filename: $!\n";
2847             return;
2848         }
2849
2850         local $_;
2851         while (<$input>) {              # note use of indirection
2852             if (/^#include "(.*)"/) {
2853                 process($1, $input);
2854                 next;
2855             }
2856             #...                # whatever
2857         }
2858     }
2859
2860 You may also, in the Bourne shell tradition, specify an EXPR beginning
2861 with C<< '>&' >>, in which case the rest of the string is interpreted as the
2862 name of a filehandle (or file descriptor, if numeric) to be
2863 duped and opened.  You may use C<&> after C<< > >>, C<<< >> >>>,
2864 C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.  The
2865 mode you specify should match the mode of the original filehandle.
2866 (Duping a filehandle does not take into account any existing contents of
2867 IO buffers.) If you use the 3 arg form then you can pass either a number,
2868 the name of a filehandle or the normal "reference to a glob".
2869
2870 Here is a script that saves, redirects, and restores C<STDOUT> and
2871 C<STDERR> using various methods:
2872
2873     #!/usr/bin/perl
2874     open my $oldout, ">&STDOUT"     or die "Can't dup STDOUT: $!";
2875     open OLDERR,     ">&", \*STDERR or die "Can't dup STDERR: $!";
2876  
2877     open STDOUT, '>', "foo.out" or die "Can't redirect STDOUT: $!";
2878     open STDERR, ">&STDOUT"     or die "Can't dup STDOUT: $!";
2879
2880     select STDERR; $| = 1;      # make unbuffered
2881     select STDOUT; $| = 1;      # make unbuffered
2882
2883     print STDOUT "stdout 1\n";  # this works for
2884     print STDERR "stderr 1\n";  # subprocesses too
2885
2886     close STDOUT;
2887     close STDERR;
2888
2889     open STDOUT, ">&", $oldout or die "Can't dup \$oldout: $!";
2890     open STDERR, ">&OLDERR"    or die "Can't dup OLDERR: $!";
2891
2892     print STDOUT "stdout 2\n";
2893     print STDERR "stderr 2\n";
2894
2895 If you specify C<< '<&=N' >>, where C<N> is a number, then Perl will
2896 do an equivalent of C's C<fdopen> of that file descriptor; this is
2897 more parsimonious of file descriptors.  For example:
2898
2899     open(FILEHANDLE, "<&=$fd")
2900
2901 or
2902
2903     open(FILEHANDLE, "<&=", $fd)
2904
2905 Note that if Perl is using the standard C libraries' fdopen() then on
2906 many UNIX systems, fdopen() is known to fail when file descriptors
2907 exceed a certain value, typically 255. If you need more file
2908 descriptors than that, consider rebuilding Perl to use the C<PerlIO>.
2909
2910 You can see whether Perl has been compiled with PerlIO or not by
2911 running C<perl -V> and looking for C<useperlio=> line.  If C<useperlio>
2912 is C<define>, you have PerlIO, otherwise you don't.
2913
2914 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
2915 with 2-arguments (or 1-argument) form of open(), then
2916 there is an implicit fork done, and the return value of open is the pid
2917 of the child within the parent process, and C<0> within the child
2918 process.  (Use C<defined($pid)> to determine whether the open was successful.)
2919 The filehandle behaves normally for the parent, but i/o to that
2920 filehandle is piped from/to the STDOUT/STDIN of the child process.
2921 In the child process the filehandle isn't opened--i/o happens from/to
2922 the new STDOUT or STDIN.  Typically this is used like the normal
2923 piped open when you want to exercise more control over just how the
2924 pipe command gets executed, such as when you are running setuid, and
2925 don't want to have to scan shell commands for metacharacters.
2926 The following triples are more or less equivalent:
2927
2928     open(FOO, "|tr '[a-z]' '[A-Z]'");
2929     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
2930     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
2931     open(FOO, '|-', "tr", '[a-z]', '[A-Z]');
2932
2933     open(FOO, "cat -n '$file'|");
2934     open(FOO, '-|', "cat -n '$file'");
2935     open(FOO, '-|') || exec 'cat', '-n', $file;
2936     open(FOO, '-|', "cat", '-n', $file);
2937
2938 The last example in each block shows the pipe as "list form", which is
2939 not yet supported on all platforms.
2940
2941 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
2942
2943 Beginning with v5.6.0, Perl will attempt to flush all files opened for
2944 output before any operation that may do a fork, but this may not be
2945 supported on some platforms (see L<perlport>).  To be safe, you may need
2946 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
2947 of C<IO::Handle> on any open handles.
2948
2949 On systems that support a close-on-exec flag on files, the flag will
2950 be set for the newly opened file descriptor as determined by the value
2951 of $^F.  See L<perlvar/$^F>.
2952
2953 Closing any piped filehandle causes the parent process to wait for the
2954 child to finish, and returns the status value in C<$?>.
2955
2956 The filename passed to 2-argument (or 1-argument) form of open() will
2957 have leading and trailing whitespace deleted, and the normal
2958 redirection characters honored.  This property, known as "magic open",
2959 can often be used to good effect.  A user could specify a filename of
2960 F<"rsh cat file |">, or you could change certain filenames as needed:
2961
2962     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
2963     open(FH, $filename) or die "Can't open $filename: $!";
2964
2965 Use 3-argument form to open a file with arbitrary weird characters in it,
2966
2967     open(FOO, '<', $file);
2968
2969 otherwise it's necessary to protect any leading and trailing whitespace:
2970
2971     $file =~ s#^(\s)#./$1#;
2972     open(FOO, "< $file\0");
2973
2974 (this may not work on some bizarre filesystems).  One should
2975 conscientiously choose between the I<magic> and 3-arguments form
2976 of open():
2977
2978     open IN, $ARGV[0];
2979
2980 will allow the user to specify an argument of the form C<"rsh cat file |">,
2981 but will not work on a filename which happens to have a trailing space, while
2982
2983     open IN, '<', $ARGV[0];
2984
2985 will have exactly the opposite restrictions.
2986
2987 If you want a "real" C C<open> (see L<open(2)> on your system), then you
2988 should use the C<sysopen> function, which involves no such magic (but
2989 may use subtly different filemodes than Perl open(), which is mapped
2990 to C fopen()).  This is
2991 another way to protect your filenames from interpretation.  For example:
2992
2993     use IO::Handle;
2994     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
2995         or die "sysopen $path: $!";
2996     $oldfh = select(HANDLE); $| = 1; select($oldfh);
2997     print HANDLE "stuff $$\n";
2998     seek(HANDLE, 0, 0);
2999     print "File contains: ", <HANDLE>;
3000
3001 Using the constructor from the C<IO::Handle> package (or one of its
3002 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3003 filehandles that have the scope of whatever variables hold references to
3004 them, and automatically close whenever and however you leave that scope:
3005
3006     use IO::File;
3007     #...
3008     sub read_myfile_munged {
3009         my $ALL = shift;
3010         my $handle = new IO::File;
3011         open($handle, "myfile") or die "myfile: $!";
3012         $first = <$handle>
3013             or return ();     # Automatically closed here.
3014         mung $first or die "mung failed";       # Or here.
3015         return $first, <$handle> if $ALL;       # Or here.
3016         $first;                                 # Or here.
3017     }
3018
3019 See L</seek> for some details about mixing reading and writing.
3020
3021 =item opendir DIRHANDLE,EXPR
3022
3023 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3024 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3025 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3026
3027 =item ord EXPR
3028
3029 =item ord
3030
3031 Returns the numeric (the native 8-bit encoding, like ASCII or EBCDIC,
3032 or Unicode) value of the first character of EXPR.  If EXPR is omitted,
3033 uses C<$_>.
3034
3035 For the reverse, see L</chr>.
3036 See L<perlunicode> and L<encoding> for more about Unicode.
3037
3038 =item our EXPR
3039
3040 =item our EXPR : ATTRIBUTES
3041
3042 An C<our> declares the listed variables to be valid globals within
3043 the enclosing block, file, or C<eval>.  That is, it has the same
3044 scoping rules as a "my" declaration, but does not create a local
3045 variable.  If more than one value is listed, the list must be placed
3046 in parentheses.  The C<our> declaration has no semantic effect unless
3047 "use strict vars" is in effect, in which case it lets you use the
3048 declared global variable without qualifying it with a package name.
3049 (But only within the lexical scope of the C<our> declaration.  In this
3050 it differs from "use vars", which is package scoped.)
3051
3052 An C<our> declaration declares a global variable that will be visible
3053 across its entire lexical scope, even across package boundaries.  The
3054 package in which the variable is entered is determined at the point
3055 of the declaration, not at the point of use.  This means the following
3056 behavior holds:
3057
3058     package Foo;
3059     our $bar;           # declares $Foo::bar for rest of lexical scope
3060     $bar = 20;
3061
3062     package Bar;
3063     print $bar;         # prints 20
3064
3065 Multiple C<our> declarations in the same lexical scope are allowed
3066 if they are in different packages.  If they happened to be in the same
3067 package, Perl will emit warnings if you have asked for them.
3068
3069     use warnings;
3070     package Foo;
3071     our $bar;           # declares $Foo::bar for rest of lexical scope
3072     $bar = 20;
3073
3074     package Bar;
3075     our $bar = 30;      # declares $Bar::bar for rest of lexical scope
3076     print $bar;         # prints 30
3077
3078     our $bar;           # emits warning
3079
3080 An C<our> declaration may also have a list of attributes associated
3081 with it.  B<WARNING>: This is an experimental feature that may be
3082 changed or removed in future releases of Perl.  It should not be
3083 relied upon.
3084
3085 The only currently recognized attribute is C<unique> which indicates
3086 that a single copy of the global is to be used by all interpreters
3087 should the program happen to be running in a multi-interpreter
3088 environment. (The default behaviour would be for each interpreter to
3089 have its own copy of the global.)  In such an environment, this
3090 attribute also has the effect of making the global readonly.
3091 Examples:
3092
3093     our @EXPORT : unique = qw(foo);
3094     our %EXPORT_TAGS : unique = (bar => [qw(aa bb cc)]);
3095     our $VERSION : unique = "1.00";
3096
3097 Multi-interpreter environments can come to being either through the
3098 fork() emulation on Windows platforms, or by embedding perl in a
3099 multi-threaded application.  The C<unique> attribute does nothing in
3100 all other environments.
3101
3102 =item pack TEMPLATE,LIST
3103
3104 Takes a LIST of values and converts it into a string using the rules
3105 given by the TEMPLATE.  The resulting string is the concatenation of
3106 the converted values.  Typically, each converted value looks
3107 like its machine-level representation.  For example, on 32-bit machines
3108 a converted integer may be represented by a sequence of 4 bytes.
3109
3110 The TEMPLATE is a sequence of characters that give the order and type
3111 of values, as follows:
3112
3113     a   A string with arbitrary binary data, will be null padded.
3114     A   A text (ASCII) string, will be space padded.
3115     Z   A null terminated (ASCIZ) string, will be null padded.
3116
3117     b   A bit string (ascending bit order inside each byte, like vec()).
3118     B   A bit string (descending bit order inside each byte).
3119     h   A hex string (low nybble first).
3120     H   A hex string (high nybble first).
3121
3122     c   A signed char value.
3123     C   An unsigned char value.  Only does bytes.  See U for Unicode.
3124
3125     s   A signed short value.
3126     S   An unsigned short value.
3127           (This 'short' is _exactly_ 16 bits, which may differ from
3128            what a local C compiler calls 'short'.  If you want
3129            native-length shorts, use the '!' suffix.)
3130
3131     i   A signed integer value.
3132     I   An unsigned integer value.
3133           (This 'integer' is _at_least_ 32 bits wide.  Its exact
3134            size depends on what a local C compiler calls 'int',
3135            and may even be larger than the 'long' described in
3136            the next item.)
3137
3138     l   A signed long value.
3139     L   An unsigned long value.
3140           (This 'long' is _exactly_ 32 bits, which may differ from
3141            what a local C compiler calls 'long'.  If you want
3142            native-length longs, use the '!' suffix.)
3143
3144     n   An unsigned short in "network" (big-endian) order.
3145     N   An unsigned long in "network" (big-endian) order.
3146     v   An unsigned short in "VAX" (little-endian) order.
3147     V   An unsigned long in "VAX" (little-endian) order.
3148           (These 'shorts' and 'longs' are _exactly_ 16 bits and
3149            _exactly_ 32 bits, respectively.)
3150
3151     q   A signed quad (64-bit) value.
3152     Q   An unsigned quad value.
3153           (Quads are available only if your system supports 64-bit
3154            integer values _and_ if Perl has been compiled to support those.
3155            Causes a fatal error otherwise.)
3156
3157     j   A signed integer value (a Perl internal integer, IV).
3158     J   An unsigned integer value (a Perl internal unsigned integer, UV).
3159
3160     f   A single-precision float in the native format.
3161     d   A double-precision float in the native format.
3162
3163     F   A floating point value in the native native format
3164            (a Perl internal floating point value, NV).
3165     D   A long double-precision float in the native format.
3166           (Long doubles are available only if your system supports long
3167            double values _and_ if Perl has been compiled to support those.
3168            Causes a fatal error otherwise.)
3169
3170     p   A pointer to a null-terminated string.
3171     P   A pointer to a structure (fixed-length string).
3172
3173     u   A uuencoded string.
3174     U   A Unicode character number.  Encodes to UTF-8 internally
3175         (or UTF-EBCDIC in EBCDIC platforms).
3176
3177     w   A BER compressed integer.  Its bytes represent an unsigned
3178         integer in base 128, most significant digit first, with as
3179         few digits as possible.  Bit eight (the high bit) is set
3180         on each byte except the last.
3181
3182     x   A null byte.
3183     X   Back up a byte.
3184     @   Null fill to absolute position.
3185     (   Start of a ()-group.
3186
3187 The following rules apply:
3188
3189 =over 8
3190
3191 =item *
3192
3193 Each letter may optionally be followed by a number giving a repeat
3194 count.  With all types except C<a>, C<A>, C<Z>, C<b>, C<B>, C<h>,
3195 C<H>, C<@>, C<x>, C<X> and C<P> the pack function will gobble up that
3196 many values from the LIST.  A C<*> for the repeat count means to use
3197 however many items are left, except for C<@>, C<x>, C<X>, where it is
3198 equivalent to C<0>, and C<u>, where it is equivalent to 1 (or 45, what
3199 is the same).  A numeric repeat count may optionally be enclosed in
3200 brackets, as in C<pack 'C[80]', @arr>.
3201
3202 One can replace the numeric repeat count by a template enclosed in brackets;
3203 then the packed length of this template in bytes is used as a count.
3204 For example, C<x[L]> skips a long (it skips the number of bytes in a long);
3205 the template C<$t X[$t] $t> unpack()s twice what $t unpacks.
3206 If the template in brackets contains alignment commands (such as C<x![d]>),
3207 its packed length is calculated as if the start of the template has the maximal
3208 possible alignment.
3209
3210 When used with C<Z>, C<*> results in the addition of a trailing null
3211 byte (so the packed result will be one longer than the byte C<length>
3212 of the item).
3213
3214 The repeat count for C<u> is interpreted as the maximal number of bytes
3215 to encode per line of output, with 0 and 1 replaced by 45.
3216
3217 =item *
3218
3219 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
3220 string of length count, padding with nulls or spaces as necessary.  When
3221 unpacking, C<A> strips trailing spaces and nulls, C<Z> strips everything
3222 after the first null, and C<a> returns data verbatim.  When packing,
3223 C<a>, and C<Z> are equivalent.
3224
3225 If the value-to-pack is too long, it is truncated.  If too long and an
3226 explicit count is provided, C<Z> packs only C<$count-1> bytes, followed
3227 by a null byte.  Thus C<Z> always packs a trailing null byte under
3228 all circumstances.
3229
3230 =item *
3231
3232 Likewise, the C<b> and C<B> fields pack a string that many bits long.
3233 Each byte of the input field of pack() generates 1 bit of the result.
3234 Each result bit is based on the least-significant bit of the corresponding
3235 input byte, i.e., on C<ord($byte)%2>.  In particular, bytes C<"0"> and
3236 C<"1"> generate bits 0 and 1, as do bytes C<"\0"> and C<"\1">.
3237
3238 Starting from the beginning of the input string of pack(), each 8-tuple
3239 of bytes is converted to 1 byte of output.  With format C<b>
3240 the first byte of the 8-tuple determines the least-significant bit of a
3241 byte, and with format C<B> it determines the most-significant bit of
3242 a byte.
3243
3244 If the length of the input string is not exactly divisible by 8, the
3245 remainder is packed as if the input string were padded by null bytes
3246 at the end.  Similarly, during unpack()ing the "extra" bits are ignored.
3247
3248 If the input string of pack() is longer than needed, extra bytes are ignored.
3249 A C<*> for the repeat count of pack() means to use all the bytes of
3250 the input field.  On unpack()ing the bits are converted to a string
3251 of C<"0">s and C<"1">s.
3252
3253 =item *
3254
3255 The C<h> and C<H> fields pack a string that many nybbles (4-bit groups,
3256 representable as hexadecimal digits, 0-9a-f) long.
3257
3258 Each byte of the input field of pack() generates 4 bits of the result.
3259 For non-alphabetical bytes the result is based on the 4 least-significant
3260 bits of the input byte, i.e., on C<ord($byte)%16>.  In particular,
3261 bytes C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
3262 C<"\0"> and C<"\1">.  For bytes C<"a".."f"> and C<"A".."F"> the result
3263 is compatible with the usual hexadecimal digits, so that C<"a"> and
3264 C<"A"> both generate the nybble C<0xa==10>.  The result for bytes
3265 C<"g".."z"> and C<"G".."Z"> is not well-defined.
3266
3267 Starting from the beginning of the input string of pack(), each pair
3268 of bytes is converted to 1 byte of output.  With format C<h> the
3269 first byte of the pair determines the least-significant nybble of the
3270 output byte, and with format C<H> it determines the most-significant
3271 nybble.
3272
3273 If the length of the input string is not even, it behaves as if padded
3274 by a null byte at the end.  Similarly, during unpack()ing the "extra"
3275 nybbles are ignored.
3276
3277 If the input string of pack() is longer than needed, extra bytes are ignored.
3278 A C<*> for the repeat count of pack() means to use all the bytes of
3279 the input field.  On unpack()ing the bits are converted to a string
3280 of hexadecimal digits.
3281
3282 =item *
3283
3284 The C<p> type packs a pointer to a null-terminated string.  You are
3285 responsible for ensuring the string is not a temporary value (which can
3286 potentially get deallocated before you get around to using the packed result).
3287 The C<P> type packs a pointer to a structure of the size indicated by the
3288 length.  A NULL pointer is created if the corresponding value for C<p> or
3289 C<P> is C<undef>, similarly for unpack().
3290
3291 =item *
3292
3293 The C</> template character allows packing and unpacking of strings where
3294 the packed structure contains a byte count followed by the string itself.
3295 You write I<length-item>C</>I<string-item>.
3296
3297 The I<length-item> can be any C<pack> template letter, and describes
3298 how the length value is packed.  The ones likely to be of most use are
3299 integer-packing ones like C<n> (for Java strings), C<w> (for ASN.1 or
3300 SNMP) and C<N> (for Sun XDR).
3301
3302 The I<string-item> must, at present, be C<"A*">, C<"a*"> or C<"Z*">.
3303 For C<unpack> the length of the string is obtained from the I<length-item>,
3304 but if you put in the '*' it will be ignored.
3305
3306     unpack 'C/a', "\04Gurusamy";        gives 'Guru'
3307     unpack 'a3/A* A*', '007 Bond  J ';  gives (' Bond','J')
3308     pack 'n/a* w/a*','hello,','world';  gives "\000\006hello,\005world"
3309
3310 The I<length-item> is not returned explicitly from C<unpack>.
3311
3312 Adding a count to the I<length-item> letter is unlikely to do anything
3313 useful, unless that letter is C<A>, C<a> or C<Z>.  Packing with a
3314 I<length-item> of C<a> or C<Z> may introduce C<"\000"> characters,
3315 which Perl does not regard as legal in numeric strings.
3316
3317 =item *
3318
3319 The integer types C<s>, C<S>, C<l>, and C<L> may be
3320 immediately followed by a C<!> suffix to signify native shorts or
3321 longs--as you can see from above for example a bare C<l> does mean
3322 exactly 32 bits, the native C<long> (as seen by the local C compiler)
3323 may be larger.  This is an issue mainly in 64-bit platforms.  You can
3324 see whether using C<!> makes any difference by
3325
3326         print length(pack("s")), " ", length(pack("s!")), "\n";
3327         print length(pack("l")), " ", length(pack("l!")), "\n";
3328
3329 C<i!> and C<I!> also work but only because of completeness;
3330 they are identical to C<i> and C<I>.
3331
3332 The actual sizes (in bytes) of native shorts, ints, longs, and long
3333 longs on the platform where Perl was built are also available via
3334 L<Config>:
3335
3336        use Config;
3337        print $Config{shortsize},    "\n";
3338        print $Config{intsize},      "\n";
3339        print $Config{longsize},     "\n";
3340        print $Config{longlongsize}, "\n";
3341
3342 (The C<$Config{longlongsize}> will be undefine if your system does
3343 not support long longs.)
3344
3345 =item *
3346
3347 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J>
3348 are inherently non-portable between processors and operating systems
3349 because they obey the native byteorder and endianness.  For example a
3350 4-byte integer 0x12345678 (305419896 decimal) would be ordered natively
3351 (arranged in and handled by the CPU registers) into bytes as
3352
3353         0x12 0x34 0x56 0x78     # big-endian
3354         0x78 0x56 0x34 0x12     # little-endian
3355
3356 Basically, the Intel and VAX CPUs are little-endian, while everybody
3357 else, for example Motorola m68k/88k, PPC, Sparc, HP PA, Power, and
3358 Cray are big-endian.  Alpha and MIPS can be either: Digital/Compaq
3359 used/uses them in little-endian mode; SGI/Cray uses them in big-endian
3360 mode.
3361
3362 The names `big-endian' and `little-endian' are comic references to
3363 the classic "Gulliver's Travels" (via the paper "On Holy Wars and a
3364 Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and
3365 the egg-eating habits of the Lilliputians.
3366
3367 Some systems may have even weirder byte orders such as
3368
3369         0x56 0x78 0x12 0x34
3370         0x34 0x12 0x78 0x56
3371
3372 You can see your system's preference with
3373
3374         print join(" ", map { sprintf "%#02x", $_ }
3375                             unpack("C*",pack("L",0x12345678))), "\n";
3376
3377 The byteorder on the platform where Perl was built is also available
3378 via L<Config>:
3379
3380         use Config;
3381         print $Config{byteorder}, "\n";
3382
3383 Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'>
3384 and C<'87654321'> are big-endian.
3385
3386 If you want portable packed integers use the formats C<n>, C<N>,
3387 C<v>, and C<V>, their byte endianness and size are known.
3388 See also L<perlport>.
3389
3390 =item *
3391
3392 Real numbers (floats and doubles) are in the native machine format only;
3393 due to the multiplicity of floating formats around, and the lack of a
3394 standard "network" representation, no facility for interchange has been
3395 made.  This means that packed floating point data written on one machine
3396 may not be readable on another - even if both use IEEE floating point
3397 arithmetic (as the endian-ness of the memory representation is not part
3398 of the IEEE spec).  See also L<perlport>.
3399
3400 Note that Perl uses doubles internally for all numeric calculation, and
3401 converting from double into float and thence back to double again will
3402 lose precision (i.e., C<unpack("f", pack("f", $foo)>) will not in general
3403 equal $foo).
3404
3405 =item *
3406
3407 If the pattern begins with a C<U>, the resulting string will be treated
3408 as Unicode-encoded. You can force UTF8 encoding on in a string with an
3409 initial C<U0>, and the bytes that follow will be interpreted as Unicode
3410 characters. If you don't want this to happen, you can begin your pattern
3411 with C<C0> (or anything else) to force Perl not to UTF8 encode your
3412 string, and then follow this with a C<U*> somewhere in your pattern.
3413
3414 =item *
3415
3416 You must yourself do any alignment or padding by inserting for example
3417 enough C<'x'>es while packing.  There is no way to pack() and unpack()
3418 could know where the bytes are going to or coming from.  Therefore
3419 C<pack> (and C<unpack>) handle their output and input as flat
3420 sequences of bytes.
3421
3422 =item *
3423
3424 A ()-group is a sub-TEMPLATE enclosed in parentheses.  A group may
3425 take a repeat count, both as postfix, and via the C</> template
3426 character.
3427
3428 =item *
3429
3430 C<x> and C<X> accept C<!> modifier.  In this case they act as
3431 alignment commands: they jump forward/back to the closest position
3432 aligned at a multiple of C<count> bytes.  For example, to pack() or
3433 unpack() C's C<struct {char c; double d; char cc[2]}> one may need to
3434 use the template C<C x![d] d C[2]>; this assumes that doubles must be
3435 aligned on the double's size.
3436
3437 For alignment commands C<count> of 0 is equivalent to C<count> of 1;
3438 both result in no-ops.
3439
3440 =item *
3441
3442 A comment in a TEMPLATE starts with C<#> and goes to the end of line.
3443
3444 =item *
3445
3446 If TEMPLATE requires more arguments to pack() than actually given, pack()
3447 assumes additional C<""> arguments.  If TEMPLATE requires less arguments
3448 to pack() than actually given, extra arguments are ignored.
3449
3450 =back
3451
3452 Examples:
3453
3454     $foo = pack("CCCC",65,66,67,68);
3455     # foo eq "ABCD"
3456     $foo = pack("C4",65,66,67,68);
3457     # same thing
3458     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
3459     # same thing with Unicode circled letters
3460
3461     $foo = pack("ccxxcc",65,66,67,68);
3462     # foo eq "AB\0\0CD"
3463
3464     # note: the above examples featuring "C" and "c" are true
3465     # only on ASCII and ASCII-derived systems such as ISO Latin 1
3466     # and UTF-8.  In EBCDIC the first example would be
3467     # $foo = pack("CCCC",193,194,195,196);
3468
3469     $foo = pack("s2",1,2);
3470     # "\1\0\2\0" on little-endian
3471     # "\0\1\0\2" on big-endian
3472
3473     $foo = pack("a4","abcd","x","y","z");
3474     # "abcd"
3475
3476     $foo = pack("aaaa","abcd","x","y","z");
3477     # "axyz"
3478
3479     $foo = pack("a14","abcdefg");
3480     # "abcdefg\0\0\0\0\0\0\0"
3481
3482     $foo = pack("i9pl", gmtime);
3483     # a real struct tm (on my system anyway)
3484
3485     $utmp_template = "Z8 Z8 Z16 L";
3486     $utmp = pack($utmp_template, @utmp1);
3487     # a struct utmp (BSDish)
3488
3489     @utmp2 = unpack($utmp_template, $utmp);
3490     # "@utmp1" eq "@utmp2"
3491
3492     sub bintodec {
3493         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
3494     }
3495
3496     $foo = pack('sx2l', 12, 34);
3497     # short 12, two zero bytes padding, long 34
3498     $bar = pack('s@4l', 12, 34);
3499     # short 12, zero fill to position 4, long 34
3500     # $foo eq $bar
3501
3502 The same template may generally also be used in unpack().
3503
3504 =item package NAMESPACE
3505
3506 =item package
3507
3508 Declares the compilation unit as being in the given namespace.  The scope
3509 of the package declaration is from the declaration itself through the end
3510 of the enclosing block, file, or eval (the same as the C<my> operator).
3511 All further unqualified dynamic identifiers will be in this namespace.
3512 A package statement affects only dynamic variables--including those
3513 you've used C<local> on--but I<not> lexical variables, which are created
3514 with C<my>.  Typically it would be the first declaration in a file to
3515 be included by the C<require> or C<use> operator.  You can switch into a
3516 package in more than one place; it merely influences which symbol table
3517 is used by the compiler for the rest of that block.  You can refer to
3518 variables and filehandles in other packages by prefixing the identifier
3519 with the package name and a double colon:  C<$Package::Variable>.
3520 If the package name is null, the C<main> package as assumed.  That is,
3521 C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>,
3522 still seen in older code).
3523
3524 If NAMESPACE is omitted, then there is no current package, and all
3525 identifiers must be fully qualified or lexicals.  However, you are
3526 strongly advised not to make use of this feature. Its use can cause
3527 unexpected behaviour, even crashing some versions of Perl. It is
3528 deprecated, and will be removed from a future release.
3529
3530 See L<perlmod/"Packages"> for more information about packages, modules,
3531 and classes.  See L<perlsub> for other scoping issues.
3532
3533 =item pipe READHANDLE,WRITEHANDLE
3534
3535 Opens a pair of connected pipes like the corresponding system call.
3536 Note that if you set up a loop of piped processes, deadlock can occur
3537 unless you are very careful.  In addition, note that Perl's pipes use
3538 IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE
3539 after each command, depending on the application.
3540
3541 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
3542 for examples of such things.
3543
3544 On systems that support a close-on-exec flag on files, the flag will be set
3545 for the newly opened file descriptors as determined by the value of $^F.
3546 See L<perlvar/$^F>.
3547
3548 =item pop ARRAY
3549
3550 =item pop
3551
3552 Pops and returns the last value of the array, shortening the array by
3553 one element.  Has an effect similar to
3554
3555     $ARRAY[$#ARRAY--]
3556
3557 If there are no elements in the array, returns the undefined value
3558 (although this may happen at other times as well).  If ARRAY is
3559 omitted, pops the C<@ARGV> array in the main program, and the C<@_>
3560 array in subroutines, just like C<shift>.
3561
3562 =item pos SCALAR
3563
3564 =item pos
3565
3566 Returns the offset of where the last C<m//g> search left off for the variable
3567 in question (C<$_> is used when the variable is not specified).  May be
3568 modified to change that offset.  Such modification will also influence
3569 the C<\G> zero-width assertion in regular expressions.  See L<perlre> and
3570 L<perlop>.
3571
3572 =item print FILEHANDLE LIST
3573
3574 =item print LIST
3575
3576 =item print
3577
3578 Prints a string or a list of strings.  Returns true if successful.
3579 FILEHANDLE may be a scalar variable name, in which case the variable
3580 contains the name of or a reference to the filehandle, thus introducing
3581 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
3582 the next token is a term, it may be misinterpreted as an operator
3583 unless you interpose a C<+> or put parentheses around the arguments.)
3584 If FILEHANDLE is omitted, prints by default to standard output (or
3585 to the last selected output channel--see L</select>).  If LIST is
3586 also omitted, prints C<$_> to the currently selected output channel.
3587 To set the default output channel to something other than STDOUT
3588 use the select operation.  The current value of C<$,> (if any) is
3589 printed between each LIST item.  The current value of C<$\> (if
3590 any) is printed after the entire LIST has been printed.  Because
3591 print takes a LIST, anything in the LIST is evaluated in list
3592 context, and any subroutine that you call will have one or more of
3593 its expressions evaluated in list context.  Also be careful not to
3594 follow the print keyword with a left parenthesis unless you want
3595 the corresponding right parenthesis to terminate the arguments to
3596 the print--interpose a C<+> or put parentheses around all the
3597 arguments.
3598
3599 Note that if you're storing FILEHANDLES in an array or other expression,
3600 you will have to use a block returning its value instead:
3601
3602     print { $files[$i] } "stuff\n";
3603     print { $OK ? STDOUT : STDERR } "stuff\n";
3604
3605 =item printf FILEHANDLE FORMAT, LIST
3606
3607 =item printf FORMAT, LIST
3608
3609 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
3610 (the output record separator) is not appended.  The first argument
3611 of the list will be interpreted as the C<printf> format. See C<sprintf>
3612 for an explanation of the format argument. If C<use locale> is in effect,
3613 the character used for the decimal point in formatted real numbers is
3614 affected by the LC_NUMERIC locale.  See L<perllocale>.
3615
3616 Don't fall into the trap of using a C<printf> when a simple
3617 C<print> would do.  The C<print> is more efficient and less
3618 error prone.
3619
3620 =item prototype FUNCTION
3621
3622 Returns the prototype of a function as a string (or C<undef> if the
3623 function has no prototype).  FUNCTION is a reference to, or the name of,
3624 the function whose prototype you want to retrieve.
3625
3626 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
3627 name for Perl builtin.  If the builtin is not I<overridable> (such as
3628 C<qw//>) or its arguments cannot be expressed by a prototype (such as
3629 C<system>) returns C<undef> because the builtin does not really behave
3630 like a Perl function.  Otherwise, the string describing the equivalent
3631 prototype is returned.
3632
3633 =item push ARRAY,LIST
3634
3635 Treats ARRAY as a stack, and pushes the values of LIST
3636 onto the end of ARRAY.  The length of ARRAY increases by the length of
3637 LIST.  Has the same effect as
3638
3639     for $value (LIST) {
3640         $ARRAY[++$#ARRAY] = $value;
3641     }
3642
3643 but is more efficient.  Returns the new number of elements in the array.
3644
3645 =item q/STRING/
3646
3647 =item qq/STRING/
3648
3649 =item qr/STRING/
3650
3651 =item qx/STRING/
3652
3653 =item qw/STRING/
3654
3655 Generalized quotes.  See L<perlop/"Regexp Quote-Like Operators">.
3656
3657 =item quotemeta EXPR
3658
3659 =item quotemeta
3660
3661 Returns the value of EXPR with all non-"word"
3662 characters backslashed.  (That is, all characters not matching
3663 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
3664 returned string, regardless of any locale settings.)
3665 This is the internal function implementing
3666 the C<\Q> escape in double-quoted strings.
3667
3668 If EXPR is omitted, uses C<$_>.
3669
3670 =item rand EXPR
3671
3672 =item rand
3673
3674 Returns a random fractional number greater than or equal to C<0> and less
3675 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
3676 omitted, or a C<0>, the value C<1> is used.  Automatically calls C<srand>
3677 unless C<srand> has already been called.  See also C<srand>.
3678
3679 Apply C<int()> to the value returned by C<rand()> if you want random
3680 integers instead of random fractional numbers.  For example,
3681
3682     int(rand(10))
3683
3684 returns a random integer between C<0> and C<9>, inclusive.
3685
3686 (Note: If your rand function consistently returns numbers that are too
3687 large or too small, then your version of Perl was probably compiled
3688 with the wrong number of RANDBITS.)
3689
3690 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
3691
3692 =item read FILEHANDLE,SCALAR,LENGTH
3693
3694 Attempts to read LENGTH I<characters> of data into variable SCALAR
3695 from the specified FILEHANDLE.  Returns the number of characters
3696 actually read, C<0> at end of file, or undef if there was an error.
3697 SCALAR will be grown or shrunk to the length actually read.  If SCALAR
3698 needs growing, the new bytes will be zero bytes.  An OFFSET may be
3699 specified to place the read data into some other place in SCALAR than
3700 the beginning.  The call is actually implemented in terms of either
3701 Perl's or system's fread() call.  To get a true read(2) system call,
3702 see C<sysread>.
3703
3704 Note the I<characters>: depending on the status of the filehandle,
3705 either (8-bit) bytes or characters are read.  By default all
3706 filehandles operate on bytes, but for example if the filehandle has
3707 been opened with the C<:utf8> discipline (see L</open>, and the C<open>
3708 pragma, L<open>), the I/O will operate on characters, not bytes.
3709
3710 =item readdir DIRHANDLE
3711
3712 Returns the next directory entry for a directory opened by C<opendir>.
3713 If used in list context, returns all the rest of the entries in the
3714 directory.  If there are no more entries, returns an undefined value in
3715 scalar context or a null list in list context.
3716
3717 If you're planning to filetest the return values out of a C<readdir>, you'd
3718 better prepend the directory in question.  Otherwise, because we didn't
3719 C<chdir> there, it would have been testing the wrong file.
3720
3721     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
3722     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
3723     closedir DIR;
3724
3725 =item readline EXPR
3726
3727 Reads from the filehandle whose typeglob is contained in EXPR.  In scalar
3728 context, each call reads and returns the next line, until end-of-file is
3729 reached, whereupon the subsequent call returns undef.  In list context,
3730 reads until end-of-file is reached and returns a list of lines.  Note that
3731 the notion of "line" used here is however you may have defined it
3732 with C<$/> or C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
3733
3734 When C<$/> is set to C<undef>, when readline() is in scalar
3735 context (i.e. file slurp mode), and when an empty file is read, it
3736 returns C<''> the first time, followed by C<undef> subsequently.
3737
3738 This is the internal function implementing the C<< <EXPR> >>
3739 operator, but you can use it directly.  The C<< <EXPR> >>
3740 operator is discussed in more detail in L<perlop/"I/O Operators">.
3741
3742     $line = <STDIN>;
3743     $line = readline(*STDIN);           # same thing
3744
3745 =item readlink EXPR
3746
3747 =item readlink
3748
3749 Returns the value of a symbolic link, if symbolic links are
3750 implemented.  If not, gives a fatal error.  If there is some system
3751 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
3752 omitted, uses C<$_>.
3753
3754 =item readpipe EXPR
3755
3756 EXPR is executed as a system command.
3757 The collected standard output of the command is returned.
3758 In scalar context, it comes back as a single (potentially
3759 multi-line) string.  In list context, returns a list of lines
3760 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
3761 This is the internal function implementing the C<qx/EXPR/>
3762 operator, but you can use it directly.  The C<qx/EXPR/>
3763 operator is discussed in more detail in L<perlop/"I/O Operators">.
3764
3765 =item recv SOCKET,SCALAR,LENGTH,FLAGS
3766
3767 Receives a message on a socket.  Attempts to receive LENGTH characters
3768 of data into variable SCALAR from the specified SOCKET filehandle.
3769 SCALAR will be grown or shrunk to the length actually read.  Takes the
3770 same flags as the system call of the same name.  Returns the address
3771 of the sender if SOCKET's protocol supports this; returns an empty
3772 string otherwise.  If there's an error, returns the undefined value.
3773 This call is actually implemented in terms of recvfrom(2) system call.
3774 See L<perlipc/"UDP: Message Passing"> for examples.
3775
3776 Note the I<characters>: depending on the status of the socket, either
3777 (8-bit) bytes or characters are received.  By default all sockets
3778 operate on bytes, but for example if the socket has been changed using
3779 binmode() to operate with the C<:utf8> discipline (see the C<open>
3780 pragma, L<open>), the I/O will operate on characters, not bytes.
3781
3782 =item redo LABEL
3783
3784 =item redo
3785
3786 The C<redo> command restarts the loop block without evaluating the
3787 conditional again.  The C<continue> block, if any, is not executed.  If
3788 the LABEL is omitted, the command refers to the innermost enclosing
3789 loop.  This command is normally used by programs that want to lie to
3790 themselves about what was just input:
3791
3792     # a simpleminded Pascal comment stripper
3793     # (warning: assumes no { or } in strings)
3794     LINE: while (<STDIN>) {
3795         while (s|({.*}.*){.*}|$1 |) {}
3796         s|{.*}| |;
3797         if (s|{.*| |) {
3798             $front = $_;
3799             while (<STDIN>) {
3800                 if (/}/) {      # end of comment?
3801                     s|^|$front\{|;
3802                     redo LINE;
3803                 }
3804             }
3805         }
3806         print;
3807     }
3808
3809 C<redo> cannot be used to retry a block which returns a value such as
3810 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
3811 a grep() or map() operation.
3812
3813 Note that a block by itself is semantically identical to a loop
3814 that executes once.  Thus C<redo> inside such a block will effectively
3815 turn it into a looping construct.
3816
3817 See also L</continue> for an illustration of how C<last>, C<next>, and
3818 C<redo> work.
3819
3820 =item ref EXPR
3821
3822 =item ref
3823
3824 Returns a true value if EXPR is a reference, false otherwise.  If EXPR
3825 is not specified, C<$_> will be used.  The value returned depends on the
3826 type of thing the reference is a reference to.
3827 Builtin types include:
3828
3829     SCALAR
3830     ARRAY
3831     HASH
3832     CODE
3833     REF
3834     GLOB
3835     LVALUE
3836
3837 If the referenced object has been blessed into a package, then that package
3838 name is returned instead.  You can think of C<ref> as a C<typeof> operator.
3839
3840     if (ref($r) eq "HASH") {
3841         print "r is a reference to a hash.\n";
3842     }
3843     unless (ref($r)) {
3844         print "r is not a reference at all.\n";
3845     }
3846     if (UNIVERSAL::isa($r, "HASH")) {  # for subclassing
3847         print "r is a reference to something that isa hash.\n";
3848     }
3849
3850 See also L<perlref>.
3851
3852 =item rename OLDNAME,NEWNAME
3853
3854 Changes the name of a file; an existing file NEWNAME will be
3855 clobbered.  Returns true for success, false otherwise.
3856
3857 Behavior of this function varies wildly depending on your system
3858 implementation.  For example, it will usually not work across file system
3859 boundaries, even though the system I<mv> command sometimes compensates
3860 for this.  Other restrictions include whether it works on directories,
3861 open files, or pre-existing files.  Check L<perlport> and either the
3862 rename(2) manpage or equivalent system documentation for details.
3863
3864 =item require VERSION
3865
3866 =item require EXPR
3867
3868 =item require
3869
3870 Demands a version of Perl specified by VERSION, or demands some semantics
3871 specified by EXPR or by C<$_> if EXPR is not supplied.
3872
3873 VERSION may be either a numeric argument such as 5.006, which will be
3874 compared to C<$]>, or a literal of the form v5.6.1, which will be compared
3875 to C<$^V> (aka $PERL_VERSION).  A fatal error is produced at run time if
3876 VERSION is greater than the version of the current Perl interpreter.
3877 Compare with L</use>, which can do a similar check at compile time.
3878
3879 Specifying VERSION as a literal of the form v5.6.1 should generally be
3880 avoided, because it leads to misleading error messages under earlier
3881 versions of Perl which do not support this syntax.  The equivalent numeric
3882 version should be used instead.
3883
3884     require v5.6.1;     # run time version check
3885     require 5.6.1;      # ditto
3886     require 5.006_001;  # ditto; preferred for backwards compatibility
3887
3888 Otherwise, demands that a library file be included if it hasn't already
3889 been included.  The file is included via the do-FILE mechanism, which is
3890 essentially just a variety of C<eval>.  Has semantics similar to the following
3891 subroutine:
3892
3893     sub require {
3894         my($filename) = @_;
3895         return 1 if $INC{$filename};
3896         my($realfilename,$result);
3897         ITER: {
3898             foreach $prefix (@INC) {
3899                 $realfilename = "$prefix/$filename";
3900                 if (-f $realfilename) {
3901                     $INC{$filename} = $realfilename;
3902                     $result = do $realfilename;
3903                     last ITER;
3904                 }
3905             }
3906             die "Can't find $filename in \@INC";
3907         }
3908         delete $INC{$filename} if $@ || !$result;
3909         die $@ if $@;
3910         die "$filename did not return true value" unless $result;
3911         return $result;
3912     }
3913
3914 Note that the file will not be included twice under the same specified
3915 name.  The file must return true as the last statement to indicate
3916 successful execution of any initialization code, so it's customary to
3917 end such a file with C<1;> unless you're sure it'll return true
3918 otherwise.  But it's better just to put the C<1;>, in case you add more
3919 statements.
3920
3921 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
3922 replaces "F<::>" with "F</>" in the filename for you,
3923 to make it easy to load standard modules.  This form of loading of
3924 modules does not risk altering your namespace.
3925
3926 In other words, if you try this:
3927
3928         require Foo::Bar;    # a splendid bareword
3929
3930 The require function will actually look for the "F<Foo/Bar.pm>" file in the
3931 directories specified in the C<@INC> array.
3932
3933 But if you try this:
3934
3935         $class = 'Foo::Bar';
3936         require $class;      # $class is not a bareword
3937     #or
3938         require "Foo::Bar";  # not a bareword because of the ""
3939
3940 The require function will look for the "F<Foo::Bar>" file in the @INC array and
3941 will complain about not finding "F<Foo::Bar>" there.  In this case you can do:
3942
3943         eval "require $class";
3944
3945 You can also insert hooks into the import facility, by putting directly
3946 Perl code into the @INC array.  There are three forms of hooks: subroutine
3947 references, array references and blessed objects.
3948
3949 Subroutine references are the simplest case.  When the inclusion system
3950 walks through @INC and encounters a subroutine, this subroutine gets
3951 called with two parameters, the first being a reference to itself, and the
3952 second the name of the file to be included (e.g. "F<Foo/Bar.pm>").  The
3953 subroutine should return C<undef> or a filehandle, from which the file to
3954 include will be read.  If C<undef> is returned, C<require> will look at
3955 the remaining elements of @INC.
3956
3957 If the hook is an array reference, its first element must be a subroutine
3958 reference.  This subroutine is called as above, but the first parameter is
3959 the array reference.  This enables to pass indirectly some arguments to
3960 the subroutine.
3961
3962 In other words, you can write:
3963
3964     push @INC, \&my_sub;
3965     sub my_sub {
3966         my ($coderef, $filename) = @_;  # $coderef is \&my_sub
3967         ...
3968     }
3969
3970 or:
3971
3972     push @INC, [ \&my_sub, $x, $y, ... ];
3973     sub my_sub {
3974         my ($arrayref, $filename) = @_;
3975         # Retrieve $x, $y, ...
3976         my @parameters = @$arrayref[1..$#$arrayref];
3977         ...
3978     }
3979
3980 If the hook is an object, it must provide an INC method, that will be
3981 called as above, the first parameter being the object itself.  (Note that
3982 you must fully qualify the sub's name, as it is always forced into package
3983 C<main>.)  Here is a typical code layout:
3984
3985     # In Foo.pm
3986     package Foo;
3987     sub new { ... }
3988     sub Foo::INC {
3989         my ($self, $filename) = @_;
3990         ...
3991     }
3992
3993     # In the main program
3994     push @INC, new Foo(...);
3995
3996 Note that these hooks are also permitted to set the %INC entry
3997 corresponding to the files they have loaded. See L<perlvar/%INC>.
3998
3999 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
4000
4001 =item reset EXPR
4002
4003 =item reset
4004
4005 Generally used in a C<continue> block at the end of a loop to clear
4006 variables and reset C<??> searches so that they work again.  The
4007 expression is interpreted as a list of single characters (hyphens
4008 allowed for ranges).  All variables and arrays beginning with one of
4009 those letters are reset to their pristine state.  If the expression is
4010 omitted, one-match searches (C<?pattern?>) are reset to match again.  Resets
4011 only variables or searches in the current package.  Always returns
4012 1.  Examples:
4013
4014     reset 'X';          # reset all X variables
4015     reset 'a-z';        # reset lower case variables
4016     reset;              # just reset ?one-time? searches
4017
4018 Resetting C<"A-Z"> is not recommended because you'll wipe out your
4019 C<@ARGV> and C<@INC> arrays and your C<%ENV> hash.  Resets only package
4020 variables--lexical variables are unaffected, but they clean themselves
4021 up on scope exit anyway, so you'll probably want to use them instead.
4022 See L</my>.
4023
4024 =item return EXPR
4025
4026 =item return
4027
4028 Returns from a subroutine, C<eval>, or C<do FILE> with the value
4029 given in EXPR.  Evaluation of EXPR may be in list, scalar, or void
4030 context, depending on how the return value will be used, and the context
4031 may vary from one execution to the next (see C<wantarray>).  If no EXPR
4032 is given, returns an empty list in list context, the undefined value in
4033 scalar context, and (of course) nothing at all in a void context.
4034
4035 (Note that in the absence of an explicit C<return>, a subroutine, eval,
4036 or do FILE will automatically return the value of the last expression
4037 evaluated.)
4038
4039 =item reverse LIST
4040
4041 In list context, returns a list value consisting of the elements
4042 of LIST in the opposite order.  In scalar context, concatenates the
4043 elements of LIST and returns a string value with all characters
4044 in the opposite order.
4045
4046     print reverse <>;           # line tac, last line first
4047
4048     undef $/;                   # for efficiency of <>
4049     print scalar reverse <>;    # character tac, last line tsrif
4050
4051 This operator is also handy for inverting a hash, although there are some
4052 caveats.  If a value is duplicated in the original hash, only one of those
4053 can be represented as a key in the inverted hash.  Also, this has to
4054 unwind one hash and build a whole new one, which may take some time
4055 on a large hash, such as from a DBM file.
4056
4057     %by_name = reverse %by_address;     # Invert the hash
4058
4059 =item rewinddir DIRHANDLE
4060
4061 Sets the current position to the beginning of the directory for the
4062 C<readdir> routine on DIRHANDLE.
4063
4064 =item rindex STR,SUBSTR,POSITION
4065
4066 =item rindex STR,SUBSTR
4067
4068 Works just like index() except that it returns the position of the LAST
4069 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
4070 last occurrence at or before that position.
4071
4072 =item rmdir FILENAME
4073
4074 =item rmdir
4075
4076 Deletes the directory specified by FILENAME if that directory is empty.  If it
4077 succeeds it returns true, otherwise it returns false and sets C<$!> (errno).  If
4078 FILENAME is omitted, uses C<$_>.
4079
4080 =item s///
4081
4082 The substitution operator.  See L<perlop>.
4083
4084 =item scalar EXPR
4085
4086 Forces EXPR to be interpreted in scalar context and returns the value
4087 of EXPR.
4088
4089     @counts = ( scalar @a, scalar @b, scalar @c );
4090
4091 There is no equivalent operator to force an expression to
4092 be interpolated in list context because in practice, this is never
4093 needed.  If you really wanted to do so, however, you could use
4094 the construction C<@{[ (some expression) ]}>, but usually a simple
4095 C<(some expression)> suffices.
4096
4097 Because C<scalar> is unary operator, if you accidentally use for EXPR a
4098 parenthesized list, this behaves as a scalar comma expression, evaluating
4099 all but the last element in void context and returning the final element
4100 evaluated in scalar context.  This is seldom what you want.
4101
4102 The following single statement:
4103
4104         print uc(scalar(&foo,$bar)),$baz;
4105
4106 is the moral equivalent of these two:
4107
4108         &foo;
4109         print(uc($bar),$baz);
4110
4111 See L<perlop> for more details on unary operators and the comma operator.
4112
4113 =item seek FILEHANDLE,POSITION,WHENCE
4114
4115 Sets FILEHANDLE's position, just like the C<fseek> call of C<stdio>.
4116 FILEHANDLE may be an expression whose value gives the name of the
4117 filehandle.  The values for WHENCE are C<0> to set the new position
4118 I<in bytes> to POSITION, C<1> to set it to the current position plus
4119 POSITION, and C<2> to set it to EOF plus POSITION (typically
4120 negative).  For WHENCE you may use the constants C<SEEK_SET>,
4121 C<SEEK_CUR>, and C<SEEK_END> (start of the file, current position, end
4122 of the file) from the Fcntl module.  Returns C<1> upon success, C<0>
4123 otherwise.
4124
4125 Note the I<in bytes>: even if the filehandle has been set to
4126 operate on characters (for example by using the C<:utf8> open
4127 discipline), tell() will return byte offsets, not character offsets
4128 (because implementing that would render seek() and tell() rather slow).
4129
4130 If you want to position file for C<sysread> or C<syswrite>, don't use
4131 C<seek>--buffering makes its effect on the file's system position
4132 unpredictable and non-portable.  Use C<sysseek> instead.
4133
4134 Due to the rules and rigors of ANSI C, on some systems you have to do a
4135 seek whenever you switch between reading and writing.  Amongst other
4136 things, this may have the effect of calling stdio's clearerr(3).
4137 A WHENCE of C<1> (C<SEEK_CUR>) is useful for not moving the file position:
4138
4139     seek(TEST,0,1);
4140
4141 This is also useful for applications emulating C<tail -f>.  Once you hit
4142 EOF on your read, and then sleep for a while, you might have to stick in a
4143 seek() to reset things.  The C<seek> doesn't change the current position,
4144 but it I<does> clear the end-of-file condition on the handle, so that the
4145 next C<< <FILE> >> makes Perl try again to read something.  We hope.
4146
4147 If that doesn't work (some IO implementations are particularly
4148 cantankerous), then you may need something more like this:
4149
4150     for (;;) {
4151         for ($curpos = tell(FILE); $_ = <FILE>;
4152              $curpos = tell(FILE)) {
4153             # search for some stuff and put it into files
4154         }
4155         sleep($for_a_while);
4156         seek(FILE, $curpos, 0);
4157     }
4158
4159 =item seekdir DIRHANDLE,POS
4160
4161 Sets the current position for the C<readdir> routine on DIRHANDLE.  POS
4162 must be a value returned by C<telldir>.  Has the same caveats about
4163 possible directory compaction as the corresponding system library
4164 routine.
4165
4166 =item select FILEHANDLE
4167
4168 =item select
4169
4170 Returns the currently selected filehandle.  Sets the current default
4171 filehandle for output, if FILEHANDLE is supplied.  This has two
4172 effects: first, a C<write> or a C<print> without a filehandle will
4173 default to this FILEHANDLE.  Second, references to variables related to
4174 output will refer to this output channel.  For example, if you have to
4175 set the top of form format for more than one output channel, you might
4176 do the following:
4177
4178     select(REPORT1);
4179     $^ = 'report1_top';
4180     select(REPORT2);
4181     $^ = 'report2_top';
4182
4183 FILEHANDLE may be an expression whose value gives the name of the
4184 actual filehandle.  Thus:
4185
4186     $oldfh = select(STDERR); $| = 1; select($oldfh);
4187
4188 Some programmers may prefer to think of filehandles as objects with
4189 methods, preferring to write the last example as:
4190
4191     use IO::Handle;
4192     STDERR->autoflush(1);
4193
4194 =item select RBITS,WBITS,EBITS,TIMEOUT
4195
4196 This calls the select(2) system call with the bit masks specified, which
4197 can be constructed using C<fileno> and C<vec>, along these lines:
4198
4199     $rin = $win = $ein = '';
4200     vec($rin,fileno(STDIN),1) = 1;
4201     vec($win,fileno(STDOUT),1) = 1;
4202     $ein = $rin | $win;
4203
4204 If you want to select on many filehandles you might wish to write a
4205 subroutine:
4206
4207     sub fhbits {
4208         my(@fhlist) = split(' ',$_[0]);
4209         my($bits);
4210         for (@fhlist) {
4211             vec($bits,fileno($_),1) = 1;
4212         }
4213         $bits;
4214     }
4215     $rin = fhbits('STDIN TTY SOCK');
4216
4217 The usual idiom is:
4218
4219     ($nfound,$timeleft) =
4220       select($rout=$rin, $wout=$win, $eout=$ein, $timeout);
4221
4222 or to block until something becomes ready just do this
4223
4224     $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);
4225
4226 Most systems do not bother to return anything useful in $timeleft, so
4227 calling select() in scalar context just returns $nfound.
4228
4229 Any of the bit masks can also be undef.  The timeout, if specified, is
4230 in seconds, which may be fractional.  Note: not all implementations are
4231 capable of returning the $timeleft.  If not, they always return
4232 $timeleft equal to the supplied $timeout.
4233
4234 You can effect a sleep of 250 milliseconds this way:
4235
4236     select(undef, undef, undef, 0.25);
4237
4238 B<WARNING>: One should not attempt to mix buffered I/O (like C<read>
4239 or <FH>) with C<select>, except as permitted by POSIX, and even
4240 then only on POSIX systems.  You have to use C<sysread> instead.
4241
4242 =item semctl ID,SEMNUM,CMD,ARG
4243
4244 Calls the System V IPC function C<semctl>.  You'll probably have to say
4245
4246     use IPC::SysV;
4247
4248 first to get the correct constant definitions.  If CMD is IPC_STAT or
4249 GETALL, then ARG must be a variable which will hold the returned
4250 semid_ds structure or semaphore value array.  Returns like C<ioctl>:
4251 the undefined value for error, "C<0 but true>" for zero, or the actual
4252 return value otherwise.  The ARG must consist of a vector of native
4253 short integers, which may be created with C<pack("s!",(0)x$nsem)>.
4254 See also L<perlipc/"SysV IPC">, C<IPC::SysV>, C<IPC::Semaphore>
4255 documentation.
4256
4257 =item semget KEY,NSEMS,FLAGS
4258
4259 Calls the System V IPC function semget.  Returns the semaphore id, or
4260 the undefined value if there is an error.  See also
4261 L<perlipc/"SysV IPC">, C<IPC::SysV>, C<IPC::SysV::Semaphore>
4262 documentation.
4263
4264 =item semop KEY,OPSTRING
4265
4266 Calls the System V IPC function semop to perform semaphore operations
4267 such as signalling and waiting.  OPSTRING must be a packed array of
4268 semop structures.  Each semop structure can be generated with
4269 C<pack("s!3", $semnum, $semop, $semflag)>.  The number of semaphore
4270 operations is implied by the length of OPSTRING.  Returns true if
4271 successful, or false if there is an error.  As an example, the
4272 following code waits on semaphore $semnum of semaphore id $semid:
4273
4274     $semop = pack("s!3", $semnum, -1, 0);
4275     die "Semaphore trouble: $!\n" unless semop($semid, $semop);
4276
4277 To signal the semaphore, replace C<-1> with C<1>.  See also
4278 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::SysV::Semaphore>
4279 documentation.
4280
4281 =item send SOCKET,MSG,FLAGS,TO
4282
4283 =item send SOCKET,MSG,FLAGS
4284
4285 Sends a message on a socket.  Attempts to send the scalar MSG to the
4286 SOCKET filehandle.  Takes the same flags as the system call of the
4287 same name.  On unconnected sockets you must specify a destination to
4288 send TO, in which case it does a C C<sendto>.  Returns the number of
4289 characters sent, or the undefined value if there is an error.  The C
4290 system call sendmsg(2) is currently unimplemented.  See
4291 L<perlipc/"UDP: Message Passing"> for examples.
4292
4293 Note the I<characters>: depending on the status of the socket, either
4294 (8-bit) bytes or characters are sent.  By default all sockets operate
4295 on bytes, but for example if the socket has been changed using
4296 binmode() to operate with the C<:utf8> discipline (see L</open>, or
4297 the C<open> pragma, L<open>), the I/O will operate on characters, not
4298 bytes.
4299
4300 =item setpgrp PID,PGRP
4301
4302 Sets the current process group for the specified PID, C<0> for the current
4303 process.  Will produce a fatal error if used on a machine that doesn't
4304 implement POSIX setpgid(2) or BSD setpgrp(2).  If the arguments are omitted,
4305 it defaults to C<0,0>.  Note that the BSD 4.2 version of C<setpgrp> does not
4306 accept any arguments, so only C<setpgrp(0,0)> is portable.  See also
4307 C<POSIX::setsid()>.
4308
4309 =item setpriority WHICH,WHO,PRIORITY
4310
4311 Sets the current priority for a process, a process group, or a user.
4312 (See setpriority(2).)  Will produce a fatal error if used on a machine
4313 that doesn't implement setpriority(2).
4314
4315 =item setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL
4316
4317 Sets the socket option requested.  Returns undefined if there is an
4318 error.  OPTVAL may be specified as C<undef> if you don't want to pass an
4319 argument.
4320
4321 =item shift ARRAY
4322
4323 =item shift
4324
4325 Shifts the first value of the array off and returns it, shortening the
4326 array by 1 and moving everything down.  If there are no elements in the
4327 array, returns the undefined value.  If ARRAY is omitted, shifts the
4328 C<@_> array within the lexical scope of subroutines and formats, and the
4329 C<@ARGV> array at file scopes or within the lexical scopes established by
4330 the C<eval ''>, C<BEGIN {}>, C<INIT {}>, C<CHECK {}>, and C<END {}>
4331 constructs.
4332
4333 See also C<unshift>, C<push>, and C<pop>.  C<shift> and C<unshift> do the
4334 same thing to the left end of an array that C<pop> and C<push> do to the
4335 right end.
4336
4337 =item shmctl ID,CMD,ARG
4338
4339 Calls the System V IPC function shmctl.  You'll probably have to say
4340
4341     use IPC::SysV;
4342
4343 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
4344 then ARG must be a variable which will hold the returned C<shmid_ds>
4345 structure.  Returns like ioctl: the undefined value for error, "C<0> but
4346 true" for zero, or the actual return value otherwise.
4347 See also L<perlipc/"SysV IPC"> and C<IPC::SysV> documentation.
4348
4349 =item shmget KEY,SIZE,FLAGS
4350
4351 Calls the System V IPC function shmget.  Returns the shared memory
4352 segment id, or the undefined value if there is an error.
4353 See also L<perlipc/"SysV IPC"> and C<IPC::SysV> documentation.
4354
4355 =item shmread ID,VAR,POS,SIZE
4356
4357 =item shmwrite ID,STRING,POS,SIZE
4358
4359 Reads or writes the System V shared memory segment ID starting at
4360 position POS for size SIZE by attaching to it, copying in/out, and
4361 detaching from it.  When reading, VAR must be a variable that will
4362 hold the data read.  When writing, if STRING is too long, only SIZE
4363 bytes are used; if STRING is too short, nulls are written to fill out
4364 SIZE bytes.  Return true if successful, or false if there is an error.
4365 shmread() taints the variable. See also L<perlipc/"SysV IPC">,
4366 C<IPC::SysV> documentation, and the C<IPC::Shareable> module from CPAN.
4367
4368 =item shutdown SOCKET,HOW
4369
4370 Shuts down a socket connection in the manner indicated by HOW, which
4371 has the same interpretation as in the system call of the same name.
4372
4373     shutdown(SOCKET, 0);    # I/we have stopped reading data
4374     shutdown(SOCKET, 1);    # I/we have stopped writing data
4375     shutdown(SOCKET, 2);    # I/we have stopped using this socket
4376
4377 This is useful with sockets when you want to tell the other
4378 side you're done writing but not done reading, or vice versa.
4379 It's also a more insistent form of close because it also
4380 disables the file descriptor in any forked copies in other
4381 processes.
4382
4383 =item sin EXPR
4384
4385 =item sin
4386
4387 Returns the sine of EXPR (expressed in radians).  If EXPR is omitted,
4388 returns sine of C<$_>.
4389
4390 For the inverse sine operation, you may use the C<Math::Trig::asin>
4391 function, or use this relation:
4392
4393     sub asin { atan2($_[0], sqrt(1 - $_[0] * $_[0])) }
4394
4395 =item sleep EXPR
4396
4397 =item sleep
4398
4399 Causes the script to sleep for EXPR seconds, or forever if no EXPR.
4400 May be interrupted if the process receives a signal such as C<SIGALRM>.
4401 Returns the number of seconds actually slept.  You probably cannot
4402 mix C<alarm> and C<sleep> calls, because C<sleep> is often implemented
4403 using C<alarm>.
4404
4405 On some older systems, it may sleep up to a full second less than what
4406 you requested, depending on how it counts seconds.  Most modern systems
4407 always sleep the full amount.  They may appear to sleep longer than that,
4408 however, because your process might not be scheduled right away in a
4409 busy multitasking system.
4410
4411 For delays of finer granularity than one second, you may use Perl's
4412 C<syscall> interface to access setitimer(2) if your system supports
4413 it, or else see L</select> above.  The Time::HiRes module (from CPAN,
4414 and starting from Perl 5.8 part of the standard distribution) may also
4415 help.
4416
4417 See also the POSIX module's C<pause> function.
4418
4419 =item sockatmark SOCKET
4420
4421 Returns true if the socket is positioned at the out-of-band mark
4422 (also known as the urgent data mark), false otherwise.  Use right
4423 after reading from the socket.
4424
4425 Not available directly, one has to import the function from
4426 the IO::Socket extension
4427
4428     use IO::Socket 'sockatmark';
4429
4430 Even this doesn't guarantee that sockatmark() really is available,
4431 though, because sockatmark() is a relatively recent addition to
4432 the family of socket functions.  If it is unavailable, attempt to
4433 use it will fail
4434
4435         IO::Socket::atmark not implemented on this architecture ...
4436
4437 See also L<IO::Socket>.
4438
4439 =item socket SOCKET,DOMAIN,TYPE,PROTOCOL
4440
4441 Opens a socket of the specified kind and attaches it to filehandle
4442 SOCKET.  DOMAIN, TYPE, and PROTOCOL are specified the same as for
4443 the system call of the same name.  You should C<use Socket> first
4444 to get the proper definitions imported.  See the examples in
4445 L<perlipc/"Sockets: Client/Server Communication">.
4446
4447 On systems that support a close-on-exec flag on files, the flag will
4448 be set for the newly opened file descriptor, as determined by the
4449 value of $^F.  See L<perlvar/$^F>.
4450
4451 =item socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL
4452
4453 Creates an unnamed pair of sockets in the specified domain, of the
4454 specified type.  DOMAIN, TYPE, and PROTOCOL are specified the same as
4455 for the system call of the same name.  If unimplemented, yields a fatal
4456 error.  Returns true if successful.
4457
4458 On systems that support a close-on-exec flag on files, the flag will
4459 be set for the newly opened file descriptors, as determined by the value
4460 of $^F.  See L<perlvar/$^F>.
4461
4462 Some systems defined C<pipe> in terms of C<socketpair>, in which a call
4463 to C<pipe(Rdr, Wtr)> is essentially:
4464
4465     use Socket;
4466     socketpair(Rdr, Wtr, AF_UNIX, SOCK_STREAM, PF_UNSPEC);
4467     shutdown(Rdr, 1);        # no more writing for reader
4468     shutdown(Wtr, 0);        # no more reading for writer
4469
4470 See L<perlipc> for an example of socketpair use.  Perl 5.8 and later will
4471 emulate socketpair using IP sockets to localhost if your system implements
4472 sockets but not socketpair.
4473
4474 =item sort SUBNAME LIST
4475
4476 =item sort BLOCK LIST
4477
4478 =item sort LIST
4479
4480 Sorts the LIST and returns the sorted list value.  If SUBNAME or BLOCK
4481 is omitted, C<sort>s in standard string comparison order.  If SUBNAME is
4482 specified, it gives the name of a subroutine that returns an integer
4483 less than, equal to, or greater than C<0>, depending on how the elements
4484 of the list are to be ordered.  (The C<< <=> >> and C<cmp>
4485 operators are extremely useful in such routines.)  SUBNAME may be a
4486 scalar variable name (unsubscripted), in which case the value provides
4487 the name of (or a reference to) the actual subroutine to use.  In place
4488 of a SUBNAME, you can provide a BLOCK as an anonymous, in-line sort
4489 subroutine.
4490
4491 If the subroutine's prototype is C<($$)>, the elements to be compared
4492 are passed by reference in C<@_>, as for a normal subroutine.  This is
4493 slower than unprototyped subroutines, where the elements to be
4494 compared are passed into the subroutine
4495 as the package global variables $a and $b (see example below).  Note that
4496 in the latter case, it is usually counter-productive to declare $a and
4497 $b as lexicals.
4498
4499 In either case, the subroutine may not be recursive.  The values to be
4500 compared are always passed by reference, so don't modify them.
4501
4502 You also cannot exit out of the sort block or subroutine using any of the
4503 loop control operators described in L<perlsyn> or with C<goto>.
4504
4505 When C<use locale> is in effect, C<sort LIST> sorts LIST according to the
4506 current collation locale.  See L<perllocale>.
4507
4508 Perl 5.6 and earlier used a quicksort algorithm to implement sort.
4509 That algorithm was not stable, and I<could> go quadratic.  (A I<stable> sort
4510 preserves the input order of elements that compare equal.  Although
4511 quicksort's run time is O(NlogN) when averaged over all arrays of
4512 length N, the time can be O(N**2), I<quadratic> behavior, for some
4513 inputs.)  In 5.7, the quicksort implementation was replaced with
4514 a stable mergesort algorithm whose worst case behavior is O(NlogN).
4515 But benchmarks indicated that for some inputs, on some platforms,
4516 the original quicksort was faster.  5.8 has a sort pragma for
4517 limited control of the sort.  Its rather blunt control of the
4518 underlying algorithm may not persist into future perls, but the
4519 ability to characterize the input or output in implementation
4520 independent ways quite probably will.  See L</use>.
4521
4522 Examples:
4523
4524     # sort lexically
4525     @articles = sort @files;
4526
4527     # same thing, but with explicit sort routine
4528     @articles = sort {$a cmp $b} @files;
4529
4530     # now case-insensitively
4531     @articles = sort {uc($a) cmp uc($b)} @files;
4532
4533     # same thing in reversed order
4534     @articles = sort {$b cmp $a} @files;
4535
4536     # sort numerically ascending
4537     @articles = sort {$a <=> $b} @files;
4538
4539     # sort numerically descending
4540     @articles = sort {$b <=> $a} @files;
4541
4542     # this sorts the %age hash by value instead of key
4543     # using an in-line function
4544     @eldest = sort { $age{$b} <=> $age{$a} } keys %age;
4545
4546     # sort using explicit subroutine name
4547     sub byage {
4548         $age{$a} <=> $age{$b};  # presuming numeric
4549     }
4550     @sortedclass = sort byage @class;
4551
4552     sub backwards { $b cmp $a }
4553     @harry  = qw(dog cat x Cain Abel);
4554     @george = qw(gone chased yz Punished Axed);
4555     print sort @harry;
4556             # prints AbelCaincatdogx
4557     print sort backwards @harry;
4558             # prints xdogcatCainAbel
4559     print sort @george, 'to', @harry;
4560             # prints AbelAxedCainPunishedcatchaseddoggonetoxyz
4561
4562     # inefficiently sort by descending numeric compare using
4563     # the first integer after the first = sign, or the
4564     # whole record case-insensitively otherwise
4565
4566     @new = sort {
4567         ($b =~ /=(\d+)/)[0] <=> ($a =~ /=(\d+)/)[0]
4568                             ||
4569                     uc($a)  cmp  uc($b)
4570     } @old;
4571
4572     # same thing, but much more efficiently;
4573     # we'll build auxiliary indices instead
4574     # for speed
4575     @nums = @caps = ();
4576     for (@old) {
4577         push @nums, /=(\d+)/;
4578         push @caps, uc($_);
4579     }
4580
4581     @new = @old[ sort {
4582                         $nums[$b] <=> $nums[$a]
4583                                  ||
4584                         $caps[$a] cmp $caps[$b]
4585                        } 0..$#old
4586                ];
4587
4588     # same thing, but without any temps
4589     @new = map { $_->[0] }
4590            sort { $b->[1] <=> $a->[1]
4591                            ||
4592                   $a->[2] cmp $b->[2]
4593            } map { [$_, /=(\d+)/, uc($_)] } @old;
4594
4595     # using a prototype allows you to use any comparison subroutine
4596     # as a sort subroutine (including other package's subroutines)
4597     package other;
4598     sub backwards ($$) { $_[1] cmp $_[0]; }     # $a and $b are not set here
4599
4600     package main;
4601     @new = sort other::backwards @old;
4602
4603     # guarantee stability, regardless of algorithm
4604     use sort 'stable';
4605     @new = sort { substr($a, 3, 5) cmp substr($b, 3, 5) } @old;
4606
4607     # force use of quicksort (not portable outside Perl 5.8)
4608     use sort '_quicksort';  # note discouraging _
4609     @new = sort { substr($a, 3, 5) cmp substr($b, 3, 5) } @old;
4610
4611     # similar to the previous example, but demand stability as well
4612     use sort qw( _mergesort stable );
4613     @new = sort { substr($a, 3, 5) cmp substr($b, 3, 5) } @old;
4614
4615 If you're using strict, you I<must not> declare $a
4616 and $b as lexicals.  They are package globals.  That means
4617 if you're in the C<main> package and type
4618
4619     @articles = sort {$b <=> $a} @files;
4620
4621 then C<$a> and C<$b> are C<$main::a> and C<$main::b> (or C<$::a> and C<$::b>),
4622 but if you're in the C<FooPack> package, it's the same as typing
4623