This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
117d7782b4e126c2c095ec28cf1b0bae45d6a5e6
[perl5.git] / cpan / Socket / Makefile.PL
1 #!perl
2 use strict;
3 use warnings;
4
5 use ExtUtils::MakeMaker;
6 use ExtUtils::Constant 0.23 'WriteConstants';
7 use Config;
8
9 my @DEFINES;
10
11 my $cb;
12 my $seq = 0;
13 sub check_for
14 {
15     my %args = @_;
16     return if $ENV{PERL_CORE};
17     return if defined $Config{$args{confkey}};
18
19     require ExtUtils::CBuilder;
20     $cb ||= ExtUtils::CBuilder->new( quiet => 1 );
21
22     my $main = $args{main};
23
24     print "Checking $args{define}...\n";
25
26     my $file_base = "test-$seq"; $seq++;
27
28     my $file_source = "$file_base.c";
29
30     {
31         open( my $file_source_fh, ">", $file_source ) or die "Cannot write $file_source - $!";
32         print $file_source_fh <<"EOF";
33 #include <sys/types.h>
34 #ifdef WIN32
35 # include <ws2tcpip.h>
36 # include <winsock.h>
37 #else
38 # include <sys/socket.h>
39 # include <netdb.h>
40 # include <netinet/in.h>
41 # include <arpa/inet.h>
42 #endif
43 int main(int argc, char *argv[])
44   {
45     (void)argc;
46     (void)argv;
47     $main
48     return 0;
49   }
50 EOF
51     }
52
53     my $file_obj = eval { $cb->compile( source => $file_source ) };
54     unlink $file_source;
55
56     return 0 unless defined $file_obj;
57
58     my $file_exe = eval { $cb->link_executable( objects => $file_obj ) };
59     unlink $file_obj;
60
61     return 0 unless defined $file_exe;
62
63     # Don't need to try running it
64     unlink $file_exe;
65
66     push @DEFINES, $args{define};
67 }
68
69 sub check_for_func
70 {
71     my %args = @_;
72     my $func = delete $args{func};
73     check_for( %args, main => "void *p = &$func; (void)p;" );
74 }
75
76 my %defines = (
77     # -Dfoo               func()        $Config{key}
78     HAS_GETADDRINFO => [ "getaddrinfo", "d_getaddrinfo" ],
79     HAS_GETNAMEINFO => [ "getnameinfo", "d_getnameinfo" ],
80     HAS_INET_ATON   => [ "inet_aton",   "d_inetaton" ],
81     HAS_INETNTOP    => [ "inet_ntop",   "d_inetntop" ],
82     HAS_INETPTON    => [ "inet_pton",   "d_inetpton" ],
83 );
84
85 foreach my $define ( sort keys %defines ) {
86     my ( $func, $key ) = @{$defines{$define}};
87     check_for_func( 
88         confkey => $key,
89         define  => $define,
90         func    => $func
91     );
92 }
93
94 check_for(
95     confkey => "d_sockaddr_sa_len",
96     define  => "HAS_SOCKADDR_SA_LEN",
97     main    => "struct sockaddr sa; sa.sa_len = 0;"
98 );
99
100 check_for(
101     confkey => "d_sockaddr_in6",
102     define  => "HAS_SOCKADDR_IN6",
103     main    => "struct sockaddr_in6 sin6; sin6.sin6_family = AF_INET6;"
104 );
105
106 check_for(
107     confkey => "d_sin6_scope_id",
108     define  => "HAS_SIN6_SCOPE_ID",
109     main    => "struct sockaddr_in6 sin6; sin6.sin6_scope_id = 0;"
110 );
111
112 check_for(
113     confkey => "d_ip_mreq",
114     define  => "HAS_IP_MREQ",
115     main    => "struct ip_mreq mreq; mreq.imr_multiaddr.s_addr = INADDR_ANY;"
116 );
117
118 # TODO: Needs adding to perl5 core before importing dual-life again
119 check_for(
120     confkey => "d_ip_mreq_source",
121     define  => "HAS_IP_MREQ_SOURCE",
122     main    => "struct ip_mreq_source mreq; mreq.imr_multiaddr.s_addr = INADDR_ANY;"
123 );
124
125 check_for(
126     confkey => "d_ipv6_mreq",
127     define  => "HAS_IPV6_MREQ",
128     main    => "struct ipv6_mreq mreq; mreq.ipv6mr_interface = 0;"
129 );
130
131 my %makefile_args;
132
133 # Since we're providing a later version of a core module, before 5.12 the
134 # @INC order is wrong so we'll have to go in perl rather than site dirs
135 $makefile_args{INSTALLDIRS} = "perl" if $] < 5.012;
136
137 WriteMakefile(
138     NAME          => 'Socket',
139     VERSION_FROM  => 'Socket.pm',
140     # ABSTRACT_FROM gets confused by C<Socket>
141     ABSTRACT      => 'networking constants and support functions',
142    ($Config{libs} =~ /(-lsocks\S*)/ ? (LIBS => [ "$1" ] ) : ()),
143     XSPROTOARG    => '-noprototypes',           # XXX remove later?
144     realclean     => {FILES=> 'const-c.inc const-xs.inc'},
145     DEFINE        => join( " ", map { "-D$_" } @DEFINES ),
146     CONFIGURE_REQUIRES => {
147         'ExtUtils::CBuilder' => 0,
148         'ExtUtils::Constant' => '0.23',
149     },
150     MIN_PERL_VERSION => '5.006001',
151     LICENSE       => 'perl',
152     %makefile_args,
153 );
154 my @names = (
155     qw(
156         AF_802 AF_AAL AF_APPLETALK AF_CCITT AF_CHAOS AF_CTF AF_DATAKIT
157         AF_DECnet AF_DLI AF_ECMA AF_GOSIP AF_HYLINK AF_IMPLINK AF_INET AF_INET6
158         AF_ISO AF_KEY AF_LAST AF_LAT AF_LINK AF_MAX AF_NBS AF_NIT AF_NS AF_OSI
159         AF_OSINET AF_PUP AF_ROUTE AF_SNA AF_UNIX AF_UNSPEC AF_USER AF_WAN
160         AF_X25
161
162         AI_ADDRCONFIG AI_ALL AI_CANONIDN AI_CANONNAME AI_IDN
163         AI_IDN_ALLOW_UNASSIGNED AI_IDN_USE_STD3_ASCII_RULES AI_NUMERICHOST
164         AI_NUMERICSERV AI_PASSIVE AI_V4MAPPED
165
166         EAI_ADDRFAMILY EAI_AGAIN EAI_BADFLAGS EAI_BADHINTS EAI_FAIL EAI_FAMILY
167         EAI_NODATA EAI_NONAME EAI_PROTOCOL EAI_SERVICE EAI_SOCKTYPE EAI_SYSTEM
168
169         IOV_MAX
170
171         IP_ADD_MEMBERSHIP IP_ADD_SOURCE_MEMBERSHIP IP_DROP_MEMBERSHIP
172         IP_DROP_SOURCE_MEMBERSHIP IP_HDRINCL IP_MULTICAST_IF IP_MULTICAST_LOOP
173         IP_MULTICAST_TTL IP_OPTIONS IP_RECVOPTS IP_RECVRETOPTS IP_RETOPTS IP_TOS
174         IP_TTL 
175
176         IPV6_ADD_MEMBERSHIP IPV6_DROP_MEMBERSHIP IPV6_JOIN_GROUP
177         IPV6_LEAVE_GROUP IPV6_MTU IPV6_MTU_DISCOVER IPV6_MULTICAST_HOPS
178         IPV6_MULTICAST_IF IPV6_MULTICAST_LOOP IPV6_UNICAST_HOPS IPV6_V6ONLY
179
180         MSG_BCAST MSG_BTAG MSG_CTLFLAGS MSG_CTLIGNORE MSG_DONTWAIT MSG_EOF
181         MSG_EOR MSG_ERRQUEUE MSG_ETAG MSG_FIN MSG_MAXIOVLEN MSG_MCAST
182         MSG_NOSIGNAL MSG_RST MSG_SYN MSG_TRUNC MSG_URG MSG_WAITALL MSG_WIRE
183
184         NI_DGRAM NI_IDN NI_IDN_ALLOW_UNASSIGNED NI_IDN_USE_STD3_ASCII_RULES
185         NI_NAMEREQD NI_NOFQDN NI_NUMERICHOST NI_NUMERICSERV
186
187         PF_802 PF_AAL PF_APPLETALK PF_CCITT PF_CHAOS PF_CTF PF_DATAKIT
188         PF_DECnet PF_DLI PF_ECMA PF_GOSIP PF_HYLINK PF_IMPLINK PF_INET PF_INET6
189         PF_ISO PF_KEY PF_LAST PF_LAT PF_LINK PF_MAX PF_NBS PF_NIT PF_NS PF_OSI
190         PF_OSINET PF_PUP PF_ROUTE PF_SNA PF_UNIX PF_UNSPEC PF_USER PF_WAN
191         PF_X25
192
193         SCM_CONNECT SCM_CREDENTIALS SCM_CREDS SCM_TIMESTAMP
194
195         SOCK_DGRAM SOCK_RAW SOCK_RDM SOCK_SEQPACKET SOCK_STREAM
196         SOCK_NONBLOCK SOCK_CLOEXEC
197
198         SOL_SOCKET 
199
200         SOMAXCONN
201
202         SO_ACCEPTCONN SO_ATTACH_FILTER SO_BACKLOG SO_BROADCAST SO_CHAMELEON
203         SO_DEBUG SO_DETACH_FILTER SO_DGRAM_ERRIND SO_DOMAIN SO_DONTLINGER
204         SO_DONTROUTE SO_ERROR SO_FAMILY SO_KEEPALIVE SO_LINGER SO_OOBINLINE
205         SO_PASSCRED SO_PASSIFNAME SO_PEERCRED SO_PROTOCOL SO_PROTOTYPE
206         SO_RCVBUF SO_RCVLOWAT SO_RCVTIMEO SO_REUSEADDR SO_REUSEPORT
207         SO_SECURITY_AUTHENTICATION SO_SECURITY_ENCRYPTION_NETWORK
208         SO_SECURITY_ENCRYPTION_TRANSPORT SO_SNDBUF SO_SNDLOWAT SO_SNDTIMEO
209         SO_STATE SO_TYPE SO_USELOOPBACK SO_XOPEN SO_XSE
210
211         TCP_CONGESTION TCP_CONNECTIONTIMEOUT TCP_CORK TCP_DEFER_ACCEPT TCP_INFO
212         TCP_INIT_CWND TCP_KEEPALIVE TCP_KEEPCNT TCP_KEEPIDLE TCP_KEEPINTVL
213         TCP_LINGER2 TCP_MAXRT TCP_MAXSEG TCP_MD5SIG TCP_NODELAY TCP_NOOPT
214         TCP_NOPUSH TCP_QUICKACK TCP_SACK_ENABLE TCP_STDURG TCP_SYNCNT
215         TCP_WINDOW_CLAMP
216
217         UIO_MAXIOV
218     ),
219     {name=>"IPPROTO_IP",   type=>"IV", default=>["IV",   0]},
220     {name=>"IPPROTO_IPV6", type=>"IV", default=>["IV",  41]},
221     {name=>"IPPROTO_RAW",  type=>"IV", default=>["IV", 255]},
222     {name=>"IPPROTO_ICMP", type=>"IV", default=>["IV",  1]},
223     {name=>"IPPROTO_TCP",  type=>"IV", default=>["IV",  6]},
224     {name=>"IPPROTO_UDP",  type=>"IV", default=>["IV", 17]},
225     {name=>"SHUT_RD",   type=>"IV", default=>["IV", "0"]},
226     {name=>"SHUT_WR",   type=>"IV", default=>["IV", "1"]},
227     {name=>"SHUT_RDWR", type=>"IV", default=>["IV", "2"]},
228 );
229
230 push @names, {
231     name  => $_,
232     type  => "IV",
233     macro => [ "#if defined($_) || defined(HAS_$_) /* might be an enum */\n",
234                "#endif\n" ]
235 } foreach qw (MSG_CTRUNC MSG_DONTROUTE MSG_OOB MSG_PEEK MSG_PROXY SCM_RIGHTS);
236
237 push @names, {
238     name  => $_,
239     type  => "SV",
240     pre   => "struct in_addr ip_address; ip_address.s_addr = htonl($_);",
241     value => "newSVpvn_flags((char *)&ip_address,sizeof(ip_address), SVs_TEMP)",
242 } foreach qw(INADDR_ANY INADDR_LOOPBACK INADDR_NONE INADDR_BROADCAST);
243
244 push @names, {
245     name  => $_,
246     type  => "SV",
247     macro => [ "#ifdef ${_}_INIT\n",
248                "#endif\n" ],
249     pre   => "struct in6_addr ip6_address = ${_}_INIT;",
250     value => "newSVpvn_flags((char *)&ip6_address,sizeof(ip6_address), SVs_TEMP)",
251 } foreach qw(IN6ADDR_ANY IN6ADDR_LOOPBACK);
252
253 # Work around an old Perl core bug that affects ExtUtils::Constants on
254 # pre-5.8.2 Perls.  EU:C should be amended to work around this itself.
255 if("$]" < 5.008002) {
256     require ExtUtils::Constant::ProxySubs;
257     no warnings "once";
258     $ExtUtils::Constant::ProxySubs::type_to_C_value{$_} = sub { () }
259         foreach qw(YES NO UNDEF), "";
260 }
261
262 WriteConstants(
263     PROXYSUBS => {autoload => 1},
264     NAME => 'Socket',
265     NAMES => \@names,
266 );