This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Re: Compress::Zlib, pack "C" and utf-8 [PATCH]
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2 X<function>
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides a scalar context to its
16 argument, while a list operator may provide either scalar or list
17 contexts for its arguments.  If it does both, the scalar arguments will
18 be first, and the list argument will follow.  (Note that there can ever
19 be only one such list argument.)  For instance, splice() has three scalar
20 arguments followed by a list, whereas gethostbyname() has four scalar
21 arguments.
22
23 In the syntax descriptions that follow, list operators that expect a
24 list (and provide list context for the elements of the list) are shown
25 with LIST as an argument.  Such a list may consist of any combination
26 of scalar arguments or list values; the list values will be included
27 in the list as if each individual element were interpolated at that
28 point in the list, forming a longer single-dimensional list value.
29 Commas should separate elements of the LIST.
30
31 Any function in the list below may be used either with or without
32 parentheses around its arguments.  (The syntax descriptions omit the
33 parentheses.)  If you use the parentheses, the simple (but occasionally
34 surprising) rule is this: It I<looks> like a function, therefore it I<is> a
35 function, and precedence doesn't matter.  Otherwise it's a list
36 operator or unary operator, and precedence does matter.  And whitespace
37 between the function and left parenthesis doesn't count--so you need to
38 be careful sometimes:
39
40     print 1+2+4;        # Prints 7.
41     print(1+2) + 4;     # Prints 3.
42     print (1+2)+4;      # Also prints 3!
43     print +(1+2)+4;     # Prints 7.
44     print ((1+2)+4);    # Prints 7.
45
46 If you run Perl with the B<-w> switch it can warn you about this.  For
47 example, the third line above produces:
48
49     print (...) interpreted as function at - line 1.
50     Useless use of integer addition in void context at - line 1.
51
52 A few functions take no arguments at all, and therefore work as neither
53 unary nor list operators.  These include such functions as C<time>
54 and C<endpwent>.  For example, C<time+86_400> always means
55 C<time() + 86_400>.
56
57 For functions that can be used in either a scalar or list context,
58 nonabortive failure is generally indicated in a scalar context by
59 returning the undefined value, and in a list context by returning the
60 null list.
61
62 Remember the following important rule: There is B<no rule> that relates
63 the behavior of an expression in list context to its behavior in scalar
64 context, or vice versa.  It might do two totally different things.
65 Each operator and function decides which sort of value it would be most
66 appropriate to return in scalar context.  Some operators return the
67 length of the list that would have been returned in list context.  Some
68 operators return the first value in the list.  Some operators return the
69 last value in the list.  Some operators return a count of successful
70 operations.  In general, they do what you want, unless you want
71 consistency.
72 X<context>
73
74 A named array in scalar context is quite different from what would at
75 first glance appear to be a list in scalar context.  You can't get a list
76 like C<(1,2,3)> into being in scalar context, because the compiler knows
77 the context at compile time.  It would generate the scalar comma operator
78 there, not the list construction version of the comma.  That means it
79 was never a list to start with.
80
81 In general, functions in Perl that serve as wrappers for system calls
82 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
83 true when they succeed and C<undef> otherwise, as is usually mentioned
84 in the descriptions below.  This is different from the C interfaces,
85 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
86 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
87 variable on failure.  Other functions do not, except accidentally.
88
89 =head2 Perl Functions by Category
90 X<function>
91
92 Here are Perl's functions (including things that look like
93 functions, like some keywords and named operators)
94 arranged by category.  Some functions appear in more
95 than one place.
96
97 =over 4
98
99 =item Functions for SCALARs or strings
100 X<scalar> X<string> X<character>
101
102 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
103 C<length>, C<oct>, C<ord>, C<pack>, C<q//>, C<qq//>, C<reverse>,
104 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
105
106 =item Regular expressions and pattern matching
107 X<regular expression> X<regex> X<regexp>
108
109 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
110
111 =item Numeric functions
112 X<numeric> X<number> X<trigonometric> X<trigonometry>
113
114 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
115 C<sin>, C<sqrt>, C<srand>
116
117 =item Functions for real @ARRAYs
118 X<array>
119
120 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
121
122 =item Functions for list data
123 X<list>
124
125 C<grep>, C<join>, C<map>, C<qw//>, C<reverse>, C<sort>, C<unpack>
126
127 =item Functions for real %HASHes
128 X<hash>
129
130 C<delete>, C<each>, C<exists>, C<keys>, C<values>
131
132 =item Input and output functions
133 X<I/O> X<input> X<output> X<dbm>
134
135 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
136 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
137 C<readdir>, C<rewinddir>, C<say>, C<seek>, C<seekdir>, C<select>, C<syscall>,
138 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
139 C<warn>, C<write>
140
141 =item Functions for fixed length data or records
142
143 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
144
145 =item Functions for filehandles, files, or directories
146 X<file> X<filehandle> X<directory> X<pipe> X<link> X<symlink>
147
148 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
149 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
150 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
151 C<umask>, C<unlink>, C<utime>
152
153 =item Keywords related to the control flow of your Perl program
154 X<control flow>
155
156 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
157 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
158
159 =item Keywords related to switch
160
161 C<break>, C<continue>, C<given>, C<when>, C<default>
162
163 (These are only available if you enable the "switch" feature.
164 See L<feature> and L<perlsyn/"Switch statements">.)
165
166 =item Keywords related to scoping
167
168 C<caller>, C<import>, C<local>, C<my>, C<our>, C<state>, C<package>,
169 C<use>
170
171 (C<state> is only available if the "state" feature is enabled. See
172 L<feature>.)
173
174 =item Miscellaneous functions
175
176 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>,
177 C<reset>, C<scalar>, C<state>, C<undef>, C<wantarray>
178
179 =item Functions for processes and process groups
180 X<process> X<pid> X<process id>
181
182 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
183 C<pipe>, C<qx//>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
184 C<times>, C<wait>, C<waitpid>
185
186 =item Keywords related to perl modules
187 X<module>
188
189 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
190
191 =item Keywords related to classes and object-orientedness
192 X<object> X<class> X<package>
193
194 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
195 C<untie>, C<use>
196
197 =item Low-level socket functions
198 X<socket> X<sock>
199
200 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
201 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
202 C<socket>, C<socketpair>
203
204 =item System V interprocess communication functions
205 X<IPC> X<System V> X<semaphore> X<shared memory> X<memory> X<message>
206
207 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
208 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
209
210 =item Fetching user and group info
211 X<user> X<group> X<password> X<uid> X<gid>  X<passwd> X</etc/passwd>
212
213 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
214 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
215 C<getpwuid>, C<setgrent>, C<setpwent>
216
217 =item Fetching network info
218 X<network> X<protocol> X<host> X<hostname> X<IP> X<address> X<service>
219
220 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
221 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
222 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
223 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
224 C<setnetent>, C<setprotoent>, C<setservent>
225
226 =item Time-related functions
227 X<time> X<date>
228
229 C<gmtime>, C<localtime>, C<time>, C<times>
230
231 =item Functions new in perl5
232 X<perl5>
233
234 C<abs>, C<bless>, C<break>, C<chomp>, C<chr>, C<continue>, C<default>, 
235 C<exists>, C<formline>, C<given>, C<glob>, C<import>, C<lc>, C<lcfirst>,
236 C<lock>, C<map>, C<my>, C<no>, C<our>, C<prototype>, C<qr//>, C<qw//>, C<qx//>,
237 C<readline>, C<readpipe>, C<ref>, C<sub>*, C<sysopen>, C<tie>, C<tied>, C<uc>,
238 C<ucfirst>, C<untie>, C<use>, C<when>
239
240 * - C<sub> was a keyword in perl4, but in perl5 it is an
241 operator, which can be used in expressions.
242
243 =item Functions obsoleted in perl5
244
245 C<dbmclose>, C<dbmopen>
246
247 =back
248
249 =head2 Portability
250 X<portability> X<Unix> X<portable>
251
252 Perl was born in Unix and can therefore access all common Unix
253 system calls.  In non-Unix environments, the functionality of some
254 Unix system calls may not be available, or details of the available
255 functionality may differ slightly.  The Perl functions affected
256 by this are:
257
258 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
259 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
260 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
261 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
262 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
263 C<getppid>, C<getpgrp>, C<getpriority>, C<getprotobynumber>,
264 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
265 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
266 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
267 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
268 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
269 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
270 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
271 C<shmwrite>, C<socket>, C<socketpair>,
272 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
273 C<times>, C<truncate>, C<umask>, C<unlink>,
274 C<utime>, C<wait>, C<waitpid>
275
276 For more information about the portability of these functions, see
277 L<perlport> and other available platform-specific documentation.
278
279 =head2 Alphabetical Listing of Perl Functions
280
281 =over 8
282
283 =item -X FILEHANDLE
284 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
285 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
286
287 =item -X EXPR
288
289 =item -X DIRHANDLE
290
291 =item -X
292
293 A file test, where X is one of the letters listed below.  This unary
294 operator takes one argument, either a filename, a filehandle, or a dirhandle, 
295 and tests the associated file to see if something is true about it.  If the
296 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
297 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
298 the undefined value if the file doesn't exist.  Despite the funny
299 names, precedence is the same as any other named unary operator.  The
300 operator may be any of:
301
302     -r  File is readable by effective uid/gid.
303     -w  File is writable by effective uid/gid.
304     -x  File is executable by effective uid/gid.
305     -o  File is owned by effective uid.
306
307     -R  File is readable by real uid/gid.
308     -W  File is writable by real uid/gid.
309     -X  File is executable by real uid/gid.
310     -O  File is owned by real uid.
311
312     -e  File exists.
313     -z  File has zero size (is empty).
314     -s  File has nonzero size (returns size in bytes).
315
316     -f  File is a plain file.
317     -d  File is a directory.
318     -l  File is a symbolic link.
319     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
320     -S  File is a socket.
321     -b  File is a block special file.
322     -c  File is a character special file.
323     -t  Filehandle is opened to a tty.
324
325     -u  File has setuid bit set.
326     -g  File has setgid bit set.
327     -k  File has sticky bit set.
328
329     -T  File is an ASCII text file (heuristic guess).
330     -B  File is a "binary" file (opposite of -T).
331
332     -M  Script start time minus file modification time, in days.
333     -A  Same for access time.
334     -C  Same for inode change time (Unix, may differ for other platforms)
335
336 Example:
337
338     while (<>) {
339         chomp;
340         next unless -f $_;      # ignore specials
341         #...
342     }
343
344 The interpretation of the file permission operators C<-r>, C<-R>,
345 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
346 of the file and the uids and gids of the user.  There may be other
347 reasons you can't actually read, write, or execute the file.  Such
348 reasons may be for example network filesystem access controls, ACLs
349 (access control lists), read-only filesystems, and unrecognized
350 executable formats.
351
352 Also note that, for the superuser on the local filesystems, the C<-r>,
353 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
354 if any execute bit is set in the mode.  Scripts run by the superuser
355 may thus need to do a stat() to determine the actual mode of the file,
356 or temporarily set their effective uid to something else.
357
358 If you are using ACLs, there is a pragma called C<filetest> that may
359 produce more accurate results than the bare stat() mode bits.
360 When under the C<use filetest 'access'> the above-mentioned filetests
361 will test whether the permission can (not) be granted using the
362 access() family of system calls.  Also note that the C<-x> and C<-X> may
363 under this pragma return true even if there are no execute permission
364 bits set (nor any extra execute permission ACLs).  This strangeness is
365 due to the underlying system calls' definitions.  Read the
366 documentation for the C<filetest> pragma for more information.
367
368 Note that C<-s/a/b/> does not do a negated substitution.  Saying
369 C<-exp($foo)> still works as expected, however--only single letters
370 following a minus are interpreted as file tests.
371
372 The C<-T> and C<-B> switches work as follows.  The first block or so of the
373 file is examined for odd characters such as strange control codes or
374 characters with the high bit set.  If too many strange characters (>30%)
375 are found, it's a C<-B> file; otherwise it's a C<-T> file.  Also, any file
376 containing null in the first block is considered a binary file.  If C<-T>
377 or C<-B> is used on a filehandle, the current IO buffer is examined
378 rather than the first block.  Both C<-T> and C<-B> return true on a null
379 file, or a file at EOF when testing a filehandle.  Because you have to
380 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
381 against the file first, as in C<next unless -f $file && -T $file>.
382
383 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
384 the special filehandle consisting of a solitary underline, then the stat
385 structure of the previous file test (or stat operator) is used, saving
386 a system call.  (This doesn't work with C<-t>, and you need to remember
387 that lstat() and C<-l> will leave values in the stat structure for the
388 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
389 an C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
390 Example:
391
392     print "Can do.\n" if -r $a || -w _ || -x _;
393
394     stat($filename);
395     print "Readable\n" if -r _;
396     print "Writable\n" if -w _;
397     print "Executable\n" if -x _;
398     print "Setuid\n" if -u _;
399     print "Setgid\n" if -g _;
400     print "Sticky\n" if -k _;
401     print "Text\n" if -T _;
402     print "Binary\n" if -B _;
403
404 As of Perl 5.9.1, as a form of purely syntactic sugar, you can stack file
405 test operators, in a way that C<-f -w -x $file> is equivalent to
406 C<-x $file && -w _ && -f _>. (This is only syntax fancy: if you use
407 the return value of C<-f $file> as an argument to another filetest
408 operator, no special magic will happen.)
409
410 =item abs VALUE
411 X<abs> X<absolute>
412
413 =item abs
414
415 Returns the absolute value of its argument.
416 If VALUE is omitted, uses C<$_>.
417
418 =item accept NEWSOCKET,GENERICSOCKET
419 X<accept>
420
421 Accepts an incoming socket connect, just as the accept(2) system call
422 does.  Returns the packed address if it succeeded, false otherwise.
423 See the example in L<perlipc/"Sockets: Client/Server Communication">.
424
425 On systems that support a close-on-exec flag on files, the flag will
426 be set for the newly opened file descriptor, as determined by the
427 value of $^F.  See L<perlvar/$^F>.
428
429 =item alarm SECONDS
430 X<alarm>
431 X<SIGALRM>
432 X<timer>
433
434 =item alarm
435
436 Arranges to have a SIGALRM delivered to this process after the
437 specified number of wallclock seconds has elapsed.  If SECONDS is not
438 specified, the value stored in C<$_> is used. (On some machines,
439 unfortunately, the elapsed time may be up to one second less or more
440 than you specified because of how seconds are counted, and process
441 scheduling may delay the delivery of the signal even further.)
442
443 Only one timer may be counting at once.  Each call disables the
444 previous timer, and an argument of C<0> may be supplied to cancel the
445 previous timer without starting a new one.  The returned value is the
446 amount of time remaining on the previous timer.
447
448 For delays of finer granularity than one second, you may use Perl's
449 four-argument version of select() leaving the first three arguments
450 undefined, or you might be able to use the C<syscall> interface to
451 access setitimer(2) if your system supports it.  The Time::HiRes
452 module (from CPAN, and starting from Perl 5.8 part of the standard
453 distribution) may also prove useful.
454
455 It is usually a mistake to intermix C<alarm> and C<sleep> calls.
456 (C<sleep> may be internally implemented in your system with C<alarm>)
457
458 If you want to use C<alarm> to time out a system call you need to use an
459 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
460 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
461 restart system calls on some systems.  Using C<eval>/C<die> always works,
462 modulo the caveats given in L<perlipc/"Signals">.
463
464     eval {
465         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
466         alarm $timeout;
467         $nread = sysread SOCKET, $buffer, $size;
468         alarm 0;
469     };
470     if ($@) {
471         die unless $@ eq "alarm\n";   # propagate unexpected errors
472         # timed out
473     }
474     else {
475         # didn't
476     }
477
478 For more information see L<perlipc>.
479
480 =item atan2 Y,X
481 X<atan2> X<arctangent> X<tan> X<tangent>
482
483 Returns the arctangent of Y/X in the range -PI to PI.
484
485 For the tangent operation, you may use the C<Math::Trig::tan>
486 function, or use the familiar relation:
487
488     sub tan { sin($_[0]) / cos($_[0])  }
489
490 Note that atan2(0, 0) is not well-defined.
491
492 =item bind SOCKET,NAME
493 X<bind>
494
495 Binds a network address to a socket, just as the bind system call
496 does.  Returns true if it succeeded, false otherwise.  NAME should be a
497 packed address of the appropriate type for the socket.  See the examples in
498 L<perlipc/"Sockets: Client/Server Communication">.
499
500 =item binmode FILEHANDLE, LAYER
501 X<binmode> X<binary> X<text> X<DOS> X<Windows>
502
503 =item binmode FILEHANDLE
504
505 Arranges for FILEHANDLE to be read or written in "binary" or "text"
506 mode on systems where the run-time libraries distinguish between
507 binary and text files.  If FILEHANDLE is an expression, the value is
508 taken as the name of the filehandle.  Returns true on success,
509 otherwise it returns C<undef> and sets C<$!> (errno).
510
511 On some systems (in general, DOS and Windows-based systems) binmode()
512 is necessary when you're not working with a text file.  For the sake
513 of portability it is a good idea to always use it when appropriate,
514 and to never use it when it isn't appropriate.  Also, people can
515 set their I/O to be by default UTF-8 encoded Unicode, not bytes.
516
517 In other words: regardless of platform, use binmode() on binary data,
518 like for example images.
519
520 If LAYER is present it is a single string, but may contain multiple
521 directives. The directives alter the behaviour of the file handle.
522 When LAYER is present using binmode on text file makes sense.
523
524 If LAYER is omitted or specified as C<:raw> the filehandle is made
525 suitable for passing binary data. This includes turning off possible CRLF
526 translation and marking it as bytes (as opposed to Unicode characters).
527 Note that, despite what may be implied in I<"Programming Perl"> (the
528 Camel) or elsewhere, C<:raw> is I<not> simply the inverse of C<:crlf>
529 -- other layers which would affect the binary nature of the stream are
530 I<also> disabled. See L<PerlIO>, L<perlrun> and the discussion about the
531 PERLIO environment variable.
532
533 The C<:bytes>, C<:crlf>, and C<:utf8>, and any other directives of the
534 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
535 establish default I/O layers.  See L<open>.
536
537 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
538 in "Programming Perl, 3rd Edition".  However, since the publishing of this
539 book, by many known as "Camel III", the consensus of the naming of this
540 functionality has moved from "discipline" to "layer".  All documentation
541 of this version of Perl therefore refers to "layers" rather than to
542 "disciplines".  Now back to the regularly scheduled documentation...>
543
544 To mark FILEHANDLE as UTF-8, use C<:utf8> or C<:encoding(utf8)>.
545 C<:utf8> just marks the data as UTF-8 without further checking,
546 while C<:encoding(utf8)> checks the data for actually being valid
547 UTF-8. More details can be found in L<PerlIO::encoding>.
548
549 In general, binmode() should be called after open() but before any I/O
550 is done on the filehandle.  Calling binmode() will normally flush any
551 pending buffered output data (and perhaps pending input data) on the
552 handle.  An exception to this is the C<:encoding> layer that
553 changes the default character encoding of the handle, see L<open>.
554 The C<:encoding> layer sometimes needs to be called in
555 mid-stream, and it doesn't flush the stream.  The C<:encoding>
556 also implicitly pushes on top of itself the C<:utf8> layer because
557 internally Perl will operate on UTF-8 encoded Unicode characters.
558
559 The operating system, device drivers, C libraries, and Perl run-time
560 system all work together to let the programmer treat a single
561 character (C<\n>) as the line terminator, irrespective of the external
562 representation.  On many operating systems, the native text file
563 representation matches the internal representation, but on some
564 platforms the external representation of C<\n> is made up of more than
565 one character.
566
567 Mac OS, all variants of Unix, and Stream_LF files on VMS use a single
568 character to end each line in the external representation of text (even
569 though that single character is CARRIAGE RETURN on Mac OS and LINE FEED
570 on Unix and most VMS files). In other systems like OS/2, DOS and the
571 various flavors of MS-Windows your program sees a C<\n> as a simple C<\cJ>,
572 but what's stored in text files are the two characters C<\cM\cJ>.  That
573 means that, if you don't use binmode() on these systems, C<\cM\cJ>
574 sequences on disk will be converted to C<\n> on input, and any C<\n> in
575 your program will be converted back to C<\cM\cJ> on output.  This is what
576 you want for text files, but it can be disastrous for binary files.
577
578 Another consequence of using binmode() (on some systems) is that
579 special end-of-file markers will be seen as part of the data stream.
580 For systems from the Microsoft family this means that if your binary
581 data contains C<\cZ>, the I/O subsystem will regard it as the end of
582 the file, unless you use binmode().
583
584 binmode() is not only important for readline() and print() operations,
585 but also when using read(), seek(), sysread(), syswrite() and tell()
586 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
587 in L<perlvar> for how to manually set your input and output
588 line-termination sequences.
589
590 =item bless REF,CLASSNAME
591 X<bless>
592
593 =item bless REF
594
595 This function tells the thingy referenced by REF that it is now an object
596 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
597 is used.  Because a C<bless> is often the last thing in a constructor,
598 it returns the reference for convenience.  Always use the two-argument
599 version if a derived class might inherit the function doing the blessing.
600 See L<perltoot> and L<perlobj> for more about the blessing (and blessings)
601 of objects.
602
603 Consider always blessing objects in CLASSNAMEs that are mixed case.
604 Namespaces with all lowercase names are considered reserved for
605 Perl pragmata.  Builtin types have all uppercase names. To prevent
606 confusion, you may wish to avoid such package names as well.  Make sure
607 that CLASSNAME is a true value.
608
609 See L<perlmod/"Perl Modules">.
610
611 =item break
612
613 Break out of a C<given()> block.
614
615 This keyword is enabled by the "switch" feature: see L<feature>
616 for more information.
617
618 =item caller EXPR
619 X<caller> X<call stack> X<stack> X<stack trace>
620
621 =item caller
622
623 Returns the context of the current subroutine call.  In scalar context,
624 returns the caller's package name if there is a caller, that is, if
625 we're in a subroutine or C<eval> or C<require>, and the undefined value
626 otherwise.  In list context, returns
627
628     # 0         1          2
629     ($package, $filename, $line) = caller;
630
631 With EXPR, it returns some extra information that the debugger uses to
632 print a stack trace.  The value of EXPR indicates how many call frames
633 to go back before the current one.
634
635     #  0         1          2      3            4
636     ($package, $filename, $line, $subroutine, $hasargs,
637
638     #  5          6          7            8       9         10
639     $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash)
640      = caller($i);
641
642 Here $subroutine may be C<(eval)> if the frame is not a subroutine
643 call, but an C<eval>.  In such a case additional elements $evaltext and
644 C<$is_require> are set: C<$is_require> is true if the frame is created by a
645 C<require> or C<use> statement, $evaltext contains the text of the
646 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
647 $filename is C<(eval)>, but $evaltext is undefined.  (Note also that
648 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
649 frame.)  $subroutine may also be C<(unknown)> if this particular
650 subroutine happens to have been deleted from the symbol table.
651 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
652 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
653 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
654 between versions of Perl, and are not meant for external use.
655
656 C<$hinthash> is a reference to a hash containing the value of C<%^H> when the
657 caller was compiled, or C<undef> if C<%^H> was empty. Do not modify the values
658 of this hash, as they are the actual values stored in the optree.
659
660 Furthermore, when called from within the DB package, caller returns more
661 detailed information: it sets the list variable C<@DB::args> to be the
662 arguments with which the subroutine was invoked.
663
664 Be aware that the optimizer might have optimized call frames away before
665 C<caller> had a chance to get the information.  That means that C<caller(N)>
666 might not return information about the call frame you expect it do, for
667 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
668 previous time C<caller> was called.
669
670 =item chdir EXPR
671 X<chdir>
672 X<cd>
673 X<directory, change>
674
675 =item chdir FILEHANDLE
676
677 =item chdir DIRHANDLE
678
679 =item chdir
680
681 Changes the working directory to EXPR, if possible. If EXPR is omitted,
682 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
683 changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the
684 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If
685 neither is set, C<chdir> does nothing. It returns true upon success,
686 false otherwise. See the example under C<die>.
687
688 On systems that support fchdir, you might pass a file handle or
689 directory handle as argument.  On systems that don't support fchdir,
690 passing handles produces a fatal error at run time.
691
692 =item chmod LIST
693 X<chmod> X<permission> X<mode>
694
695 Changes the permissions of a list of files.  The first element of the
696 list must be the numerical mode, which should probably be an octal
697 number, and which definitely should I<not> be a string of octal digits:
698 C<0644> is okay, C<'0644'> is not.  Returns the number of files
699 successfully changed.  See also L</oct>, if all you have is a string.
700
701     $cnt = chmod 0755, 'foo', 'bar';
702     chmod 0755, @executables;
703     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
704                                              # --w----r-T
705     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
706     $mode = 0644;   chmod $mode, 'foo';      # this is best
707
708 On systems that support fchmod, you might pass file handles among the
709 files.  On systems that don't support fchmod, passing file handles
710 produces a fatal error at run time.   The file handles must be passed
711 as globs or references to be recognized.  Barewords are considered
712 file names.
713
714     open(my $fh, "<", "foo");
715     my $perm = (stat $fh)[2] & 07777;
716     chmod($perm | 0600, $fh);
717
718 You can also import the symbolic C<S_I*> constants from the Fcntl
719 module:
720
721     use Fcntl ':mode';
722
723     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
724     # This is identical to the chmod 0755 of the above example.
725
726 =item chomp VARIABLE
727 X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol>
728
729 =item chomp( LIST )
730
731 =item chomp
732
733 This safer version of L</chop> removes any trailing string
734 that corresponds to the current value of C<$/> (also known as
735 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
736 number of characters removed from all its arguments.  It's often used to
737 remove the newline from the end of an input record when you're worried
738 that the final record may be missing its newline.  When in paragraph
739 mode (C<$/ = "">), it removes all trailing newlines from the string.
740 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
741 a reference to an integer or the like, see L<perlvar>) chomp() won't
742 remove anything.
743 If VARIABLE is omitted, it chomps C<$_>.  Example:
744
745     while (<>) {
746         chomp;  # avoid \n on last field
747         @array = split(/:/);
748         # ...
749     }
750
751 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
752
753 You can actually chomp anything that's an lvalue, including an assignment:
754
755     chomp($cwd = `pwd`);
756     chomp($answer = <STDIN>);
757
758 If you chomp a list, each element is chomped, and the total number of
759 characters removed is returned.
760
761 Note that parentheses are necessary when you're chomping anything
762 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
763 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
764 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
765 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
766 as C<chomp($a, $b)>.
767
768 =item chop VARIABLE
769 X<chop>
770
771 =item chop( LIST )
772
773 =item chop
774
775 Chops off the last character of a string and returns the character
776 chopped.  It is much more efficient than C<s/.$//s> because it neither
777 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
778 If VARIABLE is a hash, it chops the hash's values, but not its keys.
779
780 You can actually chop anything that's an lvalue, including an assignment.
781
782 If you chop a list, each element is chopped.  Only the value of the
783 last C<chop> is returned.
784
785 Note that C<chop> returns the last character.  To return all but the last
786 character, use C<substr($string, 0, -1)>.
787
788 See also L</chomp>.
789
790 =item chown LIST
791 X<chown> X<owner> X<user> X<group>
792
793 Changes the owner (and group) of a list of files.  The first two
794 elements of the list must be the I<numeric> uid and gid, in that
795 order.  A value of -1 in either position is interpreted by most
796 systems to leave that value unchanged.  Returns the number of files
797 successfully changed.
798
799     $cnt = chown $uid, $gid, 'foo', 'bar';
800     chown $uid, $gid, @filenames;
801
802 On systems that support fchown, you might pass file handles among the
803 files.  On systems that don't support fchown, passing file handles
804 produces a fatal error at run time.  The file handles must be passed
805 as globs or references to be recognized.  Barewords are considered
806 file names.
807
808 Here's an example that looks up nonnumeric uids in the passwd file:
809
810     print "User: ";
811     chomp($user = <STDIN>);
812     print "Files: ";
813     chomp($pattern = <STDIN>);
814
815     ($login,$pass,$uid,$gid) = getpwnam($user)
816         or die "$user not in passwd file";
817
818     @ary = glob($pattern);      # expand filenames
819     chown $uid, $gid, @ary;
820
821 On most systems, you are not allowed to change the ownership of the
822 file unless you're the superuser, although you should be able to change
823 the group to any of your secondary groups.  On insecure systems, these
824 restrictions may be relaxed, but this is not a portable assumption.
825 On POSIX systems, you can detect this condition this way:
826
827     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
828     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
829
830 =item chr NUMBER
831 X<chr> X<character> X<ASCII> X<Unicode>
832
833 =item chr
834
835 Returns the character represented by that NUMBER in the character set.
836 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
837 chr(0x263a) is a Unicode smiley face.  
838
839 Negative values give the Unicode replacement character (chr(0xfffd)),
840 except under the L<bytes> pragma, where low eight bits of the value
841 (truncated to an integer) are used.
842
843 If NUMBER is omitted, uses C<$_>.
844
845 For the reverse, use L</ord>.
846
847 Note that characters from 128 to 255 (inclusive) are by default
848 internally not encoded as UTF-8 for backward compatibility reasons.
849
850 See L<perlunicode> for more about Unicode.
851
852 =item chroot FILENAME
853 X<chroot> X<root>
854
855 =item chroot
856
857 This function works like the system call by the same name: it makes the
858 named directory the new root directory for all further pathnames that
859 begin with a C</> by your process and all its children.  (It doesn't
860 change your current working directory, which is unaffected.)  For security
861 reasons, this call is restricted to the superuser.  If FILENAME is
862 omitted, does a C<chroot> to C<$_>.
863
864 =item close FILEHANDLE
865 X<close>
866
867 =item close
868
869 Closes the file or pipe associated with the file handle, flushes the IO
870 buffers, and closes the system file descriptor.  Returns true if those
871 operations have succeeded and if no error was reported by any PerlIO
872 layer.  Closes the currently selected filehandle if the argument is
873 omitted.
874
875 You don't have to close FILEHANDLE if you are immediately going to do
876 another C<open> on it, because C<open> will close it for you.  (See
877 C<open>.)  However, an explicit C<close> on an input file resets the line
878 counter (C<$.>), while the implicit close done by C<open> does not.
879
880 If the file handle came from a piped open, C<close> will additionally
881 return false if one of the other system calls involved fails, or if the
882 program exits with non-zero status.  (If the only problem was that the
883 program exited non-zero, C<$!> will be set to C<0>.)  Closing a pipe
884 also waits for the process executing on the pipe to complete, in case you
885 want to look at the output of the pipe afterwards, and
886 implicitly puts the exit status value of that command into C<$?> and
887 C<${^CHILD_ERROR_NATIVE}>.
888
889 Prematurely closing the read end of a pipe (i.e. before the process
890 writing to it at the other end has closed it) will result in a
891 SIGPIPE being delivered to the writer.  If the other end can't
892 handle that, be sure to read all the data before closing the pipe.
893
894 Example:
895
896     open(OUTPUT, '|sort >foo')  # pipe to sort
897         or die "Can't start sort: $!";
898     #...                        # print stuff to output
899     close OUTPUT                # wait for sort to finish
900         or warn $! ? "Error closing sort pipe: $!"
901                    : "Exit status $? from sort";
902     open(INPUT, 'foo')          # get sort's results
903         or die "Can't open 'foo' for input: $!";
904
905 FILEHANDLE may be an expression whose value can be used as an indirect
906 filehandle, usually the real filehandle name.
907
908 =item closedir DIRHANDLE
909 X<closedir>
910
911 Closes a directory opened by C<opendir> and returns the success of that
912 system call.
913
914 =item connect SOCKET,NAME
915 X<connect>
916
917 Attempts to connect to a remote socket, just as the connect system call
918 does.  Returns true if it succeeded, false otherwise.  NAME should be a
919 packed address of the appropriate type for the socket.  See the examples in
920 L<perlipc/"Sockets: Client/Server Communication">.
921
922 =item continue BLOCK
923 X<continue>
924
925 =item continue
926
927 C<continue> is actually a flow control statement rather than a function.  If
928 there is a C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
929 C<foreach>), it is always executed just before the conditional is about to
930 be evaluated again, just like the third part of a C<for> loop in C.  Thus
931 it can be used to increment a loop variable, even when the loop has been
932 continued via the C<next> statement (which is similar to the C C<continue>
933 statement).
934
935 C<last>, C<next>, or C<redo> may appear within a C<continue>
936 block.  C<last> and C<redo> will behave as if they had been executed within
937 the main block.  So will C<next>, but since it will execute a C<continue>
938 block, it may be more entertaining.
939
940     while (EXPR) {
941         ### redo always comes here
942         do_something;
943     } continue {
944         ### next always comes here
945         do_something_else;
946         # then back the top to re-check EXPR
947     }
948     ### last always comes here
949
950 Omitting the C<continue> section is semantically equivalent to using an
951 empty one, logically enough.  In that case, C<next> goes directly back
952 to check the condition at the top of the loop.
953
954 If the "switch" feature is enabled, C<continue> is also a
955 function that will break out of the current C<when> or C<default>
956 block, and fall through to the next case. See L<feature> and
957 L<perlsyn/"Switch statements"> for more information.
958
959
960 =item cos EXPR
961 X<cos> X<cosine> X<acos> X<arccosine>
962
963 =item cos
964
965 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
966 takes cosine of C<$_>.
967
968 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
969 function, or use this relation:
970
971     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
972
973 =item crypt PLAINTEXT,SALT
974 X<crypt> X<digest> X<hash> X<salt> X<plaintext> X<password>
975 X<decrypt> X<cryptography> X<passwd> X<encrypt>
976
977 Creates a digest string exactly like the crypt(3) function in the C
978 library (assuming that you actually have a version there that has not
979 been extirpated as a potential munitions).
980
981 crypt() is a one-way hash function.  The PLAINTEXT and SALT is turned
982 into a short string, called a digest, which is returned.  The same
983 PLAINTEXT and SALT will always return the same string, but there is no
984 (known) way to get the original PLAINTEXT from the hash.  Small
985 changes in the PLAINTEXT or SALT will result in large changes in the
986 digest.
987
988 There is no decrypt function.  This function isn't all that useful for
989 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
990 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
991 primarily used to check if two pieces of text are the same without
992 having to transmit or store the text itself.  An example is checking
993 if a correct password is given.  The digest of the password is stored,
994 not the password itself.  The user types in a password that is
995 crypt()'d with the same salt as the stored digest.  If the two digests
996 match the password is correct.
997
998 When verifying an existing digest string you should use the digest as
999 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
1000 to create the digest is visible as part of the digest.  This ensures
1001 crypt() will hash the new string with the same salt as the digest.
1002 This allows your code to work with the standard L<crypt|/crypt> and
1003 with more exotic implementations.  In other words, do not assume
1004 anything about the returned string itself, or how many bytes in the
1005 digest matter.
1006
1007 Traditionally the result is a string of 13 bytes: two first bytes of
1008 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
1009 the first eight bytes of the digest string mattered, but alternative
1010 hashing schemes (like MD5), higher level security schemes (like C2),
1011 and implementations on non-UNIX platforms may produce different
1012 strings.
1013
1014 When choosing a new salt create a random two character string whose
1015 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
1016 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
1017 characters is just a recommendation; the characters allowed in
1018 the salt depend solely on your system's crypt library, and Perl can't
1019 restrict what salts C<crypt()> accepts.
1020
1021 Here's an example that makes sure that whoever runs this program knows
1022 their password:
1023
1024     $pwd = (getpwuid($<))[1];
1025
1026     system "stty -echo";
1027     print "Password: ";
1028     chomp($word = <STDIN>);
1029     print "\n";
1030     system "stty echo";
1031
1032     if (crypt($word, $pwd) ne $pwd) {
1033         die "Sorry...\n";
1034     } else {
1035         print "ok\n";
1036     }
1037
1038 Of course, typing in your own password to whoever asks you
1039 for it is unwise.
1040
1041 The L<crypt|/crypt> function is unsuitable for hashing large quantities
1042 of data, not least of all because you can't get the information
1043 back.  Look at the L<Digest> module for more robust algorithms.
1044
1045 If using crypt() on a Unicode string (which I<potentially> has
1046 characters with codepoints above 255), Perl tries to make sense
1047 of the situation by trying to downgrade (a copy of the string)
1048 the string back to an eight-bit byte string before calling crypt()
1049 (on that copy).  If that works, good.  If not, crypt() dies with
1050 C<Wide character in crypt>.
1051
1052 =item dbmclose HASH
1053 X<dbmclose>
1054
1055 [This function has been largely superseded by the C<untie> function.]
1056
1057 Breaks the binding between a DBM file and a hash.
1058
1059 =item dbmopen HASH,DBNAME,MASK
1060 X<dbmopen> X<dbm> X<ndbm> X<sdbm> X<gdbm>
1061
1062 [This function has been largely superseded by the C<tie> function.]
1063
1064 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
1065 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
1066 argument is I<not> a filehandle, even though it looks like one).  DBNAME
1067 is the name of the database (without the F<.dir> or F<.pag> extension if
1068 any).  If the database does not exist, it is created with protection
1069 specified by MASK (as modified by the C<umask>).  If your system supports
1070 only the older DBM functions, you may perform only one C<dbmopen> in your
1071 program.  In older versions of Perl, if your system had neither DBM nor
1072 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
1073 sdbm(3).
1074
1075 If you don't have write access to the DBM file, you can only read hash
1076 variables, not set them.  If you want to test whether you can write,
1077 either use file tests or try setting a dummy hash entry inside an C<eval>,
1078 which will trap the error.
1079
1080 Note that functions such as C<keys> and C<values> may return huge lists
1081 when used on large DBM files.  You may prefer to use the C<each>
1082 function to iterate over large DBM files.  Example:
1083
1084     # print out history file offsets
1085     dbmopen(%HIST,'/usr/lib/news/history',0666);
1086     while (($key,$val) = each %HIST) {
1087         print $key, ' = ', unpack('L',$val), "\n";
1088     }
1089     dbmclose(%HIST);
1090
1091 See also L<AnyDBM_File> for a more general description of the pros and
1092 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1093 rich implementation.
1094
1095 You can control which DBM library you use by loading that library
1096 before you call dbmopen():
1097
1098     use DB_File;
1099     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1100         or die "Can't open netscape history file: $!";
1101
1102 =item defined EXPR
1103 X<defined> X<undef> X<undefined>
1104
1105 =item defined
1106
1107 Returns a Boolean value telling whether EXPR has a value other than
1108 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
1109 checked.
1110
1111 Many operations return C<undef> to indicate failure, end of file,
1112 system error, uninitialized variable, and other exceptional
1113 conditions.  This function allows you to distinguish C<undef> from
1114 other values.  (A simple Boolean test will not distinguish among
1115 C<undef>, zero, the empty string, and C<"0">, which are all equally
1116 false.)  Note that since C<undef> is a valid scalar, its presence
1117 doesn't I<necessarily> indicate an exceptional condition: C<pop>
1118 returns C<undef> when its argument is an empty array, I<or> when the
1119 element to return happens to be C<undef>.
1120
1121 You may also use C<defined(&func)> to check whether subroutine C<&func>
1122 has ever been defined.  The return value is unaffected by any forward
1123 declarations of C<&func>.  Note that a subroutine which is not defined
1124 may still be callable: its package may have an C<AUTOLOAD> method that
1125 makes it spring into existence the first time that it is called -- see
1126 L<perlsub>.
1127
1128 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1129 used to report whether memory for that aggregate has ever been
1130 allocated.  This behavior may disappear in future versions of Perl.
1131 You should instead use a simple test for size:
1132
1133     if (@an_array) { print "has array elements\n" }
1134     if (%a_hash)   { print "has hash members\n"   }
1135
1136 When used on a hash element, it tells you whether the value is defined,
1137 not whether the key exists in the hash.  Use L</exists> for the latter
1138 purpose.
1139
1140 Examples:
1141
1142     print if defined $switch{'D'};
1143     print "$val\n" while defined($val = pop(@ary));
1144     die "Can't readlink $sym: $!"
1145         unless defined($value = readlink $sym);
1146     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1147     $debugging = 0 unless defined $debugging;
1148
1149 Note:  Many folks tend to overuse C<defined>, and then are surprised to
1150 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1151 defined values.  For example, if you say
1152
1153     "ab" =~ /a(.*)b/;
1154
1155 The pattern match succeeds, and C<$1> is defined, despite the fact that it
1156 matched "nothing".  It didn't really fail to match anything.  Rather, it
1157 matched something that happened to be zero characters long.  This is all
1158 very above-board and honest.  When a function returns an undefined value,
1159 it's an admission that it couldn't give you an honest answer.  So you
1160 should use C<defined> only when you're questioning the integrity of what
1161 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1162 what you want.
1163
1164 See also L</undef>, L</exists>, L</ref>.
1165
1166 =item delete EXPR
1167 X<delete>
1168
1169 Given an expression that specifies a hash element, array element, hash slice,
1170 or array slice, deletes the specified element(s) from the hash or array.
1171 In the case of an array, if the array elements happen to be at the end,
1172 the size of the array will shrink to the highest element that tests
1173 true for exists() (or 0 if no such element exists).
1174
1175 Returns a list with the same number of elements as the number of elements
1176 for which deletion was attempted.  Each element of that list consists of
1177 either the value of the element deleted, or the undefined value.  In scalar
1178 context, this means that you get the value of the last element deleted (or
1179 the undefined value if that element did not exist).
1180
1181     %hash = (foo => 11, bar => 22, baz => 33);
1182     $scalar = delete $hash{foo};             # $scalar is 11
1183     $scalar = delete @hash{qw(foo bar)};     # $scalar is 22
1184     @array  = delete @hash{qw(foo bar baz)}; # @array  is (undef,undef,33)
1185
1186 Deleting from C<%ENV> modifies the environment.  Deleting from
1187 a hash tied to a DBM file deletes the entry from the DBM file.  Deleting
1188 from a C<tie>d hash or array may not necessarily return anything.
1189
1190 Deleting an array element effectively returns that position of the array
1191 to its initial, uninitialized state.  Subsequently testing for the same
1192 element with exists() will return false.  Also, deleting array elements
1193 in the middle of an array will not shift the index of the elements
1194 after them down.  Use splice() for that.  See L</exists>.
1195
1196 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1197
1198     foreach $key (keys %HASH) {
1199         delete $HASH{$key};
1200     }
1201
1202     foreach $index (0 .. $#ARRAY) {
1203         delete $ARRAY[$index];
1204     }
1205
1206 And so do these:
1207
1208     delete @HASH{keys %HASH};
1209
1210     delete @ARRAY[0 .. $#ARRAY];
1211
1212 But both of these are slower than just assigning the empty list
1213 or undefining %HASH or @ARRAY:
1214
1215     %HASH = ();         # completely empty %HASH
1216     undef %HASH;        # forget %HASH ever existed
1217
1218     @ARRAY = ();        # completely empty @ARRAY
1219     undef @ARRAY;       # forget @ARRAY ever existed
1220
1221 Note that the EXPR can be arbitrarily complicated as long as the final
1222 operation is a hash element, array element,  hash slice, or array slice
1223 lookup:
1224
1225     delete $ref->[$x][$y]{$key};
1226     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1227
1228     delete $ref->[$x][$y][$index];
1229     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1230
1231 =item die LIST
1232 X<die> X<throw> X<exception> X<raise> X<$@> X<abort>
1233
1234 Outside an C<eval>, prints the value of LIST to C<STDERR> and
1235 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
1236 exits with the value of C<<< ($? >> 8) >>> (backtick `command`
1237 status).  If C<<< ($? >> 8) >>> is C<0>, exits with C<255>.  Inside
1238 an C<eval(),> the error message is stuffed into C<$@> and the
1239 C<eval> is terminated with the undefined value.  This makes
1240 C<die> the way to raise an exception.
1241
1242 Equivalent examples:
1243
1244     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1245     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1246
1247 If the last element of LIST does not end in a newline, the current
1248 script line number and input line number (if any) are also printed,
1249 and a newline is supplied.  Note that the "input line number" (also
1250 known as "chunk") is subject to whatever notion of "line" happens to
1251 be currently in effect, and is also available as the special variable
1252 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1253
1254 Hint: sometimes appending C<", stopped"> to your message will cause it
1255 to make better sense when the string C<"at foo line 123"> is appended.
1256 Suppose you are running script "canasta".
1257
1258     die "/etc/games is no good";
1259     die "/etc/games is no good, stopped";
1260
1261 produce, respectively
1262
1263     /etc/games is no good at canasta line 123.
1264     /etc/games is no good, stopped at canasta line 123.
1265
1266 See also exit(), warn(), and the Carp module.
1267
1268 If LIST is empty and C<$@> already contains a value (typically from a
1269 previous eval) that value is reused after appending C<"\t...propagated">.
1270 This is useful for propagating exceptions:
1271
1272     eval { ... };
1273     die unless $@ =~ /Expected exception/;
1274
1275 If LIST is empty and C<$@> contains an object reference that has a
1276 C<PROPAGATE> method, that method will be called with additional file
1277 and line number parameters.  The return value replaces the value in
1278 C<$@>.  i.e. as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1279 were called.
1280
1281 If C<$@> is empty then the string C<"Died"> is used.
1282
1283 die() can also be called with a reference argument.  If this happens to be
1284 trapped within an eval(), $@ contains the reference.  This behavior permits
1285 a more elaborate exception handling implementation using objects that
1286 maintain arbitrary state about the nature of the exception.  Such a scheme
1287 is sometimes preferable to matching particular string values of $@ using
1288 regular expressions.  Because $@ is a global variable, and eval() may be
1289 used within object implementations, care must be taken that analyzing the
1290 error object doesn't replace the reference in the global variable.  The
1291 easiest solution is to make a local copy of the reference before doing
1292 other manipulations.  Here's an example:
1293
1294     use Scalar::Util 'blessed';
1295
1296     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1297     if (my $ev_err = $@) {
1298         if (blessed($ev_err) && $ev_err->isa("Some::Module::Exception")) {
1299             # handle Some::Module::Exception
1300         }
1301         else {
1302             # handle all other possible exceptions
1303         }
1304     }
1305
1306 Because perl will stringify uncaught exception messages before displaying
1307 them, you may want to overload stringification operations on such custom
1308 exception objects.  See L<overload> for details about that.
1309
1310 You can arrange for a callback to be run just before the C<die>
1311 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1312 handler will be called with the error text and can change the error
1313 message, if it sees fit, by calling C<die> again.  See
1314 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1315 L<"eval BLOCK"> for some examples.  Although this feature was 
1316 to be run only right before your program was to exit, this is not
1317 currently the case--the C<$SIG{__DIE__}> hook is currently called
1318 even inside eval()ed blocks/strings!  If one wants the hook to do
1319 nothing in such situations, put
1320
1321         die @_ if $^S;
1322
1323 as the first line of the handler (see L<perlvar/$^S>).  Because
1324 this promotes strange action at a distance, this counterintuitive
1325 behavior may be fixed in a future release.
1326
1327 =item do BLOCK
1328 X<do> X<block>
1329
1330 Not really a function.  Returns the value of the last command in the
1331 sequence of commands indicated by BLOCK.  When modified by the C<while> or
1332 C<until> loop modifier, executes the BLOCK once before testing the loop
1333 condition. (On other statements the loop modifiers test the conditional
1334 first.)
1335
1336 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1337 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1338 See L<perlsyn> for alternative strategies.
1339
1340 =item do SUBROUTINE(LIST)
1341 X<do>
1342
1343 This form of subroutine call is deprecated.  See L<perlsub>.
1344
1345 =item do EXPR
1346 X<do>
1347
1348 Uses the value of EXPR as a filename and executes the contents of the
1349 file as a Perl script.
1350
1351     do 'stat.pl';
1352
1353 is just like
1354
1355     eval `cat stat.pl`;
1356
1357 except that it's more efficient and concise, keeps track of the current
1358 filename for error messages, searches the @INC directories, and updates
1359 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1360 variables.  It also differs in that code evaluated with C<do FILENAME>
1361 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1362 same, however, in that it does reparse the file every time you call it,
1363 so you probably don't want to do this inside a loop.
1364
1365 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1366 error.  If C<do> can read the file but cannot compile it, it
1367 returns undef and sets an error message in C<$@>.   If the file is
1368 successfully compiled, C<do> returns the value of the last expression
1369 evaluated.
1370
1371 Note that inclusion of library modules is better done with the
1372 C<use> and C<require> operators, which also do automatic error checking
1373 and raise an exception if there's a problem.
1374
1375 You might like to use C<do> to read in a program configuration
1376 file.  Manual error checking can be done this way:
1377
1378     # read in config files: system first, then user
1379     for $file ("/share/prog/defaults.rc",
1380                "$ENV{HOME}/.someprogrc")
1381    {
1382         unless ($return = do $file) {
1383             warn "couldn't parse $file: $@" if $@;
1384             warn "couldn't do $file: $!"    unless defined $return;
1385             warn "couldn't run $file"       unless $return;
1386         }
1387     }
1388
1389 =item dump LABEL
1390 X<dump> X<core> X<undump>
1391
1392 =item dump
1393
1394 This function causes an immediate core dump.  See also the B<-u>
1395 command-line switch in L<perlrun>, which does the same thing.
1396 Primarily this is so that you can use the B<undump> program (not
1397 supplied) to turn your core dump into an executable binary after
1398 having initialized all your variables at the beginning of the
1399 program.  When the new binary is executed it will begin by executing
1400 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1401 Think of it as a goto with an intervening core dump and reincarnation.
1402 If C<LABEL> is omitted, restarts the program from the top.
1403
1404 B<WARNING>: Any files opened at the time of the dump will I<not>
1405 be open any more when the program is reincarnated, with possible
1406 resulting confusion on the part of Perl.
1407
1408 This function is now largely obsolete, mostly because it's very hard to
1409 convert a core file into an executable. That's why you should now invoke
1410 it as C<CORE::dump()>, if you don't want to be warned against a possible
1411 typo.
1412
1413 =item each HASH
1414 X<each> X<hash, iterator>
1415
1416 When called in list context, returns a 2-element list consisting of the
1417 key and value for the next element of a hash, so that you can iterate over
1418 it.  When called in scalar context, returns only the key for the next
1419 element in the hash.
1420
1421 Entries are returned in an apparently random order.  The actual random
1422 order is subject to change in future versions of perl, but it is
1423 guaranteed to be in the same order as either the C<keys> or C<values>
1424 function would produce on the same (unmodified) hash.  Since Perl
1425 5.8.1 the ordering is different even between different runs of Perl
1426 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1427
1428 When the hash is entirely read, a null array is returned in list context
1429 (which when assigned produces a false (C<0>) value), and C<undef> in
1430 scalar context.  The next call to C<each> after that will start iterating
1431 again.  There is a single iterator for each hash, shared by all C<each>,
1432 C<keys>, and C<values> function calls in the program; it can be reset by
1433 reading all the elements from the hash, or by evaluating C<keys HASH> or
1434 C<values HASH>.  If you add or delete elements of a hash while you're
1435 iterating over it, you may get entries skipped or duplicated, so
1436 don't.  Exception: It is always safe to delete the item most recently
1437 returned by C<each()>, which means that the following code will work:
1438
1439         while (($key, $value) = each %hash) {
1440           print $key, "\n";
1441           delete $hash{$key};   # This is safe
1442         }
1443
1444 The following prints out your environment like the printenv(1) program,
1445 only in a different order:
1446
1447     while (($key,$value) = each %ENV) {
1448         print "$key=$value\n";
1449     }
1450
1451 See also C<keys>, C<values> and C<sort>.
1452
1453 =item eof FILEHANDLE
1454 X<eof>
1455 X<end of file>
1456 X<end-of-file>
1457
1458 =item eof ()
1459
1460 =item eof
1461
1462 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1463 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1464 gives the real filehandle.  (Note that this function actually
1465 reads a character and then C<ungetc>s it, so isn't very useful in an
1466 interactive context.)  Do not read from a terminal file (or call
1467 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1468 as terminals may lose the end-of-file condition if you do.
1469
1470 An C<eof> without an argument uses the last file read.  Using C<eof()>
1471 with empty parentheses is very different.  It refers to the pseudo file
1472 formed from the files listed on the command line and accessed via the
1473 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1474 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1475 used will cause C<@ARGV> to be examined to determine if input is
1476 available.   Similarly, an C<eof()> after C<< <> >> has returned
1477 end-of-file will assume you are processing another C<@ARGV> list,
1478 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1479 see L<perlop/"I/O Operators">.
1480
1481 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1482 detect the end of each file, C<eof()> will only detect the end of the
1483 last file.  Examples:
1484
1485     # reset line numbering on each input file
1486     while (<>) {
1487         next if /^\s*#/;        # skip comments
1488         print "$.\t$_";
1489     } continue {
1490         close ARGV  if eof;     # Not eof()!
1491     }
1492
1493     # insert dashes just before last line of last file
1494     while (<>) {
1495         if (eof()) {            # check for end of last file
1496             print "--------------\n";
1497         }
1498         print;
1499         last if eof();          # needed if we're reading from a terminal
1500     }
1501
1502 Practical hint: you almost never need to use C<eof> in Perl, because the
1503 input operators typically return C<undef> when they run out of data, or if
1504 there was an error.
1505
1506 =item eval EXPR
1507 X<eval> X<try> X<catch> X<evaluate> X<parse> X<execute>
1508 X<error, handling> X<exception, handling>
1509
1510 =item eval BLOCK
1511
1512 =item eval
1513
1514 In the first form, the return value of EXPR is parsed and executed as if it
1515 were a little Perl program.  The value of the expression (which is itself
1516 determined within scalar context) is first parsed, and if there weren't any
1517 errors, executed in the lexical context of the current Perl program, so
1518 that any variable settings or subroutine and format definitions remain
1519 afterwards.  Note that the value is parsed every time the C<eval> executes.
1520 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1521 delay parsing and subsequent execution of the text of EXPR until run time.
1522
1523 In the second form, the code within the BLOCK is parsed only once--at the
1524 same time the code surrounding the C<eval> itself was parsed--and executed
1525 within the context of the current Perl program.  This form is typically
1526 used to trap exceptions more efficiently than the first (see below), while
1527 also providing the benefit of checking the code within BLOCK at compile
1528 time.
1529
1530 The final semicolon, if any, may be omitted from the value of EXPR or within
1531 the BLOCK.
1532
1533 In both forms, the value returned is the value of the last expression
1534 evaluated inside the mini-program; a return statement may be also used, just
1535 as with subroutines.  The expression providing the return value is evaluated
1536 in void, scalar, or list context, depending on the context of the C<eval> 
1537 itself.  See L</wantarray> for more on how the evaluation context can be 
1538 determined.
1539
1540 If there is a syntax error or runtime error, or a C<die> statement is
1541 executed, an undefined value is returned by C<eval>, and C<$@> is set to the
1542 error message.  If there was no error, C<$@> is guaranteed to be a null
1543 string.  Beware that using C<eval> neither silences perl from printing
1544 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1545 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1546 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1547 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1548
1549 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1550 determining whether a particular feature (such as C<socket> or C<symlink>)
1551 is implemented.  It is also Perl's exception trapping mechanism, where
1552 the die operator is used to raise exceptions.
1553
1554 If the code to be executed doesn't vary, you may use the eval-BLOCK
1555 form to trap run-time errors without incurring the penalty of
1556 recompiling each time.  The error, if any, is still returned in C<$@>.
1557 Examples:
1558
1559     # make divide-by-zero nonfatal
1560     eval { $answer = $a / $b; }; warn $@ if $@;
1561
1562     # same thing, but less efficient
1563     eval '$answer = $a / $b'; warn $@ if $@;
1564
1565     # a compile-time error
1566     eval { $answer = };                 # WRONG
1567
1568     # a run-time error
1569     eval '$answer =';   # sets $@
1570
1571 Using the C<eval{}> form as an exception trap in libraries does have some
1572 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
1573 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
1574 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1575 as shown in this example:
1576
1577     # a very private exception trap for divide-by-zero
1578     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1579     warn $@ if $@;
1580
1581 This is especially significant, given that C<__DIE__> hooks can call
1582 C<die> again, which has the effect of changing their error messages:
1583
1584     # __DIE__ hooks may modify error messages
1585     {
1586        local $SIG{'__DIE__'} =
1587               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1588        eval { die "foo lives here" };
1589        print $@ if $@;                # prints "bar lives here"
1590     }
1591
1592 Because this promotes action at a distance, this counterintuitive behavior
1593 may be fixed in a future release.
1594
1595 With an C<eval>, you should be especially careful to remember what's
1596 being looked at when:
1597
1598     eval $x;            # CASE 1
1599     eval "$x";          # CASE 2
1600
1601     eval '$x';          # CASE 3
1602     eval { $x };        # CASE 4
1603
1604     eval "\$$x++";      # CASE 5
1605     $$x++;              # CASE 6
1606
1607 Cases 1 and 2 above behave identically: they run the code contained in
1608 the variable $x.  (Although case 2 has misleading double quotes making
1609 the reader wonder what else might be happening (nothing is).)  Cases 3
1610 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1611 does nothing but return the value of $x.  (Case 4 is preferred for
1612 purely visual reasons, but it also has the advantage of compiling at
1613 compile-time instead of at run-time.)  Case 5 is a place where
1614 normally you I<would> like to use double quotes, except that in this
1615 particular situation, you can just use symbolic references instead, as
1616 in case 6.
1617
1618 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1619 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1620
1621 Note that as a very special case, an C<eval ''> executed within the C<DB>
1622 package doesn't see the usual surrounding lexical scope, but rather the
1623 scope of the first non-DB piece of code that called it. You don't normally
1624 need to worry about this unless you are writing a Perl debugger.
1625
1626 =item exec LIST
1627 X<exec> X<execute>
1628
1629 =item exec PROGRAM LIST
1630
1631 The C<exec> function executes a system command I<and never returns>--
1632 use C<system> instead of C<exec> if you want it to return.  It fails and
1633 returns false only if the command does not exist I<and> it is executed
1634 directly instead of via your system's command shell (see below).
1635
1636 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1637 warns you if there is a following statement which isn't C<die>, C<warn>,
1638 or C<exit> (if C<-w> is set  -  but you always do that).   If you
1639 I<really> want to follow an C<exec> with some other statement, you
1640 can use one of these styles to avoid the warning:
1641
1642     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1643     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1644
1645 If there is more than one argument in LIST, or if LIST is an array
1646 with more than one value, calls execvp(3) with the arguments in LIST.
1647 If there is only one scalar argument or an array with one element in it,
1648 the argument is checked for shell metacharacters, and if there are any,
1649 the entire argument is passed to the system's command shell for parsing
1650 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1651 If there are no shell metacharacters in the argument, it is split into
1652 words and passed directly to C<execvp>, which is more efficient.
1653 Examples:
1654
1655     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1656     exec "sort $outfile | uniq";
1657
1658 If you don't really want to execute the first argument, but want to lie
1659 to the program you are executing about its own name, you can specify
1660 the program you actually want to run as an "indirect object" (without a
1661 comma) in front of the LIST.  (This always forces interpretation of the
1662 LIST as a multivalued list, even if there is only a single scalar in
1663 the list.)  Example:
1664
1665     $shell = '/bin/csh';
1666     exec $shell '-sh';          # pretend it's a login shell
1667
1668 or, more directly,
1669
1670     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1671
1672 When the arguments get executed via the system shell, results will
1673 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1674 for details.
1675
1676 Using an indirect object with C<exec> or C<system> is also more
1677 secure.  This usage (which also works fine with system()) forces
1678 interpretation of the arguments as a multivalued list, even if the
1679 list had just one argument.  That way you're safe from the shell
1680 expanding wildcards or splitting up words with whitespace in them.
1681
1682     @args = ( "echo surprise" );
1683
1684     exec @args;               # subject to shell escapes
1685                                 # if @args == 1
1686     exec { $args[0] } @args;  # safe even with one-arg list
1687
1688 The first version, the one without the indirect object, ran the I<echo>
1689 program, passing it C<"surprise"> an argument.  The second version
1690 didn't--it tried to run a program literally called I<"echo surprise">,
1691 didn't find it, and set C<$?> to a non-zero value indicating failure.
1692
1693 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1694 output before the exec, but this may not be supported on some platforms
1695 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1696 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1697 open handles in order to avoid lost output.
1698
1699 Note that C<exec> will not call your C<END> blocks, nor will it call
1700 any C<DESTROY> methods in your objects.
1701
1702 =item exists EXPR
1703 X<exists> X<autovivification>
1704
1705 Given an expression that specifies a hash element or array element,
1706 returns true if the specified element in the hash or array has ever
1707 been initialized, even if the corresponding value is undefined.  The
1708 element is not autovivified if it doesn't exist.
1709
1710     print "Exists\n"    if exists $hash{$key};
1711     print "Defined\n"   if defined $hash{$key};
1712     print "True\n"      if $hash{$key};
1713
1714     print "Exists\n"    if exists $array[$index];
1715     print "Defined\n"   if defined $array[$index];
1716     print "True\n"      if $array[$index];
1717
1718 A hash or array element can be true only if it's defined, and defined if
1719 it exists, but the reverse doesn't necessarily hold true.
1720
1721 Given an expression that specifies the name of a subroutine,
1722 returns true if the specified subroutine has ever been declared, even
1723 if it is undefined.  Mentioning a subroutine name for exists or defined
1724 does not count as declaring it.  Note that a subroutine which does not
1725 exist may still be callable: its package may have an C<AUTOLOAD>
1726 method that makes it spring into existence the first time that it is
1727 called -- see L<perlsub>.
1728
1729     print "Exists\n"    if exists &subroutine;
1730     print "Defined\n"   if defined &subroutine;
1731
1732 Note that the EXPR can be arbitrarily complicated as long as the final
1733 operation is a hash or array key lookup or subroutine name:
1734
1735     if (exists $ref->{A}->{B}->{$key})  { }
1736     if (exists $hash{A}{B}{$key})       { }
1737
1738     if (exists $ref->{A}->{B}->[$ix])   { }
1739     if (exists $hash{A}{B}[$ix])        { }
1740
1741     if (exists &{$ref->{A}{B}{$key}})   { }
1742
1743 Although the deepest nested array or hash will not spring into existence
1744 just because its existence was tested, any intervening ones will.
1745 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1746 into existence due to the existence test for the $key element above.
1747 This happens anywhere the arrow operator is used, including even:
1748
1749     undef $ref;
1750     if (exists $ref->{"Some key"})      { }
1751     print $ref;             # prints HASH(0x80d3d5c)
1752
1753 This surprising autovivification in what does not at first--or even
1754 second--glance appear to be an lvalue context may be fixed in a future
1755 release.
1756
1757 Use of a subroutine call, rather than a subroutine name, as an argument
1758 to exists() is an error.
1759
1760     exists &sub;        # OK
1761     exists &sub();      # Error
1762
1763 =item exit EXPR
1764 X<exit> X<terminate> X<abort>
1765
1766 =item exit
1767
1768 Evaluates EXPR and exits immediately with that value.    Example:
1769
1770     $ans = <STDIN>;
1771     exit 0 if $ans =~ /^[Xx]/;
1772
1773 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1774 universally recognized values for EXPR are C<0> for success and C<1>
1775 for error; other values are subject to interpretation depending on the
1776 environment in which the Perl program is running.  For example, exiting
1777 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1778 the mailer to return the item undelivered, but that's not true everywhere.
1779
1780 Don't use C<exit> to abort a subroutine if there's any chance that
1781 someone might want to trap whatever error happened.  Use C<die> instead,
1782 which can be trapped by an C<eval>.
1783
1784 The exit() function does not always exit immediately.  It calls any
1785 defined C<END> routines first, but these C<END> routines may not
1786 themselves abort the exit.  Likewise any object destructors that need to
1787 be called are called before the real exit.  If this is a problem, you
1788 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1789 See L<perlmod> for details.
1790
1791 =item exp EXPR
1792 X<exp> X<exponential> X<antilog> X<antilogarithm> X<e>
1793
1794 =item exp
1795
1796 Returns I<e> (the natural logarithm base) to the power of EXPR.
1797 If EXPR is omitted, gives C<exp($_)>.
1798
1799 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1800 X<fcntl>
1801
1802 Implements the fcntl(2) function.  You'll probably have to say
1803
1804     use Fcntl;
1805
1806 first to get the correct constant definitions.  Argument processing and
1807 value return works just like C<ioctl> below.
1808 For example:
1809
1810     use Fcntl;
1811     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1812         or die "can't fcntl F_GETFL: $!";
1813
1814 You don't have to check for C<defined> on the return from C<fcntl>.
1815 Like C<ioctl>, it maps a C<0> return from the system call into
1816 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1817 in numeric context.  It is also exempt from the normal B<-w> warnings
1818 on improper numeric conversions.
1819
1820 Note that C<fcntl> will produce a fatal error if used on a machine that
1821 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1822 manpage to learn what functions are available on your system.
1823
1824 Here's an example of setting a filehandle named C<REMOTE> to be
1825 non-blocking at the system level.  You'll have to negotiate C<$|>
1826 on your own, though.
1827
1828     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
1829
1830     $flags = fcntl(REMOTE, F_GETFL, 0)
1831                 or die "Can't get flags for the socket: $!\n";
1832
1833     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
1834                 or die "Can't set flags for the socket: $!\n";
1835
1836 =item fileno FILEHANDLE
1837 X<fileno>
1838
1839 Returns the file descriptor for a filehandle, or undefined if the
1840 filehandle is not open.  This is mainly useful for constructing
1841 bitmaps for C<select> and low-level POSIX tty-handling operations.
1842 If FILEHANDLE is an expression, the value is taken as an indirect
1843 filehandle, generally its name.
1844
1845 You can use this to find out whether two handles refer to the
1846 same underlying descriptor:
1847
1848     if (fileno(THIS) == fileno(THAT)) {
1849         print "THIS and THAT are dups\n";
1850     }
1851
1852 (Filehandles connected to memory objects via new features of C<open> may
1853 return undefined even though they are open.)
1854
1855
1856 =item flock FILEHANDLE,OPERATION
1857 X<flock> X<lock> X<locking>
1858
1859 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1860 for success, false on failure.  Produces a fatal error if used on a
1861 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1862 C<flock> is Perl's portable file locking interface, although it locks
1863 only entire files, not records.
1864
1865 Two potentially non-obvious but traditional C<flock> semantics are
1866 that it waits indefinitely until the lock is granted, and that its locks
1867 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1868 fewer guarantees.  This means that programs that do not also use C<flock>
1869 may modify files locked with C<flock>.  See L<perlport>, 
1870 your port's specific documentation, or your system-specific local manpages
1871 for details.  It's best to assume traditional behavior if you're writing
1872 portable programs.  (But if you're not, you should as always feel perfectly
1873 free to write for your own system's idiosyncrasies (sometimes called
1874 "features").  Slavish adherence to portability concerns shouldn't get
1875 in the way of your getting your job done.)
1876
1877 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1878 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1879 you can use the symbolic names if you import them from the Fcntl module,
1880 either individually, or as a group using the ':flock' tag.  LOCK_SH
1881 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1882 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1883 LOCK_SH or LOCK_EX then C<flock> will return immediately rather than blocking
1884 waiting for the lock (check the return status to see if you got it).
1885
1886 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1887 before locking or unlocking it.
1888
1889 Note that the emulation built with lockf(3) doesn't provide shared
1890 locks, and it requires that FILEHANDLE be open with write intent.  These
1891 are the semantics that lockf(3) implements.  Most if not all systems
1892 implement lockf(3) in terms of fcntl(2) locking, though, so the
1893 differing semantics shouldn't bite too many people.
1894
1895 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
1896 be open with read intent to use LOCK_SH and requires that it be open
1897 with write intent to use LOCK_EX.
1898
1899 Note also that some versions of C<flock> cannot lock things over the
1900 network; you would need to use the more system-specific C<fcntl> for
1901 that.  If you like you can force Perl to ignore your system's flock(2)
1902 function, and so provide its own fcntl(2)-based emulation, by passing
1903 the switch C<-Ud_flock> to the F<Configure> program when you configure
1904 perl.
1905
1906 Here's a mailbox appender for BSD systems.
1907
1908     use Fcntl ':flock'; # import LOCK_* constants
1909
1910     sub lock {
1911         flock(MBOX,LOCK_EX);
1912         # and, in case someone appended
1913         # while we were waiting...
1914         seek(MBOX, 0, 2);
1915     }
1916
1917     sub unlock {
1918         flock(MBOX,LOCK_UN);
1919     }
1920
1921     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1922             or die "Can't open mailbox: $!";
1923
1924     lock();
1925     print MBOX $msg,"\n\n";
1926     unlock();
1927
1928 On systems that support a real flock(), locks are inherited across fork()
1929 calls, whereas those that must resort to the more capricious fcntl()
1930 function lose the locks, making it harder to write servers.
1931
1932 See also L<DB_File> for other flock() examples.
1933
1934 =item fork
1935 X<fork> X<child> X<parent>
1936
1937 Does a fork(2) system call to create a new process running the
1938 same program at the same point.  It returns the child pid to the
1939 parent process, C<0> to the child process, or C<undef> if the fork is
1940 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
1941 are shared, while everything else is copied.  On most systems supporting
1942 fork(), great care has gone into making it extremely efficient (for
1943 example, using copy-on-write technology on data pages), making it the
1944 dominant paradigm for multitasking over the last few decades.
1945
1946 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1947 output before forking the child process, but this may not be supported
1948 on some platforms (see L<perlport>).  To be safe, you may need to set
1949 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1950 C<IO::Handle> on any open handles in order to avoid duplicate output.
1951
1952 If you C<fork> without ever waiting on your children, you will
1953 accumulate zombies.  On some systems, you can avoid this by setting
1954 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
1955 forking and reaping moribund children.
1956
1957 Note that if your forked child inherits system file descriptors like
1958 STDIN and STDOUT that are actually connected by a pipe or socket, even
1959 if you exit, then the remote server (such as, say, a CGI script or a
1960 backgrounded job launched from a remote shell) won't think you're done.
1961 You should reopen those to F</dev/null> if it's any issue.
1962
1963 =item format
1964 X<format>
1965
1966 Declare a picture format for use by the C<write> function.  For
1967 example:
1968
1969     format Something =
1970         Test: @<<<<<<<< @||||| @>>>>>
1971               $str,     $%,    '$' . int($num)
1972     .
1973
1974     $str = "widget";
1975     $num = $cost/$quantity;
1976     $~ = 'Something';
1977     write;
1978
1979 See L<perlform> for many details and examples.
1980
1981 =item formline PICTURE,LIST
1982 X<formline>
1983
1984 This is an internal function used by C<format>s, though you may call it,
1985 too.  It formats (see L<perlform>) a list of values according to the
1986 contents of PICTURE, placing the output into the format output
1987 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1988 Eventually, when a C<write> is done, the contents of
1989 C<$^A> are written to some filehandle.  You could also read C<$^A>
1990 and then set C<$^A> back to C<"">.  Note that a format typically
1991 does one C<formline> per line of form, but the C<formline> function itself
1992 doesn't care how many newlines are embedded in the PICTURE.  This means
1993 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1994 You may therefore need to use multiple formlines to implement a single
1995 record format, just like the format compiler.
1996
1997 Be careful if you put double quotes around the picture, because an C<@>
1998 character may be taken to mean the beginning of an array name.
1999 C<formline> always returns true.  See L<perlform> for other examples.
2000
2001 =item getc FILEHANDLE
2002 X<getc> X<getchar> X<character> X<file, read>
2003
2004 =item getc
2005
2006 Returns the next character from the input file attached to FILEHANDLE,
2007 or the undefined value at end of file, or if there was an error (in
2008 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
2009 STDIN.  This is not particularly efficient.  However, it cannot be
2010 used by itself to fetch single characters without waiting for the user
2011 to hit enter.  For that, try something more like:
2012
2013     if ($BSD_STYLE) {
2014         system "stty cbreak </dev/tty >/dev/tty 2>&1";
2015     }
2016     else {
2017         system "stty", '-icanon', 'eol', "\001";
2018     }
2019
2020     $key = getc(STDIN);
2021
2022     if ($BSD_STYLE) {
2023         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
2024     }
2025     else {
2026         system "stty", 'icanon', 'eol', '^@'; # ASCII null
2027     }
2028     print "\n";
2029
2030 Determination of whether $BSD_STYLE should be set
2031 is left as an exercise to the reader.
2032
2033 The C<POSIX::getattr> function can do this more portably on
2034 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
2035 module from your nearest CPAN site; details on CPAN can be found on
2036 L<perlmodlib/CPAN>.
2037
2038 =item getlogin
2039 X<getlogin> X<login>
2040
2041 This implements the C library function of the same name, which on most
2042 systems returns the current login from F</etc/utmp>, if any.  If null,
2043 use C<getpwuid>.
2044
2045     $login = getlogin || getpwuid($<) || "Kilroy";
2046
2047 Do not consider C<getlogin> for authentication: it is not as
2048 secure as C<getpwuid>.
2049
2050 =item getpeername SOCKET
2051 X<getpeername> X<peer>
2052
2053 Returns the packed sockaddr address of other end of the SOCKET connection.
2054
2055     use Socket;
2056     $hersockaddr    = getpeername(SOCK);
2057     ($port, $iaddr) = sockaddr_in($hersockaddr);
2058     $herhostname    = gethostbyaddr($iaddr, AF_INET);
2059     $herstraddr     = inet_ntoa($iaddr);
2060
2061 =item getpgrp PID
2062 X<getpgrp> X<group>
2063
2064 Returns the current process group for the specified PID.  Use
2065 a PID of C<0> to get the current process group for the
2066 current process.  Will raise an exception if used on a machine that
2067 doesn't implement getpgrp(2).  If PID is omitted, returns process
2068 group of current process.  Note that the POSIX version of C<getpgrp>
2069 does not accept a PID argument, so only C<PID==0> is truly portable.
2070
2071 =item getppid
2072 X<getppid> X<parent> X<pid>
2073
2074 Returns the process id of the parent process.
2075
2076 Note for Linux users: on Linux, the C functions C<getpid()> and
2077 C<getppid()> return different values from different threads. In order to
2078 be portable, this behavior is not reflected by the perl-level function
2079 C<getppid()>, that returns a consistent value across threads. If you want
2080 to call the underlying C<getppid()>, you may use the CPAN module
2081 C<Linux::Pid>.
2082
2083 =item getpriority WHICH,WHO
2084 X<getpriority> X<priority> X<nice>
2085
2086 Returns the current priority for a process, a process group, or a user.
2087 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
2088 machine that doesn't implement getpriority(2).
2089
2090 =item getpwnam NAME
2091 X<getpwnam> X<getgrnam> X<gethostbyname> X<getnetbyname> X<getprotobyname>
2092 X<getpwuid> X<getgrgid> X<getservbyname> X<gethostbyaddr> X<getnetbyaddr>
2093 X<getprotobynumber> X<getservbyport> X<getpwent> X<getgrent> X<gethostent>
2094 X<getnetent> X<getprotoent> X<getservent> X<setpwent> X<setgrent> X<sethostent>
2095 X<setnetent> X<setprotoent> X<setservent> X<endpwent> X<endgrent> X<endhostent>
2096 X<endnetent> X<endprotoent> X<endservent> 
2097
2098 =item getgrnam NAME
2099
2100 =item gethostbyname NAME
2101
2102 =item getnetbyname NAME
2103
2104 =item getprotobyname NAME
2105
2106 =item getpwuid UID
2107
2108 =item getgrgid GID
2109
2110 =item getservbyname NAME,PROTO
2111
2112 =item gethostbyaddr ADDR,ADDRTYPE
2113
2114 =item getnetbyaddr ADDR,ADDRTYPE
2115
2116 =item getprotobynumber NUMBER
2117
2118 =item getservbyport PORT,PROTO
2119
2120 =item getpwent
2121
2122 =item getgrent
2123
2124 =item gethostent
2125
2126 =item getnetent
2127
2128 =item getprotoent
2129
2130 =item getservent
2131
2132 =item setpwent
2133
2134 =item setgrent
2135
2136 =item sethostent STAYOPEN
2137
2138 =item setnetent STAYOPEN
2139
2140 =item setprotoent STAYOPEN
2141
2142 =item setservent STAYOPEN
2143
2144 =item endpwent
2145
2146 =item endgrent
2147
2148 =item endhostent
2149
2150 =item endnetent
2151
2152 =item endprotoent
2153
2154 =item endservent
2155
2156 These routines perform the same functions as their counterparts in the
2157 system library.  In list context, the return values from the
2158 various get routines are as follows:
2159
2160     ($name,$passwd,$uid,$gid,
2161        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
2162     ($name,$passwd,$gid,$members) = getgr*
2163     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2164     ($name,$aliases,$addrtype,$net) = getnet*
2165     ($name,$aliases,$proto) = getproto*
2166     ($name,$aliases,$port,$proto) = getserv*
2167
2168 (If the entry doesn't exist you get a null list.)
2169
2170 The exact meaning of the $gcos field varies but it usually contains
2171 the real name of the user (as opposed to the login name) and other
2172 information pertaining to the user.  Beware, however, that in many
2173 system users are able to change this information and therefore it
2174 cannot be trusted and therefore the $gcos is tainted (see
2175 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2176 login shell, are also tainted, because of the same reason.
2177
2178 In scalar context, you get the name, unless the function was a
2179 lookup by name, in which case you get the other thing, whatever it is.
2180 (If the entry doesn't exist you get the undefined value.)  For example:
2181
2182     $uid   = getpwnam($name);
2183     $name  = getpwuid($num);
2184     $name  = getpwent();
2185     $gid   = getgrnam($name);
2186     $name  = getgrgid($num);
2187     $name  = getgrent();
2188     #etc.
2189
2190 In I<getpw*()> the fields $quota, $comment, and $expire are special
2191 cases in the sense that in many systems they are unsupported.  If the
2192 $quota is unsupported, it is an empty scalar.  If it is supported, it
2193 usually encodes the disk quota.  If the $comment field is unsupported,
2194 it is an empty scalar.  If it is supported it usually encodes some
2195 administrative comment about the user.  In some systems the $quota
2196 field may be $change or $age, fields that have to do with password
2197 aging.  In some systems the $comment field may be $class.  The $expire
2198 field, if present, encodes the expiration period of the account or the
2199 password.  For the availability and the exact meaning of these fields
2200 in your system, please consult your getpwnam(3) documentation and your
2201 F<pwd.h> file.  You can also find out from within Perl what your
2202 $quota and $comment fields mean and whether you have the $expire field
2203 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2204 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2205 files are only supported if your vendor has implemented them in the
2206 intuitive fashion that calling the regular C library routines gets the
2207 shadow versions if you're running under privilege or if there exists
2208 the shadow(3) functions as found in System V (this includes Solaris
2209 and Linux.)  Those systems that implement a proprietary shadow password
2210 facility are unlikely to be supported.
2211
2212 The $members value returned by I<getgr*()> is a space separated list of
2213 the login names of the members of the group.
2214
2215 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2216 C, it will be returned to you via C<$?> if the function call fails.  The
2217 C<@addrs> value returned by a successful call is a list of the raw
2218 addresses returned by the corresponding system library call.  In the
2219 Internet domain, each address is four bytes long and you can unpack it
2220 by saying something like:
2221
2222     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2223
2224 The Socket library makes this slightly easier:
2225
2226     use Socket;
2227     $iaddr = inet_aton("127.1"); # or whatever address
2228     $name  = gethostbyaddr($iaddr, AF_INET);
2229
2230     # or going the other way
2231     $straddr = inet_ntoa($iaddr);
2232
2233 If you get tired of remembering which element of the return list
2234 contains which return value, by-name interfaces are provided
2235 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2236 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2237 and C<User::grent>.  These override the normal built-ins, supplying
2238 versions that return objects with the appropriate names
2239 for each field.  For example:
2240
2241    use File::stat;
2242    use User::pwent;
2243    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2244
2245 Even though it looks like they're the same method calls (uid),
2246 they aren't, because a C<File::stat> object is different from
2247 a C<User::pwent> object.
2248
2249 =item getsockname SOCKET
2250 X<getsockname>
2251
2252 Returns the packed sockaddr address of this end of the SOCKET connection,
2253 in case you don't know the address because you have several different
2254 IPs that the connection might have come in on.
2255
2256     use Socket;
2257     $mysockaddr = getsockname(SOCK);
2258     ($port, $myaddr) = sockaddr_in($mysockaddr);
2259     printf "Connect to %s [%s]\n",
2260        scalar gethostbyaddr($myaddr, AF_INET),
2261        inet_ntoa($myaddr);
2262
2263 =item getsockopt SOCKET,LEVEL,OPTNAME
2264 X<getsockopt>
2265
2266 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2267 Options may exist at multiple protocol levels depending on the socket
2268 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2269 C<Socket> module) will exist. To query options at another level the
2270 protocol number of the appropriate protocol controlling the option
2271 should be supplied. For example, to indicate that an option is to be
2272 interpreted by the TCP protocol, LEVEL should be set to the protocol
2273 number of TCP, which you can get using getprotobyname.
2274
2275 The call returns a packed string representing the requested socket option,
2276 or C<undef> if there is an error (the error reason will be in $!). What
2277 exactly is in the packed string depends in the LEVEL and OPTNAME, consult
2278 your system documentation for details. A very common case however is that
2279 the option is an integer, in which case the result will be a packed
2280 integer which you can decode using unpack with the C<i> (or C<I>) format.
2281
2282 An example testing if Nagle's algorithm is turned on on a socket:
2283
2284     use Socket qw(:all);
2285
2286     defined(my $tcp = getprotobyname("tcp"))
2287         or die "Could not determine the protocol number for tcp";
2288     # my $tcp = IPPROTO_TCP; # Alternative
2289     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2290         or die "Could not query TCP_NODELAY socket option: $!";
2291     my $nodelay = unpack("I", $packed);
2292     print "Nagle's algorithm is turned ", $nodelay ? "off\n" : "on\n";
2293
2294
2295 =item glob EXPR
2296 X<glob> X<wildcard> X<filename, expansion> X<expand>
2297
2298 =item glob
2299
2300 In list context, returns a (possibly empty) list of filename expansions on
2301 the value of EXPR such as the standard Unix shell F</bin/csh> would do. In
2302 scalar context, glob iterates through such filename expansions, returning
2303 undef when the list is exhausted. This is the internal function
2304 implementing the C<< <*.c> >> operator, but you can use it directly. If
2305 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2306 more detail in L<perlop/"I/O Operators">.
2307
2308 Beginning with v5.6.0, this operator is implemented using the standard
2309 C<File::Glob> extension.  See L<File::Glob> for details.
2310
2311 =item gmtime EXPR
2312 X<gmtime> X<UTC> X<Greenwich>
2313
2314 =item gmtime
2315
2316 Works just like L<localtime> but the returned values are
2317 localized for the standard Greenwich time zone.
2318
2319 Note: when called in list context, $isdst, the last value
2320 returned by gmtime is always C<0>.  There is no
2321 Daylight Saving Time in GMT.
2322
2323 See L<perlport/gmtime> for portability concerns.
2324
2325 =item goto LABEL
2326 X<goto> X<jump> X<jmp>
2327
2328 =item goto EXPR
2329
2330 =item goto &NAME
2331
2332 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
2333 execution there.  It may not be used to go into any construct that
2334 requires initialization, such as a subroutine or a C<foreach> loop.  It
2335 also can't be used to go into a construct that is optimized away,
2336 or to get out of a block or subroutine given to C<sort>.
2337 It can be used to go almost anywhere else within the dynamic scope,
2338 including out of subroutines, but it's usually better to use some other
2339 construct such as C<last> or C<die>.  The author of Perl has never felt the
2340 need to use this form of C<goto> (in Perl, that is--C is another matter).
2341 (The difference being that C does not offer named loops combined with
2342 loop control.  Perl does, and this replaces most structured uses of C<goto>
2343 in other languages.)
2344
2345 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2346 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2347 necessarily recommended if you're optimizing for maintainability:
2348
2349     goto ("FOO", "BAR", "GLARCH")[$i];
2350
2351 The C<goto-&NAME> form is quite different from the other forms of
2352 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2353 doesn't have the stigma associated with other gotos.  Instead, it
2354 exits the current subroutine (losing any changes set by local()) and
2355 immediately calls in its place the named subroutine using the current
2356 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2357 load another subroutine and then pretend that the other subroutine had
2358 been called in the first place (except that any modifications to C<@_>
2359 in the current subroutine are propagated to the other subroutine.)
2360 After the C<goto>, not even C<caller> will be able to tell that this
2361 routine was called first.
2362
2363 NAME needn't be the name of a subroutine; it can be a scalar variable
2364 containing a code reference, or a block that evaluates to a code
2365 reference.
2366
2367 =item grep BLOCK LIST
2368 X<grep>
2369
2370 =item grep EXPR,LIST
2371
2372 This is similar in spirit to, but not the same as, grep(1) and its
2373 relatives.  In particular, it is not limited to using regular expressions.
2374
2375 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2376 C<$_> to each element) and returns the list value consisting of those
2377 elements for which the expression evaluated to true.  In scalar
2378 context, returns the number of times the expression was true.
2379
2380     @foo = grep(!/^#/, @bar);    # weed out comments
2381
2382 or equivalently,
2383
2384     @foo = grep {!/^#/} @bar;    # weed out comments
2385
2386 Note that C<$_> is an alias to the list value, so it can be used to
2387 modify the elements of the LIST.  While this is useful and supported,
2388 it can cause bizarre results if the elements of LIST are not variables.
2389 Similarly, grep returns aliases into the original list, much as a for
2390 loop's index variable aliases the list elements.  That is, modifying an
2391 element of a list returned by grep (for example, in a C<foreach>, C<map>
2392 or another C<grep>) actually modifies the element in the original list.
2393 This is usually something to be avoided when writing clear code.
2394
2395 If C<$_> is lexical in the scope where the C<grep> appears (because it has
2396 been declared with C<my $_>) then, in addition to being locally aliased to
2397 the list elements, C<$_> keeps being lexical inside the block; i.e. it
2398 can't be seen from the outside, avoiding any potential side-effects.
2399
2400 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2401
2402 =item hex EXPR
2403 X<hex> X<hexadecimal>
2404
2405 =item hex
2406
2407 Interprets EXPR as a hex string and returns the corresponding value.
2408 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
2409 L</oct>.)  If EXPR is omitted, uses C<$_>.
2410
2411     print hex '0xAf'; # prints '175'
2412     print hex 'aF';   # same
2413
2414 Hex strings may only represent integers.  Strings that would cause
2415 integer overflow trigger a warning.  Leading whitespace is not stripped,
2416 unlike oct(). To present something as hex, look into L</printf>,
2417 L</sprintf>, or L</unpack>.
2418
2419 =item import LIST
2420 X<import>
2421
2422 There is no builtin C<import> function.  It is just an ordinary
2423 method (subroutine) defined (or inherited) by modules that wish to export
2424 names to another module.  The C<use> function calls the C<import> method
2425 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2426
2427 =item index STR,SUBSTR,POSITION
2428 X<index> X<indexOf> X<InStr>
2429
2430 =item index STR,SUBSTR
2431
2432 The index function searches for one string within another, but without
2433 the wildcard-like behavior of a full regular-expression pattern match.
2434 It returns the position of the first occurrence of SUBSTR in STR at
2435 or after POSITION.  If POSITION is omitted, starts searching from the
2436 beginning of the string.  POSITION before the beginning of the string
2437 or after its end is treated as if it were the beginning or the end,
2438 respectively.  POSITION and the return value are based at C<0> (or whatever
2439 you've set the C<$[> variable to--but don't do that).  If the substring
2440 is not found, C<index> returns one less than the base, ordinarily C<-1>.
2441
2442 =item int EXPR
2443 X<int> X<integer> X<truncate> X<trunc> X<floor>
2444
2445 =item int
2446
2447 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2448 You should not use this function for rounding: one because it truncates
2449 towards C<0>, and two because machine representations of floating point
2450 numbers can sometimes produce counterintuitive results.  For example,
2451 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2452 because it's really more like -268.99999999999994315658 instead.  Usually,
2453 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2454 functions will serve you better than will int().
2455
2456 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2457 X<ioctl>
2458
2459 Implements the ioctl(2) function.  You'll probably first have to say
2460
2461     require "sys/ioctl.ph";     # probably in $Config{archlib}/sys/ioctl.ph
2462
2463 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
2464 exist or doesn't have the correct definitions you'll have to roll your
2465 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2466 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2467 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2468 written depending on the FUNCTION--a pointer to the string value of SCALAR
2469 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2470 has no string value but does have a numeric value, that value will be
2471 passed rather than a pointer to the string value.  To guarantee this to be
2472 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2473 functions may be needed to manipulate the values of structures used by
2474 C<ioctl>.
2475
2476 The return value of C<ioctl> (and C<fcntl>) is as follows:
2477
2478         if OS returns:          then Perl returns:
2479             -1                    undefined value
2480              0                  string "0 but true"
2481         anything else               that number
2482
2483 Thus Perl returns true on success and false on failure, yet you can
2484 still easily determine the actual value returned by the operating
2485 system:
2486
2487     $retval = ioctl(...) || -1;
2488     printf "System returned %d\n", $retval;
2489
2490 The special string C<"0 but true"> is exempt from B<-w> complaints
2491 about improper numeric conversions.
2492
2493 =item join EXPR,LIST
2494 X<join>
2495
2496 Joins the separate strings of LIST into a single string with fields
2497 separated by the value of EXPR, and returns that new string.  Example:
2498
2499     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2500
2501 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2502 first argument.  Compare L</split>.
2503
2504 =item keys HASH
2505 X<keys> X<key>
2506
2507 Returns a list consisting of all the keys of the named hash.
2508 (In scalar context, returns the number of keys.)
2509
2510 The keys are returned in an apparently random order.  The actual
2511 random order is subject to change in future versions of perl, but it
2512 is guaranteed to be the same order as either the C<values> or C<each>
2513 function produces (given that the hash has not been modified).  Since
2514 Perl 5.8.1 the ordering is different even between different runs of
2515 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
2516 Attacks">).
2517
2518 As a side effect, calling keys() resets the HASH's internal iterator
2519 (see L</each>).  In particular, calling keys() in void context resets
2520 the iterator with no other overhead.
2521
2522 Here is yet another way to print your environment:
2523
2524     @keys = keys %ENV;
2525     @values = values %ENV;
2526     while (@keys) {
2527         print pop(@keys), '=', pop(@values), "\n";
2528     }
2529
2530 or how about sorted by key:
2531
2532     foreach $key (sort(keys %ENV)) {
2533         print $key, '=', $ENV{$key}, "\n";
2534     }
2535
2536 The returned values are copies of the original keys in the hash, so
2537 modifying them will not affect the original hash.  Compare L</values>.
2538
2539 To sort a hash by value, you'll need to use a C<sort> function.
2540 Here's a descending numeric sort of a hash by its values:
2541
2542     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2543         printf "%4d %s\n", $hash{$key}, $key;
2544     }
2545
2546 As an lvalue C<keys> allows you to increase the number of hash buckets
2547 allocated for the given hash.  This can gain you a measure of efficiency if
2548 you know the hash is going to get big.  (This is similar to pre-extending
2549 an array by assigning a larger number to $#array.)  If you say
2550
2551     keys %hash = 200;
2552
2553 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2554 in fact, since it rounds up to the next power of two.  These
2555 buckets will be retained even if you do C<%hash = ()>, use C<undef
2556 %hash> if you want to free the storage while C<%hash> is still in scope.
2557 You can't shrink the number of buckets allocated for the hash using
2558 C<keys> in this way (but you needn't worry about doing this by accident,
2559 as trying has no effect).
2560
2561 See also C<each>, C<values> and C<sort>.
2562
2563 =item kill SIGNAL, LIST
2564 X<kill> X<signal>
2565
2566 Sends a signal to a list of processes.  Returns the number of
2567 processes successfully signaled (which is not necessarily the
2568 same as the number actually killed).
2569
2570     $cnt = kill 1, $child1, $child2;
2571     kill 9, @goners;
2572
2573 If SIGNAL is zero, no signal is sent to the process, but the kill(2)
2574 system call will check whether it's possible to send a signal to it (that
2575 means, to be brief, that the process is owned by the same user, or we are
2576 the super-user).  This is a useful way to check that a child process is
2577 alive (even if only as a zombie) and hasn't changed its UID.  See
2578 L<perlport> for notes on the portability of this construct.
2579
2580 Unlike in the shell, if SIGNAL is negative, it kills
2581 process groups instead of processes.  (On System V, a negative I<PROCESS>
2582 number will also kill process groups, but that's not portable.)  That
2583 means you usually want to use positive not negative signals.  You may also
2584 use a signal name in quotes.
2585
2586 See L<perlipc/"Signals"> for more details.
2587
2588 =item last LABEL
2589 X<last> X<break>
2590
2591 =item last
2592
2593 The C<last> command is like the C<break> statement in C (as used in
2594 loops); it immediately exits the loop in question.  If the LABEL is
2595 omitted, the command refers to the innermost enclosing loop.  The
2596 C<continue> block, if any, is not executed:
2597
2598     LINE: while (<STDIN>) {
2599         last LINE if /^$/;      # exit when done with header
2600         #...
2601     }
2602
2603 C<last> cannot be used to exit a block which returns a value such as
2604 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2605 a grep() or map() operation.
2606
2607 Note that a block by itself is semantically identical to a loop
2608 that executes once.  Thus C<last> can be used to effect an early
2609 exit out of such a block.
2610
2611 See also L</continue> for an illustration of how C<last>, C<next>, and
2612 C<redo> work.
2613
2614 =item lc EXPR
2615 X<lc> X<lowercase>
2616
2617 =item lc
2618
2619 Returns a lowercased version of EXPR.  This is the internal function
2620 implementing the C<\L> escape in double-quoted strings.  Respects
2621 current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>
2622 and L<perlunicode> for more details about locale and Unicode support.
2623
2624 If EXPR is omitted, uses C<$_>.
2625
2626 =item lcfirst EXPR
2627 X<lcfirst> X<lowercase>
2628
2629 =item lcfirst
2630
2631 Returns the value of EXPR with the first character lowercased.  This
2632 is the internal function implementing the C<\l> escape in
2633 double-quoted strings.  Respects current LC_CTYPE locale if C<use
2634 locale> in force.  See L<perllocale> and L<perlunicode> for more
2635 details about locale and Unicode support.
2636
2637 If EXPR is omitted, uses C<$_>.
2638
2639 =item length EXPR
2640 X<length> X<size>
2641
2642 =item length
2643
2644 Returns the length in I<characters> of the value of EXPR.  If EXPR is
2645 omitted, returns length of C<$_>.  Note that this cannot be used on
2646 an entire array or hash to find out how many elements these have.
2647 For that, use C<scalar @array> and C<scalar keys %hash> respectively.
2648
2649 Note the I<characters>: if the EXPR is in Unicode, you will get the
2650 number of characters, not the number of bytes.  To get the length
2651 of the internal string in bytes, use C<bytes::length(EXPR)>, see
2652 L<bytes>.  Note that the internal encoding is variable, and the number
2653 of bytes usually meaningless.  To get the number of bytes that the
2654 string would have when encoded as UTF-8, use
2655 C<length(Encoding::encode_utf8(EXPR))>.
2656
2657 =item link OLDFILE,NEWFILE
2658 X<link>
2659
2660 Creates a new filename linked to the old filename.  Returns true for
2661 success, false otherwise.
2662
2663 =item listen SOCKET,QUEUESIZE
2664 X<listen>
2665
2666 Does the same thing that the listen system call does.  Returns true if
2667 it succeeded, false otherwise.  See the example in
2668 L<perlipc/"Sockets: Client/Server Communication">.
2669
2670 =item local EXPR
2671 X<local>
2672
2673 You really probably want to be using C<my> instead, because C<local> isn't
2674 what most people think of as "local".  See
2675 L<perlsub/"Private Variables via my()"> for details.
2676
2677 A local modifies the listed variables to be local to the enclosing
2678 block, file, or eval.  If more than one value is listed, the list must
2679 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2680 for details, including issues with tied arrays and hashes.
2681
2682 =item localtime EXPR
2683 X<localtime> X<ctime>
2684
2685 =item localtime
2686
2687 Converts a time as returned by the time function to a 9-element list
2688 with the time analyzed for the local time zone.  Typically used as
2689 follows:
2690
2691     #  0    1    2     3     4    5     6     7     8
2692     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2693                                                 localtime(time);
2694
2695 All list elements are numeric, and come straight out of the C `struct
2696 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
2697 of the specified time.
2698
2699 C<$mday> is the day of the month, and C<$mon> is the month itself, in
2700 the range C<0..11> with 0 indicating January and 11 indicating December.
2701 This makes it easy to get a month name from a list:
2702
2703     my @abbr = qw( Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec );
2704     print "$abbr[$mon] $mday";
2705     # $mon=9, $mday=18 gives "Oct 18"
2706
2707 C<$year> is the number of years since 1900, not just the last two digits
2708 of the year.  That is, C<$year> is C<123> in year 2023.  The proper way
2709 to get a complete 4-digit year is simply:
2710
2711     $year += 1900;
2712
2713 Otherwise you create non-Y2K-compliant programs--and you wouldn't want
2714 to do that, would you?
2715
2716 To get the last two digits of the year (e.g., '01' in 2001) do:
2717
2718     $year = sprintf("%02d", $year % 100);
2719
2720 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
2721 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
2722 (or C<0..365> in leap years.)
2723
2724 C<$isdst> is true if the specified time occurs during Daylight Saving
2725 Time, false otherwise.
2726
2727 If EXPR is omitted, C<localtime()> uses the current time (C<localtime(time)>).
2728
2729 In scalar context, C<localtime()> returns the ctime(3) value:
2730
2731     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2732
2733 This scalar value is B<not> locale dependent but is a Perl builtin. For GMT
2734 instead of local time use the L</gmtime> builtin. See also the
2735 C<Time::Local> module (to convert the second, minutes, hours, ... back to
2736 the integer value returned by time()), and the L<POSIX> module's strftime(3)
2737 and mktime(3) functions.
2738
2739 To get somewhat similar but locale dependent date strings, set up your
2740 locale environment variables appropriately (please see L<perllocale>) and
2741 try for example:
2742
2743     use POSIX qw(strftime);
2744     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2745     # or for GMT formatted appropriately for your locale:
2746     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
2747
2748 Note that the C<%a> and C<%b>, the short forms of the day of the week
2749 and the month of the year, may not necessarily be three characters wide.
2750
2751 See L<perlport/localtime> for portability concerns.
2752
2753 The L<Time::gmtime> and L<Time::localtime> modules provides a convenient,
2754 by-name access mechanism to the gmtime() and localtime() functions,
2755 respectively.
2756
2757 For a comprehensive date and time representation look at the
2758 L<DateTime> module on CPAN.
2759
2760 =item lock THING
2761 X<lock>
2762
2763 This function places an advisory lock on a shared variable, or referenced
2764 object contained in I<THING> until the lock goes out of scope.
2765
2766 lock() is a "weak keyword" : this means that if you've defined a function
2767 by this name (before any calls to it), that function will be called
2768 instead. (However, if you've said C<use threads>, lock() is always a
2769 keyword.) See L<threads>.
2770
2771 =item log EXPR
2772 X<log> X<logarithm> X<e> X<ln> X<base>
2773
2774 =item log
2775
2776 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2777 returns log of C<$_>.  To get the log of another base, use basic algebra:
2778 The base-N log of a number is equal to the natural log of that number
2779 divided by the natural log of N.  For example:
2780
2781     sub log10 {
2782         my $n = shift;
2783         return log($n)/log(10);
2784     }
2785
2786 See also L</exp> for the inverse operation.
2787
2788 =item lstat EXPR
2789 X<lstat>
2790
2791 =item lstat
2792
2793 Does the same thing as the C<stat> function (including setting the
2794 special C<_> filehandle) but stats a symbolic link instead of the file
2795 the symbolic link points to.  If symbolic links are unimplemented on
2796 your system, a normal C<stat> is done.  For much more detailed
2797 information, please see the documentation for C<stat>.
2798
2799 If EXPR is omitted, stats C<$_>.
2800
2801 =item m//
2802
2803 The match operator.  See L<perlop>.
2804
2805 =item map BLOCK LIST
2806 X<map>
2807
2808 =item map EXPR,LIST
2809
2810 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2811 C<$_> to each element) and returns the list value composed of the
2812 results of each such evaluation.  In scalar context, returns the
2813 total number of elements so generated.  Evaluates BLOCK or EXPR in
2814 list context, so each element of LIST may produce zero, one, or
2815 more elements in the returned value.
2816
2817     @chars = map(chr, @nums);
2818
2819 translates a list of numbers to the corresponding characters.  And
2820
2821     %hash = map { get_a_key_for($_) => $_ } @array;
2822
2823 is just a funny way to write
2824
2825     %hash = ();
2826     foreach (@array) {
2827         $hash{get_a_key_for($_)} = $_;
2828     }
2829
2830 Note that C<$_> is an alias to the list value, so it can be used to
2831 modify the elements of the LIST.  While this is useful and supported,
2832 it can cause bizarre results if the elements of LIST are not variables.
2833 Using a regular C<foreach> loop for this purpose would be clearer in
2834 most cases.  See also L</grep> for an array composed of those items of
2835 the original list for which the BLOCK or EXPR evaluates to true.
2836
2837 If C<$_> is lexical in the scope where the C<map> appears (because it has
2838 been declared with C<my $_>), then, in addition to being locally aliased to
2839 the list elements, C<$_> keeps being lexical inside the block; that is, it
2840 can't be seen from the outside, avoiding any potential side-effects.
2841
2842 C<{> starts both hash references and blocks, so C<map { ...> could be either
2843 the start of map BLOCK LIST or map EXPR, LIST. Because perl doesn't look
2844 ahead for the closing C<}> it has to take a guess at which its dealing with
2845 based what it finds just after the C<{>. Usually it gets it right, but if it
2846 doesn't it won't realize something is wrong until it gets to the C<}> and
2847 encounters the missing (or unexpected) comma. The syntax error will be
2848 reported close to the C<}> but you'll need to change something near the C<{>
2849 such as using a unary C<+> to give perl some help:
2850
2851     %hash = map {  "\L$_", 1  } @array  # perl guesses EXPR.  wrong
2852     %hash = map { +"\L$_", 1  } @array  # perl guesses BLOCK. right
2853     %hash = map { ("\L$_", 1) } @array  # this also works
2854     %hash = map {  lc($_), 1  } @array  # as does this.
2855     %hash = map +( lc($_), 1 ), @array  # this is EXPR and works!
2856
2857     %hash = map  ( lc($_), 1 ), @array  # evaluates to (1, @array)
2858
2859 or to force an anon hash constructor use C<+{>:
2860
2861    @hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end
2862
2863 and you get list of anonymous hashes each with only 1 entry.
2864
2865 =item mkdir FILENAME,MASK
2866 X<mkdir> X<md> X<directory, create>
2867
2868 =item mkdir FILENAME
2869
2870 =item mkdir
2871
2872 Creates the directory specified by FILENAME, with permissions
2873 specified by MASK (as modified by C<umask>).  If it succeeds it
2874 returns true, otherwise it returns false and sets C<$!> (errno).
2875 If omitted, MASK defaults to 0777. If omitted, FILENAME defaults
2876 to C<$_>.
2877
2878 In general, it is better to create directories with permissive MASK,
2879 and let the user modify that with their C<umask>, than it is to supply
2880 a restrictive MASK and give the user no way to be more permissive.
2881 The exceptions to this rule are when the file or directory should be
2882 kept private (mail files, for instance).  The perlfunc(1) entry on
2883 C<umask> discusses the choice of MASK in more detail.
2884
2885 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
2886 number of trailing slashes.  Some operating and filesystems do not get
2887 this right, so Perl automatically removes all trailing slashes to keep
2888 everyone happy.
2889
2890 In order to recursively create a directory structure look at
2891 the C<mkpath> function of the L<File::Path> module.
2892
2893 =item msgctl ID,CMD,ARG
2894 X<msgctl>
2895
2896 Calls the System V IPC function msgctl(2).  You'll probably have to say
2897
2898     use IPC::SysV;
2899
2900 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2901 then ARG must be a variable that will hold the returned C<msqid_ds>
2902 structure.  Returns like C<ioctl>: the undefined value for error,
2903 C<"0 but true"> for zero, or the actual return value otherwise.  See also
2904 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::Semaphore> documentation.
2905
2906 =item msgget KEY,FLAGS
2907 X<msgget>
2908
2909 Calls the System V IPC function msgget(2).  Returns the message queue
2910 id, or the undefined value if there is an error.  See also
2911 L<perlipc/"SysV IPC"> and C<IPC::SysV> and C<IPC::Msg> documentation.
2912
2913 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2914 X<msgrcv>
2915
2916 Calls the System V IPC function msgrcv to receive a message from
2917 message queue ID into variable VAR with a maximum message size of
2918 SIZE.  Note that when a message is received, the message type as a
2919 native long integer will be the first thing in VAR, followed by the
2920 actual message.  This packing may be opened with C<unpack("l! a*")>.
2921 Taints the variable.  Returns true if successful, or false if there is
2922 an error.  See also L<perlipc/"SysV IPC">, C<IPC::SysV>, and
2923 C<IPC::SysV::Msg> documentation.
2924
2925 =item msgsnd ID,MSG,FLAGS
2926 X<msgsnd>
2927
2928 Calls the System V IPC function msgsnd to send the message MSG to the
2929 message queue ID.  MSG must begin with the native long integer message
2930 type, and be followed by the length of the actual message, and finally
2931 the message itself.  This kind of packing can be achieved with
2932 C<pack("l! a*", $type, $message)>.  Returns true if successful,
2933 or false if there is an error.  See also C<IPC::SysV>
2934 and C<IPC::SysV::Msg> documentation.
2935
2936 =item my EXPR
2937 X<my>
2938
2939 =item my TYPE EXPR
2940
2941 =item my EXPR : ATTRS
2942
2943 =item my TYPE EXPR : ATTRS
2944
2945 A C<my> declares the listed variables to be local (lexically) to the
2946 enclosing block, file, or C<eval>.  If more than one value is listed,
2947 the list must be placed in parentheses.
2948
2949 The exact semantics and interface of TYPE and ATTRS are still
2950 evolving.  TYPE is currently bound to the use of C<fields> pragma,
2951 and attributes are handled using the C<attributes> pragma, or starting
2952 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
2953 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
2954 L<attributes>, and L<Attribute::Handlers>.
2955
2956 =item next LABEL
2957 X<next> X<continue>
2958
2959 =item next
2960
2961 The C<next> command is like the C<continue> statement in C; it starts
2962 the next iteration of the loop:
2963
2964     LINE: while (<STDIN>) {
2965         next LINE if /^#/;      # discard comments
2966         #...
2967     }
2968
2969 Note that if there were a C<continue> block on the above, it would get
2970 executed even on discarded lines.  If the LABEL is omitted, the command
2971 refers to the innermost enclosing loop.
2972
2973 C<next> cannot be used to exit a block which returns a value such as
2974 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2975 a grep() or map() operation.
2976
2977 Note that a block by itself is semantically identical to a loop
2978 that executes once.  Thus C<next> will exit such a block early.
2979
2980 See also L</continue> for an illustration of how C<last>, C<next>, and
2981 C<redo> work.
2982
2983 =item no Module VERSION LIST
2984 X<no>
2985
2986 =item no Module VERSION
2987
2988 =item no Module LIST
2989
2990 =item no Module
2991
2992 =item no VERSION
2993
2994 See the C<use> function, of which C<no> is the opposite.
2995
2996 =item oct EXPR
2997 X<oct> X<octal> X<hex> X<hexadecimal> X<binary> X<bin>
2998
2999 =item oct
3000
3001 Interprets EXPR as an octal string and returns the corresponding
3002 value.  (If EXPR happens to start off with C<0x>, interprets it as a
3003 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
3004 binary string.  Leading whitespace is ignored in all three cases.)
3005 The following will handle decimal, binary, octal, and hex in the standard
3006 Perl or C notation:
3007
3008     $val = oct($val) if $val =~ /^0/;
3009
3010 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
3011 in octal), use sprintf() or printf():
3012
3013     $perms = (stat("filename"))[2] & 07777;
3014     $oct_perms = sprintf "%lo", $perms;
3015
3016 The oct() function is commonly used when a string such as C<644> needs
3017 to be converted into a file mode, for example. (Although perl will
3018 automatically convert strings into numbers as needed, this automatic
3019 conversion assumes base 10.)
3020
3021 =item open FILEHANDLE,EXPR
3022 X<open> X<pipe> X<file, open> X<fopen>
3023
3024 =item open FILEHANDLE,MODE,EXPR
3025
3026 =item open FILEHANDLE,MODE,EXPR,LIST
3027
3028 =item open FILEHANDLE,MODE,REFERENCE
3029
3030 =item open FILEHANDLE
3031
3032 Opens the file whose filename is given by EXPR, and associates it with
3033 FILEHANDLE.
3034
3035 (The following is a comprehensive reference to open(): for a gentler
3036 introduction you may consider L<perlopentut>.)
3037
3038 If FILEHANDLE is an undefined scalar variable (or array or hash element)
3039 the variable is assigned a reference to a new anonymous filehandle,
3040 otherwise if FILEHANDLE is an expression, its value is used as the name of
3041 the real filehandle wanted.  (This is considered a symbolic reference, so
3042 C<use strict 'refs'> should I<not> be in effect.)
3043
3044 If EXPR is omitted, the scalar variable of the same name as the
3045 FILEHANDLE contains the filename.  (Note that lexical variables--those
3046 declared with C<my>--will not work for this purpose; so if you're
3047 using C<my>, specify EXPR in your call to open.)
3048
3049 If three or more arguments are specified then the mode of opening and
3050 the file name are separate. If MODE is C<< '<' >> or nothing, the file
3051 is opened for input.  If MODE is C<< '>' >>, the file is truncated and
3052 opened for output, being created if necessary.  If MODE is C<<< '>>' >>>,
3053 the file is opened for appending, again being created if necessary.
3054
3055 You can put a C<'+'> in front of the C<< '>' >> or C<< '<' >> to
3056 indicate that you want both read and write access to the file; thus
3057 C<< '+<' >> is almost always preferred for read/write updates--the C<<
3058 '+>' >> mode would clobber the file first.  You can't usually use
3059 either read-write mode for updating textfiles, since they have
3060 variable length records.  See the B<-i> switch in L<perlrun> for a
3061 better approach.  The file is created with permissions of C<0666>
3062 modified by the process' C<umask> value.
3063
3064 These various prefixes correspond to the fopen(3) modes of C<'r'>,
3065 C<'r+'>, C<'w'>, C<'w+'>, C<'a'>, and C<'a+'>.
3066
3067 In the 2-arguments (and 1-argument) form of the call the mode and
3068 filename should be concatenated (in this order), possibly separated by
3069 spaces.  It is possible to omit the mode in these forms if the mode is
3070 C<< '<' >>.
3071
3072 If the filename begins with C<'|'>, the filename is interpreted as a
3073 command to which output is to be piped, and if the filename ends with a
3074 C<'|'>, the filename is interpreted as a command which pipes output to
3075 us.  See L<perlipc/"Using open() for IPC">
3076 for more examples of this.  (You are not allowed to C<open> to a command
3077 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
3078 and L<perlipc/"Bidirectional Communication with Another Process">
3079 for alternatives.)
3080
3081 For three or more arguments if MODE is C<'|-'>, the filename is
3082 interpreted as a command to which output is to be piped, and if MODE
3083 is C<'-|'>, the filename is interpreted as a command which pipes
3084 output to us.  In the 2-arguments (and 1-argument) form one should
3085 replace dash (C<'-'>) with the command.
3086 See L<perlipc/"Using open() for IPC"> for more examples of this.
3087 (You are not allowed to C<open> to a command that pipes both in I<and>
3088 out, but see L<IPC::Open2>, L<IPC::Open3>, and
3089 L<perlipc/"Bidirectional Communication"> for alternatives.)
3090
3091 In the three-or-more argument form of pipe opens, if LIST is specified
3092 (extra arguments after the command name) then LIST becomes arguments
3093 to the command invoked if the platform supports it.  The meaning of
3094 C<open> with more than three arguments for non-pipe modes is not yet
3095 specified. Experimental "layers" may give extra LIST arguments
3096 meaning.
3097
3098 In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN
3099 and opening C<< '>-' >> opens STDOUT.
3100
3101 You may use the three-argument form of open to specify IO "layers"
3102 (sometimes also referred to as "disciplines") to be applied to the handle
3103 that affect how the input and output are processed (see L<open> and
3104 L<PerlIO> for more details). For example
3105
3106   open(FH, "<:encoding(UTF-8)", "file")
3107
3108 will open the UTF-8 encoded file containing Unicode characters,
3109 see L<perluniintro>. Note that if layers are specified in the
3110 three-arg form then default layers stored in ${^OPEN} (see L<perlvar>;
3111 usually set by the B<open> pragma or the switch B<-CioD>) are ignored.
3112
3113 Open returns nonzero upon success, the undefined value otherwise.  If
3114 the C<open> involved a pipe, the return value happens to be the pid of
3115 the subprocess.
3116
3117 If you're running Perl on a system that distinguishes between text
3118 files and binary files, then you should check out L</binmode> for tips
3119 for dealing with this.  The key distinction between systems that need
3120 C<binmode> and those that don't is their text file formats.  Systems
3121 like Unix, Mac OS, and Plan 9, which delimit lines with a single
3122 character, and which encode that character in C as C<"\n">, do not
3123 need C<binmode>.  The rest need it.
3124
3125 When opening a file, it's usually a bad idea to continue normal execution
3126 if the request failed, so C<open> is frequently used in connection with
3127 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
3128 where you want to make a nicely formatted error message (but there are
3129 modules that can help with that problem)) you should always check
3130 the return value from opening a file.  The infrequent exception is when
3131 working with an unopened filehandle is actually what you want to do.
3132
3133 As a special case the 3-arg form with a read/write mode and the third
3134 argument being C<undef>:
3135
3136     open(TMP, "+>", undef) or die ...
3137
3138 opens a filehandle to an anonymous temporary file.  Also using "+<"
3139 works for symmetry, but you really should consider writing something
3140 to the temporary file first.  You will need to seek() to do the
3141 reading.
3142
3143 Since v5.8.0, perl has built using PerlIO by default.  Unless you've
3144 changed this (i.e. Configure -Uuseperlio), you can open file handles to
3145 "in memory" files held in Perl scalars via:
3146
3147     open($fh, '>', \$variable) || ..
3148
3149 Though if you try to re-open C<STDOUT> or C<STDERR> as an "in memory"
3150 file, you have to close it first:
3151
3152     close STDOUT;
3153     open STDOUT, '>', \$variable or die "Can't open STDOUT: $!";
3154
3155 Examples:
3156
3157     $ARTICLE = 100;
3158     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
3159     while (<ARTICLE>) {...
3160
3161     open(LOG, '>>/usr/spool/news/twitlog');     # (log is reserved)
3162     # if the open fails, output is discarded
3163
3164     open(DBASE, '+<', 'dbase.mine')             # open for update
3165         or die "Can't open 'dbase.mine' for update: $!";
3166
3167     open(DBASE, '+<dbase.mine')                 # ditto
3168         or die "Can't open 'dbase.mine' for update: $!";
3169
3170     open(ARTICLE, '-|', "caesar <$article")     # decrypt article
3171         or die "Can't start caesar: $!";
3172
3173     open(ARTICLE, "caesar <$article |")         # ditto
3174         or die "Can't start caesar: $!";
3175
3176     open(EXTRACT, "|sort >Tmp$$")               # $$ is our process id
3177         or die "Can't start sort: $!";
3178
3179     # in memory files
3180     open(MEMORY,'>', \$var)
3181         or die "Can't open memory file: $!";
3182     print MEMORY "foo!\n";                      # output will end up in $var
3183
3184     # process argument list of files along with any includes
3185
3186     foreach $file (@ARGV) {
3187         process($file, 'fh00');
3188     }
3189
3190     sub process {
3191         my($filename, $input) = @_;
3192         $input++;               # this is a string increment
3193         unless (open($input, $filename)) {
3194             print STDERR "Can't open $filename: $!\n";
3195             return;
3196         }
3197
3198         local $_;
3199         while (<$input>) {              # note use of indirection
3200             if (/^#include "(.*)"/) {
3201                 process($1, $input);
3202                 next;
3203             }
3204             #...                # whatever
3205         }
3206     }
3207
3208 See L<perliol> for detailed info on PerlIO.
3209
3210 You may also, in the Bourne shell tradition, specify an EXPR beginning
3211 with C<< '>&' >>, in which case the rest of the string is interpreted
3212 as the name of a filehandle (or file descriptor, if numeric) to be
3213 duped (as L<dup(2)>) and opened.  You may use C<&> after C<< > >>,
3214 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
3215 The mode you specify should match the mode of the original filehandle.
3216 (Duping a filehandle does not take into account any existing contents
3217 of IO buffers.) If you use the 3-arg form then you can pass either a
3218 number, the name of a filehandle or the normal "reference to a glob".
3219
3220 Here is a script that saves, redirects, and restores C<STDOUT> and
3221 C<STDERR> using various methods:
3222
3223     #!/usr/bin/perl
3224     open my $oldout, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3225     open OLDERR,     ">&", \*STDERR or die "Can't dup STDERR: $!";
3226
3227     open STDOUT, '>', "foo.out" or die "Can't redirect STDOUT: $!";
3228     open STDERR, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3229
3230     select STDERR; $| = 1;      # make unbuffered
3231     select STDOUT; $| = 1;      # make unbuffered
3232
3233     print STDOUT "stdout 1\n";  # this works for
3234     print STDERR "stderr 1\n";  # subprocesses too
3235
3236     open STDOUT, ">&", $oldout or die "Can't dup \$oldout: $!";
3237     open STDERR, ">&OLDERR"    or die "Can't dup OLDERR: $!";
3238
3239     print STDOUT "stdout 2\n";
3240     print STDERR "stderr 2\n";
3241
3242 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
3243 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
3244 that file descriptor (and not call L<dup(2)>); this is more
3245 parsimonious of file descriptors.  For example:
3246
3247     # open for input, reusing the fileno of $fd
3248     open(FILEHANDLE, "<&=$fd")
3249
3250 or
3251
3252     open(FILEHANDLE, "<&=", $fd)
3253
3254 or
3255
3256     # open for append, using the fileno of OLDFH
3257     open(FH, ">>&=", OLDFH)
3258
3259 or
3260
3261     open(FH, ">>&=OLDFH")
3262
3263 Being parsimonious on filehandles is also useful (besides being
3264 parsimonious) for example when something is dependent on file
3265 descriptors, like for example locking using flock().  If you do just
3266 C<< open(A, '>>&B') >>, the filehandle A will not have the same file
3267 descriptor as B, and therefore flock(A) will not flock(B), and vice
3268 versa.  But with C<< open(A, '>>&=B') >> the filehandles will share
3269 the same file descriptor.
3270
3271 Note that if you are using Perls older than 5.8.0, Perl will be using
3272 the standard C libraries' fdopen() to implement the "=" functionality.
3273 On many UNIX systems fdopen() fails when file descriptors exceed a
3274 certain value, typically 255.  For Perls 5.8.0 and later, PerlIO is
3275 most often the default.
3276
3277 You can see whether Perl has been compiled with PerlIO or not by
3278 running C<perl -V> and looking for C<useperlio=> line.  If C<useperlio>
3279 is C<define>, you have PerlIO, otherwise you don't.
3280
3281 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
3282 with 2-arguments (or 1-argument) form of open(), then
3283 there is an implicit fork done, and the return value of open is the pid
3284 of the child within the parent process, and C<0> within the child
3285 process.  (Use C<defined($pid)> to determine whether the open was successful.)
3286 The filehandle behaves normally for the parent, but i/o to that
3287 filehandle is piped from/to the STDOUT/STDIN of the child process.
3288 In the child process the filehandle isn't opened--i/o happens from/to
3289 the new STDOUT or STDIN.  Typically this is used like the normal
3290 piped open when you want to exercise more control over just how the
3291 pipe command gets executed, such as when you are running setuid, and
3292 don't want to have to scan shell commands for metacharacters.
3293 The following triples are more or less equivalent:
3294
3295     open(FOO, "|tr '[a-z]' '[A-Z]'");
3296     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
3297     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
3298     open(FOO, '|-', "tr", '[a-z]', '[A-Z]');
3299
3300     open(FOO, "cat -n '$file'|");
3301     open(FOO, '-|', "cat -n '$file'");
3302     open(FOO, '-|') || exec 'cat', '-n', $file;
3303     open(FOO, '-|', "cat", '-n', $file);
3304
3305 The last example in each block shows the pipe as "list form", which is
3306 not yet supported on all platforms.  A good rule of thumb is that if
3307 your platform has true C<fork()> (in other words, if your platform is
3308 UNIX) you can use the list form.
3309
3310 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
3311
3312 Beginning with v5.6.0, Perl will attempt to flush all files opened for
3313 output before any operation that may do a fork, but this may not be
3314 supported on some platforms (see L<perlport>).  To be safe, you may need
3315 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
3316 of C<IO::Handle> on any open handles.
3317
3318 On systems that support a close-on-exec flag on files, the flag will
3319 be set for the newly opened file descriptor as determined by the value
3320 of $^F.  See L<perlvar/$^F>.
3321
3322 Closing any piped filehandle causes the parent process to wait for the
3323 child to finish, and returns the status value in C<$?> and
3324 C<${^CHILD_ERROR_NATIVE}>.
3325
3326 The filename passed to 2-argument (or 1-argument) form of open() will
3327 have leading and trailing whitespace deleted, and the normal
3328 redirection characters honored.  This property, known as "magic open",
3329 can often be used to good effect.  A user could specify a filename of
3330 F<"rsh cat file |">, or you could change certain filenames as needed:
3331
3332     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
3333     open(FH, $filename) or die "Can't open $filename: $!";
3334
3335 Use 3-argument form to open a file with arbitrary weird characters in it,
3336
3337     open(FOO, '<', $file);
3338
3339 otherwise it's necessary to protect any leading and trailing whitespace:
3340
3341     $file =~ s#^(\s)#./$1#;
3342     open(FOO, "< $file\0");
3343
3344 (this may not work on some bizarre filesystems).  One should
3345 conscientiously choose between the I<magic> and 3-arguments form
3346 of open():
3347
3348     open IN, $ARGV[0];
3349
3350 will allow the user to specify an argument of the form C<"rsh cat file |">,
3351 but will not work on a filename which happens to have a trailing space, while
3352
3353     open IN, '<', $ARGV[0];
3354
3355 will have exactly the opposite restrictions.
3356
3357 If you want a "real" C C<open> (see L<open(2)> on your system), then you
3358 should use the C<sysopen> function, which involves no such magic (but
3359 may use subtly different filemodes than Perl open(), which is mapped
3360 to C fopen()).  This is
3361 another way to protect your filenames from interpretation.  For example:
3362
3363     use IO::Handle;
3364     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
3365         or die "sysopen $path: $!";
3366     $oldfh = select(HANDLE); $| = 1; select($oldfh);
3367     print HANDLE "stuff $$\n";
3368     seek(HANDLE, 0, 0);
3369     print "File contains: ", <HANDLE>;
3370
3371 Using the constructor from the C<IO::Handle> package (or one of its
3372 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3373 filehandles that have the scope of whatever variables hold references to
3374 them, and automatically close whenever and however you leave that scope:
3375
3376     use IO::File;
3377     #...
3378     sub read_myfile_munged {
3379         my $ALL = shift;
3380         my $handle = new IO::File;
3381         open($handle, "myfile") or die "myfile: $!";
3382         $first = <$handle>
3383             or return ();     # Automatically closed here.
3384         mung $first or die "mung failed";       # Or here.
3385         return $first, <$handle> if $ALL;       # Or here.
3386         $first;                                 # Or here.
3387     }
3388
3389 See L</seek> for some details about mixing reading and writing.
3390
3391 =item opendir DIRHANDLE,EXPR
3392 X<opendir>
3393
3394 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3395 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3396 DIRHANDLE may be an expression whose value can be used as an indirect
3397 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
3398 scalar variable (or array or hash element), the variable is assigned a
3399 reference to a new anonymous dirhandle.
3400 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3401
3402 =item ord EXPR
3403 X<ord> X<encoding>
3404
3405 =item ord
3406
3407 Returns the numeric (the native 8-bit encoding, like ASCII or EBCDIC,
3408 or Unicode) value of the first character of EXPR.  If EXPR is omitted,
3409 uses C<$_>.
3410
3411 For the reverse, see L</chr>.
3412 See L<perlunicode> for more about Unicode.
3413
3414 =item our EXPR
3415 X<our> X<global>
3416
3417 =item our TYPE EXPR
3418
3419 =item our EXPR : ATTRS
3420
3421 =item our TYPE EXPR : ATTRS
3422
3423 C<our> associates a simple name with a package variable in the current
3424 package for use within the current scope.  When C<use strict 'vars'> is in
3425 effect, C<our> lets you use declared global variables without qualifying
3426 them with package names, within the lexical scope of the C<our> declaration.
3427 In this way C<our> differs from C<use vars>, which is package scoped.
3428
3429 Unlike C<my>, which both allocates storage for a variable and associates
3430 a simple name with that storage for use within the current scope, C<our>
3431 associates a simple name with a package variable in the current package,
3432 for use within the current scope.  In other words, C<our> has the same
3433 scoping rules as C<my>, but does not necessarily create a
3434 variable.
3435
3436 If more than one value is listed, the list must be placed
3437 in parentheses.
3438
3439     our $foo;
3440     our($bar, $baz);
3441
3442 An C<our> declaration declares a global variable that will be visible
3443 across its entire lexical scope, even across package boundaries.  The
3444 package in which the variable is entered is determined at the point
3445 of the declaration, not at the point of use.  This means the following
3446 behavior holds:
3447
3448     package Foo;
3449     our $bar;           # declares $Foo::bar for rest of lexical scope
3450     $bar = 20;
3451
3452     package Bar;
3453     print $bar;         # prints 20, as it refers to $Foo::bar
3454
3455 Multiple C<our> declarations with the same name in the same lexical
3456 scope are allowed if they are in different packages.  If they happen
3457 to be in the same package, Perl will emit warnings if you have asked
3458 for them, just like multiple C<my> declarations.  Unlike a second
3459 C<my> declaration, which will bind the name to a fresh variable, a
3460 second C<our> declaration in the same package, in the same scope, is
3461 merely redundant.
3462
3463     use warnings;
3464     package Foo;
3465     our $bar;           # declares $Foo::bar for rest of lexical scope
3466     $bar = 20;
3467
3468     package Bar;
3469     our $bar = 30;      # declares $Bar::bar for rest of lexical scope
3470     print $bar;         # prints 30
3471
3472     our $bar;           # emits warning but has no other effect
3473     print $bar;         # still prints 30
3474
3475 An C<our> declaration may also have a list of attributes associated
3476 with it.
3477
3478 The exact semantics and interface of TYPE and ATTRS are still
3479 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3480 and attributes are handled using the C<attributes> pragma, or starting
3481 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3482 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3483 L<attributes>, and L<Attribute::Handlers>.
3484
3485 =item pack TEMPLATE,LIST
3486 X<pack>
3487
3488 Takes a LIST of values and converts it into a string using the rules
3489 given by the TEMPLATE.  The resulting string is the concatenation of
3490 the converted values.  Typically, each converted value looks
3491 like its machine-level representation.  For example, on 32-bit machines
3492 an integer may be represented by a sequence of 4 bytes that will be 
3493 converted to a sequence of 4 characters.
3494
3495 The TEMPLATE is a sequence of characters that give the order and type
3496 of values, as follows:
3497
3498     a   A string with arbitrary binary data, will be null padded.
3499     A   A text (ASCII) string, will be space padded.
3500     Z   A null terminated (ASCIZ) string, will be null padded.
3501
3502     b   A bit string (ascending bit order inside each byte, like vec()).
3503     B   A bit string (descending bit order inside each byte).
3504     h   A hex string (low nybble first).
3505     H   A hex string (high nybble first).
3506
3507     c   A signed char (8-bit) value.
3508     C   An unsigned char (octet) value.
3509     W   An unsigned char value (can be greater than 255).
3510
3511     s   A signed short (16-bit) value.
3512     S   An unsigned short value.
3513
3514     l   A signed long (32-bit) value.
3515     L   An unsigned long value.
3516
3517     q   A signed quad (64-bit) value.
3518     Q   An unsigned quad value.
3519           (Quads are available only if your system supports 64-bit
3520            integer values _and_ if Perl has been compiled to support those.
3521            Causes a fatal error otherwise.)
3522
3523     i   A signed integer value.
3524     I   A unsigned integer value.
3525           (This 'integer' is _at_least_ 32 bits wide.  Its exact
3526            size depends on what a local C compiler calls 'int'.)
3527
3528     n   An unsigned short (16-bit) in "network" (big-endian) order.
3529     N   An unsigned long (32-bit) in "network" (big-endian) order.
3530     v   An unsigned short (16-bit) in "VAX" (little-endian) order.
3531     V   An unsigned long (32-bit) in "VAX" (little-endian) order.
3532
3533     j   A Perl internal signed integer value (IV).
3534     J   A Perl internal unsigned integer value (UV).
3535
3536     f   A single-precision float in the native format.
3537     d   A double-precision float in the native format.
3538
3539     F   A Perl internal floating point value (NV) in the native format
3540     D   A long double-precision float in the native format.
3541           (Long doubles are available only if your system supports long
3542            double values _and_ if Perl has been compiled to support those.
3543            Causes a fatal error otherwise.)
3544
3545     p   A pointer to a null-terminated string.
3546     P   A pointer to a structure (fixed-length string).
3547
3548     u   A uuencoded string.
3549     U   A Unicode character number.  Encodes to a character in character mode
3550         and UTF-8 (or UTF-EBCDIC in EBCDIC platforms) in byte mode.
3551
3552     w   A BER compressed integer (not an ASN.1 BER, see perlpacktut for
3553         details).  Its bytes represent an unsigned integer in base 128,
3554         most significant digit first, with as few digits as possible.  Bit
3555         eight (the high bit) is set on each byte except the last.
3556
3557     x   A null byte.
3558     X   Back up a byte.
3559     @   Null fill or truncate to absolute position, counted from the
3560         start of the innermost ()-group.
3561     .   Null fill or truncate to absolute position specified by value.
3562     (   Start of a ()-group.
3563
3564 One or more of the modifiers below may optionally follow some letters in the
3565 TEMPLATE (the second column lists the letters for which the modifier is
3566 valid):
3567
3568     !   sSlLiI     Forces native (short, long, int) sizes instead
3569                    of fixed (16-/32-bit) sizes.
3570
3571         xX         Make x and X act as alignment commands.
3572
3573         nNvV       Treat integers as signed instead of unsigned.
3574
3575         @.         Specify position as byte offset in the internal
3576                    representation of the packed string. Efficient but
3577                    dangerous.
3578
3579     >   sSiIlLqQ   Force big-endian byte-order on the type.
3580         jJfFdDpP   (The "big end" touches the construct.)
3581
3582     <   sSiIlLqQ   Force little-endian byte-order on the type.
3583         jJfFdDpP   (The "little end" touches the construct.)
3584
3585 The C<E<gt>> and C<E<lt>> modifiers can also be used on C<()>-groups,
3586 in which case they force a certain byte-order on all components of
3587 that group, including subgroups.
3588
3589 The following rules apply:
3590
3591 =over 8
3592
3593 =item *
3594
3595 Each letter may optionally be followed by a number giving a repeat
3596 count.  With all types except C<a>, C<A>, C<Z>, C<b>, C<B>, C<h>,
3597 C<H>, C<@>, C<.>, C<x>, C<X> and C<P> the pack function will gobble up
3598 that many values from the LIST.  A C<*> for the repeat count means to
3599 use however many items are left, except for C<@>, C<x>, C<X>, where it
3600 is equivalent to C<0>, for <.> where it means relative to string start
3601 and C<u>, where it is equivalent to 1 (or 45, which is the same).
3602 A numeric repeat count may optionally be enclosed in brackets, as in
3603 C<pack 'C[80]', @arr>.
3604
3605 One can replace the numeric repeat count by a template enclosed in brackets;
3606 then the packed length of this template in bytes is used as a count.
3607 For example, C<x[L]> skips a long (it skips the number of bytes in a long);
3608 the template C<$t X[$t] $t> unpack()s twice what $t unpacks.
3609 If the template in brackets contains alignment commands (such as C<x![d]>),
3610 its packed length is calculated as if the start of the template has the maximal
3611 possible alignment.
3612
3613 When used with C<Z>, C<*> results in the addition of a trailing null
3614 byte (so the packed result will be one longer than the byte C<length>
3615 of the item).
3616
3617 When used with C<@>, the repeat count represents an offset from the start
3618 of the innermost () group.
3619
3620 When used with C<.>, the repeat count is used to determine the starting
3621 position from where the value offset is calculated. If the repeat count
3622 is 0, it's relative to the current position. If the repeat count is C<*>,
3623 the offset is relative to the start of the packed string. And if its an
3624 integer C<n> the offset is relative to the start of the n-th innermost
3625 () group (or the start of the string if C<n> is bigger then the group
3626 level).
3627
3628 The repeat count for C<u> is interpreted as the maximal number of bytes
3629 to encode per line of output, with 0, 1 and 2 replaced by 45. The repeat 
3630 count should not be more than 65.
3631
3632 =item *
3633
3634 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
3635 string of length count, padding with nulls or spaces as necessary.  When
3636 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
3637 after the first null, and C<a> returns data verbatim.
3638
3639 If the value-to-pack is too long, it is truncated.  If too long and an
3640 explicit count is provided, C<Z> packs only C<$count-1> bytes, followed
3641 by a null byte.  Thus C<Z> always packs a trailing null (except when the
3642 count is 0).
3643
3644 =item *
3645
3646 Likewise, the C<b> and C<B> fields pack a string that many bits long.
3647 Each character of the input field of pack() generates 1 bit of the result.
3648 Each result bit is based on the least-significant bit of the corresponding
3649 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
3650 and C<"1"> generate bits 0 and 1, as do characters C<"\0"> and C<"\1">.
3651
3652 Starting from the beginning of the input string of pack(), each 8-tuple
3653 of characters is converted to 1 character of output.  With format C<b>
3654 the first character of the 8-tuple determines the least-significant bit of a
3655 character, and with format C<B> it determines the most-significant bit of
3656 a character.
3657
3658 If the length of the input string is not exactly divisible by 8, the
3659 remainder is packed as if the input string were padded by null characters
3660 at the end.  Similarly, during unpack()ing the "extra" bits are ignored.
3661
3662 If the input string of pack() is longer than needed, extra characters are 
3663 ignored. A C<*> for the repeat count of pack() means to use all the 
3664 characters of the input field.  On unpack()ing the bits are converted to a 
3665 string of C<"0">s and C<"1">s.
3666
3667 =item *
3668
3669 The C<h> and C<H> fields pack a string that many nybbles (4-bit groups,
3670 representable as hexadecimal digits, 0-9a-f) long.
3671
3672 Each character of the input field of pack() generates 4 bits of the result.
3673 For non-alphabetical characters the result is based on the 4 least-significant
3674 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
3675 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
3676 C<"\0"> and C<"\1">.  For characters C<"a".."f"> and C<"A".."F"> the result
3677 is compatible with the usual hexadecimal digits, so that C<"a"> and
3678 C<"A"> both generate the nybble C<0xa==10>.  The result for characters
3679 C<"g".."z"> and C<"G".."Z"> is not well-defined.
3680
3681 Starting from the beginning of the input string of pack(), each pair
3682 of characters is converted to 1 character of output.  With format C<h> the
3683 first character of the pair determines the least-significant nybble of the
3684 output character, and with format C<H> it determines the most-significant
3685 nybble.
3686
3687 If the length of the input string is not even, it behaves as if padded
3688 by a null character at the end.  Similarly, during unpack()ing the "extra"
3689 nybbles are ignored.
3690
3691 If the input string of pack() is longer than needed, extra characters are
3692 ignored.
3693 A C<*> for the repeat count of pack() means to use all the characters of
3694 the input field.  On unpack()ing the nybbles are converted to a string
3695 of hexadecimal digits.
3696
3697 =item *
3698
3699 The C<p> type packs a pointer to a null-terminated string.  You are
3700 responsible for ensuring the string is not a temporary value (which can
3701 potentially get deallocated before you get around to using the packed result).
3702 The C<P> type packs a pointer to a structure of the size indicated by the
3703 length.  A NULL pointer is created if the corresponding value for C<p> or
3704 C<P> is C<undef>, similarly for unpack().
3705
3706 If your system has a strange pointer size (i.e. a pointer is neither as
3707 big as an int nor as big as a long), it may not be possible to pack or
3708 unpack pointers in big- or little-endian byte order.  Attempting to do
3709 so will result in a fatal error.
3710
3711 =item *
3712
3713 The C</> template character allows packing and unpacking of a sequence of
3714 items where the packed structure contains a packed item count followed by 
3715 the packed items themselves.
3716
3717 For C<pack> you write I<length-item>C</>I<sequence-item> and the
3718 I<length-item> describes how the length value is packed. The ones likely
3719 to be of most use are integer-packing ones like C<n> (for Java strings),
3720 C<w> (for ASN.1 or SNMP) and C<N> (for Sun XDR).
3721
3722 For C<pack>, the I<sequence-item> may have a repeat count, in which case
3723 the minimum of that and the number of available items is used as argument
3724 for the I<length-item>. If it has no repeat count or uses a '*', the number
3725 of available items is used.
3726
3727 For C<unpack> an internal stack of integer arguments unpacked so far is
3728 used. You write C</>I<sequence-item> and the repeat count is obtained by
3729 popping off the last element from the stack. The I<sequence-item> must not
3730 have a repeat count.
3731
3732 If the I<sequence-item> refers to a string type (C<"A">, C<"a"> or C<"Z">),
3733 the I<length-item> is a string length, not a number of strings. If there is
3734 an explicit repeat count for pack, the packed string will be adjusted to that
3735 given length.
3736
3737     unpack 'W/a', "\04Gurusamy";            gives ('Guru')
3738     unpack 'a3/A A*', '007 Bond  J ';       gives (' Bond', 'J')
3739     unpack 'a3 x2 /A A*', '007: Bond, J.';  gives ('Bond, J', '.')
3740     pack 'n/a* w/a','hello,','world';       gives "\000\006hello,\005world"
3741     pack 'a/W2', ord('a') .. ord('z');      gives '2ab'
3742
3743 The I<length-item> is not returned explicitly from C<unpack>.
3744
3745 Adding a count to the I<length-item> letter is unlikely to do anything
3746 useful, unless that letter is C<A>, C<a> or C<Z>.  Packing with a
3747 I<length-item> of C<a> or C<Z> may introduce C<"\000"> characters,
3748 which Perl does not regard as legal in numeric strings.
3749
3750 =item *
3751
3752 The integer types C<s>, C<S>, C<l>, and C<L> may be
3753 followed by a C<!> modifier to signify native shorts or
3754 longs--as you can see from above for example a bare C<l> does mean
3755 exactly 32 bits, the native C<long> (as seen by the local C compiler)
3756 may be larger.  This is an issue mainly in 64-bit platforms.  You can
3757 see whether using C<!> makes any difference by
3758
3759         print length(pack("s")), " ", length(pack("s!")), "\n";
3760         print length(pack("l")), " ", length(pack("l!")), "\n";
3761
3762 C<i!> and C<I!> also work but only because of completeness;
3763 they are identical to C<i> and C<I>.
3764
3765 The actual sizes (in bytes) of native shorts, ints, longs, and long
3766 longs on the platform where Perl was built are also available via
3767 L<Config>:
3768
3769        use Config;
3770        print $Config{shortsize},    "\n";
3771        print $Config{intsize},      "\n";
3772        print $Config{longsize},     "\n";
3773        print $Config{longlongsize}, "\n";
3774
3775 (The C<$Config{longlongsize}> will be undefined if your system does
3776 not support long longs.)
3777
3778 =item *
3779
3780 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J>
3781 are inherently non-portable between processors and operating systems
3782 because they obey the native byteorder and endianness.  For example a
3783 4-byte integer 0x12345678 (305419896 decimal) would be ordered natively
3784 (arranged in and handled by the CPU registers) into bytes as
3785
3786         0x12 0x34 0x56 0x78     # big-endian
3787         0x78 0x56 0x34 0x12     # little-endian
3788
3789 Basically, the Intel and VAX CPUs are little-endian, while everybody
3790 else, for example Motorola m68k/88k, PPC, Sparc, HP PA, Power, and
3791 Cray are big-endian.  Alpha and MIPS can be either: Digital/Compaq
3792 used/uses them in little-endian mode; SGI/Cray uses them in big-endian
3793 mode.
3794
3795 The names `big-endian' and `little-endian' are comic references to
3796 the classic "Gulliver's Travels" (via the paper "On Holy Wars and a
3797 Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and
3798 the egg-eating habits of the Lilliputians.
3799
3800 Some systems may have even weirder byte orders such as
3801
3802         0x56 0x78 0x12 0x34
3803         0x34 0x12 0x78 0x56
3804
3805 You can see your system's preference with
3806
3807         print join(" ", map { sprintf "%#02x", $_ }
3808                             unpack("W*",pack("L",0x12345678))), "\n";
3809
3810 The byteorder on the platform where Perl was built is also available
3811 via L<Config>:
3812
3813         use Config;
3814         print $Config{byteorder}, "\n";
3815
3816 Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'>
3817 and C<'87654321'> are big-endian.
3818
3819 If you want portable packed integers you can either use the formats
3820 C<n>, C<N>, C<v>, and C<V>, or you can use the C<E<gt>> and C<E<lt>>
3821 modifiers.  These modifiers are only available as of perl 5.9.2.
3822 See also L<perlport>.
3823
3824 =item *
3825
3826 All integer and floating point formats as well as C<p> and C<P> and
3827 C<()>-groups may be followed by the C<E<gt>> or C<E<lt>> modifiers
3828 to force big- or little- endian byte-order, respectively.
3829 This is especially useful, since C<n>, C<N>, C<v> and C<V> don't cover
3830 signed integers, 64-bit integers and floating point values.  However,
3831 there are some things to keep in mind.
3832
3833 Exchanging signed integers between different platforms only works
3834 if all platforms store them in the same format.  Most platforms store
3835 signed integers in two's complement, so usually this is not an issue.
3836
3837 The C<E<gt>> or C<E<lt>> modifiers can only be used on floating point
3838 formats on big- or little-endian machines.  Otherwise, attempting to
3839 do so will result in a fatal error.
3840
3841 Forcing big- or little-endian byte-order on floating point values for
3842 data exchange can only work if all platforms are using the same
3843 binary representation (e.g. IEEE floating point format).  Even if all
3844 platforms are using IEEE, there may be subtle differences.  Being able
3845 to use C<E<gt>> or C<E<lt>> on floating point values can be very useful,
3846 but also very dangerous if you don't know exactly what you're doing.
3847 It is definitely not a general way to portably store floating point
3848 values.
3849
3850 When using C<E<gt>> or C<E<lt>> on an C<()>-group, this will affect
3851 all types inside the group that accept the byte-order modifiers,
3852 including all subgroups.  It will silently be ignored for all other
3853 types.  You are not allowed to override the byte-order within a group
3854 that already has a byte-order modifier suffix.
3855
3856 =item *
3857
3858 Real numbers (floats and doubles) are in the native machine format only;
3859 due to the multiplicity of floating formats around, and the lack of a
3860 standard "network" representation, no facility for interchange has been
3861 made.  This means that packed floating point data written on one machine
3862 may not be readable on another - even if both use IEEE floating point
3863 arithmetic (as the endian-ness of the memory representation is not part
3864 of the IEEE spec).  See also L<perlport>.
3865
3866 If you know exactly what you're doing, you can use the C<E<gt>> or C<E<lt>>
3867 modifiers to force big- or little-endian byte-order on floating point values.
3868
3869 Note that Perl uses doubles (or long doubles, if configured) internally for
3870 all numeric calculation, and converting from double into float and thence back
3871 to double again will lose precision (i.e., C<unpack("f", pack("f", $foo)>)
3872 will not in general equal $foo).
3873
3874 =item *
3875
3876 Pack and unpack can operate in two modes, character mode (C<C0> mode) where
3877 the packed string is processed per character and UTF-8 mode (C<U0> mode)
3878 where the packed string is processed in its UTF-8-encoded Unicode form on
3879 a byte by byte basis. Character mode is the default unless the format string 
3880 starts with an C<U>. You can switch mode at any moment with an explicit 
3881 C<C0> or C<U0> in the format. A mode is in effect until the next mode switch 
3882 or until the end of the ()-group in which it was entered.
3883
3884 =item *
3885
3886 You must yourself do any alignment or padding by inserting for example
3887 enough C<'x'>es while packing.  There is no way to pack() and unpack()
3888 could know where the characters are going to or coming from.  Therefore
3889 C<pack> (and C<unpack>) handle their output and input as flat
3890 sequences of characters.
3891
3892 =item *
3893
3894 A ()-group is a sub-TEMPLATE enclosed in parentheses.  A group may
3895 take a repeat count, both as postfix, and for unpack() also via the C</>
3896 template character. Within each repetition of a group, positioning with
3897 C<@> starts again at 0. Therefore, the result of
3898
3899     pack( '@1A((@2A)@3A)', 'a', 'b', 'c' )
3900
3901 is the string "\0a\0\0bc".
3902
3903 =item *
3904
3905 C<x> and C<X> accept C<!> modifier.  In this case they act as
3906 alignment commands: they jump forward/back to the closest position
3907 aligned at a multiple of C<count> characters. For example, to pack() or
3908 unpack() C's C<struct {char c; double d; char cc[2]}> one may need to
3909 use the template C<W x![d] d W[2]>; this assumes that doubles must be
3910 aligned on the double's size.
3911
3912 For alignment commands C<count> of 0 is equivalent to C<count> of 1;
3913 both result in no-ops.
3914
3915 =item *
3916
3917 C<n>, C<N>, C<v> and C<V> accept the C<!> modifier. In this case they
3918 will represent signed 16-/32-bit integers in big-/little-endian order.
3919 This is only portable if all platforms sharing the packed data use the
3920 same binary representation for signed integers (e.g. all platforms are
3921 using two's complement representation).
3922
3923 =item *
3924
3925 A comment in a TEMPLATE starts with C<#> and goes to the end of line.
3926 White space may be used to separate pack codes from each other, but
3927 modifiers and a repeat count must follow immediately.
3928
3929 =item *
3930
3931 If TEMPLATE requires more arguments to pack() than actually given, pack()
3932 assumes additional C<""> arguments.  If TEMPLATE requires fewer arguments
3933 to pack() than actually given, extra arguments are ignored.
3934
3935 =back
3936
3937 Examples:
3938
3939     $foo = pack("WWWW",65,66,67,68);
3940     # foo eq "ABCD"
3941     $foo = pack("W4",65,66,67,68);
3942     # same thing
3943     $foo = pack("W4",0x24b6,0x24b7,0x24b8,0x24b9);
3944     # same thing with Unicode circled letters.
3945     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
3946     # same thing with Unicode circled letters. You don't get the UTF-8
3947     # bytes because the U at the start of the format caused a switch to
3948     # U0-mode, so the UTF-8 bytes get joined into characters
3949     $foo = pack("C0U4",0x24b6,0x24b7,0x24b8,0x24b9);
3950     # foo eq "\xe2\x92\xb6\xe2\x92\xb7\xe2\x92\xb8\xe2\x92\xb9"
3951     # This is the UTF-8 encoding of the string in the previous example
3952
3953     $foo = pack("ccxxcc",65,66,67,68);
3954     # foo eq "AB\0\0CD"
3955
3956     # note: the above examples featuring "W" and "c" are true
3957     # only on ASCII and ASCII-derived systems such as ISO Latin 1
3958     # and UTF-8.  In EBCDIC the first example would be
3959     # $foo = pack("WWWW",193,194,195,196);
3960
3961     $foo = pack("s2",1,2);
3962     # "\1\0\2\0" on little-endian
3963     # "\0\1\0\2" on big-endian
3964
3965     $foo = pack("a4","abcd","x","y","z");
3966     # "abcd"
3967
3968     $foo = pack("aaaa","abcd","x","y","z");
3969     # "axyz"
3970
3971     $foo = pack("a14","abcdefg");
3972     # "abcdefg\0\0\0\0\0\0\0"
3973
3974     $foo = pack("i9pl", gmtime);
3975     # a real struct tm (on my system anyway)
3976
3977     $utmp_template = "Z8 Z8 Z16 L";
3978     $utmp = pack($utmp_template, @utmp1);
3979     # a struct utmp (BSDish)
3980
3981     @utmp2 = unpack($utmp_template, $utmp);
3982     # "@utmp1" eq "@utmp2"
3983
3984     sub bintodec {
3985         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
3986     }
3987
3988     $foo = pack('sx2l', 12, 34);
3989     # short 12, two zero bytes padding, long 34
3990     $bar = pack('s@4l', 12, 34);
3991     # short 12, zero fill to position 4, long 34
3992     # $foo eq $bar
3993     $baz = pack('s.l', 12, 4, 34);
3994     # short 12, zero fill to position 4, long 34
3995
3996     $foo = pack('nN', 42, 4711);
3997     # pack big-endian 16- and 32-bit unsigned integers
3998     $foo = pack('S>L>', 42, 4711);
3999     # exactly the same
4000     $foo = pack('s<l<', -42, 4711);
4001     # pack little-endian 16- and 32-bit signed integers
4002     $foo = pack('(sl)<', -42, 4711);
4003     # exactly the same
4004
4005 The same template may generally also be used in unpack().
4006
4007 =item package NAMESPACE
4008 X<package> X<module> X<namespace>
4009
4010 =item package
4011
4012 Declares the compilation unit as being in the given namespace.  The scope
4013 of the package declaration is from the declaration itself through the end
4014 of the enclosing block, file, or eval (the same as the C<my> operator).
4015 All further unqualified dynamic identifiers will be in this namespace.
4016 A package statement affects only dynamic variables--including those
4017 you've used C<local> on--but I<not> lexical variables, which are created
4018 with C<my>.  Typically it would be the first declaration in a file to
4019 be included by the C<require> or C<use> operator.  You can switch into a
4020 package in more than one place; it merely influences which symbol table
4021 is used by the compiler for the rest of that block.  You can refer to
4022 variables and filehandles in other packages by prefixing the identifier
4023 with the package name and a double colon:  C<$Package::Variable>.
4024 If the package name is null, the C<main> package as assumed.  That is,
4025 C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>,
4026 still seen in older code).
4027
4028 If NAMESPACE is omitted, then there is no current package, and all
4029 identifiers must be fully qualified or lexicals.  However, you are
4030 strongly advised not to make use of this feature. Its use can cause
4031 unexpected behaviour, even crashing some versions of Perl. It is
4032 deprecated, and will be removed from a future release.
4033
4034 See L<perlmod/"Packages"> for more information about packages, modules,
4035 and classes.  See L<perlsub> for other scoping issues.
4036
4037 =item pipe READHANDLE,WRITEHANDLE
4038 X<pipe>
4039
4040 Opens a pair of connected pipes like the corresponding system call.
4041 Note that if you set up a loop of piped processes, deadlock can occur
4042 unless you are very careful.  In addition, note that Perl's pipes use
4043 IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE
4044 after each command, depending on the application.
4045
4046 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
4047 for examples of such things.
4048
4049 On systems that support a close-on-exec flag on files, the flag will be set
4050 for the newly opened file descriptors as determined by the value of $^F.
4051 See L<perlvar/$^F>.
4052
4053 =item pop ARRAY
4054 X<pop> X<stack>
4055
4056 =item pop
4057
4058 Pops and returns the last value of the array, shortening the array by
4059 one element.  Has an effect similar to
4060
4061     $ARRAY[$#ARRAY--]
4062
4063 If there are no elements in the array, returns the undefined value
4064 (although this may happen at other times as well).  If ARRAY is
4065 omitted, pops the C<@ARGV> array in the main program, and the C<@_>
4066 array in subroutines, just like C<shift>.
4067
4068 =item pos SCALAR
4069 X<pos> X<match, position>
4070
4071 =item pos
4072
4073 Returns the offset of where the last C<m//g> search left off for the variable
4074 in question (C<$_> is used when the variable is not specified).  Note that
4075 0 is a valid match offset.  C<undef> indicates that the search position
4076 is reset (usually due to match failure, but can also be because no match has
4077 yet been performed on the scalar). C<pos> directly accesses the location used
4078 by the regexp engine to store the offset, so assigning to C<pos> will change
4079 that offset, and so will also influence the C<\G> zero-width assertion in
4080 regular expressions. Because a failed C<m//gc> match doesn't reset the offset,
4081 the return from C<pos> won't change either in this case.  See L<perlre> and
4082 L<perlop>.
4083
4084 =item print FILEHANDLE LIST
4085 X<print>
4086
4087 =item print LIST
4088
4089 =item print
4090
4091 Prints a string or a list of strings.  Returns true if successful.
4092 FILEHANDLE may be a scalar variable name, in which case the variable
4093 contains the name of or a reference to the filehandle, thus introducing
4094 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
4095 the next token is a term, it may be misinterpreted as an operator
4096 unless you interpose a C<+> or put parentheses around the arguments.)
4097 If FILEHANDLE is omitted, prints by default to standard output (or
4098 to the last selected output channel--see L</select>).  If LIST is
4099 also omitted, prints C<$_> to the currently selected output channel.
4100 To set the default output channel to something other than STDOUT
4101 use the select operation.  The current value of C<$,> (if any) is
4102 printed between each LIST item.  The current value of C<$\> (if
4103 any) is printed after the entire LIST has been printed.  Because
4104 print takes a LIST, anything in the LIST is evaluated in list
4105 context, and any subroutine that you call will have one or more of
4106 its expressions evaluated in list context.  Also be careful not to
4107 follow the print keyword with a left parenthesis unless you want
4108 the corresponding right parenthesis to terminate the arguments to
4109 the print--interpose a C<+> or put parentheses around all the
4110 arguments.
4111
4112 Note that if you're storing FILEHANDLEs in an array, or if you're using
4113 any other expression more complex than a scalar variable to retrieve it,
4114 you will have to use a block returning the filehandle value instead:
4115
4116     print { $files[$i] } "stuff\n";
4117     print { $OK ? STDOUT : STDERR } "stuff\n";
4118
4119 =item printf FILEHANDLE FORMAT, LIST
4120 X<printf>
4121
4122 =item printf FORMAT, LIST
4123
4124 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
4125 (the output record separator) is not appended.  The first argument
4126 of the list will be interpreted as the C<printf> format. See C<sprintf>
4127 for an explanation of the format argument.  If C<use locale> is in effect,
4128 and POSIX::setlocale() has been called, the character used for the decimal
4129 separator in formatted floating point numbers is affected by the LC_NUMERIC
4130 locale.  See L<perllocale> and L<POSIX>.
4131
4132 Don't fall into the trap of using a C<printf> when a simple
4133 C<print> would do.  The C<print> is more efficient and less
4134 error prone.
4135
4136 =item prototype FUNCTION
4137 X<prototype>
4138
4139 Returns the prototype of a function as a string (or C<undef> if the
4140 function has no prototype).  FUNCTION is a reference to, or the name of,
4141 the function whose prototype you want to retrieve.
4142
4143 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
4144 name for Perl builtin.  If the builtin is not I<overridable> (such as
4145 C<qw//>) or its arguments cannot be expressed by a prototype (such as
4146 C<system>) returns C<undef> because the builtin does not really behave
4147 like a Perl function.  Otherwise, the string describing the equivalent
4148 prototype is returned.
4149
4150 =item push ARRAY,LIST
4151 X<push> X<stack>
4152
4153 Treats ARRAY as a stack, and pushes the values of LIST
4154 onto the end of ARRAY.  The length of ARRAY increases by the length of
4155 LIST.  Has the same effect as
4156
4157     for $value (LIST) {
4158         $ARRAY[++$#ARRAY] = $value;
4159     }
4160
4161 but is more efficient.  Returns the number of elements in the array following
4162 the completed C<push>.
4163
4164 =item q/STRING/
4165
4166 =item qq/STRING/
4167
4168 =item qr/STRING/
4169
4170 =item qx/STRING/
4171
4172 =item qw/STRING/
4173
4174 Generalized quotes.  See L<perlop/"Regexp Quote-Like Operators">.
4175
4176 =item quotemeta EXPR
4177 X<quotemeta> X<metacharacter>
4178
4179 =item quotemeta
4180
4181 Returns the value of EXPR with all non-"word"
4182 characters backslashed.  (That is, all characters not matching
4183 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
4184 returned string, regardless of any locale settings.)
4185 This is the internal function implementing
4186 the C<\Q> escape in double-quoted strings.
4187
4188 If EXPR is omitted, uses C<$_>.
4189
4190 =item rand EXPR
4191 X<rand> X<random>
4192
4193 =item rand
4194
4195 Returns a random fractional number greater than or equal to C<0> and less
4196 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
4197 omitted, the value C<1> is used.  Currently EXPR with the value C<0> is
4198 also special-cased as C<1> - this has not been documented before perl 5.8.0
4199 and is subject to change in future versions of perl.  Automatically calls
4200 C<srand> unless C<srand> has already been called.  See also C<srand>.
4201
4202 Apply C<int()> to the value returned by C<rand()> if you want random
4203 integers instead of random fractional numbers.  For example,
4204
4205     int(rand(10))
4206
4207 returns a random integer between C<0> and C<9>, inclusive.
4208
4209 (Note: If your rand function consistently returns numbers that are too
4210 large or too small, then your version of Perl was probably compiled
4211 with the wrong number of RANDBITS.)
4212
4213 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
4214 X<read> X<file, read>
4215
4216 =item read FILEHANDLE,SCALAR,LENGTH
4217
4218 Attempts to read LENGTH I<characters> of data into variable SCALAR
4219 from the specified FILEHANDLE.  Returns the number of characters
4220 actually read, C<0> at end of file, or undef if there was an error (in
4221 the latter case C<$!> is also set).  SCALAR will be grown or shrunk 
4222 so that the last character actually read is the last character of the
4223 scalar after the read.
4224
4225 An OFFSET may be specified to place the read data at some place in the
4226 string other than the beginning.  A negative OFFSET specifies
4227 placement at that many characters counting backwards from the end of
4228 the string.  A positive OFFSET greater than the length of SCALAR
4229 results in the string being padded to the required size with C<"\0">
4230 bytes before the result of the read is appended.
4231
4232 The call is actually implemented in terms of either Perl's or system's
4233 fread() call.  To get a true read(2) system call, see C<sysread>.
4234
4235 Note the I<characters>: depending on the status of the filehandle,
4236 either (8-bit) bytes or characters are read.  By default all
4237 filehandles operate on bytes, but for example if the filehandle has
4238 been opened with the C<:utf8> I/O layer (see L</open>, and the C<open>
4239 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4240 characters, not bytes.  Similarly for the C<:encoding> pragma:
4241 in that case pretty much any characters can be read.
4242
4243 =item readdir DIRHANDLE
4244 X<readdir>
4245
4246 Returns the next directory entry for a directory opened by C<opendir>.
4247 If used in list context, returns all the rest of the entries in the
4248 directory.  If there are no more entries, returns an undefined value in
4249 scalar context or a null list in list context.
4250
4251 If you're planning to filetest the return values out of a C<readdir>, you'd
4252 better prepend the directory in question.  Otherwise, because we didn't
4253 C<chdir> there, it would have been testing the wrong file.
4254
4255     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
4256     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
4257     closedir DIR;
4258
4259 =item readline EXPR
4260
4261 =item readline
4262 X<readline> X<gets> X<fgets>
4263
4264 Reads from the filehandle whose typeglob is contained in EXPR (or from
4265 *ARGV if EXPR is not provided).  In scalar context, each call reads and
4266 returns the next line, until end-of-file is reached, whereupon the
4267 subsequent call returns undef.  In list context, reads until end-of-file
4268 is reached and returns a list of lines.  Note that the notion of "line"
4269 used here is however you may have defined it with C<$/> or
4270 C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
4271
4272 When C<$/> is set to C<undef>, when readline() is in scalar
4273 context (i.e. file slurp mode), and when an empty file is read, it
4274 returns C<''> the first time, followed by C<undef> subsequently.
4275
4276 This is the internal function implementing the C<< <EXPR> >>
4277 operator, but you can use it directly.  The C<< <EXPR> >>
4278 operator is discussed in more detail in L<perlop/"I/O Operators">.
4279
4280     $line = <STDIN>;
4281     $line = readline(*STDIN);           # same thing
4282
4283 If readline encounters an operating system error, C<$!> will be set with the
4284 corresponding error message.  It can be helpful to check C<$!> when you are
4285 reading from filehandles you don't trust, such as a tty or a socket.  The
4286 following example uses the operator form of C<readline>, and takes the necessary
4287 steps to ensure that C<readline> was successful.
4288
4289     for (;;) {
4290         undef $!;
4291         unless (defined( $line = <> )) {
4292             die $! if $!;
4293             last; # reached EOF
4294         }
4295         # ...
4296     }
4297
4298 =item readlink EXPR
4299 X<readlink>
4300
4301 =item readlink
4302
4303 Returns the value of a symbolic link, if symbolic links are
4304 implemented.  If not, gives a fatal error.  If there is some system
4305 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
4306 omitted, uses C<$_>.
4307
4308 =item readpipe EXPR
4309
4310 =item readpipe
4311 X<readpipe>
4312
4313 EXPR is executed as a system command.
4314 The collected standard output of the command is returned.
4315 In scalar context, it comes back as a single (potentially
4316 multi-line) string.  In list context, returns a list of lines
4317 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
4318 This is the internal function implementing the C<qx/EXPR/>
4319 operator, but you can use it directly.  The C<qx/EXPR/>
4320 operator is discussed in more detail in L<perlop/"I/O Operators">.
4321 If EXPR is omitted, uses C<$_>.
4322
4323 =item recv SOCKET,SCALAR,LENGTH,FLAGS
4324 X<recv>
4325
4326 Receives a message on a socket.  Attempts to receive LENGTH characters
4327 of data into variable SCALAR from the specified SOCKET filehandle.
4328 SCALAR will be grown or shrunk to the length actually read.  Takes the
4329 same flags as the system call of the same name.  Returns the address
4330 of the sender if SOCKET's protocol supports this; returns an empty
4331 string otherwise.  If there's an error, returns the undefined value.
4332 This call is actually implemented in terms of recvfrom(2) system call.
4333 See L<perlipc/"UDP: Message Passing"> for examples.
4334
4335 Note the I<characters>: depending on the status of the socket, either
4336 (8-bit) bytes or characters are received.  By default all sockets
4337 operate on bytes, but for example if the socket has been changed using
4338 binmode() to operate with the C<:utf8> I/O layer (see the C<open>
4339 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4340 characters, not bytes.  Similarly for the C<:encoding> pragma:
4341 in that case pretty much any characters can be read.
4342
4343 =item redo LABEL
4344 X<redo>
4345
4346 =item redo
4347
4348 The C<redo> command restarts the loop block without evaluating the
4349 conditional again.  The C<continue> block, if any, is not executed.  If
4350 the LABEL is omitted, the command refers to the innermost enclosing
4351 loop.  Programs that want to lie to themselves about what was just input 
4352 normally use this command:
4353
4354     # a simpleminded Pascal comment stripper
4355     # (warning: assumes no { or } in strings)
4356     LINE: while (<STDIN>) {
4357         while (s|({.*}.*){.*}|$1 |) {}
4358         s|{.*}| |;
4359         if (s|{.*| |) {
4360             $front = $_;
4361             while (<STDIN>) {
4362                 if (/}/) {      # end of comment?
4363                     s|^|$front\{|;
4364                     redo LINE;
4365                 }
4366             }
4367         }
4368         print;
4369     }
4370
4371 C<redo> cannot be used to retry a block which returns a value such as
4372 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
4373 a grep() or map() operation.
4374
4375 Note that a block by itself is semantically identical to a loop
4376 that executes once.  Thus C<redo> inside such a block will effectively
4377 turn it into a looping construct.
4378
4379 See also L</continue> for an illustration of how C<last>, C<next>, and
4380 C<redo> work.
4381
4382 =item ref EXPR
4383 X<ref> X<reference>
4384
4385 =item ref
4386
4387 Returns a non-empty string if EXPR is a reference, the empty
4388 string otherwise. If EXPR
4389 is not specified, C<$_> will be used.  The value returned depends on the
4390 type of thing the reference is a reference to.
4391 Builtin types include:
4392
4393     SCALAR
4394     ARRAY
4395     HASH
4396     CODE
4397     REF
4398     GLOB
4399     LVALUE
4400     FORMAT
4401     IO
4402     VSTRING
4403     Regexp
4404
4405 If the referenced object has been blessed into a package, then that package
4406 name is returned instead.  You can think of C<ref> as a C<typeof> operator.
4407
4408     if (ref($r) eq "HASH") {
4409         print "r is a reference to a hash.\n";
4410     }
4411     unless (ref($r)) {
4412         print "r is not a reference at all.\n";
4413     }
4414
4415 The return value C<LVALUE> indicates a reference to an lvalue that is not
4416 a variable. You get this from taking the reference of function calls like
4417 C<pos()> or C<substr()>. C<VSTRING> is returned if the reference points
4418 to a L<version string|perldata\"Version Strings">.
4419
4420 The result C<Regexp> indicates that the argument is a regular expression
4421 resulting from C<qr//>.
4422
4423 See also L<perlref>.
4424
4425 =item rename OLDNAME,NEWNAME
4426 X<rename> X<move> X<mv> X<ren>
4427
4428 Changes the name of a file; an existing file NEWNAME will be
4429 clobbered.  Returns true for success, false otherwise.
4430
4431 Behavior of this function varies wildly depending on your system
4432 implementation.  For example, it will usually not work across file system
4433 boundaries, even though the system I<mv> command sometimes compensates
4434 for this.  Other restrictions include whether it works on directories,
4435 open files, or pre-existing files.  Check L<perlport> and either the
4436 rename(2) manpage or equivalent system documentation for details.
4437
4438 For a platform independent C<move> function look at the L<File::Copy>
4439 module.
4440
4441 =item require VERSION
4442 X<require>
4443
4444 =item require EXPR
4445
4446 =item require
4447
4448 Demands a version of Perl specified by VERSION, or demands some semantics
4449 specified by EXPR or by C<$_> if EXPR is not supplied.
4450
4451 VERSION may be either a numeric argument such as 5.006, which will be
4452 compared to C<$]>, or a literal of the form v5.6.1, which will be compared
4453 to C<$^V> (aka $PERL_VERSION).  A fatal error is produced at run time if
4454 VERSION is greater than the version of the current Perl interpreter.
4455 Compare with L</use>, which can do a similar check at compile time.
4456
4457 Specifying VERSION as a literal of the form v5.6.1 should generally be
4458 avoided, because it leads to misleading error messages under earlier
4459 versions of Perl that do not support this syntax.  The equivalent numeric
4460 version should be used instead.
4461
4462     require v5.6.1;     # run time version check
4463     require 5.6.1;      # ditto
4464     require 5.006_001;  # ditto; preferred for backwards compatibility
4465
4466 Otherwise, C<require> demands that a library file be included if it
4467 hasn't already been included.  The file is included via the do-FILE
4468 mechanism, which is essentially just a variety of C<eval> with the
4469 caveat that lexical variables in the invoking script will be invisible
4470 to the included code.  Has semantics similar to the following subroutine:
4471
4472     sub require {
4473        my ($filename) = @_;
4474        if (exists $INC{$filename}) {
4475            return 1 if $INC{$filename};
4476            die "Compilation failed in require";
4477        }
4478        my ($realfilename,$result);
4479        ITER: {
4480            foreach $prefix (@INC) {
4481                $realfilename = "$prefix/$filename";
4482                if (-f $realfilename) {
4483                    $INC{$filename} = $realfilename;
4484                    $result = do $realfilename;
4485                    last ITER;
4486                }
4487            }
4488            die "Can't find $filename in \@INC";
4489        }
4490        if ($@) {
4491            $INC{$filename} = undef;
4492            die $@;
4493        } elsif (!$result) {
4494            delete $INC{$filename};
4495            die "$filename did not return true value";
4496        } else {
4497            return $result;
4498        }
4499     }
4500
4501 Note that the file will not be included twice under the same specified
4502 name.
4503
4504 The file must return true as the last statement to indicate
4505 successful execution of any initialization code, so it's customary to
4506 end such a file with C<1;> unless you're sure it'll return true
4507 otherwise.  But it's better just to put the C<1;>, in case you add more
4508 statements.
4509
4510 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
4511 replaces "F<::>" with "F</>" in the filename for you,
4512 to make it easy to load standard modules.  This form of loading of
4513 modules does not risk altering your namespace.
4514
4515 In other words, if you try this:
4516
4517         require Foo::Bar;    # a splendid bareword
4518
4519 The require function will actually look for the "F<Foo/Bar.pm>" file in the
4520 directories specified in the C<@INC> array.
4521
4522 But if you try this:
4523
4524         $class = 'Foo::Bar';
4525         require $class;      # $class is not a bareword
4526     #or
4527         require "Foo::Bar";  # not a bareword because of the ""
4528
4529 The require function will look for the "F<Foo::Bar>" file in the @INC array and
4530 will complain about not finding "F<Foo::Bar>" there.  In this case you can do:
4531
4532         eval "require $class";
4533
4534 Now that you understand how C<require> looks for files in the case of a
4535 bareword argument, there is a little extra functionality going on behind
4536 the scenes.  Before C<require> looks for a "F<.pm>" extension, it will
4537 first look for a similar filename with a "F<.pmc>" extension. If this file
4538 is found, it will be loaded in place of any file ending in a "F<.pm>"
4539 extension.
4540
4541 You can also insert hooks into the import facility, by putting directly
4542 Perl code into the @INC array.  There are three forms of hooks: subroutine
4543 references, array references and blessed objects.
4544
4545 Subroutine references are the simplest case.  When the inclusion system
4546 walks through @INC and encounters a subroutine, this subroutine gets
4547 called with two parameters, the first being a reference to itself, and the
4548 second the name of the file to be included (e.g. "F<Foo/Bar.pm>").  The
4549 subroutine should return nothing, or a list of up to three values in the
4550 following order:
4551
4552 =over
4553
4554 =item 1
4555
4556 A filehandle, from which the file will be read.  
4557
4558 =item 2
4559
4560 A reference to a subroutine. If there is no filehandle (previous item),
4561 then this subroutine is expected to generate one line of source code per
4562 call, writing the line into C<$_> and returning 1, then returning 0 at
4563 "end of file". If there is a filehandle, then the subroutine will be
4564 called to act a simple source filter, with the line as read in C<$_>.
4565 Again, return 1 for each valid line, and 0 after all lines have been
4566 returned.
4567
4568 =item 3
4569
4570 Optional state for the subroutine. The state is passed in as C<$_[1]>. A
4571 reference to the subroutine itself is passed in as C<$_[0]>.
4572
4573 =back
4574
4575 If an empty list, C<undef>, or nothing that matches the first 3 values above
4576 is returned then C<require> will look at the remaining elements of @INC.
4577 Note that this file handle must be a real file handle (strictly a typeglob,
4578 or reference to a typeglob, blessed or unblessed) - tied file handles will be
4579 ignored and return value processing will stop there.
4580
4581 If the hook is an array reference, its first element must be a subroutine
4582 reference.  This subroutine is called as above, but the first parameter is
4583 the array reference.  This enables to pass indirectly some arguments to
4584 the subroutine.
4585
4586 In other words, you can write:
4587
4588     push @INC, \&my_sub;
4589     sub my_sub {
4590         my ($coderef, $filename) = @_;  # $coderef is \&my_sub
4591         ...
4592     }
4593
4594 or:
4595
4596     push @INC, [ \&my_sub, $x, $y, ... ];
4597     sub my_sub {
4598         my ($arrayref, $filename) = @_;
4599         # Retrieve $x, $y, ...
4600         my @parameters = @$arrayref[1..$#$arrayref];
4601         ...
4602     }
4603
4604 If the hook is an object, it must provide an INC method that will be
4605 called as above, the first parameter being the object itself.  (Note that
4606 you must fully qualify the sub's name, as unqualified C<INC> is always forced
4607 into package C<main>.)  Here is a typical code layout:
4608
4609     # In Foo.pm
4610     package Foo;
4611     sub new { ... }
4612     sub Foo::INC {
4613         my ($self, $filename) = @_;
4614         ...
4615     }
4616
4617     # In the main program
4618     push @INC, new Foo(...);
4619
4620 Note that these hooks are also permitted to set the %INC entry
4621 corresponding to the files they have loaded. See L<perlvar/%INC>.
4622
4623 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
4624
4625 =item reset EXPR
4626 X<reset>
4627
4628 =item reset
4629
4630 Generally used in a C<continue> block at the end of a loop to clear
4631 variables and reset C<??> searches so that they work again.  The
4632 expression is interpreted as a list of single characters (hyphens
4633 allowed for ranges).  All variables and arrays beginning with one of
4634 those letters are reset to their pristine state.  If the expression is
4635 omitted, one-match searches (C<?pattern?>) are reset to match again.  Resets
4636 only variables or searches in the current package.  Always returns
4637 1.  Examples:
4638
4639     reset 'X';          # reset all X variables
4640     reset 'a-z';        # reset lower case variables
4641     reset;              # just reset ?one-time? searches
4642
4643 Resetting C<"A-Z"> is not recommended because you'll wipe out your
4644 C<@ARGV> and C<@INC> arrays and your C<%ENV> hash.  Resets only package
4645 variables--lexical variables are unaffected, but they clean themselves
4646 up on scope exit anyway, so you'll probably want to use them instead.
4647 See L</my>.
4648
4649 =item return EXPR
4650 X<return>
4651
4652 =item return
4653
4654 Returns from a subroutine, C<eval>, or C<do FILE> with the value
4655 given in EXPR.  Evaluation of EXPR may be in list, scalar, or void
4656 context, depending on how the return value will be used, and the context
4657 may vary from one execution to the next (see C<wantarray>).  If no EXPR
4658 is given, returns an empty list in list context, the undefined value in
4659 scalar context, and (of course) nothing at all in a void context.
4660
4661 (Note that in the absence of an explicit C<return>, a subroutine, eval,
4662 or do FILE will automatically return the value of the last expression
4663 evaluated.)
4664
4665 =item reverse LIST
4666 X<reverse> X<rev> X<invert>
4667
4668 In list context, returns a list value consisting of the elements
4669 of LIST in the opposite order.  In scalar context, concatenates the
4670 elements of LIST and returns a string value with all characters
4671 in the opposite order.
4672
4673     print reverse <>;           # line tac, last line first
4674
4675     undef $/;                   # for efficiency of <>
4676     print scalar reverse <>;    # character tac, last line tsrif
4677
4678 Used without arguments in scalar context, reverse() reverses C<$_>.
4679
4680 This operator is also handy for inverting a hash, although there are some
4681 caveats.  If a value is duplicated in the original hash, only one of those
4682 can be represented as a key in the inverted hash.  Also, this has to
4683 unwind one hash and build a whole new one, which may take some time
4684 on a large hash, such as from a DBM file.
4685
4686     %by_name = reverse %by_address;     # Invert the hash
4687
4688 =item rewinddir DIRHANDLE
4689 X<rewinddir>
4690
4691 Sets the current position to the beginning of the directory for the
4692 C<readdir> routine on DIRHANDLE.
4693
4694 =item rindex STR,SUBSTR,POSITION
4695 X<rindex>
4696
4697 =item rindex STR,SUBSTR
4698
4699 Works just like index() except that it returns the position of the I<last>
4700 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
4701 last occurrence beginning at or before that position.
4702
4703 =item rmdir FILENAME
4704 X<rmdir> X<rd> X<directory, remove>
4705
4706 =item rmdir
4707
4708 Deletes the directory specified by FILENAME if that directory is
4709 empty.  If it succeeds it returns true, otherwise it returns false and
4710 sets C<$!> (errno).  If FILENAME is omitted, uses C<$_>.
4711
4712 To remove a directory tree recursively (C<rm -rf> on unix) look at
4713 the C<rmtree> function of the L<File::Path> module.
4714
4715 =item s///
4716
4717 The substitution operator.  See L<perlop>.
4718
4719 =item say FILEHANDLE LIST
4720 X<say>
4721
4722 =item say LIST
4723
4724 =item say
4725
4726 Just like C<print>, but implicitly appends a newline.
4727 C<say LIST> is simply an abbreviation for C<{ local $\ = "\n"; print
4728 LIST }>.
4729
4730 This keyword is only available when the "say" feature is
4731 enabled: see L<feature>.
4732
4733 =item scalar EXPR
4734 X<scalar> X<context>
4735
4736 Forces EXPR to be interpreted in scalar context and returns the value
4737 of EXPR.
4738
4739     @counts = ( scalar @a, scalar @b, scalar @c );
4740
4741 There is no equivalent operator to force an expression to
4742 be interpolated in list context because in practice, this is never
4743 needed.  If you really wanted to do so, however, you could use
4744 the construction C<@{[ (some expression) ]}>, but usually a simple
4745 C<(some expression)> suffices.
4746
4747 Because C<scalar> is unary operator, if you accidentally use for EXPR a
4748 parenthesized list, this behaves as a scalar comma expression, evaluating
4749 all but the last element in void context and returning the final element
4750 evaluated in scalar context.  This is seldom what you want.
4751
4752 The following single statement:
4753
4754         print uc(scalar(&foo,$bar)),$baz;
4755
4756 is the moral equivalent of these two:
4757
4758         &foo;
4759         print(uc($bar),$baz);
4760
4761 See L<perlop> for more details on unary operators and the comma operator.
4762
4763 =item seek FILEHANDLE,POSITION,WHENCE
4764 X<seek> X<fseek> X<filehandle, position>
4765
4766 Sets FILEHANDLE's position, just like the C<fseek> call of C<stdio>.
4767 FILEHANDLE may be an expression whose value gives the name of the
4768 filehandle.  The values for WHENCE are C<0> to set the new position
4769 I<in bytes> to POSITION, C<1> to set it to the current position plus
4770 POSITION, and C<2> to set it to EOF plus POSITION (typically
4771 negative).  For WHENCE you may use the constants C<SEEK_SET>,
4772 C<SEEK_CUR>, and C<SEEK_END> (start of the file, current position, end
4773 of the file) from the Fcntl module.  Returns C<1> upon success, C<0>
4774 otherwise.
4775
4776 Note the I<in bytes>: even if the filehandle has been set to
4777 operate on characters (for example by using the C<:utf8> open
4778 layer), tell() will return byte offsets, not character offsets
4779 (because implementing that would render seek() and tell() rather slow).
4780
4781 If you want to position file for C<sysread> or C<syswrite>, don't use
4782 C<seek>--buffering makes its effect on the file's system position
4783 unpredictable and non-portable.  Use C<sysseek> instead.
4784
4785 Due to the rules and rigors of ANSI C, on some systems you have to do a
4786 seek whenever you switch between reading and writing.  Amongst other
4787 things, this may have the effect of calling stdio's clearerr(3).
4788 A WHENCE of C<1> (C<SEEK_CUR>) is useful for not moving the file position:
4789
4790     seek(TEST,0,1);
4791
4792 This is also useful for applications emulating C<tail -f>.  Once you hit
4793 EOF on your read, and then sleep for a while, you might have to stick in a
4794 seek() to reset things.  The C<seek> doesn't change the current position,
4795 but it I<does> clear the end-of-file condition on the handle, so that the
4796 next C<< <FILE> >> makes Perl try again to read something.  We hope.
4797
4798 If that doesn't work (some IO implementations are particularly
4799 cantankerous), then you may need something more like this:
4800
4801     for (;;) {
4802         for ($curpos = tell(FILE); $_ = <FILE>;
4803              $curpos = tell(FILE)) {
4804             # search for some stuff and put it into files
4805         }
4806         sleep($for_a_while);
4807         seek(FILE, $curpos, 0);
4808     }
4809
4810 =item seekdir DIRHANDLE,POS
4811 X<seekdir>
4812
4813 Sets the current position for the C<readdir> routine on DIRHANDLE.  POS
4814 must be a value returned by C<telldir>.  C<seekdir> also has the same caveats
4815 about possible directory compaction as the corresponding system library
4816 routine.
4817
4818 =item select FILEHANDLE
4819 X<select> X<filehandle, default>
4820
4821 =item select
4822
4823 Returns the currently selected filehandle.  If FILEHANDLE is supplied,
4824 sets the new current default filehandle for output.  This has two
4825 effects: first, a C<write> or a C<print> without a filehandle will
4826 default to this FILEHANDLE.  Second, references to variables related to
4827 output will refer to this output channel.  For example, if you have to
4828 set the top of form format for more than one output channel, you might
4829 do the following:
4830
4831     select(REPORT1);
4832     $^ = 'report1_top';
4833     select(REPORT2);
4834     $^ = 'report2_top';
4835
4836 FILEHANDLE may be an expression whose value gives the name of the
4837 actual filehandle.  Thus:
4838
4839     $oldfh = select(STDERR); $| = 1; select($oldfh);
4840
4841 Some programmers may prefer to think of filehandles as objects with
4842 methods, preferring to write the last example as:
4843
4844     use IO::Handle;
4845     STDERR->autoflush(1);
4846
4847 =item select RBITS,WBITS,EBITS,TIMEOUT
4848 X<select>
4849
4850 This calls the select(2) system call with the bit masks specified, which
4851 can be constructed using C<fileno> and C<vec>, along these lines:
4852
4853     $rin = $win = $ein = '';
4854     vec($rin,fileno(STDIN),1) = 1;
4855     vec($win,fileno(STDOUT),1) = 1;
4856     $ein = $rin | $win;
4857
4858 If you want to select on many filehandles you might wish to write a
4859 subroutine:
4860
4861     sub fhbits {
4862         my(@fhlist) = split(' ',$_[0]);
4863         my($bits);
4864         for (@fhlist) {
4865             vec($bits,fileno($_),1) = 1;
4866         }
4867         $bits;
4868     }
4869     $rin = fhbits('STDIN TTY SOCK');
4870
4871 The usual idiom is:
4872
4873     ($nfound,$timeleft) =
4874       select($rout=$rin, $wout=$win, $eout=$ein, $timeout);
4875
4876 or to block until something becomes ready just do this
4877
4878     $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);
4879
4880 Most systems do not bother to return anything useful in $timeleft, so
4881 calling select() in scalar context just returns $nfound.
4882
4883 Any of the bit masks can also be undef.  The timeout, if specified, is
4884 in seconds, which may be fractional.  Note: not all implementations are
4885 capable of returning the $timeleft.  If not, they always return
4886 $timeleft equal to the supplied $timeout.
4887
4888 You can effect a sleep of 250 milliseconds this way:
4889
4890     select(undef, undef, undef, 0.25);
4891
4892 Note that whether C<select> gets restarted after signals (say, SIGALRM)
4893 is implementation-dependent.  See also L<perlport> for notes on the
4894 portability of C<select>.
4895
4896 On error, C<select> behaves like the select(2) system call : it returns
4897 -1 and sets C<$!>.
4898
4899 Note: on some Unixes, the select(2) system call may report a socket file
4900 descriptor as "ready for reading", when actually no data is available,
4901 thus a subsequent read blocks. It can be avoided using always the
4902 O_NONBLOCK flag on the socket. See select(2) and fcntl(2) for further
4903 details.
4904
4905 B<WARNING>: One should not attempt to mix buffered I/O (like C<read>
4906 or <FH>) with C<select>, except as permitted by POSIX, and even
4907 then only on POSIX systems.  You have to use C<sysread> instead.
4908
4909 =item semctl ID,SEMNUM,CMD,ARG
4910 X<semctl>
4911
4912 Calls the System V IPC function C<semctl>.  You'll probably have to say
4913
4914     use IPC::SysV;
4915
4916 first to get the correct constant definitions.  If CMD is IPC_STAT or
4917 GETALL, then ARG must be a variable that will hold the returned
4918 semid_ds structure or semaphore value array.  Returns like C<ioctl>:
4919 the undefined value for error, "C<0 but true>" for zero, or the actual
4920 return value otherwise.  The ARG must consist of a vector of native
4921 short integers, which may be created with C<pack("s!",(0)x$nsem)>.
4922 See also L<perlipc/"SysV IPC">, C<IPC::SysV>, C<IPC::Semaphore>
4923 documentation.
4924
4925 =item semget KEY,NSEMS,FLAGS
4926 X<semget>
4927
4928 Calls the System V IPC function semget.  Returns the semaphore id, or
4929 the undefined value if there is an error.  See also
4930 L<perlipc/"SysV IPC">, C<IPC::SysV>, C<IPC::SysV::Semaphore>
4931 documentation.
4932
4933 =item semop KEY,OPSTRING
4934 X<semop>
4935
4936 Calls the System V IPC function semop to perform semaphore operations
4937 such as signalling and waiting.  OPSTRING must be a packed array of
4938 semop structures.  Each semop structure can be generated with
4939 C<pack("s!3", $semnum, $semop, $semflag)>.  The length of OPSTRING 
4940 implies the number of semaphore operations.  Returns true if
4941 successful, or false if there is an error.  As an example, the
4942 following code waits on semaphore $semnum of semaphore id $semid:
4943
4944     $semop = pack("s!3", $semnum, -1, 0);
4945     die "Semaphore trouble: $!\n" unless semop($semid, $semop);
4946
4947 To signal the semaphore, replace C<-1> with C<1>.  See also
4948 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::SysV::Semaphore>
4949 documentation.
4950
4951 =item send SOCKET,MSG,FLAGS,TO
4952 X<send>
4953
4954 =item send SOCKET,MSG,FLAGS
4955
4956 Sends a message on a socket.  Attempts to send the scalar MSG to the
4957 SOCKET filehandle.  Takes the same flags as the system call of the
4958 same name.  On unconnected sockets you must specify a destination to
4959 send TO, in which case it does a C C<sendto>.  Returns the number of
4960 characters sent, or the undefined value if there is an error.  The C
4961 system call sendmsg(2) is currently unimplemented.  See
4962 L<perlipc/"UDP: Message Passing"> for examples.
4963
4964 Note the I<characters>: depending on the status of the socket, either
4965 (8-bit) bytes or characters are sent.  By default all sockets operate
4966 on bytes, but for example if the socket has been changed using
4967 binmode() to operate with the C<:utf8> I/O layer (see L</open>, or the
4968 C<open> pragma, L<open>), the I/O will operate on UTF-8 encoded
4969 Unicode characters, not bytes.  Similarly for the C<:encoding> pragma:
4970 in that case pretty much any characters can be sent.
4971
4972 =item setpgrp PID,PGRP
4973 X<setpgrp> X<group>
4974
4975 Sets the current process group for the specified PID, C<0> for the current
4976 process.  Will produce a fatal error if used on a machine that doesn't
4977 implement POSIX setpgid(2) or BSD setpgrp(2).  If the arguments are omitted,
4978 it defaults to C<0,0>.  Note that the BSD 4.2 version of C<setpgrp> does not
4979 accept any arguments, so only C<setpgrp(0,0)> is portable.  See also
4980 C<POSIX::setsid()>.
4981
4982 =item setpriority WHICH,WHO,PRIORITY
4983 X<setpriority> X<priority> X<nice> X<renice>
4984
4985 Sets the current priority for a process, a process group, or a user.
4986 (See setpriority(2).)  Will produce a fatal error if used on a machine
4987 that doesn't implement setpriority(2).
4988
4989 =item setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL
4990 X<setsockopt>
4991
4992 Sets the socket option requested.  Returns undefined if there is an
4993 error.  Use integer constants provided by the C<Socket> module for
4994 LEVEL and OPNAME.  Values for LEVEL can also be obtained from
4995 getprotobyname.  OPTVAL might either be a packed string or an integer.
4996 An integer OPTVAL is shorthand for pack("i", OPTVAL).
4997
4998 An example disabling the Nagle's algorithm for a socket:
4999
5000     use Socket qw(IPPROTO_TCP TCP_NODELAY);
5001     setsockopt($socket, IPPROTO_TCP, TCP_NODELAY, 1);
5002
5003 =item shift ARRAY
5004 X<shift>
5005
5006 =item shift
5007
5008 Shifts the first value of the array off and returns it, shortening the
5009 array by 1 and moving everything down.  If there are no elements in the
5010 array, returns the undefined value.  If ARRAY is omitted, shifts the
5011 C<@_> array within the lexical scope of subroutines and formats, and the
5012 C<@ARGV> array outside of a subroutine and also within the lexical scopes
5013 established by the C<eval STRING>, C<BEGIN {}>, C<INIT {}>, C<CHECK {}>,
5014 C<UNITCHECK {}> and C<END {}> constructs.
5015
5016 See also C<unshift>, C<push>, and C<pop>.  C<shift> and C<unshift> do the
5017 same thing to the left end of an array that C<pop> and C<push> do to the
5018 right end.
5019
5020 =item shmctl ID,CMD,ARG
5021 X<shmctl>
5022
5023 Calls the System V IPC function shmctl.  You'll probably have to say
5024
5025     use IPC::SysV;
5026
5027 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
5028 then ARG must be a variable that will hold the returned C<shmid_ds>
5029 structure.  Returns like ioctl: the undefined value for error, "C<0> but
5030 true" for zero, or the actual return value otherwise.
5031 See also L<perlipc/"SysV IPC"> and C<IPC::SysV> documentation.
5032
5033 =item shmget KEY,SIZE,FLAGS
5034 X<shmget>
5035
5036 Calls the System V IPC function shmget.  Returns the shared memory
5037 segment id, or the undefined value if there is an error.
5038 See also L<perlipc/"SysV IPC"> and C<IPC::SysV> documentation.
5039
5040 =item shmread ID,VAR,POS,SIZE
5041 X<shmread>
5042 X<shmwrite>
5043
5044 =item shmwrite ID,STRING,POS,SIZE
5045
5046 Reads or writes the System V shared memory segment ID starting at
5047 position POS for size SIZE by attaching to it, copying in/out, and
5048 detaching from it.  When reading, VAR must be a variable that will
5049 hold the data read.  When writing, if STRING is too long, only SIZE
5050 bytes are used; if STRING is too short, nulls are written to fill out
5051 SIZE bytes.  Return true if successful, or false if there is an error.
5052 shmread() taints the variable. See also L<perlipc/"SysV IPC">,
5053 C<IPC::SysV> documentation, and the C<IPC::Shareable> module from CPAN.
5054
5055 =item shutdown SOCKET,HOW
5056 X<shutdown>
5057
5058 Shuts down a socket connection in the manner indicated by HOW, which
5059 has the same interpretation as in the system call of the same name.
5060
5061     shutdown(SOCKET, 0);    # I/we have stopped reading data
5062     shutdown(SOCKET, 1);    # I/we have stopped writing data
5063     shutdown(SOCKET, 2);    # I/we have stopped using this socket
5064
5065 This is useful with sockets when you want to tell the other
5066 side you're done writing but not done reading, or vice versa.
5067 It's also a more insistent form of close because it also
5068 disables the file descriptor in any forked copies in other
5069 processes.
5070
5071 =item sin EXPR
5072 X<sin> X<sine> X<asin> X<arcsine>
5073
5074 =item sin
5075
5076 Returns the sine of EXPR (expressed in radians).  If EXPR is omitted,
5077 returns sine of C<$_>.
5078
5079 For the inverse sine operation, you may use the C<Math::Trig::asin>
5080 function, or use this relation:
5081
5082     sub asin { atan2($_[0], sqrt(1 - $_[0] * $_[0])) }
5083
5084 =item sleep EXPR
5085 X<sleep> X<pause>
5086
5087 =item sleep
5088
5089 Causes the script to sleep for EXPR seconds, or forever if no EXPR.
5090 May be interrupted if the process receives a signal such as C<SIGALRM>.
5091 Returns the number of seconds actually slept.  You probably cannot
5092 mix C<alarm> and C<sleep> calls, because C<sleep> is often implemented
5093 using C<alarm>.
5094
5095 On some older systems, it may sleep up to a full second less than what
5096 you requested, depending on how it counts seconds.  Most modern systems
5097 always sleep the full amount.  They may appear to sleep longer than that,
5098 however, because your process might not be scheduled right away in a
5099 busy multitasking system.
5100
5101 For delays of finer granularity than one second, you may use Perl's
5102 C<syscall> interface to access setitimer(2) if your system supports
5103 it, or else see L</select> above.  The Time::HiRes module (from CPAN,
5104 and starting from Perl 5.8 part of the standard distribution) may also
5105 help.
5106
5107 See also the POSIX module's C<pause> function.
5108
5109 =item socket SOCKET,DOMAIN,TYPE,PROTOCOL
5110 X<socket>
5111
5112 Opens a socket of the specified kind and attaches it to filehandle
5113 SOCKET.  DOMAIN, TYPE, and PROTOCOL are specified the same as for
5114 the system call of the same name.  You should C<use Socket> first
5115 to get the proper definitions imported.  See the examples in
5116 L<perlipc/"Sockets: Client/Server Communication">.
5117
5118 On systems that support a close-on-exec flag on files, the flag will
5119 be set for the newly opened file descriptor, as determined by the
5120 value of $^F.  See L<perlvar/$^F>.
5121
5122 =item socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL
5123 X<socketpair>
5124
5125 Creates an unnamed pair of sockets in the specified domain, of the
5126 specified type.  DOMAIN, TYPE, and PROTOCOL are specified the same as
5127 for the system call of the same name.  If unimplemented, yields a fatal
5128 error.  Returns true if successful.
5129
5130 On systems that support a close-on-exec flag on files, the flag will
5131 be set for the newly opened file descriptors, as determined by the value
5132 of $^F.  See L<perlvar/$^F>.
5133
5134 Some systems defined C<pipe> in terms of C<socketpair>, in which a call
5135 to C<pipe(Rdr, Wtr)> is essentially:
5136
5137     use Socket;
5138     socketpair(Rdr, Wtr, AF_UNIX, SOCK_STREAM, PF_UNSPEC);
5139     shutdown(Rdr, 1);        # no more writing for reader
5140     shutdown(Wtr, 0);        # no more reading for writer
5141
5142 See L<perlipc> for an example of socketpair use.  Perl 5.8 and later will
5143 emulate socketpair using IP sockets to localhost if your system implements
5144 sockets but not socketpair.
5145
5146 =item sort SUBNAME LIST
5147 X<sort> X<qsort> X<quicksort> X<mergesort>
5148
5149 =item sort BLOCK LIST
5150
5151 =item sort LIST
5152
5153 In list context, this sorts the LIST and returns the sorted list value.
5154 In scalar context, the behaviour of C<sort()> is undefined.
5155
5156 If SUBNAME or BLOCK is omitted, C<sort>s in standard string comparison
5157 order.  If SUBNAME is specified, it gives the name of a subroutine
5158 that returns an integer less than, equal to, or greater than C<0>,
5159 depending on how the elements of the list are to be ordered.  (The C<<
5160 <=> >> and C<cmp> operators are extremely useful in such routines.)
5161 SUBNAME may be a scalar variable name (unsubscripted), in which case
5162 the value provides the name of (or a reference to) the actual
5163 subroutine to use.  In place of a SUBNAME, you can provide a BLOCK as
5164 an anonymous, in-line sort subroutine.
5165
5166 If the subroutine's prototype is C<($$)>, the elements to be compared
5167 are passed by reference in C<@_>, as for a normal subroutine.  This is
5168 slower than unprototyped subroutines, where the elements to be
5169 compared are passed into the subroutine
5170 as the package global variables $a and $b (see example below).  Note that
5171 in the latter case, it is usually counter-productive to declare $a and
5172 $b as lexicals.
5173
5174 The values to be compared are always passed by reference and should not
5175 be modified.
5176
5177 You also cannot exit out of the sort block or subroutine using any of the
5178 loop control operators described in L<perlsyn> or with C<goto>.
5179
5180 When C<use locale> is in effect, C<sort LIST> sorts LIST according to the
5181 current collation locale.  See L<perllocale>.
5182
5183 sort() returns aliases into the original list, much as a for loop's index
5184 variable aliases the list elements.  That is, modifying an element of a
5185 list returned by sort() (for example, in a C<foreach>, C<map> or C<grep>)
5186 actually modifies the element in the original list.  This is usually
5187 something to be avoided when writing clear code.
5188
5189 Perl 5.6 and earlier used a quicksort algorithm to implement sort.
5190 That algorithm was not stable, and I<could> go quadratic.  (A I<stable> sort
5191 preserves the input order of elements that compare equal.  Although
5192 quicksort's run time is O(NlogN) when averaged over all arrays of
5193 length N, the time can be O(N**2), I<quadratic> behavior, for some
5194 inputs.)  In 5.7, the quicksort implementation was replaced with
5195 a stable mergesort algorithm whose worst-case behavior is O(NlogN).
5196 But benchmarks indicated that for some inputs, on some platforms,
5197 the original quicksort was faster.  5.8 has a sort pragma for
5198 limited control of the sort.  Its rather blunt control of the
5199 underlying algorithm may not persist into future Perls, but the
5200 ability to characterize the input or output in implementation
5201 independent ways quite probably will.  See L<sort>.
5202
5203 Examples:
5204
5205     # sort lexically
5206     @articles = sort @files;
5207
5208     # same thing, but with explicit sort routine
5209     @articles = sort {$a cmp $b} @files;
5210
5211     # now case-insensitively
5212     @articles = sort {uc($a) cmp uc($b)} @files;
5213
5214