This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
perlfunc and perldelta updates about caller().
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2
3 perlfunc - Perl builtin functions
4
5 =head1 DESCRIPTION
6
7 The functions in this section can serve as terms in an expression.
8 They fall into two major categories: list operators and named unary
9 operators.  These differ in their precedence relationship with a
10 following comma.  (See the precedence table in L<perlop>.)  List
11 operators take more than one argument, while unary operators can never
12 take more than one argument.  Thus, a comma terminates the argument of
13 a unary operator, but merely separates the arguments of a list
14 operator.  A unary operator generally provides a scalar context to its
15 argument, while a list operator may provide either scalar or list
16 contexts for its arguments.  If it does both, the scalar arguments will
17 be first, and the list argument will follow.  (Note that there can ever
18 be only one such list argument.)  For instance, splice() has three scalar
19 arguments followed by a list, whereas gethostbyname() has four scalar
20 arguments.
21
22 In the syntax descriptions that follow, list operators that expect a
23 list (and provide list context for the elements of the list) are shown
24 with LIST as an argument.  Such a list may consist of any combination
25 of scalar arguments or list values; the list values will be included
26 in the list as if each individual element were interpolated at that
27 point in the list, forming a longer single-dimensional list value.
28 Elements of the LIST should be separated by commas.
29
30 Any function in the list below may be used either with or without
31 parentheses around its arguments.  (The syntax descriptions omit the
32 parentheses.)  If you use the parentheses, the simple (but occasionally
33 surprising) rule is this: It I<looks> like a function, therefore it I<is> a
34 function, and precedence doesn't matter.  Otherwise it's a list
35 operator or unary operator, and precedence does matter.  And whitespace
36 between the function and left parenthesis doesn't count--so you need to
37 be careful sometimes:
38
39     print 1+2+4;        # Prints 7.
40     print(1+2) + 4;     # Prints 3.
41     print (1+2)+4;      # Also prints 3!
42     print +(1+2)+4;     # Prints 7.
43     print ((1+2)+4);    # Prints 7.
44
45 If you run Perl with the B<-w> switch it can warn you about this.  For
46 example, the third line above produces:
47
48     print (...) interpreted as function at - line 1.
49     Useless use of integer addition in void context at - line 1.
50
51 A few functions take no arguments at all, and therefore work as neither
52 unary nor list operators.  These include such functions as C<time>
53 and C<endpwent>.  For example, C<time+86_400> always means
54 C<time() + 86_400>.
55
56 For functions that can be used in either a scalar or list context,
57 nonabortive failure is generally indicated in a scalar context by
58 returning the undefined value, and in a list context by returning the
59 null list.
60
61 Remember the following important rule: There is B<no rule> that relates
62 the behavior of an expression in list context to its behavior in scalar
63 context, or vice versa.  It might do two totally different things.
64 Each operator and function decides which sort of value it would be most
65 appropriate to return in scalar context.  Some operators return the
66 length of the list that would have been returned in list context.  Some
67 operators return the first value in the list.  Some operators return the
68 last value in the list.  Some operators return a count of successful
69 operations.  In general, they do what you want, unless you want
70 consistency.
71
72 A named array in scalar context is quite different from what would at
73 first glance appear to be a list in scalar context.  You can't get a list
74 like C<(1,2,3)> into being in scalar context, because the compiler knows
75 the context at compile time.  It would generate the scalar comma operator
76 there, not the list construction version of the comma.  That means it
77 was never a list to start with.
78
79 In general, functions in Perl that serve as wrappers for system calls
80 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
81 true when they succeed and C<undef> otherwise, as is usually mentioned
82 in the descriptions below.  This is different from the C interfaces,
83 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
84 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
85 variable on failure.  Other functions do not, except accidentally.
86
87 =head2 Perl Functions by Category
88
89 Here are Perl's functions (including things that look like
90 functions, like some keywords and named operators)
91 arranged by category.  Some functions appear in more
92 than one place.
93
94 =over 4
95
96 =item Functions for SCALARs or strings
97
98 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
99 C<length>, C<oct>, C<ord>, C<pack>, C<q/STRING/>, C<qq/STRING/>, C<reverse>,
100 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
101
102 =item Regular expressions and pattern matching
103
104 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
105
106 =item Numeric functions
107
108 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
109 C<sin>, C<sqrt>, C<srand>
110
111 =item Functions for real @ARRAYs
112
113 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
114
115 =item Functions for list data
116
117 C<grep>, C<join>, C<map>, C<qw/STRING/>, C<reverse>, C<sort>, C<unpack>
118
119 =item Functions for real %HASHes
120
121 C<delete>, C<each>, C<exists>, C<keys>, C<values>
122
123 =item Input and output functions
124
125 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
126 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
127 C<readdir>, C<rewinddir>, C<seek>, C<seekdir>, C<select>, C<syscall>,
128 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
129 C<warn>, C<write>
130
131 =item Functions for fixed length data or records
132
133 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
134
135 =item Functions for filehandles, files, or directories
136
137 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
138 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
139 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
140 C<umask>, C<unlink>, C<utime>
141
142 =item Keywords related to the control flow of your perl program
143
144 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
145 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
146
147 =item Keywords related to scoping
148
149 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<use>
150
151 =item Miscellaneous functions
152
153 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>, C<reset>,
154 C<scalar>, C<undef>, C<wantarray>
155
156 =item Functions for processes and process groups
157
158 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
159 C<pipe>, C<qx/STRING/>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
160 C<times>, C<wait>, C<waitpid>
161
162 =item Keywords related to perl modules
163
164 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
165
166 =item Keywords related to classes and object-orientedness
167
168 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
169 C<untie>, C<use>
170
171 =item Low-level socket functions
172
173 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
174 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
175 C<socket>, C<socketpair>
176
177 =item System V interprocess communication functions
178
179 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
180 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
181
182 =item Fetching user and group info
183
184 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
185 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
186 C<getpwuid>, C<setgrent>, C<setpwent>
187
188 =item Fetching network info
189
190 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
191 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
192 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
193 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
194 C<setnetent>, C<setprotoent>, C<setservent>
195
196 =item Time-related functions
197
198 C<gmtime>, C<localtime>, C<time>, C<times>
199
200 =item Functions new in perl5
201
202 C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>,
203 C<import>, C<lc>, C<lcfirst>, C<map>, C<my>, C<no>, C<our>, C<prototype>,
204 C<qx>, C<qw>, C<readline>, C<readpipe>, C<ref>, C<sub*>, C<sysopen>, C<tie>,
205 C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use>
206
207 * - C<sub> was a keyword in perl4, but in perl5 it is an
208 operator, which can be used in expressions.
209
210 =item Functions obsoleted in perl5
211
212 C<dbmclose>, C<dbmopen>
213
214 =back
215
216 =head2 Portability
217
218 Perl was born in Unix and can therefore access all common Unix
219 system calls.  In non-Unix environments, the functionality of some
220 Unix system calls may not be available, or details of the available
221 functionality may differ slightly.  The Perl functions affected
222 by this are:
223
224 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
225 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
226 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
227 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostent>,
228 C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
229 C<getppid>, C<getprgp>, C<getpriority>, C<getprotobynumber>,
230 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
231 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
232 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
233 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
234 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
235 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
236 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
237 C<shmwrite>, C<socket>, C<socketpair>,
238 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
239 C<times>, C<truncate>, C<umask>, C<unlink>,
240 C<utime>, C<wait>, C<waitpid>
241
242 For more information about the portability of these functions, see
243 L<perlport> and other available platform-specific documentation.
244
245 =head2 Alphabetical Listing of Perl Functions
246
247 =over 8
248
249 =item I<-X> FILEHANDLE
250
251 =item I<-X> EXPR
252
253 =item I<-X>
254
255 A file test, where X is one of the letters listed below.  This unary
256 operator takes one argument, either a filename or a filehandle, and
257 tests the associated file to see if something is true about it.  If the
258 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
259 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
260 the undefined value if the file doesn't exist.  Despite the funny
261 names, precedence is the same as any other named unary operator, and
262 the argument may be parenthesized like any other unary operator.  The
263 operator may be any of:
264 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
265 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
266
267     -r  File is readable by effective uid/gid.
268     -w  File is writable by effective uid/gid.
269     -x  File is executable by effective uid/gid.
270     -o  File is owned by effective uid.
271
272     -R  File is readable by real uid/gid.
273     -W  File is writable by real uid/gid.
274     -X  File is executable by real uid/gid.
275     -O  File is owned by real uid.
276
277     -e  File exists.
278     -z  File has zero size (is empty).
279     -s  File has nonzero size (returns size in bytes).
280
281     -f  File is a plain file.
282     -d  File is a directory.
283     -l  File is a symbolic link.
284     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
285     -S  File is a socket.
286     -b  File is a block special file.
287     -c  File is a character special file.
288     -t  Filehandle is opened to a tty.
289
290     -u  File has setuid bit set.
291     -g  File has setgid bit set.
292     -k  File has sticky bit set.
293
294     -T  File is an ASCII text file (heuristic guess).
295     -B  File is a "binary" file (opposite of -T).
296
297     -M  Script start time minus file modification time, in days.
298     -A  Same for access time.
299     -C  Same for inode change time (Unix, may differ for other platforms)
300
301 Example:
302
303     while (<>) {
304         chomp;
305         next unless -f $_;      # ignore specials
306         #...
307     }
308
309 The interpretation of the file permission operators C<-r>, C<-R>,
310 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
311 of the file and the uids and gids of the user.  There may be other
312 reasons you can't actually read, write, or execute the file.  Such
313 reasons may be for example network filesystem access controls, ACLs
314 (access control lists), read-only filesystems, and unrecognized
315 executable formats.
316
317 Also note that, for the superuser on the local filesystems, the C<-r>,
318 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
319 if any execute bit is set in the mode.  Scripts run by the superuser
320 may thus need to do a stat() to determine the actual mode of the file,
321 or temporarily set their effective uid to something else.
322
323 If you are using ACLs, there is a pragma called C<filetest> that may
324 produce more accurate results than the bare stat() mode bits.
325 When under the C<use filetest 'access'> the above-mentioned filetests
326 will test whether the permission can (not) be granted using the
327 access() family of system calls.  Also note that the C<-x> and C<-X> may
328 under this pragma return true even if there are no execute permission
329 bits set (nor any extra execute permission ACLs).  This strangeness is
330 due to the underlying system calls' definitions.  Read the
331 documentation for the C<filetest> pragma for more information.
332
333 Note that C<-s/a/b/> does not do a negated substitution.  Saying
334 C<-exp($foo)> still works as expected, however--only single letters
335 following a minus are interpreted as file tests.
336
337 The C<-T> and C<-B> switches work as follows.  The first block or so of the
338 file is examined for odd characters such as strange control codes or
339 characters with the high bit set.  If too many strange characters (>30%)
340 are found, it's a C<-B> file, otherwise it's a C<-T> file.  Also, any file
341 containing null in the first block is considered a binary file.  If C<-T>
342 or C<-B> is used on a filehandle, the current IO buffer is examined
343 rather than the first block.  Both C<-T> and C<-B> return true on a null
344 file, or a file at EOF when testing a filehandle.  Because you have to
345 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
346 against the file first, as in C<next unless -f $file && -T $file>.
347
348 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
349 the special filehandle consisting of a solitary underline, then the stat
350 structure of the previous file test (or stat operator) is used, saving
351 a system call.  (This doesn't work with C<-t>, and you need to remember
352 that lstat() and C<-l> will leave values in the stat structure for the
353 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
354 a C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
355 Example:
356
357     print "Can do.\n" if -r $a || -w _ || -x _;
358
359     stat($filename);
360     print "Readable\n" if -r _;
361     print "Writable\n" if -w _;
362     print "Executable\n" if -x _;
363     print "Setuid\n" if -u _;
364     print "Setgid\n" if -g _;
365     print "Sticky\n" if -k _;
366     print "Text\n" if -T _;
367     print "Binary\n" if -B _;
368
369 =item abs VALUE
370
371 =item abs
372
373 Returns the absolute value of its argument.
374 If VALUE is omitted, uses C<$_>.
375
376 =item accept NEWSOCKET,GENERICSOCKET
377
378 Accepts an incoming socket connect, just as the accept(2) system call
379 does.  Returns the packed address if it succeeded, false otherwise.
380 See the example in L<perlipc/"Sockets: Client/Server Communication">.
381
382 On systems that support a close-on-exec flag on files, the flag will
383 be set for the newly opened file descriptor, as determined by the
384 value of $^F.  See L<perlvar/$^F>.
385
386 =item alarm SECONDS
387
388 =item alarm
389
390 Arranges to have a SIGALRM delivered to this process after the
391 specified number of wallclock seconds have elapsed.  If SECONDS is not
392 specified, the value stored in C<$_> is used. (On some machines,
393 unfortunately, the elapsed time may be up to one second less or more
394 than you specified because of how seconds are counted, and process
395 scheduling may delay the delivery of the signal even further.)
396
397 Only one timer may be counting at once.  Each call disables the
398 previous timer, and an argument of C<0> may be supplied to cancel the
399 previous timer without starting a new one.  The returned value is the
400 amount of time remaining on the previous timer.
401
402 For delays of finer granularity than one second, you may use Perl's
403 four-argument version of select() leaving the first three arguments
404 undefined, or you might be able to use the C<syscall> interface to
405 access setitimer(2) if your system supports it.  The Time::HiRes
406 module (from CPAN, and starting from Perl 5.8 part of the standard
407 distribution) may also prove useful.
408
409 It is usually a mistake to intermix C<alarm> and C<sleep> calls.
410 (C<sleep> may be internally implemented in your system with C<alarm>)
411
412 If you want to use C<alarm> to time out a system call you need to use an
413 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
414 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
415 restart system calls on some systems.  Using C<eval>/C<die> always works,
416 modulo the caveats given in L<perlipc/"Signals">.
417
418     eval {
419         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
420         alarm $timeout;
421         $nread = sysread SOCKET, $buffer, $size;
422         alarm 0;
423     };
424     if ($@) {
425         die unless $@ eq "alarm\n";   # propagate unexpected errors
426         # timed out
427     }
428     else {
429         # didn't
430     }
431
432 =item atan2 Y,X
433
434 Returns the arctangent of Y/X in the range -PI to PI.
435
436 For the tangent operation, you may use the C<Math::Trig::tan>
437 function, or use the familiar relation:
438
439     sub tan { sin($_[0]) / cos($_[0])  }
440
441 =item bind SOCKET,NAME
442
443 Binds a network address to a socket, just as the bind system call
444 does.  Returns true if it succeeded, false otherwise.  NAME should be a
445 packed address of the appropriate type for the socket.  See the examples in
446 L<perlipc/"Sockets: Client/Server Communication">.
447
448 =item binmode FILEHANDLE, DISCIPLINE
449
450 =item binmode FILEHANDLE
451
452 Arranges for FILEHANDLE to be read or written in "binary" or "text" mode
453 on systems where the run-time libraries distinguish between binary and
454 text files.  If FILEHANDLE is an expression, the value is taken as the
455 name of the filehandle.
456
457 DISCIPLINE can be either of C<:raw> for binary mode or C<:crlf> for
458 "text" mode.  If the DISCIPLINE is omitted, it defaults to C<:raw>.
459 Returns true on success, C<undef> on failure.  To mark FILEHANDLE as
460 UTF-8, use C<:utf8>, and to mark the as bytes, use C<:bytes>.
461
462 The C<:raw> are C<:clrf>, and any other directives of the form
463 C<:...>, are called I/O I<disciplines>.  The C<open> pragma can be
464 used to establish default I/O disciplines.  See L<open>.
465
466 In general, binmode() should be called after open() but before any I/O
467 is done on the filehandle.  Calling binmode() will flush any possibly
468 pending buffered input or output data on the handle.  The only
469 exception to this is the C<:encoding> discipline that changes
470 the default character encoding of the handle, see L<open>.
471 The C<:encoding> discipline sometimes needs to be called in
472 mid-stream, and it doesn't flush the stream.
473
474 On some systems binmode() is necessary when you're not working with a
475 text file.  For the sake of portability it is a good idea to always use
476 it when appropriate, and to never use it when it isn't appropriate.
477
478 In other words:  Regardless of platform, use binmode() on binary
479 files, and do not use binmode() on text files.
480
481 The operating system, device drivers, C libraries, and Perl run-time
482 system all work together to let the programmer treat a single
483 character (C<\n>) as the line terminator, irrespective of the external
484 representation.  On many operating systems, the native text file
485 representation matches the internal representation, but on some
486 platforms the external representation of C<\n> is made up of more than
487 one character.
488
489 Mac OS, all variants of Unix, and Stream_LF files on VMS use a single
490 character to end each line in the external representation of text (even
491 though that single character is CARRIAGE RETURN on Mac OS and LINE FEED
492 on Unix and most VMS files).  Consequently binmode() has no effect on
493 these operating systems.  In other systems like OS/2, DOS and the various
494 flavors of MS-Windows your program sees a C<\n> as a simple C<\cJ>, but
495 what's stored in text files are the two characters C<\cM\cJ>.  That means
496 that, if you don't use binmode() on these systems, C<\cM\cJ> sequences on
497 disk will be converted to C<\n> on input, and any C<\n> in your program
498 will be converted back to C<\cM\cJ> on output.  This is what you want for
499 text files, but it can be disastrous for binary files.
500
501 Another consequence of using binmode() (on some systems) is that
502 special end-of-file markers will be seen as part of the data stream.
503 For systems from the Microsoft family this means that if your binary
504 data contains C<\cZ>, the I/O subsystem will regard it as the end of
505 the file, unless you use binmode().
506
507 binmode() is not only important for readline() and print() operations,
508 but also when using read(), seek(), sysread(), syswrite() and tell()
509 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
510 in L<perlvar> for how to manually set your input and output
511 line-termination sequences.
512
513 =item bless REF,CLASSNAME
514
515 =item bless REF
516
517 This function tells the thingy referenced by REF that it is now an object
518 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
519 is used.  Because a C<bless> is often the last thing in a constructor,
520 it returns the reference for convenience.  Always use the two-argument
521 version if the function doing the blessing might be inherited by a
522 derived class.  See L<perltoot> and L<perlobj> for more about the blessing
523 (and blessings) of objects.
524
525 Consider always blessing objects in CLASSNAMEs that are mixed case.
526 Namespaces with all lowercase names are considered reserved for
527 Perl pragmata.  Builtin types have all uppercase names, so to prevent
528 confusion, you may wish to avoid such package names as well.  Make sure
529 that CLASSNAME is a true value.
530
531 See L<perlmod/"Perl Modules">.
532
533 =item caller EXPR
534
535 =item caller
536
537 Returns the context of the current subroutine call.  In scalar context,
538 returns the caller's package name if there is a caller, that is, if
539 we're in a subroutine or C<eval> or C<require>, and the undefined value
540 otherwise.  In list context, returns
541
542     ($package, $filename, $line) = caller;
543
544 With EXPR, it returns some extra information that the debugger uses to
545 print a stack trace.  The value of EXPR indicates how many call frames
546 to go back before the current one.
547
548     ($package, $filename, $line, $subroutine, $hasargs,
549     $wantarray, $evaltext, $is_require, $hints, $bitmask) = caller($i);
550
551 Here $subroutine may be C<(eval)> if the frame is not a subroutine
552 call, but an C<eval>.  In such a case additional elements $evaltext and
553 C<$is_require> are set: C<$is_require> is true if the frame is created by a
554 C<require> or C<use> statement, $evaltext contains the text of the
555 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
556 $filename is C<(eval)>, but $evaltext is undefined.  (Note also that
557 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
558 frame.)  $subroutine may also be C<(unknown)> if this particular
559 subroutine happens to have been deleted from the symbol table.
560 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
561 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
562 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
563 between versions of Perl, and are not meant for external use.
564
565 Furthermore, when called from within the DB package, caller returns more
566 detailed information: it sets the list variable C<@DB::args> to be the
567 arguments with which the subroutine was invoked.
568
569 Be aware that the optimizer might have optimized call frames away before
570 C<caller> had a chance to get the information.  That means that C<caller(N)>
571 might not return information about the call frame you expect it do, for
572 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
573 previous time C<caller> was called.
574
575 =item chdir EXPR
576
577 Changes the working directory to EXPR, if possible. If EXPR is omitted,
578 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
579 changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the
580 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If
581 neither is set, C<chdir> does nothing. It returns true upon success,
582 false otherwise. See the example under C<die>.
583
584 =item chmod LIST
585
586 Changes the permissions of a list of files.  The first element of the
587 list must be the numerical mode, which should probably be an octal
588 number, and which definitely should I<not> a string of octal digits:
589 C<0644> is okay, C<'0644'> is not.  Returns the number of files
590 successfully changed.  See also L</oct>, if all you have is a string.
591
592     $cnt = chmod 0755, 'foo', 'bar';
593     chmod 0755, @executables;
594     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
595                                              # --w----r-T
596     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
597     $mode = 0644;   chmod $mode, 'foo';      # this is best
598
599 You can also import the symbolic C<S_I*> constants from the Fcntl
600 module:
601
602     use Fcntl ':mode';
603
604     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
605     # This is identical to the chmod 0755 of the above example.
606
607 =item chomp VARIABLE
608
609 =item chomp( LIST )
610
611 =item chomp
612
613 This safer version of L</chop> removes any trailing string
614 that corresponds to the current value of C<$/> (also known as
615 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
616 number of characters removed from all its arguments.  It's often used to
617 remove the newline from the end of an input record when you're worried
618 that the final record may be missing its newline.  When in paragraph
619 mode (C<$/ = "">), it removes all trailing newlines from the string.
620 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
621 a reference to an integer or the like, see L<perlvar>) chomp() won't
622 remove anything.
623 If VARIABLE is omitted, it chomps C<$_>.  Example:
624
625     while (<>) {
626         chomp;  # avoid \n on last field
627         @array = split(/:/);
628         # ...
629     }
630
631 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
632
633 You can actually chomp anything that's an lvalue, including an assignment:
634
635     chomp($cwd = `pwd`);
636     chomp($answer = <STDIN>);
637
638 If you chomp a list, each element is chomped, and the total number of
639 characters removed is returned.
640
641 =item chop VARIABLE
642
643 =item chop( LIST )
644
645 =item chop
646
647 Chops off the last character of a string and returns the character
648 chopped.  It is much more efficient than C<s/.$//s> because it neither
649 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
650 If VARIABLE is a hash, it chops the hash's values, but not its keys.
651
652 You can actually chop anything that's an lvalue, including an assignment.
653
654 If you chop a list, each element is chopped.  Only the value of the
655 last C<chop> is returned.
656
657 Note that C<chop> returns the last character.  To return all but the last
658 character, use C<substr($string, 0, -1)>.
659
660 =item chown LIST
661
662 Changes the owner (and group) of a list of files.  The first two
663 elements of the list must be the I<numeric> uid and gid, in that
664 order.  A value of -1 in either position is interpreted by most
665 systems to leave that value unchanged.  Returns the number of files
666 successfully changed.
667
668     $cnt = chown $uid, $gid, 'foo', 'bar';
669     chown $uid, $gid, @filenames;
670
671 Here's an example that looks up nonnumeric uids in the passwd file:
672
673     print "User: ";
674     chomp($user = <STDIN>);
675     print "Files: ";
676     chomp($pattern = <STDIN>);
677
678     ($login,$pass,$uid,$gid) = getpwnam($user)
679         or die "$user not in passwd file";
680
681     @ary = glob($pattern);      # expand filenames
682     chown $uid, $gid, @ary;
683
684 On most systems, you are not allowed to change the ownership of the
685 file unless you're the superuser, although you should be able to change
686 the group to any of your secondary groups.  On insecure systems, these
687 restrictions may be relaxed, but this is not a portable assumption.
688 On POSIX systems, you can detect this condition this way:
689
690     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
691     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
692
693 =item chr NUMBER
694
695 =item chr
696
697 Returns the character represented by that NUMBER in the character set.
698 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
699 chr(0x263a) is a Unicode smiley face.  Note that characters from 127
700 to 255 (inclusive) are by default not encoded in Unicode for backward
701 compatibility reasons (but see L<encoding>).
702
703 For the reverse, use L</ord>.
704 See L<perlunicode> and L<encoding> for more about Unicode.
705
706 If NUMBER is omitted, uses C<$_>.
707
708 =item chroot FILENAME
709
710 =item chroot
711
712 This function works like the system call by the same name: it makes the
713 named directory the new root directory for all further pathnames that
714 begin with a C</> by your process and all its children.  (It doesn't
715 change your current working directory, which is unaffected.)  For security
716 reasons, this call is restricted to the superuser.  If FILENAME is
717 omitted, does a C<chroot> to C<$_>.
718
719 =item close FILEHANDLE
720
721 =item close
722
723 Closes the file or pipe associated with the file handle, returning
724 true only if IO buffers are successfully flushed and closes the system
725 file descriptor.  Closes the currently selected filehandle if the
726 argument is omitted.
727
728 You don't have to close FILEHANDLE if you are immediately going to do
729 another C<open> on it, because C<open> will close it for you.  (See
730 C<open>.)  However, an explicit C<close> on an input file resets the line
731 counter (C<$.>), while the implicit close done by C<open> does not.
732
733 If the file handle came from a piped open C<close> will additionally
734 return false if one of the other system calls involved fails or if the
735 program exits with non-zero status.  (If the only problem was that the
736 program exited non-zero C<$!> will be set to C<0>.)  Closing a pipe
737 also waits for the process executing on the pipe to complete, in case you
738 want to look at the output of the pipe afterwards, and
739 implicitly puts the exit status value of that command into C<$?>.
740
741 Prematurely closing the read end of a pipe (i.e. before the process
742 writing to it at the other end has closed it) will result in a
743 SIGPIPE being delivered to the writer.  If the other end can't
744 handle that, be sure to read all the data before closing the pipe.
745
746 Example:
747
748     open(OUTPUT, '|sort >foo')  # pipe to sort
749         or die "Can't start sort: $!";
750     #...                        # print stuff to output
751     close OUTPUT                # wait for sort to finish
752         or warn $! ? "Error closing sort pipe: $!"
753                    : "Exit status $? from sort";
754     open(INPUT, 'foo')          # get sort's results
755         or die "Can't open 'foo' for input: $!";
756
757 FILEHANDLE may be an expression whose value can be used as an indirect
758 filehandle, usually the real filehandle name.
759
760 =item closedir DIRHANDLE
761
762 Closes a directory opened by C<opendir> and returns the success of that
763 system call.
764
765 DIRHANDLE may be an expression whose value can be used as an indirect
766 dirhandle, usually the real dirhandle name.
767
768 =item connect SOCKET,NAME
769
770 Attempts to connect to a remote socket, just as the connect system call
771 does.  Returns true if it succeeded, false otherwise.  NAME should be a
772 packed address of the appropriate type for the socket.  See the examples in
773 L<perlipc/"Sockets: Client/Server Communication">.
774
775 =item continue BLOCK
776
777 Actually a flow control statement rather than a function.  If there is a
778 C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
779 C<foreach>), it is always executed just before the conditional is about to
780 be evaluated again, just like the third part of a C<for> loop in C.  Thus
781 it can be used to increment a loop variable, even when the loop has been
782 continued via the C<next> statement (which is similar to the C C<continue>
783 statement).
784
785 C<last>, C<next>, or C<redo> may appear within a C<continue>
786 block.  C<last> and C<redo> will behave as if they had been executed within
787 the main block.  So will C<next>, but since it will execute a C<continue>
788 block, it may be more entertaining.
789
790     while (EXPR) {
791         ### redo always comes here
792         do_something;
793     } continue {
794         ### next always comes here
795         do_something_else;
796         # then back the top to re-check EXPR
797     }
798     ### last always comes here
799
800 Omitting the C<continue> section is semantically equivalent to using an
801 empty one, logically enough.  In that case, C<next> goes directly back
802 to check the condition at the top of the loop.
803
804 =item cos EXPR
805
806 =item cos
807
808 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
809 takes cosine of C<$_>.
810
811 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
812 function, or use this relation:
813
814     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
815
816 =item crypt PLAINTEXT,SALT
817
818 Encrypts a string exactly like the crypt(3) function in the C library
819 (assuming that you actually have a version there that has not been
820 extirpated as a potential munition).  This can prove useful for checking
821 the password file for lousy passwords, amongst other things.  Only the
822 guys wearing white hats should do this.
823
824 Note that C<crypt> is intended to be a one-way function, much like
825 breaking eggs to make an omelette.  There is no (known) corresponding
826 decrypt function (in other words, the crypt() is a one-way hash
827 function).  As a result, this function isn't all that useful for
828 cryptography.  (For that, see your nearby CPAN mirror.)
829
830 When verifying an existing encrypted string you should use the
831 encrypted text as the salt (like C<crypt($plain, $crypted) eq
832 $crypted>).  This allows your code to work with the standard C<crypt>
833 and with more exotic implementations.  In other words, do not assume
834 anything about the returned string itself, or how many bytes in
835 the encrypted string matter.
836
837 Traditionally the result is a string of 13 bytes: two first bytes of
838 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
839 the first eight bytes of the encrypted string mattered, but
840 alternative hashing schemes (like MD5), higher level security schemes
841 (like C2), and implementations on non-UNIX platforms may produce
842 different strings.
843
844 When choosing a new salt create a random two character string whose
845 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
846 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).
847
848 Here's an example that makes sure that whoever runs this program knows
849 their own password:
850
851     $pwd = (getpwuid($<))[1];
852
853     system "stty -echo";
854     print "Password: ";
855     chomp($word = <STDIN>);
856     print "\n";
857     system "stty echo";
858
859     if (crypt($word, $pwd) ne $pwd) {
860         die "Sorry...\n";
861     } else {
862         print "ok\n";
863     }
864
865 Of course, typing in your own password to whoever asks you
866 for it is unwise.
867
868 The L<crypt> function is unsuitable for encrypting large quantities
869 of data, not least of all because you can't get the information
870 back.  Look at the F<by-module/Crypt> and F<by-module/PGP> directories
871 on your favorite CPAN mirror for a slew of potentially useful
872 modules.
873
874 If using crypt() on a Unicode string (which I<potentially> has
875 characters with codepoints above 255), Perl tries to make sense
876 of the situation by trying to downgrade (a copy of the string)
877 the string back to an eight-bit byte string before calling crypt()
878 (on that copy).  If that works, good.  If not, crypt() dies with
879 C<Wide character in crypt>.
880
881 =item dbmclose HASH
882
883 [This function has been largely superseded by the C<untie> function.]
884
885 Breaks the binding between a DBM file and a hash.
886
887 =item dbmopen HASH,DBNAME,MASK
888
889 [This function has been largely superseded by the C<tie> function.]
890
891 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
892 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
893 argument is I<not> a filehandle, even though it looks like one).  DBNAME
894 is the name of the database (without the F<.dir> or F<.pag> extension if
895 any).  If the database does not exist, it is created with protection
896 specified by MASK (as modified by the C<umask>).  If your system supports
897 only the older DBM functions, you may perform only one C<dbmopen> in your
898 program.  In older versions of Perl, if your system had neither DBM nor
899 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
900 sdbm(3).
901
902 If you don't have write access to the DBM file, you can only read hash
903 variables, not set them.  If you want to test whether you can write,
904 either use file tests or try setting a dummy hash entry inside an C<eval>,
905 which will trap the error.
906
907 Note that functions such as C<keys> and C<values> may return huge lists
908 when used on large DBM files.  You may prefer to use the C<each>
909 function to iterate over large DBM files.  Example:
910
911     # print out history file offsets
912     dbmopen(%HIST,'/usr/lib/news/history',0666);
913     while (($key,$val) = each %HIST) {
914         print $key, ' = ', unpack('L',$val), "\n";
915     }
916     dbmclose(%HIST);
917
918 See also L<AnyDBM_File> for a more general description of the pros and
919 cons of the various dbm approaches, as well as L<DB_File> for a particularly
920 rich implementation.
921
922 You can control which DBM library you use by loading that library
923 before you call dbmopen():
924
925     use DB_File;
926     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
927         or die "Can't open netscape history file: $!";
928
929 =item defined EXPR
930
931 =item defined
932
933 Returns a Boolean value telling whether EXPR has a value other than
934 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
935 checked.
936
937 Many operations return C<undef> to indicate failure, end of file,
938 system error, uninitialized variable, and other exceptional
939 conditions.  This function allows you to distinguish C<undef> from
940 other values.  (A simple Boolean test will not distinguish among
941 C<undef>, zero, the empty string, and C<"0">, which are all equally
942 false.)  Note that since C<undef> is a valid scalar, its presence
943 doesn't I<necessarily> indicate an exceptional condition: C<pop>
944 returns C<undef> when its argument is an empty array, I<or> when the
945 element to return happens to be C<undef>.
946
947 You may also use C<defined(&func)> to check whether subroutine C<&func>
948 has ever been defined.  The return value is unaffected by any forward
949 declarations of C<&foo>.  Note that a subroutine which is not defined
950 may still be callable: its package may have an C<AUTOLOAD> method that
951 makes it spring into existence the first time that it is called -- see
952 L<perlsub>.
953
954 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
955 used to report whether memory for that aggregate has ever been
956 allocated.  This behavior may disappear in future versions of Perl.
957 You should instead use a simple test for size:
958
959     if (@an_array) { print "has array elements\n" }
960     if (%a_hash)   { print "has hash members\n"   }
961
962 When used on a hash element, it tells you whether the value is defined,
963 not whether the key exists in the hash.  Use L</exists> for the latter
964 purpose.
965
966 Examples:
967
968     print if defined $switch{'D'};
969     print "$val\n" while defined($val = pop(@ary));
970     die "Can't readlink $sym: $!"
971         unless defined($value = readlink $sym);
972     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
973     $debugging = 0 unless defined $debugging;
974
975 Note:  Many folks tend to overuse C<defined>, and then are surprised to
976 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
977 defined values.  For example, if you say
978
979     "ab" =~ /a(.*)b/;
980
981 The pattern match succeeds, and C<$1> is defined, despite the fact that it
982 matched "nothing".  But it didn't really match nothing--rather, it
983 matched something that happened to be zero characters long.  This is all
984 very above-board and honest.  When a function returns an undefined value,
985 it's an admission that it couldn't give you an honest answer.  So you
986 should use C<defined> only when you're questioning the integrity of what
987 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
988 what you want.
989
990 See also L</undef>, L</exists>, L</ref>.
991
992 =item delete EXPR
993
994 Given an expression that specifies a hash element, array element, hash slice,
995 or array slice, deletes the specified element(s) from the hash or array.
996 In the case of an array, if the array elements happen to be at the end,
997 the size of the array will shrink to the highest element that tests
998 true for exists() (or 0 if no such element exists).
999
1000 Returns each element so deleted or the undefined value if there was no such
1001 element.  Deleting from C<$ENV{}> modifies the environment.  Deleting from
1002 a hash tied to a DBM file deletes the entry from the DBM file.  Deleting
1003 from a C<tie>d hash or array may not necessarily return anything.
1004
1005 Deleting an array element effectively returns that position of the array
1006 to its initial, uninitialized state.  Subsequently testing for the same
1007 element with exists() will return false.  Note that deleting array
1008 elements in the middle of an array will not shift the index of the ones
1009 after them down--use splice() for that.  See L</exists>.
1010
1011 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1012
1013     foreach $key (keys %HASH) {
1014         delete $HASH{$key};
1015     }
1016
1017     foreach $index (0 .. $#ARRAY) {
1018         delete $ARRAY[$index];
1019     }
1020
1021 And so do these:
1022
1023     delete @HASH{keys %HASH};
1024
1025     delete @ARRAY[0 .. $#ARRAY];
1026
1027 But both of these are slower than just assigning the empty list
1028 or undefining %HASH or @ARRAY:
1029
1030     %HASH = ();         # completely empty %HASH
1031     undef %HASH;        # forget %HASH ever existed
1032
1033     @ARRAY = ();        # completely empty @ARRAY
1034     undef @ARRAY;       # forget @ARRAY ever existed
1035
1036 Note that the EXPR can be arbitrarily complicated as long as the final
1037 operation is a hash element, array element,  hash slice, or array slice
1038 lookup:
1039
1040     delete $ref->[$x][$y]{$key};
1041     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1042
1043     delete $ref->[$x][$y][$index];
1044     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1045
1046 =item die LIST
1047
1048 Outside an C<eval>, prints the value of LIST to C<STDERR> and
1049 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
1050 exits with the value of C<<< ($? >> 8) >>> (backtick `command`
1051 status).  If C<<< ($? >> 8) >>> is C<0>, exits with C<255>.  Inside
1052 an C<eval(),> the error message is stuffed into C<$@> and the
1053 C<eval> is terminated with the undefined value.  This makes
1054 C<die> the way to raise an exception.
1055
1056 Equivalent examples:
1057
1058     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1059     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1060
1061 If the last element of LIST does not end in a newline, the current
1062 script line number and input line number (if any) are also printed,
1063 and a newline is supplied.  Note that the "input line number" (also
1064 known as "chunk") is subject to whatever notion of "line" happens to
1065 be currently in effect, and is also available as the special variable
1066 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1067
1068 Hint: sometimes appending C<", stopped"> to your message will cause it
1069 to make better sense when the string C<"at foo line 123"> is appended.
1070 Suppose you are running script "canasta".
1071
1072     die "/etc/games is no good";
1073     die "/etc/games is no good, stopped";
1074
1075 produce, respectively
1076
1077     /etc/games is no good at canasta line 123.
1078     /etc/games is no good, stopped at canasta line 123.
1079
1080 See also exit(), warn(), and the Carp module.
1081
1082 If LIST is empty and C<$@> already contains a value (typically from a
1083 previous eval) that value is reused after appending C<"\t...propagated">.
1084 This is useful for propagating exceptions:
1085
1086     eval { ... };
1087     die unless $@ =~ /Expected exception/;
1088
1089 If LIST is empty and C<$@> contains an object reference that has a
1090 C<PROPAGATE> method, that method will be called with additional file
1091 and line number parameters.  The return value replaces the value in
1092 C<$@>.  ie. as if C<<$@ = eval { $@->PROPAGATE(__FILE__, __LINE__) };>> 
1093 were called.
1094
1095 If C<$@> is empty then the string C<"Died"> is used.
1096
1097 die() can also be called with a reference argument.  If this happens to be
1098 trapped within an eval(), $@ contains the reference.  This behavior permits
1099 a more elaborate exception handling implementation using objects that
1100 maintain arbitrary state about the nature of the exception.  Such a scheme
1101 is sometimes preferable to matching particular string values of $@ using
1102 regular expressions.  Here's an example:
1103
1104     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1105     if ($@) {
1106         if (ref($@) && UNIVERSAL::isa($@,"Some::Module::Exception")) {
1107             # handle Some::Module::Exception
1108         }
1109         else {
1110             # handle all other possible exceptions
1111         }
1112     }
1113
1114 Because perl will stringify uncaught exception messages before displaying
1115 them, you may want to overload stringification operations on such custom
1116 exception objects.  See L<overload> for details about that.
1117
1118 You can arrange for a callback to be run just before the C<die>
1119 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1120 handler will be called with the error text and can change the error
1121 message, if it sees fit, by calling C<die> again.  See
1122 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1123 L<"eval BLOCK"> for some examples.  Although this feature was meant
1124 to be run only right before your program was to exit, this is not
1125 currently the case--the C<$SIG{__DIE__}> hook is currently called
1126 even inside eval()ed blocks/strings!  If one wants the hook to do
1127 nothing in such situations, put
1128
1129         die @_ if $^S;
1130
1131 as the first line of the handler (see L<perlvar/$^S>).  Because
1132 this promotes strange action at a distance, this counterintuitive
1133 behavior may be fixed in a future release.
1134
1135 =item do BLOCK
1136
1137 Not really a function.  Returns the value of the last command in the
1138 sequence of commands indicated by BLOCK.  When modified by a loop
1139 modifier, executes the BLOCK once before testing the loop condition.
1140 (On other statements the loop modifiers test the conditional first.)
1141
1142 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1143 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1144 See L<perlsyn> for alternative strategies.
1145
1146 =item do SUBROUTINE(LIST)
1147
1148 A deprecated form of subroutine call.  See L<perlsub>.
1149
1150 =item do EXPR
1151
1152 Uses the value of EXPR as a filename and executes the contents of the
1153 file as a Perl script.  Its primary use is to include subroutines
1154 from a Perl subroutine library.
1155
1156     do 'stat.pl';
1157
1158 is just like
1159
1160     eval `cat stat.pl`;
1161
1162 except that it's more efficient and concise, keeps track of the current
1163 filename for error messages, searches the @INC libraries, and updates
1164 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1165 variables.  It also differs in that code evaluated with C<do FILENAME>
1166 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1167 same, however, in that it does reparse the file every time you call it,
1168 so you probably don't want to do this inside a loop.
1169
1170 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1171 error.  If C<do> can read the file but cannot compile it, it
1172 returns undef and sets an error message in C<$@>.   If the file is
1173 successfully compiled, C<do> returns the value of the last expression
1174 evaluated.
1175
1176 Note that inclusion of library modules is better done with the
1177 C<use> and C<require> operators, which also do automatic error checking
1178 and raise an exception if there's a problem.
1179
1180 You might like to use C<do> to read in a program configuration
1181 file.  Manual error checking can be done this way:
1182
1183     # read in config files: system first, then user
1184     for $file ("/share/prog/defaults.rc",
1185                "$ENV{HOME}/.someprogrc")
1186    {
1187         unless ($return = do $file) {
1188             warn "couldn't parse $file: $@" if $@;
1189             warn "couldn't do $file: $!"    unless defined $return;
1190             warn "couldn't run $file"       unless $return;
1191         }
1192     }
1193
1194 =item dump LABEL
1195
1196 =item dump
1197
1198 This function causes an immediate core dump.  See also the B<-u>
1199 command-line switch in L<perlrun>, which does the same thing.
1200 Primarily this is so that you can use the B<undump> program (not
1201 supplied) to turn your core dump into an executable binary after
1202 having initialized all your variables at the beginning of the
1203 program.  When the new binary is executed it will begin by executing
1204 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1205 Think of it as a goto with an intervening core dump and reincarnation.
1206 If C<LABEL> is omitted, restarts the program from the top.
1207
1208 B<WARNING>: Any files opened at the time of the dump will I<not>
1209 be open any more when the program is reincarnated, with possible
1210 resulting confusion on the part of Perl.
1211
1212 This function is now largely obsolete, partly because it's very
1213 hard to convert a core file into an executable, and because the
1214 real compiler backends for generating portable bytecode and compilable
1215 C code have superseded it.  That's why you should now invoke it as
1216 C<CORE::dump()>, if you don't want to be warned against a possible
1217 typo.
1218
1219 If you're looking to use L<dump> to speed up your program, consider
1220 generating bytecode or native C code as described in L<perlcc>.  If
1221 you're just trying to accelerate a CGI script, consider using the
1222 C<mod_perl> extension to B<Apache>, or the CPAN module, CGI::Fast.
1223 You might also consider autoloading or selfloading, which at least
1224 make your program I<appear> to run faster.
1225
1226 =item each HASH
1227
1228 When called in list context, returns a 2-element list consisting of the
1229 key and value for the next element of a hash, so that you can iterate over
1230 it.  When called in scalar context, returns only the key for the next
1231 element in the hash.
1232
1233 Entries are returned in an apparently random order.  The actual random
1234 order is subject to change in future versions of perl, but it is guaranteed
1235 to be in the same order as either the C<keys> or C<values> function
1236 would produce on the same (unmodified) hash.
1237
1238 When the hash is entirely read, a null array is returned in list context
1239 (which when assigned produces a false (C<0>) value), and C<undef> in
1240 scalar context.  The next call to C<each> after that will start iterating
1241 again.  There is a single iterator for each hash, shared by all C<each>,
1242 C<keys>, and C<values> function calls in the program; it can be reset by
1243 reading all the elements from the hash, or by evaluating C<keys HASH> or
1244 C<values HASH>.  If you add or delete elements of a hash while you're
1245 iterating over it, you may get entries skipped or duplicated, so
1246 don't.  Exception: It is always safe to delete the item most recently
1247 returned by C<each()>, which means that the following code will work:
1248
1249         while (($key, $value) = each %hash) {
1250           print $key, "\n";
1251           delete $hash{$key};   # This is safe
1252         }
1253
1254 The following prints out your environment like the printenv(1) program,
1255 only in a different order:
1256
1257     while (($key,$value) = each %ENV) {
1258         print "$key=$value\n";
1259     }
1260
1261 See also C<keys>, C<values> and C<sort>.
1262
1263 =item eof FILEHANDLE
1264
1265 =item eof ()
1266
1267 =item eof
1268
1269 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1270 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1271 gives the real filehandle.  (Note that this function actually
1272 reads a character and then C<ungetc>s it, so isn't very useful in an
1273 interactive context.)  Do not read from a terminal file (or call
1274 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1275 as terminals may lose the end-of-file condition if you do.
1276
1277 An C<eof> without an argument uses the last file read.  Using C<eof()>
1278 with empty parentheses is very different.  It refers to the pseudo file
1279 formed from the files listed on the command line and accessed via the
1280 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1281 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1282 used will cause C<@ARGV> to be examined to determine if input is
1283 available.   Similarly, an C<eof()> after C<< <> >> has returned 
1284 end-of-file will assume you are processing another C<@ARGV> list,
1285 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1286 see L<perlop/"I/O Operators">.
1287
1288 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1289 detect the end of each file, C<eof()> will only detect the end of the
1290 last file.  Examples:
1291
1292     # reset line numbering on each input file
1293     while (<>) {
1294         next if /^\s*#/;        # skip comments
1295         print "$.\t$_";
1296     } continue {
1297         close ARGV  if eof;     # Not eof()!
1298     }
1299
1300     # insert dashes just before last line of last file
1301     while (<>) {
1302         if (eof()) {            # check for end of current file
1303             print "--------------\n";
1304             close(ARGV);        # close or last; is needed if we
1305                                 # are reading from the terminal
1306         }
1307         print;
1308     }
1309
1310 Practical hint: you almost never need to use C<eof> in Perl, because the
1311 input operators typically return C<undef> when they run out of data, or if
1312 there was an error.
1313
1314 =item eval EXPR
1315
1316 =item eval BLOCK
1317
1318 In the first form, the return value of EXPR is parsed and executed as if it
1319 were a little Perl program.  The value of the expression (which is itself
1320 determined within scalar context) is first parsed, and if there weren't any
1321 errors, executed in the lexical context of the current Perl program, so
1322 that any variable settings or subroutine and format definitions remain
1323 afterwards.  Note that the value is parsed every time the eval executes.
1324 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1325 delay parsing and subsequent execution of the text of EXPR until run time.
1326
1327 In the second form, the code within the BLOCK is parsed only once--at the
1328 same time the code surrounding the eval itself was parsed--and executed
1329 within the context of the current Perl program.  This form is typically
1330 used to trap exceptions more efficiently than the first (see below), while
1331 also providing the benefit of checking the code within BLOCK at compile
1332 time.
1333
1334 The final semicolon, if any, may be omitted from the value of EXPR or within
1335 the BLOCK.
1336
1337 In both forms, the value returned is the value of the last expression
1338 evaluated inside the mini-program; a return statement may be also used, just
1339 as with subroutines.  The expression providing the return value is evaluated
1340 in void, scalar, or list context, depending on the context of the eval itself.
1341 See L</wantarray> for more on how the evaluation context can be determined.
1342
1343 If there is a syntax error or runtime error, or a C<die> statement is
1344 executed, an undefined value is returned by C<eval>, and C<$@> is set to the
1345 error message.  If there was no error, C<$@> is guaranteed to be a null
1346 string.  Beware that using C<eval> neither silences perl from printing
1347 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1348 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1349 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1350 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1351
1352 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1353 determining whether a particular feature (such as C<socket> or C<symlink>)
1354 is implemented.  It is also Perl's exception trapping mechanism, where
1355 the die operator is used to raise exceptions.
1356
1357 If the code to be executed doesn't vary, you may use the eval-BLOCK
1358 form to trap run-time errors without incurring the penalty of
1359 recompiling each time.  The error, if any, is still returned in C<$@>.
1360 Examples:
1361
1362     # make divide-by-zero nonfatal
1363     eval { $answer = $a / $b; }; warn $@ if $@;
1364
1365     # same thing, but less efficient
1366     eval '$answer = $a / $b'; warn $@ if $@;
1367
1368     # a compile-time error
1369     eval { $answer = };                 # WRONG
1370
1371     # a run-time error
1372     eval '$answer =';   # sets $@
1373
1374 Due to the current arguably broken state of C<__DIE__> hooks, when using
1375 the C<eval{}> form as an exception trap in libraries, you may wish not
1376 to trigger any C<__DIE__> hooks that user code may have installed.
1377 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1378 as shown in this example:
1379
1380     # a very private exception trap for divide-by-zero
1381     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1382     warn $@ if $@;
1383
1384 This is especially significant, given that C<__DIE__> hooks can call
1385 C<die> again, which has the effect of changing their error messages:
1386
1387     # __DIE__ hooks may modify error messages
1388     {
1389        local $SIG{'__DIE__'} =
1390               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1391        eval { die "foo lives here" };
1392        print $@ if $@;                # prints "bar lives here"
1393     }
1394
1395 Because this promotes action at a distance, this counterintuitive behavior
1396 may be fixed in a future release.
1397
1398 With an C<eval>, you should be especially careful to remember what's
1399 being looked at when:
1400
1401     eval $x;            # CASE 1
1402     eval "$x";          # CASE 2
1403
1404     eval '$x';          # CASE 3
1405     eval { $x };        # CASE 4
1406
1407     eval "\$$x++";      # CASE 5
1408     $$x++;              # CASE 6
1409
1410 Cases 1 and 2 above behave identically: they run the code contained in
1411 the variable $x.  (Although case 2 has misleading double quotes making
1412 the reader wonder what else might be happening (nothing is).)  Cases 3
1413 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1414 does nothing but return the value of $x.  (Case 4 is preferred for
1415 purely visual reasons, but it also has the advantage of compiling at
1416 compile-time instead of at run-time.)  Case 5 is a place where
1417 normally you I<would> like to use double quotes, except that in this
1418 particular situation, you can just use symbolic references instead, as
1419 in case 6.
1420
1421 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1422 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1423
1424 =item exec LIST
1425
1426 =item exec PROGRAM LIST
1427
1428 The C<exec> function executes a system command I<and never returns>--
1429 use C<system> instead of C<exec> if you want it to return.  It fails and
1430 returns false only if the command does not exist I<and> it is executed
1431 directly instead of via your system's command shell (see below).
1432
1433 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1434 warns you if there is a following statement which isn't C<die>, C<warn>,
1435 or C<exit> (if C<-w> is set  -  but you always do that).   If you
1436 I<really> want to follow an C<exec> with some other statement, you
1437 can use one of these styles to avoid the warning:
1438
1439     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1440     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1441
1442 If there is more than one argument in LIST, or if LIST is an array
1443 with more than one value, calls execvp(3) with the arguments in LIST.
1444 If there is only one scalar argument or an array with one element in it,
1445 the argument is checked for shell metacharacters, and if there are any,
1446 the entire argument is passed to the system's command shell for parsing
1447 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1448 If there are no shell metacharacters in the argument, it is split into
1449 words and passed directly to C<execvp>, which is more efficient.
1450 Examples:
1451
1452     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1453     exec "sort $outfile | uniq";
1454
1455 If you don't really want to execute the first argument, but want to lie
1456 to the program you are executing about its own name, you can specify
1457 the program you actually want to run as an "indirect object" (without a
1458 comma) in front of the LIST.  (This always forces interpretation of the
1459 LIST as a multivalued list, even if there is only a single scalar in
1460 the list.)  Example:
1461
1462     $shell = '/bin/csh';
1463     exec $shell '-sh';          # pretend it's a login shell
1464
1465 or, more directly,
1466
1467     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1468
1469 When the arguments get executed via the system shell, results will
1470 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1471 for details.
1472
1473 Using an indirect object with C<exec> or C<system> is also more
1474 secure.  This usage (which also works fine with system()) forces
1475 interpretation of the arguments as a multivalued list, even if the
1476 list had just one argument.  That way you're safe from the shell
1477 expanding wildcards or splitting up words with whitespace in them.
1478
1479     @args = ( "echo surprise" );
1480
1481     exec @args;               # subject to shell escapes
1482                                 # if @args == 1
1483     exec { $args[0] } @args;  # safe even with one-arg list
1484
1485 The first version, the one without the indirect object, ran the I<echo>
1486 program, passing it C<"surprise"> an argument.  The second version
1487 didn't--it tried to run a program literally called I<"echo surprise">,
1488 didn't find it, and set C<$?> to a non-zero value indicating failure.
1489
1490 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1491 output before the exec, but this may not be supported on some platforms
1492 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1493 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1494 open handles in order to avoid lost output.
1495
1496 Note that C<exec> will not call your C<END> blocks, nor will it call
1497 any C<DESTROY> methods in your objects.
1498
1499 =item exists EXPR
1500
1501 Given an expression that specifies a hash element or array element,
1502 returns true if the specified element in the hash or array has ever
1503 been initialized, even if the corresponding value is undefined.  The
1504 element is not autovivified if it doesn't exist.
1505
1506     print "Exists\n"    if exists $hash{$key};
1507     print "Defined\n"   if defined $hash{$key};
1508     print "True\n"      if $hash{$key};
1509
1510     print "Exists\n"    if exists $array[$index];
1511     print "Defined\n"   if defined $array[$index];
1512     print "True\n"      if $array[$index];
1513
1514 A hash or array element can be true only if it's defined, and defined if
1515 it exists, but the reverse doesn't necessarily hold true.
1516
1517 Given an expression that specifies the name of a subroutine,
1518 returns true if the specified subroutine has ever been declared, even
1519 if it is undefined.  Mentioning a subroutine name for exists or defined
1520 does not count as declaring it.  Note that a subroutine which does not
1521 exist may still be callable: its package may have an C<AUTOLOAD>
1522 method that makes it spring into existence the first time that it is
1523 called -- see L<perlsub>.
1524
1525     print "Exists\n"    if exists &subroutine;
1526     print "Defined\n"   if defined &subroutine;
1527
1528 Note that the EXPR can be arbitrarily complicated as long as the final
1529 operation is a hash or array key lookup or subroutine name:
1530
1531     if (exists $ref->{A}->{B}->{$key})  { }
1532     if (exists $hash{A}{B}{$key})       { }
1533
1534     if (exists $ref->{A}->{B}->[$ix])   { }
1535     if (exists $hash{A}{B}[$ix])        { }
1536
1537     if (exists &{$ref->{A}{B}{$key}})   { }
1538
1539 Although the deepest nested array or hash will not spring into existence
1540 just because its existence was tested, any intervening ones will.
1541 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1542 into existence due to the existence test for the $key element above.
1543 This happens anywhere the arrow operator is used, including even:
1544
1545     undef $ref;
1546     if (exists $ref->{"Some key"})      { }
1547     print $ref;             # prints HASH(0x80d3d5c)
1548
1549 This surprising autovivification in what does not at first--or even
1550 second--glance appear to be an lvalue context may be fixed in a future
1551 release.
1552
1553 See L<perlref/"Pseudo-hashes: Using an array as a hash"> for specifics
1554 on how exists() acts when used on a pseudo-hash.
1555
1556 Use of a subroutine call, rather than a subroutine name, as an argument
1557 to exists() is an error.
1558
1559     exists &sub;        # OK
1560     exists &sub();      # Error
1561
1562 =item exit EXPR
1563
1564 Evaluates EXPR and exits immediately with that value.    Example:
1565
1566     $ans = <STDIN>;
1567     exit 0 if $ans =~ /^[Xx]/;
1568
1569 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1570 universally recognized values for EXPR are C<0> for success and C<1>
1571 for error; other values are subject to interpretation depending on the
1572 environment in which the Perl program is running.  For example, exiting
1573 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1574 the mailer to return the item undelivered, but that's not true everywhere.
1575
1576 Don't use C<exit> to abort a subroutine if there's any chance that
1577 someone might want to trap whatever error happened.  Use C<die> instead,
1578 which can be trapped by an C<eval>.
1579
1580 The exit() function does not always exit immediately.  It calls any
1581 defined C<END> routines first, but these C<END> routines may not
1582 themselves abort the exit.  Likewise any object destructors that need to
1583 be called are called before the real exit.  If this is a problem, you
1584 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1585 See L<perlmod> for details.
1586
1587 =item exp EXPR
1588
1589 =item exp
1590
1591 Returns I<e> (the natural logarithm base) to the power of EXPR.
1592 If EXPR is omitted, gives C<exp($_)>.
1593
1594 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1595
1596 Implements the fcntl(2) function.  You'll probably have to say
1597
1598     use Fcntl;
1599
1600 first to get the correct constant definitions.  Argument processing and
1601 value return works just like C<ioctl> below.
1602 For example:
1603
1604     use Fcntl;
1605     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1606         or die "can't fcntl F_GETFL: $!";
1607
1608 You don't have to check for C<defined> on the return from C<fnctl>.
1609 Like C<ioctl>, it maps a C<0> return from the system call into
1610 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1611 in numeric context.  It is also exempt from the normal B<-w> warnings
1612 on improper numeric conversions.
1613
1614 Note that C<fcntl> will produce a fatal error if used on a machine that
1615 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1616 manpage to learn what functions are available on your system.
1617
1618 =item fileno FILEHANDLE
1619
1620 Returns the file descriptor for a filehandle, or undefined if the
1621 filehandle is not open.  This is mainly useful for constructing
1622 bitmaps for C<select> and low-level POSIX tty-handling operations.
1623 If FILEHANDLE is an expression, the value is taken as an indirect
1624 filehandle, generally its name.
1625
1626 You can use this to find out whether two handles refer to the
1627 same underlying descriptor:
1628
1629     if (fileno(THIS) == fileno(THAT)) {
1630         print "THIS and THAT are dups\n";
1631     }
1632
1633 (Filehandles connected to memory objects via new features of C<open> may
1634 return undefined even though they are open.)
1635
1636
1637 =item flock FILEHANDLE,OPERATION
1638
1639 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1640 for success, false on failure.  Produces a fatal error if used on a
1641 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1642 C<flock> is Perl's portable file locking interface, although it locks
1643 only entire files, not records.
1644
1645 Two potentially non-obvious but traditional C<flock> semantics are
1646 that it waits indefinitely until the lock is granted, and that its locks
1647 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1648 fewer guarantees.  This means that files locked with C<flock> may be
1649 modified by programs that do not also use C<flock>.  See L<perlport>,
1650 your port's specific documentation, or your system-specific local manpages
1651 for details.  It's best to assume traditional behavior if you're writing
1652 portable programs.  (But if you're not, you should as always feel perfectly
1653 free to write for your own system's idiosyncrasies (sometimes called
1654 "features").  Slavish adherence to portability concerns shouldn't get
1655 in the way of your getting your job done.)
1656
1657 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1658 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1659 you can use the symbolic names if you import them from the Fcntl module,
1660 either individually, or as a group using the ':flock' tag.  LOCK_SH
1661 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1662 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1663 LOCK_SH or LOCK_EX then C<flock> will return immediately rather than blocking
1664 waiting for the lock (check the return status to see if you got it).
1665
1666 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1667 before locking or unlocking it.
1668
1669 Note that the emulation built with lockf(3) doesn't provide shared
1670 locks, and it requires that FILEHANDLE be open with write intent.  These
1671 are the semantics that lockf(3) implements.  Most if not all systems
1672 implement lockf(3) in terms of fcntl(2) locking, though, so the
1673 differing semantics shouldn't bite too many people.
1674
1675 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
1676 be open with read intent to use LOCK_SH and requires that it be open
1677 with write intent to use LOCK_EX.
1678
1679 Note also that some versions of C<flock> cannot lock things over the
1680 network; you would need to use the more system-specific C<fcntl> for
1681 that.  If you like you can force Perl to ignore your system's flock(2)
1682 function, and so provide its own fcntl(2)-based emulation, by passing
1683 the switch C<-Ud_flock> to the F<Configure> program when you configure
1684 perl.
1685
1686 Here's a mailbox appender for BSD systems.
1687
1688     use Fcntl ':flock'; # import LOCK_* constants
1689
1690     sub lock {
1691         flock(MBOX,LOCK_EX);
1692         # and, in case someone appended
1693         # while we were waiting...
1694         seek(MBOX, 0, 2);
1695     }
1696
1697     sub unlock {
1698         flock(MBOX,LOCK_UN);
1699     }
1700
1701     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1702             or die "Can't open mailbox: $!";
1703
1704     lock();
1705     print MBOX $msg,"\n\n";
1706     unlock();
1707
1708 On systems that support a real flock(), locks are inherited across fork()
1709 calls, whereas those that must resort to the more capricious fcntl()
1710 function lose the locks, making it harder to write servers.
1711
1712 See also L<DB_File> for other flock() examples.
1713
1714 =item fork
1715
1716 Does a fork(2) system call to create a new process running the
1717 same program at the same point.  It returns the child pid to the
1718 parent process, C<0> to the child process, or C<undef> if the fork is
1719 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
1720 are shared, while everything else is copied.  On most systems supporting
1721 fork(), great care has gone into making it extremely efficient (for
1722 example, using copy-on-write technology on data pages), making it the
1723 dominant paradigm for multitasking over the last few decades.
1724
1725 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1726 output before forking the child process, but this may not be supported
1727 on some platforms (see L<perlport>).  To be safe, you may need to set
1728 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1729 C<IO::Handle> on any open handles in order to avoid duplicate output.
1730
1731 If you C<fork> without ever waiting on your children, you will
1732 accumulate zombies.  On some systems, you can avoid this by setting
1733 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
1734 forking and reaping moribund children.
1735
1736 Note that if your forked child inherits system file descriptors like
1737 STDIN and STDOUT that are actually connected by a pipe or socket, even
1738 if you exit, then the remote server (such as, say, a CGI script or a
1739 backgrounded job launched from a remote shell) won't think you're done.
1740 You should reopen those to F</dev/null> if it's any issue.
1741
1742 =item format
1743
1744 Declare a picture format for use by the C<write> function.  For
1745 example:
1746
1747     format Something =
1748         Test: @<<<<<<<< @||||| @>>>>>
1749               $str,     $%,    '$' . int($num)
1750     .
1751
1752     $str = "widget";
1753     $num = $cost/$quantity;
1754     $~ = 'Something';
1755     write;
1756
1757 See L<perlform> for many details and examples.
1758
1759 =item formline PICTURE,LIST
1760
1761 This is an internal function used by C<format>s, though you may call it,
1762 too.  It formats (see L<perlform>) a list of values according to the
1763 contents of PICTURE, placing the output into the format output
1764 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1765 Eventually, when a C<write> is done, the contents of
1766 C<$^A> are written to some filehandle, but you could also read C<$^A>
1767 yourself and then set C<$^A> back to C<"">.  Note that a format typically
1768 does one C<formline> per line of form, but the C<formline> function itself
1769 doesn't care how many newlines are embedded in the PICTURE.  This means
1770 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1771 You may therefore need to use multiple formlines to implement a single
1772 record format, just like the format compiler.
1773
1774 Be careful if you put double quotes around the picture, because an C<@>
1775 character may be taken to mean the beginning of an array name.
1776 C<formline> always returns true.  See L<perlform> for other examples.
1777
1778 =item getc FILEHANDLE
1779
1780 =item getc
1781
1782 Returns the next character from the input file attached to FILEHANDLE,
1783 or the undefined value at end of file, or if there was an error.
1784 If FILEHANDLE is omitted, reads from STDIN.  This is not particularly
1785 efficient.  However, it cannot be used by itself to fetch single
1786 characters without waiting for the user to hit enter.  For that, try
1787 something more like:
1788
1789     if ($BSD_STYLE) {
1790         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1791     }
1792     else {
1793         system "stty", '-icanon', 'eol', "\001";
1794     }
1795
1796     $key = getc(STDIN);
1797
1798     if ($BSD_STYLE) {
1799         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1800     }
1801     else {
1802         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1803     }
1804     print "\n";
1805
1806 Determination of whether $BSD_STYLE should be set
1807 is left as an exercise to the reader.
1808
1809 The C<POSIX::getattr> function can do this more portably on
1810 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
1811 module from your nearest CPAN site; details on CPAN can be found on
1812 L<perlmodlib/CPAN>.
1813
1814 =item getlogin
1815
1816 Implements the C library function of the same name, which on most
1817 systems returns the current login from F</etc/utmp>, if any.  If null,
1818 use C<getpwuid>.
1819
1820     $login = getlogin || getpwuid($<) || "Kilroy";
1821
1822 Do not consider C<getlogin> for authentication: it is not as
1823 secure as C<getpwuid>.
1824
1825 =item getpeername SOCKET
1826
1827 Returns the packed sockaddr address of other end of the SOCKET connection.
1828
1829     use Socket;
1830     $hersockaddr    = getpeername(SOCK);
1831     ($port, $iaddr) = sockaddr_in($hersockaddr);
1832     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1833     $herstraddr     = inet_ntoa($iaddr);
1834
1835 =item getpgrp PID
1836
1837 Returns the current process group for the specified PID.  Use
1838 a PID of C<0> to get the current process group for the
1839 current process.  Will raise an exception if used on a machine that
1840 doesn't implement getpgrp(2).  If PID is omitted, returns process
1841 group of current process.  Note that the POSIX version of C<getpgrp>
1842 does not accept a PID argument, so only C<PID==0> is truly portable.
1843
1844 =item getppid
1845
1846 Returns the process id of the parent process.
1847
1848 =item getpriority WHICH,WHO
1849
1850 Returns the current priority for a process, a process group, or a user.
1851 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1852 machine that doesn't implement getpriority(2).
1853
1854 =item getpwnam NAME
1855
1856 =item getgrnam NAME
1857
1858 =item gethostbyname NAME
1859
1860 =item getnetbyname NAME
1861
1862 =item getprotobyname NAME
1863
1864 =item getpwuid UID
1865
1866 =item getgrgid GID
1867
1868 =item getservbyname NAME,PROTO
1869
1870 =item gethostbyaddr ADDR,ADDRTYPE
1871
1872 =item getnetbyaddr ADDR,ADDRTYPE
1873
1874 =item getprotobynumber NUMBER
1875
1876 =item getservbyport PORT,PROTO
1877
1878 =item getpwent
1879
1880 =item getgrent
1881
1882 =item gethostent
1883
1884 =item getnetent
1885
1886 =item getprotoent
1887
1888 =item getservent
1889
1890 =item setpwent
1891
1892 =item setgrent
1893
1894 =item sethostent STAYOPEN
1895
1896 =item setnetent STAYOPEN
1897
1898 =item setprotoent STAYOPEN
1899
1900 =item setservent STAYOPEN
1901
1902 =item endpwent
1903
1904 =item endgrent
1905
1906 =item endhostent
1907
1908 =item endnetent
1909
1910 =item endprotoent
1911
1912 =item endservent
1913
1914 These routines perform the same functions as their counterparts in the
1915 system library.  In list context, the return values from the
1916 various get routines are as follows:
1917
1918     ($name,$passwd,$uid,$gid,
1919        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
1920     ($name,$passwd,$gid,$members) = getgr*
1921     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
1922     ($name,$aliases,$addrtype,$net) = getnet*
1923     ($name,$aliases,$proto) = getproto*
1924     ($name,$aliases,$port,$proto) = getserv*
1925
1926 (If the entry doesn't exist you get a null list.)
1927
1928 The exact meaning of the $gcos field varies but it usually contains
1929 the real name of the user (as opposed to the login name) and other
1930 information pertaining to the user.  Beware, however, that in many
1931 system users are able to change this information and therefore it
1932 cannot be trusted and therefore the $gcos is tainted (see
1933 L<perlsec>).  The $passwd and $shell, user's encrypted password and
1934 login shell, are also tainted, because of the same reason.
1935
1936 In scalar context, you get the name, unless the function was a
1937 lookup by name, in which case you get the other thing, whatever it is.
1938 (If the entry doesn't exist you get the undefined value.)  For example:
1939
1940     $uid   = getpwnam($name);
1941     $name  = getpwuid($num);
1942     $name  = getpwent();
1943     $gid   = getgrnam($name);
1944     $name  = getgrgid($num;
1945     $name  = getgrent();
1946     #etc.
1947
1948 In I<getpw*()> the fields $quota, $comment, and $expire are special
1949 cases in the sense that in many systems they are unsupported.  If the
1950 $quota is unsupported, it is an empty scalar.  If it is supported, it
1951 usually encodes the disk quota.  If the $comment field is unsupported,
1952 it is an empty scalar.  If it is supported it usually encodes some
1953 administrative comment about the user.  In some systems the $quota
1954 field may be $change or $age, fields that have to do with password
1955 aging.  In some systems the $comment field may be $class.  The $expire
1956 field, if present, encodes the expiration period of the account or the
1957 password.  For the availability and the exact meaning of these fields
1958 in your system, please consult your getpwnam(3) documentation and your
1959 F<pwd.h> file.  You can also find out from within Perl what your
1960 $quota and $comment fields mean and whether you have the $expire field
1961 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
1962 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
1963 files are only supported if your vendor has implemented them in the
1964 intuitive fashion that calling the regular C library routines gets the
1965 shadow versions if you're running under privilege or if there exists
1966 the shadow(3) functions as found in System V ( this includes Solaris
1967 and Linux.)  Those systems which implement a proprietary shadow password
1968 facility are unlikely to be supported.
1969
1970 The $members value returned by I<getgr*()> is a space separated list of
1971 the login names of the members of the group.
1972
1973 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
1974 C, it will be returned to you via C<$?> if the function call fails.  The
1975 C<@addrs> value returned by a successful call is a list of the raw
1976 addresses returned by the corresponding system library call.  In the
1977 Internet domain, each address is four bytes long and you can unpack it
1978 by saying something like:
1979
1980     ($a,$b,$c,$d) = unpack('C4',$addr[0]);
1981
1982 The Socket library makes this slightly easier:
1983
1984     use Socket;
1985     $iaddr = inet_aton("127.1"); # or whatever address
1986     $name  = gethostbyaddr($iaddr, AF_INET);
1987
1988     # or going the other way
1989     $straddr = inet_ntoa($iaddr);
1990
1991 If you get tired of remembering which element of the return list
1992 contains which return value, by-name interfaces are provided
1993 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
1994 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
1995 and C<User::grent>.  These override the normal built-ins, supplying
1996 versions that return objects with the appropriate names
1997 for each field.  For example:
1998
1999    use File::stat;
2000    use User::pwent;
2001    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2002
2003 Even though it looks like they're the same method calls (uid),
2004 they aren't, because a C<File::stat> object is different from
2005 a C<User::pwent> object.
2006
2007 =item getsockname SOCKET
2008
2009 Returns the packed sockaddr address of this end of the SOCKET connection,
2010 in case you don't know the address because you have several different
2011 IPs that the connection might have come in on.
2012
2013     use Socket;
2014     $mysockaddr = getsockname(SOCK);
2015     ($port, $myaddr) = sockaddr_in($mysockaddr);
2016     printf "Connect to %s [%s]\n",
2017        scalar gethostbyaddr($myaddr, AF_INET),
2018        inet_ntoa($myaddr);
2019
2020 =item getsockopt SOCKET,LEVEL,OPTNAME
2021
2022 Returns the socket option requested, or undef if there is an error.
2023
2024 =item glob EXPR
2025
2026 =item glob
2027
2028 Returns the value of EXPR with filename expansions such as the
2029 standard Unix shell F</bin/csh> would do.  This is the internal function
2030 implementing the C<< <*.c> >> operator, but you can use it directly.
2031 If EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is
2032 discussed in more detail in L<perlop/"I/O Operators">.
2033
2034 Beginning with v5.6.0, this operator is implemented using the standard
2035 C<File::Glob> extension.  See L<File::Glob> for details.
2036
2037 =item gmtime EXPR
2038
2039 Converts a time as returned by the time function to an 8-element list
2040 with the time localized for the standard Greenwich time zone.
2041 Typically used as follows:
2042
2043     #  0    1    2     3     4    5     6     7
2044     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday) =
2045                                             gmtime(time);
2046
2047 All list elements are numeric, and come straight out of the C `struct
2048 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2049 specified time.  $mday is the day of the month, and $mon is the month
2050 itself, in the range C<0..11> with 0 indicating January and 11
2051 indicating December.  $year is the number of years since 1900.  That
2052 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2053 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2054 the year, in the range C<0..364> (or C<0..365> in leap years.)
2055
2056 Note that the $year element is I<not> simply the last two digits of
2057 the year.  If you assume it is, then you create non-Y2K-compliant
2058 programs--and you wouldn't want to do that, would you?
2059
2060 The proper way to get a complete 4-digit year is simply:
2061
2062         $year += 1900;
2063
2064 And to get the last two digits of the year (e.g., '01' in 2001) do:
2065
2066         $year = sprintf("%02d", $year % 100);
2067
2068 If EXPR is omitted, C<gmtime()> uses the current time (C<gmtime(time)>).
2069
2070 In scalar context, C<gmtime()> returns the ctime(3) value:
2071
2072     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2073
2074 Also see the C<timegm> function provided by the C<Time::Local> module,
2075 and the strftime(3) function available via the POSIX module.
2076
2077 This scalar value is B<not> locale dependent (see L<perllocale>), but
2078 is instead a Perl builtin.  Also see the C<Time::Local> module, and the
2079 strftime(3) and mktime(3) functions available via the POSIX module.  To
2080 get somewhat similar but locale dependent date strings, set up your
2081 locale environment variables appropriately (please see L<perllocale>)
2082 and try for example:
2083
2084     use POSIX qw(strftime);
2085     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
2086
2087 Note that the C<%a> and C<%b> escapes, which represent the short forms
2088 of the day of the week and the month of the year, may not necessarily
2089 be three characters wide in all locales.
2090
2091 =item goto LABEL
2092
2093 =item goto EXPR
2094
2095 =item goto &NAME
2096
2097 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
2098 execution there.  It may not be used to go into any construct that
2099 requires initialization, such as a subroutine or a C<foreach> loop.  It
2100 also can't be used to go into a construct that is optimized away,
2101 or to get out of a block or subroutine given to C<sort>.
2102 It can be used to go almost anywhere else within the dynamic scope,
2103 including out of subroutines, but it's usually better to use some other
2104 construct such as C<last> or C<die>.  The author of Perl has never felt the
2105 need to use this form of C<goto> (in Perl, that is--C is another matter).
2106 (The difference being that C does not offer named loops combined with
2107 loop control.  Perl does, and this replaces most structured uses of C<goto>
2108 in other languages.)
2109
2110 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2111 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2112 necessarily recommended if you're optimizing for maintainability:
2113
2114     goto ("FOO", "BAR", "GLARCH")[$i];
2115
2116 The C<goto-&NAME> form is quite different from the other forms of
2117 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2118 doesn't have the stigma associated with other gotos.  Instead, it
2119 exits the current subroutine (losing any changes set by local()) and
2120 immediately calls in its place the named subroutine using the current
2121 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2122 load another subroutine and then pretend that the other subroutine had
2123 been called in the first place (except that any modifications to C<@_>
2124 in the current subroutine are propagated to the other subroutine.)
2125 After the C<goto>, not even C<caller> will be able to tell that this
2126 routine was called first.
2127
2128 NAME needn't be the name of a subroutine; it can be a scalar variable
2129 containing a code reference, or a block which evaluates to a code
2130 reference.
2131
2132 =item grep BLOCK LIST
2133
2134 =item grep EXPR,LIST
2135
2136 This is similar in spirit to, but not the same as, grep(1) and its
2137 relatives.  In particular, it is not limited to using regular expressions.
2138
2139 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2140 C<$_> to each element) and returns the list value consisting of those
2141 elements for which the expression evaluated to true.  In scalar
2142 context, returns the number of times the expression was true.
2143
2144     @foo = grep(!/^#/, @bar);    # weed out comments
2145
2146 or equivalently,
2147
2148     @foo = grep {!/^#/} @bar;    # weed out comments
2149
2150 Note that C<$_> is an alias to the list value, so it can be used to
2151 modify the elements of the LIST.  While this is useful and supported,
2152 it can cause bizarre results if the elements of LIST are not variables.
2153 Similarly, grep returns aliases into the original list, much as a for
2154 loop's index variable aliases the list elements.  That is, modifying an
2155 element of a list returned by grep (for example, in a C<foreach>, C<map>
2156 or another C<grep>) actually modifies the element in the original list.
2157 This is usually something to be avoided when writing clear code.
2158
2159 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2160
2161 =item hex EXPR
2162
2163 =item hex
2164
2165 Interprets EXPR as a hex string and returns the corresponding value.
2166 (To convert strings that might start with either 0, 0x, or 0b, see
2167 L</oct>.)  If EXPR is omitted, uses C<$_>.
2168
2169     print hex '0xAf'; # prints '175'
2170     print hex 'aF';   # same
2171
2172 Hex strings may only represent integers.  Strings that would cause
2173 integer overflow trigger a warning.  Leading whitespace is not stripped,
2174 unlike oct().
2175
2176 =item import
2177
2178 There is no builtin C<import> function.  It is just an ordinary
2179 method (subroutine) defined (or inherited) by modules that wish to export
2180 names to another module.  The C<use> function calls the C<import> method
2181 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2182
2183 =item index STR,SUBSTR,POSITION
2184
2185 =item index STR,SUBSTR
2186
2187 The index function searches for one string within another, but without
2188 the wildcard-like behavior of a full regular-expression pattern match.
2189 It returns the position of the first occurrence of SUBSTR in STR at
2190 or after POSITION.  If POSITION is omitted, starts searching from the
2191 beginning of the string.  The return value is based at C<0> (or whatever
2192 you've set the C<$[> variable to--but don't do that).  If the substring
2193 is not found, returns one less than the base, ordinarily C<-1>.
2194
2195 =item int EXPR
2196
2197 =item int
2198
2199 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2200 You should not use this function for rounding: one because it truncates
2201 towards C<0>, and two because machine representations of floating point
2202 numbers can sometimes produce counterintuitive results.  For example,
2203 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2204 because it's really more like -268.99999999999994315658 instead.  Usually,
2205 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2206 functions will serve you better than will int().
2207
2208 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2209
2210 Implements the ioctl(2) function.  You'll probably first have to say
2211
2212     require "ioctl.ph"; # probably in /usr/local/lib/perl/ioctl.ph
2213
2214 to get the correct function definitions.  If F<ioctl.ph> doesn't
2215 exist or doesn't have the correct definitions you'll have to roll your
2216 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2217 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2218 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2219 written depending on the FUNCTION--a pointer to the string value of SCALAR
2220 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2221 has no string value but does have a numeric value, that value will be
2222 passed rather than a pointer to the string value.  To guarantee this to be
2223 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2224 functions may be needed to manipulate the values of structures used by
2225 C<ioctl>.
2226
2227 The return value of C<ioctl> (and C<fcntl>) is as follows:
2228
2229         if OS returns:          then Perl returns:
2230             -1                    undefined value
2231              0                  string "0 but true"
2232         anything else               that number
2233
2234 Thus Perl returns true on success and false on failure, yet you can
2235 still easily determine the actual value returned by the operating
2236 system:
2237
2238     $retval = ioctl(...) || -1;
2239     printf "System returned %d\n", $retval;
2240
2241 The special string "C<0> but true" is exempt from B<-w> complaints
2242 about improper numeric conversions.
2243
2244 Here's an example of setting a filehandle named C<REMOTE> to be
2245 non-blocking at the system level.  You'll have to negotiate C<$|>
2246 on your own, though.
2247
2248     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
2249
2250     $flags = fcntl(REMOTE, F_GETFL, 0)
2251                 or die "Can't get flags for the socket: $!\n";
2252
2253     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
2254                 or die "Can't set flags for the socket: $!\n";
2255
2256 =item join EXPR,LIST
2257
2258 Joins the separate strings of LIST into a single string with fields
2259 separated by the value of EXPR, and returns that new string.  Example:
2260
2261     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2262
2263 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2264 first argument.  Compare L</split>.
2265
2266 =item keys HASH
2267
2268 Returns a list consisting of all the keys of the named hash.  (In
2269 scalar context, returns the number of keys.)  The keys are returned in
2270 an apparently random order.  The actual random order is subject to
2271 change in future versions of perl, but it is guaranteed to be the same
2272 order as either the C<values> or C<each> function produces (given
2273 that the hash has not been modified).  As a side effect, it resets
2274 HASH's iterator.
2275
2276 Here is yet another way to print your environment:
2277
2278     @keys = keys %ENV;
2279     @values = values %ENV;
2280     while (@keys) {
2281         print pop(@keys), '=', pop(@values), "\n";
2282     }
2283
2284 or how about sorted by key:
2285
2286     foreach $key (sort(keys %ENV)) {
2287         print $key, '=', $ENV{$key}, "\n";
2288     }
2289
2290 The returned values are copies of the original keys in the hash, so
2291 modifying them will not affect the original hash.  Compare L</values>.
2292
2293 To sort a hash by value, you'll need to use a C<sort> function.
2294 Here's a descending numeric sort of a hash by its values:
2295
2296     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2297         printf "%4d %s\n", $hash{$key}, $key;
2298     }
2299
2300 As an lvalue C<keys> allows you to increase the number of hash buckets
2301 allocated for the given hash.  This can gain you a measure of efficiency if
2302 you know the hash is going to get big.  (This is similar to pre-extending
2303 an array by assigning a larger number to $#array.)  If you say
2304
2305     keys %hash = 200;
2306
2307 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2308 in fact, since it rounds up to the next power of two.  These
2309 buckets will be retained even if you do C<%hash = ()>, use C<undef
2310 %hash> if you want to free the storage while C<%hash> is still in scope.
2311 You can't shrink the number of buckets allocated for the hash using
2312 C<keys> in this way (but you needn't worry about doing this by accident,
2313 as trying has no effect).
2314
2315 See also C<each>, C<values> and C<sort>.
2316
2317 =item kill SIGNAL, LIST
2318
2319 Sends a signal to a list of processes.  Returns the number of
2320 processes successfully signaled (which is not necessarily the
2321 same as the number actually killed).
2322
2323     $cnt = kill 1, $child1, $child2;
2324     kill 9, @goners;
2325
2326 If SIGNAL is zero, no signal is sent to the process.  This is a
2327 useful way to check that the process is alive and hasn't changed
2328 its UID.  See L<perlport> for notes on the portability of this
2329 construct.
2330
2331 Unlike in the shell, if SIGNAL is negative, it kills
2332 process groups instead of processes.  (On System V, a negative I<PROCESS>
2333 number will also kill process groups, but that's not portable.)  That
2334 means you usually want to use positive not negative signals.  You may also
2335 use a signal name in quotes.  See L<perlipc/"Signals"> for details.
2336
2337 =item last LABEL
2338
2339 =item last
2340
2341 The C<last> command is like the C<break> statement in C (as used in
2342 loops); it immediately exits the loop in question.  If the LABEL is
2343 omitted, the command refers to the innermost enclosing loop.  The
2344 C<continue> block, if any, is not executed:
2345
2346     LINE: while (<STDIN>) {
2347         last LINE if /^$/;      # exit when done with header
2348         #...
2349     }
2350
2351 C<last> cannot be used to exit a block which returns a value such as
2352 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2353 a grep() or map() operation.
2354
2355 Note that a block by itself is semantically identical to a loop
2356 that executes once.  Thus C<last> can be used to effect an early
2357 exit out of such a block.
2358
2359 See also L</continue> for an illustration of how C<last>, C<next>, and
2360 C<redo> work.
2361
2362 =item lc EXPR
2363
2364 =item lc
2365
2366 Returns a lowercased version of EXPR.  This is the internal function
2367 implementing the C<\L> escape in double-quoted strings.  Respects
2368 current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>
2369 and L<perlunicode> for more details about locale and Unicode support.
2370
2371 If EXPR is omitted, uses C<$_>.
2372
2373 =item lcfirst EXPR
2374
2375 =item lcfirst
2376
2377 Returns the value of EXPR with the first character lowercased.  This
2378 is the internal function implementing the C<\l> escape in
2379 double-quoted strings.  Respects current LC_CTYPE locale if C<use
2380 locale> in force.  See L<perllocale> and L<perlunicode> for more
2381 details about locale and Unicode support.
2382
2383 If EXPR is omitted, uses C<$_>.
2384
2385 =item length EXPR
2386
2387 =item length
2388
2389 Returns the length in characters of the value of EXPR.  If EXPR is
2390 omitted, returns length of C<$_>.  Note that this cannot be used on
2391 an entire array or hash to find out how many elements these have.
2392 For that, use C<scalar @array> and C<scalar keys %hash> respectively.
2393
2394 =item link OLDFILE,NEWFILE
2395
2396 Creates a new filename linked to the old filename.  Returns true for
2397 success, false otherwise.
2398
2399 =item listen SOCKET,QUEUESIZE
2400
2401 Does the same thing that the listen system call does.  Returns true if
2402 it succeeded, false otherwise.  See the example in
2403 L<perlipc/"Sockets: Client/Server Communication">.
2404
2405 =item local EXPR
2406
2407 You really probably want to be using C<my> instead, because C<local> isn't
2408 what most people think of as "local".  See
2409 L<perlsub/"Private Variables via my()"> for details.
2410
2411 A local modifies the listed variables to be local to the enclosing
2412 block, file, or eval.  If more than one value is listed, the list must
2413 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2414 for details, including issues with tied arrays and hashes.
2415
2416 =item localtime EXPR
2417
2418 Converts a time as returned by the time function to a 9-element list
2419 with the time analyzed for the local time zone.  Typically used as
2420 follows:
2421
2422     #  0    1    2     3     4    5     6     7     8
2423     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2424                                                 localtime(time);
2425
2426 All list elements are numeric, and come straight out of the C `struct
2427 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2428 specified time.  $mday is the day of the month, and $mon is the month
2429 itself, in the range C<0..11> with 0 indicating January and 11
2430 indicating December.  $year is the number of years since 1900.  That
2431 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2432 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2433 the year, in the range C<0..364> (or C<0..365> in leap years.)  $isdst
2434 is true if the specified time occurs during daylight savings time,
2435 false otherwise.
2436
2437 Note that the $year element is I<not> simply the last two digits of
2438 the year.  If you assume it is, then you create non-Y2K-compliant
2439 programs--and you wouldn't want to do that, would you?
2440
2441 The proper way to get a complete 4-digit year is simply:
2442
2443         $year += 1900;
2444
2445 And to get the last two digits of the year (e.g., '01' in 2001) do:
2446
2447         $year = sprintf("%02d", $year % 100);
2448
2449 If EXPR is omitted, C<localtime()> uses the current time (C<localtime(time)>).
2450
2451 In scalar context, C<localtime()> returns the ctime(3) value:
2452
2453     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2454
2455 This scalar value is B<not> locale dependent, see L<perllocale>, but
2456 instead a Perl builtin.  Also see the C<Time::Local> module
2457 (to convert the second, minutes, hours, ... back to seconds since the
2458 stroke of midnight the 1st of January 1970, the value returned by
2459 time()), and the strftime(3) and mktime(3) functions available via the
2460 POSIX module.  To get somewhat similar but locale dependent date
2461 strings, set up your locale environment variables appropriately
2462 (please see L<perllocale>) and try for example:
2463
2464     use POSIX qw(strftime);
2465     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2466
2467 Note that the C<%a> and C<%b>, the short forms of the day of the week
2468 and the month of the year, may not necessarily be three characters wide.
2469
2470 =item lock THING
2471
2472 This function places an advisory lock on a variable, subroutine,
2473 or referenced object contained in I<THING> until the lock goes out
2474 of scope.  This is a built-in function only if your version of Perl
2475 was built with threading enabled, and if you've said C<use Thread>.
2476 Otherwise a user-defined function by this name will be called.
2477 See L<Thread>.
2478
2479 =item log EXPR
2480
2481 =item log
2482
2483 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2484 returns log of C<$_>.  To get the log of another base, use basic algebra:
2485 The base-N log of a number is equal to the natural log of that number
2486 divided by the natural log of N.  For example:
2487
2488     sub log10 {
2489         my $n = shift;
2490         return log($n)/log(10);
2491     }
2492
2493 See also L</exp> for the inverse operation.
2494
2495 =item lstat EXPR
2496
2497 =item lstat
2498
2499 Does the same thing as the C<stat> function (including setting the
2500 special C<_> filehandle) but stats a symbolic link instead of the file
2501 the symbolic link points to.  If symbolic links are unimplemented on
2502 your system, a normal C<stat> is done.
2503
2504 If EXPR is omitted, stats C<$_>.
2505
2506 =item m//
2507
2508 The match operator.  See L<perlop>.
2509
2510 =item map BLOCK LIST
2511
2512 =item map EXPR,LIST
2513
2514 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2515 C<$_> to each element) and returns the list value composed of the
2516 results of each such evaluation.  In scalar context, returns the
2517 total number of elements so generated.  Evaluates BLOCK or EXPR in
2518 list context, so each element of LIST may produce zero, one, or
2519 more elements in the returned value.
2520
2521     @chars = map(chr, @nums);
2522
2523 translates a list of numbers to the corresponding characters.  And
2524
2525     %hash = map { getkey($_) => $_ } @array;
2526
2527 is just a funny way to write
2528
2529     %hash = ();
2530     foreach $_ (@array) {
2531         $hash{getkey($_)} = $_;
2532     }
2533
2534 Note that C<$_> is an alias to the list value, so it can be used to
2535 modify the elements of the LIST.  While this is useful and supported,
2536 it can cause bizarre results if the elements of LIST are not variables.
2537 Using a regular C<foreach> loop for this purpose would be clearer in
2538 most cases.  See also L</grep> for an array composed of those items of
2539 the original list for which the BLOCK or EXPR evaluates to true.
2540
2541 C<{> starts both hash references and blocks, so C<map { ...> could be either
2542 the start of map BLOCK LIST or map EXPR, LIST. Because perl doesn't look
2543 ahead for the closing C<}> it has to take a guess at which its dealing with
2544 based what it finds just after the C<{>. Usually it gets it right, but if it
2545 doesn't it won't realize something is wrong until it gets to the C<}> and
2546 encounters the missing (or unexpected) comma. The syntax error will be
2547 reported close to the C<}> but you'll need to change something near the C<{>
2548 such as using a unary C<+> to give perl some help:
2549
2550     %hash = map {  "\L$_", 1  } @array  # perl guesses EXPR.  wrong
2551     %hash = map { +"\L$_", 1  } @array  # perl guesses BLOCK. right
2552     %hash = map { ("\L$_", 1) } @array  # this also works
2553     %hash = map {  lc($_), 1  } @array  # as does this.
2554     %hash = map +( lc($_), 1 ), @array  # this is EXPR and works!
2555
2556     %hash = map  ( lc($_), 1 ), @array  # evaluates to (1, @array)
2557
2558 or to force an anon hash constructor use C<+{>
2559
2560    @hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end
2561
2562 and you get list of anonymous hashes each with only 1 entry.
2563
2564 =item mkdir FILENAME,MASK
2565
2566 =item mkdir FILENAME
2567
2568 Creates the directory specified by FILENAME, with permissions
2569 specified by MASK (as modified by C<umask>).  If it succeeds it
2570 returns true, otherwise it returns false and sets C<$!> (errno).
2571 If omitted, MASK defaults to 0777.
2572
2573 In general, it is better to create directories with permissive MASK,
2574 and let the user modify that with their C<umask>, than it is to supply
2575 a restrictive MASK and give the user no way to be more permissive.
2576 The exceptions to this rule are when the file or directory should be
2577 kept private (mail files, for instance).  The perlfunc(1) entry on
2578 C<umask> discusses the choice of MASK in more detail.
2579
2580 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
2581 number of trailing slashes.  Some operating and filesystems do not get
2582 this right, so Perl automatically removes all trailing slashes to keep
2583 everyone happy.
2584
2585 =item msgctl ID,CMD,ARG
2586
2587 Calls the System V IPC function msgctl(2).  You'll probably have to say
2588
2589     use IPC::SysV;
2590
2591 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2592 then ARG must be a variable which will hold the returned C<msqid_ds>
2593 structure.  Returns like C<ioctl>: the undefined value for error,
2594 C<"0 but true"> for zero, or the actual return value otherwise.  See also
2595 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::Semaphore> documentation.
2596
2597 =item msgget KEY,FLAGS
2598
2599 Calls the System V IPC function msgget(2).  Returns the message queue
2600 id, or the undefined value if there is an error.  See also
2601 L<perlipc/"SysV IPC"> and C<IPC::SysV> and C<IPC::Msg> documentation.
2602
2603 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2604
2605 Calls the System V IPC function msgrcv to receive a message from
2606 message queue ID into variable VAR with a maximum message size of
2607 SIZE.  Note that when a message is received, the message type as a
2608 native long integer will be the first thing in VAR, followed by the
2609 actual message.  This packing may be opened with C<unpack("l! a*")>.
2610 Taints the variable.  Returns true if successful, or false if there is
2611 an error.  See also L<perlipc/"SysV IPC">, C<IPC::SysV>, and
2612 C<IPC::SysV::Msg> documentation.
2613
2614 =item msgsnd ID,MSG,FLAGS
2615
2616 Calls the System V IPC function msgsnd to send the message MSG to the
2617 message queue ID.  MSG must begin with the native long integer message
2618 type, and be followed by the length of the actual message, and finally
2619 the message itself.  This kind of packing can be achieved with
2620 C<pack("l! a*", $type, $message)>.  Returns true if successful,
2621 or false if there is an error.  See also C<IPC::SysV>
2622 and C<IPC::SysV::Msg> documentation.
2623
2624 =item my EXPR
2625
2626 =item my EXPR : ATTRIBUTES
2627
2628 A C<my> declares the listed variables to be local (lexically) to the
2629 enclosing block, file, or C<eval>.  If
2630 more than one value is listed, the list must be placed in parentheses.  See
2631 L<perlsub/"Private Variables via my()"> for details.
2632
2633 =item next LABEL
2634
2635 =item next
2636
2637 The C<next> command is like the C<continue> statement in C; it starts
2638 the next iteration of the loop:
2639
2640     LINE: while (<STDIN>) {
2641         next LINE if /^#/;      # discard comments
2642         #...
2643     }
2644
2645 Note that if there were a C<continue> block on the above, it would get
2646 executed even on discarded lines.  If the LABEL is omitted, the command
2647 refers to the innermost enclosing loop.
2648
2649 C<next> cannot be used to exit a block which returns a value such as
2650 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2651 a grep() or map() operation.
2652
2653 Note that a block by itself is semantically identical to a loop
2654 that executes once.  Thus C<next> will exit such a block early.
2655
2656 See also L</continue> for an illustration of how C<last>, C<next>, and
2657 C<redo> work.
2658
2659 =item no Module VERSION LIST
2660
2661 =item no Module VERSION
2662
2663 =item no Module LIST
2664
2665 =item no Module
2666
2667 See the L</use> function, which C<no> is the opposite of.
2668
2669 =item oct EXPR
2670
2671 =item oct
2672
2673 Interprets EXPR as an octal string and returns the corresponding
2674 value.  (If EXPR happens to start off with C<0x>, interprets it as a
2675 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
2676 binary string.  Leading whitespace is ignored in all three cases.)
2677 The following will handle decimal, binary, octal, and hex in the standard
2678 Perl or C notation:
2679
2680     $val = oct($val) if $val =~ /^0/;
2681
2682 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
2683 in octal), use sprintf() or printf():
2684
2685     $perms = (stat("filename"))[2] & 07777;
2686     $oct_perms = sprintf "%lo", $perms;
2687
2688 The oct() function is commonly used when a string such as C<644> needs
2689 to be converted into a file mode, for example. (Although perl will
2690 automatically convert strings into numbers as needed, this automatic
2691 conversion assumes base 10.)
2692
2693 =item open FILEHANDLE,EXPR
2694
2695 =item open FILEHANDLE,MODE,EXPR
2696
2697 =item open FILEHANDLE,MODE,EXPR,LIST
2698
2699 =item open FILEHANDLE,MODE,REFERENCE
2700
2701 =item open FILEHANDLE
2702
2703 Opens the file whose filename is given by EXPR, and associates it with
2704 FILEHANDLE.
2705
2706 (The following is a comprehensive reference to open(): for a gentler
2707 introduction you may consider L<perlopentut>.)
2708
2709 If FILEHANDLE is an undefined lexical (C<my>) variable the variable is
2710 assigned a reference to a new anonymous filehandle, otherwise if
2711 FILEHANDLE is an expression, its value is used as the name of the real
2712 filehandle wanted.  (This is considered a symbolic reference, so C<use
2713 strict 'refs'> should I<not> be in effect.)
2714
2715 If EXPR is omitted, the scalar variable of the same name as the
2716 FILEHANDLE contains the filename.  (Note that lexical variables--those
2717 declared with C<my>--will not work for this purpose; so if you're
2718 using C<my>, specify EXPR in your call to open.) 
2719
2720 If three or more arguments are specified then the mode of opening and
2721 the file name are separate. If MODE is C<< '<' >> or nothing, the file
2722 is opened for input.  If MODE is C<< '>' >>, the file is truncated and
2723 opened for output, being created if necessary.  If MODE is C<<< '>>' >>>,
2724 the file is opened for appending, again being created if necessary.
2725
2726 You can put a C<'+'> in front of the C<< '>' >> or C<< '<' >> to
2727 indicate that you want both read and write access to the file; thus
2728 C<< '+<' >> is almost always preferred for read/write updates--the C<<
2729 '+>' >> mode would clobber the file first.  You can't usually use
2730 either read-write mode for updating textfiles, since they have
2731 variable length records.  See the B<-i> switch in L<perlrun> for a
2732 better approach.  The file is created with permissions of C<0666>
2733 modified by the process' C<umask> value.
2734
2735 These various prefixes correspond to the fopen(3) modes of C<'r'>,
2736 C<'r+'>, C<'w'>, C<'w+'>, C<'a'>, and C<'a+'>.
2737
2738 In the 2-arguments (and 1-argument) form of the call the mode and
2739 filename should be concatenated (in this order), possibly separated by
2740 spaces.  It is possible to omit the mode in these forms if the mode is
2741 C<< '<' >>.
2742
2743 If the filename begins with C<'|'>, the filename is interpreted as a
2744 command to which output is to be piped, and if the filename ends with a
2745 C<'|'>, the filename is interpreted as a command which pipes output to
2746 us.  See L<perlipc/"Using open() for IPC">
2747 for more examples of this.  (You are not allowed to C<open> to a command
2748 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2749 and L<perlipc/"Bidirectional Communication with Another Process">
2750 for alternatives.)
2751
2752 For three or more arguments if MODE is C<'|-'>, the filename is
2753 interpreted as a command to which output is to be piped, and if MODE
2754 is C<'-|'>, the filename is interpreted as a command which pipes
2755 output to us.  In the 2-arguments (and 1-argument) form one should
2756 replace dash (C<'-'>) with the command.
2757 See L<perlipc/"Using open() for IPC"> for more examples of this.
2758 (You are not allowed to C<open> to a command that pipes both in I<and>
2759 out, but see L<IPC::Open2>, L<IPC::Open3>, and
2760 L<perlipc/"Bidirectional Communication"> for alternatives.)
2761
2762 In the three-or-more argument form of pipe opens, if LIST is specified
2763 (extra arguments after the command name) then LIST becomes arguments
2764 to the command invoked if the platform supports it.  The meaning of
2765 C<open> with more than three arguments for non-pipe modes is not yet
2766 specified. Experimental "layers" may give extra LIST arguments
2767 meaning.
2768
2769 In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN
2770 and opening C<< '>-' >> opens STDOUT.
2771
2772 You may use the three-argument form of open to specify
2773 I<I/O disciplines> that affect how the input and output
2774 are processed: see L</binmode> and L<open>.  For example
2775
2776   open(FH, "<:utf8", "file")
2777
2778 will open the UTF-8 encoded file containing Unicode characters,
2779 see L<perluniintro>.
2780
2781 Open returns nonzero upon success, the undefined value otherwise.  If
2782 the C<open> involved a pipe, the return value happens to be the pid of
2783 the subprocess.
2784
2785 If you're running Perl on a system that distinguishes between text
2786 files and binary files, then you should check out L</binmode> for tips
2787 for dealing with this.  The key distinction between systems that need
2788 C<binmode> and those that don't is their text file formats.  Systems
2789 like Unix, MacOS, and Plan9, which delimit lines with a single
2790 character, and which encode that character in C as C<"\n">, do not
2791 need C<binmode>.  The rest need it.
2792
2793 In the three argument form MODE may also contain a list of IO "layers"
2794 (see L<open> and L<PerlIO> for more details) to be applied to the
2795 handle. This can be used to achieve the effect of C<binmode> as well
2796 as more complex behaviours.
2797
2798 When opening a file, it's usually a bad idea to continue normal execution
2799 if the request failed, so C<open> is frequently used in connection with
2800 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
2801 where you want to make a nicely formatted error message (but there are
2802 modules that can help with that problem)) you should always check
2803 the return value from opening a file.  The infrequent exception is when
2804 working with an unopened filehandle is actually what you want to do.
2805
2806 As a special case the 3 arg form with a read/write mode and the third
2807 argument being C<undef>:
2808
2809     open(TMP, "+>", undef) or die ...
2810
2811 opens a filehandle to an anonymous temporary file.
2812
2813 File handles can be opened to "in memory" files held in Perl scalars via:
2814
2815     open($fh, '>', \$variable) || ..
2816
2817 Though if you try to re-open C<STDOUT> or C<STDERR> as an "in memory"
2818 file, you have to close it first:
2819
2820     close STDOUT;
2821     open STDOUT, '>', \$variable or die "Can't open STDOUT: $!";
2822
2823 Examples:
2824
2825     $ARTICLE = 100;
2826     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
2827     while (<ARTICLE>) {...
2828
2829     open(LOG, '>>/usr/spool/news/twitlog');     # (log is reserved)
2830     # if the open fails, output is discarded
2831
2832     open(DBASE, '+<', 'dbase.mine')             # open for update
2833         or die "Can't open 'dbase.mine' for update: $!";
2834
2835     open(DBASE, '+<dbase.mine')                 # ditto
2836         or die "Can't open 'dbase.mine' for update: $!";
2837
2838     open(ARTICLE, '-|', "caesar <$article")     # decrypt article
2839         or die "Can't start caesar: $!";
2840
2841     open(ARTICLE, "caesar <$article |")         # ditto
2842         or die "Can't start caesar: $!";
2843
2844     open(EXTRACT, "|sort >/tmp/Tmp$$")          # $$ is our process id
2845         or die "Can't start sort: $!";
2846
2847     # in memory files
2848     open(MEMORY,'>', \$var)
2849         or die "Can't open memory file: $!";
2850     print MEMORY "foo!\n";                      # output will end up in $var
2851
2852     # process argument list of files along with any includes
2853
2854     foreach $file (@ARGV) {
2855         process($file, 'fh00');
2856     }
2857
2858     sub process {
2859         my($filename, $input) = @_;
2860         $input++;               # this is a string increment
2861         unless (open($input, $filename)) {
2862             print STDERR "Can't open $filename: $!\n";
2863             return;
2864         }
2865
2866         local $_;
2867         while (<$input>) {              # note use of indirection
2868             if (/^#include "(.*)"/) {
2869                 process($1, $input);
2870                 next;
2871             }
2872             #...                # whatever
2873         }
2874     }
2875
2876 You may also, in the Bourne shell tradition, specify an EXPR beginning
2877 with C<< '>&' >>, in which case the rest of the string is interpreted as the
2878 name of a filehandle (or file descriptor, if numeric) to be
2879 duped and opened.  You may use C<&> after C<< > >>, C<<< >> >>>,
2880 C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.  The
2881 mode you specify should match the mode of the original filehandle.
2882 (Duping a filehandle does not take into account any existing contents of
2883 IO buffers.) If you use the 3 arg form then you can pass either a number,
2884 the name of a filehandle or the normal "reference to a glob".
2885
2886 Here is a script that saves, redirects, and restores C<STDOUT> and
2887 C<STDERR> using various methods:
2888
2889     #!/usr/bin/perl
2890     open my $oldout, ">&STDOUT"     or die "Can't dup STDOUT: $!";
2891     open OLDERR,     ">&", \*STDERR or die "Can't dup STDERR: $!";
2892  
2893     open STDOUT, '>', "foo.out" or die "Can't redirect STDOUT: $!";
2894     open STDERR, ">&STDOUT"     or die "Can't dup STDOUT: $!";
2895
2896     select STDERR; $| = 1;      # make unbuffered
2897     select STDOUT; $| = 1;      # make unbuffered
2898
2899     print STDOUT "stdout 1\n";  # this works for
2900     print STDERR "stderr 1\n";  # subprocesses too
2901
2902     close STDOUT;
2903     close STDERR;
2904
2905     open STDOUT, ">&", $oldout or die "Can't dup \$oldout: $!";
2906     open STDERR, ">&OLDERR"    or die "Can't dup OLDERR: $!";
2907
2908     print STDOUT "stdout 2\n";
2909     print STDERR "stderr 2\n";
2910
2911 If you specify C<< '<&=N' >>, where C<N> is a number, then Perl will
2912 do an equivalent of C's C<fdopen> of that file descriptor; this is
2913 more parsimonious of file descriptors.  For example:
2914
2915     open(FILEHANDLE, "<&=$fd")
2916
2917 or
2918
2919     open(FILEHANDLE, "<&=", $fd)
2920
2921 Note that if Perl is using the standard C libraries' fdopen() then on
2922 many UNIX systems, fdopen() is known to fail when file descriptors
2923 exceed a certain value, typically 255. If you need more file
2924 descriptors than that, consider rebuilding Perl to use the C<PerlIO>.
2925
2926 You can see whether Perl has been compiled with PerlIO or not by
2927 running C<perl -V> and looking for C<useperlio=> line.  If C<useperlio>
2928 is C<define>, you have PerlIO, otherwise you don't.
2929
2930 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
2931 with 2-arguments (or 1-argument) form of open(), then
2932 there is an implicit fork done, and the return value of open is the pid
2933 of the child within the parent process, and C<0> within the child
2934 process.  (Use C<defined($pid)> to determine whether the open was successful.)
2935 The filehandle behaves normally for the parent, but i/o to that
2936 filehandle is piped from/to the STDOUT/STDIN of the child process.
2937 In the child process the filehandle isn't opened--i/o happens from/to
2938 the new STDOUT or STDIN.  Typically this is used like the normal
2939 piped open when you want to exercise more control over just how the
2940 pipe command gets executed, such as when you are running setuid, and
2941 don't want to have to scan shell commands for metacharacters.
2942 The following triples are more or less equivalent:
2943
2944     open(FOO, "|tr '[a-z]' '[A-Z]'");
2945     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
2946     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
2947     open(FOO, '|-', "tr", '[a-z]', '[A-Z]');
2948
2949     open(FOO, "cat -n '$file'|");
2950     open(FOO, '-|', "cat -n '$file'");
2951     open(FOO, '-|') || exec 'cat', '-n', $file;
2952     open(FOO, '-|', "cat", '-n', $file);
2953
2954 The last example in each block shows the pipe as "list form", which is
2955 not yet supported on all platforms.
2956
2957 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
2958
2959 Beginning with v5.6.0, Perl will attempt to flush all files opened for
2960 output before any operation that may do a fork, but this may not be
2961 supported on some platforms (see L<perlport>).  To be safe, you may need
2962 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
2963 of C<IO::Handle> on any open handles.
2964
2965 On systems that support a close-on-exec flag on files, the flag will
2966 be set for the newly opened file descriptor as determined by the value
2967 of $^F.  See L<perlvar/$^F>.
2968
2969 Closing any piped filehandle causes the parent process to wait for the
2970 child to finish, and returns the status value in C<$?>.
2971
2972 The filename passed to 2-argument (or 1-argument) form of open() will
2973 have leading and trailing whitespace deleted, and the normal
2974 redirection characters honored.  This property, known as "magic open",
2975 can often be used to good effect.  A user could specify a filename of
2976 F<"rsh cat file |">, or you could change certain filenames as needed:
2977
2978     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
2979     open(FH, $filename) or die "Can't open $filename: $!";
2980
2981 Use 3-argument form to open a file with arbitrary weird characters in it,
2982
2983     open(FOO, '<', $file);
2984
2985 otherwise it's necessary to protect any leading and trailing whitespace:
2986
2987     $file =~ s#^(\s)#./$1#;
2988     open(FOO, "< $file\0");
2989
2990 (this may not work on some bizarre filesystems).  One should
2991 conscientiously choose between the I<magic> and 3-arguments form
2992 of open():
2993
2994     open IN, $ARGV[0];
2995
2996 will allow the user to specify an argument of the form C<"rsh cat file |">,
2997 but will not work on a filename which happens to have a trailing space, while
2998
2999     open IN, '<', $ARGV[0];
3000
3001 will have exactly the opposite restrictions.
3002
3003 If you want a "real" C C<open> (see L<open(2)> on your system), then you
3004 should use the C<sysopen> function, which involves no such magic (but
3005 may use subtly different filemodes than Perl open(), which is mapped
3006 to C fopen()).  This is
3007 another way to protect your filenames from interpretation.  For example:
3008
3009     use IO::Handle;
3010     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
3011         or die "sysopen $path: $!";
3012     $oldfh = select(HANDLE); $| = 1; select($oldfh);
3013     print HANDLE "stuff $$\n";
3014     seek(HANDLE, 0, 0);
3015     print "File contains: ", <HANDLE>;
3016
3017 Using the constructor from the C<IO::Handle> package (or one of its
3018 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3019 filehandles that have the scope of whatever variables hold references to
3020 them, and automatically close whenever and however you leave that scope:
3021
3022     use IO::File;
3023     #...
3024     sub read_myfile_munged {
3025         my $ALL = shift;
3026         my $handle = new IO::File;
3027         open($handle, "myfile") or die "myfile: $!";
3028         $first = <$handle>
3029             or return ();     # Automatically closed here.
3030         mung $first or die "mung failed";       # Or here.
3031         return $first, <$handle> if $ALL;       # Or here.
3032         $first;                                 # Or here.
3033     }
3034
3035 See L</seek> for some details about mixing reading and writing.
3036
3037 =item opendir DIRHANDLE,EXPR
3038
3039 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3040 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3041 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3042
3043 =item ord EXPR
3044
3045 =item ord
3046
3047 Returns the numeric (the native 8-bit encoding, like ASCII or EBCDIC,
3048 or Unicode) value of the first character of EXPR.  If EXPR is omitted,
3049 uses C<$_>.
3050
3051 For the reverse, see L</chr>.
3052 See L<perlunicode> and L<encoding> for more about Unicode.
3053
3054 =item our EXPR
3055
3056 =item our EXPR : ATTRIBUTES
3057
3058 An C<our> declares the listed variables to be valid globals within
3059 the enclosing block, file, or C<eval>.  That is, it has the same
3060 scoping rules as a "my" declaration, but does not create a local
3061 variable.  If more than one value is listed, the list must be placed
3062 in parentheses.  The C<our> declaration has no semantic effect unless
3063 "use strict vars" is in effect, in which case it lets you use the
3064 declared global variable without qualifying it with a package name.
3065 (But only within the lexical scope of the C<our> declaration.  In this
3066 it differs from "use vars", which is package scoped.)
3067
3068 An C<our> declaration declares a global variable that will be visible
3069 across its entire lexical scope, even across package boundaries.  The
3070 package in which the variable is entered is determined at the point
3071 of the declaration, not at the point of use.  This means the following
3072 behavior holds:
3073
3074     package Foo;
3075     our $bar;           # declares $Foo::bar for rest of lexical scope
3076     $bar = 20;
3077
3078     package Bar;
3079     print $bar;         # prints 20
3080
3081 Multiple C<our> declarations in the same lexical scope are allowed
3082 if they are in different packages.  If they happened to be in the same
3083 package, Perl will emit warnings if you have asked for them.
3084
3085     use warnings;
3086     package Foo;
3087     our $bar;           # declares $Foo::bar for rest of lexical scope
3088     $bar = 20;
3089
3090     package Bar;
3091     our $bar = 30;      # declares $Bar::bar for rest of lexical scope
3092     print $bar;         # prints 30
3093
3094     our $bar;           # emits warning
3095
3096 An C<our> declaration may also have a list of attributes associated
3097 with it.  B<WARNING>: This is an experimental feature that may be
3098 changed or removed in future releases of Perl.  It should not be
3099 relied upon.
3100
3101 The only currently recognized attribute is C<unique> which indicates
3102 that a single copy of the global is to be used by all interpreters
3103 should the program happen to be running in a multi-interpreter
3104 environment. (The default behaviour would be for each interpreter to
3105 have its own copy of the global.)  In such an environment, this
3106 attribute also has the effect of making the global readonly.
3107 Examples:
3108
3109     our @EXPORT : unique = qw(foo);
3110     our %EXPORT_TAGS : unique = (bar => [qw(aa bb cc)]);
3111     our $VERSION : unique = "1.00";
3112
3113 Multi-interpreter environments can come to being either through the
3114 fork() emulation on Windows platforms, or by embedding perl in a
3115 multi-threaded application.  The C<unique> attribute does nothing in
3116 all other environments.
3117
3118 =item pack TEMPLATE,LIST
3119
3120 Takes a LIST of values and converts it into a string using the rules
3121 given by the TEMPLATE.  The resulting string is the concatenation of
3122 the converted values.  Typically, each converted value looks
3123 like its machine-level representation.  For example, on 32-bit machines
3124 a converted integer may be represented by a sequence of 4 bytes.
3125
3126 The TEMPLATE is a sequence of characters that give the order and type
3127 of values, as follows:
3128
3129     a   A string with arbitrary binary data, will be null padded.
3130     A   A text (ASCII) string, will be space padded.
3131     Z   A null terminated (ASCIZ) string, will be null padded.
3132
3133     b   A bit string (ascending bit order inside each byte, like vec()).
3134     B   A bit string (descending bit order inside each byte).
3135     h   A hex string (low nybble first).
3136     H   A hex string (high nybble first).
3137
3138     c   A signed char value.
3139     C   An unsigned char value.  Only does bytes.  See U for Unicode.
3140
3141     s   A signed short value.
3142     S   An unsigned short value.
3143           (This 'short' is _exactly_ 16 bits, which may differ from
3144            what a local C compiler calls 'short'.  If you want
3145            native-length shorts, use the '!' suffix.)
3146
3147     i   A signed integer value.
3148     I   An unsigned integer value.
3149           (This 'integer' is _at_least_ 32 bits wide.  Its exact
3150            size depends on what a local C compiler calls 'int',
3151            and may even be larger than the 'long' described in
3152            the next item.)
3153
3154     l   A signed long value.
3155     L   An unsigned long value.
3156           (This 'long' is _exactly_ 32 bits, which may differ from
3157            what a local C compiler calls 'long'.  If you want
3158            native-length longs, use the '!' suffix.)
3159
3160     n   An unsigned short in "network" (big-endian) order.
3161     N   An unsigned long in "network" (big-endian) order.
3162     v   An unsigned short in "VAX" (little-endian) order.
3163     V   An unsigned long in "VAX" (little-endian) order.
3164           (These 'shorts' and 'longs' are _exactly_ 16 bits and
3165            _exactly_ 32 bits, respectively.)
3166
3167     q   A signed quad (64-bit) value.
3168     Q   An unsigned quad value.
3169           (Quads are available only if your system supports 64-bit
3170            integer values _and_ if Perl has been compiled to support those.
3171            Causes a fatal error otherwise.)
3172
3173     j   A signed integer value (a Perl internal integer, IV).
3174     J   An unsigned integer value (a Perl internal unsigned integer, UV).
3175
3176     f   A single-precision float in the native format.
3177     d   A double-precision float in the native format.
3178
3179     F   A floating point value in the native native format
3180            (a Perl internal floating point value, NV).
3181     D   A long double-precision float in the native format.
3182           (Long doubles are available only if your system supports long
3183            double values _and_ if Perl has been compiled to support those.
3184            Causes a fatal error otherwise.)
3185
3186     p   A pointer to a null-terminated string.
3187     P   A pointer to a structure (fixed-length string).
3188
3189     u   A uuencoded string.
3190     U   A Unicode character number.  Encodes to UTF-8 internally
3191         (or UTF-EBCDIC in EBCDIC platforms).
3192
3193     w   A BER compressed integer.  Its bytes represent an unsigned
3194         integer in base 128, most significant digit first, with as
3195         few digits as possible.  Bit eight (the high bit) is set
3196         on each byte except the last.
3197
3198     x   A null byte.
3199     X   Back up a byte.
3200     @   Null fill to absolute position.
3201     (   Start of a ()-group.
3202
3203 The following rules apply:
3204
3205 =over 8
3206
3207 =item *
3208
3209 Each letter may optionally be followed by a number giving a repeat
3210 count.  With all types except C<a>, C<A>, C<Z>, C<b>, C<B>, C<h>,
3211 C<H>, C<@>, C<x>, C<X> and C<P> the pack function will gobble up that
3212 many values from the LIST.  A C<*> for the repeat count means to use
3213 however many items are left, except for C<@>, C<x>, C<X>, where it is
3214 equivalent to C<0>, and C<u>, where it is equivalent to 1 (or 45, what
3215 is the same).  A numeric repeat count may optionally be enclosed in
3216 brackets, as in C<pack 'C[80]', @arr>.
3217
3218 One can replace the numeric repeat count by a template enclosed in brackets;
3219 then the packed length of this template in bytes is used as a count.
3220 For example, C<x[L]> skips a long (it skips the number of bytes in a long);
3221 the template C<$t X[$t] $t> unpack()s twice what $t unpacks.
3222 If the template in brackets contains alignment commands (such as C<x![d]>),
3223 its packed length is calculated as if the start of the template has the maximal
3224 possible alignment.
3225
3226 When used with C<Z>, C<*> results in the addition of a trailing null
3227 byte (so the packed result will be one longer than the byte C<length>
3228 of the item).
3229
3230 The repeat count for C<u> is interpreted as the maximal number of bytes
3231 to encode per line of output, with 0 and 1 replaced by 45.
3232
3233 =item *
3234
3235 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
3236 string of length count, padding with nulls or spaces as necessary.  When
3237 unpacking, C<A> strips trailing spaces and nulls, C<Z> strips everything
3238 after the first null, and C<a> returns data verbatim.  When packing,
3239 C<a>, and C<Z> are equivalent.
3240
3241 If the value-to-pack is too long, it is truncated.  If too long and an
3242 explicit count is provided, C<Z> packs only C<$count-1> bytes, followed
3243 by a null byte.  Thus C<Z> always packs a trailing null byte under
3244 all circumstances.
3245
3246 =item *
3247
3248 Likewise, the C<b> and C<B> fields pack a string that many bits long.
3249 Each byte of the input field of pack() generates 1 bit of the result.
3250 Each result bit is based on the least-significant bit of the corresponding
3251 input byte, i.e., on C<ord($byte)%2>.  In particular, bytes C<"0"> and
3252 C<"1"> generate bits 0 and 1, as do bytes C<"\0"> and C<"\1">.
3253
3254 Starting from the beginning of the input string of pack(), each 8-tuple
3255 of bytes is converted to 1 byte of output.  With format C<b>
3256 the first byte of the 8-tuple determines the least-significant bit of a
3257 byte, and with format C<B> it determines the most-significant bit of
3258 a byte.
3259
3260 If the length of the input string is not exactly divisible by 8, the
3261 remainder is packed as if the input string were padded by null bytes
3262 at the end.  Similarly, during unpack()ing the "extra" bits are ignored.
3263
3264 If the input string of pack() is longer than needed, extra bytes are ignored.
3265 A C<*> for the repeat count of pack() means to use all the bytes of
3266 the input field.  On unpack()ing the bits are converted to a string
3267 of C<"0">s and C<"1">s.
3268
3269 =item *
3270
3271 The C<h> and C<H> fields pack a string that many nybbles (4-bit groups,
3272 representable as hexadecimal digits, 0-9a-f) long.
3273
3274 Each byte of the input field of pack() generates 4 bits of the result.
3275 For non-alphabetical bytes the result is based on the 4 least-significant
3276 bits of the input byte, i.e., on C<ord($byte)%16>.  In particular,
3277 bytes C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
3278 C<"\0"> and C<"\1">.  For bytes C<"a".."f"> and C<"A".."F"> the result
3279 is compatible with the usual hexadecimal digits, so that C<"a"> and
3280 C<"A"> both generate the nybble C<0xa==10>.  The result for bytes
3281 C<"g".."z"> and C<"G".."Z"> is not well-defined.
3282
3283 Starting from the beginning of the input string of pack(), each pair
3284 of bytes is converted to 1 byte of output.  With format C<h> the
3285 first byte of the pair determines the least-significant nybble of the
3286 output byte, and with format C<H> it determines the most-significant
3287 nybble.
3288
3289 If the length of the input string is not even, it behaves as if padded
3290 by a null byte at the end.  Similarly, during unpack()ing the "extra"
3291 nybbles are ignored.
3292
3293 If the input string of pack() is longer than needed, extra bytes are ignored.
3294 A C<*> for the repeat count of pack() means to use all the bytes of
3295 the input field.  On unpack()ing the bits are converted to a string
3296 of hexadecimal digits.
3297
3298 =item *
3299
3300 The C<p> type packs a pointer to a null-terminated string.  You are
3301 responsible for ensuring the string is not a temporary value (which can
3302 potentially get deallocated before you get around to using the packed result).
3303 The C<P> type packs a pointer to a structure of the size indicated by the
3304 length.  A NULL pointer is created if the corresponding value for C<p> or
3305 C<P> is C<undef>, similarly for unpack().
3306
3307 =item *
3308
3309 The C</> template character allows packing and unpacking of strings where
3310 the packed structure contains a byte count followed by the string itself.
3311 You write I<length-item>C</>I<string-item>.
3312
3313 The I<length-item> can be any C<pack> template letter, and describes
3314 how the length value is packed.  The ones likely to be of most use are
3315 integer-packing ones like C<n> (for Java strings), C<w> (for ASN.1 or
3316 SNMP) and C<N> (for Sun XDR).
3317
3318 The I<string-item> must, at present, be C<"A*">, C<"a*"> or C<"Z*">.
3319 For C<unpack> the length of the string is obtained from the I<length-item>,
3320 but if you put in the '*' it will be ignored.
3321
3322     unpack 'C/a', "\04Gurusamy";        gives 'Guru'
3323     unpack 'a3/A* A*', '007 Bond  J ';  gives (' Bond','J')
3324     pack 'n/a* w/a*','hello,','world';  gives "\000\006hello,\005world"
3325
3326 The I<length-item> is not returned explicitly from C<unpack>.
3327
3328 Adding a count to the I<length-item> letter is unlikely to do anything
3329 useful, unless that letter is C<A>, C<a> or C<Z>.  Packing with a
3330 I<length-item> of C<a> or C<Z> may introduce C<"\000"> characters,
3331 which Perl does not regard as legal in numeric strings.
3332
3333 =item *
3334
3335 The integer types C<s>, C<S>, C<l>, and C<L> may be
3336 immediately followed by a C<!> suffix to signify native shorts or
3337 longs--as you can see from above for example a bare C<l> does mean
3338 exactly 32 bits, the native C<long> (as seen by the local C compiler)
3339 may be larger.  This is an issue mainly in 64-bit platforms.  You can
3340 see whether using C<!> makes any difference by
3341
3342         print length(pack("s")), " ", length(pack("s!")), "\n";
3343         print length(pack("l")), " ", length(pack("l!")), "\n";
3344
3345 C<i!> and C<I!> also work but only because of completeness;
3346 they are identical to C<i> and C<I>.
3347
3348 The actual sizes (in bytes) of native shorts, ints, longs, and long
3349 longs on the platform where Perl was built are also available via
3350 L<Config>:
3351
3352        use Config;
3353        print $Config{shortsize},    "\n";
3354        print $Config{intsize},      "\n";
3355        print $Config{longsize},     "\n";
3356        print $Config{longlongsize}, "\n";
3357
3358 (The C<$Config{longlongsize}> will be undefine if your system does
3359 not support long longs.)
3360
3361 =item *
3362
3363 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J>
3364 are inherently non-portable between processors and operating systems
3365 because they obey the native byteorder and endianness.  For example a
3366 4-byte integer 0x12345678 (305419896 decimal) would be ordered natively
3367 (arranged in and handled by the CPU registers) into bytes as
3368
3369         0x12 0x34 0x56 0x78     # big-endian
3370         0x78 0x56 0x34 0x12     # little-endian
3371
3372 Basically, the Intel and VAX CPUs are little-endian, while everybody
3373 else, for example Motorola m68k/88k, PPC, Sparc, HP PA, Power, and
3374 Cray are big-endian.  Alpha and MIPS can be either: Digital/Compaq
3375 used/uses them in little-endian mode; SGI/Cray uses them in big-endian
3376 mode.
3377
3378 The names `big-endian' and `little-endian' are comic references to
3379 the classic "Gulliver's Travels" (via the paper "On Holy Wars and a
3380 Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and
3381 the egg-eating habits of the Lilliputians.
3382
3383 Some systems may have even weirder byte orders such as
3384
3385         0x56 0x78 0x12 0x34
3386         0x34 0x12 0x78 0x56
3387
3388 You can see your system's preference with
3389
3390         print join(" ", map { sprintf "%#02x", $_ }
3391                             unpack("C*",pack("L",0x12345678))), "\n";
3392
3393 The byteorder on the platform where Perl was built is also available
3394 via L<Config>:
3395
3396         use Config;
3397         print $Config{byteorder}, "\n";
3398
3399 Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'>
3400 and C<'87654321'> are big-endian.
3401
3402 If you want portable packed integers use the formats C<n>, C<N>,
3403 C<v>, and C<V>, their byte endianness and size are known.
3404 See also L<perlport>.
3405
3406 =item *
3407
3408 Real numbers (floats and doubles) are in the native machine format only;
3409 due to the multiplicity of floating formats around, and the lack of a
3410 standard "network" representation, no facility for interchange has been
3411 made.  This means that packed floating point data written on one machine
3412 may not be readable on another - even if both use IEEE floating point
3413 arithmetic (as the endian-ness of the memory representation is not part
3414 of the IEEE spec).  See also L<perlport>.
3415
3416 Note that Perl uses doubles internally for all numeric calculation, and
3417 converting from double into float and thence back to double again will
3418 lose precision (i.e., C<unpack("f", pack("f", $foo)>) will not in general
3419 equal $foo).
3420
3421 =item *
3422
3423 If the pattern begins with a C<U>, the resulting string will be treated
3424 as Unicode-encoded. You can force UTF8 encoding on in a string with an
3425 initial C<U0>, and the bytes that follow will be interpreted as Unicode
3426 characters. If you don't want this to happen, you can begin your pattern
3427 with C<C0> (or anything else) to force Perl not to UTF8 encode your
3428 string, and then follow this with a C<U*> somewhere in your pattern.
3429
3430 =item *
3431
3432 You must yourself do any alignment or padding by inserting for example
3433 enough C<'x'>es while packing.  There is no way to pack() and unpack()
3434 could know where the bytes are going to or coming from.  Therefore
3435 C<pack> (and C<unpack>) handle their output and input as flat
3436 sequences of bytes.
3437
3438 =item *
3439
3440 A ()-group is a sub-TEMPLATE enclosed in parentheses.  A group may
3441 take a repeat count, both as postfix, and via the C</> template
3442 character.
3443
3444 =item *
3445
3446 C<x> and C<X> accept C<!> modifier.  In this case they act as
3447 alignment commands: they jump forward/back to the closest position
3448 aligned at a multiple of C<count> bytes.  For example, to pack() or
3449 unpack() C's C<struct {char c; double d; char cc[2]}> one may need to
3450 use the template C<C x![d] d C[2]>; this assumes that doubles must be
3451 aligned on the double's size.
3452
3453 For alignment commands C<count> of 0 is equivalent to C<count> of 1;
3454 both result in no-ops.
3455
3456 =item *
3457
3458 A comment in a TEMPLATE starts with C<#> and goes to the end of line.
3459
3460 =item *
3461
3462 If TEMPLATE requires more arguments to pack() than actually given, pack()
3463 assumes additional C<""> arguments.  If TEMPLATE requires less arguments
3464 to pack() than actually given, extra arguments are ignored.
3465
3466 =back
3467
3468 Examples:
3469
3470     $foo = pack("CCCC",65,66,67,68);
3471     # foo eq "ABCD"
3472     $foo = pack("C4",65,66,67,68);
3473     # same thing
3474     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
3475     # same thing with Unicode circled letters
3476
3477     $foo = pack("ccxxcc",65,66,67,68);
3478     # foo eq "AB\0\0CD"
3479
3480     # note: the above examples featuring "C" and "c" are true
3481     # only on ASCII and ASCII-derived systems such as ISO Latin 1
3482     # and UTF-8.  In EBCDIC the first example would be
3483     # $foo = pack("CCCC",193,194,195,196);
3484
3485     $foo = pack("s2",1,2);
3486     # "\1\0\2\0" on little-endian
3487     # "\0\1\0\2" on big-endian
3488
3489     $foo = pack("a4","abcd","x","y","z");
3490     # "abcd"
3491
3492     $foo = pack("aaaa","abcd","x","y","z");
3493     # "axyz"
3494
3495     $foo = pack("a14","abcdefg");
3496     # "abcdefg\0\0\0\0\0\0\0"
3497
3498     $foo = pack("i9pl", gmtime);
3499     # a real struct tm (on my system anyway)
3500
3501     $utmp_template = "Z8 Z8 Z16 L";
3502     $utmp = pack($utmp_template, @utmp1);
3503     # a struct utmp (BSDish)
3504
3505     @utmp2 = unpack($utmp_template, $utmp);
3506     # "@utmp1" eq "@utmp2"
3507
3508     sub bintodec {
3509         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
3510     }
3511
3512     $foo = pack('sx2l', 12, 34);
3513     # short 12, two zero bytes padding, long 34
3514     $bar = pack('s@4l', 12, 34);
3515     # short 12, zero fill to position 4, long 34
3516     # $foo eq $bar
3517
3518 The same template may generally also be used in unpack().
3519
3520 =item package NAMESPACE
3521
3522 =item package
3523
3524 Declares the compilation unit as being in the given namespace.  The scope
3525 of the package declaration is from the declaration itself through the end
3526 of the enclosing block, file, or eval (the same as the C<my> operator).
3527 All further unqualified dynamic identifiers will be in this namespace.
3528 A package statement affects only dynamic variables--including those
3529 you've used C<local> on--but I<not> lexical variables, which are created
3530 with C<my>.  Typically it would be the first declaration in a file to
3531 be included by the C<require> or C<use> operator.  You can switch into a
3532 package in more than one place; it merely influences which symbol table
3533 is used by the compiler for the rest of that block.  You can refer to
3534 variables and filehandles in other packages by prefixing the identifier
3535 with the package name and a double colon:  C<$Package::Variable>.
3536 If the package name is null, the C<main> package as assumed.  That is,
3537 C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>,
3538 still seen in older code).
3539
3540 If NAMESPACE is omitted, then there is no current package, and all
3541 identifiers must be fully qualified or lexicals.  However, you are
3542 strongly advised not to make use of this feature. Its use can cause
3543 unexpected behaviour, even crashing some versions of Perl. It is
3544 deprecated, and will be removed from a future release.
3545
3546 See L<perlmod/"Packages"> for more information about packages, modules,
3547 and classes.  See L<perlsub> for other scoping issues.
3548
3549 =item pipe READHANDLE,WRITEHANDLE
3550
3551 Opens a pair of connected pipes like the corresponding system call.
3552 Note that if you set up a loop of piped processes, deadlock can occur
3553 unless you are very careful.  In addition, note that Perl's pipes use
3554 IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE
3555 after each command, depending on the application.
3556
3557 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
3558 for examples of such things.
3559
3560 On systems that support a close-on-exec flag on files, the flag will be set
3561 for the newly opened file descriptors as determined by the value of $^F.
3562 See L<perlvar/$^F>.
3563
3564 =item pop ARRAY
3565
3566 =item pop
3567
3568 Pops and returns the last value of the array, shortening the array by
3569 one element.  Has an effect similar to
3570
3571     $ARRAY[$#ARRAY--]
3572
3573 If there are no elements in the array, returns the undefined value
3574 (although this may happen at other times as well).  If ARRAY is
3575 omitted, pops the C<@ARGV> array in the main program, and the C<@_>
3576 array in subroutines, just like C<shift>.
3577
3578 =item pos SCALAR
3579
3580 =item pos
3581
3582 Returns the offset of where the last C<m//g> search left off for the variable
3583 in question (C<$_> is used when the variable is not specified).  May be
3584 modified to change that offset.  Such modification will also influence
3585 the C<\G> zero-width assertion in regular expressions.  See L<perlre> and
3586 L<perlop>.
3587
3588 =item print FILEHANDLE LIST
3589
3590 =item print LIST
3591
3592 =item print
3593
3594 Prints a string or a list of strings.  Returns true if successful.
3595 FILEHANDLE may be a scalar variable name, in which case the variable
3596 contains the name of or a reference to the filehandle, thus introducing
3597 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
3598 the next token is a term, it may be misinterpreted as an operator
3599 unless you interpose a C<+> or put parentheses around the arguments.)
3600 If FILEHANDLE is omitted, prints by default to standard output (or
3601 to the last selected output channel--see L</select>).  If LIST is
3602 also omitted, prints C<$_> to the currently selected output channel.
3603 To set the default output channel to something other than STDOUT
3604 use the select operation.  The current value of C<$,> (if any) is
3605 printed between each LIST item.  The current value of C<$\> (if
3606 any) is printed after the entire LIST has been printed.  Because
3607 print takes a LIST, anything in the LIST is evaluated in list
3608 context, and any subroutine that you call will have one or more of
3609 its expressions evaluated in list context.  Also be careful not to
3610 follow the print keyword with a left parenthesis unless you want
3611 the corresponding right parenthesis to terminate the arguments to
3612 the print--interpose a C<+> or put parentheses around all the
3613 arguments.
3614
3615 Note that if you're storing FILEHANDLES in an array or other expression,
3616 you will have to use a block returning its value instead:
3617
3618     print { $files[$i] } "stuff\n";
3619     print { $OK ? STDOUT : STDERR } "stuff\n";
3620
3621 =item printf FILEHANDLE FORMAT, LIST
3622
3623 =item printf FORMAT, LIST
3624
3625 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
3626 (the output record separator) is not appended.  The first argument
3627 of the list will be interpreted as the C<printf> format. See C<sprintf>
3628 for an explanation of the format argument. If C<use locale> is in effect,
3629 the character used for the decimal point in formatted real numbers is
3630 affected by the LC_NUMERIC locale.  See L<perllocale>.
3631
3632 Don't fall into the trap of using a C<printf> when a simple
3633 C<print> would do.  The C<print> is more efficient and less
3634 error prone.
3635
3636 =item prototype FUNCTION
3637
3638 Returns the prototype of a function as a string (or C<undef> if the
3639 function has no prototype).  FUNCTION is a reference to, or the name of,
3640 the function whose prototype you want to retrieve.
3641
3642 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
3643 name for Perl builtin.  If the builtin is not I<overridable> (such as
3644 C<qw//>) or its arguments cannot be expressed by a prototype (such as
3645 C<system>) returns C<undef> because the builtin does not really behave
3646 like a Perl function.  Otherwise, the string describing the equivalent
3647 prototype is returned.
3648
3649 =item push ARRAY,LIST
3650
3651 Treats ARRAY as a stack, and pushes the values of LIST
3652 onto the end of ARRAY.  The length of ARRAY increases by the length of
3653 LIST.  Has the same effect as
3654
3655     for $value (LIST) {
3656         $ARRAY[++$#ARRAY] = $value;
3657     }
3658
3659 but is more efficient.  Returns the new number of elements in the array.
3660
3661 =item q/STRING/
3662
3663 =item qq/STRING/
3664
3665 =item qr/STRING/
3666
3667 =item qx/STRING/
3668
3669 =item qw/STRING/
3670
3671 Generalized quotes.  See L<perlop/"Regexp Quote-Like Operators">.
3672
3673 =item quotemeta EXPR
3674
3675 =item quotemeta
3676
3677 Returns the value of EXPR with all non-"word"
3678 characters backslashed.  (That is, all characters not matching
3679 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
3680 returned string, regardless of any locale settings.)
3681 This is the internal function implementing
3682 the C<\Q> escape in double-quoted strings.
3683
3684 If EXPR is omitted, uses C<$_>.
3685
3686 =item rand EXPR
3687
3688 =item rand
3689
3690 Returns a random fractional number greater than or equal to C<0> and less
3691 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
3692 omitted, or a C<0>, the value C<1> is used.  Automatically calls C<srand>
3693 unless C<srand> has already been called.  See also C<srand>.
3694
3695 Apply C<int()> to the value returned by C<rand()> if you want random
3696 integers instead of random fractional numbers.  For example,
3697
3698     int(rand(10))
3699
3700 returns a random integer between C<0> and C<9>, inclusive.
3701
3702 (Note: If your rand function consistently returns numbers that are too
3703 large or too small, then your version of Perl was probably compiled
3704 with the wrong number of RANDBITS.)
3705
3706 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
3707
3708 =item read FILEHANDLE,SCALAR,LENGTH
3709
3710 Attempts to read LENGTH I<characters> of data into variable SCALAR
3711 from the specified FILEHANDLE.  Returns the number of characters
3712 actually read, C<0> at end of file, or undef if there was an error.
3713 SCALAR will be grown or shrunk to the length actually read.  If SCALAR
3714 needs growing, the new bytes will be zero bytes.  An OFFSET may be
3715 specified to place the read data into some other place in SCALAR than
3716 the beginning.  The call is actually implemented in terms of either
3717 Perl's or system's fread() call.  To get a true read(2) system call,
3718 see C<sysread>.
3719
3720 Note the I<characters>: depending on the status of the filehandle,
3721 either (8-bit) bytes or characters are read.  By default all
3722 filehandles operate on bytes, but for example if the filehandle has
3723 been opened with the C<:utf8> discipline (see L</open>, and the C<open>
3724 pragma, L<open>), the I/O will operate on characters, not bytes.
3725
3726 =item readdir DIRHANDLE
3727
3728 Returns the next directory entry for a directory opened by C<opendir>.
3729 If used in list context, returns all the rest of the entries in the
3730 directory.  If there are no more entries, returns an undefined value in
3731 scalar context or a null list in list context.
3732
3733 If you're planning to filetest the return values out of a C<readdir>, you'd
3734 better prepend the directory in question.  Otherwise, because we didn't
3735 C<chdir> there, it would have been testing the wrong file.
3736
3737     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
3738     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
3739     closedir DIR;
3740
3741 =item readline EXPR
3742
3743 Reads from the filehandle whose typeglob is contained in EXPR.  In scalar
3744 context, each call reads and returns the next line, until end-of-file is
3745 reached, whereupon the subsequent call returns undef.  In list context,
3746 reads until end-of-file is reached and returns a list of lines.  Note that
3747 the notion of "line" used here is however you may have defined it
3748 with C<$/> or C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
3749
3750 When C<$/> is set to C<undef>, when readline() is in scalar
3751 context (i.e. file slurp mode), and when an empty file is read, it
3752 returns C<''> the first time, followed by C<undef> subsequently.
3753
3754 This is the internal function implementing the C<< <EXPR> >>
3755 operator, but you can use it directly.  The C<< <EXPR> >>
3756 operator is discussed in more detail in L<perlop/"I/O Operators">.
3757
3758     $line = <STDIN>;
3759     $line = readline(*STDIN);           # same thing
3760
3761 =item readlink EXPR
3762
3763 =item readlink
3764
3765 Returns the value of a symbolic link, if symbolic links are
3766 implemented.  If not, gives a fatal error.  If there is some system
3767 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
3768 omitted, uses C<$_>.
3769
3770 =item readpipe EXPR
3771
3772 EXPR is executed as a system command.
3773 The collected standard output of the command is returned.
3774 In scalar context, it comes back as a single (potentially
3775 multi-line) string.  In list context, returns a list of lines
3776 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
3777 This is the internal function implementing the C<qx/EXPR/>
3778 operator, but you can use it directly.  The C<qx/EXPR/>
3779 operator is discussed in more detail in L<perlop/"I/O Operators">.
3780
3781 =item recv SOCKET,SCALAR,LENGTH,FLAGS
3782
3783 Receives a message on a socket.  Attempts to receive LENGTH characters
3784 of data into variable SCALAR from the specified SOCKET filehandle.
3785 SCALAR will be grown or shrunk to the length actually read.  Takes the
3786 same flags as the system call of the same name.  Returns the address
3787 of the sender if SOCKET's protocol supports this; returns an empty
3788 string otherwise.  If there's an error, returns the undefined value.
3789 This call is actually implemented in terms of recvfrom(2) system call.
3790 See L<perlipc/"UDP: Message Passing"> for examples.
3791
3792 Note the I<characters>: depending on the status of the socket, either
3793 (8-bit) bytes or characters are received.  By default all sockets
3794 operate on bytes, but for example if the socket has been changed using
3795 binmode() to operate with the C<:utf8> discipline (see the C<open>
3796 pragma, L<open>), the I/O will operate on characters, not bytes.
3797
3798 =item redo LABEL
3799
3800 =item redo
3801
3802 The C<redo> command restarts the loop block without evaluating the
3803 conditional again.  The C<continue> block, if any, is not executed.  If
3804 the LABEL is omitted, the command refers to the innermost enclosing
3805 loop.  This command is normally used by programs that want to lie to
3806 themselves about what was just input:
3807
3808     # a simpleminded Pascal comment stripper
3809     # (warning: assumes no { or } in strings)
3810     LINE: while (<STDIN>) {
3811         while (s|({.*}.*){.*}|$1 |) {}
3812         s|{.*}| |;
3813         if (s|{.*| |) {
3814             $front = $_;
3815             while (<STDIN>) {
3816                 if (/}/) {      # end of comment?
3817                     s|^|$front\{|;
3818                     redo LINE;
3819                 }
3820             }
3821         }
3822         print;
3823     }
3824
3825 C<redo> cannot be used to retry a block which returns a value such as
3826 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
3827 a grep() or map() operation.
3828
3829 Note that a block by itself is semantically identical to a loop
3830 that executes once.  Thus C<redo> inside such a block will effectively
3831 turn it into a looping construct.
3832
3833 See also L</continue> for an illustration of how C<last>, C<next>, and
3834 C<redo> work.
3835
3836 =item ref EXPR
3837
3838 =item ref
3839
3840 Returns a true value if EXPR is a reference, false otherwise.  If EXPR
3841 is not specified, C<$_> will be used.  The value returned depends on the
3842 type of thing the reference is a reference to.
3843 Builtin types include:
3844
3845     SCALAR
3846     ARRAY
3847     HASH
3848     CODE
3849     REF
3850     GLOB
3851     LVALUE
3852
3853 If the referenced object has been blessed into a package, then that package
3854 name is returned instead.  You can think of C<ref> as a C<typeof> operator.
3855
3856     if (ref($r) eq "HASH") {
3857         print "r is a reference to a hash.\n";
3858     }
3859     unless (ref($r)) {
3860         print "r is not a reference at all.\n";
3861     }
3862     if (UNIVERSAL::isa($r, "HASH")) {  # for subclassing
3863         print "r is a reference to something that isa hash.\n";
3864     }
3865
3866 See also L<perlref>.
3867
3868 =item rename OLDNAME,NEWNAME
3869
3870 Changes the name of a file; an existing file NEWNAME will be
3871 clobbered.  Returns true for success, false otherwise.
3872
3873 Behavior of this function varies wildly depending on your system
3874 implementation.  For example, it will usually not work across file system
3875 boundaries, even though the system I<mv> command sometimes compensates
3876 for this.  Other restrictions include whether it works on directories,
3877 open files, or pre-existing files.  Check L<perlport> and either the
3878 rename(2) manpage or equivalent system documentation for details.
3879
3880 =item require VERSION
3881
3882 =item require EXPR
3883
3884 =item require
3885
3886 Demands a version of Perl specified by VERSION, or demands some semantics
3887 specified by EXPR or by C<$_> if EXPR is not supplied.
3888
3889 VERSION may be either a numeric argument such as 5.006, which will be
3890 compared to C<$]>, or a literal of the form v5.6.1, which will be compared
3891 to C<$^V> (aka $PERL_VERSION).  A fatal error is produced at run time if
3892 VERSION is greater than the version of the current Perl interpreter.
3893 Compare with L</use>, which can do a similar check at compile time.
3894
3895 Specifying VERSION as a literal of the form v5.6.1 should generally be
3896 avoided, because it leads to misleading error messages under earlier
3897 versions of Perl which do not support this syntax.  The equivalent numeric
3898 version should be used instead.
3899
3900     require v5.6.1;     # run time version check
3901     require 5.6.1;      # ditto
3902     require 5.006_001;  # ditto; preferred for backwards compatibility
3903
3904 Otherwise, demands that a library file be included if it hasn't already
3905 been included.  The file is included via the do-FILE mechanism, which is
3906 essentially just a variety of C<eval>.  Has semantics similar to the following
3907 subroutine:
3908
3909     sub require {
3910         my($filename) = @_;
3911         return 1 if $INC{$filename};
3912         my($realfilename,$result);
3913         ITER: {
3914             foreach $prefix (@INC) {
3915                 $realfilename = "$prefix/$filename";
3916                 if (-f $realfilename) {
3917                     $INC{$filename} = $realfilename;
3918                     $result = do $realfilename;
3919                     last ITER;
3920                 }
3921             }
3922             die "Can't find $filename in \@INC";
3923         }
3924         delete $INC{$filename} if $@ || !$result;
3925         die $@ if $@;
3926         die "$filename did not return true value" unless $result;
3927         return $result;
3928     }
3929
3930 Note that the file will not be included twice under the same specified
3931 name.  The file must return true as the last statement to indicate
3932 successful execution of any initialization code, so it's customary to
3933 end such a file with C<1;> unless you're sure it'll return true
3934 otherwise.  But it's better just to put the C<1;>, in case you add more
3935 statements.
3936
3937 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
3938 replaces "F<::>" with "F</>" in the filename for you,
3939 to make it easy to load standard modules.  This form of loading of
3940 modules does not risk altering your namespace.
3941
3942 In other words, if you try this:
3943
3944         require Foo::Bar;    # a splendid bareword
3945
3946 The require function will actually look for the "F<Foo/Bar.pm>" file in the
3947 directories specified in the C<@INC> array.
3948
3949 But if you try this:
3950
3951         $class = 'Foo::Bar';
3952         require $class;      # $class is not a bareword
3953     #or
3954         require "Foo::Bar";  # not a bareword because of the ""
3955
3956 The require function will look for the "F<Foo::Bar>" file in the @INC array and
3957 will complain about not finding "F<Foo::Bar>" there.  In this case you can do:
3958
3959         eval "require $class";
3960
3961 You can also insert hooks into the import facility, by putting directly
3962 Perl code into the @INC array.  There are three forms of hooks: subroutine
3963 references, array references and blessed objects.
3964
3965 Subroutine references are the simplest case.  When the inclusion system
3966 walks through @INC and encounters a subroutine, this subroutine gets
3967 called with two parameters, the first being a reference to itself, and the
3968 second the name of the file to be included (e.g. "F<Foo/Bar.pm>").  The
3969 subroutine should return C<undef> or a filehandle, from which the file to
3970 include will be read.  If C<undef> is returned, C<require> will look at
3971 the remaining elements of @INC.
3972
3973 If the hook is an array reference, its first element must be a subroutine
3974 reference.  This subroutine is called as above, but the first parameter is
3975 the array reference.  This enables to pass indirectly some arguments to
3976 the subroutine.
3977
3978 In other words, you can write:
3979
3980     push @INC, \&my_sub;
3981     sub my_sub {
3982         my ($coderef, $filename) = @_;  # $coderef is \&my_sub
3983         ...
3984     }
3985
3986 or:
3987
3988     push @INC, [ \&my_sub, $x, $y, ... ];
3989     sub my_sub {
3990         my ($arrayref, $filename) = @_;
3991         # Retrieve $x, $y, ...
3992         my @parameters = @$arrayref[1..$#$arrayref];
3993         ...
3994     }
3995
3996 If the hook is an object, it must provide an INC method, that will be
3997 called as above, the first parameter being the object itself.  (Note that
3998 you must fully qualify the sub's name, as it is always forced into package
3999 C<main>.)  Here is a typical code layout:
4000
4001     # In Foo.pm
4002     package Foo;
4003     sub new { ... }
4004     sub Foo::INC {
4005         my ($self, $filename) = @_;
4006         ...
4007     }
4008
4009     # In the main program
4010     push @INC, new Foo(...);
4011
4012 Note that these hooks are also permitted to set the %INC entry
4013 corresponding to the files they have loaded. See L<perlvar/%INC>.
4014
4015 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
4016
4017 =item reset EXPR
4018
4019 =item reset
4020
4021 Generally used in a C<continue> block at the end of a loop to clear
4022 variables and reset C<??> searches so that they work again.  The
4023 expression is interpreted as a list of single characters (hyphens
4024 allowed for ranges).  All variables and arrays beginning with one of
4025 those letters are reset to their pristine state.  If the expression is
4026 omitted, one-match searches (C<?pattern?>) are reset to match again.  Resets
4027 only variables or searches in the current package.  Always returns
4028 1.  Examples:
4029
4030     reset 'X';          # reset all X variables
4031     reset 'a-z';        # reset lower case variables
4032     reset;              # just reset ?one-time? searches
4033
4034 Resetting C<"A-Z"> is not recommended because you'll wipe out your
4035 C<@ARGV> and C<@INC> arrays and your C<%ENV> hash.  Resets only package
4036 variables--lexical variables are unaffected, but they clean themselves
4037 up on scope exit anyway, so you'll probably want to use them instead.
4038 See L</my>.
4039
4040 =item return EXPR
4041
4042 =item return
4043
4044 Returns from a subroutine, C<eval>, or C<do FILE> with the value
4045 given in EXPR.  Evaluation of EXPR may be in list, scalar, or void
4046 context, depending on how the return value will be used, and the context
4047 may vary from one execution to the next (see C<wantarray>).  If no EXPR
4048 is given, returns an empty list in list context, the undefined value in
4049 scalar context, and (of course) nothing at all in a void context.
4050
4051 (Note that in the absence of an explicit C<return>, a subroutine, eval,
4052 or do FILE will automatically return the value of the last expression
4053 evaluated.)
4054
4055 =item reverse LIST
4056
4057 In list context, returns a list value consisting of the elements
4058 of LIST in the opposite order.  In scalar context, concatenates the
4059 elements of LIST and returns a string value with all characters
4060 in the opposite order.
4061
4062     print reverse <>;           # line tac, last line first
4063
4064     undef $/;                   # for efficiency of <>
4065     print scalar reverse <>;    # character tac, last line tsrif
4066
4067 This operator is also handy for inverting a hash, although there are some
4068 caveats.  If a value is duplicated in the original hash, only one of those
4069 can be represented as a key in the inverted hash.  Also, this has to
4070 unwind one hash and build a whole new one, which may take some time
4071 on a large hash, such as from a DBM file.
4072
4073     %by_name = reverse %by_address;     # Invert the hash
4074
4075 =item rewinddir DIRHANDLE
4076
4077 Sets the current position to the beginning of the directory for the
4078 C<readdir> routine on DIRHANDLE.
4079
4080 =item rindex STR,SUBSTR,POSITION
4081
4082 =item rindex STR,SUBSTR
4083
4084 Works just like index() except that it returns the position of the LAST
4085 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
4086 last occurrence at or before that position.
4087
4088 =item rmdir FILENAME
4089
4090 =item rmdir
4091
4092 Deletes the directory specified by FILENAME if that directory is empty.  If it
4093 succeeds it returns true, otherwise it returns false and sets C<$!> (errno).  If
4094 FILENAME is omitted, uses C<$_>.
4095
4096 =item s///
4097
4098 The substitution operator.  See L<perlop>.
4099
4100 =item scalar EXPR
4101
4102 Forces EXPR to be interpreted in scalar context and returns the value
4103 of EXPR.
4104
4105     @counts = ( scalar @a, scalar @b, scalar @c );
4106
4107 There is no equivalent operator to force an expression to
4108 be interpolated in list context because in practice, this is never
4109 needed.  If you really wanted to do so, however, you could use
4110 the construction C<@{[ (some expression) ]}>, but usually a simple
4111 C<(some expression)> suffices.
4112
4113 Because C<scalar> is unary operator, if you accidentally use for EXPR a
4114 parenthesized list, this behaves as a scalar comma expression, evaluating
4115 all but the last element in void context and returning the final element
4116 evaluated in scalar context.  This is seldom what you want.
4117
4118 The following single statement:
4119
4120         print uc(scalar(&foo,$bar)),$baz;
4121
4122 is the moral equivalent of these two:
4123
4124         &foo;
4125         print(uc($bar),$baz);
4126
4127 See L<perlop> for more details on unary operators and the comma operator.
4128
4129 =item seek FILEHANDLE,POSITION,WHENCE
4130
4131 Sets FILEHANDLE's position, just like the C<fseek> call of C<stdio>.
4132 FILEHANDLE may be an expression whose value gives the name of the
4133 filehandle.  The values for WHENCE are C<0> to set the new position
4134 I<in bytes> to POSITION, C<1> to set it to the current position plus
4135 POSITION, and C<2> to set it to EOF plus POSITION (typically
4136 negative).  For WHENCE you may use the constants C<SEEK_SET>,
4137 C<SEEK_CUR>, and C<SEEK_END> (start of the file, current position, end
4138 of the file) from the Fcntl module.  Returns C<1> upon success, C<0>
4139 otherwise.
4140
4141 Note the I<in bytes>: even if the filehandle has been set to
4142 operate on characters (for example by using the C<:utf8> open
4143 discipline), tell() will return byte offsets, not character offsets
4144 (because implementing that would render seek() and tell() rather slow).
4145
4146 If you want to position file for C<sysread> or C<syswrite>, don't use
4147 C<seek>--buffering makes its effect on the file's system position
4148 unpredictable and non-portable.  Use C<sysseek> instead.
4149
4150 Due to the rules and rigors of ANSI C, on some systems you have to do a
4151 seek whenever you switch between reading and writing.  Amongst other
4152 things, this may have the effect of calling stdio's clearerr(3).
4153 A WHENCE of C<1> (C<SEEK_CUR>) is useful for not moving the file position:
4154
4155     seek(TEST,0,1);
4156
4157 This is also useful for applications emulating C<tail -f>.  Once you hit
4158 EOF on your read, and then sleep for a while, you might have to stick in a
4159 seek() to reset things.  The C<seek> doesn't change the current position,
4160 but it I<does> clear the end-of-file condition on the handle, so that the
4161 next C<< <FILE> >> makes Perl try again to read something.  We hope.
4162
4163 If that doesn't work (some IO implementations are particularly
4164 cantankerous), then you may need something more like this:
4165
4166     for (;;) {
4167         for ($curpos = tell(FILE); $_ = <FILE>;
4168              $curpos = tell(FILE)) {
4169             # search for some stuff and put it into files
4170         }
4171         sleep($for_a_while);
4172         seek(FILE, $curpos, 0);
4173     }
4174
4175 =item seekdir DIRHANDLE,POS
4176
4177 Sets the current position for the C<readdir> routine on DIRHANDLE.  POS
4178 must be a value returned by C<telldir>.  Has the same caveats about
4179 possible directory compaction as the corresponding system library
4180 routine.
4181
4182 =item select FILEHANDLE
4183
4184 =item select
4185
4186 Returns the currently selected filehandle.  Sets the current default
4187 filehandle for output, if FILEHANDLE is supplied.  This has two
4188 effects: first, a C<write> or a C<print> without a filehandle will
4189 default to this FILEHANDLE.  Second, references to variables related to
4190 output will refer to this output channel.  For example, if you have to
4191 set the top of form format for more than one output channel, you might
4192 do the following:
4193
4194     select(REPORT1);
4195     $^ = 'report1_top';
4196     select(REPORT2);
4197     $^ = 'report2_top';
4198
4199 FILEHANDLE may be an expression whose value gives the name of the
4200 actual filehandle.  Thus:
4201
4202     $oldfh = select(STDERR); $| = 1; select($oldfh);
4203
4204 Some programmers may prefer to think of filehandles as objects with
4205 methods, preferring to write the last example as:
4206
4207     use IO::Handle;
4208     STDERR->autoflush(1);
4209
4210 =item select RBITS,WBITS,EBITS,TIMEOUT
4211
4212 This calls the select(2) system call with the bit masks specified, which
4213 can be constructed using C<fileno> and C<vec>, along these lines:
4214
4215     $rin = $win = $ein = '';
4216     vec($rin,fileno(STDIN),1) = 1;
4217     vec($win,fileno(STDOUT),1) = 1;
4218     $ein = $rin | $win;
4219
4220 If you want to select on many filehandles you might wish to write a
4221 subroutine:
4222
4223     sub fhbits {
4224         my(@fhlist) = split(' ',$_[0]);
4225         my($bits);
4226         for (@fhlist) {
4227             vec($bits,fileno($_),1) = 1;
4228         }
4229         $bits;
4230     }
4231     $rin = fhbits('STDIN TTY SOCK');
4232
4233 The usual idiom is:
4234
4235     ($nfound,$timeleft) =
4236       select($rout=$rin, $wout=$win, $eout=$ein, $timeout);
4237
4238 or to block until something becomes ready just do this
4239
4240     $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);
4241
4242 Most systems do not bother to return anything useful in $timeleft, so
4243 calling select() in scalar context just returns $nfound.
4244
4245 Any of the bit masks can also be undef.  The timeout, if specified, is
4246 in seconds, which may be fractional.  Note: not all implementations are
4247 capable of returning the $timeleft.  If not, they always return
4248 $timeleft equal to the supplied $timeout.
4249
4250 You can effect a sleep of 250 milliseconds this way:
4251
4252     select(undef, undef, undef, 0.25);
4253
4254 B<WARNING>: One should not attempt to mix buffered I/O (like C<read>
4255 or <FH>) with C<select>, except as permitted by POSIX, and even
4256 then only on POSIX systems.  You have to use C<sysread> instead.
4257
4258 =item semctl ID,SEMNUM,CMD,ARG
4259
4260 Calls the System V IPC function C<semctl>.  You'll probably have to say
4261
4262     use IPC::SysV;
4263
4264 first to get the correct constant definitions.  If CMD is IPC_STAT or
4265 GETALL, then ARG must be a variable which will hold the returned
4266 semid_ds structure or semaphore value array.  Returns like C<ioctl>:
4267 the undefined value for error, "C<0 but true>" for zero, or the actual
4268 return value otherwise.  The ARG must consist of a vector of native
4269 short integers, which may be created with C<pack("s!",(0)x$nsem)>.
4270 See also L<perlipc/"SysV IPC">, C<IPC::SysV>, C<IPC::Semaphore>
4271 documentation.
4272
4273 =item semget KEY,NSEMS,FLAGS
4274
4275 Calls the System V IPC function semget.  Returns the semaphore id, or
4276 the undefined value if there is an error.  See also
4277 L<perlipc/"SysV IPC">, C<IPC::SysV>, C<IPC::SysV::Semaphore>
4278 documentation.
4279
4280 =item semop KEY,OPSTRING
4281
4282 Calls the System V IPC function semop to perform semaphore operations
4283 such as signalling and waiting.  OPSTRING must be a packed array of
4284 semop structures.  Each semop structure can be generated with
4285 C<pack("s!3", $semnum, $semop, $semflag)>.  The number of semaphore
4286 operations is implied by the length of OPSTRING.  Returns true if
4287 successful, or false if there is an error.  As an example, the
4288 following code waits on semaphore $semnum of semaphore id $semid:
4289
4290     $semop = pack("s!3", $semnum, -1, 0);
4291     die "Semaphore trouble: $!\n" unless semop($semid, $semop);
4292
4293 To signal the semaphore, replace C<-1> with C<1>.  See also
4294 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::SysV::Semaphore>
4295 documentation.
4296
4297 =item send SOCKET,MSG,FLAGS,TO
4298
4299 =item send SOCKET,MSG,FLAGS
4300
4301 Sends a message on a socket.  Attempts to send the scalar MSG to the
4302 SOCKET filehandle.  Takes the same flags as the system call of the
4303 same name.  On unconnected sockets you must specify a destination to
4304 send TO, in which case it does a C C<sendto>.  Returns the number of
4305 characters sent, or the undefined value if there is an error.  The C
4306 system call sendmsg(2) is currently unimplemented.  See
4307 L<perlipc/"UDP: Message Passing"> for examples.
4308
4309 Note the I<characters>: depending on the status of the socket, either
4310 (8-bit) bytes or characters are sent.  By default all sockets operate
4311 on bytes, but for example if the socket has been changed using
4312 binmode() to operate with the C<:utf8> discipline (see L</open>, or
4313 the C<open> pragma, L<open>), the I/O will operate on characters, not
4314 bytes.
4315
4316 =item setpgrp PID,PGRP
4317
4318 Sets the current process group for the specified PID, C<0> for the current
4319 process.  Will produce a fatal error if used on a machine that doesn't
4320 implement POSIX setpgid(2) or BSD setpgrp(2).  If the arguments are omitted,
4321 it defaults to C<0,0>.  Note that the BSD 4.2 version of C<setpgrp> does not
4322 accept any arguments, so only C<setpgrp(0,0)> is portable.  See also
4323 C<POSIX::setsid()>.
4324
4325 =item setpriority WHICH,WHO,PRIORITY
4326
4327 Sets the current priority for a process, a process group, or a user.
4328 (See setpriority(2).)  Will produce a fatal error if used on a machine
4329 that doesn't implement setpriority(2).
4330
4331 =item setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL
4332
4333 Sets the socket option requested.  Returns undefined if there is an
4334 error.  OPTVAL may be specified as C<undef> if you don't want to pass an
4335 argument.
4336
4337 =item shift ARRAY
4338
4339 =item shift
4340
4341 Shifts the first value of the array off and returns it, shortening the
4342 array by 1 and moving everything down.  If there are no elements in the
4343 array, returns the undefined value.  If ARRAY is omitted, shifts the
4344 C<@_> array within the lexical scope of subroutines and formats, and the
4345 C<@ARGV> array at file scopes or within the lexical scopes established by
4346 the C<eval ''>, C<BEGIN {}>, C<INIT {}>, C<CHECK {}>, and C<END {}>
4347 constructs.
4348
4349 See also C<unshift>, C<push>, and C<pop>.  C<shift> and C<unshift> do the
4350 same thing to the left end of an array that C<pop> and C<push> do to the
4351 right end.
4352
4353 =item shmctl ID,CMD,ARG
4354
4355 Calls the System V IPC function shmctl.  You'll probably have to say
4356
4357     use IPC::SysV;
4358
4359 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
4360 then ARG must be a variable which will hold the returned C<shmid_ds>
4361 structure.  Returns like ioctl: the undefined value for error, "C<0> but
4362 true" for zero, or the actual return value otherwise.
4363 See also L<perlipc/"SysV IPC"> and C<IPC::SysV> documentation.
4364
4365 =item shmget KEY,SIZE,FLAGS
4366
4367 Calls the System V IPC function shmget.  Returns the shared memory
4368 segment id, or the undefined value if there is an error.
4369 See also L<perlipc/"SysV IPC"> and C<IPC::SysV> documentation.
4370
4371 =item shmread ID,VAR,POS,SIZE
4372
4373 =item shmwrite ID,STRING,POS,SIZE
4374
4375 Reads or writes the System V shared memory segment ID starting at
4376 position POS for size SIZE by attaching to it, copying in/out, and
4377 detaching from it.  When reading, VAR must be a variable that will
4378 hold the data read.  When writing, if STRING is too long, only SIZE
4379 bytes are used; if STRING is too short, nulls are written to fill out
4380 SIZE bytes.  Return true if successful, or false if there is an error.
4381 shmread() taints the variable. See also L<perlipc/"SysV IPC">,
4382 C<IPC::SysV> documentation, and the C<IPC::Shareable> module from CPAN.
4383
4384 =item shutdown SOCKET,HOW
4385
4386 Shuts down a socket connection in the manner indicated by HOW, which
4387 has the same interpretation as in the system call of the same name.
4388
4389     shutdown(SOCKET, 0);    # I/we have stopped reading data
4390     shutdown(SOCKET, 1);    # I/we have stopped writing data
4391     shutdown(SOCKET, 2);    # I/we have stopped using this socket
4392
4393 This is useful with sockets when you want to tell the other
4394 side you're done writing but not done reading, or vice versa.
4395 It's also a more insistent form of close because it also
4396 disables the file descriptor in any forked copies in other
4397 processes.
4398
4399 =item sin EXPR
4400
4401 =item sin
4402
4403 Returns the sine of EXPR (expressed in radians).  If EXPR is omitted,
4404 returns sine of C<$_>.
4405
4406 For the inverse sine operation, you may use the C<Math::Trig::asin>
4407 function, or use this relation:
4408
4409     sub asin { atan2($_[0], sqrt(1 - $_[0] * $_[0])) }
4410
4411 =item sleep EXPR
4412
4413 =item sleep
4414
4415 Causes the script to sleep for EXPR seconds, or forever if no EXPR.
4416 May be interrupted if the process receives a signal such as C<SIGALRM>.
4417 Returns the number of seconds actually slept.  You probably cannot
4418 mix C<alarm> and C<sleep> calls, because C<sleep> is often implemented
4419 using C<alarm>.
4420
4421 On some older systems, it may sleep up to a full second less than what
4422 you requested, depending on how it counts seconds.  Most modern systems
4423 always sleep the full amount.  They may appear to sleep longer than that,
4424 however, because your process might not be scheduled right away in a
4425 busy multitasking system.
4426
4427 For delays of finer granularity than one second, you may use Perl's
4428 C<syscall> interface to access setitimer(2) if your system supports
4429 it, or else see L</select> above.  The Time::HiRes module (from CPAN,
4430 and starting from Perl 5.8 part of the standard distribution) may also
4431 help.
4432
4433 See also the POSIX module's C<pause> function.
4434
4435 =item socket SOCKET,DOMAIN,TYPE,PROTOCOL
4436
4437 Opens a socket of the specified kind and attaches it to filehandle
4438 SOCKET.  DOMAIN, TYPE, and PROTOCOL are specified the same as for
4439 the system call of the same name.  You should C<use Socket> first
4440 to get the proper definitions imported.  See the examples in
4441 L<perlipc/"Sockets: Client/Server Communication">.
4442
4443 On systems that support a close-on-exec flag on files, the flag will
4444 be set for the newly opened file descriptor, as determined by the
4445 value of $^F.  See L<perlvar/$^F>.
4446
4447 =item socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL
4448
4449 Creates an unnamed pair of sockets in the specified domain, of the
4450 specified type.  DOMAIN, TYPE, and PROTOCOL are specified the same as
4451 for the system call of the same name.  If unimplemented, yields a fatal
4452 error.  Returns true if successful.
4453
4454 On systems that support a close-on-exec flag on files, the flag will
4455 be set for the newly opened file descriptors, as determined by the value
4456 of $^F.  See L<perlvar/$^F>.
4457
4458 Some systems defined C<pipe> in terms of C<socketpair>, in which a call
4459 to C<pipe(Rdr, Wtr)> is essentially:
4460
4461     use Socket;
4462     socketpair(Rdr, Wtr, AF_UNIX, SOCK_STREAM, PF_UNSPEC);
4463     shutdown(Rdr, 1);        # no more writing for reader
4464     shutdown(Wtr, 0);        # no more reading for writer
4465
4466 See L<perlipc> for an example of socketpair use.  Perl 5.8 and later will
4467 emulate socketpair using IP sockets to localhost if your system implements
4468 sockets but not socketpair.
4469
4470 =item sort SUBNAME LIST
4471
4472 =item sort BLOCK LIST
4473
4474 =item sort LIST
4475
4476 Sorts the LIST and returns the sorted list value.  If SUBNAME or BLOCK
4477 is omitted, C<sort>s in standard string comparison order.  If SUBNAME is
4478 specified, it gives the name of a subroutine that returns an integer
4479 less than, equal to, or greater than C<0>, depending on how the elements
4480 of the list are to be ordered.  (The C<< <=> >> and C<cmp>
4481 operators are extremely useful in such routines.)  SUBNAME may be a
4482 scalar variable name (unsubscripted), in which case the value provides
4483 the name of (or a reference to) the actual subroutine to use.  In place
4484 of a SUBNAME, you can provide a BLOCK as an anonymous, in-line sort
4485 subroutine.
4486
4487 If the subroutine's prototype is C<($$)>, the elements to be compared
4488 are passed by reference in C<@_>, as for a normal subroutine.  This is
4489 slower than unprototyped subroutines, where the elements to be
4490 compared are passed into the subroutine
4491 as the package global variables $a and $b (see example below).  Note that
4492 in the latter case, it is usually counter-productive to declare $a and
4493 $b as lexicals.
4494
4495 In either case, the subroutine may not be recursive.  The values to be
4496 compared are always passed by reference, so don't modify them.
4497
4498 You also cannot exit out of the sort block or subroutine using any of the
4499 loop control operators described in L<perlsyn> or with C<goto>.
4500
4501 When C<use locale> is in effect, C<sort LIST> sorts LIST according to the
4502 current collation locale.  See L<perllocale>.
4503
4504 Perl 5.6 and earlier used a quicksort algorithm to implement sort.
4505 That algorithm was not stable, and I<could> go quadratic.  (A I<stable> sort
4506 preserves the input order of elements that compare equal.  Although
4507 quicksort's run time is O(NlogN) when averaged over all arrays of
4508 length N, the time can be O(N**2), I<quadratic> behavior, for some
4509 inputs.)  In 5.7, the quicksort implementation was replaced with
4510 a stable mergesort algorithm whose worst case behavior is O(NlogN).
4511 But benchmarks indicated that for some inputs, on some platforms,
4512 the original quicksort was faster.  5.8 has a sort pragma for
4513 limited control of the sort.  Its rather blunt control of the
4514 underlying algorithm may not persist into future perls, but the
4515 ability to characterize the input or output in implementation
4516 independent ways quite probably will.  See L</use>.
4517
4518 Examples:
4519
4520     # sort lexically
4521     @articles = sort @files;
4522
4523     # same thing, but with explicit sort routine
4524     @articles = sort {$a cmp $b} @files;
4525
4526     # now case-insensitively
4527     @articles = sort {uc($a) cmp uc($b)} @files;
4528
4529     # same thing in reversed order
4530     @articles = sort {$b cmp $a} @files;
4531
4532     # sort numerically ascending
4533     @articles = sort {$a <=> $b} @files;
4534
4535     # sort numerically descending
4536     @articles = sort {$b <=> $a} @files;
4537
4538     # this sorts the %age hash by value instead of key
4539     # using an in-line function
4540     @eldest = sort { $age{$b} <=> $age{$a} } keys %age;
4541
4542     # sort using explicit subroutine name
4543     sub byage {
4544         $age{$a} <=> $age{$b};  # presuming numeric
4545     }
4546     @sortedclass = sort byage @class;
4547
4548     sub backwards { $b cmp $a }
4549     @harry  = qw(dog cat x Cain Abel);
4550     @george = qw(gone chased yz Punished Axed);
4551     print sort @harry;
4552             # prints AbelCaincatdogx
4553     print sort backwards @harry;
4554             # prints xdogcatCainAbel
4555     print sort @george, 'to', @harry;
4556             # prints AbelAxedCainPunishedcatchaseddoggonetoxyz
4557
4558     # inefficiently sort by descending numeric compare using
4559     # the first integer after the first = sign, or the
4560     # whole record case-insensitively otherwise
4561
4562     @new = sort {
4563         ($b =~ /=(\d+)/)[0] <=> ($a =~ /=(\d+)/)[0]
4564                             ||
4565                     uc($a)  cmp  uc($b)
4566     } @old;
4567
4568     # same thing, but much more efficiently;
4569     # we'll build auxiliary indices instead
4570     # for speed
4571     @nums = @caps = ();
4572     for (@old) {
4573         push @nums, /=(\d+)/;
4574         push @caps, uc($_);
4575     }
4576
4577     @new = @old[ sort {
4578                         $nums[$b] <=> $nums[$a]
4579                                  ||
4580                         $caps[$a] cmp $caps[$b]
4581                        } 0..$#old
4582                ];
4583
4584     # same thing, but without any temps
4585     @new = map { $_->[0] }
4586            sort { $b->[1] <=> $a->[1]
4587                            ||
4588                   $a->[2] cmp $b->[2]
4589            } map { [$_, /=(\d+)/, uc($_)] } @old;
4590
4591     # using a prototype allows you to use any comparison subroutine
4592     # as a sort subroutine (including other package's subroutines)
4593     package other;
4594     sub backwards ($$) { $_[1] cmp $_[0]; }     # $a and $b are not set here
4595
4596     package main;
4597     @new = sort other::backwards @old;
4598
4599     # guarantee stability, regardless of algorithm
4600     use sort 'stable';
4601     @new = sort { substr($a, 3, 5) cmp substr($b, 3, 5) } @old;
4602
4603     # force use of mergesort (not portable outside Perl 5.8)
4604     use sort '_mergesort';  # note discouraging _
4605     @new = sort { substr($a, 3, 5) cmp substr($b, 3, 5) } @old;
4606
4607 If you're using strict, you I<must not> declare $a
4608 and $b as lexicals.  They are package globals.  That means
4609 if you're in the C<main> package and type
4610
4611     @articles = sort {$b <=> $a} @files;
4612
4613 then C<$a> and C<$b> are C<$main::a> and C<$main::b> (or C<$::a> and C<$::b>),
4614 but if you're in the C<FooPack> package, it's the same as typing
4615
4616     @articles = sort {$FooPack::b <=> $FooPack::a} @files;
4617
4618 The comparison function is required to behave.  If it returns
4619 inconsistent results (sometimes saying C<$x[1]> is less than C<$x[2]> and
4620 sometimes saying the opposite, for example) the results are not
4621 well-defined.
4622
4623 =item splice ARRAY,OFFSET,LENGTH,LIST
4624
4625 =item splice ARRAY,OFFSET,LENGTH
4626
4627 =item splice ARRAY,OFFSET
4628
4629 =item splice ARRAY
4630
4631 Removes the elements designated by OFFSET and LENGTH from an array, and
4632 replaces them with the elements of LIST, if any.  In list context,
4633 returns the elements removed from the array.  In scalar context,
4634 returns the last element removed, or C<undef> if no elements are
4635 removed.  The array grows or shrinks as necessary.
4636 If OFFSET is negative then it starts that far from the end of the array.
4637 If LENGTH is omitted, removes everything from OFFSET onward.
4638 If LENGTH is negative, removes the elements from OFFSET onward
4639 except for -LENGTH elements at the end of the array.
4640 If both OFFSET and LENGTH are omitted, removes everything. If OFFSET is