This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
16562df50bc39ed42da75bf866cb363184238a99
[perl5.git] / lib / unicore / mktables
1 #!/usr/bin/perl -w
2
3 # !!!!!!!!!!!!!!       IF YOU MODIFY THIS FILE       !!!!!!!!!!!!!!!!!!!!!!!!!
4 # Any files created or read by this program should be listed in 'mktables.lst'
5 # Use -makelist to regenerate it.
6
7 # Needs 'no overloading' to run faster on miniperl.  Code commented out at the
8 # subroutine objaddr can be used instead to work as far back (untested) as
9 # 5.8: needs pack "U".  But almost all occurrences of objaddr have been
10 # removed in favor of using 'no overloading'.  You also would have to go
11 # through and replace occurrences like:
12 #       my $addr = do { no overloading; pack 'J', $self; }
13 # with
14 #       my $addr = main::objaddr $self;
15 # (or reverse commit 9b01bafde4b022706c3d6f947a0963f821b2e50b
16 # that instituted the change to main::objaddr, and subsequent commits that
17 # changed 0+$self to pack 'J', $self.)
18
19 my $start_time;
20 BEGIN { # Get the time the script started running; do it at compilation to
21         # get it as close as possible
22     $start_time= time;
23 }
24
25 require 5.010_001;
26 use strict;
27 use warnings;
28 use Carp;
29 use Config;
30 use File::Find;
31 use File::Path;
32 use File::Spec;
33 use Text::Tabs;
34 use re "/aa";
35
36 sub DEBUG () { 0 }  # Set to 0 for production; 1 for development
37 my $debugging_build = $Config{"ccflags"} =~ /-DDEBUGGING/;
38
39 sub NON_ASCII_PLATFORM { ord("A") != 65 }
40
41 ##########################################################################
42 #
43 # mktables -- create the runtime Perl Unicode files (lib/unicore/.../*.pl),
44 # from the Unicode database files (lib/unicore/.../*.txt),  It also generates
45 # a pod file and .t files, depending on option parameters.
46 #
47 # The structure of this file is:
48 #   First these introductory comments; then
49 #   code needed for everywhere, such as debugging stuff; then
50 #   code to handle input parameters; then
51 #   data structures likely to be of external interest (some of which depend on
52 #       the input parameters, so follows them; then
53 #   more data structures and subroutine and package (class) definitions; then
54 #   the small actual loop to process the input files and finish up; then
55 #   a __DATA__ section, for the .t tests
56 #
57 # This program works on all releases of Unicode so far.  The outputs have been
58 # scrutinized most intently for release 5.1.  The others have been checked for
59 # somewhat more than just sanity.  It can handle all non-provisional Unicode
60 # character properties in those releases.
61 #
62 # This program is mostly about Unicode character (or code point) properties.
63 # A property describes some attribute or quality of a code point, like if it
64 # is lowercase or not, its name, what version of Unicode it was first defined
65 # in, or what its uppercase equivalent is.  Unicode deals with these disparate
66 # possibilities by making all properties into mappings from each code point
67 # into some corresponding value.  In the case of it being lowercase or not,
68 # the mapping is either to 'Y' or 'N' (or various synonyms thereof).  Each
69 # property maps each Unicode code point to a single value, called a "property
70 # value".  (Some more recently defined properties, map a code point to a set
71 # of values.)
72 #
73 # When using a property in a regular expression, what is desired isn't the
74 # mapping of the code point to its property's value, but the reverse (or the
75 # mathematical "inverse relation"): starting with the property value, "Does a
76 # code point map to it?"  These are written in a "compound" form:
77 # \p{property=value}, e.g., \p{category=punctuation}.  This program generates
78 # files containing the lists of code points that map to each such regular
79 # expression property value, one file per list
80 #
81 # There is also a single form shortcut that Perl adds for many of the commonly
82 # used properties.  This happens for all binary properties, plus script,
83 # general_category, and block properties.
84 #
85 # Thus the outputs of this program are files.  There are map files, mostly in
86 # the 'To' directory; and there are list files for use in regular expression
87 # matching, all in subdirectories of the 'lib' directory, with each
88 # subdirectory being named for the property that the lists in it are for.
89 # Bookkeeping, test, and documentation files are also generated.
90
91 my $matches_directory = 'lib';   # Where match (\p{}) files go.
92 my $map_directory = 'To';        # Where map files go.
93
94 # DATA STRUCTURES
95 #
96 # The major data structures of this program are Property, of course, but also
97 # Table.  There are two kinds of tables, very similar to each other.
98 # "Match_Table" is the data structure giving the list of code points that have
99 # a particular property value, mentioned above.  There is also a "Map_Table"
100 # data structure which gives the property's mapping from code point to value.
101 # There are two structures because the match tables need to be combined in
102 # various ways, such as constructing unions, intersections, complements, etc.,
103 # and the map ones don't.  And there would be problems, perhaps subtle, if
104 # a map table were inadvertently operated on in some of those ways.
105 # The use of separate classes with operations defined on one but not the other
106 # prevents accidentally confusing the two.
107 #
108 # At the heart of each table's data structure is a "Range_List", which is just
109 # an ordered list of "Ranges", plus ancillary information, and methods to
110 # operate on them.  A Range is a compact way to store property information.
111 # Each range has a starting code point, an ending code point, and a value that
112 # is meant to apply to all the code points between the two end points,
113 # inclusive.  For a map table, this value is the property value for those
114 # code points.  Two such ranges could be written like this:
115 #   0x41 .. 0x5A, 'Upper',
116 #   0x61 .. 0x7A, 'Lower'
117 #
118 # Each range also has a type used as a convenience to classify the values.
119 # Most ranges in this program will be Type 0, or normal, but there are some
120 # ranges that have a non-zero type.  These are used only in map tables, and
121 # are for mappings that don't fit into the normal scheme of things.  Mappings
122 # that require a hash entry to communicate with utf8.c are one example;
123 # another example is mappings for charnames.pm to use which indicate a name
124 # that is algorithmically determinable from its code point (and the reverse).
125 # These are used to significantly compact these tables, instead of listing
126 # each one of the tens of thousands individually.
127 #
128 # In a match table, the value of a range is irrelevant (and hence the type as
129 # well, which will always be 0), and arbitrarily set to the null string.
130 # Using the example above, there would be two match tables for those two
131 # entries, one named Upper would contain the 0x41..0x5A range, and the other
132 # named Lower would contain 0x61..0x7A.
133 #
134 # Actually, there are two types of range lists, "Range_Map" is the one
135 # associated with map tables, and "Range_List" with match tables.
136 # Again, this is so that methods can be defined on one and not the others so
137 # as to prevent operating on them in incorrect ways.
138 #
139 # Eventually, most tables are written out to files to be read by utf8_heavy.pl
140 # in the perl core.  All tables could in theory be written, but some are
141 # suppressed because there is no current practical use for them.  It is easy
142 # to change which get written by changing various lists that are near the top
143 # of the actual code in this file.  The table data structures contain enough
144 # ancillary information to allow them to be treated as separate entities for
145 # writing, such as the path to each one's file.  There is a heading in each
146 # map table that gives the format of its entries, and what the map is for all
147 # the code points missing from it.  (This allows tables to be more compact.)
148 #
149 # The Property data structure contains one or more tables.  All properties
150 # contain a map table (except the $perl property which is a
151 # pseudo-property containing only match tables), and any properties that
152 # are usable in regular expression matches also contain various matching
153 # tables, one for each value the property can have.  A binary property can
154 # have two values, True and False (or Y and N, which are preferred by Unicode
155 # terminology).  Thus each of these properties will have a map table that
156 # takes every code point and maps it to Y or N (but having ranges cuts the
157 # number of entries in that table way down), and two match tables, one
158 # which has a list of all the code points that map to Y, and one for all the
159 # code points that map to N.  (For each binary property, a third table is also
160 # generated for the pseudo Perl property.  It contains the identical code
161 # points as the Y table, but can be written in regular expressions, not in the
162 # compound form, but in a "single" form like \p{IsUppercase}.)  Many
163 # properties are binary, but some properties have several possible values,
164 # some have many, and properties like Name have a different value for every
165 # named code point.  Those will not, unless the controlling lists are changed,
166 # have their match tables written out.  But all the ones which can be used in
167 # regular expression \p{} and \P{} constructs will.  Prior to 5.14, generally
168 # a property would have either its map table or its match tables written but
169 # not both.  Again, what gets written is controlled by lists which can easily
170 # be changed.  Starting in 5.14, advantage was taken of this, and all the map
171 # tables needed to reconstruct the Unicode db are now written out, while
172 # suppressing the Unicode .txt files that contain the data.  Our tables are
173 # much more compact than the .txt files, so a significant space savings was
174 # achieved.  Also, tables are not written out that are trivially derivable
175 # from tables that do get written.  So, there typically is no file containing
176 # the code points not matched by a binary property (the table for \P{} versus
177 # lowercase \p{}), since you just need to invert the True table to get the
178 # False table.
179
180 # Properties have a 'Type', like 'binary', or 'string', or 'enum' depending on
181 # how many match tables there are and the content of the maps.  This 'Type' is
182 # different than a range 'Type', so don't get confused by the two concepts
183 # having the same name.
184 #
185 # For information about the Unicode properties, see Unicode's UAX44 document:
186
187 my $unicode_reference_url = 'http://www.unicode.org/reports/tr44/';
188
189 # As stated earlier, this program will work on any release of Unicode so far.
190 # Most obvious problems in earlier data have NOT been corrected except when
191 # necessary to make Perl or this program work reasonably, and to keep out
192 # potential security issues.  For example, no folding information was given in
193 # early releases, so this program substitutes lower case instead, just so that
194 # a regular expression with the /i option will do something that actually
195 # gives the right results in many cases.  There are also a couple other
196 # corrections for version 1.1.5, commented at the point they are made.  As an
197 # example of corrections that weren't made (but could be) is this statement
198 # from DerivedAge.txt: "The supplementary private use code points and the
199 # non-character code points were assigned in version 2.0, but not specifically
200 # listed in the UCD until versions 3.0 and 3.1 respectively."  (To be precise
201 # it was 3.0.1 not 3.0.0)  More information on Unicode version glitches is
202 # further down in these introductory comments.
203 #
204 # This program works on all non-provisional properties as of the current
205 # Unicode release, though the files for some are suppressed for various
206 # reasons.  You can change which are output by changing lists in this program.
207 #
208 # The old version of mktables emphasized the term "Fuzzy" to mean Unicode's
209 # loose matchings rules (from Unicode TR18):
210 #
211 #    The recommended names for UCD properties and property values are in
212 #    PropertyAliases.txt [Prop] and PropertyValueAliases.txt
213 #    [PropValue]. There are both abbreviated names and longer, more
214 #    descriptive names. It is strongly recommended that both names be
215 #    recognized, and that loose matching of property names be used,
216 #    whereby the case distinctions, whitespace, hyphens, and underbar
217 #    are ignored.
218 #
219 # The program still allows Fuzzy to override its determination of if loose
220 # matching should be used, but it isn't currently used, as it is no longer
221 # needed; the calculations it makes are good enough.
222 #
223 # SUMMARY OF HOW IT WORKS:
224 #
225 #   Process arguments
226 #
227 #   A list is constructed containing each input file that is to be processed
228 #
229 #   Each file on the list is processed in a loop, using the associated handler
230 #   code for each:
231 #        The PropertyAliases.txt and PropValueAliases.txt files are processed
232 #            first.  These files name the properties and property values.
233 #            Objects are created of all the property and property value names
234 #            that the rest of the input should expect, including all synonyms.
235 #        The other input files give mappings from properties to property
236 #           values.  That is, they list code points and say what the mapping
237 #           is under the given property.  Some files give the mappings for
238 #           just one property; and some for many.  This program goes through
239 #           each file and populates the properties and their map tables from
240 #           them.  Some properties are listed in more than one file, and
241 #           Unicode has set up a precedence as to which has priority if there
242 #           is a conflict.  Thus the order of processing matters, and this
243 #           program handles the conflict possibility by processing the
244 #           overriding input files last, so that if necessary they replace
245 #           earlier values.
246 #        After this is all done, the program creates the property mappings not
247 #            furnished by Unicode, but derivable from what it does give.
248 #        The tables of code points that match each property value in each
249 #            property that is accessible by regular expressions are created.
250 #        The Perl-defined properties are created and populated.  Many of these
251 #            require data determined from the earlier steps
252 #        Any Perl-defined synonyms are created, and name clashes between Perl
253 #            and Unicode are reconciled and warned about.
254 #        All the properties are written to files
255 #        Any other files are written, and final warnings issued.
256 #
257 # For clarity, a number of operators have been overloaded to work on tables:
258 #   ~ means invert (take all characters not in the set).  The more
259 #       conventional '!' is not used because of the possibility of confusing
260 #       it with the actual boolean operation.
261 #   + means union
262 #   - means subtraction
263 #   & means intersection
264 # The precedence of these is the order listed.  Parentheses should be
265 # copiously used.  These are not a general scheme.  The operations aren't
266 # defined for a number of things, deliberately, to avoid getting into trouble.
267 # Operations are done on references and affect the underlying structures, so
268 # that the copy constructors for them have been overloaded to not return a new
269 # clone, but the input object itself.
270 #
271 # The bool operator is deliberately not overloaded to avoid confusion with
272 # "should it mean if the object merely exists, or also is non-empty?".
273 #
274 # WHY CERTAIN DESIGN DECISIONS WERE MADE
275 #
276 # This program needs to be able to run under miniperl.  Therefore, it uses a
277 # minimum of other modules, and hence implements some things itself that could
278 # be gotten from CPAN
279 #
280 # This program uses inputs published by the Unicode Consortium.  These can
281 # change incompatibly between releases without the Perl maintainers realizing
282 # it.  Therefore this program is now designed to try to flag these.  It looks
283 # at the directories where the inputs are, and flags any unrecognized files.
284 # It keeps track of all the properties in the files it handles, and flags any
285 # that it doesn't know how to handle.  It also flags any input lines that
286 # don't match the expected syntax, among other checks.
287 #
288 # It is also designed so if a new input file matches one of the known
289 # templates, one hopefully just needs to add it to a list to have it
290 # processed.
291 #
292 # As mentioned earlier, some properties are given in more than one file.  In
293 # particular, the files in the extracted directory are supposedly just
294 # reformattings of the others.  But they contain information not easily
295 # derivable from the other files, including results for Unihan, which this
296 # program doesn't ordinarily look at, and for unassigned code points.  They
297 # also have historically had errors or been incomplete.  In an attempt to
298 # create the best possible data, this program thus processes them first to
299 # glean information missing from the other files; then processes those other
300 # files to override any errors in the extracted ones.  Much of the design was
301 # driven by this need to store things and then possibly override them.
302 #
303 # It tries to keep fatal errors to a minimum, to generate something usable for
304 # testing purposes.  It always looks for files that could be inputs, and will
305 # warn about any that it doesn't know how to handle (the -q option suppresses
306 # the warning).
307 #
308 # Why is there more than one type of range?
309 #   This simplified things.  There are some very specialized code points that
310 #   have to be handled specially for output, such as Hangul syllable names.
311 #   By creating a range type (done late in the development process), it
312 #   allowed this to be stored with the range, and overridden by other input.
313 #   Originally these were stored in another data structure, and it became a
314 #   mess trying to decide if a second file that was for the same property was
315 #   overriding the earlier one or not.
316 #
317 # Why are there two kinds of tables, match and map?
318 #   (And there is a base class shared by the two as well.)  As stated above,
319 #   they actually are for different things.  Development proceeded much more
320 #   smoothly when I (khw) realized the distinction.  Map tables are used to
321 #   give the property value for every code point (actually every code point
322 #   that doesn't map to a default value).  Match tables are used for regular
323 #   expression matches, and are essentially the inverse mapping.  Separating
324 #   the two allows more specialized methods, and error checks so that one
325 #   can't just take the intersection of two map tables, for example, as that
326 #   is nonsensical.
327 #
328 # What about 'fate' and 'status'.  The concept of a table's fate was created
329 #   late when it became clear that something more was needed.  The difference
330 #   between this and 'status' is unclean, and could be improved if someone
331 #   wanted to spend the effort.
332 #
333 # DEBUGGING
334 #
335 # This program is written so it will run under miniperl.  Occasionally changes
336 # will cause an error where the backtrace doesn't work well under miniperl.
337 # To diagnose the problem, you can instead run it under regular perl, if you
338 # have one compiled.
339 #
340 # There is a good trace facility.  To enable it, first sub DEBUG must be set
341 # to return true.  Then a line like
342 #
343 # local $to_trace = 1 if main::DEBUG;
344 #
345 # can be added to enable tracing in its lexical scope (plus dynamic) or until
346 # you insert another line:
347 #
348 # local $to_trace = 0 if main::DEBUG;
349 #
350 # To actually trace, use a line like "trace $a, @b, %c, ...;
351 #
352 # Some of the more complex subroutines already have trace statements in them.
353 # Permanent trace statements should be like:
354 #
355 # trace ... if main::DEBUG && $to_trace;
356 #
357 # If there is just one or a few files that you're debugging, you can easily
358 # cause most everything else to be skipped.  Change the line
359 #
360 # my $debug_skip = 0;
361 #
362 # to 1, and every file whose object is in @input_file_objects and doesn't have
363 # a, 'non_skip => 1,' in its constructor will be skipped.  However, skipping
364 # Jamo.txt or UnicodeData.txt will likely cause fatal errors.
365 #
366 # To compare the output tables, it may be useful to specify the -annotate
367 # flag.  (As of this writing, this can't be done on a clean workspace, due to
368 # requirements in Text::Tabs used in this option; so first run mktables
369 # without this option.)  This option adds comment lines to each table, one for
370 # each non-algorithmically named character giving, currently its code point,
371 # name, and graphic representation if printable (and you have a font that
372 # knows about it).  This makes it easier to see what the particular code
373 # points are in each output table.  Non-named code points are annotated with a
374 # description of their status, and contiguous ones with the same description
375 # will be output as a range rather than individually.  Algorithmically named
376 # characters are also output as ranges, except when there are just a few
377 # contiguous ones.
378 #
379 # FUTURE ISSUES
380 #
381 # The program would break if Unicode were to change its names so that
382 # interior white space, underscores, or dashes differences were significant
383 # within property and property value names.
384 #
385 # It might be easier to use the xml versions of the UCD if this program ever
386 # would need heavy revision, and the ability to handle old versions was not
387 # required.
388 #
389 # There is the potential for name collisions, in that Perl has chosen names
390 # that Unicode could decide it also likes.  There have been such collisions in
391 # the past, with mostly Perl deciding to adopt the Unicode definition of the
392 # name.  However in the 5.2 Unicode beta testing, there were a number of such
393 # collisions, which were withdrawn before the final release, because of Perl's
394 # and other's protests.  These all involved new properties which began with
395 # 'Is'.  Based on the protests, Unicode is unlikely to try that again.  Also,
396 # many of the Perl-defined synonyms, like Any, Word, etc, are listed in a
397 # Unicode document, so they are unlikely to be used by Unicode for another
398 # purpose.  However, they might try something beginning with 'In', or use any
399 # of the other Perl-defined properties.  This program will warn you of name
400 # collisions, and refuse to generate tables with them, but manual intervention
401 # will be required in this event.  One scheme that could be implemented, if
402 # necessary, would be to have this program generate another file, or add a
403 # field to mktables.lst that gives the date of first definition of a property.
404 # Each new release of Unicode would use that file as a basis for the next
405 # iteration.  And the Perl synonym addition code could sort based on the age
406 # of the property, so older properties get priority, and newer ones that clash
407 # would be refused; hence existing code would not be impacted, and some other
408 # synonym would have to be used for the new property.  This is ugly, and
409 # manual intervention would certainly be easier to do in the short run; lets
410 # hope it never comes to this.
411 #
412 # A NOTE ON UNIHAN
413 #
414 # This program can generate tables from the Unihan database.  But it doesn't
415 # by default, letting the CPAN module Unicode::Unihan handle them.  Prior to
416 # version 5.2, this database was in a single file, Unihan.txt.  In 5.2 the
417 # database was split into 8 different files, all beginning with the letters
418 # 'Unihan'.  This program will read those file(s) if present, but it needs to
419 # know which of the many properties in the file(s) should have tables created
420 # for them.  It will create tables for any properties listed in
421 # PropertyAliases.txt and PropValueAliases.txt, plus any listed in the
422 # @cjk_properties array and the @cjk_property_values array.  Thus, if a
423 # property you want is not in those files of the release you are building
424 # against, you must add it to those two arrays.  Starting in 4.0, the
425 # Unicode_Radical_Stroke was listed in those files, so if the Unihan database
426 # is present in the directory, a table will be generated for that property.
427 # In 5.2, several more properties were added.  For your convenience, the two
428 # arrays are initialized with all the 6.0 listed properties that are also in
429 # earlier releases.  But these are commented out.  You can just uncomment the
430 # ones you want, or use them as a template for adding entries for other
431 # properties.
432 #
433 # You may need to adjust the entries to suit your purposes.  setup_unihan(),
434 # and filter_unihan_line() are the functions where this is done.  This program
435 # already does some adjusting to make the lines look more like the rest of the
436 # Unicode DB;  You can see what that is in filter_unihan_line()
437 #
438 # There is a bug in the 3.2 data file in which some values for the
439 # kPrimaryNumeric property have commas and an unexpected comment.  A filter
440 # could be added for these; or for a particular installation, the Unihan.txt
441 # file could be edited to fix them.
442 #
443 # HOW TO ADD A FILE TO BE PROCESSED
444 #
445 # A new file from Unicode needs to have an object constructed for it in
446 # @input_file_objects, probably at the end or at the end of the extracted
447 # ones.  The program should warn you if its name will clash with others on
448 # restrictive file systems, like DOS.  If so, figure out a better name, and
449 # add lines to the README.perl file giving that.  If the file is a character
450 # property, it should be in the format that Unicode has implicitly
451 # standardized for such files for the more recently introduced ones.
452 # If so, the Input_file constructor for @input_file_objects can just be the
453 # file name and release it first appeared in.  If not, then it should be
454 # possible to construct an each_line_handler() to massage the line into the
455 # standardized form.
456 #
457 # For non-character properties, more code will be needed.  You can look at
458 # the existing entries for clues.
459 #
460 # UNICODE VERSIONS NOTES
461 #
462 # The Unicode UCD has had a number of errors in it over the versions.  And
463 # these remain, by policy, in the standard for that version.  Therefore it is
464 # risky to correct them, because code may be expecting the error.  So this
465 # program doesn't generally make changes, unless the error breaks the Perl
466 # core.  As an example, some versions of 2.1.x Jamo.txt have the wrong value
467 # for U+1105, which causes real problems for the algorithms for Jamo
468 # calculations, so it is changed here.
469 #
470 # But it isn't so clear cut as to what to do about concepts that are
471 # introduced in a later release; should they extend back to earlier releases
472 # where the concept just didn't exist?  It was easier to do this than to not,
473 # so that's what was done.  For example, the default value for code points not
474 # in the files for various properties was probably undefined until changed by
475 # some version.  No_Block for blocks is such an example.  This program will
476 # assign No_Block even in Unicode versions that didn't have it.  This has the
477 # benefit that code being written doesn't have to special case earlier
478 # versions; and the detriment that it doesn't match the Standard precisely for
479 # the affected versions.
480 #
481 # Here are some observations about some of the issues in early versions:
482 #
483 # Prior to version 3.0, there were 3 character decompositions.  These are not
484 # handled by Unicode::Normalize, nor will it compile when presented a version
485 # that has them.  However, you can trivially get it to compile by simply
486 # ignoring those decompositions, by changing the croak to a carp.  At the time
487 # of this writing, the line (in cpan/Unicode-Normalize/mkheader) reads
488 #
489 #   croak("Weird Canonical Decomposition of U+$h");
490 #
491 # Simply comment it out.  It will compile, but will not know about any three
492 # character decompositions.  If using the .pm version, there is a similar
493 # line.
494
495 # The number of code points in \p{alpha=True} halved in 2.1.9.  It turns out
496 # that the reason is that the CJK block starting at 4E00 was removed from
497 # PropList, and was not put back in until 3.1.0.  The Perl extension (the
498 # single property name \p{alpha}) has the correct values.  But the compound
499 # form is simply not generated until 3.1, as it can be argued that prior to
500 # this release, this was not an official property.  The comments for
501 # filter_old_style_proplist() give more details.
502 #
503 # Unicode introduced the synonym Space for White_Space in 4.1.  Perl has
504 # always had a \p{Space}.  In release 3.2 only, they are not synonymous.  The
505 # reason is that 3.2 introduced U+205F=medium math space, which was not
506 # classed as white space, but Perl figured out that it should have been. 4.0
507 # reclassified it correctly.
508 #
509 # Another change between 3.2 and 4.0 is the CCC property value ATBL.  In 3.2
510 # this was erroneously a synonym for 202 (it should be 200).  In 4.0, ATB
511 # became 202, and ATBL was left with no code points, as all the ones that
512 # mapped to 202 stayed mapped to 202.  Thus if your program used the numeric
513 # name for the class, it would not have been affected, but if it used the
514 # mnemonic, it would have been.
515 #
516 # \p{Script=Hrkt} (Katakana_Or_Hiragana) came in 4.0.1.  Before that code
517 # points which eventually came to have this script property value, instead
518 # mapped to "Unknown".  But in the next release all these code points were
519 # moved to \p{sc=common} instead.
520 #
521 # The default for missing code points for BidiClass is complicated.  Starting
522 # in 3.1.1, the derived file DBidiClass.txt handles this, but this program
523 # tries to do the best it can for earlier releases.  It is done in
524 # process_PropertyAliases()
525 #
526 # In version 2.1.2, the entry in UnicodeData.txt:
527 #   0275;LATIN SMALL LETTER BARRED O;Ll;0;L;;;;;N;;;;019F;
528 # should instead be
529 #   0275;LATIN SMALL LETTER BARRED O;Ll;0;L;;;;;N;;;019F;;019F
530 # Without this change, there are casing problems for this character.
531 #
532 # Search for $string_compare_versions to see how to compare changes to
533 # properties between Unicode versions
534 #
535 ##############################################################################
536
537 my $UNDEF = ':UNDEF:';  # String to print out for undefined values in tracing
538                         # and errors
539 my $MAX_LINE_WIDTH = 78;
540
541 # Debugging aid to skip most files so as to not be distracted by them when
542 # concentrating on the ones being debugged.  Add
543 # non_skip => 1,
544 # to the constructor for those files you want processed when you set this.
545 # Files with a first version number of 0 are special: they are always
546 # processed regardless of the state of this flag.  Generally, Jamo.txt and
547 # UnicodeData.txt must not be skipped if you want this program to not die
548 # before normal completion.
549 my $debug_skip = 0;
550
551
552 # Normally these are suppressed.
553 my $write_Unicode_deprecated_tables = 0;
554
555 # Set to 1 to enable tracing.
556 our $to_trace = 0;
557
558 { # Closure for trace: debugging aid
559     my $print_caller = 1;        # ? Include calling subroutine name
560     my $main_with_colon = 'main::';
561     my $main_colon_length = length($main_with_colon);
562
563     sub trace {
564         return unless $to_trace;        # Do nothing if global flag not set
565
566         my @input = @_;
567
568         local $DB::trace = 0;
569         $DB::trace = 0;          # Quiet 'used only once' message
570
571         my $line_number;
572
573         # Loop looking up the stack to get the first non-trace caller
574         my $caller_line;
575         my $caller_name;
576         my $i = 0;
577         do {
578             $line_number = $caller_line;
579             (my $pkg, my $file, $caller_line, my $caller) = caller $i++;
580             $caller = $main_with_colon unless defined $caller;
581
582             $caller_name = $caller;
583
584             # get rid of pkg
585             $caller_name =~ s/.*:://;
586             if (substr($caller_name, 0, $main_colon_length)
587                 eq $main_with_colon)
588             {
589                 $caller_name = substr($caller_name, $main_colon_length);
590             }
591
592         } until ($caller_name ne 'trace');
593
594         # If the stack was empty, we were called from the top level
595         $caller_name = 'main' if ($caller_name eq ""
596                                     || $caller_name eq 'trace');
597
598         my $output = "";
599         #print STDERR __LINE__, ": ", join ", ", @input, "\n";
600         foreach my $string (@input) {
601             if (ref $string eq 'ARRAY' || ref $string eq 'HASH') {
602                 $output .= simple_dumper($string);
603             }
604             else {
605                 $string = "$string" if ref $string;
606                 $string = $UNDEF unless defined $string;
607                 chomp $string;
608                 $string = '""' if $string eq "";
609                 $output .= " " if $output ne ""
610                                 && $string ne ""
611                                 && substr($output, -1, 1) ne " "
612                                 && substr($string, 0, 1) ne " ";
613                 $output .= $string;
614             }
615         }
616
617         print STDERR sprintf "%4d: ", $line_number if defined $line_number;
618         print STDERR "$caller_name: " if $print_caller;
619         print STDERR $output, "\n";
620         return;
621     }
622 }
623
624 # This is for a rarely used development feature that allows you to compare two
625 # versions of the Unicode standard without having to deal with changes caused
626 # by the code points introduced in the later version.  Change the 0 to a
627 # string containing a SINGLE dotted Unicode release number (e.g. "2.1").  Only
628 # code points introduced in that release and earlier will be used; later ones
629 # are thrown away.  You use the version number of the earliest one you want to
630 # compare; then run this program on directory structures containing each
631 # release, and compare the outputs.  These outputs will therefore include only
632 # the code points common to both releases, and you can see the changes caused
633 # just by the underlying release semantic changes.  For versions earlier than
634 # 3.2, you must copy a version of DAge.txt into the directory.
635 my $string_compare_versions = DEBUG && 0; #  e.g., "2.1";
636 my $compare_versions = DEBUG
637                        && $string_compare_versions
638                        && pack "C*", split /\./, $string_compare_versions;
639
640 sub uniques {
641     # Returns non-duplicated input values.  From "Perl Best Practices:
642     # Encapsulated Cleverness".  p. 455 in first edition.
643
644     my %seen;
645     # Arguably this breaks encapsulation, if the goal is to permit multiple
646     # distinct objects to stringify to the same value, and be interchangeable.
647     # However, for this program, no two objects stringify identically, and all
648     # lists passed to this function are either objects or strings. So this
649     # doesn't affect correctness, but it does give a couple of percent speedup.
650     no overloading;
651     return grep { ! $seen{$_}++ } @_;
652 }
653
654 $0 = File::Spec->canonpath($0);
655
656 my $make_test_script = 0;      # ? Should we output a test script
657 my $make_norm_test_script = 0; # ? Should we output a normalization test script
658 my $write_unchanged_files = 0; # ? Should we update the output files even if
659                                #    we don't think they have changed
660 my $use_directory = "";        # ? Should we chdir somewhere.
661 my $pod_directory;             # input directory to store the pod file.
662 my $pod_file = 'perluniprops';
663 my $t_path;                     # Path to the .t test file
664 my $file_list = 'mktables.lst'; # File to store input and output file names.
665                                # This is used to speed up the build, by not
666                                # executing the main body of the program if
667                                # nothing on the list has changed since the
668                                # previous build
669 my $make_list = 1;             # ? Should we write $file_list.  Set to always
670                                # make a list so that when the pumpking is
671                                # preparing a release, s/he won't have to do
672                                # special things
673 my $glob_list = 0;             # ? Should we try to include unknown .txt files
674                                # in the input.
675 my $output_range_counts = $debugging_build;   # ? Should we include the number
676                                               # of code points in ranges in
677                                               # the output
678 my $annotate = 0;              # ? Should character names be in the output
679
680 # Verbosity levels; 0 is quiet
681 my $NORMAL_VERBOSITY = 1;
682 my $PROGRESS = 2;
683 my $VERBOSE = 3;
684
685 my $verbosity = $NORMAL_VERBOSITY;
686
687 # Stored in mktables.lst so that if this program is called with different
688 # options, will regenerate even if the files otherwise look like they're
689 # up-to-date.
690 my $command_line_arguments = join " ", @ARGV;
691
692 # Process arguments
693 while (@ARGV) {
694     my $arg = shift @ARGV;
695     if ($arg eq '-v') {
696         $verbosity = $VERBOSE;
697     }
698     elsif ($arg eq '-p') {
699         $verbosity = $PROGRESS;
700         $| = 1;     # Flush buffers as we go.
701     }
702     elsif ($arg eq '-q') {
703         $verbosity = 0;
704     }
705     elsif ($arg eq '-w') {
706         $write_unchanged_files = 1; # update the files even if havent changed
707     }
708     elsif ($arg eq '-check') {
709         my $this = shift @ARGV;
710         my $ok = shift @ARGV;
711         if ($this ne $ok) {
712             print "Skipping as check params are not the same.\n";
713             exit(0);
714         }
715     }
716     elsif ($arg eq '-P' && defined ($pod_directory = shift)) {
717         -d $pod_directory or croak "Directory '$pod_directory' doesn't exist";
718     }
719     elsif ($arg eq '-maketest' || ($arg eq '-T' && defined ($t_path = shift)))
720     {
721         $make_test_script = 1;
722     }
723     elsif ($arg eq '-makenormtest')
724     {
725         $make_norm_test_script = 1;
726     }
727     elsif ($arg eq '-makelist') {
728         $make_list = 1;
729     }
730     elsif ($arg eq '-C' && defined ($use_directory = shift)) {
731         -d $use_directory or croak "Unknown directory '$use_directory'";
732     }
733     elsif ($arg eq '-L') {
734
735         # Existence not tested until have chdir'd
736         $file_list = shift;
737     }
738     elsif ($arg eq '-globlist') {
739         $glob_list = 1;
740     }
741     elsif ($arg eq '-c') {
742         $output_range_counts = ! $output_range_counts
743     }
744     elsif ($arg eq '-annotate') {
745         $annotate = 1;
746         $debugging_build = 1;
747         $output_range_counts = 1;
748     }
749     else {
750         my $with_c = 'with';
751         $with_c .= 'out' if $output_range_counts;   # Complements the state
752         croak <<END;
753 usage: $0 [-c|-p|-q|-v|-w] [-C dir] [-L filelist] [ -P pod_dir ]
754           [ -T test_file_path ] [-globlist] [-makelist] [-maketest]
755           [-check A B ]
756   -c          : Output comments $with_c number of code points in ranges
757   -q          : Quiet Mode: Only output serious warnings.
758   -p          : Set verbosity level to normal plus show progress.
759   -v          : Set Verbosity level high:  Show progress and non-serious
760                 warnings
761   -w          : Write files regardless
762   -C dir      : Change to this directory before proceeding. All relative paths
763                 except those specified by the -P and -T options will be done
764                 with respect to this directory.
765   -P dir      : Output $pod_file file to directory 'dir'.
766   -T path     : Create a test script as 'path'; overrides -maketest
767   -L filelist : Use alternate 'filelist' instead of standard one
768   -globlist   : Take as input all non-Test *.txt files in current and sub
769                 directories
770   -maketest   : Make test script 'TestProp.pl' in current (or -C directory),
771                 overrides -T
772   -makelist   : Rewrite the file list $file_list based on current setup
773   -annotate   : Output an annotation for each character in the table files;
774                 useful for debugging mktables, looking at diffs; but is slow
775                 and memory intensive
776   -check A B  : Executes $0 only if A and B are the same
777 END
778     }
779 }
780
781 # Stores the most-recently changed file.  If none have changed, can skip the
782 # build
783 my $most_recent = (stat $0)[9];   # Do this before the chdir!
784
785 # Change directories now, because need to read 'version' early.
786 if ($use_directory) {
787     if ($pod_directory && ! File::Spec->file_name_is_absolute($pod_directory)) {
788         $pod_directory = File::Spec->rel2abs($pod_directory);
789     }
790     if ($t_path && ! File::Spec->file_name_is_absolute($t_path)) {
791         $t_path = File::Spec->rel2abs($t_path);
792     }
793     chdir $use_directory or croak "Failed to chdir to '$use_directory':$!";
794     if ($pod_directory && File::Spec->file_name_is_absolute($pod_directory)) {
795         $pod_directory = File::Spec->abs2rel($pod_directory);
796     }
797     if ($t_path && File::Spec->file_name_is_absolute($t_path)) {
798         $t_path = File::Spec->abs2rel($t_path);
799     }
800 }
801
802 # Get Unicode version into regular and v-string.  This is done now because
803 # various tables below get populated based on it.  These tables are populated
804 # here to be near the top of the file, and so easily seeable by those needing
805 # to modify things.
806 open my $VERSION, "<", "version"
807                     or croak "$0: can't open required file 'version': $!\n";
808 my $string_version = <$VERSION>;
809 close $VERSION;
810 chomp $string_version;
811 my $v_version = pack "C*", split /\./, $string_version;        # v string
812
813 # The following are the complete names of properties with property values that
814 # are known to not match any code points in some versions of Unicode, but that
815 # may change in the future so they should be matchable, hence an empty file is
816 # generated for them.
817 my @tables_that_may_be_empty;
818 push @tables_that_may_be_empty, 'Joining_Type=Left_Joining'
819                                                     if $v_version lt v6.3.0;
820 push @tables_that_may_be_empty, 'Script=Common' if $v_version le v4.0.1;
821 push @tables_that_may_be_empty, 'Title' if $v_version lt v2.0.0;
822 push @tables_that_may_be_empty, 'Script=Katakana_Or_Hiragana'
823                                                     if $v_version ge v4.1.0;
824 push @tables_that_may_be_empty, 'Script_Extensions=Katakana_Or_Hiragana'
825                                                     if $v_version ge v6.0.0;
826 push @tables_that_may_be_empty, 'Grapheme_Cluster_Break=Prepend'
827                                                     if $v_version ge v6.1.0;
828 push @tables_that_may_be_empty, 'Canonical_Combining_Class=CCC133'
829                                                     if $v_version ge v6.2.0;
830
831 # The lists below are hashes, so the key is the item in the list, and the
832 # value is the reason why it is in the list.  This makes generation of
833 # documentation easier.
834
835 my %why_suppressed;  # No file generated for these.
836
837 # Files aren't generated for empty extraneous properties.  This is arguable.
838 # Extraneous properties generally come about because a property is no longer
839 # used in a newer version of Unicode.  If we generated a file without code
840 # points, programs that used to work on that property will still execute
841 # without errors.  It just won't ever match (or will always match, with \P{}).
842 # This means that the logic is now likely wrong.  I (khw) think its better to
843 # find this out by getting an error message.  Just move them to the table
844 # above to change this behavior
845 my %why_suppress_if_empty_warn_if_not = (
846
847    # It is the only property that has ever officially been removed from the
848    # Standard.  The database never contained any code points for it.
849    'Special_Case_Condition' => 'Obsolete',
850
851    # Apparently never official, but there were code points in some versions of
852    # old-style PropList.txt
853    'Non_Break' => 'Obsolete',
854 );
855
856 # These would normally go in the warn table just above, but they were changed
857 # a long time before this program was written, so warnings about them are
858 # moot.
859 if ($v_version gt v3.2.0) {
860     push @tables_that_may_be_empty,
861                                 'Canonical_Combining_Class=Attached_Below_Left'
862 }
863
864 # These are listed in the Property aliases file in 6.0, but Unihan is ignored
865 # unless explicitly added.
866 if ($v_version ge v5.2.0) {
867     my $unihan = 'Unihan; remove from list if using Unihan';
868     foreach my $table (qw (
869                            kAccountingNumeric
870                            kOtherNumeric
871                            kPrimaryNumeric
872                            kCompatibilityVariant
873                            kIICore
874                            kIRG_GSource
875                            kIRG_HSource
876                            kIRG_JSource
877                            kIRG_KPSource
878                            kIRG_MSource
879                            kIRG_KSource
880                            kIRG_TSource
881                            kIRG_USource
882                            kIRG_VSource
883                            kRSUnicode
884                         ))
885     {
886         $why_suppress_if_empty_warn_if_not{$table} = $unihan;
887     }
888 }
889
890 # Enum values for to_output_map() method in the Map_Table package.
891 my $EXTERNAL_MAP = 1;
892 my $INTERNAL_MAP = 2;
893 my $OUTPUT_ADJUSTED = 3;
894
895 # To override computed values for writing the map tables for these properties.
896 # The default for enum map tables is to write them out, so that the Unicode
897 # .txt files can be removed, but all the data to compute any property value
898 # for any code point is available in a more compact form.
899 my %global_to_output_map = (
900     # Needed by UCD.pm, but don't want to publicize that it exists, so won't
901     # get stuck supporting it if things change.  Since it is a STRING
902     # property, it normally would be listed in the pod, but INTERNAL_MAP
903     # suppresses that.
904     Unicode_1_Name => $INTERNAL_MAP,
905
906     Present_In => 0,                # Suppress, as easily computed from Age
907     Block => (NON_ASCII_PLATFORM) ? 1 : 0,  # Suppress, as Blocks.txt is
908                                             # retained, but needed for
909                                             # non-ASCII
910
911     # Suppress, as mapping can be found instead from the
912     # Perl_Decomposition_Mapping file
913     Decomposition_Type => 0,
914 );
915
916 # Properties that this program ignores.
917 my @unimplemented_properties;
918
919 # With this release, it is automatically handled if the Unihan db is
920 # downloaded
921 push @unimplemented_properties, 'Unicode_Radical_Stroke' if $v_version lt v5.2.0;
922
923 # There are several types of obsolete properties defined by Unicode.  These
924 # must be hand-edited for every new Unicode release.
925 my %why_deprecated;  # Generates a deprecated warning message if used.
926 my %why_stabilized;  # Documentation only
927 my %why_obsolete;    # Documentation only
928
929 {   # Closure
930     my $simple = 'Perl uses the more complete version';
931     my $unihan = 'Unihan properties are by default not enabled in the Perl core.  Instead use CPAN: Unicode::Unihan';
932
933     my $other_properties = 'other properties';
934     my $contributory = "Used by Unicode internally for generating $other_properties and not intended to be used stand-alone";
935     my $why_no_expand  = "Deprecated by Unicode.  These are characters that expand to more than one character in the specified normalization form, but whether they actually take up more bytes or not depends on the encoding being used.  For example, a UTF-8 encoded character may expand to a different number of bytes than a UTF-32 encoded character.";
936
937     %why_deprecated = (
938         'Grapheme_Link' => 'Deprecated by Unicode:  Duplicates ccc=vr (Canonical_Combining_Class=Virama)',
939         'Jamo_Short_Name' => $contributory,
940         'Line_Break=Surrogate' => 'Deprecated by Unicode because surrogates should never appear in well-formed text, and therefore shouldn\'t be the basis for line breaking',
941         'Other_Alphabetic' => $contributory,
942         'Other_Default_Ignorable_Code_Point' => $contributory,
943         'Other_Grapheme_Extend' => $contributory,
944         'Other_ID_Continue' => $contributory,
945         'Other_ID_Start' => $contributory,
946         'Other_Lowercase' => $contributory,
947         'Other_Math' => $contributory,
948         'Other_Uppercase' => $contributory,
949         'Expands_On_NFC' => $why_no_expand,
950         'Expands_On_NFD' => $why_no_expand,
951         'Expands_On_NFKC' => $why_no_expand,
952         'Expands_On_NFKD' => $why_no_expand,
953     );
954
955     %why_suppressed = (
956         # There is a lib/unicore/Decomposition.pl (used by Normalize.pm) which
957         # contains the same information, but without the algorithmically
958         # determinable Hangul syllables'.  This file is not published, so it's
959         # existence is not noted in the comment.
960         'Decomposition_Mapping' => 'Accessible via Unicode::Normalize or prop_invmap() or charprop() in Unicode::UCD::',
961
962         'Indic_Matra_Category' => "Withdrawn by Unicode while still provisional",
963
964         # Don't suppress ISO_Comment, as otherwise special handling is needed
965         # to differentiate between it and gc=c, which can be written as 'isc',
966         # which is the same characters as ISO_Comment's short name.
967
968         'Name' => "Accessible via \\N{...} or 'use charnames;' or charprop() or prop_invmap() in Unicode::UCD::",
969
970         'Simple_Case_Folding' => "$simple.  Can access this through casefold(), charprop(), or prop_invmap() in Unicode::UCD",
971         'Simple_Lowercase_Mapping' => "$simple.  Can access this through charinfo(), charprop(), or prop_invmap() in Unicode::UCD",
972         'Simple_Titlecase_Mapping' => "$simple.  Can access this through charinfo(), charprop(), or prop_invmap() in Unicode::UCD",
973         'Simple_Uppercase_Mapping' => "$simple.  Can access this through charinfo(), charprop(), or prop_invmap() in Unicode::UCD",
974
975         FC_NFKC_Closure => 'Deprecated by Unicode, and supplanted in usage by NFKC_Casefold; otherwise not useful',
976     );
977
978     foreach my $property (
979
980             # The following are suppressed because they were made contributory
981             # or deprecated by Unicode before Perl ever thought about
982             # supporting them.
983             'Jamo_Short_Name',
984             'Grapheme_Link',
985             'Expands_On_NFC',
986             'Expands_On_NFD',
987             'Expands_On_NFKC',
988             'Expands_On_NFKD',
989
990             # The following are suppressed because they have been marked
991             # as deprecated for a sufficient amount of time
992             'Other_Alphabetic',
993             'Other_Default_Ignorable_Code_Point',
994             'Other_Grapheme_Extend',
995             'Other_ID_Continue',
996             'Other_ID_Start',
997             'Other_Lowercase',
998             'Other_Math',
999             'Other_Uppercase',
1000     ) {
1001         $why_suppressed{$property} = $why_deprecated{$property};
1002     }
1003
1004     # Customize the message for all the 'Other_' properties
1005     foreach my $property (keys %why_deprecated) {
1006         next if (my $main_property = $property) !~ s/^Other_//;
1007         $why_deprecated{$property} =~ s/$other_properties/the $main_property property (which should be used instead)/;
1008     }
1009 }
1010
1011 if ($write_Unicode_deprecated_tables) {
1012     foreach my $property (keys %why_suppressed) {
1013         delete $why_suppressed{$property} if $property =~
1014                                                     / ^ Other | Grapheme /x;
1015     }
1016 }
1017
1018 if ($v_version ge 4.0.0) {
1019     $why_stabilized{'Hyphen'} = 'Use the Line_Break property instead; see www.unicode.org/reports/tr14';
1020     if ($v_version ge 6.0.0) {
1021         $why_deprecated{'Hyphen'} = 'Supplanted by Line_Break property values; see www.unicode.org/reports/tr14';
1022     }
1023 }
1024 if ($v_version ge 5.2.0 && $v_version lt 6.0.0) {
1025     $why_obsolete{'ISO_Comment'} = 'Code points for it have been removed';
1026     if ($v_version ge 6.0.0) {
1027         $why_deprecated{'ISO_Comment'} = 'No longer needed for Unicode\'s internal chart generation; otherwise not useful, and code points for it have been removed';
1028     }
1029 }
1030
1031 # Probably obsolete forever
1032 if ($v_version ge v4.1.0) {
1033     $why_suppressed{'Script=Katakana_Or_Hiragana'} = 'Obsolete.  All code points previously matched by this have been moved to "Script=Common".';
1034 }
1035 if ($v_version ge v6.0.0) {
1036     $why_suppressed{'Script=Katakana_Or_Hiragana'} .= '  Consider instead using "Script_Extensions=Katakana" or "Script_Extensions=Hiragana" (or both)';
1037     $why_suppressed{'Script_Extensions=Katakana_Or_Hiragana'} = 'All code points that would be matched by this are matched by either "Script_Extensions=Katakana" or "Script_Extensions=Hiragana"';
1038 }
1039
1040 # This program can create files for enumerated-like properties, such as
1041 # 'Numeric_Type'.  This file would be the same format as for a string
1042 # property, with a mapping from code point to its value, so you could look up,
1043 # for example, the script a code point is in.  But no one so far wants this
1044 # mapping, or they have found another way to get it since this is a new
1045 # feature.  So no file is generated except if it is in this list.
1046 my @output_mapped_properties = split "\n", <<END;
1047 END
1048
1049 # If you are using the Unihan database in a Unicode version before 5.2, you
1050 # need to add the properties that you want to extract from it to this table.
1051 # For your convenience, the properties in the 6.0 PropertyAliases.txt file are
1052 # listed, commented out
1053 my @cjk_properties = split "\n", <<'END';
1054 #cjkAccountingNumeric; kAccountingNumeric
1055 #cjkOtherNumeric; kOtherNumeric
1056 #cjkPrimaryNumeric; kPrimaryNumeric
1057 #cjkCompatibilityVariant; kCompatibilityVariant
1058 #cjkIICore ; kIICore
1059 #cjkIRG_GSource; kIRG_GSource
1060 #cjkIRG_HSource; kIRG_HSource
1061 #cjkIRG_JSource; kIRG_JSource
1062 #cjkIRG_KPSource; kIRG_KPSource
1063 #cjkIRG_KSource; kIRG_KSource
1064 #cjkIRG_TSource; kIRG_TSource
1065 #cjkIRG_USource; kIRG_USource
1066 #cjkIRG_VSource; kIRG_VSource
1067 #cjkRSUnicode; kRSUnicode                ; Unicode_Radical_Stroke; URS
1068 END
1069
1070 # Similarly for the property values.  For your convenience, the lines in the
1071 # 6.0 PropertyAliases.txt file are listed.  Just remove the first BUT NOT both
1072 # '#' marks (for Unicode versions before 5.2)
1073 my @cjk_property_values = split "\n", <<'END';
1074 ## @missing: 0000..10FFFF; cjkAccountingNumeric; NaN
1075 ## @missing: 0000..10FFFF; cjkCompatibilityVariant; <code point>
1076 ## @missing: 0000..10FFFF; cjkIICore; <none>
1077 ## @missing: 0000..10FFFF; cjkIRG_GSource; <none>
1078 ## @missing: 0000..10FFFF; cjkIRG_HSource; <none>
1079 ## @missing: 0000..10FFFF; cjkIRG_JSource; <none>
1080 ## @missing: 0000..10FFFF; cjkIRG_KPSource; <none>
1081 ## @missing: 0000..10FFFF; cjkIRG_KSource; <none>
1082 ## @missing: 0000..10FFFF; cjkIRG_TSource; <none>
1083 ## @missing: 0000..10FFFF; cjkIRG_USource; <none>
1084 ## @missing: 0000..10FFFF; cjkIRG_VSource; <none>
1085 ## @missing: 0000..10FFFF; cjkOtherNumeric; NaN
1086 ## @missing: 0000..10FFFF; cjkPrimaryNumeric; NaN
1087 ## @missing: 0000..10FFFF; cjkRSUnicode; <none>
1088 END
1089
1090 # The input files don't list every code point.  Those not listed are to be
1091 # defaulted to some value.  Below are hard-coded what those values are for
1092 # non-binary properties as of 5.1.  Starting in 5.0, there are
1093 # machine-parsable comment lines in the files that give the defaults; so this
1094 # list shouldn't have to be extended.  The claim is that all missing entries
1095 # for binary properties will default to 'N'.  Unicode tried to change that in
1096 # 5.2, but the beta period produced enough protest that they backed off.
1097 #
1098 # The defaults for the fields that appear in UnicodeData.txt in this hash must
1099 # be in the form that it expects.  The others may be synonyms.
1100 my $CODE_POINT = '<code point>';
1101 my %default_mapping = (
1102     Age => "Unassigned",
1103     # Bidi_Class => Complicated; set in code
1104     Bidi_Mirroring_Glyph => "",
1105     Block => 'No_Block',
1106     Canonical_Combining_Class => 0,
1107     Case_Folding => $CODE_POINT,
1108     Decomposition_Mapping => $CODE_POINT,
1109     Decomposition_Type => 'None',
1110     East_Asian_Width => "Neutral",
1111     FC_NFKC_Closure => $CODE_POINT,
1112     General_Category => 'Cn',
1113     Grapheme_Cluster_Break => 'Other',
1114     Hangul_Syllable_Type => 'NA',
1115     ISO_Comment => "",
1116     Jamo_Short_Name => "",
1117     Joining_Group => "No_Joining_Group",
1118     # Joining_Type => Complicated; set in code
1119     kIICore => 'N',   #                       Is converted to binary
1120     #Line_Break => Complicated; set in code
1121     Lowercase_Mapping => $CODE_POINT,
1122     Name => "",
1123     Name_Alias => "",
1124     NFC_QC => 'Yes',
1125     NFD_QC => 'Yes',
1126     NFKC_QC => 'Yes',
1127     NFKD_QC => 'Yes',
1128     Numeric_Type => 'None',
1129     Numeric_Value => 'NaN',
1130     Script => ($v_version le 4.1.0) ? 'Common' : 'Unknown',
1131     Sentence_Break => 'Other',
1132     Simple_Case_Folding => $CODE_POINT,
1133     Simple_Lowercase_Mapping => $CODE_POINT,
1134     Simple_Titlecase_Mapping => $CODE_POINT,
1135     Simple_Uppercase_Mapping => $CODE_POINT,
1136     Titlecase_Mapping => $CODE_POINT,
1137     Unicode_1_Name => "",
1138     Unicode_Radical_Stroke => "",
1139     Uppercase_Mapping => $CODE_POINT,
1140     Word_Break => 'Other',
1141 );
1142
1143 # Below are files that Unicode furnishes, but this program ignores, and why.
1144 # NormalizationCorrections.txt requires some more explanation.  It documents
1145 # the cumulative fixes to erroneous normalizations in earlier Unicode
1146 # versions.  Its main purpose is so that someone running on an earlier version
1147 # can use this file to override what got published in that earlier release.
1148 # It would be easy for mktables to read and handle this file.  But all the
1149 # corrections in it should already be in the other files for the release it
1150 # is.  To get it to actually mean something useful, someone would have to be
1151 # using an earlier Unicode release, and copy it to the files for that release
1152 # and recomplile.  So far there has been no demand to do that, so this hasn't
1153 # been implemented.
1154 my %ignored_files = (
1155     'CJKRadicals.txt' => 'Maps the kRSUnicode property values to corresponding code points',
1156     'Index.txt' => 'Alphabetical index of Unicode characters',
1157     'NamedSqProv.txt' => 'Named sequences proposed for inclusion in a later version of the Unicode Standard; if you need them now, you can append this file to F<NamedSequences.txt> and recompile perl',
1158     'NamesList.txt' => 'Annotated list of characters',
1159     'NamesList.html' => 'Describes the format and contents of F<NamesList.txt>',
1160     'NormalizationCorrections.txt' => 'Documentation of corrections already incorporated into the Unicode data base',
1161     'Props.txt' => 'Only in very early releases; is a subset of F<PropList.txt> (which is used instead)',
1162     'ReadMe.txt' => 'Documentation',
1163     'StandardizedVariants.txt' => 'Certain glyph variations for character display are standardized.  This lists the non-Unihan ones; the Unihan ones are also not used by Perl, and are in a separate Unicode data base L<http://www.unicode.org/ivd>',
1164     'StandardizedVariants.html' => 'Provides a visual display of the standard variant sequences derived from F<StandardizedVariants.txt>.',
1165     'EmojiSources.txt' => 'Maps certain Unicode code points to their legacy Japanese cell-phone values',
1166     'USourceData.txt' => 'Documentation of status and cross reference of proposals for encoding by Unicode of Unihan characters',
1167     'USourceGlyphs.pdf' => 'Pictures of the characters in F<USourceData.txt>',
1168     'auxiliary/WordBreakTest.html' => 'Documentation of validation tests',
1169     'auxiliary/SentenceBreakTest.html' => 'Documentation of validation tests',
1170     'auxiliary/GraphemeBreakTest.html' => 'Documentation of validation tests',
1171     'auxiliary/LineBreakTest.html' => 'Documentation of validation tests',
1172 );
1173
1174 my %skipped_files;  # List of files that we skip
1175
1176 ### End of externally interesting definitions, except for @input_file_objects
1177
1178 my $HEADER=<<"EOF";
1179 # !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
1180 # This file is machine-generated by $0 from the Unicode
1181 # database, Version $string_version.  Any changes made here will be lost!
1182 EOF
1183
1184 my $INTERNAL_ONLY_HEADER = <<"EOF";
1185
1186 # !!!!!!!   INTERNAL PERL USE ONLY   !!!!!!!
1187 # This file is for internal use by core Perl only.  The format and even the
1188 # name or existence of this file are subject to change without notice.  Don't
1189 # use it directly.  Use Unicode::UCD to access the Unicode character data
1190 # base.
1191 EOF
1192
1193 my $DEVELOPMENT_ONLY=<<"EOF";
1194 # !!!!!!!   DEVELOPMENT USE ONLY   !!!!!!!
1195 # This file contains information artificially constrained to code points
1196 # present in Unicode release $string_compare_versions.
1197 # IT CANNOT BE RELIED ON.  It is for use during development only and should
1198 # not be used for production.
1199
1200 EOF
1201
1202 my $MAX_UNICODE_CODEPOINT_STRING = ($v_version ge v2.0.0)
1203                                    ? "10FFFF"
1204                                    : "FFFF";
1205 my $MAX_UNICODE_CODEPOINT = hex $MAX_UNICODE_CODEPOINT_STRING;
1206 my $MAX_UNICODE_CODEPOINTS = $MAX_UNICODE_CODEPOINT + 1;
1207
1208 # We work with above-Unicode code points, up to UV_MAX.   But when you get
1209 # that high, above IV_MAX, some operations don't work, and you can easily get
1210 # overflow.  Therefore for internal use, we use a much smaller number,
1211 # translating it to UV_MAX only for output.  The exact number is immaterial
1212 # (all Unicode code points are treated exactly the same), but the algorithm
1213 # requires it to be at least 2 * $MAX_UNICODE_CODEPOINTS + 1;
1214 my $MAX_WORKING_CODEPOINTS= $MAX_UNICODE_CODEPOINT * 8;
1215 my $MAX_WORKING_CODEPOINT = $MAX_WORKING_CODEPOINTS - 1;
1216 my $MAX_WORKING_CODEPOINT_STRING = sprintf("%X", $MAX_WORKING_CODEPOINT);
1217
1218 my $MAX_PLATFORM_CODEPOINT = ~0;
1219
1220 # Matches legal code point.  4-6 hex numbers, If there are 6, the first
1221 # two must be 10; if there are 5, the first must not be a 0.  Written this way
1222 # to decrease backtracking.  The first regex allows the code point to be at
1223 # the end of a word, but to work properly, the word shouldn't end with a valid
1224 # hex character.  The second one won't match a code point at the end of a
1225 # word, and doesn't have the run-on issue
1226 my $run_on_code_point_re =
1227             qr/ (?: 10[0-9A-F]{4} | [1-9A-F][0-9A-F]{4} | [0-9A-F]{4} ) \b/x;
1228 my $code_point_re = qr/\b$run_on_code_point_re/;
1229
1230 # This matches the beginning of the line in the Unicode db files that give the
1231 # defaults for code points not listed (i.e., missing) in the file.  The code
1232 # depends on this ending with a semi-colon, so it can assume it is a valid
1233 # field when the line is split() by semi-colons
1234 my $missing_defaults_prefix = qr/^#\s+\@missing:\s+0000\.\.10FFFF\s*;/;
1235
1236 # Property types.  Unicode has more types, but these are sufficient for our
1237 # purposes.
1238 my $UNKNOWN = -1;   # initialized to illegal value
1239 my $NON_STRING = 1; # Either binary or enum
1240 my $BINARY = 2;
1241 my $FORCED_BINARY = 3; # Not a binary property, but, besides its normal
1242                        # tables, additional true and false tables are
1243                        # generated so that false is anything matching the
1244                        # default value, and true is everything else.
1245 my $ENUM = 4;       # Include catalog
1246 my $STRING = 5;     # Anything else: string or misc
1247
1248 # Some input files have lines that give default values for code points not
1249 # contained in the file.  Sometimes these should be ignored.
1250 my $NO_DEFAULTS = 0;        # Must evaluate to false
1251 my $NOT_IGNORED = 1;
1252 my $IGNORED = 2;
1253
1254 # Range types.  Each range has a type.  Most ranges are type 0, for normal,
1255 # and will appear in the main body of the tables in the output files, but
1256 # there are other types of ranges as well, listed below, that are specially
1257 # handled.   There are pseudo-types as well that will never be stored as a
1258 # type, but will affect the calculation of the type.
1259
1260 # 0 is for normal, non-specials
1261 my $MULTI_CP = 1;           # Sequence of more than code point
1262 my $HANGUL_SYLLABLE = 2;
1263 my $CP_IN_NAME = 3;         # The NAME contains the code point appended to it.
1264 my $NULL = 4;               # The map is to the null string; utf8.c can't
1265                             # handle these, nor is there an accepted syntax
1266                             # for them in \p{} constructs
1267 my $COMPUTE_NO_MULTI_CP = 5; # Pseudo-type; means that ranges that would
1268                              # otherwise be $MULTI_CP type are instead type 0
1269
1270 # process_generic_property_file() can accept certain overrides in its input.
1271 # Each of these must begin AND end with $CMD_DELIM.
1272 my $CMD_DELIM = "\a";
1273 my $REPLACE_CMD = 'replace';    # Override the Replace
1274 my $MAP_TYPE_CMD = 'map_type';  # Override the Type
1275
1276 my $NO = 0;
1277 my $YES = 1;
1278
1279 # Values for the Replace argument to add_range.
1280 # $NO                      # Don't replace; add only the code points not
1281                            # already present.
1282 my $IF_NOT_EQUIVALENT = 1; # Replace only under certain conditions; details in
1283                            # the comments at the subroutine definition.
1284 my $UNCONDITIONALLY = 2;   # Replace without conditions.
1285 my $MULTIPLE_BEFORE = 4;   # Don't replace, but add a duplicate record if
1286                            # already there
1287 my $MULTIPLE_AFTER = 5;    # Don't replace, but add a duplicate record if
1288                            # already there
1289 my $CROAK = 6;             # Die with an error if is already there
1290
1291 # Flags to give property statuses.  The phrases are to remind maintainers that
1292 # if the flag is changed, the indefinite article referring to it in the
1293 # documentation may need to be as well.
1294 my $NORMAL = "";
1295 my $DEPRECATED = 'D';
1296 my $a_bold_deprecated = "a 'B<$DEPRECATED>'";
1297 my $A_bold_deprecated = "A 'B<$DEPRECATED>'";
1298 my $DISCOURAGED = 'X';
1299 my $a_bold_discouraged = "an 'B<$DISCOURAGED>'";
1300 my $A_bold_discouraged = "An 'B<$DISCOURAGED>'";
1301 my $STRICTER = 'T';
1302 my $a_bold_stricter = "a 'B<$STRICTER>'";
1303 my $A_bold_stricter = "A 'B<$STRICTER>'";
1304 my $STABILIZED = 'S';
1305 my $a_bold_stabilized = "an 'B<$STABILIZED>'";
1306 my $A_bold_stabilized = "An 'B<$STABILIZED>'";
1307 my $OBSOLETE = 'O';
1308 my $a_bold_obsolete = "an 'B<$OBSOLETE>'";
1309 my $A_bold_obsolete = "An 'B<$OBSOLETE>'";
1310
1311 my %status_past_participles = (
1312     $DISCOURAGED => 'discouraged',
1313     $STABILIZED => 'stabilized',
1314     $OBSOLETE => 'obsolete',
1315     $DEPRECATED => 'deprecated',
1316 );
1317
1318 # Table fates.  These are somewhat ordered, so that fates < $MAP_PROXIED should be
1319 # externally documented.
1320 my $ORDINARY = 0;       # The normal fate.
1321 my $MAP_PROXIED = 1;    # The map table for the property isn't written out,
1322                         # but there is a file written that can be used to
1323                         # reconstruct this table
1324 my $INTERNAL_ONLY = 2;  # The file for this table is written out, but it is
1325                         # for Perl's internal use only
1326 my $LEGACY_ONLY = 3;    # Like $INTERNAL_ONLY, but not actually used by Perl.
1327                         # Is for backwards compatibility for applications that
1328                         # read the file directly, so it's format is
1329                         # unchangeable.
1330 my $SUPPRESSED = 4;     # The file for this table is not written out, and as a
1331                         # result, we don't bother to do many computations on
1332                         # it.
1333 my $PLACEHOLDER = 5;    # Like $SUPPRESSED, but we go through all the
1334                         # computations anyway, as the values are needed for
1335                         # things to work.  This happens when we have Perl
1336                         # extensions that depend on Unicode tables that
1337                         # wouldn't normally be in a given Unicode version.
1338
1339 # The format of the values of the tables:
1340 my $EMPTY_FORMAT = "";
1341 my $BINARY_FORMAT = 'b';
1342 my $DECIMAL_FORMAT = 'd';
1343 my $FLOAT_FORMAT = 'f';
1344 my $INTEGER_FORMAT = 'i';
1345 my $HEX_FORMAT = 'x';
1346 my $RATIONAL_FORMAT = 'r';
1347 my $STRING_FORMAT = 's';
1348 my $ADJUST_FORMAT = 'a';
1349 my $HEX_ADJUST_FORMAT = 'ax';
1350 my $DECOMP_STRING_FORMAT = 'c';
1351 my $STRING_WHITE_SPACE_LIST = 'sw';
1352
1353 my %map_table_formats = (
1354     $BINARY_FORMAT => 'binary',
1355     $DECIMAL_FORMAT => 'single decimal digit',
1356     $FLOAT_FORMAT => 'floating point number',
1357     $INTEGER_FORMAT => 'integer',
1358     $HEX_FORMAT => 'non-negative hex whole number; a code point',
1359     $RATIONAL_FORMAT => 'rational: an integer or a fraction',
1360     $STRING_FORMAT => 'string',
1361     $ADJUST_FORMAT => 'some entries need adjustment',
1362     $HEX_ADJUST_FORMAT => 'mapped value in hex; some entries need adjustment',
1363     $DECOMP_STRING_FORMAT => 'Perl\'s internal (Normalize.pm) decomposition mapping',
1364     $STRING_WHITE_SPACE_LIST => 'string, but some elements are interpreted as a list; white space occurs only as list item separators'
1365 );
1366
1367 # Unicode didn't put such derived files in a separate directory at first.
1368 my $EXTRACTED_DIR = (-d 'extracted') ? 'extracted' : "";
1369 my $EXTRACTED = ($EXTRACTED_DIR) ? "$EXTRACTED_DIR/" : "";
1370 my $AUXILIARY = 'auxiliary';
1371
1372 # Hashes and arrays that will eventually go into Heavy.pl for the use of
1373 # utf8_heavy.pl and into UCD.pl for the use of UCD.pm
1374 my %loose_to_file_of;       # loosely maps table names to their respective
1375                             # files
1376 my %stricter_to_file_of;    # same; but for stricter mapping.
1377 my %loose_property_to_file_of; # Maps a loose property name to its map file
1378 my %strict_property_to_file_of; # Same, but strict
1379 my @inline_definitions = "V0"; # Each element gives a definition of a unique
1380                             # inversion list.  When a definition is inlined,
1381                             # its value in the hash it's in (one of the two
1382                             # defined just above) will include an index into
1383                             # this array.  The 0th element is initialized to
1384                             # the definition for a zero length invwersion list
1385 my %file_to_swash_name;     # Maps the file name to its corresponding key name
1386                             # in the hash %utf8::SwashInfo
1387 my %nv_floating_to_rational; # maps numeric values floating point numbers to
1388                              # their rational equivalent
1389 my %loose_property_name_of; # Loosely maps (non_string) property names to
1390                             # standard form
1391 my %strict_property_name_of; # Strictly maps (non_string) property names to
1392                             # standard form
1393 my %string_property_loose_to_name; # Same, for string properties.
1394 my %loose_defaults;         # keys are of form "prop=value", where 'prop' is
1395                             # the property name in standard loose form, and
1396                             # 'value' is the default value for that property,
1397                             # also in standard loose form.
1398 my %loose_to_standard_value; # loosely maps table names to the canonical
1399                             # alias for them
1400 my %ambiguous_names;        # keys are alias names (in standard form) that
1401                             # have more than one possible meaning.
1402 my %prop_aliases;           # Keys are standard property name; values are each
1403                             # one's aliases
1404 my %prop_value_aliases;     # Keys of top level are standard property name;
1405                             # values are keys to another hash,  Each one is
1406                             # one of the property's values, in standard form.
1407                             # The values are that prop-val's aliases.
1408 my %ucd_pod;    # Holds entries that will go into the UCD section of the pod
1409
1410 # Most properties are immune to caseless matching, otherwise you would get
1411 # nonsensical results, as properties are a function of a code point, not
1412 # everything that is caselessly equivalent to that code point.  For example,
1413 # Changes_When_Case_Folded('s') should be false, whereas caselessly it would
1414 # be true because 's' and 'S' are equivalent caselessly.  However,
1415 # traditionally, [:upper:] and [:lower:] are equivalent caselessly, so we
1416 # extend that concept to those very few properties that are like this.  Each
1417 # such property will match the full range caselessly.  They are hard-coded in
1418 # the program; it's not worth trying to make it general as it's extremely
1419 # unlikely that they will ever change.
1420 my %caseless_equivalent_to;
1421
1422 # These constants names and values were taken from the Unicode standard,
1423 # version 5.1, section 3.12.  They are used in conjunction with Hangul
1424 # syllables.  The '_string' versions are so generated tables can retain the
1425 # hex format, which is the more familiar value
1426 my $SBase_string = "0xAC00";
1427 my $SBase = CORE::hex $SBase_string;
1428 my $LBase_string = "0x1100";
1429 my $LBase = CORE::hex $LBase_string;
1430 my $VBase_string = "0x1161";
1431 my $VBase = CORE::hex $VBase_string;
1432 my $TBase_string = "0x11A7";
1433 my $TBase = CORE::hex $TBase_string;
1434 my $SCount = 11172;
1435 my $LCount = 19;
1436 my $VCount = 21;
1437 my $TCount = 28;
1438 my $NCount = $VCount * $TCount;
1439
1440 # For Hangul syllables;  These store the numbers from Jamo.txt in conjunction
1441 # with the above published constants.
1442 my %Jamo;
1443 my %Jamo_L;     # Leading consonants
1444 my %Jamo_V;     # Vowels
1445 my %Jamo_T;     # Trailing consonants
1446
1447 # For code points whose name contains its ordinal as a '-ABCD' suffix.
1448 # The key is the base name of the code point, and the value is an
1449 # array giving all the ranges that use this base name.  Each range
1450 # is actually a hash giving the 'low' and 'high' values of it.
1451 my %names_ending_in_code_point;
1452 my %loose_names_ending_in_code_point;   # Same as above, but has blanks, dashes
1453                                         # removed from the names
1454 # Inverse mapping.  The list of ranges that have these kinds of
1455 # names.  Each element contains the low, high, and base names in an
1456 # anonymous hash.
1457 my @code_points_ending_in_code_point;
1458
1459 # To hold Unicode's normalization test suite
1460 my @normalization_tests;
1461
1462 # Boolean: does this Unicode version have the hangul syllables, and are we
1463 # writing out a table for them?
1464 my $has_hangul_syllables = 0;
1465
1466 # Does this Unicode version have code points whose names end in their
1467 # respective code points, and are we writing out a table for them?  0 for no;
1468 # otherwise points to first property that a table is needed for them, so that
1469 # if multiple tables are needed, we don't create duplicates
1470 my $needing_code_points_ending_in_code_point = 0;
1471
1472 my @backslash_X_tests;     # List of tests read in for testing \X
1473 my @SB_tests;              # List of tests read in for testing \b{sb}
1474 my @WB_tests;              # List of tests read in for testing \b{wb}
1475 my @unhandled_properties;  # Will contain a list of properties found in
1476                            # the input that we didn't process.
1477 my @match_properties;      # Properties that have match tables, to be
1478                            # listed in the pod
1479 my @map_properties;        # Properties that get map files written
1480 my @named_sequences;       # NamedSequences.txt contents.
1481 my %potential_files;       # Generated list of all .txt files in the directory
1482                            # structure so we can warn if something is being
1483                            # ignored.
1484 my @files_actually_output; # List of files we generated.
1485 my @more_Names;            # Some code point names are compound; this is used
1486                            # to store the extra components of them.
1487 my $MIN_FRACTION_LENGTH = 3; # How many digits of a floating point number at
1488                            # the minimum before we consider it equivalent to a
1489                            # candidate rational
1490 my $MAX_FLOATING_SLOP = 10 ** - $MIN_FRACTION_LENGTH; # And in floating terms
1491
1492 # These store references to certain commonly used property objects
1493 my $ccc;
1494 my $gc;
1495 my $perl;
1496 my $block;
1497 my $perl_charname;
1498 my $print;
1499 my $All;
1500 my $Assigned;   # All assigned characters in this Unicode release
1501 my $script;
1502
1503 # Are there conflicting names because of beginning with 'In_', or 'Is_'
1504 my $has_In_conflicts = 0;
1505 my $has_Is_conflicts = 0;
1506
1507 sub internal_file_to_platform ($) {
1508     # Convert our file paths which have '/' separators to those of the
1509     # platform.
1510
1511     my $file = shift;
1512     return undef unless defined $file;
1513
1514     return File::Spec->join(split '/', $file);
1515 }
1516
1517 sub file_exists ($) {   # platform independent '-e'.  This program internally
1518                         # uses slash as a path separator.
1519     my $file = shift;
1520     return 0 if ! defined $file;
1521     return -e internal_file_to_platform($file);
1522 }
1523
1524 sub objaddr($) {
1525     # Returns the address of the blessed input object.
1526     # It doesn't check for blessedness because that would do a string eval
1527     # every call, and the program is structured so that this is never called
1528     # for a non-blessed object.
1529
1530     no overloading; # If overloaded, numifying below won't work.
1531
1532     # Numifying a ref gives its address.
1533     return pack 'J', $_[0];
1534 }
1535
1536 # These are used only if $annotate is true.
1537 # The entire range of Unicode characters is examined to populate these
1538 # after all the input has been processed.  But most can be skipped, as they
1539 # have the same descriptive phrases, such as being unassigned
1540 my @viacode;            # Contains the 1 million character names
1541 my @printable;          # boolean: And are those characters printable?
1542 my @annotate_char_type; # Contains a type of those characters, specifically
1543                         # for the purposes of annotation.
1544 my $annotate_ranges;    # A map of ranges of code points that have the same
1545                         # name for the purposes of annotation.  They map to the
1546                         # upper edge of the range, so that the end point can
1547                         # be immediately found.  This is used to skip ahead to
1548                         # the end of a range, and avoid processing each
1549                         # individual code point in it.
1550 my $unassigned_sans_noncharacters; # A Range_List of the unassigned
1551                                    # characters, but excluding those which are
1552                                    # also noncharacter code points
1553
1554 # The annotation types are an extension of the regular range types, though
1555 # some of the latter are folded into one.  Make the new types negative to
1556 # avoid conflicting with the regular types
1557 my $SURROGATE_TYPE = -1;
1558 my $UNASSIGNED_TYPE = -2;
1559 my $PRIVATE_USE_TYPE = -3;
1560 my $NONCHARACTER_TYPE = -4;
1561 my $CONTROL_TYPE = -5;
1562 my $ABOVE_UNICODE_TYPE = -6;
1563 my $UNKNOWN_TYPE = -7;  # Used only if there is a bug in this program
1564
1565 sub populate_char_info ($) {
1566     # Used only with the $annotate option.  Populates the arrays with the
1567     # input code point's info that are needed for outputting more detailed
1568     # comments.  If calling context wants a return, it is the end point of
1569     # any contiguous range of characters that share essentially the same info
1570
1571     my $i = shift;
1572     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1573
1574     $viacode[$i] = $perl_charname->value_of($i) || "";
1575
1576     # A character is generally printable if Unicode says it is,
1577     # but below we make sure that most Unicode general category 'C' types
1578     # aren't.
1579     $printable[$i] = $print->contains($i);
1580
1581     $annotate_char_type[$i] = $perl_charname->type_of($i) || 0;
1582
1583     # Only these two regular types are treated specially for annotations
1584     # purposes
1585     $annotate_char_type[$i] = 0 if $annotate_char_type[$i] != $CP_IN_NAME
1586                                 && $annotate_char_type[$i] != $HANGUL_SYLLABLE;
1587
1588     # Give a generic name to all code points that don't have a real name.
1589     # We output ranges, if applicable, for these.  Also calculate the end
1590     # point of the range.
1591     my $end;
1592     if (! $viacode[$i]) {
1593         my $nonchar;
1594         if ($i > $MAX_UNICODE_CODEPOINT) {
1595             $viacode[$i] = 'Above-Unicode';
1596             $annotate_char_type[$i] = $ABOVE_UNICODE_TYPE;
1597             $printable[$i] = 0;
1598             $end = $MAX_WORKING_CODEPOINT;
1599         }
1600         elsif ($gc-> table('Private_use')->contains($i)) {
1601             $viacode[$i] = 'Private Use';
1602             $annotate_char_type[$i] = $PRIVATE_USE_TYPE;
1603             $printable[$i] = 0;
1604             $end = $gc->table('Private_Use')->containing_range($i)->end;
1605         }
1606         elsif ((defined ($nonchar =
1607                             Property::property_ref('Noncharacter_Code_Point'))
1608                && $nonchar->table('Y')->contains($i)))
1609         {
1610             $viacode[$i] = 'Noncharacter';
1611             $annotate_char_type[$i] = $NONCHARACTER_TYPE;
1612             $printable[$i] = 0;
1613             $end = property_ref('Noncharacter_Code_Point')->table('Y')->
1614                                                     containing_range($i)->end;
1615         }
1616         elsif ($gc-> table('Control')->contains($i)) {
1617             $viacode[$i] = property_ref('Name_Alias')->value_of($i) || 'Control';
1618             $annotate_char_type[$i] = $CONTROL_TYPE;
1619             $printable[$i] = 0;
1620         }
1621         elsif ($gc-> table('Unassigned')->contains($i)) {
1622             $annotate_char_type[$i] = $UNASSIGNED_TYPE;
1623             $printable[$i] = 0;
1624             if ($v_version lt v2.0.0) { # No blocks in earliest releases
1625                 $viacode[$i] = 'Unassigned';
1626                 $end = $gc-> table('Unassigned')->containing_range($i)->end;
1627             }
1628             else {
1629                 $viacode[$i] = 'Unassigned, block=' . $block-> value_of($i);
1630
1631                 # Because we name the unassigned by the blocks they are in, it
1632                 # can't go past the end of that block, and it also can't go
1633                 # past the unassigned range it is in.  The special table makes
1634                 # sure that the non-characters, which are unassigned, are
1635                 # separated out.
1636                 $end = min($block->containing_range($i)->end,
1637                            $unassigned_sans_noncharacters->
1638                                                     containing_range($i)->end);
1639             }
1640         }
1641         elsif ($perl->table('_Perl_Surrogate')->contains($i)) {
1642             $viacode[$i] = 'Surrogate';
1643             $annotate_char_type[$i] = $SURROGATE_TYPE;
1644             $printable[$i] = 0;
1645             $end = $gc->table('Surrogate')->containing_range($i)->end;
1646         }
1647         else {
1648             Carp::my_carp_bug("Can't figure out how to annotate "
1649                               . sprintf("U+%04X", $i)
1650                               . ".  Proceeding anyway.");
1651             $viacode[$i] = 'UNKNOWN';
1652             $annotate_char_type[$i] = $UNKNOWN_TYPE;
1653             $printable[$i] = 0;
1654         }
1655     }
1656
1657     # Here, has a name, but if it's one in which the code point number is
1658     # appended to the name, do that.
1659     elsif ($annotate_char_type[$i] == $CP_IN_NAME) {
1660         $viacode[$i] .= sprintf("-%04X", $i);
1661         $end = $perl_charname->containing_range($i)->end;
1662     }
1663
1664     # And here, has a name, but if it's a hangul syllable one, replace it with
1665     # the correct name from the Unicode algorithm
1666     elsif ($annotate_char_type[$i] == $HANGUL_SYLLABLE) {
1667         use integer;
1668         my $SIndex = $i - $SBase;
1669         my $L = $LBase + $SIndex / $NCount;
1670         my $V = $VBase + ($SIndex % $NCount) / $TCount;
1671         my $T = $TBase + $SIndex % $TCount;
1672         $viacode[$i] = "HANGUL SYLLABLE $Jamo{$L}$Jamo{$V}";
1673         $viacode[$i] .= $Jamo{$T} if $T != $TBase;
1674         $end = $perl_charname->containing_range($i)->end;
1675     }
1676
1677     return if ! defined wantarray;
1678     return $i if ! defined $end;    # If not a range, return the input
1679
1680     # Save this whole range so can find the end point quickly
1681     $annotate_ranges->add_map($i, $end, $end);
1682
1683     return $end;
1684 }
1685
1686 # Commented code below should work on Perl 5.8.
1687 ## This 'require' doesn't necessarily work in miniperl, and even if it does,
1688 ## the native perl version of it (which is what would operate under miniperl)
1689 ## is extremely slow, as it does a string eval every call.
1690 #my $has_fast_scalar_util = $^X !~ /miniperl/
1691 #                            && defined eval "require Scalar::Util";
1692 #
1693 #sub objaddr($) {
1694 #    # Returns the address of the blessed input object.  Uses the XS version if
1695 #    # available.  It doesn't check for blessedness because that would do a
1696 #    # string eval every call, and the program is structured so that this is
1697 #    # never called for a non-blessed object.
1698 #
1699 #    return Scalar::Util::refaddr($_[0]) if $has_fast_scalar_util;
1700 #
1701 #    # Check at least that is a ref.
1702 #    my $pkg = ref($_[0]) or return undef;
1703 #
1704 #    # Change to a fake package to defeat any overloaded stringify
1705 #    bless $_[0], 'main::Fake';
1706 #
1707 #    # Numifying a ref gives its address.
1708 #    my $addr = pack 'J', $_[0];
1709 #
1710 #    # Return to original class
1711 #    bless $_[0], $pkg;
1712 #    return $addr;
1713 #}
1714
1715 sub max ($$) {
1716     my $a = shift;
1717     my $b = shift;
1718     return $a if $a >= $b;
1719     return $b;
1720 }
1721
1722 sub min ($$) {
1723     my $a = shift;
1724     my $b = shift;
1725     return $a if $a <= $b;
1726     return $b;
1727 }
1728
1729 sub clarify_number ($) {
1730     # This returns the input number with underscores inserted every 3 digits
1731     # in large (5 digits or more) numbers.  Input must be entirely digits, not
1732     # checked.
1733
1734     my $number = shift;
1735     my $pos = length($number) - 3;
1736     return $number if $pos <= 1;
1737     while ($pos > 0) {
1738         substr($number, $pos, 0) = '_';
1739         $pos -= 3;
1740     }
1741     return $number;
1742 }
1743
1744 sub clarify_code_point_count ($) {
1745     # This is like clarify_number(), but the input is assumed to be a count of
1746     # code points, rather than a generic number.
1747
1748     my $append = "";
1749
1750     my $number = shift;
1751     if ($number > $MAX_UNICODE_CODEPOINTS) {
1752         $number -= ($MAX_WORKING_CODEPOINTS - $MAX_UNICODE_CODEPOINTS);
1753         return "All above-Unicode code points" if $number == 0;
1754         $append = " + all above-Unicode code points";
1755     }
1756     return clarify_number($number) . $append;
1757 }
1758
1759 package Carp;
1760
1761 # These routines give a uniform treatment of messages in this program.  They
1762 # are placed in the Carp package to cause the stack trace to not include them,
1763 # although an alternative would be to use another package and set @CARP_NOT
1764 # for it.
1765
1766 our $Verbose = 1 if main::DEBUG;  # Useful info when debugging
1767
1768 # This is a work-around suggested by Nicholas Clark to fix a problem with Carp
1769 # and overload trying to load Scalar:Util under miniperl.  See
1770 # http://www.xray.mpe.mpg.de/mailing-lists/perl5-porters/2009-11/msg01057.html
1771 undef $overload::VERSION;
1772
1773 sub my_carp {
1774     my $message = shift || "";
1775     my $nofold = shift || 0;
1776
1777     if ($message) {
1778         $message = main::join_lines($message);
1779         $message =~ s/^$0: *//;     # Remove initial program name
1780         $message =~ s/[.;,]+$//;    # Remove certain ending punctuation
1781         $message = "\n$0: $message;";
1782
1783         # Fold the message with program name, semi-colon end punctuation
1784         # (which looks good with the message that carp appends to it), and a
1785         # hanging indent for continuation lines.
1786         $message = main::simple_fold($message, "", 4) unless $nofold;
1787         $message =~ s/\n$//;        # Remove the trailing nl so what carp
1788                                     # appends is to the same line
1789     }
1790
1791     return $message if defined wantarray;   # If a caller just wants the msg
1792
1793     carp $message;
1794     return;
1795 }
1796
1797 sub my_carp_bug {
1798     # This is called when it is clear that the problem is caused by a bug in
1799     # this program.
1800
1801     my $message = shift;
1802     $message =~ s/^$0: *//;
1803     $message = my_carp("Bug in $0.  Please report it by running perlbug or if that is unavailable, by sending email to perbug\@perl.org:\n$message");
1804     carp $message;
1805     return;
1806 }
1807
1808 sub carp_too_few_args {
1809     if (@_ != 2) {
1810         my_carp_bug("Wrong number of arguments: to 'carp_too_few_arguments'.  No action taken.");
1811         return;
1812     }
1813
1814     my $args_ref = shift;
1815     my $count = shift;
1816
1817     my_carp_bug("Need at least $count arguments to "
1818         . (caller 1)[3]
1819         . ".  Instead got: '"
1820         . join ', ', @$args_ref
1821         . "'.  No action taken.");
1822     return;
1823 }
1824
1825 sub carp_extra_args {
1826     my $args_ref = shift;
1827     my_carp_bug("Too many arguments to 'carp_extra_args': (" . join(', ', @_) . ");  Extras ignored.") if @_;
1828
1829     unless (ref $args_ref) {
1830         my_carp_bug("Argument to 'carp_extra_args' ($args_ref) must be a ref.  Not checking arguments.");
1831         return;
1832     }
1833     my ($package, $file, $line) = caller;
1834     my $subroutine = (caller 1)[3];
1835
1836     my $list;
1837     if (ref $args_ref eq 'HASH') {
1838         foreach my $key (keys %$args_ref) {
1839             $args_ref->{$key} = $UNDEF unless defined $args_ref->{$key};
1840         }
1841         $list = join ', ', each %{$args_ref};
1842     }
1843     elsif (ref $args_ref eq 'ARRAY') {
1844         foreach my $arg (@$args_ref) {
1845             $arg = $UNDEF unless defined $arg;
1846         }
1847         $list = join ', ', @$args_ref;
1848     }
1849     else {
1850         my_carp_bug("Can't cope with ref "
1851                 . ref($args_ref)
1852                 . " . argument to 'carp_extra_args'.  Not checking arguments.");
1853         return;
1854     }
1855
1856     my_carp_bug("Unrecognized parameters in options: '$list' to $subroutine.  Skipped.");
1857     return;
1858 }
1859
1860 package main;
1861
1862 { # Closure
1863
1864     # This program uses the inside-out method for objects, as recommended in
1865     # "Perl Best Practices".  (This is the best solution still, since this has
1866     # to run under miniperl.)  This closure aids in generating those.  There
1867     # are two routines.  setup_package() is called once per package to set
1868     # things up, and then set_access() is called for each hash representing a
1869     # field in the object.  These routines arrange for the object to be
1870     # properly destroyed when no longer used, and for standard accessor
1871     # functions to be generated.  If you need more complex accessors, just
1872     # write your own and leave those accesses out of the call to set_access().
1873     # More details below.
1874
1875     my %constructor_fields; # fields that are to be used in constructors; see
1876                             # below
1877
1878     # The values of this hash will be the package names as keys to other
1879     # hashes containing the name of each field in the package as keys, and
1880     # references to their respective hashes as values.
1881     my %package_fields;
1882
1883     sub setup_package {
1884         # Sets up the package, creating standard DESTROY and dump methods
1885         # (unless already defined).  The dump method is used in debugging by
1886         # simple_dumper().
1887         # The optional parameters are:
1888         #   a)  a reference to a hash, that gets populated by later
1889         #       set_access() calls with one of the accesses being
1890         #       'constructor'.  The caller can then refer to this, but it is
1891         #       not otherwise used by these two routines.
1892         #   b)  a reference to a callback routine to call during destruction
1893         #       of the object, before any fields are actually destroyed
1894
1895         my %args = @_;
1896         my $constructor_ref = delete $args{'Constructor_Fields'};
1897         my $destroy_callback = delete $args{'Destroy_Callback'};
1898         Carp::carp_extra_args(\@_) if main::DEBUG && %args;
1899
1900         my %fields;
1901         my $package = (caller)[0];
1902
1903         $package_fields{$package} = \%fields;
1904         $constructor_fields{$package} = $constructor_ref;
1905
1906         unless ($package->can('DESTROY')) {
1907             my $destroy_name = "${package}::DESTROY";
1908             no strict "refs";
1909
1910             # Use typeglob to give the anonymous subroutine the name we want
1911             *$destroy_name = sub {
1912                 my $self = shift;
1913                 my $addr = do { no overloading; pack 'J', $self; };
1914
1915                 $self->$destroy_callback if $destroy_callback;
1916                 foreach my $field (keys %{$package_fields{$package}}) {
1917                     #print STDERR __LINE__, ": Destroying ", ref $self, " ", sprintf("%04X", $addr), ": ", $field, "\n";
1918                     delete $package_fields{$package}{$field}{$addr};
1919                 }
1920                 return;
1921             }
1922         }
1923
1924         unless ($package->can('dump')) {
1925             my $dump_name = "${package}::dump";
1926             no strict "refs";
1927             *$dump_name = sub {
1928                 my $self = shift;
1929                 return dump_inside_out($self, $package_fields{$package}, @_);
1930             }
1931         }
1932         return;
1933     }
1934
1935     sub set_access {
1936         # Arrange for the input field to be garbage collected when no longer
1937         # needed.  Also, creates standard accessor functions for the field
1938         # based on the optional parameters-- none if none of these parameters:
1939         #   'addable'    creates an 'add_NAME()' accessor function.
1940         #   'readable' or 'readable_array'   creates a 'NAME()' accessor
1941         #                function.
1942         #   'settable'   creates a 'set_NAME()' accessor function.
1943         #   'constructor' doesn't create an accessor function, but adds the
1944         #                field to the hash that was previously passed to
1945         #                setup_package();
1946         # Any of the accesses can be abbreviated down, so that 'a', 'ad',
1947         # 'add' etc. all mean 'addable'.
1948         # The read accessor function will work on both array and scalar
1949         # values.  If another accessor in the parameter list is 'a', the read
1950         # access assumes an array.  You can also force it to be array access
1951         # by specifying 'readable_array' instead of 'readable'
1952         #
1953         # A sort-of 'protected' access can be set-up by preceding the addable,
1954         # readable or settable with some initial portion of 'protected_' (but,
1955         # the underscore is required), like 'p_a', 'pro_set', etc.  The
1956         # "protection" is only by convention.  All that happens is that the
1957         # accessor functions' names begin with an underscore.  So instead of
1958         # calling set_foo, the call is _set_foo.  (Real protection could be
1959         # accomplished by having a new subroutine, end_package, called at the
1960         # end of each package, and then storing the __LINE__ ranges and
1961         # checking them on every accessor.  But that is way overkill.)
1962
1963         # We create anonymous subroutines as the accessors and then use
1964         # typeglobs to assign them to the proper package and name
1965
1966         my $name = shift;   # Name of the field
1967         my $field = shift;  # Reference to the inside-out hash containing the
1968                             # field
1969
1970         my $package = (caller)[0];
1971
1972         if (! exists $package_fields{$package}) {
1973             croak "$0: Must call 'setup_package' before 'set_access'";
1974         }
1975
1976         # Stash the field so DESTROY can get it.
1977         $package_fields{$package}{$name} = $field;
1978
1979         # Remaining arguments are the accessors.  For each...
1980         foreach my $access (@_) {
1981             my $access = lc $access;
1982
1983             my $protected = "";
1984
1985             # Match the input as far as it goes.
1986             if ($access =~ /^(p[^_]*)_/) {
1987                 $protected = $1;
1988                 if (substr('protected_', 0, length $protected)
1989                     eq $protected)
1990                 {
1991
1992                     # Add 1 for the underscore not included in $protected
1993                     $access = substr($access, length($protected) + 1);
1994                     $protected = '_';
1995                 }
1996                 else {
1997                     $protected = "";
1998                 }
1999             }
2000
2001             if (substr('addable', 0, length $access) eq $access) {
2002                 my $subname = "${package}::${protected}add_$name";
2003                 no strict "refs";
2004
2005                 # add_ accessor.  Don't add if already there, which we
2006                 # determine using 'eq' for scalars and '==' otherwise.
2007                 *$subname = sub {
2008                     use strict "refs";
2009                     return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
2010                     my $self = shift;
2011                     my $value = shift;
2012                     my $addr = do { no overloading; pack 'J', $self; };
2013                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2014                     if (ref $value) {
2015                         return if grep { $value == $_ } @{$field->{$addr}};
2016                     }
2017                     else {
2018                         return if grep { $value eq $_ } @{$field->{$addr}};
2019                     }
2020                     push @{$field->{$addr}}, $value;
2021                     return;
2022                 }
2023             }
2024             elsif (substr('constructor', 0, length $access) eq $access) {
2025                 if ($protected) {
2026                     Carp::my_carp_bug("Can't set-up 'protected' constructors")
2027                 }
2028                 else {
2029                     $constructor_fields{$package}{$name} = $field;
2030                 }
2031             }
2032             elsif (substr('readable_array', 0, length $access) eq $access) {
2033
2034                 # Here has read access.  If one of the other parameters for
2035                 # access is array, or this one specifies array (by being more
2036                 # than just 'readable_'), then create a subroutine that
2037                 # assumes the data is an array.  Otherwise just a scalar
2038                 my $subname = "${package}::${protected}$name";
2039                 if (grep { /^a/i } @_
2040                     or length($access) > length('readable_'))
2041                 {
2042                     no strict "refs";
2043                     *$subname = sub {
2044                         use strict "refs";
2045                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
2046                         my $addr = do { no overloading; pack 'J', $_[0]; };
2047                         if (ref $field->{$addr} ne 'ARRAY') {
2048                             my $type = ref $field->{$addr};
2049                             $type = 'scalar' unless $type;
2050                             Carp::my_carp_bug("Trying to read $name as an array when it is a $type.  Big problems.");
2051                             return;
2052                         }
2053                         return scalar @{$field->{$addr}} unless wantarray;
2054
2055                         # Make a copy; had problems with caller modifying the
2056                         # original otherwise
2057                         my @return = @{$field->{$addr}};
2058                         return @return;
2059                     }
2060                 }
2061                 else {
2062
2063                     # Here not an array value, a simpler function.
2064                     no strict "refs";
2065                     *$subname = sub {
2066                         use strict "refs";
2067                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
2068                         no overloading;
2069                         return $field->{pack 'J', $_[0]};
2070                     }
2071                 }
2072             }
2073             elsif (substr('settable', 0, length $access) eq $access) {
2074                 my $subname = "${package}::${protected}set_$name";
2075                 no strict "refs";
2076                 *$subname = sub {
2077                     use strict "refs";
2078                     if (main::DEBUG) {
2079                         return Carp::carp_too_few_args(\@_, 2) if @_ < 2;
2080                         Carp::carp_extra_args(\@_) if @_ > 2;
2081                     }
2082                     # $self is $_[0]; $value is $_[1]
2083                     no overloading;
2084                     $field->{pack 'J', $_[0]} = $_[1];
2085                     return;
2086                 }
2087             }
2088             else {
2089                 Carp::my_carp_bug("Unknown accessor type $access.  No accessor set.");
2090             }
2091         }
2092         return;
2093     }
2094 }
2095
2096 package Input_file;
2097
2098 # All input files use this object, which stores various attributes about them,
2099 # and provides for convenient, uniform handling.  The run method wraps the
2100 # processing.  It handles all the bookkeeping of opening, reading, and closing
2101 # the file, returning only significant input lines.
2102 #
2103 # Each object gets a handler which processes the body of the file, and is
2104 # called by run().  All character property files must use the generic,
2105 # default handler, which has code scrubbed to handle things you might not
2106 # expect, including automatic EBCDIC handling.  For files that don't deal with
2107 # mapping code points to a property value, such as test files,
2108 # PropertyAliases, PropValueAliases, and named sequences, you can override the
2109 # handler to be a custom one.  Such a handler should basically be a
2110 # while(next_line()) {...} loop.
2111 #
2112 # You can also set up handlers to
2113 #   1) call before the first line is read, for pre processing
2114 #   2) call to adjust each line of the input before the main handler gets
2115 #      them.  This can be automatically generated, if appropriately simple
2116 #      enough, by specifiying a Properties parameter in the constructor.
2117 #   3) call upon EOF before the main handler exits its loop
2118 #   4) call at the end, for post processing
2119 #
2120 # $_ is used to store the input line, and is to be filtered by the
2121 # each_line_handler()s.  So, if the format of the line is not in the desired
2122 # format for the main handler, these are used to do that adjusting.  They can
2123 # be stacked (by enclosing them in an [ anonymous array ] in the constructor,
2124 # so the $_ output of one is used as the input to the next.  None of the other
2125 # handlers are stackable, but could easily be changed to be so.
2126 #
2127 # Most of the handlers can call insert_lines() or insert_adjusted_lines()
2128 # which insert the parameters as lines to be processed before the next input
2129 # file line is read.  This allows the EOF handler to flush buffers, for
2130 # example.  The difference between the two routines is that the lines inserted
2131 # by insert_lines() are subjected to the each_line_handler()s.  (So if you
2132 # called it from such a handler, you would get infinite recursion.)  Lines
2133 # inserted by insert_adjusted_lines() go directly to the main handler without
2134 # any adjustments.  If the  post-processing handler calls any of these, there
2135 # will be no effect.  Some error checking for these conditions could be added,
2136 # but it hasn't been done.
2137 #
2138 # carp_bad_line() should be called to warn of bad input lines, which clears $_
2139 # to prevent further processing of the line.  This routine will output the
2140 # message as a warning once, and then keep a count of the lines that have the
2141 # same message, and output that count at the end of the file's processing.
2142 # This keeps the number of messages down to a manageable amount.
2143 #
2144 # get_missings() should be called to retrieve any @missing input lines.
2145 # Messages will be raised if this isn't done if the options aren't to ignore
2146 # missings.
2147
2148 sub trace { return main::trace(@_); }
2149
2150 { # Closure
2151     # Keep track of fields that are to be put into the constructor.
2152     my %constructor_fields;
2153
2154     main::setup_package(Constructor_Fields => \%constructor_fields);
2155
2156     my %file; # Input file name, required
2157     main::set_access('file', \%file, qw{ c r });
2158
2159     my %first_released; # Unicode version file was first released in, required
2160     main::set_access('first_released', \%first_released, qw{ c r });
2161
2162     my %handler;    # Subroutine to process the input file, defaults to
2163                     # 'process_generic_property_file'
2164     main::set_access('handler', \%handler, qw{ c });
2165
2166     my %property;
2167     # name of property this file is for.  defaults to none, meaning not
2168     # applicable, or is otherwise determinable, for example, from each line.
2169     main::set_access('property', \%property, qw{ c r });
2170
2171     my %optional;
2172     # If this is true, the file is optional.  If not present, no warning is
2173     # output.  If it is present, the string given by this parameter is
2174     # evaluated, and if false the file is not processed.
2175     main::set_access('optional', \%optional, 'c', 'r');
2176
2177     my %non_skip;
2178     # This is used for debugging, to skip processing of all but a few input
2179     # files.  Add 'non_skip => 1' to the constructor for those files you want
2180     # processed when you set the $debug_skip global.
2181     main::set_access('non_skip', \%non_skip, 'c');
2182
2183     my %skip;
2184     # This is used to skip processing of this input file semi-permanently,
2185     # when it evaluates to true.  The value should be the reason the file is
2186     # being skipped.  It is used for files that we aren't planning to process
2187     # anytime soon, but want to allow to be in the directory and not raise a
2188     # message that we are not handling.  Mostly for test files.  This is in
2189     # contrast to the non_skip element, which is supposed to be used very
2190     # temporarily for debugging.  Sets 'optional' to 1.  Also, files that we
2191     # pretty much will never look at can be placed in the global
2192     # %ignored_files instead.  Ones used here will be added to %skipped files
2193     main::set_access('skip', \%skip, 'c');
2194
2195     my %each_line_handler;
2196     # list of subroutines to look at and filter each non-comment line in the
2197     # file.  defaults to none.  The subroutines are called in order, each is
2198     # to adjust $_ for the next one, and the final one adjusts it for
2199     # 'handler'
2200     main::set_access('each_line_handler', \%each_line_handler, 'c');
2201
2202     my %properties; # Optional ordered list of the properties that occur in each
2203     # meaningful line of the input file.  If present, an appropriate
2204     # each_line_handler() is automatically generated and pushed onto the stack
2205     # of such handlers.  This is useful when a file contains multiple
2206     # proerties per line, but no other special considerations are necessary.
2207     # The special value "<ignored>" means to discard the corresponding input
2208     # field.
2209     # Any @missing lines in the file should also match this syntax; no such
2210     # files exist as of 6.3.  But if it happens in a future release, the code
2211     # could be expanded to properly parse them.
2212     main::set_access('properties', \%properties, qw{ c r });
2213
2214     my %has_missings_defaults;
2215     # ? Are there lines in the file giving default values for code points
2216     # missing from it?.  Defaults to NO_DEFAULTS.  Otherwise NOT_IGNORED is
2217     # the norm, but IGNORED means it has such lines, but the handler doesn't
2218     # use them.  Having these three states allows us to catch changes to the
2219     # UCD that this program should track.  XXX This could be expanded to
2220     # specify the syntax for such lines, like %properties above.
2221     main::set_access('has_missings_defaults',
2222                                         \%has_missings_defaults, qw{ c r });
2223
2224     my %pre_handler;
2225     # Subroutine to call before doing anything else in the file.  If undef, no
2226     # such handler is called.
2227     main::set_access('pre_handler', \%pre_handler, qw{ c });
2228
2229     my %eof_handler;
2230     # Subroutine to call upon getting an EOF on the input file, but before
2231     # that is returned to the main handler.  This is to allow buffers to be
2232     # flushed.  The handler is expected to call insert_lines() or
2233     # insert_adjusted() with the buffered material
2234     main::set_access('eof_handler', \%eof_handler, qw{ c r });
2235
2236     my %post_handler;
2237     # Subroutine to call after all the lines of the file are read in and
2238     # processed.  If undef, no such handler is called.
2239     main::set_access('post_handler', \%post_handler, qw{ c });
2240
2241     my %progress_message;
2242     # Message to print to display progress in lieu of the standard one
2243     main::set_access('progress_message', \%progress_message, qw{ c });
2244
2245     my %handle;
2246     # cache open file handle, internal.  Is undef if file hasn't been
2247     # processed at all, empty if has;
2248     main::set_access('handle', \%handle);
2249
2250     my %added_lines;
2251     # cache of lines added virtually to the file, internal
2252     main::set_access('added_lines', \%added_lines);
2253
2254     my %remapped_lines;
2255     # cache of lines added virtually to the file, internal
2256     main::set_access('remapped_lines', \%remapped_lines);
2257
2258     my %errors;
2259     # cache of errors found, internal
2260     main::set_access('errors', \%errors);
2261
2262     my %missings;
2263     # storage of '@missing' defaults lines
2264     main::set_access('missings', \%missings);
2265
2266     sub _next_line;
2267     sub _next_line_with_remapped_range;
2268
2269     sub new {
2270         my $class = shift;
2271
2272         my $self = bless \do{ my $anonymous_scalar }, $class;
2273         my $addr = do { no overloading; pack 'J', $self; };
2274
2275         # Set defaults
2276         $handler{$addr} = \&main::process_generic_property_file;
2277         $non_skip{$addr} = 0;
2278         $skip{$addr} = 0;
2279         $has_missings_defaults{$addr} = $NO_DEFAULTS;
2280         $handle{$addr} = undef;
2281         $added_lines{$addr} = [ ];
2282         $remapped_lines{$addr} = [ ];
2283         $each_line_handler{$addr} = [ ];
2284         $errors{$addr} = { };
2285         $missings{$addr} = [ ];
2286
2287         # Two positional parameters.
2288         return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
2289         $file{$addr} = main::internal_file_to_platform(shift);
2290         $first_released{$addr} = shift;
2291
2292         undef $file{$addr} if $first_released{$addr} gt $v_version;
2293
2294         # The rest of the arguments are key => value pairs
2295         # %constructor_fields has been set up earlier to list all possible
2296         # ones.  Either set or push, depending on how the default has been set
2297         # up just above.
2298         my %args = @_;
2299         foreach my $key (keys %args) {
2300             my $argument = $args{$key};
2301
2302             # Note that the fields are the lower case of the constructor keys
2303             my $hash = $constructor_fields{lc $key};
2304             if (! defined $hash) {
2305                 Carp::my_carp_bug("Unrecognized parameters '$key => $argument' to new() for $self.  Skipped");
2306                 next;
2307             }
2308             if (ref $hash->{$addr} eq 'ARRAY') {
2309                 if (ref $argument eq 'ARRAY') {
2310                     foreach my $argument (@{$argument}) {
2311                         next if ! defined $argument;
2312                         push @{$hash->{$addr}}, $argument;
2313                     }
2314                 }
2315                 else {
2316                     push @{$hash->{$addr}}, $argument if defined $argument;
2317                 }
2318             }
2319             else {
2320                 $hash->{$addr} = $argument;
2321             }
2322             delete $args{$key};
2323         };
2324
2325         # If the file has a property for it, it means that the property is not
2326         # listed in the file's entries.  So add a handler to the list of line
2327         # handlers to insert the property name into the lines, to provide a
2328         # uniform interface to the final processing subroutine.
2329         # the final code doesn't have to worry about that.
2330         if ($property{$addr}) {
2331             push @{$each_line_handler{$addr}}, \&_insert_property_into_line;
2332         }
2333
2334         if ($non_skip{$addr} && ! $debug_skip && $verbosity) {
2335             print "Warning: " . __PACKAGE__ . " constructor for $file{$addr} has useless 'non_skip' in it\n";
2336         }
2337
2338         # If skipping, set to optional, and add to list of ignored files,
2339         # including its reason
2340         if ($skip{$addr}) {
2341             $optional{$addr} = 1;
2342             $skipped_files{$file{$addr}} = $skip{$addr} if $file{$addr};
2343         }
2344         elsif ($properties{$addr}) {
2345
2346             # Add a handler for each line in the input so that it creates a
2347             # separate input line for each property in those input lines, thus
2348             # making them suitable for process_generic_property_file().
2349
2350             push @{$each_line_handler{$addr}},
2351                  sub {
2352                     my $file = shift;
2353                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2354
2355                     my @fields = split /\s*;\s*/, $_, -1;
2356
2357                     if (@fields - 1 > @{$properties{$addr}}) {
2358                         $file->carp_bad_line('Extra fields');
2359                         $_ = "";
2360                         return;
2361                     }
2362                     my $range = shift @fields;  # 0th element is always the
2363                                                 # range
2364
2365                     # The next fields in the input line correspond
2366                     # respectively to the stored properties.
2367                     for my $i (0 ..  @{$properties{$addr}} - 1) {
2368                         my $property_name = $properties{$addr}[$i];
2369                         next if $property_name eq '<ignored>';
2370                         $file->insert_adjusted_lines(
2371                               "$range; $property_name; $fields[$i]");
2372                     }
2373                     $_ = "";
2374
2375                     return;
2376                 };
2377         }
2378
2379         {   # On non-ascii platforms, we use a special handler
2380             no strict;
2381             no warnings 'once';
2382             *next_line = (main::NON_ASCII_PLATFORM)
2383                          ? *_next_line_with_remapped_range
2384                          : *_next_line;
2385         }
2386
2387         return $self;
2388     }
2389
2390
2391     use overload
2392         fallback => 0,
2393         qw("") => "_operator_stringify",
2394         "." => \&main::_operator_dot,
2395         ".=" => \&main::_operator_dot_equal,
2396     ;
2397
2398     sub _operator_stringify {
2399         my $self = shift;
2400
2401         return __PACKAGE__ . " object for " . $self->file;
2402     }
2403
2404     # flag to make sure extracted files are processed early
2405     my $seen_non_extracted_non_age = 0;
2406
2407     sub run {
2408         # Process the input object $self.  This opens and closes the file and
2409         # calls all the handlers for it.  Currently,  this can only be called
2410         # once per file, as it destroy's the EOF handler
2411
2412         my $self = shift;
2413         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2414
2415         my $addr = do { no overloading; pack 'J', $self; };
2416
2417         my $file = $file{$addr};
2418
2419         # Don't process if not expecting this file (because released later
2420         # than this Unicode version), and isn't there.  This means if someone
2421         # copies it into an earlier version's directory, we will go ahead and
2422         # process it.
2423         return if $first_released{$addr} gt $v_version
2424                   && (! defined $file || ! -e $file);
2425
2426         # If in debugging mode and this file doesn't have the non-skip
2427         # flag set, and isn't one of the critical files, skip it.
2428         if ($debug_skip
2429             && $first_released{$addr} ne v0
2430             && ! $non_skip{$addr})
2431         {
2432             print "Skipping $file in debugging\n" if $verbosity;
2433             return;
2434         }
2435
2436         # File could be optional
2437         if ($optional{$addr}) {
2438             return unless -e $file;
2439             my $result = eval $optional{$addr};
2440             if (! defined $result) {
2441                 Carp::my_carp_bug("Got '$@' when tried to eval $optional{$addr}.  $file Skipped.");
2442                 return;
2443             }
2444             if (! $result) {
2445                 if ($verbosity) {
2446                     print STDERR "Skipping processing input file '$file' because '$optional{$addr}' is not true\n";
2447                 }
2448                 return;
2449             }
2450         }
2451
2452         if (! defined $file || ! -e $file) {
2453
2454             # If the file doesn't exist, see if have internal data for it
2455             # (based on first_released being 0).
2456             if ($first_released{$addr} eq v0) {
2457                 $handle{$addr} = 'pretend_is_open';
2458             }
2459             else {
2460                 if (! $optional{$addr}  # File could be optional
2461                     && $v_version ge $first_released{$addr})
2462                 {
2463                     print STDERR "Skipping processing input file '$file' because not found\n";
2464                 }
2465                 return;
2466             }
2467         }
2468         else {
2469
2470             # Here, the file exists.  Some platforms may change the case of
2471             # its name
2472             if ($seen_non_extracted_non_age) {
2473                 if ($file =~ /$EXTRACTED/i) {
2474                     Carp::my_carp_bug(main::join_lines(<<END
2475 $file should be processed just after the 'Prop...Alias' files, and before
2476 anything not in the $EXTRACTED_DIR directory.  Proceeding, but the results may
2477 have subtle problems
2478 END
2479                     ));
2480                 }
2481             }
2482             elsif ($EXTRACTED_DIR
2483                     && $first_released{$addr} ne v0
2484                     && $file !~ /$EXTRACTED/i
2485                     && lc($file) ne 'dage.txt')
2486             {
2487                 # We don't set this (by the 'if' above) if we have no
2488                 # extracted directory, so if running on an early version,
2489                 # this test won't work.  Not worth worrying about.
2490                 $seen_non_extracted_non_age = 1;
2491             }
2492
2493             # And mark the file as having being processed, and warn if it
2494             # isn't a file we are expecting.  As we process the files,
2495             # they are deleted from the hash, so any that remain at the
2496             # end of the program are files that we didn't process.
2497             my $fkey = File::Spec->rel2abs($file);
2498             my $expecting = delete $potential_files{lc($fkey)};
2499
2500             Carp::my_carp("Was not expecting '$file'.") if
2501                     ! $expecting
2502                     && ! defined $handle{$addr};
2503
2504             # Having deleted from expected files, we can quit if not to do
2505             # anything.  Don't print progress unless really want verbosity
2506             if ($skip{$addr}) {
2507                 print "Skipping $file.\n" if $verbosity >= $VERBOSE;
2508                 return;
2509             }
2510
2511             # Open the file, converting the slashes used in this program
2512             # into the proper form for the OS
2513             my $file_handle;
2514             if (not open $file_handle, "<", $file) {
2515                 Carp::my_carp("Can't open $file.  Skipping: $!");
2516                 return 0;
2517             }
2518             $handle{$addr} = $file_handle; # Cache the open file handle
2519
2520             if ($v_version ge v3.2.0 && lc($file) ne 'unicodedata.txt') {
2521                 if ($file !~ /^Unihan/i) {
2522                     $_ = <$file_handle>;
2523                     if ($_ !~ / - $string_version \. /x) {
2524                         chomp;
2525                         $_ =~ s/^#\s*//;
2526                         die Carp::my_carp("File '$file' is version '$_'.  It should be version $string_version");
2527                     }
2528                 }
2529                 else {
2530                     while (<$file_handle>) {
2531                         if ($_ !~ /^#/) {
2532                             Carp::my_carp_bug("Could not find the expected version info in file '$file'");
2533                             last;
2534                         }
2535                         chomp;
2536                         $_ =~ s/^#\s*//;
2537                         next if $_ !~ / version: /x;
2538                         last if $_ =~ /$string_version/;
2539                         die Carp::my_carp("File '$file' is '$_'.  It should be version $string_version");
2540                     }
2541                 }
2542             }
2543         }
2544
2545         if ($verbosity >= $PROGRESS) {
2546             if ($progress_message{$addr}) {
2547                 print "$progress_message{$addr}\n";
2548             }
2549             else {
2550                 # If using a virtual file, say so.
2551                 print "Processing ", (-e $file)
2552                                        ? $file
2553                                        : "substitute $file",
2554                                      "\n";
2555             }
2556         }
2557
2558
2559         # Call any special handler for before the file.
2560         &{$pre_handler{$addr}}($self) if $pre_handler{$addr};
2561
2562         # Then the main handler
2563         &{$handler{$addr}}($self);
2564
2565         # Then any special post-file handler.
2566         &{$post_handler{$addr}}($self) if $post_handler{$addr};
2567
2568         # If any errors have been accumulated, output the counts (as the first
2569         # error message in each class was output when it was encountered).
2570         if ($errors{$addr}) {
2571             my $total = 0;
2572             my $types = 0;
2573             foreach my $error (keys %{$errors{$addr}}) {
2574                 $total += $errors{$addr}->{$error};
2575                 delete $errors{$addr}->{$error};
2576                 $types++;
2577             }
2578             if ($total > 1) {
2579                 my $message
2580                         = "A total of $total lines had errors in $file.  ";
2581
2582                 $message .= ($types == 1)
2583                             ? '(Only the first one was displayed.)'
2584                             : '(Only the first of each type was displayed.)';
2585                 Carp::my_carp($message);
2586             }
2587         }
2588
2589         if (@{$missings{$addr}}) {
2590             Carp::my_carp_bug("Handler for $file didn't look at all the \@missing lines.  Generated tables likely are wrong");
2591         }
2592
2593         # If a real file handle, close it.
2594         close $handle{$addr} or Carp::my_carp("Can't close $file: $!") if
2595                                                         ref $handle{$addr};
2596         $handle{$addr} = "";   # Uses empty to indicate that has already seen
2597                                # the file, as opposed to undef
2598         return;
2599     }
2600
2601     sub _next_line {
2602         # Sets $_ to be the next logical input line, if any.  Returns non-zero
2603         # if such a line exists.  'logical' means that any lines that have
2604         # been added via insert_lines() will be returned in $_ before the file
2605         # is read again.
2606
2607         my $self = shift;
2608         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2609
2610         my $addr = do { no overloading; pack 'J', $self; };
2611
2612         # Here the file is open (or if the handle is not a ref, is an open
2613         # 'virtual' file).  Get the next line; any inserted lines get priority
2614         # over the file itself.
2615         my $adjusted;
2616
2617         LINE:
2618         while (1) { # Loop until find non-comment, non-empty line
2619             #local $to_trace = 1 if main::DEBUG;
2620             my $inserted_ref = shift @{$added_lines{$addr}};
2621             if (defined $inserted_ref) {
2622                 ($adjusted, $_) = @{$inserted_ref};
2623                 trace $adjusted, $_ if main::DEBUG && $to_trace;
2624                 return 1 if $adjusted;
2625             }
2626             else {
2627                 last if ! ref $handle{$addr}; # Don't read unless is real file
2628                 last if ! defined ($_ = readline $handle{$addr});
2629             }
2630             chomp;
2631             trace $_ if main::DEBUG && $to_trace;
2632
2633             # See if this line is the comment line that defines what property
2634             # value that code points that are not listed in the file should
2635             # have.  The format or existence of these lines is not guaranteed
2636             # by Unicode since they are comments, but the documentation says
2637             # that this was added for machine-readability, so probably won't
2638             # change.  This works starting in Unicode Version 5.0.  They look
2639             # like:
2640             #
2641             # @missing: 0000..10FFFF; Not_Reordered
2642             # @missing: 0000..10FFFF; Decomposition_Mapping; <code point>
2643             # @missing: 0000..10FFFF; ; NaN
2644             #
2645             # Save the line for a later get_missings() call.
2646             if (/$missing_defaults_prefix/) {
2647                 if ($has_missings_defaults{$addr} == $NO_DEFAULTS) {
2648                     $self->carp_bad_line("Unexpected \@missing line.  Assuming no missing entries");
2649                 }
2650                 elsif ($has_missings_defaults{$addr} == $NOT_IGNORED) {
2651                     my @defaults = split /\s* ; \s*/x, $_;
2652
2653                     # The first field is the @missing, which ends in a
2654                     # semi-colon, so can safely shift.
2655                     shift @defaults;
2656
2657                     # Some of these lines may have empty field placeholders
2658                     # which get in the way.  An example is:
2659                     # @missing: 0000..10FFFF; ; NaN
2660                     # Remove them.  Process starting from the top so the
2661                     # splice doesn't affect things still to be looked at.
2662                     for (my $i = @defaults - 1; $i >= 0; $i--) {
2663                         next if $defaults[$i] ne "";
2664                         splice @defaults, $i, 1;
2665                     }
2666
2667                     # What's left should be just the property (maybe) and the
2668                     # default.  Having only one element means it doesn't have
2669                     # the property.
2670                     my $default;
2671                     my $property;
2672                     if (@defaults >= 1) {
2673                         if (@defaults == 1) {
2674                             $default = $defaults[0];
2675                         }
2676                         else {
2677                             $property = $defaults[0];
2678                             $default = $defaults[1];
2679                         }
2680                     }
2681
2682                     if (@defaults < 1
2683                         || @defaults > 2
2684                         || ($default =~ /^</
2685                             && $default !~ /^<code *point>$/i
2686                             && $default !~ /^<none>$/i
2687                             && $default !~ /^<script>$/i))
2688                     {
2689                         $self->carp_bad_line("Unrecognized \@missing line: $_.  Assuming no missing entries");
2690                     }
2691                     else {
2692
2693                         # If the property is missing from the line, it should
2694                         # be the one for the whole file
2695                         $property = $property{$addr} if ! defined $property;
2696
2697                         # Change <none> to the null string, which is what it
2698                         # really means.  If the default is the code point
2699                         # itself, set it to <code point>, which is what
2700                         # Unicode uses (but sometimes they've forgotten the
2701                         # space)
2702                         if ($default =~ /^<none>$/i) {
2703                             $default = "";
2704                         }
2705                         elsif ($default =~ /^<code *point>$/i) {
2706                             $default = $CODE_POINT;
2707                         }
2708                         elsif ($default =~ /^<script>$/i) {
2709
2710                             # Special case this one.  Currently is from
2711                             # ScriptExtensions.txt, and means for all unlisted
2712                             # code points, use their Script property values.
2713                             # For the code points not listed in that file, the
2714                             # default value is 'Unknown'.
2715                             $default = "Unknown";
2716                         }
2717
2718                         # Store them as a sub-arrays with both components.
2719                         push @{$missings{$addr}}, [ $default, $property ];
2720                     }
2721                 }
2722
2723                 # There is nothing for the caller to process on this comment
2724                 # line.
2725                 next;
2726             }
2727
2728             # Remove comments and trailing space, and skip this line if the
2729             # result is empty
2730             s/#.*//;
2731             s/\s+$//;
2732             next if /^$/;
2733
2734             # Call any handlers for this line, and skip further processing of
2735             # the line if the handler sets the line to null.
2736             foreach my $sub_ref (@{$each_line_handler{$addr}}) {
2737                 &{$sub_ref}($self);
2738                 next LINE if /^$/;
2739             }
2740
2741             # Here the line is ok.  return success.
2742             return 1;
2743         } # End of looping through lines.
2744
2745         # If there is an EOF handler, call it (only once) and if it generates
2746         # more lines to process go back in the loop to handle them.
2747         if ($eof_handler{$addr}) {
2748             &{$eof_handler{$addr}}($self);
2749             $eof_handler{$addr} = "";   # Currently only get one shot at it.
2750             goto LINE if $added_lines{$addr};
2751         }
2752
2753         # Return failure -- no more lines.
2754         return 0;
2755
2756     }
2757
2758     sub _next_line_with_remapped_range {
2759         my $self = shift;
2760         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2761
2762         # like _next_line(), but for use on non-ASCII platforms.  It sets $_
2763         # to be the next logical input line, if any.  Returns non-zero if such
2764         # a line exists.  'logical' means that any lines that have been added
2765         # via insert_lines() will be returned in $_ before the file is read
2766         # again.
2767         #
2768         # The difference from _next_line() is that this remaps the Unicode
2769         # code points in the input to those of the native platform.  Each
2770         # input line contains a single code point, or a single contiguous
2771         # range of them  This routine splits each range into its individual
2772         # code points and caches them.  It returns the cached values,
2773         # translated into their native equivalents, one at a time, for each
2774         # call, before reading the next line.  Since native values can only be
2775         # a single byte wide, no translation is needed for code points above
2776         # 0xFF, and ranges that are entirely above that number are not split.
2777         # If an input line contains the range 254-1000, it would be split into
2778         # three elements: 254, 255, and 256-1000.  (The downstream table
2779         # insertion code will sort and coalesce the individual code points
2780         # into appropriate ranges.)
2781
2782         my $addr = do { no overloading; pack 'J', $self; };
2783
2784         while (1) {
2785
2786             # Look in cache before reading the next line.  Return any cached
2787             # value, translated
2788             my $inserted = shift @{$remapped_lines{$addr}};
2789             if (defined $inserted) {
2790                 trace $inserted if main::DEBUG && $to_trace;
2791                 $_ = $inserted =~ s/^ ( \d+ ) /sprintf("%04X", utf8::unicode_to_native($1))/xer;
2792                 trace $_ if main::DEBUG && $to_trace;
2793                 return 1;
2794             }
2795
2796             # Get the next line.
2797             return 0 unless _next_line($self);
2798
2799             # If there is a special handler for it, return the line,
2800             # untranslated.  This should happen only for files that are
2801             # special, not being code-point related, such as property names.
2802             return 1 if $handler{$addr}
2803                                     != \&main::process_generic_property_file;
2804
2805             my ($range, $property_name, $map, @remainder)
2806                 = split /\s*;\s*/, $_, -1; # -1 => retain trailing null fields
2807
2808             if (@remainder
2809                 || ! defined $property_name
2810                 || $range !~ /^ ($code_point_re) (?:\.\. ($code_point_re) )? $/x)
2811             {
2812                 Carp::my_carp_bug("Unrecognized input line '$_'.  Ignored");
2813             }
2814
2815             my $low = hex $1;
2816             my $high = (defined $2) ? hex $2 : $low;
2817
2818             # If the input maps the range to another code point, remap the
2819             # target if it is between 0 and 255.
2820             my $tail;
2821             if (defined $map) {
2822                 $map =~ s/\b 00 ( [0-9A-F]{2} ) \b/sprintf("%04X", utf8::unicode_to_native(hex $1))/gxe;
2823                 $tail = "$property_name; $map";
2824                 $_ = "$range; $tail";
2825             }
2826             else {
2827                 $tail = $property_name;
2828             }
2829
2830             # If entire range is above 255, just return it, unchanged (except
2831             # any mapped-to code point, already changed above)
2832             return 1 if $low > 255;
2833
2834             # Cache an entry for every code point < 255.  For those in the
2835             # range above 255, return a dummy entry for just that portion of
2836             # the range.  Note that this will be out-of-order, but that is not
2837             # a problem.
2838             foreach my $code_point ($low .. $high) {
2839                 if ($code_point > 255) {
2840                     $_ = sprintf "%04X..%04X; $tail", $code_point, $high;
2841                     return 1;
2842                 }
2843                 push @{$remapped_lines{$addr}}, "$code_point; $tail";
2844             }
2845         } # End of looping through lines.
2846
2847         # NOTREACHED
2848     }
2849
2850 #   Not currently used, not fully tested.
2851 #    sub peek {
2852 #        # Non-destructive look-ahead one non-adjusted, non-comment, non-blank
2853 #        # record.  Not callable from an each_line_handler(), nor does it call
2854 #        # an each_line_handler() on the line.
2855 #
2856 #        my $self = shift;
2857 #        my $addr = do { no overloading; pack 'J', $self; };
2858 #
2859 #        foreach my $inserted_ref (@{$added_lines{$addr}}) {
2860 #            my ($adjusted, $line) = @{$inserted_ref};
2861 #            next if $adjusted;
2862 #
2863 #            # Remove comments and trailing space, and return a non-empty
2864 #            # resulting line
2865 #            $line =~ s/#.*//;
2866 #            $line =~ s/\s+$//;
2867 #            return $line if $line ne "";
2868 #        }
2869 #
2870 #        return if ! ref $handle{$addr}; # Don't read unless is real file
2871 #        while (1) { # Loop until find non-comment, non-empty line
2872 #            local $to_trace = 1 if main::DEBUG;
2873 #            trace $_ if main::DEBUG && $to_trace;
2874 #            return if ! defined (my $line = readline $handle{$addr});
2875 #            chomp $line;
2876 #            push @{$added_lines{$addr}}, [ 0, $line ];
2877 #
2878 #            $line =~ s/#.*//;
2879 #            $line =~ s/\s+$//;
2880 #            return $line if $line ne "";
2881 #        }
2882 #
2883 #        return;
2884 #    }
2885
2886
2887     sub insert_lines {
2888         # Lines can be inserted so that it looks like they were in the input
2889         # file at the place it was when this routine is called.  See also
2890         # insert_adjusted_lines().  Lines inserted via this routine go through
2891         # any each_line_handler()
2892
2893         my $self = shift;
2894
2895         # Each inserted line is an array, with the first element being 0 to
2896         # indicate that this line hasn't been adjusted, and needs to be
2897         # processed.
2898         no overloading;
2899         push @{$added_lines{pack 'J', $self}}, map { [ 0, $_ ] } @_;
2900         return;
2901     }
2902
2903     sub insert_adjusted_lines {
2904         # Lines can be inserted so that it looks like they were in the input
2905         # file at the place it was when this routine is called.  See also
2906         # insert_lines().  Lines inserted via this routine are already fully
2907         # adjusted, ready to be processed; each_line_handler()s handlers will
2908         # not be called.  This means this is not a completely general
2909         # facility, as only the last each_line_handler on the stack should
2910         # call this.  It could be made more general, by passing to each of the
2911         # line_handlers their position on the stack, which they would pass on
2912         # to this routine, and that would replace the boolean first element in
2913         # the anonymous array pushed here, so that the next_line routine could
2914         # use that to call only those handlers whose index is after it on the
2915         # stack.  But this is overkill for what is needed now.
2916
2917         my $self = shift;
2918         trace $_[0] if main::DEBUG && $to_trace;
2919
2920         # Each inserted line is an array, with the first element being 1 to
2921         # indicate that this line has been adjusted
2922         no overloading;
2923         push @{$added_lines{pack 'J', $self}}, map { [ 1, $_ ] } @_;
2924         return;
2925     }
2926
2927     sub get_missings {
2928         # Returns the stored up @missings lines' values, and clears the list.
2929         # The values are in an array, consisting of the default in the first
2930         # element, and the property in the 2nd.  However, since these lines
2931         # can be stacked up, the return is an array of all these arrays.
2932
2933         my $self = shift;
2934         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2935
2936         my $addr = do { no overloading; pack 'J', $self; };
2937
2938         # If not accepting a list return, just return the first one.
2939         return shift @{$missings{$addr}} unless wantarray;
2940
2941         my @return = @{$missings{$addr}};
2942         undef @{$missings{$addr}};
2943         return @return;
2944     }
2945
2946     sub _insert_property_into_line {
2947         # Add a property field to $_, if this file requires it.
2948
2949         my $self = shift;
2950         my $addr = do { no overloading; pack 'J', $self; };
2951         my $property = $property{$addr};
2952         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2953
2954         $_ =~ s/(;|$)/; $property$1/;
2955         return;
2956     }
2957
2958     sub carp_bad_line {
2959         # Output consistent error messages, using either a generic one, or the
2960         # one given by the optional parameter.  To avoid gazillions of the
2961         # same message in case the syntax of a  file is way off, this routine
2962         # only outputs the first instance of each message, incrementing a
2963         # count so the totals can be output at the end of the file.
2964
2965         my $self = shift;
2966         my $message = shift;
2967         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2968
2969         my $addr = do { no overloading; pack 'J', $self; };
2970
2971         $message = 'Unexpected line' unless $message;
2972
2973         # No trailing punctuation so as to fit with our addenda.
2974         $message =~ s/[.:;,]$//;
2975
2976         # If haven't seen this exact message before, output it now.  Otherwise
2977         # increment the count of how many times it has occurred
2978         unless ($errors{$addr}->{$message}) {
2979             Carp::my_carp("$message in '$_' in "
2980                             . $file{$addr}
2981                             . " at line $..  Skipping this line;");
2982             $errors{$addr}->{$message} = 1;
2983         }
2984         else {
2985             $errors{$addr}->{$message}++;
2986         }
2987
2988         # Clear the line to prevent any further (meaningful) processing of it.
2989         $_ = "";
2990
2991         return;
2992     }
2993 } # End closure
2994
2995 package Multi_Default;
2996
2997 # Certain properties in early versions of Unicode had more than one possible
2998 # default for code points missing from the files.  In these cases, one
2999 # default applies to everything left over after all the others are applied,
3000 # and for each of the others, there is a description of which class of code
3001 # points applies to it.  This object helps implement this by storing the
3002 # defaults, and for all but that final default, an eval string that generates
3003 # the class that it applies to.
3004
3005
3006 {   # Closure
3007
3008     main::setup_package();
3009
3010     my %class_defaults;
3011     # The defaults structure for the classes
3012     main::set_access('class_defaults', \%class_defaults);
3013
3014     my %other_default;
3015     # The default that applies to everything left over.
3016     main::set_access('other_default', \%other_default, 'r');
3017
3018
3019     sub new {
3020         # The constructor is called with default => eval pairs, terminated by
3021         # the left-over default. e.g.
3022         # Multi_Default->new(
3023         #        'T' => '$gc->table("Mn") + $gc->table("Cf") - 0x200C
3024         #               -  0x200D',
3025         #        'R' => 'some other expression that evaluates to code points',
3026         #        .
3027         #        .
3028         #        .
3029         #        'U'));
3030
3031         my $class = shift;
3032
3033         my $self = bless \do{my $anonymous_scalar}, $class;
3034         my $addr = do { no overloading; pack 'J', $self; };
3035
3036         while (@_ > 1) {
3037             my $default = shift;
3038             my $eval = shift;
3039             $class_defaults{$addr}->{$default} = $eval;
3040         }
3041
3042         $other_default{$addr} = shift;
3043
3044         return $self;
3045     }
3046
3047     sub get_next_defaults {
3048         # Iterates and returns the next class of defaults.
3049         my $self = shift;
3050         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3051
3052         my $addr = do { no overloading; pack 'J', $self; };
3053
3054         return each %{$class_defaults{$addr}};
3055     }
3056 }
3057
3058 package Alias;
3059
3060 # An alias is one of the names that a table goes by.  This class defines them
3061 # including some attributes.  Everything is currently setup in the
3062 # constructor.
3063
3064
3065 {   # Closure
3066
3067     main::setup_package();
3068
3069     my %name;
3070     main::set_access('name', \%name, 'r');
3071
3072     my %loose_match;
3073     # Should this name match loosely or not.
3074     main::set_access('loose_match', \%loose_match, 'r');
3075
3076     my %make_re_pod_entry;
3077     # Some aliases should not get their own entries in the re section of the
3078     # pod, because they are covered by a wild-card, and some we want to
3079     # discourage use of.  Binary
3080     main::set_access('make_re_pod_entry', \%make_re_pod_entry, 'r', 's');
3081
3082     my %ucd;
3083     # Is this documented to be accessible via Unicode::UCD
3084     main::set_access('ucd', \%ucd, 'r', 's');
3085
3086     my %status;
3087     # Aliases have a status, like deprecated, or even suppressed (which means
3088     # they don't appear in documentation).  Enum
3089     main::set_access('status', \%status, 'r');
3090
3091     my %ok_as_filename;
3092     # Similarly, some aliases should not be considered as usable ones for
3093     # external use, such as file names, or we don't want documentation to
3094     # recommend them.  Boolean
3095     main::set_access('ok_as_filename', \%ok_as_filename, 'r');
3096
3097     sub new {
3098         my $class = shift;
3099
3100         my $self = bless \do { my $anonymous_scalar }, $class;
3101         my $addr = do { no overloading; pack 'J', $self; };
3102
3103         $name{$addr} = shift;
3104         $loose_match{$addr} = shift;
3105         $make_re_pod_entry{$addr} = shift;
3106         $ok_as_filename{$addr} = shift;
3107         $status{$addr} = shift;
3108         $ucd{$addr} = shift;
3109
3110         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3111
3112         # Null names are never ok externally
3113         $ok_as_filename{$addr} = 0 if $name{$addr} eq "";
3114
3115         return $self;
3116     }
3117 }
3118
3119 package Range;
3120
3121 # A range is the basic unit for storing code points, and is described in the
3122 # comments at the beginning of the program.  Each range has a starting code
3123 # point; an ending code point (not less than the starting one); a value
3124 # that applies to every code point in between the two end-points, inclusive;
3125 # and an enum type that applies to the value.  The type is for the user's
3126 # convenience, and has no meaning here, except that a non-zero type is
3127 # considered to not obey the normal Unicode rules for having standard forms.
3128 #
3129 # The same structure is used for both map and match tables, even though in the
3130 # latter, the value (and hence type) is irrelevant and could be used as a
3131 # comment.  In map tables, the value is what all the code points in the range
3132 # map to.  Type 0 values have the standardized version of the value stored as
3133 # well, so as to not have to recalculate it a lot.
3134
3135 sub trace { return main::trace(@_); }
3136
3137 {   # Closure
3138
3139     main::setup_package();
3140
3141     my %start;
3142     main::set_access('start', \%start, 'r', 's');
3143
3144     my %end;
3145     main::set_access('end', \%end, 'r', 's');
3146
3147     my %value;
3148     main::set_access('value', \%value, 'r');
3149
3150     my %type;
3151     main::set_access('type', \%type, 'r');
3152
3153     my %standard_form;
3154     # The value in internal standard form.  Defined only if the type is 0.
3155     main::set_access('standard_form', \%standard_form);
3156
3157     # Note that if these fields change, the dump() method should as well
3158
3159     sub new {
3160         return Carp::carp_too_few_args(\@_, 3) if main::DEBUG && @_ < 3;
3161         my $class = shift;
3162
3163         my $self = bless \do { my $anonymous_scalar }, $class;
3164         my $addr = do { no overloading; pack 'J', $self; };
3165
3166         $start{$addr} = shift;
3167         $end{$addr} = shift;
3168
3169         my %args = @_;
3170
3171         my $value = delete $args{'Value'};  # Can be 0
3172         $value = "" unless defined $value;
3173         $value{$addr} = $value;
3174
3175         $type{$addr} = delete $args{'Type'} || 0;
3176
3177         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3178
3179         return $self;
3180     }
3181
3182     use overload
3183         fallback => 0,
3184         qw("") => "_operator_stringify",
3185         "." => \&main::_operator_dot,
3186         ".=" => \&main::_operator_dot_equal,
3187     ;
3188
3189     sub _operator_stringify {
3190         my $self = shift;
3191         my $addr = do { no overloading; pack 'J', $self; };
3192
3193         # Output it like '0041..0065 (value)'
3194         my $return = sprintf("%04X", $start{$addr})
3195                         .  '..'
3196                         . sprintf("%04X", $end{$addr});
3197         my $value = $value{$addr};
3198         my $type = $type{$addr};
3199         $return .= ' (';
3200         $return .= "$value";
3201         $return .= ", Type=$type" if $type != 0;
3202         $return .= ')';
3203
3204         return $return;
3205     }
3206
3207     sub standard_form {
3208         # Calculate the standard form only if needed, and cache the result.
3209         # The standard form is the value itself if the type is special.
3210         # This represents a considerable CPU and memory saving - at the time
3211         # of writing there are 368676 non-special objects, but the standard
3212         # form is only requested for 22047 of them - ie about 6%.
3213
3214         my $self = shift;
3215         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3216
3217         my $addr = do { no overloading; pack 'J', $self; };
3218
3219         return $standard_form{$addr} if defined $standard_form{$addr};
3220
3221         my $value = $value{$addr};
3222         return $value if $type{$addr};
3223         return $standard_form{$addr} = main::standardize($value);
3224     }
3225
3226     sub dump {
3227         # Human, not machine readable.  For machine readable, comment out this
3228         # entire routine and let the standard one take effect.
3229         my $self = shift;
3230         my $indent = shift;
3231         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3232
3233         my $addr = do { no overloading; pack 'J', $self; };
3234
3235         my $return = $indent
3236                     . sprintf("%04X", $start{$addr})
3237                     . '..'
3238                     . sprintf("%04X", $end{$addr})
3239                     . " '$value{$addr}';";
3240         if (! defined $standard_form{$addr}) {
3241             $return .= "(type=$type{$addr})";
3242         }
3243         elsif ($standard_form{$addr} ne $value{$addr}) {
3244             $return .= "(standard '$standard_form{$addr}')";
3245         }
3246         return $return;
3247     }
3248 } # End closure
3249
3250 package _Range_List_Base;
3251
3252 # Base class for range lists.  A range list is simply an ordered list of
3253 # ranges, so that the ranges with the lowest starting numbers are first in it.
3254 #
3255 # When a new range is added that is adjacent to an existing range that has the
3256 # same value and type, it merges with it to form a larger range.
3257 #
3258 # Ranges generally do not overlap, except that there can be multiple entries
3259 # of single code point ranges.  This is because of NameAliases.txt.
3260 #
3261 # In this program, there is a standard value such that if two different
3262 # values, have the same standard value, they are considered equivalent.  This
3263 # value was chosen so that it gives correct results on Unicode data
3264
3265 # There are a number of methods to manipulate range lists, and some operators
3266 # are overloaded to handle them.
3267
3268 sub trace { return main::trace(@_); }
3269
3270 { # Closure
3271
3272     our $addr;
3273
3274     # Max is initialized to a negative value that isn't adjacent to 0, for
3275     # simpler tests
3276     my $max_init = -2;
3277
3278     main::setup_package();
3279
3280     my %ranges;
3281     # The list of ranges
3282     main::set_access('ranges', \%ranges, 'readable_array');
3283
3284     my %max;
3285     # The highest code point in the list.  This was originally a method, but
3286     # actual measurements said it was used a lot.
3287     main::set_access('max', \%max, 'r');
3288
3289     my %each_range_iterator;
3290     # Iterator position for each_range()
3291     main::set_access('each_range_iterator', \%each_range_iterator);
3292
3293     my %owner_name_of;
3294     # Name of parent this is attached to, if any.  Solely for better error
3295     # messages.
3296     main::set_access('owner_name_of', \%owner_name_of, 'p_r');
3297
3298     my %_search_ranges_cache;
3299     # A cache of the previous result from _search_ranges(), for better
3300     # performance
3301     main::set_access('_search_ranges_cache', \%_search_ranges_cache);
3302
3303     sub new {
3304         my $class = shift;
3305         my %args = @_;
3306
3307         # Optional initialization data for the range list.
3308         my $initialize = delete $args{'Initialize'};
3309
3310         my $self;
3311
3312         # Use _union() to initialize.  _union() returns an object of this
3313         # class, which means that it will call this constructor recursively.
3314         # But it won't have this $initialize parameter so that it won't
3315         # infinitely loop on this.
3316         return _union($class, $initialize, %args) if defined $initialize;
3317
3318         $self = bless \do { my $anonymous_scalar }, $class;
3319         my $addr = do { no overloading; pack 'J', $self; };
3320
3321         # Optional parent object, only for debug info.
3322         $owner_name_of{$addr} = delete $args{'Owner'};
3323         $owner_name_of{$addr} = "" if ! defined $owner_name_of{$addr};
3324
3325         # Stringify, in case it is an object.
3326         $owner_name_of{$addr} = "$owner_name_of{$addr}";
3327
3328         # This is used only for error messages, and so a colon is added
3329         $owner_name_of{$addr} .= ": " if $owner_name_of{$addr} ne "";
3330
3331         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3332
3333         $max{$addr} = $max_init;
3334
3335         $_search_ranges_cache{$addr} = 0;
3336         $ranges{$addr} = [];
3337
3338         return $self;
3339     }
3340
3341     use overload
3342         fallback => 0,
3343         qw("") => "_operator_stringify",
3344         "." => \&main::_operator_dot,
3345         ".=" => \&main::_operator_dot_equal,
3346     ;
3347
3348     sub _operator_stringify {
3349         my $self = shift;
3350         my $addr = do { no overloading; pack 'J', $self; };
3351
3352         return "Range_List attached to '$owner_name_of{$addr}'"
3353                                                 if $owner_name_of{$addr};
3354         return "anonymous Range_List " . \$self;
3355     }
3356
3357     sub _union {
3358         # Returns the union of the input code points.  It can be called as
3359         # either a constructor or a method.  If called as a method, the result
3360         # will be a new() instance of the calling object, containing the union
3361         # of that object with the other parameter's code points;  if called as
3362         # a constructor, the first parameter gives the class that the new object
3363         # should be, and the second parameter gives the code points to go into
3364         # it.
3365         # In either case, there are two parameters looked at by this routine;
3366         # any additional parameters are passed to the new() constructor.
3367         #
3368         # The code points can come in the form of some object that contains
3369         # ranges, and has a conventionally named method to access them; or
3370         # they can be an array of individual code points (as integers); or
3371         # just a single code point.
3372         #
3373         # If they are ranges, this routine doesn't make any effort to preserve
3374         # the range values and types of one input over the other.  Therefore
3375         # this base class should not allow _union to be called from other than
3376         # initialization code, so as to prevent two tables from being added
3377         # together where the range values matter.  The general form of this
3378         # routine therefore belongs in a derived class, but it was moved here
3379         # to avoid duplication of code.  The failure to overload this in this
3380         # class keeps it safe.
3381         #
3382         # It does make the effort during initialization to accept tables with
3383         # multiple values for the same code point, and to preserve the order
3384         # of these.  If there is only one input range or range set, it doesn't
3385         # sort (as it should already be sorted to the desired order), and will
3386         # accept multiple values per code point.  Otherwise it will merge
3387         # multiple values into a single one.
3388
3389         my $self;
3390         my @args;   # Arguments to pass to the constructor
3391
3392         my $class = shift;
3393
3394         # If a method call, will start the union with the object itself, and
3395         # the class of the new object will be the same as self.
3396         if (ref $class) {
3397             $self = $class;
3398             $class = ref $self;
3399             push @args, $self;
3400         }
3401
3402         # Add the other required parameter.
3403         push @args, shift;
3404         # Rest of parameters are passed on to the constructor
3405
3406         # Accumulate all records from both lists.
3407         my @records;
3408         my $input_count = 0;
3409         for my $arg (@args) {
3410             #local $to_trace = 0 if main::DEBUG;
3411             trace "argument = $arg" if main::DEBUG && $to_trace;
3412             if (! defined $arg) {
3413                 my $message = "";
3414                 if (defined $self) {
3415                     no overloading;
3416                     $message .= $owner_name_of{pack 'J', $self};
3417                 }
3418                 Carp::my_carp_bug($message . "Undefined argument to _union.  No union done.");
3419                 return;
3420             }
3421
3422             $arg = [ $arg ] if ! ref $arg;
3423             my $type = ref $arg;
3424             if ($type eq 'ARRAY') {
3425                 foreach my $element (@$arg) {
3426                     push @records, Range->new($element, $element);
3427                     $input_count++;
3428                 }
3429             }
3430             elsif ($arg->isa('Range')) {
3431                 push @records, $arg;
3432                 $input_count++;
3433             }
3434             elsif ($arg->can('ranges')) {
3435                 push @records, $arg->ranges;
3436                 $input_count++;
3437             }
3438             else {
3439                 my $message = "";
3440                 if (defined $self) {
3441                     no overloading;
3442                     $message .= $owner_name_of{pack 'J', $self};
3443                 }
3444                 Carp::my_carp_bug($message . "Cannot take the union of a $type.  No union done.");
3445                 return;
3446             }
3447         }
3448
3449         # Sort with the range containing the lowest ordinal first, but if
3450         # two ranges start at the same code point, sort with the bigger range
3451         # of the two first, because it takes fewer cycles.
3452         if ($input_count > 1) {
3453             @records = sort { ($a->start <=> $b->start)
3454                                       or
3455                                     # if b is shorter than a, b->end will be
3456                                     # less than a->end, and we want to select
3457                                     # a, so want to return -1
3458                                     ($b->end <=> $a->end)
3459                                    } @records;
3460         }
3461
3462         my $new = $class->new(@_);
3463
3464         # Fold in records so long as they add new information.
3465         for my $set (@records) {
3466             my $start = $set->start;
3467             my $end   = $set->end;
3468             my $value = $set->value;
3469             my $type  = $set->type;
3470             if ($start > $new->max) {
3471                 $new->_add_delete('+', $start, $end, $value, Type => $type);
3472             }
3473             elsif ($end > $new->max) {
3474                 $new->_add_delete('+', $new->max +1, $end, $value,
3475                                                                 Type => $type);
3476             }
3477             elsif ($input_count == 1) {
3478                 # Here, overlaps existing range, but is from a single input,
3479                 # so preserve the multiple values from that input.
3480                 $new->_add_delete('+', $start, $end, $value, Type => $type,
3481                                                 Replace => $MULTIPLE_AFTER);
3482             }
3483         }
3484
3485         return $new;
3486     }
3487
3488     sub range_count {        # Return the number of ranges in the range list
3489         my $self = shift;
3490         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3491
3492         no overloading;
3493         return scalar @{$ranges{pack 'J', $self}};
3494     }
3495
3496     sub min {
3497         # Returns the minimum code point currently in the range list, or if
3498         # the range list is empty, 2 beyond the max possible.  This is a
3499         # method because used so rarely, that not worth saving between calls,
3500         # and having to worry about changing it as ranges are added and
3501         # deleted.
3502
3503         my $self = shift;
3504         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3505
3506         my $addr = do { no overloading; pack 'J', $self; };
3507
3508         # If the range list is empty, return a large value that isn't adjacent
3509         # to any that could be in the range list, for simpler tests
3510         return $MAX_WORKING_CODEPOINT + 2 unless scalar @{$ranges{$addr}};
3511         return $ranges{$addr}->[0]->start;
3512     }
3513
3514     sub contains {
3515         # Boolean: Is argument in the range list?  If so returns $i such that:
3516         #   range[$i]->end < $codepoint <= range[$i+1]->end
3517         # which is one beyond what you want; this is so that the 0th range
3518         # doesn't return false
3519         my $self = shift;
3520         my $codepoint = shift;
3521         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3522
3523         my $i = $self->_search_ranges($codepoint);
3524         return 0 unless defined $i;
3525
3526         # The search returns $i, such that
3527         #   range[$i-1]->end < $codepoint <= range[$i]->end
3528         # So is in the table if and only iff it is at least the start position
3529         # of range $i.
3530         no overloading;
3531         return 0 if $ranges{pack 'J', $self}->[$i]->start > $codepoint;
3532         return $i + 1;
3533     }
3534
3535     sub containing_range {
3536         # Returns the range object that contains the code point, undef if none
3537
3538         my $self = shift;
3539         my $codepoint = shift;
3540         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3541
3542         my $i = $self->contains($codepoint);
3543         return unless $i;
3544
3545         # contains() returns 1 beyond where we should look
3546         no overloading;
3547         return $ranges{pack 'J', $self}->[$i-1];
3548     }
3549
3550     sub value_of {
3551         # Returns the value associated with the code point, undef if none
3552
3553         my $self = shift;
3554         my $codepoint = shift;
3555         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3556
3557         my $range = $self->containing_range($codepoint);
3558         return unless defined $range;
3559
3560         return $range->value;
3561     }
3562
3563     sub type_of {
3564         # Returns the type of the range containing the code point, undef if
3565         # the code point is not in the table
3566
3567         my $self = shift;
3568         my $codepoint = shift;
3569         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3570
3571         my $range = $self->containing_range($codepoint);
3572         return unless defined $range;
3573
3574         return $range->type;
3575     }
3576
3577     sub _search_ranges {
3578         # Find the range in the list which contains a code point, or where it
3579         # should go if were to add it.  That is, it returns $i, such that:
3580         #   range[$i-1]->end < $codepoint <= range[$i]->end
3581         # Returns undef if no such $i is possible (e.g. at end of table), or
3582         # if there is an error.
3583
3584         my $self = shift;
3585         my $code_point = shift;
3586         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3587
3588         my $addr = do { no overloading; pack 'J', $self; };
3589
3590         return if $code_point > $max{$addr};
3591         my $r = $ranges{$addr};                # The current list of ranges
3592         my $range_list_size = scalar @$r;
3593         my $i;
3594
3595         use integer;        # want integer division
3596
3597         # Use the cached result as the starting guess for this one, because,
3598         # an experiment on 5.1 showed that 90% of the time the cache was the
3599         # same as the result on the next call (and 7% it was one less).
3600         $i = $_search_ranges_cache{$addr};
3601         $i = 0 if $i >= $range_list_size;   # Reset if no longer valid (prob.
3602                                             # from an intervening deletion
3603         #local $to_trace = 1 if main::DEBUG;
3604         trace "previous \$i is still valid: $i" if main::DEBUG && $to_trace && $code_point <= $r->[$i]->end && ($i == 0 || $r->[$i-1]->end < $code_point);
3605         return $i if $code_point <= $r->[$i]->end
3606                      && ($i == 0 || $r->[$i-1]->end < $code_point);
3607
3608         # Here the cache doesn't yield the correct $i.  Try adding 1.
3609         if ($i < $range_list_size - 1
3610             && $r->[$i]->end < $code_point &&
3611             $code_point <= $r->[$i+1]->end)
3612         {
3613             $i++;
3614             trace "next \$i is correct: $i" if main::DEBUG && $to_trace;
3615             $_search_ranges_cache{$addr} = $i;
3616             return $i;
3617         }
3618
3619         # Here, adding 1 also didn't work.  We do a binary search to
3620         # find the correct position, starting with current $i
3621         my $lower = 0;
3622         my $upper = $range_list_size - 1;
3623         while (1) {
3624             trace "top of loop i=$i:", sprintf("%04X", $r->[$lower]->start), "[$lower] .. ", sprintf("%04X", $r->[$i]->start), "[$i] .. ", sprintf("%04X", $r->[$upper]->start), "[$upper]" if main::DEBUG && $to_trace;
3625
3626             if ($code_point <= $r->[$i]->end) {
3627
3628                 # Here we have met the upper constraint.  We can quit if we
3629                 # also meet the lower one.
3630                 last if $i == 0 || $r->[$i-1]->end < $code_point;
3631
3632                 $upper = $i;        # Still too high.
3633
3634             }
3635             else {
3636
3637                 # Here, $r[$i]->end < $code_point, so look higher up.
3638                 $lower = $i;
3639             }
3640
3641             # Split search domain in half to try again.
3642             my $temp = ($upper + $lower) / 2;
3643
3644             # No point in continuing unless $i changes for next time
3645             # in the loop.
3646             if ($temp == $i) {
3647
3648                 # We can't reach the highest element because of the averaging.
3649                 # So if one below the upper edge, force it there and try one
3650                 # more time.
3651                 if ($i == $range_list_size - 2) {
3652
3653                     trace "Forcing to upper edge" if main::DEBUG && $to_trace;
3654                     $i = $range_list_size - 1;
3655
3656                     # Change $lower as well so if fails next time through,
3657                     # taking the average will yield the same $i, and we will
3658                     # quit with the error message just below.
3659                     $lower = $i;
3660                     next;
3661                 }
3662                 Carp::my_carp_bug("$owner_name_of{$addr}Can't find where the range ought to go.  No action taken.");
3663                 return;
3664             }
3665             $i = $temp;
3666         } # End of while loop
3667
3668         if (main::DEBUG && $to_trace) {
3669             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i;
3670             trace "i=  [ $i ]", $r->[$i];
3671             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < $range_list_size - 1;
3672         }
3673
3674         # Here we have found the offset.  Cache it as a starting point for the
3675         # next call.
3676         $_search_ranges_cache{$addr} = $i;
3677         return $i;
3678     }
3679
3680     sub _add_delete {
3681         # Add, replace or delete ranges to or from a list.  The $type
3682         # parameter gives which:
3683         #   '+' => insert or replace a range, returning a list of any changed
3684         #          ranges.
3685         #   '-' => delete a range, returning a list of any deleted ranges.
3686         #
3687         # The next three parameters give respectively the start, end, and
3688         # value associated with the range.  'value' should be null unless the
3689         # operation is '+';
3690         #
3691         # The range list is kept sorted so that the range with the lowest
3692         # starting position is first in the list, and generally, adjacent
3693         # ranges with the same values are merged into a single larger one (see
3694         # exceptions below).
3695         #
3696         # There are more parameters; all are key => value pairs:
3697         #   Type    gives the type of the value.  It is only valid for '+'.
3698         #           All ranges have types; if this parameter is omitted, 0 is
3699         #           assumed.  Ranges with type 0 are assumed to obey the
3700         #           Unicode rules for casing, etc; ranges with other types are
3701         #           not.  Otherwise, the type is arbitrary, for the caller's
3702         #           convenience, and looked at only by this routine to keep
3703         #           adjacent ranges of different types from being merged into
3704         #           a single larger range, and when Replace =>
3705         #           $IF_NOT_EQUIVALENT is specified (see just below).
3706         #   Replace  determines what to do if the range list already contains
3707         #            ranges which coincide with all or portions of the input
3708         #            range.  It is only valid for '+':
3709         #       => $NO            means that the new value is not to replace
3710         #                         any existing ones, but any empty gaps of the
3711         #                         range list coinciding with the input range
3712         #                         will be filled in with the new value.
3713         #       => $UNCONDITIONALLY  means to replace the existing values with
3714         #                         this one unconditionally.  However, if the
3715         #                         new and old values are identical, the
3716         #                         replacement is skipped to save cycles
3717         #       => $IF_NOT_EQUIVALENT means to replace the existing values
3718         #          (the default)  with this one if they are not equivalent.
3719         #                         Ranges are equivalent if their types are the
3720         #                         same, and they are the same string; or if
3721         #                         both are type 0 ranges, if their Unicode
3722         #                         standard forms are identical.  In this last
3723         #                         case, the routine chooses the more "modern"
3724         #                         one to use.  This is because some of the
3725         #                         older files are formatted with values that
3726         #                         are, for example, ALL CAPs, whereas the
3727         #                         derived files have a more modern style,
3728         #                         which looks better.  By looking for this
3729         #                         style when the pre-existing and replacement
3730         #                         standard forms are the same, we can move to
3731         #                         the modern style
3732         #       => $MULTIPLE_BEFORE means that if this range duplicates an
3733         #                         existing one, but has a different value,
3734         #                         don't replace the existing one, but insert
3735         #                         this, one so that the same range can occur
3736         #                         multiple times.  They are stored LIFO, so
3737         #                         that the final one inserted is the first one
3738         #                         returned in an ordered search of the table.
3739         #                         If this is an exact duplicate, including the
3740         #                         value, the original will be moved to be
3741         #                         first, before any other duplicate ranges
3742         #                         with different values.
3743         #       => $MULTIPLE_AFTER is like $MULTIPLE_BEFORE, but is stored
3744         #                         FIFO, so that this one is inserted after all
3745         #                         others that currently exist.  If this is an
3746         #                         exact duplicate, including value, of an
3747         #                         existing range, this one is discarded
3748         #                         (leaving the existing one in its original,
3749         #                         higher priority position
3750         #       => anything else  is the same as => $IF_NOT_EQUIVALENT
3751         #
3752         # "same value" means identical for non-type-0 ranges, and it means
3753         # having the same standard forms for type-0 ranges.
3754
3755         return Carp::carp_too_few_args(\@_, 5) if main::DEBUG && @_ < 5;
3756
3757         my $self = shift;
3758         my $operation = shift;   # '+' for add/replace; '-' for delete;
3759         my $start = shift;
3760         my $end   = shift;
3761         my $value = shift;
3762
3763         my %args = @_;
3764
3765         $value = "" if not defined $value;        # warning: $value can be "0"
3766
3767         my $replace = delete $args{'Replace'};
3768         $replace = $IF_NOT_EQUIVALENT unless defined $replace;
3769
3770         my $type = delete $args{'Type'};
3771         $type = 0 unless defined $type;
3772
3773         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3774
3775         my $addr = do { no overloading; pack 'J', $self; };
3776
3777         if ($operation ne '+' && $operation ne '-') {
3778             Carp::my_carp_bug("$owner_name_of{$addr}First parameter to _add_delete must be '+' or '-'.  No action taken.");
3779             return;
3780         }
3781         unless (defined $start && defined $end) {
3782             Carp::my_carp_bug("$owner_name_of{$addr}Undefined start and/or end to _add_delete.  No action taken.");
3783             return;
3784         }
3785         unless ($end >= $start) {
3786             Carp::my_carp_bug("$owner_name_of{$addr}End of range (" . sprintf("%04X", $end) . ") must not be before start (" . sprintf("%04X", $start) . ").  No action taken.");
3787             return;
3788         }
3789         #local $to_trace = 1 if main::DEBUG;
3790
3791         if ($operation eq '-') {
3792             if ($replace != $IF_NOT_EQUIVALENT) {
3793                 Carp::my_carp_bug("$owner_name_of{$addr}Replace => \$IF_NOT_EQUIVALENT is required when deleting a range from a range list.  Assuming Replace => \$IF_NOT_EQUIVALENT.");
3794                 $replace = $IF_NOT_EQUIVALENT;
3795             }
3796             if ($type) {
3797                 Carp::my_carp_bug("$owner_name_of{$addr}Type => 0 is required when deleting a range from a range list.  Assuming Type => 0.");
3798                 $type = 0;
3799             }
3800             if ($value ne "") {
3801                 Carp::my_carp_bug("$owner_name_of{$addr}Value => \"\" is required when deleting a range from a range list.  Assuming Value => \"\".");
3802                 $value = "";
3803             }
3804         }
3805
3806         my $r = $ranges{$addr};               # The current list of ranges
3807         my $range_list_size = scalar @$r;     # And its size
3808         my $max = $max{$addr};                # The current high code point in
3809                                               # the list of ranges
3810
3811         # Do a special case requiring fewer machine cycles when the new range
3812         # starts after the current highest point.  The Unicode input data is
3813         # structured so this is common.
3814         if ($start > $max) {
3815
3816             trace "$owner_name_of{$addr} $operation", sprintf("%04X..%04X (%s) type=%d; prev max=%04X", $start, $end, $value, $type, $max) if main::DEBUG && $to_trace;
3817             return if $operation eq '-'; # Deleting a non-existing range is a
3818                                          # no-op
3819
3820             # If the new range doesn't logically extend the current final one
3821             # in the range list, create a new range at the end of the range
3822             # list.  (max cleverly is initialized to a negative number not
3823             # adjacent to 0 if the range list is empty, so even adding a range
3824             # to an empty range list starting at 0 will have this 'if'
3825             # succeed.)
3826             if ($start > $max + 1        # non-adjacent means can't extend.
3827                 || @{$r}[-1]->value ne $value # values differ, can't extend.
3828                 || @{$r}[-1]->type != $type # types differ, can't extend.
3829             ) {
3830                 push @$r, Range->new($start, $end,
3831                                      Value => $value,
3832                                      Type => $type);
3833             }
3834             else {
3835
3836                 # Here, the new range starts just after the current highest in
3837                 # the range list, and they have the same type and value.
3838                 # Extend the current range to incorporate the new one.
3839                 @{$r}[-1]->set_end($end);
3840             }
3841
3842             # This becomes the new maximum.
3843             $max{$addr} = $end;
3844
3845             return;
3846         }
3847         #local $to_trace = 0 if main::DEBUG;
3848
3849         trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) replace=$replace" if main::DEBUG && $to_trace;
3850
3851         # Here, the input range isn't after the whole rest of the range list.
3852         # Most likely 'splice' will be needed.  The rest of the routine finds
3853         # the needed splice parameters, and if necessary, does the splice.
3854         # First, find the offset parameter needed by the splice function for
3855         # the input range.  Note that the input range may span multiple
3856         # existing ones, but we'll worry about that later.  For now, just find
3857         # the beginning.  If the input range is to be inserted starting in a
3858         # position not currently in the range list, it must (obviously) come
3859         # just after the range below it, and just before the range above it.
3860         # Slightly less obviously, it will occupy the position currently
3861         # occupied by the range that is to come after it.  More formally, we
3862         # are looking for the position, $i, in the array of ranges, such that:
3863         #
3864         # r[$i-1]->start <= r[$i-1]->end < $start < r[$i]->start <= r[$i]->end
3865         #
3866         # (The ordered relationships within existing ranges are also shown in
3867         # the equation above).  However, if the start of the input range is
3868         # within an existing range, the splice offset should point to that
3869         # existing range's position in the list; that is $i satisfies a
3870         # somewhat different equation, namely:
3871         #
3872         #r[$i-1]->start <= r[$i-1]->end < r[$i]->start <= $start <= r[$i]->end
3873         #
3874         # More briefly, $start can come before or after r[$i]->start, and at
3875         # this point, we don't know which it will be.  However, these
3876         # two equations share these constraints:
3877         #
3878         #   r[$i-1]->end < $start <= r[$i]->end
3879         #
3880         # And that is good enough to find $i.
3881
3882         my $i = $self->_search_ranges($start);
3883         if (! defined $i) {
3884             Carp::my_carp_bug("Searching $self for range beginning with $start unexpectedly returned undefined.  Operation '$operation' not performed");
3885             return;
3886         }
3887
3888         # The search function returns $i such that:
3889         #
3890         # r[$i-1]->end < $start <= r[$i]->end
3891         #
3892         # That means that $i points to the first range in the range list
3893         # that could possibly be affected by this operation.  We still don't
3894         # know if the start of the input range is within r[$i], or if it
3895         # points to empty space between r[$i-1] and r[$i].
3896         trace "[$i] is the beginning splice point.  Existing range there is ", $r->[$i] if main::DEBUG && $to_trace;
3897
3898         # Special case the insertion of data that is not to replace any
3899         # existing data.
3900         if ($replace == $NO) {  # If $NO, has to be operation '+'
3901             #local $to_trace = 1 if main::DEBUG;
3902             trace "Doesn't replace" if main::DEBUG && $to_trace;
3903
3904             # Here, the new range is to take effect only on those code points
3905             # that aren't already in an existing range.  This can be done by
3906             # looking through the existing range list and finding the gaps in
3907             # the ranges that this new range affects, and then calling this
3908             # function recursively on each of those gaps, leaving untouched
3909             # anything already in the list.  Gather up a list of the changed
3910             # gaps first so that changes to the internal state as new ranges
3911             # are added won't be a problem.
3912             my @gap_list;
3913
3914             # First, if the starting point of the input range is outside an
3915             # existing one, there is a gap from there to the beginning of the
3916             # existing range -- add a span to fill the part that this new
3917             # range occupies
3918             if ($start < $r->[$i]->start) {
3919                 push @gap_list, Range->new($start,
3920                                            main::min($end,
3921                                                      $r->[$i]->start - 1),
3922                                            Type => $type);
3923                 trace "gap before $r->[$i] [$i], will add", $gap_list[-1] if main::DEBUG && $to_trace;
3924             }
3925
3926             # Then look through the range list for other gaps until we reach
3927             # the highest range affected by the input one.
3928             my $j;
3929             for ($j = $i+1; $j < $range_list_size; $j++) {
3930                 trace "j=[$j]", $r->[$j] if main::DEBUG && $to_trace;
3931                 last if $end < $r->[$j]->start;
3932
3933                 # If there is a gap between when this range starts and the
3934                 # previous one ends, add a span to fill it.  Note that just
3935                 # because there are two ranges doesn't mean there is a
3936                 # non-zero gap between them.  It could be that they have
3937                 # different values or types
3938                 if ($r->[$j-1]->end + 1 != $r->[$j]->start) {
3939                     push @gap_list,
3940                         Range->new($r->[$j-1]->end + 1,
3941                                    $r->[$j]->start - 1,
3942                                    Type => $type);
3943                     trace "gap between $r->[$j-1] and $r->[$j] [$j], will add: $gap_list[-1]" if main::DEBUG && $to_trace;
3944                 }
3945             }
3946
3947             # Here, we have either found an existing range in the range list,
3948             # beyond the area affected by the input one, or we fell off the
3949             # end of the loop because the input range affects the whole rest
3950             # of the range list.  In either case, $j is 1 higher than the
3951             # highest affected range.  If $j == $i, it means that there are no
3952             # affected ranges, that the entire insertion is in the gap between
3953             # r[$i-1], and r[$i], which we already have taken care of before
3954             # the loop.
3955             # On the other hand, if there are affected ranges, it might be
3956             # that there is a gap that needs filling after the final such
3957             # range to the end of the input range
3958             if ($r->[$j-1]->end < $end) {
3959                     push @gap_list, Range->new(main::max($start,
3960                                                          $r->[$j-1]->end + 1),
3961                                                $end,
3962                                                Type => $type);
3963                     trace "gap after $r->[$j-1], will add $gap_list[-1]" if main::DEBUG && $to_trace;
3964             }
3965
3966             # Call recursively to fill in all the gaps.
3967             foreach my $gap (@gap_list) {
3968                 $self->_add_delete($operation,
3969                                    $gap->start,
3970                                    $gap->end,
3971                                    $value,
3972                                    Type => $type);
3973             }
3974
3975             return;
3976         }
3977
3978         # Here, we have taken care of the case where $replace is $NO.
3979         # Remember that here, r[$i-1]->end < $start <= r[$i]->end
3980         # If inserting a multiple record, this is where it goes, before the
3981         # first (if any) existing one if inserting LIFO.  (If this is to go
3982         # afterwards, FIFO, we below move the pointer to there.)  These imply
3983         # an insertion, and no change to any existing ranges.  Note that $i
3984         # can be -1 if this new range doesn't actually duplicate any existing,
3985         # and comes at the beginning of the list.
3986         if ($replace == $MULTIPLE_BEFORE || $replace == $MULTIPLE_AFTER) {
3987
3988             if ($start != $end) {
3989                 Carp::my_carp_bug("$owner_name_of{$addr}Can't cope with adding a multiple record when the range ($start..$end) contains more than one code point.  No action taken.");
3990                 return;
3991             }
3992
3993             # If the new code point is within a current range ...
3994             if ($end >= $r->[$i]->start) {
3995
3996                 # Don't add an exact duplicate, as it isn't really a multiple
3997                 my $existing_value = $r->[$i]->value;
3998                 my $existing_type = $r->[$i]->type;
3999                 return if $value eq $existing_value && $type eq $existing_type;
<