lib/perl5db.pl

   1
   2 =head1 NAME
   3
   4 perl5db.pl - the perl debugger
   5
   6 =head1 SYNOPSIS
   7
   8     perl -d  your_Perl_script
   9
  10 =head1 DESCRIPTION
  11
  12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
  13 you invoke a script with C<perl -d>. This documentation tries to outline the
  14 structure and services provided by C<perl5db.pl>, and to describe how you
  15 can use them.
  16
  17 =head1 GENERAL NOTES
  18
  19 The debugger can look pretty forbidding to many Perl programmers. There are
  20 a number of reasons for this, many stemming out of the debugger's history.
  21
  22 When the debugger was first written, Perl didn't have a lot of its nicer
  23 features - no references, no lexical variables, no closures, no object-oriented
  24 programming. So a lot of the things one would normally have done using such
  25 features was done using global variables, globs and the C<local()> operator
  26 in creative ways.
  27
  28 Some of these have survived into the current debugger; a few of the more
  29 interesting and still-useful idioms are noted in this section, along with notes
  30 on the comments themselves.
  31
  32 =head2 Why not use more lexicals?
  33
  34 Experienced Perl programmers will note that the debugger code tends to use
  35 mostly package globals rather than lexically-scoped variables. This is done
  36 to allow a significant amount of control of the debugger from outside the
  37 debugger itself.
  38
  39 Unfortunately, though the variables are accessible, they're not well
  40 documented, so it's generally been a decision that hasn't made a lot of
  41 difference to most users. Where appropriate, comments have been added to
  42 make variables more accessible and usable, with the understanding that these
  43 I<are> debugger internals, and are therefore subject to change. Future
  44 development should probably attempt to replace the globals with a well-defined
  45 API, but for now, the variables are what we've got.
  46
  47 =head2 Automated variable stacking via C<local()>
  48
  49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
  50 temporary copy of a variable in the current scope. When the scope ends, the
  51 old copy is restored. This is often used in the debugger to handle the
  52 automatic stacking of variables during recursive calls:
  53
  54      sub foo {
  55         local $some_global++;
  56
  57         # Do some stuff, then ...
  58         return;
  59      }
  60
  61 What happens is that on entry to the subroutine, C<$some_global> is localized,
  62 then altered. When the subroutine returns, Perl automatically undoes the
  63 localization, restoring the previous value. Voila, automatic stack management.
  64
  65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
  66 which lets the debugger get control inside of C<eval>'ed code. The debugger
  67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
  68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
  69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
  70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
  71
  72 In any case, watch for this pattern. It occurs fairly often.
  73
  74 =head2 The C<^> trick
  75
  76 This is used to cleverly reverse the sense of a logical test depending on
  77 the value of an auxiliary variable. For instance, the debugger's C<S>
  78 (search for subroutines by pattern) allows you to negate the pattern
  79 like this:
  80
  81    # Find all non-'foo' subs:
  82    S !/foo/
  83
  84 Boolean algebra states that the truth table for XOR looks like this:
  85
  86 =over 4
  87
  88 =item * 0 ^ 0 = 0
  89
  90 (! not present and no match) --> false, don't print
  91
  92 =item * 0 ^ 1 = 1
  93
  94 (! not present and matches) --> true, print
  95
  96 =item * 1 ^ 0 = 1
  97
  98 (! present and no match) --> true, print
  99
 100 =item * 1 ^ 1 = 0
 101
 102 (! present and matches) --> false, don't print
 103
 104 =back
 105
 106 As you can see, the first pair applies when C<!> isn't supplied, and
 107 the second pair applies when it is. The XOR simply allows us to
 108 compact a more complicated if-then-elseif-else into a more elegant
 109 (but perhaps overly clever) single test. After all, it needed this
 110 explanation...
 111
 112 =head2 FLAGS, FLAGS, FLAGS
 113
 114 There is a certain C programming legacy in the debugger. Some variables,
 115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
 116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
 117 of state to be stored independently in a single scalar.
 118
 119 A test like
 120
 121     if ($scalar & 4) ...
 122
 123 is checking to see if the appropriate bit is on. Since each bit can be
 124 "addressed" independently in this way, C<$scalar> is acting sort of like
 125 an array of bits. Obviously, since the contents of C<$scalar> are just a
 126 bit-pattern, we can save and restore it easily (it will just look like
 127 a number).
 128
 129 The problem, is of course, that this tends to leave magic numbers scattered
 130 all over your program whenever a bit is set, cleared, or checked. So why do
 131 it?
 132
 133 =over 4
 134
 135 =item *
 136
 137 First, doing an arithmetical or bitwise operation on a scalar is
 138 just about the fastest thing you can do in Perl: C<use constant> actually
 139 creates a subroutine call, and array and hash lookups are much slower. Is
 140 this over-optimization at the expense of readability? Possibly, but the
 141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
 142 probably have to benchmark alternate implementations and see which is the
 143 best balance of readability and speed, and then document how it actually
 144 works.
 145
 146 =item *
 147
 148 Second, it's very easy to serialize a scalar number. This is done in
 149 the restart code; the debugger state variables are saved in C<%ENV> and then
 150 restored when the debugger is restarted. Having them be just numbers makes
 151 this trivial.
 152
 153 =item *
 154
 155 Third, some of these variables are being shared with the Perl core
 156 smack in the middle of the interpreter's execution loop. It's much faster for
 157 a C program (like the interpreter) to check a bit in a scalar than to access
 158 several different variables (or a Perl array).
 159
 160 =back
 161
 162 =head2 What are those C<XXX> comments for?
 163
 164 Any comment containing C<XXX> means that the comment is either somewhat
 165 speculative - it's not exactly clear what a given variable or chunk of
 166 code is doing, or that it is incomplete - the basics may be clear, but the
 167 subtleties are not completely documented.
 168
 169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
 170
 171 =head1 DATA STRUCTURES MAINTAINED BY CORE
 172
 173 There are a number of special data structures provided to the debugger by
 174 the Perl interpreter.
 175
 176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
 177 via glob assignment) contains the text from C<$filename>, with each
 178 element corresponding to a single line of C<$filename>. Additionally,
 179 breakable lines will be dualvars with the numeric component being the
 180 memory address of a COP node. Non-breakable lines are dualvar to 0.
 181
 182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
 183 assignment) contains breakpoints and actions.  The keys are line numbers;
 184 you can set individual values, but not the whole hash. The Perl interpreter
 185 uses this hash to determine where breakpoints have been set. Any true value is
 186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
 187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
 188
 189 The scalar C<${"_<$filename"}> simply contains the string C<<< _<$filename> >>>.
 190 This is also the case for evaluated strings that contain subroutines, or
 191 which are currently being executed.  The $filename for C<eval>ed strings looks
 192 like C<(eval 34).
 193
 194 =head1 DEBUGGER STARTUP
 195
 196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
 197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
 198 of options. In addition, this file may define a subroutine C<&afterinit>
 199 that will be executed (in the debugger's context) after the debugger has
 200 initialized itself.
 201
 202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
 203 contents as the argument of a C<o> command in the debugger.
 204
 205 =head2 STARTUP-ONLY OPTIONS
 206
 207 The following options can only be specified at startup.
 208 To set them in your rcfile, add a call to
 209 C<&parse_options("optionName=new_value")>.
 210
 211 =over 4
 212
 213 =item * TTY
 214
 215 the TTY to use for debugging i/o.
 216
 217 =item * noTTY
 218
 219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
 220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
 221 Term::Rendezvous.  Current variant is to have the name of TTY in this
 222 file.
 223
 224 =item * ReadLine
 225
 226 if false, a dummy ReadLine is used, so you can debug
 227 ReadLine applications.
 228
 229 =item * NonStop
 230
 231 if true, no i/o is performed until interrupt.
 232
 233 =item * LineInfo
 234
 235 file or pipe to print line number info to.  If it is a
 236 pipe, a short "emacs like" message is used.
 237
 238 =item * RemotePort
 239
 240 host:port to connect to on remote host for remote debugging.
 241
 242 =item * HistFile
 243
 244 file to store session history to. There is no default and so no
 245 history file is written unless this variable is explicitly set.
 246
 247 =item * HistSize
 248
 249 number of commands to store to the file specified in C<HistFile>.
 250 Default is 100.
 251
 252 =back
 253
 254 =head3 SAMPLE RCFILE
 255
 256  &parse_options("NonStop=1 LineInfo=db.out");
 257   sub afterinit { $trace = 1; }
 258
 259 The script will run without human intervention, putting trace
 260 information into C<db.out>.  (If you interrupt it, you had better
 261 reset C<LineInfo> to something I<interactive>!)
 262
 263 =head1 INTERNALS DESCRIPTION
 264
 265 =head2 DEBUGGER INTERFACE VARIABLES
 266
 267 Perl supplies the values for C<%sub>.  It effectively inserts
 268 a C<&DB::DB();> in front of each place that can have a
 269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
 270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
 271 {require 'perl5db.pl'}> before the first line.
 272
 273 After each C<require>d file is compiled, but before it is executed, a
 274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
 275 is the expanded name of the C<require>d file (as found via C<%INC>).
 276
 277 =head3 IMPORTANT INTERNAL VARIABLES
 278
 279 =head4 C<$CreateTTY>
 280
 281 Used to control when the debugger will attempt to acquire another TTY to be
 282 used for input.
 283
 284 =over
 285
 286 =item * 1 -  on C<fork()>
 287
 288 =item * 2 - debugger is started inside debugger
 289
 290 =item * 4 -  on startup
 291
 292 =back
 293
 294 =head4 C<$doret>
 295
 296 The value -2 indicates that no return value should be printed.
 297 Any other positive value causes C<DB::sub> to print return values.
 298
 299 =head4 C<$evalarg>
 300
 301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
 302 contents of C<@_> when C<DB::eval> is called.
 303
 304 =head4 C<$frame>
 305
 306 Determines what messages (if any) will get printed when a subroutine (or eval)
 307 is entered or exited.
 308
 309 =over 4
 310
 311 =item * 0 -  No enter/exit messages
 312
 313 =item * 1 - Print I<entering> messages on subroutine entry
 314
 315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
 316
 317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
 318
 319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
 320
 321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
 322
 323 =back
 324
 325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
 326 The debugger internally juggles the value of C<$frame> during execution to
 327 protect external modules that the debugger uses from getting traced.
 328
 329 =head4 C<$level>
 330
 331 Tracks current debugger nesting level. Used to figure out how many
 332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
 333 outputs a prompt. Also used to help determine if the program has finished
 334 during command parsing.
 335
 336 =head4 C<$onetimeDump>
 337
 338 Controls what (if anything) C<DB::eval()> will print after evaluating an
 339 expression.
 340
 341 =over 4
 342
 343 =item * C<undef> - don't print anything
 344
 345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
 346
 347 =item * C<methods> - print the methods callable on the first item returned
 348
 349 =back
 350
 351 =head4 C<$onetimeDumpDepth>
 352
 353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
 354 dumping a structure. Numeric. If C<undef>, print all levels.
 355
 356 =head4 C<$signal>
 357
 358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
 359 which is called before every statement, checks this and puts the user into
 360 command mode if it finds C<$signal> set to a true value.
 361
 362 =head4 C<$single>
 363
 364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
 365 each subroutine; popped again at the end of each subroutine.
 366
 367 =over 4
 368
 369 =item * 0 - run continuously.
 370
 371 =item * 1 - single-step, go into subs. The C<s> command.
 372
 373 =item * 2 - single-step, don't go into subs. The C<n> command.
 374
 375 =item * 4 - print current sub depth (turned on to force this when C<too much
 376 recursion> occurs.
 377
 378 =back
 379
 380 =head4 C<$trace>
 381
 382 Controls the output of trace information.
 383
 384 =over 4
 385
 386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
 387
 388 =item * 2 - watch expressions are active
 389
 390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
 391
 392 =back
 393
 394 =head4 C<$slave_editor>
 395
 396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
 397
 398 =head4 C<@cmdfhs>
 399
 400 Stack of filehandles that C<DB::readline()> will read commands from.
 401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
 402
 403 =head4 C<@dbline>
 404
 405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
 406 supplied by the Perl interpreter to the debugger. Contains the source.
 407
 408 =head4 C<@old_watch>
 409
 410 Previous values of watch expressions. First set when the expression is
 411 entered; reset whenever the watch expression changes.
 412
 413 =head4 C<@saved>
 414
 415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
 416 so that the debugger can substitute safe values while it's running, and
 417 restore them when it returns control.
 418
 419 =head4 C<@stack>
 420
 421 Saves the current value of C<$single> on entry to a subroutine.
 422 Manipulated by the C<c> command to turn off tracing in all subs above the
 423 current one.
 424
 425 =head4 C<@to_watch>
 426
 427 The 'watch' expressions: to be evaluated before each line is executed.
 428
 429 =head4 C<@typeahead>
 430
 431 The typeahead buffer, used by C<DB::readline>.
 432
 433 =head4 C<%alias>
 434
 435 Command aliases. Stored as character strings to be substituted for a command
 436 entered.
 437
 438 =head4 C<%break_on_load>
 439
 440 Keys are file names, values are 1 (break when this file is loaded) or undef
 441 (don't break when it is loaded).
 442
 443 =head4 C<%dbline>
 444
 445 Keys are line numbers, values are C<condition\0action>. If used in numeric
 446 context, values are 0 if not breakable, 1 if breakable, no matter what is
 447 in the actual hash entry.
 448
 449 =head4 C<%had_breakpoints>
 450
 451 Keys are file names; values are bitfields:
 452
 453 =over 4
 454
 455 =item * 1 - file has a breakpoint in it.
 456
 457 =item * 2 - file has an action in it.
 458
 459 =back
 460
 461 A zero or undefined value means this file has neither.
 462
 463 =head4 C<%option>
 464
 465 Stores the debugger options. These are character string values.
 466
 467 =head4 C<%postponed>
 468
 469 Saves breakpoints for code that hasn't been compiled yet.
 470 Keys are subroutine names, values are:
 471
 472 =over 4
 473
 474 =item * C<compile> - break when this sub is compiled
 475
 476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
 477
 478 =back
 479
 480 =head4 C<%postponed_file>
 481
 482 This hash keeps track of breakpoints that need to be set for files that have
 483 not yet been compiled. Keys are filenames; values are references to hashes.
 484 Each of these hashes is keyed by line number, and its values are breakpoint
 485 definitions (C<condition\0action>).
 486
 487 =head1 DEBUGGER INITIALIZATION
 488
 489 The debugger's initialization actually jumps all over the place inside this
 490 package. This is because there are several BEGIN blocks (which of course
 491 execute immediately) spread through the code. Why is that?
 492
 493 The debugger needs to be able to change some things and set some things up
 494 before the debugger code is compiled; most notably, the C<$deep> variable that
 495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
 496 debugger has to turn off warnings while the debugger code is compiled, but then
 497 restore them to their original setting before the program being debugged begins
 498 executing.
 499
 500 The first C<BEGIN> block simply turns off warnings by saving the current
 501 setting of C<$^W> and then setting it to zero. The second one initializes
 502 the debugger variables that are needed before the debugger begins executing.
 503 The third one puts C<$^X> back to its former value.
 504
 505 We'll detail the second C<BEGIN> block later; just remember that if you need
 506 to initialize something before the debugger starts really executing, that's
 507 where it has to go.
 508
 509 =cut
 510
 511 package DB;
 512
 513 use strict;
 514
 515 BEGIN {eval 'use IO::Handle'}; # Needed for flush only? breaks under miniperl
 516
 517 BEGIN {
 518     require feature;
 519     $^V =~ /^v(\d+\.\d+)/;
 520     feature->import(":$1");
 521 }
 522
 523 # Debugger for Perl 5.00x; perl5db.pl patch level:
 524 use vars qw($VERSION $header);
 525
 526 $VERSION = '1.39_05';
 527
 528 $header = "perl5db.pl version $VERSION";
 529
 530 =head1 DEBUGGER ROUTINES
 531
 532 =head2 C<DB::eval()>
 533
 534 This function replaces straight C<eval()> inside the debugger; it simplifies
 535 the process of evaluating code in the user's context.
 536
 537 The code to be evaluated is passed via the package global variable
 538 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
 539
 540 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
 541 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
 542 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
 543 user's current package, grabbed when C<DB::DB> got control.  This causes the
 544 proper context to be used when the eval is actually done.  Afterward, we
 545 restore C<$trace>, C<$single>, and C<$^D>.
 546
 547 Next we need to handle C<$@> without getting confused. We save C<$@> in a
 548 local lexical, localize C<$saved[0]> (which is where C<save()> will put
 549 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
 550 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
 551 considered sane by the debugger. If there was an C<eval()> error, we print
 552 it on the debugger's output. If C<$onetimedump> is defined, we call
 553 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
 554 'methods'. Setting it to something else causes the debugger to do the eval
 555 but not print the result - handy if you want to do something else with it
 556 (the "watch expressions" code does this to get the value of the watch
 557 expression but not show it unless it matters).
 558
 559 In any case, we then return the list of output from C<eval> to the caller,
 560 and unwinding restores the former version of C<$@> in C<@saved> as well
 561 (the localization of C<$saved[0]> goes away at the end of this scope).
 562
 563 =head3 Parameters and variables influencing execution of DB::eval()
 564
 565 C<DB::eval> isn't parameterized in the standard way; this is to keep the
 566 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
 567 The variables listed below influence C<DB::eval()>'s execution directly.
 568
 569 =over 4
 570
 571 =item C<$evalarg> - the thing to actually be eval'ed
 572
 573 =item C<$trace> - Current state of execution tracing
 574
 575 =item C<$single> - Current state of single-stepping
 576
 577 =item C<$onetimeDump> - what is to be displayed after the evaluation
 578
 579 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
 580
 581 =back
 582
 583 The following variables are altered by C<DB::eval()> during its execution. They
 584 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
 585
 586 =over 4
 587
 588 =item C<@res> - used to capture output from actual C<eval>.
 589
 590 =item C<$otrace> - saved value of C<$trace>.
 591
 592 =item C<$osingle> - saved value of C<$single>.
 593
 594 =item C<$od> - saved value of C<$^D>.
 595
 596 =item C<$saved[0]> - saved value of C<$@>.
 597
 598 =item $\ - for output of C<$@> if there is an evaluation error.
 599
 600 =back
 601
 602 =head3 The problem of lexicals
 603
 604 The context of C<DB::eval()> presents us with some problems. Obviously,
 605 we want to be 'sandboxed' away from the debugger's internals when we do
 606 the eval, but we need some way to control how punctuation variables and
 607 debugger globals are used.
 608
 609 We can't use local, because the code inside C<DB::eval> can see localized
 610 variables; and we can't use C<my> either for the same reason. The code
 611 in this routine compromises and uses C<my>.
 612
 613 After this routine is over, we don't have user code executing in the debugger's
 614 context, so we can use C<my> freely.
 615
 616 =cut
 617
 618 ############################################## Begin lexical danger zone
 619
 620 # 'my' variables used here could leak into (that is, be visible in)
 621 # the context that the code being evaluated is executing in. This means that
 622 # the code could modify the debugger's variables.
 623 #
 624 # Fiddling with the debugger's context could be Bad. We insulate things as
 625 # much as we can.
 626
 627 use vars qw(
 628     @args
 629     %break_on_load
 630     @cmdfhs
 631     $CommandSet
 632     $CreateTTY
 633     $DBGR
 634     @dbline
 635     $dbline
 636     %dbline
 637     $dieLevel
 638     $evalarg
 639     $filename
 640     $frame
 641     $hist
 642     $histfile
 643     $histsize
 644     $ImmediateStop
 645     $IN
 646     $inhibit_exit
 647     @ini_INC
 648     $ini_warn
 649     $line
 650     $maxtrace
 651     $od
 652     $onetimeDump
 653     $onetimedumpDepth
 654     %option
 655     @options
 656     $osingle
 657     $otrace
 658     $OUT
 659     $packname
 660     $pager
 661     $post
 662     %postponed
 663     $prc
 664     $pre
 665     $pretype
 666     $psh
 667     @RememberOnROptions
 668     $remoteport
 669     @res
 670     $rl
 671     @saved
 672     $signal
 673     $signalLevel
 674     $single
 675     $start
 676     $sub
 677     %sub
 678     $subname
 679     $term
 680     $trace
 681     $usercontext
 682     $warnLevel
 683     $window
 684 );
 685
 686 # Used to save @ARGV and extract any debugger-related flags.
 687 use vars qw(@ARGS);
 688
 689 # Used to prevent multiple entries to diesignal()
 690 # (if for instance diesignal() itself dies)
 691 use vars qw($panic);
 692
 693 # Used to prevent the debugger from running nonstop
 694 # after a restart
 695 use vars qw($second_time);
 696
 697 sub _calc_usercontext {
 698     my ($package) = @_;
 699
 700     # Cancel strict completely for the evaluated code, so the code
 701     # the user evaluates won't be affected by it. (Shlomi Fish)
 702     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @DB::saved;'
 703     . "package $package;";    # this won't let them modify, alas
 704 }
 705
 706 sub eval {
 707
 708     # 'my' would make it visible from user code
 709     #    but so does local! --tchrist
 710     # Remember: this localizes @DB::res, not @main::res.
 711     local @res;
 712     {
 713
 714         # Try to keep the user code from messing  with us. Save these so that
 715         # even if the eval'ed code changes them, we can put them back again.
 716         # Needed because the user could refer directly to the debugger's
 717         # package globals (and any 'my' variables in this containing scope)
 718         # inside the eval(), and we want to try to stay safe.
 719         local $otrace  = $trace;
 720         local $osingle = $single;
 721         local $od      = $^D;
 722
 723         # Untaint the incoming eval() argument.
 724         { ($evalarg) = $evalarg =~ /(.*)/s; }
 725
 726         # $usercontext built in DB::DB near the comment
 727         # "set up the context for DB::eval ..."
 728         # Evaluate and save any results.
 729         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
 730
 731         # Restore those old values.
 732         $trace  = $otrace;
 733         $single = $osingle;
 734         $^D     = $od;
 735     }
 736
 737     # Save the current value of $@, and preserve it in the debugger's copy
 738     # of the saved precious globals.
 739     my $at = $@;
 740
 741     # Since we're only saving $@, we only have to localize the array element
 742     # that it will be stored in.
 743     local $saved[0];    # Preserve the old value of $@
 744     eval { DB::save() };
 745
 746     # Now see whether we need to report an error back to the user.
 747     if ($at) {
 748         local $\ = '';
 749         print $OUT $at;
 750     }
 751
 752     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
 753     # are package globals.
 754     elsif ($onetimeDump) {
 755         if ( $onetimeDump eq 'dump' ) {
 756             local $option{dumpDepth} = $onetimedumpDepth
 757               if defined $onetimedumpDepth;
 758             dumpit( $OUT, \@res );
 759         }
 760         elsif ( $onetimeDump eq 'methods' ) {
 761             methods( $res[0] );
 762         }
 763     } ## end elsif ($onetimeDump)
 764     @res;
 765 } ## end sub eval
 766
 767 ############################################## End lexical danger zone
 768
 769 # After this point it is safe to introduce lexicals.
 770 # The code being debugged will be executing in its own context, and
 771 # can't see the inside of the debugger.
 772 #
 773 # However, one should not overdo it: leave as much control from outside as
 774 # possible. If you make something a lexical, it's not going to be addressable
 775 # from outside the debugger even if you know its name.
 776
 777 # This file is automatically included if you do perl -d.
 778 # It's probably not useful to include this yourself.
 779 #
 780 # Before venturing further into these twisty passages, it is
 781 # wise to read the perldebguts man page or risk the ire of dragons.
 782 #
 783 # (It should be noted that perldebguts will tell you a lot about
 784 # the underlying mechanics of how the debugger interfaces into the
 785 # Perl interpreter, but not a lot about the debugger itself. The new
 786 # comments in this code try to address this problem.)
 787
 788 # Note that no subroutine call is possible until &DB::sub is defined
 789 # (for subroutines defined outside of the package DB). In fact the same is
 790 # true if $deep is not defined.
 791
 792 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
 793
 794 # modified Perl debugger, to be run from Emacs in perldb-mode
 795 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
 796 # Johan Vromans -- upgrade to 4.0 pl 10
 797 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
 798 ########################################################################
 799
 800 =head1 DEBUGGER INITIALIZATION
 801
 802 The debugger starts up in phases.
 803
 804 =head2 BASIC SETUP
 805
 806 First, it initializes the environment it wants to run in: turning off
 807 warnings during its own compilation, defining variables which it will need
 808 to avoid warnings later, setting itself up to not exit when the program
 809 terminates, and defaulting to printing return values for the C<r> command.
 810
 811 =cut
 812
 813 # Needed for the statement after exec():
 814 #
 815 # This BEGIN block is simply used to switch off warnings during debugger
 816 # compilation. Probably it would be better practice to fix the warnings,
 817 # but this is how it's done at the moment.
 818
 819 BEGIN {
 820     $ini_warn = $^W;
 821     $^W       = 0;
 822 }    # Switch compilation warnings off until another BEGIN.
 823
 824 local ($^W) = 0;    # Switch run-time warnings off during init.
 825
 826 =head2 THREADS SUPPORT
 827
 828 If we are running under a threaded Perl, we require threads and threads::shared
 829 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
 830 threaded debugger control.  C<-dt> can also be used to set this.
 831
 832 Each new thread will be announced and the debugger prompt will always inform
 833 you of each new thread created.  It will also indicate the thread id in which
 834 we are currently running within the prompt like this:
 835
 836     [tid] DB<$i>
 837
 838 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
 839 command prompt.  The prompt will show: C<[0]> when running under threads, but
 840 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
 841
 842 While running under threads, when you set or delete a breakpoint (etc.), this
 843 will apply to all threads, not just the currently running one.  When you are
 844 in a currently executing thread, you will stay there until it completes.  With
 845 the current implementation it is not currently possible to hop from one thread
 846 to another.
 847
 848 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
 849
 850 Note that threading support was built into the debugger as of Perl version
 851 C<5.8.6> and debugger version C<1.2.8>.
 852
 853 =cut
 854
 855 BEGIN {
 856     # ensure we can share our non-threaded variables or no-op
 857     if ($ENV{PERL5DB_THREADED}) {
 858         require threads;
 859         require threads::shared;
 860         import threads::shared qw(share);
 861         $DBGR;
 862         share(\$DBGR);
 863         lock($DBGR);
 864         print "Threads support enabled\n";
 865     } else {
 866         *lock  = sub(*) {};
 867         *share = sub(*) {};
 868     }
 869 }
 870
 871 # These variables control the execution of 'dumpvar.pl'.
 872 {
 873     package dumpvar;
 874     use vars qw(
 875     $hashDepth
 876     $arrayDepth
 877     $dumpDBFiles
 878     $dumpPackages
 879     $quoteHighBit
 880     $printUndef
 881     $globPrint
 882     $usageOnly
 883     );
 884 }
 885
 886 # used to control die() reporting in diesignal()
 887 {
 888     package Carp;
 889     use vars qw($CarpLevel);
 890 }
 891
 892 # without threads, $filename is not defined until DB::DB is called
 893 foreach my $k (keys (%INC)) {
 894     share(\$main::{'_<'.$filename}) if defined $filename;
 895 };
 896
 897 # Command-line + PERLLIB:
 898 # Save the contents of @INC before they are modified elsewhere.
 899 @ini_INC = @INC;
 900
 901 # This was an attempt to clear out the previous values of various
 902 # trapped errors. Apparently it didn't help. XXX More info needed!
 903 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
 904
 905 # We set these variables to safe values. We don't want to blindly turn
 906 # off warnings, because other packages may still want them.
 907 $trace = $signal = $single = 0;    # Uninitialized warning suppression
 908                                    # (local $^W cannot help - other packages!).
 909
 910 # Default to not exiting when program finishes; print the return
 911 # value when the 'r' command is used to return from a subroutine.
 912 $inhibit_exit = $option{PrintRet} = 1;
 913
 914 use vars qw($trace_to_depth);
 915
 916 # Default to 1E9 so it won't be limited to a certain recursion depth.
 917 $trace_to_depth = 1E9;
 918
 919 =head1 OPTION PROCESSING
 920
 921 The debugger's options are actually spread out over the debugger itself and
 922 C<dumpvar.pl>; some of these are variables to be set, while others are
 923 subs to be called with a value. To try to make this a little easier to
 924 manage, the debugger uses a few data structures to define what options
 925 are legal and how they are to be processed.
 926
 927 First, the C<@options> array defines the I<names> of all the options that
 928 are to be accepted.
 929
 930 =cut
 931
 932 @options = qw(
 933   CommandSet   HistFile      HistSize
 934   hashDepth    arrayDepth    dumpDepth
 935   DumpDBFiles  DumpPackages  DumpReused
 936   compactDump  veryCompact   quote
 937   HighBit      undefPrint    globPrint
 938   PrintRet     UsageOnly     frame
 939   AutoTrace    TTY           noTTY
 940   ReadLine     NonStop       LineInfo
 941   maxTraceLen  recallCommand ShellBang
 942   pager        tkRunning     ornaments
 943   signalLevel  warnLevel     dieLevel
 944   inhibit_exit ImmediateStop bareStringify
 945   CreateTTY    RemotePort    windowSize
 946   DollarCaretP
 947 );
 948
 949 @RememberOnROptions = qw(DollarCaretP);
 950
 951 =pod
 952
 953 Second, C<optionVars> lists the variables that each option uses to save its
 954 state.
 955
 956 =cut
 957
 958 use vars qw(%optionVars);
 959
 960 %optionVars = (
 961     hashDepth     => \$dumpvar::hashDepth,
 962     arrayDepth    => \$dumpvar::arrayDepth,
 963     CommandSet    => \$CommandSet,
 964     DumpDBFiles   => \$dumpvar::dumpDBFiles,
 965     DumpPackages  => \$dumpvar::dumpPackages,
 966     DumpReused    => \$dumpvar::dumpReused,
 967     HighBit       => \$dumpvar::quoteHighBit,
 968     undefPrint    => \$dumpvar::printUndef,
 969     globPrint     => \$dumpvar::globPrint,
 970     UsageOnly     => \$dumpvar::usageOnly,
 971     CreateTTY     => \$CreateTTY,
 972     bareStringify => \$dumpvar::bareStringify,
 973     frame         => \$frame,
 974     AutoTrace     => \$trace,
 975     inhibit_exit  => \$inhibit_exit,
 976     maxTraceLen   => \$maxtrace,
 977     ImmediateStop => \$ImmediateStop,
 978     RemotePort    => \$remoteport,
 979     windowSize    => \$window,
 980     HistFile      => \$histfile,
 981     HistSize      => \$histsize,
 982 );
 983
 984 =pod
 985
 986 Third, C<%optionAction> defines the subroutine to be called to process each
 987 option.
 988
 989 =cut
 990
 991 use vars qw(%optionAction);
 992
 993 %optionAction = (
 994     compactDump   => \&dumpvar::compactDump,
 995     veryCompact   => \&dumpvar::veryCompact,
 996     quote         => \&dumpvar::quote,
 997     TTY           => \&TTY,
 998     noTTY         => \&noTTY,
 999     ReadLine      => \&ReadLine,
1000     NonStop       => \&NonStop,
1001     LineInfo      => \&LineInfo,
1002     recallCommand => \&recallCommand,
1003     ShellBang     => \&shellBang,
1004     pager         => \&pager,
1005     signalLevel   => \&signalLevel,
1006     warnLevel     => \&warnLevel,
1007     dieLevel      => \&dieLevel,
1008     tkRunning     => \&tkRunning,
1009     ornaments     => \&ornaments,
1010     RemotePort    => \&RemotePort,
1011     DollarCaretP  => \&DollarCaretP,
1012 );
1013
1014 =pod
1015
1016 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1017 option is used.
1018
1019 =cut
1020
1021 # Note that this list is not complete: several options not listed here
1022 # actually require that dumpvar.pl be loaded for them to work, but are
1023 # not in the table. A subsequent patch will correct this problem; for
1024 # the moment, we're just recommenting, and we are NOT going to change
1025 # function.
1026 use vars qw(%optionRequire);
1027
1028 %optionRequire = (
1029     compactDump => 'dumpvar.pl',
1030     veryCompact => 'dumpvar.pl',
1031     quote       => 'dumpvar.pl',
1032 );
1033
1034 =pod
1035
1036 There are a number of initialization-related variables which can be set
1037 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1038 variable. These are:
1039
1040 =over 4
1041
1042 =item C<$rl> - readline control XXX needs more explanation
1043
1044 =item C<$warnLevel> - whether or not debugger takes over warning handling
1045
1046 =item C<$dieLevel> - whether or not debugger takes over die handling
1047
1048 =item C<$signalLevel> - whether or not debugger takes over signal handling
1049
1050 =item C<$pre> - preprompt actions (array reference)
1051
1052 =item C<$post> - postprompt actions (array reference)
1053
1054 =item C<$pretype>
1055
1056 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1057
1058 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1059
1060 =back
1061
1062 =cut
1063
1064 # These guys may be defined in $ENV{PERL5DB} :
1065 $rl          = 1     unless defined $rl;
1066 $warnLevel   = 1     unless defined $warnLevel;
1067 $dieLevel    = 1     unless defined $dieLevel;
1068 $signalLevel = 1     unless defined $signalLevel;
1069 $pre         = []    unless defined $pre;
1070 $post        = []    unless defined $post;
1071 $pretype     = []    unless defined $pretype;
1072 $CreateTTY   = 3     unless defined $CreateTTY;
1073 $CommandSet  = '580' unless defined $CommandSet;
1074
1075 share($rl);
1076 share($warnLevel);
1077 share($dieLevel);
1078 share($signalLevel);
1079 share($pre);
1080 share($post);
1081 share($pretype);
1082 share($rl);
1083 share($CreateTTY);
1084 share($CommandSet);
1085
1086 =pod
1087
1088 The default C<die>, C<warn>, and C<signal> handlers are set up.
1089
1090 =cut
1091
1092 warnLevel($warnLevel);
1093 dieLevel($dieLevel);
1094 signalLevel($signalLevel);
1095
1096 =pod
1097
1098 The pager to be used is needed next. We try to get it from the
1099 environment first.  If it's not defined there, we try to find it in
1100 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1101 then call the C<pager()> function to save the pager name.
1102
1103 =cut
1104
1105 # This routine makes sure $pager is set up so that '|' can use it.
1106 pager(
1107
1108     # If PAGER is defined in the environment, use it.
1109     defined $ENV{PAGER}
1110     ? $ENV{PAGER}
1111
1112       # If not, see if Config.pm defines it.
1113     : eval { require Config }
1114       && defined $Config::Config{pager}
1115     ? $Config::Config{pager}
1116
1117       # If not, fall back to 'more'.
1118     : 'more'
1119   )
1120   unless defined $pager;
1121
1122 =pod
1123
1124 We set up the command to be used to access the man pages, the command
1125 recall character (C<!> unless otherwise defined) and the shell escape
1126 character (C<!> unless otherwise defined). Yes, these do conflict, and
1127 neither works in the debugger at the moment.
1128
1129 =cut
1130
1131 setman();
1132
1133 # Set up defaults for command recall and shell escape (note:
1134 # these currently don't work in linemode debugging).
1135 recallCommand("!") unless defined $prc;
1136 shellBang("!")     unless defined $psh;
1137
1138 =pod
1139
1140 We then set up the gigantic string containing the debugger help.
1141 We also set the limit on the number of arguments we'll display during a
1142 trace.
1143
1144 =cut
1145
1146 sethelp();
1147
1148 # If we didn't get a default for the length of eval/stack trace args,
1149 # set it here.
1150 $maxtrace = 400 unless defined $maxtrace;
1151
1152 =head2 SETTING UP THE DEBUGGER GREETING
1153
1154 The debugger I<greeting> helps to inform the user how many debuggers are
1155 running, and whether the current debugger is the primary or a child.
1156
1157 If we are the primary, we just hang onto our pid so we'll have it when
1158 or if we start a child debugger. If we are a child, we'll set things up
1159 so we'll have a unique greeting and so the parent will give us our own
1160 TTY later.
1161
1162 We save the current contents of the C<PERLDB_PIDS> environment variable
1163 because we mess around with it. We'll also need to hang onto it because
1164 we'll need it if we restart.
1165
1166 Child debuggers make a label out of the current PID structure recorded in
1167 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1168 yet so the parent will give them one later via C<resetterm()>.
1169
1170 =cut
1171
1172 # Save the current contents of the environment; we're about to
1173 # much with it. We'll need this if we have to restart.
1174 use vars qw($ini_pids);
1175 $ini_pids = $ENV{PERLDB_PIDS};
1176
1177 use vars qw ($pids $term_pid);
1178
1179 if ( defined $ENV{PERLDB_PIDS} ) {
1180
1181     # We're a child. Make us a label out of the current PID structure
1182     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1183     # a term yet so the parent will give us one later via resetterm().
1184
1185     my $env_pids = $ENV{PERLDB_PIDS};
1186     $pids = "[$env_pids]";
1187
1188     # Unless we are on OpenVMS, all programs under the DCL shell run under
1189     # the same PID.
1190
1191     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1192         $term_pid         = $$;
1193     }
1194     else {
1195         $ENV{PERLDB_PIDS} .= "->$$";
1196         $term_pid = -1;
1197     }
1198
1199 } ## end if (defined $ENV{PERLDB_PIDS...
1200 else {
1201
1202     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1203     # child debugger, and mark us as the parent, so we'll know to set up
1204     # more TTY's is we have to.
1205     $ENV{PERLDB_PIDS} = "$$";
1206     $pids             = "[pid=$$]";
1207     $term_pid         = $$;
1208 }
1209
1210 use vars qw($pidprompt);
1211 $pidprompt = '';
1212
1213 # Sets up $emacs as a synonym for $slave_editor.
1214 use vars qw($slave_editor);
1215 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1216
1217 =head2 READING THE RC FILE
1218
1219 The debugger will read a file of initialization options if supplied. If
1220 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1221
1222 =cut
1223
1224 # As noted, this test really doesn't check accurately that the debugger
1225 # is running at a terminal or not.
1226
1227 use vars qw($rcfile);
1228 {
1229     my $dev_tty = (($^O eq 'VMS') ? 'TT:' : '/dev/tty');
1230     # this is the wrong metric!
1231     $rcfile = ((-e $dev_tty) ? ".perldb" : "perldb.ini");
1232 }
1233
1234 =pod
1235
1236 The debugger does a safety test of the file to be read. It must be owned
1237 either by the current user or root, and must only be writable by the owner.
1238
1239 =cut
1240
1241 # This wraps a safety test around "do" to read and evaluate the init file.
1242 #
1243 # This isn't really safe, because there's a race
1244 # between checking and opening.  The solution is to
1245 # open and fstat the handle, but then you have to read and
1246 # eval the contents.  But then the silly thing gets
1247 # your lexical scope, which is unfortunate at best.
1248 sub safe_do {
1249     my $file = shift;
1250
1251     # Just exactly what part of the word "CORE::" don't you understand?
1252     local $SIG{__WARN__};
1253     local $SIG{__DIE__};
1254
1255     unless ( is_safe_file($file) ) {
1256         CORE::warn <<EO_GRIPE;
1257 perldb: Must not source insecure rcfile $file.
1258         You or the superuser must be the owner, and it must not
1259         be writable by anyone but its owner.
1260 EO_GRIPE
1261         return;
1262     } ## end unless (is_safe_file($file...
1263
1264     do $file;
1265     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1266 } ## end sub safe_do
1267
1268 # This is the safety test itself.
1269 #
1270 # Verifies that owner is either real user or superuser and that no
1271 # one but owner may write to it.  This function is of limited use
1272 # when called on a path instead of upon a handle, because there are
1273 # no guarantees that filename (by dirent) whose file (by ino) is
1274 # eventually accessed is the same as the one tested.
1275 # Assumes that the file's existence is not in doubt.
1276 sub is_safe_file {
1277     my $path = shift;
1278     stat($path) || return;    # mysteriously vaporized
1279     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1280
1281     return 0 if $uid != 0 && $uid != $<;
1282     return 0 if $mode & 022;
1283     return 1;
1284 } ## end sub is_safe_file
1285
1286 # If the rcfile (whichever one we decided was the right one to read)
1287 # exists, we safely do it.
1288 if ( -f $rcfile ) {
1289     safe_do("./$rcfile");
1290 }
1291
1292 # If there isn't one here, try the user's home directory.
1293 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1294     safe_do("$ENV{HOME}/$rcfile");
1295 }
1296
1297 # Else try the login directory.
1298 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1299     safe_do("$ENV{LOGDIR}/$rcfile");
1300 }
1301
1302 # If the PERLDB_OPTS variable has options in it, parse those out next.
1303 if ( defined $ENV{PERLDB_OPTS} ) {
1304     parse_options( $ENV{PERLDB_OPTS} );
1305 }
1306
1307 =pod
1308
1309 The last thing we do during initialization is determine which subroutine is
1310 to be used to obtain a new terminal when a new debugger is started. Right now,
1311 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1312 (darwin).
1313
1314 =cut
1315
1316 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1317 # Works if you're running an xterm or xterm-like window, or you're on
1318 # OS/2, or on Mac OS X. This may need some expansion.
1319
1320 if (not defined &get_fork_TTY)       # only if no routine exists
1321 {
1322     if ( defined $remoteport ) {
1323                                                  # Expect an inetd-like server
1324         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1325     }
1326     elsif (defined $ENV{TERM}                    # If we know what kind
1327                                                  # of terminal this is,
1328         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1329         and defined $ENV{DISPLAY}                # and what display it's on,
1330       )
1331     {
1332         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1333     }
1334     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1335         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1336     }
1337     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1338             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1339             and $ENV{TERM_PROGRAM}
1340                 eq 'Apple_Terminal'              # Terminal.app
1341             )
1342     {
1343         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1344     }
1345 } ## end if (not defined &get_fork_TTY...
1346
1347 # untaint $^O, which may have been tainted by the last statement.
1348 # see bug [perl #24674]
1349 $^O =~ m/^(.*)\z/;
1350 $^O = $1;
1351
1352 # Here begin the unreadable code.  It needs fixing.
1353
1354 =head2 RESTART PROCESSING
1355
1356 This section handles the restart command. When the C<R> command is invoked, it
1357 tries to capture all of the state it can into environment variables, and
1358 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1359 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1360 the R command stuffed into the environment variables.
1361
1362   PERLDB_RESTART   - flag only, contains no restart data itself.
1363   PERLDB_HIST      - command history, if it's available
1364   PERLDB_ON_LOAD   - breakpoints set by the rc file
1365   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1366   PERLDB_VISITED   - files that had breakpoints
1367   PERLDB_FILE_...  - breakpoints for a file
1368   PERLDB_OPT       - active options
1369   PERLDB_INC       - the original @INC
1370   PERLDB_PRETYPE   - preprompt debugger actions
1371   PERLDB_PRE       - preprompt Perl code
1372   PERLDB_POST      - post-prompt Perl code
1373   PERLDB_TYPEAHEAD - typeahead captured by readline()
1374
1375 We chug through all these variables and plug the values saved in them
1376 back into the appropriate spots in the debugger.
1377
1378 =cut
1379
1380 use vars qw(@hist @truehist %postponed_file @typeahead);
1381
1382 sub _restore_shared_globals_after_restart
1383 {
1384     @hist          = get_list('PERLDB_HIST');
1385     %break_on_load = get_list("PERLDB_ON_LOAD");
1386     %postponed     = get_list("PERLDB_POSTPONE");
1387
1388     share(@hist);
1389     share(@truehist);
1390     share(%break_on_load);
1391     share(%postponed);
1392 }
1393
1394 sub _restore_breakpoints_and_actions {
1395
1396     my @had_breakpoints = get_list("PERLDB_VISITED");
1397
1398     for my $file_idx ( 0 .. $#had_breakpoints ) {
1399         my $filename = $had_breakpoints[$file_idx];
1400         my %pf = get_list("PERLDB_FILE_$file_idx");
1401         $postponed_file{ $filename } = \%pf if %pf;
1402         my @lines = sort {$a <=> $b} keys(%pf);
1403         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1404         for my $line_idx (0 .. $#lines) {
1405             _set_breakpoint_enabled_status(
1406                 $filename,
1407                 $lines[$line_idx],
1408                 ($enabled_statuses[$line_idx] ? 1 : ''),
1409             );
1410         }
1411     }
1412
1413     return;
1414 }
1415
1416 sub _restore_options_after_restart
1417 {
1418     my %options_map = get_list("PERLDB_OPT");
1419
1420     while ( my ( $opt, $val ) = each %options_map ) {
1421         $val =~ s/[\\\']/\\$1/g;
1422         parse_options("$opt'$val'");
1423     }
1424
1425     return;
1426 }
1427
1428 sub _restore_globals_after_restart
1429 {
1430     # restore original @INC
1431     @INC     = get_list("PERLDB_INC");
1432     @ini_INC = @INC;
1433
1434     # return pre/postprompt actions and typeahead buffer
1435     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1436     $pre       = [ get_list("PERLDB_PRE") ];
1437     $post      = [ get_list("PERLDB_POST") ];
1438     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1439
1440     return;
1441 }
1442
1443
1444 if ( exists $ENV{PERLDB_RESTART} ) {
1445
1446     # We're restarting, so we don't need the flag that says to restart anymore.
1447     delete $ENV{PERLDB_RESTART};
1448
1449     # $restart = 1;
1450     _restore_shared_globals_after_restart();
1451
1452     _restore_breakpoints_and_actions();
1453
1454     # restore options
1455     _restore_options_after_restart();
1456
1457     _restore_globals_after_restart();
1458 } ## end if (exists $ENV{PERLDB_RESTART...
1459
1460 =head2 SETTING UP THE TERMINAL
1461
1462 Now, we'll decide how the debugger is going to interact with the user.
1463 If there's no TTY, we set the debugger to run non-stop; there's not going
1464 to be anyone there to enter commands.
1465
1466 =cut
1467
1468 use vars qw($notty $runnonstop $console $tty $LINEINFO);
1469 use vars qw($lineinfo $doccmd);
1470
1471 if ($notty) {
1472     $runnonstop = 1;
1473     share($runnonstop);
1474 }
1475
1476 =pod
1477
1478 If there is a TTY, we have to determine who it belongs to before we can
1479 proceed. If this is a slave editor or graphical debugger (denoted by
1480 the first command-line switch being '-emacs'), we shift this off and
1481 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1482
1483 =cut
1484
1485 else {
1486
1487     # Is Perl being run from a slave editor or graphical debugger?
1488     # If so, don't use readline, and set $slave_editor = 1.
1489     if ($slave_editor = ( @main::ARGV && ( $main::ARGV[0] eq '-emacs' ) )) {
1490         $rl = 0;
1491         shift(@main::ARGV);
1492     }
1493
1494     #require Term::ReadLine;
1495
1496 =pod
1497
1498 We then determine what the console should be on various systems:
1499
1500 =over 4
1501
1502 =item * Cygwin - We use C<stdin> instead of a separate device.
1503
1504 =cut
1505
1506     if ( $^O eq 'cygwin' ) {
1507
1508         # /dev/tty is binary. use stdin for textmode
1509         undef $console;
1510     }
1511
1512 =item * Unix - use C</dev/tty>.
1513
1514 =cut
1515
1516     elsif ( -e "/dev/tty" ) {
1517         $console = "/dev/tty";
1518     }
1519
1520 =item * Windows or MSDOS - use C<con>.
1521
1522 =cut
1523
1524     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1525         $console = "con";
1526     }
1527
1528 =item * VMS - use C<sys$command>.
1529
1530 =cut
1531
1532     else {
1533
1534         # everything else is ...
1535         $console = "sys\$command";
1536     }
1537
1538 =pod
1539
1540 =back
1541
1542 Several other systems don't use a specific console. We C<undef $console>
1543 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1544 with a slave editor, Epoc).
1545
1546 =cut
1547
1548     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1549
1550         # /dev/tty is binary. use stdin for textmode
1551         $console = undef;
1552     }
1553
1554     if ( $^O eq 'NetWare' ) {
1555
1556         # /dev/tty is binary. use stdin for textmode
1557         $console = undef;
1558     }
1559
1560     # In OS/2, we need to use STDIN to get textmode too, even though
1561     # it pretty much looks like Unix otherwise.
1562     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1563     {    # In OS/2
1564         $console = undef;
1565     }
1566
1567     # EPOC also falls into the 'got to use STDIN' camp.
1568     if ( $^O eq 'epoc' ) {
1569         $console = undef;
1570     }
1571
1572 =pod
1573
1574 If there is a TTY hanging around from a parent, we use that as the console.
1575
1576 =cut
1577
1578     $console = $tty if defined $tty;
1579
1580 =head2 SOCKET HANDLING
1581
1582 The debugger is capable of opening a socket and carrying out a debugging
1583 session over the socket.
1584
1585 If C<RemotePort> was defined in the options, the debugger assumes that it
1586 should try to start a debugging session on that port. It builds the socket
1587 and then tries to connect the input and output filehandles to it.
1588
1589 =cut
1590
1591     # Handle socket stuff.
1592
1593     if ( defined $remoteport ) {
1594
1595         # If RemotePort was defined in the options, connect input and output
1596         # to the socket.
1597         $IN = $OUT = connect_remoteport();
1598     } ## end if (defined $remoteport)
1599
1600 =pod
1601
1602 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1603 this is probably a situation where multiple debuggers are running (for example,
1604 a backticked command that starts up another debugger). We create a new IN and
1605 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1606 and if we can.
1607
1608 =cut
1609
1610     # Non-socket.
1611     else {
1612
1613         # Two debuggers running (probably a system or a backtick that invokes
1614         # the debugger itself under the running one). create a new IN and OUT
1615         # filehandle, and do the necessary mojo to create a new tty if we
1616         # know how, and we can.
1617         create_IN_OUT(4) if $CreateTTY & 4;
1618         if ($console) {
1619
1620             # If we have a console, check to see if there are separate ins and
1621             # outs to open. (They are assumed identical if not.)
1622
1623             my ( $i, $o ) = split /,/, $console;
1624             $o = $i unless defined $o;
1625
1626             # read/write on in, or just read, or read on STDIN.
1627             open( IN,      "+<$i" )
1628               || open( IN, "<$i" )
1629               || open( IN, "<&STDIN" );
1630
1631             # read/write/create/clobber out, or write/create/clobber out,
1632             # or merge with STDERR, or merge with STDOUT.
1633                  open( OUT, "+>$o" )
1634               || open( OUT, ">$o" )
1635               || open( OUT, ">&STDERR" )
1636               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1637
1638         } ## end if ($console)
1639         elsif ( not defined $console ) {
1640
1641             # No console. Open STDIN.
1642             open( IN, "<&STDIN" );
1643
1644             # merge with STDERR, or with STDOUT.
1645             open( OUT,      ">&STDERR" )
1646               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1647             $console = 'STDIN/OUT';
1648         } ## end elsif (not defined $console)
1649
1650         # Keep copies of the filehandles so that when the pager runs, it
1651         # can close standard input without clobbering ours.
1652         if ($console or (not defined($console))) {
1653             $IN = \*IN;
1654             $OUT = \*OUT;
1655         }
1656     } ## end elsif (from if(defined $remoteport))
1657
1658     # Unbuffer DB::OUT. We need to see responses right away.
1659     $OUT->autoflush(1);
1660
1661     # Line info goes to debugger output unless pointed elsewhere.
1662     # Pointing elsewhere makes it possible for slave editors to
1663     # keep track of file and position. We have both a filehandle
1664     # and a I/O description to keep track of.
1665     $LINEINFO = $OUT     unless defined $LINEINFO;
1666     $lineinfo = $console unless defined $lineinfo;
1667     # share($LINEINFO); # <- unable to share globs
1668     share($lineinfo);   #
1669
1670 =pod
1671
1672 To finish initialization, we show the debugger greeting,
1673 and then call the C<afterinit()> subroutine if there is one.
1674
1675 =cut
1676
1677     # Show the debugger greeting.
1678     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1679     unless ($runnonstop) {
1680         local $\ = '';
1681         local $, = '';
1682         if ( $term_pid eq '-1' ) {
1683             print $OUT "\nDaughter DB session started...\n";
1684         }
1685         else {
1686             print $OUT "\nLoading DB routines from $header\n";
1687             print $OUT (
1688                 "Editor support ",
1689                 $slave_editor ? "enabled" : "available", ".\n"
1690             );
1691             print $OUT
1692 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1693         } ## end else [ if ($term_pid eq '-1')
1694     } ## end unless ($runnonstop)
1695 } ## end else [ if ($notty)
1696
1697 # XXX This looks like a bug to me.
1698 # Why copy to @ARGS and then futz with @args?
1699 @ARGS = @ARGV;
1700 # for (@args) {
1701     # Make sure backslashes before single quotes are stripped out, and
1702     # keep args unless they are numeric (XXX why?)
1703     # s/\'/\\\'/g;                      # removed while not justified understandably
1704     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1705 # }
1706
1707 # If there was an afterinit() sub defined, call it. It will get
1708 # executed in our scope, so it can fiddle with debugger globals.
1709 if ( defined &afterinit ) {    # May be defined in $rcfile
1710     afterinit();
1711 }
1712
1713 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1714 use vars qw($I_m_init);
1715
1716 $I_m_init = 1;
1717
1718 ############################################################ Subroutines
1719
1720 =head1 SUBROUTINES
1721
1722 =head2 DB
1723
1724 This gigantic subroutine is the heart of the debugger. Called before every
1725 statement, its job is to determine if a breakpoint has been reached, and
1726 stop if so; read commands from the user, parse them, and execute
1727 them, and then send execution off to the next statement.
1728
1729 Note that the order in which the commands are processed is very important;
1730 some commands earlier in the loop will actually alter the C<$cmd> variable
1731 to create other commands to be executed later. This is all highly I<optimized>
1732 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1733 see what's happening in any given command.
1734
1735 =cut
1736
1737 use vars qw(
1738     $action
1739     %alias
1740     $cmd
1741     $doret
1742     $fall_off_end
1743     $file
1744     $filename_ini
1745     $finished
1746     %had_breakpoints
1747     $incr
1748     $laststep
1749     $level
1750     $max
1751     @old_watch
1752     $package
1753     $rc
1754     $sh
1755     @stack
1756     $stack_depth
1757     @to_watch
1758     $try
1759     $end
1760 );
1761
1762 sub _DB__determine_if_we_should_break
1763 {
1764     # if we have something here, see if we should break.
1765     # $stop is lexical and local to this block - $action on the other hand
1766     # is global.
1767     my $stop;
1768
1769     if ( $dbline{$line}
1770         && _is_breakpoint_enabled($filename, $line)
1771         && (( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1772     {
1773
1774         # Stop if the stop criterion says to just stop.
1775         if ( $stop eq '1' ) {
1776             $signal |= 1;
1777         }
1778
1779         # It's a conditional stop; eval it in the user's context and
1780         # see if we should stop. If so, remove the one-time sigil.
1781         elsif ($stop) {
1782             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1783             &eval;
1784             # If the breakpoint is temporary, then delete its enabled status.
1785             if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1786                 _cancel_breakpoint_temp_enabled_status($filename, $line);
1787             }
1788         }
1789     } ## end if ($dbline{$line} && ...
1790 }
1791
1792 sub _DB__is_finished {
1793     if ($finished and $level <= 1) {
1794         end_report();
1795         return 1;
1796     }
1797     else {
1798         return;
1799     }
1800 }
1801
1802 sub _DB__read_next_cmd
1803 {
1804     my ($tid) = @_;
1805
1806     # We have a terminal, or can get one ...
1807     if (!$term) {
1808         setterm();
1809     }
1810
1811     # ... and it belogs to this PID or we get one for this PID ...
1812     if ($term_pid != $$) {
1813         resetterm(1);
1814     }
1815
1816     # ... and we got a line of command input ...
1817     $cmd = DB::readline(
1818         "$pidprompt $tid DB"
1819         . ( '<' x $level )
1820         . ( $#hist + 1 )
1821         . ( '>' x $level ) . " "
1822     );
1823
1824     return defined($cmd);
1825 }
1826
1827 sub _DB__trim_command_and_return_first_component {
1828     $cmd =~ s/\A\s+//s;    # trim annoying leading whitespace
1829     $cmd =~ s/\s+\z//s;    # trim annoying trailing whitespace
1830
1831     $cmd =~ m{\A(\S*)};
1832     return $1;
1833 }
1834
1835 sub DB {
1836
1837     # lock the debugger and get the thread id for the prompt
1838     lock($DBGR);
1839     my $tid;
1840     my $position;
1841     my ($prefix, $after, $infix);
1842     my $pat;
1843     my $explicit_stop;
1844
1845     if ($ENV{PERL5DB_THREADED}) {
1846         $tid = eval { "[".threads->tid."]" };
1847     }
1848
1849     my $obj = DB::Obj->new(
1850         {
1851             position => \$position,
1852             prefix => \$prefix,
1853             after => \$after,
1854             explicit_stop => \$explicit_stop,
1855             infix => \$infix,
1856         },
1857     );
1858
1859     $obj->_DB_on_init__initialize_globals(@_);
1860
1861     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
1862     # The code being debugged may have altered them.
1863     &save;
1864
1865     # Since DB::DB gets called after every line, we can use caller() to
1866     # figure out where we last were executing. Sneaky, eh? This works because
1867     # caller is returning all the extra information when called from the
1868     # debugger.
1869     local ( $package, $filename, $line ) = caller;
1870     $filename_ini = $filename;
1871
1872     # set up the context for DB::eval, so it can properly execute
1873     # code on behalf of the user. We add the package in so that the
1874     # code is eval'ed in the proper package (not in the debugger!).
1875     local $usercontext = _calc_usercontext($package);
1876
1877     # Create an alias to the active file magical array to simplify
1878     # the code here.
1879     local (*dbline) = $main::{ '_<' . $filename };
1880
1881     # Last line in the program.
1882     $max = $#dbline;
1883
1884     _DB__determine_if_we_should_break(@_);
1885
1886     # Preserve the current stop-or-not, and see if any of the W
1887     # (watch expressions) has changed.
1888     my $was_signal = $signal;
1889
1890     # If we have any watch expressions ...
1891     $obj->_DB__handle_watch_expressions(@_);
1892
1893 =head2 C<watchfunction()>
1894
1895 C<watchfunction()> is a function that can be defined by the user; it is a
1896 function which will be run on each entry to C<DB::DB>; it gets the
1897 current package, filename, and line as its parameters.
1898
1899 The watchfunction can do anything it likes; it is executing in the
1900 debugger's context, so it has access to all of the debugger's internal
1901 data structures and functions.
1902
1903 C<watchfunction()> can control the debugger's actions. Any of the following
1904 will cause the debugger to return control to the user's program after
1905 C<watchfunction()> executes:
1906
1907 =over 4
1908
1909 =item *
1910
1911 Returning a false value from the C<watchfunction()> itself.
1912
1913 =item *
1914
1915 Altering C<$single> to a false value.
1916
1917 =item *
1918
1919 Altering C<$signal> to a false value.
1920
1921 =item *
1922
1923 Turning off the C<4> bit in C<$trace> (this also disables the
1924 check for C<watchfunction()>. This can be done with
1925
1926     $trace &= ~4;
1927
1928 =back
1929
1930 =cut
1931
1932     # If there's a user-defined DB::watchfunction, call it with the
1933     # current package, filename, and line. The function executes in
1934     # the DB:: package.
1935     if ( $trace & 4 ) {    # User-installed watch
1936         return
1937           if watchfunction( $package, $filename, $line )
1938           and not $single
1939           and not $was_signal
1940           and not( $trace & ~4 );
1941     } ## end if ($trace & 4)
1942
1943     # Pick up any alteration to $signal in the watchfunction, and
1944     # turn off the signal now.
1945     $was_signal = $signal;
1946     $signal     = 0;
1947
1948 =head2 GETTING READY TO EXECUTE COMMANDS
1949
1950 The debugger decides to take control if single-step mode is on, the
1951 C<t> command was entered, or the user generated a signal. If the program
1952 has fallen off the end, we set things up so that entering further commands
1953 won't cause trouble, and we say that the program is over.
1954
1955 =cut
1956
1957     # Make sure that we always print if asked for explicitly regardless
1958     # of $trace_to_depth .
1959     $explicit_stop = ($single || $was_signal);
1960
1961     # Check to see if we should grab control ($single true,
1962     # trace set appropriately, or we got a signal).
1963     if ( $explicit_stop || ( $trace & 1 ) ) {
1964         $obj->_DB__grab_control(@_);
1965     } ## end if ($single || ($trace...
1966
1967 =pod
1968
1969 If there's an action to be executed for the line we stopped at, execute it.
1970 If there are any preprompt actions, execute those as well.
1971
1972 =cut
1973
1974     # If there's an action, do it now.
1975     if ($action) {
1976         $evalarg = $action;
1977         DB::eval();
1978     }
1979
1980     # Are we nested another level (e.g., did we evaluate a function
1981     # that had a breakpoint in it at the debugger prompt)?
1982     if ( $single || $was_signal ) {
1983
1984         # Yes, go down a level.
1985         local $level = $level + 1;
1986
1987         # Do any pre-prompt actions.
1988         foreach $evalarg (@$pre) {
1989             DB::eval();
1990         }
1991
1992         # Complain about too much recursion if we passed the limit.
1993         if ($single & 4) {
1994             print $OUT $stack_depth . " levels deep in subroutine calls!\n";
1995         }
1996
1997         # The line we're currently on. Set $incr to -1 to stay here
1998         # until we get a command that tells us to advance.
1999         $start = $line;
2000         $incr  = -1;      # for backward motion.
2001
2002         # Tack preprompt debugger actions ahead of any actual input.
2003         @typeahead = ( @$pretype, @typeahead );
2004
2005 =head2 WHERE ARE WE?
2006
2007 XXX Relocate this section?
2008
2009 The debugger normally shows the line corresponding to the current line of
2010 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2011 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2012
2013 C<$incr> controls by how many lines the I<current> line should move forward
2014 after a command is executed. If set to -1, this indicates that the I<current>
2015 line shouldn't change.
2016
2017 C<$start> is the I<current> line. It is used for things like knowing where to
2018 move forwards or backwards from when doing an C<L> or C<-> command.
2019
2020 C<$max> tells the debugger where the last line of the current file is. It's
2021 used to terminate loops most often.
2022
2023 =head2 THE COMMAND LOOP
2024
2025 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2026 in two parts:
2027
2028 =over 4
2029
2030 =item *
2031
2032 The outer part of the loop, starting at the C<CMD> label. This loop
2033 reads a command and then executes it.
2034
2035 =item *
2036
2037 The inner part of the loop, starting at the C<PIPE> label. This part
2038 is wholly contained inside the C<CMD> block and only executes a command.
2039 Used to handle commands running inside a pager.
2040
2041 =back
2042
2043 So why have two labels to restart the loop? Because sometimes, it's easier to
2044 have a command I<generate> another command and then re-execute the loop to do
2045 the new command. This is faster, but perhaps a bit more convoluted.
2046
2047 =cut
2048
2049         # The big command dispatch loop. It keeps running until the
2050         # user yields up control again.
2051         #
2052         # If we have a terminal for input, and we get something back
2053         # from readline(), keep on processing.
2054         my $piped;
2055         my $selected;
2056
2057       CMD:
2058         while (_DB__read_next_cmd($tid))
2059         {
2060
2061             share($cmd);
2062             # ... try to execute the input as debugger commands.
2063
2064             # Don't stop running.
2065             $single = 0;
2066
2067             # No signal is active.
2068             $signal = 0;
2069
2070             # Handle continued commands (ending with \):
2071             if ($cmd =~ s/\\\z/\n/) {
2072                 $cmd .= DB::readline("  cont: ");
2073                 redo CMD;
2074             }
2075
2076 =head4 The null command
2077
2078 A newline entered by itself means I<re-execute the last command>. We grab the
2079 command out of C<$laststep> (where it was recorded previously), and copy it
2080 back into C<$cmd> to be executed below. If there wasn't any previous command,
2081 we'll do nothing below (no command will match). If there was, we also save it
2082 in the command history and fall through to allow the command parsing to pick
2083 it up.
2084
2085 =cut
2086
2087             # Empty input means repeat the last command.
2088             if ($cmd eq '') {
2089                 $cmd = $laststep;
2090             }
2091             chomp($cmd);    # get rid of the annoying extra newline
2092             if (length($cmd) >= 2) {
2093                 push( @hist, $cmd );
2094             }
2095             push( @truehist, $cmd );
2096             share(@hist);
2097             share(@truehist);
2098
2099             # This is a restart point for commands that didn't arrive
2100             # via direct user input. It allows us to 'redo PIPE' to
2101             # re-execute command processing without reading a new command.
2102           PIPE: {
2103                 my $i = _DB__trim_command_and_return_first_component();
2104
2105 =head3 COMMAND ALIASES
2106
2107 The debugger can create aliases for commands (these are stored in the
2108 C<%alias> hash). Before a command is executed, the command loop looks it up
2109 in the alias hash and substitutes the contents of the alias for the command,
2110 completely replacing it.
2111
2112 =cut
2113
2114                 # See if there's an alias for the command, and set it up if so.
2115                 if ( $alias{$i} ) {
2116
2117                     # Squelch signal handling; we want to keep control here
2118                     # if something goes loco during the alias eval.
2119                     local $SIG{__DIE__};
2120                     local $SIG{__WARN__};
2121
2122                     # This is a command, so we eval it in the DEBUGGER's
2123                     # scope! Otherwise, we can't see the special debugger
2124                     # variables, or get to the debugger's subs. (Well, we
2125                     # _could_, but why make it even more complicated?)
2126                     eval "\$cmd =~ $alias{$i}";
2127                     if ($@) {
2128                         local $\ = '';
2129                         print $OUT "Couldn't evaluate '$i' alias: $@";
2130                         next CMD;
2131                     }
2132                 } ## end if ($alias{$i})
2133
2134 =head3 MAIN-LINE COMMANDS
2135
2136 All of these commands work up to and after the program being debugged has
2137 terminated.
2138
2139 =head4 C<q> - quit
2140
2141 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2142 try to execute further, cleaning any restart-related stuff out of the
2143 environment, and executing with the last value of C<$?>.
2144
2145 =cut
2146
2147                 if ($cmd eq 'q') {
2148                     $fall_off_end = 1;
2149                     clean_ENV();
2150                     exit $?;
2151                 }
2152
2153 =head4 C<t> - trace [n]
2154
2155 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2156 If level is specified, set C<$trace_to_depth>.
2157
2158 =cut
2159
2160                 $obj->_handle_t_command();
2161
2162 =head4 C<S> - list subroutines matching/not matching a pattern
2163
2164 Walks through C<%sub>, checking to see whether or not to print the name.
2165
2166 =cut
2167
2168                 if (my ($print_all_subs, $should_reverse, $Spatt)
2169                     = $cmd =~ /\AS(\s+(!)?(.+))?\z/) {
2170                     # $Spatt is the pattern (if any) to use.
2171                     # Reverse scan?
2172                     my $Srev     = defined $should_reverse;
2173                     # No args - print all subs.
2174                     my $Snocheck = !defined $print_all_subs;
2175
2176                     # Need to make these sane here.
2177                     local $\ = '';
2178                     local $, = '';
2179
2180                     # Search through the debugger's magical hash of subs.
2181                     # If $nocheck is true, just print the sub name.
2182                     # Otherwise, check it against the pattern. We then use
2183                     # the XOR trick to reverse the condition as required.
2184                     foreach $subname ( sort( keys %sub ) ) {
2185                         if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
2186                             print $OUT $subname, "\n";
2187                         }
2188                     }
2189                     next CMD;
2190                 }
2191
2192 =head4 C<X> - list variables in current package
2193
2194 Since the C<V> command actually processes this, just change this to the
2195 appropriate C<V> command and fall through.
2196
2197 =cut
2198
2199                 $cmd =~ s/^X\b/V $package/;
2200
2201 =head4 C<V> - list variables
2202
2203 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2204
2205 =cut
2206
2207                 # Bare V commands get the currently-being-debugged package
2208                 # added.
2209                 if ($cmd eq "V") {
2210                     $cmd = "V $package";
2211                 }
2212
2213                 # V - show variables in package.
2214                 if (my ($new_packname, $new_vars_str) =
2215                     $cmd =~ /\AV\b\s*(\S+)\s*(.*)/) {
2216
2217                     # Save the currently selected filehandle and
2218                     # force output to debugger's filehandle (dumpvar
2219                     # just does "print" for output).
2220                     my $savout = select($OUT);
2221
2222                     # Grab package name and variables to dump.
2223                     $packname = $new_packname;
2224                     my @vars     = split( ' ', $new_vars_str );
2225
2226                     # If main::dumpvar isn't here, get it.
2227                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2228                     if ( defined &main::dumpvar ) {
2229
2230                         # We got it. Turn off subroutine entry/exit messages
2231                         # for the moment, along with return values.
2232                         local $frame = 0;
2233                         local $doret = -2;
2234
2235                         # must detect sigpipe failures  - not catching
2236                         # then will cause the debugger to die.
2237                         eval {
2238                             &main::dumpvar(
2239                                 $packname,
2240                                 defined $option{dumpDepth}
2241                                 ? $option{dumpDepth}
2242                                 : -1,    # assume -1 unless specified
2243                                 @vars
2244                             );
2245                         };
2246
2247                         # The die doesn't need to include the $@, because
2248                         # it will automatically get propagated for us.
2249                         if ($@) {
2250                             die unless $@ =~ /dumpvar print failed/;
2251                         }
2252                     } ## end if (defined &main::dumpvar)
2253                     else {
2254
2255                         # Couldn't load dumpvar.
2256                         print $OUT "dumpvar.pl not available.\n";
2257                     }
2258
2259                     # Restore the output filehandle, and go round again.
2260                     select($savout);
2261                     next CMD;
2262                 }
2263
2264 =head4 C<x> - evaluate and print an expression
2265
2266 Hands the expression off to C<DB::eval>, setting it up to print the value
2267 via C<dumpvar.pl> instead of just printing it directly.
2268
2269 =cut
2270
2271                 if ($cmd =~ s#\Ax\b# #) {    # Remainder gets done by DB::eval()
2272                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2273
2274                     # handle special  "x 3 blah" syntax XXX propagate
2275                     # doc back to special variables.
2276                     if ( $cmd =~ s#\A\s*(\d+)(?=\s)# #) {
2277                         $onetimedumpDepth = $1;
2278                     }
2279                 }
2280
2281 =head4 C<m> - print methods
2282
2283 Just uses C<DB::methods> to determine what methods are available.
2284
2285 =cut
2286
2287                 if ($cmd =~ s#\Am\s+([\w:]+)\s*\z# #) {
2288                     methods($1);
2289                     next CMD;
2290                 }
2291
2292                 # m expr - set up DB::eval to do the work
2293                 if ($cmd =~ s#\Am\b# #) {    # Rest gets done by DB::eval()
2294                     $onetimeDump = 'methods';   #  method output gets used there
2295                 }
2296
2297 =head4 C<f> - switch files
2298
2299 =cut
2300
2301                 if (($file) = $cmd =~ /\Af\b\s*(.*)/) {
2302                     $file =~ s/\s+$//;
2303
2304                     # help for no arguments (old-style was return from sub).
2305                     if ( !$file ) {
2306                         print $OUT
2307                           "The old f command is now the r command.\n";    # hint
2308                         print $OUT "The new f command switches filenames.\n";
2309                         next CMD;
2310                     } ## end if (!$file)
2311
2312                     # if not in magic file list, try a close match.
2313                     if ( !defined $main::{ '_<' . $file } ) {
2314                         if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
2315                             {
2316                                 $try = substr( $try, 2 );
2317                                 print $OUT "Choosing $try matching '$file':\n";
2318                                 $file = $try;
2319                             }
2320                         } ## end if (($try) = grep(m#^_<.*$file#...
2321                     } ## end if (!defined $main::{ ...
2322
2323                     # If not successfully switched now, we failed.
2324                     if ( !defined $main::{ '_<' . $file } ) {
2325                         print $OUT "No file matching '$file' is loaded.\n";
2326                         next CMD;
2327                     }
2328
2329                     # We switched, so switch the debugger internals around.
2330                     elsif ( $file ne $filename ) {
2331                         *dbline   = $main::{ '_<' . $file };
2332                         $max      = $#dbline;
2333                         $filename = $file;
2334                         $start    = 1;
2335                         $cmd      = "l";
2336                     } ## end elsif ($file ne $filename)
2337
2338                     # We didn't switch; say we didn't.
2339                     else {
2340                         print $OUT "Already in $file.\n";
2341                         next CMD;
2342                     }
2343                 }
2344
2345 =head4 C<.> - return to last-executed line.
2346
2347 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2348 and then we look up the line in the magical C<%dbline> hash.
2349
2350 =cut
2351
2352                 # . command.
2353                 if ($cmd eq '.') {
2354                     $incr = -1;    # stay at current line
2355
2356                     # Reset everything to the old location.
2357                     $start    = $line;
2358                     $filename = $filename_ini;
2359                     *dbline   = $main::{ '_<' . $filename };
2360                     $max      = $#dbline;
2361
2362                     # Now where are we?
2363                     print_lineinfo($position);
2364                     next CMD;
2365                 }
2366
2367 =head4 C<-> - back one window
2368
2369 We change C<$start> to be one window back; if we go back past the first line,
2370 we set it to be the first line. We ser C<$incr> to put us back at the
2371 currently-executing line, and then put a C<l $start +> (list one window from
2372 C<$start>) in C<$cmd> to be executed later.
2373
2374 =cut
2375
2376                 # - - back a window.
2377                 if ($cmd eq '-') {
2378
2379                     # back up by a window; go to 1 if back too far.
2380                     $start -= $incr + $window + 1;
2381                     $start = 1 if $start <= 0;
2382                     $incr  = $window - 1;
2383
2384                     # Generate and execute a "l +" command (handled below).
2385                     $cmd = 'l ' . ($start) . '+';
2386                 }
2387
2388 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, E<0x7B>, E<0x7B>E<0x7B>>
2389
2390 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2391 problems, most notably that the default case of several commands destroying
2392 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2393 retain the old commands for those who were used to using them or who preferred
2394 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2395 deal with them instead of processing them in-line.
2396
2397 =cut
2398
2399                 # All of these commands were remapped in perl 5.8.0;
2400                 # we send them off to the secondary dispatcher (see below).
2401                 if (my ($cmd_letter, $my_arg) = $cmd =~ /\A([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so) {
2402                     &cmd_wrapper( $cmd_letter, $my_arg, $line );
2403                     next CMD;
2404                 }
2405
2406 =head4 C<y> - List lexicals in higher scope
2407
2408 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2409 above the current one and then displays then using C<dumpvar.pl>.
2410
2411 =cut
2412
2413                 if (my ($match_level, $match_vars)
2414                     = $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/) {
2415
2416                     # See if we've got the necessary support.
2417                     eval { require PadWalker; PadWalker->VERSION(0.08) }
2418                       or &warn(
2419                         $@ =~ /locate/
2420                         ? "PadWalker module not found - please install\n"
2421                         : $@
2422                       )
2423                       and next CMD;
2424
2425                     # Load up dumpvar if we don't have it. If we can, that is.
2426                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2427                     defined &main::dumpvar
2428                       or print $OUT "dumpvar.pl not available.\n"
2429                       and next CMD;
2430
2431                     # Got all the modules we need. Find them and print them.
2432                     my @vars = split( ' ', $match_vars || '' );
2433
2434                     # Find the pad.
2435                     my $h = eval { PadWalker::peek_my( ( $match_level || 0 ) + 1 ) };
2436
2437                     # Oops. Can't find it.
2438                     $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
2439
2440                     # Show the desired vars with dumplex().
2441                     my $savout = select($OUT);
2442
2443                     # Have dumplex dump the lexicals.
2444                     dumpvar::dumplex( $_, $h->{$_},
2445                         defined $option{dumpDepth} ? $option{dumpDepth} : -1,
2446                         @vars )
2447                       for sort keys %$h;
2448                     select($savout);
2449                     next CMD;
2450                 }
2451
2452 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2453
2454 All of the commands below this point don't work after the program being
2455 debugged has ended. All of them check to see if the program has ended; this
2456 allows the commands to be relocated without worrying about a 'line of
2457 demarcation' above which commands can be entered anytime, and below which
2458 they can't.
2459
2460 =head4 C<n> - single step, but don't trace down into subs
2461
2462 Done by setting C<$single> to 2, which forces subs to execute straight through
2463 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2464 so a null command knows what to re-execute.
2465
2466 =cut
2467
2468                 # n - next
2469                 if ($cmd eq 'n') {
2470                     next CMD if _DB__is_finished();
2471
2472                     # Single step, but don't enter subs.
2473                     $single = 2;
2474
2475                     # Save for empty command (repeat last).
2476                     $laststep = $cmd;
2477                     last CMD;
2478                 }
2479
2480 =head4 C<s> - single-step, entering subs
2481
2482 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2483 subs. Also saves C<s> as C<$lastcmd>.
2484
2485 =cut
2486
2487                 # s - single step.
2488                 if ($cmd eq 's') {
2489
2490                     # Get out and restart the command loop if program
2491                     # has finished.
2492                     next CMD if _DB__is_finished();
2493
2494                     # Single step should enter subs.
2495                     $single = 1;
2496
2497                     # Save for empty command (repeat last).
2498                     $laststep = $cmd;
2499                     last CMD;
2500                 }
2501
2502 =head4 C<c> - run continuously, setting an optional breakpoint
2503
2504 Most of the code for this command is taken up with locating the optional
2505 breakpoint, which is either a subroutine name or a line number. We set
2506 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2507 in this and all call levels above this one.
2508
2509 =cut
2510
2511                 # c - start continuous execution.
2512                 if (($i) = $cmd =~ m#\Ac\b\s*([\w:]*)\s*\z#) {
2513
2514                     # Hey, show's over. The debugged program finished
2515                     # executing already.
2516                     next CMD if _DB__is_finished();
2517
2518                     # Capture the place to put a one-time break.
2519                     $subname = $i;
2520
2521                     #  Probably not needed, since we finish an interactive
2522                     #  sub-session anyway...
2523                     # local $filename = $filename;
2524                     # local *dbline = *dbline; # XXX Would this work?!
2525                     #
2526                     # The above question wonders if localizing the alias
2527                     # to the magic array works or not. Since it's commented
2528                     # out, we'll just leave that to speculation for now.
2529
2530                     # If the "subname" isn't all digits, we'll assume it
2531                     # is a subroutine name, and try to find it.
2532                     if ( $subname =~ /\D/ ) {    # subroutine name
2533                             # Qualify it to the current package unless it's
2534                             # already qualified.
2535                         $subname = $package . "::" . $subname
2536                           unless $subname =~ /::/;
2537
2538                         # find_sub will return "file:line_number" corresponding
2539                         # to where the subroutine is defined; we call find_sub,
2540                         # break up the return value, and assign it in one
2541                         # operation.
2542                         ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2543
2544                         # Force the line number to be numeric.
2545                         $i += 0;
2546
2547                         # If we got a line number, we found the sub.
2548                         if ($i) {
2549
2550                             # Switch all the debugger's internals around so
2551                             # we're actually working with that file.
2552                             $filename = $file;
2553                             *dbline   = $main::{ '_<' . $filename };
2554
2555                             # Mark that there's a breakpoint in this file.
2556                             $had_breakpoints{$filename} |= 1;
2557
2558                             # Scan forward to the first executable line
2559                             # after the 'sub whatever' line.
2560                             $max = $#dbline;
2561                             ++$i while $dbline[$i] == 0 && $i < $max;
2562                         } ## end if ($i)
2563
2564                         # We didn't find a sub by that name.
2565                         else {
2566                             print $OUT "Subroutine $subname not found.\n";
2567                             next CMD;
2568                         }
2569                     } ## end if ($subname =~ /\D/)
2570
2571                     # At this point, either the subname was all digits (an
2572                     # absolute line-break request) or we've scanned through
2573                     # the code following the definition of the sub, looking
2574                     # for an executable, which we may or may not have found.
2575                     #
2576                     # If $i (which we set $subname from) is non-zero, we
2577                     # got a request to break at some line somewhere. On
2578                     # one hand, if there wasn't any real subroutine name
2579                     # involved, this will be a request to break in the current
2580                     # file at the specified line, so we have to check to make
2581                     # sure that the line specified really is breakable.
2582                     #
2583                     # On the other hand, if there was a subname supplied, the
2584                     # preceding block has moved us to the proper file and
2585                     # location within that file, and then scanned forward
2586                     # looking for the next executable line. We have to make
2587                     # sure that one was found.
2588                     #
2589                     # On the gripping hand, we can't do anything unless the
2590                     # current value of $i points to a valid breakable line.
2591                     # Check that.
2592                     if ($i) {
2593
2594                         # Breakable?
2595                         if ( $dbline[$i] == 0 ) {
2596                             print $OUT "Line $i not breakable.\n";
2597                             next CMD;
2598                         }
2599
2600                         # Yes. Set up the one-time-break sigil.
2601                         $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2602                         _enable_breakpoint_temp_enabled_status($filename, $i);
2603                     } ## end if ($i)
2604
2605                     # Turn off stack tracing from here up.
2606                     for my $i (0 .. $stack_depth) {
2607                         $stack[ $i ] &= ~1;
2608                     }
2609                     last CMD;
2610                 }
2611
2612 =head4 C<r> - return from a subroutine
2613
2614 For C<r> to work properly, the debugger has to stop execution again
2615 immediately after the return is executed. This is done by forcing
2616 single-stepping to be on in the call level above the current one. If
2617 we are printing return values when a C<r> is executed, set C<$doret>
2618 appropriately, and force us out of the command loop.
2619
2620 =cut
2621
2622                 # r - return from the current subroutine.
2623                 if ($cmd eq 'r') {
2624
2625                     # Can't do anything if the program's over.
2626                     next CMD if _DB__is_finished();
2627
2628                     # Turn on stack trace.
2629                     $stack[$stack_depth] |= 1;
2630
2631                     # Print return value unless the stack is empty.
2632                     $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
2633                     last CMD;
2634                 }
2635
2636 =head4 C<T> - stack trace
2637
2638 Just calls C<DB::print_trace>.
2639
2640 =cut
2641
2642                 if ($cmd eq 'T') {
2643                     print_trace( $OUT, 1 );    # skip DB
2644                     next CMD;
2645                 }
2646
2647 =head4 C<w> - List window around current line.
2648
2649 Just calls C<DB::cmd_w>.
2650
2651 =cut
2652
2653                 if (my ($arg) = $cmd =~ /\Aw\b\s*(.*)/s) {
2654                     &cmd_w( 'w', $arg );
2655                     next CMD;
2656                 }
2657
2658 =head4 C<W> - watch-expression processing.
2659
2660 Just calls C<DB::cmd_W>.
2661
2662 =cut
2663
2664                 if (my ($arg) = $cmd =~ /\AW\b\s*(.*)/s) {
2665                     &cmd_W( 'W', $arg );
2666                     next CMD;
2667                 }
2668
2669 =head4 C</> - search forward for a string in the source
2670
2671 We take the argument and treat it as a pattern. If it turns out to be a
2672 bad one, we return the error we got from trying to C<eval> it and exit.
2673 If not, we create some code to do the search and C<eval> it so it can't
2674 mess us up.
2675
2676 =cut
2677
2678                 # The pattern as a string.
2679                 use vars qw($inpat);
2680
2681                 if (($inpat) = $cmd =~ m#\A/(.*)\z#) {
2682
2683                     # Remove the final slash.
2684                     $inpat =~ s:([^\\])/$:$1:;
2685
2686                     # If the pattern isn't null ...
2687                     if ( $inpat ne "" ) {
2688
2689                         # Turn of warn and die procesing for a bit.
2690                         local $SIG{__DIE__};
2691                         local $SIG{__WARN__};
2692
2693                         # Create the pattern.
2694                         eval 'no strict q/vars/; $inpat =~ m' . "\a$inpat\a";
2695                         if ( $@ ne "" ) {
2696
2697                             # Oops. Bad pattern. No biscuit.
2698                             # Print the eval error and go back for more
2699                             # commands.
2700                             print $OUT "$@";
2701                             next CMD;
2702                         }
2703                         $pat = $inpat;
2704                     } ## end if ($inpat ne "")
2705
2706                     # Set up to stop on wrap-around.
2707                     $end = $start;
2708
2709                     # Don't move off the current line.
2710                     $incr = -1;
2711
2712                     # Done in eval so nothing breaks if the pattern
2713                     # does something weird.
2714                     eval '
2715                         no strict q/vars/;
2716                         for (;;) {
2717                             # Move ahead one line.
2718                             ++$start;
2719
2720                             # Wrap if we pass the last line.
2721                             $start = 1 if ($start > $max);
2722
2723                             # Stop if we have gotten back to this line again,
2724                             last if ($start == $end);
2725
2726                             # A hit! (Note, though, that we are doing
2727                             # case-insensitive matching. Maybe a qr//
2728                             # expression would be better, so the user could
2729                             # do case-sensitive matching if desired.
2730                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2731                                 if ($slave_editor) {
2732                                     # Handle proper escaping in the slave.
2733                                     print $OUT "\032\032$filename:$start:0\n";
2734                                 }
2735                                 else {
2736                                     # Just print the line normally.
2737                                     print $OUT "$start:\t",$dbline[$start],"\n";
2738                                 }
2739                                 # And quit since we found something.
2740                                 last;
2741                             }
2742                          } ';
2743
2744                     # If we wrapped, there never was a match.
2745                     print $OUT "/$pat/: not found\n" if ( $start == $end );
2746                     next CMD;
2747                 }
2748
2749 =head4 C<?> - search backward for a string in the source
2750
2751 Same as for C</>, except the loop runs backwards.
2752
2753 =cut
2754
2755                 # ? - backward pattern search.
2756                 if (my ($inpat) = $cmd =~ m#\A\?(.*)\z#) {
2757
2758                     # Get the pattern, remove trailing question mark.
2759                     $inpat =~ s:([^\\])\?$:$1:;
2760
2761                     # If we've got one ...
2762                     if ( $inpat ne "" ) {
2763
2764                         # Turn off die & warn handlers.
2765                         local $SIG{__DIE__};
2766                         local $SIG{__WARN__};
2767                         eval '$inpat =~ m' . "\a$inpat\a";
2768
2769                         if ( $@ ne "" ) {
2770
2771                             # Ouch. Not good. Print the error.
2772                             print $OUT $@;
2773                             next CMD;
2774                         }
2775                         $pat = $inpat;
2776                     } ## end if ($inpat ne "")
2777
2778                     # Where we are now is where to stop after wraparound.
2779                     $end = $start;
2780
2781                     # Don't move away from this line.
2782                     $incr = -1;
2783
2784                     # Search inside the eval to prevent pattern badness
2785                     # from killing us.
2786                     eval '
2787                         no strict q/vars/;
2788                         for (;;) {
2789                             # Back up a line.
2790                             --$start;
2791
2792                             # Wrap if we pass the first line.
2793
2794                             $start = $max if ($start <= 0);
2795
2796                             # Quit if we get back where we started,
2797                             last if ($start == $end);
2798
2799                             # Match?
2800                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2801                                 if ($slave_editor) {
2802                                     # Yep, follow slave editor requirements.
2803                                     print $OUT "\032\032$filename:$start:0\n";
2804                                 }
2805                                 else {
2806                                     # Yep, just print normally.
2807                                     print $OUT "$start:\t",$dbline[$start],"\n";
2808                                 }
2809
2810                                 # Found, so done.
2811                                 last;
2812                             }
2813                         } ';
2814
2815                     # Say we failed if the loop never found anything,
2816                     print $OUT "?$pat?: not found\n" if ( $start == $end );
2817                     next CMD;
2818                 }
2819
2820 =head4 C<$rc> - Recall command
2821
2822 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2823 that the terminal supports history). It find the the command required, puts it
2824 into C<$cmd>, and redoes the loop to execute it.
2825
2826 =cut
2827
2828                 # $rc - recall command.
2829                 if (my ($minus, $arg) = $cmd =~ m#\A$rc+\s*(-)?(\d+)?\z#) {
2830
2831                     # No arguments, take one thing off history.
2832                     pop(@hist) if length($cmd) > 1;
2833
2834                     # Relative (- found)?
2835                     #  Y - index back from most recent (by 1 if bare minus)
2836                     #  N - go to that particular command slot or the last
2837                     #      thing if nothing following.
2838                     $i = $minus ? ( $#hist - ( $arg || 1 ) ) : ( $arg || $#hist );
2839
2840                     # Pick out the command desired.
2841                     $cmd = $hist[$i];
2842
2843                     # Print the command to be executed and restart the loop
2844                     # with that command in the buffer.
2845                     print $OUT $cmd, "\n";
2846                     redo CMD;
2847                 }
2848
2849 =head4 C<$sh$sh> - C<system()> command
2850
2851 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
2852 C<STDOUT> from getting messed up.
2853
2854 =cut
2855
2856                 # $sh$sh - run a shell command (if it's all ASCII).
2857                 # Can't run shell commands with Unicode in the debugger, hmm.
2858                 if (my ($arg) = $cmd =~ m#\A$sh$sh\s*(.*)#ms) {
2859
2860                     # System it.
2861                     &system($arg);
2862                     next CMD;
2863                 }
2864
2865 =head4 C<$rc I<pattern> $rc> - Search command history
2866
2867 Another command to manipulate C<@hist>: this one searches it with a pattern.
2868 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
2869
2870 =cut
2871
2872                 # $rc pattern $rc - find a command in the history.
2873                 if (my ($arg) = $cmd =~ /\A$rc([^$rc].*)\z/) {
2874
2875                     # Create the pattern to use.
2876                     $pat = "^$arg";
2877
2878                     # Toss off last entry if length is >1 (and it always is).
2879                     pop(@hist) if length($cmd) > 1;
2880
2881                     # Look backward through the history.
2882                     for ( $i = $#hist ; $i ; --$i ) {
2883                         # Stop if we find it.
2884                         last if $hist[$i] =~ /$pat/;
2885                     }
2886
2887                     if ( !$i ) {
2888
2889                         # Never found it.
2890                         print $OUT "No such command!\n\n";
2891                         next CMD;
2892                     }
2893
2894                     # Found it. Put it in the buffer, print it, and process it.
2895                     $cmd = $hist[$i];
2896                     print $OUT $cmd, "\n";
2897                     redo CMD;
2898                 }
2899
2900 =head4 C<$sh> - Invoke a shell
2901
2902 Uses C<DB::system> to invoke a shell.
2903
2904 =cut
2905
2906                 # $sh - start a shell.
2907                 if ($cmd =~ /\A$sh\z/) {
2908
2909                     # Run the user's shell. If none defined, run Bourne.
2910                     # We resume execution when the shell terminates.
2911                     &system( $ENV{SHELL} || "/bin/sh" );
2912                     next CMD;
2913                 }
2914
2915 =head4 C<$sh I<command>> - Force execution of a command in a shell
2916
2917 Like the above, but the command is passed to the shell. Again, we use
2918 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
2919
2920 =cut
2921
2922                 # $sh command - start a shell and run a command in it.
2923                 if (my ($arg) = $cmd =~ m#\A$sh\s*(.*)#ms) {
2924
2925                     # XXX: using csh or tcsh destroys sigint retvals!
2926                     #&system($1);  # use this instead
2927
2928                     # use the user's shell, or Bourne if none defined.
2929                     &system( $ENV{SHELL} || "/bin/sh", "-c", $arg );
2930                     next CMD;
2931                 }
2932
2933 =head4 C<H> - display commands in history
2934
2935 Prints the contents of C<@hist> (if any).
2936
2937 =cut
2938
2939                 if ($cmd =~ /\AH\b\s*\*/) {
2940                     @hist = @truehist = ();
2941                     print $OUT "History cleansed\n";
2942                     next CMD;
2943                 }
2944
2945                 if (my ($num)
2946                     = $cmd =~ /\AH\b\s*(?:-(\d+))?/) {
2947
2948                     # Anything other than negative numbers is ignored by
2949                     # the (incorrect) pattern, so this test does nothing.
2950                     $end = $num ? ( $#hist - $num ) : 0;
2951
2952                     # Set to the minimum if less than zero.
2953                     $hist = 0 if $hist < 0;
2954
2955                     # Start at the end of the array.
2956                     # Stay in while we're still above the ending value.
2957                     # Tick back by one each time around the loop.
2958                     for ( $i = $#hist ; $i > $end ; $i-- ) {
2959
2960                         # Print the command  unless it has no arguments.
2961                         print $OUT "$i: ", $hist[$i], "\n"
2962                           unless $hist[$i] =~ /^.?$/;
2963                     }
2964                     next CMD;
2965                 }
2966
2967 =head4 C<man, doc, perldoc> - look up documentation
2968
2969 Just calls C<runman()> to print the appropriate document.
2970
2971 =cut
2972
2973                 # man, perldoc, doc - show manual pages.
2974                 if (my ($man_page)
2975                     = $cmd =~ /\A(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?\z/) {
2976                     runman($man_page);
2977                     next CMD;
2978                 }
2979
2980 =head4 C<p> - print
2981
2982 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
2983 the bottom of the loop.
2984
2985 =cut
2986
2987                 my $print_cmd = 'print {$DB::OUT} ';
2988                 # p - print (no args): print $_.
2989                 if ($cmd eq 'p') {
2990                     $cmd = $print_cmd . '$_';
2991                 }
2992
2993                 # p - print the given expression.
2994                 $cmd =~ s/\Ap\b/$print_cmd /;
2995
2996 =head4 C<=> - define command alias
2997
2998 Manipulates C<%alias> to add or list command aliases.
2999
3000 =cut
3001
3002                 # = - set up a command alias.
3003                 if ($cmd =~ s/\A=\s*//) {
3004                     my @keys;
3005                     if ( length $cmd == 0 ) {
3006
3007                         # No args, get current aliases.
3008                         @keys = sort keys %alias;
3009                     }
3010                     elsif ( my ( $k, $v ) = ( $cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3011
3012                         # Creating a new alias. $k is alias name, $v is
3013                         # alias value.
3014
3015                         # can't use $_ or kill //g state
3016                         for my $x ( $k, $v ) {
3017
3018                             # Escape "alarm" characters.
3019                             $x =~ s/\a/\\a/g;
3020                         }
3021
3022                         # Substitute key for value, using alarm chars
3023                         # as separators (which is why we escaped them in
3024                         # the command).
3025                         $alias{$k} = "s\a$k\a$v\a";
3026
3027                         # Turn off standard warn and die behavior.
3028                         local $SIG{__DIE__};
3029                         local $SIG{__WARN__};
3030
3031                         # Is it valid Perl?
3032                         unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3033
3034                             # Nope. Bad alias. Say so and get out.
3035                             print $OUT "Can't alias $k to $v: $@\n";
3036                             delete $alias{$k};
3037                             next CMD;
3038                         }
3039
3040                         # We'll only list the new one.
3041                         @keys = ($k);
3042                     } ## end elsif (my ($k, $v) = ($cmd...
3043
3044                     # The argument is the alias to list.
3045                     else {
3046                         @keys = ($cmd);
3047                     }
3048
3049                     # List aliases.
3050                     for my $k (@keys) {
3051
3052                         # Messy metaquoting: Trim the substitution code off.
3053                         # We use control-G as the delimiter because it's not
3054                         # likely to appear in the alias.
3055                         if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3056
3057                             # Print the alias.
3058                             print $OUT "$k\t= $1\n";
3059                         }
3060                         elsif ( defined $alias{$k} ) {
3061
3062                             # Couldn't trim it off; just print the alias code.
3063                             print $OUT "$k\t$alias{$k}\n";
3064                         }
3065                         else {
3066
3067                             # No such, dude.
3068                             print "No alias for $k\n";
3069                         }
3070                     } ## end for my $k (@keys)
3071                     next CMD;
3072                 }
3073
3074 =head4 C<source> - read commands from a file.
3075
3076 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3077 pick it up.
3078
3079 =cut
3080
3081                 # source - read commands from a file (or pipe!) and execute.
3082                 if (my ($sourced_fn) = $cmd =~ /\Asource\s+(.*\S)/) {
3083                     if ( open my $fh, $sourced_fn ) {
3084
3085                         # Opened OK; stick it in the list of file handles.
3086                         push @cmdfhs, $fh;
3087                     }
3088                     else {
3089
3090                         # Couldn't open it.
3091                         &warn("Can't execute '$sourced_fn': $!\n");
3092                     }
3093                     next CMD;
3094                 }
3095
3096                 if (my ($which_cmd, $position)
3097                     = $cmd =~ /^(enable|disable)\s+(\S+)\s*$/) {
3098
3099                     my ($fn, $line_num);
3100                     if ($position =~ m{\A\d+\z})
3101                     {
3102                         $fn = $filename;
3103                         $line_num = $position;
3104                     }
3105                     elsif (my ($new_fn, $new_line_num)
3106                         = $position =~ m{\A(.*):(\d+)\z}) {
3107                         ($fn, $line_num) = ($new_fn, $new_line_num);
3108                     }
3109                     else
3110                     {
3111                         &warn("Wrong spec for enable/disable argument.\n");
3112                     }
3113
3114                     if (defined($fn)) {
3115                         if (_has_breakpoint_data_ref($fn, $line_num)) {
3116                             _set_breakpoint_enabled_status($fn, $line_num,
3117                                 ($which_cmd eq 'enable' ? 1 : '')
3118                             );
3119                         }
3120                         else {
3121                             &warn("No breakpoint set at ${fn}:${line_num}\n");
3122                         }
3123                     }
3124
3125                     next CMD;
3126                 }
3127
3128 =head4 C<save> - send current history to a file
3129
3130 Takes the complete history, (not the shrunken version you see with C<H>),
3131 and saves it to the given filename, so it can be replayed using C<source>.
3132
3133 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3134
3135 =cut
3136
3137                 # save source - write commands to a file for later use
3138                 if (my ($new_fn) = $cmd =~ /\Asave\s*(.*)\z/) {
3139                     my $filename = $new_fn || '.perl5dbrc';    # default?
3140                     if ( open my $fh, '>', $filename ) {
3141
3142                        # chomp to remove extraneous newlines from source'd files
3143                         chomp( my @truelist =
3144                               map { m/^\s*(save|source)/ ? "#$_" : $_ }
3145                               @truehist );
3146                         print $fh join( "\n", @truelist );
3147                         print "commands saved in $file\n";
3148                     }
3149                     else {
3150                         &warn("Can't save debugger commands in '$new_fn': $!\n");
3151                     }
3152                     next CMD;
3153                 }
3154
3155 =head4 C<R> - restart
3156
3157 Restart the debugger session.
3158
3159 =head4 C<rerun> - rerun the current session
3160
3161 Return to any given position in the B<true>-history list
3162
3163 =cut
3164
3165                 # R - restart execution.
3166                 # rerun - controlled restart execution.
3167                 if (my ($cmd_cmd, $cmd_params) =
3168                     $cmd =~ /\A((?:R)|(?:rerun\s*(.*)))\z/) {
3169                     my @args = ($cmd_cmd eq 'R' ? restart() : rerun($cmd_params));
3170
3171                     # Close all non-system fds for a clean restart.  A more
3172                     # correct method would be to close all fds that were not
3173                     # open when the process started, but this seems to be
3174                     # hard.  See "debugger 'R'estart and open database
3175                     # connections" on p5p.
3176
3177                     my $max_fd = 1024; # default if POSIX can't be loaded
3178                     if (eval { require POSIX }) {
3179                         eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
3180                     }
3181
3182                     if (defined $max_fd) {
3183                         foreach ($^F+1 .. $max_fd-1) {
3184                             next unless open FD_TO_CLOSE, "<&=$_";
3185                             close(FD_TO_CLOSE);
3186                         }
3187                     }
3188
3189                     # And run Perl again.  We use exec() to keep the
3190                     # PID stable (and that way $ini_pids is still valid).
3191                     exec(@args) || print $OUT "exec failed: $!\n";
3192
3193                     last CMD;
3194                 }
3195
3196 =head4 C<|, ||> - pipe output through the pager.
3197
3198 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3199 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3200 pipe to the pager (restoring the output filehandles if this fails). If this
3201 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3202 set C<$signal>, sending us back into the debugger.
3203
3204 We then trim off the pipe symbols and C<redo> the command loop at the
3205 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3206 reading another.
3207
3208 =cut
3209
3210                 # || - run command in the pager, with output to DB::OUT.
3211                 if ($cmd =~ m#\A\|\|?\s*[^|]#) {
3212                     if ( $pager =~ /^\|/ ) {
3213
3214                         # Default pager is into a pipe. Redirect I/O.
3215                         open( SAVEOUT, ">&STDOUT" )
3216                           || &warn("Can't save STDOUT");
3217                         open( STDOUT, ">&OUT" )
3218                           || &warn("Can't redirect STDOUT");
3219                     } ## end if ($pager =~ /^\|/)
3220                     else {
3221
3222                         # Not into a pipe. STDOUT is safe.
3223                         open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
3224                     }
3225
3226                     # Fix up environment to record we have less if so.
3227                     fix_less();
3228
3229                     unless ( $piped = open( OUT, $pager ) ) {
3230
3231                         # Couldn't open pipe to pager.
3232                         &warn("Can't pipe output to '$pager'");
3233                         if ( $pager =~ /^\|/ ) {
3234
3235                             # Redirect I/O back again.
3236                             open( OUT, ">&STDOUT" )    # XXX: lost message
3237                               || &warn("Can't restore DB::OUT");
3238                             open( STDOUT, ">&SAVEOUT" )
3239                               || &warn("Can't restore STDOUT");
3240                             close(SAVEOUT);
3241                         } ## end if ($pager =~ /^\|/)
3242                         else {
3243
3244                             # Redirect I/O. STDOUT already safe.
3245                             open( OUT, ">&STDOUT" )    # XXX: lost message
3246                               || &warn("Can't restore DB::OUT");
3247                         }
3248                         next CMD;
3249                     } ## end unless ($piped = open(OUT,...
3250
3251                     # Set up broken-pipe handler if necessary.
3252                     $SIG{PIPE} = \&DB::catch
3253                       if $pager =~ /^\|/
3254                       && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
3255
3256                     OUT->autoflush(1);
3257                     # Save current filehandle, and put it back.
3258                     $selected = select(OUT);
3259                     # Don't put it back if pager was a pipe.
3260                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
3261
3262                     # Trim off the pipe symbols and run the command now.
3263                     $cmd =~ s#\A\|+\s*##;
3264                     redo PIPE;
3265                 }
3266
3267 =head3 END OF COMMAND PARSING
3268
3269 Anything left in C<$cmd> at this point is a Perl expression that we want to
3270 evaluate. We'll always evaluate in the user's context, and fully qualify
3271 any variables we might want to address in the C<DB> package.
3272
3273 =cut
3274
3275                 # t - turn trace on.
3276                 if ($cmd =~ s#\At\s+(\d+)?#\$DB::trace |= 1;\n#) {
3277                     my $trace_arg = $1;
3278                     $trace_to_depth = $trace_arg ? $stack_depth||0 + $1 : 1E9;
3279                 }
3280
3281                 # s - single-step. Remember the last command was 's'.
3282                 if ($cmd =~ s/\As\s/\$DB::single = 1;\n/) {
3283                     $laststep = 's';
3284                 }
3285
3286                 # n - single-step, but not into subs. Remember last command
3287                 # was 'n'.
3288                 if ($cmd =~ s#\An\s#\$DB::single = 2;\n#) {
3289                     $laststep = 'n';
3290                 }
3291
3292             }    # PIPE:
3293
3294             # Make sure the flag that says "the debugger's running" is
3295             # still on, to make sure we get control again.
3296             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3297
3298             # Run *our* eval that executes in the caller's context.
3299             DB::eval();
3300
3301             # Turn off the one-time-dump stuff now.
3302             if ($onetimeDump) {
3303                 $onetimeDump      = undef;
3304                 $onetimedumpDepth = undef;
3305             }
3306             elsif ( $term_pid == $$ ) {
3307                 eval { # May run under miniperl, when not available...
3308                     STDOUT->flush();
3309                     STDERR->flush();
3310                 };
3311
3312                 # XXX If this is the master pid, print a newline.
3313                 print {$OUT} "\n";
3314             }
3315         } ## end while (($term || &setterm...
3316
3317 =head3 POST-COMMAND PROCESSING
3318
3319 After each command, we check to see if the command output was piped anywhere.
3320 If so, we go through the necessary code to unhook the pipe and go back to
3321 our standard filehandles for input and output.
3322
3323 =cut
3324
3325         continue {    # CMD:
3326
3327             # At the end of every command:
3328             if ($piped) {
3329
3330                 # Unhook the pipe mechanism now.
3331                 if ( $pager =~ /^\|/ ) {
3332
3333                     # No error from the child.
3334                     $? = 0;
3335
3336                     # we cannot warn here: the handle is missing --tchrist
3337                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3338
3339                     # most of the $? crud was coping with broken cshisms
3340                     # $? is explicitly set to 0, so this never runs.
3341                     if ($?) {
3342                         print SAVEOUT "Pager '$pager' failed: ";
3343                         if ( $? == -1 ) {
3344                             print SAVEOUT "shell returned -1\n";
3345                         }
3346                         elsif ( $? >> 8 ) {
3347                             print SAVEOUT ( $? & 127 )
3348                               ? " (SIG#" . ( $? & 127 ) . ")"
3349                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3350                         }
3351                         else {
3352                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3353                         }
3354                     } ## end if ($?)
3355
3356                     # Reopen filehandle for our output (if we can) and
3357                     # restore STDOUT (if we can).
3358                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3359                     open( STDOUT, ">&SAVEOUT" )
3360                       || &warn("Can't restore STDOUT");
3361
3362                     # Turn off pipe exception handler if necessary.
3363                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3364
3365                     # Will stop ignoring SIGPIPE if done like nohup(1)
3366                     # does SIGINT but Perl doesn't give us a choice.
3367                 } ## end if ($pager =~ /^\|/)
3368                 else {
3369
3370                     # Non-piped "pager". Just restore STDOUT.
3371                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3372                 }
3373
3374                 # Close filehandle pager was using, restore the normal one
3375                 # if necessary,
3376                 close(SAVEOUT);
3377                 select($selected), $selected = "" unless $selected eq "";
3378
3379                 # No pipes now.
3380                 $piped = "";
3381             } ## end if ($piped)
3382         }    # CMD:
3383
3384 =head3 COMMAND LOOP TERMINATION
3385
3386 When commands have finished executing, we come here. If the user closed the
3387 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3388 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3389 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3390 The interpreter will then execute the next line and then return control to us
3391 again.
3392
3393 =cut
3394
3395         # No more commands? Quit.
3396         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3397
3398         # Evaluate post-prompt commands.
3399         foreach $evalarg (@$post) {
3400             DB::eval();
3401         }
3402     }    # if ($single || $signal)
3403
3404     # Put the user's globals back where you found them.
3405     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3406     ();
3407 } ## end sub DB
3408
3409 package DB::Obj;
3410
3411 sub new {
3412     my $class = shift;
3413
3414     my $self = bless {}, $class;
3415
3416     $self->_init(@_);
3417
3418     return $self;
3419 }
3420
3421 sub _init {
3422     my ($self, $args) = @_;
3423
3424     %{$self} = (%$self, %$args);
3425
3426     return;
3427 }
3428
3429 {
3430     no strict 'refs';
3431     foreach my $slot_name (qw(after explicit_stop infix position prefix)) {
3432         my $slot = $slot_name;
3433         *{$slot} = sub {
3434             my $self = shift;
3435
3436             if (@_) {
3437                 ${ $self->{$slot} } = shift;
3438             }
3439
3440             return ${ $self->{$slot} };
3441         };
3442
3443         *{"append_to_$slot"} = sub {
3444             my $self = shift;
3445             my $s = shift;
3446
3447             return $self->$slot($self->$slot . $s);
3448         };
3449     }
3450 }
3451
3452 sub _DB_on_init__initialize_globals
3453 {
3454     my $self = shift;
3455
3456     # Check for whether we should be running continuously or not.
3457     # _After_ the perl program is compiled, $single is set to 1:
3458     if ( $DB::single and not $DB::second_time++ ) {
3459
3460         # Options say run non-stop. Run until we get an interrupt.
3461         if ($DB::runnonstop) {    # Disable until signal
3462                 # If there's any call stack in place, turn off single
3463                 # stepping into subs throughout the stack.
3464             for my $i (0 .. $DB::stack_depth) {
3465                 $DB::stack[ $i ] &= ~1;
3466             }
3467
3468             # And we are now no longer in single-step mode.
3469             $DB::single = 0;
3470
3471             # If we simply returned at this point, we wouldn't get
3472             # the trace info. Fall on through.
3473             # return;
3474         } ## end if ($runnonstop)
3475
3476         elsif ($DB::ImmediateStop) {
3477
3478             # We are supposed to stop here; XXX probably a break.
3479             $DB::ImmediateStop = 0;    # We've processed it; turn it off
3480             $DB::signal        = 1;    # Simulate an interrupt to force
3481                                    # us into the command loop
3482         }
3483     } ## end if ($single and not $second_time...
3484
3485     # If we're in single-step mode, or an interrupt (real or fake)
3486     # has occurred, turn off non-stop mode.
3487     $DB::runnonstop = 0 if $DB::single or $DB::signal;
3488
3489     return;
3490 }
3491
3492 sub _DB__handle_watch_expressions
3493 {
3494     my $self = shift;
3495
3496     if ( $DB::trace & 2 ) {
3497         for my $n (0 .. $#DB::to_watch) {
3498             $DB::evalarg = $DB::to_watch[$n];
3499             local $DB::onetimeDump;    # Tell DB::eval() to not output results
3500
3501             # Fix context DB::eval() wants to return an array, but
3502             # we need a scalar here.
3503             my ($val) = join( "', '", DB::eval() );
3504             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
3505
3506             # Did it change?
3507             if ( $val ne $DB::old_watch[$n] ) {
3508
3509                 # Yep! Show the difference, and fake an interrupt.
3510                 $DB::signal = 1;
3511                 print {$DB::OUT} <<EOP;
3512 Watchpoint $n:\t$DB::to_watch[$n] changed:
3513     old value:\t$DB::old_watch[$n]
3514     new value:\t$val
3515 EOP
3516                 $DB::old_watch[$n] = $val;
3517             } ## end if ($val ne $old_watch...
3518         } ## end for my $n (0 ..
3519     } ## end if ($trace & 2)
3520
3521     return;
3522 }
3523
3524 sub _my_print_lineinfo
3525 {
3526     my ($self, $i, $incr_pos) = @_;
3527
3528     if ($DB::frame) {
3529         # Print it indented if tracing is on.
3530         DB::print_lineinfo( ' ' x $DB::stack_depth,
3531             "$i:\t$DB::dbline[$i]" . $self->after );
3532     }
3533     else {
3534         DB::depth_print_lineinfo($self->explicit_stop, $incr_pos);
3535     }
3536 }
3537
3538 sub _curr_line {
3539     return $DB::dbline[$DB::line];
3540 }
3541
3542 sub _DB__grab_control
3543 {
3544     my $self = shift;
3545
3546     # Yes, grab control.
3547     if ($DB::slave_editor) {
3548
3549         # Tell the editor to update its position.
3550         $self->position("\032\032${DB::filename}:${DB::line}:0\n");
3551         DB::print_lineinfo($self->position());
3552     }
3553
3554 =pod
3555
3556 Special check: if we're in package C<DB::fake>, we've gone through the
3557 C<END> block at least once. We set up everything so that we can continue
3558 to enter commands and have a valid context to be in.
3559
3560 =cut
3561
3562     elsif ( $DB::package eq 'DB::fake' ) {
3563
3564         # Fallen off the end already.
3565         if (!$DB::term) {
3566             DB::setterm();
3567         }
3568
3569         DB::print_help(<<EOP);
3570 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
3571 use B<o> I<inhibit_exit> to avoid stopping after program termination,
3572 B<h q>, B<h R> or B<h o> to get additional info.
3573 EOP
3574
3575         # Set the DB::eval context appropriately.
3576         $DB::package     = 'main';
3577         $DB::usercontext = DB::_calc_usercontext($DB::package);
3578     } ## end elsif ($package eq 'DB::fake')
3579
3580 =pod
3581
3582 If the program hasn't finished executing, we scan forward to the
3583 next executable line, print that out, build the prompt from the file and line
3584 number information, and print that.
3585
3586 =cut
3587
3588     else {
3589
3590
3591         # Still somewhere in the midst of execution. Set up the
3592         #  debugger prompt.
3593         $DB::sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
3594                              # Perl 5 ones (sorry, we don't print Klingon
3595                              #module names)
3596
3597         $self->prefix($DB::sub =~ /::/ ? "" : ($DB::package . '::'));
3598         $self->append_to_prefix( "$DB::sub(${DB::filename}:" );
3599         $self->after( $self->_curr_line =~ /\n$/ ? '' : "\n" );
3600
3601         # Break up the prompt if it's really long.
3602         if ( length($self->prefix()) > 30 ) {
3603             $self->position($self->prefix . "$DB::line):\n$DB::line:\t" . $self->_curr_line . $self->after);
3604             $self->prefix("");
3605             $self->infix(":\t");
3606         }
3607         else {
3608             $self->infix("):\t");
3609             $self->position(
3610                 $self->prefix . $DB::line. $self->infix
3611                 . $self->_curr_line . $self->after
3612             );
3613         }
3614
3615         # Print current line info, indenting if necessary.
3616         $self->_my_print_lineinfo($DB::line, $self->position);
3617
3618         my $i;
3619         my $line_i = sub { return $DB::dbline[$i]; };
3620
3621         # Scan forward, stopping at either the end or the next
3622         # unbreakable line.
3623         for ( $i = $DB::line + 1 ; $i <= $DB::max && $line_i->() == 0 ; ++$i )
3624         {    #{ vi
3625
3626             # Drop out on null statements, block closers, and comments.
3627             last if $line_i->() =~ /^\s*[\;\}\#\n]/;
3628
3629             # Drop out if the user interrupted us.
3630             last if $DB::signal;
3631
3632             # Append a newline if the line doesn't have one. Can happen
3633             # in eval'ed text, for instance.
3634             $self->after( $line_i->() =~ /\n$/ ? '' : "\n" );
3635
3636             # Next executable line.
3637             my $incr_pos = $self->prefix . $i . $self->infix . $line_i->()
3638                 . $self->after;
3639             $self->append_to_position($incr_pos);
3640             $self->_my_print_lineinfo($i, $incr_pos);
3641         } ## end for ($i = $line + 1 ; $i...
3642     } ## end else [ if ($slave_editor)
3643
3644     return;
3645 }
3646
3647 sub _handle_t_command {
3648     if (my ($levels) = $DB::cmd =~ /\At(?:\s+(\d+))?\z/) {
3649         $DB::trace ^= 1;
3650         local $\ = '';
3651         $DB::trace_to_depth = $levels ? $DB::stack_depth + $levels : 1E9;
3652         print {$DB::OUT} "Trace = "
3653         . ( ( $DB::trace & 1 )
3654             ? ( $levels ? "on (to level $DB::trace_to_depth)" : "on" )
3655             : "off" ) . "\n";
3656         next CMD;
3657     }
3658
3659     return;
3660 }
3661
3662 package DB;
3663
3664 # The following code may be executed now:
3665 # BEGIN {warn 4}
3666
3667 =head2 sub
3668
3669 C<sub> is called whenever a subroutine call happens in the program being
3670 debugged. The variable C<$DB::sub> contains the name of the subroutine
3671 being called.
3672
3673 The core function of this subroutine is to actually call the sub in the proper
3674 context, capturing its output. This of course causes C<DB::DB> to get called
3675 again, repeating until the subroutine ends and returns control to C<DB::sub>
3676 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3677 return value, and returns its captured copy of the return value as its own
3678 return value. The value then feeds back into the program being debugged as if
3679 C<DB::sub> hadn't been there at all.
3680
3681 C<sub> does all the work of printing the subroutine entry and exit messages
3682 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3683 and also prints the return value if needed (for the C<r> command and if
3684 the 16 bit is set in C<$frame>).
3685
3686 It also tracks the subroutine call depth by saving the current setting of
3687 C<$single> in the C<@stack> package global; if this exceeds the value in
3688 C<$deep>, C<sub> automatically turns on printing of the current depth by
3689 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3690 of stop/don't stop on entry to subs set as it currently is set.
3691
3692 =head3 C<caller()> support
3693
3694 If C<caller()> is called from the package C<DB>, it provides some
3695 additional data, in the following order:
3696
3697 =over 4
3698
3699 =item * C<$package>
3700
3701 The package name the sub was in
3702
3703 =item * C<$filename>
3704
3705 The filename it was defined in
3706
3707 =item * C<$line>
3708
3709 The line number it was defined on
3710
3711 =item * C<$subroutine>
3712
3713 The subroutine name; C<(eval)> if an C<eval>().
3714
3715 =item * C<$hasargs>
3716
3717 1 if it has arguments, 0 if not
3718
3719 =item * C<$wantarray>
3720
3721 1 if array context, 0 if scalar context
3722
3723 =item * C<$evaltext>
3724
3725 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3726
3727 =item * C<$is_require>
3728
3729 frame was created by a C<use> or C<require> statement
3730
3731 =item * C<$hints>
3732
3733 pragma information; subject to change between versions
3734
3735 =item * C<$bitmask>
3736
3737 pragma information; subject to change between versions
3738
3739 =item * C<@DB::args>
3740
3741 arguments with which the subroutine was invoked
3742
3743 =back
3744
3745 =cut
3746
3747 use vars qw($deep);
3748
3749 # We need to fully qualify the name ("DB::sub") to make "use strict;"
3750 # happy. -- Shlomi Fish
3751 sub DB::sub {
3752     # Do not use a regex in this subroutine -> results in corrupted memory
3753     # See: [perl #66110]
3754
3755     # lock ourselves under threads
3756     lock($DBGR);
3757
3758     # Whether or not the autoloader was running, a scalar to put the
3759     # sub's return value in (if needed), and an array to put the sub's
3760     # return value in (if needed).
3761     my ( $al, $ret, @ret ) = "";
3762     if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
3763         print "creating new thread\n";
3764     }
3765
3766     # If the last ten characters are '::AUTOLOAD', note we've traced
3767     # into AUTOLOAD for $sub.
3768     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3769         no strict 'refs';
3770         $al = " for $$sub" if defined $$sub;
3771     }
3772
3773     # We stack the stack pointer and then increment it to protect us
3774     # from a situation that might unwind a whole bunch of call frames
3775     # at once. Localizing the stack pointer means that it will automatically
3776     # unwind the same amount when multiple stack frames are unwound.
3777     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3778
3779     # Expand @stack.
3780     $#stack = $stack_depth;
3781
3782     # Save current single-step setting.
3783     $stack[-1] = $single;
3784
3785     # Turn off all flags except single-stepping.
3786     $single &= 1;
3787
3788     # If we've gotten really deeply recursed, turn on the flag that will
3789     # make us stop with the 'deep recursion' message.
3790     $single |= 4 if $stack_depth == $deep;
3791
3792     # If frame messages are on ...
3793     (
3794         $frame & 4    # Extended frame entry message
3795         ? (
3796             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3797
3798             # Why -1? But it works! :-(
3799             # Because print_trace will call add 1 to it and then call
3800             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3801             # in dump_trace.
3802             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3803           )
3804         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3805
3806           # standard frame entry message
3807       )
3808       if $frame;
3809
3810     # Determine the sub's return type, and capture appropriately.
3811     if (wantarray) {
3812
3813         # Called in array context. call sub and capture output.
3814         # DB::DB will recursively get control again if appropriate; we'll come
3815         # back here when the sub is finished.
3816         {
3817             no strict 'refs';
3818             @ret = &$sub;
3819         }
3820
3821         # Pop the single-step value back off the stack.
3822         $single |= $stack[ $stack_depth-- ];
3823
3824         # Check for exit trace messages...
3825         (
3826             $frame & 4    # Extended exit message
3827             ? (
3828                 print_lineinfo( ' ' x $stack_depth, "out " ),
3829                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3830               )
3831             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3832
3833               # Standard exit message
3834           )
3835           if $frame & 2;
3836
3837         # Print the return info if we need to.
3838         if ( $doret eq $stack_depth or $frame & 16 ) {
3839
3840             # Turn off output record separator.
3841             local $\ = '';
3842             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3843
3844             # Indent if we're printing because of $frame tracing.
3845             print $fh ' ' x $stack_depth if $frame & 16;
3846
3847             # Print the return value.
3848             print $fh "list context return from $sub:\n";
3849             dumpit( $fh, \@ret );
3850
3851             # And don't print it again.
3852             $doret = -2;
3853         } ## end if ($doret eq $stack_depth...
3854             # And we have to return the return value now.
3855         @ret;
3856     } ## end if (wantarray)
3857
3858     # Scalar context.
3859     else {
3860         if ( defined wantarray ) {
3861             no strict 'refs';
3862             # Save the value if it's wanted at all.
3863             $ret = &$sub;
3864         }
3865         else {
3866             no strict 'refs';
3867             # Void return, explicitly.
3868             &$sub;
3869             undef $ret;
3870         }
3871
3872         # Pop the single-step value off the stack.
3873         $single |= $stack[ $stack_depth-- ];
3874
3875         # If we're doing exit messages...
3876         (
3877             $frame & 4    # Extended messages
3878             ? (
3879                 print_lineinfo( ' ' x $stack_depth, "out " ),
3880                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3881               )
3882             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3883
3884               # Standard messages
3885           )
3886           if $frame & 2;
3887
3888         # If we are supposed to show the return value... same as before.
3889         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
3890             local $\ = '';
3891             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3892             print $fh ( ' ' x $stack_depth ) if $frame & 16;
3893             print $fh (
3894                 defined wantarray
3895                 ? "scalar context return from $sub: "
3896                 : "void context return from $sub\n"
3897             );
3898             dumpit( $fh, $ret ) if defined wantarray;
3899             $doret = -2;
3900         } ## end if ($doret eq $stack_depth...
3901
3902         # Return the appropriate scalar value.
3903         $ret;
3904     } ## end else [ if (wantarray)
3905 } ## end sub _sub
3906
3907 sub lsub : lvalue {
3908
3909     no strict 'refs';
3910
3911     # lock ourselves under threads
3912     lock($DBGR);
3913
3914     # Whether or not the autoloader was running, a scalar to put the
3915     # sub's return value in (if needed), and an array to put the sub's
3916     # return value in (if needed).
3917     my ( $al, $ret, @ret ) = "";
3918     if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
3919         print "creating new thread\n";
3920     }
3921
3922     # If the last ten characters are C'::AUTOLOAD', note we've traced
3923     # into AUTOLOAD for $sub.
3924     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3925         $al = " for $$sub";
3926     }
3927
3928     # We stack the stack pointer and then increment it to protect us
3929     # from a situation that might unwind a whole bunch of call frames
3930     # at once. Localizing the stack pointer means that it will automatically
3931     # unwind the same amount when multiple stack frames are unwound.
3932     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3933
3934     # Expand @stack.
3935     $#stack = $stack_depth;
3936
3937     # Save current single-step setting.
3938     $stack[-1] = $single;
3939
3940     # Turn off all flags except single-stepping.
3941     $single &= 1;
3942
3943     # If we've gotten really deeply recursed, turn on the flag that will
3944     # make us stop with the 'deep recursion' message.
3945     $single |= 4 if $stack_depth == $deep;
3946
3947     # If frame messages are on ...
3948     (
3949         $frame & 4    # Extended frame entry message
3950         ? (
3951             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3952
3953             # Why -1? But it works! :-(
3954             # Because print_trace will call add 1 to it and then call
3955             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3956             # in dump_trace.
3957             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3958           )
3959         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3960
3961           # standard frame entry message
3962       )
3963       if $frame;
3964
3965     # Pop the single-step value back off the stack.
3966     $single |= $stack[ $stack_depth-- ];
3967
3968     # call the original lvalue sub.
3969     &$sub;
3970 }
3971
3972 # Abstracting common code from multiple places elsewhere:
3973 sub depth_print_lineinfo {
3974     my $always_print = shift;
3975
3976     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
3977 }
3978
3979 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
3980
3981 In Perl 5.8.0, there was a major realignment of the commands and what they did,
3982 Most of the changes were to systematize the command structure and to eliminate
3983 commands that threw away user input without checking.
3984
3985 The following sections describe the code added to make it easy to support
3986 multiple command sets with conflicting command names. This section is a start
3987 at unifying all command processing to make it simpler to develop commands.
3988
3989 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
3990 number, and C<$dbline> (the current line) as arguments.
3991
3992 Support functions in this section which have multiple modes of failure C<die>
3993 on error; the rest simply return a false value.
3994
3995 The user-interface functions (all of the C<cmd_*> functions) just output
3996 error messages.
3997
3998 =head2 C<%set>
3999
4000 The C<%set> hash defines the mapping from command letter to subroutine
4001 name suffix.
4002
4003 C<%set> is a two-level hash, indexed by set name and then by command name.
4004 Note that trying to set the CommandSet to C<foobar> simply results in the
4005 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
4006
4007 =cut
4008
4009 ### The API section
4010
4011 my %set = (    #
4012     'pre580' => {
4013         'a' => 'pre580_a',
4014         'A' => 'pre580_null',
4015         'b' => 'pre580_b',
4016         'B' => 'pre580_null',
4017         'd' => 'pre580_null',
4018         'D' => 'pre580_D',
4019         'h' => 'pre580_h',
4020         'M' => 'pre580_null',
4021         'O' => 'o',
4022         'o' => 'pre580_null',
4023         'v' => 'M',
4024         'w' => 'v',
4025         'W' => 'pre580_W',
4026     },
4027     'pre590' => {
4028         '<'  => 'pre590_prepost',
4029         '<<' => 'pre590_prepost',
4030         '>'  => 'pre590_prepost',
4031         '>>' => 'pre590_prepost',
4032         '{'  => 'pre590_prepost',
4033         '{{' => 'pre590_prepost',
4034     },
4035 );
4036
4037 my %breakpoints_data;
4038
4039 sub _has_breakpoint_data_ref {
4040     my ($filename, $line) = @_;
4041
4042     return (
4043         exists( $breakpoints_data{$filename} )
4044             and
4045         exists( $breakpoints_data{$filename}{$line} )
4046     );
4047 }
4048
4049 sub _get_breakpoint_data_ref {
4050     my ($filename, $line) = @_;
4051
4052     return ($breakpoints_data{$filename}{$line} ||= +{});
4053 }
4054
4055 sub _delete_breakpoint_data_ref {
4056     my ($filename, $line) = @_;
4057
4058     delete($breakpoints_data{$filename}{$line});
4059     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
4060         delete($breakpoints_data{$filename});
4061     }
4062
4063     return;
4064 }
4065
4066 sub _set_breakpoint_enabled_status {
4067     my ($filename, $line, $status) = @_;
4068
4069     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
4070         ($status ? 1 : '')
4071         ;
4072
4073     return;
4074 }
4075
4076 sub _enable_breakpoint_temp_enabled_status {
4077     my ($filename, $line) = @_;
4078
4079     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
4080
4081     return;
4082 }
4083
4084 sub _cancel_breakpoint_temp_enabled_status {
4085     my ($filename, $line) = @_;
4086
4087     my $ref = _get_breakpoint_data_ref($filename, $line);
4088
4089     delete ($ref->{'temp_enabled'});
4090
4091     if (! %$ref) {
4092         _delete_breakpoint_data_ref($filename, $line);
4093     }
4094
4095     return;
4096 }
4097
4098 sub _is_breakpoint_enabled {
4099     my ($filename, $line) = @_;
4100
4101     my $data_ref = _get_breakpoint_data_ref($filename, $line);
4102     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
4103 }
4104
4105 =head2 C<cmd_wrapper()> (API)
4106
4107 C<cmd_wrapper()> allows the debugger to switch command sets
4108 depending on the value of the C<CommandSet> option.
4109
4110 It tries to look up the command in the C<%set> package-level I<lexical>
4111 (which means external entities can't fiddle with it) and create the name of
4112 the sub to call based on the value found in the hash (if it's there). I<All>
4113 of the commands to be handled in a set have to be added to C<%set>; if they
4114 aren't found, the 5.8.0 equivalent is called (if there is one).
4115
4116 This code uses symbolic references.
4117
4118 =cut
4119
4120 sub cmd_wrapper {
4121     my $cmd      = shift;
4122     my $line     = shift;
4123     my $dblineno = shift;
4124
4125     # Assemble the command subroutine's name by looking up the
4126     # command set and command name in %set. If we can't find it,
4127     # default to the older version of the command.
4128     my $call = 'cmd_'
4129       . ( $set{$CommandSet}{$cmd}
4130           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
4131
4132     # Call the command subroutine, call it by name.
4133     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
4134 } ## end sub cmd_wrapper
4135
4136 =head3 C<cmd_a> (command)
4137
4138 The C<a> command handles pre-execution actions. These are associated with a
4139 particular line, so they're stored in C<%dbline>. We default to the current
4140 line if none is specified.
4141
4142 =cut
4143
4144 sub cmd_a {
4145     my $cmd    = shift;
4146     my $line   = shift || '';    # [.|line] expr
4147     my $dbline = shift;
4148
4149     # If it's dot (here), or not all digits,  use the current line.
4150     $line =~ s/^(\.|(?:[^\d]))/$dbline/;
4151
4152     # Should be a line number followed by an expression.
4153     if ( $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
4154         my ( $lineno, $expr ) = ( $1, $2 );
4155
4156         # If we have an expression ...
4157         if ( length $expr ) {
4158
4159             # ... but the line isn't breakable, complain.
4160             if ( $dbline[$lineno] == 0 ) {
4161                 print $OUT
4162                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
4163             }
4164             else {
4165
4166                 # It's executable. Record that the line has an action.
4167                 $had_breakpoints{$filename} |= 2;
4168
4169                 # Remove any action, temp breakpoint, etc.
4170                 $dbline{$lineno} =~ s/\0[^\0]*//;
4171
4172                 # Add the action to the line.
4173                 $dbline{$lineno} .= "\0" . action($expr);
4174
4175                 _set_breakpoint_enabled_status($filename, $lineno, 1);
4176             }
4177         } ## end if (length $expr)
4178     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4179     else {
4180
4181         # Syntax wrong.
4182         print $OUT
4183           "Adding an action requires an optional lineno and an expression\n"
4184           ;    # hint
4185     }
4186 } ## end sub cmd_a
4187
4188 =head3 C<cmd_A> (command)
4189
4190 Delete actions. Similar to above, except the delete code is in a separate
4191 subroutine, C<delete_action>.
4192
4193 =cut
4194
4195 sub cmd_A {
4196     my $cmd    = shift;
4197     my $line   = shift || '';
4198     my $dbline = shift;
4199
4200     # Dot is this line.
4201     $line =~ s/^\./$dbline/;
4202
4203     # Call delete_action with a null param to delete them all.
4204     # The '1' forces the eval to be true. It'll be false only
4205     # if delete_action blows up for some reason, in which case
4206     # we print $@ and get out.
4207     if ( $line eq '*' ) {
4208         if (! eval { _delete_all_actions(); 1 }) {
4209             print {$OUT} $@;
4210             return;
4211         }
4212     }
4213
4214     # There's a real line  number. Pass it to delete_action.
4215     # Error trapping is as above.
4216     elsif ( $line =~ /^(\S.*)/ ) {
4217         if (! eval { delete_action($1); 1 }) {
4218             print {$OUT} $@;
4219             return;
4220         }
4221     }
4222
4223     # Swing and a miss. Bad syntax.
4224     else {
4225         print $OUT
4226           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4227     }
4228 } ## end sub cmd_A
4229
4230 =head3 C<delete_action> (API)
4231
4232 C<delete_action> accepts either a line number or C<undef>. If a line number
4233 is specified, we check for the line being executable (if it's not, it
4234 couldn't have had an  action). If it is, we just take the action off (this
4235 will get any kind of an action, including breakpoints).
4236
4237 =cut
4238
4239 sub _remove_action_from_dbline {
4240     my $i = shift;
4241
4242     $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4243     delete $dbline{$i} if $dbline{$i} eq '';
4244
4245     return;
4246 }
4247
4248 sub _delete_all_actions {
4249     print {$OUT} "Deleting all actions...\n";
4250
4251     for my $file ( keys %had_breakpoints ) {
4252         local *dbline = $main::{ '_<' . $file };
4253         $max = $#dbline;
4254         my $was;
4255         for my $i (1 .. $max) {
4256             if ( defined $dbline{$i} ) {
4257                 _remove_action_from_dbline($i);
4258             }
4259         }
4260
4261         unless ( $had_breakpoints{$file} &= ~2 ) {
4262             delete $had_breakpoints{$file};
4263         }
4264     }
4265
4266     return;
4267 }
4268
4269 sub delete_action {
4270     my $i = shift;
4271
4272     if ( defined($i) ) {
4273         # Can there be one?
4274         die "Line $i has no action .\n" if $dbline[$i] == 0;
4275
4276         # Nuke whatever's there.
4277         _remove_action_from_dbline($i);
4278     }
4279     else {
4280         _delete_all_actions();
4281     }
4282 }
4283
4284 =head3 C<cmd_b> (command)
4285
4286 Set breakpoints. Since breakpoints can be set in so many places, in so many
4287 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4288 we try to parse the command type, and then shuttle it off to an appropriate
4289 subroutine to actually do the work of setting the breakpoint in the right
4290 place.
4291
4292 =cut
4293
4294 sub cmd_b {
4295     my $cmd    = shift;
4296     my $line   = shift;    # [.|line] [cond]
4297     my $dbline = shift;
4298
4299     my $default_cond = sub {
4300         my $cond = shift;
4301         return length($cond) ? $cond : '1';
4302     };
4303
4304     # Make . the current line number if it's there..
4305     $line =~ s/^\.(\s|\z)/$dbline$1/;
4306
4307     # No line number, no condition. Simple break on current line.
4308     if ( $line =~ /^\s*$/ ) {
4309         cmd_b_line( $dbline, 1 );
4310     }
4311
4312     # Break on load for a file.
4313     elsif ( my ($file) = $line =~ /^load\b\s*(.*)/ ) {
4314         $file =~ s/\s+\z//;
4315         cmd_b_load($file);
4316     }
4317
4318     # b compile|postpone <some sub> [<condition>]
4319     # The interpreter actually traps this one for us; we just put the
4320     # necessary condition in the %postponed hash.
4321     elsif ( my ($action, $subname, $cond)
4322         = $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4323
4324         # De-Perl4-ify the name - ' separators to ::.
4325         $subname =~ s/'/::/g;
4326
4327         # Qualify it into the current package unless it's already qualified.
4328         $subname = "${package}::" . $subname unless $subname =~ /::/;
4329
4330         # Add main if it starts with ::.
4331         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4332
4333         # Save the break type for this sub.
4334         $postponed{$subname} = (($action eq 'postpone')
4335             ? ( "break +0 if " . $default_cond->($cond) )
4336             : "compile");
4337     } ## end elsif ($line =~ ...
4338     # b <filename>:<line> [<condition>]
4339     elsif (my ($filename, $line_num, $cond)
4340         = $line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4341         cmd_b_filename_line(
4342             $filename,
4343             $line_num,
4344             (length($cond) ? $cond : '1'),
4345         );
4346     }
4347     # b <sub name> [<condition>]
4348     elsif ( my ($new_subname, $new_cond) =
4349         $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4350
4351         #
4352         $subname = $new_subname;
4353         cmd_b_sub( $subname, $default_cond->($new_cond) );
4354     }
4355
4356     # b <line> [<condition>].
4357     elsif ( my ($line_n, $cond) = $line =~ /^(\d*)\s*(.*)/ ) {
4358
4359         # Capture the line. If none, it's the current line.
4360         $line = $line_n || $dbline;
4361
4362         # Break on line.
4363         cmd_b_line( $line, $default_cond->($cond) );
4364     }
4365
4366     # Line didn't make sense.
4367     else {
4368         print "confused by line($line)?\n";
4369     }
4370
4371     return;
4372 } ## end sub cmd_b
4373
4374 =head3 C<break_on_load> (API)
4375
4376 We want to break when this file is loaded. Mark this file in the
4377 C<%break_on_load> hash, and note that it has a breakpoint in
4378 C<%had_breakpoints>.
4379
4380 =cut
4381
4382 sub break_on_load {
4383     my $file = shift;
4384     $break_on_load{$file} = 1;
4385     $had_breakpoints{$file} |= 1;
4386 }
4387
4388 =head3 C<report_break_on_load> (API)
4389
4390 Gives us an array of filenames that are set to break on load. Note that
4391 only files with break-on-load are in here, so simply showing the keys
4392 suffices.
4393
4394 =cut
4395
4396 sub report_break_on_load {
4397     sort keys %break_on_load;
4398 }
4399
4400 =head3 C<cmd_b_load> (command)
4401
4402 We take the file passed in and try to find it in C<%INC> (which maps modules
4403 to files they came from). We mark those files for break-on-load via
4404 C<break_on_load> and then report that it was done.
4405
4406 =cut
4407
4408 sub cmd_b_load {
4409     my $file = shift;
4410     my @files;
4411
4412     # This is a block because that way we can use a redo inside it
4413     # even without there being any looping structure at all outside it.
4414     {
4415
4416         # Save short name and full path if found.
4417         push @files, $file;
4418         push @files, $::INC{$file} if $::INC{$file};
4419
4420         # Tack on .pm and do it again unless there was a '.' in the name
4421         # already.
4422         $file .= '.pm', redo unless $file =~ /\./;
4423     }
4424
4425     # Do the real work here.
4426     break_on_load($_) for @files;
4427
4428     # All the files that have break-on-load breakpoints.
4429     @files = report_break_on_load;
4430
4431     # Normalize for the purposes of our printing this.
4432     local $\ = '';
4433     local $" = ' ';
4434     print $OUT "Will stop on load of '@files'.\n";
4435 } ## end sub cmd_b_load
4436
4437 =head3 C<$filename_error> (API package global)
4438
4439 Several of the functions we need to implement in the API need to work both
4440 on the current file and on other files. We don't want to duplicate code, so
4441 C<$filename_error> is used to contain the name of the file that's being
4442 worked on (if it's not the current one).
4443
4444 We can now build functions in pairs: the basic function works on the current
4445 file, and uses C<$filename_error> as part of its error message. Since this is
4446 initialized to C<"">, no filename will appear when we are working on the
4447 current file.
4448
4449 The second function is a wrapper which does the following:
4450
4451 =over 4
4452
4453 =item *
4454
4455 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4456
4457 =item *
4458
4459 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4460
4461 =item *
4462
4463 Calls the first function.
4464
4465 The first function works on the I<current> file (i.e., the one we changed to),
4466 and prints C<$filename_error> in the error message (the name of the other file)
4467 if it needs to. When the functions return, C<*dbline> is restored to point
4468 to the actual current file (the one we're executing in) and
4469 C<$filename_error> is restored to C<"">. This restores everything to
4470 the way it was before the second function was called at all.
4471
4472 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4473 details.
4474
4475 =back
4476
4477 =cut
4478
4479 use vars qw($filename_error);
4480 $filename_error = '';
4481
4482 =head3 breakable_line(from, to) (API)
4483
4484 The subroutine decides whether or not a line in the current file is breakable.
4485 It walks through C<@dbline> within the range of lines specified, looking for
4486 the first line that is breakable.
4487
4488 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4489 first line I<after> C<$to> that's breakable, if there is one.
4490
4491 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4492 first line I<before> C<$to> that's breakable, if there is one.
4493
4494 =cut
4495
4496 sub breakable_line {
4497
4498     my ( $from, $to ) = @_;
4499
4500     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4501     my $i = $from;
4502
4503     # If there are at least 2 arguments, we're trying to search a range.
4504     if ( @_ >= 2 ) {
4505
4506         # $delta is positive for a forward search, negative for a backward one.
4507         my $delta = $from < $to ? +1 : -1;
4508
4509         # Keep us from running off the ends of the file.
4510         my $limit = $delta > 0 ? $#dbline : 1;
4511
4512         # Clever test. If you're a mathematician, it's obvious why this
4513         # test works. If not:
4514         # If $delta is positive (going forward), $limit will be $#dbline.
4515         #    If $to is less than $limit, ($limit - $to) will be positive, times
4516         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4517         #    as the stopping point.
4518         #
4519         #    If $to is greater than $limit, ($limit - $to) is negative,
4520         #    times $delta of 1 (positive), so the result is < 0 and we should
4521         #    use $limit ($#dbline) as the stopping point.
4522         #
4523         # If $delta is negative (going backward), $limit will be 1.
4524         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4525         #    (negative) so the result is > 0, and we use $to as the stopping
4526         #    point.
4527         #
4528         #    If $to is less than zero, ($limit - $to) will be positive,
4529         #    times $delta of -1 (negative), so the result is not > 0, and
4530         #    we use $limit (1) as the stopping point.
4531         #
4532         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4533         #    (negative), still giving zero; the result is not > 0, and
4534         #    we use $limit (1) as the stopping point.
4535         #
4536         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4537         #    (negative), giving a positive (>0) value, so we'll set $limit to
4538         #    $to.
4539
4540         $limit = $to if ( $limit - $to ) * $delta > 0;
4541
4542         # The real search loop.
4543         # $i starts at $from (the point we want to start searching from).
4544         # We move through @dbline in the appropriate direction (determined
4545         # by $delta: either -1 (back) or +1 (ahead).
4546         # We stay in as long as we haven't hit an executable line
4547         # ($dbline[$i] == 0 means not executable) and we haven't reached
4548         # the limit yet (test similar to the above).
4549         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4550
4551     } ## end if (@_ >= 2)
4552
4553     # If $i points to a line that is executable, return that.
4554     return $i unless $dbline[$i] == 0;
4555
4556     # Format the message and print it: no breakable lines in range.
4557     my ( $pl, $upto ) = ( '', '' );
4558     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4559
4560     # If there's a filename in filename_error, we'll see it.
4561     # If not, not.
4562     die "Line$pl $from$upto$filename_error not breakable\n";
4563 } ## end sub breakable_line
4564
4565 =head3 breakable_line_in_filename(file, from, to) (API)
4566
4567 Like C<breakable_line>, but look in another file.
4568
4569 =cut
4570
4571 sub breakable_line_in_filename {
4572
4573     # Capture the file name.
4574     my ($f) = shift;
4575
4576     # Swap the magic line array over there temporarily.
4577     local *dbline = $main::{ '_<' . $f };
4578
4579     # If there's an error, it's in this other file.
4580     local $filename_error = " of '$f'";
4581
4582     # Find the breakable line.
4583     breakable_line(@_);
4584
4585     # *dbline and $filename_error get restored when this block ends.
4586
4587 } ## end sub breakable_line_in_filename
4588
4589 =head3 break_on_line(lineno, [condition]) (API)
4590
4591 Adds a breakpoint with the specified condition (or 1 if no condition was
4592 specified) to the specified line. Dies if it can't.
4593
4594 =cut
4595
4596 sub break_on_line {
4597     my $i = shift;
4598     my $cond = @_ ? shift(@_) : 1;
4599
4600     my $inii  = $i;
4601     my $after = '';
4602     my $pl    = '';
4603
4604     # Woops, not a breakable line. $filename_error allows us to say
4605     # if it was in a different file.
4606     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4607
4608     # Mark this file as having breakpoints in it.
4609     $had_breakpoints{$filename} |= 1;
4610
4611     # If there is an action or condition here already ...
4612     if ( $dbline{$i} ) {
4613
4614         # ... swap this condition for the existing one.
4615         $dbline{$i} =~ s/^[^\0]*/$cond/;
4616     }
4617     else {
4618
4619         # Nothing here - just add the condition.
4620         $dbline{$i} = $cond;
4621
4622         _set_breakpoint_enabled_status($filename, $i, 1);
4623     }
4624
4625     return;
4626 } ## end sub break_on_line
4627
4628 =head3 cmd_b_line(line, [condition]) (command)
4629
4630 Wrapper for C<break_on_line>. Prints the failure message if it
4631 doesn't work.
4632
4633 =cut
4634
4635 sub cmd_b_line {
4636     if (not eval { break_on_line(@_); 1 }) {
4637         local $\ = '';
4638         print $OUT $@ and return;
4639     }
4640
4641     return;
4642 } ## end sub cmd_b_line
4643
4644 =head3 cmd_b_filename_line(line, [condition]) (command)
4645
4646 Wrapper for C<break_on_filename_line>. Prints the failure message if it
4647 doesn't work.
4648
4649 =cut
4650
4651 sub cmd_b_filename_line {
4652     if (not eval { break_on_filename_line(@_); 1 }) {
4653         local $\ = '';
4654         print $OUT $@ and return;
4655     }
4656
4657     return;
4658 }
4659
4660 =head3 break_on_filename_line(file, line, [condition]) (API)
4661
4662 Switches to the file specified and then calls C<break_on_line> to set
4663 the breakpoint.
4664
4665 =cut
4666
4667 sub break_on_filename_line {
4668     my $f = shift;
4669     my $i = shift;
4670     my $cond = @_ ? shift(@_) : 1;
4671
4672     # Switch the magical hash temporarily.
4673     local *dbline = $main::{ '_<' . $f };
4674
4675     # Localize the variables that break_on_line uses to make its message.
4676     local $filename_error = " of '$f'";
4677     local $filename       = $f;
4678
4679     # Add the breakpoint.
4680     break_on_line( $i, $cond );
4681
4682     return;
4683 } ## end sub break_on_filename_line
4684
4685 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
4686
4687 Switch to another file, search the range of lines specified for an
4688 executable one, and put a breakpoint on the first one you find.
4689
4690 =cut
4691
4692 sub break_on_filename_line_range {
4693     my $f = shift;
4694     my $from = shift;
4695     my $to = shift;
4696     my $cond = @_ ? shift(@_) : 1;
4697
4698     # Find a breakable line if there is one.
4699     my $i = breakable_line_in_filename( $f, $from, $to );
4700
4701     # Add the breakpoint.
4702     break_on_filename_line( $f, $i, $cond );
4703
4704     return;
4705 } ## end sub break_on_filename_line_range
4706
4707 =head3 subroutine_filename_lines(subname, [condition]) (API)
4708
4709 Search for a subroutine within a given file. The condition is ignored.
4710 Uses C<find_sub> to locate the desired subroutine.
4711
4712 =cut
4713
4714 sub subroutine_filename_lines {
4715     my ( $subname ) = @_;
4716
4717     # Returned value from find_sub() is fullpathname:startline-endline.
4718     # The match creates the list (fullpathname, start, end).
4719     return (find_sub($subname) =~ /^(.*):(\d+)-(\d+)$/);
4720 } ## end sub subroutine_filename_lines
4721
4722 =head3 break_subroutine(subname) (API)
4723
4724 Places a break on the first line possible in the specified subroutine. Uses
4725 C<subroutine_filename_lines> to find the subroutine, and
4726 C<break_on_filename_line_range> to place the break.
4727
4728 =cut
4729
4730 sub break_subroutine {
4731     my $subname = shift;
4732
4733     # Get filename, start, and end.
4734     my ( $file, $s, $e ) = subroutine_filename_lines($subname)
4735       or die "Subroutine $subname not found.\n";
4736
4737
4738     # Null condition changes to '1' (always true).
4739     my $cond = @_ ? shift(@_) : 1;
4740
4741     # Put a break the first place possible in the range of lines
4742     # that make up this subroutine.
4743     break_on_filename_line_range( $file, $s, $e, $cond );
4744
4745     return;
4746 } ## end sub break_subroutine
4747
4748 =head3 cmd_b_sub(subname, [condition]) (command)
4749
4750 We take the incoming subroutine name and fully-qualify it as best we can.
4751
4752 =over 4
4753
4754 =item 1. If it's already fully-qualified, leave it alone.
4755
4756 =item 2. Try putting it in the current package.
4757
4758 =item 3. If it's not there, try putting it in CORE::GLOBAL if it exists there.
4759
4760 =item 4. If it starts with '::', put it in 'main::'.
4761
4762 =back
4763
4764 After all this cleanup, we call C<break_subroutine> to try to set the
4765 breakpoint.
4766
4767 =cut
4768
4769 sub cmd_b_sub {
4770     my ( $subname, $cond ) = @_;
4771
4772     # Add always-true condition if we have none.
4773     $cond = 1 unless @_ >= 2;
4774
4775     # If the subname isn't a code reference, qualify it so that
4776     # break_subroutine() will work right.
4777     unless ( ref $subname eq 'CODE' ) {
4778
4779         # Not Perl4.
4780         $subname =~ s/\'/::/g;
4781         my $s = $subname;
4782
4783         # Put it in this package unless it's already qualified.
4784         $subname = "${package}::" . $subname
4785           unless $subname =~ /::/;
4786
4787         # Requalify it into CORE::GLOBAL if qualifying it into this
4788         # package resulted in its not being defined, but only do so
4789         # if it really is in CORE::GLOBAL.
4790         $subname = "CORE::GLOBAL::$s"
4791           if not defined &$subname
4792           and $s !~ /::/
4793           and defined &{"CORE::GLOBAL::$s"};
4794
4795         # Put it in package 'main' if it has a leading ::.
4796         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4797
4798     } ## end unless (ref $subname eq 'CODE')
4799
4800     # Try to set the breakpoint.
4801     if (not eval { break_subroutine( $subname, $cond ); 1 }) {
4802         local $\ = '';
4803         print $OUT $@ and return;
4804     }
4805
4806     return;
4807 } ## end sub cmd_b_sub
4808
4809 =head3 C<cmd_B> - delete breakpoint(s) (command)
4810
4811 The command mostly parses the command line and tries to turn the argument
4812 into a line spec. If it can't, it uses the current line. It then calls
4813 C<delete_breakpoint> to actually do the work.
4814
4815 If C<*> is  specified, C<cmd_B> calls C<delete_breakpoint> with no arguments,
4816 thereby deleting all the breakpoints.
4817
4818 =cut
4819
4820 sub cmd_B {
4821     my $cmd = shift;
4822
4823     # No line spec? Use dbline.
4824     # If there is one, use it if it's non-zero, or wipe it out if it is.
4825     my $line   = ( $_[0] =~ /\A\./ ) ? $dbline : (shift || '');
4826     my $dbline = shift;
4827
4828     # If the line was dot, make the line the current one.
4829     $line =~ s/^\./$dbline/;
4830
4831     # If it's * we're deleting all the breakpoints.
4832     if ( $line eq '*' ) {
4833         if (not eval { delete_breakpoint(); 1 }) {
4834             print {$OUT} $@;
4835         }
4836     }
4837
4838     # If there is a line spec, delete the breakpoint on that line.
4839     elsif ( $line =~ /\A(\S.*)/ ) {
4840         if (not eval { delete_breakpoint( $line || $dbline ); 1 }) {
4841             local $\ = '';
4842             print {$OUT} $@;
4843         }
4844     } ## end elsif ($line =~ /^(\S.*)/)
4845
4846     # No line spec.
4847     else {
4848         print {$OUT}
4849           "Deleting a breakpoint requires a line number, or '*' for all\n"
4850           ;    # hint
4851     }
4852
4853     return;
4854 } ## end sub cmd_B
4855
4856 =head3 delete_breakpoint([line]) (API)
4857
4858 This actually does the work of deleting either a single breakpoint, or all
4859 of them.
4860
4861 For a single line, we look for it in C<@dbline>. If it's nonbreakable, we
4862 just drop out with a message saying so. If it is, we remove the condition
4863 part of the 'condition\0action' that says there's a breakpoint here. If,
4864 after we've done that, there's nothing left, we delete the corresponding
4865 line in C<%dbline> to signal that no action needs to be taken for this line.
4866
4867 For all breakpoints, we iterate through the keys of C<%had_breakpoints>,
4868 which lists all currently-loaded files which have breakpoints. We then look
4869 at each line in each of these files, temporarily switching the C<%dbline>
4870 and C<@dbline> structures to point to the files in question, and do what
4871 we did in the single line case: delete the condition in C<@dbline>, and
4872 delete the key in C<%dbline> if nothing's left.
4873
4874 We then wholesale delete C<%postponed>, C<%postponed_file>, and
4875 C<%break_on_load>, because these structures contain breakpoints for files
4876 and code that haven't been loaded yet. We can just kill these off because there
4877 are no magical debugger structures associated with them.
4878
4879 =cut
4880
4881 sub _remove_breakpoint_entry {
4882     my ($fn, $i) = @_;
4883
4884     delete $dbline{$i};
4885     _delete_breakpoint_data_ref($fn, $i);
4886
4887     return;
4888 }
4889
4890 sub _delete_all_breakpoints {
4891     print {$OUT} "Deleting all breakpoints...\n";
4892
4893     # %had_breakpoints lists every file that had at least one
4894     # breakpoint in it.
4895     for my $fn ( keys %had_breakpoints ) {
4896
4897         # Switch to the desired file temporarily.
4898         local *dbline = $main::{ '_<' . $fn };
4899
4900         $max = $#dbline;
4901
4902         # For all lines in this file ...
4903         for my $i (1 .. $max) {
4904
4905             # If there's a breakpoint or action on this line ...
4906             if ( defined $dbline{$i} ) {
4907
4908                 # ... remove the breakpoint.
4909                 $dbline{$i} =~ s/\A[^\0]+//;
4910                 if ( $dbline{$i} =~ s/\A\0?\z// ) {
4911                     # Remove the entry altogether if no action is there.
4912                     _remove_breakpoint_entry($fn, $i);
4913                 }
4914             } ## end if (defined $dbline{$i...
4915         } ## end for $i (1 .. $max)
4916
4917         # If, after we turn off the "there were breakpoints in this file"
4918         # bit, the entry in %had_breakpoints for this file is zero,
4919         # we should remove this file from the hash.
4920         if ( not $had_breakpoints{$fn} &= (~1) ) {
4921             delete $had_breakpoints{$fn};
4922         }
4923     } ## end for my $fn (keys %had_breakpoints)
4924
4925     # Kill off all the other breakpoints that are waiting for files that
4926     # haven't been loaded yet.
4927     undef %postponed;
4928     undef %postponed_file;
4929     undef %break_on_load;
4930
4931     return;
4932 }
4933
4934 sub _delete_breakpoint_from_line {
4935     my ($i) = @_;
4936
4937     # Woops. This line wasn't breakable at all.
4938     die "Line $i not breakable.\n" if $dbline[$i] == 0;
4939
4940     # Kill the condition, but leave any action.
4941     $dbline{$i} =~ s/\A[^\0]*//;
4942
4943     # Remove the entry entirely if there's no action left.
4944     if ($dbline{$i} eq '') {
4945         _remove_breakpoint_entry($filename, $i);
4946     }
4947
4948     return;
4949 }
4950
4951 sub delete_breakpoint {
4952     my $i = shift;
4953
4954     # If we got a line, delete just that one.
4955     if ( defined($i) ) {
4956         _delete_breakpoint_from_line($i);
4957     }
4958     # No line; delete them all.
4959     else {
4960         _delete_all_breakpoints();
4961     }
4962
4963     return;
4964 }
4965
4966 =head3 cmd_stop (command)
4967
4968 This is meant to be part of the new command API, but it isn't called or used
4969 anywhere else in the debugger. XXX It is probably meant for use in development
4970 of new commands.
4971
4972 =cut
4973
4974 sub cmd_stop {    # As on ^C, but not signal-safy.
4975     $signal = 1;
4976 }
4977
4978 =head3 C<cmd_e> - threads
4979
4980 Display the current thread id:
4981
4982     e
4983
4984 This could be how (when implemented) to send commands to this thread id (e cmd)
4985 or that thread id (e tid cmd).
4986
4987 =cut
4988
4989 sub cmd_e {
4990     my $cmd  = shift;
4991     my $line = shift;
4992     unless (exists($INC{'threads.pm'})) {
4993         print "threads not loaded($ENV{PERL5DB_THREADED})
4994         please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
4995     } else {
4996         my $tid = threads->tid;
4997         print "thread id: $tid\n";
4998     }
4999 } ## end sub cmd_e
5000
5001 =head3 C<cmd_E> - list of thread ids
5002
5003 Display the list of available thread ids:
5004
5005     E
5006
5007 This could be used (when implemented) to send commands to all threads (E cmd).
5008
5009 =cut
5010
5011 sub cmd_E {
5012     my $cmd  = shift;
5013     my $line = shift;
5014     unless (exists($INC{'threads.pm'})) {
5015         print "threads not loaded($ENV{PERL5DB_THREADED})
5016         please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
5017     } else {
5018         my $tid = threads->tid;
5019         print "thread ids: ".join(', ',
5020             map { ($tid == $_->tid ? '<'.$_->tid.'>' : $_->tid) } threads->list
5021         )."\n";
5022     }
5023 } ## end sub cmd_E
5024
5025 =head3 C<cmd_h> - help command (command)
5026
5027 Does the work of either
5028
5029 =over 4
5030
5031 =item *
5032
5033 Showing all the debugger help
5034
5035 =item *
5036
5037 Showing help for a specific command
5038
5039 =back
5040
5041 =cut
5042
5043 use vars qw($help);
5044 use vars qw($summary);
5045
5046 sub cmd_h {
5047     my $cmd = shift;
5048
5049     # If we have no operand, assume null.
5050     my $line = shift || '';
5051
5052     # 'h h'. Print the long-format help.
5053     if ( $line =~ /\Ah\s*\z/ ) {
5054         print_help($help);
5055     }
5056
5057     # 'h <something>'. Search for the command and print only its help.
5058     elsif ( my ($asked) = $line =~ /\A(\S.*)\z/ ) {
5059
5060         # support long commands; otherwise bogus errors
5061         # happen when you ask for h on <CR> for example
5062         my $qasked = quotemeta($asked);    # for searching; we don't
5063                                            # want to use it as a pattern.
5064                                            # XXX: finds CR but not <CR>
5065
5066         # Search the help string for the command.
5067         if (
5068             $help =~ /^                    # Start of a line
5069                       <?                   # Optional '<'
5070                       (?:[IB]<)            # Optional markup
5071                       $qasked              # The requested command
5072                      /mx
5073           )
5074         {
5075
5076             # It's there; pull it out and print it.
5077             while (
5078                 $help =~ /^
5079                               (<?            # Optional '<'
5080                                  (?:[IB]<)   # Optional markup
5081                                  $qasked     # The command
5082                                  ([\s\S]*?)  # Description line(s)
5083                               \n)            # End of last description line
5084                               (?!\s)         # Next line not starting with
5085                                              # whitespace
5086                              /mgx
5087               )
5088             {
5089                 print_help($1);
5090             }
5091         }
5092
5093         # Not found; not a debugger command.
5094         else {
5095             print_help("B<$asked> is not a debugger command.\n");
5096         }
5097     } ## end elsif ($line =~ /^(\S.*)$/)
5098
5099     # 'h' - print the summary help.
5100     else {
5101         print_help($summary);
5102     }
5103 } ## end sub cmd_h
5104
5105 =head3 C<cmd_i> - inheritance display
5106
5107 Display the (nested) parentage of the module or object given.
5108
5109 =cut
5110
5111 sub cmd_i {
5112     my $cmd  = shift;
5113     my $line = shift;
5114     foreach my $isa ( split( /\s+/, $line ) ) {
5115         $evalarg = $isa;
5116         ($isa) = DB::eval();
5117         no strict 'refs';
5118         print join(
5119             ', ',
5120             map {
5121                 "$_"
5122                   . (
5123                     defined( ${"$_\::VERSION"} )
5124                     ? ' ' . ${"$_\::VERSION"}
5125                     : undef )
5126               } @{mro::get_linear_isa(ref($isa) || $isa)}
5127         );
5128         print "\n";
5129     }
5130 } ## end sub cmd_i
5131
5132 =head3 C<cmd_l> - list lines (command)
5133
5134 Most of the command is taken up with transforming all the different line
5135 specification syntaxes into 'start-stop'. After that is done, the command
5136 runs a loop over C<@dbline> for the specified range of lines. It handles
5137 the printing of each line and any markers (C<==E<gt>> for current line,
5138 C<b> for break on this line, C<a> for action on this line, C<:> for this
5139 line breakable).
5140
5141 We save the last line listed in the C<$start> global for further listing
5142 later.
5143
5144 =cut
5145
5146 sub cmd_l {
5147     my $current_line = $line;
5148     my $cmd  = shift;
5149     my $line = shift;
5150
5151     # If this is '-something', delete any spaces after the dash.
5152     $line =~ s/^-\s*$/-/;
5153
5154     # If the line is '$something', assume this is a scalar containing a
5155     # line number.
5156     if ( $line =~ /^(\$.*)/s ) {
5157
5158         # Set up for DB::eval() - evaluate in *user* context.
5159         $evalarg = $1;
5160         # $evalarg = $2;
5161         my ($s) = DB::eval();
5162
5163         # Ooops. Bad scalar.
5164         if ($@) {
5165             print {$OUT} "Error: $@\n";
5166             next CMD;
5167         }
5168
5169         # Good scalar. If it's a reference, find what it points to.
5170         $s = CvGV_name($s);
5171         print {$OUT} "Interpreted as: $1 $s\n";
5172         $line = "$1 $s";
5173
5174         # Call self recursively to really do the command.
5175         cmd_l( 'l', $s );
5176     } ## end if ($line =~ /^(\$.*)/s)
5177
5178     # l name. Try to find a sub by that name.
5179     elsif ( ($subname) = $line =~ /\A([\':A-Za-z_][\':\w]*(?:\[.*\])?)/s ) {
5180         my $s = $subname;
5181
5182         # De-Perl4.
5183         $subname =~ s/\'/::/;
5184
5185         # Put it in this package unless it starts with ::.
5186         $subname = $package . "::" . $subname unless $subname =~ /::/;
5187
5188         # Put it in CORE::GLOBAL if t doesn't start with :: and
5189         # it doesn't live in this package and it lives in CORE::GLOBAL.
5190         $subname = "CORE::GLOBAL::$s"
5191           if not defined &$subname
5192           and $s !~ /::/
5193           and defined &{"CORE::GLOBAL::$s"};
5194
5195         # Put leading '::' names into 'main::'.
5196         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
5197
5198         # Get name:start-stop from find_sub, and break this up at
5199         # colons.
5200         my @pieces = split( /:/, find_sub($subname) || $sub{$subname} );
5201
5202         # Pull off start-stop.
5203         my $subrange = pop @pieces;
5204
5205         # If the name contained colons, the split broke it up.
5206         # Put it back together.
5207         $file = join( ':', @pieces );
5208
5209         # If we're not in that file, switch over to it.
5210         if ( $file ne $filename ) {
5211             print $OUT "Switching to file '$file'.\n"
5212               unless $slave_editor;
5213
5214             # Switch debugger's magic structures.
5215             *dbline   = $main::{ '_<' . $file };
5216             $max      = $#dbline;
5217             $filename = $file;
5218         } ## end if ($file ne $filename)
5219
5220         # Subrange is 'start-stop'. If this is less than a window full,
5221         # swap it to 'start+', which will list a window from the start point.
5222         if ($subrange) {
5223             if ( eval($subrange) < -$window ) {
5224                 $subrange =~ s/-.*/+/;
5225             }
5226
5227             # Call self recursively to list the range.
5228             $line = $subrange;
5229             cmd_l( 'l', $subrange );
5230         } ## end if ($subrange)
5231
5232         # Couldn't find it.
5233         else {
5234             print $OUT "Subroutine $subname not found.\n";
5235         }
5236     } ## end elsif ($line =~ /^([\':A-Za-z_][\':\w]*(\[.*\])?)/s)
5237
5238     # Bare 'l' command.
5239     elsif ( $line !~ /\S/ ) {
5240
5241         # Compute new range to list.
5242         $incr = $window - 1;
5243         $line = $start . '-' . ( $start + $incr );
5244
5245         # Recurse to do it.
5246         cmd_l( 'l', $line );
5247     }
5248
5249     # l [start]+number_of_lines
5250     elsif ( my ($new_start, $new_incr) = $line =~ /\A(\d*)\+(\d*)\z/ ) {
5251
5252         # Don't reset start for 'l +nnn'.
5253         $start = $new_start if $new_start;
5254
5255         # Increment for list. Use window size if not specified.
5256         # (Allows 'l +' to work.)
5257         $incr = $new_incr;
5258         $incr = $window - 1 unless $incr;
5259
5260         # Create a line range we'll understand, and recurse to do it.
5261         $line = $start . '-' . ( $start + $incr );
5262         cmd_l( 'l', $line );
5263     } ## end elsif ($line =~ /^(\d*)\+(\d*)$/)
5264
5265     # l start-stop or l start,stop
5266     elsif ( $line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/ ) {
5267
5268         # Determine end point; use end of file if not specified.
5269         my $end = ( !defined $2 ) ? $max : ( $4 ? $4 : $2 );
5270
5271         # Go on to the end, and then stop.
5272         $end = $max if $end > $max;
5273
5274         # Determine start line.
5275         my $i    = $2;
5276         $i    = $line if $i eq '.';
5277         $i    = 1 if $i < 1;
5278         $incr = $end - $i;
5279
5280         # If we're running under a slave editor, force it to show the lines.
5281         if ($slave_editor) {
5282             print $OUT "\032\032$filename:$i:0\n";
5283             $i = $end;
5284         }
5285
5286         # We're doing it ourselves. We want to show the line and special
5287         # markers for:
5288         # - the current line in execution
5289         # - whether a line is breakable or not
5290         # - whether a line has a break or not
5291         # - whether a line has an action or not
5292         else {
5293             for ( ; $i <= $end ; $i++ ) {
5294
5295                 # Check for breakpoints and actions.
5296                 my ( $stop, $action );
5297                 ( $stop, $action ) = split( /\0/, $dbline{$i} )
5298                   if $dbline{$i};
5299
5300                 # ==> if this is the current line in execution,
5301                 # : if it's breakable.
5302                 my $arrow =
5303                   ( $i == $current_line and $filename eq $filename_ini )
5304                   ? '==>'
5305                   : ( $dbline[$i] + 0 ? ':' : ' ' );
5306
5307                 # Add break and action indicators.
5308                 $arrow .= 'b' if $stop;
5309                 $arrow .= 'a' if $action;
5310
5311                 # Print the line.
5312                 print $OUT "$i$arrow\t", $dbline[$i];
5313
5314                 # Move on to the next line. Drop out on an interrupt.
5315                 $i++, last if $signal;
5316             } ## end for (; $i <= $end ; $i++)
5317
5318             # Line the prompt up; print a newline if the last line listed
5319             # didn't have a newline.
5320             print $OUT "\n" unless $dbline[ $i - 1 ] =~ /\n$/;
5321         } ## end else [ if ($slave_editor)
5322
5323         # Save the point we last listed to in case another relative 'l'
5324         # command is desired. Don't let it run off the end.
5325         $start = $i;
5326         $start = $max if $start > $max;
5327     } ## end elsif ($line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/)
5328 } ## end sub cmd_l
5329
5330 =head3 C<cmd_L> - list breakpoints, actions, and watch expressions (command)
5331
5332 To list breakpoints, the command has to look determine where all of them are
5333 first. It starts a C<%had_breakpoints>, which tells us what all files have
5334 breakpoints and/or actions. For each file, we switch the C<*dbline> glob (the
5335 magic source and breakpoint data structures) to the file, and then look
5336 through C<%dbline> for lines with breakpoints and/or actions, listing them
5337 out. We look through C<%postponed> not-yet-compiled subroutines that have
5338 breakpoints, and through C<%postponed_file> for not-yet-C<require>'d files
5339 that have breakpoints.
5340
5341 Watchpoints are simpler: we just list the entries in C<@to_watch>.
5342
5343 =cut
5344
5345 sub cmd_L {
5346     my $cmd = shift;
5347
5348     # If no argument, list everything. Pre-5.8.0 version always lists
5349     # everything
5350     my $arg = shift || 'abw';
5351     $arg = 'abw' unless $CommandSet eq '580';    # sigh...
5352
5353     # See what is wanted.
5354     my $action_wanted = ( $arg =~ /a/ ) ? 1 : 0;
5355     my $break_wanted  = ( $arg =~ /b/ ) ? 1 : 0;
5356     my $watch_wanted  = ( $arg =~ /w/ ) ? 1 : 0;
5357
5358     # Breaks and actions are found together, so we look in the same place
5359     # for both.
5360     if ( $break_wanted or $action_wanted ) {
5361
5362         # Look in all the files with breakpoints...
5363         for my $file ( keys %had_breakpoints ) {
5364
5365             # Temporary switch to this file.
5366             local *dbline = $main::{ '_<' . $file };
5367
5368             # Set up to look through the whole file.
5369             $max = $#dbline;
5370             my $was;    # Flag: did we print something
5371                         # in this file?
5372
5373             # For each line in the file ...
5374             for my $i (1 .. $max) {
5375
5376                 # We've got something on this line.
5377                 if ( defined $dbline{$i} ) {
5378
5379                     # Print the header if we haven't.
5380                     print $OUT "$file:\n" unless $was++;
5381
5382                     # Print the line.
5383                     print $OUT " $i:\t", $dbline[$i];
5384
5385                     # Pull out the condition and the action.
5386                     my ( $stop, $action ) = split( /\0/, $dbline{$i} );
5387
5388                     # Print the break if there is one and it's wanted.
5389                     print $OUT "   break if (", $stop, ")\n"
5390                       if $stop
5391                       and $break_wanted;
5392
5393                     # Print the action if there is one and it's wanted.
5394                     print $OUT "   action:  ", $action, "\n"
5395                       if $action
5396                       and $action_wanted;
5397
5398                     # Quit if the user hit interrupt.
5399                     last if $signal;
5400                 } ## end if (defined $dbline{$i...
5401             } ## end for my $i (1 .. $max)
5402         } ## end for my $file (keys %had_breakpoints)
5403     } ## end if ($break_wanted or $action_wanted)
5404
5405     # Look for breaks in not-yet-compiled subs:
5406     if ( %postponed and $break_wanted ) {
5407         print $OUT "Postponed breakpoints in subroutines:\n";
5408         my $subname;
5409         for $subname ( keys %postponed ) {
5410             print $OUT " $subname\t$postponed{$subname}\n";
5411             last if $signal;
5412         }
5413     } ## end if (%postponed and $break_wanted)
5414
5415     # Find files that have not-yet-loaded breaks:
5416     my @have = map {    # Combined keys
5417         keys %{ $postponed_file{$_} }
5418     } keys %postponed_file;
5419
5420     # If there are any, list them.
5421     if ( @have and ( $break_wanted or $action_wanted ) ) {
5422         print $OUT "Postponed breakpoints in files:\n";
5423         for my $file ( keys %postponed_file ) {
5424             my $db = $postponed_file{$file};
5425             print $OUT " $file:\n";
5426             for my $line ( sort { $a <=> $b } keys %$db ) {
5427                 print $OUT "  $line:\n";
5428                 my ( $stop, $action ) = split( /\0/, $$db{$line} );
5429                 print $OUT "    break if (", $stop, ")\n"
5430                   if $stop
5431                   and $break_wanted;
5432                 print $OUT "    action:  ", $action, "\n"
5433                   if $action
5434                   and $action_wanted;
5435                 last if $signal;
5436             } ## end for $line (sort { $a <=>...
5437             last if $signal;
5438         } ## end for $file (keys %postponed_file)
5439     } ## end if (@have and ($break_wanted...
5440     if ( %break_on_load and $break_wanted ) {
5441         print {$OUT} "Breakpoints on load:\n";
5442         BREAK_ON_LOAD: for my $filename ( keys %break_on_load ) {
5443             print {$OUT} " $filename\n";
5444             last BREAK_ON_LOAD if $signal;
5445         }
5446     } ## end if (%break_on_load and...
5447     if ($watch_wanted and ( $trace & 2 )) {
5448         print {$OUT} "Watch-expressions:\n" if @to_watch;
5449         TO_WATCH: for my $expr (@to_watch) {
5450             print {$OUT} " $expr\n";
5451             last TO_WATCH if $signal;
5452         }
5453     }
5454 } ## end sub cmd_L
5455
5456 =head3 C<cmd_M> - list modules (command)
5457
5458 Just call C<list_modules>.
5459
5460 =cut
5461
5462 sub cmd_M {
5463     list_modules();
5464
5465     return;
5466 }
5467
5468 =head3 C<cmd_o> - options (command)
5469
5470 If this is just C<o> by itself, we list the current settings via
5471 C<dump_option>. If there's a nonblank value following it, we pass that on to
5472 C<parse_options> for processing.
5473
5474 =cut
5475
5476 sub cmd_o {
5477     my $cmd = shift;
5478     my $opt = shift || '';    # opt[=val]
5479
5480     # Nonblank. Try to parse and process.
5481     if ( $opt =~ /^(\S.*)/ ) {
5482         &parse_options($1);
5483     }
5484
5485     # Blank. List the current option settings.
5486     else {
5487         for (@options) {
5488             &dump_option($_);
5489         }
5490     }
5491 } ## end sub cmd_o
5492
5493 =head3 C<cmd_O> - nonexistent in 5.8.x (command)
5494
5495 Advises the user that the O command has been renamed.
5496
5497 =cut
5498
5499 sub cmd_O {
5500     print $OUT "The old O command is now the o command.\n";             # hint
5501     print $OUT "Use 'h' to get current command help synopsis or\n";     #
5502     print $OUT "use 'o CommandSet=pre580' to revert to old usage\n";    #
5503 }
5504
5505 =head3 C<cmd_v> - view window (command)
5506
5507 Uses the C<$preview> variable set in the second C<BEGIN> block (q.v.) to
5508 move back a few lines to list the selected line in context. Uses C<cmd_l>
5509 to do the actual listing after figuring out the range of line to request.
5510
5511 =cut
5512
5513 use vars qw($preview);
5514
5515 sub cmd_v {
5516     my $cmd  = shift;
5517     my $line = shift;
5518
5519     # Extract the line to list around. (Astute readers will have noted that
5520     # this pattern will match whether or not a numeric line is specified,
5521     # which means that we'll always enter this loop (though a non-numeric
5522     # argument results in no action at all)).
5523     if ( $line =~ /^(\d*)$/ ) {
5524
5525         # Total number of lines to list (a windowful).
5526         $incr = $window - 1;
5527
5528         # Set the start to the argument given (if there was one).
5529         $start = $1 if $1;
5530
5531         # Back up by the context amount.
5532         $start -= $preview;
5533
5534         # Put together a linespec that cmd_l will like.
5535         $line = $start . '-' . ( $start + $incr );
5536
5537         # List the lines.
5538         cmd_l( 'l', $line );
5539     } ## end if ($line =~ /^(\d*)$/)
5540 } ## end sub cmd_v
5541
5542 =head3 C<cmd_w> - add a watch expression (command)
5543
5544 The 5.8 version of this command adds a watch expression if one is specified;
5545 it does nothing if entered with no operands.
5546
5547 We extract the expression, save it, evaluate it in the user's context, and
5548 save the value. We'll re-evaluate it each time the debugger passes a line,
5549 and will stop (see the code at the top of the command loop) if the value
5550 of any of the expressions changes.
5551
5552 =cut
5553
5554 sub _add_watch_expr {
5555     my $expr = shift;
5556
5557     # ... save it.
5558     push @to_watch, $expr;
5559
5560     # Parameterize DB::eval and call it to get the expression's value
5561     # in the user's context. This version can handle expressions which
5562     # return a list value.
5563     $evalarg = $expr;
5564     my ($val) = join( ' ', DB::eval() );
5565     $val = ( defined $val ) ? "'$val'" : 'undef';
5566
5567     # Save the current value of the expression.
5568     push @old_watch, $val;
5569
5570     # We are now watching expressions.
5571     $trace |= 2;
5572
5573     return;
5574 }
5575
5576 sub cmd_w {
5577     my $cmd = shift;
5578
5579     # Null expression if no arguments.
5580     my $expr = shift || '';
5581
5582     # If expression is not null ...
5583     if ( $expr =~ /\A\S/ ) {
5584         _add_watch_expr($expr);
5585     } ## end if ($expr =~ /^(\S.*)/)
5586
5587     # You have to give one to get one.
5588     else {
5589         print $OUT "Adding a watch-expression requires an expression\n";  # hint
5590     }
5591
5592     return;
5593 }
5594
5595 =head3 C<cmd_W> - delete watch expressions (command)
5596
5597 This command accepts either a watch expression to be removed from the list
5598 of watch expressions, or C<*> to delete them all.
5599
5600 If C<*> is specified, we simply empty the watch expression list and the
5601 watch expression value list. We also turn off the bit that says we've got
5602 watch expressions.
5603
5604 If an expression (or partial expression) is specified, we pattern-match
5605 through the expressions and remove the ones that match. We also discard
5606 the corresponding values. If no watch expressions are left, we turn off
5607 the I<watching expressions> bit.
5608
5609 =cut
5610
5611 sub cmd_W {
5612     my $cmd  = shift;
5613     my $expr = shift || '';
5614
5615     # Delete them all.
5616     if ( $expr eq '*' ) {
5617
5618         # Not watching now.
5619         $trace &= ~2;
5620
5621         print $OUT "Deleting all watch expressions ...\n";
5622
5623         # And all gone.
5624         @to_watch = @old_watch = ();
5625     }
5626
5627     # Delete one of them.
5628     elsif ( $expr =~ /^(\S.*)/ ) {
5629
5630         # Where we are in the list.
5631         my $i_cnt = 0;
5632
5633         # For each expression ...
5634         foreach (@to_watch) {
5635             my $val = $to_watch[$i_cnt];
5636
5637             # Does this one match the command argument?
5638             if ( $val eq $expr ) {    # =~ m/^\Q$i$/) {
5639                                       # Yes. Turn it off, and its value too.
5640                 splice( @to_watch,  $i_cnt, 1 );
5641                 splice( @old_watch, $i_cnt, 1 );
5642             }
5643             $i_cnt++;
5644         } ## end foreach (@to_watch)
5645
5646         # We don't bother to turn watching off because
5647         #  a) we don't want to stop calling watchfunction() it it exists
5648         #  b) foreach over a null list doesn't do anything anyway
5649
5650     } ## end elsif ($expr =~ /^(\S.*)/)
5651
5652     # No command arguments entered.
5653     else {
5654         print $OUT
5655           "Deleting a watch-expression requires an expression, or '*' for all\n"
5656           ;    # hint
5657     }
5658 } ## end sub cmd_W
5659
5660 ### END of the API section
5661
5662 =head1 SUPPORT ROUTINES
5663
5664 These are general support routines that are used in a number of places
5665 throughout the debugger.
5666
5667 =head2 save
5668
5669 save() saves the user's versions of globals that would mess us up in C<@saved>,
5670 and installs the versions we like better.
5671
5672 =cut
5673
5674 sub save {
5675
5676     # Save eval failure, command failure, extended OS error, output field
5677     # separator, input record separator, output record separator and
5678     # the warning setting.
5679     @saved = ( $@, $!, $^E, $,, $/, $\, $^W );
5680
5681     $,  = "";      # output field separator is null string
5682     $/  = "\n";    # input record separator is newline
5683     $\  = "";      # output record separator is null string
5684     $^W = 0;       # warnings are off
5685 } ## end sub save
5686
5687 =head2 C<print_lineinfo> - show where we are now
5688
5689 print_lineinfo prints whatever it is that it is handed; it prints it to the
5690 C<$LINEINFO> filehandle instead of just printing it to STDOUT. This allows
5691 us to feed line information to a slave editor without messing up the
5692 debugger output.
5693
5694 =cut
5695
5696 sub print_lineinfo {
5697
5698     # Make the terminal sensible if we're not the primary debugger.
5699     resetterm(1) if $LINEINFO eq $OUT and $term_pid != $$;
5700     local $\ = '';
5701     local $, = '';
5702     print $LINEINFO @_;
5703 } ## end sub print_lineinfo
5704
5705 =head2 C<postponed_sub>
5706
5707 Handles setting postponed breakpoints in subroutines once they're compiled.
5708 For breakpoints, we use C<DB::find_sub> to locate the source file and line
5709 range for the subroutine, then mark the file as having a breakpoint,
5710 temporarily switch the C<*dbline> glob over to the source file, and then
5711 search the given range of lines to find a breakable line. If we find one,
5712 we set the breakpoint on it, deleting the breakpoint from C<%postponed>.
5713
5714 =cut
5715
5716 # The following takes its argument via $evalarg to preserve current @_
5717
5718 sub postponed_sub {
5719
5720     # Get the subroutine name.
5721     my $subname = shift;
5722
5723     # If this is a 'break +<n> if <condition>' ...
5724     if ( $postponed{$subname} =~ s/^break\s([+-]?\d+)\s+if\s// ) {
5725
5726         # If there's no offset, use '+0'.
5727         my $offset = $1 || 0;
5728
5729         # find_sub's value is 'fullpath-filename:start-stop'. It's
5730         # possible that the filename might have colons in it too.
5731         my ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(\d+)-.*$/ );
5732         if ($i) {
5733
5734             # We got the start line. Add the offset '+<n>' from
5735             # $postponed{subname}.
5736             $i += $offset;
5737
5738             # Switch to the file this sub is in, temporarily.
5739             local *dbline = $main::{ '_<' . $file };
5740
5741             # No warnings, please.
5742             local $^W = 0;    # != 0 is magical below
5743
5744             # This file's got a breakpoint in it.
5745             $had_breakpoints{$file} |= 1;
5746
5747             # Last line in file.
5748             $max = $#dbline;
5749
5750             # Search forward until we hit a breakable line or get to
5751             # the end of the file.
5752             ++$i until $dbline[$i] != 0 or $i >= $max;
5753
5754             # Copy the breakpoint in and delete it from %postponed.
5755             $dbline{$i} = delete $postponed{$subname};
5756         } ## end if ($i)
5757
5758         # find_sub didn't find the sub.
5759         else {
5760             local $\ = '';
5761             print $OUT "Subroutine $subname not found.\n";
5762         }
5763         return;
5764     } ## end if ($postponed{$subname...
5765     elsif ( $postponed{$subname} eq 'compile' ) { $signal = 1 }
5766
5767     #print $OUT "In postponed_sub for '$subname'.\n";
5768 } ## end sub postponed_sub
5769
5770 =head2 C<postponed>
5771
5772 Called after each required file is compiled, but before it is executed;
5773 also called if the name of a just-compiled subroutine is a key of
5774 C<%postponed>. Propagates saved breakpoints (from C<b compile>, C<b load>,
5775 etc.) into the just-compiled code.
5776
5777 If this is a C<require>'d file, the incoming parameter is the glob
5778 C<*{"_<$filename"}>, with C<$filename> the name of the C<require>'d file.
5779
5780 If it's a subroutine, the incoming parameter is the subroutine name.
5781
5782 =cut
5783
5784 sub postponed {
5785
5786     # If there's a break, process it.
5787     if ($ImmediateStop) {
5788
5789         # Right, we've stopped. Turn it off.
5790         $ImmediateStop = 0;
5791
5792         # Enter the command loop when DB::DB gets called.
5793         $signal = 1;
5794     }
5795
5796     # If this is a subroutine, let postponed_sub() deal with it.
5797     return &postponed_sub unless ref \$_[0] eq 'GLOB';
5798
5799     # Not a subroutine. Deal with the file.
5800     local *dbline = shift;
5801     my $filename = $dbline;
5802     $filename =~ s/^_<//;
5803     local $\ = '';
5804     $signal = 1, print $OUT "'$filename' loaded...\n"
5805       if $break_on_load{$filename};
5806     print_lineinfo( ' ' x $stack_depth, "Package $filename.\n" ) if $frame;
5807
5808     # Do we have any breakpoints to put in this file?
5809     return unless $postponed_file{$filename};
5810
5811     # Yes. Mark this file as having breakpoints.
5812     $had_breakpoints{$filename} |= 1;
5813
5814     # "Cannot be done: insufficient magic" - we can't just put the
5815     # breakpoints saved in %postponed_file into %dbline by assigning
5816     # the whole hash; we have to do it one item at a time for the
5817     # breakpoints to be set properly.
5818     #%dbline = %{$postponed_file{$filename}};
5819
5820     # Set the breakpoints, one at a time.
5821     my $key;
5822
5823     for $key ( keys %{ $postponed_file{$filename} } ) {
5824
5825         # Stash the saved breakpoint into the current file's magic line array.
5826         $dbline{$key} = ${ $postponed_file{$filename} }{$key};
5827     }
5828
5829     # This file's been compiled; discard the stored breakpoints.
5830     delete $postponed_file{$filename};
5831
5832 } ## end sub postponed
5833
5834 =head2 C<dumpit>
5835
5836 C<dumpit> is the debugger's wrapper around dumpvar.pl.
5837
5838 It gets a filehandle (to which C<dumpvar.pl>'s output will be directed) and
5839 a reference to a variable (the thing to be dumped) as its input.
5840
5841 The incoming filehandle is selected for output (C<dumpvar.pl> is printing to
5842 the currently-selected filehandle, thank you very much). The current
5843 values of the package globals C<$single> and C<$trace> are backed up in
5844 lexicals, and they are turned off (this keeps the debugger from trying
5845 to single-step through C<dumpvar.pl> (I think.)). C<$frame> is localized to
5846 preserve its current value and it is set to zero to prevent entry/exit
5847 messages from printing, and C<$doret> is localized as well and set to -2 to
5848 prevent return values from being shown.
5849
5850 C<dumpit()> then checks to see if it needs to load C<dumpvar.pl> and
5851 tries to load it (note: if you have a C<dumpvar.pl>  ahead of the
5852 installed version in C<@INC>, yours will be used instead. Possible security
5853 problem?).
5854
5855 It then checks to see if the subroutine C<main::dumpValue> is now defined
5856 it should have been defined by C<dumpvar.pl>). If it has, C<dumpit()>
5857 localizes the globals necessary for things to be sane when C<main::dumpValue()>
5858 is called, and picks up the variable to be dumped from the parameter list.
5859
5860 It checks the package global C<%options> to see if there's a C<dumpDepth>
5861 specified. If not, -1 is assumed; if so, the supplied value gets passed on to
5862 C<dumpvar.pl>. This tells C<dumpvar.pl> where to leave off when dumping a
5863 structure: -1 means dump everything.
5864
5865 C<dumpValue()> is then called if possible; if not, C<dumpit()>just prints a
5866 warning.
5867
5868 In either case, C<$single>, C<$trace>, C<$frame>, and C<$doret> are restored
5869 and we then return to the caller.
5870
5871 =cut
5872
5873 sub dumpit {
5874
5875     # Save the current output filehandle and switch to the one
5876     # passed in as the first parameter.
5877     my $savout = select(shift);
5878
5879     # Save current settings of $single and $trace, and then turn them off.
5880     my $osingle = $single;
5881     my $otrace  = $trace;
5882     $single = $trace = 0;
5883
5884     # XXX Okay, what do $frame and $doret do, again?
5885     local $frame = 0;
5886     local $doret = -2;
5887
5888     # Load dumpvar.pl unless we've already got the sub we need from it.
5889     unless ( defined &main::dumpValue ) {
5890         do 'dumpvar.pl' or die $@;
5891     }
5892
5893     # If the load succeeded (or we already had dumpvalue()), go ahead
5894     # and dump things.
5895     if ( defined &main::dumpValue ) {
5896         local $\ = '';
5897         local $, = '';
5898         local $" = ' ';
5899         my $v = shift;
5900         my $maxdepth = shift || $option{dumpDepth};
5901         $maxdepth = -1 unless defined $maxdepth;    # -1 means infinite depth
5902         &main::dumpValue( $v, $maxdepth );
5903     } ## end if (defined &main::dumpValue)
5904
5905     # Oops, couldn't load dumpvar.pl.
5906     else {
5907         local $\ = '';
5908         print $OUT "dumpvar.pl not available.\n";
5909     }
5910
5911     # Reset $single and $trace to their old values.
5912     $single = $osingle;
5913     $trace  = $otrace;
5914
5915     # Restore the old filehandle.
5916     select($savout);
5917 } ## end sub dumpit
5918
5919 =head2 C<print_trace>
5920
5921 C<print_trace>'s job is to print a stack trace. It does this via the
5922 C<dump_trace> routine, which actually does all the ferreting-out of the
5923 stack trace data. C<print_trace> takes care of formatting it nicely and
5924 printing it to the proper filehandle.
5925
5926 Parameters:
5927
5928 =over 4
5929
5930 =item *
5931
5932 The filehandle to print to.
5933
5934 =item *
5935
5936 How many frames to skip before starting trace.
5937
5938 =item *
5939
5940 How many frames to print.
5941
5942 =item *
5943
5944 A flag: if true, print a I<short> trace without filenames, line numbers, or arguments
5945
5946 =back
5947
5948 The original comment below seems to be noting that the traceback may not be
5949 correct if this routine is called in a tied method.
5950
5951 =cut
5952
5953 # Tied method do not create a context, so may get wrong message:
5954
5955 sub print_trace {
5956     local $\ = '';
5957     my $fh = shift;
5958
5959     # If this is going to a slave editor, but we're not the primary
5960     # debugger, reset it first.
5961     resetterm(1)
5962       if $fh        eq $LINEINFO    # slave editor
5963       and $LINEINFO eq $OUT         # normal output
5964       and $term_pid != $$;          # not the primary
5965
5966     # Collect the actual trace information to be formatted.
5967     # This is an array of hashes of subroutine call info.
5968     my @sub = dump_trace( $_[0] + 1, $_[1] );
5969
5970     # Grab the "short report" flag from @_.
5971     my $short = $_[2];              # Print short report, next one for sub name
5972
5973     # Run through the traceback info, format it, and print it.
5974     my $s;
5975     for my $i (0 .. $#sub) {
5976
5977         # Drop out if the user has lost interest and hit control-C.
5978         last if $signal;
5979
5980         # Set the separator so arrys print nice.
5981         local $" = ', ';
5982
5983         # Grab and stringify the arguments if they are there.
5984         my $args =
5985           defined $sub[$i]{args}
5986           ? "(@{ $sub[$i]{args} })"
5987           : '';
5988
5989         # Shorten them up if $maxtrace says they're too long.
5990         $args = ( substr $args, 0, $maxtrace - 3 ) . '...'
5991           if length $args > $maxtrace;
5992
5993         # Get the file name.
5994         my $file = $sub[$i]{file};
5995
5996         # Put in a filename header if short is off.
5997         $file = $file eq '-e' ? $file : "file '$file'" unless $short;
5998
5999         # Get the actual sub's name, and shorten to $maxtrace's requirement.
6000         $s = $sub[$i]{sub};
6001         $s = ( substr $s, 0, $maxtrace - 3 ) . '...' if length $s > $maxtrace;
6002
6003         # Short report uses trimmed file and sub names.
6004         if ($short) {
6005             my $sub = @_ >= 4 ? $_[3] : $s;
6006             print $fh "$sub[$i]{context}=$sub$args from $file:$sub[$i]{line}\n";
6007         } ## end if ($short)
6008
6009         # Non-short report includes full names.
6010         else {
6011             print $fh "$sub[$i]{context} = $s$args"
6012               . " called from $file"
6013               . " line $sub[$i]{line}\n";
6014         }
6015     } ## end for my $i (0 .. $#sub)
6016 } ## end sub print_trace
6017
6018 =head2 dump_trace(skip[,count])
6019
6020 Actually collect the traceback information available via C<caller()>. It does
6021 some filtering and cleanup of the data, but mostly it just collects it to
6022 make C<print_trace()>'s job easier.
6023
6024 C<skip> defines the number of stack frames to be skipped, working backwards
6025 from the most current. C<count> determines the total number of frames to
6026 be returned; all of them (well, the first 10^9) are returned if C<count>
6027 is omitted.
6028
6029 This routine returns a list of hashes, from most-recent to least-recent
6030 stack frame. Each has the following keys and values:
6031
6032 =over 4
6033
6034 =item * C<context> - C<.> (null), C<$> (scalar), or C<@> (array)
6035
6036 =item * C<sub> - subroutine name, or C<eval> information
6037
6038 =item * C<args> - undef, or a reference to an array of arguments
6039
6040 =item * C<file> - the file in which this item was defined (if any)
6041
6042 =item * C<line> - the line on which it was defined
6043
6044 =back
6045
6046 =cut
6047
6048 sub dump_trace {
6049
6050     # How many levels to skip.
6051     my $skip = shift;
6052
6053     # How many levels to show. (1e9 is a cheap way of saying "all of them";
6054     # it's unlikely that we'll have more than a billion stack frames. If you
6055     # do, you've got an awfully big machine...)
6056     my $count = shift || 1e9;
6057
6058     # We increment skip because caller(1) is the first level *back* from
6059     # the current one.  Add $skip to the count of frames so we have a
6060     # simple stop criterion, counting from $skip to $count+$skip.
6061     $skip++;
6062     $count += $skip;
6063
6064     # These variables are used to capture output from caller();
6065     my ( $p, $file, $line, $sub, $h, $context );
6066
6067     my ( $e, $r, @a, @sub, $args );
6068
6069     # XXX Okay... why'd we do that?
6070     my $nothard = not $frame & 8;
6071     local $frame = 0;
6072
6073     # Do not want to trace this.
6074     my $otrace = $trace;
6075     $trace = 0;
6076
6077     # Start out at the skip count.
6078     # If we haven't reached the number of frames requested, and caller() is
6079     # still returning something, stay in the loop. (If we pass the requested
6080     # number of stack frames, or we run out - caller() returns nothing - we
6081     # quit.
6082     # Up the stack frame index to go back one more level each time.
6083     for (
6084         my $i = $skip ;
6085         $i < $count
6086         and ( $p, $file, $line, $sub, $h, $context, $e, $r ) = caller($i) ;
6087         $i++
6088     )
6089     {
6090
6091         # Go through the arguments and save them for later.
6092         @a = ();
6093         for my $arg (@args) {
6094             my $type;
6095             if ( not defined $arg ) {    # undefined parameter
6096                 push @a, "undef";
6097             }
6098
6099             elsif ( $nothard and tied $arg ) {    # tied parameter
6100                 push @a, "tied";
6101             }
6102             elsif ( $nothard and $type = ref $arg ) {    # reference
6103                 push @a, "ref($type)";
6104             }
6105             else {                                       # can be stringified
6106                 local $_ =
6107                   "$arg";    # Safe to stringify now - should not call f().
6108
6109                 # Backslash any single-quotes or backslashes.
6110                 s/([\'\\])/\\$1/g;
6111
6112                 # Single-quote it unless it's a number or a colon-separated
6113                 # name.
6114                 s/(.*)/'$1'/s
6115                   unless /^(?: -?[\d.]+ | \*[\w:]* )$/x;
6116
6117                 # Turn high-bit characters into meta-whatever.
6118                 s/([\200-\377])/sprintf("M-%c",ord($1)&0177)/eg;
6119
6120                 # Turn control characters into ^-whatever.
6121                 s/([\0-\37\177])/sprintf("^%c",ord($1)^64)/eg;
6122
6123                 push( @a, $_ );
6124             } ## end else [ if (not defined $arg)
6125         } ## end for $arg (@args)
6126
6127         # If context is true, this is array (@)context.
6128         # If context is false, this is scalar ($) context.
6129         # If neither, context isn't defined. (This is apparently a 'can't
6130         # happen' trap.)
6131         $context = $context ? '@' : ( defined $context ? "\$" : '.' );
6132
6133         # if the sub has args ($h true), make an anonymous array of the
6134         # dumped args.
6135         $args = $h ? [@a] : undef;
6136
6137         # remove trailing newline-whitespace-semicolon-end of line sequence
6138         # from the eval text, if any.
6139         $e =~ s/\n\s*\;\s*\Z// if $e;
6140
6141         # Escape backslashed single-quotes again if necessary.
6142         $e =~ s/([\\\'])/\\$1/g if $e;
6143
6144         # if the require flag is true, the eval text is from a require.
6145         if ($r) {
6146             $sub = "require '$e'";
6147         }
6148
6149         # if it's false, the eval text is really from an eval.
6150         elsif ( defined $r ) {
6151             $sub = "eval '$e'";
6152         }
6153
6154         # If the sub is '(eval)', this is a block eval, meaning we don't
6155         # know what the eval'ed text actually was.
6156         elsif ( $sub eq '(eval)' ) {
6157             $sub = "eval {...}";
6158         }
6159
6160         # Stick the collected information into @sub as an anonymous hash.
6161         push(
6162             @sub,
6163             {
6164                 context => $context,
6165                 sub     => $sub,
6166                 args    => $args,
6167                 file    => $file,
6168                 line    => $line
6169             }
6170         );
6171
6172         # Stop processing frames if the user hit control-C.
6173         last if $signal;
6174     } ## end for ($i = $skip ; $i < ...
6175
6176     # Restore the trace value again.
6177     $trace = $otrace;
6178     @sub;
6179 } ## end sub dump_trace
6180
6181 =head2 C<action()>
6182
6183 C<action()> takes input provided as the argument to an add-action command,
6184 either pre- or post-, and makes sure it's a complete command. It doesn't do
6185 any fancy parsing; it just keeps reading input until it gets a string
6186 without a trailing backslash.
6187
6188 =cut
6189
6190 sub action {
6191     my $action = shift;
6192
6193     while ( $action =~ s/\\$// ) {
6194
6195         # We have a backslash on the end. Read more.
6196         $action .= &gets;
6197     } ## end while ($action =~ s/\\$//)
6198
6199     # Return the assembled action.
6200     $action;
6201 } ## end sub action
6202
6203 =head2 unbalanced
6204
6205 This routine mostly just packages up a regular expression to be used
6206 to check that the thing it's being matched against has properly-matched
6207 curly braces.
6208
6209 Of note is the definition of the C<$balanced_brace_re> global via C<||=>, which
6210 speeds things up by only creating the qr//'ed expression once; if it's
6211 already defined, we don't try to define it again. A speed hack.
6212
6213 =cut
6214
6215 use vars qw($balanced_brace_re);
6216
6217 sub unbalanced {
6218
6219     # I hate using globals!
6220     $balanced_brace_re ||= qr{
6221         ^ \{
6222              (?:
6223                  (?> [^{}] + )              # Non-parens without backtracking
6224                 |
6225                  (??{ $balanced_brace_re }) # Group with matching parens
6226               ) *
6227           \} $
6228    }x;
6229     return $_[0] !~ m/$balanced_brace_re/;
6230 } ## end sub unbalanced
6231
6232 =head2 C<gets()>
6233
6234 C<gets()> is a primitive (very primitive) routine to read continuations.
6235 It was devised for reading continuations for actions.
6236 it just reads more input with C<readline()> and returns it.
6237
6238 =cut
6239
6240 sub gets {
6241     &readline("cont: ");
6242 }
6243
6244 =head2 C<DB::system()> - handle calls to<system()> without messing up the debugger
6245
6246 The C<system()> function assumes that it can just go ahead and use STDIN and
6247 STDOUT, but under the debugger, we want it to use the debugger's input and
6248 outout filehandles.
6249
6250 C<DB::system()> socks away the program's STDIN and STDOUT, and then substitutes
6251 the debugger's IN and OUT filehandles for them. It does the C<system()> call,
6252 and then puts everything back again.
6253
6254 =cut
6255
6256 sub system {
6257
6258     # We save, change, then restore STDIN and STDOUT to avoid fork() since
6259     # some non-Unix systems can do system() but have problems with fork().
6260     open( SAVEIN,  "<&STDIN" )  || &warn("Can't save STDIN");
6261     open( SAVEOUT, ">&STDOUT" ) || &warn("Can't save STDOUT");
6262     open( STDIN,   "<&IN" )     || &warn("Can't redirect STDIN");
6263     open( STDOUT,  ">&OUT" )    || &warn("Can't redirect STDOUT");
6264
6265     # XXX: using csh or tcsh destroys sigint retvals!
6266     system(@_);
6267     open( STDIN,  "<&SAVEIN" )  || &warn("Can't restore STDIN");
6268     open( STDOUT, ">&SAVEOUT" ) || &warn("Can't restore STDOUT");
6269     close(SAVEIN);
6270     close(SAVEOUT);
6271
6272     # most of the $? crud was coping with broken cshisms
6273     if ( $? >> 8 ) {
6274         &warn( "(Command exited ", ( $? >> 8 ), ")\n" );
6275     }
6276     elsif ($?) {
6277         &warn(
6278             "(Command died of SIG#",
6279             ( $? & 127 ),
6280             ( ( $? & 128 ) ? " -- core dumped" : "" ),
6281             ")", "\n"
6282         );
6283     } ## end elsif ($?)
6284
6285     return $?;
6286
6287 } ## end sub system
6288
6289 =head1 TTY MANAGEMENT
6290
6291 The subs here do some of the terminal management for multiple debuggers.
6292
6293 =head2 setterm
6294
6295 Top-level function called when we want to set up a new terminal for use
6296 by the debugger.
6297
6298 If the C<noTTY> debugger option was set, we'll either use the terminal
6299 supplied (the value of the C<noTTY> option), or we'll use C<Term::Rendezvous>
6300 to find one. If we're a forked debugger, we call C<resetterm> to try to
6301 get a whole new terminal if we can.
6302
6303 In either case, we set up the terminal next. If the C<ReadLine> option was
6304 true, we'll get a C<Term::ReadLine> object for the current terminal and save
6305 the appropriate attributes. We then
6306
6307 =cut
6308
6309 use vars qw($ornaments);
6310 use vars qw($rl_attribs);
6311
6312 sub setterm {
6313
6314     # Load Term::Readline, but quietly; don't debug it and don't trace it.
6315     local $frame = 0;
6316     local $doret = -2;
6317     require Term::ReadLine;
6318
6319     # If noTTY is set, but we have a TTY name, go ahead and hook up to it.
6320     if ($notty) {
6321         if ($tty) {
6322             my ( $i, $o ) = split $tty, /,/;
6323             $o = $i unless defined $o;
6324             open( IN,  "<$i" ) or die "Cannot open TTY '$i' for read: $!";
6325             open( OUT, ">$o" ) or die "Cannot open TTY '$o' for write: $!";
6326             $IN  = \*IN;
6327             $OUT = \*OUT;
6328             $OUT->autoflush(1);
6329         } ## end if ($tty)
6330
6331         # We don't have a TTY - try to find one via Term::Rendezvous.
6332         else {
6333             require Term::Rendezvous;
6334
6335             # See if we have anything to pass to Term::Rendezvous.
6336             # Use $HOME/.perldbtty$$ if not.
6337             my $rv = $ENV{PERLDB_NOTTY} || "$ENV{HOME}/.perldbtty$$";
6338
6339             # Rendezvous and get the filehandles.
6340             my $term_rv = Term::Rendezvous->new( $rv );
6341             $IN  = $term_rv->IN;
6342             $OUT = $term_rv->OUT;
6343         } ## end else [ if ($tty)
6344     } ## end if ($notty)
6345
6346     # We're a daughter debugger. Try to fork off another TTY.
6347     if ( $term_pid eq '-1' ) {    # In a TTY with another debugger
6348         resetterm(2);
6349     }
6350
6351     # If we shouldn't use Term::ReadLine, don't.
6352     if ( !$rl ) {
6353         $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
6354     }
6355
6356     # We're using Term::ReadLine. Get all the attributes for this terminal.
6357     else {
6358         $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
6359
6360         $rl_attribs = $term->Attribs;
6361         $rl_attribs->{basic_word_break_characters} .= '-:+/*,[])}'
6362           if defined $rl_attribs->{basic_word_break_characters}
6363           and index( $rl_attribs->{basic_word_break_characters}, ":" ) == -1;
6364         $rl_attribs->{special_prefixes} = '$@&%';
6365         $rl_attribs->{completer_word_break_characters} .= '$@&%';
6366         $rl_attribs->{completion_function} = \&db_complete;
6367     } ## end else [ if (!$rl)
6368
6369     # Set up the LINEINFO filehandle.
6370     $LINEINFO = $OUT     unless defined $LINEINFO;
6371     $lineinfo = $console unless defined $lineinfo;
6372
6373     $term->MinLine(2);
6374
6375     &load_hist();
6376
6377     if ( $term->Features->{setHistory} and "@hist" ne "?" ) {
6378         $term->SetHistory(@hist);
6379     }
6380
6381     # XXX Ornaments are turned on unconditionally, which is not
6382     # always a good thing.
6383     ornaments($ornaments) if defined $ornaments;
6384     $term_pid = $$;
6385 } ## end sub setterm
6386
6387 sub load_hist {
6388     $histfile //= option_val("HistFile", undef);
6389     return unless defined $histfile;
6390     open my $fh, "<", $histfile or return;
6391     local $/ = "\n";
6392     @hist = ();
6393     while (<$fh>) {
6394         chomp;
6395         push @hist, $_;
6396     }
6397     close $fh;
6398 }
6399
6400 sub save_hist {
6401     return unless defined $histfile;
6402     eval { require File::Path } or return;
6403     eval { require File::Basename } or return;
6404     File::Path::mkpath(File::Basename::dirname($histfile));
6405     open my $fh, ">", $histfile or die "Could not open '$histfile': $!";
6406     $histsize //= option_val("HistSize",100);
6407     my @copy = grep { $_ ne '?' } @hist;
6408     my $start = scalar(@copy) > $histsize ? scalar(@copy)-$histsize : 0;
6409     for ($start .. $#copy) {
6410         print $fh "$copy[$_]\n";
6411     }
6412     close $fh or die "Could not write '$histfile': $!";
6413 }
6414
6415 =head1 GET_FORK_TTY EXAMPLE FUNCTIONS
6416
6417 When the process being debugged forks, or the process invokes a command
6418 via C<system()> which starts a new debugger, we need to be able to get a new
6419 C<IN> and C<OUT> filehandle for the new debugger. Otherwise, the two processes
6420 fight over the terminal, and you can never quite be sure who's going to get the
6421 input you're typing.
6422
6423 C<get_fork_TTY> is a glob-aliased function which calls the real function that
6424 is tasked with doing all the necessary operating system mojo to get a new
6425 TTY (and probably another window) and to direct the new debugger to read and
6426 write there.
6427
6428 The debugger provides C<get_fork_TTY> functions which work for TCP
6429 socket servers, X11, OS/2, and Mac OS X. Other systems are not
6430 supported. You are encouraged to write C<get_fork_TTY> functions which
6431 work for I<your> platform and contribute them.
6432
6433 =head3 C<socket_get_fork_TTY>
6434
6435 =cut
6436
6437 sub connect_remoteport {
6438     require IO::Socket;
6439
6440     my $socket = IO::Socket::INET->new(
6441         Timeout  => '10',
6442         PeerAddr => $remoteport,
6443         Proto    => 'tcp',
6444     );
6445     if ( ! $socket ) {
6446         die "Unable to connect to remote host: $remoteport\n";
6447     }
6448     return $socket;
6449 }
6450
6451 sub socket_get_fork_TTY {
6452     $tty = $LINEINFO = $IN = $OUT = connect_remoteport();
6453
6454     # Do I need to worry about setting $term?
6455
6456     reset_IN_OUT( $IN, $OUT );
6457     return '';
6458 }
6459
6460 =head3 C<xterm_get_fork_TTY>
6461
6462 This function provides the C<get_fork_TTY> function for X11. If a
6463 program running under the debugger forks, a new <xterm> window is opened and
6464 the subsidiary debugger is directed there.
6465
6466 The C<open()> call is of particular note here. We have the new C<xterm>
6467 we're spawning route file number 3 to STDOUT, and then execute the C<tty>
6468 command (which prints the device name of the TTY we'll want to use for input
6469 and output to STDOUT, then C<sleep> for a very long time, routing this output
6470 to file number 3. This way we can simply read from the <XT> filehandle (which
6471 is STDOUT from the I<commands> we ran) to get the TTY we want to use.
6472
6473 Only works if C<xterm> is in your path and C<$ENV{DISPLAY}>, etc. are
6474 properly set up.
6475
6476 =cut
6477
6478 sub xterm_get_fork_TTY {
6479     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6480     open XT,
6481 qq[3>&1 xterm -title "Daughter Perl debugger $pids $name" -e sh -c 'tty 1>&3;\
6482  sleep 10000000' |];
6483
6484     # Get the output from 'tty' and clean it up a little.
6485     my $tty = <XT>;
6486     chomp $tty;
6487
6488     $pidprompt = '';    # Shown anyway in titlebar
6489
6490     # We need $term defined or we can not switch to the newly created xterm
6491     if ($tty ne '' && !defined $term) {
6492         require Term::ReadLine;
6493         if ( !$rl ) {
6494             $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
6495         }
6496         else {
6497             $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
6498         }
6499     }
6500     # There's our new TTY.
6501     return $tty;
6502 } ## end sub xterm_get_fork_TTY
6503
6504 =head3 C<os2_get_fork_TTY>
6505
6506 XXX It behooves an OS/2 expert to write the necessary documentation for this!
6507
6508 =cut
6509
6510 # This example function resets $IN, $OUT itself
6511 my $c_pipe = 0;
6512 sub os2_get_fork_TTY { # A simplification of the following (and works without):
6513     local $\  = '';
6514     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6515     my %opt = ( title => "Daughter Perl debugger $pids $name",
6516         ($rl ? (read_by_key => 1) : ()) );
6517     require OS2::Process;
6518     my ($in, $out, $pid) = eval { OS2::Process::io_term(related => 0, %opt) }
6519       or return;
6520     $pidprompt = '';    # Shown anyway in titlebar
6521     reset_IN_OUT($in, $out);
6522     $tty = '*reset*';
6523     return '';          # Indicate that reset_IN_OUT is called
6524 } ## end sub os2_get_fork_TTY
6525
6526 =head3 C<macosx_get_fork_TTY>
6527
6528 The Mac OS X version uses AppleScript to tell Terminal.app to create
6529 a new window.
6530
6531 =cut
6532
6533 # Notes about Terminal.app's AppleScript support,
6534 # (aka things that might break in future OS versions).
6535 #
6536 # The "do script" command doesn't return a reference to the new window
6537 # it creates, but since it appears frontmost and windows are enumerated
6538 # front to back, we can use "first window" === "window 1".
6539 #
6540 # Since "do script" is implemented by supplying the argument (plus a
6541 # return character) as terminal input, there's a potential race condition
6542 # where the debugger could beat the shell to reading the command.
6543 # To prevent this, we wait for the screen to clear before proceeding.
6544 #
6545 # 10.3 and 10.4:
6546 # There's no direct accessor for the tty device name, so we fiddle
6547 # with the window title options until it says what we want.
6548 #
6549 # 10.5:
6550 # There _is_ a direct accessor for the tty device name, _and_ there's
6551 # a new possible component of the window title (the name of the settings
6552 # set).  A separate version is needed.
6553
6554 my @script_versions=
6555
6556     ([237, <<'__LEOPARD__'],
6557 tell application "Terminal"
6558     do script "clear;exec sleep 100000"
6559     tell first tab of first window
6560         copy tty to thetty
6561         set custom title to "forked perl debugger"
6562         set title displays custom title to true
6563         repeat while (length of first paragraph of (get contents)) > 0
6564             delay 0.1
6565         end repeat
6566     end tell
6567 end tell
6568 thetty
6569 __LEOPARD__
6570
6571      [100, <<'__JAGUAR_TIGER__'],
6572 tell application "Terminal"
6573     do script "clear;exec sleep 100000"
6574     tell first window
6575         set title displays shell path to false
6576         set title displays window size to false
6577         set title displays file name to false
6578         set title displays device name to true
6579         set title displays custom title to true
6580         set custom title to ""
6581         copy "/dev/" & name to thetty
6582         set custom title to "forked perl debugger"
6583         repeat while (length of first paragraph of (get contents)) > 0
6584             delay 0.1
6585         end repeat
6586     end tell
6587 end tell
6588 thetty
6589 __JAGUAR_TIGER__
6590
6591 );
6592
6593 sub macosx_get_fork_TTY
6594 {
6595     my($version,$script,$pipe,$tty);
6596
6597     return unless $version=$ENV{TERM_PROGRAM_VERSION};
6598     foreach my $entry (@script_versions) {
6599         if ($version>=$entry->[0]) {
6600             $script=$entry->[1];
6601             last;
6602         }
6603     }
6604     return unless defined($script);
6605     return unless open($pipe,'-|','/usr/bin/osascript','-e',$script);
6606     $tty=readline($pipe);
6607     close($pipe);
6608     return unless defined($tty) && $tty =~ m(^/dev/);
6609     chomp $tty;
6610     return $tty;
6611 }
6612
6613 =head2 C<create_IN_OUT($flags)>
6614
6615 Create a new pair of filehandles, pointing to a new TTY. If impossible,
6616 try to diagnose why.
6617
6618 Flags are:
6619
6620 =over 4
6621
6622 =item * 1 - Don't know how to create a new TTY.
6623
6624 =item * 2 - Debugger has forked, but we can't get a new TTY.
6625
6626 =item * 4 - standard debugger startup is happening.
6627
6628 =back
6629
6630 =cut
6631
6632 use vars qw($fork_TTY);
6633
6634 sub create_IN_OUT {    # Create a window with IN/OUT handles redirected there
6635
6636     # If we know how to get a new TTY, do it! $in will have
6637     # the TTY name if get_fork_TTY works.
6638     my $in = &get_fork_TTY if defined &get_fork_TTY;
6639
6640     # It used to be that
6641     $in = $fork_TTY if defined $fork_TTY;    # Backward compatibility
6642
6643     if ( not defined $in ) {
6644         my $why = shift;
6645
6646         # We don't know how.
6647         print_help(<<EOP) if $why == 1;
6648 I<#########> Forked, but do not know how to create a new B<TTY>. I<#########>
6649 EOP
6650
6651         # Forked debugger.
6652         print_help(<<EOP) if $why == 2;
6653 I<#########> Daughter session, do not know how to change a B<TTY>. I<#########>
6654   This may be an asynchronous session, so the parent debugger may be active.
6655 EOP
6656
6657         # Note that both debuggers are fighting over the same input.
6658         print_help(<<EOP) if $why != 4;
6659   Since two debuggers fight for the same TTY, input is severely entangled.
6660
6661 EOP
6662         print_help(<<EOP);
6663   I know how to switch the output to a different window in xterms, OS/2
6664   consoles, and Mac OS X Terminal.app only.  For a manual switch, put the name
6665   of the created I<TTY> in B<\$DB::fork_TTY>, or define a function
6666   B<DB::get_fork_TTY()> returning this.
6667
6668   On I<UNIX>-like systems one can get the name of a I<TTY> for the given window
6669   by typing B<tty>, and disconnect the I<shell> from I<TTY> by B<sleep 1000000>.
6670
6671 EOP
6672     } ## end if (not defined $in)
6673     elsif ( $in ne '' ) {
6674         TTY($in);
6675     }
6676     else {
6677         $console = '';    # Indicate no need to open-from-the-console
6678     }
6679     undef $fork_TTY;
6680 } ## end sub create_IN_OUT
6681
6682 =head2 C<resetterm>
6683
6684 Handles rejiggering the prompt when we've forked off a new debugger.
6685
6686 If the new debugger happened because of a C<system()> that invoked a
6687 program under the debugger, the arrow between the old pid and the new
6688 in the prompt has I<two> dashes instead of one.
6689
6690 We take the current list of pids and add this one to the end. If there
6691 isn't any list yet, we make one up out of the initial pid associated with
6692 the terminal and our new pid, sticking an arrow (either one-dashed or
6693 two dashed) in between them.
6694
6695 If C<CreateTTY> is off, or C<resetterm> was called with no arguments,
6696 we don't try to create a new IN and OUT filehandle. Otherwise, we go ahead
6697 and try to do that.
6698
6699 =cut
6700
6701 sub resetterm {    # We forked, so we need a different TTY
6702
6703     # Needs to be passed to create_IN_OUT() as well.
6704     my $in = shift;
6705
6706     # resetterm(2): got in here because of a system() starting a debugger.
6707     # resetterm(1): just forked.
6708     my $systemed = $in > 1 ? '-' : '';
6709
6710     # If there's already a list of pids, add this to the end.
6711     if ($pids) {
6712         $pids =~ s/\]/$systemed->$$]/;
6713     }
6714
6715     # No pid list. Time to make one.
6716     else {
6717         $pids = "[$term_pid->$$]";
6718     }
6719
6720     # The prompt we're going to be using for this debugger.
6721     $pidprompt = $pids;
6722
6723     # We now 0wnz this terminal.
6724     $term_pid = $$;
6725
6726     # Just return if we're not supposed to try to create a new TTY.
6727     return unless $CreateTTY & $in;
6728
6729     # Try to create a new IN/OUT pair.
6730     create_IN_OUT($in);
6731 } ## end sub resetterm
6732
6733 =head2 C<readline>
6734
6735 First, we handle stuff in the typeahead buffer. If there is any, we shift off
6736 the next line, print a message saying we got it, add it to the terminal
6737 history (if possible), and return it.
6738
6739 If there's nothing in the typeahead buffer, check the command filehandle stack.
6740 If there are any filehandles there, read from the last one, and return the line
6741 if we got one. If not, we pop the filehandle off and close it, and try the
6742 next one up the stack.
6743
6744 If we've emptied the filehandle stack, we check to see if we've got a socket
6745 open, and we read that and return it if we do. If we don't, we just call the
6746 core C<readline()> and return its value.
6747
6748 =cut
6749
6750 sub readline {
6751
6752     # Localize to prevent it from being smashed in the program being debugged.
6753     local $.;
6754
6755     # If there are stacked filehandles to read from ...
6756     # (Handle it before the typeahead, because we may call source/etc. from
6757     # the typeahead.)
6758     while (@cmdfhs) {
6759
6760         # Read from the last one in the stack.
6761         my $line = CORE::readline( $cmdfhs[-1] );
6762
6763         # If we got a line ...
6764         defined $line
6765           ? ( print $OUT ">> $line" and return $line )    # Echo and return
6766           : close pop @cmdfhs;                            # Pop and close
6767     } ## end while (@cmdfhs)
6768
6769     # Pull a line out of the typeahead if there's stuff there.
6770     if (@typeahead) {
6771
6772         # How many lines left.
6773         my $left = @typeahead;
6774
6775         # Get the next line.
6776         my $got = shift @typeahead;
6777
6778         # Print a message saying we got input from the typeahead.
6779         local $\ = '';
6780         print $OUT "auto(-$left)", shift, $got, "\n";
6781
6782         # Add it to the terminal history (if possible).
6783         $term->AddHistory($got)
6784           if length($got) > 1
6785           and defined $term->Features->{addHistory};
6786         return $got;
6787     } ## end if (@typeahead)
6788
6789     # We really need to read some input. Turn off entry/exit trace and
6790     # return value printing.
6791     local $frame = 0;
6792     local $doret = -2;
6793
6794     # Nothing on the filehandle stack. Socket?
6795     if ( ref $OUT and UNIVERSAL::isa( $OUT, 'IO::Socket::INET' ) ) {
6796
6797         # Send anything we have to send.
6798         $OUT->write( join( '', @_ ) );
6799
6800         # Receive anything there is to receive.
6801         my $stuff = '';
6802         my $buf;
6803         my $first_time = 1;
6804
6805         while ($first_time or (length($buf) && ($stuff .= $buf) !~ /\n/))
6806         {
6807             $first_time = 0;
6808             $IN->recv( $buf = '', 2048 );   # XXX "what's wrong with sysread?"
6809                                             # XXX Don't know. You tell me.
6810         }
6811
6812         # What we got.
6813         return $stuff;
6814     } ## end if (ref $OUT and UNIVERSAL::isa...
6815
6816     # No socket. Just read from the terminal.
6817     else {
6818         return $term->readline(@_);
6819     }
6820 } ## end sub readline
6821
6822 =head1 OPTIONS SUPPORT ROUTINES
6823
6824 These routines handle listing and setting option values.
6825
6826 =head2 C<dump_option> - list the current value of an option setting
6827
6828 This routine uses C<option_val> to look up the value for an option.
6829 It cleans up escaped single-quotes and then displays the option and
6830 its value.
6831
6832 =cut
6833
6834 sub dump_option {
6835     my ( $opt, $val ) = @_;
6836     $val = option_val( $opt, 'N/A' );
6837     $val =~ s/([\\\'])/\\$1/g;
6838     printf $OUT "%20s = '%s'\n", $opt, $val;
6839 } ## end sub dump_option
6840
6841 sub options2remember {
6842     foreach my $k (@RememberOnROptions) {
6843         $option{$k} = option_val( $k, 'N/A' );
6844     }
6845     return %option;
6846 }
6847
6848 =head2 C<option_val> - find the current value of an option
6849
6850 This can't just be a simple hash lookup because of the indirect way that
6851 the option values are stored. Some are retrieved by calling a subroutine,
6852 some are just variables.
6853
6854 You must supply a default value to be used in case the option isn't set.
6855
6856 =cut
6857
6858 sub option_val {
6859     my ( $opt, $default ) = @_;
6860     my $val;
6861
6862     # Does this option exist, and is it a variable?
6863     # If so, retrieve the value via the value in %optionVars.
6864     if (    defined $optionVars{$opt}
6865         and defined ${ $optionVars{$opt} } )
6866     {
6867         $val = ${ $optionVars{$opt} };
6868     }
6869
6870     # Does this option exist, and it's a subroutine?
6871     # If so, call the subroutine via the ref in %optionAction
6872     # and capture the value.
6873     elsif ( defined $optionAction{$opt}
6874         and defined &{ $optionAction{$opt} } )
6875     {
6876         $val = &{ $optionAction{$opt} }();
6877     }
6878
6879     # If there's an action or variable for the supplied option,
6880     # but no value was set, use the default.
6881     elsif (defined $optionAction{$opt} and not defined $option{$opt}
6882         or defined $optionVars{$opt} and not defined ${ $optionVars{$opt} } )
6883     {
6884         $val = $default;
6885     }
6886
6887     # Otherwise, do the simple hash lookup.
6888     else {
6889         $val = $option{$opt};
6890     }
6891
6892     # If the value isn't defined, use the default.
6893     # Then return whatever the value is.
6894     $val = $default unless defined $val;
6895     $val;
6896 } ## end sub option_val
6897
6898 =head2 C<parse_options>
6899
6900 Handles the parsing and execution of option setting/displaying commands.
6901
6902 An option entered by itself is assumed to be I<set me to 1> (the default value)
6903 if the option is a boolean one. If not, the user is prompted to enter a valid
6904 value or to query the current value (via C<option? >).
6905
6906 If C<option=value> is entered, we try to extract a quoted string from the
6907 value (if it is quoted). If it's not, we just use the whole value as-is.
6908
6909 We load any modules required to service this option, and then we set it: if
6910 it just gets stuck in a variable, we do that; if there's a subroutine to
6911 handle setting the option, we call that.
6912
6913 Finally, if we're running in interactive mode, we display the effect of the
6914 user's command back to the terminal, skipping this if we're setting things
6915 during initialization.
6916
6917 =cut
6918
6919 sub parse_options {
6920     my ($s) = @_;
6921     local $\ = '';
6922
6923     my $option;
6924
6925     # These options need a value. Don't allow them to be clobbered by accident.
6926     my %opt_needs_val = map { ( $_ => 1 ) } qw{
6927       dumpDepth arrayDepth hashDepth LineInfo maxTraceLen ornaments windowSize
6928       pager quote ReadLine recallCommand RemotePort ShellBang TTY CommandSet
6929     };
6930
6931     while (length($s)) {
6932         my $val_defaulted;
6933
6934         # Clean off excess leading whitespace.
6935         $s =~ s/^\s+// && next;
6936
6937         # Options are always all word characters, followed by a non-word
6938         # separator.
6939         if ($s !~ s/^(\w+)(\W?)//) {
6940             print {$OUT} "Invalid option '$s'\n";
6941             last;
6942         }
6943         my ( $opt, $sep ) = ( $1, $2 );
6944
6945         # Make sure that such an option exists.
6946         my $matches = ( grep { /^\Q$opt/ && ( $option = $_ ) } @options )
6947           || ( grep { /^\Q$opt/i && ( $option = $_ ) } @options );
6948
6949         unless ($matches) {
6950             print {$OUT} "Unknown option '$opt'\n";
6951             next;
6952         }
6953         if ($matches > 1) {
6954             print {$OUT} "Ambiguous option '$opt'\n";
6955             next;
6956         }
6957         my $val;
6958
6959         # '?' as separator means query, but must have whitespace after it.
6960         if ( "?" eq $sep ) {
6961             if ($s =~ /\A\S/) {
6962                 print {$OUT} "Option query '$opt?' followed by non-space '$s'\n" ;
6963
6964                 last;
6965             }
6966
6967             #&dump_option($opt);
6968         } ## end if ("?" eq $sep)
6969
6970         # Separator is whitespace (or just a carriage return).
6971         # They're going for a default, which we assume is 1.
6972         elsif ( $sep !~ /\S/ ) {
6973             $val_defaulted = 1;
6974             $val           = "1";   #  this is an evil default; make 'em set it!
6975         }
6976
6977         # Separator is =. Trying to set a value.
6978         elsif ( $sep eq "=" ) {
6979
6980             # If quoted, extract a quoted string.
6981             if ($s =~ s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x) {
6982                 my $quote = $1;
6983                 ( $val = $2 ) =~ s/\\([$quote\\])/$1/g;
6984             }
6985
6986             # Not quoted. Use the whole thing. Warn about 'option='.
6987             else {
6988                 $s =~ s/^(\S*)//;
6989                 $val = $1;
6990                 print OUT qq(Option better cleared using $opt=""\n)
6991                   unless length $val;
6992             } ## end else [ if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x)
6993
6994         } ## end elsif ($sep eq "=")
6995
6996         # "Quoted" with [], <>, or {}.
6997         else {    #{ to "let some poor schmuck bounce on the % key in B<vi>."
6998             my ($end) =
6999               "\\" . substr( ")]>}$sep", index( "([<{", $sep ), 1 );    #}
7000             $s =~ s/^(([^\\$end]|\\[\\$end])*)$end($|\s+)//
7001               or print( $OUT "Unclosed option value '$opt$sep$_'\n" ), last;
7002             ( $val = $1 ) =~ s/\\([\\$end])/$1/g;
7003         } ## end else [ if ("?" eq $sep)
7004
7005         # Exclude non-booleans from getting set to 1 by default.
7006         if ( $opt_needs_val{$option} && $val_defaulted ) {
7007             my $cmd = ( $CommandSet eq '580' ) ? 'o' : 'O';
7008             print {$OUT}
7009 "Option '$opt' is non-boolean.  Use '$cmd $option=VAL' to set, '$cmd $option?' to query\n";
7010             next;
7011         } ## end if ($opt_needs_val{$option...
7012
7013         # Save the option value.
7014         $option{$option} = $val if defined $val;
7015
7016         # Load any module that this option requires.
7017         if ( defined($optionRequire{$option}) && defined($val) ) {
7018             eval qq{
7019             local \$frame = 0;
7020             local \$doret = -2;
7021             require '$optionRequire{$option}';
7022             1;
7023             } || die $@   # XXX: shouldn't happen
7024         }
7025
7026         # Set it.
7027         # Stick it in the proper variable if it goes in a variable.
7028         if (defined($optionVars{$option}) && defined($val)) {
7029             ${ $optionVars{$option} } = $val;
7030         }
7031
7032         # Call the appropriate sub if it gets set via sub.
7033         if (defined($optionAction{$option})
7034           && defined (&{ $optionAction{$option} })
7035           && defined ($val))
7036         {
7037           &{ $optionAction{$option} }($val);
7038         }
7039
7040         # Not initialization - echo the value we set it to.
7041         dump_option($option) if ($OUT ne \*STDERR);
7042     } ## end while (length)
7043 } ## end sub parse_options
7044
7045 =head1 RESTART SUPPORT
7046
7047 These routines are used to store (and restore) lists of items in environment
7048 variables during a restart.
7049
7050 =head2 set_list
7051
7052 Set_list packages up items to be stored in a set of environment variables
7053 (VAR_n, containing the number of items, and VAR_0, VAR_1, etc., containing
7054 the values). Values outside the standard ASCII charset are stored by encoding
7055 then as hexadecimal values.
7056
7057 =cut
7058
7059 sub set_list {
7060     my ( $stem, @list ) = @_;
7061     my $val;
7062
7063     # VAR_n: how many we have. Scalar assignment gets the number of items.
7064     $ENV{"${stem}_n"} = @list;
7065
7066     # Grab each item in the list, escape the backslashes, encode the non-ASCII
7067     # as hex, and then save in the appropriate VAR_0, VAR_1, etc.
7068     for my $i ( 0 .. $#list ) {
7069         $val = $list[$i];
7070         $val =~ s/\\/\\\\/g;
7071         $val =~ s/([\0-\37\177\200-\377])/"\\0x" . unpack('H2',$1)/eg;
7072         $ENV{"${stem}_$i"} = $val;
7073     } ## end for $i (0 .. $#list)
7074 } ## end sub set_list
7075
7076 =head2 get_list
7077
7078 Reverse the set_list operation: grab VAR_n to see how many we should be getting
7079 back, and then pull VAR_0, VAR_1. etc. back out.
7080
7081 =cut
7082
7083 sub get_list {
7084     my $stem = shift;
7085     my @list;
7086     my $n = delete $ENV{"${stem}_n"};
7087     my $val;
7088     for my $i ( 0 .. $n - 1 ) {
7089         $val = delete $ENV{"${stem}_$i"};
7090         $val =~ s/\\((\\)|0x(..))/ $2 ? $2 : pack('H2', $3) /ge;
7091         push @list, $val;
7092     }
7093     @list;
7094 } ## end sub get_list
7095
7096 =head1 MISCELLANEOUS SIGNAL AND I/O MANAGEMENT
7097
7098 =head2 catch()
7099
7100 The C<catch()> subroutine is the essence of fast and low-impact. We simply
7101 set an already-existing global scalar variable to a constant value. This
7102 avoids allocating any memory possibly in the middle of something that will
7103 get all confused if we do, particularly under I<unsafe signals>.
7104
7105 =cut
7106
7107 sub catch {
7108     $signal = 1;
7109     return;    # Put nothing on the stack - malloc/free land!
7110 }
7111
7112 =head2 C<warn()>
7113
7114 C<warn> emits a warning, by joining together its arguments and printing
7115 them, with couple of fillips.
7116
7117 If the composited message I<doesn't> end with a newline, we automatically
7118 add C<$!> and a newline to the end of the message. The subroutine expects $OUT
7119 to be set to the filehandle to be used to output warnings; it makes no
7120 assumptions about what filehandles are available.
7121
7122 =cut
7123
7124 sub warn {
7125     my ($msg) = join( "", @_ );
7126     $msg .= ": $!\n" unless $msg =~ /\n$/;
7127     local $\ = '';
7128     print $OUT $msg;
7129 } ## end sub warn
7130
7131 =head1 INITIALIZATION TTY SUPPORT
7132
7133 =head2 C<reset_IN_OUT>
7134
7135 This routine handles restoring the debugger's input and output filehandles
7136 after we've tried and failed to move them elsewhere.  In addition, it assigns
7137 the debugger's output filehandle to $LINEINFO if it was already open there.
7138
7139 =cut
7140
7141 sub reset_IN_OUT {
7142     my $switch_li = $LINEINFO eq $OUT;
7143
7144     # If there's a term and it's able to get a new tty, try to get one.
7145     if ( $term and $term->Features->{newTTY} ) {
7146         ( $IN, $OUT ) = ( shift, shift );
7147         $term->newTTY( $IN, $OUT );
7148     }
7149
7150     # This term can't get a new tty now. Better luck later.
7151     elsif ($term) {
7152         &warn("Too late to set IN/OUT filehandles, enabled on next 'R'!\n");
7153     }
7154
7155     # Set the filehndles up as they were.
7156     else {
7157         ( $IN, $OUT ) = ( shift, shift );
7158     }
7159
7160     # Unbuffer the output filehandle.
7161     $OUT->autoflush(1);
7162
7163     # Point LINEINFO to the same output filehandle if it was there before.
7164     $LINEINFO = $OUT if $switch_li;
7165 } ## end sub reset_IN_OUT
7166
7167 =head1 OPTION SUPPORT ROUTINES
7168
7169 The following routines are used to process some of the more complicated
7170 debugger options.
7171
7172 =head2 C<TTY>
7173
7174 Sets the input and output filehandles to the specified files or pipes.
7175 If the terminal supports switching, we go ahead and do it. If not, and
7176 there's already a terminal in place, we save the information to take effect
7177 on restart.
7178
7179 If there's no terminal yet (for instance, during debugger initialization),
7180 we go ahead and set C<$console> and C<$tty> to the file indicated.
7181
7182 =cut
7183
7184 sub TTY {
7185
7186     if ( @_ and $term and $term->Features->{newTTY} ) {
7187
7188         # This terminal supports switching to a new TTY.
7189         # Can be a list of two files, or on string containing both names,
7190         # comma-separated.
7191         # XXX Should this perhaps be an assignment from @_?
7192         my ( $in, $out ) = shift;
7193         if ( $in =~ /,/ ) {
7194
7195             # Split list apart if supplied.
7196             ( $in, $out ) = split /,/, $in, 2;
7197         }
7198         else {
7199
7200             # Use the same file for both input and output.
7201             $out = $in;
7202         }
7203
7204         # Open file onto the debugger's filehandles, if you can.
7205         open IN,  $in     or die "cannot open '$in' for read: $!";
7206         open OUT, ">$out" or die "cannot open '$out' for write: $!";
7207
7208         # Swap to the new filehandles.
7209         reset_IN_OUT( \*IN, \*OUT );
7210
7211         # Save the setting for later.
7212         return $tty = $in;
7213     } ## end if (@_ and $term and $term...
7214
7215     # Terminal doesn't support new TTY, or doesn't support readline.
7216     # Can't do it now, try restarting.
7217     &warn("Too late to set TTY, enabled on next 'R'!\n") if $term and @_;
7218
7219     # Useful if done through PERLDB_OPTS:
7220     $console = $tty = shift if @_;
7221
7222     # Return whatever the TTY is.
7223     $tty or $console;
7224 } ## end sub TTY
7225
7226 =head2 C<noTTY>
7227
7228 Sets the C<$notty> global, controlling whether or not the debugger tries to
7229 get a terminal to read from. If called after a terminal is already in place,
7230 we save the value to use it if we're restarted.
7231
7232 =cut
7233
7234 sub noTTY {
7235     if ($term) {
7236         &warn("Too late to set noTTY, enabled on next 'R'!\n") if @_;
7237     }
7238     $notty = shift if @_;
7239     $notty;
7240 } ## end sub noTTY
7241
7242 =head2 C<ReadLine>
7243
7244 Sets the C<$rl> option variable. If 0, we use C<Term::ReadLine::Stub>
7245 (essentially, no C<readline> processing on this I<terminal>). Otherwise, we
7246 use C<Term::ReadLine>. Can't be changed after a terminal's in place; we save
7247 the value in case a restart is done so we can change it then.
7248
7249 =cut
7250
7251 sub ReadLine {
7252     if ($term) {
7253         &warn("Too late to set ReadLine, enabled on next 'R'!\n") if @_;
7254     }
7255     $rl = shift if @_;
7256     $rl;
7257 } ## end sub ReadLine
7258
7259 =head2 C<RemotePort>
7260
7261 Sets the port that the debugger will try to connect to when starting up.
7262 If the terminal's already been set up, we can't do it, but we remember the
7263 setting in case the user does a restart.
7264
7265 =cut
7266
7267 sub RemotePort {
7268     if ($term) {
7269         &warn("Too late to set RemotePort, enabled on next 'R'!\n") if @_;
7270     }
7271     $remoteport = shift if @_;
7272     $remoteport;
7273 } ## end sub RemotePort
7274
7275 =head2 C<tkRunning>
7276
7277 Checks with the terminal to see if C<Tk> is running, and returns true or
7278 false. Returns false if the current terminal doesn't support C<readline>.
7279
7280 =cut
7281
7282 sub tkRunning {
7283     if ( ${ $term->Features }{tkRunning} ) {
7284         return $term->tkRunning(@_);
7285     }
7286     else {
7287         local $\ = '';
7288         print $OUT "tkRunning not supported by current ReadLine package.\n";
7289         0;
7290     }
7291 } ## end sub tkRunning
7292
7293 =head2 C<NonStop>
7294
7295 Sets nonstop mode. If a terminal's already been set up, it's too late; the
7296 debugger remembers the setting in case you restart, though.
7297
7298 =cut
7299
7300 sub NonStop {
7301     if ($term) {
7302         &warn("Too late to set up NonStop mode, enabled on next 'R'!\n")
7303           if @_;
7304     }
7305     $runnonstop = shift if @_;
7306     $runnonstop;
7307 } ## end sub NonStop
7308
7309 sub DollarCaretP {
7310     if ($term) {
7311         &warn("Some flag changes could not take effect until next 'R'!\n")
7312           if @_;
7313     }
7314     $^P = parse_DollarCaretP_flags(shift) if @_;
7315     expand_DollarCaretP_flags($^P);
7316 }
7317
7318 =head2 C<pager>
7319
7320 Set up the C<$pager> variable. Adds a pipe to the front unless there's one
7321 there already.
7322
7323 =cut
7324
7325 sub pager {
7326     if (@_) {
7327         $pager = shift;
7328         $pager = "|" . $pager unless $pager =~ /^(\+?\>|\|)/;
7329     }
7330     $pager;
7331 } ## end sub pager
7332
7333 =head2 C<shellBang>
7334
7335 Sets the shell escape command, and generates a printable copy to be used
7336 in the help.
7337
7338 =cut
7339
7340 sub shellBang {
7341
7342     # If we got an argument, meta-quote it, and add '\b' if it
7343     # ends in a word character.
7344     if (@_) {
7345         $sh = quotemeta shift;
7346         $sh .= "\\b" if $sh =~ /\w$/;
7347     }
7348
7349     # Generate the printable version for the help:
7350     $psh = $sh;    # copy it
7351     $psh =~ s/\\b$//;        # Take off trailing \b if any
7352     $psh =~ s/\\(.)/$1/g;    # De-escape
7353     $psh;                    # return the printable version
7354 } ## end sub shellBang
7355
7356 =head2 C<ornaments>
7357
7358 If the terminal has its own ornaments, fetch them. Otherwise accept whatever
7359 was passed as the argument. (This means you can't override the terminal's
7360 ornaments.)
7361
7362 =cut
7363
7364 sub ornaments {
7365     if ( defined $term ) {
7366
7367         # We don't want to show warning backtraces, but we do want die() ones.
7368         local ( $warnLevel, $dieLevel ) = ( 0, 1 );
7369
7370         # No ornaments if the terminal doesn't support them.
7371         return '' unless $term->Features->{ornaments};
7372         eval { $term->ornaments(@_) } || '';
7373     }
7374
7375     # Use what was passed in if we can't determine it ourselves.
7376     else {
7377         $ornaments = shift;
7378     }
7379 } ## end sub ornaments
7380
7381 =head2 C<recallCommand>
7382
7383 Sets the recall command, and builds a printable version which will appear in
7384 the help text.
7385
7386 =cut
7387
7388 sub recallCommand {
7389
7390     # If there is input, metaquote it. Add '\b' if it ends with a word
7391     # character.
7392     if (@_) {
7393         $rc = quotemeta shift;
7394         $rc .= "\\b" if $rc =~ /\w$/;
7395     }
7396
7397     # Build it into a printable version.
7398     $prc = $rc;    # Copy it
7399     $prc =~ s/\\b$//;        # Remove trailing \b
7400     $prc =~ s/\\(.)/$1/g;    # Remove escapes
7401     $prc;                    # Return the printable version
7402 } ## end sub recallCommand
7403
7404 =head2 C<LineInfo> - where the line number information goes
7405
7406 Called with no arguments, returns the file or pipe that line info should go to.
7407
7408 Called with an argument (a file or a pipe), it opens that onto the
7409 C<LINEINFO> filehandle, unbuffers the filehandle, and then returns the
7410 file or pipe again to the caller.
7411
7412 =cut
7413
7414 sub LineInfo {
7415     if (@_) {
7416         $lineinfo = shift;
7417
7418         #  If this is a valid "thing to be opened for output", tack a
7419         # '>' onto the front.
7420         my $stream = ( $lineinfo =~ /^(\+?\>|\|)/ ) ? $lineinfo : ">$lineinfo";
7421
7422         # If this is a pipe, the stream points to a slave editor.
7423         $slave_editor = ( $stream =~ /^\|/ );
7424
7425         # Open it up and unbuffer it.
7426         open( LINEINFO, $stream ) || &warn("Cannot open '$stream' for write");
7427         $LINEINFO = \*LINEINFO;
7428         $LINEINFO->autoflush(1);
7429     }
7430
7431     return $lineinfo;
7432 } ## end sub LineInfo
7433
7434 =head1 COMMAND SUPPORT ROUTINES
7435
7436 These subroutines provide functionality for various commands.
7437
7438 =head2 C<list_modules>
7439
7440 For the C<M> command: list modules loaded and their versions.
7441 Essentially just runs through the keys in %INC, picks each package's
7442 C<$VERSION> variable, gets the file name, and formats the information
7443 for output.
7444
7445 =cut
7446
7447 sub list_modules {    # versions
7448     my %version;
7449     my $file;
7450
7451     # keys are the "as-loaded" name, values are the fully-qualified path
7452     # to the file itself.
7453     for ( keys %INC ) {
7454         $file = $_;                                # get the module name
7455         s,\.p[lm]$,,i;                             # remove '.pl' or '.pm'
7456         s,/,::,g;                                  # change '/' to '::'
7457         s/^perl5db$/DB/;                           # Special case: debugger
7458                                                    # moves to package DB
7459         s/^Term::ReadLine::readline$/readline/;    # simplify readline
7460
7461         # If the package has a $VERSION package global (as all good packages
7462         # should!) decode it and save as partial message.
7463         my $pkg_version = do { no strict 'refs'; ${ $_ . '::VERSION' } };
7464         if ( defined $pkg_version ) {
7465             $version{$file} = "$pkg_version from ";
7466         }
7467
7468         # Finish up the message with the file the package came from.
7469         $version{$file} .= $INC{$file};
7470     } ## end for (keys %INC)
7471
7472     # Hey, dumpit() formats a hash nicely, so why not use it?
7473     dumpit( $OUT, \%version );
7474 } ## end sub list_modules
7475
7476 =head2 C<sethelp()>
7477
7478 Sets up the monster string used to format and print the help.
7479
7480 =head3 HELP MESSAGE FORMAT
7481
7482 The help message is a peculiar format unto itself; it mixes C<pod> I<ornaments>
7483 (C<< B<> >> C<< I<> >>) with tabs to come up with a format that's fairly
7484 easy to parse and portable, but which still allows the help to be a little
7485 nicer than just plain text.
7486
7487 Essentially, you define the command name (usually marked up with C<< B<> >>
7488 and C<< I<> >>), followed by a tab, and then the descriptive text, ending in a
7489 newline. The descriptive text can also be marked up in the same way. If you
7490 need to continue the descriptive text to another line, start that line with
7491 just tabs and then enter the marked-up text.
7492
7493 If you are modifying the help text, I<be careful>. The help-string parser is
7494 not very sophisticated, and if you don't follow these rules it will mangle the
7495 help beyond hope until you fix the string.
7496
7497 =cut
7498
7499 use vars qw($pre580_help);
7500 use vars qw($pre580_summary);
7501
7502 sub sethelp {
7503
7504     # XXX: make sure there are tabs between the command and explanation,
7505     #      or print_help will screw up your formatting if you have
7506     #      eeevil ornaments enabled.  This is an insane mess.
7507
7508     $help = "
7509 Help is currently only available for the new 5.8 command set.
7510 No help is available for the old command set.
7511 We assume you know what you're doing if you switch to it.
7512
7513 B<T>        Stack trace.
7514 B<s> [I<expr>]    Single step [in I<expr>].
7515 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
7516 <B<CR>>        Repeat last B<n> or B<s> command.
7517 B<r>        Return from current subroutine.
7518 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
7519         at the specified position.
7520 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
7521 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
7522 B<l> I<line>        List single I<line>.
7523 B<l> I<subname>    List first window of lines from subroutine.
7524 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
7525 B<l>        List next window of lines.
7526 B<->        List previous window of lines.
7527 B<v> [I<line>]    View window around I<line>.
7528 B<.>        Return to the executed line.
7529 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
7530         I<filename> may be either the full name of the file, or a regular
7531         expression matching the full file name:
7532         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
7533         Evals (with saved bodies) are considered to be filenames:
7534         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
7535         (in the order of execution).
7536 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
7537 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
7538 B<L> [I<a|b|w>]        List actions and or breakpoints and or watch-expressions.
7539 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
7540 B<t> [I<n>]       Toggle trace mode (to max I<n> levels below current stack depth).
7541 B<t> [I<n>] I<expr>        Trace through execution of I<expr>.
7542 B<b>        Sets breakpoint on current line)
7543 B<b> [I<line>] [I<condition>]
7544         Set breakpoint; I<line> defaults to the current execution line;
7545         I<condition> breaks if it evaluates to true, defaults to '1'.
7546 B<b> I<subname> [I<condition>]
7547         Set breakpoint at first line of subroutine.
7548 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
7549 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
7550 B<b> B<postpone> I<subname> [I<condition>]
7551         Set breakpoint at first line of subroutine after
7552         it is compiled.
7553 B<b> B<compile> I<subname>
7554         Stop after the subroutine is compiled.
7555 B<B> [I<line>]    Delete the breakpoint for I<line>.
7556 B<B> I<*>             Delete all breakpoints.
7557 B<a> [I<line>] I<command>
7558         Set an action to be done before the I<line> is executed;
7559         I<line> defaults to the current execution line.
7560         Sequence is: check for breakpoint/watchpoint, print line
7561         if necessary, do action, prompt user if necessary,
7562         execute line.
7563 B<a>        Does nothing
7564 B<A> [I<line>]    Delete the action for I<line>.
7565 B<A> I<*>             Delete all actions.
7566 B<w> I<expr>        Add a global watch-expression.
7567 B<w>             Does nothing
7568 B<W> I<expr>        Delete a global watch-expression.
7569 B<W> I<*>             Delete all watch-expressions.
7570 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
7571         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
7572 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
7573 B<x> I<expr>        Evals expression in list context, dumps the result.
7574 B<m> I<expr>        Evals expression in list context, prints methods callable
7575         on the first element of the result.
7576 B<m> I<class>        Prints methods callable via the given class.
7577 B<M>        Show versions of loaded modules.
7578 B<i> I<class>       Prints nested parents of given class.
7579 B<e>         Display current thread id.
7580 B<E>         Display all thread ids the current one will be identified: <n>.
7581 B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7582
7583 B<<> ?            List Perl commands to run before each prompt.
7584 B<<> I<expr>        Define Perl command to run before each prompt.
7585 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
7586 B<< *>                Delete the list of perl commands to run before each prompt.
7587 B<>> ?            List Perl commands to run after each prompt.
7588 B<>> I<expr>        Define Perl command to run after each prompt.
7589 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
7590 B<>>B< *>        Delete the list of Perl commands to run after each prompt.
7591 B<{> I<db_command>    Define debugger command to run before each prompt.
7592 B<{> ?            List debugger commands to run before each prompt.
7593 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
7594 B<{ *>             Delete the list of debugger commands to run before each prompt.
7595 B<$prc> I<number>    Redo a previous command (default previous command).
7596 B<$prc> I<-number>    Redo number'th-to-last command.
7597 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
7598         See 'B<O> I<recallCommand>' too.
7599 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
7600       . (
7601         $rc eq $sh
7602         ? ""
7603         : "
7604 B<$psh> [I<cmd>] Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
7605       ) . "
7606         See 'B<O> I<shellBang>' too.
7607 B<source> I<file>     Execute I<file> containing debugger commands (may nest).
7608 B<save> I<file>       Save current debugger session (actual history) to I<file>.
7609 B<rerun>           Rerun session to current position.
7610 B<rerun> I<n>         Rerun session to numbered command.
7611 B<rerun> I<-n>        Rerun session to number'th-to-last command.
7612 B<H> I<-number>    Display last number commands (default all).
7613 B<H> I<*>          Delete complete history.
7614 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
7615 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
7616 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarily select()ed as well.
7617 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
7618 I<command>        Execute as a perl statement in current package.
7619 B<R>        Pure-man-restart of debugger, some of debugger state
7620         and command-line options may be lost.
7621         Currently the following settings are preserved:
7622         history, breakpoints and actions, debugger B<O>ptions
7623         and the following command-line options: I<-w>, I<-I>, I<-e>.
7624
7625 B<o> [I<opt>] ...    Set boolean option to true
7626 B<o> [I<opt>B<?>]    Query options
7627 B<o> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
7628         Set options.  Use quotes if spaces in value.
7629     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
7630     I<pager>            program for output of \"|cmd\";
7631     I<tkRunning>            run Tk while prompting (with ReadLine);
7632     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
7633     I<inhibit_exit>        Allows stepping off the end of the script.
7634     I<ImmediateStop>        Debugger should stop as early as possible.
7635     I<RemotePort>            Remote hostname:port for remote debugging
7636   The following options affect what happens with B<V>, B<X>, and B<x> commands:
7637     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
7638     I<compactDump>, I<veryCompact>     change style of array and hash dump;
7639     I<globPrint>             whether to print contents of globs;
7640     I<DumpDBFiles>         dump arrays holding debugged files;
7641     I<DumpPackages>         dump symbol tables of packages;
7642     I<DumpReused>             dump contents of \"reused\" addresses;
7643     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
7644     I<bareStringify>         Do not print the overload-stringified value;
7645   Other options include:
7646     I<PrintRet>        affects printing of return value after B<r> command,
7647     I<frame>        affects printing messages on subroutine entry/exit.
7648     I<AutoTrace>    affects printing messages on possible breaking points.
7649     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
7650     I<ornaments>     affects screen appearance of the command line.
7651     I<CreateTTY>     bits control attempts to create a new TTY on events:
7652             1: on fork()    2: debugger is started inside debugger
7653             4: on startup
7654     During startup options are initialized from \$ENV{PERLDB_OPTS}.
7655     You can put additional initialization options I<TTY>, I<noTTY>,
7656     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
7657     B<R> after you set them).
7658
7659 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
7660 B<h>        Summary of debugger commands.
7661 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
7662 B<h h>        Long help for debugger commands
7663 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
7664         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
7665         Set B<\$DB::doccmd> to change viewer.
7666
7667 Type '|h h' for a paged display if this was too hard to read.
7668
7669 ";    # Fix balance of vi % matching: }}}}
7670
7671     #  note: tabs in the following section are not-so-helpful
7672     $summary = <<"END_SUM";
7673 I<List/search source lines:>               I<Control script execution:>
7674   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
7675   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
7676   B<v> [I<line>]    View around line            B<n> [I<expr>]    Next, steps over subs
7677   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
7678   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
7679   B<M>           Show module versions        B<c> [I<ln>|I<sub>]  Continue until position
7680 I<Debugger controls:>                        B<L>           List break/watch/actions
7681   B<o> [...]     Set debugger options        B<t> [I<n>] [I<expr>] Toggle trace [max depth] ][trace expr]
7682   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
7683   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<B> I<ln|*>      Delete a/all breakpoints
7684   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
7685   B<=> [I<a> I<val>]   Define/list an alias        B<A> I<ln|*>      Delete a/all actions
7686   B<h> [I<db_cmd>]  Get help on command         B<w> I<expr>      Add a watch expression
7687   B<h h>         Complete help page          B<W> I<expr|*>    Delete a/all watch exprs
7688   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
7689   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
7690 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
7691   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
7692   B<p> I<expr>         Print expression (uses script's current package).
7693   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
7694   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
7695   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".  B<i> I<class> inheritance tree.
7696   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7697   B<e>     Display thread id     B<E> Display all thread ids.
7698 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
7699 END_SUM
7700
7701     # ')}}; # Fix balance of vi % matching
7702
7703     # and this is really numb...
7704     $pre580_help = "
7705 B<T>        Stack trace.
7706 B<s> [I<expr>]    Single step [in I<expr>].
7707 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
7708 B<CR>>        Repeat last B<n> or B<s> command.
7709 B<r>        Return from current subroutine.
7710 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
7711         at the specified position.
7712 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
7713 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
7714 B<l> I<line>        List single I<line>.
7715 B<l> I<subname>    List first window of lines from subroutine.
7716 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
7717 B<l>        List next window of lines.
7718 B<->        List previous window of lines.
7719 B<w> [I<line>]    List window around I<line>.
7720 B<.>        Return to the executed line.
7721 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
7722         I<filename> may be either the full name of the file, or a regular
7723         expression matching the full file name:
7724         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
7725         Evals (with saved bodies) are considered to be filenames:
7726         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
7727         (in the order of execution).
7728 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
7729 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
7730 B<L>        List all breakpoints and actions.
7731 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
7732 B<t> [I<n>]       Toggle trace mode (to max I<n> levels below current stack depth) .
7733 B<t> [I<n>] I<expr>        Trace through execution of I<expr>.
7734 B<b> [I<line>] [I<condition>]
7735         Set breakpoint; I<line> defaults to the current execution line;
7736         I<condition> breaks if it evaluates to true, defaults to '1'.
7737 B<b> I<subname> [I<condition>]
7738         Set breakpoint at first line of subroutine.
7739 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
7740 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
7741 B<b> B<postpone> I<subname> [I<condition>]
7742         Set breakpoint at first line of subroutine after
7743         it is compiled.
7744 B<b> B<compile> I<subname>
7745         Stop after the subroutine is compiled.
7746 B<d> [I<line>]    Delete the breakpoint for I<line>.
7747 B<D>        Delete all breakpoints.
7748 B<a> [I<line>] I<command>
7749         Set an action to be done before the I<line> is executed;
7750         I<line> defaults to the current execution line.
7751         Sequence is: check for breakpoint/watchpoint, print line
7752         if necessary, do action, prompt user if necessary,
7753         execute line.
7754 B<a> [I<line>]    Delete the action for I<line>.
7755 B<A>        Delete all actions.
7756 B<W> I<expr>        Add a global watch-expression.
7757 B<W>        Delete all watch-expressions.
7758 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
7759         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
7760 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
7761 B<x> I<expr>        Evals expression in list context, dumps the result.
7762 B<m> I<expr>        Evals expression in list context, prints methods callable
7763         on the first element of the result.
7764 B<m> I<class>        Prints methods callable via the given class.
7765
7766 B<<> ?            List Perl commands to run before each prompt.
7767 B<<> I<expr>        Define Perl command to run before each prompt.
7768 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
7769 B<>> ?            List Perl commands to run after each prompt.
7770 B<>> I<expr>        Define Perl command to run after each prompt.
7771 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
7772 B<{> I<db_command>    Define debugger command to run before each prompt.
7773 B<{> ?            List debugger commands to run before each prompt.
7774 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
7775 B<$prc> I<number>    Redo a previous command (default previous command).
7776 B<$prc> I<-number>    Redo number'th-to-last command.
7777 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
7778         See 'B<O> I<recallCommand>' too.
7779 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
7780       . (
7781         $rc eq $sh
7782         ? ""
7783         : "
7784 B<$psh> [I<cmd>]     Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
7785       ) . "
7786         See 'B<O> I<shellBang>' too.
7787 B<source> I<file>        Execute I<file> containing debugger commands (may nest).
7788 B<H> I<-number>    Display last number commands (default all).
7789 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
7790 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
7791 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarilly select()ed as well.
7792 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
7793 I<command>        Execute as a perl statement in current package.
7794 B<v>        Show versions of loaded modules.
7795 B<R>        Pure-man-restart of debugger, some of debugger state
7796         and command-line options may be lost.
7797         Currently the following settings are preserved:
7798         history, breakpoints and actions, debugger B<O>ptions
7799         and the following command-line options: I<-w>, I<-I>, I<-e>.
7800
7801 B<O> [I<opt>] ...    Set boolean option to true
7802 B<O> [I<opt>B<?>]    Query options
7803 B<O> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
7804         Set options.  Use quotes if spaces in value.
7805     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
7806     I<pager>            program for output of \"|cmd\";
7807     I<tkRunning>            run Tk while prompting (with ReadLine);
7808     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
7809     I<inhibit_exit>        Allows stepping off the end of the script.
7810     I<ImmediateStop>        Debugger should stop as early as possible.
7811     I<RemotePort>            Remote hostname:port for remote debugging
7812   The following options affect what happens with B<V>, B<X>, and B<x> commands:
7813     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
7814     I<compactDump>, I<veryCompact>     change style of array and hash dump;
7815     I<globPrint>             whether to print contents of globs;
7816     I<DumpDBFiles>         dump arrays holding debugged files;
7817     I<DumpPackages>         dump symbol tables of packages;
7818     I<DumpReused>             dump contents of \"reused\" addresses;
7819     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
7820     I<bareStringify>         Do not print the overload-stringified value;
7821   Other options include:
7822     I<PrintRet>        affects printing of return value after B<r> command,
7823     I<frame>        affects printing messages on subroutine entry/exit.
7824     I<AutoTrace>    affects printing messages on possible breaking points.
7825     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
7826     I<ornaments>     affects screen appearance of the command line.
7827     I<CreateTTY>     bits control attempts to create a new TTY on events:
7828             1: on fork()    2: debugger is started inside debugger
7829             4: on startup
7830     During startup options are initialized from \$ENV{PERLDB_OPTS}.
7831     You can put additional initialization options I<TTY>, I<noTTY>,
7832     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
7833     B<R> after you set them).
7834
7835 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
7836 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
7837 B<h h>        Summary of debugger commands.
7838 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
7839         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
7840         Set B<\$DB::doccmd> to change viewer.
7841
7842 Type '|h' for a paged display if this was too hard to read.
7843
7844 ";    # Fix balance of vi % matching: }}}}
7845
7846     #  note: tabs in the following section are not-so-helpful
7847     $pre580_summary = <<"END_SUM";
7848 I<List/search source lines:>               I<Control script execution:>
7849   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
7850   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
7851   B<w> [I<line>]    List around line            B<n> [I<expr>]    Next, steps over subs
7852   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
7853   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
7854   B<v>           Show versions of modules    B<c> [I<ln>|I<sub>]  Continue until position
7855 I<Debugger controls:>                        B<L>           List break/watch/actions
7856   B<O> [...]     Set debugger options        B<t> [I<expr>]    Toggle trace [trace expr]
7857   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
7858   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<d> [I<ln>] or B<D> Delete a/all breakpoints
7859   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
7860   B<=> [I<a> I<val>]   Define/list an alias        B<W> I<expr>      Add a watch expression
7861   B<h> [I<db_cmd>]  Get help on command         B<A> or B<W>      Delete all actions/watch
7862   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
7863   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
7864 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
7865   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
7866   B<p> I<expr>         Print expression (uses script's current package).
7867   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
7868   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
7869   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".
7870   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7871 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
7872 END_SUM
7873
7874     # ')}}; # Fix balance of vi % matching
7875
7876 } ## end sub sethelp
7877
7878 =head2 C<print_help()>
7879
7880 Most of what C<print_help> does is just text formatting. It finds the
7881 C<B> and C<I> ornaments, cleans them off, and substitutes the proper
7882 terminal control characters to simulate them (courtesy of
7883 C<Term::ReadLine::TermCap>).
7884
7885 =cut
7886
7887 sub print_help {
7888     my $help_str = shift;
7889
7890     # Restore proper alignment destroyed by eeevil I<> and B<>
7891     # ornaments: A pox on both their houses!
7892     #
7893     # A help command will have everything up to and including
7894     # the first tab sequence padded into a field 16 (or if indented 20)
7895     # wide.  If it's wider than that, an extra space will be added.
7896     $help_str =~ s{
7897         ^                       # only matters at start of line
7898           ( \040{4} | \t )*     # some subcommands are indented
7899           ( < ?                 # so <CR> works
7900             [BI] < [^\t\n] + )  # find an eeevil ornament
7901           ( \t+ )               # original separation, discarded
7902           ( .* )                # this will now start (no earlier) than
7903                                 # column 16
7904     } {
7905         my($leadwhite, $command, $midwhite, $text) = ($1, $2, $3, $4);
7906         my $clean = $command;
7907         $clean =~ s/[BI]<([^>]*)>/$1/g;
7908
7909         # replace with this whole string:
7910         ($leadwhite ? " " x 4 : "")
7911       . $command
7912       . ((" " x (16 + ($leadwhite ? 4 : 0) - length($clean))) || " ")
7913       . $text;
7914
7915     }mgex;
7916
7917     $help_str =~ s{                          # handle bold ornaments
7918        B < ( [^>] + | > ) >
7919     } {
7920           $Term::ReadLine::TermCap::rl_term_set[2]
7921         . $1
7922         . $Term::ReadLine::TermCap::rl_term_set[3]
7923     }gex;
7924
7925     $help_str =~ s{                         # handle italic ornaments
7926        I < ( [^>] + | > ) >
7927     } {
7928           $Term::ReadLine::TermCap::rl_term_set[0]
7929         . $1
7930         . $Term::ReadLine::TermCap::rl_term_set[1]
7931     }gex;
7932
7933     local $\ = '';
7934     print {$OUT} $help_str;
7935
7936     return;
7937 } ## end sub print_help
7938
7939 =head2 C<fix_less>
7940
7941 This routine does a lot of gyrations to be sure that the pager is C<less>.
7942 It checks for C<less> masquerading as C<more> and records the result in
7943 C<$fixed_less> so we don't have to go through doing the stats again.
7944
7945 =cut
7946
7947 use vars qw($fixed_less);
7948
7949 sub _calc_is_less {
7950     if ($pager =~ /\bless\b/)
7951     {
7952         return 1;
7953     }
7954     elsif ($pager =~ /\bmore\b/)
7955     {
7956         # Nope, set to more. See what's out there.
7957         my @st_more = stat('/usr/bin/more');
7958         my @st_less = stat('/usr/bin/less');
7959
7960         # is it really less, pretending to be more?
7961         return (
7962             @st_more
7963             && @st_less
7964             && $st_more[0] == $st_less[0]
7965             && $st_more[1] == $st_less[1]
7966         );
7967     }
7968     else {
7969         return;
7970     }
7971 }
7972
7973 sub fix_less {
7974
7975     # We already know if this is set.
7976     return if $fixed_less;
7977
7978     # changes environment!
7979     # 'r' added so we don't do (slow) stats again.
7980     $fixed_less = 1 if _calc_is_less();
7981
7982     return;
7983 } ## end sub fix_less
7984
7985 =head1 DIE AND WARN MANAGEMENT
7986
7987 =head2 C<diesignal>
7988
7989 C<diesignal> is a just-drop-dead C<die> handler. It's most useful when trying
7990 to debug a debugger problem.
7991
7992 It does its best to report the error that occurred, and then forces the
7993 program, debugger, and everything to die.
7994
7995 =cut
7996
7997 sub diesignal {
7998
7999     # No entry/exit messages.
8000     local $frame = 0;
8001
8002     # No return value prints.
8003     local $doret = -2;
8004
8005     # set the abort signal handling to the default (just terminate).
8006     $SIG{'ABRT'} = 'DEFAULT';
8007
8008     # If we enter the signal handler recursively, kill myself with an
8009     # abort signal (so we just terminate).
8010     kill 'ABRT', $$ if $panic++;
8011
8012     # If we can show detailed info, do so.
8013     if ( defined &Carp::longmess ) {
8014
8015         # Don't recursively enter the warn handler, since we're carping.
8016         local $SIG{__WARN__} = '';
8017
8018         # Skip two levels before reporting traceback: we're skipping
8019         # mydie and confess.
8020         local $Carp::CarpLevel = 2;    # mydie + confess
8021
8022         # Tell us all about it.
8023         &warn( Carp::longmess("Signal @_") );
8024     }
8025
8026     # No Carp. Tell us about the signal as best we can.
8027     else {
8028         local $\ = '';
8029         print $DB::OUT "Got signal @_\n";
8030     }
8031
8032     # Drop dead.
8033     kill 'ABRT', $$;
8034 } ## end sub diesignal
8035
8036 =head2 C<dbwarn>
8037
8038 The debugger's own default C<$SIG{__WARN__}> handler. We load C<Carp> to
8039 be able to get a stack trace, and output the warning message vi C<DB::dbwarn()>.
8040
8041 =cut
8042
8043 sub dbwarn {
8044
8045     # No entry/exit trace.
8046     local $frame = 0;
8047
8048     # No return value printing.
8049     local $doret = -2;
8050
8051     # Turn off warn and die handling to prevent recursive entries to this
8052     # routine.
8053     local $SIG{__WARN__} = '';
8054     local $SIG{__DIE__}  = '';
8055
8056     # Load Carp if we can. If $^S is false (current thing being compiled isn't
8057     # done yet), we may not be able to do a require.
8058     eval { require Carp }
8059       if defined $^S;    # If error/warning during compilation,
8060                          # require may be broken.
8061
8062     # Use the core warn() unless Carp loaded OK.
8063     CORE::warn( @_,
8064         "\nCannot print stack trace, load with -MCarp option to see stack" ),
8065       return
8066       unless defined &Carp::longmess;
8067
8068     # Save the current values of $single and $trace, and then turn them off.
8069     my ( $mysingle, $mytrace ) = ( $single, $trace );
8070     $single = 0;
8071     $trace  = 0;
8072
8073     # We can call Carp::longmess without its being "debugged" (which we
8074     # don't want - we just want to use it!). Capture this for later.
8075     my $mess = Carp::longmess(@_);
8076
8077     # Restore $single and $trace to their original values.
8078     ( $single, $trace ) = ( $mysingle, $mytrace );
8079
8080     # Use the debugger's own special way of printing warnings to print
8081     # the stack trace message.
8082     &warn($mess);
8083 } ## end sub dbwarn
8084
8085 =head2 C<dbdie>
8086
8087 The debugger's own C<$SIG{__DIE__}> handler. Handles providing a stack trace
8088 by loading C<Carp> and calling C<Carp::longmess()> to get it. We turn off
8089 single stepping and tracing during the call to C<Carp::longmess> to avoid
8090 debugging it - we just want to use it.
8091
8092 If C<dieLevel> is zero, we let the program being debugged handle the
8093 exceptions. If it's 1, you get backtraces for any exception. If it's 2,
8094 the debugger takes over all exception handling, printing a backtrace and
8095 displaying the exception via its C<dbwarn()> routine.
8096
8097 =cut
8098
8099 sub dbdie {
8100     local $frame         = 0;
8101     local $doret         = -2;
8102     local $SIG{__DIE__}  = '';
8103     local $SIG{__WARN__} = '';
8104     my $i      = 0;
8105     my $ineval = 0;
8106     my $sub;
8107     if ( $dieLevel > 2 ) {
8108         local $SIG{__WARN__} = \&dbwarn;
8109         &warn(@_);    # Yell no matter what
8110         return;
8111     }
8112     if ( $dieLevel < 2 ) {
8113         die @_ if $^S;    # in eval propagate
8114     }
8115
8116     # The code used to check $^S to see if compilation of the current thing
8117     # hadn't finished. We don't do it anymore, figuring eval is pretty stable.
8118     eval { require Carp };
8119
8120     die( @_,
8121         "\nCannot print stack trace, load with -MCarp option to see stack" )
8122       unless defined &Carp::longmess;
8123
8124     # We do not want to debug this chunk (automatic disabling works
8125     # inside DB::DB, but not in Carp). Save $single and $trace, turn them off,
8126     # get the stack trace from Carp::longmess (if possible), restore $signal
8127     # and $trace, and then die with the stack trace.
8128     my ( $mysingle, $mytrace ) = ( $single, $trace );
8129     $single = 0;
8130     $trace  = 0;
8131     my $mess = "@_";
8132     {
8133
8134         package Carp;    # Do not include us in the list
8135         eval { $mess = Carp::longmess(@_); };
8136     }
8137     ( $single, $trace ) = ( $mysingle, $mytrace );
8138     die $mess;
8139 } ## end sub dbdie
8140
8141 =head2 C<warnlevel()>
8142
8143 Set the C<$DB::warnLevel> variable that stores the value of the
8144 C<warnLevel> option. Calling C<warnLevel()> with a positive value
8145 results in the debugger taking over all warning handlers. Setting
8146 C<warnLevel> to zero leaves any warning handlers set up by the program
8147 being debugged in place.
8148
8149 =cut
8150
8151 sub warnLevel {
8152     if (@_) {
8153         my $prevwarn = $SIG{__WARN__} unless $warnLevel;
8154         $warnLevel = shift;
8155         if ($warnLevel) {
8156             $SIG{__WARN__} = \&DB::dbwarn;
8157         }
8158         elsif ($prevwarn) {
8159             $SIG{__WARN__} = $prevwarn;
8160         } else {
8161             undef $SIG{__WARN__};
8162         }
8163     } ## end if (@_)
8164     $warnLevel;
8165 } ## end sub warnLevel
8166
8167 =head2 C<dielevel>
8168
8169 Similar to C<warnLevel>. Non-zero values for C<dieLevel> result in the
8170 C<DB::dbdie()> function overriding any other C<die()> handler. Setting it to
8171 zero lets you use your own C<die()> handler.
8172
8173 =cut
8174
8175 sub dieLevel {
8176     local $\ = '';
8177     if (@_) {
8178         my $prevdie = $SIG{__DIE__} unless $dieLevel;
8179         $dieLevel = shift;
8180         if ($dieLevel) {
8181
8182             # Always set it to dbdie() for non-zero values.
8183             $SIG{__DIE__} = \&DB::dbdie;    # if $dieLevel < 2;
8184
8185             # No longer exists, so don't try  to use it.
8186             #$SIG{__DIE__} = \&DB::diehard if $dieLevel >= 2;
8187
8188             # If we've finished initialization, mention that stack dumps
8189             # are enabled, If dieLevel is 1, we won't stack dump if we die
8190             # in an eval().
8191             print $OUT "Stack dump during die enabled",
8192               ( $dieLevel == 1 ? " outside of evals" : "" ), ".\n"
8193               if $I_m_init;
8194
8195             # XXX This is probably obsolete, given that diehard() is gone.
8196             print $OUT "Dump printed too.\n" if $dieLevel > 2;
8197         } ## end if ($dieLevel)
8198
8199         # Put the old one back if there was one.
8200         elsif ($prevdie) {
8201             $SIG{__DIE__} = $prevdie;
8202             print $OUT "Default die handler restored.\n";
8203         } else {
8204             undef $SIG{__DIE__};
8205             print $OUT "Die handler removed.\n";
8206         }
8207     } ## end if (@_)
8208     $dieLevel;
8209 } ## end sub dieLevel
8210
8211 =head2 C<signalLevel>
8212
8213 Number three in a series: set C<signalLevel> to zero to keep your own
8214 signal handler for C<SIGSEGV> and/or C<SIGBUS>. Otherwise, the debugger
8215 takes over and handles them with C<DB::diesignal()>.
8216
8217 =cut
8218
8219 sub signalLevel {
8220     if (@_) {
8221         my $prevsegv = $SIG{SEGV} unless $signalLevel;
8222         my $prevbus  = $SIG{BUS}  unless $signalLevel;
8223         $signalLevel = shift;
8224         if ($signalLevel) {
8225             $SIG{SEGV} = \&DB::diesignal;
8226             $SIG{BUS}  = \&DB::diesignal;
8227         }
8228         else {
8229             $SIG{SEGV} = $prevsegv;
8230             $SIG{BUS}  = $prevbus;
8231         }
8232     } ## end if (@_)
8233     $signalLevel;
8234 } ## end sub signalLevel
8235
8236 =head1 SUBROUTINE DECODING SUPPORT
8237
8238 These subroutines are used during the C<x> and C<X> commands to try to
8239 produce as much information as possible about a code reference. They use
8240 L<Devel::Peek> to try to find the glob in which this code reference lives
8241 (if it does) - this allows us to actually code references which correspond
8242 to named subroutines (including those aliased via glob assignment).
8243
8244 =head2 C<CvGV_name()>
8245
8246 Wrapper for C<CvGV_name_or_bust>; tries to get the name of a reference
8247 via that routine. If this fails, return the reference again (when the
8248 reference is stringified, it'll come out as C<SOMETHING(0x...)>).
8249
8250 =cut
8251
8252 sub CvGV_name {
8253     my $in   = shift;
8254     my $name = CvGV_name_or_bust($in);
8255     defined $name ? $name : $in;
8256 }
8257
8258 =head2 C<CvGV_name_or_bust> I<coderef>
8259
8260 Calls L<Devel::Peek> to try to find the glob the ref lives in; returns
8261 C<undef> if L<Devel::Peek> can't be loaded, or if C<Devel::Peek::CvGV> can't
8262 find a glob for this ref.
8263
8264 Returns C<< I<package>::I<glob name> >> if the code ref is found in a glob.
8265
8266 =cut
8267
8268 use vars qw($skipCvGV);
8269
8270 sub CvGV_name_or_bust {
8271     my $in = shift;
8272     return if $skipCvGV;    # Backdoor to avoid problems if XS broken...
8273     return unless ref $in;
8274     $in = \&$in;            # Hard reference...
8275     eval { require Devel::Peek; 1 } or return;
8276     my $gv = Devel::Peek::CvGV($in) or return;
8277     *$gv{PACKAGE} . '::' . *$gv{NAME};
8278 } ## end sub CvGV_name_or_bust
8279
8280 =head2 C<find_sub>
8281
8282 A utility routine used in various places; finds the file where a subroutine
8283 was defined, and returns that filename and a line-number range.
8284
8285 Tries to use C<@sub> first; if it can't find it there, it tries building a
8286 reference to the subroutine and uses C<CvGV_name_or_bust> to locate it,
8287 loading it into C<@sub> as a side effect (XXX I think). If it can't find it
8288 this way, it brute-force searches C<%sub>, checking for identical references.
8289
8290 =cut
8291
8292 sub _find_sub_helper {
8293     my $subr = shift;
8294
8295     return unless defined &$subr;
8296     my $name = CvGV_name_or_bust($subr);
8297     my $data;
8298     $data = $sub{$name} if defined $name;
8299     return $data if defined $data;
8300
8301     # Old stupid way...
8302     $subr = \&$subr;    # Hard reference
8303     my $s;
8304     for ( keys %sub ) {
8305         $s = $_, last if $subr eq \&$_;
8306     }
8307     if ($s)
8308     {
8309         return $sub{$s};
8310     }
8311     else
8312     {
8313         return;
8314     }
8315
8316 }
8317
8318 sub find_sub {
8319     my $subr = shift;
8320     return ( $sub{$subr} || _find_sub_helper($subr) );
8321 } ## end sub find_sub
8322
8323 =head2 C<methods>
8324
8325 A subroutine that uses the utility function C<methods_via> to find all the
8326 methods in the class corresponding to the current reference and in
8327 C<UNIVERSAL>.
8328
8329 =cut
8330
8331 use vars qw(%seen);
8332
8333 sub methods {
8334
8335     # Figure out the class - either this is the class or it's a reference
8336     # to something blessed into that class.
8337     my $class = shift;
8338     $class = ref $class if ref $class;
8339
8340     local %seen;
8341
8342     # Show the methods that this class has.
8343     methods_via( $class, '', 1 );
8344
8345     # Show the methods that UNIVERSAL has.
8346     methods_via( 'UNIVERSAL', 'UNIVERSAL', 0 );
8347 } ## end sub methods
8348
8349 =head2 C<methods_via($class, $prefix, $crawl_upward)>
8350
8351 C<methods_via> does the work of crawling up the C<@ISA> tree and reporting
8352 all the parent class methods. C<$class> is the name of the next class to
8353 try; C<$prefix> is the message prefix, which gets built up as we go up the
8354 C<@ISA> tree to show parentage; C<$crawl_upward> is 1 if we should try to go
8355 higher in the C<@ISA> tree, 0 if we should stop.
8356
8357 =cut
8358
8359 sub methods_via {
8360
8361     # If we've processed this class already, just quit.
8362     my $class = shift;
8363     return if $seen{$class}++;
8364
8365     # This is a package that is contributing the methods we're about to print.
8366     my $prefix  = shift;
8367     my $prepend = $prefix ? "via $prefix: " : '';
8368     my @to_print;
8369
8370     # Extract from all the symbols in this class.
8371     my $class_ref = do { no strict "refs"; \%{$class . '::'} };
8372     while (my ($name, $glob) = each %$class_ref) {
8373         # references directly in the symbol table are Proxy Constant
8374         # Subroutines, and are by their very nature defined
8375         # Otherwise, check if the thing is a typeglob, and if it is, it decays
8376         # to a subroutine reference, which can be tested by defined.
8377         # $glob might also be the value -1  (from sub foo;)
8378         # or (say) '$$' (from sub foo ($$);)
8379         # \$glob will be SCALAR in both cases.
8380         if ((ref $glob || ($glob && ref \$glob eq 'GLOB' && defined &$glob))
8381             && !$seen{$name}++) {
8382             push @to_print, "$prepend$name\n";
8383         }
8384     }
8385
8386     {
8387         local $\ = '';
8388         local $, = '';
8389         print $DB::OUT $_ foreach sort @to_print;
8390     }
8391
8392     # If the $crawl_upward argument is false, just quit here.
8393     return unless shift;
8394
8395     # $crawl_upward true: keep going up the tree.
8396     # Find all the classes this one is a subclass of.
8397     my $class_ISA_ref = do { no strict "refs"; \@{"${class}::ISA"} };
8398     for my $name ( @$class_ISA_ref ) {
8399
8400         # Set up the new prefix.
8401         $prepend = $prefix ? $prefix . " -> $name" : $name;
8402
8403         # Crawl up the tree and keep trying to crawl up.
8404         methods_via( $name, $prepend, 1 );
8405     }
8406 } ## end sub methods_via
8407
8408 =head2 C<setman> - figure out which command to use to show documentation
8409
8410 Just checks the contents of C<$^O> and sets the C<$doccmd> global accordingly.
8411
8412 =cut
8413
8414 sub setman {
8415     $doccmd = $^O !~ /^(?:MSWin32|VMS|os2|dos|amigaos|riscos|NetWare)\z/s
8416       ? "man"         # O Happy Day!
8417       : "perldoc";    # Alas, poor unfortunates
8418 } ## end sub setman
8419
8420 =head2 C<runman> - run the appropriate command to show documentation
8421
8422 Accepts a man page name; runs the appropriate command to display it (set up
8423 during debugger initialization). Uses C<DB::system> to avoid mucking up the
8424 program's STDIN and STDOUT.
8425
8426 =cut
8427
8428 my %_is_in_pods = (map { $_ => 1 }
8429     qw(
8430     5004delta
8431     5005delta
8432     561delta
8433     56delta
8434     570delta
8435     571delta
8436     572delta
8437     573delta
8438     58delta
8439     581delta
8440     582delta
8441     583delta
8442     584delta
8443     590delta
8444     591delta
8445     592delta
8446     aix
8447     amiga
8448     apio
8449     api
8450     artistic
8451     beos
8452     book
8453     boot
8454     bot
8455     bs2000
8456     call
8457     ce
8458     cheat
8459     clib
8460     cn
8461     compile
8462     cygwin
8463     data
8464     dbmfilter
8465     debguts
8466     debtut
8467     debug
8468     delta
8469     dgux
8470     diag
8471     doc
8472     dos
8473     dsc
8474     ebcdic
8475     embed
8476     epoc
8477     faq1
8478     faq2
8479     faq3
8480     faq4
8481     faq5
8482     faq6
8483     faq7
8484     faq8
8485     faq9
8486     faq
8487     filter
8488     fork
8489     form
8490     freebsd
8491     func
8492     gpl
8493     guts
8494     hack
8495     hist
8496     hpux
8497     hurd
8498     intern
8499     intro
8500     iol
8501     ipc
8502     irix
8503     jp
8504     ko
8505     lexwarn
8506     locale
8507     lol
8508     macos
8509     macosx
8510     modinstall
8511     modlib
8512     mod
8513     modstyle
8514     netware
8515     newmod
8516     number
8517     obj
8518     opentut
8519     op
8520     os2
8521     os390
8522     os400
8523     packtut
8524     plan9
8525     pod
8526     podspec
8527     port
8528     qnx
8529     ref
8530     reftut
8531     re
8532     requick
8533     reref
8534     retut
8535     run
8536     sec
8537     solaris
8538     style
8539     sub
8540     syn
8541     thrtut
8542     tie
8543     toc
8544     todo
8545     tooc
8546     toot
8547     trap
8548     tru64
8549     tw
8550     unicode
8551     uniintro
8552     util
8553     uts
8554     var
8555     vms
8556     vos
8557     win32
8558     xs
8559     xstut
8560     )
8561 );
8562
8563 sub runman {
8564     my $page = shift;
8565     unless ($page) {
8566         &system("$doccmd $doccmd");
8567         return;
8568     }
8569
8570     # this way user can override, like with $doccmd="man -Mwhatever"
8571     # or even just "man " to disable the path check.
8572     unless ( $doccmd eq 'man' ) {
8573         &system("$doccmd $page");
8574         return;
8575     }
8576
8577     $page = 'perl' if lc($page) eq 'help';
8578
8579     require Config;
8580     my $man1dir = $Config::Config{'man1dir'};
8581     my $man3dir = $Config::Config{'man3dir'};
8582     for ( $man1dir, $man3dir ) { s#/[^/]*\z## if /\S/ }
8583     my $manpath = '';
8584     $manpath .= "$man1dir:" if $man1dir =~ /\S/;
8585     $manpath .= "$man3dir:" if $man3dir =~ /\S/ && $man1dir ne $man3dir;
8586     chop $manpath if $manpath;
8587
8588     # harmless if missing, I figure
8589     my $oldpath = $ENV{MANPATH};
8590     $ENV{MANPATH} = $manpath if $manpath;
8591     my $nopathopt = $^O =~ /dunno what goes here/;
8592     if (
8593         CORE::system(
8594             $doccmd,
8595
8596             # I just *know* there are men without -M
8597             ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8598             split ' ', $page
8599         )
8600       )
8601     {
8602         unless ( $page =~ /^perl\w/ ) {
8603 # do it this way because its easier to slurp in to keep up to date - clunky though.
8604             if (exists($_is_in_pods{$page})) {
8605                 CORE::system( $doccmd,
8606                     ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8607                     "perl$page" );
8608             }
8609         }
8610     } ## end if (CORE::system($doccmd...
8611     if ( defined $oldpath ) {
8612         $ENV{MANPATH} = $manpath;
8613     }
8614     else {
8615         delete $ENV{MANPATH};
8616     }
8617 } ## end sub runman
8618
8619 #use Carp;                          # This did break, left for debugging
8620
8621 =head1 DEBUGGER INITIALIZATION - THE SECOND BEGIN BLOCK
8622
8623 Because of the way the debugger interface to the Perl core is designed, any
8624 debugger package globals that C<DB::sub()> requires have to be defined before
8625 any subroutines can be called. These are defined in the second C<BEGIN> block.
8626
8627 This block sets things up so that (basically) the world is sane
8628 before the debugger starts executing. We set up various variables that the
8629 debugger has to have set up before the Perl core starts running:
8630
8631 =over 4
8632
8633 =item *
8634
8635 The debugger's own filehandles (copies of STD and STDOUT for now).
8636
8637 =item *
8638
8639 Characters for shell escapes, the recall command, and the history command.
8640
8641 =item *
8642
8643 The maximum recursion depth.
8644
8645 =item *
8646
8647 The size of a C<w> command's window.
8648
8649 =item *
8650
8651 The before-this-line context to be printed in a C<v> (view a window around this line) command.
8652
8653 =item *
8654
8655 The fact that we're not in a sub at all right now.
8656
8657 =item *
8658
8659 The default SIGINT handler for the debugger.
8660
8661 =item *
8662
8663 The appropriate value of the flag in C<$^D> that says the debugger is running
8664
8665 =item *
8666
8667 The current debugger recursion level
8668
8669 =item *
8670
8671 The list of postponed items and the C<$single> stack (XXX define this)
8672
8673 =item *
8674
8675 That we want no return values and no subroutine entry/exit trace.
8676
8677 =back
8678
8679 =cut
8680
8681 # The following BEGIN is very handy if debugger goes havoc, debugging debugger?
8682
8683 use vars qw($db_stop);
8684
8685 BEGIN {    # This does not compile, alas. (XXX eh?)
8686     $IN  = \*STDIN;     # For bugs before DB::OUT has been opened
8687     $OUT = \*STDERR;    # For errors before DB::OUT has been opened
8688
8689     # Define characters used by command parsing.
8690     $sh       = '!';      # Shell escape (does not work)
8691     $rc       = ',';      # Recall command (does not work)
8692     @hist     = ('?');    # Show history (does not work)
8693     @truehist = ();       # Can be saved for replay (per session)
8694
8695     # This defines the point at which you get the 'deep recursion'
8696     # warning. It MUST be defined or the debugger will not load.
8697     $deep = 100;
8698
8699     # Number of lines around the current one that are shown in the
8700     # 'w' command.
8701     $window = 10;
8702
8703     # How much before-the-current-line context the 'v' command should
8704     # use in calculating the start of the window it will display.
8705     $preview = 3;
8706
8707     # We're not in any sub yet, but we need this to be a defined value.
8708     $sub = '';
8709
8710     # Set up the debugger's interrupt handler. It simply sets a flag
8711     # ($signal) that DB::DB() will check before each command is executed.
8712     $SIG{INT} = \&DB::catch;
8713
8714     # The following lines supposedly, if uncommented, allow the debugger to
8715     # debug itself. Perhaps we can try that someday.
8716     # This may be enabled to debug debugger:
8717     #$warnLevel = 1 unless defined $warnLevel;
8718     #$dieLevel = 1 unless defined $dieLevel;
8719     #$signalLevel = 1 unless defined $signalLevel;
8720
8721     # This is the flag that says "a debugger is running, please call
8722     # DB::DB and DB::sub". We will turn it on forcibly before we try to
8723     # execute anything in the user's context, because we always want to
8724     # get control back.
8725     $db_stop = 0;          # Compiler warning ...
8726     $db_stop = 1 << 30;    # ... because this is only used in an eval() later.
8727
8728     # This variable records how many levels we're nested in debugging. Used
8729     # Used in the debugger prompt, and in determining whether it's all over or
8730     # not.
8731     $level = 0;            # Level of recursive debugging
8732
8733     # "Triggers bug (?) in perl if we postpone this until runtime."
8734     # XXX No details on this yet, or whether we should fix the bug instead
8735     # of work around it. Stay tuned.
8736     @stack = (0);
8737
8738     # Used to track the current stack depth using the auto-stacked-variable
8739     # trick.
8740     $stack_depth = 0;      # Localized repeatedly; simple way to track $#stack
8741
8742     # Don't print return values on exiting a subroutine.
8743     $doret = -2;
8744
8745     # No extry/exit tracing.
8746     $frame = 0;
8747
8748 } ## end BEGIN
8749
8750 BEGIN { $^W = $ini_warn; }    # Switch warnings back
8751
8752 =head1 READLINE SUPPORT - COMPLETION FUNCTION
8753
8754 =head2 db_complete
8755
8756 C<readline> support - adds command completion to basic C<readline>.
8757
8758 Returns a list of possible completions to C<readline> when invoked. C<readline>
8759 will print the longest common substring following the text already entered.
8760
8761 If there is only a single possible completion, C<readline> will use it in full.
8762
8763 This code uses C<map> and C<grep> heavily to create lists of possible
8764 completion. Think LISP in this section.
8765
8766 =cut
8767
8768 sub db_complete {
8769
8770     # Specific code for b c l V m f O, &blah, $blah, @blah, %blah
8771     # $text is the text to be completed.
8772     # $line is the incoming line typed by the user.
8773     # $start is the start of the text to be completed in the incoming line.
8774     my ( $text, $line, $start ) = @_;
8775
8776     # Save the initial text.
8777     # The search pattern is current package, ::, extract the next qualifier
8778     # Prefix and pack are set to undef.
8779     my ( $itext, $search, $prefix, $pack ) =
8780       ( $text, "^\Q${package}::\E([^:]+)\$" );
8781
8782 =head3 C<b postpone|compile>
8783
8784 =over 4
8785
8786 =item *
8787
8788 Find all the subroutines that might match in this package
8789
8790 =item *
8791
8792 Add C<postpone>, C<load>, and C<compile> as possibles (we may be completing the keyword itself)
8793
8794 =item *
8795
8796 Include all the rest of the subs that are known
8797
8798 =item *
8799
8800 C<grep> out the ones that match the text we have so far
8801
8802 =item *
8803
8804 Return this as the list of possible completions
8805
8806 =back
8807
8808 =cut
8809
8810     return sort grep /^\Q$text/, ( keys %sub ),
8811       qw(postpone load compile),    # subroutines
8812       ( map { /$search/ ? ($1) : () } keys %sub )
8813       if ( substr $line, 0, $start ) =~ /^\|*[blc]\s+((postpone|compile)\s+)?$/;
8814
8815 =head3 C<b load>
8816
8817 Get all the possible files from C<@INC> as it currently stands and
8818 select the ones that match the text so far.
8819
8820 =cut
8821
8822     return sort grep /^\Q$text/, values %INC    # files
8823       if ( substr $line, 0, $start ) =~ /^\|*b\s+load\s+$/;
8824
8825 =head3  C<V> (list variable) and C<m> (list modules)
8826
8827 There are two entry points for these commands:
8828
8829 =head4 Unqualified package names
8830
8831 Get the top-level packages and grab everything that matches the text
8832 so far. For each match, recursively complete the partial packages to
8833 get all possible matching packages. Return this sorted list.
8834
8835 =cut
8836
8837     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
8838       grep /^\Q$text/, map { /^(.*)::$/ ? ($1) : () } keys %::    # top-packages
8839       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/ and $text =~ /^\w*$/;
8840
8841 =head4 Qualified package names
8842
8843 Take a partially-qualified package and find all subpackages for it
8844 by getting all the subpackages for the package so far, matching all
8845 the subpackages against the text, and discarding all of them which
8846 start with 'main::'. Return this list.
8847
8848 =cut
8849
8850     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
8851       grep !/^main::/, grep /^\Q$text/,
8852       map { /^(.*)::$/ ? ( $prefix . "::$1" ) : () }
8853       do { no strict 'refs'; keys %{ $prefix . '::' } }
8854       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/
8855       and $text =~ /^(.*[^:])::?(\w*)$/
8856       and $prefix = $1;
8857
8858 =head3 C<f> - switch files
8859
8860 Here, we want to get a fully-qualified filename for the C<f> command.
8861 Possibilities are:
8862
8863 =over 4
8864
8865 =item 1. The original source file itself
8866
8867 =item 2. A file from C<@INC>
8868
8869 =item 3. An C<eval> (the debugger gets a C<(eval N)> fake file for each C<eval>).
8870
8871 =back
8872
8873 =cut
8874
8875     if ( $line =~ /^\|*f\s+(.*)/ ) {    # Loaded files
8876            # We might possibly want to switch to an eval (which has a "filename"
8877            # like '(eval 9)'), so we may need to clean up the completion text
8878            # before proceeding.
8879         $prefix = length($1) - length($text);
8880         $text   = $1;
8881
8882 =pod
8883
8884 Under the debugger, source files are represented as C<_E<lt>/fullpath/to/file>
8885 (C<eval>s are C<_E<lt>(eval NNN)>) keys in C<%main::>. We pull all of these
8886 out of C<%main::>, add the initial source file, and extract the ones that
8887 match the completion text so far.
8888
8889 =cut
8890
8891         return sort
8892           map { substr $_, 2 + $prefix } grep /^_<\Q$text/, ( keys %main:: ),
8893           $0;
8894     } ## end if ($line =~ /^\|*f\s+(.*)/)
8895
8896 =head3 Subroutine name completion
8897
8898 We look through all of the defined subs (the keys of C<%sub>) and
8899 return both all the possible matches to the subroutine name plus
8900 all the matches qualified to the current package.
8901
8902 =cut
8903
8904     if ( ( substr $text, 0, 1 ) eq '&' ) {    # subroutines
8905         $text = substr $text, 1;
8906         $prefix = "&";
8907         return sort map "$prefix$_", grep /^\Q$text/, ( keys %sub ),
8908           (
8909             map { /$search/ ? ($1) : () }
8910               keys %sub
8911           );
8912     } ## end if ((substr $text, 0, ...
8913
8914 =head3  Scalar, array, and hash completion: partially qualified package
8915
8916 Much like the above, except we have to do a little more cleanup:
8917
8918 =cut
8919
8920     if ( $text =~ /^[\$@%](.*)::(.*)/ ) {    # symbols in a package
8921
8922 =pod
8923
8924 =over 4
8925
8926 =item *
8927
8928 Determine the package that the symbol is in. Put it in C<::> (effectively C<main::>) if no package is specified.
8929
8930 =cut
8931
8932         $pack = ( $1 eq 'main' ? '' : $1 ) . '::';
8933
8934 =pod
8935
8936 =item *
8937
8938 Figure out the prefix vs. what needs completing.
8939
8940 =cut
8941
8942         $prefix = ( substr $text, 0, 1 ) . $1 . '::';
8943         $text   = $2;
8944
8945 =pod
8946
8947 =item *
8948
8949 Look through all the symbols in the package. C<grep> out all the possible hashes/arrays/scalars, and then C<grep> the possible matches out of those. C<map> the prefix onto all the possibilities.
8950
8951 =cut
8952
8953         my @out = do {
8954             no strict 'refs';
8955             map "$prefix$_", grep /^\Q$text/, grep /^_?[a-zA-Z]/,
8956             keys %$pack;
8957         };
8958
8959 =pod
8960
8961 =item *
8962
8963 If there's only one hit, and it's a package qualifier, and it's not equal to the initial text, re-complete it using the symbol we actually found.
8964
8965 =cut
8966
8967         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
8968             return db_complete( $out[0], $line, $start );
8969         }
8970
8971         # Return the list of possibles.
8972         return sort @out;
8973
8974     } ## end if ($text =~ /^[\$@%](.*)::(.*)/)
8975
8976 =pod
8977
8978 =back
8979
8980 =head3 Symbol completion: current package or package C<main>.
8981
8982 =cut
8983
8984     if ( $text =~ /^[\$@%]/ ) {    # symbols (in $package + packages in main)
8985 =pod
8986
8987 =over 4
8988
8989 =item *
8990
8991 If it's C<main>, delete main to just get C<::> leading.
8992
8993 =cut
8994
8995         $pack = ( $package eq 'main' ? '' : $package ) . '::';
8996
8997 =pod
8998
8999 =item *
9000
9001 We set the prefix to the item's sigil, and trim off the sigil to get the text to be completed.
9002
9003 =cut
9004
9005         $prefix = substr $text, 0, 1;
9006         $text   = substr $text, 1;
9007
9008         my @out;
9009
9010 =pod
9011
9012 =item *
9013
9014 We look for the lexical scope above DB::DB and auto-complete lexical variables
9015 if PadWalker could be loaded.
9016
9017 =cut
9018
9019         if (not $text =~ /::/ and eval { require PadWalker } ) {
9020             my $level = 1;
9021             while (1) {
9022                 my @info = caller($level);
9023                 $level++;
9024                 $level = -1, last
9025                   if not @info;
9026                 last if $info[3] eq 'DB::DB';
9027             }
9028             if ($level > 0) {
9029                 my $lexicals = PadWalker::peek_my($level);
9030                 push @out, grep /^\Q$prefix$text/, keys %$lexicals;
9031             }
9032         }
9033
9034 =pod
9035
9036 =item *
9037
9038 If the package is C<::> (C<main>), create an empty list; if it's something else, create a list of all the packages known.  Append whichever list to a list of all the possible symbols in the current package. C<grep> out the matches to the text entered so far, then C<map> the prefix back onto the symbols.
9039
9040 =cut
9041
9042         push @out, map "$prefix$_", grep /^\Q$text/,
9043           ( grep /^_?[a-zA-Z]/, keys %$pack ),
9044           ( $pack eq '::' ? () : ( grep /::$/, keys %:: ) );
9045
9046 =item *
9047
9048 If there's only one hit, it's a package qualifier, and it's not equal to the initial text, recomplete using this symbol.
9049
9050 =back
9051
9052 =cut
9053
9054         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
9055             return db_complete( $out[0], $line, $start );
9056         }
9057
9058         # Return the list of possibles.
9059         return sort @out;
9060     } ## end if ($text =~ /^[\$@%]/)
9061
9062 =head3 Options
9063
9064 We use C<option_val()> to look up the current value of the option. If there's
9065 only a single value, we complete the command in such a way that it is a
9066 complete command for setting the option in question. If there are multiple
9067 possible values, we generate a command consisting of the option plus a trailing
9068 question mark, which, if executed, will list the current value of the option.
9069
9070 =cut
9071
9072     if ( ( substr $line, 0, $start ) =~ /^\|*[oO]\b.*\s$/ )
9073     {    # Options after space
9074            # We look for the text to be matched in the list of possible options,
9075            # and fetch the current value.
9076         my @out = grep /^\Q$text/, @options;
9077         my $val = option_val( $out[0], undef );
9078
9079         # Set up a 'query option's value' command.
9080         my $out = '? ';
9081         if ( not defined $val or $val =~ /[\n\r]/ ) {
9082
9083             # There's really nothing else we can do.
9084         }
9085
9086         # We have a value. Create a proper option-setting command.
9087         elsif ( $val =~ /\s/ ) {
9088
9089             # XXX This may be an extraneous variable.
9090             my $found;
9091
9092             # We'll want to quote the string (because of the embedded
9093             # whtespace), but we want to make sure we don't end up with
9094             # mismatched quote characters. We try several possibilities.
9095             foreach my $l ( split //, qq/\"\'\#\|/ ) {
9096
9097                 # If we didn't find this quote character in the value,
9098                 # quote it using this quote character.
9099                 $out = "$l$val$l ", last if ( index $val, $l ) == -1;
9100             }
9101         } ## end elsif ($val =~ /\s/)
9102
9103         # Don't need any quotes.
9104         else {
9105             $out = "=$val ";
9106         }
9107
9108         # If there were multiple possible values, return '? ', which
9109         # makes the command into a query command. If there was just one,
9110         # have readline append that.
9111         $rl_attribs->{completer_terminator_character} =
9112           ( @out == 1 ? $out : '? ' );
9113
9114         # Return list of possibilities.
9115         return sort @out;
9116     } ## end if ((substr $line, 0, ...
9117
9118 =head3 Filename completion
9119
9120 For entering filenames. We simply call C<readline>'s C<filename_list()>
9121 method with the completion text to get the possible completions.
9122
9123 =cut
9124
9125     return $term->filename_list($text);    # filenames
9126
9127 } ## end sub db_complete
9128
9129 =head1 MISCELLANEOUS SUPPORT FUNCTIONS
9130
9131 Functions that possibly ought to be somewhere else.
9132
9133 =head2 end_report
9134
9135 Say we're done.
9136
9137 =cut
9138
9139 sub end_report {
9140     local $\ = '';
9141     print $OUT "Use 'q' to quit or 'R' to restart.  'h q' for details.\n";
9142 }
9143
9144 =head2 clean_ENV
9145
9146 If we have $ini_pids, save it in the environment; else remove it from the
9147 environment. Used by the C<R> (restart) command.
9148
9149 =cut
9150
9151 sub clean_ENV {
9152     if ( defined($ini_pids) ) {
9153         $ENV{PERLDB_PIDS} = $ini_pids;
9154     }
9155     else {
9156         delete( $ENV{PERLDB_PIDS} );
9157     }
9158 } ## end sub clean_ENV
9159
9160 # PERLDBf_... flag names from perl.h
9161 our ( %DollarCaretP_flags, %DollarCaretP_flags_r );
9162
9163 BEGIN {
9164     %DollarCaretP_flags = (
9165         PERLDBf_SUB       => 0x01,     # Debug sub enter/exit
9166         PERLDBf_LINE      => 0x02,     # Keep line #
9167         PERLDBf_NOOPT     => 0x04,     # Switch off optimizations
9168         PERLDBf_INTER     => 0x08,     # Preserve more data
9169         PERLDBf_SUBLINE   => 0x10,     # Keep subr source lines
9170         PERLDBf_SINGLE    => 0x20,     # Start with single-step on
9171         PERLDBf_NONAME    => 0x40,     # For _SUB: no name of the subr
9172         PERLDBf_GOTO      => 0x80,     # Report goto: call DB::goto
9173         PERLDBf_NAMEEVAL  => 0x100,    # Informative names for evals
9174         PERLDBf_NAMEANON  => 0x200,    # Informative names for anon subs
9175         PERLDBf_SAVESRC   => 0x400,    # Save source lines into @{"_<$filename"}
9176         PERLDB_ALL        => 0x33f,    # No _NONAME, _GOTO
9177     );
9178     # PERLDBf_LINE also enables the actions of PERLDBf_SAVESRC, so the debugger
9179     # doesn't need to set it. It's provided for the benefit of profilers and
9180     # other code analysers.
9181
9182     %DollarCaretP_flags_r = reverse %DollarCaretP_flags;
9183 }
9184
9185 sub parse_DollarCaretP_flags {
9186     my $flags = shift;
9187     $flags =~ s/^\s+//;
9188     $flags =~ s/\s+$//;
9189     my $acu = 0;
9190     foreach my $f ( split /\s*\|\s*/, $flags ) {
9191         my $value;
9192         if ( $f =~ /^0x([[:xdigit:]]+)$/ ) {
9193             $value = hex $1;
9194         }
9195         elsif ( $f =~ /^(\d+)$/ ) {
9196             $value = int $1;
9197         }
9198         elsif ( $f =~ /^DEFAULT$/i ) {
9199             $value = $DollarCaretP_flags{PERLDB_ALL};
9200         }
9201         else {
9202             $f =~ /^(?:PERLDBf_)?(.*)$/i;
9203             $value = $DollarCaretP_flags{ 'PERLDBf_' . uc($1) };
9204             unless ( defined $value ) {
9205                 print $OUT (
9206                     "Unrecognized \$^P flag '$f'!\n",
9207                     "Acceptable flags are: "
9208                       . join( ', ', sort keys %DollarCaretP_flags ),
9209                     ", and hexadecimal and decimal numbers.\n"
9210                 );
9211                 return undef;
9212             }
9213         }
9214         $acu |= $value;
9215     }
9216     $acu;
9217 }
9218
9219 sub expand_DollarCaretP_flags {
9220     my $DollarCaretP = shift;
9221     my @bits         = (
9222         map {
9223             my $n = ( 1 << $_ );
9224             ( $DollarCaretP & $n )
9225               ? ( $DollarCaretP_flags_r{$n}
9226                   || sprintf( '0x%x', $n ) )
9227               : ()
9228           } 0 .. 31
9229     );
9230     return @bits ? join( '|', @bits ) : 0;
9231 }
9232
9233 =over 4
9234
9235 =item rerun
9236
9237 Rerun the current session to:
9238
9239     rerun        current position
9240
9241     rerun 4      command number 4
9242
9243     rerun -4     current command minus 4 (go back 4 steps)
9244
9245 Whether this always makes sense, in the current context is unknowable, and is
9246 in part left as a useful exercise for the reader.  This sub returns the
9247 appropriate arguments to rerun the current session.
9248
9249 =cut
9250
9251 sub rerun {
9252     my $i = shift;
9253     my @args;
9254     pop(@truehist);                      # strim
9255     unless (defined $truehist[$i]) {
9256         print "Unable to return to non-existent command: $i\n";
9257     } else {
9258         $#truehist = ($i < 0 ? $#truehist + $i : $i > 0 ? $i : $#truehist);
9259         my @temp = @truehist;            # store
9260         push(@DB::typeahead, @truehist); # saved
9261         @truehist = @hist = ();          # flush
9262         @args = &restart();              # setup
9263         &get_list("PERLDB_HIST");        # clean
9264         &set_list("PERLDB_HIST", @temp); # reset
9265     }
9266     return @args;
9267 }
9268
9269 =item restart
9270
9271 Restarting the debugger is a complex operation that occurs in several phases.
9272 First, we try to reconstruct the command line that was used to invoke Perl
9273 and the debugger.
9274
9275 =cut
9276
9277 sub restart {
9278     # I may not be able to resurrect you, but here goes ...
9279     print $OUT
9280 "Warning: some settings and command-line options may be lost!\n";
9281     my ( @script, @flags, $cl );
9282
9283     # If warn was on before, turn it on again.
9284     push @flags, '-w' if $ini_warn;
9285
9286     # Rebuild the -I flags that were on the initial
9287     # command line.
9288     for (@ini_INC) {
9289         push @flags, '-I', $_;
9290     }
9291
9292     # Turn on taint if it was on before.
9293     push @flags, '-T' if ${^TAINT};
9294
9295     # Arrange for setting the old INC:
9296     # Save the current @init_INC in the environment.
9297     set_list( "PERLDB_INC", @ini_INC );
9298
9299     # If this was a perl one-liner, go to the "file"
9300     # corresponding to the one-liner read all the lines
9301     # out of it (except for the first one, which is going
9302     # to be added back on again when 'perl -d' runs: that's
9303     # the 'require perl5db.pl;' line), and add them back on
9304     # to the command line to be executed.
9305     if ( $0 eq '-e' ) {
9306         my $lines = *{$main::{'_<-e'}}{ARRAY};
9307         for ( 1 .. $#$lines ) {  # The first line is PERL5DB
9308             chomp( $cl = $lines->[$_] );
9309             push @script, '-e', $cl;
9310         }
9311     } ## end if ($0 eq '-e')
9312
9313     # Otherwise we just reuse the original name we had
9314     # before.
9315     else {
9316         @script = $0;
9317     }
9318
9319 =pod
9320
9321 After the command line  has been reconstructed, the next step is to save
9322 the debugger's status in environment variables. The C<DB::set_list> routine
9323 is used to save aggregate variables (both hashes and arrays); scalars are
9324 just popped into environment variables directly.
9325
9326 =cut
9327
9328     # If the terminal supported history, grab it and
9329     # save that in the environment.
9330     set_list( "PERLDB_HIST",
9331           $term->Features->{getHistory}
9332         ? $term->GetHistory
9333         : @hist );
9334
9335     # Find all the files that were visited during this
9336     # session (i.e., the debugger had magic hashes
9337     # corresponding to them) and stick them in the environment.
9338     my @had_breakpoints = keys %had_breakpoints;
9339     set_list( "PERLDB_VISITED", @had_breakpoints );
9340
9341     # Save the debugger options we chose.
9342     set_list( "PERLDB_OPT", %option );
9343     # set_list( "PERLDB_OPT", options2remember() );
9344
9345     # Save the break-on-loads.
9346     set_list( "PERLDB_ON_LOAD", %break_on_load );
9347
9348 =pod
9349
9350 The most complex part of this is the saving of all of the breakpoints. They
9351 can live in an awful lot of places, and we have to go through all of them,
9352 find the breakpoints, and then save them in the appropriate environment
9353 variable via C<DB::set_list>.
9354
9355 =cut
9356
9357     # Go through all the breakpoints and make sure they're
9358     # still valid.
9359     my @hard;
9360     for ( 0 .. $#had_breakpoints ) {
9361
9362         # We were in this file.
9363         my $file = $had_breakpoints[$_];
9364
9365         # Grab that file's magic line hash.
9366         *dbline = $main::{ '_<' . $file };
9367
9368         # Skip out if it doesn't exist, or if the breakpoint
9369         # is in a postponed file (we'll do postponed ones
9370         # later).
9371         next unless %dbline or $postponed_file{$file};
9372
9373         # In an eval. This is a little harder, so we'll
9374         # do more processing on that below.
9375         ( push @hard, $file ), next
9376           if $file =~ /^\(\w*eval/;
9377
9378         # XXX I have no idea what this is doing. Yet.
9379         my @add;
9380         @add = %{ $postponed_file{$file} }
9381           if $postponed_file{$file};
9382
9383         # Save the list of all the breakpoints for this file.
9384         set_list( "PERLDB_FILE_$_", %dbline, @add );
9385
9386         # Serialize the extra data %breakpoints_data hash.
9387         # That's a bug fix.
9388         set_list( "PERLDB_FILE_ENABLED_$_",
9389             map { _is_breakpoint_enabled($file, $_) ? 1 : 0 }
9390             sort { $a <=> $b } keys(%dbline)
9391         )
9392     } ## end for (0 .. $#had_breakpoints)
9393
9394     # The breakpoint was inside an eval. This is a little
9395     # more difficult. XXX and I don't understand it.
9396     for (@hard) {
9397         # Get over to the eval in question.
9398         *dbline = $main::{ '_<' . $_ };
9399         my ( $quoted, $sub, %subs, $line ) = quotemeta $_;
9400         for $sub ( keys %sub ) {
9401             next unless $sub{$sub} =~ /^$quoted:(\d+)-(\d+)$/;
9402             $subs{$sub} = [ $1, $2 ];
9403         }
9404         unless (%subs) {
9405             print $OUT
9406               "No subroutines in $_, ignoring breakpoints.\n";
9407             next;
9408         }
9409       LINES: for $line ( keys %dbline ) {
9410
9411             # One breakpoint per sub only:
9412             my ( $offset, $sub, $found );
9413           SUBS: for $sub ( keys %subs ) {
9414                 if (
9415                     $subs{$sub}->[1] >=
9416                     $line    # Not after the subroutine
9417                     and (
9418                         not defined $offset    # Not caught
9419                         or $offset < 0
9420                     )
9421                   )
9422                 {                              # or badly caught
9423                     $found  = $sub;
9424                     $offset = $line - $subs{$sub}->[0];
9425                     $offset = "+$offset", last SUBS
9426                       if $offset >= 0;
9427                 } ## end if ($subs{$sub}->[1] >=...
9428             } ## end for $sub (keys %subs)
9429             if ( defined $offset ) {
9430                 $postponed{$found} =
9431                   "break $offset if $dbline{$line}";
9432             }
9433             else {
9434                 print $OUT
9435 "Breakpoint in $_:$line ignored: after all the subroutines.\n";
9436             }
9437         } ## end for $line (keys %dbline)
9438     } ## end for (@hard)
9439
9440     # Save the other things that don't need to be
9441     # processed.
9442     set_list( "PERLDB_POSTPONE",  %postponed );
9443     set_list( "PERLDB_PRETYPE",   @$pretype );
9444     set_list( "PERLDB_PRE",       @$pre );
9445     set_list( "PERLDB_POST",      @$post );
9446     set_list( "PERLDB_TYPEAHEAD", @typeahead );
9447
9448     # We are officially restarting.
9449     $ENV{PERLDB_RESTART} = 1;
9450
9451     # We are junking all child debuggers.
9452     delete $ENV{PERLDB_PIDS};    # Restore ini state
9453
9454     # Set this back to the initial pid.
9455     $ENV{PERLDB_PIDS} = $ini_pids if defined $ini_pids;
9456
9457 =pod
9458
9459 After all the debugger status has been saved, we take the command we built up
9460 and then return it, so we can C<exec()> it. The debugger will spot the
9461 C<PERLDB_RESTART> environment variable and realize it needs to reload its state
9462 from the environment.
9463
9464 =cut
9465
9466     # And run Perl again. Add the "-d" flag, all the
9467     # flags we built up, the script (whether a one-liner
9468     # or a file), add on the -emacs flag for a slave editor,
9469     # and then the old arguments.
9470
9471     return ($^X, '-d', @flags, @script, ($slave_editor ? '-emacs' : ()), @ARGS);
9472
9473 };  # end restart
9474
9475 =back
9476
9477 =head1 END PROCESSING - THE C<END> BLOCK
9478
9479 Come here at the very end of processing. We want to go into a
9480 loop where we allow the user to enter commands and interact with the
9481 debugger, but we don't want anything else to execute.
9482
9483 First we set the C<$finished> variable, so that some commands that
9484 shouldn't be run after the end of program quit working.
9485
9486 We then figure out whether we're truly done (as in the user entered a C<q>
9487 command, or we finished execution while running nonstop). If we aren't,
9488 we set C<$single> to 1 (causing the debugger to get control again).
9489
9490 We then call C<DB::fake::at_exit()>, which returns the C<Use 'q' to quit ...>
9491 message and returns control to the debugger. Repeat.
9492
9493 When the user finally enters a C<q> command, C<$fall_off_end> is set to
9494 1 and the C<END> block simply exits with C<$single> set to 0 (don't
9495 break, run to completion.).
9496
9497 =cut
9498
9499 END {
9500     $finished = 1 if $inhibit_exit;    # So that some commands may be disabled.
9501     $fall_off_end = 1 unless $inhibit_exit;
9502
9503     # Do not stop in at_exit() and destructors on exit:
9504     if ($fall_off_end or $runnonstop) {
9505         &save_hist();
9506     } else {
9507         $DB::single = 1;
9508         DB::fake::at_exit();
9509     }
9510 } ## end END
9511
9512 =head1 PRE-5.8 COMMANDS
9513
9514 Some of the commands changed function quite a bit in the 5.8 command
9515 realignment, so much so that the old code had to be replaced completely.
9516 Because we wanted to retain the option of being able to go back to the
9517 former command set, we moved the old code off to this section.
9518
9519 There's an awful lot of duplicated code here. We've duplicated the
9520 comments to keep things clear.
9521
9522 =head2 Null command
9523
9524 Does nothing. Used to I<turn off> commands.
9525
9526 =cut
9527
9528 sub cmd_pre580_null {
9529
9530     # do nothing...
9531 }
9532
9533 =head2 Old C<a> command.
9534
9535 This version added actions if you supplied them, and deleted them
9536 if you didn't.
9537
9538 =cut
9539
9540 sub cmd_pre580_a {
9541     my $xcmd = shift;
9542     my $cmd  = shift;
9543
9544     # Argument supplied. Add the action.
9545     if ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9546
9547         # If the line isn't there, use the current line.
9548         my $i = $1 || $line;
9549         my $j = $2;
9550
9551         # If there is an action ...
9552         if ( length $j ) {
9553
9554             # ... but the line isn't breakable, skip it.
9555             if ( $dbline[$i] == 0 ) {
9556                 print $OUT "Line $i may not have an action.\n";
9557             }
9558             else {
9559
9560                 # ... and the line is breakable:
9561                 # Mark that there's an action in this file.
9562                 $had_breakpoints{$filename} |= 2;
9563
9564                 # Delete any current action.
9565                 $dbline{$i} =~ s/\0[^\0]*//;
9566
9567                 # Add the new action, continuing the line as needed.
9568                 $dbline{$i} .= "\0" . action($j);
9569             }
9570         } ## end if (length $j)
9571
9572         # No action supplied.
9573         else {
9574
9575             # Delete the action.
9576             $dbline{$i} =~ s/\0[^\0]*//;
9577
9578             # Mark as having no break or action if nothing's left.
9579             delete $dbline{$i} if $dbline{$i} eq '';
9580         }
9581     } ## end if ($cmd =~ /^(\d*)\s*(.*)/)
9582 } ## end sub cmd_pre580_a
9583
9584 =head2 Old C<b> command
9585
9586 Add breakpoints.
9587
9588 =cut
9589
9590 sub cmd_pre580_b {
9591     my $xcmd   = shift;
9592     my $cmd    = shift;
9593     my $dbline = shift;
9594
9595     # Break on load.
9596     if ( $cmd =~ /^load\b\s*(.*)/ ) {
9597         my $file = $1;
9598         $file =~ s/\s+$//;
9599         &cmd_b_load($file);
9600     }
9601
9602     # b compile|postpone <some sub> [<condition>]
9603     # The interpreter actually traps this one for us; we just put the
9604     # necessary condition in the %postponed hash.
9605     elsif ( $cmd =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
9606
9607         # Capture the condition if there is one. Make it true if none.
9608         my $cond = length $3 ? $3 : '1';
9609
9610         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
9611         # if it was 'compile'.
9612         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
9613
9614         # De-Perl4-ify the name - ' separators to ::.
9615         $subname =~ s/\'/::/g;
9616
9617         # Qualify it into the current package unless it's already qualified.
9618         $subname = "${package}::" . $subname
9619           unless $subname =~ /::/;
9620
9621         # Add main if it starts with ::.
9622         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
9623
9624         # Save the break type for this sub.
9625         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
9626     } ## end elsif ($cmd =~ ...
9627
9628     # b <sub name> [<condition>]
9629     elsif ( $cmd =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
9630         my $subname = $1;
9631         my $cond = length $2 ? $2 : '1';
9632         &cmd_b_sub( $subname, $cond );
9633     }
9634     # b <line> [<condition>].
9635     elsif ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9636         my $i = $1 || $dbline;
9637         my $cond = length $2 ? $2 : '1';
9638         &cmd_b_line( $i, $cond );
9639     }
9640 } ## end sub cmd_pre580_b
9641
9642 =head2 Old C<D> command.
9643
9644 Delete all breakpoints unconditionally.
9645
9646 =cut
9647
9648 sub cmd_pre580_D {
9649     my $xcmd = shift;
9650     my $cmd  = shift;
9651     if ( $cmd =~ /^\s*$/ ) {
9652         print $OUT "Deleting all breakpoints...\n";
9653
9654         # %had_breakpoints lists every file that had at least one
9655         # breakpoint in it.
9656         my $file;
9657         for $file ( keys %had_breakpoints ) {
9658
9659             # Switch to the desired file temporarily.
9660             local *dbline = $main::{ '_<' . $file };
9661
9662             $max = $#dbline;
9663             my $was;
9664
9665             # For all lines in this file ...
9666             for my $i (1 .. $max) {
9667
9668                 # If there's a breakpoint or action on this line ...
9669                 if ( defined $dbline{$i} ) {
9670
9671                     # ... remove the breakpoint.
9672                     $dbline{$i} =~ s/^[^\0]+//;
9673                     if ( $dbline{$i} =~ s/^\0?$// ) {
9674
9675                         # Remove the entry altogether if no action is there.
9676                         delete $dbline{$i};
9677                     }
9678                 } ## end if (defined $dbline{$i...
9679             } ## end for my $i (1 .. $max)
9680
9681             # If, after we turn off the "there were breakpoints in this file"
9682             # bit, the entry in %had_breakpoints for this file is zero,
9683             # we should remove this file from the hash.
9684             if ( not $had_breakpoints{$file} &= ~1 ) {
9685                 delete $had_breakpoints{$file};
9686             }
9687         } ## end for $file (keys %had_breakpoints)
9688
9689         # Kill off all the other breakpoints that are waiting for files that
9690         # haven't been loaded yet.
9691         undef %postponed;
9692         undef %postponed_file;
9693         undef %break_on_load;
9694     } ## end if ($cmd =~ /^\s*$/)
9695 } ## end sub cmd_pre580_D
9696
9697 =head2 Old C<h> command
9698
9699 Print help. Defaults to printing the long-form help; the 5.8 version
9700 prints the summary by default.
9701
9702 =cut
9703
9704 sub cmd_pre580_h {
9705     my $xcmd = shift;
9706     my $cmd  = shift;
9707
9708     # Print the *right* help, long format.
9709     if ( $cmd =~ /^\s*$/ ) {
9710         print_help($pre580_help);
9711     }
9712
9713     # 'h h' - explicitly-requested summary.
9714     elsif ( $cmd =~ /^h\s*/ ) {
9715         print_help($pre580_summary);
9716     }
9717
9718     # Find and print a command's help.
9719     elsif ( $cmd =~ /^h\s+(\S.*)$/ ) {
9720         my $asked  = $1;                   # for proper errmsg
9721         my $qasked = quotemeta($asked);    # for searching
9722                                            # XXX: finds CR but not <CR>
9723         if (
9724             $pre580_help =~ /^
9725                               <?           # Optional '<'
9726                               (?:[IB]<)    # Optional markup
9727                               $qasked      # The command name
9728                             /mx
9729           )
9730         {
9731
9732             while (
9733                 $pre580_help =~ /^
9734                                   (             # The command help:
9735                                    <?           # Optional '<'
9736                                    (?:[IB]<)    # Optional markup
9737                                    $qasked      # The command name
9738                                    ([\s\S]*?)   # Lines starting with tabs
9739                                    \n           # Final newline
9740                                   )
9741                                   (?!\s)/mgx
9742               )    # Line not starting with space
9743                    # (Next command's help)
9744             {
9745                 print_help($1);
9746             }
9747         } ## end if ($pre580_help =~ /^<?(?:[IB]<)$qasked/m)
9748
9749         # Help not found.
9750         else {
9751             print_help("B<$asked> is not a debugger command.\n");
9752         }
9753     } ## end elsif ($cmd =~ /^h\s+(\S.*)$/)
9754 } ## end sub cmd_pre580_h
9755
9756 =head2 Old C<W> command
9757
9758 C<W E<lt>exprE<gt>> adds a watch expression, C<W> deletes them all.
9759
9760 =cut
9761
9762 sub cmd_pre580_W {
9763     my $xcmd = shift;
9764     my $cmd  = shift;
9765
9766     # Delete all watch expressions.
9767     if ( $cmd =~ /^$/ ) {
9768
9769         # No watching is going on.
9770         $trace &= ~2;
9771
9772         # Kill all the watch expressions and values.
9773         @to_watch = @old_watch = ();
9774     }
9775
9776     # Add a watch expression.
9777     elsif ( $cmd =~ /^(.*)/s ) {
9778
9779         # add it to the list to be watched.
9780         push @to_watch, $1;
9781
9782         # Get the current value of the expression.
9783         # Doesn't handle expressions returning list values!
9784         $evalarg = $1;
9785         my ($val) = DB::eval();
9786         $val = ( defined $val ) ? "'$val'" : 'undef';
9787
9788         # Save it.
9789         push @old_watch, $val;
9790
9791         # We're watching stuff.
9792         $trace |= 2;
9793
9794     } ## end elsif ($cmd =~ /^(.*)/s)
9795 } ## end sub cmd_pre580_W
9796
9797 =head1 PRE-AND-POST-PROMPT COMMANDS AND ACTIONS
9798
9799 The debugger used to have a bunch of nearly-identical code to handle
9800 the pre-and-post-prompt action commands. C<cmd_pre590_prepost> and
9801 C<cmd_prepost> unify all this into one set of code to handle the
9802 appropriate actions.
9803
9804 =head2 C<cmd_pre590_prepost>
9805
9806 A small wrapper around C<cmd_prepost>; it makes sure that the default doesn't
9807 do something destructive. In pre 5.8 debuggers, the default action was to
9808 delete all the actions.
9809
9810 =cut
9811
9812 sub cmd_pre590_prepost {
9813     my $cmd    = shift;
9814     my $line   = shift || '*';
9815     my $dbline = shift;
9816
9817     return &cmd_prepost( $cmd, $line, $dbline );
9818 } ## end sub cmd_pre590_prepost
9819
9820 =head2 C<cmd_prepost>
9821
9822 Actually does all the handling for C<E<lt>>, C<E<gt>>, C<{{>, C<{>, etc.
9823 Since the lists of actions are all held in arrays that are pointed to by
9824 references anyway, all we have to do is pick the right array reference and
9825 then use generic code to all, delete, or list actions.
9826
9827 =cut
9828
9829 sub cmd_prepost {
9830     my $cmd = shift;
9831
9832     # No action supplied defaults to 'list'.
9833     my $line = shift || '?';
9834
9835     # Figure out what to put in the prompt.
9836     my $which = '';
9837
9838     # Make sure we have some array or another to address later.
9839     # This means that if ssome reason the tests fail, we won't be
9840     # trying to stash actions or delete them from the wrong place.
9841     my $aref = [];
9842
9843     # < - Perl code to run before prompt.
9844     if ( $cmd =~ /^\</o ) {
9845         $which = 'pre-perl';
9846         $aref  = $pre;
9847     }
9848
9849     # > - Perl code to run after prompt.
9850     elsif ( $cmd =~ /^\>/o ) {
9851         $which = 'post-perl';
9852         $aref  = $post;
9853     }
9854
9855     # { - first check for properly-balanced braces.
9856     elsif ( $cmd =~ /^\{/o ) {
9857         if ( $cmd =~ /^\{.*\}$/o && unbalanced( substr( $cmd, 1 ) ) ) {
9858             print $OUT
9859 "$cmd is now a debugger command\nuse ';$cmd' if you mean Perl code\n";
9860         }
9861
9862         # Properly balanced. Pre-prompt debugger actions.
9863         else {
9864             $which = 'pre-debugger';
9865             $aref  = $pretype;
9866         }
9867     } ## end elsif ( $cmd =~ /^\{/o )
9868
9869     # Did we find something that makes sense?
9870     unless ($which) {
9871         print $OUT "Confused by command: $cmd\n";
9872     }
9873
9874     # Yes.
9875     else {
9876
9877         # List actions.
9878         if ( $line =~ /^\s*\?\s*$/o ) {
9879             unless (@$aref) {
9880
9881                 # Nothing there. Complain.
9882                 print $OUT "No $which actions.\n";
9883             }
9884             else {
9885
9886                 # List the actions in the selected list.
9887                 print $OUT "$which commands:\n";
9888                 foreach my $action (@$aref) {
9889                     print $OUT "\t$cmd -- $action\n";
9890                 }
9891             } ## end else
9892         } ## end if ( $line =~ /^\s*\?\s*$/o)
9893
9894         # Might be a delete.
9895         else {
9896             if ( length($cmd) == 1 ) {
9897                 if ( $line =~ /^\s*\*\s*$/o ) {
9898
9899                     # It's a delete. Get rid of the old actions in the
9900                     # selected list..
9901                     @$aref = ();
9902                     print $OUT "All $cmd actions cleared.\n";
9903                 }
9904                 else {
9905
9906                     # Replace all the actions. (This is a <, >, or {).
9907                     @$aref = action($line);
9908                 }
9909             } ## end if ( length($cmd) == 1)
9910             elsif ( length($cmd) == 2 ) {
9911
9912                 # Add the action to the line. (This is a <<, >>, or {{).
9913                 push @$aref, action($line);
9914             }
9915             else {
9916
9917                 # <<<, >>>>, {{{{{{ ... something not a command.
9918                 print $OUT
9919                   "Confused by strange length of $which command($cmd)...\n";
9920             }
9921         } ## end else [ if ( $line =~ /^\s*\?\s*$/o)
9922     } ## end else
9923 } ## end sub cmd_prepost
9924
9925 =head1 C<DB::fake>
9926
9927 Contains the C<at_exit> routine that the debugger uses to issue the
9928 C<Debugged program terminated ...> message after the program completes. See
9929 the C<END> block documentation for more details.
9930
9931 =cut
9932
9933 package DB::fake;
9934
9935 sub at_exit {
9936     "Debugged program terminated.  Use 'q' to quit or 'R' to restart.";
9937 }
9938
9939 package DB;    # Do not trace this 1; below!
9940
9941 1;
9942
9943