This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
0cc1e9a9bb0c68850dbc0125c602dac6d4e17979
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2 X<function>
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides scalar context to its
16 argument, while a list operator may provide either scalar or list
17 contexts for its arguments.  If it does both, scalar arguments 
18 come first and list argument follow, and there can only ever
19 be one such list argument.  For instance, splice() has three scalar
20 arguments followed by a list, whereas gethostbyname() has four scalar
21 arguments.
22
23 In the syntax descriptions that follow, list operators that expect a
24 list (and provide list context for elements of the list) are shown
25 with LIST as an argument.  Such a list may consist of any combination
26 of scalar arguments or list values; the list values will be included
27 in the list as if each individual element were interpolated at that
28 point in the list, forming a longer single-dimensional list value.
29 Commas should separate literal elements of the LIST.
30
31 Any function in the list below may be used either with or without
32 parentheses around its arguments.  (The syntax descriptions omit the
33 parentheses.)  If you use parentheses, the simple but occasionally 
34 surprising rule is this: It I<looks> like a function, therefore it I<is> a
35 function, and precedence doesn't matter.  Otherwise it's a list
36 operator or unary operator, and precedence does matter.  Whitespace
37 between the function and left parenthesis doesn't count, so sometimes
38 you need to be careful:
39
40     print 1+2+4;      # Prints 7.
41     print(1+2) + 4;   # Prints 3.
42     print (1+2)+4;    # Also prints 3!
43     print +(1+2)+4;   # Prints 7.
44     print ((1+2)+4);  # Prints 7.
45
46 If you run Perl with the B<-w> switch it can warn you about this.  For
47 example, the third line above produces:
48
49     print (...) interpreted as function at - line 1.
50     Useless use of integer addition in void context at - line 1.
51
52 A few functions take no arguments at all, and therefore work as neither
53 unary nor list operators.  These include such functions as C<time>
54 and C<endpwent>.  For example, C<time+86_400> always means
55 C<time() + 86_400>.
56
57 For functions that can be used in either a scalar or list context,
58 nonabortive failure is generally indicated in scalar context by
59 returning the undefined value, and in list context by returning the
60 empty list.
61
62 Remember the following important rule: There is B<no rule> that relates
63 the behavior of an expression in list context to its behavior in scalar
64 context, or vice versa.  It might do two totally different things.
65 Each operator and function decides which sort of value would be most
66 appropriate to return in scalar context.  Some operators return the
67 length of the list that would have been returned in list context.  Some
68 operators return the first value in the list.  Some operators return the
69 last value in the list.  Some operators return a count of successful
70 operations.  In general, they do what you want, unless you want
71 consistency.
72 X<context>
73
74 A named array in scalar context is quite different from what would at
75 first glance appear to be a list in scalar context.  You can't get a list
76 like C<(1,2,3)> into being in scalar context, because the compiler knows
77 the context at compile time.  It would generate the scalar comma operator
78 there, not the list construction version of the comma.  That means it
79 was never a list to start with.
80
81 In general, functions in Perl that serve as wrappers for system calls ("syscalls")
82 of the same name (like chown(2), fork(2), closedir(2), etc.) return
83 true when they succeed and C<undef> otherwise, as is usually mentioned
84 in the descriptions below.  This is different from the C interfaces,
85 which return C<-1> on failure.  Exceptions to this rule include C<wait>,
86 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
87 variable on failure.  Other functions do not, except accidentally.
88
89 Extension modules can also hook into the Perl parser to define new
90 kinds of keyword-headed expression.  These may look like functions, but
91 may also look completely different.  The syntax following the keyword
92 is defined entirely by the extension.  If you are an implementor, see
93 L<perlapi/PL_keyword_plugin> for the mechanism.  If you are using such
94 a module, see the module's documentation for details of the syntax that
95 it defines.
96
97 =head2 Perl Functions by Category
98 X<function>
99
100 Here are Perl's functions (including things that look like
101 functions, like some keywords and named operators)
102 arranged by category.  Some functions appear in more
103 than one place.
104
105 =over 4
106
107 =item Functions for SCALARs or strings
108 X<scalar> X<string> X<character>
109
110 =for Pod::Functions =String
111
112 C<chomp>, C<chop>, C<chr>, C<crypt>, C<fc>, C<hex>, C<index>, C<lc>,
113 C<lcfirst>, C<length>, C<oct>, C<ord>, C<pack>, C<q//>, C<qq//>, C<reverse>,
114 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
115
116 C<fc> is available only if the C<"fc"> feature is enabled or if it is
117 prefixed with C<CORE::>.  The C<"fc"> feature is enabled automatically
118 with a C<use v5.16> (or higher) declaration in the current scope.
119
120
121 =item Regular expressions and pattern matching
122 X<regular expression> X<regex> X<regexp>
123
124 =for Pod::Functions =Regexp
125
126 C<m//>, C<pos>, C<qr//>, C<quotemeta>, C<s///>, C<split>, C<study>
127
128 =item Numeric functions
129 X<numeric> X<number> X<trigonometric> X<trigonometry>
130
131 =for Pod::Functions =Math
132
133 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
134 C<sin>, C<sqrt>, C<srand>
135
136 =item Functions for real @ARRAYs
137 X<array>
138
139 =for Pod::Functions =ARRAY
140
141 C<each>, C<keys>, C<pop>, C<push>, C<shift>, C<splice>, C<unshift>, C<values>
142
143 =item Functions for list data
144 X<list>
145
146 =for Pod::Functions =LIST
147
148 C<grep>, C<join>, C<map>, C<qw//>, C<reverse>, C<sort>, C<unpack>
149
150 =item Functions for real %HASHes
151 X<hash>
152
153 =for Pod::Functions =HASH
154
155 C<delete>, C<each>, C<exists>, C<keys>, C<values>
156
157 =item Input and output functions
158 X<I/O> X<input> X<output> X<dbm>
159
160 =for Pod::Functions =I/O
161
162 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
163 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
164 C<readdir>, C<readline> C<rewinddir>, C<say>, C<seek>, C<seekdir>, C<select>,
165 C<syscall>, C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>,
166 C<truncate>, C<warn>, C<write>
167
168 C<say> is available only if the C<"say"> feature is enabled or if it is
169 prefixed with C<CORE::>.  The C<"say"> feature is enabled automatically
170 with a C<use v5.10> (or higher) declaration in the current scope.
171
172 =item Functions for fixed-length data or records
173
174 =for Pod::Functions =Binary
175
176 C<pack>, C<read>, C<syscall>, C<sysread>, C<sysseek>, C<syswrite>, C<unpack>,
177 C<vec>
178
179 =item Functions for filehandles, files, or directories
180 X<file> X<filehandle> X<directory> X<pipe> X<link> X<symlink>
181
182 =for Pod::Functions =File
183
184 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
185 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
186 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
187 C<umask>, C<unlink>, C<utime>
188
189 =item Keywords related to the control flow of your Perl program
190 X<control flow>
191
192 =for Pod::Functions =Flow
193
194 C<break>, C<caller>, C<continue>, C<die>, C<do>,
195 C<dump>, C<eval>, C<evalbytes> C<exit>,
196 C<__FILE__>, C<goto>, C<last>, C<__LINE__>, C<next>, C<__PACKAGE__>,
197 C<redo>, C<return>, C<sub>, C<__SUB__>, C<wantarray>
198
199 C<break> is available only if you enable the experimental C<"switch">
200 feature or use the C<CORE::> prefix.  The C<"switch"> feature also enables
201 the C<default>, C<given> and C<when> statements, which are documented in
202 L<perlsyn/"Switch Statements">.  The C<"switch"> feature is enabled
203 automatically with a C<use v5.10> (or higher) declaration in the current
204 scope.  In Perl v5.14 and earlier, C<continue> required the C<"switch">
205 feature, like the other keywords.
206
207 C<evalbytes> is only available with the C<"evalbytes"> feature (see
208 L<feature>) or if prefixed with C<CORE::>.  C<__SUB__> is only available
209 with the C<"current_sub"> feature or if prefixed with C<CORE::>.  Both
210 the C<"evalbytes"> and C<"current_sub"> features are enabled automatically
211 with a C<use v5.16> (or higher) declaration in the current scope.
212
213 =item Keywords related to scoping
214
215 =for Pod::Functions =Namespace
216
217 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<state>, C<use>
218
219 C<state> is available only if the C<"state"> feature is enabled or if it is
220 prefixed with C<CORE::>.  The C<"state"> feature is enabled automatically
221 with a C<use v5.10> (or higher) declaration in the current scope.
222
223 =item Miscellaneous functions
224
225 =for Pod::Functions =Misc
226
227 C<defined>, C<formline>, C<lock>, C<prototype>, C<reset>, C<scalar>, C<undef>
228
229 =item Functions for processes and process groups
230 X<process> X<pid> X<process id>
231
232 =for Pod::Functions =Process
233
234 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
235 C<pipe>, C<qx//>, C<readpipe>, C<setpgrp>,
236 C<setpriority>, C<sleep>, C<system>,
237 C<times>, C<wait>, C<waitpid>
238
239 =item Keywords related to Perl modules
240 X<module>
241
242 =for Pod::Functions =Modules
243
244 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
245
246 =item Keywords related to classes and object-orientation
247 X<object> X<class> X<package>
248
249 =for Pod::Functions =Objects
250
251 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
252 C<untie>, C<use>
253
254 =item Low-level socket functions
255 X<socket> X<sock>
256
257 =for Pod::Functions =Socket
258
259 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
260 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
261 C<socket>, C<socketpair>
262
263 =item System V interprocess communication functions
264 X<IPC> X<System V> X<semaphore> X<shared memory> X<memory> X<message>
265
266 =for Pod::Functions =SysV
267
268 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
269 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
270
271 =item Fetching user and group info
272 X<user> X<group> X<password> X<uid> X<gid>  X<passwd> X</etc/passwd>
273
274 =for Pod::Functions =User
275
276 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
277 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
278 C<getpwuid>, C<setgrent>, C<setpwent>
279
280 =item Fetching network info
281 X<network> X<protocol> X<host> X<hostname> X<IP> X<address> X<service>
282
283 =for Pod::Functions =Network
284
285 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
286 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
287 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
288 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
289 C<setnetent>, C<setprotoent>, C<setservent>
290
291 =item Time-related functions
292 X<time> X<date>
293
294 =for Pod::Functions =Time
295
296 C<gmtime>, C<localtime>, C<time>, C<times>
297
298 =item Non-function keywords
299
300 =for Pod::Functions =!Non-functions
301
302 C<and>, C<AUTOLOAD>, C<BEGIN>, C<CHECK>, C<cmp>, C<CORE>, C<__DATA__>,
303 C<default>, C<DESTROY>, C<else>, C<elseif>, C<elsif>, C<END>, C<__END__>,
304 C<eq>, C<for>, C<foreach>, C<ge>, C<given>, C<gt>, C<if>, C<INIT>, C<le>,
305 C<lt>, C<ne>, C<not>, C<or>, C<UNITCHECK>, C<unless>, C<until>, C<when>,
306 C<while>, C<x>, C<xor>
307
308 =back
309
310 =head2 Portability
311 X<portability> X<Unix> X<portable>
312
313 Perl was born in Unix and can therefore access all common Unix
314 system calls.  In non-Unix environments, the functionality of some
315 Unix system calls may not be available or details of the available
316 functionality may differ slightly.  The Perl functions affected
317 by this are:
318
319 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
320 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
321 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
322 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
323 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
324 C<getppid>, C<getpgrp>, C<getpriority>, C<getprotobynumber>,
325 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
326 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
327 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
328 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
329 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
330 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
331 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
332 C<shmwrite>, C<socket>, C<socketpair>,
333 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
334 C<times>, C<truncate>, C<umask>, C<unlink>,
335 C<utime>, C<wait>, C<waitpid>
336
337 For more information about the portability of these functions, see
338 L<perlport> and other available platform-specific documentation.
339
340 =head2 Alphabetical Listing of Perl Functions
341
342 =over 
343
344 =item -X FILEHANDLE
345 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
346 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
347
348 =item -X EXPR
349
350 =item -X DIRHANDLE
351
352 =item -X
353
354 =for Pod::Functions a file test (-r, -x, etc)
355
356 A file test, where X is one of the letters listed below.  This unary
357 operator takes one argument, either a filename, a filehandle, or a dirhandle, 
358 and tests the associated file to see if something is true about it.  If the
359 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
360 Unless otherwise documented, it returns C<1> for true and C<''> for false.
361 If the file doesn't exist or can't be examined, it returns C<undef> and
362 sets C<$!> (errno).  Despite the funny names, precedence is the same as any
363 other named unary operator.  The operator may be any of:
364
365     -r  File is readable by effective uid/gid.
366     -w  File is writable by effective uid/gid.
367     -x  File is executable by effective uid/gid.
368     -o  File is owned by effective uid.
369
370     -R  File is readable by real uid/gid.
371     -W  File is writable by real uid/gid.
372     -X  File is executable by real uid/gid.
373     -O  File is owned by real uid.
374
375     -e  File exists.
376     -z  File has zero size (is empty).
377     -s  File has nonzero size (returns size in bytes).
378
379     -f  File is a plain file.
380     -d  File is a directory.
381     -l  File is a symbolic link.
382     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
383     -S  File is a socket.
384     -b  File is a block special file.
385     -c  File is a character special file.
386     -t  Filehandle is opened to a tty.
387
388     -u  File has setuid bit set.
389     -g  File has setgid bit set.
390     -k  File has sticky bit set.
391
392     -T  File is an ASCII text file (heuristic guess).
393     -B  File is a "binary" file (opposite of -T).
394
395     -M  Script start time minus file modification time, in days.
396     -A  Same for access time.
397     -C  Same for inode change time (Unix, may differ for other
398         platforms)
399
400 Example:
401
402     while (<>) {
403         chomp;
404         next unless -f $_;  # ignore specials
405         #...
406     }
407
408 Note that C<-s/a/b/> does not do a negated substitution.  Saying
409 C<-exp($foo)> still works as expected, however: only single letters
410 following a minus are interpreted as file tests.
411
412 These operators are exempt from the "looks like a function rule" described
413 above.  That is, an opening parenthesis after the operator does not affect
414 how much of the following code constitutes the argument.  Put the opening
415 parentheses before the operator to separate it from code that follows (this
416 applies only to operators with higher precedence than unary operators, of
417 course):
418
419     -s($file) + 1024   # probably wrong; same as -s($file + 1024)
420     (-s $file) + 1024  # correct
421
422 The interpretation of the file permission operators C<-r>, C<-R>,
423 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
424 of the file and the uids and gids of the user.  There may be other
425 reasons you can't actually read, write, or execute the file: for
426 example network filesystem access controls, ACLs (access control lists),
427 read-only filesystems, and unrecognized executable formats.  Note
428 that the use of these six specific operators to verify if some operation
429 is possible is usually a mistake, because it may be open to race
430 conditions.
431
432 Also note that, for the superuser on the local filesystems, the C<-r>,
433 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
434 if any execute bit is set in the mode.  Scripts run by the superuser
435 may thus need to do a stat() to determine the actual mode of the file,
436 or temporarily set their effective uid to something else.
437
438 If you are using ACLs, there is a pragma called C<filetest> that may
439 produce more accurate results than the bare stat() mode bits.
440 When under C<use filetest 'access'> the above-mentioned filetests
441 test whether the permission can(not) be granted using the
442 access(2) family of system calls.  Also note that the C<-x> and C<-X> may
443 under this pragma return true even if there are no execute permission
444 bits set (nor any extra execute permission ACLs).  This strangeness is
445 due to the underlying system calls' definitions.  Note also that, due to
446 the implementation of C<use filetest 'access'>, the C<_> special
447 filehandle won't cache the results of the file tests when this pragma is
448 in effect.  Read the documentation for the C<filetest> pragma for more
449 information.
450
451 The C<-T> and C<-B> switches work as follows.  The first block or so of the
452 file is examined for odd characters such as strange control codes or
453 characters with the high bit set.  If too many strange characters (>30%)
454 are found, it's a C<-B> file; otherwise it's a C<-T> file.  Also, any file
455 containing a zero byte in the first block is considered a binary file.  If C<-T>
456 or C<-B> is used on a filehandle, the current IO buffer is examined
457 rather than the first block.  Both C<-T> and C<-B> return true on an empty
458 file, or a file at EOF when testing a filehandle.  Because you have to
459 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
460 against the file first, as in C<next unless -f $file && -T $file>.
461
462 If any of the file tests (or either the C<stat> or C<lstat> operator) is given
463 the special filehandle consisting of a solitary underline, then the stat
464 structure of the previous file test (or stat operator) is used, saving
465 a system call.  (This doesn't work with C<-t>, and you need to remember
466 that lstat() and C<-l> leave values in the stat structure for the
467 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
468 an C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
469 Example:
470
471     print "Can do.\n" if -r $a || -w _ || -x _;
472
473     stat($filename);
474     print "Readable\n" if -r _;
475     print "Writable\n" if -w _;
476     print "Executable\n" if -x _;
477     print "Setuid\n" if -u _;
478     print "Setgid\n" if -g _;
479     print "Sticky\n" if -k _;
480     print "Text\n" if -T _;
481     print "Binary\n" if -B _;
482
483 As of Perl 5.10.0, as a form of purely syntactic sugar, you can stack file
484 test operators, in a way that C<-f -w -x $file> is equivalent to
485 C<-x $file && -w _ && -f _>.  (This is only fancy syntax: if you use
486 the return value of C<-f $file> as an argument to another filetest
487 operator, no special magic will happen.)
488
489 Portability issues: L<perlport/-X>.
490
491 To avoid confusing would-be users of your code with mysterious
492 syntax errors, put something like this at the top of your script:
493
494     use 5.010;  # so filetest ops can stack
495
496 =item abs VALUE
497 X<abs> X<absolute>
498
499 =item abs
500
501 =for Pod::Functions absolute value function
502
503 Returns the absolute value of its argument.
504 If VALUE is omitted, uses C<$_>.
505
506 =item accept NEWSOCKET,GENERICSOCKET
507 X<accept>
508
509 =for Pod::Functions accept an incoming socket connect
510
511 Accepts an incoming socket connect, just as accept(2) 
512 does.  Returns the packed address if it succeeded, false otherwise.
513 See the example in L<perlipc/"Sockets: Client/Server Communication">.
514
515 On systems that support a close-on-exec flag on files, the flag will
516 be set for the newly opened file descriptor, as determined by the
517 value of $^F.  See L<perlvar/$^F>.
518
519 =item alarm SECONDS
520 X<alarm>
521 X<SIGALRM>
522 X<timer>
523
524 =item alarm
525
526 =for Pod::Functions schedule a SIGALRM
527
528 Arranges to have a SIGALRM delivered to this process after the
529 specified number of wallclock seconds has elapsed.  If SECONDS is not
530 specified, the value stored in C<$_> is used.  (On some machines,
531 unfortunately, the elapsed time may be up to one second less or more
532 than you specified because of how seconds are counted, and process
533 scheduling may delay the delivery of the signal even further.)
534
535 Only one timer may be counting at once.  Each call disables the
536 previous timer, and an argument of C<0> may be supplied to cancel the
537 previous timer without starting a new one.  The returned value is the
538 amount of time remaining on the previous timer.
539
540 For delays of finer granularity than one second, the Time::HiRes module
541 (from CPAN, and starting from Perl 5.8 part of the standard
542 distribution) provides ualarm().  You may also use Perl's four-argument
543 version of select() leaving the first three arguments undefined, or you
544 might be able to use the C<syscall> interface to access setitimer(2) if
545 your system supports it.  See L<perlfaq8> for details.
546
547 It is usually a mistake to intermix C<alarm> and C<sleep> calls, because
548 C<sleep> may be internally implemented on your system with C<alarm>.
549
550 If you want to use C<alarm> to time out a system call you need to use an
551 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
552 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
553 restart system calls on some systems.  Using C<eval>/C<die> always works,
554 modulo the caveats given in L<perlipc/"Signals">.
555
556     eval {
557         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
558         alarm $timeout;
559         $nread = sysread SOCKET, $buffer, $size;
560         alarm 0;
561     };
562     if ($@) {
563         die unless $@ eq "alarm\n";   # propagate unexpected errors
564         # timed out
565     }
566     else {
567         # didn't
568     }
569
570 For more information see L<perlipc>.
571
572 Portability issues: L<perlport/alarm>.
573
574 =item atan2 Y,X
575 X<atan2> X<arctangent> X<tan> X<tangent>
576
577 =for Pod::Functions arctangent of Y/X in the range -PI to PI
578
579 Returns the arctangent of Y/X in the range -PI to PI.
580
581 For the tangent operation, you may use the C<Math::Trig::tan>
582 function, or use the familiar relation:
583
584     sub tan { sin($_[0]) / cos($_[0])  }
585
586 The return value for C<atan2(0,0)> is implementation-defined; consult
587 your atan2(3) manpage for more information.
588
589 Portability issues: L<perlport/atan2>.
590
591 =item bind SOCKET,NAME
592 X<bind>
593
594 =for Pod::Functions binds an address to a socket
595
596 Binds a network address to a socket, just as bind(2)
597 does.  Returns true if it succeeded, false otherwise.  NAME should be a
598 packed address of the appropriate type for the socket.  See the examples in
599 L<perlipc/"Sockets: Client/Server Communication">.
600
601 =item binmode FILEHANDLE, LAYER
602 X<binmode> X<binary> X<text> X<DOS> X<Windows>
603
604 =item binmode FILEHANDLE
605
606 =for Pod::Functions prepare binary files for I/O
607
608 Arranges for FILEHANDLE to be read or written in "binary" or "text"
609 mode on systems where the run-time libraries distinguish between
610 binary and text files.  If FILEHANDLE is an expression, the value is
611 taken as the name of the filehandle.  Returns true on success,
612 otherwise it returns C<undef> and sets C<$!> (errno).
613
614 On some systems (in general, DOS- and Windows-based systems) binmode()
615 is necessary when you're not working with a text file.  For the sake
616 of portability it is a good idea always to use it when appropriate,
617 and never to use it when it isn't appropriate.  Also, people can
618 set their I/O to be by default UTF8-encoded Unicode, not bytes.
619
620 In other words: regardless of platform, use binmode() on binary data,
621 like images, for example.
622
623 If LAYER is present it is a single string, but may contain multiple
624 directives.  The directives alter the behaviour of the filehandle.
625 When LAYER is present, using binmode on a text file makes sense.
626
627 If LAYER is omitted or specified as C<:raw> the filehandle is made
628 suitable for passing binary data.  This includes turning off possible CRLF
629 translation and marking it as bytes (as opposed to Unicode characters).
630 Note that, despite what may be implied in I<"Programming Perl"> (the
631 Camel, 3rd edition) or elsewhere, C<:raw> is I<not> simply the inverse of C<:crlf>.
632 Other layers that would affect the binary nature of the stream are
633 I<also> disabled.  See L<PerlIO>, L<perlrun>, and the discussion about the
634 PERLIO environment variable.
635
636 The C<:bytes>, C<:crlf>, C<:utf8>, and any other directives of the
637 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
638 establish default I/O layers.  See L<open>.
639
640 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
641 in "Programming Perl, 3rd Edition".  However, since the publishing of this
642 book, by many known as "Camel III", the consensus of the naming of this
643 functionality has moved from "discipline" to "layer".  All documentation
644 of this version of Perl therefore refers to "layers" rather than to
645 "disciplines".  Now back to the regularly scheduled documentation...>
646
647 To mark FILEHANDLE as UTF-8, use C<:utf8> or C<:encoding(UTF-8)>.
648 C<:utf8> just marks the data as UTF-8 without further checking,
649 while C<:encoding(UTF-8)> checks the data for actually being valid
650 UTF-8.  More details can be found in L<PerlIO::encoding>.
651
652 In general, binmode() should be called after open() but before any I/O
653 is done on the filehandle.  Calling binmode() normally flushes any
654 pending buffered output data (and perhaps pending input data) on the
655 handle.  An exception to this is the C<:encoding> layer that
656 changes the default character encoding of the handle; see L</open>.
657 The C<:encoding> layer sometimes needs to be called in
658 mid-stream, and it doesn't flush the stream.  The C<:encoding>
659 also implicitly pushes on top of itself the C<:utf8> layer because
660 internally Perl operates on UTF8-encoded Unicode characters.
661
662 The operating system, device drivers, C libraries, and Perl run-time
663 system all conspire to let the programmer treat a single
664 character (C<\n>) as the line terminator, irrespective of external
665 representation.  On many operating systems, the native text file
666 representation matches the internal representation, but on some
667 platforms the external representation of C<\n> is made up of more than
668 one character.
669
670 All variants of Unix, Mac OS (old and new), and Stream_LF files on VMS use
671 a single character to end each line in the external representation of text
672 (even though that single character is CARRIAGE RETURN on old, pre-Darwin
673 flavors of Mac OS, and is LINE FEED on Unix and most VMS files).  In other
674 systems like OS/2, DOS, and the various flavors of MS-Windows, your program
675 sees a C<\n> as a simple C<\cJ>, but what's stored in text files are the
676 two characters C<\cM\cJ>.  That means that if you don't use binmode() on
677 these systems, C<\cM\cJ> sequences on disk will be converted to C<\n> on
678 input, and any C<\n> in your program will be converted back to C<\cM\cJ> on
679 output.  This is what you want for text files, but it can be disastrous for
680 binary files.
681
682 Another consequence of using binmode() (on some systems) is that
683 special end-of-file markers will be seen as part of the data stream.
684 For systems from the Microsoft family this means that, if your binary
685 data contain C<\cZ>, the I/O subsystem will regard it as the end of
686 the file, unless you use binmode().
687
688 binmode() is important not only for readline() and print() operations,
689 but also when using read(), seek(), sysread(), syswrite() and tell()
690 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
691 in L<perlvar> for how to manually set your input and output
692 line-termination sequences.
693
694 Portability issues: L<perlport/binmode>.
695
696 =item bless REF,CLASSNAME
697 X<bless>
698
699 =item bless REF
700
701 =for Pod::Functions create an object
702
703 This function tells the thingy referenced by REF that it is now an object
704 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
705 is used.  Because a C<bless> is often the last thing in a constructor,
706 it returns the reference for convenience.  Always use the two-argument
707 version if a derived class might inherit the function doing the blessing.
708 See L<perlobj> for more about the blessing (and blessings) of objects.
709
710 Consider always blessing objects in CLASSNAMEs that are mixed case.
711 Namespaces with all lowercase names are considered reserved for
712 Perl pragmata.  Builtin types have all uppercase names.  To prevent
713 confusion, you may wish to avoid such package names as well.  Make sure
714 that CLASSNAME is a true value.
715
716 See L<perlmod/"Perl Modules">.
717
718 =item break
719
720 =for Pod::Functions +switch break out of a C<given> block
721
722 Break out of a C<given()> block.
723
724 This keyword is enabled by the C<"switch"> feature; see L<feature> for
725 more information on C<"switch">.  You can also access it by prefixing it
726 with C<CORE::>.  Alternatively, include a C<use v5.10> or later to the
727 current scope.
728
729 =item caller EXPR
730 X<caller> X<call stack> X<stack> X<stack trace>
731
732 =item caller
733
734 =for Pod::Functions get context of the current subroutine call
735
736 Returns the context of the current pure perl subroutine call.  In scalar
737 context, returns the caller's package name if there I<is> a caller (that is, if
738 we're in a subroutine or C<eval> or C<require>) and the undefined value
739 otherwise.  caller never returns XS subs and they are skipped.  The next pure
740 perl sub will appear instead of the XS sub in caller's return values. In list
741 context, caller returns
742
743     # 0         1          2
744     ($package, $filename, $line) = caller;
745
746 With EXPR, it returns some extra information that the debugger uses to
747 print a stack trace.  The value of EXPR indicates how many call frames
748 to go back before the current one.
749
750     #  0         1          2      3            4
751     ($package, $filename, $line, $subroutine, $hasargs,
752
753     #  5          6          7            8       9         10
754     $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash)
755      = caller($i);
756
757 Here, $subroutine is the function that the caller called (rather than the
758 function containing the caller). Note that $subroutine may be C<(eval)> if
759 the frame is not a subroutine call, but an C<eval>.  In such a case
760 additional elements $evaltext and
761 C<$is_require> are set: C<$is_require> is true if the frame is created by a
762 C<require> or C<use> statement, $evaltext contains the text of the
763 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
764 $subroutine is C<(eval)>, but $evaltext is undefined.  (Note also that
765 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
766 frame.)  $subroutine may also be C<(unknown)> if this particular
767 subroutine happens to have been deleted from the symbol table.
768 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
769 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
770 compiled with.  C<$hints> corresponds to C<$^H>, and C<$bitmask>
771 corresponds to C<${^WARNING_BITS}>.  The
772 C<$hints> and C<$bitmask> values are subject
773 to change between versions of Perl, and are not meant for external use.
774
775 C<$hinthash> is a reference to a hash containing the value of C<%^H> when the
776 caller was compiled, or C<undef> if C<%^H> was empty.  Do not modify the values
777 of this hash, as they are the actual values stored in the optree.
778
779 Furthermore, when called from within the DB package in
780 list context, and with an argument, caller returns more
781 detailed information: it sets the list variable C<@DB::args> to be the
782 arguments with which the subroutine was invoked.
783
784 Be aware that the optimizer might have optimized call frames away before
785 C<caller> had a chance to get the information.  That means that C<caller(N)>
786 might not return information about the call frame you expect it to, for
787 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
788 previous time C<caller> was called.
789
790 Be aware that setting C<@DB::args> is I<best effort>, intended for
791 debugging or generating backtraces, and should not be relied upon.  In
792 particular, as C<@_> contains aliases to the caller's arguments, Perl does
793 not take a copy of C<@_>, so C<@DB::args> will contain modifications the
794 subroutine makes to C<@_> or its contents, not the original values at call
795 time.  C<@DB::args>, like C<@_>, does not hold explicit references to its
796 elements, so under certain cases its elements may have become freed and
797 reallocated for other variables or temporary values.  Finally, a side effect
798 of the current implementation is that the effects of C<shift @_> can
799 I<normally> be undone (but not C<pop @_> or other splicing, I<and> not if a
800 reference to C<@_> has been taken, I<and> subject to the caveat about reallocated
801 elements), so C<@DB::args> is actually a hybrid of the current state and
802 initial state of C<@_>.  Buyer beware.
803
804 =item chdir EXPR
805 X<chdir>
806 X<cd>
807 X<directory, change>
808
809 =item chdir FILEHANDLE
810
811 =item chdir DIRHANDLE
812
813 =item chdir
814
815 =for Pod::Functions change your current working directory
816
817 Changes the working directory to EXPR, if possible.  If EXPR is omitted,
818 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
819 changes to the directory specified by C<$ENV{LOGDIR}>.  (Under VMS, the
820 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.)  If
821 neither is set, C<chdir> does nothing.  It returns true on success,
822 false otherwise.  See the example under C<die>.
823
824 On systems that support fchdir(2), you may pass a filehandle or
825 directory handle as the argument.  On systems that don't support fchdir(2),
826 passing handles raises an exception.
827
828 =item chmod LIST
829 X<chmod> X<permission> X<mode>
830
831 =for Pod::Functions changes the permissions on a list of files
832
833 Changes the permissions of a list of files.  The first element of the
834 list must be the numeric mode, which should probably be an octal
835 number, and which definitely should I<not> be a string of octal digits:
836 C<0644> is okay, but C<"0644"> is not.  Returns the number of files
837 successfully changed.  See also L</oct> if all you have is a string.
838
839     $cnt = chmod 0755, "foo", "bar";
840     chmod 0755, @executables;
841     $mode = "0644"; chmod $mode, "foo";      # !!! sets mode to
842                                              # --w----r-T
843     $mode = "0644"; chmod oct($mode), "foo"; # this is better
844     $mode = 0644;   chmod $mode, "foo";      # this is best
845
846 On systems that support fchmod(2), you may pass filehandles among the
847 files.  On systems that don't support fchmod(2), passing filehandles raises
848 an exception.  Filehandles must be passed as globs or glob references to be
849 recognized; barewords are considered filenames.
850
851     open(my $fh, "<", "foo");
852     my $perm = (stat $fh)[2] & 07777;
853     chmod($perm | 0600, $fh);
854
855 You can also import the symbolic C<S_I*> constants from the C<Fcntl>
856 module:
857
858     use Fcntl qw( :mode );
859     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
860     # Identical to the chmod 0755 of the example above.
861
862 Portability issues: L<perlport/chmod>.
863
864 =item chomp VARIABLE
865 X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol>
866
867 =item chomp( LIST )
868
869 =item chomp
870
871 =for Pod::Functions remove a trailing record separator from a string
872
873 This safer version of L</chop> removes any trailing string
874 that corresponds to the current value of C<$/> (also known as
875 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
876 number of characters removed from all its arguments.  It's often used to
877 remove the newline from the end of an input record when you're worried
878 that the final record may be missing its newline.  When in paragraph
879 mode (C<$/ = "">), it removes all trailing newlines from the string.
880 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
881 a reference to an integer or the like; see L<perlvar>) chomp() won't
882 remove anything.
883 If VARIABLE is omitted, it chomps C<$_>.  Example:
884
885     while (<>) {
886         chomp;  # avoid \n on last field
887         @array = split(/:/);
888         # ...
889     }
890
891 If VARIABLE is a hash, it chomps the hash's values, but not its keys,
892 resetting the C<each> iterator in the process.
893
894 You can actually chomp anything that's an lvalue, including an assignment:
895
896     chomp($cwd = `pwd`);
897     chomp($answer = <STDIN>);
898
899 If you chomp a list, each element is chomped, and the total number of
900 characters removed is returned.
901
902 Note that parentheses are necessary when you're chomping anything
903 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
904 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
905 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
906 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
907 as C<chomp($a, $b)>.
908
909 =item chop VARIABLE
910 X<chop>
911
912 =item chop( LIST )
913
914 =item chop
915
916 =for Pod::Functions remove the last character from a string
917
918 Chops off the last character of a string and returns the character
919 chopped.  It is much more efficient than C<s/.$//s> because it neither
920 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
921 If VARIABLE is a hash, it chops the hash's values, but not its keys,
922 resetting the C<each> iterator in the process.
923
924 You can actually chop anything that's an lvalue, including an assignment.
925
926 If you chop a list, each element is chopped.  Only the value of the
927 last C<chop> is returned.
928
929 Note that C<chop> returns the last character.  To return all but the last
930 character, use C<substr($string, 0, -1)>.
931
932 See also L</chomp>.
933
934 =item chown LIST
935 X<chown> X<owner> X<user> X<group>
936
937 =for Pod::Functions change the ownership on a list of files
938
939 Changes the owner (and group) of a list of files.  The first two
940 elements of the list must be the I<numeric> uid and gid, in that
941 order.  A value of -1 in either position is interpreted by most
942 systems to leave that value unchanged.  Returns the number of files
943 successfully changed.
944
945     $cnt = chown $uid, $gid, 'foo', 'bar';
946     chown $uid, $gid, @filenames;
947
948 On systems that support fchown(2), you may pass filehandles among the
949 files.  On systems that don't support fchown(2), passing filehandles raises
950 an exception.  Filehandles must be passed as globs or glob references to be
951 recognized; barewords are considered filenames.
952
953 Here's an example that looks up nonnumeric uids in the passwd file:
954
955     print "User: ";
956     chomp($user = <STDIN>);
957     print "Files: ";
958     chomp($pattern = <STDIN>);
959
960     ($login,$pass,$uid,$gid) = getpwnam($user)
961         or die "$user not in passwd file";
962
963     @ary = glob($pattern);  # expand filenames
964     chown $uid, $gid, @ary;
965
966 On most systems, you are not allowed to change the ownership of the
967 file unless you're the superuser, although you should be able to change
968 the group to any of your secondary groups.  On insecure systems, these
969 restrictions may be relaxed, but this is not a portable assumption.
970 On POSIX systems, you can detect this condition this way:
971
972     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
973     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
974
975 Portability issues: L<perlport/chown>.
976
977 =item chr NUMBER
978 X<chr> X<character> X<ASCII> X<Unicode>
979
980 =item chr
981
982 =for Pod::Functions get character this number represents
983
984 Returns the character represented by that NUMBER in the character set.
985 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
986 chr(0x263a) is a Unicode smiley face.  
987
988 Negative values give the Unicode replacement character (chr(0xfffd)),
989 except under the L<bytes> pragma, where the low eight bits of the value
990 (truncated to an integer) are used.
991
992 If NUMBER is omitted, uses C<$_>.
993
994 For the reverse, use L</ord>.
995
996 Note that characters from 128 to 255 (inclusive) are by default
997 internally not encoded as UTF-8 for backward compatibility reasons.
998
999 See L<perlunicode> for more about Unicode.
1000
1001 =item chroot FILENAME
1002 X<chroot> X<root>
1003
1004 =item chroot
1005
1006 =for Pod::Functions make directory new root for path lookups
1007
1008 This function works like the system call by the same name: it makes the
1009 named directory the new root directory for all further pathnames that
1010 begin with a C</> by your process and all its children.  (It doesn't
1011 change your current working directory, which is unaffected.)  For security
1012 reasons, this call is restricted to the superuser.  If FILENAME is
1013 omitted, does a C<chroot> to C<$_>.
1014
1015 Portability issues: L<perlport/chroot>.
1016
1017 =item close FILEHANDLE
1018 X<close>
1019
1020 =item close
1021
1022 =for Pod::Functions close file (or pipe or socket) handle
1023
1024 Closes the file or pipe associated with the filehandle, flushes the IO
1025 buffers, and closes the system file descriptor.  Returns true if those
1026 operations succeed and if no error was reported by any PerlIO
1027 layer.  Closes the currently selected filehandle if the argument is
1028 omitted.
1029
1030 You don't have to close FILEHANDLE if you are immediately going to do
1031 another C<open> on it, because C<open> closes it for you.  (See
1032 L<open|/open FILEHANDLE>.)  However, an explicit C<close> on an input file resets the line
1033 counter (C<$.>), while the implicit close done by C<open> does not.
1034
1035 If the filehandle came from a piped open, C<close> returns false if one of
1036 the other syscalls involved fails or if its program exits with non-zero
1037 status.  If the only problem was that the program exited non-zero, C<$!>
1038 will be set to C<0>.  Closing a pipe also waits for the process executing
1039 on the pipe to exit--in case you wish to look at the output of the pipe
1040 afterwards--and implicitly puts the exit status value of that command into
1041 C<$?> and C<${^CHILD_ERROR_NATIVE}>.
1042
1043 If there are multiple threads running, C<close> on a filehandle from a
1044 piped open returns true without waiting for the child process to terminate,
1045 if the filehandle is still open in another thread.
1046
1047 Closing the read end of a pipe before the process writing to it at the
1048 other end is done writing results in the writer receiving a SIGPIPE.  If
1049 the other end can't handle that, be sure to read all the data before
1050 closing the pipe.
1051
1052 Example:
1053
1054     open(OUTPUT, '|sort >foo')  # pipe to sort
1055         or die "Can't start sort: $!";
1056     #...                        # print stuff to output
1057     close OUTPUT                # wait for sort to finish
1058         or warn $! ? "Error closing sort pipe: $!"
1059                    : "Exit status $? from sort";
1060     open(INPUT, 'foo')          # get sort's results
1061         or die "Can't open 'foo' for input: $!";
1062
1063 FILEHANDLE may be an expression whose value can be used as an indirect
1064 filehandle, usually the real filehandle name or an autovivified handle.
1065
1066 =item closedir DIRHANDLE
1067 X<closedir>
1068
1069 =for Pod::Functions close directory handle
1070
1071 Closes a directory opened by C<opendir> and returns the success of that
1072 system call.
1073
1074 =item connect SOCKET,NAME
1075 X<connect>
1076
1077 =for Pod::Functions connect to a remote socket
1078
1079 Attempts to connect to a remote socket, just like connect(2).
1080 Returns true if it succeeded, false otherwise.  NAME should be a
1081 packed address of the appropriate type for the socket.  See the examples in
1082 L<perlipc/"Sockets: Client/Server Communication">.
1083
1084 =item continue BLOCK
1085 X<continue>
1086
1087 =item continue
1088
1089 =for Pod::Functions optional trailing block in a while or foreach
1090
1091 When followed by a BLOCK, C<continue> is actually a
1092 flow control statement rather than a function.  If
1093 there is a C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
1094 C<foreach>), it is always executed just before the conditional is about to
1095 be evaluated again, just like the third part of a C<for> loop in C.  Thus
1096 it can be used to increment a loop variable, even when the loop has been
1097 continued via the C<next> statement (which is similar to the C C<continue>
1098 statement).
1099
1100 C<last>, C<next>, or C<redo> may appear within a C<continue>
1101 block; C<last> and C<redo> behave as if they had been executed within
1102 the main block.  So will C<next>, but since it will execute a C<continue>
1103 block, it may be more entertaining.
1104
1105     while (EXPR) {
1106         ### redo always comes here
1107         do_something;
1108     } continue {
1109         ### next always comes here
1110         do_something_else;
1111         # then back the top to re-check EXPR
1112     }
1113     ### last always comes here
1114
1115 Omitting the C<continue> section is equivalent to using an
1116 empty one, logically enough, so C<next> goes directly back
1117 to check the condition at the top of the loop.
1118
1119 When there is no BLOCK, C<continue> is a function that
1120 falls through the current C<when> or C<default> block instead of iterating
1121 a dynamically enclosing C<foreach> or exiting a lexically enclosing C<given>.
1122 In Perl 5.14 and earlier, this form of C<continue> was
1123 only available when the C<"switch"> feature was enabled.
1124 See L<feature> and L<perlsyn/"Switch Statements"> for more
1125 information.
1126
1127 =item cos EXPR
1128 X<cos> X<cosine> X<acos> X<arccosine>
1129
1130 =item cos
1131
1132 =for Pod::Functions cosine function
1133
1134 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
1135 takes the cosine of C<$_>.
1136
1137 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
1138 function, or use this relation:
1139
1140     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
1141
1142 =item crypt PLAINTEXT,SALT
1143 X<crypt> X<digest> X<hash> X<salt> X<plaintext> X<password>
1144 X<decrypt> X<cryptography> X<passwd> X<encrypt>
1145
1146 =for Pod::Functions one-way passwd-style encryption
1147
1148 Creates a digest string exactly like the crypt(3) function in the C
1149 library (assuming that you actually have a version there that has not
1150 been extirpated as a potential munition).
1151
1152 crypt() is a one-way hash function.  The PLAINTEXT and SALT are turned
1153 into a short string, called a digest, which is returned.  The same
1154 PLAINTEXT and SALT will always return the same string, but there is no
1155 (known) way to get the original PLAINTEXT from the hash.  Small
1156 changes in the PLAINTEXT or SALT will result in large changes in the
1157 digest.
1158
1159 There is no decrypt function.  This function isn't all that useful for
1160 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
1161 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
1162 primarily used to check if two pieces of text are the same without
1163 having to transmit or store the text itself.  An example is checking
1164 if a correct password is given.  The digest of the password is stored,
1165 not the password itself.  The user types in a password that is
1166 crypt()'d with the same salt as the stored digest.  If the two digests
1167 match, the password is correct.
1168
1169 When verifying an existing digest string you should use the digest as
1170 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
1171 to create the digest is visible as part of the digest.  This ensures
1172 crypt() will hash the new string with the same salt as the digest.
1173 This allows your code to work with the standard L<crypt|/crypt> and
1174 with more exotic implementations.  In other words, assume
1175 nothing about the returned string itself nor about how many bytes 
1176 of SALT may matter.
1177
1178 Traditionally the result is a string of 13 bytes: two first bytes of
1179 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
1180 the first eight bytes of PLAINTEXT mattered.  But alternative
1181 hashing schemes (like MD5), higher level security schemes (like C2),
1182 and implementations on non-Unix platforms may produce different
1183 strings.
1184
1185 When choosing a new salt create a random two character string whose
1186 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
1187 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
1188 characters is just a recommendation; the characters allowed in
1189 the salt depend solely on your system's crypt library, and Perl can't
1190 restrict what salts C<crypt()> accepts.
1191
1192 Here's an example that makes sure that whoever runs this program knows
1193 their password:
1194
1195     $pwd = (getpwuid($<))[1];
1196
1197     system "stty -echo";
1198     print "Password: ";
1199     chomp($word = <STDIN>);
1200     print "\n";
1201     system "stty echo";
1202
1203     if (crypt($word, $pwd) ne $pwd) {
1204         die "Sorry...\n";
1205     } else {
1206         print "ok\n";
1207     }
1208
1209 Of course, typing in your own password to whoever asks you
1210 for it is unwise.
1211
1212 The L<crypt|/crypt> function is unsuitable for hashing large quantities
1213 of data, not least of all because you can't get the information
1214 back.  Look at the L<Digest> module for more robust algorithms.
1215
1216 If using crypt() on a Unicode string (which I<potentially> has
1217 characters with codepoints above 255), Perl tries to make sense
1218 of the situation by trying to downgrade (a copy of)
1219 the string back to an eight-bit byte string before calling crypt()
1220 (on that copy).  If that works, good.  If not, crypt() dies with
1221 C<Wide character in crypt>.
1222
1223 Portability issues: L<perlport/crypt>.
1224
1225 =item dbmclose HASH
1226 X<dbmclose>
1227
1228 =for Pod::Functions breaks binding on a tied dbm file
1229
1230 [This function has been largely superseded by the C<untie> function.]
1231
1232 Breaks the binding between a DBM file and a hash.
1233
1234 Portability issues: L<perlport/dbmclose>.
1235
1236 =item dbmopen HASH,DBNAME,MASK
1237 X<dbmopen> X<dbm> X<ndbm> X<sdbm> X<gdbm>
1238
1239 =for Pod::Functions create binding on a tied dbm file
1240
1241 [This function has been largely superseded by the
1242 L<tie|/tie VARIABLE,CLASSNAME,LIST> function.]
1243
1244 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
1245 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
1246 argument is I<not> a filehandle, even though it looks like one).  DBNAME
1247 is the name of the database (without the F<.dir> or F<.pag> extension if
1248 any).  If the database does not exist, it is created with protection
1249 specified by MASK (as modified by the C<umask>).  To prevent creation of
1250 the database if it doesn't exist, you may specify a MODE
1251 of 0, and the function will return a false value if it
1252 can't find an existing database.  If your system supports
1253 only the older DBM functions, you may make only one C<dbmopen> call in your
1254 program.  In older versions of Perl, if your system had neither DBM nor
1255 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
1256 sdbm(3).
1257
1258 If you don't have write access to the DBM file, you can only read hash
1259 variables, not set them.  If you want to test whether you can write,
1260 either use file tests or try setting a dummy hash entry inside an C<eval> 
1261 to trap the error.
1262
1263 Note that functions such as C<keys> and C<values> may return huge lists
1264 when used on large DBM files.  You may prefer to use the C<each>
1265 function to iterate over large DBM files.  Example:
1266
1267     # print out history file offsets
1268     dbmopen(%HIST,'/usr/lib/news/history',0666);
1269     while (($key,$val) = each %HIST) {
1270         print $key, ' = ', unpack('L',$val), "\n";
1271     }
1272     dbmclose(%HIST);
1273
1274 See also L<AnyDBM_File> for a more general description of the pros and
1275 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1276 rich implementation.
1277
1278 You can control which DBM library you use by loading that library
1279 before you call dbmopen():
1280
1281     use DB_File;
1282     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1283         or die "Can't open netscape history file: $!";
1284
1285 Portability issues: L<perlport/dbmopen>.
1286
1287 =item defined EXPR
1288 X<defined> X<undef> X<undefined>
1289
1290 =item defined
1291
1292 =for Pod::Functions test whether a value, variable, or function is defined
1293
1294 Returns a Boolean value telling whether EXPR has a value other than
1295 the undefined value C<undef>.  If EXPR is not present, C<$_> is
1296 checked.
1297
1298 Many operations return C<undef> to indicate failure, end of file,
1299 system error, uninitialized variable, and other exceptional
1300 conditions.  This function allows you to distinguish C<undef> from
1301 other values.  (A simple Boolean test will not distinguish among
1302 C<undef>, zero, the empty string, and C<"0">, which are all equally
1303 false.)  Note that since C<undef> is a valid scalar, its presence
1304 doesn't I<necessarily> indicate an exceptional condition: C<pop>
1305 returns C<undef> when its argument is an empty array, I<or> when the
1306 element to return happens to be C<undef>.
1307
1308 You may also use C<defined(&func)> to check whether subroutine C<&func>
1309 has ever been defined.  The return value is unaffected by any forward
1310 declarations of C<&func>.  A subroutine that is not defined
1311 may still be callable: its package may have an C<AUTOLOAD> method that
1312 makes it spring into existence the first time that it is called; see
1313 L<perlsub>.
1314
1315 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1316 used to report whether memory for that aggregate had ever been
1317 allocated.  This behavior may disappear in future versions of Perl.
1318 You should instead use a simple test for size:
1319
1320     if (@an_array) { print "has array elements\n" }
1321     if (%a_hash)   { print "has hash members\n"   }
1322
1323 When used on a hash element, it tells you whether the value is defined,
1324 not whether the key exists in the hash.  Use L</exists> for the latter
1325 purpose.
1326
1327 Examples:
1328
1329     print if defined $switch{D};
1330     print "$val\n" while defined($val = pop(@ary));
1331     die "Can't readlink $sym: $!"
1332         unless defined($value = readlink $sym);
1333     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1334     $debugging = 0 unless defined $debugging;
1335
1336 Note:  Many folks tend to overuse C<defined> and are then surprised to
1337 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1338 defined values.  For example, if you say
1339
1340     "ab" =~ /a(.*)b/;
1341
1342 The pattern match succeeds and C<$1> is defined, although it
1343 matched "nothing".  It didn't really fail to match anything.  Rather, it
1344 matched something that happened to be zero characters long.  This is all
1345 very above-board and honest.  When a function returns an undefined value,
1346 it's an admission that it couldn't give you an honest answer.  So you
1347 should use C<defined> only when questioning the integrity of what
1348 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1349 what you want.
1350
1351 See also L</undef>, L</exists>, L</ref>.
1352
1353 =item delete EXPR
1354 X<delete>
1355
1356 =for Pod::Functions deletes a value from a hash
1357
1358 Given an expression that specifies an element or slice of a hash, C<delete>
1359 deletes the specified elements from that hash so that exists() on that element
1360 no longer returns true.  Setting a hash element to the undefined value does
1361 not remove its key, but deleting it does; see L</exists>.
1362
1363 In list context, returns the value or values deleted, or the last such
1364 element in scalar context.  The return list's length always matches that of
1365 the argument list: deleting non-existent elements returns the undefined value
1366 in their corresponding positions.
1367
1368 delete() may also be used on arrays and array slices, but its behavior is less
1369 straightforward.  Although exists() will return false for deleted entries,
1370 deleting array elements never changes indices of existing values; use shift()
1371 or splice() for that.  However, if any deleted elements fall at the end of an
1372 array, the array's size shrinks to the position of the highest element that
1373 still tests true for exists(), or to 0 if none do. In other words, an
1374 array won't have trailing nonexistent elements after a delete.
1375
1376 B<WARNING:> Calling delete on array values is deprecated and likely to
1377 be removed in a future version of Perl.
1378
1379 Deleting from C<%ENV> modifies the environment.  Deleting from a hash tied to
1380 a DBM file deletes the entry from the DBM file.  Deleting from a C<tied> hash
1381 or array may not necessarily return anything; it depends on the implementation
1382 of the C<tied> package's DELETE method, which may do whatever it pleases.
1383
1384 The C<delete local EXPR> construct localizes the deletion to the current
1385 block at run time.  Until the block exits, elements locally deleted
1386 temporarily no longer exist.  See L<perlsub/"Localized deletion of elements
1387 of composite types">.
1388
1389     %hash = (foo => 11, bar => 22, baz => 33);
1390     $scalar = delete $hash{foo};         # $scalar is 11
1391     $scalar = delete @hash{qw(foo bar)}; # $scalar is 22
1392     @array  = delete @hash{qw(foo baz)}; # @array  is (undef,33)
1393
1394 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1395
1396     foreach $key (keys %HASH) {
1397         delete $HASH{$key};
1398     }
1399
1400     foreach $index (0 .. $#ARRAY) {
1401         delete $ARRAY[$index];
1402     }
1403
1404 And so do these:
1405
1406     delete @HASH{keys %HASH};
1407
1408     delete @ARRAY[0 .. $#ARRAY];
1409
1410 But both are slower than assigning the empty list
1411 or undefining %HASH or @ARRAY, which is the customary 
1412 way to empty out an aggregate:
1413
1414     %HASH = ();     # completely empty %HASH
1415     undef %HASH;    # forget %HASH ever existed
1416
1417     @ARRAY = ();    # completely empty @ARRAY
1418     undef @ARRAY;   # forget @ARRAY ever existed
1419
1420 The EXPR can be arbitrarily complicated provided its
1421 final operation is an element or slice of an aggregate:
1422
1423     delete $ref->[$x][$y]{$key};
1424     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1425
1426     delete $ref->[$x][$y][$index];
1427     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1428
1429 =item die LIST
1430 X<die> X<throw> X<exception> X<raise> X<$@> X<abort>
1431
1432 =for Pod::Functions raise an exception or bail out
1433
1434 C<die> raises an exception.  Inside an C<eval> the error message is stuffed
1435 into C<$@> and the C<eval> is terminated with the undefined value.
1436 If the exception is outside of all enclosing C<eval>s, then the uncaught
1437 exception prints LIST to C<STDERR> and exits with a non-zero value.  If you
1438 need to exit the process with a specific exit code, see L</exit>.
1439
1440 Equivalent examples:
1441
1442     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1443     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1444
1445 If the last element of LIST does not end in a newline, the current
1446 script line number and input line number (if any) are also printed,
1447 and a newline is supplied.  Note that the "input line number" (also
1448 known as "chunk") is subject to whatever notion of "line" happens to
1449 be currently in effect, and is also available as the special variable
1450 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1451
1452 Hint: sometimes appending C<", stopped"> to your message will cause it
1453 to make better sense when the string C<"at foo line 123"> is appended.
1454 Suppose you are running script "canasta".
1455
1456     die "/etc/games is no good";
1457     die "/etc/games is no good, stopped";
1458
1459 produce, respectively
1460
1461     /etc/games is no good at canasta line 123.
1462     /etc/games is no good, stopped at canasta line 123.
1463
1464 If the output is empty and C<$@> already contains a value (typically from a
1465 previous eval) that value is reused after appending C<"\t...propagated">.
1466 This is useful for propagating exceptions:
1467
1468     eval { ... };
1469     die unless $@ =~ /Expected exception/;
1470
1471 If the output is empty and C<$@> contains an object reference that has a
1472 C<PROPAGATE> method, that method will be called with additional file
1473 and line number parameters.  The return value replaces the value in
1474 C<$@>;  i.e., as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1475 were called.
1476
1477 If C<$@> is empty then the string C<"Died"> is used.
1478
1479 If an uncaught exception results in interpreter exit, the exit code is
1480 determined from the values of C<$!> and C<$?> with this pseudocode:
1481
1482     exit $! if $!;              # errno
1483     exit $? >> 8 if $? >> 8;    # child exit status
1484     exit 255;                   # last resort
1485
1486 The intent is to squeeze as much possible information about the likely cause
1487 into the limited space of the system exit
1488 code.  However, as C<$!> is the value
1489 of C's C<errno>, which can be set by any system call, this means that the value
1490 of the exit code used by C<die> can be non-predictable, so should not be relied
1491 upon, other than to be non-zero.
1492
1493 You can also call C<die> with a reference argument, and if this is trapped
1494 within an C<eval>, C<$@> contains that reference.  This permits more
1495 elaborate exception handling using objects that maintain arbitrary state
1496 about the exception.  Such a scheme is sometimes preferable to matching
1497 particular string values of C<$@> with regular expressions.  Because C<$@> 
1498 is a global variable and C<eval> may be used within object implementations,
1499 be careful that analyzing the error object doesn't replace the reference in
1500 the global variable.  It's easiest to make a local copy of the reference
1501 before any manipulations.  Here's an example:
1502
1503     use Scalar::Util "blessed";
1504
1505     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1506     if (my $ev_err = $@) {
1507         if (blessed($ev_err)
1508             && $ev_err->isa("Some::Module::Exception")) {
1509             # handle Some::Module::Exception
1510         }
1511         else {
1512             # handle all other possible exceptions
1513         }
1514     }
1515
1516 Because Perl stringifies uncaught exception messages before display,
1517 you'll probably want to overload stringification operations on
1518 exception objects.  See L<overload> for details about that.
1519
1520 You can arrange for a callback to be run just before the C<die>
1521 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1522 handler is called with the error text and can change the error
1523 message, if it sees fit, by calling C<die> again.  See
1524 L<perlvar/%SIG> for details on setting C<%SIG> entries, and
1525 L<"eval BLOCK"> for some examples.  Although this feature was 
1526 to be run only right before your program was to exit, this is not
1527 currently so: the C<$SIG{__DIE__}> hook is currently called
1528 even inside eval()ed blocks/strings!  If one wants the hook to do
1529 nothing in such situations, put
1530
1531     die @_ if $^S;
1532
1533 as the first line of the handler (see L<perlvar/$^S>).  Because
1534 this promotes strange action at a distance, this counterintuitive
1535 behavior may be fixed in a future release.
1536
1537 See also exit(), warn(), and the Carp module.
1538
1539 =item do BLOCK
1540 X<do> X<block>
1541
1542 =for Pod::Functions turn a BLOCK into a TERM
1543
1544 Not really a function.  Returns the value of the last command in the
1545 sequence of commands indicated by BLOCK.  When modified by the C<while> or
1546 C<until> loop modifier, executes the BLOCK once before testing the loop
1547 condition.  (On other statements the loop modifiers test the conditional
1548 first.)
1549
1550 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1551 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1552 See L<perlsyn> for alternative strategies.
1553
1554 =item do EXPR
1555 X<do>
1556
1557 Uses the value of EXPR as a filename and executes the contents of the
1558 file as a Perl script.
1559
1560     do 'stat.pl';
1561
1562 is largely like
1563
1564     eval `cat stat.pl`;
1565
1566 except that it's more concise, runs no external processes, keeps track of
1567 the current
1568 filename for error messages, searches the C<@INC> directories, and updates
1569 C<%INC> if the file is found.  See L<perlvar/@INC> and L<perlvar/%INC> for
1570 these variables.  It also differs in that code evaluated with C<do FILENAME>
1571 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1572 same, however, in that it does reparse the file every time you call it,
1573 so you probably don't want to do this inside a loop.
1574
1575 If C<do> can read the file but cannot compile it, it returns C<undef> and sets
1576 an error message in C<$@>.  If C<do> cannot read the file, it returns undef
1577 and sets C<$!> to the error.  Always check C<$@> first, as compilation
1578 could fail in a way that also sets C<$!>.  If the file is successfully
1579 compiled, C<do> returns the value of the last expression evaluated.
1580
1581 Inclusion of library modules is better done with the
1582 C<use> and C<require> operators, which also do automatic error checking
1583 and raise an exception if there's a problem.
1584
1585 You might like to use C<do> to read in a program configuration
1586 file.  Manual error checking can be done this way:
1587
1588     # read in config files: system first, then user
1589     for $file ("/share/prog/defaults.rc",
1590                "$ENV{HOME}/.someprogrc")
1591     {
1592         unless ($return = do $file) {
1593             warn "couldn't parse $file: $@" if $@;
1594             warn "couldn't do $file: $!"    unless defined $return;
1595             warn "couldn't run $file"       unless $return;
1596         }
1597     }
1598
1599 =item dump LABEL
1600 X<dump> X<core> X<undump>
1601
1602 =item dump EXPR
1603
1604 =item dump
1605
1606 =for Pod::Functions create an immediate core dump
1607
1608 This function causes an immediate core dump.  See also the B<-u>
1609 command-line switch in L<perlrun>, which does the same thing.
1610 Primarily this is so that you can use the B<undump> program (not
1611 supplied) to turn your core dump into an executable binary after
1612 having initialized all your variables at the beginning of the
1613 program.  When the new binary is executed it will begin by executing
1614 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1615 Think of it as a goto with an intervening core dump and reincarnation.
1616 If C<LABEL> is omitted, restarts the program from the top.  The
1617 C<dump EXPR> form, available starting in Perl 5.18.0, allows a name to be
1618 computed at run time, being otherwise identical to C<dump LABEL>.
1619
1620 B<WARNING>: Any files opened at the time of the dump will I<not>
1621 be open any more when the program is reincarnated, with possible
1622 resulting confusion by Perl.
1623
1624 This function is now largely obsolete, mostly because it's very hard to
1625 convert a core file into an executable.  That's why you should now invoke
1626 it as C<CORE::dump()>, if you don't want to be warned against a possible
1627 typo.
1628
1629 Unlike most named operators, this has the same precedence as assignment.
1630 It is also exempt from the looks-like-a-function rule, so
1631 C<dump ("foo")."bar"> will cause "bar" to be part of the argument to
1632 C<dump>.
1633
1634 Portability issues: L<perlport/dump>.
1635
1636 =item each HASH
1637 X<each> X<hash, iterator>
1638
1639 =item each ARRAY
1640 X<array, iterator>
1641
1642 =item each EXPR
1643
1644 =for Pod::Functions retrieve the next key/value pair from a hash
1645
1646 When called on a hash in list context, returns a 2-element list
1647 consisting of the key and value for the next element of a hash.  In Perl
1648 5.12 and later only, it will also return the index and value for the next
1649 element of an array so that you can iterate over it; older Perls consider
1650 this a syntax error.  When called in scalar context, returns only the key
1651 (not the value) in a hash, or the index in an array.
1652
1653 Hash entries are returned in an apparently random order.  The actual random
1654 order is specific to a given hash; the exact same series of operations
1655 on two hashes may result in a different order for each hash.  Any insertion
1656 into the hash may change the order, as will any deletion, with the exception
1657 that the most recent key returned by C<each> or C<keys> may be deleted
1658 without changing the order.  So long as a given hash is unmodified you may
1659 rely on C<keys>, C<values> and C<each> to repeatedly return the same order
1660 as each other.  See L<perlsec/"Algorithmic Complexity Attacks"> for
1661 details on why hash order is randomized.  Aside from the guarantees
1662 provided here the exact details of Perl's hash algorithm and the hash
1663 traversal order are subject to change in any release of Perl.
1664
1665 After C<each> has returned all entries from the hash or array, the next
1666 call to C<each> returns the empty list in list context and C<undef> in
1667 scalar context; the next call following I<that> one restarts iteration.
1668 Each hash or array has its own internal iterator, accessed by C<each>,
1669 C<keys>, and C<values>.  The iterator is implicitly reset when C<each> has
1670 reached the end as just described; it can be explicitly reset by calling
1671 C<keys> or C<values> on the hash or array.  If you add or delete a hash's
1672 elements while iterating over it, the effect on the iterator is
1673 unspecified; for example, entries may be skipped or duplicated--so don't
1674 do that.  Exception: It is always safe to delete the item most recently
1675 returned by C<each()>, so the following code works properly:
1676
1677         while (($key, $value) = each %hash) {
1678           print $key, "\n";
1679           delete $hash{$key};   # This is safe
1680         }
1681
1682 This prints out your environment like the printenv(1) program,
1683 but in a different order:
1684
1685     while (($key,$value) = each %ENV) {
1686         print "$key=$value\n";
1687     }
1688
1689 Starting with Perl 5.14, C<each> can take a scalar EXPR, which must hold
1690 reference to an unblessed hash or array.  The argument will be dereferenced
1691 automatically.  This aspect of C<each> is considered highly experimental.
1692 The exact behaviour may change in a future version of Perl.
1693
1694     while (($key,$value) = each $hashref) { ... }
1695
1696 As of Perl 5.18 you can use a bare C<each> in a C<while> loop,
1697 which will set C<$_> on every iteration.
1698
1699     while(each %ENV) {
1700         print "$_=$ENV{$_}\n";
1701     }
1702
1703 To avoid confusing would-be users of your code who are running earlier
1704 versions of Perl with mysterious syntax errors, put this sort of thing at
1705 the top of your file to signal that your code will work I<only> on Perls of
1706 a recent vintage:
1707
1708     use 5.012;  # so keys/values/each work on arrays
1709     use 5.014;  # so keys/values/each work on scalars (experimental)
1710     use 5.018;  # so each assigns to $_ in a lone while test
1711
1712 See also C<keys>, C<values>, and C<sort>.
1713
1714 =item eof FILEHANDLE
1715 X<eof>
1716 X<end of file>
1717 X<end-of-file>
1718
1719 =item eof ()
1720
1721 =item eof
1722
1723 =for Pod::Functions test a filehandle for its end
1724
1725 Returns 1 if the next read on FILEHANDLE will return end of file I<or> if
1726 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1727 gives the real filehandle.  (Note that this function actually
1728 reads a character and then C<ungetc>s it, so isn't useful in an
1729 interactive context.)  Do not read from a terminal file (or call
1730 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1731 as terminals may lose the end-of-file condition if you do.
1732
1733 An C<eof> without an argument uses the last file read.  Using C<eof()>
1734 with empty parentheses is different.  It refers to the pseudo file
1735 formed from the files listed on the command line and accessed via the
1736 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1737 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1738 used will cause C<@ARGV> to be examined to determine if input is
1739 available.   Similarly, an C<eof()> after C<< <> >> has returned
1740 end-of-file will assume you are processing another C<@ARGV> list,
1741 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1742 see L<perlop/"I/O Operators">.
1743
1744 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1745 detect the end of each file, whereas C<eof()> will detect the end 
1746 of the very last file only.  Examples:
1747
1748     # reset line numbering on each input file
1749     while (<>) {
1750         next if /^\s*#/;  # skip comments
1751         print "$.\t$_";
1752     } continue {
1753         close ARGV if eof;  # Not eof()!
1754     }
1755
1756     # insert dashes just before last line of last file
1757     while (<>) {
1758         if (eof()) {  # check for end of last file
1759             print "--------------\n";
1760         }
1761         print;
1762         last if eof();     # needed if we're reading from a terminal
1763     }
1764
1765 Practical hint: you almost never need to use C<eof> in Perl, because the
1766 input operators typically return C<undef> when they run out of data or 
1767 encounter an error.
1768
1769 =item eval EXPR
1770 X<eval> X<try> X<catch> X<evaluate> X<parse> X<execute>
1771 X<error, handling> X<exception, handling>
1772
1773 =item eval BLOCK
1774
1775 =item eval
1776
1777 =for Pod::Functions catch exceptions or compile and run code
1778
1779 In the first form, often referred to as a "string eval", the return
1780 value of EXPR is parsed and executed as if it
1781 were a little Perl program.  The value of the expression (which is itself
1782 determined within scalar context) is first parsed, and if there were no
1783 errors, executed as a block within the lexical context of the current Perl
1784 program.  This means, that in particular, any outer lexical variables are
1785 visible to it, and any package variable settings or subroutine and format
1786 definitions remain afterwards.
1787
1788 Note that the value is parsed every time the C<eval> executes.
1789 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1790 delay parsing and subsequent execution of the text of EXPR until run time.
1791
1792 If the C<unicode_eval> feature is enabled (which is the default under a
1793 C<use 5.16> or higher declaration), EXPR or C<$_> is treated as a string of
1794 characters, so C<use utf8> declarations have no effect, and source filters
1795 are forbidden.  In the absence of the C<unicode_eval> feature, the string
1796 will sometimes be treated as characters and sometimes as bytes, depending
1797 on the internal encoding, and source filters activated within the C<eval>
1798 exhibit the erratic, but historical, behaviour of affecting some outer file
1799 scope that is still compiling.  See also the L</evalbytes> keyword, which
1800 always treats its input as a byte stream and works properly with source
1801 filters, and the L<feature> pragma.
1802
1803 Problems can arise if the string expands a scalar containing a floating
1804 point number.  That scalar can expand to letters, such as C<"NaN"> or
1805 C<"Infinity">; or, within the scope of a C<use locale>, the decimal
1806 point character may be something other than a dot (such as a comma).
1807 None of these are likely to parse as you are likely expecting.
1808
1809 In the second form, the code within the BLOCK is parsed only once--at the
1810 same time the code surrounding the C<eval> itself was parsed--and executed
1811 within the context of the current Perl program.  This form is typically
1812 used to trap exceptions more efficiently than the first (see below), while
1813 also providing the benefit of checking the code within BLOCK at compile
1814 time.
1815
1816 The final semicolon, if any, may be omitted from the value of EXPR or within
1817 the BLOCK.
1818
1819 In both forms, the value returned is the value of the last expression
1820 evaluated inside the mini-program; a return statement may be also used, just
1821 as with subroutines.  The expression providing the return value is evaluated
1822 in void, scalar, or list context, depending on the context of the C<eval> 
1823 itself.  See L</wantarray> for more on how the evaluation context can be 
1824 determined.
1825
1826 If there is a syntax error or runtime error, or a C<die> statement is
1827 executed, C<eval> returns C<undef> in scalar context
1828 or an empty list in list context, and C<$@> is set to the error
1829 message.  (Prior to 5.16, a bug caused C<undef> to be returned
1830 in list context for syntax errors, but not for runtime errors.)
1831 If there was no error, C<$@> is set to the empty string.  A
1832 control flow operator like C<last> or C<goto> can bypass the setting of
1833 C<$@>.  Beware that using C<eval> neither silences Perl from printing
1834 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1835 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1836 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1837 See L</warn>, L<perlvar>, and L<warnings>.
1838
1839 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1840 determining whether a particular feature (such as C<socket> or C<symlink>)
1841 is implemented.  It is also Perl's exception-trapping mechanism, where
1842 the die operator is used to raise exceptions.
1843
1844 If you want to trap errors when loading an XS module, some problems with
1845 the binary interface (such as Perl version skew) may be fatal even with
1846 C<eval> unless C<$ENV{PERL_DL_NONLAZY}> is set.  See L<perlrun>.
1847
1848 If the code to be executed doesn't vary, you may use the eval-BLOCK
1849 form to trap run-time errors without incurring the penalty of
1850 recompiling each time.  The error, if any, is still returned in C<$@>.
1851 Examples:
1852
1853     # make divide-by-zero nonfatal
1854     eval { $answer = $a / $b; }; warn $@ if $@;
1855
1856     # same thing, but less efficient
1857     eval '$answer = $a / $b'; warn $@ if $@;
1858
1859     # a compile-time error
1860     eval { $answer = }; # WRONG
1861
1862     # a run-time error
1863     eval '$answer =';   # sets $@
1864
1865 Using the C<eval{}> form as an exception trap in libraries does have some
1866 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
1867 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
1868 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1869 as this example shows:
1870
1871     # a private exception trap for divide-by-zero
1872     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1873     warn $@ if $@;
1874
1875 This is especially significant, given that C<__DIE__> hooks can call
1876 C<die> again, which has the effect of changing their error messages:
1877
1878     # __DIE__ hooks may modify error messages
1879     {
1880        local $SIG{'__DIE__'} =
1881               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1882        eval { die "foo lives here" };
1883        print $@ if $@;                # prints "bar lives here"
1884     }
1885
1886 Because this promotes action at a distance, this counterintuitive behavior
1887 may be fixed in a future release.
1888
1889 With an C<eval>, you should be especially careful to remember what's
1890 being looked at when:
1891
1892     eval $x;        # CASE 1
1893     eval "$x";      # CASE 2
1894
1895     eval '$x';      # CASE 3
1896     eval { $x };    # CASE 4
1897
1898     eval "\$$x++";  # CASE 5
1899     $$x++;          # CASE 6
1900
1901 Cases 1 and 2 above behave identically: they run the code contained in
1902 the variable $x.  (Although case 2 has misleading double quotes making
1903 the reader wonder what else might be happening (nothing is).)  Cases 3
1904 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1905 does nothing but return the value of $x.  (Case 4 is preferred for
1906 purely visual reasons, but it also has the advantage of compiling at
1907 compile-time instead of at run-time.)  Case 5 is a place where
1908 normally you I<would> like to use double quotes, except that in this
1909 particular situation, you can just use symbolic references instead, as
1910 in case 6.
1911
1912 Before Perl 5.14, the assignment to C<$@> occurred before restoration 
1913 of localized variables, which means that for your code to run on older
1914 versions, a temporary is required if you want to mask some but not all
1915 errors:
1916
1917     # alter $@ on nefarious repugnancy only
1918     {
1919        my $e;
1920        {
1921          local $@; # protect existing $@
1922          eval { test_repugnancy() };
1923          # $@ =~ /nefarious/ and die $@; # Perl 5.14 and higher only
1924          $@ =~ /nefarious/ and $e = $@;
1925        }
1926        die $e if defined $e
1927     }
1928
1929 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1930 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1931
1932 An C<eval ''> executed within a subroutine defined
1933 in the C<DB> package doesn't see the usual
1934 surrounding lexical scope, but rather the scope of the first non-DB piece
1935 of code that called it.  You don't normally need to worry about this unless
1936 you are writing a Perl debugger.
1937
1938 =item evalbytes EXPR
1939 X<evalbytes>
1940
1941 =item evalbytes
1942
1943 =for Pod::Functions +evalbytes similar to string eval, but intend to parse a bytestream
1944
1945 This function is like L</eval> with a string argument, except it always
1946 parses its argument, or C<$_> if EXPR is omitted, as a string of bytes.  A
1947 string containing characters whose ordinal value exceeds 255 results in an
1948 error.  Source filters activated within the evaluated code apply to the
1949 code itself.
1950
1951 This function is only available under the C<evalbytes> feature, a
1952 C<use v5.16> (or higher) declaration, or with a C<CORE::> prefix.  See
1953 L<feature> for more information.
1954
1955 =item exec LIST
1956 X<exec> X<execute>
1957
1958 =item exec PROGRAM LIST
1959
1960 =for Pod::Functions abandon this program to run another
1961
1962 The C<exec> function executes a system command I<and never returns>;
1963 use C<system> instead of C<exec> if you want it to return.  It fails and
1964 returns false only if the command does not exist I<and> it is executed
1965 directly instead of via your system's command shell (see below).
1966
1967 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1968 warns you if C<exec> is called in void context and if there is a following
1969 statement that isn't C<die>, C<warn>, or C<exit> (if C<-w> is set--but
1970 you always do that, right?).  If you I<really> want to follow an C<exec>
1971 with some other statement, you can use one of these styles to avoid the warning:
1972
1973     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1974     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1975
1976 If there is more than one argument in LIST, this calls execvp(3) with the
1977 arguments in LIST.  If there is only one element in LIST, the argument is
1978 checked for shell metacharacters, and if there are any, the entire
1979 argument is passed to the system's command shell for parsing (this is
1980 C</bin/sh -c> on Unix platforms, but varies on other platforms).  If
1981 there are no shell metacharacters in the argument, it is split into words
1982 and passed directly to C<execvp>, which is more efficient.  Examples:
1983
1984     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1985     exec "sort $outfile | uniq";
1986
1987 If you don't really want to execute the first argument, but want to lie
1988 to the program you are executing about its own name, you can specify
1989 the program you actually want to run as an "indirect object" (without a
1990 comma) in front of the LIST.  (This always forces interpretation of the
1991 LIST as a multivalued list, even if there is only a single scalar in
1992 the list.)  Example:
1993
1994     $shell = '/bin/csh';
1995     exec $shell '-sh';    # pretend it's a login shell
1996
1997 or, more directly,
1998
1999     exec {'/bin/csh'} '-sh';  # pretend it's a login shell
2000
2001 When the arguments get executed via the system shell, results are
2002 subject to its quirks and capabilities.  See L<perlop/"`STRING`">
2003 for details.
2004
2005 Using an indirect object with C<exec> or C<system> is also more
2006 secure.  This usage (which also works fine with system()) forces
2007 interpretation of the arguments as a multivalued list, even if the
2008 list had just one argument.  That way you're safe from the shell
2009 expanding wildcards or splitting up words with whitespace in them.
2010
2011     @args = ( "echo surprise" );
2012
2013     exec @args;               # subject to shell escapes
2014                                 # if @args == 1
2015     exec { $args[0] } @args;  # safe even with one-arg list
2016
2017 The first version, the one without the indirect object, ran the I<echo>
2018 program, passing it C<"surprise"> an argument.  The second version didn't;
2019 it tried to run a program named I<"echo surprise">, didn't find it, and set
2020 C<$?> to a non-zero value indicating failure.
2021
2022 Perl attempts to flush all files opened for output before the exec,
2023 but this may not be supported on some platforms (see L<perlport>).
2024 To be safe, you may need to set C<$|> ($AUTOFLUSH in English) or
2025 call the C<autoflush()> method of C<IO::Handle> on any open handles
2026 to avoid lost output.
2027
2028 Note that C<exec> will not call your C<END> blocks, nor will it invoke
2029 C<DESTROY> methods on your objects.
2030
2031 Portability issues: L<perlport/exec>.
2032
2033 =item exists EXPR
2034 X<exists> X<autovivification>
2035
2036 =for Pod::Functions test whether a hash key is present
2037
2038 Given an expression that specifies an element of a hash, returns true if the
2039 specified element in the hash has ever been initialized, even if the
2040 corresponding value is undefined.
2041
2042     print "Exists\n"    if exists $hash{$key};
2043     print "Defined\n"   if defined $hash{$key};
2044     print "True\n"      if $hash{$key};
2045
2046 exists may also be called on array elements, but its behavior is much less
2047 obvious and is strongly tied to the use of L</delete> on arrays.  B<Be aware>
2048 that calling exists on array values is deprecated and likely to be removed in
2049 a future version of Perl.
2050
2051     print "Exists\n"    if exists $array[$index];
2052     print "Defined\n"   if defined $array[$index];
2053     print "True\n"      if $array[$index];
2054
2055 A hash or array element can be true only if it's defined and defined only if
2056 it exists, but the reverse doesn't necessarily hold true.
2057
2058 Given an expression that specifies the name of a subroutine,
2059 returns true if the specified subroutine has ever been declared, even
2060 if it is undefined.  Mentioning a subroutine name for exists or defined
2061 does not count as declaring it.  Note that a subroutine that does not
2062 exist may still be callable: its package may have an C<AUTOLOAD>
2063 method that makes it spring into existence the first time that it is
2064 called; see L<perlsub>.
2065
2066     print "Exists\n"  if exists &subroutine;
2067     print "Defined\n" if defined &subroutine;
2068
2069 Note that the EXPR can be arbitrarily complicated as long as the final
2070 operation is a hash or array key lookup or subroutine name:
2071
2072     if (exists $ref->{A}->{B}->{$key})  { }
2073     if (exists $hash{A}{B}{$key})       { }
2074
2075     if (exists $ref->{A}->{B}->[$ix])   { }
2076     if (exists $hash{A}{B}[$ix])        { }
2077
2078     if (exists &{$ref->{A}{B}{$key}})   { }
2079
2080 Although the most deeply nested array or hash element will not spring into
2081 existence just because its existence was tested, any intervening ones will.
2082 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
2083 into existence due to the existence test for the $key element above.
2084 This happens anywhere the arrow operator is used, including even here:
2085
2086     undef $ref;
2087     if (exists $ref->{"Some key"})    { }
2088     print $ref;  # prints HASH(0x80d3d5c)
2089
2090 This surprising autovivification in what does not at first--or even
2091 second--glance appear to be an lvalue context may be fixed in a future
2092 release.
2093
2094 Use of a subroutine call, rather than a subroutine name, as an argument
2095 to exists() is an error.
2096
2097     exists &sub;    # OK
2098     exists &sub();  # Error
2099
2100 =item exit EXPR
2101 X<exit> X<terminate> X<abort>
2102
2103 =item exit
2104
2105 =for Pod::Functions terminate this program
2106
2107 Evaluates EXPR and exits immediately with that value.    Example:
2108
2109     $ans = <STDIN>;
2110     exit 0 if $ans =~ /^[Xx]/;
2111
2112 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
2113 universally recognized values for EXPR are C<0> for success and C<1>
2114 for error; other values are subject to interpretation depending on the
2115 environment in which the Perl program is running.  For example, exiting
2116 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
2117 the mailer to return the item undelivered, but that's not true everywhere.
2118
2119 Don't use C<exit> to abort a subroutine if there's any chance that
2120 someone might want to trap whatever error happened.  Use C<die> instead,
2121 which can be trapped by an C<eval>.
2122
2123 The exit() function does not always exit immediately.  It calls any
2124 defined C<END> routines first, but these C<END> routines may not
2125 themselves abort the exit.  Likewise any object destructors that need to
2126 be called are called before the real exit.  C<END> routines and destructors
2127 can change the exit status by modifying C<$?>.  If this is a problem, you
2128 can call C<POSIX::_exit($status)> to avoid END and destructor processing.
2129 See L<perlmod> for details.
2130
2131 Portability issues: L<perlport/exit>.
2132
2133 =item exp EXPR
2134 X<exp> X<exponential> X<antilog> X<antilogarithm> X<e>
2135
2136 =item exp
2137
2138 =for Pod::Functions raise I<e> to a power
2139
2140 Returns I<e> (the natural logarithm base) to the power of EXPR.
2141 If EXPR is omitted, gives C<exp($_)>.
2142
2143 =item fc EXPR
2144 X<fc> X<foldcase> X<casefold> X<fold-case> X<case-fold>
2145
2146 =item fc
2147
2148 =for Pod::Functions +fc return casefolded version of a string
2149
2150 Returns the casefolded version of EXPR.  This is the internal function
2151 implementing the C<\F> escape in double-quoted strings.
2152
2153 Casefolding is the process of mapping strings to a form where case
2154 differences are erased; comparing two strings in their casefolded
2155 form is effectively a way of asking if two strings are equal,
2156 regardless of case.
2157
2158 Roughly, if you ever found yourself writing this
2159
2160     lc($this) eq lc($that)    # Wrong!
2161         # or
2162     uc($this) eq uc($that)    # Also wrong!
2163         # or
2164     $this =~ /^\Q$that\E\z/i  # Right!
2165
2166 Now you can write
2167
2168     fc($this) eq fc($that)
2169
2170 And get the correct results.
2171
2172 Perl only implements the full form of casefolding,
2173 but you can access the simple folds using L<Unicode::UCD/casefold()> and
2174 L<Unicode::UCD/prop_invmap()>.
2175 For further information on casefolding, refer to
2176 the Unicode Standard, specifically sections 3.13 C<Default Case Operations>,
2177 4.2 C<Case-Normative>, and 5.18 C<Case Mappings>,
2178 available at L<http://www.unicode.org/versions/latest/>, as well as the
2179 Case Charts available at L<http://www.unicode.org/charts/case/>.
2180
2181 If EXPR is omitted, uses C<$_>.
2182
2183 This function behaves the same way under various pragma, such as within
2184 S<C<"use feature 'unicode_strings">>, as L</lc> does, with the single
2185 exception of C<fc> of LATIN CAPITAL LETTER SHARP S (U+1E9E) within the
2186 scope of S<C<use locale>>.  The foldcase of this character would
2187 normally be C<"ss">, but as explained in the L</lc> section, case
2188 changes that cross the 255/256 boundary are problematic under locales,
2189 and are hence prohibited.  Therefore, this function under locale returns
2190 instead the string C<"\x{17F}\x{17F}">, which is the LATIN SMALL LETTER
2191 LONG S.  Since that character itself folds to C<"s">, the string of two
2192 of them together should be equivalent to a single U+1E9E when foldcased.
2193
2194 While the Unicode Standard defines two additional forms of casefolding,
2195 one for Turkic languages and one that never maps one character into multiple
2196 characters, these are not provided by the Perl core; However, the CPAN module
2197 C<Unicode::Casing> may be used to provide an implementation.
2198
2199 This keyword is available only when the C<"fc"> feature is enabled,
2200 or when prefixed with C<CORE::>; See L<feature>.  Alternately,
2201 include a C<use v5.16> or later to the current scope.
2202
2203 =item fcntl FILEHANDLE,FUNCTION,SCALAR
2204 X<fcntl>
2205
2206 =for Pod::Functions file control system call
2207
2208 Implements the fcntl(2) function.  You'll probably have to say
2209
2210     use Fcntl;
2211
2212 first to get the correct constant definitions.  Argument processing and
2213 value returned work just like C<ioctl> below.
2214 For example:
2215
2216     use Fcntl;
2217     fcntl($filehandle, F_GETFL, $packed_return_buffer)
2218         or die "can't fcntl F_GETFL: $!";
2219
2220 You don't have to check for C<defined> on the return from C<fcntl>.
2221 Like C<ioctl>, it maps a C<0> return from the system call into
2222 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
2223 in numeric context.  It is also exempt from the normal B<-w> warnings
2224 on improper numeric conversions.
2225
2226 Note that C<fcntl> raises an exception if used on a machine that
2227 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
2228 manpage to learn what functions are available on your system.
2229
2230 Here's an example of setting a filehandle named C<REMOTE> to be
2231 non-blocking at the system level.  You'll have to negotiate C<$|>
2232 on your own, though.
2233
2234     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
2235
2236     $flags = fcntl(REMOTE, F_GETFL, 0)
2237                 or die "Can't get flags for the socket: $!\n";
2238
2239     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
2240                 or die "Can't set flags for the socket: $!\n";
2241
2242 Portability issues: L<perlport/fcntl>.
2243
2244 =item __FILE__
2245 X<__FILE__>
2246
2247 =for Pod::Functions the name of the current source file
2248
2249 A special token that returns the name of the file in which it occurs.
2250
2251 =item fileno FILEHANDLE
2252 X<fileno>
2253
2254 =for Pod::Functions return file descriptor from filehandle
2255
2256 Returns the file descriptor for a filehandle, or undefined if the
2257 filehandle is not open.  If there is no real file descriptor at the OS
2258 level, as can happen with filehandles connected to memory objects via
2259 C<open> with a reference for the third argument, -1 is returned.
2260
2261 This is mainly useful for constructing
2262 bitmaps for C<select> and low-level POSIX tty-handling operations.
2263 If FILEHANDLE is an expression, the value is taken as an indirect
2264 filehandle, generally its name.
2265
2266 You can use this to find out whether two handles refer to the
2267 same underlying descriptor:
2268
2269     if (fileno(THIS) != -1 && fileno(THIS) == fileno(THAT)) {
2270         print "THIS and THAT are dups\n";
2271     } elsif (fileno(THIS) != -1 && fileno(THAT) != -1) {
2272         print "THIS and THAT have different " .
2273             "underlying file descriptors\n";
2274     } else {
2275         print "At least one of THIS and THAT does " .
2276             "not have a real file descriptor\n";
2277     }
2278
2279 =item flock FILEHANDLE,OPERATION
2280 X<flock> X<lock> X<locking>
2281
2282 =for Pod::Functions lock an entire file with an advisory lock
2283
2284 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
2285 for success, false on failure.  Produces a fatal error if used on a
2286 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
2287 C<flock> is Perl's portable file-locking interface, although it locks
2288 entire files only, not records.
2289
2290 Two potentially non-obvious but traditional C<flock> semantics are
2291 that it waits indefinitely until the lock is granted, and that its locks
2292 are B<merely advisory>.  Such discretionary locks are more flexible, but
2293 offer fewer guarantees.  This means that programs that do not also use
2294 C<flock> may modify files locked with C<flock>.  See L<perlport>, 
2295 your port's specific documentation, and your system-specific local manpages
2296 for details.  It's best to assume traditional behavior if you're writing
2297 portable programs.  (But if you're not, you should as always feel perfectly
2298 free to write for your own system's idiosyncrasies (sometimes called
2299 "features").  Slavish adherence to portability concerns shouldn't get
2300 in the way of your getting your job done.)
2301
2302 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
2303 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
2304 you can use the symbolic names if you import them from the L<Fcntl> module,
2305 either individually, or as a group using the C<:flock> tag.  LOCK_SH
2306 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
2307 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
2308 LOCK_SH or LOCK_EX, then C<flock> returns immediately rather than blocking
2309 waiting for the lock; check the return status to see if you got it.
2310
2311 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
2312 before locking or unlocking it.
2313
2314 Note that the emulation built with lockf(3) doesn't provide shared
2315 locks, and it requires that FILEHANDLE be open with write intent.  These
2316 are the semantics that lockf(3) implements.  Most if not all systems
2317 implement lockf(3) in terms of fcntl(2) locking, though, so the
2318 differing semantics shouldn't bite too many people.
2319
2320 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
2321 be open with read intent to use LOCK_SH and requires that it be open
2322 with write intent to use LOCK_EX.
2323
2324 Note also that some versions of C<flock> cannot lock things over the
2325 network; you would need to use the more system-specific C<fcntl> for
2326 that.  If you like you can force Perl to ignore your system's flock(2)
2327 function, and so provide its own fcntl(2)-based emulation, by passing
2328 the switch C<-Ud_flock> to the F<Configure> program when you configure
2329 and build a new Perl.
2330
2331 Here's a mailbox appender for BSD systems.
2332
2333     # import LOCK_* and SEEK_END constants
2334     use Fcntl qw(:flock SEEK_END);
2335
2336     sub lock {
2337         my ($fh) = @_;
2338         flock($fh, LOCK_EX) or die "Cannot lock mailbox - $!\n";
2339
2340         # and, in case someone appended while we were waiting...
2341         seek($fh, 0, SEEK_END) or die "Cannot seek - $!\n";
2342     }
2343
2344     sub unlock {
2345         my ($fh) = @_;
2346         flock($fh, LOCK_UN) or die "Cannot unlock mailbox - $!\n";
2347     }
2348
2349     open(my $mbox, ">>", "/usr/spool/mail/$ENV{'USER'}")
2350         or die "Can't open mailbox: $!";
2351
2352     lock($mbox);
2353     print $mbox $msg,"\n\n";
2354     unlock($mbox);
2355
2356 On systems that support a real flock(2), locks are inherited across fork()
2357 calls, whereas those that must resort to the more capricious fcntl(2)
2358 function lose their locks, making it seriously harder to write servers.
2359
2360 See also L<DB_File> for other flock() examples.
2361
2362 Portability issues: L<perlport/flock>.
2363
2364 =item fork
2365 X<fork> X<child> X<parent>
2366
2367 =for Pod::Functions create a new process just like this one
2368
2369 Does a fork(2) system call to create a new process running the
2370 same program at the same point.  It returns the child pid to the
2371 parent process, C<0> to the child process, or C<undef> if the fork is
2372 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
2373 are shared, while everything else is copied.  On most systems supporting
2374 fork(), great care has gone into making it extremely efficient (for
2375 example, using copy-on-write technology on data pages), making it the
2376 dominant paradigm for multitasking over the last few decades.
2377
2378 Perl attempts to flush all files opened for
2379 output before forking the child process, but this may not be supported
2380 on some platforms (see L<perlport>).  To be safe, you may need to set
2381 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
2382 C<IO::Handle> on any open handles to avoid duplicate output.
2383
2384 If you C<fork> without ever waiting on your children, you will
2385 accumulate zombies.  On some systems, you can avoid this by setting
2386 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
2387 forking and reaping moribund children.
2388
2389 Note that if your forked child inherits system file descriptors like
2390 STDIN and STDOUT that are actually connected by a pipe or socket, even
2391 if you exit, then the remote server (such as, say, a CGI script or a
2392 backgrounded job launched from a remote shell) won't think you're done.
2393 You should reopen those to F</dev/null> if it's any issue.
2394
2395 On some platforms such as Windows, where the fork() system call is not available,
2396 Perl can be built to emulate fork() in the Perl interpreter.
2397 The emulation is designed, at the level of the Perl program,
2398 to be as compatible as possible with the "Unix" fork().
2399 However it has limitations that have to be considered in code intended to be portable.
2400 See L<perlfork> for more details.
2401
2402 Portability issues: L<perlport/fork>.
2403
2404 =item format
2405 X<format>
2406
2407 =for Pod::Functions declare a picture format with use by the write() function
2408
2409 Declare a picture format for use by the C<write> function.  For
2410 example:
2411
2412     format Something =
2413         Test: @<<<<<<<< @||||| @>>>>>
2414               $str,     $%,    '$' . int($num)
2415     .
2416
2417     $str = "widget";
2418     $num = $cost/$quantity;
2419     $~ = 'Something';
2420     write;
2421
2422 See L<perlform> for many details and examples.
2423
2424 =item formline PICTURE,LIST
2425 X<formline>
2426
2427 =for Pod::Functions internal function used for formats
2428
2429 This is an internal function used by C<format>s, though you may call it,
2430 too.  It formats (see L<perlform>) a list of values according to the
2431 contents of PICTURE, placing the output into the format output
2432 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
2433 Eventually, when a C<write> is done, the contents of
2434 C<$^A> are written to some filehandle.  You could also read C<$^A>
2435 and then set C<$^A> back to C<"">.  Note that a format typically
2436 does one C<formline> per line of form, but the C<formline> function itself
2437 doesn't care how many newlines are embedded in the PICTURE.  This means
2438 that the C<~> and C<~~> tokens treat the entire PICTURE as a single line.
2439 You may therefore need to use multiple formlines to implement a single
2440 record format, just like the C<format> compiler.
2441
2442 Be careful if you put double quotes around the picture, because an C<@>
2443 character may be taken to mean the beginning of an array name.
2444 C<formline> always returns true.  See L<perlform> for other examples.
2445
2446 If you are trying to use this instead of C<write> to capture the output,
2447 you may find it easier to open a filehandle to a scalar
2448 (C<< open $fh, ">", \$output >>) and write to that instead.
2449
2450 =item getc FILEHANDLE
2451 X<getc> X<getchar> X<character> X<file, read>
2452
2453 =item getc
2454
2455 =for Pod::Functions get the next character from the filehandle
2456
2457 Returns the next character from the input file attached to FILEHANDLE,
2458 or the undefined value at end of file or if there was an error (in
2459 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
2460 STDIN.  This is not particularly efficient.  However, it cannot be
2461 used by itself to fetch single characters without waiting for the user
2462 to hit enter.  For that, try something more like:
2463
2464     if ($BSD_STYLE) {
2465         system "stty cbreak </dev/tty >/dev/tty 2>&1";
2466     }
2467     else {
2468         system "stty", '-icanon', 'eol', "\001";
2469     }
2470
2471     $key = getc(STDIN);
2472
2473     if ($BSD_STYLE) {
2474         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
2475     }
2476     else {
2477         system 'stty', 'icanon', 'eol', '^@'; # ASCII NUL
2478     }
2479     print "\n";
2480
2481 Determination of whether $BSD_STYLE should be set
2482 is left as an exercise to the reader.
2483
2484 The C<POSIX::getattr> function can do this more portably on
2485 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
2486 module from your nearest L<CPAN|http://www.cpan.org> site.
2487
2488 =item getlogin
2489 X<getlogin> X<login>
2490
2491 =for Pod::Functions return who logged in at this tty
2492
2493 This implements the C library function of the same name, which on most
2494 systems returns the current login from F</etc/utmp>, if any.  If it
2495 returns the empty string, use C<getpwuid>.
2496
2497     $login = getlogin || getpwuid($<) || "Kilroy";
2498
2499 Do not consider C<getlogin> for authentication: it is not as
2500 secure as C<getpwuid>.
2501
2502 Portability issues: L<perlport/getlogin>.
2503
2504 =item getpeername SOCKET
2505 X<getpeername> X<peer>
2506
2507 =for Pod::Functions find the other end of a socket connection
2508
2509 Returns the packed sockaddr address of the other end of the SOCKET
2510 connection.
2511
2512     use Socket;
2513     $hersockaddr    = getpeername(SOCK);
2514     ($port, $iaddr) = sockaddr_in($hersockaddr);
2515     $herhostname    = gethostbyaddr($iaddr, AF_INET);
2516     $herstraddr     = inet_ntoa($iaddr);
2517
2518 =item getpgrp PID
2519 X<getpgrp> X<group>
2520
2521 =for Pod::Functions get process group
2522
2523 Returns the current process group for the specified PID.  Use
2524 a PID of C<0> to get the current process group for the
2525 current process.  Will raise an exception if used on a machine that
2526 doesn't implement getpgrp(2).  If PID is omitted, returns the process
2527 group of the current process.  Note that the POSIX version of C<getpgrp>
2528 does not accept a PID argument, so only C<PID==0> is truly portable.
2529
2530 Portability issues: L<perlport/getpgrp>.
2531
2532 =item getppid
2533 X<getppid> X<parent> X<pid>
2534
2535 =for Pod::Functions get parent process ID
2536
2537 Returns the process id of the parent process.
2538
2539 Note for Linux users: Between v5.8.1 and v5.16.0 Perl would work
2540 around non-POSIX thread semantics the minority of Linux systems (and
2541 Debian GNU/kFreeBSD systems) that used LinuxThreads, this emulation
2542 has since been removed.  See the documentation for L<$$|perlvar/$$> for
2543 details.
2544
2545 Portability issues: L<perlport/getppid>.
2546
2547 =item getpriority WHICH,WHO
2548 X<getpriority> X<priority> X<nice>
2549
2550 =for Pod::Functions get current nice value
2551
2552 Returns the current priority for a process, a process group, or a user.
2553 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
2554 machine that doesn't implement getpriority(2).
2555
2556 Portability issues: L<perlport/getpriority>.
2557
2558 =item getpwnam NAME
2559 X<getpwnam> X<getgrnam> X<gethostbyname> X<getnetbyname> X<getprotobyname>
2560 X<getpwuid> X<getgrgid> X<getservbyname> X<gethostbyaddr> X<getnetbyaddr>
2561 X<getprotobynumber> X<getservbyport> X<getpwent> X<getgrent> X<gethostent>
2562 X<getnetent> X<getprotoent> X<getservent> X<setpwent> X<setgrent> X<sethostent>
2563 X<setnetent> X<setprotoent> X<setservent> X<endpwent> X<endgrent> X<endhostent>
2564 X<endnetent> X<endprotoent> X<endservent> 
2565
2566 =for Pod::Functions get passwd record given user login name
2567
2568 =item getgrnam NAME
2569
2570 =for Pod::Functions get group record given group name
2571
2572 =item gethostbyname NAME
2573
2574 =for Pod::Functions get host record given name
2575
2576 =item getnetbyname NAME
2577
2578 =for Pod::Functions get networks record given name
2579
2580 =item getprotobyname NAME
2581
2582 =for Pod::Functions get protocol record given name
2583
2584 =item getpwuid UID
2585
2586 =for Pod::Functions get passwd record given user ID
2587
2588 =item getgrgid GID
2589
2590 =for Pod::Functions get group record given group user ID
2591
2592 =item getservbyname NAME,PROTO
2593
2594 =for Pod::Functions get services record given its name
2595
2596 =item gethostbyaddr ADDR,ADDRTYPE
2597
2598 =for Pod::Functions get host record given its address
2599
2600 =item getnetbyaddr ADDR,ADDRTYPE
2601
2602 =for Pod::Functions get network record given its address
2603
2604 =item getprotobynumber NUMBER
2605
2606 =for Pod::Functions get protocol record numeric protocol
2607
2608 =item getservbyport PORT,PROTO
2609
2610 =for Pod::Functions get services record given numeric port
2611
2612 =item getpwent
2613
2614 =for Pod::Functions get next passwd record
2615
2616 =item getgrent
2617
2618 =for Pod::Functions get next group record
2619
2620 =item gethostent
2621
2622 =for Pod::Functions get next hosts record
2623
2624 =item getnetent
2625
2626 =for Pod::Functions get next networks record
2627
2628 =item getprotoent
2629
2630 =for Pod::Functions get next protocols record
2631
2632 =item getservent
2633
2634 =for Pod::Functions get next services record
2635
2636 =item setpwent
2637
2638 =for Pod::Functions prepare passwd file for use
2639
2640 =item setgrent
2641
2642 =for Pod::Functions prepare group file for use
2643
2644 =item sethostent STAYOPEN
2645
2646 =for Pod::Functions prepare hosts file for use
2647
2648 =item setnetent STAYOPEN
2649
2650 =for Pod::Functions prepare networks file for use
2651
2652 =item setprotoent STAYOPEN
2653
2654 =for Pod::Functions prepare protocols file for use
2655
2656 =item setservent STAYOPEN
2657
2658 =for Pod::Functions prepare services file for use
2659
2660 =item endpwent
2661
2662 =for Pod::Functions be done using passwd file
2663
2664 =item endgrent
2665
2666 =for Pod::Functions be done using group file
2667
2668 =item endhostent
2669
2670 =for Pod::Functions be done using hosts file
2671
2672 =item endnetent
2673
2674 =for Pod::Functions be done using networks file
2675
2676 =item endprotoent
2677
2678 =for Pod::Functions be done using protocols file
2679
2680 =item endservent
2681
2682 =for Pod::Functions be done using services file
2683
2684 These routines are the same as their counterparts in the
2685 system C library.  In list context, the return values from the
2686 various get routines are as follows:
2687
2688  # 0        1          2           3         4
2689  ( $name,   $passwd,   $gid,       $members  ) = getgr*
2690  ( $name,   $aliases,  $addrtype,  $net      ) = getnet*
2691  ( $name,   $aliases,  $port,      $proto    ) = getserv*
2692  ( $name,   $aliases,  $proto                ) = getproto*
2693  ( $name,   $aliases,  $addrtype,  $length,  @addrs ) = gethost*
2694  ( $name,   $passwd,   $uid,       $gid,     $quota,
2695  $comment,  $gcos,     $dir,       $shell,   $expire ) = getpw*
2696  # 5        6          7           8         9
2697
2698 (If the entry doesn't exist you get an empty list.)
2699
2700 The exact meaning of the $gcos field varies but it usually contains
2701 the real name of the user (as opposed to the login name) and other
2702 information pertaining to the user.  Beware, however, that in many
2703 system users are able to change this information and therefore it
2704 cannot be trusted and therefore the $gcos is tainted (see
2705 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2706 login shell, are also tainted, for the same reason.
2707
2708 In scalar context, you get the name, unless the function was a
2709 lookup by name, in which case you get the other thing, whatever it is.
2710 (If the entry doesn't exist you get the undefined value.)  For example:
2711
2712     $uid   = getpwnam($name);
2713     $name  = getpwuid($num);
2714     $name  = getpwent();
2715     $gid   = getgrnam($name);
2716     $name  = getgrgid($num);
2717     $name  = getgrent();
2718     #etc.
2719
2720 In I<getpw*()> the fields $quota, $comment, and $expire are special
2721 in that they are unsupported on many systems.  If the
2722 $quota is unsupported, it is an empty scalar.  If it is supported, it
2723 usually encodes the disk quota.  If the $comment field is unsupported,
2724 it is an empty scalar.  If it is supported it usually encodes some
2725 administrative comment about the user.  In some systems the $quota
2726 field may be $change or $age, fields that have to do with password
2727 aging.  In some systems the $comment field may be $class.  The $expire
2728 field, if present, encodes the expiration period of the account or the
2729 password.  For the availability and the exact meaning of these fields
2730 in your system, please consult getpwnam(3) and your system's 
2731 F<pwd.h> file.  You can also find out from within Perl what your
2732 $quota and $comment fields mean and whether you have the $expire field
2733 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2734 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2735 files are supported only if your vendor has implemented them in the
2736 intuitive fashion that calling the regular C library routines gets the
2737 shadow versions if you're running under privilege or if there exists
2738 the shadow(3) functions as found in System V (this includes Solaris
2739 and Linux).  Those systems that implement a proprietary shadow password
2740 facility are unlikely to be supported.
2741
2742 The $members value returned by I<getgr*()> is a space-separated list of
2743 the login names of the members of the group.
2744
2745 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2746 C, it will be returned to you via C<$?> if the function call fails.  The
2747 C<@addrs> value returned by a successful call is a list of raw
2748 addresses returned by the corresponding library call.  In the
2749 Internet domain, each address is four bytes long; you can unpack it
2750 by saying something like:
2751
2752     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2753
2754 The Socket library makes this slightly easier:
2755
2756     use Socket;
2757     $iaddr = inet_aton("127.1"); # or whatever address
2758     $name  = gethostbyaddr($iaddr, AF_INET);
2759
2760     # or going the other way
2761     $straddr = inet_ntoa($iaddr);
2762
2763 In the opposite way, to resolve a hostname to the IP address
2764 you can write this:
2765
2766     use Socket;
2767     $packed_ip = gethostbyname("www.perl.org");
2768     if (defined $packed_ip) {
2769         $ip_address = inet_ntoa($packed_ip);
2770     }
2771
2772 Make sure C<gethostbyname()> is called in SCALAR context and that
2773 its return value is checked for definedness.
2774
2775 The C<getprotobynumber> function, even though it only takes one argument,
2776 has the precedence of a list operator, so beware:
2777
2778     getprotobynumber $number eq 'icmp'   # WRONG
2779     getprotobynumber($number eq 'icmp')  # actually means this
2780     getprotobynumber($number) eq 'icmp'  # better this way
2781
2782 If you get tired of remembering which element of the return list
2783 contains which return value, by-name interfaces are provided
2784 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2785 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2786 and C<User::grent>.  These override the normal built-ins, supplying
2787 versions that return objects with the appropriate names
2788 for each field.  For example:
2789
2790    use File::stat;
2791    use User::pwent;
2792    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2793
2794 Even though it looks as though they're the same method calls (uid),
2795 they aren't, because a C<File::stat> object is different from
2796 a C<User::pwent> object.
2797
2798 Portability issues: L<perlport/getpwnam> to L<perlport/endservent>.
2799
2800 =item getsockname SOCKET
2801 X<getsockname>
2802
2803 =for Pod::Functions retrieve the sockaddr for a given socket
2804
2805 Returns the packed sockaddr address of this end of the SOCKET connection,
2806 in case you don't know the address because you have several different
2807 IPs that the connection might have come in on.
2808
2809     use Socket;
2810     $mysockaddr = getsockname(SOCK);
2811     ($port, $myaddr) = sockaddr_in($mysockaddr);
2812     printf "Connect to %s [%s]\n",
2813        scalar gethostbyaddr($myaddr, AF_INET),
2814        inet_ntoa($myaddr);
2815
2816 =item getsockopt SOCKET,LEVEL,OPTNAME
2817 X<getsockopt>
2818
2819 =for Pod::Functions get socket options on a given socket
2820
2821 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2822 Options may exist at multiple protocol levels depending on the socket
2823 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2824 C<Socket> module) will exist.  To query options at another level the
2825 protocol number of the appropriate protocol controlling the option
2826 should be supplied.  For example, to indicate that an option is to be
2827 interpreted by the TCP protocol, LEVEL should be set to the protocol
2828 number of TCP, which you can get using C<getprotobyname>.
2829
2830 The function returns a packed string representing the requested socket
2831 option, or C<undef> on error, with the reason for the error placed in
2832 C<$!>.  Just what is in the packed string depends on LEVEL and OPTNAME;
2833 consult getsockopt(2) for details.  A common case is that the option is an
2834 integer, in which case the result is a packed integer, which you can decode
2835 using C<unpack> with the C<i> (or C<I>) format.
2836
2837 Here's an example to test whether Nagle's algorithm is enabled on a socket:
2838
2839     use Socket qw(:all);
2840
2841     defined(my $tcp = getprotobyname("tcp"))
2842         or die "Could not determine the protocol number for tcp";
2843     # my $tcp = IPPROTO_TCP; # Alternative
2844     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2845         or die "getsockopt TCP_NODELAY: $!";
2846     my $nodelay = unpack("I", $packed);
2847     print "Nagle's algorithm is turned ",
2848            $nodelay ? "off\n" : "on\n";
2849
2850 Portability issues: L<perlport/getsockopt>.
2851
2852 =item glob EXPR
2853 X<glob> X<wildcard> X<filename, expansion> X<expand>
2854
2855 =item glob
2856
2857 =for Pod::Functions expand filenames using wildcards
2858
2859 In list context, returns a (possibly empty) list of filename expansions on
2860 the value of EXPR such as the standard Unix shell F</bin/csh> would do.  In
2861 scalar context, glob iterates through such filename expansions, returning
2862 undef when the list is exhausted.  This is the internal function
2863 implementing the C<< <*.c> >> operator, but you can use it directly.  If
2864 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2865 more detail in L<perlop/"I/O Operators">.
2866
2867 Note that C<glob> splits its arguments on whitespace and treats
2868 each segment as separate pattern.  As such, C<glob("*.c *.h")> 
2869 matches all files with a F<.c> or F<.h> extension.  The expression
2870 C<glob(".* *")> matches all files in the current working directory.
2871 If you want to glob filenames that might contain whitespace, you'll
2872 have to use extra quotes around the spacey filename to protect it.
2873 For example, to glob filenames that have an C<e> followed by a space
2874 followed by an C<f>, use either of:
2875
2876     @spacies = <"*e f*">;
2877     @spacies = glob '"*e f*"';
2878     @spacies = glob q("*e f*");
2879
2880 If you had to get a variable through, you could do this:
2881
2882     @spacies = glob "'*${var}e f*'";
2883     @spacies = glob qq("*${var}e f*");
2884
2885 If non-empty braces are the only wildcard characters used in the
2886 C<glob>, no filenames are matched, but potentially many strings
2887 are returned.  For example, this produces nine strings, one for
2888 each pairing of fruits and colors:
2889
2890     @many =  glob "{apple,tomato,cherry}={green,yellow,red}";
2891
2892 This operator is implemented using the standard
2893 C<File::Glob> extension.  See L<File::Glob> for details, including
2894 C<bsd_glob> which does not treat whitespace as a pattern separator.
2895
2896 Portability issues: L<perlport/glob>.
2897
2898 =item gmtime EXPR
2899 X<gmtime> X<UTC> X<Greenwich>
2900
2901 =item gmtime
2902
2903 =for Pod::Functions convert UNIX time into record or string using Greenwich time
2904
2905 Works just like L</localtime> but the returned values are
2906 localized for the standard Greenwich time zone.
2907
2908 Note: When called in list context, $isdst, the last value
2909 returned by gmtime, is always C<0>.  There is no
2910 Daylight Saving Time in GMT.
2911
2912 Portability issues: L<perlport/gmtime>.
2913
2914 =item goto LABEL
2915 X<goto> X<jump> X<jmp>
2916
2917 =item goto EXPR
2918
2919 =item goto &NAME
2920
2921 =for Pod::Functions create spaghetti code
2922
2923 The C<goto LABEL> form finds the statement labeled with LABEL and
2924 resumes execution there.  It can't be used to get out of a block or
2925 subroutine given to C<sort>.  It can be used to go almost anywhere
2926 else within the dynamic scope, including out of subroutines, but it's
2927 usually better to use some other construct such as C<last> or C<die>.
2928 The author of Perl has never felt the need to use this form of C<goto>
2929 (in Perl, that is; C is another matter).  (The difference is that C
2930 does not offer named loops combined with loop control.  Perl does, and
2931 this replaces most structured uses of C<goto> in other languages.)
2932
2933 The C<goto EXPR> form expects to evaluate C<EXPR> to a code reference or
2934 a label name.  If it evaluates to a code reference, it will be handled
2935 like C<goto &NAME>, below.  This is especially useful for implementing
2936 tail recursion via C<goto __SUB__>.
2937
2938 If the expression evaluates to a label name, its scope will be resolved
2939 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2940 necessarily recommended if you're optimizing for maintainability:
2941
2942     goto ("FOO", "BAR", "GLARCH")[$i];
2943
2944 As shown in this example, C<goto EXPR> is exempt from the "looks like a
2945 function" rule.  A pair of parentheses following it does not (necessarily)
2946 delimit its argument.  C<goto("NE")."XT"> is equivalent to C<goto NEXT>.
2947 Also, unlike most named operators, this has the same precedence as
2948 assignment.
2949
2950 Use of C<goto LABEL> or C<goto EXPR> to jump into a construct is
2951 deprecated and will issue a warning.  Even then, it may not be used to
2952 go into any construct that requires initialization, such as a
2953 subroutine or a C<foreach> loop.  It also can't be used to go into a
2954 construct that is optimized away.
2955
2956 The C<goto &NAME> form is quite different from the other forms of
2957 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2958 doesn't have the stigma associated with other gotos.  Instead, it
2959 exits the current subroutine (losing any changes set by local()) and
2960 immediately calls in its place the named subroutine using the current
2961 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2962 load another subroutine and then pretend that the other subroutine had
2963 been called in the first place (except that any modifications to C<@_>
2964 in the current subroutine are propagated to the other subroutine.)
2965 After the C<goto>, not even C<caller> will be able to tell that this
2966 routine was called first.
2967
2968 NAME needn't be the name of a subroutine; it can be a scalar variable
2969 containing a code reference or a block that evaluates to a code
2970 reference.
2971
2972 =item grep BLOCK LIST
2973 X<grep>
2974
2975 =item grep EXPR,LIST
2976
2977 =for Pod::Functions locate elements in a list test true against a given criterion
2978
2979 This is similar in spirit to, but not the same as, grep(1) and its
2980 relatives.  In particular, it is not limited to using regular expressions.
2981
2982 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2983 C<$_> to each element) and returns the list value consisting of those
2984 elements for which the expression evaluated to true.  In scalar
2985 context, returns the number of times the expression was true.
2986
2987     @foo = grep(!/^#/, @bar);    # weed out comments
2988
2989 or equivalently,
2990
2991     @foo = grep {!/^#/} @bar;    # weed out comments
2992
2993 Note that C<$_> is an alias to the list value, so it can be used to
2994 modify the elements of the LIST.  While this is useful and supported,
2995 it can cause bizarre results if the elements of LIST are not variables.
2996 Similarly, grep returns aliases into the original list, much as a for
2997 loop's index variable aliases the list elements.  That is, modifying an
2998 element of a list returned by grep (for example, in a C<foreach>, C<map>
2999 or another C<grep>) actually modifies the element in the original list.
3000 This is usually something to be avoided when writing clear code.
3001
3002 If C<$_> is lexical in the scope where the C<grep> appears (because it has
3003 been declared with the deprecated C<my $_> construct)
3004 then, in addition to being locally aliased to
3005 the list elements, C<$_> keeps being lexical inside the block; i.e., it
3006 can't be seen from the outside, avoiding any potential side-effects.
3007
3008 See also L</map> for a list composed of the results of the BLOCK or EXPR.
3009
3010 =item hex EXPR
3011 X<hex> X<hexadecimal>
3012
3013 =item hex
3014
3015 =for Pod::Functions convert a string to a hexadecimal number
3016
3017 Interprets EXPR as a hex string and returns the corresponding value.
3018 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
3019 L</oct>.)  If EXPR is omitted, uses C<$_>.
3020
3021     print hex '0xAf'; # prints '175'
3022     print hex 'aF';   # same
3023
3024 Hex strings may only represent integers.  Strings that would cause
3025 integer overflow trigger a warning.  Leading whitespace is not stripped,
3026 unlike oct().  To present something as hex, look into L</printf>,
3027 L</sprintf>, and L</unpack>.
3028
3029 =item import LIST
3030 X<import>
3031
3032 =for Pod::Functions patch a module's namespace into your own
3033
3034 There is no builtin C<import> function.  It is just an ordinary
3035 method (subroutine) defined (or inherited) by modules that wish to export
3036 names to another module.  The C<use> function calls the C<import> method
3037 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
3038
3039 =item index STR,SUBSTR,POSITION
3040 X<index> X<indexOf> X<InStr>
3041
3042 =item index STR,SUBSTR
3043
3044 =for Pod::Functions find a substring within a string
3045
3046 The index function searches for one string within another, but without
3047 the wildcard-like behavior of a full regular-expression pattern match.
3048 It returns the position of the first occurrence of SUBSTR in STR at
3049 or after POSITION.  If POSITION is omitted, starts searching from the
3050 beginning of the string.  POSITION before the beginning of the string
3051 or after its end is treated as if it were the beginning or the end,
3052 respectively.  POSITION and the return value are based at zero.
3053 If the substring is not found, C<index> returns -1.
3054
3055 =item int EXPR
3056 X<int> X<integer> X<truncate> X<trunc> X<floor>
3057
3058 =item int
3059
3060 =for Pod::Functions get the integer portion of a number
3061
3062 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
3063 You should not use this function for rounding: one because it truncates
3064 towards C<0>, and two because machine representations of floating-point
3065 numbers can sometimes produce counterintuitive results.  For example,
3066 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
3067 because it's really more like -268.99999999999994315658 instead.  Usually,
3068 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
3069 functions will serve you better than will int().
3070
3071 =item ioctl FILEHANDLE,FUNCTION,SCALAR
3072 X<ioctl>
3073
3074 =for Pod::Functions system-dependent device control system call
3075
3076 Implements the ioctl(2) function.  You'll probably first have to say
3077
3078     require "sys/ioctl.ph";  # probably in
3079                              # $Config{archlib}/sys/ioctl.ph
3080
3081 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
3082 exist or doesn't have the correct definitions you'll have to roll your
3083 own, based on your C header files such as F<< <sys/ioctl.h> >>.
3084 (There is a Perl script called B<h2ph> that comes with the Perl kit that
3085 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
3086 written depending on the FUNCTION; a C pointer to the string value of SCALAR
3087 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
3088 has no string value but does have a numeric value, that value will be
3089 passed rather than a pointer to the string value.  To guarantee this to be
3090 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
3091 functions may be needed to manipulate the values of structures used by
3092 C<ioctl>.
3093
3094 The return value of C<ioctl> (and C<fcntl>) is as follows:
3095
3096     if OS returns:      then Perl returns:
3097         -1               undefined value
3098          0              string "0 but true"
3099     anything else           that number
3100
3101 Thus Perl returns true on success and false on failure, yet you can
3102 still easily determine the actual value returned by the operating
3103 system:
3104
3105     $retval = ioctl(...) || -1;
3106     printf "System returned %d\n", $retval;
3107
3108 The special string C<"0 but true"> is exempt from B<-w> complaints
3109 about improper numeric conversions.
3110
3111 Portability issues: L<perlport/ioctl>.
3112
3113 =item join EXPR,LIST
3114 X<join>
3115
3116 =for Pod::Functions join a list into a string using a separator
3117
3118 Joins the separate strings of LIST into a single string with fields
3119 separated by the value of EXPR, and returns that new string.  Example:
3120
3121     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
3122
3123 Beware that unlike C<split>, C<join> doesn't take a pattern as its
3124 first argument.  Compare L</split>.
3125
3126 =item keys HASH
3127 X<keys> X<key>
3128
3129 =item keys ARRAY
3130
3131 =item keys EXPR
3132
3133 =for Pod::Functions retrieve list of indices from a hash
3134
3135 Called in list context, returns a list consisting of all the keys of the
3136 named hash, or in Perl 5.12 or later only, the indices of an array.  Perl
3137 releases prior to 5.12 will produce a syntax error if you try to use an
3138 array argument.  In scalar context, returns the number of keys or indices.
3139
3140 Hash entries are returned in an apparently random order.  The actual random
3141 order is specific to a given hash; the exact same series of operations
3142 on two hashes may result in a different order for each hash.  Any insertion
3143 into the hash may change the order, as will any deletion, with the exception
3144 that the most recent key returned by C<each> or C<keys> may be deleted
3145 without changing the order.  So long as a given hash is unmodified you may
3146 rely on C<keys>, C<values> and C<each> to repeatedly return the same order
3147 as each other.  See L<perlsec/"Algorithmic Complexity Attacks"> for
3148 details on why hash order is randomized.  Aside from the guarantees
3149 provided here the exact details of Perl's hash algorithm and the hash
3150 traversal order are subject to change in any release of Perl.
3151
3152 As a side effect, calling keys() resets the internal iterator of the HASH or
3153 ARRAY (see L</each>).  In particular, calling keys() in void context resets
3154 the iterator with no other overhead.
3155
3156 Here is yet another way to print your environment:
3157
3158     @keys = keys %ENV;
3159     @values = values %ENV;
3160     while (@keys) {
3161         print pop(@keys), '=', pop(@values), "\n";
3162     }
3163
3164 or how about sorted by key:
3165
3166     foreach $key (sort(keys %ENV)) {
3167         print $key, '=', $ENV{$key}, "\n";
3168     }
3169
3170 The returned values are copies of the original keys in the hash, so
3171 modifying them will not affect the original hash.  Compare L</values>.
3172
3173 To sort a hash by value, you'll need to use a C<sort> function.
3174 Here's a descending numeric sort of a hash by its values:
3175
3176     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
3177         printf "%4d %s\n", $hash{$key}, $key;
3178     }
3179
3180 Used as an lvalue, C<keys> allows you to increase the number of hash buckets
3181 allocated for the given hash.  This can gain you a measure of efficiency if
3182 you know the hash is going to get big.  (This is similar to pre-extending
3183 an array by assigning a larger number to $#array.)  If you say
3184
3185     keys %hash = 200;
3186
3187 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
3188 in fact, since it rounds up to the next power of two.  These
3189 buckets will be retained even if you do C<%hash = ()>, use C<undef
3190 %hash> if you want to free the storage while C<%hash> is still in scope.
3191 You can't shrink the number of buckets allocated for the hash using
3192 C<keys> in this way (but you needn't worry about doing this by accident,
3193 as trying has no effect).  C<keys @array> in an lvalue context is a syntax
3194 error.
3195
3196 Starting with Perl 5.14, C<keys> can take a scalar EXPR, which must contain
3197 a reference to an unblessed hash or array.  The argument will be
3198 dereferenced automatically.  This aspect of C<keys> is considered highly
3199 experimental.  The exact behaviour may change in a future version of Perl.
3200
3201     for (keys $hashref) { ... }
3202     for (keys $obj->get_arrayref) { ... }
3203
3204 To avoid confusing would-be users of your code who are running earlier
3205 versions of Perl with mysterious syntax errors, put this sort of thing at
3206 the top of your file to signal that your code will work I<only> on Perls of
3207 a recent vintage:
3208
3209     use 5.012;  # so keys/values/each work on arrays
3210     use 5.014;  # so keys/values/each work on scalars (experimental)
3211
3212 See also C<each>, C<values>, and C<sort>.
3213
3214 =item kill SIGNAL, LIST
3215
3216 =item kill SIGNAL
3217 X<kill> X<signal>
3218
3219 =for Pod::Functions send a signal to a process or process group
3220
3221 Sends a signal to a list of processes.  Returns the number of arguments
3222 that were successfully used to signal (which is not necessarily the same
3223 as the number of processes actually killed, e.g. where a process group is
3224 killed).
3225
3226     $cnt = kill 'HUP', $child1, $child2;
3227     kill 'KILL', @goners;
3228
3229 SIGNAL may be either a signal name (a string) or a signal number.  A signal
3230 name may start with a C<SIG> prefix, thus C<FOO> and C<SIGFOO> refer to the
3231 same signal.  The string form of SIGNAL is recommended for portability because
3232 the same signal may have different numbers in different operating systems.
3233
3234 A list of signal names supported by the current platform can be found in
3235 C<$Config{sig_name}>, which is provided by the C<Config> module.  See L<Config>
3236 for more details.
3237
3238 A negative signal name is the same as a negative signal number, killing process
3239 groups instead of processes.  For example, C<kill '-KILL', $pgrp> and
3240 C<kill -9, $pgrp> will send C<SIGKILL> to
3241 the entire process group specified.  That
3242 means you usually want to use positive not negative signals.
3243
3244 If SIGNAL is either the number 0 or the string C<ZERO> (or C<SIGZERO>),
3245 no signal is sent to
3246 the process, but C<kill> checks whether it's I<possible> to send a signal to it
3247 (that means, to be brief, that the process is owned by the same user, or we are
3248 the super-user).  This is useful to check that a child process is still
3249 alive (even if only as a zombie) and hasn't changed its UID.  See
3250 L<perlport> for notes on the portability of this construct.
3251
3252 The behavior of kill when a I<PROCESS> number is zero or negative depends on
3253 the operating system.  For example, on POSIX-conforming systems, zero will
3254 signal the current process group, -1 will signal all processes, and any
3255 other negative PROCESS number will act as a negative signal number and
3256 kill the entire process group specified.
3257
3258 If both the SIGNAL and the PROCESS are negative, the results are undefined.
3259 A warning may be produced in a future version.
3260
3261 See L<perlipc/"Signals"> for more details.
3262
3263 On some platforms such as Windows where the fork() system call is not
3264 available, Perl can be built to emulate fork() at the interpreter level.
3265 This emulation has limitations related to kill that have to be considered,
3266 for code running on Windows and in code intended to be portable.
3267
3268 See L<perlfork> for more details.
3269
3270 If there is no I<LIST> of processes, no signal is sent, and the return
3271 value is 0.  This form is sometimes used, however, because it causes
3272 tainting checks to be run.  But see
3273 L<perlsec/Laundering and Detecting Tainted Data>.
3274
3275 Portability issues: L<perlport/kill>.
3276
3277 =item last LABEL
3278 X<last> X<break>
3279
3280 =item last EXPR
3281
3282 =item last
3283
3284 =for Pod::Functions exit a block prematurely
3285
3286 The C<last> command is like the C<break> statement in C (as used in
3287 loops); it immediately exits the loop in question.  If the LABEL is
3288 omitted, the command refers to the innermost enclosing
3289 loop.  The C<last EXPR> form, available starting in Perl
3290 5.18.0, allows a label name to be computed at run time,
3291 and is otherwise identical to C<last LABEL>.  The
3292 C<continue> block, if any, is not executed:
3293
3294     LINE: while (<STDIN>) {
3295         last LINE if /^$/;  # exit when done with header
3296         #...
3297     }
3298
3299 C<last> cannot be used to exit a block that returns a value such as
3300 C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit
3301 a grep() or map() operation.
3302
3303 Note that a block by itself is semantically identical to a loop
3304 that executes once.  Thus C<last> can be used to effect an early
3305 exit out of such a block.
3306
3307 See also L</continue> for an illustration of how C<last>, C<next>, and
3308 C<redo> work.
3309
3310 Unlike most named operators, this has the same precedence as assignment.
3311 It is also exempt from the looks-like-a-function rule, so
3312 C<last ("foo")."bar"> will cause "bar" to be part of the argument to
3313 C<last>.
3314
3315 =item lc EXPR
3316 X<lc> X<lowercase>
3317
3318 =item lc
3319
3320 =for Pod::Functions return lower-case version of a string
3321
3322 Returns a lowercased version of EXPR.  This is the internal function
3323 implementing the C<\L> escape in double-quoted strings.
3324
3325 If EXPR is omitted, uses C<$_>.
3326
3327 What gets returned depends on several factors:
3328
3329 =over
3330
3331 =item If C<use bytes> is in effect:
3332
3333 The results follow ASCII rules.  Only the characters C<A-Z> change,
3334 to C<a-z> respectively.
3335
3336 =item Otherwise, if C<use locale> (but not C<use locale ':not_characters'>) is in effect:
3337
3338 Respects current LC_CTYPE locale for code points < 256; and uses Unicode
3339 rules for the remaining code points (this last can only happen if
3340 the UTF8 flag is also set).  See L<perllocale>.
3341
3342 Starting in v5.20, Perl wil use full Unicode rules if the locale is
3343 UTF-8.  Otherwise, there is a deficiency in this scheme, which is that
3344 case changes that cross the 255/256
3345 boundary are not well-defined.  For example, the lower case of LATIN CAPITAL
3346 LETTER SHARP S (U+1E9E) in Unicode rules is U+00DF (on ASCII
3347 platforms).   But under C<use locale> (prior to v5.20 or not a UTF-8
3348 locale), the lower case of U+1E9E is
3349 itself, because 0xDF may not be LATIN SMALL LETTER SHARP S in the
3350 current locale, and Perl has no way of knowing if that character even
3351 exists in the locale, much less what code point it is.  Perl returns
3352 the input character unchanged, for all instances (and there aren't
3353 many) where the 255/256 boundary would otherwise be crossed.
3354
3355 =item Otherwise, If EXPR has the UTF8 flag set:
3356
3357 Unicode rules are used for the case change.
3358
3359 =item Otherwise, if C<use feature 'unicode_strings'> or C<use locale ':not_characters'> is in effect:
3360
3361 Unicode rules are used for the case change.
3362
3363 =item Otherwise:
3364
3365 ASCII rules are used for the case change.  The lowercase of any character
3366 outside the ASCII range is the character itself.
3367
3368 =back
3369
3370 =item lcfirst EXPR
3371 X<lcfirst> X<lowercase>
3372
3373 =item lcfirst
3374
3375 =for Pod::Functions return a string with just the next letter in lower case
3376
3377 Returns the value of EXPR with the first character lowercased.  This
3378 is the internal function implementing the C<\l> escape in
3379 double-quoted strings.
3380
3381 If EXPR is omitted, uses C<$_>.
3382
3383 This function behaves the same way under various pragmata, such as in a locale,
3384 as L</lc> does.
3385
3386 =item length EXPR
3387 X<length> X<size>
3388
3389 =item length
3390
3391 =for Pod::Functions return the number of characters in a string
3392
3393 Returns the length in I<characters> of the value of EXPR.  If EXPR is
3394 omitted, returns the length of C<$_>.  If EXPR is undefined, returns
3395 C<undef>.
3396
3397 This function cannot be used on an entire array or hash to find out how
3398 many elements these have.  For that, use C<scalar @array> and C<scalar keys
3399 %hash>, respectively.
3400
3401 Like all Perl character operations, length() normally deals in logical
3402 characters, not physical bytes.  For how many bytes a string encoded as
3403 UTF-8 would take up, use C<length(Encode::encode_utf8(EXPR))> (you'll have
3404 to C<use Encode> first).  See L<Encode> and L<perlunicode>.
3405
3406 =item __LINE__
3407 X<__LINE__>
3408
3409 =for Pod::Functions the current source line number
3410
3411 A special token that compiles to the current line number.
3412
3413 =item link OLDFILE,NEWFILE
3414 X<link>
3415
3416 =for Pod::Functions create a hard link in the filesystem
3417
3418 Creates a new filename linked to the old filename.  Returns true for
3419 success, false otherwise.
3420
3421 Portability issues: L<perlport/link>.
3422
3423 =item listen SOCKET,QUEUESIZE
3424 X<listen>
3425
3426 =for Pod::Functions register your socket as a server
3427
3428 Does the same thing that the listen(2) system call does.  Returns true if
3429 it succeeded, false otherwise.  See the example in
3430 L<perlipc/"Sockets: Client/Server Communication">.
3431
3432 =item local EXPR
3433 X<local>
3434
3435 =for Pod::Functions create a temporary value for a global variable (dynamic scoping)
3436
3437 You really probably want to be using C<my> instead, because C<local> isn't
3438 what most people think of as "local".  See
3439 L<perlsub/"Private Variables via my()"> for details.
3440
3441 A local modifies the listed variables to be local to the enclosing
3442 block, file, or eval.  If more than one value is listed, the list must
3443 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
3444 for details, including issues with tied arrays and hashes.
3445
3446 The C<delete local EXPR> construct can also be used to localize the deletion
3447 of array/hash elements to the current block.
3448 See L<perlsub/"Localized deletion of elements of composite types">.
3449
3450 =item localtime EXPR
3451 X<localtime> X<ctime>
3452
3453 =item localtime
3454
3455 =for Pod::Functions convert UNIX time into record or string using local time
3456
3457 Converts a time as returned by the time function to a 9-element list
3458 with the time analyzed for the local time zone.  Typically used as
3459 follows:
3460
3461     #  0    1    2     3     4    5     6     7     8
3462     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
3463                                                 localtime(time);
3464
3465 All list elements are numeric and come straight out of the C `struct
3466 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
3467 of the specified time.
3468
3469 C<$mday> is the day of the month and C<$mon> the month in
3470 the range C<0..11>, with 0 indicating January and 11 indicating December.
3471 This makes it easy to get a month name from a list:
3472
3473     my @abbr = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
3474     print "$abbr[$mon] $mday";
3475     # $mon=9, $mday=18 gives "Oct 18"
3476
3477 C<$year> contains the number of years since 1900.  To get a 4-digit
3478 year write:
3479
3480     $year += 1900;
3481
3482 To get the last two digits of the year (e.g., "01" in 2001) do:
3483
3484     $year = sprintf("%02d", $year % 100);
3485
3486 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
3487 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
3488 (or C<0..365> in leap years.)
3489
3490 C<$isdst> is true if the specified time occurs during Daylight Saving
3491 Time, false otherwise.
3492
3493 If EXPR is omitted, C<localtime()> uses the current time (as returned
3494 by time(3)).
3495
3496 In scalar context, C<localtime()> returns the ctime(3) value:
3497
3498     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
3499
3500 The format of this scalar value is B<not> locale-dependent
3501 but built into Perl.  For GMT instead of local
3502 time use the L</gmtime> builtin.  See also the
3503 C<Time::Local> module (for converting seconds, minutes, hours, and such back to
3504 the integer value returned by time()), and the L<POSIX> module's strftime(3)
3505 and mktime(3) functions.
3506
3507 To get somewhat similar but locale-dependent date strings, set up your
3508 locale environment variables appropriately (please see L<perllocale>) and
3509 try for example:
3510
3511     use POSIX qw(strftime);
3512     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
3513     # or for GMT formatted appropriately for your locale:
3514     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
3515
3516 Note that the C<%a> and C<%b>, the short forms of the day of the week
3517 and the month of the year, may not necessarily be three characters wide.
3518
3519 The L<Time::gmtime> and L<Time::localtime> modules provide a convenient,
3520 by-name access mechanism to the gmtime() and localtime() functions,
3521 respectively.
3522
3523 For a comprehensive date and time representation look at the
3524 L<DateTime> module on CPAN.
3525
3526 Portability issues: L<perlport/localtime>.
3527
3528 =item lock THING
3529 X<lock>
3530
3531 =for Pod::Functions +5.005 get a thread lock on a variable, subroutine, or method
3532
3533 This function places an advisory lock on a shared variable or referenced
3534 object contained in I<THING> until the lock goes out of scope.
3535
3536 The value returned is the scalar itself, if the argument is a scalar, or a
3537 reference, if the argument is a hash, array or subroutine.
3538
3539 lock() is a "weak keyword" : this means that if you've defined a function
3540 by this name (before any calls to it), that function will be called
3541 instead.  If you are not under C<use threads::shared> this does nothing.
3542 See L<threads::shared>.
3543
3544 =item log EXPR
3545 X<log> X<logarithm> X<e> X<ln> X<base>
3546
3547 =item log
3548
3549 =for Pod::Functions retrieve the natural logarithm for a number
3550
3551 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
3552 returns the log of C<$_>.  To get the
3553 log of another base, use basic algebra:
3554 The base-N log of a number is equal to the natural log of that number
3555 divided by the natural log of N.  For example:
3556
3557     sub log10 {
3558         my $n = shift;
3559         return log($n)/log(10);
3560     }
3561
3562 See also L</exp> for the inverse operation.
3563
3564 =item lstat FILEHANDLE
3565 X<lstat>
3566
3567 =item lstat EXPR
3568
3569 =item lstat DIRHANDLE
3570
3571 =item lstat
3572
3573 =for Pod::Functions stat a symbolic link
3574
3575 Does the same thing as the C<stat> function (including setting the
3576 special C<_> filehandle) but stats a symbolic link instead of the file
3577 the symbolic link points to.  If symbolic links are unimplemented on
3578 your system, a normal C<stat> is done.  For much more detailed
3579 information, please see the documentation for C<stat>.
3580
3581 If EXPR is omitted, stats C<$_>.
3582
3583 Portability issues: L<perlport/lstat>.
3584
3585 =item m//
3586
3587 =for Pod::Functions match a string with a regular expression pattern
3588
3589 The match operator.  See L<perlop/"Regexp Quote-Like Operators">.
3590
3591 =item map BLOCK LIST
3592 X<map>
3593
3594 =item map EXPR,LIST
3595
3596 =for Pod::Functions apply a change to a list to get back a new list with the changes
3597
3598 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
3599 C<$_> to each element) and returns the list value composed of the
3600 results of each such evaluation.  In scalar context, returns the
3601 total number of elements so generated.  Evaluates BLOCK or EXPR in
3602 list context, so each element of LIST may produce zero, one, or
3603 more elements in the returned value.
3604
3605     @chars = map(chr, @numbers);
3606
3607 translates a list of numbers to the corresponding characters.
3608
3609     my @squares = map { $_ * $_ } @numbers;
3610
3611 translates a list of numbers to their squared values.
3612
3613     my @squares = map { $_ > 5 ? ($_ * $_) : () } @numbers;
3614
3615 shows that number of returned elements can differ from the number of
3616 input elements.  To omit an element, return an empty list ().
3617 This could also be achieved by writing
3618
3619     my @squares = map { $_ * $_ } grep { $_ > 5 } @numbers;
3620
3621 which makes the intention more clear.
3622
3623 Map always returns a list, which can be
3624 assigned to a hash such that the elements
3625 become key/value pairs.  See L<perldata> for more details.
3626
3627     %hash = map { get_a_key_for($_) => $_ } @array;
3628
3629 is just a funny way to write
3630
3631     %hash = ();
3632     foreach (@array) {
3633         $hash{get_a_key_for($_)} = $_;
3634     }
3635
3636 Note that C<$_> is an alias to the list value, so it can be used to
3637 modify the elements of the LIST.  While this is useful and supported,
3638 it can cause bizarre results if the elements of LIST are not variables.
3639 Using a regular C<foreach> loop for this purpose would be clearer in
3640 most cases.  See also L</grep> for an array composed of those items of
3641 the original list for which the BLOCK or EXPR evaluates to true.
3642
3643 If C<$_> is lexical in the scope where the C<map> appears (because it has
3644 been declared with the deprecated C<my $_> construct),
3645 then, in addition to being locally aliased to
3646 the list elements, C<$_> keeps being lexical inside the block; that is, it
3647 can't be seen from the outside, avoiding any potential side-effects.
3648
3649 C<{> starts both hash references and blocks, so C<map { ...> could be either
3650 the start of map BLOCK LIST or map EXPR, LIST.  Because Perl doesn't look
3651 ahead for the closing C<}> it has to take a guess at which it's dealing with
3652 based on what it finds just after the
3653 C<{>.  Usually it gets it right, but if it
3654 doesn't it won't realize something is wrong until it gets to the C<}> and
3655 encounters the missing (or unexpected) comma.  The syntax error will be
3656 reported close to the C<}>, but you'll need to change something near the C<{>
3657 such as using a unary C<+> to give Perl some help:
3658
3659     %hash = map {  "\L$_" => 1  } @array # perl guesses EXPR. wrong
3660     %hash = map { +"\L$_" => 1  } @array # perl guesses BLOCK. right
3661     %hash = map { ("\L$_" => 1) } @array # this also works
3662     %hash = map {  lc($_) => 1  } @array # as does this.
3663     %hash = map +( lc($_) => 1 ), @array # this is EXPR and works!
3664
3665     %hash = map  ( lc($_), 1 ),   @array # evaluates to (1, @array)
3666
3667 or to force an anon hash constructor use C<+{>:
3668
3669     @hashes = map +{ lc($_) => 1 }, @array # EXPR, so needs
3670                                            # comma at end
3671
3672 to get a list of anonymous hashes each with only one entry apiece.
3673
3674 =item mkdir FILENAME,MASK
3675 X<mkdir> X<md> X<directory, create>
3676
3677 =item mkdir FILENAME
3678
3679 =item mkdir
3680
3681 =for Pod::Functions create a directory
3682
3683 Creates the directory specified by FILENAME, with permissions
3684 specified by MASK (as modified by C<umask>).  If it succeeds it
3685 returns true; otherwise it returns false and sets C<$!> (errno).
3686 MASK defaults to 0777 if omitted, and FILENAME defaults
3687 to C<$_> if omitted.
3688
3689 In general, it is better to create directories with a permissive MASK
3690 and let the user modify that with their C<umask> than it is to supply
3691 a restrictive MASK and give the user no way to be more permissive.
3692 The exceptions to this rule are when the file or directory should be
3693 kept private (mail files, for instance).  The perlfunc(1) entry on
3694 C<umask> discusses the choice of MASK in more detail.
3695
3696 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
3697 number of trailing slashes.  Some operating and filesystems do not get
3698 this right, so Perl automatically removes all trailing slashes to keep
3699 everyone happy.
3700
3701 To recursively create a directory structure, look at
3702 the C<make_path> function of the L<File::Path> module.
3703
3704 =item msgctl ID,CMD,ARG
3705 X<msgctl>
3706
3707 =for Pod::Functions SysV IPC message control operations
3708
3709 Calls the System V IPC function msgctl(2).  You'll probably have to say
3710
3711     use IPC::SysV;
3712
3713 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
3714 then ARG must be a variable that will hold the returned C<msqid_ds>
3715 structure.  Returns like C<ioctl>: the undefined value for error,
3716 C<"0 but true"> for zero, or the actual return value otherwise.  See also
3717 L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and
3718 C<IPC::Semaphore>.
3719
3720 Portability issues: L<perlport/msgctl>.
3721
3722 =item msgget KEY,FLAGS
3723 X<msgget>
3724
3725 =for Pod::Functions get SysV IPC message queue
3726
3727 Calls the System V IPC function msgget(2).  Returns the message queue
3728 id, or C<undef> on error.  See also
3729 L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and
3730 C<IPC::Msg>.
3731
3732 Portability issues: L<perlport/msgget>.
3733
3734 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
3735 X<msgrcv>
3736
3737 =for Pod::Functions receive a SysV IPC message from a message queue
3738
3739 Calls the System V IPC function msgrcv to receive a message from
3740 message queue ID into variable VAR with a maximum message size of
3741 SIZE.  Note that when a message is received, the message type as a
3742 native long integer will be the first thing in VAR, followed by the
3743 actual message.  This packing may be opened with C<unpack("l! a*")>.
3744 Taints the variable.  Returns true if successful, false 
3745 on error.  See also L<perlipc/"SysV IPC"> and the documentation for
3746 C<IPC::SysV> and C<IPC::SysV::Msg>.
3747
3748 Portability issues: L<perlport/msgrcv>.
3749
3750 =item msgsnd ID,MSG,FLAGS
3751 X<msgsnd>
3752
3753 =for Pod::Functions send a SysV IPC message to a message queue
3754
3755 Calls the System V IPC function msgsnd to send the message MSG to the
3756 message queue ID.  MSG must begin with the native long integer message
3757 type, be followed by the length of the actual message, and then finally
3758 the message itself.  This kind of packing can be achieved with
3759 C<pack("l! a*", $type, $message)>.  Returns true if successful,
3760 false on error.  See also the C<IPC::SysV>
3761 and C<IPC::SysV::Msg> documentation.
3762
3763 Portability issues: L<perlport/msgsnd>.
3764
3765 =item my VARLIST
3766 X<my>
3767
3768 =item my TYPE VARLIST
3769
3770 =item my VARLIST : ATTRS
3771
3772 =item my TYPE VARLIST : ATTRS
3773
3774 =for Pod::Functions declare and assign a local variable (lexical scoping)
3775
3776 A C<my> declares the listed variables to be local (lexically) to the
3777 enclosing block, file, or C<eval>.  If more than one variable is listed,
3778 the list must be placed in parentheses.
3779
3780 The exact semantics and interface of TYPE and ATTRS are still
3781 evolving.  TYPE may be a bareword, a constant declared
3782 with C<use constant>, or C<__PACKAGE__>.  It is
3783 currently bound to the use of the C<fields> pragma,
3784 and attributes are handled using the C<attributes> pragma, or starting
3785 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3786 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3787 L<attributes>, and L<Attribute::Handlers>.
3788
3789 Note that with a parenthesised list, C<undef> can be used as a dummy
3790 placeholder, for example to skip assignment of initial values:
3791
3792     my ( undef, $min, $hour ) = localtime;
3793
3794 =item next LABEL
3795 X<next> X<continue>
3796
3797 =item next EXPR
3798
3799 =item next
3800
3801 =for Pod::Functions iterate a block prematurely
3802
3803 The C<next> command is like the C<continue> statement in C; it starts
3804 the next iteration of the loop:
3805
3806     LINE: while (<STDIN>) {
3807         next LINE if /^#/;  # discard comments
3808         #...
3809     }
3810
3811 Note that if there were a C<continue> block on the above, it would get
3812 executed even on discarded lines.  If LABEL is omitted, the command
3813 refers to the innermost enclosing loop.  The C<next EXPR> form, available
3814 as of Perl 5.18.0, allows a label name to be computed at run time, being
3815 otherwise identical to C<next LABEL>.
3816
3817 C<next> cannot be used to exit a block which returns a value such as
3818 C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit
3819 a grep() or map() operation.
3820
3821 Note that a block by itself is semantically identical to a loop
3822 that executes once.  Thus C<next> will exit such a block early.
3823
3824 See also L</continue> for an illustration of how C<last>, C<next>, and
3825 C<redo> work.
3826
3827 Unlike most named operators, this has the same precedence as assignment.
3828 It is also exempt from the looks-like-a-function rule, so
3829 C<next ("foo")."bar"> will cause "bar" to be part of the argument to
3830 C<next>.
3831
3832 =item no MODULE VERSION LIST
3833 X<no declarations>
3834 X<unimporting>
3835
3836 =item no MODULE VERSION
3837
3838 =item no MODULE LIST
3839
3840 =item no MODULE
3841
3842 =item no VERSION
3843
3844 =for Pod::Functions unimport some module symbols or semantics at compile time
3845
3846 See the C<use> function, of which C<no> is the opposite.
3847
3848 =item oct EXPR
3849 X<oct> X<octal> X<hex> X<hexadecimal> X<binary> X<bin>
3850
3851 =item oct
3852
3853 =for Pod::Functions convert a string to an octal number
3854
3855 Interprets EXPR as an octal string and returns the corresponding
3856 value.  (If EXPR happens to start off with C<0x>, interprets it as a
3857 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
3858 binary string.  Leading whitespace is ignored in all three cases.)
3859 The following will handle decimal, binary, octal, and hex in standard
3860 Perl notation:
3861
3862     $val = oct($val) if $val =~ /^0/;
3863
3864 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
3865 in octal), use sprintf() or printf():
3866
3867     $dec_perms = (stat("filename"))[2] & 07777;
3868     $oct_perm_str = sprintf "%o", $perms;
3869
3870 The oct() function is commonly used when a string such as C<644> needs
3871 to be converted into a file mode, for example.  Although Perl 
3872 automatically converts strings into numbers as needed, this automatic
3873 conversion assumes base 10.
3874
3875 Leading white space is ignored without warning, as too are any trailing 
3876 non-digits, such as a decimal point (C<oct> only handles non-negative
3877 integers, not negative integers or floating point).
3878
3879 =item open FILEHANDLE,EXPR
3880 X<open> X<pipe> X<file, open> X<fopen>
3881
3882 =item open FILEHANDLE,MODE,EXPR
3883
3884 =item open FILEHANDLE,MODE,EXPR,LIST
3885
3886 =item open FILEHANDLE,MODE,REFERENCE
3887
3888 =item open FILEHANDLE
3889
3890 =for Pod::Functions open a file, pipe, or descriptor
3891
3892 Opens the file whose filename is given by EXPR, and associates it with
3893 FILEHANDLE.
3894
3895 Simple examples to open a file for reading:
3896
3897     open(my $fh, "<", "input.txt") 
3898         or die "cannot open < input.txt: $!";
3899
3900 and for writing:
3901
3902     open(my $fh, ">", "output.txt") 
3903         or die "cannot open > output.txt: $!";
3904
3905 (The following is a comprehensive reference to open(): for a gentler
3906 introduction you may consider L<perlopentut>.)
3907
3908 If FILEHANDLE is an undefined scalar variable (or array or hash element), a
3909 new filehandle is autovivified, meaning that the variable is assigned a
3910 reference to a newly allocated anonymous filehandle.  Otherwise if
3911 FILEHANDLE is an expression, its value is the real filehandle.  (This is
3912 considered a symbolic reference, so C<use strict "refs"> should I<not> be
3913 in effect.)
3914
3915 If three (or more) arguments are specified, the open mode (including
3916 optional encoding) in the second argument are distinct from the filename in
3917 the third.  If MODE is C<< < >> or nothing, the file is opened for input.
3918 If MODE is C<< > >>, the file is opened for output, with existing files
3919 first being truncated ("clobbered") and nonexisting files newly created.
3920 If MODE is C<<< >> >>>, the file is opened for appending, again being
3921 created if necessary.
3922
3923 You can put a C<+> in front of the C<< > >> or C<< < >> to
3924 indicate that you want both read and write access to the file; thus
3925 C<< +< >> is almost always preferred for read/write updates--the 
3926 C<< +> >> mode would clobber the file first.  You can't usually use
3927 either read-write mode for updating textfiles, since they have
3928 variable-length records.  See the B<-i> switch in L<perlrun> for a
3929 better approach.  The file is created with permissions of C<0666>
3930 modified by the process's C<umask> value.
3931
3932 These various prefixes correspond to the fopen(3) modes of C<r>,
3933 C<r+>, C<w>, C<w+>, C<a>, and C<a+>.
3934
3935 In the one- and two-argument forms of the call, the mode and filename
3936 should be concatenated (in that order), preferably separated by white
3937 space.  You can--but shouldn't--omit the mode in these forms when that mode
3938 is C<< < >>.  It is always safe to use the two-argument form of C<open> if
3939 the filename argument is a known literal.
3940
3941 For three or more arguments if MODE is C<|->, the filename is
3942 interpreted as a command to which output is to be piped, and if MODE
3943 is C<-|>, the filename is interpreted as a command that pipes
3944 output to us.  In the two-argument (and one-argument) form, one should
3945 replace dash (C<->) with the command.
3946 See L<perlipc/"Using open() for IPC"> for more examples of this.
3947 (You are not allowed to C<open> to a command that pipes both in I<and>
3948 out, but see L<IPC::Open2>, L<IPC::Open3>, and
3949 L<perlipc/"Bidirectional Communication with Another Process"> for
3950 alternatives.)
3951
3952 In the form of pipe opens taking three or more arguments, if LIST is specified
3953 (extra arguments after the command name) then LIST becomes arguments
3954 to the command invoked if the platform supports it.  The meaning of
3955 C<open> with more than three arguments for non-pipe modes is not yet
3956 defined, but experimental "layers" may give extra LIST arguments
3957 meaning.
3958
3959 In the two-argument (and one-argument) form, opening C<< <- >> 
3960 or C<-> opens STDIN and opening C<< >- >> opens STDOUT.
3961
3962 You may (and usually should) use the three-argument form of open to specify
3963 I/O layers (sometimes referred to as "disciplines") to apply to the handle
3964 that affect how the input and output are processed (see L<open> and
3965 L<PerlIO> for more details).  For example:
3966
3967   open(my $fh, "<:encoding(UTF-8)", "filename")
3968     || die "can't open UTF-8 encoded filename: $!";
3969
3970 opens the UTF8-encoded file containing Unicode characters;
3971 see L<perluniintro>.  Note that if layers are specified in the
3972 three-argument form, then default layers stored in ${^OPEN} (see L<perlvar>;
3973 usually set by the B<open> pragma or the switch B<-CioD>) are ignored.
3974 Those layers will also be ignored if you specifying a colon with no name
3975 following it.  In that case the default layer for the operating system
3976 (:raw on Unix, :crlf on Windows) is used.
3977
3978 Open returns nonzero on success, the undefined value otherwise.  If
3979 the C<open> involved a pipe, the return value happens to be the pid of
3980 the subprocess.
3981
3982 If you're running Perl on a system that distinguishes between text
3983 files and binary files, then you should check out L</binmode> for tips
3984 for dealing with this.  The key distinction between systems that need
3985 C<binmode> and those that don't is their text file formats.  Systems
3986 like Unix, Mac OS, and Plan 9, that end lines with a single
3987 character and encode that character in C as C<"\n"> do not
3988 need C<binmode>.  The rest need it.
3989
3990 When opening a file, it's seldom a good idea to continue 
3991 if the request failed, so C<open> is frequently used with
3992 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
3993 where you want to format a suitable error message (but there are
3994 modules that can help with that problem)) always check
3995 the return value from opening a file.  
3996
3997 The filehandle will be closed when its reference count reaches zero.
3998 If it is a lexically scoped variable declared with C<my>, that usually
3999 means the end of the enclosing scope.  However, this automatic close
4000 does not check for errors, so it is better to explicitly close
4001 filehandles, especially those used for writing:
4002
4003     close($handle)
4004        || warn "close failed: $!";
4005
4006 An older style is to use a bareword as the filehandle, as
4007
4008     open(FH, "<", "input.txt")
4009        or die "cannot open < input.txt: $!";
4010
4011 Then you can use C<FH> as the filehandle, in C<< close FH >> and C<<
4012 <FH> >> and so on.  Note that it's a global variable, so this form is
4013 not recommended in new code.
4014
4015 As a shortcut a one-argument call takes the filename from the global
4016 scalar variable of the same name as the filehandle:
4017
4018     $ARTICLE = 100;
4019     open(ARTICLE) or die "Can't find article $ARTICLE: $!\n";
4020
4021 Here C<$ARTICLE> must be a global (package) scalar variable - not one
4022 declared with C<my> or C<state>.
4023
4024 As a special case the three-argument form with a read/write mode and the third
4025 argument being C<undef>:
4026
4027     open(my $tmp, "+>", undef) or die ...
4028
4029 opens a filehandle to an anonymous temporary file.  Also using C<< +< >>
4030 works for symmetry, but you really should consider writing something
4031 to the temporary file first.  You will need to seek() to do the
4032 reading.
4033
4034 Perl is built using PerlIO by default; Unless you've
4035 changed this (such as building Perl with C<Configure -Uuseperlio>), you can
4036 open filehandles directly to Perl scalars via:
4037
4038     open($fh, ">", \$variable) || ..
4039
4040 To (re)open C<STDOUT> or C<STDERR> as an in-memory file, close it first:
4041
4042     close STDOUT;
4043     open(STDOUT, ">", \$variable)
4044         or die "Can't open STDOUT: $!";
4045
4046 General examples:
4047
4048     open(LOG, ">>/usr/spool/news/twitlog");  # (log is reserved)
4049     # if the open fails, output is discarded
4050
4051     open(my $dbase, "+<", "dbase.mine")      # open for update
4052         or die "Can't open 'dbase.mine' for update: $!";
4053
4054     open(my $dbase, "+<dbase.mine")          # ditto
4055         or die "Can't open 'dbase.mine' for update: $!";
4056
4057     open(ARTICLE, "-|", "caesar <$article")  # decrypt article
4058         or die "Can't start caesar: $!";
4059
4060     open(ARTICLE, "caesar <$article |")      # ditto
4061         or die "Can't start caesar: $!";
4062
4063     open(EXTRACT, "|sort >Tmp$$")            # $$ is our process id
4064         or die "Can't start sort: $!";
4065
4066     # in-memory files
4067     open(MEMORY, ">", \$var)
4068         or die "Can't open memory file: $!";
4069     print MEMORY "foo!\n";              # output will appear in $var
4070
4071     # process argument list of files along with any includes
4072
4073     foreach $file (@ARGV) {
4074         process($file, "fh00");
4075     }
4076
4077     sub process {
4078         my($filename, $input) = @_;
4079         $input++;    # this is a string increment
4080         unless (open($input, "<", $filename)) {
4081             print STDERR "Can't open $filename: $!\n";
4082             return;
4083         }
4084
4085         local $_;
4086         while (<$input>) {    # note use of indirection
4087             if (/^#include "(.*)"/) {
4088                 process($1, $input);
4089                 next;
4090             }
4091             #...          # whatever
4092         }
4093     }
4094
4095 See L<perliol> for detailed info on PerlIO.
4096
4097 You may also, in the Bourne shell tradition, specify an EXPR beginning
4098 with C<< >& >>, in which case the rest of the string is interpreted
4099 as the name of a filehandle (or file descriptor, if numeric) to be
4100 duped (as C<dup(2)>) and opened.  You may use C<&> after C<< > >>,
4101 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
4102 The mode you specify should match the mode of the original filehandle.
4103 (Duping a filehandle does not take into account any existing contents
4104 of IO buffers.)  If you use the three-argument
4105 form, then you can pass either a
4106 number, the name of a filehandle, or the normal "reference to a glob".
4107
4108 Here is a script that saves, redirects, and restores C<STDOUT> and
4109 C<STDERR> using various methods:
4110
4111     #!/usr/bin/perl
4112     open(my $oldout, ">&STDOUT")     or die "Can't dup STDOUT: $!";
4113     open(OLDERR,     ">&", \*STDERR) or die "Can't dup STDERR: $!";
4114
4115     open(STDOUT, '>', "foo.out") or die "Can't redirect STDOUT: $!";
4116     open(STDERR, ">&STDOUT")     or die "Can't dup STDOUT: $!";
4117
4118     select STDERR; $| = 1;  # make unbuffered
4119     select STDOUT; $| = 1;  # make unbuffered
4120
4121     print STDOUT "stdout 1\n";  # this works for
4122     print STDERR "stderr 1\n";  # subprocesses too
4123
4124     open(STDOUT, ">&", $oldout) or die "Can't dup \$oldout: $!";
4125     open(STDERR, ">&OLDERR")    or die "Can't dup OLDERR: $!";
4126
4127     print STDOUT "stdout 2\n";
4128     print STDERR "stderr 2\n";
4129
4130 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
4131 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
4132 that file descriptor (and not call C<dup(2)>); this is more
4133 parsimonious of file descriptors.  For example:
4134
4135     # open for input, reusing the fileno of $fd
4136     open(FILEHANDLE, "<&=$fd")
4137
4138 or
4139
4140     open(FILEHANDLE, "<&=", $fd)
4141
4142 or
4143
4144     # open for append, using the fileno of OLDFH
4145     open(FH, ">>&=", OLDFH)
4146
4147 or
4148
4149     open(FH, ">>&=OLDFH")
4150
4151 Being parsimonious on filehandles is also useful (besides being
4152 parsimonious) for example when something is dependent on file
4153 descriptors, like for example locking using flock().  If you do just
4154 C<< open(A, ">>&B") >>, the filehandle A will not have the same file
4155 descriptor as B, and therefore flock(A) will not flock(B) nor vice
4156 versa.  But with C<< open(A, ">>&=B") >>, the filehandles will share
4157 the same underlying system file descriptor.
4158
4159 Note that under Perls older than 5.8.0, Perl uses the standard C library's'
4160 fdopen() to implement the C<=> functionality.  On many Unix systems,
4161 fdopen() fails when file descriptors exceed a certain value, typically 255.
4162 For Perls 5.8.0 and later, PerlIO is (most often) the default.
4163
4164 You can see whether your Perl was built with PerlIO by running C<perl -V>
4165 and looking for the C<useperlio=> line.  If C<useperlio> is C<define>, you
4166 have PerlIO; otherwise you don't.
4167
4168 If you open a pipe on the command C<-> (that is, specify either C<|-> or C<-|>
4169 with the one- or two-argument forms of C<open>), 
4170 an implicit C<fork> is done, so C<open> returns twice: in the parent
4171 process it returns the pid
4172 of the child process, and in the child process it returns (a defined) C<0>.
4173 Use C<defined($pid)> or C<//> to determine whether the open was successful.
4174
4175 For example, use either
4176
4177     $child_pid = open(FROM_KID, "-|")   // die "can't fork: $!";
4178
4179 or
4180
4181     $child_pid = open(TO_KID,   "|-")   // die "can't fork: $!";
4182
4183 followed by 
4184
4185     if ($child_pid) {
4186         # am the parent:
4187         # either write TO_KID or else read FROM_KID
4188         ...
4189        waitpid $child_pid, 0;
4190     } else {
4191         # am the child; use STDIN/STDOUT normally
4192         ...
4193         exit;
4194     } 
4195
4196 The filehandle behaves normally for the parent, but I/O to that
4197 filehandle is piped from/to the STDOUT/STDIN of the child process.
4198 In the child process, the filehandle isn't opened--I/O happens from/to
4199 the new STDOUT/STDIN.  Typically this is used like the normal
4200 piped open when you want to exercise more control over just how the
4201 pipe command gets executed, such as when running setuid and
4202 you don't want to have to scan shell commands for metacharacters.
4203
4204 The following blocks are more or less equivalent:
4205
4206     open(FOO, "|tr '[a-z]' '[A-Z]'");
4207     open(FOO, "|-", "tr '[a-z]' '[A-Z]'");
4208     open(FOO, "|-") || exec 'tr', '[a-z]', '[A-Z]';
4209     open(FOO, "|-", "tr", '[a-z]', '[A-Z]');
4210
4211     open(FOO, "cat -n '$file'|");
4212     open(FOO, "-|", "cat -n '$file'");
4213     open(FOO, "-|") || exec "cat", "-n", $file;
4214     open(FOO, "-|", "cat", "-n", $file);
4215
4216 The last two examples in each block show the pipe as "list form", which is
4217 not yet supported on all platforms.  A good rule of thumb is that if
4218 your platform has a real C<fork()> (in other words, if your platform is
4219 Unix, including Linux and MacOS X), you can use the list form.  You would 
4220 want to use the list form of the pipe so you can pass literal arguments
4221 to the command without risk of the shell interpreting any shell metacharacters
4222 in them.  However, this also bars you from opening pipes to commands
4223 that intentionally contain shell metacharacters, such as:
4224
4225     open(FOO, "|cat -n | expand -4 | lpr")
4226         // die "Can't open pipeline to lpr: $!";
4227
4228 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
4229
4230 Perl will attempt to flush all files opened for
4231 output before any operation that may do a fork, but this may not be
4232 supported on some platforms (see L<perlport>).  To be safe, you may need
4233 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
4234 of C<IO::Handle> on any open handles.
4235
4236 On systems that support a close-on-exec flag on files, the flag will
4237 be set for the newly opened file descriptor as determined by the value
4238 of C<$^F>.  See L<perlvar/$^F>.
4239
4240 Closing any piped filehandle causes the parent process to wait for the
4241 child to finish, then returns the status value in C<$?> and
4242 C<${^CHILD_ERROR_NATIVE}>.
4243
4244 The filename passed to the one- and two-argument forms of open() will
4245 have leading and trailing whitespace deleted and normal
4246 redirection characters honored.  This property, known as "magic open",
4247 can often be used to good effect.  A user could specify a filename of
4248 F<"rsh cat file |">, or you could change certain filenames as needed:
4249
4250     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
4251     open(FH, $filename) or die "Can't open $filename: $!";
4252
4253 Use the three-argument form to open a file with arbitrary weird characters in it,
4254
4255     open(FOO, "<", $file)
4256         || die "can't open < $file: $!";
4257
4258 otherwise it's necessary to protect any leading and trailing whitespace:
4259
4260     $file =~ s#^(\s)#./$1#;
4261     open(FOO, "< $file\0")
4262         || die "open failed: $!";
4263
4264 (this may not work on some bizarre filesystems).  One should
4265 conscientiously choose between the I<magic> and I<three-argument> form
4266 of open():
4267
4268     open(IN, $ARGV[0]) || die "can't open $ARGV[0]: $!";
4269
4270 will allow the user to specify an argument of the form C<"rsh cat file |">,
4271 but will not work on a filename that happens to have a trailing space, while
4272
4273     open(IN, "<", $ARGV[0])
4274         || die "can't open < $ARGV[0]: $!";
4275
4276 will have exactly the opposite restrictions.
4277
4278 If you want a "real" C C<open> (see L<open(2)> on your system), then you
4279 should use the C<sysopen> function, which involves no such magic (but may
4280 use subtly different filemodes than Perl open(), which is mapped to C
4281 fopen()).  This is another way to protect your filenames from
4282 interpretation.  For example:
4283
4284     use IO::Handle;
4285     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
4286         or die "sysopen $path: $!";
4287     $oldfh = select(HANDLE); $| = 1; select($oldfh);
4288     print HANDLE "stuff $$\n";
4289     seek(HANDLE, 0, 0);
4290     print "File contains: ", <HANDLE>;
4291
4292 See L</seek> for some details about mixing reading and writing.
4293
4294 Portability issues: L<perlport/open>.
4295
4296 =item opendir DIRHANDLE,EXPR
4297 X<opendir>
4298
4299 =for Pod::Functions open a directory
4300
4301 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
4302 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
4303 DIRHANDLE may be an expression whose value can be used as an indirect
4304 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
4305 scalar variable (or array or hash element), the variable is assigned a
4306 reference to a new anonymous dirhandle; that is, it's autovivified.
4307 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
4308
4309 See the example at C<readdir>.
4310
4311 =item ord EXPR
4312 X<ord> X<encoding>
4313
4314 =item ord
4315
4316 =for Pod::Functions find a character's numeric representation
4317
4318 Returns the numeric value of the first character of EXPR.
4319 If EXPR is an empty string, returns 0.  If EXPR is omitted, uses C<$_>.
4320 (Note I<character>, not byte.)
4321
4322 For the reverse, see L</chr>.
4323 See L<perlunicode> for more about Unicode.
4324
4325 =item our VARLIST
4326 X<our> X<global>
4327
4328 =item our TYPE VARLIST
4329
4330 =item our VARLIST : ATTRS
4331
4332 =item our TYPE VARLIST : ATTRS
4333
4334 =for Pod::Functions +5.6.0 declare and assign a package variable (lexical scoping)
4335
4336 C<our> makes a lexical alias to a package variable of the same name in the current
4337 package for use within the current lexical scope.
4338
4339 C<our> has the same scoping rules as C<my> or C<state>, but C<our> only
4340 declares an alias, whereas C<my> or C<state> both declare a variable name and
4341 allocate storage for that name within the current scope.
4342
4343 This means that when C<use strict 'vars'> is in effect, C<our> lets you use
4344 a package variable without qualifying it with the package name, but only within
4345 the lexical scope of the C<our> declaration.  In this way, C<our> differs from
4346 C<use vars>, which allows use of an unqualified name I<only> within the
4347 affected package, but across scopes.
4348
4349 If more than one variable is listed, the list must be placed
4350 in parentheses.
4351
4352     our $foo;
4353     our($bar, $baz);
4354
4355 An C<our> declaration declares an alias for a package variable that will be visible
4356 across its entire lexical scope, even across package boundaries.  The
4357 package in which the variable is entered is determined at the point
4358 of the declaration, not at the point of use.  This means the following
4359 behavior holds:
4360
4361     package Foo;
4362     our $bar;      # declares $Foo::bar for rest of lexical scope
4363     $bar = 20;
4364
4365     package Bar;
4366     print $bar;    # prints 20, as it refers to $Foo::bar
4367
4368 Multiple C<our> declarations with the same name in the same lexical
4369 scope are allowed if they are in different packages.  If they happen
4370 to be in the same package, Perl will emit warnings if you have asked
4371 for them, just like multiple C<my> declarations.  Unlike a second
4372 C<my> declaration, which will bind the name to a fresh variable, a
4373 second C<our> declaration in the same package, in the same scope, is
4374 merely redundant.
4375
4376     use warnings;
4377     package Foo;
4378     our $bar;      # declares $Foo::bar for rest of lexical scope
4379     $bar = 20;
4380
4381     package Bar;
4382     our $bar = 30; # declares $Bar::bar for rest of lexical scope
4383     print $bar;    # prints 30
4384
4385     our $bar;      # emits warning but has no other effect
4386     print $bar;    # still prints 30
4387
4388 An C<our> declaration may also have a list of attributes associated
4389 with it.
4390
4391 The exact semantics and interface of TYPE and ATTRS are still
4392 evolving.  TYPE is currently bound to the use of the C<fields> pragma,
4393 and attributes are handled using the C<attributes> pragma, or, starting
4394 from Perl 5.8.0, also via the C<Attribute::Handlers> module.  See
4395 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
4396 L<attributes>, and L<Attribute::Handlers>.
4397
4398 Note that with a parenthesised list, C<undef> can be used as a dummy
4399 placeholder, for example to skip assignment of initial values:
4400
4401     our ( undef, $min, $hour ) = localtime;
4402
4403 =item pack TEMPLATE,LIST
4404 X<pack>
4405
4406 =for Pod::Functions convert a list into a binary representation
4407
4408 Takes a LIST of values and converts it into a string using the rules
4409 given by the TEMPLATE.  The resulting string is the concatenation of
4410 the converted values.  Typically, each converted value looks
4411 like its machine-level representation.  For example, on 32-bit machines
4412 an integer may be represented by a sequence of 4 bytes, which  will in
4413 Perl be presented as a string that's 4 characters long. 
4414
4415 See L<perlpacktut> for an introduction to this function.
4416
4417 The TEMPLATE is a sequence of characters that give the order and type
4418 of values, as follows:
4419
4420     a  A string with arbitrary binary data, will be null padded.
4421     A  A text (ASCII) string, will be space padded.
4422     Z  A null-terminated (ASCIZ) string, will be null padded.
4423
4424     b  A bit string (ascending bit order inside each byte,
4425        like vec()).
4426     B  A bit string (descending bit order inside each byte).
4427     h  A hex string (low nybble first).
4428     H  A hex string (high nybble first).
4429
4430     c  A signed char (8-bit) value.
4431     C  An unsigned char (octet) value.
4432     W  An unsigned char value (can be greater than 255).
4433
4434     s  A signed short (16-bit) value.
4435     S  An unsigned short value.
4436
4437     l  A signed long (32-bit) value.
4438     L  An unsigned long value.
4439
4440     q  A signed quad (64-bit) value.
4441     Q  An unsigned quad value.
4442          (Quads are available only if your system supports 64-bit
4443           integer values _and_ if Perl has been compiled to support
4444           those.  Raises an exception otherwise.)
4445
4446     i  A signed integer value.
4447     I  A unsigned integer value.
4448          (This 'integer' is _at_least_ 32 bits wide.  Its exact
4449           size depends on what a local C compiler calls 'int'.)
4450
4451     n  An unsigned short (16-bit) in "network" (big-endian) order.
4452     N  An unsigned long (32-bit) in "network" (big-endian) order.
4453     v  An unsigned short (16-bit) in "VAX" (little-endian) order.
4454     V  An unsigned long (32-bit) in "VAX" (little-endian) order.
4455
4456     j  A Perl internal signed integer value (IV).
4457     J  A Perl internal unsigned integer value (UV).
4458
4459     f  A single-precision float in native format.
4460     d  A double-precision float in native format.
4461
4462     F  A Perl internal floating-point value (NV) in native format
4463     D  A float of long-double precision in native format.
4464          (Long doubles are available only if your system supports
4465           long double values _and_ if Perl has been compiled to
4466           support those.  Raises an exception otherwise.)
4467
4468     p  A pointer to a null-terminated string.
4469     P  A pointer to a structure (fixed-length string).
4470
4471     u  A uuencoded string.
4472     U  A Unicode character number.  Encodes to a character in char-
4473        acter mode and UTF-8 (or UTF-EBCDIC in EBCDIC platforms) in
4474        byte mode.
4475
4476     w  A BER compressed integer (not an ASN.1 BER, see perlpacktut
4477        for details).  Its bytes represent an unsigned integer in
4478        base 128, most significant digit first, with as few digits
4479        as possible.  Bit eight (the high bit) is set on each byte
4480        except the last.
4481
4482     x  A null byte (a.k.a ASCII NUL, "\000", chr(0))
4483     X  Back up a byte.
4484     @  Null-fill or truncate to absolute position, counted from the
4485        start of the innermost ()-group.
4486     .  Null-fill or truncate to absolute position specified by
4487        the value.
4488     (  Start of a ()-group.
4489
4490 One or more modifiers below may optionally follow certain letters in the
4491 TEMPLATE (the second column lists letters for which the modifier is valid):
4492
4493     !   sSlLiI     Forces native (short, long, int) sizes instead
4494                    of fixed (16-/32-bit) sizes.
4495
4496     !   xX         Make x and X act as alignment commands.
4497
4498     !   nNvV       Treat integers as signed instead of unsigned.
4499
4500     !   @.         Specify position as byte offset in the internal
4501                    representation of the packed string.  Efficient
4502                    but dangerous.
4503
4504     >   sSiIlLqQ   Force big-endian byte-order on the type.
4505         jJfFdDpP   (The "big end" touches the construct.)
4506
4507     <   sSiIlLqQ   Force little-endian byte-order on the type.
4508         jJfFdDpP   (The "little end" touches the construct.)
4509
4510 The C<< > >> and C<< < >> modifiers can also be used on C<()> groups 
4511 to force a particular byte-order on all components in that group, 
4512 including all its subgroups.
4513
4514 =begin comment
4515
4516 Larry recalls that the hex and bit string formats (H, h, B, b) were added to
4517 pack for processing data from NASA's Magellan probe.  Magellan was in an
4518 elliptical orbit, using the antenna for the radar mapping when close to
4519 Venus and for communicating data back to Earth for the rest of the orbit.
4520 There were two transmission units, but one of these failed, and then the
4521 other developed a fault whereby it would randomly flip the sense of all the
4522 bits. It was easy to automatically detect complete records with the correct
4523 sense, and complete records with all the bits flipped. However, this didn't
4524 recover the records where the sense flipped midway. A colleague of Larry's
4525 was able to pretty much eyeball where the records flipped, so they wrote an
4526 editor named kybble (a pun on the dog food Kibbles 'n Bits) to enable him to
4527 manually correct the records and recover the data. For this purpose pack
4528 gained the hex and bit string format specifiers.
4529
4530 git shows that they were added to perl 3.0 in patch #44 (Jan 1991, commit
4531 27e2fb84680b9cc1), but the patch description makes no mention of their
4532 addition, let alone the story behind them.
4533
4534 =end comment
4535
4536 The following rules apply:
4537
4538 =over 
4539
4540 =item *
4541
4542 Each letter may optionally be followed by a number indicating the repeat
4543 count.  A numeric repeat count may optionally be enclosed in brackets, as
4544 in C<pack("C[80]", @arr)>.  The repeat count gobbles that many values from
4545 the LIST when used with all format types other than C<a>, C<A>, C<Z>, C<b>,
4546 C<B>, C<h>, C<H>, C<@>, C<.>, C<x>, C<X>, and C<P>, where it means
4547 something else, described below.  Supplying a C<*> for the repeat count
4548 instead of a number means to use however many items are left, except for:
4549
4550 =over 
4551
4552 =item * 
4553
4554 C<@>, C<x>, and C<X>, where it is equivalent to C<0>.
4555
4556 =item * 
4557
4558 <.>, where it means relative to the start of the string.
4559
4560 =item * 
4561
4562 C<u>, where it is equivalent to 1 (or 45, which here is equivalent).
4563
4564 =back 
4565
4566 One can replace a numeric repeat count with a template letter enclosed in
4567 brackets to use the packed byte length of the bracketed template for the
4568 repeat count.
4569
4570 For example, the template C<x[L]> skips as many bytes as in a packed long,
4571 and the template C<"$t X[$t] $t"> unpacks twice whatever $t (when
4572 variable-expanded) unpacks.  If the template in brackets contains alignment
4573 commands (such as C<x![d]>), its packed length is calculated as if the
4574 start of the template had the maximal possible alignment.
4575
4576 When used with C<Z>, a C<*> as the repeat count is guaranteed to add a
4577 trailing null byte, so the resulting string is always one byte longer than
4578 the byte length of the item itself.
4579
4580 When used with C<@>, the repeat count represents an offset from the start
4581 of the innermost C<()> group.
4582
4583 When used with C<.>, the repeat count determines the starting position to
4584 calculate the value offset as follows:
4585
4586 =over 
4587
4588 =item *
4589
4590 If the repeat count is C<0>, it's relative to the current position.
4591
4592 =item *
4593
4594 If the repeat count is C<*>, the offset is relative to the start of the
4595 packed string.
4596
4597 =item *
4598
4599 And if it's an integer I<n>, the offset is relative to the start of the
4600 I<n>th innermost C<( )> group, or to the start of the string if I<n> is
4601 bigger then the group level.
4602
4603 =back
4604
4605 The repeat count for C<u> is interpreted as the maximal number of bytes
4606 to encode per line of output, with 0, 1 and 2 replaced by 45.  The repeat 
4607 count should not be more than 65.
4608
4609 =item *
4610
4611 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
4612 string of length count, padding with nulls or spaces as needed.  When
4613 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
4614 after the first null, and C<a> returns data with no stripping at all.
4615
4616 If the value to pack is too long, the result is truncated.  If it's too
4617 long and an explicit count is provided, C<Z> packs only C<$count-1> bytes,
4618 followed by a null byte.  Thus C<Z> always packs a trailing null, except
4619 when the count is 0.
4620
4621 =item *
4622
4623 Likewise, the C<b> and C<B> formats pack a string that's that many bits long.
4624 Each such format generates 1 bit of the result.  These are typically followed
4625 by a repeat count like C<B8> or C<B64>.
4626
4627 Each result bit is based on the least-significant bit of the corresponding
4628 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
4629 and C<"1"> generate bits 0 and 1, as do characters C<"\000"> and C<"\001">.
4630
4631 Starting from the beginning of the input string, each 8-tuple
4632 of characters is converted to 1 character of output.  With format C<b>,
4633 the first character of the 8-tuple determines the least-significant bit of a
4634 character; with format C<B>, it determines the most-significant bit of
4635 a character.
4636
4637 If the length of the input string is not evenly divisible by 8, the
4638 remainder is packed as if the input string were padded by null characters
4639 at the end.  Similarly during unpacking, "extra" bits are ignored.
4640
4641 If the input string is longer than needed, remaining characters are ignored.
4642
4643 A C<*> for the repeat count uses all characters of the input field.  
4644 On unpacking, bits are converted to a string of C<0>s and C<1>s.
4645
4646 =item *
4647
4648 The C<h> and C<H> formats pack a string that many nybbles (4-bit groups,
4649 representable as hexadecimal digits, C<"0".."9"> C<"a".."f">) long.
4650
4651 For each such format, pack() generates 4 bits of result.
4652 With non-alphabetical characters, the result is based on the 4 least-significant
4653 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
4654 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
4655 C<"\000"> and C<"\001">.  For characters C<"a".."f"> and C<"A".."F">, the result
4656 is compatible with the usual hexadecimal digits, so that C<"a"> and
4657 C<"A"> both generate the nybble C<0xA==10>.  Use only these specific hex 
4658 characters with this format.
4659
4660 Starting from the beginning of the template to pack(), each pair
4661 of characters is converted to 1 character of output.  With format C<h>, the
4662 first character of the pair determines the least-significant nybble of the
4663 output character; with format C<H>, it determines the most-significant
4664 nybble.
4665
4666 If the length of the input string is not even, it behaves as if padded by
4667 a null character at the end.  Similarly, "extra" nybbles are ignored during
4668 unpacking.
4669
4670 If the input string is longer than needed, extra characters are ignored.
4671
4672 A C<*> for the repeat count uses all characters of the input field.  For
4673 unpack(), nybbles are converted to a string of hexadecimal digits.