This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Teach B::Concise about OPpCONST_NOVER
[perl5.git] / dist / B-Deparse / Deparse.pm
1 # B::Deparse.pm
2 # Copyright (c) 1998-2000, 2002, 2003, 2004, 2005, 2006 Stephen McCamant.
3 # All rights reserved.
4 # This module is free software; you can redistribute and/or modify
5 # it under the same terms as Perl itself.
6
7 # This is based on the module of the same name by Malcolm Beattie,
8 # but essentially none of his code remains.
9
10 package B::Deparse;
11 use Carp;
12 use B qw(class main_root main_start main_cv svref_2object opnumber perlstring
13          OPf_WANT OPf_WANT_VOID OPf_WANT_SCALAR OPf_WANT_LIST
14          OPf_KIDS OPf_REF OPf_STACKED OPf_SPECIAL OPf_MOD
15          OPpLVAL_INTRO OPpOUR_INTRO OPpENTERSUB_AMPER OPpSLICE OPpCONST_BARE
16          OPpTRANS_SQUASH OPpTRANS_DELETE OPpTRANS_COMPLEMENT OPpTARGET_MY
17          OPpEXISTS_SUB OPpSORT_NUMERIC OPpSORT_INTEGER
18          OPpSORT_REVERSE
19          SVf_IOK SVf_NOK SVf_ROK SVf_POK SVpad_OUR SVf_FAKE SVs_RMG SVs_SMG
20          CVf_METHOD CVf_LVALUE
21          PMf_KEEP PMf_GLOBAL PMf_CONTINUE PMf_EVAL PMf_ONCE
22          PMf_MULTILINE PMf_SINGLELINE PMf_FOLD PMf_EXTENDED);
23 $VERSION = "1.10";
24 use strict;
25 use vars qw/$AUTOLOAD/;
26 use warnings ();
27
28 BEGIN {
29     # List version-specific constants here.
30     # Easiest way to keep this code portable between version looks to
31     # be to fake up a dummy constant that will never actually be true.
32     foreach (qw(OPpSORT_INPLACE OPpSORT_DESCEND OPpITER_REVERSED OPpCONST_NOVER
33                 OPpPAD_STATE PMf_SKIPWHITE RXf_SKIPWHITE
34                 CVf_LOCKED OPpREVERSE_INPLACE OPpSUBSTR_REPL_FIRST
35                 PMf_NONDESTRUCT OPpCONST_ARYBASE OPpEVAL_BYTES)) {
36         eval { import B $_ };
37         no strict 'refs';
38         *{$_} = sub () {0} unless *{$_}{CODE};
39     }
40 }
41
42 # Changes between 0.50 and 0.51:
43 # - fixed nulled leave with live enter in sort { }
44 # - fixed reference constants (\"str")
45 # - handle empty programs gracefully
46 # - handle infinite loops (for (;;) {}, while (1) {})
47 # - differentiate between 'for my $x ...' and 'my $x; for $x ...'
48 # - various minor cleanups
49 # - moved globals into an object
50 # - added '-u', like B::C
51 # - package declarations using cop_stash
52 # - subs, formats and code sorted by cop_seq
53 # Changes between 0.51 and 0.52:
54 # - added pp_threadsv (special variables under USE_5005THREADS)
55 # - added documentation
56 # Changes between 0.52 and 0.53:
57 # - many changes adding precedence contexts and associativity
58 # - added '-p' and '-s' output style options
59 # - various other minor fixes
60 # Changes between 0.53 and 0.54:
61 # - added support for new 'for (1..100)' optimization,
62 #   thanks to Gisle Aas
63 # Changes between 0.54 and 0.55:
64 # - added support for new qr// construct
65 # - added support for new pp_regcreset OP
66 # Changes between 0.55 and 0.56:
67 # - tested on base/*.t, cmd/*.t, comp/*.t, io/*.t
68 # - fixed $# on non-lexicals broken in last big rewrite
69 # - added temporary fix for change in opcode of OP_STRINGIFY
70 # - fixed problem in 0.54's for() patch in 'for (@ary)'
71 # - fixed precedence in conditional of ?:
72 # - tweaked list paren elimination in 'my($x) = @_'
73 # - made continue-block detection trickier wrt. null ops
74 # - fixed various prototype problems in pp_entersub
75 # - added support for sub prototypes that never get GVs
76 # - added unquoting for special filehandle first arg in truncate
77 # - print doubled rv2gv (a bug) as '*{*GV}' instead of illegal '**GV'
78 # - added semicolons at the ends of blocks
79 # - added -l '#line' declaration option -- fixes cmd/subval.t 27,28
80 # Changes between 0.56 and 0.561:
81 # - fixed multiply-declared my var in pp_truncate (thanks to Sarathy)
82 # - used new B.pm symbolic constants (done by Nick Ing-Simmons)
83 # Changes between 0.561 and 0.57:
84 # - stylistic changes to symbolic constant stuff
85 # - handled scope in s///e replacement code
86 # - added unquote option for expanding "" into concats, etc.
87 # - split method and proto parts of pp_entersub into separate functions
88 # - various minor cleanups
89 # Changes after 0.57:
90 # - added parens in \&foo (patch by Albert Dvornik)
91 # Changes between 0.57 and 0.58:
92 # - fixed '0' statements that weren't being printed
93 # - added methods for use from other programs
94 #   (based on patches from James Duncan and Hugo van der Sanden)
95 # - added -si and -sT to control indenting (also based on a patch from Hugo)
96 # - added -sv to print something else instead of '???'
97 # - preliminary version of utf8 tr/// handling
98 # Changes after 0.58:
99 # - uses of $op->ppaddr changed to new $op->name (done by Sarathy)
100 # - added support for Hugo's new OP_SETSTATE (like nextstate)
101 # Changes between 0.58 and 0.59
102 # - added support for Chip's OP_METHOD_NAMED
103 # - added support for Ilya's OPpTARGET_MY optimization
104 # - elided arrows before '()' subscripts when possible
105 # Changes between 0.59 and 0.60
106 # - support for method attributes was added
107 # - some warnings fixed
108 # - separate recognition of constant subs
109 # - rewrote continue block handling, now recognizing for loops
110 # - added more control of expanding control structures
111 # Changes between 0.60 and 0.61 (mostly by Robin Houston)
112 # - many bug-fixes
113 # - support for pragmas and 'use'
114 # - support for the little-used $[ variable
115 # - support for __DATA__ sections
116 # - UTF8 support
117 # - BEGIN, CHECK, INIT and END blocks
118 # - scoping of subroutine declarations fixed
119 # - compile-time output from the input program can be suppressed, so that the
120 #   output is just the deparsed code. (a change to O.pm in fact)
121 # - our() declarations
122 # - *all* the known bugs are now listed in the BUGS section
123 # - comprehensive test mechanism (TEST -deparse)
124 # Changes between 0.62 and 0.63 (mostly by Rafael Garcia-Suarez)
125 # - bug-fixes
126 # - new switch -P
127 # - support for command-line switches (-l, -0, etc.)
128 # Changes between 0.63 and 0.64
129 # - support for //, CHECK blocks, and assertions
130 # - improved handling of foreach loops and lexicals
131 # - option to use Data::Dumper for constants
132 # - more bug fixes
133 # - discovered lots more bugs not yet fixed
134 #
135 # ...
136 #
137 # Changes between 0.72 and 0.73
138 # - support new switch constructs
139
140 # Todo:
141 #  (See also BUGS section at the end of this file)
142 #
143 # - finish tr/// changes
144 # - add option for even more parens (generalize \&foo change)
145 # - left/right context
146 # - copy comments (look at real text with $^P?)
147 # - avoid semis in one-statement blocks
148 # - associativity of &&=, ||=, ?:
149 # - ',' => '=>' (auto-unquote?)
150 # - break long lines ("\r" as discretionary break?)
151 # - configurable syntax highlighting: ANSI color, HTML, TeX, etc.
152 # - more style options: brace style, hex vs. octal, quotes, ...
153 # - print big ints as hex/octal instead of decimal (heuristic?)
154 # - handle 'my $x if 0'?
155 # - version using op_next instead of op_first/sibling?
156 # - avoid string copies (pass arrays, one big join?)
157 # - here-docs?
158
159 # Current test.deparse failures
160 # comp/hints 6 - location of BEGIN blocks wrt. block openings
161 # run/switchI 1 - missing -I switches entirely
162 #    perl -Ifoo -e 'print @INC'
163 # op/caller 2 - warning mask propagates backwards before warnings::register
164 #    'use warnings; BEGIN {${^WARNING_BITS} eq "U"x12;} use warnings::register'
165 # op/getpid 2 - can't assign to shared my() declaration (threads only)
166 #    'my $x : shared = 5'
167 # op/override 7 - parens on overridden require change v-string interpretation
168 #    'BEGIN{*CORE::GLOBAL::require=sub {}} require v5.6'
169 #    c.f. 'BEGIN { *f = sub {0} }; f 2'
170 # op/pat 774 - losing Unicode-ness of Latin1-only strings
171 #    'use charnames ":short"; $x="\N{latin:a with acute}"'
172 # op/recurse 12 - missing parens on recursive call makes it look like method
173 #    'sub f { f($x) }'
174 # op/subst 90 - inconsistent handling of utf8 under "use utf8"
175 # op/taint 29 - "use re 'taint'" deparsed in the wrong place wrt. block open
176 # op/tiehandle compile - "use strict" deparsed in the wrong place
177 # uni/tr_ several
178 # ext/B/t/xref 11 - line numbers when we add newlines to one-line subs
179 # ext/Data/Dumper/t/dumper compile
180 # ext/DB_file/several
181 # ext/Encode/several
182 # ext/Ernno/Errno warnings
183 # ext/IO/lib/IO/t/io_sel 23
184 # ext/PerlIO/t/encoding compile
185 # ext/POSIX/t/posix 6
186 # ext/Socket/Socket 8
187 # ext/Storable/t/croak compile
188 # lib/Attribute/Handlers/t/multi compile
189 # lib/bignum/ several
190 # lib/charnames 35
191 # lib/constant 32
192 # lib/English 40
193 # lib/ExtUtils/t/bytes 4
194 # lib/File/DosGlob compile
195 # lib/Filter/Simple/t/data 1
196 # lib/Math/BigInt/t/constant 1
197 # lib/Net/t/config Deparse-warning
198 # lib/overload compile
199 # lib/Switch/ several
200 # lib/Symbol 4
201 # lib/Test/Simple several
202 # lib/Term/Complete
203 # lib/Tie/File/t/29_downcopy 5
204 # lib/vars 22
205
206 # Object fields (were globals):
207 #
208 # avoid_local:
209 # (local($a), local($b)) and local($a, $b) have the same internal
210 # representation but the short form looks better. We notice we can
211 # use a large-scale local when checking the list, but need to prevent
212 # individual locals too. This hash holds the addresses of OPs that
213 # have already had their local-ness accounted for. The same thing
214 # is done with my().
215 #
216 # curcv:
217 # CV for current sub (or main program) being deparsed
218 #
219 # curcvlex:
220 # Cached hash of lexical variables for curcv: keys are names,
221 # each value is an array of pairs, indicating the cop_seq of scopes
222 # in which a var of that name is valid.
223 #
224 # curcop:
225 # COP for statement being deparsed
226 #
227 # curstash:
228 # name of the current package for deparsed code
229 #
230 # subs_todo:
231 # array of [cop_seq, CV, is_format?] for subs and formats we still
232 # want to deparse
233 #
234 # protos_todo:
235 # as above, but [name, prototype] for subs that never got a GV
236 #
237 # subs_done, forms_done:
238 # keys are addresses of GVs for subs and formats we've already
239 # deparsed (or at least put into subs_todo)
240 #
241 # subs_declared
242 # keys are names of subs for which we've printed declarations.
243 # That means we can omit parentheses from the arguments. It also means we
244 # need to put CORE:: on core functions of the same name.
245 #
246 # subs_deparsed
247 # Keeps track of fully qualified names of all deparsed subs.
248 #
249 # parens: -p
250 # linenums: -l
251 # unquote: -q
252 # cuddle: ' ' or '\n', depending on -sC
253 # indent_size: -si
254 # use_tabs: -sT
255 # ex_const: -sv
256
257 # A little explanation of how precedence contexts and associativity
258 # work:
259 #
260 # deparse() calls each per-op subroutine with an argument $cx (short
261 # for context, but not the same as the cx* in the perl core), which is
262 # a number describing the op's parents in terms of precedence, whether
263 # they're inside an expression or at statement level, etc.  (see
264 # chart below). When ops with children call deparse on them, they pass
265 # along their precedence. Fractional values are used to implement
266 # associativity ('($x + $y) + $z' => '$x + $y + $y') and related
267 # parentheses hacks. The major disadvantage of this scheme is that
268 # it doesn't know about right sides and left sides, so say if you
269 # assign a listop to a variable, it can't tell it's allowed to leave
270 # the parens off the listop.
271
272 # Precedences:
273 # 26             [TODO] inside interpolation context ("")
274 # 25 left        terms and list operators (leftward)
275 # 24 left        ->
276 # 23 nonassoc    ++ --
277 # 22 right       **
278 # 21 right       ! ~ \ and unary + and -
279 # 20 left        =~ !~
280 # 19 left        * / % x
281 # 18 left        + - .
282 # 17 left        << >>
283 # 16 nonassoc    named unary operators
284 # 15 nonassoc    < > <= >= lt gt le ge
285 # 14 nonassoc    == != <=> eq ne cmp
286 # 13 left        &
287 # 12 left        | ^
288 # 11 left        &&
289 # 10 left        ||
290 #  9 nonassoc    ..  ...
291 #  8 right       ?:
292 #  7 right       = += -= *= etc.
293 #  6 left        , =>
294 #  5 nonassoc    list operators (rightward)
295 #  4 right       not
296 #  3 left        and
297 #  2 left        or xor
298 #  1             statement modifiers
299 #  0.5           statements, but still print scopes as do { ... }
300 #  0             statement level
301
302 # Nonprinting characters with special meaning:
303 # \cS - steal parens (see maybe_parens_unop)
304 # \n - newline and indent
305 # \t - increase indent
306 # \b - decrease indent ('outdent')
307 # \f - flush left (no indent)
308 # \cK - kill following semicolon, if any
309
310 sub null {
311     my $op = shift;
312     return class($op) eq "NULL";
313 }
314
315 sub todo {
316     my $self = shift;
317     my($cv, $is_form) = @_;
318     return unless ($cv->FILE eq $0 || exists $self->{files}{$cv->FILE});
319     my $seq;
320     if ($cv->OUTSIDE_SEQ) {
321         $seq = $cv->OUTSIDE_SEQ;
322     } elsif (!null($cv->START) and is_state($cv->START)) {
323         $seq = $cv->START->cop_seq;
324     } else {
325         $seq = 0;
326     }
327     push @{$self->{'subs_todo'}}, [$seq, $cv, $is_form];
328     unless ($is_form || class($cv->STASH) eq 'SPECIAL') {
329         $self->{'subs_deparsed'}{$cv->STASH->NAME."::".$cv->GV->NAME} = 1;
330     }
331 }
332
333 sub next_todo {
334     my $self = shift;
335     my $ent = shift @{$self->{'subs_todo'}};
336     my $cv = $ent->[1];
337     my $gv = $cv->GV;
338     my $name = $self->gv_name($gv);
339     if ($ent->[2]) {
340         return "format $name =\n"
341             . $self->deparse_format($ent->[1]). "\n";
342     } else {
343         $self->{'subs_declared'}{$name} = 1;
344         if ($name eq "BEGIN") {
345             my $use_dec = $self->begin_is_use($cv);
346             if (defined ($use_dec) and $self->{'expand'} < 5) {
347                 return () if 0 == length($use_dec);
348                 return $use_dec;
349             }
350         }
351         my $l = '';
352         if ($self->{'linenums'}) {
353             my $line = $gv->LINE;
354             my $file = $gv->FILE;
355             $l = "\n\f#line $line \"$file\"\n";
356         }
357         my $p = '';
358         if (class($cv->STASH) ne "SPECIAL") {
359             my $stash = $cv->STASH->NAME;
360             if ($stash ne $self->{'curstash'}) {
361                 $p = "package $stash;\n";
362                 $name = "$self->{'curstash'}::$name" unless $name =~ /::/;
363                 $self->{'curstash'} = $stash;
364             }
365             $name =~ s/^\Q$stash\E::(?!\z|.*::)//;
366         }
367         return "${p}${l}sub $name " . $self->deparse_sub($cv);
368     }
369 }
370
371 # Return a "use" declaration for this BEGIN block, if appropriate
372 sub begin_is_use {
373     my ($self, $cv) = @_;
374     my $root = $cv->ROOT;
375     local @$self{qw'curcv curcvlex'} = ($cv);
376 #require B::Debug;
377 #B::walkoptree($cv->ROOT, "debug");
378     my $lineseq = $root->first;
379     return if $lineseq->name ne "lineseq";
380
381     my $req_op = $lineseq->first->sibling;
382     return if $req_op->name ne "require";
383
384     my $module;
385     if ($req_op->first->private & OPpCONST_BARE) {
386         # Actually it should always be a bareword
387         $module = $self->const_sv($req_op->first)->PV;
388         $module =~ s[/][::]g;
389         $module =~ s/.pm$//;
390     }
391     else {
392         $module = $self->const($self->const_sv($req_op->first), 6);
393     }
394
395     my $version;
396     my $version_op = $req_op->sibling;
397     return if class($version_op) eq "NULL";
398     if ($version_op->name eq "lineseq") {
399         # We have a version parameter; skip nextstate & pushmark
400         my $constop = $version_op->first->next->next;
401
402         return unless $self->const_sv($constop)->PV eq $module;
403         $constop = $constop->sibling;
404         $version = $self->const_sv($constop);
405         if (class($version) eq "IV") {
406             $version = $version->int_value;
407         } elsif (class($version) eq "NV") {
408             $version = $version->NV;
409         } elsif (class($version) ne "PVMG") {
410             # Includes PVIV and PVNV
411             $version = $version->PV;
412         } else {
413             # version specified as a v-string
414             $version = 'v'.join '.', map ord, split //, $version->PV;
415         }
416         $constop = $constop->sibling;
417         return if $constop->name ne "method_named";
418         return if $self->const_sv($constop)->PV ne "VERSION";
419     }
420
421     $lineseq = $version_op->sibling;
422     return if $lineseq->name ne "lineseq";
423     my $entersub = $lineseq->first->sibling;
424     if ($entersub->name eq "stub") {
425         return "use $module $version ();\n" if defined $version;
426         return "use $module ();\n";
427     }
428     return if $entersub->name ne "entersub";
429
430     # See if there are import arguments
431     my $args = '';
432
433     my $svop = $entersub->first->sibling; # Skip over pushmark
434     return unless $self->const_sv($svop)->PV eq $module;
435
436     # Pull out the arguments
437     for ($svop=$svop->sibling; $svop->name ne "method_named";
438                 $svop = $svop->sibling) {
439         $args .= ", " if length($args);
440         $args .= $self->deparse($svop, 6);
441     }
442
443     my $use = 'use';
444     my $method_named = $svop;
445     return if $method_named->name ne "method_named";
446     my $method_name = $self->const_sv($method_named)->PV;
447
448     if ($method_name eq "unimport") {
449         $use = 'no';
450     }
451
452     # Certain pragmas are dealt with using hint bits,
453     # so we ignore them here
454     if ($module eq 'strict' || $module eq 'integer'
455         || $module eq 'bytes' || $module eq 'warnings'
456         || $module eq 'feature') {
457         return "";
458     }
459
460     if (defined $version && length $args) {
461         return "$use $module $version ($args);\n";
462     } elsif (defined $version) {
463         return "$use $module $version;\n";
464     } elsif (length $args) {
465         return "$use $module ($args);\n";
466     } else {
467         return "$use $module;\n";
468     }
469 }
470
471 sub stash_subs {
472     my ($self, $pack) = @_;
473     my (@ret, $stash);
474     if (!defined $pack) {
475         $pack = '';
476         $stash = \%::;
477     }
478     else {
479         $pack =~ s/(::)?$/::/;
480         no strict 'refs';
481         $stash = \%{"main::$pack"};
482     }
483     my %stash = svref_2object($stash)->ARRAY;
484     while (my ($key, $val) = each %stash) {
485         my $class = class($val);
486         if ($class eq "PV") {
487             # Just a prototype. As an ugly but fairly effective way
488             # to find out if it belongs here is to see if the AUTOLOAD
489             # (if any) for the stash was defined in one of our files.
490             my $A = $stash{"AUTOLOAD"};
491             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
492                 && class($A->CV) eq "CV") {
493                 my $AF = $A->FILE;
494                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
495             }
496             push @{$self->{'protos_todo'}}, [$pack . $key, $val->PV];
497         } elsif ($class eq "IV" && !($val->FLAGS & SVf_ROK)) {
498             # Just a name. As above.
499             # But skip proxy constant subroutines, as some form of perl-space
500             # visible code must have created them, be it a use statement, or
501             # some direct symbol-table manipulation code that we will Deparse
502             my $A = $stash{"AUTOLOAD"};
503             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
504                 && class($A->CV) eq "CV") {
505                 my $AF = $A->FILE;
506                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
507             }
508             push @{$self->{'protos_todo'}}, [$pack . $key, undef];
509         } elsif ($class eq "GV") {
510             if (class(my $cv = $val->CV) ne "SPECIAL") {
511                 next if $self->{'subs_done'}{$$val}++;
512                 next if $$val != ${$cv->GV};   # Ignore imposters
513                 $self->todo($cv, 0);
514             }
515             if (class(my $cv = $val->FORM) ne "SPECIAL") {
516                 next if $self->{'forms_done'}{$$val}++;
517                 next if $$val != ${$cv->GV};   # Ignore imposters
518                 $self->todo($cv, 1);
519             }
520             if (class($val->HV) ne "SPECIAL" && $key =~ /::$/) {
521                 $self->stash_subs($pack . $key)
522                     unless $pack eq '' && $key eq 'main::';
523                     # avoid infinite recursion
524             }
525         }
526     }
527 }
528
529 sub print_protos {
530     my $self = shift;
531     my $ar;
532     my @ret;
533     foreach $ar (@{$self->{'protos_todo'}}) {
534         my $proto = (defined $ar->[1] ? " (". $ar->[1] . ")" : "");
535         push @ret, "sub " . $ar->[0] .  "$proto;\n";
536     }
537     delete $self->{'protos_todo'};
538     return @ret;
539 }
540
541 sub style_opts {
542     my $self = shift;
543     my $opts = shift;
544     my $opt;
545     while (length($opt = substr($opts, 0, 1))) {
546         if ($opt eq "C") {
547             $self->{'cuddle'} = " ";
548             $opts = substr($opts, 1);
549         } elsif ($opt eq "i") {
550             $opts =~ s/^i(\d+)//;
551             $self->{'indent_size'} = $1;
552         } elsif ($opt eq "T") {
553             $self->{'use_tabs'} = 1;
554             $opts = substr($opts, 1);
555         } elsif ($opt eq "v") {
556             $opts =~ s/^v([^.]*)(.|$)//;
557             $self->{'ex_const'} = $1;
558         }
559     }
560 }
561
562 sub new {
563     my $class = shift;
564     my $self = bless {}, $class;
565     $self->{'cuddle'} = "\n";
566     $self->{'curcop'} = undef;
567     $self->{'curstash'} = "main";
568     $self->{'ex_const'} = "'???'";
569     $self->{'expand'} = 0;
570     $self->{'files'} = {};
571     $self->{'indent_size'} = 4;
572     $self->{'linenums'} = 0;
573     $self->{'parens'} = 0;
574     $self->{'subs_todo'} = [];
575     $self->{'unquote'} = 0;
576     $self->{'use_dumper'} = 0;
577     $self->{'use_tabs'} = 0;
578
579     $self->{'ambient_arybase'} = 0;
580     $self->{'ambient_warnings'} = undef; # Assume no lexical warnings
581     $self->{'ambient_hints'} = 0;
582     $self->{'ambient_hinthash'} = undef;
583     $self->init();
584
585     while (my $arg = shift @_) {
586         if ($arg eq "-d") {
587             $self->{'use_dumper'} = 1;
588             require Data::Dumper;
589         } elsif ($arg =~ /^-f(.*)/) {
590             $self->{'files'}{$1} = 1;
591         } elsif ($arg eq "-l") {
592             $self->{'linenums'} = 1;
593         } elsif ($arg eq "-p") {
594             $self->{'parens'} = 1;
595         } elsif ($arg eq "-P") {
596             $self->{'noproto'} = 1;
597         } elsif ($arg eq "-q") {
598             $self->{'unquote'} = 1;
599         } elsif (substr($arg, 0, 2) eq "-s") {
600             $self->style_opts(substr $arg, 2);
601         } elsif ($arg =~ /^-x(\d)$/) {
602             $self->{'expand'} = $1;
603         }
604     }
605     return $self;
606 }
607
608 {
609     # Mask out the bits that L<warnings::register> uses
610     my $WARN_MASK;
611     BEGIN {
612         $WARN_MASK = $warnings::Bits{all} | $warnings::DeadBits{all};
613     }
614     sub WARN_MASK () {
615         return $WARN_MASK;
616     }
617 }
618
619 # Initialise the contextual information, either from
620 # defaults provided with the ambient_pragmas method,
621 # or from perl's own defaults otherwise.
622 sub init {
623     my $self = shift;
624
625     $self->{'arybase'}  = $self->{'ambient_arybase'};
626     $self->{'warnings'} = defined ($self->{'ambient_warnings'})
627                                 ? $self->{'ambient_warnings'} & WARN_MASK
628                                 : undef;
629     $self->{'hints'}    = $self->{'ambient_hints'};
630     $self->{'hints'} &= 0xFF if $] < 5.009;
631     $self->{'hinthash'} = $self->{'ambient_hinthash'};
632
633     # also a convenient place to clear out subs_declared
634     delete $self->{'subs_declared'};
635 }
636
637 sub compile {
638     my(@args) = @_;
639     return sub {
640         my $self = B::Deparse->new(@args);
641         # First deparse command-line args
642         if (defined $^I) { # deparse -i
643             print q(BEGIN { $^I = ).perlstring($^I).qq(; }\n);
644         }
645         if ($^W) { # deparse -w
646             print qq(BEGIN { \$^W = $^W; }\n);
647         }
648         if ($/ ne "\n" or defined $O::savebackslash) { # deparse -l and -0
649             my $fs = perlstring($/) || 'undef';
650             my $bs = perlstring($O::savebackslash) || 'undef';
651             print qq(BEGIN { \$/ = $fs; \$\\ = $bs; }\n);
652         }
653         my @BEGINs  = B::begin_av->isa("B::AV") ? B::begin_av->ARRAY : ();
654         my @UNITCHECKs = B::unitcheck_av->isa("B::AV")
655             ? B::unitcheck_av->ARRAY
656             : ();
657         my @CHECKs  = B::check_av->isa("B::AV") ? B::check_av->ARRAY : ();
658         my @INITs   = B::init_av->isa("B::AV") ? B::init_av->ARRAY : ();
659         my @ENDs    = B::end_av->isa("B::AV") ? B::end_av->ARRAY : ();
660         for my $block (@BEGINs, @UNITCHECKs, @CHECKs, @INITs, @ENDs) {
661             $self->todo($block, 0);
662         }
663         $self->stash_subs();
664         local($SIG{"__DIE__"}) =
665           sub {
666               if ($self->{'curcop'}) {
667                   my $cop = $self->{'curcop'};
668                   my($line, $file) = ($cop->line, $cop->file);
669                   print STDERR "While deparsing $file near line $line,\n";
670               }
671             };
672         $self->{'curcv'} = main_cv;
673         $self->{'curcvlex'} = undef;
674         print $self->print_protos;
675         @{$self->{'subs_todo'}} =
676           sort {$a->[0] <=> $b->[0]} @{$self->{'subs_todo'}};
677         print $self->indent($self->deparse_root(main_root)), "\n"
678           unless null main_root;
679         my @text;
680         while (scalar(@{$self->{'subs_todo'}})) {
681             push @text, $self->next_todo;
682         }
683         print $self->indent(join("", @text)), "\n" if @text;
684
685         # Print __DATA__ section, if necessary
686         no strict 'refs';
687         my $laststash = defined $self->{'curcop'}
688             ? $self->{'curcop'}->stash->NAME : $self->{'curstash'};
689         if (defined *{$laststash."::DATA"}{IO}) {
690             print "package $laststash;\n"
691                 unless $laststash eq $self->{'curstash'};
692             print "__DATA__\n";
693             print readline(*{$laststash."::DATA"});
694         }
695     }
696 }
697
698 sub coderef2text {
699     my $self = shift;
700     my $sub = shift;
701     croak "Usage: ->coderef2text(CODEREF)" unless UNIVERSAL::isa($sub, "CODE");
702
703     $self->init();
704     return $self->indent($self->deparse_sub(svref_2object($sub)));
705 }
706
707 sub ambient_pragmas {
708     my $self = shift;
709     my ($arybase, $hint_bits, $warning_bits, $hinthash) = (0, 0);
710
711     while (@_ > 1) {
712         my $name = shift();
713         my $val  = shift();
714
715         if ($name eq 'strict') {
716             require strict;
717
718             if ($val eq 'none') {
719                 $hint_bits &= ~strict::bits(qw/refs subs vars/);
720                 next();
721             }
722
723             my @names;
724             if ($val eq "all") {
725                 @names = qw/refs subs vars/;
726             }
727             elsif (ref $val) {
728                 @names = @$val;
729             }
730             else {
731                 @names = split' ', $val;
732             }
733             $hint_bits |= strict::bits(@names);
734         }
735
736         elsif ($name eq '$[') {
737             if (OPpCONST_ARYBASE) {
738                 $arybase = $val;
739             } else {
740                 croak "\$[ can't be non-zero on this perl" unless $val == 0;
741             }
742         }
743
744         elsif ($name eq 'integer'
745             || $name eq 'bytes'
746             || $name eq 'utf8') {
747             require "$name.pm";
748             if ($val) {
749                 $hint_bits |= ${$::{"${name}::"}{"hint_bits"}};
750             }
751             else {
752                 $hint_bits &= ~${$::{"${name}::"}{"hint_bits"}};
753             }
754         }
755
756         elsif ($name eq 're') {
757             require re;
758             if ($val eq 'none') {
759                 $hint_bits &= ~re::bits(qw/taint eval/);
760                 next();
761             }
762
763             my @names;
764             if ($val eq 'all') {
765                 @names = qw/taint eval/;
766             }
767             elsif (ref $val) {
768                 @names = @$val;
769             }
770             else {
771                 @names = split' ',$val;
772             }
773             $hint_bits |= re::bits(@names);
774         }
775
776         elsif ($name eq 'warnings') {
777             if ($val eq 'none') {
778                 $warning_bits = $warnings::NONE;
779                 next();
780             }
781
782             my @names;
783             if (ref $val) {
784                 @names = @$val;
785             }
786             else {
787                 @names = split/\s+/, $val;
788             }
789
790             $warning_bits = $warnings::NONE if !defined ($warning_bits);
791             $warning_bits |= warnings::bits(@names);
792         }
793
794         elsif ($name eq 'warning_bits') {
795             $warning_bits = $val;
796         }
797
798         elsif ($name eq 'hint_bits') {
799             $hint_bits = $val;
800         }
801
802         elsif ($name eq '%^H') {
803             $hinthash = $val;
804         }
805
806         else {
807             croak "Unknown pragma type: $name";
808         }
809     }
810     if (@_) {
811         croak "The ambient_pragmas method expects an even number of args";
812     }
813
814     $self->{'ambient_arybase'} = $arybase;
815     $self->{'ambient_warnings'} = $warning_bits;
816     $self->{'ambient_hints'} = $hint_bits;
817     $self->{'ambient_hinthash'} = $hinthash;
818 }
819
820 # This method is the inner loop, so try to keep it simple
821 sub deparse {
822     my $self = shift;
823     my($op, $cx) = @_;
824
825     Carp::confess("Null op in deparse") if !defined($op)
826                                         || class($op) eq "NULL";
827     my $meth = "pp_" . $op->name;
828     return $self->$meth($op, $cx);
829 }
830
831 sub indent {
832     my $self = shift;
833     my $txt = shift;
834     my @lines = split(/\n/, $txt);
835     my $leader = "";
836     my $level = 0;
837     my $line;
838     for $line (@lines) {
839         my $cmd = substr($line, 0, 1);
840         if ($cmd eq "\t" or $cmd eq "\b") {
841             $level += ($cmd eq "\t" ? 1 : -1) * $self->{'indent_size'};
842             if ($self->{'use_tabs'}) {
843                 $leader = "\t" x ($level / 8) . " " x ($level % 8);
844             } else {
845                 $leader = " " x $level;
846             }
847             $line = substr($line, 1);
848         }
849         if (substr($line, 0, 1) eq "\f") {
850             $line = substr($line, 1); # no indent
851         } else {
852             $line = $leader . $line;
853         }
854         $line =~ s/\cK;?//g;
855     }
856     return join("\n", @lines);
857 }
858
859 sub deparse_sub {
860     my $self = shift;
861     my $cv = shift;
862     my $proto = "";
863 Carp::confess("NULL in deparse_sub") if !defined($cv) || $cv->isa("B::NULL");
864 Carp::confess("SPECIAL in deparse_sub") if $cv->isa("B::SPECIAL");
865     local $self->{'curcop'} = $self->{'curcop'};
866     if ($cv->FLAGS & SVf_POK) {
867         $proto = "(". $cv->PV . ") ";
868     }
869     if ($cv->CvFLAGS & (CVf_METHOD|CVf_LOCKED|CVf_LVALUE)) {
870         $proto .= ": ";
871         $proto .= "lvalue " if $cv->CvFLAGS & CVf_LVALUE;
872         $proto .= "locked " if $cv->CvFLAGS & CVf_LOCKED;
873         $proto .= "method " if $cv->CvFLAGS & CVf_METHOD;
874     }
875
876     local($self->{'curcv'}) = $cv;
877     local($self->{'curcvlex'});
878     local(@$self{qw'curstash warnings hints hinthash'})
879                 = @$self{qw'curstash warnings hints hinthash'};
880     my $body;
881     if (not null $cv->ROOT) {
882         my $lineseq = $cv->ROOT->first;
883         if ($lineseq->name eq "lineseq") {
884             my @ops;
885             for(my$o=$lineseq->first; $$o; $o=$o->sibling) {
886                 push @ops, $o;
887             }
888             $body = $self->lineseq(undef, @ops).";";
889             my $scope_en = $self->find_scope_en($lineseq);
890             if (defined $scope_en) {
891                 my $subs = join"", $self->seq_subs($scope_en);
892                 $body .= ";\n$subs" if length($subs);
893             }
894         }
895         else {
896             $body = $self->deparse($cv->ROOT->first, 0);
897         }
898     }
899     else {
900         my $sv = $cv->const_sv;
901         if ($$sv) {
902             # uh-oh. inlinable sub... format it differently
903             return $proto . "{ " . $self->const($sv, 0) . " }\n";
904         } else { # XSUB? (or just a declaration)
905             return "$proto;\n";
906         }
907     }
908     return $proto ."{\n\t$body\n\b}" ."\n";
909 }
910
911 sub deparse_format {
912     my $self = shift;
913     my $form = shift;
914     my @text;
915     local($self->{'curcv'}) = $form;
916     local($self->{'curcvlex'});
917     local($self->{'in_format'}) = 1;
918     local(@$self{qw'curstash warnings hints hinthash'})
919                 = @$self{qw'curstash warnings hints hinthash'};
920     my $op = $form->ROOT;
921     my $kid;
922     return "\f." if $op->first->name eq 'stub'
923                 || $op->first->name eq 'nextstate';
924     $op = $op->first->first; # skip leavewrite, lineseq
925     while (not null $op) {
926         $op = $op->sibling; # skip nextstate
927         my @exprs;
928         $kid = $op->first->sibling; # skip pushmark
929         push @text, "\f".$self->const_sv($kid)->PV;
930         $kid = $kid->sibling;
931         for (; not null $kid; $kid = $kid->sibling) {
932             push @exprs, $self->deparse($kid, 0);
933         }
934         push @text, "\f".join(", ", @exprs)."\n" if @exprs;
935         $op = $op->sibling;
936     }
937     return join("", @text) . "\f.";
938 }
939
940 sub is_scope {
941     my $op = shift;
942     return $op->name eq "leave" || $op->name eq "scope"
943       || $op->name eq "lineseq"
944         || ($op->name eq "null" && class($op) eq "UNOP"
945             && (is_scope($op->first) || $op->first->name eq "enter"));
946 }
947
948 sub is_state {
949     my $name = $_[0]->name;
950     return $name eq "nextstate" || $name eq "dbstate" || $name eq "setstate";
951 }
952
953 sub is_miniwhile { # check for one-line loop ('foo() while $y--')
954     my $op = shift;
955     return (!null($op) and null($op->sibling)
956             and $op->name eq "null" and class($op) eq "UNOP"
957             and (($op->first->name =~ /^(and|or)$/
958                   and $op->first->first->sibling->name eq "lineseq")
959                  or ($op->first->name eq "lineseq"
960                      and not null $op->first->first->sibling
961                      and $op->first->first->sibling->name eq "unstack")
962                  ));
963 }
964
965 # Check if the op and its sibling are the initialization and the rest of a
966 # for (..;..;..) { ... } loop
967 sub is_for_loop {
968     my $op = shift;
969     # This OP might be almost anything, though it won't be a
970     # nextstate. (It's the initialization, so in the canonical case it
971     # will be an sassign.) The sibling is (old style) a lineseq whose
972     # first child is a nextstate and whose second is a leaveloop, or
973     # (new style) an unstack whose sibling is a leaveloop.
974     my $lseq = $op->sibling;
975     return 0 unless !is_state($op) and !null($lseq);
976     if ($lseq->name eq "lineseq") {
977         if ($lseq->first && !null($lseq->first) && is_state($lseq->first)
978             && (my $sib = $lseq->first->sibling)) {
979             return (!null($sib) && $sib->name eq "leaveloop");
980         }
981     } elsif ($lseq->name eq "unstack" && ($lseq->flags & OPf_SPECIAL)) {
982         my $sib = $lseq->sibling;
983         return $sib && !null($sib) && $sib->name eq "leaveloop";
984     }
985     return 0;
986 }
987
988 sub is_scalar {
989     my $op = shift;
990     return ($op->name eq "rv2sv" or
991             $op->name eq "padsv" or
992             $op->name eq "gv" or # only in array/hash constructs
993             $op->flags & OPf_KIDS && !null($op->first)
994               && $op->first->name eq "gvsv");
995 }
996
997 sub maybe_parens {
998     my $self = shift;
999     my($text, $cx, $prec) = @_;
1000     if ($prec < $cx              # unary ops nest just fine
1001         or $prec == $cx and $cx != 4 and $cx != 16 and $cx != 21
1002         or $self->{'parens'})
1003     {
1004         $text = "($text)";
1005         # In a unop, let parent reuse our parens; see maybe_parens_unop
1006         $text = "\cS" . $text if $cx == 16;
1007         return $text;
1008     } else {
1009         return $text;
1010     }
1011 }
1012
1013 # same as above, but get around the 'if it looks like a function' rule
1014 sub maybe_parens_unop {
1015     my $self = shift;
1016     my($name, $kid, $cx) = @_;
1017     if ($cx > 16 or $self->{'parens'}) {
1018         $kid =  $self->deparse($kid, 1);
1019         if ($name eq "umask" && $kid =~ /^\d+$/) {
1020             $kid = sprintf("%#o", $kid);
1021         }
1022         return $self->keyword($name) . "($kid)";
1023     } else {
1024         $kid = $self->deparse($kid, 16);
1025         if ($name eq "umask" && $kid =~ /^\d+$/) {
1026             $kid = sprintf("%#o", $kid);
1027         }
1028         $name = $self->keyword($name);
1029         if (substr($kid, 0, 1) eq "\cS") {
1030             # use kid's parens
1031             return $name . substr($kid, 1);
1032         } elsif (substr($kid, 0, 1) eq "(") {
1033             # avoid looks-like-a-function trap with extra parens
1034             # ('+' can lead to ambiguities)
1035             return "$name(" . $kid  . ")";
1036         } else {
1037             return "$name $kid";
1038         }
1039     }
1040 }
1041
1042 sub maybe_parens_func {
1043     my $self = shift;
1044     my($func, $text, $cx, $prec) = @_;
1045     if ($prec <= $cx or substr($text, 0, 1) eq "(" or $self->{'parens'}) {
1046         return "$func($text)";
1047     } else {
1048         return "$func $text";
1049     }
1050 }
1051
1052 sub maybe_local {
1053     my $self = shift;
1054     my($op, $cx, $text) = @_;
1055     my $our_intro = ($op->name =~ /^(gv|rv2)[ash]v$/) ? OPpOUR_INTRO : 0;
1056     if ($op->private & (OPpLVAL_INTRO|$our_intro)
1057         and not $self->{'avoid_local'}{$$op}) {
1058         my $our_local = ($op->private & OPpLVAL_INTRO) ? "local" : "our";
1059         if( $our_local eq 'our' ) {
1060             if ( $text !~ /^\W(\w+::)*\w+\z/
1061              and !utf8::decode($text) || $text !~ /^\W(\w+::)*\w+\z/
1062             ) {
1063                 die "Unexpected our($text)\n";
1064             }
1065             $text =~ s/(\w+::)+//;
1066         }
1067         if (want_scalar($op)) {
1068             return "$our_local $text";
1069         } else {
1070             return $self->maybe_parens_func("$our_local", $text, $cx, 16);
1071         }
1072     } else {
1073         return $text;
1074     }
1075 }
1076
1077 sub maybe_targmy {
1078     my $self = shift;
1079     my($op, $cx, $func, @args) = @_;
1080     if ($op->private & OPpTARGET_MY) {
1081         my $var = $self->padname($op->targ);
1082         my $val = $func->($self, $op, 7, @args);
1083         return $self->maybe_parens("$var = $val", $cx, 7);
1084     } else {
1085         return $func->($self, $op, $cx, @args);
1086     }
1087 }
1088
1089 sub padname_sv {
1090     my $self = shift;
1091     my $targ = shift;
1092     return $self->{'curcv'}->PADLIST->ARRAYelt(0)->ARRAYelt($targ);
1093 }
1094
1095 sub maybe_my {
1096     my $self = shift;
1097     my($op, $cx, $text) = @_;
1098     if ($op->private & OPpLVAL_INTRO and not $self->{'avoid_local'}{$$op}) {
1099         my $my = $op->private & OPpPAD_STATE
1100             ? $self->keyword("state")
1101             : "my";
1102         if (want_scalar($op)) {
1103             return "$my $text";
1104         } else {
1105             return $self->maybe_parens_func($my, $text, $cx, 16);
1106         }
1107     } else {
1108         return $text;
1109     }
1110 }
1111
1112 # The following OPs don't have functions:
1113
1114 # pp_padany -- does not exist after parsing
1115
1116 sub AUTOLOAD {
1117     if ($AUTOLOAD =~ s/^.*::pp_//) {
1118         warn "unexpected OP_".uc $AUTOLOAD;
1119         return "XXX";
1120     } else {
1121         die "Undefined subroutine $AUTOLOAD called";
1122     }
1123 }
1124
1125 sub DESTROY {}  #       Do not AUTOLOAD
1126
1127 # $root should be the op which represents the root of whatever
1128 # we're sequencing here. If it's undefined, then we don't append
1129 # any subroutine declarations to the deparsed ops, otherwise we
1130 # append appropriate declarations.
1131 sub lineseq {
1132     my($self, $root, @ops) = @_;
1133     my($expr, @exprs);
1134
1135     my $out_cop = $self->{'curcop'};
1136     my $out_seq = defined($out_cop) ? $out_cop->cop_seq : undef;
1137     my $limit_seq;
1138     if (defined $root) {
1139         $limit_seq = $out_seq;
1140         my $nseq;
1141         $nseq = $self->find_scope_st($root->sibling) if ${$root->sibling};
1142         $limit_seq = $nseq if !defined($limit_seq)
1143                            or defined($nseq) && $nseq < $limit_seq;
1144     }
1145     $limit_seq = $self->{'limit_seq'}
1146         if defined($self->{'limit_seq'})
1147         && (!defined($limit_seq) || $self->{'limit_seq'} < $limit_seq);
1148     local $self->{'limit_seq'} = $limit_seq;
1149
1150     $self->walk_lineseq($root, \@ops,
1151                        sub { push @exprs, $_[0]} );
1152
1153     my $body = join(";\n", grep {length} @exprs);
1154     my $subs = "";
1155     if (defined $root && defined $limit_seq && !$self->{'in_format'}) {
1156         $subs = join "\n", $self->seq_subs($limit_seq);
1157     }
1158     return join(";\n", grep {length} $body, $subs);
1159 }
1160
1161 sub scopeop {
1162     my($real_block, $self, $op, $cx) = @_;
1163     my $kid;
1164     my @kids;
1165
1166     local(@$self{qw'curstash warnings hints hinthash'})
1167                 = @$self{qw'curstash warnings hints hinthash'} if $real_block;
1168     if ($real_block) {
1169         $kid = $op->first->sibling; # skip enter
1170         if (is_miniwhile($kid)) {
1171             my $top = $kid->first;
1172             my $name = $top->name;
1173             if ($name eq "and") {
1174                 $name = "while";
1175             } elsif ($name eq "or") {
1176                 $name = "until";
1177             } else { # no conditional -> while 1 or until 0
1178                 return $self->deparse($top->first, 1) . " while 1";
1179             }
1180             my $cond = $top->first;
1181             my $body = $cond->sibling->first; # skip lineseq
1182             $cond = $self->deparse($cond, 1);
1183             $body = $self->deparse($body, 1);
1184             return "$body $name $cond";
1185         }
1186     } else {
1187         $kid = $op->first;
1188     }
1189     for (; !null($kid); $kid = $kid->sibling) {
1190         push @kids, $kid;
1191     }
1192     if ($cx > 0) { # inside an expression, (a do {} while for lineseq)
1193         return "do {\n\t" . $self->lineseq($op, @kids) . "\n\b}";
1194     } else {
1195         my $lineseq = $self->lineseq($op, @kids);
1196         return (length ($lineseq) ? "$lineseq;" : "");
1197     }
1198 }
1199
1200 sub pp_scope { scopeop(0, @_); }
1201 sub pp_lineseq { scopeop(0, @_); }
1202 sub pp_leave { scopeop(1, @_); }
1203
1204 # This is a special case of scopeop and lineseq, for the case of the
1205 # main_root. The difference is that we print the output statements as
1206 # soon as we get them, for the sake of impatient users.
1207 sub deparse_root {
1208     my $self = shift;
1209     my($op) = @_;
1210     local(@$self{qw'curstash warnings hints hinthash'})
1211       = @$self{qw'curstash warnings hints hinthash'};
1212     my @kids;
1213     return if null $op->first; # Can happen, e.g., for Bytecode without -k
1214     for (my $kid = $op->first->sibling; !null($kid); $kid = $kid->sibling) {
1215         push @kids, $kid;
1216     }
1217     $self->walk_lineseq($op, \@kids,
1218                         sub { print $self->indent($_[0].';');
1219                               print "\n" unless $_[1] == $#kids;
1220                           });
1221 }
1222
1223 sub walk_lineseq {
1224     my ($self, $op, $kids, $callback) = @_;
1225     my @kids = @$kids;
1226     for (my $i = 0; $i < @kids; $i++) {
1227         my $expr = "";
1228         if (is_state $kids[$i]) {
1229             $expr = $self->deparse($kids[$i++], 0);
1230             if ($i > $#kids) {
1231                 $callback->($expr, $i);
1232                 last;
1233             }
1234         }
1235         if (is_for_loop($kids[$i])) {
1236             $callback->($expr . $self->for_loop($kids[$i], 0),
1237                 $i += $kids[$i]->sibling->name eq "unstack" ? 2 : 1);
1238             next;
1239         }
1240         $expr .= $self->deparse($kids[$i], (@kids != 1)/2);
1241         $expr =~ s/;\n?\z//;
1242         $callback->($expr, $i);
1243     }
1244 }
1245
1246 # The BEGIN {} is used here because otherwise this code isn't executed
1247 # when you run B::Deparse on itself.
1248 my %globalnames;
1249 BEGIN { map($globalnames{$_}++, "SIG", "STDIN", "STDOUT", "STDERR", "INC",
1250             "ENV", "ARGV", "ARGVOUT", "_"); }
1251
1252 sub gv_name {
1253     my $self = shift;
1254     my $gv = shift;
1255 Carp::confess() unless ref($gv) eq "B::GV";
1256     my $stash = $gv->STASH->NAME;
1257     my $name = $gv->SAFENAME;
1258     if ($stash eq 'main' && $name =~ /^::/) {
1259         $stash = '::';
1260     }
1261     elsif (($stash eq 'main' && $globalnames{$name})
1262         or ($stash eq $self->{'curstash'} && !$globalnames{$name}
1263             && ($stash eq 'main' || $name !~ /::/))
1264         or $name =~ /^[^A-Za-z_:]/)
1265     {
1266         $stash = "";
1267     } else {
1268         $stash = $stash . "::";
1269     }
1270     if ($name =~ /^(\^..|{)/) {
1271         $name = "{$name}";       # ${^WARNING_BITS}, etc and ${
1272     }
1273     return $stash . $name;
1274 }
1275
1276 # Return the name to use for a stash variable.
1277 # If a lexical with the same name is in scope, it may need to be
1278 # fully-qualified.
1279 sub stash_variable {
1280     my ($self, $prefix, $name, $cx) = @_;
1281
1282     return "$prefix$name" if $name =~ /::/;
1283
1284     unless ($prefix eq '$' || $prefix eq '@' || #'
1285             $prefix eq '%' || $prefix eq '$#') {
1286         return "$prefix$name";
1287     }
1288
1289     if ($name =~ /^[^\w+-]$/) {
1290       if (defined $cx && $cx == 26) {
1291         if ($prefix eq '@') {
1292             return "$prefix\{$name}";
1293         }
1294         elsif ($name eq '#') { return '${#}' } #  "${#}a" vs "$#a"
1295       }
1296       if ($prefix eq '$#') {
1297         return "\$#{$name}";
1298       }
1299     }
1300
1301     my $v = ($prefix eq '$#' ? '@' : $prefix) . $name;
1302     return $prefix .$self->{'curstash'}.'::'. $name if $self->lex_in_scope($v);
1303     return "$prefix$name";
1304 }
1305
1306 sub lex_in_scope {
1307     my ($self, $name) = @_;
1308     $self->populate_curcvlex() if !defined $self->{'curcvlex'};
1309
1310     return 0 if !defined($self->{'curcop'});
1311     my $seq = $self->{'curcop'}->cop_seq;
1312     return 0 if !exists $self->{'curcvlex'}{$name};
1313     for my $a (@{$self->{'curcvlex'}{$name}}) {
1314         my ($st, $en) = @$a;
1315         return 1 if $seq > $st && $seq <= $en;
1316     }
1317     return 0;
1318 }
1319
1320 sub populate_curcvlex {
1321     my $self = shift;
1322     for (my $cv = $self->{'curcv'}; class($cv) eq "CV"; $cv = $cv->OUTSIDE) {
1323         my $padlist = $cv->PADLIST;
1324         # an undef CV still in lexical chain
1325         next if class($padlist) eq "SPECIAL";
1326         my @padlist = $padlist->ARRAY;
1327         my @ns = $padlist[0]->ARRAY;
1328
1329         for (my $i=0; $i<@ns; ++$i) {
1330             next if class($ns[$i]) eq "SPECIAL";
1331             next if $ns[$i]->FLAGS & SVpad_OUR;  # Skip "our" vars
1332             if (class($ns[$i]) eq "PV") {
1333                 # Probably that pesky lexical @_
1334                 next;
1335             }
1336             my $name = $ns[$i]->PVX;
1337             my ($seq_st, $seq_en) =
1338                 ($ns[$i]->FLAGS & SVf_FAKE)
1339                     ? (0, 999999)
1340                     : ($ns[$i]->COP_SEQ_RANGE_LOW, $ns[$i]->COP_SEQ_RANGE_HIGH);
1341
1342             push @{$self->{'curcvlex'}{$name}}, [$seq_st, $seq_en];
1343         }
1344     }
1345 }
1346
1347 sub find_scope_st { ((find_scope(@_))[0]); }
1348 sub find_scope_en { ((find_scope(@_))[1]); }
1349
1350 # Recurses down the tree, looking for pad variable introductions and COPs
1351 sub find_scope {
1352     my ($self, $op, $scope_st, $scope_en) = @_;
1353     carp("Undefined op in find_scope") if !defined $op;
1354     return ($scope_st, $scope_en) unless $op->flags & OPf_KIDS;
1355
1356     my @queue = ($op);
1357     while(my $op = shift @queue ) {
1358         for (my $o=$op->first; $$o; $o=$o->sibling) {
1359             if ($o->name =~ /^pad.v$/ && $o->private & OPpLVAL_INTRO) {
1360                 my $s = int($self->padname_sv($o->targ)->COP_SEQ_RANGE_LOW);
1361                 my $e = $self->padname_sv($o->targ)->COP_SEQ_RANGE_HIGH;
1362                 $scope_st = $s if !defined($scope_st) || $s < $scope_st;
1363                 $scope_en = $e if !defined($scope_en) || $e > $scope_en;
1364                 return ($scope_st, $scope_en);
1365             }
1366             elsif (is_state($o)) {
1367                 my $c = $o->cop_seq;
1368                 $scope_st = $c if !defined($scope_st) || $c < $scope_st;
1369                 $scope_en = $c if !defined($scope_en) || $c > $scope_en;
1370                 return ($scope_st, $scope_en);
1371             }
1372             elsif ($o->flags & OPf_KIDS) {
1373                 unshift (@queue, $o);
1374             }
1375         }
1376     }
1377
1378     return ($scope_st, $scope_en);
1379 }
1380
1381 # Returns a list of subs which should be inserted before the COP
1382 sub cop_subs {
1383     my ($self, $op, $out_seq) = @_;
1384     my $seq = $op->cop_seq;
1385     # If we have nephews, then our sequence number indicates
1386     # the cop_seq of the end of some sort of scope.
1387     if (class($op->sibling) ne "NULL" && $op->sibling->flags & OPf_KIDS
1388         and my $nseq = $self->find_scope_st($op->sibling) ) {
1389         $seq = $nseq;
1390     }
1391     $seq = $out_seq if defined($out_seq) && $out_seq < $seq;
1392     return $self->seq_subs($seq);
1393 }
1394
1395 sub seq_subs {
1396     my ($self, $seq) = @_;
1397     my @text;
1398 #push @text, "# ($seq)\n";
1399
1400     return "" if !defined $seq;
1401     while (scalar(@{$self->{'subs_todo'}})
1402            and $seq > $self->{'subs_todo'}[0][0]) {
1403         push @text, $self->next_todo;
1404     }
1405     return @text;
1406 }
1407
1408 # Notice how subs and formats are inserted between statements here;
1409 # also $[ assignments and pragmas.
1410 sub pp_nextstate {
1411     my $self = shift;
1412     my($op, $cx) = @_;
1413     $self->{'curcop'} = $op;
1414     my @text;
1415     push @text, $self->cop_subs($op);
1416     my $stash = $op->stashpv;
1417     if ($stash ne $self->{'curstash'}) {
1418         push @text, "package $stash;\n";
1419         $self->{'curstash'} = $stash;
1420     }
1421
1422     if (OPpCONST_ARYBASE && $self->{'arybase'} != $op->arybase) {
1423         push @text, '$[ = '. $op->arybase .";\n";
1424         $self->{'arybase'} = $op->arybase;
1425     }
1426
1427     my $warnings = $op->warnings;
1428     my $warning_bits;
1429     if ($warnings->isa("B::SPECIAL") && $$warnings == 4) {
1430         $warning_bits = $warnings::Bits{"all"} & WARN_MASK;
1431     }
1432     elsif ($warnings->isa("B::SPECIAL") && $$warnings == 5) {
1433         $warning_bits = $warnings::NONE;
1434     }
1435     elsif ($warnings->isa("B::SPECIAL")) {
1436         $warning_bits = undef;
1437     }
1438     else {
1439         $warning_bits = $warnings->PV & WARN_MASK;
1440     }
1441
1442     if (defined ($warning_bits) and
1443        !defined($self->{warnings}) || $self->{'warnings'} ne $warning_bits) {
1444         push @text, declare_warnings($self->{'warnings'}, $warning_bits);
1445         $self->{'warnings'} = $warning_bits;
1446     }
1447
1448     my $hints = $] < 5.008009 ? $op->private : $op->hints;
1449     if ($self->{'hints'} != $hints) {
1450         push @text, declare_hints($self->{'hints'}, $hints);
1451         $self->{'hints'} = $hints;
1452     }
1453
1454     if ($] > 5.009 &&
1455         @text != push @text, declare_hinthash(
1456             $self->{'hinthash'}, $op->hints_hash->HASH,
1457             $self->{indent_size}
1458         )
1459     ) {
1460         $self->{'hinthash'} = $op->hints_hash->HASH;
1461     }
1462
1463     # This should go after of any branches that add statements, to
1464     # increase the chances that it refers to the same line it did in
1465     # the original program.
1466     if ($self->{'linenums'}) {
1467         push @text, "\f#line " . $op->line .
1468           ' "' . $op->file, qq'"\n';
1469     }
1470
1471     push @text, $op->label . ": " if $op->label;
1472
1473     return join("", @text);
1474 }
1475
1476 sub declare_warnings {
1477     my ($from, $to) = @_;
1478     if (($to & WARN_MASK) eq (warnings::bits("all") & WARN_MASK)) {
1479         return "use warnings;\n";
1480     }
1481     elsif (($to & WARN_MASK) eq ("\0"x length($to) & WARN_MASK)) {
1482         return "no warnings;\n";
1483     }
1484     return "BEGIN {\${^WARNING_BITS} = ".perlstring($to)."}\n";
1485 }
1486
1487 sub declare_hints {
1488     my ($from, $to) = @_;
1489     my $use = $to   & ~$from;
1490     my $no  = $from & ~$to;
1491     my $decls = "";
1492     for my $pragma (hint_pragmas($use)) {
1493         $decls .= "use $pragma;\n";
1494     }
1495     for my $pragma (hint_pragmas($no)) {
1496         $decls .= "no $pragma;\n";
1497     }
1498     return $decls;
1499 }
1500
1501 # Internal implementation hints that the core sets automatically, so don't need
1502 # (or want) to be passed back to the user
1503 my %ignored_hints = (
1504     'open<' => 1,
1505     'open>' => 1,
1506     ':'     => 1,
1507 );
1508
1509 sub declare_hinthash {
1510     my ($from, $to, $indent) = @_;
1511     my @decls;
1512     for my $key (keys %$to) {
1513         next if $ignored_hints{$key};
1514         if (!exists $from->{$key} or $from->{$key} ne $to->{$key}) {
1515             push @decls,
1516                 qq(\$^H{) . single_delim("q", "'", $key) . qq(} = )
1517               . (
1518                    defined $to->{$key}
1519                         ? single_delim("q", "'", $to->{$key})
1520                         : 'undef'
1521                 )
1522               . qq(;);
1523         }
1524     }
1525     for my $key (keys %$from) {
1526         next if $ignored_hints{$key};
1527         if (!exists $to->{$key}) {
1528             push @decls, qq(delete \$^H{'$key'};);
1529         }
1530     }
1531     @decls or return;
1532     return join("\n" . (" " x $indent), "BEGIN {", @decls) . "\n}\n";
1533 }
1534
1535 sub hint_pragmas {
1536     my ($bits) = @_;
1537     my @pragmas;
1538     push @pragmas, "integer" if $bits & 0x1;
1539     push @pragmas, "strict 'refs'" if $bits & 0x2;
1540     push @pragmas, "bytes" if $bits & 0x8;
1541     return @pragmas;
1542 }
1543
1544 sub pp_dbstate { pp_nextstate(@_) }
1545 sub pp_setstate { pp_nextstate(@_) }
1546
1547 sub pp_unstack { return "" } # see also leaveloop
1548
1549 my %feature_keywords = (
1550   # keyword => 'feature',
1551     state   => 'state',
1552     say     => 'say',
1553     given   => 'switch',
1554     when    => 'switch',
1555     default => 'switch',
1556     break   => 'switch',
1557     evalbytes=>'evalbytes',
1558     __SUB__ => '__SUB__',
1559 );
1560
1561 sub keyword {
1562     my $self = shift;
1563     my $name = shift;
1564     return $name if $name =~ /^CORE::/; # just in case
1565     if (exists $feature_keywords{$name}) {
1566         return "CORE::$name"
1567          if !$self->{'hinthash'}
1568          || !$self->{'hinthash'}{"feature_$feature_keywords{$name}"}
1569     }
1570     if (
1571       $name !~ /^(?:chom?p|do|exec|glob|s(?:elect|ystem))\z/
1572        && !defined eval{prototype "CORE::$name"}
1573     ) { return $name }
1574     if (
1575         exists $self->{subs_declared}{$name}
1576          or
1577         exists &{"$self->{curstash}::$name"}
1578     ) {
1579         return "CORE::$name"
1580     }
1581     return $name;
1582 }
1583
1584 sub baseop {
1585     my $self = shift;
1586     my($op, $cx, $name) = @_;
1587     return $self->keyword($name);
1588 }
1589
1590 sub pp_stub {
1591     my $self = shift;
1592     my($op, $cx, $name) = @_;
1593     if ($cx >= 1) {
1594         return "()";
1595     }
1596     else {
1597         return "();";
1598     }
1599 }
1600 sub pp_wantarray { baseop(@_, "wantarray") }
1601 sub pp_fork { baseop(@_, "fork") }
1602 sub pp_wait { maybe_targmy(@_, \&baseop, "wait") }
1603 sub pp_getppid { maybe_targmy(@_, \&baseop, "getppid") }
1604 sub pp_time { maybe_targmy(@_, \&baseop, "time") }
1605 sub pp_tms { baseop(@_, "times") }
1606 sub pp_ghostent { baseop(@_, "gethostent") }
1607 sub pp_gnetent { baseop(@_, "getnetent") }
1608 sub pp_gprotoent { baseop(@_, "getprotoent") }
1609 sub pp_gservent { baseop(@_, "getservent") }
1610 sub pp_ehostent { baseop(@_, "endhostent") }
1611 sub pp_enetent { baseop(@_, "endnetent") }
1612 sub pp_eprotoent { baseop(@_, "endprotoent") }
1613 sub pp_eservent { baseop(@_, "endservent") }
1614 sub pp_gpwent { baseop(@_, "getpwent") }
1615 sub pp_spwent { baseop(@_, "setpwent") }
1616 sub pp_epwent { baseop(@_, "endpwent") }
1617 sub pp_ggrent { baseop(@_, "getgrent") }
1618 sub pp_sgrent { baseop(@_, "setgrent") }
1619 sub pp_egrent { baseop(@_, "endgrent") }
1620 sub pp_getlogin { baseop(@_, "getlogin") }
1621
1622 sub POSTFIX () { 1 }
1623
1624 # I couldn't think of a good short name, but this is the category of
1625 # symbolic unary operators with interesting precedence
1626
1627 sub pfixop {
1628     my $self = shift;
1629     my($op, $cx, $name, $prec, $flags) = (@_, 0);
1630     my $kid = $op->first;
1631     $kid = $self->deparse($kid, $prec);
1632     return $self->maybe_parens(($flags & POSTFIX)
1633                                  ? "$kid$name"
1634                                    # avoid confusion with filetests
1635                                  : $name eq '-'
1636                                    && $kid =~ /^[a-zA-Z](?!\w)/
1637                                         ? "$name($kid)"
1638                                         : "$name$kid",
1639                                $cx, $prec);
1640 }
1641
1642 sub pp_preinc { pfixop(@_, "++", 23) }
1643 sub pp_predec { pfixop(@_, "--", 23) }
1644 sub pp_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1645 sub pp_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1646 sub pp_i_preinc { pfixop(@_, "++", 23) }
1647 sub pp_i_predec { pfixop(@_, "--", 23) }
1648 sub pp_i_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1649 sub pp_i_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1650 sub pp_complement { maybe_targmy(@_, \&pfixop, "~", 21) }
1651
1652 sub pp_negate { maybe_targmy(@_, \&real_negate) }
1653 sub real_negate {
1654     my $self = shift;
1655     my($op, $cx) = @_;
1656     if ($op->first->name =~ /^(i_)?negate$/) {
1657         # avoid --$x
1658         $self->pfixop($op, $cx, "-", 21.5);
1659     } else {
1660         $self->pfixop($op, $cx, "-", 21);       
1661     }
1662 }
1663 sub pp_i_negate { pp_negate(@_) }
1664
1665 sub pp_not {
1666     my $self = shift;
1667     my($op, $cx) = @_;
1668     if ($cx <= 4) {
1669         $self->listop($op, $cx, "not", $op->first);
1670     } else {
1671         $self->pfixop($op, $cx, "!", 21);       
1672     }
1673 }
1674
1675 sub unop {
1676     my $self = shift;
1677     my($op, $cx, $name, $nollafr) = @_;
1678     my $kid;
1679     if ($op->flags & OPf_KIDS) {
1680         $kid = $op->first;
1681         if (not $name) {
1682             # this deals with 'boolkeys' right now
1683             return $self->deparse($kid,$cx);
1684         }
1685         my $builtinname = $name;
1686         $builtinname =~ /^CORE::/ or $builtinname = "CORE::$name";
1687         if (defined prototype($builtinname)
1688            && prototype($builtinname) =~ /^;?\*/
1689            && $kid->name eq "rv2gv") {
1690             $kid = $kid->first;
1691         }
1692
1693         if ($nollafr) {
1694             ($kid = $self->deparse($kid, 16)) =~ s/^\cS//;
1695             return $self->maybe_parens(
1696                         $self->keyword($name) . " $kid", $cx, 16
1697                    );
1698         }   
1699         return $self->maybe_parens_unop($name, $kid, $cx);
1700     } else {
1701         return $self->maybe_parens(
1702             $self->keyword($name) . ($op->flags & OPf_SPECIAL ? "()" : ""),
1703             $cx, 16,
1704         );
1705     }
1706 }
1707
1708 sub pp_chop { maybe_targmy(@_, \&unop, "chop") }
1709 sub pp_chomp { maybe_targmy(@_, \&unop, "chomp") }
1710 sub pp_schop { maybe_targmy(@_, \&unop, "chop") }
1711 sub pp_schomp { maybe_targmy(@_, \&unop, "chomp") }
1712 sub pp_defined { unop(@_, "defined") }
1713 sub pp_undef { unop(@_, "undef") }
1714 sub pp_study { unop(@_, "study") }
1715 sub pp_ref { unop(@_, "ref") }
1716 sub pp_pos { maybe_local(@_, unop(@_, "pos")) }
1717
1718 sub pp_sin { maybe_targmy(@_, \&unop, "sin") }
1719 sub pp_cos { maybe_targmy(@_, \&unop, "cos") }
1720 sub pp_rand { maybe_targmy(@_, \&unop, "rand") }
1721 sub pp_srand { unop(@_, "srand") }
1722 sub pp_exp { maybe_targmy(@_, \&unop, "exp") }
1723 sub pp_log { maybe_targmy(@_, \&unop, "log") }
1724 sub pp_sqrt { maybe_targmy(@_, \&unop, "sqrt") }
1725 sub pp_int { maybe_targmy(@_, \&unop, "int") }
1726 sub pp_hex { maybe_targmy(@_, \&unop, "hex") }
1727 sub pp_oct { maybe_targmy(@_, \&unop, "oct") }
1728 sub pp_abs { maybe_targmy(@_, \&unop, "abs") }
1729
1730 sub pp_length { maybe_targmy(@_, \&unop, "length") }
1731 sub pp_ord { maybe_targmy(@_, \&unop, "ord") }
1732 sub pp_chr { maybe_targmy(@_, \&unop, "chr") }
1733
1734 sub pp_each { unop(@_, "each") }
1735 sub pp_values { unop(@_, "values") }
1736 sub pp_keys { unop(@_, "keys") }
1737 { no strict 'refs'; *{"pp_r$_"} = *{"pp_$_"} for qw< keys each values >; }
1738 sub pp_boolkeys { 
1739     # no name because its an optimisation op that has no keyword
1740     unop(@_,"");
1741 }
1742 sub pp_aeach { unop(@_, "each") }
1743 sub pp_avalues { unop(@_, "values") }
1744 sub pp_akeys { unop(@_, "keys") }
1745 sub pp_pop { unop(@_, "pop") }
1746 sub pp_shift { unop(@_, "shift") }
1747
1748 sub pp_caller { unop(@_, "caller") }
1749 sub pp_reset { unop(@_, "reset") }
1750 sub pp_exit { unop(@_, "exit") }
1751 sub pp_prototype { unop(@_, "prototype") }
1752
1753 sub pp_close { unop(@_, "close") }
1754 sub pp_fileno { unop(@_, "fileno") }
1755 sub pp_umask { unop(@_, "umask") }
1756 sub pp_untie { unop(@_, "untie") }
1757 sub pp_tied { unop(@_, "tied") }
1758 sub pp_dbmclose { unop(@_, "dbmclose") }
1759 sub pp_getc { unop(@_, "getc") }
1760 sub pp_eof { unop(@_, "eof") }
1761 sub pp_tell { unop(@_, "tell") }
1762 sub pp_getsockname { unop(@_, "getsockname") }
1763 sub pp_getpeername { unop(@_, "getpeername") }
1764
1765 sub pp_chdir { maybe_targmy(@_, \&unop, "chdir") }
1766 sub pp_chroot { maybe_targmy(@_, \&unop, "chroot") }
1767 sub pp_readlink { unop(@_, "readlink") }
1768 sub pp_rmdir { maybe_targmy(@_, \&unop, "rmdir") }
1769 sub pp_readdir { unop(@_, "readdir") }
1770 sub pp_telldir { unop(@_, "telldir") }
1771 sub pp_rewinddir { unop(@_, "rewinddir") }
1772 sub pp_closedir { unop(@_, "closedir") }
1773 sub pp_getpgrp { maybe_targmy(@_, \&unop, "getpgrp") }
1774 sub pp_localtime { unop(@_, "localtime") }
1775 sub pp_gmtime { unop(@_, "gmtime") }
1776 sub pp_alarm { unop(@_, "alarm") }
1777 sub pp_sleep { maybe_targmy(@_, \&unop, "sleep") }
1778
1779 sub pp_dofile {
1780     my $code = unop(@_, "do", 1); # llafr does not apply
1781     if ($code =~ s/^((?:CORE::)?do) \{/$1({/) { $code .= ')' }
1782     $code;
1783 }
1784 sub pp_entereval {
1785     unop(
1786       @_,
1787       $_[1]->private & OPpEVAL_BYTES ? $_[0]->keyword('evalbytes') : "eval"
1788     )
1789 }
1790
1791 sub pp_ghbyname { unop(@_, "gethostbyname") }
1792 sub pp_gnbyname { unop(@_, "getnetbyname") }
1793 sub pp_gpbyname { unop(@_, "getprotobyname") }
1794 sub pp_shostent { unop(@_, "sethostent") }
1795 sub pp_snetent { unop(@_, "setnetent") }
1796 sub pp_sprotoent { unop(@_, "setprotoent") }
1797 sub pp_sservent { unop(@_, "setservent") }
1798 sub pp_gpwnam { unop(@_, "getpwnam") }
1799 sub pp_gpwuid { unop(@_, "getpwuid") }
1800 sub pp_ggrnam { unop(@_, "getgrnam") }
1801 sub pp_ggrgid { unop(@_, "getgrgid") }
1802
1803 sub pp_lock { unop(@_, "lock") }
1804
1805 sub pp_continue { unop(@_, "continue"); }
1806 sub pp_break { unop(@_, "break"); }
1807
1808 sub givwhen {
1809     my $self = shift;
1810     my($op, $cx, $givwhen) = @_;
1811
1812     my $enterop = $op->first;
1813     my ($head, $block);
1814     if ($enterop->flags & OPf_SPECIAL) {
1815         $head = $self->keyword("default");
1816         $block = $self->deparse($enterop->first, 0);
1817     }
1818     else {
1819         my $cond = $enterop->first;
1820         my $cond_str = $self->deparse($cond, 1);
1821         $head = "$givwhen ($cond_str)";
1822         $block = $self->deparse($cond->sibling, 0);
1823     }
1824
1825     return "$head {\n".
1826         "\t$block\n".
1827         "\b}\cK";
1828 }
1829
1830 sub pp_leavegiven { givwhen(@_, $_[0]->keyword("given")); }
1831 sub pp_leavewhen  { givwhen(@_, $_[0]->keyword("when")); }
1832
1833 sub pp_exists {
1834     my $self = shift;
1835     my($op, $cx) = @_;
1836     my $arg;
1837     if ($op->private & OPpEXISTS_SUB) {
1838         # Checking for the existence of a subroutine
1839         return $self->maybe_parens_func("exists",
1840                                 $self->pp_rv2cv($op->first, 16), $cx, 16);
1841     }
1842     if ($op->flags & OPf_SPECIAL) {
1843         # Array element, not hash element
1844         return $self->maybe_parens_func("exists",
1845                                 $self->pp_aelem($op->first, 16), $cx, 16);
1846     }
1847     return $self->maybe_parens_func("exists", $self->pp_helem($op->first, 16),
1848                                     $cx, 16);
1849 }
1850
1851 sub pp_delete {
1852     my $self = shift;
1853     my($op, $cx) = @_;
1854     my $arg;
1855     if ($op->private & OPpSLICE) {
1856         if ($op->flags & OPf_SPECIAL) {
1857             # Deleting from an array, not a hash
1858             return $self->maybe_parens_func("delete",
1859                                         $self->pp_aslice($op->first, 16),
1860                                         $cx, 16);
1861         }
1862         return $self->maybe_parens_func("delete",
1863                                         $self->pp_hslice($op->first, 16),
1864                                         $cx, 16);
1865     } else {
1866         if ($op->flags & OPf_SPECIAL) {
1867             # Deleting from an array, not a hash
1868             return $self->maybe_parens_func("delete",
1869                                         $self->pp_aelem($op->first, 16),
1870                                         $cx, 16);
1871         }
1872         return $self->maybe_parens_func("delete",
1873                                         $self->pp_helem($op->first, 16),
1874                                         $cx, 16);
1875     }
1876 }
1877
1878 sub pp_require {
1879     my $self = shift;
1880     my($op, $cx) = @_;
1881     my $opname = $op->flags & OPf_SPECIAL ? 'CORE::require' : 'require';
1882     if (class($op) eq "UNOP" and $op->first->name eq "const"
1883         and $op->first->private & OPpCONST_BARE)
1884     {
1885         my $name = $self->const_sv($op->first)->PV;
1886         $name =~ s[/][::]g;
1887         $name =~ s/\.pm//g;
1888         return $self->maybe_parens("$opname $name", $cx, 16);
1889     } else {    
1890         $self->unop(
1891             $op, $cx,
1892             $op->first->private & OPpCONST_NOVER ? "no" : $opname,
1893             1, # llafr does not apply
1894         );
1895     }
1896 }
1897
1898 sub pp_scalar {
1899     my $self = shift;
1900     my($op, $cx) = @_;
1901     my $kid = $op->first;
1902     if (not null $kid->sibling) {
1903         # XXX Was a here-doc
1904         return $self->dquote($op);
1905     }
1906     $self->unop(@_, "scalar");
1907 }
1908
1909
1910 sub padval {
1911     my $self = shift;
1912     my $targ = shift;
1913     return $self->{'curcv'}->PADLIST->ARRAYelt(1)->ARRAYelt($targ);
1914 }
1915
1916 sub anon_hash_or_list {
1917     my $self = shift;
1918     my($op, $cx) = @_;
1919
1920     my($pre, $post) = @{{"anonlist" => ["[","]"],
1921                          "anonhash" => ["{","}"]}->{$op->name}};
1922     my($expr, @exprs);
1923     $op = $op->first->sibling; # skip pushmark
1924     for (; !null($op); $op = $op->sibling) {
1925         $expr = $self->deparse($op, 6);
1926         push @exprs, $expr;
1927     }
1928     if ($pre eq "{" and $cx < 1) {
1929         # Disambiguate that it's not a block
1930         $pre = "+{";
1931     }
1932     return $pre . join(", ", @exprs) . $post;
1933 }
1934
1935 sub pp_anonlist {
1936     my $self = shift;
1937     my ($op, $cx) = @_;
1938     if ($op->flags & OPf_SPECIAL) {
1939         return $self->anon_hash_or_list($op, $cx);
1940     }
1941     warn "Unexpected op pp_" . $op->name() . " without OPf_SPECIAL";
1942     return 'XXX';
1943 }
1944
1945 *pp_anonhash = \&pp_anonlist;
1946
1947 sub pp_refgen {
1948     my $self = shift;   
1949     my($op, $cx) = @_;
1950     my $kid = $op->first;
1951     if ($kid->name eq "null") {
1952         $kid = $kid->first;
1953         if (!null($kid->sibling) and
1954                  $kid->sibling->name eq "anoncode") {
1955             return $self->e_anoncode({ code => $self->padval($kid->sibling->targ) });
1956         } elsif ($kid->name eq "pushmark") {
1957             my $sib_name = $kid->sibling->name;
1958             if ($sib_name =~ /^(pad|rv2)[ah]v$/
1959                 and not $kid->sibling->flags & OPf_REF)
1960             {
1961                 # The @a in \(@a) isn't in ref context, but only when the
1962                 # parens are there.
1963                 return "\\(" . $self->pp_list($op->first) . ")";
1964             } elsif ($sib_name eq 'entersub') {
1965                 my $text = $self->deparse($kid->sibling, 1);
1966                 # Always show parens for \(&func()), but only with -p otherwise
1967                 $text = "($text)" if $self->{'parens'}
1968                                  or $kid->sibling->private & OPpENTERSUB_AMPER;
1969                 return "\\$text";
1970             }
1971         }
1972     }
1973     $self->pfixop($op, $cx, "\\", 20);
1974 }
1975
1976 sub e_anoncode {
1977     my ($self, $info) = @_;
1978     my $text = $self->deparse_sub($info->{code});
1979     return "sub " . $text;
1980 }
1981
1982 sub pp_srefgen { pp_refgen(@_) }
1983
1984 sub pp_readline {
1985     my $self = shift;
1986     my($op, $cx) = @_;
1987     my $kid = $op->first;
1988     $kid = $kid->first if $kid->name eq "rv2gv"; # <$fh>
1989     return "<" . $self->deparse($kid, 1) . ">" if is_scalar($kid);
1990     return $self->unop($op, $cx, "readline");
1991 }
1992
1993 sub pp_rcatline {
1994     my $self = shift;
1995     my($op) = @_;
1996     return "<" . $self->gv_name($self->gv_or_padgv($op)) . ">";
1997 }
1998
1999 # Unary operators that can occur as pseudo-listops inside double quotes
2000 sub dq_unop {
2001     my $self = shift;
2002     my($op, $cx, $name, $prec, $flags) = (@_, 0, 0);
2003     my $kid;
2004     if ($op->flags & OPf_KIDS) {
2005        $kid = $op->first;
2006        # If there's more than one kid, the first is an ex-pushmark.
2007        $kid = $kid->sibling if not null $kid->sibling;
2008        return $self->maybe_parens_unop($name, $kid, $cx);
2009     } else {
2010        return $name .  ($op->flags & OPf_SPECIAL ? "()" : "");
2011     }
2012 }
2013
2014 sub pp_ucfirst { dq_unop(@_, "ucfirst") }
2015 sub pp_lcfirst { dq_unop(@_, "lcfirst") }
2016 sub pp_uc { dq_unop(@_, "uc") }
2017 sub pp_lc { dq_unop(@_, "lc") }
2018 sub pp_quotemeta { maybe_targmy(@_, \&dq_unop, "quotemeta") }
2019
2020 sub loopex {
2021     my $self = shift;
2022     my ($op, $cx, $name) = @_;
2023     if (class($op) eq "PVOP") {
2024         $name .= " " . $op->pv;
2025     } elsif (class($op) eq "OP") {
2026         # no-op
2027     } elsif (class($op) eq "UNOP") {
2028         (my $kid = $self->deparse($op->first, 16)) =~ s/^\cS//;
2029         $name .= " $kid";
2030     }
2031     return $self->maybe_parens($name, $cx, 16);
2032 }
2033
2034 sub pp_last { loopex(@_, "last") }
2035 sub pp_next { loopex(@_, "next") }
2036 sub pp_redo { loopex(@_, "redo") }
2037 sub pp_goto { loopex(@_, "goto") }
2038 sub pp_dump { loopex(@_, "CORE::dump") }
2039
2040 sub ftst {
2041     my $self = shift;
2042     my($op, $cx, $name) = @_;
2043     if (class($op) eq "UNOP") {
2044         # Genuine '-X' filetests are exempt from the LLAFR, but not
2045         # l?stat()
2046         if ($name =~ /^-/) {
2047             (my $kid = $self->deparse($op->first, 16)) =~ s/^\cS//;
2048             return $self->maybe_parens("$name $kid", $cx, 16);
2049         }
2050         return $self->maybe_parens_unop($name, $op->first, $cx);
2051     } elsif (class($op) =~ /^(SV|PAD)OP$/) {
2052         return $self->maybe_parens_func($name, $self->pp_gv($op, 1), $cx, 16);
2053     } else { # I don't think baseop filetests ever survive ck_ftst, but...
2054         return $name;
2055     }
2056 }
2057
2058 sub pp_lstat    { ftst(@_, "lstat") }
2059 sub pp_stat     { ftst(@_, "stat") }
2060 sub pp_ftrread  { ftst(@_, "-R") }
2061 sub pp_ftrwrite { ftst(@_, "-W") }
2062 sub pp_ftrexec  { ftst(@_, "-X") }
2063 sub pp_fteread  { ftst(@_, "-r") }
2064 sub pp_ftewrite { ftst(@_, "-w") }
2065 sub pp_fteexec  { ftst(@_, "-x") }
2066 sub pp_ftis     { ftst(@_, "-e") }
2067 sub pp_fteowned { ftst(@_, "-O") }
2068 sub pp_ftrowned { ftst(@_, "-o") }
2069 sub pp_ftzero   { ftst(@_, "-z") }
2070 sub pp_ftsize   { ftst(@_, "-s") }
2071 sub pp_ftmtime  { ftst(@_, "-M") }
2072 sub pp_ftatime  { ftst(@_, "-A") }
2073 sub pp_ftctime  { ftst(@_, "-C") }
2074 sub pp_ftsock   { ftst(@_, "-S") }
2075 sub pp_ftchr    { ftst(@_, "-c") }
2076 sub pp_ftblk    { ftst(@_, "-b") }
2077 sub pp_ftfile   { ftst(@_, "-f") }
2078 sub pp_ftdir    { ftst(@_, "-d") }
2079 sub pp_ftpipe   { ftst(@_, "-p") }
2080 sub pp_ftlink   { ftst(@_, "-l") }
2081 sub pp_ftsuid   { ftst(@_, "-u") }
2082 sub pp_ftsgid   { ftst(@_, "-g") }
2083 sub pp_ftsvtx   { ftst(@_, "-k") }
2084 sub pp_fttty    { ftst(@_, "-t") }
2085 sub pp_fttext   { ftst(@_, "-T") }
2086 sub pp_ftbinary { ftst(@_, "-B") }
2087
2088 sub SWAP_CHILDREN () { 1 }
2089 sub ASSIGN () { 2 } # has OP= variant
2090 sub LIST_CONTEXT () { 4 } # Assignment is in list context
2091
2092 my(%left, %right);
2093
2094 sub assoc_class {
2095     my $op = shift;
2096     my $name = $op->name;
2097     if ($name eq "concat" and $op->first->name eq "concat") {
2098         # avoid spurious '=' -- see comment in pp_concat
2099         return "concat";
2100     }
2101     if ($name eq "null" and class($op) eq "UNOP"
2102         and $op->first->name =~ /^(and|x?or)$/
2103         and null $op->first->sibling)
2104     {
2105         # Like all conditional constructs, OP_ANDs and OP_ORs are topped
2106         # with a null that's used as the common end point of the two
2107         # flows of control. For precedence purposes, ignore it.
2108         # (COND_EXPRs have these too, but we don't bother with
2109         # their associativity).
2110         return assoc_class($op->first);
2111     }
2112     return $name . ($op->flags & OPf_STACKED ? "=" : "");
2113 }
2114
2115 # Left associative operators, like '+', for which
2116 # $a + $b + $c is equivalent to ($a + $b) + $c
2117
2118 BEGIN {
2119     %left = ('multiply' => 19, 'i_multiply' => 19,
2120              'divide' => 19, 'i_divide' => 19,
2121              'modulo' => 19, 'i_modulo' => 19,
2122              'repeat' => 19,
2123              'add' => 18, 'i_add' => 18,
2124              'subtract' => 18, 'i_subtract' => 18,
2125              'concat' => 18,
2126              'left_shift' => 17, 'right_shift' => 17,
2127              'bit_and' => 13,
2128              'bit_or' => 12, 'bit_xor' => 12,
2129              'and' => 3,
2130              'or' => 2, 'xor' => 2,
2131             );
2132 }
2133
2134 sub deparse_binop_left {
2135     my $self = shift;
2136     my($op, $left, $prec) = @_;
2137     if ($left{assoc_class($op)} && $left{assoc_class($left)}
2138         and $left{assoc_class($op)} == $left{assoc_class($left)})
2139     {
2140         return $self->deparse($left, $prec - .00001);
2141     } else {
2142         return $self->deparse($left, $prec);    
2143     }
2144 }
2145
2146 # Right associative operators, like '=', for which
2147 # $a = $b = $c is equivalent to $a = ($b = $c)
2148
2149 BEGIN {
2150     %right = ('pow' => 22,
2151               'sassign=' => 7, 'aassign=' => 7,
2152               'multiply=' => 7, 'i_multiply=' => 7,
2153               'divide=' => 7, 'i_divide=' => 7,
2154               'modulo=' => 7, 'i_modulo=' => 7,
2155               'repeat=' => 7,
2156               'add=' => 7, 'i_add=' => 7,
2157               'subtract=' => 7, 'i_subtract=' => 7,
2158               'concat=' => 7,
2159               'left_shift=' => 7, 'right_shift=' => 7,
2160               'bit_and=' => 7,
2161               'bit_or=' => 7, 'bit_xor=' => 7,
2162               'andassign' => 7,
2163               'orassign' => 7,
2164              );
2165 }
2166
2167 sub deparse_binop_right {
2168     my $self = shift;
2169     my($op, $right, $prec) = @_;
2170     if ($right{assoc_class($op)} && $right{assoc_class($right)}
2171         and $right{assoc_class($op)} == $right{assoc_class($right)})
2172     {
2173         return $self->deparse($right, $prec - .00001);
2174     } else {
2175         return $self->deparse($right, $prec);   
2176     }
2177 }
2178
2179 sub binop {
2180     my $self = shift;
2181     my ($op, $cx, $opname, $prec, $flags) = (@_, 0);
2182     my $left = $op->first;
2183     my $right = $op->last;
2184     my $eq = "";
2185     if ($op->flags & OPf_STACKED && $flags & ASSIGN) {
2186         $eq = "=";
2187         $prec = 7;
2188     }
2189     if ($flags & SWAP_CHILDREN) {
2190         ($left, $right) = ($right, $left);
2191     }
2192     $left = $self->deparse_binop_left($op, $left, $prec);
2193     $left = "($left)" if $flags & LIST_CONTEXT
2194                 && $left !~ /^(my|our|local|)[\@\(]/;
2195     $right = $self->deparse_binop_right($op, $right, $prec);
2196     return $self->maybe_parens("$left $opname$eq $right", $cx, $prec);
2197 }
2198
2199 sub pp_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
2200 sub pp_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
2201 sub pp_subtract { maybe_targmy(@_, \&binop, "-",18,  ASSIGN) }
2202 sub pp_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
2203 sub pp_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
2204 sub pp_i_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
2205 sub pp_i_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
2206 sub pp_i_subtract { maybe_targmy(@_, \&binop, "-", 18, ASSIGN) }
2207 sub pp_i_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
2208 sub pp_i_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
2209 sub pp_pow { maybe_targmy(@_, \&binop, "**", 22, ASSIGN) }
2210
2211 sub pp_left_shift { maybe_targmy(@_, \&binop, "<<", 17, ASSIGN) }
2212 sub pp_right_shift { maybe_targmy(@_, \&binop, ">>", 17, ASSIGN) }
2213 sub pp_bit_and { maybe_targmy(@_, \&binop, "&", 13, ASSIGN) }
2214 sub pp_bit_or { maybe_targmy(@_, \&binop, "|", 12, ASSIGN) }
2215 sub pp_bit_xor { maybe_targmy(@_, \&binop, "^", 12, ASSIGN) }
2216
2217 sub pp_eq { binop(@_, "==", 14) }
2218 sub pp_ne { binop(@_, "!=", 14) }
2219 sub pp_lt { binop(@_, "<", 15) }
2220 sub pp_gt { binop(@_, ">", 15) }
2221 sub pp_ge { binop(@_, ">=", 15) }
2222 sub pp_le { binop(@_, "<=", 15) }
2223 sub pp_ncmp { binop(@_, "<=>", 14) }
2224 sub pp_i_eq { binop(@_, "==", 14) }
2225 sub pp_i_ne { binop(@_, "!=", 14) }
2226 sub pp_i_lt { binop(@_, "<", 15) }
2227 sub pp_i_gt { binop(@_, ">", 15) }
2228 sub pp_i_ge { binop(@_, ">=", 15) }
2229 sub pp_i_le { binop(@_, "<=", 15) }
2230 sub pp_i_ncmp { binop(@_, "<=>", 14) }
2231
2232 sub pp_seq { binop(@_, "eq", 14) }
2233 sub pp_sne { binop(@_, "ne", 14) }
2234 sub pp_slt { binop(@_, "lt", 15) }
2235 sub pp_sgt { binop(@_, "gt", 15) }
2236 sub pp_sge { binop(@_, "ge", 15) }
2237 sub pp_sle { binop(@_, "le", 15) }
2238 sub pp_scmp { binop(@_, "cmp", 14) }
2239
2240 sub pp_sassign { binop(@_, "=", 7, SWAP_CHILDREN) }
2241 sub pp_aassign { binop(@_, "=", 7, SWAP_CHILDREN | LIST_CONTEXT) }
2242
2243 sub pp_smartmatch {
2244     my ($self, $op, $cx) = @_;
2245     if ($op->flags & OPf_SPECIAL) {
2246         return $self->deparse($op->last, $cx);
2247     }
2248     else {
2249         binop(@_, "~~", 14);
2250     }
2251 }
2252
2253 # '.' is special because concats-of-concats are optimized to save copying
2254 # by making all but the first concat stacked. The effect is as if the
2255 # programmer had written '($a . $b) .= $c', except legal.
2256 sub pp_concat { maybe_targmy(@_, \&real_concat) }
2257 sub real_concat {
2258     my $self = shift;
2259     my($op, $cx) = @_;
2260     my $left = $op->first;
2261     my $right = $op->last;
2262     my $eq = "";
2263     my $prec = 18;
2264     if ($op->flags & OPf_STACKED and $op->first->name ne "concat") {
2265         $eq = "=";
2266         $prec = 7;
2267     }
2268     $left = $self->deparse_binop_left($op, $left, $prec);
2269     $right = $self->deparse_binop_right($op, $right, $prec);
2270     return $self->maybe_parens("$left .$eq $right", $cx, $prec);
2271 }
2272
2273 # 'x' is weird when the left arg is a list
2274 sub pp_repeat {
2275     my $self = shift;
2276     my($op, $cx) = @_;
2277     my $left = $op->first;
2278     my $right = $op->last;
2279     my $eq = "";
2280     my $prec = 19;
2281     if ($op->flags & OPf_STACKED) {
2282         $eq = "=";
2283         $prec = 7;
2284     }
2285     if (null($right)) { # list repeat; count is inside left-side ex-list
2286         my $kid = $left->first->sibling; # skip pushmark
2287         my @exprs;
2288         for (; !null($kid->sibling); $kid = $kid->sibling) {
2289             push @exprs, $self->deparse($kid, 6);
2290         }
2291         $right = $kid;
2292         $left = "(" . join(", ", @exprs). ")";
2293     } else {
2294         $left = $self->deparse_binop_left($op, $left, $prec);
2295     }
2296     $right = $self->deparse_binop_right($op, $right, $prec);
2297     return $self->maybe_parens("$left x$eq $right", $cx, $prec);
2298 }
2299
2300 sub range {
2301     my $self = shift;
2302     my ($op, $cx, $type) = @_;
2303     my $left = $op->first;
2304     my $right = $left->sibling;
2305     $left = $self->deparse($left, 9);
2306     $right = $self->deparse($right, 9);
2307     return $self->maybe_parens("$left $type $right", $cx, 9);
2308 }
2309
2310 sub pp_flop {
2311     my $self = shift;
2312     my($op, $cx) = @_;
2313     my $flip = $op->first;
2314     my $type = ($flip->flags & OPf_SPECIAL) ? "..." : "..";
2315     return $self->range($flip->first, $cx, $type);
2316 }
2317
2318 # one-line while/until is handled in pp_leave
2319
2320 sub logop {
2321     my $self = shift;
2322     my ($op, $cx, $lowop, $lowprec, $highop, $highprec, $blockname) = @_;
2323     my $left = $op->first;
2324     my $right = $op->first->sibling;
2325     if ($cx < 1 and is_scope($right) and $blockname
2326         and $self->{'expand'} < 7)
2327     { # if ($a) {$b}
2328         $left = $self->deparse($left, 1);
2329         $right = $self->deparse($right, 0);
2330         return "$blockname ($left) {\n\t$right\n\b}\cK";
2331     } elsif ($cx < 1 and $blockname and not $self->{'parens'}
2332              and $self->{'expand'} < 7) { # $b if $a
2333         $right = $self->deparse($right, 1);
2334         $left = $self->deparse($left, 1);
2335         return "$right $blockname $left";
2336     } elsif ($cx > $lowprec and $highop) { # $a && $b
2337         $left = $self->deparse_binop_left($op, $left, $highprec);
2338         $right = $self->deparse_binop_right($op, $right, $highprec);
2339         return $self->maybe_parens("$left $highop $right", $cx, $highprec);
2340     } else { # $a and $b
2341         $left = $self->deparse_binop_left($op, $left, $lowprec);
2342         $right = $self->deparse_binop_right($op, $right, $lowprec);
2343         return $self->maybe_parens("$left $lowop $right", $cx, $lowprec);
2344     }
2345 }
2346
2347 sub pp_and { logop(@_, "and", 3, "&&", 11, "if") }
2348 sub pp_or  { logop(@_, "or",  2, "||", 10, "unless") }
2349 sub pp_dor { logop(@_, "//", 10) }
2350
2351 # xor is syntactically a logop, but it's really a binop (contrary to
2352 # old versions of opcode.pl). Syntax is what matters here.
2353 sub pp_xor { logop(@_, "xor", 2, "",   0,  "") }
2354
2355 sub logassignop {
2356     my $self = shift;
2357     my ($op, $cx, $opname) = @_;
2358     my $left = $op->first;
2359     my $right = $op->first->sibling->first; # skip sassign
2360     $left = $self->deparse($left, 7);
2361     $right = $self->deparse($right, 7);
2362     return $self->maybe_parens("$left $opname $right", $cx, 7);
2363 }
2364
2365 sub pp_andassign { logassignop(@_, "&&=") }
2366 sub pp_orassign  { logassignop(@_, "||=") }
2367 sub pp_dorassign { logassignop(@_, "//=") }
2368
2369 sub listop {
2370     my $self = shift;
2371     my($op, $cx, $name, $kid, $nollafr) = @_;
2372     my(@exprs);
2373     my $parens = ($cx >= 5) || $self->{'parens'};
2374     $kid ||= $op->first->sibling;
2375     # If there are no arguments, add final parentheses (or parenthesize the
2376     # whole thing if the llafr does not apply) to account for cases like
2377     # (return)+1 or setpgrp()+1.  When the llafr does not apply, we use a
2378     # precedence of 6 (< comma), as "return, 1" does not need parentheses.
2379     if (null $kid) {
2380         return $nollafr
2381                 ? $self->maybe_parens($self->keyword($name), $cx, 7)
2382                 : $self->keyword($name) . '()' x (7 < $cx);
2383     }
2384     my $first;
2385     $name = "socketpair" if $name eq "sockpair";
2386     my $fullname = $self->keyword($name);
2387     my $proto = prototype("CORE::$name");
2388     if (defined $proto
2389         && $proto =~ /^;?\*/
2390         && $kid->name eq "rv2gv" && !($kid->private & OPpLVAL_INTRO)) {
2391         $first = $self->deparse($kid->first, 6);
2392     }
2393     else {
2394         $first = $self->deparse($kid, 6);
2395     }
2396     if ($name eq "chmod" && $first =~ /^\d+$/) {
2397         $first = sprintf("%#o", $first);
2398     }
2399     $first = "+$first"
2400         if not $parens and not $nollafr and substr($first, 0, 1) eq "(";
2401     push @exprs, $first;
2402     $kid = $kid->sibling;
2403     if (defined $proto && $proto =~ /^\*\*/ && $kid->name eq "rv2gv"
2404          && !($kid->private & OPpLVAL_INTRO)) {
2405         push @exprs, $self->deparse($kid->first, 6);
2406         $kid = $kid->sibling;
2407     }
2408     for (; !null($kid); $kid = $kid->sibling) {
2409         push @exprs, $self->deparse($kid, 6);
2410     }
2411     if ($name eq "reverse" && ($op->private & OPpREVERSE_INPLACE)) {
2412         return "$exprs[0] = $fullname"
2413                  . ($parens ? "($exprs[0])" : " $exprs[0]");
2414     }
2415     if ($parens && $nollafr) {
2416         return "($fullname " . join(", ", @exprs) . ")";
2417     } elsif ($parens) {
2418         return "$fullname(" . join(", ", @exprs) . ")";
2419     } else {
2420         return "$fullname " . join(", ", @exprs);
2421     }
2422 }
2423
2424 sub pp_bless { listop(@_, "bless") }
2425 sub pp_atan2 { maybe_targmy(@_, \&listop, "atan2") }
2426 sub pp_substr {
2427     my ($self,$op,$cx) = @_;
2428     if ($op->private & OPpSUBSTR_REPL_FIRST) {
2429         return
2430            listop($self, $op, 7, "substr", $op->first->sibling->sibling)
2431          . " = "
2432          . $self->deparse($op->first->sibling, 7);
2433     }
2434     maybe_local(@_, listop(@_, "substr"))
2435 }
2436 sub pp_vec { maybe_local(@_, listop(@_, "vec")) }
2437 sub pp_index { maybe_targmy(@_, \&listop, "index") }
2438 sub pp_rindex { maybe_targmy(@_, \&listop, "rindex") }
2439 sub pp_sprintf { maybe_targmy(@_, \&listop, "sprintf") }
2440 sub pp_formline { listop(@_, "formline") } # see also deparse_format
2441 sub pp_crypt { maybe_targmy(@_, \&listop, "crypt") }
2442 sub pp_unpack { listop(@_, "unpack") }
2443 sub pp_pack { listop(@_, "pack") }
2444 sub pp_join { maybe_targmy(@_, \&listop, "join") }
2445 sub pp_splice { listop(@_, "splice") }
2446 sub pp_push { maybe_targmy(@_, \&listop, "push") }
2447 sub pp_unshift { maybe_targmy(@_, \&listop, "unshift") }
2448 sub pp_reverse { listop(@_, "reverse") }
2449 sub pp_warn { listop(@_, "warn") }
2450 sub pp_die { listop(@_, "die") }
2451 sub pp_return { listop(@_, "return", undef, 1) } # llafr does not apply
2452 sub pp_open { listop(@_, "open") }
2453 sub pp_pipe_op { listop(@_, "pipe") }
2454 sub pp_tie { listop(@_, "tie") }
2455 sub pp_binmode { listop(@_, "binmode") }
2456 sub pp_dbmopen { listop(@_, "dbmopen") }
2457 sub pp_sselect { listop(@_, "select") }
2458 sub pp_select { listop(@_, "select") }
2459 sub pp_read { listop(@_, "read") }
2460 sub pp_sysopen { listop(@_, "sysopen") }
2461 sub pp_sysseek { listop(@_, "sysseek") }
2462 sub pp_sysread { listop(@_, "sysread") }
2463 sub pp_syswrite { listop(@_, "syswrite") }
2464 sub pp_send { listop(@_, "send") }
2465 sub pp_recv { listop(@_, "recv") }
2466 sub pp_seek { listop(@_, "seek") }
2467 sub pp_fcntl { listop(@_, "fcntl") }
2468 sub pp_ioctl { listop(@_, "ioctl") }
2469 sub pp_flock { maybe_targmy(@_, \&listop, "flock") }
2470 sub pp_socket { listop(@_, "socket") }
2471 sub pp_sockpair { listop(@_, "sockpair") }
2472 sub pp_bind { listop(@_, "bind") }
2473 sub pp_connect { listop(@_, "connect") }
2474 sub pp_listen { listop(@_, "listen") }
2475 sub pp_accept { listop(@_, "accept") }
2476 sub pp_shutdown { listop(@_, "shutdown") }
2477 sub pp_gsockopt { listop(@_, "getsockopt") }
2478 sub pp_ssockopt { listop(@_, "setsockopt") }
2479 sub pp_chown { maybe_targmy(@_, \&listop, "chown") }
2480 sub pp_unlink { maybe_targmy(@_, \&listop, "unlink") }
2481 sub pp_chmod { maybe_targmy(@_, \&listop, "chmod") }
2482 sub pp_utime { maybe_targmy(@_, \&listop, "utime") }
2483 sub pp_rename { maybe_targmy(@_, \&listop, "rename") }
2484 sub pp_link { maybe_targmy(@_, \&listop, "link") }
2485 sub pp_symlink { maybe_targmy(@_, \&listop, "symlink") }
2486 sub pp_mkdir { maybe_targmy(@_, \&listop, "mkdir") }
2487 sub pp_open_dir { listop(@_, "opendir") }
2488 sub pp_seekdir { listop(@_, "seekdir") }
2489 sub pp_waitpid { maybe_targmy(@_, \&listop, "waitpid") }
2490 sub pp_system { maybe_targmy(@_, \&listop, "system") }
2491 sub pp_exec { maybe_targmy(@_, \&listop, "exec") }
2492 sub pp_kill { maybe_targmy(@_, \&listop, "kill") }
2493 sub pp_setpgrp { maybe_targmy(@_, \&listop, "setpgrp") }
2494 sub pp_getpriority { maybe_targmy(@_, \&listop, "getpriority") }
2495 sub pp_setpriority { maybe_targmy(@_, \&listop, "setpriority") }
2496 sub pp_shmget { listop(@_, "shmget") }
2497 sub pp_shmctl { listop(@_, "shmctl") }
2498 sub pp_shmread { listop(@_, "shmread") }
2499 sub pp_shmwrite { listop(@_, "shmwrite") }
2500 sub pp_msgget { listop(@_, "msgget") }
2501 sub pp_msgctl { listop(@_, "msgctl") }
2502 sub pp_msgsnd { listop(@_, "msgsnd") }
2503 sub pp_msgrcv { listop(@_, "msgrcv") }
2504 sub pp_semget { listop(@_, "semget") }
2505 sub pp_semctl { listop(@_, "semctl") }
2506 sub pp_semop { listop(@_, "semop") }
2507 sub pp_ghbyaddr { listop(@_, "gethostbyaddr") }
2508 sub pp_gnbyaddr { listop(@_, "getnetbyaddr") }
2509 sub pp_gpbynumber { listop(@_, "getprotobynumber") }
2510 sub pp_gsbyname { listop(@_, "getservbyname") }
2511 sub pp_gsbyport { listop(@_, "getservbyport") }
2512 sub pp_syscall { listop(@_, "syscall") }
2513
2514 sub pp_glob {
2515     my $self = shift;
2516     my($op, $cx) = @_;
2517     my $text = $self->dq($op->first->sibling);  # skip pushmark
2518     my $keyword =
2519         $op->flags & OPf_SPECIAL ? 'glob' : $self->keyword('glob');
2520     if ($text =~ /^\$?(\w|::|\`)+$/ # could look like a readline
2521         or $keyword =~ /^CORE::/
2522         or $text =~ /[<>]/) {
2523         return "$keyword(" . single_delim('qq', '"', $text) . ')';
2524     } else {
2525         return '<' . $text . '>';
2526     }
2527 }
2528
2529 # Truncate is special because OPf_SPECIAL makes a bareword first arg
2530 # be a filehandle. This could probably be better fixed in the core
2531 # by moving the GV lookup into ck_truc.
2532
2533 sub pp_truncate {
2534     my $self = shift;
2535     my($op, $cx) = @_;
2536     my(@exprs);
2537     my $parens = ($cx >= 5) || $self->{'parens'};
2538     my $kid = $op->first->sibling;
2539     my $fh;
2540     if ($op->flags & OPf_SPECIAL) {
2541         # $kid is an OP_CONST
2542         $fh = $self->const_sv($kid)->PV;
2543     } else {
2544         $fh = $self->deparse($kid, 6);
2545         $fh = "+$fh" if not $parens and substr($fh, 0, 1) eq "(";
2546     }
2547     my $len = $self->deparse($kid->sibling, 6);
2548     my $name = $self->keyword('truncate');
2549     if ($parens) {
2550         return "$name($fh, $len)";
2551     } else {
2552         return "$name $fh, $len";
2553     }
2554 }
2555
2556 sub indirop {
2557     my $self = shift;
2558     my($op, $cx, $name) = @_;
2559     my($expr, @exprs);
2560     my $firstkid = my $kid = $op->first->sibling;
2561     my $indir = "";
2562     if ($op->flags & OPf_STACKED) {
2563         $indir = $kid;
2564         $indir = $indir->first; # skip rv2gv
2565         if (is_scope($indir)) {
2566             $indir = "{" . $self->deparse($indir, 0) . "}";
2567             $indir = "{;}" if $indir eq "{}";
2568         } elsif ($indir->name eq "const" && $indir->private & OPpCONST_BARE) {
2569             $indir = $self->const_sv($indir)->PV;
2570         } else {
2571             $indir = $self->deparse($indir, 24);
2572         }
2573         $indir = $indir . " ";
2574         $kid = $kid->sibling;
2575     }
2576     if ($name eq "sort" && $op->private & (OPpSORT_NUMERIC | OPpSORT_INTEGER)) {
2577         $indir = ($op->private & OPpSORT_DESCEND) ? '{$b <=> $a} '
2578                                                   : '{$a <=> $b} ';
2579     }
2580     elsif ($name eq "sort" && $op->private & OPpSORT_DESCEND) {
2581         $indir = '{$b cmp $a} ';
2582     }
2583     for (; !null($kid); $kid = $kid->sibling) {
2584         $expr = $self->deparse($kid, !$indir && $kid == $firstkid && $name eq "sort" && $firstkid->name eq "entersub" ? 16 : 6);
2585         push @exprs, $expr;
2586     }
2587     my $name2;
2588     if ($name eq "sort" && $op->private & OPpSORT_REVERSE) {
2589         $name2 = $self->keyword('reverse') . ' ' . $self->keyword('sort');
2590     }
2591     else { $name2 = $self->keyword($name) }
2592     if ($name eq "sort" && ($op->private & OPpSORT_INPLACE)) {
2593         return "$exprs[0] = $name2 $indir $exprs[0]";
2594     }
2595
2596     my $args = $indir . join(", ", @exprs);
2597     if ($indir ne "" && $name eq "sort") {
2598         # We don't want to say "sort(f 1, 2, 3)", since perl -w will
2599         # give bareword warnings in that case. Therefore if context
2600         # requires, we'll put parens around the outside "(sort f 1, 2,
2601         # 3)". Unfortunately, we'll currently think the parens are
2602         # necessary more often that they really are, because we don't
2603         # distinguish which side of an assignment we're on.
2604         if ($cx >= 5) {
2605             return "($name2 $args)";
2606         } else {
2607             return "$name2 $args";
2608         }
2609     } elsif (
2610         !$indir && $name eq "sort"
2611       && $op->first->sibling->name eq 'entersub'
2612     ) {
2613         # We cannot say sort foo(bar), as foo will be interpreted as a
2614         # comparison routine.  We have to say sort(...) in that case.
2615         return "$name2($args)";
2616     } else {
2617         return $self->maybe_parens_func($name2, $args, $cx, 5);
2618     }
2619
2620 }
2621
2622 sub pp_prtf { indirop(@_, "printf") }
2623 sub pp_print { indirop(@_, "print") }
2624 sub pp_say  { indirop(@_, "say") }
2625 sub pp_sort { indirop(@_, "sort") }
2626
2627 sub mapop {
2628     my $self = shift;
2629     my($op, $cx, $name) = @_;
2630     my($expr, @exprs);
2631     my $kid = $op->first; # this is the (map|grep)start
2632     $kid = $kid->first->sibling; # skip a pushmark
2633     my $code = $kid->first; # skip a null
2634     if (is_scope $code) {
2635         $code = "{" . $self->deparse($code, 0) . "} ";
2636     } else {
2637         $code = $self->deparse($code, 24) . ", ";
2638     }
2639     $kid = $kid->sibling;
2640     for (; !null($kid); $kid = $kid->sibling) {
2641         $expr = $self->deparse($kid, 6);
2642         push @exprs, $expr if defined $expr;
2643     }
2644     return $self->maybe_parens_func($name, $code . join(", ", @exprs), $cx, 5);
2645 }
2646
2647 sub pp_mapwhile { mapop(@_, "map") }
2648 sub pp_grepwhile { mapop(@_, "grep") }
2649 sub pp_mapstart { baseop(@_, "map") }
2650 sub pp_grepstart { baseop(@_, "grep") }
2651
2652 sub pp_list {
2653     my $self = shift;
2654     my($op, $cx) = @_;
2655     my($expr, @exprs);
2656     my $kid = $op->first->sibling; # skip pushmark
2657     return '' if class($kid) eq 'NULL';
2658     my $lop;
2659     my $local = "either"; # could be local(...), my(...), state(...) or our(...)
2660     for ($lop = $kid; !null($lop); $lop = $lop->sibling) {
2661         # This assumes that no other private flags equal 128, and that
2662         # OPs that store things other than flags in their op_private,
2663         # like OP_AELEMFAST, won't be immediate children of a list.
2664         #
2665         # OP_ENTERSUB can break this logic, so check for it.
2666         # I suspect that open and exit can too.
2667
2668         if (!($lop->private & (OPpLVAL_INTRO|OPpOUR_INTRO)
2669                 or $lop->name eq "undef")
2670             or $lop->name eq "entersub"
2671             or $lop->name eq "exit"
2672             or $lop->name eq "open")
2673         {
2674             $local = ""; # or not
2675             last;
2676         }
2677         if ($lop->name =~ /^pad[ash]v$/) {
2678             if ($lop->private & OPpPAD_STATE) { # state()
2679                 ($local = "", last) if $local =~ /^(?:local|our|my)$/;
2680                 $local = "state";
2681             } else { # my()
2682                 ($local = "", last) if $local =~ /^(?:local|our|state)$/;
2683                 $local = "my";
2684             }
2685         } elsif ($lop->name =~ /^(gv|rv2)[ash]v$/
2686                         && $lop->private & OPpOUR_INTRO
2687                 or $lop->name eq "null" && $lop->first->name eq "gvsv"
2688                         && $lop->first->private & OPpOUR_INTRO) { # our()
2689             ($local = "", last) if $local =~ /^(?:my|local|state)$/;
2690             $local = "our";
2691         } elsif ($lop->name ne "undef"
2692                 # specifically avoid the "reverse sort" optimisation,
2693                 # where "reverse" is nullified
2694                 && !($lop->name eq 'sort' && ($lop->flags & OPpSORT_REVERSE)))
2695         {
2696             # local()
2697             ($local = "", last) if $local =~ /^(?:my|our|state)$/;
2698             $local = "local";
2699         }
2700     }
2701     $local = "" if $local eq "either"; # no point if it's all undefs
2702     return $self->deparse($kid, $cx) if null $kid->sibling and not $local;
2703     for (; !null($kid); $kid = $kid->sibling) {
2704         if ($local) {
2705             if (class($kid) eq "UNOP" and $kid->first->name eq "gvsv") {
2706                 $lop = $kid->first;
2707             } else {
2708                 $lop = $kid;
2709             }
2710             $self->{'avoid_local'}{$$lop}++;
2711             $expr = $self->deparse($kid, 6);
2712             delete $self->{'avoid_local'}{$$lop};
2713         } else {
2714             $expr = $self->deparse($kid, 6);
2715         }
2716         push @exprs, $expr;
2717     }
2718     if ($local) {
2719         return "$local(" . join(", ", @exprs) . ")";
2720     } else {
2721         return $self->maybe_parens( join(", ", @exprs), $cx, 6);        
2722     }
2723 }
2724
2725 sub is_ifelse_cont {
2726     my $op = shift;
2727     return ($op->name eq "null" and class($op) eq "UNOP"
2728             and $op->first->name =~ /^(and|cond_expr)$/
2729             and is_scope($op->first->first->sibling));
2730 }
2731
2732 sub pp_cond_expr {
2733     my $self = shift;
2734     my($op, $cx) = @_;
2735     my $cond = $op->first;
2736     my $true = $cond->sibling;
2737     my $false = $true->sibling;
2738     my $cuddle = $self->{'cuddle'};
2739     unless ($cx < 1 and (is_scope($true) and $true->name ne "null") and
2740             (is_scope($false) || is_ifelse_cont($false))
2741             and $self->{'expand'} < 7) {
2742         $cond = $self->deparse($cond, 8);
2743         $true = $self->deparse($true, 6);
2744         $false = $self->deparse($false, 8);
2745         return $self->maybe_parens("$cond ? $true : $false", $cx, 8);
2746     }
2747
2748     $cond = $self->deparse($cond, 1);
2749     $true = $self->deparse($true, 0);
2750     my $head = "if ($cond) {\n\t$true\n\b}";
2751     my @elsifs;
2752     while (!null($false) and is_ifelse_cont($false)) {
2753         my $newop = $false->first;
2754         my $newcond = $newop->first;
2755         my $newtrue = $newcond->sibling;
2756         $false = $newtrue->sibling; # last in chain is OP_AND => no else
2757         if ($newcond->name eq "lineseq")
2758         {
2759             # lineseq to ensure correct line numbers in elsif()
2760             # Bug #37302 fixed by change #33710.
2761             $newcond = $newcond->first->sibling;
2762         }
2763         $newcond = $self->deparse($newcond, 1);
2764         $newtrue = $self->deparse($newtrue, 0);
2765         push @elsifs, "elsif ($newcond) {\n\t$newtrue\n\b}";
2766     }
2767     if (!null($false)) {
2768         $false = $cuddle . "else {\n\t" .
2769           $self->deparse($false, 0) . "\n\b}\cK";
2770     } else {
2771         $false = "\cK";
2772     }
2773     return $head . join($cuddle, "", @elsifs) . $false;
2774 }
2775
2776 sub pp_once {
2777     my ($self, $op, $cx) = @_;
2778     my $cond = $op->first;
2779     my $true = $cond->sibling;
2780
2781     return $self->deparse($true, $cx);
2782 }
2783
2784 sub loop_common {
2785     my $self = shift;
2786     my($op, $cx, $init) = @_;
2787     my $enter = $op->first;
2788     my $kid = $enter->sibling;
2789     local(@$self{qw'curstash warnings hints hinthash'})
2790                 = @$self{qw'curstash warnings hints hinthash'};
2791     my $head = "";
2792     my $bare = 0;
2793     my $body;
2794     my $cond = undef;
2795     if ($kid->name eq "lineseq") { # bare or infinite loop
2796         if ($kid->last->name eq "unstack") { # infinite
2797             $head = "while (1) "; # Can't use for(;;) if there's a continue
2798             $cond = "";
2799         } else {
2800             $bare = 1;
2801         }
2802         $body = $kid;
2803     } elsif ($enter->name eq "enteriter") { # foreach
2804         my $ary = $enter->first->sibling; # first was pushmark
2805         my $var = $ary->sibling;
2806         if ($ary->name eq 'null' and $enter->private & OPpITER_REVERSED) {
2807             # "reverse" was optimised away
2808             $ary = listop($self, $ary->first->sibling, 1, 'reverse');
2809         } elsif ($enter->flags & OPf_STACKED
2810             and not null $ary->first->sibling->sibling)
2811         {
2812             $ary = $self->deparse($ary->first->sibling, 9) . " .. " .
2813               $self->deparse($ary->first->sibling->sibling, 9);
2814         } else {
2815             $ary = $self->deparse($ary, 1);
2816         }
2817         if (null $var) {
2818             if (($enter->flags & OPf_SPECIAL) && ($] < 5.009)) {
2819                 # thread special var, under 5005threads
2820                 $var = $self->pp_threadsv($enter, 1);
2821             } else { # regular my() variable
2822                 $var = $self->pp_padsv($enter, 1);
2823             }
2824         } elsif ($var->name eq "rv2gv") {
2825             $var = $self->pp_rv2sv($var, 1);
2826             if ($enter->private & OPpOUR_INTRO) {
2827                 # our declarations don't have package names
2828                 $var =~ s/^(.).*::/$1/;
2829                 $var = "our $var";
2830             }
2831         } elsif ($var->name eq "gv") {
2832             $var = "\$" . $self->deparse($var, 1);
2833         }
2834         $body = $kid->first->first->sibling; # skip OP_AND and OP_ITER
2835         if (!is_state $body->first and $body->first->name ne "stub") {
2836             confess unless $var eq '$_';
2837             $body = $body->first;
2838             return $self->deparse($body, 2) . " foreach ($ary)";
2839         }
2840         $head = "foreach $var ($ary) ";
2841     } elsif ($kid->name eq "null") { # while/until
2842         $kid = $kid->first;
2843         my $name = {"and" => "while", "or" => "until"}->{$kid->name};
2844         $cond = $self->deparse($kid->first, 1);
2845         $head = "$name ($cond) ";
2846         $body = $kid->first->sibling;
2847     } elsif ($kid->name eq "stub") { # bare and empty
2848         return "{;}"; # {} could be a hashref
2849     }
2850     # If there isn't a continue block, then the next pointer for the loop
2851     # will point to the unstack, which is kid's last child, except
2852     # in a bare loop, when it will point to the leaveloop. When neither of
2853     # these conditions hold, then the second-to-last child is the continue
2854     # block (or the last in a bare loop).
2855     my $cont_start = $enter->nextop;
2856     my $cont;
2857     if ($$cont_start != $$op && ${$cont_start} != ${$body->last}) {
2858         if ($bare) {
2859             $cont = $body->last;
2860         } else {
2861             $cont = $body->first;
2862             while (!null($cont->sibling->sibling)) {
2863                 $cont = $cont->sibling;
2864             }
2865         }
2866         my $state = $body->first;
2867         my $cuddle = $self->{'cuddle'};
2868         my @states;
2869         for (; $$state != $$cont; $state = $state->sibling) {
2870             push @states, $state;
2871         }
2872         $body = $self->lineseq(undef, @states);
2873         if (defined $cond and not is_scope $cont and $self->{'expand'} < 3) {
2874             $head = "for ($init; $cond; " . $self->deparse($cont, 1) .") ";
2875             $cont = "\cK";
2876         } else {
2877             $cont = $cuddle . "continue {\n\t" .
2878               $self->deparse($cont, 0) . "\n\b}\cK";
2879         }
2880     } else {
2881         return "" if !defined $body;
2882         if (length $init) {
2883             $head = "for ($init; $cond;) ";
2884         }
2885         $cont = "\cK";
2886         $body = $self->deparse($body, 0);
2887     }
2888     $body =~ s/;?$/;\n/;
2889
2890     return $head . "{\n\t" . $body . "\b}" . $cont;
2891 }
2892
2893 sub pp_leaveloop { shift->loop_common(@_, "") }
2894
2895 sub for_loop {
2896     my $self = shift;
2897     my($op, $cx) = @_;
2898     my $init = $self->deparse($op, 1);
2899     my $s = $op->sibling;
2900     my $ll = $s->name eq "unstack" ? $s->sibling : $s->first->sibling;
2901     return $self->loop_common($ll, $cx, $init);
2902 }
2903
2904 sub pp_leavetry {
2905     my $self = shift;
2906     return "eval {\n\t" . $self->pp_leave(@_) . "\n\b}";
2907 }
2908
2909 BEGIN { for (qw[ const stringify rv2sv list glob ]) {
2910     eval "sub OP_\U$_ () { " . opnumber($_) . "}"
2911 }}
2912
2913 sub pp_null {
2914     my $self = shift;
2915     my($op, $cx) = @_;
2916     if (class($op) eq "OP") {
2917         # old value is lost
2918         return $self->{'ex_const'} if $op->targ == OP_CONST;
2919     } elsif ($op->first->name eq "pushmark") {
2920         return $self->pp_list($op, $cx);
2921     } elsif ($op->first->name eq "enter") {
2922         return $self->pp_leave($op, $cx);
2923     } elsif ($op->first->name eq "leave") {
2924         return $self->pp_leave($op->first, $cx);
2925     } elsif ($op->first->name eq "scope") {
2926         return $self->pp_scope($op->first, $cx);
2927     } elsif ($op->targ == OP_STRINGIFY) {
2928         return $self->dquote($op, $cx);
2929     } elsif ($op->targ == OP_GLOB) {
2930         return $self->pp_glob(
2931                  $op->first    # entersub
2932                     ->first    # ex-list
2933                     ->first    # pushmark
2934                     ->sibling, # glob
2935                  $cx
2936                );
2937     } elsif (!null($op->first->sibling) and
2938              $op->first->sibling->name eq "readline" and
2939              $op->first->sibling->flags & OPf_STACKED) {
2940         return $self->maybe_parens($self->deparse($op->first, 7) . " = "
2941                                    . $self->deparse($op->first->sibling, 7),
2942                                    $cx, 7);
2943     } elsif (!null($op->first->sibling) and
2944              $op->first->sibling->name eq "trans" and
2945              $op->first->sibling->flags & OPf_STACKED) {
2946         return $self->maybe_parens($self->deparse($op->first, 20) . " =~ "
2947                                    . $self->deparse($op->first->sibling, 20),
2948                                    $cx, 20);
2949     } elsif ($op->flags & OPf_SPECIAL && $cx < 1 && !$op->targ) {
2950         return "do {\n\t". $self->deparse($op->first, $cx) ."\n\b};";
2951     } elsif (!null($op->first->sibling) and
2952              $op->first->sibling->name eq "null" and
2953              class($op->first->sibling) eq "UNOP" and
2954              $op->first->sibling->first->flags & OPf_STACKED and
2955              $op->first->sibling->first->name eq "rcatline") {
2956         return $self->maybe_parens($self->deparse($op->first, 18) . " .= "
2957                                    . $self->deparse($op->first->sibling, 18),
2958                                    $cx, 18);
2959     } else {
2960         return $self->deparse($op->first, $cx);
2961     }
2962 }
2963
2964 sub padname {
2965     my $self = shift;
2966     my $targ = shift;
2967     return $self->padname_sv($targ)->PVX;
2968 }
2969
2970 sub padany {
2971     my $self = shift;
2972     my $op = shift;
2973     return substr($self->padname($op->targ), 1); # skip $/@/%
2974 }
2975
2976 sub pp_padsv {
2977     my $self = shift;
2978     my($op, $cx) = @_;
2979     return $self->maybe_my($op, $cx, $self->padname($op->targ));
2980 }
2981
2982 sub pp_padav { pp_padsv(@_) }
2983 sub pp_padhv { pp_padsv(@_) }
2984
2985 my @threadsv_names = B::threadsv_names;
2986 sub pp_threadsv {
2987     my $self = shift;
2988     my($op, $cx) = @_;
2989     return $self->maybe_local($op, $cx, "\$" .  $threadsv_names[$op->targ]);
2990 }
2991
2992 sub gv_or_padgv {
2993     my $self = shift;
2994     my $op = shift;
2995     if (class($op) eq "PADOP") {
2996         return $self->padval($op->padix);
2997     } else { # class($op) eq "SVOP"
2998         return $op->gv;
2999     }
3000 }
3001
3002 sub pp_gvsv {
3003     my $self = shift;
3004     my($op, $cx) = @_;
3005     my $gv = $self->gv_or_padgv($op);
3006     return $self->maybe_local($op, $cx, $self->stash_variable("\$",
3007                                  $self->gv_name($gv), $cx));
3008 }
3009
3010 sub pp_gv {
3011     my $self = shift;
3012     my($op, $cx) = @_;
3013     my $gv = $self->gv_or_padgv($op);
3014     return $self->gv_name($gv);
3015 }
3016
3017 sub pp_aelemfast_lex {
3018     my $self = shift;
3019     my($op, $cx) = @_;
3020     my $name = $self->padname($op->targ);
3021     $name =~ s/^@/\$/;
3022     return $name . "[" .  ($op->private + $self->{'arybase'}) . "]";
3023 }
3024
3025 sub pp_aelemfast {
3026     my $self = shift;
3027     my($op, $cx) = @_;
3028     # optimised PADAV, pre 5.15
3029     return $self->pp_aelemfast_lex(@_) if ($op->flags & OPf_SPECIAL);
3030
3031     my $gv = $self->gv_or_padgv($op);
3032     my $name = $self->gv_name($gv);
3033     $name = $self->{'curstash'}."::$name"
3034         if $name !~ /::/ && $self->lex_in_scope('@'.$name);
3035     $name = '$' . $name;
3036     return $name . "[" .  ($op->private + $self->{'arybase'}) . "]";
3037 }
3038
3039 sub rv2x {
3040     my $self = shift;
3041     my($op, $cx, $type) = @_;
3042
3043     if (class($op) eq 'NULL' || !$op->can("first")) {
3044         carp("Unexpected op in pp_rv2x");
3045         return 'XXX';
3046     }
3047     my $kid = $op->first;
3048     if ($kid->name eq "gv") {
3049         return $self->stash_variable($type, $self->deparse($kid, 0), $cx);
3050     } elsif (is_scalar $kid) {
3051         my $str = $self->deparse($kid, 0);
3052         if ($str =~ /^\$([^\w\d])\z/) {
3053             # "$$+" isn't a legal way to write the scalar dereference
3054             # of $+, since the lexer can't tell you aren't trying to
3055             # do something like "$$ + 1" to get one more than your
3056             # PID. Either "${$+}" or "$${+}" are workable
3057             # disambiguations, but if the programmer did the former,
3058             # they'd be in the "else" clause below rather than here.
3059             # It's not clear if this should somehow be unified with
3060             # the code in dq and re_dq that also adds lexer
3061             # disambiguation braces.
3062             $str = '$' . "{$1}"; #'
3063         }
3064         return $type . $str;
3065     } else {
3066         return $type . "{" . $self->deparse($kid, 0) . "}";
3067     }
3068 }
3069
3070 sub pp_rv2sv { maybe_local(@_, rv2x(@_, "\$")) }
3071 sub pp_rv2hv { maybe_local(@_, rv2x(@_, "%")) }
3072 sub pp_rv2gv { maybe_local(@_, rv2x(@_, "*")) }
3073
3074 # skip rv2av
3075 sub pp_av2arylen {
3076     my $self = shift;
3077     my($op, $cx) = @_;
3078     if ($op->first->name eq "padav") {
3079         return $self->maybe_local($op, $cx, '$#' . $self->padany($op->first));
3080     } else {
3081         return $self->maybe_local($op, $cx,
3082                                   $self->rv2x($op->first, $cx, '$#'));
3083     }
3084 }
3085
3086 # skip down to the old, ex-rv2cv
3087 sub pp_rv2cv {
3088     my ($self, $op, $cx) = @_;
3089     if (!null($op->first) && $op->first->name eq 'null' &&
3090         $op->first->targ eq OP_LIST)
3091     {
3092         return $self->rv2x($op->first->first->sibling, $cx, "&")
3093     }
3094     else {
3095         return $self->rv2x($op, $cx, "")
3096     }
3097 }
3098
3099 sub list_const {
3100     my $self = shift;
3101     my($cx, @list) = @_;
3102     my @a = map $self->const($_, 6), @list;
3103     if (@a == 0) {
3104         return "()";
3105     } elsif (@a == 1) {
3106         return $a[0];
3107     } elsif ( @a > 2 and !grep(!/^-?\d+$/, @a)) {
3108         # collapse (-1,0,1,2) into (-1..2)
3109         my ($s, $e) = @a[0,-1];
3110         my $i = $s;
3111         return $self->maybe_parens("$s..$e", $cx, 9)
3112           unless grep $i++ != $_, @a;
3113     }
3114     return $self->maybe_parens(join(", ", @a), $cx, 6);
3115 }
3116
3117 sub pp_rv2av {
3118     my $self = shift;
3119     my($op, $cx) = @_;
3120     my $kid = $op->first;
3121     if ($kid->name eq "const") { # constant list
3122         my $av = $self->const_sv($kid);
3123         return $self->list_const($cx, $av->ARRAY);
3124     } else {
3125         return $self->maybe_local($op, $cx, $self->rv2x($op, $cx, "\@"));
3126     }
3127  }
3128
3129 sub is_subscriptable {
3130     my $op = shift;
3131     if ($op->name =~ /^[ahg]elem/) {
3132         return 1;
3133     } elsif ($op->name eq "entersub") {
3134         my $kid = $op->first;
3135         return 0 unless null $kid->sibling;
3136         $kid = $kid->first;
3137         $kid = $kid->sibling until null $kid->sibling;
3138         return 0 if is_scope($kid);
3139         $kid = $kid->first;
3140         return 0 if $kid->name eq "gv";
3141         return 0 if is_scalar($kid);
3142         return is_subscriptable($kid);  
3143     } else {
3144         return 0;
3145     }
3146 }
3147
3148 sub elem_or_slice_array_name
3149 {
3150     my $self = shift;
3151     my ($array, $left, $padname, $allow_arrow) = @_;
3152
3153     if ($array->name eq $padname) {
3154         return $self->padany($array);
3155     } elsif (is_scope($array)) { # ${expr}[0]
3156         return "{" . $self->deparse($array, 0) . "}";
3157     } elsif ($array->name eq "gv") {
3158         $array = $self->gv_name($self->gv_or_padgv($array));
3159         if ($array !~ /::/) {
3160             my $prefix = ($left eq '[' ? '@' : '%');
3161             $array = $self->{curstash}.'::'.$array
3162                 if $self->lex_in_scope($prefix . $array);
3163         }
3164         return $array;
3165     } elsif (!$allow_arrow || is_scalar $array) { # $x[0], $$x[0], ...
3166         return $self->deparse($array, 24);
3167     } else {
3168         return undef;
3169     }
3170 }
3171
3172 sub elem_or_slice_single_index
3173 {
3174     my $self = shift;
3175     my ($idx) = @_;
3176
3177     $idx = $self->deparse($idx, 1);
3178
3179     # Outer parens in an array index will confuse perl
3180     # if we're interpolating in a regular expression, i.e.
3181     # /$x$foo[(-1)]/ is *not* the same as /$x$foo[-1]/
3182     #
3183     # If $self->{parens}, then an initial '(' will
3184     # definitely be paired with a final ')'. If
3185     # !$self->{parens}, the misleading parens won't
3186     # have been added in the first place.
3187     #
3188     # [You might think that we could get "(...)...(...)"
3189     # where the initial and final parens do not match
3190     # each other. But we can't, because the above would
3191     # only happen if there's an infix binop between the
3192     # two pairs of parens, and *that* means that the whole
3193     # expression would be parenthesized as well.]
3194     #
3195     $idx =~ s/^\((.*)\)$/$1/ if $self->{'parens'};
3196
3197     # Hash-element braces will autoquote a bareword inside themselves.
3198     # We need to make sure that C<$hash{warn()}> doesn't come out as
3199     # C<$hash{warn}>, which has a quite different meaning. Currently
3200     # B::Deparse will always quote strings, even if the string was a
3201     # bareword in the original (i.e. the OPpCONST_BARE flag is ignored
3202     # for constant strings.) So we can cheat slightly here - if we see
3203     # a bareword, we know that it is supposed to be a function call.
3204     #
3205     $idx =~ s/^([A-Za-z_]\w*)$/$1()/;
3206
3207     return $idx;
3208 }
3209
3210 sub elem {
3211     my $self = shift;
3212     my ($op, $cx, $left, $right, $padname) = @_;
3213     my($array, $idx) = ($op->first, $op->first->sibling);
3214
3215     $idx = $self->elem_or_slice_single_index($idx);
3216
3217     unless ($array->name eq $padname) { # Maybe this has been fixed     
3218         $array = $array->first; # skip rv2av (or ex-rv2av in _53+)
3219     }
3220     if (my $array_name=$self->elem_or_slice_array_name
3221             ($array, $left, $padname, 1)) {
3222         return "\$" . $array_name . $left . $idx . $right;
3223     } else {
3224         # $x[20][3]{hi} or expr->[20]
3225         my $arrow = is_subscriptable($array) ? "" : "->";
3226         return $self->deparse($array, 24) . $arrow . $left . $idx . $right;
3227     }
3228
3229 }
3230
3231 sub pp_aelem { maybe_local(@_, elem(@_, "[", "]", "padav")) }
3232 sub pp_helem { maybe_local(@_, elem(@_, "{", "}", "padhv")) }
3233
3234 sub pp_gelem {
3235     my $self = shift;
3236     my($op, $cx) = @_;
3237     my($glob, $part) = ($op->first, $op->last);
3238     $glob = $glob->first; # skip rv2gv
3239     $glob = $glob->first if $glob->name eq "rv2gv"; # this one's a bug
3240     my $scope = is_scope($glob);
3241     $glob = $self->deparse($glob, 0);
3242     $part = $self->deparse($part, 1);
3243     return "*" . ($scope ? "{$glob}" : $glob) . "{$part}";
3244 }
3245
3246 sub slice {
3247     my $self = shift;
3248     my ($op, $cx, $left, $right, $regname, $padname) = @_;
3249     my $last;
3250     my(@elems, $kid, $array, $list);
3251     if (class($op) eq "LISTOP") {
3252         $last = $op->last;
3253     } else { # ex-hslice inside delete()
3254         for ($kid = $op->first; !null $kid->sibling; $kid = $kid->sibling) {}
3255         $last = $kid;
3256     }
3257     $array = $last;
3258     $array = $array->first
3259         if $array->name eq $regname or $array->name eq "null";
3260     $array = $self->elem_or_slice_array_name($array,$left,$padname,0);
3261     $kid = $op->first->sibling; # skip pushmark
3262     if ($kid->name eq "list") {
3263         $kid = $kid->first->sibling; # skip list, pushmark
3264         for (; !null $kid; $kid = $kid->sibling) {
3265             push @elems, $self->deparse($kid, 6);
3266         }
3267         $list = join(", ", @elems);
3268     } else {
3269         $list = $self->elem_or_slice_single_index($kid);
3270     }
3271     return "\@" . $array . $left . $list . $right;
3272 }
3273
3274 sub pp_aslice { maybe_local(@_, slice(@_, "[", "]", "rv2av", "padav")) }
3275 sub pp_hslice { maybe_local(@_, slice(@_, "{", "}", "rv2hv", "padhv")) }
3276
3277 sub pp_lslice {
3278     my $self = shift;
3279     my($op, $cx) = @_;
3280     my $idx = $op->first;
3281     my $list = $op->last;
3282     my(@elems, $kid);
3283     $list = $self->deparse($list, 1);
3284     $idx = $self->deparse($idx, 1);
3285     return "($list)" . "[$idx]";
3286 }
3287
3288 sub want_scalar {
3289     my $op = shift;
3290     return ($op->flags & OPf_WANT) == OPf_WANT_SCALAR;
3291 }
3292
3293 sub want_list {
3294     my $op = shift;
3295     return ($op->flags & OPf_WANT) == OPf_WANT_LIST;
3296 }
3297
3298 sub _method {
3299     my $self = shift;
3300     my($op, $cx) = @_;
3301     my $kid = $op->first->sibling; # skip pushmark
3302     my($meth, $obj, @exprs);
3303     if ($kid->name eq "list" and want_list $kid) {
3304         # When an indirect object isn't a bareword but the args are in
3305         # parens, the parens aren't part of the method syntax (the LLAFR
3306         # doesn't apply), but they make a list with OPf_PARENS set that
3307         # doesn't get flattened by the append_elem that adds the method,
3308         # making a (object, arg1, arg2, ...) list where the object
3309         # usually is. This can be distinguished from
3310         # '($obj, $arg1, $arg2)->meth()' (which is legal if $arg2 is an
3311         # object) because in the later the list is in scalar context
3312         # as the left side of -> always is, while in the former
3313         # the list is in list context as method arguments always are.
3314         # (Good thing there aren't method prototypes!)
3315         $meth = $kid->sibling;
3316         $kid = $kid->first->sibling; # skip pushmark
3317         $obj = $kid;
3318         $kid = $kid->sibling;
3319         for (; not null $kid; $kid = $kid->sibling) {
3320             push @exprs, $kid;
3321         }
3322     } else {
3323         $obj = $kid;
3324         $kid = $kid->sibling;
3325         for (; !null ($kid->sibling) && $kid->name!~/^method(?:_named)?\z/;
3326               $kid = $kid->sibling) {
3327             push @exprs, $kid
3328         }
3329         $meth = $kid;
3330     }
3331
3332     if ($meth->name eq "method_named") {
3333         $meth = $self->const_sv($meth)->PV;
3334     } else {
3335         $meth = $meth->first;
3336         if ($meth->name eq "const") {
3337             # As of 5.005_58, this case is probably obsoleted by the
3338             # method_named case above
3339             $meth = $self->const_sv($meth)->PV; # needs to be bare
3340         }
3341     }
3342
3343     return { method => $meth, variable_method => ref($meth),
3344              object => $obj, args => \@exprs  },
3345            $cx;
3346 }
3347
3348 # compat function only
3349 sub method {
3350     my $self = shift;
3351     my $info = $self->_method(@_);
3352     return $self->e_method( $self->_method(@_) );
3353 }
3354
3355 sub e_method {
3356     my ($self, $info, $cx) = @_;
3357     my $obj = $self->deparse($info->{object}, 24);
3358
3359     my $meth = $info->{method};
3360     $meth = $self->deparse($meth, 1) if $info->{variable_method};
3361     my $args = join(", ", map { $self->deparse($_, 6) } @{$info->{args}} );
3362     if ($info->{object}->name eq 'scope' && want_list $info->{object}) {
3363         # method { $object }
3364         # This must be deparsed this way to preserve list context
3365         # of $object.
3366         my $need_paren = $cx >= 6;
3367         return '(' x $need_paren
3368              . $meth . substr($obj,2) # chop off the "do"
3369              . " $args"
3370              . ')' x $need_paren;
3371     }
3372     my $kid = $obj . "->" . $meth;
3373     if (length $args) {
3374         return $kid . "(" . $args . ")"; # parens mandatory
3375     } else {
3376         return $kid;
3377     }
3378 }
3379
3380 # returns "&" if the prototype doesn't match the args,
3381 # or ("", $args_after_prototype_demunging) if it does.
3382 sub check_proto {
3383     my $self = shift;
3384     return "&" if $self->{'noproto'};
3385     my($proto, @args) = @_;
3386     my($arg, $real);
3387     my $doneok = 0;
3388     my @reals;
3389     # An unbackslashed @ or % gobbles up the rest of the args
3390     1 while $proto =~ s/(?<!\\)([@%])[^\]]+$/$1/;
3391     while ($proto) {
3392         $proto =~ s/^(\\?[\$\@&%*_]|\\\[[\$\@&%*]+\]|;)//;
3393         my $chr = $1;
3394         if ($chr eq "") {
3395             return "&" if @args;
3396         } elsif ($chr eq ";") {
3397             $doneok = 1;
3398         } elsif ($chr eq "@" or $chr eq "%") {
3399             push @reals, map($self->deparse($_, 6), @args);
3400             @args = ();
3401         } else {
3402             $arg = shift @args;
3403             last unless $arg;
3404             if ($chr eq "\$" || $chr eq "_") {
3405                 if (want_scalar $arg) {
3406                     push @reals, $self->deparse($arg, 6);
3407                 } else {
3408                     return "&";
3409                 }
3410             } elsif ($chr eq "&") {
3411                 if ($arg->name =~ /^(s?refgen|undef)$/) {
3412                     push @reals, $self->deparse($arg, 6);
3413                 } else {
3414                     return "&";
3415                 }
3416             } elsif ($chr eq "*") {
3417                 if ($arg->name =~ /^s?refgen$/
3418                     and $arg->first->first->name eq "rv2gv")
3419                   {
3420                       $real = $arg->first->first; # skip refgen, null
3421                       if ($real->first->name eq "gv") {
3422                           push @reals, $self->deparse($real, 6);
3423                       } else {
3424                           push @reals, $self->deparse($real->first, 6);
3425                       }
3426                   } else {
3427                       return "&";
3428                   }
3429             } elsif (substr($chr, 0, 1) eq "\\") {
3430                 $chr =~ tr/\\[]//d;
3431                 if ($arg->name =~ /^s?refgen$/ and
3432                     !null($real = $arg->first) and
3433                     ($chr =~ /\$/ && is_scalar($real->first)
3434                      or ($chr =~ /@/
3435                          && class($real->first->sibling) ne 'NULL'
3436                          && $real->first->sibling->name
3437                          =~ /^(rv2|pad)av$/)
3438                      or ($chr =~ /%/
3439                          && class($real->first->sibling) ne 'NULL'
3440                          && $real->first->sibling->name
3441                          =~ /^(rv2|pad)hv$/)
3442                      #or ($chr =~ /&/ # This doesn't work
3443                      #   && $real->first->name eq "rv2cv")
3444                      or ($chr =~ /\*/
3445                          && $real->first->name eq "rv2gv")))
3446                   {
3447                       push @reals, $self->deparse($real, 6);
3448                   } else {
3449                       return "&";
3450                   }
3451             }
3452        }
3453     }
3454     return "&" if $proto and !$doneok; # too few args and no ';'
3455     return "&" if @args;               # too many args
3456     return ("", join ", ", @reals);
3457 }
3458
3459 sub pp_entersub {
3460     my $self = shift;
3461     my($op, $cx) = @_;
3462     return $self->e_method($self->_method($op, $cx))
3463         unless null $op->first->sibling;
3464     my $prefix = "";
3465     my $amper = "";
3466     my($kid, @exprs);
3467     if ($op->flags & OPf_SPECIAL && !($op->flags & OPf_MOD)) {
3468         $prefix = "do ";
3469     } elsif ($op->private & OPpENTERSUB_AMPER) {
3470         $amper = "&";
3471     }
3472     $kid = $op->first;
3473     $kid = $kid->first->sibling; # skip ex-list, pushmark
3474     for (; not null $kid->sibling; $kid = $kid->sibling) {
3475         push @exprs, $kid;
3476     }
3477     my $simple = 0;
3478     my $proto = undef;
3479     if (is_scope($kid)) {
3480         $amper = "&";
3481         $kid = "{" . $self->deparse($kid, 0) . "}";
3482     } elsif ($kid->first->name eq "gv") {
3483         my $gv = $self->gv_or_padgv($kid->first);
3484         if (class($gv->CV) ne "SPECIAL") {
3485             $proto = $gv->CV->PV if $gv->CV->FLAGS & SVf_POK;
3486         }
3487         $simple = 1; # only calls of named functions can be prototyped
3488         $kid = $self->deparse($kid, 24);
3489         if (!$amper) {
3490             if ($kid eq 'main::') {
3491                 $kid = '::';
3492             } elsif ($kid !~ /^(?:\w|::)(?:[\w\d]|::(?!\z))*\z/) {
3493                 $kid = single_delim("q", "'", $kid) . '->';
3494             }
3495         }
3496     } elsif (is_scalar ($kid->first) && $kid->first->name ne 'rv2cv') {
3497         $amper = "&";
3498         $kid = $self->deparse($kid, 24);
3499     } else {
3500         $prefix = "";
3501         my $arrow = is_subscriptable($kid->first) ? "" : "->";
3502         $kid = $self->deparse($kid, 24) . $arrow;
3503     }
3504
3505     # Doesn't matter how many prototypes there are, if
3506     # they haven't happened yet!
3507     my $declared;
3508     {
3509         no strict 'refs';
3510         no warnings 'uninitialized';
3511         $declared = exists $self->{'subs_declared'}{$kid}
3512             || (
3513                  defined &{ ${$self->{'curstash'}."::"}{$kid} }
3514                  && !exists
3515                      $self->{'subs_deparsed'}{$self->{'curstash'}."::".$kid}
3516                  && defined prototype $self->{'curstash'}."::".$kid
3517                );
3518         if (!$declared && defined($proto)) {
3519             # Avoid "too early to check prototype" warning
3520             ($amper, $proto) = ('&');
3521         }
3522     }
3523
3524     my $args;
3525     if ($declared and defined $proto and not $amper) {
3526         ($amper, $args) = $self->check_proto($proto, @exprs);
3527         if ($amper eq "&") {
3528             $args = join(", ", map($self->deparse($_, 6), @exprs));
3529         }
3530     } else {
3531         $args = join(", ", map($self->deparse($_, 6), @exprs));
3532     }
3533     if ($prefix or $amper) {
3534         if ($kid eq '&') { $kid = "{$kid}" } # &{&} cannot be written as &&
3535         if ($op->flags & OPf_STACKED) {
3536             return $prefix . $amper . $kid . "(" . $args . ")";
3537         } else {
3538             return $prefix . $amper. $kid;
3539         }
3540     } else {
3541         # It's a syntax error to call CORE::GLOBAL::foo with a prefix,
3542         # so it must have been translated from a keyword call. Translate
3543         # it back.
3544         $kid =~ s/^CORE::GLOBAL:://;
3545
3546         my $dproto = defined($proto) ? $proto : "undefined";
3547         if (!$declared) {
3548             return "$kid(" . $args . ")";
3549         } elsif ($dproto eq "") {
3550             return $kid;
3551         } elsif ($dproto eq "\$" and is_scalar($exprs[0])) {
3552             # is_scalar is an excessively conservative test here:
3553             # really, we should be comparing to the precedence of the
3554             # top operator of $exprs[0] (ala unop()), but that would
3555             # take some major code restructuring to do right.
3556             return $self->maybe_parens_func($kid, $args, $cx, 16);
3557         } elsif ($dproto ne '$' and defined($proto) || $simple) { #'
3558             return $self->maybe_parens_func($kid, $args, $cx, 5);
3559         } else {
3560             return "$kid(" . $args . ")";
3561         }
3562     }
3563 }
3564
3565 sub pp_enterwrite { unop(@_, "write") }
3566
3567 # escape things that cause interpolation in double quotes,
3568 # but not character escapes
3569 sub uninterp {
3570     my($str) = @_;
3571     $str =~ s/(^|\G|[^\\])((?:\\\\)*)([\$\@]|\\[uUlLQE])/$1$2\\$3/g;
3572     return $str;
3573 }
3574
3575 {
3576 my $bal;
3577 BEGIN {
3578     use re "eval";
3579     # Matches any string which is balanced with respect to {braces}
3580     $bal = qr(
3581       (?:
3582         [^\\{}]
3583       | \\\\
3584       | \\[{}]
3585       | \{(??{$bal})\}
3586       )*
3587     )x;
3588 }
3589
3590 # the same, but treat $|, $), $( and $ at the end of the string differently
3591 sub re_uninterp {
3592     my($str) = @_;
3593
3594     $str =~ s/
3595           ( ^|\G                  # $1
3596           | [^\\]
3597           )
3598
3599           (                       # $2
3600             (?:\\\\)*
3601           )
3602
3603           (                       # $3
3604             (\(\?\??\{$bal\}\))   # $4
3605           | [\$\@]
3606             (?!\||\)|\(|$)
3607           | \\[uUlLQE]
3608           )
3609
3610         /defined($4) && length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
3611
3612     return $str;
3613 }
3614
3615 # This is for regular expressions with the /x modifier
3616 # We have to leave comments unmangled.
3617 sub re_uninterp_extended {
3618     my($str) = @_;
3619
3620     $str =~ s/
3621           ( ^|\G                  # $1
3622           | [^\\]
3623           )
3624
3625           (                       # $2
3626             (?:\\\\)*
3627           )
3628
3629           (                       # $3
3630             ( \(\?\??\{$bal\}\)   # $4  (skip over (?{}) and (??{}) blocks)
3631             | \#[^\n]*            #     (skip over comments)
3632             )
3633           | [\$\@]
3634             (?!\||\)|\(|$|\s)
3635           | \\[uUlLQE]
3636           )
3637
3638         /defined($4) && length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
3639
3640     return $str;
3641 }
3642 }
3643
3644 my %unctrl = # portable to to EBCDIC
3645     (
3646      "\c@" => '\c@',    # unused
3647      "\cA" => '\cA',
3648      "\cB" => '\cB',
3649      "\cC" => '\cC',
3650      "\cD" => '\cD',
3651      "\cE" => '\cE',
3652      "\cF" => '\cF',
3653      "\cG" => '\cG',
3654      "\cH" => '\cH',
3655      "\cI" => '\cI',
3656      "\cJ" => '\cJ',
3657      "\cK" => '\cK',
3658      "\cL" => '\cL',
3659      "\cM" => '\cM',
3660      "\cN" => '\cN',
3661      "\cO" => '\cO',
3662      "\cP" => '\cP',
3663      "\cQ" => '\cQ',
3664      "\cR" => '\cR',
3665      "\cS" => '\cS',
3666      "\cT" => '\cT',
3667      "\cU" => '\cU',
3668      "\cV" => '\cV',
3669      "\cW" => '\cW',
3670      "\cX" => '\cX',
3671      "\cY" => '\cY',
3672      "\cZ" => '\cZ',
3673      "\c[" => '\c[',    # unused
3674      "\c\\" => '\c\\',  # unused
3675      "\c]" => '\c]',    # unused
3676      "\c_" => '\c_',    # unused
3677     );
3678
3679 # character escapes, but not delimiters that might need to be escaped
3680 sub escape_str { # ASCII, UTF8
3681     my($str) = @_;
3682     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
3683     $str =~ s/\a/\\a/g;
3684 #    $str =~ s/\cH/\\b/g; # \b means something different in a regex
3685     $str =~ s/\t/\\t/g;
3686     $str =~ s/\n/\\n/g;
3687     $str =~ s/\e/\\e/g;
3688     $str =~ s/\f/\\f/g;
3689     $str =~ s/\r/\\r/g;
3690     $str =~ s/([\cA-\cZ])/$unctrl{$1}/ge;
3691     $str =~ s/([[:^print:]])/sprintf("\\%03o", ord($1))/ge;
3692     return $str;
3693 }
3694
3695 # For regexes with the /x modifier.
3696 # Leave whitespace unmangled.
3697 sub escape_extended_re {
3698     my($str) = @_;
3699     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
3700     $str =~ s/([[:^print:]])/
3701         ($1 =~ y! \t\n!!) ? $1 : sprintf("\\%03o", ord($1))/ge;
3702     $str =~ s/\n/\n\f/g;
3703     return $str;
3704 }
3705
3706 # Don't do this for regexen
3707 sub unback {
3708     my($str) = @_;
3709     $str =~ s/\\/\\\\/g;
3710     return $str;
3711 }
3712
3713 # Remove backslashes which precede literal control characters,
3714 # to avoid creating ambiguity when we escape the latter.
3715 sub re_unback {
3716     my($str) = @_;
3717
3718     # the insane complexity here is due to the behaviour of "\c\"
3719     $str =~ s/(^|[^\\]|\\c\\)(?<!\\c)\\(\\\\)*(?=[[:^print:]])/$1$2/g;
3720     return $str;
3721 }
3722
3723 sub balanced_delim {
3724     my($str) = @_;
3725     my @str = split //, $str;
3726     my($ar, $open, $close, $fail, $c, $cnt, $last_bs);
3727     for $ar (['[',']'], ['(',')'], ['<','>'], ['{','}']) {
3728         ($open, $close) = @$ar;
3729         $fail = 0; $cnt = 0; $last_bs = 0;
3730         for $c (@str) {
3731             if ($c eq $open) {
3732                 $fail = 1 if $last_bs;
3733                 $cnt++;
3734             } elsif ($c eq $close) {
3735                 $fail = 1 if $last_bs;
3736                 $cnt--;
3737                 if ($cnt < 0) {
3738                     # qq()() isn't ")("
3739                     $fail = 1;
3740                     last;
3741                 }
3742             }
3743             $last_bs = $c eq '\\';
3744         }
3745         $fail = 1 if $cnt != 0;
3746         return ($open, "$open$str$close") if not $fail;
3747     }
3748     return ("", $str);
3749 }
3750
3751 sub single_delim {
3752     my($q, $default, $str) = @_;
3753     return "$default$str$default" if $default and index($str, $default) == -1;
3754     if ($q ne 'qr') {
3755         (my $succeed, $str) = balanced_delim($str);
3756         return "$q$str" if $succeed;
3757     }
3758     for my $delim ('/', '"', '#') {
3759         return "$q$delim" . $str . $delim if index($str, $delim) == -1;
3760     }
3761     if ($default) {
3762         $str =~ s/$default/\\$default/g;
3763         return "$default$str$default";
3764     } else {
3765         $str =~ s[/][\\/]g;
3766         return "$q/$str/";
3767     }
3768 }
3769
3770 my $max_prec;
3771 BEGIN { $max_prec = int(0.999 + 8*length(pack("F", 42))*log(2)/log(10)); }
3772
3773 # Split a floating point number into an integer mantissa and a binary
3774 # exponent. Assumes you've already made sure the number isn't zero or
3775 # some weird infinity or NaN.
3776 sub split_float {
3777     my($f) = @_;
3778     my $exponent = 0;
3779     if ($f == int($f)) {
3780         while ($f % 2 == 0) {
3781             $f /= 2;
3782             $exponent++;
3783         }
3784     } else {
3785         while ($f != int($f)) {
3786             $f *= 2;
3787             $exponent--;
3788         }
3789     }
3790     my $mantissa = sprintf("%.0f", $f);
3791     return ($mantissa, $exponent);
3792 }
3793
3794 sub const {
3795     my $self = shift;
3796     my($sv, $cx) = @_;
3797     if ($self->{'use_dumper'}) {
3798         return $self->const_dumper($sv, $cx);
3799     }
3800     if (class($sv) eq "SPECIAL") {
3801         # sv_undef, sv_yes, sv_no
3802         return ('undef', '1', $self->maybe_parens("!1", $cx, 21))[$$sv-1];
3803     }
3804     if (class($sv) eq "NULL") {
3805        return 'undef';
3806     }
3807     # convert a version object into the "v1.2.3" string in its V magic
3808     if ($sv->FLAGS & SVs_RMG) {
3809         for (my $mg = $sv->MAGIC; $mg; $mg = $mg->MOREMAGIC) {
3810             return $mg->PTR if $mg->TYPE eq 'V';
3811         }
3812     }
3813
3814     if ($sv->FLAGS & SVf_IOK) {
3815         my $str = $sv->int_value;
3816         $str = $self->maybe_parens($str, $cx, 21) if $str < 0;
3817         return $str;
3818     } elsif ($sv->FLAGS & SVf_NOK) {
3819         my $nv = $sv->NV;
3820         if ($nv == 0) {
3821             if (pack("F", $nv) eq pack("F", 0)) {
3822                 # positive zero
3823                 return "0";
3824             } else {
3825                 # negative zero
3826                 return $self->maybe_parens("-.0", $cx, 21);
3827             }
3828         } elsif (1/$nv == 0) {
3829             if ($nv > 0) {
3830                 # positive infinity
3831                 return $self->maybe_parens("9**9**9", $cx, 22);
3832             } else {
3833                 # negative infinity
3834                 return $self->maybe_parens("-9**9**9", $cx, 21);
3835             }
3836         } elsif ($nv != $nv) {
3837             # NaN
3838             if (pack("F", $nv) eq pack("F", sin(9**9**9))) {
3839                 # the normal kind
3840                 return "sin(9**9**9)";
3841             } elsif (pack("F", $nv) eq pack("F", -sin(9**9**9))) {
3842                 # the inverted kind
3843                 return $self->maybe_parens("-sin(9**9**9)", $cx, 21);
3844             } else {
3845                 # some other kind
3846                 my $hex = unpack("h*", pack("F", $nv));
3847                 return qq'unpack("F", pack("h*", "$hex"))';
3848             }
3849         }
3850         # first, try the default stringification
3851         my $str = "$nv";
3852         if ($str != $nv) {
3853             # failing that, try using more precision
3854             $str = sprintf("%.${max_prec}g", $nv);
3855 #           if (pack("F", $str) ne pack("F", $nv)) {
3856             if ($str != $nv) {
3857                 # not representable in decimal with whatever sprintf()
3858                 # and atof() Perl is using here.
3859                 my($mant, $exp) = split_float($nv);
3860                 return $self->maybe_parens("$mant * 2**$exp", $cx, 19);
3861             }
3862         }
3863         $str = $self->maybe_parens($str, $cx, 21) if $nv < 0;
3864         return $str;
3865     } elsif ($sv->FLAGS & SVf_ROK && $sv->can("RV")) {
3866         my $ref = $sv->RV;
3867         if (class($ref) eq "AV") {
3868             return "[" . $self->list_const(2, $ref->ARRAY) . "]";
3869         } elsif (class($ref) eq "HV") {
3870             my %hash = $ref->ARRAY;
3871             my @elts;
3872             for my $k (sort keys %hash) {
3873                 push @elts, "$k => " . $self->const($hash{$k}, 6);
3874             }
3875             return "{" . join(", ", @elts) . "}";
3876         } elsif (class($ref) eq "CV") {
3877             BEGIN {
3878 # Commented out until after 5.15.6
3879 #               if ($] > 5.0150051) {
3880                     require overloading;
3881                     unimport overloading;
3882 #               }
3883             }
3884             # Remove the 1|| after 5.15.6
3885             if ((1||$] > 5.0150051) && $self->{curcv} &&
3886                  $self->{curcv}->object_2svref == $ref->object_2svref) {
3887                 return $self->keyword("__SUB__");
3888             }
3889             return "sub " . $self->deparse_sub($ref);
3890         }
3891         if ($ref->FLAGS & SVs_SMG) {
3892             for (my $mg = $ref->MAGIC; $mg; $mg = $mg->MOREMAGIC) {
3893                 if ($mg->TYPE eq 'r') {
3894                     my $re = re_uninterp(escape_str(re_unback($mg->precomp)));
3895                     return single_delim("qr", "", $re);
3896                 }
3897             }
3898         }
3899         
3900         return $self->maybe_parens("\\" . $self->const($ref, 20), $cx, 20);
3901     } elsif ($sv->FLAGS & SVf_POK) {
3902         my $str = $sv->PV;
3903         if ($str =~ /[[:^print:]]/) {
3904             return single_delim("qq", '"', uninterp escape_str unback $str);
3905         } else {
3906             return single_delim("q", "'", unback $str);
3907         }
3908     } else {
3909         return "undef";
3910     }
3911 }
3912
3913 sub const_dumper {
3914     my $self = shift;
3915     my($sv, $cx) = @_;
3916     my $ref = $sv->object_2svref();
3917     my $dumper = Data::Dumper->new([$$ref], ['$v']);
3918     $dumper->Purity(1)->Terse(1)->Deparse(1)->Indent(0)->Useqq(1)->Sortkeys(1);
3919     my $str = $dumper->Dump();
3920     if ($str =~ /^\$v/) {
3921         return '${my ' . $str . ' \$v}';
3922     } else {
3923         return $str;
3924     }
3925 }
3926
3927 sub const_sv {
3928     my $self = shift;
3929     my $op = shift;
3930     my $sv = $op->sv;
3931     # the constant could be in the pad (under useithreads)
3932     $sv = $self->padval($op->targ) unless $$sv;
3933     return $sv;
3934 }
3935
3936 sub pp_const {
3937     my $self = shift;
3938     my($op, $cx) = @_;
3939     if ($op->private & OPpCONST_ARYBASE) {
3940         return '$[';
3941     }
3942 #    if ($op->private & OPpCONST_BARE) { # trouble with '=>' autoquoting
3943 #       return $self->const_sv($op)->PV;
3944 #    }
3945     my $sv = $self->const_sv($op);
3946     return $self->const($sv, $cx);
3947 }
3948
3949 sub dq {
3950     my $self = shift;
3951     my $op = shift;
3952     my $type = $op->name;
3953     if ($type eq "const") {
3954         return '$[' if $op->private & OPpCONST_ARYBASE;
3955         return uninterp(escape_str(unback($self->const_sv($op)->as_string)));
3956     } elsif ($type eq "concat") {
3957         my $first = $self->dq($op->first);
3958         my $last  = $self->dq($op->last);
3959
3960         # Disambiguate "${foo}bar", "${foo}{bar}", "${foo}[1]", "$foo\::bar"
3961         ($last =~ /^[A-Z\\\^\[\]_?]/ &&
3962             $first =~ s/([\$@])\^$/${1}{^}/)  # "${^}W" etc
3963             || ($last =~ /^[:'{\[\w_]/ && #'
3964                 $first =~ s/([\$@])([A-Za-z_]\w*)$/${1}{$2}/);
3965
3966         return $first . $last;
3967     } elsif ($type eq "uc") {
3968         return '\U' . $self->dq($op->first->sibling) . '\E';
3969     } elsif ($type eq "lc") {
3970         return '\L' . $self->dq($op->first->sibling) . '\E';
3971     } elsif ($type eq "ucfirst") {
3972         return '\u' . $self->dq($op->first->sibling);
3973     } elsif ($type eq "lcfirst") {
3974         return '\l' . $self->dq($op->first->sibling);
3975     } elsif ($type eq "quotemeta") {
3976         return '\Q' . $self->dq($op->first->sibling) . '\E';
3977     } elsif ($type eq "join") {
3978         return $self->deparse($op->last, 26); # was join($", @ary)
3979     } else {
3980         return $self->deparse($op, 26);
3981     }
3982 }
3983
3984 sub pp_backtick {
3985     my $self = shift;
3986     my($op, $cx) = @_;
3987     # skip pushmark if it exists (readpipe() vs ``)
3988     my $child = $op->first->sibling->isa('B::NULL')
3989         ? $op->first : $op->first->sibling;
3990     if ($self->pure_string($child)) {
3991         return single_delim("qx", '`', $self->dq($child, 1));
3992     }
3993     unop($self, @_, "readpipe");
3994 }
3995
3996 sub dquote {
3997     my $self = shift;
3998     my($op, $cx) = @_;
3999     my $kid = $op->first->sibling; # skip ex-stringify, pushmark
4000     return $self->deparse($kid, $cx) if $self->{'unquote'};
4001     $self->maybe_targmy($kid, $cx,
4002                         sub {single_delim("qq", '"', $self->dq($_[1]))});
4003 }
4004
4005 # OP_STRINGIFY is a listop, but it only ever has one arg
4006 sub pp_stringify { maybe_targmy(@_, \&dquote) }
4007
4008 # tr/// and s/// (and tr[][], tr[]//, tr###, etc)
4009 # note that tr(from)/to/ is OK, but not tr/from/(to)
4010 sub double_delim {
4011     my($from, $to) = @_;
4012     my($succeed, $delim);
4013     if ($from !~ m[/] and $to !~ m[/]) {
4014         return "/$from/$to/";
4015     } elsif (($succeed, $from) = balanced_delim($from) and $succeed) {
4016         if (($succeed, $to) = balanced_delim($to) and $succeed) {
4017             return "$from$to";
4018         } else {
4019             for $delim ('/', '"', '#') { # note no "'" -- s''' is special
4020                 return "$from$delim$to$delim" if index($to, $delim) == -1;
4021             }
4022             $to =~ s[/][\\/]g;
4023             return "$from/$to/";
4024         }
4025     } else {
4026         for $delim ('/', '"', '#') { # note no '
4027             return "$delim$from$delim$to$delim"
4028                 if index($to . $from, $delim) == -1;
4029         }
4030         $from =~ s[/][\\/]g;
4031         $to =~ s[/][\\/]g;
4032         return "/$from/$to/";   
4033     }
4034 }
4035
4036 # Only used by tr///, so backslashes hyphens
4037 sub pchr { # ASCII
4038     my($n) = @_;
4039     if ($n == ord '\\') {
4040         return '\\\\';
4041     } elsif ($n == ord "-") {
4042         return "\\-";
4043     } elsif ($n >= ord(' ') and $n <= ord('~')) {
4044         return chr($n);
4045     } elsif ($n == ord "\a") {
4046         return '\\a';
4047     } elsif ($n == ord "\b") {
4048         return '\\b';
4049     } elsif ($n == ord "\t") {
4050         return '\\t';
4051     } elsif ($n == ord "\n") {
4052         return '\\n';
4053     } elsif ($n == ord "\e") {
4054         return '\\e';
4055     } elsif ($n == ord "\f") {
4056         return '\\f';
4057     } elsif ($n == ord "\r") {
4058         return '\\r';
4059     } elsif ($n >= ord("\cA") and $n <= ord("\cZ")) {
4060         return '\\c' . chr(ord("@") + $n);
4061     } else {
4062 #       return '\x' . sprintf("%02x", $n);
4063         return '\\' . sprintf("%03o", $n);
4064     }
4065 }
4066
4067 sub collapse {
4068     my(@chars) = @_;
4069     my($str, $c, $tr) = ("");
4070     for ($c = 0; $c < @chars; $c++) {
4071         $tr = $chars[$c];
4072         $str .= pchr($tr);
4073         if ($c <= $#chars - 2 and $chars[$c + 1] == $tr + 1 and
4074             $chars[$c + 2] == $tr + 2)
4075         {
4076             for (; $c <= $#chars-1 and $chars[$c + 1] == $chars[$c] + 1; $c++)
4077               {}
4078             $str .= "-";
4079             $str .= pchr($chars[$c]);
4080         }
4081     }
4082     return $str;
4083 }
4084
4085 sub tr_decode_byte {
4086     my($table, $flags) = @_;
4087     my(@table) = unpack("s*", $table);
4088     splice @table, 0x100, 1;   # Number of subsequent elements
4089     my($c, $tr, @from, @to, @delfrom, $delhyphen);
4090     if ($table[ord "-"] != -1 and
4091         $table[ord("-") - 1] == -1 || $table[ord("-") + 1] == -1)
4092     {
4093         $tr = $table[ord "-"];
4094         $table[ord "-"] = -1;
4095         if ($tr >= 0) {
4096             @from = ord("-");
4097             @to = $tr;
4098         } else { # -2 ==> delete
4099             $delhyphen = 1;
4100         }
4101     }
4102     for ($c = 0; $c < @table; $c++) {
4103         $tr = $table[$c];
4104         if ($tr >= 0) {
4105             push @from, $c; push @to, $tr;
4106         } elsif ($tr == -2) {
4107             push @delfrom, $c;
4108         }
4109     }
4110     @from = (@from, @delfrom);
4111     if ($flags & OPpTRANS_COMPLEMENT) {
4112         my @newfrom = ();
4113         my %from;
4114         @from{@from} = (1) x @from;
4115         for ($c = 0; $c < 256; $c++) {
4116             push @newfrom, $c unless $from{$c};
4117         }
4118         @from = @newfrom;
4119     }
4120     unless ($flags & OPpTRANS_DELETE || !@to) {
4121         pop @to while $#to and $to[$#to] == $to[$#to -1];
4122     }
4123     my($from, $to);
4124     $from = collapse(@from);
4125     $to = collapse(@to);
4126     $from .= "-" if $delhyphen;
4127     return ($from, $to);
4128 }
4129
4130 sub tr_chr {
4131     my $x = shift;
4132     if ($x == ord "-") {
4133         return "\\-";
4134     } elsif ($x == ord "\\") {
4135         return "\\\\";
4136     } else {
4137         return chr $x;
4138     }
4139 }
4140
4141 # XXX This doesn't yet handle all cases correctly either
4142
4143 sub tr_decode_utf8 {
4144     my($swash_hv, $flags) = @_;
4145     my %swash = $swash_hv->ARRAY;
4146     my $final = undef;
4147     $final = $swash{'FINAL'}->IV if exists $swash{'FINAL'};
4148     my $none = $swash{"NONE"}->IV;
4149     my $extra = $none + 1;
4150     my(@from, @delfrom, @to);
4151     my $line;
4152     foreach $line (split /\n/, $swash{'LIST'}->PV) {
4153         my($min, $max, $result) = split(/\t/, $line);
4154         $min = hex $min;
4155         if (length $max) {
4156             $max = hex $max;
4157         } else {
4158             $max = $min;
4159         }
4160         $result = hex $result;
4161         if ($result == $extra) {
4162             push @delfrom, [$min, $max];
4163         } else {
4164             push @from, [$min, $max];
4165             push @to, [$result, $result + $max - $min];
4166         }
4167     }
4168     for my $i (0 .. $#from) {
4169         if ($from[$i][0] == ord '-') {
4170             unshift @from, splice(@from, $i, 1);
4171             unshift @to, splice(@to, $i, 1);
4172             last;
4173         } elsif ($from[$i][1] == ord '-') {
4174             $from[$i][1]--;
4175             $to[$i][1]--;
4176             unshift @from, ord '-';
4177             unshift @to, ord '-';
4178             last;
4179         }
4180     }
4181     for my $i (0 .. $#delfrom) {
4182         if ($delfrom[$i][0] == ord '-') {
4183             push @delfrom, splice(@delfrom, $i, 1);
4184             last;
4185         } elsif ($delfrom[$i][1] == ord '-') {
4186             $delfrom[$i][1]--;
4187             push @delfrom, ord '-';
4188             last;
4189         }
4190     }
4191     if (defined $final and $to[$#to][1] != $final) {
4192         push @to, [$final, $final];
4193     }
4194     push @from, @delfrom;
4195     if ($flags & OPpTRANS_COMPLEMENT) {
4196         my @newfrom;
4197         my $next = 0;
4198         for my $i (0 .. $#from) {
4199             push @newfrom, [$next, $from[$i][0] - 1];
4200             $next = $from[$i][1] + 1;
4201         }
4202         @from = ();
4203         for my $range (@newfrom) {
4204             if ($range->[0] <= $range->[1]) {
4205                 push @from, $range;
4206             }
4207         }
4208     }
4209     my($from, $to, $diff);
4210     for my $chunk (@from) {
4211         $diff = $chunk->[1] - $chunk->[0];
4212         if ($diff > 1) {
4213             $from .= tr_chr($chunk->[0]) . "-" . tr_chr($chunk->[1]);
4214         } elsif ($diff == 1) {
4215             $from .= tr_chr($chunk->[0]) . tr_chr($chunk->[1]);
4216         } else {
4217             $from .= tr_chr($chunk->[0]);
4218         }
4219     }
4220     for my $chunk (@to) {
4221         $diff = $chunk->[1] - $chunk->[0];
4222         if ($diff > 1) {
4223             $to .= tr_chr($chunk->[0]) . "-" . tr_chr($chunk->[1]);
4224         } elsif ($diff == 1) {
4225             $to .= tr_chr($chunk->[0]) . tr_chr($chunk->[1]);
4226         } else {
4227             $to .= tr_chr($chunk->[0]);
4228         }
4229     }
4230     #$final = sprintf("%04x", $final) if defined $final;
4231     #$none = sprintf("%04x", $none) if defined $none;
4232     #$extra = sprintf("%04x", $extra) if defined $extra;
4233     #print STDERR "final: $final\n none: $none\nextra: $extra\n";
4234     #print STDERR $swash{'LIST'}->PV;
4235     return (escape_str($from), escape_str($to));
4236 }
4237
4238 sub pp_trans {
4239     my $self = shift;
4240     my($op, $cx) = @_;
4241     my($from, $to);
4242     my $class = class($op);
4243     my $priv_flags = $op->private;
4244     if ($class eq "PVOP") {
4245         ($from, $to) = tr_decode_byte($op->pv, $priv_flags);
4246     } elsif ($class eq "PADOP") {
4247         ($from, $to)
4248           = tr_decode_utf8($self->padval($op->padix)->RV, $priv_flags);
4249     } else { # class($op) eq "SVOP"
4250         ($from, $to) = tr_decode_utf8($op->sv->RV, $priv_flags);
4251     }
4252     my $flags = "";
4253     $flags .= "c" if $priv_flags & OPpTRANS_COMPLEMENT;
4254     $flags .= "d" if $priv_flags & OPpTRANS_DELETE;
4255     $to = "" if $from eq $to and $flags eq "";
4256     $flags .= "s" if $priv_flags & OPpTRANS_SQUASH;
4257     return "tr" . double_delim($from, $to) . $flags;
4258 }
4259
4260 sub pp_transr { &pp_trans . 'r' }
4261
4262 sub re_dq_disambiguate {
4263     my ($first, $last) = @_;
4264     # Disambiguate "${foo}bar", "${foo}{bar}", "${foo}[1]"
4265     ($last =~ /^[A-Z\\\^\[\]_?]/ &&
4266         $first =~ s/([\$@])\^$/${1}{^}/)  # "${^}W" etc
4267         || ($last =~ /^[{\[\w_]/ &&
4268             $first =~ s/([\$@])([A-Za-z_]\w*)$/${1}{$2}/);
4269     return $first . $last;
4270 }
4271
4272 # Like dq(), but different
4273 sub re_dq {
4274     my $self = shift;
4275     my ($op, $extended) = @_;
4276
4277     my $type = $op->name;
4278     if ($type eq "const") {
4279         return '$[' if $op->private & OPpCONST_ARYBASE;
4280         my $unbacked = re_unback($self->const_sv($op)->as_string);
4281         return re_uninterp_extended(escape_extended_re($unbacked))
4282             if $extended;
4283         return re_uninterp(escape_str($unbacked));
4284     } elsif ($type eq "concat") {
4285         my $first = $self->re_dq($op->first, $extended);
4286         my $last  = $self->re_dq($op->last,  $extended);
4287         return re_dq_disambiguate($first, $last);
4288     } elsif ($type eq "uc") {
4289         return '\U' . $self->re_dq($op->first->sibling, $extended) . '\E';
4290     } elsif ($type eq "lc") {
4291         return '\L' . $self->re_dq($op->first->sibling, $extended) . '\E';
4292     } elsif ($type eq "ucfirst") {
4293         return '\u' . $self->re_dq($op->first->sibling, $extended);
4294     } elsif ($type eq "lcfirst") {
4295         return '\l' . $self->re_dq($op->first->sibling, $extended);
4296     } elsif ($type eq "quotemeta") {
4297         return '\Q' . $self->re_dq($op->first->sibling, $extended) . '\E';
4298     } elsif ($type eq "join") {
4299         return $self->deparse($op->last, 26); # was join($", @ary)
4300     } else {
4301         return $self->deparse($op, 26);
4302     }
4303 }
4304
4305 sub pure_string {
4306     my ($self, $op) = @_;
4307     return 0 if null $op;
4308     my $type = $op->name;
4309
4310     if ($type eq 'const') {
4311         return 1;
4312     }
4313     elsif ($type =~ /^[ul]c(first)?$/ || $type eq 'quotemeta') {
4314         return $self->pure_string($op->first->sibling);
4315     }
4316     elsif ($type eq 'join') {
4317         my $join_op = $op->first->sibling;  # Skip pushmark
4318         return 0 unless $join_op->name eq 'null' && $join_op->targ eq OP_RV2SV;
4319
4320         my $gvop = $join_op->first;
4321         return 0 unless $gvop->name eq 'gvsv';
4322         return 0 unless '"' eq $self->gv_name($self->gv_or_padgv($gvop));
4323
4324         return 0 unless ${$join_op->sibling} eq ${$op->last};
4325         return 0 unless $op->last->name =~ /^(?:[ah]slice|(?:rv2|pad)av)$/;
4326     }
4327     elsif ($type eq 'concat') {
4328         return $self->pure_string($op->first)
4329             && $self->pure_string($op->last);
4330     }
4331     elsif (is_scalar($op) || $type =~ /^[ah]elem$/) {
4332         return 1;
4333     }
4334     elsif ($type eq "null" and $op->can('first') and not null $op->first and
4335            $op->first->name eq "null" and $op->first->can('first')
4336            and not null $op->first->first and
4337            $op->first->first->name eq "aelemfast") {
4338         return 1;
4339     }
4340     else {
4341         return 0;
4342     }
4343
4344     return 1;
4345 }
4346
4347 sub regcomp {
4348     my $self = shift;
4349     my($op, $cx, $extended) = @_;
4350     my $kid = $op->first;
4351     $kid = $kid->first if $kid->name eq "regcmaybe";
4352     $kid = $kid->first if $kid->name eq "regcreset";
4353     if ($kid->name eq "null" and !null($kid->first)
4354         and $kid->first->name eq 'pushmark')
4355     {
4356         my $str = '';
4357         $kid = $kid->first->sibling;
4358         while (!null($kid)) {
4359             my $first = $str;
4360             my $last = $self->re_dq($kid, $extended);
4361             $str = re_dq_disambiguate($first, $last);