This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
157161313d401465aef42c552309d5abb570464d
[perl5.git] / pod / perlref.pod
1 =head1 NAME
2 X<reference> X<pointer> X<data structure> X<structure> X<struct>
3
4 perlref - Perl references and nested data structures
5
6 =head1 NOTE
7
8 This is complete documentation about all aspects of references.
9 For a shorter, tutorial introduction to just the essential features,
10 see L<perlreftut>.
11
12 =head1 DESCRIPTION
13
14 Before release 5 of Perl it was difficult to represent complex data
15 structures, because all references had to be symbolic--and even then
16 it was difficult to refer to a variable instead of a symbol table entry.
17 Perl now not only makes it easier to use symbolic references to variables,
18 but also lets you have "hard" references to any piece of data or code.
19 Any scalar may hold a hard reference.  Because arrays and hashes contain
20 scalars, you can now easily build arrays of arrays, arrays of hashes,
21 hashes of arrays, arrays of hashes of functions, and so on.
22
23 Hard references are smart--they keep track of reference counts for you,
24 automatically freeing the thing referred to when its reference count goes
25 to zero.  (Reference counts for values in self-referential or
26 cyclic data structures may not go to zero without a little help; see
27 L</"Circular References"> for a detailed explanation.)
28 If that thing happens to be an object, the object is destructed.  See
29 L<perlobj> for more about objects.  (In a sense, everything in Perl is an
30 object, but we usually reserve the word for references to objects that
31 have been officially "blessed" into a class package.)
32
33 Symbolic references are names of variables or other objects, just as a
34 symbolic link in a Unix filesystem contains merely the name of a file.
35 The C<*glob> notation is something of a symbolic reference.  (Symbolic
36 references are sometimes called "soft references", but please don't call
37 them that; references are confusing enough without useless synonyms.)
38 X<reference, symbolic> X<reference, soft>
39 X<symbolic reference> X<soft reference>
40
41 In contrast, hard references are more like hard links in a Unix file
42 system: They are used to access an underlying object without concern for
43 what its (other) name is.  When the word "reference" is used without an
44 adjective, as in the following paragraph, it is usually talking about a
45 hard reference.
46 X<reference, hard> X<hard reference>
47
48 References are easy to use in Perl.  There is just one overriding
49 principle: in general, Perl does no implicit referencing or dereferencing.
50 When a scalar is holding a reference, it always behaves as a simple scalar.
51 It doesn't magically start being an array or hash or subroutine; you have to
52 tell it explicitly to do so, by dereferencing it.
53
54 That said, be aware that Perl version 5.14 introduces an exception
55 to the rule, for syntactic convenience.  Experimental array and hash container
56 function behavior allows array and hash references to be handled by Perl as
57 if they had been explicitly syntactically dereferenced.  See
58 L<perl5140delta/"Syntactical Enhancements">
59 and L<perlfunc> for details.
60
61 =head2 Making References
62 X<reference, creation> X<referencing>
63
64 References can be created in several ways.
65
66 =over 4
67
68 =item 1.
69 X<\> X<backslash>
70
71 By using the backslash operator on a variable, subroutine, or value.
72 (This works much like the & (address-of) operator in C.)  
73 This typically creates I<another> reference to a variable, because
74 there's already a reference to the variable in the symbol table.  But
75 the symbol table reference might go away, and you'll still have the
76 reference that the backslash returned.  Here are some examples:
77
78     $scalarref = \$foo;
79     $arrayref  = \@ARGV;
80     $hashref   = \%ENV;
81     $coderef   = \&handler;
82     $globref   = \*foo;
83
84 It isn't possible to create a true reference to an IO handle (filehandle
85 or dirhandle) using the backslash operator.  The most you can get is a
86 reference to a typeglob, which is actually a complete symbol table entry.
87 But see the explanation of the C<*foo{THING}> syntax below.  However,
88 you can still use type globs and globrefs as though they were IO handles.
89
90 =item 2.
91 X<array, anonymous> X<[> X<[]> X<square bracket>
92 X<bracket, square> X<arrayref> X<array reference> X<reference, array>
93
94 A reference to an anonymous array can be created using square
95 brackets:
96
97     $arrayref = [1, 2, ['a', 'b', 'c']];
98
99 Here we've created a reference to an anonymous array of three elements
100 whose final element is itself a reference to another anonymous array of three
101 elements.  (The multidimensional syntax described later can be used to
102 access this.  For example, after the above, C<< $arrayref->[2][1] >> would have
103 the value "b".)
104
105 Taking a reference to an enumerated list is not the same
106 as using square brackets--instead it's the same as creating
107 a list of references!
108
109     @list = (\$a, \@b, \%c);
110     @list = \($a, @b, %c);      # same thing!
111
112 As a special case, C<\(@foo)> returns a list of references to the contents
113 of C<@foo>, not a reference to C<@foo> itself.  Likewise for C<%foo>,
114 except that the key references are to copies (since the keys are just
115 strings rather than full-fledged scalars).
116
117 =item 3.
118 X<hash, anonymous> X<{> X<{}> X<curly bracket>
119 X<bracket, curly> X<brace> X<hashref> X<hash reference> X<reference, hash>
120
121 A reference to an anonymous hash can be created using curly
122 brackets:
123
124     $hashref = {
125         'Adam'  => 'Eve',
126         'Clyde' => 'Bonnie',
127     };
128
129 Anonymous hash and array composers like these can be intermixed freely to
130 produce as complicated a structure as you want.  The multidimensional
131 syntax described below works for these too.  The values above are
132 literals, but variables and expressions would work just as well, because
133 assignment operators in Perl (even within local() or my()) are executable
134 statements, not compile-time declarations.
135
136 Because curly brackets (braces) are used for several other things
137 including BLOCKs, you may occasionally have to disambiguate braces at the
138 beginning of a statement by putting a C<+> or a C<return> in front so
139 that Perl realizes the opening brace isn't starting a BLOCK.  The economy and
140 mnemonic value of using curlies is deemed worth this occasional extra
141 hassle.
142
143 For example, if you wanted a function to make a new hash and return a
144 reference to it, you have these options:
145
146     sub hashem {        { @_ } }   # silently wrong
147     sub hashem {       +{ @_ } }   # ok
148     sub hashem { return { @_ } }   # ok
149
150 On the other hand, if you want the other meaning, you can do this:
151
152     sub showem {        { @_ } }   # ambiguous (currently ok, but may change)
153     sub showem {       {; @_ } }   # ok
154     sub showem { { return @_ } }   # ok
155
156 The leading C<+{> and C<{;> always serve to disambiguate
157 the expression to mean either the HASH reference, or the BLOCK.
158
159 =item 4.
160 X<subroutine, anonymous> X<subroutine, reference> X<reference, subroutine>
161 X<scope, lexical> X<closure> X<lexical> X<lexical scope>
162
163 A reference to an anonymous subroutine can be created by using
164 C<sub> without a subname:
165
166     $coderef = sub { print "Boink!\n" };
167
168 Note the semicolon.  Except for the code
169 inside not being immediately executed, a C<sub {}> is not so much a
170 declaration as it is an operator, like C<do{}> or C<eval{}>.  (However, no
171 matter how many times you execute that particular line (unless you're in an
172 C<eval("...")>), $coderef will still have a reference to the I<same>
173 anonymous subroutine.)
174
175 Anonymous subroutines act as closures with respect to my() variables,
176 that is, variables lexically visible within the current scope.  Closure
177 is a notion out of the Lisp world that says if you define an anonymous
178 function in a particular lexical context, it pretends to run in that
179 context even when it's called outside the context.
180
181 In human terms, it's a funny way of passing arguments to a subroutine when
182 you define it as well as when you call it.  It's useful for setting up
183 little bits of code to run later, such as callbacks.  You can even
184 do object-oriented stuff with it, though Perl already provides a different
185 mechanism to do that--see L<perlobj>.
186
187 You might also think of closure as a way to write a subroutine
188 template without using eval().  Here's a small example of how
189 closures work:
190
191     sub newprint {
192         my $x = shift;
193         return sub { my $y = shift; print "$x, $y!\n"; };
194     }
195     $h = newprint("Howdy");
196     $g = newprint("Greetings");
197
198     # Time passes...
199
200     &$h("world");
201     &$g("earthlings");
202
203 This prints
204
205     Howdy, world!
206     Greetings, earthlings!
207
208 Note particularly that $x continues to refer to the value passed
209 into newprint() I<despite> "my $x" having gone out of scope by the
210 time the anonymous subroutine runs.  That's what a closure is all
211 about.
212
213 This applies only to lexical variables, by the way.  Dynamic variables
214 continue to work as they have always worked.  Closure is not something
215 that most Perl programmers need trouble themselves about to begin with.
216
217 =item 5.
218 X<constructor> X<new>
219
220 References are often returned by special subroutines called constructors.  Perl
221 objects are just references to a special type of object that happens to know
222 which package it's associated with.  Constructors are just special subroutines
223 that know how to create that association.  They do so by starting with an
224 ordinary reference, and it remains an ordinary reference even while it's also
225 being an object.  Constructors are often named C<new()>.  You I<can> call them
226 indirectly:
227
228     $objref = new Doggie( Tail => 'short', Ears => 'long' );
229
230 But that can produce ambiguous syntax in certain cases, so it's often
231 better to use the direct method invocation approach:
232
233     $objref   = Doggie->new(Tail => 'short', Ears => 'long');
234
235     use Term::Cap;
236     $terminal = Term::Cap->Tgetent( { OSPEED => 9600 });
237
238     use Tk;
239     $main    = MainWindow->new();
240     $menubar = $main->Frame(-relief              => "raised",
241                             -borderwidth         => 2)
242
243 =item 6.
244 X<autovivification>
245
246 References of the appropriate type can spring into existence if you
247 dereference them in a context that assumes they exist.  Because we haven't
248 talked about dereferencing yet, we can't show you any examples yet.
249
250 =item 7.
251 X<*foo{THING}> X<*>
252
253 A reference can be created by using a special syntax, lovingly known as
254 the *foo{THING} syntax.  *foo{THING} returns a reference to the THING
255 slot in *foo (which is the symbol table entry which holds everything
256 known as foo).
257
258     $scalarref = *foo{SCALAR};
259     $arrayref  = *ARGV{ARRAY};
260     $hashref   = *ENV{HASH};
261     $coderef   = *handler{CODE};
262     $ioref     = *STDIN{IO};
263     $globref   = *foo{GLOB};
264     $formatref = *foo{FORMAT};
265
266 All of these are self-explanatory except for C<*foo{IO}>.  It returns
267 the IO handle, used for file handles (L<perlfunc/open>), sockets
268 (L<perlfunc/socket> and L<perlfunc/socketpair>), and directory
269 handles (L<perlfunc/opendir>).  For compatibility with previous
270 versions of Perl, C<*foo{FILEHANDLE}> is a synonym for C<*foo{IO}>, though it
271 is deprecated as of 5.8.0.  If deprecation warnings are in effect, it will warn
272 of its use.
273
274 C<*foo{THING}> returns undef if that particular THING hasn't been used yet,
275 except in the case of scalars.  C<*foo{SCALAR}> returns a reference to an
276 anonymous scalar if $foo hasn't been used yet.  This might change in a
277 future release.
278
279 C<*foo{IO}> is an alternative to the C<*HANDLE> mechanism given in
280 L<perldata/"Typeglobs and Filehandles"> for passing filehandles
281 into or out of subroutines, or storing into larger data structures.
282 Its disadvantage is that it won't create a new filehandle for you.
283 Its advantage is that you have less risk of clobbering more than
284 you want to with a typeglob assignment.  (It still conflates file
285 and directory handles, though.)  However, if you assign the incoming
286 value to a scalar instead of a typeglob as we do in the examples
287 below, there's no risk of that happening.
288
289     splutter(*STDOUT);          # pass the whole glob
290     splutter(*STDOUT{IO});      # pass both file and dir handles
291
292     sub splutter {
293         my $fh = shift;
294         print $fh "her um well a hmmm\n";
295     }
296
297     $rec = get_rec(*STDIN);     # pass the whole glob
298     $rec = get_rec(*STDIN{IO}); # pass both file and dir handles
299
300     sub get_rec {
301         my $fh = shift;
302         return scalar <$fh>;
303     }
304
305 =back
306
307 =head2 Using References
308 X<reference, use> X<dereferencing> X<dereference>
309
310 That's it for creating references.  By now you're probably dying to
311 know how to use references to get back to your long-lost data.  There
312 are several basic methods.
313
314 =over 4
315
316 =item 1.
317
318 Anywhere you'd put an identifier (or chain of identifiers) as part
319 of a variable or subroutine name, you can replace the identifier with
320 a simple scalar variable containing a reference of the correct type:
321
322     $bar = $$scalarref;
323     push(@$arrayref, $filename);
324     $$arrayref[0] = "January";
325     $$hashref{"KEY"} = "VALUE";
326     &$coderef(1,2,3);
327     print $globref "output\n";
328
329 It's important to understand that we are specifically I<not> dereferencing
330 C<$arrayref[0]> or C<$hashref{"KEY"}> there.  The dereference of the
331 scalar variable happens I<before> it does any key lookups.  Anything more
332 complicated than a simple scalar variable must use methods 2 or 3 below.
333 However, a "simple scalar" includes an identifier that itself uses method
334 1 recursively.  Therefore, the following prints "howdy".
335
336     $refrefref = \\\"howdy";
337     print $$$$refrefref;
338
339 =item 2.
340
341 Anywhere you'd put an identifier (or chain of identifiers) as part of a
342 variable or subroutine name, you can replace the identifier with a
343 BLOCK returning a reference of the correct type.  In other words, the
344 previous examples could be written like this:
345
346     $bar = ${$scalarref};
347     push(@{$arrayref}, $filename);
348     ${$arrayref}[0] = "January";
349     ${$hashref}{"KEY"} = "VALUE";
350     &{$coderef}(1,2,3);
351     $globref->print("output\n");  # iff IO::Handle is loaded
352
353 Admittedly, it's a little silly to use the curlies in this case, but
354 the BLOCK can contain any arbitrary expression, in particular,
355 subscripted expressions:
356
357     &{ $dispatch{$index} }(1,2,3);      # call correct routine
358
359 Because of being able to omit the curlies for the simple case of C<$$x>,
360 people often make the mistake of viewing the dereferencing symbols as
361 proper operators, and wonder about their precedence.  If they were,
362 though, you could use parentheses instead of braces.  That's not the case.
363 Consider the difference below; case 0 is a short-hand version of case 1,
364 I<not> case 2:
365
366     $$hashref{"KEY"}   = "VALUE";       # CASE 0
367     ${$hashref}{"KEY"} = "VALUE";       # CASE 1
368     ${$hashref{"KEY"}} = "VALUE";       # CASE 2
369     ${$hashref->{"KEY"}} = "VALUE";     # CASE 3
370
371 Case 2 is also deceptive in that you're accessing a variable
372 called %hashref, not dereferencing through $hashref to the hash
373 it's presumably referencing.  That would be case 3.
374
375 =item 3.
376
377 Subroutine calls and lookups of individual array elements arise often
378 enough that it gets cumbersome to use method 2.  As a form of
379 syntactic sugar, the examples for method 2 may be written:
380
381     $arrayref->[0] = "January";   # Array element
382     $hashref->{"KEY"} = "VALUE";  # Hash element
383     $coderef->(1,2,3);            # Subroutine call
384
385 The left side of the arrow can be any expression returning a reference,
386 including a previous dereference.  Note that C<$array[$x]> is I<not> the
387 same thing as C<< $array->[$x] >> here:
388
389     $array[$x]->{"foo"}->[0] = "January";
390
391 This is one of the cases we mentioned earlier in which references could
392 spring into existence when in an lvalue context.  Before this
393 statement, C<$array[$x]> may have been undefined.  If so, it's
394 automatically defined with a hash reference so that we can look up
395 C<{"foo"}> in it.  Likewise C<< $array[$x]->{"foo"} >> will automatically get
396 defined with an array reference so that we can look up C<[0]> in it.
397 This process is called I<autovivification>.
398
399 One more thing here.  The arrow is optional I<between> brackets
400 subscripts, so you can shrink the above down to
401
402     $array[$x]{"foo"}[0] = "January";
403
404 Which, in the degenerate case of using only ordinary arrays, gives you
405 multidimensional arrays just like C's:
406
407     $score[$x][$y][$z] += 42;
408
409 Well, okay, not entirely like C's arrays, actually.  C doesn't know how
410 to grow its arrays on demand.  Perl does.
411
412 =item 4.
413
414 If a reference happens to be a reference to an object, then there are
415 probably methods to access the things referred to, and you should probably
416 stick to those methods unless you're in the class package that defines the
417 object's methods.  In other words, be nice, and don't violate the object's
418 encapsulation without a very good reason.  Perl does not enforce
419 encapsulation.  We are not totalitarians here.  We do expect some basic
420 civility though.
421
422 =back
423
424 Using a string or number as a reference produces a symbolic reference,
425 as explained above.  Using a reference as a number produces an
426 integer representing its storage location in memory.  The only
427 useful thing to be done with this is to compare two references
428 numerically to see whether they refer to the same location.
429 X<reference, numeric context>
430
431     if ($ref1 == $ref2) {  # cheap numeric compare of references
432         print "refs 1 and 2 refer to the same thing\n";
433     }
434
435 Using a reference as a string produces both its referent's type,
436 including any package blessing as described in L<perlobj>, as well
437 as the numeric address expressed in hex.  The ref() operator returns
438 just the type of thing the reference is pointing to, without the
439 address.  See L<perlfunc/ref> for details and examples of its use.
440 X<reference, string context>
441
442 The bless() operator may be used to associate the object a reference
443 points to with a package functioning as an object class.  See L<perlobj>.
444
445 A typeglob may be dereferenced the same way a reference can, because
446 the dereference syntax always indicates the type of reference desired.
447 So C<${*foo}> and C<${\$foo}> both indicate the same scalar variable.
448
449 Here's a trick for interpolating a subroutine call into a string:
450
451     print "My sub returned @{[mysub(1,2,3)]} that time.\n";
452
453 The way it works is that when the C<@{...}> is seen in the double-quoted
454 string, it's evaluated as a block.  The block creates a reference to an
455 anonymous array containing the results of the call to C<mysub(1,2,3)>.  So
456 the whole block returns a reference to an array, which is then
457 dereferenced by C<@{...}> and stuck into the double-quoted string. This
458 chicanery is also useful for arbitrary expressions:
459
460     print "That yields @{[$n + 5]} widgets\n";
461
462 Similarly, an expression that returns a reference to a scalar can be
463 dereferenced via C<${...}>. Thus, the above expression may be written
464 as:
465
466     print "That yields ${\($n + 5)} widgets\n";
467
468 =head2 Circular References
469 X<circular reference> X<reference, circular>
470
471 It is possible to create a "circular reference" in Perl, which can lead
472 to memory leaks. A circular reference occurs when two references
473 contain a reference to each other, like this:
474
475     my $foo = {};
476     my $bar = { foo => $foo };
477     $foo->{bar} = $bar;
478
479 You can also create a circular reference with a single variable:
480
481     my $foo;
482     $foo = \$foo;
483
484 In this case, the reference count for the variables will never reach 0,
485 and the references will never be garbage-collected. This can lead to
486 memory leaks.
487
488 Because objects in Perl are implemented as references, it's possible to
489 have circular references with objects as well. Imagine a TreeNode class
490 where each node references its parent and child nodes. Any node with a
491 parent will be part of a circular reference.
492
493 You can break circular references by creating a "weak reference". A
494 weak reference does not increment the reference count for a variable,
495 which means that the object can go out of scope and be destroyed. You
496 can weaken a reference with the C<weaken> function exported by the
497 L<Scalar::Util> module.
498
499 Here's how we can make the first example safer:
500
501     use Scalar::Util 'weaken';
502
503     my $foo = {};
504     my $bar = { foo => $foo };
505     $foo->{bar} = $bar;
506
507     weaken $foo->{bar};
508
509 The reference from C<$foo> to C<$bar> has been weakened. When the
510 C<$bar> variable goes out of scope, it will be garbage-collected. The
511 next time you look at the value of the C<< $foo->{bar} >> key, it will
512 be C<undef>.
513
514 This action at a distance can be confusing, so you should be careful
515 with your use of weaken. You should weaken the reference in the
516 variable that will go out of scope I<first>. That way, the longer-lived
517 variable will contain the expected reference until it goes out of
518 scope.
519
520 =head2 Symbolic references
521 X<reference, symbolic> X<reference, soft>
522 X<symbolic reference> X<soft reference>
523
524 We said that references spring into existence as necessary if they are
525 undefined, but we didn't say what happens if a value used as a
526 reference is already defined, but I<isn't> a hard reference.  If you
527 use it as a reference, it'll be treated as a symbolic
528 reference.  That is, the value of the scalar is taken to be the I<name>
529 of a variable, rather than a direct link to a (possibly) anonymous
530 value.
531
532 People frequently expect it to work like this.  So it does.
533
534     $name = "foo";
535     $$name = 1;                 # Sets $foo
536     ${$name} = 2;               # Sets $foo
537     ${$name x 2} = 3;           # Sets $foofoo
538     $name->[0] = 4;             # Sets $foo[0]
539     @$name = ();                # Clears @foo
540     &$name();                   # Calls &foo()
541     $pack = "THAT";
542     ${"${pack}::$name"} = 5;    # Sets $THAT::foo without eval
543
544 This is powerful, and slightly dangerous, in that it's possible
545 to intend (with the utmost sincerity) to use a hard reference, and
546 accidentally use a symbolic reference instead.  To protect against
547 that, you can say
548
549     use strict 'refs';
550
551 and then only hard references will be allowed for the rest of the enclosing
552 block.  An inner block may countermand that with
553
554     no strict 'refs';
555
556 Only package variables (globals, even if localized) are visible to
557 symbolic references.  Lexical variables (declared with my()) aren't in
558 a symbol table, and thus are invisible to this mechanism.  For example:
559
560     local $value = 10;
561     $ref = "value";
562     {
563         my $value = 20;
564         print $$ref;
565     }
566
567 This will still print 10, not 20.  Remember that local() affects package
568 variables, which are all "global" to the package.
569
570 =head2 Not-so-symbolic references
571
572 Brackets around a symbolic reference can simply
573 serve to isolate an identifier or variable name from the rest of an
574 expression, just as they always have within a string.  For example,
575
576     $push = "pop on ";
577     print "${push}over";
578
579 has always meant to print "pop on over", even though push is
580 a reserved word.  This is generalized to work the same
581 without the enclosing double quotes, so that
582
583     print ${push} . "over";
584
585 and even
586
587     print ${ push } . "over";
588
589 will have the same effect.  This
590 construct is I<not> considered to be a symbolic reference when you're
591 using strict refs:
592
593     use strict 'refs';
594     ${ bareword };      # Okay, means $bareword.
595     ${ "bareword" };    # Error, symbolic reference.
596
597 Similarly, because of all the subscripting that is done using single words,
598 the same rule applies to any bareword that is used for subscripting a hash.
599 So now, instead of writing
600
601     $array{ "aaa" }{ "bbb" }{ "ccc" }
602
603 you can write just
604
605     $array{ aaa }{ bbb }{ ccc }
606
607 and not worry about whether the subscripts are reserved words.  In the
608 rare event that you do wish to do something like
609
610     $array{ shift }
611
612 you can force interpretation as a reserved word by adding anything that
613 makes it more than a bareword:
614
615     $array{ shift() }
616     $array{ +shift }
617     $array{ shift @_ }
618
619 The C<use warnings> pragma or the B<-w> switch will warn you if it
620 interprets a reserved word as a string.
621 But it will no longer warn you about using lowercase words, because the
622 string is effectively quoted.
623
624 =head2 Pseudo-hashes: Using an array as a hash
625 X<pseudo-hash> X<pseudo hash> X<pseudohash>
626
627 Pseudo-hashes have been removed from Perl.  The 'fields' pragma
628 remains available.
629
630 =head2 Function Templates
631 X<scope, lexical> X<closure> X<lexical> X<lexical scope>
632 X<subroutine, nested> X<sub, nested> X<subroutine, local> X<sub, local>
633
634 As explained above, an anonymous function with access to the lexical
635 variables visible when that function was compiled, creates a closure.  It
636 retains access to those variables even though it doesn't get run until
637 later, such as in a signal handler or a Tk callback.
638
639 Using a closure as a function template allows us to generate many functions
640 that act similarly.  Suppose you wanted functions named after the colors
641 that generated HTML font changes for the various colors:
642
643     print "Be ", red("careful"), "with that ", green("light");
644
645 The red() and green() functions would be similar.  To create these,
646 we'll assign a closure to a typeglob of the name of the function we're
647 trying to build.  
648
649     @colors = qw(red blue green yellow orange purple violet);
650     for my $name (@colors) {
651         no strict 'refs';       # allow symbol table manipulation
652         *$name = *{uc $name} = sub { "<FONT COLOR='$name'>@_</FONT>" };
653     } 
654
655 Now all those different functions appear to exist independently.  You can
656 call red(), RED(), blue(), BLUE(), green(), etc.  This technique saves on
657 both compile time and memory use, and is less error-prone as well, since
658 syntax checks happen at compile time.  It's critical that any variables in
659 the anonymous subroutine be lexicals in order to create a proper closure.
660 That's the reasons for the C<my> on the loop iteration variable.
661
662 This is one of the only places where giving a prototype to a closure makes
663 much sense.  If you wanted to impose scalar context on the arguments of
664 these functions (probably not a wise idea for this particular example),
665 you could have written it this way instead:
666
667     *$name = sub ($) { "<FONT COLOR='$name'>$_[0]</FONT>" };
668
669 However, since prototype checking happens at compile time, the assignment
670 above happens too late to be of much use.  You could address this by
671 putting the whole loop of assignments within a BEGIN block, forcing it
672 to occur during compilation.
673
674 Access to lexicals that change over time--like those in the C<for> loop
675 above, basically aliases to elements from the surrounding lexical scopes--
676 only works with anonymous subs, not with named subroutines. Generally
677 said, named subroutines do not nest properly and should only be declared
678 in the main package scope.
679
680 This is because named subroutines are created at compile time so their
681 lexical variables get assigned to the parent lexicals from the first
682 execution of the parent block. If a parent scope is entered a second
683 time, its lexicals are created again, while the nested subs still
684 reference the old ones.
685
686 Anonymous subroutines get to capture each time you execute the C<sub>
687 operator, as they are created on the fly. If you are accustomed to using
688 nested subroutines in other programming languages with their own private
689 variables, you'll have to work at it a bit in Perl.  The intuitive coding
690 of this type of thing incurs mysterious warnings about "will not stay
691 shared" due to the reasons explained above. 
692 For example, this won't work:
693
694     sub outer {
695         my $x = $_[0] + 35;
696         sub inner { return $x * 19 }   # WRONG
697         return $x + inner();
698     }
699
700 A work-around is the following:
701
702     sub outer {
703         my $x = $_[0] + 35;
704         local *inner = sub { return $x * 19 };
705         return $x + inner();
706     }
707
708 Now inner() can only be called from within outer(), because of the
709 temporary assignments of the anonymous subroutine. But when it does,
710 it has normal access to the lexical variable $x from the scope of
711 outer() at the time outer is invoked.
712
713 This has the interesting effect of creating a function local to another
714 function, something not normally supported in Perl.
715
716 =head1 WARNING
717 X<reference, string context> X<reference, use as hash key>
718
719 You may not (usefully) use a reference as the key to a hash.  It will be
720 converted into a string:
721
722     $x{ \$a } = $a;
723
724 If you try to dereference the key, it won't do a hard dereference, and
725 you won't accomplish what you're attempting.  You might want to do something
726 more like
727
728     $r = \@a;
729     $x{ $r } = $r;
730
731 And then at least you can use the values(), which will be
732 real refs, instead of the keys(), which won't.
733
734 The standard Tie::RefHash module provides a convenient workaround to this.
735
736 =head1 SEE ALSO
737
738 Besides the obvious documents, source code can be instructive.
739 Some pathological examples of the use of references can be found
740 in the F<t/op/ref.t> regression test in the Perl source directory.
741
742 See also L<perldsc> and L<perllol> for how to use references to create
743 complex data structures, and L<perlootut> and L<perlobj>
744 for how to use them to create objects.