This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
1609819382630f0c6dfb29bc94484c945c78012e
[perl5.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.
9
10 If you haven't used regular expressions before, a quick-start
11 introduction is available in L<perlrequick>, and a longer tutorial
12 introduction is available in L<perlretut>.
13
14 For reference on how regular expressions are used in matching
15 operations, plus various examples of the same, see discussions of
16 C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
17 Operators">.
18
19
20 =head2 Modifiers
21
22 Matching operations can have various modifiers.  Modifiers
23 that relate to the interpretation of the regular expression inside
24 are listed below.  Modifiers that alter the way a regular expression
25 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
26 L<perlop/"Gory details of parsing quoted constructs">.
27
28 =over 4
29
30 =item m
31 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
32
33 Treat string as multiple lines.  That is, change "^" and "$" from matching
34 the start or end of line only at the left and right ends of the string to
35 matching them anywhere within the string.
36
37 =item s
38 X</s> X<regex, single-line> X<regexp, single-line>
39 X<regular expression, single-line>
40
41 Treat string as single line.  That is, change "." to match any character
42 whatsoever, even a newline, which normally it would not match.
43
44 Used together, as C</ms>, they let the "." match any character whatsoever,
45 while still allowing "^" and "$" to match, respectively, just after
46 and just before newlines within the string.
47
48 =item i
49 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
50 X<regular expression, case-insensitive>
51
52 Do case-insensitive pattern matching.
53
54 If locale matching rules are in effect, the case map is taken from the
55 current
56 locale for code points less than 255, and from Unicode rules for larger
57 code points.  However, matches that would cross the Unicode
58 rules/non-Unicode rules boundary (ords 255/256) will not succeed.  See
59 L<perllocale>.
60
61 There are a number of Unicode characters that match multiple characters
62 under C</i>.  For example, C<LATIN SMALL LIGATURE FI>
63 should match the sequence C<fi>.  Perl is not
64 currently able to do this when the multiple characters are in the pattern and
65 are split between groupings, or when one or more are quantified.  Thus
66
67  "\N{LATIN SMALL LIGATURE FI}" =~ /fi/i;          # Matches
68  "\N{LATIN SMALL LIGATURE FI}" =~ /[fi][fi]/i;    # Doesn't match!
69  "\N{LATIN SMALL LIGATURE FI}" =~ /fi*/i;         # Doesn't match!
70
71  # The below doesn't match, and it isn't clear what $1 and $2 would
72  # be even if it did!!
73  "\N{LATIN SMALL LIGATURE FI}" =~ /(f)(i)/i;      # Doesn't match!
74
75 Perl doesn't match multiple characters in a bracketed
76 character class unless the character that maps to them is explicitly
77 mentioned, and it doesn't match them at all if the character class is
78 inverted, which otherwise could be highly confusing.  See
79 L<perlrecharclass/Bracketed Character Classes>, and
80 L<perlrecharclass/Negation>.
81
82 =item x
83 X</x>
84
85 Extend your pattern's legibility by permitting whitespace and comments.
86 Details in L</"/x">
87
88 =item p
89 X</p> X<regex, preserve> X<regexp, preserve>
90
91 Preserve the string matched such that ${^PREMATCH}, ${^MATCH}, and
92 ${^POSTMATCH} are available for use after matching.
93
94 In Perl 5.18 and higher this is ignored.  ${^PREMATCH}, ${^MATCH}, and
95 ${^POSTMATCH} will be available after the match regardless of the modifier.
96
97 =item g and c
98 X</g> X</c>
99
100 Global matching, and keep the Current position after failed matching.
101 Unlike i, m, s and x, these two flags affect the way the regex is used
102 rather than the regex itself. See
103 L<perlretut/"Using regular expressions in Perl"> for further explanation
104 of the g and c modifiers.
105
106 =item a, d, l and u
107 X</a> X</d> X</l> X</u>
108
109 These modifiers, all new in 5.14, affect which character-set semantics
110 (Unicode, etc.) are used, as described below in
111 L</Character set modifiers>.
112
113 =back
114
115 Regular expression modifiers are usually written in documentation
116 as e.g., "the C</x> modifier", even though the delimiter
117 in question might not really be a slash.  The modifiers C</imsxadlup>
118 may also be embedded within the regular expression itself using
119 the C<(?...)> construct, see L</Extended Patterns> below.
120
121 =head3 /x
122
123 C</x> tells
124 the regular expression parser to ignore most whitespace that is neither
125 backslashed nor within a character class.  You can use this to break up
126 your regular expression into (slightly) more readable parts.  The C<#>
127 character is also treated as a metacharacter introducing a comment,
128 just as in ordinary Perl code.  This also means that if you want real
129 whitespace or C<#> characters in the pattern (outside a character
130 class, where they are unaffected by C</x>), then you'll either have to
131 escape them (using backslashes or C<\Q...\E>) or encode them using octal,
132 hex, or C<\N{}> escapes.  Taken together, these features go a long way towards
133 making Perl's regular expressions more readable.  Note that you have to
134 be careful not to include the pattern delimiter in the comment--perl has
135 no way of knowing you did not intend to close the pattern early.  See
136 the C-comment deletion code in L<perlop>.  Also note that anything inside
137 a C<\Q...\E> stays unaffected by C</x>.  And note that C</x> doesn't affect
138 space interpretation within a single multi-character construct.  For
139 example in C<\x{...}>, regardless of the C</x> modifier, there can be no
140 spaces.  Same for a L<quantifier|/Quantifiers> such as C<{3}> or
141 C<{5,}>.  Similarly, C<(?:...)> can't have a space between the C<?> and C<:>,
142 but can between the C<(> and C<?>.  Within any delimiters for such a
143 construct, allowed spaces are not affected by C</x>, and depend on the
144 construct.  For example, C<\x{...}> can't have spaces because hexadecimal
145 numbers don't have spaces in them.  But, Unicode properties can have spaces, so
146 in C<\p{...}> there can be spaces that follow the Unicode rules, for which see
147 L<perluniprops/Properties accessible through \p{} and \P{}>.
148 X</x>
149
150 =head3 Character set modifiers
151
152 C</d>, C</u>, C</a>, and C</l>, available starting in 5.14, are called
153 the character set modifiers; they affect the character set semantics
154 used for the regular expression.
155
156 The C</d>, C</u>, and C</l> modifiers are not likely to be of much use
157 to you, and so you need not worry about them very much.  They exist for
158 Perl's internal use, so that complex regular expression data structures
159 can be automatically serialized and later exactly reconstituted,
160 including all their nuances.  But, since Perl can't keep a secret, and
161 there may be rare instances where they are useful, they are documented
162 here.
163
164 The C</a> modifier, on the other hand, may be useful.  Its purpose is to
165 allow code that is to work mostly on ASCII data to not have to concern
166 itself with Unicode.
167
168 Briefly, C</l> sets the character set to that of whatever B<L>ocale is in
169 effect at the time of the execution of the pattern match.
170
171 C</u> sets the character set to B<U>nicode.
172
173 C</a> also sets the character set to Unicode, BUT adds several
174 restrictions for B<A>SCII-safe matching.
175
176 C</d> is the old, problematic, pre-5.14 B<D>efault character set
177 behavior.  Its only use is to force that old behavior.
178
179 At any given time, exactly one of these modifiers is in effect.  Their
180 existence allows Perl to keep the originally compiled behavior of a
181 regular expression, regardless of what rules are in effect when it is
182 actually executed.  And if it is interpolated into a larger regex, the
183 original's rules continue to apply to it, and only it.
184
185 The C</l> and C</u> modifiers are automatically selected for
186 regular expressions compiled within the scope of various pragmas,
187 and we recommend that in general, you use those pragmas instead of
188 specifying these modifiers explicitly.  For one thing, the modifiers
189 affect only pattern matching, and do not extend to even any replacement
190 done, whereas using the pragmas give consistent results for all
191 appropriate operations within their scopes.  For example,
192
193  s/foo/\Ubar/il
194
195 will match "foo" using the locale's rules for case-insensitive matching,
196 but the C</l> does not affect how the C<\U> operates.  Most likely you
197 want both of them to use locale rules.  To do this, instead compile the
198 regular expression within the scope of C<use locale>.  This both
199 implicitly adds the C</l> and applies locale rules to the C<\U>.   The
200 lesson is to C<use locale> and not C</l> explicitly.
201
202 Similarly, it would be better to use C<use feature 'unicode_strings'>
203 instead of,
204
205  s/foo/\Lbar/iu
206
207 to get Unicode rules, as the C<\L> in the former (but not necessarily
208 the latter) would also use Unicode rules.
209
210 More detail on each of the modifiers follows.  Most likely you don't
211 need to know this detail for C</l>, C</u>, and C</d>, and can skip ahead
212 to L<E<sol>a|/E<sol>a (and E<sol>aa)>.
213
214 =head4 /l
215
216 means to use the current locale's rules (see L<perllocale>) when pattern
217 matching.  For example, C<\w> will match the "word" characters of that
218 locale, and C<"/i"> case-insensitive matching will match according to
219 the locale's case folding rules.  The locale used will be the one in
220 effect at the time of execution of the pattern match.  This may not be
221 the same as the compilation-time locale, and can differ from one match
222 to another if there is an intervening call of the
223 L<setlocale() function|perllocale/The setlocale function>.
224
225 Perl only supports single-byte locales.  This means that code points
226 above 255 are treated as Unicode no matter what locale is in effect.
227 Under Unicode rules, there are a few case-insensitive matches that cross
228 the 255/256 boundary.  These are disallowed under C</l>.  For example,
229 0xFF (on ASCII platforms) does not caselessly match the character at
230 0x178, C<LATIN CAPITAL LETTER Y WITH DIAERESIS>, because 0xFF may not be
231 C<LATIN SMALL LETTER Y WITH DIAERESIS> in the current locale, and Perl
232 has no way of knowing if that character even exists in the locale, much
233 less what code point it is.
234
235 This modifier may be specified to be the default by C<use locale>, but
236 see L</Which character set modifier is in effect?>.
237 X</l>
238
239 =head4 /u
240
241 means to use Unicode rules when pattern matching.  On ASCII platforms,
242 this means that the code points between 128 and 255 take on their
243 Latin-1 (ISO-8859-1) meanings (which are the same as Unicode's).
244 (Otherwise Perl considers their meanings to be undefined.)  Thus,
245 under this modifier, the ASCII platform effectively becomes a Unicode
246 platform; and hence, for example, C<\w> will match any of the more than
247 100_000 word characters in Unicode.
248
249 Unlike most locales, which are specific to a language and country pair,
250 Unicode classifies all the characters that are letters I<somewhere> in
251 the world as
252 C<\w>.  For example, your locale might not think that C<LATIN SMALL
253 LETTER ETH> is a letter (unless you happen to speak Icelandic), but
254 Unicode does.  Similarly, all the characters that are decimal digits
255 somewhere in the world will match C<\d>; this is hundreds, not 10,
256 possible matches.  And some of those digits look like some of the 10
257 ASCII digits, but mean a different number, so a human could easily think
258 a number is a different quantity than it really is.  For example,
259 C<BENGALI DIGIT FOUR> (U+09EA) looks very much like an
260 C<ASCII DIGIT EIGHT> (U+0038).  And, C<\d+>, may match strings of digits
261 that are a mixture from different writing systems, creating a security
262 issue.  L<Unicode::UCD/num()> can be used to sort
263 this out.  Or the C</a> modifier can be used to force C<\d> to match
264 just the ASCII 0 through 9.
265
266 Also, under this modifier, case-insensitive matching works on the full
267 set of Unicode
268 characters.  The C<KELVIN SIGN>, for example matches the letters "k" and
269 "K"; and C<LATIN SMALL LIGATURE FF> matches the sequence "ff", which,
270 if you're not prepared, might make it look like a hexadecimal constant,
271 presenting another potential security issue.  See
272 L<http://unicode.org/reports/tr36> for a detailed discussion of Unicode
273 security issues.
274
275 On the EBCDIC platforms that Perl handles, the native character set is
276 equivalent to Latin-1.  Thus this modifier changes behavior only when
277 the C<"/i"> modifier is also specified, and it turns out it affects only
278 two characters, giving them full Unicode semantics: the C<MICRO SIGN>
279 will match the Greek capital and small letters C<MU>, otherwise not; and
280 the C<LATIN CAPITAL LETTER SHARP S> will match any of C<SS>, C<Ss>,
281 C<sS>, and C<ss>, otherwise not.
282
283 This modifier may be specified to be the default by C<use feature
284 'unicode_strings>, C<use locale ':not_characters'>, or
285 C<L<use 5.012|perlfunc/use VERSION>> (or higher),
286 but see L</Which character set modifier is in effect?>.
287 X</u>
288
289 =head4 /d
290
291 This modifier means to use the "Default" native rules of the platform
292 except when there is cause to use Unicode rules instead, as follows:
293
294 =over 4
295
296 =item 1
297
298 the target string is encoded in UTF-8; or
299
300 =item 2
301
302 the pattern is encoded in UTF-8; or
303
304 =item 3
305
306 the pattern explicitly mentions a code point that is above 255 (say by
307 C<\x{100}>); or
308
309 =item 4
310
311 the pattern uses a Unicode name (C<\N{...}>);  or
312
313 =item 5
314
315 the pattern uses a Unicode property (C<\p{...}>); or
316
317 =item 6
318
319 the pattern uses L</C<(?[ ])>>
320
321 =back
322
323 Another mnemonic for this modifier is "Depends", as the rules actually
324 used depend on various things, and as a result you can get unexpected
325 results.  See L<perlunicode/The "Unicode Bug">.  The Unicode Bug has
326 become rather infamous, leading to yet another (printable) name for this
327 modifier, "Dodgy".
328
329 On ASCII platforms, the native rules are ASCII, and on EBCDIC platforms
330 (at least the ones that Perl handles), they are Latin-1.
331
332 Here are some examples of how that works on an ASCII platform:
333
334  $str =  "\xDF";      # $str is not in UTF-8 format.
335  $str =~ /^\w/;       # No match, as $str isn't in UTF-8 format.
336  $str .= "\x{0e0b}";  # Now $str is in UTF-8 format.
337  $str =~ /^\w/;       # Match! $str is now in UTF-8 format.
338  chop $str;
339  $str =~ /^\w/;       # Still a match! $str remains in UTF-8 format.
340
341 This modifier is automatically selected by default when none of the
342 others are, so yet another name for it is "Default".
343
344 Because of the unexpected behaviors associated with this modifier, you
345 probably should only use it to maintain weird backward compatibilities.
346
347 =head4 /a (and /aa)
348
349 This modifier stands for ASCII-restrict (or ASCII-safe).  This modifier,
350 unlike the others, may be doubled-up to increase its effect.
351
352 When it appears singly, it causes the sequences C<\d>, C<\s>, C<\w>, and
353 the Posix character classes to match only in the ASCII range.  They thus
354 revert to their pre-5.6, pre-Unicode meanings.  Under C</a>,  C<\d>
355 always means precisely the digits C<"0"> to C<"9">; C<\s> means the five
356 characters C<[ \f\n\r\t]>, and starting in Perl v5.18, experimentally,
357 the vertical tab; C<\w> means the 63 characters
358 C<[A-Za-z0-9_]>; and likewise, all the Posix classes such as
359 C<[[:print:]]> match only the appropriate ASCII-range characters.
360
361 This modifier is useful for people who only incidentally use Unicode,
362 and who do not wish to be burdened with its complexities and security
363 concerns.
364
365 With C</a>, one can write C<\d> with confidence that it will only match
366 ASCII characters, and should the need arise to match beyond ASCII, you
367 can instead use C<\p{Digit}> (or C<\p{Word}> for C<\w>).  There are
368 similar C<\p{...}> constructs that can match beyond ASCII both white
369 space (see L<perlrecharclass/Whitespace>), and Posix classes (see
370 L<perlrecharclass/POSIX Character Classes>).  Thus, this modifier
371 doesn't mean you can't use Unicode, it means that to get Unicode
372 matching you must explicitly use a construct (C<\p{}>, C<\P{}>) that
373 signals Unicode.
374
375 As you would expect, this modifier causes, for example, C<\D> to mean
376 the same thing as C<[^0-9]>; in fact, all non-ASCII characters match
377 C<\D>, C<\S>, and C<\W>.  C<\b> still means to match at the boundary
378 between C<\w> and C<\W>, using the C</a> definitions of them (similarly
379 for C<\B>).
380
381 Otherwise, C</a> behaves like the C</u> modifier, in that
382 case-insensitive matching uses Unicode semantics; for example, "k" will
383 match the Unicode C<\N{KELVIN SIGN}> under C</i> matching, and code
384 points in the Latin1 range, above ASCII will have Unicode rules when it
385 comes to case-insensitive matching.
386
387 To forbid ASCII/non-ASCII matches (like "k" with C<\N{KELVIN SIGN}>),
388 specify the "a" twice, for example C</aai> or C</aia>.  (The first
389 occurrence of "a" restricts the C<\d>, etc., and the second occurrence
390 adds the C</i> restrictions.)  But, note that code points outside the
391 ASCII range will use Unicode rules for C</i> matching, so the modifier
392 doesn't really restrict things to just ASCII; it just forbids the
393 intermixing of ASCII and non-ASCII.
394
395 To summarize, this modifier provides protection for applications that
396 don't wish to be exposed to all of Unicode.  Specifying it twice
397 gives added protection.
398
399 This modifier may be specified to be the default by C<use re '/a'>
400 or C<use re '/aa'>.  If you do so, you may actually have occasion to use
401 the C</u> modifier explictly if there are a few regular expressions
402 where you do want full Unicode rules (but even here, it's best if
403 everything were under feature C<"unicode_strings">, along with the
404 C<use re '/aa'>).  Also see L</Which character set modifier is in
405 effect?>.
406 X</a>
407 X</aa>
408
409 =head4 Which character set modifier is in effect?
410
411 Which of these modifiers is in effect at any given point in a regular
412 expression depends on a fairly complex set of interactions.  These have
413 been designed so that in general you don't have to worry about it, but
414 this section gives the gory details.  As
415 explained below in L</Extended Patterns> it is possible to explicitly
416 specify modifiers that apply only to portions of a regular expression.
417 The innermost always has priority over any outer ones, and one applying
418 to the whole expression has priority over any of the default settings that are
419 described in the remainder of this section.
420
421 The C<L<use re 'E<sol>foo'|re/"'/flags' mode">> pragma can be used to set
422 default modifiers (including these) for regular expressions compiled
423 within its scope.  This pragma has precedence over the other pragmas
424 listed below that also change the defaults.
425
426 Otherwise, C<L<use locale|perllocale>> sets the default modifier to C</l>;
427 and C<L<use feature 'unicode_strings|feature>>, or
428 C<L<use 5.012|perlfunc/use VERSION>> (or higher) set the default to
429 C</u> when not in the same scope as either C<L<use locale|perllocale>>
430 or C<L<use bytes|bytes>>.
431 (C<L<use locale ':not_characters'|perllocale/Unicode and UTF-8>> also
432 sets the default to C</u>, overriding any plain C<use locale>.)
433 Unlike the mechanisms mentioned above, these
434 affect operations besides regular expressions pattern matching, and so
435 give more consistent results with other operators, including using
436 C<\U>, C<\l>, etc. in substitution replacements.
437
438 If none of the above apply, for backwards compatibility reasons, the
439 C</d> modifier is the one in effect by default.  As this can lead to
440 unexpected results, it is best to specify which other rule set should be
441 used.
442
443 =head4 Character set modifier behavior prior to Perl 5.14
444
445 Prior to 5.14, there were no explicit modifiers, but C</l> was implied
446 for regexes compiled within the scope of C<use locale>, and C</d> was
447 implied otherwise.  However, interpolating a regex into a larger regex
448 would ignore the original compilation in favor of whatever was in effect
449 at the time of the second compilation.  There were a number of
450 inconsistencies (bugs) with the C</d> modifier, where Unicode rules
451 would be used when inappropriate, and vice versa.  C<\p{}> did not imply
452 Unicode rules, and neither did all occurrences of C<\N{}>, until 5.12.
453
454 =head2 Regular Expressions
455
456 =head3 Metacharacters
457
458 The patterns used in Perl pattern matching evolved from those supplied in
459 the Version 8 regex routines.  (The routines are derived
460 (distantly) from Henry Spencer's freely redistributable reimplementation
461 of the V8 routines.)  See L<Version 8 Regular Expressions> for
462 details.
463
464 In particular the following metacharacters have their standard I<egrep>-ish
465 meanings:
466 X<metacharacter>
467 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
468
469
470     \        Quote the next metacharacter
471     ^        Match the beginning of the line
472     .        Match any character (except newline)
473     $        Match the end of the line (or before newline at the end)
474     |        Alternation
475     ()       Grouping
476     []       Bracketed Character class
477
478 By default, the "^" character is guaranteed to match only the
479 beginning of the string, the "$" character only the end (or before the
480 newline at the end), and Perl does certain optimizations with the
481 assumption that the string contains only one line.  Embedded newlines
482 will not be matched by "^" or "$".  You may, however, wish to treat a
483 string as a multi-line buffer, such that the "^" will match after any
484 newline within the string (except if the newline is the last character in
485 the string), and "$" will match before any newline.  At the
486 cost of a little more overhead, you can do this by using the /m modifier
487 on the pattern match operator.  (Older programs did this by setting C<$*>,
488 but this option was removed in perl 5.10.)
489 X<^> X<$> X</m>
490
491 To simplify multi-line substitutions, the "." character never matches a
492 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
493 the string is a single line--even if it isn't.
494 X<.> X</s>
495
496 =head3 Quantifiers
497
498 The following standard quantifiers are recognized:
499 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
500
501     *           Match 0 or more times
502     +           Match 1 or more times
503     ?           Match 1 or 0 times
504     {n}         Match exactly n times
505     {n,}        Match at least n times
506     {n,m}       Match at least n but not more than m times
507
508 (If a curly bracket occurs in any other context and does not form part of
509 a backslashed sequence like C<\x{...}>, it is treated as a regular
510 character.  In particular, the lower quantifier bound is not optional,
511 and a typo in a quantifier silently causes it to be treated as the
512 literal characters.  For example,
513
514     /o{4,3}/
515
516 looks like a quantifier that matches 0 times, since 4 is greater than 3,
517 but it really means to match the sequence of six characters
518 S<C<"o { 4 , 3 }">>.  It is planned to eventually require literal uses
519 of curly brackets to be escaped, say by preceding them with a backslash
520 or enclosing them within square brackets, (C<"\{"> or C<"[{]">).  This
521 change will allow for future syntax extensions (like making the lower
522 bound of a quantifier optional), and better error checking.  In the
523 meantime, you should get in the habit of escaping all instances where
524 you mean a literal "{".)
525
526 The "*" quantifier is equivalent to C<{0,}>, the "+"
527 quantifier to C<{1,}>, and the "?" quantifier to C<{0,1}>.  n and m are limited
528 to non-negative integral values less than a preset limit defined when perl is built.
529 This is usually 32766 on the most common platforms.  The actual limit can
530 be seen in the error message generated by code such as this:
531
532     $_ **= $_ , / {$_} / for 2 .. 42;
533
534 By default, a quantified subpattern is "greedy", that is, it will match as
535 many times as possible (given a particular starting location) while still
536 allowing the rest of the pattern to match.  If you want it to match the
537 minimum number of times possible, follow the quantifier with a "?".  Note
538 that the meanings don't change, just the "greediness":
539 X<metacharacter> X<greedy> X<greediness>
540 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
541
542     *?        Match 0 or more times, not greedily
543     +?        Match 1 or more times, not greedily
544     ??        Match 0 or 1 time, not greedily
545     {n}?      Match exactly n times, not greedily (redundant)
546     {n,}?     Match at least n times, not greedily
547     {n,m}?    Match at least n but not more than m times, not greedily
548
549 By default, when a quantified subpattern does not allow the rest of the
550 overall pattern to match, Perl will backtrack. However, this behaviour is
551 sometimes undesirable. Thus Perl provides the "possessive" quantifier form
552 as well.
553
554  *+     Match 0 or more times and give nothing back
555  ++     Match 1 or more times and give nothing back
556  ?+     Match 0 or 1 time and give nothing back
557  {n}+   Match exactly n times and give nothing back (redundant)
558  {n,}+  Match at least n times and give nothing back
559  {n,m}+ Match at least n but not more than m times and give nothing back
560
561 For instance,
562
563    'aaaa' =~ /a++a/
564
565 will never match, as the C<a++> will gobble up all the C<a>'s in the
566 string and won't leave any for the remaining part of the pattern. This
567 feature can be extremely useful to give perl hints about where it
568 shouldn't backtrack. For instance, the typical "match a double-quoted
569 string" problem can be most efficiently performed when written as:
570
571    /"(?:[^"\\]++|\\.)*+"/
572
573 as we know that if the final quote does not match, backtracking will not
574 help. See the independent subexpression
575 L</C<< (?>pattern) >>> for more details;
576 possessive quantifiers are just syntactic sugar for that construct. For
577 instance the above example could also be written as follows:
578
579    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
580
581 =head3 Escape sequences
582
583 Because patterns are processed as double-quoted strings, the following
584 also work:
585
586  \t          tab                   (HT, TAB)
587  \n          newline               (LF, NL)
588  \r          return                (CR)
589  \f          form feed             (FF)
590  \a          alarm (bell)          (BEL)
591  \e          escape (think troff)  (ESC)
592  \cK         control char          (example: VT)
593  \x{}, \x00  character whose ordinal is the given hexadecimal number
594  \N{name}    named Unicode character or character sequence
595  \N{U+263D}  Unicode character     (example: FIRST QUARTER MOON)
596  \o{}, \000  character whose ordinal is the given octal number
597  \l          lowercase next char (think vi)
598  \u          uppercase next char (think vi)
599  \L          lowercase till \E (think vi)
600  \U          uppercase till \E (think vi)
601  \Q          quote (disable) pattern metacharacters till \E
602  \E          end either case modification or quoted section, think vi
603
604 Details are in L<perlop/Quote and Quote-like Operators>.
605
606 =head3 Character Classes and other Special Escapes
607
608 In addition, Perl defines the following:
609 X<\g> X<\k> X<\K> X<backreference>
610
611  Sequence   Note    Description
612   [...]     [1]  Match a character according to the rules of the
613                    bracketed character class defined by the "...".
614                    Example: [a-z] matches "a" or "b" or "c" ... or "z"
615   [[:...:]] [2]  Match a character according to the rules of the POSIX
616                    character class "..." within the outer bracketed
617                    character class.  Example: [[:upper:]] matches any
618                    uppercase character.
619   (?[...])  [8]  Extended bracketed character class
620   \w        [3]  Match a "word" character (alphanumeric plus "_", plus
621                    other connector punctuation chars plus Unicode
622                    marks)
623   \W        [3]  Match a non-"word" character
624   \s        [3]  Match a whitespace character
625   \S        [3]  Match a non-whitespace character
626   \d        [3]  Match a decimal digit character
627   \D        [3]  Match a non-digit character
628   \pP       [3]  Match P, named property.  Use \p{Prop} for longer names
629   \PP       [3]  Match non-P
630   \X        [4]  Match Unicode "eXtended grapheme cluster"
631   \C             Match a single C-language char (octet) even if that is
632                    part of a larger UTF-8 character.  Thus it breaks up
633                    characters into their UTF-8 bytes, so you may end up
634                    with malformed pieces of UTF-8.  Unsupported in
635                    lookbehind.
636   \1        [5]  Backreference to a specific capture group or buffer.
637                    '1' may actually be any positive integer.
638   \g1       [5]  Backreference to a specific or previous group,
639   \g{-1}    [5]  The number may be negative indicating a relative
640                    previous group and may optionally be wrapped in
641                    curly brackets for safer parsing.
642   \g{name}  [5]  Named backreference
643   \k<name>  [5]  Named backreference
644   \K        [6]  Keep the stuff left of the \K, don't include it in $&
645   \N        [7]  Any character but \n (experimental).  Not affected by
646                    /s modifier
647   \v        [3]  Vertical whitespace
648   \V        [3]  Not vertical whitespace
649   \h        [3]  Horizontal whitespace
650   \H        [3]  Not horizontal whitespace
651   \R        [4]  Linebreak
652
653 =over 4
654
655 =item [1]
656
657 See L<perlrecharclass/Bracketed Character Classes> for details.
658
659 =item [2]
660
661 See L<perlrecharclass/POSIX Character Classes> for details.
662
663 =item [3]
664
665 See L<perlrecharclass/Backslash sequences> for details.
666
667 =item [4]
668
669 See L<perlrebackslash/Misc> for details.
670
671 =item [5]
672
673 See L</Capture groups> below for details.
674
675 =item [6]
676
677 See L</Extended Patterns> below for details.
678
679 =item [7]
680
681 Note that C<\N> has two meanings.  When of the form C<\N{NAME}>, it matches the
682 character or character sequence whose name is C<NAME>; and similarly
683 when of the form C<\N{U+I<hex>}>, it matches the character whose Unicode
684 code point is I<hex>.  Otherwise it matches any character but C<\n>.
685
686 =item [8]
687
688 See L<perlrecharclass/Extended Bracketed Character Classes> for details.
689
690 =back
691
692 =head3 Assertions
693
694 Perl defines the following zero-width assertions:
695 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
696 X<regexp, zero-width assertion>
697 X<regular expression, zero-width assertion>
698 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
699
700     \b  Match a word boundary
701     \B  Match except at a word boundary
702     \A  Match only at beginning of string
703     \Z  Match only at end of string, or before newline at the end
704     \z  Match only at end of string
705     \G  Match only at pos() (e.g. at the end-of-match position
706         of prior m//g)
707
708 A word boundary (C<\b>) is a spot between two characters
709 that has a C<\w> on one side of it and a C<\W> on the other side
710 of it (in either order), counting the imaginary characters off the
711 beginning and end of the string as matching a C<\W>.  (Within
712 character classes C<\b> represents backspace rather than a word
713 boundary, just as it normally does in any double-quoted string.)
714 The C<\A> and C<\Z> are just like "^" and "$", except that they
715 won't match multiple times when the C</m> modifier is used, while
716 "^" and "$" will match at every internal line boundary.  To match
717 the actual end of the string and not ignore an optional trailing
718 newline, use C<\z>.
719 X<\b> X<\A> X<\Z> X<\z> X</m>
720
721 The C<\G> assertion can be used to chain global matches (using
722 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
723 It is also useful when writing C<lex>-like scanners, when you have
724 several patterns that you want to match against consequent substrings
725 of your string; see the previous reference.  The actual location
726 where C<\G> will match can also be influenced by using C<pos()> as
727 an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
728 matches (see L</"Repeated Patterns Matching a Zero-length Substring">)
729 is modified somewhat, in that contents to the left of C<\G> are
730 not counted when determining the length of the match. Thus the following
731 will not match forever:
732 X<\G>
733
734      my $string = 'ABC';
735      pos($string) = 1;
736      while ($string =~ /(.\G)/g) {
737          print $1;
738      }
739
740 It will print 'A' and then terminate, as it considers the match to
741 be zero-width, and thus will not match at the same position twice in a
742 row.
743
744 It is worth noting that C<\G> improperly used can result in an infinite
745 loop. Take care when using patterns that include C<\G> in an alternation.
746
747 =head3 Capture groups
748
749 The bracketing construct C<( ... )> creates capture groups (also referred to as
750 capture buffers). To refer to the current contents of a group later on, within
751 the same pattern, use C<\g1> (or C<\g{1}>) for the first, C<\g2> (or C<\g{2}>)
752 for the second, and so on.
753 This is called a I<backreference>.
754 X<regex, capture buffer> X<regexp, capture buffer>
755 X<regex, capture group> X<regexp, capture group>
756 X<regular expression, capture buffer> X<backreference>
757 X<regular expression, capture group> X<backreference>
758 X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
759 X<named capture buffer> X<regular expression, named capture buffer>
760 X<named capture group> X<regular expression, named capture group>
761 X<%+> X<$+{name}> X<< \k<name> >>
762 There is no limit to the number of captured substrings that you may use.
763 Groups are numbered with the leftmost open parenthesis being number 1, etc.  If
764 a group did not match, the associated backreference won't match either. (This
765 can happen if the group is optional, or in a different branch of an
766 alternation.)
767 You can omit the C<"g">, and write C<"\1">, etc, but there are some issues with
768 this form, described below.
769
770 You can also refer to capture groups relatively, by using a negative number, so
771 that C<\g-1> and C<\g{-1}> both refer to the immediately preceding capture
772 group, and C<\g-2> and C<\g{-2}> both refer to the group before it.  For
773 example:
774
775         /
776          (Y)            # group 1
777          (              # group 2
778             (X)         # group 3
779             \g{-1}      # backref to group 3
780             \g{-3}      # backref to group 1
781          )
782         /x
783
784 would match the same as C</(Y) ( (X) \g3 \g1 )/x>.  This allows you to
785 interpolate regexes into larger regexes and not have to worry about the
786 capture groups being renumbered.
787
788 You can dispense with numbers altogether and create named capture groups.
789 The notation is C<(?E<lt>I<name>E<gt>...)> to declare and C<\g{I<name>}> to
790 reference.  (To be compatible with .Net regular expressions, C<\g{I<name>}> may
791 also be written as C<\k{I<name>}>, C<\kE<lt>I<name>E<gt>> or C<\k'I<name>'>.)
792 I<name> must not begin with a number, nor contain hyphens.
793 When different groups within the same pattern have the same name, any reference
794 to that name assumes the leftmost defined group.  Named groups count in
795 absolute and relative numbering, and so can also be referred to by those
796 numbers.
797 (It's possible to do things with named capture groups that would otherwise
798 require C<(??{})>.)
799
800 Capture group contents are dynamically scoped and available to you outside the
801 pattern until the end of the enclosing block or until the next successful
802 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
803 You can refer to them by absolute number (using C<"$1"> instead of C<"\g1">,
804 etc); or by name via the C<%+> hash, using C<"$+{I<name>}">.
805
806 Braces are required in referring to named capture groups, but are optional for
807 absolute or relative numbered ones.  Braces are safer when creating a regex by
808 concatenating smaller strings.  For example if you have C<qr/$a$b/>, and C<$a>
809 contained C<"\g1">, and C<$b> contained C<"37">, you would get C</\g137/> which
810 is probably not what you intended.
811
812 The C<\g> and C<\k> notations were introduced in Perl 5.10.0.  Prior to that
813 there were no named nor relative numbered capture groups.  Absolute numbered
814 groups were referred to using C<\1>,
815 C<\2>, etc., and this notation is still
816 accepted (and likely always will be).  But it leads to some ambiguities if
817 there are more than 9 capture groups, as C<\10> could mean either the tenth
818 capture group, or the character whose ordinal in octal is 010 (a backspace in
819 ASCII).  Perl resolves this ambiguity by interpreting C<\10> as a backreference
820 only if at least 10 left parentheses have opened before it.  Likewise C<\11> is
821 a backreference only if at least 11 left parentheses have opened before it.
822 And so on.  C<\1> through C<\9> are always interpreted as backreferences.
823 There are several examples below that illustrate these perils.  You can avoid
824 the ambiguity by always using C<\g{}> or C<\g> if you mean capturing groups;
825 and for octal constants always using C<\o{}>, or for C<\077> and below, using 3
826 digits padded with leading zeros, since a leading zero implies an octal
827 constant.
828
829 The C<\I<digit>> notation also works in certain circumstances outside
830 the pattern.  See L</Warning on \1 Instead of $1> below for details.
831
832 Examples:
833
834     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
835
836     /(.)\g1/                        # find first doubled char
837          and print "'$1' is the first doubled character\n";
838
839     /(?<char>.)\k<char>/            # ... a different way
840          and print "'$+{char}' is the first doubled character\n";
841
842     /(?'char'.)\g1/                 # ... mix and match
843          and print "'$1' is the first doubled character\n";
844
845     if (/Time: (..):(..):(..)/) {   # parse out values
846         $hours = $1;
847         $minutes = $2;
848         $seconds = $3;
849     }
850
851     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\g10/   # \g10 is a backreference
852     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\10/    # \10 is octal
853     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\10/  # \10 is a backreference
854     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\010/ # \010 is octal
855
856     $a = '(.)\1';        # Creates problems when concatenated.
857     $b = '(.)\g{1}';     # Avoids the problems.
858     "aa" =~ /${a}/;      # True
859     "aa" =~ /${b}/;      # True
860     "aa0" =~ /${a}0/;    # False!
861     "aa0" =~ /${b}0/;    # True
862     "aa\x08" =~ /${a}0/;  # True!
863     "aa\x08" =~ /${b}0/;  # False
864
865 Several special variables also refer back to portions of the previous
866 match.  C<$+> returns whatever the last bracket match matched.
867 C<$&> returns the entire matched string.  (At one point C<$0> did
868 also, but now it returns the name of the program.)  C<$`> returns
869 everything before the matched string.  C<$'> returns everything
870 after the matched string. And C<$^N> contains whatever was matched by
871 the most-recently closed group (submatch). C<$^N> can be used in
872 extended patterns (see below), for example to assign a submatch to a
873 variable.
874 X<$+> X<$^N> X<$&> X<$`> X<$'>
875
876 These special variables, like the C<%+> hash and the numbered match variables
877 (C<$1>, C<$2>, C<$3>, etc.) are dynamically scoped
878 until the end of the enclosing block or until the next successful
879 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
880 X<$+> X<$^N> X<$&> X<$`> X<$'>
881 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
882
883 B<NOTE>: Failed matches in Perl do not reset the match variables,
884 which makes it easier to write code that tests for a series of more
885 specific cases and remembers the best match.
886
887 B<WARNING>: If your code is to run on Perl 5.16 or earlier,
888 beware that once Perl sees that you need one of C<$&>, C<$`>, or
889 C<$'> anywhere in the program, it has to provide them for every
890 pattern match.  This may substantially slow your program.  (In Perl 5.18 a
891 more efficient mechanism is used, eliminating any slowdown.)  Perl
892 uses the same mechanism to produce C<$1>, C<$2>, etc, so you also pay a
893 price for each pattern that contains capturing parentheses.  (To
894 avoid this cost while retaining the grouping behaviour, use the
895 extended regular expression C<(?: ... )> instead.)  But if you never
896 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
897 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
898 if you can, but if you can't (and some algorithms really appreciate
899 them), once you've used them once, use them at will, because you've
900 already paid the price. 
901 X<$&> X<$`> X<$'>
902
903 As a workaround for this problem, Perl 5.10.0 introduced C<${^PREMATCH}>,
904 C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
905 and C<$'>, B<except> that they are only guaranteed to be defined after a
906 successful match that was executed with the C</p> (preserve) modifier.
907 The use of these variables incurs no global performance penalty, unlike
908 their punctuation char equivalents, however at the trade-off that you
909 have to tell perl when you want to use them.  As of Perl 5.18, these three
910 variables are equivalent to C<$`>, C<$&> and C<$'>, and C</p> is ignored.
911 X</p> X<p modifier>
912
913 =head2 Quoting metacharacters
914
915 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
916 C<\w>, C<\n>.  Unlike some other regular expression languages, there
917 are no backslashed symbols that aren't alphanumeric.  So anything
918 that looks like \\, \(, \), \[, \], \{, or \} is always
919 interpreted as a literal character, not a metacharacter.  This was
920 once used in a common idiom to disable or quote the special meanings
921 of regular expression metacharacters in a string that you want to
922 use for a pattern. Simply quote all non-"word" characters:
923
924     $pattern =~ s/(\W)/\\$1/g;
925
926 (If C<use locale> is set, then this depends on the current locale.)
927 Today it is more common to use the quotemeta() function or the C<\Q>
928 metaquoting escape sequence to disable all metacharacters' special
929 meanings like this:
930
931     /$unquoted\Q$quoted\E$unquoted/
932
933 Beware that if you put literal backslashes (those not inside
934 interpolated variables) between C<\Q> and C<\E>, double-quotish
935 backslash interpolation may lead to confusing results.  If you
936 I<need> to use literal backslashes within C<\Q...\E>,
937 consult L<perlop/"Gory details of parsing quoted constructs">.
938
939 C<quotemeta()> and C<\Q> are fully described in L<perlfunc/quotemeta>.
940
941 =head2 Extended Patterns
942
943 Perl also defines a consistent extension syntax for features not
944 found in standard tools like B<awk> and
945 B<lex>.  The syntax for most of these is a
946 pair of parentheses with a question mark as the first thing within
947 the parentheses.  The character after the question mark indicates
948 the extension.
949
950 The stability of these extensions varies widely.  Some have been
951 part of the core language for many years.  Others are experimental
952 and may change without warning or be completely removed.  Check
953 the documentation on an individual feature to verify its current
954 status.
955
956 A question mark was chosen for this and for the minimal-matching
957 construct because 1) question marks are rare in older regular
958 expressions, and 2) whenever you see one, you should stop and
959 "question" exactly what is going on.  That's psychology....
960
961 =over 4
962
963 =item C<(?#text)>
964 X<(?#)>
965
966 A comment.  The text is ignored.  If the C</x> modifier enables
967 whitespace formatting, a simple C<#> will suffice.  Note that Perl closes
968 the comment as soon as it sees a C<)>, so there is no way to put a literal
969 C<)> in the comment.
970
971 =item C<(?adlupimsx-imsx)>
972
973 =item C<(?^alupimsx)>
974 X<(?)> X<(?^)>
975
976 One or more embedded pattern-match modifiers, to be turned on (or
977 turned off, if preceded by C<->) for the remainder of the pattern or
978 the remainder of the enclosing pattern group (if any).
979
980 This is particularly useful for dynamic patterns, such as those read in from a
981 configuration file, taken from an argument, or specified in a table
982 somewhere.  Consider the case where some patterns want to be
983 case-sensitive and some do not:  The case-insensitive ones merely need to
984 include C<(?i)> at the front of the pattern.  For example:
985
986     $pattern = "foobar";
987     if ( /$pattern/i ) { }
988
989     # more flexible:
990
991     $pattern = "(?i)foobar";
992     if ( /$pattern/ ) { }
993
994 These modifiers are restored at the end of the enclosing group. For example,
995
996     ( (?i) blah ) \s+ \g1
997
998 will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
999 repetition of the previous word, assuming the C</x> modifier, and no C</i>
1000 modifier outside this group.
1001
1002 These modifiers do not carry over into named subpatterns called in the
1003 enclosing group. In other words, a pattern such as C<((?i)(?&NAME))> does not
1004 change the case-sensitivity of the "NAME" pattern.
1005
1006 Any of these modifiers can be set to apply globally to all regular
1007 expressions compiled within the scope of a C<use re>.  See
1008 L<re/"'/flags' mode">.
1009
1010 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
1011 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Flags (except
1012 C<"d">) may follow the caret to override it.
1013 But a minus sign is not legal with it.
1014
1015 Note that the C<a>, C<d>, C<l>, C<p>, and C<u> modifiers are special in
1016 that they can only be enabled, not disabled, and the C<a>, C<d>, C<l>, and
1017 C<u> modifiers are mutually exclusive: specifying one de-specifies the
1018 others, and a maximum of one (or two C<a>'s) may appear in the
1019 construct.  Thus, for
1020 example, C<(?-p)> will warn when compiled under C<use warnings>;
1021 C<(?-d:...)> and C<(?dl:...)> are fatal errors.
1022
1023 Note also that the C<p> modifier is special in that its presence
1024 anywhere in a pattern has a global effect.
1025
1026 =item C<(?:pattern)>
1027 X<(?:)>
1028
1029 =item C<(?adluimsx-imsx:pattern)>
1030
1031 =item C<(?^aluimsx:pattern)>
1032 X<(?^:)>
1033
1034 This is for clustering, not capturing; it groups subexpressions like
1035 "()", but doesn't make backreferences as "()" does.  So
1036
1037     @fields = split(/\b(?:a|b|c)\b/)
1038
1039 is like
1040
1041     @fields = split(/\b(a|b|c)\b/)
1042
1043 but doesn't spit out extra fields.  It's also cheaper not to capture
1044 characters if you don't need to.
1045
1046 Any letters between C<?> and C<:> act as flags modifiers as with
1047 C<(?adluimsx-imsx)>.  For example,
1048
1049     /(?s-i:more.*than).*million/i
1050
1051 is equivalent to the more verbose
1052
1053     /(?:(?s-i)more.*than).*million/i
1054
1055 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
1056 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Any positive
1057 flags (except C<"d">) may follow the caret, so
1058
1059     (?^x:foo)
1060
1061 is equivalent to
1062
1063     (?x-ims:foo)
1064
1065 The caret tells Perl that this cluster doesn't inherit the flags of any
1066 surrounding pattern, but uses the system defaults (C<d-imsx>),
1067 modified by any flags specified.
1068
1069 The caret allows for simpler stringification of compiled regular
1070 expressions.  These look like
1071
1072     (?^:pattern)
1073
1074 with any non-default flags appearing between the caret and the colon.
1075 A test that looks at such stringification thus doesn't need to have the
1076 system default flags hard-coded in it, just the caret.  If new flags are
1077 added to Perl, the meaning of the caret's expansion will change to include
1078 the default for those flags, so the test will still work, unchanged.
1079
1080 Specifying a negative flag after the caret is an error, as the flag is
1081 redundant.
1082
1083 Mnemonic for C<(?^...)>:  A fresh beginning since the usual use of a caret is
1084 to match at the beginning.
1085
1086 =item C<(?|pattern)>
1087 X<(?|)> X<Branch reset>
1088
1089 This is the "branch reset" pattern, which has the special property
1090 that the capture groups are numbered from the same starting point
1091 in each alternation branch. It is available starting from perl 5.10.0.
1092
1093 Capture groups are numbered from left to right, but inside this
1094 construct the numbering is restarted for each branch.
1095
1096 The numbering within each branch will be as normal, and any groups
1097 following this construct will be numbered as though the construct
1098 contained only one branch, that being the one with the most capture
1099 groups in it.
1100
1101 This construct is useful when you want to capture one of a
1102 number of alternative matches.
1103
1104 Consider the following pattern.  The numbers underneath show in
1105 which group the captured content will be stored.
1106
1107
1108     # before  ---------------branch-reset----------- after        
1109     / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
1110     # 1            2         2  3        2     3     4  
1111
1112 Be careful when using the branch reset pattern in combination with 
1113 named captures. Named captures are implemented as being aliases to 
1114 numbered groups holding the captures, and that interferes with the
1115 implementation of the branch reset pattern. If you are using named
1116 captures in a branch reset pattern, it's best to use the same names,
1117 in the same order, in each of the alternations:
1118
1119    /(?|  (?<a> x ) (?<b> y )
1120       |  (?<a> z ) (?<b> w )) /x
1121
1122 Not doing so may lead to surprises:
1123
1124   "12" =~ /(?| (?<a> \d+ ) | (?<b> \D+))/x;
1125   say $+ {a};   # Prints '12'
1126   say $+ {b};   # *Also* prints '12'.
1127
1128 The problem here is that both the group named C<< a >> and the group
1129 named C<< b >> are aliases for the group belonging to C<< $1 >>.
1130
1131 =item Look-Around Assertions
1132 X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
1133
1134 Look-around assertions are zero-width patterns which match a specific
1135 pattern without including it in C<$&>. Positive assertions match when
1136 their subpattern matches, negative assertions match when their subpattern
1137 fails. Look-behind matches text up to the current match position,
1138 look-ahead matches text following the current match position.
1139
1140 =over 4
1141
1142 =item C<(?=pattern)>
1143 X<(?=)> X<look-ahead, positive> X<lookahead, positive>
1144
1145 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
1146 matches a word followed by a tab, without including the tab in C<$&>.
1147
1148 =item C<(?!pattern)>
1149 X<(?!)> X<look-ahead, negative> X<lookahead, negative>
1150
1151 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
1152 matches any occurrence of "foo" that isn't followed by "bar".  Note
1153 however that look-ahead and look-behind are NOT the same thing.  You cannot
1154 use this for look-behind.
1155
1156 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
1157 will not do what you want.  That's because the C<(?!foo)> is just saying that
1158 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
1159 match.  Use look-behind instead (see below).
1160
1161 =item C<(?<=pattern)> C<\K>
1162 X<(?<=)> X<look-behind, positive> X<lookbehind, positive> X<\K>
1163
1164 A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
1165 matches a word that follows a tab, without including the tab in C<$&>.
1166 Works only for fixed-width look-behind.
1167
1168 There is a special form of this construct, called C<\K>, which causes the
1169 regex engine to "keep" everything it had matched prior to the C<\K> and
1170 not include it in C<$&>. This effectively provides variable-length
1171 look-behind. The use of C<\K> inside of another look-around assertion
1172 is allowed, but the behaviour is currently not well defined.
1173
1174 For various reasons C<\K> may be significantly more efficient than the
1175 equivalent C<< (?<=...) >> construct, and it is especially useful in
1176 situations where you want to efficiently remove something following
1177 something else in a string. For instance
1178
1179   s/(foo)bar/$1/g;
1180
1181 can be rewritten as the much more efficient
1182
1183   s/foo\Kbar//g;
1184
1185 =item C<(?<!pattern)>
1186 X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
1187
1188 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
1189 matches any occurrence of "foo" that does not follow "bar".  Works
1190 only for fixed-width look-behind.
1191
1192 =back
1193
1194 =item C<(?'NAME'pattern)>
1195
1196 =item C<< (?<NAME>pattern) >>
1197 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
1198
1199 A named capture group. Identical in every respect to normal capturing
1200 parentheses C<()> but for the additional fact that the group
1201 can be referred to by name in various regular expression
1202 constructs (like C<\g{NAME}>) and can be accessed by name
1203 after a successful match via C<%+> or C<%->. See L<perlvar>
1204 for more details on the C<%+> and C<%-> hashes.
1205
1206 If multiple distinct capture groups have the same name then the
1207 $+{NAME} will refer to the leftmost defined group in the match.
1208
1209 The forms C<(?'NAME'pattern)> and C<< (?<NAME>pattern) >> are equivalent.
1210
1211 B<NOTE:> While the notation of this construct is the same as the similar
1212 function in .NET regexes, the behavior is not. In Perl the groups are
1213 numbered sequentially regardless of being named or not. Thus in the
1214 pattern
1215
1216   /(x)(?<foo>y)(z)/
1217
1218 $+{foo} will be the same as $2, and $3 will contain 'z' instead of
1219 the opposite which is what a .NET regex hacker might expect.
1220
1221 Currently NAME is restricted to simple identifiers only.
1222 In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
1223 its Unicode extension (see L<utf8>),
1224 though it isn't extended by the locale (see L<perllocale>).
1225
1226 B<NOTE:> In order to make things easier for programmers with experience
1227 with the Python or PCRE regex engines, the pattern C<< (?PE<lt>NAMEE<gt>pattern) >>
1228 may be used instead of C<< (?<NAME>pattern) >>; however this form does not
1229 support the use of single quotes as a delimiter for the name.
1230
1231 =item C<< \k<NAME> >>
1232
1233 =item C<< \k'NAME' >>
1234
1235 Named backreference. Similar to numeric backreferences, except that
1236 the group is designated by name and not number. If multiple groups
1237 have the same name then it refers to the leftmost defined group in
1238 the current match.
1239
1240 It is an error to refer to a name not defined by a C<< (?<NAME>) >>
1241 earlier in the pattern.
1242
1243 Both forms are equivalent.
1244
1245 B<NOTE:> In order to make things easier for programmers with experience
1246 with the Python or PCRE regex engines, the pattern C<< (?P=NAME) >>
1247 may be used instead of C<< \k<NAME> >>.
1248
1249 =item C<(?{ code })>
1250 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
1251
1252 B<WARNING>: This extended regular expression feature is considered
1253 experimental, and may be changed without notice. Code executed that
1254 has side effects may not perform identically from version to version
1255 due to the effect of future optimisations in the regex engine. The
1256 implementation of this feature was radically overhauled for the 5.18.0
1257 release, and its behaviour in earlier versions of perl was much buggier,
1258 especially in relation to parsing, lexical vars, scoping, recursion and
1259 reentrancy.
1260
1261 This zero-width assertion executes any embedded Perl code.  It always
1262 succeeds, and its return value is set as C<$^R>.
1263
1264 In literal patterns, the code is parsed at the same time as the
1265 surrounding code. While within the pattern, control is passed temporarily
1266 back to the perl parser, until the logically-balancing closing brace is
1267 encountered. This is similar to the way that an array index expression in
1268 a literal string is handled, for example
1269
1270     "abc$array[ 1 + f('[') + g()]def"
1271
1272 In particular, braces do not need to be balanced:
1273
1274     s/abc(?{ f('{'); })/def/
1275
1276 Even in a pattern that is interpolated and compiled at run-time, literal
1277 code blocks will be compiled once, at perl compile time; the following
1278 prints "ABCD":
1279
1280     print "D";
1281     my $qr = qr/(?{ BEGIN { print "A" } })/;
1282     my $foo = "foo";
1283     /$foo$qr(?{ BEGIN { print "B" } })/;
1284     BEGIN { print "C" }
1285
1286 In patterns where the text of the code is derived from run-time
1287 information rather than appearing literally in a source code /pattern/,
1288 the code is compiled at the same time that the pattern is compiled, and
1289 for reasons of security, C<use re 'eval'> must be in scope. This is to
1290 stop user-supplied patterns containing code snippets from being
1291 executable.
1292
1293 In situations where you need to enable this with C<use re 'eval'>, you should
1294 also have taint checking enabled.  Better yet, use the carefully
1295 constrained evaluation within a Safe compartment.  See L<perlsec> for
1296 details about both these mechanisms.
1297
1298 From the viewpoint of parsing, lexical variable scope and closures,
1299
1300     /AAA(?{ BBB })CCC/
1301
1302 behaves approximately like
1303
1304     /AAA/ && do { BBB } && /CCC/
1305
1306 Similarly,
1307
1308     qr/AAA(?{ BBB })CCC/
1309
1310 behaves approximately like
1311
1312     sub { /AAA/ && do { BBB } && /CCC/ }
1313
1314 In particular:
1315
1316     { my $i = 1; $r = qr/(?{ print $i })/ }
1317     my $i = 2;
1318     /$r/; # prints "1"
1319
1320 Inside a C<(?{...})> block, C<$_> refers to the string the regular
1321 expression is matching against. You can also use C<pos()> to know what is
1322 the current position of matching within this string.
1323
1324 The code block introduces a new scope from the perspective of lexical
1325 variable declarations, but B<not> from the perspective of C<local> and
1326 similar localizing behaviours. So later code blocks within the same
1327 pattern will still see the values which were localized in earlier blocks.
1328 These accumulated localizations are undone either at the end of a
1329 successful match, or if the assertion is backtracked (compare
1330 L<"Backtracking">). For example,
1331
1332   $_ = 'a' x 8;
1333   m<
1334      (?{ $cnt = 0 })               # Initialize $cnt.
1335      (
1336        a
1337        (?{
1338            local $cnt = $cnt + 1;  # Update $cnt,
1339                                    # backtracking-safe.
1340        })
1341      )*
1342      aaaa
1343      (?{ $res = $cnt })            # On success copy to
1344                                    # non-localized location.
1345    >x;
1346
1347 will initially increment C<$cnt> up to 8; then during backtracking, its
1348 value will be unwound back to 4, which is the value assigned to C<$res>.
1349 At the end of the regex execution, $cnt will be wound back to its initial
1350 value of 0.
1351
1352 This assertion may be used as the condition in a
1353
1354     (?(condition)yes-pattern|no-pattern)
1355
1356 switch.  If I<not> used in this way, the result of evaluation of C<code>
1357 is put into the special variable C<$^R>.  This happens immediately, so
1358 C<$^R> can be used from other C<(?{ code })> assertions inside the same
1359 regular expression.
1360
1361 The assignment to C<$^R> above is properly localized, so the old
1362 value of C<$^R> is restored if the assertion is backtracked; compare
1363 L<"Backtracking">.
1364
1365 Note that the special variable C<$^N>  is particularly useful with code
1366 blocks to capture the results of submatches in variables without having to
1367 keep track of the number of nested parentheses. For example:
1368
1369   $_ = "The brown fox jumps over the lazy dog";
1370   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
1371   print "color = $color, animal = $animal\n";
1372
1373
1374 =item C<(??{ code })>
1375 X<(??{})>
1376 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
1377
1378 B<WARNING>: This extended regular expression feature is considered
1379 experimental, and may be changed without notice. Code executed that
1380 has side effects may not perform identically from version to version
1381 due to the effect of future optimisations in the regex engine.
1382
1383 This is a "postponed" regular subexpression.  It behaves in I<exactly> the
1384 same way as a C<(?{ code })> code block as described above, except that
1385 its return value, rather than being assigned to C<$^R>, is treated as a
1386 pattern, compiled if it's a string (or used as-is if its a qr// object),
1387 then matched as if it were inserted instead of this construct.
1388
1389 During the matching of this sub-pattern, it has its own set of
1390 captures which are valid during the sub-match, but are discarded once
1391 control returns to the main pattern. For example, the following matches,
1392 with the inner pattern capturing "B" and matching "BB", while the outer
1393 pattern captures "A";
1394
1395     my $inner = '(.)\1';
1396     "ABBA" =~ /^(.)(??{ $inner })\1/;
1397     print $1; # prints "A";
1398
1399 Note that this means that  there is no way for the inner pattern to refer
1400 to a capture group defined outside.  (The code block itself can use C<$1>,
1401 etc., to refer to the enclosing pattern's capture groups.)  Thus, although
1402
1403     ('a' x 100)=~/(??{'(.)' x 100})/
1404
1405 I<will> match, it will I<not> set $1 on exit.
1406
1407 The following pattern matches a parenthesized group:
1408
1409  $re = qr{
1410             \(
1411             (?:
1412                (?> [^()]+ )  # Non-parens without backtracking
1413              |
1414                (??{ $re })   # Group with matching parens
1415             )*
1416             \)
1417          }x;
1418
1419 See also C<(?PARNO)> for a different, more efficient way to accomplish
1420 the same task.
1421
1422 Executing a postponed regular expression 50 times without consuming any
1423 input string will result in a fatal error.  The maximum depth is compiled
1424 into perl, so changing it requires a custom build.
1425
1426 =item C<(?PARNO)> C<(?-PARNO)> C<(?+PARNO)> C<(?R)> C<(?0)>
1427 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
1428 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
1429 X<regex, relative recursion>
1430
1431 Similar to C<(??{ code })> except that it does not involve executing any
1432 code or potentially compiling a returned pattern string; instead it treats
1433 the part of the current pattern contained within a specified capture group
1434 as an independent pattern that must match at the current position.
1435 Capture groups contained by the pattern will have the value as determined
1436 by the outermost recursion.
1437
1438 PARNO is a sequence of digits (not starting with 0) whose value reflects
1439 the paren-number of the capture group to recurse to. C<(?R)> recurses to
1440 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
1441 C<(?R)>. If PARNO is preceded by a plus or minus sign then it is assumed
1442 to be relative, with negative numbers indicating preceding capture groups
1443 and positive ones following. Thus C<(?-1)> refers to the most recently
1444 declared group, and C<(?+1)> indicates the next group to be declared.
1445 Note that the counting for relative recursion differs from that of
1446 relative backreferences, in that with recursion unclosed groups B<are>
1447 included.
1448
1449 The following pattern matches a function foo() which may contain
1450 balanced parentheses as the argument.
1451
1452   $re = qr{ (                   # paren group 1 (full function)
1453               foo
1454               (                 # paren group 2 (parens)
1455                 \(
1456                   (             # paren group 3 (contents of parens)
1457                   (?:
1458                    (?> [^()]+ ) # Non-parens without backtracking
1459                   |
1460                    (?2)         # Recurse to start of paren group 2
1461                   )*
1462                   )
1463                 \)
1464               )
1465             )
1466           }x;
1467
1468 If the pattern was used as follows
1469
1470     'foo(bar(baz)+baz(bop))'=~/$re/
1471         and print "\$1 = $1\n",
1472                   "\$2 = $2\n",
1473                   "\$3 = $3\n";
1474
1475 the output produced should be the following:
1476
1477     $1 = foo(bar(baz)+baz(bop))
1478     $2 = (bar(baz)+baz(bop))
1479     $3 = bar(baz)+baz(bop)
1480
1481 If there is no corresponding capture group defined, then it is a
1482 fatal error.  Recursing deeper than 50 times without consuming any input
1483 string will also result in a fatal error.  The maximum depth is compiled
1484 into perl, so changing it requires a custom build.
1485
1486 The following shows how using negative indexing can make it
1487 easier to embed recursive patterns inside of a C<qr//> construct
1488 for later use:
1489
1490     my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1491     if (/foo $parens \s+ \+ \s+ bar $parens/x) {
1492        # do something here...
1493     }
1494
1495 B<Note> that this pattern does not behave the same way as the equivalent
1496 PCRE or Python construct of the same form. In Perl you can backtrack into
1497 a recursed group, in PCRE and Python the recursed into group is treated
1498 as atomic. Also, modifiers are resolved at compile time, so constructs
1499 like (?i:(?1)) or (?:(?i)(?1)) do not affect how the sub-pattern will
1500 be processed.
1501
1502 =item C<(?&NAME)>
1503 X<(?&NAME)>
1504
1505 Recurse to a named subpattern. Identical to C<(?PARNO)> except that the
1506 parenthesis to recurse to is determined by name. If multiple parentheses have
1507 the same name, then it recurses to the leftmost.
1508
1509 It is an error to refer to a name that is not declared somewhere in the
1510 pattern.
1511
1512 B<NOTE:> In order to make things easier for programmers with experience
1513 with the Python or PCRE regex engines the pattern C<< (?P>NAME) >>
1514 may be used instead of C<< (?&NAME) >>.
1515
1516 =item C<(?(condition)yes-pattern|no-pattern)>
1517 X<(?()>
1518
1519 =item C<(?(condition)yes-pattern)>
1520
1521 Conditional expression. Matches C<yes-pattern> if C<condition> yields
1522 a true value, matches C<no-pattern> otherwise. A missing pattern always
1523 matches.
1524
1525 C<(condition)> should be one of: 1) an integer in
1526 parentheses (which is valid if the corresponding pair of parentheses
1527 matched); 2) a look-ahead/look-behind/evaluate zero-width assertion; 3) a
1528 name in angle brackets or single quotes (which is valid if a group
1529 with the given name matched); or 4) the special symbol (R) (true when
1530 evaluated inside of recursion or eval). Additionally the R may be
1531 followed by a number, (which will be true when evaluated when recursing
1532 inside of the appropriate group), or by C<&NAME>, in which case it will
1533 be true only when evaluated during recursion in the named group.
1534
1535 Here's a summary of the possible predicates:
1536
1537 =over 4
1538
1539 =item (1) (2) ...
1540
1541 Checks if the numbered capturing group has matched something.
1542
1543 =item (<NAME>) ('NAME')
1544
1545 Checks if a group with the given name has matched something.
1546
1547 =item (?=...) (?!...) (?<=...) (?<!...)
1548
1549 Checks whether the pattern matches (or does not match, for the '!'
1550 variants).
1551
1552 =item (?{ CODE })
1553
1554 Treats the return value of the code block as the condition.
1555
1556 =item (R)
1557
1558 Checks if the expression has been evaluated inside of recursion.
1559
1560 =item (R1) (R2) ...
1561
1562 Checks if the expression has been evaluated while executing directly
1563 inside of the n-th capture group. This check is the regex equivalent of
1564
1565   if ((caller(0))[3] eq 'subname') { ... }
1566
1567 In other words, it does not check the full recursion stack.
1568
1569 =item (R&NAME)
1570
1571 Similar to C<(R1)>, this predicate checks to see if we're executing
1572 directly inside of the leftmost group with a given name (this is the same
1573 logic used by C<(?&NAME)> to disambiguate). It does not check the full
1574 stack, but only the name of the innermost active recursion.
1575
1576 =item (DEFINE)
1577
1578 In this case, the yes-pattern is never directly executed, and no
1579 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
1580 See below for details.
1581
1582 =back
1583
1584 For example:
1585
1586     m{ ( \( )?
1587        [^()]+
1588        (?(1) \) )
1589      }x
1590
1591 matches a chunk of non-parentheses, possibly included in parentheses
1592 themselves.
1593
1594 A special form is the C<(DEFINE)> predicate, which never executes its
1595 yes-pattern directly, and does not allow a no-pattern. This allows one to
1596 define subpatterns which will be executed only by the recursion mechanism.
1597 This way, you can define a set of regular expression rules that can be
1598 bundled into any pattern you choose.
1599
1600 It is recommended that for this usage you put the DEFINE block at the
1601 end of the pattern, and that you name any subpatterns defined within it.
1602
1603 Also, it's worth noting that patterns defined this way probably will
1604 not be as efficient, as the optimiser is not very clever about
1605 handling them.
1606
1607 An example of how this might be used is as follows:
1608
1609   /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
1610    (?(DEFINE)
1611      (?<NAME_PAT>....)
1612      (?<ADRESS_PAT>....)
1613    )/x
1614
1615 Note that capture groups matched inside of recursion are not accessible
1616 after the recursion returns, so the extra layer of capturing groups is
1617 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
1618 C<$+{NAME}> would be.
1619
1620 Finally, keep in mind that subpatterns created inside a DEFINE block
1621 count towards the absolute and relative number of captures, so this:
1622
1623     my @captures = "a" =~ /(.)                  # First capture
1624                            (?(DEFINE)
1625                                (?<EXAMPLE> 1 )  # Second capture
1626                            )/x;
1627     say scalar @captures;
1628
1629 Will output 2, not 1. This is particularly important if you intend to
1630 compile the definitions with the C<qr//> operator, and later
1631 interpolate them in another pattern.
1632
1633 =item C<< (?>pattern) >>
1634 X<backtrack> X<backtracking> X<atomic> X<possessive>
1635
1636 An "independent" subexpression, one which matches the substring
1637 that a I<standalone> C<pattern> would match if anchored at the given
1638 position, and it matches I<nothing other than this substring>.  This
1639 construct is useful for optimizations of what would otherwise be
1640 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
1641 It may also be useful in places where the "grab all you can, and do not
1642 give anything back" semantic is desirable.
1643
1644 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
1645 (anchored at the beginning of string, as above) will match I<all>
1646 characters C<a> at the beginning of string, leaving no C<a> for
1647 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
1648 since the match of the subgroup C<a*> is influenced by the following
1649 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
1650 C<a*ab> will match fewer characters than a standalone C<a*>, since
1651 this makes the tail match.
1652
1653 C<< (?>pattern) >> does not disable backtracking altogether once it has
1654 matched. It is still possible to backtrack past the construct, but not
1655 into it. So C<< ((?>a*)|(?>b*))ar >> will still match "bar".
1656
1657 An effect similar to C<< (?>pattern) >> may be achieved by writing
1658 C<(?=(pattern))\g{-1}>.  This matches the same substring as a standalone
1659 C<a+>, and the following C<\g{-1}> eats the matched string; it therefore
1660 makes a zero-length assertion into an analogue of C<< (?>...) >>.
1661 (The difference between these two constructs is that the second one
1662 uses a capturing group, thus shifting ordinals of backreferences
1663 in the rest of a regular expression.)
1664
1665 Consider this pattern:
1666
1667     m{ \(
1668           (
1669             [^()]+           # x+
1670           |
1671             \( [^()]* \)
1672           )+
1673        \)
1674      }x
1675
1676 That will efficiently match a nonempty group with matching parentheses
1677 two levels deep or less.  However, if there is no such group, it
1678 will take virtually forever on a long string.  That's because there
1679 are so many different ways to split a long string into several
1680 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
1681 to a subpattern of the above pattern.  Consider how the pattern
1682 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
1683 seconds, but that each extra letter doubles this time.  This
1684 exponential performance will make it appear that your program has
1685 hung.  However, a tiny change to this pattern
1686
1687     m{ \(
1688           (
1689             (?> [^()]+ )        # change x+ above to (?> x+ )
1690           |
1691             \( [^()]* \)
1692           )+
1693        \)
1694      }x
1695
1696 which uses C<< (?>...) >> matches exactly when the one above does (verifying
1697 this yourself would be a productive exercise), but finishes in a fourth
1698 the time when used on a similar string with 1000000 C<a>s.  Be aware,
1699 however, that, when this construct is followed by a
1700 quantifier, it currently triggers a warning message under
1701 the C<use warnings> pragma or B<-w> switch saying it
1702 C<"matches null string many times in regex">.
1703
1704 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
1705 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
1706 This was only 4 times slower on a string with 1000000 C<a>s.
1707
1708 The "grab all you can, and do not give anything back" semantic is desirable
1709 in many situations where on the first sight a simple C<()*> looks like
1710 the correct solution.  Suppose we parse text with comments being delimited
1711 by C<#> followed by some optional (horizontal) whitespace.  Contrary to
1712 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
1713 the comment delimiter, because it may "give up" some whitespace if
1714 the remainder of the pattern can be made to match that way.  The correct
1715 answer is either one of these:
1716
1717     (?>#[ \t]*)
1718     #[ \t]*(?![ \t])
1719
1720 For example, to grab non-empty comments into $1, one should use either
1721 one of these:
1722
1723     / (?> \# [ \t]* ) (        .+ ) /x;
1724     /     \# [ \t]*   ( [^ \t] .* ) /x;
1725
1726 Which one you pick depends on which of these expressions better reflects
1727 the above specification of comments.
1728
1729 In some literature this construct is called "atomic matching" or
1730 "possessive matching".
1731
1732 Possessive quantifiers are equivalent to putting the item they are applied
1733 to inside of one of these constructs. The following equivalences apply:
1734
1735     Quantifier Form     Bracketing Form
1736     ---------------     ---------------
1737     PAT*+               (?>PAT*)
1738     PAT++               (?>PAT+)
1739     PAT?+               (?>PAT?)
1740     PAT{min,max}+       (?>PAT{min,max})
1741
1742 =item C<(?[ ])>
1743
1744 See L<perlrecharclass/Extended Bracketed Character Classes>.
1745
1746 =back
1747
1748 =head2 Special Backtracking Control Verbs
1749
1750 B<WARNING:> These patterns are experimental and subject to change or
1751 removal in a future version of Perl. Their usage in production code should
1752 be noted to avoid problems during upgrades.
1753
1754 These special patterns are generally of the form C<(*VERB:ARG)>. Unless
1755 otherwise stated the ARG argument is optional; in some cases, it is
1756 forbidden.
1757
1758 Any pattern containing a special backtracking verb that allows an argument
1759 has the special behaviour that when executed it sets the current package's
1760 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
1761 rules apply:
1762
1763 On failure, the C<$REGERROR> variable will be set to the ARG value of the
1764 verb pattern, if the verb was involved in the failure of the match. If the
1765 ARG part of the pattern was omitted, then C<$REGERROR> will be set to the
1766 name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
1767 none. Also, the C<$REGMARK> variable will be set to FALSE.
1768
1769 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
1770 the C<$REGMARK> variable will be set to the name of the last
1771 C<(*MARK:NAME)> pattern executed.  See the explanation for the
1772 C<(*MARK:NAME)> verb below for more details.
1773
1774 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
1775 and most other regex-related variables. They are not local to a scope, nor
1776 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
1777 Use C<local> to localize changes to them to a specific scope if necessary.
1778
1779 If a pattern does not contain a special backtracking verb that allows an
1780 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
1781
1782 =over 3
1783
1784 =item Verbs that take an argument
1785
1786 =over 4
1787
1788 =item C<(*PRUNE)> C<(*PRUNE:NAME)>
1789 X<(*PRUNE)> X<(*PRUNE:NAME)>
1790
1791 This zero-width pattern prunes the backtracking tree at the current point
1792 when backtracked into on failure. Consider the pattern C<A (*PRUNE) B>,
1793 where A and B are complex patterns. Until the C<(*PRUNE)> verb is reached,
1794 A may backtrack as necessary to match. Once it is reached, matching
1795 continues in B, which may also backtrack as necessary; however, should B
1796 not match, then no further backtracking will take place, and the pattern
1797 will fail outright at the current starting position.
1798
1799 The following example counts all the possible matching strings in a
1800 pattern (without actually matching any of them).
1801
1802     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
1803     print "Count=$count\n";
1804
1805 which produces:
1806
1807     aaab
1808     aaa
1809     aa
1810     a
1811     aab
1812     aa
1813     a
1814     ab
1815     a
1816     Count=9
1817
1818 If we add a C<(*PRUNE)> before the count like the following
1819
1820     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
1821     print "Count=$count\n";
1822
1823 we prevent backtracking and find the count of the longest matching string
1824 at each matching starting point like so:
1825
1826     aaab
1827     aab
1828     ab
1829     Count=3
1830
1831 Any number of C<(*PRUNE)> assertions may be used in a pattern.
1832
1833 See also C<< (?>pattern) >> and possessive quantifiers for other ways to
1834 control backtracking. In some cases, the use of C<(*PRUNE)> can be
1835 replaced with a C<< (?>pattern) >> with no functional difference; however,
1836 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
1837 C<< (?>pattern) >> alone.
1838
1839 =item C<(*SKIP)> C<(*SKIP:NAME)>
1840 X<(*SKIP)>
1841
1842 This zero-width pattern is similar to C<(*PRUNE)>, except that on
1843 failure it also signifies that whatever text that was matched leading up
1844 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
1845 of this pattern. This effectively means that the regex engine "skips" forward
1846 to this position on failure and tries to match again, (assuming that
1847 there is sufficient room to match).
1848
1849 The name of the C<(*SKIP:NAME)> pattern has special significance. If a
1850 C<(*MARK:NAME)> was encountered while matching, then it is that position
1851 which is used as the "skip point". If no C<(*MARK)> of that name was
1852 encountered, then the C<(*SKIP)> operator has no effect. When used
1853 without a name the "skip point" is where the match point was when
1854 executing the (*SKIP) pattern.
1855
1856 Compare the following to the examples in C<(*PRUNE)>; note the string
1857 is twice as long:
1858
1859  'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
1860  print "Count=$count\n";
1861
1862 outputs
1863
1864     aaab
1865     aaab
1866     Count=2
1867
1868 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
1869 executed, the next starting point will be where the cursor was when the
1870 C<(*SKIP)> was executed.
1871
1872 =item C<(*MARK:NAME)> C<(*:NAME)>
1873 X<(*MARK)> X<(*MARK:NAME)> X<(*:NAME)>
1874
1875 This zero-width pattern can be used to mark the point reached in a string
1876 when a certain part of the pattern has been successfully matched. This
1877 mark may be given a name. A later C<(*SKIP)> pattern will then skip
1878 forward to that point if backtracked into on failure. Any number of
1879 C<(*MARK)> patterns are allowed, and the NAME portion may be duplicated.
1880
1881 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
1882 can be used to "label" a pattern branch, so that after matching, the
1883 program can determine which branches of the pattern were involved in the
1884 match.
1885
1886 When a match is successful, the C<$REGMARK> variable will be set to the
1887 name of the most recently executed C<(*MARK:NAME)> that was involved
1888 in the match.
1889
1890 This can be used to determine which branch of a pattern was matched
1891 without using a separate capture group for each branch, which in turn
1892 can result in a performance improvement, as perl cannot optimize
1893 C</(?:(x)|(y)|(z))/> as efficiently as something like
1894 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
1895
1896 When a match has failed, and unless another verb has been involved in
1897 failing the match and has provided its own name to use, the C<$REGERROR>
1898 variable will be set to the name of the most recently executed
1899 C<(*MARK:NAME)>.
1900
1901 See L</(*SKIP)> for more details.
1902
1903 As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
1904
1905 =item C<(*THEN)> C<(*THEN:NAME)>
1906
1907 This is similar to the "cut group" operator C<::> from Perl 6.  Like
1908 C<(*PRUNE)>, this verb always matches, and when backtracked into on
1909 failure, it causes the regex engine to try the next alternation in the
1910 innermost enclosing group (capturing or otherwise) that has alternations.
1911 The two branches of a C<(?(condition)yes-pattern|no-pattern)> do not
1912 count as an alternation, as far as C<(*THEN)> is concerned.
1913
1914 Its name comes from the observation that this operation combined with the
1915 alternation operator (C<|>) can be used to create what is essentially a
1916 pattern-based if/then/else block:
1917
1918   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
1919
1920 Note that if this operator is used and NOT inside of an alternation then
1921 it acts exactly like the C<(*PRUNE)> operator.
1922
1923   / A (*PRUNE) B /
1924
1925 is the same as
1926
1927   / A (*THEN) B /
1928
1929 but
1930
1931   / ( A (*THEN) B | C ) /
1932
1933 is not the same as
1934
1935   / ( A (*PRUNE) B | C ) /
1936
1937 as after matching the A but failing on the B the C<(*THEN)> verb will
1938 backtrack and try C; but the C<(*PRUNE)> verb will simply fail.
1939
1940 =back
1941
1942 =item Verbs without an argument
1943
1944 =over 4
1945
1946 =item C<(*COMMIT)>
1947 X<(*COMMIT)>
1948
1949 This is the Perl 6 "commit pattern" C<< <commit> >> or C<:::>. It's a
1950 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
1951 into on failure it causes the match to fail outright. No further attempts
1952 to find a valid match by advancing the start pointer will occur again.
1953 For example,
1954
1955  'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
1956  print "Count=$count\n";
1957
1958 outputs
1959
1960     aaab
1961     Count=1
1962
1963 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
1964 does not match, the regex engine will not try any further matching on the
1965 rest of the string.
1966
1967 =item C<(*FAIL)> C<(*F)>
1968 X<(*FAIL)> X<(*F)>
1969
1970 This pattern matches nothing and always fails. It can be used to force the
1971 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
1972 fact, C<(?!)> gets optimised into C<(*FAIL)> internally.
1973
1974 It is probably useful only when combined with C<(?{})> or C<(??{})>.
1975
1976 =item C<(*ACCEPT)>
1977 X<(*ACCEPT)>
1978
1979 B<WARNING:> This feature is highly experimental. It is not recommended
1980 for production code.
1981
1982 This pattern matches nothing and causes the end of successful matching at
1983 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
1984 whether there is actually more to match in the string. When inside of a
1985 nested pattern, such as recursion, or in a subpattern dynamically generated
1986 via C<(??{})>, only the innermost pattern is ended immediately.
1987
1988 If the C<(*ACCEPT)> is inside of capturing groups then the groups are
1989 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
1990 For instance:
1991
1992   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
1993
1994 will match, and C<$1> will be C<AB> and C<$2> will be C<B>, C<$3> will not
1995 be set. If another branch in the inner parentheses was matched, such as in the
1996 string 'ACDE', then the C<D> and C<E> would have to be matched as well.
1997
1998 =back
1999
2000 =back
2001
2002 =head2 Backtracking
2003 X<backtrack> X<backtracking>
2004
2005 NOTE: This section presents an abstract approximation of regular
2006 expression behavior.  For a more rigorous (and complicated) view of
2007 the rules involved in selecting a match among possible alternatives,
2008 see L<Combining RE Pieces>.
2009
2010 A fundamental feature of regular expression matching involves the
2011 notion called I<backtracking>, which is currently used (when needed)
2012 by all regular non-possessive expression quantifiers, namely C<*>, C<*?>, C<+>,
2013 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
2014 internally, but the general principle outlined here is valid.
2015
2016 For a regular expression to match, the I<entire> regular expression must
2017 match, not just part of it.  So if the beginning of a pattern containing a
2018 quantifier succeeds in a way that causes later parts in the pattern to
2019 fail, the matching engine backs up and recalculates the beginning
2020 part--that's why it's called backtracking.
2021
2022 Here is an example of backtracking:  Let's say you want to find the
2023 word following "foo" in the string "Food is on the foo table.":
2024
2025     $_ = "Food is on the foo table.";
2026     if ( /\b(foo)\s+(\w+)/i ) {
2027         print "$2 follows $1.\n";
2028     }
2029
2030 When the match runs, the first part of the regular expression (C<\b(foo)>)
2031 finds a possible match right at the beginning of the string, and loads up
2032 $1 with "Foo".  However, as soon as the matching engine sees that there's
2033 no whitespace following the "Foo" that it had saved in $1, it realizes its
2034 mistake and starts over again one character after where it had the
2035 tentative match.  This time it goes all the way until the next occurrence
2036 of "foo". The complete regular expression matches this time, and you get
2037 the expected output of "table follows foo."
2038
2039 Sometimes minimal matching can help a lot.  Imagine you'd like to match
2040 everything between "foo" and "bar".  Initially, you write something
2041 like this:
2042
2043     $_ =  "The food is under the bar in the barn.";
2044     if ( /foo(.*)bar/ ) {
2045         print "got <$1>\n";
2046     }
2047
2048 Which perhaps unexpectedly yields:
2049
2050   got <d is under the bar in the >
2051
2052 That's because C<.*> was greedy, so you get everything between the
2053 I<first> "foo" and the I<last> "bar".  Here it's more effective
2054 to use minimal matching to make sure you get the text between a "foo"
2055 and the first "bar" thereafter.
2056
2057     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
2058   got <d is under the >
2059
2060 Here's another example. Let's say you'd like to match a number at the end
2061 of a string, and you also want to keep the preceding part of the match.
2062 So you write this:
2063
2064     $_ = "I have 2 numbers: 53147";
2065     if ( /(.*)(\d*)/ ) {                                # Wrong!
2066         print "Beginning is <$1>, number is <$2>.\n";
2067     }
2068
2069 That won't work at all, because C<.*> was greedy and gobbled up the
2070 whole string. As C<\d*> can match on an empty string the complete
2071 regular expression matched successfully.
2072
2073     Beginning is <I have 2 numbers: 53147>, number is <>.
2074
2075 Here are some variants, most of which don't work:
2076
2077     $_ = "I have 2 numbers: 53147";
2078     @pats = qw{
2079         (.*)(\d*)
2080         (.*)(\d+)
2081         (.*?)(\d*)
2082         (.*?)(\d+)
2083         (.*)(\d+)$
2084         (.*?)(\d+)$
2085         (.*)\b(\d+)$
2086         (.*\D)(\d+)$
2087     };
2088
2089     for $pat (@pats) {
2090         printf "%-12s ", $pat;
2091         if ( /$pat/ ) {
2092             print "<$1> <$2>\n";
2093         } else {
2094             print "FAIL\n";
2095         }
2096     }
2097
2098 That will print out:
2099
2100     (.*)(\d*)    <I have 2 numbers: 53147> <>
2101     (.*)(\d+)    <I have 2 numbers: 5314> <7>
2102     (.*?)(\d*)   <> <>
2103     (.*?)(\d+)   <I have > <2>
2104     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
2105     (.*?)(\d+)$  <I have 2 numbers: > <53147>
2106     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
2107     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
2108
2109 As you see, this can be a bit tricky.  It's important to realize that a
2110 regular expression is merely a set of assertions that gives a definition
2111 of success.  There may be 0, 1, or several different ways that the
2112 definition might succeed against a particular string.  And if there are
2113 multiple ways it might succeed, you need to understand backtracking to
2114 know which variety of success you will achieve.
2115
2116 When using look-ahead assertions and negations, this can all get even
2117 trickier.  Imagine you'd like to find a sequence of non-digits not
2118 followed by "123".  You might try to write that as
2119
2120     $_ = "ABC123";
2121     if ( /^\D*(?!123)/ ) {                # Wrong!
2122         print "Yup, no 123 in $_\n";
2123     }
2124
2125 But that isn't going to match; at least, not the way you're hoping.  It
2126 claims that there is no 123 in the string.  Here's a clearer picture of
2127 why that pattern matches, contrary to popular expectations:
2128
2129     $x = 'ABC123';
2130     $y = 'ABC445';
2131
2132     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
2133     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
2134
2135     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
2136     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
2137
2138 This prints
2139
2140     2: got ABC
2141     3: got AB
2142     4: got ABC
2143
2144 You might have expected test 3 to fail because it seems to a more
2145 general purpose version of test 1.  The important difference between
2146 them is that test 3 contains a quantifier (C<\D*>) and so can use
2147 backtracking, whereas test 1 will not.  What's happening is
2148 that you've asked "Is it true that at the start of $x, following 0 or more
2149 non-digits, you have something that's not 123?"  If the pattern matcher had
2150 let C<\D*> expand to "ABC", this would have caused the whole pattern to
2151 fail.
2152
2153 The search engine will initially match C<\D*> with "ABC".  Then it will
2154 try to match C<(?!123)> with "123", which fails.  But because
2155 a quantifier (C<\D*>) has been used in the regular expression, the
2156 search engine can backtrack and retry the match differently
2157 in the hope of matching the complete regular expression.
2158
2159 The pattern really, I<really> wants to succeed, so it uses the
2160 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
2161 time.  Now there's indeed something following "AB" that is not
2162 "123".  It's "C123", which suffices.
2163
2164 We can deal with this by using both an assertion and a negation.
2165 We'll say that the first part in $1 must be followed both by a digit
2166 and by something that's not "123".  Remember that the look-aheads
2167 are zero-width expressions--they only look, but don't consume any
2168 of the string in their match.  So rewriting this way produces what
2169 you'd expect; that is, case 5 will fail, but case 6 succeeds:
2170
2171     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
2172     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
2173
2174     6: got ABC
2175
2176 In other words, the two zero-width assertions next to each other work as though
2177 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
2178 matches only if you're at the beginning of the line AND the end of the
2179 line simultaneously.  The deeper underlying truth is that juxtaposition in
2180 regular expressions always means AND, except when you write an explicit OR
2181 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
2182 although the attempted matches are made at different positions because "a"
2183 is not a zero-width assertion, but a one-width assertion.
2184
2185 B<WARNING>: Particularly complicated regular expressions can take
2186 exponential time to solve because of the immense number of possible
2187 ways they can use backtracking to try for a match.  For example, without
2188 internal optimizations done by the regular expression engine, this will
2189 take a painfully long time to run:
2190
2191     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
2192
2193 And if you used C<*>'s in the internal groups instead of limiting them
2194 to 0 through 5 matches, then it would take forever--or until you ran
2195 out of stack space.  Moreover, these internal optimizations are not
2196 always applicable.  For example, if you put C<{0,5}> instead of C<*>
2197 on the external group, no current optimization is applicable, and the
2198 match takes a long time to finish.
2199
2200 A powerful tool for optimizing such beasts is what is known as an
2201 "independent group",
2202 which does not backtrack (see L</C<< (?>pattern) >>>).  Note also that
2203 zero-length look-ahead/look-behind assertions will not backtrack to make
2204 the tail match, since they are in "logical" context: only
2205 whether they match is considered relevant.  For an example
2206 where side-effects of look-ahead I<might> have influenced the
2207 following match, see L</C<< (?>pattern) >>>.
2208
2209 =head2 Version 8 Regular Expressions
2210 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
2211
2212 In case you're not familiar with the "regular" Version 8 regex
2213 routines, here are the pattern-matching rules not described above.
2214
2215 Any single character matches itself, unless it is a I<metacharacter>
2216 with a special meaning described here or above.  You can cause
2217 characters that normally function as metacharacters to be interpreted
2218 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
2219 character; "\\" matches a "\"). This escape mechanism is also required
2220 for the character used as the pattern delimiter.
2221
2222 A series of characters matches that series of characters in the target
2223 string, so the pattern C<blurfl> would match "blurfl" in the target
2224 string.
2225
2226 You can specify a character class, by enclosing a list of characters
2227 in C<[]>, which will match any character from the list.  If the
2228 first character after the "[" is "^", the class matches any character not
2229 in the list.  Within a list, the "-" character specifies a
2230 range, so that C<a-z> represents all characters between "a" and "z",
2231 inclusive.  If you want either "-" or "]" itself to be a member of a
2232 class, put it at the start of the list (possibly after a "^"), or
2233 escape it with a backslash.  "-" is also taken literally when it is
2234 at the end of the list, just before the closing "]".  (The
2235 following all specify the same class of three characters: C<[-az]>,
2236 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
2237 specifies a class containing twenty-six characters, even on EBCDIC-based
2238 character sets.)  Also, if you try to use the character
2239 classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of
2240 a range, the "-" is understood literally.
2241
2242 Note also that the whole range idea is rather unportable between
2243 character sets--and even within character sets they may cause results
2244 you probably didn't expect.  A sound principle is to use only ranges
2245 that begin from and end at either alphabetics of equal case ([a-e],
2246 [A-E]), or digits ([0-9]).  Anything else is unsafe.  If in doubt,
2247 spell out the character sets in full.
2248
2249 Characters may be specified using a metacharacter syntax much like that
2250 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
2251 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
2252 of three octal digits, matches the character whose coded character set value
2253 is I<nnn>.  Similarly, \xI<nn>, where I<nn> are hexadecimal digits,
2254 matches the character whose ordinal is I<nn>. The expression \cI<x>
2255 matches the character control-I<x>.  Finally, the "." metacharacter
2256 matches any character except "\n" (unless you use C</s>).
2257
2258 You can specify a series of alternatives for a pattern using "|" to
2259 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
2260 or "foe" in the target string (as would C<f(e|i|o)e>).  The
2261 first alternative includes everything from the last pattern delimiter
2262 ("(", "(?:", etc. or the beginning of the pattern) up to the first "|", and
2263 the last alternative contains everything from the last "|" to the next
2264 closing pattern delimiter.  That's why it's common practice to include
2265 alternatives in parentheses: to minimize confusion about where they
2266 start and end.
2267
2268 Alternatives are tried from left to right, so the first
2269 alternative found for which the entire expression matches, is the one that
2270 is chosen. This means that alternatives are not necessarily greedy. For
2271 example: when matching C<foo|foot> against "barefoot", only the "foo"
2272 part will match, as that is the first alternative tried, and it successfully
2273 matches the target string. (This might not seem important, but it is
2274 important when you are capturing matched text using parentheses.)
2275
2276 Also remember that "|" is interpreted as a literal within square brackets,
2277 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
2278
2279 Within a pattern, you may designate subpatterns for later reference
2280 by enclosing them in parentheses, and you may refer back to the
2281 I<n>th subpattern later in the pattern using the metacharacter
2282 \I<n> or \gI<n>.  Subpatterns are numbered based on the left to right order
2283 of their opening parenthesis.  A backreference matches whatever
2284 actually matched the subpattern in the string being examined, not
2285 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\g1\d*> will
2286 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
2287 1 matched "0x", even though the rule C<0|0x> could potentially match
2288 the leading 0 in the second number.
2289
2290 =head2 Warning on \1 Instead of $1
2291
2292 Some people get too used to writing things like:
2293
2294     $pattern =~ s/(\W)/\\\1/g;
2295
2296 This is grandfathered (for \1 to \9) for the RHS of a substitute to avoid
2297 shocking the
2298 B<sed> addicts, but it's a dirty habit to get into.  That's because in
2299 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
2300 the usual double-quoted string means a control-A.  The customary Unix
2301 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
2302 of doing that, you get yourself into trouble if you then add an C</e>
2303 modifier.
2304
2305     s/(\d+)/ \1 + 1 /eg;            # causes warning under -w
2306
2307 Or if you try to do
2308
2309     s/(\d+)/\1000/;
2310
2311 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
2312 C<${1}000>.  The operation of interpolation should not be confused
2313 with the operation of matching a backreference.  Certainly they mean two
2314 different things on the I<left> side of the C<s///>.
2315
2316 =head2 Repeated Patterns Matching a Zero-length Substring
2317
2318 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
2319
2320 Regular expressions provide a terse and powerful programming language.  As
2321 with most other power tools, power comes together with the ability
2322 to wreak havoc.
2323
2324 A common abuse of this power stems from the ability to make infinite
2325 loops using regular expressions, with something as innocuous as:
2326
2327     'foo' =~ m{ ( o? )* }x;
2328
2329 The C<o?> matches at the beginning of C<'foo'>, and since the position
2330 in the string is not moved by the match, C<o?> would match again and again
2331 because of the C<*> quantifier.  Another common way to create a similar cycle
2332 is with the looping modifier C<//g>:
2333
2334     @matches = ( 'foo' =~ m{ o? }xg );
2335
2336 or
2337
2338     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
2339
2340 or the loop implied by split().
2341
2342 However, long experience has shown that many programming tasks may
2343 be significantly simplified by using repeated subexpressions that
2344 may match zero-length substrings.  Here's a simple example being:
2345
2346     @chars = split //, $string;           # // is not magic in split
2347     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
2348
2349 Thus Perl allows such constructs, by I<forcefully breaking
2350 the infinite loop>.  The rules for this are different for lower-level
2351 loops given by the greedy quantifiers C<*+{}>, and for higher-level
2352 ones like the C</g> modifier or split() operator.
2353
2354 The lower-level loops are I<interrupted> (that is, the loop is
2355 broken) when Perl detects that a repeated expression matched a
2356 zero-length substring.   Thus
2357
2358    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
2359
2360 is made equivalent to
2361
2362    m{ (?: NON_ZERO_LENGTH )* (?: ZERO_LENGTH )? }x;
2363
2364 For example, this program
2365
2366    #!perl -l
2367    "aaaaab" =~ /
2368      (?:
2369         a                 # non-zero
2370         |                 # or
2371        (?{print "hello"}) # print hello whenever this
2372                           #    branch is tried
2373        (?=(b))            # zero-width assertion
2374      )*  # any number of times
2375     /x;
2376    print $&;
2377    print $1;
2378
2379 prints
2380
2381    hello
2382    aaaaa
2383    b
2384
2385 Notice that "hello" is only printed once, as when Perl sees that the sixth
2386 iteration of the outermost C<(?:)*> matches a zero-length string, it stops
2387 the C<*>.
2388
2389 The higher-level loops preserve an additional state between iterations:
2390 whether the last match was zero-length.  To break the loop, the following
2391 match after a zero-length match is prohibited to have a length of zero.
2392 This prohibition interacts with backtracking (see L<"Backtracking">),
2393 and so the I<second best> match is chosen if the I<best> match is of
2394 zero length.
2395
2396 For example:
2397
2398     $_ = 'bar';
2399     s/\w??/<$&>/g;
2400
2401 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
2402 match given by non-greedy C<??> is the zero-length match, and the I<second
2403 best> match is what is matched by C<\w>.  Thus zero-length matches
2404 alternate with one-character-long matches.
2405
2406 Similarly, for repeated C<m/()/g> the second-best match is the match at the
2407 position one notch further in the string.
2408
2409 The additional state of being I<matched with zero-length> is associated with
2410 the matched string, and is reset by each assignment to pos().
2411 Zero-length matches at the end of the previous match are ignored
2412 during C<split>.
2413
2414 =head2 Combining RE Pieces
2415
2416 Each of the elementary pieces of regular expressions which were described
2417 before (such as C<ab> or C<\Z>) could match at most one substring
2418 at the given position of the input string.  However, in a typical regular
2419 expression these elementary pieces are combined into more complicated
2420 patterns using combining operators C<ST>, C<S|T>, C<S*> etc.
2421 (in these examples C<S> and C<T> are regular subexpressions).
2422
2423 Such combinations can include alternatives, leading to a problem of choice:
2424 if we match a regular expression C<a|ab> against C<"abc">, will it match
2425 substring C<"a"> or C<"ab">?  One way to describe which substring is
2426 actually matched is the concept of backtracking (see L<"Backtracking">).
2427 However, this description is too low-level and makes you think
2428 in terms of a particular implementation.
2429
2430 Another description starts with notions of "better"/"worse".  All the
2431 substrings which may be matched by the given regular expression can be
2432 sorted from the "best" match to the "worst" match, and it is the "best"
2433 match which is chosen.  This substitutes the question of "what is chosen?"
2434 by the question of "which matches are better, and which are worse?".
2435
2436 Again, for elementary pieces there is no such question, since at most
2437 one match at a given position is possible.  This section describes the
2438 notion of better/worse for combining operators.  In the description
2439 below C<S> and C<T> are regular subexpressions.
2440
2441 =over 4
2442
2443 =item C<ST>
2444
2445 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
2446 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
2447 which can be matched by C<T>.
2448
2449 If C<A> is a better match for C<S> than C<A'>, C<AB> is a better
2450 match than C<A'B'>.
2451
2452 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
2453 C<B> is a better match for C<T> than C<B'>.
2454
2455 =item C<S|T>
2456
2457 When C<S> can match, it is a better match than when only C<T> can match.
2458
2459 Ordering of two matches for C<S> is the same as for C<S>.  Similar for
2460 two matches for C<T>.
2461
2462 =item C<S{REPEAT_COUNT}>
2463
2464 Matches as C<SSS...S> (repeated as many times as necessary).
2465
2466 =item C<S{min,max}>
2467
2468 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
2469
2470 =item C<S{min,max}?>
2471
2472 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
2473
2474 =item C<S?>, C<S*>, C<S+>
2475
2476 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
2477
2478 =item C<S??>, C<S*?>, C<S+?>
2479
2480 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
2481
2482 =item C<< (?>S) >>
2483
2484 Matches the best match for C<S> and only that.
2485
2486 =item C<(?=S)>, C<(?<=S)>
2487
2488 Only the best match for C<S> is considered.  (This is important only if
2489 C<S> has capturing parentheses, and backreferences are used somewhere
2490 else in the whole regular expression.)
2491
2492 =item C<(?!S)>, C<(?<!S)>
2493
2494 For this grouping operator there is no need to describe the ordering, since
2495 only whether or not C<S> can match is important.
2496
2497 =item C<(??{ EXPR })>, C<(?PARNO)>
2498
2499 The ordering is the same as for the regular expression which is
2500 the result of EXPR, or the pattern contained by capture group PARNO.
2501
2502 =item C<(?(condition)yes-pattern|no-pattern)>
2503
2504 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
2505 already determined.  The ordering of the matches is the same as for the
2506 chosen subexpression.
2507
2508 =back
2509
2510 The above recipes describe the ordering of matches I<at a given position>.
2511 One more rule is needed to understand how a match is determined for the
2512 whole regular expression: a match at an earlier position is always better
2513 than a match at a later position.
2514
2515 =head2 Creating Custom RE Engines
2516
2517 As of Perl 5.10.0, one can create custom regular expression engines.  This
2518 is not for the faint of heart, as they have to plug in at the C level.  See
2519 L<perlreapi> for more details.
2520
2521 As an alternative, overloaded constants (see L<overload>) provide a simple
2522 way to extend the functionality of the RE engine, by substituting one
2523 pattern for another.
2524
2525 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
2526 matches at a boundary between whitespace characters and non-whitespace
2527 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
2528 at these positions, so we want to have each C<\Y|> in the place of the
2529 more complicated version.  We can create a module C<customre> to do
2530 this:
2531
2532     package customre;
2533     use overload;
2534
2535     sub import {
2536       shift;
2537       die "No argument to customre::import allowed" if @_;
2538       overload::constant 'qr' => \&convert;
2539     }
2540
2541     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
2542
2543     # We must also take care of not escaping the legitimate \\Y|
2544     # sequence, hence the presence of '\\' in the conversion rules.
2545     my %rules = ( '\\' => '\\\\',
2546                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
2547     sub convert {
2548       my $re = shift;
2549       $re =~ s{
2550                 \\ ( \\ | Y . )
2551               }
2552               { $rules{$1} or invalid($re,$1) }sgex;
2553       return $re;
2554     }
2555
2556 Now C<use customre> enables the new escape in constant regular
2557 expressions, i.e., those without any runtime variable interpolations.
2558 As documented in L<overload>, this conversion will work only over
2559 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
2560 part of this regular expression needs to be converted explicitly
2561 (but only if the special meaning of C<\Y|> should be enabled inside $re):
2562
2563     use customre;
2564     $re = <>;
2565     chomp $re;
2566     $re = customre::convert $re;
2567     /\Y|$re\Y|/;
2568
2569 =head2 PCRE/Python Support
2570
2571 As of Perl 5.10.0, Perl supports several Python/PCRE-specific extensions
2572 to the regex syntax. While Perl programmers are encouraged to use the
2573 Perl-specific syntax, the following are also accepted:
2574
2575 =over 4
2576
2577 =item C<< (?PE<lt>NAMEE<gt>pattern) >>
2578
2579 Define a named capture group. Equivalent to C<< (?<NAME>pattern) >>.
2580
2581 =item C<< (?P=NAME) >>
2582
2583 Backreference to a named capture group. Equivalent to C<< \g{NAME} >>.
2584
2585 =item C<< (?P>NAME) >>
2586
2587 Subroutine call to a named capture group. Equivalent to C<< (?&NAME) >>.
2588
2589 =back
2590
2591 =head1 BUGS
2592
2593 Many regular expression constructs don't work on EBCDIC platforms.
2594
2595 There are a number of issues with regard to case-insensitive matching
2596 in Unicode rules.  See C<i> under L</Modifiers> above.
2597
2598 This document varies from difficult to understand to completely
2599 and utterly opaque.  The wandering prose riddled with jargon is
2600 hard to fathom in several places.
2601
2602 This document needs a rewrite that separates the tutorial content
2603 from the reference content.
2604
2605 =head1 SEE ALSO
2606
2607 L<perlrequick>.
2608
2609 L<perlretut>.
2610
2611 L<perlop/"Regexp Quote-Like Operators">.
2612
2613 L<perlop/"Gory details of parsing quoted constructs">.
2614
2615 L<perlfaq6>.
2616
2617 L<perlfunc/pos>.
2618
2619 L<perllocale>.
2620
2621 L<perlebcdic>.
2622
2623 I<Mastering Regular Expressions> by Jeffrey Friedl, published
2624 by O'Reilly and Associates.