This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
0c8c83cde104b243204c750e04a2c47ef3fa5c19
[perl5.git] / lib / unicore / mktables
1 #!/usr/bin/perl -w
2
3 # !!!!!!!!!!!!!!       IF YOU MODIFY THIS FILE       !!!!!!!!!!!!!!!!!!!!!!!!!
4 # Any files created or read by this program should be listed in 'mktables.lst'
5 # Use -makelist to regenerate it.
6
7 # There was an attempt when this was first rewritten to make it 5.8
8 # compatible, but that has now been abandoned, and newer constructs are used
9 # as convenient.
10
11 # NOTE: this script can run quite slowly in older/slower systems.
12 # It can also consume a lot of memory (128 MB or more), you may need
13 # to raise your process resource limits (e.g. in bash, "ulimit -a"
14 # to inspect, and "ulimit -d ..." or "ulimit -m ..." to set)
15
16 my $start_time;
17 BEGIN { # Get the time the script started running; do it at compilation to
18         # get it as close as possible
19     $start_time= time;
20 }
21
22 require 5.010_001;
23 use strict;
24 use warnings;
25 use Carp;
26 use Config;
27 use File::Find;
28 use File::Path;
29 use File::Spec;
30 use Text::Tabs;
31 use re "/aa";
32 use feature 'state';
33
34 sub DEBUG () { 0 }  # Set to 0 for production; 1 for development
35 my $debugging_build = $Config{"ccflags"} =~ /-DDEBUGGING/;
36
37 sub NON_ASCII_PLATFORM { ord("A") != 65 }
38
39 # When a new version of Unicode is published, unfortunately the algorithms for
40 # dealing with various bounds, like \b{gcb}, \b{lb} may have to be updated
41 # manually.  The changes may or may not be backward compatible with older
42 # releases.  The code is in regen/mk_invlist.pl and regexec.c.  Make the
43 # changes, then come back here and set the variable below to what version the
44 # code is expecting.  If a newer version of Unicode is being compiled than
45 # expected, a warning will be generated.  If an older version is being
46 # compiled, any bounds tests that fail in the generated test file (-maketest
47 # option) will be marked as TODO.
48 my $version_of_mk_invlist_bounds = v10.0.0;
49
50 ##########################################################################
51 #
52 # mktables -- create the runtime Perl Unicode files (lib/unicore/.../*.pl),
53 # from the Unicode database files (lib/unicore/.../*.txt),  It also generates
54 # a pod file and .t files, depending on option parameters.
55 #
56 # The structure of this file is:
57 #   First these introductory comments; then
58 #   code needed for everywhere, such as debugging stuff; then
59 #   code to handle input parameters; then
60 #   data structures likely to be of external interest (some of which depend on
61 #       the input parameters, so follows them; then
62 #   more data structures and subroutine and package (class) definitions; then
63 #   the small actual loop to process the input files and finish up; then
64 #   a __DATA__ section, for the .t tests
65 #
66 # This program works on all releases of Unicode so far.  The outputs have been
67 # scrutinized most intently for release 5.1.  The others have been checked for
68 # somewhat more than just sanity.  It can handle all non-provisional Unicode
69 # character properties in those releases.
70 #
71 # This program is mostly about Unicode character (or code point) properties.
72 # A property describes some attribute or quality of a code point, like if it
73 # is lowercase or not, its name, what version of Unicode it was first defined
74 # in, or what its uppercase equivalent is.  Unicode deals with these disparate
75 # possibilities by making all properties into mappings from each code point
76 # into some corresponding value.  In the case of it being lowercase or not,
77 # the mapping is either to 'Y' or 'N' (or various synonyms thereof).  Each
78 # property maps each Unicode code point to a single value, called a "property
79 # value".  (Some more recently defined properties, map a code point to a set
80 # of values.)
81 #
82 # When using a property in a regular expression, what is desired isn't the
83 # mapping of the code point to its property's value, but the reverse (or the
84 # mathematical "inverse relation"): starting with the property value, "Does a
85 # code point map to it?"  These are written in a "compound" form:
86 # \p{property=value}, e.g., \p{category=punctuation}.  This program generates
87 # files containing the lists of code points that map to each such regular
88 # expression property value, one file per list
89 #
90 # There is also a single form shortcut that Perl adds for many of the commonly
91 # used properties.  This happens for all binary properties, plus script,
92 # general_category, and block properties.
93 #
94 # Thus the outputs of this program are files.  There are map files, mostly in
95 # the 'To' directory; and there are list files for use in regular expression
96 # matching, all in subdirectories of the 'lib' directory, with each
97 # subdirectory being named for the property that the lists in it are for.
98 # Bookkeeping, test, and documentation files are also generated.
99
100 my $matches_directory = 'lib';   # Where match (\p{}) files go.
101 my $map_directory = 'To';        # Where map files go.
102
103 # DATA STRUCTURES
104 #
105 # The major data structures of this program are Property, of course, but also
106 # Table.  There are two kinds of tables, very similar to each other.
107 # "Match_Table" is the data structure giving the list of code points that have
108 # a particular property value, mentioned above.  There is also a "Map_Table"
109 # data structure which gives the property's mapping from code point to value.
110 # There are two structures because the match tables need to be combined in
111 # various ways, such as constructing unions, intersections, complements, etc.,
112 # and the map ones don't.  And there would be problems, perhaps subtle, if
113 # a map table were inadvertently operated on in some of those ways.
114 # The use of separate classes with operations defined on one but not the other
115 # prevents accidentally confusing the two.
116 #
117 # At the heart of each table's data structure is a "Range_List", which is just
118 # an ordered list of "Ranges", plus ancillary information, and methods to
119 # operate on them.  A Range is a compact way to store property information.
120 # Each range has a starting code point, an ending code point, and a value that
121 # is meant to apply to all the code points between the two end points,
122 # inclusive.  For a map table, this value is the property value for those
123 # code points.  Two such ranges could be written like this:
124 #   0x41 .. 0x5A, 'Upper',
125 #   0x61 .. 0x7A, 'Lower'
126 #
127 # Each range also has a type used as a convenience to classify the values.
128 # Most ranges in this program will be Type 0, or normal, but there are some
129 # ranges that have a non-zero type.  These are used only in map tables, and
130 # are for mappings that don't fit into the normal scheme of things.  Mappings
131 # that require a hash entry to communicate with utf8.c are one example;
132 # another example is mappings for charnames.pm to use which indicate a name
133 # that is algorithmically determinable from its code point (and the reverse).
134 # These are used to significantly compact these tables, instead of listing
135 # each one of the tens of thousands individually.
136 #
137 # In a match table, the value of a range is irrelevant (and hence the type as
138 # well, which will always be 0), and arbitrarily set to the null string.
139 # Using the example above, there would be two match tables for those two
140 # entries, one named Upper would contain the 0x41..0x5A range, and the other
141 # named Lower would contain 0x61..0x7A.
142 #
143 # Actually, there are two types of range lists, "Range_Map" is the one
144 # associated with map tables, and "Range_List" with match tables.
145 # Again, this is so that methods can be defined on one and not the others so
146 # as to prevent operating on them in incorrect ways.
147 #
148 # Eventually, most tables are written out to files to be read by utf8_heavy.pl
149 # in the perl core.  All tables could in theory be written, but some are
150 # suppressed because there is no current practical use for them.  It is easy
151 # to change which get written by changing various lists that are near the top
152 # of the actual code in this file.  The table data structures contain enough
153 # ancillary information to allow them to be treated as separate entities for
154 # writing, such as the path to each one's file.  There is a heading in each
155 # map table that gives the format of its entries, and what the map is for all
156 # the code points missing from it.  (This allows tables to be more compact.)
157 #
158 # The Property data structure contains one or more tables.  All properties
159 # contain a map table (except the $perl property which is a
160 # pseudo-property containing only match tables), and any properties that
161 # are usable in regular expression matches also contain various matching
162 # tables, one for each value the property can have.  A binary property can
163 # have two values, True and False (or Y and N, which are preferred by Unicode
164 # terminology).  Thus each of these properties will have a map table that
165 # takes every code point and maps it to Y or N (but having ranges cuts the
166 # number of entries in that table way down), and two match tables, one
167 # which has a list of all the code points that map to Y, and one for all the
168 # code points that map to N.  (For each binary property, a third table is also
169 # generated for the pseudo Perl property.  It contains the identical code
170 # points as the Y table, but can be written in regular expressions, not in the
171 # compound form, but in a "single" form like \p{IsUppercase}.)  Many
172 # properties are binary, but some properties have several possible values,
173 # some have many, and properties like Name have a different value for every
174 # named code point.  Those will not, unless the controlling lists are changed,
175 # have their match tables written out.  But all the ones which can be used in
176 # regular expression \p{} and \P{} constructs will.  Prior to 5.14, generally
177 # a property would have either its map table or its match tables written but
178 # not both.  Again, what gets written is controlled by lists which can easily
179 # be changed.  Starting in 5.14, advantage was taken of this, and all the map
180 # tables needed to reconstruct the Unicode db are now written out, while
181 # suppressing the Unicode .txt files that contain the data.  Our tables are
182 # much more compact than the .txt files, so a significant space savings was
183 # achieved.  Also, tables are not written out that are trivially derivable
184 # from tables that do get written.  So, there typically is no file containing
185 # the code points not matched by a binary property (the table for \P{} versus
186 # lowercase \p{}), since you just need to invert the True table to get the
187 # False table.
188
189 # Properties have a 'Type', like 'binary', or 'string', or 'enum' depending on
190 # how many match tables there are and the content of the maps.  This 'Type' is
191 # different than a range 'Type', so don't get confused by the two concepts
192 # having the same name.
193 #
194 # For information about the Unicode properties, see Unicode's UAX44 document:
195
196 my $unicode_reference_url = 'http://www.unicode.org/reports/tr44/';
197
198 # As stated earlier, this program will work on any release of Unicode so far.
199 # Most obvious problems in earlier data have NOT been corrected except when
200 # necessary to make Perl or this program work reasonably, and to keep out
201 # potential security issues.  For example, no folding information was given in
202 # early releases, so this program substitutes lower case instead, just so that
203 # a regular expression with the /i option will do something that actually
204 # gives the right results in many cases.  There are also a couple other
205 # corrections for version 1.1.5, commented at the point they are made.  As an
206 # example of corrections that weren't made (but could be) is this statement
207 # from DerivedAge.txt: "The supplementary private use code points and the
208 # non-character code points were assigned in version 2.0, but not specifically
209 # listed in the UCD until versions 3.0 and 3.1 respectively."  (To be precise
210 # it was 3.0.1 not 3.0.0)  More information on Unicode version glitches is
211 # further down in these introductory comments.
212 #
213 # This program works on all non-provisional properties as of the current
214 # Unicode release, though the files for some are suppressed for various
215 # reasons.  You can change which are output by changing lists in this program.
216 #
217 # The old version of mktables emphasized the term "Fuzzy" to mean Unicode's
218 # loose matchings rules (from Unicode TR18):
219 #
220 #    The recommended names for UCD properties and property values are in
221 #    PropertyAliases.txt [Prop] and PropertyValueAliases.txt
222 #    [PropValue]. There are both abbreviated names and longer, more
223 #    descriptive names. It is strongly recommended that both names be
224 #    recognized, and that loose matching of property names be used,
225 #    whereby the case distinctions, whitespace, hyphens, and underbar
226 #    are ignored.
227 #
228 # The program still allows Fuzzy to override its determination of if loose
229 # matching should be used, but it isn't currently used, as it is no longer
230 # needed; the calculations it makes are good enough.
231 #
232 # SUMMARY OF HOW IT WORKS:
233 #
234 #   Process arguments
235 #
236 #   A list is constructed containing each input file that is to be processed
237 #
238 #   Each file on the list is processed in a loop, using the associated handler
239 #   code for each:
240 #        The PropertyAliases.txt and PropValueAliases.txt files are processed
241 #            first.  These files name the properties and property values.
242 #            Objects are created of all the property and property value names
243 #            that the rest of the input should expect, including all synonyms.
244 #        The other input files give mappings from properties to property
245 #           values.  That is, they list code points and say what the mapping
246 #           is under the given property.  Some files give the mappings for
247 #           just one property; and some for many.  This program goes through
248 #           each file and populates the properties and their map tables from
249 #           them.  Some properties are listed in more than one file, and
250 #           Unicode has set up a precedence as to which has priority if there
251 #           is a conflict.  Thus the order of processing matters, and this
252 #           program handles the conflict possibility by processing the
253 #           overriding input files last, so that if necessary they replace
254 #           earlier values.
255 #        After this is all done, the program creates the property mappings not
256 #            furnished by Unicode, but derivable from what it does give.
257 #        The tables of code points that match each property value in each
258 #            property that is accessible by regular expressions are created.
259 #        The Perl-defined properties are created and populated.  Many of these
260 #            require data determined from the earlier steps
261 #        Any Perl-defined synonyms are created, and name clashes between Perl
262 #            and Unicode are reconciled and warned about.
263 #        All the properties are written to files
264 #        Any other files are written, and final warnings issued.
265 #
266 # For clarity, a number of operators have been overloaded to work on tables:
267 #   ~ means invert (take all characters not in the set).  The more
268 #       conventional '!' is not used because of the possibility of confusing
269 #       it with the actual boolean operation.
270 #   + means union
271 #   - means subtraction
272 #   & means intersection
273 # The precedence of these is the order listed.  Parentheses should be
274 # copiously used.  These are not a general scheme.  The operations aren't
275 # defined for a number of things, deliberately, to avoid getting into trouble.
276 # Operations are done on references and affect the underlying structures, so
277 # that the copy constructors for them have been overloaded to not return a new
278 # clone, but the input object itself.
279 #
280 # The bool operator is deliberately not overloaded to avoid confusion with
281 # "should it mean if the object merely exists, or also is non-empty?".
282 #
283 # WHY CERTAIN DESIGN DECISIONS WERE MADE
284 #
285 # This program needs to be able to run under miniperl.  Therefore, it uses a
286 # minimum of other modules, and hence implements some things itself that could
287 # be gotten from CPAN
288 #
289 # This program uses inputs published by the Unicode Consortium.  These can
290 # change incompatibly between releases without the Perl maintainers realizing
291 # it.  Therefore this program is now designed to try to flag these.  It looks
292 # at the directories where the inputs are, and flags any unrecognized files.
293 # It keeps track of all the properties in the files it handles, and flags any
294 # that it doesn't know how to handle.  It also flags any input lines that
295 # don't match the expected syntax, among other checks.
296 #
297 # It is also designed so if a new input file matches one of the known
298 # templates, one hopefully just needs to add it to a list to have it
299 # processed.
300 #
301 # As mentioned earlier, some properties are given in more than one file.  In
302 # particular, the files in the extracted directory are supposedly just
303 # reformattings of the others.  But they contain information not easily
304 # derivable from the other files, including results for Unihan (which isn't
305 # usually available to this program) and for unassigned code points.  They
306 # also have historically had errors or been incomplete.  In an attempt to
307 # create the best possible data, this program thus processes them first to
308 # glean information missing from the other files; then processes those other
309 # files to override any errors in the extracted ones.  Much of the design was
310 # driven by this need to store things and then possibly override them.
311 #
312 # It tries to keep fatal errors to a minimum, to generate something usable for
313 # testing purposes.  It always looks for files that could be inputs, and will
314 # warn about any that it doesn't know how to handle (the -q option suppresses
315 # the warning).
316 #
317 # Why is there more than one type of range?
318 #   This simplified things.  There are some very specialized code points that
319 #   have to be handled specially for output, such as Hangul syllable names.
320 #   By creating a range type (done late in the development process), it
321 #   allowed this to be stored with the range, and overridden by other input.
322 #   Originally these were stored in another data structure, and it became a
323 #   mess trying to decide if a second file that was for the same property was
324 #   overriding the earlier one or not.
325 #
326 # Why are there two kinds of tables, match and map?
327 #   (And there is a base class shared by the two as well.)  As stated above,
328 #   they actually are for different things.  Development proceeded much more
329 #   smoothly when I (khw) realized the distinction.  Map tables are used to
330 #   give the property value for every code point (actually every code point
331 #   that doesn't map to a default value).  Match tables are used for regular
332 #   expression matches, and are essentially the inverse mapping.  Separating
333 #   the two allows more specialized methods, and error checks so that one
334 #   can't just take the intersection of two map tables, for example, as that
335 #   is nonsensical.
336 #
337 # What about 'fate' and 'status'.  The concept of a table's fate was created
338 #   late when it became clear that something more was needed.  The difference
339 #   between this and 'status' is unclean, and could be improved if someone
340 #   wanted to spend the effort.
341 #
342 # DEBUGGING
343 #
344 # This program is written so it will run under miniperl.  Occasionally changes
345 # will cause an error where the backtrace doesn't work well under miniperl.
346 # To diagnose the problem, you can instead run it under regular perl, if you
347 # have one compiled.
348 #
349 # There is a good trace facility.  To enable it, first sub DEBUG must be set
350 # to return true.  Then a line like
351 #
352 # local $to_trace = 1 if main::DEBUG;
353 #
354 # can be added to enable tracing in its lexical scope (plus dynamic) or until
355 # you insert another line:
356 #
357 # local $to_trace = 0 if main::DEBUG;
358 #
359 # To actually trace, use a line like "trace $a, @b, %c, ...;
360 #
361 # Some of the more complex subroutines already have trace statements in them.
362 # Permanent trace statements should be like:
363 #
364 # trace ... if main::DEBUG && $to_trace;
365 #
366 # main::stack_trace() will display what its name implies
367 #
368 # If there is just one or a few files that you're debugging, you can easily
369 # cause most everything else to be skipped.  Change the line
370 #
371 # my $debug_skip = 0;
372 #
373 # to 1, and every file whose object is in @input_file_objects and doesn't have
374 # a, 'non_skip => 1,' in its constructor will be skipped.  However, skipping
375 # Jamo.txt or UnicodeData.txt will likely cause fatal errors.
376 #
377 # To compare the output tables, it may be useful to specify the -annotate
378 # flag.  (As of this writing, this can't be done on a clean workspace, due to
379 # requirements in Text::Tabs used in this option; so first run mktables
380 # without this option.)  This option adds comment lines to each table, one for
381 # each non-algorithmically named character giving, currently its code point,
382 # name, and graphic representation if printable (and you have a font that
383 # knows about it).  This makes it easier to see what the particular code
384 # points are in each output table.  Non-named code points are annotated with a
385 # description of their status, and contiguous ones with the same description
386 # will be output as a range rather than individually.  Algorithmically named
387 # characters are also output as ranges, except when there are just a few
388 # contiguous ones.
389 #
390 # FUTURE ISSUES
391 #
392 # The program would break if Unicode were to change its names so that
393 # interior white space, underscores, or dashes differences were significant
394 # within property and property value names.
395 #
396 # It might be easier to use the xml versions of the UCD if this program ever
397 # would need heavy revision, and the ability to handle old versions was not
398 # required.
399 #
400 # There is the potential for name collisions, in that Perl has chosen names
401 # that Unicode could decide it also likes.  There have been such collisions in
402 # the past, with mostly Perl deciding to adopt the Unicode definition of the
403 # name.  However in the 5.2 Unicode beta testing, there were a number of such
404 # collisions, which were withdrawn before the final release, because of Perl's
405 # and other's protests.  These all involved new properties which began with
406 # 'Is'.  Based on the protests, Unicode is unlikely to try that again.  Also,
407 # many of the Perl-defined synonyms, like Any, Word, etc, are listed in a
408 # Unicode document, so they are unlikely to be used by Unicode for another
409 # purpose.  However, they might try something beginning with 'In', or use any
410 # of the other Perl-defined properties.  This program will warn you of name
411 # collisions, and refuse to generate tables with them, but manual intervention
412 # will be required in this event.  One scheme that could be implemented, if
413 # necessary, would be to have this program generate another file, or add a
414 # field to mktables.lst that gives the date of first definition of a property.
415 # Each new release of Unicode would use that file as a basis for the next
416 # iteration.  And the Perl synonym addition code could sort based on the age
417 # of the property, so older properties get priority, and newer ones that clash
418 # would be refused; hence existing code would not be impacted, and some other
419 # synonym would have to be used for the new property.  This is ugly, and
420 # manual intervention would certainly be easier to do in the short run; lets
421 # hope it never comes to this.
422 #
423 # A NOTE ON UNIHAN
424 #
425 # This program can generate tables from the Unihan database.  But that DB
426 # isn't normally available, so it is marked as optional.  Prior to version
427 # 5.2, this database was in a single file, Unihan.txt.  In 5.2 the database
428 # was split into 8 different files, all beginning with the letters 'Unihan'.
429 # If you plunk those files down into the directory mktables ($0) is in, this
430 # program will read them and automatically create tables for the properties
431 # from it that are listed in PropertyAliases.txt and PropValueAliases.txt,
432 # plus any you add to the @cjk_properties array and the @cjk_property_values
433 # array, being sure to add necessary '# @missings' lines to the latter.  For
434 # Unicode versions earlier than 5.2, most of the Unihan properties are not
435 # listed at all in PropertyAliases nor PropValueAliases.  This program assumes
436 # for these early releases that you want the properties that are specified in
437 # the 5.2 release.
438 #
439 # You may need to adjust the entries to suit your purposes.  setup_unihan(),
440 # and filter_unihan_line() are the functions where this is done.  This program
441 # already does some adjusting to make the lines look more like the rest of the
442 # Unicode DB;  You can see what that is in filter_unihan_line()
443 #
444 # There is a bug in the 3.2 data file in which some values for the
445 # kPrimaryNumeric property have commas and an unexpected comment.  A filter
446 # could be added to correct these; or for a particular installation, the
447 # Unihan.txt file could be edited to fix them.
448 #
449 # HOW TO ADD A FILE TO BE PROCESSED
450 #
451 # A new file from Unicode needs to have an object constructed for it in
452 # @input_file_objects, probably at the end or at the end of the extracted
453 # ones.  The program should warn you if its name will clash with others on
454 # restrictive file systems, like DOS.  If so, figure out a better name, and
455 # add lines to the README.perl file giving that.  If the file is a character
456 # property, it should be in the format that Unicode has implicitly
457 # standardized for such files for the more recently introduced ones.
458 # If so, the Input_file constructor for @input_file_objects can just be the
459 # file name and release it first appeared in.  If not, then it should be
460 # possible to construct an each_line_handler() to massage the line into the
461 # standardized form.
462 #
463 # For non-character properties, more code will be needed.  You can look at
464 # the existing entries for clues.
465 #
466 # UNICODE VERSIONS NOTES
467 #
468 # The Unicode UCD has had a number of errors in it over the versions.  And
469 # these remain, by policy, in the standard for that version.  Therefore it is
470 # risky to correct them, because code may be expecting the error.  So this
471 # program doesn't generally make changes, unless the error breaks the Perl
472 # core.  As an example, some versions of 2.1.x Jamo.txt have the wrong value
473 # for U+1105, which causes real problems for the algorithms for Jamo
474 # calculations, so it is changed here.
475 #
476 # But it isn't so clear cut as to what to do about concepts that are
477 # introduced in a later release; should they extend back to earlier releases
478 # where the concept just didn't exist?  It was easier to do this than to not,
479 # so that's what was done.  For example, the default value for code points not
480 # in the files for various properties was probably undefined until changed by
481 # some version.  No_Block for blocks is such an example.  This program will
482 # assign No_Block even in Unicode versions that didn't have it.  This has the
483 # benefit that code being written doesn't have to special case earlier
484 # versions; and the detriment that it doesn't match the Standard precisely for
485 # the affected versions.
486 #
487 # Here are some observations about some of the issues in early versions:
488 #
489 # Prior to version 3.0, there were 3 character decompositions.  These are not
490 # handled by Unicode::Normalize, nor will it compile when presented a version
491 # that has them.  However, you can trivially get it to compile by simply
492 # ignoring those decompositions, by changing the croak to a carp.  At the time
493 # of this writing, the line (in dist/Unicode-Normalize/Normalize.pm or
494 # dist/Unicode-Normalize/mkheader) reads
495 #
496 #   croak("Weird Canonical Decomposition of U+$h");
497 #
498 # Simply comment it out.  It will compile, but will not know about any three
499 # character decompositions.
500
501 # The number of code points in \p{alpha=True} halved in 2.1.9.  It turns out
502 # that the reason is that the CJK block starting at 4E00 was removed from
503 # PropList, and was not put back in until 3.1.0.  The Perl extension (the
504 # single property name \p{alpha}) has the correct values.  But the compound
505 # form is simply not generated until 3.1, as it can be argued that prior to
506 # this release, this was not an official property.  The comments for
507 # filter_old_style_proplist() give more details.
508 #
509 # Unicode introduced the synonym Space for White_Space in 4.1.  Perl has
510 # always had a \p{Space}.  In release 3.2 only, they are not synonymous.  The
511 # reason is that 3.2 introduced U+205F=medium math space, which was not
512 # classed as white space, but Perl figured out that it should have been. 4.0
513 # reclassified it correctly.
514 #
515 # Another change between 3.2 and 4.0 is the CCC property value ATBL.  In 3.2
516 # this was erroneously a synonym for 202 (it should be 200).  In 4.0, ATB
517 # became 202, and ATBL was left with no code points, as all the ones that
518 # mapped to 202 stayed mapped to 202.  Thus if your program used the numeric
519 # name for the class, it would not have been affected, but if it used the
520 # mnemonic, it would have been.
521 #
522 # \p{Script=Hrkt} (Katakana_Or_Hiragana) came in 4.0.1.  Before that, code
523 # points which eventually came to have this script property value, instead
524 # mapped to "Unknown".  But in the next release all these code points were
525 # moved to \p{sc=common} instead.
526
527 # The tests furnished  by Unicode for testing WordBreak and SentenceBreak
528 # generate errors in 5.0 and earlier.
529 #
530 # The default for missing code points for BidiClass is complicated.  Starting
531 # in 3.1.1, the derived file DBidiClass.txt handles this, but this program
532 # tries to do the best it can for earlier releases.  It is done in
533 # process_PropertyAliases()
534 #
535 # In version 2.1.2, the entry in UnicodeData.txt:
536 #   0275;LATIN SMALL LETTER BARRED O;Ll;0;L;;;;;N;;;;019F;
537 # should instead be
538 #   0275;LATIN SMALL LETTER BARRED O;Ll;0;L;;;;;N;;;019F;;019F
539 # Without this change, there are casing problems for this character.
540 #
541 # Search for $string_compare_versions to see how to compare changes to
542 # properties between Unicode versions
543 #
544 ##############################################################################
545
546 my $UNDEF = ':UNDEF:';  # String to print out for undefined values in tracing
547                         # and errors
548 my $MAX_LINE_WIDTH = 78;
549
550 # Debugging aid to skip most files so as to not be distracted by them when
551 # concentrating on the ones being debugged.  Add
552 # non_skip => 1,
553 # to the constructor for those files you want processed when you set this.
554 # Files with a first version number of 0 are special: they are always
555 # processed regardless of the state of this flag.  Generally, Jamo.txt and
556 # UnicodeData.txt must not be skipped if you want this program to not die
557 # before normal completion.
558 my $debug_skip = 0;
559
560
561 # Normally these are suppressed.
562 my $write_Unicode_deprecated_tables = 0;
563
564 # Set to 1 to enable tracing.
565 our $to_trace = 0;
566
567 { # Closure for trace: debugging aid
568     my $print_caller = 1;        # ? Include calling subroutine name
569     my $main_with_colon = 'main::';
570     my $main_colon_length = length($main_with_colon);
571
572     sub trace {
573         return unless $to_trace;        # Do nothing if global flag not set
574
575         my @input = @_;
576
577         local $DB::trace = 0;
578         $DB::trace = 0;          # Quiet 'used only once' message
579
580         my $line_number;
581
582         # Loop looking up the stack to get the first non-trace caller
583         my $caller_line;
584         my $caller_name;
585         my $i = 0;
586         do {
587             $line_number = $caller_line;
588             (my $pkg, my $file, $caller_line, my $caller) = caller $i++;
589             $caller = $main_with_colon unless defined $caller;
590
591             $caller_name = $caller;
592
593             # get rid of pkg
594             $caller_name =~ s/.*:://;
595             if (substr($caller_name, 0, $main_colon_length)
596                 eq $main_with_colon)
597             {
598                 $caller_name = substr($caller_name, $main_colon_length);
599             }
600
601         } until ($caller_name ne 'trace');
602
603         # If the stack was empty, we were called from the top level
604         $caller_name = 'main' if ($caller_name eq ""
605                                     || $caller_name eq 'trace');
606
607         my $output = "";
608         #print STDERR __LINE__, ": ", join ", ", @input, "\n";
609         foreach my $string (@input) {
610             if (ref $string eq 'ARRAY' || ref $string eq 'HASH') {
611                 $output .= simple_dumper($string);
612             }
613             else {
614                 $string = "$string" if ref $string;
615                 $string = $UNDEF unless defined $string;
616                 chomp $string;
617                 $string = '""' if $string eq "";
618                 $output .= " " if $output ne ""
619                                 && $string ne ""
620                                 && substr($output, -1, 1) ne " "
621                                 && substr($string, 0, 1) ne " ";
622                 $output .= $string;
623             }
624         }
625
626         print STDERR sprintf "%4d: ", $line_number if defined $line_number;
627         print STDERR "$caller_name: " if $print_caller;
628         print STDERR $output, "\n";
629         return;
630     }
631 }
632
633 sub stack_trace() {
634     local $to_trace = 1 if main::DEBUG;
635     my $line = (caller(0))[2];
636     my $i = 1;
637
638     # Accumulate the stack trace
639     while (1) {
640         my ($pkg, $file, $caller_line, $caller) = caller $i++;
641
642         last unless defined $caller;
643
644         trace "called from $caller() at line $line";
645         $line = $caller_line;
646     }
647 }
648
649 # This is for a rarely used development feature that allows you to compare two
650 # versions of the Unicode standard without having to deal with changes caused
651 # by the code points introduced in the later version.  You probably also want
652 # to use the -annotate option when using this.  Run this program on a unicore
653 # containing the starting release you want to compare.  Save that output
654 # structure.  Then, switching to a unicore with the ending release, change the
655 # 0 in the $string_compare_versions definition just below to a string
656 # containing a SINGLE dotted Unicode release number (e.g. "2.1") corresponding
657 # to the starting release.  This program will then compile, but throw away all
658 # code points introduced after the starting release.  Finally use a diff tool
659 # to compare the two directory structures.  They include only the code points
660 # common to both releases, and you can see the changes caused just by the
661 # underlying release semantic changes.  For versions earlier than 3.2, you
662 # must copy a version of DAge.txt into the directory.
663 my $string_compare_versions = DEBUG && ""; #  e.g., "2.1";
664 my $compare_versions = DEBUG
665                        && $string_compare_versions
666                        && pack "C*", split /\./, $string_compare_versions;
667
668 sub uniques {
669     # Returns non-duplicated input values.  From "Perl Best Practices:
670     # Encapsulated Cleverness".  p. 455 in first edition.
671
672     my %seen;
673     # Arguably this breaks encapsulation, if the goal is to permit multiple
674     # distinct objects to stringify to the same value, and be interchangeable.
675     # However, for this program, no two objects stringify identically, and all
676     # lists passed to this function are either objects or strings. So this
677     # doesn't affect correctness, but it does give a couple of percent speedup.
678     no overloading;
679     return grep { ! $seen{$_}++ } @_;
680 }
681
682 $0 = File::Spec->canonpath($0);
683
684 my $make_test_script = 0;      # ? Should we output a test script
685 my $make_norm_test_script = 0; # ? Should we output a normalization test script
686 my $write_unchanged_files = 0; # ? Should we update the output files even if
687                                #    we don't think they have changed
688 my $use_directory = "";        # ? Should we chdir somewhere.
689 my $pod_directory;             # input directory to store the pod file.
690 my $pod_file = 'perluniprops';
691 my $t_path;                     # Path to the .t test file
692 my $file_list = 'mktables.lst'; # File to store input and output file names.
693                                # This is used to speed up the build, by not
694                                # executing the main body of the program if
695                                # nothing on the list has changed since the
696                                # previous build
697 my $make_list = 1;             # ? Should we write $file_list.  Set to always
698                                # make a list so that when the pumpking is
699                                # preparing a release, s/he won't have to do
700                                # special things
701 my $glob_list = 0;             # ? Should we try to include unknown .txt files
702                                # in the input.
703 my $output_range_counts = $debugging_build;   # ? Should we include the number
704                                               # of code points in ranges in
705                                               # the output
706 my $annotate = 0;              # ? Should character names be in the output
707
708 # Verbosity levels; 0 is quiet
709 my $NORMAL_VERBOSITY = 1;
710 my $PROGRESS = 2;
711 my $VERBOSE = 3;
712
713 my $verbosity = $NORMAL_VERBOSITY;
714
715 # Stored in mktables.lst so that if this program is called with different
716 # options, will regenerate even if the files otherwise look like they're
717 # up-to-date.
718 my $command_line_arguments = join " ", @ARGV;
719
720 # Process arguments
721 while (@ARGV) {
722     my $arg = shift @ARGV;
723     if ($arg eq '-v') {
724         $verbosity = $VERBOSE;
725     }
726     elsif ($arg eq '-p') {
727         $verbosity = $PROGRESS;
728         $| = 1;     # Flush buffers as we go.
729     }
730     elsif ($arg eq '-q') {
731         $verbosity = 0;
732     }
733     elsif ($arg eq '-w') {
734         # update the files even if they haven't changed
735         $write_unchanged_files = 1;
736     }
737     elsif ($arg eq '-check') {
738         my $this = shift @ARGV;
739         my $ok = shift @ARGV;
740         if ($this ne $ok) {
741             print "Skipping as check params are not the same.\n";
742             exit(0);
743         }
744     }
745     elsif ($arg eq '-P' && defined ($pod_directory = shift)) {
746         -d $pod_directory or croak "Directory '$pod_directory' doesn't exist";
747     }
748     elsif ($arg eq '-maketest' || ($arg eq '-T' && defined ($t_path = shift)))
749     {
750         $make_test_script = 1;
751     }
752     elsif ($arg eq '-makenormtest')
753     {
754         $make_norm_test_script = 1;
755     }
756     elsif ($arg eq '-makelist') {
757         $make_list = 1;
758     }
759     elsif ($arg eq '-C' && defined ($use_directory = shift)) {
760         -d $use_directory or croak "Unknown directory '$use_directory'";
761     }
762     elsif ($arg eq '-L') {
763
764         # Existence not tested until have chdir'd
765         $file_list = shift;
766     }
767     elsif ($arg eq '-globlist') {
768         $glob_list = 1;
769     }
770     elsif ($arg eq '-c') {
771         $output_range_counts = ! $output_range_counts
772     }
773     elsif ($arg eq '-annotate') {
774         $annotate = 1;
775         $debugging_build = 1;
776         $output_range_counts = 1;
777     }
778     else {
779         my $with_c = 'with';
780         $with_c .= 'out' if $output_range_counts;   # Complements the state
781         croak <<END;
782 usage: $0 [-c|-p|-q|-v|-w] [-C dir] [-L filelist] [ -P pod_dir ]
783           [ -T test_file_path ] [-globlist] [-makelist] [-maketest]
784           [-check A B ]
785   -c          : Output comments $with_c number of code points in ranges
786   -q          : Quiet Mode: Only output serious warnings.
787   -p          : Set verbosity level to normal plus show progress.
788   -v          : Set Verbosity level high:  Show progress and non-serious
789                 warnings
790   -w          : Write files regardless
791   -C dir      : Change to this directory before proceeding. All relative paths
792                 except those specified by the -P and -T options will be done
793                 with respect to this directory.
794   -P dir      : Output $pod_file file to directory 'dir'.
795   -T path     : Create a test script as 'path'; overrides -maketest
796   -L filelist : Use alternate 'filelist' instead of standard one
797   -globlist   : Take as input all non-Test *.txt files in current and sub
798                 directories
799   -maketest   : Make test script 'TestProp.pl' in current (or -C directory),
800                 overrides -T
801   -makelist   : Rewrite the file list $file_list based on current setup
802   -annotate   : Output an annotation for each character in the table files;
803                 useful for debugging mktables, looking at diffs; but is slow
804                 and memory intensive
805   -check A B  : Executes $0 only if A and B are the same
806 END
807     }
808 }
809
810 # Stores the most-recently changed file.  If none have changed, can skip the
811 # build
812 my $most_recent = (stat $0)[9];   # Do this before the chdir!
813
814 # Change directories now, because need to read 'version' early.
815 if ($use_directory) {
816     if ($pod_directory && ! File::Spec->file_name_is_absolute($pod_directory)) {
817         $pod_directory = File::Spec->rel2abs($pod_directory);
818     }
819     if ($t_path && ! File::Spec->file_name_is_absolute($t_path)) {
820         $t_path = File::Spec->rel2abs($t_path);
821     }
822     chdir $use_directory or croak "Failed to chdir to '$use_directory':$!";
823     if ($pod_directory && File::Spec->file_name_is_absolute($pod_directory)) {
824         $pod_directory = File::Spec->abs2rel($pod_directory);
825     }
826     if ($t_path && File::Spec->file_name_is_absolute($t_path)) {
827         $t_path = File::Spec->abs2rel($t_path);
828     }
829 }
830
831 # Get Unicode version into regular and v-string.  This is done now because
832 # various tables below get populated based on it.  These tables are populated
833 # here to be near the top of the file, and so easily seeable by those needing
834 # to modify things.
835 open my $VERSION, "<", "version"
836                     or croak "$0: can't open required file 'version': $!\n";
837 my $string_version = <$VERSION>;
838 close $VERSION;
839 chomp $string_version;
840 my $v_version = pack "C*", split /\./, $string_version;        # v string
841
842 my $unicode_version = ($compare_versions)
843                       ? (  "$string_compare_versions (using "
844                          . "$string_version rules)")
845                       : $string_version;
846
847 # The following are the complete names of properties with property values that
848 # are known to not match any code points in some versions of Unicode, but that
849 # may change in the future so they should be matchable, hence an empty file is
850 # generated for them.
851 my @tables_that_may_be_empty;
852 push @tables_that_may_be_empty, 'Joining_Type=Left_Joining'
853                                                     if $v_version lt v6.3.0;
854 push @tables_that_may_be_empty, 'Script=Common' if $v_version le v4.0.1;
855 push @tables_that_may_be_empty, 'Title' if $v_version lt v2.0.0;
856 push @tables_that_may_be_empty, 'Script=Katakana_Or_Hiragana'
857                                                     if $v_version ge v4.1.0;
858 push @tables_that_may_be_empty, 'Script_Extensions=Katakana_Or_Hiragana'
859                                                     if $v_version ge v6.0.0;
860 push @tables_that_may_be_empty, 'Grapheme_Cluster_Break=Prepend'
861                                                     if $v_version ge v6.1.0;
862 push @tables_that_may_be_empty, 'Canonical_Combining_Class=CCC133'
863                                                     if $v_version ge v6.2.0;
864
865 # The lists below are hashes, so the key is the item in the list, and the
866 # value is the reason why it is in the list.  This makes generation of
867 # documentation easier.
868
869 my %why_suppressed;  # No file generated for these.
870
871 # Files aren't generated for empty extraneous properties.  This is arguable.
872 # Extraneous properties generally come about because a property is no longer
873 # used in a newer version of Unicode.  If we generated a file without code
874 # points, programs that used to work on that property will still execute
875 # without errors.  It just won't ever match (or will always match, with \P{}).
876 # This means that the logic is now likely wrong.  I (khw) think its better to
877 # find this out by getting an error message.  Just move them to the table
878 # above to change this behavior
879 my %why_suppress_if_empty_warn_if_not = (
880
881    # It is the only property that has ever officially been removed from the
882    # Standard.  The database never contained any code points for it.
883    'Special_Case_Condition' => 'Obsolete',
884
885    # Apparently never official, but there were code points in some versions of
886    # old-style PropList.txt
887    'Non_Break' => 'Obsolete',
888 );
889
890 # These would normally go in the warn table just above, but they were changed
891 # a long time before this program was written, so warnings about them are
892 # moot.
893 if ($v_version gt v3.2.0) {
894     push @tables_that_may_be_empty,
895                                 'Canonical_Combining_Class=Attached_Below_Left'
896 }
897
898 # Enum values for to_output_map() method in the Map_Table package. (0 is don't
899 # output)
900 my $EXTERNAL_MAP = 1;
901 my $INTERNAL_MAP = 2;
902 my $OUTPUT_ADJUSTED = 3;
903
904 # To override computed values for writing the map tables for these properties.
905 # The default for enum map tables is to write them out, so that the Unicode
906 # .txt files can be removed, but all the data to compute any property value
907 # for any code point is available in a more compact form.
908 my %global_to_output_map = (
909     # Needed by UCD.pm, but don't want to publicize that it exists, so won't
910     # get stuck supporting it if things change.  Since it is a STRING
911     # property, it normally would be listed in the pod, but INTERNAL_MAP
912     # suppresses that.
913     Unicode_1_Name => $INTERNAL_MAP,
914
915     Present_In => 0,                # Suppress, as easily computed from Age
916     Block => (NON_ASCII_PLATFORM) ? 1 : 0,  # Suppress, as Blocks.txt is
917                                             # retained, but needed for
918                                             # non-ASCII
919
920     # Suppress, as mapping can be found instead from the
921     # Perl_Decomposition_Mapping file
922     Decomposition_Type => 0,
923 );
924
925 # There are several types of obsolete properties defined by Unicode.  These
926 # must be hand-edited for every new Unicode release.
927 my %why_deprecated;  # Generates a deprecated warning message if used.
928 my %why_stabilized;  # Documentation only
929 my %why_obsolete;    # Documentation only
930
931 {   # Closure
932     my $simple = 'Perl uses the more complete version';
933     my $unihan = 'Unihan properties are by default not enabled in the Perl core.  Instead use CPAN: Unicode::Unihan';
934
935     my $other_properties = 'other properties';
936     my $contributory = "Used by Unicode internally for generating $other_properties and not intended to be used stand-alone";
937     my $why_no_expand  = "Deprecated by Unicode.  These are characters that expand to more than one character in the specified normalization form, but whether they actually take up more bytes or not depends on the encoding being used.  For example, a UTF-8 encoded character may expand to a different number of bytes than a UTF-32 encoded character.";
938
939     %why_deprecated = (
940         'Grapheme_Link' => 'Deprecated by Unicode:  Duplicates ccc=vr (Canonical_Combining_Class=Virama)',
941         'Jamo_Short_Name' => $contributory,
942         'Line_Break=Surrogate' => 'Deprecated by Unicode because surrogates should never appear in well-formed text, and therefore shouldn\'t be the basis for line breaking',
943         'Other_Alphabetic' => $contributory,
944         'Other_Default_Ignorable_Code_Point' => $contributory,
945         'Other_Grapheme_Extend' => $contributory,
946         'Other_ID_Continue' => $contributory,
947         'Other_ID_Start' => $contributory,
948         'Other_Lowercase' => $contributory,
949         'Other_Math' => $contributory,
950         'Other_Uppercase' => $contributory,
951         'Expands_On_NFC' => $why_no_expand,
952         'Expands_On_NFD' => $why_no_expand,
953         'Expands_On_NFKC' => $why_no_expand,
954         'Expands_On_NFKD' => $why_no_expand,
955     );
956
957     %why_suppressed = (
958         # There is a lib/unicore/Decomposition.pl (used by Normalize.pm) which
959         # contains the same information, but without the algorithmically
960         # determinable Hangul syllables'.  This file is not published, so it's
961         # existence is not noted in the comment.
962         'Decomposition_Mapping' => 'Accessible via Unicode::Normalize or prop_invmap() or charprop() in Unicode::UCD::',
963
964         # Don't suppress ISO_Comment, as otherwise special handling is needed
965         # to differentiate between it and gc=c, which can be written as 'isc',
966         # which is the same characters as ISO_Comment's short name.
967
968         'Name' => "Accessible via \\N{...} or 'use charnames;' or charprop() or prop_invmap() in Unicode::UCD::",
969
970         'Simple_Case_Folding' => "$simple.  Can access this through casefold(), charprop(), or prop_invmap() in Unicode::UCD",
971         'Simple_Lowercase_Mapping' => "$simple.  Can access this through charinfo(), charprop(), or prop_invmap() in Unicode::UCD",
972         'Simple_Titlecase_Mapping' => "$simple.  Can access this through charinfo(), charprop(), or prop_invmap() in Unicode::UCD",
973         'Simple_Uppercase_Mapping' => "$simple.  Can access this through charinfo(), charprop(), or prop_invmap() in Unicode::UCD",
974
975         FC_NFKC_Closure => 'Deprecated by Unicode, and supplanted in usage by NFKC_Casefold; otherwise not useful',
976     );
977
978     foreach my $property (
979
980             # The following are suppressed because they were made contributory
981             # or deprecated by Unicode before Perl ever thought about
982             # supporting them.
983             'Jamo_Short_Name',
984             'Grapheme_Link',
985             'Expands_On_NFC',
986             'Expands_On_NFD',
987             'Expands_On_NFKC',
988             'Expands_On_NFKD',
989
990             # The following are suppressed because they have been marked
991             # as deprecated for a sufficient amount of time
992             'Other_Alphabetic',
993             'Other_Default_Ignorable_Code_Point',
994             'Other_Grapheme_Extend',
995             'Other_ID_Continue',
996             'Other_ID_Start',
997             'Other_Lowercase',
998             'Other_Math',
999             'Other_Uppercase',
1000     ) {
1001         $why_suppressed{$property} = $why_deprecated{$property};
1002     }
1003
1004     # Customize the message for all the 'Other_' properties
1005     foreach my $property (keys %why_deprecated) {
1006         next if (my $main_property = $property) !~ s/^Other_//;
1007         $why_deprecated{$property} =~ s/$other_properties/the $main_property property (which should be used instead)/;
1008     }
1009 }
1010
1011 if ($write_Unicode_deprecated_tables) {
1012     foreach my $property (keys %why_suppressed) {
1013         delete $why_suppressed{$property} if $property =~
1014                                                     / ^ Other | Grapheme /x;
1015     }
1016 }
1017
1018 if ($v_version ge 4.0.0) {
1019     $why_stabilized{'Hyphen'} = 'Use the Line_Break property instead; see www.unicode.org/reports/tr14';
1020     if ($v_version ge 6.0.0) {
1021         $why_deprecated{'Hyphen'} = 'Supplanted by Line_Break property values; see www.unicode.org/reports/tr14';
1022     }
1023 }
1024 if ($v_version ge 5.2.0 && $v_version lt 6.0.0) {
1025     $why_obsolete{'ISO_Comment'} = 'Code points for it have been removed';
1026     if ($v_version ge 6.0.0) {
1027         $why_deprecated{'ISO_Comment'} = 'No longer needed for Unicode\'s internal chart generation; otherwise not useful, and code points for it have been removed';
1028     }
1029 }
1030
1031 # Probably obsolete forever
1032 if ($v_version ge v4.1.0) {
1033     $why_suppressed{'Script=Katakana_Or_Hiragana'} = 'Obsolete.  All code points previously matched by this have been moved to "Script=Common".';
1034 }
1035 if ($v_version ge v6.0.0) {
1036     $why_suppressed{'Script=Katakana_Or_Hiragana'} .= '  Consider instead using "Script_Extensions=Katakana" or "Script_Extensions=Hiragana" (or both)';
1037     $why_suppressed{'Script_Extensions=Katakana_Or_Hiragana'} = 'All code points that would be matched by this are matched by either "Script_Extensions=Katakana" or "Script_Extensions=Hiragana"';
1038 }
1039
1040 # This program can create files for enumerated-like properties, such as
1041 # 'Numeric_Type'.  This file would be the same format as for a string
1042 # property, with a mapping from code point to its value, so you could look up,
1043 # for example, the script a code point is in.  But no one so far wants this
1044 # mapping, or they have found another way to get it since this is a new
1045 # feature.  So no file is generated except if it is in this list.
1046 my @output_mapped_properties = split "\n", <<END;
1047 END
1048
1049 # If you want more Unihan properties than the default, you need to add them to
1050 # these arrays.  Depending on the property type, @missing lines might have to
1051 # be added to the second array.  A sample entry would be (including the '#'):
1052 # @missing: 0000..10FFFF; cjkAccountingNumeric; NaN
1053 my @cjk_properties = split "\n", <<'END';
1054 END
1055 my @cjk_property_values = split "\n", <<'END';
1056 END
1057
1058 # The input files don't list every code point.  Those not listed are to be
1059 # defaulted to some value.  Below are hard-coded what those values are for
1060 # non-binary properties as of 5.1.  Starting in 5.0, there are
1061 # machine-parsable comment lines in the files that give the defaults; so this
1062 # list shouldn't have to be extended.  The claim is that all missing entries
1063 # for binary properties will default to 'N'.  Unicode tried to change that in
1064 # 5.2, but the beta period produced enough protest that they backed off.
1065 #
1066 # The defaults for the fields that appear in UnicodeData.txt in this hash must
1067 # be in the form that it expects.  The others may be synonyms.
1068 my $CODE_POINT = '<code point>';
1069 my %default_mapping = (
1070     Age => "Unassigned",
1071     # Bidi_Class => Complicated; set in code
1072     Bidi_Mirroring_Glyph => "",
1073     Block => 'No_Block',
1074     Canonical_Combining_Class => 0,
1075     Case_Folding => $CODE_POINT,
1076     Decomposition_Mapping => $CODE_POINT,
1077     Decomposition_Type => 'None',
1078     East_Asian_Width => "Neutral",
1079     FC_NFKC_Closure => $CODE_POINT,
1080     General_Category => ($v_version le 6.3.0) ? 'Cn' : 'Unassigned',
1081     Grapheme_Cluster_Break => 'Other',
1082     Hangul_Syllable_Type => 'NA',
1083     ISO_Comment => "",
1084     Jamo_Short_Name => "",
1085     Joining_Group => "No_Joining_Group",
1086     # Joining_Type => Complicated; set in code
1087     kIICore => 'N',   #                       Is converted to binary
1088     #Line_Break => Complicated; set in code
1089     Lowercase_Mapping => $CODE_POINT,
1090     Name => "",
1091     Name_Alias => "",
1092     NFC_QC => 'Yes',
1093     NFD_QC => 'Yes',
1094     NFKC_QC => 'Yes',
1095     NFKD_QC => 'Yes',
1096     Numeric_Type => 'None',
1097     Numeric_Value => 'NaN',
1098     Script => ($v_version le 4.1.0) ? 'Common' : 'Unknown',
1099     Sentence_Break => 'Other',
1100     Simple_Case_Folding => $CODE_POINT,
1101     Simple_Lowercase_Mapping => $CODE_POINT,
1102     Simple_Titlecase_Mapping => $CODE_POINT,
1103     Simple_Uppercase_Mapping => $CODE_POINT,
1104     Titlecase_Mapping => $CODE_POINT,
1105     Unicode_1_Name => "",
1106     Unicode_Radical_Stroke => "",
1107     Uppercase_Mapping => $CODE_POINT,
1108     Word_Break => 'Other',
1109 );
1110
1111 ### End of externally interesting definitions, except for @input_file_objects
1112
1113 my $HEADER=<<"EOF";
1114 # !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
1115 # This file is machine-generated by $0 from the Unicode
1116 # database, Version $unicode_version.  Any changes made here will be lost!
1117 EOF
1118
1119 my $INTERNAL_ONLY_HEADER = <<"EOF";
1120
1121 # !!!!!!!   INTERNAL PERL USE ONLY   !!!!!!!
1122 # This file is for internal use by core Perl only.  The format and even the
1123 # name or existence of this file are subject to change without notice.  Don't
1124 # use it directly.  Use Unicode::UCD to access the Unicode character data
1125 # base.
1126 EOF
1127
1128 my $DEVELOPMENT_ONLY=<<"EOF";
1129 # !!!!!!!   DEVELOPMENT USE ONLY   !!!!!!!
1130 # This file contains information artificially constrained to code points
1131 # present in Unicode release $string_compare_versions.
1132 # IT CANNOT BE RELIED ON.  It is for use during development only and should
1133 # not be used for production.
1134
1135 EOF
1136
1137 my $MAX_UNICODE_CODEPOINT_STRING = ($v_version ge v2.0.0)
1138                                    ? "10FFFF"
1139                                    : "FFFF";
1140 my $MAX_UNICODE_CODEPOINT = hex $MAX_UNICODE_CODEPOINT_STRING;
1141 my $MAX_UNICODE_CODEPOINTS = $MAX_UNICODE_CODEPOINT + 1;
1142
1143 # We work with above-Unicode code points, up to UV_MAX.   But when you get
1144 # that high, above IV_MAX, some operations don't work, and you can easily get
1145 # overflow.  Therefore for internal use, we use a much smaller number,
1146 # translating it to UV_MAX only for output.  The exact number is immaterial
1147 # (all Unicode code points are treated exactly the same), but the algorithm
1148 # requires it to be at least 2 * $MAX_UNICODE_CODEPOINTS + 1;
1149 my $MAX_WORKING_CODEPOINTS= $MAX_UNICODE_CODEPOINT * 8;
1150 my $MAX_WORKING_CODEPOINT = $MAX_WORKING_CODEPOINTS - 1;
1151 my $MAX_WORKING_CODEPOINT_STRING = sprintf("%X", $MAX_WORKING_CODEPOINT);
1152
1153 my $MAX_PLATFORM_CODEPOINT = ~0;
1154
1155 # Matches legal code point.  4-6 hex numbers, If there are 6, the first
1156 # two must be 10; if there are 5, the first must not be a 0.  Written this way
1157 # to decrease backtracking.  The first regex allows the code point to be at
1158 # the end of a word, but to work properly, the word shouldn't end with a valid
1159 # hex character.  The second one won't match a code point at the end of a
1160 # word, and doesn't have the run-on issue
1161 my $run_on_code_point_re =
1162             qr/ (?: 10[0-9A-F]{4} | [1-9A-F][0-9A-F]{4} | [0-9A-F]{4} ) \b/x;
1163 my $code_point_re = qr/\b$run_on_code_point_re/;
1164
1165 # This matches the beginning of the line in the Unicode DB files that give the
1166 # defaults for code points not listed (i.e., missing) in the file.  The code
1167 # depends on this ending with a semi-colon, so it can assume it is a valid
1168 # field when the line is split() by semi-colons
1169 my $missing_defaults_prefix = qr/^#\s+\@missing:\s+0000\.\.10FFFF\s*;/;
1170
1171 # Property types.  Unicode has more types, but these are sufficient for our
1172 # purposes.
1173 my $UNKNOWN = -1;   # initialized to illegal value
1174 my $NON_STRING = 1; # Either binary or enum
1175 my $BINARY = 2;
1176 my $FORCED_BINARY = 3; # Not a binary property, but, besides its normal
1177                        # tables, additional true and false tables are
1178                        # generated so that false is anything matching the
1179                        # default value, and true is everything else.
1180 my $ENUM = 4;       # Include catalog
1181 my $STRING = 5;     # Anything else: string or misc
1182
1183 # Some input files have lines that give default values for code points not
1184 # contained in the file.  Sometimes these should be ignored.
1185 my $NO_DEFAULTS = 0;        # Must evaluate to false
1186 my $NOT_IGNORED = 1;
1187 my $IGNORED = 2;
1188
1189 # Range types.  Each range has a type.  Most ranges are type 0, for normal,
1190 # and will appear in the main body of the tables in the output files, but
1191 # there are other types of ranges as well, listed below, that are specially
1192 # handled.   There are pseudo-types as well that will never be stored as a
1193 # type, but will affect the calculation of the type.
1194
1195 # 0 is for normal, non-specials
1196 my $MULTI_CP = 1;           # Sequence of more than code point
1197 my $HANGUL_SYLLABLE = 2;
1198 my $CP_IN_NAME = 3;         # The NAME contains the code point appended to it.
1199 my $NULL = 4;               # The map is to the null string; utf8.c can't
1200                             # handle these, nor is there an accepted syntax
1201                             # for them in \p{} constructs
1202 my $COMPUTE_NO_MULTI_CP = 5; # Pseudo-type; means that ranges that would
1203                              # otherwise be $MULTI_CP type are instead type 0
1204
1205 # process_generic_property_file() can accept certain overrides in its input.
1206 # Each of these must begin AND end with $CMD_DELIM.
1207 my $CMD_DELIM = "\a";
1208 my $REPLACE_CMD = 'replace';    # Override the Replace
1209 my $MAP_TYPE_CMD = 'map_type';  # Override the Type
1210
1211 my $NO = 0;
1212 my $YES = 1;
1213
1214 # Values for the Replace argument to add_range.
1215 # $NO                      # Don't replace; add only the code points not
1216                            # already present.
1217 my $IF_NOT_EQUIVALENT = 1; # Replace only under certain conditions; details in
1218                            # the comments at the subroutine definition.
1219 my $UNCONDITIONALLY = 2;   # Replace without conditions.
1220 my $MULTIPLE_BEFORE = 4;   # Don't replace, but add a duplicate record if
1221                            # already there
1222 my $MULTIPLE_AFTER = 5;    # Don't replace, but add a duplicate record if
1223                            # already there
1224 my $CROAK = 6;             # Die with an error if is already there
1225
1226 # Flags to give property statuses.  The phrases are to remind maintainers that
1227 # if the flag is changed, the indefinite article referring to it in the
1228 # documentation may need to be as well.
1229 my $NORMAL = "";
1230 my $DEPRECATED = 'D';
1231 my $a_bold_deprecated = "a 'B<$DEPRECATED>'";
1232 my $A_bold_deprecated = "A 'B<$DEPRECATED>'";
1233 my $DISCOURAGED = 'X';
1234 my $a_bold_discouraged = "an 'B<$DISCOURAGED>'";
1235 my $A_bold_discouraged = "An 'B<$DISCOURAGED>'";
1236 my $STRICTER = 'T';
1237 my $a_bold_stricter = "a 'B<$STRICTER>'";
1238 my $A_bold_stricter = "A 'B<$STRICTER>'";
1239 my $STABILIZED = 'S';
1240 my $a_bold_stabilized = "an 'B<$STABILIZED>'";
1241 my $A_bold_stabilized = "An 'B<$STABILIZED>'";
1242 my $OBSOLETE = 'O';
1243 my $a_bold_obsolete = "an 'B<$OBSOLETE>'";
1244 my $A_bold_obsolete = "An 'B<$OBSOLETE>'";
1245
1246 # Aliases can also have an extra status:
1247 my $INTERNAL_ALIAS = 'P';
1248
1249 my %status_past_participles = (
1250     $DISCOURAGED => 'discouraged',
1251     $STABILIZED => 'stabilized',
1252     $OBSOLETE => 'obsolete',
1253     $DEPRECATED => 'deprecated',
1254     $INTERNAL_ALIAS => 'reserved for Perl core internal use only',
1255 );
1256
1257 # Table fates.  These are somewhat ordered, so that fates < $MAP_PROXIED should be
1258 # externally documented.
1259 my $ORDINARY = 0;       # The normal fate.
1260 my $MAP_PROXIED = 1;    # The map table for the property isn't written out,
1261                         # but there is a file written that can be used to
1262                         # reconstruct this table
1263 my $INTERNAL_ONLY = 2;  # The file for this table is written out, but it is
1264                         # for Perl's internal use only
1265 my $LEGACY_ONLY = 3;    # Like $INTERNAL_ONLY, but not actually used by Perl.
1266                         # Is for backwards compatibility for applications that
1267                         # read the file directly, so it's format is
1268                         # unchangeable.
1269 my $SUPPRESSED = 4;     # The file for this table is not written out, and as a
1270                         # result, we don't bother to do many computations on
1271                         # it.
1272 my $PLACEHOLDER = 5;    # Like $SUPPRESSED, but we go through all the
1273                         # computations anyway, as the values are needed for
1274                         # things to work.  This happens when we have Perl
1275                         # extensions that depend on Unicode tables that
1276                         # wouldn't normally be in a given Unicode version.
1277
1278 # The format of the values of the tables:
1279 my $EMPTY_FORMAT = "";
1280 my $BINARY_FORMAT = 'b';
1281 my $DECIMAL_FORMAT = 'd';
1282 my $FLOAT_FORMAT = 'f';
1283 my $INTEGER_FORMAT = 'i';
1284 my $HEX_FORMAT = 'x';
1285 my $RATIONAL_FORMAT = 'r';
1286 my $STRING_FORMAT = 's';
1287 my $ADJUST_FORMAT = 'a';
1288 my $HEX_ADJUST_FORMAT = 'ax';
1289 my $DECOMP_STRING_FORMAT = 'c';
1290 my $STRING_WHITE_SPACE_LIST = 'sw';
1291
1292 my %map_table_formats = (
1293     $BINARY_FORMAT => 'binary',
1294     $DECIMAL_FORMAT => 'single decimal digit',
1295     $FLOAT_FORMAT => 'floating point number',
1296     $INTEGER_FORMAT => 'integer',
1297     $HEX_FORMAT => 'non-negative hex whole number; a code point',
1298     $RATIONAL_FORMAT => 'rational: an integer or a fraction',
1299     $STRING_FORMAT => 'string',
1300     $ADJUST_FORMAT => 'some entries need adjustment',
1301     $HEX_ADJUST_FORMAT => 'mapped value in hex; some entries need adjustment',
1302     $DECOMP_STRING_FORMAT => 'Perl\'s internal (Normalize.pm) decomposition mapping',
1303     $STRING_WHITE_SPACE_LIST => 'string, but some elements are interpreted as a list; white space occurs only as list item separators'
1304 );
1305
1306 # Unicode didn't put such derived files in a separate directory at first.
1307 my $EXTRACTED_DIR = (-d 'extracted') ? 'extracted' : "";
1308 my $EXTRACTED = ($EXTRACTED_DIR) ? "$EXTRACTED_DIR/" : "";
1309 my $AUXILIARY = 'auxiliary';
1310
1311 # Hashes and arrays that will eventually go into Heavy.pl for the use of
1312 # utf8_heavy.pl and into UCD.pl for the use of UCD.pm
1313 my %loose_to_file_of;       # loosely maps table names to their respective
1314                             # files
1315 my %stricter_to_file_of;    # same; but for stricter mapping.
1316 my %loose_property_to_file_of; # Maps a loose property name to its map file
1317 my %strict_property_to_file_of; # Same, but strict
1318 my @inline_definitions = "V0"; # Each element gives a definition of a unique
1319                             # inversion list.  When a definition is inlined,
1320                             # its value in the hash it's in (one of the two
1321                             # defined just above) will include an index into
1322                             # this array.  The 0th element is initialized to
1323                             # the definition for a zero length inversion list
1324 my %file_to_swash_name;     # Maps the file name to its corresponding key name
1325                             # in the hash %utf8::SwashInfo
1326 my %nv_floating_to_rational; # maps numeric values floating point numbers to
1327                              # their rational equivalent
1328 my %loose_property_name_of; # Loosely maps (non_string) property names to
1329                             # standard form
1330 my %strict_property_name_of; # Strictly maps (non_string) property names to
1331                             # standard form
1332 my %string_property_loose_to_name; # Same, for string properties.
1333 my %loose_defaults;         # keys are of form "prop=value", where 'prop' is
1334                             # the property name in standard loose form, and
1335                             # 'value' is the default value for that property,
1336                             # also in standard loose form.
1337 my %loose_to_standard_value; # loosely maps table names to the canonical
1338                             # alias for them
1339 my %ambiguous_names;        # keys are alias names (in standard form) that
1340                             # have more than one possible meaning.
1341 my %combination_property;   # keys are alias names (in standard form) that
1342                             # have both a map table, and a binary one that
1343                             # yields true for all non-null maps.
1344 my %prop_aliases;           # Keys are standard property name; values are each
1345                             # one's aliases
1346 my %prop_value_aliases;     # Keys of top level are standard property name;
1347                             # values are keys to another hash,  Each one is
1348                             # one of the property's values, in standard form.
1349                             # The values are that prop-val's aliases.
1350 my %skipped_files;          # List of files that we skip
1351 my %ucd_pod;    # Holds entries that will go into the UCD section of the pod
1352
1353 # Most properties are immune to caseless matching, otherwise you would get
1354 # nonsensical results, as properties are a function of a code point, not
1355 # everything that is caselessly equivalent to that code point.  For example,
1356 # Changes_When_Case_Folded('s') should be false, whereas caselessly it would
1357 # be true because 's' and 'S' are equivalent caselessly.  However,
1358 # traditionally, [:upper:] and [:lower:] are equivalent caselessly, so we
1359 # extend that concept to those very few properties that are like this.  Each
1360 # such property will match the full range caselessly.  They are hard-coded in
1361 # the program; it's not worth trying to make it general as it's extremely
1362 # unlikely that they will ever change.
1363 my %caseless_equivalent_to;
1364
1365 # This is the range of characters that were in Release 1 of Unicode, and
1366 # removed in Release 2 (replaced with the current Hangul syllables starting at
1367 # U+AC00).  The range was reused starting in Release 3 for other purposes.
1368 my $FIRST_REMOVED_HANGUL_SYLLABLE = 0x3400;
1369 my $FINAL_REMOVED_HANGUL_SYLLABLE = 0x4DFF;
1370
1371 # These constants names and values were taken from the Unicode standard,
1372 # version 5.1, section 3.12.  They are used in conjunction with Hangul
1373 # syllables.  The '_string' versions are so generated tables can retain the
1374 # hex format, which is the more familiar value
1375 my $SBase_string = "0xAC00";
1376 my $SBase = CORE::hex $SBase_string;
1377 my $LBase_string = "0x1100";
1378 my $LBase = CORE::hex $LBase_string;
1379 my $VBase_string = "0x1161";
1380 my $VBase = CORE::hex $VBase_string;
1381 my $TBase_string = "0x11A7";
1382 my $TBase = CORE::hex $TBase_string;
1383 my $SCount = 11172;
1384 my $LCount = 19;
1385 my $VCount = 21;
1386 my $TCount = 28;
1387 my $NCount = $VCount * $TCount;
1388
1389 # For Hangul syllables;  These store the numbers from Jamo.txt in conjunction
1390 # with the above published constants.
1391 my %Jamo;
1392 my %Jamo_L;     # Leading consonants
1393 my %Jamo_V;     # Vowels
1394 my %Jamo_T;     # Trailing consonants
1395
1396 # For code points whose name contains its ordinal as a '-ABCD' suffix.
1397 # The key is the base name of the code point, and the value is an
1398 # array giving all the ranges that use this base name.  Each range
1399 # is actually a hash giving the 'low' and 'high' values of it.
1400 my %names_ending_in_code_point;
1401 my %loose_names_ending_in_code_point;   # Same as above, but has blanks, dashes
1402                                         # removed from the names
1403 # Inverse mapping.  The list of ranges that have these kinds of
1404 # names.  Each element contains the low, high, and base names in an
1405 # anonymous hash.
1406 my @code_points_ending_in_code_point;
1407
1408 # To hold Unicode's normalization test suite
1409 my @normalization_tests;
1410
1411 # Boolean: does this Unicode version have the hangul syllables, and are we
1412 # writing out a table for them?
1413 my $has_hangul_syllables = 0;
1414
1415 # Does this Unicode version have code points whose names end in their
1416 # respective code points, and are we writing out a table for them?  0 for no;
1417 # otherwise points to first property that a table is needed for them, so that
1418 # if multiple tables are needed, we don't create duplicates
1419 my $needing_code_points_ending_in_code_point = 0;
1420
1421 my @backslash_X_tests;     # List of tests read in for testing \X
1422 my @LB_tests;              # List of tests read in for testing \b{lb}
1423 my @SB_tests;              # List of tests read in for testing \b{sb}
1424 my @WB_tests;              # List of tests read in for testing \b{wb}
1425 my @unhandled_properties;  # Will contain a list of properties found in
1426                            # the input that we didn't process.
1427 my @match_properties;      # Properties that have match tables, to be
1428                            # listed in the pod
1429 my @map_properties;        # Properties that get map files written
1430 my @named_sequences;       # NamedSequences.txt contents.
1431 my %potential_files;       # Generated list of all .txt files in the directory
1432                            # structure so we can warn if something is being
1433                            # ignored.
1434 my @missing_early_files;   # Generated list of absent files that we need to
1435                            # proceed in compiling this early Unicode version
1436 my @files_actually_output; # List of files we generated.
1437 my @more_Names;            # Some code point names are compound; this is used
1438                            # to store the extra components of them.
1439 my $MIN_FRACTION_LENGTH = 3; # How many digits of a floating point number at
1440                            # the minimum before we consider it equivalent to a
1441                            # candidate rational
1442 my $MAX_FLOATING_SLOP = 10 ** - $MIN_FRACTION_LENGTH; # And in floating terms
1443
1444 # These store references to certain commonly used property objects
1445 my $age;
1446 my $ccc;
1447 my $gc;
1448 my $perl;
1449 my $block;
1450 my $perl_charname;
1451 my $print;
1452 my $All;
1453 my $Assigned;   # All assigned characters in this Unicode release
1454 my $DI;         # Default_Ignorable_Code_Point property
1455 my $NChar;      # Noncharacter_Code_Point property
1456 my $script;
1457
1458 # Are there conflicting names because of beginning with 'In_', or 'Is_'
1459 my $has_In_conflicts = 0;
1460 my $has_Is_conflicts = 0;
1461
1462 sub internal_file_to_platform ($) {
1463     # Convert our file paths which have '/' separators to those of the
1464     # platform.
1465
1466     my $file = shift;
1467     return undef unless defined $file;
1468
1469     return File::Spec->join(split '/', $file);
1470 }
1471
1472 sub file_exists ($) {   # platform independent '-e'.  This program internally
1473                         # uses slash as a path separator.
1474     my $file = shift;
1475     return 0 if ! defined $file;
1476     return -e internal_file_to_platform($file);
1477 }
1478
1479 sub objaddr($) {
1480     # Returns the address of the blessed input object.
1481     # It doesn't check for blessedness because that would do a string eval
1482     # every call, and the program is structured so that this is never called
1483     # for a non-blessed object.
1484
1485     no overloading; # If overloaded, numifying below won't work.
1486
1487     # Numifying a ref gives its address.
1488     return pack 'J', $_[0];
1489 }
1490
1491 # These are used only if $annotate is true.
1492 # The entire range of Unicode characters is examined to populate these
1493 # after all the input has been processed.  But most can be skipped, as they
1494 # have the same descriptive phrases, such as being unassigned
1495 my @viacode;            # Contains the 1 million character names
1496 my @age;                # And their ages ("" if none)
1497 my @printable;          # boolean: And are those characters printable?
1498 my @annotate_char_type; # Contains a type of those characters, specifically
1499                         # for the purposes of annotation.
1500 my $annotate_ranges;    # A map of ranges of code points that have the same
1501                         # name for the purposes of annotation.  They map to the
1502                         # upper edge of the range, so that the end point can
1503                         # be immediately found.  This is used to skip ahead to
1504                         # the end of a range, and avoid processing each
1505                         # individual code point in it.
1506 my $unassigned_sans_noncharacters; # A Range_List of the unassigned
1507                                    # characters, but excluding those which are
1508                                    # also noncharacter code points
1509
1510 # The annotation types are an extension of the regular range types, though
1511 # some of the latter are folded into one.  Make the new types negative to
1512 # avoid conflicting with the regular types
1513 my $SURROGATE_TYPE = -1;
1514 my $UNASSIGNED_TYPE = -2;
1515 my $PRIVATE_USE_TYPE = -3;
1516 my $NONCHARACTER_TYPE = -4;
1517 my $CONTROL_TYPE = -5;
1518 my $ABOVE_UNICODE_TYPE = -6;
1519 my $UNKNOWN_TYPE = -7;  # Used only if there is a bug in this program
1520
1521 sub populate_char_info ($) {
1522     # Used only with the $annotate option.  Populates the arrays with the
1523     # input code point's info that are needed for outputting more detailed
1524     # comments.  If calling context wants a return, it is the end point of
1525     # any contiguous range of characters that share essentially the same info
1526
1527     my $i = shift;
1528     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1529
1530     $viacode[$i] = $perl_charname->value_of($i) || "";
1531     $age[$i] = (defined $age)
1532                ? (($age->value_of($i) =~ / ^ \d+ \. \d+ $ /x)
1533                   ? $age->value_of($i)
1534                   : "")
1535                : "";
1536
1537     # A character is generally printable if Unicode says it is,
1538     # but below we make sure that most Unicode general category 'C' types
1539     # aren't.
1540     $printable[$i] = $print->contains($i);
1541
1542     # But the characters in this range were removed in v2.0 and replaced by
1543     # different ones later.  Modern fonts will be for the replacement
1544     # characters, so suppress printing them.
1545     if (($v_version lt v2.0
1546          || ($compare_versions && $compare_versions lt v2.0))
1547         && (   $i >= $FIRST_REMOVED_HANGUL_SYLLABLE
1548             && $i <= $FINAL_REMOVED_HANGUL_SYLLABLE))
1549     {
1550         $printable[$i] = 0;
1551     }
1552
1553     $annotate_char_type[$i] = $perl_charname->type_of($i) || 0;
1554
1555     # Only these two regular types are treated specially for annotations
1556     # purposes
1557     $annotate_char_type[$i] = 0 if $annotate_char_type[$i] != $CP_IN_NAME
1558                                 && $annotate_char_type[$i] != $HANGUL_SYLLABLE;
1559
1560     # Give a generic name to all code points that don't have a real name.
1561     # We output ranges, if applicable, for these.  Also calculate the end
1562     # point of the range.
1563     my $end;
1564     if (! $viacode[$i]) {
1565         if ($i > $MAX_UNICODE_CODEPOINT) {
1566             $viacode[$i] = 'Above-Unicode';
1567             $annotate_char_type[$i] = $ABOVE_UNICODE_TYPE;
1568             $printable[$i] = 0;
1569             $end = $MAX_WORKING_CODEPOINT;
1570         }
1571         elsif ($gc-> table('Private_use')->contains($i)) {
1572             $viacode[$i] = 'Private Use';
1573             $annotate_char_type[$i] = $PRIVATE_USE_TYPE;
1574             $printable[$i] = 0;
1575             $end = $gc->table('Private_Use')->containing_range($i)->end;
1576         }
1577         elsif ($NChar->contains($i)) {
1578             $viacode[$i] = 'Noncharacter';
1579             $annotate_char_type[$i] = $NONCHARACTER_TYPE;
1580             $printable[$i] = 0;
1581             $end = $NChar->containing_range($i)->end;
1582         }
1583         elsif ($gc-> table('Control')->contains($i)) {
1584             my $name_ref = property_ref('Name_Alias');
1585             $name_ref = property_ref('Unicode_1_Name') if ! defined $name_ref;
1586             $viacode[$i] = (defined $name_ref)
1587                            ? $name_ref->value_of($i)
1588                            : 'Control';
1589             $annotate_char_type[$i] = $CONTROL_TYPE;
1590             $printable[$i] = 0;
1591         }
1592         elsif ($gc-> table('Unassigned')->contains($i)) {
1593             $annotate_char_type[$i] = $UNASSIGNED_TYPE;
1594             $printable[$i] = 0;
1595             $viacode[$i] = 'Unassigned';
1596
1597             if (defined $block) { # No blocks in earliest releases
1598                 $viacode[$i] .= ', block=' . $block-> value_of($i);
1599                 $end = $gc-> table('Unassigned')->containing_range($i)->end;
1600
1601                 # Because we name the unassigned by the blocks they are in, it
1602                 # can't go past the end of that block, and it also can't go
1603                 # past the unassigned range it is in.  The special table makes
1604                 # sure that the non-characters, which are unassigned, are
1605                 # separated out.
1606                 $end = min($block->containing_range($i)->end,
1607                            $unassigned_sans_noncharacters->
1608                                                     containing_range($i)->end);
1609             }
1610             else {
1611                 $end = $i + 1;
1612                 while ($unassigned_sans_noncharacters->contains($end)) {
1613                     $end++;
1614                 }
1615                 $end--;
1616             }
1617         }
1618         elsif ($perl->table('_Perl_Surrogate')->contains($i)) {
1619             $viacode[$i] = 'Surrogate';
1620             $annotate_char_type[$i] = $SURROGATE_TYPE;
1621             $printable[$i] = 0;
1622             $end = $gc->table('Surrogate')->containing_range($i)->end;
1623         }
1624         else {
1625             Carp::my_carp_bug("Can't figure out how to annotate "
1626                               . sprintf("U+%04X", $i)
1627                               . ".  Proceeding anyway.");
1628             $viacode[$i] = 'UNKNOWN';
1629             $annotate_char_type[$i] = $UNKNOWN_TYPE;
1630             $printable[$i] = 0;
1631         }
1632     }
1633
1634     # Here, has a name, but if it's one in which the code point number is
1635     # appended to the name, do that.
1636     elsif ($annotate_char_type[$i] == $CP_IN_NAME) {
1637         $viacode[$i] .= sprintf("-%04X", $i);
1638
1639         my $limit = $perl_charname->containing_range($i)->end;
1640         if (defined $age) {
1641             # Do all these as groups of the same age, instead of individually,
1642             # because their names are so meaningless, and there are typically
1643             # large quantities of them.
1644             $end = $i + 1;
1645             while ($end <= $limit && $age->value_of($end) == $age[$i]) {
1646                 $end++;
1647             }
1648             $end--;
1649         }
1650         else {
1651             $end = $limit;
1652         }
1653     }
1654
1655     # And here, has a name, but if it's a hangul syllable one, replace it with
1656     # the correct name from the Unicode algorithm
1657     elsif ($annotate_char_type[$i] == $HANGUL_SYLLABLE) {
1658         use integer;
1659         my $SIndex = $i - $SBase;
1660         my $L = $LBase + $SIndex / $NCount;
1661         my $V = $VBase + ($SIndex % $NCount) / $TCount;
1662         my $T = $TBase + $SIndex % $TCount;
1663         $viacode[$i] = "HANGUL SYLLABLE $Jamo{$L}$Jamo{$V}";
1664         $viacode[$i] .= $Jamo{$T} if $T != $TBase;
1665         $end = $perl_charname->containing_range($i)->end;
1666     }
1667
1668     return if ! defined wantarray;
1669     return $i if ! defined $end;    # If not a range, return the input
1670
1671     # Save this whole range so can find the end point quickly
1672     $annotate_ranges->add_map($i, $end, $end);
1673
1674     return $end;
1675 }
1676
1677 # Commented code below should work on Perl 5.8.
1678 ## This 'require' doesn't necessarily work in miniperl, and even if it does,
1679 ## the native perl version of it (which is what would operate under miniperl)
1680 ## is extremely slow, as it does a string eval every call.
1681 #my $has_fast_scalar_util = $^X !~ /miniperl/
1682 #                            && defined eval "require Scalar::Util";
1683 #
1684 #sub objaddr($) {
1685 #    # Returns the address of the blessed input object.  Uses the XS version if
1686 #    # available.  It doesn't check for blessedness because that would do a
1687 #    # string eval every call, and the program is structured so that this is
1688 #    # never called for a non-blessed object.
1689 #
1690 #    return Scalar::Util::refaddr($_[0]) if $has_fast_scalar_util;
1691 #
1692 #    # Check at least that is a ref.
1693 #    my $pkg = ref($_[0]) or return undef;
1694 #
1695 #    # Change to a fake package to defeat any overloaded stringify
1696 #    bless $_[0], 'main::Fake';
1697 #
1698 #    # Numifying a ref gives its address.
1699 #    my $addr = pack 'J', $_[0];
1700 #
1701 #    # Return to original class
1702 #    bless $_[0], $pkg;
1703 #    return $addr;
1704 #}
1705
1706 sub max ($$) {
1707     my $a = shift;
1708     my $b = shift;
1709     return $a if $a >= $b;
1710     return $b;
1711 }
1712
1713 sub min ($$) {
1714     my $a = shift;
1715     my $b = shift;
1716     return $a if $a <= $b;
1717     return $b;
1718 }
1719
1720 sub clarify_number ($) {
1721     # This returns the input number with underscores inserted every 3 digits
1722     # in large (5 digits or more) numbers.  Input must be entirely digits, not
1723     # checked.
1724
1725     my $number = shift;
1726     my $pos = length($number) - 3;
1727     return $number if $pos <= 1;
1728     while ($pos > 0) {
1729         substr($number, $pos, 0) = '_';
1730         $pos -= 3;
1731     }
1732     return $number;
1733 }
1734
1735 sub clarify_code_point_count ($) {
1736     # This is like clarify_number(), but the input is assumed to be a count of
1737     # code points, rather than a generic number.
1738
1739     my $append = "";
1740
1741     my $number = shift;
1742     if ($number > $MAX_UNICODE_CODEPOINTS) {
1743         $number -= ($MAX_WORKING_CODEPOINTS - $MAX_UNICODE_CODEPOINTS);
1744         return "All above-Unicode code points" if $number == 0;
1745         $append = " + all above-Unicode code points";
1746     }
1747     return clarify_number($number) . $append;
1748 }
1749
1750 package Carp;
1751
1752 # These routines give a uniform treatment of messages in this program.  They
1753 # are placed in the Carp package to cause the stack trace to not include them,
1754 # although an alternative would be to use another package and set @CARP_NOT
1755 # for it.
1756
1757 our $Verbose = 1 if main::DEBUG;  # Useful info when debugging
1758
1759 # This is a work-around suggested by Nicholas Clark to fix a problem with Carp
1760 # and overload trying to load Scalar:Util under miniperl.  See
1761 # http://www.xray.mpe.mpg.de/mailing-lists/perl5-porters/2009-11/msg01057.html
1762 undef $overload::VERSION;
1763
1764 sub my_carp {
1765     my $message = shift || "";
1766     my $nofold = shift || 0;
1767
1768     if ($message) {
1769         $message = main::join_lines($message);
1770         $message =~ s/^$0: *//;     # Remove initial program name
1771         $message =~ s/[.;,]+$//;    # Remove certain ending punctuation
1772         $message = "\n$0: $message;";
1773
1774         # Fold the message with program name, semi-colon end punctuation
1775         # (which looks good with the message that carp appends to it), and a
1776         # hanging indent for continuation lines.
1777         $message = main::simple_fold($message, "", 4) unless $nofold;
1778         $message =~ s/\n$//;        # Remove the trailing nl so what carp
1779                                     # appends is to the same line
1780     }
1781
1782     return $message if defined wantarray;   # If a caller just wants the msg
1783
1784     carp $message;
1785     return;
1786 }
1787
1788 sub my_carp_bug {
1789     # This is called when it is clear that the problem is caused by a bug in
1790     # this program.
1791
1792     my $message = shift;
1793     $message =~ s/^$0: *//;
1794     $message = my_carp("Bug in $0.  Please report it by running perlbug or if that is unavailable, by sending email to perbug\@perl.org:\n$message");
1795     carp $message;
1796     return;
1797 }
1798
1799 sub carp_too_few_args {
1800     if (@_ != 2) {
1801         my_carp_bug("Wrong number of arguments: to 'carp_too_few_arguments'.  No action taken.");
1802         return;
1803     }
1804
1805     my $args_ref = shift;
1806     my $count = shift;
1807
1808     my_carp_bug("Need at least $count arguments to "
1809         . (caller 1)[3]
1810         . ".  Instead got: '"
1811         . join ', ', @$args_ref
1812         . "'.  No action taken.");
1813     return;
1814 }
1815
1816 sub carp_extra_args {
1817     my $args_ref = shift;
1818     my_carp_bug("Too many arguments to 'carp_extra_args': (" . join(', ', @_) . ");  Extras ignored.") if @_;
1819
1820     unless (ref $args_ref) {
1821         my_carp_bug("Argument to 'carp_extra_args' ($args_ref) must be a ref.  Not checking arguments.");
1822         return;
1823     }
1824     my ($package, $file, $line) = caller;
1825     my $subroutine = (caller 1)[3];
1826
1827     my $list;
1828     if (ref $args_ref eq 'HASH') {
1829         foreach my $key (keys %$args_ref) {
1830             $args_ref->{$key} = $UNDEF unless defined $args_ref->{$key};
1831         }
1832         $list = join ', ', each %{$args_ref};
1833     }
1834     elsif (ref $args_ref eq 'ARRAY') {
1835         foreach my $arg (@$args_ref) {
1836             $arg = $UNDEF unless defined $arg;
1837         }
1838         $list = join ', ', @$args_ref;
1839     }
1840     else {
1841         my_carp_bug("Can't cope with ref "
1842                 . ref($args_ref)
1843                 . " . argument to 'carp_extra_args'.  Not checking arguments.");
1844         return;
1845     }
1846
1847     my_carp_bug("Unrecognized parameters in options: '$list' to $subroutine.  Skipped.");
1848     return;
1849 }
1850
1851 package main;
1852
1853 { # Closure
1854
1855     # This program uses the inside-out method for objects, as recommended in
1856     # "Perl Best Practices".  (This is the best solution still, since this has
1857     # to run under miniperl.)  This closure aids in generating those.  There
1858     # are two routines.  setup_package() is called once per package to set
1859     # things up, and then set_access() is called for each hash representing a
1860     # field in the object.  These routines arrange for the object to be
1861     # properly destroyed when no longer used, and for standard accessor
1862     # functions to be generated.  If you need more complex accessors, just
1863     # write your own and leave those accesses out of the call to set_access().
1864     # More details below.
1865
1866     my %constructor_fields; # fields that are to be used in constructors; see
1867                             # below
1868
1869     # The values of this hash will be the package names as keys to other
1870     # hashes containing the name of each field in the package as keys, and
1871     # references to their respective hashes as values.
1872     my %package_fields;
1873
1874     sub setup_package {
1875         # Sets up the package, creating standard DESTROY and dump methods
1876         # (unless already defined).  The dump method is used in debugging by
1877         # simple_dumper().
1878         # The optional parameters are:
1879         #   a)  a reference to a hash, that gets populated by later
1880         #       set_access() calls with one of the accesses being
1881         #       'constructor'.  The caller can then refer to this, but it is
1882         #       not otherwise used by these two routines.
1883         #   b)  a reference to a callback routine to call during destruction
1884         #       of the object, before any fields are actually destroyed
1885
1886         my %args = @_;
1887         my $constructor_ref = delete $args{'Constructor_Fields'};
1888         my $destroy_callback = delete $args{'Destroy_Callback'};
1889         Carp::carp_extra_args(\@_) if main::DEBUG && %args;
1890
1891         my %fields;
1892         my $package = (caller)[0];
1893
1894         $package_fields{$package} = \%fields;
1895         $constructor_fields{$package} = $constructor_ref;
1896
1897         unless ($package->can('DESTROY')) {
1898             my $destroy_name = "${package}::DESTROY";
1899             no strict "refs";
1900
1901             # Use typeglob to give the anonymous subroutine the name we want
1902             *$destroy_name = sub {
1903                 my $self = shift;
1904                 my $addr = do { no overloading; pack 'J', $self; };
1905
1906                 $self->$destroy_callback if $destroy_callback;
1907                 foreach my $field (keys %{$package_fields{$package}}) {
1908                     #print STDERR __LINE__, ": Destroying ", ref $self, " ", sprintf("%04X", $addr), ": ", $field, "\n";
1909                     delete $package_fields{$package}{$field}{$addr};
1910                 }
1911                 return;
1912             }
1913         }
1914
1915         unless ($package->can('dump')) {
1916             my $dump_name = "${package}::dump";
1917             no strict "refs";
1918             *$dump_name = sub {
1919                 my $self = shift;
1920                 return dump_inside_out($self, $package_fields{$package}, @_);
1921             }
1922         }
1923         return;
1924     }
1925
1926     sub set_access {
1927         # Arrange for the input field to be garbage collected when no longer
1928         # needed.  Also, creates standard accessor functions for the field
1929         # based on the optional parameters-- none if none of these parameters:
1930         #   'addable'    creates an 'add_NAME()' accessor function.
1931         #   'readable' or 'readable_array'   creates a 'NAME()' accessor
1932         #                function.
1933         #   'settable'   creates a 'set_NAME()' accessor function.
1934         #   'constructor' doesn't create an accessor function, but adds the
1935         #                field to the hash that was previously passed to
1936         #                setup_package();
1937         # Any of the accesses can be abbreviated down, so that 'a', 'ad',
1938         # 'add' etc. all mean 'addable'.
1939         # The read accessor function will work on both array and scalar
1940         # values.  If another accessor in the parameter list is 'a', the read
1941         # access assumes an array.  You can also force it to be array access
1942         # by specifying 'readable_array' instead of 'readable'
1943         #
1944         # A sort-of 'protected' access can be set-up by preceding the addable,
1945         # readable or settable with some initial portion of 'protected_' (but,
1946         # the underscore is required), like 'p_a', 'pro_set', etc.  The
1947         # "protection" is only by convention.  All that happens is that the
1948         # accessor functions' names begin with an underscore.  So instead of
1949         # calling set_foo, the call is _set_foo.  (Real protection could be
1950         # accomplished by having a new subroutine, end_package, called at the
1951         # end of each package, and then storing the __LINE__ ranges and
1952         # checking them on every accessor.  But that is way overkill.)
1953
1954         # We create anonymous subroutines as the accessors and then use
1955         # typeglobs to assign them to the proper package and name
1956
1957         my $name = shift;   # Name of the field
1958         my $field = shift;  # Reference to the inside-out hash containing the
1959                             # field
1960
1961         my $package = (caller)[0];
1962
1963         if (! exists $package_fields{$package}) {
1964             croak "$0: Must call 'setup_package' before 'set_access'";
1965         }
1966
1967         # Stash the field so DESTROY can get it.
1968         $package_fields{$package}{$name} = $field;
1969
1970         # Remaining arguments are the accessors.  For each...
1971         foreach my $access (@_) {
1972             my $access = lc $access;
1973
1974             my $protected = "";
1975
1976             # Match the input as far as it goes.
1977             if ($access =~ /^(p[^_]*)_/) {
1978                 $protected = $1;
1979                 if (substr('protected_', 0, length $protected)
1980                     eq $protected)
1981                 {
1982
1983                     # Add 1 for the underscore not included in $protected
1984                     $access = substr($access, length($protected) + 1);
1985                     $protected = '_';
1986                 }
1987                 else {
1988                     $protected = "";
1989                 }
1990             }
1991
1992             if (substr('addable', 0, length $access) eq $access) {
1993                 my $subname = "${package}::${protected}add_$name";
1994                 no strict "refs";
1995
1996                 # add_ accessor.  Don't add if already there, which we
1997                 # determine using 'eq' for scalars and '==' otherwise.
1998                 *$subname = sub {
1999                     use strict "refs";
2000                     return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
2001                     my $self = shift;
2002                     my $value = shift;
2003                     my $addr = do { no overloading; pack 'J', $self; };
2004                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2005                     if (ref $value) {
2006                         return if grep { $value == $_ } @{$field->{$addr}};
2007                     }
2008                     else {
2009                         return if grep { $value eq $_ } @{$field->{$addr}};
2010                     }
2011                     push @{$field->{$addr}}, $value;
2012                     return;
2013                 }
2014             }
2015             elsif (substr('constructor', 0, length $access) eq $access) {
2016                 if ($protected) {
2017                     Carp::my_carp_bug("Can't set-up 'protected' constructors")
2018                 }
2019                 else {
2020                     $constructor_fields{$package}{$name} = $field;
2021                 }
2022             }
2023             elsif (substr('readable_array', 0, length $access) eq $access) {
2024
2025                 # Here has read access.  If one of the other parameters for
2026                 # access is array, or this one specifies array (by being more
2027                 # than just 'readable_'), then create a subroutine that
2028                 # assumes the data is an array.  Otherwise just a scalar
2029                 my $subname = "${package}::${protected}$name";
2030                 if (grep { /^a/i } @_
2031                     or length($access) > length('readable_'))
2032                 {
2033                     no strict "refs";
2034                     *$subname = sub {
2035                         use strict "refs";
2036                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
2037                         my $addr = do { no overloading; pack 'J', $_[0]; };
2038                         if (ref $field->{$addr} ne 'ARRAY') {
2039                             my $type = ref $field->{$addr};
2040                             $type = 'scalar' unless $type;
2041                             Carp::my_carp_bug("Trying to read $name as an array when it is a $type.  Big problems.");
2042                             return;
2043                         }
2044                         return scalar @{$field->{$addr}} unless wantarray;
2045
2046                         # Make a copy; had problems with caller modifying the
2047                         # original otherwise
2048                         my @return = @{$field->{$addr}};
2049                         return @return;
2050                     }
2051                 }
2052                 else {
2053
2054                     # Here not an array value, a simpler function.
2055                     no strict "refs";
2056                     *$subname = sub {
2057                         use strict "refs";
2058                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
2059                         no overloading;
2060                         return $field->{pack 'J', $_[0]};
2061                     }
2062                 }
2063             }
2064             elsif (substr('settable', 0, length $access) eq $access) {
2065                 my $subname = "${package}::${protected}set_$name";
2066                 no strict "refs";
2067                 *$subname = sub {
2068                     use strict "refs";
2069                     if (main::DEBUG) {
2070                         return Carp::carp_too_few_args(\@_, 2) if @_ < 2;
2071                         Carp::carp_extra_args(\@_) if @_ > 2;
2072                     }
2073                     # $self is $_[0]; $value is $_[1]
2074                     no overloading;
2075                     $field->{pack 'J', $_[0]} = $_[1];
2076                     return;
2077                 }
2078             }
2079             else {
2080                 Carp::my_carp_bug("Unknown accessor type $access.  No accessor set.");
2081             }
2082         }
2083         return;
2084     }
2085 }
2086
2087 package Input_file;
2088
2089 # All input files use this object, which stores various attributes about them,
2090 # and provides for convenient, uniform handling.  The run method wraps the
2091 # processing.  It handles all the bookkeeping of opening, reading, and closing
2092 # the file, returning only significant input lines.
2093 #
2094 # Each object gets a handler which processes the body of the file, and is
2095 # called by run().  All character property files must use the generic,
2096 # default handler, which has code scrubbed to handle things you might not
2097 # expect, including automatic EBCDIC handling.  For files that don't deal with
2098 # mapping code points to a property value, such as test files,
2099 # PropertyAliases, PropValueAliases, and named sequences, you can override the
2100 # handler to be a custom one.  Such a handler should basically be a
2101 # while(next_line()) {...} loop.
2102 #
2103 # You can also set up handlers to
2104 #   0) call during object construction time, after everything else is done
2105 #   1) call before the first line is read, for pre processing
2106 #   2) call to adjust each line of the input before the main handler gets
2107 #      them.  This can be automatically generated, if appropriately simple
2108 #      enough, by specifying a Properties parameter in the constructor.
2109 #   3) call upon EOF before the main handler exits its loop
2110 #   4) call at the end, for post processing
2111 #
2112 # $_ is used to store the input line, and is to be filtered by the
2113 # each_line_handler()s.  So, if the format of the line is not in the desired
2114 # format for the main handler, these are used to do that adjusting.  They can
2115 # be stacked (by enclosing them in an [ anonymous array ] in the constructor,
2116 # so the $_ output of one is used as the input to the next.  The EOF handler
2117 # is also stackable, but none of the others are, but could easily be changed
2118 # to be so.
2119 #
2120 # Some properties are used by the Perl core but aren't defined until later
2121 # Unicode releases.  The perl interpreter would have problems working when
2122 # compiled with an earlier Unicode version that doesn't have them, so we need
2123 # to define them somehow for those releases.  The 'Early' constructor
2124 # parameter can be used to automatically handle this.  It is essentially
2125 # ignored if the Unicode version being compiled has a data file for this
2126 # property.  Either code to execute or a file to read can be specified.
2127 # Details are at the %early definition.
2128 #
2129 # Most of the handlers can call insert_lines() or insert_adjusted_lines()
2130 # which insert the parameters as lines to be processed before the next input
2131 # file line is read.  This allows the EOF handler(s) to flush buffers, for
2132 # example.  The difference between the two routines is that the lines inserted
2133 # by insert_lines() are subjected to the each_line_handler()s.  (So if you
2134 # called it from such a handler, you would get infinite recursion without some
2135 # mechanism to prevent that.)  Lines inserted by insert_adjusted_lines() go
2136 # directly to the main handler without any adjustments.  If the
2137 # post-processing handler calls any of these, there will be no effect.  Some
2138 # error checking for these conditions could be added, but it hasn't been done.
2139 #
2140 # carp_bad_line() should be called to warn of bad input lines, which clears $_
2141 # to prevent further processing of the line.  This routine will output the
2142 # message as a warning once, and then keep a count of the lines that have the
2143 # same message, and output that count at the end of the file's processing.
2144 # This keeps the number of messages down to a manageable amount.
2145 #
2146 # get_missings() should be called to retrieve any @missing input lines.
2147 # Messages will be raised if this isn't done if the options aren't to ignore
2148 # missings.
2149
2150 sub trace { return main::trace(@_); }
2151
2152 { # Closure
2153     # Keep track of fields that are to be put into the constructor.
2154     my %constructor_fields;
2155
2156     main::setup_package(Constructor_Fields => \%constructor_fields);
2157
2158     my %file; # Input file name, required
2159     main::set_access('file', \%file, qw{ c r });
2160
2161     my %first_released; # Unicode version file was first released in, required
2162     main::set_access('first_released', \%first_released, qw{ c r });
2163
2164     my %handler;    # Subroutine to process the input file, defaults to
2165                     # 'process_generic_property_file'
2166     main::set_access('handler', \%handler, qw{ c });
2167
2168     my %property;
2169     # name of property this file is for.  defaults to none, meaning not
2170     # applicable, or is otherwise determinable, for example, from each line.
2171     main::set_access('property', \%property, qw{ c r });
2172
2173     my %optional;
2174     # This is either an unsigned number, or a list of property names.  In the
2175     # former case, if it is non-zero, it means the file is optional, so if the
2176     # file is absent, no warning about that is output.  In the latter case, it
2177     # is a list of properties that the file (exclusively) defines.  If the
2178     # file is present, tables for those properties will be produced; if
2179     # absent, none will, even if they are listed elsewhere (namely
2180     # PropertyAliases.txt and PropValueAliases.txt) as being in this release,
2181     # and no warnings will be raised about them not being available.  (And no
2182     # warning about the file itself will be raised.)
2183     main::set_access('optional', \%optional, qw{ c readable_array } );
2184
2185     my %non_skip;
2186     # This is used for debugging, to skip processing of all but a few input
2187     # files.  Add 'non_skip => 1' to the constructor for those files you want
2188     # processed when you set the $debug_skip global.
2189     main::set_access('non_skip', \%non_skip, 'c');
2190
2191     my %skip;
2192     # This is used to skip processing of this input file (semi-) permanently.
2193     # The value should be the reason the file is being skipped.  It is used
2194     # for files that we aren't planning to process anytime soon, but want to
2195     # allow to be in the directory and be checked for their names not
2196     # conflicting with any other files on a DOS 8.3 name filesystem, but to
2197     # not otherwise be processed, and to not raise a warning about not being
2198     # handled.  In the constructor call, any value that evaluates to a numeric
2199     # 0 or undef means don't skip.  Any other value is a string giving the
2200     # reason it is being skipped, and this will appear in generated pod.
2201     # However, an empty string reason will suppress the pod entry.
2202     # Internally, calls that evaluate to numeric 0 are changed into undef to
2203     # distinguish them from an empty string call.
2204     main::set_access('skip', \%skip, 'c', 'r');
2205
2206     my %each_line_handler;
2207     # list of subroutines to look at and filter each non-comment line in the
2208     # file.  defaults to none.  The subroutines are called in order, each is
2209     # to adjust $_ for the next one, and the final one adjusts it for
2210     # 'handler'
2211     main::set_access('each_line_handler', \%each_line_handler, 'c');
2212
2213     my %retain_trailing_comments;
2214     # This is used to not discard the comments that end data lines.  This
2215     # would be used only for files with non-typical syntax, and most code here
2216     # assumes that comments have been stripped, so special handlers would have
2217     # to be written.  It is assumed that the code will use these in
2218     # single-quoted contexts, and so any "'" marks in the comment will be
2219     # prefixed by a backslash.
2220     main::set_access('retain_trailing_comments', \%retain_trailing_comments, 'c');
2221
2222     my %properties; # Optional ordered list of the properties that occur in each
2223     # meaningful line of the input file.  If present, an appropriate
2224     # each_line_handler() is automatically generated and pushed onto the stack
2225     # of such handlers.  This is useful when a file contains multiple
2226     # properties per line, but no other special considerations are necessary.
2227     # The special value "<ignored>" means to discard the corresponding input
2228     # field.
2229     # Any @missing lines in the file should also match this syntax; no such
2230     # files exist as of 6.3.  But if it happens in a future release, the code
2231     # could be expanded to properly parse them.
2232     main::set_access('properties', \%properties, qw{ c r });
2233
2234     my %has_missings_defaults;
2235     # ? Are there lines in the file giving default values for code points
2236     # missing from it?.  Defaults to NO_DEFAULTS.  Otherwise NOT_IGNORED is
2237     # the norm, but IGNORED means it has such lines, but the handler doesn't
2238     # use them.  Having these three states allows us to catch changes to the
2239     # UCD that this program should track.  XXX This could be expanded to
2240     # specify the syntax for such lines, like %properties above.
2241     main::set_access('has_missings_defaults',
2242                                         \%has_missings_defaults, qw{ c r });
2243
2244     my %construction_time_handler;
2245     # Subroutine to call at the end of the new method.  If undef, no such
2246     # handler is called.
2247     main::set_access('construction_time_handler',
2248                                         \%construction_time_handler, qw{ c });
2249
2250     my %pre_handler;
2251     # Subroutine to call before doing anything else in the file.  If undef, no
2252     # such handler is called.
2253     main::set_access('pre_handler', \%pre_handler, qw{ c });
2254
2255     my %eof_handler;
2256     # Subroutines to call upon getting an EOF on the input file, but before
2257     # that is returned to the main handler.  This is to allow buffers to be
2258     # flushed.  The handler is expected to call insert_lines() or
2259     # insert_adjusted() with the buffered material
2260     main::set_access('eof_handler', \%eof_handler, qw{ c });
2261
2262     my %post_handler;
2263     # Subroutine to call after all the lines of the file are read in and
2264     # processed.  If undef, no such handler is called.  Note that this cannot
2265     # add lines to be processed; instead use eof_handler
2266     main::set_access('post_handler', \%post_handler, qw{ c });
2267
2268     my %progress_message;
2269     # Message to print to display progress in lieu of the standard one
2270     main::set_access('progress_message', \%progress_message, qw{ c });
2271
2272     my %handle;
2273     # cache open file handle, internal.  Is undef if file hasn't been
2274     # processed at all, empty if has;
2275     main::set_access('handle', \%handle);
2276
2277     my %added_lines;
2278     # cache of lines added virtually to the file, internal
2279     main::set_access('added_lines', \%added_lines);
2280
2281     my %remapped_lines;
2282     # cache of lines added virtually to the file, internal
2283     main::set_access('remapped_lines', \%remapped_lines);
2284
2285     my %errors;
2286     # cache of errors found, internal
2287     main::set_access('errors', \%errors);
2288
2289     my %missings;
2290     # storage of '@missing' defaults lines
2291     main::set_access('missings', \%missings);
2292
2293     my %early;
2294     # Used for properties that must be defined (for Perl's purposes) on
2295     # versions of Unicode earlier than Unicode itself defines them.  The
2296     # parameter is an array (it would be better to be a hash, but not worth
2297     # bothering about due to its rare use).
2298     #
2299     # The first element is either a code reference to call when in a release
2300     # earlier than the Unicode file is available in, or it is an alternate
2301     # file to use instead of the non-existent one.  This file must have been
2302     # plunked down in the same directory as mktables.  Should you be compiling
2303     # on a release that needs such a file, mktables will abort the
2304     # compilation, and tell you where to get the necessary file(s), and what
2305     # name(s) to use to store them as.
2306     # In the case of specifying an alternate file, the array must contain two
2307     # further elements:
2308     #
2309     # [1] is the name of the property that will be generated by this file.
2310     # The class automatically takes the input file and excludes any code
2311     # points in it that were not assigned in the Unicode version being
2312     # compiled.  It then uses this result to define the property in the given
2313     # version.  Since the property doesn't actually exist in the Unicode
2314     # version being compiled, this should be a name accessible only by core
2315     # perl.  If it is the same name as the regular property, the constructor
2316     # will mark the output table as a $PLACEHOLDER so that it doesn't actually
2317     # get output, and so will be unusable by non-core code.  Otherwise it gets
2318     # marked as $INTERNAL_ONLY.
2319     #
2320     # [2] is a property value to assign (only when compiling Unicode 1.1.5) to
2321     # the Hangul syllables in that release (which were ripped out in version
2322     # 2) for the given property .  (Hence it is ignored except when compiling
2323     # version 1.  You only get one value that applies to all of them, which
2324     # may not be the actual reality, but probably nobody cares anyway for
2325     # these obsolete characters.)
2326     #
2327     # [3] if present is the default value for the property to assign for code
2328     # points not given in the input.  If not present, the default from the
2329     # normal property is used
2330     #
2331     # [-1] If there is an extra final element that is the string 'ONLY_EARLY'.
2332     # it means to not add the name in [1] as an alias to the property name
2333     # used for these.  Normally, when compiling Unicode versions that don't
2334     # invoke the early handling, the name is added as a synonym.
2335     #
2336     # Not all files can be handled in the above way, and so the code ref
2337     # alternative is available.  It can do whatever it needs to.  The other
2338     # array elements are optional in this case, and the code is free to use or
2339     # ignore them if they are present.
2340     #
2341     # Internally, the constructor unshifts a 0 or 1 onto this array to
2342     # indicate if an early alternative is actually being used or not.  This
2343     # makes for easier testing later on.
2344     main::set_access('early', \%early, 'c');
2345
2346     my %only_early;
2347     main::set_access('only_early', \%only_early, 'c');
2348
2349     my %required_even_in_debug_skip;
2350     # debug_skip is used to speed up compilation during debugging by skipping
2351     # processing files that are not needed for the task at hand.  However,
2352     # some files pretty much can never be skipped, and this is used to specify
2353     # that this is one of them.  In order to skip this file, the call to the
2354     # constructor must be edited to comment out this parameter.
2355     main::set_access('required_even_in_debug_skip',
2356                      \%required_even_in_debug_skip, 'c');
2357
2358     my %withdrawn;
2359     # Some files get removed from the Unicode DB.  This is a version object
2360     # giving the first release without this file.
2361     main::set_access('withdrawn', \%withdrawn, 'c');
2362
2363     my %in_this_release;
2364     # Calculated value from %first_released and %withdrawn.  Are we compiling
2365     # a Unicode release which includes this file?
2366     main::set_access('in_this_release', \%in_this_release);
2367
2368     sub _next_line;
2369     sub _next_line_with_remapped_range;
2370
2371     sub new {
2372         my $class = shift;
2373
2374         my $self = bless \do{ my $anonymous_scalar }, $class;
2375         my $addr = do { no overloading; pack 'J', $self; };
2376
2377         # Set defaults
2378         $handler{$addr} = \&main::process_generic_property_file;
2379         $retain_trailing_comments{$addr} = 0;
2380         $non_skip{$addr} = 0;
2381         $skip{$addr} = undef;
2382         $has_missings_defaults{$addr} = $NO_DEFAULTS;
2383         $handle{$addr} = undef;
2384         $added_lines{$addr} = [ ];
2385         $remapped_lines{$addr} = [ ];
2386         $each_line_handler{$addr} = [ ];
2387         $eof_handler{$addr} = [ ];
2388         $errors{$addr} = { };
2389         $missings{$addr} = [ ];
2390         $early{$addr} = [ ];
2391         $optional{$addr} = [ ];
2392
2393         # Two positional parameters.
2394         return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
2395         $file{$addr} = main::internal_file_to_platform(shift);
2396         $first_released{$addr} = shift;
2397
2398         # The rest of the arguments are key => value pairs
2399         # %constructor_fields has been set up earlier to list all possible
2400         # ones.  Either set or push, depending on how the default has been set
2401         # up just above.
2402         my %args = @_;
2403         foreach my $key (keys %args) {
2404             my $argument = $args{$key};
2405
2406             # Note that the fields are the lower case of the constructor keys
2407             my $hash = $constructor_fields{lc $key};
2408             if (! defined $hash) {
2409                 Carp::my_carp_bug("Unrecognized parameters '$key => $argument' to new() for $self.  Skipped");
2410                 next;
2411             }
2412             if (ref $hash->{$addr} eq 'ARRAY') {
2413                 if (ref $argument eq 'ARRAY') {
2414                     foreach my $argument (@{$argument}) {
2415                         next if ! defined $argument;
2416                         push @{$hash->{$addr}}, $argument;
2417                     }
2418                 }
2419                 else {
2420                     push @{$hash->{$addr}}, $argument if defined $argument;
2421                 }
2422             }
2423             else {
2424                 $hash->{$addr} = $argument;
2425             }
2426             delete $args{$key};
2427         };
2428
2429         $non_skip{$addr} = 1 if $required_even_in_debug_skip{$addr};
2430
2431         # Convert 0 (meaning don't skip) to undef
2432         undef $skip{$addr} unless $skip{$addr};
2433
2434         # Handle the case where this file is optional
2435         my $pod_message_for_non_existent_optional = "";
2436         if ($optional{$addr}->@*) {
2437
2438             # First element is the pod message
2439             $pod_message_for_non_existent_optional
2440                                                 = shift $optional{$addr}->@*;
2441             # Convert a 0 'Optional' argument to an empty list to make later
2442             # code more concise.
2443             if (   $optional{$addr}->@*
2444                 && $optional{$addr}->@* == 1
2445                 && $optional{$addr}[0] ne ""
2446                 && $optional{$addr}[0] !~ /\D/
2447                 && $optional{$addr}[0] == 0)
2448             {
2449                 $optional{$addr} = [ ];
2450             }
2451             else {  # But if the only element doesn't evaluate to 0, make sure
2452                     # that this file is indeed considered optional below.
2453                 unshift $optional{$addr}->@*, 1;
2454             }
2455         }
2456
2457         my $progress;
2458         my $function_instead_of_file = 0;
2459
2460         if ($early{$addr}->@* && $early{$addr}[-1] eq 'ONLY_EARLY') {
2461             $only_early{$addr} = 1;
2462             pop $early{$addr}->@*;
2463         }
2464
2465         # If we are compiling a Unicode release earlier than the file became
2466         # available, the constructor may have supplied a substitute
2467         if ($first_released{$addr} gt $v_version && $early{$addr}->@*) {
2468
2469             # Yes, we have a substitute, that we will use; mark it so
2470             unshift $early{$addr}->@*, 1;
2471
2472             # See the definition of %early for what the array elements mean.
2473             # Note that we have just unshifted onto the array, so the numbers
2474             # below are +1 of those in the %early description.
2475             # If we have a property this defines, create a table and default
2476             # map for it now (at essentially compile time), so that it will be
2477             # available for the whole of run time.  (We will want to add this
2478             # name as an alias when we are using the official property name;
2479             # but this must be deferred until run(), because at construction
2480             # time the official names have yet to be defined.)
2481             if ($early{$addr}[2]) {
2482                 my $fate = ($property{$addr}
2483                             && $property{$addr} eq $early{$addr}[2])
2484                           ? $PLACEHOLDER
2485                           : $INTERNAL_ONLY;
2486                 my $prop_object = Property->new($early{$addr}[2],
2487                                                 Fate => $fate,
2488                                                 Perl_Extension => 1,
2489                                                 );
2490
2491                 # If not specified by the constructor, use the default mapping
2492                 # for the regular property for this substitute one.
2493                 if ($early{$addr}[4]) {
2494                     $prop_object->set_default_map($early{$addr}[4]);
2495                 }
2496                 elsif (    defined $property{$addr}
2497                        &&  defined $default_mapping{$property{$addr}})
2498                 {
2499                     $prop_object
2500                         ->set_default_map($default_mapping{$property{$addr}});
2501                 }
2502             }
2503
2504             if (ref $early{$addr}[1] eq 'CODE') {
2505                 $function_instead_of_file = 1;
2506
2507                 # If the first element of the array is a code ref, the others
2508                 # are optional.
2509                 $handler{$addr} = $early{$addr}[1];
2510                 $property{$addr} = $early{$addr}[2]
2511                                                 if defined $early{$addr}[2];
2512                 $progress = "substitute $file{$addr}";
2513
2514                 undef $file{$addr};
2515             }
2516             else {  # Specifying a substitute file
2517
2518                 if (! main::file_exists($early{$addr}[1])) {
2519
2520                     # If we don't see the substitute file, generate an error
2521                     # message giving the needed things, and add it to the list
2522                     # of such to output before actual processing happens
2523                     # (hence the user finds out all of them in one run).
2524                     # Instead of creating a general method for NameAliases,
2525                     # hard-code it here, as there is unlikely to ever be a
2526                     # second one which needs special handling.
2527                     my $string_version = ($file{$addr} eq "NameAliases.txt")
2528                                     ? 'at least 6.1 (the later, the better)'
2529                                     : sprintf "%vd", $first_released{$addr};
2530                     push @missing_early_files, <<END;
2531 '$file{$addr}' version $string_version should be copied to '$early{$addr}[1]'.
2532 END
2533                     ;
2534                     return;
2535                 }
2536                 $progress = $early{$addr}[1];
2537                 $progress .= ", substituting for $file{$addr}" if $file{$addr};
2538                 $file{$addr} = $early{$addr}[1];
2539                 $property{$addr} = $early{$addr}[2];
2540
2541                 # Ignore code points not in the version being compiled
2542                 push $each_line_handler{$addr}->@*, \&_exclude_unassigned;
2543
2544                 if (   $v_version lt v2.0        # Hanguls in this release ...
2545                     && defined $early{$addr}[3]) # ... need special treatment
2546                 {
2547                     push $eof_handler{$addr}->@*, \&_fixup_obsolete_hanguls;
2548                 }
2549             }
2550
2551             # And this substitute is valid for all releases.
2552             $first_released{$addr} = v0;
2553         }
2554         else {  # Normal behavior
2555             $progress = $file{$addr};
2556             unshift $early{$addr}->@*, 0; # No substitute
2557         }
2558
2559         my $file = $file{$addr};
2560         $progress_message{$addr} = "Processing $progress"
2561                                             unless $progress_message{$addr};
2562
2563         # A file should be there if it is within the window of versions for
2564         # which Unicode supplies it
2565         if ($withdrawn{$addr} && $withdrawn{$addr} le $v_version) {
2566             $in_this_release{$addr} = 0;
2567             $skip{$addr} = "";
2568         }
2569         else {
2570             $in_this_release{$addr} = $first_released{$addr} le $v_version;
2571
2572             # Check that the file for this object (possibly using a substitute
2573             # for early releases) exists or we have a function alternative
2574             if (   ! $function_instead_of_file
2575                 && ! main::file_exists($file))
2576             {
2577                 # Here there is nothing available for this release.  This is
2578                 # fine if we aren't expecting anything in this release.
2579                 if (! $in_this_release{$addr}) {
2580                     $skip{$addr} = "";  # Don't remark since we expected
2581                                         # nothing and got nothing
2582                 }
2583                 elsif ($optional{$addr}->@*) {
2584
2585                     # Here the file is optional in this release; Use the
2586                     # passed in text to document this case in the pod.
2587                     $skip{$addr} = $pod_message_for_non_existent_optional;
2588                 }
2589                 elsif (   $in_this_release{$addr}
2590                        && ! defined $skip{$addr}
2591                        && defined $file)
2592                 { # Doesn't exist but should.
2593                     $skip{$addr} = "'$file' not found.  Possibly Big problems";
2594                     Carp::my_carp($skip{$addr});
2595                 }
2596             }
2597             elsif ($debug_skip && ! defined $skip{$addr} && ! $non_skip{$addr})
2598             {
2599
2600                 # The file exists; if not skipped for another reason, and we are
2601                 # skipping most everything during debugging builds, use that as
2602                 # the skip reason.
2603                 $skip{$addr} = '$debug_skip is on'
2604             }
2605         }
2606
2607         if (   ! $debug_skip
2608             && $non_skip{$addr}
2609             && ! $required_even_in_debug_skip{$addr}
2610             && $verbosity)
2611         {
2612             print "Warning: " . __PACKAGE__ . " constructor for $file has useless 'non_skip' in it\n";
2613         }
2614
2615         # Here, we have figured out if we will be skipping this file or not.
2616         # If so, we add any single property it defines to any passed in
2617         # optional property list.  These will be dealt with at run time.
2618         if (defined $skip{$addr}) {
2619             if ($property{$addr}) {
2620                 push $optional{$addr}->@*, $property{$addr};
2621             }
2622         } # Otherwise, are going to process the file.
2623         elsif ($property{$addr}) {
2624
2625             # If the file has a property defined in the constructor for it, it
2626             # means that the property is not listed in the file's entries.  So
2627             # add a handler (to the list of line handlers) to insert the
2628             # property name into the lines, to provide a uniform interface to
2629             # the final processing subroutine.
2630             push @{$each_line_handler{$addr}}, \&_insert_property_into_line;
2631         }
2632         elsif ($properties{$addr}) {
2633
2634             # Similarly, there may be more than one property represented on
2635             # each line, with no clue but the constructor input what those
2636             # might be.  Add a handler for each line in the input so that it
2637             # creates a separate input line for each property in those input
2638             # lines, thus making them suitable to handle generically.
2639
2640             push @{$each_line_handler{$addr}},
2641                  sub {
2642                     my $file = shift;
2643                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2644
2645                     my @fields = split /\s*;\s*/, $_, -1;
2646
2647                     if (@fields - 1 > @{$properties{$addr}}) {
2648                         $file->carp_bad_line('Extra fields');
2649                         $_ = "";
2650                         return;
2651                     }
2652                     my $range = shift @fields;  # 0th element is always the
2653                                                 # range
2654
2655                     # The next fields in the input line correspond
2656                     # respectively to the stored properties.
2657                     for my $i (0 ..  @{$properties{$addr}} - 1) {
2658                         my $property_name = $properties{$addr}[$i];
2659                         next if $property_name eq '<ignored>';
2660                         $file->insert_adjusted_lines(
2661                               "$range; $property_name; $fields[$i]");
2662                     }
2663                     $_ = "";
2664
2665                     return;
2666                 };
2667         }
2668
2669         {   # On non-ascii platforms, we use a special pre-handler
2670             no strict;
2671             no warnings 'once';
2672             *next_line = (main::NON_ASCII_PLATFORM)
2673                          ? *_next_line_with_remapped_range
2674                          : *_next_line;
2675         }
2676
2677         &{$construction_time_handler{$addr}}($self)
2678                                         if $construction_time_handler{$addr};
2679
2680         return $self;
2681     }
2682
2683
2684     use overload
2685         fallback => 0,
2686         qw("") => "_operator_stringify",
2687         "." => \&main::_operator_dot,
2688         ".=" => \&main::_operator_dot_equal,
2689     ;
2690
2691     sub _operator_stringify {
2692         my $self = shift;
2693
2694         return __PACKAGE__ . " object for " . $self->file;
2695     }
2696
2697     sub run {
2698         # Process the input object $self.  This opens and closes the file and
2699         # calls all the handlers for it.  Currently,  this can only be called
2700         # once per file, as it destroy's the EOF handlers
2701
2702         # flag to make sure extracted files are processed early
2703         state $seen_non_extracted = 0;
2704
2705         my $self = shift;
2706         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2707
2708         my $addr = do { no overloading; pack 'J', $self; };
2709
2710         my $file = $file{$addr};
2711
2712         if (! $file) {
2713             $handle{$addr} = 'pretend_is_open';
2714         }
2715         else {
2716             if ($seen_non_extracted) {
2717                 if ($file =~ /$EXTRACTED/i) # Some platforms may change the
2718                                             # case of the file's name
2719                 {
2720                     Carp::my_carp_bug(main::join_lines(<<END
2721 $file should be processed just after the 'Prop...Alias' files, and before
2722 anything not in the $EXTRACTED_DIR directory.  Proceeding, but the results may
2723 have subtle problems
2724 END
2725                     ));
2726                 }
2727             }
2728             elsif ($EXTRACTED_DIR
2729
2730                     # We only do this check for generic property files
2731                     && $handler{$addr} == \&main::process_generic_property_file
2732
2733                     && $file !~ /$EXTRACTED/i)
2734             {
2735                 # We don't set this (by the 'if' above) if we have no
2736                 # extracted directory, so if running on an early version,
2737                 # this test won't work.  Not worth worrying about.
2738                 $seen_non_extracted = 1;
2739             }
2740
2741             # Mark the file as having being processed, and warn if it
2742             # isn't a file we are expecting.  As we process the files,
2743             # they are deleted from the hash, so any that remain at the
2744             # end of the program are files that we didn't process.
2745             my $fkey = File::Spec->rel2abs($file);
2746             my $exists = delete $potential_files{lc($fkey)};
2747
2748             Carp::my_carp("Was not expecting '$file'.")
2749                                     if $exists && ! $in_this_release{$addr};
2750
2751             # If there is special handling for compiling Unicode releases
2752             # earlier than the first one in which Unicode defines this
2753             # property ...
2754             if ($early{$addr}->@* > 1) {
2755
2756                 # Mark as processed any substitute file that would be used in
2757                 # such a release
2758                 $fkey = File::Spec->rel2abs($early{$addr}[1]);
2759                 delete $potential_files{lc($fkey)};
2760
2761                 # As commented in the constructor code, when using the
2762                 # official property, we still have to allow the publicly
2763                 # inaccessible early name so that the core code which uses it
2764                 # will work regardless.
2765                 if (   ! $only_early{$addr}
2766                     && ! $early{$addr}[0]
2767                     && $early{$addr}->@* > 2)
2768                 {
2769                     my $early_property_name = $early{$addr}[2];
2770                     if ($property{$addr} ne $early_property_name) {
2771                         main::property_ref($property{$addr})
2772                                             ->add_alias($early_property_name);
2773                     }
2774                 }
2775             }
2776
2777             # We may be skipping this file ...
2778             if (defined $skip{$addr}) {
2779
2780                 # If the file isn't supposed to be in this release, there is
2781                 # nothing to do
2782                 if ($in_this_release{$addr}) {
2783
2784                     # But otherwise, we may print a message
2785                     if ($debug_skip) {
2786                         print STDERR "Skipping input file '$file'",
2787                                      " because '$skip{$addr}'\n";
2788                     }
2789
2790                     # And add it to the list of skipped files, which is later
2791                     # used to make the pod
2792                     $skipped_files{$file} = $skip{$addr};
2793
2794                     # The 'optional' list contains properties that are also to
2795                     # be skipped along with the file.  (There may also be
2796                     # digits which are just placeholders to make sure it isn't
2797                     # an empty list
2798                     foreach my $property ($optional{$addr}->@*) {
2799                         next unless $property =~ /\D/;
2800                         my $prop_object = main::property_ref($property);
2801                         next unless defined $prop_object;
2802                         $prop_object->set_fate($SUPPRESSED, $skip{$addr});
2803                     }
2804                 }
2805
2806                 return;
2807             }
2808
2809             # Here, we are going to process the file.  Open it, converting the
2810             # slashes used in this program into the proper form for the OS
2811             my $file_handle;
2812             if (not open $file_handle, "<", $file) {
2813                 Carp::my_carp("Can't open $file.  Skipping: $!");
2814                 return;
2815             }
2816             $handle{$addr} = $file_handle; # Cache the open file handle
2817
2818             # If possible, make sure that the file is the correct version.
2819             # (This data isn't available on early Unicode releases or in
2820             # UnicodeData.txt.)  We don't do this check if we are using a
2821             # substitute file instead of the official one (though the code
2822             # could be extended to do so).
2823             if ($in_this_release{$addr}
2824                 && ! $early{$addr}[0]
2825                 && lc($file) ne 'unicodedata.txt')
2826             {
2827                 if ($file !~ /^Unihan/i) {
2828
2829                     # The non-Unihan files started getting version numbers in
2830                     # 3.2, but some files in 4.0 are unchanged from 3.2, and
2831                     # marked as 3.2.  4.0.1 is the first version where there
2832                     # are no files marked as being from less than 4.0, though
2833                     # some are marked as 4.0.  In versions after that, the
2834                     # numbers are correct.
2835                     if ($v_version ge v4.0.1) {
2836                         $_ = <$file_handle>;    # The version number is in the
2837                                                 # very first line
2838                         if ($_ !~ / - $string_version \. /x) {
2839                             chomp;
2840                             $_ =~ s/^#\s*//;
2841
2842                             # 4.0.1 had some valid files that weren't updated.
2843                             if (! ($v_version eq v4.0.1 && $_ =~ /4\.0\.0/)) {
2844                                 die Carp::my_carp("File '$file' is version "
2845                                                 . "'$_'.  It should be "
2846                                                 . "version $string_version");
2847                             }
2848                         }
2849                     }
2850                 }
2851                 elsif ($v_version ge v6.0.0) { # Unihan
2852
2853                     # Unihan files didn't get accurate version numbers until
2854                     # 6.0.  The version is somewhere in the first comment
2855                     # block
2856                     while (<$file_handle>) {
2857                         if ($_ !~ /^#/) {
2858                             Carp::my_carp_bug("Could not find the expected "
2859                                             . "version info in file '$file'");
2860                             last;
2861                         }
2862                         chomp;
2863                         $_ =~ s/^#\s*//;
2864                         next if $_ !~ / version: /x;
2865                         last if $_ =~ /$string_version/;
2866                         die Carp::my_carp("File '$file' is version "
2867                                         . "'$_'.  It should be "
2868                                         . "version $string_version");
2869                     }
2870                 }
2871             }
2872         }
2873
2874         print "$progress_message{$addr}\n" if $verbosity >= $PROGRESS;
2875
2876         # Call any special handler for before the file.
2877         &{$pre_handler{$addr}}($self) if $pre_handler{$addr};
2878
2879         # Then the main handler
2880         &{$handler{$addr}}($self);
2881
2882         # Then any special post-file handler.
2883         &{$post_handler{$addr}}($self) if $post_handler{$addr};
2884
2885         # If any errors have been accumulated, output the counts (as the first
2886         # error message in each class was output when it was encountered).
2887         if ($errors{$addr}) {
2888             my $total = 0;
2889             my $types = 0;
2890             foreach my $error (keys %{$errors{$addr}}) {
2891                 $total += $errors{$addr}->{$error};
2892                 delete $errors{$addr}->{$error};
2893                 $types++;
2894             }
2895             if ($total > 1) {
2896                 my $message
2897                         = "A total of $total lines had errors in $file.  ";
2898
2899                 $message .= ($types == 1)
2900                             ? '(Only the first one was displayed.)'
2901                             : '(Only the first of each type was displayed.)';
2902                 Carp::my_carp($message);
2903             }
2904         }
2905
2906         if (@{$missings{$addr}}) {
2907             Carp::my_carp_bug("Handler for $file didn't look at all the \@missing lines.  Generated tables likely are wrong");
2908         }
2909
2910         # If a real file handle, close it.
2911         close $handle{$addr} or Carp::my_carp("Can't close $file: $!") if
2912                                                         ref $handle{$addr};
2913         $handle{$addr} = "";   # Uses empty to indicate that has already seen
2914                                # the file, as opposed to undef
2915         return;
2916     }
2917
2918     sub _next_line {
2919         # Sets $_ to be the next logical input line, if any.  Returns non-zero
2920         # if such a line exists.  'logical' means that any lines that have
2921         # been added via insert_lines() will be returned in $_ before the file
2922         # is read again.
2923
2924         my $self = shift;
2925         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2926
2927         my $addr = do { no overloading; pack 'J', $self; };
2928
2929         # Here the file is open (or if the handle is not a ref, is an open
2930         # 'virtual' file).  Get the next line; any inserted lines get priority
2931         # over the file itself.
2932         my $adjusted;
2933
2934         LINE:
2935         while (1) { # Loop until find non-comment, non-empty line
2936             #local $to_trace = 1 if main::DEBUG;
2937             my $inserted_ref = shift @{$added_lines{$addr}};
2938             if (defined $inserted_ref) {
2939                 ($adjusted, $_) = @{$inserted_ref};
2940                 trace $adjusted, $_ if main::DEBUG && $to_trace;
2941                 return 1 if $adjusted;
2942             }
2943             else {
2944                 last if ! ref $handle{$addr}; # Don't read unless is real file
2945                 last if ! defined ($_ = readline $handle{$addr});
2946             }
2947             chomp;
2948             trace $_ if main::DEBUG && $to_trace;
2949
2950             # See if this line is the comment line that defines what property
2951             # value that code points that are not listed in the file should
2952             # have.  The format or existence of these lines is not guaranteed
2953             # by Unicode since they are comments, but the documentation says
2954             # that this was added for machine-readability, so probably won't
2955             # change.  This works starting in Unicode Version 5.0.  They look
2956             # like:
2957             #
2958             # @missing: 0000..10FFFF; Not_Reordered
2959             # @missing: 0000..10FFFF; Decomposition_Mapping; <code point>
2960             # @missing: 0000..10FFFF; ; NaN
2961             #
2962             # Save the line for a later get_missings() call.
2963             if (/$missing_defaults_prefix/) {
2964                 if ($has_missings_defaults{$addr} == $NO_DEFAULTS) {
2965                     $self->carp_bad_line("Unexpected \@missing line.  Assuming no missing entries");
2966                 }
2967                 elsif ($has_missings_defaults{$addr} == $NOT_IGNORED) {
2968                     my @defaults = split /\s* ; \s*/x, $_;
2969
2970                     # The first field is the @missing, which ends in a
2971                     # semi-colon, so can safely shift.
2972                     shift @defaults;
2973
2974                     # Some of these lines may have empty field placeholders
2975                     # which get in the way.  An example is:
2976                     # @missing: 0000..10FFFF; ; NaN
2977                     # Remove them.  Process starting from the top so the
2978                     # splice doesn't affect things still to be looked at.
2979                     for (my $i = @defaults - 1; $i >= 0; $i--) {
2980                         next if $defaults[$i] ne "";
2981                         splice @defaults, $i, 1;
2982                     }
2983
2984                     # What's left should be just the property (maybe) and the
2985                     # default.  Having only one element means it doesn't have
2986                     # the property.
2987                     my $default;
2988                     my $property;
2989                     if (@defaults >= 1) {
2990                         if (@defaults == 1) {
2991                             $default = $defaults[0];
2992                         }
2993                         else {
2994                             $property = $defaults[0];
2995                             $default = $defaults[1];
2996                         }
2997                     }
2998
2999                     if (@defaults < 1
3000                         || @defaults > 2
3001                         || ($default =~ /^</
3002                             && $default !~ /^<code *point>$/i
3003                             && $default !~ /^<none>$/i
3004                             && $default !~ /^<script>$/i))
3005                     {
3006                         $self->carp_bad_line("Unrecognized \@missing line: $_.  Assuming no missing entries");
3007                     }
3008                     else {
3009
3010                         # If the property is missing from the line, it should
3011                         # be the one for the whole file
3012                         $property = $property{$addr} if ! defined $property;
3013
3014                         # Change <none> to the null string, which is what it
3015                         # really means.  If the default is the code point
3016                         # itself, set it to <code point>, which is what
3017                         # Unicode uses (but sometimes they've forgotten the
3018                         # space)
3019                         if ($default =~ /^<none>$/i) {
3020                             $default = "";
3021                         }
3022                         elsif ($default =~ /^<code *point>$/i) {
3023                             $default = $CODE_POINT;
3024                         }
3025                         elsif ($default =~ /^<script>$/i) {
3026
3027                             # Special case this one.  Currently is from
3028                             # ScriptExtensions.txt, and means for all unlisted
3029                             # code points, use their Script property values.
3030                             # For the code points not listed in that file, the
3031                             # default value is 'Unknown'.
3032                             $default = "Unknown";
3033                         }
3034
3035                         # Store them as a sub-arrays with both components.
3036                         push @{$missings{$addr}}, [ $default, $property ];
3037                     }
3038                 }
3039
3040                 # There is nothing for the caller to process on this comment
3041                 # line.
3042                 next;
3043             }
3044
3045             # Unless to keep, remove comments.  If to keep, ignore
3046             # comment-only lines
3047             if ($retain_trailing_comments{$addr}) {
3048                 next if / ^ \s* \# /x;
3049
3050                 # But escape any single quotes (done in both the comment and
3051                 # non-comment portion; this could be a bug someday, but not
3052                 # likely)
3053                 s/'/\\'/g;
3054             }
3055             else {
3056                 s/#.*//;
3057             }
3058
3059             # Remove trailing space, and skip this line if the result is empty
3060             s/\s+$//;
3061             next if /^$/;
3062
3063             # Call any handlers for this line, and skip further processing of
3064             # the line if the handler sets the line to null.
3065             foreach my $sub_ref (@{$each_line_handler{$addr}}) {
3066                 &{$sub_ref}($self);
3067                 next LINE if /^$/;
3068             }
3069
3070             # Here the line is ok.  return success.
3071             return 1;
3072         } # End of looping through lines.
3073
3074         # If there are EOF handlers, call each (only once) and if it generates
3075         # more lines to process go back in the loop to handle them.
3076         while ($eof_handler{$addr}->@*) {
3077             &{$eof_handler{$addr}[0]}($self);
3078             shift $eof_handler{$addr}->@*;   # Currently only get one shot at it.
3079             goto LINE if $added_lines{$addr};
3080         }
3081
3082         # Return failure -- no more lines.
3083         return 0;
3084
3085     }
3086
3087     sub _next_line_with_remapped_range {
3088         my $self = shift;
3089         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3090
3091         # like _next_line(), but for use on non-ASCII platforms.  It sets $_
3092         # to be the next logical input line, if any.  Returns non-zero if such
3093         # a line exists.  'logical' means that any lines that have been added
3094         # via insert_lines() will be returned in $_ before the file is read
3095         # again.
3096         #
3097         # The difference from _next_line() is that this remaps the Unicode
3098         # code points in the input to those of the native platform.  Each
3099         # input line contains a single code point, or a single contiguous
3100         # range of them  This routine splits each range into its individual
3101         # code points and caches them.  It returns the cached values,
3102         # translated into their native equivalents, one at a time, for each
3103         # call, before reading the next line.  Since native values can only be
3104         # a single byte wide, no translation is needed for code points above
3105         # 0xFF, and ranges that are entirely above that number are not split.
3106         # If an input line contains the range 254-1000, it would be split into
3107         # three elements: 254, 255, and 256-1000.  (The downstream table
3108         # insertion code will sort and coalesce the individual code points
3109         # into appropriate ranges.)
3110
3111         my $addr = do { no overloading; pack 'J', $self; };
3112
3113         while (1) {
3114
3115             # Look in cache before reading the next line.  Return any cached
3116             # value, translated
3117             my $inserted = shift @{$remapped_lines{$addr}};
3118             if (defined $inserted) {
3119                 trace $inserted if main::DEBUG && $to_trace;
3120                 $_ = $inserted =~ s/^ ( \d+ ) /sprintf("%04X", utf8::unicode_to_native($1))/xer;
3121                 trace $_ if main::DEBUG && $to_trace;
3122                 return 1;
3123             }
3124
3125             # Get the next line.
3126             return 0 unless _next_line($self);
3127
3128             # If there is a special handler for it, return the line,
3129             # untranslated.  This should happen only for files that are
3130             # special, not being code-point related, such as property names.
3131             return 1 if $handler{$addr}
3132                                     != \&main::process_generic_property_file;
3133
3134             my ($range, $property_name, $map, @remainder)
3135                 = split /\s*;\s*/, $_, -1; # -1 => retain trailing null fields
3136
3137             if (@remainder
3138                 || ! defined $property_name
3139                 || $range !~ /^ ($code_point_re) (?:\.\. ($code_point_re) )? $/x)
3140             {
3141                 Carp::my_carp_bug("Unrecognized input line '$_'.  Ignored");
3142             }
3143
3144             my $low = hex $1;
3145             my $high = (defined $2) ? hex $2 : $low;
3146
3147             # If the input maps the range to another code point, remap the
3148             # target if it is between 0 and 255.
3149             my $tail;
3150             if (defined $map) {
3151                 $map =~ s/\b 00 ( [0-9A-F]{2} ) \b/sprintf("%04X", utf8::unicode_to_native(hex $1))/gxe;
3152                 $tail = "$property_name; $map";
3153                 $_ = "$range; $tail";
3154             }
3155             else {
3156                 $tail = $property_name;
3157             }
3158
3159             # If entire range is above 255, just return it, unchanged (except
3160             # any mapped-to code point, already changed above)
3161             return 1 if $low > 255;
3162
3163             # Cache an entry for every code point < 255.  For those in the
3164             # range above 255, return a dummy entry for just that portion of
3165             # the range.  Note that this will be out-of-order, but that is not
3166             # a problem.
3167             foreach my $code_point ($low .. $high) {
3168                 if ($code_point > 255) {
3169                     $_ = sprintf "%04X..%04X; $tail", $code_point, $high;
3170                     return 1;
3171                 }
3172                 push @{$remapped_lines{$addr}}, "$code_point; $tail";
3173             }
3174         } # End of looping through lines.
3175
3176         # NOTREACHED
3177     }
3178
3179 #   Not currently used, not fully tested.
3180 #    sub peek {
3181 #        # Non-destructive lookahead one non-adjusted, non-comment, non-blank
3182 #        # record.  Not callable from an each_line_handler(), nor does it call
3183 #        # an each_line_handler() on the line.
3184 #
3185 #        my $self = shift;
3186 #        my $addr = do { no overloading; pack 'J', $self; };
3187 #
3188 #        foreach my $inserted_ref (@{$added_lines{$addr}}) {
3189 #            my ($adjusted, $line) = @{$inserted_ref};
3190 #            next if $adjusted;
3191 #
3192 #            # Remove comments and trailing space, and return a non-empty
3193 #            # resulting line
3194 #            $line =~ s/#.*//;
3195 #            $line =~ s/\s+$//;
3196 #            return $line if $line ne "";
3197 #        }
3198 #
3199 #        return if ! ref $handle{$addr}; # Don't read unless is real file
3200 #        while (1) { # Loop until find non-comment, non-empty line
3201 #            local $to_trace = 1 if main::DEBUG;
3202 #            trace $_ if main::DEBUG && $to_trace;
3203 #            return if ! defined (my $line = readline $handle{$addr});
3204 #            chomp $line;
3205 #            push @{$added_lines{$addr}}, [ 0, $line ];
3206 #
3207 #            $line =~ s/#.*//;
3208 #            $line =~ s/\s+$//;
3209 #            return $line if $line ne "";
3210 #        }
3211 #
3212 #        return;
3213 #    }
3214
3215
3216     sub insert_lines {
3217         # Lines can be inserted so that it looks like they were in the input
3218         # file at the place it was when this routine is called.  See also
3219         # insert_adjusted_lines().  Lines inserted via this routine go through
3220         # any each_line_handler()
3221
3222         my $self = shift;
3223
3224         # Each inserted line is an array, with the first element being 0 to
3225         # indicate that this line hasn't been adjusted, and needs to be
3226         # processed.
3227         no overloading;
3228         push @{$added_lines{pack 'J', $self}}, map { [ 0, $_ ] } @_;
3229         return;
3230     }
3231
3232     sub insert_adjusted_lines {
3233         # Lines can be inserted so that it looks like they were in the input
3234         # file at the place it was when this routine is called.  See also
3235         # insert_lines().  Lines inserted via this routine are already fully
3236         # adjusted, ready to be processed; each_line_handler()s handlers will
3237         # not be called.  This means this is not a completely general
3238         # facility, as only the last each_line_handler on the stack should
3239         # call this.  It could be made more general, by passing to each of the
3240         # line_handlers their position on the stack, which they would pass on
3241         # to this routine, and that would replace the boolean first element in
3242         # the anonymous array pushed here, so that the next_line routine could
3243         # use that to call only those handlers whose index is after it on the
3244         # stack.  But this is overkill for what is needed now.
3245
3246         my $self = shift;
3247         trace $_[0] if main::DEBUG && $to_trace;
3248
3249         # Each inserted line is an array, with the first element being 1 to
3250         # indicate that this line has been adjusted
3251         no overloading;
3252         push @{$added_lines{pack 'J', $self}}, map { [ 1, $_ ] } @_;
3253         return;
3254     }
3255
3256     sub get_missings {
3257         # Returns the stored up @missings lines' values, and clears the list.
3258         # The values are in an array, consisting of the default in the first
3259         # element, and the property in the 2nd.  However, since these lines
3260         # can be stacked up, the return is an array of all these arrays.
3261
3262         my $self = shift;
3263         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3264
3265         my $addr = do { no overloading; pack 'J', $self; };
3266
3267         # If not accepting a list return, just return the first one.
3268         return shift @{$missings{$addr}} unless wantarray;
3269
3270         my @return = @{$missings{$addr}};
3271         undef @{$missings{$addr}};
3272         return @return;
3273     }
3274
3275     sub _exclude_unassigned {
3276
3277         # Takes the range in $_ and excludes code points that aren't assigned
3278         # in this release
3279
3280         state $skip_inserted_count = 0;
3281
3282         # Ignore recursive calls.
3283         if ($skip_inserted_count) {
3284             $skip_inserted_count--;
3285             return;
3286         }
3287
3288         # Find what code points are assigned in this release
3289         main::calculate_Assigned() if ! defined $Assigned;
3290
3291         my $self = shift;
3292         my $addr = do { no overloading; pack 'J', $self; };
3293         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3294
3295         my ($range, @remainder)
3296             = split /\s*;\s*/, $_, -1; # -1 => retain trailing null fields
3297
3298         # Examine the range.
3299         if ($range =~ /^ ($code_point_re) (?:\.\. ($code_point_re) )? $/x)
3300         {
3301             my $low = hex $1;
3302             my $high = (defined $2) ? hex $2 : $low;
3303
3304             # Split the range into subranges of just those code points in it
3305             # that are assigned.
3306             my @ranges = (Range_List->new(Initialize
3307                               => Range->new($low, $high)) & $Assigned)->ranges;
3308
3309             # Do nothing if nothing in the original range is assigned in this
3310             # release; handle normally if everything is in this release.
3311             if (! @ranges) {
3312                 $_ = "";
3313             }
3314             elsif (@ranges != 1) {
3315
3316                 # Here, some code points in the original range aren't in this
3317                 # release; @ranges gives the ones that are.  Create fake input
3318                 # lines for each of the ranges, and set things up so that when
3319                 # this routine is called on that fake input, it will do
3320                 # nothing.
3321                 $skip_inserted_count = @ranges;
3322                 my $remainder = join ";", @remainder;
3323                 for my $range (@ranges) {
3324                     $self->insert_lines(sprintf("%04X..%04X;%s",
3325                                     $range->start, $range->end, $remainder));
3326                 }
3327                 $_ = "";    # The original range is now defunct.
3328             }
3329         }
3330
3331         return;
3332     }
3333
3334     sub _fixup_obsolete_hanguls {
3335
3336         # This is called only when compiling Unicode version 1.  All Unicode
3337         # data for subsequent releases assumes that the code points that were
3338         # Hangul syllables in this release only are something else, so if
3339         # using such data, we have to override it
3340
3341         my $self = shift;
3342         my $addr = do { no overloading; pack 'J', $self; };
3343         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3344
3345         my $object = main::property_ref($property{$addr});
3346         $object->add_map($FIRST_REMOVED_HANGUL_SYLLABLE,
3347                          $FINAL_REMOVED_HANGUL_SYLLABLE,
3348                          $early{$addr}[3],  # Passed-in value for these
3349                          Replace => $UNCONDITIONALLY);
3350     }
3351
3352     sub _insert_property_into_line {
3353         # Add a property field to $_, if this file requires it.
3354
3355         my $self = shift;
3356         my $addr = do { no overloading; pack 'J', $self; };
3357         my $property = $property{$addr};
3358         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3359
3360         $_ =~ s/(;|$)/; $property$1/;
3361         return;
3362     }
3363
3364     sub carp_bad_line {
3365         # Output consistent error messages, using either a generic one, or the
3366         # one given by the optional parameter.  To avoid gazillions of the
3367         # same message in case the syntax of a  file is way off, this routine
3368         # only outputs the first instance of each message, incrementing a
3369         # count so the totals can be output at the end of the file.
3370
3371         my $self = shift;
3372         my $message = shift;
3373         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3374
3375         my $addr = do { no overloading; pack 'J', $self; };
3376
3377         $message = 'Unexpected line' unless $message;
3378
3379         # No trailing punctuation so as to fit with our addenda.
3380         $message =~ s/[.:;,]$//;
3381
3382         # If haven't seen this exact message before, output it now.  Otherwise
3383         # increment the count of how many times it has occurred
3384         unless ($errors{$addr}->{$message}) {
3385             Carp::my_carp("$message in '$_' in "
3386                             . $file{$addr}
3387                             . " at line $..  Skipping this line;");
3388             $errors{$addr}->{$message} = 1;
3389         }
3390         else {
3391             $errors{$addr}->{$message}++;
3392         }
3393
3394         # Clear the line to prevent any further (meaningful) processing of it.
3395         $_ = "";
3396
3397         return;
3398     }
3399 } # End closure
3400
3401 package Multi_Default;
3402
3403 # Certain properties in early versions of Unicode had more than one possible
3404 # default for code points missing from the files.  In these cases, one
3405 # default applies to everything left over after all the others are applied,
3406 # and for each of the others, there is a description of which class of code
3407 # points applies to it.  This object helps implement this by storing the
3408 # defaults, and for all but that final default, an eval string that generates
3409 # the class that it applies to.
3410
3411
3412 {   # Closure
3413
3414     main::setup_package();
3415
3416     my %class_defaults;
3417     # The defaults structure for the classes
3418     main::set_access('class_defaults', \%class_defaults);
3419
3420     my %other_default;
3421     # The default that applies to everything left over.
3422     main::set_access('other_default', \%other_default, 'r');
3423
3424
3425     sub new {
3426         # The constructor is called with default => eval pairs, terminated by
3427         # the left-over default. e.g.
3428         # Multi_Default->new(
3429         #        'T' => '$gc->table("Mn") + $gc->table("Cf") - 0x200C
3430         #               -  0x200D',
3431         #        'R' => 'some other expression that evaluates to code points',
3432         #        .
3433         #        .
3434         #        .
3435         #        'U'));
3436         # It is best to leave the final value be the one that matches the
3437         # above-Unicode code points.
3438
3439         my $class = shift;
3440
3441         my $self = bless \do{my $anonymous_scalar}, $class;
3442         my $addr = do { no overloading; pack 'J', $self; };
3443
3444         while (@_ > 1) {
3445             my $default = shift;
3446             my $eval = shift;
3447             $class_defaults{$addr}->{$default} = $eval;
3448         }
3449
3450         $other_default{$addr} = shift;
3451
3452         return $self;
3453     }
3454
3455     sub get_next_defaults {
3456         # Iterates and returns the next class of defaults.
3457         my $self = shift;
3458         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3459
3460         my $addr = do { no overloading; pack 'J', $self; };
3461
3462         return each %{$class_defaults{$addr}};
3463     }
3464 }
3465
3466 package Alias;
3467
3468 # An alias is one of the names that a table goes by.  This class defines them
3469 # including some attributes.  Everything is currently setup in the
3470 # constructor.
3471
3472
3473 {   # Closure
3474
3475     main::setup_package();
3476
3477     my %name;
3478     main::set_access('name', \%name, 'r');
3479
3480     my %loose_match;
3481     # Should this name match loosely or not.
3482     main::set_access('loose_match', \%loose_match, 'r');
3483
3484     my %make_re_pod_entry;
3485     # Some aliases should not get their own entries in the re section of the
3486     # pod, because they are covered by a wild-card, and some we want to
3487     # discourage use of.  Binary
3488     main::set_access('make_re_pod_entry', \%make_re_pod_entry, 'r', 's');
3489
3490     my %ucd;
3491     # Is this documented to be accessible via Unicode::UCD
3492     main::set_access('ucd', \%ucd, 'r', 's');
3493
3494     my %status;
3495     # Aliases have a status, like deprecated, or even suppressed (which means
3496     # they don't appear in documentation).  Enum
3497     main::set_access('status', \%status, 'r');
3498
3499     my %ok_as_filename;
3500     # Similarly, some aliases should not be considered as usable ones for
3501     # external use, such as file names, or we don't want documentation to
3502     # recommend them.  Boolean
3503     main::set_access('ok_as_filename', \%ok_as_filename, 'r');
3504
3505     sub new {
3506         my $class = shift;
3507
3508         my $self = bless \do { my $anonymous_scalar }, $class;
3509         my $addr = do { no overloading; pack 'J', $self; };
3510
3511         $name{$addr} = shift;
3512         $loose_match{$addr} = shift;
3513         $make_re_pod_entry{$addr} = shift;
3514         $ok_as_filename{$addr} = shift;
3515         $status{$addr} = shift;
3516         $ucd{$addr} = shift;
3517
3518         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3519
3520         # Null names are never ok externally
3521         $ok_as_filename{$addr} = 0 if $name{$addr} eq "";
3522
3523         return $self;
3524     }
3525 }
3526
3527 package Range;
3528
3529 # A range is the basic unit for storing code points, and is described in the
3530 # comments at the beginning of the program.  Each range has a starting code
3531 # point; an ending code point (not less than the starting one); a value
3532 # that applies to every code point in between the two end-points, inclusive;
3533 # and an enum type that applies to the value.  The type is for the user's
3534 # convenience, and has no meaning here, except that a non-zero type is
3535 # considered to not obey the normal Unicode rules for having standard forms.
3536 #
3537 # The same structure is used for both map and match tables, even though in the
3538 # latter, the value (and hence type) is irrelevant and could be used as a
3539 # comment.  In map tables, the value is what all the code points in the range
3540 # map to.  Type 0 values have the standardized version of the value stored as
3541 # well, so as to not have to recalculate it a lot.
3542
3543 sub trace { return main::trace(@_); }
3544
3545 {   # Closure
3546
3547     main::setup_package();
3548
3549     my %start;
3550     main::set_access('start', \%start, 'r', 's');
3551
3552     my %end;
3553     main::set_access('end', \%end, 'r', 's');
3554
3555     my %value;
3556     main::set_access('value', \%value, 'r');
3557
3558     my %type;
3559     main::set_access('type', \%type, 'r');
3560
3561     my %standard_form;
3562     # The value in internal standard form.  Defined only if the type is 0.
3563     main::set_access('standard_form', \%standard_form);
3564
3565     # Note that if these fields change, the dump() method should as well
3566
3567     sub new {
3568         return Carp::carp_too_few_args(\@_, 3) if main::DEBUG && @_ < 3;
3569         my $class = shift;
3570
3571         my $self = bless \do { my $anonymous_scalar }, $class;
3572         my $addr = do { no overloading; pack 'J', $self; };
3573
3574         $start{$addr} = shift;
3575         $end{$addr} = shift;
3576
3577         my %args = @_;
3578
3579         my $value = delete $args{'Value'};  # Can be 0
3580         $value = "" unless defined $value;
3581         $value{$addr} = $value;
3582
3583         $type{$addr} = delete $args{'Type'} || 0;
3584
3585         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3586
3587         return $self;
3588     }
3589
3590     use overload
3591         fallback => 0,
3592         qw("") => "_operator_stringify",
3593         "." => \&main::_operator_dot,
3594         ".=" => \&main::_operator_dot_equal,
3595     ;
3596
3597     sub _operator_stringify {
3598         my $self = shift;
3599         my $addr = do { no overloading; pack 'J', $self; };
3600
3601         # Output it like '0041..0065 (value)'
3602         my $return = sprintf("%04X", $start{$addr})
3603                         .  '..'
3604                         . sprintf("%04X", $end{$addr});
3605         my $value = $value{$addr};
3606         my $type = $type{$addr};
3607         $return .= ' (';
3608         $return .= "$value";
3609         $return .= ", Type=$type" if $type != 0;
3610         $return .= ')';
3611
3612         return $return;
3613     }
3614
3615     sub standard_form {
3616         # Calculate the standard form only if needed, and cache the result.
3617         # The standard form is the value itself if the type is special.
3618         # This represents a considerable CPU and memory saving - at the time
3619         # of writing there are 368676 non-special objects, but the standard
3620         # form is only requested for 22047 of them - ie about 6%.
3621
3622         my $self = shift;
3623         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3624
3625         my $addr = do { no overloading; pack 'J', $self; };
3626
3627         return $standard_form{$addr} if defined $standard_form{$addr};
3628
3629         my $value = $value{$addr};
3630         return $value if $type{$addr};
3631         return $standard_form{$addr} = main::standardize($value);
3632     }
3633
3634     sub dump {
3635         # Human, not machine readable.  For machine readable, comment out this
3636         # entire routine and let the standard one take effect.
3637         my $self = shift;
3638         my $indent = shift;
3639         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3640
3641         my $addr = do { no overloading; pack 'J', $self; };
3642
3643         my $return = $indent
3644                     . sprintf("%04X", $start{$addr})
3645                     . '..'
3646                     . sprintf("%04X", $end{$addr})
3647                     . " '$value{$addr}';";
3648         if (! defined $standard_form{$addr}) {
3649             $return .= "(type=$type{$addr})";
3650         }
3651         elsif ($standard_form{$addr} ne $value{$addr}) {
3652             $return .= "(standard '$standard_form{$addr}')";
3653         }
3654         return $return;
3655     }
3656 } # End closure
3657
3658 package _Range_List_Base;
3659
3660 # Base class for range lists.  A range list is simply an ordered list of
3661 # ranges, so that the ranges with the lowest starting numbers are first in it.
3662 #
3663 # When a new range is added that is adjacent to an existing range that has the
3664 # same value and type, it merges with it to form a larger range.
3665 #
3666 # Ranges generally do not overlap, except that there can be multiple entries
3667 # of single code point ranges.  This is because of NameAliases.txt.
3668 #
3669 # In this program, there is a standard value such that if two different
3670 # values, have the same standard value, they are considered equivalent.  This
3671 # value was chosen so that it gives correct results on Unicode data
3672
3673 # There are a number of methods to manipulate range lists, and some operators
3674 # are overloaded to handle them.
3675
3676 sub trace { return main::trace(@_); }
3677
3678 { # Closure
3679
3680     our $addr;
3681
3682     # Max is initialized to a negative value that isn't adjacent to 0, for
3683     # simpler tests
3684     my $max_init = -2;
3685
3686     main::setup_package();
3687
3688     my %ranges;
3689     # The list of ranges
3690     main::set_access('ranges', \%ranges, 'readable_array');
3691
3692     my %max;
3693     # The highest code point in the list.  This was originally a method, but
3694     # actual measurements said it was used a lot.
3695     main::set_access('max', \%max, 'r');
3696
3697     my %each_range_iterator;
3698     # Iterator position for each_range()
3699     main::set_access('each_range_iterator', \%each_range_iterator);
3700
3701     my %owner_name_of;
3702     # Name of parent this is attached to, if any.  Solely for better error
3703     # messages.
3704     main::set_access('owner_name_of', \%owner_name_of, 'p_r');
3705
3706     my %_search_ranges_cache;
3707     # A cache of the previous result from _search_ranges(), for better
3708     # performance
3709     main::set_access('_search_ranges_cache', \%_search_ranges_cache);
3710
3711     sub new {
3712         my $class = shift;
3713         my %args = @_;
3714
3715         # Optional initialization data for the range list.
3716         my $initialize = delete $args{'Initialize'};
3717
3718         my $self;
3719
3720         # Use _union() to initialize.  _union() returns an object of this
3721         # class, which means that it will call this constructor recursively.
3722         # But it won't have this $initialize parameter so that it won't
3723         # infinitely loop on this.
3724         return _union($class, $initialize, %args) if defined $initialize;
3725
3726         $self = bless \do { my $anonymous_scalar }, $class;
3727         my $addr = do { no overloading; pack 'J', $self; };
3728
3729         # Optional parent object, only for debug info.
3730         $owner_name_of{$addr} = delete $args{'Owner'};
3731         $owner_name_of{$addr} = "" if ! defined $owner_name_of{$addr};
3732
3733         # Stringify, in case it is an object.
3734         $owner_name_of{$addr} = "$owner_name_of{$addr}";
3735
3736         # This is used only for error messages, and so a colon is added
3737         $owner_name_of{$addr} .= ": " if $owner_name_of{$addr} ne "";
3738
3739         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3740
3741         $max{$addr} = $max_init;
3742
3743         $_search_ranges_cache{$addr} = 0;
3744         $ranges{$addr} = [];
3745
3746         return $self;
3747     }
3748
3749     use overload
3750         fallback => 0,
3751         qw("") => "_operator_stringify",
3752         "." => \&main::_operator_dot,
3753         ".=" => \&main::_operator_dot_equal,
3754     ;
3755
3756     sub _operator_stringify {
3757         my $self = shift;
3758         my $addr = do { no overloading; pack 'J', $self; };
3759
3760         return "Range_List attached to '$owner_name_of{$addr}'"
3761                                                 if $owner_name_of{$addr};
3762         return "anonymous Range_List " . \$self;
3763     }
3764
3765     sub _union {
3766         # Returns the union of the input code points.  It can be called as
3767         # either a constructor or a method.  If called as a method, the result
3768         # will be a new() instance of the calling object, containing the union
3769         # of that object with the other parameter's code points;  if called as
3770         # a constructor, the first parameter gives the class that the new object
3771         # should be, and the second parameter gives the code points to go into
3772         # it.
3773         # In either case, there are two parameters looked at by this routine;
3774         # any additional parameters are passed to the new() constructor.
3775         #
3776         # The code points can come in the form of some object that contains
3777         # ranges, and has a conventionally named method to access them; or
3778         # they can be an array of individual code points (as integers); or
3779         # just a single code point.
3780         #
3781         # If they are ranges, this routine doesn't make any effort to preserve
3782         # the range values and types of one input over the other.  Therefore
3783         # this base class should not allow _union to be called from other than
3784         # initialization code, so as to prevent two tables from being added
3785         # together where the range values matter.  The general form of this
3786         # routine therefore belongs in a derived class, but it was moved here
3787         # to avoid duplication of code.  The failure to overload this in this
3788         # class keeps it safe.
3789         #
3790         # It does make the effort during initialization to accept tables with
3791         # multiple values for the same code point, and to preserve the order
3792         # of these.  If there is only one input range or range set, it doesn't
3793         # sort (as it should already be sorted to the desired order), and will
3794         # accept multiple values per code point.  Otherwise it will merge
3795         # multiple values into a single one.
3796
3797         my $self;
3798         my @args;   # Arguments to pass to the constructor
3799
3800         my $class = shift;
3801
3802         # If a method call, will start the union with the object itself, and
3803         # the class of the new object will be the same as self.
3804         if (ref $class) {
3805             $self = $class;
3806             $class = ref $self;
3807             push @args, $self;
3808         }
3809
3810         # Add the other required parameter.
3811         push @args, shift;
3812         # Rest of parameters are passed on to the constructor
3813
3814         # Accumulate all records from both lists.
3815         my @records;
3816         my $input_count = 0;
3817         for my $arg (@args) {
3818             #local $to_trace = 0 if main::DEBUG;
3819             trace "argument = $arg" if main::DEBUG && $to_trace;
3820             if (! defined $arg) {
3821                 my $message = "";
3822                 if (defined $self) {
3823                     no overloading;
3824                     $message .= $owner_name_of{pack 'J', $self};
3825                 }
3826                 Carp::my_carp_bug($message . "Undefined argument to _union.  No union done.");
3827                 return;
3828             }
3829
3830             $arg = [ $arg ] if ! ref $arg;
3831             my $type = ref $arg;
3832             if ($type eq 'ARRAY') {
3833                 foreach my $element (@$arg) {
3834                     push @records, Range->new($element, $element);
3835                     $input_count++;
3836                 }
3837             }
3838             elsif ($arg->isa('Range')) {
3839                 push @records, $arg;
3840                 $input_count++;
3841             }
3842             elsif ($arg->can('ranges')) {
3843                 push @records, $arg->ranges;
3844                 $input_count++;
3845             }
3846             else {
3847                 my $message = "";
3848                 if (defined $self) {
3849                     no overloading;
3850                     $message .= $owner_name_of{pack 'J', $self};
3851                 }
3852                 Carp::my_carp_bug($message . "Cannot take the union of a $type.  No union done.");
3853                 return;
3854             }
3855         }
3856
3857         # Sort with the range containing the lowest ordinal first, but if
3858         # two ranges start at the same code point, sort with the bigger range
3859         # of the two first, because it takes fewer cycles.
3860         if ($input_count > 1) {
3861             @records = sort { ($a->start <=> $b->start)
3862                                       or
3863                                     # if b is shorter than a, b->end will be
3864                                     # less than a->end, and we want to select
3865                                     # a, so want to return -1
3866                                     ($b->end <=> $a->end)
3867                                    } @records;
3868         }
3869
3870         my $new = $class->new(@_);
3871
3872         # Fold in records so long as they add new information.
3873         for my $set (@records) {
3874             my $start = $set->start;
3875             my $end   = $set->end;
3876             my $value = $set->value;
3877             my $type  = $set->type;
3878             if ($start > $new->max) {
3879                 $new->_add_delete('+', $start, $end, $value, Type => $type);
3880             }
3881             elsif ($end > $new->max) {
3882                 $new->_add_delete('+', $new->max +1, $end, $value,
3883                                                                 Type => $type);
3884             }
3885             elsif ($input_count == 1) {
3886                 # Here, overlaps existing range, but is from a single input,
3887                 # so preserve the multiple values from that input.
3888                 $new->_add_delete('+', $start, $end, $value, Type => $type,
3889                                                 Replace => $MULTIPLE_AFTER);
3890             }
3891         }
3892
3893         return $new;
3894     }
3895
3896     sub range_count {        # Return the number of ranges in the range list
3897         my $self = shift;
3898         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3899
3900         no overloading;
3901         return scalar @{$ranges{pack 'J', $self}};
3902     }
3903
3904     sub min {
3905         # Returns the minimum code point currently in the range list, or if
3906         # the range list is empty, 2 beyond the max possible.  This is a
3907         # method because used so rarely, that not worth saving between calls,
3908         # and having to worry about changing it as ranges are added and
3909         # deleted.
3910
3911         my $self = shift;
3912         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3913
3914         my $addr = do { no overloading; pack 'J', $self; };
3915
3916         # If the range list is empty, return a large value that isn't adjacent
3917         # to any that could be in the range list, for simpler tests
3918         return $MAX_WORKING_CODEPOINT + 2 unless scalar @{$ranges{$addr}};
3919         return $ranges{$addr}->[0]->start;
3920     }
3921
3922     sub contains {
3923         # Boolean: Is argument in the range list?  If so returns $i such that:
3924         #   range[$i]->end < $codepoint <= range[$i+1]->end
3925         # which is one beyond what you want; this is so that the 0th range
3926         # doesn't return false
3927         my $self = shift;
3928         my $codepoint = shift;
3929         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3930
3931         my $i = $self->_search_ranges($codepoint);
3932         return 0 unless defined $i;
3933
3934         # The search returns $i, such that
3935         #   range[$i-1]->end < $codepoint <= range[$i]->end
3936         # So is in the table if and only iff it is at least the start position
3937         # of range $i.
3938         no overloading;
3939         return 0 if $ranges{pack 'J', $self}->[$i]->start > $codepoint;
3940         return $i + 1;
3941     }
3942
3943     sub containing_range {
3944         # Returns the range object that contains the code point, undef if none
3945
3946         my $self = shift;
3947         my $codepoint = shift;
3948         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3949
3950         my $i = $self->contains($codepoint);
3951         return unless $i;
3952
3953         # contains() returns 1 beyond where we should look
3954         no overloading;
3955         return $ranges{pack 'J', $self}->[$i-1];
3956     }
3957
3958     sub value_of {
3959         # Returns the value associated with the code point, undef if none
3960
3961         my $self = shift;
3962         my $codepoint = shift;
3963         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3964
3965         my $range = $self->containing_range($codepoint);
3966         return unless defined $range;
3967
3968         return $range->value;
3969     }
3970
3971     sub type_of {
3972         # Returns the type of the range containing the code point, undef if
3973         # the code point is not in the table
3974
3975         my $self = shift;
3976         my $codepoint = shift;
3977         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3978
3979         my $range = $self->containing_range($codepoint);
3980         return unless defined $range;
3981
3982         return $range->type;
3983     }
3984
3985     sub _search_ranges {
3986         # Find the range in the list which contains a code point, or where it
3987         # should go if were to add it.  That is, it returns $i, such that:
3988         #   range[$i-1]->end < $codepoint <= range[$i]->end
3989         # Returns undef if no such $i is possible (e.g. at end of table), or
3990         # if there is an error.
3991
3992         my $self = shift;
3993         my $code_point = shift;
3994         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3995
3996         my $addr = do { no overloading; pack 'J', $self; };
3997
3998         return if $code_point > $max{$addr};
3999         my $r = $ranges{$addr};                # The current list of ranges
4000         my $range_list_size = scalar @$r;
4001         my $i;
4002
4003         use integer;        # want integer division
4004
4005         # Use the cached result as the starting guess for this one, because,
4006         # an experiment on 5.1 showed that 90% of the time the cache was the
4007         # same as the result on the next call (and 7% it was one less).
4008         $i = $_search_ranges_cache{$addr};
4009         $i = 0 if $i >= $range_list_size;   # Reset if no longer valid (prob.
4010                                             # from an intervening deletion
4011         #local $to_trace = 1 if main::DEBUG;
4012         trace "previous \$i is still valid: $i" if main::DEBUG && $to_trace && $code_point <= $r->[$i]->end && ($i == 0 || $r->[$i-1]->end < $code_point);
4013         return $i if $code_point <= $r->[$i]->end
4014                      && ($i == 0 || $r->[$i-1]->end < $code_point);
4015
4016         # Here the cache doesn't yield the correct $i.  Try adding 1.
4017         if ($i < $range_list_size - 1
4018             && $r->[$i]->end < $code_point &&
4019             $code_point <= $r->[$i+1]->end)
4020         {
4021             $i++;
4022             trace "next \$i is correct: $i" if main::DEBUG && $to_trace;
4023             $_search_ranges_cache{$addr} = $i;
4024             return $i;
4025         }
4026
4027         # Here, adding 1&n