This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
t/re/regexp_unicode_prop.t: Avoid a TEST crash if failure
[perl5.git] / t / re / regexp_unicode_prop.t
1 #!./perl
2 #
3 # Tests that have to do with checking whether characters have (or not have)
4 # certain Unicode properties; belong (or not belong) to blocks, scripts, etc.
5 #
6
7 use strict;
8 use warnings;
9 use 5.010;
10
11 my @warnings;
12 local $SIG {__WARN__} = sub {push @warnings, "@_"};
13
14 BEGIN {
15     chdir 't' if -d 't';
16     require './test.pl';
17     skip_all_if_miniperl("no dynamic loading on miniperl, no File::Spec (used by charnames)");
18 }
19
20 sub run_tests;
21
22 sub get_str_name($) {
23     my $char = shift;
24
25     my ($str, $name);
26
27     if ($char =~ /^\\/) {
28         $str  = eval qq ["$char"];
29         $name =      qq ["$char"];
30     }
31     elsif ($char =~ /^0x([0-9A-Fa-f]+)$/) {
32         $str  =  chr hex $1;
33         $name = "chr ($char)";
34     }
35     else {
36         $str  =      $char;
37         $name = qq ["$char"];
38     }
39
40     return ($str, $name);
41 }
42
43 #
44 # This is the data to test.
45 #
46 # This is a hash; keys are the property to test.
47 # Values are arrays containing characters to test. The characters can
48 # have the following formats:
49 #   '\N{CHARACTER NAME}'  -  Use character with that name
50 #   '\x{1234}'            -  Use character with that hex escape
51 #   '0x1234'              -  Use chr() to get that character
52 #   "a"                   -  Character to use
53 #
54 # If a character entry starts with ! the character does not belong to the class
55 #
56 # If the class is just single letter, we use both \pL and \p{L}
57 #
58
59 use charnames ':full';
60
61 my @CLASSES = (
62     L                         => ["a", "A"],
63     Ll                        => ["b", "!B"],
64     Lu                        => ["!c", "C"],
65     IsLl                      => ["d", "!D"],
66     IsLu                      => ["!e", "E"],
67     LC                        => ["f", "!1"],
68    'L&'                       => ["g", "!2"],
69    'Lowercase Letter'         => ["h", "!H"],
70
71     Common                    => ["!i", "3"],
72     Inherited                 => ["!j", '\x{300}'],
73
74     InBasicLatin              => ['\N{LATIN CAPITAL LETTER A}'],
75     InLatin1Supplement        => ['\N{LATIN CAPITAL LETTER A WITH GRAVE}'],
76     InLatinExtendedA          => ['\N{LATIN CAPITAL LETTER A WITH MACRON}'],
77     InLatinExtendedB          => ['\N{LATIN SMALL LETTER B WITH STROKE}'],
78     InKatakana                => ['\N{KATAKANA LETTER SMALL A}'],
79     IsLatin                   => ["0x100", "0x212b"],
80     IsHebrew                  => ["0x5d0", "0xfb4f"],
81     IsGreek                   => ["0x37a", "0x386", "!0x387", "0x388",
82                                   "0x38a", "!0x38b", "0x38c"],
83     HangulSyllables           => ['\x{AC00}'],
84    'Script=Latin'             => ['\x{0100}'],
85    'Block=LatinExtendedA'     => ['\x{0100}'],
86    'Category=UppercaseLetter' => ['\x{0100}'],
87
88     #
89     # It's ok to repeat class names.
90     #
91     InLatin1Supplement        =>
92                             ['!\N{U+7f}',  '\N{U+80}',  '\N{U+ff}', '!\x{100}'],
93     InLatinExtendedA          =>
94                             ['!\N{U+7f}', '!\N{U+80}', '!\N{U+ff}',  '\x{100}'],
95
96     #
97     # Properties are case-insensitive, and may have whitespace,
98     # dashes and underscores.
99     #
100    'in-latin1_SUPPLEMENT'     => ['\N{U+80}',
101                                   '\N{LATIN SMALL LETTER Y WITH DIAERESIS}'],
102    '  ^  In Latin 1 Supplement  '
103                               => ['!\N{U+80}', '\N{COFFIN}'],
104    'latin-1   supplement'     => ['\N{U+80}', "0xDF"],
105
106 );
107
108     my @USER_DEFINED_PROPERTIES = (
109         #
110         # User defined properties
111         #
112         InKana1                   => ['\x{3040}', '!\x{303F}'],
113         InKana2                   => ['\x{3040}', '!\x{303F}'],
114         InKana3                   => ['\x{3041}', '!\x{3040}'],
115         InNotKana                 => ['\x{3040}', '!\x{3041}'],
116         InConsonant               => ['d',        '!e'],
117         IsSyriac1                 => ['\x{0712}', '!\x{072F}'],
118         IsSyriac1KanaMark         => ['\x{309A}', '!\x{3090}'],
119         IsSyriac1KanaMark         => ['\x{0730}', '!\x{0712}'],
120         '# User-defined character properties may lack \n at the end',
121         InGreekSmall              => ['\N{GREEK SMALL LETTER PI}',
122                                         '\N{GREEK SMALL LETTER FINAL SIGMA}'],
123         InGreekCapital            => ['\N{GREEK CAPITAL LETTER PI}', '!\x{03A2}'],
124         Dash                      => ['-'],
125         ASCII_Hex_Digit           => ['!-', 'A'],
126         IsAsciiHexAndDash         => ['-', 'A'],
127
128         # This overrides the official one
129         InLatin1                  => ['\x{0100}', '!\x{00FF}'],
130     );
131
132     my @USER_CASELESS_PROPERTIES = (
133         #
134         # User defined properties which differ depending on /i.  Second entry
135         # is false normally, true under /i
136         #
137         'IsMyUpper'                => ["M", "!m" ],
138     );
139
140
141 #
142 # From the short properties we populate POSIX-like classes.
143 #
144 my %SHORT_PROPERTIES = (
145     'Ll'  => ['m', '\N{CYRILLIC SMALL LETTER A}'],
146     'Lu'  => ['M', '\N{GREEK CAPITAL LETTER ALPHA}'],
147     'Lo'  => ['\N{HIRAGANA LETTER SMALL A}'],
148     # is also in other alphabetic
149     'Mn'  => ['\N{HEBREW POINT RAFE}'],
150     'Nd'  => ["0", '\N{ARABIC-INDIC DIGIT ZERO}'],
151     'Pc'  => ["_"],
152     'Po'  => ["!"],
153     'Zs'  => [" "],
154     'Cc'  => ['\x{00}'],
155 );
156
157 #
158 # Illegal properties
159 #
160 my @ILLEGAL_PROPERTIES =
161     qw[q qrst f foo isfoo infoo ISfoo INfoo Is::foo In::foo];
162
163 my %d;
164
165 while (my ($class, $chars) = each %SHORT_PROPERTIES) {
166     push @{$d {IsAlpha}} => map {$class =~ /^[LM]/   ? $_ : "!$_"} @$chars;
167     push @{$d {IsAlnum}} => map {$class =~ /^[LMN]./ ? $_ : "!$_"} @$chars;
168     push @{$d {IsASCII}} => map {length ($_) == 1 || $_ eq '\x{00}'
169                                                      ? $_ : "!$_"} @$chars;
170     push @{$d {IsCntrl}} => map {$class =~ /^C/      ? $_ : "!$_"} @$chars;
171     push @{$d {IsBlank}} => map {$class =~ /^Z[lps]/ ? $_ : "!$_"} @$chars;
172     push @{$d {IsDigit}} => map {$class =~ /^Nd$/    ? $_ : "!$_"} @$chars;
173     push @{$d {IsGraph}} => map {$class =~ /^([LMNPS]|Co)/
174                                                      ? $_ : "!$_"} @$chars;
175     push @{$d {IsPrint}} => map {$class =~ /^([LMNPS]|Co|Zs)/
176                                                      ? $_ : "!$_"} @$chars;
177     push @{$d {IsLower}} => map {$class =~ /^Ll$/    ? $_ : "!$_"} @$chars;
178     push @{$d {IsUpper}} => map {$class =~ /^L[ut]/  ? $_ : "!$_"} @$chars;
179     push @{$d {IsPunct}} => map {$class =~ /^P/      ? $_ : "!$_"} @$chars;
180     push @{$d {IsWord}}  => map {$class =~ /^[LMN]/ || $_ eq "_"
181                                                      ? $_ : "!$_"} @$chars;
182     push @{$d {IsSpace}} => map {$class =~ /^Z/ ||
183                                  length ($_) == 1 && utf8::native_to_unicode(ord ($_)) >= 0x09
184                                                   && utf8::native_to_unicode(ord ($_)) <= 0x0D
185                                                      ? $_ : "!$_"} @$chars;
186 }
187
188 push @CLASSES => "# Short properties"        => %SHORT_PROPERTIES,
189                  "# POSIX like properties"   => %d,
190                  "# User defined properties" => @USER_DEFINED_PROPERTIES;
191
192
193 #
194 # Calculate the number of tests.
195 #
196 my $count = 0;
197 for (my $i = 0; $i < @CLASSES; $i += 2) {
198     $i ++, redo if $CLASSES [$i] =~ /^\h*#\h*(.*)/;
199     $count += 2 * (length $CLASSES [$i] == 1 ? 4 : 2) * @{$CLASSES [$i + 1]};
200 }
201 $count += 4 * @ILLEGAL_PROPERTIES;
202 $count += 4 * grep {length $_ == 1} @ILLEGAL_PROPERTIES;
203 $count += 8 * @USER_CASELESS_PROPERTIES;
204 $count += 1;    # Test for pkg:IsMyLower
205 $count += 1;    # No warnings generated
206
207 plan(tests => $count);
208
209 run_tests unless caller ();
210
211 sub match {
212     my ($char, $match, $nomatch, $caseless) = @_;
213     $caseless = "" unless defined $caseless;
214     $caseless = 'i' if $caseless;
215
216     my ($str, $name) = get_str_name($char);
217
218     undef $@;
219     my $pat = "qr/$match/$caseless";
220     my $match_pat = eval $pat;
221     if (is($@, '', "$pat compiled correctly to a regexp: $@")) {
222         like($str, $match_pat, "$name correctly matched");
223     }
224
225     undef $@;
226     $pat = "qr/$nomatch/$caseless";
227     my $nomatch_pat = eval $pat;
228     if (is($@, '', "$pat compiled correctly to a regexp: $@")) {
229         unlike($str, $nomatch_pat, "$name correctly did not match");
230     }
231 }
232
233 sub run_tests {
234
235     while (@CLASSES) {
236         my $class = shift @CLASSES;
237         if ($class =~ /^\h*#\h*(.*)/) {
238             print "# $1\n";
239             next;
240         }
241         last unless @CLASSES;
242         my $chars   = shift @CLASSES;
243         my @in      =                       grep {!/^!./} @$chars;
244         my @out     = map {s/^!(?=.)//; $_} grep { /^!./} @$chars;
245         my $in_pat  = eval qq ['\\p{$class}'];
246         my $out_pat = eval qq ['\\P{$class}'];
247
248         match $_, $in_pat,  $out_pat for @in;
249         match $_, $out_pat, $in_pat  for @out;
250
251         if (1 == length $class) {   # Repeat without braces if name length 1
252             my $in_pat  = eval qq ['\\p$class'];
253             my $out_pat = eval qq ['\\P$class'];
254
255             match $_, $in_pat,  $out_pat for @in;
256             match $_, $out_pat, $in_pat  for @out;
257         }
258     }
259
260
261     print "# Illegal properties\n";
262     foreach my $p (@ILLEGAL_PROPERTIES) {
263         my $pat;
264         if ($p =~ /::/) {
265             $pat = qr /^Illegal user-defined property name/;
266         }
267         else {
268             $pat = qr /^Can't find Unicode property definition/;
269         }
270
271         undef $@;
272         my $r = eval "'a' =~ /\\p{$p}/; 1";
273         is($r, undef, "Unknown Unicode property \\p{$p}");
274         like($@, $pat, "Unknown Unicode property \\p{$p}");
275         undef $@;
276         my $s = eval "'a' =~ /\\P{$p}/; 1";
277         is($s, undef, "Unknown Unicode property \\p{$p}");
278         like($@, $pat, "Unknown Unicode property \\p{$p}");
279         if (length $p == 1) {
280             undef $@;
281             my $r = eval "'a' =~ /\\p$p/; 1";
282             is($r, undef, "Unknown Unicode property \\p$p");
283             like($@, $pat, "Unknown Unicode property \\p$p");
284             undef $@;
285             my $s = eval "'a' =~ /\\P$p/; 1";
286             is($r, undef, "Unknown Unicode property \\P$p");
287             like($@, $pat, "Unknown Unicode property \\P$p");
288         }
289     }
290
291     print "# User-defined properties with /i differences\n";
292     while (my $class = shift @USER_CASELESS_PROPERTIES) {
293         my $chars_ref = shift @USER_CASELESS_PROPERTIES;
294         my @in      =                       grep {!/^!./} @$chars_ref;
295         my @out     = map {s/^!(?=.)//; $_} grep { /^!./} @$chars_ref;
296         my $in_pat  = eval qq ['\\p{$class}'];
297         my $out_pat = eval qq ['\\P{$class}'];
298
299         # Verify works as regularly for not /i
300         match $_, $in_pat,  $out_pat for @in;
301         match $_, $out_pat, $in_pat  for @out;
302
303         # Verify that adding /i doesn't change the in set.
304         match $_, $in_pat,  $out_pat, 'i' for @in;
305
306         # Verify that adding /i does change the out set to match.
307         match $_, $in_pat,  $out_pat, 'i' for @out;
308     }
309 }
310
311
312 #
313 # User defined properties
314 #
315
316 sub InKana1 {<<'--'}
317 3040    309F
318 30A0    30FF
319 --
320
321 sub InKana2 {<<'--'}
322 +utf8::InHiragana
323 +utf8::InKatakana
324 --
325
326 sub InKana3 {<<'--'}
327 +utf8::InHiragana
328 +utf8::InKatakana
329 -utf8::IsCn
330 --
331
332 sub InNotKana {<<'--'}
333 !utf8::InHiragana
334 -utf8::InKatakana
335 +utf8::IsCn
336 --
337
338 sub InConsonant {
339
340     my $return = "+utf8::Lowercase\n&utf8::ASCII\n";
341     $return .= sprintf("-%X\n", ord "a");
342     $return .= sprintf("-%X\n", ord "e");
343     $return .= sprintf("-%X\n", ord "i");
344     $return .= sprintf("-%X\n", ord "o");
345     $return .= sprintf("-%X\n", ord "u");
346     return $return;
347 }
348
349 sub IsSyriac1 {<<'--'}
350 0712    072C
351 0730    074A
352 --
353
354 sub InGreekSmall   {return "03B1\t03C9"}
355 sub InGreekCapital {return "0391\t03A9\n-03A2"}
356
357 sub IsAsciiHexAndDash {<<'--'}
358 +utf8::ASCII_Hex_Digit
359 +utf8::Dash
360 --
361
362 sub InLatin1 {
363     return "0100\t10FFFF";
364 }
365
366 sub IsMyUpper {
367     my $caseless = shift;
368     return "+utf8::"
369            . (($caseless)
370                ? 'Alphabetic'
371                : 'Uppercase')
372            . "\n&utf8::ASCII";
373 }
374
375 {   # This has to be done here and not like the others, because we have to
376     # make sure that the property is not known until after the regex is
377     # compiled.  It was previously getting confused about the pkg and /i
378     # combination
379
380     my $mylower = qr/\p{pkg::IsMyLower}/i;
381
382 sub pkg::IsMyLower {
383     my $caseless = shift;
384     return "+utf8::"
385         . (($caseless)
386             ? 'Alphabetic'
387             : 'Lowercase')
388         . "\n&utf8::ASCII";
389 }
390
391     like("A", $mylower, "Not available until runtime user-defined property with pkg:: and /i works");
392
393 }
394
395 # Verify that can use user-defined properties inside another one
396 sub IsSyriac1KanaMark {<<'--'}
397 +main::IsSyriac1
398 +main::InKana3
399 &utf8::IsMark
400 --
401
402 # fake user-defined properties; these subs shouldn't be called, because
403 # their names don't start with In or Is
404
405 sub f       { die }
406 sub foo     { die }
407 sub isfoo   { die }
408 sub infoo   { die }
409 sub ISfoo   { die }
410 sub INfoo   { die }
411 sub Is::foo { die }
412 sub In::foo { die }
413
414 if (! is(@warnings, 0, "No warnings were generated")) {
415     diag join "\n", @warnings, "\n";
416 }
417
418 1;
419 __END__