This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
1324f5a1a877b75f3933e668655fbf27b9bfc32a
[perl5.git] / t / run / switches.t
1 #!./perl -w
2
3 # Tests for the command-line switches:
4 # -0, -c, -l, -s, -m, -M, -V, -v, -h, -i, -E and all unknown
5 # Some switches have their own tests, see MANIFEST.
6
7 BEGIN {
8     chdir 't' if -d 't';
9     @INC = '../lib';
10 }
11
12 BEGIN { require "./test.pl"; }
13
14 plan(tests => 115);
15
16 use Config;
17 use Errno qw(EACCES EISDIR);
18
19 # due to a bug in VMS's piping which makes it impossible for runperl()
20 # to emulate echo -n (ie. stdin always winds up with a newline), these 
21 # tests almost totally fail.
22 $TODO = "runperl() unable to emulate echo -n due to pipe bug" if $^O eq 'VMS';
23
24 my $r;
25 my @tmpfiles = ();
26 END { unlink_all @tmpfiles }
27
28 # Tests for -0
29
30 $r = runperl(
31     switches    => [ '-0', ],
32     stdin       => 'foo\0bar\0baz\0',
33     prog        => 'print qq(<$_>) while <>',
34 );
35 is( $r, "<foo\0><bar\0><baz\0>", "-0" );
36
37 $r = runperl(
38     switches    => [ '-l', '-0', '-p' ],
39     stdin       => 'foo\0bar\0baz\0',
40     prog        => '1',
41 );
42 is( $r, "foo\nbar\nbaz\n", "-0 after a -l" );
43
44 $r = runperl(
45     switches    => [ '-0', '-l', '-p' ],
46     stdin       => 'foo\0bar\0baz\0',
47     prog        => '1',
48 );
49 is( $r, "foo\0bar\0baz\0", "-0 before a -l" );
50
51 $r = runperl(
52     switches    => [ sprintf("-0%o", ord 'x') ],
53     stdin       => 'fooxbarxbazx',
54     prog        => 'print qq(<$_>) while <>',
55 );
56 is( $r, "<foox><barx><bazx>", "-0 with octal number" );
57
58 $r = runperl(
59     switches    => [ '-00', '-p' ],
60     stdin       => 'abc\ndef\n\nghi\njkl\nmno\n\npq\n',
61     prog        => 's/\n/-/g;$_.=q(/)',
62 );
63 is( $r, 'abc-def--/ghi-jkl-mno--/pq-/', '-00 (paragraph mode)' );
64
65 $r = runperl(
66     switches    => [ '-0777', '-p' ],
67     stdin       => 'abc\ndef\n\nghi\njkl\nmno\n\npq\n',
68     prog        => 's/\n/-/g;$_.=q(/)',
69 );
70 is( $r, 'abc-def--ghi-jkl-mno--pq-/', '-0777 (slurp mode)' );
71
72 $r = runperl(
73     switches    => [ '-066' ],
74     prog        => 'BEGIN { print qq{($/)} } print qq{[$/]}',
75 );
76 is( $r, "(\066)[\066]", '$/ set at compile-time' );
77
78 # Tests for -c
79
80 my $filename = tempfile();
81 SKIP: {
82     local $TODO = '';   # this one works on VMS
83
84     open my $f, ">$filename" or skip( "Can't write temp file $filename: $!" );
85     print $f <<'SWTEST';
86 BEGIN { print "block 1\n"; }
87 CHECK { print "block 2\n"; }
88 INIT  { print "block 3\n"; }
89         print "block 4\n";
90 END   { print "block 5\n"; }
91 SWTEST
92     close $f or die "Could not close: $!";
93     $r = runperl(
94         switches        => [ '-c' ],
95         progfile        => $filename,
96         stderr          => 1,
97     );
98     # Because of the stderr redirection, we can't tell reliably the order
99     # in which the output is given
100     ok(
101         $r =~ /$filename syntax OK/
102         && $r =~ /\bblock 1\b/
103         && $r =~ /\bblock 2\b/
104         && $r !~ /\bblock 3\b/
105         && $r !~ /\bblock 4\b/
106         && $r !~ /\bblock 5\b/,
107         '-c'
108     );
109 }
110
111 {
112     my $tempdir = tempfile;
113     mkdir $tempdir, 0700 or die "Can't mkdir '$tempdir': $!";
114
115     local $ENV{'LC_ALL'} = 'C'; # Keep the test simple: expect English
116     local $ENV{LANGUAGE} = 'C';
117
118     # Win32 won't let us open the directory, so we never get to die with
119     # EISDIR, which happens after open.
120     my $error  = do { local $! = $^O eq 'MSWin32' ? EACCES : EISDIR; "$!" };
121     like(
122         runperl( switches => [ '-c' ], args  => [ $tempdir ], stderr => 1),
123         qr/Can't open perl script.*$tempdir.*\Q$error/s,
124         "RT \#61362: Cannot syntax-check a directory"
125     );
126     rmdir $tempdir or die "Can't rmdir '$tempdir': $!";
127 }
128
129 # Tests for -l
130
131 $r = runperl(
132     switches    => [ sprintf("-l%o", ord 'x') ],
133     prog        => 'print for qw/foo bar/'
134 );
135 is( $r, 'fooxbarx', '-l with octal number' );
136
137 # Tests for -s
138
139 $r = runperl(
140     switches    => [ '-s' ],
141     prog        => 'for (qw/abc def ghi/) {print defined $$_ ? $$_ : q(-)}',
142     args        => [ '--', '-abc=2', '-def', ],
143 );
144 is( $r, '21-', '-s switch parsing' );
145
146 $filename = tempfile();
147 SKIP: {
148     open my $f, ">$filename" or skip( "Can't write temp file $filename: $!" );
149     print $f <<'SWTEST';
150 #!perl -s
151 BEGIN { print $x,$y; exit }
152 SWTEST
153     close $f or die "Could not close: $!";
154     $r = runperl(
155         progfile    => $filename,
156         args        => [ '-x=foo -y' ],
157     );
158     is( $r, 'foo1', '-s on the shebang line' );
159 }
160
161 # Bug ID 20011106.084
162 $filename = tempfile();
163 SKIP: {
164     open my $f, ">$filename" or skip( "Can't write temp file $filename: $!" );
165     print $f <<'SWTEST';
166 #!perl -sn
167 BEGIN { print $x; exit }
168 SWTEST
169     close $f or die "Could not close: $!";
170     $r = runperl(
171         progfile    => $filename,
172         args        => [ '-x=foo' ],
173     );
174     is( $r, 'foo', '-sn on the shebang line' );
175 }
176
177 # Tests for -m and -M
178
179 my $package = tempfile();
180 $filename = "$package.pm";
181 SKIP: {
182     open my $f, ">$filename" or skip( "Can't write temp file $filename: $!",4 );
183     print $f <<"SWTESTPM";
184 package $package;
185 sub import { print map "<\$_>", \@_ }
186 1;
187 SWTESTPM
188     close $f or die "Could not close: $!";
189     $r = runperl(
190         switches    => [ "-M$package" ],
191         prog        => '1',
192     );
193     is( $r, "<$package>", '-M' );
194     $r = runperl(
195         switches    => [ "-M$package=foo" ],
196         prog        => '1',
197     );
198     is( $r, "<$package><foo>", '-M with import parameter' );
199     $r = runperl(
200         switches    => [ "-m$package" ],
201         prog        => '1',
202     );
203
204     {
205         local $TODO = '';  # this one works on VMS
206         is( $r, '', '-m' );
207     }
208     $r = runperl(
209         switches    => [ "-m$package=foo,bar" ],
210         prog        => '1',
211     );
212     is( $r, "<$package><foo><bar>", '-m with import parameters' );
213     push @tmpfiles, $filename;
214
215   {
216     local $TODO = '';  # these work on VMS
217
218     is( runperl( switches => [ '-MTie::Hash' ], stderr => 1, prog => 1 ),
219           '', "-MFoo::Bar allowed" );
220
221     like( runperl( switches => [ "-M:$package" ], stderr => 1,
222                    prog => 'die q{oops}' ),
223           qr/Invalid module name [\w:]+ with -M option\b/,
224           "-M:Foo not allowed" );
225
226     like( runperl( switches => [ '-mA:B:C' ], stderr => 1,
227                    prog => 'die q{oops}' ),
228           qr/Invalid module name [\w:]+ with -m option\b/,
229           "-mFoo:Bar not allowed" );
230
231     like( runperl( switches => [ '-m-A:B:C' ], stderr => 1,
232                    prog => 'die q{oops}' ),
233           qr/Invalid module name [\w:]+ with -m option\b/,
234           "-m-Foo:Bar not allowed" );
235
236     like( runperl( switches => [ '-m-' ], stderr => 1,
237                    prog => 'die q{oops}' ),
238           qr/Module name required with -m option\b/,
239           "-m- not allowed" );
240
241     like( runperl( switches => [ '-M-=' ], stderr => 1,
242                    prog => 'die q{oops}' ),
243           qr/Module name required with -M option\b/,
244           "-M- not allowed" );
245   }  # disable TODO on VMS
246 }
247 is runperl(stderr => 1, prog => '#!perl -m'),
248    qq 'Too late for "-m" option at -e line 1.\n', '#!perl -m';
249 is runperl(stderr => 1, prog => '#!perl -M'),
250    qq 'Too late for "-M" option at -e line 1.\n', '#!perl -M';
251
252 # Tests for -V
253
254 {
255     local $TODO = '';   # these ones should work on VMS
256
257     # basic perl -V should generate significant output.
258     # we don't test actual format too much since it could change
259     like( runperl( switches => ['-V'] ), qr/(\n.*){20}/,
260           '-V generates 20+ lines' );
261
262     like( runperl( switches => ['-V'] ),
263           qr/\ASummary of my perl5 .*configuration:/,
264           '-V looks okay' );
265
266     # lookup a known config var
267     chomp( $r=runperl( switches => ['-V:osname'] ) );
268     is( $r, "osname='$^O';", 'perl -V:osname');
269
270     # lookup a nonexistent var
271     chomp( $r=runperl( switches => ['-V:this_var_makes_switches_test_fail'] ) );
272     is( $r, "this_var_makes_switches_test_fail='UNKNOWN';",
273         'perl -V:unknown var');
274
275     # regexp lookup
276     # platforms that don't like this quoting can either skip this test
277     # or fix test.pl _quote_args
278     $r = runperl( switches => ['"-V:i\D+size"'] );
279     # should be unlike( $r, qr/^$|not found|UNKNOWN/ );
280     like( $r, qr/^(?!.*(not found|UNKNOWN))./, 'perl -V:re got a result' );
281
282     # make sure each line we got matches the re
283     ok( !( grep !/^i\D+size=/, split /^/, $r ), '-V:re correct' );
284 }
285
286 # Tests for -v
287
288 {
289     local $TODO = '';   # these ones should work on VMS
290     # there are definitely known build configs where this test will fail
291     # DG/UX comes to mind. Maybe we should remove these special cases?
292     my $v = sprintf "%vd", $^V;
293     my $ver = $Config{PERL_VERSION};
294     my $rel = $Config{PERL_SUBVERSION};
295     like( runperl( switches => ['-v'] ),
296           qr/This is perl 5, version \Q$ver\E, subversion \Q$rel\E \(v\Q$v\E(?:[-*\w]+| \([^)]+\))?\) built for \Q$Config{archname}\E.+Copyright.+Larry Wall.+Artistic License.+GNU General Public License/s,
297           '-v looks okay' );
298
299 }
300
301 # Tests for -h
302
303 {
304     local $TODO = '';   # these ones should work on VMS
305
306     like( runperl( switches => ['-h'] ),
307           qr/Usage: .+(?i:perl(?:$Config{_exe})?).+switches.+programfile.+arguments/,
308           '-h looks okay' );
309
310 }
311
312 # Tests for switches which do not exist
313
314 foreach my $switch (split //, "ABbGgHJjKkLNOoPQqRrYyZz123456789_")
315 {
316     local $TODO = '';   # these ones should work on VMS
317
318     like( runperl( switches => ["-$switch"], stderr => 1,
319                    prog => 'die q{oops}' ),
320           qr/\QUnrecognized switch: -$switch  (-h will show valid options)./,
321           "-$switch correctly unknown" );
322
323     # [perl #104288]
324     like( runperl( stderr => 1, prog => "#!perl -$switch" ),
325           qr/^Unrecognized switch: -$switch  \(-h will show valid (?x:
326              )options\) at -e line 1\./,
327           "-$switch unrecognised on #! line" );
328 }
329
330 # Tests for unshebangable switches
331 for (qw( e f x E S V )) {
332     $r = runperl(
333         stderr   => 1,
334         prog     => "#!perl -$_",
335     );
336     is $r, "Can't emulate -$_ on #! line at -e line 1.\n","-$_ on #! line";
337 }
338
339 # Tests for -i
340
341 {
342     local $TODO = '';   # these ones should work on VMS
343
344     sub do_i_unlink { unlink_all("file", "file.bak") }
345
346     open(FILE, ">file") or die "$0: Failed to create 'file': $!";
347     print FILE <<__EOF__;
348 foo yada dada
349 bada foo bing
350 king kong foo
351 __EOF__
352     close FILE;
353
354     END { do_i_unlink() }
355
356     runperl( switches => ['-pi.bak'], prog => 's/foo/bar/', args => ['file'] );
357
358     open(FILE, "file") or die "$0: Failed to open 'file': $!";
359     chomp(my @file = <FILE>);
360     close FILE;
361
362     open(BAK, "file.bak") or die "$0: Failed to open 'file': $!";
363     chomp(my @bak = <BAK>);
364     close BAK;
365
366     is(join(":", @file),
367        "bar yada dada:bada bar bing:king kong bar",
368        "-i new file");
369     is(join(":", @bak),
370        "foo yada dada:bada foo bing:king kong foo",
371        "-i backup file");
372
373     my $out1 = runperl(
374         switches => ['-i.bak -p'],
375         prog     => 'exit',
376         stderr   => 1,
377         stdin    => "1\n",
378     );
379     is(
380         $out1,
381         "-i used with no filenames on the command line, reading from STDIN.\n",
382         "warning when no files given"
383     );
384     my $out2 = runperl(
385         switches => ['-i.bak -p'],
386         prog     => 'exit',
387         stderr   => 1,
388         stdin    => "1\n",
389         args     => ['file'],
390     );
391     is($out2, "", "no warning when files given");
392 }
393
394 # Tests for -E
395
396 $TODO = '';  # the -E tests work on VMS
397
398 $r = runperl(
399     switches    => [ '-E', '"say q(Hello, world!)"']
400 );
401 is( $r, "Hello, world!\n", "-E say" );
402
403
404 $r = runperl(
405     switches    => [ '-E', '"undef ~~ undef and say q(Hello, world!)"']
406 );
407 is( $r, "Hello, world!\n", "-E ~~" );
408
409 $r = runperl(
410     switches    => [ '-E', '"given(undef) {when(undef) { say q(Hello, world!)"}}']
411 );
412 is( $r, "Hello, world!\n", "-E given" );
413
414 $r = runperl(
415     switches    => [ '-nE', q("} END { say q/affe/") ],
416     stdin       => 'zomtek',
417 );
418 is( $r, "affe\n", '-E works outside of the block created by -n' );
419
420 $r = runperl(
421     switches    => [ '-E', q("*{'bar'} = sub{}; print 'Hello, world!',qq|\n|;")]
422 );
423 is( $r, "Hello, world!\n", "-E does not enable strictures" );
424
425 # RT #30660
426
427 $filename = tempfile();
428 SKIP: {
429     open my $f, ">$filename" or skip( "Can't write temp file $filename: $!" );
430     print $f <<'SWTEST';
431 #!perl -w    -iok
432 print "$^I\n";
433 SWTEST
434     close $f or die "Could not close: $!";
435     $r = runperl(
436         progfile    => $filename,
437     );
438     like( $r, qr/ok/, 'Spaces on the #! line (#30660)' );
439 }