t/op/sigdispatch.t

   1 #!perl -w
   2
   3 # We assume that TestInit has been used.
   4
   5 BEGIN {
   6       require './test.pl';
   7 }
   8
   9 use strict;
  10 use Config;
  11
  12 plan tests => 29;
  13 $| = 1;
  14
  15 watchdog(15);
  16
  17 $SIG{ALRM} = sub {
  18     die "Alarm!\n";
  19 };
  20
  21 pass('before the first loop');
  22
  23 alarm 2;
  24
  25 eval {
  26     1 while 1;
  27 };
  28
  29 is($@, "Alarm!\n", 'after the first loop');
  30
  31 pass('before the second loop');
  32
  33 alarm 2;
  34
  35 eval {
  36     while (1) {
  37     }
  38 };
  39
  40 is($@, "Alarm!\n", 'after the second loop');
  41
  42 SKIP: {
  43     skip('We can\'t test blocking without sigprocmask', 17)
  44         if is_miniperl() || !$Config{d_sigprocmask};
  45     skip('This doesn\'t work on $^O threaded builds RT#88814', 17)
  46         if $^O =~ /openbsd|cygwin/ && $Config{useithreads};
  47
  48     require POSIX;
  49     my $pending = POSIX::SigSet->new();
  50     is POSIX::sigpending($pending), '0 but true', 'sigpending';
  51     is $pending->ismember(&POSIX::SIGUSR1), 0, 'SIGUSR1 is not pending';
  52     my $new = POSIX::SigSet->new(&POSIX::SIGUSR1);
  53     POSIX::sigprocmask(&POSIX::SIG_BLOCK, $new);
  54
  55     my $gotit = 0;
  56     $SIG{USR1} = sub { $gotit++ };
  57     kill 'SIGUSR1', $$;
  58     is $gotit, 0, 'Haven\'t received third signal yet';
  59
  60     diag "2nd sigpending crashes on cygwin" if $^O eq 'cygwin';
  61     is POSIX::sigpending($pending), '0 but true', 'sigpending';
  62     is $pending->ismember(&POSIX::SIGUSR1), 1, 'SIGUSR1 is pending';
  63
  64     my $old = POSIX::SigSet->new();
  65     POSIX::sigsuspend($old);
  66     is $gotit, 1, 'Received third signal';
  67     is POSIX::sigpending($pending), '0 but true', 'sigpending';
  68     is $pending->ismember(&POSIX::SIGUSR1), 0, 'SIGUSR1 is no longer pending';
  69
  70         {
  71                 kill 'SIGUSR1', $$;
  72                 local $SIG{USR1} = sub { die "FAIL\n" };
  73                 POSIX::sigprocmask(&POSIX::SIG_BLOCK, undef, $old);
  74                 ok $old->ismember(&POSIX::SIGUSR1), 'SIGUSR1 is blocked';
  75                 eval { POSIX::sigsuspend(POSIX::SigSet->new) };
  76                 is $@, "FAIL\n", 'Exception is thrown, so received fourth signal';
  77                 POSIX::sigprocmask(&POSIX::SIG_BLOCK, undef, $old);
  78 TODO:
  79             {
  80                 local $::TODO = "Needs investigation" if $^O eq 'VMS';
  81                 ok $old->ismember(&POSIX::SIGUSR1), 'SIGUSR1 is still blocked';
  82             }
  83         }
  84
  85     POSIX::sigprocmask(&POSIX::SIG_BLOCK, $new);
  86     kill 'SIGUSR1', $$;
  87     is $gotit, 1, 'Haven\'t received fifth signal yet';
  88     POSIX::sigprocmask(&POSIX::SIG_UNBLOCK, $new, $old);
  89     ok $old->ismember(&POSIX::SIGUSR1), 'SIGUSR1 was still blocked';
  90     is $gotit, 2, 'Received fifth signal';
  91
  92     # test unsafe signal handlers in combination with exceptions
  93
  94     SKIP: {
  95         # #89718: on old linux kernels, this test hangs. No-ones thought
  96         # of a reliable way to probe for this, so for now, just skip the
  97         # tests on production releases
  98         skip("some OSes hang here", 3) if (int($]*1000) & 1) == 0;
  99
 100         my $action = POSIX::SigAction->new(sub { $gotit--, die }, POSIX::SigSet->new, 0);
 101         POSIX::sigaction(&POSIX::SIGALRM, $action);
 102         eval {
 103             alarm 1;
 104             my $set = POSIX::SigSet->new;
 105             POSIX::sigprocmask(&POSIX::SIG_BLOCK, undef, $set);
 106             is $set->ismember(&POSIX::SIGALRM), 0, "SIGALRM is not blocked on attempt $_";
 107             POSIX::sigsuspend($set);
 108         } for 1..2;
 109         is $gotit, 0, 'Received both signals';
 110     }
 111 }
 112
 113 SKIP: {
 114     skip("alarm cannot interrupt blocking system calls on $^O", 2)
 115         if $^O =~ /MSWin32|cygwin|VMS/;
 116     # RT #88774
 117     # make sure the signal handler's called in an eval block *before*
 118     # the eval is popped
 119
 120     $SIG{'ALRM'} = sub { die "HANDLER CALLED\n" };
 121
 122     eval {
 123         alarm(2);
 124         select(undef,undef,undef,10);
 125     };
 126     alarm(0);
 127     is($@, "HANDLER CALLED\n", 'block eval');
 128
 129     eval q{
 130         alarm(2);
 131         select(undef,undef,undef,10);
 132     };
 133     alarm(0);
 134     is($@, "HANDLER CALLED\n", 'string eval');
 135 }
 136
 137 eval { $SIG{"__WARN__\0"} = sub { 1 } };
 138 like $@, qr/No such hook: __WARN__\\0 at/, q!Fetching %SIG hooks with an extra trailing nul is nul-clean!;
 139
 140 eval { $SIG{"__DIE__\0whoops"} = sub { 1 } };
 141 like $@, qr/No such hook: __DIE__\\0whoops at/;
 142
 143 {
 144     use warnings;
 145     my $w;
 146     local $SIG{__WARN__} = sub { $w = shift };
 147
 148     $SIG{"KILL\0"} = sub { 1 };
 149     like $w, qr/No such signal: SIGKILL\\0 at/, 'Arbitrary signal lookup through %SIG is clean';
 150 }
 151
 152 # [perl #45173]
 153 {
 154     my $int_called;
 155     local $SIG{INT} = sub { $int_called = 1; };
 156     $@ = "died";
 157     is($@, "died");
 158     kill 'INT', $$;
 159     # this is needed to ensure signal delivery on MSWin32
 160     sleep(1);
 161     is($int_called, 1);
 162     is($@, "died");
 163 }