This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
In TestInit, eliminate @new_inc, by assigning to @INC directly.
[perl5.git] / TestInit.pm
1 # This is a replacement for the old BEGIN preamble which heads (or
2 # should head) up every core test program to prepare it for running.
3 # Now instead of:
4 #
5 # BEGIN {
6 #   chdir 't' if -d 't';
7 #   @INC = '../lib';
8 # }
9 #
10 # Its primary purpose is to clear @INC so core tests don't pick up
11 # modules from an installed Perl.
12 #
13 # t/TEST will use -MTestInit.  You may "use TestInit" in the test
14 # programs but it is not required.
15 #
16 # P.S. This documentation is not in POD format in order to avoid
17 # problems when there are fundamental bugs in perl.
18
19 package TestInit;
20
21 $VERSION = 1.04;
22
23 # Let tests know they're running in the perl core.  Useful for modules
24 # which live dual lives on CPAN.
25 # Don't interfere with the taintedness of %ENV, this could perturbate tests.
26 # This feels like a better solution than the original, from
27 # http://www.xray.mpe.mpg.de/mailing-lists/perl5-porters/2003-07/msg00154.html
28 $ENV{PERL_CORE} = $^X;
29
30 sub import {
31     my $self = shift;
32     my @up_2_t = ('../../lib', '../../t');
33     my ($abs, $chdir, $setopt);
34     foreach (@_) {
35         if ($_ eq 'U2T') {
36             @INC = @up_2_t;
37             $setopt = 1;
38         } elsif ($_ eq 'U1') {
39             @INC = '../lib';
40             $setopt = 1;
41         } elsif ($_ eq 'NC') {
42             delete $ENV{PERL_CORE}
43         } elsif ($_ eq 'A') {
44             $abs = 1;
45         } elsif ($_ eq 'T') {
46             $chdir = '..'
47                 unless -f 't/TEST' && -f 'MANIFEST' && -d 'lib' && -d 'ext';
48             @INC = 'lib';
49             $setopt = 1;
50         } else {
51             die "Unknown option '$_'";
52         }
53     }
54
55     # Need to default. This behaviour is consistent with previous behaviour,
56     # as the equivalent of this code used to be run at the top level, hence
57     # would happen (unconditionally) before import() was called.
58     unless ($setopt) {
59         if (-f 't/TEST' && -f 'MANIFEST' && -d 'lib' && -d 'ext') {
60             # We're being run from the top level. Try to change directory, and
61             # set things up correctly. This is a 90% solution, but for
62             # hand-running tests, that's good enough
63             if ($0 =~ s!^((?:ext|dist|cpan)[\\/][^\\/]+)[\//](.*\.t)$!$2!) {
64                 # Looks like a test in ext.
65                 $chdir = $1;
66                 @INC = @up_2_t;
67                 $setopt = 1;
68                 $^X =~ s!^\.([/\\])!..$1..$1!;
69             } else {
70                 $chdir = 't';
71                 @INC = '../lib';
72                 $setopt = $0 =~ m!^lib/!;
73             }
74         } else {
75             # (likely) we're being run by t/TEST or t/harness, and we're a test
76             # in t/
77             @INC = '../lib';
78         }
79     }
80
81     if (defined $chdir) {
82         chdir $chdir or die "Can't chdir '$chdir': $!";
83     }
84
85     if ($abs) {
86         require File::Spec::Functions;
87         # Forcibly untaint this.
88         @INC = map { $_ = File::Spec::Functions::rel2abs($_); /(.*)/; $1 } @INC;
89         $^X = File::Spec::Functions::rel2abs($^X);
90     }
91
92     if ($setopt) {
93         my $sep;
94         if ($^O eq 'VMS') {
95             $sep = '|';
96         } elsif ($^O eq 'MSWin32') {
97             $sep = ';';
98         } else {
99             $sep = ':';
100         }
101
102         my $lib = join $sep, @INC;
103         if (exists $ENV{PERL5LIB}) {
104             $ENV{PERL5LIB} = $lib . substr $ENV{PERL5LIB}, 0, 0;
105         } else {
106             $ENV{PERL5LIB} = $lib;
107         }
108     }
109
110     push @INC, '.' unless ${^TAINT};
111 }
112
113 $0 =~ s/\.dp$//; # for the test.deparse make target
114 1;