This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
18a818680472e2aba2304d70610a382540316d80
[perl5.git] / lib / unicore / mktables
1 #!/usr/bin/perl -w
2
3 # !!!!!!!!!!!!!!       IF YOU MODIFY THIS FILE       !!!!!!!!!!!!!!!!!!!!!!!!!
4 # Any files created or read by this program should be listed in 'mktables.lst'
5 # Use -makelist to regenerate it.
6
7 # There was an attempt when this was first rewritten to make it 5.8
8 # compatible, but that has now been abandoned, and newer constructs are used
9 # as convenient.
10
11 my $start_time;
12 BEGIN { # Get the time the script started running; do it at compilation to
13         # get it as close as possible
14     $start_time= time;
15 }
16
17 require 5.010_001;
18 use strict;
19 use warnings;
20 use Carp;
21 use Config;
22 use File::Find;
23 use File::Path;
24 use File::Spec;
25 use Text::Tabs;
26 use re "/aa";
27 use feature 'state';
28
29 sub DEBUG () { 0 }  # Set to 0 for production; 1 for development
30 my $debugging_build = $Config{"ccflags"} =~ /-DDEBUGGING/;
31
32 sub NON_ASCII_PLATFORM { ord("A") != 65 }
33
34 ##########################################################################
35 #
36 # mktables -- create the runtime Perl Unicode files (lib/unicore/.../*.pl),
37 # from the Unicode database files (lib/unicore/.../*.txt),  It also generates
38 # a pod file and .t files, depending on option parameters.
39 #
40 # The structure of this file is:
41 #   First these introductory comments; then
42 #   code needed for everywhere, such as debugging stuff; then
43 #   code to handle input parameters; then
44 #   data structures likely to be of external interest (some of which depend on
45 #       the input parameters, so follows them; then
46 #   more data structures and subroutine and package (class) definitions; then
47 #   the small actual loop to process the input files and finish up; then
48 #   a __DATA__ section, for the .t tests
49 #
50 # This program works on all releases of Unicode so far.  The outputs have been
51 # scrutinized most intently for release 5.1.  The others have been checked for
52 # somewhat more than just sanity.  It can handle all non-provisional Unicode
53 # character properties in those releases.
54 #
55 # This program is mostly about Unicode character (or code point) properties.
56 # A property describes some attribute or quality of a code point, like if it
57 # is lowercase or not, its name, what version of Unicode it was first defined
58 # in, or what its uppercase equivalent is.  Unicode deals with these disparate
59 # possibilities by making all properties into mappings from each code point
60 # into some corresponding value.  In the case of it being lowercase or not,
61 # the mapping is either to 'Y' or 'N' (or various synonyms thereof).  Each
62 # property maps each Unicode code point to a single value, called a "property
63 # value".  (Some more recently defined properties, map a code point to a set
64 # of values.)
65 #
66 # When using a property in a regular expression, what is desired isn't the
67 # mapping of the code point to its property's value, but the reverse (or the
68 # mathematical "inverse relation"): starting with the property value, "Does a
69 # code point map to it?"  These are written in a "compound" form:
70 # \p{property=value}, e.g., \p{category=punctuation}.  This program generates
71 # files containing the lists of code points that map to each such regular
72 # expression property value, one file per list
73 #
74 # There is also a single form shortcut that Perl adds for many of the commonly
75 # used properties.  This happens for all binary properties, plus script,
76 # general_category, and block properties.
77 #
78 # Thus the outputs of this program are files.  There are map files, mostly in
79 # the 'To' directory; and there are list files for use in regular expression
80 # matching, all in subdirectories of the 'lib' directory, with each
81 # subdirectory being named for the property that the lists in it are for.
82 # Bookkeeping, test, and documentation files are also generated.
83
84 my $matches_directory = 'lib';   # Where match (\p{}) files go.
85 my $map_directory = 'To';        # Where map files go.
86
87 # DATA STRUCTURES
88 #
89 # The major data structures of this program are Property, of course, but also
90 # Table.  There are two kinds of tables, very similar to each other.
91 # "Match_Table" is the data structure giving the list of code points that have
92 # a particular property value, mentioned above.  There is also a "Map_Table"
93 # data structure which gives the property's mapping from code point to value.
94 # There are two structures because the match tables need to be combined in
95 # various ways, such as constructing unions, intersections, complements, etc.,
96 # and the map ones don't.  And there would be problems, perhaps subtle, if
97 # a map table were inadvertently operated on in some of those ways.
98 # The use of separate classes with operations defined on one but not the other
99 # prevents accidentally confusing the two.
100 #
101 # At the heart of each table's data structure is a "Range_List", which is just
102 # an ordered list of "Ranges", plus ancillary information, and methods to
103 # operate on them.  A Range is a compact way to store property information.
104 # Each range has a starting code point, an ending code point, and a value that
105 # is meant to apply to all the code points between the two end points,
106 # inclusive.  For a map table, this value is the property value for those
107 # code points.  Two such ranges could be written like this:
108 #   0x41 .. 0x5A, 'Upper',
109 #   0x61 .. 0x7A, 'Lower'
110 #
111 # Each range also has a type used as a convenience to classify the values.
112 # Most ranges in this program will be Type 0, or normal, but there are some
113 # ranges that have a non-zero type.  These are used only in map tables, and
114 # are for mappings that don't fit into the normal scheme of things.  Mappings
115 # that require a hash entry to communicate with utf8.c are one example;
116 # another example is mappings for charnames.pm to use which indicate a name
117 # that is algorithmically determinable from its code point (and the reverse).
118 # These are used to significantly compact these tables, instead of listing
119 # each one of the tens of thousands individually.
120 #
121 # In a match table, the value of a range is irrelevant (and hence the type as
122 # well, which will always be 0), and arbitrarily set to the null string.
123 # Using the example above, there would be two match tables for those two
124 # entries, one named Upper would contain the 0x41..0x5A range, and the other
125 # named Lower would contain 0x61..0x7A.
126 #
127 # Actually, there are two types of range lists, "Range_Map" is the one
128 # associated with map tables, and "Range_List" with match tables.
129 # Again, this is so that methods can be defined on one and not the others so
130 # as to prevent operating on them in incorrect ways.
131 #
132 # Eventually, most tables are written out to files to be read by utf8_heavy.pl
133 # in the perl core.  All tables could in theory be written, but some are
134 # suppressed because there is no current practical use for them.  It is easy
135 # to change which get written by changing various lists that are near the top
136 # of the actual code in this file.  The table data structures contain enough
137 # ancillary information to allow them to be treated as separate entities for
138 # writing, such as the path to each one's file.  There is a heading in each
139 # map table that gives the format of its entries, and what the map is for all
140 # the code points missing from it.  (This allows tables to be more compact.)
141 #
142 # The Property data structure contains one or more tables.  All properties
143 # contain a map table (except the $perl property which is a
144 # pseudo-property containing only match tables), and any properties that
145 # are usable in regular expression matches also contain various matching
146 # tables, one for each value the property can have.  A binary property can
147 # have two values, True and False (or Y and N, which are preferred by Unicode
148 # terminology).  Thus each of these properties will have a map table that
149 # takes every code point and maps it to Y or N (but having ranges cuts the
150 # number of entries in that table way down), and two match tables, one
151 # which has a list of all the code points that map to Y, and one for all the
152 # code points that map to N.  (For each binary property, a third table is also
153 # generated for the pseudo Perl property.  It contains the identical code
154 # points as the Y table, but can be written in regular expressions, not in the
155 # compound form, but in a "single" form like \p{IsUppercase}.)  Many
156 # properties are binary, but some properties have several possible values,
157 # some have many, and properties like Name have a different value for every
158 # named code point.  Those will not, unless the controlling lists are changed,
159 # have their match tables written out.  But all the ones which can be used in
160 # regular expression \p{} and \P{} constructs will.  Prior to 5.14, generally
161 # a property would have either its map table or its match tables written but
162 # not both.  Again, what gets written is controlled by lists which can easily
163 # be changed.  Starting in 5.14, advantage was taken of this, and all the map
164 # tables needed to reconstruct the Unicode db are now written out, while
165 # suppressing the Unicode .txt files that contain the data.  Our tables are
166 # much more compact than the .txt files, so a significant space savings was
167 # achieved.  Also, tables are not written out that are trivially derivable
168 # from tables that do get written.  So, there typically is no file containing
169 # the code points not matched by a binary property (the table for \P{} versus
170 # lowercase \p{}), since you just need to invert the True table to get the
171 # False table.
172
173 # Properties have a 'Type', like 'binary', or 'string', or 'enum' depending on
174 # how many match tables there are and the content of the maps.  This 'Type' is
175 # different than a range 'Type', so don't get confused by the two concepts
176 # having the same name.
177 #
178 # For information about the Unicode properties, see Unicode's UAX44 document:
179
180 my $unicode_reference_url = 'http://www.unicode.org/reports/tr44/';
181
182 # As stated earlier, this program will work on any release of Unicode so far.
183 # Most obvious problems in earlier data have NOT been corrected except when
184 # necessary to make Perl or this program work reasonably, and to keep out
185 # potential security issues.  For example, no folding information was given in
186 # early releases, so this program substitutes lower case instead, just so that
187 # a regular expression with the /i option will do something that actually
188 # gives the right results in many cases.  There are also a couple other
189 # corrections for version 1.1.5, commented at the point they are made.  As an
190 # example of corrections that weren't made (but could be) is this statement
191 # from DerivedAge.txt: "The supplementary private use code points and the
192 # non-character code points were assigned in version 2.0, but not specifically
193 # listed in the UCD until versions 3.0 and 3.1 respectively."  (To be precise
194 # it was 3.0.1 not 3.0.0)  More information on Unicode version glitches is
195 # further down in these introductory comments.
196 #
197 # This program works on all non-provisional properties as of the current
198 # Unicode release, though the files for some are suppressed for various
199 # reasons.  You can change which are output by changing lists in this program.
200 #
201 # The old version of mktables emphasized the term "Fuzzy" to mean Unicode's
202 # loose matchings rules (from Unicode TR18):
203 #
204 #    The recommended names for UCD properties and property values are in
205 #    PropertyAliases.txt [Prop] and PropertyValueAliases.txt
206 #    [PropValue]. There are both abbreviated names and longer, more
207 #    descriptive names. It is strongly recommended that both names be
208 #    recognized, and that loose matching of property names be used,
209 #    whereby the case distinctions, whitespace, hyphens, and underbar
210 #    are ignored.
211 #
212 # The program still allows Fuzzy to override its determination of if loose
213 # matching should be used, but it isn't currently used, as it is no longer
214 # needed; the calculations it makes are good enough.
215 #
216 # SUMMARY OF HOW IT WORKS:
217 #
218 #   Process arguments
219 #
220 #   A list is constructed containing each input file that is to be processed
221 #
222 #   Each file on the list is processed in a loop, using the associated handler
223 #   code for each:
224 #        The PropertyAliases.txt and PropValueAliases.txt files are processed
225 #            first.  These files name the properties and property values.
226 #            Objects are created of all the property and property value names
227 #            that the rest of the input should expect, including all synonyms.
228 #        The other input files give mappings from properties to property
229 #           values.  That is, they list code points and say what the mapping
230 #           is under the given property.  Some files give the mappings for
231 #           just one property; and some for many.  This program goes through
232 #           each file and populates the properties and their map tables from
233 #           them.  Some properties are listed in more than one file, and
234 #           Unicode has set up a precedence as to which has priority if there
235 #           is a conflict.  Thus the order of processing matters, and this
236 #           program handles the conflict possibility by processing the
237 #           overriding input files last, so that if necessary they replace
238 #           earlier values.
239 #        After this is all done, the program creates the property mappings not
240 #            furnished by Unicode, but derivable from what it does give.
241 #        The tables of code points that match each property value in each
242 #            property that is accessible by regular expressions are created.
243 #        The Perl-defined properties are created and populated.  Many of these
244 #            require data determined from the earlier steps
245 #        Any Perl-defined synonyms are created, and name clashes between Perl
246 #            and Unicode are reconciled and warned about.
247 #        All the properties are written to files
248 #        Any other files are written, and final warnings issued.
249 #
250 # For clarity, a number of operators have been overloaded to work on tables:
251 #   ~ means invert (take all characters not in the set).  The more
252 #       conventional '!' is not used because of the possibility of confusing
253 #       it with the actual boolean operation.
254 #   + means union
255 #   - means subtraction
256 #   & means intersection
257 # The precedence of these is the order listed.  Parentheses should be
258 # copiously used.  These are not a general scheme.  The operations aren't
259 # defined for a number of things, deliberately, to avoid getting into trouble.
260 # Operations are done on references and affect the underlying structures, so
261 # that the copy constructors for them have been overloaded to not return a new
262 # clone, but the input object itself.
263 #
264 # The bool operator is deliberately not overloaded to avoid confusion with
265 # "should it mean if the object merely exists, or also is non-empty?".
266 #
267 # WHY CERTAIN DESIGN DECISIONS WERE MADE
268 #
269 # This program needs to be able to run under miniperl.  Therefore, it uses a
270 # minimum of other modules, and hence implements some things itself that could
271 # be gotten from CPAN
272 #
273 # This program uses inputs published by the Unicode Consortium.  These can
274 # change incompatibly between releases without the Perl maintainers realizing
275 # it.  Therefore this program is now designed to try to flag these.  It looks
276 # at the directories where the inputs are, and flags any unrecognized files.
277 # It keeps track of all the properties in the files it handles, and flags any
278 # that it doesn't know how to handle.  It also flags any input lines that
279 # don't match the expected syntax, among other checks.
280 #
281 # It is also designed so if a new input file matches one of the known
282 # templates, one hopefully just needs to add it to a list to have it
283 # processed.
284 #
285 # As mentioned earlier, some properties are given in more than one file.  In
286 # particular, the files in the extracted directory are supposedly just
287 # reformattings of the others.  But they contain information not easily
288 # derivable from the other files, including results for Unihan (which isn't
289 # usually available to this program) and for unassigned code points.  They
290 # also have historically had errors or been incomplete.  In an attempt to
291 # create the best possible data, this program thus processes them first to
292 # glean information missing from the other files; then processes those other
293 # files to override any errors in the extracted ones.  Much of the design was
294 # driven by this need to store things and then possibly override them.
295 #
296 # It tries to keep fatal errors to a minimum, to generate something usable for
297 # testing purposes.  It always looks for files that could be inputs, and will
298 # warn about any that it doesn't know how to handle (the -q option suppresses
299 # the warning).
300 #
301 # Why is there more than one type of range?
302 #   This simplified things.  There are some very specialized code points that
303 #   have to be handled specially for output, such as Hangul syllable names.
304 #   By creating a range type (done late in the development process), it
305 #   allowed this to be stored with the range, and overridden by other input.
306 #   Originally these were stored in another data structure, and it became a
307 #   mess trying to decide if a second file that was for the same property was
308 #   overriding the earlier one or not.
309 #
310 # Why are there two kinds of tables, match and map?
311 #   (And there is a base class shared by the two as well.)  As stated above,
312 #   they actually are for different things.  Development proceeded much more
313 #   smoothly when I (khw) realized the distinction.  Map tables are used to
314 #   give the property value for every code point (actually every code point
315 #   that doesn't map to a default value).  Match tables are used for regular
316 #   expression matches, and are essentially the inverse mapping.  Separating
317 #   the two allows more specialized methods, and error checks so that one
318 #   can't just take the intersection of two map tables, for example, as that
319 #   is nonsensical.
320 #
321 # What about 'fate' and 'status'.  The concept of a table's fate was created
322 #   late when it became clear that something more was needed.  The difference
323 #   between this and 'status' is unclean, and could be improved if someone
324 #   wanted to spend the effort.
325 #
326 # DEBUGGING
327 #
328 # This program is written so it will run under miniperl.  Occasionally changes
329 # will cause an error where the backtrace doesn't work well under miniperl.
330 # To diagnose the problem, you can instead run it under regular perl, if you
331 # have one compiled.
332 #
333 # There is a good trace facility.  To enable it, first sub DEBUG must be set
334 # to return true.  Then a line like
335 #
336 # local $to_trace = 1 if main::DEBUG;
337 #
338 # can be added to enable tracing in its lexical scope (plus dynamic) or until
339 # you insert another line:
340 #
341 # local $to_trace = 0 if main::DEBUG;
342 #
343 # To actually trace, use a line like "trace $a, @b, %c, ...;
344 #
345 # Some of the more complex subroutines already have trace statements in them.
346 # Permanent trace statements should be like:
347 #
348 # trace ... if main::DEBUG && $to_trace;
349 #
350 # If there is just one or a few files that you're debugging, you can easily
351 # cause most everything else to be skipped.  Change the line
352 #
353 # my $debug_skip = 0;
354 #
355 # to 1, and every file whose object is in @input_file_objects and doesn't have
356 # a, 'non_skip => 1,' in its constructor will be skipped.  However, skipping
357 # Jamo.txt or UnicodeData.txt will likely cause fatal errors.
358 #
359 # To compare the output tables, it may be useful to specify the -annotate
360 # flag.  (As of this writing, this can't be done on a clean workspace, due to
361 # requirements in Text::Tabs used in this option; so first run mktables
362 # without this option.)  This option adds comment lines to each table, one for
363 # each non-algorithmically named character giving, currently its code point,
364 # name, and graphic representation if printable (and you have a font that
365 # knows about it).  This makes it easier to see what the particular code
366 # points are in each output table.  Non-named code points are annotated with a
367 # description of their status, and contiguous ones with the same description
368 # will be output as a range rather than individually.  Algorithmically named
369 # characters are also output as ranges, except when there are just a few
370 # contiguous ones.
371 #
372 # FUTURE ISSUES
373 #
374 # The program would break if Unicode were to change its names so that
375 # interior white space, underscores, or dashes differences were significant
376 # within property and property value names.
377 #
378 # It might be easier to use the xml versions of the UCD if this program ever
379 # would need heavy revision, and the ability to handle old versions was not
380 # required.
381 #
382 # There is the potential for name collisions, in that Perl has chosen names
383 # that Unicode could decide it also likes.  There have been such collisions in
384 # the past, with mostly Perl deciding to adopt the Unicode definition of the
385 # name.  However in the 5.2 Unicode beta testing, there were a number of such
386 # collisions, which were withdrawn before the final release, because of Perl's
387 # and other's protests.  These all involved new properties which began with
388 # 'Is'.  Based on the protests, Unicode is unlikely to try that again.  Also,
389 # many of the Perl-defined synonyms, like Any, Word, etc, are listed in a
390 # Unicode document, so they are unlikely to be used by Unicode for another
391 # purpose.  However, they might try something beginning with 'In', or use any
392 # of the other Perl-defined properties.  This program will warn you of name
393 # collisions, and refuse to generate tables with them, but manual intervention
394 # will be required in this event.  One scheme that could be implemented, if
395 # necessary, would be to have this program generate another file, or add a
396 # field to mktables.lst that gives the date of first definition of a property.
397 # Each new release of Unicode would use that file as a basis for the next
398 # iteration.  And the Perl synonym addition code could sort based on the age
399 # of the property, so older properties get priority, and newer ones that clash
400 # would be refused; hence existing code would not be impacted, and some other
401 # synonym would have to be used for the new property.  This is ugly, and
402 # manual intervention would certainly be easier to do in the short run; lets
403 # hope it never comes to this.
404 #
405 # A NOTE ON UNIHAN
406 #
407 # This program can generate tables from the Unihan database.  But that db
408 # isn't normally available, so it is marked as optional.  Prior to version
409 # 5.2, this database was in a single file, Unihan.txt.  In 5.2 the database
410 # was split into 8 different files, all beginning with the letters 'Unihan'.
411 # If you plunk those files down into the directory mktables ($0) is in, this
412 # program will read them and automatically create tables for the properties
413 # from it that are listed in PropertyAliases.txt and PropValueAliases.txt,
414 # plus any you add to the @cjk_properties array and the @cjk_property_values
415 # array, being sure to add necessary '# @missings' lines to the latter.  For
416 # Unicode versions earlier than 5.2, most of the Unihan properties are not
417 # listed at all in PropertyAliases nor PropValueAliases.  This program assumes
418 # for these early releases that you want the properties that are specified in
419 # the 5.2 release.
420 #
421 # You may need to adjust the entries to suit your purposes.  setup_unihan(),
422 # and filter_unihan_line() are the functions where this is done.  This program
423 # already does some adjusting to make the lines look more like the rest of the
424 # Unicode DB;  You can see what that is in filter_unihan_line()
425 #
426 # There is a bug in the 3.2 data file in which some values for the
427 # kPrimaryNumeric property have commas and an unexpected comment.  A filter
428 # could be added to correct these; or for a particular installation, the
429 # Unihan.txt file could be edited to fix them.
430 #
431 # HOW TO ADD A FILE TO BE PROCESSED
432 #
433 # A new file from Unicode needs to have an object constructed for it in
434 # @input_file_objects, probably at the end or at the end of the extracted
435 # ones.  The program should warn you if its name will clash with others on
436 # restrictive file systems, like DOS.  If so, figure out a better name, and
437 # add lines to the README.perl file giving that.  If the file is a character
438 # property, it should be in the format that Unicode has implicitly
439 # standardized for such files for the more recently introduced ones.
440 # If so, the Input_file constructor for @input_file_objects can just be the
441 # file name and release it first appeared in.  If not, then it should be
442 # possible to construct an each_line_handler() to massage the line into the
443 # standardized form.
444 #
445 # For non-character properties, more code will be needed.  You can look at
446 # the existing entries for clues.
447 #
448 # UNICODE VERSIONS NOTES
449 #
450 # The Unicode UCD has had a number of errors in it over the versions.  And
451 # these remain, by policy, in the standard for that version.  Therefore it is
452 # risky to correct them, because code may be expecting the error.  So this
453 # program doesn't generally make changes, unless the error breaks the Perl
454 # core.  As an example, some versions of 2.1.x Jamo.txt have the wrong value
455 # for U+1105, which causes real problems for the algorithms for Jamo
456 # calculations, so it is changed here.
457 #
458 # But it isn't so clear cut as to what to do about concepts that are
459 # introduced in a later release; should they extend back to earlier releases
460 # where the concept just didn't exist?  It was easier to do this than to not,
461 # so that's what was done.  For example, the default value for code points not
462 # in the files for various properties was probably undefined until changed by
463 # some version.  No_Block for blocks is such an example.  This program will
464 # assign No_Block even in Unicode versions that didn't have it.  This has the
465 # benefit that code being written doesn't have to special case earlier
466 # versions; and the detriment that it doesn't match the Standard precisely for
467 # the affected versions.
468 #
469 # Here are some observations about some of the issues in early versions:
470 #
471 # Prior to version 3.0, there were 3 character decompositions.  These are not
472 # handled by Unicode::Normalize, nor will it compile when presented a version
473 # that has them.  However, you can trivially get it to compile by simply
474 # ignoring those decompositions, by changing the croak to a carp.  At the time
475 # of this writing, the line (in cpan/Unicode-Normalize/Normalize.pm or
476 # cpan/Unicode-Normalize/mkheader) reads
477 #
478 #   croak("Weird Canonical Decomposition of U+$h");
479 #
480 # Simply comment it out.  It will compile, but will not know about any three
481 # character decompositions.
482
483 # The number of code points in \p{alpha=True} halved in 2.1.9.  It turns out
484 # that the reason is that the CJK block starting at 4E00 was removed from
485 # PropList, and was not put back in until 3.1.0.  The Perl extension (the
486 # single property name \p{alpha}) has the correct values.  But the compound
487 # form is simply not generated until 3.1, as it can be argued that prior to
488 # this release, this was not an official property.  The comments for
489 # filter_old_style_proplist() give more details.
490 #
491 # Unicode introduced the synonym Space for White_Space in 4.1.  Perl has
492 # always had a \p{Space}.  In release 3.2 only, they are not synonymous.  The
493 # reason is that 3.2 introduced U+205F=medium math space, which was not
494 # classed as white space, but Perl figured out that it should have been. 4.0
495 # reclassified it correctly.
496 #
497 # Another change between 3.2 and 4.0 is the CCC property value ATBL.  In 3.2
498 # this was erroneously a synonym for 202 (it should be 200).  In 4.0, ATB
499 # became 202, and ATBL was left with no code points, as all the ones that
500 # mapped to 202 stayed mapped to 202.  Thus if your program used the numeric
501 # name for the class, it would not have been affected, but if it used the
502 # mnemonic, it would have been.
503 #
504 # \p{Script=Hrkt} (Katakana_Or_Hiragana) came in 4.0.1.  Before that, code
505 # points which eventually came to have this script property value, instead
506 # mapped to "Unknown".  But in the next release all these code points were
507 # moved to \p{sc=common} instead.
508
509 # The tests furnished  by Unicode for testing WordBreak and SentenceBreak
510 # generate errors in 5.0 and earlier.
511 #
512 # The default for missing code points for BidiClass is complicated.  Starting
513 # in 3.1.1, the derived file DBidiClass.txt handles this, but this program
514 # tries to do the best it can for earlier releases.  It is done in
515 # process_PropertyAliases()
516 #
517 # In version 2.1.2, the entry in UnicodeData.txt:
518 #   0275;LATIN SMALL LETTER BARRED O;Ll;0;L;;;;;N;;;;019F;
519 # should instead be
520 #   0275;LATIN SMALL LETTER BARRED O;Ll;0;L;;;;;N;;;019F;;019F
521 # Without this change, there are casing problems for this character.
522 #
523 # Search for $string_compare_versions to see how to compare changes to
524 # properties between Unicode versions
525 #
526 ##############################################################################
527
528 my $UNDEF = ':UNDEF:';  # String to print out for undefined values in tracing
529                         # and errors
530 my $MAX_LINE_WIDTH = 78;
531
532 # Debugging aid to skip most files so as to not be distracted by them when
533 # concentrating on the ones being debugged.  Add
534 # non_skip => 1,
535 # to the constructor for those files you want processed when you set this.
536 # Files with a first version number of 0 are special: they are always
537 # processed regardless of the state of this flag.  Generally, Jamo.txt and
538 # UnicodeData.txt must not be skipped if you want this program to not die
539 # before normal completion.
540 my $debug_skip = 0;
541
542
543 # Normally these are suppressed.
544 my $write_Unicode_deprecated_tables = 0;
545
546 # Set to 1 to enable tracing.
547 our $to_trace = 0;
548
549 { # Closure for trace: debugging aid
550     my $print_caller = 1;        # ? Include calling subroutine name
551     my $main_with_colon = 'main::';
552     my $main_colon_length = length($main_with_colon);
553
554     sub trace {
555         return unless $to_trace;        # Do nothing if global flag not set
556
557         my @input = @_;
558
559         local $DB::trace = 0;
560         $DB::trace = 0;          # Quiet 'used only once' message
561
562         my $line_number;
563
564         # Loop looking up the stack to get the first non-trace caller
565         my $caller_line;
566         my $caller_name;
567         my $i = 0;
568         do {
569             $line_number = $caller_line;
570             (my $pkg, my $file, $caller_line, my $caller) = caller $i++;
571             $caller = $main_with_colon unless defined $caller;
572
573             $caller_name = $caller;
574
575             # get rid of pkg
576             $caller_name =~ s/.*:://;
577             if (substr($caller_name, 0, $main_colon_length)
578                 eq $main_with_colon)
579             {
580                 $caller_name = substr($caller_name, $main_colon_length);
581             }
582
583         } until ($caller_name ne 'trace');
584
585         # If the stack was empty, we were called from the top level
586         $caller_name = 'main' if ($caller_name eq ""
587                                     || $caller_name eq 'trace');
588
589         my $output = "";
590         #print STDERR __LINE__, ": ", join ", ", @input, "\n";
591         foreach my $string (@input) {
592             if (ref $string eq 'ARRAY' || ref $string eq 'HASH') {
593                 $output .= simple_dumper($string);
594             }
595             else {
596                 $string = "$string" if ref $string;
597                 $string = $UNDEF unless defined $string;
598                 chomp $string;
599                 $string = '""' if $string eq "";
600                 $output .= " " if $output ne ""
601                                 && $string ne ""
602                                 && substr($output, -1, 1) ne " "
603                                 && substr($string, 0, 1) ne " ";
604                 $output .= $string;
605             }
606         }
607
608         print STDERR sprintf "%4d: ", $line_number if defined $line_number;
609         print STDERR "$caller_name: " if $print_caller;
610         print STDERR $output, "\n";
611         return;
612     }
613 }
614
615 # This is for a rarely used development feature that allows you to compare two
616 # versions of the Unicode standard without having to deal with changes caused
617 # by the code points introduced in the later version.  You probably also want
618 # to use the -annotate option when using this.  Change the 0 to a string
619 # containing a SINGLE dotted Unicode release number (e.g. "2.1").  Only code
620 # points introduced in that release and earlier will be used; later ones are
621 # thrown away.  You use the version number of the earliest one you want to
622 # compare; then run this program on directory structures containing each
623 # release, and compare the outputs.  These outputs will therefore include only
624 # the code points common to both releases, and you can see the changes caused
625 # just by the underlying release semantic changes.  For versions earlier than
626 # 3.2, you must copy a version of DAge.txt into the directory.
627 my $string_compare_versions = DEBUG && 0; #  e.g., "2.1";
628 my $compare_versions = DEBUG
629                        && $string_compare_versions
630                        && pack "C*", split /\./, $string_compare_versions;
631
632 sub uniques {
633     # Returns non-duplicated input values.  From "Perl Best Practices:
634     # Encapsulated Cleverness".  p. 455 in first edition.
635
636     my %seen;
637     # Arguably this breaks encapsulation, if the goal is to permit multiple
638     # distinct objects to stringify to the same value, and be interchangeable.
639     # However, for this program, no two objects stringify identically, and all
640     # lists passed to this function are either objects or strings. So this
641     # doesn't affect correctness, but it does give a couple of percent speedup.
642     no overloading;
643     return grep { ! $seen{$_}++ } @_;
644 }
645
646 $0 = File::Spec->canonpath($0);
647
648 my $make_test_script = 0;      # ? Should we output a test script
649 my $make_norm_test_script = 0; # ? Should we output a normalization test script
650 my $write_unchanged_files = 0; # ? Should we update the output files even if
651                                #    we don't think they have changed
652 my $use_directory = "";        # ? Should we chdir somewhere.
653 my $pod_directory;             # input directory to store the pod file.
654 my $pod_file = 'perluniprops';
655 my $t_path;                     # Path to the .t test file
656 my $file_list = 'mktables.lst'; # File to store input and output file names.
657                                # This is used to speed up the build, by not
658                                # executing the main body of the program if
659                                # nothing on the list has changed since the
660                                # previous build
661 my $make_list = 1;             # ? Should we write $file_list.  Set to always
662                                # make a list so that when the pumpking is
663                                # preparing a release, s/he won't have to do
664                                # special things
665 my $glob_list = 0;             # ? Should we try to include unknown .txt files
666                                # in the input.
667 my $output_range_counts = $debugging_build;   # ? Should we include the number
668                                               # of code points in ranges in
669                                               # the output
670 my $annotate = 0;              # ? Should character names be in the output
671
672 # Verbosity levels; 0 is quiet
673 my $NORMAL_VERBOSITY = 1;
674 my $PROGRESS = 2;
675 my $VERBOSE = 3;
676
677 my $verbosity = $NORMAL_VERBOSITY;
678
679 # Stored in mktables.lst so that if this program is called with different
680 # options, will regenerate even if the files otherwise look like they're
681 # up-to-date.
682 my $command_line_arguments = join " ", @ARGV;
683
684 # Process arguments
685 while (@ARGV) {
686     my $arg = shift @ARGV;
687     if ($arg eq '-v') {
688         $verbosity = $VERBOSE;
689     }
690     elsif ($arg eq '-p') {
691         $verbosity = $PROGRESS;
692         $| = 1;     # Flush buffers as we go.
693     }
694     elsif ($arg eq '-q') {
695         $verbosity = 0;
696     }
697     elsif ($arg eq '-w') {
698         $write_unchanged_files = 1; # update the files even if havent changed
699     }
700     elsif ($arg eq '-check') {
701         my $this = shift @ARGV;
702         my $ok = shift @ARGV;
703         if ($this ne $ok) {
704             print "Skipping as check params are not the same.\n";
705             exit(0);
706         }
707     }
708     elsif ($arg eq '-P' && defined ($pod_directory = shift)) {
709         -d $pod_directory or croak "Directory '$pod_directory' doesn't exist";
710     }
711     elsif ($arg eq '-maketest' || ($arg eq '-T' && defined ($t_path = shift)))
712     {
713         $make_test_script = 1;
714     }
715     elsif ($arg eq '-makenormtest')
716     {
717         $make_norm_test_script = 1;
718     }
719     elsif ($arg eq '-makelist') {
720         $make_list = 1;
721     }
722     elsif ($arg eq '-C' && defined ($use_directory = shift)) {
723         -d $use_directory or croak "Unknown directory '$use_directory'";
724     }
725     elsif ($arg eq '-L') {
726
727         # Existence not tested until have chdir'd
728         $file_list = shift;
729     }
730     elsif ($arg eq '-globlist') {
731         $glob_list = 1;
732     }
733     elsif ($arg eq '-c') {
734         $output_range_counts = ! $output_range_counts
735     }
736     elsif ($arg eq '-annotate') {
737         $annotate = 1;
738         $debugging_build = 1;
739         $output_range_counts = 1;
740     }
741     else {
742         my $with_c = 'with';
743         $with_c .= 'out' if $output_range_counts;   # Complements the state
744         croak <<END;
745 usage: $0 [-c|-p|-q|-v|-w] [-C dir] [-L filelist] [ -P pod_dir ]
746           [ -T test_file_path ] [-globlist] [-makelist] [-maketest]
747           [-check A B ]
748   -c          : Output comments $with_c number of code points in ranges
749   -q          : Quiet Mode: Only output serious warnings.
750   -p          : Set verbosity level to normal plus show progress.
751   -v          : Set Verbosity level high:  Show progress and non-serious
752                 warnings
753   -w          : Write files regardless
754   -C dir      : Change to this directory before proceeding. All relative paths
755                 except those specified by the -P and -T options will be done
756                 with respect to this directory.
757   -P dir      : Output $pod_file file to directory 'dir'.
758   -T path     : Create a test script as 'path'; overrides -maketest
759   -L filelist : Use alternate 'filelist' instead of standard one
760   -globlist   : Take as input all non-Test *.txt files in current and sub
761                 directories
762   -maketest   : Make test script 'TestProp.pl' in current (or -C directory),
763                 overrides -T
764   -makelist   : Rewrite the file list $file_list based on current setup
765   -annotate   : Output an annotation for each character in the table files;
766                 useful for debugging mktables, looking at diffs; but is slow
767                 and memory intensive
768   -check A B  : Executes $0 only if A and B are the same
769 END
770     }
771 }
772
773 # Stores the most-recently changed file.  If none have changed, can skip the
774 # build
775 my $most_recent = (stat $0)[9];   # Do this before the chdir!
776
777 # Change directories now, because need to read 'version' early.
778 if ($use_directory) {
779     if ($pod_directory && ! File::Spec->file_name_is_absolute($pod_directory)) {
780         $pod_directory = File::Spec->rel2abs($pod_directory);
781     }
782     if ($t_path && ! File::Spec->file_name_is_absolute($t_path)) {
783         $t_path = File::Spec->rel2abs($t_path);
784     }
785     chdir $use_directory or croak "Failed to chdir to '$use_directory':$!";
786     if ($pod_directory && File::Spec->file_name_is_absolute($pod_directory)) {
787         $pod_directory = File::Spec->abs2rel($pod_directory);
788     }
789     if ($t_path && File::Spec->file_name_is_absolute($t_path)) {
790         $t_path = File::Spec->abs2rel($t_path);
791     }
792 }
793
794 # Get Unicode version into regular and v-string.  This is done now because
795 # various tables below get populated based on it.  These tables are populated
796 # here to be near the top of the file, and so easily seeable by those needing
797 # to modify things.
798 open my $VERSION, "<", "version"
799                     or croak "$0: can't open required file 'version': $!\n";
800 my $string_version = <$VERSION>;
801 close $VERSION;
802 chomp $string_version;
803 my $v_version = pack "C*", split /\./, $string_version;        # v string
804
805 # The following are the complete names of properties with property values that
806 # are known to not match any code points in some versions of Unicode, but that
807 # may change in the future so they should be matchable, hence an empty file is
808 # generated for them.
809 my @tables_that_may_be_empty;
810 push @tables_that_may_be_empty, 'Joining_Type=Left_Joining'
811                                                     if $v_version lt v6.3.0;
812 push @tables_that_may_be_empty, 'Script=Common' if $v_version le v4.0.1;
813 push @tables_that_may_be_empty, 'Title' if $v_version lt v2.0.0;
814 push @tables_that_may_be_empty, 'Script=Katakana_Or_Hiragana'
815                                                     if $v_version ge v4.1.0;
816 push @tables_that_may_be_empty, 'Script_Extensions=Katakana_Or_Hiragana'
817                                                     if $v_version ge v6.0.0;
818 push @tables_that_may_be_empty, 'Grapheme_Cluster_Break=Prepend'
819                                                     if $v_version ge v6.1.0;
820 push @tables_that_may_be_empty, 'Canonical_Combining_Class=CCC133'
821                                                     if $v_version ge v6.2.0;
822
823 # The lists below are hashes, so the key is the item in the list, and the
824 # value is the reason why it is in the list.  This makes generation of
825 # documentation easier.
826
827 my %why_suppressed;  # No file generated for these.
828
829 # Files aren't generated for empty extraneous properties.  This is arguable.
830 # Extraneous properties generally come about because a property is no longer
831 # used in a newer version of Unicode.  If we generated a file without code
832 # points, programs that used to work on that property will still execute
833 # without errors.  It just won't ever match (or will always match, with \P{}).
834 # This means that the logic is now likely wrong.  I (khw) think its better to
835 # find this out by getting an error message.  Just move them to the table
836 # above to change this behavior
837 my %why_suppress_if_empty_warn_if_not = (
838
839    # It is the only property that has ever officially been removed from the
840    # Standard.  The database never contained any code points for it.
841    'Special_Case_Condition' => 'Obsolete',
842
843    # Apparently never official, but there were code points in some versions of
844    # old-style PropList.txt
845    'Non_Break' => 'Obsolete',
846 );
847
848 # These would normally go in the warn table just above, but they were changed
849 # a long time before this program was written, so warnings about them are
850 # moot.
851 if ($v_version gt v3.2.0) {
852     push @tables_that_may_be_empty,
853                                 'Canonical_Combining_Class=Attached_Below_Left'
854 }
855
856 # Enum values for to_output_map() method in the Map_Table package. (0 is don't
857 # output)
858 my $EXTERNAL_MAP = 1;
859 my $INTERNAL_MAP = 2;
860 my $OUTPUT_ADJUSTED = 3;
861
862 # To override computed values for writing the map tables for these properties.
863 # The default for enum map tables is to write them out, so that the Unicode
864 # .txt files can be removed, but all the data to compute any property value
865 # for any code point is available in a more compact form.
866 my %global_to_output_map = (
867     # Needed by UCD.pm, but don't want to publicize that it exists, so won't
868     # get stuck supporting it if things change.  Since it is a STRING
869     # property, it normally would be listed in the pod, but INTERNAL_MAP
870     # suppresses that.
871     Unicode_1_Name => $INTERNAL_MAP,
872
873     Present_In => 0,                # Suppress, as easily computed from Age
874     Block => (NON_ASCII_PLATFORM) ? 1 : 0,  # Suppress, as Blocks.txt is
875                                             # retained, but needed for
876                                             # non-ASCII
877
878     # Suppress, as mapping can be found instead from the
879     # Perl_Decomposition_Mapping file
880     Decomposition_Type => 0,
881 );
882
883 # There are several types of obsolete properties defined by Unicode.  These
884 # must be hand-edited for every new Unicode release.
885 my %why_deprecated;  # Generates a deprecated warning message if used.
886 my %why_stabilized;  # Documentation only
887 my %why_obsolete;    # Documentation only
888
889 {   # Closure
890     my $simple = 'Perl uses the more complete version';
891     my $unihan = 'Unihan properties are by default not enabled in the Perl core.  Instead use CPAN: Unicode::Unihan';
892
893     my $other_properties = 'other properties';
894     my $contributory = "Used by Unicode internally for generating $other_properties and not intended to be used stand-alone";
895     my $why_no_expand  = "Deprecated by Unicode.  These are characters that expand to more than one character in the specified normalization form, but whether they actually take up more bytes or not depends on the encoding being used.  For example, a UTF-8 encoded character may expand to a different number of bytes than a UTF-32 encoded character.";
896
897     %why_deprecated = (
898         'Grapheme_Link' => 'Deprecated by Unicode:  Duplicates ccc=vr (Canonical_Combining_Class=Virama)',
899         'Jamo_Short_Name' => $contributory,
900         'Line_Break=Surrogate' => 'Deprecated by Unicode because surrogates should never appear in well-formed text, and therefore shouldn\'t be the basis for line breaking',
901         'Other_Alphabetic' => $contributory,
902         'Other_Default_Ignorable_Code_Point' => $contributory,
903         'Other_Grapheme_Extend' => $contributory,
904         'Other_ID_Continue' => $contributory,
905         'Other_ID_Start' => $contributory,
906         'Other_Lowercase' => $contributory,
907         'Other_Math' => $contributory,
908         'Other_Uppercase' => $contributory,
909         'Expands_On_NFC' => $why_no_expand,
910         'Expands_On_NFD' => $why_no_expand,
911         'Expands_On_NFKC' => $why_no_expand,
912         'Expands_On_NFKD' => $why_no_expand,
913     );
914
915     %why_suppressed = (
916         # There is a lib/unicore/Decomposition.pl (used by Normalize.pm) which
917         # contains the same information, but without the algorithmically
918         # determinable Hangul syllables'.  This file is not published, so it's
919         # existence is not noted in the comment.
920         'Decomposition_Mapping' => 'Accessible via Unicode::Normalize or prop_invmap() or charprop() in Unicode::UCD::',
921
922         # Don't suppress ISO_Comment, as otherwise special handling is needed
923         # to differentiate between it and gc=c, which can be written as 'isc',
924         # which is the same characters as ISO_Comment's short name.
925
926         'Name' => "Accessible via \\N{...} or 'use charnames;' or charprop() or prop_invmap() in Unicode::UCD::",
927
928         'Simple_Case_Folding' => "$simple.  Can access this through casefold(), charprop(), or prop_invmap() in Unicode::UCD",
929         'Simple_Lowercase_Mapping' => "$simple.  Can access this through charinfo(), charprop(), or prop_invmap() in Unicode::UCD",
930         'Simple_Titlecase_Mapping' => "$simple.  Can access this through charinfo(), charprop(), or prop_invmap() in Unicode::UCD",
931         'Simple_Uppercase_Mapping' => "$simple.  Can access this through charinfo(), charprop(), or prop_invmap() in Unicode::UCD",
932
933         FC_NFKC_Closure => 'Deprecated by Unicode, and supplanted in usage by NFKC_Casefold; otherwise not useful',
934     );
935
936     foreach my $property (
937
938             # The following are suppressed because they were made contributory
939             # or deprecated by Unicode before Perl ever thought about
940             # supporting them.
941             'Jamo_Short_Name',
942             'Grapheme_Link',
943             'Expands_On_NFC',
944             'Expands_On_NFD',
945             'Expands_On_NFKC',
946             'Expands_On_NFKD',
947
948             # The following are suppressed because they have been marked
949             # as deprecated for a sufficient amount of time
950             'Other_Alphabetic',
951             'Other_Default_Ignorable_Code_Point',
952             'Other_Grapheme_Extend',
953             'Other_ID_Continue',
954             'Other_ID_Start',
955             'Other_Lowercase',
956             'Other_Math',
957             'Other_Uppercase',
958     ) {
959         $why_suppressed{$property} = $why_deprecated{$property};
960     }
961
962     # Customize the message for all the 'Other_' properties
963     foreach my $property (keys %why_deprecated) {
964         next if (my $main_property = $property) !~ s/^Other_//;
965         $why_deprecated{$property} =~ s/$other_properties/the $main_property property (which should be used instead)/;
966     }
967 }
968
969 if ($write_Unicode_deprecated_tables) {
970     foreach my $property (keys %why_suppressed) {
971         delete $why_suppressed{$property} if $property =~
972                                                     / ^ Other | Grapheme /x;
973     }
974 }
975
976 if ($v_version ge 4.0.0) {
977     $why_stabilized{'Hyphen'} = 'Use the Line_Break property instead; see www.unicode.org/reports/tr14';
978     if ($v_version ge 6.0.0) {
979         $why_deprecated{'Hyphen'} = 'Supplanted by Line_Break property values; see www.unicode.org/reports/tr14';
980     }
981 }
982 if ($v_version ge 5.2.0 && $v_version lt 6.0.0) {
983     $why_obsolete{'ISO_Comment'} = 'Code points for it have been removed';
984     if ($v_version ge 6.0.0) {
985         $why_deprecated{'ISO_Comment'} = 'No longer needed for Unicode\'s internal chart generation; otherwise not useful, and code points for it have been removed';
986     }
987 }
988
989 # Probably obsolete forever
990 if ($v_version ge v4.1.0) {
991     $why_suppressed{'Script=Katakana_Or_Hiragana'} = 'Obsolete.  All code points previously matched by this have been moved to "Script=Common".';
992 }
993 if ($v_version ge v6.0.0) {
994     $why_suppressed{'Script=Katakana_Or_Hiragana'} .= '  Consider instead using "Script_Extensions=Katakana" or "Script_Extensions=Hiragana" (or both)';
995     $why_suppressed{'Script_Extensions=Katakana_Or_Hiragana'} = 'All code points that would be matched by this are matched by either "Script_Extensions=Katakana" or "Script_Extensions=Hiragana"';
996 }
997
998 # This program can create files for enumerated-like properties, such as
999 # 'Numeric_Type'.  This file would be the same format as for a string
1000 # property, with a mapping from code point to its value, so you could look up,
1001 # for example, the script a code point is in.  But no one so far wants this
1002 # mapping, or they have found another way to get it since this is a new
1003 # feature.  So no file is generated except if it is in this list.
1004 my @output_mapped_properties = split "\n", <<END;
1005 END
1006
1007 # If you want more Unihan properties than the default, you need to add them to
1008 # these arrays.  Depending on the property type, @missing lines might have to
1009 # be added to the second array.  A sample entry would be (including the '#'):
1010 # @missing: 0000..10FFFF; cjkAccountingNumeric; NaN
1011 my @cjk_properties = split "\n", <<'END';
1012 END
1013 my @cjk_property_values = split "\n", <<'END';
1014 END
1015
1016 # The input files don't list every code point.  Those not listed are to be
1017 # defaulted to some value.  Below are hard-coded what those values are for
1018 # non-binary properties as of 5.1.  Starting in 5.0, there are
1019 # machine-parsable comment lines in the files that give the defaults; so this
1020 # list shouldn't have to be extended.  The claim is that all missing entries
1021 # for binary properties will default to 'N'.  Unicode tried to change that in
1022 # 5.2, but the beta period produced enough protest that they backed off.
1023 #
1024 # The defaults for the fields that appear in UnicodeData.txt in this hash must
1025 # be in the form that it expects.  The others may be synonyms.
1026 my $CODE_POINT = '<code point>';
1027 my %default_mapping = (
1028     Age => "Unassigned",
1029     # Bidi_Class => Complicated; set in code
1030     Bidi_Mirroring_Glyph => "",
1031     Block => 'No_Block',
1032     Canonical_Combining_Class => 0,
1033     Case_Folding => $CODE_POINT,
1034     Decomposition_Mapping => $CODE_POINT,
1035     Decomposition_Type => 'None',
1036     East_Asian_Width => "Neutral",
1037     FC_NFKC_Closure => $CODE_POINT,
1038     General_Category => ($v_version le 6.3.0) ? 'Cn' : 'Unassigned',
1039     Grapheme_Cluster_Break => 'Other',
1040     Hangul_Syllable_Type => 'NA',
1041     ISO_Comment => "",
1042     Jamo_Short_Name => "",
1043     Joining_Group => "No_Joining_Group",
1044     # Joining_Type => Complicated; set in code
1045     kIICore => 'N',   #                       Is converted to binary
1046     #Line_Break => Complicated; set in code
1047     Lowercase_Mapping => $CODE_POINT,
1048     Name => "",
1049     Name_Alias => "",
1050     NFC_QC => 'Yes',
1051     NFD_QC => 'Yes',
1052     NFKC_QC => 'Yes',
1053     NFKD_QC => 'Yes',
1054     Numeric_Type => 'None',
1055     Numeric_Value => 'NaN',
1056     Script => ($v_version le 4.1.0) ? 'Common' : 'Unknown',
1057     Sentence_Break => 'Other',
1058     Simple_Case_Folding => $CODE_POINT,
1059     Simple_Lowercase_Mapping => $CODE_POINT,
1060     Simple_Titlecase_Mapping => $CODE_POINT,
1061     Simple_Uppercase_Mapping => $CODE_POINT,
1062     Titlecase_Mapping => $CODE_POINT,
1063     Unicode_1_Name => "",
1064     Unicode_Radical_Stroke => "",
1065     Uppercase_Mapping => $CODE_POINT,
1066     Word_Break => 'Other',
1067 );
1068
1069 ### End of externally interesting definitions, except for @input_file_objects
1070
1071 my $HEADER=<<"EOF";
1072 # !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
1073 # This file is machine-generated by $0 from the Unicode
1074 # database, Version $string_version.  Any changes made here will be lost!
1075 EOF
1076
1077 my $INTERNAL_ONLY_HEADER = <<"EOF";
1078
1079 # !!!!!!!   INTERNAL PERL USE ONLY   !!!!!!!
1080 # This file is for internal use by core Perl only.  The format and even the
1081 # name or existence of this file are subject to change without notice.  Don't
1082 # use it directly.  Use Unicode::UCD to access the Unicode character data
1083 # base.
1084 EOF
1085
1086 my $DEVELOPMENT_ONLY=<<"EOF";
1087 # !!!!!!!   DEVELOPMENT USE ONLY   !!!!!!!
1088 # This file contains information artificially constrained to code points
1089 # present in Unicode release $string_compare_versions.
1090 # IT CANNOT BE RELIED ON.  It is for use during development only and should
1091 # not be used for production.
1092
1093 EOF
1094
1095 my $MAX_UNICODE_CODEPOINT_STRING = ($v_version ge v2.0.0)
1096                                    ? "10FFFF"
1097                                    : "FFFF";
1098 my $MAX_UNICODE_CODEPOINT = hex $MAX_UNICODE_CODEPOINT_STRING;
1099 my $MAX_UNICODE_CODEPOINTS = $MAX_UNICODE_CODEPOINT + 1;
1100
1101 # We work with above-Unicode code points, up to UV_MAX.   But when you get
1102 # that high, above IV_MAX, some operations don't work, and you can easily get
1103 # overflow.  Therefore for internal use, we use a much smaller number,
1104 # translating it to UV_MAX only for output.  The exact number is immaterial
1105 # (all Unicode code points are treated exactly the same), but the algorithm
1106 # requires it to be at least 2 * $MAX_UNICODE_CODEPOINTS + 1;
1107 my $MAX_WORKING_CODEPOINTS= $MAX_UNICODE_CODEPOINT * 8;
1108 my $MAX_WORKING_CODEPOINT = $MAX_WORKING_CODEPOINTS - 1;
1109 my $MAX_WORKING_CODEPOINT_STRING = sprintf("%X", $MAX_WORKING_CODEPOINT);
1110
1111 my $MAX_PLATFORM_CODEPOINT = ~0;
1112
1113 # Matches legal code point.  4-6 hex numbers, If there are 6, the first
1114 # two must be 10; if there are 5, the first must not be a 0.  Written this way
1115 # to decrease backtracking.  The first regex allows the code point to be at
1116 # the end of a word, but to work properly, the word shouldn't end with a valid
1117 # hex character.  The second one won't match a code point at the end of a
1118 # word, and doesn't have the run-on issue
1119 my $run_on_code_point_re =
1120             qr/ (?: 10[0-9A-F]{4} | [1-9A-F][0-9A-F]{4} | [0-9A-F]{4} ) \b/x;
1121 my $code_point_re = qr/\b$run_on_code_point_re/;
1122
1123 # This matches the beginning of the line in the Unicode db files that give the
1124 # defaults for code points not listed (i.e., missing) in the file.  The code
1125 # depends on this ending with a semi-colon, so it can assume it is a valid
1126 # field when the line is split() by semi-colons
1127 my $missing_defaults_prefix = qr/^#\s+\@missing:\s+0000\.\.10FFFF\s*;/;
1128
1129 # Property types.  Unicode has more types, but these are sufficient for our
1130 # purposes.
1131 my $UNKNOWN = -1;   # initialized to illegal value
1132 my $NON_STRING = 1; # Either binary or enum
1133 my $BINARY = 2;
1134 my $FORCED_BINARY = 3; # Not a binary property, but, besides its normal
1135                        # tables, additional true and false tables are
1136                        # generated so that false is anything matching the
1137                        # default value, and true is everything else.
1138 my $ENUM = 4;       # Include catalog
1139 my $STRING = 5;     # Anything else: string or misc
1140
1141 # Some input files have lines that give default values for code points not
1142 # contained in the file.  Sometimes these should be ignored.
1143 my $NO_DEFAULTS = 0;        # Must evaluate to false
1144 my $NOT_IGNORED = 1;
1145 my $IGNORED = 2;
1146
1147 # Range types.  Each range has a type.  Most ranges are type 0, for normal,
1148 # and will appear in the main body of the tables in the output files, but
1149 # there are other types of ranges as well, listed below, that are specially
1150 # handled.   There are pseudo-types as well that will never be stored as a
1151 # type, but will affect the calculation of the type.
1152
1153 # 0 is for normal, non-specials
1154 my $MULTI_CP = 1;           # Sequence of more than code point
1155 my $HANGUL_SYLLABLE = 2;
1156 my $CP_IN_NAME = 3;         # The NAME contains the code point appended to it.
1157 my $NULL = 4;               # The map is to the null string; utf8.c can't
1158                             # handle these, nor is there an accepted syntax
1159                             # for them in \p{} constructs
1160 my $COMPUTE_NO_MULTI_CP = 5; # Pseudo-type; means that ranges that would
1161                              # otherwise be $MULTI_CP type are instead type 0
1162
1163 # process_generic_property_file() can accept certain overrides in its input.
1164 # Each of these must begin AND end with $CMD_DELIM.
1165 my $CMD_DELIM = "\a";
1166 my $REPLACE_CMD = 'replace';    # Override the Replace
1167 my $MAP_TYPE_CMD = 'map_type';  # Override the Type
1168
1169 my $NO = 0;
1170 my $YES = 1;
1171
1172 # Values for the Replace argument to add_range.
1173 # $NO                      # Don't replace; add only the code points not
1174                            # already present.
1175 my $IF_NOT_EQUIVALENT = 1; # Replace only under certain conditions; details in
1176                            # the comments at the subroutine definition.
1177 my $UNCONDITIONALLY = 2;   # Replace without conditions.
1178 my $MULTIPLE_BEFORE = 4;   # Don't replace, but add a duplicate record if
1179                            # already there
1180 my $MULTIPLE_AFTER = 5;    # Don't replace, but add a duplicate record if
1181                            # already there
1182 my $CROAK = 6;             # Die with an error if is already there
1183
1184 # Flags to give property statuses.  The phrases are to remind maintainers that
1185 # if the flag is changed, the indefinite article referring to it in the
1186 # documentation may need to be as well.
1187 my $NORMAL = "";
1188 my $DEPRECATED = 'D';
1189 my $a_bold_deprecated = "a 'B<$DEPRECATED>'";
1190 my $A_bold_deprecated = "A 'B<$DEPRECATED>'";
1191 my $DISCOURAGED = 'X';
1192 my $a_bold_discouraged = "an 'B<$DISCOURAGED>'";
1193 my $A_bold_discouraged = "An 'B<$DISCOURAGED>'";
1194 my $STRICTER = 'T';
1195 my $a_bold_stricter = "a 'B<$STRICTER>'";
1196 my $A_bold_stricter = "A 'B<$STRICTER>'";
1197 my $STABILIZED = 'S';
1198 my $a_bold_stabilized = "an 'B<$STABILIZED>'";
1199 my $A_bold_stabilized = "An 'B<$STABILIZED>'";
1200 my $OBSOLETE = 'O';
1201 my $a_bold_obsolete = "an 'B<$OBSOLETE>'";
1202 my $A_bold_obsolete = "An 'B<$OBSOLETE>'";
1203
1204 # Aliases can also have an extra status:
1205 my $INTERNAL_ALIAS = 'P';
1206
1207 my %status_past_participles = (
1208     $DISCOURAGED => 'discouraged',
1209     $STABILIZED => 'stabilized',
1210     $OBSOLETE => 'obsolete',
1211     $DEPRECATED => 'deprecated',
1212     $INTERNAL_ALIAS => 'reserved for Perl core internal use only',
1213 );
1214
1215 # Table fates.  These are somewhat ordered, so that fates < $MAP_PROXIED should be
1216 # externally documented.
1217 my $ORDINARY = 0;       # The normal fate.
1218 my $MAP_PROXIED = 1;    # The map table for the property isn't written out,
1219                         # but there is a file written that can be used to
1220                         # reconstruct this table
1221 my $INTERNAL_ONLY = 2;  # The file for this table is written out, but it is
1222                         # for Perl's internal use only
1223 my $LEGACY_ONLY = 3;    # Like $INTERNAL_ONLY, but not actually used by Perl.
1224                         # Is for backwards compatibility for applications that
1225                         # read the file directly, so it's format is
1226                         # unchangeable.
1227 my $SUPPRESSED = 4;     # The file for this table is not written out, and as a
1228                         # result, we don't bother to do many computations on
1229                         # it.
1230 my $PLACEHOLDER = 5;    # Like $SUPPRESSED, but we go through all the
1231                         # computations anyway, as the values are needed for
1232                         # things to work.  This happens when we have Perl
1233                         # extensions that depend on Unicode tables that
1234                         # wouldn't normally be in a given Unicode version.
1235
1236 # The format of the values of the tables:
1237 my $EMPTY_FORMAT = "";
1238 my $BINARY_FORMAT = 'b';
1239 my $DECIMAL_FORMAT = 'd';
1240 my $FLOAT_FORMAT = 'f';
1241 my $INTEGER_FORMAT = 'i';
1242 my $HEX_FORMAT = 'x';
1243 my $RATIONAL_FORMAT = 'r';
1244 my $STRING_FORMAT = 's';
1245 my $ADJUST_FORMAT = 'a';
1246 my $HEX_ADJUST_FORMAT = 'ax';
1247 my $DECOMP_STRING_FORMAT = 'c';
1248 my $STRING_WHITE_SPACE_LIST = 'sw';
1249
1250 my %map_table_formats = (
1251     $BINARY_FORMAT => 'binary',
1252     $DECIMAL_FORMAT => 'single decimal digit',
1253     $FLOAT_FORMAT => 'floating point number',
1254     $INTEGER_FORMAT => 'integer',
1255     $HEX_FORMAT => 'non-negative hex whole number; a code point',
1256     $RATIONAL_FORMAT => 'rational: an integer or a fraction',
1257     $STRING_FORMAT => 'string',
1258     $ADJUST_FORMAT => 'some entries need adjustment',
1259     $HEX_ADJUST_FORMAT => 'mapped value in hex; some entries need adjustment',
1260     $DECOMP_STRING_FORMAT => 'Perl\'s internal (Normalize.pm) decomposition mapping',
1261     $STRING_WHITE_SPACE_LIST => 'string, but some elements are interpreted as a list; white space occurs only as list item separators'
1262 );
1263
1264 # Unicode didn't put such derived files in a separate directory at first.
1265 my $EXTRACTED_DIR = (-d 'extracted') ? 'extracted' : "";
1266 my $EXTRACTED = ($EXTRACTED_DIR) ? "$EXTRACTED_DIR/" : "";
1267 my $AUXILIARY = 'auxiliary';
1268
1269 # Hashes and arrays that will eventually go into Heavy.pl for the use of
1270 # utf8_heavy.pl and into UCD.pl for the use of UCD.pm
1271 my %loose_to_file_of;       # loosely maps table names to their respective
1272                             # files
1273 my %stricter_to_file_of;    # same; but for stricter mapping.
1274 my %loose_property_to_file_of; # Maps a loose property name to its map file
1275 my %strict_property_to_file_of; # Same, but strict
1276 my @inline_definitions = "V0"; # Each element gives a definition of a unique
1277                             # inversion list.  When a definition is inlined,
1278                             # its value in the hash it's in (one of the two
1279                             # defined just above) will include an index into
1280                             # this array.  The 0th element is initialized to
1281                             # the definition for a zero length inversion list
1282 my %file_to_swash_name;     # Maps the file name to its corresponding key name
1283                             # in the hash %utf8::SwashInfo
1284 my %nv_floating_to_rational; # maps numeric values floating point numbers to
1285                              # their rational equivalent
1286 my %loose_property_name_of; # Loosely maps (non_string) property names to
1287                             # standard form
1288 my %strict_property_name_of; # Strictly maps (non_string) property names to
1289                             # standard form
1290 my %string_property_loose_to_name; # Same, for string properties.
1291 my %loose_defaults;         # keys are of form "prop=value", where 'prop' is
1292                             # the property name in standard loose form, and
1293                             # 'value' is the default value for that property,
1294                             # also in standard loose form.
1295 my %loose_to_standard_value; # loosely maps table names to the canonical
1296                             # alias for them
1297 my %ambiguous_names;        # keys are alias names (in standard form) that
1298                             # have more than one possible meaning.
1299 my %combination_property;   # keys are alias names (in standard form) that
1300                             # have both a map table, and a binary one that
1301                             # yields true for all non-null maps.
1302 my %prop_aliases;           # Keys are standard property name; values are each
1303                             # one's aliases
1304 my %prop_value_aliases;     # Keys of top level are standard property name;
1305                             # values are keys to another hash,  Each one is
1306                             # one of the property's values, in standard form.
1307                             # The values are that prop-val's aliases.
1308 my %skipped_files;          # List of files that we skip
1309 my %ucd_pod;    # Holds entries that will go into the UCD section of the pod
1310
1311 # Most properties are immune to caseless matching, otherwise you would get
1312 # nonsensical results, as properties are a function of a code point, not
1313 # everything that is caselessly equivalent to that code point.  For example,
1314 # Changes_When_Case_Folded('s') should be false, whereas caselessly it would
1315 # be true because 's' and 'S' are equivalent caselessly.  However,
1316 # traditionally, [:upper:] and [:lower:] are equivalent caselessly, so we
1317 # extend that concept to those very few properties that are like this.  Each
1318 # such property will match the full range caselessly.  They are hard-coded in
1319 # the program; it's not worth trying to make it general as it's extremely
1320 # unlikely that they will ever change.
1321 my %caseless_equivalent_to;
1322
1323 # This is the range of characters that were in Release 1 of Unicode, and
1324 # removed in Release 2 (replaced with the current Hangul syllables starting at
1325 # U+AC00).  The range was reused starting in Release 3 for other purposes.
1326 my $FIRST_REMOVED_HANGUL_SYLLABLE = 0x3400;
1327 my $FINAL_REMOVED_HANGUL_SYLLABLE = 0x4DFF;
1328
1329 # These constants names and values were taken from the Unicode standard,
1330 # version 5.1, section 3.12.  They are used in conjunction with Hangul
1331 # syllables.  The '_string' versions are so generated tables can retain the
1332 # hex format, which is the more familiar value
1333 my $SBase_string = "0xAC00";
1334 my $SBase = CORE::hex $SBase_string;
1335 my $LBase_string = "0x1100";
1336 my $LBase = CORE::hex $LBase_string;
1337 my $VBase_string = "0x1161";
1338 my $VBase = CORE::hex $VBase_string;
1339 my $TBase_string = "0x11A7";
1340 my $TBase = CORE::hex $TBase_string;
1341 my $SCount = 11172;
1342 my $LCount = 19;
1343 my $VCount = 21;
1344 my $TCount = 28;
1345 my $NCount = $VCount * $TCount;
1346
1347 # For Hangul syllables;  These store the numbers from Jamo.txt in conjunction
1348 # with the above published constants.
1349 my %Jamo;
1350 my %Jamo_L;     # Leading consonants
1351 my %Jamo_V;     # Vowels
1352 my %Jamo_T;     # Trailing consonants
1353
1354 # For code points whose name contains its ordinal as a '-ABCD' suffix.
1355 # The key is the base name of the code point, and the value is an
1356 # array giving all the ranges that use this base name.  Each range
1357 # is actually a hash giving the 'low' and 'high' values of it.
1358 my %names_ending_in_code_point;
1359 my %loose_names_ending_in_code_point;   # Same as above, but has blanks, dashes
1360                                         # removed from the names
1361 # Inverse mapping.  The list of ranges that have these kinds of
1362 # names.  Each element contains the low, high, and base names in an
1363 # anonymous hash.
1364 my @code_points_ending_in_code_point;
1365
1366 # To hold Unicode's normalization test suite
1367 my @normalization_tests;
1368
1369 # Boolean: does this Unicode version have the hangul syllables, and are we
1370 # writing out a table for them?
1371 my $has_hangul_syllables = 0;
1372
1373 # Does this Unicode version have code points whose names end in their
1374 # respective code points, and are we writing out a table for them?  0 for no;
1375 # otherwise points to first property that a table is needed for them, so that
1376 # if multiple tables are needed, we don't create duplicates
1377 my $needing_code_points_ending_in_code_point = 0;
1378
1379 my @backslash_X_tests;     # List of tests read in for testing \X
1380 my @SB_tests;              # List of tests read in for testing \b{sb}
1381 my @WB_tests;              # List of tests read in for testing \b{wb}
1382 my @unhandled_properties;  # Will contain a list of properties found in
1383                            # the input that we didn't process.
1384 my @match_properties;      # Properties that have match tables, to be
1385                            # listed in the pod
1386 my @map_properties;        # Properties that get map files written
1387 my @named_sequences;       # NamedSequences.txt contents.
1388 my %potential_files;       # Generated list of all .txt files in the directory
1389                            # structure so we can warn if something is being
1390                            # ignored.
1391 my @missing_early_files;   # Generated list of absent files that we need to
1392                            # proceed in compiling this early Unicode version
1393 my @files_actually_output; # List of files we generated.
1394 my @more_Names;            # Some code point names are compound; this is used
1395                            # to store the extra components of them.
1396 my $MIN_FRACTION_LENGTH = 3; # How many digits of a floating point number at
1397                            # the minimum before we consider it equivalent to a
1398                            # candidate rational
1399 my $MAX_FLOATING_SLOP = 10 ** - $MIN_FRACTION_LENGTH; # And in floating terms
1400
1401 # These store references to certain commonly used property objects
1402 my $ccc;
1403 my $gc;
1404 my $perl;
1405 my $block;
1406 my $perl_charname;
1407 my $print;
1408 my $All;
1409 my $Assigned;   # All assigned characters in this Unicode release
1410 my $script;
1411
1412 # Are there conflicting names because of beginning with 'In_', or 'Is_'
1413 my $has_In_conflicts = 0;
1414 my $has_Is_conflicts = 0;
1415
1416 sub internal_file_to_platform ($) {
1417     # Convert our file paths which have '/' separators to those of the
1418     # platform.
1419
1420     my $file = shift;
1421     return undef unless defined $file;
1422
1423     return File::Spec->join(split '/', $file);
1424 }
1425
1426 sub file_exists ($) {   # platform independent '-e'.  This program internally
1427                         # uses slash as a path separator.
1428     my $file = shift;
1429     return 0 if ! defined $file;
1430     return -e internal_file_to_platform($file);
1431 }
1432
1433 sub objaddr($) {
1434     # Returns the address of the blessed input object.
1435     # It doesn't check for blessedness because that would do a string eval
1436     # every call, and the program is structured so that this is never called
1437     # for a non-blessed object.
1438
1439     no overloading; # If overloaded, numifying below won't work.
1440
1441     # Numifying a ref gives its address.
1442     return pack 'J', $_[0];
1443 }
1444
1445 # These are used only if $annotate is true.
1446 # The entire range of Unicode characters is examined to populate these
1447 # after all the input has been processed.  But most can be skipped, as they
1448 # have the same descriptive phrases, such as being unassigned
1449 my @viacode;            # Contains the 1 million character names
1450 my @age;                # And their ages ("" if none)
1451 my @printable;          # boolean: And are those characters printable?
1452 my @annotate_char_type; # Contains a type of those characters, specifically
1453                         # for the purposes of annotation.
1454 my $annotate_ranges;    # A map of ranges of code points that have the same
1455                         # name for the purposes of annotation.  They map to the
1456                         # upper edge of the range, so that the end point can
1457                         # be immediately found.  This is used to skip ahead to
1458                         # the end of a range, and avoid processing each
1459                         # individual code point in it.
1460 my $unassigned_sans_noncharacters; # A Range_List of the unassigned
1461                                    # characters, but excluding those which are
1462                                    # also noncharacter code points
1463
1464 # The annotation types are an extension of the regular range types, though
1465 # some of the latter are folded into one.  Make the new types negative to
1466 # avoid conflicting with the regular types
1467 my $SURROGATE_TYPE = -1;
1468 my $UNASSIGNED_TYPE = -2;
1469 my $PRIVATE_USE_TYPE = -3;
1470 my $NONCHARACTER_TYPE = -4;
1471 my $CONTROL_TYPE = -5;
1472 my $ABOVE_UNICODE_TYPE = -6;
1473 my $UNKNOWN_TYPE = -7;  # Used only if there is a bug in this program
1474
1475 sub populate_char_info ($) {
1476     # Used only with the $annotate option.  Populates the arrays with the
1477     # input code point's info that are needed for outputting more detailed
1478     # comments.  If calling context wants a return, it is the end point of
1479     # any contiguous range of characters that share essentially the same info
1480
1481     my $i = shift;
1482     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1483
1484     $viacode[$i] = $perl_charname->value_of($i) || "";
1485
1486     # A character is generally printable if Unicode says it is,
1487     # but below we make sure that most Unicode general category 'C' types
1488     # aren't.
1489     $printable[$i] = $print->contains($i);
1490
1491     $annotate_char_type[$i] = $perl_charname->type_of($i) || 0;
1492
1493     # Only these two regular types are treated specially for annotations
1494     # purposes
1495     $annotate_char_type[$i] = 0 if $annotate_char_type[$i] != $CP_IN_NAME
1496                                 && $annotate_char_type[$i] != $HANGUL_SYLLABLE;
1497
1498     # Give a generic name to all code points that don't have a real name.
1499     # We output ranges, if applicable, for these.  Also calculate the end
1500     # point of the range.
1501     my $end;
1502     if (! $viacode[$i]) {
1503         my $nonchar;
1504         if ($i > $MAX_UNICODE_CODEPOINT) {
1505             $viacode[$i] = 'Above-Unicode';
1506             $annotate_char_type[$i] = $ABOVE_UNICODE_TYPE;
1507             $printable[$i] = 0;
1508             $end = $MAX_WORKING_CODEPOINT;
1509             $age[$i] = "";
1510         }
1511         elsif ($gc-> table('Private_use')->contains($i)) {
1512             $viacode[$i] = 'Private Use';
1513             $annotate_char_type[$i] = $PRIVATE_USE_TYPE;
1514             $printable[$i] = 0;
1515             $end = $gc->table('Private_Use')->containing_range($i)->end;
1516             $age[$i] = property_ref("Age")->value_of($i);
1517         }
1518         elsif ((defined ($nonchar =
1519                             Property::property_ref('Noncharacter_Code_Point'))
1520                && $nonchar->table('Y')->contains($i)))
1521         {
1522             $viacode[$i] = 'Noncharacter';
1523             $annotate_char_type[$i] = $NONCHARACTER_TYPE;
1524             $printable[$i] = 0;
1525             $end = property_ref('Noncharacter_Code_Point')->table('Y')->
1526                                                     containing_range($i)->end;
1527             $age[$i] = property_ref("Age")->value_of($i);
1528         }
1529         elsif ($gc-> table('Control')->contains($i)) {
1530             $viacode[$i] = property_ref('Name_Alias')->value_of($i) || 'Control';
1531             $annotate_char_type[$i] = $CONTROL_TYPE;
1532             $printable[$i] = 0;
1533             $age[$i] = property_ref("Age")->value_of($i);
1534         }
1535         elsif ($gc-> table('Unassigned')->contains($i)) {
1536             $annotate_char_type[$i] = $UNASSIGNED_TYPE;
1537             $printable[$i] = 0;
1538             if (defined $block) { # No blocks in earliest releases
1539                 $viacode[$i] = 'Unassigned';
1540                 $end = $gc-> table('Unassigned')->containing_range($i)->end;
1541             }
1542             else {
1543                 $viacode[$i] = 'Unassigned, block=' . $block-> value_of($i);
1544
1545                 # Because we name the unassigned by the blocks they are in, it
1546                 # can't go past the end of that block, and it also can't go
1547                 # past the unassigned range it is in.  The special table makes
1548                 # sure that the non-characters, which are unassigned, are
1549                 # separated out.
1550                 $end = min($block->containing_range($i)->end,
1551                            $unassigned_sans_noncharacters->
1552                                                     containing_range($i)->end);
1553             }
1554             $age[$i] = property_ref("Age")->value_of($i);
1555         }
1556         elsif ($perl->table('_Perl_Surrogate')->contains($i)) {
1557             $viacode[$i] = 'Surrogate';
1558             $annotate_char_type[$i] = $SURROGATE_TYPE;
1559             $printable[$i] = 0;
1560             $end = $gc->table('Surrogate')->containing_range($i)->end;
1561             $age[$i] = property_ref("Age")->value_of($i);
1562         }
1563         else {
1564             Carp::my_carp_bug("Can't figure out how to annotate "
1565                               . sprintf("U+%04X", $i)
1566                               . ".  Proceeding anyway.");
1567             $viacode[$i] = 'UNKNOWN';
1568             $annotate_char_type[$i] = $UNKNOWN_TYPE;
1569             $printable[$i] = 0;
1570         }
1571     }
1572
1573     # Here, has a name, but if it's one in which the code point number is
1574     # appended to the name, do that.
1575     elsif ($annotate_char_type[$i] == $CP_IN_NAME) {
1576         $viacode[$i] .= sprintf("-%04X", $i);
1577
1578         # Do all these as groups of the same age, instead of individually,
1579         # because their names are so meaningless, and there are typically
1580         # large quantities of them.
1581         my $Age = property_ref("Age");
1582         $age[$i] = $Age->value_of($i);
1583         my $limit = $perl_charname->containing_range($i)->end;
1584         $end = $i + 1;
1585         while ($end <= $limit && $Age->value_of($end) == $age[$i]) {
1586             $end++;
1587         }
1588         $end--;
1589     }
1590
1591     # And here, has a name, but if it's a hangul syllable one, replace it with
1592     # the correct name from the Unicode algorithm
1593     elsif ($annotate_char_type[$i] == $HANGUL_SYLLABLE) {
1594         use integer;
1595         my $SIndex = $i - $SBase;
1596         my $L = $LBase + $SIndex / $NCount;
1597         my $V = $VBase + ($SIndex % $NCount) / $TCount;
1598         my $T = $TBase + $SIndex % $TCount;
1599         $viacode[$i] = "HANGUL SYLLABLE $Jamo{$L}$Jamo{$V}";
1600         $viacode[$i] .= $Jamo{$T} if $T != $TBase;
1601         $age[$i] = property_ref("Age")->value_of($i);
1602         $end = $perl_charname->containing_range($i)->end;
1603     }
1604     else {
1605         $age[$i] = property_ref("Age")->value_of($i);
1606     }
1607
1608     return if ! defined wantarray;
1609     return $i if ! defined $end;    # If not a range, return the input
1610
1611     # Save this whole range so can find the end point quickly
1612     $annotate_ranges->add_map($i, $end, $end);
1613
1614     return $end;
1615 }
1616
1617 # Commented code below should work on Perl 5.8.
1618 ## This 'require' doesn't necessarily work in miniperl, and even if it does,
1619 ## the native perl version of it (which is what would operate under miniperl)
1620 ## is extremely slow, as it does a string eval every call.
1621 #my $has_fast_scalar_util = $^X !~ /miniperl/
1622 #                            && defined eval "require Scalar::Util";
1623 #
1624 #sub objaddr($) {
1625 #    # Returns the address of the blessed input object.  Uses the XS version if
1626 #    # available.  It doesn't check for blessedness because that would do a
1627 #    # string eval every call, and the program is structured so that this is
1628 #    # never called for a non-blessed object.
1629 #
1630 #    return Scalar::Util::refaddr($_[0]) if $has_fast_scalar_util;
1631 #
1632 #    # Check at least that is a ref.
1633 #    my $pkg = ref($_[0]) or return undef;
1634 #
1635 #    # Change to a fake package to defeat any overloaded stringify
1636 #    bless $_[0], 'main::Fake';
1637 #
1638 #    # Numifying a ref gives its address.
1639 #    my $addr = pack 'J', $_[0];
1640 #
1641 #    # Return to original class
1642 #    bless $_[0], $pkg;
1643 #    return $addr;
1644 #}
1645
1646 sub max ($$) {
1647     my $a = shift;
1648     my $b = shift;
1649     return $a if $a >= $b;
1650     return $b;
1651 }
1652
1653 sub min ($$) {
1654     my $a = shift;
1655     my $b = shift;
1656     return $a if $a <= $b;
1657     return $b;
1658 }
1659
1660 sub clarify_number ($) {
1661     # This returns the input number with underscores inserted every 3 digits
1662     # in large (5 digits or more) numbers.  Input must be entirely digits, not
1663     # checked.
1664
1665     my $number = shift;
1666     my $pos = length($number) - 3;
1667     return $number if $pos <= 1;
1668     while ($pos > 0) {
1669         substr($number, $pos, 0) = '_';
1670         $pos -= 3;
1671     }
1672     return $number;
1673 }
1674
1675 sub clarify_code_point_count ($) {
1676     # This is like clarify_number(), but the input is assumed to be a count of
1677     # code points, rather than a generic number.
1678
1679     my $append = "";
1680
1681     my $number = shift;
1682     if ($number > $MAX_UNICODE_CODEPOINTS) {
1683         $number -= ($MAX_WORKING_CODEPOINTS - $MAX_UNICODE_CODEPOINTS);
1684         return "All above-Unicode code points" if $number == 0;
1685         $append = " + all above-Unicode code points";
1686     }
1687     return clarify_number($number) . $append;
1688 }
1689
1690 package Carp;
1691
1692 # These routines give a uniform treatment of messages in this program.  They
1693 # are placed in the Carp package to cause the stack trace to not include them,
1694 # although an alternative would be to use another package and set @CARP_NOT
1695 # for it.
1696
1697 our $Verbose = 1 if main::DEBUG;  # Useful info when debugging
1698
1699 # This is a work-around suggested by Nicholas Clark to fix a problem with Carp
1700 # and overload trying to load Scalar:Util under miniperl.  See
1701 # http://www.xray.mpe.mpg.de/mailing-lists/perl5-porters/2009-11/msg01057.html
1702 undef $overload::VERSION;
1703
1704 sub my_carp {
1705     my $message = shift || "";
1706     my $nofold = shift || 0;
1707
1708     if ($message) {
1709         $message = main::join_lines($message);
1710         $message =~ s/^$0: *//;     # Remove initial program name
1711         $message =~ s/[.;,]+$//;    # Remove certain ending punctuation
1712         $message = "\n$0: $message;";
1713
1714         # Fold the message with program name, semi-colon end punctuation
1715         # (which looks good with the message that carp appends to it), and a
1716         # hanging indent for continuation lines.
1717         $message = main::simple_fold($message, "", 4) unless $nofold;
1718         $message =~ s/\n$//;        # Remove the trailing nl so what carp
1719                                     # appends is to the same line
1720     }
1721
1722     return $message if defined wantarray;   # If a caller just wants the msg
1723
1724     carp $message;
1725     return;
1726 }
1727
1728 sub my_carp_bug {
1729     # This is called when it is clear that the problem is caused by a bug in
1730     # this program.
1731
1732     my $message = shift;
1733     $message =~ s/^$0: *//;
1734     $message = my_carp("Bug in $0.  Please report it by running perlbug or if that is unavailable, by sending email to perbug\@perl.org:\n$message");
1735     carp $message;
1736     return;
1737 }
1738
1739 sub carp_too_few_args {
1740     if (@_ != 2) {
1741         my_carp_bug("Wrong number of arguments: to 'carp_too_few_arguments'.  No action taken.");
1742         return;
1743     }
1744
1745     my $args_ref = shift;
1746     my $count = shift;
1747
1748     my_carp_bug("Need at least $count arguments to "
1749         . (caller 1)[3]
1750         . ".  Instead got: '"
1751         . join ', ', @$args_ref
1752         . "'.  No action taken.");
1753     return;
1754 }
1755
1756 sub carp_extra_args {
1757     my $args_ref = shift;
1758     my_carp_bug("Too many arguments to 'carp_extra_args': (" . join(', ', @_) . ");  Extras ignored.") if @_;
1759
1760     unless (ref $args_ref) {
1761         my_carp_bug("Argument to 'carp_extra_args' ($args_ref) must be a ref.  Not checking arguments.");
1762         return;
1763     }
1764     my ($package, $file, $line) = caller;
1765     my $subroutine = (caller 1)[3];
1766
1767     my $list;
1768     if (ref $args_ref eq 'HASH') {
1769         foreach my $key (keys %$args_ref) {
1770             $args_ref->{$key} = $UNDEF unless defined $args_ref->{$key};
1771         }
1772         $list = join ', ', each %{$args_ref};
1773     }
1774     elsif (ref $args_ref eq 'ARRAY') {
1775         foreach my $arg (@$args_ref) {
1776             $arg = $UNDEF unless defined $arg;
1777         }
1778         $list = join ', ', @$args_ref;
1779     }
1780     else {
1781         my_carp_bug("Can't cope with ref "
1782                 . ref($args_ref)
1783                 . " . argument to 'carp_extra_args'.  Not checking arguments.");
1784         return;
1785     }
1786
1787     my_carp_bug("Unrecognized parameters in options: '$list' to $subroutine.  Skipped.");
1788     return;
1789 }
1790
1791 package main;
1792
1793 { # Closure
1794
1795     # This program uses the inside-out method for objects, as recommended in
1796     # "Perl Best Practices".  (This is the best solution still, since this has
1797     # to run under miniperl.)  This closure aids in generating those.  There
1798     # are two routines.  setup_package() is called once per package to set
1799     # things up, and then set_access() is called for each hash representing a
1800     # field in the object.  These routines arrange for the object to be
1801     # properly destroyed when no longer used, and for standard accessor
1802     # functions to be generated.  If you need more complex accessors, just
1803     # write your own and leave those accesses out of the call to set_access().
1804     # More details below.
1805
1806     my %constructor_fields; # fields that are to be used in constructors; see
1807                             # below
1808
1809     # The values of this hash will be the package names as keys to other
1810     # hashes containing the name of each field in the package as keys, and
1811     # references to their respective hashes as values.
1812     my %package_fields;
1813
1814     sub setup_package {
1815         # Sets up the package, creating standard DESTROY and dump methods
1816         # (unless already defined).  The dump method is used in debugging by
1817         # simple_dumper().
1818         # The optional parameters are:
1819         #   a)  a reference to a hash, that gets populated by later
1820         #       set_access() calls with one of the accesses being
1821         #       'constructor'.  The caller can then refer to this, but it is
1822         #       not otherwise used by these two routines.
1823         #   b)  a reference to a callback routine to call during destruction
1824         #       of the object, before any fields are actually destroyed
1825
1826         my %args = @_;
1827         my $constructor_ref = delete $args{'Constructor_Fields'};
1828         my $destroy_callback = delete $args{'Destroy_Callback'};
1829         Carp::carp_extra_args(\@_) if main::DEBUG && %args;
1830
1831         my %fields;
1832         my $package = (caller)[0];
1833
1834         $package_fields{$package} = \%fields;
1835         $constructor_fields{$package} = $constructor_ref;
1836
1837         unless ($package->can('DESTROY')) {
1838             my $destroy_name = "${package}::DESTROY";
1839             no strict "refs";
1840
1841             # Use typeglob to give the anonymous subroutine the name we want
1842             *$destroy_name = sub {
1843                 my $self = shift;
1844                 my $addr = do { no overloading; pack 'J', $self; };
1845
1846                 $self->$destroy_callback if $destroy_callback;
1847                 foreach my $field (keys %{$package_fields{$package}}) {
1848                     #print STDERR __LINE__, ": Destroying ", ref $self, " ", sprintf("%04X", $addr), ": ", $field, "\n";
1849                     delete $package_fields{$package}{$field}{$addr};
1850                 }
1851                 return;
1852             }
1853         }
1854
1855         unless ($package->can('dump')) {
1856             my $dump_name = "${package}::dump";
1857             no strict "refs";
1858             *$dump_name = sub {
1859                 my $self = shift;
1860                 return dump_inside_out($self, $package_fields{$package}, @_);
1861             }
1862         }
1863         return;
1864     }
1865
1866     sub set_access {
1867         # Arrange for the input field to be garbage collected when no longer
1868         # needed.  Also, creates standard accessor functions for the field
1869         # based on the optional parameters-- none if none of these parameters:
1870         #   'addable'    creates an 'add_NAME()' accessor function.
1871         #   'readable' or 'readable_array'   creates a 'NAME()' accessor
1872         #                function.
1873         #   'settable'   creates a 'set_NAME()' accessor function.
1874         #   'constructor' doesn't create an accessor function, but adds the
1875         #                field to the hash that was previously passed to
1876         #                setup_package();
1877         # Any of the accesses can be abbreviated down, so that 'a', 'ad',
1878         # 'add' etc. all mean 'addable'.
1879         # The read accessor function will work on both array and scalar
1880         # values.  If another accessor in the parameter list is 'a', the read
1881         # access assumes an array.  You can also force it to be array access
1882         # by specifying 'readable_array' instead of 'readable'
1883         #
1884         # A sort-of 'protected' access can be set-up by preceding the addable,
1885         # readable or settable with some initial portion of 'protected_' (but,
1886         # the underscore is required), like 'p_a', 'pro_set', etc.  The
1887         # "protection" is only by convention.  All that happens is that the
1888         # accessor functions' names begin with an underscore.  So instead of
1889         # calling set_foo, the call is _set_foo.  (Real protection could be
1890         # accomplished by having a new subroutine, end_package, called at the
1891         # end of each package, and then storing the __LINE__ ranges and
1892         # checking them on every accessor.  But that is way overkill.)
1893
1894         # We create anonymous subroutines as the accessors and then use
1895         # typeglobs to assign them to the proper package and name
1896
1897         my $name = shift;   # Name of the field
1898         my $field = shift;  # Reference to the inside-out hash containing the
1899                             # field
1900
1901         my $package = (caller)[0];
1902
1903         if (! exists $package_fields{$package}) {
1904             croak "$0: Must call 'setup_package' before 'set_access'";
1905         }
1906
1907         # Stash the field so DESTROY can get it.
1908         $package_fields{$package}{$name} = $field;
1909
1910         # Remaining arguments are the accessors.  For each...
1911         foreach my $access (@_) {
1912             my $access = lc $access;
1913
1914             my $protected = "";
1915
1916             # Match the input as far as it goes.
1917             if ($access =~ /^(p[^_]*)_/) {
1918                 $protected = $1;
1919                 if (substr('protected_', 0, length $protected)
1920                     eq $protected)
1921                 {
1922
1923                     # Add 1 for the underscore not included in $protected
1924                     $access = substr($access, length($protected) + 1);
1925                     $protected = '_';
1926                 }
1927                 else {
1928                     $protected = "";
1929                 }
1930             }
1931
1932             if (substr('addable', 0, length $access) eq $access) {
1933                 my $subname = "${package}::${protected}add_$name";
1934                 no strict "refs";
1935
1936                 # add_ accessor.  Don't add if already there, which we
1937                 # determine using 'eq' for scalars and '==' otherwise.
1938                 *$subname = sub {
1939                     use strict "refs";
1940                     return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
1941                     my $self = shift;
1942                     my $value = shift;
1943                     my $addr = do { no overloading; pack 'J', $self; };
1944                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1945                     if (ref $value) {
1946                         return if grep { $value == $_ } @{$field->{$addr}};
1947                     }
1948                     else {
1949                         return if grep { $value eq $_ } @{$field->{$addr}};
1950                     }
1951                     push @{$field->{$addr}}, $value;
1952                     return;
1953                 }
1954             }
1955             elsif (substr('constructor', 0, length $access) eq $access) {
1956                 if ($protected) {
1957                     Carp::my_carp_bug("Can't set-up 'protected' constructors")
1958                 }
1959                 else {
1960                     $constructor_fields{$package}{$name} = $field;
1961                 }
1962             }
1963             elsif (substr('readable_array', 0, length $access) eq $access) {
1964
1965                 # Here has read access.  If one of the other parameters for
1966                 # access is array, or this one specifies array (by being more
1967                 # than just 'readable_'), then create a subroutine that
1968                 # assumes the data is an array.  Otherwise just a scalar
1969                 my $subname = "${package}::${protected}$name";
1970                 if (grep { /^a/i } @_
1971                     or length($access) > length('readable_'))
1972                 {
1973                     no strict "refs";
1974                     *$subname = sub {
1975                         use strict "refs";
1976                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1977                         my $addr = do { no overloading; pack 'J', $_[0]; };
1978                         if (ref $field->{$addr} ne 'ARRAY') {
1979                             my $type = ref $field->{$addr};
1980                             $type = 'scalar' unless $type;
1981                             Carp::my_carp_bug("Trying to read $name as an array when it is a $type.  Big problems.");
1982                             return;
1983                         }
1984                         return scalar @{$field->{$addr}} unless wantarray;
1985
1986                         # Make a copy; had problems with caller modifying the
1987                         # original otherwise
1988                         my @return = @{$field->{$addr}};
1989                         return @return;
1990                     }
1991                 }
1992                 else {
1993
1994                     # Here not an array value, a simpler function.
1995                     no strict "refs";
1996                     *$subname = sub {
1997                         use strict "refs";
1998                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1999                         no overloading;
2000                         return $field->{pack 'J', $_[0]};
2001                     }
2002                 }
2003             }
2004             elsif (substr('settable', 0, length $access) eq $access) {
2005                 my $subname = "${package}::${protected}set_$name";
2006                 no strict "refs";
2007                 *$subname = sub {
2008                     use strict "refs";
2009                     if (main::DEBUG) {
2010                         return Carp::carp_too_few_args(\@_, 2) if @_ < 2;
2011                         Carp::carp_extra_args(\@_) if @_ > 2;
2012                     }
2013                     # $self is $_[0]; $value is $_[1]
2014                     no overloading;
2015                     $field->{pack 'J', $_[0]} = $_[1];
2016                     return;
2017                 }
2018             }
2019             else {
2020                 Carp::my_carp_bug("Unknown accessor type $access.  No accessor set.");
2021             }
2022         }
2023         return;
2024     }
2025 }
2026
2027 package Input_file;
2028
2029 # All input files use this object, which stores various attributes about them,
2030 # and provides for convenient, uniform handling.  The run method wraps the
2031 # processing.  It handles all the bookkeeping of opening, reading, and closing
2032 # the file, returning only significant input lines.
2033 #
2034 # Each object gets a handler which processes the body of the file, and is
2035 # called by run().  All character property files must use the generic,
2036 # default handler, which has code scrubbed to handle things you might not
2037 # expect, including automatic EBCDIC handling.  For files that don't deal with
2038 # mapping code points to a property value, such as test files,
2039 # PropertyAliases, PropValueAliases, and named sequences, you can override the
2040 # handler to be a custom one.  Such a handler should basically be a
2041 # while(next_line()) {...} loop.
2042 #
2043 # You can also set up handlers to
2044 #   0) call during object construction time, after everything else is done
2045 #   1) call before the first line is read, for pre processing
2046 #   2) call to adjust each line of the input before the main handler gets
2047 #      them.  This can be automatically generated, if appropriately simple
2048 #      enough, by specifiying a Properties parameter in the constructor.
2049 #   3) call upon EOF before the main handler exits its loop
2050 #   4) call at the end, for post processing
2051 #
2052 # $_ is used to store the input line, and is to be filtered by the
2053 # each_line_handler()s.  So, if the format of the line is not in the desired
2054 # format for the main handler, these are used to do that adjusting.  They can
2055 # be stacked (by enclosing them in an [ anonymous array ] in the constructor,
2056 # so the $_ output of one is used as the input to the next.  The eof handler
2057 # is also stackable, but none of the others are, but could easily be changed
2058 # to be so.
2059 #
2060 # Some properties are used by the Perl core but aren't defined until later
2061 # Unicode releases.  The perl interpreter would have problems working when
2062 # compiled with an earlier Unicode version that doesn't have them, so we need
2063 # to define them somehow for those releases.  The 'Early' constructor
2064 # parameter can be used to automatically handle this.  It is essentially
2065 # ignored if the Unicode version being compiled has a data file for this
2066 # property.  Either code to execute or a file to read can be specified.
2067 # Details are at the %early definition.
2068 #
2069 # Most of the handlers can call insert_lines() or insert_adjusted_lines()
2070 # which insert the parameters as lines to be processed before the next input
2071 # file line is read.  This allows the EOF handler(s) to flush buffers, for
2072 # example.  The difference between the two routines is that the lines inserted
2073 # by insert_lines() are subjected to the each_line_handler()s.  (So if you
2074 # called it from such a handler, you would get infinite recursion without some
2075 # mechanism to prevent that.)  Lines inserted by insert_adjusted_lines() go
2076 # directly to the main handler without any adjustments.  If the
2077 # post-processing handler calls any of these, there will be no effect.  Some
2078 # error checking for these conditions could be added, but it hasn't been done.
2079 #
2080 # carp_bad_line() should be called to warn of bad input lines, which clears $_
2081 # to prevent further processing of the line.  This routine will output the
2082 # message as a warning once, and then keep a count of the lines that have the
2083 # same message, and output that count at the end of the file's processing.
2084 # This keeps the number of messages down to a manageable amount.
2085 #
2086 # get_missings() should be called to retrieve any @missing input lines.
2087 # Messages will be raised if this isn't done if the options aren't to ignore
2088 # missings.
2089
2090 sub trace { return main::trace(@_); }
2091
2092 { # Closure
2093     # Keep track of fields that are to be put into the constructor.
2094     my %constructor_fields;
2095
2096     main::setup_package(Constructor_Fields => \%constructor_fields);
2097
2098     my %file; # Input file name, required
2099     main::set_access('file', \%file, qw{ c r });
2100
2101     my %first_released; # Unicode version file was first released in, required
2102     main::set_access('first_released', \%first_released, qw{ c r });
2103
2104     my %handler;    # Subroutine to process the input file, defaults to
2105                     # 'process_generic_property_file'
2106     main::set_access('handler', \%handler, qw{ c });
2107
2108     my %property;
2109     # name of property this file is for.  defaults to none, meaning not
2110     # applicable, or is otherwise determinable, for example, from each line.
2111     main::set_access('property', \%property, qw{ c r });
2112
2113     my %optional;
2114     # This is either an unsigned number, or a list of property names.  In the
2115     # former case, if it is non-zero, it means the file is optional, so if the
2116     # file is absent, no warning about that is output.  In the latter case, it
2117     # is a list of properties that the file (exclusively) defines.  If the
2118     # file is present, tables for those properties will be produced; if
2119     # absent, none will, even if they are listed elsewhere (namely
2120     # PropertyAliases.txt and PropValueAliases.txt) as being in this release,
2121     # and no warnings will be raised about them not being available.  (And no
2122     # warning about the file itself will be raised.)
2123     main::set_access('optional', \%optional, qw{ c readable_array } );
2124
2125     my %non_skip;
2126     # This is used for debugging, to skip processing of all but a few input
2127     # files.  Add 'non_skip => 1' to the constructor for those files you want
2128     # processed when you set the $debug_skip global.
2129     main::set_access('non_skip', \%non_skip, 'c');
2130
2131     my %skip;
2132     # This is used to skip processing of this input file (semi-) permanently.
2133     # The value should be the reason the file is being skipped.  It is used
2134     # for files that we aren't planning to process anytime soon, but want to
2135     # allow to be in the directory and be checked for their names not
2136     # conflicting with any other files on a DOS 8.3 name filesystem, but to
2137     # not otherwise be processed, and to not raise a warning about not being
2138     # handled.  In the constructor call, any value that evaluates to a numeric
2139     # 0 or undef means don't skip.  Any other value is a string giving the
2140     # reason it is being skippped, and this will appear in generated pod.
2141     # However, an empty string reason will suppress the pod entry.
2142     # Internally, calls that evaluate to numeric 0 are changed into undef to
2143     # distinguish them from an empty string call.
2144     main::set_access('skip', \%skip, 'c', 'r');
2145
2146     my %each_line_handler;
2147     # list of subroutines to look at and filter each non-comment line in the
2148     # file.  defaults to none.  The subroutines are called in order, each is
2149     # to adjust $_ for the next one, and the final one adjusts it for
2150     # 'handler'
2151     main::set_access('each_line_handler', \%each_line_handler, 'c');
2152
2153     my %properties; # Optional ordered list of the properties that occur in each
2154     # meaningful line of the input file.  If present, an appropriate
2155     # each_line_handler() is automatically generated and pushed onto the stack
2156     # of such handlers.  This is useful when a file contains multiple
2157     # proerties per line, but no other special considerations are necessary.
2158     # The special value "<ignored>" means to discard the corresponding input
2159     # field.
2160     # Any @missing lines in the file should also match this syntax; no such
2161     # files exist as of 6.3.  But if it happens in a future release, the code
2162     # could be expanded to properly parse them.
2163     main::set_access('properties', \%properties, qw{ c r });
2164
2165     my %has_missings_defaults;
2166     # ? Are there lines in the file giving default values for code points
2167     # missing from it?.  Defaults to NO_DEFAULTS.  Otherwise NOT_IGNORED is
2168     # the norm, but IGNORED means it has such lines, but the handler doesn't
2169     # use them.  Having these three states allows us to catch changes to the
2170     # UCD that this program should track.  XXX This could be expanded to
2171     # specify the syntax for such lines, like %properties above.
2172     main::set_access('has_missings_defaults',
2173                                         \%has_missings_defaults, qw{ c r });
2174
2175     my %construction_time_handler;
2176     # Subroutine to call at the end of the new method.  If undef, no such
2177     # handler is called.
2178     main::set_access('construction_time_handler',
2179                                         \%construction_time_handler, qw{ c });
2180
2181     my %pre_handler;
2182     # Subroutine to call before doing anything else in the file.  If undef, no
2183     # such handler is called.
2184     main::set_access('pre_handler', \%pre_handler, qw{ c });
2185
2186     my %eof_handler;
2187     # Subroutines to call upon getting an EOF on the input file, but before
2188     # that is returned to the main handler.  This is to allow buffers to be
2189     # flushed.  The handler is expected to call insert_lines() or
2190     # insert_adjusted() with the buffered material
2191     main::set_access('eof_handler', \%eof_handler, qw{ c });
2192
2193     my %post_handler;
2194     # Subroutine to call after all the lines of the file are read in and
2195     # processed.  If undef, no such handler is called.  Note that this cannot
2196     # add lines to be processed; instead use eof_handler
2197     main::set_access('post_handler', \%post_handler, qw{ c });
2198
2199     my %progress_message;
2200     # Message to print to display progress in lieu of the standard one
2201     main::set_access('progress_message', \%progress_message, qw{ c });
2202
2203     my %handle;
2204     # cache open file handle, internal.  Is undef if file hasn't been
2205     # processed at all, empty if has;
2206     main::set_access('handle', \%handle);
2207
2208     my %added_lines;
2209     # cache of lines added virtually to the file, internal
2210     main::set_access('added_lines', \%added_lines);
2211
2212     my %remapped_lines;
2213     # cache of lines added virtually to the file, internal
2214     main::set_access('remapped_lines', \%remapped_lines);
2215
2216     my %errors;
2217     # cache of errors found, internal
2218     main::set_access('errors', \%errors);
2219
2220     my %missings;
2221     # storage of '@missing' defaults lines
2222     main::set_access('missings', \%missings);
2223
2224     my %early;
2225     # Used for properties that must be defined (for Perl's purposes) on
2226     # versions of Unicode earlier than Unicode itself defines them.  The
2227     # parameter is an array (it would be better to be a hash, but not worth
2228     # bothering about due to its rare use).
2229     #
2230     # The first element is either a code reference to call when in a release
2231     # earlier than the Unicode file is available in, or it is an alternate
2232     # file to use instead of the non-existent one.  This file must have been
2233     # plunked down in the same directory as mktables.  Should you be compiling
2234     # on a release that needs such a file, mktables will abort the
2235     # compilation, and tell you where to get the necessary file(s), and what
2236     # name(s) to use to store them as.
2237     # In the case of specifying an alternate file, the array must contain two
2238     # further elements:
2239     #
2240     # [1] is the name of the property that will be generated by this file.
2241     # The class automatically takes the input file and excludes any code
2242     # points in it that were not assigned in the Unicode version being
2243     # compiled.  It then uses this result to define the property in the given
2244     # version.  Since the property doesn't actually exist in the Unicode
2245     # version being compiled, this should be a name accessible only by core
2246     # perl.  If it is the same name as the regular property, the constructor
2247     # will mark the output table as a $PLACEHOLDER so that it doesn't actually
2248     # get output, and so will be unusable by non-core code.  Otherwise it gets
2249     # marked as $INTERNAL_ONLY.
2250     #
2251     # [2] is a property value to assign (only when compiling Unicode 1.1.5) to
2252     # the Hangul syllables in that release (which were ripped out in version
2253     # 2) for the given property .  (Hence it is ignored except when compiling
2254     # version 1.  You only get one value that applies to all of them, which
2255     # may not be the actual reality, but probably nobody cares anyway for
2256     # these obsolete characters.)
2257     #
2258     # Not all files can be handled in the above way, and so the code ref
2259     # alternative is available.  It can do whatever it needs to.  The other
2260     # array elements are optional in this case, and the code is free to use or
2261     # ignore them if they are present.
2262     #
2263     # Internally, the constructor unshifts a 0 or 1 onto this array to
2264     # indicate if an early alternative is actually being used or not.  This
2265     # makes for easier testing later on.
2266     main::set_access('early', \%early, 'c');
2267
2268     my %required_even_in_debug_skip;
2269     # debug_skip is used to speed up compilation during debugging by skipping
2270     # processing files that are not needed for the task at hand.  However,
2271     # some files pretty much can never be skipped, and this is used to specify
2272     # that this is one of them.  In order to skip this file, the call to the
2273     # constructor must be edited to comment out this parameter.
2274     main::set_access('required_even_in_debug_skip',
2275                      \%required_even_in_debug_skip, 'c');
2276
2277     my %withdrawn;
2278     # Some files get removed from the Unicode DB.  This is a version object
2279     # giving the first release without this file.
2280     main::set_access('withdrawn', \%withdrawn, 'c');
2281
2282     my %in_this_release;
2283     # Calculated value from %first_released and %withdrawn.  Are we compiling
2284     # a Unicode release which includes this file?
2285     main::set_access('in_this_release', \%in_this_release);
2286
2287     sub _next_line;
2288     sub _next_line_with_remapped_range;
2289
2290     sub new {
2291         my $class = shift;
2292
2293         my $self = bless \do{ my $anonymous_scalar }, $class;
2294         my $addr = do { no overloading; pack 'J', $self; };
2295
2296         # Set defaults
2297         $handler{$addr} = \&main::process_generic_property_file;
2298         $non_skip{$addr} = 0;
2299         $skip{$addr} = undef;
2300         $has_missings_defaults{$addr} = $NO_DEFAULTS;
2301         $handle{$addr} = undef;
2302         $added_lines{$addr} = [ ];
2303         $remapped_lines{$addr} = [ ];
2304         $each_line_handler{$addr} = [ ];
2305         $eof_handler{$addr} = [ ];
2306         $errors{$addr} = { };
2307         $missings{$addr} = [ ];
2308         $early{$addr} = [ ];
2309         $optional{$addr} = [ ];
2310
2311         # Two positional parameters.
2312         return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
2313         $file{$addr} = main::internal_file_to_platform(shift);
2314         $first_released{$addr} = shift;
2315
2316         # The rest of the arguments are key => value pairs
2317         # %constructor_fields has been set up earlier to list all possible
2318         # ones.  Either set or push, depending on how the default has been set
2319         # up just above.
2320         my %args = @_;
2321         foreach my $key (keys %args) {
2322             my $argument = $args{$key};
2323
2324             # Note that the fields are the lower case of the constructor keys
2325             my $hash = $constructor_fields{lc $key};
2326             if (! defined $hash) {
2327                 Carp::my_carp_bug("Unrecognized parameters '$key => $argument' to new() for $self.  Skipped");
2328                 next;
2329             }
2330             if (ref $hash->{$addr} eq 'ARRAY') {
2331                 if (ref $argument eq 'ARRAY') {
2332                     foreach my $argument (@{$argument}) {
2333                         next if ! defined $argument;
2334                         push @{$hash->{$addr}}, $argument;
2335                     }
2336                 }
2337                 else {
2338                     push @{$hash->{$addr}}, $argument if defined $argument;
2339                 }
2340             }
2341             else {
2342                 $hash->{$addr} = $argument;
2343             }
2344             delete $args{$key};
2345         };
2346
2347         $non_skip{$addr} = 1 if $required_even_in_debug_skip{$addr};
2348
2349         # Convert 0 (meaning don't skip) to undef
2350         undef $skip{$addr} unless $skip{$addr};
2351
2352         # Handle the case where this file is optional
2353         my $pod_message_for_non_existent_optional = "";
2354         if ($optional{$addr}->@*) {
2355
2356             # First element is the pod message
2357             $pod_message_for_non_existent_optional
2358                                                 = shift $optional{$addr}->@*;
2359             # Convert a 0 'Optional' argument to an empty list to make later
2360             # code more concise.
2361             if (   $optional{$addr}->@*
2362                 && $optional{$addr}->@* == 1
2363                 && $optional{$addr}[0] ne ""
2364                 && $optional{$addr}[0] !~ /\D/
2365                 && $optional{$addr}[0] == 0)
2366             {
2367                 $optional{$addr} = [ ];
2368             }
2369             else {  # But if the only element doesn't evaluate to 0, make sure
2370                     # that this file is indeed considered optional below.
2371                 unshift $optional{$addr}->@*, 1;
2372             }
2373         }
2374
2375         my $progress;
2376         my $function_instead_of_file = 0;
2377
2378         # If we are compiling a Unicode release earlier than the file became
2379         # available, the constructor may have supplied a substitute
2380         if ($first_released{$addr} gt $v_version && $early{$addr}->@*) {
2381
2382             # Yes, we have a substitute, that we will use; mark it so
2383             unshift $early{$addr}->@*, 1;
2384
2385             # See the definition of %early for what the array elements mean.
2386             # If we have a property this defines, create a table and default
2387             # map for it now (at essentially compile time), so that it will be
2388             # available for the whole of run time.  (We will want to add this
2389             # name as an alias when we are using the official property name;
2390             # but this must be deferred until run(), because at construction
2391             # time the official names have yet to be defined.)
2392             if ($early{$addr}[2]) {
2393                 my $fate = ($property{$addr}
2394                             && $property{$addr} eq $early{$addr}[2])
2395                           ? $PLACEHOLDER
2396                           : $INTERNAL_ONLY;
2397                 my $prop_object = Property->new($early{$addr}[2],
2398                                                 Fate => $fate,
2399                                                 Perl_Extension => 1,
2400                                                 );
2401
2402                 # Use the default mapping for the regular property for this
2403                 # substitute one.
2404                 if (    defined $property{$addr}
2405                     &&  defined $default_mapping{$property{$addr}})
2406                 {
2407                     $prop_object
2408                         ->set_default_map($default_mapping{$property{$addr}});
2409                 }
2410             }
2411
2412             if (ref $early{$addr}[1] eq 'CODE') {
2413                 $function_instead_of_file = 1;
2414
2415                 # If the first element of the array is a code ref, the others
2416                 # are optional.
2417                 $handler{$addr} = $early{$addr}[1];
2418                 $property{$addr} = $early{$addr}[2]
2419                                                 if defined $early{$addr}[2];
2420                 $progress = "substitute $file{$addr}";
2421
2422                 undef $file{$addr};
2423             }
2424             else {  # Specifying a substitute file
2425
2426                 if (! main::file_exists($early{$addr}[1])) {
2427
2428                     # If we don't see the substitute file, generate an error
2429                     # message giving the needed things, and add it to the list
2430                     # of such to output before actual processing happens
2431                     # (hence the user finds out all of them in one run).
2432                     # Instead of creating a general method for NameAliases,
2433                     # hard-code it here, as there is unlikely to ever be a
2434                     # second one which needs special handling.
2435                     my $string_version = ($file{$addr} eq "NameAliases.txt")
2436                                     ? 'at least 6.1 (the later, the better)'
2437                                     : sprintf "%vd", $first_released{$addr};
2438                     push @missing_early_files, <<END;
2439 '$file{$addr}' version $string_version should be copied to '$early{$addr}[1]'.
2440 END
2441                     ;
2442                     return;
2443                 }
2444                 $progress = $early{$addr}[1];
2445                 $progress .= ", substituting for $file{$addr}" if $file{$addr};
2446                 $file{$addr} = $early{$addr}[1];
2447                 $property{$addr} = $early{$addr}[2];
2448
2449                 # Ignore code points not in the version being compiled
2450                 push $each_line_handler{$addr}->@*, \&_exclude_unassigned;
2451
2452                 if (   $v_version lt v2.0        # Hanguls in this release ...
2453                     && defined $early{$addr}[3]) # ... need special treatment
2454                 {
2455                     push $eof_handler{$addr}->@*, \&_fixup_obsolete_hanguls;
2456                 }
2457             }
2458
2459             # And this substitute is valid for all releases.
2460             $first_released{$addr} = v0;
2461         }
2462         else {  # Normal behavior
2463             $progress = $file{$addr};
2464             unshift $early{$addr}->@*, 0; # No substitute
2465         }
2466
2467         my $file = $file{$addr};
2468         $progress_message{$addr} = "Processing $progress"
2469                                             unless $progress_message{$addr};
2470
2471         # A file should be there if it is within the window of versions for
2472         # which Unicode supplies it
2473         if ($withdrawn{$addr} && $withdrawn{$addr} le $v_version) {
2474             $in_this_release{$addr} = 0;
2475             $skip{$addr} = "";
2476         }
2477         else {
2478             $in_this_release{$addr} = $first_released{$addr} le $v_version;
2479
2480             # Check that the file for this object (possibly using a substitute
2481             # for early releases) exists or we have a function alternative
2482             if (   ! $function_instead_of_file
2483                 && ! main::file_exists($file))
2484             {
2485                 # Here there is nothing available for this release.  This is
2486                 # fine if we aren't expecting anything in this release.
2487                 if (! $in_this_release{$addr}) {
2488                     $skip{$addr} = "";  # Don't remark since we expected
2489                                         # nothing and got nothing
2490                 }
2491                 elsif ($optional{$addr}->@*) {
2492
2493                     # Here the file is optional in this release; Use the
2494                     # passed in text to document this case in the pod.
2495                     $skip{$addr} = $pod_message_for_non_existent_optional;
2496                 }
2497                 elsif (   $in_this_release{$addr}
2498                        && ! defined $skip{$addr}
2499                        && defined $file)
2500                 { # Doesn't exist but should.
2501                     $skip{$addr} = "'$file' not found.  Possibly Big problems";
2502                     Carp::my_carp($skip{$addr});
2503                 }
2504             }
2505             elsif ($debug_skip && ! defined $skip{$addr} && ! $non_skip{$addr})
2506             {
2507
2508                 # The file exists; if not skipped for another reason, and we are
2509                 # skipping most everything during debugging builds, use that as
2510                 # the skip reason.
2511                 $skip{$addr} = '$debug_skip is on'
2512             }
2513         }
2514
2515         if (   ! $debug_skip
2516             && $non_skip{$addr}
2517             && ! $required_even_in_debug_skip{$addr}
2518             && $verbosity)
2519         {
2520             print "Warning: " . __PACKAGE__ . " constructor for $file has useless 'non_skip' in it\n";
2521         }
2522
2523         # Here, we have figured out if we will be skipping this file or not.
2524         # If so, we add any single property it defines to any passed in
2525         # optional property list.  These will be dealt with at run time.
2526         if (defined $skip{$addr}) {
2527             if ($property{$addr}) {
2528                 push $optional{$addr}->@*, $property{$addr};
2529             }
2530         } # Otherwise, are going to process the file.
2531         elsif ($property{$addr}) {
2532
2533             # If the file has a property defined in the constructor for it, it
2534             # means that the property is not listed in the file's entries.  So
2535             # add a handler (to the list of line handlers) to insert the
2536             # property name into the lines, to provide a uniform interface to
2537             # the final processing subroutine.
2538             push @{$each_line_handler{$addr}}, \&_insert_property_into_line;
2539         }
2540         elsif ($properties{$addr}) {
2541
2542             # Similarly, there may be more than one property represented on
2543             # each line, with no clue but the constructor input what those
2544             # might be.  Add a handler for each line in the input so that it
2545             # creates a separate input line for each property in those input
2546             # lines, thus making them suitable to handle generically.
2547
2548             push @{$each_line_handler{$addr}},
2549                  sub {
2550                     my $file = shift;
2551                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2552
2553                     my @fields = split /\s*;\s*/, $_, -1;
2554
2555                     if (@fields - 1 > @{$properties{$addr}}) {
2556                         $file->carp_bad_line('Extra fields');
2557                         $_ = "";
2558                         return;
2559                     }
2560                     my $range = shift @fields;  # 0th element is always the
2561                                                 # range
2562
2563                     # The next fields in the input line correspond
2564                     # respectively to the stored properties.
2565                     for my $i (0 ..  @{$properties{$addr}} - 1) {
2566                         my $property_name = $properties{$addr}[$i];
2567                         next if $property_name eq '<ignored>';
2568                         $file->insert_adjusted_lines(
2569                               "$range; $property_name; $fields[$i]");
2570                     }
2571                     $_ = "";
2572
2573                     return;
2574                 };
2575         }
2576
2577         {   # On non-ascii platforms, we use a special pre-handler
2578             no strict;
2579             no warnings 'once';
2580             *next_line = (main::NON_ASCII_PLATFORM)
2581                          ? *_next_line_with_remapped_range
2582                          : *_next_line;
2583         }
2584
2585         &{$construction_time_handler{$addr}}($self)
2586                                         if $construction_time_handler{$addr};
2587
2588         return $self;
2589     }
2590
2591
2592     use overload
2593         fallback => 0,
2594         qw("") => "_operator_stringify",
2595         "." => \&main::_operator_dot,
2596         ".=" => \&main::_operator_dot_equal,
2597     ;
2598
2599     sub _operator_stringify {
2600         my $self = shift;
2601
2602         return __PACKAGE__ . " object for " . $self->file;
2603     }
2604
2605     sub run {
2606         # Process the input object $self.  This opens and closes the file and
2607         # calls all the handlers for it.  Currently,  this can only be called
2608         # once per file, as it destroy's the EOF handlers
2609
2610         # flag to make sure extracted files are processed early
2611         state $seen_non_extracted_non_age = 0;
2612
2613         my $self = shift;
2614         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2615
2616         my $addr = do { no overloading; pack 'J', $self; };
2617
2618         my $file = $file{$addr};
2619
2620         if (! $file) {
2621             $handle{$addr} = 'pretend_is_open';
2622         }
2623         else {
2624             if ($seen_non_extracted_non_age) {
2625                 if ($file =~ /$EXTRACTED/i) # Some platforms may change the
2626                                             # case of the file's name
2627                 {
2628                     Carp::my_carp_bug(main::join_lines(<<END
2629 $file should be processed just after the 'Prop...Alias' files, and before
2630 anything not in the $EXTRACTED_DIR directory.  Proceeding, but the results may
2631 have subtle problems
2632 END
2633                     ));
2634                 }
2635             }
2636             elsif ($EXTRACTED_DIR
2637
2638                     # We only do this check for generic property files
2639                     && $handler{$addr} == \&main::process_generic_property_file
2640
2641                     && $file !~ /$EXTRACTED/i
2642                     && lc($file) ne 'dage.txt')
2643             {
2644                 # We don't set this (by the 'if' above) if we have no
2645                 # extracted directory, so if running on an early version,
2646                 # this test won't work.  Not worth worrying about.
2647                 $seen_non_extracted_non_age = 1;
2648             }
2649
2650             # Mark the file as having being processed, and warn if it
2651             # isn't a file we are expecting.  As we process the files,
2652             # they are deleted from the hash, so any that remain at the
2653             # end of the program are files that we didn't process.
2654             my $fkey = File::Spec->rel2abs($file);
2655             my $exists = delete $potential_files{lc($fkey)};
2656
2657             Carp::my_carp("Was not expecting '$file'.")
2658                                     if $exists && ! $in_this_release{$addr};
2659
2660             # If there is special handling for compiling Unicode releases
2661             # earlier than the first one in which Unicode defines this
2662             # property ...
2663             if ($early{$addr}->@* > 1) {
2664
2665                 # Mark as processed any substitute file that would be used in
2666                 # such a release
2667                 $fkey = File::Spec->rel2abs($early{$addr}[1]);
2668                 delete $potential_files{lc($fkey)};
2669
2670                 # As commented in the constructor code, when using the
2671                 # official property, we still have to allow the publicly
2672                 # inaccessible early name so that the core code which uses it
2673                 # will work regardless.
2674                 if (! $early{$addr}[0] && $early{$addr}->@* > 2) {
2675                     my $early_property_name = $early{$addr}[2];
2676                     if ($property{$addr} ne $early_property_name) {
2677                         main::property_ref($property{$addr})
2678                                             ->add_alias($early_property_name);
2679                     }
2680                 }
2681             }
2682
2683             # We may be skipping this file ...
2684             if (defined $skip{$addr}) {
2685
2686                 # If the file isn't supposed to be in this release, there is
2687                 # nothing to do
2688                 if ($in_this_release{$addr}) {
2689
2690                     # But otherwise, we may print a message
2691                     if ($debug_skip) {
2692                         print STDERR "Skipping input file '$file'",
2693                                      " because '$skip{$addr}'\n";
2694                     }
2695
2696                     # And add it to the list of skipped files, which is later
2697                     # used to make the pod
2698                     $skipped_files{$file} = $skip{$addr};
2699
2700                     # The 'optional' list contains properties that are also to
2701                     # be skipped along with the file.  (There may also be
2702                     # digits which are just placeholders to make sure it isn't
2703                     # an empty list
2704                     foreach my $property ($optional{$addr}->@*) {
2705                         next unless $property =~ /\D/;
2706                         my $prop_object = main::property_ref($property);
2707                         next unless defined $prop_object;
2708                         $prop_object->set_fate($SUPPRESSED, $skip{$addr});
2709                     }
2710                 }
2711
2712                 return;
2713             }
2714
2715             # Here, we are going to process the file.  Open it, converting the
2716             # slashes used in this program into the proper form for the OS
2717             my $file_handle;
2718             if (not open $file_handle, "<", $file) {
2719                 Carp::my_carp("Can't open $file.  Skipping: $!");
2720                 return;
2721             }
2722             $handle{$addr} = $file_handle; # Cache the open file handle
2723
2724             # If possible, make sure that the file is the correct version.
2725             # (This data isn't available on early Unicode releases or in
2726             # UnicodeData.txt.)  We don't do this check if we are using a
2727             # substitute file instead of the official one (though the code
2728             # could be extended to do so).
2729             if ($in_this_release{$addr}
2730                 && ! $early{$addr}[0]
2731                 && lc($file) ne 'unicodedata.txt')
2732             {
2733                 if ($file !~ /^Unihan/i) {
2734
2735                     # The non-Unihan files started getting version numbers in
2736                     # 3.2, but some files in 4.0 are unchanged from 3.2, and
2737                     # marked as 3.2.  4.0.1 is the first version where there
2738                     # are no files marked as being from less than 4.0, though
2739                     # some are marked as 4.0.  In versions after that, the
2740                     # numbers are correct.
2741                     if ($v_version ge v4.0.1) {
2742                         $_ = <$file_handle>;    # The version number is in the
2743                                                 # very first line
2744                         if ($_ !~ / - $string_version \. /x) {
2745                             chomp;
2746                             $_ =~ s/^#\s*//;
2747
2748                             # 4.0.1 had some valid files that weren't updated.
2749                             if (! ($v_version eq v4.0.1 && $_ =~ /4\.0\.0/)) {
2750                                 die Carp::my_carp("File '$file' is version "
2751                                                 . "'$_'.  It should be "
2752                                                 . "version $string_version");
2753                             }
2754                         }
2755                     }
2756                 }
2757                 elsif ($v_version ge v6.0.0) { # Unihan
2758
2759                     # Unihan files didn't get accurate version numbers until
2760                     # 6.0.  The version is somewhere in the first comment
2761                     # block
2762                     while (<$file_handle>) {
2763                         if ($_ !~ /^#/) {
2764                             Carp::my_carp_bug("Could not find the expected "
2765                                             . "version info in file '$file'");
2766                             last;
2767                         }
2768                         chomp;
2769                         $_ =~ s/^#\s*//;
2770                         next if $_ !~ / version: /x;
2771                         last if $_ =~ /$string_version/;
2772                         die Carp::my_carp("File '$file' is version "
2773                                         . "'$_'.  It should be "
2774                                         . "version $string_version");
2775                     }
2776                 }
2777             }
2778         }
2779
2780         print "$progress_message{$addr}\n" if $verbosity >= $PROGRESS;
2781
2782         # Call any special handler for before the file.
2783         &{$pre_handler{$addr}}($self) if $pre_handler{$addr};
2784
2785         # Then the main handler
2786         &{$handler{$addr}}($self);
2787
2788         # Then any special post-file handler.
2789         &{$post_handler{$addr}}($self) if $post_handler{$addr};
2790
2791         # If any errors have been accumulated, output the counts (as the first
2792         # error message in each class was output when it was encountered).
2793         if ($errors{$addr}) {
2794             my $total = 0;
2795             my $types = 0;
2796             foreach my $error (keys %{$errors{$addr}}) {
2797                 $total += $errors{$addr}->{$error};
2798                 delete $errors{$addr}->{$error};
2799                 $types++;
2800             }
2801             if ($total > 1) {
2802                 my $message
2803                         = "A total of $total lines had errors in $file.  ";
2804
2805                 $message .= ($types == 1)
2806                             ? '(Only the first one was displayed.)'
2807                             : '(Only the first of each type was displayed.)';
2808                 Carp::my_carp($message);
2809             }
2810         }
2811
2812         if (@{$missings{$addr}}) {
2813             Carp::my_carp_bug("Handler for $file didn't look at all the \@missing lines.  Generated tables likely are wrong");
2814         }
2815
2816         # If a real file handle, close it.
2817         close $handle{$addr} or Carp::my_carp("Can't close $file: $!") if
2818                                                         ref $handle{$addr};
2819         $handle{$addr} = "";   # Uses empty to indicate that has already seen
2820                                # the file, as opposed to undef
2821         return;
2822     }
2823
2824     sub _next_line {
2825         # Sets $_ to be the next logical input line, if any.  Returns non-zero
2826         # if such a line exists.  'logical' means that any lines that have
2827         # been added via insert_lines() will be returned in $_ before the file
2828         # is read again.
2829
2830         my $self = shift;
2831         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2832
2833         my $addr = do { no overloading; pack 'J', $self; };
2834
2835         # Here the file is open (or if the handle is not a ref, is an open
2836         # 'virtual' file).  Get the next line; any inserted lines get priority
2837         # over the file itself.
2838         my $adjusted;
2839
2840         LINE:
2841         while (1) { # Loop until find non-comment, non-empty line
2842             #local $to_trace = 1 if main::DEBUG;
2843             my $inserted_ref = shift @{$added_lines{$addr}};
2844             if (defined $inserted_ref) {
2845                 ($adjusted, $_) = @{$inserted_ref};
2846                 trace $adjusted, $_ if main::DEBUG && $to_trace;
2847                 return 1 if $adjusted;
2848             }
2849             else {
2850                 last if ! ref $handle{$addr}; # Don't read unless is real file
2851                 last if ! defined ($_ = readline $handle{$addr});
2852             }
2853             chomp;
2854             trace $_ if main::DEBUG && $to_trace;
2855
2856             # See if this line is the comment line that defines what property
2857             # value that code points that are not listed in the file should
2858             # have.  The format or existence of these lines is not guaranteed
2859             # by Unicode since they are comments, but the documentation says
2860             # that this was added for machine-readability, so probably won't
2861             # change.  This works starting in Unicode Version 5.0.  They look
2862             # like:
2863             #
2864             # @missing: 0000..10FFFF; Not_Reordered
2865             # @missing: 0000..10FFFF; Decomposition_Mapping; <code point>
2866             # @missing: 0000..10FFFF; ; NaN
2867             #
2868             # Save the line for a later get_missings() call.
2869             if (/$missing_defaults_prefix/) {
2870                 if ($has_missings_defaults{$addr} == $NO_DEFAULTS) {
2871                     $self->carp_bad_line("Unexpected \@missing line.  Assuming no missing entries");
2872                 }
2873                 elsif ($has_missings_defaults{$addr} == $NOT_IGNORED) {
2874                     my @defaults = split /\s* ; \s*/x, $_;
2875
2876                     # The first field is the @missing, which ends in a
2877                     # semi-colon, so can safely shift.
2878                     shift @defaults;
2879
2880                     # Some of these lines may have empty field placeholders
2881                     # which get in the way.  An example is:
2882                     # @missing: 0000..10FFFF; ; NaN
2883                     # Remove them.  Process starting from the top so the
2884                     # splice doesn't affect things still to be looked at.
2885                     for (my $i = @defaults - 1; $i >= 0; $i--) {
2886                         next if $defaults[$i] ne "";
2887                         splice @defaults, $i, 1;
2888                     }
2889
2890                     # What's left should be just the property (maybe) and the
2891                     # default.  Having only one element means it doesn't have
2892                     # the property.
2893                     my $default;
2894                     my $property;
2895                     if (@defaults >= 1) {
2896                         if (@defaults == 1) {
2897                             $default = $defaults[0];
2898                         }
2899                         else {
2900                             $property = $defaults[0];
2901                             $default = $defaults[1];
2902                         }
2903                     }
2904
2905                     if (@defaults < 1
2906                         || @defaults > 2
2907                         || ($default =~ /^</
2908                             && $default !~ /^<code *point>$/i
2909                             && $default !~ /^<none>$/i
2910                             && $default !~ /^<script>$/i))
2911                     {
2912                         $self->carp_bad_line("Unrecognized \@missing line: $_.  Assuming no missing entries");
2913                     }
2914                     else {
2915
2916                         # If the property is missing from the line, it should
2917                         # be the one for the whole file
2918                         $property = $property{$addr} if ! defined $property;
2919
2920                         # Change <none> to the null string, which is what it
2921                         # really means.  If the default is the code point
2922                         # itself, set it to <code point>, which is what
2923                         # Unicode uses (but sometimes they've forgotten the
2924                         # space)
2925                         if ($default =~ /^<none>$/i) {
2926                             $default = "";
2927                         }
2928                         elsif ($default =~ /^<code *point>$/i) {
2929                             $default = $CODE_POINT;
2930                         }
2931                         elsif ($default =~ /^<script>$/i) {
2932
2933                             # Special case this one.  Currently is from
2934                             # ScriptExtensions.txt, and means for all unlisted
2935                             # code points, use their Script property values.
2936                             # For the code points not listed in that file, the
2937                             # default value is 'Unknown'.
2938                             $default = "Unknown";
2939                         }
2940
2941                         # Store them as a sub-arrays with both components.
2942                         push @{$missings{$addr}}, [ $default, $property ];
2943                     }
2944                 }
2945
2946                 # There is nothing for the caller to process on this comment
2947                 # line.
2948                 next;
2949             }
2950
2951             # Remove comments and trailing space, and skip this line if the
2952             # result is empty
2953             s/#.*//;
2954             s/\s+$//;
2955             next if /^$/;
2956
2957             # Call any handlers for this line, and skip further processing of
2958             # the line if the handler sets the line to null.
2959             foreach my $sub_ref (@{$each_line_handler{$addr}}) {
2960                 &{$sub_ref}($self);
2961                 next LINE if /^$/;
2962             }
2963
2964             # Here the line is ok.  return success.
2965             return 1;
2966         } # End of looping through lines.
2967
2968         # If there are EOF handlers, call each (only once) and if it generates
2969         # more lines to process go back in the loop to handle them.
2970         while ($eof_handler{$addr}->@*) {
2971             &{$eof_handler{$addr}[0]}($self);
2972             shift $eof_handler{$addr}->@*;   # Currently only get one shot at it.
2973             goto LINE if $added_lines{$addr};
2974         }
2975
2976         # Return failure -- no more lines.
2977         return 0;
2978
2979     }
2980
2981     sub _next_line_with_remapped_range {
2982         my $self = shift;
2983         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2984
2985         # like _next_line(), but for use on non-ASCII platforms.  It sets $_
2986         # to be the next logical input line, if any.  Returns non-zero if such
2987         # a line exists.  'logical' means that any lines that have been added
2988         # via insert_lines() will be returned in $_ before the file is read
2989         # again.
2990         #
2991         # The difference from _next_line() is that this remaps the Unicode
2992         # code points in the input to those of the native platform.  Each
2993         # input line contains a single code point, or a single contiguous
2994         # range of them  This routine splits each range into its individual
2995         # code points and caches them.  It returns the cached values,
2996         # translated into their native equivalents, one at a time, for each
2997         # call, before reading the next line.  Since native values can only be
2998         # a single byte wide, no translation is needed for code points above
2999         # 0xFF, and ranges that are entirely above that number are not split.
3000         # If an input line contains the range 254-1000, it would be split into
3001         # three elements: 254, 255, and 256-1000.  (The downstream table
3002         # insertion code will sort and coalesce the individual code points
3003         # into appropriate ranges.)
3004
3005         my $addr = do { no overloading; pack 'J', $self; };
3006
3007         while (1) {
3008
3009             # Look in cache before reading the next line.  Return any cached
3010             # value, translated
3011             my $inserted = shift @{$remapped_lines{$addr}};
3012             if (defined $inserted) {
3013                 trace $inserted if main::DEBUG && $to_trace;
3014                 $_ = $inserted =~ s/^ ( \d+ ) /sprintf("%04X", utf8::unicode_to_native($1))/xer;
3015                 trace $_ if main::DEBUG && $to_trace;
3016                 return 1;
3017             }
3018
3019             # Get the next line.
3020             return 0 unless _next_line($self);
3021
3022             # If there is a special handler for it, return the line,
3023             # untranslated.  This should happen only for files that are
3024             # special, not being code-point related, such as property names.
3025             return 1 if $handler{$addr}
3026                                     != \&main::process_generic_property_file;
3027
3028             my ($range, $property_name, $map, @remainder)
3029                 = split /\s*;\s*/, $_, -1; # -1 => retain trailing null fields
3030
3031             if (@remainder
3032                 || ! defined $property_name
3033                 || $range !~ /^ ($code_point_re) (?:\.\. ($code_point_re) )? $/x)
3034             {
3035                 Carp::my_carp_bug("Unrecognized input line '$_'.  Ignored");
3036             }
3037
3038             my $low = hex $1;
3039             my $high = (defined $2) ? hex $2 : $low;
3040
3041             # If the input maps the range to another code point, remap the
3042             # target if it is between 0 and 255.
3043             my $tail;
3044             if (defined $map) {
3045                 $map =~ s/\b 00 ( [0-9A-F]{2} ) \b/sprintf("%04X", utf8::unicode_to_native(hex $1))/gxe;
3046                 $tail = "$property_name; $map";
3047                 $_ = "$range; $tail";
3048             }
3049             else {
3050                 $tail = $property_name;
3051             }
3052
3053             # If entire range is above 255, just return it, unchanged (except
3054             # any mapped-to code point, already changed above)
3055             return 1 if $low > 255;
3056
3057             # Cache an entry for every code point < 255.  For those in the
3058             # range above 255, return a dummy entry for just that portion of
3059             # the range.  Note that this will be out-of-order, but that is not
3060             # a problem.
3061             foreach my $code_point ($low .. $high) {
3062                 if ($code_point > 255) {
3063                     $_ = sprintf "%04X..%04X; $tail", $code_point, $high;
3064                     return 1;
3065                 }
3066                 push @{$remapped_lines{$addr}}, "$code_point; $tail";
3067             }
3068         } # End of looping through lines.
3069
3070         # NOTREACHED
3071     }
3072
3073 #   Not currently used, not fully tested.
3074 #    sub peek {
3075 #        # Non-destructive look-ahead one non-adjusted, non-comment, non-blank
3076 #        # record.  Not callable from an each_line_handler(), nor does it call
3077 #        # an each_line_handler() on the line.
3078 #
3079 #        my $self = shift;
3080 #        my $addr = do { no overloading; pack 'J', $self; };
3081 #
3082 #        foreach my $inserted_ref (@{$added_lines{$addr}}) {
3083 #            my ($adjusted, $line) = @{$inserted_ref};
3084 #            next if $adjusted;
3085 #
3086 #            # Remove comments and trailing space, and return a non-empty
3087 #            # resulting line
3088 #            $line =~ s/#.*//;
3089 #            $line =~ s/\s+$//;
3090 #            return $line if $line ne "";
3091 #        }
3092 #
3093 #        return if ! ref $handle{$addr}; # Don't read unless is real file
3094 #        while (1) { # Loop until find non-comment, non-empty line
3095 #            local $to_trace = 1 if main::DEBUG;
3096 #            trace $_ if main::DEBUG && $to_trace;
3097 #            return if ! defined (my $line = readline $handle{$addr});
3098 #            chomp $line;
3099 #            push @{$added_lines{$addr}}, [ 0, $line ];
3100 #
3101 #            $line =~ s/#.*//;
3102 #            $line =~ s/\s+$//;
3103 #            return $line if $line ne "";
3104 #        }
3105 #
3106 #        return;
3107 #    }
3108
3109
3110     sub insert_lines {
3111         # Lines can be inserted so that it looks like they were in the input
3112         # file at the place it was when this routine is called.  See also
3113         # insert_adjusted_lines().  Lines inserted via this routine go through
3114         # any each_line_handler()
3115
3116         my $self = shift;
3117
3118         # Each inserted line is an array, with the first element being 0 to
3119         # indicate that this line hasn't been adjusted, and needs to be
3120         # processed.
3121         no overloading;
3122         push @{$added_lines{pack 'J', $self}}, map { [ 0, $_ ] } @_;
3123         return;
3124     }
3125
3126     sub insert_adjusted_lines {
3127         # Lines can be inserted so that it looks like they were in the input
3128         # file at the place it was when this routine is called.  See also
3129         # insert_lines().  Lines inserted via this routine are already fully
3130         # adjusted, ready to be processed; each_line_handler()s handlers will
3131         # not be called.  This means this is not a completely general
3132         # facility, as only the last each_line_handler on the stack should
3133         # call this.  It could be made more general, by passing to each of the
3134         # line_handlers their position on the stack, which they would pass on
3135         # to this routine, and that would replace the boolean first element in
3136         # the anonymous array pushed here, so that the next_line routine could
3137         # use that to call only those handlers whose index is after it on the
3138         # stack.  But this is overkill for what is needed now.
3139
3140         my $self = shift;
3141         trace $_[0] if main::DEBUG && $to_trace;
3142
3143         # Each inserted line is an array, with the first element being 1 to
3144         # indicate that this line has been adjusted
3145         no overloading;
3146         push @{$added_lines{pack 'J', $self}}, map { [ 1, $_ ] } @_;
3147         return;
3148     }
3149
3150     sub get_missings {
3151         # Returns the stored up @missings lines' values, and clears the list.
3152         # The values are in an array, consisting of the default in the first
3153         # element, and the property in the 2nd.  However, since these lines
3154         # can be stacked up, the return is an array of all these arrays.
3155
3156         my $self = shift;
3157         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3158
3159         my $addr = do { no overloading; pack 'J', $self; };
3160
3161         # If not accepting a list return, just return the first one.
3162         return shift @{$missings{$addr}} unless wantarray;
3163
3164         my @return = @{$missings{$addr}};
3165         undef @{$missings{$addr}};
3166         return @return;
3167     }
3168
3169     sub _exclude_unassigned {
3170
3171         # Takes the range in $_ and excludes code points that aren't assigned
3172         # in this release
3173
3174         state $skip_inserted_count = 0;
3175
3176         # Ignore recursive calls.
3177         if ($skip_inserted_count) {
3178             $skip_inserted_count--;
3179             return;
3180         }
3181
3182         # Find what code points are assigned in this release
3183         main::calculate_Assigned() if ! defined $Assigned;
3184
3185         my $self = shift;
3186         my $addr = do { no overloading; pack 'J', $self; };
3187         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3188
3189         my ($range, @remainder)
3190             = split /\s*;\s*/, $_, -1; # -1 => retain trailing null fields
3191
3192         # Examine the range.
3193         if ($range =~ /^ ($code_point_re) (?:\.\. ($code_point_re) )? $/x)
3194         {
3195             my $low = hex $1;
3196             my $high = (defined $2) ? hex $2 : $low;
3197
3198             # Split the range into subranges of just those code points in it
3199             # that are assigned.
3200             my @ranges = (Range_List->new(Initialize
3201                               => Range->new($low, $high)) & $Assigned)->ranges;
3202
3203             # Do nothing if nothing in the original range is assigned in this
3204             # release; handle normally if everything is in this release.
3205             if (! @ranges) {
3206                 $_ = "";
3207             }
3208             elsif (@ranges != 1) {
3209
3210                 # Here, some code points in the original range aren't in this
3211                 # release; @ranges gives the ones that are.  Create fake input
3212                 # lines for each of the ranges, and set things up so that when
3213                 # this routine is called on that fake input, it will do
3214                 # nothing.
3215                 $skip_inserted_count = @ranges;
3216                 my $remainder = join ";", @remainder;
3217                 for my $range (@ranges) {
3218                     $self->insert_lines(sprintf("%04X..%04X;%s",
3219                                     $range->start, $range->end, $remainder));
3220                 }
3221                 $_ = "";    # The original range is now defunct.
3222             }
3223         }
3224
3225         return;
3226     }
3227
3228     sub _fixup_obsolete_hanguls {
3229
3230         # This is called only when compiling Unicode version 1.  All Unicode
3231         # data for subsequent releases assumes that the code points that were
3232         # Hangul syllables in this release only are something else, so if
3233         # using such data, we have to override it
3234
3235         my $self = shift;
3236         my $addr = do { no overloading; pack 'J', $self; };
3237         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3238
3239         my $object = main::property_ref($property{$addr});
3240         $object->add_map($FIRST_REMOVED_HANGUL_SYLLABLE,
3241                          $FINAL_REMOVED_HANGUL_SYLLABLE,
3242                          $early{$addr}[3],  # Passed-in value for these
3243                          Replace => $UNCONDITIONALLY);
3244     }
3245
3246     sub _insert_property_into_line {
3247         # Add a property field to $_, if this file requires it.
3248
3249         my $self = shift;
3250         my $addr = do { no overloading; pack 'J', $self; };
3251         my $property = $property{$addr};
3252         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3253
3254         $_ =~ s/(;|$)/; $property$1/;
3255         return;
3256     }
3257
3258     sub carp_bad_line {
3259         # Output consistent error messages, using either a generic one, or the
3260         # one given by the optional parameter.  To avoid gazillions of the
3261         # same message in case the syntax of a  file is way off, this routine
3262         # only outputs the first instance of each message, incrementing a
3263         # count so the totals can be output at the end of the file.
3264
3265         my $self = shift;
3266         my $message = shift;
3267         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3268
3269         my $addr = do { no overloading; pack 'J', $self; };
3270
3271         $message = 'Unexpected line' unless $message;
3272
3273         # No trailing punctuation so as to fit with our addenda.
3274         $message =~ s/[.:;,]$//;
3275
3276         # If haven't seen this exact message before, output it now.  Otherwise
3277         # increment the count of how many times it has occurred
3278         unless ($errors{$addr}->{$message}) {
3279             Carp::my_carp("$message in '$_' in "
3280                             . $file{$addr}
3281                             . " at line $..  Skipping this line;");
3282             $errors{$addr}->{$message} = 1;
3283         }
3284         else {
3285             $errors{$addr}->{$message}++;
3286         }
3287
3288         # Clear the line to prevent any further (meaningful) processing of it.
3289         $_ = "";
3290
3291         return;
3292     }
3293 } # End closure
3294
3295 package Multi_Default;
3296
3297 # Certain properties in early versions of Unicode had more than one possible
3298 # default for code points missing from the files.  In these cases, one
3299 # default applies to everything left over after all the others are applied,
3300 # and for each of the others, there is a description of which class of code
3301 # points applies to it.  This object helps implement this by storing the
3302 # defaults, and for all but that final default, an eval string that generates
3303 # the class that it applies to.
3304
3305
3306 {   # Closure
3307
3308     main::setup_package();
3309
3310     my %class_defaults;
3311     # The defaults structure for the classes
3312     main::set_access('class_defaults', \%class_defaults);
3313
3314     my %other_default;
3315     # The default that applies to everything left over.
3316     main::set_access('other_default', \%other_default, 'r');
3317
3318
3319     sub new {
3320         # The constructor is called with default => eval pairs, terminated by
3321         # the left-over default. e.g.
3322         # Multi_Default->new(
3323         #        'T' => '$gc->table("Mn") + $gc->table("Cf") - 0x200C
3324         #               -  0x200D',
3325         #        'R' => 'some other expression that evaluates to code points',
3326         #        .
3327         #        .
3328         #        .
3329         #        'U'));
3330         # It is best to leave the final value be the one that matches the
3331         # above-Unicode code points.
3332
3333         my $class = shift;
3334
3335         my $self = bless \do{my $anonymous_scalar}, $class;
3336         my $addr = do { no overloading; pack 'J', $self; };
3337
3338         while (@_ > 1) {
3339             my $default = shift;
3340             my $eval = shift;
3341             $class_defaults{$addr}->{$default} = $eval;
3342         }
3343
3344         $other_default{$addr} = shift;
3345
3346         return $self;
3347     }
3348
3349     sub get_next_defaults {
3350         # Iterates and returns the next class of defaults.
3351         my $self = shift;
3352         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3353
3354         my $addr = do { no overloading; pack 'J', $self; };
3355
3356         return each %{$class_defaults{$addr}};
3357     }
3358 }
3359
3360 package Alias;
3361
3362 # An alias is one of the names that a table goes by.  This class defines them
3363 # including some attributes.  Everything is currently setup in the
3364 # constructor.
3365
3366
3367 {   # Closure
3368
3369     main::setup_package();
3370
3371     my %name;
3372     main::set_access('name', \%name, 'r');
3373
3374     my %loose_match;
3375     # Should this name match loosely or not.
3376     main::set_access('loose_match', \%loose_match, 'r');
3377
3378     my %make_re_pod_entry;
3379     # Some aliases should not get their own entries in the re section of the
3380     # pod, because they are covered by a wild-card, and some we want to
3381     # discourage use of.  Binary
3382     main::set_access('make_re_pod_entry', \%make_re_pod_entry, 'r', 's');
3383
3384     my %ucd;
3385     # Is this documented to be accessible via Unicode::UCD
3386     main::set_access('ucd', \%ucd, 'r', 's');
3387
3388     my %status;
3389     # Aliases have a status, like deprecated, or even suppressed (which means
3390     # they don't appear in documentation).  Enum
3391     main::set_access('status', \%status, 'r');
3392
3393     my %ok_as_filename;
3394     # Similarly, some aliases should not be considered as usable ones for
3395     # external use, such as file names, or we don't want documentation to
3396     # recommend them.  Boolean
3397     main::set_access('ok_as_filename', \%ok_as_filename, 'r');
3398
3399     sub new {
3400         my $class = shift;
3401
3402         my $self = bless \do { my $anonymous_scalar }, $class;
3403         my $addr = do { no overloading; pack 'J', $self; };
3404
3405         $name{$addr} = shift;
3406         $loose_match{$addr} = shift;
3407         $make_re_pod_entry{$addr} = shift;
3408         $ok_as_filename{$addr} = shift;
3409         $status{$addr} = shift;
3410         $ucd{$addr} = shift;
3411
3412         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3413
3414         # Null names are never ok externally
3415         $ok_as_filename{$addr} = 0 if $name{$addr} eq "";
3416
3417         return $self;
3418     }
3419 }
3420
3421 package Range;
3422
3423 # A range is the basic unit for storing code points, and is described in the
3424 # comments at the beginning of the program.  Each range has a starting code
3425 # point; an ending code point (not less than the starting one); a value
3426 # that applies to every code point in between the two end-points, inclusive;
3427 # and an enum type that applies to the value.  The type is for the user's
3428 # convenience, and has no meaning here, except that a non-zero type is
3429 # considered to not obey the normal Unicode rules for having standard forms.
3430 #
3431 # The same structure is used for both map and match tables, even though in the
3432 # latter, the value (and hence type) is irrelevant and could be used as a
3433 # comment.  In map tables, the value is what all the code points in the range
3434 # map to.  Type 0 values have the standardized version of the value stored as
3435 # well, so as to not have to recalculate it a lot.
3436
3437 sub trace { return main::trace(@_); }
3438
3439 {   # Closure
3440
3441     main::setup_package();
3442
3443     my %start;
3444     main::set_access('start', \%start, 'r', 's');
3445
3446     my %end;
3447     main::set_access('end', \%end, 'r', 's');
3448
3449     my %value;
3450     main::set_access('value', \%value, 'r');
3451
3452     my %type;
3453     main::set_access('type', \%type, 'r');
3454
3455     my %standard_form;
3456     # The value in internal standard form.  Defined only if the type is 0.
3457     main::set_access('standard_form', \%standard_form);
3458
3459     # Note that if these fields change, the dump() method should as well
3460
3461     sub new {
3462         return Carp::carp_too_few_args(\@_, 3) if main::DEBUG && @_ < 3;
3463         my $class = shift;
3464
3465         my $self = bless \do { my $anonymous_scalar }, $class;
3466         my $addr = do { no overloading; pack 'J', $self; };
3467
3468         $start{$addr} = shift;
3469         $end{$addr} = shift;
3470
3471         my %args = @_;
3472
3473         my $value = delete $args{'Value'};  # Can be 0
3474         $value = "" unless defined $value;
3475         $value{$addr} = $value;
3476
3477         $type{$addr} = delete $args{'Type'} || 0;
3478
3479         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3480
3481         return $self;
3482     }
3483
3484     use overload
3485         fallback => 0,
3486         qw("") => "_operator_stringify",
3487         "." => \&main::_operator_dot,
3488         ".=" => \&main::_operator_dot_equal,
3489     ;
3490
3491     sub _operator_stringify {
3492         my $self = shift;
3493         my $addr = do { no overloading; pack 'J', $self; };
3494
3495         # Output it like '0041..0065 (value)'
3496         my $return = sprintf("%04X", $start{$addr})
3497                         .  '..'
3498                         . sprintf("%04X", $end{$addr});
3499         my $value = $value{$addr};
3500         my $type = $type{$addr};
3501         $return .= ' (';
3502         $return .= "$value";
3503         $return .= ", Type=$type" if $type != 0;
3504         $return .= ')';
3505
3506         return $return;
3507     }
3508
3509     sub standard_form {
3510         # Calculate the standard form only if needed, and cache the result.
3511         # The standard form is the value itself if the type is special.
3512         # This represents a considerable CPU and memory saving - at the time
3513         # of writing there are 368676 non-special objects, but the standard
3514         # form is only requested for 22047 of them - ie about 6%.
3515
3516         my $self = shift;
3517         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3518
3519         my $addr = do { no overloading; pack 'J', $self; };
3520
3521         return $standard_form{$addr} if defined $standard_form{$addr};
3522
3523         my $value = $value{$addr};
3524         return $value if $type{$addr};
3525         return $standard_form{$addr} = main::standardize($value);
3526     }
3527
3528     sub dump {
3529         # Human, not machine readable.  For machine readable, comment out this
3530         # entire routine and let the standard one take effect.
3531         my $self = shift;
3532         my $indent = shift;
3533         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3534
3535         my $addr = do { no overloading; pack 'J', $self; };
3536
3537         my $return = $indent
3538                     . sprintf("%04X", $start{$addr})
3539                     . '..'
3540                     . sprintf("%04X", $end{$addr})
3541                     . " '$value{$addr}';";
3542         if (! defined $standard_form{$addr}) {
3543             $return .= "(type=$type{$addr})";
3544         }
3545         elsif ($standard_form{$addr} ne $value{$addr}) {
3546             $return .= "(standard '$standard_form{$addr}')";
3547         }
3548         return $return;
3549     }
3550 } # End closure
3551
3552 package _Range_List_Base;
3553
3554 # Base class for range lists.  A range list is simply an ordered list of
3555 # ranges, so that the ranges with the lowest starting numbers are first in it.
3556 #
3557 # When a new range is added that is adjacent to an existing range that has the
3558 # same value and type, it merges with it to form a larger range.
3559 #
3560 # Ranges generally do not overlap, except that there can be multiple entries
3561 # of single code point ranges.  This is because of NameAliases.txt.
3562 #
3563 # In this program, there is a standard value such that if two different
3564 # values, have the same standard value, they are considered equivalent.  This
3565 # value was chosen so that it gives correct results on Unicode data
3566
3567 # There are a number of methods to manipulate range lists, and some operators
3568 # are overloaded to handle them.
3569
3570 sub trace { return main::trace(@_); }
3571
3572 { # Closure
3573
3574     our $addr;
3575
3576     # Max is initialized to a negative value that isn't adjacent to 0, for
3577     # simpler tests
3578     my $max_init = -2;
3579
3580     main::setup_package();
3581
3582     my %ranges;
3583     # The list of ranges
3584     main::set_access('ranges', \%ranges, 'readable_array');
3585
3586     my %max;
3587     # The highest code point in the list.  This was originally a method, but
3588     # actual measurements said it was used a lot.
3589     main::set_access('max', \%max, 'r');
3590
3591     my %each_range_iterator;
3592     # Iterator position for each_range()
3593     main::set_access('each_range_iterator', \%each_range_iterator);
3594
3595     my %owner_name_of;
3596     # Name of parent this is attached to, if any.  Solely for better error
3597     # messages.
3598     main::set_access('owner_name_of', \%owner_name_of, 'p_r');
3599
3600     my %_search_ranges_cache;
3601     # A cache of the previous result from _search_ranges(), for better
3602     # performance
3603     main::set_access('_search_ranges_cache', \%_search_ranges_cache);
3604
3605     sub new {
3606         my $class = shift;
3607         my %args = @_;
3608
3609         # Optional initialization data for the range list.
3610         my $initialize = delete $args{'Initialize'};
3611
3612         my $self;
3613
3614         # Use _union() to initialize.  _union() returns an object of this
3615         # class, which means that it will call this constructor recursively.
3616         # But it won't have this $initialize parameter so that it won't
3617         # infinitely loop on this.
3618         return _union($class, $initialize, %args) if defined $initialize;
3619
3620         $self = bless \do { my $anonymous_scalar }, $class;
3621         my $addr = do { no overloading; pack 'J', $self; };
3622
3623         # Optional parent object, only for debug info.
3624         $owner_name_of{$addr} = delete $args{'Owner'};
3625         $owner_name_of{$addr} = "" if ! defined $owner_name_of{$addr};
3626
3627         # Stringify, in case it is an object.
3628         $owner_name_of{$addr} = "$owner_name_of{$addr}";
3629
3630         # This is used only for error messages, and so a colon is added
3631         $owner_name_of{$addr} .= ": " if $owner_name_of{$addr} ne "";
3632
3633         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3634
3635         $max{$addr} = $max_init;
3636
3637         $_search_ranges_cache{$addr} = 0;
3638         $ranges{$addr} = [];
3639
3640         return $self;
3641     }
3642
3643     use overload
3644         fallback => 0,
3645         qw("") => "_operator_stringify",
3646         "." => \&main::_operator_dot,
3647         ".=" => \&main::_operator_dot_equal,
3648     ;
3649
3650     sub _operator_stringify {
3651         my $self = shift;
3652         my $addr = do { no overloading; pack 'J', $self; };
3653
3654         return "Range_List attached to '$owner_name_of{$addr}'"
3655                                                 if $owner_name_of{$addr};
3656         return "anonymous Range_List " . \$self;
3657     }
3658
3659     sub _union {
3660         # Returns the union of the input code points.  It can be called as
3661         # either a constructor or a method.  If called as a method, the result
3662         # will be a new() instance of the calling object, containing the union
3663         # of that object with the other parameter's code points;  if called as
3664         # a constructor, the first parameter gives the class that the new object
3665         # should be, and the second parameter gives the code points to go into
3666         # it.
3667         # In either case, there are two parameters looked at by this routine;
3668         # any additional parameters are passed to the new() constructor.
3669         #
3670         # The code points can come in the form of some object that contains
3671         # ranges, and has a conventionally named method to access them; or
3672         # they can be an array of individual code points (as integers); or
3673         # just a single code point.
3674         #
3675         # If they are ranges, this routine doesn't make any effort to preserve
3676         # the range values and types of one input over the other.  Therefore
3677         # this base class should not allow _union to be called from other than
3678         # initialization code, so as to prevent two tables from being added
3679         # together where the range values matter.  The general form of this
3680         # routine therefore belongs in a derived class, but it was moved here
3681         # to avoid duplication of code.  The failure to overload this in this
3682         # class keeps it safe.
3683         #
3684         # It does make the effort during initialization to accept tables with
3685         # multiple values for the same code point, and to preserve the order
3686         # of these.  If there is only one input range or range set, it doesn't
3687         # sort (as it should already be sorted to the desired order), and will
3688         # accept multiple values per code point.  Otherwise it will merge
3689         # multiple values into a single one.
3690
3691         my $self;
3692         my @args;   # Arguments to pass to the constructor
3693
3694         my $class = shift;
3695
3696         # If a method call, will start the union with the object itself, and
3697         # the class of the new object will be the same as self.
3698         if (ref $class) {
3699             $self = $class;
3700             $class = ref $self;
3701             push @args, $self;
3702         }
3703
3704         # Add the other required parameter.
3705         push @args, shift;
3706         # Rest of parameters are passed on to the constructor
3707
3708         # Accumulate all records from both lists.
3709         my @records;
3710         my $input_count = 0;
3711         for my $arg (@args) {
3712             #local $to_trace = 0 if main::DEBUG;
3713             trace "argument = $arg" if main::DEBUG && $to_trace;
3714             if (! defined $arg) {
3715                 my $message = "";
3716                 if (defined $self) {
3717                     no overloading;
3718                     $message .= $owner_name_of{pack 'J', $self};
3719                 }
3720                 Carp::my_carp_bug($message . "Undefined argument to _union.  No union done.");
3721                 return;
3722             }
3723
3724             $arg = [ $arg ] if ! ref $arg;
3725             my $type = ref $arg;
3726             if ($type eq 'ARRAY') {
3727                 foreach my $element (@$arg) {
3728                     push @records, Range->new($element, $element);
3729                     $input_count++;
3730                 }
3731             }
3732             elsif ($arg->isa('Range')) {
3733                 push @records, $arg;
3734                 $input_count++;
3735             }
3736             elsif ($arg->can('ranges')) {
3737                 push @records, $arg->ranges;
3738                 $input_count++;
3739             }
3740             else {
3741                 my $message = "";
3742                 if (defined $self) {
3743                     no overloading;
3744                     $message .= $owner_name_of{pack 'J', $self};
3745                 }
3746                 Carp::my_carp_bug($message . "Cannot take the union of a $type.  No union done.");
3747                 return;
3748             }
3749         }
3750
3751         # Sort with the range containing the lowest ordinal first, but if
3752         # two ranges start at the same code point, sort with the bigger range
3753         # of the two first, because it takes fewer cycles.
3754         if ($input_count > 1) {
3755             @records = sort { ($a->start <=> $b->start)
3756                                       or
3757                                     # if b is shorter than a, b->end will be
3758                                     # less than a->end, and we want to select
3759                                     # a, so want to return -1
3760                                     ($b->end <=> $a->end)
3761                                    } @records;
3762         }
3763
3764         my $new = $class->new(@_);
3765
3766         # Fold in records so long as they add new information.
3767         for my $set (@records) {
3768             my $start = $set->start;
3769             my $end   = $set->end;
3770             my $value = $set->value;
3771             my $type  = $set->type;
3772             if ($start > $new->max) {
3773                 $new->_add_delete('+', $start, $end, $value, Type => $type);
3774             }
3775             elsif ($end > $new->max) {
3776                 $new->_add_delete('+', $new->max +1, $end, $value,
3777                                                                 Type => $type);
3778             }
3779             elsif ($input_count == 1) {
3780                 # Here, overlaps existing range, but is from a single input,
3781                 # so preserve the multiple values from that input.
3782                 $new->_add_delete('+', $start, $end, $value, Type => $type,
3783                                                 Replace => $MULTIPLE_AFTER);
3784             }
3785         }
3786
3787         return $new;
3788     }
3789
3790     sub range_count {        # Return the number of ranges in the range list
3791         my $self = shift;
3792         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3793
3794         no overloading;
3795         return scalar @{$ranges{pack 'J', $self}};
3796     }
3797
3798     sub min {
3799         # Returns the minimum code point currently in the range list, or if
3800         # the range list is empty, 2 beyond the max possible.  This is a
3801         # method because used so rarely, that not worth saving between calls,
3802         # and having to worry about changing it as ranges are added and
3803         # deleted.
3804
3805         my $self = shift;
3806         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3807
3808         my $addr = do { no overloading; pack 'J', $self; };
3809
3810         # If the range list is empty, return a large value that isn't adjacent
3811         # to any that could be in the range list, for simpler tests
3812         return $MAX_WORKING_CODEPOINT + 2 unless scalar @{$ranges{$addr}};
3813         return $ranges{$addr}->[0]->start;
3814     }
3815
3816     sub contains {
3817         # Boolean: Is argument in the range list?  If so returns $i such that:
3818         #   range[$i]->end < $codepoint <= range[$i+1]->end
3819         # which is one beyond what you want; this is so that the 0th range
3820         # doesn't return false
3821         my $self = shift;
3822         my $codepoint = shift;
3823         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3824
3825         my $i = $self->_search_ranges($codepoint);
3826         return 0 unless defined $i;
3827
3828         # The search returns $i, such that
3829         #   range[$i-1]->end < $codepoint <= range[$i]->end
3830         # So is in the table if and only iff it is at least the start position
3831         # of range $i.
3832         no overloading;
3833         return 0 if $ranges{pack 'J', $self}->[$i]->start > $codepoint;
3834         return $i + 1;
3835     }
3836
3837     sub containing_range {
3838         # Returns the range object that contains the code point, undef if none
3839
3840         my $self = shift;
3841         my $codepoint = shift;
3842         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3843
3844         my $i = $self->contains($codepoint);
3845         return unless $i;
3846
3847         # contains() returns 1 beyond where we should look
3848         no overloading;
3849         return $ranges{pack 'J', $self}->[$i-1];
3850     }
3851
3852     sub value_of {
3853         # Returns the value associated with the code point, undef if none
3854
3855         my $self = shift;
3856         my $codepoint = shift;
3857         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3858
3859         my $range = $self->containing_range($codepoint);
3860         return unless defined $range;
3861
3862         return $range->value;
3863     }
3864
3865     sub type_of {
3866         # Returns the type of the range containing the code point, undef if
3867         # the code point is not in the table
3868
3869         my $self = shift;
3870         my $codepoint = shift;
3871         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3872
3873         my $range = $self->containing_range($codepoint);
3874         return unless defined $range;
3875
3876         return $range->type;
3877     }
3878
3879     sub _search_ranges {
3880         # Find the range in the list which contains a code point, or where it
3881         # should go if were to add it.  That is, it returns $i, such that:
3882         #   range[$i-1]->end < $codepoint <= range[$i]->end
3883         # Returns undef if no such $i is possible (e.g. at end of table), or
3884         # if there is an error.
3885
3886         my $self = shift;
3887         my $code_point = shift;
3888         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3889
3890         my $addr = do { no overloading; pack 'J', $self; };
3891
3892         return if $code_point > $max{$addr};
3893         my $r = $ranges{$addr};                # The current list of ranges
3894         my $range_list_size = scalar @$r;
3895         my $i;
3896
3897         use integer;        # want integer division
3898
3899         # Use the cached result as the starting guess for this one, because,
3900         # an experiment on 5.1 showed that 90% of the time the cache was the
3901         # same as the result on the next call (and 7% it was one less).
3902         $i = $_search_ranges_cache{$addr};
3903         $i = 0 if $i >= $range_list_size;   # Reset if no longer valid (prob.
3904                                             # from an intervening deletion
3905         #local $to_trace = 1 if main::DEBUG;
3906         trace "previous \$i is still valid: $i" if main::DEBUG && $to_trace && $code_point <= $r->[$i]->end && ($i == 0 || $r->[$i-1]->end < $code_point);
3907         return $i if $code_point <= $r->[$i]->end
3908                      && ($i == 0 || $r->[$i-1]->end < $code_point);
3909
3910         # Here the cache doesn't yield the correct $i.  Try adding 1.
3911         if ($i < $range_list_size - 1
3912             && $r->[$i]->end < $code_point &&
3913             $code_point <= $r->[$i+1]->end)
3914         {
3915             $i++;
3916             trace "next \$i is correct: $i" if main::DEBUG && $to_trace;
3917             $_search_ranges_cache{$addr} = $i;
3918             return $i;
3919         }
3920
3921         # Here, adding 1 also didn't work.  We do a binary search to
3922         # find the correct position, starting with current $i
3923         my $lower = 0;
3924         my $upper = $range_list_size - 1;
3925         while (1) {
3926             trace "top of loop i=$i:", sprintf("%04X", $r->[$lower]->start), "[$lower] .. ", sprintf("%04X", $r->[$i]->start), "[$i] .. ", sprintf("%04X", $r->[$upper]->start), "[$upper]" if main::DEBUG && $to_trace;
3927
3928             if ($code_point <= $r->[$i]->end) {
3929
3930                 # Here we have met the upper constraint.  We can quit if we
3931                 # also meet the lower one.
3932                 last if $i == 0 || $r->[$i-1]->end < $code_point;
3933
3934                 $upper = $i;        # Still too high.
3935
3936             }
3937             else {
3938
3939                 # Here, $r[$i]->end < $code_point, so look higher up.
3940                 $lower = $i;
3941             }
3942
3943             # Split search domain in half to try again.
3944             my $temp = ($upper + $lower) / 2;
3945
3946             # No point in continuing unless $i changes for next time
3947             # in the loop.
3948             if ($temp == $i) {
3949
3950                 # We can't reach the highest element because of the averaging.
3951                 # So if one below the upper edge, force it there and try one
3952                 # more time.
3953                 if ($i == $range_list_size - 2) {
3954
3955                     trace "Forcing to upper edge" if main::DEBUG && $to_trace;
3956                     $i = $range_list_size - 1;
3957
3958                     # Change $lower as well so if fails next time through,
3959                     # taking the average will yield the same $i, and we will
3960                     # quit with the error message just below.
3961                     $lower = $i;
3962                     next;
3963                 }
3964                 Carp::my_carp_bug("$owner_name_of{$addr}Can't find where the range ought to go.  No action taken.");
3965                 return;
3966             }
3967             $i = $temp;
3968         } # End of while loop
3969
3970         if (main::DEBUG && $to_trace) {
3971             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i;
3972             trace "i=  [ $i ]", $r->[$i];
3973             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < $range_list_size - 1;
3974         }
3975
3976         # Here we have found the offset.  Cache it as a starting point for the
3977         # next call.
3978         $_search_ranges_cache{$addr} = $i;
3979         return $i;
3980     }
3981
3982     sub _add_delete {
3983         # Add, replace or delete ranges to or from a list.  The $type
3984         # parameter gives which:
3985         #   '+' => insert or replace a range, returning a list of any changed
3986         #          ranges.
3987         #   '-' => delete a range, returning a list of any deleted ranges.
3988         #
3989         # The next three parameters give respectively the start, end, and
3990         # value associated with the range.  'value' should be null unless the
3991         # operation is '+';
3992         #
3993         # The range list is kept sorted so that the range with the lowest
3994         # starting position is first in the list, and generally, adjacent
3995         # ranges with the same values are merged into a single larger one (see
3996         # exceptions below).
3997         #
3998         # There are more parameters; all are key => value pairs:
3999         #   Type    gives the type of the value.  It is only valid for '+'.
4000         #           All ranges have types; if this parameter is omitted, 0 is
4001         #           assumed.  Ranges with type 0 are assumed to obey the
4002         #           Unicode rules for casing, etc; ranges with other types are
4003         #           not.  Otherwise, the type is arbitrary, for the caller's
4004         #           convenience, and looked at only by this routine to keep
4005         #           adjacent ranges of different types from being merged into
4006         #           a single larger range, and when Replace =>
4007         #           $IF_NOT_EQUIVALENT is specified (see just below).
4008         #   Replace  determines what to do if the range list already contains
4009         #            ranges which coincide with all or portions of the input
4010         #            range.  It is only valid for '+':
4011         #       => $NO            means that the new value is not to replace
4012         #                         any existing ones, but any empty gaps of the
4013         #                         range list coinciding with the input range