This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
0ae1758c63e190f8379208c0eaedb3ae084bc387
[perl5.git] / pod / perlrecharclass.pod
1 =head1 NAME
2 X<character class>
3
4 perlrecharclass - Perl Regular Expression Character Classes
5
6 =head1 DESCRIPTION
7
8 The top level documentation about Perl regular expressions
9 is found in L<perlre>.
10
11 This manual page discusses the syntax and use of character
12 classes in Perl regular expressions.
13
14 A character class is a way of denoting a set of characters
15 in such a way that one character of the set is matched.
16 It's important to remember that: matching a character class
17 consumes exactly one character in the source string. (The source
18 string is the string the regular expression is matched against.)
19
20 There are three types of character classes in Perl regular
21 expressions: the dot, backslash sequences, and the form enclosed in square
22 brackets.  Keep in mind, though, that often the term "character class" is used
23 to mean just the bracketed form.  Certainly, most Perl documentation does that.
24
25 =head2 The dot
26
27 The dot (or period), C<.> is probably the most used, and certainly
28 the most well-known character class. By default, a dot matches any
29 character, except for the newline. The default can be changed to
30 add matching the newline by using the I<single line> modifier: either
31 for the entire regular expression with the C</s> modifier, or
32 locally with C<(?s)>.  (The experimental C<\N> backslash sequence, described
33 below, matches any character except newline without regard to the
34 I<single line> modifier.)
35
36 Here are some examples:
37
38  "a"  =~  /./       # Match
39  "."  =~  /./       # Match
40  ""   =~  /./       # No match (dot has to match a character)
41  "\n" =~  /./       # No match (dot does not match a newline)
42  "\n" =~  /./s      # Match (global 'single line' modifier)
43  "\n" =~  /(?s:.)/  # Match (local 'single line' modifier)
44  "ab" =~  /^.$/     # No match (dot matches one character)
45
46 =head2 Backslash sequences
47 X<\w> X<\W> X<\s> X<\S> X<\d> X<\D> X<\p> X<\P> 
48 X<\N> X<\v> X<\V> X<\h> X<\H>
49 X<word> X<whitespace>
50
51 A backslash sequence is a sequence of characters, the first one of which is a
52 backslash.  Perl ascribes special meaning to many such sequences, and some of
53 these are character classes.  That is, they match a single character each,
54 provided that the character belongs to the specific set of characters defined
55 by the sequence.
56
57 Here's a list of the backslash sequences that are character classes.  They
58 are discussed in more detail below.  (For the backslash sequences that aren't
59 character classes, see L<perlrebackslash>.)
60
61  \d             Match a decimal digit character.
62  \D             Match a non-decimal-digit character.
63  \w             Match a "word" character.
64  \W             Match a non-"word" character.
65  \s             Match a whitespace character.
66  \S             Match a non-whitespace character.
67  \h             Match a horizontal whitespace character.
68  \H             Match a character that isn't horizontal whitespace.
69  \v             Match a vertical whitespace character.
70  \V             Match a character that isn't vertical whitespace.
71  \N             Match a character that isn't a newline.  Experimental.
72  \pP, \p{Prop}  Match a character that has the given Unicode property.
73  \PP, \P{Prop}  Match a character that doesn't have the Unicode property
74
75 =head3 Digits
76
77 C<\d> matches a single character that is considered to be a decimal I<digit>.
78 What is considered a decimal digit depends on several factors, detailed
79 below in L</Locale, EBCDIC, Unicode and UTF-8>.  If those factors
80 indicate a Unicode interpretation, C<\d> not only matches the digits
81 '0' - '9', but also Arabic, Devanagari and digits from other languages.
82 Otherwise, if there is a locale in effect, it will match whatever
83 characters the locale considers decimal digits.  Without a locale, C<\d>
84 matches just the digits '0' to '9'.
85
86 Unicode digits may cause some confusion, and some security issues.  In UTF-8
87 strings, unless the C<"a"> modifier is specified, C<\d> matches the same
88 characters matched by
89 C<\p{General_Category=Decimal_Number}>, or synonymously,
90 C<\p{General_Category=Digit}>.  Starting with Unicode version 4.1, this is the
91 same set of characters matched by C<\p{Numeric_Type=Decimal}>.  
92
93 But Unicode also has a different property with a similar name,
94 C<\p{Numeric_Type=Digit}>, which matches a completely different set of
95 characters.  These characters are things such as subscripts.
96
97 The design intent is for C<\d> to match all the digits (and no other characters)
98 that can be used with "normal" big-endian positional decimal syntax, whereby a
99 sequence of such digits {N0, N1, N2, ...Nn} has the numeric value (...(N0 * 10
100 + N1) * 10 + N2) * 10 ... + Nn).  In Unicode 5.2, the Tamil digits (U+0BE6 -
101 U+0BEF) can also legally be used in old-style Tamil numbers in which they would
102 appear no more than one in a row, separated by characters that mean "times 10",
103 "times 100", etc.  (See L<http://www.unicode.org/notes/tn21>.)
104
105 Some of the non-European digits that C<\d> matches look like European ones, but
106 have different values.  For example, BENGALI DIGIT FOUR (U+09EA) looks
107 very much like an ASCII DIGIT EIGHT (U+0038).
108
109 It may be useful for security purposes for an application to require that all
110 digits in a row be from the same script.   See L<Unicode::UCD/charscript()>.
111
112 Any character that isn't matched by C<\d> will be matched by C<\D>.
113
114 =head3 Word characters
115
116 A C<\w> matches a single alphanumeric character (an alphabetic character, or a
117 decimal digit) or a connecting punctuation character, such as an
118 underscore ("_").  It does not match a whole word.  To match a whole
119 word, use C<\w+>.  This isn't the same thing as matching an English word, but 
120 in the ASCII range it is the same as a string of Perl-identifier
121 characters.  What is considered a
122 word character depends on several factors, detailed below in L</Locale,
123 EBCDIC, Unicode and UTF-8>.  If those factors indicate a Unicode
124 interpretation, C<\w> matches the characters that are considered word
125 characters in the Unicode database. That is, it not only matches ASCII letters,
126 but also Thai letters, Greek letters, etc.  This includes connector
127 punctuation (like the underscore) which connect two words together, or
128 marks, such as a C<COMBINING TILDE>, which are generally used to add
129 diacritical marks to letters.   If a Unicode interpretation
130 is not indicated, C<\w> matches those characters that are considered
131 word characters by the current locale or EBCDIC code page.  Without a
132 locale or EBCDIC code page, C<\w> matches the ASCII letters, digits and
133 the underscore.
134
135 There are a number of security issues with the full Unicode list of word
136 characters.  See L<http://unicode.org/reports/tr36>.
137
138 Also, for a somewhat finer-grained set of characters that are in programming
139 language identifiers beyond the ASCII range, you may wish to instead use the
140 more customized Unicode properties, "ID_Start", ID_Continue", "XID_Start", and
141 "XID_Continue".  See L<http://unicode.org/reports/tr31>.
142
143 Any character that isn't matched by C<\w> will be matched by C<\W>.
144
145 =head3 Whitespace
146
147 C<\s> matches any single character that is considered whitespace.  The exact
148 set of characters matched by C<\s> depends on several factors, detailed
149 below in L</Locale, EBCDIC, Unicode and UTF-8>.  If those factors
150 indicate a Unicode interpretation, C<\s> matches what is considered
151 whitespace in the Unicode database; the complete list is in the table
152 below. Otherwise, if there is a locale or EBCDIC code page in effect,
153 C<\s> matches whatever is considered whitespace by the current locale or
154 EBCDIC code page. Without a locale or EBCDIC code page, C<\s> matches
155 the horizontal tab (C<\t>), the newline (C<\n>), the form feed (C<\f>),
156 the carriage return (C<\r>), and the space.  (Note that it doesn't match
157 the vertical tab, C<\cK>.)  Perhaps the most notable possible surprise
158 is that C<\s> matches a non-breaking space only if a Unicode
159 interpretation is indicated, or the locale or EBCDIC code page that is
160 in effect has that character.
161
162 Any character that isn't matched by C<\s> will be matched by C<\S>.
163
164 C<\h> will match any character that is considered horizontal whitespace;
165 this includes the space and the tab characters and a number other characters,
166 all of which are listed in the table below.  C<\H> will match any character
167 that is not considered horizontal whitespace.
168
169 C<\v> will match any character that is considered vertical whitespace;
170 this includes the carriage return and line feed characters (newline) plus several
171 other characters, all listed in the table below.
172 C<\V> will match any character that is not considered vertical whitespace.
173
174 C<\R> matches anything that can be considered a newline under Unicode
175 rules. It's not a character class, as it can match a multi-character
176 sequence. Therefore, it cannot be used inside a bracketed character
177 class; use C<\v> instead (vertical whitespace).
178 Details are discussed in L<perlrebackslash>.
179
180 Note that unlike C<\s>, C<\d> and C<\w>, C<\h> and C<\v> always match
181 the same characters, without regard to other factors, such as if the
182 source string is in UTF-8 format or not.
183
184 One might think that C<\s> is equivalent to C<[\h\v]>. This is not true.  The
185 vertical tab (C<"\x0b">) is not matched by C<\s>, it is however considered
186 vertical whitespace. Furthermore, if the source string is not in UTF-8 format,
187 and any locale or EBCDIC code page that is in effect doesn't include them, the
188 next line (ASCII-platform C<"\x85">) and the no-break space (ASCII-platform
189 C<"\xA0">) characters are not matched by C<\s>, but are by C<\v> and C<\h>
190 respectively.  If the source string is in UTF-8 format, both the next line and
191 the no-break space are matched by C<\s>.
192
193 The following table is a complete listing of characters matched by
194 C<\s>, C<\h> and C<\v> as of Unicode 5.2.
195
196 The first column gives the code point of the character (in hex format),
197 the second column gives the (Unicode) name. The third column indicates
198 by which class(es) the character is matched (assuming no locale or EBCDIC code
199 page is in effect that changes the C<\s> matching).
200
201  0x00009        CHARACTER TABULATION   h s
202  0x0000a              LINE FEED (LF)    vs
203  0x0000b             LINE TABULATION    v
204  0x0000c              FORM FEED (FF)    vs
205  0x0000d        CARRIAGE RETURN (CR)    vs
206  0x00020                       SPACE   h s
207  0x00085             NEXT LINE (NEL)    vs  [1]
208  0x000a0              NO-BREAK SPACE   h s  [1]
209  0x01680            OGHAM SPACE MARK   h s
210  0x0180e   MONGOLIAN VOWEL SEPARATOR   h s
211  0x02000                     EN QUAD   h s
212  0x02001                     EM QUAD   h s
213  0x02002                    EN SPACE   h s
214  0x02003                    EM SPACE   h s
215  0x02004          THREE-PER-EM SPACE   h s
216  0x02005           FOUR-PER-EM SPACE   h s
217  0x02006            SIX-PER-EM SPACE   h s
218  0x02007                FIGURE SPACE   h s
219  0x02008           PUNCTUATION SPACE   h s
220  0x02009                  THIN SPACE   h s
221  0x0200a                  HAIR SPACE   h s
222  0x02028              LINE SEPARATOR    vs
223  0x02029         PARAGRAPH SEPARATOR    vs
224  0x0202f       NARROW NO-BREAK SPACE   h s
225  0x0205f   MEDIUM MATHEMATICAL SPACE   h s
226  0x03000           IDEOGRAPHIC SPACE   h s
227
228 =over 4
229
230 =item [1]
231
232 NEXT LINE and NO-BREAK SPACE only match C<\s> if the source string is in
233 UTF-8 format, or the locale or EBCDIC code page that is in effect includes them.
234
235 =back
236
237 It is worth noting that C<\d>, C<\w>, etc, match single characters, not
238 complete numbers or words. To match a number (that consists of digits),
239 use C<\d+>; to match a word, use C<\w+>.
240
241 =head3 \N
242
243 C<\N> is new in 5.12, and is experimental.  It, like the dot, will match any
244 character that is not a newline. The difference is that C<\N> is not influenced
245 by the I<single line> regular expression modifier (see L</The dot> above).  Note
246 that the form C<\N{...}> may mean something completely different.  When the
247 C<{...}> is a L<quantifier|perlre/Quantifiers>, it means to match a non-newline
248 character that many times.  For example, C<\N{3}> means to match 3
249 non-newlines; C<\N{5,}> means to match 5 or more non-newlines.  But if C<{...}>
250 is not a legal quantifier, it is presumed to be a named character.  See
251 L<charnames> for those.  For example, none of C<\N{COLON}>, C<\N{4F}>, and
252 C<\N{F4}> contain legal quantifiers, so Perl will try to find characters whose
253 names are, respectively, C<COLON>, C<4F>, and C<F4>.
254
255 =head3 Unicode Properties
256
257 C<\pP> and C<\p{Prop}> are character classes to match characters that fit given
258 Unicode properties.  One letter property names can be used in the C<\pP> form,
259 with the property name following the C<\p>, otherwise, braces are required.
260 When using braces, there is a single form, which is just the property name
261 enclosed in the braces, and a compound form which looks like C<\p{name=value}>,
262 which means to match if the property "name" for the character has the particular
263 "value".
264 For instance, a match for a number can be written as C</\pN/> or as
265 C</\p{Number}/>, or as C</\p{Number=True}/>.
266 Lowercase letters are matched by the property I<Lowercase_Letter> which
267 has as short form I<Ll>. They need the braces, so are written as C</\p{Ll}/> or
268 C</\p{Lowercase_Letter}/>, or C</\p{General_Category=Lowercase_Letter}/>
269 (the underscores are optional).
270 C</\pLl/> is valid, but means something different.
271 It matches a two character string: a letter (Unicode property C<\pL>),
272 followed by a lowercase C<l>.
273
274 For more details, see L<perlunicode/Unicode Character Properties>; for a
275 complete list of possible properties, see
276 L<perluniprops/Properties accessible through \p{} and \P{}>.
277 It is also possible to define your own properties. This is discussed in
278 L<perlunicode/User-Defined Character Properties>.
279
280
281 =head4 Examples
282
283  "a"  =~  /\w/      # Match, "a" is a 'word' character.
284  "7"  =~  /\w/      # Match, "7" is a 'word' character as well.
285  "a"  =~  /\d/      # No match, "a" isn't a digit.
286  "7"  =~  /\d/      # Match, "7" is a digit.
287  " "  =~  /\s/      # Match, a space is whitespace.
288  "a"  =~  /\D/      # Match, "a" is a non-digit.
289  "7"  =~  /\D/      # No match, "7" is not a non-digit.
290  " "  =~  /\S/      # No match, a space is not non-whitespace.
291
292  " "  =~  /\h/      # Match, space is horizontal whitespace.
293  " "  =~  /\v/      # No match, space is not vertical whitespace.
294  "\r" =~  /\v/      # Match, a return is vertical whitespace.
295
296  "a"  =~  /\pL/     # Match, "a" is a letter.
297  "a"  =~  /\p{Lu}/  # No match, /\p{Lu}/ matches upper case letters.
298
299  "\x{0e0b}" =~ /\p{Thai}/  # Match, \x{0e0b} is the character
300                            # 'THAI CHARACTER SO SO', and that's in
301                            # Thai Unicode class.
302  "a"  =~  /\P{Lao}/ # Match, as "a" is not a Laotian character.
303
304
305 =head2 Bracketed Character Classes
306
307 The third form of character class you can use in Perl regular expressions
308 is the bracketed character class.  In its simplest form, it lists the characters
309 that may be matched, surrounded by square brackets, like this: C<[aeiou]>.
310 This matches one of C<a>, C<e>, C<i>, C<o> or C<u>.  Like the other
311 character classes, exactly one character will be matched. To match
312 a longer string consisting of characters mentioned in the character
313 class, follow the character class with a L<quantifier|perlre/Quantifiers>.  For
314 instance, C<[aeiou]+> matches a string of one or more lowercase English vowels.
315
316 Repeating a character in a character class has no
317 effect; it's considered to be in the set only once.
318
319 Examples:
320
321  "e"  =~  /[aeiou]/        # Match, as "e" is listed in the class.
322  "p"  =~  /[aeiou]/        # No match, "p" is not listed in the class.
323  "ae" =~  /^[aeiou]$/      # No match, a character class only matches
324                            # a single character.
325  "ae" =~  /^[aeiou]+$/     # Match, due to the quantifier.
326
327 =head3 Special Characters Inside a Bracketed Character Class
328
329 Most characters that are meta characters in regular expressions (that
330 is, characters that carry a special meaning like C<.>, C<*>, or C<(>) lose
331 their special meaning and can be used inside a character class without
332 the need to escape them. For instance, C<[()]> matches either an opening
333 parenthesis, or a closing parenthesis, and the parens inside the character
334 class don't group or capture.
335
336 Characters that may carry a special meaning inside a character class are:
337 C<\>, C<^>, C<->, C<[> and C<]>, and are discussed below. They can be
338 escaped with a backslash, although this is sometimes not needed, in which
339 case the backslash may be omitted.
340
341 The sequence C<\b> is special inside a bracketed character class. While
342 outside the character class, C<\b> is an assertion indicating a point
343 that does not have either two word characters or two non-word characters
344 on either side, inside a bracketed character class, C<\b> matches a
345 backspace character.
346
347 The sequences
348 C<\a>,
349 C<\c>,
350 C<\e>,
351 C<\f>,
352 C<\n>,
353 C<\N{I<NAME>}>,
354 C<\N{U+I<hex char>}>,
355 C<\r>,
356 C<\t>,
357 and
358 C<\x>
359 are also special and have the same meanings as they do outside a
360 bracketed character class.  (However, inside a bracketed character
361 class, if C<\N{I<NAME>}> expands to a sequence of characters, only the first
362 one in the sequence is used, with a warning.)
363
364 Also, a backslash followed by two or three octal digits is considered an octal
365 number.
366
367 A C<[> is not special inside a character class, unless it's the start of a
368 POSIX character class (see L</POSIX Character Classes> below). It normally does
369 not need escaping.
370
371 A C<]> is normally either the end of a POSIX character class (see
372 L</POSIX Character Classes> below), or it signals the end of the bracketed
373 character class.  If you want to include a C<]> in the set of characters, you
374 must generally escape it.
375 However, if the C<]> is the I<first> (or the second if the first
376 character is a caret) character of a bracketed character class, it
377 does not denote the end of the class (as you cannot have an empty class)
378 and is considered part of the set of characters that can be matched without
379 escaping.
380
381 Examples:
382
383  "+"   =~ /[+?*]/     #  Match, "+" in a character class is not special.
384  "\cH" =~ /[\b]/      #  Match, \b inside in a character class
385                       #  is equivalent to a backspace.
386  "]"   =~ /[][]/      #  Match, as the character class contains.
387                       #  both [ and ].
388  "[]"  =~ /[[]]/      #  Match, the pattern contains a character class
389                       #  containing just ], and the character class is
390                       #  followed by a ].
391
392 =head3 Character Ranges
393
394 It is not uncommon to want to match a range of characters. Luckily, instead
395 of listing all the characters in the range, one may use the hyphen (C<->).
396 If inside a bracketed character class you have two characters separated
397 by a hyphen, it's treated as if all the characters between the two are in
398 the class. For instance, C<[0-9]> matches any ASCII digit, and C<[a-m]>
399 matches any lowercase letter from the first half of the ASCII alphabet.
400
401 Note that the two characters on either side of the hyphen are not
402 necessarily both letters or both digits. Any character is possible,
403 although not advisable.  C<['-?]> contains a range of characters, but
404 most people will not know which characters that will be. Furthermore,
405 such ranges may lead to portability problems if the code has to run on
406 a platform that uses a different character set, such as EBCDIC.
407
408 If a hyphen in a character class cannot syntactically be part of a range, for
409 instance because it is the first or the last character of the character class,
410 or if it immediately follows a range, the hyphen isn't special, and will be
411 considered a character that is to be matched literally. You have to escape the
412 hyphen with a backslash if you want to have a hyphen in your set of characters
413 to be matched, and its position in the class is such that it could be
414 considered part of a range.
415
416 Examples:
417
418  [a-z]       #  Matches a character that is a lower case ASCII letter.
419  [a-fz]      #  Matches any letter between 'a' and 'f' (inclusive) or
420              #  the letter 'z'.
421  [-z]        #  Matches either a hyphen ('-') or the letter 'z'.
422  [a-f-m]     #  Matches any letter between 'a' and 'f' (inclusive), the
423              #  hyphen ('-'), or the letter 'm'.
424  ['-?]       #  Matches any of the characters  '()*+,-./0123456789:;<=>?
425              #  (But not on an EBCDIC platform).
426
427
428 =head3 Negation
429
430 It is also possible to instead list the characters you do not want to
431 match. You can do so by using a caret (C<^>) as the first character in the
432 character class. For instance, C<[^a-z]> matches a character that is not a
433 lowercase ASCII letter.
434
435 This syntax make the caret a special character inside a bracketed character
436 class, but only if it is the first character of the class. So if you want
437 to have the caret as one of the characters you want to match, you either
438 have to escape the caret, or not list it first.
439
440 Examples:
441
442  "e"  =~  /[^aeiou]/   #  No match, the 'e' is listed.
443  "x"  =~  /[^aeiou]/   #  Match, as 'x' isn't a lowercase vowel.
444  "^"  =~  /[^^]/       #  No match, matches anything that isn't a caret.
445  "^"  =~  /[x^]/       #  Match, caret is not special here.
446
447 =head3 Backslash Sequences
448
449 You can put any backslash sequence character class (with the exception of
450 C<\N> and C<\R>) inside a bracketed character class, and it will act just
451 as if you put all the characters matched by the backslash sequence inside the
452 character class. For instance, C<[a-f\d]> will match any decimal digit, or any
453 of the lowercase letters between 'a' and 'f' inclusive.
454
455 C<\N> within a bracketed character class must be of the forms C<\N{I<name>}>
456 or C<\N{U+I<hex char>}>, and NOT be the form that matches non-newlines,
457 for the same reason that a dot C<.> inside a bracketed character class loses
458 its special meaning: it matches nearly anything, which generally isn't what you
459 want to happen.
460
461
462 Examples:
463
464  /[\p{Thai}\d]/     # Matches a character that is either a Thai
465                     # character, or a digit.
466  /[^\p{Arabic}()]/  # Matches a character that is neither an Arabic
467                     # character, nor a parenthesis.
468
469 Backslash sequence character classes cannot form one of the endpoints
470 of a range.  Thus, you can't say:
471
472  /[\p{Thai}-\d]/     # Wrong!
473
474 =head3 POSIX Character Classes
475 X<character class> X<\p> X<\p{}>
476 X<alpha> X<alnum> X<ascii> X<blank> X<cntrl> X<digit> X<graph>
477 X<lower> X<print> X<punct> X<space> X<upper> X<word> X<xdigit>
478
479 POSIX character classes have the form C<[:class:]>, where I<class> is
480 name, and the C<[:> and C<:]> delimiters. POSIX character classes only appear
481 I<inside> bracketed character classes, and are a convenient and descriptive
482 way of listing a group of characters, though they currently suffer from
483 portability issues (see below and L<Locale, EBCDIC, Unicode and UTF-8>).
484
485 Be careful about the syntax,
486
487  # Correct:
488  $string =~ /[[:alpha:]]/
489
490  # Incorrect (will warn):
491  $string =~ /[:alpha:]/
492
493 The latter pattern would be a character class consisting of a colon,
494 and the letters C<a>, C<l>, C<p> and C<h>.
495 POSIX character classes can be part of a larger bracketed character class.  For
496 example,
497
498  [01[:alpha:]%]
499
500 is valid and matches '0', '1', any alphabetic character, and the percent sign.
501
502 Perl recognizes the following POSIX character classes:
503
504  alpha  Any alphabetical character ("[A-Za-z]").
505  alnum  Any alphanumerical character. ("[A-Za-z0-9]")
506  ascii  Any character in the ASCII character set.
507  blank  A GNU extension, equal to a space or a horizontal tab ("\t").
508  cntrl  Any control character.  See Note [2] below.
509  digit  Any decimal digit ("[0-9]"), equivalent to "\d".
510  graph  Any printable character, excluding a space.  See Note [3] below.
511  lower  Any lowercase character ("[a-z]").
512  print  Any printable character, including a space.  See Note [4] below.
513  punct  Any graphical character excluding "word" characters.  Note [5].
514  space  Any whitespace character. "\s" plus the vertical tab ("\cK").
515  upper  Any uppercase character ("[A-Z]").
516  word   A Perl extension ("[A-Za-z0-9_]"), equivalent to "\w".
517  xdigit Any hexadecimal digit ("[0-9a-fA-F]").
518
519 Most POSIX character classes have two Unicode-style C<\p> property
520 counterparts.  (They are not official Unicode properties, but Perl extensions
521 derived from official Unicode properties.)  The table below shows the relation
522 between POSIX character classes and these counterparts.
523
524 One counterpart, in the column labelled "ASCII-range Unicode" in
525 the table, will only match characters in the ASCII character set.
526
527 The other counterpart, in the column labelled "Full-range Unicode", matches any
528 appropriate characters in the full Unicode character set.  For example,
529 C<\p{Alpha}> will match not just the ASCII alphabetic characters, but any
530 character in the entire Unicode character set that is considered to be
531 alphabetic.  The column labelled "backslash sequence" is a (short) synonym for
532 the Full-range Unicode form.
533
534 (Each of the counterparts has various synonyms as well.
535 L<perluniprops/Properties accessible through \p{} and \P{}> lists all the
536 synonyms, plus all the characters matched by each of the ASCII-range
537 properties.  For example C<\p{AHex}> is a synonym for C<\p{ASCII_Hex_Digit}>,
538 and any C<\p> property name can be prefixed with "Is" such as C<\p{IsAlpha}>.)
539
540 Both the C<\p> forms are unaffected by any locale that is in effect, or whether
541 the string is in UTF-8 format or not, or whether the platform is EBCDIC or not.
542 In contrast, the POSIX character classes are affected.  If the source string is
543 in UTF-8 format, the POSIX classes behave like their "Full-range"
544 Unicode counterparts.  If the
545 source string is not in UTF-8 format, and no locale is in effect, and the
546 platform is not EBCDIC, all the POSIX classes behave like their ASCII-range
547 counterparts.  Otherwise, they behave based on the rules of the locale or
548 EBCDIC code page.
549
550 It is proposed to change this behavior in a future release of Perl so that the
551 the UTF-8-ness of the source string will be irrelevant to the behavior of the
552 POSIX character classes.  This means they will always behave in strict
553 accordance with the official POSIX standard.  That is, if either locale or
554 EBCDIC code page is present, they will behave in accordance with those; if
555 absent, the classes will match only their ASCII-range counterparts.  If you
556 wish to comment on this proposal, send email to C<perl5-porters@perl.org>.
557
558  [[:...:]]      ASCII-range          Full-range  backslash  Note
559                  Unicode              Unicode     sequence
560  -----------------------------------------------------
561    alpha      \p{PosixAlpha}       \p{XPosixAlpha}
562    alnum      \p{PosixAlnum}       \p{XPosixAlnum}
563    ascii      \p{ASCII}          
564    blank      \p{PosixBlank}       \p{XPosixBlank}  \h      [1]
565                                    or \p{HorizSpace}        [1]
566    cntrl      \p{PosixCntrl}       \p{XPosixCntrl}          [2]
567    digit      \p{PosixDigit}       \p{XPosixDigit}  \d
568    graph      \p{PosixGraph}       \p{XPosixGraph}          [3]
569    lower      \p{PosixLower}       \p{XPosixLower}
570    print      \p{PosixPrint}       \p{XPosixPrint}          [4]
571    punct      \p{PosixPunct}       \p{XPosixPunct}          [5]
572               \p{PerlSpace}        \p{XPerlSpace}   \s      [6]
573    space      \p{PosixSpace}       \p{XPosixSpace}          [6]
574    upper      \p{PosixUpper}       \p{XPosixUpper}
575    word       \p{PosixWord}        \p{XPosixWord}   \w
576    xdigit     \p{ASCII_Hex_Digit}  \p{XPosixXDigit}
577
578 =over 4
579
580 =item [1]
581
582 C<\p{Blank}> and C<\p{HorizSpace}> are synonyms.
583
584 =item [2]
585
586 Control characters don't produce output as such, but instead usually control
587 the terminal somehow: for example newline and backspace are control characters.
588 In the ASCII range, characters whose ordinals are between 0 and 31 inclusive,
589 plus 127 (C<DEL>) are control characters.
590
591 On EBCDIC platforms, it is likely that the code page will define C<[[:cntrl:]]>
592 to be the EBCDIC equivalents of the ASCII controls, plus the controls
593 that in Unicode have ordinals from 128 through 159.
594
595 =item [3]
596
597 Any character that is I<graphical>, that is, visible. This class consists
598 of all the alphanumerical characters and all punctuation characters.
599
600 =item [4]
601
602 All printable characters, which is the set of all the graphical characters
603 plus whitespace characters that are not also controls.
604
605 =item [5]
606
607 C<\p{PosixPunct}> and C<[[:punct:]]> in the ASCII range match all the
608 non-controls, non-alphanumeric, non-space characters:
609 C<[-!"#$%&'()*+,./:;<=E<gt>?@[\\\]^_`{|}~]> (although if a locale is in effect,
610 it could alter the behavior of C<[[:punct:]]>).
611
612 The similarly named property, C<\p{Punct}>, matches a somewhat different
613 set in the ASCII range, namely
614 C<[-!"#%&'()*,./:;?@[\\\]_{}]>.  That is, it is missing C<[$+E<lt>=E<gt>^`|~]>.
615 This is because Unicode splits what POSIX considers to be punctuation into two
616 categories, Punctuation and Symbols.
617
618 C<\p{XPosixPunct}> and (in Unicode mode) C<[[:punct:]]>, match what
619 C<\p{PosixPunct}> matches in the ASCII range, plus what C<\p{Punct}>
620 matches.  This is different than strictly matching according to
621 C<\p{Punct}>.  Another way to say it is that
622 for a UTF-8 string, C<[[:punct:]]> matches all the characters that Unicode
623 considers to be punctuation, plus all the ASCII-range characters that Unicode
624 considers to be symbols.
625
626 =item [6]
627
628 C<\p{SpacePerl}> and C<\p{Space}> differ only in that C<\p{Space}> additionally
629 matches the vertical tab, C<\cK>.   Same for the two ASCII-only range forms.
630
631 =back
632
633 There are various other synonyms that can be used for these besides
634 C<\p{HorizSpace}> and \C<\p{XPosixBlank}>.  For example
635 C<\p{PosixAlpha}> can be written as C<\p{Alpha}>.  All are listed
636 in L<perluniprops/Properties accessible through \p{} and \P{}>.
637
638 =head4 Negation
639 X<character class, negation>
640
641 A Perl extension to the POSIX character class is the ability to
642 negate it. This is done by prefixing the class name with a caret (C<^>).
643 Some examples:
644
645      POSIX         ASCII-range     Full-range  backslash
646                     Unicode         Unicode    sequence
647  -----------------------------------------------------
648  [[:^digit:]]   \P{PosixDigit}  \P{XPosixDigit}   \D
649  [[:^space:]]   \P{PosixSpace}  \P{XPosixSpace}
650                 \P{PerlSpace}   \P{XPerlSpace}    \S
651  [[:^word:]]    \P{PerlWord}    \P{XPosixWord}    \W
652
653 The backslash sequence can mean either ASCII- or Full-range Unicode,
654 depending on various factors.  See L</Locale, EBCDIC, Unicode and UTF-8>
655 below.
656
657 =head4 [= =] and [. .]
658
659 Perl will recognize the POSIX character classes C<[=class=]>, and
660 C<[.class.]>, but does not (yet?) support them.  Use of
661 such a construct will lead to an error.
662
663
664 =head4 Examples
665
666  /[[:digit:]]/            # Matches a character that is a digit.
667  /[01[:lower:]]/          # Matches a character that is either a
668                           # lowercase letter, or '0' or '1'.
669  /[[:digit:][:^xdigit:]]/ # Matches a character that can be anything
670                           # except the letters 'a' to 'f'.  This is
671                           # because the main character class is composed
672                           # of two POSIX character classes that are ORed
673                           # together, one that matches any digit, and
674                           # the other that matches anything that isn't a
675                           # hex digit.  The result matches all
676                           # characters except the letters 'a' to 'f' and
677                           # 'A' to 'F'.
678
679
680 =head2 Locale, EBCDIC, Unicode and UTF-8
681
682 Some of the character classes have a somewhat different behaviour depending
683 on the internal encoding of the source string, if the regular expression
684 is marked as having Unicode semantics, the locale that is in effect,
685 and if the program is running on an EBCDIC platform.
686
687 C<\w>, C<\d>, C<\s> and the POSIX character classes (and their negations,
688 including C<\W>, C<\D>, C<\S>) have this behaviour.  (Since the backslash
689 sequences C<\b> and C<\B> are defined in terms of C<\w> and C<\W>, they also are
690 affected.)
691
692 The rule is that if the source string is in UTF-8 format or the regular
693 expression is marked as indicating Unicode semantics (see the next
694 paragraph), the character classes match according to the Unicode
695 properties.  Otherwise, the character classes match according to
696 whatever locale or EBCDIC code page is in effect. If there is no locale
697 nor EBCDIC, they match the ASCII defaults (0 to 9 for C<\d>; 52 letters,
698 10 digits and underscore for C<\w>; etc.).
699
700 A regular expression is marked for Unicode semantics if it is encoded in
701 utf8 (usually as a result of including a literal character whose code
702 point is above 255), or if it contains a C<\N{U+...}> or C<\N{I<name>}>
703 construct, or (starting in Perl 5.14) if it was compiled in the scope of a
704 C<S<use feature "unicode_strings">> pragma, or has the C<"u"> regular
705 expression modifier.
706
707 The differences in behavior between locale and non-locale semantics
708 can affect any character whose code point is 255 or less.  The
709 differences in behavior between Unicode and non-Unicode semantics
710 affects only ASCII platforms, and only when matching against characters
711 whose code points are between 128 and 255 inclusive.  See
712 L<perlunicode/The "Unicode Bug">.
713
714 For portability reasons, it may be better to not use C<\w>, C<\d>, C<\s>
715 or the POSIX character classes, and use the Unicode properties instead.
716 That way you can control whether you want matching of just characters in
717 the ASCII character set, or any Unicode characters.
718 C<S<use feature "unicode_strings">> will allow seamless Unicode behavior
719 no matter what the internal encodings are, but won't allow restricting
720 to just the ASCII characters.
721
722 =head4 Examples
723
724  $str =  "\xDF";      # $str is not in UTF-8 format.
725  $str =~ /^\w/;       # No match, as $str isn't in UTF-8 format.
726  $str .= "\x{0e0b}";  # Now $str is in UTF-8 format.
727  $str =~ /^\w/;       # Match! $str is now in UTF-8 format.
728  chop $str;
729  $str =~ /^\w/;       # Still a match! $str remains in UTF-8 format.
730
731 =cut