This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
1861fd24866466b43f3e97d1afa27da8ad65346e
[perl5.git] / dist / B-Deparse / t / deparse.t
1 #!./perl
2
3 BEGIN {
4     unshift @INC, 't';
5     require Config;
6     if (($Config::Config{'extensions'} !~ /\bB\b/) ){
7         print "1..0 # Skip -- Perl configured without B module\n";
8         exit 0;
9     }
10 }
11
12 use warnings;
13 use strict;
14 use Test::More;
15
16 my $tests = 17; # not counting those in the __DATA__ section
17
18 use B::Deparse;
19 my $deparse = B::Deparse->new();
20 isa_ok($deparse, 'B::Deparse', 'instantiate a B::Deparse object');
21
22 $/ = "\n####\n";
23 while (<DATA>) {
24     chomp;
25     $tests ++;
26     # This code is pinched from the t/lib/common.pl for TODO.
27     # It's not clear how to avoid duplication
28     my %meta = (context => '');
29     foreach my $what (qw(skip todo context)) {
30         s/^#\s*\U$what\E\s*(.*)\n//m and $meta{$what} = $1;
31         # If the SKIP reason starts ? then it's taken as a code snippet to
32         # evaluate. This provides the flexibility to have conditional SKIPs
33         if ($meta{$what} && $meta{$what} =~ s/^\?//) {
34             my $temp = eval $meta{$what};
35             if ($@) {
36                 die "# In \U$what\E code reason:\n# $meta{$what}\n$@";
37             }
38             $meta{$what} = $temp;
39         }
40     }
41
42     s/^\s*#\s*(.*)$//mg;
43     my $desc = $1;
44     die "Missing name in test $_" unless defined $desc;
45
46     if ($meta{skip}) {
47         # Like this to avoid needing a label SKIP:
48         Test::More->builder->skip($meta{skip});
49         next;
50     }
51
52     my ($input, $expected);
53     if (/(.*)\n>>>>\n(.*)/s) {
54         ($input, $expected) = ($1, $2);
55     }
56     else {
57         ($input, $expected) = ($_, $_);
58     }
59
60     my $coderef = eval "$meta{context};\n" . <<'EOC' . "sub {$input}";
61 # Tell B::Deparse about our ambient pragmas
62 my ($hint_bits, $warning_bits, $hinthash);
63 BEGIN {
64     ($hint_bits, $warning_bits, $hinthash) = ($^H, ${^WARNING_BITS}, \%^H);
65 }
66 $deparse->ambient_pragmas (
67     hint_bits    => $hint_bits,
68     warning_bits => $warning_bits,
69     '%^H'        => $hinthash,
70 );
71 EOC
72
73     if ($@) {
74         is($@, "", "compilation of $desc");
75     }
76     else {
77         my $deparsed = $deparse->coderef2text( $coderef );
78         my $regex = $expected;
79         $regex =~ s/(\S+)/\Q$1/g;
80         $regex =~ s/\s+/\\s+/g;
81         $regex = '^\{\s*' . $regex . '\s*\}$';
82
83         local $::TODO = $meta{todo};
84         like($deparsed, qr/$regex/, $desc);
85     }
86 }
87
88 use constant 'c', 'stuff';
89 is((eval "sub ".$deparse->coderef2text(\&c))->(), 'stuff',
90    'the subroutine generated by use constant deparses');
91
92 my $a = 0;
93 is($deparse->coderef2text(sub{(-1) ** $a }), "{\n    (-1) ** \$a;\n}",
94    'anon sub capturing an external lexical');
95
96 use constant cr => ['hello'];
97 my $string = "sub " . $deparse->coderef2text(\&cr);
98 my $val = (eval $string)->() or diag $string;
99 is(ref($val), 'ARRAY', 'constant array references deparse');
100 is($val->[0], 'hello', 'and return the correct value');
101
102 my $path = join " ", map { qq["-I$_"] } @INC;
103
104 $a = `$^X $path "-MO=Deparse" -anlwi.bak -e 1 2>&1`;
105 $a =~ s/-e syntax OK\n//g;
106 $a =~ s/.*possible typo.*\n//;     # Remove warning line
107 $a =~ s{\\340\\242}{\\s} if (ord("\\") == 224); # EBCDIC, cp 1047 or 037
108 $a =~ s{\\274\\242}{\\s} if (ord("\\") == 188); # $^O eq 'posix-bc'
109 $b = <<'EOF';
110 BEGIN { $^I = ".bak"; }
111 BEGIN { $^W = 1; }
112 BEGIN { $/ = "\n"; $\ = "\n"; }
113 LINE: while (defined($_ = <ARGV>)) {
114     chomp $_;
115     our(@F) = split(' ', $_, 0);
116     '???';
117 }
118 EOF
119 is($a, $b,
120    'command line flags deparse as BEGIN blocks setting control variables');
121
122 $a = `$^X $path "-MO=Deparse" -e "use constant PI => 4" 2>&1`;
123 $a =~ s/-e syntax OK\n//g;
124 is($a, "use constant ('PI', 4);\n",
125    "Proxy Constant Subroutines must not show up as (incorrect) prototypes");
126
127 #Re: perlbug #35857, patch #24505
128 #handle warnings::register-ed packages properly.
129 package B::Deparse::Wrapper;
130 use strict;
131 use warnings;
132 use warnings::register;
133 sub getcode {
134    my $deparser = B::Deparse->new();
135    return $deparser->coderef2text(shift);
136 }
137
138 package Moo;
139 use overload '0+' => sub { 42 };
140
141 package main;
142 use strict;
143 use warnings;
144 use constant GLIPP => 'glipp';
145 use constant PI => 4;
146 use constant OVERLOADED_NUMIFICATION => bless({}, 'Moo');
147 use Fcntl qw/O_TRUNC O_APPEND O_EXCL/;
148 BEGIN { delete $::Fcntl::{O_APPEND}; }
149 use POSIX qw/O_CREAT/;
150 sub test {
151    my $val = shift;
152    my $res = B::Deparse::Wrapper::getcode($val);
153    like($res, qr/use warnings/,
154         '[perl #35857] [PATCH] B::Deparse doesnt handle warnings register properly');
155 }
156 my ($q,$p);
157 my $x=sub { ++$q,++$p };
158 test($x);
159 eval <<EOFCODE and test($x);
160    package bar;
161    use strict;
162    use warnings;
163    use warnings::register;
164    package main;
165    1
166 EOFCODE
167
168 # Exotic sub declarations
169 $a = `$^X $path "-MO=Deparse" -e "sub ::::{}sub ::::::{}" 2>&1`;
170 $a =~ s/-e syntax OK\n//g;
171 is($a, <<'EOCODG', "sub :::: and sub ::::::");
172 sub :::: {
173     
174 }
175 sub :::::: {
176     
177 }
178 EOCODG
179
180 # [perl #33752]
181 {
182   my $code = <<"EOCODE";
183 {
184     our \$\x{1e1f}\x{14d}\x{14d};
185 }
186 EOCODE
187   my $deparsed
188    = $deparse->coderef2text(eval "sub { our \$\x{1e1f}\x{14d}\x{14d} }" );
189   s/$ \n//x for $deparsed, $code;
190   is $deparsed, $code, 'our $funny_Unicode_chars';
191 }
192
193 # [perl #62500]
194 $a =
195   `$^X $path "-MO=Deparse" -e "BEGIN{*CORE::GLOBAL::require=sub{1}}" 2>&1`;
196 $a =~ s/-e syntax OK\n//g;
197 is($a, <<'EOCODF', "CORE::GLOBAL::require override causing panick");
198 sub BEGIN {
199     *CORE::GLOBAL::require = sub {
200         1;
201     }
202     ;
203 }
204 EOCODF
205
206 # [perl #91384]
207 $a =
208   `$^X $path "-MO=Deparse" -e "BEGIN{*Acme::Acme:: = *Acme::}" 2>&1`;
209 like($a, qr/-e syntax OK/,
210     "Deparse does not hang when traversing stash circularities");
211
212 # [perl #93990]
213 @* = ();
214 is($deparse->coderef2text(sub{ print "@{*}" }),
215 q<{
216     print "@{*}";
217 }>, 'curly around to interpolate "@{*}"');
218 is($deparse->coderef2text(sub{ print "@{-}" }),
219 q<{
220     print "@-";
221 }>, 'no need to curly around to interpolate "@-"');
222
223 # Strict hints in %^H are mercilessly suppressed
224 $a =
225   `$^X $path "-MO=Deparse" -e "use strict; print;" 2>&1`;
226 unlike($a, qr/BEGIN/,
227     "Deparse does not emit strict hh hints");
228
229 # ambient_pragmas should not mess with strict settings.
230 SKIP: {
231     skip "requires 5.11", 1 unless $] >= 5.011;
232     eval q`
233         no strict;
234         BEGIN {
235             # Clear out the strict hints from %^H
236             %^H = ();
237             new B::Deparse -> ambient_pragmas(strict => 'all');
238         }
239         use 5.011;  # should enable strict
240         ok !eval '$do_noT_create_a_variable_with_this_name = 1',
241           'ambient_pragmas do not mess with compiling scope';
242    `;
243 }
244
245 done_testing($tests);
246
247 __DATA__
248 # A constant
249 1;
250 ####
251 # Constants in a block
252 {
253     no warnings;
254     '???';
255     2;
256 }
257 ####
258 # Lexical and simple arithmetic
259 my $test;
260 ++$test and $test /= 2;
261 >>>>
262 my $test;
263 $test /= 2 if ++$test;
264 ####
265 # list x
266 -((1, 2) x 2);
267 ####
268 # lvalue sub
269 {
270     my $test = sub : lvalue {
271         my $x;
272     }
273     ;
274 }
275 ####
276 # method
277 {
278     my $test = sub : method {
279         my $x;
280     }
281     ;
282 }
283 ####
284 # block with continue
285 {
286     234;
287 }
288 continue {
289     123;
290 }
291 ####
292 # lexical and package scalars
293 my $x;
294 print $main::x;
295 ####
296 # lexical and package arrays
297 my @x;
298 print $main::x[1];
299 ####
300 # lexical and package hashes
301 my %x;
302 $x{warn()};
303 ####
304 # <>
305 my $foo;
306 $_ .= <ARGV> . <$foo>;
307 ####
308 # \x{}
309 my $foo = "Ab\x{100}\200\x{200}\237Cd\000Ef\x{1000}\cA\x{2000}\cZ";
310 ####
311 # s///e
312 s/x/'y';/e;
313 ####
314 # block
315 { my $x; }
316 ####
317 # while 1
318 while (1) { my $k; }
319 ####
320 # trailing for
321 my ($x,@a);
322 $x=1 for @a;
323 >>>>
324 my($x, @a);
325 $x = 1 foreach (@a);
326 ####
327 # 2 arguments in a 3 argument for
328 for (my $i = 0; $i < 2;) {
329     my $z = 1;
330 }
331 ####
332 # 3 argument for
333 for (my $i = 0; $i < 2; ++$i) {
334     my $z = 1;
335 }
336 ####
337 # 3 argument for again
338 for (my $i = 0; $i < 2; ++$i) {
339     my $z = 1;
340 }
341 ####
342 # while/continue
343 my $i;
344 while ($i) { my $z = 1; } continue { $i = 99; }
345 ####
346 # foreach with my
347 foreach my $i (1, 2) {
348     my $z = 1;
349 }
350 ####
351 # foreach
352 my $i;
353 foreach $i (1, 2) {
354     my $z = 1;
355 }
356 ####
357 # foreach, 2 mys
358 my $i;
359 foreach my $i (1, 2) {
360     my $z = 1;
361 }
362 ####
363 # foreach
364 foreach my $i (1, 2) {
365     my $z = 1;
366 }
367 ####
368 # foreach with our
369 foreach our $i (1, 2) {
370     my $z = 1;
371 }
372 ####
373 # foreach with my and our
374 my $i;
375 foreach our $i (1, 2) {
376     my $z = 1;
377 }
378 ####
379 # reverse sort
380 my @x;
381 print reverse sort(@x);
382 ####
383 # sort with cmp
384 my @x;
385 print((sort {$b cmp $a} @x));
386 ####
387 # reverse sort with block
388 my @x;
389 print((reverse sort {$b <=> $a} @x));
390 ####
391 # foreach reverse
392 our @a;
393 print $_ foreach (reverse @a);
394 ####
395 # foreach reverse (not inplace)
396 our @a;
397 print $_ foreach (reverse 1, 2..5);
398 ####
399 # bug #38684
400 our @ary;
401 @ary = split(' ', 'foo', 0);
402 ####
403 # bug #40055
404 do { () }; 
405 ####
406 # bug #40055
407 do { my $x = 1; $x }; 
408 ####
409 # <20061012113037.GJ25805@c4.convolution.nl>
410 my $f = sub {
411     +{[]};
412 } ;
413 ####
414 # bug #43010
415 '!@$%'->();
416 ####
417 # bug #43010
418 ::();
419 ####
420 # bug #43010
421 '::::'->();
422 ####
423 # bug #43010
424 &::::;
425 ####
426 # [perl #77172]
427 package rt77172;
428 sub foo {} foo & & & foo;
429 >>>>
430 package rt77172;
431 foo(&{&} & foo());
432 ####
433 # variables as method names
434 my $bar;
435 'Foo'->$bar('orz');
436 'Foo'->$bar('orz') = 'a stranger stranger than before';
437 ####
438 # constants as method names
439 'Foo'->bar('orz');
440 ####
441 # constants as method names without ()
442 'Foo'->bar;
443 ####
444 # [perl #47359] "indirect" method call notation
445 our @bar;
446 foo{@bar}+1,->foo;
447 (foo{@bar}+1),foo();
448 foo{@bar}1 xor foo();
449 >>>>
450 our @bar;
451 (foo { @bar } 1)->foo;
452 (foo { @bar } 1), foo();
453 foo { @bar } 1 xor foo();
454 ####
455 # SKIP ?$] < 5.010 && "say not implemented on this Perl version"
456 # CONTEXT use feature ':5.10';
457 # say
458 say 'foo';
459 ####
460 # SKIP ?$] < 5.010 && "say not implemented on this Perl version"
461 # TODO B::Deparse outputs CORE::say
462 # CONTEXT use 5.10.0;
463 # say in the context of use 5.10.0
464 say 'foo';
465 ####
466 # SKIP ?$] < 5.010 && "say not implemented on this Perl version"
467 # TODO B::Deparse outputs CORE::say
468 # say with use 5.10.0
469 use 5.10.0;
470 say 'foo';
471 >>>>
472 no feature;
473 use feature ':5.10';
474 say 'foo';
475 ####
476 # SKIP ?$] < 5.010 && "say not implemented on this Perl version"
477 # say with use feature ':5.10';
478 use feature ':5.10';
479 say 'foo';
480 >>>>
481 use feature 'say', 'state', 'switch';
482 say 'foo';
483 ####
484 # SKIP ?$] < 5.010 && "say not implemented on this Perl version"
485 # TODO B::Deparse outputs CORE::say
486 # CONTEXT use feature ':5.10';
487 # say with use 5.10.0 in the context of use feature
488 use 5.10.0;
489 say 'foo';
490 >>>>
491 no feature;
492 use feature ':5.10';
493 say 'foo';
494 ####
495 # SKIP ?$] < 5.010 && "say not implemented on this Perl version"
496 # CONTEXT use 5.10.0;
497 # say with use feature ':5.10' in the context of use 5.10.0
498 use feature ':5.10';
499 say 'foo';
500 >>>>
501 say 'foo';
502 ####
503 # SKIP ?$] < 5.015 && "__SUB__ not implemented on this Perl version"
504 # CONTEXT use feature ':5.15';
505 # __SUB__
506 __SUB__;
507 ####
508 # SKIP ?$] < 5.015 && "__SUB__ not implemented on this Perl version"
509 # TODO B::Deparse outputs CORE::__SUB__
510 # CONTEXT use 5.15.0;
511 # __SUB__ in the context of use 5.15.0
512 __SUB__;
513 ####
514 # SKIP ?$] < 5.015 && "__SUB__ not implemented on this Perl version"
515 # TODO B::Deparse outputs CORE::__SUB__
516 # __SUB__ with use 5.15.0
517 use 5.15.0;
518 __SUB__;
519 >>>>
520 no feature;
521 use feature ':5.16';
522 __SUB__;
523 ####
524 # SKIP ?$] < 5.015 && "__SUB__ not implemented on this Perl version"
525 # __SUB__ with use feature ':5.15';
526 use feature ':5.15';
527 __SUB__;
528 >>>>
529 use feature 'current_sub', 'evalbytes', 'fc', 'say', 'state', 'switch', 'unicode_strings', 'unicode_eval';
530 __SUB__;
531 ####
532 # SKIP ?$] < 5.015 && "__SUB__ not implemented on this Perl version"
533 # TODO B::Deparse outputs CORE::__SUB__
534 # CONTEXT use feature ':5.15';
535 # __SUB__ with use 5.15.0 in the context of use feature
536 use 5.15.0;
537 __SUB__;
538 >>>>
539 no feature;
540 use feature ':5.16';
541 __SUB__;
542 ####
543 # SKIP ?$] < 5.015 && "__SUB__ not implemented on this Perl version"
544 # CONTEXT use 5.15.0;
545 # __SUB__ with use feature ':5.15' in the context of use 5.15.0
546 use feature ':5.15';
547 __SUB__;
548 >>>>
549 __SUB__;
550 ####
551 # SKIP ?$] < 5.010 && "state vars not implemented on this Perl version"
552 # CONTEXT use feature ':5.10';
553 # state vars
554 state $x = 42;
555 ####
556 # SKIP ?$] < 5.010 && "state vars not implemented on this Perl version"
557 # CONTEXT use feature ':5.10';
558 # state var assignment
559 {
560     my $y = (state $x = 42);
561 }
562 ####
563 # SKIP ?$] < 5.010 && "state vars not implemented on this Perl version"
564 # CONTEXT use feature ':5.10';
565 # state vars in anonymous subroutines
566 $a = sub {
567     state $x;
568     return $x++;
569 }
570 ;
571 ####
572 # SKIP ?$] < 5.011 && 'each @array not implemented on this Perl version'
573 # each @array;
574 each @ARGV;
575 each @$a;
576 ####
577 # SKIP ?$] < 5.011 && 'each @array not implemented on this Perl version'
578 # keys @array; values @array
579 keys @$a if keys @ARGV;
580 values @ARGV if values @$a;
581 ####
582 # Anonymous arrays and hashes, and references to them
583 my $a = {};
584 my $b = \{};
585 my $c = [];
586 my $d = \[];
587 ####
588 # SKIP ?$] < 5.010 && "smartmatch and given/when not implemented on this Perl version"
589 # CONTEXT use feature ':5.10';
590 # implicit smartmatch in given/when
591 given ('foo') {
592     when ('bar') { continue; }
593     when ($_ ~~ 'quux') { continue; }
594     default { 0; }
595 }
596 ####
597 # conditions in elsifs (regression in change #33710 which fixed bug #37302)
598 if ($a) { x(); }
599 elsif ($b) { x(); }
600 elsif ($a and $b) { x(); }
601 elsif ($a or $b) { x(); }
602 else { x(); }
603 ####
604 # interpolation in regexps
605 my($y, $t);
606 /x${y}z$t/;
607 ####
608 # TODO new undocumented cpan-bug #33708
609 # cpan-bug #33708
610 %{$_ || {}}
611 ####
612 # TODO hash constants not yet fixed
613 # cpan-bug #33708
614 use constant H => { "#" => 1 }; H->{"#"}
615 ####
616 # TODO optimized away 0 not yet fixed
617 # cpan-bug #33708
618 foreach my $i (@_) { 0 }
619 ####
620 # tests with not, not optimized
621 my $c;
622 x() unless $a;
623 x() if not $a and $b;
624 x() if $a and not $b;
625 x() unless not $a and $b;
626 x() unless $a and not $b;
627 x() if not $a or $b;
628 x() if $a or not $b;
629 x() unless not $a or $b;
630 x() unless $a or not $b;
631 x() if $a and not $b and $c;
632 x() if not $a and $b and not $c;
633 x() unless $a and not $b and $c;
634 x() unless not $a and $b and not $c;
635 x() if $a or not $b or $c;
636 x() if not $a or $b or not $c;
637 x() unless $a or not $b or $c;
638 x() unless not $a or $b or not $c;
639 ####
640 # tests with not, optimized
641 my $c;
642 x() if not $a;
643 x() unless not $a;
644 x() if not $a and not $b;
645 x() unless not $a and not $b;
646 x() if not $a or not $b;
647 x() unless not $a or not $b;
648 x() if not $a and not $b and $c;
649 x() unless not $a and not $b and $c;
650 x() if not $a or not $b or $c;
651 x() unless not $a or not $b or $c;
652 x() if not $a and not $b and not $c;
653 x() unless not $a and not $b and not $c;
654 x() if not $a or not $b or not $c;
655 x() unless not $a or not $b or not $c;
656 x() unless not $a or not $b or not $c;
657 >>>>
658 my $c;
659 x() unless $a;
660 x() if $a;
661 x() unless $a or $b;
662 x() if $a or $b;
663 x() unless $a and $b;
664 x() if $a and $b;
665 x() if not $a || $b and $c;
666 x() unless not $a || $b and $c;
667 x() if not $a && $b or $c;
668 x() unless not $a && $b or $c;
669 x() unless $a or $b or $c;
670 x() if $a or $b or $c;
671 x() unless $a and $b and $c;
672 x() if $a and $b and $c;
673 x() unless not $a && $b && $c;
674 ####
675 # tests that should be constant folded
676 x() if 1;
677 x() if GLIPP;
678 x() if !GLIPP;
679 x() if GLIPP && GLIPP;
680 x() if !GLIPP || GLIPP;
681 x() if do { GLIPP };
682 x() if do { no warnings 'void'; 5; GLIPP };
683 x() if do { !GLIPP };
684 if (GLIPP) { x() } else { z() }
685 if (!GLIPP) { x() } else { z() }
686 if (GLIPP) { x() } elsif (GLIPP) { z() }
687 if (!GLIPP) { x() } elsif (GLIPP) { z() }
688 if (GLIPP) { x() } elsif (!GLIPP) { z() }
689 if (!GLIPP) { x() } elsif (!GLIPP) { z() }
690 if (!GLIPP) { x() } elsif (!GLIPP) { z() } elsif (GLIPP) { t() }
691 if (!GLIPP) { x() } elsif (!GLIPP) { z() } elsif (!GLIPP) { t() }
692 if (!GLIPP) { x() } elsif (!GLIPP) { z() } elsif (!GLIPP) { t() }
693 >>>>
694 x();
695 x();
696 '???';
697 x();
698 x();
699 x();
700 x();
701 do {
702     '???'
703 };
704 do {
705     x()
706 };
707 do {
708     z()
709 };
710 do {
711     x()
712 };
713 do {
714     z()
715 };
716 do {
717     x()
718 };
719 '???';
720 do {
721     t()
722 };
723 '???';
724 !1;
725 ####
726 # TODO constant deparsing has been backed out for 5.12
727 # XXXTODO ? $Config::Config{useithreads} && "doesn't work with threads"
728 # tests that shouldn't be constant folded
729 # It might be fundamentally impossible to make this work on ithreads, in which
730 # case the TODO should become a SKIP
731 x() if $a;
732 if ($a == 1) { x() } elsif ($b == 2) { z() }
733 if (do { foo(); GLIPP }) { x() }
734 if (do { $a++; GLIPP }) { x() }
735 >>>>
736 x() if $a;
737 if ($a == 1) { x(); } elsif ($b == 2) { z(); }
738 if (do { foo(); GLIPP }) { x(); }
739 if (do { ++$a; GLIPP }) { x(); }
740 ####
741 # TODO constant deparsing has been backed out for 5.12
742 # tests for deparsing constants
743 warn PI;
744 ####
745 # TODO constant deparsing has been backed out for 5.12
746 # tests for deparsing imported constants
747 warn O_TRUNC;
748 ####
749 # TODO constant deparsing has been backed out for 5.12
750 # tests for deparsing re-exported constants
751 warn O_CREAT;
752 ####
753 # TODO constant deparsing has been backed out for 5.12
754 # tests for deparsing imported constants that got deleted from the original namespace
755 warn O_APPEND;
756 ####
757 # TODO constant deparsing has been backed out for 5.12
758 # XXXTODO ? $Config::Config{useithreads} && "doesn't work with threads"
759 # tests for deparsing constants which got turned into full typeglobs
760 # It might be fundamentally impossible to make this work on ithreads, in which
761 # case the TODO should become a SKIP
762 warn O_EXCL;
763 eval '@Fcntl::O_EXCL = qw/affe tiger/;';
764 warn O_EXCL;
765 ####
766 # TODO constant deparsing has been backed out for 5.12
767 # tests for deparsing of blessed constant with overloaded numification
768 warn OVERLOADED_NUMIFICATION;
769 ####
770 # strict
771 no strict;
772 print $x;
773 use strict 'vars';
774 print $main::x;
775 use strict 'subs';
776 print $main::x;
777 use strict 'refs';
778 print $main::x;
779 no strict 'vars';
780 $x;
781 ####
782 # TODO Subsets of warnings could be encoded textually, rather than as bitflips.
783 # subsets of warnings
784 no warnings 'deprecated';
785 my $x;
786 ####
787 # TODO Better test for CPAN #33708 - the deparsed code has different behaviour
788 # CPAN #33708
789 use strict;
790 no warnings;
791
792 foreach (0..3) {
793     my $x = 2;
794     {
795         my $x if 0;
796         print ++$x, "\n";
797     }
798 }
799 ####
800 # no attribute list
801 my $pi = 4;
802 ####
803 # SKIP ?$] > 5.013006 && ":= is now a syntax error"
804 # := treated as an empty attribute list
805 no warnings;
806 my $pi := 4;
807 >>>>
808 no warnings;
809 my $pi = 4;
810 ####
811 # : = empty attribute list
812 my $pi : = 4;
813 >>>>
814 my $pi = 4;
815 ####
816 # in place sort
817 our @a;
818 my @b;
819 @a = sort @a;
820 @b = sort @b;
821 ();
822 ####
823 # in place reverse
824 our @a;
825 my @b;
826 @a = reverse @a;
827 @b = reverse @b;
828 ();
829 ####
830 # #71870 Use of uninitialized value in bitwise and B::Deparse
831 my($r, $s, @a);
832 @a = split(/foo/, $s, 0);
833 $r = qr/foo/;
834 @a = split(/$r/, $s, 0);
835 ();
836 ####
837 # package declaration before label
838 {
839     package Foo;
840     label: print 123;
841 }
842 ####
843 # shift optimisation
844 shift;
845 >>>>
846 shift();
847 ####
848 # shift optimisation
849 shift @_;
850 ####
851 # shift optimisation
852 pop;
853 >>>>
854 pop();
855 ####
856 # shift optimisation
857 pop @_;
858 ####
859 #[perl #20444]
860 "foo" =~ (1 ? /foo/ : /bar/);
861 "foo" =~ (1 ? y/foo// : /bar/);
862 "foo" =~ (1 ? y/foo//r : /bar/);
863 "foo" =~ (1 ? s/foo// : /bar/);
864 >>>>
865 'foo' =~ ($_ =~ /foo/);
866 'foo' =~ ($_ =~ tr/fo//);
867 'foo' =~ ($_ =~ tr/fo//r);
868 'foo' =~ ($_ =~ s/foo//);
869 ####
870 # The fix for [perl #20444] broke this.
871 'foo' =~ do { () };
872 ####
873 # [perl #81424] match against aelemfast_lex
874 my @s;
875 print /$s[1]/;
876 ####
877 # /$#a/
878 print /$#main::a/;
879 ####
880 # [perl #91318] /regexp/applaud
881 print /a/a, s/b/c/a;
882 print /a/aa, s/b/c/aa;
883 print /a/p, s/b/c/p;
884 print /a/l, s/b/c/l;
885 print /a/u, s/b/c/u;
886 {
887     use feature "unicode_strings";
888     print /a/d, s/b/c/d;
889 }
890 {
891     use re "/u";
892     print /a/d, s/b/c/d;
893 }
894 {
895     use 5.012;
896     print /a/d, s/b/c/d;
897 }
898 >>>>
899 print /a/a, s/b/c/a;
900 print /a/aa, s/b/c/aa;
901 print /a/p, s/b/c/p;
902 print /a/l, s/b/c/l;
903 print /a/u, s/b/c/u;
904 {
905     use feature 'unicode_strings';
906     print /a/d, s/b/c/d;
907 }
908 {
909     BEGIN { $^H{'reflags'}         = '0';
910             $^H{'reflags_charset'} = '2'; }
911     print /a/d, s/b/c/d;
912 }
913 {
914     no feature;
915     use feature ':5.12';
916     print /a/d, s/b/c/d;
917 }
918 ####
919 # Test @threadsv_names under 5005threads
920 foreach $' (1, 2) {
921     sleep $';
922 }
923 ####
924 # y///r
925 tr/a/b/r;
926 ####
927 # y/uni/code/
928 tr/\x{345}/\x{370}/;
929 ####
930 # [perl #90898]
931 <a,>;
932 ####
933 # [perl #91008]
934 each $@;
935 keys $~;
936 values $!;
937 ####
938 # readpipe with complex expression
939 readpipe $a + $b;
940 ####
941 # aelemfast
942 $b::a[0] = 1;
943 ####
944 # aelemfast for a lexical
945 my @a;
946 $a[0] = 1;
947 ####
948 # feature features without feature
949 CORE::state $x;
950 CORE::say $x;
951 CORE::given ($x) {
952     CORE::when (3) {
953         continue;
954     }
955     CORE::default {
956         CORE::break;
957     }
958 }
959 CORE::evalbytes '';
960 () = CORE::__SUB__;
961 () = CORE::fc $x;
962 ####
963 # feature features when feature has been disabled by use VERSION
964 use feature (sprintf(":%vd", $^V));
965 use 1;
966 CORE::state $x;
967 CORE::say $x;
968 CORE::given ($x) {
969     CORE::when (3) {
970         continue;
971     }
972     CORE::default {
973         CORE::break;
974     }
975 }
976 CORE::evalbytes '';
977 () = CORE::__SUB__;
978 >>>>
979 CORE::state $x;
980 CORE::say $x;
981 CORE::given ($x) {
982     CORE::when (3) {
983         continue;
984     }
985     CORE::default {
986         CORE::break;
987     }
988 }
989 CORE::evalbytes '';
990 () = CORE::__SUB__;
991 ####
992 # (the above test with CONTEXT, and the output is equivalent but different)
993 # CONTEXT use feature ':5.10';
994 # feature features when feature has been disabled by use VERSION
995 use feature (sprintf(":%vd", $^V));
996 use 1;
997 CORE::state $x;
998 CORE::say $x;
999 CORE::given ($x) {
1000     CORE::when (3) {
1001         continue;
1002     }
1003     CORE::default {
1004         CORE::break;
1005     }
1006 }
1007 CORE::evalbytes '';
1008 () = CORE::__SUB__;
1009 >>>>
1010 no feature;
1011 use feature ':default';
1012 CORE::state $x;
1013 CORE::say $x;
1014 CORE::given ($x) {
1015     CORE::when (3) {
1016         continue;
1017     }
1018     CORE::default {
1019         CORE::break;
1020     }
1021 }
1022 CORE::evalbytes '';
1023 () = CORE::__SUB__;
1024 ####
1025 # Feature hints
1026 use feature 'current_sub', 'evalbytes';
1027 print;
1028 use 1;
1029 print;
1030 use 5.014;
1031 print;
1032 no feature 'unicode_strings';
1033 print;
1034 >>>>
1035 use feature 'current_sub', 'evalbytes';
1036 print $_;
1037 no feature;
1038 use feature ':default';
1039 print $_;
1040 no feature;
1041 use feature ':5.12';
1042 print $_;
1043 no feature 'unicode_strings';
1044 print $_;
1045 ####
1046 # $#- $#+ $#{%} etc.
1047 my @x;
1048 @x = ($#{`}, $#{~}, $#{!}, $#{@}, $#{$}, $#{%}, $#{^}, $#{&}, $#{*});
1049 @x = ($#{(}, $#{)}, $#{[}, $#{{}, $#{]}, $#{}}, $#{'}, $#{"}, $#{,});
1050 @x = ($#{<}, $#{.}, $#{>}, $#{/}, $#{?}, $#{=}, $#+, $#{\}, $#{|}, $#-);
1051 @x = ($#{;}, $#{:});
1052 ####
1053 # ${#} interpolated (the first line magically disables the warning)
1054 () = *#;
1055 () = "${#}a";
1056 ####
1057 # [perl #86060] $( $| $) in regexps need braces
1058 /${(}/;
1059 /${|}/;
1060 /${)}/;
1061 /${(}${|}${)}/;
1062 ####
1063 # ()[...]
1064 my(@a) = ()[()];
1065 ####
1066 # sort(foo(bar))
1067 # sort(foo(bar)) is interpreted as sort &foo(bar)
1068 # sort foo(bar) is interpreted as sort foo bar
1069 # parentheses are not optional in this case
1070 print sort(foo('bar'));
1071 >>>>
1072 print sort(foo('bar'));
1073 ####
1074 # substr assignment
1075 substr(my $a, 0, 0) = (foo(), bar());
1076 $a++;
1077 ####
1078 # hint hash
1079 BEGIN { $^H{'foo'} = undef; }
1080 {
1081  BEGIN { $^H{'bar'} = undef; }
1082  {
1083   BEGIN { $^H{'baz'} = undef; }
1084   {
1085    print $_;
1086   }
1087   print $_;
1088  }
1089  print $_;
1090 }
1091 BEGIN { $^H{q[']} = '('; }
1092 print $_;
1093 ####
1094 # hint hash changes that serialise the same way with sort %hh
1095 BEGIN { $^H{'a'} = 'b'; }
1096 {
1097  BEGIN { $^H{'b'} = 'a'; delete $^H{'a'}; }
1098  print $_;
1099 }
1100 print $_;
1101 ####
1102 # [perl #47361] do({}) and do +{} (variants of do-file)
1103 do({});
1104 do +{};
1105 sub foo::do {}
1106 package foo;
1107 CORE::do({});
1108 CORE::do +{};
1109 >>>>
1110 do({});
1111 do({});
1112 package foo;
1113 CORE::do({});
1114 CORE::do({});
1115 ####
1116 # [perl #77096] functions that do not follow the llafr
1117 () = (return 1) + time;
1118 () = (return ($1 + $2) * $3) + time;
1119 () = (return ($a xor $b)) + time;
1120 () = (do 'file') + time;
1121 () = (do ($1 + $2) * $3) + time;
1122 () = (do ($1 xor $2)) + time;
1123 () = (goto 1) + 3;
1124 () = (require 'foo') + 3;
1125 () = (require foo) + 3;
1126 () = (CORE::dump 1) + 3;
1127 () = (last 1) + 3;
1128 () = (next 1) + 3;
1129 () = (redo 1) + 3;
1130 () = (-R $_) + 3;
1131 () = (-W $_) + 3;
1132 () = (-X $_) + 3;
1133 () = (-r $_) + 3;
1134 () = (-w $_) + 3;
1135 () = (-x $_) + 3;
1136 ####
1137 # [perl #97476] not() *does* follow the llafr
1138 $_ = ($a xor not +($1 || 2) ** 2);
1139 ####
1140 # Precedence conundrums with argument-less function calls
1141 () = (eof) + 1;
1142 () = (return) + 1;
1143 () = (return, 1);
1144 () = warn;
1145 () = warn() + 1;
1146 () = setpgrp() + 1;
1147 ####
1148 # [perl #63558] open local(*FH)
1149 open local *FH;
1150 pipe local *FH, local *FH;
1151 ####
1152 # [perl #91416] open "string"
1153 open 'open';
1154 open '####';
1155 open '^A';
1156 open "\ca";
1157 >>>>
1158 open *open;
1159 open '####';
1160 open '^A';
1161 open *^A;
1162 ####
1163 # "string"->[] ->{}
1164 no strict 'vars';
1165 () = 'open'->[0]; #aelemfast
1166 () = '####'->[0];
1167 () = '^A'->[0];
1168 () = "\ca"->[0];
1169 () = 'a::]b'->[0];
1170 () = 'open'->[$_]; #aelem
1171 () = '####'->[$_];
1172 () = '^A'->[$_];
1173 () = "\ca"->[$_];
1174 () = 'a::]b'->[$_];
1175 () = 'open'->{0}; #helem
1176 () = '####'->{0};
1177 () = '^A'->{0};
1178 () = "\ca"->{0};
1179 () = 'a::]b'->{0};
1180 >>>>
1181 no strict 'vars';
1182 () = $open[0];
1183 () = '####'->[0];
1184 () = '^A'->[0];
1185 () = $^A[0];
1186 () = 'a::]b'->[0];
1187 () = $open[$_];
1188 () = '####'->[$_];
1189 () = '^A'->[$_];
1190 () = $^A[$_];
1191 () = 'a::]b'->[$_];
1192 () = $open{'0'};
1193 () = '####'->{'0'};
1194 () = '^A'->{'0'};
1195 () = $^A{'0'};
1196 () = 'a::]b'->{'0'};
1197 ####
1198 # [perl #74740] -(f()) vs -f()
1199 $_ = -(f());
1200 ####
1201 # require <binop>
1202 require 'a' . $1;
1203 ####
1204 #[perl #30504] foreach-my postfix/prefix difference
1205 $_ = 'foo' foreach my ($foo1, $bar1, $baz1);
1206 foreach (my ($foo2, $bar2, $baz2)) { $_ = 'foo' }
1207 foreach my $i (my ($foo3, $bar3, $baz3)) { $i = 'foo' }
1208 >>>>
1209 $_ = 'foo' foreach (my($foo1, $bar1, $baz1));
1210 foreach $_ (my($foo2, $bar2, $baz2)) {
1211     $_ = 'foo';
1212 }
1213 foreach my $i (my($foo3, $bar3, $baz3)) {
1214     $i = 'foo';
1215 }
1216 ####
1217 #[perl #108224] foreach with continue block
1218 foreach (1 .. 3) { print } continue { print "\n" }
1219 foreach (1 .. 3) { } continue { }
1220 foreach my $i (1 .. 3) { print $i } continue { print "\n" }
1221 foreach my $i (1 .. 3) { } continue { }
1222 >>>>
1223 foreach $_ (1 .. 3) {
1224     print $_;
1225 }
1226 continue {
1227     print "\n";
1228 }
1229 foreach $_ (1 .. 3) {
1230     ();
1231 }
1232 continue {
1233     ();
1234 }
1235 foreach my $i (1 .. 3) {
1236     print $i;
1237 }
1238 continue {
1239     print "\n";
1240 }
1241 foreach my $i (1 .. 3) {
1242     ();
1243 }
1244 continue {
1245     ();
1246 }