This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Update File-Path to CPAN version 2.11
[perl5.git] / cpan / File-Path / lib / File / Path.pm
1 package File::Path;
2
3 use 5.005_04;
4 use strict;
5
6 use Cwd 'getcwd';
7 use File::Basename ();
8 use File::Spec     ();
9
10 BEGIN {
11     if ( $] < 5.006 ) {
12
13         # can't say 'opendir my $dh, $dirname'
14         # need to initialise $dh
15         eval 'use Symbol';
16     }
17 }
18
19 use Exporter ();
20 use vars qw($VERSION @ISA @EXPORT @EXPORT_OK);
21 $VERSION   = '2.11';
22 $VERSION   = eval $VERSION;
23 @ISA       = qw(Exporter);
24 @EXPORT    = qw(mkpath rmtree);
25 @EXPORT_OK = qw(make_path remove_tree);
26
27 BEGIN {
28   for (qw(VMS MacOS MSWin32 os2)) {
29     no strict 'refs';
30     *{"_IS_\U$_"} = $^O eq $_ ? sub () { 1 } : sub () { 0 };
31   }
32
33   # These OSes complain if you want to remove a file that you have no
34   # write permission to:
35   *_FORCE_WRITABLE = (
36     grep { $^O eq $_ } qw(amigaos dos epoc MSWin32 MacOS os2)
37   ) ? sub () { 1 } : sub () { 0 };
38
39   # Unix-like systems need to stat each directory in order to detect
40   # race condition. MS-Windows is immune to this particular attack.
41   *_NEED_STAT_CHECK = !(_IS_MSWIN32()) ? sub () { 1 } : sub () { 0 };
42 }
43
44 sub _carp {
45     require Carp;
46     goto &Carp::carp;
47 }
48
49 sub _croak {
50     require Carp;
51     goto &Carp::croak;
52 }
53
54 sub _error {
55     my $arg     = shift;
56     my $message = shift;
57     my $object  = shift;
58
59     if ( $arg->{error} ) {
60         $object = '' unless defined $object;
61         $message .= ": $!" if $!;
62         push @{ ${ $arg->{error} } }, { $object => $message };
63     }
64     else {
65         _carp( defined($object) ? "$message for $object: $!" : "$message: $!" );
66     }
67 }
68
69 sub __is_arg {
70     my ($arg) = @_;
71
72     # If client code blessed an array ref to HASH, this will not work
73     # properly. We could have done $arg->isa() wrapped in eval, but
74     # that would be expensive. This implementation should suffice.
75     # We could have also used Scalar::Util:blessed, but we choose not
76     # to add this dependency
77     return ( ref $arg eq 'HASH' );
78 }
79
80 sub make_path {
81     push @_, {} unless @_ and __is_arg( $_[-1] );
82     goto &mkpath;
83 }
84
85 sub mkpath {
86     my $old_style = !( @_ and __is_arg( $_[-1] ) );
87
88     my $arg;
89     my $paths;
90
91     if ($old_style) {
92         my ( $verbose, $mode );
93         ( $paths, $verbose, $mode ) = @_;
94         $paths = [$paths] unless UNIVERSAL::isa( $paths, 'ARRAY' );
95         $arg->{verbose} = $verbose;
96         $arg->{mode} = defined $mode ? $mode : oct '777';
97     }
98     else {
99         my %args_permitted = map { $_ => 1 } ( qw|
100             chmod
101             error
102             group
103             mask
104             mode
105             owner
106             uid
107             user
108             verbose
109         | );
110         my @bad_args = ();
111         $arg = pop @_;
112         for my $k (sort keys %{$arg}) {
113             push @bad_args, $k unless $args_permitted{$k};
114         }
115         _carp("Unrecognized option(s) passed to make_path(): @bad_args")
116             if @bad_args;
117         $arg->{mode} = delete $arg->{mask} if exists $arg->{mask};
118         $arg->{mode} = oct '777' unless exists $arg->{mode};
119         ${ $arg->{error} } = [] if exists $arg->{error};
120         $arg->{owner} = delete $arg->{user} if exists $arg->{user};
121         $arg->{owner} = delete $arg->{uid}  if exists $arg->{uid};
122         if ( exists $arg->{owner} and $arg->{owner} =~ /\D/ ) {
123             my $uid = ( getpwnam $arg->{owner} )[2];
124             if ( defined $uid ) {
125                 $arg->{owner} = $uid;
126             }
127             else {
128                 _error( $arg,
129 "unable to map $arg->{owner} to a uid, ownership not changed"
130                 );
131                 delete $arg->{owner};
132             }
133         }
134         if ( exists $arg->{group} and $arg->{group} =~ /\D/ ) {
135             my $gid = ( getgrnam $arg->{group} )[2];
136             if ( defined $gid ) {
137                 $arg->{group} = $gid;
138             }
139             else {
140                 _error( $arg,
141 "unable to map $arg->{group} to a gid, group ownership not changed"
142                 );
143                 delete $arg->{group};
144             }
145         }
146         if ( exists $arg->{owner} and not exists $arg->{group} ) {
147             $arg->{group} = -1;    # chown will leave group unchanged
148         }
149         if ( exists $arg->{group} and not exists $arg->{owner} ) {
150             $arg->{owner} = -1;    # chown will leave owner unchanged
151         }
152         $paths = [@_];
153     }
154     return _mkpath( $arg, $paths );
155 }
156
157 sub _mkpath {
158     my $arg   = shift;
159     my $paths = shift;
160
161     my ( @created );
162     foreach my $path ( @{$paths} ) {
163         next unless defined($path) and length($path);
164         $path .= '/' if _IS_OS2 and $path =~ /^\w:\z/s; # feature of CRT
165
166         # Logic wants Unix paths, so go with the flow.
167         if (_IS_VMS) {
168             next if $path eq '/';
169             $path = VMS::Filespec::unixify($path);
170         }
171         next if -d $path;
172         my $parent = File::Basename::dirname($path);
173         unless ( -d $parent or $path eq $parent ) {
174             push( @created, _mkpath( $arg, [$parent] ) );
175         }
176         print "mkdir $path\n" if $arg->{verbose};
177         if ( mkdir( $path, $arg->{mode} ) ) {
178             push( @created, $path );
179             if ( exists $arg->{owner} ) {
180
181                 # NB: $arg->{group} guaranteed to be set during initialisation
182                 if ( !chown $arg->{owner}, $arg->{group}, $path ) {
183                     _error( $arg,
184 "Cannot change ownership of $path to $arg->{owner}:$arg->{group}"
185                     );
186                 }
187             }
188             if ( exists $arg->{chmod} ) {
189                 if ( !chmod $arg->{chmod}, $path ) {
190                     _error( $arg,
191                         "Cannot change permissions of $path to $arg->{chmod}" );
192                 }
193             }
194         }
195         else {
196             my $save_bang = $!;
197             my ( $e, $e1 ) = ( $save_bang, $^E );
198             $e .= "; $e1" if $e ne $e1;
199
200             # allow for another process to have created it meanwhile
201             if ( ! -d $path ) {
202                 $! = $save_bang;
203                 if ( $arg->{error} ) {
204                     push @{ ${ $arg->{error} } }, { $path => $e };
205                 }
206                 else {
207                     _croak("mkdir $path: $e");
208                 }
209             }
210         }
211     }
212     return @created;
213 }
214
215 sub remove_tree {
216     push @_, {} unless @_ and __is_arg( $_[-1] );
217     goto &rmtree;
218 }
219
220 sub _is_subdir {
221     my ( $dir, $test ) = @_;
222
223     my ( $dv, $dd ) = File::Spec->splitpath( $dir,  1 );
224     my ( $tv, $td ) = File::Spec->splitpath( $test, 1 );
225
226     # not on same volume
227     return 0 if $dv ne $tv;
228
229     my @d = File::Spec->splitdir($dd);
230     my @t = File::Spec->splitdir($td);
231
232     # @t can't be a subdir if it's shorter than @d
233     return 0 if @t < @d;
234
235     return join( '/', @d ) eq join( '/', splice @t, 0, +@d );
236 }
237
238 sub rmtree {
239     my $old_style = !( @_ and __is_arg( $_[-1] ) );
240
241     my $arg;
242     my $paths;
243
244     if ($old_style) {
245         my ( $verbose, $safe );
246         ( $paths, $verbose, $safe ) = @_;
247         $arg->{verbose} = $verbose;
248         $arg->{safe} = defined $safe ? $safe : 0;
249
250         if ( defined($paths) and length($paths) ) {
251             $paths = [$paths] unless UNIVERSAL::isa( $paths, 'ARRAY' );
252         }
253         else {
254             _carp("No root path(s) specified\n");
255             return 0;
256         }
257     }
258     else {
259         my %args_permitted = map { $_ => 1 } ( qw|
260             error
261             keep_root
262             result
263             safe
264             verbose
265         | );
266         my @bad_args = ();
267         $arg = pop @_;
268         for my $k (sort keys %{$arg}) {
269             push @bad_args, $k unless $args_permitted{$k};
270         }
271         _carp("Unrecognized option(s) passed to remove_tree(): @bad_args")
272             if @bad_args;
273         ${ $arg->{error} }  = [] if exists $arg->{error};
274         ${ $arg->{result} } = [] if exists $arg->{result};
275         $paths = [@_];
276     }
277
278     $arg->{prefix} = '';
279     $arg->{depth}  = 0;
280
281     my @clean_path;
282     $arg->{cwd} = getcwd() or do {
283         _error( $arg, "cannot fetch initial working directory" );
284         return 0;
285     };
286     for ( $arg->{cwd} ) { /\A(.*)\Z/s; $_ = $1 }    # untaint
287
288     for my $p (@$paths) {
289
290         # need to fixup case and map \ to / on Windows
291         my $ortho_root = _IS_MSWIN32 ? _slash_lc($p) : $p;
292         my $ortho_cwd =
293           _IS_MSWIN32 ? _slash_lc( $arg->{cwd} ) : $arg->{cwd};
294         my $ortho_root_length = length($ortho_root);
295         $ortho_root_length-- if _IS_VMS;   # don't compare '.' with ']'
296         if ( $ortho_root_length && _is_subdir( $ortho_root, $ortho_cwd ) ) {
297             local $! = 0;
298             _error( $arg, "cannot remove path when cwd is $arg->{cwd}", $p );
299             next;
300         }
301
302         if (_IS_MACOS) {
303             $p = ":$p" unless $p =~ /:/;
304             $p .= ":" unless $p =~ /:\z/;
305         }
306         elsif ( _IS_MSWIN32 ) {
307             $p =~ s{[/\\]\z}{};
308         }
309         else {
310             $p =~ s{/\z}{};
311         }
312         push @clean_path, $p;
313     }
314
315     @{$arg}{qw(device inode perm)} = ( lstat $arg->{cwd} )[ 0, 1 ] or do {
316         _error( $arg, "cannot stat initial working directory", $arg->{cwd} );
317         return 0;
318     };
319
320     return _rmtree( $arg, \@clean_path );
321 }
322
323 sub _rmtree {
324     my $arg   = shift;
325     my $paths = shift;
326
327     my $count  = 0;
328     my $curdir = File::Spec->curdir();
329     my $updir  = File::Spec->updir();
330
331     my ( @files, $root );
332   ROOT_DIR:
333     foreach my $root (@$paths) {
334
335         # since we chdir into each directory, it may not be obvious
336         # to figure out where we are if we generate a message about
337         # a file name. We therefore construct a semi-canonical
338         # filename, anchored from the directory being unlinked (as
339         # opposed to being truly canonical, anchored from the root (/).
340
341         my $canon =
342           $arg->{prefix}
343           ? File::Spec->catfile( $arg->{prefix}, $root )
344           : $root;
345
346         my ( $ldev, $lino, $perm ) = ( lstat $root )[ 0, 1, 2 ]
347           or ( _error( $arg, "$root", $root ) and next ROOT_DIR );
348
349         if ( -d _ ) {
350             $root = VMS::Filespec::vmspath( VMS::Filespec::pathify($root) )
351               if _IS_VMS;
352
353             if ( !chdir($root) ) {
354
355                 # see if we can escalate privileges to get in
356                 # (e.g. funny protection mask such as -w- instead of rwx)
357                 $perm &= oct '7777';
358                 my $nperm = $perm | oct '700';
359                 if (
360                     !(
361                            $arg->{safe}
362                         or $nperm == $perm
363                         or chmod( $nperm, $root )
364                     )
365                   )
366                 {
367                     _error( $arg,
368                         "cannot make child directory read-write-exec", $canon );
369                     next ROOT_DIR;
370                 }
371                 elsif ( !chdir($root) ) {
372                     _error( $arg, "cannot chdir to child", $canon );
373                     next ROOT_DIR;
374                 }
375             }
376
377             my ( $cur_dev, $cur_inode, $perm ) = ( stat $curdir )[ 0, 1, 2 ]
378               or do {
379                 _error( $arg, "cannot stat current working directory", $canon );
380                 next ROOT_DIR;
381               };
382
383             if (_NEED_STAT_CHECK) {
384                 ( $ldev eq $cur_dev and $lino eq $cur_inode )
385                   or _croak(
386 "directory $canon changed before chdir, expected dev=$ldev ino=$lino, actual dev=$cur_dev ino=$cur_inode, aborting."
387                   );
388             }
389
390             $perm &= oct '7777';    # don't forget setuid, setgid, sticky bits
391             my $nperm = $perm | oct '700';
392
393             # notabene: 0700 is for making readable in the first place,
394             # it's also intended to change it to writable in case we have
395             # to recurse in which case we are better than rm -rf for
396             # subtrees with strange permissions
397
398             if (
399                 !(
400                        $arg->{safe}
401                     or $nperm == $perm
402                     or chmod( $nperm, $curdir )
403                 )
404               )
405             {
406                 _error( $arg, "cannot make directory read+writeable", $canon );
407                 $nperm = $perm;
408             }
409
410             my $d;
411             $d = gensym() if $] < 5.006;
412             if ( !opendir $d, $curdir ) {
413                 _error( $arg, "cannot opendir", $canon );
414                 @files = ();
415             }
416             else {
417                 if ( !defined ${^TAINT} or ${^TAINT} ) {
418                     # Blindly untaint dir names if taint mode is active
419                     @files = map { /\A(.*)\z/s; $1 } readdir $d;
420                 }
421                 else {
422                     @files = readdir $d;
423                 }
424                 closedir $d;
425             }
426
427             if (_IS_VMS) {
428
429                 # Deleting large numbers of files from VMS Files-11
430                 # filesystems is faster if done in reverse ASCIIbetical order.
431                 # include '.' to '.;' from blead patch #31775
432                 @files = map { $_ eq '.' ? '.;' : $_ } reverse @files;
433             }
434
435             @files = grep { $_ ne $updir and $_ ne $curdir } @files;
436
437             if (@files) {
438
439                 # remove the contained files before the directory itself
440                 my $narg = {%$arg};
441                 @{$narg}{qw(device inode cwd prefix depth)} =
442                   ( $cur_dev, $cur_inode, $updir, $canon, $arg->{depth} + 1 );
443                 $count += _rmtree( $narg, \@files );
444             }
445
446             # restore directory permissions of required now (in case the rmdir
447             # below fails), while we are still in the directory and may do so
448             # without a race via '.'
449             if ( $nperm != $perm and not chmod( $perm, $curdir ) ) {
450                 _error( $arg, "cannot reset chmod", $canon );
451             }
452
453             # don't leave the client code in an unexpected directory
454             chdir( $arg->{cwd} )
455               or
456               _croak("cannot chdir to $arg->{cwd} from $canon: $!, aborting.");
457
458             # ensure that a chdir upwards didn't take us somewhere other
459             # than we expected (see CVE-2002-0435)
460             ( $cur_dev, $cur_inode ) = ( stat $curdir )[ 0, 1 ]
461               or _croak(
462                 "cannot stat prior working directory $arg->{cwd}: $!, aborting."
463               );
464
465             if (_NEED_STAT_CHECK) {
466                 ( $arg->{device} eq $cur_dev and $arg->{inode} eq $cur_inode )
467                   or _croak(  "previous directory $arg->{cwd} "
468                             . "changed before entering $canon, "
469                             . "expected dev=$ldev ino=$lino, "
470                             . "actual dev=$cur_dev ino=$cur_inode, aborting."
471                   );
472             }
473
474             if ( $arg->{depth} or !$arg->{keep_root} ) {
475                 if ( $arg->{safe}
476                     && ( _IS_VMS
477                         ? !&VMS::Filespec::candelete($root)
478                         : !-w $root ) )
479                 {
480                     print "skipped $root\n" if $arg->{verbose};
481                     next ROOT_DIR;
482                 }
483                 if ( _FORCE_WRITABLE and !chmod $perm | oct '700', $root ) {
484                     _error( $arg, "cannot make directory writeable", $canon );
485                 }
486                 print "rmdir $root\n" if $arg->{verbose};
487                 if ( rmdir $root ) {
488                     push @{ ${ $arg->{result} } }, $root if $arg->{result};
489                     ++$count;
490                 }
491                 else {
492                     _error( $arg, "cannot remove directory", $canon );
493                     if (
494                         _FORCE_WRITABLE
495                         && !chmod( $perm,
496                             ( _IS_VMS ? VMS::Filespec::fileify($root) : $root )
497                         )
498                       )
499                     {
500                         _error(
501                             $arg,
502                             sprintf( "cannot restore permissions to 0%o",
503                                 $perm ),
504                             $canon
505                         );
506                     }
507                 }
508             }
509         }
510         else {
511             # not a directory
512             $root = VMS::Filespec::vmsify("./$root")
513               if _IS_VMS
514               && !File::Spec->file_name_is_absolute($root)
515               && ( $root !~ m/(?<!\^)[\]>]+/ );    # not already in VMS syntax
516
517             if (
518                 $arg->{safe}
519                 && (
520                     _IS_VMS
521                     ? !&VMS::Filespec::candelete($root)
522                     : !( -l $root || -w $root )
523                 )
524               )
525             {
526                 print "skipped $root\n" if $arg->{verbose};
527                 next ROOT_DIR;
528             }
529
530             my $nperm = $perm & oct '7777' | oct '600';
531             if (    _FORCE_WRITABLE
532                 and $nperm != $perm
533                 and not chmod $nperm, $root )
534             {
535                 _error( $arg, "cannot make file writeable", $canon );
536             }
537             print "unlink $canon\n" if $arg->{verbose};
538
539             # delete all versions under VMS
540             for ( ; ; ) {
541                 if ( unlink $root ) {
542                     push @{ ${ $arg->{result} } }, $root if $arg->{result};
543                 }
544                 else {
545                     _error( $arg, "cannot unlink file", $canon );
546                     _FORCE_WRITABLE and chmod( $perm, $root )
547                       or _error( $arg,
548                         sprintf( "cannot restore permissions to 0%o", $perm ),
549                         $canon );
550                     last;
551                 }
552                 ++$count;
553                 last unless _IS_VMS && lstat $root;
554             }
555         }
556     }
557     return $count;
558 }
559
560 sub _slash_lc {
561
562     # fix up slashes and case on MSWin32 so that we can determine that
563     # c:\path\to\dir is underneath C:/Path/To
564     my $path = shift;
565     $path =~ tr{\\}{/};
566     return lc($path);
567 }
568
569 1;
570
571 __END__
572
573 =head1 NAME
574
575 File::Path - Create or remove directory trees
576
577 =head1 VERSION
578
579 This document describes version 2.09 of File::Path, released
580 2013-01-17.
581
582 =head1 SYNOPSIS
583
584   use File::Path qw(make_path remove_tree);
585
586   @created = make_path('foo/bar/baz', '/zug/zwang');
587   @created = make_path('foo/bar/baz', '/zug/zwang', {
588       verbose => 1,
589       mode => 0711,
590   });
591   make_path('foo/bar/baz', '/zug/zwang', {
592       chmod => 0777,
593   });
594
595   $removed_count = remove_tree('foo/bar/baz', '/zug/zwang');
596   $removed_count = remove_tree('foo/bar/baz', '/zug/zwang', {
597       verbose => 1,
598       error  => \my $err_list,
599   });
600
601   # legacy (interface promoted before v2.00)
602   @created = mkpath('/foo/bar/baz');
603   @created = mkpath('/foo/bar/baz', 1, 0711);
604   @created = mkpath(['/foo/bar/baz', 'blurfl/quux'], 1, 0711);
605   $removed_count = rmtree('foo/bar/baz', 1, 1);
606   $removed_count = rmtree(['foo/bar/baz', 'blurfl/quux'], 1, 1);
607
608   # legacy (interface promoted before v2.06)
609   @created = mkpath('foo/bar/baz', '/zug/zwang', { verbose => 1, mode => 0711 });
610   $removed_count = rmtree('foo/bar/baz', '/zug/zwang', { verbose => 1, mode => 0711 });
611
612 =head1 DESCRIPTION
613
614 This module provide a convenient way to create directories of
615 arbitrary depth and to delete an entire directory subtree from the
616 filesystem.
617
618 The following functions are provided:
619
620 =over
621
622 =item make_path( $dir1, $dir2, .... )
623
624 =item make_path( $dir1, $dir2, ...., \%opts )
625
626 The C<make_path> function creates the given directories if they don't
627 exists before, much like the Unix command C<mkdir -p>.
628
629 The function accepts a list of directories to be created. Its
630 behaviour may be tuned by an optional hashref appearing as the last
631 parameter on the call.
632
633 The function returns the list of directories actually created during
634 the call; in scalar context the number of directories created.
635
636 The following keys are recognised in the option hash:
637
638 =over
639
640 =item mode => $num
641
642 The numeric permissions mode to apply to each created directory
643 (defaults to 0777), to be modified by the current C<umask>. If the
644 directory already exists (and thus does not need to be created),
645 the permissions will not be modified.
646
647 C<mask> is recognised as an alias for this parameter.
648
649 =item chmod => $num
650
651 Takes a numeric mode to apply to each created directory (not
652 modified by the current C<umask>). If the directory already exists
653 (and thus does not need to be created), the permissions will
654 not be modified.
655
656 =item verbose => $bool
657
658 If present, will cause C<make_path> to print the name of each directory
659 as it is created. By default nothing is printed.
660
661 =item error => \$err
662
663 If present, it should be a reference to a scalar.
664 This scalar will be made to reference an array, which will
665 be used to store any errors that are encountered.  See the L</"ERROR
666 HANDLING"> section for more information.
667
668 If this parameter is not used, certain error conditions may raise
669 a fatal error that will cause the program to halt, unless trapped
670 in an C<eval> block.
671
672 =item owner => $owner
673
674 =item user => $owner
675
676 =item uid => $owner
677
678 If present, will cause any created directory to be owned by C<$owner>.
679 If the value is numeric, it will be interpreted as a uid, otherwise
680 as username is assumed. An error will be issued if the username cannot be
681 mapped to a uid, or the uid does not exist, or the process lacks the
682 privileges to change ownership.
683
684 Ownership of directories that already exist will not be changed.
685
686 C<user> and C<uid> are aliases of C<owner>.
687
688 =item group => $group
689
690 If present, will cause any created directory to be owned by the group C<$group>.
691 If the value is numeric, it will be interpreted as a gid, otherwise
692 as group name is assumed. An error will be issued if the group name cannot be
693 mapped to a gid, or the gid does not exist, or the process lacks the
694 privileges to change group ownership.
695
696 Group ownership of directories that already exist will not be changed.
697
698     make_path '/var/tmp/webcache', {owner=>'nobody', group=>'nogroup'};
699
700 =back
701
702 =item mkpath( $dir )
703
704 =item mkpath( $dir, $verbose, $mode )
705
706 =item mkpath( [$dir1, $dir2,...], $verbose, $mode )
707
708 =item mkpath( $dir1, $dir2,..., \%opt )
709
710 The mkpath() function provide the legacy interface of make_path() with
711 a different interpretation of the arguments passed.  The behaviour and
712 return value of the function is otherwise identical to make_path().
713
714 =item remove_tree( $dir1, $dir2, .... )
715
716 =item remove_tree( $dir1, $dir2, ...., \%opts )
717
718 The C<remove_tree> function deletes the given directories and any
719 files and subdirectories they might contain, much like the Unix
720 command C<rm -r> or the Windows commands C<rmdir /s> and C<rd /s>.
721
722 The function accepts a list of directories to be
723 removed. Its behaviour may be tuned by an optional hashref
724 appearing as the last parameter on the call.
725
726 The functions returns the number of files successfully deleted.
727
728 The following keys are recognised in the option hash:
729
730 =over
731
732 =item verbose => $bool
733
734 If present, will cause C<remove_tree> to print the name of each file as
735 it is unlinked. By default nothing is printed.
736
737 =item safe => $bool
738
739 When set to a true value, will cause C<remove_tree> to skip the files
740 for which the process lacks the required privileges needed to delete
741 files, such as delete privileges on VMS. In other words, the code
742 will make no attempt to alter file permissions. Thus, if the process
743 is interrupted, no filesystem object will be left in a more
744 permissive mode.
745
746 =item keep_root => $bool
747
748 When set to a true value, will cause all files and subdirectories
749 to be removed, except the initially specified directories. This comes
750 in handy when cleaning out an application's scratch directory.
751
752   remove_tree( '/tmp', {keep_root => 1} );
753
754 =item result => \$res
755
756 If present, it should be a reference to a scalar.
757 This scalar will be made to reference an array, which will
758 be used to store all files and directories unlinked
759 during the call. If nothing is unlinked, the array will be empty.
760
761   remove_tree( '/tmp', {result => \my $list} );
762   print "unlinked $_\n" for @$list;
763
764 This is a useful alternative to the C<verbose> key.
765
766 =item error => \$err
767
768 If present, it should be a reference to a scalar.
769 This scalar will be made to reference an array, which will
770 be used to store any errors that are encountered.  See the L</"ERROR
771 HANDLING"> section for more information.
772
773 Removing things is a much more dangerous proposition than
774 creating things. As such, there are certain conditions that
775 C<remove_tree> may encounter that are so dangerous that the only
776 sane action left is to kill the program.
777
778 Use C<error> to trap all that is reasonable (problems with
779 permissions and the like), and let it die if things get out
780 of hand. This is the safest course of action.
781
782 =back
783
784 =item rmtree( $dir )
785
786 =item rmtree( $dir, $verbose, $safe )
787
788 =item rmtree( [$dir1, $dir2,...], $verbose, $safe )
789
790 =item rmtree( $dir1, $dir2,..., \%opt )
791
792 The rmtree() function provide the legacy interface of remove_tree()
793 with a different interpretation of the arguments passed. The behaviour
794 and return value of the function is otherwise identical to
795 remove_tree().
796
797 =back
798
799 =head2 ERROR HANDLING
800
801 =over 4
802
803 =item B<NOTE:>
804
805 The following error handling mechanism is considered
806 experimental and is subject to change pending feedback from
807 users.
808
809 =back
810
811 If C<make_path> or C<remove_tree> encounter an error, a diagnostic
812 message will be printed to C<STDERR> via C<carp> (for non-fatal
813 errors), or via C<croak> (for fatal errors).
814
815 If this behaviour is not desirable, the C<error> attribute may be
816 used to hold a reference to a variable, which will be used to store
817 the diagnostics. The variable is made a reference to an array of hash
818 references.  Each hash contain a single key/value pair where the key
819 is the name of the file, and the value is the error message (including
820 the contents of C<$!> when appropriate).  If a general error is
821 encountered the diagnostic key will be empty.
822
823 An example usage looks like:
824
825   remove_tree( 'foo/bar', 'bar/rat', {error => \my $err} );
826   if (@$err) {
827       for my $diag (@$err) {
828           my ($file, $message) = %$diag;
829           if ($file eq '') {
830               print "general error: $message\n";
831           }
832           else {
833               print "problem unlinking $file: $message\n";
834           }
835       }
836   }
837   else {
838       print "No error encountered\n";
839   }
840
841 Note that if no errors are encountered, C<$err> will reference an
842 empty array.  This means that C<$err> will always end up TRUE; so you
843 need to test C<@$err> to determine if errors occurred.
844
845 =head2 NOTES
846
847 C<File::Path> blindly exports C<mkpath> and C<rmtree> into the
848 current namespace. These days, this is considered bad style, but
849 to change it now would break too much code. Nonetheless, you are
850 invited to specify what it is you are expecting to use:
851
852   use File::Path 'rmtree';
853
854 The routines C<make_path> and C<remove_tree> are B<not> exported
855 by default. You must specify which ones you want to use.
856
857   use File::Path 'remove_tree';
858
859 Note that a side-effect of the above is that C<mkpath> and C<rmtree>
860 are no longer exported at all. This is due to the way the C<Exporter>
861 module works. If you are migrating a codebase to use the new
862 interface, you will have to list everything explicitly. But that's
863 just good practice anyway.
864
865   use File::Path qw(remove_tree rmtree);
866
867 =head3 API CHANGES
868
869 The API was changed in the 2.0 branch. For a time, C<mkpath> and
870 C<rmtree> tried, unsuccessfully, to deal with the two different
871 calling mechanisms. This approach was considered a failure.
872
873 The new semantics are now only available with C<make_path> and
874 C<remove_tree>. The old semantics are only available through
875 C<mkpath> and C<rmtree>. Users are strongly encouraged to upgrade
876 to at least 2.08 in order to avoid surprises.
877
878 =head3 SECURITY CONSIDERATIONS
879
880 There were race conditions 1.x implementations of File::Path's
881 C<rmtree> function (although sometimes patched depending on the OS
882 distribution or platform). The 2.0 version contains code to avoid the
883 problem mentioned in CVE-2002-0435.
884
885 See the following pages for more information:
886
887   http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=286905
888   http://www.nntp.perl.org/group/perl.perl5.porters/2005/01/msg97623.html
889   http://www.debian.org/security/2005/dsa-696
890
891 Additionally, unless the C<safe> parameter is set (or the
892 third parameter in the traditional interface is TRUE), should a
893 C<remove_tree> be interrupted, files that were originally in read-only
894 mode may now have their permissions set to a read-write (or "delete
895 OK") mode.
896
897 =head1 DIAGNOSTICS
898
899 FATAL errors will cause the program to halt (C<croak>), since the
900 problem is so severe that it would be dangerous to continue. (This
901 can always be trapped with C<eval>, but it's not a good idea. Under
902 the circumstances, dying is the best thing to do).
903
904 SEVERE errors may be trapped using the modern interface. If the
905 they are not trapped, or the old interface is used, such an error
906 will cause the program will halt.
907
908 All other errors may be trapped using the modern interface, otherwise
909 they will be C<carp>ed about. Program execution will not be halted.
910
911 =over 4
912
913 =item mkdir [path]: [errmsg] (SEVERE)
914
915 C<make_path> was unable to create the path. Probably some sort of
916 permissions error at the point of departure, or insufficient resources
917 (such as free inodes on Unix).
918
919 =item No root path(s) specified
920
921 C<make_path> was not given any paths to create. This message is only
922 emitted if the routine is called with the traditional interface.
923 The modern interface will remain silent if given nothing to do.
924
925 =item No such file or directory
926
927 On Windows, if C<make_path> gives you this warning, it may mean that
928 you have exceeded your filesystem's maximum path length.
929
930 =item cannot fetch initial working directory: [errmsg]
931
932 C<remove_tree> attempted to determine the initial directory by calling
933 C<Cwd::getcwd>, but the call failed for some reason. No attempt
934 will be made to delete anything.
935
936 =item cannot stat initial working directory: [errmsg]
937
938 C<remove_tree> attempted to stat the initial directory (after having
939 successfully obtained its name via C<getcwd>), however, the call
940 failed for some reason. No attempt will be made to delete anything.
941
942 =item cannot chdir to [dir]: [errmsg]
943
944 C<remove_tree> attempted to set the working directory in order to
945 begin deleting the objects therein, but was unsuccessful. This is
946 usually a permissions issue. The routine will continue to delete
947 other things, but this directory will be left intact.
948
949 =item directory [dir] changed before chdir, expected dev=[n] ino=[n], actual dev=[n] ino=[n], aborting. (FATAL)
950
951 C<remove_tree> recorded the device and inode of a directory, and then
952 moved into it. It then performed a C<stat> on the current directory
953 and detected that the device and inode were no longer the same. As
954 this is at the heart of the race condition problem, the program
955 will die at this point.
956
957 =item cannot make directory [dir] read+writeable: [errmsg]
958
959 C<remove_tree> attempted to change the permissions on the current directory
960 to ensure that subsequent unlinkings would not run into problems,
961 but was unable to do so. The permissions remain as they were, and
962 the program will carry on, doing the best it can.
963
964 =item cannot read [dir]: [errmsg]
965
966 C<remove_tree> tried to read the contents of the directory in order
967 to acquire the names of the directory entries to be unlinked, but
968 was unsuccessful. This is usually a permissions issue. The
969 program will continue, but the files in this directory will remain
970 after the call.
971
972 =item cannot reset chmod [dir]: [errmsg]
973
974 C<remove_tree>, after having deleted everything in a directory, attempted
975 to restore its permissions to the original state but failed. The
976 directory may wind up being left behind.
977
978 =item cannot remove [dir] when cwd is [dir]
979
980 The current working directory of the program is F</some/path/to/here>
981 and you are attempting to remove an ancestor, such as F</some/path>.
982 The directory tree is left untouched.
983
984 The solution is to C<chdir> out of the child directory to a place
985 outside the directory tree to be removed.
986
987 =item cannot chdir to [parent-dir] from [child-dir]: [errmsg], aborting. (FATAL)
988
989 C<remove_tree>, after having deleted everything and restored the permissions
990 of a directory, was unable to chdir back to the parent. The program
991 halts to avoid a race condition from occurring.
992
993 =item cannot stat prior working directory [dir]: [errmsg], aborting. (FATAL)
994
995 C<remove_tree> was unable to stat the parent directory after have returned
996 from the child. Since there is no way of knowing if we returned to
997 where we think we should be (by comparing device and inode) the only
998 way out is to C<croak>.
999
1000 =item previous directory [parent-dir] changed before entering [child-dir], expected dev=[n] ino=[n], actual dev=[n] ino=[n], aborting. (FATAL)
1001
1002 When C<remove_tree> returned from deleting files in a child directory, a
1003 check revealed that the parent directory it returned to wasn't the one
1004 it started out from. This is considered a sign of malicious activity.
1005
1006 =item cannot make directory [dir] writeable: [errmsg]
1007
1008 Just before removing a directory (after having successfully removed
1009 everything it contained), C<remove_tree> attempted to set the permissions
1010 on the directory to ensure it could be removed and failed. Program
1011 execution continues, but the directory may possibly not be deleted.
1012
1013 =item cannot remove directory [dir]: [errmsg]
1014
1015 C<remove_tree> attempted to remove a directory, but failed. This may because
1016 some objects that were unable to be removed remain in the directory, or
1017 a permissions issue. The directory will be left behind.
1018
1019 =item cannot restore permissions of [dir] to [0nnn]: [errmsg]
1020
1021 After having failed to remove a directory, C<remove_tree> was unable to
1022 restore its permissions from a permissive state back to a possibly
1023 more restrictive setting. (Permissions given in octal).
1024
1025 =item cannot make file [file] writeable: [errmsg]
1026
1027 C<remove_tree> attempted to force the permissions of a file to ensure it
1028 could be deleted, but failed to do so. It will, however, still attempt
1029 to unlink the file.
1030
1031 =item cannot unlink file [file]: [errmsg]
1032
1033 C<remove_tree> failed to remove a file. Probably a permissions issue.
1034
1035 =item cannot restore permissions of [file] to [0nnn]: [errmsg]
1036
1037 After having failed to remove a file, C<remove_tree> was also unable
1038 to restore the permissions on the file to a possibly less permissive
1039 setting. (Permissions given in octal).
1040
1041 =item unable to map [owner] to a uid, ownership not changed");
1042
1043 C<make_path> was instructed to give the ownership of created
1044 directories to the symbolic name [owner], but C<getpwnam> did
1045 not return the corresponding numeric uid. The directory will
1046 be created, but ownership will not be changed.
1047
1048 =item unable to map [group] to a gid, group ownership not changed
1049
1050 C<make_path> was instructed to give the group ownership of created
1051 directories to the symbolic name [group], but C<getgrnam> did
1052 not return the corresponding numeric gid. The directory will
1053 be created, but group ownership will not be changed.
1054
1055 =back
1056
1057 =head1 SEE ALSO
1058
1059 =over 4
1060
1061 =item *
1062
1063 L<File::Remove>
1064
1065 Allows files and directories to be moved to the Trashcan/Recycle
1066 Bin (where they may later be restored if necessary) if the operating
1067 system supports such functionality. This feature may one day be
1068 made available directly in C<File::Path>.
1069
1070 =item *
1071
1072 L<File::Find::Rule>
1073
1074 When removing directory trees, if you want to examine each file to
1075 decide whether to delete it (and possibly leaving large swathes
1076 alone), F<File::Find::Rule> offers a convenient and flexible approach
1077 to examining directory trees.
1078
1079 =back
1080
1081 =head1 BUGS AND LIMITATIONS
1082
1083 The following describes F<File::Path> limitations and how to report bugs.
1084
1085 =head2 MULTITHREAD APPLICATIONS
1086
1087 F<File::Path> B<rmtree> and B<remove_tree> will not work with multithreaded
1088 applications due to its use of B<chdir>.  At this time, no warning or error
1089 results and you will certainly encounter unexpected results.
1090
1091 The implementation that surfaces this limitation may change in a future
1092 release.
1093
1094 =head2 NFS Mount Points
1095
1096 F<File::Path> is not responsible for triggering the automounts, mirror mounts,
1097 and the contents of network mounted filesystems.  If your NFS implementation
1098 requires an action to be performed on the filesystem in order for
1099 F<File::Path> to perform operations, it is strongly suggested you assure
1100 filesystem availability by reading the root of the mounted filesystem.
1101
1102 =head2 REPORTING BUGS
1103
1104 Please report all bugs on the RT queue, either via the web interface:
1105
1106 L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=File-Path>
1107
1108 or by email:
1109
1110     bug-File-Path@rt.cpan.org
1111
1112 In either case, please B<attach> patches to the bug report rather than
1113 including them inline in the web post or the body of the email.
1114
1115 You can also send pull requests to the Github repository:
1116
1117 L<https://github.com/rpcme/File-Path>
1118
1119 =head1 ACKNOWLEDGEMENTS
1120
1121 Paul Szabo identified the race condition originally, and Brendan
1122 O'Dea wrote an implementation for Debian that addressed the problem.
1123 That code was used as a basis for the current code. Their efforts
1124 are greatly appreciated.
1125
1126 Gisle Aas made a number of improvements to the documentation for
1127 2.07 and his advice and assistance is also greatly appreciated.
1128
1129 =head1 AUTHORS
1130
1131 Prior authors and maintainers: Tim Bunce, Charles Bailey, and
1132 David Landgren <F<david@landgren.net>>.
1133
1134 Current maintainers are Richard Elberger <F<riche@cpan.org>> and
1135 James (Jim) Keenan <F<jkeenan@cpan.org>>.
1136
1137 =head1 CONTRIBUTORS
1138
1139 Contributors to File::Path, in alphabetical order.
1140
1141 =over 1
1142
1143 =item <F<bulkdd@cpan.org>>
1144
1145 =item Richard Elberger <F<riche@cpan.org>>
1146
1147 =item Ryan Yee <F<ryee@cpan.org>>
1148
1149 =item Skye Shaw <F<shaw@cpan.org>>
1150
1151 =item Tom Lutz <F<tommylutz@gmail.com>>
1152
1153 =back
1154
1155 =head1 COPYRIGHT
1156
1157 This module is copyright (C) Charles Bailey, Tim Bunce, David Landgren,
1158 James Keenan, and Richard Elberger 1995-2015. All rights reserved.
1159
1160 =head1 LICENSE
1161
1162 This library is free software; you can redistribute it and/or modify
1163 it under the same terms as Perl itself.
1164
1165 =cut