This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Link to more useful section of perlop from readpipe
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2 X<function>
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides scalar context to its
16 argument, while a list operator may provide either scalar or list
17 contexts for its arguments.  If it does both, scalar arguments
18 come first and list argument follow, and there can only ever
19 be one such list argument.  For instance,
20 L<C<splice>|/splice ARRAY,OFFSET,LENGTH,LIST> has three scalar arguments
21 followed by a list, whereas L<C<gethostbyname>|/gethostbyname NAME> has
22 four scalar arguments.
23
24 In the syntax descriptions that follow, list operators that expect a
25 list (and provide list context for elements of the list) are shown
26 with LIST as an argument.  Such a list may consist of any combination
27 of scalar arguments or list values; the list values will be included
28 in the list as if each individual element were interpolated at that
29 point in the list, forming a longer single-dimensional list value.
30 Commas should separate literal elements of the LIST.
31
32 Any function in the list below may be used either with or without
33 parentheses around its arguments.  (The syntax descriptions omit the
34 parentheses.)  If you use parentheses, the simple but occasionally
35 surprising rule is this: It I<looks> like a function, therefore it I<is> a
36 function, and precedence doesn't matter.  Otherwise it's a list
37 operator or unary operator, and precedence does matter.  Whitespace
38 between the function and left parenthesis doesn't count, so sometimes
39 you need to be careful:
40
41     print 1+2+4;      # Prints 7.
42     print(1+2) + 4;   # Prints 3.
43     print (1+2)+4;    # Also prints 3!
44     print +(1+2)+4;   # Prints 7.
45     print ((1+2)+4);  # Prints 7.
46
47 If you run Perl with the L<C<use warnings>|warnings> pragma, it can warn
48 you about this.  For example, the third line above produces:
49
50     print (...) interpreted as function at - line 1.
51     Useless use of integer addition in void context at - line 1.
52
53 A few functions take no arguments at all, and therefore work as neither
54 unary nor list operators.  These include such functions as
55 L<C<time>|/time> and L<C<endpwent>|/endpwent>.  For example,
56 C<time+86_400> always means C<time() + 86_400>.
57
58 For functions that can be used in either a scalar or list context,
59 nonabortive failure is generally indicated in scalar context by
60 returning the undefined value, and in list context by returning the
61 empty list.
62
63 Remember the following important rule: There is B<no rule> that relates
64 the behavior of an expression in list context to its behavior in scalar
65 context, or vice versa.  It might do two totally different things.
66 Each operator and function decides which sort of value would be most
67 appropriate to return in scalar context.  Some operators return the
68 length of the list that would have been returned in list context.  Some
69 operators return the first value in the list.  Some operators return the
70 last value in the list.  Some operators return a count of successful
71 operations.  In general, they do what you want, unless you want
72 consistency.
73 X<context>
74
75 A named array in scalar context is quite different from what would at
76 first glance appear to be a list in scalar context.  You can't get a list
77 like C<(1,2,3)> into being in scalar context, because the compiler knows
78 the context at compile time.  It would generate the scalar comma operator
79 there, not the list concatenation version of the comma.  That means it
80 was never a list to start with.
81
82 In general, functions in Perl that serve as wrappers for system calls
83 ("syscalls") of the same name (like L<chown(2)>, L<fork(2)>,
84 L<closedir(2)>, etc.) return true when they succeed and
85 L<C<undef>|/undef EXPR> otherwise, as is usually mentioned in the
86 descriptions below.  This is different from the C interfaces, which
87 return C<-1> on failure.  Exceptions to this rule include
88 L<C<wait>|/wait>, L<C<waitpid>|/waitpid PID,FLAGS>, and
89 L<C<syscall>|/syscall NUMBER, LIST>.  System calls also set the special
90 L<C<$!>|perlvar/$!> variable on failure.  Other functions do not, except
91 accidentally.
92
93 Extension modules can also hook into the Perl parser to define new
94 kinds of keyword-headed expression.  These may look like functions, but
95 may also look completely different.  The syntax following the keyword
96 is defined entirely by the extension.  If you are an implementor, see
97 L<perlapi/PL_keyword_plugin> for the mechanism.  If you are using such
98 a module, see the module's documentation for details of the syntax that
99 it defines.
100
101 =head2 Perl Functions by Category
102 X<function>
103
104 Here are Perl's functions (including things that look like
105 functions, like some keywords and named operators)
106 arranged by category.  Some functions appear in more
107 than one place.  Any warnings, including those produced by
108 keywords, are described in L<perldiag> and L<warnings>.
109
110 =over 4
111
112 =item Functions for SCALARs or strings
113 X<scalar> X<string> X<character>
114
115 =for Pod::Functions =String
116
117 L<C<chomp>|/chomp VARIABLE>, L<C<chop>|/chop VARIABLE>,
118 L<C<chr>|/chr NUMBER>, L<C<crypt>|/crypt PLAINTEXT,SALT>,
119 L<C<fc>|/fc EXPR>, L<C<hex>|/hex EXPR>,
120 L<C<index>|/index STR,SUBSTR,POSITION>, L<C<lc>|/lc EXPR>,
121 L<C<lcfirst>|/lcfirst EXPR>, L<C<length>|/length EXPR>,
122 L<C<oct>|/oct EXPR>, L<C<ord>|/ord EXPR>,
123 L<C<pack>|/pack TEMPLATE,LIST>,
124 L<C<qE<sol>E<sol>>|/qE<sol>STRINGE<sol>>,
125 L<C<qqE<sol>E<sol>>|/qqE<sol>STRINGE<sol>>, L<C<reverse>|/reverse LIST>,
126 L<C<rindex>|/rindex STR,SUBSTR,POSITION>,
127 L<C<sprintf>|/sprintf FORMAT, LIST>,
128 L<C<substr>|/substr EXPR,OFFSET,LENGTH,REPLACEMENT>,
129 L<C<trE<sol>E<sol>E<sol>>|/trE<sol>E<sol>E<sol>>, L<C<uc>|/uc EXPR>,
130 L<C<ucfirst>|/ucfirst EXPR>,
131 L<C<yE<sol>E<sol>E<sol>>|/yE<sol>E<sol>E<sol>>
132
133 L<C<fc>|/fc EXPR> is available only if the
134 L<C<"fc"> feature|feature/The 'fc' feature> is enabled or if it is
135 prefixed with C<CORE::>.  The
136 L<C<"fc"> feature|feature/The 'fc' feature> is enabled automatically
137 with a C<use v5.16> (or higher) declaration in the current scope.
138
139 =item Regular expressions and pattern matching
140 X<regular expression> X<regex> X<regexp>
141
142 =for Pod::Functions =Regexp
143
144 L<C<mE<sol>E<sol>>|/mE<sol>E<sol>>, L<C<pos>|/pos SCALAR>,
145 L<C<qrE<sol>E<sol>>|/qrE<sol>STRINGE<sol>>,
146 L<C<quotemeta>|/quotemeta EXPR>,
147 L<C<sE<sol>E<sol>E<sol>>|/sE<sol>E<sol>E<sol>>,
148 L<C<split>|/split E<sol>PATTERNE<sol>,EXPR,LIMIT>,
149 L<C<study>|/study SCALAR>
150
151 =item Numeric functions
152 X<numeric> X<number> X<trigonometric> X<trigonometry>
153
154 =for Pod::Functions =Math
155
156 L<C<abs>|/abs VALUE>, L<C<atan2>|/atan2 Y,X>, L<C<cos>|/cos EXPR>,
157 L<C<exp>|/exp EXPR>, L<C<hex>|/hex EXPR>, L<C<int>|/int EXPR>,
158 L<C<log>|/log EXPR>, L<C<oct>|/oct EXPR>, L<C<rand>|/rand EXPR>,
159 L<C<sin>|/sin EXPR>, L<C<sqrt>|/sqrt EXPR>, L<C<srand>|/srand EXPR>
160
161 =item Functions for real @ARRAYs
162 X<array>
163
164 =for Pod::Functions =ARRAY
165
166 L<C<each>|/each HASH>, L<C<keys>|/keys HASH>, L<C<pop>|/pop ARRAY>,
167 L<C<push>|/push ARRAY,LIST>, L<C<shift>|/shift ARRAY>,
168 L<C<splice>|/splice ARRAY,OFFSET,LENGTH,LIST>,
169 L<C<unshift>|/unshift ARRAY,LIST>, L<C<values>|/values HASH>
170
171 =item Functions for list data
172 X<list>
173
174 =for Pod::Functions =LIST
175
176 L<C<grep>|/grep BLOCK LIST>, L<C<join>|/join EXPR,LIST>,
177 L<C<map>|/map BLOCK LIST>, L<C<qwE<sol>E<sol>>|/qwE<sol>STRINGE<sol>>,
178 L<C<reverse>|/reverse LIST>, L<C<sort>|/sort SUBNAME LIST>,
179 L<C<unpack>|/unpack TEMPLATE,EXPR>
180
181 =item Functions for real %HASHes
182 X<hash>
183
184 =for Pod::Functions =HASH
185
186 L<C<delete>|/delete EXPR>, L<C<each>|/each HASH>,
187 L<C<exists>|/exists EXPR>, L<C<keys>|/keys HASH>,
188 L<C<values>|/values HASH>
189
190 =item Input and output functions
191 X<I/O> X<input> X<output> X<dbm>
192
193 =for Pod::Functions =I/O
194
195 L<C<binmode>|/binmode FILEHANDLE, LAYER>, L<C<close>|/close FILEHANDLE>,
196 L<C<closedir>|/closedir DIRHANDLE>, L<C<dbmclose>|/dbmclose HASH>,
197 L<C<dbmopen>|/dbmopen HASH,DBNAME,MASK>, L<C<die>|/die LIST>,
198 L<C<eof>|/eof FILEHANDLE>, L<C<fileno>|/fileno FILEHANDLE>,
199 L<C<flock>|/flock FILEHANDLE,OPERATION>, L<C<format>|/format>,
200 L<C<getc>|/getc FILEHANDLE>, L<C<print>|/print FILEHANDLE LIST>,
201 L<C<printf>|/printf FILEHANDLE FORMAT, LIST>,
202 L<C<read>|/read FILEHANDLE,SCALAR,LENGTH,OFFSET>,
203 L<C<readdir>|/readdir DIRHANDLE>, L<C<readline>|/readline EXPR>,
204 L<C<rewinddir>|/rewinddir DIRHANDLE>, L<C<say>|/say FILEHANDLE LIST>,
205 L<C<seek>|/seek FILEHANDLE,POSITION,WHENCE>,
206 L<C<seekdir>|/seekdir DIRHANDLE,POS>,
207 L<C<select>|/select RBITS,WBITS,EBITS,TIMEOUT>,
208 L<C<syscall>|/syscall NUMBER, LIST>,
209 L<C<sysread>|/sysread FILEHANDLE,SCALAR,LENGTH,OFFSET>,
210 L<C<sysseek>|/sysseek FILEHANDLE,POSITION,WHENCE>,
211 L<C<syswrite>|/syswrite FILEHANDLE,SCALAR,LENGTH,OFFSET>,
212 L<C<tell>|/tell FILEHANDLE>, L<C<telldir>|/telldir DIRHANDLE>,
213 L<C<truncate>|/truncate FILEHANDLE,LENGTH>, L<C<warn>|/warn LIST>,
214 L<C<write>|/write FILEHANDLE>
215
216 L<C<say>|/say FILEHANDLE LIST> is available only if the
217 L<C<"say"> feature|feature/The 'say' feature> is enabled or if it is
218 prefixed with C<CORE::>.  The
219 L<C<"say"> feature|feature/The 'say' feature> is enabled automatically
220 with a C<use v5.10> (or higher) declaration in the current scope.
221
222 =item Functions for fixed-length data or records
223
224 =for Pod::Functions =Binary
225
226 L<C<pack>|/pack TEMPLATE,LIST>,
227 L<C<read>|/read FILEHANDLE,SCALAR,LENGTH,OFFSET>,
228 L<C<syscall>|/syscall NUMBER, LIST>,
229 L<C<sysread>|/sysread FILEHANDLE,SCALAR,LENGTH,OFFSET>,
230 L<C<sysseek>|/sysseek FILEHANDLE,POSITION,WHENCE>,
231 L<C<syswrite>|/syswrite FILEHANDLE,SCALAR,LENGTH,OFFSET>,
232 L<C<unpack>|/unpack TEMPLATE,EXPR>, L<C<vec>|/vec EXPR,OFFSET,BITS>
233
234 =item Functions for filehandles, files, or directories
235 X<file> X<filehandle> X<directory> X<pipe> X<link> X<symlink>
236
237 =for Pod::Functions =File
238
239 L<C<-I<X>>|/-X FILEHANDLE>, L<C<chdir>|/chdir EXPR>,
240 L<C<chmod>|/chmod LIST>, L<C<chown>|/chown LIST>,
241 L<C<chroot>|/chroot FILENAME>,
242 L<C<fcntl>|/fcntl FILEHANDLE,FUNCTION,SCALAR>, L<C<glob>|/glob EXPR>,
243 L<C<ioctl>|/ioctl FILEHANDLE,FUNCTION,SCALAR>,
244 L<C<link>|/link OLDFILE,NEWFILE>, L<C<lstat>|/lstat FILEHANDLE>,
245 L<C<mkdir>|/mkdir FILENAME,MODE>, L<C<open>|/open FILEHANDLE,EXPR>,
246 L<C<opendir>|/opendir DIRHANDLE,EXPR>, L<C<readlink>|/readlink EXPR>,
247 L<C<rename>|/rename OLDNAME,NEWNAME>, L<C<rmdir>|/rmdir FILENAME>,
248 L<C<select>|/select FILEHANDLE>, L<C<stat>|/stat FILEHANDLE>,
249 L<C<symlink>|/symlink OLDFILE,NEWFILE>,
250 L<C<sysopen>|/sysopen FILEHANDLE,FILENAME,MODE>,
251 L<C<umask>|/umask EXPR>, L<C<unlink>|/unlink LIST>,
252 L<C<utime>|/utime LIST>
253
254 =item Keywords related to the control flow of your Perl program
255 X<control flow>
256
257 =for Pod::Functions =Flow
258
259 L<C<break>|/break>, L<C<caller>|/caller EXPR>,
260 L<C<continue>|/continue BLOCK>, L<C<die>|/die LIST>, L<C<do>|/do BLOCK>,
261 L<C<dump>|/dump LABEL>, L<C<eval>|/eval EXPR>,
262 L<C<evalbytes>|/evalbytes EXPR>, L<C<exit>|/exit EXPR>,
263 L<C<__FILE__>|/__FILE__>, L<C<goto>|/goto LABEL>,
264 L<C<last>|/last LABEL>, L<C<__LINE__>|/__LINE__>,
265 L<C<next>|/next LABEL>, L<C<__PACKAGE__>|/__PACKAGE__>,
266 L<C<redo>|/redo LABEL>, L<C<return>|/return EXPR>,
267 L<C<sub>|/sub NAME BLOCK>, L<C<__SUB__>|/__SUB__>,
268 L<C<wantarray>|/wantarray>
269
270 L<C<break>|/break> is available only if you enable the experimental
271 L<C<"switch"> feature|feature/The 'switch' feature> or use the C<CORE::>
272 prefix.  The L<C<"switch"> feature|feature/The 'switch' feature> also
273 enables the C<default>, C<given> and C<when> statements, which are
274 documented in L<perlsyn/"Switch Statements">.
275 The L<C<"switch"> feature|feature/The 'switch' feature> is enabled
276 automatically with a C<use v5.10> (or higher) declaration in the current
277 scope.  In Perl v5.14 and earlier, L<C<continue>|/continue BLOCK>
278 required the L<C<"switch"> feature|feature/The 'switch' feature>, like
279 the other keywords.
280
281 L<C<evalbytes>|/evalbytes EXPR> is only available with the
282 L<C<"evalbytes"> feature|feature/The 'unicode_eval' and 'evalbytes' features>
283 (see L<feature>) or if prefixed with C<CORE::>.  L<C<__SUB__>|/__SUB__>
284 is only available with the
285 L<C<"current_sub"> feature|feature/The 'current_sub' feature> or if
286 prefixed with C<CORE::>.  Both the
287 L<C<"evalbytes">|feature/The 'unicode_eval' and 'evalbytes' features>
288 and L<C<"current_sub">|feature/The 'current_sub' feature> features are
289 enabled automatically with a C<use v5.16> (or higher) declaration in the
290 current scope.
291
292 =item Keywords related to scoping
293
294 =for Pod::Functions =Namespace
295
296 L<C<caller>|/caller EXPR>, L<C<import>|/import LIST>,
297 L<C<local>|/local EXPR>, L<C<my>|/my VARLIST>, L<C<our>|/our VARLIST>,
298 L<C<package>|/package NAMESPACE>, L<C<state>|/state VARLIST>,
299 L<C<use>|/use Module VERSION LIST>
300
301 L<C<state>|/state VARLIST> is available only if the
302 L<C<"state"> feature|feature/The 'state' feature> is enabled or if it is
303 prefixed with C<CORE::>.  The
304 L<C<"state"> feature|feature/The 'state' feature> is enabled
305 automatically with a C<use v5.10> (or higher) declaration in the current
306 scope.
307
308 =item Miscellaneous functions
309
310 =for Pod::Functions =Misc
311
312 L<C<defined>|/defined EXPR>, L<C<formline>|/formline PICTURE,LIST>,
313 L<C<lock>|/lock THING>, L<C<prototype>|/prototype FUNCTION>,
314 L<C<reset>|/reset EXPR>, L<C<scalar>|/scalar EXPR>,
315 L<C<undef>|/undef EXPR>
316
317 =item Functions for processes and process groups
318 X<process> X<pid> X<process id>
319
320 =for Pod::Functions =Process
321
322 L<C<alarm>|/alarm SECONDS>, L<C<exec>|/exec LIST>, L<C<fork>|/fork>,
323 L<C<getpgrp>|/getpgrp PID>, L<C<getppid>|/getppid>,
324 L<C<getpriority>|/getpriority WHICH,WHO>, L<C<kill>|/kill SIGNAL, LIST>,
325 L<C<pipe>|/pipe READHANDLE,WRITEHANDLE>,
326 L<C<qxE<sol>E<sol>>|/qxE<sol>STRINGE<sol>>,
327 L<C<readpipe>|/readpipe EXPR>, L<C<setpgrp>|/setpgrp PID,PGRP>,
328 L<C<setpriority>|/setpriority WHICH,WHO,PRIORITY>,
329 L<C<sleep>|/sleep EXPR>, L<C<system>|/system LIST>, L<C<times>|/times>,
330 L<C<wait>|/wait>, L<C<waitpid>|/waitpid PID,FLAGS>
331
332 =item Keywords related to Perl modules
333 X<module>
334
335 =for Pod::Functions =Modules
336
337 L<C<do>|/do EXPR>, L<C<import>|/import LIST>,
338 L<C<no>|/no MODULE VERSION LIST>, L<C<package>|/package NAMESPACE>,
339 L<C<require>|/require VERSION>, L<C<use>|/use Module VERSION LIST>
340
341 =item Keywords related to classes and object-orientation
342 X<object> X<class> X<package>
343
344 =for Pod::Functions =Objects
345
346 L<C<bless>|/bless REF,CLASSNAME>, L<C<dbmclose>|/dbmclose HASH>,
347 L<C<dbmopen>|/dbmopen HASH,DBNAME,MASK>,
348 L<C<package>|/package NAMESPACE>, L<C<ref>|/ref EXPR>,
349 L<C<tie>|/tie VARIABLE,CLASSNAME,LIST>, L<C<tied>|/tied VARIABLE>,
350 L<C<untie>|/untie VARIABLE>, L<C<use>|/use Module VERSION LIST>
351
352 =item Low-level socket functions
353 X<socket> X<sock>
354
355 =for Pod::Functions =Socket
356
357 L<C<accept>|/accept NEWSOCKET,GENERICSOCKET>,
358 L<C<bind>|/bind SOCKET,NAME>, L<C<connect>|/connect SOCKET,NAME>,
359 L<C<getpeername>|/getpeername SOCKET>,
360 L<C<getsockname>|/getsockname SOCKET>,
361 L<C<getsockopt>|/getsockopt SOCKET,LEVEL,OPTNAME>,
362 L<C<listen>|/listen SOCKET,QUEUESIZE>,
363 L<C<recv>|/recv SOCKET,SCALAR,LENGTH,FLAGS>,
364 L<C<send>|/send SOCKET,MSG,FLAGS,TO>,
365 L<C<setsockopt>|/setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL>,
366 L<C<shutdown>|/shutdown SOCKET,HOW>,
367 L<C<socket>|/socket SOCKET,DOMAIN,TYPE,PROTOCOL>,
368 L<C<socketpair>|/socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL>
369
370 =item System V interprocess communication functions
371 X<IPC> X<System V> X<semaphore> X<shared memory> X<memory> X<message>
372
373 =for Pod::Functions =SysV
374
375 L<C<msgctl>|/msgctl ID,CMD,ARG>, L<C<msgget>|/msgget KEY,FLAGS>,
376 L<C<msgrcv>|/msgrcv ID,VAR,SIZE,TYPE,FLAGS>,
377 L<C<msgsnd>|/msgsnd ID,MSG,FLAGS>,
378 L<C<semctl>|/semctl ID,SEMNUM,CMD,ARG>,
379 L<C<semget>|/semget KEY,NSEMS,FLAGS>, L<C<semop>|/semop KEY,OPSTRING>,
380 L<C<shmctl>|/shmctl ID,CMD,ARG>, L<C<shmget>|/shmget KEY,SIZE,FLAGS>,
381 L<C<shmread>|/shmread ID,VAR,POS,SIZE>,
382 L<C<shmwrite>|/shmwrite ID,STRING,POS,SIZE>
383
384 =item Fetching user and group info
385 X<user> X<group> X<password> X<uid> X<gid>  X<passwd> X</etc/passwd>
386
387 =for Pod::Functions =User
388
389 L<C<endgrent>|/endgrent>, L<C<endhostent>|/endhostent>,
390 L<C<endnetent>|/endnetent>, L<C<endpwent>|/endpwent>,
391 L<C<getgrent>|/getgrent>, L<C<getgrgid>|/getgrgid GID>,
392 L<C<getgrnam>|/getgrnam NAME>, L<C<getlogin>|/getlogin>,
393 L<C<getpwent>|/getpwent>, L<C<getpwnam>|/getpwnam NAME>,
394 L<C<getpwuid>|/getpwuid UID>, L<C<setgrent>|/setgrent>,
395 L<C<setpwent>|/setpwent>
396
397 =item Fetching network info
398 X<network> X<protocol> X<host> X<hostname> X<IP> X<address> X<service>
399
400 =for Pod::Functions =Network
401
402 L<C<endprotoent>|/endprotoent>, L<C<endservent>|/endservent>,
403 L<C<gethostbyaddr>|/gethostbyaddr ADDR,ADDRTYPE>,
404 L<C<gethostbyname>|/gethostbyname NAME>, L<C<gethostent>|/gethostent>,
405 L<C<getnetbyaddr>|/getnetbyaddr ADDR,ADDRTYPE>,
406 L<C<getnetbyname>|/getnetbyname NAME>, L<C<getnetent>|/getnetent>,
407 L<C<getprotobyname>|/getprotobyname NAME>,
408 L<C<getprotobynumber>|/getprotobynumber NUMBER>,
409 L<C<getprotoent>|/getprotoent>,
410 L<C<getservbyname>|/getservbyname NAME,PROTO>,
411 L<C<getservbyport>|/getservbyport PORT,PROTO>,
412 L<C<getservent>|/getservent>, L<C<sethostent>|/sethostent STAYOPEN>,
413 L<C<setnetent>|/setnetent STAYOPEN>,
414 L<C<setprotoent>|/setprotoent STAYOPEN>,
415 L<C<setservent>|/setservent STAYOPEN>
416
417 =item Time-related functions
418 X<time> X<date>
419
420 =for Pod::Functions =Time
421
422 L<C<gmtime>|/gmtime EXPR>, L<C<localtime>|/localtime EXPR>,
423 L<C<time>|/time>, L<C<times>|/times>
424
425 =item Non-function keywords
426
427 =for Pod::Functions =!Non-functions
428
429 C<and>, C<AUTOLOAD>, C<BEGIN>, C<CHECK>, C<cmp>, C<CORE>, C<__DATA__>,
430 C<default>, C<DESTROY>, C<else>, C<elseif>, C<elsif>, C<END>, C<__END__>,
431 C<eq>, C<for>, C<foreach>, C<ge>, C<given>, C<gt>, C<if>, C<INIT>, C<le>,
432 C<lt>, C<ne>, C<not>, C<or>, C<UNITCHECK>, C<unless>, C<until>, C<when>,
433 C<while>, C<x>, C<xor>
434
435 =back
436
437 =head2 Portability
438 X<portability> X<Unix> X<portable>
439
440 Perl was born in Unix and can therefore access all common Unix
441 system calls.  In non-Unix environments, the functionality of some
442 Unix system calls may not be available or details of the available
443 functionality may differ slightly.  The Perl functions affected
444 by this are:
445
446 L<C<-I<X>>|/-X FILEHANDLE>, L<C<binmode>|/binmode FILEHANDLE, LAYER>,
447 L<C<chmod>|/chmod LIST>, L<C<chown>|/chown LIST>,
448 L<C<chroot>|/chroot FILENAME>, L<C<crypt>|/crypt PLAINTEXT,SALT>,
449 L<C<dbmclose>|/dbmclose HASH>, L<C<dbmopen>|/dbmopen HASH,DBNAME,MASK>,
450 L<C<dump>|/dump LABEL>, L<C<endgrent>|/endgrent>,
451 L<C<endhostent>|/endhostent>, L<C<endnetent>|/endnetent>,
452 L<C<endprotoent>|/endprotoent>, L<C<endpwent>|/endpwent>,
453 L<C<endservent>|/endservent>, L<C<exec>|/exec LIST>,
454 L<C<fcntl>|/fcntl FILEHANDLE,FUNCTION,SCALAR>,
455 L<C<flock>|/flock FILEHANDLE,OPERATION>, L<C<fork>|/fork>,
456 L<C<getgrent>|/getgrent>, L<C<getgrgid>|/getgrgid GID>,
457 L<C<gethostbyname>|/gethostbyname NAME>, L<C<gethostent>|/gethostent>,
458 L<C<getlogin>|/getlogin>,
459 L<C<getnetbyaddr>|/getnetbyaddr ADDR,ADDRTYPE>,
460 L<C<getnetbyname>|/getnetbyname NAME>, L<C<getnetent>|/getnetent>,
461 L<C<getppid>|/getppid>, L<C<getpgrp>|/getpgrp PID>,
462 L<C<getpriority>|/getpriority WHICH,WHO>,
463 L<C<getprotobynumber>|/getprotobynumber NUMBER>,
464 L<C<getprotoent>|/getprotoent>, L<C<getpwent>|/getpwent>,
465 L<C<getpwnam>|/getpwnam NAME>, L<C<getpwuid>|/getpwuid UID>,
466 L<C<getservbyport>|/getservbyport PORT,PROTO>,
467 L<C<getservent>|/getservent>,
468 L<C<getsockopt>|/getsockopt SOCKET,LEVEL,OPTNAME>,
469 L<C<glob>|/glob EXPR>, L<C<ioctl>|/ioctl FILEHANDLE,FUNCTION,SCALAR>,
470 L<C<kill>|/kill SIGNAL, LIST>, L<C<link>|/link OLDFILE,NEWFILE>,
471 L<C<lstat>|/lstat FILEHANDLE>, L<C<msgctl>|/msgctl ID,CMD,ARG>,
472 L<C<msgget>|/msgget KEY,FLAGS>,
473 L<C<msgrcv>|/msgrcv ID,VAR,SIZE,TYPE,FLAGS>,
474 L<C<msgsnd>|/msgsnd ID,MSG,FLAGS>, L<C<open>|/open FILEHANDLE,EXPR>,
475 L<C<pipe>|/pipe READHANDLE,WRITEHANDLE>, L<C<readlink>|/readlink EXPR>,
476 L<C<rename>|/rename OLDNAME,NEWNAME>,
477 L<C<select>|/select RBITS,WBITS,EBITS,TIMEOUT>,
478 L<C<semctl>|/semctl ID,SEMNUM,CMD,ARG>,
479 L<C<semget>|/semget KEY,NSEMS,FLAGS>, L<C<semop>|/semop KEY,OPSTRING>,
480 L<C<setgrent>|/setgrent>, L<C<sethostent>|/sethostent STAYOPEN>,
481 L<C<setnetent>|/setnetent STAYOPEN>, L<C<setpgrp>|/setpgrp PID,PGRP>,
482 L<C<setpriority>|/setpriority WHICH,WHO,PRIORITY>,
483 L<C<setprotoent>|/setprotoent STAYOPEN>, L<C<setpwent>|/setpwent>,
484 L<C<setservent>|/setservent STAYOPEN>,
485 L<C<setsockopt>|/setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL>,
486 L<C<shmctl>|/shmctl ID,CMD,ARG>, L<C<shmget>|/shmget KEY,SIZE,FLAGS>,
487 L<C<shmread>|/shmread ID,VAR,POS,SIZE>,
488 L<C<shmwrite>|/shmwrite ID,STRING,POS,SIZE>,
489 L<C<socket>|/socket SOCKET,DOMAIN,TYPE,PROTOCOL>,
490 L<C<socketpair>|/socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL>,
491 L<C<stat>|/stat FILEHANDLE>, L<C<symlink>|/symlink OLDFILE,NEWFILE>,
492 L<C<syscall>|/syscall NUMBER, LIST>,
493 L<C<sysopen>|/sysopen FILEHANDLE,FILENAME,MODE>,
494 L<C<system>|/system LIST>, L<C<times>|/times>,
495 L<C<truncate>|/truncate FILEHANDLE,LENGTH>, L<C<umask>|/umask EXPR>,
496 L<C<unlink>|/unlink LIST>, L<C<utime>|/utime LIST>, L<C<wait>|/wait>,
497 L<C<waitpid>|/waitpid PID,FLAGS>
498
499 For more information about the portability of these functions, see
500 L<perlport> and other available platform-specific documentation.
501
502 =head2 Alphabetical Listing of Perl Functions
503
504 =over
505
506 =item -X FILEHANDLE
507 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
508 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
509
510 =item -X EXPR
511
512 =item -X DIRHANDLE
513
514 =item -X
515
516 =for Pod::Functions a file test (-r, -x, etc)
517
518 A file test, where X is one of the letters listed below.  This unary
519 operator takes one argument, either a filename, a filehandle, or a dirhandle,
520 and tests the associated file to see if something is true about it.  If the
521 argument is omitted, tests L<C<$_>|perlvar/$_>, except for C<-t>, which
522 tests STDIN.  Unless otherwise documented, it returns C<1> for true and
523 C<''> for false.  If the file doesn't exist or can't be examined, it
524 returns L<C<undef>|/undef EXPR> and sets L<C<$!>|perlvar/$!> (errno).
525 With the exception of the C<-l> test they all follow symbolic links
526 because they use C<stat()> and not C<lstat()> (so dangling symlinks can't
527 be examined and will therefore report failure).
528
529 Despite the funny names, precedence is the same as any other named unary
530 operator.  The operator may be any of:
531
532     -r  File is readable by effective uid/gid.
533     -w  File is writable by effective uid/gid.
534     -x  File is executable by effective uid/gid.
535     -o  File is owned by effective uid.
536
537     -R  File is readable by real uid/gid.
538     -W  File is writable by real uid/gid.
539     -X  File is executable by real uid/gid.
540     -O  File is owned by real uid.
541
542     -e  File exists.
543     -z  File has zero size (is empty).
544     -s  File has nonzero size (returns size in bytes).
545
546     -f  File is a plain file.
547     -d  File is a directory.
548     -l  File is a symbolic link (false if symlinks aren't
549         supported by the file system).
550     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
551     -S  File is a socket.
552     -b  File is a block special file.
553     -c  File is a character special file.
554     -t  Filehandle is opened to a tty.
555
556     -u  File has setuid bit set.
557     -g  File has setgid bit set.
558     -k  File has sticky bit set.
559
560     -T  File is an ASCII or UTF-8 text file (heuristic guess).
561     -B  File is a "binary" file (opposite of -T).
562
563     -M  Script start time minus file modification time, in days.
564     -A  Same for access time.
565     -C  Same for inode change time (Unix, may differ for other
566         platforms)
567
568 Example:
569
570     while (<>) {
571         chomp;
572         next unless -f $_;  # ignore specials
573         #...
574     }
575
576 Note that C<-s/a/b/> does not do a negated substitution.  Saying
577 C<-exp($foo)> still works as expected, however: only single letters
578 following a minus are interpreted as file tests.
579
580 These operators are exempt from the "looks like a function rule" described
581 above.  That is, an opening parenthesis after the operator does not affect
582 how much of the following code constitutes the argument.  Put the opening
583 parentheses before the operator to separate it from code that follows (this
584 applies only to operators with higher precedence than unary operators, of
585 course):
586
587     -s($file) + 1024   # probably wrong; same as -s($file + 1024)
588     (-s $file) + 1024  # correct
589
590 The interpretation of the file permission operators C<-r>, C<-R>,
591 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
592 of the file and the uids and gids of the user.  There may be other
593 reasons you can't actually read, write, or execute the file: for
594 example network filesystem access controls, ACLs (access control lists),
595 read-only filesystems, and unrecognized executable formats.  Note
596 that the use of these six specific operators to verify if some operation
597 is possible is usually a mistake, because it may be open to race
598 conditions.
599
600 Also note that, for the superuser on the local filesystems, the C<-r>,
601 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
602 if any execute bit is set in the mode.  Scripts run by the superuser
603 may thus need to do a L<C<stat>|/stat FILEHANDLE> to determine the
604 actual mode of the file, or temporarily set their effective uid to
605 something else.
606
607 If you are using ACLs, there is a pragma called L<C<filetest>|filetest>
608 that may produce more accurate results than the bare
609 L<C<stat>|/stat FILEHANDLE> mode bits.
610 When under C<use filetest 'access'>, the above-mentioned filetests
611 test whether the permission can(not) be granted using the L<access(2)>
612 family of system calls.  Also note that the C<-x> and C<-X> tests may
613 under this pragma return true even if there are no execute permission
614 bits set (nor any extra execute permission ACLs).  This strangeness is
615 due to the underlying system calls' definitions.  Note also that, due to
616 the implementation of C<use filetest 'access'>, the C<_> special
617 filehandle won't cache the results of the file tests when this pragma is
618 in effect.  Read the documentation for the L<C<filetest>|filetest>
619 pragma for more information.
620
621 The C<-T> and C<-B> tests work as follows.  The first block or so of
622 the file is examined to see if it is valid UTF-8 that includes non-ASCII
623 characters.  If so, it's a C<-T> file.  Otherwise, that same portion of
624 the file is examined for odd characters such as strange control codes or
625 characters with the high bit set.  If more than a third of the
626 characters are strange, it's a C<-B> file; otherwise it's a C<-T> file.
627 Also, any file containing a zero byte in the examined portion is
628 considered a binary file.  (If executed within the scope of a L<S<use
629 locale>|perllocale> which includes C<LC_CTYPE>, odd characters are
630 anything that isn't a printable nor space in the current locale.)  If
631 C<-T> or C<-B> is used on a filehandle, the current IO buffer is
632 examined
633 rather than the first block.  Both C<-T> and C<-B> return true on an empty
634 file, or a file at EOF when testing a filehandle.  Because you have to
635 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
636 against the file first, as in C<next unless -f $file && -T $file>.
637
638 If any of the file tests (or either the L<C<stat>|/stat FILEHANDLE> or
639 L<C<lstat>|/lstat FILEHANDLE> operator) is given the special filehandle
640 consisting of a solitary underline, then the stat structure of the
641 previous file test (or L<C<stat>|/stat FILEHANDLE> operator) is used,
642 saving a system call.  (This doesn't work with C<-t>, and you need to
643 remember that L<C<lstat>|/lstat FILEHANDLE> and C<-l> leave values in
644 the stat structure for the symbolic link, not the real file.)  (Also, if
645 the stat buffer was filled by an L<C<lstat>|/lstat FILEHANDLE> call,
646 C<-T> and C<-B> will reset it with the results of C<stat _>).
647 Example:
648
649     print "Can do.\n" if -r $a || -w _ || -x _;
650
651     stat($filename);
652     print "Readable\n" if -r _;
653     print "Writable\n" if -w _;
654     print "Executable\n" if -x _;
655     print "Setuid\n" if -u _;
656     print "Setgid\n" if -g _;
657     print "Sticky\n" if -k _;
658     print "Text\n" if -T _;
659     print "Binary\n" if -B _;
660
661 As of Perl 5.10.0, as a form of purely syntactic sugar, you can stack file
662 test operators, in a way that C<-f -w -x $file> is equivalent to
663 C<-x $file && -w _ && -f _>.  (This is only fancy syntax: if you use
664 the return value of C<-f $file> as an argument to another filetest
665 operator, no special magic will happen.)
666
667 Portability issues: L<perlport/-X>.
668
669 To avoid confusing would-be users of your code with mysterious
670 syntax errors, put something like this at the top of your script:
671
672     use 5.010;  # so filetest ops can stack
673
674 =item abs VALUE
675 X<abs> X<absolute>
676
677 =item abs
678
679 =for Pod::Functions absolute value function
680
681 Returns the absolute value of its argument.
682 If VALUE is omitted, uses L<C<$_>|perlvar/$_>.
683
684 =item accept NEWSOCKET,GENERICSOCKET
685 X<accept>
686
687 =for Pod::Functions accept an incoming socket connect
688
689 Accepts an incoming socket connect, just as L<accept(2)>
690 does.  Returns the packed address if it succeeded, false otherwise.
691 See the example in L<perlipc/"Sockets: Client/Server Communication">.
692
693 On systems that support a close-on-exec flag on files, the flag will
694 be set for the newly opened file descriptor, as determined by the
695 value of L<C<$^F>|perlvar/$^F>.  See L<perlvar/$^F>.
696
697 =item alarm SECONDS
698 X<alarm>
699 X<SIGALRM>
700 X<timer>
701
702 =item alarm
703
704 =for Pod::Functions schedule a SIGALRM
705
706 Arranges to have a SIGALRM delivered to this process after the
707 specified number of wallclock seconds has elapsed.  If SECONDS is not
708 specified, the value stored in L<C<$_>|perlvar/$_> is used.  (On some
709 machines, unfortunately, the elapsed time may be up to one second less
710 or more than you specified because of how seconds are counted, and
711 process scheduling may delay the delivery of the signal even further.)
712
713 Only one timer may be counting at once.  Each call disables the
714 previous timer, and an argument of C<0> may be supplied to cancel the
715 previous timer without starting a new one.  The returned value is the
716 amount of time remaining on the previous timer.
717
718 For delays of finer granularity than one second, the L<Time::HiRes> module
719 (from CPAN, and starting from Perl 5.8 part of the standard
720 distribution) provides
721 L<C<ualarm>|Time::HiRes/ualarm ( $useconds [, $interval_useconds ] )>.
722 You may also use Perl's four-argument version of
723 L<C<select>|/select RBITS,WBITS,EBITS,TIMEOUT> leaving the first three
724 arguments undefined, or you might be able to use the
725 L<C<syscall>|/syscall NUMBER, LIST> interface to access L<setitimer(2)>
726 if your system supports it.  See L<perlfaq8> for details.
727
728 It is usually a mistake to intermix L<C<alarm>|/alarm SECONDS> and
729 L<C<sleep>|/sleep EXPR> calls, because L<C<sleep>|/sleep EXPR> may be
730 internally implemented on your system with L<C<alarm>|/alarm SECONDS>.
731
732 If you want to use L<C<alarm>|/alarm SECONDS> to time out a system call
733 you need to use an L<C<eval>|/eval EXPR>/L<C<die>|/die LIST> pair.  You
734 can't rely on the alarm causing the system call to fail with
735 L<C<$!>|perlvar/$!> set to C<EINTR> because Perl sets up signal handlers
736 to restart system calls on some systems.  Using
737 L<C<eval>|/eval EXPR>/L<C<die>|/die LIST> always works, modulo the
738 caveats given in L<perlipc/"Signals">.
739
740     eval {
741         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
742         alarm $timeout;
743         my $nread = sysread $socket, $buffer, $size;
744         alarm 0;
745     };
746     if ($@) {
747         die unless $@ eq "alarm\n";   # propagate unexpected errors
748         # timed out
749     }
750     else {
751         # didn't
752     }
753
754 For more information see L<perlipc>.
755
756 Portability issues: L<perlport/alarm>.
757
758 =item atan2 Y,X
759 X<atan2> X<arctangent> X<tan> X<tangent>
760
761 =for Pod::Functions arctangent of Y/X in the range -PI to PI
762
763 Returns the arctangent of Y/X in the range -PI to PI.
764
765 For the tangent operation, you may use the
766 L<C<Math::Trig::tan>|Math::Trig/B<tan>> function, or use the familiar
767 relation:
768
769     sub tan { sin($_[0]) / cos($_[0])  }
770
771 The return value for C<atan2(0,0)> is implementation-defined; consult
772 your L<atan2(3)> manpage for more information.
773
774 Portability issues: L<perlport/atan2>.
775
776 =item bind SOCKET,NAME
777 X<bind>
778
779 =for Pod::Functions binds an address to a socket
780
781 Binds a network address to a socket, just as L<bind(2)>
782 does.  Returns true if it succeeded, false otherwise.  NAME should be a
783 packed address of the appropriate type for the socket.  See the examples in
784 L<perlipc/"Sockets: Client/Server Communication">.
785
786 =item binmode FILEHANDLE, LAYER
787 X<binmode> X<binary> X<text> X<DOS> X<Windows>
788
789 =item binmode FILEHANDLE
790
791 =for Pod::Functions prepare binary files for I/O
792
793 Arranges for FILEHANDLE to be read or written in "binary" or "text"
794 mode on systems where the run-time libraries distinguish between
795 binary and text files.  If FILEHANDLE is an expression, the value is
796 taken as the name of the filehandle.  Returns true on success,
797 otherwise it returns L<C<undef>|/undef EXPR> and sets
798 L<C<$!>|perlvar/$!> (errno).
799
800 On some systems (in general, DOS- and Windows-based systems)
801 L<C<binmode>|/binmode FILEHANDLE, LAYER> is necessary when you're not
802 working with a text file.  For the sake of portability it is a good idea
803 always to use it when appropriate, and never to use it when it isn't
804 appropriate.  Also, people can set their I/O to be by default
805 UTF8-encoded Unicode, not bytes.
806
807 In other words: regardless of platform, use
808 L<C<binmode>|/binmode FILEHANDLE, LAYER> on binary data, like images,
809 for example.
810
811 If LAYER is present it is a single string, but may contain multiple
812 directives.  The directives alter the behaviour of the filehandle.
813 When LAYER is present, using binmode on a text file makes sense.
814
815 If LAYER is omitted or specified as C<:raw> the filehandle is made
816 suitable for passing binary data.  This includes turning off possible CRLF
817 translation and marking it as bytes (as opposed to Unicode characters).
818 Note that, despite what may be implied in I<"Programming Perl"> (the
819 Camel, 3rd edition) or elsewhere, C<:raw> is I<not> simply the inverse of C<:crlf>.
820 Other layers that would affect the binary nature of the stream are
821 I<also> disabled.  See L<PerlIO>, and the discussion about the PERLIO
822 environment variable in L<perlrun|perlrun/PERLIO>.
823
824 The C<:bytes>, C<:crlf>, C<:utf8>, and any other directives of the
825 form C<:...>, are called I/O I<layers>.  The L<open> pragma can be used to
826 establish default I/O layers.
827
828 I<The LAYER parameter of the L<C<binmode>|/binmode FILEHANDLE, LAYER>
829 function is described as "DISCIPLINE" in "Programming Perl, 3rd
830 Edition".  However, since the publishing of this book, by many known as
831 "Camel III", the consensus of the naming of this functionality has moved
832 from "discipline" to "layer".  All documentation of this version of Perl
833 therefore refers to "layers" rather than to "disciplines".  Now back to
834 the regularly scheduled documentation...>
835
836 To mark FILEHANDLE as UTF-8, use C<:utf8> or C<:encoding(UTF-8)>.
837 C<:utf8> just marks the data as UTF-8 without further checking,
838 while C<:encoding(UTF-8)> checks the data for actually being valid
839 UTF-8.  More details can be found in L<PerlIO::encoding>.
840
841 In general, L<C<binmode>|/binmode FILEHANDLE, LAYER> should be called
842 after L<C<open>|/open FILEHANDLE,EXPR> but before any I/O is done on the
843 filehandle.  Calling L<C<binmode>|/binmode FILEHANDLE, LAYER> normally
844 flushes any pending buffered output data (and perhaps pending input
845 data) on the handle.  An exception to this is the C<:encoding> layer
846 that changes the default character encoding of the handle.
847 The C<:encoding> layer sometimes needs to be called in
848 mid-stream, and it doesn't flush the stream.  C<:encoding>
849 also implicitly pushes on top of itself the C<:utf8> layer because
850 internally Perl operates on UTF8-encoded Unicode characters.
851
852 The operating system, device drivers, C libraries, and Perl run-time
853 system all conspire to let the programmer treat a single
854 character (C<\n>) as the line terminator, irrespective of external
855 representation.  On many operating systems, the native text file
856 representation matches the internal representation, but on some
857 platforms the external representation of C<\n> is made up of more than
858 one character.
859
860 All variants of Unix, Mac OS (old and new), and Stream_LF files on VMS use
861 a single character to end each line in the external representation of text
862 (even though that single character is CARRIAGE RETURN on old, pre-Darwin
863 flavors of Mac OS, and is LINE FEED on Unix and most VMS files).  In other
864 systems like OS/2, DOS, and the various flavors of MS-Windows, your program
865 sees a C<\n> as a simple C<\cJ>, but what's stored in text files are the
866 two characters C<\cM\cJ>.  That means that if you don't use
867 L<C<binmode>|/binmode FILEHANDLE, LAYER> on these systems, C<\cM\cJ>
868 sequences on disk will be converted to C<\n> on input, and any C<\n> in
869 your program will be converted back to C<\cM\cJ> on output.  This is
870 what you want for text files, but it can be disastrous for binary files.
871
872 Another consequence of using L<C<binmode>|/binmode FILEHANDLE, LAYER>
873 (on some systems) is that special end-of-file markers will be seen as
874 part of the data stream.  For systems from the Microsoft family this
875 means that, if your binary data contain C<\cZ>, the I/O subsystem will
876 regard it as the end of the file, unless you use
877 L<C<binmode>|/binmode FILEHANDLE, LAYER>.
878
879 L<C<binmode>|/binmode FILEHANDLE, LAYER> is important not only for
880 L<C<readline>|/readline EXPR> and L<C<print>|/print FILEHANDLE LIST>
881 operations, but also when using
882 L<C<read>|/read FILEHANDLE,SCALAR,LENGTH,OFFSET>,
883 L<C<seek>|/seek FILEHANDLE,POSITION,WHENCE>,
884 L<C<sysread>|/sysread FILEHANDLE,SCALAR,LENGTH,OFFSET>,
885 L<C<syswrite>|/syswrite FILEHANDLE,SCALAR,LENGTH,OFFSET> and
886 L<C<tell>|/tell FILEHANDLE> (see L<perlport> for more details).  See the
887 L<C<$E<sol>>|perlvar/$E<sol>> and L<C<$\>|perlvar/$\> variables in
888 L<perlvar> for how to manually set your input and output
889 line-termination sequences.
890
891 Portability issues: L<perlport/binmode>.
892
893 =item bless REF,CLASSNAME
894 X<bless>
895
896 =item bless REF
897
898 =for Pod::Functions create an object
899
900 This function tells the thingy referenced by REF that it is now an object
901 in the CLASSNAME package.  If CLASSNAME is an empty string, it is
902 interpreted as referring to the C<main> package.
903 If CLASSNAME is omitted, the current package
904 is used.  Because a L<C<bless>|/bless REF,CLASSNAME> is often the last
905 thing in a constructor, it returns the reference for convenience.
906 Always use the two-argument version if a derived class might inherit the
907 method doing the blessing.  See L<perlobj> for more about the blessing
908 (and blessings) of objects.
909
910 Consider always blessing objects in CLASSNAMEs that are mixed case.
911 Namespaces with all lowercase names are considered reserved for
912 Perl pragmas.  Builtin types have all uppercase names.  To prevent
913 confusion, you may wish to avoid such package names as well.
914 It is advised to avoid the class name C<0>, because much code erroneously
915 uses the result of L<C<ref>|/ref EXPR> as a truth value.
916
917 See L<perlmod/"Perl Modules">.
918
919 =item break
920
921 =for Pod::Functions +switch break out of a C<given> block
922
923 Break out of a C<given> block.
924
925 L<C<break>|/break> is available only if the
926 L<C<"switch"> feature|feature/The 'switch' feature> is enabled or if it
927 is prefixed with C<CORE::>. The
928 L<C<"switch"> feature|feature/The 'switch' feature> is enabled
929 automatically with a C<use v5.10> (or higher) declaration in the current
930 scope.
931
932 =item caller EXPR
933 X<caller> X<call stack> X<stack> X<stack trace>
934
935 =item caller
936
937 =for Pod::Functions get context of the current subroutine call
938
939 Returns the context of the current pure perl subroutine call.  In scalar
940 context, returns the caller's package name if there I<is> a caller (that is, if
941 we're in a subroutine or L<C<eval>|/eval EXPR> or
942 L<C<require>|/require VERSION>) and the undefined value otherwise.
943 caller never returns XS subs and they are skipped.  The next pure perl
944 sub will appear instead of the XS sub in caller's return values.  In
945 list context, caller returns
946
947        # 0         1          2
948     my ($package, $filename, $line) = caller;
949
950 With EXPR, it returns some extra information that the debugger uses to
951 print a stack trace.  The value of EXPR indicates how many call frames
952 to go back before the current one.
953
954     #  0         1          2      3            4
955  my ($package, $filename, $line, $subroutine, $hasargs,
956
957     #  5          6          7            8       9         10
958     $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash)
959   = caller($i);
960
961 Here, $subroutine is the function that the caller called (rather than the
962 function containing the caller).  Note that $subroutine may be C<(eval)> if
963 the frame is not a subroutine call, but an L<C<eval>|/eval EXPR>.  In
964 such a case additional elements $evaltext and C<$is_require> are set:
965 C<$is_require> is true if the frame is created by a
966 L<C<require>|/require VERSION> or L<C<use>|/use Module VERSION LIST>
967 statement, $evaltext contains the text of the C<eval EXPR> statement.
968 In particular, for an C<eval BLOCK> statement, $subroutine is C<(eval)>,
969 but $evaltext is undefined.  (Note also that each
970 L<C<use>|/use Module VERSION LIST> statement creates a
971 L<C<require>|/require VERSION> frame inside an C<eval EXPR> frame.)
972 $subroutine may also be C<(unknown)> if this particular subroutine
973 happens to have been deleted from the symbol table.  C<$hasargs> is true
974 if a new instance of L<C<@_>|perlvar/@_> was set up for the frame.
975 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
976 compiled with.  C<$hints> corresponds to L<C<$^H>|perlvar/$^H>, and
977 C<$bitmask> corresponds to
978 L<C<${^WARNING_BITS}>|perlvar/${^WARNING_BITS}>.  The C<$hints> and
979 C<$bitmask> values are subject to change between versions of Perl, and
980 are not meant for external use.
981
982 C<$hinthash> is a reference to a hash containing the value of
983 L<C<%^H>|perlvar/%^H> when the caller was compiled, or
984 L<C<undef>|/undef EXPR> if L<C<%^H>|perlvar/%^H> was empty.  Do not
985 modify the values of this hash, as they are the actual values stored in
986 the optree.
987
988 Furthermore, when called from within the DB package in
989 list context, and with an argument, caller returns more
990 detailed information: it sets the list variable C<@DB::args> to be the
991 arguments with which the subroutine was invoked.
992
993 Be aware that the optimizer might have optimized call frames away before
994 L<C<caller>|/caller EXPR> had a chance to get the information.  That
995 means that C<caller(N)> might not return information about the call
996 frame you expect it to, for C<< N > 1 >>.  In particular, C<@DB::args>
997 might have information from the previous time L<C<caller>|/caller EXPR>
998 was called.
999
1000 Be aware that setting C<@DB::args> is I<best effort>, intended for
1001 debugging or generating backtraces, and should not be relied upon.  In
1002 particular, as L<C<@_>|perlvar/@_> contains aliases to the caller's
1003 arguments, Perl does not take a copy of L<C<@_>|perlvar/@_>, so
1004 C<@DB::args> will contain modifications the subroutine makes to
1005 L<C<@_>|perlvar/@_> or its contents, not the original values at call
1006 time.  C<@DB::args>, like L<C<@_>|perlvar/@_>, does not hold explicit
1007 references to its elements, so under certain cases its elements may have
1008 become freed and reallocated for other variables or temporary values.
1009 Finally, a side effect of the current implementation is that the effects
1010 of C<shift @_> can I<normally> be undone (but not C<pop @_> or other
1011 splicing, I<and> not if a reference to L<C<@_>|perlvar/@_> has been
1012 taken, I<and> subject to the caveat about reallocated elements), so
1013 C<@DB::args> is actually a hybrid of the current state and initial state
1014 of L<C<@_>|perlvar/@_>.  Buyer beware.
1015
1016 =item chdir EXPR
1017 X<chdir>
1018 X<cd>
1019 X<directory, change>
1020
1021 =item chdir FILEHANDLE
1022
1023 =item chdir DIRHANDLE
1024
1025 =item chdir
1026
1027 =for Pod::Functions change your current working directory
1028
1029 Changes the working directory to EXPR, if possible.  If EXPR is omitted,
1030 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
1031 changes to the directory specified by C<$ENV{LOGDIR}>.  (Under VMS, the
1032 variable C<$ENV{'SYS$LOGIN'}> is also checked, and used if it is set.)  If
1033 neither is set, L<C<chdir>|/chdir EXPR> does nothing and fails.  It
1034 returns true on success, false otherwise.  See the example under
1035 L<C<die>|/die LIST>.
1036
1037 On systems that support L<fchdir(2)>, you may pass a filehandle or
1038 directory handle as the argument.  On systems that don't support L<fchdir(2)>,
1039 passing handles raises an exception.
1040
1041 =item chmod LIST
1042 X<chmod> X<permission> X<mode>
1043
1044 =for Pod::Functions changes the permissions on a list of files
1045
1046 Changes the permissions of a list of files.  The first element of the
1047 list must be the numeric mode, which should probably be an octal
1048 number, and which definitely should I<not> be a string of octal digits:
1049 C<0644> is okay, but C<"0644"> is not.  Returns the number of files
1050 successfully changed.  See also L<C<oct>|/oct EXPR> if all you have is a
1051 string.
1052
1053     my $cnt = chmod 0755, "foo", "bar";
1054     chmod 0755, @executables;
1055     my $mode = "0644"; chmod $mode, "foo";      # !!! sets mode to
1056                                                 # --w----r-T
1057     my $mode = "0644"; chmod oct($mode), "foo"; # this is better
1058     my $mode = 0644;   chmod $mode, "foo";      # this is best
1059
1060 On systems that support L<fchmod(2)>, you may pass filehandles among the
1061 files.  On systems that don't support L<fchmod(2)>, passing filehandles raises
1062 an exception.  Filehandles must be passed as globs or glob references to be
1063 recognized; barewords are considered filenames.
1064
1065     open(my $fh, "<", "foo");
1066     my $perm = (stat $fh)[2] & 07777;
1067     chmod($perm | 0600, $fh);
1068
1069 You can also import the symbolic C<S_I*> constants from the
1070 L<C<Fcntl>|Fcntl> module:
1071
1072     use Fcntl qw( :mode );
1073     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
1074     # Identical to the chmod 0755 of the example above.
1075
1076 Portability issues: L<perlport/chmod>.
1077
1078 =item chomp VARIABLE
1079 X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol>
1080
1081 =item chomp( LIST )
1082
1083 =item chomp
1084
1085 =for Pod::Functions remove a trailing record separator from a string
1086
1087 This safer version of L<C<chop>|/chop VARIABLE> removes any trailing
1088 string that corresponds to the current value of
1089 L<C<$E<sol>>|perlvar/$E<sol>> (also known as C<$INPUT_RECORD_SEPARATOR>
1090 in the L<C<English>|English> module).  It returns the total
1091 number of characters removed from all its arguments.  It's often used to
1092 remove the newline from the end of an input record when you're worried
1093 that the final record may be missing its newline.  When in paragraph
1094 mode (C<$/ = ''>), it removes all trailing newlines from the string.
1095 When in slurp mode (C<$/ = undef>) or fixed-length record mode
1096 (L<C<$E<sol>>|perlvar/$E<sol>> is a reference to an integer or the like;
1097 see L<perlvar>), L<C<chomp>|/chomp VARIABLE> won't remove anything.
1098 If VARIABLE is omitted, it chomps L<C<$_>|perlvar/$_>.  Example:
1099
1100     while (<>) {
1101         chomp;  # avoid \n on last field
1102         my @array = split(/:/);
1103         # ...
1104     }
1105
1106 If VARIABLE is a hash, it chomps the hash's values, but not its keys,
1107 resetting the L<C<each>|/each HASH> iterator in the process.
1108
1109 You can actually chomp anything that's an lvalue, including an assignment:
1110
1111     chomp(my $cwd = `pwd`);
1112     chomp(my $answer = <STDIN>);
1113
1114 If you chomp a list, each element is chomped, and the total number of
1115 characters removed is returned.
1116
1117 Note that parentheses are necessary when you're chomping anything
1118 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
1119 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
1120 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
1121 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
1122 as C<chomp($a, $b)>.
1123
1124 =item chop VARIABLE
1125 X<chop>
1126
1127 =item chop( LIST )
1128
1129 =item chop
1130
1131 =for Pod::Functions remove the last character from a string
1132
1133 Chops off the last character of a string and returns the character
1134 chopped.  It is much more efficient than C<s/.$//s> because it neither
1135 scans nor copies the string.  If VARIABLE is omitted, chops
1136 L<C<$_>|perlvar/$_>.
1137 If VARIABLE is a hash, it chops the hash's values, but not its keys,
1138 resetting the L<C<each>|/each HASH> iterator in the process.
1139
1140 You can actually chop anything that's an lvalue, including an assignment.
1141
1142 If you chop a list, each element is chopped.  Only the value of the
1143 last L<C<chop>|/chop VARIABLE> is returned.
1144
1145 Note that L<C<chop>|/chop VARIABLE> returns the last character.  To
1146 return all but the last character, use C<substr($string, 0, -1)>.
1147
1148 See also L<C<chomp>|/chomp VARIABLE>.
1149
1150 =item chown LIST
1151 X<chown> X<owner> X<user> X<group>
1152
1153 =for Pod::Functions change the ownership on a list of files
1154
1155 Changes the owner (and group) of a list of files.  The first two
1156 elements of the list must be the I<numeric> uid and gid, in that
1157 order.  A value of -1 in either position is interpreted by most
1158 systems to leave that value unchanged.  Returns the number of files
1159 successfully changed.
1160
1161     my $cnt = chown $uid, $gid, 'foo', 'bar';
1162     chown $uid, $gid, @filenames;
1163
1164 On systems that support L<fchown(2)>, you may pass filehandles among the
1165 files.  On systems that don't support L<fchown(2)>, passing filehandles raises
1166 an exception.  Filehandles must be passed as globs or glob references to be
1167 recognized; barewords are considered filenames.
1168
1169 Here's an example that looks up nonnumeric uids in the passwd file:
1170
1171     print "User: ";
1172     chomp(my $user = <STDIN>);
1173     print "Files: ";
1174     chomp(my $pattern = <STDIN>);
1175
1176     my ($login,$pass,$uid,$gid) = getpwnam($user)
1177         or die "$user not in passwd file";
1178
1179     my @ary = glob($pattern);  # expand filenames
1180     chown $uid, $gid, @ary;
1181
1182 On most systems, you are not allowed to change the ownership of the
1183 file unless you're the superuser, although you should be able to change
1184 the group to any of your secondary groups.  On insecure systems, these
1185 restrictions may be relaxed, but this is not a portable assumption.
1186 On POSIX systems, you can detect this condition this way:
1187
1188     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
1189     my $can_chown_giveaway = ! sysconf(_PC_CHOWN_RESTRICTED);
1190
1191 Portability issues: L<perlport/chown>.
1192
1193 =item chr NUMBER
1194 X<chr> X<character> X<ASCII> X<Unicode>
1195
1196 =item chr
1197
1198 =for Pod::Functions get character this number represents
1199
1200 Returns the character represented by that NUMBER in the character set.
1201 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
1202 chr(0x263a) is a Unicode smiley face.
1203
1204 Negative values give the Unicode replacement character (chr(0xfffd)),
1205 except under the L<bytes> pragma, where the low eight bits of the value
1206 (truncated to an integer) are used.
1207
1208 If NUMBER is omitted, uses L<C<$_>|perlvar/$_>.
1209
1210 For the reverse, use L<C<ord>|/ord EXPR>.
1211
1212 Note that characters from 128 to 255 (inclusive) are by default
1213 internally not encoded as UTF-8 for backward compatibility reasons.
1214
1215 See L<perlunicode> for more about Unicode.
1216
1217 =item chroot FILENAME
1218 X<chroot> X<root>
1219
1220 =item chroot
1221
1222 =for Pod::Functions make directory new root for path lookups
1223
1224 This function works like the system call by the same name: it makes the
1225 named directory the new root directory for all further pathnames that
1226 begin with a C</> by your process and all its children.  (It doesn't
1227 change your current working directory, which is unaffected.)  For security
1228 reasons, this call is restricted to the superuser.  If FILENAME is
1229 omitted, does a L<C<chroot>|/chroot FILENAME> to L<C<$_>|perlvar/$_>.
1230
1231 B<NOTE:>  It is mandatory for security to C<chdir("/")>
1232 (L<C<chdir>|/chdir EXPR> to the root directory) immediately after a
1233 L<C<chroot>|/chroot FILENAME>, otherwise the current working directory
1234 may be outside of the new root.
1235
1236 Portability issues: L<perlport/chroot>.
1237
1238 =item close FILEHANDLE
1239 X<close>
1240
1241 =item close
1242
1243 =for Pod::Functions close file (or pipe or socket) handle
1244
1245 Closes the file or pipe associated with the filehandle, flushes the IO
1246 buffers, and closes the system file descriptor.  Returns true if those
1247 operations succeed and if no error was reported by any PerlIO
1248 layer.  Closes the currently selected filehandle if the argument is
1249 omitted.
1250
1251 You don't have to close FILEHANDLE if you are immediately going to do
1252 another L<C<open>|/open FILEHANDLE,EXPR> on it, because
1253 L<C<open>|/open FILEHANDLE,EXPR> closes it for you.  (See
1254 L<C<open>|/open FILEHANDLE,EXPR>.) However, an explicit
1255 L<C<close>|/close FILEHANDLE> on an input file resets the line counter
1256 (L<C<$.>|perlvar/$.>), while the implicit close done by
1257 L<C<open>|/open FILEHANDLE,EXPR> does not.
1258
1259 If the filehandle came from a piped open, L<C<close>|/close FILEHANDLE>
1260 returns false if one of the other syscalls involved fails or if its
1261 program exits with non-zero status.  If the only problem was that the
1262 program exited non-zero, L<C<$!>|perlvar/$!> will be set to C<0>.
1263 Closing a pipe also waits for the process executing on the pipe to
1264 exit--in case you wish to look at the output of the pipe afterwards--and
1265 implicitly puts the exit status value of that command into
1266 L<C<$?>|perlvar/$?> and
1267 L<C<${^CHILD_ERROR_NATIVE}>|perlvar/${^CHILD_ERROR_NATIVE}>.
1268
1269 If there are multiple threads running, L<C<close>|/close FILEHANDLE> on
1270 a filehandle from a piped open returns true without waiting for the
1271 child process to terminate, if the filehandle is still open in another
1272 thread.
1273
1274 Closing the read end of a pipe before the process writing to it at the
1275 other end is done writing results in the writer receiving a SIGPIPE.  If
1276 the other end can't handle that, be sure to read all the data before
1277 closing the pipe.
1278
1279 Example:
1280
1281     open(OUTPUT, '|sort >foo')  # pipe to sort
1282         or die "Can't start sort: $!";
1283     #...                        # print stuff to output
1284     close OUTPUT                # wait for sort to finish
1285         or warn $! ? "Error closing sort pipe: $!"
1286                    : "Exit status $? from sort";
1287     open(INPUT, 'foo')          # get sort's results
1288         or die "Can't open 'foo' for input: $!";
1289
1290 FILEHANDLE may be an expression whose value can be used as an indirect
1291 filehandle, usually the real filehandle name or an autovivified handle.
1292
1293 =item closedir DIRHANDLE
1294 X<closedir>
1295
1296 =for Pod::Functions close directory handle
1297
1298 Closes a directory opened by L<C<opendir>|/opendir DIRHANDLE,EXPR> and
1299 returns the success of that system call.
1300
1301 =item connect SOCKET,NAME
1302 X<connect>
1303
1304 =for Pod::Functions connect to a remote socket
1305
1306 Attempts to connect to a remote socket, just like L<connect(2)>.
1307 Returns true if it succeeded, false otherwise.  NAME should be a
1308 packed address of the appropriate type for the socket.  See the examples in
1309 L<perlipc/"Sockets: Client/Server Communication">.
1310
1311 =item continue BLOCK
1312 X<continue>
1313
1314 =item continue
1315
1316 =for Pod::Functions optional trailing block in a while or foreach
1317
1318 When followed by a BLOCK, L<C<continue>|/continue BLOCK> is actually a
1319 flow control statement rather than a function.  If there is a
1320 L<C<continue>|/continue BLOCK> BLOCK attached to a BLOCK (typically in a
1321 C<while> or C<foreach>), it is always executed just before the
1322 conditional is about to be evaluated again, just like the third part of
1323 a C<for> loop in C.  Thus it can be used to increment a loop variable,
1324 even when the loop has been continued via the L<C<next>|/next LABEL>
1325 statement (which is similar to the C L<C<continue>|/continue BLOCK>
1326 statement).
1327
1328 L<C<last>|/last LABEL>, L<C<next>|/next LABEL>, or
1329 L<C<redo>|/redo LABEL> may appear within a
1330 L<C<continue>|/continue BLOCK> block; L<C<last>|/last LABEL> and
1331 L<C<redo>|/redo LABEL> behave as if they had been executed within the
1332 main block.  So will L<C<next>|/next LABEL>, but since it will execute a
1333 L<C<continue>|/continue BLOCK> block, it may be more entertaining.
1334
1335     while (EXPR) {
1336         ### redo always comes here
1337         do_something;
1338     } continue {
1339         ### next always comes here
1340         do_something_else;
1341         # then back the top to re-check EXPR
1342     }
1343     ### last always comes here
1344
1345 Omitting the L<C<continue>|/continue BLOCK> section is equivalent to
1346 using an empty one, logically enough, so L<C<next>|/next LABEL> goes
1347 directly back to check the condition at the top of the loop.
1348
1349 When there is no BLOCK, L<C<continue>|/continue BLOCK> is a function
1350 that falls through the current C<when> or C<default> block instead of
1351 iterating a dynamically enclosing C<foreach> or exiting a lexically
1352 enclosing C<given>.  In Perl 5.14 and earlier, this form of
1353 L<C<continue>|/continue BLOCK> was only available when the
1354 L<C<"switch"> feature|feature/The 'switch' feature> was enabled.  See
1355 L<feature> and L<perlsyn/"Switch Statements"> for more information.
1356
1357 =item cos EXPR
1358 X<cos> X<cosine> X<acos> X<arccosine>
1359
1360 =item cos
1361
1362 =for Pod::Functions cosine function
1363
1364 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
1365 takes the cosine of L<C<$_>|perlvar/$_>.
1366
1367 For the inverse cosine operation, you may use the
1368 L<C<Math::Trig::acos>|Math::Trig> function, or use this relation:
1369
1370     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
1371
1372 =item crypt PLAINTEXT,SALT
1373 X<crypt> X<digest> X<hash> X<salt> X<plaintext> X<password>
1374 X<decrypt> X<cryptography> X<passwd> X<encrypt>
1375
1376 =for Pod::Functions one-way passwd-style encryption
1377
1378 Creates a digest string exactly like the L<crypt(3)> function in the C
1379 library (assuming that you actually have a version there that has not
1380 been extirpated as a potential munition).
1381
1382 L<C<crypt>|/crypt PLAINTEXT,SALT> is a one-way hash function.  The
1383 PLAINTEXT and SALT are turned
1384 into a short string, called a digest, which is returned.  The same
1385 PLAINTEXT and SALT will always return the same string, but there is no
1386 (known) way to get the original PLAINTEXT from the hash.  Small
1387 changes in the PLAINTEXT or SALT will result in large changes in the
1388 digest.
1389
1390 There is no decrypt function.  This function isn't all that useful for
1391 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
1392 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
1393 primarily used to check if two pieces of text are the same without
1394 having to transmit or store the text itself.  An example is checking
1395 if a correct password is given.  The digest of the password is stored,
1396 not the password itself.  The user types in a password that is
1397 L<C<crypt>|/crypt PLAINTEXT,SALT>'d with the same salt as the stored
1398 digest.  If the two digests match, the password is correct.
1399
1400 When verifying an existing digest string you should use the digest as
1401 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
1402 to create the digest is visible as part of the digest.  This ensures
1403 L<C<crypt>|/crypt PLAINTEXT,SALT> will hash the new string with the same
1404 salt as the digest.  This allows your code to work with the standard
1405 L<C<crypt>|/crypt PLAINTEXT,SALT> and with more exotic implementations.
1406 In other words, assume nothing about the returned string itself nor
1407 about how many bytes of SALT may matter.
1408
1409 Traditionally the result is a string of 13 bytes: two first bytes of
1410 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
1411 the first eight bytes of PLAINTEXT mattered.  But alternative
1412 hashing schemes (like MD5), higher level security schemes (like C2),
1413 and implementations on non-Unix platforms may produce different
1414 strings.
1415
1416 When choosing a new salt create a random two character string whose
1417 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
1418 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
1419 characters is just a recommendation; the characters allowed in
1420 the salt depend solely on your system's crypt library, and Perl can't
1421 restrict what salts L<C<crypt>|/crypt PLAINTEXT,SALT> accepts.
1422
1423 Here's an example that makes sure that whoever runs this program knows
1424 their password:
1425
1426     my $pwd = (getpwuid($<))[1];
1427
1428     system "stty -echo";
1429     print "Password: ";
1430     chomp(my $word = <STDIN>);
1431     print "\n";
1432     system "stty echo";
1433
1434     if (crypt($word, $pwd) ne $pwd) {
1435         die "Sorry...\n";
1436     } else {
1437         print "ok\n";
1438     }
1439
1440 Of course, typing in your own password to whoever asks you
1441 for it is unwise.
1442
1443 The L<C<crypt>|/crypt PLAINTEXT,SALT> function is unsuitable for hashing
1444 large quantities of data, not least of all because you can't get the
1445 information back.  Look at the L<Digest> module for more robust
1446 algorithms.
1447
1448 If using L<C<crypt>|/crypt PLAINTEXT,SALT> on a Unicode string (which
1449 I<potentially> has characters with codepoints above 255), Perl tries to
1450 make sense of the situation by trying to downgrade (a copy of) the
1451 string back to an eight-bit byte string before calling
1452 L<C<crypt>|/crypt PLAINTEXT,SALT> (on that copy).  If that works, good.
1453 If not, L<C<crypt>|/crypt PLAINTEXT,SALT> dies with
1454 L<C<Wide character in crypt>|perldiag/Wide character in %s>.
1455
1456 Portability issues: L<perlport/crypt>.
1457
1458 =item dbmclose HASH
1459 X<dbmclose>
1460
1461 =for Pod::Functions breaks binding on a tied dbm file
1462
1463 [This function has been largely superseded by the
1464 L<C<untie>|/untie VARIABLE> function.]
1465
1466 Breaks the binding between a DBM file and a hash.
1467
1468 Portability issues: L<perlport/dbmclose>.
1469
1470 =item dbmopen HASH,DBNAME,MASK
1471 X<dbmopen> X<dbm> X<ndbm> X<sdbm> X<gdbm>
1472
1473 =for Pod::Functions create binding on a tied dbm file
1474
1475 [This function has been largely superseded by the
1476 L<C<tie>|/tie VARIABLE,CLASSNAME,LIST> function.]
1477
1478 This binds a L<dbm(3)>, L<ndbm(3)>, L<sdbm(3)>, L<gdbm(3)>, or Berkeley
1479 DB file to a hash.  HASH is the name of the hash.  (Unlike normal
1480 L<C<open>|/open FILEHANDLE,EXPR>, the first argument is I<not> a
1481 filehandle, even though it looks like one).  DBNAME is the name of the
1482 database (without the F<.dir> or F<.pag> extension if any).  If the
1483 database does not exist, it is created with protection specified by MASK
1484 (as modified by the L<C<umask>|/umask EXPR>).  To prevent creation of
1485 the database if it doesn't exist, you may specify a MODE of 0, and the
1486 function will return a false value if it can't find an existing
1487 database.  If your system supports only the older DBM functions, you may
1488 make only one L<C<dbmopen>|/dbmopen HASH,DBNAME,MASK> call in your
1489 program.  In older versions of Perl, if your system had neither DBM nor
1490 ndbm, calling L<C<dbmopen>|/dbmopen HASH,DBNAME,MASK> produced a fatal
1491 error; it now falls back to L<sdbm(3)>.
1492
1493 If you don't have write access to the DBM file, you can only read hash
1494 variables, not set them.  If you want to test whether you can write,
1495 either use file tests or try setting a dummy hash entry inside an
1496 L<C<eval>|/eval EXPR> to trap the error.
1497
1498 Note that functions such as L<C<keys>|/keys HASH> and
1499 L<C<values>|/values HASH> may return huge lists when used on large DBM
1500 files.  You may prefer to use the L<C<each>|/each HASH> function to
1501 iterate over large DBM files.  Example:
1502
1503     # print out history file offsets
1504     dbmopen(%HIST,'/usr/lib/news/history',0666);
1505     while (($key,$val) = each %HIST) {
1506         print $key, ' = ', unpack('L',$val), "\n";
1507     }
1508     dbmclose(%HIST);
1509
1510 See also L<AnyDBM_File> for a more general description of the pros and
1511 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1512 rich implementation.
1513
1514 You can control which DBM library you use by loading that library
1515 before you call L<C<dbmopen>|/dbmopen HASH,DBNAME,MASK>:
1516
1517     use DB_File;
1518     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1519         or die "Can't open netscape history file: $!";
1520
1521 Portability issues: L<perlport/dbmopen>.
1522
1523 =item defined EXPR
1524 X<defined> X<undef> X<undefined>
1525
1526 =item defined
1527
1528 =for Pod::Functions test whether a value, variable, or function is defined
1529
1530 Returns a Boolean value telling whether EXPR has a value other than the
1531 undefined value L<C<undef>|/undef EXPR>.  If EXPR is not present,
1532 L<C<$_>|perlvar/$_> is checked.
1533
1534 Many operations return L<C<undef>|/undef EXPR> to indicate failure, end
1535 of file, system error, uninitialized variable, and other exceptional
1536 conditions.  This function allows you to distinguish
1537 L<C<undef>|/undef EXPR> from other values.  (A simple Boolean test will
1538 not distinguish among L<C<undef>|/undef EXPR>, zero, the empty string,
1539 and C<"0">, which are all equally false.)  Note that since
1540 L<C<undef>|/undef EXPR> is a valid scalar, its presence doesn't
1541 I<necessarily> indicate an exceptional condition: L<C<pop>|/pop ARRAY>
1542 returns L<C<undef>|/undef EXPR> when its argument is an empty array,
1543 I<or> when the element to return happens to be L<C<undef>|/undef EXPR>.
1544
1545 You may also use C<defined(&func)> to check whether subroutine C<func>
1546 has ever been defined.  The return value is unaffected by any forward
1547 declarations of C<func>.  A subroutine that is not defined
1548 may still be callable: its package may have an C<AUTOLOAD> method that
1549 makes it spring into existence the first time that it is called; see
1550 L<perlsub>.
1551
1552 Use of L<C<defined>|/defined EXPR> on aggregates (hashes and arrays) is
1553 no longer supported. It used to report whether memory for that
1554 aggregate had ever been allocated.  You should instead use a simple
1555 test for size:
1556
1557     if (@an_array) { print "has array elements\n" }
1558     if (%a_hash)   { print "has hash members\n"   }
1559
1560 When used on a hash element, it tells you whether the value is defined,
1561 not whether the key exists in the hash.  Use L<C<exists>|/exists EXPR>
1562 for the latter purpose.
1563
1564 Examples:
1565
1566     print if defined $switch{D};
1567     print "$val\n" while defined($val = pop(@ary));
1568     die "Can't readlink $sym: $!"
1569         unless defined($value = readlink $sym);
1570     sub foo { defined &$bar ? $bar->(@_) : die "No bar"; }
1571     $debugging = 0 unless defined $debugging;
1572
1573 Note:  Many folks tend to overuse L<C<defined>|/defined EXPR> and are
1574 then surprised to discover that the number C<0> and C<""> (the
1575 zero-length string) are, in fact, defined values.  For example, if you
1576 say
1577
1578     "ab" =~ /a(.*)b/;
1579
1580 The pattern match succeeds and C<$1> is defined, although it
1581 matched "nothing".  It didn't really fail to match anything.  Rather, it
1582 matched something that happened to be zero characters long.  This is all
1583 very above-board and honest.  When a function returns an undefined value,
1584 it's an admission that it couldn't give you an honest answer.  So you
1585 should use L<C<defined>|/defined EXPR> only when questioning the
1586 integrity of what you're trying to do.  At other times, a simple
1587 comparison to C<0> or C<""> is what you want.
1588
1589 See also L<C<undef>|/undef EXPR>, L<C<exists>|/exists EXPR>,
1590 L<C<ref>|/ref EXPR>.
1591
1592 =item delete EXPR
1593 X<delete>
1594
1595 =for Pod::Functions deletes a value from a hash
1596
1597 Given an expression that specifies an element or slice of a hash,
1598 L<C<delete>|/delete EXPR> deletes the specified elements from that hash
1599 so that L<C<exists>|/exists EXPR> on that element no longer returns
1600 true.  Setting a hash element to the undefined value does not remove its
1601 key, but deleting it does; see L<C<exists>|/exists EXPR>.
1602
1603 In list context, usually returns the value or values deleted, or the last such
1604 element in scalar context.  The return list's length corresponds to that of
1605 the argument list: deleting non-existent elements returns the undefined value
1606 in their corresponding positions. When a
1607 L<keyE<sol>value hash slice|perldata/KeyE<sol>Value Hash Slices> is passed to
1608 C<delete>, the return value is a list of key/value pairs (two elements for each
1609 item deleted from the hash).
1610
1611 L<C<delete>|/delete EXPR> may also be used on arrays and array slices,
1612 but its behavior is less straightforward.  Although
1613 L<C<exists>|/exists EXPR> will return false for deleted entries,
1614 deleting array elements never changes indices of existing values; use
1615 L<C<shift>|/shift ARRAY> or L<C<splice>|/splice
1616 ARRAY,OFFSET,LENGTH,LIST> for that.  However, if any deleted elements
1617 fall at the end of an array, the array's size shrinks to the position of
1618 the highest element that still tests true for L<C<exists>|/exists EXPR>,
1619 or to 0 if none do.  In other words, an array won't have trailing
1620 nonexistent elements after a delete.
1621
1622 B<WARNING:> Calling L<C<delete>|/delete EXPR> on array values is
1623 strongly discouraged.  The
1624 notion of deleting or checking the existence of Perl array elements is not
1625 conceptually coherent, and can lead to surprising behavior.
1626
1627 Deleting from L<C<%ENV>|perlvar/%ENV> modifies the environment.
1628 Deleting from a hash tied to a DBM file deletes the entry from the DBM
1629 file.  Deleting from a L<C<tied>|/tied VARIABLE> hash or array may not
1630 necessarily return anything; it depends on the implementation of the
1631 L<C<tied>|/tied VARIABLE> package's DELETE method, which may do whatever
1632 it pleases.
1633
1634 The C<delete local EXPR> construct localizes the deletion to the current
1635 block at run time.  Until the block exits, elements locally deleted
1636 temporarily no longer exist.  See L<perlsub/"Localized deletion of elements
1637 of composite types">.
1638
1639     my %hash = (foo => 11, bar => 22, baz => 33);
1640     my $scalar = delete $hash{foo};         # $scalar is 11
1641     $scalar = delete @hash{qw(foo bar)}; # $scalar is 22
1642     my @array  = delete @hash{qw(foo baz)}; # @array  is (undef,33)
1643
1644 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1645
1646     foreach my $key (keys %HASH) {
1647         delete $HASH{$key};
1648     }
1649
1650     foreach my $index (0 .. $#ARRAY) {
1651         delete $ARRAY[$index];
1652     }
1653
1654 And so do these:
1655
1656     delete @HASH{keys %HASH};
1657
1658     delete @ARRAY[0 .. $#ARRAY];
1659
1660 But both are slower than assigning the empty list
1661 or undefining %HASH or @ARRAY, which is the customary
1662 way to empty out an aggregate:
1663
1664     %HASH = ();     # completely empty %HASH
1665     undef %HASH;    # forget %HASH ever existed
1666
1667     @ARRAY = ();    # completely empty @ARRAY
1668     undef @ARRAY;   # forget @ARRAY ever existed
1669
1670 The EXPR can be arbitrarily complicated provided its
1671 final operation is an element or slice of an aggregate:
1672
1673     delete $ref->[$x][$y]{$key};
1674     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1675
1676     delete $ref->[$x][$y][$index];
1677     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1678
1679 =item die LIST
1680 X<die> X<throw> X<exception> X<raise> X<$@> X<abort>
1681
1682 =for Pod::Functions raise an exception or bail out
1683
1684 L<C<die>|/die LIST> raises an exception.  Inside an L<C<eval>|/eval EXPR>
1685 the exception is stuffed into L<C<$@>|perlvar/$@> and the L<C<eval>|/eval
1686 EXPR> is terminated with the undefined value.  If the exception is
1687 outside of all enclosing L<C<eval>|/eval EXPR>s, then the uncaught
1688 exception is printed to C<STDERR> and perl exits with an exit code
1689 indicating failure.  If you need to exit the process with a specific
1690 exit code, see L<C<exit>|/exit EXPR>.
1691
1692 Equivalent examples:
1693
1694     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1695     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1696
1697 Most of the time, C<die> is called with a string to use as the exception.
1698 You may either give a single non-reference operand to serve as the
1699 exception, or a list of two or more items, which will be stringified
1700 and concatenated to make the exception.
1701
1702 If the string exception does not end in a newline, the current
1703 script line number and input line number (if any) and a newline
1704 are appended to it.  Note that the "input line number" (also
1705 known as "chunk") is subject to whatever notion of "line" happens to
1706 be currently in effect, and is also available as the special variable
1707 L<C<$.>|perlvar/$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1708
1709 Hint: sometimes appending C<", stopped"> to your message will cause it
1710 to make better sense when the string C<"at foo line 123"> is appended.
1711 Suppose you are running script "canasta".
1712
1713     die "/etc/games is no good";
1714     die "/etc/games is no good, stopped";
1715
1716 produce, respectively
1717
1718     /etc/games is no good at canasta line 123.
1719     /etc/games is no good, stopped at canasta line 123.
1720
1721 If LIST was empty or made an empty string, and L<C<$@>|perlvar/$@>
1722 already contains an exception value (typically from a previous
1723 L<C<eval>|/eval EXPR>), then that value is reused after
1724 appending C<"\t...propagated">.  This is useful for propagating exceptions:
1725
1726     eval { ... };
1727     die unless $@ =~ /Expected exception/;
1728
1729 If LIST was empty or made an empty string,
1730 and L<C<$@>|perlvar/$@> contains an object
1731 reference that has a C<PROPAGATE> method, that method will be called
1732 with additional file and line number parameters.  The return value
1733 replaces the value in L<C<$@>|perlvar/$@>;  i.e., as if
1734 C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >> were called.
1735
1736 If LIST was empty or made an empty string, and L<C<$@>|perlvar/$@>
1737 is also empty, then the string C<"Died"> is used.
1738
1739 You can also call L<C<die>|/die LIST> with a reference argument, and if
1740 this is trapped within an L<C<eval>|/eval EXPR>, L<C<$@>|perlvar/$@>
1741 contains that reference.  This permits more elaborate exception handling
1742 using objects that maintain arbitrary state about the exception.  Such a
1743 scheme is sometimes preferable to matching particular string values of
1744 L<C<$@>|perlvar/$@> with regular expressions.
1745
1746 Because Perl stringifies uncaught exception messages before display,
1747 you'll probably want to overload stringification operations on
1748 exception objects.  See L<overload> for details about that.
1749 The stringified message should be non-empty, and should end in a newline,
1750 in order to fit in with the treatment of string exceptions.
1751 Also, because an exception object reference cannot be stringified
1752 without destroying it, Perl doesn't attempt to append location or other
1753 information to a reference exception.  If you want location information
1754 with a complex exception object, you'll have to arrange to put the
1755 location information into the object yourself.
1756
1757 Because L<C<$@>|perlvar/$@> is a global variable, be careful that
1758 analyzing an exception caught by C<eval> doesn't replace the reference
1759 in the global variable.  It's
1760 easiest to make a local copy of the reference before any manipulations.
1761 Here's an example:
1762
1763     use Scalar::Util "blessed";
1764
1765     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1766     if (my $ev_err = $@) {
1767         if (blessed($ev_err)
1768             && $ev_err->isa("Some::Module::Exception")) {
1769             # handle Some::Module::Exception
1770         }
1771         else {
1772             # handle all other possible exceptions
1773         }
1774     }
1775
1776 If an uncaught exception results in interpreter exit, the exit code is
1777 determined from the values of L<C<$!>|perlvar/$!> and
1778 L<C<$?>|perlvar/$?> with this pseudocode:
1779
1780     exit $! if $!;              # errno
1781     exit $? >> 8 if $? >> 8;    # child exit status
1782     exit 255;                   # last resort
1783
1784 As with L<C<exit>|/exit EXPR>, L<C<$?>|perlvar/$?> is set prior to
1785 unwinding the call stack; any C<DESTROY> or C<END> handlers can then
1786 alter this value, and thus Perl's exit code.
1787
1788 The intent is to squeeze as much possible information about the likely cause
1789 into the limited space of the system exit code.  However, as
1790 L<C<$!>|perlvar/$!> is the value of C's C<errno>, which can be set by
1791 any system call, this means that the value of the exit code used by
1792 L<C<die>|/die LIST> can be non-predictable, so should not be relied
1793 upon, other than to be non-zero.
1794
1795 You can arrange for a callback to be run just before the
1796 L<C<die>|/die LIST> does its deed, by setting the
1797 L<C<$SIG{__DIE__}>|perlvar/%SIG> hook.  The associated handler is called
1798 with the exception as an argument, and can change the exception,
1799 if it sees fit, by
1800 calling L<C<die>|/die LIST> again.  See L<perlvar/%SIG> for details on
1801 setting L<C<%SIG>|perlvar/%SIG> entries, and L<C<eval>|/eval EXPR> for some
1802 examples.  Although this feature was to be run only right before your
1803 program was to exit, this is not currently so: the
1804 L<C<$SIG{__DIE__}>|perlvar/%SIG> hook is currently called even inside
1805 L<C<eval>|/eval EXPR>ed blocks/strings!  If one wants the hook to do
1806 nothing in such situations, put
1807
1808     die @_ if $^S;
1809
1810 as the first line of the handler (see L<perlvar/$^S>).  Because
1811 this promotes strange action at a distance, this counterintuitive
1812 behavior may be fixed in a future release.
1813
1814 See also L<C<exit>|/exit EXPR>, L<C<warn>|/warn LIST>, and the L<Carp>
1815 module.
1816
1817 =item do BLOCK
1818 X<do> X<block>
1819
1820 =for Pod::Functions turn a BLOCK into a TERM
1821
1822 Not really a function.  Returns the value of the last command in the
1823 sequence of commands indicated by BLOCK.  When modified by the C<while> or
1824 C<until> loop modifier, executes the BLOCK once before testing the loop
1825 condition.  (On other statements the loop modifiers test the conditional
1826 first.)
1827
1828 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1829 L<C<next>|/next LABEL>, L<C<last>|/last LABEL>, or
1830 L<C<redo>|/redo LABEL> cannot be used to leave or restart the block.
1831 See L<perlsyn> for alternative strategies.
1832
1833 =item do EXPR
1834 X<do>
1835
1836 Uses the value of EXPR as a filename and executes the contents of the
1837 file as a Perl script:
1838
1839     # load the exact specified file (./ and ../ special-cased)
1840     do '/foo/stat.pl';
1841     do './stat.pl';
1842     do '../foo/stat.pl';
1843
1844     # search for the named file within @INC
1845     do 'stat.pl';
1846     do 'foo/stat.pl';
1847
1848 C<do './stat.pl'> is largely like
1849
1850     eval `cat stat.pl`;
1851
1852 except that it's more concise, runs no external processes, and keeps
1853 track of the current filename for error messages. It also differs in that
1854 code evaluated with C<do FILE> cannot see lexicals in the enclosing
1855 scope; C<eval STRING> does.  It's the same, however, in that it does
1856 reparse the file every time you call it, so you probably don't want
1857 to do this inside a loop.
1858
1859 Using C<do> with a relative path (except for F<./> and F<../>), like
1860
1861     do 'foo/stat.pl';
1862
1863 will search the L<C<@INC>|perlvar/@INC> directories, and update
1864 L<C<%INC>|perlvar/%INC> if the file is found.  See L<perlvar/@INC>
1865 and L<perlvar/%INC> for these variables. In particular, note that
1866 whilst historically L<C<@INC>|perlvar/@INC> contained '.' (the
1867 current directory) making these two cases equivalent, that is no
1868 longer necessarily the case, as '.' is not included in C<@INC> by default
1869 in perl versions 5.26.0 onwards. Instead, perl will now warn:
1870
1871     do "stat.pl" failed, '.' is no longer in @INC;
1872     did you mean do "./stat.pl"?
1873
1874 If L<C<do>|/do EXPR> can read the file but cannot compile it, it
1875 returns L<C<undef>|/undef EXPR> and sets an error message in
1876 L<C<$@>|perlvar/$@>.  If L<C<do>|/do EXPR> cannot read the file, it
1877 returns undef and sets L<C<$!>|perlvar/$!> to the error.  Always check
1878 L<C<$@>|perlvar/$@> first, as compilation could fail in a way that also
1879 sets L<C<$!>|perlvar/$!>.  If the file is successfully compiled,
1880 L<C<do>|/do EXPR> returns the value of the last expression evaluated.
1881
1882 Inclusion of library modules is better done with the
1883 L<C<use>|/use Module VERSION LIST> and L<C<require>|/require VERSION>
1884 operators, which also do automatic error checking and raise an exception
1885 if there's a problem.
1886
1887 You might like to use L<C<do>|/do EXPR> to read in a program
1888 configuration file.  Manual error checking can be done this way:
1889
1890     # Read in config files: system first, then user.
1891     # Beware of using relative pathnames here.
1892     for $file ("/share/prog/defaults.rc",
1893                "$ENV{HOME}/.someprogrc")
1894     {
1895         unless ($return = do $file) {
1896             warn "couldn't parse $file: $@" if $@;
1897             warn "couldn't do $file: $!"    unless defined $return;
1898             warn "couldn't run $file"       unless $return;
1899         }
1900     }
1901
1902 =item dump LABEL
1903 X<dump> X<core> X<undump>
1904
1905 =item dump EXPR
1906
1907 =item dump
1908
1909 =for Pod::Functions create an immediate core dump
1910
1911 This function causes an immediate core dump.  See also the B<-u>
1912 command-line switch in L<perlrun|perlrun/-u>, which does the same thing.
1913 Primarily this is so that you can use the B<undump> program (not
1914 supplied) to turn your core dump into an executable binary after
1915 having initialized all your variables at the beginning of the
1916 program.  When the new binary is executed it will begin by executing
1917 a C<goto LABEL> (with all the restrictions that L<C<goto>|/goto LABEL>
1918 suffers).
1919 Think of it as a goto with an intervening core dump and reincarnation.
1920 If C<LABEL> is omitted, restarts the program from the top.  The
1921 C<dump EXPR> form, available starting in Perl 5.18.0, allows a name to be
1922 computed at run time, being otherwise identical to C<dump LABEL>.
1923
1924 B<WARNING>: Any files opened at the time of the dump will I<not>
1925 be open any more when the program is reincarnated, with possible
1926 resulting confusion by Perl.
1927
1928 This function is now largely obsolete, mostly because it's very hard to
1929 convert a core file into an executable.  As of Perl 5.30, it must be invoked
1930 as C<CORE::dump()>.
1931
1932 Unlike most named operators, this has the same precedence as assignment.
1933 It is also exempt from the looks-like-a-function rule, so
1934 C<dump ("foo")."bar"> will cause "bar" to be part of the argument to
1935 L<C<dump>|/dump LABEL>.
1936
1937 Portability issues: L<perlport/dump>.
1938
1939 =item each HASH
1940 X<each> X<hash, iterator>
1941
1942 =item each ARRAY
1943 X<array, iterator>
1944
1945 =for Pod::Functions retrieve the next key/value pair from a hash
1946
1947 When called on a hash in list context, returns a 2-element list
1948 consisting of the key and value for the next element of a hash.  In Perl
1949 5.12 and later only, it will also return the index and value for the next
1950 element of an array so that you can iterate over it; older Perls consider
1951 this a syntax error.  When called in scalar context, returns only the key
1952 (not the value) in a hash, or the index in an array.
1953
1954 Hash entries are returned in an apparently random order.  The actual random
1955 order is specific to a given hash; the exact same series of operations
1956 on two hashes may result in a different order for each hash.  Any insertion
1957 into the hash may change the order, as will any deletion, with the exception
1958 that the most recent key returned by L<C<each>|/each HASH> or
1959 L<C<keys>|/keys HASH> may be deleted without changing the order.  So
1960 long as a given hash is unmodified you may rely on
1961 L<C<keys>|/keys HASH>, L<C<values>|/values HASH> and
1962 L<C<each>|/each HASH> to repeatedly return the same order
1963 as each other.  See L<perlsec/"Algorithmic Complexity Attacks"> for
1964 details on why hash order is randomized.  Aside from the guarantees
1965 provided here the exact details of Perl's hash algorithm and the hash
1966 traversal order are subject to change in any release of Perl.
1967
1968 After L<C<each>|/each HASH> has returned all entries from the hash or
1969 array, the next call to L<C<each>|/each HASH> returns the empty list in
1970 list context and L<C<undef>|/undef EXPR> in scalar context; the next
1971 call following I<that> one restarts iteration.  Each hash or array has
1972 its own internal iterator, accessed by L<C<each>|/each HASH>,
1973 L<C<keys>|/keys HASH>, and L<C<values>|/values HASH>.  The iterator is
1974 implicitly reset when L<C<each>|/each HASH> has reached the end as just
1975 described; it can be explicitly reset by calling L<C<keys>|/keys HASH>
1976 or L<C<values>|/values HASH> on the hash or array, or by referencing
1977 the hash (but not array) in list context.  If you add or delete
1978 a hash's elements while iterating over it, the effect on the iterator is
1979 unspecified; for example, entries may be skipped or duplicated--so don't
1980 do that.  Exception: It is always safe to delete the item most recently
1981 returned by L<C<each>|/each HASH>, so the following code works properly:
1982
1983     while (my ($key, $value) = each %hash) {
1984         print $key, "\n";
1985         delete $hash{$key};   # This is safe
1986     }
1987
1988 Tied hashes may have a different ordering behaviour to perl's hash
1989 implementation.
1990
1991 The iterator used by C<each> is attached to the hash or array, and is
1992 shared between all iteration operations applied to the same hash or array.
1993 Thus all uses of C<each> on a single hash or array advance the same
1994 iterator location.  All uses of C<each> are also subject to having the
1995 iterator reset by any use of C<keys> or C<values> on the same hash or
1996 array, or by the hash (but not array) being referenced in list context.
1997 This makes C<each>-based loops quite fragile: it is easy to arrive at
1998 such a loop with the iterator already part way through the object, or to
1999 accidentally clobber the iterator state during execution of the loop body.
2000 It's easy enough to explicitly reset the iterator before starting a loop,
2001 but there is no way to insulate the iterator state used by a loop from
2002 the iterator state used by anything else that might execute during the
2003 loop body.  To avoid these problems, use a C<foreach> loop rather than
2004 C<while>-C<each>.
2005
2006 This prints out your environment like the L<printenv(1)> program,
2007 but in a different order:
2008
2009     while (my ($key,$value) = each %ENV) {
2010         print "$key=$value\n";
2011     }
2012
2013 Starting with Perl 5.14, an experimental feature allowed
2014 L<C<each>|/each HASH> to take a scalar expression. This experiment has
2015 been deemed unsuccessful, and was removed as of Perl 5.24.
2016
2017 As of Perl 5.18 you can use a bare L<C<each>|/each HASH> in a C<while>
2018 loop, which will set L<C<$_>|perlvar/$_> on every iteration.
2019 If either an C<each> expression or an explicit assignment of an C<each>
2020 expression to a scalar is used as a C<while>/C<for> condition, then
2021 the condition actually tests for definedness of the expression's value,
2022 not for its regular truth value.
2023
2024     while (each %ENV) {
2025         print "$_=$ENV{$_}\n";
2026     }
2027
2028 To avoid confusing would-be users of your code who are running earlier
2029 versions of Perl with mysterious syntax errors, put this sort of thing at
2030 the top of your file to signal that your code will work I<only> on Perls of
2031 a recent vintage:
2032
2033     use 5.012;  # so keys/values/each work on arrays
2034     use 5.018;  # so each assigns to $_ in a lone while test
2035
2036 See also L<C<keys>|/keys HASH>, L<C<values>|/values HASH>, and
2037 L<C<sort>|/sort SUBNAME LIST>.
2038
2039 =item eof FILEHANDLE
2040 X<eof>
2041 X<end of file>
2042 X<end-of-file>
2043
2044 =item eof ()
2045
2046 =item eof
2047
2048 =for Pod::Functions test a filehandle for its end
2049
2050 Returns 1 if the next read on FILEHANDLE will return end of file I<or> if
2051 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
2052 gives the real filehandle.  (Note that this function actually
2053 reads a character and then C<ungetc>s it, so isn't useful in an
2054 interactive context.)  Do not read from a terminal file (or call
2055 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
2056 as terminals may lose the end-of-file condition if you do.
2057
2058 An L<C<eof>|/eof FILEHANDLE> without an argument uses the last file
2059 read.  Using L<C<eof()>|/eof FILEHANDLE> with empty parentheses is
2060 different.  It refers to the pseudo file formed from the files listed on
2061 the command line and accessed via the C<< <> >> operator.  Since
2062 C<< <> >> isn't explicitly opened, as a normal filehandle is, an
2063 L<C<eof()>|/eof FILEHANDLE> before C<< <> >> has been used will cause
2064 L<C<@ARGV>|perlvar/@ARGV> to be examined to determine if input is
2065 available.   Similarly, an L<C<eof()>|/eof FILEHANDLE> after C<< <> >>
2066 has returned end-of-file will assume you are processing another
2067 L<C<@ARGV>|perlvar/@ARGV> list, and if you haven't set
2068 L<C<@ARGV>|perlvar/@ARGV>, will read input from C<STDIN>; see
2069 L<perlop/"I/O Operators">.
2070
2071 In a C<< while (<>) >> loop, L<C<eof>|/eof FILEHANDLE> or C<eof(ARGV)>
2072 can be used to detect the end of each file, whereas
2073 L<C<eof()>|/eof FILEHANDLE> will detect the end of the very last file
2074 only.  Examples:
2075
2076     # reset line numbering on each input file
2077     while (<>) {
2078         next if /^\s*#/;  # skip comments
2079         print "$.\t$_";
2080     } continue {
2081         close ARGV if eof;  # Not eof()!
2082     }
2083
2084     # insert dashes just before last line of last file
2085     while (<>) {
2086         if (eof()) {  # check for end of last file
2087             print "--------------\n";
2088         }
2089         print;
2090         last if eof();     # needed if we're reading from a terminal
2091     }
2092
2093 Practical hint: you almost never need to use L<C<eof>|/eof FILEHANDLE>
2094 in Perl, because the input operators typically return L<C<undef>|/undef
2095 EXPR> when they run out of data or encounter an error.
2096
2097 =item eval EXPR
2098 X<eval> X<try> X<catch> X<evaluate> X<parse> X<execute>
2099 X<error, handling> X<exception, handling>
2100
2101 =item eval BLOCK
2102
2103 =item eval
2104
2105 =for Pod::Functions catch exceptions or compile and run code
2106
2107 C<eval> in all its forms is used to execute a little Perl program,
2108 trapping any errors encountered so they don't crash the calling program.
2109
2110 Plain C<eval> with no argument is just C<eval EXPR>, where the
2111 expression is understood to be contained in L<C<$_>|perlvar/$_>.  Thus
2112 there are only two real C<eval> forms; the one with an EXPR is often
2113 called "string eval".  In a string eval, the value of the expression
2114 (which is itself determined within scalar context) is first parsed, and
2115 if there were no errors, executed as a block within the lexical context
2116 of the current Perl program.  This form is typically used to delay
2117 parsing and subsequent execution of the text of EXPR until run time.
2118 Note that the value is parsed every time the C<eval> executes.
2119
2120 The other form is called "block eval".  It is less general than string
2121 eval, but the code within the BLOCK is parsed only once (at the same
2122 time the code surrounding the C<eval> itself was parsed) and executed
2123 within the context of the current Perl program.  This form is typically
2124 used to trap exceptions more efficiently than the first, while also
2125 providing the benefit of checking the code within BLOCK at compile time.
2126 BLOCK is parsed and compiled just once.  Since errors are trapped, it
2127 often is used to check if a given feature is available.
2128
2129 In both forms, the value returned is the value of the last expression
2130 evaluated inside the mini-program; a return statement may also be used, just
2131 as with subroutines.  The expression providing the return value is evaluated
2132 in void, scalar, or list context, depending on the context of the
2133 C<eval> itself.  See L<C<wantarray>|/wantarray> for more
2134 on how the evaluation context can be determined.
2135
2136 If there is a syntax error or runtime error, or a L<C<die>|/die LIST>
2137 statement is executed, C<eval> returns
2138 L<C<undef>|/undef EXPR> in scalar context, or an empty list in list
2139 context, and L<C<$@>|perlvar/$@> is set to the error message.  (Prior to
2140 5.16, a bug caused L<C<undef>|/undef EXPR> to be returned in list
2141 context for syntax errors, but not for runtime errors.) If there was no
2142 error, L<C<$@>|perlvar/$@> is set to the empty string.  A control flow
2143 operator like L<C<last>|/last LABEL> or L<C<goto>|/goto LABEL> can
2144 bypass the setting of L<C<$@>|perlvar/$@>.  Beware that using
2145 C<eval> neither silences Perl from printing warnings to
2146 STDERR, nor does it stuff the text of warning messages into
2147 L<C<$@>|perlvar/$@>.  To do either of those, you have to use the
2148 L<C<$SIG{__WARN__}>|perlvar/%SIG> facility, or turn off warnings inside
2149 the BLOCK or EXPR using S<C<no warnings 'all'>>.  See
2150 L<C<warn>|/warn LIST>, L<perlvar>, and L<warnings>.
2151
2152 Note that, because C<eval> traps otherwise-fatal errors,
2153 it is useful for determining whether a particular feature (such as
2154 L<C<socket>|/socket SOCKET,DOMAIN,TYPE,PROTOCOL> or
2155 L<C<symlink>|/symlink OLDFILE,NEWFILE>) is implemented.  It is also
2156 Perl's exception-trapping mechanism, where the L<C<die>|/die LIST>
2157 operator is used to raise exceptions.
2158
2159 Before Perl 5.14, the assignment to L<C<$@>|perlvar/$@> occurred before
2160 restoration
2161 of localized variables, which means that for your code to run on older
2162 versions, a temporary is required if you want to mask some, but not all
2163 errors:
2164
2165  # alter $@ on nefarious repugnancy only
2166  {
2167     my $e;
2168     {
2169       local $@; # protect existing $@
2170       eval { test_repugnancy() };
2171       # $@ =~ /nefarious/ and die $@; # Perl 5.14 and higher only
2172       $@ =~ /nefarious/ and $e = $@;
2173     }
2174     die $e if defined $e
2175  }
2176
2177 There are some different considerations for each form:
2178
2179 =over 4
2180
2181 =item String eval
2182
2183 Since the return value of EXPR is executed as a block within the lexical
2184 context of the current Perl program, any outer lexical variables are
2185 visible to it, and any package variable settings or subroutine and
2186 format definitions remain afterwards.
2187
2188 =over 4
2189
2190 =item Under the L<C<"unicode_eval"> feature|feature/The 'unicode_eval' and 'evalbytes' features>
2191
2192 If this feature is enabled (which is the default under a C<use 5.16> or
2193 higher declaration), EXPR is considered to be
2194 in the same encoding as the surrounding program.  Thus if
2195 S<L<C<use utf8>|utf8>> is in effect, the string will be treated as being
2196 UTF-8 encoded.  Otherwise, the string is considered to be a sequence of
2197 independent bytes.  Bytes that correspond to ASCII-range code points
2198 will have their normal meanings for operators in the string.  The
2199 treatment of the other bytes depends on if the
2200 L<C<'unicode_strings"> feature|feature/The 'unicode_strings' feature> is
2201 in effect.
2202
2203 In a plain C<eval> without an EXPR argument, being in S<C<use utf8>> or
2204 not is irrelevant; the UTF-8ness of C<$_> itself determines the
2205 behavior.
2206
2207 Any S<C<use utf8>> or S<C<no utf8>> declarations within the string have
2208 no effect, and source filters are forbidden.  (C<unicode_strings>,
2209 however, can appear within the string.)  See also the
2210 L<C<evalbytes>|/evalbytes EXPR> operator, which works properly with
2211 source filters.
2212
2213 Variables defined outside the C<eval> and used inside it retain their
2214 original UTF-8ness.  Everything inside the string follows the normal
2215 rules for a Perl program with the given state of S<C<use utf8>>.
2216
2217 =item Outside the C<"unicode_eval"> feature
2218
2219 In this case, the behavior is problematic and is not so easily
2220 described.  Here are two bugs that cannot easily be fixed without
2221 breaking existing programs:
2222
2223 =over 4
2224
2225 =item *
2226
2227 It can lose track of whether something should be encoded as UTF-8 or
2228 not.
2229
2230 =item *
2231
2232 Source filters activated within C<eval> leak out into whichever file
2233 scope is currently being compiled.  To give an example with the CPAN module
2234 L<Semi::Semicolons>:
2235
2236  BEGIN { eval "use Semi::Semicolons; # not filtered" }
2237  # filtered here!
2238
2239 L<C<evalbytes>|/evalbytes EXPR> fixes that to work the way one would
2240 expect:
2241
2242  use feature "evalbytes";
2243  BEGIN { evalbytes "use Semi::Semicolons; # filtered" }
2244  # not filtered
2245
2246 =back
2247
2248 =back
2249
2250 Problems can arise if the string expands a scalar containing a floating
2251 point number.  That scalar can expand to letters, such as C<"NaN"> or
2252 C<"Infinity">; or, within the scope of a L<C<use locale>|locale>, the
2253 decimal point character may be something other than a dot (such as a
2254 comma).  None of these are likely to parse as you are likely expecting.
2255
2256 You should be especially careful to remember what's being looked at
2257 when:
2258
2259     eval $x;        # CASE 1
2260     eval "$x";      # CASE 2
2261
2262     eval '$x';      # CASE 3
2263     eval { $x };    # CASE 4
2264
2265     eval "\$$x++";  # CASE 5
2266     $$x++;          # CASE 6
2267
2268 Cases 1 and 2 above behave identically: they run the code contained in
2269 the variable $x.  (Although case 2 has misleading double quotes making
2270 the reader wonder what else might be happening (nothing is).)  Cases 3
2271 and 4 likewise behave in the same way: they run the code C<'$x'>, which
2272 does nothing but return the value of $x.  (Case 4 is preferred for
2273 purely visual reasons, but it also has the advantage of compiling at
2274 compile-time instead of at run-time.)  Case 5 is a place where
2275 normally you I<would> like to use double quotes, except that in this
2276 particular situation, you can just use symbolic references instead, as
2277 in case 6.
2278
2279 An C<eval ''> executed within a subroutine defined
2280 in the C<DB> package doesn't see the usual
2281 surrounding lexical scope, but rather the scope of the first non-DB piece
2282 of code that called it.  You don't normally need to worry about this unless
2283 you are writing a Perl debugger.
2284
2285 The final semicolon, if any, may be omitted from the value of EXPR.
2286
2287 =item Block eval
2288
2289 If the code to be executed doesn't vary, you may use the eval-BLOCK
2290 form to trap run-time errors without incurring the penalty of
2291 recompiling each time.  The error, if any, is still returned in
2292 L<C<$@>|perlvar/$@>.
2293 Examples:
2294
2295     # make divide-by-zero nonfatal
2296     eval { $answer = $a / $b; }; warn $@ if $@;
2297
2298     # same thing, but less efficient
2299     eval '$answer = $a / $b'; warn $@ if $@;
2300
2301     # a compile-time error
2302     eval { $answer = }; # WRONG
2303
2304     # a run-time error
2305     eval '$answer =';   # sets $@
2306
2307 If you want to trap errors when loading an XS module, some problems with
2308 the binary interface (such as Perl version skew) may be fatal even with
2309 C<eval> unless C<$ENV{PERL_DL_NONLAZY}> is set.  See
2310 L<perlrun|perlrun/PERL_DL_NONLAZY>.
2311
2312 Using the C<eval {}> form as an exception trap in libraries does have some
2313 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
2314 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
2315 You can use the C<local $SIG{__DIE__}> construct for this purpose,
2316 as this example shows:
2317
2318     # a private exception trap for divide-by-zero
2319     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
2320     warn $@ if $@;
2321
2322 This is especially significant, given that C<__DIE__> hooks can call
2323 L<C<die>|/die LIST> again, which has the effect of changing their error
2324 messages:
2325
2326     # __DIE__ hooks may modify error messages
2327     {
2328        local $SIG{'__DIE__'} =
2329               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
2330        eval { die "foo lives here" };
2331        print $@ if $@;                # prints "bar lives here"
2332     }
2333
2334 Because this promotes action at a distance, this counterintuitive behavior
2335 may be fixed in a future release.
2336
2337 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
2338 L<C<next>|/next LABEL>, L<C<last>|/last LABEL>, or
2339 L<C<redo>|/redo LABEL> cannot be used to leave or restart the block.
2340
2341 The final semicolon, if any, may be omitted from within the BLOCK.
2342
2343 =back
2344
2345 =item evalbytes EXPR
2346 X<evalbytes>
2347
2348 =item evalbytes
2349
2350 =for Pod::Functions +evalbytes similar to string eval, but intend to parse a bytestream
2351
2352 This function is similar to a L<string eval|/eval EXPR>, except it
2353 always parses its argument (or L<C<$_>|perlvar/$_> if EXPR is omitted)
2354 as a string of independent bytes.
2355
2356 If called when S<C<use utf8>> is in effect, the string will be assumed
2357 to be encoded in UTF-8, and C<evalbytes> will make a temporary copy to
2358 work from, downgraded to non-UTF-8.  If this is not possible
2359 (because one or more characters in it require UTF-8), the C<evalbytes>
2360 will fail with the error stored in C<$@>.
2361
2362 Bytes that correspond to ASCII-range code points will have their normal
2363 meanings for operators in the string.  The treatment of the other bytes
2364 depends on if the L<C<'unicode_strings"> feature|feature/The
2365 'unicode_strings' feature> is in effect.
2366
2367 Of course, variables that are UTF-8 and are referred to in the string
2368 retain that:
2369
2370  my $a = "\x{100}";
2371  evalbytes 'print ord $a, "\n"';
2372
2373 prints
2374
2375  256
2376
2377 and C<$@> is empty.
2378
2379 Source filters activated within the evaluated code apply to the code
2380 itself.
2381
2382 L<C<evalbytes>|/evalbytes EXPR> is available starting in Perl v5.16.  To
2383 access it, you must say C<CORE::evalbytes>, but you can omit the
2384 C<CORE::> if the
2385 L<C<"evalbytes"> feature|feature/The 'unicode_eval' and 'evalbytes' features>
2386 is enabled.  This is enabled automatically with a C<use v5.16> (or
2387 higher) declaration in the current scope.
2388
2389 =item exec LIST
2390 X<exec> X<execute>
2391
2392 =item exec PROGRAM LIST
2393
2394 =for Pod::Functions abandon this program to run another
2395
2396 The L<C<exec>|/exec LIST> function executes a system command I<and never
2397 returns>; use L<C<system>|/system LIST> instead of L<C<exec>|/exec LIST>
2398 if you want it to return.  It fails and
2399 returns false only if the command does not exist I<and> it is executed
2400 directly instead of via your system's command shell (see below).
2401
2402 Since it's a common mistake to use L<C<exec>|/exec LIST> instead of
2403 L<C<system>|/system LIST>, Perl warns you if L<C<exec>|/exec LIST> is
2404 called in void context and if there is a following statement that isn't
2405 L<C<die>|/die LIST>, L<C<warn>|/warn LIST>, or L<C<exit>|/exit EXPR> (if
2406 L<warnings> are enabled--but you always do that, right?).  If you
2407 I<really> want to follow an L<C<exec>|/exec LIST> with some other
2408 statement, you can use one of these styles to avoid the warning:
2409
2410     exec ('foo')   or print STDERR "couldn't exec foo: $!";
2411     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
2412
2413 If there is more than one argument in LIST, this calls L<execvp(3)> with the
2414 arguments in LIST.  If there is only one element in LIST, the argument is
2415 checked for shell metacharacters, and if there are any, the entire
2416 argument is passed to the system's command shell for parsing (this is
2417 C</bin/sh -c> on Unix platforms, but varies on other platforms).  If
2418 there are no shell metacharacters in the argument, it is split into words
2419 and passed directly to C<execvp>, which is more efficient.  Examples:
2420
2421     exec '/bin/echo', 'Your arguments are: ', @ARGV;
2422     exec "sort $outfile | uniq";
2423
2424 If you don't really want to execute the first argument, but want to lie
2425 to the program you are executing about its own name, you can specify
2426 the program you actually want to run as an "indirect object" (without a
2427 comma) in front of the LIST, as in C<exec PROGRAM LIST>.  (This always
2428 forces interpretation of the LIST as a multivalued list, even if there
2429 is only a single scalar in the list.)  Example:
2430
2431     my $shell = '/bin/csh';
2432     exec $shell '-sh';    # pretend it's a login shell
2433
2434 or, more directly,
2435
2436     exec {'/bin/csh'} '-sh';  # pretend it's a login shell
2437
2438 When the arguments get executed via the system shell, results are
2439 subject to its quirks and capabilities.  See L<perlop/"`STRING`">
2440 for details.
2441
2442 Using an indirect object with L<C<exec>|/exec LIST> or
2443 L<C<system>|/system LIST> is also more secure.  This usage (which also
2444 works fine with L<C<system>|/system LIST>) forces
2445 interpretation of the arguments as a multivalued list, even if the
2446 list had just one argument.  That way you're safe from the shell
2447 expanding wildcards or splitting up words with whitespace in them.
2448
2449     my @args = ( "echo surprise" );
2450
2451     exec @args;               # subject to shell escapes
2452                                 # if @args == 1
2453     exec { $args[0] } @args;  # safe even with one-arg list
2454
2455 The first version, the one without the indirect object, ran the I<echo>
2456 program, passing it C<"surprise"> an argument.  The second version didn't;
2457 it tried to run a program named I<"echo surprise">, didn't find it, and set
2458 L<C<$?>|perlvar/$?> to a non-zero value indicating failure.
2459
2460 On Windows, only the C<exec PROGRAM LIST> indirect object syntax will
2461 reliably avoid using the shell; C<exec LIST>, even with more than one
2462 element, will fall back to the shell if the first spawn fails.
2463
2464 Perl attempts to flush all files opened for output before the exec,
2465 but this may not be supported on some platforms (see L<perlport>).
2466 To be safe, you may need to set L<C<$E<verbar>>|perlvar/$E<verbar>>
2467 (C<$AUTOFLUSH> in L<English>) or call the C<autoflush> method of
2468 L<C<IO::Handle>|IO::Handle/METHODS> on any open handles to avoid lost
2469 output.
2470
2471 Note that L<C<exec>|/exec LIST> will not call your C<END> blocks, nor
2472 will it invoke C<DESTROY> methods on your objects.
2473
2474 Portability issues: L<perlport/exec>.
2475
2476 =item exists EXPR
2477 X<exists> X<autovivification>
2478
2479 =for Pod::Functions test whether a hash key is present
2480
2481 Given an expression that specifies an element of a hash, returns true if the
2482 specified element in the hash has ever been initialized, even if the
2483 corresponding value is undefined.
2484
2485     print "Exists\n"    if exists $hash{$key};
2486     print "Defined\n"   if defined $hash{$key};
2487     print "True\n"      if $hash{$key};
2488
2489 exists may also be called on array elements, but its behavior is much less
2490 obvious and is strongly tied to the use of L<C<delete>|/delete EXPR> on
2491 arrays.
2492
2493 B<WARNING:> Calling L<C<exists>|/exists EXPR> on array values is
2494 strongly discouraged.  The
2495 notion of deleting or checking the existence of Perl array elements is not
2496 conceptually coherent, and can lead to surprising behavior.
2497
2498     print "Exists\n"    if exists $array[$index];
2499     print "Defined\n"   if defined $array[$index];
2500     print "True\n"      if $array[$index];
2501
2502 A hash or array element can be true only if it's defined and defined only if
2503 it exists, but the reverse doesn't necessarily hold true.
2504
2505 Given an expression that specifies the name of a subroutine,
2506 returns true if the specified subroutine has ever been declared, even
2507 if it is undefined.  Mentioning a subroutine name for exists or defined
2508 does not count as declaring it.  Note that a subroutine that does not
2509 exist may still be callable: its package may have an C<AUTOLOAD>
2510 method that makes it spring into existence the first time that it is
2511 called; see L<perlsub>.
2512
2513     print "Exists\n"  if exists &subroutine;
2514     print "Defined\n" if defined &subroutine;
2515
2516 Note that the EXPR can be arbitrarily complicated as long as the final
2517 operation is a hash or array key lookup or subroutine name:
2518
2519     if (exists $ref->{A}->{B}->{$key})  { }
2520     if (exists $hash{A}{B}{$key})       { }
2521
2522     if (exists $ref->{A}->{B}->[$ix])   { }
2523     if (exists $hash{A}{B}[$ix])        { }
2524
2525     if (exists &{$ref->{A}{B}{$key}})   { }
2526
2527 Although the most deeply nested array or hash element will not spring into
2528 existence just because its existence was tested, any intervening ones will.
2529 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
2530 into existence due to the existence test for the C<$key> element above.
2531 This happens anywhere the arrow operator is used, including even here:
2532
2533     undef $ref;
2534     if (exists $ref->{"Some key"})    { }
2535     print $ref;  # prints HASH(0x80d3d5c)
2536
2537 Use of a subroutine call, rather than a subroutine name, as an argument
2538 to L<C<exists>|/exists EXPR> is an error.
2539
2540     exists &sub;    # OK
2541     exists &sub();  # Error
2542
2543 =item exit EXPR
2544 X<exit> X<terminate> X<abort>
2545
2546 =item exit
2547
2548 =for Pod::Functions terminate this program
2549
2550 Evaluates EXPR and exits immediately with that value.    Example:
2551
2552     my $ans = <STDIN>;
2553     exit 0 if $ans =~ /^[Xx]/;
2554
2555 See also L<C<die>|/die LIST>.  If EXPR is omitted, exits with C<0>
2556 status.  The only
2557 universally recognized values for EXPR are C<0> for success and C<1>
2558 for error; other values are subject to interpretation depending on the
2559 environment in which the Perl program is running.  For example, exiting
2560 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
2561 the mailer to return the item undelivered, but that's not true everywhere.
2562
2563 Don't use L<C<exit>|/exit EXPR> to abort a subroutine if there's any
2564 chance that someone might want to trap whatever error happened.  Use
2565 L<C<die>|/die LIST> instead, which can be trapped by an
2566 L<C<eval>|/eval EXPR>.
2567
2568 The L<C<exit>|/exit EXPR> function does not always exit immediately.  It
2569 calls any defined C<END> routines first, but these C<END> routines may
2570 not themselves abort the exit.  Likewise any object destructors that
2571 need to be called are called before the real exit.  C<END> routines and
2572 destructors can change the exit status by modifying L<C<$?>|perlvar/$?>.
2573 If this is a problem, you can call
2574 L<C<POSIX::_exit($status)>|POSIX/C<_exit>> to avoid C<END> and destructor
2575 processing.  See L<perlmod> for details.
2576
2577 Portability issues: L<perlport/exit>.
2578
2579 =item exp EXPR
2580 X<exp> X<exponential> X<antilog> X<antilogarithm> X<e>
2581
2582 =item exp
2583
2584 =for Pod::Functions raise I<e> to a power
2585
2586 Returns I<e> (the natural logarithm base) to the power of EXPR.
2587 If EXPR is omitted, gives C<exp($_)>.
2588
2589 =item fc EXPR
2590 X<fc> X<foldcase> X<casefold> X<fold-case> X<case-fold>
2591
2592 =item fc
2593
2594 =for Pod::Functions +fc return casefolded version of a string
2595
2596 Returns the casefolded version of EXPR.  This is the internal function
2597 implementing the C<\F> escape in double-quoted strings.
2598
2599 Casefolding is the process of mapping strings to a form where case
2600 differences are erased; comparing two strings in their casefolded
2601 form is effectively a way of asking if two strings are equal,
2602 regardless of case.
2603
2604 Roughly, if you ever found yourself writing this
2605
2606     lc($this) eq lc($that)    # Wrong!
2607         # or
2608     uc($this) eq uc($that)    # Also wrong!
2609         # or
2610     $this =~ /^\Q$that\E\z/i  # Right!
2611
2612 Now you can write
2613
2614     fc($this) eq fc($that)
2615
2616 And get the correct results.
2617
2618 Perl only implements the full form of casefolding, but you can access
2619 the simple folds using L<Unicode::UCD/B<casefold()>> and
2620 L<Unicode::UCD/B<prop_invmap()>>.
2621 For further information on casefolding, refer to
2622 the Unicode Standard, specifically sections 3.13 C<Default Case Operations>,
2623 4.2 C<Case-Normative>, and 5.18 C<Case Mappings>,
2624 available at L<https://www.unicode.org/versions/latest/>, as well as the
2625 Case Charts available at L<https://www.unicode.org/charts/case/>.
2626
2627 If EXPR is omitted, uses L<C<$_>|perlvar/$_>.
2628
2629 This function behaves the same way under various pragmas, such as within
2630 L<S<C<"use feature 'unicode_strings">>|feature/The 'unicode_strings' feature>,
2631 as L<C<lc>|/lc EXPR> does, with the single exception of
2632 L<C<fc>|/fc EXPR> of I<LATIN CAPITAL LETTER SHARP S> (U+1E9E) within the
2633 scope of L<S<C<use locale>>|locale>.  The foldcase of this character
2634 would normally be C<"ss">, but as explained in the L<C<lc>|/lc EXPR>
2635 section, case
2636 changes that cross the 255/256 boundary are problematic under locales,
2637 and are hence prohibited.  Therefore, this function under locale returns
2638 instead the string C<"\x{17F}\x{17F}">, which is the I<LATIN SMALL LETTER
2639 LONG S>.  Since that character itself folds to C<"s">, the string of two
2640 of them together should be equivalent to a single U+1E9E when foldcased.
2641
2642 While the Unicode Standard defines two additional forms of casefolding,
2643 one for Turkic languages and one that never maps one character into multiple
2644 characters, these are not provided by the Perl core.  However, the CPAN module
2645 L<C<Unicode::Casing>|Unicode::Casing> may be used to provide an implementation.
2646
2647 L<C<fc>|/fc EXPR> is available only if the
2648 L<C<"fc"> feature|feature/The 'fc' feature> is enabled or if it is
2649 prefixed with C<CORE::>.  The
2650 L<C<"fc"> feature|feature/The 'fc' feature> is enabled automatically
2651 with a C<use v5.16> (or higher) declaration in the current scope.
2652
2653 =item fcntl FILEHANDLE,FUNCTION,SCALAR
2654 X<fcntl>
2655
2656 =for Pod::Functions file control system call
2657
2658 Implements the L<fcntl(2)> function.  You'll probably have to say
2659
2660     use Fcntl;
2661
2662 first to get the correct constant definitions.  Argument processing and
2663 value returned work just like L<C<ioctl>|/ioctl
2664 FILEHANDLE,FUNCTION,SCALAR> below.  For example:
2665
2666     use Fcntl;
2667     my $flags = fcntl($filehandle, F_GETFL, 0)
2668         or die "Can't fcntl F_GETFL: $!";
2669
2670 You don't have to check for L<C<defined>|/defined EXPR> on the return
2671 from L<C<fcntl>|/fcntl FILEHANDLE,FUNCTION,SCALAR>.  Like
2672 L<C<ioctl>|/ioctl FILEHANDLE,FUNCTION,SCALAR>, it maps a C<0> return
2673 from the system call into C<"0 but true"> in Perl.  This string is true
2674 in boolean context and C<0> in numeric context.  It is also exempt from
2675 the normal
2676 L<C<Argument "..." isn't numeric>|perldiag/Argument "%s" isn't numeric%s>
2677 L<warnings> on improper numeric conversions.
2678
2679 Note that L<C<fcntl>|/fcntl FILEHANDLE,FUNCTION,SCALAR> raises an
2680 exception if used on a machine that doesn't implement L<fcntl(2)>.  See
2681 the L<Fcntl> module or your L<fcntl(2)> manpage to learn what functions
2682 are available on your system.
2683
2684 Here's an example of setting a filehandle named C<$REMOTE> to be
2685 non-blocking at the system level.  You'll have to negotiate
2686 L<C<$E<verbar>>|perlvar/$E<verbar>> on your own, though.
2687
2688     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
2689
2690     my $flags = fcntl($REMOTE, F_GETFL, 0)
2691         or die "Can't get flags for the socket: $!\n";
2692
2693     fcntl($REMOTE, F_SETFL, $flags | O_NONBLOCK)
2694         or die "Can't set flags for the socket: $!\n";
2695
2696 Portability issues: L<perlport/fcntl>.
2697
2698 =item __FILE__
2699 X<__FILE__>
2700
2701 =for Pod::Functions the name of the current source file
2702
2703 A special token that returns the name of the file in which it occurs.
2704
2705 =item fileno FILEHANDLE
2706 X<fileno>
2707
2708 =item fileno DIRHANDLE
2709
2710 =for Pod::Functions return file descriptor from filehandle
2711
2712 Returns the file descriptor for a filehandle or directory handle,
2713 or undefined if the
2714 filehandle is not open.  If there is no real file descriptor at the OS
2715 level, as can happen with filehandles connected to memory objects via
2716 L<C<open>|/open FILEHANDLE,EXPR> with a reference for the third
2717 argument, -1 is returned.
2718
2719 This is mainly useful for constructing bitmaps for
2720 L<C<select>|/select RBITS,WBITS,EBITS,TIMEOUT> and low-level POSIX
2721 tty-handling operations.
2722 If FILEHANDLE is an expression, the value is taken as an indirect
2723 filehandle, generally its name.
2724
2725 You can use this to find out whether two handles refer to the
2726 same underlying descriptor:
2727
2728     if (fileno($this) != -1 && fileno($this) == fileno($that)) {
2729         print "\$this and \$that are dups\n";
2730     } elsif (fileno($this) != -1 && fileno($that) != -1) {
2731         print "\$this and \$that have different " .
2732             "underlying file descriptors\n";
2733     } else {
2734         print "At least one of \$this and \$that does " .
2735             "not have a real file descriptor\n";
2736     }
2737
2738 The behavior of L<C<fileno>|/fileno FILEHANDLE> on a directory handle
2739 depends on the operating system.  On a system with L<dirfd(3)> or
2740 similar, L<C<fileno>|/fileno FILEHANDLE> on a directory
2741 handle returns the underlying file descriptor associated with the
2742 handle; on systems with no such support, it returns the undefined value,
2743 and sets L<C<$!>|perlvar/$!> (errno).
2744
2745 =item flock FILEHANDLE,OPERATION
2746 X<flock> X<lock> X<locking>
2747
2748 =for Pod::Functions lock an entire file with an advisory lock
2749
2750 Calls L<flock(2)>, or an emulation of it, on FILEHANDLE.  Returns true
2751 for success, false on failure.  Produces a fatal error if used on a
2752 machine that doesn't implement L<flock(2)>, L<fcntl(2)> locking, or
2753 L<lockf(3)>.  L<C<flock>|/flock FILEHANDLE,OPERATION> is Perl's portable
2754 file-locking interface, although it locks entire files only, not
2755 records.
2756
2757 Two potentially non-obvious but traditional L<C<flock>|/flock
2758 FILEHANDLE,OPERATION> semantics are
2759 that it waits indefinitely until the lock is granted, and that its locks
2760 are B<merely advisory>.  Such discretionary locks are more flexible, but
2761 offer fewer guarantees.  This means that programs that do not also use
2762 L<C<flock>|/flock FILEHANDLE,OPERATION> may modify files locked with
2763 L<C<flock>|/flock FILEHANDLE,OPERATION>.  See L<perlport>,
2764 your port's specific documentation, and your system-specific local manpages
2765 for details.  It's best to assume traditional behavior if you're writing
2766 portable programs.  (But if you're not, you should as always feel perfectly
2767 free to write for your own system's idiosyncrasies (sometimes called
2768 "features").  Slavish adherence to portability concerns shouldn't get
2769 in the way of your getting your job done.)
2770
2771 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
2772 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
2773 you can use the symbolic names if you import them from the L<Fcntl> module,
2774 either individually, or as a group using the C<:flock> tag.  LOCK_SH
2775 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
2776 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
2777 LOCK_SH or LOCK_EX, then L<C<flock>|/flock FILEHANDLE,OPERATION> returns
2778 immediately rather than blocking waiting for the lock; check the return
2779 status to see if you got it.
2780
2781 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
2782 before locking or unlocking it.
2783
2784 Note that the emulation built with L<lockf(3)> doesn't provide shared
2785 locks, and it requires that FILEHANDLE be open with write intent.  These
2786 are the semantics that L<lockf(3)> implements.  Most if not all systems
2787 implement L<lockf(3)> in terms of L<fcntl(2)> locking, though, so the
2788 differing semantics shouldn't bite too many people.
2789
2790 Note that the L<fcntl(2)> emulation of L<flock(3)> requires that FILEHANDLE
2791 be open with read intent to use LOCK_SH and requires that it be open
2792 with write intent to use LOCK_EX.
2793
2794 Note also that some versions of L<C<flock>|/flock FILEHANDLE,OPERATION>
2795 cannot lock things over the network; you would need to use the more
2796 system-specific L<C<fcntl>|/fcntl FILEHANDLE,FUNCTION,SCALAR> for
2797 that.  If you like you can force Perl to ignore your system's L<flock(2)>
2798 function, and so provide its own L<fcntl(2)>-based emulation, by passing
2799 the switch C<-Ud_flock> to the F<Configure> program when you configure
2800 and build a new Perl.
2801
2802 Here's a mailbox appender for BSD systems.
2803
2804     # import LOCK_* and SEEK_END constants
2805     use Fcntl qw(:flock SEEK_END);
2806
2807     sub lock {
2808         my ($fh) = @_;
2809         flock($fh, LOCK_EX) or die "Cannot lock mailbox - $!\n";
2810         # and, in case we're running on a very old UNIX
2811         # variant without the modern O_APPEND semantics...
2812         seek($fh, 0, SEEK_END) or die "Cannot seek - $!\n";
2813     }
2814
2815     sub unlock {
2816         my ($fh) = @_;
2817         flock($fh, LOCK_UN) or die "Cannot unlock mailbox - $!\n";
2818     }
2819
2820     open(my $mbox, ">>", "/usr/spool/mail/$ENV{'USER'}")
2821         or die "Can't open mailbox: $!";
2822
2823     lock($mbox);
2824     print $mbox $msg,"\n\n";
2825     unlock($mbox);
2826
2827 On systems that support a real L<flock(2)>, locks are inherited across
2828 L<C<fork>|/fork> calls, whereas those that must resort to the more
2829 capricious L<fcntl(2)> function lose their locks, making it seriously
2830 harder to write servers.
2831
2832 See also L<DB_File> for other L<C<flock>|/flock FILEHANDLE,OPERATION>
2833 examples.
2834
2835 Portability issues: L<perlport/flock>.
2836
2837 =item fork
2838 X<fork> X<child> X<parent>
2839
2840 =for Pod::Functions create a new process just like this one
2841
2842 Does a L<fork(2)> system call to create a new process running the
2843 same program at the same point.  It returns the child pid to the
2844 parent process, C<0> to the child process, or L<C<undef>|/undef EXPR> if
2845 the fork is
2846 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
2847 are shared, while everything else is copied.  On most systems supporting
2848 L<fork(2)>, great care has gone into making it extremely efficient (for
2849 example, using copy-on-write technology on data pages), making it the
2850 dominant paradigm for multitasking over the last few decades.
2851
2852 Perl attempts to flush all files opened for output before forking the
2853 child process, but this may not be supported on some platforms (see
2854 L<perlport>).  To be safe, you may need to set
2855 L<C<$E<verbar>>|perlvar/$E<verbar>> (C<$AUTOFLUSH> in L<English>) or
2856 call the C<autoflush> method of L<C<IO::Handle>|IO::Handle/METHODS> on
2857 any open handles to avoid duplicate output.
2858
2859 If you L<C<fork>|/fork> without ever waiting on your children, you will
2860 accumulate zombies.  On some systems, you can avoid this by setting
2861 L<C<$SIG{CHLD}>|perlvar/%SIG> to C<"IGNORE">.  See also L<perlipc> for
2862 more examples of forking and reaping moribund children.
2863
2864 Note that if your forked child inherits system file descriptors like
2865 STDIN and STDOUT that are actually connected by a pipe or socket, even
2866 if you exit, then the remote server (such as, say, a CGI script or a
2867 backgrounded job launched from a remote shell) won't think you're done.
2868 You should reopen those to F</dev/null> if it's any issue.
2869
2870 On some platforms such as Windows, where the L<fork(2)> system call is
2871 not available, Perl can be built to emulate L<C<fork>|/fork> in the Perl
2872 interpreter.  The emulation is designed, at the level of the Perl
2873 program, to be as compatible as possible with the "Unix" L<fork(2)>.
2874 However it has limitations that have to be considered in code intended
2875 to be portable.  See L<perlfork> for more details.
2876
2877 Portability issues: L<perlport/fork>.
2878
2879 =item format
2880 X<format>
2881
2882 =for Pod::Functions declare a picture format with use by the write() function
2883
2884 Declare a picture format for use by the L<C<write>|/write FILEHANDLE>
2885 function.  For example:
2886
2887     format Something =
2888         Test: @<<<<<<<< @||||| @>>>>>
2889               $str,     $%,    '$' . int($num)
2890     .
2891
2892     $str = "widget";
2893     $num = $cost/$quantity;
2894     $~ = 'Something';
2895     write;
2896
2897 See L<perlform> for many details and examples.
2898
2899 =item formline PICTURE,LIST
2900 X<formline>
2901
2902 =for Pod::Functions internal function used for formats
2903
2904 This is an internal function used by L<C<format>|/format>s, though you
2905 may call it, too.  It formats (see L<perlform>) a list of values
2906 according to the contents of PICTURE, placing the output into the format
2907 output accumulator, L<C<$^A>|perlvar/$^A> (or C<$ACCUMULATOR> in
2908 L<English>).  Eventually, when a L<C<write>|/write FILEHANDLE> is done,
2909 the contents of L<C<$^A>|perlvar/$^A> are written to some filehandle.
2910 You could also read L<C<$^A>|perlvar/$^A> and then set
2911 L<C<$^A>|perlvar/$^A> back to C<"">.  Note that a format typically does
2912 one L<C<formline>|/formline PICTURE,LIST> per line of form, but the
2913 L<C<formline>|/formline PICTURE,LIST> function itself doesn't care how
2914 many newlines are embedded in the PICTURE.  This means that the C<~> and
2915 C<~~> tokens treat the entire PICTURE as a single line.  You may
2916 therefore need to use multiple formlines to implement a single record
2917 format, just like the L<C<format>|/format> compiler.
2918
2919 Be careful if you put double quotes around the picture, because an C<@>
2920 character may be taken to mean the beginning of an array name.
2921 L<C<formline>|/formline PICTURE,LIST> always returns true.  See
2922 L<perlform> for other examples.
2923
2924 If you are trying to use this instead of L<C<write>|/write FILEHANDLE>
2925 to capture the output, you may find it easier to open a filehandle to a
2926 scalar (C<< open my $fh, ">", \$output >>) and write to that instead.
2927
2928 =item getc FILEHANDLE
2929 X<getc> X<getchar> X<character> X<file, read>
2930
2931 =item getc
2932
2933 =for Pod::Functions get the next character from the filehandle
2934
2935 Returns the next character from the input file attached to FILEHANDLE,
2936 or the undefined value at end of file or if there was an error (in
2937 the latter case L<C<$!>|perlvar/$!> is set).  If FILEHANDLE is omitted,
2938 reads from
2939 STDIN.  This is not particularly efficient.  However, it cannot be
2940 used by itself to fetch single characters without waiting for the user
2941 to hit enter.  For that, try something more like:
2942
2943     if ($BSD_STYLE) {
2944         system "stty cbreak </dev/tty >/dev/tty 2>&1";
2945     }
2946     else {
2947         system "stty", '-icanon', 'eol', "\001";
2948     }
2949
2950     my $key = getc(STDIN);
2951
2952     if ($BSD_STYLE) {
2953         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
2954     }
2955     else {
2956         system 'stty', 'icanon', 'eol', '^@'; # ASCII NUL
2957     }
2958     print "\n";
2959
2960 Determination of whether C<$BSD_STYLE> should be set is left as an
2961 exercise to the reader.
2962
2963 The L<C<POSIX::getattr>|POSIX/C<getattr>> function can do this more
2964 portably on systems purporting POSIX compliance.  See also the
2965 L<C<Term::ReadKey>|Term::ReadKey> module on CPAN.
2966
2967 =item getlogin
2968 X<getlogin> X<login>
2969
2970 =for Pod::Functions return who logged in at this tty
2971
2972 This implements the C library function of the same name, which on most
2973 systems returns the current login from F</etc/utmp>, if any.  If it
2974 returns the empty string, use L<C<getpwuid>|/getpwuid UID>.
2975
2976     my $login = getlogin || getpwuid($<) || "Kilroy";
2977
2978 Do not consider L<C<getlogin>|/getlogin> for authentication: it is not
2979 as secure as L<C<getpwuid>|/getpwuid UID>.
2980
2981 Portability issues: L<perlport/getlogin>.
2982
2983 =item getpeername SOCKET
2984 X<getpeername> X<peer>
2985
2986 =for Pod::Functions find the other end of a socket connection
2987
2988 Returns the packed sockaddr address of the other end of the SOCKET
2989 connection.
2990
2991     use Socket;
2992     my $hersockaddr    = getpeername($sock);
2993     my ($port, $iaddr) = sockaddr_in($hersockaddr);
2994     my $herhostname    = gethostbyaddr($iaddr, AF_INET);
2995     my $herstraddr     = inet_ntoa($iaddr);
2996
2997 =item getpgrp PID
2998 X<getpgrp> X<group>
2999
3000 =for Pod::Functions get process group
3001
3002 Returns the current process group for the specified PID.  Use
3003 a PID of C<0> to get the current process group for the
3004 current process.  Will raise an exception if used on a machine that
3005 doesn't implement L<getpgrp(2)>.  If PID is omitted, returns the process
3006 group of the current process.  Note that the POSIX version of
3007 L<C<getpgrp>|/getpgrp PID> does not accept a PID argument, so only
3008 C<PID==0> is truly portable.
3009
3010 Portability issues: L<perlport/getpgrp>.
3011
3012 =item getppid
3013 X<getppid> X<parent> X<pid>
3014
3015 =for Pod::Functions get parent process ID
3016
3017 Returns the process id of the parent process.
3018
3019 Note for Linux users: Between v5.8.1 and v5.16.0 Perl would work
3020 around non-POSIX thread semantics the minority of Linux systems (and
3021 Debian GNU/kFreeBSD systems) that used LinuxThreads, this emulation
3022 has since been removed.  See the documentation for L<$$|perlvar/$$> for
3023 details.
3024
3025 Portability issues: L<perlport/getppid>.
3026
3027 =item getpriority WHICH,WHO
3028 X<getpriority> X<priority> X<nice>
3029
3030 =for Pod::Functions get current nice value
3031
3032 Returns the current priority for a process, a process group, or a user.
3033 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
3034 machine that doesn't implement L<getpriority(2)>.
3035
3036 C<WHICH> can be any of C<PRIO_PROCESS>, C<PRIO_PGRP> or C<PRIO_USER>
3037 imported from L<POSIX/RESOURCE CONSTANTS>.
3038
3039 Portability issues: L<perlport/getpriority>.
3040
3041 =item getpwnam NAME
3042 X<getpwnam> X<getgrnam> X<gethostbyname> X<getnetbyname> X<getprotobyname>
3043 X<getpwuid> X<getgrgid> X<getservbyname> X<gethostbyaddr> X<getnetbyaddr>
3044 X<getprotobynumber> X<getservbyport> X<getpwent> X<getgrent> X<gethostent>
3045 X<getnetent> X<getprotoent> X<getservent> X<setpwent> X<setgrent> X<sethostent>
3046 X<setnetent> X<setprotoent> X<setservent> X<endpwent> X<endgrent> X<endhostent>
3047 X<endnetent> X<endprotoent> X<endservent>
3048
3049 =for Pod::Functions get passwd record given user login name
3050
3051 =item getgrnam NAME
3052
3053 =for Pod::Functions get group record given group name
3054
3055 =item gethostbyname NAME
3056
3057 =for Pod::Functions get host record given name
3058
3059 =item getnetbyname NAME
3060
3061 =for Pod::Functions get networks record given name
3062
3063 =item getprotobyname NAME
3064
3065 =for Pod::Functions get protocol record given name
3066
3067 =item getpwuid UID
3068
3069 =for Pod::Functions get passwd record given user ID
3070
3071 =item getgrgid GID
3072
3073 =for Pod::Functions get group record given group user ID
3074
3075 =item getservbyname NAME,PROTO
3076
3077 =for Pod::Functions get services record given its name
3078
3079 =item gethostbyaddr ADDR,ADDRTYPE
3080
3081 =for Pod::Functions get host record given its address
3082
3083 =item getnetbyaddr ADDR,ADDRTYPE
3084
3085 =for Pod::Functions get network record given its address
3086
3087 =item getprotobynumber NUMBER
3088
3089 =for Pod::Functions get protocol record numeric protocol
3090
3091 =item getservbyport PORT,PROTO
3092
3093 =for Pod::Functions get services record given numeric port
3094
3095 =item getpwent
3096
3097 =for Pod::Functions get next passwd record
3098
3099 =item getgrent
3100
3101 =for Pod::Functions get next group record
3102
3103 =item gethostent
3104
3105 =for Pod::Functions get next hosts record
3106
3107 =item getnetent
3108
3109 =for Pod::Functions get next networks record
3110
3111 =item getprotoent
3112
3113 =for Pod::Functions get next protocols record
3114
3115 =item getservent
3116
3117 =for Pod::Functions get next services record
3118
3119 =item setpwent
3120
3121 =for Pod::Functions prepare passwd file for use
3122
3123 =item setgrent
3124
3125 =for Pod::Functions prepare group file for use
3126
3127 =item sethostent STAYOPEN
3128
3129 =for Pod::Functions prepare hosts file for use
3130
3131 =item setnetent STAYOPEN
3132
3133 =for Pod::Functions prepare networks file for use
3134
3135 =item setprotoent STAYOPEN
3136
3137 =for Pod::Functions prepare protocols file for use
3138
3139 =item setservent STAYOPEN
3140
3141 =for Pod::Functions prepare services file for use
3142
3143 =item endpwent
3144
3145 =for Pod::Functions be done using passwd file
3146
3147 =item endgrent
3148
3149 =for Pod::Functions be done using group file
3150
3151 =item endhostent
3152
3153 =for Pod::Functions be done using hosts file
3154
3155 =item endnetent
3156
3157 =for Pod::Functions be done using networks file
3158
3159 =item endprotoent
3160
3161 =for Pod::Functions be done using protocols file
3162
3163 =item endservent
3164
3165 =for Pod::Functions be done using services file
3166
3167 These routines are the same as their counterparts in the
3168 system C library.  In list context, the return values from the
3169 various get routines are as follows:
3170
3171  #    0        1          2           3         4
3172  my ( $name,   $passwd,   $gid,       $members  ) = getgr*
3173  my ( $name,   $aliases,  $addrtype,  $net      ) = getnet*
3174  my ( $name,   $aliases,  $port,      $proto    ) = getserv*
3175  my ( $name,   $aliases,  $proto                ) = getproto*
3176  my ( $name,   $aliases,  $addrtype,  $length,  @addrs ) = gethost*
3177  my ( $name,   $passwd,   $uid,       $gid,     $quota,
3178     $comment,  $gcos,     $dir,       $shell,   $expire ) = getpw*
3179  #    5        6          7           8         9
3180
3181 (If the entry doesn't exist, the return value is a single meaningless true
3182 value.)
3183
3184 The exact meaning of the $gcos field varies but it usually contains
3185 the real name of the user (as opposed to the login name) and other
3186 information pertaining to the user.  Beware, however, that in many
3187 system users are able to change this information and therefore it
3188 cannot be trusted and therefore the $gcos is tainted (see
3189 L<perlsec>).  The $passwd and $shell, user's encrypted password and
3190 login shell, are also tainted, for the same reason.
3191
3192 In scalar context, you get the name, unless the function was a
3193 lookup by name, in which case you get the other thing, whatever it is.
3194 (If the entry doesn't exist you get the undefined value.)  For example:
3195
3196     my $uid   = getpwnam($name);
3197     my $name  = getpwuid($num);
3198     my $name  = getpwent();
3199     my $gid   = getgrnam($name);
3200     my $name  = getgrgid($num);
3201     my $name  = getgrent();
3202     # etc.
3203
3204 In I<getpw*()> the fields $quota, $comment, and $expire are special
3205 in that they are unsupported on many systems.  If the
3206 $quota is unsupported, it is an empty scalar.  If it is supported, it
3207 usually encodes the disk quota.  If the $comment field is unsupported,
3208 it is an empty scalar.  If it is supported it usually encodes some
3209 administrative comment about the user.  In some systems the $quota
3210 field may be $change or $age, fields that have to do with password
3211 aging.  In some systems the $comment field may be $class.  The $expire
3212 field, if present, encodes the expiration period of the account or the
3213 password.  For the availability and the exact meaning of these fields
3214 in your system, please consult L<getpwnam(3)> and your system's
3215 F<pwd.h> file.  You can also find out from within Perl what your
3216 $quota and $comment fields mean and whether you have the $expire field
3217 by using the L<C<Config>|Config> module and the values C<d_pwquota>, C<d_pwage>,
3218 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
3219 files are supported only if your vendor has implemented them in the
3220 intuitive fashion that calling the regular C library routines gets the
3221 shadow versions if you're running under privilege or if there exists
3222 the L<shadow(3)> functions as found in System V (this includes Solaris
3223 and Linux).  Those systems that implement a proprietary shadow password
3224 facility are unlikely to be supported.
3225
3226 The $members value returned by I<getgr*()> is a space-separated list of
3227 the login names of the members of the group.
3228
3229 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
3230 C, it will be returned to you via L<C<$?>|perlvar/$?> if the function
3231 call fails.  The
3232 C<@addrs> value returned by a successful call is a list of raw
3233 addresses returned by the corresponding library call.  In the
3234 Internet domain, each address is four bytes long; you can unpack it
3235 by saying something like:
3236
3237     my ($w,$x,$y,$z) = unpack('W4',$addr[0]);
3238
3239 The Socket library makes this slightly easier:
3240
3241     use Socket;
3242     my $iaddr = inet_aton("127.1"); # or whatever address
3243     my $name  = gethostbyaddr($iaddr, AF_INET);
3244
3245     # or going the other way
3246     my $straddr = inet_ntoa($iaddr);
3247
3248 In the opposite way, to resolve a hostname to the IP address
3249 you can write this:
3250
3251     use Socket;
3252     my $packed_ip = gethostbyname("www.perl.org");
3253     my $ip_address;
3254     if (defined $packed_ip) {
3255         $ip_address = inet_ntoa($packed_ip);
3256     }
3257
3258 Make sure L<C<gethostbyname>|/gethostbyname NAME> is called in SCALAR
3259 context and that its return value is checked for definedness.
3260
3261 The L<C<getprotobynumber>|/getprotobynumber NUMBER> function, even
3262 though it only takes one argument, has the precedence of a list
3263 operator, so beware:
3264
3265     getprotobynumber $number eq 'icmp'   # WRONG
3266     getprotobynumber($number eq 'icmp')  # actually means this
3267     getprotobynumber($number) eq 'icmp'  # better this way
3268
3269 If you get tired of remembering which element of the return list
3270 contains which return value, by-name interfaces are provided in standard
3271 modules: L<C<File::stat>|File::stat>, L<C<Net::hostent>|Net::hostent>,
3272 L<C<Net::netent>|Net::netent>, L<C<Net::protoent>|Net::protoent>,
3273 L<C<Net::servent>|Net::servent>, L<C<Time::gmtime>|Time::gmtime>,
3274 L<C<Time::localtime>|Time::localtime>, and
3275 L<C<User::grent>|User::grent>.  These override the normal built-ins,
3276 supplying versions that return objects with the appropriate names for
3277 each field.  For example:
3278
3279    use File::stat;
3280    use User::pwent;
3281    my $is_his = (stat($filename)->uid == pwent($whoever)->uid);
3282
3283 Even though it looks as though they're the same method calls (uid),
3284 they aren't, because a C<File::stat> object is different from
3285 a C<User::pwent> object.
3286
3287 Many of these functions are not safe in a multi-threaded environment
3288 where more than one thread can be using them.  In particular, functions
3289 like C<getpwent()> iterate per-process and not per-thread, so if two
3290 threads are simultaneously iterating, neither will get all the records.
3291
3292 Some systems have thread-safe versions of some of the functions, such as
3293 C<getpwnam_r()> instead of C<getpwnam()>.  There, Perl automatically and
3294 invisibly substitutes the thread-safe version, without notice.  This
3295 means that code that safely runs on some systems can fail on others that
3296 lack the thread-safe versions.
3297
3298 Portability issues: L<perlport/getpwnam> to L<perlport/endservent>.
3299
3300 =item getsockname SOCKET
3301 X<getsockname>
3302
3303 =for Pod::Functions retrieve the sockaddr for a given socket
3304
3305 Returns the packed sockaddr address of this end of the SOCKET connection,
3306 in case you don't know the address because you have several different
3307 IPs that the connection might have come in on.
3308
3309     use Socket;
3310     my $mysockaddr = getsockname($sock);
3311     my ($port, $myaddr) = sockaddr_in($mysockaddr);
3312     printf "Connect to %s [%s]\n",
3313        scalar gethostbyaddr($myaddr, AF_INET),
3314        inet_ntoa($myaddr);
3315
3316 =item getsockopt SOCKET,LEVEL,OPTNAME
3317 X<getsockopt>
3318
3319 =for Pod::Functions get socket options on a given socket
3320
3321 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
3322 Options may exist at multiple protocol levels depending on the socket
3323 type, but at least the uppermost socket level SOL_SOCKET (defined in the
3324 L<C<Socket>|Socket> module) will exist.  To query options at another
3325 level the protocol number of the appropriate protocol controlling the
3326 option should be supplied.  For example, to indicate that an option is
3327 to be interpreted by the TCP protocol, LEVEL should be set to the
3328 protocol number of TCP, which you can get using
3329 L<C<getprotobyname>|/getprotobyname NAME>.
3330
3331 The function returns a packed string representing the requested socket
3332 option, or L<C<undef>|/undef EXPR> on error, with the reason for the
3333 error placed in L<C<$!>|perlvar/$!>.  Just what is in the packed string
3334 depends on LEVEL and OPTNAME; consult L<getsockopt(2)> for details.  A
3335 common case is that the option is an integer, in which case the result
3336 is a packed integer, which you can decode using
3337 L<C<unpack>|/unpack TEMPLATE,EXPR> with the C<i> (or C<I>) format.
3338
3339 Here's an example to test whether Nagle's algorithm is enabled on a socket:
3340
3341     use Socket qw(:all);
3342
3343     defined(my $tcp = getprotobyname("tcp"))
3344         or die "Could not determine the protocol number for tcp";
3345     # my $tcp = IPPROTO_TCP; # Alternative
3346     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
3347         or die "getsockopt TCP_NODELAY: $!";
3348     my $nodelay = unpack("I", $packed);
3349     print "Nagle's algorithm is turned ",
3350            $nodelay ? "off\n" : "on\n";
3351
3352 Portability issues: L<perlport/getsockopt>.
3353
3354 =item glob EXPR
3355 X<glob> X<wildcard> X<filename, expansion> X<expand>
3356
3357 =item glob
3358
3359 =for Pod::Functions expand filenames using wildcards
3360
3361 In list context, returns a (possibly empty) list of filename expansions on
3362 the value of EXPR such as the standard Unix shell F</bin/csh> would do.  In
3363 scalar context, glob iterates through such filename expansions, returning
3364 undef when the list is exhausted.  This is the internal function
3365 implementing the C<< <*.c> >> operator, but you can use it directly.  If
3366 EXPR is omitted, L<C<$_>|perlvar/$_> is used.  The C<< <*.c> >> operator
3367 is discussed in more detail in L<perlop/"I/O Operators">.
3368
3369 Note that L<C<glob>|/glob EXPR> splits its arguments on whitespace and
3370 treats
3371 each segment as separate pattern.  As such, C<glob("*.c *.h")>
3372 matches all files with a F<.c> or F<.h> extension.  The expression
3373 C<glob(".* *")> matches all files in the current working directory.
3374 If you want to glob filenames that might contain whitespace, you'll
3375 have to use extra quotes around the spacey filename to protect it.
3376 For example, to glob filenames that have an C<e> followed by a space
3377 followed by an C<f>, use one of:
3378
3379     my @spacies = <"*e f*">;
3380     my @spacies = glob '"*e f*"';
3381     my @spacies = glob q("*e f*");
3382
3383 If you had to get a variable through, you could do this:
3384
3385     my @spacies = glob "'*${var}e f*'";
3386     my @spacies = glob qq("*${var}e f*");
3387
3388 If non-empty braces are the only wildcard characters used in the
3389 L<C<glob>|/glob EXPR>, no filenames are matched, but potentially many
3390 strings are returned.  For example, this produces nine strings, one for
3391 each pairing of fruits and colors:
3392
3393     my @many = glob "{apple,tomato,cherry}={green,yellow,red}";
3394
3395 This operator is implemented using the standard C<File::Glob> extension.
3396 See L<File::Glob> for details, including
3397 L<C<bsd_glob>|File::Glob/C<bsd_glob>>, which does not treat whitespace
3398 as a pattern separator.
3399
3400 If a C<glob> expression is used as the condition of a C<while> or C<for>
3401 loop, then it will be implicitly assigned to C<$_>.  If either a C<glob>
3402 expression or an explicit assignment of a C<glob> expression to a scalar
3403 is used as a C<while>/C<for> condition, then the condition actually
3404 tests for definedness of the expression's value, not for its regular
3405 truth value.
3406
3407 Portability issues: L<perlport/glob>.
3408
3409 =item gmtime EXPR
3410 X<gmtime> X<UTC> X<Greenwich>
3411
3412 =item gmtime
3413
3414 =for Pod::Functions convert UNIX time into record or string using Greenwich time
3415
3416 Works just like L<C<localtime>|/localtime EXPR> but the returned values
3417 are localized for the standard Greenwich time zone.
3418
3419 Note: When called in list context, $isdst, the last value
3420 returned by gmtime, is always C<0>.  There is no
3421 Daylight Saving Time in GMT.
3422
3423 Portability issues: L<perlport/gmtime>.
3424
3425 =item goto LABEL
3426 X<goto> X<jump> X<jmp>
3427
3428 =item goto EXPR
3429
3430 =item goto &NAME
3431
3432 =for Pod::Functions create spaghetti code
3433
3434 The C<goto LABEL> form finds the statement labeled with LABEL and
3435 resumes execution there.  It can't be used to get out of a block or
3436 subroutine given to L<C<sort>|/sort SUBNAME LIST>.  It can be used to go
3437 almost anywhere else within the dynamic scope, including out of
3438 subroutines, but it's usually better to use some other construct such as
3439 L<C<last>|/last LABEL> or L<C<die>|/die LIST>.  The author of Perl has
3440 never felt the need to use this form of L<C<goto>|/goto LABEL> (in Perl,
3441 that is; C is another matter).  (The difference is that C does not offer
3442 named loops combined with loop control.  Perl does, and this replaces
3443 most structured uses of L<C<goto>|/goto LABEL> in other languages.)
3444
3445 The C<goto EXPR> form expects to evaluate C<EXPR> to a code reference or
3446 a label name.  If it evaluates to a code reference, it will be handled
3447 like C<goto &NAME>, below.  This is especially useful for implementing
3448 tail recursion via C<goto __SUB__>.
3449
3450 If the expression evaluates to a label name, its scope will be resolved
3451 dynamically.  This allows for computed L<C<goto>|/goto LABEL>s per
3452 FORTRAN, but isn't necessarily recommended if you're optimizing for
3453 maintainability:
3454
3455     goto ("FOO", "BAR", "GLARCH")[$i];
3456
3457 As shown in this example, C<goto EXPR> is exempt from the "looks like a
3458 function" rule.  A pair of parentheses following it does not (necessarily)
3459 delimit its argument.  C<goto("NE")."XT"> is equivalent to C<goto NEXT>.
3460 Also, unlike most named operators, this has the same precedence as
3461 assignment.
3462
3463 Use of C<goto LABEL> or C<goto EXPR> to jump into a construct is
3464 deprecated and will issue a warning.  Even then, it may not be used to
3465 go into any construct that requires initialization, such as a
3466 subroutine, a C<foreach> loop, or a C<given>
3467 block.  In general, it may not be used to jump into the parameter
3468 of a binary or list operator, but it may be used to jump into the
3469 I<first> parameter of a binary operator.  (The C<=>
3470 assignment operator's "first" operand is its right-hand
3471 operand.)  It also can't be used to go into a
3472 construct that is optimized away.
3473
3474 The C<goto &NAME> form is quite different from the other forms of
3475 L<C<goto>|/goto LABEL>.  In fact, it isn't a goto in the normal sense at
3476 all, and doesn't have the stigma associated with other gotos.  Instead,
3477 it exits the current subroutine (losing any changes set by
3478 L<C<local>|/local EXPR>) and immediately calls in its place the named
3479 subroutine using the current value of L<C<@_>|perlvar/@_>.  This is used
3480 by C<AUTOLOAD> subroutines that wish to load another subroutine and then
3481 pretend that the other subroutine had been called in the first place
3482 (except that any modifications to L<C<@_>|perlvar/@_> in the current
3483 subroutine are propagated to the other subroutine.) After the
3484 L<C<goto>|/goto LABEL>, not even L<C<caller>|/caller EXPR> will be able
3485 to tell that this routine was called first.
3486
3487 NAME needn't be the name of a subroutine; it can be a scalar variable
3488 containing a code reference or a block that evaluates to a code
3489 reference.
3490
3491 =item grep BLOCK LIST
3492 X<grep>
3493
3494 =item grep EXPR,LIST
3495
3496 =for Pod::Functions locate elements in a list test true against a given criterion
3497
3498 This is similar in spirit to, but not the same as, L<grep(1)> and its
3499 relatives.  In particular, it is not limited to using regular expressions.
3500
3501 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
3502 L<C<$_>|perlvar/$_> to each element) and returns the list value
3503 consisting of those
3504 elements for which the expression evaluated to true.  In scalar
3505 context, returns the number of times the expression was true.
3506
3507     my @foo = grep(!/^#/, @bar);    # weed out comments
3508
3509 or equivalently,
3510
3511     my @foo = grep {!/^#/} @bar;    # weed out comments
3512
3513 Note that L<C<$_>|perlvar/$_> is an alias to the list value, so it can
3514 be used to
3515 modify the elements of the LIST.  While this is useful and supported,
3516 it can cause bizarre results if the elements of LIST are not variables.
3517 Similarly, grep returns aliases into the original list, much as a for
3518 loop's index variable aliases the list elements.  That is, modifying an
3519 element of a list returned by grep (for example, in a C<foreach>,
3520 L<C<map>|/map BLOCK LIST> or another L<C<grep>|/grep BLOCK LIST>)
3521 actually modifies the element in the original list.
3522 This is usually something to be avoided when writing clear code.
3523
3524 See also L<C<map>|/map BLOCK LIST> for a list composed of the results of
3525 the BLOCK or EXPR.
3526
3527 =item hex EXPR
3528 X<hex> X<hexadecimal>
3529
3530 =item hex
3531
3532 =for Pod::Functions convert a hexadecimal string to a number
3533
3534 Interprets EXPR as a hex string and returns the corresponding numeric value.
3535 If EXPR is omitted, uses L<C<$_>|perlvar/$_>.
3536
3537     print hex '0xAf'; # prints '175'
3538     print hex 'aF';   # same
3539     $valid_input =~ /\A(?:0?[xX])?(?:_?[0-9a-fA-F])*\z/
3540
3541 A hex string consists of hex digits and an optional C<0x> or C<x> prefix.
3542 Each hex digit may be preceded by a single underscore, which will be ignored.
3543 Any other character triggers a warning and causes the rest of the string
3544 to be ignored (even leading whitespace, unlike L<C<oct>|/oct EXPR>).
3545 Only integers can be represented, and integer overflow triggers a warning.
3546
3547 To convert strings that might start with any of C<0>, C<0x>, or C<0b>,
3548 see L<C<oct>|/oct EXPR>.  To present something as hex, look into
3549 L<C<printf>|/printf FILEHANDLE FORMAT, LIST>,
3550 L<C<sprintf>|/sprintf FORMAT, LIST>, and
3551 L<C<unpack>|/unpack TEMPLATE,EXPR>.
3552
3553 =item import LIST
3554 X<import>
3555
3556 =for Pod::Functions patch a module's namespace into your own
3557
3558 There is no builtin L<C<import>|/import LIST> function.  It is just an
3559 ordinary method (subroutine) defined (or inherited) by modules that wish
3560 to export names to another module.  The
3561 L<C<use>|/use Module VERSION LIST> function calls the
3562 L<C<import>|/import LIST> method for the package used.  See also
3563 L<C<use>|/use Module VERSION LIST>, L<perlmod>, and L<Exporter>.
3564
3565 =item index STR,SUBSTR,POSITION
3566 X<index> X<indexOf> X<InStr>
3567
3568 =item index STR,SUBSTR
3569
3570 =for Pod::Functions find a substring within a string
3571
3572 The index function searches for one string within another, but without
3573 the wildcard-like behavior of a full regular-expression pattern match.
3574 It returns the position of the first occurrence of SUBSTR in STR at
3575 or after POSITION.  If POSITION is omitted, starts searching from the
3576 beginning of the string.  POSITION before the beginning of the string
3577 or after its end is treated as if it were the beginning or the end,
3578 respectively.  POSITION and the return value are based at zero.
3579 If the substring is not found, L<C<index>|/index STR,SUBSTR,POSITION>
3580 returns -1.
3581
3582 =item int EXPR
3583 X<int> X<integer> X<truncate> X<trunc> X<floor>
3584
3585 =item int
3586
3587 =for Pod::Functions get the integer portion of a number
3588
3589 Returns the integer portion of EXPR.  If EXPR is omitted, uses
3590 L<C<$_>|perlvar/$_>.
3591 You should not use this function for rounding: one because it truncates
3592 towards C<0>, and two because machine representations of floating-point
3593 numbers can sometimes produce counterintuitive results.  For example,
3594 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
3595 because it's really more like -268.99999999999994315658 instead.  Usually,
3596 the L<C<sprintf>|/sprintf FORMAT, LIST>,
3597 L<C<printf>|/printf FILEHANDLE FORMAT, LIST>, or the
3598 L<C<POSIX::floor>|POSIX/C<floor>> and L<C<POSIX::ceil>|POSIX/C<ceil>>
3599 functions will serve you better than will L<C<int>|/int EXPR>.
3600
3601 =item ioctl FILEHANDLE,FUNCTION,SCALAR
3602 X<ioctl>
3603
3604 =for Pod::Functions system-dependent device control system call
3605
3606 Implements the L<ioctl(2)> function.  You'll probably first have to say
3607
3608     require "sys/ioctl.ph";  # probably in
3609                              # $Config{archlib}/sys/ioctl.ph
3610
3611 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
3612 exist or doesn't have the correct definitions you'll have to roll your
3613 own, based on your C header files such as F<< <sys/ioctl.h> >>.
3614 (There is a Perl script called B<h2ph> that comes with the Perl kit that
3615 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
3616 written depending on the FUNCTION; a C pointer to the string value of SCALAR
3617 will be passed as the third argument of the actual
3618 L<C<ioctl>|/ioctl FILEHANDLE,FUNCTION,SCALAR> call.  (If SCALAR
3619 has no string value but does have a numeric value, that value will be
3620 passed rather than a pointer to the string value.  To guarantee this to be
3621 true, add a C<0> to the scalar before using it.)  The
3622 L<C<pack>|/pack TEMPLATE,LIST> and L<C<unpack>|/unpack TEMPLATE,EXPR>
3623 functions may be needed to manipulate the values of structures used by
3624 L<C<ioctl>|/ioctl FILEHANDLE,FUNCTION,SCALAR>.
3625
3626 The return value of L<C<ioctl>|/ioctl FILEHANDLE,FUNCTION,SCALAR> (and
3627 L<C<fcntl>|/fcntl FILEHANDLE,FUNCTION,SCALAR>) is as follows:
3628
3629     if OS returns:      then Perl returns:
3630         -1               undefined value
3631          0              string "0 but true"
3632     anything else           that number
3633
3634 Thus Perl returns true on success and false on failure, yet you can
3635 still easily determine the actual value returned by the operating
3636 system:
3637
3638     my $retval = ioctl(...) || -1;
3639     printf "System returned %d\n", $retval;
3640
3641 The special string C<"0 but true"> is exempt from
3642 L<C<Argument "..." isn't numeric>|perldiag/Argument "%s" isn't numeric%s>
3643 L<warnings> on improper numeric conversions.
3644
3645 Portability issues: L<perlport/ioctl>.
3646
3647 =item join EXPR,LIST
3648 X<join>
3649
3650 =for Pod::Functions join a list into a string using a separator
3651
3652 Joins the separate strings of LIST into a single string with fields
3653 separated by the value of EXPR, and returns that new string.  Example:
3654
3655    my $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
3656
3657 Beware that unlike L<C<split>|/split E<sol>PATTERNE<sol>,EXPR,LIMIT>,
3658 L<C<join>|/join EXPR,LIST> doesn't take a pattern as its first argument.
3659 Compare L<C<split>|/split E<sol>PATTERNE<sol>,EXPR,LIMIT>.
3660
3661 =item keys HASH
3662 X<keys> X<key>
3663
3664 =item keys ARRAY
3665
3666 =for Pod::Functions retrieve list of indices from a hash
3667
3668 Called in list context, returns a list consisting of all the keys of the
3669 named hash, or in Perl 5.12 or later only, the indices of an array.  Perl
3670 releases prior to 5.12 will produce a syntax error if you try to use an
3671 array argument.  In scalar context, returns the number of keys or indices.
3672
3673 Hash entries are returned in an apparently random order.  The actual random
3674 order is specific to a given hash; the exact same series of operations
3675 on two hashes may result in a different order for each hash.  Any insertion
3676 into the hash may change the order, as will any deletion, with the exception
3677 that the most recent key returned by L<C<each>|/each HASH> or
3678 L<C<keys>|/keys HASH> may be deleted without changing the order.  So
3679 long as a given hash is unmodified you may rely on
3680 L<C<keys>|/keys HASH>, L<C<values>|/values HASH> and L<C<each>|/each
3681 HASH> to repeatedly return the same order
3682 as each other.  See L<perlsec/"Algorithmic Complexity Attacks"> for
3683 details on why hash order is randomized.  Aside from the guarantees
3684 provided here the exact details of Perl's hash algorithm and the hash
3685 traversal order are subject to change in any release of Perl.  Tied hashes
3686 may behave differently to Perl's hashes with respect to changes in order on
3687 insertion and deletion of items.
3688
3689 As a side effect, calling L<C<keys>|/keys HASH> resets the internal
3690 iterator of the HASH or ARRAY (see L<C<each>|/each HASH>) before
3691 yielding the keys.  In
3692 particular, calling L<C<keys>|/keys HASH> in void context resets the
3693 iterator with no other overhead.
3694
3695 Here is yet another way to print your environment:
3696
3697     my @keys = keys %ENV;
3698     my @values = values %ENV;
3699     while (@keys) {
3700         print pop(@keys), '=', pop(@values), "\n";
3701     }
3702
3703 or how about sorted by key:
3704
3705     foreach my $key (sort(keys %ENV)) {
3706         print $key, '=', $ENV{$key}, "\n";
3707     }
3708
3709 The returned values are copies of the original keys in the hash, so
3710 modifying them will not affect the original hash.  Compare
3711 L<C<values>|/values HASH>.
3712
3713 To sort a hash by value, you'll need to use a
3714 L<C<sort>|/sort SUBNAME LIST> function.  Here's a descending numeric
3715 sort of a hash by its values:
3716
3717     foreach my $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
3718         printf "%4d %s\n", $hash{$key}, $key;
3719     }
3720
3721 Used as an lvalue, L<C<keys>|/keys HASH> allows you to increase the
3722 number of hash buckets
3723 allocated for the given hash.  This can gain you a measure of efficiency if
3724 you know the hash is going to get big.  (This is similar to pre-extending
3725 an array by assigning a larger number to $#array.)  If you say
3726
3727     keys %hash = 200;
3728
3729 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
3730 in fact, since it rounds up to the next power of two.  These
3731 buckets will be retained even if you do C<%hash = ()>, use C<undef
3732 %hash> if you want to free the storage while C<%hash> is still in scope.
3733 You can't shrink the number of buckets allocated for the hash using
3734 L<C<keys>|/keys HASH> in this way (but you needn't worry about doing
3735 this by accident, as trying has no effect).  C<keys @array> in an lvalue
3736 context is a syntax error.
3737
3738 Starting with Perl 5.14, an experimental feature allowed
3739 L<C<keys>|/keys HASH> to take a scalar expression. This experiment has
3740 been deemed unsuccessful, and was removed as of Perl 5.24.
3741
3742 To avoid confusing would-be users of your code who are running earlier
3743 versions of Perl with mysterious syntax errors, put this sort of thing at
3744 the top of your file to signal that your code will work I<only> on Perls of
3745 a recent vintage:
3746
3747     use 5.012;  # so keys/values/each work on arrays
3748
3749 See also L<C<each>|/each HASH>, L<C<values>|/values HASH>, and
3750 L<C<sort>|/sort SUBNAME LIST>.
3751
3752 =item kill SIGNAL, LIST
3753
3754 =item kill SIGNAL
3755 X<kill> X<signal>
3756
3757 =for Pod::Functions send a signal to a process or process group
3758
3759 Sends a signal to a list of processes.  Returns the number of arguments
3760 that were successfully used to signal (which is not necessarily the same
3761 as the number of processes actually killed, e.g. where a process group is
3762 killed).
3763
3764     my $cnt = kill 'HUP', $child1, $child2;
3765     kill 'KILL', @goners;
3766
3767 SIGNAL may be either a signal name (a string) or a signal number.  A signal
3768 name may start with a C<SIG> prefix, thus C<FOO> and C<SIGFOO> refer to the
3769 same signal.  The string form of SIGNAL is recommended for portability because
3770 the same signal may have different numbers in different operating systems.
3771
3772 A list of signal names supported by the current platform can be found in
3773 C<$Config{sig_name}>, which is provided by the L<C<Config>|Config>
3774 module.  See L<Config> for more details.
3775
3776 A negative signal name is the same as a negative signal number, killing process
3777 groups instead of processes.  For example, C<kill '-KILL', $pgrp> and
3778 C<kill -9, $pgrp> will send C<SIGKILL> to
3779 the entire process group specified.  That
3780 means you usually want to use positive not negative signals.
3781
3782 If SIGNAL is either the number 0 or the string C<ZERO> (or C<SIGZERO>),
3783 no signal is sent to the process, but L<C<kill>|/kill SIGNAL, LIST>
3784 checks whether it's I<possible> to send a signal to it
3785 (that means, to be brief, that the process is owned by the same user, or we are
3786 the super-user).  This is useful to check that a child process is still
3787 alive (even if only as a zombie) and hasn't changed its UID.  See
3788 L<perlport> for notes on the portability of this construct.
3789
3790 The behavior of kill when a I<PROCESS> number is zero or negative depends on
3791 the operating system.  For example, on POSIX-conforming systems, zero will
3792 signal the current process group, -1 will signal all processes, and any
3793 other negative PROCESS number will act as a negative signal number and
3794 kill the entire process group specified.
3795
3796 If both the SIGNAL and the PROCESS are negative, the results are undefined.
3797 A warning may be produced in a future version.
3798
3799 See L<perlipc/"Signals"> for more details.
3800
3801 On some platforms such as Windows where the L<fork(2)> system call is not
3802 available, Perl can be built to emulate L<C<fork>|/fork> at the
3803 interpreter level.
3804 This emulation has limitations related to kill that have to be considered,
3805 for code running on Windows and in code intended to be portable.
3806
3807 See L<perlfork> for more details.
3808
3809 If there is no I<LIST> of processes, no signal is sent, and the return
3810 value is 0.  This form is sometimes used, however, because it causes
3811 tainting checks to be run.  But see
3812 L<perlsec/Laundering and Detecting Tainted Data>.
3813
3814 Portability issues: L<perlport/kill>.
3815
3816 =item last LABEL
3817 X<last> X<break>
3818
3819 =item last EXPR
3820
3821 =item last
3822
3823 =for Pod::Functions exit a block prematurely
3824
3825 The L<C<last>|/last LABEL> command is like the C<break> statement in C
3826 (as used in
3827 loops); it immediately exits the loop in question.  If the LABEL is
3828 omitted, the command refers to the innermost enclosing
3829 loop.  The C<last EXPR> form, available starting in Perl
3830 5.18.0, allows a label name to be computed at run time,
3831 and is otherwise identical to C<last LABEL>.  The
3832 L<C<continue>|/continue BLOCK> block, if any, is not executed:
3833
3834     LINE: while (<STDIN>) {
3835         last LINE if /^$/;  # exit when done with header
3836         #...
3837     }
3838
3839 L<C<last>|/last LABEL> cannot return a value from a block that typically
3840 returns a value, such as C<eval {}>, C<sub {}>, or C<do {}>. It will perform
3841 its flow control behavior, which precludes any return value. It should not be
3842 used to exit a L<C<grep>|/grep BLOCK LIST> or L<C<map>|/map BLOCK LIST>
3843 operation.
3844
3845 Note that a block by itself is semantically identical to a loop
3846 that executes once.  Thus L<C<last>|/last LABEL> can be used to effect
3847 an early exit out of such a block.
3848
3849 See also L<C<continue>|/continue BLOCK> for an illustration of how
3850 L<C<last>|/last LABEL>, L<C<next>|/next LABEL>, and
3851 L<C<redo>|/redo LABEL> work.
3852
3853 Unlike most named operators, this has the same precedence as assignment.
3854 It is also exempt from the looks-like-a-function rule, so
3855 C<last ("foo")."bar"> will cause "bar" to be part of the argument to
3856 L<C<last>|/last LABEL>.
3857
3858 =item lc EXPR
3859 X<lc> X<lowercase>
3860
3861 =item lc
3862
3863 =for Pod::Functions return lower-case version of a string
3864
3865 Returns a lowercased version of EXPR.  This is the internal function
3866 implementing the C<\L> escape in double-quoted strings.
3867
3868 If EXPR is omitted, uses L<C<$_>|perlvar/$_>.
3869
3870 What gets returned depends on several factors:
3871
3872 =over
3873
3874 =item If C<use bytes> is in effect:
3875
3876 The results follow ASCII rules.  Only the characters C<A-Z> change,
3877 to C<a-z> respectively.
3878
3879 =item Otherwise, if C<use locale> for C<LC_CTYPE> is in effect:
3880
3881 Respects current C<LC_CTYPE> locale for code points < 256; and uses Unicode
3882 rules for the remaining code points (this last can only happen if
3883 the UTF8 flag is also set).  See L<perllocale>.
3884
3885 Starting in v5.20, Perl uses full Unicode rules if the locale is
3886 UTF-8.  Otherwise, there is a deficiency in this scheme, which is that
3887 case changes that cross the 255/256
3888 boundary are not well-defined.  For example, the lower case of LATIN CAPITAL
3889 LETTER SHARP S (U+1E9E) in Unicode rules is U+00DF (on ASCII
3890 platforms).   But under C<use locale> (prior to v5.20 or not a UTF-8
3891 locale), the lower case of U+1E9E is
3892 itself, because 0xDF may not be LATIN SMALL LETTER SHARP S in the
3893 current locale, and Perl has no way of knowing if that character even
3894 exists in the locale, much less what code point it is.  Perl returns
3895 a result that is above 255 (almost always the input character unchanged),
3896 for all instances (and there aren't many) where the 255/256 boundary
3897 would otherwise be crossed; and starting in v5.22, it raises a
3898 L<locale|perldiag/Can't do %s("%s") on non-UTF-8 locale; resolved to "%s".> warning.
3899
3900 =item Otherwise, If EXPR has the UTF8 flag set:
3901
3902 Unicode rules are used for the case change.
3903
3904 =item Otherwise, if C<use feature 'unicode_strings'> or C<use locale ':not_characters'> is in effect:
3905
3906 Unicode rules are used for the case change.
3907
3908 =item Otherwise:
3909
3910 ASCII rules are used for the case change.  The lowercase of any character
3911 outside the ASCII range is the character itself.
3912
3913 =back
3914
3915 =item lcfirst EXPR
3916 X<lcfirst> X<lowercase>
3917
3918 =item lcfirst
3919
3920 =for Pod::Functions return a string with just the next letter in lower case
3921
3922 Returns the value of EXPR with the first character lowercased.  This
3923 is the internal function implementing the C<\l> escape in
3924 double-quoted strings.
3925
3926 If EXPR is omitted, uses L<C<$_>|perlvar/$_>.
3927
3928 This function behaves the same way under various pragmas, such as in a locale,
3929 as L<C<lc>|/lc EXPR> does.
3930
3931 =item length EXPR
3932 X<length> X<size>
3933
3934 =item length
3935
3936 =for Pod::Functions return the number of characters in a string
3937
3938 Returns the length in I<characters> of the value of EXPR.  If EXPR is
3939 omitted, returns the length of L<C<$_>|perlvar/$_>.  If EXPR is
3940 undefined, returns L<C<undef>|/undef EXPR>.
3941
3942 This function cannot be used on an entire array or hash to find out how
3943 many elements these have.  For that, use C<scalar @array> and C<scalar keys
3944 %hash>, respectively.
3945
3946 Like all Perl character operations, L<C<length>|/length EXPR> normally
3947 deals in logical
3948 characters, not physical bytes.  For how many bytes a string encoded as
3949 UTF-8 would take up, use C<length(Encode::encode('UTF-8', EXPR))>
3950 (you'll have to C<use Encode> first).  See L<Encode> and L<perlunicode>.
3951
3952 =item __LINE__
3953 X<__LINE__>
3954
3955 =for Pod::Functions the current source line number
3956
3957 A special token that compiles to the current line number.
3958
3959 =item link OLDFILE,NEWFILE
3960 X<link>
3961
3962 =for Pod::Functions create a hard link in the filesystem
3963
3964 Creates a new filename linked to the old filename.  Returns true for
3965 success, false otherwise.
3966
3967 Portability issues: L<perlport/link>.
3968
3969 =item listen SOCKET,QUEUESIZE
3970 X<listen>
3971
3972 =for Pod::Functions register your socket as a server
3973
3974 Does the same thing that the L<listen(2)> system call does.  Returns true if
3975 it succeeded, false otherwise.  See the example in
3976 L<perlipc/"Sockets: Client/Server Communication">.
3977
3978 =item local EXPR
3979 X<local>
3980
3981 =for Pod::Functions create a temporary value for a global variable (dynamic scoping)
3982
3983 You really probably want to be using L<C<my>|/my VARLIST> instead,
3984 because L<C<local>|/local EXPR> isn't what most people think of as
3985 "local".  See L<perlsub/"Private Variables via my()"> for details.
3986
3987 A local modifies the listed variables to be local to the enclosing
3988 block, file, or eval.  If more than one value is listed, the list must
3989 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
3990 for details, including issues with tied arrays and hashes.
3991
3992 The C<delete local EXPR> construct can also be used to localize the deletion
3993 of array/hash elements to the current block.
3994 See L<perlsub/"Localized deletion of elements of composite types">.
3995
3996 =item localtime EXPR
3997 X<localtime> X<ctime>
3998
3999 =item localtime
4000
4001 =for Pod::Functions convert UNIX time into record or string using local time
4002
4003 Converts a time as returned by the time function to a 9-element list
4004 with the time analyzed for the local time zone.  Typically used as
4005 follows:
4006
4007     #     0    1    2     3     4    5     6     7     8
4008     my ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
4009                                                 localtime(time);
4010
4011 All list elements are numeric and come straight out of the C `struct
4012 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
4013 of the specified time.
4014
4015 C<$mday> is the day of the month and C<$mon> the month in
4016 the range C<0..11>, with 0 indicating January and 11 indicating December.
4017 This makes it easy to get a month name from a list:
4018
4019     my @abbr = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
4020     print "$abbr[$mon] $mday";
4021     # $mon=9, $mday=18 gives "Oct 18"
4022
4023 C<$year> contains the number of years since 1900.  To get a 4-digit
4024 year write:
4025
4026     $year += 1900;
4027
4028 To get the last two digits of the year (e.g., "01" in 2001) do:
4029
4030     $year = sprintf("%02d", $year % 100);
4031
4032 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
4033 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
4034 (or C<0..365> in leap years.)
4035
4036 C<$isdst> is true if the specified time occurs during Daylight Saving
4037 Time, false otherwise.
4038
4039 If EXPR is omitted, L<C<localtime>|/localtime EXPR> uses the current
4040 time (as returned by L<C<time>|/time>).
4041
4042 In scalar context, L<C<localtime>|/localtime EXPR> returns the
4043 L<ctime(3)> value:
4044
4045     my $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
4046
4047 The format of this scalar value is B<not> locale-dependent but built
4048 into Perl.  For GMT instead of local time use the
4049 L<C<gmtime>|/gmtime EXPR> builtin.  See also the
4050 L<C<Time::Local>|Time::Local> module (for converting seconds, minutes,
4051 hours, and such back to the integer value returned by L<C<time>|/time>),
4052 and the L<POSIX> module's L<C<strftime>|POSIX/C<strftime>> and
4053 L<C<mktime>|POSIX/C<mktime>> functions.
4054
4055 To get somewhat similar but locale-dependent date strings, set up your
4056 locale environment variables appropriately (please see L<perllocale>) and
4057 try for example:
4058
4059     use POSIX qw(strftime);
4060     my $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
4061     # or for GMT formatted appropriately for your locale:
4062     my $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
4063
4064 Note that C<%a> and C<%b>, the short forms of the day of the week
4065 and the month of the year, may not necessarily be three characters wide.
4066
4067 The L<Time::gmtime> and L<Time::localtime> modules provide a convenient,
4068 by-name access mechanism to the L<C<gmtime>|/gmtime EXPR> and
4069 L<C<localtime>|/localtime EXPR> functions, respectively.
4070
4071 For a comprehensive date and time representation look at the
4072 L<DateTime> module on CPAN.
4073
4074 Portability issues: L<perlport/localtime>.
4075
4076 =item lock THING
4077 X<lock>
4078
4079 =for Pod::Functions +5.005 get a thread lock on a variable, subroutine, or method
4080
4081 This function places an advisory lock on a shared variable or referenced
4082 object contained in I<THING> until the lock goes out of scope.
4083
4084 The value returned is the scalar itself, if the argument is a scalar, or a
4085 reference, if the argument is a hash, array or subroutine.
4086
4087 L<C<lock>|/lock THING> is a "weak keyword"; this means that if you've
4088 defined a function
4089 by this name (before any calls to it), that function will be called
4090 instead.  If you are not under C<use threads::shared> this does nothing.
4091 See L<threads::shared>.
4092
4093 =item log EXPR
4094 X<log> X<logarithm> X<e> X<ln> X<base>
4095
4096 =item log
4097
4098 =for Pod::Functions retrieve the natural logarithm for a number
4099
4100 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
4101 returns the log of L<C<$_>|perlvar/$_>.  To get the
4102 log of another base, use basic algebra:
4103 The base-N log of a number is equal to the natural log of that number
4104 divided by the natural log of N.  For example:
4105
4106     sub log10 {
4107         my $n = shift;
4108         return log($n)/log(10);
4109     }
4110
4111 See also L<C<exp>|/exp EXPR> for the inverse operation.
4112
4113 =item lstat FILEHANDLE
4114 X<lstat>
4115
4116 =item lstat EXPR
4117
4118 =item lstat DIRHANDLE
4119
4120 =item lstat
4121
4122 =for Pod::Functions stat a symbolic link
4123
4124 Does the same thing as the L<C<stat>|/stat FILEHANDLE> function
4125 (including setting the special C<_> filehandle) but stats a symbolic
4126 link instead of the file the symbolic link points to.  If symbolic links
4127 are unimplemented on your system, a normal L<C<stat>|/stat FILEHANDLE>
4128 is done.  For much more detailed information, please see the
4129 documentation for L<C<stat>|/stat FILEHANDLE>.
4130
4131 If EXPR is omitted, stats L<C<$_>|perlvar/$_>.
4132
4133 Portability issues: L<perlport/lstat>.
4134
4135 =item m//
4136
4137 =for Pod::Functions match a string with a regular expression pattern
4138
4139 The match operator.  See L<perlop/"Regexp Quote-Like Operators">.
4140
4141 =item map BLOCK LIST
4142 X<map>
4143
4144 =item map EXPR,LIST
4145
4146 =for Pod::Functions apply a change to a list to get back a new list with the changes
4147
4148 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
4149 L<C<$_>|perlvar/$_> to each element) and composes a list of the results of
4150 each such evaluation.  Each element of LIST may produce zero, one, or more
4151 elements in the generated list, so the number of elements in the generated
4152 list may differ from that in LIST.  In scalar context, returns the total
4153 number of elements so generated.  In list context, returns the generated list.
4154
4155     my @chars = map(chr, @numbers);
4156
4157 translates a list of numbers to the corresponding characters.
4158
4159     my @squares = map { $_ * $_ } @numbers;
4160
4161 translates a list of numbers to their squared values.
4162
4163     my @squares = map { $_ > 5 ? ($_ * $_) : () } @numbers;
4164
4165 shows that number of returned elements can differ from the number of
4166 input elements.  To omit an element, return an empty list ().
4167 This could also be achieved by writing
4168
4169     my @squares = map { $_ * $_ } grep { $_ > 5 } @numbers;
4170
4171 which makes the intention more clear.
4172
4173 Map always returns a list, which can be
4174 assigned to a hash such that the elements
4175 become key/value pairs.  See L<perldata> for more details.
4176
4177     my %hash = map { get_a_key_for($_) => $_ } @array;
4178
4179 is just a funny way to write
4180
4181     my %hash;
4182     foreach (@array) {
4183         $hash{get_a_key_for($_)} = $_;
4184     }
4185
4186 Note that L<C<$_>|perlvar/$_> is an alias to the list value, so it can
4187 be used to modify the elements of the LIST.  While this is useful and
4188 supported, it can cause bizarre results if the elements of LIST are not
4189 variables.  Using a regular C<foreach> loop for this purpose would be
4190 clearer in most cases.  See also L<C<grep>|/grep BLOCK LIST> for a
4191 list composed of those items of the original list for which the BLOCK
4192 or EXPR evaluates to true.
4193
4194 C<{> starts both hash references and blocks, so C<map { ...> could be either
4195 the start of map BLOCK LIST or map EXPR, LIST.  Because Perl doesn't look
4196 ahead for the closing C<}> it has to take a guess at which it's dealing with
4197 based on what it finds just after the
4198 C<{>.  Usually it gets it right, but if it
4199 doesn't it won't realize something is wrong until it gets to the C<}> and
4200 encounters the missing (or unexpected) comma.  The syntax error will be
4201 reported close to the C<}>, but you'll need to change something near the C<{>
4202 such as using a unary C<+> or semicolon to give Perl some help:
4203
4204  my %hash = map {  "\L$_" => 1  } @array # perl guesses EXPR. wrong
4205  my %hash = map { +"\L$_" => 1  } @array # perl guesses BLOCK. right
4206  my %hash = map {; "\L$_" => 1  } @array # this also works
4207  my %hash = map { ("\L$_" => 1) } @array # as does this
4208  my %hash = map {  lc($_) => 1  } @array # and this.
4209  my %hash = map +( lc($_) => 1 ), @array # this is EXPR and works!
4210
4211  my %hash = map  ( lc($_), 1 ),   @array # evaluates to (1, @array)
4212
4213 or to force an anon hash constructor use C<+{>:
4214
4215     my @hashes = map +{ lc($_) => 1 }, @array # EXPR, so needs
4216                                               # comma at end
4217
4218 to get a list of anonymous hashes each with only one entry apiece.
4219
4220 =item mkdir FILENAME,MODE
4221 X<mkdir> X<md> X<directory, create>
4222
4223 =item mkdir FILENAME
4224
4225 =item mkdir
4226
4227 =for Pod::Functions create a directory
4228
4229 Creates the directory specified by FILENAME, with permissions
4230 specified by MODE (as modified by L<C<umask>|/umask EXPR>).  If it
4231 succeeds it returns true; otherwise it returns false and sets
4232 L<C<$!>|perlvar/$!> (errno).
4233 MODE defaults to 0777 if omitted, and FILENAME defaults
4234 to L<C<$_>|perlvar/$_> if omitted.
4235
4236 In general, it is better to create directories with a permissive MODE
4237 and let the user modify that with their L<C<umask>|/umask EXPR> than it
4238 is to supply
4239 a restrictive MODE and give the user no way to be more permissive.
4240 The exceptions to this rule are when the file or directory should be
4241 kept private (mail files, for instance).  The documentation for
4242 L<C<umask>|/umask EXPR> discusses the choice of MODE in more detail.
4243
4244 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
4245 number of trailing slashes.  Some operating and filesystems do not get
4246 this right, so Perl automatically removes all trailing slashes to keep
4247 everyone happy.
4248
4249 To recursively create a directory structure, look at
4250 the L<C<make_path>|File::Path/make_path( $dir1, $dir2, .... )> function
4251 of the L<File::Path> module.
4252
4253 =item msgctl ID,CMD,ARG
4254 X<msgctl>
4255
4256 =for Pod::Functions SysV IPC message control operations
4257
4258 Calls the System V IPC function L<msgctl(2)>.  You'll probably have to say
4259
4260     use IPC::SysV;
4261
4262 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
4263 then ARG must be a variable that will hold the returned C<msqid_ds>
4264 structure.  Returns like L<C<ioctl>|/ioctl FILEHANDLE,FUNCTION,SCALAR>:
4265 the undefined value for error, C<"0 but true"> for zero, or the actual
4266 return value otherwise.  See also L<perlipc/"SysV IPC"> and the
4267 documentation for L<C<IPC::SysV>|IPC::SysV> and
4268 L<C<IPC::Semaphore>|IPC::Semaphore>.
4269
4270 Portability issues: L<perlport/msgctl>.
4271
4272 =item msgget KEY,FLAGS
4273 X<msgget>
4274
4275 =for Pod::Functions get SysV IPC message queue
4276
4277 Calls the System V IPC function L<msgget(2)>.  Returns the message queue
4278 id, or L<C<undef>|/undef EXPR> on error.  See also L<perlipc/"SysV IPC">
4279 and the documentation for L<C<IPC::SysV>|IPC::SysV> and
4280 L<C<IPC::Msg>|IPC::Msg>.
4281
4282 Portability issues: L<perlport/msgget>.
4283
4284 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
4285 X<msgrcv>
4286
4287 =for Pod::Functions receive a SysV IPC message from a message queue
4288
4289 Calls the System V IPC function msgrcv to receive a message from
4290 message queue ID into variable VAR with a maximum message size of
4291 SIZE.  Note that when a message is received, the message type as a
4292 native long integer will be the first thing in VAR, followed by the
4293 actual message.  This packing may be opened with C<unpack("l! a*")>.
4294 Taints the variable.  Returns true if successful, false
4295 on error.  See also L<perlipc/"SysV IPC"> and the documentation for
4296 L<C<IPC::SysV>|IPC::SysV> and L<C<IPC::Msg>|IPC::Msg>.
4297
4298 Portability issues: L<perlport/msgrcv>.
4299
4300 =item msgsnd ID,MSG,FLAGS
4301 X<msgsnd>
4302
4303 =for Pod::Functions send a SysV IPC message to a message queue
4304
4305 Calls the System V IPC function msgsnd to send the message MSG to the
4306 message queue ID.  MSG must begin with the native long integer message
4307 type, be followed by the length of the actual message, and then finally
4308 the message itself.  This kind of packing can be achieved with
4309 C<pack("l! a*", $type, $message)>.  Returns true if successful,
4310 false on error.  See also L<perlipc/"SysV IPC"> and the documentation
4311 for L<C<IPC::SysV>|IPC::SysV> and L<C<IPC::Msg>|IPC::Msg>.
4312
4313 Portability issues: L<perlport/msgsnd>.
4314
4315 =item my VARLIST
4316 X<my>
4317
4318 =item my TYPE VARLIST
4319
4320 =item my VARLIST : ATTRS
4321
4322 =item my TYPE VARLIST : ATTRS
4323
4324 =for Pod::Functions declare and assign a local variable (lexical scoping)
4325
4326 A L<C<my>|/my VARLIST> declares the listed variables to be local
4327 (lexically) to the enclosing block, file, or L<C<eval>|/eval EXPR>.  If
4328 more than one variable is listed, the list must be placed in
4329 parentheses.
4330
4331 The exact semantics and interface of TYPE and ATTRS are still
4332 evolving.  TYPE may be a bareword, a constant declared
4333 with L<C<use constant>|constant>, or L<C<__PACKAGE__>|/__PACKAGE__>.  It
4334 is
4335 currently bound to the use of the L<fields> pragma,
4336 and attributes are handled using the L<attributes> pragma, or starting
4337 from Perl 5.8.0 also via the L<Attribute::Handlers> module.  See
4338 L<perlsub/"Private Variables via my()"> for details.
4339
4340 Note that with a parenthesised list, L<C<undef>|/undef EXPR> can be used
4341 as a dummy placeholder, for example to skip assignment of initial
4342 values:
4343
4344     my ( undef, $min, $hour ) = localtime;
4345
4346 =item next LABEL
4347 X<next> X<continue>
4348
4349 =item next EXPR
4350
4351 =item next
4352
4353 =for Pod::Functions iterate a block prematurely
4354
4355 The L<C<next>|/next LABEL> command is like the C<continue> statement in
4356 C; it starts the next iteration of the loop:
4357
4358     LINE: while (<STDIN>) {
4359         next LINE if /^#/;  # discard comments
4360         #...
4361     }
4362
4363 Note that if there were a L<C<continue>|/continue BLOCK> block on the
4364 above, it would get
4365 executed even on discarded lines.  If LABEL is omitted, the command
4366 refers to the innermost enclosing loop.  The C<next EXPR> form, available
4367 as of Perl 5.18.0, allows a label name to be computed at run time, being
4368 otherwise identical to C<next LABEL>.
4369
4370 L<C<next>|/next LABEL> cannot return a value from a block that typically
4371 returns a value, such as C<eval {}>, C<sub {}>, or C<do {}>. It will perform
4372 its flow control behavior, which precludes any return value. It should not be
4373 used to exit a L<C<grep>|/grep BLOCK LIST> or L<C<map>|/map BLOCK LIST>
4374 operation.
4375
4376 Note that a block by itself is semantically identical to a loop
4377 that executes once.  Thus L<C<next>|/next LABEL> will exit such a block
4378 early.
4379
4380 See also L<C<continue>|/continue BLOCK> for an illustration of how
4381 L<C<last>|/last LABEL>, L<C<next>|/next LABEL>, and
4382 L<C<redo>|/redo LABEL> work.
4383
4384 Unlike most named operators, this has the same precedence as assignment.
4385 It is also exempt from the looks-like-a-function rule, so
4386 C<next ("foo")."bar"> will cause "bar" to be part of the argument to
4387 L<C<next>|/next LABEL>.
4388
4389 =item no MODULE VERSION LIST
4390 X<no declarations>
4391 X<unimporting>
4392
4393 =item no MODULE VERSION
4394
4395 =item no MODULE LIST
4396
4397 =item no MODULE
4398
4399 =item no VERSION
4400
4401 =for Pod::Functions unimport some module symbols or semantics at compile time
4402
4403 See the L<C<use>|/use Module VERSION LIST> function, of which
4404 L<C<no>|/no MODULE VERSION LIST> is the opposite.
4405
4406 =item oct EXPR
4407 X<oct> X<octal> X<hex> X<hexadecimal> X<binary> X<bin>
4408
4409 =item oct
4410
4411 =for Pod::Functions convert a string to an octal number
4412
4413 Interprets EXPR as an octal string and returns the corresponding
4414 value.  (If EXPR happens to start off with C<0x>, interprets it as a
4415 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
4416 binary string.  Leading whitespace is ignored in all three cases.)
4417 The following will handle decimal, binary, octal, and hex in standard
4418 Perl notation:
4419
4420     $val = oct($val) if $val =~ /^0/;
4421
4422 If EXPR is omitted, uses L<C<$_>|perlvar/$_>.   To go the other way
4423 (produce a number in octal), use L<C<sprintf>|/sprintf FORMAT, LIST> or
4424 L<C<printf>|/printf FILEHANDLE FORMAT, LIST>:
4425
4426     my $dec_perms = (stat("filename"))[2] & 07777;
4427     my $oct_perm_str = sprintf "%o", $perms;
4428
4429 The L<C<oct>|/oct EXPR> function is commonly used when a string such as
4430 C<644> needs
4431 to be converted into a file mode, for example.  Although Perl
4432 automatically converts strings into numbers as needed, this automatic
4433 conversion assumes base 10.
4434
4435 Leading white space is ignored without warning, as too are any trailing
4436 non-digits, such as a decimal point (L<C<oct>|/oct EXPR> only handles
4437 non-negative integers, not negative integers or floating point).
4438
4439 =item open FILEHANDLE,EXPR
4440 X<open> X<pipe> X<file, open> X<fopen>
4441
4442 =item open FILEHANDLE,MODE,EXPR
4443
4444 =item open FILEHANDLE,MODE,EXPR,LIST
4445
4446 =item open FILEHANDLE,MODE,REFERENCE
4447
4448 =item open FILEHANDLE
4449
4450 =for Pod::Functions open a file, pipe, or descriptor
4451
4452 Opens the file whose filename is given by EXPR, and associates it with
4453 FILEHANDLE.
4454
4455 Simple examples to open a file for reading:
4456
4457     open(my $fh, "<", "input.txt")
4458         or die "Can't open < input.txt: $!";
4459
4460 and for writing:
4461
4462     open(my $fh, ">", "output.txt")
4463         or die "Can't open > output.txt: $!";
4464
4465 (The following is a comprehensive reference to
4466 L<C<open>|/open FILEHANDLE,EXPR>: for a gentler introduction you may
4467 consider L<perlopentut>.)
4468
4469 If FILEHANDLE is an undefined scalar variable (or array or hash element), a
4470 new filehandle is autovivified, meaning that the variable is assigned a
4471 reference to a newly allocated anonymous filehandle.  Otherwise if
4472 FILEHANDLE is an expression, its value is the real filehandle.  (This is
4473 considered a symbolic reference, so C<use strict "refs"> should I<not> be
4474 in effect.)
4475
4476 If three (or more) arguments are specified, the open mode (including
4477 optional encoding) in the second argument are distinct from the filename in
4478 the third.  If MODE is C<< < >> or nothing, the file is opened for input.
4479 If MODE is C<< > >>, the file is opened for output, with existing files
4480 first being truncated ("clobbered") and nonexisting files newly created.
4481 If MODE is C<<< >> >>>, the file is opened for appending, again being
4482 created if necessary.
4483
4484 You can put a C<+> in front of the C<< > >> or C<< < >> to
4485 indicate that you want both read and write access to the file; thus
4486 C<< +< >> is almost always preferred for read/write updates--the
4487 C<< +> >> mode would clobber the file first.  You can't usually use
4488 either read-write mode for updating textfiles, since they have
4489 variable-length records.  See the B<-i> switch in
4490 L<perlrun|perlrun/-i[extension]> for a better approach.  The file is
4491 created with permissions of C<0666> modified by the process's
4492 L<C<umask>|/umask EXPR> value.
4493
4494 These various prefixes correspond to the L<fopen(3)> modes of C<r>,
4495 C<r+>, C<w>, C<w+>, C<a>, and C<a+>.
4496
4497 In the one- and two-argument forms of the call, the mode and filename
4498 should be concatenated (in that order), preferably separated by white
4499 space.  You can--but shouldn't--omit the mode in these forms when that mode
4500 is C<< < >>.  It is safe to use the two-argument form of
4501 L<C<open>|/open FILEHANDLE,EXPR> if the filename argument is a known literal.
4502
4503 For three or more arguments if MODE is C<|->, the filename is
4504 interpreted as a command to which output is to be piped, and if MODE
4505 is C<-|>, the filename is interpreted as a command that pipes
4506 output to us.  In the two-argument (and one-argument) form, one should
4507 replace dash (C<->) with the command.
4508 See L<perlipc/"Using open() for IPC"> for more examples of this.
4509 (You are not allowed to L<C<open>|/open FILEHANDLE,EXPR> to a command
4510 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>, and
4511 L<perlipc/"Bidirectional Communication with Another Process"> for
4512 alternatives.)
4513
4514 In the form of pipe opens taking three or more arguments, if LIST is specified
4515 (extra arguments after the command name) then LIST becomes arguments
4516 to the command invoked if the platform supports it.  The meaning of
4517 L<C<open>|/open FILEHANDLE,EXPR> with more than three arguments for
4518 non-pipe modes is not yet defined, but experimental "layers" may give
4519 extra LIST arguments meaning.
4520
4521 In the two-argument (and one-argument) form, opening C<< <- >>
4522 or C<-> opens STDIN and opening C<< >- >> opens STDOUT.
4523
4524 You may (and usually should) use the three-argument form of open to specify
4525 I/O layers (sometimes referred to as "disciplines") to apply to the handle
4526 that affect how the input and output are processed (see L<open> and
4527 L<PerlIO> for more details).  For example:
4528
4529   open(my $fh, "<:encoding(UTF-8)", $filename)
4530     || die "Can't open UTF-8 encoded $filename: $!";
4531
4532 opens the UTF8-encoded file containing Unicode characters;
4533 see L<perluniintro>.  Note that if layers are specified in the
4534 three-argument form, then default layers stored in ${^OPEN} (see L<perlvar>;
4535 usually set by the L<open> pragma or the switch C<-CioD>) are ignored.
4536 Those layers will also be ignored if you specify a colon with no name
4537 following it.  In that case the default layer for the operating system
4538 (:raw on Unix, :crlf on Windows) is used.
4539
4540 Open returns nonzero on success, the undefined value otherwise.  If
4541 the L<C<open>|/open FILEHANDLE,EXPR> involved a pipe, the return value
4542 happens to be the pid of the subprocess.
4543
4544 On some systems (in general, DOS- and Windows-based systems)
4545 L<C<binmode>|/binmode FILEHANDLE, LAYER> is necessary when you're not
4546 working with a text file.  For the sake of portability it is a good idea
4547 always to use it when appropriate, and never to use it when it isn't
4548 appropriate.  Also, people can set their I/O to be by default
4549 UTF8-encoded Unicode, not bytes.
4550
4551 When opening a file, it's seldom a good idea to continue
4552 if the request failed, so L<C<open>|/open FILEHANDLE,EXPR> is frequently
4553 used with L<C<die>|/die LIST>.  Even if L<C<die>|/die LIST> won't do
4554 what you want (say, in a CGI script,
4555 where you want to format a suitable error message (but there are
4556 modules that can help with that problem)) always check
4557 the return value from opening a file.
4558
4559 The filehandle will be closed when its reference count reaches zero.
4560 If it is a lexically scoped variable declared with L<C<my>|/my VARLIST>,
4561 that usually
4562 means the end of the enclosing scope.  However, this automatic close
4563 does not check for errors, so it is better to explicitly close
4564 filehandles, especially those used for writing:
4565
4566     close($handle)
4567        || warn "close failed: $!";
4568
4569 An older style is to use a bareword as the filehandle, as
4570
4571     open(FH, "<", "input.txt")
4572        or die "Can't open < input.txt: $!";
4573
4574 Then you can use C<FH> as the filehandle, in C<< close FH >> and C<<
4575 <FH> >> and so on.  Note that it's a global variable, so this form is
4576 not recommended in new code.
4577
4578 As a shortcut a one-argument call takes the filename from the global
4579 scalar variable of the same name as the filehandle:
4580
4581     $ARTICLE = 100;
4582     open(ARTICLE) or die "Can't find article $ARTICLE: $!\n";
4583
4584 Here C<$ARTICLE> must be a global (package) scalar variable - not one
4585 declared with L<C<my>|/my VARLIST> or L<C<state>|/state VARLIST>.
4586
4587 As a special case the three-argument form with a read/write mode and the third
4588 argument being L<C<undef>|/undef EXPR>:
4589
4590     open(my $tmp, "+>", undef) or die ...
4591
4592 opens a filehandle to a newly created empty anonymous temporary file.
4593 (This happens under any mode, which makes C<< +> >> the only useful and
4594 sensible mode to use.)  You will need to
4595 L<C<seek>|/seek FILEHANDLE,POSITION,WHENCE> to do the reading.
4596
4597 Perl is built using PerlIO by default.  Unless you've
4598 changed this (such as building Perl with C<Configure -Uuseperlio>), you can
4599 open filehandles directly to Perl scalars via:
4600
4601     open(my $fh, ">", \$variable) || ..
4602
4603 To (re)open C<STDOUT> or C<STDERR> as an in-memory file, close it first:
4604
4605     close STDOUT;
4606     open(STDOUT, ">", \$variable)
4607         or die "Can't open STDOUT: $!";
4608
4609 The scalars for in-memory files are treated as octet strings: unless
4610 the file is being opened with truncation the scalar may not contain
4611 any code points over 0xFF.
4612
4613 Opening in-memory files I<can> fail for a variety of reasons.  As with
4614 any other C<open>, check the return value for success.
4615
4616 See L<perliol> for detailed info on PerlIO.
4617
4618 General examples:
4619
4620  open(my $log, ">>", "/usr/spool/news/twitlog");
4621  # if the open fails, output is discarded
4622
4623  open(my $dbase, "+<", "dbase.mine")      # open for update
4624      or die "Can't open 'dbase.mine' for update: $!";
4625
4626  open(my $dbase, "+<dbase.mine")          # ditto
4627      or die "Can't open 'dbase.mine' for update: $!";
4628
4629  open(my $article_fh, "-|", "caesar <$article")  # decrypt
4630                                                  # article
4631      or die "Can't start caesar: $!";
4632
4633  open(my $article_fh, "caesar <$article |")      # ditto
4634      or die "Can't start caesar: $!";
4635
4636  open(my $out_fh, "|-", "sort >Tmp$$")    # $$ is our process id
4637      or die "Can't start sort: $!";
4638
4639  # in-memory files
4640  open(my $memory, ">", \$var)
4641      or die "Can't open memory file: $!";
4642  print $memory "foo!\n";              # output will appear in $var
4643
4644 You may also, in the Bourne shell tradition, specify an EXPR beginning
4645 with C<< >& >>, in which case the rest of the string is interpreted
4646 as the name of a filehandle (or file descriptor, if numeric) to be
4647 duped (as in L<dup(2)>) and opened.  You may use C<&> after C<< > >>,
4648 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
4649 The mode you specify should match the mode of the original filehandle.
4650 (Duping a filehandle does not take into account any existing contents
4651 of IO buffers.)  If you use the three-argument
4652 form, then you can pass either a
4653 number, the name of a filehandle, or the normal "reference to a glob".
4654
4655 Here is a script that saves, redirects, and restores C<STDOUT> and
4656 C<STDERR> using various methods:
4657
4658     #!/usr/bin/perl
4659     open(my $oldout, ">&STDOUT")     or die "Can't dup STDOUT: $!";
4660     open(OLDERR,     ">&", \*STDERR) or die "Can't dup STDERR: $!";
4661
4662     open(STDOUT, '>', "foo.out") or die "Can't redirect STDOUT: $!";
4663     open(STDERR, ">&STDOUT")     or die "Can't dup STDOUT: $!";
4664
4665     select STDERR; $| = 1;  # make unbuffered
4666     select STDOUT; $| = 1;  # make unbuffered
4667
4668     print STDOUT "stdout 1\n";  # this works for
4669     print STDERR "stderr 1\n";  # subprocesses too
4670
4671     open(STDOUT, ">&", $oldout) or die "Can't dup \$oldout: $!";
4672     open(STDERR, ">&OLDERR")    or die "Can't dup OLDERR: $!";
4673
4674     print STDOUT "stdout 2\n";
4675     print STDERR "stderr 2\n";
4676
4677 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
4678 or a filehandle, then Perl will do an equivalent of C's L<fdopen(3)> of
4679 that file descriptor (and not call L<dup(2)>); this is more
4680 parsimonious of file descriptors.  For example:
4681
4682     # open for input, reusing the fileno of $fd
4683     open(my $fh, "<&=", $fd)
4684
4685 or
4686
4687     open(my $fh, "<&=$fd")
4688
4689 or
4690
4691     # open for append, using the fileno of $oldfh
4692     open(my $fh, ">>&=", $oldfh)