This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Document the U+0085, U+2028, and U+2029.
[perl5.git] / pod / perlre.pod
1 =head1 NAME
2
3 perlre - Perl regular expressions
4
5 =head1 DESCRIPTION
6
7 This page describes the syntax of regular expressions in Perl.  
8
9 if you haven't used regular expressions before, a quick-start
10 introduction is available in L<perlrequick>, and a longer tutorial
11 introduction is available in L<perlretut>.
12
13 For reference on how regular expressions are used in matching
14 operations, plus various examples of the same, see discussions of
15 C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
16 Operators">.
17
18 Matching operations can have various modifiers.  Modifiers
19 that relate to the interpretation of the regular expression inside
20 are listed below.  Modifiers that alter the way a regular expression
21 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and 
22 L<perlop/"Gory details of parsing quoted constructs">.
23
24 =over 4
25
26 =item i
27
28 Do case-insensitive pattern matching.
29
30 If C<use locale> is in effect, the case map is taken from the current
31 locale.  See L<perllocale>.
32
33 =item m
34
35 Treat string as multiple lines.  That is, change "^" and "$" from matching
36 the start or end of the string to matching the start or end of any
37 line anywhere within the string.
38
39 =item s
40
41 Treat string as single line.  That is, change "." to match any character
42 whatsoever, even a newline, which normally it would not match.
43
44 The C</s> and C</m> modifiers both override the C<$*> setting.  That
45 is, no matter what C<$*> contains, C</s> without C</m> will force
46 "^" to match only at the beginning of the string and "$" to match
47 only at the end (or just before a newline at the end) of the string.
48 Together, as /ms, they let the "." match any character whatsoever,
49 while still allowing "^" and "$" to match, respectively, just after
50 and just before newlines within the string.
51
52 =item x
53
54 Extend your pattern's legibility by permitting whitespace and comments.
55
56 =back
57
58 These are usually written as "the C</x> modifier", even though the delimiter
59 in question might not really be a slash.  Any of these
60 modifiers may also be embedded within the regular expression itself using
61 the C<(?...)> construct.  See below.
62
63 The C</x> modifier itself needs a little more explanation.  It tells
64 the regular expression parser to ignore whitespace that is neither
65 backslashed nor within a character class.  You can use this to break up
66 your regular expression into (slightly) more readable parts.  The C<#>
67 character is also treated as a metacharacter introducing a comment,
68 just as in ordinary Perl code.  This also means that if you want real
69 whitespace or C<#> characters in the pattern (outside a character
70 class, where they are unaffected by C</x>), that you'll either have to 
71 escape them or encode them using octal or hex escapes.  Taken together,
72 these features go a long way towards making Perl's regular expressions
73 more readable.  Note that you have to be careful not to include the
74 pattern delimiter in the comment--perl has no way of knowing you did
75 not intend to close the pattern early.  See the C-comment deletion code
76 in L<perlop>.
77
78 =head2 Regular Expressions
79
80 The patterns used in Perl pattern matching derive from supplied in
81 the Version 8 regex routines.  (The routines are derived
82 (distantly) from Henry Spencer's freely redistributable reimplementation
83 of the V8 routines.)  See L<Version 8 Regular Expressions> for
84 details.
85
86 In particular the following metacharacters have their standard I<egrep>-ish
87 meanings:
88
89     \   Quote the next metacharacter
90     ^   Match the beginning of the line
91     .   Match any character (except newline)
92     $   Match the end of the line (or before newline at the end)
93     |   Alternation
94     ()  Grouping
95     []  Character class
96
97 By default, the "^" character is guaranteed to match only the
98 beginning of the string, the "$" character only the end (or before the
99 newline at the end), and Perl does certain optimizations with the
100 assumption that the string contains only one line.  Embedded newlines
101 will not be matched by "^" or "$".  You may, however, wish to treat a
102 string as a multi-line buffer, such that the "^" will match after any
103 newline within the string, and "$" will match before any newline.  At the
104 cost of a little more overhead, you can do this by using the /m modifier
105 on the pattern match operator.  (Older programs did this by setting C<$*>,
106 but this practice is now deprecated.)
107
108 To simplify multi-line substitutions, the "." character never matches a
109 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
110 the string is a single line--even if it isn't.  The C</s> modifier also
111 overrides the setting of C<$*>, in case you have some (badly behaved) older
112 code that sets it in another module.
113
114 The following standard quantifiers are recognized:
115
116     *      Match 0 or more times
117     +      Match 1 or more times
118     ?      Match 1 or 0 times
119     {n}    Match exactly n times
120     {n,}   Match at least n times
121     {n,m}  Match at least n but not more than m times
122
123 (If a curly bracket occurs in any other context, it is treated
124 as a regular character.)  The "*" modifier is equivalent to C<{0,}>, the "+"
125 modifier to C<{1,}>, and the "?" modifier to C<{0,1}>.  n and m are limited
126 to integral values less than a preset limit defined when perl is built.
127 This is usually 32766 on the most common platforms.  The actual limit can
128 be seen in the error message generated by code such as this:
129
130     $_ **= $_ , / {$_} / for 2 .. 42;
131
132 By default, a quantified subpattern is "greedy", that is, it will match as
133 many times as possible (given a particular starting location) while still
134 allowing the rest of the pattern to match.  If you want it to match the
135 minimum number of times possible, follow the quantifier with a "?".  Note
136 that the meanings don't change, just the "greediness":
137
138     *?     Match 0 or more times
139     +?     Match 1 or more times
140     ??     Match 0 or 1 time
141     {n}?   Match exactly n times
142     {n,}?  Match at least n times
143     {n,m}? Match at least n but not more than m times
144
145 Because patterns are processed as double quoted strings, the following
146 also work:
147
148     \t          tab                   (HT, TAB)
149     \n          newline               (LF, NL)
150     \r          return                (CR)
151     \f          form feed             (FF)
152     \a          alarm (bell)          (BEL)
153     \e          escape (think troff)  (ESC)
154     \033        octal char (think of a PDP-11)
155     \x1B        hex char
156     \x{263a}    wide hex char         (Unicode SMILEY)
157     \c[         control char
158     \N{name}    named char
159     \l          lowercase next char (think vi)
160     \u          uppercase next char (think vi)
161     \L          lowercase till \E (think vi)
162     \U          uppercase till \E (think vi)
163     \E          end case modification (think vi)
164     \Q          quote (disable) pattern metacharacters till \E
165
166 If C<use locale> is in effect, the case map used by C<\l>, C<\L>, C<\u>
167 and C<\U> is taken from the current locale.  See L<perllocale>.  For
168 documentation of C<\N{name}>, see L<charnames>.
169
170 You cannot include a literal C<$> or C<@> within a C<\Q> sequence.
171 An unescaped C<$> or C<@> interpolates the corresponding variable,
172 while escaping will cause the literal string C<\$> to be matched.
173 You'll need to write something like C<m/\Quser\E\@\Qhost/>.
174
175 In addition, Perl defines the following:
176
177     \w  Match a "word" character (alphanumeric plus "_")
178     \W  Match a non-"word" character
179     \s  Match a whitespace character
180     \S  Match a non-whitespace character
181     \d  Match a digit character
182     \D  Match a non-digit character
183     \pP Match P, named property.  Use \p{Prop} for longer names.
184     \PP Match non-P
185     \X  Match eXtended Unicode "combining character sequence",
186         equivalent to (?:\PM\pM*)
187     \C  Match a single C char (octet) even under Unicode.
188         NOTE: breaks up characters into their UTF-8 bytes,
189         so you may end up with malformed pieces of UTF-8.
190
191 A C<\w> matches a single alphanumeric character (an alphabetic
192 character, or a decimal digit) or C<_>, not a whole word.  Use C<\w+>
193 to match a string of Perl-identifier characters (which isn't the same
194 as matching an English word).  If C<use locale> is in effect, the list
195 of alphabetic characters generated by C<\w> is taken from the current
196 locale.  See L<perllocale>.  You may use C<\w>, C<\W>, C<\s>, C<\S>,
197 C<\d>, and C<\D> within character classes, but if you try to use them
198 as endpoints of a range, that's not a range, the "-" is understood
199 literally.  If Unicode is in effect, C<\s> matches also "\x{85}",
200 "\x{2028}, and "\x{2029}", see L<perlunicode> for more details about
201 C<\pP>, C<\PP>, and C<\X>, and L<perluniintro> about Unicode in
202 general.
203
204 The POSIX character class syntax
205
206     [:class:]
207
208 is also available.  The available classes and their backslash
209 equivalents (if available) are as follows:
210
211     alpha
212     alnum
213     ascii
214     blank               [1]
215     cntrl
216     digit       \d
217     graph
218     lower
219     print
220     punct
221     space       \s      [2]
222     upper
223     word        \w      [3]
224     xdigit
225
226 =over
227
228 =item [1]
229
230 A GNU extension equivalent to C<[ \t]>, `all horizontal whitespace'.
231
232 =item [2]
233
234 Not exactly equivalent to C<\s> since the C<[[:space:]]> includes
235 also the (very rare) `vertical tabulator', "\ck", chr(11).
236
237 =item [3]
238
239 A Perl extension, see above.
240
241 =back
242
243 For example use C<[:upper:]> to match all the uppercase characters.
244 Note that the C<[]> are part of the C<[::]> construct, not part of the
245 whole character class.  For example:
246
247     [01[:alpha:]%]
248
249 matches zero, one, any alphabetic character, and the percentage sign.
250
251 The following equivalences to Unicode \p{} constructs and equivalent
252 backslash character classes (if available), will hold:
253
254     [:...:]     \p{...}         backslash
255
256     alpha       IsAlpha
257     alnum       IsAlnum
258     ascii       IsASCII
259     blank       IsSpace
260     cntrl       IsCntrl
261     digit       IsDigit        \d
262     graph       IsGraph
263     lower       IsLower
264     print       IsPrint
265     punct       IsPunct
266     space       IsSpace
267                 IsSpacePerl    \s
268     upper       IsUpper
269     word        IsWord
270     xdigit      IsXDigit
271
272 For example C<[:lower:]> and C<\p{IsLower}> are equivalent.
273
274 If the C<utf8> pragma is not used but the C<locale> pragma is, the
275 classes correlate with the usual isalpha(3) interface (except for
276 `word' and `blank').
277
278 The assumedly non-obviously named classes are:
279
280 =over 4
281
282 =item cntrl
283
284 Any control character.  Usually characters that don't produce output as
285 such but instead control the terminal somehow: for example newline and
286 backspace are control characters.  All characters with ord() less than
287 32 are most often classified as control characters (assuming ASCII,
288 the ISO Latin character sets, and Unicode), as is the character with
289 the ord() value of 127 (C<DEL>).
290
291 =item graph
292
293 Any alphanumeric or punctuation (special) character.
294
295 =item print
296
297 Any alphanumeric or punctuation (special) character or the space character.
298
299 =item punct
300
301 Any punctuation (special) character.
302
303 =item xdigit
304
305 Any hexadecimal digit.  Though this may feel silly ([0-9A-Fa-f] would
306 work just fine) it is included for completeness.
307
308 =back
309
310 You can negate the [::] character classes by prefixing the class name
311 with a '^'. This is a Perl extension.  For example:
312
313     POSIX       traditional Unicode
314
315     [:^digit:]      \D      \P{IsDigit}
316     [:^space:]      \S      \P{IsSpace}
317     [:^word:]       \W      \P{IsWord}
318
319 The POSIX character classes [.cc.] and [=cc=] are recognized but
320 B<not> supported and trying to use them will cause an error.
321
322 Perl defines the following zero-width assertions:
323
324     \b  Match a word boundary
325     \B  Match a non-(word boundary)
326     \A  Match only at beginning of string
327     \Z  Match only at end of string, or before newline at the end
328     \z  Match only at end of string
329     \G  Match only at pos() (e.g. at the end-of-match position
330         of prior m//g)
331
332 A word boundary (C<\b>) is a spot between two characters
333 that has a C<\w> on one side of it and a C<\W> on the other side
334 of it (in either order), counting the imaginary characters off the
335 beginning and end of the string as matching a C<\W>.  (Within
336 character classes C<\b> represents backspace rather than a word
337 boundary, just as it normally does in any double-quoted string.)
338 The C<\A> and C<\Z> are just like "^" and "$", except that they
339 won't match multiple times when the C</m> modifier is used, while
340 "^" and "$" will match at every internal line boundary.  To match
341 the actual end of the string and not ignore an optional trailing
342 newline, use C<\z>.
343
344 The C<\G> assertion can be used to chain global matches (using
345 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
346 It is also useful when writing C<lex>-like scanners, when you have
347 several patterns that you want to match against consequent substrings
348 of your string, see the previous reference.  The actual location
349 where C<\G> will match can also be influenced by using C<pos()> as
350 an lvalue.  See L<perlfunc/pos>.
351
352 The bracketing construct C<( ... )> creates capture buffers.  To
353 refer to the digit'th buffer use \<digit> within the
354 match.  Outside the match use "$" instead of "\".  (The
355 \<digit> notation works in certain circumstances outside 
356 the match.  See the warning below about \1 vs $1 for details.)
357 Referring back to another part of the match is called a
358 I<backreference>.
359
360 There is no limit to the number of captured substrings that you may
361 use.  However Perl also uses \10, \11, etc. as aliases for \010,
362 \011, etc.  (Recall that 0 means octal, so \011 is the character at
363 number 9 in your coded character set; which would be the 10th character,
364 a horizontal tab under ASCII.)  Perl resolves this 
365 ambiguity by interpreting \10 as a backreference only if at least 10 
366 left parentheses have opened before it.  Likewise \11 is a 
367 backreference only if at least 11 left parentheses have opened 
368 before it.  And so on.  \1 through \9 are always interpreted as 
369 backreferences.
370
371 Examples:
372
373     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
374
375      if (/(.)\1/) {                 # find first doubled char
376          print "'$1' is the first doubled character\n";
377      }
378
379     if (/Time: (..):(..):(..)/) {   # parse out values
380         $hours = $1;
381         $minutes = $2;
382         $seconds = $3;
383     }
384
385 Several special variables also refer back to portions of the previous
386 match.  C<$+> returns whatever the last bracket match matched.
387 C<$&> returns the entire matched string.  (At one point C<$0> did
388 also, but now it returns the name of the program.)  C<$`> returns
389 everything before the matched string.  And C<$'> returns everything
390 after the matched string.
391
392 The numbered variables ($1, $2, $3, etc.) and the related punctuation
393 set (C<$+>, C<$&>, C<$`>, and C<$'>) are all dynamically scoped
394 until the end of the enclosing block or until the next successful
395 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
396
397 B<WARNING>: Once Perl sees that you need one of C<$&>, C<$`>, or
398 C<$'> anywhere in the program, it has to provide them for every
399 pattern match.  This may substantially slow your program.  Perl
400 uses the same mechanism to produce $1, $2, etc, so you also pay a
401 price for each pattern that contains capturing parentheses.  (To
402 avoid this cost while retaining the grouping behaviour, use the
403 extended regular expression C<(?: ... )> instead.)  But if you never
404 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
405 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
406 if you can, but if you can't (and some algorithms really appreciate
407 them), once you've used them once, use them at will, because you've
408 already paid the price.  As of 5.005, C<$&> is not so costly as the
409 other two.
410
411 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
412 C<\w>, C<\n>.  Unlike some other regular expression languages, there
413 are no backslashed symbols that aren't alphanumeric.  So anything
414 that looks like \\, \(, \), \<, \>, \{, or \} is always
415 interpreted as a literal character, not a metacharacter.  This was
416 once used in a common idiom to disable or quote the special meanings
417 of regular expression metacharacters in a string that you want to
418 use for a pattern. Simply quote all non-"word" characters:
419
420     $pattern =~ s/(\W)/\\$1/g;
421
422 (If C<use locale> is set, then this depends on the current locale.)
423 Today it is more common to use the quotemeta() function or the C<\Q>
424 metaquoting escape sequence to disable all metacharacters' special
425 meanings like this:
426
427     /$unquoted\Q$quoted\E$unquoted/
428
429 Beware that if you put literal backslashes (those not inside
430 interpolated variables) between C<\Q> and C<\E>, double-quotish
431 backslash interpolation may lead to confusing results.  If you
432 I<need> to use literal backslashes within C<\Q...\E>,
433 consult L<perlop/"Gory details of parsing quoted constructs">.
434
435 =head2 Extended Patterns
436
437 Perl also defines a consistent extension syntax for features not
438 found in standard tools like B<awk> and B<lex>.  The syntax is a
439 pair of parentheses with a question mark as the first thing within
440 the parentheses.  The character after the question mark indicates
441 the extension.
442
443 The stability of these extensions varies widely.  Some have been
444 part of the core language for many years.  Others are experimental
445 and may change without warning or be completely removed.  Check
446 the documentation on an individual feature to verify its current
447 status.
448
449 A question mark was chosen for this and for the minimal-matching
450 construct because 1) question marks are rare in older regular
451 expressions, and 2) whenever you see one, you should stop and
452 "question" exactly what is going on.  That's psychology...
453
454 =over 10
455
456 =item C<(?#text)>
457
458 A comment.  The text is ignored.  If the C</x> modifier enables
459 whitespace formatting, a simple C<#> will suffice.  Note that Perl closes
460 the comment as soon as it sees a C<)>, so there is no way to put a literal
461 C<)> in the comment.
462
463 =item C<(?imsx-imsx)>
464
465 One or more embedded pattern-match modifiers, to be turned on (or
466 turned off, if preceded by C<->) for the remainder of the pattern or
467 the remainder of the enclosing pattern group (if any). This is
468 particularly useful for dynamic patterns, such as those read in from a
469 configuration file, read in as an argument, are specified in a table
470 somewhere, etc.  Consider the case that some of which want to be case
471 sensitive and some do not.  The case insensitive ones need to include
472 merely C<(?i)> at the front of the pattern.  For example:
473
474     $pattern = "foobar";
475     if ( /$pattern/i ) { } 
476
477     # more flexible:
478
479     $pattern = "(?i)foobar";
480     if ( /$pattern/ ) { } 
481
482 These modifiers are restored at the end of the enclosing group. For example,
483
484     ( (?i) blah ) \s+ \1
485
486 will match a repeated (I<including the case>!) word C<blah> in any
487 case, assuming C<x> modifier, and no C<i> modifier outside this
488 group.
489
490 =item C<(?:pattern)>
491
492 =item C<(?imsx-imsx:pattern)>
493
494 This is for clustering, not capturing; it groups subexpressions like
495 "()", but doesn't make backreferences as "()" does.  So
496
497     @fields = split(/\b(?:a|b|c)\b/)
498
499 is like
500
501     @fields = split(/\b(a|b|c)\b/)
502
503 but doesn't spit out extra fields.  It's also cheaper not to capture
504 characters if you don't need to.
505
506 Any letters between C<?> and C<:> act as flags modifiers as with
507 C<(?imsx-imsx)>.  For example, 
508
509     /(?s-i:more.*than).*million/i
510
511 is equivalent to the more verbose
512
513     /(?:(?s-i)more.*than).*million/i
514
515 =item C<(?=pattern)>
516
517 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
518 matches a word followed by a tab, without including the tab in C<$&>.
519
520 =item C<(?!pattern)>
521
522 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
523 matches any occurrence of "foo" that isn't followed by "bar".  Note
524 however that look-ahead and look-behind are NOT the same thing.  You cannot
525 use this for look-behind.
526
527 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
528 will not do what you want.  That's because the C<(?!foo)> is just saying that
529 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
530 match.  You would have to do something like C</(?!foo)...bar/> for that.   We
531 say "like" because there's the case of your "bar" not having three characters
532 before it.  You could cover that this way: C</(?:(?!foo)...|^.{0,2})bar/>.
533 Sometimes it's still easier just to say:
534
535     if (/bar/ && $` !~ /foo$/)
536
537 For look-behind see below.
538
539 =item C<(?<=pattern)>
540
541 A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
542 matches a word that follows a tab, without including the tab in C<$&>.
543 Works only for fixed-width look-behind.
544
545 =item C<(?<!pattern)>
546
547 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
548 matches any occurrence of "foo" that does not follow "bar".  Works
549 only for fixed-width look-behind.
550
551 =item C<(?{ code })>
552
553 B<WARNING>: This extended regular expression feature is considered
554 highly experimental, and may be changed or deleted without notice.
555
556 This zero-width assertion evaluate any embedded Perl code.  It
557 always succeeds, and its C<code> is not interpolated.  Currently,
558 the rules to determine where the C<code> ends are somewhat convoluted.
559
560 The C<code> is properly scoped in the following sense: If the assertion
561 is backtracked (compare L<"Backtracking">), all changes introduced after
562 C<local>ization are undone, so that
563
564   $_ = 'a' x 8;
565   m< 
566      (?{ $cnt = 0 })                    # Initialize $cnt.
567      (
568        a 
569        (?{
570            local $cnt = $cnt + 1;       # Update $cnt, backtracking-safe.
571        })
572      )*  
573      aaaa
574      (?{ $res = $cnt })                 # On success copy to non-localized
575                                         # location.
576    >x;
577
578 will set C<$res = 4>.  Note that after the match, $cnt returns to the globally
579 introduced value, because the scopes that restrict C<local> operators
580 are unwound.
581
582 This assertion may be used as a C<(?(condition)yes-pattern|no-pattern)>
583 switch.  If I<not> used in this way, the result of evaluation of
584 C<code> is put into the special variable C<$^R>.  This happens
585 immediately, so C<$^R> can be used from other C<(?{ code })> assertions
586 inside the same regular expression.
587
588 The assignment to C<$^R> above is properly localized, so the old
589 value of C<$^R> is restored if the assertion is backtracked; compare
590 L<"Backtracking">.
591
592 For reasons of security, this construct is forbidden if the regular
593 expression involves run-time interpolation of variables, unless the
594 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
595 variables contain results of C<qr//> operator (see
596 L<perlop/"qr/STRING/imosx">).  
597
598 This restriction is because of the wide-spread and remarkably convenient
599 custom of using run-time determined strings as patterns.  For example:
600
601     $re = <>;
602     chomp $re;
603     $string =~ /$re/;
604
605 Before Perl knew how to execute interpolated code within a pattern,
606 this operation was completely safe from a security point of view,
607 although it could raise an exception from an illegal pattern.  If
608 you turn on the C<use re 'eval'>, though, it is no longer secure,
609 so you should only do so if you are also using taint checking.
610 Better yet, use the carefully constrained evaluation within a Safe
611 module.  See L<perlsec> for details about both these mechanisms.
612
613 =item C<(??{ code })>
614
615 B<WARNING>: This extended regular expression feature is considered
616 highly experimental, and may be changed or deleted without notice.
617 A simplified version of the syntax may be introduced for commonly
618 used idioms.
619
620 This is a "postponed" regular subexpression.  The C<code> is evaluated
621 at run time, at the moment this subexpression may match.  The result
622 of evaluation is considered as a regular expression and matched as
623 if it were inserted instead of this construct.
624
625 The C<code> is not interpolated.  As before, the rules to determine
626 where the C<code> ends are currently somewhat convoluted.
627
628 The following pattern matches a parenthesized group:
629
630   $re = qr{
631              \(
632              (?:
633                 (?> [^()]+ )    # Non-parens without backtracking
634               |
635                 (??{ $re })     # Group with matching parens
636              )*
637              \)
638           }x;
639
640 =item C<< (?>pattern) >>
641
642 B<WARNING>: This extended regular expression feature is considered
643 highly experimental, and may be changed or deleted without notice.
644
645 An "independent" subexpression, one which matches the substring
646 that a I<standalone> C<pattern> would match if anchored at the given
647 position, and it matches I<nothing other than this substring>.  This
648 construct is useful for optimizations of what would otherwise be
649 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
650 It may also be useful in places where the "grab all you can, and do not
651 give anything back" semantic is desirable.
652
653 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
654 (anchored at the beginning of string, as above) will match I<all>
655 characters C<a> at the beginning of string, leaving no C<a> for
656 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
657 since the match of the subgroup C<a*> is influenced by the following
658 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
659 C<a*ab> will match fewer characters than a standalone C<a*>, since
660 this makes the tail match.
661
662 An effect similar to C<< (?>pattern) >> may be achieved by writing
663 C<(?=(pattern))\1>.  This matches the same substring as a standalone
664 C<a+>, and the following C<\1> eats the matched string; it therefore
665 makes a zero-length assertion into an analogue of C<< (?>...) >>.
666 (The difference between these two constructs is that the second one
667 uses a capturing group, thus shifting ordinals of backreferences
668 in the rest of a regular expression.)
669
670 Consider this pattern:
671
672     m{ \(
673           ( 
674             [^()]+              # x+
675           | 
676             \( [^()]* \)
677           )+
678        \) 
679      }x
680
681 That will efficiently match a nonempty group with matching parentheses
682 two levels deep or less.  However, if there is no such group, it
683 will take virtually forever on a long string.  That's because there
684 are so many different ways to split a long string into several
685 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
686 to a subpattern of the above pattern.  Consider how the pattern
687 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
688 seconds, but that each extra letter doubles this time.  This
689 exponential performance will make it appear that your program has
690 hung.  However, a tiny change to this pattern
691
692     m{ \( 
693           ( 
694             (?> [^()]+ )        # change x+ above to (?> x+ )
695           | 
696             \( [^()]* \)
697           )+
698        \) 
699      }x
700
701 which uses C<< (?>...) >> matches exactly when the one above does (verifying
702 this yourself would be a productive exercise), but finishes in a fourth
703 the time when used on a similar string with 1000000 C<a>s.  Be aware,
704 however, that this pattern currently triggers a warning message under
705 the C<use warnings> pragma or B<-w> switch saying it
706 C<"matches null string many times in regex">.
707
708 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
709 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
710 This was only 4 times slower on a string with 1000000 C<a>s.
711
712 The "grab all you can, and do not give anything back" semantic is desirable
713 in many situations where on the first sight a simple C<()*> looks like
714 the correct solution.  Suppose we parse text with comments being delimited
715 by C<#> followed by some optional (horizontal) whitespace.  Contrary to
716 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
717 the comment delimiter, because it may "give up" some whitespace if
718 the remainder of the pattern can be made to match that way.  The correct
719 answer is either one of these:
720
721     (?>#[ \t]*)
722     #[ \t]*(?![ \t])
723
724 For example, to grab non-empty comments into $1, one should use either
725 one of these:
726
727     / (?> \# [ \t]* ) (        .+ ) /x;
728     /     \# [ \t]*   ( [^ \t] .* ) /x;
729
730 Which one you pick depends on which of these expressions better reflects
731 the above specification of comments.
732
733 =item C<(?(condition)yes-pattern|no-pattern)>
734
735 =item C<(?(condition)yes-pattern)>
736
737 B<WARNING>: This extended regular expression feature is considered
738 highly experimental, and may be changed or deleted without notice.
739
740 Conditional expression.  C<(condition)> should be either an integer in
741 parentheses (which is valid if the corresponding pair of parentheses
742 matched), or look-ahead/look-behind/evaluate zero-width assertion.
743
744 For example:
745
746     m{ ( \( )? 
747        [^()]+ 
748        (?(1) \) ) 
749      }x
750
751 matches a chunk of non-parentheses, possibly included in parentheses
752 themselves.
753
754 =back
755
756 =head2 Backtracking
757
758 NOTE: This section presents an abstract approximation of regular
759 expression behavior.  For a more rigorous (and complicated) view of
760 the rules involved in selecting a match among possible alternatives,
761 see L<Combining pieces together>.
762
763 A fundamental feature of regular expression matching involves the
764 notion called I<backtracking>, which is currently used (when needed)
765 by all regular expression quantifiers, namely C<*>, C<*?>, C<+>,
766 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
767 internally, but the general principle outlined here is valid.
768
769 For a regular expression to match, the I<entire> regular expression must
770 match, not just part of it.  So if the beginning of a pattern containing a
771 quantifier succeeds in a way that causes later parts in the pattern to
772 fail, the matching engine backs up and recalculates the beginning
773 part--that's why it's called backtracking.
774
775 Here is an example of backtracking:  Let's say you want to find the
776 word following "foo" in the string "Food is on the foo table.":
777
778     $_ = "Food is on the foo table.";
779     if ( /\b(foo)\s+(\w+)/i ) {
780         print "$2 follows $1.\n";
781     }
782
783 When the match runs, the first part of the regular expression (C<\b(foo)>)
784 finds a possible match right at the beginning of the string, and loads up
785 $1 with "Foo".  However, as soon as the matching engine sees that there's
786 no whitespace following the "Foo" that it had saved in $1, it realizes its
787 mistake and starts over again one character after where it had the
788 tentative match.  This time it goes all the way until the next occurrence
789 of "foo". The complete regular expression matches this time, and you get
790 the expected output of "table follows foo."
791
792 Sometimes minimal matching can help a lot.  Imagine you'd like to match
793 everything between "foo" and "bar".  Initially, you write something
794 like this:
795
796     $_ =  "The food is under the bar in the barn.";
797     if ( /foo(.*)bar/ ) {
798         print "got <$1>\n";
799     }
800
801 Which perhaps unexpectedly yields:
802
803   got <d is under the bar in the >
804
805 That's because C<.*> was greedy, so you get everything between the
806 I<first> "foo" and the I<last> "bar".  Here it's more effective
807 to use minimal matching to make sure you get the text between a "foo"
808 and the first "bar" thereafter.
809
810     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
811   got <d is under the >
812
813 Here's another example: let's say you'd like to match a number at the end
814 of a string, and you also want to keep the preceding part of the match.
815 So you write this:
816
817     $_ = "I have 2 numbers: 53147";
818     if ( /(.*)(\d*)/ ) {                                # Wrong!
819         print "Beginning is <$1>, number is <$2>.\n";
820     }
821
822 That won't work at all, because C<.*> was greedy and gobbled up the
823 whole string. As C<\d*> can match on an empty string the complete
824 regular expression matched successfully.
825
826     Beginning is <I have 2 numbers: 53147>, number is <>.
827
828 Here are some variants, most of which don't work:
829
830     $_ = "I have 2 numbers: 53147";
831     @pats = qw{
832         (.*)(\d*)
833         (.*)(\d+)
834         (.*?)(\d*)
835         (.*?)(\d+)
836         (.*)(\d+)$
837         (.*?)(\d+)$
838         (.*)\b(\d+)$
839         (.*\D)(\d+)$
840     };
841
842     for $pat (@pats) {
843         printf "%-12s ", $pat;
844         if ( /$pat/ ) {
845             print "<$1> <$2>\n";
846         } else {
847             print "FAIL\n";
848         }
849     }
850
851 That will print out:
852
853     (.*)(\d*)    <I have 2 numbers: 53147> <>
854     (.*)(\d+)    <I have 2 numbers: 5314> <7>
855     (.*?)(\d*)   <> <>
856     (.*?)(\d+)   <I have > <2>
857     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
858     (.*?)(\d+)$  <I have 2 numbers: > <53147>
859     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
860     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
861
862 As you see, this can be a bit tricky.  It's important to realize that a
863 regular expression is merely a set of assertions that gives a definition
864 of success.  There may be 0, 1, or several different ways that the
865 definition might succeed against a particular string.  And if there are
866 multiple ways it might succeed, you need to understand backtracking to
867 know which variety of success you will achieve.
868
869 When using look-ahead assertions and negations, this can all get even
870 tricker.  Imagine you'd like to find a sequence of non-digits not
871 followed by "123".  You might try to write that as
872
873     $_ = "ABC123";
874     if ( /^\D*(?!123)/ ) {              # Wrong!
875         print "Yup, no 123 in $_\n";
876     }
877
878 But that isn't going to match; at least, not the way you're hoping.  It
879 claims that there is no 123 in the string.  Here's a clearer picture of
880 why that pattern matches, contrary to popular expectations:
881
882     $x = 'ABC123' ;
883     $y = 'ABC445' ;
884
885     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/ ;
886     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/ ;
887
888     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/ ;
889     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/ ;
890
891 This prints
892
893     2: got ABC
894     3: got AB
895     4: got ABC
896
897 You might have expected test 3 to fail because it seems to a more
898 general purpose version of test 1.  The important difference between
899 them is that test 3 contains a quantifier (C<\D*>) and so can use
900 backtracking, whereas test 1 will not.  What's happening is
901 that you've asked "Is it true that at the start of $x, following 0 or more
902 non-digits, you have something that's not 123?"  If the pattern matcher had
903 let C<\D*> expand to "ABC", this would have caused the whole pattern to
904 fail.
905
906 The search engine will initially match C<\D*> with "ABC".  Then it will
907 try to match C<(?!123> with "123", which fails.  But because
908 a quantifier (C<\D*>) has been used in the regular expression, the
909 search engine can backtrack and retry the match differently
910 in the hope of matching the complete regular expression.
911
912 The pattern really, I<really> wants to succeed, so it uses the
913 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
914 time.  Now there's indeed something following "AB" that is not
915 "123".  It's "C123", which suffices.
916
917 We can deal with this by using both an assertion and a negation.
918 We'll say that the first part in $1 must be followed both by a digit
919 and by something that's not "123".  Remember that the look-aheads
920 are zero-width expressions--they only look, but don't consume any
921 of the string in their match.  So rewriting this way produces what
922 you'd expect; that is, case 5 will fail, but case 6 succeeds:
923
924     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/ ;
925     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/ ;
926
927     6: got ABC
928
929 In other words, the two zero-width assertions next to each other work as though
930 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
931 matches only if you're at the beginning of the line AND the end of the
932 line simultaneously.  The deeper underlying truth is that juxtaposition in
933 regular expressions always means AND, except when you write an explicit OR
934 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
935 although the attempted matches are made at different positions because "a"
936 is not a zero-width assertion, but a one-width assertion.
937
938 B<WARNING>: particularly complicated regular expressions can take
939 exponential time to solve because of the immense number of possible
940 ways they can use backtracking to try match.  For example, without
941 internal optimizations done by the regular expression engine, this will
942 take a painfully long time to run:
943
944     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
945
946 And if you used C<*>'s in the internal groups instead of limiting them
947 to 0 through 5 matches, then it would take forever--or until you ran
948 out of stack space.  Moreover, these internal optimizations are not
949 always applicable.  For example, if you put C<{0,5}> instead of C<*>
950 on the external group, no current optimization is applicable, and the
951 match takes a long time to finish.
952
953 A powerful tool for optimizing such beasts is what is known as an
954 "independent group",
955 which does not backtrack (see L<C<< (?>pattern) >>>).  Note also that
956 zero-length look-ahead/look-behind assertions will not backtrack to make
957 the tail match, since they are in "logical" context: only 
958 whether they match is considered relevant.  For an example
959 where side-effects of look-ahead I<might> have influenced the
960 following match, see L<C<< (?>pattern) >>>.
961
962 =head2 Version 8 Regular Expressions
963
964 In case you're not familiar with the "regular" Version 8 regex
965 routines, here are the pattern-matching rules not described above.
966
967 Any single character matches itself, unless it is a I<metacharacter>
968 with a special meaning described here or above.  You can cause
969 characters that normally function as metacharacters to be interpreted
970 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
971 character; "\\" matches a "\").  A series of characters matches that
972 series of characters in the target string, so the pattern C<blurfl>
973 would match "blurfl" in the target string.
974
975 You can specify a character class, by enclosing a list of characters
976 in C<[]>, which will match any one character from the list.  If the
977 first character after the "[" is "^", the class matches any character not
978 in the list.  Within a list, the "-" character specifies a
979 range, so that C<a-z> represents all characters between "a" and "z",
980 inclusive.  If you want either "-" or "]" itself to be a member of a
981 class, put it at the start of the list (possibly after a "^"), or
982 escape it with a backslash.  "-" is also taken literally when it is
983 at the end of the list, just before the closing "]".  (The
984 following all specify the same class of three characters: C<[-az]>,
985 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
986 specifies a class containing twenty-six characters, even on EBCDIC
987 based coded character sets.)  Also, if you try to use the character 
988 classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of 
989 a range, that's not a range, the "-" is understood literally.
990
991 Note also that the whole range idea is rather unportable between
992 character sets--and even within character sets they may cause results
993 you probably didn't expect.  A sound principle is to use only ranges
994 that begin from and end at either alphabets of equal case ([a-e],
995 [A-E]), or digits ([0-9]).  Anything else is unsafe.  If in doubt,
996 spell out the character sets in full.
997
998 Characters may be specified using a metacharacter syntax much like that
999 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
1000 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
1001 of octal digits, matches the character whose coded character set value 
1002 is I<nnn>.  Similarly, \xI<nn>, where I<nn> are hexadecimal digits, 
1003 matches the character whose numeric value is I<nn>. The expression \cI<x> 
1004 matches the character control-I<x>.  Finally, the "." metacharacter 
1005 matches any character except "\n" (unless you use C</s>).
1006
1007 You can specify a series of alternatives for a pattern using "|" to
1008 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
1009 or "foe" in the target string (as would C<f(e|i|o)e>).  The
1010 first alternative includes everything from the last pattern delimiter
1011 ("(", "[", or the beginning of the pattern) up to the first "|", and
1012 the last alternative contains everything from the last "|" to the next
1013 pattern delimiter.  That's why it's common practice to include
1014 alternatives in parentheses: to minimize confusion about where they
1015 start and end.
1016
1017 Alternatives are tried from left to right, so the first
1018 alternative found for which the entire expression matches, is the one that
1019 is chosen. This means that alternatives are not necessarily greedy. For
1020 example: when matching C<foo|foot> against "barefoot", only the "foo"
1021 part will match, as that is the first alternative tried, and it successfully
1022 matches the target string. (This might not seem important, but it is
1023 important when you are capturing matched text using parentheses.)
1024
1025 Also remember that "|" is interpreted as a literal within square brackets,
1026 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
1027
1028 Within a pattern, you may designate subpatterns for later reference
1029 by enclosing them in parentheses, and you may refer back to the
1030 I<n>th subpattern later in the pattern using the metacharacter
1031 \I<n>.  Subpatterns are numbered based on the left to right order
1032 of their opening parenthesis.  A backreference matches whatever
1033 actually matched the subpattern in the string being examined, not
1034 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\1\d*> will
1035 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
1036 1 matched "0x", even though the rule C<0|0x> could potentially match
1037 the leading 0 in the second number.
1038
1039 =head2 Warning on \1 vs $1
1040
1041 Some people get too used to writing things like:
1042
1043     $pattern =~ s/(\W)/\\\1/g;
1044
1045 This is grandfathered for the RHS of a substitute to avoid shocking the
1046 B<sed> addicts, but it's a dirty habit to get into.  That's because in
1047 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
1048 the usual double-quoted string means a control-A.  The customary Unix
1049 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
1050 of doing that, you get yourself into trouble if you then add an C</e>
1051 modifier.
1052
1053     s/(\d+)/ \1 + 1 /eg;        # causes warning under -w
1054
1055 Or if you try to do
1056
1057     s/(\d+)/\1000/;
1058
1059 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
1060 C<${1}000>.  The operation of interpolation should not be confused
1061 with the operation of matching a backreference.  Certainly they mean two
1062 different things on the I<left> side of the C<s///>.
1063
1064 =head2 Repeated patterns matching zero-length substring
1065
1066 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
1067
1068 Regular expressions provide a terse and powerful programming language.  As
1069 with most other power tools, power comes together with the ability
1070 to wreak havoc.
1071
1072 A common abuse of this power stems from the ability to make infinite
1073 loops using regular expressions, with something as innocuous as:
1074
1075     'foo' =~ m{ ( o? )* }x;
1076
1077 The C<o?> can match at the beginning of C<'foo'>, and since the position
1078 in the string is not moved by the match, C<o?> would match again and again
1079 because of the C<*> modifier.  Another common way to create a similar cycle
1080 is with the looping modifier C<//g>:
1081
1082     @matches = ( 'foo' =~ m{ o? }xg );
1083
1084 or
1085
1086     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
1087
1088 or the loop implied by split().
1089
1090 However, long experience has shown that many programming tasks may
1091 be significantly simplified by using repeated subexpressions that
1092 may match zero-length substrings.  Here's a simple example being:
1093
1094     @chars = split //, $string;           # // is not magic in split
1095     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
1096
1097 Thus Perl allows such constructs, by I<forcefully breaking
1098 the infinite loop>.  The rules for this are different for lower-level
1099 loops given by the greedy modifiers C<*+{}>, and for higher-level
1100 ones like the C</g> modifier or split() operator.
1101
1102 The lower-level loops are I<interrupted> (that is, the loop is
1103 broken) when Perl detects that a repeated expression matched a
1104 zero-length substring.   Thus
1105
1106    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
1107
1108 is made equivalent to 
1109
1110    m{   (?: NON_ZERO_LENGTH )* 
1111       | 
1112         (?: ZERO_LENGTH )? 
1113     }x;
1114
1115 The higher level-loops preserve an additional state between iterations:
1116 whether the last match was zero-length.  To break the loop, the following 
1117 match after a zero-length match is prohibited to have a length of zero.
1118 This prohibition interacts with backtracking (see L<"Backtracking">), 
1119 and so the I<second best> match is chosen if the I<best> match is of
1120 zero length.
1121
1122 For example:
1123
1124     $_ = 'bar';
1125     s/\w??/<$&>/g;
1126
1127 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
1128 match given by non-greedy C<??> is the zero-length match, and the I<second 
1129 best> match is what is matched by C<\w>.  Thus zero-length matches
1130 alternate with one-character-long matches.
1131
1132 Similarly, for repeated C<m/()/g> the second-best match is the match at the 
1133 position one notch further in the string.
1134
1135 The additional state of being I<matched with zero-length> is associated with
1136 the matched string, and is reset by each assignment to pos().
1137 Zero-length matches at the end of the previous match are ignored
1138 during C<split>.
1139
1140 =head2 Combining pieces together
1141
1142 Each of the elementary pieces of regular expressions which were described
1143 before (such as C<ab> or C<\Z>) could match at most one substring
1144 at the given position of the input string.  However, in a typical regular
1145 expression these elementary pieces are combined into more complicated
1146 patterns using combining operators C<ST>, C<S|T>, C<S*> etc
1147 (in these examples C<S> and C<T> are regular subexpressions).
1148
1149 Such combinations can include alternatives, leading to a problem of choice:
1150 if we match a regular expression C<a|ab> against C<"abc">, will it match
1151 substring C<"a"> or C<"ab">?  One way to describe which substring is
1152 actually matched is the concept of backtracking (see L<"Backtracking">).
1153 However, this description is too low-level and makes you think
1154 in terms of a particular implementation.
1155
1156 Another description starts with notions of "better"/"worse".  All the
1157 substrings which may be matched by the given regular expression can be
1158 sorted from the "best" match to the "worst" match, and it is the "best"
1159 match which is chosen.  This substitutes the question of "what is chosen?"
1160 by the question of "which matches are better, and which are worse?".
1161
1162 Again, for elementary pieces there is no such question, since at most
1163 one match at a given position is possible.  This section describes the
1164 notion of better/worse for combining operators.  In the description
1165 below C<S> and C<T> are regular subexpressions.
1166
1167 =over 4
1168
1169 =item C<ST>
1170
1171 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
1172 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
1173 which can be matched by C<T>. 
1174
1175 If C<A> is better match for C<S> than C<A'>, C<AB> is a better
1176 match than C<A'B'>.
1177
1178 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
1179 C<B> is better match for C<T> than C<B'>.
1180
1181 =item C<S|T>
1182
1183 When C<S> can match, it is a better match than when only C<T> can match.
1184
1185 Ordering of two matches for C<S> is the same as for C<S>.  Similar for
1186 two matches for C<T>.
1187
1188 =item C<S{REPEAT_COUNT}>
1189
1190 Matches as C<SSS...S> (repeated as many times as necessary).
1191
1192 =item C<S{min,max}>
1193
1194 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
1195
1196 =item C<S{min,max}?>
1197
1198 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
1199
1200 =item C<S?>, C<S*>, C<S+>
1201
1202 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
1203
1204 =item C<S??>, C<S*?>, C<S+?>
1205
1206 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
1207
1208 =item C<< (?>S) >>
1209
1210 Matches the best match for C<S> and only that.
1211
1212 =item C<(?=S)>, C<(?<=S)>
1213
1214 Only the best match for C<S> is considered.  (This is important only if
1215 C<S> has capturing parentheses, and backreferences are used somewhere
1216 else in the whole regular expression.)
1217
1218 =item C<(?!S)>, C<(?<!S)>
1219
1220 For this grouping operator there is no need to describe the ordering, since
1221 only whether or not C<S> can match is important.
1222
1223 =item C<(??{ EXPR })>
1224
1225 The ordering is the same as for the regular expression which is
1226 the result of EXPR.
1227
1228 =item C<(?(condition)yes-pattern|no-pattern)>
1229
1230 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
1231 already determined.  The ordering of the matches is the same as for the
1232 chosen subexpression.
1233
1234 =back
1235
1236 The above recipes describe the ordering of matches I<at a given position>.
1237 One more rule is needed to understand how a match is determined for the
1238 whole regular expression: a match at an earlier position is always better
1239 than a match at a later position.
1240
1241 =head2 Creating custom RE engines
1242
1243 Overloaded constants (see L<overload>) provide a simple way to extend
1244 the functionality of the RE engine.
1245
1246 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
1247 matches at boundary between white-space characters and non-whitespace
1248 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
1249 at these positions, so we want to have each C<\Y|> in the place of the
1250 more complicated version.  We can create a module C<customre> to do
1251 this:
1252
1253     package customre;
1254     use overload;
1255
1256     sub import {
1257       shift;
1258       die "No argument to customre::import allowed" if @_;
1259       overload::constant 'qr' => \&convert;
1260     }
1261
1262     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
1263
1264     my %rules = ( '\\' => '\\', 
1265                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
1266     sub convert {
1267       my $re = shift;
1268       $re =~ s{ 
1269                 \\ ( \\ | Y . )
1270               }
1271               { $rules{$1} or invalid($re,$1) }sgex; 
1272       return $re;
1273     }
1274
1275 Now C<use customre> enables the new escape in constant regular
1276 expressions, i.e., those without any runtime variable interpolations.
1277 As documented in L<overload>, this conversion will work only over
1278 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
1279 part of this regular expression needs to be converted explicitly
1280 (but only if the special meaning of C<\Y|> should be enabled inside $re):
1281
1282     use customre;
1283     $re = <>;
1284     chomp $re;
1285     $re = customre::convert $re;
1286     /\Y|$re\Y|/;
1287
1288 =head1 BUGS
1289
1290 This document varies from difficult to understand to completely
1291 and utterly opaque.  The wandering prose riddled with jargon is
1292 hard to fathom in several places.
1293
1294 This document needs a rewrite that separates the tutorial content
1295 from the reference content.
1296
1297 =head1 SEE ALSO
1298
1299 L<perlrequick>.
1300
1301 L<perlretut>.
1302
1303 L<perlop/"Regexp Quote-Like Operators">.
1304
1305 L<perlop/"Gory details of parsing quoted constructs">.
1306
1307 L<perlfaq6>.
1308
1309 L<perlfunc/pos>.
1310
1311 L<perllocale>.
1312
1313 L<perlebcdic>.
1314
1315 I<Mastering Regular Expressions> by Jeffrey Friedl, published
1316 by O'Reilly and Associates.