This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Extract _handle_rc_recall_command.
[perl5.git] / lib / perl5db.pl
1
2 =head1 NAME
3
4 perl5db.pl - the perl debugger
5
6 =head1 SYNOPSIS
7
8     perl -d  your_Perl_script
9
10 =head1 DESCRIPTION
11
12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
13 you invoke a script with C<perl -d>. This documentation tries to outline the
14 structure and services provided by C<perl5db.pl>, and to describe how you
15 can use them.
16
17 =head1 GENERAL NOTES
18
19 The debugger can look pretty forbidding to many Perl programmers. There are
20 a number of reasons for this, many stemming out of the debugger's history.
21
22 When the debugger was first written, Perl didn't have a lot of its nicer
23 features - no references, no lexical variables, no closures, no object-oriented
24 programming. So a lot of the things one would normally have done using such
25 features was done using global variables, globs and the C<local()> operator
26 in creative ways.
27
28 Some of these have survived into the current debugger; a few of the more
29 interesting and still-useful idioms are noted in this section, along with notes
30 on the comments themselves.
31
32 =head2 Why not use more lexicals?
33
34 Experienced Perl programmers will note that the debugger code tends to use
35 mostly package globals rather than lexically-scoped variables. This is done
36 to allow a significant amount of control of the debugger from outside the
37 debugger itself.
38
39 Unfortunately, though the variables are accessible, they're not well
40 documented, so it's generally been a decision that hasn't made a lot of
41 difference to most users. Where appropriate, comments have been added to
42 make variables more accessible and usable, with the understanding that these
43 I<are> debugger internals, and are therefore subject to change. Future
44 development should probably attempt to replace the globals with a well-defined
45 API, but for now, the variables are what we've got.
46
47 =head2 Automated variable stacking via C<local()>
48
49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
50 temporary copy of a variable in the current scope. When the scope ends, the
51 old copy is restored. This is often used in the debugger to handle the
52 automatic stacking of variables during recursive calls:
53
54      sub foo {
55         local $some_global++;
56
57         # Do some stuff, then ...
58         return;
59      }
60
61 What happens is that on entry to the subroutine, C<$some_global> is localized,
62 then altered. When the subroutine returns, Perl automatically undoes the
63 localization, restoring the previous value. Voila, automatic stack management.
64
65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
66 which lets the debugger get control inside of C<eval>'ed code. The debugger
67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
71
72 In any case, watch for this pattern. It occurs fairly often.
73
74 =head2 The C<^> trick
75
76 This is used to cleverly reverse the sense of a logical test depending on
77 the value of an auxiliary variable. For instance, the debugger's C<S>
78 (search for subroutines by pattern) allows you to negate the pattern
79 like this:
80
81    # Find all non-'foo' subs:
82    S !/foo/
83
84 Boolean algebra states that the truth table for XOR looks like this:
85
86 =over 4
87
88 =item * 0 ^ 0 = 0
89
90 (! not present and no match) --> false, don't print
91
92 =item * 0 ^ 1 = 1
93
94 (! not present and matches) --> true, print
95
96 =item * 1 ^ 0 = 1
97
98 (! present and no match) --> true, print
99
100 =item * 1 ^ 1 = 0
101
102 (! present and matches) --> false, don't print
103
104 =back
105
106 As you can see, the first pair applies when C<!> isn't supplied, and
107 the second pair applies when it is. The XOR simply allows us to
108 compact a more complicated if-then-elseif-else into a more elegant
109 (but perhaps overly clever) single test. After all, it needed this
110 explanation...
111
112 =head2 FLAGS, FLAGS, FLAGS
113
114 There is a certain C programming legacy in the debugger. Some variables,
115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
117 of state to be stored independently in a single scalar.
118
119 A test like
120
121     if ($scalar & 4) ...
122
123 is checking to see if the appropriate bit is on. Since each bit can be
124 "addressed" independently in this way, C<$scalar> is acting sort of like
125 an array of bits. Obviously, since the contents of C<$scalar> are just a
126 bit-pattern, we can save and restore it easily (it will just look like
127 a number).
128
129 The problem, is of course, that this tends to leave magic numbers scattered
130 all over your program whenever a bit is set, cleared, or checked. So why do
131 it?
132
133 =over 4
134
135 =item *
136
137 First, doing an arithmetical or bitwise operation on a scalar is
138 just about the fastest thing you can do in Perl: C<use constant> actually
139 creates a subroutine call, and array and hash lookups are much slower. Is
140 this over-optimization at the expense of readability? Possibly, but the
141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
142 probably have to benchmark alternate implementations and see which is the
143 best balance of readability and speed, and then document how it actually
144 works.
145
146 =item *
147
148 Second, it's very easy to serialize a scalar number. This is done in
149 the restart code; the debugger state variables are saved in C<%ENV> and then
150 restored when the debugger is restarted. Having them be just numbers makes
151 this trivial.
152
153 =item *
154
155 Third, some of these variables are being shared with the Perl core
156 smack in the middle of the interpreter's execution loop. It's much faster for
157 a C program (like the interpreter) to check a bit in a scalar than to access
158 several different variables (or a Perl array).
159
160 =back
161
162 =head2 What are those C<XXX> comments for?
163
164 Any comment containing C<XXX> means that the comment is either somewhat
165 speculative - it's not exactly clear what a given variable or chunk of
166 code is doing, or that it is incomplete - the basics may be clear, but the
167 subtleties are not completely documented.
168
169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
170
171 =head1 DATA STRUCTURES MAINTAINED BY CORE
172
173 There are a number of special data structures provided to the debugger by
174 the Perl interpreter.
175
176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
177 via glob assignment) contains the text from C<$filename>, with each
178 element corresponding to a single line of C<$filename>. Additionally,
179 breakable lines will be dualvars with the numeric component being the
180 memory address of a COP node. Non-breakable lines are dualvar to 0.
181
182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
183 assignment) contains breakpoints and actions.  The keys are line numbers;
184 you can set individual values, but not the whole hash. The Perl interpreter
185 uses this hash to determine where breakpoints have been set. Any true value is
186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
188
189 The scalar C<${"_<$filename"}> simply contains the string C<<< _<$filename> >>>.
190 This is also the case for evaluated strings that contain subroutines, or
191 which are currently being executed.  The $filename for C<eval>ed strings looks
192 like C<(eval 34).
193
194 =head1 DEBUGGER STARTUP
195
196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
198 of options. In addition, this file may define a subroutine C<&afterinit>
199 that will be executed (in the debugger's context) after the debugger has
200 initialized itself.
201
202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
203 contents as the argument of a C<o> command in the debugger.
204
205 =head2 STARTUP-ONLY OPTIONS
206
207 The following options can only be specified at startup.
208 To set them in your rcfile, add a call to
209 C<&parse_options("optionName=new_value")>.
210
211 =over 4
212
213 =item * TTY
214
215 the TTY to use for debugging i/o.
216
217 =item * noTTY
218
219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
221 Term::Rendezvous.  Current variant is to have the name of TTY in this
222 file.
223
224 =item * ReadLine
225
226 if false, a dummy ReadLine is used, so you can debug
227 ReadLine applications.
228
229 =item * NonStop
230
231 if true, no i/o is performed until interrupt.
232
233 =item * LineInfo
234
235 file or pipe to print line number info to.  If it is a
236 pipe, a short "emacs like" message is used.
237
238 =item * RemotePort
239
240 host:port to connect to on remote host for remote debugging.
241
242 =item * HistFile
243
244 file to store session history to. There is no default and so no
245 history file is written unless this variable is explicitly set.
246
247 =item * HistSize
248
249 number of commands to store to the file specified in C<HistFile>.
250 Default is 100.
251
252 =back
253
254 =head3 SAMPLE RCFILE
255
256  &parse_options("NonStop=1 LineInfo=db.out");
257   sub afterinit { $trace = 1; }
258
259 The script will run without human intervention, putting trace
260 information into C<db.out>.  (If you interrupt it, you had better
261 reset C<LineInfo> to something I<interactive>!)
262
263 =head1 INTERNALS DESCRIPTION
264
265 =head2 DEBUGGER INTERFACE VARIABLES
266
267 Perl supplies the values for C<%sub>.  It effectively inserts
268 a C<&DB::DB();> in front of each place that can have a
269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
271 {require 'perl5db.pl'}> before the first line.
272
273 After each C<require>d file is compiled, but before it is executed, a
274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
275 is the expanded name of the C<require>d file (as found via C<%INC>).
276
277 =head3 IMPORTANT INTERNAL VARIABLES
278
279 =head4 C<$CreateTTY>
280
281 Used to control when the debugger will attempt to acquire another TTY to be
282 used for input.
283
284 =over
285
286 =item * 1 -  on C<fork()>
287
288 =item * 2 - debugger is started inside debugger
289
290 =item * 4 -  on startup
291
292 =back
293
294 =head4 C<$doret>
295
296 The value -2 indicates that no return value should be printed.
297 Any other positive value causes C<DB::sub> to print return values.
298
299 =head4 C<$evalarg>
300
301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
302 contents of C<@_> when C<DB::eval> is called.
303
304 =head4 C<$frame>
305
306 Determines what messages (if any) will get printed when a subroutine (or eval)
307 is entered or exited.
308
309 =over 4
310
311 =item * 0 -  No enter/exit messages
312
313 =item * 1 - Print I<entering> messages on subroutine entry
314
315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
316
317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
318
319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
320
321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
322
323 =back
324
325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
326 The debugger internally juggles the value of C<$frame> during execution to
327 protect external modules that the debugger uses from getting traced.
328
329 =head4 C<$level>
330
331 Tracks current debugger nesting level. Used to figure out how many
332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
333 outputs a prompt. Also used to help determine if the program has finished
334 during command parsing.
335
336 =head4 C<$onetimeDump>
337
338 Controls what (if anything) C<DB::eval()> will print after evaluating an
339 expression.
340
341 =over 4
342
343 =item * C<undef> - don't print anything
344
345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
346
347 =item * C<methods> - print the methods callable on the first item returned
348
349 =back
350
351 =head4 C<$onetimeDumpDepth>
352
353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
354 dumping a structure. Numeric. If C<undef>, print all levels.
355
356 =head4 C<$signal>
357
358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
359 which is called before every statement, checks this and puts the user into
360 command mode if it finds C<$signal> set to a true value.
361
362 =head4 C<$single>
363
364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
365 each subroutine; popped again at the end of each subroutine.
366
367 =over 4
368
369 =item * 0 - run continuously.
370
371 =item * 1 - single-step, go into subs. The C<s> command.
372
373 =item * 2 - single-step, don't go into subs. The C<n> command.
374
375 =item * 4 - print current sub depth (turned on to force this when C<too much
376 recursion> occurs.
377
378 =back
379
380 =head4 C<$trace>
381
382 Controls the output of trace information.
383
384 =over 4
385
386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
387
388 =item * 2 - watch expressions are active
389
390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
391
392 =back
393
394 =head4 C<$slave_editor>
395
396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
397
398 =head4 C<@cmdfhs>
399
400 Stack of filehandles that C<DB::readline()> will read commands from.
401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
402
403 =head4 C<@dbline>
404
405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
406 supplied by the Perl interpreter to the debugger. Contains the source.
407
408 =head4 C<@old_watch>
409
410 Previous values of watch expressions. First set when the expression is
411 entered; reset whenever the watch expression changes.
412
413 =head4 C<@saved>
414
415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
416 so that the debugger can substitute safe values while it's running, and
417 restore them when it returns control.
418
419 =head4 C<@stack>
420
421 Saves the current value of C<$single> on entry to a subroutine.
422 Manipulated by the C<c> command to turn off tracing in all subs above the
423 current one.
424
425 =head4 C<@to_watch>
426
427 The 'watch' expressions: to be evaluated before each line is executed.
428
429 =head4 C<@typeahead>
430
431 The typeahead buffer, used by C<DB::readline>.
432
433 =head4 C<%alias>
434
435 Command aliases. Stored as character strings to be substituted for a command
436 entered.
437
438 =head4 C<%break_on_load>
439
440 Keys are file names, values are 1 (break when this file is loaded) or undef
441 (don't break when it is loaded).
442
443 =head4 C<%dbline>
444
445 Keys are line numbers, values are C<condition\0action>. If used in numeric
446 context, values are 0 if not breakable, 1 if breakable, no matter what is
447 in the actual hash entry.
448
449 =head4 C<%had_breakpoints>
450
451 Keys are file names; values are bitfields:
452
453 =over 4
454
455 =item * 1 - file has a breakpoint in it.
456
457 =item * 2 - file has an action in it.
458
459 =back
460
461 A zero or undefined value means this file has neither.
462
463 =head4 C<%option>
464
465 Stores the debugger options. These are character string values.
466
467 =head4 C<%postponed>
468
469 Saves breakpoints for code that hasn't been compiled yet.
470 Keys are subroutine names, values are:
471
472 =over 4
473
474 =item * C<compile> - break when this sub is compiled
475
476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
477
478 =back
479
480 =head4 C<%postponed_file>
481
482 This hash keeps track of breakpoints that need to be set for files that have
483 not yet been compiled. Keys are filenames; values are references to hashes.
484 Each of these hashes is keyed by line number, and its values are breakpoint
485 definitions (C<condition\0action>).
486
487 =head1 DEBUGGER INITIALIZATION
488
489 The debugger's initialization actually jumps all over the place inside this
490 package. This is because there are several BEGIN blocks (which of course
491 execute immediately) spread through the code. Why is that?
492
493 The debugger needs to be able to change some things and set some things up
494 before the debugger code is compiled; most notably, the C<$deep> variable that
495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
496 debugger has to turn off warnings while the debugger code is compiled, but then
497 restore them to their original setting before the program being debugged begins
498 executing.
499
500 The first C<BEGIN> block simply turns off warnings by saving the current
501 setting of C<$^W> and then setting it to zero. The second one initializes
502 the debugger variables that are needed before the debugger begins executing.
503 The third one puts C<$^X> back to its former value.
504
505 We'll detail the second C<BEGIN> block later; just remember that if you need
506 to initialize something before the debugger starts really executing, that's
507 where it has to go.
508
509 =cut
510
511 package DB;
512
513 use strict;
514
515 BEGIN {eval 'use IO::Handle'}; # Needed for flush only? breaks under miniperl
516
517 BEGIN {
518     require feature;
519     $^V =~ /^v(\d+\.\d+)/;
520     feature->import(":$1");
521 }
522
523 # Debugger for Perl 5.00x; perl5db.pl patch level:
524 use vars qw($VERSION $header);
525
526 $VERSION = '1.39_05';
527
528 $header = "perl5db.pl version $VERSION";
529
530 =head1 DEBUGGER ROUTINES
531
532 =head2 C<DB::eval()>
533
534 This function replaces straight C<eval()> inside the debugger; it simplifies
535 the process of evaluating code in the user's context.
536
537 The code to be evaluated is passed via the package global variable
538 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
539
540 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
541 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
542 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
543 user's current package, grabbed when C<DB::DB> got control.  This causes the
544 proper context to be used when the eval is actually done.  Afterward, we
545 restore C<$trace>, C<$single>, and C<$^D>.
546
547 Next we need to handle C<$@> without getting confused. We save C<$@> in a
548 local lexical, localize C<$saved[0]> (which is where C<save()> will put
549 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
550 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
551 considered sane by the debugger. If there was an C<eval()> error, we print
552 it on the debugger's output. If C<$onetimedump> is defined, we call
553 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
554 'methods'. Setting it to something else causes the debugger to do the eval
555 but not print the result - handy if you want to do something else with it
556 (the "watch expressions" code does this to get the value of the watch
557 expression but not show it unless it matters).
558
559 In any case, we then return the list of output from C<eval> to the caller,
560 and unwinding restores the former version of C<$@> in C<@saved> as well
561 (the localization of C<$saved[0]> goes away at the end of this scope).
562
563 =head3 Parameters and variables influencing execution of DB::eval()
564
565 C<DB::eval> isn't parameterized in the standard way; this is to keep the
566 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
567 The variables listed below influence C<DB::eval()>'s execution directly.
568
569 =over 4
570
571 =item C<$evalarg> - the thing to actually be eval'ed
572
573 =item C<$trace> - Current state of execution tracing
574
575 =item C<$single> - Current state of single-stepping
576
577 =item C<$onetimeDump> - what is to be displayed after the evaluation
578
579 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
580
581 =back
582
583 The following variables are altered by C<DB::eval()> during its execution. They
584 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
585
586 =over 4
587
588 =item C<@res> - used to capture output from actual C<eval>.
589
590 =item C<$otrace> - saved value of C<$trace>.
591
592 =item C<$osingle> - saved value of C<$single>.
593
594 =item C<$od> - saved value of C<$^D>.
595
596 =item C<$saved[0]> - saved value of C<$@>.
597
598 =item $\ - for output of C<$@> if there is an evaluation error.
599
600 =back
601
602 =head3 The problem of lexicals
603
604 The context of C<DB::eval()> presents us with some problems. Obviously,
605 we want to be 'sandboxed' away from the debugger's internals when we do
606 the eval, but we need some way to control how punctuation variables and
607 debugger globals are used.
608
609 We can't use local, because the code inside C<DB::eval> can see localized
610 variables; and we can't use C<my> either for the same reason. The code
611 in this routine compromises and uses C<my>.
612
613 After this routine is over, we don't have user code executing in the debugger's
614 context, so we can use C<my> freely.
615
616 =cut
617
618 ############################################## Begin lexical danger zone
619
620 # 'my' variables used here could leak into (that is, be visible in)
621 # the context that the code being evaluated is executing in. This means that
622 # the code could modify the debugger's variables.
623 #
624 # Fiddling with the debugger's context could be Bad. We insulate things as
625 # much as we can.
626
627 use vars qw(
628     @args
629     %break_on_load
630     @cmdfhs
631     $CommandSet
632     $CreateTTY
633     $DBGR
634     @dbline
635     $dbline
636     %dbline
637     $dieLevel
638     $filename
639     $hist
640     $histfile
641     $histsize
642     $IN
643     $inhibit_exit
644     @ini_INC
645     $ini_warn
646     $maxtrace
647     $od
648     $onetimedumpDepth
649     @options
650     $osingle
651     $otrace
652     $pager
653     $post
654     %postponed
655     $prc
656     $pre
657     $pretype
658     $psh
659     @RememberOnROptions
660     $remoteport
661     @res
662     $rl
663     @saved
664     $signalLevel
665     $sub
666     $term
667     $usercontext
668     $warnLevel
669 );
670
671 our (
672     $evalarg,
673     $frame,
674     $ImmediateStop,
675     $line,
676     $onetimeDump,
677     %option,
678     $OUT,
679     $packname,
680     $signal,
681     $single,
682     $start,
683     %sub,
684     $subname,
685     $trace,
686     $window,
687 );
688
689 # Used to save @ARGV and extract any debugger-related flags.
690 use vars qw(@ARGS);
691
692 # Used to prevent multiple entries to diesignal()
693 # (if for instance diesignal() itself dies)
694 use vars qw($panic);
695
696 # Used to prevent the debugger from running nonstop
697 # after a restart
698 our ($second_time);
699
700 sub _calc_usercontext {
701     my ($package) = @_;
702
703     # Cancel strict completely for the evaluated code, so the code
704     # the user evaluates won't be affected by it. (Shlomi Fish)
705     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @DB::saved;'
706     . "package $package;";    # this won't let them modify, alas
707 }
708
709 sub eval {
710
711     # 'my' would make it visible from user code
712     #    but so does local! --tchrist
713     # Remember: this localizes @DB::res, not @main::res.
714     local @res;
715     {
716
717         # Try to keep the user code from messing  with us. Save these so that
718         # even if the eval'ed code changes them, we can put them back again.
719         # Needed because the user could refer directly to the debugger's
720         # package globals (and any 'my' variables in this containing scope)
721         # inside the eval(), and we want to try to stay safe.
722         local $otrace  = $trace;
723         local $osingle = $single;
724         local $od      = $^D;
725
726         # Untaint the incoming eval() argument.
727         { ($evalarg) = $evalarg =~ /(.*)/s; }
728
729         # $usercontext built in DB::DB near the comment
730         # "set up the context for DB::eval ..."
731         # Evaluate and save any results.
732         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
733
734         # Restore those old values.
735         $trace  = $otrace;
736         $single = $osingle;
737         $^D     = $od;
738     }
739
740     # Save the current value of $@, and preserve it in the debugger's copy
741     # of the saved precious globals.
742     my $at = $@;
743
744     # Since we're only saving $@, we only have to localize the array element
745     # that it will be stored in.
746     local $saved[0];    # Preserve the old value of $@
747     eval { DB::save() };
748
749     # Now see whether we need to report an error back to the user.
750     if ($at) {
751         local $\ = '';
752         print $OUT $at;
753     }
754
755     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
756     # are package globals.
757     elsif ($onetimeDump) {
758         if ( $onetimeDump eq 'dump' ) {
759             local $option{dumpDepth} = $onetimedumpDepth
760               if defined $onetimedumpDepth;
761             dumpit( $OUT, \@res );
762         }
763         elsif ( $onetimeDump eq 'methods' ) {
764             methods( $res[0] );
765         }
766     } ## end elsif ($onetimeDump)
767     @res;
768 } ## end sub eval
769
770 ############################################## End lexical danger zone
771
772 # After this point it is safe to introduce lexicals.
773 # The code being debugged will be executing in its own context, and
774 # can't see the inside of the debugger.
775 #
776 # However, one should not overdo it: leave as much control from outside as
777 # possible. If you make something a lexical, it's not going to be addressable
778 # from outside the debugger even if you know its name.
779
780 # This file is automatically included if you do perl -d.
781 # It's probably not useful to include this yourself.
782 #
783 # Before venturing further into these twisty passages, it is
784 # wise to read the perldebguts man page or risk the ire of dragons.
785 #
786 # (It should be noted that perldebguts will tell you a lot about
787 # the underlying mechanics of how the debugger interfaces into the
788 # Perl interpreter, but not a lot about the debugger itself. The new
789 # comments in this code try to address this problem.)
790
791 # Note that no subroutine call is possible until &DB::sub is defined
792 # (for subroutines defined outside of the package DB). In fact the same is
793 # true if $deep is not defined.
794
795 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
796
797 # modified Perl debugger, to be run from Emacs in perldb-mode
798 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
799 # Johan Vromans -- upgrade to 4.0 pl 10
800 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
801 ########################################################################
802
803 =head1 DEBUGGER INITIALIZATION
804
805 The debugger starts up in phases.
806
807 =head2 BASIC SETUP
808
809 First, it initializes the environment it wants to run in: turning off
810 warnings during its own compilation, defining variables which it will need
811 to avoid warnings later, setting itself up to not exit when the program
812 terminates, and defaulting to printing return values for the C<r> command.
813
814 =cut
815
816 # Needed for the statement after exec():
817 #
818 # This BEGIN block is simply used to switch off warnings during debugger
819 # compilation. Probably it would be better practice to fix the warnings,
820 # but this is how it's done at the moment.
821
822 BEGIN {
823     $ini_warn = $^W;
824     $^W       = 0;
825 }    # Switch compilation warnings off until another BEGIN.
826
827 local ($^W) = 0;    # Switch run-time warnings off during init.
828
829 =head2 THREADS SUPPORT
830
831 If we are running under a threaded Perl, we require threads and threads::shared
832 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
833 threaded debugger control.  C<-dt> can also be used to set this.
834
835 Each new thread will be announced and the debugger prompt will always inform
836 you of each new thread created.  It will also indicate the thread id in which
837 we are currently running within the prompt like this:
838
839     [tid] DB<$i>
840
841 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
842 command prompt.  The prompt will show: C<[0]> when running under threads, but
843 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
844
845 While running under threads, when you set or delete a breakpoint (etc.), this
846 will apply to all threads, not just the currently running one.  When you are
847 in a currently executing thread, you will stay there until it completes.  With
848 the current implementation it is not currently possible to hop from one thread
849 to another.
850
851 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
852
853 Note that threading support was built into the debugger as of Perl version
854 C<5.8.6> and debugger version C<1.2.8>.
855
856 =cut
857
858 BEGIN {
859     # ensure we can share our non-threaded variables or no-op
860     if ($ENV{PERL5DB_THREADED}) {
861         require threads;
862         require threads::shared;
863         import threads::shared qw(share);
864         $DBGR;
865         share(\$DBGR);
866         lock($DBGR);
867         print "Threads support enabled\n";
868     } else {
869         *lock  = sub(*) {};
870         *share = sub(*) {};
871     }
872 }
873
874 # These variables control the execution of 'dumpvar.pl'.
875 {
876     package dumpvar;
877     use vars qw(
878     $hashDepth
879     $arrayDepth
880     $dumpDBFiles
881     $dumpPackages
882     $quoteHighBit
883     $printUndef
884     $globPrint
885     $usageOnly
886     );
887 }
888
889 # used to control die() reporting in diesignal()
890 {
891     package Carp;
892     use vars qw($CarpLevel);
893 }
894
895 # without threads, $filename is not defined until DB::DB is called
896 foreach my $k (keys (%INC)) {
897     share(\$main::{'_<'.$filename}) if defined $filename;
898 };
899
900 # Command-line + PERLLIB:
901 # Save the contents of @INC before they are modified elsewhere.
902 @ini_INC = @INC;
903
904 # This was an attempt to clear out the previous values of various
905 # trapped errors. Apparently it didn't help. XXX More info needed!
906 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
907
908 # We set these variables to safe values. We don't want to blindly turn
909 # off warnings, because other packages may still want them.
910 $trace = $signal = $single = 0;    # Uninitialized warning suppression
911                                    # (local $^W cannot help - other packages!).
912
913 # Default to not exiting when program finishes; print the return
914 # value when the 'r' command is used to return from a subroutine.
915 $inhibit_exit = $option{PrintRet} = 1;
916
917 use vars qw($trace_to_depth);
918
919 # Default to 1E9 so it won't be limited to a certain recursion depth.
920 $trace_to_depth = 1E9;
921
922 =head1 OPTION PROCESSING
923
924 The debugger's options are actually spread out over the debugger itself and
925 C<dumpvar.pl>; some of these are variables to be set, while others are
926 subs to be called with a value. To try to make this a little easier to
927 manage, the debugger uses a few data structures to define what options
928 are legal and how they are to be processed.
929
930 First, the C<@options> array defines the I<names> of all the options that
931 are to be accepted.
932
933 =cut
934
935 @options = qw(
936   CommandSet   HistFile      HistSize
937   hashDepth    arrayDepth    dumpDepth
938   DumpDBFiles  DumpPackages  DumpReused
939   compactDump  veryCompact   quote
940   HighBit      undefPrint    globPrint
941   PrintRet     UsageOnly     frame
942   AutoTrace    TTY           noTTY
943   ReadLine     NonStop       LineInfo
944   maxTraceLen  recallCommand ShellBang
945   pager        tkRunning     ornaments
946   signalLevel  warnLevel     dieLevel
947   inhibit_exit ImmediateStop bareStringify
948   CreateTTY    RemotePort    windowSize
949   DollarCaretP
950 );
951
952 @RememberOnROptions = qw(DollarCaretP);
953
954 =pod
955
956 Second, C<optionVars> lists the variables that each option uses to save its
957 state.
958
959 =cut
960
961 use vars qw(%optionVars);
962
963 %optionVars = (
964     hashDepth     => \$dumpvar::hashDepth,
965     arrayDepth    => \$dumpvar::arrayDepth,
966     CommandSet    => \$CommandSet,
967     DumpDBFiles   => \$dumpvar::dumpDBFiles,
968     DumpPackages  => \$dumpvar::dumpPackages,
969     DumpReused    => \$dumpvar::dumpReused,
970     HighBit       => \$dumpvar::quoteHighBit,
971     undefPrint    => \$dumpvar::printUndef,
972     globPrint     => \$dumpvar::globPrint,
973     UsageOnly     => \$dumpvar::usageOnly,
974     CreateTTY     => \$CreateTTY,
975     bareStringify => \$dumpvar::bareStringify,
976     frame         => \$frame,
977     AutoTrace     => \$trace,
978     inhibit_exit  => \$inhibit_exit,
979     maxTraceLen   => \$maxtrace,
980     ImmediateStop => \$ImmediateStop,
981     RemotePort    => \$remoteport,
982     windowSize    => \$window,
983     HistFile      => \$histfile,
984     HistSize      => \$histsize,
985 );
986
987 =pod
988
989 Third, C<%optionAction> defines the subroutine to be called to process each
990 option.
991
992 =cut
993
994 use vars qw(%optionAction);
995
996 %optionAction = (
997     compactDump   => \&dumpvar::compactDump,
998     veryCompact   => \&dumpvar::veryCompact,
999     quote         => \&dumpvar::quote,
1000     TTY           => \&TTY,
1001     noTTY         => \&noTTY,
1002     ReadLine      => \&ReadLine,
1003     NonStop       => \&NonStop,
1004     LineInfo      => \&LineInfo,
1005     recallCommand => \&recallCommand,
1006     ShellBang     => \&shellBang,
1007     pager         => \&pager,
1008     signalLevel   => \&signalLevel,
1009     warnLevel     => \&warnLevel,
1010     dieLevel      => \&dieLevel,
1011     tkRunning     => \&tkRunning,
1012     ornaments     => \&ornaments,
1013     RemotePort    => \&RemotePort,
1014     DollarCaretP  => \&DollarCaretP,
1015 );
1016
1017 =pod
1018
1019 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1020 option is used.
1021
1022 =cut
1023
1024 # Note that this list is not complete: several options not listed here
1025 # actually require that dumpvar.pl be loaded for them to work, but are
1026 # not in the table. A subsequent patch will correct this problem; for
1027 # the moment, we're just recommenting, and we are NOT going to change
1028 # function.
1029 use vars qw(%optionRequire);
1030
1031 %optionRequire = (
1032     compactDump => 'dumpvar.pl',
1033     veryCompact => 'dumpvar.pl',
1034     quote       => 'dumpvar.pl',
1035 );
1036
1037 =pod
1038
1039 There are a number of initialization-related variables which can be set
1040 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1041 variable. These are:
1042
1043 =over 4
1044
1045 =item C<$rl> - readline control XXX needs more explanation
1046
1047 =item C<$warnLevel> - whether or not debugger takes over warning handling
1048
1049 =item C<$dieLevel> - whether or not debugger takes over die handling
1050
1051 =item C<$signalLevel> - whether or not debugger takes over signal handling
1052
1053 =item C<$pre> - preprompt actions (array reference)
1054
1055 =item C<$post> - postprompt actions (array reference)
1056
1057 =item C<$pretype>
1058
1059 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1060
1061 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1062
1063 =back
1064
1065 =cut
1066
1067 # These guys may be defined in $ENV{PERL5DB} :
1068 $rl          = 1     unless defined $rl;
1069 $warnLevel   = 1     unless defined $warnLevel;
1070 $dieLevel    = 1     unless defined $dieLevel;
1071 $signalLevel = 1     unless defined $signalLevel;
1072 $pre         = []    unless defined $pre;
1073 $post        = []    unless defined $post;
1074 $pretype     = []    unless defined $pretype;
1075 $CreateTTY   = 3     unless defined $CreateTTY;
1076 $CommandSet  = '580' unless defined $CommandSet;
1077
1078 share($rl);
1079 share($warnLevel);
1080 share($dieLevel);
1081 share($signalLevel);
1082 share($pre);
1083 share($post);
1084 share($pretype);
1085 share($rl);
1086 share($CreateTTY);
1087 share($CommandSet);
1088
1089 =pod
1090
1091 The default C<die>, C<warn>, and C<signal> handlers are set up.
1092
1093 =cut
1094
1095 warnLevel($warnLevel);
1096 dieLevel($dieLevel);
1097 signalLevel($signalLevel);
1098
1099 =pod
1100
1101 The pager to be used is needed next. We try to get it from the
1102 environment first.  If it's not defined there, we try to find it in
1103 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1104 then call the C<pager()> function to save the pager name.
1105
1106 =cut
1107
1108 # This routine makes sure $pager is set up so that '|' can use it.
1109 pager(
1110
1111     # If PAGER is defined in the environment, use it.
1112     defined $ENV{PAGER}
1113     ? $ENV{PAGER}
1114
1115       # If not, see if Config.pm defines it.
1116     : eval { require Config }
1117       && defined $Config::Config{pager}
1118     ? $Config::Config{pager}
1119
1120       # If not, fall back to 'more'.
1121     : 'more'
1122   )
1123   unless defined $pager;
1124
1125 =pod
1126
1127 We set up the command to be used to access the man pages, the command
1128 recall character (C<!> unless otherwise defined) and the shell escape
1129 character (C<!> unless otherwise defined). Yes, these do conflict, and
1130 neither works in the debugger at the moment.
1131
1132 =cut
1133
1134 setman();
1135
1136 # Set up defaults for command recall and shell escape (note:
1137 # these currently don't work in linemode debugging).
1138 recallCommand("!") unless defined $prc;
1139 shellBang("!")     unless defined $psh;
1140
1141 =pod
1142
1143 We then set up the gigantic string containing the debugger help.
1144 We also set the limit on the number of arguments we'll display during a
1145 trace.
1146
1147 =cut
1148
1149 sethelp();
1150
1151 # If we didn't get a default for the length of eval/stack trace args,
1152 # set it here.
1153 $maxtrace = 400 unless defined $maxtrace;
1154
1155 =head2 SETTING UP THE DEBUGGER GREETING
1156
1157 The debugger I<greeting> helps to inform the user how many debuggers are
1158 running, and whether the current debugger is the primary or a child.
1159
1160 If we are the primary, we just hang onto our pid so we'll have it when
1161 or if we start a child debugger. If we are a child, we'll set things up
1162 so we'll have a unique greeting and so the parent will give us our own
1163 TTY later.
1164
1165 We save the current contents of the C<PERLDB_PIDS> environment variable
1166 because we mess around with it. We'll also need to hang onto it because
1167 we'll need it if we restart.
1168
1169 Child debuggers make a label out of the current PID structure recorded in
1170 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1171 yet so the parent will give them one later via C<resetterm()>.
1172
1173 =cut
1174
1175 # Save the current contents of the environment; we're about to
1176 # much with it. We'll need this if we have to restart.
1177 use vars qw($ini_pids);
1178 $ini_pids = $ENV{PERLDB_PIDS};
1179
1180 use vars qw ($pids $term_pid);
1181
1182 if ( defined $ENV{PERLDB_PIDS} ) {
1183
1184     # We're a child. Make us a label out of the current PID structure
1185     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1186     # a term yet so the parent will give us one later via resetterm().
1187
1188     my $env_pids = $ENV{PERLDB_PIDS};
1189     $pids = "[$env_pids]";
1190
1191     # Unless we are on OpenVMS, all programs under the DCL shell run under
1192     # the same PID.
1193
1194     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1195         $term_pid         = $$;
1196     }
1197     else {
1198         $ENV{PERLDB_PIDS} .= "->$$";
1199         $term_pid = -1;
1200     }
1201
1202 } ## end if (defined $ENV{PERLDB_PIDS...
1203 else {
1204
1205     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1206     # child debugger, and mark us as the parent, so we'll know to set up
1207     # more TTY's is we have to.
1208     $ENV{PERLDB_PIDS} = "$$";
1209     $pids             = "[pid=$$]";
1210     $term_pid         = $$;
1211 }
1212
1213 use vars qw($pidprompt);
1214 $pidprompt = '';
1215
1216 # Sets up $emacs as a synonym for $slave_editor.
1217 our ($slave_editor);
1218 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1219
1220 =head2 READING THE RC FILE
1221
1222 The debugger will read a file of initialization options if supplied. If
1223 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1224
1225 =cut
1226
1227 # As noted, this test really doesn't check accurately that the debugger
1228 # is running at a terminal or not.
1229
1230 use vars qw($rcfile);
1231 {
1232     my $dev_tty = (($^O eq 'VMS') ? 'TT:' : '/dev/tty');
1233     # this is the wrong metric!
1234     $rcfile = ((-e $dev_tty) ? ".perldb" : "perldb.ini");
1235 }
1236
1237 =pod
1238
1239 The debugger does a safety test of the file to be read. It must be owned
1240 either by the current user or root, and must only be writable by the owner.
1241
1242 =cut
1243
1244 # This wraps a safety test around "do" to read and evaluate the init file.
1245 #
1246 # This isn't really safe, because there's a race
1247 # between checking and opening.  The solution is to
1248 # open and fstat the handle, but then you have to read and
1249 # eval the contents.  But then the silly thing gets
1250 # your lexical scope, which is unfortunate at best.
1251 sub safe_do {
1252     my $file = shift;
1253
1254     # Just exactly what part of the word "CORE::" don't you understand?
1255     local $SIG{__WARN__};
1256     local $SIG{__DIE__};
1257
1258     unless ( is_safe_file($file) ) {
1259         CORE::warn <<EO_GRIPE;
1260 perldb: Must not source insecure rcfile $file.
1261         You or the superuser must be the owner, and it must not
1262         be writable by anyone but its owner.
1263 EO_GRIPE
1264         return;
1265     } ## end unless (is_safe_file($file...
1266
1267     do $file;
1268     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1269 } ## end sub safe_do
1270
1271 # This is the safety test itself.
1272 #
1273 # Verifies that owner is either real user or superuser and that no
1274 # one but owner may write to it.  This function is of limited use
1275 # when called on a path instead of upon a handle, because there are
1276 # no guarantees that filename (by dirent) whose file (by ino) is
1277 # eventually accessed is the same as the one tested.
1278 # Assumes that the file's existence is not in doubt.
1279 sub is_safe_file {
1280     my $path = shift;
1281     stat($path) || return;    # mysteriously vaporized
1282     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1283
1284     return 0 if $uid != 0 && $uid != $<;
1285     return 0 if $mode & 022;
1286     return 1;
1287 } ## end sub is_safe_file
1288
1289 # If the rcfile (whichever one we decided was the right one to read)
1290 # exists, we safely do it.
1291 if ( -f $rcfile ) {
1292     safe_do("./$rcfile");
1293 }
1294
1295 # If there isn't one here, try the user's home directory.
1296 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1297     safe_do("$ENV{HOME}/$rcfile");
1298 }
1299
1300 # Else try the login directory.
1301 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1302     safe_do("$ENV{LOGDIR}/$rcfile");
1303 }
1304
1305 # If the PERLDB_OPTS variable has options in it, parse those out next.
1306 if ( defined $ENV{PERLDB_OPTS} ) {
1307     parse_options( $ENV{PERLDB_OPTS} );
1308 }
1309
1310 =pod
1311
1312 The last thing we do during initialization is determine which subroutine is
1313 to be used to obtain a new terminal when a new debugger is started. Right now,
1314 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1315 (darwin).
1316
1317 =cut
1318
1319 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1320 # Works if you're running an xterm or xterm-like window, or you're on
1321 # OS/2, or on Mac OS X. This may need some expansion.
1322
1323 if (not defined &get_fork_TTY)       # only if no routine exists
1324 {
1325     if ( defined $remoteport ) {
1326                                                  # Expect an inetd-like server
1327         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1328     }
1329     elsif (defined $ENV{TERM}                    # If we know what kind
1330                                                  # of terminal this is,
1331         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1332         and defined $ENV{DISPLAY}                # and what display it's on,
1333       )
1334     {
1335         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1336     }
1337     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1338         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1339     }
1340     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1341             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1342             and $ENV{TERM_PROGRAM}
1343                 eq 'Apple_Terminal'              # Terminal.app
1344             )
1345     {
1346         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1347     }
1348 } ## end if (not defined &get_fork_TTY...
1349
1350 # untaint $^O, which may have been tainted by the last statement.
1351 # see bug [perl #24674]
1352 $^O =~ m/^(.*)\z/;
1353 $^O = $1;
1354
1355 # Here begin the unreadable code.  It needs fixing.
1356
1357 =head2 RESTART PROCESSING
1358
1359 This section handles the restart command. When the C<R> command is invoked, it
1360 tries to capture all of the state it can into environment variables, and
1361 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1362 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1363 the R command stuffed into the environment variables.
1364
1365   PERLDB_RESTART   - flag only, contains no restart data itself.
1366   PERLDB_HIST      - command history, if it's available
1367   PERLDB_ON_LOAD   - breakpoints set by the rc file
1368   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1369   PERLDB_VISITED   - files that had breakpoints
1370   PERLDB_FILE_...  - breakpoints for a file
1371   PERLDB_OPT       - active options
1372   PERLDB_INC       - the original @INC
1373   PERLDB_PRETYPE   - preprompt debugger actions
1374   PERLDB_PRE       - preprompt Perl code
1375   PERLDB_POST      - post-prompt Perl code
1376   PERLDB_TYPEAHEAD - typeahead captured by readline()
1377
1378 We chug through all these variables and plug the values saved in them
1379 back into the appropriate spots in the debugger.
1380
1381 =cut
1382
1383 use vars qw(@truehist %postponed_file @typeahead);
1384
1385 our (@hist);
1386
1387 sub _restore_shared_globals_after_restart
1388 {
1389     @hist          = get_list('PERLDB_HIST');
1390     %break_on_load = get_list("PERLDB_ON_LOAD");
1391     %postponed     = get_list("PERLDB_POSTPONE");
1392
1393     share(@hist);
1394     share(@truehist);
1395     share(%break_on_load);
1396     share(%postponed);
1397 }
1398
1399 sub _restore_breakpoints_and_actions {
1400
1401     my @had_breakpoints = get_list("PERLDB_VISITED");
1402
1403     for my $file_idx ( 0 .. $#had_breakpoints ) {
1404         my $filename = $had_breakpoints[$file_idx];
1405         my %pf = get_list("PERLDB_FILE_$file_idx");
1406         $postponed_file{ $filename } = \%pf if %pf;
1407         my @lines = sort {$a <=> $b} keys(%pf);
1408         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1409         for my $line_idx (0 .. $#lines) {
1410             _set_breakpoint_enabled_status(
1411                 $filename,
1412                 $lines[$line_idx],
1413                 ($enabled_statuses[$line_idx] ? 1 : ''),
1414             );
1415         }
1416     }
1417
1418     return;
1419 }
1420
1421 sub _restore_options_after_restart
1422 {
1423     my %options_map = get_list("PERLDB_OPT");
1424
1425     while ( my ( $opt, $val ) = each %options_map ) {
1426         $val =~ s/[\\\']/\\$1/g;
1427         parse_options("$opt'$val'");
1428     }
1429
1430     return;
1431 }
1432
1433 sub _restore_globals_after_restart
1434 {
1435     # restore original @INC
1436     @INC     = get_list("PERLDB_INC");
1437     @ini_INC = @INC;
1438
1439     # return pre/postprompt actions and typeahead buffer
1440     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1441     $pre       = [ get_list("PERLDB_PRE") ];
1442     $post      = [ get_list("PERLDB_POST") ];
1443     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1444
1445     return;
1446 }
1447
1448
1449 if ( exists $ENV{PERLDB_RESTART} ) {
1450
1451     # We're restarting, so we don't need the flag that says to restart anymore.
1452     delete $ENV{PERLDB_RESTART};
1453
1454     # $restart = 1;
1455     _restore_shared_globals_after_restart();
1456
1457     _restore_breakpoints_and_actions();
1458
1459     # restore options
1460     _restore_options_after_restart();
1461
1462     _restore_globals_after_restart();
1463 } ## end if (exists $ENV{PERLDB_RESTART...
1464
1465 =head2 SETTING UP THE TERMINAL
1466
1467 Now, we'll decide how the debugger is going to interact with the user.
1468 If there's no TTY, we set the debugger to run non-stop; there's not going
1469 to be anyone there to enter commands.
1470
1471 =cut
1472
1473 use vars qw($notty $console $tty $LINEINFO);
1474 use vars qw($lineinfo $doccmd);
1475
1476 our ($runnonstop);
1477
1478 if ($notty) {
1479     $runnonstop = 1;
1480     share($runnonstop);
1481 }
1482
1483 =pod
1484
1485 If there is a TTY, we have to determine who it belongs to before we can
1486 proceed. If this is a slave editor or graphical debugger (denoted by
1487 the first command-line switch being '-emacs'), we shift this off and
1488 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1489
1490 =cut
1491
1492 else {
1493
1494     # Is Perl being run from a slave editor or graphical debugger?
1495     # If so, don't use readline, and set $slave_editor = 1.
1496     if ($slave_editor = ( @main::ARGV && ( $main::ARGV[0] eq '-emacs' ) )) {
1497         $rl = 0;
1498         shift(@main::ARGV);
1499     }
1500
1501     #require Term::ReadLine;
1502
1503 =pod
1504
1505 We then determine what the console should be on various systems:
1506
1507 =over 4
1508
1509 =item * Cygwin - We use C<stdin> instead of a separate device.
1510
1511 =cut
1512
1513     if ( $^O eq 'cygwin' ) {
1514
1515         # /dev/tty is binary. use stdin for textmode
1516         undef $console;
1517     }
1518
1519 =item * Unix - use C</dev/tty>.
1520
1521 =cut
1522
1523     elsif ( -e "/dev/tty" ) {
1524         $console = "/dev/tty";
1525     }
1526
1527 =item * Windows or MSDOS - use C<con>.
1528
1529 =cut
1530
1531     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1532         $console = "con";
1533     }
1534
1535 =item * VMS - use C<sys$command>.
1536
1537 =cut
1538
1539     else {
1540
1541         # everything else is ...
1542         $console = "sys\$command";
1543     }
1544
1545 =pod
1546
1547 =back
1548
1549 Several other systems don't use a specific console. We C<undef $console>
1550 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1551 with a slave editor, Epoc).
1552
1553 =cut
1554
1555     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1556
1557         # /dev/tty is binary. use stdin for textmode
1558         $console = undef;
1559     }
1560
1561     if ( $^O eq 'NetWare' ) {
1562
1563         # /dev/tty is binary. use stdin for textmode
1564         $console = undef;
1565     }
1566
1567     # In OS/2, we need to use STDIN to get textmode too, even though
1568     # it pretty much looks like Unix otherwise.
1569     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1570     {    # In OS/2
1571         $console = undef;
1572     }
1573
1574     # EPOC also falls into the 'got to use STDIN' camp.
1575     if ( $^O eq 'epoc' ) {
1576         $console = undef;
1577     }
1578
1579 =pod
1580
1581 If there is a TTY hanging around from a parent, we use that as the console.
1582
1583 =cut
1584
1585     $console = $tty if defined $tty;
1586
1587 =head2 SOCKET HANDLING
1588
1589 The debugger is capable of opening a socket and carrying out a debugging
1590 session over the socket.
1591
1592 If C<RemotePort> was defined in the options, the debugger assumes that it
1593 should try to start a debugging session on that port. It builds the socket
1594 and then tries to connect the input and output filehandles to it.
1595
1596 =cut
1597
1598     # Handle socket stuff.
1599
1600     if ( defined $remoteport ) {
1601
1602         # If RemotePort was defined in the options, connect input and output
1603         # to the socket.
1604         $IN = $OUT = connect_remoteport();
1605     } ## end if (defined $remoteport)
1606
1607 =pod
1608
1609 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1610 this is probably a situation where multiple debuggers are running (for example,
1611 a backticked command that starts up another debugger). We create a new IN and
1612 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1613 and if we can.
1614
1615 =cut
1616
1617     # Non-socket.
1618     else {
1619
1620         # Two debuggers running (probably a system or a backtick that invokes
1621         # the debugger itself under the running one). create a new IN and OUT
1622         # filehandle, and do the necessary mojo to create a new tty if we
1623         # know how, and we can.
1624         create_IN_OUT(4) if $CreateTTY & 4;
1625         if ($console) {
1626
1627             # If we have a console, check to see if there are separate ins and
1628             # outs to open. (They are assumed identical if not.)
1629
1630             my ( $i, $o ) = split /,/, $console;
1631             $o = $i unless defined $o;
1632
1633             # read/write on in, or just read, or read on STDIN.
1634             open( IN,      "+<$i" )
1635               || open( IN, "<$i" )
1636               || open( IN, "<&STDIN" );
1637
1638             # read/write/create/clobber out, or write/create/clobber out,
1639             # or merge with STDERR, or merge with STDOUT.
1640                  open( OUT, "+>$o" )
1641               || open( OUT, ">$o" )
1642               || open( OUT, ">&STDERR" )
1643               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1644
1645         } ## end if ($console)
1646         elsif ( not defined $console ) {
1647
1648             # No console. Open STDIN.
1649             open( IN, "<&STDIN" );
1650
1651             # merge with STDERR, or with STDOUT.
1652             open( OUT,      ">&STDERR" )
1653               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1654             $console = 'STDIN/OUT';
1655         } ## end elsif (not defined $console)
1656
1657         # Keep copies of the filehandles so that when the pager runs, it
1658         # can close standard input without clobbering ours.
1659         if ($console or (not defined($console))) {
1660             $IN = \*IN;
1661             $OUT = \*OUT;
1662         }
1663     } ## end elsif (from if(defined $remoteport))
1664
1665     # Unbuffer DB::OUT. We need to see responses right away.
1666     $OUT->autoflush(1);
1667
1668     # Line info goes to debugger output unless pointed elsewhere.
1669     # Pointing elsewhere makes it possible for slave editors to
1670     # keep track of file and position. We have both a filehandle
1671     # and a I/O description to keep track of.
1672     $LINEINFO = $OUT     unless defined $LINEINFO;
1673     $lineinfo = $console unless defined $lineinfo;
1674     # share($LINEINFO); # <- unable to share globs
1675     share($lineinfo);   #
1676
1677 =pod
1678
1679 To finish initialization, we show the debugger greeting,
1680 and then call the C<afterinit()> subroutine if there is one.
1681
1682 =cut
1683
1684     # Show the debugger greeting.
1685     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1686     unless ($runnonstop) {
1687         local $\ = '';
1688         local $, = '';
1689         if ( $term_pid eq '-1' ) {
1690             print $OUT "\nDaughter DB session started...\n";
1691         }
1692         else {
1693             print $OUT "\nLoading DB routines from $header\n";
1694             print $OUT (
1695                 "Editor support ",
1696                 $slave_editor ? "enabled" : "available", ".\n"
1697             );
1698             print $OUT
1699 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1700         } ## end else [ if ($term_pid eq '-1')
1701     } ## end unless ($runnonstop)
1702 } ## end else [ if ($notty)
1703
1704 # XXX This looks like a bug to me.
1705 # Why copy to @ARGS and then futz with @args?
1706 @ARGS = @ARGV;
1707 # for (@args) {
1708     # Make sure backslashes before single quotes are stripped out, and
1709     # keep args unless they are numeric (XXX why?)
1710     # s/\'/\\\'/g;                      # removed while not justified understandably
1711     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1712 # }
1713
1714 # If there was an afterinit() sub defined, call it. It will get
1715 # executed in our scope, so it can fiddle with debugger globals.
1716 if ( defined &afterinit ) {    # May be defined in $rcfile
1717     afterinit();
1718 }
1719
1720 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1721 use vars qw($I_m_init);
1722
1723 $I_m_init = 1;
1724
1725 ############################################################ Subroutines
1726
1727 =head1 SUBROUTINES
1728
1729 =head2 DB
1730
1731 This gigantic subroutine is the heart of the debugger. Called before every
1732 statement, its job is to determine if a breakpoint has been reached, and
1733 stop if so; read commands from the user, parse them, and execute
1734 them, and then send execution off to the next statement.
1735
1736 Note that the order in which the commands are processed is very important;
1737 some commands earlier in the loop will actually alter the C<$cmd> variable
1738 to create other commands to be executed later. This is all highly I<optimized>
1739 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1740 see what's happening in any given command.
1741
1742 =cut
1743
1744 use vars qw(
1745     $action
1746     %alias
1747     $cmd
1748     $fall_off_end
1749     $file
1750     $filename_ini
1751     $finished
1752     %had_breakpoints
1753     $level
1754     $max
1755     $package
1756     $sh
1757     $try
1758     $end
1759 );
1760
1761 our (
1762     $doret,
1763     $incr,
1764     $laststep,
1765     $rc,
1766     $stack_depth,
1767     @stack,
1768     @to_watch,
1769     @old_watch,
1770 );
1771
1772 sub _DB__determine_if_we_should_break
1773 {
1774     # if we have something here, see if we should break.
1775     # $stop is lexical and local to this block - $action on the other hand
1776     # is global.
1777     my $stop;
1778
1779     if ( $dbline{$line}
1780         && _is_breakpoint_enabled($filename, $line)
1781         && (( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1782     {
1783
1784         # Stop if the stop criterion says to just stop.
1785         if ( $stop eq '1' ) {
1786             $signal |= 1;
1787         }
1788
1789         # It's a conditional stop; eval it in the user's context and
1790         # see if we should stop. If so, remove the one-time sigil.
1791         elsif ($stop) {
1792             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1793             &eval;
1794             # If the breakpoint is temporary, then delete its enabled status.
1795             if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1796                 _cancel_breakpoint_temp_enabled_status($filename, $line);
1797             }
1798         }
1799     } ## end if ($dbline{$line} && ...
1800 }
1801
1802 sub _DB__is_finished {
1803     if ($finished and $level <= 1) {
1804         end_report();
1805         return 1;
1806     }
1807     else {
1808         return;
1809     }
1810 }
1811
1812 sub _DB__read_next_cmd
1813 {
1814     my ($tid) = @_;
1815
1816     # We have a terminal, or can get one ...
1817     if (!$term) {
1818         setterm();
1819     }
1820
1821     # ... and it belogs to this PID or we get one for this PID ...
1822     if ($term_pid != $$) {
1823         resetterm(1);
1824     }
1825
1826     # ... and we got a line of command input ...
1827     $cmd = DB::readline(
1828         "$pidprompt $tid DB"
1829         . ( '<' x $level )
1830         . ( $#hist + 1 )
1831         . ( '>' x $level ) . " "
1832     );
1833
1834     return defined($cmd);
1835 }
1836
1837 sub _DB__trim_command_and_return_first_component {
1838     $cmd =~ s/\A\s+//s;    # trim annoying leading whitespace
1839     $cmd =~ s/\s+\z//s;    # trim annoying trailing whitespace
1840
1841     $cmd =~ m{\A(\S*)};
1842     return $1;
1843 }
1844
1845 sub _DB__handle_f_command {
1846     if (($file) = $cmd =~ /\Af\b\s*(.*)/) {
1847         $file =~ s/\s+$//;
1848
1849         # help for no arguments (old-style was return from sub).
1850         if ( !$file ) {
1851             print $OUT
1852             "The old f command is now the r command.\n";    # hint
1853             print $OUT "The new f command switches filenames.\n";
1854             next CMD;
1855         } ## end if (!$file)
1856
1857         # if not in magic file list, try a close match.
1858         if ( !defined $main::{ '_<' . $file } ) {
1859             if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
1860                 {
1861                     $try = substr( $try, 2 );
1862                     print $OUT "Choosing $try matching '$file':\n";
1863                     $file = $try;
1864                 }
1865             } ## end if (($try) = grep(m#^_<.*$file#...
1866         } ## end if (!defined $main::{ ...
1867
1868         # If not successfully switched now, we failed.
1869         if ( !defined $main::{ '_<' . $file } ) {
1870             print $OUT "No file matching '$file' is loaded.\n";
1871             next CMD;
1872         }
1873
1874         # We switched, so switch the debugger internals around.
1875         elsif ( $file ne $filename ) {
1876             *dbline   = $main::{ '_<' . $file };
1877             $max      = $#dbline;
1878             $filename = $file;
1879             $start    = 1;
1880             $cmd      = "l";
1881         } ## end elsif ($file ne $filename)
1882
1883         # We didn't switch; say we didn't.
1884         else {
1885             print $OUT "Already in $file.\n";
1886             next CMD;
1887         }
1888     }
1889
1890     return;
1891 }
1892
1893 sub _DB__handle_dot_command {
1894     my ($obj) = @_;
1895
1896     # . command.
1897     if ($cmd eq '.') {
1898         $incr = -1;    # stay at current line
1899
1900         # Reset everything to the old location.
1901         $start    = $line;
1902         $filename = $filename_ini;
1903         *dbline   = $main::{ '_<' . $filename };
1904         $max      = $#dbline;
1905
1906         # Now where are we?
1907         print_lineinfo($obj->position());
1908         next CMD;
1909     }
1910
1911     return;
1912 }
1913
1914 sub _DB__handle_y_command {
1915     my ($obj) = @_;
1916
1917     if (my ($match_level, $match_vars)
1918         = $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/) {
1919
1920         # See if we've got the necessary support.
1921         eval { require PadWalker; PadWalker->VERSION(0.08) }
1922             or &warn(
1923             $@ =~ /locate/
1924             ? "PadWalker module not found - please install\n"
1925             : $@
1926         )
1927             and next CMD;
1928
1929         # Load up dumpvar if we don't have it. If we can, that is.
1930         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
1931         defined &main::dumpvar
1932             or print $OUT "dumpvar.pl not available.\n"
1933             and next CMD;
1934
1935         # Got all the modules we need. Find them and print them.
1936         my @vars = split( ' ', $match_vars || '' );
1937
1938         # Find the pad.
1939         my $h = eval { PadWalker::peek_my( ( $match_level || 0 ) + 1 ) };
1940
1941         # Oops. Can't find it.
1942         $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
1943
1944         # Show the desired vars with dumplex().
1945         my $savout = select($OUT);
1946
1947         # Have dumplex dump the lexicals.
1948         dumpvar::dumplex( $_, $h->{$_},
1949             defined $option{dumpDepth} ? $option{dumpDepth} : -1,
1950             @vars )
1951         for sort keys %$h;
1952         select($savout);
1953         next CMD;
1954     }
1955 }
1956
1957 sub _DB__handle_c_command {
1958     my ($obj) = @_;
1959
1960     if (my ($new_i) = $cmd =~ m#\Ac\b\s*([\w:]*)\s*\z#) {
1961
1962         $obj->i_cmd($new_i);
1963
1964         # Hey, show's over. The debugged program finished
1965         # executing already.
1966         next CMD if _DB__is_finished();
1967
1968         # Capture the place to put a one-time break.
1969         $subname = $obj->i_cmd;
1970
1971         #  Probably not needed, since we finish an interactive
1972         #  sub-session anyway...
1973         # local $filename = $filename;
1974         # local *dbline = *dbline; # XXX Would this work?!
1975         #
1976         # The above question wonders if localizing the alias
1977         # to the magic array works or not. Since it's commented
1978         # out, we'll just leave that to speculation for now.
1979
1980         # If the "subname" isn't all digits, we'll assume it
1981         # is a subroutine name, and try to find it.
1982         if ( $subname =~ /\D/ ) {    # subroutine name
1983             # Qualify it to the current package unless it's
1984             # already qualified.
1985             $subname = $package . "::" . $subname
1986             unless $subname =~ /::/;
1987
1988             # find_sub will return "file:line_number" corresponding
1989             # to where the subroutine is defined; we call find_sub,
1990             # break up the return value, and assign it in one
1991             # operation.
1992             ( $file, $new_i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
1993
1994             # Force the line number to be numeric.
1995             $obj->i_cmd($new_i + 0);
1996
1997             # If we got a line number, we found the sub.
1998             if ($obj->i_cmd) {
1999
2000                 # Switch all the debugger's internals around so
2001                 # we're actually working with that file.
2002                 $filename = $file;
2003                 *dbline   = $main::{ '_<' . $filename };
2004
2005                 # Mark that there's a breakpoint in this file.
2006                 $had_breakpoints{$filename} |= 1;
2007
2008                 # Scan forward to the first executable line
2009                 # after the 'sub whatever' line.
2010                 $max = $#dbline;
2011                 my $ii = $obj->i_cmd;
2012                 ++$ii while $dbline[$ii] == 0 && $ii < $max;
2013                 $obj->i_cmd($ii);
2014             } ## end if ($i)
2015
2016             # We didn't find a sub by that name.
2017             else {
2018                 print $OUT "Subroutine $subname not found.\n";
2019                 next CMD;
2020             }
2021         } ## end if ($subname =~ /\D/)
2022
2023         # At this point, either the subname was all digits (an
2024         # absolute line-break request) or we've scanned through
2025         # the code following the definition of the sub, looking
2026         # for an executable, which we may or may not have found.
2027         #
2028         # If $i (which we set $subname from) is non-zero, we
2029         # got a request to break at some line somewhere. On
2030         # one hand, if there wasn't any real subroutine name
2031         # involved, this will be a request to break in the current
2032         # file at the specified line, so we have to check to make
2033         # sure that the line specified really is breakable.
2034         #
2035         # On the other hand, if there was a subname supplied, the
2036         # preceding block has moved us to the proper file and
2037         # location within that file, and then scanned forward
2038         # looking for the next executable line. We have to make
2039         # sure that one was found.
2040         #
2041         # On the gripping hand, we can't do anything unless the
2042         # current value of $i points to a valid breakable line.
2043         # Check that.
2044         if ($obj->i_cmd) {
2045
2046             # Breakable?
2047             if ( $dbline[$obj->i_cmd] == 0 ) {
2048                 print $OUT "Line " . $obj->i_cmd . " not breakable.\n";
2049                 next CMD;
2050             }
2051
2052             # Yes. Set up the one-time-break sigil.
2053             $dbline{$obj->i_cmd} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2054             _enable_breakpoint_temp_enabled_status($filename, $obj->i_cmd);
2055         } ## end if ($i)
2056
2057         # Turn off stack tracing from here up.
2058         for my $i (0 .. $stack_depth) {
2059             $stack[ $i ] &= ~1;
2060         }
2061         last CMD;
2062     }
2063
2064     return;
2065 }
2066
2067 sub _DB__handle_forward_slash_command {
2068     my ($obj) = @_;
2069
2070     # The pattern as a string.
2071     use vars qw($inpat);
2072
2073     if (($inpat) = $cmd =~ m#\A/(.*)\z#) {
2074
2075         # Remove the final slash.
2076         $inpat =~ s:([^\\])/$:$1:;
2077
2078         # If the pattern isn't null ...
2079         if ( $inpat ne "" ) {
2080
2081             # Turn of warn and die procesing for a bit.
2082             local $SIG{__DIE__};
2083             local $SIG{__WARN__};
2084
2085             # Create the pattern.
2086             eval 'no strict q/vars/; $inpat =~ m' . "\a$inpat\a";
2087             if ( $@ ne "" ) {
2088
2089                 # Oops. Bad pattern. No biscuit.
2090                 # Print the eval error and go back for more
2091                 # commands.
2092                 print $OUT "$@";
2093                 next CMD;
2094             }
2095             $obj->pat($inpat);
2096         } ## end if ($inpat ne "")
2097
2098         # Set up to stop on wrap-around.
2099         $end = $start;
2100
2101         # Don't move off the current line.
2102         $incr = -1;
2103
2104         my $pat = $obj->pat;
2105
2106         # Done in eval so nothing breaks if the pattern
2107         # does something weird.
2108         eval
2109         {
2110             no strict q/vars/;
2111             for (;;) {
2112                 # Move ahead one line.
2113                 ++$start;
2114
2115                 # Wrap if we pass the last line.
2116                 $start = 1 if ($start > $max);
2117
2118                 # Stop if we have gotten back to this line again,
2119                 last if ($start == $end);
2120
2121                 # A hit! (Note, though, that we are doing
2122                 # case-insensitive matching. Maybe a qr//
2123                 # expression would be better, so the user could
2124                 # do case-sensitive matching if desired.
2125                 if ($dbline[$start] =~ m/$pat/i) {
2126                     if ($slave_editor) {
2127                         # Handle proper escaping in the slave.
2128                         print $OUT "\032\032$filename:$start:0\n";
2129                     }
2130                     else {
2131                         # Just print the line normally.
2132                         print $OUT "$start:\t",$dbline[$start],"\n";
2133                     }
2134                     # And quit since we found something.
2135                     last;
2136                 }
2137             }
2138         };
2139
2140         if ($@) {
2141             warn $@;
2142         }
2143
2144         # If we wrapped, there never was a match.
2145         if ( $start == $end ) {
2146             print {$OUT} "/$pat/: not found\n";
2147         }
2148         next CMD;
2149     }
2150
2151     return;
2152 }
2153
2154 sub _DB__handle_question_mark_command {
2155     my ($obj) = @_;
2156
2157     # ? - backward pattern search.
2158     if (my ($inpat) = $cmd =~ m#\A\?(.*)\z#) {
2159
2160         # Get the pattern, remove trailing question mark.
2161         $inpat =~ s:([^\\])\?$:$1:;
2162
2163         # If we've got one ...
2164         if ( $inpat ne "" ) {
2165
2166             # Turn off die & warn handlers.
2167             local $SIG{__DIE__};
2168             local $SIG{__WARN__};
2169             eval '$inpat =~ m' . "\a$inpat\a";
2170
2171             if ( $@ ne "" ) {
2172
2173                 # Ouch. Not good. Print the error.
2174                 print $OUT $@;
2175                 next CMD;
2176             }
2177             $obj->pat($inpat);
2178         } ## end if ($inpat ne "")
2179
2180         # Where we are now is where to stop after wraparound.
2181         $end = $start;
2182
2183         # Don't move away from this line.
2184         $incr = -1;
2185
2186         my $pat = $obj->pat;
2187         # Search inside the eval to prevent pattern badness
2188         # from killing us.
2189         eval {
2190             no strict q/vars/;
2191             for (;;) {
2192                 # Back up a line.
2193                 --$start;
2194
2195                 # Wrap if we pass the first line.
2196
2197                 $start = $max if ($start <= 0);
2198
2199                 # Quit if we get back where we started,
2200                 last if ($start == $end);
2201
2202                 # Match?
2203                 if ($dbline[$start] =~ m/$pat/i) {
2204                     if ($slave_editor) {
2205                         # Yep, follow slave editor requirements.
2206                         print $OUT "\032\032$filename:$start:0\n";
2207                     }
2208                     else {
2209                         # Yep, just print normally.
2210                         print $OUT "$start:\t",$dbline[$start],"\n";
2211                     }
2212
2213                     # Found, so done.
2214                     last;
2215                 }
2216             }
2217         };
2218
2219         # Say we failed if the loop never found anything,
2220         if ( $start == $end ) {
2221             print {$OUT} "?$pat?: not found\n";
2222         }
2223         next CMD;
2224     }
2225
2226     return;
2227 }
2228
2229 sub DB {
2230
2231     # lock the debugger and get the thread id for the prompt
2232     lock($DBGR);
2233     my $tid;
2234     my $position;
2235     my ($prefix, $after, $infix);
2236     my $pat;
2237     my $explicit_stop;
2238
2239     if ($ENV{PERL5DB_THREADED}) {
2240         $tid = eval { "[".threads->tid."]" };
2241     }
2242
2243     my $i;
2244
2245     my $obj = DB::Obj->new(
2246         {
2247             position => \$position,
2248             prefix => \$prefix,
2249             after => \$after,
2250             explicit_stop => \$explicit_stop,
2251             infix => \$infix,
2252             i_cmd => \$i,
2253             pat => \$pat,
2254         },
2255     );
2256
2257     $obj->_DB_on_init__initialize_globals(@_);
2258
2259     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
2260     # The code being debugged may have altered them.
2261     &save;
2262
2263     # Since DB::DB gets called after every line, we can use caller() to
2264     # figure out where we last were executing. Sneaky, eh? This works because
2265     # caller is returning all the extra information when called from the
2266     # debugger.
2267     local ( $package, $filename, $line ) = caller;
2268     $filename_ini = $filename;
2269
2270     # set up the context for DB::eval, so it can properly execute
2271     # code on behalf of the user. We add the package in so that the
2272     # code is eval'ed in the proper package (not in the debugger!).
2273     local $usercontext = _calc_usercontext($package);
2274
2275     # Create an alias to the active file magical array to simplify
2276     # the code here.
2277     local (*dbline) = $main::{ '_<' . $filename };
2278
2279     # Last line in the program.
2280     $max = $#dbline;
2281
2282     _DB__determine_if_we_should_break(@_);
2283
2284     # Preserve the current stop-or-not, and see if any of the W
2285     # (watch expressions) has changed.
2286     my $was_signal = $signal;
2287
2288     # If we have any watch expressions ...
2289     $obj->_DB__handle_watch_expressions(@_);
2290
2291 =head2 C<watchfunction()>
2292
2293 C<watchfunction()> is a function that can be defined by the user; it is a
2294 function which will be run on each entry to C<DB::DB>; it gets the
2295 current package, filename, and line as its parameters.
2296
2297 The watchfunction can do anything it likes; it is executing in the
2298 debugger's context, so it has access to all of the debugger's internal
2299 data structures and functions.
2300
2301 C<watchfunction()> can control the debugger's actions. Any of the following
2302 will cause the debugger to return control to the user's program after
2303 C<watchfunction()> executes:
2304
2305 =over 4
2306
2307 =item *
2308
2309 Returning a false value from the C<watchfunction()> itself.
2310
2311 =item *
2312
2313 Altering C<$single> to a false value.
2314
2315 =item *
2316
2317 Altering C<$signal> to a false value.
2318
2319 =item *
2320
2321 Turning off the C<4> bit in C<$trace> (this also disables the
2322 check for C<watchfunction()>. This can be done with
2323
2324     $trace &= ~4;
2325
2326 =back
2327
2328 =cut
2329
2330     # If there's a user-defined DB::watchfunction, call it with the
2331     # current package, filename, and line. The function executes in
2332     # the DB:: package.
2333     if ( $trace & 4 ) {    # User-installed watch
2334         return
2335           if watchfunction( $package, $filename, $line )
2336           and not $single
2337           and not $was_signal
2338           and not( $trace & ~4 );
2339     } ## end if ($trace & 4)
2340
2341     # Pick up any alteration to $signal in the watchfunction, and
2342     # turn off the signal now.
2343     $was_signal = $signal;
2344     $signal     = 0;
2345
2346 =head2 GETTING READY TO EXECUTE COMMANDS
2347
2348 The debugger decides to take control if single-step mode is on, the
2349 C<t> command was entered, or the user generated a signal. If the program
2350 has fallen off the end, we set things up so that entering further commands
2351 won't cause trouble, and we say that the program is over.
2352
2353 =cut
2354
2355     # Make sure that we always print if asked for explicitly regardless
2356     # of $trace_to_depth .
2357     $explicit_stop = ($single || $was_signal);
2358
2359     # Check to see if we should grab control ($single true,
2360     # trace set appropriately, or we got a signal).
2361     if ( $explicit_stop || ( $trace & 1 ) ) {
2362         $obj->_DB__grab_control(@_);
2363     } ## end if ($single || ($trace...
2364
2365 =pod
2366
2367 If there's an action to be executed for the line we stopped at, execute it.
2368 If there are any preprompt actions, execute those as well.
2369
2370 =cut
2371
2372     # If there's an action, do it now.
2373     if ($action) {
2374         $evalarg = $action;
2375         DB::eval();
2376     }
2377
2378     # Are we nested another level (e.g., did we evaluate a function
2379     # that had a breakpoint in it at the debugger prompt)?
2380     if ( $single || $was_signal ) {
2381
2382         # Yes, go down a level.
2383         local $level = $level + 1;
2384
2385         # Do any pre-prompt actions.
2386         foreach $evalarg (@$pre) {
2387             DB::eval();
2388         }
2389
2390         # Complain about too much recursion if we passed the limit.
2391         if ($single & 4) {
2392             print $OUT $stack_depth . " levels deep in subroutine calls!\n";
2393         }
2394
2395         # The line we're currently on. Set $incr to -1 to stay here
2396         # until we get a command that tells us to advance.
2397         $start = $line;
2398         $incr  = -1;      # for backward motion.
2399
2400         # Tack preprompt debugger actions ahead of any actual input.
2401         @typeahead = ( @$pretype, @typeahead );
2402
2403 =head2 WHERE ARE WE?
2404
2405 XXX Relocate this section?
2406
2407 The debugger normally shows the line corresponding to the current line of
2408 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2409 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2410
2411 C<$incr> controls by how many lines the I<current> line should move forward
2412 after a command is executed. If set to -1, this indicates that the I<current>
2413 line shouldn't change.
2414
2415 C<$start> is the I<current> line. It is used for things like knowing where to
2416 move forwards or backwards from when doing an C<L> or C<-> command.
2417
2418 C<$max> tells the debugger where the last line of the current file is. It's
2419 used to terminate loops most often.
2420
2421 =head2 THE COMMAND LOOP
2422
2423 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2424 in two parts:
2425
2426 =over 4
2427
2428 =item *
2429
2430 The outer part of the loop, starting at the C<CMD> label. This loop
2431 reads a command and then executes it.
2432
2433 =item *
2434
2435 The inner part of the loop, starting at the C<PIPE> label. This part
2436 is wholly contained inside the C<CMD> block and only executes a command.
2437 Used to handle commands running inside a pager.
2438
2439 =back
2440
2441 So why have two labels to restart the loop? Because sometimes, it's easier to
2442 have a command I<generate> another command and then re-execute the loop to do
2443 the new command. This is faster, but perhaps a bit more convoluted.
2444
2445 =cut
2446
2447         # The big command dispatch loop. It keeps running until the
2448         # user yields up control again.
2449         #
2450         # If we have a terminal for input, and we get something back
2451         # from readline(), keep on processing.
2452         my $piped;
2453         my $selected;
2454
2455       CMD:
2456         while (_DB__read_next_cmd($tid))
2457         {
2458
2459             share($cmd);
2460             # ... try to execute the input as debugger commands.
2461
2462             # Don't stop running.
2463             $single = 0;
2464
2465             # No signal is active.
2466             $signal = 0;
2467
2468             # Handle continued commands (ending with \):
2469             if ($cmd =~ s/\\\z/\n/) {
2470                 $cmd .= DB::readline("  cont: ");
2471                 redo CMD;
2472             }
2473
2474 =head4 The null command
2475
2476 A newline entered by itself means I<re-execute the last command>. We grab the
2477 command out of C<$laststep> (where it was recorded previously), and copy it
2478 back into C<$cmd> to be executed below. If there wasn't any previous command,
2479 we'll do nothing below (no command will match). If there was, we also save it
2480 in the command history and fall through to allow the command parsing to pick
2481 it up.
2482
2483 =cut
2484
2485             # Empty input means repeat the last command.
2486             if ($cmd eq '') {
2487                 $cmd = $laststep;
2488             }
2489             chomp($cmd);    # get rid of the annoying extra newline
2490             if (length($cmd) >= 2) {
2491                 push( @hist, $cmd );
2492             }
2493             push( @truehist, $cmd );
2494             share(@hist);
2495             share(@truehist);
2496
2497             # This is a restart point for commands that didn't arrive
2498             # via direct user input. It allows us to 'redo PIPE' to
2499             # re-execute command processing without reading a new command.
2500           PIPE: {
2501                 $i = _DB__trim_command_and_return_first_component();
2502
2503 =head3 COMMAND ALIASES
2504
2505 The debugger can create aliases for commands (these are stored in the
2506 C<%alias> hash). Before a command is executed, the command loop looks it up
2507 in the alias hash and substitutes the contents of the alias for the command,
2508 completely replacing it.
2509
2510 =cut
2511
2512                 # See if there's an alias for the command, and set it up if so.
2513                 if ( $alias{$i} ) {
2514
2515                     # Squelch signal handling; we want to keep control here
2516                     # if something goes loco during the alias eval.
2517                     local $SIG{__DIE__};
2518                     local $SIG{__WARN__};
2519
2520                     # This is a command, so we eval it in the DEBUGGER's
2521                     # scope! Otherwise, we can't see the special debugger
2522                     # variables, or get to the debugger's subs. (Well, we
2523                     # _could_, but why make it even more complicated?)
2524                     eval "\$cmd =~ $alias{$i}";
2525                     if ($@) {
2526                         local $\ = '';
2527                         print $OUT "Couldn't evaluate '$i' alias: $@";
2528                         next CMD;
2529                     }
2530                 } ## end if ($alias{$i})
2531
2532 =head3 MAIN-LINE COMMANDS
2533
2534 All of these commands work up to and after the program being debugged has
2535 terminated.
2536
2537 =head4 C<q> - quit
2538
2539 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2540 try to execute further, cleaning any restart-related stuff out of the
2541 environment, and executing with the last value of C<$?>.
2542
2543 =cut
2544
2545                 if ($cmd eq 'q') {
2546                     $fall_off_end = 1;
2547                     clean_ENV();
2548                     exit $?;
2549                 }
2550
2551 =head4 C<t> - trace [n]
2552
2553 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2554 If level is specified, set C<$trace_to_depth>.
2555
2556 =cut
2557
2558                 $obj->_handle_t_command;
2559
2560 =head4 C<S> - list subroutines matching/not matching a pattern
2561
2562 Walks through C<%sub>, checking to see whether or not to print the name.
2563
2564 =cut
2565
2566                 $obj->_handle_S_command;
2567
2568 =head4 C<X> - list variables in current package
2569
2570 Since the C<V> command actually processes this, just change this to the
2571 appropriate C<V> command and fall through.
2572
2573 =head4 C<V> - list variables
2574
2575 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2576
2577 =cut
2578
2579                 $obj->_handle_V_command_and_X_command;
2580
2581 =head4 C<x> - evaluate and print an expression
2582
2583 Hands the expression off to C<DB::eval>, setting it up to print the value
2584 via C<dumpvar.pl> instead of just printing it directly.
2585
2586 =cut
2587
2588                 if ($cmd =~ s#\Ax\b# #) {    # Remainder gets done by DB::eval()
2589                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2590
2591                     # handle special  "x 3 blah" syntax XXX propagate
2592                     # doc back to special variables.
2593                     if ( $cmd =~ s#\A\s*(\d+)(?=\s)# #) {
2594                         $onetimedumpDepth = $1;
2595                     }
2596                 }
2597
2598 =head4 C<m> - print methods
2599
2600 Just uses C<DB::methods> to determine what methods are available.
2601
2602 =cut
2603
2604                 if ($cmd =~ s#\Am\s+([\w:]+)\s*\z# #) {
2605                     methods($1);
2606                     next CMD;
2607                 }
2608
2609                 # m expr - set up DB::eval to do the work
2610                 if ($cmd =~ s#\Am\b# #) {    # Rest gets done by DB::eval()
2611                     $onetimeDump = 'methods';   #  method output gets used there
2612                 }
2613
2614 =head4 C<f> - switch files
2615
2616 =cut
2617
2618                 _DB__handle_f_command();
2619
2620 =head4 C<.> - return to last-executed line.
2621
2622 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2623 and then we look up the line in the magical C<%dbline> hash.
2624
2625 =cut
2626
2627         _DB__handle_dot_command($obj);
2628
2629 =head4 C<-> - back one window
2630
2631 We change C<$start> to be one window back; if we go back past the first line,
2632 we set it to be the first line. We ser C<$incr> to put us back at the
2633 currently-executing line, and then put a C<l $start +> (list one window from
2634 C<$start>) in C<$cmd> to be executed later.
2635
2636 =cut
2637
2638                 # - - back a window.
2639                 $obj->_handle_dash_command;
2640
2641 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, E<0x7B>, E<0x7B>E<0x7B>>
2642
2643 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2644 problems, most notably that the default case of several commands destroying
2645 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2646 retain the old commands for those who were used to using them or who preferred
2647 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2648 deal with them instead of processing them in-line.
2649
2650 =cut
2651
2652                 # All of these commands were remapped in perl 5.8.0;
2653                 # we send them off to the secondary dispatcher (see below).
2654                 if (my ($cmd_letter, $my_arg) = $cmd =~ /\A([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so) {
2655                     &cmd_wrapper( $cmd_letter, $my_arg, $line );
2656                     next CMD;
2657                 }
2658
2659 =head4 C<y> - List lexicals in higher scope
2660
2661 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2662 above the current one and then displays then using C<dumpvar.pl>.
2663
2664 =cut
2665
2666                 _DB__handle_y_command($obj);
2667
2668 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2669
2670 All of the commands below this point don't work after the program being
2671 debugged has ended. All of them check to see if the program has ended; this
2672 allows the commands to be relocated without worrying about a 'line of
2673 demarcation' above which commands can be entered anytime, and below which
2674 they can't.
2675
2676 =head4 C<n> - single step, but don't trace down into subs
2677
2678 Done by setting C<$single> to 2, which forces subs to execute straight through
2679 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2680 so a null command knows what to re-execute.
2681
2682 =cut
2683
2684                 # n - next
2685                 $obj->_handle_n_command;
2686
2687 =head4 C<s> - single-step, entering subs
2688
2689 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2690 subs. Also saves C<s> as C<$lastcmd>.
2691
2692 =cut
2693
2694                 $obj->_handle_s_command;
2695
2696 =head4 C<c> - run continuously, setting an optional breakpoint
2697
2698 Most of the code for this command is taken up with locating the optional
2699 breakpoint, which is either a subroutine name or a line number. We set
2700 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2701 in this and all call levels above this one.
2702
2703 =cut
2704
2705                 # c - start continuous execution.
2706                 _DB__handle_c_command($obj);
2707
2708 =head4 C<r> - return from a subroutine
2709
2710 For C<r> to work properly, the debugger has to stop execution again
2711 immediately after the return is executed. This is done by forcing
2712 single-stepping to be on in the call level above the current one. If
2713 we are printing return values when a C<r> is executed, set C<$doret>
2714 appropriately, and force us out of the command loop.
2715
2716 =cut
2717
2718                 # r - return from the current subroutine.
2719                 $obj->_handle_r_command;
2720
2721 =head4 C<T> - stack trace
2722
2723 Just calls C<DB::print_trace>.
2724
2725 =cut
2726
2727                 $obj->_handle_T_command;
2728
2729 =head4 C<w> - List window around current line.
2730
2731 Just calls C<DB::cmd_w>.
2732
2733 =cut
2734
2735                 $obj->_handle_w_command;
2736
2737 =head4 C<W> - watch-expression processing.
2738
2739 Just calls C<DB::cmd_W>.
2740
2741 =cut
2742
2743                 $obj->_handle_W_command;
2744
2745 =head4 C</> - search forward for a string in the source
2746
2747 We take the argument and treat it as a pattern. If it turns out to be a
2748 bad one, we return the error we got from trying to C<eval> it and exit.
2749 If not, we create some code to do the search and C<eval> it so it can't
2750 mess us up.
2751
2752 =cut
2753
2754                 _DB__handle_forward_slash_command($obj);
2755
2756 =head4 C<?> - search backward for a string in the source
2757
2758 Same as for C</>, except the loop runs backwards.
2759
2760 =cut
2761
2762                 _DB__handle_question_mark_command($obj);
2763
2764 =head4 C<$rc> - Recall command
2765
2766 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2767 that the terminal supports history). It find the the command required, puts it
2768 into C<$cmd>, and redoes the loop to execute it.
2769
2770 =cut
2771
2772                 # $rc - recall command.
2773                 $obj->_handle_rc_recall_command;
2774
2775 =head4 C<$sh$sh> - C<system()> command
2776
2777 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
2778 C<STDOUT> from getting messed up.
2779
2780 =cut
2781
2782                 # $sh$sh - run a shell command (if it's all ASCII).
2783                 # Can't run shell commands with Unicode in the debugger, hmm.
2784                 if (my ($arg) = $cmd =~ m#\A$sh$sh\s*(.*)#ms) {
2785
2786                     # System it.
2787                     &system($arg);
2788                     next CMD;
2789                 }
2790
2791 =head4 C<$rc I<pattern> $rc> - Search command history
2792
2793 Another command to manipulate C<@hist>: this one searches it with a pattern.
2794 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
2795
2796 =cut
2797
2798                 # $rc pattern $rc - find a command in the history.
2799                 if (my ($arg) = $cmd =~ /\A$rc([^$rc].*)\z/) {
2800
2801                     # Create the pattern to use.
2802                     $pat = "^$arg";
2803
2804                     # Toss off last entry if length is >1 (and it always is).
2805                     pop(@hist) if length($cmd) > 1;
2806
2807                     # Look backward through the history.
2808                     for ( $i = $#hist ; $i ; --$i ) {
2809                         # Stop if we find it.
2810                         last if $hist[$i] =~ /$pat/;
2811                     }
2812
2813                     if ( !$i ) {
2814
2815                         # Never found it.
2816                         print $OUT "No such command!\n\n";
2817                         next CMD;
2818                     }
2819
2820                     # Found it. Put it in the buffer, print it, and process it.
2821                     $cmd = $hist[$i];
2822                     print $OUT $cmd, "\n";
2823                     redo CMD;
2824                 }
2825
2826 =head4 C<$sh> - Invoke a shell
2827
2828 Uses C<DB::system> to invoke a shell.
2829
2830 =cut
2831
2832                 # $sh - start a shell.
2833                 if ($cmd =~ /\A$sh\z/) {
2834
2835                     # Run the user's shell. If none defined, run Bourne.
2836                     # We resume execution when the shell terminates.
2837                     &system( $ENV{SHELL} || "/bin/sh" );
2838                     next CMD;
2839                 }
2840
2841 =head4 C<$sh I<command>> - Force execution of a command in a shell
2842
2843 Like the above, but the command is passed to the shell. Again, we use
2844 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
2845
2846 =cut
2847
2848                 # $sh command - start a shell and run a command in it.
2849                 if (my ($arg) = $cmd =~ m#\A$sh\s*(.*)#ms) {
2850
2851                     # XXX: using csh or tcsh destroys sigint retvals!
2852                     #&system($1);  # use this instead
2853
2854                     # use the user's shell, or Bourne if none defined.
2855                     &system( $ENV{SHELL} || "/bin/sh", "-c", $arg );
2856                     next CMD;
2857                 }
2858
2859 =head4 C<H> - display commands in history
2860
2861 Prints the contents of C<@hist> (if any).
2862
2863 =cut
2864
2865                 if ($cmd =~ /\AH\b\s*\*/) {
2866                     @hist = @truehist = ();
2867                     print $OUT "History cleansed\n";
2868                     next CMD;
2869                 }
2870
2871                 if (my ($num)
2872                     = $cmd =~ /\AH\b\s*(?:-(\d+))?/) {
2873
2874                     # Anything other than negative numbers is ignored by
2875                     # the (incorrect) pattern, so this test does nothing.
2876                     $end = $num ? ( $#hist - $num ) : 0;
2877
2878                     # Set to the minimum if less than zero.
2879                     $hist = 0 if $hist < 0;
2880
2881                     # Start at the end of the array.
2882                     # Stay in while we're still above the ending value.
2883                     # Tick back by one each time around the loop.
2884                     for ( $i = $#hist ; $i > $end ; $i-- ) {
2885
2886                         # Print the command  unless it has no arguments.
2887                         print $OUT "$i: ", $hist[$i], "\n"
2888                           unless $hist[$i] =~ /^.?$/;
2889                     }
2890                     next CMD;
2891                 }
2892
2893 =head4 C<man, doc, perldoc> - look up documentation
2894
2895 Just calls C<runman()> to print the appropriate document.
2896
2897 =cut
2898
2899                 # man, perldoc, doc - show manual pages.
2900                 if (my ($man_page)
2901                     = $cmd =~ /\A(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?\z/) {
2902                     runman($man_page);
2903                     next CMD;
2904                 }
2905
2906 =head4 C<p> - print
2907
2908 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
2909 the bottom of the loop.
2910
2911 =cut
2912
2913                 my $print_cmd = 'print {$DB::OUT} ';
2914                 # p - print (no args): print $_.
2915                 if ($cmd eq 'p') {
2916                     $cmd = $print_cmd . '$_';
2917                 }
2918
2919                 # p - print the given expression.
2920                 $cmd =~ s/\Ap\b/$print_cmd /;
2921
2922 =head4 C<=> - define command alias
2923
2924 Manipulates C<%alias> to add or list command aliases.
2925
2926 =cut
2927
2928                 # = - set up a command alias.
2929                 if ($cmd =~ s/\A=\s*//) {
2930                     my @keys;
2931                     if ( length $cmd == 0 ) {
2932
2933                         # No args, get current aliases.
2934                         @keys = sort keys %alias;
2935                     }
2936                     elsif ( my ( $k, $v ) = ( $cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
2937
2938                         # Creating a new alias. $k is alias name, $v is
2939                         # alias value.
2940
2941                         # can't use $_ or kill //g state
2942                         for my $x ( $k, $v ) {
2943
2944                             # Escape "alarm" characters.
2945                             $x =~ s/\a/\\a/g;
2946                         }
2947
2948                         # Substitute key for value, using alarm chars
2949                         # as separators (which is why we escaped them in
2950                         # the command).
2951                         $alias{$k} = "s\a$k\a$v\a";
2952
2953                         # Turn off standard warn and die behavior.
2954                         local $SIG{__DIE__};
2955                         local $SIG{__WARN__};
2956
2957                         # Is it valid Perl?
2958                         unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
2959
2960                             # Nope. Bad alias. Say so and get out.
2961                             print $OUT "Can't alias $k to $v: $@\n";
2962                             delete $alias{$k};
2963                             next CMD;
2964                         }
2965
2966                         # We'll only list the new one.
2967                         @keys = ($k);
2968                     } ## end elsif (my ($k, $v) = ($cmd...
2969
2970                     # The argument is the alias to list.
2971                     else {
2972                         @keys = ($cmd);
2973                     }
2974
2975                     # List aliases.
2976                     for my $k (@keys) {
2977
2978                         # Messy metaquoting: Trim the substitution code off.
2979                         # We use control-G as the delimiter because it's not
2980                         # likely to appear in the alias.
2981                         if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
2982
2983                             # Print the alias.
2984                             print $OUT "$k\t= $1\n";
2985                         }
2986                         elsif ( defined $alias{$k} ) {
2987
2988                             # Couldn't trim it off; just print the alias code.
2989                             print $OUT "$k\t$alias{$k}\n";
2990                         }
2991                         else {
2992
2993                             # No such, dude.
2994                             print "No alias for $k\n";
2995                         }
2996                     } ## end for my $k (@keys)
2997                     next CMD;
2998                 }
2999
3000 =head4 C<source> - read commands from a file.
3001
3002 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3003 pick it up.
3004
3005 =cut
3006
3007                 # source - read commands from a file (or pipe!) and execute.
3008                 if (my ($sourced_fn) = $cmd =~ /\Asource\s+(.*\S)/) {
3009                     if ( open my $fh, $sourced_fn ) {
3010
3011                         # Opened OK; stick it in the list of file handles.
3012                         push @cmdfhs, $fh;
3013                     }
3014                     else {
3015
3016                         # Couldn't open it.
3017                         &warn("Can't execute '$sourced_fn': $!\n");
3018                     }
3019                     next CMD;
3020                 }
3021
3022                 if (my ($which_cmd, $position)
3023                     = $cmd =~ /^(enable|disable)\s+(\S+)\s*$/) {
3024
3025                     my ($fn, $line_num);
3026                     if ($position =~ m{\A\d+\z})
3027                     {
3028                         $fn = $filename;
3029                         $line_num = $position;
3030                     }
3031                     elsif (my ($new_fn, $new_line_num)
3032                         = $position =~ m{\A(.*):(\d+)\z}) {
3033                         ($fn, $line_num) = ($new_fn, $new_line_num);
3034                     }
3035                     else
3036                     {
3037                         &warn("Wrong spec for enable/disable argument.\n");
3038                     }
3039
3040                     if (defined($fn)) {
3041                         if (_has_breakpoint_data_ref($fn, $line_num)) {
3042                             _set_breakpoint_enabled_status($fn, $line_num,
3043                                 ($which_cmd eq 'enable' ? 1 : '')
3044                             );
3045                         }
3046                         else {
3047                             &warn("No breakpoint set at ${fn}:${line_num}\n");
3048                         }
3049                     }
3050
3051                     next CMD;
3052                 }
3053
3054 =head4 C<save> - send current history to a file
3055
3056 Takes the complete history, (not the shrunken version you see with C<H>),
3057 and saves it to the given filename, so it can be replayed using C<source>.
3058
3059 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3060
3061 =cut
3062
3063                 # save source - write commands to a file for later use
3064                 if (my ($new_fn) = $cmd =~ /\Asave\s*(.*)\z/) {
3065                     my $filename = $new_fn || '.perl5dbrc';    # default?
3066                     if ( open my $fh, '>', $filename ) {
3067
3068                        # chomp to remove extraneous newlines from source'd files
3069                         chomp( my @truelist =
3070                               map { m/^\s*(save|source)/ ? "#$_" : $_ }
3071                               @truehist );
3072                         print $fh join( "\n", @truelist );
3073                         print "commands saved in $file\n";
3074                     }
3075                     else {
3076                         &warn("Can't save debugger commands in '$new_fn': $!\n");
3077                     }
3078                     next CMD;
3079                 }
3080
3081 =head4 C<R> - restart
3082
3083 Restart the debugger session.
3084
3085 =head4 C<rerun> - rerun the current session
3086
3087 Return to any given position in the B<true>-history list
3088
3089 =cut
3090
3091                 # R - restart execution.
3092                 # rerun - controlled restart execution.
3093                 if (my ($cmd_cmd, $cmd_params) =
3094                     $cmd =~ /\A((?:R)|(?:rerun\s*(.*)))\z/) {
3095                     my @args = ($cmd_cmd eq 'R' ? restart() : rerun($cmd_params));
3096
3097                     # Close all non-system fds for a clean restart.  A more
3098                     # correct method would be to close all fds that were not
3099                     # open when the process started, but this seems to be
3100                     # hard.  See "debugger 'R'estart and open database
3101                     # connections" on p5p.
3102
3103                     my $max_fd = 1024; # default if POSIX can't be loaded
3104                     if (eval { require POSIX }) {
3105                         eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
3106                     }
3107
3108                     if (defined $max_fd) {
3109                         foreach ($^F+1 .. $max_fd-1) {
3110                             next unless open FD_TO_CLOSE, "<&=$_";
3111                             close(FD_TO_CLOSE);
3112                         }
3113                     }
3114
3115                     # And run Perl again.  We use exec() to keep the
3116                     # PID stable (and that way $ini_pids is still valid).
3117                     exec(@args) || print $OUT "exec failed: $!\n";
3118
3119                     last CMD;
3120                 }
3121
3122 =head4 C<|, ||> - pipe output through the pager.
3123
3124 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3125 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3126 pipe to the pager (restoring the output filehandles if this fails). If this
3127 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3128 set C<$signal>, sending us back into the debugger.
3129
3130 We then trim off the pipe symbols and C<redo> the command loop at the
3131 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3132 reading another.
3133
3134 =cut
3135
3136                 # || - run command in the pager, with output to DB::OUT.
3137                 if ($cmd =~ m#\A\|\|?\s*[^|]#) {
3138                     if ( $pager =~ /^\|/ ) {
3139
3140                         # Default pager is into a pipe. Redirect I/O.
3141                         open( SAVEOUT, ">&STDOUT" )
3142                           || &warn("Can't save STDOUT");
3143                         open( STDOUT, ">&OUT" )
3144                           || &warn("Can't redirect STDOUT");
3145                     } ## end if ($pager =~ /^\|/)
3146                     else {
3147
3148                         # Not into a pipe. STDOUT is safe.
3149                         open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
3150                     }
3151
3152                     # Fix up environment to record we have less if so.
3153                     fix_less();
3154
3155                     unless ( $piped = open( OUT, $pager ) ) {
3156
3157                         # Couldn't open pipe to pager.
3158                         &warn("Can't pipe output to '$pager'");
3159                         if ( $pager =~ /^\|/ ) {
3160
3161                             # Redirect I/O back again.
3162                             open( OUT, ">&STDOUT" )    # XXX: lost message
3163                               || &warn("Can't restore DB::OUT");
3164                             open( STDOUT, ">&SAVEOUT" )
3165                               || &warn("Can't restore STDOUT");
3166                             close(SAVEOUT);
3167                         } ## end if ($pager =~ /^\|/)
3168                         else {
3169
3170                             # Redirect I/O. STDOUT already safe.
3171                             open( OUT, ">&STDOUT" )    # XXX: lost message
3172                               || &warn("Can't restore DB::OUT");
3173                         }
3174                         next CMD;
3175                     } ## end unless ($piped = open(OUT,...
3176
3177                     # Set up broken-pipe handler if necessary.
3178                     $SIG{PIPE} = \&DB::catch
3179                       if $pager =~ /^\|/
3180                       && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
3181
3182                     OUT->autoflush(1);
3183                     # Save current filehandle, and put it back.
3184                     $selected = select(OUT);
3185                     # Don't put it back if pager was a pipe.
3186                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
3187
3188                     # Trim off the pipe symbols and run the command now.
3189                     $cmd =~ s#\A\|+\s*##;
3190                     redo PIPE;
3191                 }
3192
3193 =head3 END OF COMMAND PARSING
3194
3195 Anything left in C<$cmd> at this point is a Perl expression that we want to
3196 evaluate. We'll always evaluate in the user's context, and fully qualify
3197 any variables we might want to address in the C<DB> package.
3198
3199 =cut
3200
3201                 # t - turn trace on.
3202                 if ($cmd =~ s#\At\s+(\d+)?#\$DB::trace |= 1;\n#) {
3203                     my $trace_arg = $1;
3204                     $trace_to_depth = $trace_arg ? $stack_depth||0 + $1 : 1E9;
3205                 }
3206
3207                 # s - single-step. Remember the last command was 's'.
3208                 if ($cmd =~ s/\As\s/\$DB::single = 1;\n/) {
3209                     $laststep = 's';
3210                 }
3211
3212                 # n - single-step, but not into subs. Remember last command
3213                 # was 'n'.
3214                 if ($cmd =~ s#\An\s#\$DB::single = 2;\n#) {
3215                     $laststep = 'n';
3216                 }
3217
3218             }    # PIPE:
3219
3220             # Make sure the flag that says "the debugger's running" is
3221             # still on, to make sure we get control again.
3222             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3223
3224             # Run *our* eval that executes in the caller's context.
3225             DB::eval();
3226
3227             # Turn off the one-time-dump stuff now.
3228             if ($onetimeDump) {
3229                 $onetimeDump      = undef;
3230                 $onetimedumpDepth = undef;
3231             }
3232             elsif ( $term_pid == $$ ) {
3233                 eval { # May run under miniperl, when not available...
3234                     STDOUT->flush();
3235                     STDERR->flush();
3236                 };
3237
3238                 # XXX If this is the master pid, print a newline.
3239                 print {$OUT} "\n";
3240             }
3241         } ## end while (($term || &setterm...
3242
3243 =head3 POST-COMMAND PROCESSING
3244
3245 After each command, we check to see if the command output was piped anywhere.
3246 If so, we go through the necessary code to unhook the pipe and go back to
3247 our standard filehandles for input and output.
3248
3249 =cut
3250
3251         continue {    # CMD:
3252
3253             # At the end of every command:
3254             if ($piped) {
3255
3256                 # Unhook the pipe mechanism now.
3257                 if ( $pager =~ /^\|/ ) {
3258
3259                     # No error from the child.
3260                     $? = 0;
3261
3262                     # we cannot warn here: the handle is missing --tchrist
3263                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3264
3265                     # most of the $? crud was coping with broken cshisms
3266                     # $? is explicitly set to 0, so this never runs.
3267                     if ($?) {
3268                         print SAVEOUT "Pager '$pager' failed: ";
3269                         if ( $? == -1 ) {
3270                             print SAVEOUT "shell returned -1\n";
3271                         }
3272                         elsif ( $? >> 8 ) {
3273                             print SAVEOUT ( $? & 127 )
3274                               ? " (SIG#" . ( $? & 127 ) . ")"
3275                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3276                         }
3277                         else {
3278                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3279                         }
3280                     } ## end if ($?)
3281
3282                     # Reopen filehandle for our output (if we can) and
3283                     # restore STDOUT (if we can).
3284                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3285                     open( STDOUT, ">&SAVEOUT" )
3286                       || &warn("Can't restore STDOUT");
3287
3288                     # Turn off pipe exception handler if necessary.
3289                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3290
3291                     # Will stop ignoring SIGPIPE if done like nohup(1)
3292                     # does SIGINT but Perl doesn't give us a choice.
3293                 } ## end if ($pager =~ /^\|/)
3294                 else {
3295
3296                     # Non-piped "pager". Just restore STDOUT.
3297                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3298                 }
3299
3300                 # Close filehandle pager was using, restore the normal one
3301                 # if necessary,
3302                 close(SAVEOUT);
3303                 select($selected), $selected = "" unless $selected eq "";
3304
3305                 # No pipes now.
3306                 $piped = "";
3307             } ## end if ($piped)
3308         }    # CMD:
3309
3310 =head3 COMMAND LOOP TERMINATION
3311
3312 When commands have finished executing, we come here. If the user closed the
3313 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3314 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3315 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3316 The interpreter will then execute the next line and then return control to us
3317 again.
3318
3319 =cut
3320
3321         # No more commands? Quit.
3322         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3323
3324         # Evaluate post-prompt commands.
3325         foreach $evalarg (@$post) {
3326             DB::eval();
3327         }
3328     }    # if ($single || $signal)
3329
3330     # Put the user's globals back where you found them.
3331     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3332     ();
3333 } ## end sub DB
3334
3335 package DB::Obj;
3336
3337 sub new {
3338     my $class = shift;
3339
3340     my $self = bless {}, $class;
3341
3342     $self->_init(@_);
3343
3344     return $self;
3345 }
3346
3347 sub _init {
3348     my ($self, $args) = @_;
3349
3350     %{$self} = (%$self, %$args);
3351
3352     return;
3353 }
3354
3355 {
3356     no strict 'refs';
3357     foreach my $slot_name (qw(
3358         after explicit_stop infix pat position prefix i_cmd
3359         )) {
3360         my $slot = $slot_name;
3361         *{$slot} = sub {
3362             my $self = shift;
3363
3364             if (@_) {
3365                 ${ $self->{$slot} } = shift;
3366             }
3367
3368             return ${ $self->{$slot} };
3369         };
3370
3371         *{"append_to_$slot"} = sub {
3372             my $self = shift;
3373             my $s = shift;
3374
3375             return $self->$slot($self->$slot . $s);
3376         };
3377     }
3378 }
3379
3380 sub _DB_on_init__initialize_globals
3381 {
3382     my $self = shift;
3383
3384     # Check for whether we should be running continuously or not.
3385     # _After_ the perl program is compiled, $single is set to 1:
3386     if ( $single and not $second_time++ ) {
3387
3388         # Options say run non-stop. Run until we get an interrupt.
3389         if ($runnonstop) {    # Disable until signal
3390                 # If there's any call stack in place, turn off single
3391                 # stepping into subs throughout the stack.
3392             for my $i (0 .. $stack_depth) {
3393                 $stack[ $i ] &= ~1;
3394             }
3395
3396             # And we are now no longer in single-step mode.
3397             $single = 0;
3398
3399             # If we simply returned at this point, we wouldn't get
3400             # the trace info. Fall on through.
3401             # return;
3402         } ## end if ($runnonstop)
3403
3404         elsif ($ImmediateStop) {
3405
3406             # We are supposed to stop here; XXX probably a break.
3407             $ImmediateStop = 0;    # We've processed it; turn it off
3408             $signal        = 1;    # Simulate an interrupt to force
3409                                    # us into the command loop
3410         }
3411     } ## end if ($single and not $second_time...
3412
3413     # If we're in single-step mode, or an interrupt (real or fake)
3414     # has occurred, turn off non-stop mode.
3415     $runnonstop = 0 if $single or $signal;
3416
3417     return;
3418 }
3419
3420 sub _DB__handle_watch_expressions
3421 {
3422     my $self = shift;
3423
3424     if ( $trace & 2 ) {
3425         for my $n (0 .. $#to_watch) {
3426             $evalarg = $to_watch[$n];
3427             local $onetimeDump;    # Tell DB::eval() to not output results
3428
3429             # Fix context DB::eval() wants to return an array, but
3430             # we need a scalar here.
3431             my ($val) = join( "', '", DB::eval() );
3432             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
3433
3434             # Did it change?
3435             if ( $val ne $old_watch[$n] ) {
3436
3437                 # Yep! Show the difference, and fake an interrupt.
3438                 $signal = 1;
3439                 print {$OUT} <<EOP;
3440 Watchpoint $n:\t$to_watch[$n] changed:
3441     old value:\t$old_watch[$n]
3442     new value:\t$val
3443 EOP
3444                 $old_watch[$n] = $val;
3445             } ## end if ($val ne $old_watch...
3446         } ## end for my $n (0 ..
3447     } ## end if ($trace & 2)
3448
3449     return;
3450 }
3451
3452 sub _my_print_lineinfo
3453 {
3454     my ($self, $i, $incr_pos) = @_;
3455
3456     if ($frame) {
3457         # Print it indented if tracing is on.
3458         DB::print_lineinfo( ' ' x $stack_depth,
3459             "$i:\t$DB::dbline[$i]" . $self->after );
3460     }
3461     else {
3462         DB::depth_print_lineinfo($self->explicit_stop, $incr_pos);
3463     }
3464 }
3465
3466 sub _curr_line {
3467     return $DB::dbline[$line];
3468 }
3469
3470 sub _DB__grab_control
3471 {
3472     my $self = shift;
3473
3474     # Yes, grab control.
3475     if ($slave_editor) {
3476
3477         # Tell the editor to update its position.
3478         $self->position("\032\032${DB::filename}:$line:0\n");
3479         DB::print_lineinfo($self->position());
3480     }
3481
3482 =pod
3483
3484 Special check: if we're in package C<DB::fake>, we've gone through the
3485 C<END> block at least once. We set up everything so that we can continue
3486 to enter commands and have a valid context to be in.
3487
3488 =cut
3489
3490     elsif ( $DB::package eq 'DB::fake' ) {
3491
3492         # Fallen off the end already.
3493         if (!$DB::term) {
3494             DB::setterm();
3495         }
3496
3497         DB::print_help(<<EOP);
3498 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
3499 use B<o> I<inhibit_exit> to avoid stopping after program termination,
3500 B<h q>, B<h R> or B<h o> to get additional info.
3501 EOP
3502
3503         # Set the DB::eval context appropriately.
3504         $DB::package     = 'main';
3505         $DB::usercontext = DB::_calc_usercontext($DB::package);
3506     } ## end elsif ($package eq 'DB::fake')
3507
3508 =pod
3509
3510 If the program hasn't finished executing, we scan forward to the
3511 next executable line, print that out, build the prompt from the file and line
3512 number information, and print that.
3513
3514 =cut
3515
3516     else {
3517
3518
3519         # Still somewhere in the midst of execution. Set up the
3520         #  debugger prompt.
3521         $DB::sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
3522                              # Perl 5 ones (sorry, we don't print Klingon
3523                              #module names)
3524
3525         $self->prefix($DB::sub =~ /::/ ? "" : ($DB::package . '::'));
3526         $self->append_to_prefix( "$DB::sub(${DB::filename}:" );
3527         $self->after( $self->_curr_line =~ /\n$/ ? '' : "\n" );
3528
3529         # Break up the prompt if it's really long.
3530         if ( length($self->prefix()) > 30 ) {
3531             $self->position($self->prefix . "$line):\n$line:\t" . $self->_curr_line . $self->after);
3532             $self->prefix("");
3533             $self->infix(":\t");
3534         }
3535         else {
3536             $self->infix("):\t");
3537             $self->position(
3538                 $self->prefix . $line. $self->infix
3539                 . $self->_curr_line . $self->after
3540             );
3541         }
3542
3543         # Print current line info, indenting if necessary.
3544         $self->_my_print_lineinfo($line, $self->position);
3545
3546         my $i;
3547         my $line_i = sub { return $DB::dbline[$i]; };
3548
3549         # Scan forward, stopping at either the end or the next
3550         # unbreakable line.
3551         for ( $i = $line + 1 ; $i <= $DB::max && $line_i->() == 0 ; ++$i )
3552         {    #{ vi
3553
3554             # Drop out on null statements, block closers, and comments.
3555             last if $line_i->() =~ /^\s*[\;\}\#\n]/;
3556
3557             # Drop out if the user interrupted us.
3558             last if $signal;
3559
3560             # Append a newline if the line doesn't have one. Can happen
3561             # in eval'ed text, for instance.
3562             $self->after( $line_i->() =~ /\n$/ ? '' : "\n" );
3563
3564             # Next executable line.
3565             my $incr_pos = $self->prefix . $i . $self->infix . $line_i->()
3566                 . $self->after;
3567             $self->append_to_position($incr_pos);
3568             $self->_my_print_lineinfo($i, $incr_pos);
3569         } ## end for ($i = $line + 1 ; $i...
3570     } ## end else [ if ($slave_editor)
3571
3572     return;
3573 }
3574
3575 sub _handle_t_command {
3576     if (my ($levels) = $DB::cmd =~ /\At(?:\s+(\d+))?\z/) {
3577         $trace ^= 1;
3578         local $\ = '';
3579         $DB::trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
3580         print {$OUT} "Trace = "
3581         . ( ( $trace & 1 )
3582             ? ( $levels ? "on (to level $DB::trace_to_depth)" : "on" )
3583             : "off" ) . "\n";
3584         next CMD;
3585     }
3586
3587     return;
3588 }
3589
3590
3591 sub _handle_S_command {
3592     if (my ($print_all_subs, $should_reverse, $Spatt)
3593         = $DB::cmd =~ /\AS(\s+(!)?(.+))?\z/) {
3594         # $Spatt is the pattern (if any) to use.
3595         # Reverse scan?
3596         my $Srev     = defined $should_reverse;
3597         # No args - print all subs.
3598         my $Snocheck = !defined $print_all_subs;
3599
3600         # Need to make these sane here.
3601         local $\ = '';
3602         local $, = '';
3603
3604         # Search through the debugger's magical hash of subs.
3605         # If $nocheck is true, just print the sub name.
3606         # Otherwise, check it against the pattern. We then use
3607         # the XOR trick to reverse the condition as required.
3608         foreach $subname ( sort( keys %sub ) ) {
3609             if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
3610                 print $OUT $subname, "\n";
3611             }
3612         }
3613         next CMD;
3614     }
3615
3616     return;
3617 }
3618
3619 sub _handle_V_command_and_X_command {
3620
3621     $DB::cmd =~ s/^X\b/V $DB::package/;
3622
3623     # Bare V commands get the currently-being-debugged package
3624     # added.
3625     if ($DB::cmd eq "V") {
3626         $DB::cmd = "V $DB::package";
3627     }
3628
3629     # V - show variables in package.
3630     if (my ($new_packname, $new_vars_str) =
3631         $DB::cmd =~ /\AV\b\s*(\S+)\s*(.*)/) {
3632
3633         # Save the currently selected filehandle and
3634         # force output to debugger's filehandle (dumpvar
3635         # just does "print" for output).
3636         my $savout = select($OUT);
3637
3638         # Grab package name and variables to dump.
3639         $packname = $new_packname;
3640         my @vars     = split( ' ', $new_vars_str );
3641
3642         # If main::dumpvar isn't here, get it.
3643         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
3644         if ( defined &main::dumpvar ) {
3645
3646             # We got it. Turn off subroutine entry/exit messages
3647             # for the moment, along with return values.
3648             local $frame = 0;
3649             local $doret = -2;
3650
3651             # must detect sigpipe failures  - not catching
3652             # then will cause the debugger to die.
3653             eval {
3654                 &main::dumpvar(
3655                     $packname,
3656                     defined $option{dumpDepth}
3657                     ? $option{dumpDepth}
3658                     : -1,    # assume -1 unless specified
3659                     @vars
3660                 );
3661             };
3662
3663             # The die doesn't need to include the $@, because
3664             # it will automatically get propagated for us.
3665             if ($@) {
3666                 die unless $@ =~ /dumpvar print failed/;
3667             }
3668         } ## end if (defined &main::dumpvar)
3669         else {
3670
3671             # Couldn't load dumpvar.
3672             print $OUT "dumpvar.pl not available.\n";
3673         }
3674
3675         # Restore the output filehandle, and go round again.
3676         select($savout);
3677         next CMD;
3678     }
3679
3680     return;
3681 }
3682
3683 sub _handle_dash_command {
3684
3685     if ($DB::cmd eq '-') {
3686
3687         # back up by a window; go to 1 if back too far.
3688         $start -= $incr + $window + 1;
3689         $start = 1 if $start <= 0;
3690         $incr  = $window - 1;
3691
3692         # Generate and execute a "l +" command (handled below).
3693         $DB::cmd = 'l ' . ($start) . '+';
3694     }
3695     return;
3696 }
3697
3698 sub _n_or_s_commands_generic {
3699     my ($self, $new_val) = @_;
3700     # n - next
3701     next CMD if DB::_DB__is_finished();
3702
3703     # Single step, but don't enter subs.
3704     $single = $new_val;
3705
3706     # Save for empty command (repeat last).
3707     $laststep = $DB::cmd;
3708     last CMD;
3709 }
3710
3711 sub _n_or_s {
3712     my ($self, $letter, $new_val) = @_;
3713
3714     if ($DB::cmd eq $letter) {
3715         $self->_n_or_s_commands_generic($new_val);
3716     }
3717
3718     return;
3719 }
3720
3721 sub _handle_n_command {
3722     my $self = shift;
3723
3724     return $self->_n_or_s('n', 2);
3725 }
3726
3727 sub _handle_s_command {
3728     my $self = shift;
3729
3730     return $self->_n_or_s('s', 1);
3731 }
3732
3733 sub _handle_r_command {
3734     my $self = shift;
3735     # r - return from the current subroutine.
3736     if ($DB::cmd eq 'r') {
3737
3738         # Can't do anything if the program's over.
3739         next CMD if DB::_DB__is_finished();
3740
3741         # Turn on stack trace.
3742         $stack[$stack_depth] |= 1;
3743
3744         # Print return value unless the stack is empty.
3745         $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
3746         last CMD;
3747     }
3748
3749     return;
3750 }
3751
3752 sub _handle_T_command {
3753     if ($DB::cmd eq 'T') {
3754         DB::print_trace( $OUT, 1 );    # skip DB
3755         next CMD;
3756     }
3757
3758     return;
3759 }
3760
3761 sub _handle_w_command {
3762     if (my ($arg) = $DB::cmd =~ /\Aw\b\s*(.*)/s) {
3763         DB::cmd_w( 'w', $arg );
3764         next CMD;
3765     }
3766
3767     return;
3768 }
3769
3770 sub _handle_W_command {
3771     if (my ($arg) = $DB::cmd =~ /\AW\b\s*(.*)/s) {
3772         DB::cmd_W( 'W', $arg );
3773         next CMD;
3774     }
3775
3776     return;
3777 }
3778
3779 sub _handle_rc_recall_command {
3780     my $self = shift;
3781
3782     # $rc - recall command.
3783     if (my ($minus, $arg) = $DB::cmd =~ m#\A$rc+\s*(-)?(\d+)?\z#) {
3784
3785         # No arguments, take one thing off history.
3786         pop(@hist) if length($DB::cmd) > 1;
3787
3788         # Relative (- found)?
3789         #  Y - index back from most recent (by 1 if bare minus)
3790         #  N - go to that particular command slot or the last
3791         #      thing if nothing following.
3792         my $new_i = $minus ? ( $#hist - ( $arg || 1 ) ) : ( $arg || $#hist );
3793
3794         $self->i_cmd($new_i);
3795
3796         # Pick out the command desired.
3797         $DB::cmd = $hist[$self->i_cmd];
3798
3799         # Print the command to be executed and restart the loop
3800         # with that command in the buffer.
3801         print {$OUT} $DB::cmd, "\n";
3802         redo CMD;
3803     }
3804
3805     return;
3806 }
3807
3808 package DB;
3809
3810 # The following code may be executed now:
3811 # BEGIN {warn 4}
3812
3813 =head2 sub
3814
3815 C<sub> is called whenever a subroutine call happens in the program being
3816 debugged. The variable C<$DB::sub> contains the name of the subroutine
3817 being called.
3818
3819 The core function of this subroutine is to actually call the sub in the proper
3820 context, capturing its output. This of course causes C<DB::DB> to get called
3821 again, repeating until the subroutine ends and returns control to C<DB::sub>
3822 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3823 return value, and returns its captured copy of the return value as its own
3824 return value. The value then feeds back into the program being debugged as if
3825 C<DB::sub> hadn't been there at all.
3826
3827 C<sub> does all the work of printing the subroutine entry and exit messages
3828 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3829 and also prints the return value if needed (for the C<r> command and if
3830 the 16 bit is set in C<$frame>).
3831
3832 It also tracks the subroutine call depth by saving the current setting of
3833 C<$single> in the C<@stack> package global; if this exceeds the value in
3834 C<$deep>, C<sub> automatically turns on printing of the current depth by
3835 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3836 of stop/don't stop on entry to subs set as it currently is set.
3837
3838 =head3 C<caller()> support
3839
3840 If C<caller()> is called from the package C<DB>, it provides some
3841 additional data, in the following order:
3842
3843 =over 4
3844
3845 =item * C<$package>
3846
3847 The package name the sub was in
3848
3849 =item * C<$filename>
3850
3851 The filename it was defined in
3852
3853 =item * C<$line>
3854
3855 The line number it was defined on
3856
3857 =item * C<$subroutine>
3858
3859 The subroutine name; C<(eval)> if an C<eval>().
3860
3861 =item * C<$hasargs>
3862
3863 1 if it has arguments, 0 if not
3864
3865 =item * C<$wantarray>
3866
3867 1 if array context, 0 if scalar context
3868
3869 =item * C<$evaltext>
3870
3871 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3872
3873 =item * C<$is_require>
3874
3875 frame was created by a C<use> or C<require> statement
3876
3877 =item * C<$hints>
3878
3879 pragma information; subject to change between versions
3880
3881 =item * C<$bitmask>
3882
3883 pragma information; subject to change between versions
3884
3885 =item * C<@DB::args>
3886
3887 arguments with which the subroutine was invoked
3888
3889 =back
3890
3891 =cut
3892
3893 use vars qw($deep);
3894
3895 # We need to fully qualify the name ("DB::sub") to make "use strict;"
3896 # happy. -- Shlomi Fish
3897 sub DB::sub {
3898     # Do not use a regex in this subroutine -> results in corrupted memory
3899     # See: [perl #66110]
3900
3901     # lock ourselves under threads
3902     lock($DBGR);
3903
3904     # Whether or not the autoloader was running, a scalar to put the
3905     # sub's return value in (if needed), and an array to put the sub's
3906     # return value in (if needed).
3907     my ( $al, $ret, @ret ) = "";
3908     if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
3909         print "creating new thread\n";
3910     }
3911
3912     # If the last ten characters are '::AUTOLOAD', note we've traced
3913     # into AUTOLOAD for $sub.
3914     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3915         no strict 'refs';
3916         $al = " for $$sub" if defined $$sub;
3917     }
3918
3919     # We stack the stack pointer and then increment it to protect us
3920     # from a situation that might unwind a whole bunch of call frames
3921     # at once. Localizing the stack pointer means that it will automatically
3922     # unwind the same amount when multiple stack frames are unwound.
3923     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3924
3925     # Expand @stack.
3926     $#stack = $stack_depth;
3927
3928     # Save current single-step setting.
3929     $stack[-1] = $single;
3930
3931     # Turn off all flags except single-stepping.
3932     $single &= 1;
3933
3934     # If we've gotten really deeply recursed, turn on the flag that will
3935     # make us stop with the 'deep recursion' message.
3936     $single |= 4 if $stack_depth == $deep;
3937
3938     # If frame messages are on ...
3939     (
3940         $frame & 4    # Extended frame entry message
3941         ? (
3942             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3943
3944             # Why -1? But it works! :-(
3945             # Because print_trace will call add 1 to it and then call
3946             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3947             # in dump_trace.
3948             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3949           )
3950         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3951
3952           # standard frame entry message
3953       )
3954       if $frame;
3955
3956     # Determine the sub's return type, and capture appropriately.
3957     if (wantarray) {
3958
3959         # Called in array context. call sub and capture output.
3960         # DB::DB will recursively get control again if appropriate; we'll come
3961         # back here when the sub is finished.
3962         {
3963             no strict 'refs';
3964             @ret = &$sub;
3965         }
3966
3967         # Pop the single-step value back off the stack.
3968         $single |= $stack[ $stack_depth-- ];
3969
3970         # Check for exit trace messages...
3971         (
3972             $frame & 4    # Extended exit message
3973             ? (
3974                 print_lineinfo( ' ' x $stack_depth, "out " ),
3975                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3976               )
3977             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3978
3979               # Standard exit message
3980           )
3981           if $frame & 2;
3982
3983         # Print the return info if we need to.
3984         if ( $doret eq $stack_depth or $frame & 16 ) {
3985
3986             # Turn off output record separator.
3987             local $\ = '';
3988             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3989
3990             # Indent if we're printing because of $frame tracing.
3991             print $fh ' ' x $stack_depth if $frame & 16;
3992
3993             # Print the return value.
3994             print $fh "list context return from $sub:\n";
3995             dumpit( $fh, \@ret );
3996
3997             # And don't print it again.
3998             $doret = -2;
3999         } ## end if ($doret eq $stack_depth...
4000             # And we have to return the return value now.
4001         @ret;
4002     } ## end if (wantarray)
4003
4004     # Scalar context.
4005     else {
4006         if ( defined wantarray ) {
4007             no strict 'refs';
4008             # Save the value if it's wanted at all.
4009             $ret = &$sub;
4010         }
4011         else {
4012             no strict 'refs';
4013             # Void return, explicitly.
4014             &$sub;
4015             undef $ret;
4016         }
4017
4018         # Pop the single-step value off the stack.
4019         $single |= $stack[ $stack_depth-- ];
4020
4021         # If we're doing exit messages...
4022         (
4023             $frame & 4    # Extended messages
4024             ? (
4025                 print_lineinfo( ' ' x $stack_depth, "out " ),
4026                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
4027               )
4028             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
4029
4030               # Standard messages
4031           )
4032           if $frame & 2;
4033
4034         # If we are supposed to show the return value... same as before.
4035         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
4036             local $\ = '';
4037             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
4038             print $fh ( ' ' x $stack_depth ) if $frame & 16;
4039             print $fh (
4040                 defined wantarray
4041                 ? "scalar context return from $sub: "
4042                 : "void context return from $sub\n"
4043             );
4044             dumpit( $fh, $ret ) if defined wantarray;
4045             $doret = -2;
4046         } ## end if ($doret eq $stack_depth...
4047
4048         # Return the appropriate scalar value.
4049         $ret;
4050     } ## end else [ if (wantarray)
4051 } ## end sub _sub
4052
4053 sub lsub : lvalue {
4054
4055     no strict 'refs';
4056
4057     # lock ourselves under threads
4058     lock($DBGR);
4059
4060     # Whether or not the autoloader was running, a scalar to put the
4061     # sub's return value in (if needed), and an array to put the sub's
4062     # return value in (if needed).
4063     my ( $al, $ret, @ret ) = "";
4064     if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
4065         print "creating new thread\n";
4066     }
4067
4068     # If the last ten characters are C'::AUTOLOAD', note we've traced
4069     # into AUTOLOAD for $sub.
4070     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
4071         $al = " for $$sub";
4072     }
4073
4074     # We stack the stack pointer and then increment it to protect us
4075     # from a situation that might unwind a whole bunch of call frames
4076     # at once. Localizing the stack pointer means that it will automatically
4077     # unwind the same amount when multiple stack frames are unwound.
4078     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
4079
4080     # Expand @stack.
4081     $#stack = $stack_depth;
4082
4083     # Save current single-step setting.
4084     $stack[-1] = $single;
4085
4086     # Turn off all flags except single-stepping.
4087     $single &= 1;
4088
4089     # If we've gotten really deeply recursed, turn on the flag that will
4090     # make us stop with the 'deep recursion' message.
4091     $single |= 4 if $stack_depth == $deep;
4092
4093     # If frame messages are on ...
4094     (
4095         $frame & 4    # Extended frame entry message
4096         ? (
4097             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
4098
4099             # Why -1? But it works! :-(
4100             # Because print_trace will call add 1 to it and then call
4101             # dump_trace; this results in our skipping -1+1 = 0 stack frames
4102             # in dump_trace.
4103             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
4104           )
4105         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
4106
4107           # standard frame entry message
4108       )
4109       if $frame;
4110
4111     # Pop the single-step value back off the stack.
4112     $single |= $stack[ $stack_depth-- ];
4113
4114     # call the original lvalue sub.
4115     &$sub;
4116 }
4117
4118 # Abstracting common code from multiple places elsewhere:
4119 sub depth_print_lineinfo {
4120     my $always_print = shift;
4121
4122     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
4123 }
4124
4125 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
4126
4127 In Perl 5.8.0, there was a major realignment of the commands and what they did,
4128 Most of the changes were to systematize the command structure and to eliminate
4129 commands that threw away user input without checking.
4130
4131 The following sections describe the code added to make it easy to support
4132 multiple command sets with conflicting command names. This section is a start
4133 at unifying all command processing to make it simpler to develop commands.
4134
4135 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
4136 number, and C<$dbline> (the current line) as arguments.
4137
4138 Support functions in this section which have multiple modes of failure C<die>
4139 on error; the rest simply return a false value.
4140
4141 The user-interface functions (all of the C<cmd_*> functions) just output
4142 error messages.
4143
4144 =head2 C<%set>
4145
4146 The C<%set> hash defines the mapping from command letter to subroutine
4147 name suffix.
4148
4149 C<%set> is a two-level hash, indexed by set name and then by command name.
4150 Note that trying to set the CommandSet to C<foobar> simply results in the
4151 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
4152
4153 =cut
4154
4155 ### The API section
4156
4157 my %set = (    #
4158     'pre580' => {
4159         'a' => 'pre580_a',
4160         'A' => 'pre580_null',
4161         'b' => 'pre580_b',
4162         'B' => 'pre580_null',
4163         'd' => 'pre580_null',
4164         'D' => 'pre580_D',
4165         'h' => 'pre580_h',
4166         'M' => 'pre580_null',
4167         'O' => 'o',
4168         'o' => 'pre580_null',
4169         'v' => 'M',
4170         'w' => 'v',
4171         'W' => 'pre580_W',
4172     },
4173     'pre590' => {
4174         '<'  => 'pre590_prepost',
4175         '<<' => 'pre590_prepost',
4176         '>'  => 'pre590_prepost',
4177         '>>' => 'pre590_prepost',
4178         '{'  => 'pre590_prepost',
4179         '{{' => 'pre590_prepost',
4180     },
4181 );
4182
4183 my %breakpoints_data;
4184
4185 sub _has_breakpoint_data_ref {
4186     my ($filename, $line) = @_;
4187
4188     return (
4189         exists( $breakpoints_data{$filename} )
4190             and
4191         exists( $breakpoints_data{$filename}{$line} )
4192     );
4193 }
4194
4195 sub _get_breakpoint_data_ref {
4196     my ($filename, $line) = @_;
4197
4198     return ($breakpoints_data{$filename}{$line} ||= +{});
4199 }
4200
4201 sub _delete_breakpoint_data_ref {
4202     my ($filename, $line) = @_;
4203
4204     delete($breakpoints_data{$filename}{$line});
4205     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
4206         delete($breakpoints_data{$filename});
4207     }
4208
4209     return;
4210 }
4211
4212 sub _set_breakpoint_enabled_status {
4213     my ($filename, $line, $status) = @_;
4214
4215     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
4216         ($status ? 1 : '')
4217         ;
4218
4219     return;
4220 }
4221
4222 sub _enable_breakpoint_temp_enabled_status {
4223     my ($filename, $line) = @_;
4224
4225     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
4226
4227     return;
4228 }
4229
4230 sub _cancel_breakpoint_temp_enabled_status {
4231     my ($filename, $line) = @_;
4232
4233     my $ref = _get_breakpoint_data_ref($filename, $line);
4234
4235     delete ($ref->{'temp_enabled'});
4236
4237     if (! %$ref) {
4238         _delete_breakpoint_data_ref($filename, $line);
4239     }
4240
4241     return;
4242 }
4243
4244 sub _is_breakpoint_enabled {
4245     my ($filename, $line) = @_;
4246
4247     my $data_ref = _get_breakpoint_data_ref($filename, $line);
4248     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
4249 }
4250
4251 =head2 C<cmd_wrapper()> (API)
4252
4253 C<cmd_wrapper()> allows the debugger to switch command sets
4254 depending on the value of the C<CommandSet> option.
4255
4256 It tries to look up the command in the C<%set> package-level I<lexical>
4257 (which means external entities can't fiddle with it) and create the name of
4258 the sub to call based on the value found in the hash (if it's there). I<All>
4259 of the commands to be handled in a set have to be added to C<%set>; if they
4260 aren't found, the 5.8.0 equivalent is called (if there is one).
4261
4262 This code uses symbolic references.
4263
4264 =cut
4265
4266 sub cmd_wrapper {
4267     my $cmd      = shift;
4268     my $line     = shift;
4269     my $dblineno = shift;
4270
4271     # Assemble the command subroutine's name by looking up the
4272     # command set and command name in %set. If we can't find it,
4273     # default to the older version of the command.
4274     my $call = 'cmd_'
4275       . ( $set{$CommandSet}{$cmd}
4276           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
4277
4278     # Call the command subroutine, call it by name.
4279     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
4280 } ## end sub cmd_wrapper
4281
4282 =head3 C<cmd_a> (command)
4283
4284 The C<a> command handles pre-execution actions. These are associated with a
4285 particular line, so they're stored in C<%dbline>. We default to the current
4286 line if none is specified.
4287
4288 =cut
4289
4290 sub cmd_a {
4291     my $cmd    = shift;
4292     my $line   = shift || '';    # [.|line] expr
4293     my $dbline = shift;
4294
4295     # If it's dot (here), or not all digits,  use the current line.
4296     $line =~ s/\A\./$dbline/;
4297
4298     # Should be a line number followed by an expression.
4299     if ( my ($lineno, $expr) = $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
4300
4301         if (! length($lineno)) {
4302             $lineno = $dbline;
4303         }
4304
4305         # If we have an expression ...
4306         if ( length $expr ) {
4307
4308             # ... but the line isn't breakable, complain.
4309             if ( $dbline[$lineno] == 0 ) {
4310                 print $OUT
4311                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
4312             }
4313             else {
4314
4315                 # It's executable. Record that the line has an action.
4316                 $had_breakpoints{$filename} |= 2;
4317
4318                 # Remove any action, temp breakpoint, etc.
4319                 $dbline{$lineno} =~ s/\0[^\0]*//;
4320
4321                 # Add the action to the line.
4322                 $dbline{$lineno} .= "\0" . action($expr);
4323
4324                 _set_breakpoint_enabled_status($filename, $lineno, 1);
4325             }
4326         } ## end if (length $expr)
4327     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4328     else {
4329
4330         # Syntax wrong.
4331         print $OUT
4332           "Adding an action requires an optional lineno and an expression\n"
4333           ;    # hint
4334     }
4335 } ## end sub cmd_a
4336
4337 =head3 C<cmd_A> (command)
4338
4339 Delete actions. Similar to above, except the delete code is in a separate
4340 subroutine, C<delete_action>.
4341
4342 =cut
4343
4344 sub cmd_A {
4345     my $cmd    = shift;
4346     my $line   = shift || '';
4347     my $dbline = shift;
4348
4349     # Dot is this line.
4350     $line =~ s/^\./$dbline/;
4351
4352     # Call delete_action with a null param to delete them all.
4353     # The '1' forces the eval to be true. It'll be false only
4354     # if delete_action blows up for some reason, in which case
4355     # we print $@ and get out.
4356     if ( $line eq '*' ) {
4357         if (! eval { _delete_all_actions(); 1 }) {
4358             print {$OUT} $@;
4359             return;
4360         }
4361     }
4362
4363     # There's a real line  number. Pass it to delete_action.
4364     # Error trapping is as above.
4365     elsif ( $line =~ /^(\S.*)/ ) {
4366         if (! eval { delete_action($1); 1 }) {
4367             print {$OUT} $@;
4368             return;
4369         }
4370     }
4371
4372     # Swing and a miss. Bad syntax.
4373     else {
4374         print $OUT
4375           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4376     }
4377 } ## end sub cmd_A
4378
4379 =head3 C<delete_action> (API)
4380
4381 C<delete_action> accepts either a line number or C<undef>. If a line number
4382 is specified, we check for the line being executable (if it's not, it
4383 couldn't have had an  action). If it is, we just take the action off (this
4384 will get any kind of an action, including breakpoints).
4385
4386 =cut
4387
4388 sub _remove_action_from_dbline {
4389     my $i = shift;
4390
4391     $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4392     delete $dbline{$i} if $dbline{$i} eq '';
4393
4394     return;
4395 }
4396
4397 sub _delete_all_actions {
4398     print {$OUT} "Deleting all actions...\n";
4399
4400     for my $file ( keys %had_breakpoints ) {
4401         local *dbline = $main::{ '_<' . $file };
4402         $max = $#dbline;
4403         my $was;
4404         for my $i (1 .. $max) {
4405             if ( defined $dbline{$i} ) {
4406                 _remove_action_from_dbline($i);
4407             }
4408         }
4409
4410         unless ( $had_breakpoints{$file} &= ~2 ) {
4411             delete $had_breakpoints{$file};
4412         }
4413     }
4414
4415     return;
4416 }
4417
4418 sub delete_action {
4419     my $i = shift;
4420
4421     if ( defined($i) ) {
4422         # Can there be one?
4423         die "Line $i has no action .\n" if $dbline[$i] == 0;
4424
4425         # Nuke whatever's there.
4426         _remove_action_from_dbline($i);
4427     }
4428     else {
4429         _delete_all_actions();
4430     }
4431 }
4432
4433 =head3 C<cmd_b> (command)
4434
4435 Set breakpoints. Since breakpoints can be set in so many places, in so many
4436 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4437 we try to parse the command type, and then shuttle it off to an appropriate
4438 subroutine to actually do the work of setting the breakpoint in the right
4439 place.
4440
4441 =cut
4442
4443 sub cmd_b {
4444     my $cmd    = shift;
4445     my $line   = shift;    # [.|line] [cond]
4446     my $dbline = shift;
4447
4448     my $default_cond = sub {
4449         my $cond = shift;
4450         return length($cond) ? $cond : '1';
4451     };
4452
4453     # Make . the current line number if it's there..
4454     $line =~ s/^\.(\s|\z)/$dbline$1/;
4455
4456     # No line number, no condition. Simple break on current line.
4457     if ( $line =~ /^\s*$/ ) {
4458         cmd_b_line( $dbline, 1 );
4459     }
4460
4461     # Break on load for a file.
4462     elsif ( my ($file) = $line =~ /^load\b\s*(.*)/ ) {
4463         $file =~ s/\s+\z//;
4464         cmd_b_load($file);
4465     }
4466
4467     # b compile|postpone <some sub> [<condition>]
4468     # The interpreter actually traps this one for us; we just put the
4469     # necessary condition in the %postponed hash.
4470     elsif ( my ($action, $subname, $cond)
4471         = $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4472
4473         # De-Perl4-ify the name - ' separators to ::.
4474         $subname =~ s/'/::/g;
4475
4476         # Qualify it into the current package unless it's already qualified.
4477         $subname = "${package}::" . $subname unless $subname =~ /::/;
4478
4479         # Add main if it starts with ::.
4480         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4481
4482         # Save the break type for this sub.
4483         $postponed{$subname} = (($action eq 'postpone')
4484             ? ( "break +0 if " . $default_cond->($cond) )
4485             : "compile");
4486     } ## end elsif ($line =~ ...
4487     # b <filename>:<line> [<condition>]
4488     elsif (my ($filename, $line_num, $cond)
4489         = $line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4490         cmd_b_filename_line(
4491             $filename,
4492             $line_num,
4493             (length($cond) ? $cond : '1'),
4494         );
4495     }
4496     # b <sub name> [<condition>]
4497     elsif ( my ($new_subname, $new_cond) =
4498         $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4499
4500         #
4501         $subname = $new_subname;
4502         cmd_b_sub( $subname, $default_cond->($new_cond) );
4503     }
4504
4505     # b <line> [<condition>].
4506     elsif ( my ($line_n, $cond) = $line =~ /^(\d*)\s*(.*)/ ) {
4507
4508         # Capture the line. If none, it's the current line.
4509         $line = $line_n || $dbline;
4510
4511         # Break on line.
4512         cmd_b_line( $line, $default_cond->($cond) );
4513     }
4514
4515     # Line didn't make sense.
4516     else {
4517         print "confused by line($line)?\n";
4518     }
4519
4520     return;
4521 } ## end sub cmd_b
4522
4523 =head3 C<break_on_load> (API)
4524
4525 We want to break when this file is loaded. Mark this file in the
4526 C<%break_on_load> hash, and note that it has a breakpoint in
4527 C<%had_breakpoints>.
4528
4529 =cut
4530
4531 sub break_on_load {
4532     my $file = shift;
4533     $break_on_load{$file} = 1;
4534     $had_breakpoints{$file} |= 1;
4535 }
4536
4537 =head3 C<report_break_on_load> (API)
4538
4539 Gives us an array of filenames that are set to break on load. Note that
4540 only files with break-on-load are in here, so simply showing the keys
4541 suffices.
4542
4543 =cut
4544
4545 sub report_break_on_load {
4546     sort keys %break_on_load;
4547 }
4548
4549 =head3 C<cmd_b_load> (command)
4550
4551 We take the file passed in and try to find it in C<%INC> (which maps modules
4552 to files they came from). We mark those files for break-on-load via
4553 C<break_on_load> and then report that it was done.
4554
4555 =cut
4556
4557 sub cmd_b_load {
4558     my $file = shift;
4559     my @files;
4560
4561     # This is a block because that way we can use a redo inside it
4562     # even without there being any looping structure at all outside it.
4563     {
4564
4565         # Save short name and full path if found.
4566         push @files, $file;
4567         push @files, $::INC{$file} if $::INC{$file};
4568
4569         # Tack on .pm and do it again unless there was a '.' in the name
4570         # already.
4571         $file .= '.pm', redo unless $file =~ /\./;
4572     }
4573
4574     # Do the real work here.
4575     break_on_load($_) for @files;
4576
4577     # All the files that have break-on-load breakpoints.
4578     @files = report_break_on_load;
4579
4580     # Normalize for the purposes of our printing this.
4581     local $\ = '';
4582     local $" = ' ';
4583     print $OUT "Will stop on load of '@files'.\n";
4584 } ## end sub cmd_b_load
4585
4586 =head3 C<$filename_error> (API package global)
4587
4588 Several of the functions we need to implement in the API need to work both
4589 on the current file and on other files. We don't want to duplicate code, so
4590 C<$filename_error> is used to contain the name of the file that's being
4591 worked on (if it's not the current one).
4592
4593 We can now build functions in pairs: the basic function works on the current
4594 file, and uses C<$filename_error> as part of its error message. Since this is
4595 initialized to C<"">, no filename will appear when we are working on the
4596 current file.
4597
4598 The second function is a wrapper which does the following:
4599
4600 =over 4
4601
4602 =item *
4603
4604 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4605
4606 =item *
4607
4608 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4609
4610 =item *
4611
4612 Calls the first function.
4613
4614 The first function works on the I<current> file (i.e., the one we changed to),
4615 and prints C<$filename_error> in the error message (the name of the other file)
4616 if it needs to. When the functions return, C<*dbline> is restored to point
4617 to the actual current file (the one we're executing in) and
4618 C<$filename_error> is restored to C<"">. This restores everything to
4619 the way it was before the second function was called at all.
4620
4621 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4622 details.
4623
4624 =back
4625
4626 =cut
4627
4628 use vars qw($filename_error);
4629 $filename_error = '';
4630
4631 =head3 breakable_line(from, to) (API)
4632
4633 The subroutine decides whether or not a line in the current file is breakable.
4634 It walks through C<@dbline> within the range of lines specified, looking for
4635 the first line that is breakable.
4636
4637 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4638 first line I<after> C<$to> that's breakable, if there is one.
4639
4640 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4641 first line I<before> C<$to> that's breakable, if there is one.
4642
4643 =cut
4644
4645 sub breakable_line {
4646
4647     my ( $from, $to ) = @_;
4648
4649     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4650     my $i = $from;
4651
4652     # If there are at least 2 arguments, we're trying to search a range.
4653     if ( @_ >= 2 ) {
4654
4655         # $delta is positive for a forward search, negative for a backward one.
4656         my $delta = $from < $to ? +1 : -1;
4657
4658         # Keep us from running off the ends of the file.
4659         my $limit = $delta > 0 ? $#dbline : 1;
4660
4661         # Clever test. If you're a mathematician, it's obvious why this
4662         # test works. If not:
4663         # If $delta is positive (going forward), $limit will be $#dbline.
4664         #    If $to is less than $limit, ($limit - $to) will be positive, times
4665         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4666         #    as the stopping point.
4667         #
4668         #    If $to is greater than $limit, ($limit - $to) is negative,
4669         #    times $delta of 1 (positive), so the result is < 0 and we should
4670         #    use $limit ($#dbline) as the stopping point.
4671         #
4672         # If $delta is negative (going backward), $limit will be 1.
4673         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4674         #    (negative) so the result is > 0, and we use $to as the stopping
4675         #    point.
4676         #
4677         #    If $to is less than zero, ($limit - $to) will be positive,
4678         #    times $delta of -1 (negative), so the result is not > 0, and
4679         #    we use $limit (1) as the stopping point.
4680         #
4681         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4682         #    (negative), still giving zero; the result is not > 0, and
4683         #    we use $limit (1) as the stopping point.
4684         #
4685         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4686         #    (negative), giving a positive (>0) value, so we'll set $limit to
4687         #    $to.
4688
4689         $limit = $to if ( $limit - $to ) * $delta > 0;
4690
4691         # The real search loop.
4692         # $i starts at $from (the point we want to start searching from).
4693         # We move through @dbline in the appropriate direction (determined
4694         # by $delta: either -1 (back) or +1 (ahead).
4695         # We stay in as long as we haven't hit an executable line
4696         # ($dbline[$i] == 0 means not executable) and we haven't reached
4697         # the limit yet (test similar to the above).
4698         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4699
4700     } ## end if (@_ >= 2)
4701
4702     # If $i points to a line that is executable, return that.
4703     return $i unless $dbline[$i] == 0;
4704
4705     # Format the message and print it: no breakable lines in range.
4706     my ( $pl, $upto ) = ( '', '' );
4707     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4708
4709     # If there's a filename in filename_error, we'll see it.
4710     # If not, not.
4711     die "Line$pl $from$upto$filename_error not breakable\n";
4712 } ## end sub breakable_line
4713
4714 =head3 breakable_line_in_filename(file, from, to) (API)
4715
4716 Like C<breakable_line>, but look in another file.
4717
4718 =cut
4719
4720 sub breakable_line_in_filename {
4721
4722     # Capture the file name.
4723     my ($f) = shift;
4724
4725     # Swap the magic line array over there temporarily.
4726     local *dbline = $main::{ '_<' . $f };
4727
4728     # If there's an error, it's in this other file.
4729     local $filename_error = " of '$f'";
4730
4731     # Find the breakable line.
4732     breakable_line(@_);
4733
4734     # *dbline and $filename_error get restored when this block ends.
4735
4736 } ## end sub breakable_line_in_filename
4737
4738 =head3 break_on_line(lineno, [condition]) (API)
4739
4740 Adds a breakpoint with the specified condition (or 1 if no