This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Update generated Module::Build::ConfigData
[perl5.git] / cpan / Module-Build / lib / Module / Build.pm
1 package Module::Build;
2
3 # This module doesn't do much of anything itself, it inherits from the
4 # modules that do the real work.  The only real thing it has to do is
5 # figure out which OS-specific module to pull in.  Many of the
6 # OS-specific modules don't do anything either - most of the work is
7 # done in Module::Build::Base.
8
9 use strict;
10 use File::Spec ();
11 use File::Path ();
12 use File::Basename ();
13
14 use Module::Build::Base;
15
16 use vars qw($VERSION @ISA);
17 @ISA = qw(Module::Build::Base);
18 $VERSION = '0.35_09';
19 $VERSION = eval $VERSION;
20
21 # Okay, this is the brute-force method of finding out what kind of
22 # platform we're on.  I don't know of a systematic way.  These values
23 # came from the latest (bleadperl) perlport.pod.
24
25 my %OSTYPES = qw(
26                  aix       Unix
27                  bsdos     Unix
28                  dgux      Unix
29                  dragonfly Unix
30                  dynixptx  Unix
31                  freebsd   Unix
32                  linux     Unix
33                  haiku     Unix
34                  hpux      Unix
35                  irix      Unix
36                  darwin    Unix
37                  machten   Unix
38                  midnightbsd Unix
39                  mirbsd    Unix
40                  next      Unix
41                  openbsd   Unix
42                  netbsd    Unix
43                  dec_osf   Unix
44                  nto       Unix
45                  svr4      Unix
46                  svr5      Unix
47                  sco_sv    Unix
48                  unicos    Unix
49                  unicosmk  Unix
50                  solaris   Unix
51                  sunos     Unix
52                  cygwin    Unix
53                  os2       Unix
54                  interix   Unix
55                  gnu       Unix
56                  gnukfreebsd Unix
57                  nto       Unix
58
59                  dos       Windows
60                  MSWin32   Windows
61
62                  os390     EBCDIC
63                  os400     EBCDIC
64                  posix-bc  EBCDIC
65                  vmesa     EBCDIC
66
67                  MacOS     MacOS
68                  VMS       VMS
69                  VOS       VOS
70                  riscos    RiscOS
71                  amigaos   Amiga
72                  mpeix     MPEiX
73                 );
74
75 # Inserts the given module into the @ISA hierarchy between
76 # Module::Build and its immediate parent
77 sub _interpose_module {
78   my ($self, $mod) = @_;
79   eval "use $mod";
80   die $@ if $@;
81
82   no strict 'refs';
83   my $top_class = $mod;
84   while (@{"${top_class}::ISA"}) {
85     last if ${"${top_class}::ISA"}[0] eq $ISA[0];
86     $top_class = ${"${top_class}::ISA"}[0];
87   }
88
89   @{"${top_class}::ISA"} = @ISA;
90   @ISA = ($mod);
91 }
92
93 if (grep {-e File::Spec->catfile($_, qw(Module Build Platform), $^O) . '.pm'} @INC) {
94   __PACKAGE__->_interpose_module("Module::Build::Platform::$^O");
95
96 } elsif (exists $OSTYPES{$^O}) {
97   __PACKAGE__->_interpose_module("Module::Build::Platform::$OSTYPES{$^O}");
98
99 } else {
100   warn "Unknown OS type '$^O' - using default settings\n";
101 }
102
103 sub os_type { $OSTYPES{$^O} }
104
105 sub is_vmsish { return ((os_type() || '') eq 'VMS') }
106 sub is_windowsish { return ((os_type() || '') eq 'Windows') }
107 sub is_unixish { return ((os_type() || '') eq 'Unix') }
108
109 1;
110
111 __END__
112
113 =for :stopwords
114 bindoc binhtml destdir distcheck distclean distdir distmeta distsign disttest
115 fakeinstall html installdirs installsitebin installsitescript installvendorbin
116 installvendorscript libdoc libhtml pardist ppd ppmdist realclean skipcheck
117 testall testcover testdb testpod testpodcoverage versioninstall
118
119 =head1 NAME
120
121 Module::Build - Build and install Perl modules
122
123
124 =head1 SYNOPSIS
125
126 Standard process for building & installing modules:
127
128   perl Build.PL
129   ./Build
130   ./Build test
131   ./Build install
132
133 Or, if you're on a platform (like DOS or Windows) that doesn't require
134 the "./" notation, you can do this:
135
136   perl Build.PL
137   Build
138   Build test
139   Build install
140
141
142 =head1 DESCRIPTION
143
144 C<Module::Build> is a system for building, testing, and installing
145 Perl modules.  It is meant to be an alternative to
146 C<ExtUtils::MakeMaker>.  Developers may alter the behavior of the
147 module through subclassing in a much more straightforward way than
148 with C<MakeMaker>.  It also does not require a C<make> on your system
149 - most of the C<Module::Build> code is pure-perl and written in a very
150 cross-platform way.  In fact, you don't even need a shell, so even
151 platforms like MacOS (traditional) can use it fairly easily.  Its only
152 prerequisites are modules that are included with perl 5.6.0, and it
153 works fine on perl 5.005 if you can install a few additional modules.
154
155 See L<"MOTIVATIONS"> for more comparisons between C<ExtUtils::MakeMaker>
156 and C<Module::Build>.
157
158 To install C<Module::Build>, and any other module that uses
159 C<Module::Build> for its installation process, do the following:
160
161   perl Build.PL       # 'Build.PL' script creates the 'Build' script
162   ./Build             # Need ./ to ensure we're using this "Build" script
163   ./Build test        # and not another one that happens to be in the PATH
164   ./Build install
165
166 This illustrates initial configuration and the running of three
167 'actions'.  In this case the actions run are 'build' (the default
168 action), 'test', and 'install'.  Other actions defined so far include:
169
170   build                          manifest    
171   clean                          manpages    
172   code                           pardist     
173   config_data                    ppd         
174   diff                           ppmdist     
175   dist                           prereq_data 
176   distcheck                      prereq_report
177   distclean                      pure_install
178   distdir                        realclean   
179   distmeta                       retest      
180   distsign                       skipcheck   
181   disttest                       test        
182   docs                           testall     
183   fakeinstall                    testcover   
184   help                           testdb      
185   html                           testpod     
186   install                        testpodcoverage
187   installdeps                    versioninstall
188
189
190 You can run the 'help' action for a complete list of actions.
191
192
193 =head1 GUIDE TO DOCUMENTATION
194
195 The documentation for C<Module::Build> is broken up into three sections:
196
197 =over
198
199 =item General Usage (L<Module::Build>)
200
201 This is the document you are currently reading. It describes basic
202 usage and background information.  Its main purpose is to assist the
203 user who wants to learn how to invoke and control C<Module::Build>
204 scripts at the command line.
205
206 =item Authoring Reference (L<Module::Build::Authoring>)
207
208 This document describes the structure and organization of
209 C<Module::Build>, and the relevant concepts needed by authors who are
210 writing F<Build.PL> scripts for a distribution or controlling
211 C<Module::Build> processes programmatically.
212
213 =item API Reference (L<Module::Build::API>)
214
215 This is a reference to the C<Module::Build> API.
216
217 =item Cookbook (L<Module::Build::Cookbook>)
218
219 This document demonstrates how to accomplish many common tasks.  It
220 covers general command line usage and authoring of F<Build.PL>
221 scripts.  Includes working examples.
222
223 =back
224
225
226 =head1 ACTIONS
227
228 There are some general principles at work here.  First, each task when
229 building a module is called an "action".  These actions are listed
230 above; they correspond to the building, testing, installing,
231 packaging, etc., tasks.
232
233 Second, arguments are processed in a very systematic way.  Arguments
234 are always key=value pairs.  They may be specified at C<perl Build.PL>
235 time (i.e. C<perl Build.PL destdir=/my/secret/place>), in which case
236 their values last for the lifetime of the C<Build> script.  They may
237 also be specified when executing a particular action (i.e.
238 C<Build test verbose=1>), in which case their values last only for the
239 lifetime of that command.  Per-action command line parameters take
240 precedence over parameters specified at C<perl Build.PL> time.
241
242 The build process also relies heavily on the C<Config.pm> module.
243 If the user wishes to override any of the
244 values in C<Config.pm>, she may specify them like so:
245
246   perl Build.PL --config cc=gcc --config ld=gcc
247
248 The following build actions are provided by default.
249
250 =over 4
251
252 =item build
253
254 [version 0.01]
255
256 If you run the C<Build> script without any arguments, it runs the
257 C<build> action, which in turn runs the C<code> and C<docs> actions.
258
259 This is analogous to the C<MakeMaker> I<make all> target.
260
261 =item clean
262
263 [version 0.01]
264
265 This action will clean up any files that the build process may have
266 created, including the C<blib/> directory (but not including the
267 C<_build/> directory and the C<Build> script itself).
268
269 =item code
270
271 [version 0.20]
272
273 This action builds your code base.
274
275 By default it just creates a C<blib/> directory and copies any C<.pm>
276 and C<.pod> files from your C<lib/> directory into the C<blib/>
277 directory.  It also compiles any C<.xs> files from C<lib/> and places
278 them in C<blib/>.  Of course, you need a working C compiler (probably
279 the same one that built perl itself) for the compilation to work
280 properly.
281
282 The C<code> action also runs any C<.PL> files in your F<lib/>
283 directory.  Typically these create other files, named the same but
284 without the C<.PL> ending.  For example, a file F<lib/Foo/Bar.pm.PL>
285 could create the file F<lib/Foo/Bar.pm>.  The C<.PL> files are
286 processed first, so any C<.pm> files (or other kinds that we deal
287 with) will get copied correctly.
288
289 =item config_data
290
291 [version 0.26]
292
293 ...
294
295 =item diff
296
297 [version 0.14]
298
299 This action will compare the files about to be installed with their
300 installed counterparts.  For .pm and .pod files, a diff will be shown
301 (this currently requires a 'diff' program to be in your PATH).  For
302 other files like compiled binary files, we simply report whether they
303 differ.
304
305 A C<flags> parameter may be passed to the action, which will be passed
306 to the 'diff' program.  Consult your 'diff' documentation for the
307 parameters it will accept - a good one is C<-u>:
308
309   ./Build diff flags=-u
310
311 =item dist
312
313 [version 0.02]
314
315 This action is helpful for module authors who want to package up their
316 module for source distribution through a medium like CPAN.  It will create a
317 tarball of the files listed in F<MANIFEST> and compress the tarball using
318 GZIP compression.
319
320 By default, this action will use the C<Archive::Tar> module. However, you can
321 force it to use binary "tar" and "gzip" executables by supplying an explicit 
322 C<tar> (and optional C<gzip>) parameter:
323
324   ./Build dist --tar C:\path\to\tar.exe --gzip C:\path\to\zip.exe
325
326 =item distcheck
327
328 [version 0.05]
329
330 Reports which files are in the build directory but not in the
331 F<MANIFEST> file, and vice versa.  (See L<manifest> for details.)
332
333 =item distclean
334
335 [version 0.05]
336
337 Performs the 'realclean' action and then the 'distcheck' action.
338
339 =item distdir
340
341 [version 0.05]
342
343 Creates a "distribution directory" named C<$dist_name-$dist_version>
344 (if that directory already exists, it will be removed first), then
345 copies all the files listed in the F<MANIFEST> file to that directory.
346 This directory is what the distribution tarball is created from.
347
348 =item distmeta
349
350 [version 0.21]
351
352 Creates the F<META.yml> file that describes the distribution.
353
354 F<META.yml> is a file containing various bits of I<metadata> about the
355 distribution.  The metadata includes the distribution name, version,
356 abstract, prerequisites, license, and various other data about the
357 distribution.  This file is created as F<META.yml> in YAML format.
358 It is recommended that the C<YAML::Tiny> module be installed to create it.
359 If the C<YAML::Tiny> module is not installed, an internal module supplied
360 with Module::Build will be used to write the META.yml file, and this
361 will most likely be fine.
362
363 F<META.yml> file must also be listed in F<MANIFEST> - if it's not, a
364 warning will be issued.
365
366 The current version of the F<META.yml> specification can be found at
367 L<http://module-build.sourceforge.net/META-spec-current.html>
368
369 =item distsign
370
371 [version 0.16]
372
373 Uses C<Module::Signature> to create a SIGNATURE file for your
374 distribution, and adds the SIGNATURE file to the distribution's
375 MANIFEST.
376
377 =item disttest
378
379 [version 0.05]
380
381 Performs the 'distdir' action, then switches into that directory and
382 runs a C<perl Build.PL>, followed by the 'build' and 'test' actions in
383 that directory.
384
385 =item docs
386
387 [version 0.20]
388
389 This will generate documentation (e.g. Unix man pages and HTML
390 documents) for any installable items under B<blib/> that
391 contain POD.  If there are no C<bindoc> or C<libdoc> installation
392 targets defined (as will be the case on systems that don't support
393 Unix manpages) no action is taken for manpages.  If there are no
394 C<binhtml> or C<libhtml> installation targets defined no action is
395 taken for HTML documents.
396
397 =item fakeinstall
398
399 [version 0.02]
400
401 This is just like the C<install> action, but it won't actually do
402 anything, it will just report what it I<would> have done if you had
403 actually run the C<install> action.
404
405 =item help
406
407 [version 0.03]
408
409 This action will simply print out a message that is meant to help you
410 use the build process.  It will show you a list of available build
411 actions too.
412
413 With an optional argument specifying an action name (e.g. C<Build help
414 test>), the 'help' action will show you any POD documentation it can
415 find for that action.
416
417 =item html
418
419 [version 0.26]
420
421 This will generate HTML documentation for any binary or library files
422 under B<blib/> that contain POD.  The HTML documentation will only be
423 installed if the install paths can be determined from values in
424 C<Config.pm>.  You can also supply or override install paths on the
425 command line by specifying C<install_path> values for the C<binhtml>
426 and/or C<libhtml> installation targets.
427
428 =item install
429
430 [version 0.01]
431
432 This action will use C<ExtUtils::Install> to install the files from
433 C<blib/> into the system.  See L<"INSTALL PATHS">
434 for details about how Module::Build determines where to install
435 things, and how to influence this process.
436
437 If you want the installation process to look around in C<@INC> for
438 other versions of the stuff you're installing and try to delete it,
439 you can use the C<uninst> parameter, which tells C<ExtUtils::Install> to
440 do so:
441
442   ./Build install uninst=1
443
444 This can be a good idea, as it helps prevent multiple versions of a
445 module from being present on your system, which can be a confusing
446 situation indeed.
447
448 =item installdeps
449
450 [version 0.36]
451
452 This action will use the C<cpan_client> parameter as a command to install
453 missing prerequisites.  You will be prompted whether to install
454 optional dependencies.
455
456 The C<cpan_client> option defaults to 'cpan' but can be set as an option or in
457 F<.modulebuildrc>.  It must be a shell command that takes a list of modules to
458 install as arguments (e.g. 'cpanp -i' for CPANPLUS).  If the program part is a
459 relative path (e.g. 'cpan' or 'cpanp'), it will be located relative to the perl
460 program that executed Build.PL.
461
462   /opt/perl/5.8.9/bin/perl Build.PL
463   ./Build installdeps --cpan_client 'cpanp -i'
464   # installs to 5.8.9
465
466 =item manifest
467
468 [version 0.05]
469
470 This is an action intended for use by module authors, not people
471 installing modules.  It will bring the F<MANIFEST> up to date with the
472 files currently present in the distribution.  You may use a
473 F<MANIFEST.SKIP> file to exclude certain files or directories from
474 inclusion in the F<MANIFEST>.  F<MANIFEST.SKIP> should contain a bunch
475 of regular expressions, one per line.  If a file in the distribution
476 directory matches any of the regular expressions, it won't be included
477 in the F<MANIFEST>.
478
479 The following is a reasonable F<MANIFEST.SKIP> starting point, you can
480 add your own stuff to it:
481
482   ^_build
483   ^Build$
484   ^blib
485   ~$
486   \.bak$
487   ^MANIFEST\.SKIP$
488   CVS
489
490 See the L<distcheck> and L<skipcheck> actions if you want to find out
491 what the C<manifest> action would do, without actually doing anything.
492
493 =item manpages
494
495 [version 0.28]
496
497 This will generate man pages for any binary or library files under
498 B<blib/> that contain POD.  The man pages will only be installed if the
499 install paths can be determined from values in C<Config.pm>.  You can
500 also supply or override install paths by specifying there values on
501 the command line with the C<bindoc> and C<libdoc> installation
502 targets.
503
504 =item pardist
505
506 [version 0.2806]
507
508 Generates a PAR binary distribution for use with L<PAR> or L<PAR::Dist>.
509
510 It requires that the PAR::Dist module (version 0.17 and up) is
511 installed on your system.
512
513 =item ppd
514
515 [version 0.20]
516
517 Build a PPD file for your distribution.
518
519 This action takes an optional argument C<codebase> which is used in
520 the generated PPD file to specify the (usually relative) URL of the
521 distribution.  By default, this value is the distribution name without
522 any path information.
523
524 Example:
525
526   ./Build ppd --codebase "MSWin32-x86-multi-thread/Module-Build-0.21.tar.gz"
527
528 =item ppmdist
529
530 [version 0.23]
531
532 Generates a PPM binary distribution and a PPD description file.  This
533 action also invokes the C<ppd> action, so it can accept the same
534 C<codebase> argument described under that action.
535
536 This uses the same mechanism as the C<dist> action to tar & zip its
537 output, so you can supply C<tar> and/or C<gzip> parameters to affect
538 the result.
539
540 =item prereq_data
541
542 [version 0.32]
543
544 This action prints out a Perl data structure of all prerequisites and the versions
545 required.  The output can be loaded again using C<eval()>.  This can be useful for
546 external tools that wish to query a Build script for prerequisites.
547
548 =item prereq_report
549
550 [version 0.28]
551
552 This action prints out a list of all prerequisites, the versions required, and
553 the versions actually installed.  This can be useful for reviewing the
554 configuration of your system prior to a build, or when compiling data to send
555 for a bug report.
556
557 =item pure_install
558
559 [version 0.28]
560
561 This action is identical to the C<install> action.  In the future,
562 though, when C<install> starts writing to the file 
563 F<$(INSTALLARCHLIB)/perllocal.pod>, C<pure_install> won't, and that
564 will be the only difference between them.
565
566 =item realclean
567
568 [version 0.01]
569
570 This action is just like the C<clean> action, but also removes the
571 C<_build> directory and the C<Build> script.  If you run the
572 C<realclean> action, you are essentially starting over, so you will
573 have to re-create the C<Build> script again.
574
575 =item retest
576
577 [version 0.2806]
578
579 This is just like the C<test> action, but doesn't actually build the
580 distribution first, and doesn't add F<blib/> to the load path, and
581 therefore will test against a I<previously> installed version of the
582 distribution.  This can be used to verify that a certain installed
583 distribution still works, or to see whether newer versions of a
584 distribution still pass the old regression tests, and so on.
585
586 =item skipcheck
587
588 [version 0.05]
589
590 Reports which files are skipped due to the entries in the
591 F<MANIFEST.SKIP> file (See L<manifest> for details)
592
593 =item test
594
595 [version 0.01]
596
597 This will use C<Test::Harness> or C<TAP::Harness> to run any regression
598 tests and report their results. Tests can be defined in the standard
599 places: a file called C<test.pl> in the top-level directory, or several
600 files ending with C<.t> in a C<t/> directory.
601
602 If you want tests to be 'verbose', i.e. show details of test execution
603 rather than just summary information, pass the argument C<verbose=1>.
604
605 If you want to run tests under the perl debugger, pass the argument
606 C<debugger=1>.
607
608 If you want to have Module::Build find test files with different file
609 name extensions, pass the C<test_file_exts> argument with an array
610 of extensions, such as C<[qw( .t .s .z )]>.
611
612 If you want test to be run by C<TAP::Harness>, rather than C<Test::Harness>,
613 pass the argument C<tap_harness_args> as an array reference of arguments to
614 pass to the TAP::Harness constructor.
615
616 In addition, if a file called C<visual.pl> exists in the top-level
617 directory, this file will be executed as a Perl script and its output
618 will be shown to the user.  This is a good place to put speed tests or
619 other tests that don't use the C<Test::Harness> format for output.
620
621 To override the choice of tests to run, you may pass a C<test_files>
622 argument whose value is a whitespace-separated list of test scripts to
623 run.  This is especially useful in development, when you only want to
624 run a single test to see whether you've squashed a certain bug yet:
625
626   ./Build test --test_files t/something_failing.t
627
628 You may also pass several C<test_files> arguments separately:
629
630   ./Build test --test_files t/one.t --test_files t/two.t
631
632 or use a C<glob()>-style pattern:
633
634   ./Build test --test_files 't/01-*.t'
635
636 =item testall
637
638 [version 0.2807]
639
640 [Note: the 'testall' action and the code snippets below are currently
641 in alpha stage, see
642 L<"http://www.nntp.perl.org/group/perl.module.build/2007/03/msg584.html"> ]
643
644 Runs the C<test> action plus each of the C<test$type> actions defined by
645 the keys of the C<test_types> parameter.
646
647 Currently, you need to define the ACTION_test$type method yourself and
648 enumerate them in the test_types parameter.
649
650   my $mb = Module::Build->subclass(
651     code => q(
652       sub ACTION_testspecial { shift->generic_test(type => 'special'); }
653       sub ACTION_testauthor  { shift->generic_test(type => 'author'); }
654     )
655   )->new(
656     ...
657     test_types  => {
658       special => '.st',
659       author  => ['.at', '.pt' ],
660     },
661     ...
662
663 =item testcover
664
665 [version 0.26]
666
667 Runs the C<test> action using C<Devel::Cover>, generating a
668 code-coverage report showing which parts of the code were actually
669 exercised during the tests.
670
671 To pass options to C<Devel::Cover>, set the C<$DEVEL_COVER_OPTIONS>
672 environment variable:
673
674   DEVEL_COVER_OPTIONS=-ignore,Build ./Build testcover
675
676 =item testdb
677
678 [version 0.05]
679
680 This is a synonym for the 'test' action with the C<debugger=1>
681 argument.
682
683 =item testpod
684
685 [version 0.25]
686
687 This checks all the files described in the C<docs> action and 
688 produces C<Test::Harness>-style output.  If you are a module author,
689 this is useful to run before creating a new release.
690
691 =item testpodcoverage
692
693 [version 0.28]
694
695 This checks the pod coverage of the distribution and 
696 produces C<Test::Harness>-style output. If you are a module author,
697 this is useful to run before creating a new release.
698
699 =item versioninstall
700
701 [version 0.16]
702
703 ** Note: since C<only.pm> is so new, and since we just recently added
704 support for it here too, this feature is to be considered
705 experimental. **
706
707 If you have the C<only.pm> module installed on your system, you can
708 use this action to install a module into the version-specific library
709 trees.  This means that you can have several versions of the same
710 module installed and C<use> a specific one like this:
711
712   use only MyModule => 0.55;
713
714 To override the default installation libraries in C<only::config>,
715 specify the C<versionlib> parameter when you run the C<Build.PL> script:
716
717   perl Build.PL --versionlib /my/version/place/
718
719 To override which version the module is installed as, specify the
720 C<versionlib> parameter when you run the C<Build.PL> script:
721
722   perl Build.PL --version 0.50
723
724 See the C<only.pm> documentation for more information on
725 version-specific installs.
726
727 =back
728
729
730 =head1 OPTIONS
731
732 =head2 Command Line Options
733
734 The following options can be used during any invocation of C<Build.PL>
735 or the Build script, during any action.  For information on other
736 options specific to an action, see the documentation for the
737 respective action.
738
739 NOTE: There is some preliminary support for options to use the more
740 familiar long option style.  Most options can be preceded with the
741 C<--> long option prefix, and the underscores changed to dashes
742 (e.g. C<--use-rcfile>).  Additionally, the argument to boolean options is
743 optional, and boolean options can be negated by prefixing them with
744 C<no> or C<no-> (e.g. C<--noverbose> or C<--no-verbose>).
745
746 =over 4
747
748 =item quiet
749
750 Suppress informative messages on output.
751
752 =item verbose
753
754 Display extra information about the Build on output.
755
756 =item cpan_client
757
758 Sets the C<cpan_client> command for use with the C<installdeps> action.
759 See C<installdeps> for more details.
760
761 =item use_rcfile
762
763 Load the F<~/.modulebuildrc> option file.  This option can be set to
764 false to prevent the custom resource file from being loaded.
765
766 =item allow_mb_mismatch
767
768 Suppresses the check upon startup that the version of Module::Build
769 we're now running under is the same version that was initially invoked
770 when building the distribution (i.e. when the C<Build.PL> script was
771 first run).  Use with caution.
772
773 =item debug
774
775 Prints Module::Build debugging information to STDOUT, such as a trace of
776 executed build actions.
777
778 =back
779
780 =head2 Default Options File (F<.modulebuildrc>)
781
782 [version 0.28]
783
784 When Module::Build starts up, it will look first for a file,
785 F<$ENV{HOME}/.modulebuildrc>.  If it's not found there, it will look
786 in the the F<.modulebuildrc> file in the directories referred to by
787 the environment variables C<HOMEDRIVE> + C<HOMEDIR>, C<USERPROFILE>,
788 C<APPDATA>, C<WINDIR>, C<SYS$LOGIN>.  If the file exists, the options
789 specified there will be used as defaults, as if they were typed on the
790 command line.  The defaults can be overridden by specifying new values
791 on the command line.
792
793 The action name must come at the beginning of the line, followed by any
794 amount of whitespace and then the options.  Options are given the same
795 as they would be on the command line.  They can be separated by any
796 amount of whitespace, including newlines, as long there is whitespace at
797 the beginning of each continued line.  Anything following a hash mark (C<#>)
798 is considered a comment, and is stripped before parsing.  If more than
799 one line begins with the same action name, those lines are merged into
800 one set of options.
801
802 Besides the regular actions, there are two special pseudo-actions: the
803 key C<*> (asterisk) denotes any global options that should be applied
804 to all actions, and the key 'Build_PL' specifies options to be applied
805 when you invoke C<perl Build.PL>.
806
807   *           verbose=1   # global options
808   diff        flags=-u
809   install     --install_base /home/ken
810               --install_path html=/home/ken/docs/html
811   installdeps --cpan_client 'cpanp -i'
812
813 If you wish to locate your resource file in a different location, you
814 can set the environment variable C<MODULEBUILDRC> to the complete
815 absolute path of the file containing your options.
816
817 =head2 Environment variables
818
819 =over
820
821 =item MODULEBUILDRC
822
823 [version 0.28]
824
825 Specifies an alternate location for a default options file as described above.
826
827 =item PERL_MB_OPT
828
829 [version 0.36]
830
831 Command line options that are applied to Build.PL or any Build action.  The
832 string is split as the shell would (e.g. whitespace) and the result is
833 prepended to any actual command-line arguments.
834
835 =back
836
837 =head1 INSTALL PATHS
838
839 [version 0.19]
840
841 When you invoke Module::Build's C<build> action, it needs to figure
842 out where to install things.  The nutshell version of how this works
843 is that default installation locations are determined from
844 F<Config.pm>, and they may be overridden by using the C<install_path>
845 parameter.  An C<install_base> parameter lets you specify an
846 alternative installation root like F</home/foo>, and a C<destdir> lets
847 you specify a temporary installation directory like F</tmp/install> in
848 case you want to create bundled-up installable packages.
849
850 Natively, Module::Build provides default installation locations for
851 the following types of installable items:
852
853 =over 4
854
855 =item lib
856
857 Usually pure-Perl module files ending in F<.pm>.
858
859 =item arch
860
861 "Architecture-dependent" module files, usually produced by compiling
862 XS, L<Inline>, or similar code.
863
864 =item script
865
866 Programs written in pure Perl.  In order to improve reuse, try to make
867 these as small as possible - put the code into modules whenever
868 possible.
869
870 =item bin
871
872 "Architecture-dependent" executable programs, i.e. compiled C code or
873 something.  Pretty rare to see this in a perl distribution, but it
874 happens.
875
876 =item bindoc
877
878 Documentation for the stuff in C<script> and C<bin>.  Usually
879 generated from the POD in those files.  Under Unix, these are manual
880 pages belonging to the 'man1' category.
881
882 =item libdoc
883
884 Documentation for the stuff in C<lib> and C<arch>.  This is usually
885 generated from the POD in F<.pm> files.  Under Unix, these are manual
886 pages belonging to the 'man3' category.
887
888 =item binhtml
889
890 This is the same as C<bindoc> above, but applies to HTML documents.
891
892 =item libhtml
893
894 This is the same as C<bindoc> above, but applies to HTML documents.
895
896 =back
897
898 Four other parameters let you control various aspects of how
899 installation paths are determined:
900
901 =over 4
902
903 =item installdirs
904
905 The default destinations for these installable things come from
906 entries in your system's C<Config.pm>.  You can select from three
907 different sets of default locations by setting the C<installdirs>
908 parameter as follows:
909
910                           'installdirs' set to:
911                    core          site                vendor
912
913               uses the following defaults from Config.pm:
914
915   lib     => installprivlib  installsitelib      installvendorlib
916   arch    => installarchlib  installsitearch     installvendorarch
917   script  => installscript   installsitebin      installvendorbin
918   bin     => installbin      installsitebin      installvendorbin
919   bindoc  => installman1dir  installsiteman1dir  installvendorman1dir
920   libdoc  => installman3dir  installsiteman3dir  installvendorman3dir
921   binhtml => installhtml1dir installsitehtml1dir installvendorhtml1dir [*]
922   libhtml => installhtml3dir installsitehtml3dir installvendorhtml3dir [*]
923
924   * Under some OS (eg. MSWin32) the destination for HTML documents is
925     determined by the C<Config.pm> entry C<installhtmldir>.
926
927 The default value of C<installdirs> is "site".  If you're creating
928 vendor distributions of module packages, you may want to do something
929 like this:
930
931   perl Build.PL --installdirs vendor
932
933 or
934
935   ./Build install --installdirs vendor
936
937 If you're installing an updated version of a module that was included
938 with perl itself (i.e. a "core module"), then you may set
939 C<installdirs> to "core" to overwrite the module in its present
940 location.
941
942 (Note that the 'script' line is different from C<MakeMaker> -
943 unfortunately there's no such thing as "installsitescript" or
944 "installvendorscript" entry in C<Config.pm>, so we use the
945 "installsitebin" and "installvendorbin" entries to at least get the
946 general location right.  In the future, if C<Config.pm> adds some more
947 appropriate entries, we'll start using those.)
948
949 =item install_path
950
951 Once the defaults have been set, you can override them.
952
953 On the command line, that would look like this:
954
955   perl Build.PL --install_path lib=/foo/lib --install_path arch=/foo/lib/arch
956
957 or this:
958
959   ./Build install --install_path lib=/foo/lib --install_path arch=/foo/lib/arch
960
961 =item install_base
962
963 You can also set the whole bunch of installation paths by supplying the
964 C<install_base> parameter to point to a directory on your system.  For
965 instance, if you set C<install_base> to "/home/ken" on a Linux
966 system, you'll install as follows:
967
968   lib     => /home/ken/lib/perl5
969   arch    => /home/ken/lib/perl5/i386-linux
970   script  => /home/ken/bin
971   bin     => /home/ken/bin
972   bindoc  => /home/ken/man/man1
973   libdoc  => /home/ken/man/man3
974   binhtml => /home/ken/html
975   libhtml => /home/ken/html
976
977 Note that this is I<different> from how C<MakeMaker>'s C<PREFIX>
978 parameter works.  C<install_base> just gives you a default layout under the
979 directory you specify, which may have little to do with the
980 C<installdirs=site> layout.
981
982 The exact layout under the directory you specify may vary by system -
983 we try to do the "sensible" thing on each platform.
984
985 =item destdir
986
987 If you want to install everything into a temporary directory first
988 (for instance, if you want to create a directory tree that a package
989 manager like C<rpm> or C<dpkg> could create a package from), you can
990 use the C<destdir> parameter:
991
992   perl Build.PL --destdir /tmp/foo
993
994 or
995
996   ./Build install --destdir /tmp/foo
997
998 This will effectively install to "/tmp/foo/$sitelib",
999 "/tmp/foo/$sitearch", and the like, except that it will use
1000 C<File::Spec> to make the pathnames work correctly on whatever
1001 platform you're installing on.
1002
1003 =item prefix
1004
1005 Provided for compatibility with C<ExtUtils::MakeMaker>'s PREFIX argument.
1006 C<prefix> should be used when you wish Module::Build to install your
1007 modules, documentation and scripts in the same place
1008 C<ExtUtils::MakeMaker> does.
1009
1010 The following are equivalent.
1011
1012     perl Build.PL --prefix /tmp/foo
1013     perl Makefile.PL PREFIX=/tmp/foo
1014
1015 Because of the very complex nature of the prefixification logic, the
1016 behavior of PREFIX in C<MakeMaker> has changed subtly over time.
1017 Module::Build's --prefix logic is equivalent to the PREFIX logic found
1018 in C<ExtUtils::MakeMaker> 6.30.
1019
1020 If you do not need to retain compatibility with C<ExtUtils::MakeMaker> or
1021 are starting a fresh Perl installation we recommend you use
1022 C<install_base> instead (and C<INSTALL_BASE> in C<ExtUtils::MakeMaker>).
1023 See L<Module::Build::Cookbook/Instaling in the same location as
1024 ExtUtils::MakeMaker> for further information.
1025
1026
1027 =back
1028
1029
1030 =head1 MOTIVATIONS
1031
1032 There are several reasons I wanted to start over, and not just fix
1033 what I didn't like about C<MakeMaker>:
1034
1035 =over 4
1036
1037 =item *
1038
1039 I don't like the core idea of C<MakeMaker>, namely that C<make> should be
1040 involved in the build process.  Here are my reasons:
1041
1042 =over 4
1043
1044 =item +
1045
1046 When a person is installing a Perl module, what can you assume about
1047 their environment?  Can you assume they have C<make>?  No, but you can
1048 assume they have some version of Perl.
1049
1050 =item +
1051
1052 When a person is writing a Perl module for intended distribution, can
1053 you assume that they know how to build a Makefile, so they can
1054 customize their build process?  No, but you can assume they know Perl,
1055 and could customize that way.
1056
1057 =back
1058
1059 For years, these things have been a barrier to people getting the
1060 build/install process to do what they want.
1061
1062 =item *
1063
1064 There are several architectural decisions in C<MakeMaker> that make it
1065 very difficult to customize its behavior.  For instance, when using
1066 C<MakeMaker> you do C<use ExtUtils::MakeMaker>, but the object created in
1067 C<WriteMakefile()> is actually blessed into a package name that's
1068 created on the fly, so you can't simply subclass
1069 C<ExtUtils::MakeMaker>.  There is a workaround C<MY> package that lets
1070 you override certain C<MakeMaker> methods, but only certain explicitly
1071 preselected (by C<MakeMaker>) methods can be overridden.  Also, the method
1072 of customization is very crude: you have to modify a string containing
1073 the Makefile text for the particular target.  Since these strings
1074 aren't documented, and I<can't> be documented (they take on different
1075 values depending on the platform, version of perl, version of
1076 C<MakeMaker>, etc.), you have no guarantee that your modifications will
1077 work on someone else's machine or after an upgrade of C<MakeMaker> or
1078 perl.
1079
1080 =item *
1081
1082 It is risky to make major changes to C<MakeMaker>, since it does so many
1083 things, is so important, and generally works.  C<Module::Build> is an
1084 entirely separate package so that I can work on it all I want, without
1085 worrying about backward compatibility.
1086
1087 =item *
1088
1089 Finally, Perl is said to be a language for system administration.
1090 Could it really be the case that Perl isn't up to the task of building
1091 and installing software?  Even if that software is a bunch of stupid
1092 little C<.pm> files that just need to be copied from one place to
1093 another?  My sense was that we could design a system to accomplish
1094 this in a flexible, extensible, and friendly manner.  Or die trying.
1095
1096 =back
1097
1098
1099 =head1 TO DO
1100
1101 The current method of relying on time stamps to determine whether a
1102 derived file is out of date isn't likely to scale well, since it
1103 requires tracing all dependencies backward, it runs into problems on
1104 NFS, and it's just generally flimsy.  It would be better to use an MD5
1105 signature or the like, if available.  See C<cons> for an example.
1106
1107  - append to perllocal.pod
1108  - add a 'plugin' functionality
1109
1110
1111 =head1 AUTHOR
1112
1113 Ken Williams <kwilliams@cpan.org>
1114
1115 Development questions, bug reports, and patches should be sent to the
1116 Module-Build mailing list at <module-build@perl.org>.
1117
1118 Bug reports are also welcome at
1119 <http://rt.cpan.org/NoAuth/Bugs.html?Dist=Module-Build>.
1120
1121 The latest development version is available from the Subversion
1122 repository at <https://svn.perl.org/modules/Module-Build/trunk/>
1123
1124
1125 =head1 COPYRIGHT
1126
1127 Copyright (c) 2001-2006 Ken Williams.  All rights reserved.
1128
1129 This library is free software; you can redistribute it and/or
1130 modify it under the same terms as Perl itself.
1131
1132
1133 =head1 SEE ALSO
1134
1135 perl(1), L<Module::Build::Cookbook>, L<Module::Build::Authoring>,
1136 L<Module::Build::API>, L<ExtUtils::MakeMaker>, L<YAML::Tiny>
1137
1138 F<META.yml> Specification:
1139 L<http://module-build.sourceforge.net/META-spec-current.html>
1140
1141 L<http://www.dsmit.com/cons/>
1142
1143 L<http://search.cpan.org/dist/PerlBuildSystem/>
1144
1145 =cut