This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
doubled words in pods (from Simon Cozens
[perl5.git] / pod / perllocale.pod
1 =head1 NAME
2
3 perllocale - Perl locale handling (internationalization and localization)
4
5 =head1 DESCRIPTION
6
7 Perl supports language-specific notions of data such as "is this
8 a letter", "what is the uppercase equivalent of this letter", and
9 "which of these letters comes first".  These are important issues,
10 especially for languages other than English--but also for English: it
11 would be naE<iuml>ve to imagine that C<A-Za-z> defines all the "letters"
12 needed to write in English. Perl is also aware that some character other
13 than '.' may be preferred as a decimal point, and that output date
14 representations may be language-specific.  The process of making an
15 application take account of its users' preferences in such matters is
16 called B<internationalization> (often abbreviated as B<i18n>); telling
17 such an application about a particular set of preferences is known as
18 B<localization> (B<l10n>).
19
20 Perl can understand language-specific data via the standardized (ISO C,
21 XPG4, POSIX 1.c) method called "the locale system". The locale system is
22 controlled per application using one pragma, one function call, and
23 several environment variables.
24
25 B<NOTE>: This feature is new in Perl 5.004, and does not apply unless an
26 application specifically requests it--see L<Backward compatibility>.
27 The one exception is that write() now B<always> uses the current locale
28 - see L<"NOTES">.
29
30 =head1 PREPARING TO USE LOCALES
31
32 If Perl applications are to understand and present your data
33 correctly according a locale of your choice, B<all> of the following
34 must be true:
35
36 =over 4
37
38 =item *
39
40 B<Your operating system must support the locale system>.  If it does,
41 you should find that the setlocale() function is a documented part of
42 its C library.
43
44 =item *
45
46 B<Definitions for locales that you use must be installed>.  You, or
47 your system administrator, must make sure that this is the case. The
48 available locales, the location in which they are kept, and the manner
49 in which they are installed all vary from system to system.  Some systems
50 provide only a few, hard-wired locales and do not allow more to be
51 added.  Others allow you to add "canned" locales provided by the system
52 supplier.  Still others allow you or the system administrator to define
53 and add arbitrary locales.  (You may have to ask your supplier to
54 provide canned locales that are not delivered with your operating
55 system.)  Read your system documentation for further illumination.
56
57 =item *
58
59 B<Perl must believe that the locale system is supported>.  If it does,
60 C<perl -V:d_setlocale> will say that the value for C<d_setlocale> is
61 C<define>.
62
63 =back
64
65 If you want a Perl application to process and present your data
66 according to a particular locale, the application code should include
67 the S<C<use locale>> pragma (see L<The use locale pragma>) where
68 appropriate, and B<at least one> of the following must be true:
69
70 =over 4
71
72 =item *
73
74 B<The locale-determining environment variables (see L<"ENVIRONMENT">)
75 must be correctly set up> at the time the application is started, either
76 by yourself or by whoever set up your system account.
77
78 =item *
79
80 B<The application must set its own locale> using the method described in
81 L<The setlocale function>.
82
83 =back
84
85 =head1 USING LOCALES
86
87 =head2 The use locale pragma
88
89 By default, Perl ignores the current locale.  The S<C<use locale>>
90 pragma tells Perl to use the current locale for some operations:
91
92 =over 4
93
94 =item *
95
96 B<The comparison operators> (C<lt>, C<le>, C<cmp>, C<ge>, and C<gt>) and
97 the POSIX string collation functions strcoll() and strxfrm() use
98 C<LC_COLLATE>.  sort() is also affected if used without an
99 explicit comparison function, because it uses C<cmp> by default.
100
101 B<Note:> C<eq> and C<ne> are unaffected by locale: they always
102 perform a byte-by-byte comparison of their scalar operands.  What's
103 more, if C<cmp> finds that its operands are equal according to the
104 collation sequence specified by the current locale, it goes on to
105 perform a byte-by-byte comparison, and only returns I<0> (equal) if the
106 operands are bit-for-bit identical.  If you really want to know whether
107 two strings--which C<eq> and C<cmp> may consider different--are equal
108 as far as collation in the locale is concerned, see the discussion in
109 L<Category LC_COLLATE: Collation>.
110
111 =item *
112
113 B<Regular expressions and case-modification functions> (uc(), lc(),
114 ucfirst(), and lcfirst()) use C<LC_CTYPE>
115
116 =item *
117
118 B<The formatting functions> (printf(), sprintf() and write()) use
119 C<LC_NUMERIC>
120
121 =item *
122
123 B<The POSIX date formatting function> (strftime()) uses C<LC_TIME>.
124
125 =back
126
127 C<LC_COLLATE>, C<LC_CTYPE>, and so on, are discussed further in L<LOCALE
128 CATEGORIES>.
129
130 The default behavior is restored with the S<C<no locale>> pragma, or
131 upon reaching the end of block enclosing C<use locale>.
132
133 The string result of any operation that uses locale
134 information is tainted, as it is possible for a locale to be
135 untrustworthy.  See L<"SECURITY">.
136
137 =head2 The setlocale function
138
139 You can switch locales as often as you wish at run time with the
140 POSIX::setlocale() function:
141
142         # This functionality not usable prior to Perl 5.004
143         require 5.004;
144
145         # Import locale-handling tool set from POSIX module.
146         # This example uses: setlocale -- the function call
147         #                    LC_CTYPE -- explained below
148         use POSIX qw(locale_h);
149
150         # query and save the old locale
151         $old_locale = setlocale(LC_CTYPE);
152
153         setlocale(LC_CTYPE, "fr_CA.ISO8859-1");
154         # LC_CTYPE now in locale "French, Canada, codeset ISO 8859-1"
155
156         setlocale(LC_CTYPE, "");
157         # LC_CTYPE now reset to default defined by LC_ALL/LC_CTYPE/LANG
158         # environment variables.  See below for documentation.
159
160         # restore the old locale
161         setlocale(LC_CTYPE, $old_locale);
162
163 The first argument of setlocale() gives the B<category>, the second the
164 B<locale>.  The category tells in what aspect of data processing you
165 want to apply locale-specific rules.  Category names are discussed in
166 L<LOCALE CATEGORIES> and L<"ENVIRONMENT">.  The locale is the name of a
167 collection of customization information corresponding to a particular
168 combination of language, country or territory, and codeset.  Read on for
169 hints on the naming of locales: not all systems name locales as in the
170 example.
171
172 If no second argument is provided and the category is something else
173 than LC_ALL, the function returns a string naming the current locale
174 for the category.  You can use this value as the second argument in a
175 subsequent call to setlocale().
176
177 If no second argument is provided and the category is LC_ALL, the
178 result is implementation-dependent.  It may be a string of
179 concatenated locales names (separator also implementation-dependent)
180 or a single locale name.  Please consult your L<setlocale(3)> for
181 details.
182
183 If a second argument is given and it corresponds to a valid locale,
184 the locale for the category is set to that value, and the function
185 returns the now-current locale value.  You can then use this in yet
186 another call to setlocale().  (In some implementations, the return
187 value may sometimes differ from the value you gave as the second
188 argument--think of it as an alias for the value you gave.)
189
190 As the example shows, if the second argument is an empty string, the
191 category's locale is returned to the default specified by the
192 corresponding environment variables.  Generally, this results in a
193 return to the default that was in force when Perl started up: changes
194 to the environment made by the application after startup may or may not
195 be noticed, depending on your system's C library.
196
197 If the second argument does not correspond to a valid locale, the locale
198 for the category is not changed, and the function returns I<undef>.
199
200 For further information about the categories, consult L<setlocale(3)>.
201
202 =head2 Finding locales
203
204 For locales available in your system, consult also L<setlocale(3)> to
205 see whether it leads to the list of available locales (search for the
206 I<SEE ALSO> section).  If that fails, try the following command lines:
207
208         locale -a
209
210         nlsinfo
211
212         ls /usr/lib/nls/loc
213
214         ls /usr/lib/locale
215
216         ls /usr/lib/nls
217
218         ls /usr/share/locale
219
220 and see whether they list something resembling these
221
222         en_US.ISO8859-1     de_DE.ISO8859-1     ru_RU.ISO8859-5
223         en_US.iso88591      de_DE.iso88591      ru_RU.iso88595
224         en_US               de_DE               ru_RU
225         en                  de                  ru
226         english             german              russian
227         english.iso88591    german.iso88591     russian.iso88595
228         english.roman8                          russian.koi8r
229
230 Sadly, even though the calling interface for setlocale() has been
231 standardized, names of locales and the directories where the
232 configuration resides have not been.  The basic form of the name is
233 I<language_territory>B<.>I<codeset>, but the latter parts after
234 I<language> are not always present.  The I<language> and I<country>
235 are usually from the standards B<ISO 3166> and B<ISO 639>, the
236 two-letter abbreviations for the countries and the languages of the
237 world, respectively.  The I<codeset> part often mentions some B<ISO
238 8859> character set, the Latin codesets.  For example, C<ISO 8859-1>
239 is the so-called "Western European codeset" that can be used to encode
240 most Western European languages adequately.  Again, there are several
241 ways to write even the name of that one standard.  Lamentably.
242
243 Two special locales are worth particular mention: "C" and "POSIX".
244 Currently these are effectively the same locale: the difference is
245 mainly that the first one is defined by the C standard, the second by
246 the POSIX standard.  They define the B<default locale> in which
247 every program starts in the absence of locale information in its
248 environment.  (The I<default> default locale, if you will.)  Its language
249 is (American) English and its character codeset ASCII.
250
251 B<NOTE>: Not all systems have the "POSIX" locale (not all systems are
252 POSIX-conformant), so use "C" when you need explicitly to specify this
253 default locale.
254
255 =head2 LOCALE PROBLEMS
256
257 You may encounter the following warning message at Perl startup:
258
259         perl: warning: Setting locale failed.
260         perl: warning: Please check that your locale settings:
261                 LC_ALL = "En_US",
262                 LANG = (unset)
263             are supported and installed on your system.
264         perl: warning: Falling back to the standard locale ("C").
265
266 This means that your locale settings had LC_ALL set to "En_US" and
267 LANG exists but has no value.  Perl tried to believe you but could not.
268 Instead, Perl gave up and fell back to the "C" locale, the default locale
269 that is supposed to work no matter what.  This usually means your locale
270 settings were wrong, they mention locales your system has never heard
271 of, or the locale installation in your system has problems (for example,
272 some system files are broken or missing).  There are quick and temporary
273 fixes to these problems, as well as more thorough and lasting fixes.
274
275 =head2 Temporarily fixing locale problems
276
277 The two quickest fixes are either to render Perl silent about any
278 locale inconsistencies or to run Perl under the default locale "C".
279
280 Perl's moaning about locale problems can be silenced by setting the
281 environment variable PERL_BADLANG to a zero value, for example "0".
282 This method really just sweeps the problem under the carpet: you tell
283 Perl to shut up even when Perl sees that something is wrong.  Do not
284 be surprised if later something locale-dependent misbehaves.
285
286 Perl can be run under the "C" locale by setting the environment
287 variable LC_ALL to "C".  This method is perhaps a bit more civilized
288 than the PERL_BADLANG approach, but setting LC_ALL (or
289 other locale variables) may affect other programs as well, not just
290 Perl.  In particular, external programs run from within Perl will see
291 these changes.  If you make the new settings permanent (read on), all
292 programs you run see the changes.  See L<ENVIRONMENT> for
293 the full list of relevant environment variables and L<USING LOCALES>
294 for their effects in Perl.  Effects in other programs are 
295 easily deducible.  For example, the variable LC_COLLATE may well affect
296 your B<sort> program (or whatever the program that arranges `records'
297 alphabetically in your system is called).
298
299 You can test out changing these variables temporarily, and if the
300 new settings seem to help, put those settings into your shell startup
301 files.  Consult your local documentation for the exact details.  For in
302 Bourne-like shells (B<sh>, B<ksh>, B<bash>, B<zsh>):
303
304         LC_ALL=en_US.ISO8859-1
305         export LC_ALL
306
307 This assumes that we saw the locale "en_US.ISO8859-1" using the commands
308 discussed above.  We decided to try that instead of the above faulty
309 locale "En_US"--and in Cshish shells (B<csh>, B<tcsh>)
310
311         setenv LC_ALL en_US.ISO8859-1
312
313 If you do not know what shell you have, consult your local
314 helpdesk or the equivalent.
315
316 =head2 Permanently fixing locale problems
317
318 The slower but superior fixes are when you may be able to yourself
319 fix the misconfiguration of your own environment variables.  The
320 mis(sing)configuration of the whole system's locales usually requires
321 the help of your friendly system administrator.
322
323 First, see earlier in this document about L<Finding locales>.  That tells
324 how to find which locales are really supported--and more importantly,
325 installed--on your system.  In our example error message, environment
326 variables affecting the locale are listed in the order of decreasing
327 importance (and unset variables do not matter).  Therefore, having
328 LC_ALL set to "En_US" must have been the bad choice, as shown by the
329 error message.  First try fixing locale settings listed first.
330
331 Second, if using the listed commands you see something B<exactly>
332 (prefix matches do not count and case usually counts) like "En_US"
333 without the quotes, then you should be okay because you are using a
334 locale name that should be installed and available in your system.
335 In this case, see L<Permanently fixing your system's locale configuration>.
336
337 =head2 Permanently fixing your system's locale configuration
338
339 This is when you see something like:
340
341         perl: warning: Please check that your locale settings:
342                 LC_ALL = "En_US",
343                 LANG = (unset)
344             are supported and installed on your system.
345
346 but then cannot see that "En_US" listed by the above-mentioned
347 commands.  You may see things like "en_US.ISO8859-1", but that isn't
348 the same.  In this case, try running under a locale
349 that you can list and which somehow matches what you tried.  The
350 rules for matching locale names are a bit vague because
351 standardization is weak in this area.  See again the L<Finding
352 locales> about general rules.
353
354 =head2 Fixing system locale configuration
355
356 Contact a system administrator (preferably your own) and report the exact
357 error message you get, and ask them to read this same documentation you
358 are now reading.  They should be able to check whether there is something
359 wrong with the locale configuration of the system.  The L<Finding locales>
360 section is unfortunately a bit vague about the exact commands and places
361 because these things are not that standardized.
362
363 =head2 The localeconv function
364
365 The POSIX::localeconv() function allows you to get particulars of the
366 locale-dependent numeric formatting information specified by the current
367 C<LC_NUMERIC> and C<LC_MONETARY> locales.  (If you just want the name of
368 the current locale for a particular category, use POSIX::setlocale()
369 with a single parameter--see L<The setlocale function>.)
370
371         use POSIX qw(locale_h);
372
373         # Get a reference to a hash of locale-dependent info
374         $locale_values = localeconv();
375
376         # Output sorted list of the values
377         for (sort keys %$locale_values) {
378             printf "%-20s = %s\n", $_, $locale_values->{$_}
379         }
380
381 localeconv() takes no arguments, and returns B<a reference to> a hash.
382 The keys of this hash are variable names for formatting, such as
383 C<decimal_point> and C<thousands_sep>.  The values are the
384 corresponding, er, values.  See L<POSIX (3)/localeconv> for a longer
385 example listing the categories an implementation might be expected to
386 provide; some provide more and others fewer.  You don't need an
387 explicit C<use locale>, because localeconv() always observes the
388 current locale.
389
390 Here's a simple-minded example program that rewrites its command-line
391 parameters as integers correctly formatted in the current locale:
392
393         # See comments in previous example
394         require 5.004;
395         use POSIX qw(locale_h);
396
397         # Get some of locale's numeric formatting parameters
398         my ($thousands_sep, $grouping) =
399              @{localeconv()}{'thousands_sep', 'grouping'};
400
401         # Apply defaults if values are missing
402         $thousands_sep = ',' unless $thousands_sep;
403
404         # grouping and mon_grouping are packed lists
405         # of small integers (characters) telling the
406         # grouping (thousand_seps and mon_thousand_seps
407         # being the group dividers) of numbers and
408         # monetary quantities.  The integers' meanings:
409         # 255 means no more grouping, 0 means repeat
410         # the previous grouping, 1-254 means use that
411         # as the current grouping.  Grouping goes from
412         # right to left (low to high digits).  In the
413         # below we cheat slightly by never using anything
414         # else than the first grouping (whatever that is).
415         if ($grouping) {
416             @grouping = unpack("C*", $grouping);
417         } else {
418             @grouping = (3);
419         }
420
421         # Format command line params for current locale
422         for (@ARGV) {
423             $_ = int;    # Chop non-integer part
424             1 while
425             s/(\d)(\d{$grouping[0]}($|$thousands_sep))/$1$thousands_sep$2/;
426             print "$_";
427         }
428         print "\n";
429
430 =head1 LOCALE CATEGORIES
431
432 The following subsections describe basic locale categories.  Beyond these,
433 some combination categories allow manipulation of more than one
434 basic category at a time.  See L<"ENVIRONMENT"> for a discussion of these.
435
436 =head2 Category LC_COLLATE: Collation
437
438 In the scope of S<C<use locale>>, Perl looks to the C<LC_COLLATE>
439 environment variable to determine the application's notions on collation
440 (ordering) of characters.  For example, 'b' follows 'a' in Latin
441 alphabets, but where do 'E<aacute>' and 'E<aring>' belong?  And while
442 'color' follows 'chocolate' in English, what about in Spanish?
443
444 The following collations all make sense and you may meet any of them
445 if you "use locale".
446
447         A B C D E a b c d e
448         A a B b C c D d D e
449         a A b B c C d D e E
450         a b c d e A B C D E
451
452 Here is a code snippet to tell what alphanumeric
453 characters are in the current locale, in that locale's order:
454
455         use locale;
456         print +(sort grep /\w/, map { chr() } 0..255), "\n";
457
458 Compare this with the characters that you see and their order if you
459 state explicitly that the locale should be ignored:
460
461         no locale;
462         print +(sort grep /\w/, map { chr() } 0..255), "\n";
463
464 This machine-native collation (which is what you get unless S<C<use
465 locale>> has appeared earlier in the same block) must be used for
466 sorting raw binary data, whereas the locale-dependent collation of the
467 first example is useful for natural text.
468
469 As noted in L<USING LOCALES>, C<cmp> compares according to the current
470 collation locale when C<use locale> is in effect, but falls back to a
471 byte-by-byte comparison for strings that the locale says are equal. You
472 can use POSIX::strcoll() if you don't want this fall-back:
473
474         use POSIX qw(strcoll);
475         $equal_in_locale =
476             !strcoll("space and case ignored", "SpaceAndCaseIgnored");
477
478 $equal_in_locale will be true if the collation locale specifies a
479 dictionary-like ordering that ignores space characters completely and
480 which folds case.
481
482 If you have a single string that you want to check for "equality in
483 locale" against several others, you might think you could gain a little
484 efficiency by using POSIX::strxfrm() in conjunction with C<eq>:
485
486         use POSIX qw(strxfrm);
487         $xfrm_string = strxfrm("Mixed-case string");
488         print "locale collation ignores spaces\n"
489             if $xfrm_string eq strxfrm("Mixed-casestring");
490         print "locale collation ignores hyphens\n"
491             if $xfrm_string eq strxfrm("Mixedcase string");
492         print "locale collation ignores case\n"
493             if $xfrm_string eq strxfrm("mixed-case string");
494
495 strxfrm() takes a string and maps it into a transformed string for use
496 in byte-by-byte comparisons against other transformed strings during
497 collation.  "Under the hood", locale-affected Perl comparison operators
498 call strxfrm() for both operands, then do a byte-by-byte
499 comparison of the transformed strings.  By calling strxfrm() explicitly
500 and using a non locale-affected comparison, the example attempts to save
501 a couple of transformations.  But in fact, it doesn't save anything: Perl
502 magic (see L<perlguts/Magic Variables>) creates the transformed version of a
503 string the first time it's needed in a comparison, then keeps this version around
504 in case it's needed again.  An example rewritten the easy way with
505 C<cmp> runs just about as fast.  It also copes with null characters
506 embedded in strings; if you call strxfrm() directly, it treats the first
507 null it finds as a terminator.  don't expect the transformed strings
508 it produces to be portable across systems--or even from one revision
509 of your operating system to the next.  In short, don't call strxfrm()
510 directly: let Perl do it for you.
511
512 Note: C<use locale> isn't shown in some of these examples because it isn't
513 needed: strcoll() and strxfrm() exist only to generate locale-dependent
514 results, and so always obey the current C<LC_COLLATE> locale.
515
516 =head2 Category LC_CTYPE: Character Types
517
518 In the scope of S<C<use locale>>, Perl obeys the C<LC_CTYPE> locale
519 setting.  This controls the application's notion of which characters are
520 alphabetic.  This affects Perl's C<\w> regular expression metanotation,
521 which stands for alphanumeric characters--that is, alphabetic and
522 numeric characters.  (Consult L<perlre> for more information about
523 regular expressions.)  Thanks to C<LC_CTYPE>, depending on your locale
524 setting, characters like 'E<aelig>', 'E<eth>', 'E<szlig>', and
525 'E<oslash>' may be understood as C<\w> characters.
526
527 The C<LC_CTYPE> locale also provides the map used in transliterating
528 characters between lower and uppercase.  This affects the case-mapping
529 functions--lc(), lcfirst, uc(), and ucfirst(); case-mapping
530 interpolation with C<\l>, C<\L>, C<\u>, or C<\U> in double-quoted strings
531 and C<s///> substitutions; and case-independent regular expression
532 pattern matching using the C<i> modifier.
533
534 Finally, C<LC_CTYPE> affects the POSIX character-class test
535 functions--isalpha(), islower(), and so on.  For example, if you move
536 from the "C" locale to a 7-bit Scandinavian one, you may find--possibly
537 to your surprise--that "|" moves from the ispunct() class to isalpha().
538
539 B<Note:> A broken or malicious C<LC_CTYPE> locale definition may result
540 in clearly ineligible characters being considered to be alphanumeric by
541 your application.  For strict matching of (mundane) letters and
542 digits--for example, in command strings--locale-aware applications
543 should use C<\w> inside a C<no locale> block.  See L<"SECURITY">.
544
545 =head2 Category LC_NUMERIC: Numeric Formatting
546
547 In the scope of S<C<use locale>>, Perl obeys the C<LC_NUMERIC> locale
548 information, which controls an application's idea of how numbers should
549 be formatted for human readability by the printf(), sprintf(), and
550 write() functions.  String-to-numeric conversion by the POSIX::strtod()
551 function is also affected.  In most implementations the only effect is to
552 change the character used for the decimal point--perhaps from '.'  to ','.
553 These functions aren't aware of such niceties as thousands separation and
554 so on.  (See L<The localeconv function> if you care about these things.)
555
556 Output produced by print() is B<never> affected by the
557 current locale: it is independent of whether C<use locale> or C<no
558 locale> is in effect, and corresponds to what you'd get from printf()
559 in the "C" locale.  The same is true for Perl's internal conversions
560 between numeric and string formats:
561
562         use POSIX qw(strtod);
563         use locale;
564
565         $n = 5/2;   # Assign numeric 2.5 to $n
566
567         $a = " $n"; # Locale-independent conversion to string
568
569         print "half five is $n\n";       # Locale-independent output
570
571         printf "half five is %g\n", $n;  # Locale-dependent output
572
573         print "DECIMAL POINT IS COMMA\n"
574             if $n == (strtod("2,5"))[0]; # Locale-dependent conversion
575
576 =head2 Category LC_MONETARY: Formatting of monetary amounts
577
578 The C standard defines the C<LC_MONETARY> category, but no function
579 that is affected by its contents.  (Those with experience of standards
580 committees will recognize that the working group decided to punt on the
581 issue.)  Consequently, Perl takes no notice of it.  If you really want
582 to use C<LC_MONETARY>, you can query its contents--see L<The localeconv
583 function>--and use the information that it returns in your application's
584 own formatting of currency amounts.  However, you may well find that
585 the information, voluminous and complex though it may be, still does not
586 quite meet your requirements: currency formatting is a hard nut to crack.
587
588 =head2 LC_TIME
589
590 Output produced by POSIX::strftime(), which builds a formatted
591 human-readable date/time string, is affected by the current C<LC_TIME>
592 locale.  Thus, in a French locale, the output produced by the C<%B>
593 format element (full month name) for the first month of the year would
594 be "janvier".  Here's how to get a list of long month names in the
595 current locale:
596
597         use POSIX qw(strftime);
598         for (0..11) {
599             $long_month_name[$_] =
600                 strftime("%B", 0, 0, 0, 1, $_, 96);
601         }
602
603 Note: C<use locale> isn't needed in this example: as a function that
604 exists only to generate locale-dependent results, strftime() always
605 obeys the current C<LC_TIME> locale.
606
607 =head2 Other categories
608
609 The remaining locale category, C<LC_MESSAGES> (possibly supplemented
610 by others in particular implementations) is not currently used by
611 Perl--except possibly to affect the behavior of library functions
612 called by extensions outside the standard Perl distribution and by the
613 operating system and its utilities.  Note especially that the string
614 value of C<$!> and the error messages given by external utilities may
615 be changed by C<LC_MESSAGES>.  If you want to have portable error
616 codes, use C<%!>.  See L<Errno>.
617
618 =head1 SECURITY
619
620 Although the main discussion of Perl security issues can be found in
621 L<perlsec>, a discussion of Perl's locale handling would be incomplete
622 if it did not draw your attention to locale-dependent security issues.
623 Locales--particularly on systems that allow unprivileged users to
624 build their own locales--are untrustworthy.  A malicious (or just plain
625 broken) locale can make a locale-aware application give unexpected
626 results.  Here are a few possibilities:
627
628 =over 4
629
630 =item *
631
632 Regular expression checks for safe file names or mail addresses using
633 C<\w> may be spoofed by an C<LC_CTYPE> locale that claims that
634 characters such as "E<gt>" and "|" are alphanumeric.
635
636 =item *
637
638 String interpolation with case-mapping, as in, say, C<$dest =
639 "C:\U$name.$ext">, may produce dangerous results if a bogus LC_CTYPE
640 case-mapping table is in effect.
641
642 =item *
643
644 Some systems are broken in that they allow the "C" locale to be
645 overridden by users.  If the decimal point character in the
646 C<LC_NUMERIC> category of the "C" locale is surreptitiously changed
647 from a dot to a comma, C<sprintf("%g", 0.123456e3)> produces a
648 string result of "123,456".  Many people would interpret this as
649 one hundred and twenty-three thousand, four hundred and fifty-six.
650
651 =item *
652
653 A sneaky C<LC_COLLATE> locale could result in the names of students with
654 "D" grades appearing ahead of those with "A"s.
655
656 =item *
657
658 An application that takes the trouble to use information in
659 C<LC_MONETARY> may format debits as if they were credits and vice versa
660 if that locale has been subverted.  Or it might make payments in US
661 dollars instead of Hong Kong dollars.
662
663 =item *
664
665 The date and day names in dates formatted by strftime() could be
666 manipulated to advantage by a malicious user able to subvert the
667 C<LC_DATE> locale.  ("Look--it says I wasn't in the building on
668 Sunday.")
669
670 =back
671
672 Such dangers are not peculiar to the locale system: any aspect of an
673 application's environment which may be modified maliciously presents
674 similar challenges.  Similarly, they are not specific to Perl: any
675 programming language that allows you to write programs that take
676 account of their environment exposes you to these issues.
677
678 Perl cannot protect you from all possibilities shown in the
679 examples--there is no substitute for your own vigilance--but, when
680 C<use locale> is in effect, Perl uses the tainting mechanism (see
681 L<perlsec>) to mark string results that become locale-dependent, and
682 which may be untrustworthy in consequence.  Here is a summary of the
683 tainting behavior of operators and functions that may be affected by
684 the locale:
685
686 =over 4
687
688 =item B<Comparison operators> (C<lt>, C<le>, C<ge>, C<gt> and C<cmp>):
689
690 Scalar true/false (or less/equal/greater) result is never tainted.
691
692 =item B<Case-mapping interpolation> (with C<\l>, C<\L>, C<\u> or C<\U>)
693
694 Result string containing interpolated material is tainted if
695 C<use locale> is in effect.
696
697 =item B<Matching operator> (C<m//>):
698
699 Scalar true/false result never tainted.
700
701 Subpatterns, either delivered as a list-context result or as $1 etc.
702 are tainted if C<use locale> is in effect, and the subpattern regular
703 expression contains C<\w> (to match an alphanumeric character), C<\W>
704 (non-alphanumeric character), C<\s> (white-space character), or C<\S>
705 (non white-space character).  The matched-pattern variable, $&, $`
706 (pre-match), $' (post-match), and $+ (last match) are also tainted if
707 C<use locale> is in effect and the regular expression contains C<\w>,
708 C<\W>, C<\s>, or C<\S>.
709
710 =item B<Substitution operator> (C<s///>):
711
712 Has the same behavior as the match operator.  Also, the left
713 operand of C<=~> becomes tainted when C<use locale> in effect
714 if modified as a result of a substitution based on a regular
715 expression match involving C<\w>, C<\W>, C<\s>, or C<\S>; or of
716 case-mapping with C<\l>, C<\L>,C<\u> or C<\U>.
717
718 =item B<Output formatting functions> (printf() and write()):
719
720 Success/failure result is never tainted.
721
722 =item B<Case-mapping functions> (lc(), lcfirst(), uc(), ucfirst()):
723
724 Results are tainted if C<use locale> is in effect.
725
726 =item B<POSIX locale-dependent functions> (localeconv(), strcoll(),
727 strftime(), strxfrm()):
728
729 Results are never tainted.
730
731 =item B<POSIX character class tests> (isalnum(), isalpha(), isdigit(),
732 isgraph(), islower(), isprint(), ispunct(), isspace(), isupper(),
733 isxdigit()):
734
735 True/false results are never tainted.
736
737 =back
738
739 Three examples illustrate locale-dependent tainting.
740 The first program, which ignores its locale, won't run: a value taken
741 directly from the command line may not be used to name an output file
742 when taint checks are enabled.
743
744         #/usr/local/bin/perl -T
745         # Run with taint checking
746
747         # Command line sanity check omitted...
748         $tainted_output_file = shift;
749
750         open(F, ">$tainted_output_file")
751             or warn "Open of $untainted_output_file failed: $!\n";
752
753 The program can be made to run by "laundering" the tainted value through
754 a regular expression: the second example--which still ignores locale
755 information--runs, creating the file named on its command line
756 if it can.
757
758         #/usr/local/bin/perl -T
759
760         $tainted_output_file = shift;
761         $tainted_output_file =~ m%[\w/]+%;
762         $untainted_output_file = $&;
763
764         open(F, ">$untainted_output_file")
765             or warn "Open of $untainted_output_file failed: $!\n";
766
767 Compare this with a similar but locale-aware program:
768
769         #/usr/local/bin/perl -T
770
771         $tainted_output_file = shift;
772         use locale;
773         $tainted_output_file =~ m%[\w/]+%;
774         $localized_output_file = $&;
775
776         open(F, ">$localized_output_file")
777             or warn "Open of $localized_output_file failed: $!\n";
778
779 This third program fails to run because $& is tainted: it is the result
780 of a match involving C<\w> while C<use locale> is in effect.
781
782 =head1 ENVIRONMENT
783
784 =over 12
785
786 =item PERL_BADLANG
787
788 A string that can suppress Perl's warning about failed locale settings
789 at startup.  Failure can occur if the locale support in the operating
790 system is lacking (broken) in some way--or if you mistyped the name of
791 a locale when you set up your environment.  If this environment
792 variable is absent, or has a value that does not evaluate to integer
793 zero--that is, "0" or ""-- Perl will complain about locale setting
794 failures.
795
796 B<NOTE>: PERL_BADLANG only gives you a way to hide the warning message.
797 The message tells about some problem in your system's locale support,
798 and you should investigate what the problem is.
799
800 =back
801
802 The following environment variables are not specific to Perl: They are
803 part of the standardized (ISO C, XPG4, POSIX 1.c) setlocale() method
804 for controlling an application's opinion on data.
805
806 =over 12
807
808 =item LC_ALL
809
810 C<LC_ALL> is the "override-all" locale environment variable. If
811 set, it overrides all the rest of the locale environment variables.
812
813 =item LANGUAGE
814
815 B<NOTE>: C<LANGUAGE> is a GNU extension, it affects you only if you
816 are using the GNU libc.  This is the case if you are using e.g. Linux.
817 If you are using "commercial" UNIXes you are most probably I<not>
818 using GNU libc and you can ignore C<LANGUAGE>.
819
820 However, in the case you are using C<LANGUAGE>: it affects the
821 language of informational, warning, and error messages output by
822 commands (in other words, it's like C<LC_MESSAGES>) but it has higher
823 priority than L<LC_ALL>.  Moreover, it's not a single value but
824 instead a "path" (":"-separated list) of I<languages> (not locales).
825 See the GNU C<gettext> library documentation for more information.
826
827 =item LC_CTYPE
828
829 In the absence of C<LC_ALL>, C<LC_CTYPE> chooses the character type
830 locale.  In the absence of both C<LC_ALL> and C<LC_CTYPE>, C<LANG>
831 chooses the character type locale.
832
833 =item LC_COLLATE
834
835 In the absence of C<LC_ALL>, C<LC_COLLATE> chooses the collation
836 (sorting) locale.  In the absence of both C<LC_ALL> and C<LC_COLLATE>,
837 C<LANG> chooses the collation locale.
838
839 =item LC_MONETARY
840
841 In the absence of C<LC_ALL>, C<LC_MONETARY> chooses the monetary
842 formatting locale.  In the absence of both C<LC_ALL> and C<LC_MONETARY>,
843 C<LANG> chooses the monetary formatting locale.
844
845 =item LC_NUMERIC
846
847 In the absence of C<LC_ALL>, C<LC_NUMERIC> chooses the numeric format
848 locale.  In the absence of both C<LC_ALL> and C<LC_NUMERIC>, C<LANG>
849 chooses the numeric format.
850
851 =item LC_TIME
852
853 In the absence of C<LC_ALL>, C<LC_TIME> chooses the date and time
854 formatting locale.  In the absence of both C<LC_ALL> and C<LC_TIME>,
855 C<LANG> chooses the date and time formatting locale.
856
857 =item LANG
858
859 C<LANG> is the "catch-all" locale environment variable. If it is set, it
860 is used as the last resort after the overall C<LC_ALL> and the
861 category-specific C<LC_...>.
862
863 =back
864
865 =head1 NOTES
866
867 =head2 Backward compatibility
868
869 Versions of Perl prior to 5.004 B<mostly> ignored locale information,
870 generally behaving as if something similar to the C<"C"> locale were
871 always in force, even if the program environment suggested otherwise
872 (see L<The setlocale function>).  By default, Perl still behaves this
873 way for backward compatibility.  If you want a Perl application to pay
874 attention to locale information, you B<must> use the S<C<use locale>>
875 pragma (see L<The use locale pragma>) to instruct it to do so.
876
877 Versions of Perl from 5.002 to 5.003 did use the C<LC_CTYPE>
878 information if available; that is, C<\w> did understand what
879 were the letters according to the locale environment variables.
880 The problem was that the user had no control over the feature:
881 if the C library supported locales, Perl used them.
882
883 =head2 I18N:Collate obsolete
884
885 In versions of Perl prior to 5.004, per-locale collation was possible
886 using the C<I18N::Collate> library module.  This module is now mildly
887 obsolete and should be avoided in new applications.  The C<LC_COLLATE>
888 functionality is now integrated into the Perl core language: One can
889 use locale-specific scalar data completely normally with C<use locale>,
890 so there is no longer any need to juggle with the scalar references of
891 C<I18N::Collate>.
892
893 =head2 Sort speed and memory use impacts
894
895 Comparing and sorting by locale is usually slower than the default
896 sorting; slow-downs of two to four times have been observed.  It will
897 also consume more memory: once a Perl scalar variable has participated
898 in any string comparison or sorting operation obeying the locale
899 collation rules, it will take 3-15 times more memory than before.  (The
900 exact multiplier depends on the string's contents, the operating system
901 and the locale.) These downsides are dictated more by the operating
902 system's implementation of the locale system than by Perl.
903
904 =head2 write() and LC_NUMERIC
905
906 Formats are the only part of Perl that unconditionally use information
907 from a program's locale; if a program's environment specifies an
908 LC_NUMERIC locale, it is always used to specify the decimal point
909 character in formatted output.  Formatted output cannot be controlled by
910 C<use locale> because the pragma is tied to the block structure of the
911 program, and, for historical reasons, formats exist outside that block
912 structure.
913
914 =head2 Freely available locale definitions
915
916 There is a large collection of locale definitions at
917 C<ftp://dkuug.dk/i18n/WG15-collection>.  You should be aware that it is
918 unsupported, and is not claimed to be fit for any purpose.  If your
919 system allows installation of arbitrary locales, you may find the
920 definitions useful as they are, or as a basis for the development of
921 your own locales.
922
923 =head2 I18n and l10n
924
925 "Internationalization" is often abbreviated as B<i18n> because its first
926 and last letters are separated by eighteen others.  (You may guess why
927 the internalin ... internaliti ... i18n tends to get abbreviated.)  In
928 the same way, "localization" is often abbreviated to B<l10n>.
929
930 =head2 An imperfect standard
931
932 Internationalization, as defined in the C and POSIX standards, can be
933 criticized as incomplete, ungainly, and having too large a granularity.
934 (Locales apply to a whole process, when it would arguably be more useful
935 to have them apply to a single thread, window group, or whatever.)  They
936 also have a tendency, like standards groups, to divide the world into
937 nations, when we all know that the world can equally well be divided
938 into bankers, bikers, gamers, and so on.  But, for now, it's the only
939 standard we've got.  This may be construed as a bug.
940
941 =head1 BUGS
942
943 =head2 Broken systems
944
945 In certain systems, the operating system's locale support
946 is broken and cannot be fixed or used by Perl.  Such deficiencies can
947 and will result in mysterious hangs and/or Perl core dumps when the
948 C<use locale> is in effect.  When confronted with such a system,
949 please report in excruciating detail to <F<perlbug@perl.com>>, and
950 complain to your vendor: bug fixes may exist for these problems
951 in your operating system.  Sometimes such bug fixes are called an
952 operating system upgrade.
953
954 =head1 SEE ALSO
955
956 L<POSIX (3)/isalnum>
957
958 L<POSIX (3)/isalpha>
959
960 L<POSIX (3)/isdigit>
961
962 L<POSIX (3)/isgraph>
963
964 L<POSIX (3)/islower>
965
966 L<POSIX (3)/isprint>,
967
968 L<POSIX (3)/ispunct>
969
970 L<POSIX (3)/isspace>
971
972 L<POSIX (3)/isupper>,
973
974 L<POSIX (3)/isxdigit>
975
976 L<POSIX (3)/localeconv>
977
978 L<POSIX (3)/setlocale>,
979
980 L<POSIX (3)/strcoll>
981
982 L<POSIX (3)/strftime>
983
984 L<POSIX (3)/strtod>,
985
986 L<POSIX (3)/strxfrm>
987
988 =head1 HISTORY
989
990 Jarkko Hietaniemi's original F<perli18n.pod> heavily hacked by Dominic
991 Dunlop, assisted by the perl5-porters.  Prose worked over a bit by
992 Tom Christiansen.
993
994 Last update: Thu Jun 11 08:44:13 MDT 1998