This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
19fa7807b68d2e5f55e0d150824d6a921a1d34cc
[perl5.git] / pod / perlfaq7.pod
1 =head1 NAME
2
3 perlfaq7 - General Perl Language Issues ($Revision: 1.21 $, $Date: 2005/01/21 12:10:22 $)
4
5 =head1 DESCRIPTION
6
7 This section deals with general Perl language issues that don't
8 clearly fit into any of the other sections.
9
10 =head2 Can I get a BNF/yacc/RE for the Perl language?
11
12 There is no BNF, but you can paw your way through the yacc grammar in
13 perly.y in the source distribution if you're particularly brave.  The
14 grammar relies on very smart tokenizing code, so be prepared to
15 venture into toke.c as well.
16
17 In the words of Chaim Frenkel: "Perl's grammar can not be reduced to BNF.
18 The work of parsing perl is distributed between yacc, the lexer, smoke
19 and mirrors."
20
21 =head2 What are all these $@%&* punctuation signs, and how do I know when to use them?
22
23 They are type specifiers, as detailed in L<perldata>:
24
25     $ for scalar values (number, string or reference)
26     @ for arrays
27     % for hashes (associative arrays)
28     & for subroutines (aka functions, procedures, methods)
29     * for all types of that symbol name.  In version 4 you used them like
30       pointers, but in modern perls you can just use references.
31
32 There are couple of other symbols that you're likely to encounter that aren't
33 really type specifiers:
34
35     <> are used for inputting a record from a filehandle.
36     \  takes a reference to something.
37
38 Note that <FILE> is I<neither> the type specifier for files
39 nor the name of the handle.  It is the C<< <> >> operator applied
40 to the handle FILE.  It reads one line (well, record--see
41 L<perlvar/$E<sol>>) from the handle FILE in scalar context, or I<all> lines
42 in list context.  When performing open, close, or any other operation
43 besides C<< <> >> on files, or even when talking about the handle, do
44 I<not> use the brackets.  These are correct: C<eof(FH)>, C<seek(FH, 0,
45 2)> and "copying from STDIN to FILE".
46
47 =head2 Do I always/never have to quote my strings or use semicolons and commas?
48
49 Normally, a bareword doesn't need to be quoted, but in most cases
50 probably should be (and must be under C<use strict>).  But a hash key
51 consisting of a simple word (that isn't the name of a defined
52 subroutine) and the left-hand operand to the C<< => >> operator both
53 count as though they were quoted:
54
55     This                    is like this
56     ------------            ---------------
57     $foo{line}              $foo{"line"}
58     bar => stuff            "bar" => stuff
59
60 The final semicolon in a block is optional, as is the final comma in a
61 list.  Good style (see L<perlstyle>) says to put them in except for
62 one-liners:
63
64     if ($whoops) { exit 1 }
65     @nums = (1, 2, 3);
66
67     if ($whoops) {
68         exit 1;
69     }
70     @lines = (
71         "There Beren came from mountains cold",
72         "And lost he wandered under leaves",
73     );
74
75 =head2 How do I skip some return values?
76
77 One way is to treat the return values as a list and index into it:
78
79         $dir = (getpwnam($user))[7];
80
81 Another way is to use undef as an element on the left-hand-side:
82
83     ($dev, $ino, undef, undef, $uid, $gid) = stat($file);
84
85 You can also use a list slice to select only the elements that
86 you need:
87
88         ($dev, $ino, $uid, $gid) = ( stat($file) )[0,1,4,5];
89
90 =head2 How do I temporarily block warnings?
91
92 If you are running Perl 5.6.0 or better, the C<use warnings> pragma
93 allows fine control of what warning are produced.
94 See L<perllexwarn> for more details.
95
96     {
97         no warnings;          # temporarily turn off warnings
98         $a = $b + $c;         # I know these might be undef
99     }
100     
101 Additionally, you can enable and disable categories of warnings.
102 You turn off the categories you want to ignore and you can still
103 get other categories of warnings.  See L<perllexwarn> for the
104 complete details, including the category names and hierarchy.
105
106         {
107         no warnings 'uninitialized';
108         $a = $b + $c;
109         }
110
111 If you have an older version of Perl, the C<$^W> variable (documented
112 in L<perlvar>) controls runtime warnings for a block:
113
114     {
115         local $^W = 0;        # temporarily turn off warnings
116         $a = $b + $c;         # I know these might be undef
117     }
118
119 Note that like all the punctuation variables, you cannot currently
120 use my() on C<$^W>, only local().
121
122 =head2 What's an extension?
123
124 An extension is a way of calling compiled C code from Perl.  Reading
125 L<perlxstut> is a good place to learn more about extensions.
126
127 =head2 Why do Perl operators have different precedence than C operators?
128
129 Actually, they don't.  All C operators that Perl copies have the same
130 precedence in Perl as they do in C.  The problem is with operators that C
131 doesn't have, especially functions that give a list context to everything
132 on their right, eg. print, chmod, exec, and so on.  Such functions are
133 called "list operators" and appear as such in the precedence table in
134 L<perlop>.
135
136 A common mistake is to write:
137
138     unlink $file || die "snafu";
139
140 This gets interpreted as:
141
142     unlink ($file || die "snafu");
143
144 To avoid this problem, either put in extra parentheses or use the
145 super low precedence C<or> operator:
146
147     (unlink $file) || die "snafu";
148     unlink $file or die "snafu";
149
150 The "English" operators (C<and>, C<or>, C<xor>, and C<not>)
151 deliberately have precedence lower than that of list operators for
152 just such situations as the one above.
153
154 Another operator with surprising precedence is exponentiation.  It
155 binds more tightly even than unary minus, making C<-2**2> product a
156 negative not a positive four.  It is also right-associating, meaning
157 that C<2**3**2> is two raised to the ninth power, not eight squared.
158
159 Although it has the same precedence as in C, Perl's C<?:> operator
160 produces an lvalue.  This assigns $x to either $a or $b, depending
161 on the trueness of $maybe:
162
163     ($maybe ? $a : $b) = $x;
164
165 =head2 How do I declare/create a structure?
166
167 In general, you don't "declare" a structure.  Just use a (probably
168 anonymous) hash reference.  See L<perlref> and L<perldsc> for details.
169 Here's an example:
170
171     $person = {};                   # new anonymous hash
172     $person->{AGE}  = 24;           # set field AGE to 24
173     $person->{NAME} = "Nat";        # set field NAME to "Nat"
174
175 If you're looking for something a bit more rigorous, try L<perltoot>.
176
177 =head2 How do I create a module?
178
179 (contributed by brian d foy)
180
181 L<perlmod>, L<perlmodlib>, L<perlmodstyle> explain modules
182 in all the gory details. L<perlnewmod> gives a a brief
183 overview of the process along with a couple of suggestions
184 about style.
185
186 If you need to include C code or C library interfaces in
187 your module, you'll need h2xs.  h2xs will create the module
188 distribution structure and the initial interface files
189 you'll need.  L<perlxs> and L<perlxstut> explain the details.
190
191 If you don't need to use C code, other tools such as
192 ExtUtils::ModuleMaker and Module::Starter, can help you
193 create a skeleton module distribution.
194
195 You may also want to see Sam Tregar's "Writing Perl Modules
196 for CPAN" ( http://apress.com/book/bookDisplay.html?bID=14 )
197 which is the best hands-on guide to creating module
198 distributions.
199
200 =head2 How do I create a class?
201
202 See L<perltoot> for an introduction to classes and objects, as well as
203 L<perlobj> and L<perlbot>.
204
205 =head2 How can I tell if a variable is tainted?
206
207 You can use the tainted() function of the Scalar::Util module, available
208 from CPAN (or included with Perl since release 5.8.0).
209 See also L<perlsec/"Laundering and Detecting Tainted Data">.
210
211 =head2 What's a closure?
212
213 Closures are documented in L<perlref>.
214
215 I<Closure> is a computer science term with a precise but
216 hard-to-explain meaning. Closures are implemented in Perl as anonymous
217 subroutines with lasting references to lexical variables outside their
218 own scopes.  These lexicals magically refer to the variables that were
219 around when the subroutine was defined (deep binding).
220
221 Closures make sense in any programming language where you can have the
222 return value of a function be itself a function, as you can in Perl.
223 Note that some languages provide anonymous functions but are not
224 capable of providing proper closures: the Python language, for
225 example.  For more information on closures, check out any textbook on
226 functional programming.  Scheme is a language that not only supports
227 but encourages closures.
228
229 Here's a classic function-generating function:
230
231     sub add_function_generator {
232       return sub { shift() + shift() };
233     }
234
235     $add_sub = add_function_generator();
236     $sum = $add_sub->(4,5);                # $sum is 9 now.
237
238 The closure works as a I<function template> with some customization
239 slots left out to be filled later.  The anonymous subroutine returned
240 by add_function_generator() isn't technically a closure because it
241 refers to no lexicals outside its own scope.
242
243 Contrast this with the following make_adder() function, in which the
244 returned anonymous function contains a reference to a lexical variable
245 outside the scope of that function itself.  Such a reference requires
246 that Perl return a proper closure, thus locking in for all time the
247 value that the lexical had when the function was created.
248
249     sub make_adder {
250         my $addpiece = shift;
251         return sub { shift() + $addpiece };
252     }
253
254     $f1 = make_adder(20);
255     $f2 = make_adder(555);
256
257 Now C<&$f1($n)> is always 20 plus whatever $n you pass in, whereas
258 C<&$f2($n)> is always 555 plus whatever $n you pass in.  The $addpiece
259 in the closure sticks around.
260
261 Closures are often used for less esoteric purposes.  For example, when
262 you want to pass in a bit of code into a function:
263
264     my $line;
265     timeout( 30, sub { $line = <STDIN> } );
266
267 If the code to execute had been passed in as a string,
268 C<< '$line = <STDIN>' >>, there would have been no way for the
269 hypothetical timeout() function to access the lexical variable
270 $line back in its caller's scope.
271
272 =head2 What is variable suicide and how can I prevent it?
273
274 Variable suicide is when you (temporarily or permanently) lose the
275 value of a variable.  It is caused by scoping through my() and local()
276 interacting with either closures or aliased foreach() iterator
277 variables and subroutine arguments.  It used to be easy to
278 inadvertently lose a variable's value this way, but now it's much
279 harder.  Take this code:
280
281     my $f = "foo";
282     sub T {
283       while ($i++ < 3) { my $f = $f; $f .= "bar"; print $f, "\n" }
284     }
285     T;
286     print "Finally $f\n";
287
288 The $f that has "bar" added to it three times should be a new C<$f>
289 (C<my $f> should create a new local variable each time through the loop).
290 It isn't, however.  This was a bug, now fixed in the latest releases
291 (tested against 5.004_05, 5.005_03, and 5.005_56).
292
293 =head2 How can I pass/return a {Function, FileHandle, Array, Hash, Method, Regex}?
294
295 With the exception of regexes, you need to pass references to these
296 objects.  See L<perlsub/"Pass by Reference"> for this particular
297 question, and L<perlref> for information on references.
298
299 See ``Passing Regexes'', below, for information on passing regular
300 expressions.
301
302 =over 4
303
304 =item Passing Variables and Functions
305
306 Regular variables and functions are quite easy to pass: just pass in a
307 reference to an existing or anonymous variable or function:
308
309     func( \$some_scalar );
310
311     func( \@some_array  );
312     func( [ 1 .. 10 ]   );
313
314     func( \%some_hash   );
315     func( { this => 10, that => 20 }   );
316
317     func( \&some_func   );
318     func( sub { $_[0] ** $_[1] }   );
319
320 =item Passing Filehandles
321
322 As of Perl 5.6, you can represent filehandles with scalar variables
323 which you treat as any other scalar.
324
325         open my $fh, $filename or die "Cannot open $filename! $!";
326         func( $fh );
327
328         sub func {
329                 my $passed_fh = shift;
330
331                 my $line = <$fh>;
332                 }
333
334 Before Perl 5.6, you had to use the C<*FH> or C<\*FH> notations.
335 These are "typeglobs"--see L<perldata/"Typeglobs and Filehandles">
336 and especially L<perlsub/"Pass by Reference"> for more information.
337
338 =item Passing Regexes
339
340 To pass regexes around, you'll need to be using a release of Perl
341 sufficiently recent as to support the C<qr//> construct, pass around
342 strings and use an exception-trapping eval, or else be very, very clever.
343
344 Here's an example of how to pass in a string to be regex compared
345 using C<qr//>:
346
347     sub compare($$) {
348         my ($val1, $regex) = @_;
349         my $retval = $val1 =~ /$regex/;
350         return $retval;
351     }
352     $match = compare("old McDonald", qr/d.*D/i);
353
354 Notice how C<qr//> allows flags at the end.  That pattern was compiled
355 at compile time, although it was executed later.  The nifty C<qr//>
356 notation wasn't introduced until the 5.005 release.  Before that, you
357 had to approach this problem much less intuitively.  For example, here
358 it is again if you don't have C<qr//>:
359
360     sub compare($$) {
361         my ($val1, $regex) = @_;
362         my $retval = eval { $val1 =~ /$regex/ };
363         die if $@;
364         return $retval;
365     }
366
367     $match = compare("old McDonald", q/($?i)d.*D/);
368
369 Make sure you never say something like this:
370
371     return eval "\$val =~ /$regex/";   # WRONG
372
373 or someone can sneak shell escapes into the regex due to the double
374 interpolation of the eval and the double-quoted string.  For example:
375
376     $pattern_of_evil = 'danger ${ system("rm -rf * &") } danger';
377
378     eval "\$string =~ /$pattern_of_evil/";
379
380 Those preferring to be very, very clever might see the O'Reilly book,
381 I<Mastering Regular Expressions>, by Jeffrey Friedl.  Page 273's
382 Build_MatchMany_Function() is particularly interesting.  A complete
383 citation of this book is given in L<perlfaq2>.
384
385 =item Passing Methods
386
387 To pass an object method into a subroutine, you can do this:
388
389     call_a_lot(10, $some_obj, "methname")
390     sub call_a_lot {
391         my ($count, $widget, $trick) = @_;
392         for (my $i = 0; $i < $count; $i++) {
393             $widget->$trick();
394         }
395     }
396
397 Or, you can use a closure to bundle up the object, its
398 method call, and arguments:
399
400     my $whatnot =  sub { $some_obj->obfuscate(@args) };
401     func($whatnot);
402     sub func {
403         my $code = shift;
404         &$code();
405     }
406
407 You could also investigate the can() method in the UNIVERSAL class
408 (part of the standard perl distribution).
409
410 =back
411
412 =head2 How do I create a static variable?
413
414 As with most things in Perl, TMTOWTDI.  What is a "static variable" in
415 other languages could be either a function-private variable (visible
416 only within a single function, retaining its value between calls to
417 that function), or a file-private variable (visible only to functions
418 within the file it was declared in) in Perl.
419
420 Here's code to implement a function-private variable:
421
422     BEGIN {
423         my $counter = 42;
424         sub prev_counter { return --$counter }
425         sub next_counter { return $counter++ }
426     }
427
428 Now prev_counter() and next_counter() share a private variable $counter
429 that was initialized at compile time.
430
431 To declare a file-private variable, you'll still use a my(), putting
432 the declaration at the outer scope level at the top of the file.
433 Assume this is in file Pax.pm:
434
435     package Pax;
436     my $started = scalar(localtime(time()));
437
438     sub begun { return $started }
439
440 When C<use Pax> or C<require Pax> loads this module, the variable will
441 be initialized.  It won't get garbage-collected the way most variables
442 going out of scope do, because the begun() function cares about it,
443 but no one else can get it.  It is not called $Pax::started because
444 its scope is unrelated to the package.  It's scoped to the file.  You
445 could conceivably have several packages in that same file all
446 accessing the same private variable, but another file with the same
447 package couldn't get to it.
448
449 See L<perlsub/"Persistent Private Variables"> for details.
450
451 =head2 What's the difference between dynamic and lexical (static) scoping?  Between local() and my()?
452
453 C<local($x)> saves away the old value of the global variable C<$x>
454 and assigns a new value for the duration of the subroutine I<which is
455 visible in other functions called from that subroutine>.  This is done
456 at run-time, so is called dynamic scoping.  local() always affects global
457 variables, also called package variables or dynamic variables.
458
459 C<my($x)> creates a new variable that is only visible in the current
460 subroutine.  This is done at compile-time, so it is called lexical or
461 static scoping.  my() always affects private variables, also called
462 lexical variables or (improperly) static(ly scoped) variables.
463
464 For instance:
465
466     sub visible {
467         print "var has value $var\n";
468     }
469
470     sub dynamic {
471         local $var = 'local';   # new temporary value for the still-global
472         visible();              #   variable called $var
473     }
474
475     sub lexical {
476         my $var = 'private';    # new private variable, $var
477         visible();              # (invisible outside of sub scope)
478     }
479
480     $var = 'global';
481
482     visible();                  # prints global
483     dynamic();                  # prints local
484     lexical();                  # prints global
485
486 Notice how at no point does the value "private" get printed.  That's
487 because $var only has that value within the block of the lexical()
488 function, and it is hidden from called subroutine.
489
490 In summary, local() doesn't make what you think of as private, local
491 variables.  It gives a global variable a temporary value.  my() is
492 what you're looking for if you want private variables.
493
494 See L<perlsub/"Private Variables via my()"> and
495 L<perlsub/"Temporary Values via local()"> for excruciating details.
496
497 =head2 How can I access a dynamic variable while a similarly named lexical is in scope?
498
499 If you know your package, you can just mention it explicitly, as in
500 $Some_Pack::var. Note that the notation $::var is B<not> the dynamic $var
501 in the current package, but rather the one in the "main" package, as
502 though you had written $main::var.
503
504         use vars '$var';
505         local $var = "global";
506         my    $var = "lexical";
507
508         print "lexical is $var\n";
509         print "global  is $main::var\n";
510
511 Alternatively you can use the compiler directive our() to bring a
512 dynamic variable into the current lexical scope.
513
514         require 5.006; # our() did not exist before 5.6
515         use vars '$var';
516
517         local $var = "global";
518         my $var    = "lexical";
519
520         print "lexical is $var\n";
521
522         {
523           our $var;
524           print "global  is $var\n";
525         }
526
527 =head2 What's the difference between deep and shallow binding?
528
529 In deep binding, lexical variables mentioned in anonymous subroutines
530 are the same ones that were in scope when the subroutine was created.
531 In shallow binding, they are whichever variables with the same names
532 happen to be in scope when the subroutine is called.  Perl always uses
533 deep binding of lexical variables (i.e., those created with my()).
534 However, dynamic variables (aka global, local, or package variables)
535 are effectively shallowly bound.  Consider this just one more reason
536 not to use them.  See the answer to L<"What's a closure?">.
537
538 =head2 Why doesn't "my($foo) = E<lt>FILEE<gt>;" work right?
539
540 C<my()> and C<local()> give list context to the right hand side
541 of C<=>.  The <FH> read operation, like so many of Perl's
542 functions and operators, can tell which context it was called in and
543 behaves appropriately.  In general, the scalar() function can help.
544 This function does nothing to the data itself (contrary to popular myth)
545 but rather tells its argument to behave in whatever its scalar fashion is.
546 If that function doesn't have a defined scalar behavior, this of course
547 doesn't help you (such as with sort()).
548
549 To enforce scalar context in this particular case, however, you need
550 merely omit the parentheses:
551
552     local($foo) = <FILE>;           # WRONG
553     local($foo) = scalar(<FILE>);   # ok
554     local $foo  = <FILE>;           # right
555
556 You should probably be using lexical variables anyway, although the
557 issue is the same here:
558
559     my($foo) = <FILE>;  # WRONG
560     my $foo  = <FILE>;  # right
561
562 =head2 How do I redefine a builtin function, operator, or method?
563
564 Why do you want to do that? :-)
565
566 If you want to override a predefined function, such as open(),
567 then you'll have to import the new definition from a different
568 module.  See L<perlsub/"Overriding Built-in Functions">.  There's
569 also an example in L<perltoot/"Class::Template">.
570
571 If you want to overload a Perl operator, such as C<+> or C<**>,
572 then you'll want to use the C<use overload> pragma, documented
573 in L<overload>.
574
575 If you're talking about obscuring method calls in parent classes,
576 see L<perltoot/"Overridden Methods">.
577
578 =head2 What's the difference between calling a function as &foo and foo()?
579
580 When you call a function as C<&foo>, you allow that function access to
581 your current @_ values, and you bypass prototypes.
582 The function doesn't get an empty @_--it gets yours!  While not
583 strictly speaking a bug (it's documented that way in L<perlsub>), it
584 would be hard to consider this a feature in most cases.
585
586 When you call your function as C<&foo()>, then you I<do> get a new @_,
587 but prototyping is still circumvented.
588
589 Normally, you want to call a function using C<foo()>.  You may only
590 omit the parentheses if the function is already known to the compiler
591 because it already saw the definition (C<use> but not C<require>),
592 or via a forward reference or C<use subs> declaration.  Even in this
593 case, you get a clean @_ without any of the old values leaking through
594 where they don't belong.
595
596 =head2 How do I create a switch or case statement?
597
598 This is explained in more depth in the L<perlsyn>.  Briefly, there's
599 no official case statement, because of the variety of tests possible
600 in Perl (numeric comparison, string comparison, glob comparison,
601 regex matching, overloaded comparisons, ...).
602 Larry couldn't decide how best to do this, so he left it out, even
603 though it's been on the wish list since perl1.
604
605 Starting from Perl 5.8 to get switch and case one can use the
606 Switch extension and say:
607
608         use Switch;
609
610 after which one has switch and case.  It is not as fast as it could be
611 because it's not really part of the language (it's done using source
612 filters) but it is available, and it's very flexible.
613
614 But if one wants to use pure Perl, the general answer is to write a
615 construct like this:
616
617     for ($variable_to_test) {
618         if    (/pat1/)  { }     # do something
619         elsif (/pat2/)  { }     # do something else
620         elsif (/pat3/)  { }     # do something else
621         else            { }     # default
622     }
623
624 Here's a simple example of a switch based on pattern matching, this
625 time lined up in a way to make it look more like a switch statement.
626 We'll do a multiway conditional based on the type of reference stored
627 in $whatchamacallit:
628
629     SWITCH: for (ref $whatchamacallit) {
630
631         /^$/            && die "not a reference";
632
633         /SCALAR/        && do {
634                                 print_scalar($$ref);
635                                 last SWITCH;
636                         };
637
638         /ARRAY/         && do {
639                                 print_array(@$ref);
640                                 last SWITCH;
641                         };
642
643         /HASH/          && do {
644                                 print_hash(%$ref);
645                                 last SWITCH;
646                         };
647
648         /CODE/          && do {
649                                 warn "can't print function ref";
650                                 last SWITCH;
651                         };
652
653         # DEFAULT
654
655         warn "User defined type skipped";
656
657     }
658
659 See C<perlsyn/"Basic BLOCKs and Switch Statements"> for many other
660 examples in this style.
661
662 Sometimes you should change the positions of the constant and the variable.
663 For example, let's say you wanted to test which of many answers you were
664 given, but in a case-insensitive way that also allows abbreviations.
665 You can use the following technique if the strings all start with
666 different characters or if you want to arrange the matches so that
667 one takes precedence over another, as C<"SEND"> has precedence over
668 C<"STOP"> here:
669
670     chomp($answer = <>);
671     if    ("SEND"  =~ /^\Q$answer/i) { print "Action is send\n"  }
672     elsif ("STOP"  =~ /^\Q$answer/i) { print "Action is stop\n"  }
673     elsif ("ABORT" =~ /^\Q$answer/i) { print "Action is abort\n" }
674     elsif ("LIST"  =~ /^\Q$answer/i) { print "Action is list\n"  }
675     elsif ("EDIT"  =~ /^\Q$answer/i) { print "Action is edit\n"  }
676
677 A totally different approach is to create a hash of function references.
678
679     my %commands = (
680         "happy" => \&joy,
681         "sad",  => \&sullen,
682         "done"  => sub { die "See ya!" },
683         "mad"   => \&angry,
684     );
685
686     print "How are you? ";
687     chomp($string = <STDIN>);
688     if ($commands{$string}) {
689         $commands{$string}->();
690     } else {
691         print "No such command: $string\n";
692     }
693
694 =head2 How can I catch accesses to undefined variables, functions, or methods?
695
696 The AUTOLOAD method, discussed in L<perlsub/"Autoloading"> and
697 L<perltoot/"AUTOLOAD: Proxy Methods">, lets you capture calls to
698 undefined functions and methods.
699
700 When it comes to undefined variables that would trigger a warning
701 under C<use warnings>, you can promote the warning to an error.
702
703         use warnings FATAL => qw(uninitialized);
704
705 =head2 Why can't a method included in this same file be found?
706
707 Some possible reasons: your inheritance is getting confused, you've
708 misspelled the method name, or the object is of the wrong type.  Check
709 out L<perltoot> for details about any of the above cases.  You may
710 also use C<print ref($object)> to find out the class C<$object> was
711 blessed into.
712
713 Another possible reason for problems is because you've used the
714 indirect object syntax (eg, C<find Guru "Samy">) on a class name
715 before Perl has seen that such a package exists.  It's wisest to make
716 sure your packages are all defined before you start using them, which
717 will be taken care of if you use the C<use> statement instead of
718 C<require>.  If not, make sure to use arrow notation (eg.,
719 C<< Guru->find("Samy") >>) instead.  Object notation is explained in
720 L<perlobj>.
721
722 Make sure to read about creating modules in L<perlmod> and
723 the perils of indirect objects in L<perlobj/"Method Invocation">.
724
725 =head2 How can I find out my current package?
726
727 If you're just a random program, you can do this to find
728 out what the currently compiled package is:
729
730     my $packname = __PACKAGE__;
731
732 But, if you're a method and you want to print an error message
733 that includes the kind of object you were called on (which is
734 not necessarily the same as the one in which you were compiled):
735
736     sub amethod {
737         my $self  = shift;
738         my $class = ref($self) || $self;
739         warn "called me from a $class object";
740     }
741
742 =head2 How can I comment out a large block of perl code?
743
744 You can use embedded POD to discard it.  Enclose the blocks you want
745 to comment out in POD markers.  The <=begin> directive marks a section
746 for a specific formatter.  Use the C<comment> format, which no formatter
747 should claim to understand (by policy).  Mark the end of the block
748 with <=end>.
749
750     # program is here
751
752     =begin comment
753
754     all of this stuff
755
756     here will be ignored
757     by everyone
758
759         =end comment
760         
761     =cut
762
763     # program continues
764
765 The pod directives cannot go just anywhere.  You must put a
766 pod directive where the parser is expecting a new statement,
767 not just in the middle of an expression or some other
768 arbitrary grammar production.
769
770 See L<perlpod> for more details.
771
772 =head2 How do I clear a package?
773
774 Use this code, provided by Mark-Jason Dominus:
775
776     sub scrub_package {
777         no strict 'refs';
778         my $pack = shift;
779         die "Shouldn't delete main package"
780             if $pack eq "" || $pack eq "main";
781         my $stash = *{$pack . '::'}{HASH};
782         my $name;
783         foreach $name (keys %$stash) {
784             my $fullname = $pack . '::' . $name;
785             # Get rid of everything with that name.
786             undef $$fullname;
787             undef @$fullname;
788             undef %$fullname;
789             undef &$fullname;
790             undef *$fullname;
791         }
792     }
793
794 Or, if you're using a recent release of Perl, you can
795 just use the Symbol::delete_package() function instead.
796
797 =head2 How can I use a variable as a variable name?
798
799 Beginners often think they want to have a variable contain the name
800 of a variable.
801
802     $fred    = 23;
803     $varname = "fred";
804     ++$$varname;         # $fred now 24
805
806 This works I<sometimes>, but it is a very bad idea for two reasons.
807
808 The first reason is that this technique I<only works on global
809 variables>.  That means that if $fred is a lexical variable created
810 with my() in the above example, the code wouldn't work at all: you'd
811 accidentally access the global and skip right over the private lexical
812 altogether.  Global variables are bad because they can easily collide
813 accidentally and in general make for non-scalable and confusing code.
814
815 Symbolic references are forbidden under the C<use strict> pragma.
816 They are not true references and consequently are not reference counted
817 or garbage collected.
818
819 The other reason why using a variable to hold the name of another
820 variable is a bad idea is that the question often stems from a lack of
821 understanding of Perl data structures, particularly hashes.  By using
822 symbolic references, you are just using the package's symbol-table hash
823 (like C<%main::>) instead of a user-defined hash.  The solution is to
824 use your own hash or a real reference instead.
825
826     $USER_VARS{"fred"} = 23;
827     $varname = "fred";
828     $USER_VARS{$varname}++;  # not $$varname++
829
830 There we're using the %USER_VARS hash instead of symbolic references.
831 Sometimes this comes up in reading strings from the user with variable
832 references and wanting to expand them to the values of your perl
833 program's variables.  This is also a bad idea because it conflates the
834 program-addressable namespace and the user-addressable one.  Instead of
835 reading a string and expanding it to the actual contents of your program's
836 own variables:
837
838     $str = 'this has a $fred and $barney in it';
839     $str =~ s/(\$\w+)/$1/eeg;             # need double eval
840
841 it would be better to keep a hash around like %USER_VARS and have
842 variable references actually refer to entries in that hash:
843
844     $str =~ s/\$(\w+)/$USER_VARS{$1}/g;   # no /e here at all
845
846 That's faster, cleaner, and safer than the previous approach.  Of course,
847 you don't need to use a dollar sign.  You could use your own scheme to
848 make it less confusing, like bracketed percent symbols, etc.
849
850     $str = 'this has a %fred% and %barney% in it';
851     $str =~ s/%(\w+)%/$USER_VARS{$1}/g;   # no /e here at all
852
853 Another reason that folks sometimes think they want a variable to
854 contain the name of a variable is because they don't know how to build
855 proper data structures using hashes.  For example, let's say they
856 wanted two hashes in their program: %fred and %barney, and that they
857 wanted to use another scalar variable to refer to those by name.
858
859     $name = "fred";
860     $$name{WIFE} = "wilma";     # set %fred
861
862     $name = "barney";
863     $$name{WIFE} = "betty";     # set %barney
864
865 This is still a symbolic reference, and is still saddled with the
866 problems enumerated above.  It would be far better to write:
867
868     $folks{"fred"}{WIFE}   = "wilma";
869     $folks{"barney"}{WIFE} = "betty";
870
871 And just use a multilevel hash to start with.
872
873 The only times that you absolutely I<must> use symbolic references are
874 when you really must refer to the symbol table.  This may be because it's
875 something that can't take a real reference to, such as a format name.
876 Doing so may also be important for method calls, since these always go
877 through the symbol table for resolution.
878
879 In those cases, you would turn off C<strict 'refs'> temporarily so you
880 can play around with the symbol table.  For example:
881
882     @colors = qw(red blue green yellow orange purple violet);
883     for my $name (@colors) {
884         no strict 'refs';  # renege for the block
885         *$name = sub { "<FONT COLOR='$name'>@_</FONT>" };
886     }
887
888 All those functions (red(), blue(), green(), etc.) appear to be separate,
889 but the real code in the closure actually was compiled only once.
890
891 So, sometimes you might want to use symbolic references to directly
892 manipulate the symbol table.  This doesn't matter for formats, handles, and
893 subroutines, because they are always global--you can't use my() on them.
894 For scalars, arrays, and hashes, though--and usually for subroutines--
895 you probably only want to use hard references.
896
897 =head2 What does "bad interpreter" mean?
898
899 The "bad interpreter" message comes from the shell, not perl.  The
900 actual message may vary depending on your platform, shell, and locale
901 settings.
902
903 If you see "bad interpreter - no such file or directory", the first
904 line in your perl script (the "shebang" line) does not contain the
905 right path to perl (or any other program capable of running scripts). 
906 Sometimes this happens when you move the script from one machine to
907 another and each machine has a different path to perl---/usr/bin/perl
908 versus /usr/local/bin/perl for instance.
909
910 If you see "bad interpreter: Permission denied", you need to make your
911 script executable.
912
913 In either case, you should still be able to run the scripts with perl
914 explicitly:
915
916         % perl script.pl
917
918 If you get a message like "perl: command not found", perl is not in
919 your PATH, which might also mean that the location of perl is not
920 where you expect it so you need to adjust your shebang line.
921
922 =head1 AUTHOR AND COPYRIGHT
923
924 Copyright (c) 1997-2005 Tom Christiansen, Nathan Torkington, and
925 other authors as noted. All rights reserved.
926
927 This documentation is free; you can redistribute it and/or modify it
928 under the same terms as Perl itself.
929
930 Irrespective of its distribution, all code examples in this file
931 are hereby placed into the public domain.  You are permitted and
932 encouraged to use this code in your own programs for fun
933 or for profit as you see fit.  A simple comment in the code giving
934 credit would be courteous but is not required.
935