This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
pod updates (from David Adler, M J T Guy)
[perl5.git] / pod / perlsyn.pod
1 =head1 NAME
2
3 perlsyn - Perl syntax
4
5 =head1 DESCRIPTION
6
7 A Perl script consists of a sequence of declarations and statements.
8 The sequence of statements is executed just once, unlike in B<sed>
9 and B<awk> scripts, where the sequence of statements is executed
10 for each input line.  While this means that you must explicitly
11 loop over the lines of your input file (or files), it also means
12 you have much more control over which files and which lines you look at.
13 (Actually, I'm lying--it is possible to do an implicit loop with
14 either the B<-n> or B<-p> switch.  It's just not the mandatory
15 default like it is in B<sed> and B<awk>.)
16
17 Perl is, for the most part, a free-form language.  (The only exception
18 to this is format declarations, for obvious reasons.)  Text from a
19 C<"#"> character until the end of the line is a comment, and is
20 ignored.  If you attempt to use C</* */> C-style comments, it will be
21 interpreted either as division or pattern matching, depending on the
22 context, and C++ C<//> comments just look like a null regular
23 expression, so don't do that.
24
25 =head2 Declarations
26
27 The only things you need to declare in Perl are report formats
28 and subroutines--and even undefined subroutines can be handled
29 through AUTOLOAD.  A variable holds the undefined value (C<undef>)
30 until it has been assigned a defined value, which is anything
31 other than C<undef>.  When used as a number, C<undef> is treated
32 as C<0>; when used as a string, it is treated the empty string,
33 C<"">; and when used as a reference that isn't being assigned
34 to, it is treated as an error.  If you enable warnings, you'll
35 be notified of an uninitialized value whenever you treat C<undef>
36 as a string or a number.  Well, usually.  Boolean ("don't-care")
37 contexts and operators such as C<++>, C<-->, C<+=>, C<-=>, and
38 C<.=> are always exempt from such warnings.
39
40 A declaration can be put anywhere a statement can, but has no effect on
41 the execution of the primary sequence of statements--declarations all
42 take effect at compile time.  Typically all the declarations are put at
43 the beginning or the end of the script.  However, if you're using
44 lexically-scoped private variables created with C<my()>, you'll
45 have to make sure
46 your format or subroutine definition is within the same block scope
47 as the my if you expect to be able to access those private variables.
48
49 Declaring a subroutine allows a subroutine name to be used as if it were a
50 list operator from that point forward in the program.  You can declare a
51 subroutine without defining it by saying C<sub name>, thus:
52
53     sub myname;
54     $me = myname $0             or die "can't get myname";
55
56 Note that my() functions as a list operator, not as a unary operator; so
57 be careful to use C<or> instead of C<||> in this case.  However, if
58 you were to declare the subroutine as C<sub myname ($)>, then
59 C<myname> would function as a unary operator, so either C<or> or
60 C<||> would work.
61
62 Subroutines declarations can also be loaded up with the C<require> statement
63 or both loaded and imported into your namespace with a C<use> statement.
64 See L<perlmod> for details on this.
65
66 A statement sequence may contain declarations of lexically-scoped
67 variables, but apart from declaring a variable name, the declaration acts
68 like an ordinary statement, and is elaborated within the sequence of
69 statements as if it were an ordinary statement.  That means it actually
70 has both compile-time and run-time effects.
71
72 =head2 Simple statements
73
74 The only kind of simple statement is an expression evaluated for its
75 side effects.  Every simple statement must be terminated with a
76 semicolon, unless it is the final statement in a block, in which case
77 the semicolon is optional.  (A semicolon is still encouraged there if the
78 block takes up more than one line, because you may eventually add another line.)
79 Note that there are some operators like C<eval {}> and C<do {}> that look
80 like compound statements, but aren't (they're just TERMs in an expression),
81 and thus need an explicit termination if used as the last item in a statement.
82
83 Any simple statement may optionally be followed by a I<SINGLE> modifier,
84 just before the terminating semicolon (or block ending).  The possible
85 modifiers are:
86
87     if EXPR
88     unless EXPR
89     while EXPR
90     until EXPR
91     foreach EXPR
92
93 The C<if> and C<unless> modifiers have the expected semantics,
94 presuming you're a speaker of English.  The C<foreach> modifier is an
95 iterator:  For each value in EXPR, it aliases C<$_> to the value and
96 executes the statement.  The C<while> and C<until> modifiers have the
97 usual "C<while> loop" semantics (conditional evaluated first), except
98 when applied to a C<do>-BLOCK (or to the deprecated C<do>-SUBROUTINE
99 statement), in which case the block executes once before the
100 conditional is evaluated.  This is so that you can write loops like:
101
102     do {
103         $line = <STDIN>;
104         ...
105     } until $line  eq ".\n";
106
107 See L<perlfunc/do>.  Note also that the loop control statements described
108 later will I<NOT> work in this construct, because modifiers don't take
109 loop labels.  Sorry.  You can always put another block inside of it
110 (for C<next>) or around it (for C<last>) to do that sort of thing.
111 For C<next>, just double the braces:
112
113     do {{
114         next if $x == $y;
115         # do something here
116     }} until $x++ > $z;
117
118 For C<last>, you have to be more elaborate:
119
120     LOOP: { 
121             do {
122                 last if $x = $y**2;
123                 # do something here
124             } while $x++ <= $z;
125     }
126
127 =head2 Compound statements
128
129 In Perl, a sequence of statements that defines a scope is called a block.
130 Sometimes a block is delimited by the file containing it (in the case
131 of a required file, or the program as a whole), and sometimes a block
132 is delimited by the extent of a string (in the case of an eval).
133
134 But generally, a block is delimited by curly brackets, also known as braces.
135 We will call this syntactic construct a BLOCK.
136
137 The following compound statements may be used to control flow:
138
139     if (EXPR) BLOCK
140     if (EXPR) BLOCK else BLOCK
141     if (EXPR) BLOCK elsif (EXPR) BLOCK ... else BLOCK
142     LABEL while (EXPR) BLOCK
143     LABEL while (EXPR) BLOCK continue BLOCK
144     LABEL for (EXPR; EXPR; EXPR) BLOCK
145     LABEL foreach VAR (LIST) BLOCK
146     LABEL foreach VAR (LIST) BLOCK continue BLOCK
147     LABEL BLOCK continue BLOCK
148
149 Note that, unlike C and Pascal, these are defined in terms of BLOCKs,
150 not statements.  This means that the curly brackets are I<required>--no
151 dangling statements allowed.  If you want to write conditionals without
152 curly brackets there are several other ways to do it.  The following
153 all do the same thing:
154
155     if (!open(FOO)) { die "Can't open $FOO: $!"; }
156     die "Can't open $FOO: $!" unless open(FOO);
157     open(FOO) or die "Can't open $FOO: $!";     # FOO or bust!
158     open(FOO) ? 'hi mom' : die "Can't open $FOO: $!";
159                         # a bit exotic, that last one
160
161 The C<if> statement is straightforward.  Because BLOCKs are always
162 bounded by curly brackets, there is never any ambiguity about which
163 C<if> an C<else> goes with.  If you use C<unless> in place of C<if>,
164 the sense of the test is reversed.
165
166 The C<while> statement executes the block as long as the expression is
167 true (does not evaluate to the null string C<""> or C<0> or C<"0">).
168 The LABEL is optional, and if present, consists of an identifier followed
169 by a colon.  The LABEL identifies the loop for the loop control
170 statements C<next>, C<last>, and C<redo>.
171 If the LABEL is omitted, the loop control statement
172 refers to the innermost enclosing loop.  This may include dynamically
173 looking back your call-stack at run time to find the LABEL.  Such
174 desperate behavior triggers a warning if you use the B<-w> flag.
175 Unlike a C<foreach> statement, a C<while> statement never implicitly
176 localises any variables.
177
178 If there is a C<continue> BLOCK, it is always executed just before the
179 conditional is about to be evaluated again, just like the third part of a
180 C<for> loop in C.  Thus it can be used to increment a loop variable, even
181 when the loop has been continued via the C<next> statement (which is
182 similar to the C C<continue> statement).
183
184 =head2 Loop Control
185
186 The C<next> command is like the C<continue> statement in C; it starts
187 the next iteration of the loop:
188
189     LINE: while (<STDIN>) {
190         next LINE if /^#/;      # discard comments
191         ...
192     }
193
194 The C<last> command is like the C<break> statement in C (as used in
195 loops); it immediately exits the loop in question.  The
196 C<continue> block, if any, is not executed:
197
198     LINE: while (<STDIN>) {
199         last LINE if /^$/;      # exit when done with header
200         ...
201     }
202
203 The C<redo> command restarts the loop block without evaluating the
204 conditional again.  The C<continue> block, if any, is I<not> executed.
205 This command is normally used by programs that want to lie to themselves
206 about what was just input.
207
208 For example, when processing a file like F</etc/termcap>.
209 If your input lines might end in backslashes to indicate continuation, you
210 want to skip ahead and get the next record.
211
212     while (<>) {
213         chomp;
214         if (s/\\$//) {
215             $_ .= <>;
216             redo unless eof();
217         }
218         # now process $_
219     }
220
221 which is Perl short-hand for the more explicitly written version:
222
223     LINE: while (defined($line = <ARGV>)) {
224         chomp($line);
225         if ($line =~ s/\\$//) {
226             $line .= <ARGV>;
227             redo LINE unless eof(); # not eof(ARGV)!
228         }
229         # now process $line
230     }
231
232 Note that if there were a C<continue> block on the above code, it would get
233 executed even on discarded lines.  This is often used to reset line counters 
234 or C<?pat?> one-time matches.
235
236     # inspired by :1,$g/fred/s//WILMA/
237     while (<>) {
238         ?(fred)?    && s//WILMA $1 WILMA/;
239         ?(barney)?  && s//BETTY $1 BETTY/;
240         ?(homer)?   && s//MARGE $1 MARGE/;
241     } continue {
242         print "$ARGV $.: $_";
243         close ARGV  if eof();           # reset $.
244         reset       if eof();           # reset ?pat?
245     }
246
247 If the word C<while> is replaced by the word C<until>, the sense of the
248 test is reversed, but the conditional is still tested before the first
249 iteration.
250
251 The loop control statements don't work in an C<if> or C<unless>, since
252 they aren't loops.  You can double the braces to make them such, though.
253
254     if (/pattern/) {{
255         next if /fred/;
256         next if /barney/;
257         # so something here
258     }}
259
260 The form C<while/if BLOCK BLOCK>, available in Perl 4, is no longer
261 available.   Replace any occurrence of C<if BLOCK> by C<if (do BLOCK)>.
262
263 =head2 For Loops
264
265 Perl's C-style C<for> loop works exactly like the corresponding C<while> loop;
266 that means that this:
267
268     for ($i = 1; $i < 10; $i++) {
269         ...
270     }
271
272 is the same as this:
273
274     $i = 1;
275     while ($i < 10) {
276         ...
277     } continue {
278         $i++;
279     }
280
281 (There is one minor difference: The first form implies a lexical scope
282 for variables declared with C<my> in the initialization expression.)
283
284 Besides the normal array index looping, C<for> can lend itself
285 to many other interesting applications.  Here's one that avoids the
286 problem you get into if you explicitly test for end-of-file on
287 an interactive file descriptor causing your program to appear to
288 hang.
289
290     $on_a_tty = -t STDIN && -t STDOUT;
291     sub prompt { print "yes? " if $on_a_tty }
292     for ( prompt(); <STDIN>; prompt() ) {
293         # do something
294     }
295
296 =head2 Foreach Loops
297
298 The C<foreach> loop iterates over a normal list value and sets the
299 variable VAR to be each element of the list in turn.  If the variable
300 is preceded with the keyword C<my>, then it is lexically scoped, and
301 is therefore visible only within the loop.  Otherwise, the variable is
302 implicitly local to the loop and regains its former value upon exiting
303 the loop.  If the variable was previously declared with C<my>, it uses
304 that variable instead of the global one, but it's still localized to
305 the loop.  
306
307 The C<foreach> keyword is actually a synonym for the C<for> keyword, so
308 you can use C<foreach> for readability or C<for> for brevity.  (Or because
309 the Bourne shell is more familiar to you than I<csh>, so writing C<for>
310 comes more naturally.)  If VAR is omitted, C<$_> is set to each value.
311 If any element of LIST is an lvalue, you can modify it by modifying VAR
312 inside the loop.  That's because the C<foreach> loop index variable is
313 an implicit alias for each item in the list that you're looping over.
314
315 If any part of LIST is an array, C<foreach> will get very confused if
316 you add or remove elements within the loop body, for example with
317 C<splice>.   So don't do that.
318
319 C<foreach> probably won't do what you expect if VAR is a tied or other
320 special variable.   Don't do that either.
321
322 Examples:
323
324     for (@ary) { s/foo/bar/ }
325
326     foreach my $elem (@elements) {
327         $elem *= 2;
328     }
329
330     for $count (10,9,8,7,6,5,4,3,2,1,'BOOM') {
331         print $count, "\n"; sleep(1);
332     }
333
334     for (1..15) { print "Merry Christmas\n"; }
335
336     foreach $item (split(/:[\\\n:]*/, $ENV{TERMCAP})) {
337         print "Item: $item\n";
338     }
339
340 Here's how a C programmer might code up a particular algorithm in Perl:
341
342     for (my $i = 0; $i < @ary1; $i++) {
343         for (my $j = 0; $j < @ary2; $j++) {
344             if ($ary1[$i] > $ary2[$j]) {
345                 last; # can't go to outer :-(
346             }
347             $ary1[$i] += $ary2[$j];
348         }
349         # this is where that last takes me
350     }
351
352 Whereas here's how a Perl programmer more comfortable with the idiom might
353 do it:
354
355     OUTER: foreach my $wid (@ary1) {
356     INNER:   foreach my $jet (@ary2) {
357                 next OUTER if $wid > $jet;
358                 $wid += $jet;
359              }
360           }
361
362 See how much easier this is?  It's cleaner, safer, and faster.  It's
363 cleaner because it's less noisy.  It's safer because if code gets added
364 between the inner and outer loops later on, the new code won't be
365 accidentally executed.  The C<next> explicitly iterates the other loop
366 rather than merely terminating the inner one.  And it's faster because
367 Perl executes a C<foreach> statement more rapidly than it would the
368 equivalent C<for> loop.
369
370 =head2 Basic BLOCKs and Switch Statements
371
372 A BLOCK by itself (labeled or not) is semantically equivalent to a
373 loop that executes once.  Thus you can use any of the loop control
374 statements in it to leave or restart the block.  (Note that this is
375 I<NOT> true in C<eval{}>, C<sub{}>, or contrary to popular belief
376 C<do{}> blocks, which do I<NOT> count as loops.)  The C<continue>
377 block is optional.
378
379 The BLOCK construct is particularly nice for doing case
380 structures.
381
382     SWITCH: {
383         if (/^abc/) { $abc = 1; last SWITCH; }
384         if (/^def/) { $def = 1; last SWITCH; }
385         if (/^xyz/) { $xyz = 1; last SWITCH; }
386         $nothing = 1;
387     }
388
389 There is no official C<switch> statement in Perl, because there are
390 already several ways to write the equivalent.  In addition to the
391 above, you could write
392
393     SWITCH: {
394         $abc = 1, last SWITCH  if /^abc/;
395         $def = 1, last SWITCH  if /^def/;
396         $xyz = 1, last SWITCH  if /^xyz/;
397         $nothing = 1;
398     }
399
400 (That's actually not as strange as it looks once you realize that you can
401 use loop control "operators" within an expression,  That's just the normal
402 C comma operator.)
403
404 or
405
406     SWITCH: {
407         /^abc/ && do { $abc = 1; last SWITCH; };
408         /^def/ && do { $def = 1; last SWITCH; };
409         /^xyz/ && do { $xyz = 1; last SWITCH; };
410         $nothing = 1;
411     }
412
413 or formatted so it stands out more as a "proper" C<switch> statement:
414
415     SWITCH: {
416         /^abc/      && do {
417                             $abc = 1;
418                             last SWITCH;
419                        };
420
421         /^def/      && do {
422                             $def = 1;
423                             last SWITCH;
424                        };
425
426         /^xyz/      && do {
427                             $xyz = 1;
428                             last SWITCH;
429                         };
430         $nothing = 1;
431     }
432
433 or
434
435     SWITCH: {
436         /^abc/ and $abc = 1, last SWITCH;
437         /^def/ and $def = 1, last SWITCH;
438         /^xyz/ and $xyz = 1, last SWITCH;
439         $nothing = 1;
440     }
441
442 or even, horrors,
443
444     if (/^abc/)
445         { $abc = 1 }
446     elsif (/^def/)
447         { $def = 1 }
448     elsif (/^xyz/)
449         { $xyz = 1 }
450     else
451         { $nothing = 1 }
452
453 A common idiom for a C<switch> statement is to use C<foreach>'s aliasing to make
454 a temporary assignment to C<$_> for convenient matching:
455
456     SWITCH: for ($where) {
457                 /In Card Names/     && do { push @flags, '-e'; last; };
458                 /Anywhere/          && do { push @flags, '-h'; last; };
459                 /In Rulings/        && do {                    last; };
460                 die "unknown value for form variable where: `$where'";
461             }
462
463 Another interesting approach to a switch statement is arrange
464 for a C<do> block to return the proper value:
465
466     $amode = do {
467         if     ($flag & O_RDONLY) { "r" }       # XXX: isn't this 0?
468         elsif  ($flag & O_WRONLY) { ($flag & O_APPEND) ? "a" : "w" }
469         elsif  ($flag & O_RDWR)   {
470             if ($flag & O_CREAT)  { "w+" }
471             else                  { ($flag & O_APPEND) ? "a+" : "r+" }
472         }
473     };
474
475 Or 
476
477         print do {
478             ($flags & O_WRONLY) ? "write-only"          :
479             ($flags & O_RDWR)   ? "read-write"          :
480                                   "read-only";
481         };
482
483 Or if you are certainly that all the C<&&> clauses are true, you can use
484 something like this, which "switches" on the value of the
485 C<HTTP_USER_AGENT> envariable.
486
487     #!/usr/bin/perl 
488     # pick out jargon file page based on browser
489     $dir = 'http://www.wins.uva.nl/~mes/jargon';
490     for ($ENV{HTTP_USER_AGENT}) { 
491         $page  =    /Mac/            && 'm/Macintrash.html'
492                  || /Win(dows )?NT/  && 'e/evilandrude.html'
493                  || /Win|MSIE|WebTV/ && 'm/MicroslothWindows.html'
494                  || /Linux/          && 'l/Linux.html'
495                  || /HP-UX/          && 'h/HP-SUX.html'
496                  || /SunOS/          && 's/ScumOS.html'
497                  ||                     'a/AppendixB.html';
498     }
499     print "Location: $dir/$page\015\012\015\012";
500
501 That kind of switch statement only works when you know the C<&&> clauses
502 will be true.  If you don't, the previous C<?:> example should be used.
503
504 You might also consider writing a hash of subroutine references
505 instead of synthesizing a C<switch> statement.
506
507 =head2 Goto
508
509 Although not for the faint of heart, Perl does support a C<goto>
510 statement.  There are three forms: C<goto>-LABEL, C<goto>-EXPR, and
511 C<goto>-&NAME.  A loop's LABEL is not actually a valid target for
512 a C<goto>; it's just the name of the loop.
513
514 The C<goto>-LABEL form finds the statement labeled with LABEL and resumes
515 execution there.  It may not be used to go into any construct that
516 requires initialization, such as a subroutine or a C<foreach> loop.  It
517 also can't be used to go into a construct that is optimized away.  It
518 can be used to go almost anywhere else within the dynamic scope,
519 including out of subroutines, but it's usually better to use some other
520 construct such as C<last> or C<die>.  The author of Perl has never felt the
521 need to use this form of C<goto> (in Perl, that is--C is another matter).
522
523 The C<goto>-EXPR form expects a label name, whose scope will be resolved
524 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
525 necessarily recommended if you're optimizing for maintainability:
526
527     goto ("FOO", "BAR", "GLARCH")[$i];
528
529 The C<goto>-&NAME form is highly magical, and substitutes a call to the
530 named subroutine for the currently running subroutine.  This is used by
531 C<AUTOLOAD()> subroutines that wish to load another subroutine and then
532 pretend that the other subroutine had been called in the first place
533 (except that any modifications to C<@_> in the current subroutine are
534 propagated to the other subroutine.)  After the C<goto>, not even C<caller()>
535 will be able to tell that this routine was called first.
536
537 In almost all cases like this, it's usually a far, far better idea to use the
538 structured control flow mechanisms of C<next>, C<last>, or C<redo> instead of
539 resorting to a C<goto>.  For certain applications, the catch and throw pair of
540 C<eval{}> and die() for exception processing can also be a prudent approach.
541
542 =head2 PODs: Embedded Documentation
543
544 Perl has a mechanism for intermixing documentation with source code.
545 While it's expecting the beginning of a new statement, if the compiler
546 encounters a line that begins with an equal sign and a word, like this
547
548     =head1 Here There Be Pods!
549
550 Then that text and all remaining text up through and including a line
551 beginning with C<=cut> will be ignored.  The format of the intervening
552 text is described in L<perlpod>.
553
554 This allows you to intermix your source code
555 and your documentation text freely, as in
556
557     =item snazzle($)
558
559     The snazzle() function will behave in the most spectacular
560     form that you can possibly imagine, not even excepting
561     cybernetic pyrotechnics.
562
563     =cut back to the compiler, nuff of this pod stuff!
564
565     sub snazzle($) {
566         my $thingie = shift;
567         .........
568     }
569
570 Note that pod translators should look at only paragraphs beginning
571 with a pod directive (it makes parsing easier), whereas the compiler
572 actually knows to look for pod escapes even in the middle of a
573 paragraph.  This means that the following secret stuff will be
574 ignored by both the compiler and the translators.
575
576     $a=3;
577     =secret stuff
578      warn "Neither POD nor CODE!?"
579     =cut back
580     print "got $a\n";
581
582 You probably shouldn't rely upon the C<warn()> being podded out forever.
583 Not all pod translators are well-behaved in this regard, and perhaps
584 the compiler will become pickier.
585
586 One may also use pod directives to quickly comment out a section
587 of code.
588
589 =head2 Plain Old Comments (Not!)
590
591 Much like the C preprocessor, Perl can process line directives.  Using
592 this, one can control Perl's idea of filenames and line numbers in
593 error or warning messages (especially for strings that are processed
594 with C<eval()>).  The syntax for this mechanism is the same as for most
595 C preprocessors: it matches the regular expression
596 C</^#\s*line\s+(\d+)\s*(?:\s"([^"]*)")?/> with C<$1> being the line
597 number for the next line, and C<$2> being the optional filename
598 (specified within quotes).
599
600 Here are some examples that you should be able to type into your command
601 shell:
602
603     % perl
604     # line 200 "bzzzt"
605     # the `#' on the previous line must be the first char on line
606     die 'foo';
607     __END__
608     foo at bzzzt line 201.
609
610     % perl
611     # line 200 "bzzzt"
612     eval qq[\n#line 2001 ""\ndie 'foo']; print $@;
613     __END__
614     foo at - line 2001.
615
616     % perl
617     eval qq[\n#line 200 "foo bar"\ndie 'foo']; print $@;
618     __END__
619     foo at foo bar line 200.
620
621     % perl
622     # line 345 "goop"
623     eval "\n#line " . __LINE__ . ' "' . __FILE__ ."\"\ndie 'foo'";
624     print $@;
625     __END__
626     foo at goop line 345.
627
628 =cut