This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
op/stat.t test 9 failing on recent cygwin snapshots
[perl5.git] / t / op / stat.t
1 #!./perl
2
3 BEGIN {
4     chdir 't' if -d 't';
5     @INC = '../lib';
6     require './test.pl';        # for which_perl() etc
7 }
8
9 use Config;
10 use File::Spec;
11
12 plan tests => 78;
13
14 my $Perl = which_perl();
15
16 $Is_Amiga   = $^O eq 'amigaos';
17 $Is_Cygwin  = $^O eq 'cygwin';
18 $Is_Darwin  = $^O eq 'darwin';
19 $Is_Dos     = $^O eq 'dos';
20 $Is_MacOS   = $^O eq 'MacOS';
21 $Is_MPE     = $^O eq 'mpeix';
22 $Is_MSWin32 = $^O eq 'MSWin32';
23 $Is_NetWare = $^O eq 'NetWare';
24 $Is_OS2     = $^O eq 'os2';
25 $Is_Solaris = $^O eq 'solaris';
26 $Is_VMS     = $^O eq 'VMS';
27 $Is_DGUX    = $^O eq 'dgux';
28 $Is_MPRAS   = $^O =~ /svr4/ && -f '/etc/.relid';
29 $Is_Rhapsody= $^O eq 'rhapsody';
30
31 $Is_Dosish  = $Is_Dos || $Is_OS2 || $Is_MSWin32 || $Is_NetWare || $Is_Cygwin;
32
33 $Is_UFS     = $Is_Darwin && (() = `df -t ufs .`) == 2;
34
35 my($DEV, $INO, $MODE, $NLINK, $UID, $GID, $RDEV, $SIZE,
36    $ATIME, $MTIME, $CTIME, $BLKSIZE, $BLOCKS) = (0..12);
37
38 my $Curdir = File::Spec->curdir;
39
40
41 my $tmpfile = 'Op_stat.tmp';
42 my $tmpfile_link = $tmpfile.'2';
43
44
45 1 while unlink $tmpfile;
46 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
47 close FOO;
48
49 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
50
51 my($nlink, $mtime, $ctime) = (stat(FOO))[$NLINK, $MTIME, $CTIME];
52 SKIP: {
53     skip "No link count", 1 if $Is_VMS;
54
55     is($nlink, 1, 'nlink on regular file');
56 }
57
58 SKIP: {
59   skip "mtime and ctime not reliable", 2
60     if $Is_MSWin32 or $Is_NetWare or $Is_Cygwin or $Is_Dos or $Is_MacOS;
61
62   ok( $mtime,           'mtime' );
63   is( $mtime, $ctime,   'mtime == ctime' );
64 }
65
66
67 # Cygwin seems to have a 3 second granularity on its timestamps.
68 my $funky_FAT_timestamps = $Is_Cygwin;
69 sleep 3 if $funky_FAT_timestamps;
70
71 print FOO "Now is the time for all good men to come to.\n";
72 close(FOO);
73
74 sleep 2;
75
76
77 SKIP: {
78     unlink $tmpfile_link;
79     my $lnk_result = eval { link $tmpfile, $tmpfile_link };
80     skip "link() unimplemented", 6 if $@ =~ /unimplemented/;
81
82     is( $@, '',         'link() implemented' );
83     ok( $lnk_result,    'linked tmp testfile' );
84     ok( chmod(0644, $tmpfile),             'chmoded tmp testfile' );
85
86     my($nlink, $mtime, $ctime) = (stat($tmpfile))[$NLINK, $MTIME, $CTIME];
87
88     SKIP: {
89         skip "No link count", 1 if $Config{dont_use_nlink};
90         skip "Cygwin9X fakes hard links by copying", 1
91           if $Config{myuname} =~ /^cygwin_(?:9\d|me)\b/i;
92
93         is($nlink, 2,     'Link count on hard linked file' );
94     }
95
96     SKIP: {
97         my $cwd = File::Spec->rel2abs($Curdir);
98         skip "Solaris tmpfs has different mtime/ctime link semantics", 2
99                                      if $Is_Solaris and $cwd =~ m#^/tmp# and
100                                         $mtime && $mtime == $ctime;
101         skip "AFS has different mtime/ctime link semantics", 2
102                                      if $cwd =~ m#$Config{'afsroot'}/#;
103         skip "AmigaOS has different mtime/ctime link semantics", 2
104                                      if $Is_Amiga;
105         # Win32 could pass $mtime test but as FAT and NTFS have
106         # no ctime concept $ctime is ALWAYS == $mtime
107         # expect netware to be the same ...
108         skip "No ctime concept on this OS", 2
109                                      if $Is_MSWin32 || 
110                                         ($Is_Darwin && $Is_UFS);
111
112         if( !ok($mtime, 'hard link mtime') ||
113             !isnt($mtime, $ctime, 'hard link ctime != mtime') ) {
114             print STDERR <<DIAG;
115 # Check if you are on a tmpfs of some sort.  Building in /tmp sometimes
116 # has this problem.  Building on the ClearCase VOBS filesystem may also
117 # cause this failure.
118 #
119 # Darwin's UFS doesn't have a ctime concept, and thus is expected to fail
120 # this test.
121 DIAG
122         }
123     }
124
125 }
126
127 # truncate and touch $tmpfile.
128 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
129 close F;
130
131 ok(-z $tmpfile,     '-z on empty file');
132 ok(! -s $tmpfile,   '   and -s');
133
134 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
135 print F "hi\n";
136 close F;
137
138 ok(! -z $tmpfile,   '-z on non-empty file');
139 ok(-s $tmpfile,     '   and -s');
140
141
142 # Strip all access rights from the file.
143 ok( chmod(0000, $tmpfile),     'chmod 0000' );
144
145 SKIP: {
146     skip "-r, -w and -x have different meanings on VMS", 3 if $Is_VMS;
147
148     SKIP: {
149         # Going to try to switch away from root.  Might not work.
150         my $olduid = $>;
151         eval { $> = 1; };
152         skip "Can't test -r or -w meaningfully if you're superuser", 2
153           if $> == 0;
154
155         SKIP: {
156             skip "Can't test -r meaningfully?", 1 if $Is_Dos || $Is_Cygwin;
157             ok(!-r $tmpfile,    "   -r");
158         }
159
160         ok(!-w $tmpfile,    "   -w");
161
162         # switch uid back (may not be implemented)
163         eval { $> = $olduid; };
164     }
165
166     ok(! -x $tmpfile,   '   -x');
167 }
168
169
170
171
172 # in ms windows, $tmpfile inherits owner uid from directory
173 # not sure about os/2, but chown is harmless anyway
174 eval { chown $>,$tmpfile; 1 } or print "# $@" ;
175
176 ok(chmod(0700,$tmpfile),    'chmod 0700');
177 ok(-r $tmpfile,     '   -r');
178 ok(-w $tmpfile,     '   -w');
179
180 SKIP: {
181     skip "-x simply determines if a file ends in an executable suffix", 1
182       if $Is_Dosish || $Is_MacOS;
183
184     ok(-x $tmpfile,     '   -x');
185 }
186
187 ok(  -f $tmpfile,   '   -f');
188 ok(! -d $tmpfile,   '   !-d');
189
190 # Is this portable?
191 ok(  -d $Curdir,          '-d cwd' );
192 ok(! -f $Curdir,          '!-f cwd' );
193
194
195 SKIP: {
196     unlink($tmpfile_link);
197     my $symlink_rslt = eval { symlink $tmpfile, $tmpfile_link };
198     skip "symlink not implemented", 3 if $@ =~ /unimplemented/;
199
200     is( $@, '',     'symlink() implemented' );
201     ok( $symlink_rslt,      'symlink() ok' );
202     ok(-l $tmpfile_link,    '-l');
203 }
204
205 ok(-o $tmpfile,     '-o');
206
207 ok(-e $tmpfile,     '-e');
208
209 unlink($tmpfile_link);
210 ok(! -e $tmpfile_link,  '   -e on unlinked file');
211
212 SKIP: {
213     skip "No character, socket or block special files", 6
214       if $Is_MSWin32 || $Is_NetWare || $Is_Dos;
215     skip "/dev isn't available to test against", 6
216       unless -d '/dev' && -r '/dev' && -x '/dev';
217     skip "Skipping: unexpected ls output in MP-RAS", 6
218       if $Is_MPRAS;
219
220     my $LS  = $Config{d_readlink} ? "ls -lL" : "ls -l";
221     my $CMD = "$LS /dev 2>/dev/null";
222     my $DEV = qx($CMD);
223
224     skip "$CMD failed", 6 if $DEV eq '';
225
226     my @DEV = do { my $dev; opendir($dev, "/dev") ? readdir($dev) : () };
227
228     skip "opendir failed: $!", 6 if @DEV == 0;
229
230     # /dev/stdout might be either character special or a named pipe,
231     # or a symlink, or a socket, depending on which OS and how are
232     # you running the test, so let's censor that one away.
233     # Similar remarks hold for stderr.
234     $DEV =~ s{^[cpls].+?\sstdout$}{}m;
235     @DEV =  grep { $_ ne 'stdout' } @DEV;
236     $DEV =~ s{^[cpls].+?\sstderr$}{}m;
237     @DEV =  grep { $_ ne 'stderr' } @DEV;
238
239     # /dev/printer is also naughty: in IRIX it shows up as
240     # Srwx-----, not srwx------.
241     $DEV =~ s{^.+?\sprinter$}{}m;
242     @DEV =  grep { $_ ne 'printer' } @DEV;
243
244     # If running as root, we will see .files in the ls result,
245     # and readdir() will see them always.  Potential for conflict,
246     # so let's weed them out.
247     $DEV =~ s{^.+?\s\..+?$}{}m;
248     @DEV =  grep { ! m{^\..+$} } @DEV;
249
250     # Irix ls -l marks sockets with 'S' while 's' is a 'XENIX semaphore'.
251     if ($^O eq 'irix') {
252         $DEV =~ s{^S(.+?)}{s$1}mg;
253     }
254
255     my $try = sub {
256         my @c1 = eval qq[\$DEV =~ /^$_[0].*/mg];
257         my @c2 = eval qq[grep { $_[1] "/dev/\$_" } \@DEV];
258         my $c1 = scalar @c1;
259         my $c2 = scalar @c2;
260         is($c1, $c2, "ls and $_[1] agreeing on /dev ($c1 $c2)");
261     };
262
263 SKIP: {
264     skip("DG/UX ls -L broken", 3) if $Is_DGUX;
265
266     $try->('b', '-b');
267     $try->('c', '-c');
268     $try->('s', '-S');
269
270 }
271
272 ok(! -b $Curdir,    '!-b cwd');
273 ok(! -c $Curdir,    '!-c cwd');
274 ok(! -S $Curdir,    '!-S cwd');
275
276 }
277
278 SKIP: {
279     my($cnt, $uid);
280     $cnt = $uid = 0;
281
282     # Find a set of directories that's very likely to have setuid files
283     # but not likely to be *all* setuid files.
284     my @bin = grep {-d && -r && -x} qw(/sbin /usr/sbin /bin /usr/bin);
285     skip "Can't find a setuid file to test with", 3 unless @bin;
286
287     for my $bin (@bin) {
288         opendir BIN, $bin or die "Can't opendir $bin: $!";
289         while (defined($_ = readdir BIN)) {
290             $_ = "$bin/$_";
291             $cnt++;
292             $uid++ if -u;
293             last if $uid && $uid < $cnt;
294         }
295     }
296     closedir BIN;
297
298     skip "No setuid programs", 3 if $uid == 0;
299
300     isnt($cnt, 0,    'found some programs');
301     isnt($uid, 0,    '  found some setuid programs');
302     ok($uid < $cnt,  "    they're not all setuid");
303 }
304
305
306 # To assist in automated testing when a controlling terminal (/dev/tty)
307 # may not be available (at, cron  rsh etc), the PERL_SKIP_TTY_TEST env var
308 # can be set to skip the tests that need a tty.
309 SKIP: {
310     skip "These tests require a TTY", 4 if $ENV{PERL_SKIP_TTY_TEST};
311
312     my $TTY = $Is_Rhapsody ? "/dev/ttyp0" : "/dev/tty";
313
314     SKIP: {
315         skip "Test uses unixisms", 2 if $Is_MSWin32 || $Is_NetWare;
316         skip "No TTY to test -t with", 2 unless -e $TTY;
317
318         open(TTY, $TTY) ||
319           warn "Can't open $TTY--run t/TEST outside of make.\n";
320         ok(-t TTY,  '-t');
321         ok(-c TTY,  'tty is -c');
322         close(TTY);
323     }
324     ok(! -t TTY,    '!-t on closed TTY filehandle');
325
326     {
327         local $TODO = 'STDIN not a tty when output is to pipe' if $Is_VMS;
328         ok(-t,          '-t on STDIN');
329     }
330 }
331
332 my $Null = File::Spec->devnull;
333 SKIP: {
334     skip "No null device to test with", 1 unless -e $Null;
335     skip "We know Win32 thinks '$Null' is a TTY", 1 if $Is_MSWin32;
336
337     open(NULL, $Null) or DIE("Can't open $Null: $!");
338     ok(! -t NULL,   'null device is not a TTY');
339     close(NULL);
340 }
341
342
343 # These aren't strictly "stat" calls, but so what?
344 my $statfile = File::Spec->catfile($Curdir, 'op', 'stat.t');
345 ok(  -T $statfile,    '-T');
346 ok(! -B $statfile,    '!-B');
347
348 SKIP: {
349      skip("DG/UX", 1) if $Is_DGUX;
350 ok(-B $Perl,      '-B');
351 }
352
353 ok(! -T $Perl,    '!-T');
354
355 open(FOO,$statfile);
356 SKIP: {
357     eval { -T FOO; };
358     skip "-T/B on filehandle not implemented", 15 if $@ =~ /not implemented/;
359
360     is( $@, '',     '-T on filehandle causes no errors' );
361
362     ok(-T FOO,      '   -T');
363     ok(! -B FOO,    '   !-B');
364
365     $_ = <FOO>;
366     like($_, qr/perl/, 'after readline');
367     ok(-T FOO,      '   still -T');
368     ok(! -B FOO,    '   still -B');
369     close(FOO);
370
371     open(FOO,$statfile);
372     $_ = <FOO>;
373     like($_, qr/perl/,      'reopened and after readline');
374     ok(-T FOO,      '   still -T');
375     ok(! -B FOO,    '   still !-B');
376
377     ok(seek(FOO,0,0),   'after seek');
378     ok(-T FOO,          '   still -T');
379     ok(! -B FOO,        '   still !-B');
380
381     # It's documented this way in perlfunc *shrug*
382     () = <FOO>;
383     ok(eof FOO,         'at EOF');
384     ok(-T FOO,          '   still -T');
385     ok(-B FOO,          '   now -B');
386 }
387 close(FOO);
388
389
390 SKIP: {
391     skip "No null device to test with", 2 unless -e $Null;
392
393     ok(-T $Null,  'null device is -T');
394     ok(-B $Null,  '    and -B');
395 }
396
397
398 # and now, a few parsing tests:
399 $_ = $tmpfile;
400 ok(-f,      'bare -f   uses $_');
401 ok(-f(),    '     -f() "');
402
403 unlink $tmpfile or print "# unlink failed: $!\n";
404
405 # bug id 20011101.069
406 my @r = \stat($Curdir);
407 is(scalar @r, 13,   'stat returns full 13 elements');
408
409 SKIP: {
410     skip "No lstat", 4 unless $Config{d_lstat};
411
412     stat $0;
413     eval { lstat _ };
414     like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
415         'lstat _ croaks after stat' );
416     eval { -l _ };
417     like( $@, qr/^The stat preceding -l _ wasn't an lstat/,
418         '-l _ croaks after stat' );
419
420     # bug id 20020124.004
421     # If we have d_lstat, we should have symlink()
422     my $linkname = 'dolzero';
423     symlink $0, $linkname or die "# Can't symlink $0: $!";
424     lstat $linkname;
425     -T _;
426     eval { lstat _ };
427     like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
428         'lstat croaks after -T _' );
429     eval { -l _ };
430     like( $@, qr/^The stat preceding -l _ wasn't an lstat/,
431         '-l _ croaks after -T _' );
432     unlink $linkname or print "# unlink $linkname failed: $!\n";
433 }
434
435 print "# Zzz...\n";
436 sleep(3);
437 my $f = 'tstamp.tmp';
438 unlink $f;
439 ok (open(S, "> $f"), 'can create tmp file');
440 close S or die;
441 my @a = stat $f;
442 print "# time=$^T, stat=(@a)\n";
443 my @b = (-M _, -A _, -C _);
444 print "# -MAC=(@b)\n";
445 ok( (-M _) < 0, 'negative -M works');
446 ok( (-A _) < 0, 'negative -A works');
447 ok( (-C _) < 0, 'negative -C works');
448 ok(unlink($f), 'unlink tmp file');
449
450 END {
451     1 while unlink $tmpfile;
452 }