This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
perlvar: Fix broken link
[perl5.git] / pod / perlvar.pod
1 =head1 NAME
2
3 perlvar - Perl predefined variables
4
5 =head1 DESCRIPTION
6
7 =head2 The Syntax of Variable Names
8
9 Variable names in Perl can have several formats.  Usually, they
10 must begin with a letter or underscore, in which case they can be
11 arbitrarily long (up to an internal limit of 251 characters) and
12 may contain letters, digits, underscores, or the special sequence
13 C<::> or C<'>.  In this case, the part before the last C<::> or
14 C<'> is taken to be a I<package qualifier>; see L<perlmod>.
15 A Unicode letter that is not ASCII is not considered to be a letter
16 unless S<C<"use utf8">> is in effect, and somewhat more complicated
17 rules apply; see L<perldata/Identifier parsing> for details.
18
19 Perl variable names may also be a sequence of digits, a single
20 punctuation character, or the two-character sequence: C<^> (caret or
21 CIRCUMFLEX ACCENT) followed by any one of the characters C<[][A-Z^_?\]>.
22 These names are all reserved for
23 special uses by Perl; for example, the all-digits names are used
24 to hold data captured by backreferences after a regular expression
25 match.
26
27 Since Perl v5.6.0, Perl variable names may also be alphanumeric strings
28 preceded by a caret.  These must all be written in the form C<${^Foo}>;
29 the braces are not optional.  C<${^Foo}> denotes the scalar variable
30 whose name is considered to be a control-C<F> followed by two C<o>'s.
31 These variables are
32 reserved for future special uses by Perl, except for the ones that
33 begin with C<^_> (caret-underscore).  No
34 name that begins with C<^_> will acquire a special
35 meaning in any future version of Perl; such names may therefore be
36 used safely in programs.  C<$^_> itself, however, I<is> reserved.
37
38 Perl identifiers that begin with digits or
39 punctuation characters are exempt from the effects of the C<package>
40 declaration and are always forced to be in package C<main>; they are
41 also exempt from C<strict 'vars'> errors.  A few other names are also
42 exempt in these ways:
43
44     ENV      STDIN
45     INC      STDOUT
46     ARGV     STDERR
47     ARGVOUT
48     SIG
49
50 In particular, the special C<${^_XYZ}> variables are always taken
51 to be in package C<main>, regardless of any C<package> declarations
52 presently in scope.
53
54 =head1 SPECIAL VARIABLES
55
56 The following names have special meaning to Perl.  Most punctuation
57 names have reasonable mnemonics, or analogs in the shells.
58 Nevertheless, if you wish to use long variable names, you need only say:
59
60     use English;
61
62 at the top of your program.  This aliases all the short names to the long
63 names in the current package.  Some even have medium names, generally
64 borrowed from B<awk>.  For more info, please see L<English>.
65
66 Before you continue, note the sort order for variables.  In general, we
67 first list the variables in case-insensitive, almost-lexigraphical
68 order (ignoring the C<{> or C<^> preceding words, as in C<${^UNICODE}>
69 or C<$^T>), although C<$_> and C<@_> move up to the top of the pile.
70 For variables with the same identifier, we list it in order of scalar,
71 array, hash, and bareword.
72
73 =head2 General Variables
74
75 =over 8
76
77 =item $ARG
78
79 =item $_
80 X<$_> X<$ARG>
81
82 The default input and pattern-searching space.  The following pairs are
83 equivalent:
84
85     while (<>) {...}    # equivalent only in while!
86     while (defined($_ = <>)) {...}
87
88     /^Subject:/
89     $_ =~ /^Subject:/
90
91     tr/a-z/A-Z/
92     $_ =~ tr/a-z/A-Z/
93
94     chomp
95     chomp($_)
96
97 Here are the places where Perl will assume C<$_> even if you don't use it:
98
99 =over 3
100
101 =item *
102
103 The following functions use C<$_> as a default argument:
104
105 abs, alarm, chomp, chop, chr, chroot,
106 cos, defined, eval, evalbytes, exp, fc, glob, hex, int, lc,
107 lcfirst, length, log, lstat, mkdir, oct, ord, pos, print, printf,
108 quotemeta, readlink, readpipe, ref, require, reverse (in scalar context only),
109 rmdir, say, sin, split (for its second
110 argument), sqrt, stat, study, uc, ucfirst,
111 unlink, unpack.
112
113 =item *
114
115 All file tests (C<-f>, C<-d>) except for C<-t>, which defaults to STDIN.
116 See L<perlfunc/-X>
117
118 =item *
119
120 The pattern matching operations C<m//>, C<s///> and C<tr///> (aka C<y///>)
121 when used without an C<=~> operator.
122
123 =item *
124
125 The default iterator variable in a C<foreach> loop if no other
126 variable is supplied.
127
128 =item *
129
130 The implicit iterator variable in the C<grep()> and C<map()> functions.
131
132 =item *
133
134 The implicit variable of C<given()>.
135
136 =item *
137
138 The default place to put the next value or input record
139 when a C<< <FH> >>, C<readline>, C<readdir> or C<each>
140 operation's result is tested by itself as the sole criterion of a C<while>
141 test.  Outside a C<while> test, this will not happen.
142
143 =back
144
145 C<$_> is a global variable.
146
147 However, between perl v5.10.0 and v5.24.0, it could be used lexically by
148 writing C<my $_>.  Making C<$_> refer to the global C<$_> in the same scope
149 was then possible with C<our $_>.  This experimental feature was removed and is
150 now a fatal error, but you may encounter it in older code.
151
152 Mnemonic: underline is understood in certain operations.
153
154 =item @ARG
155
156 =item @_
157 X<@_> X<@ARG>
158
159 Within a subroutine the array C<@_> contains the parameters passed to
160 that subroutine.  Inside a subroutine, C<@_> is the default array for
161 the array operators C<pop> and C<shift>.
162
163 See L<perlsub>.
164
165 =item $LIST_SEPARATOR
166
167 =item $"
168 X<$"> X<$LIST_SEPARATOR>
169
170 When an array or an array slice is interpolated into a double-quoted
171 string or a similar context such as C</.../>, its elements are
172 separated by this value.  Default is a space.  For example, this:
173
174     print "The array is: @array\n";
175
176 is equivalent to this:
177
178     print "The array is: " . join($", @array) . "\n";
179
180 Mnemonic: works in double-quoted context.
181
182 =item $PROCESS_ID
183
184 =item $PID
185
186 =item $$
187 X<$$> X<$PID> X<$PROCESS_ID>
188
189 The process number of the Perl running this script.  Though you I<can> set
190 this variable, doing so is generally discouraged, although it can be
191 invaluable for some testing purposes.  It will be reset automatically
192 across C<fork()> calls.
193
194 Note for Linux and Debian GNU/kFreeBSD users: Before Perl v5.16.0 perl
195 would emulate POSIX semantics on Linux systems using LinuxThreads, a
196 partial implementation of POSIX Threads that has since been superseded
197 by the Native POSIX Thread Library (NPTL).
198
199 LinuxThreads is now obsolete on Linux, and caching C<getpid()>
200 like this made embedding perl unnecessarily complex (since you'd have
201 to manually update the value of $$), so now C<$$> and C<getppid()>
202 will always return the same values as the underlying C library.
203
204 Debian GNU/kFreeBSD systems also used LinuxThreads up until and
205 including the 6.0 release, but after that moved to FreeBSD thread
206 semantics, which are POSIX-like.
207
208 To see if your system is affected by this discrepancy check if
209 C<getconf GNU_LIBPTHREAD_VERSION | grep -q NPTL> returns a false
210 value.  NTPL threads preserve the POSIX semantics.
211
212 Mnemonic: same as shells.
213
214 =item $PROGRAM_NAME
215
216 =item $0
217 X<$0> X<$PROGRAM_NAME>
218
219 Contains the name of the program being executed.
220
221 On some (but not all) operating systems assigning to C<$0> modifies
222 the argument area that the C<ps> program sees.  On some platforms you
223 may have to use special C<ps> options or a different C<ps> to see the
224 changes.  Modifying the C<$0> is more useful as a way of indicating the
225 current program state than it is for hiding the program you're
226 running.
227
228 Note that there are platform-specific limitations on the maximum
229 length of C<$0>.  In the most extreme case it may be limited to the
230 space occupied by the original C<$0>.
231
232 In some platforms there may be arbitrary amount of padding, for
233 example space characters, after the modified name as shown by C<ps>.
234 In some platforms this padding may extend all the way to the original
235 length of the argument area, no matter what you do (this is the case
236 for example with Linux 2.2).
237
238 Note for BSD users: setting C<$0> does not completely remove "perl"
239 from the ps(1) output.  For example, setting C<$0> to C<"foobar"> may
240 result in C<"perl: foobar (perl)"> (whether both the C<"perl: "> prefix
241 and the " (perl)" suffix are shown depends on your exact BSD variant
242 and version).  This is an operating system feature, Perl cannot help it.
243
244 In multithreaded scripts Perl coordinates the threads so that any
245 thread may modify its copy of the C<$0> and the change becomes visible
246 to ps(1) (assuming the operating system plays along).  Note that
247 the view of C<$0> the other threads have will not change since they
248 have their own copies of it.
249
250 If the program has been given to perl via the switches C<-e> or C<-E>,
251 C<$0> will contain the string C<"-e">.
252
253 On Linux as of perl v5.14.0 the legacy process name will be set with
254 C<prctl(2)>, in addition to altering the POSIX name via C<argv[0]> as
255 perl has done since version 4.000.  Now system utilities that read the
256 legacy process name such as ps, top and killall will recognize the
257 name you set when assigning to C<$0>.  The string you supply will be
258 cut off at 16 bytes, this is a limitation imposed by Linux.
259
260 Mnemonic: same as B<sh> and B<ksh>.
261
262 =item $REAL_GROUP_ID
263
264 =item $GID
265
266 =item $(
267 X<$(> X<$GID> X<$REAL_GROUP_ID>
268
269 The real gid of this process.  If you are on a machine that supports
270 membership in multiple groups simultaneously, gives a space separated
271 list of groups you are in.  The first number is the one returned by
272 C<getgid()>, and the subsequent ones by C<getgroups()>, one of which may be
273 the same as the first number.
274
275 However, a value assigned to C<$(> must be a single number used to
276 set the real gid.  So the value given by C<$(> should I<not> be assigned
277 back to C<$(> without being forced numeric, such as by adding zero.  Note
278 that this is different to the effective gid (C<$)>) which does take a
279 list.
280
281 You can change both the real gid and the effective gid at the same
282 time by using C<POSIX::setgid()>.  Changes
283 to C<$(> require a check to C<$!>
284 to detect any possible errors after an attempted change.
285
286 Mnemonic: parentheses are used to I<group> things.  The real gid is the
287 group you I<left>, if you're running setgid.
288
289 =item $EFFECTIVE_GROUP_ID
290
291 =item $EGID
292
293 =item $)
294 X<$)> X<$EGID> X<$EFFECTIVE_GROUP_ID>
295
296 The effective gid of this process.  If you are on a machine that
297 supports membership in multiple groups simultaneously, gives a space
298 separated list of groups you are in.  The first number is the one
299 returned by C<getegid()>, and the subsequent ones by C<getgroups()>,
300 one of which may be the same as the first number.
301
302 Similarly, a value assigned to C<$)> must also be a space-separated
303 list of numbers.  The first number sets the effective gid, and
304 the rest (if any) are passed to C<setgroups()>.  To get the effect of an
305 empty list for C<setgroups()>, just repeat the new effective gid; that is,
306 to force an effective gid of 5 and an effectively empty C<setgroups()>
307 list, say C< $) = "5 5" >.
308
309 You can change both the effective gid and the real gid at the same
310 time by using C<POSIX::setgid()> (use only a single numeric argument).
311 Changes to C<$)> require a check to C<$!> to detect any possible errors
312 after an attempted change.
313
314 C<< $< >>, C<< $> >>, C<$(> and C<$)> can be set only on
315 machines that support the corresponding I<set[re][ug]id()> routine.  C<$(>
316 and C<$)> can be swapped only on machines supporting C<setregid()>.
317
318 Mnemonic: parentheses are used to I<group> things.  The effective gid
319 is the group that's I<right> for you, if you're running setgid.
320
321 =item $REAL_USER_ID
322
323 =item $UID
324
325 =item $<
326 X<< $< >> X<$UID> X<$REAL_USER_ID>
327
328 The real uid of this process.  You can change both the real uid and the
329 effective uid at the same time by using C<POSIX::setuid()>.  Since
330 changes to C<< $< >> require a system call, check C<$!> after a change
331 attempt to detect any possible errors.
332
333 Mnemonic: it's the uid you came I<from>, if you're running setuid.
334
335 =item $EFFECTIVE_USER_ID
336
337 =item $EUID
338
339 =item $>
340 X<< $> >> X<$EUID> X<$EFFECTIVE_USER_ID>
341
342 The effective uid of this process.  For example:
343
344     $< = $>;            # set real to effective uid
345     ($<,$>) = ($>,$<);  # swap real and effective uids
346
347 You can change both the effective uid and the real uid at the same
348 time by using C<POSIX::setuid()>.  Changes to C<< $> >> require a check
349 to C<$!> to detect any possible errors after an attempted change.
350
351 C<< $< >> and C<< $> >> can be swapped only on machines
352 supporting C<setreuid()>.
353
354 Mnemonic: it's the uid you went I<to>, if you're running setuid.
355
356 =item $SUBSCRIPT_SEPARATOR
357
358 =item $SUBSEP
359
360 =item $;
361 X<$;> X<$SUBSEP> X<SUBSCRIPT_SEPARATOR>
362
363 The subscript separator for multidimensional array emulation.  If you
364 refer to a hash element as
365
366     $foo{$x,$y,$z}
367
368 it really means
369
370     $foo{join($;, $x, $y, $z)}
371
372 But don't put
373
374     @foo{$x,$y,$z}      # a slice--note the @
375
376 which means
377
378     ($foo{$x},$foo{$y},$foo{$z})
379
380 Default is "\034", the same as SUBSEP in B<awk>.  If your keys contain
381 binary data there might not be any safe value for C<$;>.
382
383 Consider using "real" multidimensional arrays as described
384 in L<perllol>.
385
386 Mnemonic: comma (the syntactic subscript separator) is a semi-semicolon.
387
388 =item $a
389
390 =item $b
391 X<$a> X<$b>
392
393 Special package variables when using C<sort()>, see L<perlfunc/sort>.
394 Because of this specialness C<$a> and C<$b> don't need to be declared
395 (using C<use vars>, or C<our()>) even when using the C<strict 'vars'>
396 pragma.  Don't lexicalize them with C<my $a> or C<my $b> if you want to
397 be able to use them in the C<sort()> comparison block or function.
398
399 =item %ENV
400 X<%ENV>
401
402 The hash C<%ENV> contains your current environment.  Setting a
403 value in C<ENV> changes the environment for any child processes
404 you subsequently C<fork()> off.
405
406 As of v5.18.0, both keys and values stored in C<%ENV> are stringified.
407
408     my $foo = 1;
409     $ENV{'bar'} = \$foo;
410     if( ref $ENV{'bar'} ) {
411         say "Pre 5.18.0 Behaviour";
412     } else {
413         say "Post 5.18.0 Behaviour";
414     }
415
416 Previously, only child processes received stringified values:
417
418     my $foo = 1;
419     $ENV{'bar'} = \$foo;
420
421     # Always printed 'non ref'
422     system($^X, '-e',
423            q/print ( ref $ENV{'bar'}  ? 'ref' : 'non ref' ) /);
424
425 This happens because you can't really share arbitrary data structures with
426 foreign processes.
427
428 =item $OLD_PERL_VERSION
429
430 =item $]
431 X<$]> X<$OLD_PERL_VERSION>
432
433 The revision, version, and subversion of the Perl interpreter, represented
434 as a decimal of the form 5.XXXYYY, where XXX is the version / 1e3 and YYY
435 is the subversion / 1e6.  For example, Perl v5.10.1 would be "5.010001".
436
437 This variable can be used to determine whether the Perl interpreter
438 executing a script is in the right range of versions:
439
440     warn "No PerlIO!\n" if $] lt '5.008';
441
442 When comparing C<$]>, string comparison operators are B<highly
443 recommended>.  The inherent limitations of binary floating point
444 representation can sometimes lead to incorrect comparisons for some
445 numbers on some architectures.
446
447 See also the documentation of C<use VERSION> and C<require VERSION>
448 for a convenient way to fail if the running Perl interpreter is too old.
449
450 See L</$^V> for a representation of the Perl version as a L<version>
451 object, which allows more flexible string comparisons.
452
453 The main advantage of C<$]> over C<$^V> is that it works the same on any
454 version of Perl.  The disadvantages are that it can't easily be compared
455 to versions in other formats (e.g. literal v-strings, "v1.2.3" or
456 version objects) and numeric comparisons can occasionally fail; it's good
457 for string literal version checks and bad for comparing to a variable
458 that hasn't been sanity-checked.
459
460 The C<$OLD_PERL_VERSION> form was added in Perl v5.20.0 for historical
461 reasons but its use is discouraged. (If your reason to use C<$]> is to
462 run code on old perls then referring to it as C<$OLD_PERL_VERSION> would
463 be self-defeating.)
464
465 Mnemonic: Is this version of perl in the right bracket?
466
467 =item $SYSTEM_FD_MAX
468
469 =item $^F
470 X<$^F> X<$SYSTEM_FD_MAX>
471
472 The maximum system file descriptor, ordinarily 2.  System file
473 descriptors are passed to C<exec()>ed processes, while higher file
474 descriptors are not.  Also, during an
475 C<open()>, system file descriptors are
476 preserved even if the C<open()> fails (ordinary file descriptors are
477 closed before the C<open()> is attempted).  The close-on-exec
478 status of a file descriptor will be decided according to the value of
479 C<$^F> when the corresponding file, pipe, or socket was opened, not the
480 time of the C<exec()>.
481
482 =item @F
483 X<@F>
484
485 The array C<@F> contains the fields of each line read in when autosplit
486 mode is turned on.  See L<perlrun> for the B<-a> switch.  This array
487 is package-specific, and must be declared or given a full package name
488 if not in package main when running under C<strict 'vars'>.
489
490 =item @INC
491 X<@INC>
492
493 The array C<@INC> contains the list of places that the C<do EXPR>,
494 C<require>, or C<use> constructs look for their library files.  It
495 initially consists of the arguments to any B<-I> command-line
496 switches, followed by the default Perl library, probably
497 F</usr/local/lib/perl>, followed by ".", to represent the current
498 directory.  ("." will not be appended if taint checks are enabled,
499 either by C<-T> or by C<-t>, or if configured not to do so by the
500 C<-Ddefault_inc_excludes_dot> compile time option.)  If you need to
501 modify this at runtime, you should use the C<use lib> pragma to get
502 the machine-dependent library properly loaded also:
503
504     use lib '/mypath/libdir/';
505     use SomeMod;
506
507 You can also insert hooks into the file inclusion system by putting Perl
508 code directly into C<@INC>.  Those hooks may be subroutine references,
509 array references or blessed objects.  See L<perlfunc/require> for details.
510
511 =item %INC
512 X<%INC>
513
514 The hash C<%INC> contains entries for each filename included via the
515 C<do>, C<require>, or C<use> operators.  The key is the filename
516 you specified (with module names converted to pathnames), and the
517 value is the location of the file found.  The C<require>
518 operator uses this hash to determine whether a particular file has
519 already been included.
520
521 If the file was loaded via a hook (e.g. a subroutine reference, see
522 L<perlfunc/require> for a description of these hooks), this hook is
523 by default inserted into C<%INC> in place of a filename.  Note, however,
524 that the hook may have set the C<%INC> entry by itself to provide some more
525 specific info.
526
527 =item $INPLACE_EDIT
528
529 =item $^I
530 X<$^I> X<$INPLACE_EDIT>
531
532 The current value of the inplace-edit extension.  Use C<undef> to disable
533 inplace editing.
534
535 Mnemonic: value of B<-i> switch.
536
537 =item @ISA
538 X<@ISA>
539
540 Each package contains a special array called C<@ISA> which contains a list
541 of that class's parent classes, if any. This array is simply a list of
542 scalars, each of which is a string that corresponds to a package name. The
543 array is examined when Perl does method resolution, which is covered in
544 L<perlobj>.
545
546 To load packages while adding them to C<@ISA>, see the L<parent> pragma. The
547 discouraged L<base> pragma does this as well, but should not be used except
548 when compatibility with the discouraged L<fields> pragma is required.
549
550 =item $^M
551 X<$^M>
552
553 By default, running out of memory is an untrappable, fatal error.
554 However, if suitably built, Perl can use the contents of C<$^M>
555 as an emergency memory pool after C<die()>ing.  Suppose that your Perl
556 were compiled with C<-DPERL_EMERGENCY_SBRK> and used Perl's malloc.
557 Then
558
559     $^M = 'a' x (1 << 16);
560
561 would allocate a 64K buffer for use in an emergency.  See the
562 F<INSTALL> file in the Perl distribution for information on how to
563 add custom C compilation flags when compiling perl.  To discourage casual
564 use of this advanced feature, there is no L<English|English> long name for
565 this variable.
566
567 This variable was added in Perl 5.004.
568
569 =item $OSNAME
570
571 =item $^O
572 X<$^O> X<$OSNAME>
573
574 The name of the operating system under which this copy of Perl was
575 built, as determined during the configuration process.  For examples
576 see L<perlport/PLATFORMS>.
577
578 The value is identical to C<$Config{'osname'}>.  See also L<Config>
579 and the B<-V> command-line switch documented in L<perlrun>.
580
581 In Windows platforms, C<$^O> is not very helpful: since it is always
582 C<MSWin32>, it doesn't tell the difference between
583 95/98/ME/NT/2000/XP/CE/.NET.  Use C<Win32::GetOSName()> or
584 Win32::GetOSVersion() (see L<Win32> and L<perlport>) to distinguish
585 between the variants.
586
587 This variable was added in Perl 5.003.
588
589 =item %SIG
590 X<%SIG>
591
592 The hash C<%SIG> contains signal handlers for signals.  For example:
593
594     sub handler {   # 1st argument is signal name
595         my($sig) = @_;
596         print "Caught a SIG$sig--shutting down\n";
597         close(LOG);
598         exit(0);
599         }
600
601     $SIG{'INT'}  = \&handler;
602     $SIG{'QUIT'} = \&handler;
603     ...
604     $SIG{'INT'}  = 'DEFAULT';   # restore default action
605     $SIG{'QUIT'} = 'IGNORE';    # ignore SIGQUIT
606
607 Using a value of C<'IGNORE'> usually has the effect of ignoring the
608 signal, except for the C<CHLD> signal.  See L<perlipc> for more about
609 this special case.
610
611 Here are some other examples:
612
613     $SIG{"PIPE"} = "Plumber";   # assumes main::Plumber (not
614                                 # recommended)
615     $SIG{"PIPE"} = \&Plumber;   # just fine; assume current
616                                 # Plumber
617     $SIG{"PIPE"} = *Plumber;    # somewhat esoteric
618     $SIG{"PIPE"} = Plumber();   # oops, what did Plumber()
619                                 # return??
620
621 Be sure not to use a bareword as the name of a signal handler,
622 lest you inadvertently call it.
623
624 If your system has the C<sigaction()> function then signal handlers
625 are installed using it.  This means you get reliable signal handling.
626
627 The default delivery policy of signals changed in Perl v5.8.0 from
628 immediate (also known as "unsafe") to deferred, also known as "safe
629 signals".  See L<perlipc> for more information.
630
631 Certain internal hooks can be also set using the C<%SIG> hash.  The
632 routine indicated by C<$SIG{__WARN__}> is called when a warning
633 message is about to be printed.  The warning message is passed as the
634 first argument.  The presence of a C<__WARN__> hook causes the
635 ordinary printing of warnings to C<STDERR> to be suppressed.  You can
636 use this to save warnings in a variable, or turn warnings into fatal
637 errors, like this:
638
639     local $SIG{__WARN__} = sub { die $_[0] };
640     eval $proggie;
641
642 As the C<'IGNORE'> hook is not supported by C<__WARN__>, you can
643 disable warnings using the empty subroutine:
644
645     local $SIG{__WARN__} = sub {};
646
647 The routine indicated by C<$SIG{__DIE__}> is called when a fatal
648 exception is about to be thrown.  The error message is passed as the
649 first argument.  When a C<__DIE__> hook routine returns, the exception
650 processing continues as it would have in the absence of the hook,
651 unless the hook routine itself exits via a C<goto &sub>, a loop exit,
652 or a C<die()>.  The C<__DIE__> handler is explicitly disabled during
653 the call, so that you can die from a C<__DIE__> handler.  Similarly
654 for C<__WARN__>.
655
656 The C<$SIG{__DIE__}> hook is called even inside an C<eval()>. It was
657 never intended to happen this way, but an implementation glitch made
658 this possible. This used to be deprecated, as it allowed strange action
659 at a distance like rewriting a pending exception in C<$@>. Plans to
660 rectify this have been scrapped, as users found that rewriting a 
661 pending exception is actually a useful feature, and not a bug.
662
663 C<__DIE__>/C<__WARN__> handlers are very special in one respect: they
664 may be called to report (probable) errors found by the parser.  In such
665 a case the parser may be in inconsistent state, so any attempt to
666 evaluate Perl code from such a handler will probably result in a
667 segfault.  This means that warnings or errors that result from parsing
668 Perl should be used with extreme caution, like this:
669
670     require Carp if defined $^S;
671     Carp::confess("Something wrong") if defined &Carp::confess;
672     die "Something wrong, but could not load Carp to give "
673       . "backtrace...\n\t"
674       . "To see backtrace try starting Perl with -MCarp switch";
675
676 Here the first line will load C<Carp> I<unless> it is the parser who
677 called the handler.  The second line will print backtrace and die if
678 C<Carp> was available.  The third line will be executed only if C<Carp> was
679 not available.
680
681 Having to even think about the C<$^S> variable in your exception
682 handlers is simply wrong.  C<$SIG{__DIE__}> as currently implemented
683 invites grievous and difficult to track down errors.  Avoid it
684 and use an C<END{}> or CORE::GLOBAL::die override instead.
685
686 See L<perlfunc/die>, L<perlfunc/warn>, L<perlfunc/eval>, and
687 L<warnings> for additional information.
688
689 =item $BASETIME
690
691 =item $^T
692 X<$^T> X<$BASETIME>
693
694 The time at which the program began running, in seconds since the
695 epoch (beginning of 1970).  The values returned by the B<-M>, B<-A>,
696 and B<-C> filetests are based on this value.
697
698 =item $PERL_VERSION
699
700 =item $^V
701 X<$^V> X<$PERL_VERSION>
702
703 The revision, version, and subversion of the Perl interpreter,
704 represented as a L<version> object.
705
706 This variable first appeared in perl v5.6.0; earlier versions of perl
707 will see an undefined value.  Before perl v5.10.0 C<$^V> was represented
708 as a v-string rather than a L<version> object.
709
710 C<$^V> can be used to determine whether the Perl interpreter executing
711 a script is in the right range of versions.  For example:
712
713     warn "Hashes not randomized!\n" if !$^V or $^V lt v5.8.1
714
715 While version objects overload stringification, to portably convert
716 C<$^V> into its string representation, use C<sprintf()>'s C<"%vd">
717 conversion, which works for both v-strings or version objects:
718
719     printf "version is v%vd\n", $^V;  # Perl's version
720
721 See the documentation of C<use VERSION> and C<require VERSION>
722 for a convenient way to fail if the running Perl interpreter is too old.
723
724 See also C<L</$]>> for a decimal representation of the Perl version.
725
726 The main advantage of C<$^V> over C<$]> is that, for Perl v5.10.0 or
727 later, it overloads operators, allowing easy comparison against other
728 version representations (e.g. decimal, literal v-string, "v1.2.3", or
729 objects).  The disadvantage is that prior to v5.10.0, it was only a
730 literal v-string, which can't be easily printed or compared, whereas
731 the behavior of C<$]> is unchanged on all versions of Perl.
732
733 Mnemonic: use ^V for a version object.
734
735 =item ${^WIN32_SLOPPY_STAT}
736 X<${^WIN32_SLOPPY_STAT}> X<sitecustomize> X<sitecustomize.pl>
737
738 If this variable is set to a true value, then C<stat()> on Windows will
739 not try to open the file.  This means that the link count cannot be
740 determined and file attributes may be out of date if additional
741 hardlinks to the file exist.  On the other hand, not opening the file
742 is considerably faster, especially for files on network drives.
743
744 This variable could be set in the F<sitecustomize.pl> file to
745 configure the local Perl installation to use "sloppy" C<stat()> by
746 default.  See the documentation for B<-f> in
747 L<perlrun|perlrun/"Command Switches"> for more information about site
748 customization.
749
750 This variable was added in Perl v5.10.0.
751
752 =item $EXECUTABLE_NAME
753
754 =item $^X
755 X<$^X> X<$EXECUTABLE_NAME>
756
757 The name used to execute the current copy of Perl, from C's
758 C<argv[0]> or (where supported) F</proc/self/exe>.
759
760 Depending on the host operating system, the value of C<$^X> may be
761 a relative or absolute pathname of the perl program file, or may
762 be the string used to invoke perl but not the pathname of the
763 perl program file.  Also, most operating systems permit invoking
764 programs that are not in the PATH environment variable, so there
765 is no guarantee that the value of C<$^X> is in PATH.  For VMS, the
766 value may or may not include a version number.
767
768 You usually can use the value of C<$^X> to re-invoke an independent
769 copy of the same perl that is currently running, e.g.,
770
771     @first_run = `$^X -le "print int rand 100 for 1..100"`;
772
773 But recall that not all operating systems support forking or
774 capturing of the output of commands, so this complex statement
775 may not be portable.
776
777 It is not safe to use the value of C<$^X> as a path name of a file,
778 as some operating systems that have a mandatory suffix on
779 executable files do not require use of the suffix when invoking
780 a command.  To convert the value of C<$^X> to a path name, use the
781 following statements:
782
783     # Build up a set of file names (not command names).
784     use Config;
785     my $this_perl = $^X;
786     if ($^O ne 'VMS') {
787         $this_perl .= $Config{_exe}
788           unless $this_perl =~ m/$Config{_exe}$/i;
789         }
790
791 Because many operating systems permit anyone with read access to
792 the Perl program file to make a copy of it, patch the copy, and
793 then execute the copy, the security-conscious Perl programmer
794 should take care to invoke the installed copy of perl, not the
795 copy referenced by C<$^X>.  The following statements accomplish
796 this goal, and produce a pathname that can be invoked as a
797 command or referenced as a file.
798
799     use Config;
800     my $secure_perl_path = $Config{perlpath};
801     if ($^O ne 'VMS') {
802         $secure_perl_path .= $Config{_exe}
803             unless $secure_perl_path =~ m/$Config{_exe}$/i;
804         }
805
806 =back
807
808 =head2 Variables related to regular expressions
809
810 Most of the special variables related to regular expressions are side
811 effects.  Perl sets these variables when it has a successful match, so
812 you should check the match result before using them.  For instance:
813
814     if( /P(A)TT(ER)N/ ) {
815         print "I found $1 and $2\n";
816         }
817
818 These variables are read-only and dynamically-scoped, unless we note
819 otherwise.
820
821 The dynamic nature of the regular expression variables means that
822 their value is limited to the block that they are in, as demonstrated
823 by this bit of code:
824
825     my $outer = 'Wallace and Grommit';
826     my $inner = 'Mutt and Jeff';
827
828     my $pattern = qr/(\S+) and (\S+)/;
829
830     sub show_n { print "\$1 is $1; \$2 is $2\n" }
831
832     {
833     OUTER:
834         show_n() if $outer =~ m/$pattern/;
835
836         INNER: {
837             show_n() if $inner =~ m/$pattern/;
838             }
839
840         show_n();
841     }
842
843 The output shows that while in the C<OUTER> block, the values of C<$1>
844 and C<$2> are from the match against C<$outer>.  Inside the C<INNER>
845 block, the values of C<$1> and C<$2> are from the match against
846 C<$inner>, but only until the end of the block (i.e. the dynamic
847 scope).  After the C<INNER> block completes, the values of C<$1> and
848 C<$2> return to the values for the match against C<$outer> even though
849 we have not made another match:
850
851     $1 is Wallace; $2 is Grommit
852     $1 is Mutt; $2 is Jeff
853     $1 is Wallace; $2 is Grommit
854
855 =head3 Performance issues
856
857 Traditionally in Perl, any use of any of the three variables  C<$`>, C<$&>
858 or C<$'> (or their C<use English> equivalents) anywhere in the code, caused
859 all subsequent successful pattern matches to make a copy of the matched
860 string, in case the code might subsequently access one of those variables.
861 This imposed a considerable performance penalty across the whole program,
862 so generally the use of these variables has been discouraged.
863
864 In Perl 5.6.0 the C<@-> and C<@+> dynamic arrays were introduced that
865 supply the indices of successful matches. So you could for example do
866 this:
867
868     $str =~ /pattern/;
869
870     print $`, $&, $'; # bad: performance hit
871
872     print             # good: no performance hit
873         substr($str, 0,     $-[0]),
874         substr($str, $-[0], $+[0]-$-[0]),
875         substr($str, $+[0]);
876
877 In Perl 5.10.0 the C</p> match operator flag and the C<${^PREMATCH}>,
878 C<${^MATCH}>, and C<${^POSTMATCH}> variables were introduced, that allowed
879 you to suffer the penalties only on patterns marked with C</p>.
880
881 In Perl 5.18.0 onwards, perl started noting the presence of each of the
882 three variables separately, and only copied that part of the string
883 required; so in
884
885     $`; $&; "abcdefgh" =~ /d/
886
887 perl would only copy the "abcd" part of the string. That could make a big
888 difference in something like
889
890     $str = 'x' x 1_000_000;
891     $&; # whoops
892     $str =~ /x/g # one char copied a million times, not a million chars
893
894 In Perl 5.20.0 a new copy-on-write system was enabled by default, which
895 finally fixes all performance issues with these three variables, and makes
896 them safe to use anywhere.
897
898 The C<Devel::NYTProf> and C<Devel::FindAmpersand> modules can help you
899 find uses of these problematic match variables in your code.
900
901 =over 8
902
903 =item $<I<digits>> ($1, $2, ...)
904 X<$1> X<$2> X<$3> X<$I<digits>>
905
906 Contains the subpattern from the corresponding set of capturing
907 parentheses from the last successful pattern match, not counting patterns
908 matched in nested blocks that have been exited already.
909
910 Note there is a distinction between a capture buffer which matches
911 the empty string a capture buffer which is optional. Eg, C<(x?)> and
912 C<(x)?> The latter may be undef, the former not.
913
914 These variables are read-only and dynamically-scoped.
915
916 Mnemonic: like \digits.
917
918 =item @{^CAPTURE}
919 X<@{^CAPTURE}> X<@^CAPTURE>
920
921 An array which exposes the contents of the capture buffers, if any, of
922 the last successful pattern match, not counting patterns matched
923 in nested blocks that have been exited already.
924
925 Note that the 0 index of @{^CAPTURE} is equivalent to $1, the 1 index
926 is equivalent to $2, etc.
927
928     if ("foal"=~/(.)(.)(.)(.)/) {
929         print join "-", @{^CAPTURE};
930     }
931
932 should output "f-o-a-l".
933
934 See also L<<< /$<I<digits>> ($1, $2, ...) >>>, L</%{^CAPTURE}> and
935 L</%{^CAPTURE_ALL}>.
936
937 Note that unlike most other regex magic variables there is no single
938 letter equivalent to C<@{^CAPTURE}>.
939
940 This variable was added in 5.25.7
941
942 =item $MATCH
943
944 =item $&
945 X<$&> X<$MATCH>
946
947 The string matched by the last successful pattern match (not counting
948 any matches hidden within a BLOCK or C<eval()> enclosed by the current
949 BLOCK).
950
951 See L</Performance issues> above for the serious performance implications
952 of using this variable (even once) in your code.
953
954 This variable is read-only and dynamically-scoped.
955
956 Mnemonic: like C<&> in some editors.
957
958 =item ${^MATCH}
959 X<${^MATCH}>
960
961 This is similar to C<$&> (C<$MATCH>) except that it does not incur the
962 performance penalty associated with that variable.
963
964 See L</Performance issues> above.
965
966 In Perl v5.18 and earlier, it is only guaranteed
967 to return a defined value when the pattern was compiled or executed with
968 the C</p> modifier.  In Perl v5.20, the C</p> modifier does nothing, so
969 C<${^MATCH}> does the same thing as C<$MATCH>.
970
971 This variable was added in Perl v5.10.0.
972
973 This variable is read-only and dynamically-scoped.
974
975 =item $PREMATCH
976
977 =item $`
978 X<$`> X<$PREMATCH> X<${^PREMATCH}>
979
980 The string preceding whatever was matched by the last successful
981 pattern match, not counting any matches hidden within a BLOCK or C<eval>
982 enclosed by the current BLOCK.
983
984 See L</Performance issues> above for the serious performance implications
985 of using this variable (even once) in your code.
986
987 This variable is read-only and dynamically-scoped.
988
989 Mnemonic: C<`> often precedes a quoted string.
990
991 =item ${^PREMATCH}
992 X<$`> X<${^PREMATCH}>
993
994 This is similar to C<$`> ($PREMATCH) except that it does not incur the
995 performance penalty associated with that variable.
996
997 See L</Performance issues> above.
998
999 In Perl v5.18 and earlier, it is only guaranteed
1000 to return a defined value when the pattern was compiled or executed with
1001 the C</p> modifier.  In Perl v5.20, the C</p> modifier does nothing, so
1002 C<${^PREMATCH}> does the same thing as C<$PREMATCH>.
1003
1004 This variable was added in Perl v5.10.0.
1005
1006 This variable is read-only and dynamically-scoped.
1007
1008 =item $POSTMATCH
1009
1010 =item $'
1011 X<$'> X<$POSTMATCH> X<${^POSTMATCH}> X<@->
1012
1013 The string following whatever was matched by the last successful
1014 pattern match (not counting any matches hidden within a BLOCK or C<eval()>
1015 enclosed by the current BLOCK).  Example:
1016
1017     local $_ = 'abcdefghi';
1018     /def/;
1019     print "$`:$&:$'\n";         # prints abc:def:ghi
1020
1021 See L</Performance issues> above for the serious performance implications
1022 of using this variable (even once) in your code.
1023
1024 This variable is read-only and dynamically-scoped.
1025
1026 Mnemonic: C<'> often follows a quoted string.
1027
1028 =item ${^POSTMATCH}
1029 X<${^POSTMATCH}> X<$'> X<$POSTMATCH>
1030
1031 This is similar to C<$'> (C<$POSTMATCH>) except that it does not incur the
1032 performance penalty associated with that variable.
1033
1034 See L</Performance issues> above.
1035
1036 In Perl v5.18 and earlier, it is only guaranteed
1037 to return a defined value when the pattern was compiled or executed with
1038 the C</p> modifier.  In Perl v5.20, the C</p> modifier does nothing, so
1039 C<${^POSTMATCH}> does the same thing as C<$POSTMATCH>.
1040
1041 This variable was added in Perl v5.10.0.
1042
1043 This variable is read-only and dynamically-scoped.
1044
1045 =item $LAST_PAREN_MATCH
1046
1047 =item $+
1048 X<$+> X<$LAST_PAREN_MATCH>
1049
1050 The text matched by the highest used capture group of the last
1051 successful search pattern.  It is logically equivalent to the highest
1052 numbered capture variable (C<$1>, C<$2>, ...) which has a defined value.
1053
1054 This is useful if you don't know which one of a set of alternative patterns
1055 matched.  For example:
1056
1057     /Version: (.*)|Revision: (.*)/ && ($rev = $+);
1058
1059 This variable is read-only and dynamically-scoped.
1060
1061 Mnemonic: be positive and forward looking.
1062
1063 =item $LAST_SUBMATCH_RESULT
1064
1065 =item $^N
1066 X<$^N> X<$LAST_SUBMATCH_RESULT>
1067
1068 The text matched by the used group most-recently closed (i.e. the group
1069 with the rightmost closing parenthesis) of the last successful search
1070 pattern. This is subtly different from C<$+>. For example in
1071
1072     "ab" =~ /^((.)(.))$/
1073
1074 we have
1075
1076     $1,$^N   have the value "ab"
1077     $2       has  the value "a"
1078     $3,$+    have the value "b"
1079
1080 This is primarily used inside C<(?{...})> blocks for examining text
1081 recently matched.  For example, to effectively capture text to a variable
1082 (in addition to C<$1>, C<$2>, etc.), replace C<(...)> with
1083
1084     (?:(...)(?{ $var = $^N }))
1085
1086 By setting and then using C<$var> in this way relieves you from having to
1087 worry about exactly which numbered set of parentheses they are.
1088
1089 This variable was added in Perl v5.8.0.
1090
1091 Mnemonic: the (possibly) Nested parenthesis that most recently closed.
1092
1093 =item @LAST_MATCH_END
1094
1095 =item @+
1096 X<@+> X<@LAST_MATCH_END>
1097
1098 This array holds the offsets of the ends of the last successful
1099 submatches in the currently active dynamic scope.  C<$+[0]> is
1100 the offset into the string of the end of the entire match.  This
1101 is the same value as what the C<pos> function returns when called
1102 on the variable that was matched against.  The I<n>th element
1103 of this array holds the offset of the I<n>th submatch, so
1104 C<$+[1]> is the offset past where C<$1> ends, C<$+[2]> the offset
1105 past where C<$2> ends, and so on.  You can use C<$#+> to determine
1106 how many subgroups were in the last successful match.  See the
1107 examples given for the C<@-> variable.
1108
1109 This variable was added in Perl v5.6.0.
1110
1111 =item %{^CAPTURE}
1112
1113 =item %LAST_PAREN_MATCH
1114
1115 =item %+
1116 X<%+> X<%LAST_PAREN_MATCH> X<%{^CAPTURE}>
1117
1118 Similar to C<@+>, the C<%+> hash allows access to the named capture
1119 buffers, should they exist, in the last successful match in the
1120 currently active dynamic scope.
1121
1122 For example, C<$+{foo}> is equivalent to C<$1> after the following match:
1123
1124     'foo' =~ /(?<foo>foo)/;
1125
1126 The keys of the C<%+> hash list only the names of buffers that have
1127 captured (and that are thus associated to defined values).
1128
1129 If multiple distinct capture groups have the same name, then
1130 C<$+{NAME}> will refer to the leftmost defined group in the match.
1131
1132 The underlying behaviour of C<%+> is provided by the
1133 L<Tie::Hash::NamedCapture> module.
1134
1135 B<Note:> C<%-> and C<%+> are tied views into a common internal hash
1136 associated with the last successful regular expression.  Therefore mixing
1137 iterative access to them via C<each> may have unpredictable results.
1138 Likewise, if the last successful match changes, then the results may be
1139 surprising.
1140
1141 This variable was added in Perl v5.10.0. The C<%{^CAPTURE}> alias was
1142 added in 5.25.7.
1143
1144 This variable is read-only and dynamically-scoped.
1145
1146 =item @LAST_MATCH_START
1147
1148 =item @-
1149 X<@-> X<@LAST_MATCH_START>
1150
1151 C<$-[0]> is the offset of the start of the last successful match.
1152 C<$-[>I<n>C<]> is the offset of the start of the substring matched by
1153 I<n>-th subpattern, or undef if the subpattern did not match.
1154
1155 Thus, after a match against C<$_>, C<$&> coincides with C<substr $_, $-[0],
1156 $+[0] - $-[0]>.  Similarly, $I<n> coincides with C<substr $_, $-[n],
1157 $+[n] - $-[n]> if C<$-[n]> is defined, and $+ coincides with
1158 C<substr $_, $-[$#-], $+[$#-] - $-[$#-]>.  One can use C<$#-> to find the
1159 last matched subgroup in the last successful match.  Contrast with
1160 C<$#+>, the number of subgroups in the regular expression.  Compare
1161 with C<@+>.
1162
1163 This array holds the offsets of the beginnings of the last
1164 successful submatches in the currently active dynamic scope.
1165 C<$-[0]> is the offset into the string of the beginning of the
1166 entire match.  The I<n>th element of this array holds the offset
1167 of the I<n>th submatch, so C<$-[1]> is the offset where C<$1>
1168 begins, C<$-[2]> the offset where C<$2> begins, and so on.
1169
1170 After a match against some variable C<$var>:
1171
1172 =over 5
1173
1174 =item C<$`> is the same as C<substr($var, 0, $-[0])>
1175
1176 =item C<$&> is the same as C<substr($var, $-[0], $+[0] - $-[0])>
1177
1178 =item C<$'> is the same as C<substr($var, $+[0])>
1179
1180 =item C<$1> is the same as C<substr($var, $-[1], $+[1] - $-[1])>
1181
1182 =item C<$2> is the same as C<substr($var, $-[2], $+[2] - $-[2])>
1183
1184 =item C<$3> is the same as C<substr($var, $-[3], $+[3] - $-[3])>
1185
1186 =back
1187
1188 This variable was added in Perl v5.6.0.
1189
1190 =item %{^CAPTURE_ALL}
1191 X<%{^CAPTURE_ALL}>
1192
1193 =item %-
1194 X<%->
1195
1196 Similar to C<%+>, this variable allows access to the named capture groups
1197 in the last successful match in the currently active dynamic scope.  To
1198 each capture group name found in the regular expression, it associates a
1199 reference to an array containing the list of values captured by all
1200 buffers with that name (should there be several of them), in the order
1201 where they appear.
1202
1203 Here's an example:
1204
1205     if ('1234' =~ /(?<A>1)(?<B>2)(?<A>3)(?<B>4)/) {
1206         foreach my $bufname (sort keys %-) {
1207             my $ary = $-{$bufname};
1208             foreach my $idx (0..$#$ary) {
1209                 print "\$-{$bufname}[$idx] : ",
1210                       (defined($ary->[$idx])
1211                           ? "'$ary->[$idx]'"
1212                           : "undef"),
1213                       "\n";
1214             }
1215         }
1216     }
1217
1218 would print out:
1219
1220     $-{A}[0] : '1'
1221     $-{A}[1] : '3'
1222     $-{B}[0] : '2'
1223     $-{B}[1] : '4'
1224
1225 The keys of the C<%-> hash correspond to all buffer names found in
1226 the regular expression.
1227
1228 The behaviour of C<%-> is implemented via the
1229 L<Tie::Hash::NamedCapture> module.
1230
1231 B<Note:> C<%-> and C<%+> are tied views into a common internal hash
1232 associated with the last successful regular expression.  Therefore mixing
1233 iterative access to them via C<each> may have unpredictable results.
1234 Likewise, if the last successful match changes, then the results may be
1235 surprising.
1236
1237 This variable was added in Perl v5.10.0. The C<%{^CAPTURE_ALL}> alias was
1238 added in 5.25.7.
1239
1240 This variable is read-only and dynamically-scoped.
1241
1242 =item $LAST_REGEXP_CODE_RESULT
1243
1244 =item $^R
1245 X<$^R> X<$LAST_REGEXP_CODE_RESULT>
1246
1247 The result of evaluation of the last successful C<(?{ code })>
1248 regular expression assertion (see L<perlre>).  May be written to.
1249
1250 This variable was added in Perl 5.005.
1251
1252 =item ${^RE_DEBUG_FLAGS}
1253 X<${^RE_DEBUG_FLAGS}>
1254
1255 The current value of the regex debugging flags.  Set to 0 for no debug output
1256 even when the C<re 'debug'> module is loaded.  See L<re> for details.
1257
1258 This variable was added in Perl v5.10.0.
1259
1260 =item ${^RE_TRIE_MAXBUF}
1261 X<${^RE_TRIE_MAXBUF}>
1262
1263 Controls how certain regex optimisations are applied and how much memory they
1264 utilize.  This value by default is 65536 which corresponds to a 512kB
1265 temporary cache.  Set this to a higher value to trade
1266 memory for speed when matching large alternations.  Set
1267 it to a lower value if you want the optimisations to
1268 be as conservative of memory as possible but still occur, and set it to a
1269 negative value to prevent the optimisation and conserve the most memory.
1270 Under normal situations this variable should be of no interest to you.
1271
1272 This variable was added in Perl v5.10.0.
1273
1274 =back
1275
1276 =head2 Variables related to filehandles
1277
1278 Variables that depend on the currently selected filehandle may be set
1279 by calling an appropriate object method on the C<IO::Handle> object,
1280 although this is less efficient than using the regular built-in
1281 variables.  (Summary lines below for this contain the word HANDLE.)
1282 First you must say
1283
1284     use IO::Handle;
1285
1286 after which you may use either
1287
1288     method HANDLE EXPR
1289
1290 or more safely,
1291
1292     HANDLE->method(EXPR)
1293
1294 Each method returns the old value of the C<IO::Handle> attribute.  The
1295 methods each take an optional EXPR, which, if supplied, specifies the
1296 new value for the C<IO::Handle> attribute in question.  If not
1297 supplied, most methods do nothing to the current value--except for
1298 C<autoflush()>, which will assume a 1 for you, just to be different.
1299
1300 Because loading in the C<IO::Handle> class is an expensive operation,
1301 you should learn how to use the regular built-in variables.
1302
1303 A few of these variables are considered "read-only".  This means that
1304 if you try to assign to this variable, either directly or indirectly
1305 through a reference, you'll raise a run-time exception.
1306
1307 You should be very careful when modifying the default values of most
1308 special variables described in this document.  In most cases you want
1309 to localize these variables before changing them, since if you don't,
1310 the change may affect other modules which rely on the default values
1311 of the special variables that you have changed.  This is one of the
1312 correct ways to read the whole file at once:
1313
1314     open my $fh, "<", "foo" or die $!;
1315     local $/; # enable localized slurp mode
1316     my $content = <$fh>;
1317     close $fh;
1318
1319 But the following code is quite bad:
1320
1321     open my $fh, "<", "foo" or die $!;
1322     undef $/; # enable slurp mode
1323     my $content = <$fh>;
1324     close $fh;
1325
1326 since some other module, may want to read data from some file in the
1327 default "line mode", so if the code we have just presented has been
1328 executed, the global value of C<$/> is now changed for any other code
1329 running inside the same Perl interpreter.
1330
1331 Usually when a variable is localized you want to make sure that this
1332 change affects the shortest scope possible.  So unless you are already
1333 inside some short C<{}> block, you should create one yourself.  For
1334 example:
1335
1336     my $content = '';
1337     open my $fh, "<", "foo" or die $!;
1338     {
1339         local $/;
1340         $content = <$fh>;
1341     }
1342     close $fh;
1343
1344 Here is an example of how your own code can go broken:
1345
1346     for ( 1..3 ){
1347         $\ = "\r\n";
1348         nasty_break();
1349         print "$_";
1350     }
1351
1352     sub nasty_break {
1353         $\ = "\f";
1354         # do something with $_
1355     }
1356
1357 You probably expect this code to print the equivalent of
1358
1359     "1\r\n2\r\n3\r\n"
1360
1361 but instead you get:
1362
1363     "1\f2\f3\f"
1364
1365 Why? Because C<nasty_break()> modifies C<$\> without localizing it
1366 first.  The value you set in  C<nasty_break()> is still there when you
1367 return.  The fix is to add C<local()> so the value doesn't leak out of
1368 C<nasty_break()>:
1369
1370     local $\ = "\f";
1371
1372 It's easy to notice the problem in such a short example, but in more
1373 complicated code you are looking for trouble if you don't localize
1374 changes to the special variables.
1375
1376 =over 8
1377
1378 =item $ARGV
1379 X<$ARGV>
1380
1381 Contains the name of the current file when reading from C<< <> >>.
1382
1383 =item @ARGV
1384 X<@ARGV>
1385
1386 The array C<@ARGV> contains the command-line arguments intended for
1387 the script.  C<$#ARGV> is generally the number of arguments minus
1388 one, because C<$ARGV[0]> is the first argument, I<not> the program's
1389 command name itself.  See L</$0> for the command name.
1390
1391 =item ARGV
1392 X<ARGV>
1393
1394 The special filehandle that iterates over command-line filenames in
1395 C<@ARGV>.  Usually written as the null filehandle in the angle operator
1396 C<< <> >>.  Note that currently C<ARGV> only has its magical effect
1397 within the C<< <> >> operator; elsewhere it is just a plain filehandle
1398 corresponding to the last file opened by C<< <> >>.  In particular,
1399 passing C<\*ARGV> as a parameter to a function that expects a filehandle
1400 may not cause your function to automatically read the contents of all the
1401 files in C<@ARGV>.
1402
1403 =item ARGVOUT
1404 X<ARGVOUT>
1405
1406 The special filehandle that points to the currently open output file
1407 when doing edit-in-place processing with B<-i>.  Useful when you have
1408 to do a lot of inserting and don't want to keep modifying C<$_>.  See
1409 L<perlrun> for the B<-i> switch.
1410
1411 =item IO::Handle->output_field_separator( EXPR )
1412
1413 =item $OUTPUT_FIELD_SEPARATOR
1414
1415 =item $OFS
1416
1417 =item $,
1418 X<$,> X<$OFS> X<$OUTPUT_FIELD_SEPARATOR>
1419
1420 The output field separator for the print operator.  If defined, this
1421 value is printed between each of print's arguments.  Default is C<undef>.
1422
1423 You cannot call C<output_field_separator()> on a handle, only as a
1424 static method.  See L<IO::Handle|IO::Handle>.
1425
1426 Mnemonic: what is printed when there is a "," in your print statement.
1427
1428 =item HANDLE->input_line_number( EXPR )
1429
1430 =item $INPUT_LINE_NUMBER
1431
1432 =item $NR
1433
1434 =item $.
1435 X<$.> X<$NR> X<$INPUT_LINE_NUMBER> X<line number>
1436
1437 Current line number for the last filehandle accessed.
1438
1439 Each filehandle in Perl counts the number of lines that have been read
1440 from it.  (Depending on the value of C<$/>, Perl's idea of what
1441 constitutes a line may not match yours.)  When a line is read from a
1442 filehandle (via C<readline()> or C<< <> >>), or when C<tell()> or
1443 C<seek()> is called on it, C<$.> becomes an alias to the line counter
1444 for that filehandle.
1445
1446 You can adjust the counter by assigning to C<$.>, but this will not
1447 actually move the seek pointer.  I<Localizing C<$.> will not localize
1448 the filehandle's line count>.  Instead, it will localize perl's notion
1449 of which filehandle C<$.> is currently aliased to.
1450
1451 C<$.> is reset when the filehandle is closed, but B<not> when an open
1452 filehandle is reopened without an intervening C<close()>.  For more
1453 details, see L<perlop/"IE<sol>O Operators">.  Because C<< <> >> never does
1454 an explicit close, line numbers increase across C<ARGV> files (but see
1455 examples in L<perlfunc/eof>).
1456
1457 You can also use C<< HANDLE->input_line_number(EXPR) >> to access the
1458 line counter for a given filehandle without having to worry about
1459 which handle you last accessed.
1460
1461 Mnemonic: many programs use "." to mean the current line number.
1462
1463 =item IO::Handle->input_record_separator( EXPR )
1464
1465 =item $INPUT_RECORD_SEPARATOR
1466
1467 =item $RS
1468
1469 =item $/
1470 X<$/> X<$RS> X<$INPUT_RECORD_SEPARATOR>
1471
1472 The input record separator, newline by default.  This influences Perl's
1473 idea of what a "line" is.  Works like B<awk>'s RS variable, including
1474 treating empty lines as a terminator if set to the null string (an
1475 empty line cannot contain any spaces or tabs).  You may set it to a
1476 multi-character string to match a multi-character terminator, or to
1477 C<undef> to read through the end of file.  Setting it to C<"\n\n">
1478 means something slightly different than setting to C<"">, if the file
1479 contains consecutive empty lines.  Setting to C<""> will treat two or
1480 more consecutive empty lines as a single empty line.  Setting to
1481 C<"\n\n"> will blindly assume that the next input character belongs to
1482 the next paragraph, even if it's a newline.
1483
1484     local $/;           # enable "slurp" mode
1485     local $_ = <FH>;    # whole file now here
1486     s/\n[ \t]+/ /g;
1487
1488 Remember: the value of C<$/> is a string, not a regex.  B<awk> has to
1489 be better for something. :-)
1490
1491 Setting C<$/> to an empty string -- the so-called I<paragraph mode> -- merits
1492 special attention.  When C<$/> is set to C<""> and the entire file is read in
1493 with that setting, any sequence of consecutive newlines C<"\n\n"> at the
1494 beginning of the file is discarded.  With the exception of the final record in
1495 the file, each sequence of characters ending in two or more newlines is
1496 treated as one record and is read in to end in exactly two newlines.  If the
1497 last record in the file ends in zero or one consecutive newlines, that record
1498 is read in with that number of newlines.  If the last record ends in two or
1499 more consecutive newlines, it is read in with two newlines like all preceding
1500 records.
1501
1502 Suppose we wrote the following string to a file:
1503
1504     my $string = "\n\n\n";
1505     $string .= "alpha beta\ngamma delta\n\n\n";
1506     $string .= "epsilon zeta eta\n\n";
1507     $string .= "theta\n";
1508
1509     my $file = 'simple_file.txt'; 
1510     open my $OUT, '>', $file or die;
1511     print $OUT $string;
1512     close $OUT or die;
1513
1514 Now we read that file in paragraph mode:
1515
1516     local $/ = ""; # paragraph mode
1517     open my $IN, '<', $file or die;
1518     my @records = <$IN>;
1519     close $IN or die;
1520
1521 C<@records> will consist of these 3 strings:
1522
1523     (
1524       "alpha beta\ngamma delta\n\n",
1525       "epsilon zeta eta\n\n",
1526       "theta\n",
1527     )
1528
1529 Setting C<$/> to a reference to an integer, scalar containing an
1530 integer, or scalar that's convertible to an integer will attempt to
1531 read records instead of lines, with the maximum record size being the
1532 referenced integer number of characters.  So this:
1533
1534     local $/ = \32768; # or \"32768", or \$var_containing_32768
1535     open my $fh, "<", $myfile or die $!;
1536     local $_ = <$fh>;
1537
1538 will read a record of no more than 32768 characters from $fh.  If you're
1539 not reading from a record-oriented file (or your OS doesn't have
1540 record-oriented files), then you'll likely get a full chunk of data
1541 with every read.  If a record is larger than the record size you've
1542 set, you'll get the record back in pieces.  Trying to set the record
1543 size to zero or less is deprecated and will cause $/ to have the value
1544 of "undef", which will cause reading in the (rest of the) whole file.
1545
1546 As of 5.19.9 setting C<$/> to any other form of reference will throw a
1547 fatal exception. This is in preparation for supporting new ways to set
1548 C<$/> in the future.
1549
1550 On VMS only, record reads bypass PerlIO layers and any associated
1551 buffering, so you must not mix record and non-record reads on the
1552 same filehandle.  Record mode mixes with line mode only when the
1553 same buffering layer is in use for both modes.
1554
1555 You cannot call C<input_record_separator()> on a handle, only as a
1556 static method.  See L<IO::Handle|IO::Handle>.
1557
1558 See also L<perlport/"Newlines">.  Also see L</$.>.
1559
1560 Mnemonic: / delimits line boundaries when quoting poetry.
1561
1562 =item IO::Handle->output_record_separator( EXPR )
1563
1564 =item $OUTPUT_RECORD_SEPARATOR
1565
1566 =item $ORS
1567
1568 =item $\
1569 X<$\> X<$ORS> X<$OUTPUT_RECORD_SEPARATOR>
1570
1571 The output record separator for the print operator.  If defined, this
1572 value is printed after the last of print's arguments.  Default is C<undef>.
1573
1574 You cannot call C<output_record_separator()> on a handle, only as a
1575 static method.  See L<IO::Handle|IO::Handle>.
1576
1577 Mnemonic: you set C<$\> instead of adding "\n" at the end of the print.
1578 Also, it's just like C<$/>, but it's what you get "back" from Perl.
1579
1580 =item HANDLE->autoflush( EXPR )
1581
1582 =item $OUTPUT_AUTOFLUSH
1583
1584 =item $|
1585 X<$|> X<autoflush> X<flush> X<$OUTPUT_AUTOFLUSH>
1586
1587 If set to nonzero, forces a flush right away and after every write or
1588 print on the currently selected output channel.  Default is 0
1589 (regardless of whether the channel is really buffered by the system or
1590 not; C<$|> tells you only whether you've asked Perl explicitly to
1591 flush after each write).  STDOUT will typically be line buffered if
1592 output is to the terminal and block buffered otherwise.  Setting this
1593 variable is useful primarily when you are outputting to a pipe or
1594 socket, such as when you are running a Perl program under B<rsh> and
1595 want to see the output as it's happening.  This has no effect on input
1596 buffering.  See L<perlfunc/getc> for that.  See L<perlfunc/select> on
1597 how to select the output channel.  See also L<IO::Handle>.
1598
1599 Mnemonic: when you want your pipes to be piping hot.
1600
1601 =item ${^LAST_FH}
1602 X<${^LAST_FH}>
1603
1604 This read-only variable contains a reference to the last-read filehandle.
1605 This is set by C<< <HANDLE> >>, C<readline>, C<tell>, C<eof> and C<seek>.
1606 This is the same handle that C<$.> and C<tell> and C<eof> without arguments
1607 use.  It is also the handle used when Perl appends ", <STDIN> line 1" to
1608 an error or warning message.
1609
1610 This variable was added in Perl v5.18.0.
1611
1612 =back
1613
1614 =head3 Variables related to formats
1615
1616 The special variables for formats are a subset of those for
1617 filehandles.  See L<perlform> for more information about Perl's
1618 formats.
1619
1620 =over 8
1621
1622 =item $ACCUMULATOR
1623
1624 =item $^A
1625 X<$^A> X<$ACCUMULATOR>
1626
1627 The current value of the C<write()> accumulator for C<format()> lines.
1628 A format contains C<formline()> calls that put their result into
1629 C<$^A>.  After calling its format, C<write()> prints out the contents
1630 of C<$^A> and empties.  So you never really see the contents of C<$^A>
1631 unless you call C<formline()> yourself and then look at it.  See
1632 L<perlform> and L<perlfunc/"formline PICTURE,LIST">.
1633
1634 =item IO::Handle->format_formfeed(EXPR)
1635
1636 =item $FORMAT_FORMFEED
1637
1638 =item $^L
1639 X<$^L> X<$FORMAT_FORMFEED>
1640
1641 What formats output as a form feed.  The default is C<\f>.
1642
1643 You cannot call C<format_formfeed()> on a handle, only as a static
1644 method.  See L<IO::Handle|IO::Handle>.
1645
1646 =item HANDLE->format_page_number(EXPR)
1647
1648 =item $FORMAT_PAGE_NUMBER
1649
1650 =item $%
1651 X<$%> X<$FORMAT_PAGE_NUMBER>
1652
1653 The current page number of the currently selected output channel.
1654
1655 Mnemonic: C<%> is page number in B<nroff>.
1656
1657 =item HANDLE->format_lines_left(EXPR)
1658
1659 =item $FORMAT_LINES_LEFT
1660
1661 =item $-
1662 X<$-> X<$FORMAT_LINES_LEFT>
1663
1664 The number of lines left on the page of the currently selected output
1665 channel.
1666
1667 Mnemonic: lines_on_page - lines_printed.
1668
1669 =item IO::Handle->format_line_break_characters EXPR
1670
1671 =item $FORMAT_LINE_BREAK_CHARACTERS
1672
1673 =item $:
1674 X<$:> X<FORMAT_LINE_BREAK_CHARACTERS>
1675
1676 The current set of characters after which a string may be broken to
1677 fill continuation fields (starting with C<^>) in a format.  The default is
1678 S<" \n-">, to break on a space, newline, or a hyphen.
1679
1680 You cannot call C<format_line_break_characters()> on a handle, only as
1681 a static method.  See L<IO::Handle|IO::Handle>.
1682
1683 Mnemonic: a "colon" in poetry is a part of a line.
1684
1685 =item HANDLE->format_lines_per_page(EXPR)
1686
1687 =item $FORMAT_LINES_PER_PAGE
1688
1689 =item $=
1690 X<$=> X<$FORMAT_LINES_PER_PAGE>
1691
1692 The current page length (printable lines) of the currently selected
1693 output channel.  The default is 60.
1694
1695 Mnemonic: = has horizontal lines.
1696
1697 =item HANDLE->format_top_name(EXPR)
1698
1699 =item $FORMAT_TOP_NAME
1700
1701 =item $^
1702 X<$^> X<$FORMAT_TOP_NAME>
1703
1704 The name of the current top-of-page format for the currently selected
1705 output channel.  The default is the name of the filehandle with C<_TOP>
1706 appended.  For example, the default format top name for the C<STDOUT>
1707 filehandle is C<STDOUT_TOP>.
1708
1709 Mnemonic: points to top of page.
1710
1711 =item HANDLE->format_name(EXPR)
1712
1713 =item $FORMAT_NAME
1714
1715 =item $~
1716 X<$~> X<$FORMAT_NAME>
1717
1718 The name of the current report format for the currently selected
1719 output channel.  The default format name is the same as the filehandle
1720 name.  For example, the default format name for the C<STDOUT>
1721 filehandle is just C<STDOUT>.
1722
1723 Mnemonic: brother to C<$^>.
1724
1725 =back
1726
1727 =head2 Error Variables
1728 X<error> X<exception>
1729
1730 The variables C<$@>, C<$!>, C<$^E>, and C<$?> contain information
1731 about different types of error conditions that may appear during
1732 execution of a Perl program.  The variables are shown ordered by
1733 the "distance" between the subsystem which reported the error and
1734 the Perl process.  They correspond to errors detected by the Perl
1735 interpreter, C library, operating system, or an external program,
1736 respectively.
1737
1738 To illustrate the differences between these variables, consider the
1739 following Perl expression, which uses a single-quoted string.  After
1740 execution of this statement, perl may have set all four special error
1741 variables:
1742
1743     eval q{
1744         open my $pipe, "/cdrom/install |" or die $!;
1745         my @res = <$pipe>;
1746         close $pipe or die "bad pipe: $?, $!";
1747     };
1748
1749 When perl executes the C<eval()> expression, it translates the
1750 C<open()>, C<< <PIPE> >>, and C<close> calls in the C run-time library
1751 and thence to the operating system kernel.  perl sets C<$!> to
1752 the C library's C<errno> if one of these calls fails.
1753
1754 C<$@> is set if the string to be C<eval>-ed did not compile (this may
1755 happen if C<open> or C<close> were imported with bad prototypes), or
1756 if Perl code executed during evaluation C<die()>d.  In these cases the
1757 value of C<$@> is the compile error, or the argument to C<die> (which
1758 will interpolate C<$!> and C<$?>).  (See also L<Fatal>, though.)
1759
1760 Under a few operating systems, C<$^E> may contain a more verbose error
1761 indicator, such as in this case, "CDROM tray not closed."  Systems that
1762 do not support extended error messages leave C<$^E> the same as C<$!>.
1763
1764 Finally, C<$?> may be set to a non-0 value if the external program
1765 F</cdrom/install> fails.  The upper eight bits reflect specific error
1766 conditions encountered by the program (the program's C<exit()> value).
1767 The lower eight bits reflect mode of failure, like signal death and
1768 core dump information.  See L<wait(2)> for details.  In contrast to
1769 C<$!> and C<$^E>, which are set only if an error condition is detected,
1770 the variable C<$?> is set on each C<wait> or pipe C<close>,
1771 overwriting the old value.  This is more like C<$@>, which on every
1772 C<eval()> is always set on failure and cleared on success.
1773
1774 For more details, see the individual descriptions at C<$@>, C<$!>,
1775 C<$^E>, and C<$?>.
1776
1777 =over 8
1778
1779 =item ${^CHILD_ERROR_NATIVE}
1780 X<$^CHILD_ERROR_NATIVE>
1781
1782 The native status returned by the last pipe close, backtick (C<``>)
1783 command, successful call to C<wait()> or C<waitpid()>, or from the
1784 C<system()> operator.  On POSIX-like systems this value can be decoded
1785 with the WIFEXITED, WEXITSTATUS, WIFSIGNALED, WTERMSIG, WIFSTOPPED,
1786 WSTOPSIG and WIFCONTINUED functions provided by the L<POSIX> module.
1787
1788 Under VMS this reflects the actual VMS exit status; i.e. it is the
1789 same as C<$?> when the pragma C<use vmsish 'status'> is in effect.
1790
1791 This variable was added in Perl v5.10.0.
1792
1793 =item $EXTENDED_OS_ERROR
1794
1795 =item $^E
1796 X<$^E> X<$EXTENDED_OS_ERROR>
1797
1798 Error information specific to the current operating system.  At the
1799 moment, this differs from C<L</$!>> under only VMS, OS/2, and Win32 (and
1800 for MacPerl).  On all other platforms, C<$^E> is always just the same
1801 as C<$!>.
1802
1803 Under VMS, C<$^E> provides the VMS status value from the last system
1804 error.  This is more specific information about the last system error
1805 than that provided by C<$!>.  This is particularly important when C<$!>
1806 is set to B<EVMSERR>.
1807
1808 Under OS/2, C<$^E> is set to the error code of the last call to OS/2
1809 API either via CRT, or directly from perl.
1810
1811 Under Win32, C<$^E> always returns the last error information reported
1812 by the Win32 call C<GetLastError()> which describes the last error
1813 from within the Win32 API.  Most Win32-specific code will report errors
1814 via C<$^E>.  ANSI C and Unix-like calls set C<errno> and so most
1815 portable Perl code will report errors via C<$!>.
1816
1817 Caveats mentioned in the description of C<L</$!>> generally apply to
1818 C<$^E>, also.
1819
1820 This variable was added in Perl 5.003.
1821
1822 Mnemonic: Extra error explanation.
1823
1824 =item $EXCEPTIONS_BEING_CAUGHT
1825
1826 =item $^S
1827 X<$^S> X<$EXCEPTIONS_BEING_CAUGHT>
1828
1829 Current state of the interpreter.
1830
1831         $^S         State
1832         ---------   -------------------------------------
1833         undef       Parsing module, eval, or main program
1834         true (1)    Executing an eval
1835         false (0)   Otherwise
1836
1837 The first state may happen in C<$SIG{__DIE__}> and C<$SIG{__WARN__}>
1838 handlers.
1839
1840 The English name $EXCEPTIONS_BEING_CAUGHT is slightly misleading, because
1841 the C<undef> value does not indicate whether exceptions are being caught,
1842 since compilation of the main program does not catch exceptions.
1843
1844 This variable was added in Perl 5.004.
1845
1846 =item $WARNING
1847
1848 =item $^W
1849 X<$^W> X<$WARNING>
1850
1851 The current value of the warning switch, initially true if B<-w> was
1852 used, false otherwise, but directly modifiable.
1853
1854 See also L<warnings>.
1855
1856 Mnemonic: related to the B<-w> switch.
1857
1858 =item ${^WARNING_BITS}
1859 X<${^WARNING_BITS}>
1860
1861 The current set of warning checks enabled by the C<use warnings> pragma.
1862 It has the same scoping as the C<$^H> and C<%^H> variables.  The exact
1863 values are considered internal to the L<warnings> pragma and may change
1864 between versions of Perl.
1865
1866 This variable was added in Perl v5.6.0.
1867
1868 =item $OS_ERROR
1869
1870 =item $ERRNO
1871
1872 =item $!
1873 X<$!> X<$ERRNO> X<$OS_ERROR>
1874
1875 When referenced, C<$!> retrieves the current value
1876 of the C C<errno> integer variable.
1877 If C<$!> is assigned a numerical value, that value is stored in C<errno>.
1878 When referenced as a string, C<$!> yields the system error string
1879 corresponding to C<errno>.
1880
1881 Many system or library calls set C<errno> if they fail,
1882 to indicate the cause of failure.  They usually do B<not>
1883 set C<errno> to zero if they succeed.  This means C<errno>,
1884 hence C<$!>, is meaningful only I<immediately> after a B<failure>:
1885
1886     if (open my $fh, "<", $filename) {
1887                 # Here $! is meaningless.
1888                 ...
1889     }
1890     else {
1891                 # ONLY here is $! meaningful.
1892                 ...
1893                 # Already here $! might be meaningless.
1894     }
1895     # Since here we might have either success or failure,
1896     # $! is meaningless.
1897
1898 Here, I<meaningless> means that C<$!> may be unrelated to the outcome
1899 of the C<open()> operator.  Assignment to C<$!> is similarly ephemeral.
1900 It can be used immediately before invoking the C<die()> operator,
1901 to set the exit value, or to inspect the system error string
1902 corresponding to error I<n>, or to restore C<$!> to a meaningful state.
1903
1904 Mnemonic: What just went bang?
1905
1906 =item %OS_ERROR
1907
1908 =item %ERRNO
1909
1910 =item %!
1911 X<%!> X<%OS_ERROR> X<%ERRNO>
1912
1913 Each element of C<%!> has a true value only if C<$!> is set to that
1914 value.  For example, C<$!{ENOENT}> is true if and only if the current
1915 value of C<$!> is C<ENOENT>; that is, if the most recent error was "No
1916 such file or directory" (or its moral equivalent: not all operating
1917 systems give that exact error, and certainly not all languages).  The
1918 specific true value is not guaranteed, but in the past has generally
1919 been the numeric value of C<$!>.  To check if a particular key is
1920 meaningful on your system, use C<exists $!{the_key}>; for a list of legal
1921 keys, use C<keys %!>.  See L<Errno> for more information, and also see
1922 L</$!>.
1923
1924 This variable was added in Perl 5.005.
1925
1926 =item $CHILD_ERROR
1927
1928 =item $?
1929 X<$?> X<$CHILD_ERROR>
1930
1931 The status returned by the last pipe close, backtick (C<``>) command,
1932 successful call to C<wait()> or C<waitpid()>, or from the C<system()>
1933 operator.  This is just the 16-bit status word returned by the
1934 traditional Unix C<wait()> system call (or else is made up to look
1935 like it).  Thus, the exit value of the subprocess is really (C<<< $? >>
1936 8 >>>), and C<$? & 127> gives which signal, if any, the process died
1937 from, and C<$? & 128> reports whether there was a core dump.
1938
1939 Additionally, if the C<h_errno> variable is supported in C, its value
1940 is returned via C<$?> if any C<gethost*()> function fails.
1941
1942 If you have installed a signal handler for C<SIGCHLD>, the
1943 value of C<$?> will usually be wrong outside that handler.
1944
1945 Inside an C<END> subroutine C<$?> contains the value that is going to be
1946 given to C<exit()>.  You can modify C<$?> in an C<END> subroutine to
1947 change the exit status of your program.  For example:
1948
1949     END {
1950         $? = 1 if $? == 255;  # die would make it 255
1951     }
1952
1953 Under VMS, the pragma C<use vmsish 'status'> makes C<$?> reflect the
1954 actual VMS exit status, instead of the default emulation of POSIX
1955 status; see L<perlvms/$?> for details.
1956
1957 Mnemonic: similar to B<sh> and B<ksh>.
1958
1959 =item $EVAL_ERROR
1960
1961 =item $@
1962 X<$@> X<$EVAL_ERROR>
1963
1964 The Perl error from the last C<eval> operator, i.e. the last exception that
1965 was caught.  For C<eval BLOCK>, this is either a runtime error message or the
1966 string or reference C<die> was called with.  The C<eval STRING> form also
1967 catches syntax errors and other compile time exceptions.
1968
1969 If no error occurs, C<eval> sets C<$@> to the empty string.
1970
1971 Warning messages are not collected in this variable.  You can, however,
1972 set up a routine to process warnings by setting C<$SIG{__WARN__}> as
1973 described in L</%SIG>.
1974
1975 Mnemonic: Where was the error "at"?
1976
1977 =back
1978
1979 =head2 Variables related to the interpreter state
1980
1981 These variables provide information about the current interpreter state.
1982
1983 =over 8
1984
1985 =item $COMPILING
1986
1987 =item $^C
1988 X<$^C> X<$COMPILING>
1989
1990 The current value of the flag associated with the B<-c> switch.
1991 Mainly of use with B<-MO=...> to allow code to alter its behavior
1992 when being compiled, such as for example to C<AUTOLOAD> at compile
1993 time rather than normal, deferred loading.  Setting
1994 C<$^C = 1> is similar to calling C<B::minus_c>.
1995
1996 This variable was added in Perl v5.6.0.
1997
1998 =item $DEBUGGING
1999
2000 =item $^D
2001 X<$^D> X<$DEBUGGING>
2002
2003 The current value of the debugging flags.  May be read or set.  Like its
2004 L<command-line equivalent|perlrun/B<-D>I<letters>>, you can use numeric
2005 or symbolic values, e.g. C<$^D = 10> or C<$^D = "st">.  See
2006 L<perlrun/B<-D>I<number>>.  The contents of this variable also affects the
2007 debugger operation.  See L<perldebguts/Debugger Internals>.
2008
2009 Mnemonic: value of B<-D> switch.
2010
2011 =item ${^ENCODING}
2012 X<${^ENCODING}>
2013
2014 This variable is no longer supported.
2015
2016 It used to hold the I<object reference> to the C<Encode> object that was
2017 used to convert the source code to Unicode.
2018
2019 Its purpose was to allow your non-ASCII Perl
2020 scripts not to have to be written in UTF-8; this was
2021 useful before editors that worked on UTF-8 encoded text were common, but
2022 that was long ago.  It caused problems, such as affecting the operation
2023 of other modules that weren't expecting it, causing general mayhem.
2024
2025 If you need something like this functionality, it is recommended that use
2026 you a simple source filter, such as L<Filter::Encoding>.
2027
2028 If you are coming here because code of yours is being adversely affected
2029 by someone's use of this variable, you can usually work around it by
2030 doing this:
2031
2032  local ${^ENCODING};
2033
2034 near the beginning of the functions that are getting broken.  This
2035 undefines the variable during the scope of execution of the including
2036 function.
2037
2038 This variable was added in Perl 5.8.2 and removed in 5.26.0.
2039 Setting it to anything other than C<undef> was made fatal in Perl 5.28.0.
2040
2041 =item ${^GLOBAL_PHASE}
2042 X<${^GLOBAL_PHASE}>
2043
2044 The current phase of the perl interpreter.
2045
2046 Possible values are:
2047
2048 =over 8
2049
2050 =item CONSTRUCT
2051
2052 The C<PerlInterpreter*> is being constructed via C<perl_construct>.  This
2053 value is mostly there for completeness and for use via the
2054 underlying C variable C<PL_phase>.  It's not really possible for Perl
2055 code to be executed unless construction of the interpreter is
2056 finished.
2057
2058 =item START
2059
2060 This is the global compile-time.  That includes, basically, every
2061 C<BEGIN> block executed directly or indirectly from during the
2062 compile-time of the top-level program.
2063
2064 This phase is not called "BEGIN" to avoid confusion with
2065 C<BEGIN>-blocks, as those are executed during compile-time of any
2066 compilation unit, not just the top-level program.  A new, localised
2067 compile-time entered at run-time, for example by constructs as
2068 C<eval "use SomeModule"> are not global interpreter phases, and
2069 therefore aren't reflected by C<${^GLOBAL_PHASE}>.
2070
2071 =item CHECK
2072
2073 Execution of any C<CHECK> blocks.
2074
2075 =item INIT
2076
2077 Similar to "CHECK", but for C<INIT>-blocks, not C<CHECK> blocks.
2078
2079 =item RUN
2080
2081 The main run-time, i.e. the execution of C<PL_main_root>.
2082
2083 =item END
2084
2085 Execution of any C<END> blocks.
2086
2087 =item DESTRUCT
2088
2089 Global destruction.
2090
2091 =back
2092
2093 Also note that there's no value for UNITCHECK-blocks.  That's because
2094 those are run for each compilation unit individually, and therefore is
2095 not a global interpreter phase.
2096
2097 Not every program has to go through each of the possible phases, but
2098 transition from one phase to another can only happen in the order
2099 described in the above list.
2100
2101 An example of all of the phases Perl code can see:
2102
2103     BEGIN { print "compile-time: ${^GLOBAL_PHASE}\n" }
2104
2105     INIT  { print "init-time: ${^GLOBAL_PHASE}\n" }
2106
2107     CHECK { print "check-time: ${^GLOBAL_PHASE}\n" }
2108
2109     {
2110         package Print::Phase;
2111
2112         sub new {
2113             my ($class, $time) = @_;
2114             return bless \$time, $class;
2115         }
2116
2117         sub DESTROY {
2118             my $self = shift;
2119             print "$$self: ${^GLOBAL_PHASE}\n";
2120         }
2121     }
2122
2123     print "run-time: ${^GLOBAL_PHASE}\n";
2124
2125     my $runtime = Print::Phase->new(
2126         "lexical variables are garbage collected before END"
2127     );
2128
2129     END   { print "end-time: ${^GLOBAL_PHASE}\n" }
2130
2131     our $destruct = Print::Phase->new(
2132         "package variables are garbage collected after END"
2133     );
2134
2135 This will print out
2136
2137     compile-time: START
2138     check-time: CHECK
2139     init-time: INIT
2140     run-time: RUN
2141     lexical variables are garbage collected before END: RUN
2142     end-time: END
2143     package variables are garbage collected after END: DESTRUCT
2144
2145 This variable was added in Perl 5.14.0.
2146
2147 =item $^H
2148 X<$^H>
2149
2150 WARNING: This variable is strictly for
2151 internal use only.  Its availability,
2152 behavior, and contents are subject to change without notice.
2153
2154 This variable contains compile-time hints for the Perl interpreter.  At the
2155 end of compilation of a BLOCK the value of this variable is restored to the
2156 value when the interpreter started to compile the BLOCK.
2157
2158 When perl begins to parse any block construct that provides a lexical scope
2159 (e.g., eval body, required file, subroutine body, loop body, or conditional
2160 block), the existing value of C<$^H> is saved, but its value is left unchanged.
2161 When the compilation of the block is completed, it regains the saved value.
2162 Between the points where its value is saved and restored, code that
2163 executes within BEGIN blocks is free to change the value of C<$^H>.
2164
2165 This behavior provides the semantic of lexical scoping, and is used in,
2166 for instance, the C<use strict> pragma.
2167
2168 The contents should be an integer; different bits of it are used for
2169 different pragmatic flags.  Here's an example:
2170
2171     sub add_100 { $^H |= 0x100 }
2172
2173     sub foo {
2174         BEGIN { add_100() }
2175         bar->baz($boon);
2176     }
2177
2178 Consider what happens during execution of the BEGIN block.  At this point
2179 the BEGIN block has already been compiled, but the body of C<foo()> is still
2180 being compiled.  The new value of C<$^H>
2181 will therefore be visible only while
2182 the body of C<foo()> is being compiled.
2183
2184 Substitution of C<BEGIN { add_100() }> block with:
2185
2186     BEGIN { require strict; strict->import('vars') }
2187
2188 demonstrates how C<use strict 'vars'> is implemented.  Here's a conditional
2189 version of the same lexical pragma:
2190
2191     BEGIN {
2192         require strict; strict->import('vars') if $condition
2193     }
2194
2195 This variable was added in Perl 5.003.
2196
2197 =item %^H
2198 X<%^H>
2199
2200 The C<%^H> hash provides the same scoping semantic as C<$^H>.  This makes
2201 it useful for implementation of lexically scoped pragmas.  See
2202 L<perlpragma>.   All the entries are stringified when accessed at
2203 runtime, so only simple values can be accommodated.  This means no
2204 pointers to objects, for example.
2205
2206 When putting items into C<%^H>, in order to avoid conflicting with other
2207 users of the hash there is a convention regarding which keys to use.
2208 A module should use only keys that begin with the module's name (the
2209 name of its main package) and a "/" character.  For example, a module
2210 C<Foo::Bar> should use keys such as C<Foo::Bar/baz>.
2211
2212 This variable was added in Perl v5.6.0.
2213
2214 =item ${^OPEN}
2215 X<${^OPEN}>
2216
2217 An internal variable used by PerlIO.  A string in two parts, separated
2218 by a C<\0> byte, the first part describes the input layers, the second
2219 part describes the output layers.
2220
2221 This variable was added in Perl v5.8.0.
2222
2223 =item $PERLDB
2224
2225 =item $^P
2226 X<$^P> X<$PERLDB>
2227
2228 The internal variable for debugging support.  The meanings of the
2229 various bits are subject to change, but currently indicate:
2230
2231 =over 6
2232
2233 =item 0x01
2234
2235 Debug subroutine enter/exit.
2236
2237 =item 0x02
2238
2239 Line-by-line debugging.  Causes C<DB::DB()> subroutine to be called for
2240 each statement executed.  Also causes saving source code lines (like
2241 0x400).
2242
2243 =item 0x04
2244
2245 Switch off optimizations.
2246
2247 =item 0x08
2248
2249 Preserve more data for future interactive inspections.
2250
2251 =item 0x10
2252
2253 Keep info about source lines on which a subroutine is defined.
2254
2255 =item 0x20
2256
2257 Start with single-step on.
2258
2259 =item 0x40
2260
2261 Use subroutine address instead of name when reporting.
2262
2263 =item 0x80
2264
2265 Report C<goto &subroutine> as well.
2266
2267 =item 0x100
2268
2269 Provide informative "file" names for evals based on the place they were compiled.
2270
2271 =item 0x200
2272
2273 Provide informative names to anonymous subroutines based on the place they
2274 were compiled.
2275
2276 =item 0x400
2277
2278 Save source code lines into C<@{"_<$filename"}>.
2279
2280 =item 0x800
2281
2282 When saving source, include evals that generate no subroutines.
2283
2284 =item 0x1000
2285
2286 When saving source, include source that did not compile.
2287
2288 =back
2289
2290 Some bits may be relevant at compile-time only, some at
2291 run-time only.  This is a new mechanism and the details may change.
2292 See also L<perldebguts>.
2293
2294 =item ${^TAINT}
2295 X<${^TAINT}>
2296
2297 Reflects if taint mode is on or off.  1 for on (the program was run with
2298 B<-T>), 0 for off, -1 when only taint warnings are enabled (i.e. with
2299 B<-t> or B<-TU>).
2300
2301 This variable is read-only.
2302
2303 This variable was added in Perl v5.8.0.
2304
2305 =item ${^SAFE_LOCALES}
2306 X<${^SAFE_LOCALES}>
2307
2308 Reflects if safe locale operations are available to this perl (when the
2309 value is 1) or not (the value is 0).  This variable is always 1 if the
2310 perl has been compiled without threads.  It is also 1 if this perl is
2311 using thread-safe locale operations.  Note that an individual thread may
2312 choose to use the global locale (generally unsafe) by calling
2313 L<perlapi/switch_to_global_locale>.  This variable currently is still
2314 set to 1 in such threads.
2315
2316 This variable is read-only.
2317
2318 This variable was added in Perl v5.28.0.
2319
2320 =item ${^UNICODE}
2321 X<${^UNICODE}>
2322
2323 Reflects certain Unicode settings of Perl.  See L<perlrun>
2324 documentation for the C<-C> switch for more information about
2325 the possible values.
2326
2327 This variable is set during Perl startup and is thereafter read-only.
2328
2329 This variable was added in Perl v5.8.2.
2330
2331 =item ${^UTF8CACHE}
2332 X<${^UTF8CACHE}>
2333
2334 This variable controls the state of the internal UTF-8 offset caching code.
2335 1 for on (the default), 0 for off, -1 to debug the caching code by checking
2336 all its results against linear scans, and panicking on any discrepancy.
2337
2338 This variable was added in Perl v5.8.9.  It is subject to change or
2339 removal without notice, but is currently used to avoid recalculating the
2340 boundaries of multi-byte UTF-8-encoded characters.
2341
2342 =item ${^UTF8LOCALE}
2343 X<${^UTF8LOCALE}>
2344
2345 This variable indicates whether a UTF-8 locale was detected by perl at
2346 startup.  This information is used by perl when it's in
2347 adjust-utf8ness-to-locale mode (as when run with the C<-CL> command-line
2348 switch); see L<perlrun> for more info on this.
2349
2350 This variable was added in Perl v5.8.8.
2351
2352 =back
2353
2354 =head2 Deprecated and removed variables
2355
2356 Deprecating a variable announces the intent of the perl maintainers to
2357 eventually remove the variable from the language.  It may still be
2358 available despite its status.  Using a deprecated variable triggers
2359 a warning.
2360
2361 Once a variable is removed, its use triggers an error telling you
2362 the variable is unsupported.
2363
2364 See L<perldiag> for details about error messages.
2365
2366 =over 8
2367
2368 =item $#
2369 X<$#>
2370
2371 C<$#> was a variable that could be used to format printed numbers.
2372 After a deprecation cycle, its magic was removed in Perl v5.10.0 and
2373 using it now triggers a warning: C<$# is no longer supported>.
2374
2375 This is not the sigil you use in front of an array name to get the
2376 last index, like C<$#array>.  That's still how you get the last index
2377 of an array in Perl.  The two have nothing to do with each other.
2378
2379 Deprecated in Perl 5.
2380
2381 Removed in Perl v5.10.0.
2382
2383 =item $*
2384 X<$*>
2385
2386 C<$*> was a variable that you could use to enable multiline matching.
2387 After a deprecation cycle, its magic was removed in Perl v5.10.0.
2388 Using it now triggers a warning: C<$* is no longer supported>.
2389 You should use the C</s> and C</m> regexp modifiers instead.
2390
2391 Deprecated in Perl 5.
2392
2393 Removed in Perl v5.10.0.
2394
2395 =item $[
2396 X<$[>
2397
2398 This variable stores the index of the first element in an array, and
2399 of the first character in a substring.  The default is 0, but you could
2400 theoretically set it to 1 to make Perl behave more like B<awk> (or Fortran)
2401 when subscripting and when evaluating the index() and substr() functions.
2402
2403 As of release 5 of Perl, assignment to C<$[> is treated as a compiler
2404 directive, and cannot influence the behavior of any other file.
2405 (That's why you can only assign compile-time constants to it.)
2406 Its use is highly discouraged.
2407
2408 Prior to Perl v5.10.0, assignment to C<$[> could be seen from outer lexical
2409 scopes in the same file, unlike other compile-time directives (such as
2410 L<strict>).  Using local() on it would bind its value strictly to a lexical
2411 block.  Now it is always lexically scoped.
2412
2413 As of Perl v5.16.0, it is implemented by the L<arybase> module.
2414
2415 As of Perl v5.30.0, or under C<use v5.16>, or C<no feature "array_base">,
2416 C<$[> no longer has any effect, and always contains 0.
2417 Assigning 0 to it is permitted, but any other value will produce an error.
2418
2419 Mnemonic: [ begins subscripts.
2420
2421 Deprecated in Perl v5.12.0.
2422
2423 =back
2424
2425 =cut