t/TEST

   1 #!./perl
   2
   3 # This is written in a peculiar style, since we're trying to avoid
   4 # most of the constructs we'll be testing for.  (This comment is
   5 # probably obsolete on the avoidance side, though still currrent
   6 # on the peculiarity side.)
   7
   8 # t/TEST and t/harness need to share code. The logical way to do this would be
   9 # to have the common code in a file both require or use. However, t/TEST needs
  10 # to still work, to generate test results, even if require isn't working, so
  11 # we cannot do that. t/harness has no such restriction, so it is quite
  12 # acceptable to have it require t/TEST.
  13
  14 # In which case, we need to stop t/TEST actually running tests, as all
  15 # t/harness needs are its subroutines.
  16
  17
  18 # directories with special sets of test switches
  19 my %dir_to_switch =
  20     (base => '',
  21      comp => '',
  22      run => '',
  23      '../ext/File-Glob/t' => '-I.. -MTestInit', # FIXME - tests assume t/
  24      );
  25
  26 # "not absolute" is the the default, as it saves some fakery within TestInit
  27 # which can peturb tests, and takes CPU. Working with the upstream author of
  28 # any of these, to figure out how to remove them from this list, considered
  29 # "a good thing".
  30 my %abs = (
  31            '../cpan/Archive-Extract' => 1,
  32            '../cpan/Archive-Tar' => 1,
  33            '../cpan/AutoLoader' => 1,
  34            '../cpan/CPAN' => 1,
  35            '../cpan/Class-ISA' => 1,
  36            '../cpan/Devel-PPPort' => 1,
  37            '../cpan/Encode' => 1,
  38            '../cpan/ExtUtils-Constant' => 1,
  39            '../cpan/ExtUtils-MakeMaker' => 1,
  40            '../cpan/File-Fetch' => 1,
  41            '../cpan/IPC-Cmd' => 1,
  42            '../cpan/IPC-SysV' => 1,
  43            '../cpan/Locale-Codes' => 1,
  44            '../cpan/Log-Message' => 1,
  45            '../cpan/Module-Build' => 1,
  46            '../cpan/Module-Load' => 1,
  47            '../cpan/Module-Load-Conditional' => 1,
  48            '../cpan/Object-Accessor' => 1,
  49            '../cpan/Package-Constants' => 1,
  50            '../cpan/Parse-CPAN-Meta' => 1,
  51            '../cpan/Pod-Simple' => 1,
  52            '../cpan/Term-UI' => 1,
  53            '../cpan/Test-Simple' => 1,
  54            '../cpan/Tie-File' => 1,
  55            '../cpan/podlators' => 1,
  56            '../dist/Cwd' => 1,
  57            '../dist/ExtUtils-Command' => 1,
  58            '../dist/ExtUtils-Install' => 1,
  59            '../dist/ExtUtils-Manifest' => 1,
  60            '../dist/ExtUtils-ParseXS' => 1,
  61           );
  62
  63 my %temp_no_core =
  64     ('../cpan/B-Debug' => 1,
  65      '../cpan/Compress-Raw-Bzip2' => 1,
  66      '../cpan/Compress-Raw-Zlib' => 1,
  67      '../cpan/Devel-PPPort' => 1,
  68      '../cpan/Getopt-Long' => 1,
  69      '../cpan/IO-Compress' => 1,
  70      '../cpan/MIME-Base64' => 1,
  71      '../cpan/parent' => 1,
  72      '../cpan/Parse-CPAN-Meta' => 1,
  73      '../cpan/Pod-Simple' => 1,
  74      '../cpan/podlators' => 1,
  75      '../cpan/Test-Simple' => 1,
  76      '../cpan/Tie-RefHash' => 1,
  77      '../cpan/Unicode-Collate' => 1,
  78      '../cpan/Unicode-Normalize' => 1,
  79     );
  80
  81 # delete env vars that may influence the results
  82 # but allow override via *_TEST env var if wanted
  83 # (e.g. PERL5OPT_TEST=-d:NYTProf)
  84 for my $envname (qw(PERL5LIB PERLLIB PERL5OPT)) {
  85     my $override = $ENV{"${envname}_TEST"};
  86     if (defined $override) {
  87         warn "$0: $envname=$override\n";
  88         $ENV{$envname} = $override;
  89     }
  90     else {
  91         delete $ENV{$envname};
  92     }
  93 }
  94
  95 if ($::do_nothing) {
  96     return 1;
  97 }
  98
  99 # Location to put the Valgrind log.
 100 our $Valgrind_Log;
 101
 102 $| = 1;
 103
 104 # for testing TEST only
 105 #BEGIN { require '../lib/strict.pm'; "strict"->import() };
 106 #BEGIN { require '../lib/warnings.pm'; "warnings"->import() };
 107
 108 # remove empty elements due to insertion of empty symbols via "''p1'" syntax
 109 @ARGV = grep($_,@ARGV) if $^O eq 'VMS';
 110 our $show_elapsed_time = $ENV{HARNESS_TIMER} || 0;
 111
 112 # Cheesy version of Getopt::Std.  We can't replace it with that, because we
 113 # can't rely on require working.
 114 {
 115     my @argv = ();
 116     foreach my $idx (0..$#ARGV) {
 117         push( @argv, $ARGV[$idx] ), next unless $ARGV[$idx] =~ /^-(\S+)$/;
 118         $::benchmark = 1 if $1 eq 'benchmark';
 119         $::core    = 1 if $1 eq 'core';
 120         $::verbose = 1 if $1 eq 'v';
 121         $::torture = 1 if $1 eq 'torture';
 122         $::with_utf8 = 1 if $1 eq 'utf8';
 123         $::with_utf16 = 1 if $1 eq 'utf16';
 124         $::taintwarn = 1 if $1 eq 'taintwarn';
 125         if ($1 =~ /^deparse(,.+)?$/) {
 126             $::deparse = 1;
 127             $::deparse_opts = $1;
 128         }
 129     }
 130     @ARGV = @argv;
 131 }
 132
 133 chdir 't' if -f 't/TEST';
 134 if (-f 'TEST' && -f 'harness' && -d '../lib') {
 135     @INC = '../lib';
 136 }
 137
 138 die "You need to run \"make test\" first to set things up.\n"
 139   unless -e 'perl' or -e 'perl.exe' or -e 'perl.pm';
 140
 141 if ($ENV{PERL_3LOG}) { # Tru64 third(1) tool, see perlhack
 142     unless (-x 'perl.third') {
 143         unless (-x '../perl.third') {
 144             die "You need to run \"make perl.third first.\n";
 145         }
 146         else {
 147             print "Symlinking ../perl.third as perl.third...\n";
 148             die "Failed to symlink: $!\n"
 149                 unless symlink("../perl.third", "perl.third");
 150             die "Symlinked but no executable perl.third: $!\n"
 151                 unless -x 'perl.third';
 152         }
 153     }
 154 }
 155
 156 # check leakage for embedders
 157 $ENV{PERL_DESTRUCT_LEVEL} = 2 unless exists $ENV{PERL_DESTRUCT_LEVEL};
 158
 159 $ENV{EMXSHELL} = 'sh';        # For OS/2
 160
 161 if ($show_elapsed_time) { require Time::HiRes }
 162 my %timings = (); # testname => [@et] pairs if $show_elapsed_time.
 163
 164 my %skip = (
 165             '.' => 1,
 166             '..' => 1,
 167             'CVS' => 1,
 168             'RCS' => 1,
 169             'SCCS' => 1,
 170             '.svn' => 1,
 171            );
 172
 173 # Roll your own File::Find!
 174 sub _find_tests {
 175     my($dir) = @_;
 176     opendir DIR, $dir or die "Trouble opening $dir: $!";
 177     foreach my $f (sort { $a cmp $b } readdir DIR) {
 178         next if $skip{$f};
 179
 180         my $fullpath = "$dir/$f";
 181
 182         if (-d $fullpath) {
 183             _find_tests($fullpath);
 184         } elsif ($f =~ /\.t$/) {
 185             push @ARGV, $fullpath;
 186         }
 187     }
 188 }
 189
 190
 191 # Scan the text of the test program to find switches and special options
 192 # we might need to apply.
 193 sub _scan_test {
 194     my($test, $type) = @_;
 195
 196     open(my $script, "<", $test) or die "Can't read $test.\n";
 197     my $first_line = <$script>;
 198
 199     $first_line =~ tr/\0//d if $::with_utf16;
 200
 201     my $switch = "";
 202     if ($first_line =~ /#!.*\bperl.*\s-\w*([tT])/) {
 203         $switch = "-$1";
 204     } else {
 205         if ($::taintwarn) {
 206             # not all tests are expected to pass with this option
 207             $switch = '-t';
 208         } else {
 209             $switch = '';
 210         }
 211     }
 212
 213     my $file_opts = "";
 214     if ($type eq 'deparse') {
 215         # Look for #line directives which change the filename
 216         while (<$script>) {
 217             $file_opts = $file_opts . ",-f$3$4"
 218               if /^#\s*line\s+(\d+)\s+((\w+)|"([^"]+)")/;
 219         }
 220     }
 221
 222     close $script;
 223
 224     my $perl = './perl';
 225     my $lib  = '../lib';
 226     my $run_dir;
 227     my $return_dir;
 228
 229     $test =~ /^(.+)\/[^\/]+/;
 230     my $dir = $1;
 231     my $testswitch = $dir_to_switch{$dir};
 232     if (!defined $testswitch) {
 233         if ($test =~ s!^(\.\./(cpan|dist|ext)/[^/]+)/t!t!) {
 234             $run_dir = $1;
 235             $return_dir = '../../t';
 236             $lib = '../../lib';
 237             $perl = '../../t/perl';
 238             $testswitch = "-I../.. -MTestInit=U2T";
 239             if ($2 eq 'cpan' || $2 eq 'dist') {
 240                 if($abs{$run_dir}) {
 241                     $testswitch = $testswitch . ',A';
 242                 }
 243                 if ($temp_no_core{$run_dir}) {
 244                     $testswitch = $testswitch . ',NC';
 245                 }
 246             }
 247         } elsif ($test =~ m!^\.\./lib!) {
 248             $testswitch = '-I.. -MTestInit=U1'; # -T will remove . from @INC
 249         } else {
 250             $testswitch = '-I.. -MTestInit';  # -T will remove . from @INC
 251         }
 252     }
 253
 254     my $utf8 = ($::with_utf8 || $::with_utf16) ? "-I$lib -Mutf8" : '';
 255
 256     my %options = (
 257         perl => $perl,
 258         lib => $lib,
 259         test => $test,
 260         run_dir => $run_dir,
 261         return_dir => $return_dir,
 262         testswitch => $testswitch,
 263         utf8 => $utf8,
 264         file => $file_opts,
 265         switch => $switch,
 266     );
 267
 268     return \%options;
 269 }
 270
 271 sub _cmd {
 272     my($options, $type) = @_;
 273
 274     my $test = $options->{test};
 275
 276     my $cmd;
 277     if ($type eq 'deparse') {
 278         my $perl = "$options->{perl} $options->{testswitch}";
 279         my $lib = $options->{lib};
 280
 281         $cmd = (
 282           "$perl $options->{switch} -I$lib -MO=-qq,Deparse,-sv1.,".
 283           "-l$::deparse_opts$options->{file} ".
 284           "$test > $test.dp ".
 285           "&& $perl $options->{switch} -I$lib $test.dp"
 286         );
 287     }
 288     elsif ($type eq 'perl') {
 289         my $perl = $options->{perl};
 290         my $redir = $^O eq 'VMS' ? '2>&1' : '';
 291
 292         if ($ENV{PERL_VALGRIND}) {
 293             my $perl_supp = $options->{return_dir} ? "$options->{return_dir}/perl.supp" : "perl.supp";
 294             my $valgrind_exe = $ENV{VALGRIND} // 'valgrind';
 295             my $vg_opts = $ENV{VG_OPTS}
 296               // '--log-fd=3 '
 297                   . "--suppressions=$perl_supp --leak-check=yes "
 298                   . "--leak-resolution=high --show-reachable=yes "
 299                   . "--num-callers=50 --track-origins=yes";
 300             $perl = "$valgrind_exe $vg_opts $perl";
 301             $redir = "3>$Valgrind_Log";
 302             if ($options->{run_dir}) {
 303                 $Valgrind_Log = "$options->{run_dir}/$Valgrind_Log";
 304             }
 305         }
 306
 307         my $args = "$options->{testswitch} $options->{switch} $options->{utf8}";
 308         $cmd = $perl . _quote_args($args) . " $test $redir";
 309     }
 310     return $cmd;
 311 }
 312
 313 sub _before_fork {
 314     my ($options) = @_;
 315
 316     if ($options->{run_dir}) {
 317         my $run_dir = $options->{run_dir};
 318         chdir $run_dir or die "Can't chdir to '$run_dir': $!";
 319     }
 320
 321     return;
 322 }
 323
 324 sub _after_fork {
 325     my ($options) = @_;
 326
 327     if ($options->{return_dir}) {
 328         my $return_dir = $options->{return_dir};
 329         chdir $return_dir
 330            or die "Can't chdir from '$options->{run_dir}' to '$return_dir': $!";
 331     }
 332
 333     return;
 334 }
 335
 336 sub _run_test {
 337     my ($test, $type) = @_;
 338
 339     my $options = _scan_test($test, $type);
 340     # $test might have changed if we're in ext/Foo, so don't use it anymore
 341     # from now on. Use $options->{test} instead.
 342
 343     _before_fork($options);
 344
 345     my $cmd = _cmd($options, $type);
 346
 347     open(my $results, "$cmd |") or print "can't run '$cmd': $!.\n";
 348
 349     _after_fork($options);
 350
 351     # Our environment may force us to use UTF-8, but we can't be sure that
 352     # anything we're reading from will be generating (well formed) UTF-8
 353     # This may not be the best way - possibly we should unset ${^OPEN} up
 354     # top?
 355     binmode $results;
 356
 357     return $results;
 358 }
 359
 360 sub _quote_args {
 361     my ($args) = @_;
 362     my $argstring = '';
 363
 364     foreach (split(/\s+/,$args)) {
 365        # In VMS protect with doublequotes because otherwise
 366        # DCL will lowercase -- unless already doublequoted.
 367        $_ = q(").$_.q(") if ($^O eq 'VMS') && !/^\"/ && length($_) > 0;
 368        $argstring = $argstring . ' ' . $_;
 369     }
 370     return $argstring;
 371 }
 372
 373 sub _populate_hash {
 374     return unless defined $_[0];
 375     return map {$_, 1} split /\s+/, $_[0];
 376 }
 377
 378 sub _tests_from_manifest {
 379     my ($extensions, $known_extensions) = @_;
 380     my %skip;
 381     my %extensions = _populate_hash($extensions);
 382     my %known_extensions = _populate_hash($known_extensions);
 383
 384     foreach (keys %known_extensions) {
 385         $skip{$_} = 1 unless $extensions{$_};
 386     }
 387
 388     my @results;
 389     my $mani = '../MANIFEST';
 390     if (open(MANI, $mani)) {
 391         while (<MANI>) {
 392             if (m!^((?:cpan|dist|ext)/(\S+)/+(?:[^/\s]+\.t|test\.pl)|lib/\S+?(?:\.t|test\.pl))\s!) {
 393                 my $t = $1;
 394                 my $extension = $2;
 395                 if (!$::core || $t =~ m!^lib/[a-z]!) {
 396                     if (defined $extension) {
 397                         $extension =~ s!/t(:?/\S+)*$!!;
 398                         # XXX Do I want to warn that I'm skipping these?
 399                         next if $skip{$extension};
 400                         my $flat_extension = $extension;
 401                         $flat_extension =~ s!-!/!g;
 402                         next if $skip{$flat_extension}; # Foo/Bar may live in Foo-Bar
 403                     }
 404                     my $path = "../$t";
 405                     push @results, $path;
 406                     $::path_to_name{$path} = $t;
 407                 }
 408             }
 409         }
 410         close MANI;
 411     } else {
 412         warn "$0: cannot open $mani: $!\n";
 413     }
 414     return @results;
 415 }
 416
 417 unless (@ARGV) {
 418     # base first, as TEST bails out if that can't run
 419     # then comp, to validate that require works
 420     # then run, to validate that -M works
 421     # then we know we can -MTestInit for everything else, making life simpler
 422     foreach my $dir (qw(base comp run cmd io re op uni mro)) {
 423         _find_tests($dir);
 424     }
 425     _find_tests("lib") unless $::core;
 426     # Config.pm may be broken for make minitest. And this is only a refinement
 427     # for skipping tests on non-default builds, so it is allowed to fail.
 428     # What we want to to is make a list of extensions which we did not build.
 429     my $configsh = '../config.sh';
 430     my ($extensions, $known_extensions);
 431     if (-f $configsh) {
 432         open FH, $configsh or die "Can't open $configsh: $!";
 433         while (<FH>) {
 434             if (/^extensions=['"](.*)['"]$/) {
 435                 $extensions = $1;
 436             }
 437             elsif (/^known_extensions=['"](.*)['"]$/) {
 438                 $known_extensions = $1;
 439             }
 440         }
 441         if (!defined $known_extensions) {
 442             warn "No known_extensions line found in $configsh";
 443         }
 444         if (!defined $extensions) {
 445             warn "No extensions line found in $configsh";
 446         }
 447     }
 448     # The "complex" constructions of list return from a subroutine, and push of
 449     # a list, might fail if perl is really hosed, but they aren't needed for
 450     # make minitest, and the building of extensions will likely also fail if
 451     # something is that badly wrong.
 452     push @ARGV, _tests_from_manifest($extensions, $known_extensions);
 453     unless ($::core) {
 454         _find_tests('x2p');
 455         _find_tests('porting');
 456         _find_tests('japh') if $::torture;
 457         _find_tests('t/benchmark') if $::benchmark or $ENV{PERL_BENCHMARK};
 458     }
 459 }
 460
 461 if ($::deparse) {
 462     _testprogs('deparse', '',   @ARGV);
 463 }
 464 elsif ($::with_utf16) {
 465     for my $e (0, 1) {
 466         for my $b (0, 1) {
 467             print STDERR "# ENDIAN $e BOM $b\n";
 468             my @UARGV;
 469             for my $a (@ARGV) {
 470                 my $u = $a . "." . ($e ? "l" : "b") . "e" . ($b ? "b" : "");
 471                 my $f = $e ? "v" : "n";
 472                 push @UARGV, $u;
 473                 unlink($u);
 474                 if (open(A, $a)) {
 475                     if (open(U, ">$u")) {
 476                         print U pack("$f", 0xFEFF) if $b;
 477                         while (<A>) {
 478                             print U pack("$f*", unpack("C*", $_));
 479                         }
 480                         close(U);
 481                     }
 482                     close(A);
 483                 }
 484             }
 485             _testprogs('perl', '', @UARGV);
 486             unlink(@UARGV);
 487         }
 488     }
 489 }
 490 else {
 491     _testprogs('perl',    '',   @ARGV);
 492 }
 493
 494 sub _testprogs {
 495     my ($type, $args, @tests) = @_;
 496
 497     print <<'EOT' if ($type eq 'deparse');
 498 ------------------------------------------------------------------------------
 499 TESTING DEPARSER
 500 ------------------------------------------------------------------------------
 501 EOT
 502
 503     $::bad_files = 0;
 504
 505     foreach my $t (@tests) {
 506       unless (exists $::path_to_name{$t}) {
 507         my $tname = "t/$t";
 508         $::path_to_name{$t} = $tname;
 509       }
 510     }
 511     my $maxlen = 0;
 512     foreach (@::path_to_name{@tests}) {
 513         s/\.\w+\z/ /; # space gives easy doubleclick to select fname
 514         my $len = length ;
 515         $maxlen = $len if $len > $maxlen;
 516     }
 517     # + 3 : we want three dots between the test name and the "ok"
 518     my $dotdotdot = $maxlen + 3 ;
 519     my $grind_ct = 0;           # count of non-empty valgrind reports
 520     my $total_files = @tests;
 521     my $good_files = 0;
 522     my $tested_files  = 0;
 523     my $totmax = 0;
 524     my %failed_tests;
 525
 526     while (my $test = shift @tests) {
 527         my ($test_start_time, @starttimes) = 0;
 528         if ($show_elapsed_time) {
 529             $test_start_time = Time::HiRes::time();
 530             # times() reports usage by TEST, but we want usage of each
 531             # testprog it calls, so record accumulated times now,
 532             # subtract them out afterwards.  Ideally, we'd take times
 533             # in BEGIN/END blocks (giving better visibility of self vs
 534             # children of each testprog), but that would require some
 535             # IPC to send results back here, or a completely different
 536             # collection scheme (Storable isnt tuned for incremental use)
 537             @starttimes = times;
 538         }
 539         if ($test =~ /^$/) {
 540             next;
 541         }
 542         if ($type eq 'deparse') {
 543             if ($test eq "comp/redef.t") {
 544                 # Redefinition happens at compile time
 545                 next;
 546             }
 547             elsif ($test =~ m{lib/Switch/t/}) {
 548                 # B::Deparse doesn't support source filtering
 549                 next;
 550             }
 551         }
 552         my $te = $::path_to_name{$test} . '.'
 553                     x ($dotdotdot - length($::path_to_name{$test})) .' ';
 554
 555         if ($^O ne 'VMS') {  # defer printing on VMS due to piping bug
 556             print $te;
 557             $te = '';
 558         }
 559
 560         (local $Valgrind_Log = "$test.valgrind-current") =~ s/^.*\///;
 561         my $results = _run_test($test, $type);
 562
 563         my $failure;
 564         my $next = 0;
 565         my $seen_leader = 0;
 566         my $seen_ok = 0;
 567         my $trailing_leader = 0;
 568         my $max;
 569         my %todo;
 570         while (<$results>) {
 571             next if /^\s*$/; # skip blank lines
 572             if (/^1..$/ && ($^O eq 'VMS')) {
 573                 # VMS pipe bug inserts blank lines.
 574                 my $l2 = <RESULTS>;
 575                 if ($l2 =~ /^\s*$/) {
 576                     $l2 = <RESULTS>;
 577                 }
 578                 $_ = '1..' . $l2;
 579             }
 580             if ($::verbose) {
 581                 print $_;
 582             }
 583             unless (/^\#/) {
 584                 if ($trailing_leader) {
 585                     # shouldn't be anything following a postfix 1..n
 586                     $failure = 'FAILED--extra output after trailing 1..n';
 587                     last;
 588                 }
 589                 if (/^1\.\.([0-9]+)( todo ([\d ]+))?/) {
 590                     if ($seen_leader) {
 591                         $failure = 'FAILED--seen duplicate leader';
 592                         last;
 593                     }
 594                     $max = $1;
 595                     %todo = map { $_ => 1 } split / /, $3 if $3;
 596                     $totmax = $totmax + $max;
 597                     $tested_files = $tested_files + 1;
 598                     if ($seen_ok) {
 599                         # 1..n appears at end of file
 600                         $trailing_leader = 1;
 601                         if ($next != $max) {
 602                             $failure = "FAILED--expected $max tests, saw $next";
 603                             last;
 604                         }
 605                     }
 606                     else {
 607                         $next = 0;
 608                     }
 609                     $seen_leader = 1;
 610                 }
 611                 else {
 612                     if (/^(not )?ok(?: (\d+))?[^\#]*(\s*\#.*)?/) {
 613                         unless ($seen_leader) {
 614                             unless ($seen_ok) {
 615                                 $next = 0;
 616                             }
 617                         }
 618                         $seen_ok = 1;
 619                         $next = $next + 1;
 620                         my($not, $num, $extra, $istodo) = ($1, $2, $3, 0);
 621                         $num = $next unless $num;
 622
 623                         if ($num == $next) {
 624
 625                             # SKIP is essentially the same as TODO for t/TEST
 626                             # this still conforms to TAP:
 627                             # http://testanything.org/wiki/index.php/TAP_specification
 628                             $extra and $istodo = $extra =~ /#\s*(?:TODO|SKIP)\b/;
 629                             $istodo = 1 if $todo{$num};
 630
 631                             if( $not && !$istodo ) {
 632                                 $failure = "FAILED at test $num";
 633                                 last;
 634                             }
 635                         }
 636                         else {
 637                             $failure ="FAILED--expected test $next, saw test $num";
 638                             last;
 639                         }
 640                     }
 641                     elsif (/^Bail out!\s*(.*)/i) { # magic words
 642                         die "FAILED--Further testing stopped" . ($1 ? ": $1\n" : ".\n");
 643                     }
 644                     else {
 645                         # module tests are allowed extra output,
 646                         # because Test::Harness allows it
 647                         next if $test =~ /^\W*(cpan|dist|ext|lib)\b/;
 648                         $failure = "FAILED--unexpected output at test $next";
 649                         last;
 650                     }
 651                 }
 652             }
 653         }
 654         close $results;
 655
 656         if (not defined $failure) {
 657             $failure = 'FAILED--no leader found' unless $seen_leader;
 658         }
 659
 660         if ($ENV{PERL_VALGRIND}) {
 661             my $toolnm = $ENV{VALGRIND};
 662             $toolnm =~ s|.*/||;  # keep basename
 663             my @valgrind;       # gets content of file
 664             if (-e $Valgrind_Log) {
 665                 if (open(V, $Valgrind_Log)) {
 666                     @valgrind = <V>;
 667                     close V;
 668                 } else {
 669                     warn "$0: Failed to open '$Valgrind_Log': $!\n";
 670                 }
 671             }
 672             if ($ENV{VG_OPTS} =~ /(cachegrind)/ or $toolnm =~ /(perf)/) {
 673                 $toolnm = $1;
 674                 if ($toolnm eq 'perf') {
 675                     # append perfs subcommand, not just stat
 676                     my ($sub) = split /\s/, $ENV{VG_OPTS};
 677                     $toolnm .= "-$sub";
 678                 }
 679                 if (rename $Valgrind_Log, "$test.$toolnm") {
 680                     $grind_ct++;
 681                 } else {
 682                     warn "$0: Failed to create '$test.$toolnm': $!\n";
 683                 }
 684             }
 685             elsif (@valgrind) {
 686                 my $leaks = 0;
 687                 my $errors = 0;
 688                 for my $i (0..$#valgrind) {
 689                     local $_ = $valgrind[$i];
 690                     if (/^==\d+== ERROR SUMMARY: (\d+) errors? /) {
 691                         $errors = $errors + $1;   # there may be multiple error summaries
 692                     } elsif (/^==\d+== LEAK SUMMARY:/) {
 693                         for my $off (1 .. 4) {
 694                             if ($valgrind[$i+$off] =~
 695                                 /(?:lost|reachable):\s+\d+ bytes in (\d+) blocks/) {
 696                                 $leaks = $leaks + $1;
 697                             }
 698                         }
 699                     }
 700                 }
 701                 if ($errors or $leaks) {
 702                     if (rename $Valgrind_Log, "$test.valgrind") {
 703                         $grind_ct = $grind_ct + 1;
 704                     } else {
 705                         warn "$0: Failed to create '$test.valgrind': $!\n";
 706                     }
 707                 }
 708             } else {
 709                 warn "No valgrind output?\n";
 710             }
 711             if (-e $Valgrind_Log) {
 712                 unlink $Valgrind_Log
 713                     or warn "$0: Failed to unlink '$Valgrind_Log': $!\n";
 714             }
 715         }
 716         if ($type eq 'deparse') {
 717             unlink "./$test.dp";
 718         }
 719         if ($ENV{PERL_3LOG}) {
 720             my $tpp = $test;
 721             $tpp =~ s:^\.\./::;
 722             $tpp =~ s:/:_:g;
 723             $tpp =~ s:\.t$:.3log:;
 724             rename("perl.3log", $tpp) ||
 725                 die "rename: perl3.log to $tpp: $!\n";
 726         }
 727         if (not defined $failure and $next != $max) {
 728             $failure="FAILED--expected $max tests, saw $next";
 729         }
 730
 731         if( !defined $failure  # don't mask a test failure
 732             and $? )
 733         {
 734             $failure = "FAILED--non-zero wait status: $?";
 735         }
 736
 737         if (defined $failure) {
 738             print "${te}$failure\n";
 739             $::bad_files = $::bad_files + 1;
 740             if ($test =~ /^base/) {
 741                 die "Failed a basic test ($test) -- cannot continue.\n";
 742             }
 743             $failed_tests{$test} = 1;
 744         }
 745         else {
 746             if ($max) {
 747                 my ($elapsed, $etms) = ("", 0);
 748                 if ( $show_elapsed_time ) {
 749                     $etms = (Time::HiRes::time() - $test_start_time) * 1000;
 750                     $elapsed = sprintf(" %8.0f ms", $etms);
 751
 752                     my (@endtimes) = times;
 753                     $endtimes[$_] -= $starttimes[$_] for 0..$#endtimes;
 754                     splice @endtimes, 0, 2;    # drop self/harness times
 755                     $_ *= 1000 for @endtimes;  # and scale to ms
 756                     $timings{$test} = [$etms,@endtimes];
 757                     $elapsed .= sprintf(" %5.0f ms", $_) for @endtimes;
 758                 }
 759                 print "${te}ok$elapsed\n";
 760                 $good_files = $good_files + 1;
 761             }
 762             else {
 763                 print "${te}skipped\n";
 764                 $tested_files = $tested_files - 1;
 765             }
 766         }
 767     } # while tests
 768
 769     if ($::bad_files == 0) {
 770         if ($good_files) {
 771             print "All tests successful.\n";
 772             # XXX add mention of 'perlbug -ok' ?
 773         }
 774         else {
 775             die "FAILED--no tests were run for some reason.\n";
 776         }
 777     }
 778     else {
 779         my $pct = $tested_files ? sprintf("%.2f", ($tested_files - $::bad_files) / $tested_files * 100) : "0.00";
 780         my $s = $::bad_files == 1 ? "" : "s";
 781         warn "Failed $::bad_files test$s out of $tested_files, $pct% okay.\n";
 782         for my $test ( sort keys %failed_tests ) {
 783             print "\t$test\n";
 784         }
 785         warn <<'SHRDLU_1';
 786 ### Since not all tests were successful, you may want to run some of
 787 ### them individually and examine any diagnostic messages they produce.
 788 ### See the INSTALL document's section on "make test".
 789 SHRDLU_1
 790         warn <<'SHRDLU_2' if $good_files / $total_files > 0.8;
 791 ### You have a good chance to get more information by running
 792 ###   ./perl harness
 793 ### in the 't' directory since most (>=80%) of the tests succeeded.
 794 SHRDLU_2
 795         if (eval {require Config; import Config; 1}) {
 796             if ($::Config{usedl} && (my $p = $::Config{ldlibpthname})) {
 797                 warn <<SHRDLU_3;
 798 ### You may have to set your dynamic library search path,
 799 ### $p, to point to the build directory:
 800 SHRDLU_3
 801                 if (exists $ENV{$p} && $ENV{$p} ne '') {
 802                     warn <<SHRDLU_4a;
 803 ###   setenv $p `pwd`:\$$p; cd t; ./perl harness
 804 ###   $p=`pwd`:\$$p; export $p; cd t; ./perl harness
 805 ###   export $p=`pwd`:\$$p; cd t; ./perl harness
 806 SHRDLU_4a
 807                 } else {
 808                     warn <<SHRDLU_4b;
 809 ###   setenv $p `pwd`; cd t; ./perl harness
 810 ###   $p=`pwd`; export $p; cd t; ./perl harness
 811 ###   export $p=`pwd`; cd t; ./perl harness
 812 SHRDLU_4b
 813                 }
 814                 warn <<SHRDLU_5;
 815 ### for csh-style shells, like tcsh; or for traditional/modern
 816 ### Bourne-style shells, like bash, ksh, and zsh, respectively.
 817 SHRDLU_5
 818             }
 819         }
 820     }
 821     my ($user,$sys,$cuser,$csys) = times;
 822     my $tot = sprintf("u=%.2f  s=%.2f  cu=%.2f  cs=%.2f  scripts=%d  tests=%d",
 823                       $user,$sys,$cuser,$csys,$tested_files,$totmax);
 824     print "$tot\n";
 825     if ($good_files) {
 826         if (-d $show_elapsed_time) {
 827             # HARNESS_TIMER = <a-directory>.  Save timings etc to
 828             # storable file there.  NB: the test cds to ./t/, so
 829             # relative path must account for that, ie ../../perf
 830             # points to dir next to source tree.
 831             require Storable;
 832             my @dt = localtime;
 833             $dt[5] += 1900; $dt[4] += 1; # fix year, month
 834             my $fn = "$show_elapsed_time/".join('-', @dt[5,4,3,2,1]).".ttimes";
 835             Storable::store({ perf => \%timings,
 836                               gather_conf_platform_info(),
 837                               total => $tot,
 838                             }, $fn);
 839             print "wrote storable file: $fn\n";
 840         }
 841     }
 842     if ($ENV{PERL_VALGRIND}) {
 843         my $s = $grind_ct == 1 ? '' : 's';
 844         print "$grind_ct valgrind report$s created.\n", ;
 845     }
 846 }
 847 exit ($::bad_files != 0);
 848
 849 # Collect platform, config data that should allow comparing
 850 # performance data between different machines.  With enough data,
 851 # and/or clever statistical analysis, it should be possible to
 852 # determine the effect of config choices, more memory, etc
 853
 854 sub gather_conf_platform_info {
 855     # currently rather quick & dirty, and subject to change
 856     # for both content and format.
 857     require Config;
 858     my (%conf, @platform) = ();
 859     $conf{$_} = $Config::Config{$_} for
 860         grep /cc|git|config_arg\d+/, keys %Config::Config;
 861     if (-f '/proc/cpuinfo') {
 862         open my $fh, '/proc/cpuinfo' or warn "$!: /proc/cpuinfo\n";
 863         @platform = grep /name|cpu/, <$fh>;
 864         chomp $_ for @platform;
 865     }
 866     unshift @platform, $^O;
 867
 868     return (
 869         conf => \%conf,
 870         platform => {cpu => \@platform,
 871                      mem => [ grep s/\s+/ /,
 872                               grep chomp, `free` ],
 873                      load => [ grep chomp, `uptime` ],
 874         },
 875         host => (grep chomp, `hostname -f`),
 876         version => '0.03', # bump for conf, platform, or data collection changes
 877         );
 878 }
 879
 880 # ex: set ts=8 sts=4 sw=4 noet: