This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
18ecd4099c504c8e9846e9f0075d13c2eda57ae4
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2 X<function>
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides scalar context to its
16 argument, while a list operator may provide either scalar or list
17 contexts for its arguments.  If it does both, scalar arguments 
18 come first and list argument follow, and there can only ever
19 be one such list argument.  For instance, splice() has three scalar
20 arguments followed by a list, whereas gethostbyname() has four scalar
21 arguments.
22
23 In the syntax descriptions that follow, list operators that expect a
24 list (and provide list context for elements of the list) are shown
25 with LIST as an argument.  Such a list may consist of any combination
26 of scalar arguments or list values; the list values will be included
27 in the list as if each individual element were interpolated at that
28 point in the list, forming a longer single-dimensional list value.
29 Commas should separate literal elements of the LIST.
30
31 Any function in the list below may be used either with or without
32 parentheses around its arguments.  (The syntax descriptions omit the
33 parentheses.)  If you use parentheses, the simple but occasionally 
34 surprising rule is this: It I<looks> like a function, therefore it I<is> a
35 function, and precedence doesn't matter.  Otherwise it's a list
36 operator or unary operator, and precedence does matter.  Whitespace
37 between the function and left parenthesis doesn't count, so sometimes
38 you need to be careful:
39
40     print 1+2+4;      # Prints 7.
41     print(1+2) + 4;   # Prints 3.
42     print (1+2)+4;    # Also prints 3!
43     print +(1+2)+4;   # Prints 7.
44     print ((1+2)+4);  # Prints 7.
45
46 If you run Perl with the B<-w> switch it can warn you about this.  For
47 example, the third line above produces:
48
49     print (...) interpreted as function at - line 1.
50     Useless use of integer addition in void context at - line 1.
51
52 A few functions take no arguments at all, and therefore work as neither
53 unary nor list operators.  These include such functions as C<time>
54 and C<endpwent>.  For example, C<time+86_400> always means
55 C<time() + 86_400>.
56
57 For functions that can be used in either a scalar or list context,
58 nonabortive failure is generally indicated in scalar context by
59 returning the undefined value, and in list context by returning the
60 empty list.
61
62 Remember the following important rule: There is B<no rule> that relates
63 the behavior of an expression in list context to its behavior in scalar
64 context, or vice versa.  It might do two totally different things.
65 Each operator and function decides which sort of value would be most
66 appropriate to return in scalar context.  Some operators return the
67 length of the list that would have been returned in list context.  Some
68 operators return the first value in the list.  Some operators return the
69 last value in the list.  Some operators return a count of successful
70 operations.  In general, they do what you want, unless you want
71 consistency.
72 X<context>
73
74 A named array in scalar context is quite different from what would at
75 first glance appear to be a list in scalar context.  You can't get a list
76 like C<(1,2,3)> into being in scalar context, because the compiler knows
77 the context at compile time.  It would generate the scalar comma operator
78 there, not the list construction version of the comma.  That means it
79 was never a list to start with.
80
81 In general, functions in Perl that serve as wrappers for system calls ("syscalls")
82 of the same name (like chown(2), fork(2), closedir(2), etc.) return
83 true when they succeed and C<undef> otherwise, as is usually mentioned
84 in the descriptions below.  This is different from the C interfaces,
85 which return C<-1> on failure.  Exceptions to this rule include C<wait>,
86 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
87 variable on failure.  Other functions do not, except accidentally.
88
89 Extension modules can also hook into the Perl parser to define new
90 kinds of keyword-headed expression.  These may look like functions, but
91 may also look completely different.  The syntax following the keyword
92 is defined entirely by the extension.  If you are an implementor, see
93 L<perlapi/PL_keyword_plugin> for the mechanism.  If you are using such
94 a module, see the module's documentation for details of the syntax that
95 it defines.
96
97 =head2 Perl Functions by Category
98 X<function>
99
100 Here are Perl's functions (including things that look like
101 functions, like some keywords and named operators)
102 arranged by category.  Some functions appear in more
103 than one place.
104
105 =over 4
106
107 =item Functions for SCALARs or strings
108 X<scalar> X<string> X<character>
109
110 =for Pod::Functions =String
111
112 C<chomp>, C<chop>, C<chr>, C<crypt>, C<fc>, C<hex>, C<index>, C<lc>,
113 C<lcfirst>, C<length>, C<oct>, C<ord>, C<pack>, C<q//>, C<qq//>, C<reverse>,
114 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
115
116 C<fc> is available only if the C<"fc"> feature is enabled or if it is
117 prefixed with C<CORE::>.  The C<"fc"> feature is enabled automatically
118 with a C<use v5.16> (or higher) declaration in the current scope.
119
120
121 =item Regular expressions and pattern matching
122 X<regular expression> X<regex> X<regexp>
123
124 =for Pod::Functions =Regexp
125
126 C<m//>, C<pos>, C<qr//>, C<quotemeta>, C<s///>, C<split>, C<study>
127
128 =item Numeric functions
129 X<numeric> X<number> X<trigonometric> X<trigonometry>
130
131 =for Pod::Functions =Math
132
133 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
134 C<sin>, C<sqrt>, C<srand>
135
136 =item Functions for real @ARRAYs
137 X<array>
138
139 =for Pod::Functions =ARRAY
140
141 C<each>, C<keys>, C<pop>, C<push>, C<shift>, C<splice>, C<unshift>, C<values>
142
143 =item Functions for list data
144 X<list>
145
146 =for Pod::Functions =LIST
147
148 C<grep>, C<join>, C<map>, C<qw//>, C<reverse>, C<sort>, C<unpack>
149
150 =item Functions for real %HASHes
151 X<hash>
152
153 =for Pod::Functions =HASH
154
155 C<delete>, C<each>, C<exists>, C<keys>, C<values>
156
157 =item Input and output functions
158 X<I/O> X<input> X<output> X<dbm>
159
160 =for Pod::Functions =I/O
161
162 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
163 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
164 C<readdir>, C<readline> C<rewinddir>, C<say>, C<seek>, C<seekdir>, C<select>,
165 C<syscall>, C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>,
166 C<truncate>, C<warn>, C<write>
167
168 C<say> is available only if the C<"say"> feature is enabled or if it is
169 prefixed with C<CORE::>.  The C<"say"> feature is enabled automatically
170 with a C<use v5.10> (or higher) declaration in the current scope.
171
172 =item Functions for fixed-length data or records
173
174 =for Pod::Functions =Binary
175
176 C<pack>, C<read>, C<syscall>, C<sysread>, C<sysseek>, C<syswrite>, C<unpack>,
177 C<vec>
178
179 =item Functions for filehandles, files, or directories
180 X<file> X<filehandle> X<directory> X<pipe> X<link> X<symlink>
181
182 =for Pod::Functions =File
183
184 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
185 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
186 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
187 C<umask>, C<unlink>, C<utime>
188
189 =item Keywords related to the control flow of your Perl program
190 X<control flow>
191
192 =for Pod::Functions =Flow
193
194 C<break>, C<caller>, C<continue>, C<die>, C<do>,
195 C<dump>, C<eval>, C<evalbytes> C<exit>,
196 C<__FILE__>, C<goto>, C<last>, C<__LINE__>, C<next>, C<__PACKAGE__>,
197 C<redo>, C<return>, C<sub>, C<__SUB__>, C<wantarray>
198
199 C<break> is available only if you enable the experimental C<"switch">
200 feature or use the C<CORE::> prefix.  The C<"switch"> feature also enables
201 the C<default>, C<given> and C<when> statements, which are documented in
202 L<perlsyn/"Switch Statements">.  The C<"switch"> feature is enabled
203 automatically with a C<use v5.10> (or higher) declaration in the current
204 scope.  In Perl v5.14 and earlier, C<continue> required the C<"switch">
205 feature, like the other keywords.
206
207 C<evalbytes> is only available with the C<"evalbytes"> feature (see
208 L<feature>) or if prefixed with C<CORE::>.  C<__SUB__> is only available
209 with the C<"current_sub"> feature or if prefixed with C<CORE::>.  Both
210 the C<"evalbytes"> and C<"current_sub"> features are enabled automatically
211 with a C<use v5.16> (or higher) declaration in the current scope.
212
213 =item Keywords related to scoping
214
215 =for Pod::Functions =Namespace
216
217 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<state>, C<use>
218
219 C<state> is available only if the C<"state"> feature is enabled or if it is
220 prefixed with C<CORE::>.  The C<"state"> feature is enabled automatically
221 with a C<use v5.10> (or higher) declaration in the current scope.
222
223 =item Miscellaneous functions
224
225 =for Pod::Functions =Misc
226
227 C<defined>, C<formline>, C<lock>, C<prototype>, C<reset>, C<scalar>, C<undef>
228
229 =item Functions for processes and process groups
230 X<process> X<pid> X<process id>
231
232 =for Pod::Functions =Process
233
234 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
235 C<pipe>, C<qx//>, C<readpipe>, C<setpgrp>,
236 C<setpriority>, C<sleep>, C<system>,
237 C<times>, C<wait>, C<waitpid>
238
239 =item Keywords related to Perl modules
240 X<module>
241
242 =for Pod::Functions =Modules
243
244 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
245
246 =item Keywords related to classes and object-orientation
247 X<object> X<class> X<package>
248
249 =for Pod::Functions =Objects
250
251 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
252 C<untie>, C<use>
253
254 =item Low-level socket functions
255 X<socket> X<sock>
256
257 =for Pod::Functions =Socket
258
259 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
260 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
261 C<socket>, C<socketpair>
262
263 =item System V interprocess communication functions
264 X<IPC> X<System V> X<semaphore> X<shared memory> X<memory> X<message>
265
266 =for Pod::Functions =SysV
267
268 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
269 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
270
271 =item Fetching user and group info
272 X<user> X<group> X<password> X<uid> X<gid>  X<passwd> X</etc/passwd>
273
274 =for Pod::Functions =User
275
276 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
277 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
278 C<getpwuid>, C<setgrent>, C<setpwent>
279
280 =item Fetching network info
281 X<network> X<protocol> X<host> X<hostname> X<IP> X<address> X<service>
282
283 =for Pod::Functions =Network
284
285 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
286 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
287 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
288 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
289 C<setnetent>, C<setprotoent>, C<setservent>
290
291 =item Time-related functions
292 X<time> X<date>
293
294 =for Pod::Functions =Time
295
296 C<gmtime>, C<localtime>, C<time>, C<times>
297
298 =item Non-function keywords
299
300 =for Pod::Functions =!Non-functions
301
302 C<and>, C<AUTOLOAD>, C<BEGIN>, C<CHECK>, C<cmp>, C<CORE>, C<__DATA__>,
303 C<default>, C<DESTROY>, C<else>, C<elseif>, C<elsif>, C<END>, C<__END__>,
304 C<eq>, C<for>, C<foreach>, C<ge>, C<given>, C<gt>, C<if>, C<INIT>, C<le>,
305 C<lt>, C<ne>, C<not>, C<or>, C<UNITCHECK>, C<unless>, C<until>, C<when>,
306 C<while>, C<x>, C<xor>
307
308 =back
309
310 =head2 Portability
311 X<portability> X<Unix> X<portable>
312
313 Perl was born in Unix and can therefore access all common Unix
314 system calls.  In non-Unix environments, the functionality of some
315 Unix system calls may not be available or details of the available
316 functionality may differ slightly.  The Perl functions affected
317 by this are:
318
319 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
320 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
321 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
322 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
323 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
324 C<getppid>, C<getpgrp>, C<getpriority>, C<getprotobynumber>,
325 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
326 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
327 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
328 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
329 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
330 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
331 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
332 C<shmwrite>, C<socket>, C<socketpair>,
333 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
334 C<times>, C<truncate>, C<umask>, C<unlink>,
335 C<utime>, C<wait>, C<waitpid>
336
337 For more information about the portability of these functions, see
338 L<perlport> and other available platform-specific documentation.
339
340 =head2 Alphabetical Listing of Perl Functions
341
342 =over 
343
344 =item -X FILEHANDLE
345 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
346 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
347
348 =item -X EXPR
349
350 =item -X DIRHANDLE
351
352 =item -X
353
354 =for Pod::Functions a file test (-r, -x, etc)
355
356 A file test, where X is one of the letters listed below.  This unary
357 operator takes one argument, either a filename, a filehandle, or a dirhandle, 
358 and tests the associated file to see if something is true about it.  If the
359 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
360 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
361 the undefined value if the file doesn't exist.  Despite the funny
362 names, precedence is the same as any other named unary operator.  The
363 operator may be any of:
364
365     -r  File is readable by effective uid/gid.
366     -w  File is writable by effective uid/gid.
367     -x  File is executable by effective uid/gid.
368     -o  File is owned by effective uid.
369
370     -R  File is readable by real uid/gid.
371     -W  File is writable by real uid/gid.
372     -X  File is executable by real uid/gid.
373     -O  File is owned by real uid.
374
375     -e  File exists.
376     -z  File has zero size (is empty).
377     -s  File has nonzero size (returns size in bytes).
378
379     -f  File is a plain file.
380     -d  File is a directory.
381     -l  File is a symbolic link.
382     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
383     -S  File is a socket.
384     -b  File is a block special file.
385     -c  File is a character special file.
386     -t  Filehandle is opened to a tty.
387
388     -u  File has setuid bit set.
389     -g  File has setgid bit set.
390     -k  File has sticky bit set.
391
392     -T  File is an ASCII text file (heuristic guess).
393     -B  File is a "binary" file (opposite of -T).
394
395     -M  Script start time minus file modification time, in days.
396     -A  Same for access time.
397     -C  Same for inode change time (Unix, may differ for other
398         platforms)
399
400 Example:
401
402     while (<>) {
403         chomp;
404         next unless -f $_;  # ignore specials
405         #...
406     }
407
408 Note that C<-s/a/b/> does not do a negated substitution.  Saying
409 C<-exp($foo)> still works as expected, however: only single letters
410 following a minus are interpreted as file tests.
411
412 These operators are exempt from the "looks like a function rule" described
413 above.  That is, an opening parenthesis after the operator does not affect
414 how much of the following code constitutes the argument.  Put the opening
415 parentheses before the operator to separate it from code that follows (this
416 applies only to operators with higher precedence than unary operators, of
417 course):
418
419     -s($file) + 1024   # probably wrong; same as -s($file + 1024)
420     (-s $file) + 1024  # correct
421
422 The interpretation of the file permission operators C<-r>, C<-R>,
423 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
424 of the file and the uids and gids of the user.  There may be other
425 reasons you can't actually read, write, or execute the file: for
426 example network filesystem access controls, ACLs (access control lists),
427 read-only filesystems, and unrecognized executable formats.  Note
428 that the use of these six specific operators to verify if some operation
429 is possible is usually a mistake, because it may be open to race
430 conditions.
431
432 Also note that, for the superuser on the local filesystems, the C<-r>,
433 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
434 if any execute bit is set in the mode.  Scripts run by the superuser
435 may thus need to do a stat() to determine the actual mode of the file,
436 or temporarily set their effective uid to something else.
437
438 If you are using ACLs, there is a pragma called C<filetest> that may
439 produce more accurate results than the bare stat() mode bits.
440 When under C<use filetest 'access'> the above-mentioned filetests
441 test whether the permission can(not) be granted using the
442 access(2) family of system calls.  Also note that the C<-x> and C<-X> may
443 under this pragma return true even if there are no execute permission
444 bits set (nor any extra execute permission ACLs).  This strangeness is
445 due to the underlying system calls' definitions.  Note also that, due to
446 the implementation of C<use filetest 'access'>, the C<_> special
447 filehandle won't cache the results of the file tests when this pragma is
448 in effect.  Read the documentation for the C<filetest> pragma for more
449 information.
450
451 The C<-T> and C<-B> switches work as follows.  The first block or so of the
452 file is examined for odd characters such as strange control codes or
453 characters with the high bit set.  If too many strange characters (>30%)
454 are found, it's a C<-B> file; otherwise it's a C<-T> file.  Also, any file
455 containing a zero byte in the first block is considered a binary file.  If C<-T>
456 or C<-B> is used on a filehandle, the current IO buffer is examined
457 rather than the first block.  Both C<-T> and C<-B> return true on an empty
458 file, or a file at EOF when testing a filehandle.  Because you have to
459 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
460 against the file first, as in C<next unless -f $file && -T $file>.
461
462 If any of the file tests (or either the C<stat> or C<lstat> operator) is given
463 the special filehandle consisting of a solitary underline, then the stat
464 structure of the previous file test (or stat operator) is used, saving
465 a system call.  (This doesn't work with C<-t>, and you need to remember
466 that lstat() and C<-l> leave values in the stat structure for the
467 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
468 an C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
469 Example:
470
471     print "Can do.\n" if -r $a || -w _ || -x _;
472
473     stat($filename);
474     print "Readable\n" if -r _;
475     print "Writable\n" if -w _;
476     print "Executable\n" if -x _;
477     print "Setuid\n" if -u _;
478     print "Setgid\n" if -g _;
479     print "Sticky\n" if -k _;
480     print "Text\n" if -T _;
481     print "Binary\n" if -B _;
482
483 As of Perl 5.10.0, as a form of purely syntactic sugar, you can stack file
484 test operators, in a way that C<-f -w -x $file> is equivalent to
485 C<-x $file && -w _ && -f _>.  (This is only fancy syntax: if you use
486 the return value of C<-f $file> as an argument to another filetest
487 operator, no special magic will happen.)
488
489 Portability issues: L<perlport/-X>.
490
491 To avoid confusing would-be users of your code with mysterious
492 syntax errors, put something like this at the top of your script:
493
494     use 5.010;  # so filetest ops can stack
495
496 =item abs VALUE
497 X<abs> X<absolute>
498
499 =item abs
500
501 =for Pod::Functions absolute value function
502
503 Returns the absolute value of its argument.
504 If VALUE is omitted, uses C<$_>.
505
506 =item accept NEWSOCKET,GENERICSOCKET
507 X<accept>
508
509 =for Pod::Functions accept an incoming socket connect
510
511 Accepts an incoming socket connect, just as accept(2) 
512 does.  Returns the packed address if it succeeded, false otherwise.
513 See the example in L<perlipc/"Sockets: Client/Server Communication">.
514
515 On systems that support a close-on-exec flag on files, the flag will
516 be set for the newly opened file descriptor, as determined by the
517 value of $^F.  See L<perlvar/$^F>.
518
519 =item alarm SECONDS
520 X<alarm>
521 X<SIGALRM>
522 X<timer>
523
524 =item alarm
525
526 =for Pod::Functions schedule a SIGALRM
527
528 Arranges to have a SIGALRM delivered to this process after the
529 specified number of wallclock seconds has elapsed.  If SECONDS is not
530 specified, the value stored in C<$_> is used.  (On some machines,
531 unfortunately, the elapsed time may be up to one second less or more
532 than you specified because of how seconds are counted, and process
533 scheduling may delay the delivery of the signal even further.)
534
535 Only one timer may be counting at once.  Each call disables the
536 previous timer, and an argument of C<0> may be supplied to cancel the
537 previous timer without starting a new one.  The returned value is the
538 amount of time remaining on the previous timer.
539
540 For delays of finer granularity than one second, the Time::HiRes module
541 (from CPAN, and starting from Perl 5.8 part of the standard
542 distribution) provides ualarm().  You may also use Perl's four-argument
543 version of select() leaving the first three arguments undefined, or you
544 might be able to use the C<syscall> interface to access setitimer(2) if
545 your system supports it.  See L<perlfaq8> for details.
546
547 It is usually a mistake to intermix C<alarm> and C<sleep> calls, because
548 C<sleep> may be internally implemented on your system with C<alarm>.
549
550 If you want to use C<alarm> to time out a system call you need to use an
551 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
552 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
553 restart system calls on some systems.  Using C<eval>/C<die> always works,
554 modulo the caveats given in L<perlipc/"Signals">.
555
556     eval {
557         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
558         alarm $timeout;
559         $nread = sysread SOCKET, $buffer, $size;
560         alarm 0;
561     };
562     if ($@) {
563         die unless $@ eq "alarm\n";   # propagate unexpected errors
564         # timed out
565     }
566     else {
567         # didn't
568     }
569
570 For more information see L<perlipc>.
571
572 Portability issues: L<perlport/alarm>.
573
574 =item atan2 Y,X
575 X<atan2> X<arctangent> X<tan> X<tangent>
576
577 =for Pod::Functions arctangent of Y/X in the range -PI to PI
578
579 Returns the arctangent of Y/X in the range -PI to PI.
580
581 For the tangent operation, you may use the C<Math::Trig::tan>
582 function, or use the familiar relation:
583
584     sub tan { sin($_[0]) / cos($_[0])  }
585
586 The return value for C<atan2(0,0)> is implementation-defined; consult
587 your atan2(3) manpage for more information.
588
589 Portability issues: L<perlport/atan2>.
590
591 =item bind SOCKET,NAME
592 X<bind>
593
594 =for Pod::Functions binds an address to a socket
595
596 Binds a network address to a socket, just as bind(2)
597 does.  Returns true if it succeeded, false otherwise.  NAME should be a
598 packed address of the appropriate type for the socket.  See the examples in
599 L<perlipc/"Sockets: Client/Server Communication">.
600
601 =item binmode FILEHANDLE, LAYER
602 X<binmode> X<binary> X<text> X<DOS> X<Windows>
603
604 =item binmode FILEHANDLE
605
606 =for Pod::Functions prepare binary files for I/O
607
608 Arranges for FILEHANDLE to be read or written in "binary" or "text"
609 mode on systems where the run-time libraries distinguish between
610 binary and text files.  If FILEHANDLE is an expression, the value is
611 taken as the name of the filehandle.  Returns true on success,
612 otherwise it returns C<undef> and sets C<$!> (errno).
613
614 On some systems (in general, DOS- and Windows-based systems) binmode()
615 is necessary when you're not working with a text file.  For the sake
616 of portability it is a good idea always to use it when appropriate,
617 and never to use it when it isn't appropriate.  Also, people can
618 set their I/O to be by default UTF8-encoded Unicode, not bytes.
619
620 In other words: regardless of platform, use binmode() on binary data,
621 like images, for example.
622
623 If LAYER is present it is a single string, but may contain multiple
624 directives.  The directives alter the behaviour of the filehandle.
625 When LAYER is present, using binmode on a text file makes sense.
626
627 If LAYER is omitted or specified as C<:raw> the filehandle is made
628 suitable for passing binary data.  This includes turning off possible CRLF
629 translation and marking it as bytes (as opposed to Unicode characters).
630 Note that, despite what may be implied in I<"Programming Perl"> (the
631 Camel, 3rd edition) or elsewhere, C<:raw> is I<not> simply the inverse of C<:crlf>.
632 Other layers that would affect the binary nature of the stream are
633 I<also> disabled.  See L<PerlIO>, L<perlrun>, and the discussion about the
634 PERLIO environment variable.
635
636 The C<:bytes>, C<:crlf>, C<:utf8>, and any other directives of the
637 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
638 establish default I/O layers.  See L<open>.
639
640 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
641 in "Programming Perl, 3rd Edition".  However, since the publishing of this
642 book, by many known as "Camel III", the consensus of the naming of this
643 functionality has moved from "discipline" to "layer".  All documentation
644 of this version of Perl therefore refers to "layers" rather than to
645 "disciplines".  Now back to the regularly scheduled documentation...>
646
647 To mark FILEHANDLE as UTF-8, use C<:utf8> or C<:encoding(UTF-8)>.
648 C<:utf8> just marks the data as UTF-8 without further checking,
649 while C<:encoding(UTF-8)> checks the data for actually being valid
650 UTF-8.  More details can be found in L<PerlIO::encoding>.
651
652 In general, binmode() should be called after open() but before any I/O
653 is done on the filehandle.  Calling binmode() normally flushes any
654 pending buffered output data (and perhaps pending input data) on the
655 handle.  An exception to this is the C<:encoding> layer that
656 changes the default character encoding of the handle; see L</open>.
657 The C<:encoding> layer sometimes needs to be called in
658 mid-stream, and it doesn't flush the stream.  The C<:encoding>
659 also implicitly pushes on top of itself the C<:utf8> layer because
660 internally Perl operates on UTF8-encoded Unicode characters.
661
662 The operating system, device drivers, C libraries, and Perl run-time
663 system all conspire to let the programmer treat a single
664 character (C<\n>) as the line terminator, irrespective of external
665 representation.  On many operating systems, the native text file
666 representation matches the internal representation, but on some
667 platforms the external representation of C<\n> is made up of more than
668 one character.
669
670 All variants of Unix, Mac OS (old and new), and Stream_LF files on VMS use
671 a single character to end each line in the external representation of text
672 (even though that single character is CARRIAGE RETURN on old, pre-Darwin
673 flavors of Mac OS, and is LINE FEED on Unix and most VMS files).  In other
674 systems like OS/2, DOS, and the various flavors of MS-Windows, your program
675 sees a C<\n> as a simple C<\cJ>, but what's stored in text files are the
676 two characters C<\cM\cJ>.  That means that if you don't use binmode() on
677 these systems, C<\cM\cJ> sequences on disk will be converted to C<\n> on
678 input, and any C<\n> in your program will be converted back to C<\cM\cJ> on
679 output.  This is what you want for text files, but it can be disastrous for
680 binary files.
681
682 Another consequence of using binmode() (on some systems) is that
683 special end-of-file markers will be seen as part of the data stream.
684 For systems from the Microsoft family this means that, if your binary
685 data contain C<\cZ>, the I/O subsystem will regard it as the end of
686 the file, unless you use binmode().
687
688 binmode() is important not only for readline() and print() operations,
689 but also when using read(), seek(), sysread(), syswrite() and tell()
690 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
691 in L<perlvar> for how to manually set your input and output
692 line-termination sequences.
693
694 Portability issues: L<perlport/binmode>.
695
696 =item bless REF,CLASSNAME
697 X<bless>
698
699 =item bless REF
700
701 =for Pod::Functions create an object
702
703 This function tells the thingy referenced by REF that it is now an object
704 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
705 is used.  Because a C<bless> is often the last thing in a constructor,
706 it returns the reference for convenience.  Always use the two-argument
707 version if a derived class might inherit the function doing the blessing.
708 See L<perlobj> for more about the blessing (and blessings) of objects.
709
710 Consider always blessing objects in CLASSNAMEs that are mixed case.
711 Namespaces with all lowercase names are considered reserved for
712 Perl pragmata.  Builtin types have all uppercase names.  To prevent
713 confusion, you may wish to avoid such package names as well.  Make sure
714 that CLASSNAME is a true value.
715
716 See L<perlmod/"Perl Modules">.
717
718 =item break
719
720 =for Pod::Functions +switch break out of a C<given> block
721
722 Break out of a C<given()> block.
723
724 This keyword is enabled by the C<"switch"> feature; see L<feature> for
725 more information on C<"switch">.  You can also access it by prefixing it
726 with C<CORE::>.  Alternatively, include a C<use v5.10> or later to the
727 current scope.
728
729 =item caller EXPR
730 X<caller> X<call stack> X<stack> X<stack trace>
731
732 =item caller
733
734 =for Pod::Functions get context of the current subroutine call
735
736 Returns the context of the current pure perl subroutine call.  In scalar
737 context, returns the caller's package name if there I<is> a caller (that is, if
738 we're in a subroutine or C<eval> or C<require>) and the undefined value
739 otherwise.  caller never returns XS subs and they are skipped.  The next pure
740 perl sub will appear instead of the XS sub in caller's return values. In list
741 context, caller returns
742
743     # 0         1          2
744     ($package, $filename, $line) = caller;
745
746 With EXPR, it returns some extra information that the debugger uses to
747 print a stack trace.  The value of EXPR indicates how many call frames
748 to go back before the current one.
749
750     #  0         1          2      3            4
751     ($package, $filename, $line, $subroutine, $hasargs,
752
753     #  5          6          7            8       9         10
754     $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash)
755      = caller($i);
756
757 Here $subroutine may be C<(eval)> if the frame is not a subroutine
758 call, but an C<eval>.  In such a case additional elements $evaltext and
759 C<$is_require> are set: C<$is_require> is true if the frame is created by a
760 C<require> or C<use> statement, $evaltext contains the text of the
761 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
762 $subroutine is C<(eval)>, but $evaltext is undefined.  (Note also that
763 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
764 frame.)  $subroutine may also be C<(unknown)> if this particular
765 subroutine happens to have been deleted from the symbol table.
766 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
767 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
768 compiled with.  C<$hints> corresponds to C<$^H>, and C<$bitmask>
769 corresponds to C<${^WARNING_BITS}>.  The
770 C<$hints> and C<$bitmask> values are subject
771 to change between versions of Perl, and are not meant for external use.
772
773 C<$hinthash> is a reference to a hash containing the value of C<%^H> when the
774 caller was compiled, or C<undef> if C<%^H> was empty.  Do not modify the values
775 of this hash, as they are the actual values stored in the optree.
776
777 Furthermore, when called from within the DB package in
778 list context, and with an argument, caller returns more
779 detailed information: it sets the list variable C<@DB::args> to be the
780 arguments with which the subroutine was invoked.
781
782 Be aware that the optimizer might have optimized call frames away before
783 C<caller> had a chance to get the information.  That means that C<caller(N)>
784 might not return information about the call frame you expect it to, for
785 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
786 previous time C<caller> was called.
787
788 Be aware that setting C<@DB::args> is I<best effort>, intended for
789 debugging or generating backtraces, and should not be relied upon.  In
790 particular, as C<@_> contains aliases to the caller's arguments, Perl does
791 not take a copy of C<@_>, so C<@DB::args> will contain modifications the
792 subroutine makes to C<@_> or its contents, not the original values at call
793 time.  C<@DB::args>, like C<@_>, does not hold explicit references to its
794 elements, so under certain cases its elements may have become freed and
795 reallocated for other variables or temporary values.  Finally, a side effect
796 of the current implementation is that the effects of C<shift @_> can
797 I<normally> be undone (but not C<pop @_> or other splicing, I<and> not if a
798 reference to C<@_> has been taken, I<and> subject to the caveat about reallocated
799 elements), so C<@DB::args> is actually a hybrid of the current state and
800 initial state of C<@_>.  Buyer beware.
801
802 =item chdir EXPR
803 X<chdir>
804 X<cd>
805 X<directory, change>
806
807 =item chdir FILEHANDLE
808
809 =item chdir DIRHANDLE
810
811 =item chdir
812
813 =for Pod::Functions change your current working directory
814
815 Changes the working directory to EXPR, if possible.  If EXPR is omitted,
816 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
817 changes to the directory specified by C<$ENV{LOGDIR}>.  (Under VMS, the
818 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.)  If
819 neither is set, C<chdir> does nothing.  It returns true on success,
820 false otherwise.  See the example under C<die>.
821
822 On systems that support fchdir(2), you may pass a filehandle or
823 directory handle as the argument.  On systems that don't support fchdir(2),
824 passing handles raises an exception.
825
826 =item chmod LIST
827 X<chmod> X<permission> X<mode>
828
829 =for Pod::Functions changes the permissions on a list of files
830
831 Changes the permissions of a list of files.  The first element of the
832 list must be the numeric mode, which should probably be an octal
833 number, and which definitely should I<not> be a string of octal digits:
834 C<0644> is okay, but C<"0644"> is not.  Returns the number of files
835 successfully changed.  See also L</oct> if all you have is a string.
836
837     $cnt = chmod 0755, "foo", "bar";
838     chmod 0755, @executables;
839     $mode = "0644"; chmod $mode, "foo";      # !!! sets mode to
840                                              # --w----r-T
841     $mode = "0644"; chmod oct($mode), "foo"; # this is better
842     $mode = 0644;   chmod $mode, "foo";      # this is best
843
844 On systems that support fchmod(2), you may pass filehandles among the
845 files.  On systems that don't support fchmod(2), passing filehandles raises
846 an exception.  Filehandles must be passed as globs or glob references to be
847 recognized; barewords are considered filenames.
848
849     open(my $fh, "<", "foo");
850     my $perm = (stat $fh)[2] & 07777;
851     chmod($perm | 0600, $fh);
852
853 You can also import the symbolic C<S_I*> constants from the C<Fcntl>
854 module:
855
856     use Fcntl qw( :mode );
857     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
858     # Identical to the chmod 0755 of the example above.
859
860 Portability issues: L<perlport/chmod>.
861
862 =item chomp VARIABLE
863 X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol>
864
865 =item chomp( LIST )
866
867 =item chomp
868
869 =for Pod::Functions remove a trailing record separator from a string
870
871 This safer version of L</chop> removes any trailing string
872 that corresponds to the current value of C<$/> (also known as
873 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
874 number of characters removed from all its arguments.  It's often used to
875 remove the newline from the end of an input record when you're worried
876 that the final record may be missing its newline.  When in paragraph
877 mode (C<$/ = "">), it removes all trailing newlines from the string.
878 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
879 a reference to an integer or the like; see L<perlvar>) chomp() won't
880 remove anything.
881 If VARIABLE is omitted, it chomps C<$_>.  Example:
882
883     while (<>) {
884         chomp;  # avoid \n on last field
885         @array = split(/:/);
886         # ...
887     }
888
889 If VARIABLE is a hash, it chomps the hash's values, but not its keys,
890 resetting the C<each> iterator in the process.
891
892 You can actually chomp anything that's an lvalue, including an assignment:
893
894     chomp($cwd = `pwd`);
895     chomp($answer = <STDIN>);
896
897 If you chomp a list, each element is chomped, and the total number of
898 characters removed is returned.
899
900 Note that parentheses are necessary when you're chomping anything
901 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
902 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
903 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
904 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
905 as C<chomp($a, $b)>.
906
907 =item chop VARIABLE
908 X<chop>
909
910 =item chop( LIST )
911
912 =item chop
913
914 =for Pod::Functions remove the last character from a string
915
916 Chops off the last character of a string and returns the character
917 chopped.  It is much more efficient than C<s/.$//s> because it neither
918 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
919 If VARIABLE is a hash, it chops the hash's values, but not its keys,
920 resetting the C<each> iterator in the process.
921
922 You can actually chop anything that's an lvalue, including an assignment.
923
924 If you chop a list, each element is chopped.  Only the value of the
925 last C<chop> is returned.
926
927 Note that C<chop> returns the last character.  To return all but the last
928 character, use C<substr($string, 0, -1)>.
929
930 See also L</chomp>.
931
932 =item chown LIST
933 X<chown> X<owner> X<user> X<group>
934
935 =for Pod::Functions change the ownership on a list of files
936
937 Changes the owner (and group) of a list of files.  The first two
938 elements of the list must be the I<numeric> uid and gid, in that
939 order.  A value of -1 in either position is interpreted by most
940 systems to leave that value unchanged.  Returns the number of files
941 successfully changed.
942
943     $cnt = chown $uid, $gid, 'foo', 'bar';
944     chown $uid, $gid, @filenames;
945
946 On systems that support fchown(2), you may pass filehandles among the
947 files.  On systems that don't support fchown(2), passing filehandles raises
948 an exception.  Filehandles must be passed as globs or glob references to be
949 recognized; barewords are considered filenames.
950
951 Here's an example that looks up nonnumeric uids in the passwd file:
952
953     print "User: ";
954     chomp($user = <STDIN>);
955     print "Files: ";
956     chomp($pattern = <STDIN>);
957
958     ($login,$pass,$uid,$gid) = getpwnam($user)
959         or die "$user not in passwd file";
960
961     @ary = glob($pattern);  # expand filenames
962     chown $uid, $gid, @ary;
963
964 On most systems, you are not allowed to change the ownership of the
965 file unless you're the superuser, although you should be able to change
966 the group to any of your secondary groups.  On insecure systems, these
967 restrictions may be relaxed, but this is not a portable assumption.
968 On POSIX systems, you can detect this condition this way:
969
970     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
971     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
972
973 Portability issues: L<perlport/chmod>.
974
975 =item chr NUMBER
976 X<chr> X<character> X<ASCII> X<Unicode>
977
978 =item chr
979
980 =for Pod::Functions get character this number represents
981
982 Returns the character represented by that NUMBER in the character set.
983 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
984 chr(0x263a) is a Unicode smiley face.  
985
986 Negative values give the Unicode replacement character (chr(0xfffd)),
987 except under the L<bytes> pragma, where the low eight bits of the value
988 (truncated to an integer) are used.
989
990 If NUMBER is omitted, uses C<$_>.
991
992 For the reverse, use L</ord>.
993
994 Note that characters from 128 to 255 (inclusive) are by default
995 internally not encoded as UTF-8 for backward compatibility reasons.
996
997 See L<perlunicode> for more about Unicode.
998
999 =item chroot FILENAME
1000 X<chroot> X<root>
1001
1002 =item chroot
1003
1004 =for Pod::Functions make directory new root for path lookups
1005
1006 This function works like the system call by the same name: it makes the
1007 named directory the new root directory for all further pathnames that
1008 begin with a C</> by your process and all its children.  (It doesn't
1009 change your current working directory, which is unaffected.)  For security
1010 reasons, this call is restricted to the superuser.  If FILENAME is
1011 omitted, does a C<chroot> to C<$_>.
1012
1013 Portability issues: L<perlport/chroot>.
1014
1015 =item close FILEHANDLE
1016 X<close>
1017
1018 =item close
1019
1020 =for Pod::Functions close file (or pipe or socket) handle
1021
1022 Closes the file or pipe associated with the filehandle, flushes the IO
1023 buffers, and closes the system file descriptor.  Returns true if those
1024 operations succeed and if no error was reported by any PerlIO
1025 layer.  Closes the currently selected filehandle if the argument is
1026 omitted.
1027
1028 You don't have to close FILEHANDLE if you are immediately going to do
1029 another C<open> on it, because C<open> closes it for you.  (See
1030 L<open|/open FILEHANDLE>.)  However, an explicit C<close> on an input file resets the line
1031 counter (C<$.>), while the implicit close done by C<open> does not.
1032
1033 If the filehandle came from a piped open, C<close> returns false if one of
1034 the other syscalls involved fails or if its program exits with non-zero
1035 status.  If the only problem was that the program exited non-zero, C<$!>
1036 will be set to C<0>.  Closing a pipe also waits for the process executing
1037 on the pipe to exit--in case you wish to look at the output of the pipe
1038 afterwards--and implicitly puts the exit status value of that command into
1039 C<$?> and C<${^CHILD_ERROR_NATIVE}>.
1040
1041 If there are multiple threads running, C<close> on a filehandle from a
1042 piped open returns true without waiting for the child process to terminate,
1043 if the filehandle is still open in another thread.
1044
1045 Closing the read end of a pipe before the process writing to it at the
1046 other end is done writing results in the writer receiving a SIGPIPE.  If
1047 the other end can't handle that, be sure to read all the data before
1048 closing the pipe.
1049
1050 Example:
1051
1052     open(OUTPUT, '|sort >foo')  # pipe to sort
1053         or die "Can't start sort: $!";
1054     #...                        # print stuff to output
1055     close OUTPUT                # wait for sort to finish
1056         or warn $! ? "Error closing sort pipe: $!"
1057                    : "Exit status $? from sort";
1058     open(INPUT, 'foo')          # get sort's results
1059         or die "Can't open 'foo' for input: $!";
1060
1061 FILEHANDLE may be an expression whose value can be used as an indirect
1062 filehandle, usually the real filehandle name or an autovivified handle.
1063
1064 =item closedir DIRHANDLE
1065 X<closedir>
1066
1067 =for Pod::Functions close directory handle
1068
1069 Closes a directory opened by C<opendir> and returns the success of that
1070 system call.
1071
1072 =item connect SOCKET,NAME
1073 X<connect>
1074
1075 =for Pod::Functions connect to a remote socket
1076
1077 Attempts to connect to a remote socket, just like connect(2).
1078 Returns true if it succeeded, false otherwise.  NAME should be a
1079 packed address of the appropriate type for the socket.  See the examples in
1080 L<perlipc/"Sockets: Client/Server Communication">.
1081
1082 =item continue BLOCK
1083 X<continue>
1084
1085 =item continue
1086
1087 =for Pod::Functions optional trailing block in a while or foreach
1088
1089 When followed by a BLOCK, C<continue> is actually a
1090 flow control statement rather than a function.  If
1091 there is a C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
1092 C<foreach>), it is always executed just before the conditional is about to
1093 be evaluated again, just like the third part of a C<for> loop in C.  Thus
1094 it can be used to increment a loop variable, even when the loop has been
1095 continued via the C<next> statement (which is similar to the C C<continue>
1096 statement).
1097
1098 C<last>, C<next>, or C<redo> may appear within a C<continue>
1099 block; C<last> and C<redo> behave as if they had been executed within
1100 the main block.  So will C<next>, but since it will execute a C<continue>
1101 block, it may be more entertaining.
1102
1103     while (EXPR) {
1104         ### redo always comes here
1105         do_something;
1106     } continue {
1107         ### next always comes here
1108         do_something_else;
1109         # then back the top to re-check EXPR
1110     }
1111     ### last always comes here
1112
1113 Omitting the C<continue> section is equivalent to using an
1114 empty one, logically enough, so C<next> goes directly back
1115 to check the condition at the top of the loop.
1116
1117 When there is no BLOCK, C<continue> is a function that
1118 falls through the current C<when> or C<default> block instead of iterating
1119 a dynamically enclosing C<foreach> or exiting a lexically enclosing C<given>.
1120 In Perl 5.14 and earlier, this form of C<continue> was
1121 only available when the C<"switch"> feature was enabled.
1122 See L<feature> and L<perlsyn/"Switch Statements"> for more
1123 information.
1124
1125 =item cos EXPR
1126 X<cos> X<cosine> X<acos> X<arccosine>
1127
1128 =item cos
1129
1130 =for Pod::Functions cosine function
1131
1132 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
1133 takes the cosine of C<$_>.
1134
1135 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
1136 function, or use this relation:
1137
1138     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
1139
1140 =item crypt PLAINTEXT,SALT
1141 X<crypt> X<digest> X<hash> X<salt> X<plaintext> X<password>
1142 X<decrypt> X<cryptography> X<passwd> X<encrypt>
1143
1144 =for Pod::Functions one-way passwd-style encryption
1145
1146 Creates a digest string exactly like the crypt(3) function in the C
1147 library (assuming that you actually have a version there that has not
1148 been extirpated as a potential munition).
1149
1150 crypt() is a one-way hash function.  The PLAINTEXT and SALT are turned
1151 into a short string, called a digest, which is returned.  The same
1152 PLAINTEXT and SALT will always return the same string, but there is no
1153 (known) way to get the original PLAINTEXT from the hash.  Small
1154 changes in the PLAINTEXT or SALT will result in large changes in the
1155 digest.
1156
1157 There is no decrypt function.  This function isn't all that useful for
1158 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
1159 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
1160 primarily used to check if two pieces of text are the same without
1161 having to transmit or store the text itself.  An example is checking
1162 if a correct password is given.  The digest of the password is stored,
1163 not the password itself.  The user types in a password that is
1164 crypt()'d with the same salt as the stored digest.  If the two digests
1165 match, the password is correct.
1166
1167 When verifying an existing digest string you should use the digest as
1168 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
1169 to create the digest is visible as part of the digest.  This ensures
1170 crypt() will hash the new string with the same salt as the digest.
1171 This allows your code to work with the standard L<crypt|/crypt> and
1172 with more exotic implementations.  In other words, assume
1173 nothing about the returned string itself nor about how many bytes 
1174 of SALT may matter.
1175
1176 Traditionally the result is a string of 13 bytes: two first bytes of
1177 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
1178 the first eight bytes of PLAINTEXT mattered.  But alternative
1179 hashing schemes (like MD5), higher level security schemes (like C2),
1180 and implementations on non-Unix platforms may produce different
1181 strings.
1182
1183 When choosing a new salt create a random two character string whose
1184 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
1185 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
1186 characters is just a recommendation; the characters allowed in
1187 the salt depend solely on your system's crypt library, and Perl can't
1188 restrict what salts C<crypt()> accepts.
1189
1190 Here's an example that makes sure that whoever runs this program knows
1191 their password:
1192
1193     $pwd = (getpwuid($<))[1];
1194
1195     system "stty -echo";
1196     print "Password: ";
1197     chomp($word = <STDIN>);
1198     print "\n";
1199     system "stty echo";
1200
1201     if (crypt($word, $pwd) ne $pwd) {
1202         die "Sorry...\n";
1203     } else {
1204         print "ok\n";
1205     }
1206
1207 Of course, typing in your own password to whoever asks you
1208 for it is unwise.
1209
1210 The L<crypt|/crypt> function is unsuitable for hashing large quantities
1211 of data, not least of all because you can't get the information
1212 back.  Look at the L<Digest> module for more robust algorithms.
1213
1214 If using crypt() on a Unicode string (which I<potentially> has
1215 characters with codepoints above 255), Perl tries to make sense
1216 of the situation by trying to downgrade (a copy of)
1217 the string back to an eight-bit byte string before calling crypt()
1218 (on that copy).  If that works, good.  If not, crypt() dies with
1219 C<Wide character in crypt>.
1220
1221 Portability issues: L<perlport/crypt>.
1222
1223 =item dbmclose HASH
1224 X<dbmclose>
1225
1226 =for Pod::Functions breaks binding on a tied dbm file
1227
1228 [This function has been largely superseded by the C<untie> function.]
1229
1230 Breaks the binding between a DBM file and a hash.
1231
1232 Portability issues: L<perlport/dbmclose>.
1233
1234 =item dbmopen HASH,DBNAME,MASK
1235 X<dbmopen> X<dbm> X<ndbm> X<sdbm> X<gdbm>
1236
1237 =for Pod::Functions create binding on a tied dbm file
1238
1239 [This function has been largely superseded by the
1240 L<tie|/tie VARIABLE,CLASSNAME,LIST> function.]
1241
1242 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
1243 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
1244 argument is I<not> a filehandle, even though it looks like one).  DBNAME
1245 is the name of the database (without the F<.dir> or F<.pag> extension if
1246 any).  If the database does not exist, it is created with protection
1247 specified by MASK (as modified by the C<umask>).  To prevent creation of
1248 the database if it doesn't exist, you may specify a MODE
1249 of 0, and the function will return a false value if it
1250 can't find an existing database.  If your system supports
1251 only the older DBM functions, you may make only one C<dbmopen> call in your
1252 program.  In older versions of Perl, if your system had neither DBM nor
1253 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
1254 sdbm(3).
1255
1256 If you don't have write access to the DBM file, you can only read hash
1257 variables, not set them.  If you want to test whether you can write,
1258 either use file tests or try setting a dummy hash entry inside an C<eval> 
1259 to trap the error.
1260
1261 Note that functions such as C<keys> and C<values> may return huge lists
1262 when used on large DBM files.  You may prefer to use the C<each>
1263 function to iterate over large DBM files.  Example:
1264
1265     # print out history file offsets
1266     dbmopen(%HIST,'/usr/lib/news/history',0666);
1267     while (($key,$val) = each %HIST) {
1268         print $key, ' = ', unpack('L',$val), "\n";
1269     }
1270     dbmclose(%HIST);
1271
1272 See also L<AnyDBM_File> for a more general description of the pros and
1273 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1274 rich implementation.
1275
1276 You can control which DBM library you use by loading that library
1277 before you call dbmopen():
1278
1279     use DB_File;
1280     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1281         or die "Can't open netscape history file: $!";
1282
1283 Portability issues: L<perlport/dbmopen>.
1284
1285 =item defined EXPR
1286 X<defined> X<undef> X<undefined>
1287
1288 =item defined
1289
1290 =for Pod::Functions test whether a value, variable, or function is defined
1291
1292 Returns a Boolean value telling whether EXPR has a value other than
1293 the undefined value C<undef>.  If EXPR is not present, C<$_> is
1294 checked.
1295
1296 Many operations return C<undef> to indicate failure, end of file,
1297 system error, uninitialized variable, and other exceptional
1298 conditions.  This function allows you to distinguish C<undef> from
1299 other values.  (A simple Boolean test will not distinguish among
1300 C<undef>, zero, the empty string, and C<"0">, which are all equally
1301 false.)  Note that since C<undef> is a valid scalar, its presence
1302 doesn't I<necessarily> indicate an exceptional condition: C<pop>
1303 returns C<undef> when its argument is an empty array, I<or> when the
1304 element to return happens to be C<undef>.
1305
1306 You may also use C<defined(&func)> to check whether subroutine C<&func>
1307 has ever been defined.  The return value is unaffected by any forward
1308 declarations of C<&func>.  A subroutine that is not defined
1309 may still be callable: its package may have an C<AUTOLOAD> method that
1310 makes it spring into existence the first time that it is called; see
1311 L<perlsub>.
1312
1313 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1314 used to report whether memory for that aggregate had ever been
1315 allocated.  This behavior may disappear in future versions of Perl.
1316 You should instead use a simple test for size:
1317
1318     if (@an_array) { print "has array elements\n" }
1319     if (%a_hash)   { print "has hash members\n"   }
1320
1321 When used on a hash element, it tells you whether the value is defined,
1322 not whether the key exists in the hash.  Use L</exists> for the latter
1323 purpose.
1324
1325 Examples:
1326
1327     print if defined $switch{D};
1328     print "$val\n" while defined($val = pop(@ary));
1329     die "Can't readlink $sym: $!"
1330         unless defined($value = readlink $sym);
1331     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1332     $debugging = 0 unless defined $debugging;
1333
1334 Note:  Many folks tend to overuse C<defined> and are then surprised to
1335 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1336 defined values.  For example, if you say
1337
1338     "ab" =~ /a(.*)b/;
1339
1340 The pattern match succeeds and C<$1> is defined, although it
1341 matched "nothing".  It didn't really fail to match anything.  Rather, it
1342 matched something that happened to be zero characters long.  This is all
1343 very above-board and honest.  When a function returns an undefined value,
1344 it's an admission that it couldn't give you an honest answer.  So you
1345 should use C<defined> only when questioning the integrity of what
1346 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1347 what you want.
1348
1349 See also L</undef>, L</exists>, L</ref>.
1350
1351 =item delete EXPR
1352 X<delete>
1353
1354 =for Pod::Functions deletes a value from a hash
1355
1356 Given an expression that specifies an element or slice of a hash, C<delete>
1357 deletes the specified elements from that hash so that exists() on that element
1358 no longer returns true.  Setting a hash element to the undefined value does
1359 not remove its key, but deleting it does; see L</exists>.
1360
1361 In list context, returns the value or values deleted, or the last such
1362 element in scalar context.  The return list's length always matches that of
1363 the argument list: deleting non-existent elements returns the undefined value
1364 in their corresponding positions.
1365
1366 delete() may also be used on arrays and array slices, but its behavior is less
1367 straightforward.  Although exists() will return false for deleted entries,
1368 deleting array elements never changes indices of existing values; use shift()
1369 or splice() for that.  However, if all deleted elements fall at the end of an
1370 array, the array's size shrinks to the position of the highest element that
1371 still tests true for exists(), or to 0 if none do.
1372
1373 B<WARNING:> Calling delete on array values is deprecated and likely to
1374 be removed in a future version of Perl.
1375
1376 Deleting from C<%ENV> modifies the environment.  Deleting from a hash tied to
1377 a DBM file deletes the entry from the DBM file.  Deleting from a C<tied> hash
1378 or array may not necessarily return anything; it depends on the implementation
1379 of the C<tied> package's DELETE method, which may do whatever it pleases.
1380
1381 The C<delete local EXPR> construct localizes the deletion to the current
1382 block at run time.  Until the block exits, elements locally deleted
1383 temporarily no longer exist.  See L<perlsub/"Localized deletion of elements
1384 of composite types">.
1385
1386     %hash = (foo => 11, bar => 22, baz => 33);
1387     $scalar = delete $hash{foo};         # $scalar is 11
1388     $scalar = delete @hash{qw(foo bar)}; # $scalar is 22
1389     @array  = delete @hash{qw(foo baz)}; # @array  is (undef,33)
1390
1391 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1392
1393     foreach $key (keys %HASH) {
1394         delete $HASH{$key};
1395     }
1396
1397     foreach $index (0 .. $#ARRAY) {
1398         delete $ARRAY[$index];
1399     }
1400
1401 And so do these:
1402
1403     delete @HASH{keys %HASH};
1404
1405     delete @ARRAY[0 .. $#ARRAY];
1406
1407 But both are slower than assigning the empty list
1408 or undefining %HASH or @ARRAY, which is the customary 
1409 way to empty out an aggregate:
1410
1411     %HASH = ();     # completely empty %HASH
1412     undef %HASH;    # forget %HASH ever existed
1413
1414     @ARRAY = ();    # completely empty @ARRAY
1415     undef @ARRAY;   # forget @ARRAY ever existed
1416
1417 The EXPR can be arbitrarily complicated provided its
1418 final operation is an element or slice of an aggregate:
1419
1420     delete $ref->[$x][$y]{$key};
1421     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1422
1423     delete $ref->[$x][$y][$index];
1424     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1425
1426 =item die LIST
1427 X<die> X<throw> X<exception> X<raise> X<$@> X<abort>
1428
1429 =for Pod::Functions raise an exception or bail out
1430
1431 C<die> raises an exception.  Inside an C<eval> the error message is stuffed
1432 into C<$@> and the C<eval> is terminated with the undefined value.
1433 If the exception is outside of all enclosing C<eval>s, then the uncaught
1434 exception prints LIST to C<STDERR> and exits with a non-zero value.  If you
1435 need to exit the process with a specific exit code, see L</exit>.
1436
1437 Equivalent examples:
1438
1439     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1440     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1441
1442 If the last element of LIST does not end in a newline, the current
1443 script line number and input line number (if any) are also printed,
1444 and a newline is supplied.  Note that the "input line number" (also
1445 known as "chunk") is subject to whatever notion of "line" happens to
1446 be currently in effect, and is also available as the special variable
1447 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1448
1449 Hint: sometimes appending C<", stopped"> to your message will cause it
1450 to make better sense when the string C<"at foo line 123"> is appended.
1451 Suppose you are running script "canasta".
1452
1453     die "/etc/games is no good";
1454     die "/etc/games is no good, stopped";
1455
1456 produce, respectively
1457
1458     /etc/games is no good at canasta line 123.
1459     /etc/games is no good, stopped at canasta line 123.
1460
1461 If the output is empty and C<$@> already contains a value (typically from a
1462 previous eval) that value is reused after appending C<"\t...propagated">.
1463 This is useful for propagating exceptions:
1464
1465     eval { ... };
1466     die unless $@ =~ /Expected exception/;
1467
1468 If the output is empty and C<$@> contains an object reference that has a
1469 C<PROPAGATE> method, that method will be called with additional file
1470 and line number parameters.  The return value replaces the value in
1471 C<$@>;  i.e., as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1472 were called.
1473
1474 If C<$@> is empty then the string C<"Died"> is used.
1475
1476 If an uncaught exception results in interpreter exit, the exit code is
1477 determined from the values of C<$!> and C<$?> with this pseudocode:
1478
1479     exit $! if $!;              # errno
1480     exit $? >> 8 if $? >> 8;    # child exit status
1481     exit 255;                   # last resort
1482
1483 The intent is to squeeze as much possible information about the likely cause
1484 into the limited space of the system exit
1485 code.  However, as C<$!> is the value
1486 of C's C<errno>, which can be set by any system call, this means that the value
1487 of the exit code used by C<die> can be non-predictable, so should not be relied
1488 upon, other than to be non-zero.
1489
1490 You can also call C<die> with a reference argument, and if this is trapped
1491 within an C<eval>, C<$@> contains that reference.  This permits more
1492 elaborate exception handling using objects that maintain arbitrary state
1493 about the exception.  Such a scheme is sometimes preferable to matching
1494 particular string values of C<$@> with regular expressions.  Because C<$@> 
1495 is a global variable and C<eval> may be used within object implementations,
1496 be careful that analyzing the error object doesn't replace the reference in
1497 the global variable.  It's easiest to make a local copy of the reference
1498 before any manipulations.  Here's an example:
1499
1500     use Scalar::Util "blessed";
1501
1502     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1503     if (my $ev_err = $@) {
1504         if (blessed($ev_err)
1505             && $ev_err->isa("Some::Module::Exception")) {
1506             # handle Some::Module::Exception
1507         }
1508         else {
1509             # handle all other possible exceptions
1510         }
1511     }
1512
1513 Because Perl stringifies uncaught exception messages before display,
1514 you'll probably want to overload stringification operations on
1515 exception objects.  See L<overload> for details about that.
1516
1517 You can arrange for a callback to be run just before the C<die>
1518 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1519 handler is called with the error text and can change the error
1520 message, if it sees fit, by calling C<die> again.  See
1521 L<perlvar/%SIG> for details on setting C<%SIG> entries, and
1522 L<"eval BLOCK"> for some examples.  Although this feature was 
1523 to be run only right before your program was to exit, this is not
1524 currently so: the C<$SIG{__DIE__}> hook is currently called
1525 even inside eval()ed blocks/strings!  If one wants the hook to do
1526 nothing in such situations, put
1527
1528     die @_ if $^S;
1529
1530 as the first line of the handler (see L<perlvar/$^S>).  Because
1531 this promotes strange action at a distance, this counterintuitive
1532 behavior may be fixed in a future release.
1533
1534 See also exit(), warn(), and the Carp module.
1535
1536 =item do BLOCK
1537 X<do> X<block>
1538
1539 =for Pod::Functions turn a BLOCK into a TERM
1540
1541 Not really a function.  Returns the value of the last command in the
1542 sequence of commands indicated by BLOCK.  When modified by the C<while> or
1543 C<until> loop modifier, executes the BLOCK once before testing the loop
1544 condition.  (On other statements the loop modifiers test the conditional
1545 first.)
1546
1547 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1548 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1549 See L<perlsyn> for alternative strategies.
1550
1551 =item do SUBROUTINE(LIST)
1552 X<do>
1553
1554 This form of subroutine call is deprecated.  SUBROUTINE can be a bareword
1555 or scalar variable.
1556
1557 =item do EXPR
1558 X<do>
1559
1560 Uses the value of EXPR as a filename and executes the contents of the
1561 file as a Perl script.
1562
1563     do 'stat.pl';
1564
1565 is largely like
1566
1567     eval `cat stat.pl`;
1568
1569 except that it's more concise, runs no external processes, keeps track of
1570 the current
1571 filename for error messages, searches the C<@INC> directories, and updates
1572 C<%INC> if the file is found.  See L<perlvar/@INC> and L<perlvar/%INC> for
1573 these variables.  It also differs in that code evaluated with C<do FILENAME>
1574 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1575 same, however, in that it does reparse the file every time you call it,
1576 so you probably don't want to do this inside a loop.
1577
1578 If C<do> can read the file but cannot compile it, it returns C<undef> and sets
1579 an error message in C<$@>.  If C<do> cannot read the file, it returns undef
1580 and sets C<$!> to the error.  Always check C<$@> first, as compilation
1581 could fail in a way that also sets C<$!>.  If the file is successfully
1582 compiled, C<do> returns the value of the last expression evaluated.
1583
1584 Inclusion of library modules is better done with the
1585 C<use> and C<require> operators, which also do automatic error checking
1586 and raise an exception if there's a problem.
1587
1588 You might like to use C<do> to read in a program configuration
1589 file.  Manual error checking can be done this way:
1590
1591     # read in config files: system first, then user
1592     for $file ("/share/prog/defaults.rc",
1593                "$ENV{HOME}/.someprogrc")
1594     {
1595         unless ($return = do $file) {
1596             warn "couldn't parse $file: $@" if $@;
1597             warn "couldn't do $file: $!"    unless defined $return;
1598             warn "couldn't run $file"       unless $return;
1599         }
1600     }
1601
1602 =item dump LABEL
1603 X<dump> X<core> X<undump>
1604
1605 =item dump EXPR
1606
1607 =item dump
1608
1609 =for Pod::Functions create an immediate core dump
1610
1611 This function causes an immediate core dump.  See also the B<-u>
1612 command-line switch in L<perlrun>, which does the same thing.
1613 Primarily this is so that you can use the B<undump> program (not
1614 supplied) to turn your core dump into an executable binary after
1615 having initialized all your variables at the beginning of the
1616 program.  When the new binary is executed it will begin by executing
1617 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1618 Think of it as a goto with an intervening core dump and reincarnation.
1619 If C<LABEL> is omitted, restarts the program from the top.  The
1620 C<dump EXPR> form, available starting in Perl 5.18.0, allows a name to be
1621 computed at run time, being otherwise identical to C<dump LABEL>.
1622
1623 B<WARNING>: Any files opened at the time of the dump will I<not>
1624 be open any more when the program is reincarnated, with possible
1625 resulting confusion by Perl.
1626
1627 This function is now largely obsolete, mostly because it's very hard to
1628 convert a core file into an executable.  That's why you should now invoke
1629 it as C<CORE::dump()>, if you don't want to be warned against a possible
1630 typo.
1631
1632 Unlike most named operators, this has the same precedence as assignment.
1633 It is also exempt from the looks-like-a-function rule, so
1634 C<dump ("foo")."bar"> will cause "bar" to be part of the argument to
1635 C<dump>.
1636
1637 Portability issues: L<perlport/dump>.
1638
1639 =item each HASH
1640 X<each> X<hash, iterator>
1641
1642 =item each ARRAY
1643 X<array, iterator>
1644
1645 =item each EXPR
1646
1647 =for Pod::Functions retrieve the next key/value pair from a hash
1648
1649 When called on a hash in list context, returns a 2-element list
1650 consisting of the key and value for the next element of a hash.  In Perl
1651 5.12 and later only, it will also return the index and value for the next
1652 element of an array so that you can iterate over it; older Perls consider
1653 this a syntax error.  When called in scalar context, returns only the key
1654 (not the value) in a hash, or the index in an array.
1655
1656 Hash entries are returned in an apparently random order.  The actual random
1657 order is specific to a given hash; the exact same series of operations
1658 on two hashes may result in a different order for each hash.  Any insertion
1659 into the hash may change the order, as will any deletion, with the exception
1660 that the most recent key returned by C<each> or C<keys> may be deleted
1661 without changing the order.  So long as a given hash is unmodified you may
1662 rely on C<keys>, C<values> and C<each> to repeatedly return the same order
1663 as each other.  See L<perlsec/"Algorithmic Complexity Attacks"> for
1664 details on why hash order is randomized.  Aside from the guarantees
1665 provided here the exact details of Perl's hash algorithm and the hash
1666 traversal order are subject to change in any release of Perl.
1667
1668 After C<each> has returned all entries from the hash or array, the next
1669 call to C<each> returns the empty list in list context and C<undef> in
1670 scalar context; the next call following I<that> one restarts iteration.
1671 Each hash or array has its own internal iterator, accessed by C<each>,
1672 C<keys>, and C<values>.  The iterator is implicitly reset when C<each> has
1673 reached the end as just described; it can be explicitly reset by calling
1674 C<keys> or C<values> on the hash or array.  If you add or delete a hash's
1675 elements while iterating over it, entries may be skipped or duplicated--so
1676 don't do that.  Exception: In the current implementation, it is always safe
1677 to delete the item most recently returned by C<each()>, so the following
1678 code works properly:
1679
1680         while (($key, $value) = each %hash) {
1681           print $key, "\n";
1682           delete $hash{$key};   # This is safe
1683         }
1684
1685 This prints out your environment like the printenv(1) program,
1686 but in a different order:
1687
1688     while (($key,$value) = each %ENV) {
1689         print "$key=$value\n";
1690     }
1691
1692 Starting with Perl 5.14, C<each> can take a scalar EXPR, which must hold
1693 reference to an unblessed hash or array.  The argument will be dereferenced
1694 automatically.  This aspect of C<each> is considered highly experimental.
1695 The exact behaviour may change in a future version of Perl.
1696
1697     while (($key,$value) = each $hashref) { ... }
1698
1699 As of Perl 5.18 you can use a bare C<each> in a C<while> loop,
1700 which will set C<$_> on every iteration.
1701
1702     while(each %ENV) {
1703         print "$_=$ENV{$_}\n";
1704     }
1705
1706 To avoid confusing would-be users of your code who are running earlier
1707 versions of Perl with mysterious syntax errors, put this sort of thing at
1708 the top of your file to signal that your code will work I<only> on Perls of
1709 a recent vintage:
1710
1711     use 5.012;  # so keys/values/each work on arrays
1712     use 5.014;  # so keys/values/each work on scalars (experimental)
1713     use 5.018;  # so each assigns to $_ in a lone while test
1714
1715 See also C<keys>, C<values>, and C<sort>.
1716
1717 =item eof FILEHANDLE
1718 X<eof>
1719 X<end of file>
1720 X<end-of-file>
1721
1722 =item eof ()
1723
1724 =item eof
1725
1726 =for Pod::Functions test a filehandle for its end
1727
1728 Returns 1 if the next read on FILEHANDLE will return end of file I<or> if
1729 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1730 gives the real filehandle.  (Note that this function actually
1731 reads a character and then C<ungetc>s it, so isn't useful in an
1732 interactive context.)  Do not read from a terminal file (or call
1733 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1734 as terminals may lose the end-of-file condition if you do.
1735
1736 An C<eof> without an argument uses the last file read.  Using C<eof()>
1737 with empty parentheses is different.  It refers to the pseudo file
1738 formed from the files listed on the command line and accessed via the
1739 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1740 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1741 used will cause C<@ARGV> to be examined to determine if input is
1742 available.   Similarly, an C<eof()> after C<< <> >> has returned
1743 end-of-file will assume you are processing another C<@ARGV> list,
1744 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1745 see L<perlop/"I/O Operators">.
1746
1747 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1748 detect the end of each file, whereas C<eof()> will detect the end 
1749 of the very last file only.  Examples:
1750
1751     # reset line numbering on each input file
1752     while (<>) {
1753         next if /^\s*#/;  # skip comments
1754         print "$.\t$_";
1755     } continue {
1756         close ARGV if eof;  # Not eof()!
1757     }
1758
1759     # insert dashes just before last line of last file
1760     while (<>) {
1761         if (eof()) {  # check for end of last file
1762             print "--------------\n";
1763         }
1764         print;
1765         last if eof();     # needed if we're reading from a terminal
1766     }
1767
1768 Practical hint: you almost never need to use C<eof> in Perl, because the
1769 input operators typically return C<undef> when they run out of data or 
1770 encounter an error.
1771
1772 =item eval EXPR
1773 X<eval> X<try> X<catch> X<evaluate> X<parse> X<execute>
1774 X<error, handling> X<exception, handling>
1775
1776 =item eval BLOCK
1777
1778 =item eval
1779
1780 =for Pod::Functions catch exceptions or compile and run code
1781
1782 In the first form, often referred to as a "string eval", the return
1783 value of EXPR is parsed and executed as if it
1784 were a little Perl program.  The value of the expression (which is itself
1785 determined within scalar context) is first parsed, and if there were no
1786 errors, executed as a block within the lexical context of the current Perl
1787 program.  This means, that in particular, any outer lexical variables are
1788 visible to it, and any package variable settings or subroutine and format
1789 definitions remain afterwards.
1790
1791 Note that the value is parsed every time the C<eval> executes.
1792 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1793 delay parsing and subsequent execution of the text of EXPR until run time.
1794
1795 If the C<unicode_eval> feature is enabled (which is the default under a
1796 C<use 5.16> or higher declaration), EXPR or C<$_> is treated as a string of
1797 characters, so C<use utf8> declarations have no effect, and source filters
1798 are forbidden.  In the absence of the C<unicode_eval> feature, the string
1799 will sometimes be treated as characters and sometimes as bytes, depending
1800 on the internal encoding, and source filters activated within the C<eval>
1801 exhibit the erratic, but historical, behaviour of affecting some outer file
1802 scope that is still compiling.  See also the L</evalbytes> keyword, which
1803 always treats its input as a byte stream and works properly with source
1804 filters, and the L<feature> pragma.
1805
1806 Problems can arise if the string expands a scalar containing a floating
1807 point number.  That scalar can expand to letters, such as C<"NaN"> or
1808 C<"Infinity">; or, within the scope of a C<use locale>, the decimal
1809 point character may be something other than a dot (such as a comma).
1810 None of these are likely to parse as you are likely expecting.
1811
1812 In the second form, the code within the BLOCK is parsed only once--at the
1813 same time the code surrounding the C<eval> itself was parsed--and executed
1814 within the context of the current Perl program.  This form is typically
1815 used to trap exceptions more efficiently than the first (see below), while
1816 also providing the benefit of checking the code within BLOCK at compile
1817 time.
1818
1819 The final semicolon, if any, may be omitted from the value of EXPR or within
1820 the BLOCK.
1821
1822 In both forms, the value returned is the value of the last expression
1823 evaluated inside the mini-program; a return statement may be also used, just
1824 as with subroutines.  The expression providing the return value is evaluated
1825 in void, scalar, or list context, depending on the context of the C<eval> 
1826 itself.  See L</wantarray> for more on how the evaluation context can be 
1827 determined.
1828
1829 If there is a syntax error or runtime error, or a C<die> statement is
1830 executed, C<eval> returns C<undef> in scalar context
1831 or an empty list in list context, and C<$@> is set to the error
1832 message.  (Prior to 5.16, a bug caused C<undef> to be returned
1833 in list context for syntax errors, but not for runtime errors.)
1834 If there was no error, C<$@> is set to the empty string.  A
1835 control flow operator like C<last> or C<goto> can bypass the setting of
1836 C<$@>.  Beware that using C<eval> neither silences Perl from printing
1837 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1838 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1839 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1840 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1841
1842 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1843 determining whether a particular feature (such as C<socket> or C<symlink>)
1844 is implemented.  It is also Perl's exception-trapping mechanism, where
1845 the die operator is used to raise exceptions.
1846
1847 If you want to trap errors when loading an XS module, some problems with
1848 the binary interface (such as Perl version skew) may be fatal even with
1849 C<eval> unless C<$ENV{PERL_DL_NONLAZY}> is set.  See L<perlrun>.
1850
1851 If the code to be executed doesn't vary, you may use the eval-BLOCK
1852 form to trap run-time errors without incurring the penalty of
1853 recompiling each time.  The error, if any, is still returned in C<$@>.
1854 Examples:
1855
1856     # make divide-by-zero nonfatal
1857     eval { $answer = $a / $b; }; warn $@ if $@;
1858
1859     # same thing, but less efficient
1860     eval '$answer = $a / $b'; warn $@ if $@;
1861
1862     # a compile-time error
1863     eval { $answer = }; # WRONG
1864
1865     # a run-time error
1866     eval '$answer =';   # sets $@
1867
1868 Using the C<eval{}> form as an exception trap in libraries does have some
1869 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
1870 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
1871 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1872 as this example shows:
1873
1874     # a private exception trap for divide-by-zero
1875     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1876     warn $@ if $@;
1877
1878 This is especially significant, given that C<__DIE__> hooks can call
1879 C<die> again, which has the effect of changing their error messages:
1880
1881     # __DIE__ hooks may modify error messages
1882     {
1883        local $SIG{'__DIE__'} =
1884               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1885        eval { die "foo lives here" };
1886        print $@ if $@;                # prints "bar lives here"
1887     }
1888
1889 Because this promotes action at a distance, this counterintuitive behavior
1890 may be fixed in a future release.
1891
1892 With an C<eval>, you should be especially careful to remember what's
1893 being looked at when:
1894
1895     eval $x;        # CASE 1
1896     eval "$x";      # CASE 2
1897
1898     eval '$x';      # CASE 3
1899     eval { $x };    # CASE 4
1900
1901     eval "\$$x++";  # CASE 5
1902     $$x++;          # CASE 6
1903
1904 Cases 1 and 2 above behave identically: they run the code contained in
1905 the variable $x.  (Although case 2 has misleading double quotes making
1906 the reader wonder what else might be happening (nothing is).)  Cases 3
1907 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1908 does nothing but return the value of $x.  (Case 4 is preferred for
1909 purely visual reasons, but it also has the advantage of compiling at
1910 compile-time instead of at run-time.)  Case 5 is a place where
1911 normally you I<would> like to use double quotes, except that in this
1912 particular situation, you can just use symbolic references instead, as
1913 in case 6.
1914
1915 Before Perl 5.14, the assignment to C<$@> occurred before restoration 
1916 of localized variables, which means that for your code to run on older
1917 versions, a temporary is required if you want to mask some but not all
1918 errors:
1919
1920     # alter $@ on nefarious repugnancy only
1921     {
1922        my $e;
1923        {
1924          local $@; # protect existing $@
1925          eval { test_repugnancy() };
1926          # $@ =~ /nefarious/ and die $@; # Perl 5.14 and higher only
1927          $@ =~ /nefarious/ and $e = $@;
1928        }
1929        die $e if defined $e
1930     }
1931
1932 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1933 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1934
1935 An C<eval ''> executed within a subroutine defined
1936 in the C<DB> package doesn't see the usual
1937 surrounding lexical scope, but rather the scope of the first non-DB piece
1938 of code that called it.  You don't normally need to worry about this unless
1939 you are writing a Perl debugger.
1940
1941 =item evalbytes EXPR
1942 X<evalbytes>
1943
1944 =item evalbytes
1945
1946 =for Pod::Functions +evalbytes similar to string eval, but intend to parse a bytestream
1947
1948 This function is like L</eval> with a string argument, except it always
1949 parses its argument, or C<$_> if EXPR is omitted, as a string of bytes.  A
1950 string containing characters whose ordinal value exceeds 255 results in an
1951 error.  Source filters activated within the evaluated code apply to the
1952 code itself.
1953
1954 This function is only available under the C<evalbytes> feature, a
1955 C<use v5.16> (or higher) declaration, or with a C<CORE::> prefix.  See
1956 L<feature> for more information.
1957
1958 =item exec LIST
1959 X<exec> X<execute>
1960
1961 =item exec PROGRAM LIST
1962
1963 =for Pod::Functions abandon this program to run another
1964
1965 The C<exec> function executes a system command I<and never returns>;
1966 use C<system> instead of C<exec> if you want it to return.  It fails and
1967 returns false only if the command does not exist I<and> it is executed
1968 directly instead of via your system's command shell (see below).
1969
1970 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1971 warns you if C<exec> is called in void context and if there is a following
1972 statement that isn't C<die>, C<warn>, or C<exit> (if C<-w> is set--but
1973 you always do that, right?).  If you I<really> want to follow an C<exec>
1974 with some other statement, you can use one of these styles to avoid the warning:
1975
1976     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1977     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1978
1979 If there is more than one argument in LIST, or if LIST is an array
1980 with more than one value, calls execvp(3) with the arguments in LIST.
1981 If there is only one scalar argument or an array with one element in it,
1982 the argument is checked for shell metacharacters, and if there are any,
1983 the entire argument is passed to the system's command shell for parsing
1984 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1985 If there are no shell metacharacters in the argument, it is split into
1986 words and passed directly to C<execvp>, which is more efficient.
1987 Examples:
1988
1989     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1990     exec "sort $outfile | uniq";
1991
1992 If you don't really want to execute the first argument, but want to lie
1993 to the program you are executing about its own name, you can specify
1994 the program you actually want to run as an "indirect object" (without a
1995 comma) in front of the LIST.  (This always forces interpretation of the
1996 LIST as a multivalued list, even if there is only a single scalar in
1997 the list.)  Example:
1998
1999     $shell = '/bin/csh';
2000     exec $shell '-sh';    # pretend it's a login shell
2001
2002 or, more directly,
2003
2004     exec {'/bin/csh'} '-sh';  # pretend it's a login shell
2005
2006 When the arguments get executed via the system shell, results are
2007 subject to its quirks and capabilities.  See L<perlop/"`STRING`">
2008 for details.
2009
2010 Using an indirect object with C<exec> or C<system> is also more
2011 secure.  This usage (which also works fine with system()) forces
2012 interpretation of the arguments as a multivalued list, even if the
2013 list had just one argument.  That way you're safe from the shell
2014 expanding wildcards or splitting up words with whitespace in them.
2015
2016     @args = ( "echo surprise" );
2017
2018     exec @args;               # subject to shell escapes
2019                                 # if @args == 1
2020     exec { $args[0] } @args;  # safe even with one-arg list
2021
2022 The first version, the one without the indirect object, ran the I<echo>
2023 program, passing it C<"surprise"> an argument.  The second version didn't;
2024 it tried to run a program named I<"echo surprise">, didn't find it, and set
2025 C<$?> to a non-zero value indicating failure.
2026
2027 Perl attempts to flush all files opened for output before the exec,
2028 but this may not be supported on some platforms (see L<perlport>).
2029 To be safe, you may need to set C<$|> ($AUTOFLUSH in English) or
2030 call the C<autoflush()> method of C<IO::Handle> on any open handles
2031 to avoid lost output.
2032
2033 Note that C<exec> will not call your C<END> blocks, nor will it invoke
2034 C<DESTROY> methods on your objects.
2035
2036 Portability issues: L<perlport/exec>.
2037
2038 =item exists EXPR
2039 X<exists> X<autovivification>
2040
2041 =for Pod::Functions test whether a hash key is present
2042
2043 Given an expression that specifies an element of a hash, returns true if the
2044 specified element in the hash has ever been initialized, even if the
2045 corresponding value is undefined.
2046
2047     print "Exists\n"    if exists $hash{$key};
2048     print "Defined\n"   if defined $hash{$key};
2049     print "True\n"      if $hash{$key};
2050
2051 exists may also be called on array elements, but its behavior is much less
2052 obvious and is strongly tied to the use of L</delete> on arrays.  B<Be aware>
2053 that calling exists on array values is deprecated and likely to be removed in
2054 a future version of Perl.
2055
2056     print "Exists\n"    if exists $array[$index];
2057     print "Defined\n"   if defined $array[$index];
2058     print "True\n"      if $array[$index];
2059
2060 A hash or array element can be true only if it's defined and defined only if
2061 it exists, but the reverse doesn't necessarily hold true.
2062
2063 Given an expression that specifies the name of a subroutine,
2064 returns true if the specified subroutine has ever been declared, even
2065 if it is undefined.  Mentioning a subroutine name for exists or defined
2066 does not count as declaring it.  Note that a subroutine that does not
2067 exist may still be callable: its package may have an C<AUTOLOAD>
2068 method that makes it spring into existence the first time that it is
2069 called; see L<perlsub>.
2070
2071     print "Exists\n"  if exists &subroutine;
2072     print "Defined\n" if defined &subroutine;
2073
2074 Note that the EXPR can be arbitrarily complicated as long as the final
2075 operation is a hash or array key lookup or subroutine name:
2076
2077     if (exists $ref->{A}->{B}->{$key})  { }
2078     if (exists $hash{A}{B}{$key})       { }
2079
2080     if (exists $ref->{A}->{B}->[$ix])   { }
2081     if (exists $hash{A}{B}[$ix])        { }
2082
2083     if (exists &{$ref->{A}{B}{$key}})   { }
2084
2085 Although the most deeply nested array or hash element will not spring into
2086 existence just because its existence was tested, any intervening ones will.
2087 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
2088 into existence due to the existence test for the $key element above.
2089 This happens anywhere the arrow operator is used, including even here:
2090
2091     undef $ref;
2092     if (exists $ref->{"Some key"})    { }
2093     print $ref;  # prints HASH(0x80d3d5c)
2094
2095 This surprising autovivification in what does not at first--or even
2096 second--glance appear to be an lvalue context may be fixed in a future
2097 release.
2098
2099 Use of a subroutine call, rather than a subroutine name, as an argument
2100 to exists() is an error.
2101
2102     exists &sub;    # OK
2103     exists &sub();  # Error
2104
2105 =item exit EXPR
2106 X<exit> X<terminate> X<abort>
2107
2108 =item exit
2109
2110 =for Pod::Functions terminate this program
2111
2112 Evaluates EXPR and exits immediately with that value.    Example:
2113
2114     $ans = <STDIN>;
2115     exit 0 if $ans =~ /^[Xx]/;
2116
2117 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
2118 universally recognized values for EXPR are C<0> for success and C<1>
2119 for error; other values are subject to interpretation depending on the
2120 environment in which the Perl program is running.  For example, exiting
2121 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
2122 the mailer to return the item undelivered, but that's not true everywhere.
2123
2124 Don't use C<exit> to abort a subroutine if there's any chance that
2125 someone might want to trap whatever error happened.  Use C<die> instead,
2126 which can be trapped by an C<eval>.
2127
2128 The exit() function does not always exit immediately.  It calls any
2129 defined C<END> routines first, but these C<END> routines may not
2130 themselves abort the exit.  Likewise any object destructors that need to
2131 be called are called before the real exit.  C<END> routines and destructors
2132 can change the exit status by modifying C<$?>.  If this is a problem, you
2133 can call C<POSIX::_exit($status)> to avoid END and destructor processing.
2134 See L<perlmod> for details.
2135
2136 Portability issues: L<perlport/exit>.
2137
2138 =item exp EXPR
2139 X<exp> X<exponential> X<antilog> X<antilogarithm> X<e>
2140
2141 =item exp
2142
2143 =for Pod::Functions raise I<e> to a power
2144
2145 Returns I<e> (the natural logarithm base) to the power of EXPR.
2146 If EXPR is omitted, gives C<exp($_)>.
2147
2148 =item fc EXPR
2149 X<fc> X<foldcase> X<casefold> X<fold-case> X<case-fold>
2150
2151 =item fc
2152
2153 =for Pod::Functions +fc return casefolded version of a string
2154
2155 Returns the casefolded version of EXPR.  This is the internal function
2156 implementing the C<\F> escape in double-quoted strings.
2157
2158 Casefolding is the process of mapping strings to a form where case
2159 differences are erased; comparing two strings in their casefolded
2160 form is effectively a way of asking if two strings are equal,
2161 regardless of case.
2162
2163 Roughly, if you ever found yourself writing this
2164
2165     lc($this) eq lc($that)    # Wrong!
2166         # or
2167     uc($this) eq uc($that)    # Also wrong!
2168         # or
2169     $this =~ /^\Q$that\E\z/i  # Right!
2170
2171 Now you can write
2172
2173     fc($this) eq fc($that)
2174
2175 And get the correct results.
2176
2177 Perl only implements the full form of casefolding,
2178 but you can access the simple folds using L<Unicode::UCD/casefold()> and
2179 L<Unicode::UCD/prop_invmap()>.
2180 For further information on casefolding, refer to
2181 the Unicode Standard, specifically sections 3.13 C<Default Case Operations>,
2182 4.2 C<Case-Normative>, and 5.18 C<Case Mappings>,
2183 available at L<http://www.unicode.org/versions/latest/>, as well as the
2184 Case Charts available at L<http://www.unicode.org/charts/case/>.
2185
2186 If EXPR is omitted, uses C<$_>.
2187
2188 This function behaves the same way under various pragma, such as within
2189 S<C<"use feature 'unicode_strings">>, as L</lc> does, with the single
2190 exception of C<fc> of LATIN CAPITAL LETTER SHARP S (U+1E9E) within the
2191 scope of S<C<use locale>>.  The foldcase of this character would
2192 normally be C<"ss">, but as explained in the L</lc> section, case
2193 changes that cross the 255/256 boundary are problematic under locales,
2194 and are hence prohibited.  Therefore, this function under locale returns
2195 instead the string C<"\x{17F}\x{17F}">, which is the LATIN SMALL LETTER
2196 LONG S.  Since that character itself folds to C<"s">, the string of two
2197 of them together should be equivalent to a single U+1E9E when foldcased.
2198
2199 While the Unicode Standard defines two additional forms of casefolding,
2200 one for Turkic languages and one that never maps one character into multiple
2201 characters, these are not provided by the Perl core; However, the CPAN module
2202 C<Unicode::Casing> may be used to provide an implementation.
2203
2204 This keyword is available only when the C<"fc"> feature is enabled,
2205 or when prefixed with C<CORE::>; See L<feature>.  Alternately,
2206 include a C<use v5.16> or later to the current scope.
2207
2208 =item fcntl FILEHANDLE,FUNCTION,SCALAR
2209 X<fcntl>
2210
2211 =for Pod::Functions file control system call
2212
2213 Implements the fcntl(2) function.  You'll probably have to say
2214
2215     use Fcntl;
2216
2217 first to get the correct constant definitions.  Argument processing and
2218 value returned work just like C<ioctl> below.
2219 For example:
2220
2221     use Fcntl;
2222     fcntl($filehandle, F_GETFL, $packed_return_buffer)
2223         or die "can't fcntl F_GETFL: $!";
2224
2225 You don't have to check for C<defined> on the return from C<fcntl>.
2226 Like C<ioctl>, it maps a C<0> return from the system call into
2227 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
2228 in numeric context.  It is also exempt from the normal B<-w> warnings
2229 on improper numeric conversions.
2230
2231 Note that C<fcntl> raises an exception if used on a machine that
2232 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
2233 manpage to learn what functions are available on your system.
2234
2235 Here's an example of setting a filehandle named C<REMOTE> to be
2236 non-blocking at the system level.  You'll have to negotiate C<$|>
2237 on your own, though.
2238
2239     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
2240
2241     $flags = fcntl(REMOTE, F_GETFL, 0)
2242                 or die "Can't get flags for the socket: $!\n";
2243
2244     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
2245                 or die "Can't set flags for the socket: $!\n";
2246
2247 Portability issues: L<perlport/fcntl>.
2248
2249 =item __FILE__
2250 X<__FILE__>
2251
2252 =for Pod::Functions the name of the current source file
2253
2254 A special token that returns the name of the file in which it occurs.
2255
2256 =item fileno FILEHANDLE
2257 X<fileno>
2258
2259 =for Pod::Functions return file descriptor from filehandle
2260
2261 Returns the file descriptor for a filehandle, or undefined if the
2262 filehandle is not open.  If there is no real file descriptor at the OS
2263 level, as can happen with filehandles connected to memory objects via
2264 C<open> with a reference for the third argument, -1 is returned.
2265
2266 This is mainly useful for constructing
2267 bitmaps for C<select> and low-level POSIX tty-handling operations.
2268 If FILEHANDLE is an expression, the value is taken as an indirect
2269 filehandle, generally its name.
2270
2271 You can use this to find out whether two handles refer to the
2272 same underlying descriptor:
2273
2274     if (fileno(THIS) != -1 && fileno(THIS) == fileno(THAT)) {
2275         print "THIS and THAT are dups\n";
2276     } elsif (fileno(THIS) != -1 && fileno(THAT) != -1) {
2277         print "THIS and THAT have different " .
2278             "underlying file descriptors\n";
2279     } else {
2280         print "At least one of THIS and THAT does " .
2281             "not have a real file descriptor\n";
2282     }
2283
2284 =item flock FILEHANDLE,OPERATION
2285 X<flock> X<lock> X<locking>
2286
2287 =for Pod::Functions lock an entire file with an advisory lock
2288
2289 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
2290 for success, false on failure.  Produces a fatal error if used on a
2291 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
2292 C<flock> is Perl's portable file-locking interface, although it locks
2293 entire files only, not records.
2294
2295 Two potentially non-obvious but traditional C<flock> semantics are
2296 that it waits indefinitely until the lock is granted, and that its locks
2297 are B<merely advisory>.  Such discretionary locks are more flexible, but
2298 offer fewer guarantees.  This means that programs that do not also use
2299 C<flock> may modify files locked with C<flock>.  See L<perlport>, 
2300 your port's specific documentation, and your system-specific local manpages
2301 for details.  It's best to assume traditional behavior if you're writing
2302 portable programs.  (But if you're not, you should as always feel perfectly
2303 free to write for your own system's idiosyncrasies (sometimes called
2304 "features").  Slavish adherence to portability concerns shouldn't get
2305 in the way of your getting your job done.)
2306
2307 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
2308 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
2309 you can use the symbolic names if you import them from the L<Fcntl> module,
2310 either individually, or as a group using the C<:flock> tag.  LOCK_SH
2311 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
2312 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
2313 LOCK_SH or LOCK_EX, then C<flock> returns immediately rather than blocking
2314 waiting for the lock; check the return status to see if you got it.
2315
2316 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
2317 before locking or unlocking it.
2318
2319 Note that the emulation built with lockf(3) doesn't provide shared
2320 locks, and it requires that FILEHANDLE be open with write intent.  These
2321 are the semantics that lockf(3) implements.  Most if not all systems
2322 implement lockf(3) in terms of fcntl(2) locking, though, so the
2323 differing semantics shouldn't bite too many people.
2324
2325 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
2326 be open with read intent to use LOCK_SH and requires that it be open
2327 with write intent to use LOCK_EX.
2328
2329 Note also that some versions of C<flock> cannot lock things over the
2330 network; you would need to use the more system-specific C<fcntl> for
2331 that.  If you like you can force Perl to ignore your system's flock(2)
2332 function, and so provide its own fcntl(2)-based emulation, by passing
2333 the switch C<-Ud_flock> to the F<Configure> program when you configure
2334 and build a new Perl.
2335
2336 Here's a mailbox appender for BSD systems.
2337
2338     # import LOCK_* and SEEK_END constants
2339     use Fcntl qw(:flock SEEK_END);
2340
2341     sub lock {
2342         my ($fh) = @_;
2343         flock($fh, LOCK_EX) or die "Cannot lock mailbox - $!\n";
2344
2345         # and, in case someone appended while we were waiting...
2346         seek($fh, 0, SEEK_END) or die "Cannot seek - $!\n";
2347     }
2348
2349     sub unlock {
2350         my ($fh) = @_;
2351         flock($fh, LOCK_UN) or die "Cannot unlock mailbox - $!\n";
2352     }
2353
2354     open(my $mbox, ">>", "/usr/spool/mail/$ENV{'USER'}")
2355         or die "Can't open mailbox: $!";
2356
2357     lock($mbox);
2358     print $mbox $msg,"\n\n";
2359     unlock($mbox);
2360
2361 On systems that support a real flock(2), locks are inherited across fork()
2362 calls, whereas those that must resort to the more capricious fcntl(2)
2363 function lose their locks, making it seriously harder to write servers.
2364
2365 See also L<DB_File> for other flock() examples.
2366
2367 Portability issues: L<perlport/flock>.
2368
2369 =item fork
2370 X<fork> X<child> X<parent>
2371
2372 =for Pod::Functions create a new process just like this one
2373
2374 Does a fork(2) system call to create a new process running the
2375 same program at the same point.  It returns the child pid to the
2376 parent process, C<0> to the child process, or C<undef> if the fork is
2377 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
2378 are shared, while everything else is copied.  On most systems supporting
2379 fork(), great care has gone into making it extremely efficient (for
2380 example, using copy-on-write technology on data pages), making it the
2381 dominant paradigm for multitasking over the last few decades.
2382
2383 Perl attempts to flush all files opened for
2384 output before forking the child process, but this may not be supported
2385 on some platforms (see L<perlport>).  To be safe, you may need to set
2386 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
2387 C<IO::Handle> on any open handles to avoid duplicate output.
2388
2389 If you C<fork> without ever waiting on your children, you will
2390 accumulate zombies.  On some systems, you can avoid this by setting
2391 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
2392 forking and reaping moribund children.
2393
2394 Note that if your forked child inherits system file descriptors like
2395 STDIN and STDOUT that are actually connected by a pipe or socket, even
2396 if you exit, then the remote server (such as, say, a CGI script or a
2397 backgrounded job launched from a remote shell) won't think you're done.
2398 You should reopen those to F</dev/null> if it's any issue.
2399
2400 On some platforms such as Windows, where the fork() system call is not available,
2401 Perl can be built to emulate fork() in the Perl interpreter.
2402 The emulation is designed, at the level of the Perl program,
2403 to be as compatible as possible with the "Unix" fork().
2404 However it has limitations that have to be considered in code intended to be portable.
2405 See L<perlfork> for more details.
2406
2407 Portability issues: L<perlport/fork>.
2408
2409 =item format
2410 X<format>
2411
2412 =for Pod::Functions declare a picture format with use by the write() function
2413
2414 Declare a picture format for use by the C<write> function.  For
2415 example:
2416
2417     format Something =
2418         Test: @<<<<<<<< @||||| @>>>>>
2419               $str,     $%,    '$' . int($num)
2420     .
2421
2422     $str = "widget";
2423     $num = $cost/$quantity;
2424     $~ = 'Something';
2425     write;
2426
2427 See L<perlform> for many details and examples.
2428
2429 =item formline PICTURE,LIST
2430 X<formline>
2431
2432 =for Pod::Functions internal function used for formats
2433
2434 This is an internal function used by C<format>s, though you may call it,
2435 too.  It formats (see L<perlform>) a list of values according to the
2436 contents of PICTURE, placing the output into the format output
2437 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
2438 Eventually, when a C<write> is done, the contents of
2439 C<$^A> are written to some filehandle.  You could also read C<$^A>
2440 and then set C<$^A> back to C<"">.  Note that a format typically
2441 does one C<formline> per line of form, but the C<formline> function itself
2442 doesn't care how many newlines are embedded in the PICTURE.  This means
2443 that the C<~> and C<~~> tokens treat the entire PICTURE as a single line.
2444 You may therefore need to use multiple formlines to implement a single
2445 record format, just like the C<format> compiler.
2446
2447 Be careful if you put double quotes around the picture, because an C<@>
2448 character may be taken to mean the beginning of an array name.
2449 C<formline> always returns true.  See L<perlform> for other examples.
2450
2451 If you are trying to use this instead of C<write> to capture the output,
2452 you may find it easier to open a filehandle to a scalar
2453 (C<< open $fh, ">", \$output >>) and write to that instead.
2454
2455 =item getc FILEHANDLE
2456 X<getc> X<getchar> X<character> X<file, read>
2457
2458 =item getc
2459
2460 =for Pod::Functions get the next character from the filehandle
2461
2462 Returns the next character from the input file attached to FILEHANDLE,
2463 or the undefined value at end of file or if there was an error (in
2464 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
2465 STDIN.  This is not particularly efficient.  However, it cannot be
2466 used by itself to fetch single characters without waiting for the user
2467 to hit enter.  For that, try something more like:
2468
2469     if ($BSD_STYLE) {
2470         system "stty cbreak </dev/tty >/dev/tty 2>&1";
2471     }
2472     else {
2473         system "stty", '-icanon', 'eol', "\001";
2474     }
2475
2476     $key = getc(STDIN);
2477
2478     if ($BSD_STYLE) {
2479         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
2480     }
2481     else {
2482         system 'stty', 'icanon', 'eol', '^@'; # ASCII NUL
2483     }
2484     print "\n";
2485
2486 Determination of whether $BSD_STYLE should be set
2487 is left as an exercise to the reader.
2488
2489 The C<POSIX::getattr> function can do this more portably on
2490 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
2491 module from your nearest L<CPAN|http://www.cpan.org> site.
2492
2493 =item getlogin
2494 X<getlogin> X<login>
2495
2496 =for Pod::Functions return who logged in at this tty
2497
2498 This implements the C library function of the same name, which on most
2499 systems returns the current login from F</etc/utmp>, if any.  If it
2500 returns the empty string, use C<getpwuid>.
2501
2502     $login = getlogin || getpwuid($<) || "Kilroy";
2503
2504 Do not consider C<getlogin> for authentication: it is not as
2505 secure as C<getpwuid>.
2506
2507 Portability issues: L<perlport/getlogin>.
2508
2509 =item getpeername SOCKET
2510 X<getpeername> X<peer>
2511
2512 =for Pod::Functions find the other end of a socket connection
2513
2514 Returns the packed sockaddr address of the other end of the SOCKET
2515 connection.
2516
2517     use Socket;
2518     $hersockaddr    = getpeername(SOCK);
2519     ($port, $iaddr) = sockaddr_in($hersockaddr);
2520     $herhostname    = gethostbyaddr($iaddr, AF_INET);
2521     $herstraddr     = inet_ntoa($iaddr);
2522
2523 =item getpgrp PID
2524 X<getpgrp> X<group>
2525
2526 =for Pod::Functions get process group
2527
2528 Returns the current process group for the specified PID.  Use
2529 a PID of C<0> to get the current process group for the
2530 current process.  Will raise an exception if used on a machine that
2531 doesn't implement getpgrp(2).  If PID is omitted, returns the process
2532 group of the current process.  Note that the POSIX version of C<getpgrp>
2533 does not accept a PID argument, so only C<PID==0> is truly portable.
2534
2535 Portability issues: L<perlport/getpgrp>.
2536
2537 =item getppid
2538 X<getppid> X<parent> X<pid>
2539
2540 =for Pod::Functions get parent process ID
2541
2542 Returns the process id of the parent process.
2543
2544 Note for Linux users: Between v5.8.1 and v5.16.0 Perl would work
2545 around non-POSIX thread semantics the minority of Linux systems (and
2546 Debian GNU/kFreeBSD systems) that used LinuxThreads, this emulation
2547 has since been removed.  See the documentation for L<$$|perlvar/$$> for
2548 details.
2549
2550 Portability issues: L<perlport/getppid>.
2551
2552 =item getpriority WHICH,WHO
2553 X<getpriority> X<priority> X<nice>
2554
2555 =for Pod::Functions get current nice value
2556
2557 Returns the current priority for a process, a process group, or a user.
2558 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
2559 machine that doesn't implement getpriority(2).
2560
2561 Portability issues: L<perlport/getpriority>.
2562
2563 =item getpwnam NAME
2564 X<getpwnam> X<getgrnam> X<gethostbyname> X<getnetbyname> X<getprotobyname>
2565 X<getpwuid> X<getgrgid> X<getservbyname> X<gethostbyaddr> X<getnetbyaddr>
2566 X<getprotobynumber> X<getservbyport> X<getpwent> X<getgrent> X<gethostent>
2567 X<getnetent> X<getprotoent> X<getservent> X<setpwent> X<setgrent> X<sethostent>
2568 X<setnetent> X<setprotoent> X<setservent> X<endpwent> X<endgrent> X<endhostent>
2569 X<endnetent> X<endprotoent> X<endservent> 
2570
2571 =for Pod::Functions get passwd record given user login name
2572
2573 =item getgrnam NAME
2574
2575 =for Pod::Functions get group record given group name
2576
2577 =item gethostbyname NAME
2578
2579 =for Pod::Functions get host record given name
2580
2581 =item getnetbyname NAME
2582
2583 =for Pod::Functions get networks record given name
2584
2585 =item getprotobyname NAME
2586
2587 =for Pod::Functions get protocol record given name
2588
2589 =item getpwuid UID
2590
2591 =for Pod::Functions get passwd record given user ID
2592
2593 =item getgrgid GID
2594
2595 =for Pod::Functions get group record given group user ID
2596
2597 =item getservbyname NAME,PROTO
2598
2599 =for Pod::Functions get services record given its name
2600
2601 =item gethostbyaddr ADDR,ADDRTYPE
2602
2603 =for Pod::Functions get host record given its address
2604
2605 =item getnetbyaddr ADDR,ADDRTYPE
2606
2607 =for Pod::Functions get network record given its address
2608
2609 =item getprotobynumber NUMBER
2610
2611 =for Pod::Functions get protocol record numeric protocol
2612
2613 =item getservbyport PORT,PROTO
2614
2615 =for Pod::Functions get services record given numeric port
2616
2617 =item getpwent
2618
2619 =for Pod::Functions get next passwd record
2620
2621 =item getgrent
2622
2623 =for Pod::Functions get next group record
2624
2625 =item gethostent
2626
2627 =for Pod::Functions get next hosts record
2628
2629 =item getnetent
2630
2631 =for Pod::Functions get next networks record
2632
2633 =item getprotoent
2634
2635 =for Pod::Functions get next protocols record
2636
2637 =item getservent
2638
2639 =for Pod::Functions get next services record
2640
2641 =item setpwent
2642
2643 =for Pod::Functions prepare passwd file for use
2644
2645 =item setgrent
2646
2647 =for Pod::Functions prepare group file for use
2648
2649 =item sethostent STAYOPEN
2650
2651 =for Pod::Functions prepare hosts file for use
2652
2653 =item setnetent STAYOPEN
2654
2655 =for Pod::Functions prepare networks file for use
2656
2657 =item setprotoent STAYOPEN
2658
2659 =for Pod::Functions prepare protocols file for use
2660
2661 =item setservent STAYOPEN
2662
2663 =for Pod::Functions prepare services file for use
2664
2665 =item endpwent
2666
2667 =for Pod::Functions be done using passwd file
2668
2669 =item endgrent
2670
2671 =for Pod::Functions be done using group file
2672
2673 =item endhostent
2674
2675 =for Pod::Functions be done using hosts file
2676
2677 =item endnetent
2678
2679 =for Pod::Functions be done using networks file
2680
2681 =item endprotoent
2682
2683 =for Pod::Functions be done using protocols file
2684
2685 =item endservent
2686
2687 =for Pod::Functions be done using services file
2688
2689 These routines are the same as their counterparts in the
2690 system C library.  In list context, the return values from the
2691 various get routines are as follows:
2692
2693     ($name,$passwd,$uid,$gid,
2694        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
2695     ($name,$passwd,$gid,$members) = getgr*
2696     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2697     ($name,$aliases,$addrtype,$net) = getnet*
2698     ($name,$aliases,$proto) = getproto*
2699     ($name,$aliases,$port,$proto) = getserv*
2700
2701 (If the entry doesn't exist you get an empty list.)
2702
2703 The exact meaning of the $gcos field varies but it usually contains
2704 the real name of the user (as opposed to the login name) and other
2705 information pertaining to the user.  Beware, however, that in many
2706 system users are able to change this information and therefore it
2707 cannot be trusted and therefore the $gcos is tainted (see
2708 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2709 login shell, are also tainted, for the same reason.
2710
2711 In scalar context, you get the name, unless the function was a
2712 lookup by name, in which case you get the other thing, whatever it is.
2713 (If the entry doesn't exist you get the undefined value.)  For example:
2714
2715     $uid   = getpwnam($name);
2716     $name  = getpwuid($num);
2717     $name  = getpwent();
2718     $gid   = getgrnam($name);
2719     $name  = getgrgid($num);
2720     $name  = getgrent();
2721     #etc.
2722
2723 In I<getpw*()> the fields $quota, $comment, and $expire are special
2724 in that they are unsupported on many systems.  If the
2725 $quota is unsupported, it is an empty scalar.  If it is supported, it
2726 usually encodes the disk quota.  If the $comment field is unsupported,
2727 it is an empty scalar.  If it is supported it usually encodes some
2728 administrative comment about the user.  In some systems the $quota
2729 field may be $change or $age, fields that have to do with password
2730 aging.  In some systems the $comment field may be $class.  The $expire
2731 field, if present, encodes the expiration period of the account or the
2732 password.  For the availability and the exact meaning of these fields
2733 in your system, please consult getpwnam(3) and your system's 
2734 F<pwd.h> file.  You can also find out from within Perl what your
2735 $quota and $comment fields mean and whether you have the $expire field
2736 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2737 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2738 files are supported only if your vendor has implemented them in the
2739 intuitive fashion that calling the regular C library routines gets the
2740 shadow versions if you're running under privilege or if there exists
2741 the shadow(3) functions as found in System V (this includes Solaris
2742 and Linux).  Those systems that implement a proprietary shadow password
2743 facility are unlikely to be supported.
2744
2745 The $members value returned by I<getgr*()> is a space-separated list of
2746 the login names of the members of the group.
2747
2748 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2749 C, it will be returned to you via C<$?> if the function call fails.  The
2750 C<@addrs> value returned by a successful call is a list of raw
2751 addresses returned by the corresponding library call.  In the
2752 Internet domain, each address is four bytes long; you can unpack it
2753 by saying something like:
2754
2755     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2756
2757 The Socket library makes this slightly easier:
2758
2759     use Socket;
2760     $iaddr = inet_aton("127.1"); # or whatever address
2761     $name  = gethostbyaddr($iaddr, AF_INET);
2762
2763     # or going the other way
2764     $straddr = inet_ntoa($iaddr);
2765
2766 In the opposite way, to resolve a hostname to the IP address
2767 you can write this:
2768
2769     use Socket;
2770     $packed_ip = gethostbyname("www.perl.org");
2771     if (defined $packed_ip) {
2772         $ip_address = inet_ntoa($packed_ip);
2773     }
2774
2775 Make sure C<gethostbyname()> is called in SCALAR context and that
2776 its return value is checked for definedness.
2777
2778 The C<getprotobynumber> function, even though it only takes one argument,
2779 has the precedence of a list operator, so beware:
2780
2781     getprotobynumber $number eq 'icmp'   # WRONG
2782     getprotobynumber($number eq 'icmp')  # actually means this
2783     getprotobynumber($number) eq 'icmp'  # better this way
2784
2785 If you get tired of remembering which element of the return list
2786 contains which return value, by-name interfaces are provided
2787 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2788 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2789 and C<User::grent>.  These override the normal built-ins, supplying
2790 versions that return objects with the appropriate names
2791 for each field.  For example:
2792
2793    use File::stat;
2794    use User::pwent;
2795    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2796
2797 Even though it looks as though they're the same method calls (uid),
2798 they aren't, because a C<File::stat> object is different from
2799 a C<User::pwent> object.
2800
2801 Portability issues: L<perlport/getpwnam> to L<perlport/endservent>.
2802
2803 =item getsockname SOCKET
2804 X<getsockname>
2805
2806 =for Pod::Functions retrieve the sockaddr for a given socket
2807
2808 Returns the packed sockaddr address of this end of the SOCKET connection,
2809 in case you don't know the address because you have several different
2810 IPs that the connection might have come in on.
2811
2812     use Socket;
2813     $mysockaddr = getsockname(SOCK);
2814     ($port, $myaddr) = sockaddr_in($mysockaddr);
2815     printf "Connect to %s [%s]\n",
2816        scalar gethostbyaddr($myaddr, AF_INET),
2817        inet_ntoa($myaddr);
2818
2819 =item getsockopt SOCKET,LEVEL,OPTNAME
2820 X<getsockopt>
2821
2822 =for Pod::Functions get socket options on a given socket
2823
2824 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2825 Options may exist at multiple protocol levels depending on the socket
2826 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2827 C<Socket> module) will exist.  To query options at another level the
2828 protocol number of the appropriate protocol controlling the option
2829 should be supplied.  For example, to indicate that an option is to be
2830 interpreted by the TCP protocol, LEVEL should be set to the protocol
2831 number of TCP, which you can get using C<getprotobyname>.
2832
2833 The function returns a packed string representing the requested socket
2834 option, or C<undef> on error, with the reason for the error placed in
2835 C<$!>.  Just what is in the packed string depends on LEVEL and OPTNAME;
2836 consult getsockopt(2) for details.  A common case is that the option is an
2837 integer, in which case the result is a packed integer, which you can decode
2838 using C<unpack> with the C<i> (or C<I>) format.
2839
2840 Here's an example to test whether Nagle's algorithm is enabled on a socket:
2841
2842     use Socket qw(:all);
2843
2844     defined(my $tcp = getprotobyname("tcp"))
2845         or die "Could not determine the protocol number for tcp";
2846     # my $tcp = IPPROTO_TCP; # Alternative
2847     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2848         or die "getsockopt TCP_NODELAY: $!";
2849     my $nodelay = unpack("I", $packed);
2850     print "Nagle's algorithm is turned ",
2851            $nodelay ? "off\n" : "on\n";
2852
2853 Portability issues: L<perlport/getsockopt>.
2854
2855 =item glob EXPR
2856 X<glob> X<wildcard> X<filename, expansion> X<expand>
2857
2858 =item glob
2859
2860 =for Pod::Functions expand filenames using wildcards
2861
2862 In list context, returns a (possibly empty) list of filename expansions on
2863 the value of EXPR such as the standard Unix shell F</bin/csh> would do.  In
2864 scalar context, glob iterates through such filename expansions, returning
2865 undef when the list is exhausted.  This is the internal function
2866 implementing the C<< <*.c> >> operator, but you can use it directly.  If
2867 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2868 more detail in L<perlop/"I/O Operators">.
2869
2870 Note that C<glob> splits its arguments on whitespace and treats
2871 each segment as separate pattern.  As such, C<glob("*.c *.h")> 
2872 matches all files with a F<.c> or F<.h> extension.  The expression
2873 C<glob(".* *")> matches all files in the current working directory.
2874 If you want to glob filenames that might contain whitespace, you'll
2875 have to use extra quotes around the spacey filename to protect it.
2876 For example, to glob filenames that have an C<e> followed by a space
2877 followed by an C<f>, use either of:
2878
2879     @spacies = <"*e f*">;
2880     @spacies = glob '"*e f*"';
2881     @spacies = glob q("*e f*");
2882
2883 If you had to get a variable through, you could do this:
2884
2885     @spacies = glob "'*${var}e f*'";
2886     @spacies = glob qq("*${var}e f*");
2887
2888 If non-empty braces are the only wildcard characters used in the
2889 C<glob>, no filenames are matched, but potentially many strings
2890 are returned.  For example, this produces nine strings, one for
2891 each pairing of fruits and colors:
2892
2893     @many =  glob "{apple,tomato,cherry}={green,yellow,red}";
2894
2895 This operator is implemented using the standard
2896 C<File::Glob> extension.  See L<File::Glob> for details, including
2897 C<bsd_glob> which does not treat whitespace as a pattern separator.
2898
2899 Portability issues: L<perlport/glob>.
2900
2901 =item gmtime EXPR
2902 X<gmtime> X<UTC> X<Greenwich>
2903
2904 =item gmtime
2905
2906 =for Pod::Functions convert UNIX time into record or string using Greenwich time
2907
2908 Works just like L</localtime> but the returned values are
2909 localized for the standard Greenwich time zone.
2910
2911 Note: When called in list context, $isdst, the last value
2912 returned by gmtime, is always C<0>.  There is no
2913 Daylight Saving Time in GMT.
2914
2915 Portability issues: L<perlport/gmtime>.
2916
2917 =item goto LABEL
2918 X<goto> X<jump> X<jmp>
2919
2920 =item goto EXPR
2921
2922 =item goto &NAME
2923
2924 =for Pod::Functions create spaghetti code
2925
2926 The C<goto LABEL> form finds the statement labeled with LABEL and
2927 resumes execution there.  It can't be used to get out of a block or
2928 subroutine given to C<sort>.  It can be used to go almost anywhere
2929 else within the dynamic scope, including out of subroutines, but it's
2930 usually better to use some other construct such as C<last> or C<die>.
2931 The author of Perl has never felt the need to use this form of C<goto>
2932 (in Perl, that is; C is another matter).  (The difference is that C
2933 does not offer named loops combined with loop control.  Perl does, and
2934 this replaces most structured uses of C<goto> in other languages.)
2935
2936 The C<goto EXPR> form expects to evaluate C<EXPR> to a code reference or
2937 a label name.  If it evaluates to a code reference, it will be handled
2938 like C<goto &NAME>, below.  This is especially useful for implementing
2939 tail recursion via C<goto __SUB__>.
2940
2941 If the expression evaluates to a label name, its scope will be resolved
2942 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2943 necessarily recommended if you're optimizing for maintainability:
2944
2945     goto ("FOO", "BAR", "GLARCH")[$i];
2946
2947 As shown in this example, C<goto EXPR> is exempt from the "looks like a
2948 function" rule.  A pair of parentheses following it does not (necessarily)
2949 delimit its argument.  C<goto("NE")."XT"> is equivalent to C<goto NEXT>.
2950 Also, unlike most named operators, this has the same precedence as
2951 assignment.
2952
2953 Use of C<goto LABEL> or C<goto EXPR> to jump into a construct is
2954 deprecated and will issue a warning.  Even then, it may not be used to
2955 go into any construct that requires initialization, such as a
2956 subroutine or a C<foreach> loop.  It also can't be used to go into a
2957 construct that is optimized away.
2958
2959 The C<goto &NAME> form is quite different from the other forms of
2960 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2961 doesn't have the stigma associated with other gotos.  Instead, it
2962 exits the current subroutine (losing any changes set by local()) and
2963 immediately calls in its place the named subroutine using the current
2964 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2965 load another subroutine and then pretend that the other subroutine had
2966 been called in the first place (except that any modifications to C<@_>
2967 in the current subroutine are propagated to the other subroutine.)
2968 After the C<goto>, not even C<caller> will be able to tell that this
2969 routine was called first.
2970
2971 NAME needn't be the name of a subroutine; it can be a scalar variable
2972 containing a code reference or a block that evaluates to a code
2973 reference.
2974
2975 =item grep BLOCK LIST
2976 X<grep>
2977
2978 =item grep EXPR,LIST
2979
2980 =for Pod::Functions locate elements in a list test true against a given criterion
2981
2982 This is similar in spirit to, but not the same as, grep(1) and its
2983 relatives.  In particular, it is not limited to using regular expressions.
2984
2985 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2986 C<$_> to each element) and returns the list value consisting of those
2987 elements for which the expression evaluated to true.  In scalar
2988 context, returns the number of times the expression was true.
2989
2990     @foo = grep(!/^#/, @bar);    # weed out comments
2991
2992 or equivalently,
2993
2994     @foo = grep {!/^#/} @bar;    # weed out comments
2995
2996 Note that C<$_> is an alias to the list value, so it can be used to
2997 modify the elements of the LIST.  While this is useful and supported,
2998 it can cause bizarre results if the elements of LIST are not variables.
2999 Similarly, grep returns aliases into the original list, much as a for
3000 loop's index variable aliases the list elements.  That is, modifying an
3001 element of a list returned by grep (for example, in a C<foreach>, C<map>
3002 or another C<grep>) actually modifies the element in the original list.
3003 This is usually something to be avoided when writing clear code.
3004
3005 If C<$_> is lexical in the scope where the C<grep> appears (because it has
3006 been declared with the deprecated C<my $_> construct)
3007 then, in addition to being locally aliased to
3008 the list elements, C<$_> keeps being lexical inside the block; i.e., it
3009 can't be seen from the outside, avoiding any potential side-effects.
3010
3011 See also L</map> for a list composed of the results of the BLOCK or EXPR.
3012
3013 =item hex EXPR
3014 X<hex> X<hexadecimal>
3015
3016 =item hex
3017
3018 =for Pod::Functions convert a string to a hexadecimal number
3019
3020 Interprets EXPR as a hex string and returns the corresponding value.
3021 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
3022 L</oct>.)  If EXPR is omitted, uses C<$_>.
3023
3024     print hex '0xAf'; # prints '175'
3025     print hex 'aF';   # same
3026
3027 Hex strings may only represent integers.  Strings that would cause
3028 integer overflow trigger a warning.  Leading whitespace is not stripped,
3029 unlike oct().  To present something as hex, look into L</printf>,
3030 L</sprintf>, and L</unpack>.
3031
3032 =item import LIST
3033 X<import>
3034
3035 =for Pod::Functions patch a module's namespace into your own
3036
3037 There is no builtin C<import> function.  It is just an ordinary
3038 method (subroutine) defined (or inherited) by modules that wish to export
3039 names to another module.  The C<use> function calls the C<import> method
3040 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
3041
3042 =item index STR,SUBSTR,POSITION
3043 X<index> X<indexOf> X<InStr>
3044
3045 =item index STR,SUBSTR
3046
3047 =for Pod::Functions find a substring within a string
3048
3049 The index function searches for one string within another, but without
3050 the wildcard-like behavior of a full regular-expression pattern match.
3051 It returns the position of the first occurrence of SUBSTR in STR at
3052 or after POSITION.  If POSITION is omitted, starts searching from the
3053 beginning of the string.  POSITION before the beginning of the string
3054 or after its end is treated as if it were the beginning or the end,
3055 respectively.  POSITION and the return value are based at zero.
3056 If the substring is not found, C<index> returns -1.
3057
3058 =item int EXPR
3059 X<int> X<integer> X<truncate> X<trunc> X<floor>
3060
3061 =item int
3062
3063 =for Pod::Functions get the integer portion of a number
3064
3065 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
3066 You should not use this function for rounding: one because it truncates
3067 towards C<0>, and two because machine representations of floating-point
3068 numbers can sometimes produce counterintuitive results.  For example,
3069 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
3070 because it's really more like -268.99999999999994315658 instead.  Usually,
3071 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
3072 functions will serve you better than will int().
3073
3074 =item ioctl FILEHANDLE,FUNCTION,SCALAR
3075 X<ioctl>
3076
3077 =for Pod::Functions system-dependent device control system call
3078
3079 Implements the ioctl(2) function.  You'll probably first have to say
3080
3081     require "sys/ioctl.ph";  # probably in
3082                              # $Config{archlib}/sys/ioctl.ph
3083
3084 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
3085 exist or doesn't have the correct definitions you'll have to roll your
3086 own, based on your C header files such as F<< <sys/ioctl.h> >>.
3087 (There is a Perl script called B<h2ph> that comes with the Perl kit that
3088 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
3089 written depending on the FUNCTION; a C pointer to the string value of SCALAR
3090 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
3091 has no string value but does have a numeric value, that value will be
3092 passed rather than a pointer to the string value.  To guarantee this to be
3093 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
3094 functions may be needed to manipulate the values of structures used by
3095 C<ioctl>.
3096
3097 The return value of C<ioctl> (and C<fcntl>) is as follows:
3098
3099     if OS returns:      then Perl returns:
3100         -1               undefined value
3101          0              string "0 but true"
3102     anything else           that number
3103
3104 Thus Perl returns true on success and false on failure, yet you can
3105 still easily determine the actual value returned by the operating
3106 system:
3107
3108     $retval = ioctl(...) || -1;
3109     printf "System returned %d\n", $retval;
3110
3111 The special string C<"0 but true"> is exempt from B<-w> complaints
3112 about improper numeric conversions.
3113
3114 Portability issues: L<perlport/ioctl>.
3115
3116 =item join EXPR,LIST
3117 X<join>
3118
3119 =for Pod::Functions join a list into a string using a separator
3120
3121 Joins the separate strings of LIST into a single string with fields
3122 separated by the value of EXPR, and returns that new string.  Example:
3123
3124     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
3125
3126 Beware that unlike C<split>, C<join> doesn't take a pattern as its
3127 first argument.  Compare L</split>.
3128
3129 =item keys HASH
3130 X<keys> X<key>
3131
3132 =item keys ARRAY
3133
3134 =item keys EXPR
3135
3136 =for Pod::Functions retrieve list of indices from a hash
3137
3138 Called in list context, returns a list consisting of all the keys of the
3139 named hash, or in Perl 5.12 or later only, the indices of an array.  Perl
3140 releases prior to 5.12 will produce a syntax error if you try to use an
3141 array argument.  In scalar context, returns the number of keys or indices.
3142
3143 Hash entries are returned in an apparently random order.  The actual random
3144 order is specific to a given hash; the exact same series of operations
3145 on two hashes may result in a different order for each hash.  Any insertion
3146 into the hash may change the order, as will any deletion, with the exception
3147 that the most recent key returned by C<each> or C<keys> may be deleted
3148 without changing the order.  So long as a given hash is unmodified you may
3149 rely on C<keys>, C<values> and C<each> to repeatedly return the same order
3150 as each other.  See L<perlsec/"Algorithmic Complexity Attacks"> for
3151 details on why hash order is randomized.  Aside from the guarantees
3152 provided here the exact details of Perl's hash algorithm and the hash
3153 traversal order are subject to change in any release of Perl.
3154
3155 As a side effect, calling keys() resets the internal iterator of the HASH or
3156 ARRAY (see L</each>).  In particular, calling keys() in void context resets
3157 the iterator with no other overhead.
3158
3159 Here is yet another way to print your environment:
3160
3161     @keys = keys %ENV;
3162     @values = values %ENV;
3163     while (@keys) {
3164         print pop(@keys), '=', pop(@values), "\n";
3165     }
3166
3167 or how about sorted by key:
3168
3169     foreach $key (sort(keys %ENV)) {
3170         print $key, '=', $ENV{$key}, "\n";
3171     }
3172
3173 The returned values are copies of the original keys in the hash, so
3174 modifying them will not affect the original hash.  Compare L</values>.
3175
3176 To sort a hash by value, you'll need to use a C<sort> function.
3177 Here's a descending numeric sort of a hash by its values:
3178
3179     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
3180         printf "%4d %s\n", $hash{$key}, $key;
3181     }
3182
3183 Used as an lvalue, C<keys> allows you to increase the number of hash buckets
3184 allocated for the given hash.  This can gain you a measure of efficiency if
3185 you know the hash is going to get big.  (This is similar to pre-extending
3186 an array by assigning a larger number to $#array.)  If you say
3187
3188     keys %hash = 200;
3189
3190 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
3191 in fact, since it rounds up to the next power of two.  These
3192 buckets will be retained even if you do C<%hash = ()>, use C<undef
3193 %hash> if you want to free the storage while C<%hash> is still in scope.
3194 You can't shrink the number of buckets allocated for the hash using
3195 C<keys> in this way (but you needn't worry about doing this by accident,
3196 as trying has no effect).  C<keys @array> in an lvalue context is a syntax
3197 error.
3198
3199 Starting with Perl 5.14, C<keys> can take a scalar EXPR, which must contain
3200 a reference to an unblessed hash or array.  The argument will be
3201 dereferenced automatically.  This aspect of C<keys> is considered highly
3202 experimental.  The exact behaviour may change in a future version of Perl.
3203
3204     for (keys $hashref) { ... }
3205     for (keys $obj->get_arrayref) { ... }
3206
3207 To avoid confusing would-be users of your code who are running earlier
3208 versions of Perl with mysterious syntax errors, put this sort of thing at
3209 the top of your file to signal that your code will work I<only> on Perls of
3210 a recent vintage:
3211
3212     use 5.012;  # so keys/values/each work on arrays
3213     use 5.014;  # so keys/values/each work on scalars (experimental)
3214
3215 See also C<each>, C<values>, and C<sort>.
3216
3217 =item kill SIGNAL, LIST
3218
3219 =item kill SIGNAL
3220 X<kill> X<signal>
3221
3222 =for Pod::Functions send a signal to a process or process group
3223
3224 Sends a signal to a list of processes.  Returns the number of
3225 processes successfully signaled (which is not necessarily the
3226 same as the number actually killed).
3227
3228     $cnt = kill 'HUP', $child1, $child2;
3229     kill 'KILL', @goners;
3230
3231 SIGNAL may be either a signal name (a string) or a signal number.  A signal
3232 name may start with a C<SIG> prefix, thus C<FOO> and C<SIGFOO> refer to the
3233 same signal.  The string form of SIGNAL is recommended for portability because
3234 the same signal may have different numbers in different operating systems.
3235
3236 A list of signal names supported by the current platform can be found in
3237 C<$Config{sig_name}>, which is provided by the C<Config> module.  See L<Config>
3238 for more details.
3239
3240 A negative signal name is the same as a negative signal number, killing process
3241 groups instead of processes.  For example, C<kill '-KILL', $pgrp> and
3242 C<kill -9, $pgrp> will send C<SIGKILL> to
3243 the entire process group specified.  That
3244 means you usually want to use positive not negative signals.
3245
3246 If SIGNAL is either the number 0 or the string C<ZERO> (or C<SIGZERO>),
3247 no signal is sent to
3248 the process, but C<kill> checks whether it's I<possible> to send a signal to it
3249 (that means, to be brief, that the process is owned by the same user, or we are
3250 the super-user).  This is useful to check that a child process is still
3251 alive (even if only as a zombie) and hasn't changed its UID.  See
3252 L<perlport> for notes on the portability of this construct.
3253
3254 The behavior of kill when a I<PROCESS> number is zero or negative depends on
3255 the operating system.  For example, on POSIX-conforming systems, zero will
3256 signal the current process group, -1 will signal all processes, and any
3257 other negative PROCESS number will act as a negative signal number and
3258 kill the entire process group specified.
3259
3260 If both the SIGNAL and the PROCESS are negative, the results are undefined.
3261 A warning may be produced in a future version.
3262
3263 See L<perlipc/"Signals"> for more details.
3264
3265 On some platforms such as Windows where the fork() system call is not available.
3266 Perl can be built to emulate fork() at the interpreter level.
3267 This emulation has limitations related to kill that have to be considered,
3268 for code running on Windows and in code intended to be portable.
3269
3270 See L<perlfork> for more details.
3271
3272 If there is no I<LIST> of processes, no signal is sent, and the return
3273 value is 0.  This form is sometimes used, however, because it causes
3274 tainting checks to be run.  But see
3275 L<perlsec/Laundering and Detecting Tainted Data>.
3276
3277 Portability issues: L<perlport/kill>.
3278
3279 =item last LABEL
3280 X<last> X<break>
3281
3282 =item last EXPR
3283
3284 =item last
3285
3286 =for Pod::Functions exit a block prematurely
3287
3288 The C<last> command is like the C<break> statement in C (as used in
3289 loops); it immediately exits the loop in question.  If the LABEL is
3290 omitted, the command refers to the innermost enclosing
3291 loop.  The C<last EXPR> form, available starting in Perl
3292 5.18.0, allows a label name to be computed at run time,
3293 and is otherwise identical to C<last LABEL>.  The
3294 C<continue> block, if any, is not executed:
3295
3296     LINE: while (<STDIN>) {
3297         last LINE if /^$/;  # exit when done with header
3298         #...
3299     }
3300
3301 C<last> cannot be used to exit a block that returns a value such as
3302 C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit
3303 a grep() or map() operation.
3304
3305 Note that a block by itself is semantically identical to a loop
3306 that executes once.  Thus C<last> can be used to effect an early
3307 exit out of such a block.
3308
3309 See also L</continue> for an illustration of how C<last>, C<next>, and
3310 C<redo> work.
3311
3312 Unlike most named operators, this has the same precedence as assignment.
3313 It is also exempt from the looks-like-a-function rule, so
3314 C<last ("foo")."bar"> will cause "bar" to be part of the argument to
3315 C<last>.
3316
3317 =item lc EXPR
3318 X<lc> X<lowercase>
3319
3320 =item lc
3321
3322 =for Pod::Functions return lower-case version of a string
3323
3324 Returns a lowercased version of EXPR.  This is the internal function
3325 implementing the C<\L> escape in double-quoted strings.
3326
3327 If EXPR is omitted, uses C<$_>.
3328
3329 What gets returned depends on several factors:
3330
3331 =over
3332
3333 =item If C<use bytes> is in effect:
3334
3335 The results follow ASCII semantics.  Only characters C<A-Z> change, to C<a-z>
3336 respectively.
3337
3338 =item Otherwise, if C<use locale> (but not C<use locale ':not_characters'>) is in effect:
3339
3340 Respects current LC_CTYPE locale for code points < 256; and uses Unicode
3341 semantics for the remaining code points (this last can only happen if
3342 the UTF8 flag is also set).  See L<perllocale>.
3343
3344 A deficiency in this is that case changes that cross the 255/256
3345 boundary are not well-defined.  For example, the lower case of LATIN CAPITAL
3346 LETTER SHARP S (U+1E9E) in Unicode semantics is U+00DF (on ASCII
3347 platforms).   But under C<use locale>, the lower case of U+1E9E is
3348 itself, because 0xDF may not be LATIN SMALL LETTER SHARP S in the
3349 current locale, and Perl has no way of knowing if that character even
3350 exists in the locale, much less what code point it is.  Perl returns
3351 the input character unchanged, for all instances (and there aren't
3352 many) where the 255/256 boundary would otherwise be crossed.
3353
3354 =item Otherwise, If EXPR has the UTF8 flag set:
3355
3356 Unicode semantics are used for the case change.
3357
3358 =item Otherwise, if C<use feature 'unicode_strings'> or C<use locale ':not_characters'> is in effect:
3359
3360 Unicode semantics are used for the case change.
3361
3362 =item Otherwise:
3363
3364 ASCII semantics are used for the case change.  The lowercase of any character
3365 outside the ASCII range is the character itself.
3366
3367 =back
3368
3369 =item lcfirst EXPR
3370 X<lcfirst> X<lowercase>
3371
3372 =item lcfirst
3373
3374 =for Pod::Functions return a string with just the next letter in lower case
3375
3376 Returns the value of EXPR with the first character lowercased.  This
3377 is the internal function implementing the C<\l> escape in
3378 double-quoted strings.
3379
3380 If EXPR is omitted, uses C<$_>.
3381
3382 This function behaves the same way under various pragmata, such as in a locale,
3383 as L</lc> does.
3384
3385 =item length EXPR
3386 X<length> X<size>
3387
3388 =item length
3389
3390 =for Pod::Functions return the number of characters in a string
3391
3392 Returns the length in I<characters> of the value of EXPR.  If EXPR is
3393 omitted, returns the length of C<$_>.  If EXPR is undefined, returns
3394 C<undef>.
3395
3396 This function cannot be used on an entire array or hash to find out how
3397 many elements these have.  For that, use C<scalar @array> and C<scalar keys
3398 %hash>, respectively.
3399
3400 Like all Perl character operations, length() normally deals in logical
3401 characters, not physical bytes.  For how many bytes a string encoded as
3402 UTF-8 would take up, use C<length(Encode::encode_utf8(EXPR))> (you'll have
3403 to C<use Encode> first).  See L<Encode> and L<perlunicode>.
3404
3405 =item __LINE__
3406 X<__LINE__>
3407
3408 =for Pod::Functions the current source line number
3409
3410 A special token that compiles to the current line number.
3411
3412 =item link OLDFILE,NEWFILE
3413 X<link>
3414
3415 =for Pod::Functions create a hard link in the filesystem
3416
3417 Creates a new filename linked to the old filename.  Returns true for
3418 success, false otherwise.
3419
3420 Portability issues: L<perlport/link>.
3421
3422 =item listen SOCKET,QUEUESIZE
3423 X<listen>
3424
3425 =for Pod::Functions register your socket as a server
3426
3427 Does the same thing that the listen(2) system call does.  Returns true if
3428 it succeeded, false otherwise.  See the example in
3429 L<perlipc/"Sockets: Client/Server Communication">.
3430
3431 =item local EXPR
3432 X<local>
3433
3434 =for Pod::Functions create a temporary value for a global variable (dynamic scoping)
3435
3436 You really probably want to be using C<my> instead, because C<local> isn't
3437 what most people think of as "local".  See
3438 L<perlsub/"Private Variables via my()"> for details.
3439
3440 A local modifies the listed variables to be local to the enclosing
3441 block, file, or eval.  If more than one value is listed, the list must
3442 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
3443 for details, including issues with tied arrays and hashes.
3444
3445 The C<delete local EXPR> construct can also be used to localize the deletion
3446 of array/hash elements to the current block.
3447 See L<perlsub/"Localized deletion of elements of composite types">.
3448
3449 =item localtime EXPR
3450 X<localtime> X<ctime>
3451
3452 =item localtime
3453
3454 =for Pod::Functions convert UNIX time into record or string using local time
3455
3456 Converts a time as returned by the time function to a 9-element list
3457 with the time analyzed for the local time zone.  Typically used as
3458 follows:
3459
3460     #  0    1    2     3     4    5     6     7     8
3461     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
3462                                                 localtime(time);
3463
3464 All list elements are numeric and come straight out of the C `struct
3465 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
3466 of the specified time.
3467
3468 C<$mday> is the day of the month and C<$mon> the month in
3469 the range C<0..11>, with 0 indicating January and 11 indicating December.
3470 This makes it easy to get a month name from a list:
3471
3472     my @abbr = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
3473     print "$abbr[$mon] $mday";
3474     # $mon=9, $mday=18 gives "Oct 18"
3475
3476 C<$year> contains the number of years since 1900.  To get a 4-digit
3477 year write:
3478
3479     $year += 1900;
3480
3481 To get the last two digits of the year (e.g., "01" in 2001) do:
3482
3483     $year = sprintf("%02d", $year % 100);
3484
3485 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
3486 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
3487 (or C<0..365> in leap years.)
3488
3489 C<$isdst> is true if the specified time occurs during Daylight Saving
3490 Time, false otherwise.
3491
3492 If EXPR is omitted, C<localtime()> uses the current time (as returned
3493 by time(3)).
3494
3495 In scalar context, C<localtime()> returns the ctime(3) value:
3496
3497     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
3498
3499 The format of this scalar value is B<not> locale-dependent
3500 but built into Perl.  For GMT instead of local
3501 time use the L</gmtime> builtin.  See also the
3502 C<Time::Local> module (for converting seconds, minutes, hours, and such back to
3503 the integer value returned by time()), and the L<POSIX> module's strftime(3)
3504 and mktime(3) functions.
3505
3506 To get somewhat similar but locale-dependent date strings, set up your
3507 locale environment variables appropriately (please see L<perllocale>) and
3508 try for example:
3509
3510     use POSIX qw(strftime);
3511     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
3512     # or for GMT formatted appropriately for your locale:
3513     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
3514
3515 Note that the C<%a> and C<%b>, the short forms of the day of the week
3516 and the month of the year, may not necessarily be three characters wide.
3517
3518 The L<Time::gmtime> and L<Time::localtime> modules provide a convenient,
3519 by-name access mechanism to the gmtime() and localtime() functions,
3520 respectively.
3521
3522 For a comprehensive date and time representation look at the
3523 L<DateTime> module on CPAN.
3524
3525 Portability issues: L<perlport/localtime>.
3526
3527 =item lock THING
3528 X<lock>
3529
3530 =for Pod::Functions +5.005 get a thread lock on a variable, subroutine, or method
3531
3532 This function places an advisory lock on a shared variable or referenced
3533 object contained in I<THING> until the lock goes out of scope.
3534
3535 The value returned is the scalar itself, if the argument is a scalar, or a
3536 reference, if the argument is a hash, array or subroutine.
3537
3538 lock() is a "weak keyword" : this means that if you've defined a function
3539 by this name (before any calls to it), that function will be called
3540 instead.  If you are not under C<use threads::shared> this does nothing.
3541 See L<threads::shared>.
3542
3543 =item log EXPR
3544 X<log> X<logarithm> X<e> X<ln> X<base>
3545
3546 =item log
3547
3548 =for Pod::Functions retrieve the natural logarithm for a number
3549
3550 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
3551 returns the log of C<$_>.  To get the
3552 log of another base, use basic algebra:
3553 The base-N log of a number is equal to the natural log of that number
3554 divided by the natural log of N.  For example:
3555
3556     sub log10 {
3557         my $n = shift;
3558         return log($n)/log(10);
3559     }
3560
3561 See also L</exp> for the inverse operation.
3562
3563 =item lstat FILEHANDLE
3564 X<lstat>
3565
3566 =item lstat EXPR
3567
3568 =item lstat DIRHANDLE
3569
3570 =item lstat
3571
3572 =for Pod::Functions stat a symbolic link
3573
3574 Does the same thing as the C<stat> function (including setting the
3575 special C<_> filehandle) but stats a symbolic link instead of the file
3576 the symbolic link points to.  If symbolic links are unimplemented on
3577 your system, a normal C<stat> is done.  For much more detailed
3578 information, please see the documentation for C<stat>.
3579
3580 If EXPR is omitted, stats C<$_>.
3581
3582 Portability issues: L<perlport/lstat>.
3583
3584 =item m//
3585
3586 =for Pod::Functions match a string with a regular expression pattern
3587
3588 The match operator.  See L<perlop/"Regexp Quote-Like Operators">.
3589
3590 =item map BLOCK LIST
3591 X<map>
3592
3593 =item map EXPR,LIST
3594
3595 =for Pod::Functions apply a change to a list to get back a new list with the changes
3596
3597 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
3598 C<$_> to each element) and returns the list value composed of the
3599 results of each such evaluation.  In scalar context, returns the
3600 total number of elements so generated.  Evaluates BLOCK or EXPR in
3601 list context, so each element of LIST may produce zero, one, or
3602 more elements in the returned value.
3603
3604     @chars = map(chr, @numbers);
3605
3606 translates a list of numbers to the corresponding characters.
3607
3608     my @squares = map { $_ * $_ } @numbers;
3609
3610 translates a list of numbers to their squared values.
3611
3612     my @squares = map { $_ > 5 ? ($_ * $_) : () } @numbers;
3613
3614 shows that number of returned elements can differ from the number of
3615 input elements.  To omit an element, return an empty list ().
3616 This could also be achieved by writing
3617
3618     my @squares = map { $_ * $_ } grep { $_ > 5 } @numbers;
3619
3620 which makes the intention more clear.
3621
3622 Map always returns a list, which can be
3623 assigned to a hash such that the elements
3624 become key/value pairs.  See L<perldata> for more details.
3625
3626     %hash = map { get_a_key_for($_) => $_ } @array;
3627
3628 is just a funny way to write
3629
3630     %hash = ();
3631     foreach (@array) {
3632         $hash{get_a_key_for($_)} = $_;
3633     }
3634
3635 Note that C<$_> is an alias to the list value, so it can be used to
3636 modify the elements of the LIST.  While this is useful and supported,
3637 it can cause bizarre results if the elements of LIST are not variables.
3638 Using a regular C<foreach> loop for this purpose would be clearer in
3639 most cases.  See also L</grep> for an array composed of those items of
3640 the original list for which the BLOCK or EXPR evaluates to true.
3641
3642 If C<$_> is lexical in the scope where the C<map> appears (because it has
3643 been declared with the deprecated C<my $_> construct),
3644 then, in addition to being locally aliased to
3645 the list elements, C<$_> keeps being lexical inside the block; that is, it
3646 can't be seen from the outside, avoiding any potential side-effects.
3647
3648 C<{> starts both hash references and blocks, so C<map { ...> could be either
3649 the start of map BLOCK LIST or map EXPR, LIST.  Because Perl doesn't look
3650 ahead for the closing C<}> it has to take a guess at which it's dealing with
3651 based on what it finds just after the
3652 C<{>.  Usually it gets it right, but if it
3653 doesn't it won't realize something is wrong until it gets to the C<}> and
3654 encounters the missing (or unexpected) comma.  The syntax error will be
3655 reported close to the C<}>, but you'll need to change something near the C<{>
3656 such as using a unary C<+> to give Perl some help:
3657
3658     %hash = map {  "\L$_" => 1  } @array # perl guesses EXPR. wrong
3659     %hash = map { +"\L$_" => 1  } @array # perl guesses BLOCK. right
3660     %hash = map { ("\L$_" => 1) } @array # this also works
3661     %hash = map {  lc($_) => 1  } @array # as does this.
3662     %hash = map +( lc($_) => 1 ), @array # this is EXPR and works!
3663
3664     %hash = map  ( lc($_), 1 ),   @array # evaluates to (1, @array)
3665
3666 or to force an anon hash constructor use C<+{>:
3667
3668     @hashes = map +{ lc($_) => 1 }, @array # EXPR, so needs
3669                                            # comma at end
3670
3671 to get a list of anonymous hashes each with only one entry apiece.
3672
3673 =item mkdir FILENAME,MASK
3674 X<mkdir> X<md> X<directory, create>
3675
3676 =item mkdir FILENAME
3677
3678 =item mkdir
3679
3680 =for Pod::Functions create a directory
3681
3682 Creates the directory specified by FILENAME, with permissions
3683 specified by MASK (as modified by C<umask>).  If it succeeds it
3684 returns true; otherwise it returns false and sets C<$!> (errno).
3685 MASK defaults to 0777 if omitted, and FILENAME defaults
3686 to C<$_> if omitted.
3687
3688 In general, it is better to create directories with a permissive MASK
3689 and let the user modify that with their C<umask> than it is to supply
3690 a restrictive MASK and give the user no way to be more permissive.
3691 The exceptions to this rule are when the file or directory should be
3692 kept private (mail files, for instance).  The perlfunc(1) entry on
3693 C<umask> discusses the choice of MASK in more detail.
3694
3695 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
3696 number of trailing slashes.  Some operating and filesystems do not get
3697 this right, so Perl automatically removes all trailing slashes to keep
3698 everyone happy.
3699
3700 To recursively create a directory structure, look at
3701 the C<mkpath> function of the L<File::Path> module.
3702
3703 =item msgctl ID,CMD,ARG
3704 X<msgctl>
3705
3706 =for Pod::Functions SysV IPC message control operations
3707
3708 Calls the System V IPC function msgctl(2).  You'll probably have to say
3709
3710     use IPC::SysV;
3711
3712 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
3713 then ARG must be a variable that will hold the returned C<msqid_ds>
3714 structure.  Returns like C<ioctl>: the undefined value for error,
3715 C<"0 but true"> for zero, or the actual return value otherwise.  See also
3716 L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and
3717 C<IPC::Semaphore>.
3718
3719 Portability issues: L<perlport/msgctl>.
3720
3721 =item msgget KEY,FLAGS
3722 X<msgget>
3723
3724 =for Pod::Functions get SysV IPC message queue
3725
3726 Calls the System V IPC function msgget(2).  Returns the message queue
3727 id, or C<undef> on error.  See also
3728 L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and
3729 C<IPC::Msg>.
3730
3731 Portability issues: L<perlport/msgget>.
3732
3733 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
3734 X<msgrcv>
3735
3736 =for Pod::Functions receive a SysV IPC message from a message queue
3737
3738 Calls the System V IPC function msgrcv to receive a message from
3739 message queue ID into variable VAR with a maximum message size of
3740 SIZE.  Note that when a message is received, the message type as a
3741 native long integer will be the first thing in VAR, followed by the
3742 actual message.  This packing may be opened with C<unpack("l! a*")>.
3743 Taints the variable.  Returns true if successful, false 
3744 on error.  See also L<perlipc/"SysV IPC"> and the documentation for
3745 C<IPC::SysV> and C<IPC::SysV::Msg>.
3746
3747 Portability issues: L<perlport/msgrcv>.
3748
3749 =item msgsnd ID,MSG,FLAGS
3750 X<msgsnd>
3751
3752 =for Pod::Functions send a SysV IPC message to a message queue
3753
3754 Calls the System V IPC function msgsnd to send the message MSG to the
3755 message queue ID.  MSG must begin with the native long integer message
3756 type, be followed by the length of the actual message, and then finally
3757 the message itself.  This kind of packing can be achieved with
3758 C<pack("l! a*", $type, $message)>.  Returns true if successful,
3759 false on error.  See also the C<IPC::SysV>
3760 and C<IPC::SysV::Msg> documentation.
3761
3762 Portability issues: L<perlport/msgsnd>.
3763
3764 =item my VARLIST
3765 X<my>
3766
3767 =item my TYPE VARLIST
3768
3769 =item my VARLIST : ATTRS
3770
3771 =item my TYPE VARLIST : ATTRS
3772
3773 =for Pod::Functions declare and assign a local variable (lexical scoping)
3774
3775 A C<my> declares the listed variables to be local (lexically) to the
3776 enclosing block, file, or C<eval>.  If more than one variable is listed,
3777 the list must be placed in parentheses.
3778
3779 The exact semantics and interface of TYPE and ATTRS are still
3780 evolving.  TYPE is currently bound to the use of the C<fields> pragma,
3781 and attributes are handled using the C<attributes> pragma, or starting
3782 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3783 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3784 L<attributes>, and L<Attribute::Handlers>.
3785
3786 Note that with a parenthesised list, C<undef> can be used as a dummy
3787 placeholder, for example to skip assignment of initial values:
3788
3789     my ( undef, $min, $hour ) = localtime;
3790
3791 =item next LABEL
3792 X<next> X<continue>
3793
3794 =item next EXPR
3795
3796 =item next
3797
3798 =for Pod::Functions iterate a block prematurely
3799
3800 The C<next> command is like the C<continue> statement in C; it starts
3801 the next iteration of the loop:
3802
3803     LINE: while (<STDIN>) {
3804         next LINE if /^#/;  # discard comments
3805         #...
3806     }
3807
3808 Note that if there were a C<continue> block on the above, it would get
3809 executed even on discarded lines.  If LABEL is omitted, the command
3810 refers to the innermost enclosing loop.  The C<next EXPR> form, available
3811 as of Perl 5.18.0, allows a label name to be computed at run time, being
3812 otherwise identical to C<next LABEL>.
3813
3814 C<next> cannot be used to exit a block which returns a value such as
3815 C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit
3816 a grep() or map() operation.
3817
3818 Note that a block by itself is semantically identical to a loop
3819 that executes once.  Thus C<next> will exit such a block early.
3820
3821 See also L</continue> for an illustration of how C<last>, C<next>, and
3822 C<redo> work.
3823
3824 Unlike most named operators, this has the same precedence as assignment.
3825 It is also exempt from the looks-like-a-function rule, so
3826 C<next ("foo")."bar"> will cause "bar" to be part of the argument to
3827 C<next>.
3828
3829 =item no MODULE VERSION LIST
3830 X<no declarations>
3831 X<unimporting>
3832
3833 =item no MODULE VERSION
3834
3835 =item no MODULE LIST
3836
3837 =item no MODULE
3838
3839 =item no VERSION
3840
3841 =for Pod::Functions unimport some module symbols or semantics at compile time
3842
3843 See the C<use> function, of which C<no> is the opposite.
3844
3845 =item oct EXPR
3846 X<oct> X<octal> X<hex> X<hexadecimal> X<binary> X<bin>
3847
3848 =item oct
3849
3850 =for Pod::Functions convert a string to an octal number
3851
3852 Interprets EXPR as an octal string and returns the corresponding
3853 value.  (If EXPR happens to start off with C<0x>, interprets it as a
3854 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
3855 binary string.  Leading whitespace is ignored in all three cases.)
3856 The following will handle decimal, binary, octal, and hex in standard
3857 Perl notation:
3858
3859     $val = oct($val) if $val =~ /^0/;
3860
3861 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
3862 in octal), use sprintf() or printf():
3863
3864     $dec_perms = (stat("filename"))[2] & 07777;
3865     $oct_perm_str = sprintf "%o", $perms;
3866
3867 The oct() function is commonly used when a string such as C<644> needs
3868 to be converted into a file mode, for example.  Although Perl 
3869 automatically converts strings into numbers as needed, this automatic
3870 conversion assumes base 10.
3871
3872 Leading white space is ignored without warning, as too are any trailing 
3873 non-digits, such as a decimal point (C<oct> only handles non-negative
3874 integers, not negative integers or floating point).
3875
3876 =item open FILEHANDLE,EXPR
3877 X<open> X<pipe> X<file, open> X<fopen>
3878
3879 =item open FILEHANDLE,MODE,EXPR
3880
3881 =item open FILEHANDLE,MODE,EXPR,LIST
3882
3883 =item open FILEHANDLE,MODE,REFERENCE
3884
3885 =item open FILEHANDLE
3886
3887 =for Pod::Functions open a file, pipe, or descriptor
3888
3889 Opens the file whose filename is given by EXPR, and associates it with
3890 FILEHANDLE.
3891
3892 Simple examples to open a file for reading:
3893
3894     open(my $fh, "<", "input.txt") 
3895         or die "cannot open < input.txt: $!";
3896
3897 and for writing:
3898
3899     open(my $fh, ">", "output.txt") 
3900         or die "cannot open > output.txt: $!";
3901
3902 (The following is a comprehensive reference to open(): for a gentler
3903 introduction you may consider L<perlopentut>.)
3904
3905 If FILEHANDLE is an undefined scalar variable (or array or hash element), a
3906 new filehandle is autovivified, meaning that the variable is assigned a
3907 reference to a newly allocated anonymous filehandle.  Otherwise if
3908 FILEHANDLE is an expression, its value is the real filehandle.  (This is
3909 considered a symbolic reference, so C<use strict "refs"> should I<not> be
3910 in effect.)
3911
3912 If EXPR is omitted, the global (package) scalar variable of the same
3913 name as the FILEHANDLE contains the filename.  (Note that lexical 
3914 variables--those declared with C<my> or C<state>--will not work for this
3915 purpose; so if you're using C<my> or C<state>, specify EXPR in your
3916 call to open.)
3917
3918 If three (or more) arguments are specified, the open mode (including
3919 optional encoding) in the second argument are distinct from the filename in
3920 the third.  If MODE is C<< < >> or nothing, the file is opened for input.
3921 If MODE is C<< > >>, the file is opened for output, with existing files
3922 first being truncated ("clobbered") and nonexisting files newly created.
3923 If MODE is C<<< >> >>>, the file is opened for appending, again being
3924 created if necessary.
3925
3926 You can put a C<+> in front of the C<< > >> or C<< < >> to
3927 indicate that you want both read and write access to the file; thus
3928 C<< +< >> is almost always preferred for read/write updates--the 
3929 C<< +> >> mode would clobber the file first.  You can't usually use
3930 either read-write mode for updating textfiles, since they have
3931 variable-length records.  See the B<-i> switch in L<perlrun> for a
3932 better approach.  The file is created with permissions of C<0666>
3933 modified by the process's C<umask> value.
3934
3935 These various prefixes correspond to the fopen(3) modes of C<r>,
3936 C<r+>, C<w>, C<w+>, C<a>, and C<a+>.
3937
3938 In the one- and two-argument forms of the call, the mode and filename
3939 should be concatenated (in that order), preferably separated by white
3940 space.  You can--but shouldn't--omit the mode in these forms when that mode
3941 is C<< < >>.  It is always safe to use the two-argument form of C<open> if
3942 the filename argument is a known literal.
3943
3944 For three or more arguments if MODE is C<|->, the filename is
3945 interpreted as a command to which output is to be piped, and if MODE
3946 is C<-|>, the filename is interpreted as a command that pipes
3947 output to us.  In the two-argument (and one-argument) form, one should
3948 replace dash (C<->) with the command.
3949 See L<perlipc/"Using open() for IPC"> for more examples of this.
3950 (You are not allowed to C<open> to a command that pipes both in I<and>
3951 out, but see L<IPC::Open2>, L<IPC::Open3>, and
3952 L<perlipc/"Bidirectional Communication with Another Process"> for
3953 alternatives.)
3954
3955 In the form of pipe opens taking three or more arguments, if LIST is specified
3956 (extra arguments after the command name) then LIST becomes arguments
3957 to the command invoked if the platform supports it.  The meaning of
3958 C<open> with more than three arguments for non-pipe modes is not yet
3959 defined, but experimental "layers" may give extra LIST arguments
3960 meaning.
3961
3962 In the two-argument (and one-argument) form, opening C<< <- >> 
3963 or C<-> opens STDIN and opening C<< >- >> opens STDOUT.
3964
3965 You may (and usually should) use the three-argument form of open to specify
3966 I/O layers (sometimes referred to as "disciplines") to apply to the handle
3967 that affect how the input and output are processed (see L<open> and
3968 L<PerlIO> for more details).  For example:
3969
3970   open(my $fh, "<:encoding(UTF-8)", "filename")
3971     || die "can't open UTF-8 encoded filename: $!";
3972
3973 opens the UTF8-encoded file containing Unicode characters;
3974 see L<perluniintro>.  Note that if layers are specified in the
3975 three-argument form, then default layers stored in ${^OPEN} (see L<perlvar>;
3976 usually set by the B<open> pragma or the switch B<-CioD>) are ignored.
3977 Those layers will also be ignored if you specifying a colon with no name
3978 following it.  In that case the default layer for the operating system
3979 (:raw on Unix, :crlf on Windows) is used.
3980
3981 Open returns nonzero on success, the undefined value otherwise.  If
3982 the C<open> involved a pipe, the return value happens to be the pid of
3983 the subprocess.
3984
3985 If you're running Perl on a system that distinguishes between text
3986 files and binary files, then you should check out L</binmode> for tips
3987 for dealing with this.  The key distinction between systems that need
3988 C<binmode> and those that don't is their text file formats.  Systems
3989 like Unix, Mac OS, and Plan 9, that end lines with a single
3990 character and encode that character in C as C<"\n"> do not
3991 need C<binmode>.  The rest need it.
3992
3993 When opening a file, it's seldom a good idea to continue 
3994 if the request failed, so C<open> is frequently used with
3995 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
3996 where you want to format a suitable error message (but there are
3997 modules that can help with that problem)) always check
3998 the return value from opening a file.  
3999
4000 As a special case the three-argument form with a read/write mode and the third
4001 argument being C<undef>:
4002
4003     open(my $tmp, "+>", undef) or die ...
4004
4005 opens a filehandle to an anonymous temporary file.  Also using C<< +< >>
4006 works for symmetry, but you really should consider writing something
4007 to the temporary file first.  You will need to seek() to do the
4008 reading.
4009
4010 Perl is built using PerlIO by default; Unless you've
4011 changed this (such as building Perl with C<Configure -Uuseperlio>), you can
4012 open filehandles directly to Perl scalars via:
4013
4014     open($fh, ">", \$variable) || ..
4015
4016 To (re)open C<STDOUT> or C<STDERR> as an in-memory file, close it first:
4017
4018     close STDOUT;
4019     open(STDOUT, ">", \$variable)
4020         or die "Can't open STDOUT: $!";
4021
4022 General examples:
4023
4024     $ARTICLE = 100;
4025     open(ARTICLE) or die "Can't find article $ARTICLE: $!\n";
4026     while (<ARTICLE>) {...
4027
4028     open(LOG, ">>/usr/spool/news/twitlog");  # (log is reserved)
4029     # if the open fails, output is discarded
4030
4031     open(my $dbase, "+<", "dbase.mine")      # open for update
4032         or die "Can't open 'dbase.mine' for update: $!";
4033
4034     open(my $dbase, "+<dbase.mine")          # ditto
4035         or die "Can't open 'dbase.mine' for update: $!";
4036
4037     open(ARTICLE, "-|", "caesar <$article")  # decrypt article
4038         or die "Can't start caesar: $!";
4039
4040     open(ARTICLE, "caesar <$article |")      # ditto
4041         or die "Can't start caesar: $!";
4042
4043     open(EXTRACT, "|sort >Tmp$$")            # $$ is our process id
4044         or die "Can't start sort: $!";
4045
4046     # in-memory files
4047     open(MEMORY, ">", \$var)
4048         or die "Can't open memory file: $!";
4049     print MEMORY "foo!\n";              # output will appear in $var
4050
4051     # process argument list of files along with any includes
4052
4053     foreach $file (@ARGV) {
4054         process($file, "fh00");
4055     }
4056
4057     sub process {
4058         my($filename, $input) = @_;
4059         $input++;    # this is a string increment
4060         unless (open($input, "<", $filename)) {
4061             print STDERR "Can't open $filename: $!\n";
4062             return;
4063         }
4064
4065         local $_;
4066         while (<$input>) {    # note use of indirection
4067             if (/^#include "(.*)"/) {
4068                 process($1, $input);
4069                 next;
4070             }
4071             #...          # whatever
4072         }
4073     }
4074
4075 See L<perliol> for detailed info on PerlIO.
4076
4077 You may also, in the Bourne shell tradition, specify an EXPR beginning
4078 with C<< >& >>, in which case the rest of the string is interpreted
4079 as the name of a filehandle (or file descriptor, if numeric) to be
4080 duped (as C<dup(2)>) and opened.  You may use C<&> after C<< > >>,
4081 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
4082 The mode you specify should match the mode of the original filehandle.
4083 (Duping a filehandle does not take into account any existing contents
4084 of IO buffers.)  If you use the three-argument
4085 form, then you can pass either a
4086 number, the name of a filehandle, or the normal "reference to a glob".
4087
4088 Here is a script that saves, redirects, and restores C<STDOUT> and
4089 C<STDERR> using various methods:
4090
4091     #!/usr/bin/perl
4092     open(my $oldout, ">&STDOUT")     or die "Can't dup STDOUT: $!";
4093     open(OLDERR,     ">&", \*STDERR) or die "Can't dup STDERR: $!";
4094
4095     open(STDOUT, '>', "foo.out") or die "Can't redirect STDOUT: $!";
4096     open(STDERR, ">&STDOUT")     or die "Can't dup STDOUT: $!";
4097
4098     select STDERR; $| = 1;  # make unbuffered
4099     select STDOUT; $| = 1;  # make unbuffered
4100
4101     print STDOUT "stdout 1\n";  # this works for
4102     print STDERR "stderr 1\n";  # subprocesses too
4103
4104     open(STDOUT, ">&", $oldout) or die "Can't dup \$oldout: $!";
4105     open(STDERR, ">&OLDERR")    or die "Can't dup OLDERR: $!";
4106
4107     print STDOUT "stdout 2\n";
4108     print STDERR "stderr 2\n";
4109
4110 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
4111 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
4112 that file descriptor (and not call C<dup(2)>); this is more
4113 parsimonious of file descriptors.  For example:
4114
4115     # open for input, reusing the fileno of $fd
4116     open(FILEHANDLE, "<&=$fd")
4117
4118 or
4119
4120     open(FILEHANDLE, "<&=", $fd)
4121
4122 or
4123
4124     # open for append, using the fileno of OLDFH
4125     open(FH, ">>&=", OLDFH)
4126
4127 or
4128
4129     open(FH, ">>&=OLDFH")
4130
4131 Being parsimonious on filehandles is also useful (besides being
4132 parsimonious) for example when something is dependent on file
4133 descriptors, like for example locking using flock().  If you do just
4134 C<< open(A, ">>&B") >>, the filehandle A will not have the same file
4135 descriptor as B, and therefore flock(A) will not flock(B) nor vice
4136 versa.  But with C<< open(A, ">>&=B") >>, the filehandles will share
4137 the same underlying system file descriptor.
4138
4139 Note that under Perls older than 5.8.0, Perl uses the standard C library's'
4140 fdopen() to implement the C<=> functionality.  On many Unix systems,
4141 fdopen() fails when file descriptors exceed a certain value, typically 255.
4142 For Perls 5.8.0 and later, PerlIO is (most often) the default.
4143
4144 You can see whether your Perl was built with PerlIO by running C<perl -V>
4145 and looking for the C<useperlio=> line.  If C<useperlio> is C<define>, you
4146 have PerlIO; otherwise you don't.
4147
4148 If you open a pipe on the command C<-> (that is, specify either C<|-> or C<-|>
4149 with the one- or two-argument forms of C<open>), 
4150 an implicit C<fork> is done, so C<open> returns twice: in the parent
4151 process it returns the pid
4152 of the child process, and in the child process it returns (a defined) C<0>.
4153 Use C<defined($pid)> or C<//> to determine whether the open was successful.
4154
4155 For example, use either
4156
4157     $child_pid = open(FROM_KID, "-|")   // die "can't fork: $!";
4158
4159 or
4160
4161     $child_pid = open(TO_KID,   "|-")   // die "can't fork: $!";
4162
4163 followed by 
4164
4165     if ($child_pid) {
4166         # am the parent:
4167         # either write TO_KID or else read FROM_KID
4168         ...
4169        waitpid $child_pid, 0;
4170     } else {
4171         # am the child; use STDIN/STDOUT normally
4172         ...
4173         exit;
4174     } 
4175
4176 The filehandle behaves normally for the parent, but I/O to that
4177 filehandle is piped from/to the STDOUT/STDIN of the child process.
4178 In the child process, the filehandle isn't opened--I/O happens from/to
4179 the new STDOUT/STDIN.  Typically this is used like the normal
4180 piped open when you want to exercise more control over just how the
4181 pipe command gets executed, such as when running setuid and
4182 you don't want to have to scan shell commands for metacharacters.
4183
4184 The following blocks are more or less equivalent:
4185
4186     open(FOO, "|tr '[a-z]' '[A-Z]'");
4187     open(FOO, "|-", "tr '[a-z]' '[A-Z]'");
4188     open(FOO, "|-") || exec 'tr', '[a-z]', '[A-Z]';
4189     open(FOO, "|-", "tr", '[a-z]', '[A-Z]');
4190
4191     open(FOO, "cat -n '$file'|");
4192     open(FOO, "-|", "cat -n '$file'");
4193     open(FOO, "-|") || exec "cat", "-n", $file;
4194     open(FOO, "-|", "cat", "-n", $file);
4195
4196 The last two examples in each block show the pipe as "list form", which is
4197 not yet supported on all platforms.  A good rule of thumb is that if
4198 your platform has a real C<fork()> (in other words, if your platform is
4199 Unix, including Linux and MacOS X), you can use the list form.  You would 
4200 want to use the list form of the pipe so you can pass literal arguments
4201 to the command without risk of the shell interpreting any shell metacharacters
4202 in them.  However, this also bars you from opening pipes to commands
4203 that intentionally contain shell metacharacters, such as:
4204
4205     open(FOO, "|cat -n | expand -4 | lpr")
4206         // die "Can't open pipeline to lpr: $!";
4207
4208 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
4209
4210 Perl will attempt to flush all files opened for
4211 output before any operation that may do a fork, but this may not be
4212 supported on some platforms (see L<perlport>).  To be safe, you may need
4213 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
4214 of C<IO::Handle> on any open handles.
4215
4216 On systems that support a close-on-exec flag on files, the flag will
4217 be set for the newly opened file descriptor as determined by the value
4218 of C<$^F>.  See L<perlvar/$^F>.
4219
4220 Closing any piped filehandle causes the parent process to wait for the
4221 child to finish, then returns the status value in C<$?> and
4222 C<${^CHILD_ERROR_NATIVE}>.
4223
4224 The filename passed to the one- and two-argument forms of open() will
4225 have leading and trailing whitespace deleted and normal
4226 redirection characters honored.  This property, known as "magic open",
4227 can often be used to good effect.  A user could specify a filename of
4228 F<"rsh cat file |">, or you could change certain filenames as needed:
4229
4230     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
4231     open(FH, $filename) or die "Can't open $filename: $!";
4232
4233 Use the three-argument form to open a file with arbitrary weird characters in it,
4234
4235     open(FOO, "<", $file)
4236         || die "can't open < $file: $!";
4237
4238 otherwise it's necessary to protect any leading and trailing whitespace:
4239
4240     $file =~ s#^(\s)#./$1#;
4241     open(FOO, "< $file\0")
4242         || die "open failed: $!";
4243
4244 (this may not work on some bizarre filesystems).  One should
4245 conscientiously choose between the I<magic> and I<three-argument> form
4246 of open():
4247
4248     open(IN, $ARGV[0]) || die "can't open $ARGV[0]: $!";
4249
4250 will allow the user to specify an argument of the form C<"rsh cat file |">,
4251 but will not work on a filename that happens to have a trailing space, while
4252
4253     open(IN, "<", $ARGV[0])
4254         || die "can't open < $ARGV[0]: $!";
4255
4256 will have exactly the opposite restrictions.
4257
4258 If you want a "real" C C<open> (see L<open(2)> on your system), then you
4259 should use the C<sysopen> function, which involves no such magic (but may
4260 use subtly different filemodes than Perl open(), which is mapped to C
4261 fopen()).  This is another way to protect your filenames from
4262 interpretation.  For example:
4263
4264     use IO::Handle;
4265     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
4266         or die "sysopen $path: $!";
4267     $oldfh = select(HANDLE); $| = 1; select($oldfh);
4268     print HANDLE "stuff $$\n";
4269     seek(HANDLE, 0, 0);
4270     print "File contains: ", <HANDLE>;
4271
4272 Using the constructor from the C<IO::Handle> package (or one of its
4273 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
4274 filehandles that have the scope of the variables used to hold them, then
4275 automatically (but silently) close once their reference counts become
4276 zero, typically at scope exit:
4277
4278     use IO::File;
4279     #...
4280     sub read_myfile_munged {
4281         my $ALL = shift;
4282         # or just leave it undef to autoviv
4283         my $handle = IO::File->new;
4284         open($handle, "<", "myfile") or die "myfile: $!";
4285         $first = <$handle>
4286             or return ();     # Automatically closed here.
4287         mung($first) or die "mung failed";  # Or here.
4288         return (first, <$handle>) if $ALL;  # Or here.
4289         return $first;                      # Or here.
4290     }
4291
4292 B<WARNING:> The previous example has a bug because the automatic
4293 close that happens when the refcount on C<handle> reaches zero does not
4294 properly detect and report failures.  I<Always> close the handle
4295 yourself and inspect the return value.
4296
4297     close($handle) 
4298         || warn "close failed: $!";
4299
4300 See L</seek> for some details about mixing reading and writing.
4301
4302 Portability issues: L<perlport/open>.
4303
4304 =item opendir DIRHANDLE,EXPR
4305 X<opendir>
4306
4307 =for Pod::Functions open a directory
4308
4309 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
4310 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
4311 DIRHANDLE may be an expression whose value can be used as an indirect
4312 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
4313 scalar variable (or array or hash element), the variable is assigned a
4314 reference to a new anonymous dirhandle; that is, it's autovivified.
4315 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
4316
4317 See the example at C<readdir>.
4318
4319 =item ord EXPR
4320 X<ord> X<encoding>
4321
4322 =item ord
4323
4324 =for Pod::Functions find a character's numeric representation
4325
4326 Returns the numeric value of the first character of EXPR.
4327 If EXPR is an empty string, returns 0.  If EXPR is omitted, uses C<$_>.
4328 (Note I<character>, not byte.)
4329
4330 For the reverse, see L</chr>.
4331 See L<perlunicode> for more about Unicode.
4332
4333 =item our VARLIST
4334 X<our> X<global>
4335
4336 =item our TYPE VARLIST
4337
4338 =item our VARLIST : ATTRS
4339
4340 =item our TYPE VARLIST : ATTRS
4341
4342 =for Pod::Functions +5.6.0 declare and assign a package variable (lexical scoping)
4343
4344 C<our> makes a lexical alias to a package variable of the same name in the current
4345 package for use within the current lexical scope.
4346
4347 C<our> has the same scoping rules as C<my> or C<state>, but C<our> only
4348 declares an alias, whereas C<my> or C<state> both declare a variable name and
4349 allocate storage for that name within the current scope.
4350
4351 This means that when C<use strict 'vars'> is in effect, C<our> lets you use
4352 a package variable without qualifying it with the package name, but only within
4353 the lexical scope of the C<our> declaration.  In this way, C<our> differs from
4354 C<use vars>, which allows use of an unqualified name I<only> within the
4355 affected package, but across scopes.
4356
4357 If more than one variable is listed, the list must be placed
4358 in parentheses.
4359
4360     our $foo;
4361     our($bar, $baz);
4362
4363 An C<our> declaration declares an alias for a package variable that will be visible
4364 across its entire lexical scope, even across package boundaries.  The
4365 package in which the variable is entered is determined at the point
4366 of the declaration, not at the point of use.  This means the following
4367 behavior holds:
4368
4369     package Foo;
4370     our $bar;      # declares $Foo::bar for rest of lexical scope
4371     $bar = 20;
4372
4373     package Bar;
4374     print $bar;    # prints 20, as it refers to $Foo::bar
4375
4376 Multiple C<our> declarations with the same name in the same lexical
4377 scope are allowed if they are in different packages.  If they happen
4378 to be in the same package, Perl will emit warnings if you have asked
4379 for them, just like multiple C<my> declarations.  Unlike a second
4380 C<my> declaration, which will bind the name to a fresh variable, a
4381 second C<our> declaration in the same package, in the same scope, is
4382 merely redundant.
4383
4384     use warnings;
4385     package Foo;
4386     our $bar;      # declares $Foo::bar for rest of lexical scope
4387     $bar = 20;
4388
4389     package Bar;
4390     our $bar = 30; # declares $Bar::bar for rest of lexical scope
4391     print $bar;    # prints 30
4392
4393     our $bar;      # emits warning but has no other effect
4394     print $bar;    # still prints 30
4395
4396 An C<our> declaration may also have a list of attributes associated
4397 with it.
4398
4399 The exact semantics and interface of TYPE and ATTRS are still
4400 evolving.  TYPE is currently bound to the use of the C<fields> pragma,
4401 and attributes are handled using the C<attributes> pragma, or, starting
4402 from Perl 5.8.0, also via the C<Attribute::Handlers> module.  See
4403 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
4404 L<attributes>, and L<Attribute::Handlers>.
4405
4406 Note that with a parenthesised list, C<undef> can be used as a dummy
4407 placeholder, for example to skip assignment of initial values:
4408
4409     our ( undef, $min, $hour ) = localtime;
4410
4411 =item pack TEMPLATE,LIST
4412 X<pack>
4413
4414 =for Pod::Functions convert a list into a binary representation
4415
4416 Takes a LIST of values and converts it into a string using the rules
4417 given by the TEMPLATE.  The resulting string is the concatenation of
4418 the converted values.  Typically, each converted value looks
4419 like its machine-level representation.  For example, on 32-bit machines
4420 an integer may be represented by a sequence of 4 bytes, which  will in
4421 Perl be presented as a string that's 4 characters long. 
4422
4423 See L<perlpacktut> for an introduction to this function.
4424
4425 The TEMPLATE is a sequence of characters that give the order and type
4426 of values, as follows:
4427
4428     a  A string with arbitrary binary data, will be null padded.
4429     A  A text (ASCII) string, will be space padded.
4430     Z  A null-terminated (ASCIZ) string, will be null padded.
4431
4432     b  A bit string (ascending bit order inside each byte,
4433        like vec()).
4434     B  A bit string (descending bit order inside each byte).
4435     h  A hex string (low nybble first).
4436     H  A hex string (high nybble first).
4437
4438     c  A signed char (8-bit) value.
4439     C  An unsigned char (octet) value.
4440     W  An unsigned char value (can be greater than 255).
4441
4442     s  A signed short (16-bit) value.
4443     S  An unsigned short value.
4444
4445     l  A signed long (32-bit) value.
4446     L  An unsigned long value.
4447
4448     q  A signed quad (64-bit) value.
4449     Q  An unsigned quad value.
4450          (Quads are available only if your system supports 64-bit
4451           integer values _and_ if Perl has been compiled to support
4452           those.  Raises an exception otherwise.)
4453
4454     i  A signed integer value.
4455     I  A unsigned integer value.
4456          (This 'integer' is _at_least_ 32 bits wide.  Its exact
4457           size depends on what a local C compiler calls 'int'.)
4458
4459     n  An unsigned short (16-bit) in "network" (big-endian) order.
4460     N  An unsigned long (32-bit) in "network" (big-endian) order.
4461     v  An unsigned short (16-bit) in "VAX" (little-endian) order.
4462     V  An unsigned long (32-bit) in "VAX" (little-endian) order.
4463
4464     j  A Perl internal signed integer value (IV).
4465     J  A Perl internal unsigned integer value (UV).
4466
4467     f  A single-precision float in native format.
4468     d  A double-precision float in native format.
4469
4470     F  A Perl internal floating-point value (NV) in native format
4471     D  A float of long-double precision in native format.
4472          (Long doubles are available only if your system supports
4473           long double values _and_ if Perl has been compiled to
4474           support those.  Raises an exception otherwise.)
4475
4476     p  A pointer to a null-terminated string.
4477     P  A pointer to a structure (fixed-length string).
4478
4479     u  A uuencoded string.
4480     U  A Unicode character number.  Encodes to a character in char-
4481        acter mode and UTF-8 (or UTF-EBCDIC in EBCDIC platforms) in
4482        byte mode.
4483
4484     w  A BER compressed integer (not an ASN.1 BER, see perlpacktut
4485        for details).  Its bytes represent an unsigned integer in
4486        base 128, most significant digit first, with as few digits
4487        as possible.  Bit eight (the high bit) is set on each byte
4488        except the last.
4489
4490     x  A null byte (a.k.a ASCII NUL, "\000", chr(0))
4491     X  Back up a byte.
4492     @  Null-fill or truncate to absolute position, counted from the
4493        start of the innermost ()-group.
4494     .  Null-fill or truncate to absolute position specified by
4495        the value.
4496     (  Start of a ()-group.
4497
4498 One or more modifiers below may optionally follow certain letters in the
4499 TEMPLATE (the second column lists letters for which the modifier is valid):
4500
4501     !   sSlLiI     Forces native (short, long, int) sizes instead
4502                    of fixed (16-/32-bit) sizes.
4503
4504         xX         Make x and X act as alignment commands.
4505
4506         nNvV       Treat integers as signed instead of unsigned.
4507
4508         @.         Specify position as byte offset in the internal
4509                    representation of the packed string.  Efficient
4510                    but dangerous.
4511
4512     >   sSiIlLqQ   Force big-endian byte-order on the type.
4513         jJfFdDpP   (The "big end" touches the construct.)
4514
4515     <   sSiIlLqQ   Force little-endian byte-order on the type.
4516         jJfFdDpP   (The "little end" touches the construct.)
4517
4518 The C<< > >> and C<< < >> modifiers can also be used on C<()> groups 
4519 to force a particular byte-order on all components in that group, 
4520 including all its subgroups.
4521
4522 =begin comment
4523
4524 Larry recalls that the hex and bit string formats (H, h, B, b) were added to
4525 pack for processing data from NASA's Magellan probe.  Magellan was in an
4526 elliptical orbit, using the antenna for the radar mapping when close to
4527 Venus and for communicating data back to Earth for the rest of the orbit.
4528 There were two transmission units, but one of these failed, and then the
4529 other developed a fault whereby it would randomly flip the sense of all the
4530 bits. It was easy to automatically detect complete records with the correct
4531 sense, and complete records with all the bits flipped. However, this didn't
4532 recover the records where the sense flipped midway. A colleague of Larry's
4533 was able to pretty much eyeball where the records flipped, so they wrote an
4534 editor named kybble (a pun on the dog food Kibbles 'n Bits) to enable him to
4535 manually correct the records and recover the data. For this purpose pack
4536 gained the hex and bit string format specifiers.
4537
4538 git shows that they were added to perl 3.0 in patch #44 (Jan 1991, commit
4539 27e2fb84680b9cc1), but the patch description makes no mention of their
4540 addition, let alone the story behind them.
4541
4542 =end comment
4543
4544 The following rules apply:
4545
4546 =over 
4547
4548 =item *
4549
4550 Each letter may optionally be followed by a number indicating the repeat
4551 count.  A numeric repeat count may optionally be enclosed in brackets, as
4552 in C<pack("C[80]", @arr)>.  The repeat count gobbles that many values from
4553 the LIST when used with all format types other than C<a>, C<A>, C<Z>, C<b>,
4554 C<B>, C<h>, C<H>, C<@>, C<.>, C<x>, C<X>, and C<P>, where it means
4555 something else, described below.  Supplying a C<*> for the repeat count
4556 instead of a number means to use however many items are left, except for:
4557
4558 =over 
4559
4560 =item * 
4561
4562 C<@>, C<x>, and C<X>, where it is equivalent to C<0>.
4563
4564 =item * 
4565
4566 <.>, where it means relative to the start of the string.
4567
4568 =item * 
4569
4570 C<u>, where it is equivalent to 1 (or 45, which here is equivalent).
4571
4572 =back 
4573
4574 One can replace a numeric repeat count with a template letter enclosed in
4575 brackets to use the packed byte length of the bracketed template for the
4576 repeat count.
4577
4578 For example, the template C<x[L]> skips as many bytes as in a packed long,
4579 and the template C<"$t X[$t] $t"> unpacks twice whatever $t (when
4580 variable-expanded) unpacks.  If the template in brackets contains alignment
4581 commands (such as C<x![d]>), its packed length is calculated as if the
4582 start of the template had the maximal possible alignment.
4583
4584 When used with C<Z>, a C<*> as the repeat count is guaranteed to add a
4585 trailing null byte, so the resulting string is always one byte longer than
4586 the byte length of the item itself.
4587
4588 When used with C<@>, the repeat count represents an offset from the start
4589 of the innermost C<()> group.
4590
4591 When used with C<.>, the repeat count determines the starting position to
4592 calculate the value offset as follows:
4593
4594 =over 
4595
4596 =item *
4597
4598 If the repeat count is C<0>, it's relative to the current position.
4599
4600 =item *
4601
4602 If the repeat count is C<*>, the offset is relative to the start of the
4603 packed string.
4604
4605 =item *
4606
4607 And if it's an integer I<n>, the offset is relative to the start of the
4608 I<n>th innermost C<( )> group, or to the start of the string if I<n> is
4609 bigger then the group level.
4610
4611 =back
4612
4613 The repeat count for C<u> is interpreted as the maximal number of bytes
4614 to encode per line of output, with 0, 1 and 2 replaced by 45.  The repeat 
4615 count should not be more than 65.
4616
4617 =item *
4618
4619 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
4620 string of length count, padding with nulls or spaces as needed.  When
4621 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
4622 after the first null, and C<a> returns data with no stripping at all.
4623
4624 If the value to pack is too long, the result is truncated.  If it's too
4625 long and an explicit count is provided, C<Z> packs only C<$count-1> bytes,
4626 followed by a null byte.  Thus C<Z> always packs a trailing null, except
4627 when the count is 0.
4628
4629 =item *
4630
4631 Likewise, the C<b> and C<B> formats pack a string that's that many bits long.
4632 Each such format generates 1 bit of the result.  These are typically followed
4633 by a repeat count like C<B8> or C<B64>.
4634
4635 Each result bit is based on the least-significant bit of the corresponding
4636 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
4637 and C<"1"> generate bits 0 and 1, as do characters C<"\000"> and C<"\001">.
4638
4639 Starting from the beginning of the input string, each 8-tuple
4640 of characters is converted to 1 character of output.  With format C<b>,
4641 the first character of the 8-tuple determines the least-significant bit of a
4642 character; with format C<B>, it determines the most-significant bit of
4643 a character.
4644
4645 If the length of the input string is not evenly divisible by 8, the
4646 remainder is packed as if the input string were padded by null characters
4647 at the end.  Similarly during unpacking, "extra" bits are ignored.
4648
4649 If the input string is longer than needed, remaining characters are ignored.
4650
4651 A C<*> for the repeat count uses all characters of the input field.  
4652 On unpacking, bits are converted to a string of C<0>s and C<1>s.
4653
4654 =item *
4655
4656 The C<h> and C<H> formats pack a string that many nybbles (4-bit groups,
4657 representable as hexadecimal digits, C<"0".."9"> C<"a".."f">) long.
4658
4659 For each such format, pack() generates 4 bits of result.
4660 With non-alphabetical characters, the result is based on the 4 least-significant
4661 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
4662 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
4663 C<"\000"> and C<"\001">.  For characters C<"a".."f"> and C<"A".."F">, the result
4664 is compatible with the usual hexadecimal digits, so that C<"a"> and
4665 C<"A"> both generate the nybble C<0xA==10>.  Use only these specific hex 
4666 characters with this format.
4667
4668 Starting from the beginning of the template to pack(), each pair
4669 of characters is converted to 1 character of output.  With format C<h>, the
4670 first character of the pair determines the least-significant nybble of the
4671 output character; with format C<H>, it determines the most-significant
4672 nybble.
4673
4674 If the length of the input string is not even, it behaves as if padded by
4675 a null character at the end.  Similarly, "extra" nybbles are ignored during
4676 unpacking.
4677
4678 If the input string is longer than needed, extra characters a