This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Break upon <filename>:<line>
[perl5.git] / lib / perl5db.pl
1
2 =head1 NAME 
3
4 perl5db.pl - the perl debugger
5
6 =head1 SYNOPSIS
7
8     perl -d  your_Perl_script
9
10 =head1 DESCRIPTION
11
12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
13 you invoke a script with C<perl -d>. This documentation tries to outline the
14 structure and services provided by C<perl5db.pl>, and to describe how you
15 can use them.
16
17 =head1 GENERAL NOTES
18
19 The debugger can look pretty forbidding to many Perl programmers. There are
20 a number of reasons for this, many stemming out of the debugger's history.
21
22 When the debugger was first written, Perl didn't have a lot of its nicer
23 features - no references, no lexical variables, no closures, no object-oriented
24 programming. So a lot of the things one would normally have done using such
25 features was done using global variables, globs and the C<local()> operator 
26 in creative ways.
27
28 Some of these have survived into the current debugger; a few of the more
29 interesting and still-useful idioms are noted in this section, along with notes
30 on the comments themselves.
31
32 =head2 Why not use more lexicals?
33
34 Experienced Perl programmers will note that the debugger code tends to use
35 mostly package globals rather than lexically-scoped variables. This is done
36 to allow a significant amount of control of the debugger from outside the
37 debugger itself.       
38
39 Unfortunately, though the variables are accessible, they're not well
40 documented, so it's generally been a decision that hasn't made a lot of
41 difference to most users. Where appropriate, comments have been added to
42 make variables more accessible and usable, with the understanding that these
43 I<are> debugger internals, and are therefore subject to change. Future
44 development should probably attempt to replace the globals with a well-defined
45 API, but for now, the variables are what we've got.
46
47 =head2 Automated variable stacking via C<local()>
48
49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a 
50 temporary copy of a variable in the current scope. When the scope ends, the
51 old copy is restored. This is often used in the debugger to handle the 
52 automatic stacking of variables during recursive calls:
53
54      sub foo {
55         local $some_global++;
56
57         # Do some stuff, then ...
58         return;
59      }
60
61 What happens is that on entry to the subroutine, C<$some_global> is localized,
62 then altered. When the subroutine returns, Perl automatically undoes the 
63 localization, restoring the previous value. Voila, automatic stack management.
64
65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>, 
66 which lets the debugger get control inside of C<eval>'ed code. The debugger
67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep 
70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
71
72 In any case, watch for this pattern. It occurs fairly often.
73
74 =head2 The C<^> trick
75
76 This is used to cleverly reverse the sense of a logical test depending on 
77 the value of an auxiliary variable. For instance, the debugger's C<S>
78 (search for subroutines by pattern) allows you to negate the pattern 
79 like this:
80
81    # Find all non-'foo' subs:
82    S !/foo/      
83
84 Boolean algebra states that the truth table for XOR looks like this:
85
86 =over 4
87
88 =item * 0 ^ 0 = 0 
89
90 (! not present and no match) --> false, don't print
91
92 =item * 0 ^ 1 = 1 
93
94 (! not present and matches) --> true, print
95
96 =item * 1 ^ 0 = 1 
97
98 (! present and no match) --> true, print
99
100 =item * 1 ^ 1 = 0 
101
102 (! present and matches) --> false, don't print
103
104 =back
105
106 As you can see, the first pair applies when C<!> isn't supplied, and
107 the second pair applies when it is. The XOR simply allows us to
108 compact a more complicated if-then-elseif-else into a more elegant 
109 (but perhaps overly clever) single test. After all, it needed this
110 explanation...
111
112 =head2 FLAGS, FLAGS, FLAGS
113
114 There is a certain C programming legacy in the debugger. Some variables,
115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
117 of state to be stored independently in a single scalar. 
118
119 A test like
120
121     if ($scalar & 4) ...
122
123 is checking to see if the appropriate bit is on. Since each bit can be 
124 "addressed" independently in this way, C<$scalar> is acting sort of like
125 an array of bits. Obviously, since the contents of C<$scalar> are just a 
126 bit-pattern, we can save and restore it easily (it will just look like
127 a number).
128
129 The problem, is of course, that this tends to leave magic numbers scattered
130 all over your program whenever a bit is set, cleared, or checked. So why do 
131 it?
132
133 =over 4
134
135 =item *
136
137 First, doing an arithmetical or bitwise operation on a scalar is
138 just about the fastest thing you can do in Perl: C<use constant> actually
139 creates a subroutine call, and array and hash lookups are much slower. Is
140 this over-optimization at the expense of readability? Possibly, but the 
141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
142 probably have to benchmark alternate implementations and see which is the
143 best balance of readability and speed, and then document how it actually 
144 works.
145
146 =item *
147
148 Second, it's very easy to serialize a scalar number. This is done in 
149 the restart code; the debugger state variables are saved in C<%ENV> and then
150 restored when the debugger is restarted. Having them be just numbers makes
151 this trivial. 
152
153 =item *
154
155 Third, some of these variables are being shared with the Perl core 
156 smack in the middle of the interpreter's execution loop. It's much faster for 
157 a C program (like the interpreter) to check a bit in a scalar than to access 
158 several different variables (or a Perl array).
159
160 =back
161
162 =head2 What are those C<XXX> comments for?
163
164 Any comment containing C<XXX> means that the comment is either somewhat
165 speculative - it's not exactly clear what a given variable or chunk of 
166 code is doing, or that it is incomplete - the basics may be clear, but the
167 subtleties are not completely documented.
168
169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
170
171 =head1 DATA STRUCTURES MAINTAINED BY CORE         
172
173 There are a number of special data structures provided to the debugger by
174 the Perl interpreter.
175
176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
177 via glob assignment) contains the text from C<$filename>, with each
178 element corresponding to a single line of C<$filename>. Additionally,
179 breakable lines will be dualvars with the numeric component being the
180 memory address of a COP node. Non-breakable lines are dualvar to 0.
181
182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob 
183 assignment) contains breakpoints and actions.  The keys are line numbers; 
184 you can set individual values, but not the whole hash. The Perl interpreter 
185 uses this hash to determine where breakpoints have been set. Any true value is
186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
188
189 The scalar C<${"_<$filename"}> simply contains the string C<_<$filename>.
190 This is also the case for evaluated strings that contain subroutines, or
191 which are currently being executed.  The $filename for C<eval>ed strings looks
192 like C<(eval 34)> or C<(re_eval 19)>.
193
194 =head1 DEBUGGER STARTUP
195
196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
198 of options. In addition, this file may define a subroutine C<&afterinit>
199 that will be executed (in the debugger's context) after the debugger has 
200 initialized itself.
201
202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its 
203 contents as the argument of a C<o> command in the debugger.
204
205 =head2 STARTUP-ONLY OPTIONS
206
207 The following options can only be specified at startup.
208 To set them in your rcfile, add a call to
209 C<&parse_options("optionName=new_value")>.
210
211 =over 4
212
213 =item * TTY 
214
215 the TTY to use for debugging i/o.
216
217 =item * noTTY 
218
219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
221 Term::Rendezvous.  Current variant is to have the name of TTY in this
222 file.
223
224 =item * ReadLine 
225
226 if false, a dummy ReadLine is used, so you can debug
227 ReadLine applications.
228
229 =item * NonStop 
230
231 if true, no i/o is performed until interrupt.
232
233 =item * LineInfo 
234
235 file or pipe to print line number info to.  If it is a
236 pipe, a short "emacs like" message is used.
237
238 =item * RemotePort 
239
240 host:port to connect to on remote host for remote debugging.
241
242 =item * HistFile
243
244 file to store session history to. There is no default and so no
245 history file is written unless this variable is explicitly set.
246
247 =item * HistSize
248
249 number of commands to store to the file specified in C<HistFile>.
250 Default is 100.
251
252 =back
253
254 =head3 SAMPLE RCFILE
255
256  &parse_options("NonStop=1 LineInfo=db.out");
257   sub afterinit { $trace = 1; }
258
259 The script will run without human intervention, putting trace
260 information into C<db.out>.  (If you interrupt it, you had better
261 reset C<LineInfo> to something I<interactive>!)
262
263 =head1 INTERNALS DESCRIPTION
264
265 =head2 DEBUGGER INTERFACE VARIABLES
266
267 Perl supplies the values for C<%sub>.  It effectively inserts
268 a C<&DB::DB();> in front of each place that can have a
269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
271 {require 'perl5db.pl'}> before the first line.
272
273 After each C<require>d file is compiled, but before it is executed, a
274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
275 is the expanded name of the C<require>d file (as found via C<%INC>).
276
277 =head3 IMPORTANT INTERNAL VARIABLES
278
279 =head4 C<$CreateTTY>
280
281 Used to control when the debugger will attempt to acquire another TTY to be
282 used for input. 
283
284 =over   
285
286 =item * 1 -  on C<fork()>
287
288 =item * 2 - debugger is started inside debugger
289
290 =item * 4 -  on startup
291
292 =back
293
294 =head4 C<$doret>
295
296 The value -2 indicates that no return value should be printed.
297 Any other positive value causes C<DB::sub> to print return values.
298
299 =head4 C<$evalarg>
300
301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
302 contents of C<@_> when C<DB::eval> is called.
303
304 =head4 C<$frame>
305
306 Determines what messages (if any) will get printed when a subroutine (or eval)
307 is entered or exited. 
308
309 =over 4
310
311 =item * 0 -  No enter/exit messages
312
313 =item * 1 - Print I<entering> messages on subroutine entry
314
315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
316
317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
318
319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
320
321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
322
323 =back
324
325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
326 The debugger internally juggles the value of C<$frame> during execution to
327 protect external modules that the debugger uses from getting traced.
328
329 =head4 C<$level>
330
331 Tracks current debugger nesting level. Used to figure out how many 
332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger 
333 outputs a prompt. Also used to help determine if the program has finished
334 during command parsing.
335
336 =head4 C<$onetimeDump>
337
338 Controls what (if anything) C<DB::eval()> will print after evaluating an
339 expression.
340
341 =over 4
342
343 =item * C<undef> - don't print anything
344
345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
346
347 =item * C<methods> - print the methods callable on the first item returned
348
349 =back
350
351 =head4 C<$onetimeDumpDepth>
352
353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
354 dumping a structure. Numeric. If C<undef>, print all levels.
355
356 =head4 C<$signal>
357
358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
359 which is called before every statement, checks this and puts the user into
360 command mode if it finds C<$signal> set to a true value.
361
362 =head4 C<$single>
363
364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
365 each subroutine; popped again at the end of each subroutine.
366
367 =over 4 
368
369 =item * 0 - run continuously.
370
371 =item * 1 - single-step, go into subs. The C<s> command.
372
373 =item * 2 - single-step, don't go into subs. The C<n> command.
374
375 =item * 4 - print current sub depth (turned on to force this when C<too much
376 recursion> occurs.
377
378 =back
379
380 =head4 C<$trace>
381
382 Controls the output of trace information. 
383
384 =over 4
385
386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
387
388 =item * 2 - watch expressions are active
389
390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
391
392 =back
393
394 =head4 C<$slave_editor>
395
396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
397
398 =head4 C<@cmdfhs>
399
400 Stack of filehandles that C<DB::readline()> will read commands from.
401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
402
403 =head4 C<@dbline>
404
405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> , 
406 supplied by the Perl interpreter to the debugger. Contains the source.
407
408 =head4 C<@old_watch>
409
410 Previous values of watch expressions. First set when the expression is
411 entered; reset whenever the watch expression changes.
412
413 =head4 C<@saved>
414
415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
416 so that the debugger can substitute safe values while it's running, and
417 restore them when it returns control.
418
419 =head4 C<@stack>
420
421 Saves the current value of C<$single> on entry to a subroutine.
422 Manipulated by the C<c> command to turn off tracing in all subs above the
423 current one.
424
425 =head4 C<@to_watch>
426
427 The 'watch' expressions: to be evaluated before each line is executed.
428
429 =head4 C<@typeahead>
430
431 The typeahead buffer, used by C<DB::readline>.
432
433 =head4 C<%alias>
434
435 Command aliases. Stored as character strings to be substituted for a command
436 entered.
437
438 =head4 C<%break_on_load>
439
440 Keys are file names, values are 1 (break when this file is loaded) or undef
441 (don't break when it is loaded).
442
443 =head4 C<%dbline>
444
445 Keys are line numbers, values are C<condition\0action>. If used in numeric
446 context, values are 0 if not breakable, 1 if breakable, no matter what is
447 in the actual hash entry.
448
449 =head4 C<%had_breakpoints>
450
451 Keys are file names; values are bitfields:
452
453 =over 4 
454
455 =item * 1 - file has a breakpoint in it.
456
457 =item * 2 - file has an action in it.
458
459 =back
460
461 A zero or undefined value means this file has neither.
462
463 =head4 C<%option>
464
465 Stores the debugger options. These are character string values.
466
467 =head4 C<%postponed>
468
469 Saves breakpoints for code that hasn't been compiled yet.
470 Keys are subroutine names, values are:
471
472 =over 4
473
474 =item * C<compile> - break when this sub is compiled
475
476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
477
478 =back
479
480 =head4 C<%postponed_file>
481
482 This hash keeps track of breakpoints that need to be set for files that have
483 not yet been compiled. Keys are filenames; values are references to hashes.
484 Each of these hashes is keyed by line number, and its values are breakpoint
485 definitions (C<condition\0action>).
486
487 =head1 DEBUGGER INITIALIZATION
488
489 The debugger's initialization actually jumps all over the place inside this
490 package. This is because there are several BEGIN blocks (which of course 
491 execute immediately) spread through the code. Why is that? 
492
493 The debugger needs to be able to change some things and set some things up 
494 before the debugger code is compiled; most notably, the C<$deep> variable that
495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
496 debugger has to turn off warnings while the debugger code is compiled, but then
497 restore them to their original setting before the program being debugged begins
498 executing.
499
500 The first C<BEGIN> block simply turns off warnings by saving the current
501 setting of C<$^W> and then setting it to zero. The second one initializes
502 the debugger variables that are needed before the debugger begins executing.
503 The third one puts C<$^X> back to its former value. 
504
505 We'll detail the second C<BEGIN> block later; just remember that if you need
506 to initialize something before the debugger starts really executing, that's
507 where it has to go.
508
509 =cut
510
511 package DB;
512
513 BEGIN {eval 'use IO::Handle'};  # Needed for flush only? breaks under miniperl
514
515 BEGIN {
516     require feature;
517     $^V =~ /^v(\d+\.\d+)/;
518     feature->import(":$1");
519 }
520
521 # Debugger for Perl 5.00x; perl5db.pl patch level:
522 $VERSION = '1.34';
523
524 $header = "perl5db.pl version $VERSION";
525
526 =head1 DEBUGGER ROUTINES
527
528 =head2 C<DB::eval()>
529
530 This function replaces straight C<eval()> inside the debugger; it simplifies
531 the process of evaluating code in the user's context.
532
533 The code to be evaluated is passed via the package global variable 
534 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
535
536 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
537 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
538 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
539 user's current package, grabbed when C<DB::DB> got control.  This causes the
540 proper context to be used when the eval is actually done.  Afterward, we
541 restore C<$trace>, C<$single>, and C<$^D>.
542
543 Next we need to handle C<$@> without getting confused. We save C<$@> in a
544 local lexical, localize C<$saved[0]> (which is where C<save()> will put 
545 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>, 
546 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
547 considered sane by the debugger. If there was an C<eval()> error, we print 
548 it on the debugger's output. If C<$onetimedump> is defined, we call 
549 C<dumpit> if it's set to 'dump', or C<methods> if it's set to 
550 'methods'. Setting it to something else causes the debugger to do the eval 
551 but not print the result - handy if you want to do something else with it 
552 (the "watch expressions" code does this to get the value of the watch
553 expression but not show it unless it matters).
554
555 In any case, we then return the list of output from C<eval> to the caller, 
556 and unwinding restores the former version of C<$@> in C<@saved> as well 
557 (the localization of C<$saved[0]> goes away at the end of this scope).
558
559 =head3 Parameters and variables influencing execution of DB::eval()
560
561 C<DB::eval> isn't parameterized in the standard way; this is to keep the
562 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
563 The variables listed below influence C<DB::eval()>'s execution directly. 
564
565 =over 4
566
567 =item C<$evalarg> - the thing to actually be eval'ed
568
569 =item C<$trace> - Current state of execution tracing
570
571 =item C<$single> - Current state of single-stepping
572
573 =item C<$onetimeDump> - what is to be displayed after the evaluation 
574
575 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
576
577 =back
578
579 The following variables are altered by C<DB::eval()> during its execution. They
580 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>. 
581
582 =over 4
583
584 =item C<@res> - used to capture output from actual C<eval>.
585
586 =item C<$otrace> - saved value of C<$trace>.
587
588 =item C<$osingle> - saved value of C<$single>.      
589
590 =item C<$od> - saved value of C<$^D>.
591
592 =item C<$saved[0]> - saved value of C<$@>.
593
594 =item $\ - for output of C<$@> if there is an evaluation error.      
595
596 =back
597
598 =head3 The problem of lexicals
599
600 The context of C<DB::eval()> presents us with some problems. Obviously,
601 we want to be 'sandboxed' away from the debugger's internals when we do
602 the eval, but we need some way to control how punctuation variables and
603 debugger globals are used. 
604
605 We can't use local, because the code inside C<DB::eval> can see localized
606 variables; and we can't use C<my> either for the same reason. The code
607 in this routine compromises and uses C<my>.
608
609 After this routine is over, we don't have user code executing in the debugger's
610 context, so we can use C<my> freely.
611
612 =cut
613
614 ############################################## Begin lexical danger zone
615
616 # 'my' variables used here could leak into (that is, be visible in)
617 # the context that the code being evaluated is executing in. This means that
618 # the code could modify the debugger's variables.
619 #
620 # Fiddling with the debugger's context could be Bad. We insulate things as
621 # much as we can.
622
623 sub eval {
624
625     # 'my' would make it visible from user code
626     #    but so does local! --tchrist
627     # Remember: this localizes @DB::res, not @main::res.
628     local @res;
629     {
630
631         # Try to keep the user code from messing  with us. Save these so that
632         # even if the eval'ed code changes them, we can put them back again.
633         # Needed because the user could refer directly to the debugger's
634         # package globals (and any 'my' variables in this containing scope)
635         # inside the eval(), and we want to try to stay safe.
636         local $otrace  = $trace;
637         local $osingle = $single;
638         local $od      = $^D;
639
640         # Untaint the incoming eval() argument.
641         { ($evalarg) = $evalarg =~ /(.*)/s; }
642
643         # $usercontext built in DB::DB near the comment
644         # "set up the context for DB::eval ..."
645         # Evaluate and save any results.
646         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
647
648         # Restore those old values.
649         $trace  = $otrace;
650         $single = $osingle;
651         $^D     = $od;
652     }
653
654     # Save the current value of $@, and preserve it in the debugger's copy
655     # of the saved precious globals.
656     my $at = $@;
657
658     # Since we're only saving $@, we only have to localize the array element
659     # that it will be stored in.
660     local $saved[0];    # Preserve the old value of $@
661     eval { &DB::save };
662
663     # Now see whether we need to report an error back to the user.
664     if ($at) {
665         local $\ = '';
666         print $OUT $at;
667     }
668
669     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
670     # are package globals.
671     elsif ($onetimeDump) {
672         if ( $onetimeDump eq 'dump' ) {
673             local $option{dumpDepth} = $onetimedumpDepth
674               if defined $onetimedumpDepth;
675             dumpit( $OUT, \@res );
676         }
677         elsif ( $onetimeDump eq 'methods' ) {
678             methods( $res[0] );
679         }
680     } ## end elsif ($onetimeDump)
681     @res;
682 } ## end sub eval
683
684 ############################################## End lexical danger zone
685
686 # After this point it is safe to introduce lexicals.
687 # The code being debugged will be executing in its own context, and
688 # can't see the inside of the debugger.
689 #
690 # However, one should not overdo it: leave as much control from outside as
691 # possible. If you make something a lexical, it's not going to be addressable
692 # from outside the debugger even if you know its name.
693
694 # This file is automatically included if you do perl -d.
695 # It's probably not useful to include this yourself.
696 #
697 # Before venturing further into these twisty passages, it is
698 # wise to read the perldebguts man page or risk the ire of dragons.
699 #
700 # (It should be noted that perldebguts will tell you a lot about
701 # the underlying mechanics of how the debugger interfaces into the
702 # Perl interpreter, but not a lot about the debugger itself. The new
703 # comments in this code try to address this problem.)
704
705 # Note that no subroutine call is possible until &DB::sub is defined
706 # (for subroutines defined outside of the package DB). In fact the same is
707 # true if $deep is not defined.
708
709 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
710
711 # modified Perl debugger, to be run from Emacs in perldb-mode
712 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
713 # Johan Vromans -- upgrade to 4.0 pl 10
714 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
715
716 # (We have made efforts to  clarify the comments in the change log
717 # in other places; some of them may seem somewhat obscure as they
718 # were originally written, and explaining them away from the code
719 # in question seems conterproductive.. -JM)
720
721 ########################################################################
722 # Changes: 0.94
723 #   + A lot of things changed after 0.94. First of all, core now informs
724 #     debugger about entry into XSUBs, overloaded operators, tied operations,
725 #     BEGIN and END. Handy with `O f=2'.
726 #   + This can make debugger a little bit too verbose, please be patient
727 #     and report your problems promptly.
728 #   + Now the option frame has 3 values: 0,1,2. XXX Document!
729 #   + Note that if DESTROY returns a reference to the object (or object),
730 #     the deletion of data may be postponed until the next function call,
731 #     due to the need to examine the return value.
732 #
733 # Changes: 0.95
734 #   + `v' command shows versions.
735 #
736 # Changes: 0.96
737 #   + `v' command shows version of readline.
738 #     primitive completion works (dynamic variables, subs for `b' and `l',
739 #     options). Can `p %var'
740 #   + Better help (`h <' now works). New commands <<, >>, {, {{.
741 #     {dump|print}_trace() coded (to be able to do it from <<cmd).
742 #   + `c sub' documented.
743 #   + At last enough magic combined to stop after the end of debuggee.
744 #   + !! should work now (thanks to Emacs bracket matching an extra
745 #     `]' in a regexp is caught).
746 #   + `L', `D' and `A' span files now (as documented).
747 #   + Breakpoints in `require'd code are possible (used in `R').
748 #   +  Some additional words on internal work of debugger.
749 #   + `b load filename' implemented.
750 #   + `b postpone subr' implemented.
751 #   + now only `q' exits debugger (overwritable on $inhibit_exit).
752 #   + When restarting debugger breakpoints/actions persist.
753 #   + Buglet: When restarting debugger only one breakpoint/action per
754 #             autoloaded function persists.
755 #
756 # Changes: 0.97: NonStop will not stop in at_exit().
757 #   + Option AutoTrace implemented.
758 #   + Trace printed differently if frames are printed too.
759 #   + new `inhibitExit' option.
760 #   + printing of a very long statement interruptible.
761 # Changes: 0.98: New command `m' for printing possible methods
762 #   + 'l -' is a synonym for `-'.
763 #   + Cosmetic bugs in printing stack trace.
764 #   +  `frame' & 8 to print "expanded args" in stack trace.
765 #   + Can list/break in imported subs.
766 #   + new `maxTraceLen' option.
767 #   + frame & 4 and frame & 8 granted.
768 #   + new command `m'
769 #   + nonstoppable lines do not have `:' near the line number.
770 #   + `b compile subname' implemented.
771 #   + Will not use $` any more.
772 #   + `-' behaves sane now.
773 # Changes: 0.99: Completion for `f', `m'.
774 #   +  `m' will remove duplicate names instead of duplicate functions.
775 #   + `b load' strips trailing whitespace.
776 #     completion ignores leading `|'; takes into account current package
777 #     when completing a subroutine name (same for `l').
778 # Changes: 1.07: Many fixed by tchrist 13-March-2000
779 #   BUG FIXES:
780 #   + Added bare minimal security checks on perldb rc files, plus
781 #     comments on what else is needed.
782 #   + Fixed the ornaments that made "|h" completely unusable.
783 #     They are not used in print_help if they will hurt.  Strip pod
784 #     if we're paging to less.
785 #   + Fixed mis-formatting of help messages caused by ornaments
786 #     to restore Larry's original formatting.
787 #   + Fixed many other formatting errors.  The code is still suboptimal,
788 #     and needs a lot of work at restructuring.  It's also misindented
789 #     in many places.
790 #   + Fixed bug where trying to look at an option like your pager
791 #     shows "1".
792 #   + Fixed some $? processing.  Note: if you use csh or tcsh, you will
793 #     lose.  You should consider shell escapes not using their shell,
794 #     or else not caring about detailed status.  This should really be
795 #     unified into one place, too.
796 #   + Fixed bug where invisible trailing whitespace on commands hoses you,
797 #     tricking Perl into thinking you weren't calling a debugger command!
798 #   + Fixed bug where leading whitespace on commands hoses you.  (One
799 #     suggests a leading semicolon or any other irrelevant non-whitespace
800 #     to indicate literal Perl code.)
801 #   + Fixed bugs that ate warnings due to wrong selected handle.
802 #   + Fixed a precedence bug on signal stuff.
803 #   + Fixed some unseemly wording.
804 #   + Fixed bug in help command trying to call perl method code.
805 #   + Fixed to call dumpvar from exception handler.  SIGPIPE killed us.
806 #   ENHANCEMENTS:
807 #   + Added some comments.  This code is still nasty spaghetti.
808 #   + Added message if you clear your pre/post command stacks which was
809 #     very easy to do if you just typed a bare >, <, or {.  (A command
810 #     without an argument should *never* be a destructive action; this
811 #     API is fundamentally screwed up; likewise option setting, which
812 #     is equally buggered.)
813 #   + Added command stack dump on argument of "?" for >, <, or {.
814 #   + Added a semi-built-in doc viewer command that calls man with the
815 #     proper %Config::Config path (and thus gets caching, man -k, etc),
816 #     or else perldoc on obstreperous platforms.
817 #   + Added to and rearranged the help information.
818 #   + Detected apparent misuse of { ... } to declare a block; this used
819 #     to work but now is a command, and mysteriously gave no complaint.
820 #
821 # Changes: 1.08: Apr 25, 2001  Jon Eveland <jweveland@yahoo.com>
822 #   BUG FIX:
823 #   + This patch to perl5db.pl cleans up formatting issues on the help
824 #     summary (h h) screen in the debugger.  Mostly columnar alignment
825 #     issues, plus converted the printed text to use all spaces, since
826 #     tabs don't seem to help much here.
827 #
828 # Changes: 1.09: May 19, 2001  Ilya Zakharevich <ilya@math.ohio-state.edu>
829 #   Minor bugs corrected;
830 #   + Support for auto-creation of new TTY window on startup, either
831 #     unconditionally, or if started as a kid of another debugger session;
832 #   + New `O'ption CreateTTY
833 #       I<CreateTTY>      bits control attempts to create a new TTY on events:
834 #                         1: on fork()
835 #                         2: debugger is started inside debugger
836 #                         4: on startup
837 #   + Code to auto-create a new TTY window on OS/2 (currently one
838 #     extra window per session - need named pipes to have more...);
839 #   + Simplified interface for custom createTTY functions (with a backward
840 #     compatibility hack); now returns the TTY name to use; return of ''
841 #     means that the function reset the I/O handles itself;
842 #   + Better message on the semantic of custom createTTY function;
843 #   + Convert the existing code to create a TTY into a custom createTTY
844 #     function;
845 #   + Consistent support for TTY names of the form "TTYin,TTYout";
846 #   + Switch line-tracing output too to the created TTY window;
847 #   + make `b fork' DWIM with CORE::GLOBAL::fork;
848 #   + High-level debugger API cmd_*():
849 #      cmd_b_load($filenamepart)            # b load filenamepart
850 #      cmd_b_line($lineno [, $cond])        # b lineno [cond]
851 #      cmd_b_sub($sub [, $cond])            # b sub [cond]
852 #      cmd_stop()                           # Control-C
853 #      cmd_d($lineno)                       # d lineno (B)
854 #      The cmd_*() API returns FALSE on failure; in this case it outputs
855 #      the error message to the debugging output.
856 #   + Low-level debugger API
857 #      break_on_load($filename)             # b load filename
858 #      @files = report_break_on_load()      # List files with load-breakpoints
859 #      breakable_line_in_filename($name, $from [, $to])
860 #                                           # First breakable line in the
861 #                                           # range $from .. $to.  $to defaults
862 #                                           # to $from, and may be less than
863 #                                           # $to
864 #      breakable_line($from [, $to])        # Same for the current file
865 #      break_on_filename_line($name, $lineno [, $cond])
866 #                                           # Set breakpoint,$cond defaults to
867 #                                           # 1
868 #      break_on_filename_line_range($name, $from, $to [, $cond])
869 #                                           # As above, on the first
870 #                                           # breakable line in range
871 #      break_on_line($lineno [, $cond])     # As above, in the current file
872 #      break_subroutine($sub [, $cond])     # break on the first breakable line
873 #      ($name, $from, $to) = subroutine_filename_lines($sub)
874 #                                           # The range of lines of the text
875 #      The low-level API returns TRUE on success, and die()s on failure.
876 #
877 # Changes: 1.10: May 23, 2001  Daniel Lewart <d-lewart@uiuc.edu>
878 #   BUG FIXES:
879 #   + Fixed warnings generated by "perl -dWe 42"
880 #   + Corrected spelling errors
881 #   + Squeezed Help (h) output into 80 columns
882 #
883 # Changes: 1.11: May 24, 2001  David Dyck <dcd@tc.fluke.com>
884 #   + Made "x @INC" work like it used to
885 #
886 # Changes: 1.12: May 24, 2001  Daniel Lewart <d-lewart@uiuc.edu>
887 #   + Fixed warnings generated by "O" (Show debugger options)
888 #   + Fixed warnings generated by "p 42" (Print expression)
889 # Changes: 1.13: Jun 19, 2001 Scott.L.Miller@compaq.com
890 #   + Added windowSize option
891 # Changes: 1.14: Oct  9, 2001 multiple
892 #   + Clean up after itself on VMS (Charles Lane in 12385)
893 #   + Adding "@ file" syntax (Peter Scott in 12014)
894 #   + Debug reloading selfloaded stuff (Ilya Zakharevich in 11457)
895 #   + $^S and other debugger fixes (Ilya Zakharevich in 11120)
896 #   + Forgot a my() declaration (Ilya Zakharevich in 11085)
897 # Changes: 1.15: Nov  6, 2001 Michael G Schwern <schwern@pobox.com>
898 #   + Updated 1.14 change log
899 #   + Added *dbline explanatory comments
900 #   + Mentioning perldebguts man page
901 # Changes: 1.16: Feb 15, 2002 Mark-Jason Dominus <mjd@plover.com>
902 #   + $onetimeDump improvements
903 # Changes: 1.17: Feb 20, 2002 Richard Foley <richard.foley@rfi.net>
904 #   Moved some code to cmd_[.]()'s for clarity and ease of handling,
905 #   rationalised the following commands and added cmd_wrapper() to
906 #   enable switching between old and frighteningly consistent new
907 #   behaviours for diehards: 'o CommandSet=pre580' (sigh...)
908 #     a(add),       A(del)            # action expr   (added del by line)
909 #   + b(add),       B(del)            # break  [line] (was b,D)
910 #   + w(add),       W(del)            # watch  expr   (was W,W)
911 #                                     # added del by expr
912 #   + h(summary), h h(long)           # help (hh)     (was h h,h)
913 #   + m(methods),   M(modules)        # ...           (was m,v)
914 #   + o(option)                       # lc            (was O)
915 #   + v(view code), V(view Variables) # ...           (was w,V)
916 # Changes: 1.18: Mar 17, 2002 Richard Foley <richard.foley@rfi.net>
917 #   + fixed missing cmd_O bug
918 # Changes: 1.19: Mar 29, 2002 Spider Boardman
919 #   + Added missing local()s -- DB::DB is called recursively.
920 # Changes: 1.20: Feb 17, 2003 Richard Foley <richard.foley@rfi.net>
921 #   + pre'n'post commands no longer trashed with no args
922 #   + watch val joined out of eval()
923 # Changes: 1.21: Jun 04, 2003 Joe McMahon <mcmahon@ibiblio.org>
924 #   + Added comments and reformatted source. No bug fixes/enhancements.
925 #   + Includes cleanup by Robin Barker and Jarkko Hietaniemi.
926 # Changes: 1.22  Jun 09, 2003 Alex Vandiver <alexmv@MIT.EDU>
927 #   + Flush stdout/stderr before the debugger prompt is printed.
928 # Changes: 1.23: Dec 21, 2003 Dominique Quatravaux
929 #   + Fix a side-effect of bug #24674 in the perl debugger ("odd taint bug")
930 # Changes: 1.24: Mar 03, 2004 Richard Foley <richard.foley@rfi.net>
931 #   + Added command to save all debugger commands for sourcing later.
932 #   + Added command to display parent inheritance tree of given class.
933 #   + Fixed minor newline in history bug.
934 # Changes: 1.25: Apr 17, 2004 Richard Foley <richard.foley@rfi.net>
935 #   + Fixed option bug (setting invalid options + not recognising valid short forms)
936 # Changes: 1.26: Apr 22, 2004 Richard Foley <richard.foley@rfi.net>
937 #   + unfork the 5.8.x and 5.9.x debuggers.
938 #   + whitespace and assertions call cleanup across versions 
939 #   + H * deletes (resets) history
940 #   + i now handles Class + blessed objects
941 # Changes: 1.27: May 09, 2004 Richard Foley <richard.foley@rfi.net>
942 #   + updated pod page references - clunky.
943 #   + removed windowid restriction for forking into an xterm.
944 #   + more whitespace again.
945 #   + wrapped restart and enabled rerun [-n] (go back n steps) command.
946 # Changes: 1.28: Oct 12, 2004 Richard Foley <richard.foley@rfi.net>
947 #   + Added threads support (inc. e and E commands)
948 # Changes: 1.29: Nov 28, 2006 Bo Lindbergh <blgl@hagernas.com> 
949 #   + Added macosx_get_fork_TTY support 
950 # Changes: 1.30: Mar 06, 2007 Andreas Koenig <andk@cpan.org>
951 #   + Added HistFile, HistSize
952 # Changes: 1.31
953 #   + Remove support for assertions and -A
954 #   + stop NEXT::AUTOLOAD from emitting warnings under the debugger. RT #25053
955 #   + "update for Mac OS X 10.5" [finding the tty device]
956 #   + "What I needed to get the forked debugger to work" [on VMS]
957 #   + [perl #57016] debugger: o warn=0 die=0 ignored
958 #   + Note, but don't use, PERLDBf_SAVESRC
959 #   + Fix #7013: lvalue subs not working inside debugger
960 # Changes: 1.32: Jun 03, 2009 Jonathan Leto <jonathan@leto.net>
961 #   + Fix bug where a key _< with undefined value was put into the symbol table
962 #   +   when the $filename variable is not set
963 # Changes: 1.33:
964 #   + Debugger prints lines to the remote port when it forks and openes a new port (f633fd2)
965 #   + The debugger now continues to use RemotePort when it's been configured to use it. (11653f7)
966 #   + Stop using $ENV{LESS} for parameters not intended for less (d463cf2)
967 #   + Configure has a path to less and perl5db.pl can use it (bf320d6)
968 #   + Die with $@ instead of empty message (86755f4)
969 #   + Remove extra/useless $@ check after eval { require PadWalker } (which is still checked) (dab8d6d)
970 #   + Promote eval( "require ..." ) to eval { require ... } (4a49187)
971 #   + Promote eval { require( ... )} || die to mere require( ... ) (999f23b)
972 #   + Remove indirect object notation from debugger (bee4b46)
973 #   + Document that @{$main::{'_<'.$filename}} lines are dualvar to (COP*). (7e17a74)
974 #   + Remove MacOS classic support from the debugger. (2b894b7)
975 ########################################################################
976
977 =head1 DEBUGGER INITIALIZATION
978
979 The debugger starts up in phases.
980
981 =head2 BASIC SETUP
982
983 First, it initializes the environment it wants to run in: turning off
984 warnings during its own compilation, defining variables which it will need
985 to avoid warnings later, setting itself up to not exit when the program
986 terminates, and defaulting to printing return values for the C<r> command.
987
988 =cut
989
990 # Needed for the statement after exec():
991 #
992 # This BEGIN block is simply used to switch off warnings during debugger
993 # compilation. Probably it would be better practice to fix the warnings,
994 # but this is how it's done at the moment.
995
996 BEGIN {
997     $ini_warn = $^W;
998     $^W       = 0;
999 }    # Switch compilation warnings off until another BEGIN.
1000
1001 local ($^W) = 0;    # Switch run-time warnings off during init.
1002
1003 =head2 THREADS SUPPORT
1004
1005 If we are running under a threaded Perl, we require threads and threads::shared
1006 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
1007 threaded debugger control.  C<-dt> can also be used to set this.
1008
1009 Each new thread will be announced and the debugger prompt will always inform
1010 you of each new thread created.  It will also indicate the thread id in which
1011 we are currently running within the prompt like this:
1012
1013         [tid] DB<$i>
1014
1015 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
1016 command prompt.  The prompt will show: C<[0]> when running under threads, but
1017 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
1018
1019 While running under threads, when you set or delete a breakpoint (etc.), this
1020 will apply to all threads, not just the currently running one.  When you are 
1021 in a currently executing thread, you will stay there until it completes.  With
1022 the current implementation it is not currently possible to hop from one thread
1023 to another.
1024
1025 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
1026
1027 Note that threading support was built into the debugger as of Perl version
1028 C<5.8.6> and debugger version C<1.2.8>.
1029
1030 =cut
1031
1032 BEGIN {
1033   # ensure we can share our non-threaded variables or no-op
1034   if ($ENV{PERL5DB_THREADED}) {
1035         require threads;
1036         require threads::shared;
1037         import threads::shared qw(share);
1038         $DBGR;
1039         share(\$DBGR);
1040         lock($DBGR);
1041         print "Threads support enabled\n";
1042   } else {
1043         *lock  = sub(*) {};
1044         *share = sub(*) {};
1045   }
1046 }
1047
1048 # This would probably be better done with "use vars", but that wasn't around
1049 # when this code was originally written. (Neither was "use strict".) And on
1050 # the principle of not fiddling with something that was working, this was
1051 # left alone.
1052 warn(               # Do not ;-)
1053     # These variables control the execution of 'dumpvar.pl'.
1054     $dumpvar::hashDepth,
1055     $dumpvar::arrayDepth,
1056     $dumpvar::dumpDBFiles,
1057     $dumpvar::dumpPackages,
1058     $dumpvar::quoteHighBit,
1059     $dumpvar::printUndef,
1060     $dumpvar::globPrint,
1061     $dumpvar::usageOnly,
1062
1063     # used to save @ARGV and extract any debugger-related flags.
1064     @ARGS,
1065
1066     # used to control die() reporting in diesignal()
1067     $Carp::CarpLevel,
1068
1069     # used to prevent multiple entries to diesignal()
1070     # (if for instance diesignal() itself dies)
1071     $panic,
1072
1073     # used to prevent the debugger from running nonstop
1074     # after a restart
1075     $second_time,
1076   )
1077   if 0;
1078
1079 # without threads, $filename is not defined until DB::DB is called
1080 foreach my $k (keys (%INC)) {
1081         &share(\$main::{'_<'.$filename}) if defined $filename;
1082 };
1083
1084 # Command-line + PERLLIB:
1085 # Save the contents of @INC before they are modified elsewhere.
1086 @ini_INC = @INC;
1087
1088 # This was an attempt to clear out the previous values of various
1089 # trapped errors. Apparently it didn't help. XXX More info needed!
1090 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
1091
1092 # We set these variables to safe values. We don't want to blindly turn
1093 # off warnings, because other packages may still want them.
1094 $trace = $signal = $single = 0;    # Uninitialized warning suppression
1095                                    # (local $^W cannot help - other packages!).
1096
1097 # Default to not exiting when program finishes; print the return
1098 # value when the 'r' command is used to return from a subroutine.
1099 $inhibit_exit = $option{PrintRet} = 1;
1100
1101 =head1 OPTION PROCESSING
1102
1103 The debugger's options are actually spread out over the debugger itself and 
1104 C<dumpvar.pl>; some of these are variables to be set, while others are 
1105 subs to be called with a value. To try to make this a little easier to
1106 manage, the debugger uses a few data structures to define what options
1107 are legal and how they are to be processed.
1108
1109 First, the C<@options> array defines the I<names> of all the options that
1110 are to be accepted.
1111
1112 =cut
1113
1114 @options = qw(
1115   CommandSet   HistFile      HistSize
1116   hashDepth    arrayDepth    dumpDepth
1117   DumpDBFiles  DumpPackages  DumpReused
1118   compactDump  veryCompact   quote
1119   HighBit      undefPrint    globPrint
1120   PrintRet     UsageOnly     frame
1121   AutoTrace    TTY           noTTY
1122   ReadLine     NonStop       LineInfo
1123   maxTraceLen  recallCommand ShellBang
1124   pager        tkRunning     ornaments
1125   signalLevel  warnLevel     dieLevel
1126   inhibit_exit ImmediateStop bareStringify
1127   CreateTTY    RemotePort    windowSize
1128   DollarCaretP
1129 );
1130
1131 @RememberOnROptions = qw(DollarCaretP);
1132
1133 =pod
1134
1135 Second, C<optionVars> lists the variables that each option uses to save its
1136 state.
1137
1138 =cut
1139
1140 %optionVars = (
1141     hashDepth     => \$dumpvar::hashDepth,
1142     arrayDepth    => \$dumpvar::arrayDepth,
1143     CommandSet    => \$CommandSet,
1144     DumpDBFiles   => \$dumpvar::dumpDBFiles,
1145     DumpPackages  => \$dumpvar::dumpPackages,
1146     DumpReused    => \$dumpvar::dumpReused,
1147     HighBit       => \$dumpvar::quoteHighBit,
1148     undefPrint    => \$dumpvar::printUndef,
1149     globPrint     => \$dumpvar::globPrint,
1150     UsageOnly     => \$dumpvar::usageOnly,
1151     CreateTTY     => \$CreateTTY,
1152     bareStringify => \$dumpvar::bareStringify,
1153     frame         => \$frame,
1154     AutoTrace     => \$trace,
1155     inhibit_exit  => \$inhibit_exit,
1156     maxTraceLen   => \$maxtrace,
1157     ImmediateStop => \$ImmediateStop,
1158     RemotePort    => \$remoteport,
1159     windowSize    => \$window,
1160     HistFile      => \$histfile,
1161     HistSize      => \$histsize,
1162 );
1163
1164 =pod
1165
1166 Third, C<%optionAction> defines the subroutine to be called to process each
1167 option.
1168
1169 =cut 
1170
1171 %optionAction = (
1172     compactDump   => \&dumpvar::compactDump,
1173     veryCompact   => \&dumpvar::veryCompact,
1174     quote         => \&dumpvar::quote,
1175     TTY           => \&TTY,
1176     noTTY         => \&noTTY,
1177     ReadLine      => \&ReadLine,
1178     NonStop       => \&NonStop,
1179     LineInfo      => \&LineInfo,
1180     recallCommand => \&recallCommand,
1181     ShellBang     => \&shellBang,
1182     pager         => \&pager,
1183     signalLevel   => \&signalLevel,
1184     warnLevel     => \&warnLevel,
1185     dieLevel      => \&dieLevel,
1186     tkRunning     => \&tkRunning,
1187     ornaments     => \&ornaments,
1188     RemotePort    => \&RemotePort,
1189     DollarCaretP  => \&DollarCaretP,
1190 );
1191
1192 =pod
1193
1194 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1195 option is used.
1196
1197 =cut
1198
1199 # Note that this list is not complete: several options not listed here
1200 # actually require that dumpvar.pl be loaded for them to work, but are
1201 # not in the table. A subsequent patch will correct this problem; for
1202 # the moment, we're just recommenting, and we are NOT going to change
1203 # function.
1204 %optionRequire = (
1205     compactDump => 'dumpvar.pl',
1206     veryCompact => 'dumpvar.pl',
1207     quote       => 'dumpvar.pl',
1208 );
1209
1210 =pod
1211
1212 There are a number of initialization-related variables which can be set
1213 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1214 variable. These are:
1215
1216 =over 4
1217
1218 =item C<$rl> - readline control XXX needs more explanation
1219
1220 =item C<$warnLevel> - whether or not debugger takes over warning handling
1221
1222 =item C<$dieLevel> - whether or not debugger takes over die handling
1223
1224 =item C<$signalLevel> - whether or not debugger takes over signal handling
1225
1226 =item C<$pre> - preprompt actions (array reference)
1227
1228 =item C<$post> - postprompt actions (array reference)
1229
1230 =item C<$pretype>
1231
1232 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1233
1234 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1235
1236 =back
1237
1238 =cut
1239
1240 # These guys may be defined in $ENV{PERL5DB} :
1241 $rl          = 1     unless defined $rl;
1242 $warnLevel   = 1     unless defined $warnLevel;
1243 $dieLevel    = 1     unless defined $dieLevel;
1244 $signalLevel = 1     unless defined $signalLevel;
1245 $pre         = []    unless defined $pre;
1246 $post        = []    unless defined $post;
1247 $pretype     = []    unless defined $pretype;
1248 $CreateTTY   = 3     unless defined $CreateTTY;
1249 $CommandSet  = '580' unless defined $CommandSet;
1250
1251 share($rl);
1252 share($warnLevel);
1253 share($dieLevel);
1254 share($signalLevel);
1255 share($pre);
1256 share($post);
1257 share($pretype);
1258 share($rl);
1259 share($CreateTTY);
1260 share($CommandSet);
1261
1262 =pod
1263
1264 The default C<die>, C<warn>, and C<signal> handlers are set up.
1265
1266 =cut
1267
1268 warnLevel($warnLevel);
1269 dieLevel($dieLevel);
1270 signalLevel($signalLevel);
1271
1272 =pod
1273
1274 The pager to be used is needed next. We try to get it from the
1275 environment first.  If it's not defined there, we try to find it in
1276 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1277 then call the C<pager()> function to save the pager name.
1278
1279 =cut
1280
1281 # This routine makes sure $pager is set up so that '|' can use it.
1282 pager(
1283
1284     # If PAGER is defined in the environment, use it.
1285     defined $ENV{PAGER}
1286     ? $ENV{PAGER}
1287
1288       # If not, see if Config.pm defines it.
1289     : eval { require Config }
1290       && defined $Config::Config{pager}
1291     ? $Config::Config{pager}
1292
1293       # If not, fall back to 'more'.
1294     : 'more'
1295   )
1296   unless defined $pager;
1297
1298 =pod
1299
1300 We set up the command to be used to access the man pages, the command
1301 recall character (C<!> unless otherwise defined) and the shell escape
1302 character (C<!> unless otherwise defined). Yes, these do conflict, and
1303 neither works in the debugger at the moment.
1304
1305 =cut
1306
1307 setman();
1308
1309 # Set up defaults for command recall and shell escape (note:
1310 # these currently don't work in linemode debugging).
1311 &recallCommand("!") unless defined $prc;
1312 &shellBang("!")     unless defined $psh;
1313
1314 =pod
1315
1316 We then set up the gigantic string containing the debugger help.
1317 We also set the limit on the number of arguments we'll display during a
1318 trace.
1319
1320 =cut
1321
1322 sethelp();
1323
1324 # If we didn't get a default for the length of eval/stack trace args,
1325 # set it here.
1326 $maxtrace = 400 unless defined $maxtrace;
1327
1328 =head2 SETTING UP THE DEBUGGER GREETING
1329
1330 The debugger I<greeting> helps to inform the user how many debuggers are
1331 running, and whether the current debugger is the primary or a child.
1332
1333 If we are the primary, we just hang onto our pid so we'll have it when
1334 or if we start a child debugger. If we are a child, we'll set things up
1335 so we'll have a unique greeting and so the parent will give us our own
1336 TTY later.
1337
1338 We save the current contents of the C<PERLDB_PIDS> environment variable
1339 because we mess around with it. We'll also need to hang onto it because
1340 we'll need it if we restart.
1341
1342 Child debuggers make a label out of the current PID structure recorded in
1343 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1344 yet so the parent will give them one later via C<resetterm()>.
1345
1346 =cut
1347
1348 # Save the current contents of the environment; we're about to
1349 # much with it. We'll need this if we have to restart.
1350 $ini_pids = $ENV{PERLDB_PIDS};
1351
1352 if ( defined $ENV{PERLDB_PIDS} ) {
1353
1354     # We're a child. Make us a label out of the current PID structure
1355     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1356     # a term yet so the parent will give us one later via resetterm().
1357
1358     my $env_pids = $ENV{PERLDB_PIDS};
1359     $pids = "[$env_pids]";
1360
1361     # Unless we are on OpenVMS, all programs under the DCL shell run under
1362     # the same PID.
1363
1364     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1365         $term_pid         = $$;
1366     }
1367     else {
1368         $ENV{PERLDB_PIDS} .= "->$$";
1369         $term_pid = -1;
1370     }
1371
1372 } ## end if (defined $ENV{PERLDB_PIDS...
1373 else {
1374
1375     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1376     # child debugger, and mark us as the parent, so we'll know to set up
1377     # more TTY's is we have to.
1378     $ENV{PERLDB_PIDS} = "$$";
1379     $pids             = "[pid=$$]";
1380     $term_pid         = $$;
1381 }
1382
1383 $pidprompt = '';
1384
1385 # Sets up $emacs as a synonym for $slave_editor.
1386 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1387
1388 =head2 READING THE RC FILE
1389
1390 The debugger will read a file of initialization options if supplied. If    
1391 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1392
1393 =cut      
1394
1395 # As noted, this test really doesn't check accurately that the debugger
1396 # is running at a terminal or not.
1397
1398 my $dev_tty = '/dev/tty';
1399    $dev_tty = 'TT:' if ($^O eq 'VMS');
1400 if ( -e $dev_tty ) {                      # this is the wrong metric!
1401     $rcfile = ".perldb";
1402 }
1403 else {
1404     $rcfile = "perldb.ini";
1405 }
1406
1407 =pod
1408
1409 The debugger does a safety test of the file to be read. It must be owned
1410 either by the current user or root, and must only be writable by the owner.
1411
1412 =cut
1413
1414 # This wraps a safety test around "do" to read and evaluate the init file.
1415 #
1416 # This isn't really safe, because there's a race
1417 # between checking and opening.  The solution is to
1418 # open and fstat the handle, but then you have to read and
1419 # eval the contents.  But then the silly thing gets
1420 # your lexical scope, which is unfortunate at best.
1421 sub safe_do {
1422     my $file = shift;
1423
1424     # Just exactly what part of the word "CORE::" don't you understand?
1425     local $SIG{__WARN__};
1426     local $SIG{__DIE__};
1427
1428     unless ( is_safe_file($file) ) {
1429         CORE::warn <<EO_GRIPE;
1430 perldb: Must not source insecure rcfile $file.
1431         You or the superuser must be the owner, and it must not 
1432         be writable by anyone but its owner.
1433 EO_GRIPE
1434         return;
1435     } ## end unless (is_safe_file($file...
1436
1437     do $file;
1438     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1439 } ## end sub safe_do
1440
1441 # This is the safety test itself.
1442 #
1443 # Verifies that owner is either real user or superuser and that no
1444 # one but owner may write to it.  This function is of limited use
1445 # when called on a path instead of upon a handle, because there are
1446 # no guarantees that filename (by dirent) whose file (by ino) is
1447 # eventually accessed is the same as the one tested.
1448 # Assumes that the file's existence is not in doubt.
1449 sub is_safe_file {
1450     my $path = shift;
1451     stat($path) || return;    # mysteriously vaporized
1452     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1453
1454     return 0 if $uid != 0 && $uid != $<;
1455     return 0 if $mode & 022;
1456     return 1;
1457 } ## end sub is_safe_file
1458
1459 # If the rcfile (whichever one we decided was the right one to read)
1460 # exists, we safely do it.
1461 if ( -f $rcfile ) {
1462     safe_do("./$rcfile");
1463 }
1464
1465 # If there isn't one here, try the user's home directory.
1466 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1467     safe_do("$ENV{HOME}/$rcfile");
1468 }
1469
1470 # Else try the login directory.
1471 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1472     safe_do("$ENV{LOGDIR}/$rcfile");
1473 }
1474
1475 # If the PERLDB_OPTS variable has options in it, parse those out next.
1476 if ( defined $ENV{PERLDB_OPTS} ) {
1477     parse_options( $ENV{PERLDB_OPTS} );
1478 }
1479
1480 =pod
1481
1482 The last thing we do during initialization is determine which subroutine is
1483 to be used to obtain a new terminal when a new debugger is started. Right now,
1484 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1485 (darwin).
1486
1487 =cut
1488
1489 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1490 # Works if you're running an xterm or xterm-like window, or you're on
1491 # OS/2, or on Mac OS X. This may need some expansion.
1492
1493 if (not defined &get_fork_TTY)       # only if no routine exists
1494 {
1495     if ( defined $remoteport ) {                 
1496                                                  # Expect an inetd-like server
1497         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1498     }
1499     elsif (defined $ENV{TERM}                    # If we know what kind
1500                                                  # of terminal this is,
1501         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1502         and defined $ENV{DISPLAY}                # and what display it's on,
1503       )
1504     {
1505         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1506     }
1507     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1508         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1509     }
1510     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1511             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1512             and $ENV{TERM_PROGRAM}
1513                 eq 'Apple_Terminal'              # Terminal.app
1514             )
1515     {
1516         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1517     }
1518 } ## end if (not defined &get_fork_TTY...
1519
1520 # untaint $^O, which may have been tainted by the last statement.
1521 # see bug [perl #24674]
1522 $^O =~ m/^(.*)\z/;
1523 $^O = $1;
1524
1525 # Here begin the unreadable code.  It needs fixing.
1526
1527 =head2 RESTART PROCESSING
1528
1529 This section handles the restart command. When the C<R> command is invoked, it
1530 tries to capture all of the state it can into environment variables, and
1531 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1532 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1533 the R command stuffed into the environment variables.
1534
1535   PERLDB_RESTART   - flag only, contains no restart data itself.       
1536   PERLDB_HIST      - command history, if it's available
1537   PERLDB_ON_LOAD   - breakpoints set by the rc file
1538   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1539   PERLDB_VISITED   - files that had breakpoints
1540   PERLDB_FILE_...  - breakpoints for a file
1541   PERLDB_OPT       - active options
1542   PERLDB_INC       - the original @INC
1543   PERLDB_PRETYPE   - preprompt debugger actions
1544   PERLDB_PRE       - preprompt Perl code
1545   PERLDB_POST      - post-prompt Perl code
1546   PERLDB_TYPEAHEAD - typeahead captured by readline()
1547
1548 We chug through all these variables and plug the values saved in them
1549 back into the appropriate spots in the debugger.
1550
1551 =cut
1552
1553 if ( exists $ENV{PERLDB_RESTART} ) {
1554
1555     # We're restarting, so we don't need the flag that says to restart anymore.
1556     delete $ENV{PERLDB_RESTART};
1557
1558     # $restart = 1;
1559     @hist          = get_list('PERLDB_HIST');
1560     %break_on_load = get_list("PERLDB_ON_LOAD");
1561     %postponed     = get_list("PERLDB_POSTPONE");
1562
1563         share(@hist);
1564         share(@truehist);
1565         share(%break_on_load);
1566         share(%postponed);
1567
1568     # restore breakpoints/actions
1569     my @had_breakpoints = get_list("PERLDB_VISITED");
1570     for ( 0 .. $#had_breakpoints ) {
1571         my %pf = get_list("PERLDB_FILE_$_");
1572         $postponed_file{ $had_breakpoints[$_] } = \%pf if %pf;
1573     }
1574
1575     # restore options
1576     my %opt = get_list("PERLDB_OPT");
1577     my ( $opt, $val );
1578     while ( ( $opt, $val ) = each %opt ) {
1579         $val =~ s/[\\\']/\\$1/g;
1580         parse_options("$opt'$val'");
1581     }
1582
1583     # restore original @INC
1584     @INC     = get_list("PERLDB_INC");
1585     @ini_INC = @INC;
1586
1587     # return pre/postprompt actions and typeahead buffer
1588     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1589     $pre       = [ get_list("PERLDB_PRE") ];
1590     $post      = [ get_list("PERLDB_POST") ];
1591     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1592 } ## end if (exists $ENV{PERLDB_RESTART...
1593
1594 =head2 SETTING UP THE TERMINAL
1595
1596 Now, we'll decide how the debugger is going to interact with the user.
1597 If there's no TTY, we set the debugger to run non-stop; there's not going
1598 to be anyone there to enter commands.
1599
1600 =cut
1601
1602 if ($notty) {
1603     $runnonstop = 1;
1604         share($runnonstop);
1605 }
1606
1607 =pod
1608
1609 If there is a TTY, we have to determine who it belongs to before we can
1610 proceed. If this is a slave editor or graphical debugger (denoted by
1611 the first command-line switch being '-emacs'), we shift this off and
1612 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1613
1614 =cut
1615
1616 else {
1617
1618     # Is Perl being run from a slave editor or graphical debugger?
1619     # If so, don't use readline, and set $slave_editor = 1.
1620     $slave_editor =
1621       ( ( defined $main::ARGV[0] ) and ( $main::ARGV[0] eq '-emacs' ) );
1622     $rl = 0, shift(@main::ARGV) if $slave_editor;
1623
1624     #require Term::ReadLine;
1625
1626 =pod
1627
1628 We then determine what the console should be on various systems:
1629
1630 =over 4
1631
1632 =item * Cygwin - We use C<stdin> instead of a separate device.
1633
1634 =cut
1635
1636     if ( $^O eq 'cygwin' ) {
1637
1638         # /dev/tty is binary. use stdin for textmode
1639         undef $console;
1640     }
1641
1642 =item * Unix - use C</dev/tty>.
1643
1644 =cut
1645
1646     elsif ( -e "/dev/tty" ) {
1647         $console = "/dev/tty";
1648     }
1649
1650 =item * Windows or MSDOS - use C<con>.
1651
1652 =cut
1653
1654     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1655         $console = "con";
1656     }
1657
1658 =item * VMS - use C<sys$command>.
1659
1660 =cut
1661
1662     else {
1663
1664         # everything else is ...
1665         $console = "sys\$command";
1666     }
1667
1668 =pod
1669
1670 =back
1671
1672 Several other systems don't use a specific console. We C<undef $console>
1673 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1674 with a slave editor, Epoc).
1675
1676 =cut
1677
1678     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1679
1680         # /dev/tty is binary. use stdin for textmode
1681         $console = undef;
1682     }
1683
1684     if ( $^O eq 'NetWare' ) {
1685
1686         # /dev/tty is binary. use stdin for textmode
1687         $console = undef;
1688     }
1689
1690     # In OS/2, we need to use STDIN to get textmode too, even though
1691     # it pretty much looks like Unix otherwise.
1692     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1693     {    # In OS/2
1694         $console = undef;
1695     }
1696
1697     # EPOC also falls into the 'got to use STDIN' camp.
1698     if ( $^O eq 'epoc' ) {
1699         $console = undef;
1700     }
1701
1702 =pod
1703
1704 If there is a TTY hanging around from a parent, we use that as the console.
1705
1706 =cut
1707
1708     $console = $tty if defined $tty;
1709
1710 =head2 SOCKET HANDLING   
1711
1712 The debugger is capable of opening a socket and carrying out a debugging
1713 session over the socket.
1714
1715 If C<RemotePort> was defined in the options, the debugger assumes that it
1716 should try to start a debugging session on that port. It builds the socket
1717 and then tries to connect the input and output filehandles to it.
1718
1719 =cut
1720
1721     # Handle socket stuff.
1722
1723     if ( defined $remoteport ) {
1724
1725         # If RemotePort was defined in the options, connect input and output
1726         # to the socket.
1727         $IN = $OUT = connect_remoteport();
1728     } ## end if (defined $remoteport)
1729
1730 =pod
1731
1732 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1733 this is probably a situation where multiple debuggers are running (for example,
1734 a backticked command that starts up another debugger). We create a new IN and
1735 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1736 and if we can.
1737
1738 =cut
1739
1740     # Non-socket.
1741     else {
1742
1743         # Two debuggers running (probably a system or a backtick that invokes
1744         # the debugger itself under the running one). create a new IN and OUT
1745         # filehandle, and do the necessary mojo to create a new tty if we
1746         # know how, and we can.
1747         create_IN_OUT(4) if $CreateTTY & 4;
1748         if ($console) {
1749
1750             # If we have a console, check to see if there are separate ins and
1751             # outs to open. (They are assumed identical if not.)
1752
1753             my ( $i, $o ) = split /,/, $console;
1754             $o = $i unless defined $o;
1755
1756             # read/write on in, or just read, or read on STDIN.
1757             open( IN,      "+<$i" )
1758               || open( IN, "<$i" )
1759               || open( IN, "<&STDIN" );
1760
1761             # read/write/create/clobber out, or write/create/clobber out,
1762             # or merge with STDERR, or merge with STDOUT.
1763                  open( OUT, "+>$o" )
1764               || open( OUT, ">$o" )
1765               || open( OUT, ">&STDERR" )
1766               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1767
1768         } ## end if ($console)
1769         elsif ( not defined $console ) {
1770
1771             # No console. Open STDIN.
1772             open( IN, "<&STDIN" );
1773
1774             # merge with STDERR, or with STDOUT.
1775             open( OUT,      ">&STDERR" )
1776               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1777             $console = 'STDIN/OUT';
1778         } ## end elsif (not defined $console)
1779
1780         # Keep copies of the filehandles so that when the pager runs, it
1781         # can close standard input without clobbering ours.
1782         $IN = \*IN, $OUT = \*OUT if $console or not defined $console;
1783     } ## end elsif (from if(defined $remoteport))
1784
1785     # Unbuffer DB::OUT. We need to see responses right away.
1786     my $previous = select($OUT);
1787     $| = 1;                                  # for DB::OUT
1788     select($previous);
1789
1790     # Line info goes to debugger output unless pointed elsewhere.
1791     # Pointing elsewhere makes it possible for slave editors to
1792     # keep track of file and position. We have both a filehandle
1793     # and a I/O description to keep track of.
1794     $LINEINFO = $OUT     unless defined $LINEINFO;
1795     $lineinfo = $console unless defined $lineinfo;
1796         # share($LINEINFO); # <- unable to share globs
1797         share($lineinfo);   # 
1798
1799 =pod
1800
1801 To finish initialization, we show the debugger greeting,
1802 and then call the C<afterinit()> subroutine if there is one.
1803
1804 =cut
1805
1806     # Show the debugger greeting.
1807     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1808     unless ($runnonstop) {
1809         local $\ = '';
1810         local $, = '';
1811         if ( $term_pid eq '-1' ) {
1812             print $OUT "\nDaughter DB session started...\n";
1813         }
1814         else {
1815             print $OUT "\nLoading DB routines from $header\n";
1816             print $OUT (
1817                 "Editor support ",
1818                 $slave_editor ? "enabled" : "available", ".\n"
1819             );
1820             print $OUT
1821 "\nEnter h or `h h' for help, or `$doccmd perldebug' for more help.\n\n";
1822         } ## end else [ if ($term_pid eq '-1')
1823     } ## end unless ($runnonstop)
1824 } ## end else [ if ($notty)
1825
1826 # XXX This looks like a bug to me.
1827 # Why copy to @ARGS and then futz with @args?
1828 @ARGS = @ARGV;
1829 for (@args) {
1830     # Make sure backslashes before single quotes are stripped out, and
1831     # keep args unless they are numeric (XXX why?)
1832     # s/\'/\\\'/g;                      # removed while not justified understandably
1833     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1834 }
1835
1836 # If there was an afterinit() sub defined, call it. It will get
1837 # executed in our scope, so it can fiddle with debugger globals.
1838 if ( defined &afterinit ) {    # May be defined in $rcfile
1839     &afterinit();
1840 }
1841
1842 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1843 $I_m_init = 1;
1844
1845 ############################################################ Subroutines
1846
1847 =head1 SUBROUTINES
1848
1849 =head2 DB
1850
1851 This gigantic subroutine is the heart of the debugger. Called before every
1852 statement, its job is to determine if a breakpoint has been reached, and
1853 stop if so; read commands from the user, parse them, and execute
1854 them, and then send execution off to the next statement.
1855
1856 Note that the order in which the commands are processed is very important;
1857 some commands earlier in the loop will actually alter the C<$cmd> variable
1858 to create other commands to be executed later. This is all highly I<optimized>
1859 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1860 see what's happening in any given command.
1861
1862 =cut
1863
1864 sub DB {
1865
1866     # lock the debugger and get the thread id for the prompt
1867         lock($DBGR);
1868         my $tid;
1869         if ($ENV{PERL5DB_THREADED}) {
1870                 $tid = eval { "[".threads->tid."]" };
1871         }
1872
1873     # Check for whether we should be running continuously or not.
1874     # _After_ the perl program is compiled, $single is set to 1:
1875     if ( $single and not $second_time++ ) {
1876
1877         # Options say run non-stop. Run until we get an interrupt.
1878         if ($runnonstop) {    # Disable until signal
1879                 # If there's any call stack in place, turn off single
1880                 # stepping into subs throughout the stack.
1881             for ( $i = 0 ; $i <= $stack_depth ; ) {
1882                 $stack[ $i++ ] &= ~1;
1883             }
1884
1885             # And we are now no longer in single-step mode.
1886             $single = 0;
1887
1888             # If we simply returned at this point, we wouldn't get
1889             # the trace info. Fall on through.
1890             # return;
1891         } ## end if ($runnonstop)
1892
1893         elsif ($ImmediateStop) {
1894
1895             # We are supposed to stop here; XXX probably a break.
1896             $ImmediateStop = 0;    # We've processed it; turn it off
1897             $signal        = 1;    # Simulate an interrupt to force
1898                                    # us into the command loop
1899         }
1900     } ## end if ($single and not $second_time...
1901
1902     # If we're in single-step mode, or an interrupt (real or fake)
1903     # has occurred, turn off non-stop mode.
1904     $runnonstop = 0 if $single or $signal;
1905
1906     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
1907     # The code being debugged may have altered them.
1908     &save;
1909
1910     # Since DB::DB gets called after every line, we can use caller() to
1911     # figure out where we last were executing. Sneaky, eh? This works because
1912     # caller is returning all the extra information when called from the
1913     # debugger.
1914     local ( $package, $filename, $line ) = caller;
1915     local $filename_ini = $filename;
1916
1917     # set up the context for DB::eval, so it can properly execute
1918     # code on behalf of the user. We add the package in so that the
1919     # code is eval'ed in the proper package (not in the debugger!).
1920     local $usercontext =
1921       '($@, $!, $^E, $,, $/, $\, $^W) = @saved;' . "package $package;";
1922
1923     # Create an alias to the active file magical array to simplify
1924     # the code here.
1925     local (*dbline) = $main::{ '_<' . $filename };
1926
1927     # Last line in the program.
1928     local $max = $#dbline;
1929
1930     # if we have something here, see if we should break.
1931     if ( $dbline{$line}
1932         && ( ( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1933     {
1934
1935         # Stop if the stop criterion says to just stop.
1936         if ( $stop eq '1' ) {
1937             $signal |= 1;
1938         }
1939
1940         # It's a conditional stop; eval it in the user's context and
1941         # see if we should stop. If so, remove the one-time sigil.
1942         elsif ($stop) {
1943             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1944             &eval;
1945             $dbline{$line} =~ s/;9($|\0)/$1/;
1946         }
1947     } ## end if ($dbline{$line} && ...
1948
1949     # Preserve the current stop-or-not, and see if any of the W
1950     # (watch expressions) has changed.
1951     my $was_signal = $signal;
1952
1953     # If we have any watch expressions ...
1954     if ( $trace & 2 ) {
1955         for ( my $n = 0 ; $n <= $#to_watch ; $n++ ) {
1956             $evalarg = $to_watch[$n];
1957             local $onetimeDump;    # Tell DB::eval() to not output results
1958
1959             # Fix context DB::eval() wants to return an array, but
1960             # we need a scalar here.
1961             my ($val) = join( "', '", &eval );
1962             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
1963
1964             # Did it change?
1965             if ( $val ne $old_watch[$n] ) {
1966
1967                 # Yep! Show the difference, and fake an interrupt.
1968                 $signal = 1;
1969                 print $OUT <<EOP;
1970 Watchpoint $n:\t$to_watch[$n] changed:
1971     old value:\t$old_watch[$n]
1972     new value:\t$val
1973 EOP
1974                 $old_watch[$n] = $val;
1975             } ## end if ($val ne $old_watch...
1976         } ## end for (my $n = 0 ; $n <= ...
1977     } ## end if ($trace & 2)
1978
1979 =head2 C<watchfunction()>
1980
1981 C<watchfunction()> is a function that can be defined by the user; it is a
1982 function which will be run on each entry to C<DB::DB>; it gets the 
1983 current package, filename, and line as its parameters.
1984
1985 The watchfunction can do anything it likes; it is executing in the 
1986 debugger's context, so it has access to all of the debugger's internal
1987 data structures and functions.
1988
1989 C<watchfunction()> can control the debugger's actions. Any of the following
1990 will cause the debugger to return control to the user's program after
1991 C<watchfunction()> executes:
1992
1993 =over 4 
1994
1995 =item *
1996
1997 Returning a false value from the C<watchfunction()> itself.
1998
1999 =item *
2000
2001 Altering C<$single> to a false value.
2002
2003 =item *
2004
2005 Altering C<$signal> to a false value.
2006
2007 =item *
2008
2009 Turning off the C<4> bit in C<$trace> (this also disables the
2010 check for C<watchfunction()>. This can be done with
2011
2012     $trace &= ~4;
2013
2014 =back
2015
2016 =cut
2017
2018     # If there's a user-defined DB::watchfunction, call it with the
2019     # current package, filename, and line. The function executes in
2020     # the DB:: package.
2021     if ( $trace & 4 ) {    # User-installed watch
2022         return
2023           if watchfunction( $package, $filename, $line )
2024           and not $single
2025           and not $was_signal
2026           and not( $trace & ~4 );
2027     } ## end if ($trace & 4)
2028
2029     # Pick up any alteration to $signal in the watchfunction, and
2030     # turn off the signal now.
2031     $was_signal = $signal;
2032     $signal     = 0;
2033
2034 =head2 GETTING READY TO EXECUTE COMMANDS
2035
2036 The debugger decides to take control if single-step mode is on, the
2037 C<t> command was entered, or the user generated a signal. If the program
2038 has fallen off the end, we set things up so that entering further commands
2039 won't cause trouble, and we say that the program is over.
2040
2041 =cut
2042
2043     # Check to see if we should grab control ($single true,
2044     # trace set appropriately, or we got a signal).
2045     if ( $single || ( $trace & 1 ) || $was_signal ) {
2046
2047         # Yes, grab control.
2048         if ($slave_editor) {
2049
2050             # Tell the editor to update its position.
2051             $position = "\032\032$filename:$line:0\n";
2052             print_lineinfo($position);
2053         }
2054
2055 =pod
2056
2057 Special check: if we're in package C<DB::fake>, we've gone through the 
2058 C<END> block at least once. We set up everything so that we can continue
2059 to enter commands and have a valid context to be in.
2060
2061 =cut
2062
2063         elsif ( $package eq 'DB::fake' ) {
2064
2065             # Fallen off the end already.
2066             $term || &setterm;
2067             print_help(<<EOP);
2068 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
2069   use B<o> I<inhibit_exit> to avoid stopping after program termination,
2070   B<h q>, B<h R> or B<h o> to get additional info.  
2071 EOP
2072
2073             # Set the DB::eval context appropriately.
2074             $package     = 'main';
2075             $usercontext =
2076                 '($@, $!, $^E, $,, $/, $\, $^W) = @saved;'
2077               . "package $package;";    # this won't let them modify, alas
2078         } ## end elsif ($package eq 'DB::fake')
2079
2080 =pod
2081
2082 If the program hasn't finished executing, we scan forward to the
2083 next executable line, print that out, build the prompt from the file and line
2084 number information, and print that.   
2085
2086 =cut
2087
2088         else {
2089
2090             # Still somewhere in the midst of execution. Set up the
2091             #  debugger prompt.
2092             $sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
2093                                  # Perl 5 ones (sorry, we don't print Klingon
2094                                  #module names)
2095
2096             $prefix = $sub =~ /::/ ? "" : "${'package'}::";
2097             $prefix .= "$sub($filename:";
2098             $after = ( $dbline[$line] =~ /\n$/ ? '' : "\n" );
2099
2100             # Break up the prompt if it's really long.
2101             if ( length($prefix) > 30 ) {
2102                 $position = "$prefix$line):\n$line:\t$dbline[$line]$after";
2103                 $prefix   = "";
2104                 $infix    = ":\t";
2105             }
2106             else {
2107                 $infix    = "):\t";
2108                 $position = "$prefix$line$infix$dbline[$line]$after";
2109             }
2110
2111             # Print current line info, indenting if necessary.
2112             if ($frame) {
2113                 print_lineinfo( ' ' x $stack_depth,
2114                     "$line:\t$dbline[$line]$after" );
2115             }
2116             else {
2117                 print_lineinfo($position);
2118             }
2119
2120             # Scan forward, stopping at either the end or the next
2121             # unbreakable line.
2122             for ( $i = $line + 1 ; $i <= $max && $dbline[$i] == 0 ; ++$i )
2123             {    #{ vi
2124
2125                 # Drop out on null statements, block closers, and comments.
2126                 last if $dbline[$i] =~ /^\s*[\;\}\#\n]/;
2127
2128                 # Drop out if the user interrupted us.
2129                 last if $signal;
2130
2131                 # Append a newline if the line doesn't have one. Can happen
2132                 # in eval'ed text, for instance.
2133                 $after = ( $dbline[$i] =~ /\n$/ ? '' : "\n" );
2134
2135                 # Next executable line.
2136                 $incr_pos = "$prefix$i$infix$dbline[$i]$after";
2137                 $position .= $incr_pos;
2138                 if ($frame) {
2139
2140                     # Print it indented if tracing is on.
2141                     print_lineinfo( ' ' x $stack_depth,
2142                         "$i:\t$dbline[$i]$after" );
2143                 }
2144                 else {
2145                     print_lineinfo($incr_pos);
2146                 }
2147             } ## end for ($i = $line + 1 ; $i...
2148         } ## end else [ if ($slave_editor)
2149     } ## end if ($single || ($trace...
2150
2151 =pod
2152
2153 If there's an action to be executed for the line we stopped at, execute it.
2154 If there are any preprompt actions, execute those as well.      
2155
2156 =cut
2157
2158     # If there's an action, do it now.
2159     $evalarg = $action, &eval if $action;
2160
2161     # Are we nested another level (e.g., did we evaluate a function
2162     # that had a breakpoint in it at the debugger prompt)?
2163     if ( $single || $was_signal ) {
2164
2165         # Yes, go down a level.
2166         local $level = $level + 1;
2167
2168         # Do any pre-prompt actions.
2169         foreach $evalarg (@$pre) {
2170             &eval;
2171         }
2172
2173         # Complain about too much recursion if we passed the limit.
2174         print $OUT $stack_depth . " levels deep in subroutine calls!\n"
2175           if $single & 4;
2176
2177         # The line we're currently on. Set $incr to -1 to stay here
2178         # until we get a command that tells us to advance.
2179         $start = $line;
2180         $incr  = -1;      # for backward motion.
2181
2182         # Tack preprompt debugger actions ahead of any actual input.
2183         @typeahead = ( @$pretype, @typeahead );
2184
2185 =head2 WHERE ARE WE?
2186
2187 XXX Relocate this section?
2188
2189 The debugger normally shows the line corresponding to the current line of
2190 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2191 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2192
2193 C<$incr> controls by how many lines the I<current> line should move forward
2194 after a command is executed. If set to -1, this indicates that the I<current>
2195 line shouldn't change.
2196
2197 C<$start> is the I<current> line. It is used for things like knowing where to
2198 move forwards or backwards from when doing an C<L> or C<-> command.
2199
2200 C<$max> tells the debugger where the last line of the current file is. It's
2201 used to terminate loops most often.
2202
2203 =head2 THE COMMAND LOOP
2204
2205 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2206 in two parts:
2207
2208 =over 4
2209
2210 =item *
2211
2212 The outer part of the loop, starting at the C<CMD> label. This loop
2213 reads a command and then executes it.
2214
2215 =item *
2216
2217 The inner part of the loop, starting at the C<PIPE> label. This part
2218 is wholly contained inside the C<CMD> block and only executes a command.
2219 Used to handle commands running inside a pager.
2220
2221 =back
2222
2223 So why have two labels to restart the loop? Because sometimes, it's easier to
2224 have a command I<generate> another command and then re-execute the loop to do
2225 the new command. This is faster, but perhaps a bit more convoluted.
2226
2227 =cut
2228
2229         # The big command dispatch loop. It keeps running until the
2230         # user yields up control again.
2231         #
2232         # If we have a terminal for input, and we get something back
2233         # from readline(), keep on processing.
2234       CMD:
2235         while (
2236
2237             # We have a terminal, or can get one ...
2238             ( $term || &setterm ),
2239
2240             # ... and it belogs to this PID or we get one for this PID ...
2241             ( $term_pid == $$ or resetterm(1) ),
2242
2243             # ... and we got a line of command input ...
2244             defined(
2245                 $cmd = &readline(
2246                         "$pidprompt $tid DB"
2247                       . ( '<' x $level )
2248                       . ( $#hist + 1 )
2249                       . ( '>' x $level ) . " "
2250                 )
2251             )
2252           )
2253         {
2254
2255                         share($cmd);
2256             # ... try to execute the input as debugger commands.
2257
2258             # Don't stop running.
2259             $single = 0;
2260
2261             # No signal is active.
2262             $signal = 0;
2263
2264             # Handle continued commands (ending with \):
2265             $cmd =~ s/\\$/\n/ && do {
2266                 $cmd .= &readline("  cont: ");
2267                 redo CMD;
2268             };
2269
2270 =head4 The null command
2271
2272 A newline entered by itself means I<re-execute the last command>. We grab the
2273 command out of C<$laststep> (where it was recorded previously), and copy it
2274 back into C<$cmd> to be executed below. If there wasn't any previous command,
2275 we'll do nothing below (no command will match). If there was, we also save it
2276 in the command history and fall through to allow the command parsing to pick
2277 it up.
2278
2279 =cut
2280
2281             # Empty input means repeat the last command.
2282             $cmd =~ /^$/ && ( $cmd = $laststep );
2283             chomp($cmd);    # get rid of the annoying extra newline
2284             push( @hist, $cmd ) if length($cmd) > 1;
2285             push( @truehist, $cmd );
2286                         share(@hist);
2287                         share(@truehist);
2288
2289             # This is a restart point for commands that didn't arrive
2290             # via direct user input. It allows us to 'redo PIPE' to
2291             # re-execute command processing without reading a new command.
2292           PIPE: {
2293                 $cmd =~ s/^\s+//s;    # trim annoying leading whitespace
2294                 $cmd =~ s/\s+$//s;    # trim annoying trailing whitespace
2295                 ($i) = split( /\s+/, $cmd );
2296
2297 =head3 COMMAND ALIASES
2298
2299 The debugger can create aliases for commands (these are stored in the
2300 C<%alias> hash). Before a command is executed, the command loop looks it up
2301 in the alias hash and substitutes the contents of the alias for the command,
2302 completely replacing it.
2303
2304 =cut
2305
2306                 # See if there's an alias for the command, and set it up if so.
2307                 if ( $alias{$i} ) {
2308
2309                     # Squelch signal handling; we want to keep control here
2310                     # if something goes loco during the alias eval.
2311                     local $SIG{__DIE__};
2312                     local $SIG{__WARN__};
2313
2314                     # This is a command, so we eval it in the DEBUGGER's
2315                     # scope! Otherwise, we can't see the special debugger
2316                     # variables, or get to the debugger's subs. (Well, we
2317                     # _could_, but why make it even more complicated?)
2318                     eval "\$cmd =~ $alias{$i}";
2319                     if ($@) {
2320                         local $\ = '';
2321                         print $OUT "Couldn't evaluate `$i' alias: $@";
2322                         next CMD;
2323                     }
2324                 } ## end if ($alias{$i})
2325
2326 =head3 MAIN-LINE COMMANDS
2327
2328 All of these commands work up to and after the program being debugged has
2329 terminated. 
2330
2331 =head4 C<q> - quit
2332
2333 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't 
2334 try to execute further, cleaning any restart-related stuff out of the
2335 environment, and executing with the last value of C<$?>.
2336
2337 =cut
2338
2339                 $cmd =~ /^q$/ && do {
2340                     $fall_off_end = 1;
2341                     clean_ENV();
2342                     exit $?;
2343                 };
2344
2345 =head4 C<t> - trace
2346
2347 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2348
2349 =cut
2350
2351                 $cmd =~ /^t$/ && do {
2352                     $trace ^= 1;
2353                     local $\ = '';
2354                     print $OUT "Trace = "
2355                       . ( ( $trace & 1 ) ? "on" : "off" ) . "\n";
2356                     next CMD;
2357                 };
2358
2359 =head4 C<S> - list subroutines matching/not matching a pattern
2360
2361 Walks through C<%sub>, checking to see whether or not to print the name.
2362
2363 =cut
2364
2365                 $cmd =~ /^S(\s+(!)?(.+))?$/ && do {
2366
2367                     $Srev     = defined $2;     # Reverse scan?
2368                     $Spatt    = $3;             # The pattern (if any) to use.
2369                     $Snocheck = !defined $1;    # No args - print all subs.
2370
2371                     # Need to make these sane here.
2372                     local $\ = '';
2373                     local $, = '';
2374
2375                     # Search through the debugger's magical hash of subs.
2376                     # If $nocheck is true, just print the sub name.
2377                     # Otherwise, check it against the pattern. We then use
2378                     # the XOR trick to reverse the condition as required.
2379                     foreach $subname ( sort( keys %sub ) ) {
2380                         if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
2381                             print $OUT $subname, "\n";
2382                         }
2383                     }
2384                     next CMD;
2385                 };
2386
2387 =head4 C<X> - list variables in current package
2388
2389 Since the C<V> command actually processes this, just change this to the 
2390 appropriate C<V> command and fall through.
2391
2392 =cut
2393
2394                 $cmd =~ s/^X\b/V $package/;
2395
2396 =head4 C<V> - list variables
2397
2398 Uses C<dumpvar.pl> to dump out the current values for selected variables. 
2399
2400 =cut
2401
2402                 # Bare V commands get the currently-being-debugged package
2403                 # added.
2404                 $cmd =~ /^V$/ && do {
2405                     $cmd = "V $package";
2406                 };
2407
2408                 # V - show variables in package.
2409                 $cmd =~ /^V\b\s*(\S+)\s*(.*)/ && do {
2410
2411                     # Save the currently selected filehandle and
2412                     # force output to debugger's filehandle (dumpvar
2413                     # just does "print" for output).
2414                     local ($savout) = select($OUT);
2415
2416                     # Grab package name and variables to dump.
2417                     $packname = $1;
2418                     @vars     = split( ' ', $2 );
2419
2420                     # If main::dumpvar isn't here, get it.
2421                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2422                     if ( defined &main::dumpvar ) {
2423
2424                         # We got it. Turn off subroutine entry/exit messages
2425                         # for the moment, along with return values.
2426                         local $frame = 0;
2427                         local $doret = -2;
2428
2429                         # must detect sigpipe failures  - not catching
2430                         # then will cause the debugger to die.
2431                         eval {
2432                             &main::dumpvar(
2433                                 $packname,
2434                                 defined $option{dumpDepth}
2435                                 ? $option{dumpDepth}
2436                                 : -1,    # assume -1 unless specified
2437                                 @vars
2438                             );
2439                         };
2440
2441                         # The die doesn't need to include the $@, because
2442                         # it will automatically get propagated for us.
2443                         if ($@) {
2444                             die unless $@ =~ /dumpvar print failed/;
2445                         }
2446                     } ## end if (defined &main::dumpvar)
2447                     else {
2448
2449                         # Couldn't load dumpvar.
2450                         print $OUT "dumpvar.pl not available.\n";
2451                     }
2452
2453                     # Restore the output filehandle, and go round again.
2454                     select($savout);
2455                     next CMD;
2456                 };
2457
2458 =head4 C<x> - evaluate and print an expression
2459
2460 Hands the expression off to C<DB::eval>, setting it up to print the value
2461 via C<dumpvar.pl> instead of just printing it directly.
2462
2463 =cut
2464
2465                 $cmd =~ s/^x\b/ / && do {    # Remainder gets done by DB::eval()
2466                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2467
2468                     # handle special  "x 3 blah" syntax XXX propagate
2469                     # doc back to special variables.
2470                     if ( $cmd =~ s/^\s*(\d+)(?=\s)/ / ) {
2471                         $onetimedumpDepth = $1;
2472                     }
2473                 };
2474
2475 =head4 C<m> - print methods
2476
2477 Just uses C<DB::methods> to determine what methods are available.
2478
2479 =cut
2480
2481                 $cmd =~ s/^m\s+([\w:]+)\s*$/ / && do {
2482                     methods($1);
2483                     next CMD;
2484                 };
2485
2486                 # m expr - set up DB::eval to do the work
2487                 $cmd =~ s/^m\b/ / && do {    # Rest gets done by DB::eval()
2488                     $onetimeDump = 'methods';   #  method output gets used there
2489                 };
2490
2491 =head4 C<f> - switch files
2492
2493 =cut
2494
2495                 $cmd =~ /^f\b\s*(.*)/ && do {
2496                     $file = $1;
2497                     $file =~ s/\s+$//;
2498
2499                     # help for no arguments (old-style was return from sub).
2500                     if ( !$file ) {
2501                         print $OUT
2502                           "The old f command is now the r command.\n";    # hint
2503                         print $OUT "The new f command switches filenames.\n";
2504                         next CMD;
2505                     } ## end if (!$file)
2506
2507                     # if not in magic file list, try a close match.
2508                     if ( !defined $main::{ '_<' . $file } ) {
2509                         if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
2510                             {
2511                                 $try = substr( $try, 2 );
2512                                 print $OUT "Choosing $try matching `$file':\n";
2513                                 $file = $try;
2514                             }
2515                         } ## end if (($try) = grep(m#^_<.*$file#...
2516                     } ## end if (!defined $main::{ ...
2517
2518                     # If not successfully switched now, we failed.
2519                     if ( !defined $main::{ '_<' . $file } ) {
2520                         print $OUT "No file matching `$file' is loaded.\n";
2521                         next CMD;
2522                     }
2523
2524                     # We switched, so switch the debugger internals around.
2525                     elsif ( $file ne $filename ) {
2526                         *dbline   = $main::{ '_<' . $file };
2527                         $max      = $#dbline;
2528                         $filename = $file;
2529                         $start    = 1;
2530                         $cmd      = "l";
2531                     } ## end elsif ($file ne $filename)
2532
2533                     # We didn't switch; say we didn't.
2534                     else {
2535                         print $OUT "Already in $file.\n";
2536                         next CMD;
2537                     }
2538                 };
2539
2540 =head4 C<.> - return to last-executed line.
2541
2542 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2543 and then we look up the line in the magical C<%dbline> hash.
2544
2545 =cut
2546
2547                 # . command.
2548                 $cmd =~ /^\.$/ && do {
2549                     $incr = -1;    # stay at current line
2550
2551                     # Reset everything to the old location.
2552                     $start    = $line;
2553                     $filename = $filename_ini;
2554                     *dbline   = $main::{ '_<' . $filename };
2555                     $max      = $#dbline;
2556
2557                     # Now where are we?
2558                     print_lineinfo($position);
2559                     next CMD;
2560                 };
2561
2562 =head4 C<-> - back one window
2563
2564 We change C<$start> to be one window back; if we go back past the first line,
2565 we set it to be the first line. We ser C<$incr> to put us back at the
2566 currently-executing line, and then put a C<l $start +> (list one window from
2567 C<$start>) in C<$cmd> to be executed later.
2568
2569 =cut
2570
2571                 # - - back a window.
2572                 $cmd =~ /^-$/ && do {
2573
2574                     # back up by a window; go to 1 if back too far.
2575                     $start -= $incr + $window + 1;
2576                     $start = 1 if $start <= 0;
2577                     $incr  = $window - 1;
2578
2579                     # Generate and execute a "l +" command (handled below).
2580                     $cmd = 'l ' . ($start) . '+';
2581                 };
2582
2583 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, {, {{>
2584
2585 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2586 problems, most notably that the default case of several commands destroying
2587 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2588 retain the old commands for those who were used to using them or who preferred
2589 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2590 deal with them instead of processing them in-line.
2591
2592 =cut
2593
2594                 # All of these commands were remapped in perl 5.8.0;
2595                 # we send them off to the secondary dispatcher (see below).
2596                 $cmd =~ /^([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so && do {
2597                     &cmd_wrapper( $1, $2, $line );
2598                     next CMD;
2599                 };
2600
2601 =head4 C<y> - List lexicals in higher scope
2602
2603 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope    
2604 above the current one and then displays then using C<dumpvar.pl>.
2605
2606 =cut
2607
2608                 $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/ && do {
2609
2610                     # See if we've got the necessary support.
2611                     eval { require PadWalker; PadWalker->VERSION(0.08) }
2612                       or &warn(
2613                         $@ =~ /locate/
2614                         ? "PadWalker module not found - please install\n"
2615                         : $@
2616                       )
2617                       and next CMD;
2618
2619                     # Load up dumpvar if we don't have it. If we can, that is.
2620                     do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
2621                     defined &main::dumpvar
2622                       or print $OUT "dumpvar.pl not available.\n"
2623                       and next CMD;
2624
2625                     # Got all the modules we need. Find them and print them.
2626                     my @vars = split( ' ', $2 || '' );
2627
2628                     # Find the pad.
2629                     my $h = eval { PadWalker::peek_my( ( $1 || 0 ) + 1 ) };
2630
2631                     # Oops. Can't find it.
2632                     $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
2633
2634                     # Show the desired vars with dumplex().
2635                     my $savout = select($OUT);
2636
2637                     # Have dumplex dump the lexicals.
2638                     dumpvar::dumplex( $_, $h->{$_},
2639                         defined $option{dumpDepth} ? $option{dumpDepth} : -1,
2640                         @vars )
2641                       for sort keys %$h;
2642                     select($savout);
2643                     next CMD;
2644                 };
2645
2646 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2647
2648 All of the commands below this point don't work after the program being
2649 debugged has ended. All of them check to see if the program has ended; this
2650 allows the commands to be relocated without worrying about a 'line of
2651 demarcation' above which commands can be entered anytime, and below which
2652 they can't.
2653
2654 =head4 C<n> - single step, but don't trace down into subs
2655
2656 Done by setting C<$single> to 2, which forces subs to execute straight through
2657 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2658 so a null command knows what to re-execute. 
2659
2660 =cut
2661
2662                 # n - next
2663                 $cmd =~ /^n$/ && do {
2664                     end_report(), next CMD if $finished and $level <= 1;
2665
2666                     # Single step, but don't enter subs.
2667                     $single = 2;
2668
2669                     # Save for empty command (repeat last).
2670                     $laststep = $cmd;
2671                     last CMD;
2672                 };
2673
2674 =head4 C<s> - single-step, entering subs
2675
2676 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside     
2677 subs. Also saves C<s> as C<$lastcmd>.
2678
2679 =cut
2680
2681                 # s - single step.
2682                 $cmd =~ /^s$/ && do {
2683
2684                     # Get out and restart the command loop if program
2685                     # has finished.
2686                     end_report(), next CMD if $finished and $level <= 1;
2687
2688                     # Single step should enter subs.
2689                     $single = 1;
2690
2691                     # Save for empty command (repeat last).
2692                     $laststep = $cmd;
2693                     last CMD;
2694                 };
2695
2696 =head4 C<c> - run continuously, setting an optional breakpoint
2697
2698 Most of the code for this command is taken up with locating the optional
2699 breakpoint, which is either a subroutine name or a line number. We set
2700 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2701 in this and all call levels above this one.
2702
2703 =cut
2704
2705                 # c - start continuous execution.
2706                 $cmd =~ /^c\b\s*([\w:]*)\s*$/ && do {
2707
2708                     # Hey, show's over. The debugged program finished
2709                     # executing already.
2710                     end_report(), next CMD if $finished and $level <= 1;
2711
2712                     # Capture the place to put a one-time break.
2713                     $subname = $i = $1;
2714
2715                     #  Probably not needed, since we finish an interactive
2716                     #  sub-session anyway...
2717                     # local $filename = $filename;
2718                     # local *dbline = *dbline; # XXX Would this work?!
2719                     #
2720                     # The above question wonders if localizing the alias
2721                     # to the magic array works or not. Since it's commented
2722                     # out, we'll just leave that to speculation for now.
2723
2724                     # If the "subname" isn't all digits, we'll assume it
2725                     # is a subroutine name, and try to find it.
2726                     if ( $subname =~ /\D/ ) {    # subroutine name
2727                             # Qualify it to the current package unless it's
2728                             # already qualified.
2729                         $subname = $package . "::" . $subname
2730                           unless $subname =~ /::/;
2731
2732                         # find_sub will return "file:line_number" corresponding
2733                         # to where the subroutine is defined; we call find_sub,
2734                         # break up the return value, and assign it in one
2735                         # operation.
2736                         ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2737
2738                         # Force the line number to be numeric.
2739                         $i += 0;
2740
2741                         # If we got a line number, we found the sub.
2742                         if ($i) {
2743
2744                             # Switch all the debugger's internals around so
2745                             # we're actually working with that file.
2746                             $filename = $file;
2747                             *dbline   = $main::{ '_<' . $filename };
2748
2749                             # Mark that there's a breakpoint in this file.
2750                             $had_breakpoints{$filename} |= 1;
2751
2752                             # Scan forward to the first executable line
2753                             # after the 'sub whatever' line.
2754                             $max = $#dbline;
2755                             ++$i while $dbline[$i] == 0 && $i < $max;
2756                         } ## end if ($i)
2757
2758                         # We didn't find a sub by that name.
2759                         else {
2760                             print $OUT "Subroutine $subname not found.\n";
2761                             next CMD;
2762                         }
2763                     } ## end if ($subname =~ /\D/)
2764
2765                     # At this point, either the subname was all digits (an
2766                     # absolute line-break request) or we've scanned through
2767                     # the code following the definition of the sub, looking
2768                     # for an executable, which we may or may not have found.
2769                     #
2770                     # If $i (which we set $subname from) is non-zero, we
2771                     # got a request to break at some line somewhere. On
2772                     # one hand, if there wasn't any real subroutine name
2773                     # involved, this will be a request to break in the current
2774                     # file at the specified line, so we have to check to make
2775                     # sure that the line specified really is breakable.
2776                     #
2777                     # On the other hand, if there was a subname supplied, the
2778                     # preceding block has moved us to the proper file and
2779                     # location within that file, and then scanned forward
2780                     # looking for the next executable line. We have to make
2781                     # sure that one was found.
2782                     #
2783                     # On the gripping hand, we can't do anything unless the
2784                     # current value of $i points to a valid breakable line.
2785                     # Check that.
2786                     if ($i) {
2787
2788                         # Breakable?
2789                         if ( $dbline[$i] == 0 ) {
2790                             print $OUT "Line $i not breakable.\n";
2791                             next CMD;
2792                         }
2793
2794                         # Yes. Set up the one-time-break sigil.
2795                         $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2796                     } ## end if ($i)
2797
2798                     # Turn off stack tracing from here up.
2799                     for ( $i = 0 ; $i <= $stack_depth ; ) {
2800                         $stack[ $i++ ] &= ~1;
2801                     }
2802                     last CMD;
2803                 };
2804
2805 =head4 C<r> - return from a subroutine
2806
2807 For C<r> to work properly, the debugger has to stop execution again
2808 immediately after the return is executed. This is done by forcing
2809 single-stepping to be on in the call level above the current one. If
2810 we are printing return values when a C<r> is executed, set C<$doret>
2811 appropriately, and force us out of the command loop.
2812
2813 =cut
2814
2815                 # r - return from the current subroutine.
2816                 $cmd =~ /^r$/ && do {
2817
2818                     # Can't do anything if the program's over.
2819                     end_report(), next CMD if $finished and $level <= 1;
2820
2821                     # Turn on stack trace.
2822                     $stack[$stack_depth] |= 1;
2823
2824                     # Print return value unless the stack is empty.
2825                     $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
2826                     last CMD;
2827                 };
2828
2829 =head4 C<T> - stack trace
2830
2831 Just calls C<DB::print_trace>.
2832
2833 =cut
2834
2835                 $cmd =~ /^T$/ && do {
2836                     print_trace( $OUT, 1 );    # skip DB
2837                     next CMD;
2838                 };
2839
2840 =head4 C<w> - List window around current line.
2841
2842 Just calls C<DB::cmd_w>.
2843
2844 =cut
2845
2846                 $cmd =~ /^w\b\s*(.*)/s && do { &cmd_w( 'w', $1 ); next CMD; };
2847
2848 =head4 C<W> - watch-expression processing.
2849
2850 Just calls C<DB::cmd_W>. 
2851
2852 =cut
2853
2854                 $cmd =~ /^W\b\s*(.*)/s && do { &cmd_W( 'W', $1 ); next CMD; };
2855
2856 =head4 C</> - search forward for a string in the source
2857
2858 We take the argument and treat it as a pattern. If it turns out to be a 
2859 bad one, we return the error we got from trying to C<eval> it and exit.
2860 If not, we create some code to do the search and C<eval> it so it can't 
2861 mess us up.
2862
2863 =cut
2864
2865                 $cmd =~ /^\/(.*)$/ && do {
2866
2867                     # The pattern as a string.
2868                     $inpat = $1;
2869
2870                     # Remove the final slash.
2871                     $inpat =~ s:([^\\])/$:$1:;
2872
2873                     # If the pattern isn't null ...
2874                     if ( $inpat ne "" ) {
2875
2876                         # Turn of warn and die procesing for a bit.
2877                         local $SIG{__DIE__};
2878                         local $SIG{__WARN__};
2879
2880                         # Create the pattern.
2881                         eval '$inpat =~ m' . "\a$inpat\a";
2882                         if ( $@ ne "" ) {
2883
2884                             # Oops. Bad pattern. No biscuit.
2885                             # Print the eval error and go back for more
2886                             # commands.
2887                             print $OUT "$@";
2888                             next CMD;
2889                         }
2890                         $pat = $inpat;
2891                     } ## end if ($inpat ne "")
2892
2893                     # Set up to stop on wrap-around.
2894                     $end = $start;
2895
2896                     # Don't move off the current line.
2897                     $incr = -1;
2898
2899                     # Done in eval so nothing breaks if the pattern
2900                     # does something weird.
2901                     eval '
2902                         for (;;) {
2903                             # Move ahead one line.
2904                             ++$start;
2905
2906                             # Wrap if we pass the last line.
2907                             $start = 1 if ($start > $max);
2908
2909                             # Stop if we have gotten back to this line again,
2910                             last if ($start == $end);
2911
2912                             # A hit! (Note, though, that we are doing
2913                             # case-insensitive matching. Maybe a qr//
2914                             # expression would be better, so the user could
2915                             # do case-sensitive matching if desired.
2916                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2917                                 if ($slave_editor) {
2918                                     # Handle proper escaping in the slave.
2919                                     print $OUT "\032\032$filename:$start:0\n";
2920                                 } 
2921                                 else {
2922                                     # Just print the line normally.
2923                                     print $OUT "$start:\t",$dbline[$start],"\n";
2924                                 }
2925                                 # And quit since we found something.
2926                                 last;
2927                             }
2928                          } ';
2929
2930                     # If we wrapped, there never was a match.
2931                     print $OUT "/$pat/: not found\n" if ( $start == $end );
2932                     next CMD;
2933                 };
2934
2935 =head4 C<?> - search backward for a string in the source
2936
2937 Same as for C</>, except the loop runs backwards.
2938
2939 =cut
2940
2941                 # ? - backward pattern search.
2942                 $cmd =~ /^\?(.*)$/ && do {
2943
2944                     # Get the pattern, remove trailing question mark.
2945                     $inpat = $1;
2946                     $inpat =~ s:([^\\])\?$:$1:;
2947
2948                     # If we've got one ...
2949                     if ( $inpat ne "" ) {
2950
2951                         # Turn off die & warn handlers.
2952                         local $SIG{__DIE__};
2953                         local $SIG{__WARN__};
2954                         eval '$inpat =~ m' . "\a$inpat\a";
2955
2956                         if ( $@ ne "" ) {
2957
2958                             # Ouch. Not good. Print the error.
2959                             print $OUT $@;
2960                             next CMD;
2961                         }
2962                         $pat = $inpat;
2963                     } ## end if ($inpat ne "")
2964
2965                     # Where we are now is where to stop after wraparound.
2966                     $end = $start;
2967
2968                     # Don't move away from this line.
2969                     $incr = -1;
2970
2971                     # Search inside the eval to prevent pattern badness
2972                     # from killing us.
2973                     eval '
2974                         for (;;) {
2975                             # Back up a line.
2976                             --$start;
2977
2978                             # Wrap if we pass the first line.
2979
2980                             $start = $max if ($start <= 0);
2981
2982                             # Quit if we get back where we started,
2983                             last if ($start == $end);
2984
2985                             # Match?
2986                             if ($dbline[$start] =~ m' . "\a$pat\a" . 'i) {
2987                                 if ($slave_editor) {
2988                                     # Yep, follow slave editor requirements.
2989                                     print $OUT "\032\032$filename:$start:0\n";
2990                                 } 
2991                                 else {
2992                                     # Yep, just print normally.
2993                                     print $OUT "$start:\t",$dbline[$start],"\n";
2994                                 }
2995
2996                                 # Found, so done.
2997                                 last;
2998                             }
2999                         } ';
3000
3001                     # Say we failed if the loop never found anything,
3002                     print $OUT "?$pat?: not found\n" if ( $start == $end );
3003                     next CMD;
3004                 };
3005
3006 =head4 C<$rc> - Recall command
3007
3008 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
3009 that the terminal supports history). It find the the command required, puts it
3010 into C<$cmd>, and redoes the loop to execute it.
3011
3012 =cut
3013
3014                 # $rc - recall command.
3015                 $cmd =~ /^$rc+\s*(-)?(\d+)?$/ && do {
3016
3017                     # No arguments, take one thing off history.
3018                     pop(@hist) if length($cmd) > 1;
3019
3020                     # Relative (- found)?
3021                     #  Y - index back from most recent (by 1 if bare minus)
3022                     #  N - go to that particular command slot or the last
3023                     #      thing if nothing following.
3024                     $i = $1 ? ( $#hist - ( $2 || 1 ) ) : ( $2 || $#hist );
3025
3026                     # Pick out the command desired.
3027                     $cmd = $hist[$i];
3028
3029                     # Print the command to be executed and restart the loop
3030                     # with that command in the buffer.
3031                     print $OUT $cmd, "\n";
3032                     redo CMD;
3033                 };
3034
3035 =head4 C<$sh$sh> - C<system()> command
3036
3037 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
3038 C<STDOUT> from getting messed up.
3039
3040 =cut
3041
3042                 # $sh$sh - run a shell command (if it's all ASCII).
3043                 # Can't run shell commands with Unicode in the debugger, hmm.
3044                 $cmd =~ /^$sh$sh\s*([\x00-\xff]*)/ && do {
3045
3046                     # System it.
3047                     &system($1);
3048                     next CMD;
3049                 };
3050
3051 =head4 C<$rc I<pattern> $rc> - Search command history
3052
3053 Another command to manipulate C<@hist>: this one searches it with a pattern.
3054 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
3055
3056 =cut
3057
3058                 # $rc pattern $rc - find a command in the history.
3059                 $cmd =~ /^$rc([^$rc].*)$/ && do {
3060
3061                     # Create the pattern to use.
3062                     $pat = "^$1";
3063
3064                     # Toss off last entry if length is >1 (and it always is).
3065                     pop(@hist) if length($cmd) > 1;
3066
3067                     # Look backward through the history.
3068                     for ( $i = $#hist ; $i ; --$i ) {
3069
3070                         # Stop if we find it.
3071                         last if $hist[$i] =~ /$pat/;
3072                     }
3073
3074                     if ( !$i ) {
3075
3076                         # Never found it.
3077                         print $OUT "No such command!\n\n";
3078                         next CMD;
3079                     }
3080
3081                     # Found it. Put it in the buffer, print it, and process it.
3082                     $cmd = $hist[$i];
3083                     print $OUT $cmd, "\n";
3084                     redo CMD;
3085                 };
3086
3087 =head4 C<$sh> - Invoke a shell     
3088
3089 Uses C<DB::system> to invoke a shell.
3090
3091 =cut
3092
3093                 # $sh - start a shell.
3094                 $cmd =~ /^$sh$/ && do {
3095
3096                     # Run the user's shell. If none defined, run Bourne.
3097                     # We resume execution when the shell terminates.
3098                     &system( $ENV{SHELL} || "/bin/sh" );
3099                     next CMD;
3100                 };
3101
3102 =head4 C<$sh I<command>> - Force execution of a command in a shell
3103
3104 Like the above, but the command is passed to the shell. Again, we use
3105 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
3106
3107 =cut
3108
3109                 # $sh command - start a shell and run a command in it.
3110                 $cmd =~ /^$sh\s*([\x00-\xff]*)/ && do {
3111
3112                     # XXX: using csh or tcsh destroys sigint retvals!
3113                     #&system($1);  # use this instead
3114
3115                     # use the user's shell, or Bourne if none defined.
3116                     &system( $ENV{SHELL} || "/bin/sh", "-c", $1 );
3117                     next CMD;
3118                 };
3119
3120 =head4 C<H> - display commands in history
3121
3122 Prints the contents of C<@hist> (if any).
3123
3124 =cut
3125
3126                 $cmd =~ /^H\b\s*\*/ && do {
3127                     @hist = @truehist = ();
3128                     print $OUT "History cleansed\n";
3129                     next CMD;
3130                 };
3131
3132                 $cmd =~ /^H\b\s*(-(\d+))?/ && do {
3133
3134                     # Anything other than negative numbers is ignored by
3135                     # the (incorrect) pattern, so this test does nothing.
3136                     $end = $2 ? ( $#hist - $2 ) : 0;
3137
3138                     # Set to the minimum if less than zero.
3139                     $hist = 0 if $hist < 0;
3140
3141                     # Start at the end of the array.
3142                     # Stay in while we're still above the ending value.
3143                     # Tick back by one each time around the loop.
3144                     for ( $i = $#hist ; $i > $end ; $i-- ) {
3145
3146                         # Print the command  unless it has no arguments.
3147                         print $OUT "$i: ", $hist[$i], "\n"
3148                           unless $hist[$i] =~ /^.?$/;
3149                     }
3150                     next CMD;
3151                 };
3152
3153 =head4 C<man, doc, perldoc> - look up documentation
3154
3155 Just calls C<runman()> to print the appropriate document.
3156
3157 =cut
3158
3159                 # man, perldoc, doc - show manual pages.
3160                 $cmd =~ /^(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?$/ && do {
3161                     runman($1);
3162                     next CMD;
3163                 };
3164
3165 =head4 C<p> - print
3166
3167 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
3168 the bottom of the loop.
3169
3170 =cut
3171
3172                 # p - print (no args): print $_.
3173                 $cmd =~ s/^p$/print {\$DB::OUT} \$_/;
3174
3175                 # p - print the given expression.
3176                 $cmd =~ s/^p\b/print {\$DB::OUT} /;
3177
3178 =head4 C<=> - define command alias
3179
3180 Manipulates C<%alias> to add or list command aliases.
3181
3182 =cut
3183
3184                 # = - set up a command alias.
3185                 $cmd =~ s/^=\s*// && do {
3186                     my @keys;
3187                     if ( length $cmd == 0 ) {
3188
3189                         # No args, get current aliases.
3190                         @keys = sort keys %alias;
3191                     }
3192                     elsif ( my ( $k, $v ) = ( $cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3193
3194                         # Creating a new alias. $k is alias name, $v is
3195                         # alias value.
3196
3197                         # can't use $_ or kill //g state
3198                         for my $x ( $k, $v ) {
3199
3200                             # Escape "alarm" characters.
3201                             $x =~ s/\a/\\a/g;
3202                         }
3203
3204                         # Substitute key for value, using alarm chars
3205                         # as separators (which is why we escaped them in
3206                         # the command).
3207                         $alias{$k} = "s\a$k\a$v\a";
3208
3209                         # Turn off standard warn and die behavior.
3210                         local $SIG{__DIE__};
3211                         local $SIG{__WARN__};
3212
3213                         # Is it valid Perl?
3214                         unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3215
3216                             # Nope. Bad alias. Say so and get out.
3217                             print $OUT "Can't alias $k to $v: $@\n";
3218                             delete $alias{$k};
3219                             next CMD;
3220                         }
3221
3222                         # We'll only list the new one.
3223                         @keys = ($k);
3224                     } ## end elsif (my ($k, $v) = ($cmd...
3225
3226                     # The argument is the alias to list.
3227                     else {
3228                         @keys = ($cmd);
3229                     }
3230
3231                     # List aliases.
3232                     for my $k (@keys) {
3233
3234                         # Messy metaquoting: Trim the substitution code off.
3235                         # We use control-G as the delimiter because it's not
3236                         # likely to appear in the alias.
3237                         if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3238
3239                             # Print the alias.
3240                             print $OUT "$k\t= $1\n";
3241                         }
3242                         elsif ( defined $alias{$k} ) {
3243
3244                             # Couldn't trim it off; just print the alias code.
3245                             print $OUT "$k\t$alias{$k}\n";
3246                         }
3247                         else {
3248
3249                             # No such, dude.
3250                             print "No alias for $k\n";
3251                         }
3252                     } ## end for my $k (@keys)
3253                     next CMD;
3254                 };
3255
3256 =head4 C<source> - read commands from a file.
3257
3258 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3259 pick it up.
3260
3261 =cut
3262
3263                 # source - read commands from a file (or pipe!) and execute.
3264                 $cmd =~ /^source\s+(.*\S)/ && do {
3265                     if ( open my $fh, $1 ) {
3266
3267                         # Opened OK; stick it in the list of file handles.
3268                         push @cmdfhs, $fh;
3269                     }
3270                     else {
3271
3272                         # Couldn't open it.
3273                         &warn("Can't execute `$1': $!\n");
3274                     }
3275                     next CMD;
3276                 };
3277
3278 =head4 C<save> - send current history to a file
3279
3280 Takes the complete history, (not the shrunken version you see with C<H>),
3281 and saves it to the given filename, so it can be replayed using C<source>.
3282
3283 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3284
3285 =cut
3286
3287                 # save source - write commands to a file for later use
3288                 $cmd =~ /^save\s*(.*)$/ && do {
3289                     my $file = $1 || '.perl5dbrc';    # default?
3290                     if ( open my $fh, "> $file" ) {
3291
3292                        # chomp to remove extraneous newlines from source'd files
3293                         chomp( my @truelist =
3294                               map { m/^\s*(save|source)/ ? "#$_" : $_ }
3295                               @truehist );
3296                         print $fh join( "\n", @truelist );
3297                         print "commands saved in $file\n";
3298                     }
3299                     else {
3300                         &warn("Can't save debugger commands in '$1': $!\n");
3301                     }
3302                     next CMD;
3303                 };
3304
3305 =head4 C<R> - restart
3306
3307 Restart the debugger session. 
3308
3309 =head4 C<rerun> - rerun the current session
3310
3311 Return to any given position in the B<true>-history list
3312
3313 =cut
3314
3315                 # R - restart execution.
3316                 # rerun - controlled restart execution.
3317                 $cmd =~ /^(R|rerun\s*(.*))$/ && do {
3318                     my @args = ($1 eq 'R' ? restart() : rerun($2));
3319
3320                     # Close all non-system fds for a clean restart.  A more
3321                     # correct method would be to close all fds that were not
3322                     # open when the process started, but this seems to be
3323                     # hard.  See "debugger 'R'estart and open database
3324                     # connections" on p5p.
3325
3326                     my $max_fd = 1024; # default if POSIX can't be loaded
3327                     if (eval { require POSIX }) {
3328                         eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
3329                     }
3330
3331                     if (defined $max_fd) {
3332                         foreach ($^F+1 .. $max_fd-1) {
3333                             next unless open FD_TO_CLOSE, "<&=$_";
3334                             close(FD_TO_CLOSE);
3335                         }
3336                     }
3337
3338                     # And run Perl again.  We use exec() to keep the
3339                     # PID stable (and that way $ini_pids is still valid).
3340                     exec(@args) || print $OUT "exec failed: $!\n";
3341
3342                     last CMD;
3343                 };
3344
3345 =head4 C<|, ||> - pipe output through the pager.
3346
3347 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3348 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3349 pipe to the pager (restoring the output filehandles if this fails). If this
3350 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply 
3351 set C<$signal>, sending us back into the debugger.
3352
3353 We then trim off the pipe symbols and C<redo> the command loop at the
3354 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3355 reading another.
3356
3357 =cut
3358
3359                 # || - run command in the pager, with output to DB::OUT.
3360                 $cmd =~ /^\|\|?\s*[^|]/ && do {
3361                     if ( $pager =~ /^\|/ ) {
3362
3363                         # Default pager is into a pipe. Redirect I/O.
3364                         open( SAVEOUT, ">&STDOUT" )
3365                           || &warn("Can't save STDOUT");
3366                         open( STDOUT, ">&OUT" )
3367                           || &warn("Can't redirect STDOUT");
3368                     } ## end if ($pager =~ /^\|/)
3369                     else {
3370
3371                         # Not into a pipe. STDOUT is safe.
3372                         open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
3373                     }
3374
3375                     # Fix up environment to record we have less if so.
3376                     fix_less();
3377
3378                     unless ( $piped = open( OUT, $pager ) ) {
3379
3380                         # Couldn't open pipe to pager.
3381                         &warn("Can't pipe output to `$pager'");
3382                         if ( $pager =~ /^\|/ ) {
3383
3384                             # Redirect I/O back again.
3385                             open( OUT, ">&STDOUT" )    # XXX: lost message
3386                               || &warn("Can't restore DB::OUT");
3387                             open( STDOUT, ">&SAVEOUT" )
3388                               || &warn("Can't restore STDOUT");
3389                             close(SAVEOUT);
3390                         } ## end if ($pager =~ /^\|/)
3391                         else {
3392
3393                             # Redirect I/O. STDOUT already safe.
3394                             open( OUT, ">&STDOUT" )    # XXX: lost message
3395                               || &warn("Can't restore DB::OUT");
3396                         }
3397                         next CMD;
3398                     } ## end unless ($piped = open(OUT,...
3399
3400                     # Set up broken-pipe handler if necessary.
3401                     $SIG{PIPE} = \&DB::catch
3402                       if $pager =~ /^\|/
3403                       && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
3404
3405                     # Save current filehandle, unbuffer out, and put it back.
3406                     $selected = select(OUT);
3407                     $|        = 1;
3408
3409                     # Don't put it back if pager was a pipe.
3410                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
3411
3412                     # Trim off the pipe symbols and run the command now.
3413                     $cmd =~ s/^\|+\s*//;
3414                     redo PIPE;
3415                 };
3416
3417 =head3 END OF COMMAND PARSING
3418
3419 Anything left in C<$cmd> at this point is a Perl expression that we want to 
3420 evaluate. We'll always evaluate in the user's context, and fully qualify 
3421 any variables we might want to address in the C<DB> package.
3422
3423 =cut
3424
3425                 # t - turn trace on.
3426                 $cmd =~ s/^t\s/\$DB::trace |= 1;\n/;
3427
3428                 # s - single-step. Remember the last command was 's'.
3429                 $cmd =~ s/^s\s/\$DB::single = 1;\n/ && do { $laststep = 's' };
3430
3431                 # n - single-step, but not into subs. Remember last command
3432                 # was 'n'.
3433                 $cmd =~ s/^n\s/\$DB::single = 2;\n/ && do { $laststep = 'n' };
3434
3435             }    # PIPE:
3436
3437             # Make sure the flag that says "the debugger's running" is
3438             # still on, to make sure we get control again.
3439             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3440
3441             # Run *our* eval that executes in the caller's context.
3442             &eval;
3443
3444             # Turn off the one-time-dump stuff now.
3445             if ($onetimeDump) {
3446                 $onetimeDump      = undef;
3447                 $onetimedumpDepth = undef;
3448             }
3449             elsif ( $term_pid == $$ ) {
3450                 eval {          # May run under miniperl, when not available...
3451                     STDOUT->flush();
3452                     STDERR->flush();
3453                 };
3454
3455                 # XXX If this is the master pid, print a newline.
3456                 print $OUT "\n";
3457             }
3458         } ## end while (($term || &setterm...
3459
3460 =head3 POST-COMMAND PROCESSING
3461
3462 After each command, we check to see if the command output was piped anywhere.
3463 If so, we go through the necessary code to unhook the pipe and go back to
3464 our standard filehandles for input and output.
3465
3466 =cut
3467
3468         continue {    # CMD:
3469
3470             # At the end of every command:
3471             if ($piped) {
3472
3473                 # Unhook the pipe mechanism now.
3474                 if ( $pager =~ /^\|/ ) {
3475
3476                     # No error from the child.
3477                     $? = 0;
3478
3479                     # we cannot warn here: the handle is missing --tchrist
3480                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3481
3482                     # most of the $? crud was coping with broken cshisms
3483                     # $? is explicitly set to 0, so this never runs.
3484                     if ($?) {
3485                         print SAVEOUT "Pager `$pager' failed: ";
3486                         if ( $? == -1 ) {
3487                             print SAVEOUT "shell returned -1\n";
3488                         }
3489                         elsif ( $? >> 8 ) {
3490                             print SAVEOUT ( $? & 127 )
3491                               ? " (SIG#" . ( $? & 127 ) . ")"
3492                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3493                         }
3494                         else {
3495                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3496                         }
3497                     } ## end if ($?)
3498
3499                     # Reopen filehandle for our output (if we can) and
3500                     # restore STDOUT (if we can).
3501                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3502                     open( STDOUT, ">&SAVEOUT" )
3503                       || &warn("Can't restore STDOUT");
3504
3505                     # Turn off pipe exception handler if necessary.
3506                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3507
3508                     # Will stop ignoring SIGPIPE if done like nohup(1)
3509                     # does SIGINT but Perl doesn't give us a choice.
3510                 } ## end if ($pager =~ /^\|/)
3511                 else {
3512
3513                     # Non-piped "pager". Just restore STDOUT.
3514                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3515                 }
3516
3517                 # Close filehandle pager was using, restore the normal one
3518                 # if necessary,
3519                 close(SAVEOUT);
3520                 select($selected), $selected = "" unless $selected eq "";
3521
3522                 # No pipes now.
3523                 $piped = "";
3524             } ## end if ($piped)
3525         }    # CMD:
3526
3527 =head3 COMMAND LOOP TERMINATION
3528
3529 When commands have finished executing, we come here. If the user closed the
3530 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3531 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3532 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3533 The interpreter will then execute the next line and then return control to us
3534 again.
3535
3536 =cut
3537
3538         # No more commands? Quit.
3539         $fall_off_end = 1 unless defined $cmd;    # Emulate `q' on EOF
3540
3541         # Evaluate post-prompt commands.
3542         foreach $evalarg (@$post) {
3543             &eval;
3544         }
3545     }    # if ($single || $signal)
3546
3547     # Put the user's globals back where you found them.
3548     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3549     ();
3550 } ## end sub DB
3551
3552 # The following code may be executed now:
3553 # BEGIN {warn 4}
3554
3555 =head2 sub
3556
3557 C<sub> is called whenever a subroutine call happens in the program being 
3558 debugged. The variable C<$DB::sub> contains the name of the subroutine
3559 being called.
3560
3561 The core function of this subroutine is to actually call the sub in the proper
3562 context, capturing its output. This of course causes C<DB::DB> to get called
3563 again, repeating until the subroutine ends and returns control to C<DB::sub>
3564 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3565 return value, and returns its captured copy of the return value as its own
3566 return value. The value then feeds back into the program being debugged as if
3567 C<DB::sub> hadn't been there at all.
3568
3569 C<sub> does all the work of printing the subroutine entry and exit messages
3570 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3571 and also prints the return value if needed (for the C<r> command and if 
3572 the 16 bit is set in C<$frame>).
3573
3574 It also tracks the subroutine call depth by saving the current setting of
3575 C<$single> in the C<@stack> package global; if this exceeds the value in
3576 C<$deep>, C<sub> automatically turns on printing of the current depth by
3577 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3578 of stop/don't stop on entry to subs set as it currently is set.
3579
3580 =head3 C<caller()> support
3581
3582 If C<caller()> is called from the package C<DB>, it provides some
3583 additional data, in the following order:
3584
3585 =over 4
3586
3587 =item * C<$package>
3588
3589 The package name the sub was in
3590
3591 =item * C<$filename>
3592
3593 The filename it was defined in
3594
3595 =item * C<$line>
3596
3597 The line number it was defined on
3598
3599 =item * C<$subroutine>
3600
3601 The subroutine name; C<(eval)> if an C<eval>().
3602
3603 =item * C<$hasargs>
3604
3605 1 if it has arguments, 0 if not
3606
3607 =item * C<$wantarray>
3608
3609 1 if array context, 0 if scalar context
3610
3611 =item * C<$evaltext>
3612
3613 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3614
3615 =item * C<$is_require>
3616
3617 frame was created by a C<use> or C<require> statement
3618
3619 =item * C<$hints>
3620
3621 pragma information; subject to change between versions
3622
3623 =item * C<$bitmask>
3624
3625 pragma information; subject to change between versions
3626
3627 =item * C<@DB::args>
3628
3629 arguments with which the subroutine was invoked
3630
3631 =back
3632
3633 =cut
3634
3635 sub sub {
3636         # Do not use a regex in this subroutine -> results in corrupted memory
3637         # See: [perl #66110]
3638
3639         # lock ourselves under threads
3640         lock($DBGR);
3641
3642     # Whether or not the autoloader was running, a scalar to put the
3643     # sub's return value in (if needed), and an array to put the sub's
3644     # return value in (if needed).
3645     my ( $al, $ret, @ret ) = "";
3646         if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
3647                 print "creating new thread\n"; 
3648         }
3649
3650     # If the last ten characters are '::AUTOLOAD', note we've traced
3651     # into AUTOLOAD for $sub.
3652     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3653         $al = " for $$sub" if defined $$sub;
3654     }
3655
3656     # We stack the stack pointer and then increment it to protect us
3657     # from a situation that might unwind a whole bunch of call frames
3658     # at once. Localizing the stack pointer means that it will automatically
3659     # unwind the same amount when multiple stack frames are unwound.
3660     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3661
3662     # Expand @stack.
3663     $#stack = $stack_depth;
3664
3665     # Save current single-step setting.
3666     $stack[-1] = $single;
3667
3668     # Turn off all flags except single-stepping.
3669     $single &= 1;
3670
3671     # If we've gotten really deeply recursed, turn on the flag that will
3672     # make us stop with the 'deep recursion' message.
3673     $single |= 4 if $stack_depth == $deep;
3674
3675     # If frame messages are on ...
3676     (
3677         $frame & 4    # Extended frame entry message
3678         ? (
3679             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3680
3681             # Why -1? But it works! :-(
3682             # Because print_trace will call add 1 to it and then call
3683             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3684             # in dump_trace.
3685             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3686           )
3687         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3688
3689           # standard frame entry message
3690       )
3691       if $frame;
3692
3693     # Determine the sub's return type, and capture appropriately.
3694     if (wantarray) {
3695
3696         # Called in array context. call sub and capture output.
3697         # DB::DB will recursively get control again if appropriate; we'll come
3698         # back here when the sub is finished.
3699         @ret = &$sub;
3700
3701         # Pop the single-step value back off the stack.
3702         $single |= $stack[ $stack_depth-- ];
3703
3704         # Check for exit trace messages...
3705         (
3706             $frame & 4    # Extended exit message
3707             ? (
3708                 print_lineinfo( ' ' x $stack_depth, "out " ),
3709                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3710               )
3711             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3712
3713               # Standard exit message
3714           )
3715           if $frame & 2;
3716
3717         # Print the return info if we need to.
3718         if ( $doret eq $stack_depth or $frame & 16 ) {
3719
3720             # Turn off output record separator.
3721             local $\ = '';
3722             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3723
3724             # Indent if we're printing because of $frame tracing.
3725             print $fh ' ' x $stack_depth if $frame & 16;
3726
3727             # Print the return value.
3728             print $fh "list context return from $sub:\n";
3729             dumpit( $fh, \@ret );
3730
3731             # And don't print it again.
3732             $doret = -2;
3733         } ## end if ($doret eq $stack_depth...
3734             # And we have to return the return value now.
3735         @ret;
3736     } ## end if (wantarray)
3737
3738     # Scalar context.
3739     else {
3740         if ( defined wantarray ) {
3741
3742             # Save the value if it's wanted at all.
3743             $ret = &$sub;
3744         }
3745         else {
3746
3747             # Void return, explicitly.
3748             &$sub;
3749             undef $ret;
3750         }
3751
3752         # Pop the single-step value off the stack.
3753         $single |= $stack[ $stack_depth-- ];
3754
3755         # If we're doing exit messages...
3756         (
3757             $frame & 4    # Extended messages
3758             ? (
3759                 print_lineinfo( ' ' x $stack_depth, "out " ),
3760                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3761               )
3762             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3763
3764               # Standard messages
3765           )
3766           if $frame & 2;
3767
3768         # If we are supposed to show the return value... same as before.
3769         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
3770             local $\ = '';
3771             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3772             print $fh ( ' ' x $stack_depth ) if $frame & 16;
3773             print $fh (
3774                 defined wantarray
3775                 ? "scalar context return from $sub: "
3776                 : "void context return from $sub\n"
3777             );
3778             dumpit( $fh, $ret ) if defined wantarray;
3779             $doret = -2;
3780         } ## end if ($doret eq $stack_depth...
3781
3782         # Return the appropriate scalar value.
3783         $ret;
3784     } ## end else [ if (wantarray)
3785 } ## end sub sub
3786
3787 sub lsub : lvalue {
3788
3789         # lock ourselves under threads
3790         lock($DBGR);
3791
3792     # Whether or not the autoloader was running, a scalar to put the
3793     # sub's return value in (if needed), and an array to put the sub's
3794     # return value in (if needed).
3795     my ( $al, $ret, @ret ) = "";
3796         if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
3797                 print "creating new thread\n";
3798         }
3799
3800     # If the last ten characters are C'::AUTOLOAD', note we've traced
3801     # into AUTOLOAD for $sub.
3802     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3803         $al = " for $$sub";
3804     }
3805
3806     # We stack the stack pointer and then increment it to protect us
3807     # from a situation that might unwind a whole bunch of call frames
3808     # at once. Localizing the stack pointer means that it will automatically
3809     # unwind the same amount when multiple stack frames are unwound.
3810     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3811
3812     # Expand @stack.
3813     $#stack = $stack_depth;
3814
3815     # Save current single-step setting.
3816     $stack[-1] = $single;
3817
3818     # Turn off all flags except single-stepping.
3819     $single &= 1;
3820
3821     # If we've gotten really deeply recursed, turn on the flag that will
3822     # make us stop with the 'deep recursion' message.
3823     $single |= 4 if $stack_depth == $deep;
3824
3825     # If frame messages are on ...
3826     (
3827         $frame & 4    # Extended frame entry message
3828         ? (
3829             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3830
3831             # Why -1? But it works! :-(
3832             # Because print_trace will call add 1 to it and then call
3833             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3834             # in dump_trace.
3835             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3836           )
3837         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3838
3839           # standard frame entry message
3840       )
3841       if $frame;
3842
3843     # Pop the single-step value back off the stack.
3844     $single |= $stack[ $stack_depth-- ];
3845
3846     # call the original lvalue sub.
3847     &$sub;
3848 }
3849
3850 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
3851
3852 In Perl 5.8.0, there was a major realignment of the commands and what they did,
3853 Most of the changes were to systematize the command structure and to eliminate
3854 commands that threw away user input without checking.
3855
3856 The following sections describe the code added to make it easy to support 
3857 multiple command sets with conflicting command names. This section is a start 
3858 at unifying all command processing to make it simpler to develop commands.
3859
3860 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line 
3861 number, and C<$dbline> (the current line) as arguments.
3862
3863 Support functions in this section which have multiple modes of failure C<die> 
3864 on error; the rest simply return a false value.
3865
3866 The user-interface functions (all of the C<cmd_*> functions) just output
3867 error messages.
3868
3869 =head2 C<%set>
3870
3871 The C<%set> hash defines the mapping from command letter to subroutine
3872 name suffix. 
3873
3874 C<%set> is a two-level hash, indexed by set name and then by command name.
3875 Note that trying to set the CommandSet to C<foobar> simply results in the
3876 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
3877
3878 =cut 
3879
3880 ### The API section
3881
3882 my %set = (    #
3883     'pre580' => {
3884         'a' => 'pre580_a',
3885         'A' => 'pre580_null',
3886         'b' => 'pre580_b',
3887         'B' => 'pre580_null',
3888         'd' => 'pre580_null',
3889         'D' => 'pre580_D',
3890         'h' => 'pre580_h',
3891         'M' => 'pre580_null',
3892         'O' => 'o',
3893         'o' => 'pre580_null',
3894         'v' => 'M',
3895         'w' => 'v',
3896         'W' => 'pre580_W',
3897     },
3898     'pre590' => {
3899         '<'  => 'pre590_prepost',
3900         '<<' => 'pre590_prepost',
3901         '>'  => 'pre590_prepost',
3902         '>>' => 'pre590_prepost',
3903         '{'  => 'pre590_prepost',
3904         '{{' => 'pre590_prepost',
3905     },
3906 );
3907
3908 =head2 C<cmd_wrapper()> (API)
3909
3910 C<cmd_wrapper()> allows the debugger to switch command sets 
3911 depending on the value of the C<CommandSet> option. 
3912
3913 It tries to look up the command in the C<%set> package-level I<lexical>
3914 (which means external entities can't fiddle with it) and create the name of 
3915 the sub to call based on the value found in the hash (if it's there). I<All> 
3916 of the commands to be handled in a set have to be added to C<%set>; if they 
3917 aren't found, the 5.8.0 equivalent is called (if there is one).
3918
3919 This code uses symbolic references. 
3920
3921 =cut
3922
3923 sub cmd_wrapper {
3924     my $cmd      = shift;
3925     my $line     = shift;
3926     my $dblineno = shift;
3927
3928     # Assemble the command subroutine's name by looking up the
3929     # command set and command name in %set. If we can't find it,
3930     # default to the older version of the command.
3931     my $call = 'cmd_'
3932       . ( $set{$CommandSet}{$cmd}
3933           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
3934
3935     # Call the command subroutine, call it by name.
3936     return &$call( $cmd, $line, $dblineno );
3937 } ## end sub cmd_wrapper
3938
3939 =head3 C<cmd_a> (command)
3940
3941 The C<a> command handles pre-execution actions. These are associated with a
3942 particular line, so they're stored in C<%dbline>. We default to the current 
3943 line if none is specified. 
3944
3945 =cut
3946
3947 sub cmd_a {
3948     my $cmd    = shift;
3949     my $line   = shift || '';    # [.|line] expr
3950     my $dbline = shift;
3951
3952     # If it's dot (here), or not all digits,  use the current line.
3953     $line =~ s/^(\.|(?:[^\d]))/$dbline/;
3954
3955     # Should be a line number followed by an expression.
3956     if ( $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
3957         my ( $lineno, $expr ) = ( $1, $2 );
3958
3959         # If we have an expression ...
3960         if ( length $expr ) {
3961
3962             # ... but the line isn't breakable, complain.
3963             if ( $dbline[$lineno] == 0 ) {
3964                 print $OUT
3965                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
3966             }
3967             else {
3968
3969                 # It's executable. Record that the line has an action.
3970                 $had_breakpoints{$filename} |= 2;
3971
3972                 # Remove any action, temp breakpoint, etc.
3973                 $dbline{$lineno} =~ s/\0[^\0]*//;
3974
3975                 # Add the action to the line.
3976                 $dbline{$lineno} .= "\0" . action($expr);
3977             }
3978         } ## end if (length $expr)
3979     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
3980     else {
3981
3982         # Syntax wrong.
3983         print $OUT
3984           "Adding an action requires an optional lineno and an expression\n"
3985           ;    # hint
3986     }
3987 } ## end sub cmd_a
3988
3989 =head3 C<cmd_A> (command)
3990
3991 Delete actions. Similar to above, except the delete code is in a separate
3992 subroutine, C<delete_action>.
3993
3994 =cut
3995
3996 sub cmd_A {
3997     my $cmd    = shift;
3998     my $line   = shift || '';
3999     my $dbline = shift;
4000
4001     # Dot is this line.
4002     $line =~ s/^\./$dbline/;
4003
4004     # Call delete_action with a null param to delete them all.
4005     # The '1' forces the eval to be true. It'll be false only
4006     # if delete_action blows up for some reason, in which case
4007     # we print $@ and get out.
4008     if ( $line eq '*' ) {
4009         eval { &delete_action(); 1 } or print $OUT $@ and return;
4010     }
4011
4012     # There's a real line  number. Pass it to delete_action.
4013     # Error trapping is as above.
4014     elsif ( $line =~ /^(\S.*)/ ) {
4015         eval { &delete_action($1); 1 } or print $OUT $@ and return;
4016     }
4017
4018     # Swing and a miss. Bad syntax.
4019     else {
4020         print $OUT
4021           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4022     }
4023 } ## end sub cmd_A
4024
4025 =head3 C<delete_action> (API)
4026
4027 C<delete_action> accepts either a line number or C<undef>. If a line number
4028 is specified, we check for the line being executable (if it's not, it 
4029 couldn't have had an  action). If it is, we just take the action off (this
4030 will get any kind of an action, including breakpoints).
4031
4032 =cut
4033
4034 sub delete_action {
4035     my $i = shift;
4036     if ( defined($i) ) {
4037
4038         # Can there be one?
4039         die "Line $i has no action .\n" if $dbline[$i] == 0;
4040
4041         # Nuke whatever's there.
4042         $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4043         delete $dbline{$i} if $dbline{$i} eq '';
4044     }
4045     else {
4046         print $OUT "Deleting all actions...\n";
4047         for my $file ( keys %had_breakpoints ) {
4048             local *dbline = $main::{ '_<' . $file };
4049             my $max = $#dbline;
4050             my $was;
4051             for ( $i = 1 ; $i <= $max ; $i++ ) {
4052                 if ( defined $dbline{$i} ) {
4053                     $dbline{$i} =~ s/\0[^\0]*//;
4054                     delete $dbline{$i} if $dbline{$i} eq '';
4055                 }
4056                 unless ( $had_breakpoints{$file} &= ~2 ) {
4057                     delete $had_breakpoints{$file};
4058                 }
4059             } ## end for ($i = 1 ; $i <= $max...
4060         } ## end for my $file (keys %had_breakpoints)
4061     } ## end else [ if (defined($i))
4062 } ## end sub delete_action
4063
4064 =head3 C<cmd_b> (command)
4065
4066 Set breakpoints. Since breakpoints can be set in so many places, in so many
4067 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4068 we try to parse the command type, and then shuttle it off to an appropriate
4069 subroutine to actually do the work of setting the breakpoint in the right
4070 place.
4071
4072 =cut
4073
4074 sub cmd_b {
4075     my $cmd    = shift;
4076     my $line   = shift;    # [.|line] [cond]
4077     my $dbline = shift;
4078
4079     # Make . the current line number if it's there..
4080     $line =~ s/^\.\b/$dbline/;
4081
4082     # No line number, no condition. Simple break on current line.
4083     if ( $line =~ /^\s*$/ ) {
4084         &cmd_b_line( $dbline, 1 );
4085     }
4086
4087     # Break on load for a file.
4088     elsif ( $line =~ /^load\b\s*(.*)/ ) {
4089         my $file = $1;
4090         $file =~ s/\s+$//;
4091         &cmd_b_load($file);
4092     }
4093
4094     # b compile|postpone <some sub> [<condition>]
4095     # The interpreter actually traps this one for us; we just put the
4096     # necessary condition in the %postponed hash.
4097     elsif ( $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4098
4099         # Capture the condition if there is one. Make it true if none.
4100         my $cond = length $3 ? $3 : '1';
4101
4102         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
4103         # if it was 'compile'.
4104         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
4105
4106         # De-Perl4-ify the name - ' separators to ::.
4107         $subname =~ s/\'/::/g;
4108
4109         # Qualify it into the current package unless it's already qualified.
4110         $subname = "${'package'}::" . $subname unless $subname =~ /::/;
4111
4112         # Add main if it starts with ::.
4113         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4114
4115         # Save the break type for this sub.
4116         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
4117     } ## end elsif ($line =~ ...
4118     # b <filename>:<line> [<condition>]
4119     elsif ($line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4120         my ($filename, $line_num, $cond) = ($1, $2, $3);
4121         cmd_b_filename_line(
4122             $filename,
4123             $line_num, 
4124             (length($cond) ? $cond : '1'),
4125         );
4126     }
4127     # b <sub name> [<condition>]
4128     elsif ( $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4129
4130         #
4131         $subname = $1;
4132         $cond = length $2 ? $2 : '1';
4133         &cmd_b_sub( $subname, $cond );
4134     }
4135
4136     # b <line> [<condition>].
4137     elsif ( $line =~ /^(\d*)\s*(.*)/ ) {
4138
4139         # Capture the line. If none, it's the current line.
4140         $line = $1 || $dbline;
4141
4142         # If there's no condition, make it '1'.
4143         $cond = length $2 ? $2 : '1';
4144
4145         # Break on line.
4146         &cmd_b_line( $line, $cond );
4147     }
4148
4149     # Line didn't make sense.
4150     else {
4151         print "confused by line($line)?\n";
4152     }
4153 } ## end sub cmd_b
4154
4155 =head3 C<break_on_load> (API)
4156
4157 We want to break when this file is loaded. Mark this file in the
4158 C<%break_on_load> hash, and note that it has a breakpoint in 
4159 C<%had_breakpoints>.
4160
4161 =cut
4162
4163 sub break_on_load {
4164     my $file = shift;
4165     $break_on_load{$file} = 1;
4166     $had_breakpoints{$file} |= 1;
4167 }
4168
4169 =head3 C<report_break_on_load> (API)
4170
4171 Gives us an array of filenames that are set to break on load. Note that 
4172 only files with break-on-load are in here, so simply showing the keys
4173 suffices.
4174
4175 =cut
4176
4177 sub report_break_on_load {
4178     sort keys %break_on_load;
4179 }
4180
4181 =head3 C<cmd_b_load> (command)
4182
4183 We take the file passed in and try to find it in C<%INC> (which maps modules
4184 to files they came from). We mark those files for break-on-load via 
4185 C<break_on_load> and then report that it was done.
4186
4187 =cut
4188
4189 sub cmd_b_load {
4190     my $file = shift;
4191     my @files;
4192
4193     # This is a block because that way we can use a redo inside it
4194     # even without there being any looping structure at all outside it.
4195     {
4196
4197         # Save short name and full path if found.
4198         push @files, $file;
4199         push @files, $::INC{$file} if $::INC{$file};
4200
4201         # Tack on .pm and do it again unless there was a '.' in the name
4202         # already.
4203         $file .= '.pm', redo unless $file =~ /\./;
4204     }
4205
4206     # Do the real work here.
4207     break_on_load($_) for @files;
4208
4209     # All the files that have break-on-load breakpoints.
4210     @files = report_break_on_load;
4211
4212     # Normalize for the purposes of our printing this.
4213     local $\ = '';
4214     local $" = ' ';
4215     print $OUT "Will stop on load of `@files'.\n";
4216 } ## end sub cmd_b_load
4217
4218 =head3 C<$filename_error> (API package global)
4219
4220 Several of the functions we need to implement in the API need to work both
4221 on the current file and on other files. We don't want to duplicate code, so
4222 C<$filename_error> is used to contain the name of the file that's being 
4223 worked on (if it's not the current one).
4224
4225 We can now build functions in pairs: the basic function works on the current
4226 file, and uses C<$filename_error> as part of its error message. Since this is
4227 initialized to C<"">, no filename will appear when we are working on the
4228 current file.
4229
4230 The second function is a wrapper which does the following:
4231
4232 =over 4 
4233
4234 =item *
4235
4236 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4237
4238 =item *
4239
4240 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process. 
4241
4242 =item *
4243
4244 Calls the first function. 
4245
4246 The first function works on the I<current> file (i.e., the one we changed to),
4247 and prints C<$filename_error> in the error message (the name of the other file)
4248 if it needs to. When the functions return, C<*dbline> is restored to point
4249 to the actual current file (the one we're executing in) and
4250 C<$filename_error> is restored to C<"">. This restores everything to
4251 the way it was before the second function was called at all.
4252
4253 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4254 details.
4255
4256 =back
4257
4258 =cut
4259
4260 $filename_error = '';
4261
4262 =head3 breakable_line(from, to) (API)
4263
4264 The subroutine decides whether or not a line in the current file is breakable.
4265 It walks through C<@dbline> within the range of lines specified, looking for
4266 the first line that is breakable.
4267
4268 If C<$to> is greater than C<$from>, the search moves forwards, finding the 
4269 first line I<after> C<$to> that's breakable, if there is one.
4270
4271 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4272 first line I<before> C<$to> that's breakable, if there is one.
4273
4274 =cut
4275
4276 sub breakable_line {
4277
4278     my ( $from, $to ) = @_;
4279
4280     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4281     my $i = $from;
4282
4283     # If there are at least 2 arguments, we're trying to search a range.
4284     if ( @_ >= 2 ) {
4285
4286         # $delta is positive for a forward search, negative for a backward one.
4287         my $delta = $from < $to ? +1 : -1;
4288
4289         # Keep us from running off the ends of the file.
4290         my $limit = $delta > 0 ? $#dbline : 1;
4291
4292         # Clever test. If you're a mathematician, it's obvious why this
4293         # test works. If not:
4294         # If $delta is positive (going forward), $limit will be $#dbline.
4295         #    If $to is less than $limit, ($limit - $to) will be positive, times
4296         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4297         #    as the stopping point.
4298         #
4299         #    If $to is greater than $limit, ($limit - $to) is negative,
4300         #    times $delta of 1 (positive), so the result is < 0 and we should
4301         #    use $limit ($#dbline) as the stopping point.
4302         #
4303         # If $delta is negative (going backward), $limit will be 1.
4304         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4305         #    (negative) so the result is > 0, and we use $to as the stopping
4306         #    point.
4307         #
4308         #    If $to is less than zero, ($limit - $to) will be positive,
4309         #    times $delta of -1 (negative), so the result is not > 0, and
4310         #    we use $limit (1) as the stopping point.
4311         #
4312         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4313         #    (negative), still giving zero; the result is not > 0, and
4314         #    we use $limit (1) as the stopping point.
4315         #
4316         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4317         #    (negative), giving a positive (>0) value, so we'll set $limit to
4318         #    $to.
4319
4320         $limit = $to if ( $limit - $to ) * $delta > 0;
4321
4322         # The real search loop.
4323         # $i starts at $from (the point we want to start searching from).
4324         # We move through @dbline in the appropriate direction (determined
4325         # by $delta: either -1 (back) or +1 (ahead).
4326         # We stay in as long as we haven't hit an executable line
4327         # ($dbline[$i] == 0 means not executable) and we haven't reached
4328         # the limit yet (test similar to the above).
4329         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4330
4331     } ## end if (@_ >= 2)
4332
4333     # If $i points to a line that is executable, return that.
4334     return $i unless $dbline[$i] == 0;
4335
4336     # Format the message and print it: no breakable lines in range.
4337     my ( $pl, $upto ) = ( '', '' );
4338     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4339
4340     # If there's a filename in filename_error, we'll see it.
4341     # If not, not.
4342     die "Line$pl $from$upto$filename_error not breakable\n";
4343 } ## end sub breakable_line
4344
4345 =head3 breakable_line_in_filename(file, from, to) (API)
4346
4347 Like C<breakable_line>, but look in another file.
4348
4349 =cut
4350
4351 sub breakable_line_in_filename {
4352
4353     # Capture the file name.
4354     my ($f) = shift;
4355
4356     # Swap the magic line array over there temporarily.
4357     local *dbline = $main::{ '_<' . $f };
4358
4359     # If there's an error, it's in this other file.
4360     local $filename_error = " of `$f'";
4361
4362     # Find the breakable line.
4363     breakable_line(@_);
4364
4365     # *dbline and $filename_error get restored when this block ends.
4366
4367 } ## end sub breakable_line_in_filename
4368
4369 =head3 break_on_line(lineno, [condition]) (API)
4370
4371 Adds a breakpoint with the specified condition (or 1 if no condition was 
4372 specified) to the specified line. Dies if it can't.
4373
4374 =cut
4375
4376 sub break_on_line {
4377     my ( $i, $cond ) = @_;
4378
4379     # Always true if no condition supplied.
4380     $cond = 1 unless @_ >= 2;
4381
4382     my $inii  = $i;
4383     my $after = '';
4384     my $pl    = '';
4385
4386     # Woops, not a breakable line. $filename_error allows us to say
4387     # if it was in a different file.
4388     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4389
4390     # Mark this file as having breakpoints in it.
4391     $had_breakpoints{$filename} |= 1;
4392
4393     # If there is an action or condition here already ...
4394     if ( $dbline{$i} ) {
4395
4396         # ... swap this condition for the existing one.
4397         $dbline{$i} =~ s/^[^\0]*/$cond/;
4398     }
4399     else {
4400
4401         # Nothing here - just add the condition.
4402         $dbline{$i} = $cond;
4403     }
4404 } ## end sub break_on_line
4405
4406 =head3 cmd_b_line(line, [condition]) (command)
4407
4408 Wrapper for C<break_on_line>. Prints the failure message if it 
4409 doesn't work.
4410
4411 =cut 
4412
4413 sub cmd_b_line {
4414     eval { break_on_line(@_); 1 } or do {
4415         local $\ = '';
4416         print $OUT $@ and return;
4417     };
4418 } ## end sub cmd_b_line
4419
4420 =head3 cmd_b_filename_line(line, [condition]) (command)
4421
4422 Wrapper for C<break_on_filename_line>. Prints the failure message if it 
4423 doesn't work.
4424
4425 =cut 
4426
4427 sub cmd_b_filename_line {
4428     eval { break_on_filename_line(@_); 1 } or do {
4429         local $\ = '';
4430         print $OUT $@ and return;
4431     };
4432 }
4433
4434 =head3 break_on_filename_line(file, line, [condition]) (API)
4435
4436 Switches to the file specified and then calls C<break_on_line> to set 
4437 the breakpoint.
4438
4439 =cut
4440
4441 sub break_on_filename_line {
4442     my ( $f, $i, $cond ) = @_;
4443
4444     # Always true if condition left off.
4445     $cond = 1 unless @_ >= 3;
4446
4447     # Switch the magical hash temporarily.
4448     local *dbline = $main::{ '_<' . $f };
4449
4450     # Localize the variables that break_on_line uses to make its message.
4451     local $filename_error = " of `$f'";
4452     local $filename       = $f;