This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Extract _restore_globals_after_restart.
[perl5.git] / lib / perl5db.pl
1
2 =head1 NAME
3
4 perl5db.pl - the perl debugger
5
6 =head1 SYNOPSIS
7
8     perl -d  your_Perl_script
9
10 =head1 DESCRIPTION
11
12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
13 you invoke a script with C<perl -d>. This documentation tries to outline the
14 structure and services provided by C<perl5db.pl>, and to describe how you
15 can use them.
16
17 =head1 GENERAL NOTES
18
19 The debugger can look pretty forbidding to many Perl programmers. There are
20 a number of reasons for this, many stemming out of the debugger's history.
21
22 When the debugger was first written, Perl didn't have a lot of its nicer
23 features - no references, no lexical variables, no closures, no object-oriented
24 programming. So a lot of the things one would normally have done using such
25 features was done using global variables, globs and the C<local()> operator
26 in creative ways.
27
28 Some of these have survived into the current debugger; a few of the more
29 interesting and still-useful idioms are noted in this section, along with notes
30 on the comments themselves.
31
32 =head2 Why not use more lexicals?
33
34 Experienced Perl programmers will note that the debugger code tends to use
35 mostly package globals rather than lexically-scoped variables. This is done
36 to allow a significant amount of control of the debugger from outside the
37 debugger itself.
38
39 Unfortunately, though the variables are accessible, they're not well
40 documented, so it's generally been a decision that hasn't made a lot of
41 difference to most users. Where appropriate, comments have been added to
42 make variables more accessible and usable, with the understanding that these
43 I<are> debugger internals, and are therefore subject to change. Future
44 development should probably attempt to replace the globals with a well-defined
45 API, but for now, the variables are what we've got.
46
47 =head2 Automated variable stacking via C<local()>
48
49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
50 temporary copy of a variable in the current scope. When the scope ends, the
51 old copy is restored. This is often used in the debugger to handle the
52 automatic stacking of variables during recursive calls:
53
54      sub foo {
55         local $some_global++;
56
57         # Do some stuff, then ...
58         return;
59      }
60
61 What happens is that on entry to the subroutine, C<$some_global> is localized,
62 then altered. When the subroutine returns, Perl automatically undoes the
63 localization, restoring the previous value. Voila, automatic stack management.
64
65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
66 which lets the debugger get control inside of C<eval>'ed code. The debugger
67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
71
72 In any case, watch for this pattern. It occurs fairly often.
73
74 =head2 The C<^> trick
75
76 This is used to cleverly reverse the sense of a logical test depending on
77 the value of an auxiliary variable. For instance, the debugger's C<S>
78 (search for subroutines by pattern) allows you to negate the pattern
79 like this:
80
81    # Find all non-'foo' subs:
82    S !/foo/
83
84 Boolean algebra states that the truth table for XOR looks like this:
85
86 =over 4
87
88 =item * 0 ^ 0 = 0
89
90 (! not present and no match) --> false, don't print
91
92 =item * 0 ^ 1 = 1
93
94 (! not present and matches) --> true, print
95
96 =item * 1 ^ 0 = 1
97
98 (! present and no match) --> true, print
99
100 =item * 1 ^ 1 = 0
101
102 (! present and matches) --> false, don't print
103
104 =back
105
106 As you can see, the first pair applies when C<!> isn't supplied, and
107 the second pair applies when it is. The XOR simply allows us to
108 compact a more complicated if-then-elseif-else into a more elegant
109 (but perhaps overly clever) single test. After all, it needed this
110 explanation...
111
112 =head2 FLAGS, FLAGS, FLAGS
113
114 There is a certain C programming legacy in the debugger. Some variables,
115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
117 of state to be stored independently in a single scalar.
118
119 A test like
120
121     if ($scalar & 4) ...
122
123 is checking to see if the appropriate bit is on. Since each bit can be
124 "addressed" independently in this way, C<$scalar> is acting sort of like
125 an array of bits. Obviously, since the contents of C<$scalar> are just a
126 bit-pattern, we can save and restore it easily (it will just look like
127 a number).
128
129 The problem, is of course, that this tends to leave magic numbers scattered
130 all over your program whenever a bit is set, cleared, or checked. So why do
131 it?
132
133 =over 4
134
135 =item *
136
137 First, doing an arithmetical or bitwise operation on a scalar is
138 just about the fastest thing you can do in Perl: C<use constant> actually
139 creates a subroutine call, and array and hash lookups are much slower. Is
140 this over-optimization at the expense of readability? Possibly, but the
141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
142 probably have to benchmark alternate implementations and see which is the
143 best balance of readability and speed, and then document how it actually
144 works.
145
146 =item *
147
148 Second, it's very easy to serialize a scalar number. This is done in
149 the restart code; the debugger state variables are saved in C<%ENV> and then
150 restored when the debugger is restarted. Having them be just numbers makes
151 this trivial.
152
153 =item *
154
155 Third, some of these variables are being shared with the Perl core
156 smack in the middle of the interpreter's execution loop. It's much faster for
157 a C program (like the interpreter) to check a bit in a scalar than to access
158 several different variables (or a Perl array).
159
160 =back
161
162 =head2 What are those C<XXX> comments for?
163
164 Any comment containing C<XXX> means that the comment is either somewhat
165 speculative - it's not exactly clear what a given variable or chunk of
166 code is doing, or that it is incomplete - the basics may be clear, but the
167 subtleties are not completely documented.
168
169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
170
171 =head1 DATA STRUCTURES MAINTAINED BY CORE
172
173 There are a number of special data structures provided to the debugger by
174 the Perl interpreter.
175
176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
177 via glob assignment) contains the text from C<$filename>, with each
178 element corresponding to a single line of C<$filename>. Additionally,
179 breakable lines will be dualvars with the numeric component being the
180 memory address of a COP node. Non-breakable lines are dualvar to 0.
181
182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
183 assignment) contains breakpoints and actions.  The keys are line numbers;
184 you can set individual values, but not the whole hash. The Perl interpreter
185 uses this hash to determine where breakpoints have been set. Any true value is
186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
188
189 The scalar C<${"_<$filename"}> simply contains the string C<<< _<$filename> >>>.
190 This is also the case for evaluated strings that contain subroutines, or
191 which are currently being executed.  The $filename for C<eval>ed strings looks
192 like C<(eval 34).
193
194 =head1 DEBUGGER STARTUP
195
196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
198 of options. In addition, this file may define a subroutine C<&afterinit>
199 that will be executed (in the debugger's context) after the debugger has
200 initialized itself.
201
202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
203 contents as the argument of a C<o> command in the debugger.
204
205 =head2 STARTUP-ONLY OPTIONS
206
207 The following options can only be specified at startup.
208 To set them in your rcfile, add a call to
209 C<&parse_options("optionName=new_value")>.
210
211 =over 4
212
213 =item * TTY
214
215 the TTY to use for debugging i/o.
216
217 =item * noTTY
218
219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
221 Term::Rendezvous.  Current variant is to have the name of TTY in this
222 file.
223
224 =item * ReadLine
225
226 if false, a dummy ReadLine is used, so you can debug
227 ReadLine applications.
228
229 =item * NonStop
230
231 if true, no i/o is performed until interrupt.
232
233 =item * LineInfo
234
235 file or pipe to print line number info to.  If it is a
236 pipe, a short "emacs like" message is used.
237
238 =item * RemotePort
239
240 host:port to connect to on remote host for remote debugging.
241
242 =item * HistFile
243
244 file to store session history to. There is no default and so no
245 history file is written unless this variable is explicitly set.
246
247 =item * HistSize
248
249 number of commands to store to the file specified in C<HistFile>.
250 Default is 100.
251
252 =back
253
254 =head3 SAMPLE RCFILE
255
256  &parse_options("NonStop=1 LineInfo=db.out");
257   sub afterinit { $trace = 1; }
258
259 The script will run without human intervention, putting trace
260 information into C<db.out>.  (If you interrupt it, you had better
261 reset C<LineInfo> to something I<interactive>!)
262
263 =head1 INTERNALS DESCRIPTION
264
265 =head2 DEBUGGER INTERFACE VARIABLES
266
267 Perl supplies the values for C<%sub>.  It effectively inserts
268 a C<&DB::DB();> in front of each place that can have a
269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
271 {require 'perl5db.pl'}> before the first line.
272
273 After each C<require>d file is compiled, but before it is executed, a
274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
275 is the expanded name of the C<require>d file (as found via C<%INC>).
276
277 =head3 IMPORTANT INTERNAL VARIABLES
278
279 =head4 C<$CreateTTY>
280
281 Used to control when the debugger will attempt to acquire another TTY to be
282 used for input.
283
284 =over
285
286 =item * 1 -  on C<fork()>
287
288 =item * 2 - debugger is started inside debugger
289
290 =item * 4 -  on startup
291
292 =back
293
294 =head4 C<$doret>
295
296 The value -2 indicates that no return value should be printed.
297 Any other positive value causes C<DB::sub> to print return values.
298
299 =head4 C<$evalarg>
300
301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
302 contents of C<@_> when C<DB::eval> is called.
303
304 =head4 C<$frame>
305
306 Determines what messages (if any) will get printed when a subroutine (or eval)
307 is entered or exited.
308
309 =over 4
310
311 =item * 0 -  No enter/exit messages
312
313 =item * 1 - Print I<entering> messages on subroutine entry
314
315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
316
317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
318
319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
320
321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
322
323 =back
324
325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
326 The debugger internally juggles the value of C<$frame> during execution to
327 protect external modules that the debugger uses from getting traced.
328
329 =head4 C<$level>
330
331 Tracks current debugger nesting level. Used to figure out how many
332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
333 outputs a prompt. Also used to help determine if the program has finished
334 during command parsing.
335
336 =head4 C<$onetimeDump>
337
338 Controls what (if anything) C<DB::eval()> will print after evaluating an
339 expression.
340
341 =over 4
342
343 =item * C<undef> - don't print anything
344
345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
346
347 =item * C<methods> - print the methods callable on the first item returned
348
349 =back
350
351 =head4 C<$onetimeDumpDepth>
352
353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
354 dumping a structure. Numeric. If C<undef>, print all levels.
355
356 =head4 C<$signal>
357
358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
359 which is called before every statement, checks this and puts the user into
360 command mode if it finds C<$signal> set to a true value.
361
362 =head4 C<$single>
363
364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
365 each subroutine; popped again at the end of each subroutine.
366
367 =over 4
368
369 =item * 0 - run continuously.
370
371 =item * 1 - single-step, go into subs. The C<s> command.
372
373 =item * 2 - single-step, don't go into subs. The C<n> command.
374
375 =item * 4 - print current sub depth (turned on to force this when C<too much
376 recursion> occurs.
377
378 =back
379
380 =head4 C<$trace>
381
382 Controls the output of trace information.
383
384 =over 4
385
386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
387
388 =item * 2 - watch expressions are active
389
390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
391
392 =back
393
394 =head4 C<$slave_editor>
395
396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
397
398 =head4 C<@cmdfhs>
399
400 Stack of filehandles that C<DB::readline()> will read commands from.
401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
402
403 =head4 C<@dbline>
404
405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
406 supplied by the Perl interpreter to the debugger. Contains the source.
407
408 =head4 C<@old_watch>
409
410 Previous values of watch expressions. First set when the expression is
411 entered; reset whenever the watch expression changes.
412
413 =head4 C<@saved>
414
415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
416 so that the debugger can substitute safe values while it's running, and
417 restore them when it returns control.
418
419 =head4 C<@stack>
420
421 Saves the current value of C<$single> on entry to a subroutine.
422 Manipulated by the C<c> command to turn off tracing in all subs above the
423 current one.
424
425 =head4 C<@to_watch>
426
427 The 'watch' expressions: to be evaluated before each line is executed.
428
429 =head4 C<@typeahead>
430
431 The typeahead buffer, used by C<DB::readline>.
432
433 =head4 C<%alias>
434
435 Command aliases. Stored as character strings to be substituted for a command
436 entered.
437
438 =head4 C<%break_on_load>
439
440 Keys are file names, values are 1 (break when this file is loaded) or undef
441 (don't break when it is loaded).
442
443 =head4 C<%dbline>
444
445 Keys are line numbers, values are C<condition\0action>. If used in numeric
446 context, values are 0 if not breakable, 1 if breakable, no matter what is
447 in the actual hash entry.
448
449 =head4 C<%had_breakpoints>
450
451 Keys are file names; values are bitfields:
452
453 =over 4
454
455 =item * 1 - file has a breakpoint in it.
456
457 =item * 2 - file has an action in it.
458
459 =back
460
461 A zero or undefined value means this file has neither.
462
463 =head4 C<%option>
464
465 Stores the debugger options. These are character string values.
466
467 =head4 C<%postponed>
468
469 Saves breakpoints for code that hasn't been compiled yet.
470 Keys are subroutine names, values are:
471
472 =over 4
473
474 =item * C<compile> - break when this sub is compiled
475
476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
477
478 =back
479
480 =head4 C<%postponed_file>
481
482 This hash keeps track of breakpoints that need to be set for files that have
483 not yet been compiled. Keys are filenames; values are references to hashes.
484 Each of these hashes is keyed by line number, and its values are breakpoint
485 definitions (C<condition\0action>).
486
487 =head1 DEBUGGER INITIALIZATION
488
489 The debugger's initialization actually jumps all over the place inside this
490 package. This is because there are several BEGIN blocks (which of course
491 execute immediately) spread through the code. Why is that?
492
493 The debugger needs to be able to change some things and set some things up
494 before the debugger code is compiled; most notably, the C<$deep> variable that
495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
496 debugger has to turn off warnings while the debugger code is compiled, but then
497 restore them to their original setting before the program being debugged begins
498 executing.
499
500 The first C<BEGIN> block simply turns off warnings by saving the current
501 setting of C<$^W> and then setting it to zero. The second one initializes
502 the debugger variables that are needed before the debugger begins executing.
503 The third one puts C<$^X> back to its former value.
504
505 We'll detail the second C<BEGIN> block later; just remember that if you need
506 to initialize something before the debugger starts really executing, that's
507 where it has to go.
508
509 =cut
510
511 package DB;
512
513 use strict;
514
515 BEGIN {eval 'use IO::Handle'};  # Needed for flush only? breaks under miniperl
516
517 BEGIN {
518     require feature;
519     $^V =~ /^v(\d+\.\d+)/;
520     feature->import(":$1");
521 }
522
523 # Debugger for Perl 5.00x; perl5db.pl patch level:
524 use vars qw($VERSION $header);
525
526 $VERSION = '1.39_04';
527
528 $header = "perl5db.pl version $VERSION";
529
530 =head1 DEBUGGER ROUTINES
531
532 =head2 C<DB::eval()>
533
534 This function replaces straight C<eval()> inside the debugger; it simplifies
535 the process of evaluating code in the user's context.
536
537 The code to be evaluated is passed via the package global variable
538 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
539
540 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
541 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
542 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
543 user's current package, grabbed when C<DB::DB> got control.  This causes the
544 proper context to be used when the eval is actually done.  Afterward, we
545 restore C<$trace>, C<$single>, and C<$^D>.
546
547 Next we need to handle C<$@> without getting confused. We save C<$@> in a
548 local lexical, localize C<$saved[0]> (which is where C<save()> will put
549 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
550 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
551 considered sane by the debugger. If there was an C<eval()> error, we print
552 it on the debugger's output. If C<$onetimedump> is defined, we call
553 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
554 'methods'. Setting it to something else causes the debugger to do the eval
555 but not print the result - handy if you want to do something else with it
556 (the "watch expressions" code does this to get the value of the watch
557 expression but not show it unless it matters).
558
559 In any case, we then return the list of output from C<eval> to the caller,
560 and unwinding restores the former version of C<$@> in C<@saved> as well
561 (the localization of C<$saved[0]> goes away at the end of this scope).
562
563 =head3 Parameters and variables influencing execution of DB::eval()
564
565 C<DB::eval> isn't parameterized in the standard way; this is to keep the
566 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
567 The variables listed below influence C<DB::eval()>'s execution directly.
568
569 =over 4
570
571 =item C<$evalarg> - the thing to actually be eval'ed
572
573 =item C<$trace> - Current state of execution tracing
574
575 =item C<$single> - Current state of single-stepping
576
577 =item C<$onetimeDump> - what is to be displayed after the evaluation
578
579 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
580
581 =back
582
583 The following variables are altered by C<DB::eval()> during its execution. They
584 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
585
586 =over 4
587
588 =item C<@res> - used to capture output from actual C<eval>.
589
590 =item C<$otrace> - saved value of C<$trace>.
591
592 =item C<$osingle> - saved value of C<$single>.
593
594 =item C<$od> - saved value of C<$^D>.
595
596 =item C<$saved[0]> - saved value of C<$@>.
597
598 =item $\ - for output of C<$@> if there is an evaluation error.
599
600 =back
601
602 =head3 The problem of lexicals
603
604 The context of C<DB::eval()> presents us with some problems. Obviously,
605 we want to be 'sandboxed' away from the debugger's internals when we do
606 the eval, but we need some way to control how punctuation variables and
607 debugger globals are used.
608
609 We can't use local, because the code inside C<DB::eval> can see localized
610 variables; and we can't use C<my> either for the same reason. The code
611 in this routine compromises and uses C<my>.
612
613 After this routine is over, we don't have user code executing in the debugger's
614 context, so we can use C<my> freely.
615
616 =cut
617
618 ############################################## Begin lexical danger zone
619
620 # 'my' variables used here could leak into (that is, be visible in)
621 # the context that the code being evaluated is executing in. This means that
622 # the code could modify the debugger's variables.
623 #
624 # Fiddling with the debugger's context could be Bad. We insulate things as
625 # much as we can.
626
627 use vars qw(
628     @args
629     %break_on_load
630     @cmdfhs
631     $CommandSet
632     $CreateTTY
633     $DBGR
634     @dbline
635     $dbline
636     %dbline
637     $dieLevel
638     $evalarg
639     $filename
640     $frame
641     $hist
642     $histfile
643     $histsize
644     $ImmediateStop
645     $IN
646     $inhibit_exit
647     @ini_INC
648     $ini_warn
649     $line
650     $maxtrace
651     $od
652     $onetimeDump
653     $onetimedumpDepth
654     %option
655     @options
656     $osingle
657     $otrace
658     $OUT
659     $packname
660     $pager
661     $post
662     %postponed
663     $prc
664     $pre
665     $pretype
666     $psh
667     @RememberOnROptions
668     $remoteport
669     @res
670     $rl
671     @saved
672     $signal
673     $signalLevel
674     $single
675     $start
676     $sub
677     %sub
678     $subname
679     $term
680     $trace
681     $usercontext
682     $warnLevel
683     $window
684 );
685
686 # Used to save @ARGV and extract any debugger-related flags.
687 use vars qw(@ARGS);
688
689 # Used to prevent multiple entries to diesignal()
690 # (if for instance diesignal() itself dies)
691 use vars qw($panic);
692
693 # Used to prevent the debugger from running nonstop
694 # after a restart
695 use vars qw($second_time);
696
697 sub _calc_usercontext {
698     my ($package) = @_;
699
700     # Cancel strict completely for the evaluated code, so the code
701     # the user evaluates won't be affected by it. (Shlomi Fish)
702     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @saved;'
703     . "package $package;";    # this won't let them modify, alas
704 }
705
706 sub eval {
707
708     # 'my' would make it visible from user code
709     #    but so does local! --tchrist
710     # Remember: this localizes @DB::res, not @main::res.
711     local @res;
712     {
713
714         # Try to keep the user code from messing  with us. Save these so that
715         # even if the eval'ed code changes them, we can put them back again.
716         # Needed because the user could refer directly to the debugger's
717         # package globals (and any 'my' variables in this containing scope)
718         # inside the eval(), and we want to try to stay safe.
719         local $otrace  = $trace;
720         local $osingle = $single;
721         local $od      = $^D;
722
723         # Untaint the incoming eval() argument.
724         { ($evalarg) = $evalarg =~ /(.*)/s; }
725
726         # $usercontext built in DB::DB near the comment
727         # "set up the context for DB::eval ..."
728         # Evaluate and save any results.
729         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
730
731         # Restore those old values.
732         $trace  = $otrace;
733         $single = $osingle;
734         $^D     = $od;
735     }
736
737     # Save the current value of $@, and preserve it in the debugger's copy
738     # of the saved precious globals.
739     my $at = $@;
740
741     # Since we're only saving $@, we only have to localize the array element
742     # that it will be stored in.
743     local $saved[0];    # Preserve the old value of $@
744     eval { &DB::save };
745
746     # Now see whether we need to report an error back to the user.
747     if ($at) {
748         local $\ = '';
749         print $OUT $at;
750     }
751
752     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
753     # are package globals.
754     elsif ($onetimeDump) {
755         if ( $onetimeDump eq 'dump' ) {
756             local $option{dumpDepth} = $onetimedumpDepth
757               if defined $onetimedumpDepth;
758             dumpit( $OUT, \@res );
759         }
760         elsif ( $onetimeDump eq 'methods' ) {
761             methods( $res[0] );
762         }
763     } ## end elsif ($onetimeDump)
764     @res;
765 } ## end sub eval
766
767 ############################################## End lexical danger zone
768
769 # After this point it is safe to introduce lexicals.
770 # The code being debugged will be executing in its own context, and
771 # can't see the inside of the debugger.
772 #
773 # However, one should not overdo it: leave as much control from outside as
774 # possible. If you make something a lexical, it's not going to be addressable
775 # from outside the debugger even if you know its name.
776
777 # This file is automatically included if you do perl -d.
778 # It's probably not useful to include this yourself.
779 #
780 # Before venturing further into these twisty passages, it is
781 # wise to read the perldebguts man page or risk the ire of dragons.
782 #
783 # (It should be noted that perldebguts will tell you a lot about
784 # the underlying mechanics of how the debugger interfaces into the
785 # Perl interpreter, but not a lot about the debugger itself. The new
786 # comments in this code try to address this problem.)
787
788 # Note that no subroutine call is possible until &DB::sub is defined
789 # (for subroutines defined outside of the package DB). In fact the same is
790 # true if $deep is not defined.
791
792 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
793
794 # modified Perl debugger, to be run from Emacs in perldb-mode
795 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
796 # Johan Vromans -- upgrade to 4.0 pl 10
797 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
798 ########################################################################
799
800 =head1 DEBUGGER INITIALIZATION
801
802 The debugger starts up in phases.
803
804 =head2 BASIC SETUP
805
806 First, it initializes the environment it wants to run in: turning off
807 warnings during its own compilation, defining variables which it will need
808 to avoid warnings later, setting itself up to not exit when the program
809 terminates, and defaulting to printing return values for the C<r> command.
810
811 =cut
812
813 # Needed for the statement after exec():
814 #
815 # This BEGIN block is simply used to switch off warnings during debugger
816 # compilation. Probably it would be better practice to fix the warnings,
817 # but this is how it's done at the moment.
818
819 BEGIN {
820     $ini_warn = $^W;
821     $^W       = 0;
822 }    # Switch compilation warnings off until another BEGIN.
823
824 local ($^W) = 0;    # Switch run-time warnings off during init.
825
826 =head2 THREADS SUPPORT
827
828 If we are running under a threaded Perl, we require threads and threads::shared
829 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
830 threaded debugger control.  C<-dt> can also be used to set this.
831
832 Each new thread will be announced and the debugger prompt will always inform
833 you of each new thread created.  It will also indicate the thread id in which
834 we are currently running within the prompt like this:
835
836         [tid] DB<$i>
837
838 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
839 command prompt.  The prompt will show: C<[0]> when running under threads, but
840 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
841
842 While running under threads, when you set or delete a breakpoint (etc.), this
843 will apply to all threads, not just the currently running one.  When you are
844 in a currently executing thread, you will stay there until it completes.  With
845 the current implementation it is not currently possible to hop from one thread
846 to another.
847
848 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
849
850 Note that threading support was built into the debugger as of Perl version
851 C<5.8.6> and debugger version C<1.2.8>.
852
853 =cut
854
855 BEGIN {
856   # ensure we can share our non-threaded variables or no-op
857   if ($ENV{PERL5DB_THREADED}) {
858         require threads;
859         require threads::shared;
860         import threads::shared qw(share);
861         $DBGR;
862         share(\$DBGR);
863         lock($DBGR);
864         print "Threads support enabled\n";
865   } else {
866         *lock  = sub(*) {};
867         *share = sub(*) {};
868   }
869 }
870
871 # These variables control the execution of 'dumpvar.pl'.
872 {
873     package dumpvar;
874     use vars qw(
875     $hashDepth
876     $arrayDepth
877     $dumpDBFiles
878     $dumpPackages
879     $quoteHighBit
880     $printUndef
881     $globPrint
882     $usageOnly
883     );
884 }
885
886 # used to control die() reporting in diesignal()
887 {
888     package Carp;
889     use vars qw($CarpLevel);
890 }
891
892 # without threads, $filename is not defined until DB::DB is called
893 foreach my $k (keys (%INC)) {
894         share(\$main::{'_<'.$filename}) if defined $filename;
895 };
896
897 # Command-line + PERLLIB:
898 # Save the contents of @INC before they are modified elsewhere.
899 @ini_INC = @INC;
900
901 # This was an attempt to clear out the previous values of various
902 # trapped errors. Apparently it didn't help. XXX More info needed!
903 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
904
905 # We set these variables to safe values. We don't want to blindly turn
906 # off warnings, because other packages may still want them.
907 $trace = $signal = $single = 0;    # Uninitialized warning suppression
908                                    # (local $^W cannot help - other packages!).
909
910 # Default to not exiting when program finishes; print the return
911 # value when the 'r' command is used to return from a subroutine.
912 $inhibit_exit = $option{PrintRet} = 1;
913
914 use vars qw($trace_to_depth);
915
916 # Default to 1E9 so it won't be limited to a certain recursion depth.
917 $trace_to_depth = 1E9;
918
919 =head1 OPTION PROCESSING
920
921 The debugger's options are actually spread out over the debugger itself and
922 C<dumpvar.pl>; some of these are variables to be set, while others are
923 subs to be called with a value. To try to make this a little easier to
924 manage, the debugger uses a few data structures to define what options
925 are legal and how they are to be processed.
926
927 First, the C<@options> array defines the I<names> of all the options that
928 are to be accepted.
929
930 =cut
931
932 @options = qw(
933   CommandSet   HistFile      HistSize
934   hashDepth    arrayDepth    dumpDepth
935   DumpDBFiles  DumpPackages  DumpReused
936   compactDump  veryCompact   quote
937   HighBit      undefPrint    globPrint
938   PrintRet     UsageOnly     frame
939   AutoTrace    TTY           noTTY
940   ReadLine     NonStop       LineInfo
941   maxTraceLen  recallCommand ShellBang
942   pager        tkRunning     ornaments
943   signalLevel  warnLevel     dieLevel
944   inhibit_exit ImmediateStop bareStringify
945   CreateTTY    RemotePort    windowSize
946   DollarCaretP
947 );
948
949 @RememberOnROptions = qw(DollarCaretP);
950
951 =pod
952
953 Second, C<optionVars> lists the variables that each option uses to save its
954 state.
955
956 =cut
957
958 use vars qw(%optionVars);
959
960 %optionVars = (
961     hashDepth     => \$dumpvar::hashDepth,
962     arrayDepth    => \$dumpvar::arrayDepth,
963     CommandSet    => \$CommandSet,
964     DumpDBFiles   => \$dumpvar::dumpDBFiles,
965     DumpPackages  => \$dumpvar::dumpPackages,
966     DumpReused    => \$dumpvar::dumpReused,
967     HighBit       => \$dumpvar::quoteHighBit,
968     undefPrint    => \$dumpvar::printUndef,
969     globPrint     => \$dumpvar::globPrint,
970     UsageOnly     => \$dumpvar::usageOnly,
971     CreateTTY     => \$CreateTTY,
972     bareStringify => \$dumpvar::bareStringify,
973     frame         => \$frame,
974     AutoTrace     => \$trace,
975     inhibit_exit  => \$inhibit_exit,
976     maxTraceLen   => \$maxtrace,
977     ImmediateStop => \$ImmediateStop,
978     RemotePort    => \$remoteport,
979     windowSize    => \$window,
980     HistFile      => \$histfile,
981     HistSize      => \$histsize,
982 );
983
984 =pod
985
986 Third, C<%optionAction> defines the subroutine to be called to process each
987 option.
988
989 =cut
990
991 use vars qw(%optionAction);
992
993 %optionAction = (
994     compactDump   => \&dumpvar::compactDump,
995     veryCompact   => \&dumpvar::veryCompact,
996     quote         => \&dumpvar::quote,
997     TTY           => \&TTY,
998     noTTY         => \&noTTY,
999     ReadLine      => \&ReadLine,
1000     NonStop       => \&NonStop,
1001     LineInfo      => \&LineInfo,
1002     recallCommand => \&recallCommand,
1003     ShellBang     => \&shellBang,
1004     pager         => \&pager,
1005     signalLevel   => \&signalLevel,
1006     warnLevel     => \&warnLevel,
1007     dieLevel      => \&dieLevel,
1008     tkRunning     => \&tkRunning,
1009     ornaments     => \&ornaments,
1010     RemotePort    => \&RemotePort,
1011     DollarCaretP  => \&DollarCaretP,
1012 );
1013
1014 =pod
1015
1016 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1017 option is used.
1018
1019 =cut
1020
1021 # Note that this list is not complete: several options not listed here
1022 # actually require that dumpvar.pl be loaded for them to work, but are
1023 # not in the table. A subsequent patch will correct this problem; for
1024 # the moment, we're just recommenting, and we are NOT going to change
1025 # function.
1026 use vars qw(%optionRequire);
1027
1028 %optionRequire = (
1029     compactDump => 'dumpvar.pl',
1030     veryCompact => 'dumpvar.pl',
1031     quote       => 'dumpvar.pl',
1032 );
1033
1034 =pod
1035
1036 There are a number of initialization-related variables which can be set
1037 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1038 variable. These are:
1039
1040 =over 4
1041
1042 =item C<$rl> - readline control XXX needs more explanation
1043
1044 =item C<$warnLevel> - whether or not debugger takes over warning handling
1045
1046 =item C<$dieLevel> - whether or not debugger takes over die handling
1047
1048 =item C<$signalLevel> - whether or not debugger takes over signal handling
1049
1050 =item C<$pre> - preprompt actions (array reference)
1051
1052 =item C<$post> - postprompt actions (array reference)
1053
1054 =item C<$pretype>
1055
1056 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1057
1058 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1059
1060 =back
1061
1062 =cut
1063
1064 # These guys may be defined in $ENV{PERL5DB} :
1065 $rl          = 1     unless defined $rl;
1066 $warnLevel   = 1     unless defined $warnLevel;
1067 $dieLevel    = 1     unless defined $dieLevel;
1068 $signalLevel = 1     unless defined $signalLevel;
1069 $pre         = []    unless defined $pre;
1070 $post        = []    unless defined $post;
1071 $pretype     = []    unless defined $pretype;
1072 $CreateTTY   = 3     unless defined $CreateTTY;
1073 $CommandSet  = '580' unless defined $CommandSet;
1074
1075 share($rl);
1076 share($warnLevel);
1077 share($dieLevel);
1078 share($signalLevel);
1079 share($pre);
1080 share($post);
1081 share($pretype);
1082 share($rl);
1083 share($CreateTTY);
1084 share($CommandSet);
1085
1086 =pod
1087
1088 The default C<die>, C<warn>, and C<signal> handlers are set up.
1089
1090 =cut
1091
1092 warnLevel($warnLevel);
1093 dieLevel($dieLevel);
1094 signalLevel($signalLevel);
1095
1096 =pod
1097
1098 The pager to be used is needed next. We try to get it from the
1099 environment first.  If it's not defined there, we try to find it in
1100 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1101 then call the C<pager()> function to save the pager name.
1102
1103 =cut
1104
1105 # This routine makes sure $pager is set up so that '|' can use it.
1106 pager(
1107
1108     # If PAGER is defined in the environment, use it.
1109     defined $ENV{PAGER}
1110     ? $ENV{PAGER}
1111
1112       # If not, see if Config.pm defines it.
1113     : eval { require Config }
1114       && defined $Config::Config{pager}
1115     ? $Config::Config{pager}
1116
1117       # If not, fall back to 'more'.
1118     : 'more'
1119   )
1120   unless defined $pager;
1121
1122 =pod
1123
1124 We set up the command to be used to access the man pages, the command
1125 recall character (C<!> unless otherwise defined) and the shell escape
1126 character (C<!> unless otherwise defined). Yes, these do conflict, and
1127 neither works in the debugger at the moment.
1128
1129 =cut
1130
1131 setman();
1132
1133 # Set up defaults for command recall and shell escape (note:
1134 # these currently don't work in linemode debugging).
1135 recallCommand("!") unless defined $prc;
1136 shellBang("!")     unless defined $psh;
1137
1138 =pod
1139
1140 We then set up the gigantic string containing the debugger help.
1141 We also set the limit on the number of arguments we'll display during a
1142 trace.
1143
1144 =cut
1145
1146 sethelp();
1147
1148 # If we didn't get a default for the length of eval/stack trace args,
1149 # set it here.
1150 $maxtrace = 400 unless defined $maxtrace;
1151
1152 =head2 SETTING UP THE DEBUGGER GREETING
1153
1154 The debugger I<greeting> helps to inform the user how many debuggers are
1155 running, and whether the current debugger is the primary or a child.
1156
1157 If we are the primary, we just hang onto our pid so we'll have it when
1158 or if we start a child debugger. If we are a child, we'll set things up
1159 so we'll have a unique greeting and so the parent will give us our own
1160 TTY later.
1161
1162 We save the current contents of the C<PERLDB_PIDS> environment variable
1163 because we mess around with it. We'll also need to hang onto it because
1164 we'll need it if we restart.
1165
1166 Child debuggers make a label out of the current PID structure recorded in
1167 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1168 yet so the parent will give them one later via C<resetterm()>.
1169
1170 =cut
1171
1172 # Save the current contents of the environment; we're about to
1173 # much with it. We'll need this if we have to restart.
1174 use vars qw($ini_pids);
1175 $ini_pids = $ENV{PERLDB_PIDS};
1176
1177 use vars qw ($pids $term_pid);
1178
1179 if ( defined $ENV{PERLDB_PIDS} ) {
1180
1181     # We're a child. Make us a label out of the current PID structure
1182     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1183     # a term yet so the parent will give us one later via resetterm().
1184
1185     my $env_pids = $ENV{PERLDB_PIDS};
1186     $pids = "[$env_pids]";
1187
1188     # Unless we are on OpenVMS, all programs under the DCL shell run under
1189     # the same PID.
1190
1191     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1192         $term_pid         = $$;
1193     }
1194     else {
1195         $ENV{PERLDB_PIDS} .= "->$$";
1196         $term_pid = -1;
1197     }
1198
1199 } ## end if (defined $ENV{PERLDB_PIDS...
1200 else {
1201
1202     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1203     # child debugger, and mark us as the parent, so we'll know to set up
1204     # more TTY's is we have to.
1205     $ENV{PERLDB_PIDS} = "$$";
1206     $pids             = "[pid=$$]";
1207     $term_pid         = $$;
1208 }
1209
1210 use vars qw($pidprompt);
1211 $pidprompt = '';
1212
1213 # Sets up $emacs as a synonym for $slave_editor.
1214 use vars qw($slave_editor);
1215 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1216
1217 =head2 READING THE RC FILE
1218
1219 The debugger will read a file of initialization options if supplied. If
1220 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1221
1222 =cut
1223
1224 # As noted, this test really doesn't check accurately that the debugger
1225 # is running at a terminal or not.
1226
1227 use vars qw($rcfile);
1228 {
1229     my $dev_tty = (($^O eq 'VMS') ? 'TT:' : '/dev/tty');
1230     # this is the wrong metric!
1231     $rcfile = ((-e $dev_tty) ? ".perldb" : "perldb.ini");
1232 }
1233
1234 =pod
1235
1236 The debugger does a safety test of the file to be read. It must be owned
1237 either by the current user or root, and must only be writable by the owner.
1238
1239 =cut
1240
1241 # This wraps a safety test around "do" to read and evaluate the init file.
1242 #
1243 # This isn't really safe, because there's a race
1244 # between checking and opening.  The solution is to
1245 # open and fstat the handle, but then you have to read and
1246 # eval the contents.  But then the silly thing gets
1247 # your lexical scope, which is unfortunate at best.
1248 sub safe_do {
1249     my $file = shift;
1250
1251     # Just exactly what part of the word "CORE::" don't you understand?
1252     local $SIG{__WARN__};
1253     local $SIG{__DIE__};
1254
1255     unless ( is_safe_file($file) ) {
1256         CORE::warn <<EO_GRIPE;
1257 perldb: Must not source insecure rcfile $file.
1258         You or the superuser must be the owner, and it must not
1259         be writable by anyone but its owner.
1260 EO_GRIPE
1261         return;
1262     } ## end unless (is_safe_file($file...
1263
1264     do $file;
1265     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1266 } ## end sub safe_do
1267
1268 # This is the safety test itself.
1269 #
1270 # Verifies that owner is either real user or superuser and that no
1271 # one but owner may write to it.  This function is of limited use
1272 # when called on a path instead of upon a handle, because there are
1273 # no guarantees that filename (by dirent) whose file (by ino) is
1274 # eventually accessed is the same as the one tested.
1275 # Assumes that the file's existence is not in doubt.
1276 sub is_safe_file {
1277     my $path = shift;
1278     stat($path) || return;    # mysteriously vaporized
1279     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1280
1281     return 0 if $uid != 0 && $uid != $<;
1282     return 0 if $mode & 022;
1283     return 1;
1284 } ## end sub is_safe_file
1285
1286 # If the rcfile (whichever one we decided was the right one to read)
1287 # exists, we safely do it.
1288 if ( -f $rcfile ) {
1289     safe_do("./$rcfile");
1290 }
1291
1292 # If there isn't one here, try the user's home directory.
1293 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1294     safe_do("$ENV{HOME}/$rcfile");
1295 }
1296
1297 # Else try the login directory.
1298 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1299     safe_do("$ENV{LOGDIR}/$rcfile");
1300 }
1301
1302 # If the PERLDB_OPTS variable has options in it, parse those out next.
1303 if ( defined $ENV{PERLDB_OPTS} ) {
1304     parse_options( $ENV{PERLDB_OPTS} );
1305 }
1306
1307 =pod
1308
1309 The last thing we do during initialization is determine which subroutine is
1310 to be used to obtain a new terminal when a new debugger is started. Right now,
1311 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1312 (darwin).
1313
1314 =cut
1315
1316 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1317 # Works if you're running an xterm or xterm-like window, or you're on
1318 # OS/2, or on Mac OS X. This may need some expansion.
1319
1320 if (not defined &get_fork_TTY)       # only if no routine exists
1321 {
1322     if ( defined $remoteport ) {
1323                                                  # Expect an inetd-like server
1324         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1325     }
1326     elsif (defined $ENV{TERM}                    # If we know what kind
1327                                                  # of terminal this is,
1328         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1329         and defined $ENV{DISPLAY}                # and what display it's on,
1330       )
1331     {
1332         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1333     }
1334     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1335         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1336     }
1337     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1338             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1339             and $ENV{TERM_PROGRAM}
1340                 eq 'Apple_Terminal'              # Terminal.app
1341             )
1342     {
1343         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1344     }
1345 } ## end if (not defined &get_fork_TTY...
1346
1347 # untaint $^O, which may have been tainted by the last statement.
1348 # see bug [perl #24674]
1349 $^O =~ m/^(.*)\z/;
1350 $^O = $1;
1351
1352 # Here begin the unreadable code.  It needs fixing.
1353
1354 =head2 RESTART PROCESSING
1355
1356 This section handles the restart command. When the C<R> command is invoked, it
1357 tries to capture all of the state it can into environment variables, and
1358 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1359 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1360 the R command stuffed into the environment variables.
1361
1362   PERLDB_RESTART   - flag only, contains no restart data itself.
1363   PERLDB_HIST      - command history, if it's available
1364   PERLDB_ON_LOAD   - breakpoints set by the rc file
1365   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1366   PERLDB_VISITED   - files that had breakpoints
1367   PERLDB_FILE_...  - breakpoints for a file
1368   PERLDB_OPT       - active options
1369   PERLDB_INC       - the original @INC
1370   PERLDB_PRETYPE   - preprompt debugger actions
1371   PERLDB_PRE       - preprompt Perl code
1372   PERLDB_POST      - post-prompt Perl code
1373   PERLDB_TYPEAHEAD - typeahead captured by readline()
1374
1375 We chug through all these variables and plug the values saved in them
1376 back into the appropriate spots in the debugger.
1377
1378 =cut
1379
1380 use vars qw(@hist @truehist %postponed_file @typeahead);
1381
1382 sub _restore_breakpoints_and_actions {
1383
1384     my @had_breakpoints = get_list("PERLDB_VISITED");
1385
1386     for my $file_idx ( 0 .. $#had_breakpoints ) {
1387         my $filename = $had_breakpoints[$file_idx];
1388         my %pf = get_list("PERLDB_FILE_$file_idx");
1389         $postponed_file{ $filename } = \%pf if %pf;
1390         my @lines = sort {$a <=> $b} keys(%pf);
1391         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1392         for my $line_idx (0 .. $#lines) {
1393             _set_breakpoint_enabled_status(
1394                 $filename,
1395                 $lines[$line_idx],
1396                 ($enabled_statuses[$line_idx] ? 1 : ''),
1397             );
1398         }
1399     }
1400
1401     return;
1402 }
1403
1404 sub _restore_options_after_restart
1405 {
1406     my %options_map = get_list("PERLDB_OPT");
1407
1408     while ( my ( $opt, $val ) = each %options_map ) {
1409         $val =~ s/[\\\']/\\$1/g;
1410         parse_options("$opt'$val'");
1411     }
1412
1413     return;
1414 }
1415
1416 sub _restore_globals_after_restart
1417 {
1418     # restore original @INC
1419     @INC     = get_list("PERLDB_INC");
1420     @ini_INC = @INC;
1421
1422     # return pre/postprompt actions and typeahead buffer
1423     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1424     $pre       = [ get_list("PERLDB_PRE") ];
1425     $post      = [ get_list("PERLDB_POST") ];
1426     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1427
1428     return;
1429 }
1430
1431 if ( exists $ENV{PERLDB_RESTART} ) {
1432
1433     # We're restarting, so we don't need the flag that says to restart anymore.
1434     delete $ENV{PERLDB_RESTART};
1435
1436     # $restart = 1;
1437     @hist          = get_list('PERLDB_HIST');
1438     %break_on_load = get_list("PERLDB_ON_LOAD");
1439     %postponed     = get_list("PERLDB_POSTPONE");
1440
1441     share(@hist);
1442     share(@truehist);
1443     share(%break_on_load);
1444     share(%postponed);
1445
1446     _restore_breakpoints_and_actions();
1447
1448     # restore options
1449     _restore_options_after_restart();
1450
1451     _restore_globals_after_restart();
1452 } ## end if (exists $ENV{PERLDB_RESTART...
1453
1454 =head2 SETTING UP THE TERMINAL
1455
1456 Now, we'll decide how the debugger is going to interact with the user.
1457 If there's no TTY, we set the debugger to run non-stop; there's not going
1458 to be anyone there to enter commands.
1459
1460 =cut
1461
1462 use vars qw($notty $runnonstop $console $tty $LINEINFO);
1463 use vars qw($lineinfo $doccmd);
1464
1465 if ($notty) {
1466     $runnonstop = 1;
1467         share($runnonstop);
1468 }
1469
1470 =pod
1471
1472 If there is a TTY, we have to determine who it belongs to before we can
1473 proceed. If this is a slave editor or graphical debugger (denoted by
1474 the first command-line switch being '-emacs'), we shift this off and
1475 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1476
1477 =cut
1478
1479 else {
1480
1481     # Is Perl being run from a slave editor or graphical debugger?
1482     # If so, don't use readline, and set $slave_editor = 1.
1483     $slave_editor =
1484       ( ( defined $main::ARGV[0] ) and ( $main::ARGV[0] eq '-emacs' ) );
1485     $rl = 0, shift(@main::ARGV) if $slave_editor;
1486
1487     #require Term::ReadLine;
1488
1489 =pod
1490
1491 We then determine what the console should be on various systems:
1492
1493 =over 4
1494
1495 =item * Cygwin - We use C<stdin> instead of a separate device.
1496
1497 =cut
1498
1499     if ( $^O eq 'cygwin' ) {
1500
1501         # /dev/tty is binary. use stdin for textmode
1502         undef $console;
1503     }
1504
1505 =item * Unix - use C</dev/tty>.
1506
1507 =cut
1508
1509     elsif ( -e "/dev/tty" ) {
1510         $console = "/dev/tty";
1511     }
1512
1513 =item * Windows or MSDOS - use C<con>.
1514
1515 =cut
1516
1517     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1518         $console = "con";
1519     }
1520
1521 =item * VMS - use C<sys$command>.
1522
1523 =cut
1524
1525     else {
1526
1527         # everything else is ...
1528         $console = "sys\$command";
1529     }
1530
1531 =pod
1532
1533 =back
1534
1535 Several other systems don't use a specific console. We C<undef $console>
1536 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1537 with a slave editor, Epoc).
1538
1539 =cut
1540
1541     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1542
1543         # /dev/tty is binary. use stdin for textmode
1544         $console = undef;
1545     }
1546
1547     if ( $^O eq 'NetWare' ) {
1548
1549         # /dev/tty is binary. use stdin for textmode
1550         $console = undef;
1551     }
1552
1553     # In OS/2, we need to use STDIN to get textmode too, even though
1554     # it pretty much looks like Unix otherwise.
1555     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1556     {    # In OS/2
1557         $console = undef;
1558     }
1559
1560     # EPOC also falls into the 'got to use STDIN' camp.
1561     if ( $^O eq 'epoc' ) {
1562         $console = undef;
1563     }
1564
1565 =pod
1566
1567 If there is a TTY hanging around from a parent, we use that as the console.
1568
1569 =cut
1570
1571     $console = $tty if defined $tty;
1572
1573 =head2 SOCKET HANDLING
1574
1575 The debugger is capable of opening a socket and carrying out a debugging
1576 session over the socket.
1577
1578 If C<RemotePort> was defined in the options, the debugger assumes that it
1579 should try to start a debugging session on that port. It builds the socket
1580 and then tries to connect the input and output filehandles to it.
1581
1582 =cut
1583
1584     # Handle socket stuff.
1585
1586     if ( defined $remoteport ) {
1587
1588         # If RemotePort was defined in the options, connect input and output
1589         # to the socket.
1590         $IN = $OUT = connect_remoteport();
1591     } ## end if (defined $remoteport)
1592
1593 =pod
1594
1595 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1596 this is probably a situation where multiple debuggers are running (for example,
1597 a backticked command that starts up another debugger). We create a new IN and
1598 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1599 and if we can.
1600
1601 =cut
1602
1603     # Non-socket.
1604     else {
1605
1606         # Two debuggers running (probably a system or a backtick that invokes
1607         # the debugger itself under the running one). create a new IN and OUT
1608         # filehandle, and do the necessary mojo to create a new tty if we
1609         # know how, and we can.
1610         create_IN_OUT(4) if $CreateTTY & 4;
1611         if ($console) {
1612
1613             # If we have a console, check to see if there are separate ins and
1614             # outs to open. (They are assumed identical if not.)
1615
1616             my ( $i, $o ) = split /,/, $console;
1617             $o = $i unless defined $o;
1618
1619             # read/write on in, or just read, or read on STDIN.
1620             open( IN,      "+<$i" )
1621               || open( IN, "<$i" )
1622               || open( IN, "<&STDIN" );
1623
1624             # read/write/create/clobber out, or write/create/clobber out,
1625             # or merge with STDERR, or merge with STDOUT.
1626                  open( OUT, "+>$o" )
1627               || open( OUT, ">$o" )
1628               || open( OUT, ">&STDERR" )
1629               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1630
1631         } ## end if ($console)
1632         elsif ( not defined $console ) {
1633
1634             # No console. Open STDIN.
1635             open( IN, "<&STDIN" );
1636
1637             # merge with STDERR, or with STDOUT.
1638             open( OUT,      ">&STDERR" )
1639               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1640             $console = 'STDIN/OUT';
1641         } ## end elsif (not defined $console)
1642
1643         # Keep copies of the filehandles so that when the pager runs, it
1644         # can close standard input without clobbering ours.
1645         $IN = \*IN, $OUT = \*OUT if $console or not defined $console;
1646     } ## end elsif (from if(defined $remoteport))
1647
1648     # Unbuffer DB::OUT. We need to see responses right away.
1649     $OUT->autoflush(1);
1650
1651     # Line info goes to debugger output unless pointed elsewhere.
1652     # Pointing elsewhere makes it possible for slave editors to
1653     # keep track of file and position. We have both a filehandle
1654     # and a I/O description to keep track of.
1655     $LINEINFO = $OUT     unless defined $LINEINFO;
1656     $lineinfo = $console unless defined $lineinfo;
1657         # share($LINEINFO); # <- unable to share globs
1658         share($lineinfo);   #
1659
1660 =pod
1661
1662 To finish initialization, we show the debugger greeting,
1663 and then call the C<afterinit()> subroutine if there is one.
1664
1665 =cut
1666
1667     # Show the debugger greeting.
1668     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1669     unless ($runnonstop) {
1670         local $\ = '';
1671         local $, = '';
1672         if ( $term_pid eq '-1' ) {
1673             print $OUT "\nDaughter DB session started...\n";
1674         }
1675         else {
1676             print $OUT "\nLoading DB routines from $header\n";
1677             print $OUT (
1678                 "Editor support ",
1679                 $slave_editor ? "enabled" : "available", ".\n"
1680             );
1681             print $OUT
1682 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1683         } ## end else [ if ($term_pid eq '-1')
1684     } ## end unless ($runnonstop)
1685 } ## end else [ if ($notty)
1686
1687 # XXX This looks like a bug to me.
1688 # Why copy to @ARGS and then futz with @args?
1689 @ARGS = @ARGV;
1690 # for (@args) {
1691     # Make sure backslashes before single quotes are stripped out, and
1692     # keep args unless they are numeric (XXX why?)
1693     # s/\'/\\\'/g;                      # removed while not justified understandably
1694     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1695 # }
1696
1697 # If there was an afterinit() sub defined, call it. It will get
1698 # executed in our scope, so it can fiddle with debugger globals.
1699 if ( defined &afterinit ) {    # May be defined in $rcfile
1700     &afterinit();
1701 }
1702
1703 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1704 use vars qw($I_m_init);
1705
1706 $I_m_init = 1;
1707
1708 ############################################################ Subroutines
1709
1710 =head1 SUBROUTINES
1711
1712 =head2 DB
1713
1714 This gigantic subroutine is the heart of the debugger. Called before every
1715 statement, its job is to determine if a breakpoint has been reached, and
1716 stop if so; read commands from the user, parse them, and execute
1717 them, and then send execution off to the next statement.
1718
1719 Note that the order in which the commands are processed is very important;
1720 some commands earlier in the loop will actually alter the C<$cmd> variable
1721 to create other commands to be executed later. This is all highly I<optimized>
1722 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1723 see what's happening in any given command.
1724
1725 =cut
1726
1727 use vars qw(
1728     $action
1729     %alias
1730     $cmd
1731     $doret
1732     $fall_off_end
1733     $file
1734     $filename_ini
1735     $finished
1736     %had_breakpoints
1737     $incr
1738     $laststep
1739     $level
1740     $max
1741     @old_watch
1742     $package
1743     $rc
1744     $sh
1745     @stack
1746     $stack_depth
1747     @to_watch
1748     $try
1749     $end
1750 );
1751
1752 sub DB {
1753
1754     # lock the debugger and get the thread id for the prompt
1755         lock($DBGR);
1756         my $tid;
1757         my $position;
1758         my ($prefix, $after, $infix);
1759         my $pat;
1760
1761         if ($ENV{PERL5DB_THREADED}) {
1762                 $tid = eval { "[".threads->tid."]" };
1763         }
1764
1765     # Check for whether we should be running continuously or not.
1766     # _After_ the perl program is compiled, $single is set to 1:
1767     if ( $single and not $second_time++ ) {
1768
1769         # Options say run non-stop. Run until we get an interrupt.
1770         if ($runnonstop) {    # Disable until signal
1771                 # If there's any call stack in place, turn off single
1772                 # stepping into subs throughout the stack.
1773             for my $i (0 .. $stack_depth) {
1774                 $stack[ $i ] &= ~1;
1775             }
1776
1777             # And we are now no longer in single-step mode.
1778             $single = 0;
1779
1780             # If we simply returned at this point, we wouldn't get
1781             # the trace info. Fall on through.
1782             # return;
1783         } ## end if ($runnonstop)
1784
1785         elsif ($ImmediateStop) {
1786
1787             # We are supposed to stop here; XXX probably a break.
1788             $ImmediateStop = 0;    # We've processed it; turn it off
1789             $signal        = 1;    # Simulate an interrupt to force
1790                                    # us into the command loop
1791         }
1792     } ## end if ($single and not $second_time...
1793
1794     # If we're in single-step mode, or an interrupt (real or fake)
1795     # has occurred, turn off non-stop mode.
1796     $runnonstop = 0 if $single or $signal;
1797
1798     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
1799     # The code being debugged may have altered them.
1800     &save;
1801
1802     # Since DB::DB gets called after every line, we can use caller() to
1803     # figure out where we last were executing. Sneaky, eh? This works because
1804     # caller is returning all the extra information when called from the
1805     # debugger.
1806     local ( $package, $filename, $line ) = caller;
1807     $filename_ini = $filename;
1808
1809     # set up the context for DB::eval, so it can properly execute
1810     # code on behalf of the user. We add the package in so that the
1811     # code is eval'ed in the proper package (not in the debugger!).
1812     local $usercontext = _calc_usercontext($package);
1813
1814     # Create an alias to the active file magical array to simplify
1815     # the code here.
1816     local (*dbline) = $main::{ '_<' . $filename };
1817
1818     # Last line in the program.
1819     $max = $#dbline;
1820
1821     # if we have something here, see if we should break.
1822     {
1823         # $stop is lexical and local to this block - $action on the other hand
1824         # is global.
1825         my $stop;
1826
1827         if ( $dbline{$line}
1828             && _is_breakpoint_enabled($filename, $line)
1829             && (( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1830         {
1831
1832             # Stop if the stop criterion says to just stop.
1833             if ( $stop eq '1' ) {
1834                 $signal |= 1;
1835             }
1836
1837             # It's a conditional stop; eval it in the user's context and
1838             # see if we should stop. If so, remove the one-time sigil.
1839             elsif ($stop) {
1840                 $evalarg = "\$DB::signal |= 1 if do {$stop}";
1841                 &eval;
1842                 # If the breakpoint is temporary, then delete its enabled status.
1843                 if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1844                     _cancel_breakpoint_temp_enabled_status($filename, $line);
1845                 }
1846             }
1847         } ## end if ($dbline{$line} && ...
1848     }
1849
1850     # Preserve the current stop-or-not, and see if any of the W
1851     # (watch expressions) has changed.
1852     my $was_signal = $signal;
1853
1854     # If we have any watch expressions ...
1855     if ( $trace & 2 ) {
1856         for my $n (0 .. $#to_watch) {
1857             $evalarg = $to_watch[$n];
1858             local $onetimeDump;    # Tell DB::eval() to not output results
1859
1860             # Fix context DB::eval() wants to return an array, but
1861             # we need a scalar here.
1862             my ($val) = join( "', '", &eval );
1863             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
1864
1865             # Did it change?
1866             if ( $val ne $old_watch[$n] ) {
1867
1868                 # Yep! Show the difference, and fake an interrupt.
1869                 $signal = 1;
1870                 print $OUT <<EOP;
1871 Watchpoint $n:\t$to_watch[$n] changed:
1872     old value:\t$old_watch[$n]
1873     new value:\t$val
1874 EOP
1875                 $old_watch[$n] = $val;
1876             } ## end if ($val ne $old_watch...
1877         } ## end for my $n (0 ..
1878     } ## end if ($trace & 2)
1879
1880 =head2 C<watchfunction()>
1881
1882 C<watchfunction()> is a function that can be defined by the user; it is a
1883 function which will be run on each entry to C<DB::DB>; it gets the
1884 current package, filename, and line as its parameters.
1885
1886 The watchfunction can do anything it likes; it is executing in the
1887 debugger's context, so it has access to all of the debugger's internal
1888 data structures and functions.
1889
1890 C<watchfunction()> can control the debugger's actions. Any of the following
1891 will cause the debugger to return control to the user's program after
1892 C<watchfunction()> executes:
1893
1894 =over 4
1895
1896 =item *
1897
1898 Returning a false value from the C<watchfunction()> itself.
1899
1900 =item *
1901
1902 Altering C<$single> to a false value.
1903
1904 =item *
1905
1906 Altering C<$signal> to a false value.
1907
1908 =item *
1909
1910 Turning off the C<4> bit in C<$trace> (this also disables the
1911 check for C<watchfunction()>. This can be done with
1912
1913     $trace &= ~4;
1914
1915 =back
1916
1917 =cut
1918
1919     # If there's a user-defined DB::watchfunction, call it with the
1920     # current package, filename, and line. The function executes in
1921     # the DB:: package.
1922     if ( $trace & 4 ) {    # User-installed watch
1923         return
1924           if watchfunction( $package, $filename, $line )
1925           and not $single
1926           and not $was_signal
1927           and not( $trace & ~4 );
1928     } ## end if ($trace & 4)
1929
1930     # Pick up any alteration to $signal in the watchfunction, and
1931     # turn off the signal now.
1932     $was_signal = $signal;
1933     $signal     = 0;
1934
1935 =head2 GETTING READY TO EXECUTE COMMANDS
1936
1937 The debugger decides to take control if single-step mode is on, the
1938 C<t> command was entered, or the user generated a signal. If the program
1939 has fallen off the end, we set things up so that entering further commands
1940 won't cause trouble, and we say that the program is over.
1941
1942 =cut
1943
1944     # Make sure that we always print if asked for explicitly regardless
1945     # of $trace_to_depth .
1946     my $explicit_stop = ($single || $was_signal);
1947
1948     # Check to see if we should grab control ($single true,
1949     # trace set appropriately, or we got a signal).
1950     if ( $explicit_stop || ( $trace & 1 ) ) {
1951
1952         # Yes, grab control.
1953         if ($slave_editor) {
1954
1955             # Tell the editor to update its position.
1956             $position = "\032\032$filename:$line:0\n";
1957             print_lineinfo($position);
1958         }
1959
1960 =pod
1961
1962 Special check: if we're in package C<DB::fake>, we've gone through the
1963 C<END> block at least once. We set up everything so that we can continue
1964 to enter commands and have a valid context to be in.
1965
1966 =cut
1967
1968         elsif ( $package eq 'DB::fake' ) {
1969
1970             # Fallen off the end already.
1971             $term || &setterm;
1972             print_help(<<EOP);
1973 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
1974   use B<o> I<inhibit_exit> to avoid stopping after program termination,
1975   B<h q>, B<h R> or B<h o> to get additional info.
1976 EOP
1977
1978             # Set the DB::eval context appropriately.
1979             $package     = 'main';
1980             $usercontext = _calc_usercontext($package);
1981         } ## end elsif ($package eq 'DB::fake')
1982
1983 =pod
1984
1985 If the program hasn't finished executing, we scan forward to the
1986 next executable line, print that out, build the prompt from the file and line
1987 number information, and print that.
1988
1989 =cut
1990
1991         else {
1992
1993
1994             # Still somewhere in the midst of execution. Set up the
1995             #  debugger prompt.
1996             $sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
1997                                  # Perl 5 ones (sorry, we don't print Klingon
1998                                  #module names)
1999
2000             $prefix = $sub =~ /::/ ? "" : ($package . '::');
2001             $prefix .= "$sub($filename:";
2002             $after = ( $dbline[$line] =~ /\n$/ ? '' : "\n" );
2003
2004             # Break up the prompt if it's really long.
2005             if ( length($prefix) > 30 ) {
2006                 $position = "$prefix$line):\n$line:\t$dbline[$line]$after";
2007                 $prefix   = "";
2008                 $infix    = ":\t";
2009             }
2010             else {
2011                 $infix    = "):\t";
2012                 $position = "$prefix$line$infix$dbline[$line]$after";
2013             }
2014
2015             # Print current line info, indenting if necessary.
2016             if ($frame) {
2017                 print_lineinfo( ' ' x $stack_depth,
2018                     "$line:\t$dbline[$line]$after" );
2019             }
2020             else {
2021                 depth_print_lineinfo($explicit_stop, $position);
2022             }
2023
2024             # Scan forward, stopping at either the end or the next
2025             # unbreakable line.
2026             for ( my $i = $line + 1 ; $i <= $max && $dbline[$i] == 0 ; ++$i )
2027             {    #{ vi
2028
2029                 # Drop out on null statements, block closers, and comments.
2030                 last if $dbline[$i] =~ /^\s*[\;\}\#\n]/;
2031
2032                 # Drop out if the user interrupted us.
2033                 last if $signal;
2034
2035                 # Append a newline if the line doesn't have one. Can happen
2036                 # in eval'ed text, for instance.
2037                 $after = ( $dbline[$i] =~ /\n$/ ? '' : "\n" );
2038
2039                 # Next executable line.
2040                 my $incr_pos = "$prefix$i$infix$dbline[$i]$after";
2041                 $position .= $incr_pos;
2042                 if ($frame) {
2043
2044                     # Print it indented if tracing is on.
2045                     print_lineinfo( ' ' x $stack_depth,
2046                         "$i:\t$dbline[$i]$after" );
2047                 }
2048                 else {
2049                     depth_print_lineinfo($explicit_stop, $incr_pos);
2050                 }
2051             } ## end for ($i = $line + 1 ; $i...
2052         } ## end else [ if ($slave_editor)
2053     } ## end if ($single || ($trace...
2054
2055 =pod
2056
2057 If there's an action to be executed for the line we stopped at, execute it.
2058 If there are any preprompt actions, execute those as well.
2059
2060 =cut
2061
2062     # If there's an action, do it now.
2063     $evalarg = $action, &eval if $action;
2064
2065     # Are we nested another level (e.g., did we evaluate a function
2066     # that had a breakpoint in it at the debugger prompt)?
2067     if ( $single || $was_signal ) {
2068
2069         # Yes, go down a level.
2070         local $level = $level + 1;
2071
2072         # Do any pre-prompt actions.
2073         foreach $evalarg (@$pre) {
2074             &eval;
2075         }
2076
2077         # Complain about too much recursion if we passed the limit.
2078         print $OUT $stack_depth . " levels deep in subroutine calls!\n"
2079           if $single & 4;
2080
2081         # The line we're currently on. Set $incr to -1 to stay here
2082         # until we get a command that tells us to advance.
2083         $start = $line;
2084         $incr  = -1;      # for backward motion.
2085
2086         # Tack preprompt debugger actions ahead of any actual input.
2087         @typeahead = ( @$pretype, @typeahead );
2088
2089 =head2 WHERE ARE WE?
2090
2091 XXX Relocate this section?
2092
2093 The debugger normally shows the line corresponding to the current line of
2094 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2095 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2096
2097 C<$incr> controls by how many lines the I<current> line should move forward
2098 after a command is executed. If set to -1, this indicates that the I<current>
2099 line shouldn't change.
2100
2101 C<$start> is the I<current> line. It is used for things like knowing where to
2102 move forwards or backwards from when doing an C<L> or C<-> command.
2103
2104 C<$max> tells the debugger where the last line of the current file is. It's
2105 used to terminate loops most often.
2106
2107 =head2 THE COMMAND LOOP
2108
2109 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2110 in two parts:
2111
2112 =over 4
2113
2114 =item *
2115
2116 The outer part of the loop, starting at the C<CMD> label. This loop
2117 reads a command and then executes it.
2118
2119 =item *
2120
2121 The inner part of the loop, starting at the C<PIPE> label. This part
2122 is wholly contained inside the C<CMD> block and only executes a command.
2123 Used to handle commands running inside a pager.
2124
2125 =back
2126
2127 So why have two labels to restart the loop? Because sometimes, it's easier to
2128 have a command I<generate> another command and then re-execute the loop to do
2129 the new command. This is faster, but perhaps a bit more convoluted.
2130
2131 =cut
2132
2133         # The big command dispatch loop. It keeps running until the
2134         # user yields up control again.
2135         #
2136         # If we have a terminal for input, and we get something back
2137         # from readline(), keep on processing.
2138         my $piped;
2139         my $selected;
2140
2141       CMD:
2142         while (
2143
2144             # We have a terminal, or can get one ...
2145             ( $term || &setterm ),
2146
2147             # ... and it belogs to this PID or we get one for this PID ...
2148             ( $term_pid == $$ or resetterm(1) ),
2149
2150             # ... and we got a line of command input ...
2151             defined(
2152                 $cmd = &readline(
2153                         "$pidprompt $tid DB"
2154                       . ( '<' x $level )
2155                       . ( $#hist + 1 )
2156                       . ( '>' x $level ) . " "
2157                 )
2158             )
2159           )
2160         {
2161
2162                         share($cmd);
2163             # ... try to execute the input as debugger commands.
2164
2165             # Don't stop running.
2166             $single = 0;
2167
2168             # No signal is active.
2169             $signal = 0;
2170
2171             # Handle continued commands (ending with \):
2172             if ($cmd =~ s/\\\z/\n/) {
2173                 $cmd .= &readline("  cont: ");
2174                 redo CMD;
2175             }
2176
2177 =head4 The null command
2178
2179 A newline entered by itself means I<re-execute the last command>. We grab the
2180 command out of C<$laststep> (where it was recorded previously), and copy it
2181 back into C<$cmd> to be executed below. If there wasn't any previous command,
2182 we'll do nothing below (no command will match). If there was, we also save it
2183 in the command history and fall through to allow the command parsing to pick
2184 it up.
2185
2186 =cut
2187
2188             # Empty input means repeat the last command.
2189             $cmd =~ /^$/ && ( $cmd = $laststep );
2190             chomp($cmd);    # get rid of the annoying extra newline
2191             push( @hist, $cmd ) if length($cmd) > 1;
2192             push( @truehist, $cmd );
2193                         share(@hist);
2194                         share(@truehist);
2195
2196             # This is a restart point for commands that didn't arrive
2197             # via direct user input. It allows us to 'redo PIPE' to
2198             # re-execute command processing without reading a new command.
2199           PIPE: {
2200                 $cmd =~ s/^\s+//s;    # trim annoying leading whitespace
2201                 $cmd =~ s/\s+$//s;    # trim annoying trailing whitespace
2202                 my ($i) = split( /\s+/, $cmd );
2203
2204 =head3 COMMAND ALIASES
2205
2206 The debugger can create aliases for commands (these are stored in the
2207 C<%alias> hash). Before a command is executed, the command loop looks it up
2208 in the alias hash and substitutes the contents of the alias for the command,
2209 completely replacing it.
2210
2211 =cut
2212
2213                 # See if there's an alias for the command, and set it up if so.
2214                 if ( $alias{$i} ) {
2215
2216                     # Squelch signal handling; we want to keep control here
2217                     # if something goes loco during the alias eval.
2218                     local $SIG{__DIE__};
2219                     local $SIG{__WARN__};
2220
2221                     # This is a command, so we eval it in the DEBUGGER's
2222                     # scope! Otherwise, we can't see the special debugger
2223                     # variables, or get to the debugger's subs. (Well, we
2224                     # _could_, but why make it even more complicated?)
2225                     eval "\$cmd =~ $alias{$i}";
2226                     if ($@) {
2227                         local $\ = '';
2228                         print $OUT "Couldn't evaluate '$i' alias: $@";
2229                         next CMD;
2230                     }
2231                 } ## end if ($alias{$i})
2232
2233 =head3 MAIN-LINE COMMANDS
2234
2235 All of these commands work up to and after the program being debugged has
2236 terminated.
2237
2238 =head4 C<q> - quit
2239
2240 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2241 try to execute further, cleaning any restart-related stuff out of the
2242 environment, and executing with the last value of C<$?>.
2243
2244 =cut
2245
2246                 if ($cmd eq 'q') {
2247                     $fall_off_end = 1;
2248                     clean_ENV();
2249                     exit $?;
2250                 }
2251
2252 =head4 C<t> - trace [n]
2253
2254 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2255 If level is specified, set C<$trace_to_depth>.
2256
2257 =cut
2258
2259                 if (my ($levels) = $cmd =~ /\At(?:\s+(\d+))?\z/) {
2260                     $trace ^= 1;
2261                     local $\ = '';
2262                     $trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
2263                     print $OUT "Trace = "
2264                       . ( ( $trace & 1 )
2265                       ? ( $levels ? "on (to level $trace_to_depth)" : "on" )
2266                       : "off" ) . "\n";
2267                     next CMD;
2268                 }
2269
2270 =head4 C<S> - list subroutines matching/not matching a pattern
2271
2272 Walks through C<%sub>, checking to see whether or not to print the name.
2273
2274 =cut
2275
2276                 if (my ($print_all_subs, $should_reverse, $Spatt)
2277                     = $cmd =~ /\AS(\s+(!)?(.+))?\z/) {
2278                     # $Spatt is the pattern (if any) to use.
2279                     # Reverse scan?
2280                     my $Srev     = defined $should_reverse;
2281                     # No args - print all subs.
2282                     my $Snocheck = !defined $print_all_subs;
2283
2284                     # Need to make these sane here.
2285                     local $\ = '';
2286                     local $, = '';
2287
2288                     # Search through the debugger's magical hash of subs.
2289                     # If $nocheck is true, just print the sub name.
2290                     # Otherwise, check it against the pattern. We then use
2291                     # the XOR trick to reverse the condition as required.
2292                     foreach $subname ( sort( keys %sub ) ) {
2293                         if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
2294                             print $OUT $subname, "\n";
2295                         }
2296                     }
2297                     next CMD;
2298                 }
2299
2300 =head4 C<X> - list variables in current package
2301
2302 Since the C<V> command actually processes this, just change this to the
2303 appropriate C<V> command and fall through.
2304
2305 =cut
2306
2307                 $cmd =~ s/^X\b/V $package/;
2308
2309 =head4 C<V> - list variables
2310
2311 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2312
2313 =cut
2314
2315                 # Bare V commands get the currently-being-debugged package
2316                 # added.
2317                 if ($cmd eq "V") {
2318                     $cmd = "V $package";
2319                 }
2320
2321                 # V - show variables in package.
2322                 if (my ($new_packname, $new_vars_str) =
2323                     $cmd =~ /\AV\b\s*(\S+)\s*(.*)/) {
2324
2325                     # Save the currently selected filehandle and
2326                     # force output to debugger's filehandle (dumpvar
2327                     # just does "print" for output).
2328                     my $savout = select($OUT);
2329
2330                     # Grab package name and variables to dump.
2331                     $packname = $new_packname;
2332                     my @vars     = split( ' ', $new_vars_str );
2333
2334                     # If main::dumpvar isn't here, get it.
2335                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2336                     if ( defined &main::dumpvar ) {
2337
2338                         # We got it. Turn off subroutine entry/exit messages
2339                         # for the moment, along with return values.
2340                         local $frame = 0;
2341                         local $doret = -2;
2342
2343                         # must detect sigpipe failures  - not catching
2344                         # then will cause the debugger to die.
2345                         eval {
2346                             &main::dumpvar(
2347                                 $packname,
2348                                 defined $option{dumpDepth}
2349                                 ? $option{dumpDepth}
2350                                 : -1,    # assume -1 unless specified
2351                                 @vars
2352                             );
2353                         };
2354
2355                         # The die doesn't need to include the $@, because
2356                         # it will automatically get propagated for us.
2357                         if ($@) {
2358                             die unless $@ =~ /dumpvar print failed/;
2359                         }
2360                     } ## end if (defined &main::dumpvar)
2361                     else {
2362
2363                         # Couldn't load dumpvar.
2364                         print $OUT "dumpvar.pl not available.\n";
2365                     }
2366
2367                     # Restore the output filehandle, and go round again.
2368                     select($savout);
2369                     next CMD;
2370                 }
2371
2372 =head4 C<x> - evaluate and print an expression
2373
2374 Hands the expression off to C<DB::eval>, setting it up to print the value
2375 via C<dumpvar.pl> instead of just printing it directly.
2376
2377 =cut
2378
2379                 if ($cmd =~ s#\Ax\b# #) {    # Remainder gets done by DB::eval()
2380                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2381
2382                     # handle special  "x 3 blah" syntax XXX propagate
2383                     # doc back to special variables.
2384                     if ( $cmd =~ s#\A\s*(\d+)(?=\s)# #) {
2385                         $onetimedumpDepth = $1;
2386                     }
2387                 }
2388
2389 =head4 C<m> - print methods
2390
2391 Just uses C<DB::methods> to determine what methods are available.
2392
2393 =cut
2394
2395                 if ($cmd =~ s#\Am\s+([\w:]+)\s*\z# #) {
2396                     methods($1);
2397                     next CMD;
2398                 }
2399
2400                 # m expr - set up DB::eval to do the work
2401                 if ($cmd =~ s#\Am\b# #) {    # Rest gets done by DB::eval()
2402                     $onetimeDump = 'methods';   #  method output gets used there
2403                 }
2404
2405 =head4 C<f> - switch files
2406
2407 =cut
2408
2409                 if (($file) = $cmd =~ /\Af\b\s*(.*)/) {
2410                     $file =~ s/\s+$//;
2411
2412                     # help for no arguments (old-style was return from sub).
2413                     if ( !$file ) {
2414                         print $OUT
2415                           "The old f command is now the r command.\n";    # hint
2416                         print $OUT "The new f command switches filenames.\n";
2417                         next CMD;
2418                     } ## end if (!$file)
2419
2420                     # if not in magic file list, try a close match.
2421                     if ( !defined $main::{ '_<' . $file } ) {
2422                         if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
2423                             {
2424                                 $try = substr( $try, 2 );
2425                                 print $OUT "Choosing $try matching '$file':\n";
2426                                 $file = $try;
2427                             }
2428                         } ## end if (($try) = grep(m#^_<.*$file#...
2429                     } ## end if (!defined $main::{ ...
2430
2431                     # If not successfully switched now, we failed.
2432                     if ( !defined $main::{ '_<' . $file } ) {
2433                         print $OUT "No file matching '$file' is loaded.\n";
2434                         next CMD;
2435                     }
2436
2437                     # We switched, so switch the debugger internals around.
2438                     elsif ( $file ne $filename ) {
2439                         *dbline   = $main::{ '_<' . $file };
2440                         $max      = $#dbline;
2441                         $filename = $file;
2442                         $start    = 1;
2443                         $cmd      = "l";
2444                     } ## end elsif ($file ne $filename)
2445
2446                     # We didn't switch; say we didn't.
2447                     else {
2448                         print $OUT "Already in $file.\n";
2449                         next CMD;
2450                     }
2451                 }
2452
2453 =head4 C<.> - return to last-executed line.
2454
2455 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2456 and then we look up the line in the magical C<%dbline> hash.
2457
2458 =cut
2459
2460                 # . command.
2461                 if ($cmd eq '.') {
2462                     $incr = -1;    # stay at current line
2463
2464                     # Reset everything to the old location.
2465                     $start    = $line;
2466                     $filename = $filename_ini;
2467                     *dbline   = $main::{ '_<' . $filename };
2468                     $max      = $#dbline;
2469
2470                     # Now where are we?
2471                     print_lineinfo($position);
2472                     next CMD;
2473                 }
2474
2475 =head4 C<-> - back one window
2476
2477 We change C<$start> to be one window back; if we go back past the first line,
2478 we set it to be the first line. We ser C<$incr> to put us back at the
2479 currently-executing line, and then put a C<l $start +> (list one window from
2480 C<$start>) in C<$cmd> to be executed later.
2481
2482 =cut
2483
2484                 # - - back a window.
2485                 if ($cmd eq '-') {
2486
2487                     # back up by a window; go to 1 if back too far.
2488                     $start -= $incr + $window + 1;
2489                     $start = 1 if $start <= 0;
2490                     $incr  = $window - 1;
2491
2492                     # Generate and execute a "l +" command (handled below).
2493                     $cmd = 'l ' . ($start) . '+';
2494                 }
2495
2496 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, {, {{>
2497
2498 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2499 problems, most notably that the default case of several commands destroying
2500 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2501 retain the old commands for those who were used to using them or who preferred
2502 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2503 deal with them instead of processing them in-line.
2504
2505 =cut
2506
2507                 # All of these commands were remapped in perl 5.8.0;
2508                 # we send them off to the secondary dispatcher (see below).
2509                 if (my ($cmd_letter, $my_arg) = $cmd =~ /\A([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so) {
2510                     &cmd_wrapper( $cmd_letter, $my_arg, $line );
2511                     next CMD;
2512                 }
2513
2514 =head4 C<y> - List lexicals in higher scope
2515
2516 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2517 above the current one and then displays then using C<dumpvar.pl>.
2518
2519 =cut
2520
2521                 if (my ($match_level, $match_vars)
2522                     = $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/) {
2523
2524                     # See if we've got the necessary support.
2525                     eval { require PadWalker; PadWalker->VERSION(0.08) }
2526                       or &warn(
2527                         $@ =~ /locate/
2528                         ? "PadWalker module not found - please install\n"
2529                         : $@
2530                       )
2531                       and next CMD;
2532
2533                     # Load up dumpvar if we don't have it. If we can, that is.
2534                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2535                     defined &main::dumpvar
2536                       or print $OUT "dumpvar.pl not available.\n"
2537                       and next CMD;
2538
2539                     # Got all the modules we need. Find them and print them.
2540                     my @vars = split( ' ', $match_vars || '' );
2541
2542                     # Find the pad.
2543                     my $h = eval { PadWalker::peek_my( ( $match_level || 0 ) + 1 ) };
2544
2545                     # Oops. Can't find it.
2546                     $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
2547
2548                     # Show the desired vars with dumplex().
2549                     my $savout = select($OUT);
2550
2551                     # Have dumplex dump the lexicals.
2552                     dumpvar::dumplex( $_, $h->{$_},
2553                         defined $option{dumpDepth} ? $option{dumpDepth} : -1,
2554                         @vars )
2555                       for sort keys %$h;
2556                     select($savout);
2557                     next CMD;
2558                 }
2559
2560 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2561
2562 All of the commands below this point don't work after the program being
2563 debugged has ended. All of them check to see if the program has ended; this
2564 allows the commands to be relocated without worrying about a 'line of
2565 demarcation' above which commands can be entered anytime, and below which
2566 they can't.
2567
2568 =head4 C<n> - single step, but don't trace down into subs
2569
2570 Done by setting C<$single> to 2, which forces subs to execute straight through
2571 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2572 so a null command knows what to re-execute.
2573
2574 =cut
2575
2576                 # n - next
2577                 if ($cmd eq 'n') {
2578                     end_report(), next CMD if $finished and $level <= 1;
2579
2580                     # Single step, but don't enter subs.
2581                     $single = 2;
2582
2583                     # Save for empty command (repeat last).
2584                     $laststep = $cmd;
2585                     last CMD;
2586                 }
2587
2588 =head4 C<s> - single-step, entering subs
2589
2590 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2591 subs. Also saves C<s> as C<$lastcmd>.
2592
2593 =cut
2594
2595                 # s - single step.
2596                 if ($cmd eq 's') {
2597
2598                     # Get out and restart the command loop if program
2599                     # has finished.
2600                     end_report(), next CMD if $finished and $level <= 1;
2601
2602                     # Single step should enter subs.
2603                     $single = 1;
2604
2605                     # Save for empty command (repeat last).
2606                     $laststep = $cmd;
2607                     last CMD;
2608                 }
2609
2610 =head4 C<c> - run continuously, setting an optional breakpoint
2611
2612 Most of the code for this command is taken up with locating the optional
2613 breakpoint, which is either a subroutine name or a line number. We set
2614 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2615 in this and all call levels above this one.
2616
2617 =cut
2618
2619                 # c - start continuous execution.
2620                 if (($i) = $cmd =~ m#\Ac\b\s*([\w:]*)\s*\z#) {
2621
2622                     # Hey, show's over. The debugged program finished
2623                     # executing already.
2624                     end_report(), next CMD if $finished and $level <= 1;
2625
2626                     # Capture the place to put a one-time break.
2627                     $subname = $i;
2628
2629                     #  Probably not needed, since we finish an interactive
2630                     #  sub-session anyway...
2631                     # local $filename = $filename;
2632                     # local *dbline = *dbline; # XXX Would this work?!
2633                     #
2634                     # The above question wonders if localizing the alias
2635                     # to the magic array works or not. Since it's commented
2636                     # out, we'll just leave that to speculation for now.
2637
2638                     # If the "subname" isn't all digits, we'll assume it
2639                     # is a subroutine name, and try to find it.
2640                     if ( $subname =~ /\D/ ) {    # subroutine name
2641                             # Qualify it to the current package unless it's
2642                             # already qualified.
2643                         $subname = $package . "::" . $subname
2644                           unless $subname =~ /::/;
2645
2646                         # find_sub will return "file:line_number" corresponding
2647                         # to where the subroutine is defined; we call find_sub,
2648                         # break up the return value, and assign it in one
2649                         # operation.
2650                         ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2651
2652                         # Force the line number to be numeric.
2653                         $i += 0;
2654
2655                         # If we got a line number, we found the sub.
2656                         if ($i) {
2657
2658                             # Switch all the debugger's internals around so
2659                             # we're actually working with that file.
2660                             $filename = $file;
2661                             *dbline   = $main::{ '_<' . $filename };
2662
2663                             # Mark that there's a breakpoint in this file.
2664                             $had_breakpoints{$filename} |= 1;
2665
2666                             # Scan forward to the first executable line
2667                             # after the 'sub whatever' line.
2668                             $max = $#dbline;
2669                             ++$i while $dbline[$i] == 0 && $i < $max;
2670                         } ## end if ($i)
2671
2672                         # We didn't find a sub by that name.
2673                         else {
2674                             print $OUT "Subroutine $subname not found.\n";
2675                             next CMD;
2676                         }
2677                     } ## end if ($subname =~ /\D/)
2678
2679                     # At this point, either the subname was all digits (an
2680                     # absolute line-break request) or we've scanned through
2681                     # the code following the definition of the sub, looking
2682                     # for an executable, which we may or may not have found.
2683                     #
2684                     # If $i (which we set $subname from) is non-zero, we
2685                     # got a request to break at some line somewhere. On
2686                     # one hand, if there wasn't any real subroutine name
2687                     # involved, this will be a request to break in the current
2688                     # file at the specified line, so we have to check to make
2689                     # sure that the line specified really is breakable.
2690                     #
2691                     # On the other hand, if there was a subname supplied, the
2692                     # preceding block has moved us to the proper file and
2693                     # location within that file, and then scanned forward
2694                     # looking for the next executable line. We have to make
2695                     # sure that one was found.
2696                     #
2697                     # On the gripping hand, we can't do anything unless the
2698                     # current value of $i points to a valid breakable line.
2699                     # Check that.
2700                     if ($i) {
2701
2702                         # Breakable?
2703                         if ( $dbline[$i] == 0 ) {
2704                             print $OUT "Line $i not breakable.\n";
2705                             next CMD;
2706                         }
2707
2708                         # Yes. Set up the one-time-break sigil.
2709                         $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2710                         _enable_breakpoint_temp_enabled_status($filename, $i);
2711                     } ## end if ($i)
2712
2713                     # Turn off stack tracing from here up.
2714                     for my $i (0 .. $stack_depth) {
2715                         $stack[ $i ] &= ~1;
2716                     }
2717                     last CMD;
2718                 }
2719
2720 =head4 C<r> - return from a subroutine
2721
2722 For C<r> to work properly, the debugger has to stop execution again
2723 immediately after the return is executed. This is done by forcing
2724 single-stepping to be on in the call level above the current one. If
2725 we are printing return values when a C<r> is executed, set C<$doret>
2726 appropriately, and force us out of the command loop.
2727
2728 =cut
2729
2730                 # r - return from the current subroutine.
2731                 if ($cmd eq 'r') {
2732
2733                     # Can't do anything if the program's over.
2734                     end_report(), next CMD if $finished and $level <= 1;
2735
2736                     # Turn on stack trace.
2737                     $stack[$stack_depth] |= 1;
2738
2739                     # Print return value unless the stack is empty.
2740                     $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
2741                     last CMD;
2742                 }
2743
2744 =head4 C<T> - stack trace
2745
2746 Just calls C<DB::print_trace>.
2747
2748 =cut
2749
2750                 if ($cmd eq 'T') {
2751                     print_trace( $OUT, 1 );    # skip DB
2752                     next CMD;
2753                 }
2754
2755 =head4 C<w> - List window around current line.
2756
2757 Just calls C<DB::cmd_w>.
2758
2759 =cut
2760
2761                 if (my ($arg) = $cmd =~ /\Aw\b\s*(.*)/s) {
2762                     &cmd_w( 'w', $arg );
2763                     next CMD;
2764                 }
2765
2766 =head4 C<W> - watch-expression processing.
2767
2768 Just calls C<DB::cmd_W>.
2769
2770 =cut
2771
2772                 if (my ($arg) = $cmd =~ /\AW\b\s*(.*)/s) {
2773                     &cmd_W( 'W', $arg );
2774                     next CMD;
2775                 }
2776
2777 =head4 C</> - search forward for a string in the source
2778
2779 We take the argument and treat it as a pattern. If it turns out to be a
2780 bad one, we return the error we got from trying to C<eval> it and exit.
2781 If not, we create some code to do the search and C<eval> it so it can't
2782 mess us up.
2783
2784 =cut
2785
2786                 # The pattern as a string.
2787                 use vars qw($inpat);
2788
2789                 if (($inpat) = $cmd =~ m#\A/(.*)\z#) {
2790
2791                     # Remove the final slash.
2792                     $inpat =~ s:([^\\])/$:$1:;
2793
2794                     # If the pattern isn't null ...
2795                     if ( $inpat ne "" ) {
2796
2797                         # Turn of warn and die procesing for a bit.
2798                         local $SIG{__DIE__};
2799                         local $SIG{__WARN__};
2800
2801                         # Create the pattern.
2802                         eval '$inpat =~ m' . "\a$inpat\a";
2803                         if ( $@ ne "" ) {
2804
2805                             # Oops. Bad pattern. No biscuit.
2806                             # Print the eval error and go back for more
2807                             # commands.
2808                             print $OUT "$@";
2809                             next CMD;
2810                         }
2811                         $pat = $inpat;
2812                     } ## end if ($inpat ne "")
2813
2814                     # Set up to stop on wrap-around.
2815                     $end = $start;
2816
2817                     # Don't move off the current line.
2818                     $incr = -1;
2819
2820                     # Done in eval so nothing breaks if the pattern
2821                     # does something weird.
2822                     eval '
2823                         for (;;) {
2824                             # Move ahead one line.
2825                             ++$start;
2826
2827                             # Wrap if we pass the last line.
2828                             $start = 1 if ($start > $max);
2829
2830                             # Stop if we have gotten back to this line again,
2831                             last if ($start == $end);
2832
2833                             # A hit! (Note, though, that we are doing
2834                             # case-insensitive matching. Maybe a qr//
2835                             # expression would be better, so the user could
2836                             # do case-sensitive matching if desired.
2837                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2838                                 if ($slave_editor) {
2839                                     # Handle proper escaping in the slave.
2840                                     print $OUT "\032\032$filename:$start:0\n";
2841                                 }
2842                                 else {
2843                                     # Just print the line normally.
2844                                     print $OUT "$start:\t",$dbline[$start],"\n";
2845                                 }
2846                                 # And quit since we found something.
2847                                 last;
2848                             }
2849                          } ';
2850
2851                     # If we wrapped, there never was a match.
2852                     print $OUT "/$pat/: not found\n" if ( $start == $end );
2853                     next CMD;
2854                 }
2855
2856 =head4 C<?> - search backward for a string in the source
2857
2858 Same as for C</>, except the loop runs backwards.
2859
2860 =cut
2861
2862                 # ? - backward pattern search.
2863                 if (my ($inpat) = $cmd =~ m#\A\?(.*)\z#) {
2864
2865                     # Get the pattern, remove trailing question mark.
2866                     $inpat =~ s:([^\\])\?$:$1:;
2867
2868                     # If we've got one ...
2869                     if ( $inpat ne "" ) {
2870
2871                         # Turn off die & warn handlers.
2872                         local $SIG{__DIE__};
2873                         local $SIG{__WARN__};
2874                         eval '$inpat =~ m' . "\a$inpat\a";
2875
2876                         if ( $@ ne "" ) {
2877
2878                             # Ouch. Not good. Print the error.
2879                             print $OUT $@;
2880                             next CMD;
2881                         }
2882                         $pat = $inpat;
2883                     } ## end if ($inpat ne "")
2884
2885                     # Where we are now is where to stop after wraparound.
2886                     $end = $start;
2887
2888                     # Don't move away from this line.
2889                     $incr = -1;
2890
2891                     # Search inside the eval to prevent pattern badness
2892                     # from killing us.
2893                     eval '
2894                         for (;;) {
2895                             # Back up a line.
2896                             --$start;
2897
2898                             # Wrap if we pass the first line.
2899
2900                             $start = $max if ($start <= 0);
2901
2902                             # Quit if we get back where we started,
2903                             last if ($start == $end);
2904
2905                             # Match?
2906                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2907                                 if ($slave_editor) {
2908                                     # Yep, follow slave editor requirements.
2909                                     print $OUT "\032\032$filename:$start:0\n";
2910                                 }
2911                                 else {
2912                                     # Yep, just print normally.
2913                                     print $OUT "$start:\t",$dbline[$start],"\n";
2914                                 }
2915
2916                                 # Found, so done.
2917                                 last;
2918                             }
2919                         } ';
2920
2921                     # Say we failed if the loop never found anything,
2922                     print $OUT "?$pat?: not found\n" if ( $start == $end );
2923                     next CMD;
2924                 }
2925
2926 =head4 C<$rc> - Recall command
2927
2928 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2929 that the terminal supports history). It find the the command required, puts it
2930 into C<$cmd>, and redoes the loop to execute it.
2931
2932 =cut
2933
2934                 # $rc - recall command.
2935                 if (my ($minus, $arg) = $cmd =~ m#\A$rc+\s*(-)?(\d+)?\z#) {
2936
2937                     # No arguments, take one thing off history.
2938                     pop(@hist) if length($cmd) > 1;
2939
2940                     # Relative (- found)?
2941                     #  Y - index back from most recent (by 1 if bare minus)
2942                     #  N - go to that particular command slot or the last
2943                     #      thing if nothing following.
2944                     $i = $minus ? ( $#hist - ( $arg || 1 ) ) : ( $arg || $#hist );
2945
2946                     # Pick out the command desired.
2947                     $cmd = $hist[$i];
2948
2949                     # Print the command to be executed and restart the loop
2950                     # with that command in the buffer.
2951                     print $OUT $cmd, "\n";
2952                     redo CMD;
2953                 }
2954
2955 =head4 C<$sh$sh> - C<system()> command
2956
2957 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
2958 C<STDOUT> from getting messed up.
2959
2960 =cut
2961
2962                 # $sh$sh - run a shell command (if it's all ASCII).
2963                 # Can't run shell commands with Unicode in the debugger, hmm.
2964                 if (my ($arg) = $cmd =~ m#\A$sh$sh\s*(.*)#ms) {
2965
2966                     # System it.
2967                     &system($arg);
2968                     next CMD;
2969                 }
2970
2971 =head4 C<$rc I<pattern> $rc> - Search command history
2972
2973 Another command to manipulate C<@hist>: this one searches it with a pattern.
2974 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
2975
2976 =cut
2977
2978                 # $rc pattern $rc - find a command in the history.
2979                 if (my ($arg) = $cmd =~ /\A$rc([^$rc].*)\z/) {
2980
2981                     # Create the pattern to use.
2982                     $pat = "^$arg";
2983
2984                     # Toss off last entry if length is >1 (and it always is).
2985                     pop(@hist) if length($cmd) > 1;
2986
2987                     # Look backward through the history.
2988                     for ( $i = $#hist ; $i ; --$i ) {
2989                         # Stop if we find it.
2990                         last if $hist[$i] =~ /$pat/;
2991                     }
2992
2993                     if ( !$i ) {
2994
2995                         # Never found it.
2996                         print $OUT "No such command!\n\n";
2997                         next CMD;
2998                     }
2999
3000                     # Found it. Put it in the buffer, print it, and process it.
3001                     $cmd = $hist[$i];
3002                     print $OUT $cmd, "\n";
3003                     redo CMD;
3004                 }
3005
3006 =head4 C<$sh> - Invoke a shell
3007
3008 Uses C<DB::system> to invoke a shell.
3009
3010 =cut
3011
3012                 # $sh - start a shell.
3013                 if ($cmd =~ /\A$sh\z/) {
3014
3015                     # Run the user's shell. If none defined, run Bourne.
3016                     # We resume execution when the shell terminates.
3017                     &system( $ENV{SHELL} || "/bin/sh" );
3018                     next CMD;
3019                 }
3020
3021 =head4 C<$sh I<command>> - Force execution of a command in a shell
3022
3023 Like the above, but the command is passed to the shell. Again, we use
3024 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
3025
3026 =cut
3027
3028                 # $sh command - start a shell and run a command in it.
3029                 if (my ($arg) = $cmd =~ m#\A$sh\s*(.*)#ms) {
3030
3031                     # XXX: using csh or tcsh destroys sigint retvals!
3032                     #&system($1);  # use this instead
3033
3034                     # use the user's shell, or Bourne if none defined.
3035                     &system( $ENV{SHELL} || "/bin/sh", "-c", $arg );
3036                     next CMD;
3037                 }
3038
3039 =head4 C<H> - display commands in history
3040
3041 Prints the contents of C<@hist> (if any).
3042
3043 =cut
3044
3045                 if ($cmd =~ /\AH\b\s*\*/) {
3046                     @hist = @truehist = ();
3047                     print $OUT "History cleansed\n";
3048                     next CMD;
3049                 }
3050
3051                 if (my ($num)
3052                     = $cmd =~ /\AH\b\s*(?:-(\d+))?/) {
3053
3054                     # Anything other than negative numbers is ignored by
3055                     # the (incorrect) pattern, so this test does nothing.
3056                     $end = $num ? ( $#hist - $num ) : 0;
3057
3058                     # Set to the minimum if less than zero.
3059                     $hist = 0 if $hist < 0;
3060
3061                     # Start at the end of the array.
3062                     # Stay in while we're still above the ending value.
3063                     # Tick back by one each time around the loop.
3064                     for ( $i = $#hist ; $i > $end ; $i-- ) {
3065
3066                         # Print the command  unless it has no arguments.
3067                         print $OUT "$i: ", $hist[$i], "\n"
3068                           unless $hist[$i] =~ /^.?$/;
3069                     }
3070                     next CMD;
3071                 }
3072
3073 =head4 C<man, doc, perldoc> - look up documentation
3074
3075 Just calls C<runman()> to print the appropriate document.
3076
3077 =cut
3078
3079                 # man, perldoc, doc - show manual pages.
3080                 if (my ($man_page)
3081                     = $cmd =~ /\A(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?\z/) {
3082                     runman($man_page);
3083                     next CMD;
3084                 }
3085
3086 =head4 C<p> - print
3087
3088 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
3089 the bottom of the loop.
3090
3091 =cut
3092
3093                 my $print_cmd = 'print {$DB::OUT} ';
3094                 # p - print (no args): print $_.
3095                 if ($cmd eq 'p') {
3096                     $cmd = $print_cmd . '$_';
3097                 }
3098
3099                 # p - print the given expression.
3100                 $cmd =~ s/\Ap\b/$print_cmd /;
3101
3102 =head4 C<=> - define command alias
3103
3104 Manipulates C<%alias> to add or list command aliases.
3105
3106 =cut
3107
3108                 # = - set up a command alias.
3109                 if ($cmd =~ s/\A=\s*//) {
3110                     my @keys;
3111                     if ( length $cmd == 0 ) {
3112
3113                         # No args, get current aliases.
3114                         @keys = sort keys %alias;
3115                     }
3116                     elsif ( my ( $k, $v ) = ( $cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3117
3118                         # Creating a new alias. $k is alias name, $v is
3119                         # alias value.
3120
3121                         # can't use $_ or kill //g state
3122                         for my $x ( $k, $v ) {
3123
3124                             # Escape "alarm" characters.
3125                             $x =~ s/\a/\\a/g;
3126                         }
3127
3128                         # Substitute key for value, using alarm chars
3129                         # as separators (which is why we escaped them in
3130                         # the command).
3131                         $alias{$k} = "s\a$k\a$v\a";
3132
3133                         # Turn off standard warn and die behavior.
3134                         local $SIG{__DIE__};
3135                         local $SIG{__WARN__};
3136
3137                         # Is it valid Perl?
3138                         unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3139
3140                             # Nope. Bad alias. Say so and get out.
3141                             print $OUT "Can't alias $k to $v: $@\n";
3142                             delete $alias{$k};
3143                             next CMD;
3144                         }
3145
3146                         # We'll only list the new one.
3147                         @keys = ($k);
3148                     } ## end elsif (my ($k, $v) = ($cmd...
3149
3150                     # The argument is the alias to list.
3151                     else {
3152                         @keys = ($cmd);
3153                     }
3154
3155                     # List aliases.
3156                     for my $k (@keys) {
3157
3158                         # Messy metaquoting: Trim the substitution code off.
3159                         # We use control-G as the delimiter because it's not
3160                         # likely to appear in the alias.
3161                         if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3162
3163                             # Print the alias.
3164                             print $OUT "$k\t= $1\n";
3165                         }
3166                         elsif ( defined $alias{$k} ) {
3167
3168                             # Couldn't trim it off; just print the alias code.
3169                             print $OUT "$k\t$alias{$k}\n";
3170                         }
3171                         else {
3172
3173                             # No such, dude.
3174                             print "No alias for $k\n";
3175                         }
3176                     } ## end for my $k (@keys)
3177                     next CMD;
3178                 }
3179
3180 =head4 C<source> - read commands from a file.
3181
3182 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3183 pick it up.
3184
3185 =cut
3186
3187                 # source - read commands from a file (or pipe!) and execute.
3188                 if (my ($sourced_fn) = $cmd =~ /\Asource\s+(.*\S)/) {
3189                     if ( open my $fh, $sourced_fn ) {
3190
3191                         # Opened OK; stick it in the list of file handles.
3192                         push @cmdfhs, $fh;
3193                     }
3194                     else {
3195
3196                         # Couldn't open it.
3197                         &warn("Can't execute '$sourced_fn': $!\n");
3198                     }
3199                     next CMD;
3200                 }
3201
3202                 if (my ($which_cmd, $position)
3203                     = $cmd =~ /^(enable|disable)\s+(\S+)\s*$/) {
3204
3205                     my ($fn, $line_num);
3206                     if ($position =~ m{\A\d+\z})
3207                     {
3208                         $fn = $filename;
3209                         $line_num = $position;
3210                     }
3211                     elsif (my ($new_fn, $new_line_num)
3212                         = $position =~ m{\A(.*):(\d+)\z}) {
3213                         ($fn, $line_num) = ($new_fn, $new_line_num);
3214                     }
3215                     else
3216                     {
3217                         &warn("Wrong spec for enable/disable argument.\n");
3218                     }
3219
3220                     if (defined($fn)) {
3221                         if (_has_breakpoint_data_ref($fn, $line_num)) {
3222                             _set_breakpoint_enabled_status($fn, $line_num,
3223                                 ($which_cmd eq 'enable' ? 1 : '')
3224                             );
3225                         }
3226                         else {
3227                             &warn("No breakpoint set at ${fn}:${line_num}\n");
3228                         }
3229                     }
3230
3231                     next CMD;
3232                 }
3233
3234 =head4 C<save> - send current history to a file
3235
3236 Takes the complete history, (not the shrunken version you see with C<H>),
3237 and saves it to the given filename, so it can be replayed using C<source>.
3238
3239 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3240
3241 =cut
3242
3243                 # save source - write commands to a file for later use
3244                 if (my ($new_fn) = $cmd =~ /\Asave\s*(.*)\z/) {
3245                     my $filename = $new_fn || '.perl5dbrc';    # default?
3246                     if ( open my $fh, '>', $filename ) {
3247
3248                        # chomp to remove extraneous newlines from source'd files
3249                         chomp( my @truelist =
3250                               map { m/^\s*(save|source)/ ? "#$_" : $_ }
3251                               @truehist );
3252                         print $fh join( "\n", @truelist );
3253                         print "commands saved in $file\n";
3254                     }
3255                     else {
3256                         &warn("Can't save debugger commands in '$new_fn': $!\n");
3257                     }
3258                     next CMD;
3259                 }
3260
3261 =head4 C<R> - restart
3262
3263 Restart the debugger session.
3264
3265 =head4 C<rerun> - rerun the current session
3266
3267 Return to any given position in the B<true>-history list
3268
3269 =cut
3270
3271                 # R - restart execution.
3272                 # rerun - controlled restart execution.
3273                 if (my ($cmd_cmd, $cmd_params) =
3274                     $cmd =~ /\A((?:R)|(?:rerun\s*(.*)))\z/) {
3275                     my @args = ($cmd_cmd eq 'R' ? restart() : rerun($cmd_params));
3276
3277                     # Close all non-system fds for a clean restart.  A more
3278                     # correct method would be to close all fds that were not
3279                     # open when the process started, but this seems to be
3280                     # hard.  See "debugger 'R'estart and open database
3281                     # connections" on p5p.
3282
3283                     my $max_fd = 1024; # default if POSIX can't be loaded
3284                     if (eval { require POSIX }) {
3285                         eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
3286                     }
3287
3288                     if (defined $max_fd) {
3289                         foreach ($^F+1 .. $max_fd-1) {
3290                             next unless open FD_TO_CLOSE, "<&=$_";
3291                             close(FD_TO_CLOSE);
3292                         }
3293                     }
3294
3295                     # And run Perl again.  We use exec() to keep the
3296                     # PID stable (and that way $ini_pids is still valid).
3297                     exec(@args) || print $OUT "exec failed: $!\n";
3298
3299                     last CMD;
3300                 }
3301
3302 =head4 C<|, ||> - pipe output through the pager.
3303
3304 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3305 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3306 pipe to the pager (restoring the output filehandles if this fails). If this
3307 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3308 set C<$signal>, sending us back into the debugger.
3309
3310 We then trim off the pipe symbols and C<redo> the command loop at the
3311 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3312 reading another.
3313
3314 =cut
3315
3316                 # || - run command in the pager, with output to DB::OUT.
3317                 if ($cmd =~ m#\A\|\|?\s*[^|]#) {
3318                     if ( $pager =~ /^\|/ ) {
3319
3320                         # Default pager is into a pipe. Redirect I/O.
3321                         open( SAVEOUT, ">&STDOUT" )
3322                           || &warn("Can't save STDOUT");
3323                         open( STDOUT, ">&OUT" )
3324                           || &warn("Can't redirect STDOUT");
3325                     } ## end if ($pager =~ /^\|/)
3326                     else {
3327
3328                         # Not into a pipe. STDOUT is safe.
3329                         open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
3330                     }
3331
3332                     # Fix up environment to record we have less if so.
3333                     fix_less();
3334
3335                     unless ( $piped = open( OUT, $pager ) ) {
3336
3337                         # Couldn't open pipe to pager.
3338                         &warn("Can't pipe output to '$pager'");
3339                         if ( $pager =~ /^\|/ ) {
3340
3341                             # Redirect I/O back again.
3342                             open( OUT, ">&STDOUT" )    # XXX: lost message
3343                               || &warn("Can't restore DB::OUT");
3344                             open( STDOUT, ">&SAVEOUT" )
3345                               || &warn("Can't restore STDOUT");
3346                             close(SAVEOUT);
3347                         } ## end if ($pager =~ /^\|/)
3348                         else {
3349
3350                             # Redirect I/O. STDOUT already safe.
3351                             open( OUT, ">&STDOUT" )    # XXX: lost message
3352                               || &warn("Can't restore DB::OUT");
3353                         }
3354                         next CMD;
3355                     } ## end unless ($piped = open(OUT,...
3356
3357                     # Set up broken-pipe handler if necessary.
3358                     $SIG{PIPE} = \&DB::catch
3359                       if $pager =~ /^\|/
3360                       && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
3361
3362                     OUT->autoflush(1);
3363                     # Save current filehandle, and put it back.
3364                     $selected = select(OUT);
3365                     # Don't put it back if pager was a pipe.
3366                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
3367
3368                     # Trim off the pipe symbols and run the command now.
3369                     $cmd =~ s#\A\|+\s*##;
3370                     redo PIPE;
3371                 }
3372
3373 =head3 END OF COMMAND PARSING
3374
3375 Anything left in C<$cmd> at this point is a Perl expression that we want to
3376 evaluate. We'll always evaluate in the user's context, and fully qualify
3377 any variables we might want to address in the C<DB> package.
3378
3379 =cut
3380
3381                 # t - turn trace on.
3382                 if ($cmd =~ s#\At\s+(\d+)?#\$DB::trace |= 1;\n#) {
3383                     my $trace_arg = $1;
3384                     $trace_to_depth = $trace_arg ? $stack_depth||0 + $1 : 1E9;
3385                 }
3386
3387                 # s - single-step. Remember the last command was 's'.
3388                 if ($cmd =~ s/\As\s/\$DB::single = 1;\n/) {
3389                     $laststep = 's';
3390                 }
3391
3392                 # n - single-step, but not into subs. Remember last command
3393                 # was 'n'.
3394                 if ($cmd =~ s#\An\s#\$DB::single = 2;\n#) {
3395                     $laststep = 'n';
3396                 }
3397
3398             }    # PIPE:
3399
3400             # Make sure the flag that says "the debugger's running" is
3401             # still on, to make sure we get control again.
3402             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3403
3404             # Run *our* eval that executes in the caller's context.
3405             &eval;
3406
3407             # Turn off the one-time-dump stuff now.
3408             if ($onetimeDump) {
3409                 $onetimeDump      = undef;
3410                 $onetimedumpDepth = undef;
3411             }
3412             elsif ( $term_pid == $$ ) {
3413                 eval {          # May run under miniperl, when not available...
3414                     STDOUT->flush();
3415                     STDERR->flush();
3416                 };
3417
3418                 # XXX If this is the master pid, print a newline.
3419                 print $OUT "\n";
3420             }
3421         } ## end while (($term || &setterm...
3422
3423 =head3 POST-COMMAND PROCESSING
3424
3425 After each command, we check to see if the command output was piped anywhere.
3426 If so, we go through the necessary code to unhook the pipe and go back to
3427 our standard filehandles for input and output.
3428
3429 =cut
3430
3431         continue {    # CMD:
3432
3433             # At the end of every command:
3434             if ($piped) {
3435
3436                 # Unhook the pipe mechanism now.
3437                 if ( $pager =~ /^\|/ ) {
3438
3439                     # No error from the child.
3440                     $? = 0;
3441
3442                     # we cannot warn here: the handle is missing --tchrist
3443                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3444
3445                     # most of the $? crud was coping with broken cshisms
3446                     # $? is explicitly set to 0, so this never runs.
3447                     if ($?) {
3448                         print SAVEOUT "Pager '$pager' failed: ";
3449                         if ( $? == -1 ) {
3450                             print SAVEOUT "shell returned -1\n";
3451                         }
3452                         elsif ( $? >> 8 ) {
3453                             print SAVEOUT ( $? & 127 )
3454                               ? " (SIG#" . ( $? & 127 ) . ")"
3455                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3456                         }
3457                         else {
3458                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3459                         }
3460                     } ## end if ($?)
3461
3462                     # Reopen filehandle for our output (if we can) and
3463                     # restore STDOUT (if we can).
3464                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3465                     open( STDOUT, ">&SAVEOUT" )
3466                       || &warn("Can't restore STDOUT");
3467
3468                     # Turn off pipe exception handler if necessary.
3469                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3470
3471                     # Will stop ignoring SIGPIPE if done like nohup(1)
3472                     # does SIGINT but Perl doesn't give us a choice.
3473                 } ## end if ($pager =~ /^\|/)
3474                 else {
3475
3476                     # Non-piped "pager". Just restore STDOUT.
3477                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3478                 }
3479
3480                 # Close filehandle pager was using, restore the normal one
3481                 # if necessary,
3482                 close(SAVEOUT);
3483                 select($selected), $selected = "" unless $selected eq "";
3484
3485                 # No pipes now.
3486                 $piped = "";
3487             } ## end if ($piped)
3488         }    # CMD:
3489
3490 =head3 COMMAND LOOP TERMINATION
3491
3492 When commands have finished executing, we come here. If the user closed the
3493 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3494 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3495 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3496 The interpreter will then execute the next line and then return control to us
3497 again.
3498
3499 =cut
3500
3501         # No more commands? Quit.
3502         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3503
3504         # Evaluate post-prompt commands.
3505         foreach $evalarg (@$post) {
3506             &eval;
3507         }
3508     }    # if ($single || $signal)
3509
3510     # Put the user's globals back where you found them.
3511     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3512     ();
3513 } ## end sub DB
3514
3515 # The following code may be executed now:
3516 # BEGIN {warn 4}
3517
3518 =head2 sub
3519
3520 C<sub> is called whenever a subroutine call happens in the program being
3521 debugged. The variable C<$DB::sub> contains the name of the subroutine
3522 being called.
3523
3524 The core function of this subroutine is to actually call the sub in the proper
3525 context, capturing its output. This of course causes C<DB::DB> to get called
3526 again, repeating until the subroutine ends and returns control to C<DB::sub>
3527 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3528 return value, and returns its captured copy of the return value as its own
3529 return value. The value then feeds back into the program being debugged as if
3530 C<DB::sub> hadn't been there at all.
3531
3532 C<sub> does all the work of printing the subroutine entry and exit messages
3533 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3534 and also prints the return value if needed (for the C<r> command and if
3535 the 16 bit is set in C<$frame>).
3536
3537 It also tracks the subroutine call depth by saving the current setting of
3538 C<$single> in the C<@stack> package global; if this exceeds the value in
3539 C<$deep>, C<sub> automatically turns on printing of the current depth by
3540 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3541 of stop/don't stop on entry to subs set as it currently is set.
3542
3543 =head3 C<caller()> support
3544
3545 If C<caller()> is called from the package C<DB>, it provides some
3546 additional data, in the following order:
3547
3548 =over 4
3549
3550 =item * C<$package>
3551
3552 The package name the sub was in
3553
3554 =item * C<$filename>
3555
3556 The filename it was defined in
3557
3558 =item * C<$line>
3559
3560 The line number it was defined on
3561
3562 =item * C<$subroutine>
3563
3564 The subroutine name; C<(eval)> if an C<eval>().
3565
3566 =item * C<$hasargs>
3567
3568 1 if it has arguments, 0 if not
3569
3570 =item * C<$wantarray>
3571
3572 1 if array context, 0 if scalar context
3573
3574 =item * C<$evaltext>
3575
3576 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3577
3578 =item * C<$is_require>
3579
3580 frame was created by a C<use> or C<require> statement
3581
3582 =item * C<$hints>
3583
3584 pragma information; subject to change between versions
3585
3586 =item * C<$bitmask>
3587
3588 pragma information; subject to change between versions
3589
3590 =item * C<@DB::args>
3591
3592 arguments with which the subroutine was invoked
3593
3594 =back
3595
3596 =cut
3597
3598 use vars qw($deep);
3599
3600 # We need to fully qualify the name ("DB::sub") to make "use strict;"
3601 # happy. -- Shlomi Fish
3602 sub DB::sub {
3603         # Do not use a regex in this subroutine -> results in corrupted memory
3604         # See: [perl #66110]
3605
3606         # lock ourselves under threads
3607         lock($DBGR);
3608
3609     # Whether or not the autoloader was running, a scalar to put the
3610     # sub's return value in (if needed), and an array to put the sub's
3611     # return value in (if needed).
3612     my ( $al, $ret, @ret ) = "";
3613         if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
3614                 print "creating new thread\n";
3615         }
3616
3617     # If the last ten characters are '::AUTOLOAD', note we've traced
3618     # into AUTOLOAD for $sub.
3619     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3620         no strict 'refs';
3621         $al = " for $$sub" if defined $$sub;
3622     }
3623
3624     # We stack the stack pointer and then increment it to protect us
3625     # from a situation that might unwind a whole bunch of call frames
3626     # at once. Localizing the stack pointer means that it will automatically
3627     # unwind the same amount when multiple stack frames are unwound.
3628     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3629
3630     # Expand @stack.
3631     $#stack = $stack_depth;
3632
3633     # Save current single-step setting.
3634     $stack[-1] = $single;
3635
3636     # Turn off all flags except single-stepping.
3637     $single &= 1;
3638
3639     # If we've gotten really deeply recursed, turn on the flag that will
3640     # make us stop with the 'deep recursion' message.
3641     $single |= 4 if $stack_depth == $deep;
3642
3643     # If frame messages are on ...
3644     (
3645         $frame & 4    # Extended frame entry message
3646         ? (
3647             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3648
3649             # Why -1? But it works! :-(
3650             # Because print_trace will call add 1 to it and then call
3651             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3652             # in dump_trace.
3653             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3654           )
3655         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3656
3657           # standard frame entry message
3658       )
3659       if $frame;
3660
3661     # Determine the sub's return type, and capture appropriately.
3662     if (wantarray) {
3663
3664         # Called in array context. call sub and capture output.
3665         # DB::DB will recursively get control again if appropriate; we'll come
3666         # back here when the sub is finished.
3667         {
3668             no strict 'refs';
3669             @ret = &$sub;
3670         }
3671
3672         # Pop the single-step value back off the stack.
3673         $single |= $stack[ $stack_depth-- ];
3674
3675         # Check for exit trace messages...
3676         (
3677             $frame & 4    # Extended exit message
3678             ? (
3679                 print_lineinfo( ' ' x $stack_depth, "out " ),
3680                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3681               )
3682             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3683
3684               # Standard exit message
3685           )
3686           if $frame & 2;
3687
3688         # Print the return info if we need to.
3689         if ( $doret eq $stack_depth or $frame & 16 ) {
3690
3691             # Turn off output record separator.
3692             local $\ = '';
3693             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3694
3695             # Indent if we're printing because of $frame tracing.
3696             print $fh ' ' x $stack_depth if $frame & 16;
3697
3698             # Print the return value.
3699             print $fh "list context return from $sub:\n";
3700             dumpit( $fh, \@ret );
3701
3702             # And don't print it again.
3703             $doret = -2;
3704         } ## end if ($doret eq $stack_depth...
3705             # And we have to return the return value now.
3706         @ret;
3707     } ## end if (wantarray)
3708
3709     # Scalar context.
3710     else {
3711         if ( defined wantarray ) {
3712         no strict 'refs';
3713             # Save the value if it's wanted at all.
3714             $ret = &$sub;
3715         }
3716         else {
3717         no strict 'refs';
3718             # Void return, explicitly.
3719             &$sub;
3720             undef $ret;
3721         }
3722
3723         # Pop the single-step value off the stack.
3724         $single |= $stack[ $stack_depth-- ];
3725
3726         # If we're doing exit messages...
3727         (
3728             $frame & 4    # Extended messages
3729             ? (
3730                 print_lineinfo( ' ' x $stack_depth, "out " ),
3731                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3732               )
3733             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3734
3735               # Standard messages
3736           )
3737           if $frame & 2;
3738
3739         # If we are supposed to show the return value... same as before.
3740         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
3741             local $\ = '';
3742             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3743             print $fh ( ' ' x $stack_depth ) if $frame & 16;
3744             print $fh (
3745                 defined wantarray
3746                 ? "scalar context return from $sub: "
3747                 : "void context return from $sub\n"
3748             );
3749             dumpit( $fh, $ret ) if defined wantarray;
3750             $doret = -2;
3751         } ## end if ($doret eq $stack_depth...
3752
3753         # Return the appropriate scalar value.
3754         $ret;
3755     } ## end else [ if (wantarray)
3756 } ## end sub _sub
3757
3758 sub lsub : lvalue {
3759
3760     no strict 'refs';
3761
3762         # lock ourselves under threads
3763         lock($DBGR);
3764
3765     # Whether or not the autoloader was running, a scalar to put the
3766     # sub's return value in (if needed), and an array to put the sub's
3767     # return value in (if needed).
3768     my ( $al, $ret, @ret ) = "";
3769         if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
3770                 print "creating new thread\n";
3771         }
3772
3773     # If the last ten characters are C'::AUTOLOAD', note we've traced
3774     # into AUTOLOAD for $sub.
3775     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3776         $al = " for $$sub";
3777     }
3778
3779     # We stack the stack pointer and then increment it to protect us
3780     # from a situation that might unwind a whole bunch of call frames
3781     # at once. Localizing the stack pointer means that it will automatically
3782     # unwind the same amount when multiple stack frames are unwound.
3783     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3784
3785     # Expand @stack.
3786     $#stack = $stack_depth;
3787
3788     # Save current single-step setting.
3789     $stack[-1] = $single;
3790
3791     # Turn off all flags except single-stepping.
3792     $single &= 1;
3793
3794     # If we've gotten really deeply recursed, turn on the flag that will
3795     # make us stop with the 'deep recursion' message.
3796     $single |= 4 if $stack_depth == $deep;
3797
3798     # If frame messages are on ...
3799     (
3800         $frame & 4    # Extended frame entry message
3801         ? (
3802             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3803
3804             # Why -1? But it works! :-(
3805             # Because print_trace will call add 1 to it and then call
3806             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3807             # in dump_trace.
3808             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3809           )
3810         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3811
3812           # standard frame entry message
3813       )
3814       if $frame;
3815
3816     # Pop the single-step value back off the stack.
3817     $single |= $stack[ $stack_depth-- ];
3818
3819     # call the original lvalue sub.
3820     &$sub;
3821 }
3822
3823 # Abstracting common code from multiple places elsewhere:
3824 sub depth_print_lineinfo {
3825     my $always_print = shift;
3826
3827     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
3828 }
3829
3830 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
3831
3832 In Perl 5.8.0, there was a major realignment of the commands and what they did,
3833 Most of the changes were to systematize the command structure and to eliminate
3834 commands that threw away user input without checking.
3835
3836 The following sections describe the code added to make it easy to support
3837 multiple command sets with conflicting command names. This section is a start
3838 at unifying all command processing to make it simpler to develop commands.
3839
3840 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
3841 number, and C<$dbline> (the current line) as arguments.
3842
3843 Support functions in this section which have multiple modes of failure C<die>
3844 on error; the rest simply return a false value.
3845
3846 The user-interface functions (all of the C<cmd_*> functions) just output
3847 error messages.
3848
3849 =head2 C<%set>
3850
3851 The C<%set> hash defines the mapping from command letter to subroutine
3852 name suffix.
3853
3854 C<%set> is a two-level hash, indexed by set name and then by command name.
3855 Note that trying to set the CommandSet to C<foobar> simply results in the
3856 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
3857
3858 =cut
3859
3860 ### The API section
3861
3862 my %set = (    #
3863     'pre580' => {
3864         'a' => 'pre580_a',
3865         'A' => 'pre580_null',
3866         'b' => 'pre580_b',
3867         'B' => 'pre580_null',
3868         'd' => 'pre580_null',
3869         'D' => 'pre580_D',
3870         'h' => 'pre580_h',
3871         'M' => 'pre580_null',
3872         'O' => 'o',
3873         'o' => 'pre580_null',
3874         'v' => 'M',
3875         'w' => 'v',
3876         'W' => 'pre580_W',
3877     },
3878     'pre590' => {
3879         '<'  => 'pre590_prepost',
3880         '<<' => 'pre590_prepost',
3881         '>'  => 'pre590_prepost',
3882         '>>' => 'pre590_prepost',
3883         '{'  => 'pre590_prepost',
3884         '{{' => 'pre590_prepost',
3885     },
3886 );
3887
3888 my %breakpoints_data;
3889
3890 sub _has_breakpoint_data_ref {
3891     my ($filename, $line) = @_;
3892
3893     return (
3894         exists( $breakpoints_data{$filename} )
3895             and
3896         exists( $breakpoints_data{$filename}{$line} )
3897     );
3898 }
3899
3900 sub _get_breakpoint_data_ref {
3901     my ($filename, $line) = @_;
3902
3903     return ($breakpoints_data{$filename}{$line} ||= +{});
3904 }
3905
3906 sub _delete_breakpoint_data_ref {
3907     my ($filename, $line) = @_;
3908
3909     delete($breakpoints_data{$filename}{$line});
3910     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
3911         delete($breakpoints_data{$filename});
3912     }
3913
3914     return;
3915 }
3916
3917 sub _set_breakpoint_enabled_status {
3918     my ($filename, $line, $status) = @_;
3919
3920     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
3921         ($status ? 1 : '')
3922         ;
3923
3924     return;
3925 }
3926
3927 sub _enable_breakpoint_temp_enabled_status {
3928     my ($filename, $line) = @_;
3929
3930     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
3931
3932     return;
3933 }
3934
3935 sub _cancel_breakpoint_temp_enabled_status {
3936     my ($filename, $line) = @_;
3937
3938     my $ref = _get_breakpoint_data_ref($filename, $line);
3939
3940     delete ($ref->{'temp_enabled'});
3941
3942     if (! %$ref) {
3943         _delete_breakpoint_data_ref($filename, $line);
3944     }
3945
3946     return;
3947 }
3948
3949 sub _is_breakpoint_enabled {
3950     my ($filename, $line) = @_;
3951
3952     my $data_ref = _get_breakpoint_data_ref($filename, $line);
3953     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
3954 }
3955
3956 =head2 C<cmd_wrapper()> (API)
3957
3958 C<cmd_wrapper()> allows the debugger to switch command sets
3959 depending on the value of the C<CommandSet> option.
3960
3961 It tries to look up the command in the C<%set> package-level I<lexical>
3962 (which means external entities can't fiddle with it) and create the name of
3963 the sub to call based on the value found in the hash (if it's there). I<All>
3964 of the commands to be handled in a set have to be added to C<%set>; if they
3965 aren't found, the 5.8.0 equivalent is called (if there is one).
3966
3967 This code uses symbolic references.
3968
3969 =cut
3970
3971 sub cmd_wrapper {
3972     my $cmd      = shift;
3973     my $line     = shift;
3974     my $dblineno = shift;
3975
3976     # Assemble the command subroutine's name by looking up the
3977     # command set and command name in %set. If we can't find it,
3978     # default to the older version of the command.
3979     my $call = 'cmd_'
3980       . ( $set{$CommandSet}{$cmd}
3981           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
3982
3983     # Call the command subroutine, call it by name.
3984     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
3985 } ## end sub cmd_wrapper
3986
3987 =head3 C<cmd_a> (command)
3988
3989 The C<a> command handles pre-execution actions. These are associated with a
3990 particular line, so they're stored in C<%dbline>. We default to the current
3991 line if none is specified.
3992
3993 =cut
3994
3995 sub cmd_a {
3996     my $cmd    = shift;
3997     my $line   = shift || '';    # [.|line] expr
3998     my $dbline = shift;
3999
4000     # If it's dot (here), or not all digits,  use the current line.
4001     $line =~ s/^(\.|(?:[^\d]))/$dbline/;
4002
4003     # Should be a line number followed by an expression.
4004     if ( $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
4005         my ( $lineno, $expr ) = ( $1, $2 );
4006
4007         # If we have an expression ...
4008         if ( length $expr ) {
4009
4010             # ... but the line isn't breakable, complain.
4011             if ( $dbline[$lineno] == 0 ) {
4012                 print $OUT
4013                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
4014             }
4015             else {
4016
4017                 # It's executable. Record that the line has an action.
4018                 $had_breakpoints{$filename} |= 2;
4019
4020                 # Remove any action, temp breakpoint, etc.
4021                 $dbline{$lineno} =~ s/\0[^\0]*//;
4022
4023                 # Add the action to the line.
4024                 $dbline{$lineno} .= "\0" . action($expr);
4025
4026                 _set_breakpoint_enabled_status($filename, $lineno, 1);
4027             }
4028         } ## end if (length $expr)
4029     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4030     else {
4031
4032         # Syntax wrong.
4033         print $OUT
4034           "Adding an action requires an optional lineno and an expression\n"
4035           ;    # hint
4036     }
4037 } ## end sub cmd_a
4038
4039 =head3 C<cmd_A> (command)
4040
4041 Delete actions. Similar to above, except the delete code is in a separate
4042 subroutine, C<delete_action>.
4043
4044 =cut
4045
4046 sub cmd_A {
4047     my $cmd    = shift;
4048     my $line   = shift || '';
4049     my $dbline = shift;
4050
4051     # Dot is this line.
4052     $line =~ s/^\./$dbline/;
4053
4054     # Call delete_action with a null param to delete them all.
4055     # The '1' forces the eval to be true. It'll be false only
4056     # if delete_action blows up for some reason, in which case
4057     # we print $@ and get out.
4058     if ( $line eq '*' ) {
4059         eval { &delete_action(); 1 } or print $OUT $@ and return;
4060     }
4061
4062     # There's a real line  number. Pass it to delete_action.
4063     # Error trapping is as above.
4064     elsif ( $line =~ /^(\S.*)/ ) {
4065         eval { &delete_action($1); 1 } or print $OUT $@ and return;
4066     }
4067
4068     # Swing and a miss. Bad syntax.
4069     else {
4070         print $OUT
4071           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4072     }
4073 } ## end sub cmd_A
4074
4075 =head3 C<delete_action> (API)
4076
4077 C<delete_action> accepts either a line number or C<undef>. If a line number
4078 is specified, we check for the line being executable (if it's not, it
4079 couldn't have had an  action). If it is, we just take the action off (this
4080 will get any kind of an action, including breakpoints).
4081
4082 =cut
4083
4084 sub delete_action {
4085     my $i = shift;
4086     if ( defined($i) ) {
4087
4088         # Can there be one?
4089         die "Line $i has no action .\n" if $dbline[$i] == 0;
4090
4091         # Nuke whatever's there.
4092         $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4093         delete $dbline{$i} if $dbline{$i} eq '';
4094     }
4095     else {
4096         print $OUT "Deleting all actions...\n";
4097         for my $file ( keys %had_breakpoints ) {
4098             local *dbline = $main::{ '_<' . $file };
4099             $max = $#dbline;
4100             my $was;
4101             for $i (1 .. $max) {
4102                 if ( defined $dbline{$i} ) {
4103                     $dbline{$i} =~ s/\0[^\0]*//;
4104                     delete $dbline{$i} if $dbline{$i} eq '';
4105                 }
4106                 unless ( $had_breakpoints{$file} &= ~2 ) {
4107                     delete $had_breakpoints{$file};
4108                 }
4109             } ## end for ($i = 1 .. $max)
4110         } ## end for my $file (keys %had_breakpoints)
4111     } ## end else [ if (defined($i))
4112 } ## end sub delete_action
4113
4114 =head3 C<cmd_b> (command)
4115
4116 Set breakpoints. Since breakpoints can be set in so many places, in so many
4117 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4118 we try to parse the command type, and then shuttle it off to an appropriate
4119 subroutine to actually do the work of setting the breakpoint in the right
4120 place.
4121
4122 =cut
4123
4124 sub cmd_b {
4125     my $cmd    = shift;
4126     my $line   = shift;    # [.|line] [cond]
4127     my $dbline = shift;
4128
4129     # Make . the current line number if it's there..
4130     $line =~ s/^\.(\s|\z)/$dbline$1/;
4131
4132     # No line number, no condition. Simple break on current line.
4133     if ( $line =~ /^\s*$/ ) {
4134         &cmd_b_line( $dbline, 1 );
4135     }
4136
4137     # Break on load for a file.
4138     elsif ( $line =~ /^load\b\s*(.*)/ ) {
4139         my $file = $1;
4140         $file =~ s/\s+$//;
4141         &cmd_b_load($file);
4142     }
4143
4144     # b compile|postpone <some sub> [<condition>]
4145     # The interpreter actually traps this one for us; we just put the
4146     # necessary condition in the %postponed hash.
4147     elsif ( $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4148
4149         # Capture the condition if there is one. Make it true if none.
4150         my $cond = length $3 ? $3 : '1';
4151
4152         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
4153         # if it was 'compile'.
4154         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
4155
4156         # De-Perl4-ify the name - ' separators to ::.
4157         $subname =~ s/\'/::/g;
4158
4159         # Qualify it into the current package unless it's already qualified.
4160         $subname = "${package}::" . $subname unless $subname =~ /::/;
4161
4162         # Add main if it starts with ::.
4163         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4164
4165         # Save the break type for this sub.
4166         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
4167     } ## end elsif ($line =~ ...
4168     # b <filename>:<line> [<condition>]
4169     elsif ($line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4170         my ($filename, $line_num, $cond) = ($1, $2, $3);
4171         cmd_b_filename_line(
4172             $filename,
4173             $line_num,
4174             (length($cond) ? $cond : '1'),
4175         );
4176     }
4177     # b <sub name> [<condition>]
4178     elsif ( $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4179
4180         #
4181         $subname = $1;
4182         my $cond = length $2 ? $2 : '1';
4183         &cmd_b_sub( $subname, $cond );
4184     }
4185
4186     # b <line> [<condition>].
4187     elsif ( $line =~ /^(\d*)\s*(.*)/ ) {
4188
4189         # Capture the line. If none, it's the current line.
4190         $line = $1 || $dbline;
4191
4192         # If there's no condition, make it '1'.
4193         my $cond = length $2 ? $2 : '1';
4194
4195         # Break on line.
4196         &cmd_b_line( $line, $cond );
4197     }
4198
4199     # Line didn't make sense.
4200     else {
4201         print "confused by line($line)?\n";
4202     }
4203 } ## end sub cmd_b
4204
4205 =head3 C<break_on_load> (API)
4206
4207 We want to break when this file is loaded. Mark this file in the
4208 C<%break_on_load> hash, and note that it has a breakpoint in
4209 C<%had_breakpoints>.
4210
4211 =cut
4212
4213 sub break_on_load {
4214     my $file = shift;
4215     $break_on_load{$file} = 1;
4216     $had_breakpoints{$file} |= 1;
4217 }
4218
4219 =head3 C<report_break_on_load> (API)
4220
4221 Gives us an array of filenames that are set to break on load. Note that
4222 only files with break-on-load are in here, so simply showing the keys
4223 suffices.
4224
4225 =cut
4226
4227 sub report_break_on_load {
4228     sort keys %break_on_load;
4229 }
4230
4231 =head3 C<cmd_b_load> (command)
4232
4233 We take the file passed in and try to find it in C<%INC> (which maps modules
4234 to files they came from). We mark those files for break-on-load via
4235 C<break_on_load> and then report that it was done.
4236
4237 =cut
4238
4239 sub cmd_b_load {
4240     my $file = shift;
4241     my @files;
4242
4243     # This is a block because that way we can use a redo inside it
4244     # even without there being any looping structure at all outside it.
4245     {
4246
4247         # Save short name and full path if found.
4248         push @files, $file;
4249         push @files, $::INC{$file} if $::INC{$file};
4250
4251         # Tack on .pm and do it again unless there was a '.' in the name
4252         # already.
4253         $file .= '.pm', redo unless $file =~ /\./;
4254     }
4255
4256     # Do the real work here.
4257     break_on_load($_) for @files;
4258
4259     # All the files that have break-on-load breakpoints.
4260     @files = report_break_on_load;
4261
4262     # Normalize for the purposes of our printing this.
4263     local $\ = '';
4264     local $" = ' ';
4265     print $OUT "Will stop on load of '@files'.\n";
4266 } ## end sub cmd_b_load
4267
4268 =head3 C<$filename_error> (API package global)
4269
4270 Several of the functions we need to implement in the API need to work both
4271 on the current file and on other files. We don't want to duplicate code, so
4272 C<$filename_error> is used to contain the name of the file that's being
4273 worked on (if it's not the current one).
4274
4275 We can now build functions in pairs: the basic function works on the current
4276 file, and uses C<$filename_error> as part of its error message. Since this is
4277 initialized to C<"">, no filename will appear when we are working on the
4278 current file.
4279
4280 The second function is a wrapper which does the following:
4281
4282 =over 4
4283
4284 =item *
4285
4286 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4287
4288 =item *
4289
4290 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4291
4292 =item *
4293
4294 Calls the first function.
4295
4296 The first function works on the I<current> file (i.e., the one we changed to),
4297 and prints C<$filename_error> in the error message (the name of the other file)
4298 if it needs to. When the functions return, C<*dbline> is restored to point
4299 to the actual current file (the one we're executing in) and
4300 C<$filename_error> is restored to C<"">. This restores everything to
4301 the way it was before the second function was called at all.
4302
4303 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4304 details.
4305
4306 =back
4307
4308 =cut
4309
4310 use vars qw($filename_error);
4311 $filename_error = '';
4312
4313 =head3 breakable_line(from, to) (API)
4314
4315 The subroutine decides whether or not a line in the current file is breakable.
4316 It walks through C<@dbline> within the range of lines specified, looking for
4317 the first line that is breakable.
4318
4319 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4320 first line I<after> C<$to> that's breakable, if there is one.
4321
4322 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4323 first line I<before> C<$to> that's breakable, if there is one.
4324
4325 =cut
4326
4327 sub breakable_line {
4328
4329     my ( $from, $to ) = @_;
4330
4331     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4332     my $i = $from;
4333
4334     # If there are at least 2 arguments, we're trying to search a range.
4335     if ( @_ >= 2 ) {
4336
4337         # $delta is positive for a forward search, negative for a backward one.
4338         my $delta = $from < $to ? +1 : -1;
4339
4340         # Keep us from running off the ends of the file.
4341         my $limit = $delta > 0 ? $#dbline : 1;
4342
4343         # Clever test. If you're a mathematician, it's obvious why this
4344         # test works. If not:
4345         # If $delta is positive (going forward), $limit will be $#dbline.
4346         #    If $to is less than $limit, ($limit - $to) will be positive, times
4347         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4348         #    as the stopping point.
4349         #
4350         #    If $to is greater than $limit, ($limit - $to) is negative,
4351         #    times $delta of 1 (positive), so the result is < 0 and we should
4352         #    use $limit ($#dbline) as the stopping point.
4353         #
4354         # If $delta is negative (going backward), $limit will be 1.
4355         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4356         #    (negative) so the result is > 0, and we use $to as the stopping
4357         #    point.
4358         #
4359         #    If $to is less than zero, ($limit - $to) will be positive,
4360         #    times $delta of -1 (negative), so the result is not > 0, and
4361         #    we use $limit (1) as the stopping point.
4362         #
4363         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4364         #    (negative), still giving zero; the result is not > 0, and
4365         #    we use $limit (1) as the stopping point.
4366         #
4367         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4368         #    (negative), giving a positive (>0) value, so we'll set $limit to
4369         #    $to.
4370
4371         $limit = $to if ( $limit - $to ) * $delta > 0;
4372
4373         # The real search loop.
4374         # $i starts at $from (the point we want to start searching from).
4375         # We move through @dbline in the appropriate direction (determined
4376         # by $delta: either -1 (back) or +1 (ahead).
4377         # We stay in as long as we haven't hit an executable line
4378         # ($dbline[$i] == 0 means not executable) and we haven't reached
4379         # the limit yet (test similar to the above).
4380         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4381
4382     } ## end if (@_ >= 2)
4383
4384     # If $i points to a line that is executable, return that.
4385     return $i unless $dbline[$i] == 0;
4386
4387     # Format the message and print it: no breakable lines in range.
4388     my ( $pl, $upto ) = ( '', '' );
4389     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4390
4391     # If there's a filename in filename_error, we'll see it.
4392     # If not, not.
4393     die "Line$pl $from$upto$filename_error not breakable\n";
4394 } ## end sub breakable_line
4395
4396 =head3 breakable_line_in_filename(file, from, to) (API)
4397
4398 Like C<breakable_line>, but look in another file.
4399
4400 =cut
4401
4402 sub breakable_line_in_filename {
4403
4404     # Capture the file name.
4405     my ($f) = shift;
4406
4407     # Swap the magic line array over there temporarily.
4408     local *dbline = $main::{ '_<' . $f };
4409
4410     # If there's an error, it's in this other file.
4411     local $filename_error = " of '$f'";
4412
4413     # Find the breakable line.
4414     breakable_line(@_);
4415
4416     # *dbline and $filename_error get restored when this block ends.
4417
4418 } ## end sub breakable_line_in_filename
4419
4420 =head3 break_on_line(lineno, [condition]) (API)
4421
4422 Adds a breakpoint with the specified condition (or 1 if no condition was
4423 specified) to the specified line. Dies if it can't.
4424
4425 =cut
4426
4427 sub break_on_line {
4428     my ( $i, $cond ) = @_;
4429
4430     # Always true if no condition supplied.
4431     $cond = 1 unless @_ >= 2;
4432
4433     my $inii  = $i;
4434     my $after = '';
4435     my $pl    = '';
4436
4437     # Woops, not a breakable line. $filename_error allows us to say
4438     # if it was in a different file.
4439     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4440
4441     # Mark this file as having breakpoints in it.
4442     $had_breakpoints{$filename} |= 1;
4443
4444     # If there is an action or condition here already ...
4445     if ( $dbline{$i} ) {
4446
4447         # ... swap this condition for the existing one.
4448         $dbline{$i} =~ s/^[^\0]*/$cond/;
4449     }
4450     else {
4451
4452         # Nothing here - just add the condition.
4453         $dbline{$i} = $cond;
4454
4455         _set_breakpoint_enabled_status($filename, $i, 1);
4456     }
4457 } ## end sub break_on_line
4458
4459 =head3 cmd_b_line(line, [condition]) (command)
4460
4461 Wrapper for C<break_on_line>. Prints the failure message if it
4462 doesn't work.
4463
4464 =cut
4465
4466 sub cmd_b_line {
4467     if (not eval { break_on_line(@_); 1 }) {
4468         local $\ = '';
4469         print $OUT $@ and return;
4470     }
4471
4472     return;
4473 } ## end sub cmd_b_line
4474
4475 =head3 cmd_b_filename_line(line, [condition]) (command)
4476
4477 Wrapper for C<break_on_filename_line>. Prints the failure message if it
4478 doesn't work.
4479
4480 =cut
4481
4482 sub cmd_b_filename_line {
4483     if (not eval { break_on_filename_line(@_); 1 }) {
4484         local $\ = '';
4485         print $OUT $@ and return;
4486     }
4487
4488     return;
4489 }
4490
4491 =head3 break_on_filename_line(file, line, [condition]) (API)
4492
4493 Switches to the file specified and then calls C<break_on_line> to set
4494 the breakpoint.
4495
4496 =cut
4497
4498 sub break_on_filename_line {
4499     my ( $f, $i, $cond ) = @_;
4500
4501     # Always true if condition left off.
4502     $cond = 1 unless @_ >= 3;
4503
4504     # Switch the magical hash temporarily.
4505     local *dbline = $main::{ '_<' . $f };
4506
4507     # Localize the variables that break_on_line uses to make its message.
4508     local $filename_error = " of '$f'";
4509     local $filename       = $f;
4510
4511     # Add the breakpoint.
4512     break_on_line( $i, $cond );
4513 } ## end sub break_on_filename_line
4514
4515 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
4516
4517 Switch to another file, search the range of lines specified for an
4518 executable one, and put a breakpoint on the first one you find.
4519
4520 =cut
4521
4522 sub break_on_filename_line_range {
4523     my ( $f, $from, $to, $cond ) = @_;
4524
4525     # Find a breakable line if there is one.
4526     my $i = breakable_line_in_filename( $f, $from, $to );
4527
4528     # Always true if missing.
4529     $cond = 1 unless @_ >= 3;
4530
4531     # Add the breakpoint.
4532     break_on_filename_line( $f, $i, $cond );
4533 } ## end sub break_on_filename_line_range
4534
4535 =head3 subroutine_filename_lines(subname, [condition]) (API)
4536
4537 Search for a subroutine within a given file. The condition is ignored.
4538 Uses C<find_sub> to locate the desired subroutine.
4539
4540 =cut
4541