This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
0ff277083998fef30feb7b0ed96ffedee82981ae
[perl5.git] / lib / perl5db.pl
1
2 =head1 NAME
3
4 perl5db.pl - the perl debugger
5
6 =head1 SYNOPSIS
7
8     perl -d  your_Perl_script
9
10 =head1 DESCRIPTION
11
12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
13 you invoke a script with C<perl -d>. This documentation tries to outline the
14 structure and services provided by C<perl5db.pl>, and to describe how you
15 can use them.
16
17 =head1 GENERAL NOTES
18
19 The debugger can look pretty forbidding to many Perl programmers. There are
20 a number of reasons for this, many stemming out of the debugger's history.
21
22 When the debugger was first written, Perl didn't have a lot of its nicer
23 features - no references, no lexical variables, no closures, no object-oriented
24 programming. So a lot of the things one would normally have done using such
25 features was done using global variables, globs and the C<local()> operator
26 in creative ways.
27
28 Some of these have survived into the current debugger; a few of the more
29 interesting and still-useful idioms are noted in this section, along with notes
30 on the comments themselves.
31
32 =head2 Why not use more lexicals?
33
34 Experienced Perl programmers will note that the debugger code tends to use
35 mostly package globals rather than lexically-scoped variables. This is done
36 to allow a significant amount of control of the debugger from outside the
37 debugger itself.
38
39 Unfortunately, though the variables are accessible, they're not well
40 documented, so it's generally been a decision that hasn't made a lot of
41 difference to most users. Where appropriate, comments have been added to
42 make variables more accessible and usable, with the understanding that these
43 I<are> debugger internals, and are therefore subject to change. Future
44 development should probably attempt to replace the globals with a well-defined
45 API, but for now, the variables are what we've got.
46
47 =head2 Automated variable stacking via C<local()>
48
49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
50 temporary copy of a variable in the current scope. When the scope ends, the
51 old copy is restored. This is often used in the debugger to handle the
52 automatic stacking of variables during recursive calls:
53
54      sub foo {
55         local $some_global++;
56
57         # Do some stuff, then ...
58         return;
59      }
60
61 What happens is that on entry to the subroutine, C<$some_global> is localized,
62 then altered. When the subroutine returns, Perl automatically undoes the
63 localization, restoring the previous value. Voila, automatic stack management.
64
65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
66 which lets the debugger get control inside of C<eval>'ed code. The debugger
67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
71
72 In any case, watch for this pattern. It occurs fairly often.
73
74 =head2 The C<^> trick
75
76 This is used to cleverly reverse the sense of a logical test depending on
77 the value of an auxiliary variable. For instance, the debugger's C<S>
78 (search for subroutines by pattern) allows you to negate the pattern
79 like this:
80
81    # Find all non-'foo' subs:
82    S !/foo/
83
84 Boolean algebra states that the truth table for XOR looks like this:
85
86 =over 4
87
88 =item * 0 ^ 0 = 0
89
90 (! not present and no match) --> false, don't print
91
92 =item * 0 ^ 1 = 1
93
94 (! not present and matches) --> true, print
95
96 =item * 1 ^ 0 = 1
97
98 (! present and no match) --> true, print
99
100 =item * 1 ^ 1 = 0
101
102 (! present and matches) --> false, don't print
103
104 =back
105
106 As you can see, the first pair applies when C<!> isn't supplied, and
107 the second pair applies when it is. The XOR simply allows us to
108 compact a more complicated if-then-elseif-else into a more elegant
109 (but perhaps overly clever) single test. After all, it needed this
110 explanation...
111
112 =head2 FLAGS, FLAGS, FLAGS
113
114 There is a certain C programming legacy in the debugger. Some variables,
115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
117 of state to be stored independently in a single scalar.
118
119 A test like
120
121     if ($scalar & 4) ...
122
123 is checking to see if the appropriate bit is on. Since each bit can be
124 "addressed" independently in this way, C<$scalar> is acting sort of like
125 an array of bits. Obviously, since the contents of C<$scalar> are just a
126 bit-pattern, we can save and restore it easily (it will just look like
127 a number).
128
129 The problem, is of course, that this tends to leave magic numbers scattered
130 all over your program whenever a bit is set, cleared, or checked. So why do
131 it?
132
133 =over 4
134
135 =item *
136
137 First, doing an arithmetical or bitwise operation on a scalar is
138 just about the fastest thing you can do in Perl: C<use constant> actually
139 creates a subroutine call, and array and hash lookups are much slower. Is
140 this over-optimization at the expense of readability? Possibly, but the
141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
142 probably have to benchmark alternate implementations and see which is the
143 best balance of readability and speed, and then document how it actually
144 works.
145
146 =item *
147
148 Second, it's very easy to serialize a scalar number. This is done in
149 the restart code; the debugger state variables are saved in C<%ENV> and then
150 restored when the debugger is restarted. Having them be just numbers makes
151 this trivial.
152
153 =item *
154
155 Third, some of these variables are being shared with the Perl core
156 smack in the middle of the interpreter's execution loop. It's much faster for
157 a C program (like the interpreter) to check a bit in a scalar than to access
158 several different variables (or a Perl array).
159
160 =back
161
162 =head2 What are those C<XXX> comments for?
163
164 Any comment containing C<XXX> means that the comment is either somewhat
165 speculative - it's not exactly clear what a given variable or chunk of
166 code is doing, or that it is incomplete - the basics may be clear, but the
167 subtleties are not completely documented.
168
169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
170
171 =head1 DATA STRUCTURES MAINTAINED BY CORE
172
173 There are a number of special data structures provided to the debugger by
174 the Perl interpreter.
175
176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
177 via glob assignment) contains the text from C<$filename>, with each
178 element corresponding to a single line of C<$filename>. Additionally,
179 breakable lines will be dualvars with the numeric component being the
180 memory address of a COP node. Non-breakable lines are dualvar to 0.
181
182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
183 assignment) contains breakpoints and actions.  The keys are line numbers;
184 you can set individual values, but not the whole hash. The Perl interpreter
185 uses this hash to determine where breakpoints have been set. Any true value is
186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
188
189 The scalar C<${"_<$filename"}> simply contains the string C<<< _<$filename> >>>.
190 This is also the case for evaluated strings that contain subroutines, or
191 which are currently being executed.  The $filename for C<eval>ed strings looks
192 like C<(eval 34).
193
194 =head1 DEBUGGER STARTUP
195
196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
198 of options. In addition, this file may define a subroutine C<&afterinit>
199 that will be executed (in the debugger's context) after the debugger has
200 initialized itself.
201
202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
203 contents as the argument of a C<o> command in the debugger.
204
205 =head2 STARTUP-ONLY OPTIONS
206
207 The following options can only be specified at startup.
208 To set them in your rcfile, add a call to
209 C<&parse_options("optionName=new_value")>.
210
211 =over 4
212
213 =item * TTY
214
215 the TTY to use for debugging i/o.
216
217 =item * noTTY
218
219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
221 Term::Rendezvous.  Current variant is to have the name of TTY in this
222 file.
223
224 =item * ReadLine
225
226 if false, a dummy ReadLine is used, so you can debug
227 ReadLine applications.
228
229 =item * NonStop
230
231 if true, no i/o is performed until interrupt.
232
233 =item * LineInfo
234
235 file or pipe to print line number info to.  If it is a
236 pipe, a short "emacs like" message is used.
237
238 =item * RemotePort
239
240 host:port to connect to on remote host for remote debugging.
241
242 =item * HistFile
243
244 file to store session history to. There is no default and so no
245 history file is written unless this variable is explicitly set.
246
247 =item * HistSize
248
249 number of commands to store to the file specified in C<HistFile>.
250 Default is 100.
251
252 =back
253
254 =head3 SAMPLE RCFILE
255
256  &parse_options("NonStop=1 LineInfo=db.out");
257   sub afterinit { $trace = 1; }
258
259 The script will run without human intervention, putting trace
260 information into C<db.out>.  (If you interrupt it, you had better
261 reset C<LineInfo> to something I<interactive>!)
262
263 =head1 INTERNALS DESCRIPTION
264
265 =head2 DEBUGGER INTERFACE VARIABLES
266
267 Perl supplies the values for C<%sub>.  It effectively inserts
268 a C<&DB::DB();> in front of each place that can have a
269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
271 {require 'perl5db.pl'}> before the first line.
272
273 After each C<require>d file is compiled, but before it is executed, a
274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
275 is the expanded name of the C<require>d file (as found via C<%INC>).
276
277 =head3 IMPORTANT INTERNAL VARIABLES
278
279 =head4 C<$CreateTTY>
280
281 Used to control when the debugger will attempt to acquire another TTY to be
282 used for input.
283
284 =over
285
286 =item * 1 -  on C<fork()>
287
288 =item * 2 - debugger is started inside debugger
289
290 =item * 4 -  on startup
291
292 =back
293
294 =head4 C<$doret>
295
296 The value -2 indicates that no return value should be printed.
297 Any other positive value causes C<DB::sub> to print return values.
298
299 =head4 C<$evalarg>
300
301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
302 contents of C<@_> when C<DB::eval> is called.
303
304 =head4 C<$frame>
305
306 Determines what messages (if any) will get printed when a subroutine (or eval)
307 is entered or exited.
308
309 =over 4
310
311 =item * 0 -  No enter/exit messages
312
313 =item * 1 - Print I<entering> messages on subroutine entry
314
315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
316
317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
318
319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
320
321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
322
323 =back
324
325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
326 The debugger internally juggles the value of C<$frame> during execution to
327 protect external modules that the debugger uses from getting traced.
328
329 =head4 C<$level>
330
331 Tracks current debugger nesting level. Used to figure out how many
332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
333 outputs a prompt. Also used to help determine if the program has finished
334 during command parsing.
335
336 =head4 C<$onetimeDump>
337
338 Controls what (if anything) C<DB::eval()> will print after evaluating an
339 expression.
340
341 =over 4
342
343 =item * C<undef> - don't print anything
344
345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
346
347 =item * C<methods> - print the methods callable on the first item returned
348
349 =back
350
351 =head4 C<$onetimeDumpDepth>
352
353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
354 dumping a structure. Numeric. If C<undef>, print all levels.
355
356 =head4 C<$signal>
357
358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
359 which is called before every statement, checks this and puts the user into
360 command mode if it finds C<$signal> set to a true value.
361
362 =head4 C<$single>
363
364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
365 each subroutine; popped again at the end of each subroutine.
366
367 =over 4
368
369 =item * 0 - run continuously.
370
371 =item * 1 - single-step, go into subs. The C<s> command.
372
373 =item * 2 - single-step, don't go into subs. The C<n> command.
374
375 =item * 4 - print current sub depth (turned on to force this when C<too much
376 recursion> occurs.
377
378 =back
379
380 =head4 C<$trace>
381
382 Controls the output of trace information.
383
384 =over 4
385
386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
387
388 =item * 2 - watch expressions are active
389
390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
391
392 =back
393
394 =head4 C<$slave_editor>
395
396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
397
398 =head4 C<@cmdfhs>
399
400 Stack of filehandles that C<DB::readline()> will read commands from.
401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
402
403 =head4 C<@dbline>
404
405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
406 supplied by the Perl interpreter to the debugger. Contains the source.
407
408 =head4 C<@old_watch>
409
410 Previous values of watch expressions. First set when the expression is
411 entered; reset whenever the watch expression changes.
412
413 =head4 C<@saved>
414
415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
416 so that the debugger can substitute safe values while it's running, and
417 restore them when it returns control.
418
419 =head4 C<@stack>
420
421 Saves the current value of C<$single> on entry to a subroutine.
422 Manipulated by the C<c> command to turn off tracing in all subs above the
423 current one.
424
425 =head4 C<@to_watch>
426
427 The 'watch' expressions: to be evaluated before each line is executed.
428
429 =head4 C<@typeahead>
430
431 The typeahead buffer, used by C<DB::readline>.
432
433 =head4 C<%alias>
434
435 Command aliases. Stored as character strings to be substituted for a command
436 entered.
437
438 =head4 C<%break_on_load>
439
440 Keys are file names, values are 1 (break when this file is loaded) or undef
441 (don't break when it is loaded).
442
443 =head4 C<%dbline>
444
445 Keys are line numbers, values are C<condition\0action>. If used in numeric
446 context, values are 0 if not breakable, 1 if breakable, no matter what is
447 in the actual hash entry.
448
449 =head4 C<%had_breakpoints>
450
451 Keys are file names; values are bitfields:
452
453 =over 4
454
455 =item * 1 - file has a breakpoint in it.
456
457 =item * 2 - file has an action in it.
458
459 =back
460
461 A zero or undefined value means this file has neither.
462
463 =head4 C<%option>
464
465 Stores the debugger options. These are character string values.
466
467 =head4 C<%postponed>
468
469 Saves breakpoints for code that hasn't been compiled yet.
470 Keys are subroutine names, values are:
471
472 =over 4
473
474 =item * C<compile> - break when this sub is compiled
475
476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
477
478 =back
479
480 =head4 C<%postponed_file>
481
482 This hash keeps track of breakpoints that need to be set for files that have
483 not yet been compiled. Keys are filenames; values are references to hashes.
484 Each of these hashes is keyed by line number, and its values are breakpoint
485 definitions (C<condition\0action>).
486
487 =head1 DEBUGGER INITIALIZATION
488
489 The debugger's initialization actually jumps all over the place inside this
490 package. This is because there are several BEGIN blocks (which of course
491 execute immediately) spread through the code. Why is that?
492
493 The debugger needs to be able to change some things and set some things up
494 before the debugger code is compiled; most notably, the C<$deep> variable that
495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
496 debugger has to turn off warnings while the debugger code is compiled, but then
497 restore them to their original setting before the program being debugged begins
498 executing.
499
500 The first C<BEGIN> block simply turns off warnings by saving the current
501 setting of C<$^W> and then setting it to zero. The second one initializes
502 the debugger variables that are needed before the debugger begins executing.
503 The third one puts C<$^X> back to its former value.
504
505 We'll detail the second C<BEGIN> block later; just remember that if you need
506 to initialize something before the debugger starts really executing, that's
507 where it has to go.
508
509 =cut
510
511 package DB;
512
513 use strict;
514
515 BEGIN {eval 'use IO::Handle'};  # Needed for flush only? breaks under miniperl
516
517 BEGIN {
518     require feature;
519     $^V =~ /^v(\d+\.\d+)/;
520     feature->import(":$1");
521 }
522
523 # Debugger for Perl 5.00x; perl5db.pl patch level:
524 use vars qw($VERSION $header);
525
526 $VERSION = '1.39_04';
527
528 $header = "perl5db.pl version $VERSION";
529
530 =head1 DEBUGGER ROUTINES
531
532 =head2 C<DB::eval()>
533
534 This function replaces straight C<eval()> inside the debugger; it simplifies
535 the process of evaluating code in the user's context.
536
537 The code to be evaluated is passed via the package global variable
538 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
539
540 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
541 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
542 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
543 user's current package, grabbed when C<DB::DB> got control.  This causes the
544 proper context to be used when the eval is actually done.  Afterward, we
545 restore C<$trace>, C<$single>, and C<$^D>.
546
547 Next we need to handle C<$@> without getting confused. We save C<$@> in a
548 local lexical, localize C<$saved[0]> (which is where C<save()> will put
549 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
550 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
551 considered sane by the debugger. If there was an C<eval()> error, we print
552 it on the debugger's output. If C<$onetimedump> is defined, we call
553 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
554 'methods'. Setting it to something else causes the debugger to do the eval
555 but not print the result - handy if you want to do something else with it
556 (the "watch expressions" code does this to get the value of the watch
557 expression but not show it unless it matters).
558
559 In any case, we then return the list of output from C<eval> to the caller,
560 and unwinding restores the former version of C<$@> in C<@saved> as well
561 (the localization of C<$saved[0]> goes away at the end of this scope).
562
563 =head3 Parameters and variables influencing execution of DB::eval()
564
565 C<DB::eval> isn't parameterized in the standard way; this is to keep the
566 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
567 The variables listed below influence C<DB::eval()>'s execution directly.
568
569 =over 4
570
571 =item C<$evalarg> - the thing to actually be eval'ed
572
573 =item C<$trace> - Current state of execution tracing
574
575 =item C<$single> - Current state of single-stepping
576
577 =item C<$onetimeDump> - what is to be displayed after the evaluation
578
579 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
580
581 =back
582
583 The following variables are altered by C<DB::eval()> during its execution. They
584 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
585
586 =over 4
587
588 =item C<@res> - used to capture output from actual C<eval>.
589
590 =item C<$otrace> - saved value of C<$trace>.
591
592 =item C<$osingle> - saved value of C<$single>.
593
594 =item C<$od> - saved value of C<$^D>.
595
596 =item C<$saved[0]> - saved value of C<$@>.
597
598 =item $\ - for output of C<$@> if there is an evaluation error.
599
600 =back
601
602 =head3 The problem of lexicals
603
604 The context of C<DB::eval()> presents us with some problems. Obviously,
605 we want to be 'sandboxed' away from the debugger's internals when we do
606 the eval, but we need some way to control how punctuation variables and
607 debugger globals are used.
608
609 We can't use local, because the code inside C<DB::eval> can see localized
610 variables; and we can't use C<my> either for the same reason. The code
611 in this routine compromises and uses C<my>.
612
613 After this routine is over, we don't have user code executing in the debugger's
614 context, so we can use C<my> freely.
615
616 =cut
617
618 ############################################## Begin lexical danger zone
619
620 # 'my' variables used here could leak into (that is, be visible in)
621 # the context that the code being evaluated is executing in. This means that
622 # the code could modify the debugger's variables.
623 #
624 # Fiddling with the debugger's context could be Bad. We insulate things as
625 # much as we can.
626
627 use vars qw(
628     @args
629     %break_on_load
630     @cmdfhs
631     $CommandSet
632     $CreateTTY
633     $DBGR
634     @dbline
635     $dbline
636     %dbline
637     $dieLevel
638     $evalarg
639     $filename
640     $frame
641     $hist
642     $histfile
643     $histsize
644     $ImmediateStop
645     $IN
646     $inhibit_exit
647     @ini_INC
648     $ini_warn
649     $line
650     $maxtrace
651     $od
652     $onetimeDump
653     $onetimedumpDepth
654     %option
655     @options
656     $osingle
657     $otrace
658     $OUT
659     $packname
660     $pager
661     $post
662     %postponed
663     $prc
664     $pre
665     $pretype
666     $psh
667     @RememberOnROptions
668     $remoteport
669     @res
670     $rl
671     @saved
672     $signal
673     $signalLevel
674     $single
675     $start
676     $sub
677     %sub
678     $subname
679     $term
680     $trace
681     $usercontext
682     $warnLevel
683     $window
684 );
685
686 # Used to save @ARGV and extract any debugger-related flags.
687 use vars qw(@ARGS);
688
689 # Used to prevent multiple entries to diesignal()
690 # (if for instance diesignal() itself dies)
691 use vars qw($panic);
692
693 # Used to prevent the debugger from running nonstop
694 # after a restart
695 use vars qw($second_time);
696
697 sub _calc_usercontext {
698     my ($package) = @_;
699
700     # Cancel strict completely for the evaluated code, so the code
701     # the user evaluates won't be affected by it. (Shlomi Fish)
702     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @saved;'
703     . "package $package;";    # this won't let them modify, alas
704 }
705
706 sub eval {
707
708     # 'my' would make it visible from user code
709     #    but so does local! --tchrist
710     # Remember: this localizes @DB::res, not @main::res.
711     local @res;
712     {
713
714         # Try to keep the user code from messing  with us. Save these so that
715         # even if the eval'ed code changes them, we can put them back again.
716         # Needed because the user could refer directly to the debugger's
717         # package globals (and any 'my' variables in this containing scope)
718         # inside the eval(), and we want to try to stay safe.
719         local $otrace  = $trace;
720         local $osingle = $single;
721         local $od      = $^D;
722
723         # Untaint the incoming eval() argument.
724         { ($evalarg) = $evalarg =~ /(.*)/s; }
725
726         # $usercontext built in DB::DB near the comment
727         # "set up the context for DB::eval ..."
728         # Evaluate and save any results.
729         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
730
731         # Restore those old values.
732         $trace  = $otrace;
733         $single = $osingle;
734         $^D     = $od;
735     }
736
737     # Save the current value of $@, and preserve it in the debugger's copy
738     # of the saved precious globals.
739     my $at = $@;
740
741     # Since we're only saving $@, we only have to localize the array element
742     # that it will be stored in.
743     local $saved[0];    # Preserve the old value of $@
744     eval { &DB::save };
745
746     # Now see whether we need to report an error back to the user.
747     if ($at) {
748         local $\ = '';
749         print $OUT $at;
750     }
751
752     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
753     # are package globals.
754     elsif ($onetimeDump) {
755         if ( $onetimeDump eq 'dump' ) {
756             local $option{dumpDepth} = $onetimedumpDepth
757               if defined $onetimedumpDepth;
758             dumpit( $OUT, \@res );
759         }
760         elsif ( $onetimeDump eq 'methods' ) {
761             methods( $res[0] );
762         }
763     } ## end elsif ($onetimeDump)
764     @res;
765 } ## end sub eval
766
767 ############################################## End lexical danger zone
768
769 # After this point it is safe to introduce lexicals.
770 # The code being debugged will be executing in its own context, and
771 # can't see the inside of the debugger.
772 #
773 # However, one should not overdo it: leave as much control from outside as
774 # possible. If you make something a lexical, it's not going to be addressable
775 # from outside the debugger even if you know its name.
776
777 # This file is automatically included if you do perl -d.
778 # It's probably not useful to include this yourself.
779 #
780 # Before venturing further into these twisty passages, it is
781 # wise to read the perldebguts man page or risk the ire of dragons.
782 #
783 # (It should be noted that perldebguts will tell you a lot about
784 # the underlying mechanics of how the debugger interfaces into the
785 # Perl interpreter, but not a lot about the debugger itself. The new
786 # comments in this code try to address this problem.)
787
788 # Note that no subroutine call is possible until &DB::sub is defined
789 # (for subroutines defined outside of the package DB). In fact the same is
790 # true if $deep is not defined.
791
792 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
793
794 # modified Perl debugger, to be run from Emacs in perldb-mode
795 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
796 # Johan Vromans -- upgrade to 4.0 pl 10
797 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
798 ########################################################################
799
800 =head1 DEBUGGER INITIALIZATION
801
802 The debugger starts up in phases.
803
804 =head2 BASIC SETUP
805
806 First, it initializes the environment it wants to run in: turning off
807 warnings during its own compilation, defining variables which it will need
808 to avoid warnings later, setting itself up to not exit when the program
809 terminates, and defaulting to printing return values for the C<r> command.
810
811 =cut
812
813 # Needed for the statement after exec():
814 #
815 # This BEGIN block is simply used to switch off warnings during debugger
816 # compilation. Probably it would be better practice to fix the warnings,
817 # but this is how it's done at the moment.
818
819 BEGIN {
820     $ini_warn = $^W;
821     $^W       = 0;
822 }    # Switch compilation warnings off until another BEGIN.
823
824 local ($^W) = 0;    # Switch run-time warnings off during init.
825
826 =head2 THREADS SUPPORT
827
828 If we are running under a threaded Perl, we require threads and threads::shared
829 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
830 threaded debugger control.  C<-dt> can also be used to set this.
831
832 Each new thread will be announced and the debugger prompt will always inform
833 you of each new thread created.  It will also indicate the thread id in which
834 we are currently running within the prompt like this:
835
836         [tid] DB<$i>
837
838 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
839 command prompt.  The prompt will show: C<[0]> when running under threads, but
840 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
841
842 While running under threads, when you set or delete a breakpoint (etc.), this
843 will apply to all threads, not just the currently running one.  When you are
844 in a currently executing thread, you will stay there until it completes.  With
845 the current implementation it is not currently possible to hop from one thread
846 to another.
847
848 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
849
850 Note that threading support was built into the debugger as of Perl version
851 C<5.8.6> and debugger version C<1.2.8>.
852
853 =cut
854
855 BEGIN {
856   # ensure we can share our non-threaded variables or no-op
857   if ($ENV{PERL5DB_THREADED}) {
858         require threads;
859         require threads::shared;
860         import threads::shared qw(share);
861         $DBGR;
862         share(\$DBGR);
863         lock($DBGR);
864         print "Threads support enabled\n";
865   } else {
866         *lock  = sub(*) {};
867         *share = sub(*) {};
868   }
869 }
870
871 # These variables control the execution of 'dumpvar.pl'.
872 {
873     package dumpvar;
874     use vars qw(
875     $hashDepth
876     $arrayDepth
877     $dumpDBFiles
878     $dumpPackages
879     $quoteHighBit
880     $printUndef
881     $globPrint
882     $usageOnly
883     );
884 }
885
886 # used to control die() reporting in diesignal()
887 {
888     package Carp;
889     use vars qw($CarpLevel);
890 }
891
892 # without threads, $filename is not defined until DB::DB is called
893 foreach my $k (keys (%INC)) {
894         share(\$main::{'_<'.$filename}) if defined $filename;
895 };
896
897 # Command-line + PERLLIB:
898 # Save the contents of @INC before they are modified elsewhere.
899 @ini_INC = @INC;
900
901 # This was an attempt to clear out the previous values of various
902 # trapped errors. Apparently it didn't help. XXX More info needed!
903 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
904
905 # We set these variables to safe values. We don't want to blindly turn
906 # off warnings, because other packages may still want them.
907 $trace = $signal = $single = 0;    # Uninitialized warning suppression
908                                    # (local $^W cannot help - other packages!).
909
910 # Default to not exiting when program finishes; print the return
911 # value when the 'r' command is used to return from a subroutine.
912 $inhibit_exit = $option{PrintRet} = 1;
913
914 use vars qw($trace_to_depth);
915
916 # Default to 1E9 so it won't be limited to a certain recursion depth.
917 $trace_to_depth = 1E9;
918
919 =head1 OPTION PROCESSING
920
921 The debugger's options are actually spread out over the debugger itself and
922 C<dumpvar.pl>; some of these are variables to be set, while others are
923 subs to be called with a value. To try to make this a little easier to
924 manage, the debugger uses a few data structures to define what options
925 are legal and how they are to be processed.
926
927 First, the C<@options> array defines the I<names> of all the options that
928 are to be accepted.
929
930 =cut
931
932 @options = qw(
933   CommandSet   HistFile      HistSize
934   hashDepth    arrayDepth    dumpDepth
935   DumpDBFiles  DumpPackages  DumpReused
936   compactDump  veryCompact   quote
937   HighBit      undefPrint    globPrint
938   PrintRet     UsageOnly     frame
939   AutoTrace    TTY           noTTY
940   ReadLine     NonStop       LineInfo
941   maxTraceLen  recallCommand ShellBang
942   pager        tkRunning     ornaments
943   signalLevel  warnLevel     dieLevel
944   inhibit_exit ImmediateStop bareStringify
945   CreateTTY    RemotePort    windowSize
946   DollarCaretP
947 );
948
949 @RememberOnROptions = qw(DollarCaretP);
950
951 =pod
952
953 Second, C<optionVars> lists the variables that each option uses to save its
954 state.
955
956 =cut
957
958 use vars qw(%optionVars);
959
960 %optionVars = (
961     hashDepth     => \$dumpvar::hashDepth,
962     arrayDepth    => \$dumpvar::arrayDepth,
963     CommandSet    => \$CommandSet,
964     DumpDBFiles   => \$dumpvar::dumpDBFiles,
965     DumpPackages  => \$dumpvar::dumpPackages,
966     DumpReused    => \$dumpvar::dumpReused,
967     HighBit       => \$dumpvar::quoteHighBit,
968     undefPrint    => \$dumpvar::printUndef,
969     globPrint     => \$dumpvar::globPrint,
970     UsageOnly     => \$dumpvar::usageOnly,
971     CreateTTY     => \$CreateTTY,
972     bareStringify => \$dumpvar::bareStringify,
973     frame         => \$frame,
974     AutoTrace     => \$trace,
975     inhibit_exit  => \$inhibit_exit,
976     maxTraceLen   => \$maxtrace,
977     ImmediateStop => \$ImmediateStop,
978     RemotePort    => \$remoteport,
979     windowSize    => \$window,
980     HistFile      => \$histfile,
981     HistSize      => \$histsize,
982 );
983
984 =pod
985
986 Third, C<%optionAction> defines the subroutine to be called to process each
987 option.
988
989 =cut
990
991 use vars qw(%optionAction);
992
993 %optionAction = (
994     compactDump   => \&dumpvar::compactDump,
995     veryCompact   => \&dumpvar::veryCompact,
996     quote         => \&dumpvar::quote,
997     TTY           => \&TTY,
998     noTTY         => \&noTTY,
999     ReadLine      => \&ReadLine,
1000     NonStop       => \&NonStop,
1001     LineInfo      => \&LineInfo,
1002     recallCommand => \&recallCommand,
1003     ShellBang     => \&shellBang,
1004     pager         => \&pager,
1005     signalLevel   => \&signalLevel,
1006     warnLevel     => \&warnLevel,
1007     dieLevel      => \&dieLevel,
1008     tkRunning     => \&tkRunning,
1009     ornaments     => \&ornaments,
1010     RemotePort    => \&RemotePort,
1011     DollarCaretP  => \&DollarCaretP,
1012 );
1013
1014 =pod
1015
1016 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1017 option is used.
1018
1019 =cut
1020
1021 # Note that this list is not complete: several options not listed here
1022 # actually require that dumpvar.pl be loaded for them to work, but are
1023 # not in the table. A subsequent patch will correct this problem; for
1024 # the moment, we're just recommenting, and we are NOT going to change
1025 # function.
1026 use vars qw(%optionRequire);
1027
1028 %optionRequire = (
1029     compactDump => 'dumpvar.pl',
1030     veryCompact => 'dumpvar.pl',
1031     quote       => 'dumpvar.pl',
1032 );
1033
1034 =pod
1035
1036 There are a number of initialization-related variables which can be set
1037 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1038 variable. These are:
1039
1040 =over 4
1041
1042 =item C<$rl> - readline control XXX needs more explanation
1043
1044 =item C<$warnLevel> - whether or not debugger takes over warning handling
1045
1046 =item C<$dieLevel> - whether or not debugger takes over die handling
1047
1048 =item C<$signalLevel> - whether or not debugger takes over signal handling
1049
1050 =item C<$pre> - preprompt actions (array reference)
1051
1052 =item C<$post> - postprompt actions (array reference)
1053
1054 =item C<$pretype>
1055
1056 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1057
1058 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1059
1060 =back
1061
1062 =cut
1063
1064 # These guys may be defined in $ENV{PERL5DB} :
1065 $rl          = 1     unless defined $rl;
1066 $warnLevel   = 1     unless defined $warnLevel;
1067 $dieLevel    = 1     unless defined $dieLevel;
1068 $signalLevel = 1     unless defined $signalLevel;
1069 $pre         = []    unless defined $pre;
1070 $post        = []    unless defined $post;
1071 $pretype     = []    unless defined $pretype;
1072 $CreateTTY   = 3     unless defined $CreateTTY;
1073 $CommandSet  = '580' unless defined $CommandSet;
1074
1075 share($rl);
1076 share($warnLevel);
1077 share($dieLevel);
1078 share($signalLevel);
1079 share($pre);
1080 share($post);
1081 share($pretype);
1082 share($rl);
1083 share($CreateTTY);
1084 share($CommandSet);
1085
1086 =pod
1087
1088 The default C<die>, C<warn>, and C<signal> handlers are set up.
1089
1090 =cut
1091
1092 warnLevel($warnLevel);
1093 dieLevel($dieLevel);
1094 signalLevel($signalLevel);
1095
1096 =pod
1097
1098 The pager to be used is needed next. We try to get it from the
1099 environment first.  If it's not defined there, we try to find it in
1100 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1101 then call the C<pager()> function to save the pager name.
1102
1103 =cut
1104
1105 # This routine makes sure $pager is set up so that '|' can use it.
1106 pager(
1107
1108     # If PAGER is defined in the environment, use it.
1109     defined $ENV{PAGER}
1110     ? $ENV{PAGER}
1111
1112       # If not, see if Config.pm defines it.
1113     : eval { require Config }
1114       && defined $Config::Config{pager}
1115     ? $Config::Config{pager}
1116
1117       # If not, fall back to 'more'.
1118     : 'more'
1119   )
1120   unless defined $pager;
1121
1122 =pod
1123
1124 We set up the command to be used to access the man pages, the command
1125 recall character (C<!> unless otherwise defined) and the shell escape
1126 character (C<!> unless otherwise defined). Yes, these do conflict, and
1127 neither works in the debugger at the moment.
1128
1129 =cut
1130
1131 setman();
1132
1133 # Set up defaults for command recall and shell escape (note:
1134 # these currently don't work in linemode debugging).
1135 recallCommand("!") unless defined $prc;
1136 shellBang("!")     unless defined $psh;
1137
1138 =pod
1139
1140 We then set up the gigantic string containing the debugger help.
1141 We also set the limit on the number of arguments we'll display during a
1142 trace.
1143
1144 =cut
1145
1146 sethelp();
1147
1148 # If we didn't get a default for the length of eval/stack trace args,
1149 # set it here.
1150 $maxtrace = 400 unless defined $maxtrace;
1151
1152 =head2 SETTING UP THE DEBUGGER GREETING
1153
1154 The debugger I<greeting> helps to inform the user how many debuggers are
1155 running, and whether the current debugger is the primary or a child.
1156
1157 If we are the primary, we just hang onto our pid so we'll have it when
1158 or if we start a child debugger. If we are a child, we'll set things up
1159 so we'll have a unique greeting and so the parent will give us our own
1160 TTY later.
1161
1162 We save the current contents of the C<PERLDB_PIDS> environment variable
1163 because we mess around with it. We'll also need to hang onto it because
1164 we'll need it if we restart.
1165
1166 Child debuggers make a label out of the current PID structure recorded in
1167 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1168 yet so the parent will give them one later via C<resetterm()>.
1169
1170 =cut
1171
1172 # Save the current contents of the environment; we're about to
1173 # much with it. We'll need this if we have to restart.
1174 use vars qw($ini_pids);
1175 $ini_pids = $ENV{PERLDB_PIDS};
1176
1177 use vars qw ($pids $term_pid);
1178
1179 if ( defined $ENV{PERLDB_PIDS} ) {
1180
1181     # We're a child. Make us a label out of the current PID structure
1182     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1183     # a term yet so the parent will give us one later via resetterm().
1184
1185     my $env_pids = $ENV{PERLDB_PIDS};
1186     $pids = "[$env_pids]";
1187
1188     # Unless we are on OpenVMS, all programs under the DCL shell run under
1189     # the same PID.
1190
1191     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1192         $term_pid         = $$;
1193     }
1194     else {
1195         $ENV{PERLDB_PIDS} .= "->$$";
1196         $term_pid = -1;
1197     }
1198
1199 } ## end if (defined $ENV{PERLDB_PIDS...
1200 else {
1201
1202     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1203     # child debugger, and mark us as the parent, so we'll know to set up
1204     # more TTY's is we have to.
1205     $ENV{PERLDB_PIDS} = "$$";
1206     $pids             = "[pid=$$]";
1207     $term_pid         = $$;
1208 }
1209
1210 use vars qw($pidprompt);
1211 $pidprompt = '';
1212
1213 # Sets up $emacs as a synonym for $slave_editor.
1214 use vars qw($slave_editor);
1215 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1216
1217 =head2 READING THE RC FILE
1218
1219 The debugger will read a file of initialization options if supplied. If
1220 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1221
1222 =cut
1223
1224 # As noted, this test really doesn't check accurately that the debugger
1225 # is running at a terminal or not.
1226
1227 use vars qw($rcfile);
1228 {
1229     my $dev_tty = (($^O eq 'VMS') ? 'TT:' : '/dev/tty');
1230     # this is the wrong metric!
1231     $rcfile = ((-e $dev_tty) ? ".perldb" : "perldb.ini");
1232 }
1233
1234 =pod
1235
1236 The debugger does a safety test of the file to be read. It must be owned
1237 either by the current user or root, and must only be writable by the owner.
1238
1239 =cut
1240
1241 # This wraps a safety test around "do" to read and evaluate the init file.
1242 #
1243 # This isn't really safe, because there's a race
1244 # between checking and opening.  The solution is to
1245 # open and fstat the handle, but then you have to read and
1246 # eval the contents.  But then the silly thing gets
1247 # your lexical scope, which is unfortunate at best.
1248 sub safe_do {
1249     my $file = shift;
1250
1251     # Just exactly what part of the word "CORE::" don't you understand?
1252     local $SIG{__WARN__};
1253     local $SIG{__DIE__};
1254
1255     unless ( is_safe_file($file) ) {
1256         CORE::warn <<EO_GRIPE;
1257 perldb: Must not source insecure rcfile $file.
1258         You or the superuser must be the owner, and it must not
1259         be writable by anyone but its owner.
1260 EO_GRIPE
1261         return;
1262     } ## end unless (is_safe_file($file...
1263
1264     do $file;
1265     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1266 } ## end sub safe_do
1267
1268 # This is the safety test itself.
1269 #
1270 # Verifies that owner is either real user or superuser and that no
1271 # one but owner may write to it.  This function is of limited use
1272 # when called on a path instead of upon a handle, because there are
1273 # no guarantees that filename (by dirent) whose file (by ino) is
1274 # eventually accessed is the same as the one tested.
1275 # Assumes that the file's existence is not in doubt.
1276 sub is_safe_file {
1277     my $path = shift;
1278     stat($path) || return;    # mysteriously vaporized
1279     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1280
1281     return 0 if $uid != 0 && $uid != $<;
1282     return 0 if $mode & 022;
1283     return 1;
1284 } ## end sub is_safe_file
1285
1286 # If the rcfile (whichever one we decided was the right one to read)
1287 # exists, we safely do it.
1288 if ( -f $rcfile ) {
1289     safe_do("./$rcfile");
1290 }
1291
1292 # If there isn't one here, try the user's home directory.
1293 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1294     safe_do("$ENV{HOME}/$rcfile");
1295 }
1296
1297 # Else try the login directory.
1298 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1299     safe_do("$ENV{LOGDIR}/$rcfile");
1300 }
1301
1302 # If the PERLDB_OPTS variable has options in it, parse those out next.
1303 if ( defined $ENV{PERLDB_OPTS} ) {
1304     parse_options( $ENV{PERLDB_OPTS} );
1305 }
1306
1307 =pod
1308
1309 The last thing we do during initialization is determine which subroutine is
1310 to be used to obtain a new terminal when a new debugger is started. Right now,
1311 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1312 (darwin).
1313
1314 =cut
1315
1316 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1317 # Works if you're running an xterm or xterm-like window, or you're on
1318 # OS/2, or on Mac OS X. This may need some expansion.
1319
1320 if (not defined &get_fork_TTY)       # only if no routine exists
1321 {
1322     if ( defined $remoteport ) {
1323                                                  # Expect an inetd-like server
1324         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1325     }
1326     elsif (defined $ENV{TERM}                    # If we know what kind
1327                                                  # of terminal this is,
1328         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1329         and defined $ENV{DISPLAY}                # and what display it's on,
1330       )
1331     {
1332         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1333     }
1334     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1335         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1336     }
1337     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1338             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1339             and $ENV{TERM_PROGRAM}
1340                 eq 'Apple_Terminal'              # Terminal.app
1341             )
1342     {
1343         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1344     }
1345 } ## end if (not defined &get_fork_TTY...
1346
1347 # untaint $^O, which may have been tainted by the last statement.
1348 # see bug [perl #24674]
1349 $^O =~ m/^(.*)\z/;
1350 $^O = $1;
1351
1352 # Here begin the unreadable code.  It needs fixing.
1353
1354 =head2 RESTART PROCESSING
1355
1356 This section handles the restart command. When the C<R> command is invoked, it
1357 tries to capture all of the state it can into environment variables, and
1358 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1359 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1360 the R command stuffed into the environment variables.
1361
1362   PERLDB_RESTART   - flag only, contains no restart data itself.
1363   PERLDB_HIST      - command history, if it's available
1364   PERLDB_ON_LOAD   - breakpoints set by the rc file
1365   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1366   PERLDB_VISITED   - files that had breakpoints
1367   PERLDB_FILE_...  - breakpoints for a file
1368   PERLDB_OPT       - active options
1369   PERLDB_INC       - the original @INC
1370   PERLDB_PRETYPE   - preprompt debugger actions
1371   PERLDB_PRE       - preprompt Perl code
1372   PERLDB_POST      - post-prompt Perl code
1373   PERLDB_TYPEAHEAD - typeahead captured by readline()
1374
1375 We chug through all these variables and plug the values saved in them
1376 back into the appropriate spots in the debugger.
1377
1378 =cut
1379
1380 use vars qw(@hist @truehist %postponed_file @typeahead);
1381
1382 sub _restore_breakpoints_and_actions {
1383
1384     my @had_breakpoints = get_list("PERLDB_VISITED");
1385
1386     for my $file_idx ( 0 .. $#had_breakpoints ) {
1387         my $filename = $had_breakpoints[$file_idx];
1388         my %pf = get_list("PERLDB_FILE_$file_idx");
1389         $postponed_file{ $filename } = \%pf if %pf;
1390         my @lines = sort {$a <=> $b} keys(%pf);
1391         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1392         for my $line_idx (0 .. $#lines) {
1393             _set_breakpoint_enabled_status(
1394                 $filename,
1395                 $lines[$line_idx],
1396                 ($enabled_statuses[$line_idx] ? 1 : ''),
1397             );
1398         }
1399     }
1400
1401     return;
1402 }
1403
1404 if ( exists $ENV{PERLDB_RESTART} ) {
1405
1406     # We're restarting, so we don't need the flag that says to restart anymore.
1407     delete $ENV{PERLDB_RESTART};
1408
1409     # $restart = 1;
1410     @hist          = get_list('PERLDB_HIST');
1411     %break_on_load = get_list("PERLDB_ON_LOAD");
1412     %postponed     = get_list("PERLDB_POSTPONE");
1413
1414     share(@hist);
1415     share(@truehist);
1416     share(%break_on_load);
1417     share(%postponed);
1418
1419     _restore_breakpoints_and_actions();
1420
1421     # restore options
1422     my %opt = get_list("PERLDB_OPT");
1423     my ( $opt, $val );
1424     while ( ( $opt, $val ) = each %opt ) {
1425         $val =~ s/[\\\']/\\$1/g;
1426         parse_options("$opt'$val'");
1427     }
1428
1429     # restore original @INC
1430     @INC     = get_list("PERLDB_INC");
1431     @ini_INC = @INC;
1432
1433     # return pre/postprompt actions and typeahead buffer
1434     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1435     $pre       = [ get_list("PERLDB_PRE") ];
1436     $post      = [ get_list("PERLDB_POST") ];
1437     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1438 } ## end if (exists $ENV{PERLDB_RESTART...
1439
1440 =head2 SETTING UP THE TERMINAL
1441
1442 Now, we'll decide how the debugger is going to interact with the user.
1443 If there's no TTY, we set the debugger to run non-stop; there's not going
1444 to be anyone there to enter commands.
1445
1446 =cut
1447
1448 use vars qw($notty $runnonstop $console $tty $LINEINFO);
1449 use vars qw($lineinfo $doccmd);
1450
1451 if ($notty) {
1452     $runnonstop = 1;
1453         share($runnonstop);
1454 }
1455
1456 =pod
1457
1458 If there is a TTY, we have to determine who it belongs to before we can
1459 proceed. If this is a slave editor or graphical debugger (denoted by
1460 the first command-line switch being '-emacs'), we shift this off and
1461 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1462
1463 =cut
1464
1465 else {
1466
1467     # Is Perl being run from a slave editor or graphical debugger?
1468     # If so, don't use readline, and set $slave_editor = 1.
1469     $slave_editor =
1470       ( ( defined $main::ARGV[0] ) and ( $main::ARGV[0] eq '-emacs' ) );
1471     $rl = 0, shift(@main::ARGV) if $slave_editor;
1472
1473     #require Term::ReadLine;
1474
1475 =pod
1476
1477 We then determine what the console should be on various systems:
1478
1479 =over 4
1480
1481 =item * Cygwin - We use C<stdin> instead of a separate device.
1482
1483 =cut
1484
1485     if ( $^O eq 'cygwin' ) {
1486
1487         # /dev/tty is binary. use stdin for textmode
1488         undef $console;
1489     }
1490
1491 =item * Unix - use C</dev/tty>.
1492
1493 =cut
1494
1495     elsif ( -e "/dev/tty" ) {
1496         $console = "/dev/tty";
1497     }
1498
1499 =item * Windows or MSDOS - use C<con>.
1500
1501 =cut
1502
1503     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1504         $console = "con";
1505     }
1506
1507 =item * VMS - use C<sys$command>.
1508
1509 =cut
1510
1511     else {
1512
1513         # everything else is ...
1514         $console = "sys\$command";
1515     }
1516
1517 =pod
1518
1519 =back
1520
1521 Several other systems don't use a specific console. We C<undef $console>
1522 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1523 with a slave editor, Epoc).
1524
1525 =cut
1526
1527     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1528
1529         # /dev/tty is binary. use stdin for textmode
1530         $console = undef;
1531     }
1532
1533     if ( $^O eq 'NetWare' ) {
1534
1535         # /dev/tty is binary. use stdin for textmode
1536         $console = undef;
1537     }
1538
1539     # In OS/2, we need to use STDIN to get textmode too, even though
1540     # it pretty much looks like Unix otherwise.
1541     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1542     {    # In OS/2
1543         $console = undef;
1544     }
1545
1546     # EPOC also falls into the 'got to use STDIN' camp.
1547     if ( $^O eq 'epoc' ) {
1548         $console = undef;
1549     }
1550
1551 =pod
1552
1553 If there is a TTY hanging around from a parent, we use that as the console.
1554
1555 =cut
1556
1557     $console = $tty if defined $tty;
1558
1559 =head2 SOCKET HANDLING
1560
1561 The debugger is capable of opening a socket and carrying out a debugging
1562 session over the socket.
1563
1564 If C<RemotePort> was defined in the options, the debugger assumes that it
1565 should try to start a debugging session on that port. It builds the socket
1566 and then tries to connect the input and output filehandles to it.
1567
1568 =cut
1569
1570     # Handle socket stuff.
1571
1572     if ( defined $remoteport ) {
1573
1574         # If RemotePort was defined in the options, connect input and output
1575         # to the socket.
1576         $IN = $OUT = connect_remoteport();
1577     } ## end if (defined $remoteport)
1578
1579 =pod
1580
1581 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1582 this is probably a situation where multiple debuggers are running (for example,
1583 a backticked command that starts up another debugger). We create a new IN and
1584 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1585 and if we can.
1586
1587 =cut
1588
1589     # Non-socket.
1590     else {
1591
1592         # Two debuggers running (probably a system or a backtick that invokes
1593         # the debugger itself under the running one). create a new IN and OUT
1594         # filehandle, and do the necessary mojo to create a new tty if we
1595         # know how, and we can.
1596         create_IN_OUT(4) if $CreateTTY & 4;
1597         if ($console) {
1598
1599             # If we have a console, check to see if there are separate ins and
1600             # outs to open. (They are assumed identical if not.)
1601
1602             my ( $i, $o ) = split /,/, $console;
1603             $o = $i unless defined $o;
1604
1605             # read/write on in, or just read, or read on STDIN.
1606             open( IN,      "+<$i" )
1607               || open( IN, "<$i" )
1608               || open( IN, "<&STDIN" );
1609
1610             # read/write/create/clobber out, or write/create/clobber out,
1611             # or merge with STDERR, or merge with STDOUT.
1612                  open( OUT, "+>$o" )
1613               || open( OUT, ">$o" )
1614               || open( OUT, ">&STDERR" )
1615               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1616
1617         } ## end if ($console)
1618         elsif ( not defined $console ) {
1619
1620             # No console. Open STDIN.
1621             open( IN, "<&STDIN" );
1622
1623             # merge with STDERR, or with STDOUT.
1624             open( OUT,      ">&STDERR" )
1625               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1626             $console = 'STDIN/OUT';
1627         } ## end elsif (not defined $console)
1628
1629         # Keep copies of the filehandles so that when the pager runs, it
1630         # can close standard input without clobbering ours.
1631         $IN = \*IN, $OUT = \*OUT if $console or not defined $console;
1632     } ## end elsif (from if(defined $remoteport))
1633
1634     # Unbuffer DB::OUT. We need to see responses right away.
1635     $OUT->autoflush(1);
1636
1637     # Line info goes to debugger output unless pointed elsewhere.
1638     # Pointing elsewhere makes it possible for slave editors to
1639     # keep track of file and position. We have both a filehandle
1640     # and a I/O description to keep track of.
1641     $LINEINFO = $OUT     unless defined $LINEINFO;
1642     $lineinfo = $console unless defined $lineinfo;
1643         # share($LINEINFO); # <- unable to share globs
1644         share($lineinfo);   #
1645
1646 =pod
1647
1648 To finish initialization, we show the debugger greeting,
1649 and then call the C<afterinit()> subroutine if there is one.
1650
1651 =cut
1652
1653     # Show the debugger greeting.
1654     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1655     unless ($runnonstop) {
1656         local $\ = '';
1657         local $, = '';
1658         if ( $term_pid eq '-1' ) {
1659             print $OUT "\nDaughter DB session started...\n";
1660         }
1661         else {
1662             print $OUT "\nLoading DB routines from $header\n";
1663             print $OUT (
1664                 "Editor support ",
1665                 $slave_editor ? "enabled" : "available", ".\n"
1666             );
1667             print $OUT
1668 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1669         } ## end else [ if ($term_pid eq '-1')
1670     } ## end unless ($runnonstop)
1671 } ## end else [ if ($notty)
1672
1673 # XXX This looks like a bug to me.
1674 # Why copy to @ARGS and then futz with @args?
1675 @ARGS = @ARGV;
1676 # for (@args) {
1677     # Make sure backslashes before single quotes are stripped out, and
1678     # keep args unless they are numeric (XXX why?)
1679     # s/\'/\\\'/g;                      # removed while not justified understandably
1680     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1681 # }
1682
1683 # If there was an afterinit() sub defined, call it. It will get
1684 # executed in our scope, so it can fiddle with debugger globals.
1685 if ( defined &afterinit ) {    # May be defined in $rcfile
1686     &afterinit();
1687 }
1688
1689 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1690 use vars qw($I_m_init);
1691
1692 $I_m_init = 1;
1693
1694 ############################################################ Subroutines
1695
1696 =head1 SUBROUTINES
1697
1698 =head2 DB
1699
1700 This gigantic subroutine is the heart of the debugger. Called before every
1701 statement, its job is to determine if a breakpoint has been reached, and
1702 stop if so; read commands from the user, parse them, and execute
1703 them, and then send execution off to the next statement.
1704
1705 Note that the order in which the commands are processed is very important;
1706 some commands earlier in the loop will actually alter the C<$cmd> variable
1707 to create other commands to be executed later. This is all highly I<optimized>
1708 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1709 see what's happening in any given command.
1710
1711 =cut
1712
1713 use vars qw(
1714     $action
1715     %alias
1716     $cmd
1717     $doret
1718     $fall_off_end
1719     $file
1720     $filename_ini
1721     $finished
1722     %had_breakpoints
1723     $incr
1724     $laststep
1725     $level
1726     $max
1727     @old_watch
1728     $package
1729     $rc
1730     $sh
1731     @stack
1732     $stack_depth
1733     @to_watch
1734     $try
1735     $end
1736 );
1737
1738 sub DB {
1739
1740     # lock the debugger and get the thread id for the prompt
1741         lock($DBGR);
1742         my $tid;
1743         my $position;
1744         my ($prefix, $after, $infix);
1745         my $pat;
1746
1747         if ($ENV{PERL5DB_THREADED}) {
1748                 $tid = eval { "[".threads->tid."]" };
1749         }
1750
1751     # Check for whether we should be running continuously or not.
1752     # _After_ the perl program is compiled, $single is set to 1:
1753     if ( $single and not $second_time++ ) {
1754
1755         # Options say run non-stop. Run until we get an interrupt.
1756         if ($runnonstop) {    # Disable until signal
1757                 # If there's any call stack in place, turn off single
1758                 # stepping into subs throughout the stack.
1759             for my $i (0 .. $stack_depth) {
1760                 $stack[ $i ] &= ~1;
1761             }
1762
1763             # And we are now no longer in single-step mode.
1764             $single = 0;
1765
1766             # If we simply returned at this point, we wouldn't get
1767             # the trace info. Fall on through.
1768             # return;
1769         } ## end if ($runnonstop)
1770
1771         elsif ($ImmediateStop) {
1772
1773             # We are supposed to stop here; XXX probably a break.
1774             $ImmediateStop = 0;    # We've processed it; turn it off
1775             $signal        = 1;    # Simulate an interrupt to force
1776                                    # us into the command loop
1777         }
1778     } ## end if ($single and not $second_time...
1779
1780     # If we're in single-step mode, or an interrupt (real or fake)
1781     # has occurred, turn off non-stop mode.
1782     $runnonstop = 0 if $single or $signal;
1783
1784     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
1785     # The code being debugged may have altered them.
1786     &save;
1787
1788     # Since DB::DB gets called after every line, we can use caller() to
1789     # figure out where we last were executing. Sneaky, eh? This works because
1790     # caller is returning all the extra information when called from the
1791     # debugger.
1792     local ( $package, $filename, $line ) = caller;
1793     $filename_ini = $filename;
1794
1795     # set up the context for DB::eval, so it can properly execute
1796     # code on behalf of the user. We add the package in so that the
1797     # code is eval'ed in the proper package (not in the debugger!).
1798     local $usercontext = _calc_usercontext($package);
1799
1800     # Create an alias to the active file magical array to simplify
1801     # the code here.
1802     local (*dbline) = $main::{ '_<' . $filename };
1803
1804     # Last line in the program.
1805     $max = $#dbline;
1806
1807     # if we have something here, see if we should break.
1808     {
1809         # $stop is lexical and local to this block - $action on the other hand
1810         # is global.
1811         my $stop;
1812
1813         if ( $dbline{$line}
1814             && _is_breakpoint_enabled($filename, $line)
1815             && (( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1816         {
1817
1818             # Stop if the stop criterion says to just stop.
1819             if ( $stop eq '1' ) {
1820                 $signal |= 1;
1821             }
1822
1823             # It's a conditional stop; eval it in the user's context and
1824             # see if we should stop. If so, remove the one-time sigil.
1825             elsif ($stop) {
1826                 $evalarg = "\$DB::signal |= 1 if do {$stop}";
1827                 &eval;
1828                 # If the breakpoint is temporary, then delete its enabled status.
1829                 if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1830                     _cancel_breakpoint_temp_enabled_status($filename, $line);
1831                 }
1832             }
1833         } ## end if ($dbline{$line} && ...
1834     }
1835
1836     # Preserve the current stop-or-not, and see if any of the W
1837     # (watch expressions) has changed.
1838     my $was_signal = $signal;
1839
1840     # If we have any watch expressions ...
1841     if ( $trace & 2 ) {
1842         for my $n (0 .. $#to_watch) {
1843             $evalarg = $to_watch[$n];
1844             local $onetimeDump;    # Tell DB::eval() to not output results
1845
1846             # Fix context DB::eval() wants to return an array, but
1847             # we need a scalar here.
1848             my ($val) = join( "', '", &eval );
1849             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
1850
1851             # Did it change?
1852             if ( $val ne $old_watch[$n] ) {
1853
1854                 # Yep! Show the difference, and fake an interrupt.
1855                 $signal = 1;
1856                 print $OUT <<EOP;
1857 Watchpoint $n:\t$to_watch[$n] changed:
1858     old value:\t$old_watch[$n]
1859     new value:\t$val
1860 EOP
1861                 $old_watch[$n] = $val;
1862             } ## end if ($val ne $old_watch...
1863         } ## end for my $n (0 ..
1864     } ## end if ($trace & 2)
1865
1866 =head2 C<watchfunction()>
1867
1868 C<watchfunction()> is a function that can be defined by the user; it is a
1869 function which will be run on each entry to C<DB::DB>; it gets the
1870 current package, filename, and line as its parameters.
1871
1872 The watchfunction can do anything it likes; it is executing in the
1873 debugger's context, so it has access to all of the debugger's internal
1874 data structures and functions.
1875
1876 C<watchfunction()> can control the debugger's actions. Any of the following
1877 will cause the debugger to return control to the user's program after
1878 C<watchfunction()> executes:
1879
1880 =over 4
1881
1882 =item *
1883
1884 Returning a false value from the C<watchfunction()> itself.
1885
1886 =item *
1887
1888 Altering C<$single> to a false value.
1889
1890 =item *
1891
1892 Altering C<$signal> to a false value.
1893
1894 =item *
1895
1896 Turning off the C<4> bit in C<$trace> (this also disables the
1897 check for C<watchfunction()>. This can be done with
1898
1899     $trace &= ~4;
1900
1901 =back
1902
1903 =cut
1904
1905     # If there's a user-defined DB::watchfunction, call it with the
1906     # current package, filename, and line. The function executes in
1907     # the DB:: package.
1908     if ( $trace & 4 ) {    # User-installed watch
1909         return
1910           if watchfunction( $package, $filename, $line )
1911           and not $single
1912           and not $was_signal
1913           and not( $trace & ~4 );
1914     } ## end if ($trace & 4)
1915
1916     # Pick up any alteration to $signal in the watchfunction, and
1917     # turn off the signal now.
1918     $was_signal = $signal;
1919     $signal     = 0;
1920
1921 =head2 GETTING READY TO EXECUTE COMMANDS
1922
1923 The debugger decides to take control if single-step mode is on, the
1924 C<t> command was entered, or the user generated a signal. If the program
1925 has fallen off the end, we set things up so that entering further commands
1926 won't cause trouble, and we say that the program is over.
1927
1928 =cut
1929
1930     # Make sure that we always print if asked for explicitly regardless
1931     # of $trace_to_depth .
1932     my $explicit_stop = ($single || $was_signal);
1933
1934     # Check to see if we should grab control ($single true,
1935     # trace set appropriately, or we got a signal).
1936     if ( $explicit_stop || ( $trace & 1 ) ) {
1937
1938         # Yes, grab control.
1939         if ($slave_editor) {
1940
1941             # Tell the editor to update its position.
1942             $position = "\032\032$filename:$line:0\n";
1943             print_lineinfo($position);
1944         }
1945
1946 =pod
1947
1948 Special check: if we're in package C<DB::fake>, we've gone through the
1949 C<END> block at least once. We set up everything so that we can continue
1950 to enter commands and have a valid context to be in.
1951
1952 =cut
1953
1954         elsif ( $package eq 'DB::fake' ) {
1955
1956             # Fallen off the end already.
1957             $term || &setterm;
1958             print_help(<<EOP);
1959 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
1960   use B<o> I<inhibit_exit> to avoid stopping after program termination,
1961   B<h q>, B<h R> or B<h o> to get additional info.
1962 EOP
1963
1964             # Set the DB::eval context appropriately.
1965             $package     = 'main';
1966             $usercontext = _calc_usercontext($package);
1967         } ## end elsif ($package eq 'DB::fake')
1968
1969 =pod
1970
1971 If the program hasn't finished executing, we scan forward to the
1972 next executable line, print that out, build the prompt from the file and line
1973 number information, and print that.
1974
1975 =cut
1976
1977         else {
1978
1979
1980             # Still somewhere in the midst of execution. Set up the
1981             #  debugger prompt.
1982             $sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
1983                                  # Perl 5 ones (sorry, we don't print Klingon
1984                                  #module names)
1985
1986             $prefix = $sub =~ /::/ ? "" : ($package . '::');
1987             $prefix .= "$sub($filename:";
1988             $after = ( $dbline[$line] =~ /\n$/ ? '' : "\n" );
1989
1990             # Break up the prompt if it's really long.
1991             if ( length($prefix) > 30 ) {
1992                 $position = "$prefix$line):\n$line:\t$dbline[$line]$after";
1993                 $prefix   = "";
1994                 $infix    = ":\t";
1995             }
1996             else {
1997                 $infix    = "):\t";
1998                 $position = "$prefix$line$infix$dbline[$line]$after";
1999             }
2000
2001             # Print current line info, indenting if necessary.
2002             if ($frame) {
2003                 print_lineinfo( ' ' x $stack_depth,
2004                     "$line:\t$dbline[$line]$after" );
2005             }
2006             else {
2007                 depth_print_lineinfo($explicit_stop, $position);
2008             }
2009
2010             # Scan forward, stopping at either the end or the next
2011             # unbreakable line.
2012             for ( my $i = $line + 1 ; $i <= $max && $dbline[$i] == 0 ; ++$i )
2013             {    #{ vi
2014
2015                 # Drop out on null statements, block closers, and comments.
2016                 last if $dbline[$i] =~ /^\s*[\;\}\#\n]/;
2017
2018                 # Drop out if the user interrupted us.
2019                 last if $signal;
2020
2021                 # Append a newline if the line doesn't have one. Can happen
2022                 # in eval'ed text, for instance.
2023                 $after = ( $dbline[$i] =~ /\n$/ ? '' : "\n" );
2024
2025                 # Next executable line.
2026                 my $incr_pos = "$prefix$i$infix$dbline[$i]$after";
2027                 $position .= $incr_pos;
2028                 if ($frame) {
2029
2030                     # Print it indented if tracing is on.
2031                     print_lineinfo( ' ' x $stack_depth,
2032                         "$i:\t$dbline[$i]$after" );
2033                 }
2034                 else {
2035                     depth_print_lineinfo($explicit_stop, $incr_pos);
2036                 }
2037             } ## end for ($i = $line + 1 ; $i...
2038         } ## end else [ if ($slave_editor)
2039     } ## end if ($single || ($trace...
2040
2041 =pod
2042
2043 If there's an action to be executed for the line we stopped at, execute it.
2044 If there are any preprompt actions, execute those as well.
2045
2046 =cut
2047
2048     # If there's an action, do it now.
2049     $evalarg = $action, &eval if $action;
2050
2051     # Are we nested another level (e.g., did we evaluate a function
2052     # that had a breakpoint in it at the debugger prompt)?
2053     if ( $single || $was_signal ) {
2054
2055         # Yes, go down a level.
2056         local $level = $level + 1;
2057
2058         # Do any pre-prompt actions.
2059         foreach $evalarg (@$pre) {
2060             &eval;
2061         }
2062
2063         # Complain about too much recursion if we passed the limit.
2064         print $OUT $stack_depth . " levels deep in subroutine calls!\n"
2065           if $single & 4;
2066
2067         # The line we're currently on. Set $incr to -1 to stay here
2068         # until we get a command that tells us to advance.
2069         $start = $line;
2070         $incr  = -1;      # for backward motion.
2071
2072         # Tack preprompt debugger actions ahead of any actual input.
2073         @typeahead = ( @$pretype, @typeahead );
2074
2075 =head2 WHERE ARE WE?
2076
2077 XXX Relocate this section?
2078
2079 The debugger normally shows the line corresponding to the current line of
2080 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2081 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2082
2083 C<$incr> controls by how many lines the I<current> line should move forward
2084 after a command is executed. If set to -1, this indicates that the I<current>
2085 line shouldn't change.
2086
2087 C<$start> is the I<current> line. It is used for things like knowing where to
2088 move forwards or backwards from when doing an C<L> or C<-> command.
2089
2090 C<$max> tells the debugger where the last line of the current file is. It's
2091 used to terminate loops most often.
2092
2093 =head2 THE COMMAND LOOP
2094
2095 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2096 in two parts:
2097
2098 =over 4
2099
2100 =item *
2101
2102 The outer part of the loop, starting at the C<CMD> label. This loop
2103 reads a command and then executes it.
2104
2105 =item *
2106
2107 The inner part of the loop, starting at the C<PIPE> label. This part
2108 is wholly contained inside the C<CMD> block and only executes a command.
2109 Used to handle commands running inside a pager.
2110
2111 =back
2112
2113 So why have two labels to restart the loop? Because sometimes, it's easier to
2114 have a command I<generate> another command and then re-execute the loop to do
2115 the new command. This is faster, but perhaps a bit more convoluted.
2116
2117 =cut
2118
2119         # The big command dispatch loop. It keeps running until the
2120         # user yields up control again.
2121         #
2122         # If we have a terminal for input, and we get something back
2123         # from readline(), keep on processing.
2124         my $piped;
2125         my $selected;
2126
2127       CMD:
2128         while (
2129
2130             # We have a terminal, or can get one ...
2131             ( $term || &setterm ),
2132
2133             # ... and it belogs to this PID or we get one for this PID ...
2134             ( $term_pid == $$ or resetterm(1) ),
2135
2136             # ... and we got a line of command input ...
2137             defined(
2138                 $cmd = &readline(
2139                         "$pidprompt $tid DB"
2140                       . ( '<' x $level )
2141                       . ( $#hist + 1 )
2142                       . ( '>' x $level ) . " "
2143                 )
2144             )
2145           )
2146         {
2147
2148                         share($cmd);
2149             # ... try to execute the input as debugger commands.
2150
2151             # Don't stop running.
2152             $single = 0;
2153
2154             # No signal is active.
2155             $signal = 0;
2156
2157             # Handle continued commands (ending with \):
2158             if ($cmd =~ s/\\\z/\n/) {
2159                 $cmd .= &readline("  cont: ");
2160                 redo CMD;
2161             }
2162
2163 =head4 The null command
2164
2165 A newline entered by itself means I<re-execute the last command>. We grab the
2166 command out of C<$laststep> (where it was recorded previously), and copy it
2167 back into C<$cmd> to be executed below. If there wasn't any previous command,
2168 we'll do nothing below (no command will match). If there was, we also save it
2169 in the command history and fall through to allow the command parsing to pick
2170 it up.
2171
2172 =cut
2173
2174             # Empty input means repeat the last command.
2175             $cmd =~ /^$/ && ( $cmd = $laststep );
2176             chomp($cmd);    # get rid of the annoying extra newline
2177             push( @hist, $cmd ) if length($cmd) > 1;
2178             push( @truehist, $cmd );
2179                         share(@hist);
2180                         share(@truehist);
2181
2182             # This is a restart point for commands that didn't arrive
2183             # via direct user input. It allows us to 'redo PIPE' to
2184             # re-execute command processing without reading a new command.
2185           PIPE: {
2186                 $cmd =~ s/^\s+//s;    # trim annoying leading whitespace
2187                 $cmd =~ s/\s+$//s;    # trim annoying trailing whitespace
2188                 my ($i) = split( /\s+/, $cmd );
2189
2190 =head3 COMMAND ALIASES
2191
2192 The debugger can create aliases for commands (these are stored in the
2193 C<%alias> hash). Before a command is executed, the command loop looks it up
2194 in the alias hash and substitutes the contents of the alias for the command,
2195 completely replacing it.
2196
2197 =cut
2198
2199                 # See if there's an alias for the command, and set it up if so.
2200                 if ( $alias{$i} ) {
2201
2202                     # Squelch signal handling; we want to keep control here
2203                     # if something goes loco during the alias eval.
2204                     local $SIG{__DIE__};
2205                     local $SIG{__WARN__};
2206
2207                     # This is a command, so we eval it in the DEBUGGER's
2208                     # scope! Otherwise, we can't see the special debugger
2209                     # variables, or get to the debugger's subs. (Well, we
2210                     # _could_, but why make it even more complicated?)
2211                     eval "\$cmd =~ $alias{$i}";
2212                     if ($@) {
2213                         local $\ = '';
2214                         print $OUT "Couldn't evaluate '$i' alias: $@";
2215                         next CMD;
2216                     }
2217                 } ## end if ($alias{$i})
2218
2219 =head3 MAIN-LINE COMMANDS
2220
2221 All of these commands work up to and after the program being debugged has
2222 terminated.
2223
2224 =head4 C<q> - quit
2225
2226 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2227 try to execute further, cleaning any restart-related stuff out of the
2228 environment, and executing with the last value of C<$?>.
2229
2230 =cut
2231
2232                 if ($cmd eq 'q') {
2233                     $fall_off_end = 1;
2234                     clean_ENV();
2235                     exit $?;
2236                 }
2237
2238 =head4 C<t> - trace [n]
2239
2240 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2241 If level is specified, set C<$trace_to_depth>.
2242
2243 =cut
2244
2245                 if (my ($levels) = $cmd =~ /\At(?:\s+(\d+))?\z/) {
2246                     $trace ^= 1;
2247                     local $\ = '';
2248                     $trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
2249                     print $OUT "Trace = "
2250                       . ( ( $trace & 1 )
2251                       ? ( $levels ? "on (to level $trace_to_depth)" : "on" )
2252                       : "off" ) . "\n";
2253                     next CMD;
2254                 }
2255
2256 =head4 C<S> - list subroutines matching/not matching a pattern
2257
2258 Walks through C<%sub>, checking to see whether or not to print the name.
2259
2260 =cut
2261
2262                 if (my ($print_all_subs, $should_reverse, $Spatt)
2263                     = $cmd =~ /\AS(\s+(!)?(.+))?\z/) {
2264                     # $Spatt is the pattern (if any) to use.
2265                     # Reverse scan?
2266                     my $Srev     = defined $should_reverse;
2267                     # No args - print all subs.
2268                     my $Snocheck = !defined $print_all_subs;
2269
2270                     # Need to make these sane here.
2271                     local $\ = '';
2272                     local $, = '';
2273
2274                     # Search through the debugger's magical hash of subs.
2275                     # If $nocheck is true, just print the sub name.
2276                     # Otherwise, check it against the pattern. We then use
2277                     # the XOR trick to reverse the condition as required.
2278                     foreach $subname ( sort( keys %sub ) ) {
2279                         if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
2280                             print $OUT $subname, "\n";
2281                         }
2282                     }
2283                     next CMD;
2284                 }
2285
2286 =head4 C<X> - list variables in current package
2287
2288 Since the C<V> command actually processes this, just change this to the
2289 appropriate C<V> command and fall through.
2290
2291 =cut
2292
2293                 $cmd =~ s/^X\b/V $package/;
2294
2295 =head4 C<V> - list variables
2296
2297 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2298
2299 =cut
2300
2301                 # Bare V commands get the currently-being-debugged package
2302                 # added.
2303                 if ($cmd eq "V") {
2304                     $cmd = "V $package";
2305                 }
2306
2307                 # V - show variables in package.
2308                 if (my ($new_packname, $new_vars_str) =
2309                     $cmd =~ /\AV\b\s*(\S+)\s*(.*)/) {
2310
2311                     # Save the currently selected filehandle and
2312                     # force output to debugger's filehandle (dumpvar
2313                     # just does "print" for output).
2314                     my $savout = select($OUT);
2315
2316                     # Grab package name and variables to dump.
2317                     $packname = $new_packname;
2318                     my @vars     = split( ' ', $new_vars_str );
2319
2320                     # If main::dumpvar isn't here, get it.
2321                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2322                     if ( defined &main::dumpvar ) {
2323
2324                         # We got it. Turn off subroutine entry/exit messages
2325                         # for the moment, along with return values.
2326                         local $frame = 0;
2327                         local $doret = -2;
2328
2329                         # must detect sigpipe failures  - not catching
2330                         # then will cause the debugger to die.
2331                         eval {
2332                             &main::dumpvar(
2333                                 $packname,
2334                                 defined $option{dumpDepth}
2335                                 ? $option{dumpDepth}
2336                                 : -1,    # assume -1 unless specified
2337                                 @vars
2338                             );
2339                         };
2340
2341                         # The die doesn't need to include the $@, because
2342                         # it will automatically get propagated for us.
2343                         if ($@) {
2344                             die unless $@ =~ /dumpvar print failed/;
2345                         }
2346                     } ## end if (defined &main::dumpvar)
2347                     else {
2348
2349                         # Couldn't load dumpvar.
2350                         print $OUT "dumpvar.pl not available.\n";
2351                     }
2352
2353                     # Restore the output filehandle, and go round again.
2354                     select($savout);
2355                     next CMD;
2356                 }
2357
2358 =head4 C<x> - evaluate and print an expression
2359
2360 Hands the expression off to C<DB::eval>, setting it up to print the value
2361 via C<dumpvar.pl> instead of just printing it directly.
2362
2363 =cut
2364
2365                 if ($cmd =~ s#\Ax\b# #) {    # Remainder gets done by DB::eval()
2366                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2367
2368                     # handle special  "x 3 blah" syntax XXX propagate
2369                     # doc back to special variables.
2370                     if ( $cmd =~ s#\A\s*(\d+)(?=\s)# #) {
2371                         $onetimedumpDepth = $1;
2372                     }
2373                 }
2374
2375 =head4 C<m> - print methods
2376
2377 Just uses C<DB::methods> to determine what methods are available.
2378
2379 =cut
2380
2381                 if ($cmd =~ s#\Am\s+([\w:]+)\s*\z# #) {
2382                     methods($1);
2383                     next CMD;
2384                 }
2385
2386                 # m expr - set up DB::eval to do the work
2387                 if ($cmd =~ s#\Am\b# #) {    # Rest gets done by DB::eval()
2388                     $onetimeDump = 'methods';   #  method output gets used there
2389                 }
2390
2391 =head4 C<f> - switch files
2392
2393 =cut
2394
2395                 if (($file) = $cmd =~ /\Af\b\s*(.*)/) {
2396                     $file =~ s/\s+$//;
2397
2398                     # help for no arguments (old-style was return from sub).
2399                     if ( !$file ) {
2400                         print $OUT
2401                           "The old f command is now the r command.\n";    # hint
2402                         print $OUT "The new f command switches filenames.\n";
2403                         next CMD;
2404                     } ## end if (!$file)
2405
2406                     # if not in magic file list, try a close match.
2407                     if ( !defined $main::{ '_<' . $file } ) {
2408                         if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
2409                             {
2410                                 $try = substr( $try, 2 );
2411                                 print $OUT "Choosing $try matching '$file':\n";
2412                                 $file = $try;
2413                             }
2414                         } ## end if (($try) = grep(m#^_<.*$file#...
2415                     } ## end if (!defined $main::{ ...
2416
2417                     # If not successfully switched now, we failed.
2418                     if ( !defined $main::{ '_<' . $file } ) {
2419                         print $OUT "No file matching '$file' is loaded.\n";
2420                         next CMD;
2421                     }
2422
2423                     # We switched, so switch the debugger internals around.
2424                     elsif ( $file ne $filename ) {
2425                         *dbline   = $main::{ '_<' . $file };
2426                         $max      = $#dbline;
2427                         $filename = $file;
2428                         $start    = 1;
2429                         $cmd      = "l";
2430                     } ## end elsif ($file ne $filename)
2431
2432                     # We didn't switch; say we didn't.
2433                     else {
2434                         print $OUT "Already in $file.\n";
2435                         next CMD;
2436                     }
2437                 }
2438
2439 =head4 C<.> - return to last-executed line.
2440
2441 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2442 and then we look up the line in the magical C<%dbline> hash.
2443
2444 =cut
2445
2446                 # . command.
2447                 if ($cmd eq '.') {
2448                     $incr = -1;    # stay at current line
2449
2450                     # Reset everything to the old location.
2451                     $start    = $line;
2452                     $filename = $filename_ini;
2453                     *dbline   = $main::{ '_<' . $filename };
2454                     $max      = $#dbline;
2455
2456                     # Now where are we?
2457                     print_lineinfo($position);
2458                     next CMD;
2459                 }
2460
2461 =head4 C<-> - back one window
2462
2463 We change C<$start> to be one window back; if we go back past the first line,
2464 we set it to be the first line. We ser C<$incr> to put us back at the
2465 currently-executing line, and then put a C<l $start +> (list one window from
2466 C<$start>) in C<$cmd> to be executed later.
2467
2468 =cut
2469
2470                 # - - back a window.
2471                 if ($cmd eq '-') {
2472
2473                     # back up by a window; go to 1 if back too far.
2474                     $start -= $incr + $window + 1;
2475                     $start = 1 if $start <= 0;
2476                     $incr  = $window - 1;
2477
2478                     # Generate and execute a "l +" command (handled below).
2479                     $cmd = 'l ' . ($start) . '+';
2480                 }
2481
2482 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, {, {{>
2483
2484 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2485 problems, most notably that the default case of several commands destroying
2486 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2487 retain the old commands for those who were used to using them or who preferred
2488 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2489 deal with them instead of processing them in-line.
2490
2491 =cut
2492
2493                 # All of these commands were remapped in perl 5.8.0;
2494                 # we send them off to the secondary dispatcher (see below).
2495                 if (my ($cmd_letter, $my_arg) = $cmd =~ /\A([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so) {
2496                     &cmd_wrapper( $cmd_letter, $my_arg, $line );
2497                     next CMD;
2498                 }
2499
2500 =head4 C<y> - List lexicals in higher scope
2501
2502 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2503 above the current one and then displays then using C<dumpvar.pl>.
2504
2505 =cut
2506
2507                 if (my ($match_level, $match_vars)
2508                     = $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/) {
2509
2510                     # See if we've got the necessary support.
2511                     eval { require PadWalker; PadWalker->VERSION(0.08) }
2512                       or &warn(
2513                         $@ =~ /locate/
2514                         ? "PadWalker module not found - please install\n"
2515                         : $@
2516                       )
2517                       and next CMD;
2518
2519                     # Load up dumpvar if we don't have it. If we can, that is.
2520                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2521                     defined &main::dumpvar
2522                       or print $OUT "dumpvar.pl not available.\n"
2523                       and next CMD;
2524
2525                     # Got all the modules we need. Find them and print them.
2526                     my @vars = split( ' ', $match_vars || '' );
2527
2528                     # Find the pad.
2529                     my $h = eval { PadWalker::peek_my( ( $match_level || 0 ) + 1 ) };
2530
2531                     # Oops. Can't find it.
2532                     $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
2533
2534                     # Show the desired vars with dumplex().
2535                     my $savout = select($OUT);
2536
2537                     # Have dumplex dump the lexicals.
2538                     dumpvar::dumplex( $_, $h->{$_},
2539                         defined $option{dumpDepth} ? $option{dumpDepth} : -1,
2540                         @vars )
2541                       for sort keys %$h;
2542                     select($savout);
2543                     next CMD;
2544                 }
2545
2546 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2547
2548 All of the commands below this point don't work after the program being
2549 debugged has ended. All of them check to see if the program has ended; this
2550 allows the commands to be relocated without worrying about a 'line of
2551 demarcation' above which commands can be entered anytime, and below which
2552 they can't.
2553
2554 =head4 C<n> - single step, but don't trace down into subs
2555
2556 Done by setting C<$single> to 2, which forces subs to execute straight through
2557 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2558 so a null command knows what to re-execute.
2559
2560 =cut
2561
2562                 # n - next
2563                 if ($cmd eq 'n') {
2564                     end_report(), next CMD if $finished and $level <= 1;
2565
2566                     # Single step, but don't enter subs.
2567                     $single = 2;
2568
2569                     # Save for empty command (repeat last).
2570                     $laststep = $cmd;
2571                     last CMD;
2572                 }
2573
2574 =head4 C<s> - single-step, entering subs
2575
2576 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2577 subs. Also saves C<s> as C<$lastcmd>.
2578
2579 =cut
2580
2581                 # s - single step.
2582                 if ($cmd eq 's') {
2583
2584                     # Get out and restart the command loop if program
2585                     # has finished.
2586                     end_report(), next CMD if $finished and $level <= 1;
2587
2588                     # Single step should enter subs.
2589                     $single = 1;
2590
2591                     # Save for empty command (repeat last).
2592                     $laststep = $cmd;
2593                     last CMD;
2594                 }
2595
2596 =head4 C<c> - run continuously, setting an optional breakpoint
2597
2598 Most of the code for this command is taken up with locating the optional
2599 breakpoint, which is either a subroutine name or a line number. We set
2600 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2601 in this and all call levels above this one.
2602
2603 =cut
2604
2605                 # c - start continuous execution.
2606                 if (($i) = $cmd =~ m#\Ac\b\s*([\w:]*)\s*\z#) {
2607
2608                     # Hey, show's over. The debugged program finished
2609                     # executing already.
2610                     end_report(), next CMD if $finished and $level <= 1;
2611
2612                     # Capture the place to put a one-time break.
2613                     $subname = $i;
2614
2615                     #  Probably not needed, since we finish an interactive
2616                     #  sub-session anyway...
2617                     # local $filename = $filename;
2618                     # local *dbline = *dbline; # XXX Would this work?!
2619                     #
2620                     # The above question wonders if localizing the alias
2621                     # to the magic array works or not. Since it's commented
2622                     # out, we'll just leave that to speculation for now.
2623
2624                     # If the "subname" isn't all digits, we'll assume it
2625                     # is a subroutine name, and try to find it.
2626                     if ( $subname =~ /\D/ ) {    # subroutine name
2627                             # Qualify it to the current package unless it's
2628                             # already qualified.
2629                         $subname = $package . "::" . $subname
2630                           unless $subname =~ /::/;
2631
2632                         # find_sub will return "file:line_number" corresponding
2633                         # to where the subroutine is defined; we call find_sub,
2634                         # break up the return value, and assign it in one
2635                         # operation.
2636                         ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2637
2638                         # Force the line number to be numeric.
2639                         $i += 0;
2640
2641                         # If we got a line number, we found the sub.
2642                         if ($i) {
2643
2644                             # Switch all the debugger's internals around so
2645                             # we're actually working with that file.
2646                             $filename = $file;
2647                             *dbline   = $main::{ '_<' . $filename };
2648
2649                             # Mark that there's a breakpoint in this file.
2650                             $had_breakpoints{$filename} |= 1;
2651
2652                             # Scan forward to the first executable line
2653                             # after the 'sub whatever' line.
2654                             $max = $#dbline;
2655                             ++$i while $dbline[$i] == 0 && $i < $max;
2656                         } ## end if ($i)
2657
2658                         # We didn't find a sub by that name.
2659                         else {
2660                             print $OUT "Subroutine $subname not found.\n";
2661                             next CMD;
2662                         }
2663                     } ## end if ($subname =~ /\D/)
2664
2665                     # At this point, either the subname was all digits (an
2666                     # absolute line-break request) or we've scanned through
2667                     # the code following the definition of the sub, looking
2668                     # for an executable, which we may or may not have found.
2669                     #
2670                     # If $i (which we set $subname from) is non-zero, we
2671                     # got a request to break at some line somewhere. On
2672                     # one hand, if there wasn't any real subroutine name
2673                     # involved, this will be a request to break in the current
2674                     # file at the specified line, so we have to check to make
2675                     # sure that the line specified really is breakable.
2676                     #
2677                     # On the other hand, if there was a subname supplied, the
2678                     # preceding block has moved us to the proper file and
2679                     # location within that file, and then scanned forward
2680                     # looking for the next executable line. We have to make
2681                     # sure that one was found.
2682                     #
2683                     # On the gripping hand, we can't do anything unless the
2684                     # current value of $i points to a valid breakable line.
2685                     # Check that.
2686                     if ($i) {
2687
2688                         # Breakable?
2689                         if ( $dbline[$i] == 0 ) {
2690                             print $OUT "Line $i not breakable.\n";
2691                             next CMD;
2692                         }
2693
2694                         # Yes. Set up the one-time-break sigil.
2695                         $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2696                         _enable_breakpoint_temp_enabled_status($filename, $i);
2697                     } ## end if ($i)
2698
2699                     # Turn off stack tracing from here up.
2700                     for my $i (0 .. $stack_depth) {
2701                         $stack[ $i ] &= ~1;
2702                     }
2703                     last CMD;
2704                 }
2705
2706 =head4 C<r> - return from a subroutine
2707
2708 For C<r> to work properly, the debugger has to stop execution again
2709 immediately after the return is executed. This is done by forcing
2710 single-stepping to be on in the call level above the current one. If
2711 we are printing return values when a C<r> is executed, set C<$doret>
2712 appropriately, and force us out of the command loop.
2713
2714 =cut
2715
2716                 # r - return from the current subroutine.
2717                 if ($cmd eq 'r') {
2718
2719                     # Can't do anything if the program's over.
2720                     end_report(), next CMD if $finished and $level <= 1;
2721
2722                     # Turn on stack trace.
2723                     $stack[$stack_depth] |= 1;
2724
2725                     # Print return value unless the stack is empty.
2726                     $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
2727                     last CMD;
2728                 }
2729
2730 =head4 C<T> - stack trace
2731
2732 Just calls C<DB::print_trace>.
2733
2734 =cut
2735
2736                 if ($cmd eq 'T') {
2737                     print_trace( $OUT, 1 );    # skip DB
2738                     next CMD;
2739                 }
2740
2741 =head4 C<w> - List window around current line.
2742
2743 Just calls C<DB::cmd_w>.
2744
2745 =cut
2746
2747                 if (my ($arg) = $cmd =~ /\Aw\b\s*(.*)/s) {
2748                     &cmd_w( 'w', $arg );
2749                     next CMD;
2750                 }
2751
2752 =head4 C<W> - watch-expression processing.
2753
2754 Just calls C<DB::cmd_W>.
2755
2756 =cut
2757
2758                 if (my ($arg) = $cmd =~ /\AW\b\s*(.*)/s) {
2759                     &cmd_W( 'W', $arg );
2760                     next CMD;
2761                 }
2762
2763 =head4 C</> - search forward for a string in the source
2764
2765 We take the argument and treat it as a pattern. If it turns out to be a
2766 bad one, we return the error we got from trying to C<eval> it and exit.
2767 If not, we create some code to do the search and C<eval> it so it can't
2768 mess us up.
2769
2770 =cut
2771
2772                 # The pattern as a string.
2773                 use vars qw($inpat);
2774
2775                 if (($inpat) = $cmd =~ m#\A/(.*)\z#) {
2776
2777                     # Remove the final slash.
2778                     $inpat =~ s:([^\\])/$:$1:;
2779
2780                     # If the pattern isn't null ...
2781                     if ( $inpat ne "" ) {
2782
2783                         # Turn of warn and die procesing for a bit.
2784                         local $SIG{__DIE__};
2785                         local $SIG{__WARN__};
2786
2787                         # Create the pattern.
2788                         eval '$inpat =~ m' . "\a$inpat\a";
2789                         if ( $@ ne "" ) {
2790
2791                             # Oops. Bad pattern. No biscuit.
2792                             # Print the eval error and go back for more
2793                             # commands.
2794                             print $OUT "$@";
2795                             next CMD;
2796                         }
2797                         $pat = $inpat;
2798                     } ## end if ($inpat ne "")
2799
2800                     # Set up to stop on wrap-around.
2801                     $end = $start;
2802
2803                     # Don't move off the current line.
2804                     $incr = -1;
2805
2806                     # Done in eval so nothing breaks if the pattern
2807                     # does something weird.
2808                     eval '
2809                         for (;;) {
2810                             # Move ahead one line.
2811                             ++$start;
2812
2813                             # Wrap if we pass the last line.
2814                             $start = 1 if ($start > $max);
2815
2816                             # Stop if we have gotten back to this line again,
2817                             last if ($start == $end);
2818
2819                             # A hit! (Note, though, that we are doing
2820                             # case-insensitive matching. Maybe a qr//
2821                             # expression would be better, so the user could
2822                             # do case-sensitive matching if desired.
2823                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2824                                 if ($slave_editor) {
2825                                     # Handle proper escaping in the slave.
2826                                     print $OUT "\032\032$filename:$start:0\n";
2827                                 }
2828                                 else {
2829                                     # Just print the line normally.
2830                                     print $OUT "$start:\t",$dbline[$start],"\n";
2831                                 }
2832                                 # And quit since we found something.
2833                                 last;
2834                             }
2835                          } ';
2836
2837                     # If we wrapped, there never was a match.
2838                     print $OUT "/$pat/: not found\n" if ( $start == $end );
2839                     next CMD;
2840                 }
2841
2842 =head4 C<?> - search backward for a string in the source
2843
2844 Same as for C</>, except the loop runs backwards.
2845
2846 =cut
2847
2848                 # ? - backward pattern search.
2849                 if (my ($inpat) = $cmd =~ m#\A\?(.*)\z#) {
2850
2851                     # Get the pattern, remove trailing question mark.
2852                     $inpat =~ s:([^\\])\?$:$1:;
2853
2854                     # If we've got one ...
2855                     if ( $inpat ne "" ) {
2856
2857                         # Turn off die & warn handlers.
2858                         local $SIG{__DIE__};
2859                         local $SIG{__WARN__};
2860                         eval '$inpat =~ m' . "\a$inpat\a";
2861
2862                         if ( $@ ne "" ) {
2863
2864                             # Ouch. Not good. Print the error.
2865                             print $OUT $@;
2866                             next CMD;
2867                         }
2868                         $pat = $inpat;
2869                     } ## end if ($inpat ne "")
2870
2871                     # Where we are now is where to stop after wraparound.
2872                     $end = $start;
2873
2874                     # Don't move away from this line.
2875                     $incr = -1;
2876
2877                     # Search inside the eval to prevent pattern badness
2878                     # from killing us.
2879                     eval '
2880                         for (;;) {
2881                             # Back up a line.
2882                             --$start;
2883
2884                             # Wrap if we pass the first line.
2885
2886                             $start = $max if ($start <= 0);
2887
2888                             # Quit if we get back where we started,
2889                             last if ($start == $end);
2890
2891                             # Match?
2892                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2893                                 if ($slave_editor) {
2894                                     # Yep, follow slave editor requirements.
2895                                     print $OUT "\032\032$filename:$start:0\n";
2896                                 }
2897                                 else {
2898                                     # Yep, just print normally.
2899                                     print $OUT "$start:\t",$dbline[$start],"\n";
2900                                 }
2901
2902                                 # Found, so done.
2903                                 last;
2904                             }
2905                         } ';
2906
2907                     # Say we failed if the loop never found anything,
2908                     print $OUT "?$pat?: not found\n" if ( $start == $end );
2909                     next CMD;
2910                 }
2911
2912 =head4 C<$rc> - Recall command
2913
2914 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2915 that the terminal supports history). It find the the command required, puts it
2916 into C<$cmd>, and redoes the loop to execute it.
2917
2918 =cut
2919
2920                 # $rc - recall command.
2921                 if (my ($minus, $arg) = $cmd =~ m#\A$rc+\s*(-)?(\d+)?\z#) {
2922
2923                     # No arguments, take one thing off history.
2924                     pop(@hist) if length($cmd) > 1;
2925
2926                     # Relative (- found)?
2927                     #  Y - index back from most recent (by 1 if bare minus)
2928                     #  N - go to that particular command slot or the last
2929                     #      thing if nothing following.
2930                     $i = $minus ? ( $#hist - ( $arg || 1 ) ) : ( $arg || $#hist );
2931
2932                     # Pick out the command desired.
2933                     $cmd = $hist[$i];
2934
2935                     # Print the command to be executed and restart the loop
2936                     # with that command in the buffer.
2937                     print $OUT $cmd, "\n";
2938                     redo CMD;
2939                 }
2940
2941 =head4 C<$sh$sh> - C<system()> command
2942
2943 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
2944 C<STDOUT> from getting messed up.
2945
2946 =cut
2947
2948                 # $sh$sh - run a shell command (if it's all ASCII).
2949                 # Can't run shell commands with Unicode in the debugger, hmm.
2950                 if (my ($arg) = $cmd =~ m#\A$sh$sh\s*(.*)#ms) {
2951
2952                     # System it.
2953                     &system($arg);
2954                     next CMD;
2955                 }
2956
2957 =head4 C<$rc I<pattern> $rc> - Search command history
2958
2959 Another command to manipulate C<@hist>: this one searches it with a pattern.
2960 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
2961
2962 =cut
2963
2964                 # $rc pattern $rc - find a command in the history.
2965                 if (my ($arg) = $cmd =~ /\A$rc([^$rc].*)\z/) {
2966
2967                     # Create the pattern to use.
2968                     $pat = "^$arg";
2969
2970                     # Toss off last entry if length is >1 (and it always is).
2971                     pop(@hist) if length($cmd) > 1;
2972
2973                     # Look backward through the history.
2974                     for ( $i = $#hist ; $i ; --$i ) {
2975                         # Stop if we find it.
2976                         last if $hist[$i] =~ /$pat/;
2977                     }
2978
2979                     if ( !$i ) {
2980
2981                         # Never found it.
2982                         print $OUT "No such command!\n\n";
2983                         next CMD;
2984                     }
2985
2986                     # Found it. Put it in the buffer, print it, and process it.
2987                     $cmd = $hist[$i];
2988                     print $OUT $cmd, "\n";
2989                     redo CMD;
2990                 }
2991
2992 =head4 C<$sh> - Invoke a shell
2993
2994 Uses C<DB::system> to invoke a shell.
2995
2996 =cut
2997
2998                 # $sh - start a shell.
2999                 if ($cmd =~ /\A$sh\z/) {
3000
3001                     # Run the user's shell. If none defined, run Bourne.
3002                     # We resume execution when the shell terminates.
3003                     &system( $ENV{SHELL} || "/bin/sh" );
3004                     next CMD;
3005                 }
3006
3007 =head4 C<$sh I<command>> - Force execution of a command in a shell
3008
3009 Like the above, but the command is passed to the shell. Again, we use
3010 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
3011
3012 =cut
3013
3014                 # $sh command - start a shell and run a command in it.
3015                 if (my ($arg) = $cmd =~ m#\A$sh\s*(.*)#ms) {
3016
3017                     # XXX: using csh or tcsh destroys sigint retvals!
3018                     #&system($1);  # use this instead
3019
3020                     # use the user's shell, or Bourne if none defined.
3021                     &system( $ENV{SHELL} || "/bin/sh", "-c", $arg );
3022                     next CMD;
3023                 }
3024
3025 =head4 C<H> - display commands in history
3026
3027 Prints the contents of C<@hist> (if any).
3028
3029 =cut
3030
3031                 if ($cmd =~ /\AH\b\s*\*/) {
3032                     @hist = @truehist = ();
3033                     print $OUT "History cleansed\n";
3034                     next CMD;
3035                 }
3036
3037                 if (my ($num)
3038                     = $cmd =~ /\AH\b\s*(?:-(\d+))?/) {
3039
3040                     # Anything other than negative numbers is ignored by
3041                     # the (incorrect) pattern, so this test does nothing.
3042                     $end = $num ? ( $#hist - $num ) : 0;
3043
3044                     # Set to the minimum if less than zero.
3045                     $hist = 0 if $hist < 0;
3046
3047                     # Start at the end of the array.
3048                     # Stay in while we're still above the ending value.
3049                     # Tick back by one each time around the loop.
3050                     for ( $i = $#hist ; $i > $end ; $i-- ) {
3051
3052                         # Print the command  unless it has no arguments.
3053                         print $OUT "$i: ", $hist[$i], "\n"
3054                           unless $hist[$i] =~ /^.?$/;
3055                     }
3056                     next CMD;
3057                 }
3058
3059 =head4 C<man, doc, perldoc> - look up documentation
3060
3061 Just calls C<runman()> to print the appropriate document.
3062
3063 =cut
3064
3065                 # man, perldoc, doc - show manual pages.
3066                 if (my ($man_page)
3067                     = $cmd =~ /\A(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?\z/) {
3068                     runman($man_page);
3069                     next CMD;
3070                 }
3071
3072 =head4 C<p> - print
3073
3074 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
3075 the bottom of the loop.
3076
3077 =cut
3078
3079                 my $print_cmd = 'print {$DB::OUT} ';
3080                 # p - print (no args): print $_.
3081                 if ($cmd eq 'p') {
3082                     $cmd = $print_cmd . '$_';
3083                 }
3084
3085                 # p - print the given expression.
3086                 $cmd =~ s/\Ap\b/$print_cmd /;
3087
3088 =head4 C<=> - define command alias
3089
3090 Manipulates C<%alias> to add or list command aliases.
3091
3092 =cut
3093
3094                 # = - set up a command alias.
3095                 if ($cmd =~ s/\A=\s*//) {
3096                     my @keys;
3097                     if ( length $cmd == 0 ) {
3098
3099                         # No args, get current aliases.
3100                         @keys = sort keys %alias;
3101                     }
3102                     elsif ( my ( $k, $v ) = ( $cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3103
3104                         # Creating a new alias. $k is alias name, $v is
3105                         # alias value.
3106
3107                         # can't use $_ or kill //g state
3108                         for my $x ( $k, $v ) {
3109
3110                             # Escape "alarm" characters.
3111                             $x =~ s/\a/\\a/g;
3112                         }
3113
3114                         # Substitute key for value, using alarm chars
3115                         # as separators (which is why we escaped them in
3116                         # the command).
3117                         $alias{$k} = "s\a$k\a$v\a";
3118
3119                         # Turn off standard warn and die behavior.
3120                         local $SIG{__DIE__};
3121                         local $SIG{__WARN__};
3122
3123                         # Is it valid Perl?
3124                         unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3125
3126                             # Nope. Bad alias. Say so and get out.
3127                             print $OUT "Can't alias $k to $v: $@\n";
3128                             delete $alias{$k};
3129                             next CMD;
3130                         }
3131
3132                         # We'll only list the new one.
3133                         @keys = ($k);
3134                     } ## end elsif (my ($k, $v) = ($cmd...
3135
3136                     # The argument is the alias to list.
3137                     else {
3138                         @keys = ($cmd);
3139                     }
3140
3141                     # List aliases.
3142                     for my $k (@keys) {
3143
3144                         # Messy metaquoting: Trim the substitution code off.
3145                         # We use control-G as the delimiter because it's not
3146                         # likely to appear in the alias.
3147                         if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3148
3149                             # Print the alias.
3150                             print $OUT "$k\t= $1\n";
3151                         }
3152                         elsif ( defined $alias{$k} ) {
3153
3154                             # Couldn't trim it off; just print the alias code.
3155                             print $OUT "$k\t$alias{$k}\n";
3156                         }
3157                         else {
3158
3159                             # No such, dude.
3160                             print "No alias for $k\n";
3161                         }
3162                     } ## end for my $k (@keys)
3163                     next CMD;
3164                 }
3165
3166 =head4 C<source> - read commands from a file.
3167
3168 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3169 pick it up.
3170
3171 =cut
3172
3173                 # source - read commands from a file (or pipe!) and execute.
3174                 if (my ($sourced_fn) = $cmd =~ /\Asource\s+(.*\S)/) {
3175                     if ( open my $fh, $sourced_fn ) {
3176
3177                         # Opened OK; stick it in the list of file handles.
3178                         push @cmdfhs, $fh;
3179                     }
3180                     else {
3181
3182                         # Couldn't open it.
3183                         &warn("Can't execute '$sourced_fn': $!\n");
3184                     }
3185                     next CMD;
3186                 }
3187
3188                 if (my ($which_cmd, $position)
3189                     = $cmd =~ /^(enable|disable)\s+(\S+)\s*$/) {
3190
3191                     my ($fn, $line_num);
3192                     if ($position =~ m{\A\d+\z})
3193                     {
3194                         $fn = $filename;
3195                         $line_num = $position;
3196                     }
3197                     elsif (my ($new_fn, $new_line_num)
3198                         = $position =~ m{\A(.*):(\d+)\z}) {
3199                         ($fn, $line_num) = ($new_fn, $new_line_num);
3200                     }
3201                     else
3202                     {
3203                         &warn("Wrong spec for enable/disable argument.\n");
3204                     }
3205
3206                     if (defined($fn)) {
3207                         if (_has_breakpoint_data_ref($fn, $line_num)) {
3208                             _set_breakpoint_enabled_status($fn, $line_num,
3209                                 ($which_cmd eq 'enable' ? 1 : '')
3210                             );
3211                         }
3212                         else {
3213                             &warn("No breakpoint set at ${fn}:${line_num}\n");
3214                         }
3215                     }
3216
3217                     next CMD;
3218                 }
3219
3220 =head4 C<save> - send current history to a file
3221
3222 Takes the complete history, (not the shrunken version you see with C<H>),
3223 and saves it to the given filename, so it can be replayed using C<source>.
3224
3225 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3226
3227 =cut
3228
3229                 # save source - write commands to a file for later use
3230                 if (my ($new_fn) = $cmd =~ /\Asave\s*(.*)\z/) {
3231                     my $filename = $new_fn || '.perl5dbrc';    # default?
3232                     if ( open my $fh, '>', $filename ) {
3233
3234                        # chomp to remove extraneous newlines from source'd files
3235                         chomp( my @truelist =
3236                               map { m/^\s*(save|source)/ ? "#$_" : $_ }
3237                               @truehist );
3238                         print $fh join( "\n", @truelist );
3239                         print "commands saved in $file\n";
3240                     }
3241                     else {
3242                         &warn("Can't save debugger commands in '$new_fn': $!\n");
3243                     }
3244                     next CMD;
3245                 }
3246
3247 =head4 C<R> - restart
3248
3249 Restart the debugger session.
3250
3251 =head4 C<rerun> - rerun the current session
3252
3253 Return to any given position in the B<true>-history list
3254
3255 =cut
3256
3257                 # R - restart execution.
3258                 # rerun - controlled restart execution.
3259                 if (my ($cmd_cmd, $cmd_params) =
3260                     $cmd =~ /\A((?:R)|(?:rerun\s*(.*)))\z/) {
3261                     my @args = ($cmd_cmd eq 'R' ? restart() : rerun($cmd_params));
3262
3263                     # Close all non-system fds for a clean restart.  A more
3264                     # correct method would be to close all fds that were not
3265                     # open when the process started, but this seems to be
3266                     # hard.  See "debugger 'R'estart and open database
3267                     # connections" on p5p.
3268
3269                     my $max_fd = 1024; # default if POSIX can't be loaded
3270                     if (eval { require POSIX }) {
3271                         eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
3272                     }
3273
3274                     if (defined $max_fd) {
3275                         foreach ($^F+1 .. $max_fd-1) {
3276                             next unless open FD_TO_CLOSE, "<&=$_";
3277                             close(FD_TO_CLOSE);
3278                         }
3279                     }
3280
3281                     # And run Perl again.  We use exec() to keep the
3282                     # PID stable (and that way $ini_pids is still valid).
3283                     exec(@args) || print $OUT "exec failed: $!\n";
3284
3285                     last CMD;
3286                 }
3287
3288 =head4 C<|, ||> - pipe output through the pager.
3289
3290 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3291 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3292 pipe to the pager (restoring the output filehandles if this fails). If this
3293 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3294 set C<$signal>, sending us back into the debugger.
3295
3296 We then trim off the pipe symbols and C<redo> the command loop at the
3297 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3298 reading another.
3299
3300 =cut
3301
3302                 # || - run command in the pager, with output to DB::OUT.
3303                 if ($cmd =~ m#\A\|\|?\s*[^|]#) {
3304                     if ( $pager =~ /^\|/ ) {
3305
3306                         # Default pager is into a pipe. Redirect I/O.
3307                         open( SAVEOUT, ">&STDOUT" )
3308                           || &warn("Can't save STDOUT");
3309                         open( STDOUT, ">&OUT" )
3310                           || &warn("Can't redirect STDOUT");
3311                     } ## end if ($pager =~ /^\|/)
3312                     else {
3313
3314                         # Not into a pipe. STDOUT is safe.
3315                         open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
3316                     }
3317
3318                     # Fix up environment to record we have less if so.
3319                     fix_less();
3320
3321                     unless ( $piped = open( OUT, $pager ) ) {
3322
3323                         # Couldn't open pipe to pager.
3324                         &warn("Can't pipe output to '$pager'");
3325                         if ( $pager =~ /^\|/ ) {
3326
3327                             # Redirect I/O back again.
3328                             open( OUT, ">&STDOUT" )    # XXX: lost message
3329                               || &warn("Can't restore DB::OUT");
3330                             open( STDOUT, ">&SAVEOUT" )
3331                               || &warn("Can't restore STDOUT");
3332                             close(SAVEOUT);
3333                         } ## end if ($pager =~ /^\|/)
3334                         else {
3335
3336                             # Redirect I/O. STDOUT already safe.
3337                             open( OUT, ">&STDOUT" )    # XXX: lost message
3338                               || &warn("Can't restore DB::OUT");
3339                         }
3340                         next CMD;
3341                     } ## end unless ($piped = open(OUT,...
3342
3343                     # Set up broken-pipe handler if necessary.
3344                     $SIG{PIPE} = \&DB::catch
3345                       if $pager =~ /^\|/
3346                       && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
3347
3348                     OUT->autoflush(1);
3349                     # Save current filehandle, and put it back.
3350                     $selected = select(OUT);
3351                     # Don't put it back if pager was a pipe.
3352                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
3353
3354                     # Trim off the pipe symbols and run the command now.
3355                     $cmd =~ s#\A\|+\s*##;
3356                     redo PIPE;
3357                 }
3358
3359 =head3 END OF COMMAND PARSING
3360
3361 Anything left in C<$cmd> at this point is a Perl expression that we want to
3362 evaluate. We'll always evaluate in the user's context, and fully qualify
3363 any variables we might want to address in the C<DB> package.
3364
3365 =cut
3366
3367                 # t - turn trace on.
3368                 if ($cmd =~ s#\At\s+(\d+)?#\$DB::trace |= 1;\n#) {
3369                     my $trace_arg = $1;
3370                     $trace_to_depth = $trace_arg ? $stack_depth||0 + $1 : 1E9;
3371                 }
3372
3373                 # s - single-step. Remember the last command was 's'.
3374                 if ($cmd =~ s/\As\s/\$DB::single = 1;\n/) {
3375                     $laststep = 's';
3376                 }
3377
3378                 # n - single-step, but not into subs. Remember last command
3379                 # was 'n'.
3380                 if ($cmd =~ s#\An\s#\$DB::single = 2;\n#) {
3381                     $laststep = 'n';
3382                 }
3383
3384             }    # PIPE:
3385
3386             # Make sure the flag that says "the debugger's running" is
3387             # still on, to make sure we get control again.
3388             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3389
3390             # Run *our* eval that executes in the caller's context.
3391             &eval;
3392
3393             # Turn off the one-time-dump stuff now.
3394             if ($onetimeDump) {
3395                 $onetimeDump      = undef;
3396                 $onetimedumpDepth = undef;
3397             }
3398             elsif ( $term_pid == $$ ) {
3399                 eval {          # May run under miniperl, when not available...
3400                     STDOUT->flush();
3401                     STDERR->flush();
3402                 };
3403
3404                 # XXX If this is the master pid, print a newline.
3405                 print $OUT "\n";
3406             }
3407         } ## end while (($term || &setterm...
3408
3409 =head3 POST-COMMAND PROCESSING
3410
3411 After each command, we check to see if the command output was piped anywhere.
3412 If so, we go through the necessary code to unhook the pipe and go back to
3413 our standard filehandles for input and output.
3414
3415 =cut
3416
3417         continue {    # CMD:
3418
3419             # At the end of every command:
3420             if ($piped) {
3421
3422                 # Unhook the pipe mechanism now.
3423                 if ( $pager =~ /^\|/ ) {
3424
3425                     # No error from the child.
3426                     $? = 0;
3427
3428                     # we cannot warn here: the handle is missing --tchrist
3429                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3430
3431                     # most of the $? crud was coping with broken cshisms
3432                     # $? is explicitly set to 0, so this never runs.
3433                     if ($?) {
3434                         print SAVEOUT "Pager '$pager' failed: ";
3435                         if ( $? == -1 ) {
3436                             print SAVEOUT "shell returned -1\n";
3437                         }
3438                         elsif ( $? >> 8 ) {
3439                             print SAVEOUT ( $? & 127 )
3440                               ? " (SIG#" . ( $? & 127 ) . ")"
3441                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3442                         }
3443                         else {
3444                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3445                         }
3446                     } ## end if ($?)
3447
3448                     # Reopen filehandle for our output (if we can) and
3449                     # restore STDOUT (if we can).
3450                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3451                     open( STDOUT, ">&SAVEOUT" )
3452                       || &warn("Can't restore STDOUT");
3453
3454                     # Turn off pipe exception handler if necessary.
3455                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3456
3457                     # Will stop ignoring SIGPIPE if done like nohup(1)
3458                     # does SIGINT but Perl doesn't give us a choice.
3459                 } ## end if ($pager =~ /^\|/)
3460                 else {
3461
3462                     # Non-piped "pager". Just restore STDOUT.
3463                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3464                 }
3465
3466                 # Close filehandle pager was using, restore the normal one
3467                 # if necessary,
3468                 close(SAVEOUT);
3469                 select($selected), $selected = "" unless $selected eq "";
3470
3471                 # No pipes now.
3472                 $piped = "";
3473             } ## end if ($piped)
3474         }    # CMD:
3475
3476 =head3 COMMAND LOOP TERMINATION
3477
3478 When commands have finished executing, we come here. If the user closed the
3479 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3480 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3481 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3482 The interpreter will then execute the next line and then return control to us
3483 again.
3484
3485 =cut
3486
3487         # No more commands? Quit.
3488         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3489
3490         # Evaluate post-prompt commands.
3491         foreach $evalarg (@$post) {
3492             &eval;
3493         }
3494     }    # if ($single || $signal)
3495
3496     # Put the user's globals back where you found them.
3497     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3498     ();
3499 } ## end sub DB
3500
3501 # The following code may be executed now:
3502 # BEGIN {warn 4}
3503
3504 =head2 sub
3505
3506 C<sub> is called whenever a subroutine call happens in the program being
3507 debugged. The variable C<$DB::sub> contains the name of the subroutine
3508 being called.
3509
3510 The core function of this subroutine is to actually call the sub in the proper
3511 context, capturing its output. This of course causes C<DB::DB> to get called
3512 again, repeating until the subroutine ends and returns control to C<DB::sub>
3513 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3514 return value, and returns its captured copy of the return value as its own
3515 return value. The value then feeds back into the program being debugged as if
3516 C<DB::sub> hadn't been there at all.
3517
3518 C<sub> does all the work of printing the subroutine entry and exit messages
3519 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3520 and also prints the return value if needed (for the C<r> command and if
3521 the 16 bit is set in C<$frame>).
3522
3523 It also tracks the subroutine call depth by saving the current setting of
3524 C<$single> in the C<@stack> package global; if this exceeds the value in
3525 C<$deep>, C<sub> automatically turns on printing of the current depth by
3526 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3527 of stop/don't stop on entry to subs set as it currently is set.
3528
3529 =head3 C<caller()> support
3530
3531 If C<caller()> is called from the package C<DB>, it provides some
3532 additional data, in the following order:
3533
3534 =over 4
3535
3536 =item * C<$package>
3537
3538 The package name the sub was in
3539
3540 =item * C<$filename>
3541
3542 The filename it was defined in
3543
3544 =item * C<$line>
3545
3546 The line number it was defined on
3547
3548 =item * C<$subroutine>
3549
3550 The subroutine name; C<(eval)> if an C<eval>().
3551
3552 =item * C<$hasargs>
3553
3554 1 if it has arguments, 0 if not
3555
3556 =item * C<$wantarray>
3557
3558 1 if array context, 0 if scalar context
3559
3560 =item * C<$evaltext>
3561
3562 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3563
3564 =item * C<$is_require>
3565
3566 frame was created by a C<use> or C<require> statement
3567
3568 =item * C<$hints>
3569
3570 pragma information; subject to change between versions
3571
3572 =item * C<$bitmask>
3573
3574 pragma information; subject to change between versions
3575
3576 =item * C<@DB::args>
3577
3578 arguments with which the subroutine was invoked
3579
3580 =back
3581
3582 =cut
3583
3584 use vars qw($deep);
3585
3586 # We need to fully qualify the name ("DB::sub") to make "use strict;"
3587 # happy. -- Shlomi Fish
3588 sub DB::sub {
3589         # Do not use a regex in this subroutine -> results in corrupted memory
3590         # See: [perl #66110]
3591
3592         # lock ourselves under threads
3593         lock($DBGR);
3594
3595     # Whether or not the autoloader was running, a scalar to put the
3596     # sub's return value in (if needed), and an array to put the sub's
3597     # return value in (if needed).
3598     my ( $al, $ret, @ret ) = "";
3599         if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
3600                 print "creating new thread\n";
3601         }
3602
3603     # If the last ten characters are '::AUTOLOAD', note we've traced
3604     # into AUTOLOAD for $sub.
3605     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3606         no strict 'refs';
3607         $al = " for $$sub" if defined $$sub;
3608     }
3609
3610     # We stack the stack pointer and then increment it to protect us
3611     # from a situation that might unwind a whole bunch of call frames
3612     # at once. Localizing the stack pointer means that it will automatically
3613     # unwind the same amount when multiple stack frames are unwound.
3614     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3615
3616     # Expand @stack.
3617     $#stack = $stack_depth;
3618
3619     # Save current single-step setting.
3620     $stack[-1] = $single;
3621
3622     # Turn off all flags except single-stepping.
3623     $single &= 1;
3624
3625     # If we've gotten really deeply recursed, turn on the flag that will
3626     # make us stop with the 'deep recursion' message.
3627     $single |= 4 if $stack_depth == $deep;
3628
3629     # If frame messages are on ...
3630     (
3631         $frame & 4    # Extended frame entry message
3632         ? (
3633             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3634
3635             # Why -1? But it works! :-(
3636             # Because print_trace will call add 1 to it and then call
3637             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3638             # in dump_trace.
3639             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3640           )
3641         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3642
3643           # standard frame entry message
3644       )
3645       if $frame;
3646
3647     # Determine the sub's return type, and capture appropriately.
3648     if (wantarray) {
3649
3650         # Called in array context. call sub and capture output.
3651         # DB::DB will recursively get control again if appropriate; we'll come
3652         # back here when the sub is finished.
3653         {
3654             no strict 'refs';
3655             @ret = &$sub;
3656         }
3657
3658         # Pop the single-step value back off the stack.
3659         $single |= $stack[ $stack_depth-- ];
3660
3661         # Check for exit trace messages...
3662         (
3663             $frame & 4    # Extended exit message
3664             ? (
3665                 print_lineinfo( ' ' x $stack_depth, "out " ),
3666                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3667               )
3668             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3669
3670               # Standard exit message
3671           )
3672           if $frame & 2;
3673
3674         # Print the return info if we need to.
3675         if ( $doret eq $stack_depth or $frame & 16 ) {
3676
3677             # Turn off output record separator.
3678             local $\ = '';
3679             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3680
3681             # Indent if we're printing because of $frame tracing.
3682             print $fh ' ' x $stack_depth if $frame & 16;
3683
3684             # Print the return value.
3685             print $fh "list context return from $sub:\n";
3686             dumpit( $fh, \@ret );
3687
3688             # And don't print it again.
3689             $doret = -2;
3690         } ## end if ($doret eq $stack_depth...
3691             # And we have to return the return value now.
3692         @ret;
3693     } ## end if (wantarray)
3694
3695     # Scalar context.
3696     else {
3697         if ( defined wantarray ) {
3698         no strict 'refs';
3699             # Save the value if it's wanted at all.
3700             $ret = &$sub;
3701         }
3702         else {
3703         no strict 'refs';
3704             # Void return, explicitly.
3705             &$sub;
3706             undef $ret;
3707         }
3708
3709         # Pop the single-step value off the stack.
3710         $single |= $stack[ $stack_depth-- ];
3711
3712         # If we're doing exit messages...
3713         (
3714             $frame & 4    # Extended messages
3715             ? (
3716                 print_lineinfo( ' ' x $stack_depth, "out " ),
3717                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3718               )
3719             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3720
3721               # Standard messages
3722           )
3723           if $frame & 2;
3724
3725         # If we are supposed to show the return value... same as before.
3726         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
3727             local $\ = '';
3728             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3729             print $fh ( ' ' x $stack_depth ) if $frame & 16;
3730             print $fh (
3731                 defined wantarray
3732                 ? "scalar context return from $sub: "
3733                 : "void context return from $sub\n"
3734             );
3735             dumpit( $fh, $ret ) if defined wantarray;
3736             $doret = -2;
3737         } ## end if ($doret eq $stack_depth...
3738
3739         # Return the appropriate scalar value.
3740         $ret;
3741     } ## end else [ if (wantarray)
3742 } ## end sub _sub
3743
3744 sub lsub : lvalue {
3745
3746     no strict 'refs';
3747
3748         # lock ourselves under threads
3749         lock($DBGR);
3750
3751     # Whether or not the autoloader was running, a scalar to put the
3752     # sub's return value in (if needed), and an array to put the sub's
3753     # return value in (if needed).
3754     my ( $al, $ret, @ret ) = "";
3755         if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
3756                 print "creating new thread\n";
3757         }
3758
3759     # If the last ten characters are C'::AUTOLOAD', note we've traced
3760     # into AUTOLOAD for $sub.
3761     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3762         $al = " for $$sub";
3763     }
3764
3765     # We stack the stack pointer and then increment it to protect us
3766     # from a situation that might unwind a whole bunch of call frames
3767     # at once. Localizing the stack pointer means that it will automatically
3768     # unwind the same amount when multiple stack frames are unwound.
3769     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3770
3771     # Expand @stack.
3772     $#stack = $stack_depth;
3773
3774     # Save current single-step setting.
3775     $stack[-1] = $single;
3776
3777     # Turn off all flags except single-stepping.
3778     $single &= 1;
3779
3780     # If we've gotten really deeply recursed, turn on the flag that will
3781     # make us stop with the 'deep recursion' message.
3782     $single |= 4 if $stack_depth == $deep;
3783
3784     # If frame messages are on ...
3785     (
3786         $frame & 4    # Extended frame entry message
3787         ? (
3788             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3789
3790             # Why -1? But it works! :-(
3791             # Because print_trace will call add 1 to it and then call
3792             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3793             # in dump_trace.
3794             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3795           )
3796         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3797
3798           # standard frame entry message
3799       )
3800       if $frame;
3801
3802     # Pop the single-step value back off the stack.
3803     $single |= $stack[ $stack_depth-- ];
3804
3805     # call the original lvalue sub.
3806     &$sub;
3807 }
3808
3809 # Abstracting common code from multiple places elsewhere:
3810 sub depth_print_lineinfo {
3811     my $always_print = shift;
3812
3813     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
3814 }
3815
3816 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
3817
3818 In Perl 5.8.0, there was a major realignment of the commands and what they did,
3819 Most of the changes were to systematize the command structure and to eliminate
3820 commands that threw away user input without checking.
3821
3822 The following sections describe the code added to make it easy to support
3823 multiple command sets with conflicting command names. This section is a start
3824 at unifying all command processing to make it simpler to develop commands.
3825
3826 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
3827 number, and C<$dbline> (the current line) as arguments.
3828
3829 Support functions in this section which have multiple modes of failure C<die>
3830 on error; the rest simply return a false value.
3831
3832 The user-interface functions (all of the C<cmd_*> functions) just output
3833 error messages.
3834
3835 =head2 C<%set>
3836
3837 The C<%set> hash defines the mapping from command letter to subroutine
3838 name suffix.
3839
3840 C<%set> is a two-level hash, indexed by set name and then by command name.
3841 Note that trying to set the CommandSet to C<foobar> simply results in the
3842 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
3843
3844 =cut
3845
3846 ### The API section
3847
3848 my %set = (    #
3849     'pre580' => {
3850         'a' => 'pre580_a',
3851         'A' => 'pre580_null',
3852         'b' => 'pre580_b',
3853         'B' => 'pre580_null',
3854         'd' => 'pre580_null',
3855         'D' => 'pre580_D',
3856         'h' => 'pre580_h',
3857         'M' => 'pre580_null',
3858         'O' => 'o',
3859         'o' => 'pre580_null',
3860         'v' => 'M',
3861         'w' => 'v',
3862         'W' => 'pre580_W',
3863     },
3864     'pre590' => {
3865         '<'  => 'pre590_prepost',
3866         '<<' => 'pre590_prepost',
3867         '>'  => 'pre590_prepost',
3868         '>>' => 'pre590_prepost',
3869         '{'  => 'pre590_prepost',
3870         '{{' => 'pre590_prepost',
3871     },
3872 );
3873
3874 my %breakpoints_data;
3875
3876 sub _has_breakpoint_data_ref {
3877     my ($filename, $line) = @_;
3878
3879     return (
3880         exists( $breakpoints_data{$filename} )
3881             and
3882         exists( $breakpoints_data{$filename}{$line} )
3883     );
3884 }
3885
3886 sub _get_breakpoint_data_ref {
3887     my ($filename, $line) = @_;
3888
3889     return ($breakpoints_data{$filename}{$line} ||= +{});
3890 }
3891
3892 sub _delete_breakpoint_data_ref {
3893     my ($filename, $line) = @_;
3894
3895     delete($breakpoints_data{$filename}{$line});
3896     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
3897         delete($breakpoints_data{$filename});
3898     }
3899
3900     return;
3901 }
3902
3903 sub _set_breakpoint_enabled_status {
3904     my ($filename, $line, $status) = @_;
3905
3906     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
3907         ($status ? 1 : '')
3908         ;
3909
3910     return;
3911 }
3912
3913 sub _enable_breakpoint_temp_enabled_status {
3914     my ($filename, $line) = @_;
3915
3916     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
3917
3918     return;
3919 }
3920
3921 sub _cancel_breakpoint_temp_enabled_status {
3922     my ($filename, $line) = @_;
3923
3924     my $ref = _get_breakpoint_data_ref($filename, $line);
3925
3926     delete ($ref->{'temp_enabled'});
3927
3928     if (! %$ref) {
3929         _delete_breakpoint_data_ref($filename, $line);
3930     }
3931
3932     return;
3933 }
3934
3935 sub _is_breakpoint_enabled {
3936     my ($filename, $line) = @_;
3937
3938     my $data_ref = _get_breakpoint_data_ref($filename, $line);
3939     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
3940 }
3941
3942 =head2 C<cmd_wrapper()> (API)
3943
3944 C<cmd_wrapper()> allows the debugger to switch command sets
3945 depending on the value of the C<CommandSet> option.
3946
3947 It tries to look up the command in the C<%set> package-level I<lexical>
3948 (which means external entities can't fiddle with it) and create the name of
3949 the sub to call based on the value found in the hash (if it's there). I<All>
3950 of the commands to be handled in a set have to be added to C<%set>; if they
3951 aren't found, the 5.8.0 equivalent is called (if there is one).
3952
3953 This code uses symbolic references.
3954
3955 =cut
3956
3957 sub cmd_wrapper {
3958     my $cmd      = shift;
3959     my $line     = shift;
3960     my $dblineno = shift;
3961
3962     # Assemble the command subroutine's name by looking up the
3963     # command set and command name in %set. If we can't find it,
3964     # default to the older version of the command.
3965     my $call = 'cmd_'
3966       . ( $set{$CommandSet}{$cmd}
3967           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
3968
3969     # Call the command subroutine, call it by name.
3970     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
3971 } ## end sub cmd_wrapper
3972
3973 =head3 C<cmd_a> (command)
3974
3975 The C<a> command handles pre-execution actions. These are associated with a
3976 particular line, so they're stored in C<%dbline>. We default to the current
3977 line if none is specified.
3978
3979 =cut
3980
3981 sub cmd_a {
3982     my $cmd    = shift;
3983     my $line   = shift || '';    # [.|line] expr
3984     my $dbline = shift;
3985
3986     # If it's dot (here), or not all digits,  use the current line.
3987     $line =~ s/^(\.|(?:[^\d]))/$dbline/;
3988
3989     # Should be a line number followed by an expression.
3990     if ( $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
3991         my ( $lineno, $expr ) = ( $1, $2 );
3992
3993         # If we have an expression ...
3994         if ( length $expr ) {
3995
3996             # ... but the line isn't breakable, complain.
3997             if ( $dbline[$lineno] == 0 ) {
3998                 print $OUT
3999                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
4000             }
4001             else {
4002
4003                 # It's executable. Record that the line has an action.
4004                 $had_breakpoints{$filename} |= 2;
4005
4006                 # Remove any action, temp breakpoint, etc.
4007                 $dbline{$lineno} =~ s/\0[^\0]*//;
4008
4009                 # Add the action to the line.
4010                 $dbline{$lineno} .= "\0" . action($expr);
4011
4012                 _set_breakpoint_enabled_status($filename, $lineno, 1);
4013             }
4014         } ## end if (length $expr)
4015     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4016     else {
4017
4018         # Syntax wrong.
4019         print $OUT
4020           "Adding an action requires an optional lineno and an expression\n"
4021           ;    # hint
4022     }
4023 } ## end sub cmd_a
4024
4025 =head3 C<cmd_A> (command)
4026
4027 Delete actions. Similar to above, except the delete code is in a separate
4028 subroutine, C<delete_action>.
4029
4030 =cut
4031
4032 sub cmd_A {
4033     my $cmd    = shift;
4034     my $line   = shift || '';
4035     my $dbline = shift;
4036
4037     # Dot is this line.
4038     $line =~ s/^\./$dbline/;
4039
4040     # Call delete_action with a null param to delete them all.
4041     # The '1' forces the eval to be true. It'll be false only
4042     # if delete_action blows up for some reason, in which case
4043     # we print $@ and get out.
4044     if ( $line eq '*' ) {
4045         eval { &delete_action(); 1 } or print $OUT $@ and return;
4046     }
4047
4048     # There's a real line  number. Pass it to delete_action.
4049     # Error trapping is as above.
4050     elsif ( $line =~ /^(\S.*)/ ) {
4051         eval { &delete_action($1); 1 } or print $OUT $@ and return;
4052     }
4053
4054     # Swing and a miss. Bad syntax.
4055     else {
4056         print $OUT
4057           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4058     }
4059 } ## end sub cmd_A
4060
4061 =head3 C<delete_action> (API)
4062
4063 C<delete_action> accepts either a line number or C<undef>. If a line number
4064 is specified, we check for the line being executable (if it's not, it
4065 couldn't have had an  action). If it is, we just take the action off (this
4066 will get any kind of an action, including breakpoints).
4067
4068 =cut
4069
4070 sub delete_action {
4071     my $i = shift;
4072     if ( defined($i) ) {
4073
4074         # Can there be one?
4075         die "Line $i has no action .\n" if $dbline[$i] == 0;
4076
4077         # Nuke whatever's there.
4078         $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4079         delete $dbline{$i} if $dbline{$i} eq '';
4080     }
4081     else {
4082         print $OUT "Deleting all actions...\n";
4083         for my $file ( keys %had_breakpoints ) {
4084             local *dbline = $main::{ '_<' . $file };
4085             $max = $#dbline;
4086             my $was;
4087             for $i (1 .. $max) {
4088                 if ( defined $dbline{$i} ) {
4089                     $dbline{$i} =~ s/\0[^\0]*//;
4090                     delete $dbline{$i} if $dbline{$i} eq '';
4091                 }
4092                 unless ( $had_breakpoints{$file} &= ~2 ) {
4093                     delete $had_breakpoints{$file};
4094                 }
4095             } ## end for ($i = 1 .. $max)
4096         } ## end for my $file (keys %had_breakpoints)
4097     } ## end else [ if (defined($i))
4098 } ## end sub delete_action
4099
4100 =head3 C<cmd_b> (command)
4101
4102 Set breakpoints. Since breakpoints can be set in so many places, in so many
4103 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4104 we try to parse the command type, and then shuttle it off to an appropriate
4105 subroutine to actually do the work of setting the breakpoint in the right
4106 place.
4107
4108 =cut
4109
4110 sub cmd_b {
4111     my $cmd    = shift;
4112     my $line   = shift;    # [.|line] [cond]
4113     my $dbline = shift;
4114
4115     # Make . the current line number if it's there..
4116     $line =~ s/^\.(\s|\z)/$dbline$1/;
4117
4118     # No line number, no condition. Simple break on current line.
4119     if ( $line =~ /^\s*$/ ) {
4120         &cmd_b_line( $dbline, 1 );
4121     }
4122
4123     # Break on load for a file.
4124     elsif ( $line =~ /^load\b\s*(.*)/ ) {
4125         my $file = $1;
4126         $file =~ s/\s+$//;
4127         &cmd_b_load($file);
4128     }
4129
4130     # b compile|postpone <some sub> [<condition>]
4131     # The interpreter actually traps this one for us; we just put the
4132     # necessary condition in the %postponed hash.
4133     elsif ( $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4134
4135         # Capture the condition if there is one. Make it true if none.
4136         my $cond = length $3 ? $3 : '1';
4137
4138         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
4139         # if it was 'compile'.
4140         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
4141
4142         # De-Perl4-ify the name - ' separators to ::.
4143         $subname =~ s/\'/::/g;
4144
4145         # Qualify it into the current package unless it's already qualified.
4146         $subname = "${package}::" . $subname unless $subname =~ /::/;
4147
4148         # Add main if it starts with ::.
4149         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4150
4151         # Save the break type for this sub.
4152         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
4153     } ## end elsif ($line =~ ...
4154     # b <filename>:<line> [<condition>]
4155     elsif ($line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4156         my ($filename, $line_num, $cond) = ($1, $2, $3);
4157         cmd_b_filename_line(
4158             $filename,
4159             $line_num,
4160             (length($cond) ? $cond : '1'),
4161         );
4162     }
4163     # b <sub name> [<condition>]
4164     elsif ( $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4165
4166         #
4167         $subname = $1;
4168         my $cond = length $2 ? $2 : '1';
4169         &cmd_b_sub( $subname, $cond );
4170     }
4171
4172     # b <line> [<condition>].
4173     elsif ( $line =~ /^(\d*)\s*(.*)/ ) {
4174
4175         # Capture the line. If none, it's the current line.
4176         $line = $1 || $dbline;
4177
4178         # If there's no condition, make it '1'.
4179         my $cond = length $2 ? $2 : '1';
4180
4181         # Break on line.
4182         &cmd_b_line( $line, $cond );
4183     }
4184
4185     # Line didn't make sense.
4186     else {
4187         print "confused by line($line)?\n";
4188     }
4189 } ## end sub cmd_b
4190
4191 =head3 C<break_on_load> (API)
4192
4193 We want to break when this file is loaded. Mark this file in the
4194 C<%break_on_load> hash, and note that it has a breakpoint in
4195 C<%had_breakpoints>.
4196
4197 =cut
4198
4199 sub break_on_load {
4200     my $file = shift;
4201     $break_on_load{$file} = 1;
4202     $had_breakpoints{$file} |= 1;
4203 }
4204
4205 =head3 C<report_break_on_load> (API)
4206
4207 Gives us an array of filenames that are set to break on load. Note that
4208 only files with break-on-load are in here, so simply showing the keys
4209 suffices.
4210
4211 =cut
4212
4213 sub report_break_on_load {
4214     sort keys %break_on_load;
4215 }
4216
4217 =head3 C<cmd_b_load> (command)
4218
4219 We take the file passed in and try to find it in C<%INC> (which maps modules
4220 to files they came from). We mark those files for break-on-load via
4221 C<break_on_load> and then report that it was done.
4222
4223 =cut
4224
4225 sub cmd_b_load {
4226     my $file = shift;
4227     my @files;
4228
4229     # This is a block because that way we can use a redo inside it
4230     # even without there being any looping structure at all outside it.
4231     {
4232
4233         # Save short name and full path if found.
4234         push @files, $file;
4235         push @files, $::INC{$file} if $::INC{$file};
4236
4237         # Tack on .pm and do it again unless there was a '.' in the name
4238         # already.
4239         $file .= '.pm', redo unless $file =~ /\./;
4240     }
4241
4242     # Do the real work here.
4243     break_on_load($_) for @files;
4244
4245     # All the files that have break-on-load breakpoints.
4246     @files = report_break_on_load;
4247
4248     # Normalize for the purposes of our printing this.
4249     local $\ = '';
4250     local $" = ' ';
4251     print $OUT "Will stop on load of '@files'.\n";
4252 } ## end sub cmd_b_load
4253
4254 =head3 C<$filename_error> (API package global)
4255
4256 Several of the functions we need to implement in the API need to work both
4257 on the current file and on other files. We don't want to duplicate code, so
4258 C<$filename_error> is used to contain the name of the file that's being
4259 worked on (if it's not the current one).
4260
4261 We can now build functions in pairs: the basic function works on the current
4262 file, and uses C<$filename_error> as part of its error message. Since this is
4263 initialized to C<"">, no filename will appear when we are working on the
4264 current file.
4265
4266 The second function is a wrapper which does the following:
4267
4268 =over 4
4269
4270 =item *
4271
4272 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4273
4274 =item *
4275
4276 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4277
4278 =item *
4279
4280 Calls the first function.
4281
4282 The first function works on the I<current> file (i.e., the one we changed to),
4283 and prints C<$filename_error> in the error message (the name of the other file)
4284 if it needs to. When the functions return, C<*dbline> is restored to point
4285 to the actual current file (the one we're executing in) and
4286 C<$filename_error> is restored to C<"">. This restores everything to
4287 the way it was before the second function was called at all.
4288
4289 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4290 details.
4291
4292 =back
4293
4294 =cut
4295
4296 use vars qw($filename_error);
4297 $filename_error = '';
4298
4299 =head3 breakable_line(from, to) (API)
4300
4301 The subroutine decides whether or not a line in the current file is breakable.
4302 It walks through C<@dbline> within the range of lines specified, looking for
4303 the first line that is breakable.
4304
4305 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4306 first line I<after> C<$to> that's breakable, if there is one.
4307
4308 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4309 first line I<before> C<$to> that's breakable, if there is one.
4310
4311 =cut
4312
4313 sub breakable_line {
4314
4315     my ( $from, $to ) = @_;
4316
4317     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4318     my $i = $from;
4319
4320     # If there are at least 2 arguments, we're trying to search a range.
4321     if ( @_ >= 2 ) {
4322
4323         # $delta is positive for a forward search, negative for a backward one.
4324         my $delta = $from < $to ? +1 : -1;
4325
4326         # Keep us from running off the ends of the file.
4327         my $limit = $delta > 0 ? $#dbline : 1;
4328
4329         # Clever test. If you're a mathematician, it's obvious why this
4330         # test works. If not:
4331         # If $delta is positive (going forward), $limit will be $#dbline.
4332         #    If $to is less than $limit, ($limit - $to) will be positive, times
4333         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4334         #    as the stopping point.
4335         #
4336         #    If $to is greater than $limit, ($limit - $to) is negative,
4337         #    times $delta of 1 (positive), so the result is < 0 and we should
4338         #    use $limit ($#dbline) as the stopping point.
4339         #
4340         # If $delta is negative (going backward), $limit will be 1.
4341         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4342         #    (negative) so the result is > 0, and we use $to as the stopping
4343         #    point.
4344         #
4345         #    If $to is less than zero, ($limit - $to) will be positive,
4346         #    times $delta of -1 (negative), so the result is not > 0, and
4347         #    we use $limit (1) as the stopping point.
4348         #
4349         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4350         #    (negative), still giving zero; the result is not > 0, and
4351         #    we use $limit (1) as the stopping point.
4352         #
4353         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4354         #    (negative), giving a positive (>0) value, so we'll set $limit to
4355         #    $to.
4356
4357         $limit = $to if ( $limit - $to ) * $delta > 0;
4358
4359         # The real search loop.
4360         # $i starts at $from (the point we want to start searching from).
4361         # We move through @dbline in the appropriate direction (determined
4362         # by $delta: either -1 (back) or +1 (ahead).
4363         # We stay in as long as we haven't hit an executable line
4364         # ($dbline[$i] == 0 means not executable) and we haven't reached
4365         # the limit yet (test similar to the above).
4366         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4367
4368     } ## end if (@_ >= 2)
4369
4370     # If $i points to a line that is executable, return that.
4371     return $i unless $dbline[$i] == 0;
4372
4373     # Format the message and print it: no breakable lines in range.
4374     my ( $pl, $upto ) = ( '', '' );
4375     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4376
4377     # If there's a filename in filename_error, we'll see it.
4378     # If not, not.
4379     die "Line$pl $from$upto$filename_error not breakable\n";
4380 } ## end sub breakable_line
4381
4382 =head3 breakable_line_in_filename(file, from, to) (API)
4383
4384 Like C<breakable_line>, but look in another file.
4385
4386 =cut
4387
4388 sub breakable_line_in_filename {
4389
4390     # Capture the file name.
4391     my ($f) = shift;
4392
4393     # Swap the magic line array over there temporarily.
4394     local *dbline = $main::{ '_<' . $f };
4395
4396     # If there's an error, it's in this other file.
4397     local $filename_error = " of '$f'";
4398
4399     # Find the breakable line.
4400     breakable_line(@_);
4401
4402     # *dbline and $filename_error get restored when this block ends.
4403
4404 } ## end sub breakable_line_in_filename
4405
4406 =head3 break_on_line(lineno, [condition]) (API)
4407
4408 Adds a breakpoint with the specified condition (or 1 if no condition was
4409 specified) to the specified line. Dies if it can't.
4410
4411 =cut
4412
4413 sub break_on_line {
4414     my ( $i, $cond ) = @_;
4415
4416     # Always true if no condition supplied.
4417     $cond = 1 unless @_ >= 2;
4418
4419     my $inii  = $i;
4420     my $after = '';
4421     my $pl    = '';
4422
4423     # Woops, not a breakable line. $filename_error allows us to say
4424     # if it was in a different file.
4425     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4426
4427     # Mark this file as having breakpoints in it.
4428     $had_breakpoints{$filename} |= 1;
4429
4430     # If there is an action or condition here already ...
4431     if ( $dbline{$i} ) {
4432
4433         # ... swap this condition for the existing one.
4434         $dbline{$i} =~ s/^[^\0]*/$cond/;
4435     }
4436     else {
4437
4438         # Nothing here - just add the condition.
4439         $dbline{$i} = $cond;
4440
4441         _set_breakpoint_enabled_status($filename, $i, 1);
4442     }
4443 } ## end sub break_on_line
4444
4445 =head3 cmd_b_line(line, [condition]) (command)
4446
4447 Wrapper for C<break_on_line>. Prints the failure message if it
4448 doesn't work.
4449
4450 =cut
4451
4452 sub cmd_b_line {
4453     if (not eval { break_on_line(@_); 1 }) {
4454         local $\ = '';
4455         print $OUT $@ and return;
4456     }
4457
4458     return;
4459 } ## end sub cmd_b_line
4460
4461 =head3 cmd_b_filename_line(line, [condition]) (command)
4462
4463 Wrapper for C<break_on_filename_line>. Prints the failure message if it
4464 doesn't work.
4465
4466 =cut
4467
4468 sub cmd_b_filename_line {
4469     if (not eval { break_on_filename_line(@_); 1 }) {
4470         local $\ = '';
4471         print $OUT $@ and return;
4472     }
4473
4474     return;
4475 }
4476
4477 =head3 break_on_filename_line(file, line, [condition]) (API)
4478
4479 Switches to the file specified and then calls C<break_on_line> to set
4480 the breakpoint.
4481
4482 =cut
4483
4484 sub break_on_filename_line {
4485     my ( $f, $i, $cond ) = @_;
4486
4487     # Always true if condition left off.
4488     $cond = 1 unless @_ >= 3;
4489
4490     # Switch the magical hash temporarily.
4491     local *dbline = $main::{ '_<' . $f };
4492
4493     # Localize the variables that break_on_line uses to make its message.
4494     local $filename_error = " of '$f'";
4495     local $filename       = $f;
4496
4497     # Add the breakpoint.
4498     break_on_line( $i, $cond );
4499 } ## end sub break_on_filename_line
4500
4501 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
4502
4503 Switch to another file, search the range of lines specified for an
4504 executable one, and put a breakpoint on the first one you find.
4505
4506 =cut
4507
4508 sub break_on_filename_line_range {
4509     my ( $f, $from, $to, $cond ) = @_;
4510
4511     # Find a breakable line if there is one.
4512     my $i = breakable_line_in_filename( $f, $from, $to );
4513
4514     # Always true if missing.
4515     $cond = 1 unless @_ >= 3;
4516
4517     # Add the breakpoint.
4518     break_on_filename_line( $f, $i, $cond );
4519 } ## end sub break_on_filename_line_range
4520