t/op/die_exit.t

   1 #!./perl -w
   2
   3 #
   4 # Verify that C<die> return the return code
   5 #       -- Robin Barker
   6 #
   7
   8 BEGIN {
   9     chdir 't' if -d 't';
  10     @INC = '../lib';
  11     require './test.pl';
  12 }
  13
  14 use strict;
  15
  16 skip_all('broken on MPE/iX') if $^O eq 'mpeix';
  17
  18 $| = 1;
  19
  20 my @tests = (
  21         [   0,   0],
  22         [   0,   1],
  23         [   0, 127],
  24         [   0, 128],
  25         [   0, 255],
  26         [   0, 256],
  27         [   0, 512],
  28         [   1,   0],
  29         [   1,   1],
  30         [   1, 256],
  31         [ 128,   0],
  32         [ 128,   1],
  33         [ 128, 256],
  34         [ 255,   0],
  35         [ 255,   1],
  36         [ 255, 256],
  37         # see if implicit close preserves $?
  38         [  0,  512, '{ local *F; open F, q[TEST]; close F; $!=0 } die;'],
  39 );
  40
  41 plan(tests => scalar @tests);
  42
  43 my $vms_exit_mode = 0;
  44
  45 if ($^O eq 'VMS') {
  46     if (eval 'require VMS::Feature') {
  47         $vms_exit_mode = !(VMS::Feature::current("posix_exit"));
  48     } else {
  49         my $env_unix_rpt = $ENV{'DECC$FILENAME_UNIX_REPORT'} || '';
  50         my $env_posix_ex = $ENV{'PERL_VMS_POSIX_EXIT'} || '';
  51         my $unix_rpt = $env_unix_rpt =~ /^[ET1]/i;
  52         my $posix_ex = $env_posix_ex =~ /^[ET1]/i;
  53         if (($unix_rpt || $posix_ex) ) {
  54             $vms_exit_mode = 0;
  55         } else {
  56             $vms_exit_mode = 1;
  57         }
  58     }
  59 }
  60
  61 # Dump any error messages from the dying processes off to a temp file.
  62 my $tempfile = tempfile();
  63 open STDERR, '>', $tempfile or die "Can't open temp error file $tempfile:  $!";
  64
  65 foreach my $test (@tests) {
  66     my($bang, $query, $code) = @$test;
  67     $code ||= 'die;';
  68     if ($^O eq 'MSWin32' || $^O eq 'NetWare' || $^O eq 'VMS') {
  69         system(qq{$^X -e "\$! = $bang; \$? = $query; $code"});
  70     }
  71     else {
  72         system(qq{$^X -e '\$! = $bang; \$? = $query; $code'});
  73     }
  74     my $exit = $?;
  75
  76     # The legacy VMS exit code 44 (SS$_ABORT) is returned if a program dies.
  77     # We only get the severity bits, which boils down to 4.  See L<perlvms/$?>.
  78     $bang = 4 if $vms_exit_mode;
  79
  80     is($exit, (($bang || ($query >> 8) || 255) << 8),
  81        sprintf "exit = 0x%04x bang = 0x%04x query = 0x%04x", $exit, $bang, $query);
  82 }
  83
  84 close STDERR;