This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
1562854056818c040715bc16c6a602ecb591e855
[perl5.git] / t / test.pl
1 #
2 # t/test.pl - most of Test::More functionality without the fuss
3
4
5 # NOTE:
6 #
7 # Increment ($x++) has a certain amount of cleverness for things like
8 #
9 #   $x = 'zz';
10 #   $x++; # $x eq 'aaa';
11 #
12 # stands more chance of breaking than just a simple
13 #
14 #   $x = $x + 1
15 #
16 # In this file, we use the latter "Baby Perl" approach, and increment
17 # will be worked over by t/op/inc.t
18
19 $Level = 1;
20 my $test = 1;
21 my $planned;
22 my $noplan;
23
24 $TODO = 0;
25 $NO_ENDING = 0;
26
27 sub plan {
28     my $n;
29     if (@_ == 1) {
30         $n = shift;
31         if ($n eq 'no_plan') {
32           undef $n;
33           $noplan = 1;
34         }
35     } else {
36         my %plan = @_;
37         $n = $plan{tests};
38     }
39     print STDOUT "1..$n\n" unless $noplan;
40     $planned = $n;
41 }
42
43 END {
44     my $ran = $test - 1;
45     if (!$NO_ENDING) {
46         if (defined $planned && $planned != $ran) {
47             print STDERR
48                 "# Looks like you planned $planned tests but ran $ran.\n";
49         } elsif ($noplan) {
50             print "1..$ran\n";
51         }
52     }
53 }
54
55 # Use this instead of "print STDERR" when outputing failure diagnostic
56 # messages
57 sub _diag {
58     return unless @_;
59     my @mess = map { /^#/ ? "$_\n" : "# $_\n" }
60                map { split /\n/ } @_;
61     my $fh = $TODO ? *STDOUT : *STDERR;
62     print $fh @mess;
63
64 }
65
66 sub diag {
67     _diag(@_);
68 }
69
70 sub skip_all {
71     if (@_) {
72         print STDOUT "1..0 # Skipped: @_\n";
73     } else {
74         print STDOUT "1..0\n";
75     }
76     exit(0);
77 }
78
79 sub _ok {
80     my ($pass, $where, $name, @mess) = @_;
81     # Do not try to microoptimize by factoring out the "not ".
82     # VMS will avenge.
83     my $out;
84     if ($name) {
85         # escape out '#' or it will interfere with '# skip' and such
86         $name =~ s/#/\\#/g;
87         $out = $pass ? "ok $test - $name" : "not ok $test - $name";
88     } else {
89         $out = $pass ? "ok $test" : "not ok $test";
90     }
91
92     $out .= " # TODO $TODO" if $TODO;
93     print STDOUT "$out\n";
94
95     unless ($pass) {
96         _diag "# Failed $where\n";
97     }
98
99     # Ensure that the message is properly escaped.
100     _diag @mess;
101
102     $test = $test + 1; # don't use ++
103
104     return $pass;
105 }
106
107 sub _where {
108     my @caller = caller($Level);
109     return "at $caller[1] line $caller[2]";
110 }
111
112 # DON'T use this for matches. Use like() instead.
113 sub ok ($@) {
114     my ($pass, $name, @mess) = @_;
115     _ok($pass, _where(), $name, @mess);
116 }
117
118 sub _q {
119     my $x = shift;
120     return 'undef' unless defined $x;
121     my $q = $x;
122     $q =~ s/\\/\\\\/g;
123     $q =~ s/'/\\'/g;
124     return "'$q'";
125 }
126
127 sub _qq {
128     my $x = shift;
129     return defined $x ? '"' . display ($x) . '"' : 'undef';
130 };
131
132 # keys are the codes \n etc map to, values are 2 char strings such as \n
133 my %backslash_escape;
134 foreach my $x (split //, 'nrtfa\\\'"') {
135     $backslash_escape{ord eval "\"\\$x\""} = "\\$x";
136 }
137 # A way to display scalars containing control characters and Unicode.
138 # Trying to avoid setting $_, or relying on local $_ to work.
139 sub display {
140     my @result;
141     foreach my $x (@_) {
142         if (defined $x and not ref $x) {
143             my $y = '';
144             foreach my $c (unpack("U*", $x)) {
145                 if ($c > 255) {
146                     $y .= sprintf "\\x{%x}", $c;
147                 } elsif ($backslash_escape{$c}) {
148                     $y .= $backslash_escape{$c};
149                 } else {
150                     my $z = chr $c; # Maybe we can get away with a literal...
151                     $z = sprintf "\\%03o", $c if $z =~ /[[:^print:]]/;
152                     $y .= $z;
153                 }
154             }
155             $x = $y;
156         }
157         return $x unless wantarray;
158         push @result, $x;
159     }
160     return @result;
161 }
162
163 sub is ($$@) {
164     my ($got, $expected, $name, @mess) = @_;
165
166     my $pass;
167     if( !defined $got || !defined $expected ) {
168         # undef only matches undef
169         $pass = !defined $got && !defined $expected;
170     }
171     else {
172         $pass = $got eq $expected;
173     }
174
175     unless ($pass) {
176         unshift(@mess, "#      got "._q($got)."\n",
177                        "# expected "._q($expected)."\n");
178     }
179     _ok($pass, _where(), $name, @mess);
180 }
181
182 sub isnt ($$@) {
183     my ($got, $isnt, $name, @mess) = @_;
184
185     my $pass;
186     if( !defined $got || !defined $isnt ) {
187         # undef only matches undef
188         $pass = defined $got || defined $isnt;
189     }
190     else {
191         $pass = $got ne $isnt;
192     }
193
194     unless( $pass ) {
195         unshift(@mess, "# it should not be "._q($got)."\n",
196                        "# but it is.\n");
197     }
198     _ok($pass, _where(), $name, @mess);
199 }
200
201 sub cmp_ok ($$$@) {
202     my($got, $type, $expected, $name, @mess) = @_;
203
204     my $pass;
205     {
206         local $^W = 0;
207         local($@,$!);   # don't interfere with $@
208                         # eval() sometimes resets $!
209         $pass = eval "\$got $type \$expected";
210     }
211     unless ($pass) {
212         # It seems Irix long doubles can have 2147483648 and 2147483648
213         # that stringify to the same thing but are acutally numerically
214         # different. Display the numbers if $type isn't a string operator,
215         # and the numbers are stringwise the same.
216         # (all string operators have alphabetic names, so tr/a-z// is true)
217         # This will also show numbers for some uneeded cases, but will
218         # definately be helpful for things such as == and <= that fail
219         if ($got eq $expected and $type !~ tr/a-z//) {
220             unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
221         }
222         unshift(@mess, "#      got "._q($got)."\n",
223                        "# expected $type "._q($expected)."\n");
224     }
225     _ok($pass, _where(), $name, @mess);
226 }
227
228 # Check that $got is within $range of $expected
229 # if $range is 0, then check it's exact
230 # else if $expected is 0, then $range is an absolute value
231 # otherwise $range is a fractional error.
232 # Here $range must be numeric, >= 0
233 # Non numeric ranges might be a useful future extension. (eg %)
234 sub within ($$$@) {
235     my ($got, $expected, $range, $name, @mess) = @_;
236     my $pass;
237     if (!defined $got or !defined $expected or !defined $range) {
238         # This is a fail, but doesn't need extra diagnostics
239     } elsif ($got !~ tr/0-9// or $expected !~ tr/0-9// or $range !~ tr/0-9//) {
240         # This is a fail
241         unshift @mess, "# got, expected and range must be numeric\n";
242     } elsif ($range < 0) {
243         # This is also a fail
244         unshift @mess, "# range must not be negative\n";
245     } elsif ($range == 0) {
246         # Within 0 is ==
247         $pass = $got == $expected;
248     } elsif ($expected == 0) {
249         # If expected is 0, treat range as absolute
250         $pass = ($got <= $range) && ($got >= - $range);
251     } else {
252         my $diff = $got - $expected;
253         $pass = abs ($diff / $expected) < $range;
254     }
255     unless ($pass) {
256         if ($got eq $expected) {
257             unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
258         }
259         unshift@mess, "#      got "._q($got)."\n",
260                       "# expected "._q($expected)." (within "._q($range).")\n";
261     }
262     _ok($pass, _where(), $name, @mess);
263 }
264
265 # Note: this isn't quite as fancy as Test::More::like().
266
267 sub like   ($$@) { like_yn (0,@_) }; # 0 for -
268 sub unlike ($$@) { like_yn (1,@_) }; # 1 for un-
269
270 sub like_yn ($$$@) {
271     my ($flip, $got, $expected, $name, @mess) = @_;
272     my $pass;
273     $pass = $got =~ /$expected/ if !$flip;
274     $pass = $got !~ /$expected/ if $flip;
275     unless ($pass) {
276         unshift(@mess, "#      got '$got'\n",
277                 "# expected /$expected/\n");
278     }
279     local $Level = 2;
280     _ok($pass, _where(), $name, @mess);
281 }
282
283 sub pass {
284     _ok(1, '', @_);
285 }
286
287 sub fail {
288     _ok(0, _where(), @_);
289 }
290
291 sub curr_test {
292     $test = shift if @_;
293     return $test;
294 }
295
296 sub next_test {
297   $test = $test + 1; # don't use ++
298 }
299
300 # Note: can't pass multipart messages since we try to
301 # be compatible with Test::More::skip().
302 sub skip {
303     my $why = shift;
304     my $n    = @_ ? shift : 1;
305     for (1..$n) {
306         print STDOUT "ok $test # skip: $why\n";
307         $test = $test + 1;
308     }
309     local $^W = 0;
310     last SKIP;
311 }
312
313 sub todo_skip {
314     my $why = shift;
315     my $n   = @_ ? shift : 1;
316
317     for (1..$n) {
318         print STDOUT "not ok $test # TODO & SKIP: $why\n";
319         $test = $test + 1;
320     }
321     local $^W = 0;
322     last TODO;
323 }
324
325 sub eq_array {
326     my ($ra, $rb) = @_;
327     return 0 unless $#$ra == $#$rb;
328     for my $i (0..$#$ra) {
329         next     if !defined $ra->[$i] && !defined $rb->[$i];
330         return 0 if !defined $ra->[$i];
331         return 0 if !defined $rb->[$i];
332         return 0 unless $ra->[$i] eq $rb->[$i];
333     }
334     return 1;
335 }
336
337 sub eq_hash {
338   my ($orig, $suspect) = @_;
339   my $fail;
340   while (my ($key, $value) = each %$suspect) {
341     # Force a hash recompute if this perl's internals can cache the hash key.
342     $key = "" . $key;
343     if (exists $orig->{$key}) {
344       if ($orig->{$key} ne $value) {
345         print STDOUT "# key ", _qq($key), " was ", _qq($orig->{$key}),
346                      " now ", _qq($value), "\n";
347         $fail = 1;
348       }
349     } else {
350       print STDOUT "# key ", _qq($key), " is ", _qq($value),
351                    ", not in original.\n";
352       $fail = 1;
353     }
354   }
355   foreach (keys %$orig) {
356     # Force a hash recompute if this perl's internals can cache the hash key.
357     $_ = "" . $_;
358     next if (exists $suspect->{$_});
359     print STDOUT "# key ", _qq($_), " was ", _qq($orig->{$_}), " now missing.\n";
360     $fail = 1;
361   }
362   !$fail;
363 }
364
365 sub require_ok ($) {
366     my ($require) = @_;
367     eval <<REQUIRE_OK;
368 require $require;
369 REQUIRE_OK
370     _ok(!$@, _where(), "require $require");
371 }
372
373 sub use_ok ($) {
374     my ($use) = @_;
375     eval <<USE_OK;
376 use $use;
377 USE_OK
378     _ok(!$@, _where(), "use $use");
379 }
380
381 # runperl - Runs a separate perl interpreter.
382 # Arguments :
383 #   switches => [ command-line switches ]
384 #   nolib    => 1 # don't use -I../lib (included by default)
385 #   prog     => one-liner (avoid quotes)
386 #   progs    => [ multi-liner (avoid quotes) ]
387 #   progfile => perl script
388 #   stdin    => string to feed the stdin
389 #   stderr   => redirect stderr to stdout
390 #   args     => [ command-line arguments to the perl program ]
391 #   verbose  => print the command line
392
393 my $is_mswin    = $^O eq 'MSWin32';
394 my $is_netware  = $^O eq 'NetWare';
395 my $is_macos    = $^O eq 'MacOS';
396 my $is_vms      = $^O eq 'VMS';
397
398 sub _quote_args {
399     my ($runperl, $args) = @_;
400
401     foreach (@$args) {
402         # In VMS protect with doublequotes because otherwise
403         # DCL will lowercase -- unless already doublequoted.
404        $_ = q(").$_.q(") if $is_vms && !/^\"/ && length($_) > 0;
405         $$runperl .= ' ' . $_;
406     }
407 }
408
409 sub _create_runperl { # Create the string to qx in runperl().
410     my %args = @_;
411     my $runperl = $^X =~ m/\s/ ? qq{"$^X"} : $^X;
412     #- this allows, for example, to set PERL_RUNPERL_DEBUG=/usr/bin/valgrind
413     if ($ENV{PERL_RUNPERL_DEBUG}) {
414         $runperl = "$ENV{PERL_RUNPERL_DEBUG} $runperl";
415     }
416     unless ($args{nolib}) {
417         if ($is_macos) {
418             $runperl .= ' -I::lib';
419             # Use UNIX style error messages instead of MPW style.
420             $runperl .= ' -MMac::err=unix' if $args{stderr};
421         }
422         else {
423             $runperl .= ' "-I../lib"'; # doublequotes because of VMS
424         }
425     }
426     if ($args{switches}) {
427         local $Level = 2;
428         die "test.pl:runperl(): 'switches' must be an ARRAYREF " . _where()
429             unless ref $args{switches} eq "ARRAY";
430         _quote_args(\$runperl, $args{switches});
431     }
432     if (defined $args{prog}) {
433         die "test.pl:runperl(): both 'prog' and 'progs' cannot be used " . _where()
434             if defined $args{progs};
435         $args{progs} = [$args{prog}]
436     }
437     if (defined $args{progs}) {
438         die "test.pl:runperl(): 'progs' must be an ARRAYREF " . _where()
439             unless ref $args{progs} eq "ARRAY";
440         foreach my $prog (@{$args{progs}}) {
441             if ($is_mswin || $is_netware || $is_vms) {
442                 $runperl .= qq ( -e "$prog" );
443             }
444             else {
445                 $runperl .= qq ( -e '$prog' );
446             }
447         }
448     } elsif (defined $args{progfile}) {
449         $runperl .= qq( "$args{progfile}");
450     } else {
451         # You probaby didn't want to be sucking in from the upstream stdin
452         die "test.pl:runperl(): none of prog, progs, progfile, args, "
453             . " switches or stdin specified"
454             unless defined $args{args} or defined $args{switches}
455                 or defined $args{stdin};
456     }
457     if (defined $args{stdin}) {
458         # so we don't try to put literal newlines and crs onto the
459         # command line.
460         $args{stdin} =~ s/\n/\\n/g;
461         $args{stdin} =~ s/\r/\\r/g;
462
463         if ($is_mswin || $is_netware || $is_vms) {
464             $runperl = qq{$^X -e "print qq(} .
465                 $args{stdin} . q{)" | } . $runperl;
466         }
467         elsif ($is_macos) {
468             # MacOS can only do two processes under MPW at once;
469             # the test itself is one; we can't do two more, so
470             # write to temp file
471             my $stdin = qq{$^X -e 'print qq(} . $args{stdin} . qq{)' > teststdin; };
472             if ($args{verbose}) {
473                 my $stdindisplay = $stdin;
474                 $stdindisplay =~ s/\n/\n\#/g;
475                 print STDERR "# $stdindisplay\n";
476             }
477             `$stdin`;
478             $runperl .= q{ < teststdin };
479         }
480         else {
481             $runperl = qq{$^X -e 'print qq(} .
482                 $args{stdin} . q{)' | } . $runperl;
483         }
484     }
485     if (defined $args{args}) {
486         _quote_args(\$runperl, $args{args});
487     }
488     $runperl .= ' 2>&1'          if  $args{stderr} && !$is_macos;
489     $runperl .= " \xB3 Dev:Null" if !$args{stderr} &&  $is_macos;
490     if ($args{verbose}) {
491         my $runperldisplay = $runperl;
492         $runperldisplay =~ s/\n/\n\#/g;
493         print STDERR "# $runperldisplay\n";
494     }
495     return $runperl;
496 }
497
498 sub runperl {
499     die "test.pl:runperl() does not take a hashref"
500         if ref $_[0] and ref $_[0] eq 'HASH';
501     my $runperl = &_create_runperl;
502     my $result;
503
504     my $tainted = ${^TAINT};
505     my %args = @_;
506     exists $args{switches} && grep m/^-T$/, @{$args{switches}} and $tainted = $tainted + 1;
507
508     if ($tainted) {
509         # We will assume that if you're running under -T, you really mean to
510         # run a fresh perl, so we'll brute force launder everything for you
511         my $sep;
512
513         eval "require Config; Config->import";
514         if ($@) {
515             warn "test.pl had problems loading Config: $@";
516             $sep = ':';
517         } else {
518             $sep = $Config{path_sep};
519         }
520
521         my @keys = grep {exists $ENV{$_}} qw(CDPATH IFS ENV BASH_ENV);
522         local @ENV{@keys} = ();
523         # Untaint, plus take out . and empty string:
524         $ENV{PATH} =~ /(.*)/s;
525         local $ENV{PATH} =
526             join $sep, grep { $_ ne "" and $_ ne "." and
527                 ($is_mswin or !(stat && (stat _)[2]&0022)) }
528                     split quotemeta ($sep), $1;
529
530         $runperl =~ /(.*)/s;
531         $runperl = $1;
532
533         $result = `$runperl`;
534     } else {
535         $result = `$runperl`;
536     }
537     $result =~ s/\n\n/\n/ if $is_vms; # XXX pipes sometimes double these
538     return $result;
539 }
540
541 *run_perl = \&runperl; # Nice alias.
542
543 sub DIE {
544     print STDERR "# @_\n";
545     exit 1;
546 }
547
548 # A somewhat safer version of the sometimes wrong $^X.
549 my $Perl;
550 sub which_perl {
551     unless (defined $Perl) {
552         $Perl = $^X;
553
554         # VMS should have 'perl' aliased properly
555         return $Perl if $^O eq 'VMS';
556
557         my $exe;
558         eval "require Config; Config->import";
559         if ($@) {
560             warn "test.pl had problems loading Config: $@";
561             $exe = '';
562         } else {
563             $exe = $Config{_exe};
564         }
565        $exe = '' unless defined $exe;
566
567         # This doesn't absolutize the path: beware of future chdirs().
568         # We could do File::Spec->abs2rel() but that does getcwd()s,
569         # which is a bit heavyweight to do here.
570
571         if ($Perl =~ /^perl\Q$exe\E$/i) {
572             my $perl = "perl$exe";
573             eval "require File::Spec";
574             if ($@) {
575                 warn "test.pl had problems loading File::Spec: $@";
576                 $Perl = "./$perl";
577             } else {
578                 $Perl = File::Spec->catfile(File::Spec->curdir(), $perl);
579             }
580         }
581
582         # Build up the name of the executable file from the name of
583         # the command.
584
585         if ($Perl !~ /\Q$exe\E$/i) {
586             $Perl .= $exe;
587         }
588
589         warn "which_perl: cannot find $Perl from $^X" unless -f $Perl;
590
591         # For subcommands to use.
592         $ENV{PERLEXE} = $Perl;
593     }
594     return $Perl;
595 }
596
597 sub unlink_all {
598     foreach my $file (@_) {
599         1 while unlink $file;
600         print STDERR "# Couldn't unlink '$file': $!\n" if -f $file;
601     }
602 }
603
604
605 my $tmpfile = "misctmp000";
606 1 while -f ++$tmpfile;
607 END { unlink_all $tmpfile }
608
609 #
610 # _fresh_perl
611 #
612 # The $resolve must be a subref that tests the first argument
613 # for success, or returns the definition of success (e.g. the
614 # expected scalar) if given no arguments.
615 #
616
617 sub _fresh_perl {
618     my($prog, $resolve, $runperl_args, $name) = @_;
619
620     $runperl_args ||= {};
621     $runperl_args->{progfile} = $tmpfile;
622     $runperl_args->{stderr} = 1;
623
624     open TEST, ">$tmpfile" or die "Cannot open $tmpfile: $!";
625
626     # VMS adjustments
627     if( $^O eq 'VMS' ) {
628         $prog =~ s#/dev/null#NL:#;
629
630         # VMS file locking
631         $prog =~ s{if \(-e _ and -f _ and -r _\)}
632                   {if (-e _ and -f _)}
633     }
634
635     print TEST $prog;
636     close TEST or die "Cannot close $tmpfile: $!";
637
638     my $results = runperl(%$runperl_args);
639     my $status = $?;
640
641     # Clean up the results into something a bit more predictable.
642     $results =~ s/\n+$//;
643     $results =~ s/at\s+misctmp\d+\s+line/at - line/g;
644     $results =~ s/of\s+misctmp\d+\s+aborted/of - aborted/g;
645
646     # bison says 'parse error' instead of 'syntax error',
647     # various yaccs may or may not capitalize 'syntax'.
648     $results =~ s/^(syntax|parse) error/syntax error/mig;
649
650     if ($^O eq 'VMS') {
651         # some tests will trigger VMS messages that won't be expected
652         $results =~ s/\n?%[A-Z]+-[SIWEF]-[A-Z]+,.*//;
653
654         # pipes double these sometimes
655         $results =~ s/\n\n/\n/g;
656     }
657
658     my $pass = $resolve->($results);
659     unless ($pass) {
660         _diag "# PROG: \n$prog\n";
661         _diag "# EXPECTED:\n", $resolve->(), "\n";
662         _diag "# GOT:\n$results\n";
663         _diag "# STATUS: $status\n";
664     }
665
666     # Use the first line of the program as a name if none was given
667     unless( $name ) {
668         ($first_line, $name) = $prog =~ /^((.{1,50}).*)/;
669         $name .= '...' if length $first_line > length $name;
670     }
671
672     _ok($pass, _where(), "fresh_perl - $name");
673 }
674
675 #
676 # fresh_perl_is
677 #
678 # Combination of run_perl() and is().
679 #
680
681 sub fresh_perl_is {
682     my($prog, $expected, $runperl_args, $name) = @_;
683     local $Level = 2;
684     _fresh_perl($prog,
685                 sub { @_ ? $_[0] eq $expected : $expected },
686                 $runperl_args, $name);
687 }
688
689 #
690 # fresh_perl_like
691 #
692 # Combination of run_perl() and like().
693 #
694
695 sub fresh_perl_like {
696     my($prog, $expected, $runperl_args, $name) = @_;
697     local $Level = 2;
698     _fresh_perl($prog,
699                 sub { @_ ?
700                           $_[0] =~ (ref $expected ? $expected : /$expected/) :
701                           $expected },
702                 $runperl_args, $name);
703 }
704
705 sub can_ok ($@) {
706     my($proto, @methods) = @_;
707     my $class = ref $proto || $proto;
708
709     unless( @methods ) {
710         return _ok( 0, _where(), "$class->can(...)" );
711     }
712
713     my @nok = ();
714     foreach my $method (@methods) {
715         local($!, $@);  # don't interfere with caller's $@
716                         # eval sometimes resets $!
717         eval { $proto->can($method) } || push @nok, $method;
718     }
719
720     my $name;
721     $name = @methods == 1 ? "$class->can('$methods[0]')"
722                           : "$class->can(...)";
723
724     _ok( !@nok, _where(), $name );
725 }
726
727 sub isa_ok ($$;$) {
728     my($object, $class, $obj_name) = @_;
729
730     my $diag;
731     $obj_name = 'The object' unless defined $obj_name;
732     my $name = "$obj_name isa $class";
733     if( !defined $object ) {
734         $diag = "$obj_name isn't defined";
735     }
736     elsif( !ref $object ) {
737         $diag = "$obj_name isn't a reference";
738     }
739     else {
740         # We can't use UNIVERSAL::isa because we want to honor isa() overrides
741         local($@, $!);  # eval sometimes resets $!
742         my $rslt = eval { $object->isa($class) };
743         if( $@ ) {
744             if( $@ =~ /^Can't call method "isa" on unblessed reference/ ) {
745                 if( !UNIVERSAL::isa($object, $class) ) {
746                     my $ref = ref $object;
747                     $diag = "$obj_name isn't a '$class' it's a '$ref'";
748                 }
749             } else {
750                 die <<WHOA;
751 WHOA! I tried to call ->isa on your object and got some weird error.
752 This should never happen.  Please contact the author immediately.
753 Here's the error.
754 $@
755 WHOA
756             }
757         }
758         elsif( !$rslt ) {
759             my $ref = ref $object;
760             $diag = "$obj_name isn't a '$class' it's a '$ref'";
761         }
762     }
763
764     _ok( !$diag, _where(), $name );
765 }
766
767 1;