This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Add Unicode property wildcards
[perl5.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.
9
10 If you haven't used regular expressions before, a tutorial introduction
11 is available in L<perlretut>.  If you know just a little about them,
12 a quick-start introduction is available in L<perlrequick>.
13
14 Except for L</The Basics> section, this page assumes you are familiar
15 with regular expression basics, like what is a "pattern", what does it
16 look like, and how it is basically used.  For a reference on how they
17 are used, plus various examples of the same, see discussions of C<m//>,
18 C<s///>, C<qr//> and C<"??"> in L<perlop/"Regexp Quote-Like Operators">.
19
20 New in v5.22, L<C<use re 'strict'>|re/'strict' mode> applies stricter
21 rules than otherwise when compiling regular expression patterns.  It can
22 find things that, while legal, may not be what you intended.
23
24 =head2 The Basics
25 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
26
27 Regular expressions are strings with the very particular syntax and
28 meaning described in this document and auxiliary documents referred to
29 by this one.  The strings are called "patterns".  Patterns are used to
30 determine if some other string, called the "target", has (or doesn't
31 have) the characteristics specified by the pattern.  We call this
32 "matching" the target string against the pattern.  Usually the match is
33 done by having the target be the first operand, and the pattern be the
34 second operand, of one of the two binary operators C<=~> and C<!~>,
35 listed in L<perlop/Binding Operators>; and the pattern will have been
36 converted from an ordinary string by one of the operators in
37 L<perlop/"Regexp Quote-Like Operators">, like so:
38
39  $foo =~ m/abc/
40
41 This evaluates to true if and only if the string in the variable C<$foo>
42 contains somewhere in it, the sequence of characters "a", "b", then "c".
43 (The C<=~ m>, or match operator, is described in
44 L<perlop/m/PATTERN/msixpodualngc>.)
45
46 Patterns that aren't already stored in some variable must be delimitted,
47 at both ends, by delimitter characters.  These are often, as in the
48 example above, forward slashes, and the typical way a pattern is written
49 in documentation is with those slashes.  In most cases, the delimitter
50 is the same character, fore and aft, but there are a few cases where a
51 character looks like it has a mirror-image mate, where the opening
52 version is the beginning delimiter, and the closing one is the ending
53 delimiter, like
54
55  $foo =~ m<abc>
56
57 Most times, the pattern is evaluated in double-quotish context, but it
58 is possible to choose delimiters to force single-quotish, like
59
60  $foo =~ m'abc'
61
62 If the pattern contains its delimiter within it, that delimiter must be
63 escaped.  Prefixing it with a backslash (I<e.g.>, C<"/foo\/bar/">)
64 serves this purpose.
65
66 Any single character in a pattern matches that same character in the
67 target string, unless the character is a I<metacharacter> with a special
68 meaning described in this document.  A sequence of non-metacharacters
69 matches the same sequence in the target string, as we saw above with
70 C<m/abc/>.
71
72 Only a few characters (all of them being ASCII punctuation characters)
73 are metacharacters.  The most commonly used one is a dot C<".">, which
74 normally matches almost any character (including a dot itself).
75
76 You can cause characters that normally function as metacharacters to be
77 interpreted literally by prefixing them with a C<"\">, just like the
78 pattern's delimiter must be escaped if it also occurs within the
79 pattern.  Thus, C<"\."> matches just a literal dot, C<"."> instead of
80 its normal meaning.  This means that the backslash is also a
81 metacharacter, so C<"\\"> matches a single C<"\">.  And a sequence that
82 contains an escaped metacharacter matches the same sequence (but without
83 the escape) in the target string.  So, the pattern C</blur\\fl/> would
84 match any target string that contains the sequence C<"blur\fl">.
85
86 The metacharacter C<"|"> is used to match one thing or another.  Thus
87
88  $foo =~ m/this|that/
89
90 is TRUE if and only if C<$foo> contains either the sequence C<"this"> or
91 the sequence C<"that">.  Like all metacharacters, prefixing the C<"|">
92 with a backslash makes it match the plain punctuation character; in its
93 case, the VERTICAL LINE.
94
95  $foo =~ m/this\|that/
96
97 is TRUE if and only if C<$foo> contains the sequence C<"this|that">.
98
99 You aren't limited to just a single C<"|">.
100
101  $foo =~ m/fee|fie|foe|fum/
102
103 is TRUE if and only if C<$foo> contains any of those 4 sequences from
104 the children's story "Jack and the Beanstalk".
105
106 As you can see, the C<"|"> binds less tightly than a sequence of
107 ordinary characters.  We can override this by using the grouping
108 metacharacters, the parentheses C<"("> and C<")">.
109
110  $foo =~ m/th(is|at) thing/
111
112 is TRUE if and only if C<$foo> contains either the sequence S<C<"this
113 thing">> or the sequence S<C<"that thing">>.  The portions of the string
114 that match the portions of the pattern enclosed in parentheses are
115 normally made available separately for use later in the pattern,
116 substitution, or program.  This is called "capturing", and it can get
117 complicated.  See L</Capture groups>.
118
119 The first alternative includes everything from the last pattern
120 delimiter (C<"(">, C<"(?:"> (described later), I<etc>. or the beginning
121 of the pattern) up to the first C<"|">, and the last alternative
122 contains everything from the last C<"|"> to the next closing pattern
123 delimiter.  That's why it's common practice to include alternatives in
124 parentheses: to minimize confusion about where they start and end.
125
126 Alternatives are tried from left to right, so the first
127 alternative found for which the entire expression matches, is the one that
128 is chosen. This means that alternatives are not necessarily greedy. For
129 example: when matching C<foo|foot> against C<"barefoot">, only the C<"foo">
130 part will match, as that is the first alternative tried, and it successfully
131 matches the target string. (This might not seem important, but it is
132 important when you are capturing matched text using parentheses.)
133
134 Besides taking away the special meaning of a metacharacter, a prefixed
135 backslash changes some letter and digit characters away from matching
136 just themselves to instead have special meaning.  These are called
137 "escape sequences", and all such are described in L<perlrebackslash>.  A
138 backslash sequence (of a letter or digit) that doesn't currently have
139 special meaning to Perl will raise a warning if warnings are enabled,
140 as those are reserved for potential future use.
141
142 One such sequence is C<\b>, which matches a boundary of some sort.
143 C<\b{wb}> and a few others give specialized types of boundaries.
144 (They are all described in detail starting at
145 L<perlrebackslash/\b{}, \b, \B{}, \B>.)  Note that these don't match
146 characters, but the zero-width spaces between characters.  They are an
147 example of a L<zero-width assertion|/Assertions>.  Consider again,
148
149  $foo =~ m/fee|fie|foe|fum/
150
151 It evaluates to TRUE if, besides those 4 words, any of the sequences
152 "feed", "field", "Defoe", "fume", and many others are in C<$foo>.  By
153 judicious use of C<\b> (or better (because it is designed to handle
154 natural language) C<\b{wb}>), we can make sure that only the Giant's
155 words are matched:
156
157  $foo =~ m/\b(fee|fie|foe|fum)\b/
158  $foo =~ m/\b{wb}(fee|fie|foe|fum)\b{wb}/
159
160 The final example shows that the characters C<"{"> and C<"}"> are
161 metacharacters.
162
163 Another use for escape sequences is to specify characters that cannot
164 (or which you prefer not to) be written literally.  These are described
165 in detail in L<perlrebackslash/Character Escapes>, but the next three
166 paragraphs briefly describe some of them.
167
168 Various control characters can be written in C language style: C<"\n">
169 matches a newline, C<"\t"> a tab, C<"\r"> a carriage return, C<"\f"> a
170 form feed, I<etc>.
171
172 More generally, C<\I<nnn>>, where I<nnn> is a string of three octal
173 digits, matches the character whose native code point is I<nnn>.  You
174 can easily run into trouble if you don't have exactly three digits.  So
175 always use three, or since Perl 5.14, you can use C<\o{...}> to specify
176 any number of octal digits.
177
178 Similarly, C<\xI<nn>>, where I<nn> are hexadecimal digits, matches the
179 character whose native ordinal is I<nn>.  Again, not using exactly two
180 digits is a recipe for disaster, but you can use C<\x{...}> to specify
181 any number of hex digits.
182
183 Besides being a metacharacter, the C<"."> is an example of a "character
184 class", something that can match any single character of a given set of
185 them.  In its case, the set is just about all possible characters.  Perl
186 predefines several character classes besides the C<".">; there is a
187 separate reference page about just these, L<perlrecharclass>.
188
189 You can define your own custom character classes, by putting into your
190 pattern in the appropriate place(s), a list of all the characters you
191 want in the set.  You do this by enclosing the list within C<[]> bracket
192 characters.  These are called "bracketed character classes" when we are
193 being precise, but often the word "bracketed" is dropped.  (Dropping it
194 usually doesn't cause confusion.)  This means that the C<"["> character
195 is another metacharacter.  It doesn't match anything just by itself; it
196 is used only to tell Perl that what follows it is a bracketed character
197 class.  If you want to match a literal left square bracket, you must
198 escape it, like C<"\[">.  The matching C<"]"> is also a metacharacter;
199 again it doesn't match anything by itself, but just marks the end of
200 your custom class to Perl.  It is an example of a "sometimes
201 metacharacter".  It isn't a metacharacter if there is no corresponding
202 C<"[">, and matches its literal self:
203
204  print "]" =~ /]/;  # prints 1
205
206 The list of characters within the character class gives the set of
207 characters matched by the class.  C<"[abc]"> matches a single "a" or "b"
208 or "c".  But if the first character after the C<"["> is C<"^">, the
209 class instead matches any character not in the list.  Within a list, the
210 C<"-"> character specifies a range of characters, so that C<a-z>
211 represents all characters between "a" and "z", inclusive.  If you want
212 either C<"-"> or C<"]"> itself to be a member of a class, put it at the
213 start of the list (possibly after a C<"^">), or escape it with a
214 backslash.  C<"-"> is also taken literally when it is at the end of the
215 list, just before the closing C<"]">.  (The following all specify the
216 same class of three characters: C<[-az]>, C<[az-]>, and C<[a\-z]>.  All
217 are different from C<[a-z]>, which specifies a class containing
218 twenty-six characters, even on EBCDIC-based character sets.)
219
220 There is lots more to bracketed character classes; full details are in
221 L<perlrecharclass/Bracketed Character Classes>.
222
223 =head3 Metacharacters
224 X<metacharacter>
225 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
226
227 L</The Basics> introduced some of the metacharacters.  This section
228 gives them all.  Most of them have the same meaning as in the I<egrep>
229 command.
230
231 Only the C<"\"> is always a metacharacter.  The others are metacharacters
232 just sometimes.  The following tables lists all of them, summarizes
233 their use, and gives the contexts where they are metacharacters.
234 Outside those contexts or if prefixed by a C<"\">, they match their
235 corresponding punctuation character.  In some cases, their meaning
236 varies depending on various pattern modifiers that alter the default
237 behaviors.  See L</Modifiers>.
238
239
240             PURPOSE                                  WHERE
241  \   Escape the next character                    Always, except when
242                                                   escaped by another \
243  ^   Match the beginning of the string            Not in []
244        (or line, if /m is used)
245  ^   Complement the [] class                      At the beginning of []
246  .   Match any single character except newline    Not in []
247        (under /s, includes newline)
248  $   Match the end of the string                  Not in [], but can
249        (or before newline at the end of the       mean interpolate a
250        string; or before any newline if /m is     scalar
251        used)
252  |   Alternation                                  Not in []
253  ()  Grouping                                     Not in []
254  [   Start Bracketed Character class              Not in []
255  ]   End Bracketed Character class                Only in [], and
256                                                     not first
257  *   Matches the preceding element 0 or more      Not in []
258        times
259  +   Matches the preceding element 1 or more      Not in []
260        times
261  ?   Matches the preceding element 0 or 1         Not in []
262        times
263  {   Starts a sequence that gives number(s)       Not in []
264        of times the preceding element can be
265        matched
266  {   when following certain escape sequences
267        starts a modifier to the meaning of the
268        sequence
269  }   End sequence started by {
270  -   Indicates a range                            Only in [] interior
271  #   Beginning of comment, extends to line end    Only with /x modifier
272
273 Notice that most of the metacharacters lose their special meaning when
274 they occur in a bracketed character class, except C<"^"> has a different
275 meaning when it is at the beginning of such a class.  And C<"-"> and C<"]">
276 are metacharacters only at restricted positions within bracketed
277 character classes; while C<"}"> is a metacharacter only when closing a
278 special construct started by C<"{">.
279
280 In double-quotish context, as is usually the case,  you need to be
281 careful about C<"$"> and the non-metacharacter C<"@">.  Those could
282 interpolate variables, which may or may not be what you intended.
283
284 These rules were designed for compactness of expression, rather than
285 legibility and maintainability.  The L</E<sol>x and E<sol>xx> pattern
286 modifiers allow you to insert white space to improve readability.  And
287 use of S<C<L<re 'strict'|re/'strict' mode>>> adds extra checking to
288 catch some typos that might silently compile into something unintended.
289
290 By default, the C<"^"> character is guaranteed to match only the
291 beginning of the string, the C<"$"> character only the end (or before the
292 newline at the end), and Perl does certain optimizations with the
293 assumption that the string contains only one line.  Embedded newlines
294 will not be matched by C<"^"> or C<"$">.  You may, however, wish to treat a
295 string as a multi-line buffer, such that the C<"^"> will match after any
296 newline within the string (except if the newline is the last character in
297 the string), and C<"$"> will match before any newline.  At the
298 cost of a little more overhead, you can do this by using the
299 L</C<E<sol>m>> modifier on the pattern match operator.  (Older programs
300 did this by setting C<$*>, but this option was removed in perl 5.10.)
301 X<^> X<$> X</m>
302
303 To simplify multi-line substitutions, the C<"."> character never matches a
304 newline unless you use the L<C<E<sol>s>|/s> modifier, which in effect tells
305 Perl to pretend the string is a single line--even if it isn't.
306 X<.> X</s>
307
308 =head2 Modifiers
309
310 =head3 Overview
311
312 The default behavior for matching can be changed, using various
313 modifiers.  Modifiers that relate to the interpretation of the pattern
314 are listed just below.  Modifiers that alter the way a pattern is used
315 by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
316 L<perlop/"Gory details of parsing quoted constructs">.
317
318 =over 4
319
320 =item B<C<m>>
321 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
322
323 Treat the string being matched against as multiple lines.  That is, change C<"^"> and C<"$"> from matching
324 the start of the string's first line and the end of its last line to
325 matching the start and end of each line within the string.
326
327 =item B<C<s>>
328 X</s> X<regex, single-line> X<regexp, single-line>
329 X<regular expression, single-line>
330
331 Treat the string as single line.  That is, change C<"."> to match any character
332 whatsoever, even a newline, which normally it would not match.
333
334 Used together, as C</ms>, they let the C<"."> match any character whatsoever,
335 while still allowing C<"^"> and C<"$"> to match, respectively, just after
336 and just before newlines within the string.
337
338 =item B<C<i>>
339 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
340 X<regular expression, case-insensitive>
341
342 Do case-insensitive pattern matching.  For example, "A" will match "a"
343 under C</i>.
344
345 If locale matching rules are in effect, the case map is taken from the
346 current
347 locale for code points less than 255, and from Unicode rules for larger
348 code points.  However, matches that would cross the Unicode
349 rules/non-Unicode rules boundary (ords 255/256) will not succeed, unless
350 the locale is a UTF-8 one.  See L<perllocale>.
351
352 There are a number of Unicode characters that match a sequence of
353 multiple characters under C</i>.  For example,
354 C<LATIN SMALL LIGATURE FI> should match the sequence C<fi>.  Perl is not
355 currently able to do this when the multiple characters are in the pattern and
356 are split between groupings, or when one or more are quantified.  Thus
357
358  "\N{LATIN SMALL LIGATURE FI}" =~ /fi/i;          # Matches
359  "\N{LATIN SMALL LIGATURE FI}" =~ /[fi][fi]/i;    # Doesn't match!
360  "\N{LATIN SMALL LIGATURE FI}" =~ /fi*/i;         # Doesn't match!
361
362  # The below doesn't match, and it isn't clear what $1 and $2 would
363  # be even if it did!!
364  "\N{LATIN SMALL LIGATURE FI}" =~ /(f)(i)/i;      # Doesn't match!
365
366 Perl doesn't match multiple characters in a bracketed
367 character class unless the character that maps to them is explicitly
368 mentioned, and it doesn't match them at all if the character class is
369 inverted, which otherwise could be highly confusing.  See
370 L<perlrecharclass/Bracketed Character Classes>, and
371 L<perlrecharclass/Negation>.
372
373 =item B<C<x>> and B<C<xx>>
374 X</x>
375
376 Extend your pattern's legibility by permitting whitespace and comments.
377 Details in L</E<sol>x and  E<sol>xx>
378
379 =item B<C<p>>
380 X</p> X<regex, preserve> X<regexp, preserve>
381
382 Preserve the string matched such that C<${^PREMATCH}>, C<${^MATCH}>, and
383 C<${^POSTMATCH}> are available for use after matching.
384
385 In Perl 5.20 and higher this is ignored. Due to a new copy-on-write
386 mechanism, C<${^PREMATCH}>, C<${^MATCH}>, and C<${^POSTMATCH}> will be available
387 after the match regardless of the modifier.
388
389 =item B<C<a>>, B<C<d>>, B<C<l>>, and B<C<u>>
390 X</a> X</d> X</l> X</u>
391
392 These modifiers, all new in 5.14, affect which character-set rules
393 (Unicode, I<etc>.) are used, as described below in
394 L</Character set modifiers>.
395
396 =item B<C<n>>
397 X</n> X<regex, non-capture> X<regexp, non-capture>
398 X<regular expression, non-capture>
399
400 Prevent the grouping metacharacters C<()> from capturing. This modifier,
401 new in 5.22, will stop C<$1>, C<$2>, I<etc>... from being filled in.
402
403   "hello" =~ /(hi|hello)/;   # $1 is "hello"
404   "hello" =~ /(hi|hello)/n;  # $1 is undef
405
406 This is equivalent to putting C<?:> at the beginning of every capturing group:
407
408   "hello" =~ /(?:hi|hello)/; # $1 is undef
409
410 C</n> can be negated on a per-group basis. Alternatively, named captures
411 may still be used.
412
413   "hello" =~ /(?-n:(hi|hello))/n;   # $1 is "hello"
414   "hello" =~ /(?<greet>hi|hello)/n; # $1 is "hello", $+{greet} is
415                                     # "hello"
416
417 =item Other Modifiers
418
419 There are a number of flags that can be found at the end of regular
420 expression constructs that are I<not> generic regular expression flags, but
421 apply to the operation being performed, like matching or substitution (C<m//>
422 or C<s///> respectively).
423
424 Flags described further in
425 L<perlretut/"Using regular expressions in Perl"> are:
426
427   c  - keep the current position during repeated matching
428   g  - globally match the pattern repeatedly in the string
429
430 Substitution-specific modifiers described in
431 L<perlop/"s/PATTERN/REPLACEMENT/msixpodualngcer"> are:
432
433   e  - evaluate the right-hand side as an expression
434   ee - evaluate the right side as a string then eval the result
435   o  - pretend to optimize your code, but actually introduce bugs
436   r  - perform non-destructive substitution and return the new value
437
438 =back
439
440 Regular expression modifiers are usually written in documentation
441 as I<e.g.>, "the C</x> modifier", even though the delimiter
442 in question might not really be a slash.  The modifiers C</imnsxadlup>
443 may also be embedded within the regular expression itself using
444 the C<(?...)> construct, see L</Extended Patterns> below.
445
446 =head3 Details on some modifiers
447
448 Some of the modifiers require more explanation than given in the
449 L</Overview> above.
450
451 =head4 C</x> and  C</xx>
452
453 A single C</x> tells
454 the regular expression parser to ignore most whitespace that is neither
455 backslashed nor within a bracketed character class.  You can use this to
456 break up your regular expression into more readable parts.
457 Also, the C<"#"> character is treated as a metacharacter introducing a
458 comment that runs up to the pattern's closing delimiter, or to the end
459 of the current line if the pattern extends onto the next line.  Hence,
460 this is very much like an ordinary Perl code comment.  (You can include
461 the closing delimiter within the comment only if you precede it with a
462 backslash, so be careful!)
463
464 Use of C</x> means that if you want real
465 whitespace or C<"#"> characters in the pattern (outside a bracketed character
466 class, which is unaffected by C</x>), then you'll either have to
467 escape them (using backslashes or C<\Q...\E>) or encode them using octal,
468 hex, or C<\N{}> escapes.
469 It is ineffective to try to continue a comment onto the next line by
470 escaping the C<\n> with a backslash or C<\Q>.
471
472 You can use L</(?#text)> to create a comment that ends earlier than the
473 end of the current line, but C<text> also can't contain the closing
474 delimiter unless escaped with a backslash.
475
476 A common pitfall is to forget that C<"#"> characters begin a comment under
477 C</x> and are not matched literally.  Just keep that in mind when trying
478 to puzzle out why a particular C</x> pattern isn't working as expected.
479
480 Starting in Perl v5.26, if the modifier has a second C<"x"> within it,
481 it does everything that a single C</x> does, but additionally
482 non-backslashed SPACE and TAB characters within bracketed character
483 classes are also generally ignored, and hence can be added to make the
484 classes more readable.
485
486     / [d-e g-i 3-7]/xx
487     /[ ! @ " # $ % ^ & * () = ? <> ' ]/xx
488
489 may be easier to grasp than the squashed equivalents
490
491     /[d-eg-i3-7]/
492     /[!@"#$%^&*()=?<>']/
493
494 Taken together, these features go a long way towards
495 making Perl's regular expressions more readable.  Here's an example:
496
497     # Delete (most) C comments.
498     $program =~ s {
499         /\*     # Match the opening delimiter.
500         .*?     # Match a minimal number of characters.
501         \*/     # Match the closing delimiter.
502     } []gsx;
503
504 Note that anything inside
505 a C<\Q...\E> stays unaffected by C</x>.  And note that C</x> doesn't affect
506 space interpretation within a single multi-character construct.  For
507 example in C<\x{...}>, regardless of the C</x> modifier, there can be no
508 spaces.  Same for a L<quantifier|/Quantifiers> such as C<{3}> or
509 C<{5,}>.  Similarly, C<(?:...)> can't have a space between the C<"(">,
510 C<"?">, and C<":">.  Within any delimiters for such a
511 construct, allowed spaces are not affected by C</x>, and depend on the
512 construct.  For example, C<\x{...}> can't have spaces because hexadecimal
513 numbers don't have spaces in them.  But, Unicode properties can have spaces, so
514 in C<\p{...}> there can be spaces that follow the Unicode rules, for which see
515 L<perluniprops/Properties accessible through \p{} and \P{}>.
516 X</x>
517
518 The set of characters that are deemed whitespace are those that Unicode
519 calls "Pattern White Space", namely:
520
521  U+0009 CHARACTER TABULATION
522  U+000A LINE FEED
523  U+000B LINE TABULATION
524  U+000C FORM FEED
525  U+000D CARRIAGE RETURN
526  U+0020 SPACE
527  U+0085 NEXT LINE
528  U+200E LEFT-TO-RIGHT MARK
529  U+200F RIGHT-TO-LEFT MARK
530  U+2028 LINE SEPARATOR
531  U+2029 PARAGRAPH SEPARATOR
532
533 =head4 Character set modifiers
534
535 C</d>, C</u>, C</a>, and C</l>, available starting in 5.14, are called
536 the character set modifiers; they affect the character set rules
537 used for the regular expression.
538
539 The C</d>, C</u>, and C</l> modifiers are not likely to be of much use
540 to you, and so you need not worry about them very much.  They exist for
541 Perl's internal use, so that complex regular expression data structures
542 can be automatically serialized and later exactly reconstituted,
543 including all their nuances.  But, since Perl can't keep a secret, and
544 there may be rare instances where they are useful, they are documented
545 here.
546
547 The C</a> modifier, on the other hand, may be useful.  Its purpose is to
548 allow code that is to work mostly on ASCII data to not have to concern
549 itself with Unicode.
550
551 Briefly, C</l> sets the character set to that of whatever B<L>ocale is in
552 effect at the time of the execution of the pattern match.
553
554 C</u> sets the character set to B<U>nicode.
555
556 C</a> also sets the character set to Unicode, BUT adds several
557 restrictions for B<A>SCII-safe matching.
558
559 C</d> is the old, problematic, pre-5.14 B<D>efault character set
560 behavior.  Its only use is to force that old behavior.
561
562 At any given time, exactly one of these modifiers is in effect.  Their
563 existence allows Perl to keep the originally compiled behavior of a
564 regular expression, regardless of what rules are in effect when it is
565 actually executed.  And if it is interpolated into a larger regex, the
566 original's rules continue to apply to it, and only it.
567
568 The C</l> and C</u> modifiers are automatically selected for
569 regular expressions compiled within the scope of various pragmas,
570 and we recommend that in general, you use those pragmas instead of
571 specifying these modifiers explicitly.  For one thing, the modifiers
572 affect only pattern matching, and do not extend to even any replacement
573 done, whereas using the pragmas gives consistent results for all
574 appropriate operations within their scopes.  For example,
575
576  s/foo/\Ubar/il
577
578 will match "foo" using the locale's rules for case-insensitive matching,
579 but the C</l> does not affect how the C<\U> operates.  Most likely you
580 want both of them to use locale rules.  To do this, instead compile the
581 regular expression within the scope of C<use locale>.  This both
582 implicitly adds the C</l>, and applies locale rules to the C<\U>.   The
583 lesson is to C<use locale>, and not C</l> explicitly.
584
585 Similarly, it would be better to use C<use feature 'unicode_strings'>
586 instead of,
587
588  s/foo/\Lbar/iu
589
590 to get Unicode rules, as the C<\L> in the former (but not necessarily
591 the latter) would also use Unicode rules.
592
593 More detail on each of the modifiers follows.  Most likely you don't
594 need to know this detail for C</l>, C</u>, and C</d>, and can skip ahead
595 to L<E<sol>a|/E<sol>a (and E<sol>aa)>.
596
597 =head4 /l
598
599 means to use the current locale's rules (see L<perllocale>) when pattern
600 matching.  For example, C<\w> will match the "word" characters of that
601 locale, and C<"/i"> case-insensitive matching will match according to
602 the locale's case folding rules.  The locale used will be the one in
603 effect at the time of execution of the pattern match.  This may not be
604 the same as the compilation-time locale, and can differ from one match
605 to another if there is an intervening call of the
606 L<setlocale() function|perllocale/The setlocale function>.
607
608 Prior to v5.20, Perl did not support multi-byte locales.  Starting then,
609 UTF-8 locales are supported.  No other multi byte locales are ever
610 likely to be supported.  However, in all locales, one can have code
611 points above 255 and these will always be treated as Unicode no matter
612 what locale is in effect.
613
614 Under Unicode rules, there are a few case-insensitive matches that cross
615 the 255/256 boundary.  Except for UTF-8 locales in Perls v5.20 and
616 later, these are disallowed under C</l>.  For example, 0xFF (on ASCII
617 platforms) does not caselessly match the character at 0x178, C<LATIN
618 CAPITAL LETTER Y WITH DIAERESIS>, because 0xFF may not be C<LATIN SMALL
619 LETTER Y WITH DIAERESIS> in the current locale, and Perl has no way of
620 knowing if that character even exists in the locale, much less what code
621 point it is.
622
623 In a UTF-8 locale in v5.20 and later, the only visible difference
624 between locale and non-locale in regular expressions should be tainting
625 (see L<perlsec>).
626
627 This modifier may be specified to be the default by C<use locale>, but
628 see L</Which character set modifier is in effect?>.
629 X</l>
630
631 =head4 /u
632
633 means to use Unicode rules when pattern matching.  On ASCII platforms,
634 this means that the code points between 128 and 255 take on their
635 Latin-1 (ISO-8859-1) meanings (which are the same as Unicode's).
636 (Otherwise Perl considers their meanings to be undefined.)  Thus,
637 under this modifier, the ASCII platform effectively becomes a Unicode
638 platform; and hence, for example, C<\w> will match any of the more than
639 100_000 word characters in Unicode.
640
641 Unlike most locales, which are specific to a language and country pair,
642 Unicode classifies all the characters that are letters I<somewhere> in
643 the world as
644 C<\w>.  For example, your locale might not think that C<LATIN SMALL
645 LETTER ETH> is a letter (unless you happen to speak Icelandic), but
646 Unicode does.  Similarly, all the characters that are decimal digits
647 somewhere in the world will match C<\d>; this is hundreds, not 10,
648 possible matches.  And some of those digits look like some of the 10
649 ASCII digits, but mean a different number, so a human could easily think
650 a number is a different quantity than it really is.  For example,
651 C<BENGALI DIGIT FOUR> (U+09EA) looks very much like an
652 C<ASCII DIGIT EIGHT> (U+0038), and C<LEPCHA DIGIT SIX> (U+1C46) looks
653 very much like an C<ASCII DIGIT FIVE> (U+0035).  And, C<\d+>, may match
654 strings of digits that are a mixture from different writing systems,
655 creating a security issue.  A fraudulent website, for example, could
656 display the price of something using U+1C46, and it would appear to the
657 user that something cost 500 units, but it really costs 600.  A browser
658 that enforced script runs (L</Script Runs>) would prevent that
659 fraudulent display.  L<Unicode::UCD/num()> can also be used to sort this
660 out.  Or the C</a> modifier can be used to force C<\d> to match just the
661 ASCII 0 through 9.
662
663 Also, under this modifier, case-insensitive matching works on the full
664 set of Unicode
665 characters.  The C<KELVIN SIGN>, for example matches the letters "k" and
666 "K"; and C<LATIN SMALL LIGATURE FF> matches the sequence "ff", which,
667 if you're not prepared, might make it look like a hexadecimal constant,
668 presenting another potential security issue.  See
669 L<http://unicode.org/reports/tr36> for a detailed discussion of Unicode
670 security issues.
671
672 This modifier may be specified to be the default by C<use feature
673 'unicode_strings>, C<use locale ':not_characters'>, or
674 C<L<use 5.012|perlfunc/use VERSION>> (or higher),
675 but see L</Which character set modifier is in effect?>.
676 X</u>
677
678 =head4 /d
679
680 This modifier means to use the "Default" native rules of the platform
681 except when there is cause to use Unicode rules instead, as follows:
682
683 =over 4
684
685 =item 1
686
687 the target string is encoded in UTF-8; or
688
689 =item 2
690
691 the pattern is encoded in UTF-8; or
692
693 =item 3
694
695 the pattern explicitly mentions a code point that is above 255 (say by
696 C<\x{100}>); or
697
698 =item 4
699
700 the pattern uses a Unicode name (C<\N{...}>);  or
701
702 =item 5
703
704 the pattern uses a Unicode property (C<\p{...}> or C<\P{...}>); or
705
706 =item 6
707
708 the pattern uses a Unicode break (C<\b{...}> or C<\B{...}>); or
709
710 =item 7
711
712 the pattern uses L</C<(?[ ])>>
713
714 =item 8
715
716 the pattern uses L<C<(*script_run: ...)>|/Script Runs>
717
718 =back
719
720 Another mnemonic for this modifier is "Depends", as the rules actually
721 used depend on various things, and as a result you can get unexpected
722 results.  See L<perlunicode/The "Unicode Bug">.  The Unicode Bug has
723 become rather infamous, leading to yet another (printable) name for this
724 modifier, "Dodgy".
725
726 Unless the pattern or string are encoded in UTF-8, only ASCII characters
727 can match positively.
728
729 Here are some examples of how that works on an ASCII platform:
730
731  $str =  "\xDF";      # $str is not in UTF-8 format.
732  $str =~ /^\w/;       # No match, as $str isn't in UTF-8 format.
733  $str .= "\x{0e0b}";  # Now $str is in UTF-8 format.
734  $str =~ /^\w/;       # Match! $str is now in UTF-8 format.
735  chop $str;
736  $str =~ /^\w/;       # Still a match! $str remains in UTF-8 format.
737
738 This modifier is automatically selected by default when none of the
739 others are, so yet another name for it is "Default".
740
741 Because of the unexpected behaviors associated with this modifier, you
742 probably should only explicitly use it to maintain weird backward
743 compatibilities.
744
745 =head4 /a (and /aa)
746
747 This modifier stands for ASCII-restrict (or ASCII-safe).  This modifier
748 may be doubled-up to increase its effect.
749
750 When it appears singly, it causes the sequences C<\d>, C<\s>, C<\w>, and
751 the Posix character classes to match only in the ASCII range.  They thus
752 revert to their pre-5.6, pre-Unicode meanings.  Under C</a>,  C<\d>
753 always means precisely the digits C<"0"> to C<"9">; C<\s> means the five
754 characters C<[ \f\n\r\t]>, and starting in Perl v5.18, the vertical tab;
755 C<\w> means the 63 characters
756 C<[A-Za-z0-9_]>; and likewise, all the Posix classes such as
757 C<[[:print:]]> match only the appropriate ASCII-range characters.
758
759 This modifier is useful for people who only incidentally use Unicode,
760 and who do not wish to be burdened with its complexities and security
761 concerns.
762
763 With C</a>, one can write C<\d> with confidence that it will only match
764 ASCII characters, and should the need arise to match beyond ASCII, you
765 can instead use C<\p{Digit}> (or C<\p{Word}> for C<\w>).  There are
766 similar C<\p{...}> constructs that can match beyond ASCII both white
767 space (see L<perlrecharclass/Whitespace>), and Posix classes (see
768 L<perlrecharclass/POSIX Character Classes>).  Thus, this modifier
769 doesn't mean you can't use Unicode, it means that to get Unicode
770 matching you must explicitly use a construct (C<\p{}>, C<\P{}>) that
771 signals Unicode.
772
773 As you would expect, this modifier causes, for example, C<\D> to mean
774 the same thing as C<[^0-9]>; in fact, all non-ASCII characters match
775 C<\D>, C<\S>, and C<\W>.  C<\b> still means to match at the boundary
776 between C<\w> and C<\W>, using the C</a> definitions of them (similarly
777 for C<\B>).
778
779 Otherwise, C</a> behaves like the C</u> modifier, in that
780 case-insensitive matching uses Unicode rules; for example, "k" will
781 match the Unicode C<\N{KELVIN SIGN}> under C</i> matching, and code
782 points in the Latin1 range, above ASCII will have Unicode rules when it
783 comes to case-insensitive matching.
784
785 To forbid ASCII/non-ASCII matches (like "k" with C<\N{KELVIN SIGN}>),
786 specify the C<"a"> twice, for example C</aai> or C</aia>.  (The first
787 occurrence of C<"a"> restricts the C<\d>, I<etc>., and the second occurrence
788 adds the C</i> restrictions.)  But, note that code points outside the
789 ASCII range will use Unicode rules for C</i> matching, so the modifier
790 doesn't really restrict things to just ASCII; it just forbids the
791 intermixing of ASCII and non-ASCII.
792
793 To summarize, this modifier provides protection for applications that
794 don't wish to be exposed to all of Unicode.  Specifying it twice
795 gives added protection.
796
797 This modifier may be specified to be the default by C<use re '/a'>
798 or C<use re '/aa'>.  If you do so, you may actually have occasion to use
799 the C</u> modifier explicitly if there are a few regular expressions
800 where you do want full Unicode rules (but even here, it's best if
801 everything were under feature C<"unicode_strings">, along with the
802 C<use re '/aa'>).  Also see L</Which character set modifier is in
803 effect?>.
804 X</a>
805 X</aa>
806
807 =head4 Which character set modifier is in effect?
808
809 Which of these modifiers is in effect at any given point in a regular
810 expression depends on a fairly complex set of interactions.  These have
811 been designed so that in general you don't have to worry about it, but
812 this section gives the gory details.  As
813 explained below in L</Extended Patterns> it is possible to explicitly
814 specify modifiers that apply only to portions of a regular expression.
815 The innermost always has priority over any outer ones, and one applying
816 to the whole expression has priority over any of the default settings that are
817 described in the remainder of this section.
818
819 The C<L<use re 'E<sol>foo'|re/"'/flags' mode">> pragma can be used to set
820 default modifiers (including these) for regular expressions compiled
821 within its scope.  This pragma has precedence over the other pragmas
822 listed below that also change the defaults.
823
824 Otherwise, C<L<use locale|perllocale>> sets the default modifier to C</l>;
825 and C<L<use feature 'unicode_strings|feature>>, or
826 C<L<use 5.012|perlfunc/use VERSION>> (or higher) set the default to
827 C</u> when not in the same scope as either C<L<use locale|perllocale>>
828 or C<L<use bytes|bytes>>.
829 (C<L<use locale ':not_characters'|perllocale/Unicode and UTF-8>> also
830 sets the default to C</u>, overriding any plain C<use locale>.)
831 Unlike the mechanisms mentioned above, these
832 affect operations besides regular expressions pattern matching, and so
833 give more consistent results with other operators, including using
834 C<\U>, C<\l>, I<etc>. in substitution replacements.
835
836 If none of the above apply, for backwards compatibility reasons, the
837 C</d> modifier is the one in effect by default.  As this can lead to
838 unexpected results, it is best to specify which other rule set should be
839 used.
840
841 =head4 Character set modifier behavior prior to Perl 5.14
842
843 Prior to 5.14, there were no explicit modifiers, but C</l> was implied
844 for regexes compiled within the scope of C<use locale>, and C</d> was
845 implied otherwise.  However, interpolating a regex into a larger regex
846 would ignore the original compilation in favor of whatever was in effect
847 at the time of the second compilation.  There were a number of
848 inconsistencies (bugs) with the C</d> modifier, where Unicode rules
849 would be used when inappropriate, and vice versa.  C<\p{}> did not imply
850 Unicode rules, and neither did all occurrences of C<\N{}>, until 5.12.
851
852 =head2 Regular Expressions
853
854 =head3 Quantifiers
855
856 Quantifiers are used when a particular portion of a pattern needs to
857 match a certain number (or numbers) of times.  If there isn't a
858 quantifier the number of times to match is exactly one.  The following
859 standard quantifiers are recognized:
860 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
861
862     *           Match 0 or more times
863     +           Match 1 or more times
864     ?           Match 1 or 0 times
865     {n}         Match exactly n times
866     {n,}        Match at least n times
867     {n,m}       Match at least n but not more than m times
868
869 (If a non-escaped curly bracket occurs in a context other than one of
870 the quantifiers listed above, where it does not form part of a
871 backslashed sequence like C<\x{...}>, it is either a fatal syntax error,
872 or treated as a regular character, generally with a deprecation warning
873 raised.  To escape it, you can precede it with a backslash (C<"\{">) or
874 enclose it within square brackets  (C<"[{]">).
875 This change will allow for future syntax extensions (like making the
876 lower bound of a quantifier optional), and better error checking of
877 quantifiers).
878
879 The C<"*"> quantifier is equivalent to C<{0,}>, the C<"+">
880 quantifier to C<{1,}>, and the C<"?"> quantifier to C<{0,1}>.  I<n> and I<m> are limited
881 to non-negative integral values less than a preset limit defined when perl is built.
882 This is usually 32766 on the most common platforms.  The actual limit can
883 be seen in the error message generated by code such as this:
884
885     $_ **= $_ , / {$_} / for 2 .. 42;
886
887 By default, a quantified subpattern is "greedy", that is, it will match as
888 many times as possible (given a particular starting location) while still
889 allowing the rest of the pattern to match.  If you want it to match the
890 minimum number of times possible, follow the quantifier with a C<"?">.  Note
891 that the meanings don't change, just the "greediness":
892 X<metacharacter> X<greedy> X<greediness>
893 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
894
895     *?        Match 0 or more times, not greedily
896     +?        Match 1 or more times, not greedily
897     ??        Match 0 or 1 time, not greedily
898     {n}?      Match exactly n times, not greedily (redundant)
899     {n,}?     Match at least n times, not greedily
900     {n,m}?    Match at least n but not more than m times, not greedily
901
902 Normally when a quantified subpattern does not allow the rest of the
903 overall pattern to match, Perl will backtrack. However, this behaviour is
904 sometimes undesirable. Thus Perl provides the "possessive" quantifier form
905 as well.
906
907  *+     Match 0 or more times and give nothing back
908  ++     Match 1 or more times and give nothing back
909  ?+     Match 0 or 1 time and give nothing back
910  {n}+   Match exactly n times and give nothing back (redundant)
911  {n,}+  Match at least n times and give nothing back
912  {n,m}+ Match at least n but not more than m times and give nothing back
913
914 For instance,
915
916    'aaaa' =~ /a++a/
917
918 will never match, as the C<a++> will gobble up all the C<"a">'s in the
919 string and won't leave any for the remaining part of the pattern. This
920 feature can be extremely useful to give perl hints about where it
921 shouldn't backtrack. For instance, the typical "match a double-quoted
922 string" problem can be most efficiently performed when written as:
923
924    /"(?:[^"\\]++|\\.)*+"/
925
926 as we know that if the final quote does not match, backtracking will not
927 help. See the independent subexpression
928 L</C<< (?>pattern) >>> for more details;
929 possessive quantifiers are just syntactic sugar for that construct. For
930 instance the above example could also be written as follows:
931
932    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
933
934 Note that the possessive quantifier modifier can not be combined
935 with the non-greedy modifier. This is because it would make no sense.
936 Consider the follow equivalency table:
937
938     Illegal         Legal
939     ------------    ------
940     X??+            X{0}
941     X+?+            X{1}
942     X{min,max}?+    X{min}
943
944 =head3 Escape sequences
945
946 Because patterns are processed as double-quoted strings, the following
947 also work:
948
949  \t          tab                   (HT, TAB)
950  \n          newline               (LF, NL)
951  \r          return                (CR)
952  \f          form feed             (FF)
953  \a          alarm (bell)          (BEL)
954  \e          escape (think troff)  (ESC)
955  \cK         control char          (example: VT)
956  \x{}, \x00  character whose ordinal is the given hexadecimal number
957  \N{name}    named Unicode character or character sequence
958  \N{U+263D}  Unicode character     (example: FIRST QUARTER MOON)
959  \o{}, \000  character whose ordinal is the given octal number
960  \l          lowercase next char (think vi)
961  \u          uppercase next char (think vi)
962  \L          lowercase until \E (think vi)
963  \U          uppercase until \E (think vi)
964  \Q          quote (disable) pattern metacharacters until \E
965  \E          end either case modification or quoted section, think vi
966
967 Details are in L<perlop/Quote and Quote-like Operators>.
968
969 =head3 Character Classes and other Special Escapes
970
971 In addition, Perl defines the following:
972 X<\g> X<\k> X<\K> X<backreference>
973
974  Sequence   Note    Description
975   [...]     [1]  Match a character according to the rules of the
976                    bracketed character class defined by the "...".
977                    Example: [a-z] matches "a" or "b" or "c" ... or "z"
978   [[:...:]] [2]  Match a character according to the rules of the POSIX
979                    character class "..." within the outer bracketed
980                    character class.  Example: [[:upper:]] matches any
981                    uppercase character.
982   (?[...])  [8]  Extended bracketed character class
983   \w        [3]  Match a "word" character (alphanumeric plus "_", plus
984                    other connector punctuation chars plus Unicode
985                    marks)
986   \W        [3]  Match a non-"word" character
987   \s        [3]  Match a whitespace character
988   \S        [3]  Match a non-whitespace character
989   \d        [3]  Match a decimal digit character
990   \D        [3]  Match a non-digit character
991   \pP       [3]  Match P, named property.  Use \p{Prop} for longer names
992   \PP       [3]  Match non-P
993   \X        [4]  Match Unicode "eXtended grapheme cluster"
994   \1        [5]  Backreference to a specific capture group or buffer.
995                    '1' may actually be any positive integer.
996   \g1       [5]  Backreference to a specific or previous group,
997   \g{-1}    [5]  The number may be negative indicating a relative
998                    previous group and may optionally be wrapped in
999                    curly brackets for safer parsing.
1000   \g{name}  [5]  Named backreference
1001   \k<name>  [5]  Named backreference
1002   \K        [6]  Keep the stuff left of the \K, don't include it in $&
1003   \N        [7]  Any character but \n.  Not affected by /s modifier
1004   \v        [3]  Vertical whitespace
1005   \V        [3]  Not vertical whitespace
1006   \h        [3]  Horizontal whitespace
1007   \H        [3]  Not horizontal whitespace
1008   \R        [4]  Linebreak
1009
1010 =over 4
1011
1012 =item [1]
1013
1014 See L<perlrecharclass/Bracketed Character Classes> for details.
1015
1016 =item [2]
1017
1018 See L<perlrecharclass/POSIX Character Classes> for details.
1019
1020 =item [3]
1021
1022 See L<perlunicode/Unicode Character Properties> for details
1023
1024 =item [4]
1025
1026 See L<perlrebackslash/Misc> for details.
1027
1028 =item [5]
1029
1030 See L</Capture groups> below for details.
1031
1032 =item [6]
1033
1034 See L</Extended Patterns> below for details.
1035
1036 =item [7]
1037
1038 Note that C<\N> has two meanings.  When of the form C<\N{NAME}>, it matches the
1039 character or character sequence whose name is C<NAME>; and similarly
1040 when of the form C<\N{U+I<hex>}>, it matches the character whose Unicode
1041 code point is I<hex>.  Otherwise it matches any character but C<\n>.
1042
1043 =item [8]
1044
1045 See L<perlrecharclass/Extended Bracketed Character Classes> for details.
1046
1047 =back
1048
1049 =head3 Assertions
1050
1051 Besides L<C<"^"> and C<"$">|/Metacharacters>, Perl defines the following
1052 zero-width assertions:
1053 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
1054 X<regexp, zero-width assertion>
1055 X<regular expression, zero-width assertion>
1056 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
1057
1058  \b{}   Match at Unicode boundary of specified type
1059  \B{}   Match where corresponding \b{} doesn't match
1060  \b     Match a \w\W or \W\w boundary
1061  \B     Match except at a \w\W or \W\w boundary
1062  \A     Match only at beginning of string
1063  \Z     Match only at end of string, or before newline at the end
1064  \z     Match only at end of string
1065  \G     Match only at pos() (e.g. at the end-of-match position
1066         of prior m//g)
1067
1068 A Unicode boundary (C<\b{}>), available starting in v5.22, is a spot
1069 between two characters, or before the first character in the string, or
1070 after the final character in the string where certain criteria defined
1071 by Unicode are met.  See L<perlrebackslash/\b{}, \b, \B{}, \B> for
1072 details.
1073
1074 A word boundary (C<\b>) is a spot between two characters
1075 that has a C<\w> on one side of it and a C<\W> on the other side
1076 of it (in either order), counting the imaginary characters off the
1077 beginning and end of the string as matching a C<\W>.  (Within
1078 character classes C<\b> represents backspace rather than a word
1079 boundary, just as it normally does in any double-quoted string.)
1080 The C<\A> and C<\Z> are just like C<"^"> and C<"$">, except that they
1081 won't match multiple times when the C</m> modifier is used, while
1082 C<"^"> and C<"$"> will match at every internal line boundary.  To match
1083 the actual end of the string and not ignore an optional trailing
1084 newline, use C<\z>.
1085 X<\b> X<\A> X<\Z> X<\z> X</m>
1086
1087 The C<\G> assertion can be used to chain global matches (using
1088 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
1089 It is also useful when writing C<lex>-like scanners, when you have
1090 several patterns that you want to match against consequent substrings
1091 of your string; see the previous reference.  The actual location
1092 where C<\G> will match can also be influenced by using C<pos()> as
1093 an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
1094 matches (see L</"Repeated Patterns Matching a Zero-length Substring">)
1095 is modified somewhat, in that contents to the left of C<\G> are
1096 not counted when determining the length of the match. Thus the following
1097 will not match forever:
1098 X<\G>
1099
1100      my $string = 'ABC';
1101      pos($string) = 1;
1102      while ($string =~ /(.\G)/g) {
1103          print $1;
1104      }
1105
1106 It will print 'A' and then terminate, as it considers the match to
1107 be zero-width, and thus will not match at the same position twice in a
1108 row.
1109
1110 It is worth noting that C<\G> improperly used can result in an infinite
1111 loop. Take care when using patterns that include C<\G> in an alternation.
1112
1113 Note also that C<s///> will refuse to overwrite part of a substitution
1114 that has already been replaced; so for example this will stop after the
1115 first iteration, rather than iterating its way backwards through the
1116 string:
1117
1118     $_ = "123456789";
1119     pos = 6;
1120     s/.(?=.\G)/X/g;
1121     print;      # prints 1234X6789, not XXXXX6789
1122
1123
1124 =head3 Capture groups
1125
1126 The grouping construct C<( ... )> creates capture groups (also referred to as
1127 capture buffers). To refer to the current contents of a group later on, within
1128 the same pattern, use C<\g1> (or C<\g{1}>) for the first, C<\g2> (or C<\g{2}>)
1129 for the second, and so on.
1130 This is called a I<backreference>.
1131 X<regex, capture buffer> X<regexp, capture buffer>
1132 X<regex, capture group> X<regexp, capture group>
1133 X<regular expression, capture buffer> X<backreference>
1134 X<regular expression, capture group> X<backreference>
1135 X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
1136 X<named capture buffer> X<regular expression, named capture buffer>
1137 X<named capture group> X<regular expression, named capture group>
1138 X<%+> X<$+{name}> X<< \k<name> >>
1139 There is no limit to the number of captured substrings that you may use.
1140 Groups are numbered with the leftmost open parenthesis being number 1, I<etc>.  If
1141 a group did not match, the associated backreference won't match either. (This
1142 can happen if the group is optional, or in a different branch of an
1143 alternation.)
1144 You can omit the C<"g">, and write C<"\1">, I<etc>, but there are some issues with
1145 this form, described below.
1146
1147 You can also refer to capture groups relatively, by using a negative number, so
1148 that C<\g-1> and C<\g{-1}> both refer to the immediately preceding capture
1149 group, and C<\g-2> and C<\g{-2}> both refer to the group before it.  For
1150 example:
1151
1152         /
1153          (Y)            # group 1
1154          (              # group 2
1155             (X)         # group 3
1156             \g{-1}      # backref to group 3
1157             \g{-3}      # backref to group 1
1158          )
1159         /x
1160
1161 would match the same as C</(Y) ( (X) \g3 \g1 )/x>.  This allows you to
1162 interpolate regexes into larger regexes and not have to worry about the
1163 capture groups being renumbered.
1164
1165 You can dispense with numbers altogether and create named capture groups.
1166 The notation is C<(?E<lt>I<name>E<gt>...)> to declare and C<\g{I<name>}> to
1167 reference.  (To be compatible with .Net regular expressions, C<\g{I<name>}> may
1168 also be written as C<\k{I<name>}>, C<\kE<lt>I<name>E<gt>> or C<\k'I<name>'>.)
1169 I<name> must not begin with a number, nor contain hyphens.
1170 When different groups within the same pattern have the same name, any reference
1171 to that name assumes the leftmost defined group.  Named groups count in
1172 absolute and relative numbering, and so can also be referred to by those
1173 numbers.
1174 (It's possible to do things with named capture groups that would otherwise
1175 require C<(??{})>.)
1176
1177 Capture group contents are dynamically scoped and available to you outside the
1178 pattern until the end of the enclosing block or until the next successful
1179 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
1180 You can refer to them by absolute number (using C<"$1"> instead of C<"\g1">,
1181 I<etc>); or by name via the C<%+> hash, using C<"$+{I<name>}">.
1182
1183 Braces are required in referring to named capture groups, but are optional for
1184 absolute or relative numbered ones.  Braces are safer when creating a regex by
1185 concatenating smaller strings.  For example if you have C<qr/$a$b/>, and C<$a>
1186 contained C<"\g1">, and C<$b> contained C<"37">, you would get C</\g137/> which
1187 is probably not what you intended.
1188
1189 The C<\g> and C<\k> notations were introduced in Perl 5.10.0.  Prior to that
1190 there were no named nor relative numbered capture groups.  Absolute numbered
1191 groups were referred to using C<\1>,
1192 C<\2>, I<etc>., and this notation is still
1193 accepted (and likely always will be).  But it leads to some ambiguities if
1194 there are more than 9 capture groups, as C<\10> could mean either the tenth
1195 capture group, or the character whose ordinal in octal is 010 (a backspace in
1196 ASCII).  Perl resolves this ambiguity by interpreting C<\10> as a backreference
1197 only if at least 10 left parentheses have opened before it.  Likewise C<\11> is
1198 a backreference only if at least 11 left parentheses have opened before it.
1199 And so on.  C<\1> through C<\9> are always interpreted as backreferences.
1200 There are several examples below that illustrate these perils.  You can avoid
1201 the ambiguity by always using C<\g{}> or C<\g> if you mean capturing groups;
1202 and for octal constants always using C<\o{}>, or for C<\077> and below, using 3
1203 digits padded with leading zeros, since a leading zero implies an octal
1204 constant.
1205
1206 The C<\I<digit>> notation also works in certain circumstances outside
1207 the pattern.  See L</Warning on \1 Instead of $1> below for details.
1208
1209 Examples:
1210
1211     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
1212
1213     /(.)\g1/                        # find first doubled char
1214          and print "'$1' is the first doubled character\n";
1215
1216     /(?<char>.)\k<char>/            # ... a different way
1217          and print "'$+{char}' is the first doubled character\n";
1218
1219     /(?'char'.)\g1/                 # ... mix and match
1220          and print "'$1' is the first doubled character\n";
1221
1222     if (/Time: (..):(..):(..)/) {   # parse out values
1223         $hours = $1;
1224         $minutes = $2;
1225         $seconds = $3;
1226     }
1227
1228     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\g10/   # \g10 is a backreference
1229     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\10/    # \10 is octal
1230     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\10/  # \10 is a backreference
1231     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\010/ # \010 is octal
1232
1233     $a = '(.)\1';        # Creates problems when concatenated.
1234     $b = '(.)\g{1}';     # Avoids the problems.
1235     "aa" =~ /${a}/;      # True
1236     "aa" =~ /${b}/;      # True
1237     "aa0" =~ /${a}0/;    # False!
1238     "aa0" =~ /${b}0/;    # True
1239     "aa\x08" =~ /${a}0/;  # True!
1240     "aa\x08" =~ /${b}0/;  # False
1241
1242 Several special variables also refer back to portions of the previous
1243 match.  C<$+> returns whatever the last bracket match matched.
1244 C<$&> returns the entire matched string.  (At one point C<$0> did
1245 also, but now it returns the name of the program.)  C<$`> returns
1246 everything before the matched string.  C<$'> returns everything
1247 after the matched string. And C<$^N> contains whatever was matched by
1248 the most-recently closed group (submatch). C<$^N> can be used in
1249 extended patterns (see below), for example to assign a submatch to a
1250 variable.
1251 X<$+> X<$^N> X<$&> X<$`> X<$'>
1252
1253 These special variables, like the C<%+> hash and the numbered match variables
1254 (C<$1>, C<$2>, C<$3>, I<etc>.) are dynamically scoped
1255 until the end of the enclosing block or until the next successful
1256 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
1257 X<$+> X<$^N> X<$&> X<$`> X<$'>
1258 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
1259
1260 B<NOTE>: Failed matches in Perl do not reset the match variables,
1261 which makes it easier to write code that tests for a series of more
1262 specific cases and remembers the best match.
1263
1264 B<WARNING>: If your code is to run on Perl 5.16 or earlier,
1265 beware that once Perl sees that you need one of C<$&>, C<$`>, or
1266 C<$'> anywhere in the program, it has to provide them for every
1267 pattern match.  This may substantially slow your program.
1268
1269 Perl uses the same mechanism to produce C<$1>, C<$2>, I<etc>, so you also
1270 pay a price for each pattern that contains capturing parentheses.
1271 (To avoid this cost while retaining the grouping behaviour, use the
1272 extended regular expression C<(?: ... )> instead.)  But if you never
1273 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
1274 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
1275 if you can, but if you can't (and some algorithms really appreciate
1276 them), once you've used them once, use them at will, because you've
1277 already paid the price.
1278 X<$&> X<$`> X<$'>
1279
1280 Perl 5.16 introduced a slightly more efficient mechanism that notes
1281 separately whether each of C<$`>, C<$&>, and C<$'> have been seen, and
1282 thus may only need to copy part of the string.  Perl 5.20 introduced a
1283 much more efficient copy-on-write mechanism which eliminates any slowdown.
1284
1285 As another workaround for this problem, Perl 5.10.0 introduced C<${^PREMATCH}>,
1286 C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
1287 and C<$'>, B<except> that they are only guaranteed to be defined after a
1288 successful match that was executed with the C</p> (preserve) modifier.
1289 The use of these variables incurs no global performance penalty, unlike
1290 their punctuation character equivalents, however at the trade-off that you
1291 have to tell perl when you want to use them.  As of Perl 5.20, these three
1292 variables are equivalent to C<$`>, C<$&> and C<$'>, and C</p> is ignored.
1293 X</p> X<p modifier>
1294
1295 =head2 Quoting metacharacters
1296
1297 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
1298 C<\w>, C<\n>.  Unlike some other regular expression languages, there
1299 are no backslashed symbols that aren't alphanumeric.  So anything
1300 that looks like C<\\>, C<\(>, C<\)>, C<\[>, C<\]>, C<\{>, or C<\}> is
1301 always
1302 interpreted as a literal character, not a metacharacter.  This was
1303 once used in a common idiom to disable or quote the special meanings
1304 of regular expression metacharacters in a string that you want to
1305 use for a pattern. Simply quote all non-"word" characters:
1306
1307     $pattern =~ s/(\W)/\\$1/g;
1308
1309 (If C<use locale> is set, then this depends on the current locale.)
1310 Today it is more common to use the C<L<quotemeta()|perlfunc/quotemeta>>
1311 function or the C<\Q> metaquoting escape sequence to disable all
1312 metacharacters' special meanings like this:
1313
1314     /$unquoted\Q$quoted\E$unquoted/
1315
1316 Beware that if you put literal backslashes (those not inside
1317 interpolated variables) between C<\Q> and C<\E>, double-quotish
1318 backslash interpolation may lead to confusing results.  If you
1319 I<need> to use literal backslashes within C<\Q...\E>,
1320 consult L<perlop/"Gory details of parsing quoted constructs">.
1321
1322 C<quotemeta()> and C<\Q> are fully described in L<perlfunc/quotemeta>.
1323
1324 =head2 Extended Patterns
1325
1326 Perl also defines a consistent extension syntax for features not
1327 found in standard tools like B<awk> and
1328 B<lex>.  The syntax for most of these is a
1329 pair of parentheses with a question mark as the first thing within
1330 the parentheses.  The character after the question mark indicates
1331 the extension.
1332
1333 A question mark was chosen for this and for the minimal-matching
1334 construct because 1) question marks are rare in older regular
1335 expressions, and 2) whenever you see one, you should stop and
1336 "question" exactly what is going on.  That's psychology....
1337
1338 =over 4
1339
1340 =item C<(?#text)>
1341 X<(?#)>
1342
1343 A comment.  The text is ignored.
1344 Note that Perl closes
1345 the comment as soon as it sees a C<")">, so there is no way to put a literal
1346 C<")"> in the comment.  The pattern's closing delimiter must be escaped by
1347 a backslash if it appears in the comment.
1348
1349 See L</E<sol>x> for another way to have comments in patterns.
1350
1351 Note that a comment can go just about anywhere, except in the middle of
1352 an escape sequence.   Examples:
1353
1354  qr/foo(?#comment)bar/'  # Matches 'foobar'
1355
1356  # The pattern below matches 'abcd', 'abccd', or 'abcccd'
1357  qr/abc(?#comment between literal and its quantifier){1,3}d/
1358
1359  # The pattern below generates a syntax error, because the '\p' must
1360  # be followed immediately by a '{'.
1361  qr/\p(?#comment between \p and its property name){Any}/
1362
1363  # The pattern below generates a syntax error, because the initial
1364  # '\(' is a literal opening parenthesis, and so there is nothing
1365  # for the  closing ')' to match
1366  qr/\(?#the backslash means this isn't a comment)p{Any}/
1367
1368  # Comments can be used to fold long patterns into multiple lines
1369  qr/First part of a long regex(?#
1370    )remaining part/
1371
1372 =item C<(?adlupimnsx-imnsx)>
1373
1374 =item C<(?^alupimnsx)>
1375 X<(?)> X<(?^)>
1376
1377 One or more embedded pattern-match modifiers, to be turned on (or
1378 turned off if preceded by C<"-">) for the remainder of the pattern or
1379 the remainder of the enclosing pattern group (if any).
1380
1381 This is particularly useful for dynamically-generated patterns,
1382 such as those read in from a
1383 configuration file, taken from an argument, or specified in a table
1384 somewhere.  Consider the case where some patterns want to be
1385 case-sensitive and some do not:  The case-insensitive ones merely need to
1386 include C<(?i)> at the front of the pattern.  For example:
1387
1388     $pattern = "foobar";
1389     if ( /$pattern/i ) { }
1390
1391     # more flexible:
1392
1393     $pattern = "(?i)foobar";
1394     if ( /$pattern/ ) { }
1395
1396 These modifiers are restored at the end of the enclosing group. For example,
1397
1398     ( (?i) blah ) \s+ \g1
1399
1400 will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
1401 repetition of the previous word, assuming the C</x> modifier, and no C</i>
1402 modifier outside this group.
1403
1404 These modifiers do not carry over into named subpatterns called in the
1405 enclosing group. In other words, a pattern such as C<((?i)(?&NAME))> does not
1406 change the case-sensitivity of the C<"NAME"> pattern.
1407
1408 A modifier is overridden by later occurrences of this construct in the
1409 same scope containing the same modifier, so that
1410
1411     /((?im)foo(?-m)bar)/
1412
1413 matches all of C<foobar> case insensitively, but uses C</m> rules for
1414 only the C<foo> portion.  The C<"a"> flag overrides C<aa> as well;
1415 likewise C<aa> overrides C<"a">.  The same goes for C<"x"> and C<xx>.
1416 Hence, in
1417
1418     /(?-x)foo/xx
1419
1420 both C</x> and C</xx> are turned off during matching C<foo>.  And in
1421
1422     /(?x)foo/x
1423
1424 C</x> but NOT C</xx> is turned on for matching C<foo>.  (One might
1425 mistakenly think that since the inner C<(?x)> is already in the scope of
1426 C</x>, that the result would effectively be the sum of them, yielding
1427 C</xx>.  It doesn't work that way.)  Similarly, doing something like
1428 C<(?xx-x)foo> turns off all C<"x"> behavior for matching C<foo>, it is not
1429 that you subtract 1 C<"x"> from 2 to get 1 C<"x"> remaining.
1430
1431 Any of these modifiers can be set to apply globally to all regular
1432 expressions compiled within the scope of a C<use re>.  See
1433 L<re/"'/flags' mode">.
1434
1435 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
1436 after the C<"?"> is a shorthand equivalent to C<d-imnsx>.  Flags (except
1437 C<"d">) may follow the caret to override it.
1438 But a minus sign is not legal with it.
1439
1440 Note that the C<"a">, C<"d">, C<"l">, C<"p">, and C<"u"> modifiers are special in
1441 that they can only be enabled, not disabled, and the C<"a">, C<"d">, C<"l">, and
1442 C<"u"> modifiers are mutually exclusive: specifying one de-specifies the
1443 others, and a maximum of one (or two C<"a">'s) may appear in the
1444 construct.  Thus, for
1445 example, C<(?-p)> will warn when compiled under C<use warnings>;
1446 C<(?-d:...)> and C<(?dl:...)> are fatal errors.
1447
1448 Note also that the C<"p"> modifier is special in that its presence
1449 anywhere in a pattern has a global effect.
1450
1451 =item C<(?:pattern)>
1452 X<(?:)>
1453
1454 =item C<(?adluimnsx-imnsx:pattern)>
1455
1456 =item C<(?^aluimnsx:pattern)>
1457 X<(?^:)>
1458
1459 This is for clustering, not capturing; it groups subexpressions like
1460 C<"()">, but doesn't make backreferences as C<"()"> does.  So
1461
1462     @fields = split(/\b(?:a|b|c)\b/)
1463
1464 matches the same field delimiters as
1465
1466     @fields = split(/\b(a|b|c)\b/)
1467
1468 but doesn't spit out the delimiters themselves as extra fields (even though
1469 that's the behaviour of L<perlfunc/split> when its pattern contains capturing
1470 groups).  It's also cheaper not to capture
1471 characters if you don't need to.
1472
1473 Any letters between C<"?"> and C<":"> act as flags modifiers as with
1474 C<(?adluimnsx-imnsx)>.  For example,
1475
1476     /(?s-i:more.*than).*million/i
1477
1478 is equivalent to the more verbose
1479
1480     /(?:(?s-i)more.*than).*million/i
1481
1482 Note that any C<()> constructs enclosed within this one will still
1483 capture unless the C</n> modifier is in effect.
1484
1485 Like the L</(?adlupimnsx-imnsx)> construct, C<aa> and C<"a"> override each
1486 other, as do C<xx> and C<"x">.  They are not additive.  So, doing
1487 something like C<(?xx-x:foo)> turns off all C<"x"> behavior for matching
1488 C<foo>.
1489
1490 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
1491 after the C<"?"> is a shorthand equivalent to C<d-imnsx>.  Any positive
1492 flags (except C<"d">) may follow the caret, so
1493
1494     (?^x:foo)
1495
1496 is equivalent to
1497
1498     (?x-imns:foo)
1499
1500 The caret tells Perl that this cluster doesn't inherit the flags of any
1501 surrounding pattern, but uses the system defaults (C<d-imnsx>),
1502 modified by any flags specified.
1503
1504 The caret allows for simpler stringification of compiled regular
1505 expressions.  These look like
1506
1507     (?^:pattern)
1508
1509 with any non-default flags appearing between the caret and the colon.
1510 A test that looks at such stringification thus doesn't need to have the
1511 system default flags hard-coded in it, just the caret.  If new flags are
1512 added to Perl, the meaning of the caret's expansion will change to include
1513 the default for those flags, so the test will still work, unchanged.
1514
1515 Specifying a negative flag after the caret is an error, as the flag is
1516 redundant.
1517
1518 Mnemonic for C<(?^...)>:  A fresh beginning since the usual use of a caret is
1519 to match at the beginning.
1520
1521 =item C<(?|pattern)>
1522 X<(?|)> X<Branch reset>
1523
1524 This is the "branch reset" pattern, which has the special property
1525 that the capture groups are numbered from the same starting point
1526 in each alternation branch. It is available starting from perl 5.10.0.
1527
1528 Capture groups are numbered from left to right, but inside this
1529 construct the numbering is restarted for each branch.
1530
1531 The numbering within each branch will be as normal, and any groups
1532 following this construct will be numbered as though the construct
1533 contained only one branch, that being the one with the most capture
1534 groups in it.
1535
1536 This construct is useful when you want to capture one of a
1537 number of alternative matches.
1538
1539 Consider the following pattern.  The numbers underneath show in
1540 which group the captured content will be stored.
1541
1542
1543     # before  ---------------branch-reset----------- after
1544     / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
1545     # 1            2         2  3        2     3     4
1546
1547 Be careful when using the branch reset pattern in combination with
1548 named captures. Named captures are implemented as being aliases to
1549 numbered groups holding the captures, and that interferes with the
1550 implementation of the branch reset pattern. If you are using named
1551 captures in a branch reset pattern, it's best to use the same names,
1552 in the same order, in each of the alternations:
1553
1554    /(?|  (?<a> x ) (?<b> y )
1555       |  (?<a> z ) (?<b> w )) /x
1556
1557 Not doing so may lead to surprises:
1558
1559   "12" =~ /(?| (?<a> \d+ ) | (?<b> \D+))/x;
1560   say $+{a};    # Prints '12'
1561   say $+{b};    # *Also* prints '12'.
1562
1563 The problem here is that both the group named C<< a >> and the group
1564 named C<< b >> are aliases for the group belonging to C<< $1 >>.
1565
1566 =item Lookaround Assertions
1567 X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
1568
1569 Lookaround assertions are zero-width patterns which match a specific
1570 pattern without including it in C<$&>. Positive assertions match when
1571 their subpattern matches, negative assertions match when their subpattern
1572 fails. Lookbehind matches text up to the current match position,
1573 lookahead matches text following the current match position.
1574
1575 =over 4
1576
1577 =item C<(?=pattern)>
1578
1579 =item C<(*pla:pattern)>
1580
1581 =item C<(*positive_lookahead:pattern)>
1582 X<(?=)>
1583 X<(*pla>
1584 X<(*positive_lookahead>
1585 X<look-ahead, positive> X<lookahead, positive>
1586
1587 A zero-width positive lookahead assertion.  For example, C</\w+(?=\t)/>
1588 matches a word followed by a tab, without including the tab in C<$&>.
1589
1590 The alphabetic forms are experimental; using them yields a warning in the
1591 C<experimental::alpha_assertions> category.
1592
1593 =item C<(?!pattern)>
1594
1595 =item C<(*nla:pattern)>
1596
1597 =item C<(*negative_lookahead:pattern)>
1598 X<(?!)>
1599 X<(*nla>
1600 X<(*negative_lookahead>
1601 X<look-ahead, negative> X<lookahead, negative>
1602
1603 A zero-width negative lookahead assertion.  For example C</foo(?!bar)/>
1604 matches any occurrence of "foo" that isn't followed by "bar".  Note
1605 however that lookahead and lookbehind are NOT the same thing.  You cannot
1606 use this for lookbehind.
1607
1608 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
1609 will not do what you want.  That's because the C<(?!foo)> is just saying that
1610 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
1611 match.  Use lookbehind instead (see below).
1612
1613 The alphabetic forms are experimental; using them yields a warning in the
1614 C<experimental::alpha_assertions> category.
1615
1616 =item C<(?<=pattern)>
1617
1618 =item C<\K>
1619
1620 =item C<(*plb:pattern)>
1621
1622 =item C<(*positive_lookbehind:pattern)>
1623 X<(?<=)>
1624 X<(*plb>
1625 X<(*positive_lookbehind>
1626 X<look-behind, positive> X<lookbehind, positive> X<\K>
1627
1628 A zero-width positive lookbehind assertion.  For example, C</(?<=\t)\w+/>
1629 matches a word that follows a tab, without including the tab in C<$&>.
1630 Works only for fixed-width lookbehind of up to 255 characters.  Note
1631 that a compilation error will be generated if the assertion contains a
1632 multi-character match under C</i>, as that could match a single
1633 character, or it could match two or three, and that makes it variable
1634 length, which is forbidden.
1635
1636 There is a special form of this construct, called C<\K> (available since
1637 Perl 5.10.0), which causes the
1638 regex engine to "keep" everything it had matched prior to the C<\K> and
1639 not include it in C<$&>. This effectively provides variable-length
1640 lookbehind. The use of C<\K> inside of another lookaround assertion
1641 is allowed, but the behaviour is currently not well defined.
1642
1643 For various reasons C<\K> may be significantly more efficient than the
1644 equivalent C<< (?<=...) >> construct, and it is especially useful in
1645 situations where you want to efficiently remove something following
1646 something else in a string. For instance
1647
1648   s/(foo)bar/$1/g;
1649
1650 can be rewritten as the much more efficient
1651
1652   s/foo\Kbar//g;
1653
1654 The alphabetic forms (not including C<\K> are experimental; using them
1655 yields a warning in the C<experimental::alpha_assertions> category.
1656
1657 =item C<(?<!pattern)>
1658
1659 =item C<(*nlb:pattern)>
1660
1661 =item C<(*negative_lookbehind:pattern)>
1662 X<(?<!)>
1663 X<(*nlb>
1664 X<(*negative_lookbehind>
1665 X<look-behind, negative> X<lookbehind, negative>
1666
1667 A zero-width negative lookbehind assertion.  For example C</(?<!bar)foo/>
1668 matches any occurrence of "foo" that does not follow "bar".  Works
1669 only for fixed-width lookbehind of up to 255 characters.  Note that a
1670 compilation error will be generated if the assertion contains a
1671 multi-character match under C</i>, as that could match a single
1672 character, or it could match two or three, and that makes it variable
1673 length, which is forbidden.
1674
1675 The alphabetic forms are experimental; using them yields a warning in the
1676 C<experimental::alpha_assertions> category.
1677
1678 =back
1679
1680 =item C<< (?<NAME>pattern) >>
1681
1682 =item C<(?'NAME'pattern)>
1683 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
1684
1685 A named capture group. Identical in every respect to normal capturing
1686 parentheses C<()> but for the additional fact that the group
1687 can be referred to by name in various regular expression
1688 constructs (like C<\g{NAME}>) and can be accessed by name
1689 after a successful match via C<%+> or C<%->. See L<perlvar>
1690 for more details on the C<%+> and C<%-> hashes.
1691
1692 If multiple distinct capture groups have the same name, then
1693 C<$+{NAME}> will refer to the leftmost defined group in the match.
1694
1695 The forms C<(?'NAME'pattern)> and C<< (?<NAME>pattern) >> are equivalent.
1696
1697 B<NOTE:> While the notation of this construct is the same as the similar
1698 function in .NET regexes, the behavior is not. In Perl the groups are
1699 numbered sequentially regardless of being named or not. Thus in the
1700 pattern
1701
1702   /(x)(?<foo>y)(z)/
1703
1704 C<$+{I<foo>}> will be the same as C<$2>, and C<$3> will contain 'z' instead of
1705 the opposite which is what a .NET regex hacker might expect.
1706
1707 Currently I<NAME> is restricted to simple identifiers only.
1708 In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
1709 its Unicode extension (see L<utf8>),
1710 though it isn't extended by the locale (see L<perllocale>).
1711
1712 B<NOTE:> In order to make things easier for programmers with experience
1713 with the Python or PCRE regex engines, the pattern C<< (?PE<lt>NAMEE<gt>pattern) >>
1714 may be used instead of C<< (?<NAME>pattern) >>; however this form does not
1715 support the use of single quotes as a delimiter for the name.
1716
1717 =item C<< \k<NAME> >>
1718
1719 =item C<< \k'NAME' >>
1720
1721 Named backreference. Similar to numeric backreferences, except that
1722 the group is designated by name and not number. If multiple groups
1723 have the same name then it refers to the leftmost defined group in
1724 the current match.
1725
1726 It is an error to refer to a name not defined by a C<< (?<NAME>) >>
1727 earlier in the pattern.
1728
1729 Both forms are equivalent.
1730
1731 B<NOTE:> In order to make things easier for programmers with experience
1732 with the Python or PCRE regex engines, the pattern C<< (?P=NAME) >>
1733 may be used instead of C<< \k<NAME> >>.
1734
1735 =item C<(?{ code })>
1736 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
1737
1738 B<WARNING>: Using this feature safely requires that you understand its
1739 limitations.  Code executed that has side effects may not perform identically
1740 from version to version due to the effect of future optimisations in the regex
1741 engine.  For more information on this, see L</Embedded Code Execution
1742 Frequency>.
1743
1744 This zero-width assertion executes any embedded Perl code.  It always
1745 succeeds, and its return value is set as C<$^R>.
1746
1747 In literal patterns, the code is parsed at the same time as the
1748 surrounding code. While within the pattern, control is passed temporarily
1749 back to the perl parser, until the logically-balancing closing brace is
1750 encountered. This is similar to the way that an array index expression in
1751 a literal string is handled, for example
1752
1753     "abc$array[ 1 + f('[') + g()]def"
1754
1755 In particular, braces do not need to be balanced:
1756
1757     s/abc(?{ f('{'); })/def/
1758
1759 Even in a pattern that is interpolated and compiled at run-time, literal
1760 code blocks will be compiled once, at perl compile time; the following
1761 prints "ABCD":
1762
1763     print "D";
1764     my $qr = qr/(?{ BEGIN { print "A" } })/;
1765     my $foo = "foo";
1766     /$foo$qr(?{ BEGIN { print "B" } })/;
1767     BEGIN { print "C" }
1768
1769 In patterns where the text of the code is derived from run-time
1770 information rather than appearing literally in a source code /pattern/,
1771 the code is compiled at the same time that the pattern is compiled, and
1772 for reasons of security, C<use re 'eval'> must be in scope. This is to
1773 stop user-supplied patterns containing code snippets from being
1774 executable.
1775
1776 In situations where you need to enable this with C<use re 'eval'>, you should
1777 also have taint checking enabled.  Better yet, use the carefully
1778 constrained evaluation within a Safe compartment.  See L<perlsec> for
1779 details about both these mechanisms.
1780
1781 From the viewpoint of parsing, lexical variable scope and closures,
1782
1783     /AAA(?{ BBB })CCC/
1784
1785 behaves approximately like
1786
1787     /AAA/ && do { BBB } && /CCC/
1788
1789 Similarly,
1790
1791     qr/AAA(?{ BBB })CCC/
1792
1793 behaves approximately like
1794
1795     sub { /AAA/ && do { BBB } && /CCC/ }
1796
1797 In particular:
1798
1799     { my $i = 1; $r = qr/(?{ print $i })/ }
1800     my $i = 2;
1801     /$r/; # prints "1"
1802
1803 Inside a C<(?{...})> block, C<$_> refers to the string the regular
1804 expression is matching against. You can also use C<pos()> to know what is
1805 the current position of matching within this string.
1806
1807 The code block introduces a new scope from the perspective of lexical
1808 variable declarations, but B<not> from the perspective of C<local> and
1809 similar localizing behaviours. So later code blocks within the same
1810 pattern will still see the values which were localized in earlier blocks.
1811 These accumulated localizations are undone either at the end of a
1812 successful match, or if the assertion is backtracked (compare
1813 L</"Backtracking">). For example,
1814
1815   $_ = 'a' x 8;
1816   m<
1817      (?{ $cnt = 0 })               # Initialize $cnt.
1818      (
1819        a
1820        (?{
1821            local $cnt = $cnt + 1;  # Update $cnt,
1822                                    # backtracking-safe.
1823        })
1824      )*
1825      aaaa
1826      (?{ $res = $cnt })            # On success copy to
1827                                    # non-localized location.
1828    >x;
1829
1830 will initially increment C<$cnt> up to 8; then during backtracking, its
1831 value will be unwound back to 4, which is the value assigned to C<$res>.
1832 At the end of the regex execution, C<$cnt> will be wound back to its initial
1833 value of 0.
1834
1835 This assertion may be used as the condition in a
1836
1837     (?(condition)yes-pattern|no-pattern)
1838
1839 switch.  If I<not> used in this way, the result of evaluation of C<code>
1840 is put into the special variable C<$^R>.  This happens immediately, so
1841 C<$^R> can be used from other C<(?{ code })> assertions inside the same
1842 regular expression.
1843
1844 The assignment to C<$^R> above is properly localized, so the old
1845 value of C<$^R> is restored if the assertion is backtracked; compare
1846 L</"Backtracking">.
1847
1848 Note that the special variable C<$^N>  is particularly useful with code
1849 blocks to capture the results of submatches in variables without having to
1850 keep track of the number of nested parentheses. For example:
1851
1852   $_ = "The brown fox jumps over the lazy dog";
1853   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
1854   print "color = $color, animal = $animal\n";
1855
1856
1857 =item C<(??{ code })>
1858 X<(??{})>
1859 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
1860
1861 B<WARNING>: Using this feature safely requires that you understand its
1862 limitations.  Code executed that has side effects may not perform
1863 identically from version to version due to the effect of future
1864 optimisations in the regex engine.  For more information on this, see
1865 L</Embedded Code Execution Frequency>.
1866
1867 This is a "postponed" regular subexpression.  It behaves in I<exactly> the
1868 same way as a C<(?{ code })> code block as described above, except that
1869 its return value, rather than being assigned to C<$^R>, is treated as a
1870 pattern, compiled if it's a string (or used as-is if its a qr// object),
1871 then matched as if it were inserted instead of this construct.
1872
1873 During the matching of this sub-pattern, it has its own set of
1874 captures which are valid during the sub-match, but are discarded once
1875 control returns to the main pattern. For example, the following matches,
1876 with the inner pattern capturing "B" and matching "BB", while the outer
1877 pattern captures "A";
1878
1879     my $inner = '(.)\1';
1880     "ABBA" =~ /^(.)(??{ $inner })\1/;
1881     print $1; # prints "A";
1882
1883 Note that this means that  there is no way for the inner pattern to refer
1884 to a capture group defined outside.  (The code block itself can use C<$1>,
1885 I<etc>., to refer to the enclosing pattern's capture groups.)  Thus, although
1886
1887     ('a' x 100)=~/(??{'(.)' x 100})/
1888
1889 I<will> match, it will I<not> set C<$1> on exit.
1890
1891 The following pattern matches a parenthesized group:
1892
1893  $re = qr{
1894             \(
1895             (?:
1896                (?> [^()]+ )  # Non-parens without backtracking
1897              |
1898                (??{ $re })   # Group with matching parens
1899             )*
1900             \)
1901          }x;
1902
1903 See also
1904 L<C<(?I<PARNO>)>|/(?PARNO) (?-PARNO) (?+PARNO) (?R) (?0)>
1905 for a different, more efficient way to accomplish
1906 the same task.
1907
1908 Executing a postponed regular expression too many times without
1909 consuming any input string will also result in a fatal error.  The depth
1910 at which that happens is compiled into perl, so it can be changed with a
1911 custom build.
1912
1913 =item C<(?I<PARNO>)> C<(?-I<PARNO>)> C<(?+I<PARNO>)> C<(?R)> C<(?0)>
1914 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
1915 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
1916 X<regex, relative recursion> X<GOSUB> X<GOSTART>
1917
1918 Recursive subpattern. Treat the contents of a given capture buffer in the
1919 current pattern as an independent subpattern and attempt to match it at
1920 the current position in the string. Information about capture state from
1921 the caller for things like backreferences is available to the subpattern,
1922 but capture buffers set by the subpattern are not visible to the caller.
1923
1924 Similar to C<(??{ code })> except that it does not involve executing any
1925 code or potentially compiling a returned pattern string; instead it treats
1926 the part of the current pattern contained within a specified capture group
1927 as an independent pattern that must match at the current position. Also
1928 different is the treatment of capture buffers, unlike C<(??{ code })>
1929 recursive patterns have access to their caller's match state, so one can
1930 use backreferences safely.
1931
1932 I<PARNO> is a sequence of digits (not starting with 0) whose value reflects
1933 the paren-number of the capture group to recurse to. C<(?R)> recurses to
1934 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
1935 C<(?R)>. If I<PARNO> is preceded by a plus or minus sign then it is assumed
1936 to be relative, with negative numbers indicating preceding capture groups
1937 and positive ones following. Thus C<(?-1)> refers to the most recently
1938 declared group, and C<(?+1)> indicates the next group to be declared.
1939 Note that the counting for relative recursion differs from that of
1940 relative backreferences, in that with recursion unclosed groups B<are>
1941 included.
1942
1943 The following pattern matches a function C<foo()> which may contain
1944 balanced parentheses as the argument.
1945
1946   $re = qr{ (                   # paren group 1 (full function)
1947               foo
1948               (                 # paren group 2 (parens)
1949                 \(
1950                   (             # paren group 3 (contents of parens)
1951                   (?:
1952                    (?> [^()]+ ) # Non-parens without backtracking
1953                   |
1954                    (?2)         # Recurse to start of paren group 2
1955                   )*
1956                   )
1957                 \)
1958               )
1959             )
1960           }x;
1961
1962 If the pattern was used as follows
1963
1964     'foo(bar(baz)+baz(bop))'=~/$re/
1965         and print "\$1 = $1\n",
1966                   "\$2 = $2\n",
1967                   "\$3 = $3\n";
1968
1969 the output produced should be the following:
1970
1971     $1 = foo(bar(baz)+baz(bop))
1972     $2 = (bar(baz)+baz(bop))
1973     $3 = bar(baz)+baz(bop)
1974
1975 If there is no corresponding capture group defined, then it is a
1976 fatal error.  Recursing deeply without consuming any input string will
1977 also result in a fatal error.  The depth at which that happens is
1978 compiled into perl, so it can be changed with a custom build.
1979
1980 The following shows how using negative indexing can make it
1981 easier to embed recursive patterns inside of a C<qr//> construct
1982 for later use:
1983
1984     my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1985     if (/foo $parens \s+ \+ \s+ bar $parens/x) {
1986        # do something here...
1987     }
1988
1989 B<Note> that this pattern does not behave the same way as the equivalent
1990 PCRE or Python construct of the same form. In Perl you can backtrack into
1991 a recursed group, in PCRE and Python the recursed into group is treated
1992 as atomic. Also, modifiers are resolved at compile time, so constructs
1993 like C<(?i:(?1))> or C<(?:(?i)(?1))> do not affect how the sub-pattern will
1994 be processed.
1995
1996 =item C<(?&NAME)>
1997 X<(?&NAME)>
1998
1999 Recurse to a named subpattern. Identical to C<(?I<PARNO>)> except that the
2000 parenthesis to recurse to is determined by name. If multiple parentheses have
2001 the same name, then it recurses to the leftmost.
2002
2003 It is an error to refer to a name that is not declared somewhere in the
2004 pattern.
2005
2006 B<NOTE:> In order to make things easier for programmers with experience
2007 with the Python or PCRE regex engines the pattern C<< (?P>NAME) >>
2008 may be used instead of C<< (?&NAME) >>.
2009
2010 =item C<(?(condition)yes-pattern|no-pattern)>
2011 X<(?()>
2012
2013 =item C<(?(condition)yes-pattern)>
2014
2015 Conditional expression. Matches C<yes-pattern> if C<condition> yields
2016 a true value, matches C<no-pattern> otherwise. A missing pattern always
2017 matches.
2018
2019 C<(condition)> should be one of:
2020
2021 =over 4
2022
2023 =item an integer in parentheses
2024
2025 (which is valid if the corresponding pair of parentheses
2026 matched);
2027
2028 =item a lookahead/lookbehind/evaluate zero-width assertion;
2029
2030 =item a name in angle brackets or single quotes
2031
2032 (which is valid if a group with the given name matched);
2033
2034 =item the special symbol C<(R)>
2035
2036 (true when evaluated inside of recursion or eval).  Additionally the
2037 C<"R"> may be
2038 followed by a number, (which will be true when evaluated when recursing
2039 inside of the appropriate group), or by C<&NAME>, in which case it will
2040 be true only when evaluated during recursion in the named group.
2041
2042 =back
2043
2044 Here's a summary of the possible predicates:
2045
2046 =over 4
2047
2048 =item C<(1)> C<(2)> ...
2049
2050 Checks if the numbered capturing group has matched something.
2051 Full syntax: C<< (?(1)then|else) >>
2052
2053 =item C<(E<lt>I<NAME>E<gt>)> C<('I<NAME>')>
2054
2055 Checks if a group with the given name has matched something.
2056 Full syntax: C<< (?(<name>)then|else) >>
2057
2058 =item C<(?=...)> C<(?!...)> C<(?<=...)> C<(?<!...)>
2059
2060 Checks whether the pattern matches (or does not match, for the C<"!">
2061 variants).
2062 Full syntax: C<< (?(?=I<lookahead>)I<then>|I<else>) >>
2063
2064 =item C<(?{ I<CODE> })>
2065
2066 Treats the return value of the code block as the condition.
2067 Full syntax: C<< (?(?{ code })then|else) >>
2068
2069 =item C<(R)>
2070
2071 Checks if the expression has been evaluated inside of recursion.
2072 Full syntax: C<< (?(R)then|else) >>
2073
2074 =item C<(R1)> C<(R2)> ...
2075
2076 Checks if the expression has been evaluated while executing directly
2077 inside of the n-th capture group. This check is the regex equivalent of
2078
2079   if ((caller(0))[3] eq 'subname') { ... }
2080
2081 In other words, it does not check the full recursion stack.
2082
2083 Full syntax: C<< (?(R1)then|else) >>
2084
2085 =item C<(R&I<NAME>)>
2086
2087 Similar to C<(R1)>, this predicate checks to see if we're executing
2088 directly inside of the leftmost group with a given name (this is the same
2089 logic used by C<(?&I<NAME>)> to disambiguate). It does not check the full
2090 stack, but only the name of the innermost active recursion.
2091 Full syntax: C<< (?(R&name)then|else) >>
2092
2093 =item C<(DEFINE)>
2094
2095 In this case, the yes-pattern is never directly executed, and no
2096 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
2097 See below for details.
2098 Full syntax: C<< (?(DEFINE)definitions...) >>
2099
2100 =back
2101
2102 For example:
2103
2104     m{ ( \( )?
2105        [^()]+
2106        (?(1) \) )
2107      }x
2108
2109 matches a chunk of non-parentheses, possibly included in parentheses
2110 themselves.
2111
2112 A special form is the C<(DEFINE)> predicate, which never executes its
2113 yes-pattern directly, and does not allow a no-pattern. This allows one to
2114 define subpatterns which will be executed only by the recursion mechanism.
2115 This way, you can define a set of regular expression rules that can be
2116 bundled into any pattern you choose.
2117
2118 It is recommended that for this usage you put the DEFINE block at the
2119 end of the pattern, and that you name any subpatterns defined within it.
2120
2121 Also, it's worth noting that patterns defined this way probably will
2122 not be as efficient, as the optimizer is not very clever about
2123 handling them.
2124
2125 An example of how this might be used is as follows:
2126
2127   /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
2128    (?(DEFINE)
2129      (?<NAME_PAT>....)
2130      (?<ADDRESS_PAT>....)
2131    )/x
2132
2133 Note that capture groups matched inside of recursion are not accessible
2134 after the recursion returns, so the extra layer of capturing groups is
2135 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
2136 C<$+{NAME}> would be.
2137
2138 Finally, keep in mind that subpatterns created inside a DEFINE block
2139 count towards the absolute and relative number of captures, so this:
2140
2141     my @captures = "a" =~ /(.)                  # First capture
2142                            (?(DEFINE)
2143                                (?<EXAMPLE> 1 )  # Second capture
2144                            )/x;
2145     say scalar @captures;
2146
2147 Will output 2, not 1. This is particularly important if you intend to
2148 compile the definitions with the C<qr//> operator, and later
2149 interpolate them in another pattern.
2150
2151 =item C<< (?>pattern) >>
2152
2153 =item C<< (*atomic:pattern) >>
2154 X<(?E<gt>pattern)>
2155 X<(*atomic>
2156 X<backtrack> X<backtracking> X<atomic> X<possessive>
2157
2158 An "independent" subexpression, one which matches the substring
2159 that a I<standalone> C<pattern> would match if anchored at the given
2160 position, and it matches I<nothing other than this substring>.  This
2161 construct is useful for optimizations of what would otherwise be
2162 "eternal" matches, because it will not backtrack (see L</"Backtracking">).
2163 It may also be useful in places where the "grab all you can, and do not
2164 give anything back" semantic is desirable.
2165
2166 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
2167 (anchored at the beginning of string, as above) will match I<all>
2168 characters C<"a"> at the beginning of string, leaving no C<"a"> for
2169 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
2170 since the match of the subgroup C<a*> is influenced by the following
2171 group C<ab> (see L</"Backtracking">).  In particular, C<a*> inside
2172 C<a*ab> will match fewer characters than a standalone C<a*>, since
2173 this makes the tail match.
2174
2175 C<< (?>pattern) >> does not disable backtracking altogether once it has
2176 matched. It is still possible to backtrack past the construct, but not
2177 into it. So C<< ((?>a*)|(?>b*))ar >> will still match "bar".
2178
2179 An effect similar to C<< (?>pattern) >> may be achieved by writing
2180 C<(?=(pattern))\g{-1}>.  This matches the same substring as a standalone
2181 C<a+>, and the following C<\g{-1}> eats the matched string; it therefore
2182 makes a zero-length assertion into an analogue of C<< (?>...) >>.
2183 (The difference between these two constructs is that the second one
2184 uses a capturing group, thus shifting ordinals of backreferences
2185 in the rest of a regular expression.)
2186
2187 Consider this pattern:
2188
2189     m{ \(
2190           (
2191             [^()]+           # x+
2192           |
2193             \( [^()]* \)
2194           )+
2195        \)
2196      }x
2197
2198 That will efficiently match a nonempty group with matching parentheses
2199 two levels deep or less.  However, if there is no such group, it
2200 will take virtually forever on a long string.  That's because there
2201 are so many different ways to split a long string into several
2202 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
2203 to a subpattern of the above pattern.  Consider how the pattern
2204 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
2205 seconds, but that each extra letter doubles this time.  This
2206 exponential performance will make it appear that your program has
2207 hung.  However, a tiny change to this pattern
2208
2209     m{ \(
2210           (
2211             (?> [^()]+ )        # change x+ above to (?> x+ )
2212           |
2213             \( [^()]* \)
2214           )+
2215        \)
2216      }x
2217
2218 which uses C<< (?>...) >> matches exactly when the one above does (verifying
2219 this yourself would be a productive exercise), but finishes in a fourth
2220 the time when used on a similar string with 1000000 C<"a">s.  Be aware,
2221 however, that, when this construct is followed by a
2222 quantifier, it currently triggers a warning message under
2223 the C<use warnings> pragma or B<-w> switch saying it
2224 C<"matches null string many times in regex">.
2225
2226 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
2227 effect may be achieved by negative lookahead, as in C<[^()]+ (?! [^()] )>.
2228 This was only 4 times slower on a string with 1000000 C<"a">s.
2229
2230 The "grab all you can, and do not give anything back" semantic is desirable
2231 in many situations where on the first sight a simple C<()*> looks like
2232 the correct solution.  Suppose we parse text with comments being delimited
2233 by C<"#"> followed by some optional (horizontal) whitespace.  Contrary to
2234 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
2235 the comment delimiter, because it may "give up" some whitespace if
2236 the remainder of the pattern can be made to match that way.  The correct
2237 answer is either one of these:
2238
2239     (?>#[ \t]*)
2240     #[ \t]*(?![ \t])
2241
2242 For example, to grab non-empty comments into C<$1>, one should use either
2243 one of these:
2244
2245     / (?> \# [ \t]* ) (        .+ ) /x;
2246     /     \# [ \t]*   ( [^ \t] .* ) /x;
2247
2248 Which one you pick depends on which of these expressions better reflects
2249 the above specification of comments.
2250
2251 In some literature this construct is called "atomic matching" or
2252 "possessive matching".
2253
2254 Possessive quantifiers are equivalent to putting the item they are applied
2255 to inside of one of these constructs. The following equivalences apply:
2256
2257     Quantifier Form     Bracketing Form
2258     ---------------     ---------------
2259     PAT*+               (?>PAT*)
2260     PAT++               (?>PAT+)
2261     PAT?+               (?>PAT?)
2262     PAT{min,max}+       (?>PAT{min,max})
2263
2264 Nested C<(?E<gt>...)> constructs are not no-ops, even if at first glance
2265 they might seem to be.  This is because the nested C<(?E<gt>...)> can
2266 restrict internal backtracking that otherwise might occur.  For example,
2267
2268  "abc" =~ /(?>a[bc]*c)/
2269
2270 matches, but
2271
2272  "abc" =~ /(?>a(?>[bc]*)c)/
2273
2274 does not.
2275
2276 The alphabetic form (C<(*atomic:...)>) is experimental; using it
2277 yields a warning in the C<experimental::alpha_assertions> category.
2278
2279 =item C<(?[ ])>
2280
2281 See L<perlrecharclass/Extended Bracketed Character Classes>.
2282
2283 Note that this feature is currently L<experimental|perlpolicy/experimental>;
2284 using it yields a warning in the C<experimental::regex_sets> category.
2285
2286 =back
2287
2288 =head2 Backtracking
2289 X<backtrack> X<backtracking>
2290
2291 NOTE: This section presents an abstract approximation of regular
2292 expression behavior.  For a more rigorous (and complicated) view of
2293 the rules involved in selecting a match among possible alternatives,
2294 see L</Combining RE Pieces>.
2295
2296 A fundamental feature of regular expression matching involves the
2297 notion called I<backtracking>, which is currently used (when needed)
2298 by all regular non-possessive expression quantifiers, namely C<"*">, C<*?>, C<"+">,
2299 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
2300 internally, but the general principle outlined here is valid.
2301
2302 For a regular expression to match, the I<entire> regular expression must
2303 match, not just part of it.  So if the beginning of a pattern containing a
2304 quantifier succeeds in a way that causes later parts in the pattern to
2305 fail, the matching engine backs up and recalculates the beginning
2306 part--that's why it's called backtracking.
2307
2308 Here is an example of backtracking:  Let's say you want to find the
2309 word following "foo" in the string "Food is on the foo table.":
2310
2311     $_ = "Food is on the foo table.";
2312     if ( /\b(foo)\s+(\w+)/i ) {
2313         print "$2 follows $1.\n";
2314     }
2315
2316 When the match runs, the first part of the regular expression (C<\b(foo)>)
2317 finds a possible match right at the beginning of the string, and loads up
2318 C<$1> with "Foo".  However, as soon as the matching engine sees that there's
2319 no whitespace following the "Foo" that it had saved in C<$1>, it realizes its
2320 mistake and starts over again one character after where it had the
2321 tentative match.  This time it goes all the way until the next occurrence
2322 of "foo". The complete regular expression matches this time, and you get
2323 the expected output of "table follows foo."
2324
2325 Sometimes minimal matching can help a lot.  Imagine you'd like to match
2326 everything between "foo" and "bar".  Initially, you write something
2327 like this:
2328
2329     $_ =  "The food is under the bar in the barn.";
2330     if ( /foo(.*)bar/ ) {
2331         print "got <$1>\n";
2332     }
2333
2334 Which perhaps unexpectedly yields:
2335
2336   got <d is under the bar in the >
2337
2338 That's because C<.*> was greedy, so you get everything between the
2339 I<first> "foo" and the I<last> "bar".  Here it's more effective
2340 to use minimal matching to make sure you get the text between a "foo"
2341 and the first "bar" thereafter.
2342
2343     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
2344   got <d is under the >
2345
2346 Here's another example. Let's say you'd like to match a number at the end
2347 of a string, and you also want to keep the preceding part of the match.
2348 So you write this:
2349
2350     $_ = "I have 2 numbers: 53147";
2351     if ( /(.*)(\d*)/ ) {                                # Wrong!
2352         print "Beginning is <$1>, number is <$2>.\n";
2353     }
2354
2355 That won't work at all, because C<.*> was greedy and gobbled up the
2356 whole string. As C<\d*> can match on an empty string the complete
2357 regular expression matched successfully.
2358
2359     Beginning is <I have 2 numbers: 53147>, number is <>.
2360
2361 Here are some variants, most of which don't work:
2362
2363     $_ = "I have 2 numbers: 53147";
2364     @pats = qw{
2365         (.*)(\d*)
2366         (.*)(\d+)
2367         (.*?)(\d*)
2368         (.*?)(\d+)
2369         (.*)(\d+)$
2370         (.*?)(\d+)$
2371         (.*)\b(\d+)$
2372         (.*\D)(\d+)$
2373     };
2374
2375     for $pat (@pats) {
2376         printf "%-12s ", $pat;
2377         if ( /$pat/ ) {
2378             print "<$1> <$2>\n";
2379         } else {
2380             print "FAIL\n";
2381         }
2382     }
2383
2384 That will print out:
2385
2386     (.*)(\d*)    <I have 2 numbers: 53147> <>
2387     (.*)(\d+)    <I have 2 numbers: 5314> <7>
2388     (.*?)(\d*)   <> <>
2389     (.*?)(\d+)   <I have > <2>
2390     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
2391     (.*?)(\d+)$  <I have 2 numbers: > <53147>
2392     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
2393     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
2394
2395 As you see, this can be a bit tricky.  It's important to realize that a
2396 regular expression is merely a set of assertions that gives a definition
2397 of success.  There may be 0, 1, or several different ways that the
2398 definition might succeed against a particular string.  And if there are
2399 multiple ways it might succeed, you need to understand backtracking to
2400 know which variety of success you will achieve.
2401
2402 When using lookahead assertions and negations, this can all get even
2403 trickier.  Imagine you'd like to find a sequence of non-digits not
2404 followed by "123".  You might try to write that as
2405
2406     $_ = "ABC123";
2407     if ( /^\D*(?!123)/ ) {                # Wrong!
2408         print "Yup, no 123 in $_\n";
2409     }
2410
2411 But that isn't going to match; at least, not the way you're hoping.  It
2412 claims that there is no 123 in the string.  Here's a clearer picture of
2413 why that pattern matches, contrary to popular expectations:
2414
2415     $x = 'ABC123';
2416     $y = 'ABC445';
2417
2418     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
2419     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
2420
2421     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
2422     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
2423
2424 This prints
2425
2426     2: got ABC
2427     3: got AB
2428     4: got ABC
2429
2430 You might have expected test 3 to fail because it seems to a more
2431 general purpose version of test 1.  The important difference between
2432 them is that test 3 contains a quantifier (C<\D*>) and so can use
2433 backtracking, whereas test 1 will not.  What's happening is
2434 that you've asked "Is it true that at the start of C<$x>, following 0 or more
2435 non-digits, you have something that's not 123?"  If the pattern matcher had
2436 let C<\D*> expand to "ABC", this would have caused the whole pattern to
2437 fail.
2438
2439 The search engine will initially match C<\D*> with "ABC".  Then it will
2440 try to match C<(?!123)> with "123", which fails.  But because
2441 a quantifier (C<\D*>) has been used in the regular expression, the
2442 search engine can backtrack and retry the match differently
2443 in the hope of matching the complete regular expression.
2444
2445 The pattern really, I<really> wants to succeed, so it uses the
2446 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
2447 time.  Now there's indeed something following "AB" that is not
2448 "123".  It's "C123", which suffices.
2449
2450 We can deal with this by using both an assertion and a negation.
2451 We'll say that the first part in C<$1> must be followed both by a digit
2452 and by something that's not "123".  Remember that the lookaheads
2453 are zero-width expressions--they only look, but don't consume any
2454 of the string in their match.  So rewriting this way produces what
2455 you'd expect; that is, case 5 will fail, but case 6 succeeds:
2456
2457     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
2458     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
2459
2460     6: got ABC
2461
2462 In other words, the two zero-width assertions next to each other work as though
2463 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
2464 matches only if you're at the beginning of the line AND the end of the
2465 line simultaneously.  The deeper underlying truth is that juxtaposition in
2466 regular expressions always means AND, except when you write an explicit OR
2467 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
2468 although the attempted matches are made at different positions because "a"
2469 is not a zero-width assertion, but a one-width assertion.
2470
2471 B<WARNING>: Particularly complicated regular expressions can take
2472 exponential time to solve because of the immense number of possible
2473 ways they can use backtracking to try for a match.  For example, without
2474 internal optimizations done by the regular expression engine, this will
2475 take a painfully long time to run:
2476
2477     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
2478
2479 And if you used C<"*">'s in the internal groups instead of limiting them
2480 to 0 through 5 matches, then it would take forever--or until you ran
2481 out of stack space.  Moreover, these internal optimizations are not
2482 always applicable.  For example, if you put C<{0,5}> instead of C<"*">
2483 on the external group, no current optimization is applicable, and the
2484 match takes a long time to finish.
2485
2486 A powerful tool for optimizing such beasts is what is known as an
2487 "independent group",
2488 which does not backtrack (see L</C<< (?>pattern) >>>).  Note also that
2489 zero-length lookahead/lookbehind assertions will not backtrack to make
2490 the tail match, since they are in "logical" context: only
2491 whether they match is considered relevant.  For an example
2492 where side-effects of lookahead I<might> have influenced the
2493 following match, see L</C<< (?>pattern) >>>.
2494
2495 =head2 Script Runs
2496 X<(*script_run:...)> X<(sr:...)>
2497 X<(*atomic_script_run:...)> X<(asr:...)>
2498
2499 A script run is basically a sequence of characters, all from the same
2500 Unicode script (see L<perlunicode/Scripts>), such as Latin or Greek.  In
2501 most places a single word would never be written in multiple scripts,
2502 unless it is a spoofing attack.  An infamous example, is
2503
2504  paypal.com
2505
2506 Those letters could all be Latin (as in the example just above), or they
2507 could be all Cyrillic (except for the dot), or they could be a mixture
2508 of the two.  In the case of an internet address the C<.com> would be in
2509 Latin, And any Cyrillic ones would cause it to be a mixture, not a
2510 script run.  Someone clicking on such a link would not be directed to
2511 the real Paypal website, but an attacker would craft a look-alike one to
2512 attempt to gather sensitive information from the person.
2513
2514 Starting in Perl 5.28, it is now easy to detect strings that aren't
2515 script runs.  Simply enclose just about any pattern like either of
2516 these:
2517
2518  (*script_run:pattern)
2519  (*sr:pattern)
2520
2521 What happens is that after I<pattern> succeeds in matching, it is
2522 subjected to the additional criterion that every character in it must be
2523 from the same script (see exceptions below).  If this isn't true,
2524 backtracking occurs until something all in the same script is found that
2525 matches, or all possibilities are exhausted.  This can cause a lot of
2526 backtracking, but generally, only malicious input will result in this,
2527 though the slow down could cause a denial of service attack.  If your
2528 needs permit, it is best to make the pattern atomic to cut down on the
2529 amount of backtracking.  This is so likely to be what you want, that
2530 instead of writing this:
2531
2532  (*script_run:(?>pattern))
2533
2534 you can write either of these:
2535
2536  (*atomic_script_run:pattern)
2537  (*asr:pattern)
2538
2539 (See L</C<(?E<gt>pattern)>>.)
2540
2541 In Taiwan, Japan, and Korea, it is common for text to have a mixture of
2542 characters from their native scripts and base Chinese.  Perl follows
2543 Unicode's UTS 39 (L<http://unicode.org/reports/tr39/>) Unicode Security
2544 Mechanisms in allowing such mixtures.  For example, the Japanese scripts
2545 Katakana and Hiragana are commonly mixed together in practice, along
2546 with some Chinese characters, and hence are treated as being in a single
2547 script run by Perl.
2548
2549 The rules used for matching decimal digits are somewhat different.  Many
2550 scripts have their own sets of digits equivalent to the Western C<0>
2551 through C<9> ones.  A few, such as Arabic, have more than one set.  For
2552 a string to be considered a script run, all digits in it must come from
2553 the same set, as determined by the first digit encountered. The ASCII
2554 C<[0-9]> are accepted as being in any script, even those that have their
2555 own set.  This is because these are often used in commerce even in such
2556 scripts.  But any mixing of the ASCII and other digits will cause the
2557 sequence to not be a script run, failing the match.  As an example,
2558
2559  qr/(*script_run: \d+ \b )/x
2560
2561 guarantees that the digits matched will all be from the same set of 10.
2562 You won't get a look-alike digit from a different script that has a
2563 different value than what it appears to be.
2564
2565 Unicode has three pseudo scripts that are handled specially.
2566
2567 "Unknown" is applied to code points whose meaning has yet to be
2568 determined.  Perl currently will match as a script run, any single
2569 character string consisting of one of these code points.  But any string
2570 longer than one code point containing one of these will not be
2571 considered a script run.
2572
2573 "Inherited" is applied to characters that modify another, such as an
2574 accent of some type.  These are considered to be in the script of the
2575 master character, and so never cause a script run to not match.
2576
2577 The other one is "Common".  This consists of mostly punctuation, emoji,
2578 and characters used in mathematics and music, and the ASCII digits C<0>
2579 through C<9>.  These characters can appear intermixed in text in many of
2580 the world's scripts.  These also don't cause a script run to not match,
2581 except any ASCII digits encountered have to obey the decimal digit rules
2582 described above.
2583
2584 This construct is non-capturing.  You can add parentheses to I<pattern>
2585 to capture, if desired.  You will have to do this if you plan to use
2586 L</(*ACCEPT) (*ACCEPT:arg)> and not have it bypass the script run
2587 checking.
2588
2589 This feature is experimental, and the exact syntax and details of
2590 operation are subject to change; using it yields a warning in the
2591 C<experimental::script_run> category.
2592
2593 The C<Script_Extensions> property as modified by UTS 39
2594 (L<http://unicode.org/reports/tr39/>) is used as the basis for this
2595 feature.
2596
2597 To summarize,
2598
2599 =over 4
2600
2601 =item *
2602
2603 All length 0 or length 1 sequences are script runs.
2604
2605 =item *
2606
2607 A longer sequence is a script run if and only if B<all> of the following
2608 conditions are met:
2609
2610 Z<>
2611
2612 =over
2613
2614 =item 1
2615
2616 No code point in the sequence has the C<Script_Extension> property of
2617 C<Unknown>.
2618
2619 This currently means that all code points in the sequence have been
2620 assigned by Unicode to be characters that aren't private use nor
2621 surrogate code points.
2622
2623 =item 2
2624
2625 All characters in the sequence come from the Common script and/or the
2626 Inherited script and/or a single other script.
2627
2628 The script of a character is determined by the C<Script_Extensions>
2629 property as modified by UTS 39 (L<http://unicode.org/reports/tr39/>), as
2630 described above.
2631
2632 =item 3
2633
2634 All decimal digits in the sequence come from the same block of 10
2635 consecutive digits.
2636
2637 =back
2638
2639 =back
2640
2641 =head2 Special Backtracking Control Verbs
2642
2643 These special patterns are generally of the form C<(*I<VERB>:I<ARG>)>. Unless
2644 otherwise stated the I<ARG> argument is optional; in some cases, it is
2645 mandatory.
2646
2647 Any pattern containing a special backtracking verb that allows an argument
2648 has the special behaviour that when executed it sets the current package's
2649 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
2650 rules apply:
2651
2652 On failure, the C<$REGERROR> variable will be set to the I<ARG> value of the
2653 verb pattern, if the verb was involved in the failure of the match. If the
2654 I<ARG> part of the pattern was omitted, then C<$REGERROR> will be set to the
2655 name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
2656 none. Also, the C<$REGMARK> variable will be set to FALSE.
2657
2658 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
2659 the C<$REGMARK> variable will be set to the name of the last
2660 C<(*MARK:NAME)> pattern executed.  See the explanation for the
2661 C<(*MARK:NAME)> verb below for more details.
2662
2663 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
2664 and most other regex-related variables. They are not local to a scope, nor
2665 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
2666 They are set in the package containing the code that I<executed> the regex
2667 (rather than the one that compiled it, where those differ).  If necessary, you
2668 can use C<local> to localize changes to these variables to a specific scope
2669 before executing a regex.
2670
2671 If a pattern does not contain a special backtracking verb that allows an
2672 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
2673
2674 =over 3
2675
2676 =item Verbs
2677
2678 =over 4
2679
2680 =item C<(*PRUNE)> C<(*PRUNE:NAME)>
2681 X<(*PRUNE)> X<(*PRUNE:NAME)>
2682
2683 This zero-width pattern prunes the backtracking tree at the current point
2684 when backtracked into on failure. Consider the pattern C</I<A> (*PRUNE) I<B>/>,
2685 where I<A> and I<B> are complex patterns. Until the C<(*PRUNE)> verb is reached,
2686 I<A> may backtrack as necessary to match. Once it is reached, matching
2687 continues in I<B>, which may also backtrack as necessary; however, should B
2688 not match, then no further backtracking will take place, and the pattern
2689 will fail outright at the current starting position.
2690
2691 The following example counts all the possible matching strings in a
2692 pattern (without actually matching any of them).
2693
2694     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
2695     print "Count=$count\n";
2696
2697 which produces:
2698
2699     aaab
2700     aaa
2701     aa
2702     a
2703     aab
2704     aa
2705     a
2706     ab
2707     a
2708     Count=9
2709
2710 If we add a C<(*PRUNE)> before the count like the following
2711
2712     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
2713     print "Count=$count\n";
2714
2715 we prevent backtracking and find the count of the longest matching string
2716 at each matching starting point like so:
2717
2718     aaab
2719     aab
2720     ab
2721     Count=3
2722
2723 Any number of C<(*PRUNE)> assertions may be used in a pattern.
2724
2725 See also C<<< L<< /(?>pattern) >> >>> and possessive quantifiers for
2726 other ways to
2727 control backtracking. In some cases, the use of C<(*PRUNE)> can be
2728 replaced with a C<< (?>pattern) >> with no functional difference; however,
2729 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
2730 C<< (?>pattern) >> alone.
2731
2732 =item C<(*SKIP)> C<(*SKIP:NAME)>
2733 X<(*SKIP)>
2734
2735 This zero-width pattern is similar to C<(*PRUNE)>, except that on
2736 failure it also signifies that whatever text that was matched leading up
2737 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
2738 of this pattern. This effectively means that the regex engine "skips" forward
2739 to this position on failure and tries to match again, (assuming that
2740 there is sufficient room to match).
2741
2742 The name of the C<(*SKIP:NAME)> pattern has special significance. If a
2743 C<(*MARK:NAME)> was encountered while matching, then it is that position
2744 which is used as the "skip point". If no C<(*MARK)> of that name was
2745 encountered, then the C<(*SKIP)> operator has no effect. When used
2746 without a name the "skip point" is where the match point was when
2747 executing the C<(*SKIP)> pattern.
2748
2749 Compare the following to the examples in C<(*PRUNE)>; note the string
2750 is twice as long:
2751
2752  'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
2753  print "Count=$count\n";
2754
2755 outputs
2756
2757     aaab
2758     aaab
2759     Count=2
2760
2761 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
2762 executed, the next starting point will be where the cursor was when the
2763 C<(*SKIP)> was executed.
2764
2765 =item C<(*MARK:NAME)> C<(*:NAME)>
2766 X<(*MARK)> X<(*MARK:NAME)> X<(*:NAME)>
2767
2768 This zero-width pattern can be used to mark the point reached in a string
2769 when a certain part of the pattern has been successfully matched. This
2770 mark may be given a name. A later C<(*SKIP)> pattern will then skip
2771 forward to that point if backtracked into on failure. Any number of
2772 C<(*MARK)> patterns are allowed, and the I<NAME> portion may be duplicated.
2773
2774 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
2775 can be used to "label" a pattern branch, so that after matching, the
2776 program can determine which branches of the pattern were involved in the
2777 match.
2778
2779 When a match is successful, the C<$REGMARK> variable will be set to the
2780 name of the most recently executed C<(*MARK:NAME)> that was involved
2781 in the match.
2782
2783 This can be used to determine which branch of a pattern was matched
2784 without using a separate capture group for each branch, which in turn
2785 can result in a performance improvement, as perl cannot optimize
2786 C</(?:(x)|(y)|(z))/> as efficiently as something like
2787 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
2788
2789 When a match has failed, and unless another verb has been involved in
2790 failing the match and has provided its own name to use, the C<$REGERROR>
2791 variable will be set to the name of the most recently executed
2792 C<(*MARK:NAME)>.
2793
2794 See L</(*SKIP)> for more details.
2795
2796 As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
2797
2798 =item C<(*THEN)> C<(*THEN:NAME)>
2799
2800 This is similar to the "cut group" operator C<::> from Perl 6.  Like
2801 C<(*PRUNE)>, this verb always matches, and when backtracked into on
2802 failure, it causes the regex engine to try the next alternation in the
2803 innermost enclosing group (capturing or otherwise) that has alternations.
2804 The two branches of a C<(?(condition)yes-pattern|no-pattern)> do not
2805 count as an alternation, as far as C<(*THEN)> is concerned.
2806
2807 Its name comes from the observation that this operation combined with the
2808 alternation operator (C<"|">) can be used to create what is essentially a
2809 pattern-based if/then/else block:
2810
2811   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
2812
2813 Note that if this operator is used and NOT inside of an alternation then
2814 it acts exactly like the C<(*PRUNE)> operator.
2815
2816   / A (*PRUNE) B /
2817
2818 is the same as
2819
2820   / A (*THEN) B /
2821
2822 but
2823
2824   / ( A (*THEN) B | C ) /
2825
2826 is not the same as
2827
2828   / ( A (*PRUNE) B | C ) /
2829
2830 as after matching the I<A> but failing on the I<B> the C<(*THEN)> verb will
2831 backtrack and try I<C>; but the C<(*PRUNE)> verb will simply fail.
2832
2833 =item C<(*COMMIT)> C<(*COMMIT:args)>
2834 X<(*COMMIT)>
2835
2836 This is the Perl 6 "commit pattern" C<< <commit> >> or C<:::>. It's a
2837 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
2838 into on failure it causes the match to fail outright. No further attempts
2839 to find a valid match by advancing the start pointer will occur again.
2840 For example,
2841
2842  'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
2843  print "Count=$count\n";
2844
2845 outputs
2846
2847     aaab
2848     Count=1
2849
2850 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
2851 does not match, the regex engine will not try any further matching on the
2852 rest of the string.
2853
2854 =item C<(*FAIL)> C<(*F)> C<(*FAIL:arg)>
2855 X<(*FAIL)> X<(*F)>
2856
2857 This pattern matches nothing and always fails. It can be used to force the
2858 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
2859 fact, C<(?!)> gets optimised into C<(*FAIL)> internally. You can provide
2860 an argument so that if the match fails because of this C<FAIL> directive
2861 the argument can be obtained from C<$REGERROR>.
2862
2863 It is probably useful only when combined with C<(?{})> or C<(??{})>.
2864
2865 =item C<(*ACCEPT)> C<(*ACCEPT:arg)>
2866 X<(*ACCEPT)>
2867
2868 This pattern matches nothing and causes the end of successful matching at
2869 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
2870 whether there is actually more to match in the string. When inside of a
2871 nested pattern, such as recursion, or in a subpattern dynamically generated
2872 via C<(??{})>, only the innermost pattern is ended immediately.
2873
2874 If the C<(*ACCEPT)> is inside of capturing groups then the groups are
2875 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
2876 For instance:
2877
2878   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
2879
2880 will match, and C<$1> will be C<AB> and C<$2> will be C<"B">, C<$3> will not
2881 be set. If another branch in the inner parentheses was matched, such as in the
2882 string 'ACDE', then the C<"D"> and C<"E"> would have to be matched as well.
2883
2884 You can provide an argument, which will be available in the var
2885 C<$REGMARK> after the match completes.
2886
2887 =back
2888
2889 =back
2890
2891 =head2 Warning on C<\1> Instead of C<$1>
2892
2893 Some people get too used to writing things like:
2894
2895     $pattern =~ s/(\W)/\\\1/g;
2896
2897 This is grandfathered (for \1 to \9) for the RHS of a substitute to avoid
2898 shocking the
2899 B<sed> addicts, but it's a dirty habit to get into.  That's because in
2900 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
2901 the usual double-quoted string means a control-A.  The customary Unix
2902 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
2903 of doing that, you get yourself into trouble if you then add an C</e>
2904 modifier.
2905
2906     s/(\d+)/ \1 + 1 /eg;            # causes warning under -w
2907
2908 Or if you try to do
2909
2910     s/(\d+)/\1000/;
2911
2912 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
2913 C<${1}000>.  The operation of interpolation should not be confused
2914 with the operation of matching a backreference.  Certainly they mean two
2915 different things on the I<left> side of the C<s///>.
2916
2917 =head2 Repeated Patterns Matching a Zero-length Substring
2918
2919 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
2920
2921 Regular expressions provide a terse and powerful programming language.  As
2922 with most other power tools, power comes together with the ability
2923 to wreak havoc.
2924
2925 A common abuse of this power stems from the ability to make infinite
2926 loops using regular expressions, with something as innocuous as:
2927
2928     'foo' =~ m{ ( o? )* }x;
2929
2930 The C<o?> matches at the beginning of "C<foo>", and since the position
2931 in the string is not moved by the match, C<o?> would match again and again
2932 because of the C<"*"> quantifier.  Another common way to create a similar cycle
2933 is with the looping modifier C</g>:
2934
2935     @matches = ( 'foo' =~ m{ o? }xg );
2936
2937 or
2938
2939     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
2940
2941 or the loop implied by C<split()>.
2942
2943 However, long experience has shown that many programming tasks may
2944 be significantly simplified by using repeated subexpressions that
2945 may match zero-length substrings.  Here's a simple example being:
2946
2947     @chars = split //, $string;           # // is not magic in split
2948     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
2949
2950 Thus Perl allows such constructs, by I<forcefully breaking
2951 the infinite loop>.  The rules for this are different for lower-level
2952 loops given by the greedy quantifiers C<*+{}>, and for higher-level
2953 ones like the C</g> modifier or C<split()> operator.
2954
2955 The lower-level loops are I<interrupted> (that is, the loop is
2956 broken) when Perl detects that a repeated expression matched a
2957 zero-length substring.   Thus
2958
2959    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
2960
2961 is made equivalent to
2962
2963    m{ (?: NON_ZERO_LENGTH )* (?: ZERO_LENGTH )? }x;
2964
2965 For example, this program
2966
2967    #!perl -l
2968    "aaaaab" =~ /
2969      (?:
2970         a                 # non-zero
2971         |                 # or
2972        (?{print "hello"}) # print hello whenever this
2973                           #    branch is tried
2974        (?=(b))            # zero-width assertion
2975      )*  # any number of times
2976     /x;
2977    print $&;
2978    print $1;
2979
2980 prints
2981
2982    hello
2983    aaaaa
2984    b
2985
2986 Notice that "hello" is only printed once, as when Perl sees that the sixth
2987 iteration of the outermost C<(?:)*> matches a zero-length string, it stops
2988 the C<"*">.
2989
2990 The higher-level loops preserve an additional state between iterations:
2991 whether the last match was zero-length.  To break the loop, the following
2992 match after a zero-length match is prohibited to have a length of zero.
2993 This prohibition interacts with backtracking (see L</"Backtracking">),
2994 and so the I<second best> match is chosen if the I<best> match is of
2995 zero length.
2996
2997 For example:
2998
2999     $_ = 'bar';
3000     s/\w??/<$&>/g;
3001
3002 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
3003 match given by non-greedy C<??> is the zero-length match, and the I<second
3004 best> match is what is matched by C<\w>.  Thus zero-length matches
3005 alternate with one-character-long matches.
3006
3007 Similarly, for repeated C<m/()/g> the second-best match is the match at the
3008 position one notch further in the string.
3009
3010 The additional state of being I<matched with zero-length> is associated with
3011 the matched string, and is reset by each assignment to C<pos()>.
3012 Zero-length matches at the end of the previous match are ignored
3013 during C<split>.
3014
3015 =head2 Combining RE Pieces
3016
3017 Each of the elementary pieces of regular expressions which were described
3018 before (such as C<ab> or C<\Z>) could match at most one substring
3019 at the given position of the input string.  However, in a typical regular
3020 expression these elementary pieces are combined into more complicated
3021 patterns using combining operators C<ST>, C<S|T>, C<S*> I<etc>.
3022 (in these examples C<"S"> and C<"T"> are regular subexpressions).
3023
3024 Such combinations can include alternatives, leading to a problem of choice:
3025 if we match a regular expression C<a|ab> against C<"abc">, will it match
3026 substring C<"a"> or C<"ab">?  One way to describe which substring is
3027 actually matched is the concept of backtracking (see L</"Backtracking">).
3028 However, this description is too low-level and makes you think
3029 in terms of a particular implementation.
3030
3031 Another description starts with notions of "better"/"worse".  All the
3032 substrings which may be matched by the given regular expression can be
3033 sorted from the "best" match to the "worst" match, and it is the "best"
3034 match which is chosen.  This substitutes the question of "what is chosen?"
3035 by the question of "which matches are better, and which are worse?".
3036
3037 Again, for elementary pieces there is no such question, since at most
3038 one match at a given position is possible.  This section describes the
3039 notion of better/worse for combining operators.  In the description
3040 below C<"S"> and C<"T"> are regular subexpressions.
3041
3042 =over 4
3043
3044 =item C<ST>
3045
3046 Consider two possible matches, C<AB> and C<A'B'>, C<"A"> and C<A'> are
3047 substrings which can be matched by C<"S">, C<"B"> and C<B'> are substrings
3048 which can be matched by C<"T">.
3049
3050 If C<"A"> is a better match for C<"S"> than C<A'>, C<AB> is a better
3051 match than C<A'B'>.
3052
3053 If C<"A"> and C<A'> coincide: C<AB> is a better match than C<AB'> if
3054 C<"B"> is a better match for C<"T"> than C<B'>.
3055
3056 =item C<S|T>
3057
3058 When C<"S"> can match, it is a better match than when only C<"T"> can match.
3059
3060 Ordering of two matches for C<"S"> is the same as for C<"S">.  Similar for
3061 two matches for C<"T">.
3062
3063 =item C<S{REPEAT_COUNT}>
3064
3065 Matches as C<SSS...S> (repeated as many times as necessary).
3066
3067 =item C<S{min,max}>
3068
3069 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
3070
3071 =item C<S{min,max}?>
3072
3073 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
3074
3075 =item C<S?>, C<S*>, C<S+>
3076
3077 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
3078
3079 =item C<S??>, C<S*?>, C<S+?>
3080
3081 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
3082
3083 =item C<< (?>S) >>
3084
3085 Matches the best match for C<"S"> and only that.
3086
3087 =item C<(?=S)>, C<(?<=S)>
3088
3089 Only the best match for C<"S"> is considered.  (This is important only if
3090 C<"S"> has capturing parentheses, and backreferences are used somewhere
3091 else in the whole regular expression.)
3092
3093 =item C<(?!S)>, C<(?<!S)>
3094
3095 For this grouping operator there is no need to describe the ordering, since
3096 only whether or not C<"S"> can match is important.
3097
3098 =item C<(??{ EXPR })>, C<(?I<PARNO>)>
3099
3100 The ordering is the same as for the regular expression which is
3101 the result of EXPR, or the pattern contained by capture group I<PARNO>.
3102
3103 =item C<(?(condition)yes-pattern|no-pattern)>
3104
3105 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
3106 already determined.  The ordering of the matches is the same as for the
3107 chosen subexpression.
3108
3109 =back
3110
3111 The above recipes describe the ordering of matches I<at a given position>.
3112 One more rule is needed to understand how a match is determined for the
3113 whole regular expression: a match at an earlier position is always better
3114 than a match at a later position.
3115
3116 =head2 Creating Custom RE Engines
3117
3118 As of Perl 5.10.0, one can create custom regular expression engines.  This
3119 is not for the faint of heart, as they have to plug in at the C level.  See
3120 L<perlreapi> for more details.
3121
3122 As an alternative, overloaded constants (see L<overload>) provide a simple
3123 way to extend the functionality of the RE engine, by substituting one
3124 pattern for another.
3125
3126 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
3127 matches at a boundary between whitespace characters and non-whitespace
3128 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
3129 at these positions, so we want to have each C<\Y|> in the place of the
3130 more complicated version.  We can create a module C<customre> to do
3131 this:
3132
3133     package customre;
3134     use overload;
3135
3136     sub import {
3137       shift;
3138       die "No argument to customre::import allowed" if @_;
3139       overload::constant 'qr' => \&convert;
3140     }
3141
3142     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
3143
3144     # We must also take care of not escaping the legitimate \\Y|
3145     # sequence, hence the presence of '\\' in the conversion rules.
3146     my %rules = ( '\\' => '\\\\',
3147                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
3148     sub convert {
3149       my $re = shift;
3150       $re =~ s{
3151                 \\ ( \\ | Y . )
3152               }
3153               { $rules{$1} or invalid($re,$1) }sgex;
3154       return $re;
3155     }
3156
3157 Now C<use customre> enables the new escape in constant regular
3158 expressions, I<i.e.>, those without any runtime variable interpolations.
3159 As documented in L<overload>, this conversion will work only over
3160 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
3161 part of this regular expression needs to be converted explicitly
3162 (but only if the special meaning of C<\Y|> should be enabled inside C<$re>):
3163
3164     use customre;
3165     $re = <>;
3166     chomp $re;
3167     $re = customre::convert $re;
3168     /\Y|$re\Y|/;
3169
3170 =head2 Embedded Code Execution Frequency
3171
3172 The exact rules for how often C<(??{})> and C<(?{})> are executed in a pattern
3173 are unspecified.  In the case of a successful match you can assume that
3174 they DWIM and will be executed in left to right order the appropriate
3175 number of times in the accepting path of the pattern as would any other
3176 meta-pattern.  How non-accepting pathways and match failures affect the
3177 number of times a pattern is executed is specifically unspecified and
3178 may vary depending on what optimizations can be applied to the pattern
3179 and is likely to change from version to version.
3180
3181 For instance in
3182
3183   "aaabcdeeeee"=~/a(?{print "a"})b(?{print "b"})cde/;
3184
3185 the exact number of times "a" or "b" are printed out is unspecified for
3186 failure, but you may assume they will be printed at least once during
3187 a successful match, additionally you may assume that if "b" is printed,
3188 it will be preceded by at least one "a".
3189
3190 In the case of branching constructs like the following:
3191
3192   /a(b|(?{ print "a" }))c(?{ print "c" })/;
3193
3194 you can assume that the input "ac" will output "ac", and that "abc"
3195 will output only "c".
3196
3197 When embedded code is quantified, successful matches will call the
3198 code once for each matched iteration of the quantifier.  For
3199 example:
3200
3201   "good" =~ /g(?:o(?{print "o"}))*d/;
3202
3203 will output "o" twice.
3204
3205 =head2 PCRE/Python Support
3206
3207 As of Perl 5.10.0, Perl supports several Python/PCRE-specific extensions
3208 to the regex syntax. While Perl programmers are encouraged to use the
3209 Perl-specific syntax, the following are also accepted:
3210
3211 =over 4
3212
3213 =item C<< (?PE<lt>NAMEE<gt>pattern) >>
3214
3215 Define a named capture group. Equivalent to C<< (?<NAME>pattern) >>.
3216
3217 =item C<< (?P=NAME) >>
3218
3219 Backreference to a named capture group. Equivalent to C<< \g{NAME} >>.
3220
3221 =item C<< (?P>NAME) >>
3222
3223 Subroutine call to a named capture group. Equivalent to C<< (?&NAME) >>.
3224
3225 =back
3226
3227 =head1 BUGS
3228
3229 There are a number of issues with regard to case-insensitive matching
3230 in Unicode rules.  See C<"i"> under L</Modifiers> above.
3231
3232 This document varies from difficult to understand to completely
3233 and utterly opaque.  The wandering prose riddled with jargon is
3234 hard to fathom in several places.
3235
3236 This document needs a rewrite that separates the tutorial content
3237 from the reference content.
3238
3239 =head1 SEE ALSO
3240
3241 The syntax of patterns used in Perl pattern matching evolved from those
3242 supplied in the Bell Labs Research Unix 8th Edition (Version 8) regex
3243 routines.  (The code is actually derived (distantly) from Henry
3244 Spencer's freely redistributable reimplementation of those V8 routines.)
3245
3246 L<perlrequick>.
3247
3248 L<perlretut>.
3249
3250 L<perlop/"Regexp Quote-Like Operators">.
3251
3252 L<perlop/"Gory details of parsing quoted constructs">.
3253
3254 L<perlfaq6>.
3255
3256 L<perlfunc/pos>.
3257
3258 L<perllocale>.
3259
3260 L<perlebcdic>.
3261
3262 I<Mastering Regular Expressions> by Jeffrey Friedl, published
3263 by O'Reilly and Associates.