This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Add Unicode property wildcards
[perl5.git] / pod / perlrecharclass.pod
1 =head1 NAME
2 X<character class>
3
4 perlrecharclass - Perl Regular Expression Character Classes
5
6 =head1 DESCRIPTION
7
8 The top level documentation about Perl regular expressions
9 is found in L<perlre>.
10
11 This manual page discusses the syntax and use of character
12 classes in Perl regular expressions.
13
14 A character class is a way of denoting a set of characters
15 in such a way that one character of the set is matched.
16 It's important to remember that: matching a character class
17 consumes exactly one character in the source string. (The source
18 string is the string the regular expression is matched against.)
19
20 There are three types of character classes in Perl regular
21 expressions: the dot, backslash sequences, and the form enclosed in square
22 brackets.  Keep in mind, though, that often the term "character class" is used
23 to mean just the bracketed form.  Certainly, most Perl documentation does that.
24
25 =head2 The dot
26
27 The dot (or period), C<.> is probably the most used, and certainly
28 the most well-known character class. By default, a dot matches any
29 character, except for the newline. That default can be changed to
30 add matching the newline by using the I<single line> modifier:
31 for the entire regular expression with the C</s> modifier, or
32 locally with C<(?s)>  (and even globally within the scope of
33 L<C<use re '/s'>|re/'E<sol>flags' mode>).  (The C<L</\N>> backslash
34 sequence, described
35 below, matches any character except newline without regard to the
36 I<single line> modifier.)
37
38 Here are some examples:
39
40  "a"  =~  /./       # Match
41  "."  =~  /./       # Match
42  ""   =~  /./       # No match (dot has to match a character)
43  "\n" =~  /./       # No match (dot does not match a newline)
44  "\n" =~  /./s      # Match (global 'single line' modifier)
45  "\n" =~  /(?s:.)/  # Match (local 'single line' modifier)
46  "ab" =~  /^.$/     # No match (dot matches one character)
47
48 =head2 Backslash sequences
49 X<\w> X<\W> X<\s> X<\S> X<\d> X<\D> X<\p> X<\P>
50 X<\N> X<\v> X<\V> X<\h> X<\H>
51 X<word> X<whitespace>
52
53 A backslash sequence is a sequence of characters, the first one of which is a
54 backslash.  Perl ascribes special meaning to many such sequences, and some of
55 these are character classes.  That is, they match a single character each,
56 provided that the character belongs to the specific set of characters defined
57 by the sequence.
58
59 Here's a list of the backslash sequences that are character classes.  They
60 are discussed in more detail below.  (For the backslash sequences that aren't
61 character classes, see L<perlrebackslash>.)
62
63  \d             Match a decimal digit character.
64  \D             Match a non-decimal-digit character.
65  \w             Match a "word" character.
66  \W             Match a non-"word" character.
67  \s             Match a whitespace character.
68  \S             Match a non-whitespace character.
69  \h             Match a horizontal whitespace character.
70  \H             Match a character that isn't horizontal whitespace.
71  \v             Match a vertical whitespace character.
72  \V             Match a character that isn't vertical whitespace.
73  \N             Match a character that isn't a newline.
74  \pP, \p{Prop}  Match a character that has the given Unicode property.
75  \PP, \P{Prop}  Match a character that doesn't have the Unicode property
76
77 =head3 \N
78
79 C<\N>, available starting in v5.12, like the dot, matches any
80 character that is not a newline. The difference is that C<\N> is not influenced
81 by the I<single line> regular expression modifier (see L</The dot> above).  Note
82 that the form C<\N{...}> may mean something completely different.  When the
83 C<{...}> is a L<quantifier|perlre/Quantifiers>, it means to match a non-newline
84 character that many times.  For example, C<\N{3}> means to match 3
85 non-newlines; C<\N{5,}> means to match 5 or more non-newlines.  But if C<{...}>
86 is not a legal quantifier, it is presumed to be a named character.  See
87 L<charnames> for those.  For example, none of C<\N{COLON}>, C<\N{4F}>, and
88 C<\N{F4}> contain legal quantifiers, so Perl will try to find characters whose
89 names are respectively C<COLON>, C<4F>, and C<F4>.
90
91 =head3 Digits
92
93 C<\d> matches a single character considered to be a decimal I<digit>.
94 If the C</a> regular expression modifier is in effect, it matches [0-9].
95 Otherwise, it
96 matches anything that is matched by C<\p{Digit}>, which includes [0-9].
97 (An unlikely possible exception is that under locale matching rules, the
98 current locale might not have C<[0-9]> matched by C<\d>, and/or might match
99 other characters whose code point is less than 256.  The only such locale
100 definitions that are legal would be to match C<[0-9]> plus another set of
101 10 consecutive digit characters;  anything else would be in violation of
102 the C language standard, but Perl doesn't currently assume anything in
103 regard to this.)
104
105 What this means is that unless the C</a> modifier is in effect C<\d> not
106 only matches the digits '0' - '9', but also Arabic, Devanagari, and
107 digits from other languages.  This may cause some confusion, and some
108 security issues.
109
110 Some digits that C<\d> matches look like some of the [0-9] ones, but
111 have different values.  For example, BENGALI DIGIT FOUR (U+09EA) looks
112 very much like an ASCII DIGIT EIGHT (U+0038), and LEPCHA DIGIT SIX
113 (U+1C46) looks very much like an ASCII DIGIT FIVE (U+0035).  An
114 application that
115 is expecting only the ASCII digits might be misled, or if the match is
116 C<\d+>, the matched string might contain a mixture of digits from
117 different writing systems that look like they signify a number different
118 than they actually do.  L<Unicode::UCD/num()> can
119 be used to safely
120 calculate the value, returning C<undef> if the input string contains
121 such a mixture.  Otherwise, for example, a displayed price might be
122 deliberately different than it appears.
123
124 What C<\p{Digit}> means (and hence C<\d> except under the C</a>
125 modifier) is C<\p{General_Category=Decimal_Number}>, or synonymously,
126 C<\p{General_Category=Digit}>.  Starting with Unicode version 4.1, this
127 is the same set of characters matched by C<\p{Numeric_Type=Decimal}>.
128 But Unicode also has a different property with a similar name,
129 C<\p{Numeric_Type=Digit}>, which matches a completely different set of
130 characters.  These characters are things such as C<CIRCLED DIGIT ONE>
131 or subscripts, or are from writing systems that lack all ten digits.
132
133 The design intent is for C<\d> to exactly match the set of characters
134 that can safely be used with "normal" big-endian positional decimal
135 syntax, where, for example 123 means one 'hundred', plus two 'tens',
136 plus three 'ones'.  This positional notation does not necessarily apply
137 to characters that match the other type of "digit",
138 C<\p{Numeric_Type=Digit}>, and so C<\d> doesn't match them.
139
140 The Tamil digits (U+0BE6 - U+0BEF) can also legally be
141 used in old-style Tamil numbers in which they would appear no more than
142 one in a row, separated by characters that mean "times 10", "times 100",
143 etc.  (See L<http://www.unicode.org/notes/tn21>.)
144
145 Any character not matched by C<\d> is matched by C<\D>.
146
147 =head3 Word characters
148
149 A C<\w> matches a single alphanumeric character (an alphabetic character, or a
150 decimal digit); or a connecting punctuation character, such as an
151 underscore ("_"); or a "mark" character (like some sort of accent) that
152 attaches to one of those.  It does not match a whole word.  To match a
153 whole word, use C<\w+>.  This isn't the same thing as matching an
154 English word, but in the ASCII range it is the same as a string of
155 Perl-identifier characters.
156
157 =over
158
159 =item If the C</a> modifier is in effect ...
160
161 C<\w> matches the 63 characters [a-zA-Z0-9_].
162
163 =item otherwise ...
164
165 =over
166
167 =item For code points above 255 ...
168
169 C<\w> matches the same as C<\p{Word}> matches in this range.  That is,
170 it matches Thai letters, Greek letters, etc.  This includes connector
171 punctuation (like the underscore) which connect two words together, or
172 diacritics, such as a C<COMBINING TILDE> and the modifier letters, which
173 are generally used to add auxiliary markings to letters.
174
175 =item For code points below 256 ...
176
177 =over
178
179 =item if locale rules are in effect ...
180
181 C<\w> matches the platform's native underscore character plus whatever
182 the locale considers to be alphanumeric.
183
184 =item if, instead, Unicode rules are in effect ...
185
186 C<\w> matches exactly what C<\p{Word}> matches.
187
188 =item otherwise ...
189
190 C<\w> matches [a-zA-Z0-9_].
191
192 =back
193
194 =back
195
196 =back
197
198 Which rules apply are determined as described in L<perlre/Which character set modifier is in effect?>.
199
200 There are a number of security issues with the full Unicode list of word
201 characters.  See L<http://unicode.org/reports/tr36>.
202
203 Also, for a somewhat finer-grained set of characters that are in programming
204 language identifiers beyond the ASCII range, you may wish to instead use the
205 more customized L</Unicode Properties>, C<\p{ID_Start}>,
206 C<\p{ID_Continue}>, C<\p{XID_Start}>, and C<\p{XID_Continue}>.  See
207 L<http://unicode.org/reports/tr31>.
208
209 Any character not matched by C<\w> is matched by C<\W>.
210
211 =head3 Whitespace
212
213 C<\s> matches any single character considered whitespace.
214
215 =over
216
217 =item If the C</a> modifier is in effect ...
218
219 In all Perl versions, C<\s> matches the 5 characters [\t\n\f\r ]; that
220 is, the horizontal tab,
221 the newline, the form feed, the carriage return, and the space.
222 Starting in Perl v5.18, it also matches the vertical tab, C<\cK>.
223 See note C<[1]> below for a discussion of this.
224
225 =item otherwise ...
226
227 =over
228
229 =item For code points above 255 ...
230
231 C<\s> matches exactly the code points above 255 shown with an "s" column
232 in the table below.
233
234 =item For code points below 256 ...
235
236 =over
237
238 =item if locale rules are in effect ...
239
240 C<\s> matches whatever the locale considers to be whitespace.
241
242 =item if, instead, Unicode rules are in effect ...
243
244 C<\s> matches exactly the characters shown with an "s" column in the
245 table below.
246
247 =item otherwise ...
248
249 C<\s> matches [\t\n\f\r ] and, starting in Perl
250 v5.18, the vertical tab, C<\cK>.
251 (See note C<[1]> below for a discussion of this.)
252 Note that this list doesn't include the non-breaking space.
253
254 =back
255
256 =back
257
258 =back
259
260 Which rules apply are determined as described in L<perlre/Which character set modifier is in effect?>.
261
262 Any character not matched by C<\s> is matched by C<\S>.
263
264 C<\h> matches any character considered horizontal whitespace;
265 this includes the platform's space and tab characters and several others
266 listed in the table below.  C<\H> matches any character
267 not considered horizontal whitespace.  They use the platform's native
268 character set, and do not consider any locale that may otherwise be in
269 use.
270
271 C<\v> matches any character considered vertical whitespace;
272 this includes the platform's carriage return and line feed characters (newline)
273 plus several other characters, all listed in the table below.
274 C<\V> matches any character not considered vertical whitespace.
275 They use the platform's native character set, and do not consider any
276 locale that may otherwise be in use.
277
278 C<\R> matches anything that can be considered a newline under Unicode
279 rules. It can match a multi-character sequence. It cannot be used inside
280 a bracketed character class; use C<\v> instead (vertical whitespace).
281 It uses the platform's
282 native character set, and does not consider any locale that may
283 otherwise be in use.
284 Details are discussed in L<perlrebackslash>.
285
286 Note that unlike C<\s> (and C<\d> and C<\w>), C<\h> and C<\v> always match
287 the same characters, without regard to other factors, such as the active
288 locale or whether the source string is in UTF-8 format.
289
290 One might think that C<\s> is equivalent to C<[\h\v]>. This is indeed true
291 starting in Perl v5.18, but prior to that, the sole difference was that the
292 vertical tab (C<"\cK">) was not matched by C<\s>.
293
294 The following table is a complete listing of characters matched by
295 C<\s>, C<\h> and C<\v> as of Unicode 6.3.
296
297 The first column gives the Unicode code point of the character (in hex format),
298 the second column gives the (Unicode) name. The third column indicates
299 by which class(es) the character is matched (assuming no locale is in
300 effect that changes the C<\s> matching).
301
302  0x0009        CHARACTER TABULATION   h s
303  0x000a              LINE FEED (LF)    vs
304  0x000b             LINE TABULATION    vs  [1]
305  0x000c              FORM FEED (FF)    vs
306  0x000d        CARRIAGE RETURN (CR)    vs
307  0x0020                       SPACE   h s
308  0x0085             NEXT LINE (NEL)    vs  [2]
309  0x00a0              NO-BREAK SPACE   h s  [2]
310  0x1680            OGHAM SPACE MARK   h s
311  0x2000                     EN QUAD   h s
312  0x2001                     EM QUAD   h s
313  0x2002                    EN SPACE   h s
314  0x2003                    EM SPACE   h s
315  0x2004          THREE-PER-EM SPACE   h s
316  0x2005           FOUR-PER-EM SPACE   h s
317  0x2006            SIX-PER-EM SPACE   h s
318  0x2007                FIGURE SPACE   h s
319  0x2008           PUNCTUATION SPACE   h s
320  0x2009                  THIN SPACE   h s
321  0x200a                  HAIR SPACE   h s
322  0x2028              LINE SEPARATOR    vs
323  0x2029         PARAGRAPH SEPARATOR    vs
324  0x202f       NARROW NO-BREAK SPACE   h s
325  0x205f   MEDIUM MATHEMATICAL SPACE   h s
326  0x3000           IDEOGRAPHIC SPACE   h s
327
328 =over 4
329
330 =item [1]
331
332 Prior to Perl v5.18, C<\s> did not match the vertical tab.
333 C<[^\S\cK]> (obscurely) matches what C<\s> traditionally did.
334
335 =item [2]
336
337 NEXT LINE and NO-BREAK SPACE may or may not match C<\s> depending
338 on the rules in effect.  See
339 L<the beginning of this section|/Whitespace>.
340
341 =back
342
343 =head3 Unicode Properties
344
345 C<\pP> and C<\p{Prop}> are character classes to match characters that fit given
346 Unicode properties.  One letter property names can be used in the C<\pP> form,
347 with the property name following the C<\p>, otherwise, braces are required.
348 When using braces, there is a single form, which is just the property name
349 enclosed in the braces, and a compound form which looks like C<\p{name=value}>,
350 which means to match if the property "name" for the character has that particular
351 "value".
352 For instance, a match for a number can be written as C</\pN/> or as
353 C</\p{Number}/>, or as C</\p{Number=True}/>.
354 Lowercase letters are matched by the property I<Lowercase_Letter> which
355 has the short form I<Ll>. They need the braces, so are written as C</\p{Ll}/> or
356 C</\p{Lowercase_Letter}/>, or C</\p{General_Category=Lowercase_Letter}/>
357 (the underscores are optional).
358 C</\pLl/> is valid, but means something different.
359 It matches a two character string: a letter (Unicode property C<\pL>),
360 followed by a lowercase C<l>.
361
362 If locale rules are not in effect, the use of
363 a Unicode property will force the regular expression into using Unicode
364 rules, if it isn't already.
365
366 Note that almost all properties are immune to case-insensitive matching.
367 That is, adding a C</i> regular expression modifier does not change what
368 they match.  There are two sets that are affected.  The first set is
369 C<Uppercase_Letter>,
370 C<Lowercase_Letter>,
371 and C<Titlecase_Letter>,
372 all of which match C<Cased_Letter> under C</i> matching.
373 The second set is
374 C<Uppercase>,
375 C<Lowercase>,
376 and C<Titlecase>,
377 all of which match C<Cased> under C</i> matching.
378 (The difference between these sets is that some things, such as Roman
379 numerals, come in both upper and lower case, so they are C<Cased>, but
380 aren't considered to be letters, so they aren't C<Cased_Letter>s. They're
381 actually C<Letter_Number>s.)
382 This set also includes its subsets C<PosixUpper> and C<PosixLower>, both
383 of which under C</i> match C<PosixAlpha>.
384
385 For more details on Unicode properties, see L<perlunicode/Unicode
386 Character Properties>; for a
387 complete list of possible properties, see
388 L<perluniprops/Properties accessible through \p{} and \P{}>,
389 which notes all forms that have C</i> differences.
390 It is also possible to define your own properties. This is discussed in
391 L<perlunicode/User-Defined Character Properties>.
392
393 Unicode properties are defined (surprise!) only on Unicode code points.
394 Starting in v5.20, when matching against C<\p> and C<\P>, Perl treats
395 non-Unicode code points (those above the legal Unicode maximum of
396 0x10FFFF) as if they were typical unassigned Unicode code points.
397
398 Prior to v5.20, Perl raised a warning and made all matches fail on
399 non-Unicode code points.  This could be somewhat surprising:
400
401  chr(0x110000) =~ \p{ASCII_Hex_Digit=True}     # Fails on Perls < v5.20.
402  chr(0x110000) =~ \p{ASCII_Hex_Digit=False}    # Also fails on Perls
403                                                # < v5.20
404
405 Even though these two matches might be thought of as complements, until
406 v5.20 they were so only on Unicode code points.
407
408 Starting in perl v5.30, wildcards are allowed in Unicode property
409 values.  See L<perlunicode/Wildcards in Property Values>.
410
411 =head4 Examples
412
413  "a"  =~  /\w/      # Match, "a" is a 'word' character.
414  "7"  =~  /\w/      # Match, "7" is a 'word' character as well.
415  "a"  =~  /\d/      # No match, "a" isn't a digit.
416  "7"  =~  /\d/      # Match, "7" is a digit.
417  " "  =~  /\s/      # Match, a space is whitespace.
418  "a"  =~  /\D/      # Match, "a" is a non-digit.
419  "7"  =~  /\D/      # No match, "7" is not a non-digit.
420  " "  =~  /\S/      # No match, a space is not non-whitespace.
421
422  " "  =~  /\h/      # Match, space is horizontal whitespace.
423  " "  =~  /\v/      # No match, space is not vertical whitespace.
424  "\r" =~  /\v/      # Match, a return is vertical whitespace.
425
426  "a"  =~  /\pL/     # Match, "a" is a letter.
427  "a"  =~  /\p{Lu}/  # No match, /\p{Lu}/ matches upper case letters.
428
429  "\x{0e0b}" =~ /\p{Thai}/  # Match, \x{0e0b} is the character
430                            # 'THAI CHARACTER SO SO', and that's in
431                            # Thai Unicode class.
432  "a"  =~  /\P{Lao}/ # Match, as "a" is not a Laotian character.
433
434 It is worth emphasizing that C<\d>, C<\w>, etc, match single characters, not
435 complete numbers or words. To match a number (that consists of digits),
436 use C<\d+>; to match a word, use C<\w+>.  But be aware of the security
437 considerations in doing so, as mentioned above.
438
439 =head2 Bracketed Character Classes
440
441 The third form of character class you can use in Perl regular expressions
442 is the bracketed character class.  In its simplest form, it lists the characters
443 that may be matched, surrounded by square brackets, like this: C<[aeiou]>.
444 This matches one of C<a>, C<e>, C<i>, C<o> or C<u>.  Like the other
445 character classes, exactly one character is matched.* To match
446 a longer string consisting of characters mentioned in the character
447 class, follow the character class with a L<quantifier|perlre/Quantifiers>.  For
448 instance, C<[aeiou]+> matches one or more lowercase English vowels.
449
450 Repeating a character in a character class has no
451 effect; it's considered to be in the set only once.
452
453 Examples:
454
455  "e"  =~  /[aeiou]/        # Match, as "e" is listed in the class.
456  "p"  =~  /[aeiou]/        # No match, "p" is not listed in the class.
457  "ae" =~  /^[aeiou]$/      # No match, a character class only matches
458                            # a single character.
459  "ae" =~  /^[aeiou]+$/     # Match, due to the quantifier.
460
461  -------
462
463 * There are two exceptions to a bracketed character class matching a
464 single character only.  Each requires special handling by Perl to make
465 things work:
466
467 =over
468
469 =item *
470
471 When the class is to match caselessly under C</i> matching rules, and a
472 character that is explicitly mentioned inside the class matches a
473 multiple-character sequence caselessly under Unicode rules, the class
474 will also match that sequence.  For example, Unicode says that the
475 letter C<LATIN SMALL LETTER SHARP S> should match the sequence C<ss>
476 under C</i> rules.  Thus,
477
478  'ss' =~ /\A\N{LATIN SMALL LETTER SHARP S}\z/i             # Matches
479  'ss' =~ /\A[aeioust\N{LATIN SMALL LETTER SHARP S}]\z/i    # Matches
480
481 For this to happen, the class must not be inverted (see L</Negation>)
482 and the character must be explicitly specified, and not be part of a
483 multi-character range (not even as one of its endpoints).  (L</Character
484 Ranges> will be explained shortly.) Therefore,
485
486  'ss' =~ /\A[\0-\x{ff}]\z/ui       # Doesn't match
487  'ss' =~ /\A[\0-\N{LATIN SMALL LETTER SHARP S}]\z/ui   # No match
488  'ss' =~ /\A[\xDF-\xDF]\z/ui   # Matches on ASCII platforms, since
489                                # \xDF is LATIN SMALL LETTER SHARP S,
490                                # and the range is just a single
491                                # element
492
493 Note that it isn't a good idea to specify these types of ranges anyway.
494
495 =item *
496
497 Some names known to C<\N{...}> refer to a sequence of multiple characters,
498 instead of the usual single character.  When one of these is included in
499 the class, the entire sequence is matched.  For example,
500
501   "\N{TAMIL LETTER KA}\N{TAMIL VOWEL SIGN AU}"
502                               =~ / ^ [\N{TAMIL SYLLABLE KAU}]  $ /x;
503
504 matches, because C<\N{TAMIL SYLLABLE KAU}> is a named sequence
505 consisting of the two characters matched against.  Like the other
506 instance where a bracketed class can match multiple characters, and for
507 similar reasons, the class must not be inverted, and the named sequence
508 may not appear in a range, even one where it is both endpoints.  If
509 these happen, it is a fatal error if the character class is within the
510 scope of L<C<use re 'strict>|re/'strict' mode>, or within an extended
511 L<C<(?[...])>|/Extended Bracketed Character Classes> class; otherwise
512 only the first code point is used (with a C<regexp>-type warning
513 raised).
514
515 =back
516
517 =head3 Special Characters Inside a Bracketed Character Class
518
519 Most characters that are meta characters in regular expressions (that
520 is, characters that carry a special meaning like C<.>, C<*>, or C<(>) lose
521 their special meaning and can be used inside a character class without
522 the need to escape them. For instance, C<[()]> matches either an opening
523 parenthesis, or a closing parenthesis, and the parens inside the character
524 class don't group or capture.  Be aware that, unless the pattern is
525 evaluated in single-quotish context, variable interpolation will take
526 place before the bracketed class is parsed:
527
528  $, = "\t| ";
529  $a =~ m'[$,]';        # single-quotish: matches '$' or ','
530  $a =~ q{[$,]}'        # same
531  $a =~ m/[$,]/;        # double-quotish: matches "\t", "|", or " "
532
533 Characters that may carry a special meaning inside a character class are:
534 C<\>, C<^>, C<->, C<[> and C<]>, and are discussed below. They can be
535 escaped with a backslash, although this is sometimes not needed, in which
536 case the backslash may be omitted.
537
538 The sequence C<\b> is special inside a bracketed character class. While
539 outside the character class, C<\b> is an assertion indicating a point
540 that does not have either two word characters or two non-word characters
541 on either side, inside a bracketed character class, C<\b> matches a
542 backspace character.
543
544 The sequences
545 C<\a>,
546 C<\c>,
547 C<\e>,
548 C<\f>,
549 C<\n>,
550 C<\N{I<NAME>}>,
551 C<\N{U+I<hex char>}>,
552 C<\r>,
553 C<\t>,
554 and
555 C<\x>
556 are also special and have the same meanings as they do outside a
557 bracketed character class.
558
559 Also, a backslash followed by two or three octal digits is considered an octal
560 number.
561
562 A C<[> is not special inside a character class, unless it's the start of a
563 POSIX character class (see L</POSIX Character Classes> below). It normally does
564 not need escaping.
565
566 A C<]> is normally either the end of a POSIX character class (see
567 L</POSIX Character Classes> below), or it signals the end of the bracketed
568 character class.  If you want to include a C<]> in the set of characters, you
569 must generally escape it.
570
571 However, if the C<]> is the I<first> (or the second if the first
572 character is a caret) character of a bracketed character class, it
573 does not denote the end of the class (as you cannot have an empty class)
574 and is considered part of the set of characters that can be matched without
575 escaping.
576
577 Examples:
578
579  "+"   =~ /[+?*]/     #  Match, "+" in a character class is not special.
580  "\cH" =~ /[\b]/      #  Match, \b inside in a character class
581                       #  is equivalent to a backspace.
582  "]"   =~ /[][]/      #  Match, as the character class contains
583                       #  both [ and ].
584  "[]"  =~ /[[]]/      #  Match, the pattern contains a character class
585                       #  containing just [, and the character class is
586                       #  followed by a ].
587
588 =head3 Bracketed Character Classes and the C</xx> pattern modifier
589
590 Normally SPACE and TAB characters have no special meaning inside a
591 bracketed character class; they are just added to the list of characters
592 matched by the class.  But if the L<C</xx>|perlre/E<sol>x and E<sol>xx>
593 pattern modifier is in effect, they are generally ignored and can be
594 added to improve readability.  They can't be added in the middle of a
595 single construct:
596
597  / [ \x{10 FFFF} ] /xx  # WRONG!
598
599 The SPACE in the middle of the hex constant is illegal.
600
601 To specify a literal SPACE character, you can escape it with a
602 backslash, like:
603
604  /[ a e i o u \  ]/xx
605
606 This matches the English vowels plus the SPACE character.
607
608 For clarity, you should already have been using C<\t> to specify a
609 literal tab, and C<\t> is unaffected by C</xx>.
610
611 =head3 Character Ranges
612
613 It is not uncommon to want to match a range of characters. Luckily, instead
614 of listing all characters in the range, one may use the hyphen (C<->).
615 If inside a bracketed character class you have two characters separated
616 by a hyphen, it's treated as if all characters between the two were in
617 the class. For instance, C<[0-9]> matches any ASCII digit, and C<[a-m]>
618 matches any lowercase letter from the first half of the ASCII alphabet.
619
620 Note that the two characters on either side of the hyphen are not
621 necessarily both letters or both digits. Any character is possible,
622 although not advisable.  C<['-?]> contains a range of characters, but
623 most people will not know which characters that means.  Furthermore,
624 such ranges may lead to portability problems if the code has to run on
625 a platform that uses a different character set, such as EBCDIC.
626
627 If a hyphen in a character class cannot syntactically be part of a range, for
628 instance because it is the first or the last character of the character class,
629 or if it immediately follows a range, the hyphen isn't special, and so is
630 considered a character to be matched literally.  If you want a hyphen in
631 your set of characters to be matched and its position in the class is such
632 that it could be considered part of a range, you must escape that hyphen
633 with a backslash.
634
635 Examples:
636
637  [a-z]       #  Matches a character that is a lower case ASCII letter.
638  [a-fz]      #  Matches any letter between 'a' and 'f' (inclusive) or
639              #  the letter 'z'.
640  [-z]        #  Matches either a hyphen ('-') or the letter 'z'.
641  [a-f-m]     #  Matches any letter between 'a' and 'f' (inclusive), the
642              #  hyphen ('-'), or the letter 'm'.
643  ['-?]       #  Matches any of the characters  '()*+,-./0123456789:;<=>?
644              #  (But not on an EBCDIC platform).
645  [\N{APOSTROPHE}-\N{QUESTION MARK}]
646              #  Matches any of the characters  '()*+,-./0123456789:;<=>?
647              #  even on an EBCDIC platform.
648  [\N{U+27}-\N{U+3F}] # Same. (U+27 is "'", and U+3F is "?")
649
650 As the final two examples above show, you can achieve portability to
651 non-ASCII platforms by using the C<\N{...}> form for the range
652 endpoints.  These indicate that the specified range is to be interpreted
653 using Unicode values, so C<[\N{U+27}-\N{U+3F}]> means to match
654 C<\N{U+27}>, C<\N{U+28}>, C<\N{U+29}>, ..., C<\N{U+3D}>, C<\N{U+3E}>,
655 and C<\N{U+3F}>, whatever the native code point versions for those are.
656 These are called "Unicode" ranges.  If either end is of the C<\N{...}>
657 form, the range is considered Unicode.  A C<regexp> warning is raised
658 under C<S<"use re 'strict'">> if the other endpoint is specified
659 non-portably:
660
661  [\N{U+00}-\x09]    # Warning under re 'strict'; \x09 is non-portable
662  [\N{U+00}-\t]      # No warning;
663
664 Both of the above match the characters C<\N{U+00}> C<\N{U+01}>, ...
665 C<\N{U+08}>, C<\N{U+09}>, but the C<\x09> looks like it could be a
666 mistake so the warning is raised (under C<re 'strict'>) for it.
667
668 Perl also guarantees that the ranges C<A-Z>, C<a-z>, C<0-9>, and any
669 subranges of these match what an English-only speaker would expect them
670 to match on any platform.  That is, C<[A-Z]> matches the 26 ASCII
671 uppercase letters;
672 C<[a-z]> matches the 26 lowercase letters; and C<[0-9]> matches the 10
673 digits.  Subranges, like C<[h-k]>, match correspondingly, in this case
674 just the four letters C<"h">, C<"i">, C<"j">, and C<"k">.  This is the
675 natural behavior on ASCII platforms where the code points (ordinal
676 values) for C<"h"> through C<"k"> are consecutive integers (0x68 through
677 0x6B).  But special handling to achieve this may be needed on platforms
678 with a non-ASCII native character set.  For example, on EBCDIC
679 platforms, the code point for C<"h"> is 0x88, C<"i"> is 0x89, C<"j"> is
680 0x91, and C<"k"> is 0x92.   Perl specially treats C<[h-k]> to exclude the
681 seven code points in the gap: 0x8A through 0x90.  This special handling is
682 only invoked when the range is a subrange of one of the ASCII uppercase,
683 lowercase, and digit ranges, AND each end of the range is expressed
684 either as a literal, like C<"A">, or as a named character (C<\N{...}>,
685 including the C<\N{U+...> form).
686
687 EBCDIC Examples:
688
689  [i-j]               #  Matches either "i" or "j"
690  [i-\N{LATIN SMALL LETTER J}]  # Same
691  [i-\N{U+6A}]        #  Same
692  [\N{U+69}-\N{U+6A}] #  Same
693  [\x{89}-\x{91}]     #  Matches 0x89 ("i"), 0x8A .. 0x90, 0x91 ("j")
694  [i-\x{91}]          #  Same
695  [\x{89}-j]          #  Same
696  [i-J]               #  Matches, 0x89 ("i") .. 0xC1 ("J"); special
697                      #  handling doesn't apply because range is mixed
698                      #  case
699
700 =head3 Negation
701
702 It is also possible to instead list the characters you do not want to
703 match. You can do so by using a caret (C<^>) as the first character in the
704 character class. For instance, C<[^a-z]> matches any character that is not a
705 lowercase ASCII letter, which therefore includes more than a million
706 Unicode code points.  The class is said to be "negated" or "inverted".
707
708 This syntax make the caret a special character inside a bracketed character
709 class, but only if it is the first character of the class. So if you want
710 the caret as one of the characters to match, either escape the caret or
711 else don't list it first.
712
713 In inverted bracketed character classes, Perl ignores the Unicode rules
714 that normally say that named sequence, and certain characters should
715 match a sequence of multiple characters use under caseless C</i>
716 matching.  Following those rules could lead to highly confusing
717 situations:
718
719  "ss" =~ /^[^\xDF]+$/ui;   # Matches!
720
721 This should match any sequences of characters that aren't C<\xDF> nor
722 what C<\xDF> matches under C</i>.  C<"s"> isn't C<\xDF>, but Unicode
723 says that C<"ss"> is what C<\xDF> matches under C</i>.  So which one
724 "wins"? Do you fail the match because the string has C<ss> or accept it
725 because it has an C<s> followed by another C<s>?  Perl has chosen the
726 latter.  (See note in L</Bracketed Character Classes> above.)
727
728 Examples:
729
730  "e"  =~  /[^aeiou]/   #  No match, the 'e' is listed.
731  "x"  =~  /[^aeiou]/   #  Match, as 'x' isn't a lowercase vowel.
732  "^"  =~  /[^^]/       #  No match, matches anything that isn't a caret.
733  "^"  =~  /[x^]/       #  Match, caret is not special here.
734
735 =head3 Backslash Sequences
736
737 You can put any backslash sequence character class (with the exception of
738 C<\N> and C<\R>) inside a bracketed character class, and it will act just
739 as if you had put all characters matched by the backslash sequence inside the
740 character class. For instance, C<[a-f\d]> matches any decimal digit, or any
741 of the lowercase letters between 'a' and 'f' inclusive.
742
743 C<\N> within a bracketed character class must be of the forms C<\N{I<name>}>
744 or C<\N{U+I<hex char>}>, and NOT be the form that matches non-newlines,
745 for the same reason that a dot C<.> inside a bracketed character class loses
746 its special meaning: it matches nearly anything, which generally isn't what you
747 want to happen.
748
749
750 Examples:
751
752  /[\p{Thai}\d]/     # Matches a character that is either a Thai
753                     # character, or a digit.
754  /[^\p{Arabic}()]/  # Matches a character that is neither an Arabic
755                     # character, nor a parenthesis.
756
757 Backslash sequence character classes cannot form one of the endpoints
758 of a range.  Thus, you can't say:
759
760  /[\p{Thai}-\d]/     # Wrong!
761
762 =head3 POSIX Character Classes
763 X<character class> X<\p> X<\p{}>
764 X<alpha> X<alnum> X<ascii> X<blank> X<cntrl> X<digit> X<graph>
765 X<lower> X<print> X<punct> X<space> X<upper> X<word> X<xdigit>
766
767 POSIX character classes have the form C<[:class:]>, where I<class> is the
768 name, and the C<[:> and C<:]> delimiters. POSIX character classes only appear
769 I<inside> bracketed character classes, and are a convenient and descriptive
770 way of listing a group of characters.
771
772 Be careful about the syntax,
773
774  # Correct:
775  $string =~ /[[:alpha:]]/
776
777  # Incorrect (will warn):
778  $string =~ /[:alpha:]/
779
780 The latter pattern would be a character class consisting of a colon,
781 and the letters C<a>, C<l>, C<p> and C<h>.
782
783 POSIX character classes can be part of a larger bracketed character class.
784 For example,
785
786  [01[:alpha:]%]
787
788 is valid and matches '0', '1', any alphabetic character, and the percent sign.
789
790 Perl recognizes the following POSIX character classes:
791
792  alpha  Any alphabetical character (e.g., [A-Za-z]).
793  alnum  Any alphanumeric character (e.g., [A-Za-z0-9]).
794  ascii  Any character in the ASCII character set.
795  blank  A GNU extension, equal to a space or a horizontal tab ("\t").
796  cntrl  Any control character.  See Note [2] below.
797  digit  Any decimal digit (e.g., [0-9]), equivalent to "\d".
798  graph  Any printable character, excluding a space.  See Note [3] below.
799  lower  Any lowercase character (e.g., [a-z]).
800  print  Any printable character, including a space.  See Note [4] below.
801  punct  Any graphical character excluding "word" characters.  Note [5].
802  space  Any whitespace character. "\s" including the vertical tab
803         ("\cK").
804  upper  Any uppercase character (e.g., [A-Z]).
805  word   A Perl extension (e.g., [A-Za-z0-9_]), equivalent to "\w".
806  xdigit Any hexadecimal digit (e.g., [0-9a-fA-F]).  Note [7].
807
808 Like the L<Unicode properties|/Unicode Properties>, most of the POSIX
809 properties match the same regardless of whether case-insensitive (C</i>)
810 matching is in effect or not.  The two exceptions are C<[:upper:]> and
811 C<[:lower:]>.  Under C</i>, they each match the union of C<[:upper:]> and
812 C<[:lower:]>.
813
814 Most POSIX character classes have two Unicode-style C<\p> property
815 counterparts.  (They are not official Unicode properties, but Perl extensions
816 derived from official Unicode properties.)  The table below shows the relation
817 between POSIX character classes and these counterparts.
818
819 One counterpart, in the column labelled "ASCII-range Unicode" in
820 the table, matches only characters in the ASCII character set.
821
822 The other counterpart, in the column labelled "Full-range Unicode", matches any
823 appropriate characters in the full Unicode character set.  For example,
824 C<\p{Alpha}> matches not just the ASCII alphabetic characters, but any
825 character in the entire Unicode character set considered alphabetic.
826 An entry in the column labelled "backslash sequence" is a (short)
827 equivalent.
828
829  [[:...:]]      ASCII-range          Full-range  backslash  Note
830                  Unicode              Unicode     sequence
831  -----------------------------------------------------
832    alpha      \p{PosixAlpha}       \p{XPosixAlpha}
833    alnum      \p{PosixAlnum}       \p{XPosixAlnum}
834    ascii      \p{ASCII}
835    blank      \p{PosixBlank}       \p{XPosixBlank}  \h      [1]
836                                    or \p{HorizSpace}        [1]
837    cntrl      \p{PosixCntrl}       \p{XPosixCntrl}          [2]
838    digit      \p{PosixDigit}       \p{XPosixDigit}  \d
839    graph      \p{PosixGraph}       \p{XPosixGraph}          [3]
840    lower      \p{PosixLower}       \p{XPosixLower}
841    print      \p{PosixPrint}       \p{XPosixPrint}          [4]
842    punct      \p{PosixPunct}       \p{XPosixPunct}          [5]
843               \p{PerlSpace}        \p{XPerlSpace}   \s      [6]
844    space      \p{PosixSpace}       \p{XPosixSpace}          [6]
845    upper      \p{PosixUpper}       \p{XPosixUpper}
846    word       \p{PosixWord}        \p{XPosixWord}   \w
847    xdigit     \p{PosixXDigit}      \p{XPosixXDigit}         [7]
848
849 =over 4
850
851 =item [1]
852
853 C<\p{Blank}> and C<\p{HorizSpace}> are synonyms.
854
855 =item [2]
856
857 Control characters don't produce output as such, but instead usually control
858 the terminal somehow: for example, newline and backspace are control characters.
859 On ASCII platforms, in the ASCII range, characters whose code points are
860 between 0 and 31 inclusive, plus 127 (C<DEL>) are control characters; on
861 EBCDIC platforms, their counterparts are control characters.
862
863 =item [3]
864
865 Any character that is I<graphical>, that is, visible. This class consists
866 of all alphanumeric characters and all punctuation characters.
867
868 =item [4]
869
870 All printable characters, which is the set of all graphical characters
871 plus those whitespace characters which are not also controls.
872
873 =item [5]
874
875 C<\p{PosixPunct}> and C<[[:punct:]]> in the ASCII range match all
876 non-controls, non-alphanumeric, non-space characters:
877 C<[-!"#$%&'()*+,./:;<=E<gt>?@[\\\]^_`{|}~]> (although if a locale is in effect,
878 it could alter the behavior of C<[[:punct:]]>).
879
880 The similarly named property, C<\p{Punct}>, matches a somewhat different
881 set in the ASCII range, namely
882 C<[-!"#%&'()*,./:;?@[\\\]_{}]>.  That is, it is missing the nine
883 characters C<[$+E<lt>=E<gt>^`|~]>.
884 This is because Unicode splits what POSIX considers to be punctuation into two
885 categories, Punctuation and Symbols.
886
887 C<\p{XPosixPunct}> and (under Unicode rules) C<[[:punct:]]>, match what
888 C<\p{PosixPunct}> matches in the ASCII range, plus what C<\p{Punct}>
889 matches.  This is different than strictly matching according to
890 C<\p{Punct}>.  Another way to say it is that
891 if Unicode rules are in effect, C<[[:punct:]]> matches all characters
892 that Unicode considers punctuation, plus all ASCII-range characters that
893 Unicode considers symbols.
894
895 =item [6]
896
897 C<\p{XPerlSpace}> and C<\p{Space}> match identically starting with Perl
898 v5.18.  In earlier versions, these differ only in that in non-locale
899 matching, C<\p{XPerlSpace}> did not match the vertical tab, C<\cK>.
900 Same for the two ASCII-only range forms.
901
902 =item [7]
903
904 Unlike C<[[:digit:]]> which matches digits in many writing systems, such
905 as Thai and Devanagari, there are currently only two sets of hexadecimal
906 digits, and it is unlikely that more will be added.  This is because you
907 not only need the ten digits, but also the six C<[A-F]> (and C<[a-f]>)
908 to correspond.  That means only the Latin script is suitable for these,
909 and Unicode has only two sets of these, the familiar ASCII set, and the
910 fullwidth forms starting at U+FF10 (FULLWIDTH DIGIT ZERO).
911
912 =back
913
914 There are various other synonyms that can be used besides the names
915 listed in the table.  For example, C<\p{XPosixAlpha}> can be written as
916 C<\p{Alpha}>.  All are listed in
917 L<perluniprops/Properties accessible through \p{} and \P{}>.
918
919 Both the C<\p> counterparts always assume Unicode rules are in effect.
920 On ASCII platforms, this means they assume that the code points from 128
921 to 255 are Latin-1, and that means that using them under locale rules is
922 unwise unless the locale is guaranteed to be Latin-1 or UTF-8.  In contrast, the
923 POSIX character classes are useful under locale rules.  They are
924 affected by the actual rules in effect, as follows:
925
926 =over
927
928 =item If the C</a> modifier, is in effect ...
929
930 Each of the POSIX classes matches exactly the same as their ASCII-range
931 counterparts.
932
933 =item otherwise ...
934
935 =over
936
937 =item For code points above 255 ...
938
939 The POSIX class matches the same as its Full-range counterpart.
940
941 =item For code points below 256 ...
942
943 =over
944
945 =item if locale rules are in effect ...
946
947 The POSIX class matches according to the locale, except:
948
949 =over
950
951 =item C<word>
952
953 also includes the platform's native underscore character, no matter what
954 the locale is.
955
956 =item C<ascii>
957
958 on platforms that don't have the POSIX C<ascii> extension, this matches
959 just the platform's native ASCII-range characters.
960
961 =item C<blank>
962
963 on platforms that don't have the POSIX C<blank> extension, this matches
964 just the platform's native tab and space characters.
965
966 =back
967
968 =item if, instead, Unicode rules are in effect ...
969
970 The POSIX class matches the same as the Full-range counterpart.
971
972 =item otherwise ...
973
974 The POSIX class matches the same as the ASCII range counterpart.
975
976 =back
977
978 =back
979
980 =back
981
982 Which rules apply are determined as described in
983 L<perlre/Which character set modifier is in effect?>.
984
985 =head4 Negation of POSIX character classes
986 X<character class, negation>
987
988 A Perl extension to the POSIX character class is the ability to
989 negate it. This is done by prefixing the class name with a caret (C<^>).
990 Some examples:
991
992      POSIX         ASCII-range     Full-range  backslash
993                     Unicode         Unicode    sequence
994  -----------------------------------------------------
995  [[:^digit:]]   \P{PosixDigit}  \P{XPosixDigit}   \D
996  [[:^space:]]   \P{PosixSpace}  \P{XPosixSpace}
997                 \P{PerlSpace}   \P{XPerlSpace}    \S
998  [[:^word:]]    \P{PerlWord}    \P{XPosixWord}    \W
999
1000 The backslash sequence can mean either ASCII- or Full-range Unicode,
1001 depending on various factors as described in L<perlre/Which character set modifier is in effect?>.
1002
1003 =head4 [= =] and [. .]
1004
1005 Perl recognizes the POSIX character classes C<[=class=]> and
1006 C<[.class.]>, but does not (yet?) support them.  Any attempt to use
1007 either construct raises an exception.
1008
1009 =head4 Examples
1010
1011  /[[:digit:]]/            # Matches a character that is a digit.
1012  /[01[:lower:]]/          # Matches a character that is either a
1013                           # lowercase letter, or '0' or '1'.
1014  /[[:digit:][:^xdigit:]]/ # Matches a character that can be anything
1015                           # except the letters 'a' to 'f' and 'A' to
1016                           # 'F'.  This is because the main character
1017                           # class is composed of two POSIX character
1018                           # classes that are ORed together, one that
1019                           # matches any digit, and the other that
1020                           # matches anything that isn't a hex digit.
1021                           # The OR adds the digits, leaving only the
1022                           # letters 'a' to 'f' and 'A' to 'F' excluded.
1023
1024 =head3 Extended Bracketed Character Classes
1025 X<character class>
1026 X<set operations>
1027
1028 This is a fancy bracketed character class that can be used for more
1029 readable and less error-prone classes, and to perform set operations,
1030 such as intersection. An example is
1031
1032  /(?[ \p{Thai} & \p{Digit} ])/
1033
1034 This will match all the digit characters that are in the Thai script.
1035
1036 This is an experimental feature available starting in 5.18, and is
1037 subject to change as we gain field experience with it.  Any attempt to
1038 use it will raise a warning, unless disabled via
1039
1040  no warnings "experimental::regex_sets";
1041
1042 Comments on this feature are welcome; send email to
1043 C<perl5-porters@perl.org>.
1044
1045 The rules used by L<C<use re 'strict>|re/'strict' mode> apply to this
1046 construct.
1047
1048 We can extend the example above:
1049
1050  /(?[ ( \p{Thai} + \p{Lao} ) & \p{Digit} ])/
1051
1052 This matches digits that are in either the Thai or Laotian scripts.
1053
1054 Notice the white space in these examples.  This construct always has
1055 the C<E<sol>xx> modifier turned on within it.
1056
1057 The available binary operators are:
1058
1059  &    intersection
1060  +    union
1061  |    another name for '+', hence means union
1062  -    subtraction (the result matches the set consisting of those
1063       code points matched by the first operand, excluding any that
1064       are also matched by the second operand)
1065  ^    symmetric difference (the union minus the intersection).  This
1066       is like an exclusive or, in that the result is the set of code
1067       points that are matched by either, but not both, of the
1068       operands.
1069
1070 There is one unary operator:
1071
1072  !    complement
1073
1074 All the binary operators left associate; C<"&"> is higher precedence
1075 than the others, which all have equal precedence.  The unary operator
1076 right associates, and has highest precedence.  Thus this follows the
1077 normal Perl precedence rules for logical operators.  Use parentheses to
1078 override the default precedence and associativity.
1079
1080 The main restriction is that everything is a metacharacter.  Thus,
1081 you cannot refer to single characters by doing something like this:
1082
1083  /(?[ a + b ])/ # Syntax error!
1084
1085 The easiest way to specify an individual typable character is to enclose
1086 it in brackets:
1087
1088  /(?[ [a] + [b] ])/
1089
1090 (This is the same thing as C<[ab]>.)  You could also have said the
1091 equivalent:
1092
1093  /(?[[ a b ]])/
1094
1095 (You can, of course, specify single characters by using, C<\x{...}>,
1096 C<\N{...}>, etc.)
1097
1098 This last example shows the use of this construct to specify an ordinary
1099 bracketed character class without additional set operations.  Note the
1100 white space within it.  This is allowed because C<E<sol>xx> is
1101 automatically turned on within this construct.
1102
1103 All the other escapes accepted by normal bracketed character classes are
1104 accepted here as well.
1105
1106 Because this construct compiles under
1107 L<C<use re 'strict>|re/'strict' mode>,  unrecognized escapes that
1108 generate warnings in normal classes are fatal errors here, as well as
1109 all other warnings from these class elements, as well as some
1110 practices that don't currently warn outside C<re 'strict'>.  For example
1111 you cannot say
1112
1113  /(?[ [ \xF ] ])/     # Syntax error!
1114
1115 You have to have two hex digits after a braceless C<\x> (use a leading
1116 zero to make two).  These restrictions are to lower the incidence of
1117 typos causing the class to not match what you thought it would.
1118
1119 If a regular bracketed character class contains a C<\p{}> or C<\P{}> and
1120 is matched against a non-Unicode code point, a warning may be
1121 raised, as the result is not Unicode-defined.  No such warning will come
1122 when using this extended form.
1123
1124 The final difference between regular bracketed character classes and
1125 these, is that it is not possible to get these to match a
1126 multi-character fold.  Thus,
1127
1128  /(?[ [\xDF] ])/iu
1129
1130 does not match the string C<ss>.
1131
1132 You don't have to enclose POSIX class names inside double brackets,
1133 hence both of the following work:
1134
1135  /(?[ [:word:] - [:lower:] ])/
1136  /(?[ [[:word:]] - [[:lower:]] ])/
1137
1138 Any contained POSIX character classes, including things like C<\w> and C<\D>
1139 respect the C<E<sol>a> (and C<E<sol>aa>) modifiers.
1140
1141 Note that C<< (?[ ]) >> is a regex-compile-time construct.  Any attempt
1142 to use something which isn't knowable at the time the containing regular
1143 expression is compiled is a fatal error.  In practice, this means
1144 just three limitations:
1145
1146 =over 4
1147
1148 =item 1
1149
1150 When compiled within the scope of C<use locale> (or the C<E<sol>l> regex
1151 modifier), this construct assumes that the execution-time locale will be
1152 a UTF-8 one, and the generated pattern always uses Unicode rules.  What
1153 gets matched or not thus isn't dependent on the actual runtime locale, so
1154 tainting is not enabled.  But a C<locale> category warning is raised
1155 if the runtime locale turns out to not be UTF-8.
1156
1157 =item 2
1158
1159 Any
1160 L<user-defined property|perlunicode/"User-Defined Character Properties">
1161 used must be already defined by the time the regular expression is
1162 compiled (but note that this construct can be used instead of such
1163 properties).
1164
1165 =item 3
1166
1167 A regular expression that otherwise would compile
1168 using C<E<sol>d> rules, and which uses this construct will instead
1169 use C<E<sol>u>.  Thus this construct tells Perl that you don't want
1170 C<E<sol>d> rules for the entire regular expression containing it.
1171
1172 =back
1173
1174 Note that skipping white space applies only to the interior of this
1175 construct.  There must not be any space between any of the characters
1176 that form the initial C<(?[>.  Nor may there be space between the
1177 closing C<])> characters.
1178
1179 Just as in all regular expressions, the pattern can be built up by
1180 including variables that are interpolated at regex compilation time.
1181 But its best to compile each sub-component.
1182
1183  my $thai_or_lao = qr/(?[ \p{Thai} + \p{Lao} ])/;
1184  my $lower = qr/(?[ \p{Lower} + \p{Digit} ])/;
1185
1186 When these are embedded in another pattern, what they match does not
1187 change, regardless of parenthesization or what modifiers are in effect
1188 in that outer pattern.  If you fail to compile the subcomponents, you
1189 can get some nasty surprises.  For example:
1190
1191  my $thai_or_lao = '\p{Thai} + \p{Lao}';
1192  ...
1193  qr/(?[ \p{Digit} & $thai_or_lao ])/;
1194
1195 compiles to
1196
1197  qr/(?[ \p{Digit} & \p{Thai} + \p{Lao} ])/;
1198
1199 But this does not have the effect that someone reading the source code
1200 would likely expect, as the intersection applies just to C<\p{Thai}>,
1201 excluding the Laotian.  Its best to compile the subcomponents, but you
1202 could also parenthesize the component pieces:
1203
1204  my $thai_or_lao = '( \p{Thai} + \p{Lao} )';
1205
1206 But any modifiers will still apply to all the components:
1207
1208  my $lower = '\p{Lower} + \p{Digit}';
1209  qr/(?[ \p{Greek} & $lower ])/i;
1210
1211 matches upper case things.  So just, compile the subcomponents, as
1212 illustrated above.
1213
1214 Due to the way that Perl parses things, your parentheses and brackets
1215 may need to be balanced, even including comments.  If you run into any
1216 examples, please send them to C<perlbug@perl.org>, so that we can have a
1217 concrete example for this man page.
1218
1219 We may change it so that things that remain legal uses in normal bracketed
1220 character classes might become illegal within this experimental
1221 construct.  One proposal, for example, is to forbid adjacent uses of the
1222 same character, as in C<(?[ [aa] ])>.  The motivation for such a change
1223 is that this usage is likely a typo, as the second "a" adds nothing.