ext/POSIX/lib/POSIX.pm

   1 package POSIX;
   2 use strict;
   3 use warnings;
   4
   5 our ($AUTOLOAD, %SIGRT);
   6
   7 our $VERSION = '1.48';
   8
   9 require XSLoader;
  10
  11 use Fcntl qw(FD_CLOEXEC F_DUPFD F_GETFD F_GETFL F_GETLK F_RDLCK F_SETFD
  12              F_SETFL F_SETLK F_SETLKW F_UNLCK F_WRLCK O_ACCMODE O_APPEND
  13              O_CREAT O_EXCL O_NOCTTY O_NONBLOCK O_RDONLY O_RDWR O_TRUNC
  14              O_WRONLY SEEK_CUR SEEK_END SEEK_SET
  15              S_ISBLK S_ISCHR S_ISDIR S_ISFIFO S_ISREG
  16              S_IRGRP S_IROTH S_IRUSR S_IRWXG S_IRWXO S_IRWXU S_ISGID S_ISUID
  17              S_IWGRP S_IWOTH S_IWUSR S_IXGRP S_IXOTH S_IXUSR);
  18
  19 my $loaded;
  20
  21 sub import {
  22     my $pkg = shift;
  23
  24     load_imports() unless $loaded++;
  25
  26     # Grandfather old foo_h form to new :foo_h form
  27     s/^(?=\w+_h$)/:/ for my @list = @_;
  28
  29     local $Exporter::ExportLevel = 1;
  30     Exporter::import($pkg,@list);
  31 }
  32
  33 sub croak { require Carp;  goto &Carp::croak }
  34 sub usage { croak "Usage: POSIX::$_[0]" }
  35
  36 XSLoader::load();
  37
  38 my %replacement = (
  39     atexit      => 'END {}',
  40     atof        => undef,
  41     atoi        => undef,
  42     atol        => undef,
  43     bsearch     => \'not supplied',
  44     calloc      => undef,
  45     clearerr    => 'IO::Handle::clearerr',
  46     div         => '/, % and int',
  47     execl       => undef,
  48     execle      => undef,
  49     execlp      => undef,
  50     execv       => undef,
  51     execve      => undef,
  52     execvp      => undef,
  53     fclose      => 'IO::Handle::close',
  54     fdopen      => 'IO::Handle::new_from_fd',
  55     feof        => 'IO::Handle::eof',
  56     ferror      => 'IO::Handle::error',
  57     fflush      => 'IO::Handle::flush',
  58     fgetc       => 'IO::Handle::getc',
  59     fgetpos     => 'IO::Seekable::getpos',
  60     fgets       => 'IO::Handle::gets',
  61     fileno      => 'IO::Handle::fileno',
  62     fopen       => 'IO::File::open',
  63     fprintf     => 'printf',
  64     fputc       => 'print',
  65     fputs       => 'print',
  66     fread       => 'read',
  67     free        => undef,
  68     freopen     => 'open',
  69     fscanf      => '<> and regular expressions',
  70     fseek       => 'IO::Seekable::seek',
  71     fsetpos     => 'IO::Seekable::setpos',
  72     fsync       => 'IO::Handle::sync',
  73     ftell       => 'IO::Seekable::tell',
  74     fwrite      => 'print',
  75     labs        => 'abs',
  76     ldiv        => '/, % and int',
  77     longjmp     => 'die',
  78     malloc      => undef,
  79     memchr      => 'index()',
  80     memcmp      => 'eq',
  81     memcpy      => '=',
  82     memmove     => '=',
  83     memset      => 'x',
  84     offsetof    => undef,
  85     putc        => 'print',
  86     putchar     => 'print',
  87     puts        => 'print',
  88     qsort       => 'sort',
  89     rand        => \'non-portable, use Perl\'s rand instead',
  90     realloc     => undef,
  91     scanf       => '<> and regular expressions',
  92     setbuf      => 'IO::Handle::setbuf',
  93     setjmp      => 'eval {}',
  94     setvbuf     => 'IO::Handle::setvbuf',
  95     siglongjmp  => 'die',
  96     sigsetjmp   => 'eval {}',
  97     srand       => \'not supplied; refer to Perl\'s srand documentation',
  98     sscanf      => 'regular expressions',
  99     strcat      => '.=',
 100     strchr      => 'index()',
 101     strcmp      => 'eq',
 102     strcpy      => '=',
 103     strcspn     => 'regular expressions',
 104     strlen      => 'length',
 105     strncat     => '.=',
 106     strncmp     => 'eq',
 107     strncpy     => '=',
 108     strpbrk     => undef,
 109     strrchr     => 'rindex()',
 110     strspn      => undef,
 111     strtok      => undef,
 112     tmpfile     => 'IO::File::new_tmpfile',
 113     ungetc      => 'IO::Handle::ungetc',
 114     vfprintf    => undef,
 115     vprintf     => undef,
 116     vsprintf    => undef,
 117 );
 118
 119 my %reimpl = (
 120     assert    => 'expr => croak "Assertion failed" if !$_[0]',
 121     tolower   => 'string => lc($_[0])',
 122     toupper   => 'string => uc($_[0])',
 123     closedir  => 'dirhandle => CORE::closedir($_[0])',
 124     opendir   => 'directory => my $dh; CORE::opendir($dh, $_[0]) ? $dh : undef',
 125     readdir   => 'dirhandle => CORE::readdir($_[0])',
 126     rewinddir => 'dirhandle => CORE::rewinddir($_[0])',
 127     errno     => '$! + 0',
 128     creat     => 'filename, mode => &open($_[0], &O_WRONLY | &O_CREAT | &O_TRUNC, $_[1])',
 129     fcntl     => 'filehandle, cmd, arg => CORE::fcntl($_[0], $_[1], $_[2])',
 130     getgrgid  => 'gid => CORE::getgrgid($_[0])',
 131     getgrnam  => 'name => CORE::getgrnam($_[0])',
 132     atan2     => 'x, y => CORE::atan2($_[0], $_[1])',
 133     cos       => 'x => CORE::cos($_[0])',
 134     exp       => 'x => CORE::exp($_[0])',
 135     fabs      => 'x => CORE::abs($_[0])',
 136     log       => 'x => CORE::log($_[0])',
 137     pow       => 'x, exponent => $_[0] ** $_[1]',
 138     sin       => 'x => CORE::sin($_[0])',
 139     sqrt      => 'x => CORE::sqrt($_[0])',
 140     getpwnam  => 'name => CORE::getpwnam($_[0])',
 141     getpwuid  => 'uid => CORE::getpwuid($_[0])',
 142     kill      => 'pid, sig => CORE::kill $_[1], $_[0]',
 143     raise     => 'sig => CORE::kill $_[0], $$;  # Is this good enough',
 144     getc      => 'handle => CORE::getc($_[0])',
 145     getchar   => 'CORE::getc(STDIN)',
 146     gets      => 'scalar <STDIN>',
 147     remove    => 'filename => (-d $_[0]) ? CORE::rmdir($_[0]) : CORE::unlink($_[0])',
 148     rename    => 'oldfilename, newfilename => CORE::rename($_[0], $_[1])',
 149     rewind    => 'filehandle => CORE::seek($_[0],0,0)',
 150     abs       => 'x => CORE::abs($_[0])',
 151     exit      => 'status => CORE::exit($_[0])',
 152     getenv    => 'name => $ENV{$_[0]}',
 153     system    => 'command => CORE::system($_[0])',
 154     strerror  => 'errno => local $! = $_[0]; "$!"',
 155     strstr    => 'big, little => CORE::index($_[0], $_[1])',
 156     chmod     => 'mode, filename => CORE::chmod($_[0], $_[1])',
 157     fstat     => 'fd => CORE::open my $dup, "<&", $_[0]; CORE::stat($dup)', # Gross.
 158     mkdir     => 'directoryname, mode => CORE::mkdir($_[0], $_[1])',
 159     stat      => 'filename => CORE::stat($_[0])',
 160     umask     => 'mask => CORE::umask($_[0])',
 161     wait      => 'CORE::wait()',
 162     waitpid   => 'pid, options => CORE::waitpid($_[0], $_[1])',
 163     gmtime    => 'time => CORE::gmtime($_[0])',
 164     localtime => 'time => CORE::localtime($_[0])',
 165     time      => 'CORE::time',
 166     alarm     => 'seconds => CORE::alarm($_[0])',
 167     chdir     => 'directory => CORE::chdir($_[0])',
 168     chown     => 'uid, gid, filename => CORE::chown($_[0], $_[1], $_[2])',
 169     fork      => 'CORE::fork',
 170     getegid   => '$) + 0',
 171     geteuid   => '$> + 0',
 172     getgid    => '$( + 0',
 173     getgroups => 'my %seen; grep !$seen{$_}++, split " ", $)',
 174     getlogin  => 'CORE::getlogin()',
 175     getpgrp   => 'CORE::getpgrp',
 176     getpid    => '$$',
 177     getppid   => 'CORE::getppid',
 178     getuid    => '$<',
 179     isatty    => 'filehandle => -t $_[0]',
 180     link      => 'oldfilename, newfilename => CORE::link($_[0], $_[1])',
 181     rmdir     => 'directoryname => CORE::rmdir($_[0])',
 182     unlink    => 'filename => CORE::unlink($_[0])',
 183     utime     => 'filename, atime, mtime => CORE::utime($_[1], $_[2], $_[0])',
 184 );
 185
 186 eval join ';', map "sub $_", keys %replacement, keys %reimpl;
 187
 188 sub AUTOLOAD {
 189     my ($func) = ($AUTOLOAD =~ /.*::(.*)/);
 190
 191     die "POSIX.xs has failed to load\n" if $func eq 'constant';
 192
 193     if (my $code = $reimpl{$func}) {
 194         my ($num, $arg) = (0, '');
 195         if ($code =~ s/^(.*?) *=> *//) {
 196             $arg = $1;
 197             $num = 1 + $arg =~ tr/,//;
 198         }
 199         # no warnings to be consistent with the old implementation, where each
 200         # function was in its own little AutoSplit world:
 201         eval qq{ sub $func {
 202                 no warnings;
 203                 usage "$func($arg)" if \@_ != $num;
 204                 $code
 205             } };
 206         no strict;
 207         goto &$AUTOLOAD;
 208     }
 209     if (exists $replacement{$func}) {
 210         my $how = $replacement{$func};
 211         croak "Unimplemented: POSIX::$func() is C-specific, stopped"
 212             unless defined $how;
 213         croak "Unimplemented: POSIX::$func() is $$how" if ref $how;
 214         croak "Use method $how() instead of POSIX::$func()" if $how =~ /::/;
 215         croak "Unimplemented: POSIX::$func() is C-specific: use $how instead";
 216     }
 217
 218     constant($func);
 219 }
 220
 221 sub perror {
 222     print STDERR "@_: " if @_;
 223     print STDERR $!,"\n";
 224 }
 225
 226 sub printf {
 227     usage "printf(pattern, args...)" if @_ < 1;
 228     CORE::printf STDOUT @_;
 229 }
 230
 231 sub sprintf {
 232     usage "sprintf(pattern, args...)" if @_ == 0;
 233     CORE::sprintf(shift,@_);
 234 }
 235
 236 sub load_imports {
 237 our %EXPORT_TAGS = (
 238
 239     assert_h => [qw(assert NDEBUG)],
 240
 241     ctype_h =>  [qw(isalnum isalpha iscntrl isdigit isgraph islower
 242                 isprint ispunct isspace isupper isxdigit tolower toupper)],
 243
 244     dirent_h => [],
 245
 246     errno_h =>  [qw(E2BIG EACCES EADDRINUSE EADDRNOTAVAIL EAFNOSUPPORT EAGAIN
 247                 EALREADY EBADF EBADMSG EBUSY ECANCELED ECHILD ECONNABORTED
 248                 ECONNREFUSED ECONNRESET EDEADLK EDESTADDRREQ EDOM EDQUOT EEXIST
 249                 EFAULT EFBIG EHOSTDOWN EHOSTUNREACH EIDRM EILSEQ EINPROGRESS
 250                 EINTR EINVAL EIO EISCONN EISDIR ELOOP EMFILE EMLINK EMSGSIZE
 251                 ENAMETOOLONG ENETDOWN ENETRESET ENETUNREACH ENFILE ENOBUFS
 252                 ENODATA ENODEV ENOENT ENOEXEC ENOLCK ENOLINK ENOMEM ENOMSG
 253                 ENOPROTOOPT ENOSPC ENOSR ENOSTR ENOSYS ENOTBLK ENOTCONN ENOTDIR
 254                 ENOTEMPTY ENOTRECOVERABLE ENOTSOCK ENOTSUP ENOTTY ENXIO
 255                 EOPNOTSUPP EOTHER EOVERFLOW EOWNERDEAD EPERM EPFNOSUPPORT EPIPE
 256                 EPROCLIM EPROTO EPROTONOSUPPORT EPROTOTYPE ERANGE EREMOTE
 257                 ERESTART EROFS ESHUTDOWN ESOCKTNOSUPPORT ESPIPE ESRCH ESTALE
 258                 ETIME ETIMEDOUT ETOOMANYREFS ETXTBSY EUSERS EWOULDBLOCK EXDEV
 259                 errno)],
 260
 261     fcntl_h =>  [qw(FD_CLOEXEC F_DUPFD F_GETFD F_GETFL F_GETLK F_RDLCK
 262                 F_SETFD F_SETFL F_SETLK F_SETLKW F_UNLCK F_WRLCK
 263                 O_ACCMODE O_APPEND O_CREAT O_EXCL O_NOCTTY O_NONBLOCK
 264                 O_RDONLY O_RDWR O_TRUNC O_WRONLY
 265                 creat
 266                 SEEK_CUR SEEK_END SEEK_SET
 267                 S_IRGRP S_IROTH S_IRUSR S_IRWXG S_IRWXO S_IRWXU
 268                 S_ISBLK S_ISCHR S_ISDIR S_ISFIFO S_ISGID S_ISREG S_ISUID
 269                 S_IWGRP S_IWOTH S_IWUSR)],
 270
 271     fenv_h =>   [qw(FE_DOWNWARD FE_TONEAREST FE_TOWARDZERO FE_UPWARD
 272                     fegetround fesetround)],
 273
 274     float_h =>  [qw(DBL_DIG DBL_EPSILON DBL_MANT_DIG
 275                 DBL_MAX DBL_MAX_10_EXP DBL_MAX_EXP
 276                 DBL_MIN DBL_MIN_10_EXP DBL_MIN_EXP
 277                 FLT_DIG FLT_EPSILON FLT_MANT_DIG
 278                 FLT_MAX FLT_MAX_10_EXP FLT_MAX_EXP
 279                 FLT_MIN FLT_MIN_10_EXP FLT_MIN_EXP
 280                 FLT_RADIX FLT_ROUNDS
 281                 LDBL_DIG LDBL_EPSILON LDBL_MANT_DIG
 282                 LDBL_MAX LDBL_MAX_10_EXP LDBL_MAX_EXP
 283                 LDBL_MIN LDBL_MIN_10_EXP LDBL_MIN_EXP)],
 284
 285     grp_h =>    [],
 286
 287     limits_h => [qw( ARG_MAX CHAR_BIT CHAR_MAX CHAR_MIN CHILD_MAX
 288                 INT_MAX INT_MIN LINK_MAX LONG_MAX LONG_MIN MAX_CANON
 289                 MAX_INPUT MB_LEN_MAX NAME_MAX NGROUPS_MAX OPEN_MAX
 290                 PATH_MAX PIPE_BUF SCHAR_MAX SCHAR_MIN SHRT_MAX SHRT_MIN
 291                 SSIZE_MAX STREAM_MAX TZNAME_MAX UCHAR_MAX UINT_MAX
 292                 ULONG_MAX USHRT_MAX _POSIX_ARG_MAX _POSIX_CHILD_MAX
 293                 _POSIX_LINK_MAX _POSIX_MAX_CANON _POSIX_MAX_INPUT
 294                 _POSIX_NAME_MAX _POSIX_NGROUPS_MAX _POSIX_OPEN_MAX
 295                 _POSIX_PATH_MAX _POSIX_PIPE_BUF _POSIX_SSIZE_MAX
 296                 _POSIX_STREAM_MAX _POSIX_TZNAME_MAX)],
 297
 298     locale_h => [qw(LC_ALL LC_COLLATE LC_CTYPE LC_MESSAGES
 299                     LC_MONETARY LC_NUMERIC LC_TIME NULL
 300                     localeconv setlocale)],
 301
 302     math_h => [qw(FP_ILOGB0 FP_ILOGBNAN FP_INFINITE FP_NAN FP_NORMAL
 303                   FP_SUBNORMAL FP_ZERO HUGE_VAL INFINITY Inf M_1_PI
 304                   M_2_PI M_2_SQRTPI M_E M_LN10 M_LN2 M_LOG10E M_LOG2E M_PI
 305                   M_PI_2 M_PI_4 M_SQRT1_2 M_SQRT2 NAN NaN acos acosh
 306                   asin asinh atan atanh cbrt ceil copysign cosh erf
 307                   erfc exp2 expm1 fabs fdim floor fma fmax fmin fmod
 308                   fpclassify frexp hypot ilogb isfinite isgreater
 309                   isgreaterequal isinf isless islessequal
 310                   islessgreater isnan isnormal isunordered j0 j1 jn
 311                   ldexp lgamma log10 log1p log2 logb lrint modf nan
 312                   nearbyint nextafter nexttoward pow remainder remquo
 313                   rint round scalbn signbit sinh tan tanh tgamma trunc
 314                   y0 y1 yn)],
 315
 316     pwd_h =>    [],
 317
 318     setjmp_h => [qw(longjmp setjmp siglongjmp sigsetjmp)],
 319
 320     signal_h => [qw(SA_NOCLDSTOP SA_NOCLDWAIT SA_NODEFER SA_ONSTACK
 321                 SA_RESETHAND SA_RESTART SA_SIGINFO SIGABRT SIGALRM
 322                 SIGCHLD SIGCONT SIGFPE SIGHUP SIGILL SIGINT SIGKILL
 323                 SIGPIPE %SIGRT SIGRTMIN SIGRTMAX SIGQUIT SIGSEGV SIGSTOP
 324                 SIGTERM SIGTSTP SIGTTIN SIGTTOU SIGUSR1 SIGUSR2 SIGBUS
 325                 SIGPOLL SIGPROF SIGSYS SIGTRAP SIGURG SIGVTALRM SIGXCPU SIGXFSZ
 326                 SIG_BLOCK SIG_DFL SIG_ERR SIG_IGN SIG_SETMASK SIG_UNBLOCK
 327                 raise sigaction signal sigpending sigprocmask sigsuspend)],
 328
 329     stdarg_h => [],
 330
 331     stddef_h => [qw(NULL offsetof)],
 332
 333     stdio_h =>  [qw(BUFSIZ EOF FILENAME_MAX L_ctermid L_cuserid
 334                 L_tmpname NULL SEEK_CUR SEEK_END SEEK_SET
 335                 STREAM_MAX TMP_MAX stderr stdin stdout
 336                 clearerr fclose fdopen feof ferror fflush fgetc fgetpos
 337                 fgets fopen fprintf fputc fputs fread freopen
 338                 fscanf fseek fsetpos ftell fwrite getchar gets
 339                 perror putc putchar puts remove rewind
 340                 scanf setbuf setvbuf sscanf tmpfile tmpnam
 341                 ungetc vfprintf vprintf vsprintf)],
 342
 343     stdlib_h => [qw(EXIT_FAILURE EXIT_SUCCESS MB_CUR_MAX NULL RAND_MAX
 344                 abort atexit atof atoi atol bsearch calloc div
 345                 free getenv labs ldiv malloc mblen mbstowcs mbtowc
 346                 qsort realloc strtod strtol strtold strtoul wcstombs wctomb)],
 347
 348     string_h => [qw(NULL memchr memcmp memcpy memmove memset strcat
 349                 strchr strcmp strcoll strcpy strcspn strerror strlen
 350                 strncat strncmp strncpy strpbrk strrchr strspn strstr
 351                 strtok strxfrm)],
 352
 353     sys_stat_h => [qw(S_IRGRP S_IROTH S_IRUSR S_IRWXG S_IRWXO S_IRWXU
 354                 S_ISBLK S_ISCHR S_ISDIR S_ISFIFO S_ISGID S_ISREG
 355                 S_ISUID S_IWGRP S_IWOTH S_IWUSR S_IXGRP S_IXOTH S_IXUSR
 356                 fstat mkfifo)],
 357
 358     sys_times_h => [],
 359
 360     sys_types_h => [],
 361
 362     sys_utsname_h => [qw(uname)],
 363
 364     sys_wait_h => [qw(WEXITSTATUS WIFEXITED WIFSIGNALED WIFSTOPPED
 365                 WNOHANG WSTOPSIG WTERMSIG WUNTRACED)],
 366
 367     termios_h => [qw( B0 B110 B1200 B134 B150 B1800 B19200 B200 B2400
 368                 B300 B38400 B4800 B50 B600 B75 B9600 BRKINT CLOCAL
 369                 CREAD CS5 CS6 CS7 CS8 CSIZE CSTOPB ECHO ECHOE ECHOK
 370                 ECHONL HUPCL ICANON ICRNL IEXTEN IGNBRK IGNCR IGNPAR
 371                 INLCR INPCK ISIG ISTRIP IXOFF IXON NCCS NOFLSH OPOST
 372                 PARENB PARMRK PARODD TCIFLUSH TCIOFF TCIOFLUSH TCION
 373                 TCOFLUSH TCOOFF TCOON TCSADRAIN TCSAFLUSH TCSANOW
 374                 TOSTOP VEOF VEOL VERASE VINTR VKILL VMIN VQUIT VSTART
 375                 VSTOP VSUSP VTIME
 376                 cfgetispeed cfgetospeed cfsetispeed cfsetospeed tcdrain
 377                 tcflow tcflush tcgetattr tcsendbreak tcsetattr )],
 378
 379     time_h =>   [qw(CLK_TCK CLOCKS_PER_SEC NULL asctime clock ctime
 380                 difftime mktime strftime tzset tzname)],
 381
 382     unistd_h => [qw(F_OK NULL R_OK SEEK_CUR SEEK_END SEEK_SET
 383                 STDERR_FILENO STDIN_FILENO STDOUT_FILENO W_OK X_OK
 384                 _PC_CHOWN_RESTRICTED _PC_LINK_MAX _PC_MAX_CANON
 385                 _PC_MAX_INPUT _PC_NAME_MAX _PC_NO_TRUNC _PC_PATH_MAX
 386                 _PC_PIPE_BUF _PC_VDISABLE _POSIX_CHOWN_RESTRICTED
 387                 _POSIX_JOB_CONTROL _POSIX_NO_TRUNC _POSIX_SAVED_IDS
 388                 _POSIX_VDISABLE _POSIX_VERSION _SC_ARG_MAX
 389                 _SC_CHILD_MAX _SC_CLK_TCK _SC_JOB_CONTROL
 390                 _SC_NGROUPS_MAX _SC_OPEN_MAX _SC_PAGESIZE _SC_SAVED_IDS
 391                 _SC_STREAM_MAX _SC_TZNAME_MAX _SC_VERSION
 392                 _exit access ctermid cuserid
 393                 dup2 dup execl execle execlp execv execve execvp
 394                 fpathconf fsync getcwd getegid geteuid getgid getgroups
 395                 getpid getuid isatty lseek pathconf pause setgid setpgid
 396                 setsid setuid sysconf tcgetpgrp tcsetpgrp ttyname)],
 397
 398     utime_h =>  [],
 399 );
 400
 401 # Exporter::export_tags();
 402 {
 403   # De-duplicate the export list:
 404   my %export;
 405   @export{map {@$_} values %EXPORT_TAGS} = ();
 406   # Doing the de-dup with a temporary hash has the advantage that the SVs in
 407   # @EXPORT are actually shared hash key scalars, which will save some memory.
 408   our @EXPORT = keys %export;
 409
 410   our @EXPORT_OK = (qw(close lchown nice open pipe read sleep times write
 411                        printf sprintf),
 412                     grep {!exists $export{$_}} keys %reimpl, keys %replacement);
 413 }
 414
 415 require Exporter;
 416 }
 417
 418 package POSIX::SigAction;
 419
 420 sub new { bless {HANDLER => $_[1], MASK => $_[2], FLAGS => $_[3] || 0, SAFE => 0}, $_[0] }
 421 sub handler { $_[0]->{HANDLER} = $_[1] if @_ > 1; $_[0]->{HANDLER} };
 422 sub mask    { $_[0]->{MASK}    = $_[1] if @_ > 1; $_[0]->{MASK} };
 423 sub flags   { $_[0]->{FLAGS}   = $_[1] if @_ > 1; $_[0]->{FLAGS} };
 424 sub safe    { $_[0]->{SAFE}    = $_[1] if @_ > 1; $_[0]->{SAFE} };
 425
 426 {
 427 package POSIX::SigSet;
 428 # This package is here entirely to make sure that POSIX::SigSet is seen by the
 429 # PAUSE indexer, so that it will always be clearly indexed in core.  This is to
 430 # prevent the accidental case where a third-party distribution can accidentally
 431 # claim the POSIX::SigSet package, as occurred in 2011-12. -- rjbs, 2011-12-30
 432 }
 433
 434 package POSIX::SigRt;
 435
 436 require Tie::Hash;
 437
 438 our @ISA = 'Tie::StdHash';
 439
 440 our ($_SIGRTMIN, $_SIGRTMAX, $_sigrtn);
 441
 442 our $SIGACTION_FLAGS = 0;
 443
 444 sub _init {
 445     $_SIGRTMIN = &POSIX::SIGRTMIN;
 446     $_SIGRTMAX = &POSIX::SIGRTMAX;
 447     $_sigrtn   = $_SIGRTMAX - $_SIGRTMIN;
 448 }
 449
 450 sub _croak {
 451     &_init unless defined $_sigrtn;
 452     die "POSIX::SigRt not available" unless defined $_sigrtn && $_sigrtn > 0;
 453 }
 454
 455 sub _getsig {
 456     &_croak;
 457     my $rtsig = $_[0];
 458     # Allow (SIGRT)?MIN( + n)?, a common idiom when doing these things in C.
 459     $rtsig = $_SIGRTMIN + ($1 || 0)
 460         if $rtsig =~ /^(?:(?:SIG)?RT)?MIN(\s*\+\s*(\d+))?$/;
 461     return $rtsig;
 462 }
 463
 464 sub _exist {
 465     my $rtsig = _getsig($_[1]);
 466     my $ok    = $rtsig >= $_SIGRTMIN && $rtsig <= $_SIGRTMAX;
 467     ($rtsig, $ok);
 468 }
 469
 470 sub _check {
 471     my ($rtsig, $ok) = &_exist;
 472     die "No POSIX::SigRt signal $_[1] (valid range SIGRTMIN..SIGRTMAX, or $_SIGRTMIN..$_SIGRTMAX)"
 473         unless $ok;
 474     return $rtsig;
 475 }
 476
 477 sub new {
 478     my ($rtsig, $handler, $flags) = @_;
 479     my $sigset = POSIX::SigSet->new($rtsig);
 480     my $sigact = POSIX::SigAction->new($handler, $sigset, $flags);
 481     POSIX::sigaction($rtsig, $sigact);
 482 }
 483
 484 sub EXISTS { &_exist }
 485 sub FETCH  { my $rtsig = &_check;
 486              my $oa = POSIX::SigAction->new();
 487              POSIX::sigaction($rtsig, undef, $oa);
 488              return $oa->{HANDLER} }
 489 sub STORE  { my $rtsig = &_check; new($rtsig, $_[2], $SIGACTION_FLAGS) }
 490 sub DELETE { delete $SIG{ &_check } }
 491 sub CLEAR  { &_exist; delete @SIG{ &POSIX::SIGRTMIN .. &POSIX::SIGRTMAX } }
 492 sub SCALAR { &_croak; $_sigrtn + 1 }
 493
 494 tie %POSIX::SIGRT, 'POSIX::SigRt';
 495 # and the expression on the line above is true, so we return true.